configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [204],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  71
  72 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  73
  74 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  75 m4_ifdef([GTK_DOC_CHECK], [
  76 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  77          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  78           enable_gtk_doc=no])
  79
  80 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  81         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  82 ])
  83
  84 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  85 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  86 ], [
  87    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  88    enable_introspection=no])
  89
  90 AC_CHECK_TOOL(OBJCOPY, objcopy)
  91 AC_CHECK_TOOL(STRINGS, strings)
  92 AC_CHECK_TOOL(GPERF, gperf)
  93 if test -z "$GPERF" ; then
  94         AC_MSG_ERROR([*** gperf not found])
  95 fi
  96
  97 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  98         -pipe \
  99         -Wall \
 100         -Wextra \
 101         -Wno-inline \
 102         -Wundef \
 103         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 104         -Wlogical-op \
 105         -Wsign-compare \
 106         -Wmissing-include-dirs \
 107         -Wold-style-definition \
 108         -Wpointer-arith \
 109         -Winit-self \
 110         -Wdeclaration-after-statement \
 111         -Wfloat-equal \
 112         -Wmissing-prototypes \
 113         -Wstrict-prototypes \
 114         -Wredundant-decls \
 115         -Wmissing-declarations \
 116         -Wmissing-noreturn \
 117         -Wshadow \
 118         -Wendif-labels \
 119         -Wcast-align \
 120         -Wstrict-aliasing=2 \
 121         -Wwrite-strings \
 122         -Wno-long-long \
 123         -Wno-overlength-strings \
 124         -Wno-unused-parameter \
 125         -Wno-missing-field-initializers \
 126         -Wno-unused-result \
 127         -Werror=overflow \
 128         -ffast-math \
 129         -fno-common \
 130         -fdiagnostics-show-option \
 131         -fno-strict-aliasing \
 132         -fvisibility=hidden \
 133         -ffunction-sections \
 134         -fdata-sections \
 135         -fstack-protector \
 136         --param=ssp-buffer-size=4])
 137 AC_SUBST([OUR_CFLAGS], $with_cflags)
 138
 139 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
 140         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 141                -Wp,-D_FORTIFY_SOURCE=2])], [
 142         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 143         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 144 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 145
 146 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 147         -Wl,--as-needed \
 148         -Wl,--no-undefined \
 149         -Wl,--gc-sections \
 150         -Wl,-z,relro \
 151         -Wl,-z,now])
 152 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 153
 154 # ------------------------------------------------------------------------------
 155 # we use python to build the man page index, and for systemd-python
 156 have_python=no
 157 have_python_devel=no
 158
 159 AC_ARG_WITH([python],
 160         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 161
 162 AS_IF([test "x$with_python" != "xno"], [
 163         AM_PATH_PYTHON(,, [:])
 164         AS_IF([test "$PYTHON" != :], [have_python=yes])
 165 ])
 166 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 167 AS_IF([test "x$PYTHON_BINARY" = "x"],
 168       [AS_IF([test "x$have_python" = "xyes"],
 169              [PYTHON_BINARY="$(which "$PYTHON")"],
 170              [PYTHON_BINARY=/usr/bin/python])])
 171 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 172
 173 AS_IF([test "x$with_python" != "xno"], [
 174         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 175         AS_IF([test -n "$PYTHON_CONFIG"], [
 176               have_python_devel=yes
 177               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
 178               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
 179               AC_SUBST(PYTHON_CFLAGS)
 180               AC_SUBST(PYTHON_LIBS)
 181               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 182         ])
 183 ])
 184 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 185
 186 # ------------------------------------------------------------------------------
 187
 188 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 189 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 190
 191 save_LIBS="$LIBS"
 192 LIBS=
 193 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 194 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 195 CAP_LIBS="$LIBS"
 196 LIBS="$save_LIBS"
 197 AC_SUBST(CAP_LIBS)
 198
 199 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 200 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 201 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 202 #include <unistd.h>
 203 #include <sys/mount.h>
 204 #include <fcntl.h>]])
 205
 206 # This makes sure pkg.m4 is available.
 207 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 208
 209 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 210
 211 # ------------------------------------------------------------------------------
 212 have_kmod=no
 213 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 214 if test "x$enable_kmod" != "xno"; then
 215         PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ],
 216                 [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available]) have_kmod=yes], have_kmod=no)
 217         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 218                 AC_MSG_ERROR([*** kmod support requested but libraries not found])
 219         fi
 220 fi
 221 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 222
 223 # ------------------------------------------------------------------------------
 224 have_blkid=no
 225 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 226 if test "x$enable_blkid" != "xno"; then
 227         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 228                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 229         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 230                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 231         fi
 232 fi
 233 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 234
 235 # ------------------------------------------------------------------------------
 236 have_ima=yes
 237 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 238                 [case "${enableval}" in
 239                         yes) have_ima=yes ;;
 240                         no) have_ima=no ;;
 241                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 242                 esac],
 243                 [have_ima=yes])
 244
 245 if test "x${have_ima}" != xno ; then
 246         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 247 fi
 248
 249 # ------------------------------------------------------------------------------
 250 have_chkconfig=yes
 251 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 252                 [case "${enableval}" in
 253                         yes) have_chkconfig=yes ;;
 254                         no) have_chkconfig=no ;;
 255                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 256                 esac],
 257                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 258                 if test -z "$CHKCONFIG"; then
 259                         have_chkconfig=no
 260                 else
 261                         have_chkconfig=yes
 262                 fi])
 263
 264 if test "x${have_chkconfig}" != xno ; then
 265         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 266 fi
 267
 268 # ------------------------------------------------------------------------------
 269 have_selinux=no
 270 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 271 if test "x$enable_selinux" != "xno"; then
 272         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 273                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 274         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 275                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 276         fi
 277 fi
 278 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 279
 280 AC_ARG_WITH(debug-shell,
 281         AS_HELP_STRING([--with-debug-shell=PATH],
 282                 [Path to debug shell binary]),
 283         [SUSHELL="$withval"],[
 284         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 285
 286 AC_SUBST(SUSHELL)
 287
 288 AC_ARG_WITH([debug-tty],
 289         AS_HELP_STRING([--with-debug-tty=PATH],
 290                 [Specify the tty device for debug shell]),
 291         [DEBUGTTY="$withval"],
 292         [DEBUGTTY=/dev/tty9])
 293
 294 AC_SUBST(DEBUGTTY)
 295
 296 # ------------------------------------------------------------------------------
 297 have_xz=no
 298 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 299 if test "x$enable_xz" != "xno"; then
 300         PKG_CHECK_MODULES(XZ, [ liblzma ],
 301                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 302         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 303                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 304         fi
 305 fi
 306 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 307
 308 # ------------------------------------------------------------------------------
 309 AC_ARG_ENABLE([tcpwrap],
 310         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 311                 [case "${enableval}" in
 312                         yes) have_tcpwrap=yes ;;
 313                         no) have_tcpwrap=no ;;
 314                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 315                 esac],
 316                 [have_tcpwrap=auto])
 317
 318 if test "x${have_tcpwrap}" != xno ; then
 319         ACX_LIBWRAP
 320         if test "x${LIBWRAP_LIBS}" = x ; then
 321                 if test "x$have_tcpwrap" = xyes ; then
 322                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 323                 fi
 324                 have_tcpwrap=no
 325         else
 326                 have_tcpwrap=yes
 327         fi
 328 else
 329         LIBWRAP_LIBS=
 330 fi
 331 AC_SUBST(LIBWRAP_LIBS)
 332
 333 # ------------------------------------------------------------------------------
 334 AC_ARG_ENABLE([pam],
 335         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 336                 [case "${enableval}" in
 337                         yes) have_pam=yes ;;
 338                         no) have_pam=no ;;
 339                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 340                 esac],
 341                 [have_pam=auto])
 342
 343 if test "x${have_pam}" != xno ; then
 344         AC_CHECK_HEADERS(
 345                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 346                 [have_pam=yes],
 347                 [if test "x$have_pam" = xyes ; then
 348                         AC_MSG_ERROR([*** PAM headers not found.])
 349                 fi])
 350
 351         AC_CHECK_LIB(
 352                 [pam],
 353                 [pam_syslog],
 354                 [have_pam=yes],
 355                 [if test "x$have_pam" = xyes ; then
 356                         AC_MSG_ERROR([*** libpam not found.])
 357                 fi])
 358
 359         if test "x$have_pam" = xyes ; then
 360                 PAM_LIBS="-lpam -lpam_misc"
 361                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 362         else
 363                 have_pam=no
 364         fi
 365 else
 366         PAM_LIBS=
 367 fi
 368 AC_SUBST(PAM_LIBS)
 369 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 370
 371 # ------------------------------------------------------------------------------
 372 AC_ARG_ENABLE([acl],
 373         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 374                 [case "${enableval}" in
 375                         yes) have_acl=yes ;;
 376                         no) have_acl=no ;;
 377                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 378                 esac],
 379                 [have_acl=auto])
 380
 381 if test "x${have_acl}" != xno ; then
 382         AC_CHECK_HEADERS(
 383                 [sys/acl.h acl/libacl.h],
 384                 [have_acl=yes],
 385                 [if test "x$have_acl" = xyes ; then
 386                         AC_MSG_ERROR([*** ACL headers not found.])
 387                 fi])
 388
 389         AC_CHECK_LIB(
 390                 [acl],
 391                 [acl_get_file],
 392                 [have_acl=yes],
 393                 [if test "x$have_acl" = xyes ; then
 394                         AC_MSG_ERROR([*** libacl not found.])
 395                 fi])
 396
 397         if test "x$have_acl" = xyes ; then
 398                 ACL_LIBS="-lacl"
 399                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 400         else
 401                 have_acl=no
 402         fi
 403 else
 404         ACL_LIBS=
 405 fi
 406 AC_SUBST(ACL_LIBS)
 407 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 408
 409 # ------------------------------------------------------------------------------
 410 AC_ARG_ENABLE([xattr],
 411         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 412                 [case "${enableval}" in
 413                         yes) have_xattr=yes ;;
 414                         no) have_xattr=no ;;
 415                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 416                 esac],
 417                 [have_xattr=auto])
 418
 419 if test "x${have_xattr}" != xno ; then
 420         AC_CHECK_HEADERS(
 421                 [attr/xattr.h],
 422                 [have_xattr=yes],
 423                 [if test "x$have_xattr" = xyes ; then
 424                         AC_MSG_ERROR([*** XATTR headers not found.])
 425                 fi])
 426
 427         AC_CHECK_LIB(
 428                 [attr],
 429                 [fsetxattr],
 430                 [have_xattr=yes],
 431                 [if test "x$have_xattr" = xyes ; then
 432                         AC_MSG_ERROR([*** libattr not found.])
 433                 fi])
 434
 435         if test "x$have_xattr" = xyes ; then
 436                 XATTR_LIBS="-lattr"
 437                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 438         else
 439                 have_xattr=no
 440         fi
 441 else
 442         XATTR_LIBS=
 443 fi
 444 AC_SUBST(XATTR_LIBS)
 445 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 446
 447 # ------------------------------------------------------------------------------
 448 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 449                 [case "${enableval}" in
 450                         yes) have_smack=yes ;;
 451                         no) have_smack=no ;;
 452                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 453                 esac],
 454                 [have_smack=auto])
 455
 456 if test "x${have_xattr}" = xno; then
 457         if test "x${have_smack}" = xyes; then
 458                 AC_MSG_ERROR(SMACK requires xattr support)
 459         else
 460                 have_smack=no
 461         fi
 462 else
 463         if test "x${have_smack}" = xauto; then
 464                 have_smack=yes
 465         fi
 466 fi
 467
 468 if test "x${have_smack}" = xyes ; then
 469         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 470 fi
 471
 472 # ------------------------------------------------------------------------------
 473 AC_ARG_ENABLE([gcrypt],
 474         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 475                 [case "${enableval}" in
 476                         yes) have_gcrypt=yes ;;
 477                         no) have_gcrypt=no ;;
 478                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 479                 esac],
 480                 [have_gcrypt=auto])
 481
 482 if test "x${have_gcrypt}" != xno ; then
 483         AM_PATH_LIBGCRYPT(
 484                 [1.4.5],
 485                 [have_gcrypt=yes],
 486                 [if test "x$have_gcrypt" = xyes ; then
 487                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 488                 fi])
 489
 490         if test "x$have_gcrypt" = xyes ; then
 491                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 492                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 493                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 494         else
 495                 have_gcrypt=no
 496         fi
 497 else
 498         GCRYPT_LIBS=
 499         GCRYPT_CFLAGS=
 500 fi
 501 AC_SUBST(GCRYPT_LIBS)
 502 AC_SUBST(GCRYPT_CFLAGS)
 503 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 504
 505 # ------------------------------------------------------------------------------
 506 AC_ARG_ENABLE([audit],
 507         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 508                 [case "${enableval}" in
 509                         yes) have_audit=yes ;;
 510                         no) have_audit=no ;;
 511                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 512                 esac],
 513                 [have_audit=auto])
 514
 515 if test "x${have_audit}" != xno ; then
 516         AC_CHECK_HEADERS(
 517                 [libaudit.h],
 518                 [have_audit=yes],
 519                 [if test "x$have_audit" = xyes ; then
 520                         AC_MSG_ERROR([*** AUDIT headers not found.])
 521                 fi])
 522
 523         AC_CHECK_LIB(
 524                 [audit],
 525                 [audit_open],
 526                 [have_audit=yes],
 527                 [if test "x$have_audit" = xyes ; then
 528                         AC_MSG_ERROR([*** libaudit not found.])
 529                 fi])
 530
 531         if test "x$have_audit" = xyes ; then
 532                 AUDIT_LIBS="-laudit"
 533                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 534         else
 535                 have_audit=no
 536         fi
 537 else
 538         AUDIT_LIBS=
 539 fi
 540 AC_SUBST(AUDIT_LIBS)
 541
 542 # ------------------------------------------------------------------------------
 543 have_libcryptsetup=no
 544 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 545 if test "x$enable_libcryptsetup" != "xno"; then
 546         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 547                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 548         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 549                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 550         fi
 551 fi
 552 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 553
 554 # ------------------------------------------------------------------------------
 555 have_qrencode=no
 556 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 557 if test "x$enable_qrencode" != "xno"; then
 558         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 559                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 560         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 561                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 562         fi
 563 fi
 564 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 565
 566 # ------------------------------------------------------------------------------
 567 have_microhttpd=no
 568 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 569 if test "x$enable_microhttpd" != "xno"; then
 570         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 571                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 572         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 573                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 574         fi
 575 fi
 576 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 577
 578 # ------------------------------------------------------------------------------
 579 have_binfmt=no
 580 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 581 if test "x$enable_binfmt" != "xno"; then
 582         have_binfmt=yes
 583 fi
 584 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 585
 586 # ------------------------------------------------------------------------------
 587 have_vconsole=no
 588 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 589 if test "x$enable_vconsole" != "xno"; then
 590         have_vconsole=yes
 591 fi
 592 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 593
 594 # ------------------------------------------------------------------------------
 595 have_readahead=no
 596 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 597 if test "x$enable_readahead" != "xno"; then
 598         have_readahead=yes
 599 fi
 600 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 601
 602 # ------------------------------------------------------------------------------
 603 have_bootchart=no
 604 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 605 if test "x$enable_bootchart" != "xno"; then
 606         have_bootchart=yes
 607 fi
 608 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 609
 610 # ------------------------------------------------------------------------------
 611 have_quotacheck=no
 612 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 613 if test "x$enable_quotacheck" != "xno"; then
 614         have_quotacheck=yes
 615 fi
 616 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 617
 618 # ------------------------------------------------------------------------------
 619 have_randomseed=no
 620 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 621 if test "x$enable_randomseed" != "xno"; then
 622         have_randomseed=yes
 623 fi
 624 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 625
 626 # ------------------------------------------------------------------------------
 627 have_logind=no
 628 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 629 if test "x$enable_logind" != "xno"; then
 630         have_logind=yes
 631 fi
 632 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 633 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 634
 635 # ------------------------------------------------------------------------------
 636 have_hostnamed=no
 637 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 638 if test "x$enable_hostnamed" != "xno"; then
 639         have_hostnamed=yes
 640 fi
 641 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 642
 643 # ------------------------------------------------------------------------------
 644 have_timedated=no
 645 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 646 if test "x$enable_timedated" != "xno"; then
 647         have_timedated=yes
 648 fi
 649 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 650
 651 # ------------------------------------------------------------------------------
 652 have_localed=no
 653 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 654 if test "x$enable_localed" != "xno"; then
 655         have_localed=yes
 656 fi
 657 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 658
 659 # ------------------------------------------------------------------------------
 660 have_coredump=no
 661 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 662 if test "x$enable_coredump" != "xno"; then
 663         have_coredump=yes
 664 fi
 665 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 666
 667 # ------------------------------------------------------------------------------
 668 have_polkit=no
 669 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 670 if test "x$enable_polkit" != "xno"; then
 671         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 672         have_polkit=yes
 673 fi
 674 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 675
 676 # ------------------------------------------------------------------------------
 677 have_efi=no
 678 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 679 if test "x$enable_efi" != "xno"; then
 680         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 681         have_efi=yes
 682 fi
 683 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 684
 685 # ------------------------------------------------------------------------------
 686 AC_ARG_WITH(rc-local-script-path-start,
 687         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 688                 [Path to /etc/rc.local]),
 689         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 690         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 691
 692 AC_ARG_WITH(rc-local-script-path-stop,
 693         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 694                 [Path to /usr/sbin/halt.local]),
 695         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 696         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 697
 698 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 699 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 700
 701 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 702 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 703
 704 # ------------------------------------------------------------------------------
 705 AC_ARG_WITH(kbd-loadkeys,
 706         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 707                 [Path to loadkeys]),
 708         [KBD_LOADKEYS="$withval"],
 709         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 710
 711 AC_ARG_WITH(kbd-setfont,
 712         AS_HELP_STRING([--with-kbd-setfont=PATH],
 713                 [Path to setfont]),
 714         [KBD_SETFONT="$withval"],
 715         [KBD_SETFONT="/usr/bin/setfont"])
 716
 717 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 718 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 719
 720 AC_SUBST(KBD_LOADKEYS)
 721 AC_SUBST(KBD_SETFONT)
 722
 723 AC_ARG_WITH(telinit,
 724         AS_HELP_STRING([--with-telinit=PATH],
 725                 [Path to telinit]),
 726         [TELINIT="$withval"],
 727         [TELINIT="/lib/upstart/telinit"])
 728
 729 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 730
 731 AC_SUBST(TELINIT)
 732
 733 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 734
 735 # ------------------------------------------------------------------------------
 736 have_myhostname=no
 737 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 738 if test "x$enable_myhostname" != "xno"; then
 739         AC_HEADER_STDC
 740         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 741
 742         AC_C_CONST
 743         AC_TYPE_SIZE_T
 744         AC_HEADER_TIME
 745
 746         AC_FUNC_MALLOC
 747         AC_FUNC_SELECT_ARGTYPES
 748         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 749
 750         have_myhostname=yes
 751 fi
 752 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 753
 754 # ------------------------------------------------------------------------------
 755 AC_ARG_WITH(firmware-path,
 756        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 757           [Firmware search path (default="")]),
 758        [], [with_firmware_path=""])
 759 OLD_IFS=$IFS
 760 IFS=:
 761 for i in $with_firmware_path; do
 762        if test "x${FIRMWARE_PATH}" = "x"; then
 763               FIRMWARE_PATH="\\\"${i}/\\\""
 764        else
 765               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 766        fi
 767 done
 768 IFS=$OLD_IFS
 769 AC_SUBST(FIRMWARE_PATH)
 770 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 771 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 772
 773 # ------------------------------------------------------------------------------
 774 AC_ARG_ENABLE([gudev],
 775        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 776        [], [enable_gudev=yes])
 777 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 778 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 779 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 780
 781 # ------------------------------------------------------------------------------
 782 AC_ARG_ENABLE([keymap],
 783        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 784        [], [enable_keymap=yes])
 785 AS_IF([test "x$enable_keymap" = "xyes"], [
 786        AC_PATH_PROG([GPERF], [gperf])
 787        if test -z "$GPERF"; then
 788               AC_MSG_ERROR([gperf is needed])
 789        fi
 790
 791        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 792        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 793 ])
 794 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 795
 796 # ------------------------------------------------------------------------------
 797 have_manpages=no
 798 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 799 AS_IF([test "x$enable_manpages" != xno], [
 800         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 801                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 802         ])
 803         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 804 ])
 805 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 806
 807 # ------------------------------------------------------------------------------
 808
 809 # Location of the init scripts as mandated by LSB
 810 SYSTEM_SYSVINIT_PATH=/etc/init.d
 811 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 812 M4_DEFINES=
 813
 814 AC_ARG_WITH([sysvinit-path],
 815         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 816                 [Specify the path to where the SysV init scripts are located])],
 817         [SYSTEM_SYSVINIT_PATH="$withval"],
 818         [])
 819
 820 AC_ARG_WITH([sysvrcnd-path],
 821         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 822                 [Specify the path to the base directory for the SysV rcN.d directories])],
 823         [SYSTEM_SYSVRCND_PATH="$withval"],
 824         [])
 825
 826 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 827         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 828         SYSTEM_SYSV_COMPAT="yes"
 829         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 830 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 831         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 832 else
 833         SYSTEM_SYSV_COMPAT="no"
 834 fi
 835
 836 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 837 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 838 AC_SUBST(M4_DEFINES)
 839
 840 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 841
 842 AC_ARG_WITH([tty-gid],
 843         [AS_HELP_STRING([--with-tty-gid=GID],
 844                 [Specify the numeric GID of the 'tty' group])],
 845         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 846         [])
 847
 848 AC_ARG_WITH([dbuspolicydir],
 849         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 850         [],
 851         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 852
 853 AC_ARG_WITH([dbussessionservicedir],
 854         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 855         [],
 856         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 857
 858 AC_ARG_WITH([dbussystemservicedir],
 859         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 860         [],
 861         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 862
 863 AC_ARG_WITH([dbusinterfacedir],
 864         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 865         [],
 866         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 867
 868 AC_ARG_WITH([bashcompletiondir],
 869         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 870         [],
 871         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 872                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 873         ] , [
 874                 with_bashcompletiondir=${datadir}/bash-completion/completions
 875         ])])
 876
 877 AC_ARG_WITH([rootprefix],
 878         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 879         [], [with_rootprefix=${ac_default_prefix}])
 880
 881 AC_ARG_WITH([rootlibdir],
 882         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 883         [],
 884         [with_rootlibdir=${libdir}])
 885
 886 AC_ARG_WITH([pamlibdir],
 887         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 888         [],
 889         [with_pamlibdir=${with_rootlibdir}/security])
 890
 891 AC_ARG_ENABLE([split-usr],
 892         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 893         [],
 894         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 895                 enable_split_usr=yes
 896         ], [
 897                 enable_split_usr=no
 898         ])])
 899
 900 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 901         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 902 ])
 903
 904 # Work around intltoolize and gtk-doc problems in VPATH builds
 905 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 906                                        [Define to do gtk-doc tests])
 907 AS_IF([test "x$0" != "x./configure"], [
 908         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 909 ])
 910
 911 AC_ARG_ENABLE(tests,
 912        [AC_HELP_STRING([--disable-tests], [disable tests])],
 913        enable_tests=$enableval, enable_tests=yes)
 914 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 915
 916 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 917 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 918 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 919 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 920 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 921 AC_SUBST([pamlibdir], [$with_pamlibdir])
 922 AC_SUBST([rootprefix], [$with_rootprefix])
 923 AC_SUBST([rootlibdir], [$with_rootlibdir])
 924
 925 AC_CONFIG_FILES([
 926         Makefile po/Makefile.in
 927         docs/libudev/Makefile
 928         docs/libudev/version.xml
 929         docs/gudev/Makefile
 930         docs/gudev/version.xml
 931 ])
 932
 933 AC_OUTPUT
 934 AC_MSG_RESULT([
 935         $PACKAGE_NAME $VERSION
 936
 937         libcryptsetup:           ${have_libcryptsetup}
 938         tcpwrap:                 ${have_tcpwrap}
 939         PAM:                     ${have_pam}
 940         AUDIT:                   ${have_audit}
 941         IMA:                     ${have_ima}
 942         SELinux:                 ${have_selinux}
 943         SMACK:                   ${have_smack}
 944         XZ:                      ${have_xz}
 945         ACL:                     ${have_acl}
 946         XATTR:                   ${have_xattr}
 947         GCRYPT:                  ${have_gcrypt}
 948         QRENCODE:                ${have_qrencode}
 949         MICROHTTPD:              ${have_microhttpd}
 950         CHKCONFIG:               ${have_chkconfig}
 951         binfmt:                  ${have_binfmt}
 952         vconsole:                ${have_vconsole}
 953         readahead:               ${have_readahead}
 954         bootchart:               ${have_bootchart}
 955         quotacheck:              ${have_quotacheck}
 956         randomseed:              ${have_randomseed}
 957         logind:                  ${have_logind}
 958         hostnamed:               ${have_hostnamed}
 959         timedated:               ${have_timedated}
 960         localed:                 ${have_localed}
 961         coredump:                ${have_coredump}
 962         polkit:                  ${have_polkit}
 963         efi:                     ${have_efi}
 964         kmod:                    ${have_kmod}
 965         blkid:                   ${have_blkid}
 966         nss-myhostname:          ${have_myhostname}
 967         gudev:                   ${enable_gudev}
 968         gintrospection:          ${enable_introspection}
 969         keymap:                  ${enable_keymap}
 970         Python:                  ${have_python}
 971         Python Headers:          ${have_python_devel}
 972         man pages:               ${have_manpages}
 973         gtk-doc:                 ${enable_gtk_doc}
 974         Split /usr:              ${enable_split_usr}
 975         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 976
 977         prefix:                  ${prefix}
 978         rootprefix:              ${with_rootprefix}
 979         sysconf dir:             ${sysconfdir}
 980         datarootdir:             ${datarootdir}
 981         includedir:              ${includedir}
 982         include_prefix:          ${INCLUDE_PREFIX}
 983         lib dir:                 ${libdir}
 984         rootlib dir:             ${with_rootlibdir}
 985         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 986         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 987         Build Python:            ${PYTHON}
 988         Installation Python:     ${PYTHON_BINARY}
 989         firmware path:           ${FIRMWARE_PATH}
 990         PAM modules dir:         ${with_pamlibdir}
 991         D-Bus policy dir:        ${with_dbuspolicydir}
 992         D-Bus session dir:       ${with_dbussessionservicedir}
 993         D-Bus system dir:        ${with_dbussystemservicedir}
 994         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 995         Bash completions dir:    ${with_bashcompletiondir}
 996         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
 997         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
 998         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
 999
1000         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1001         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1002         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1003         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
1004         PYTHON_LIBS:             ${PYTHON_LIBS}
1005 ])