chiark / gitweb /
resolved: add alignment to base64
[elogind.git] / configure.ac
1 #
2 #  This file is part of elogind.
3 #
4 #  Copyright 2010-2012 Lennart Poettering
5 #  Copyright 2010-2012 Kay Sievers
6 #
7 #  elogind is free software; you can redistribute it and/or modify it
8 #  under the terms of the GNU Lesser General Public License as published by
9 #  the Free Software Foundation; either version 2.1 of the License, or
10 #  (at your option) any later version.
11 #
12 #  elogind is distributed in the hope that it will be useful, but
13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 #  Lesser General Public License for more details.
16 #
17 #  You should have received a copy of the GNU Lesser General Public License
18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
19
20 AC_PREREQ([2.64])
21
22 AC_INIT([elogind],
23         [228.3],
24         [https://github.com/elogind/elogind/issues],
25         [elogind],
26         [https://github.com/elogind/elogind])
27
28 AC_CONFIG_SRCDIR([src/login/logind.c])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_HEADERS([config.h])
31 AC_CONFIG_AUX_DIR([build-aux])
32
33 AC_USE_SYSTEM_EXTENSIONS
34 AC_SYS_LARGEFILE
35 AC_PREFIX_DEFAULT([/usr])
36 AM_MAINTAINER_MODE([enable])
37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
38 AM_SILENT_RULES([yes])
39 AC_CANONICAL_HOST
40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
41
42 AC_PROG_CC_C99
43
44 AX_COMPILER_VENDOR
45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
49 ])
50
51 LT_PREREQ(2.2)
52 LT_INIT([disable-static])
53
54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
56
57 SET_ARCH(X86_64, x86_64*)
58 SET_ARCH(IA32, i*86*)
59 SET_ARCH(MIPS, mips*)
60 SET_ARCH(AARCH64, aarch64*)
61
62 # i18n stuff for the PolicyKit policy files, check whether intltool can be found, disable NLS otherwise
63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
64 AS_IF([test x"$intltool_found" != xyes],
65       [AS_IF([test x"$enable_nls" = xyes],
66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
67              [AS_IF([test x"$enable_nls" != xno],
68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
69                      enable_nls=no])
70              ])
71       ])
72
73 AM_NLS
74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
76 IT_PROG_INTLTOOL([0.40.0])
77 ])
78
79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
82     AC_SUBST(INTLTOOL_POLICY_RULE)
83 ])
84
85 GETTEXT_PACKAGE=elogind
86 AC_SUBST(GETTEXT_PACKAGE)
87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
88
89 AC_PROG_MKDIR_P
90 AC_PROG_LN_S
91 AC_PROG_SED
92 AC_PROG_GREP
93 AC_PROG_AWK
94
95 AC_PATH_PROG([M4], [m4])
96 AC_PATH_PROG([XSLTPROC], [xsltproc])
97
98 AC_PATH_PROG([HALT], [halt], [halt])
99 AC_PATH_PROG([REBOOT], [reboot], [reboot])
100 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
101
102 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
103
104 M4_DEFINES=
105
106 AC_CHECK_TOOL(OBJCOPY, objcopy)
107 AC_CHECK_TOOL(GPERF, gperf)
108 if test -z "$GPERF" ; then
109         AC_MSG_ERROR([*** gperf not found])
110 fi
111
112
113 # ------------------------------------------------------------------------------
114 # Find running cgroup controller
115 with_cgroupctrl=
116 AS_IF(  [test -f /proc/self/cgroup], [
117         # If the init system is a cgroup controler, it will be position 1.
118         # Secondary controllers, like cgmanager, do not work.
119         with_cgroupctrl=`grep "^1:name=" /proc/self/cgroup | cut -d ':' -f 2`
120         AS_IF(  [test -z "$with_cgroupctrl"], [
121                 # Try to be our own cgroup controller
122                 with_cgroupctrl="name=elogind"
123         ])
124 ])
125 AS_IF(  [test -z "$with_cgroupctrl"],
126         AC_MSG_ERROR([No running cgroup controller found]))
127
128
129 # ------------------------------------------------------------------------------
130 address_sanitizer_cflags=
131 address_sanitizer_cppflags=
132 address_sanitizer_ldflags=
133 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
134 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
135             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
136             AS_IF([test -z "$with_as_cflags"],
137                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
138             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
139             address_sanitizer_cppflags="-DVALGRIND=1"
140             address_sanitizer_ldflags="-Wc,-fsanitize=address"
141       ])
142
143 undefined_sanitizer_cflags=
144 undefined_sanitizer_cppflags=
145 undefined_sanitizer_ldflags=
146 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
147 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
148             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
149             AS_IF([test -z "$with_us_cflags"],
150                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
151             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
152             undefined_sanitizer_cppflags="-DVALGRIND=1"
153             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
154       ])
155
156 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
157 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
158 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
159
160 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
161         -pipe \
162         -Wall \
163         -Wextra \
164         -Wundef \
165         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
166         -Wlogical-op \
167         -Wmissing-include-dirs \
168         -Wold-style-definition \
169         -Wpointer-arith \
170         -Winit-self \
171         -Wdeclaration-after-statement \
172         -Wfloat-equal \
173         -Wsuggest-attribute=noreturn \
174         -Werror=missing-prototypes \
175         -Werror=implicit-function-declaration \
176         -Werror=missing-declarations \
177         -Werror=return-type \
178         -Wstrict-prototypes \
179         -Wredundant-decls \
180         -Wmissing-noreturn \
181         -Wshadow \
182         -Wendif-labels \
183         -Wstrict-aliasing=2 \
184         -Wwrite-strings \
185         -Wno-unused-parameter \
186         -Wno-missing-field-initializers \
187         -Wno-unused-result \
188         -Wno-format-signedness \
189         -Werror=overflow \
190         -Wdate-time \
191         -Wnested-externs \
192         -ffast-math \
193         -fno-common \
194         -fdiagnostics-show-option \
195         -fno-strict-aliasing \
196         -fvisibility=hidden \
197         -fstack-protector \
198         -fstack-protector-strong \
199         -fPIE \
200         --param=ssp-buffer-size=4])
201
202 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
203 #include <time.h>
204 #include <inttypes.h>
205 typedef uint64_t usec_t;
206 usec_t now(clockid_t clock);
207 int main(void) {
208         struct timespec now;
209         return 0;
210 }
211 ])
212
213 AS_CASE([$CC], [*clang*],
214         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
215                -Wno-typedef-redefinition \
216                -Wno-gnu-variable-sized-type-not-at-end \
217         ])])
218
219
220 # ------------------------------------------------------------------------------
221 # On some distributions -flto, even if available, leads to linking errors.
222 # We therefore make it optional
223 have_lto=no
224 AC_ARG_ENABLE([lto],
225         [AS_HELP_STRING([--disable-lto], [Disable link time optimization (default: test)])])
226
227 AS_IF([test "x$enable_lto" != "xno"], [
228         AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
229                 [have_lto=yes],
230                 [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
231         AS_IF([test "$have_lto" != "no"],
232                 [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-flto])]
233         )
234         AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
235 ])
236
237 # ------------------------------------------------------------------------------
238 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
239         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
240                -Wp,-D_FORTIFY_SOURCE=2])],
241         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
242 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
243
244 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
245         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
246                -Wl,--gc-sections])],
247         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
248 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
249
250 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
251         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
252                -ffunction-sections -fdata-sections])],
253         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
254 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
255
256 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
257         -Wl,--as-needed \
258         -Wl,--no-undefined \
259         -Wl,-z,relro \
260         -Wl,-z,now \
261         -pie \
262         -Wl,-fuse-ld=gold])
263 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
264
265 AC_CHECK_SIZEOF(pid_t)
266 AC_CHECK_SIZEOF(uid_t)
267 AC_CHECK_SIZEOF(gid_t)
268 AC_CHECK_SIZEOF(time_t)
269 AC_CHECK_SIZEOF(dev_t)
270 AC_CHECK_SIZEOF(rlim_t,,[
271        #include <sys/time.h>
272        #include <sys/resource.h>
273 ])
274
275 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
276 save_CFLAGS="$CFLAGS"
277 CFLAGS="$CFLAGS -Wno-error"
278 AC_COMPILE_IFELSE(
279         [AC_LANG_PROGRAM([
280                 #include <string.h>
281                 const char * in_word_set(const char *, size_t);
282                 $GPERF_TEST]
283         )],
284         [GPERF_LEN_TYPE=size_t],
285         [AC_COMPILE_IFELSE(
286                 [AC_LANG_PROGRAM([
287                         #include <string.h>
288                         const char * in_word_set(const char *, unsigned);
289                         $GPERF_TEST]
290                 )],
291                 [GPERF_LEN_TYPE=unsigned],
292                 [AC_MSG_ERROR([** unable to determine gperf len type])]
293         )]
294 )
295 CFLAGS="$save_CFLAGS"
296
297 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
298
299 # ------------------------------------------------------------------------------
300 # we use python to build the man page index
301 have_python=no
302 AC_ARG_WITH([python],
303         [AS_HELP_STRING([--without-python], [Disable building the man page index (default: test)])])
304
305 have_lxml=no
306 AS_IF([test "x$with_python" != "xno"], [
307         AM_PATH_PYTHON(,, [:])
308         AS_IF([test "x$PYTHON" != "x:"], [
309                 AC_MSG_CHECKING([for python lxml module])
310                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
311                 AC_MSG_RESULT([$have_lxml])
312                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
313                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
314         ])
315 ])
316 AS_IF([test "$have_python" != "yes"], [
317       AS_IF([test "$with_python" = "yes"],
318             [AC_MSG_ERROR([*** python support requested but python support not found])])
319       AS_IF([test "$with_python" != "no"],
320             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
321 ])
322 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
323
324 # ------------------------------------------------------------------------------
325
326 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
327 AC_CHECK_HEADERS([linux/memfd.h], [], [])
328
329 AC_CHECK_HEADERS([printf.h], [have_printf_h=yes], [have_printf_h=no])
330 AS_IF([test x$have_printf_h = xyes], [
331         AC_DEFINE(HAVE_PRINTF_H, 1, [Define if printf.h was found])
332 ])
333
334
335
336 # unconditionally pull-in librt with old glibc versions
337 dnl AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
338 dnl AC_SEARCH_LIBS([mq_unlink], [rt], [], [])
339
340 save_LIBS="$LIBS"
341 LIBS=
342 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
343 CAP_LIBS="$LIBS"
344 AC_SUBST(CAP_LIBS)
345
346 AC_CHECK_FUNCS([memfd_create])
347 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
348 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
349                [], [], [[
350 #include <sys/types.h>
351 #include <unistd.h>
352 #include <sys/mount.h>
353 #include <fcntl.h>
354 #include <sched.h>
355 #include <linux/loop.h>
356 #include <linux/random.h>
357 ]])
358
359 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
360                 IFLA_MACVLAN_FLAGS,
361                 IFLA_IPVLAN_MODE,
362                 IFLA_VTI_REMOTE,
363                 IFLA_PHYS_PORT_ID,
364                 IFLA_BOND_AD_INFO,
365                 IFLA_VLAN_PROTOCOL,
366                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
367                 IFLA_IPTUN_ENCAP_DPORT,
368                 IFLA_GRE_ENCAP_DPORT,
369                 IFLA_BRIDGE_VLAN_INFO,
370                 IFLA_BRPORT_LEARNING_SYNC,
371                 IFLA_BR_PRIORITY,
372                 NDA_IFINDEX,
373                 IFA_FLAGS],
374 [], [], [[
375 #include <inttypes.h>
376 #include <netinet/in.h>
377 #include <netinet/ether.h>
378 #include <linux/rtnetlink.h>
379 #include <net/if.h>
380 #include <linux/ip.h>
381 #include <linux/if_tunnel.h>
382 #include <linux/if_link.h>
383 #include <linux/if_bridge.h>
384 #include <linux/if_addr.h>
385 #include <linux/neighbour.h>
386 ]])
387
388 # This makes sure pkg.m4 is available.
389 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
390
391
392 # ------------------------------------------------------------------------------
393 PKG_CHECK_MODULES(UDEV, [libudev])
394 dnl
395 AC_ARG_WITH([udevrulesdir],
396             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
397             [],
398             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
399 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
400
401 AC_ARG_WITH([udevbindir],
402             AS_HELP_STRING([--with-udevbindir=DIR], [Directory for udev binary files]),
403             [],
404             [with_udevbindir=$($PKG_CONFIG --variable=udevdir udev)])
405 AC_SUBST([udevbindir], [$with_udevbindir])
406
407 # ------------------------------------------------------------------------------
408 have_coverage=no
409 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
410 if test "x$enable_coverage" = "xyes" ; then
411         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
412         if test "x$lcov_found" = xno ; then
413                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
414         else
415                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
416                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
417                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
418                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
419                 else
420                         have_coverage=yes
421                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
422                         -fprofile-arcs \
423                         -ftest-coverage])
424                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
425                 fi
426         fi
427 fi
428 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
429
430 # ------------------------------------------------------------------------------
431 have_selinux=no
432 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
433 if test "x$enable_selinux" != "xno"; then
434         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
435                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
436                  have_selinux=yes
437                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
438                 [have_selinux=no])
439         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
440                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
441         fi
442 fi
443 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
444
445 # ------------------------------------------------------------------------------
446 AC_ARG_ENABLE([pam],
447         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
448                 [case "${enableval}" in
449                         yes) have_pam=yes ;;
450                         no) have_pam=no ;;
451                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
452                 esac],
453                 [have_pam=auto])
454
455 if test "x${have_pam}" != xno ; then
456         AC_CHECK_HEADERS(
457                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
458                 [have_pam=yes],
459                 [if test "x$have_pam" = xyes ; then
460                         AC_MSG_ERROR([*** PAM headers not found.])
461                 fi])
462
463         AC_CHECK_LIB(
464                 [pam],
465                 [pam_syslog],
466                 [have_pam=yes],
467                 [if test "x$have_pam" = xyes ; then
468                         AC_MSG_ERROR([*** libpam not found.])
469                 fi])
470
471         if test "x$have_pam" = xyes ; then
472                 PAM_LIBS="-lpam -lpam_misc"
473                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
474                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
475         else
476                 have_pam=no
477         fi
478 else
479         PAM_LIBS=
480 fi
481 AC_SUBST(PAM_LIBS)
482 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
483
484 # ------------------------------------------------------------------------------
485 AC_ARG_ENABLE([acl],
486         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
487                 [case "${enableval}" in
488                         yes) have_acl=yes ;;
489                         no) have_acl=no ;;
490                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
491                 esac],
492                 [have_acl=auto])
493
494 if test "x${have_acl}" != xno ; then
495         AC_CHECK_HEADERS(
496                 [sys/acl.h acl/libacl.h],
497                 [have_acl=yes],
498                 [if test "x$have_acl" = xyes ; then
499                         AC_MSG_ERROR([*** ACL headers not found.])
500                 fi])
501
502         AC_CHECK_LIB(
503                 [acl],
504                 [acl_get_file],
505                 [have_acl=yes],
506                 [if test "x$have_acl" = xyes ; then
507                         AC_MSG_ERROR([*** libacl not found.])
508                 fi])
509
510         if test "x$have_acl" = xyes ; then
511                 ACL_LIBS="-lacl"
512                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
513                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
514         else
515                 have_acl=no
516         fi
517 else
518         ACL_LIBS=
519 fi
520 AC_SUBST(ACL_LIBS)
521 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
522
523 # ------------------------------------------------------------------------------
524 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
525                 [case "${enableval}" in
526                         yes) have_smack=yes ;;
527                         no) have_smack=no ;;
528                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
529                 esac],
530                 [have_smack=auto])
531
532 if test "x${have_smack}" = xauto; then
533         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
534         have_smack=yes
535 fi
536
537 have_smack_run_label=no
538 AC_ARG_WITH(smack-run-label,
539 AS_HELP_STRING([--with-smack-run-label=STRING],
540         [run systemd --system itself with a specific SMACK label]),
541         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
542         [])
543
544 if test "x${have_smack_run_label}" = xyes; then
545         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
546 fi
547
548 AC_ARG_WITH(smack-default-process-label,
549 AS_HELP_STRING([--with-smack-default-process-label=STRING],
550         [default SMACK label for executed processes]),
551         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
552         [])
553
554 if test "x${have_smack}" = xyes ; then
555         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
556 fi
557
558 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
559
560 # ------------------------------------------------------------------------------
561 AC_ARG_WITH(system-uid-max,
562         AS_HELP_STRING([--with-system-uid-max=UID]
563                 [Maximum UID for system users]),
564         [SYSTEM_UID_MAX="$withval"],
565         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
566
567 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
568 AC_SUBST(SYSTEM_UID_MAX)
569
570 # ------------------------------------------------------------------------------
571 AC_ARG_WITH(system-gid-max,
572         AS_HELP_STRING([--with-system-gid-max=GID]
573                 [Maximum GID for system groups]),
574         [SYSTEM_GID_MAX="$withval"],
575         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
576
577 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
578 AC_SUBST(SYSTEM_GID_MAX)
579
580 # ------------------------------------------------------------------------------
581 have_polkit=no
582 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
583 if test "x$enable_polkit" != "xno"; then
584         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
585         have_polkit=yes
586 fi
587 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
588
589 # ------------------------------------------------------------------------------
590 have_kdbus=no
591 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
592 if test "x$enable_kdbus" != "xno"; then
593         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
594         have_kdbus=yes
595         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
596 fi
597 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
598
599 # ------------------------------------------------------------------------------
600 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
601
602 # ------------------------------------------------------------------------------
603 have_manpages=no
604 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
605 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
606 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
607
608 # ------------------------------------------------------------------------------
609 AC_SUBST(M4_DEFINES)
610
611 AC_ARG_WITH([dbuspolicydir],
612         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
613         [],
614         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
615 AX_NORMALIZE_PATH([with_dbuspolicydir])
616
617 AC_ARG_WITH([dbussystemservicedir],
618         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
619         [],
620         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
621 AX_NORMALIZE_PATH([with_dbussystemservicedir])
622
623 AC_ARG_WITH([bashcompletiondir],
624         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
625         [],
626         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
627                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
628         ] , [
629                 with_bashcompletiondir=${datadir}/bash-completion/completions
630         ])])
631 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
632 AX_NORMALIZE_PATH([with_bashcompletiondir])
633
634 AC_ARG_WITH([zshcompletiondir],
635         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
636         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
637 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
638 AX_NORMALIZE_PATH([with_zshcompletiondir])
639
640 AC_ARG_WITH([rootprefix],
641         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
642         [], [with_rootprefix=${ac_default_prefix}])
643 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
644 # defaults those to ".", solve that here for now until we can find a suitable
645 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
646 # See: https://github.com/systemd/systemd/issues/54
647 if test "x${with_rootprefix}" = "x"; then
648         with_rootprefix="/"
649 fi
650 AX_NORMALIZE_PATH([with_rootprefix])
651
652 AC_ARG_WITH([rootlibdir],
653         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
654         [],
655         [with_rootlibdir=${libdir}])
656 AX_NORMALIZE_PATH([with_rootlibdir])
657
658 AC_ARG_WITH([pamlibdir],
659         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
660         [],
661         [with_pamlibdir=${with_rootlibdir}/security])
662 AX_NORMALIZE_PATH([with_pamlibdir])
663
664 AC_ARG_WITH([pamconfdir],
665         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
666         [],
667         [with_pamconfdir=${sysconfdir}/pam.d])
668 AX_NORMALIZE_PATH([with_pamconfdir])
669
670 AC_ARG_ENABLE([split-usr],
671         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
672         [],
673         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
674                 enable_split_usr=yes
675         ], [
676                 enable_split_usr=no
677         ])])
678
679 AS_IF([test "x${enable_split_usr}" = "xyes"], [
680         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
681 ])
682 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
683
684 # work around intltool-update issues during 'make distcheck'
685 AS_IF([test "x$0" != "x./configure"], [
686         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
687 ])
688
689 AC_ARG_ENABLE(tests,
690         [AC_HELP_STRING([--disable-tests], [disable tests])],
691         enable_tests=$enableval, enable_tests=yes)
692 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
693
694 AC_ARG_ENABLE(debug,
695         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (elogind,hashmap,mmap-cache)])],
696         [if test "x$enableval" = "xyes"; then
697                 enableval="elogind,hashmap,mmap-cache"
698         fi
699         saved_ifs="$IFS"
700         IFS="$IFS$PATH_SEPARATOR,"
701         for name in $enableval; do
702                 case $name in
703                 elogind)
704                         enable_debug_elogind=yes
705                         ;;
706                 hashmap)
707                         enable_debug_hashmap=yes
708                         ;;
709                 mmap-cache)
710                         enable_debug_mmap_cache=yes
711                         ;;
712                 esac
713         done
714         IFS="$saved_ifs"],[])
715
716 enable_debug=""
717 AS_IF([test x$enable_debug_elogind = xyes], [
718         AC_DEFINE(ENABLE_DEBUG_ELOGIND, 1, [Define if elogind debugging is to be enabled])
719         enable_debug="elogind $enable_debug"
720 ])
721 AS_IF([test x$enable_debug_hashmap = xyes], [
722         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
723         enable_debug="hashmap $enable_debug"
724 ])
725 AS_IF([test x$enable_debug_mmap_cache = xyes], [
726         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
727         enable_debug="mmap-cache $enable_debug"
728 ])
729 test -z "$enable_debug" && enable_debug="none"
730
731 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
732 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
733 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
734 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
735 AC_SUBST([pamlibdir], [$with_pamlibdir])
736 AC_SUBST([pamconfdir], [$with_pamconfdir])
737 AC_SUBST([rootprefix], [$with_rootprefix])
738 AC_SUBST([rootlibdir], [$with_rootlibdir])
739 AC_SUBST([cgroup_controller], [$with_cgroupctrl])
740
741 AC_CONFIG_FILES([
742         Makefile
743         po/Makefile.in
744 ])
745
746 AC_OUTPUT
747 AC_MSG_RESULT([
748         $PACKAGE_NAME $VERSION
749
750         PAM:                     ${have_pam}
751         SELinux:                 ${have_selinux}
752         SMACK:                   ${have_smack}
753         ACL:                     ${have_acl}
754         polkit:                  ${have_polkit}
755         kdbus:                   ${have_kdbus}
756         Python:                  ${have_python}
757         man pages:               ${have_manpages}
758         test coverage:           ${have_coverage}
759         Split /usr:              ${enable_split_usr}
760         Link time optimization:  ${have_lto}
761         extra debugging:         ${enable_debug}
762         cgroup controller:       ${with_cgroupctrl}
763
764         prefix:                  ${prefix}
765         rootprefix:              ${with_rootprefix}
766         sysconf dir:             ${sysconfdir}
767         datarootdir:             ${datarootdir}
768         includedir:              ${includedir}
769         lib dir:                 ${libdir}
770         rootlib dir:             ${with_rootlibdir}
771         PAM modules dir:         ${with_pamlibdir}
772         PAM configuration dir:   ${with_pamconfdir}
773         D-Bus policy dir:        ${with_dbuspolicydir}
774         D-Bus system dir:        ${with_dbussystemservicedir}
775         Bash completions dir:    ${with_bashcompletiondir}
776         Zsh completions dir:     ${with_zshcompletiondir}
777         Maximum System UID:      ${SYSTEM_UID_MAX}
778         Maximum System GID:      ${SYSTEM_GID_MAX}
779
780         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
781         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
782         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
783 ])