configure.ac

   1
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [194],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/sbin/setcap])
  71
  72 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  73 m4_ifdef([GTK_DOC_CHECK], [
  74 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  75 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  76
  77 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  78         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  79 ])
  80
  81 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  82 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  83 ], [AM_CONDITIONAL([HAVE_INTROSPECTION], [false])])
  84
  85 AC_PATH_TOOL(OBJCOPY, objcopy)
  86 AC_PATH_TOOL(STRINGS, strings)
  87 AC_PATH_TOOL(GPERF, gperf)
  88 if test -z "$GPERF" ; then
  89         AC_MSG_ERROR([*** gperf not found])
  90 fi
  91
  92 # we use python to build the man page index, and for systemd-python
  93 have_python=no
  94 have_python_devel=no
  95 AM_PATH_PYTHON(,, [:])
  96 if test "$PYTHON" != : ; then
  97         have_python=yes
  98         AC_PATH_PROG([PYTHON_CONFIG], python-config)
  99
 100         if test -n "$PYTHON_CONFIG" ; then
 101                 have_python_devel=yes
 102                 PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags`"
 103                 PYTHON_LIBS="`$PYTHON_CONFIG --libs`"
 104                 AC_SUBST(PYTHON_CFLAGS)
 105                 AC_SUBST(PYTHON_LIBS)
 106         fi
 107 fi
 108 AM_CONDITIONAL([HAVE_PYTHON], [test "$have_python" = "yes"])
 109 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 110
 111 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 112         -pipe \
 113         -Wall \
 114         -Wextra \
 115         -Wno-inline \
 116         -Wundef \
 117         -Wformat=2 \
 118         -Wlogical-op \
 119         -Wsign-compare \
 120         -Wformat-security \
 121         -Wmissing-include-dirs \
 122         -Wformat-nonliteral \
 123         -Wold-style-definition \
 124         -Wpointer-arith \
 125         -Winit-self \
 126         -Wdeclaration-after-statement \
 127         -Wfloat-equal \
 128         -Wmissing-prototypes \
 129         -Wstrict-prototypes \
 130         -Wredundant-decls \
 131         -Wmissing-declarations \
 132         -Wmissing-noreturn \
 133         -Wshadow \
 134         -Wendif-labels \
 135         -Wcast-align \
 136         -Wstrict-aliasing=2 \
 137         -Wwrite-strings \
 138         -Wno-long-long \
 139         -Wno-overlength-strings \
 140         -Wno-unused-parameter \
 141         -Wno-missing-field-initializers \
 142         -Wno-unused-result \
 143         -Werror=overflow \
 144         -ffast-math \
 145         -fno-common \
 146         -fdiagnostics-show-option \
 147         -fno-strict-aliasing \
 148         -fvisibility=hidden \
 149         -ffunction-sections \
 150         -fdata-sections \
 151         -fstack-protector \
 152         --param=ssp-buffer-size=4])
 153 AC_SUBST([OUR_CFLAGS], $with_cflags)
 154
 155 CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 156         -Wp,-D_FORTIFY_SOURCE=2])
 157 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 158
 159 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 160         -Wl,--as-needed \
 161         -Wl,--gc-sections \
 162         -Wl,-z,relro \
 163         -Wl,-z,now])
 164 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 165
 166 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 167 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 168
 169 save_LIBS="$LIBS"
 170 LIBS=
 171 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 172 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 173 CAP_LIBS="$LIBS"
 174 LIBS="$save_LIBS"
 175 AC_SUBST(CAP_LIBS)
 176
 177 AC_CHECK_FUNCS([fanotify_init fanotify_mark name_to_handle_at])
 178 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 179 AC_CHECK_DECLS([gettid, pivot_root], [], [], [[#include <sys/types.h>
 180 #include <unistd.h>
 181 #include <sys/mount.h>]])
 182
 183 # This makes sure pkg.m4 is available.
 184 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 185
 186 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 187 PKG_CHECK_MODULES(KMOD, [libkmod >= 5])
 188 PKG_CHECK_MODULES(BLKID,[blkid >= 2.20])
 189
 190 # ------------------------------------------------------------------------------
 191 have_ima=yes
 192 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 193                 [case "${enableval}" in
 194                         yes) have_ima=yes ;;
 195                         no) have_ima=no ;;
 196                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 197                 esac],
 198                 [have_ima=yes])
 199
 200 if test "x${have_ima}" != xno ; then
 201         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 202 fi
 203
 204 # ------------------------------------------------------------------------------
 205 have_selinux=no
 206 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 207 if test "x$enable_selinux" != "xno"; then
 208         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 209                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 210         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 211                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 212         fi
 213 fi
 214 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 215 if test "x${have_selinux}" != xno ; then
 216         sushell=/sbin/sushell
 217 else
 218         sushell=/bin/bash
 219 fi
 220 AC_SUBST(sushell)
 221
 222 # ------------------------------------------------------------------------------
 223 have_xz=no
 224 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 225 if test "x$enable_xz" != "xno"; then
 226         PKG_CHECK_MODULES(XZ, [ liblzma ],
 227                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 228         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 229                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 230         fi
 231 fi
 232 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 233
 234 # ------------------------------------------------------------------------------
 235 AC_ARG_ENABLE([tcpwrap],
 236         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 237                 [case "${enableval}" in
 238                         yes) have_tcpwrap=yes ;;
 239                         no) have_tcpwrap=no ;;
 240                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 241                 esac],
 242                 [have_tcpwrap=auto])
 243
 244 if test "x${have_tcpwrap}" != xno ; then
 245         ACX_LIBWRAP
 246         if test "x${LIBWRAP_LIBS}" = x ; then
 247                 if test "x$have_tcpwrap" = xyes ; then
 248                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 249                 fi
 250                 have_tcpwrap=no
 251         else
 252                 have_tcpwrap=yes
 253         fi
 254 else
 255         LIBWRAP_LIBS=
 256 fi
 257 AC_SUBST(LIBWRAP_LIBS)
 258
 259 # ------------------------------------------------------------------------------
 260 AC_ARG_ENABLE([pam],
 261         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 262                 [case "${enableval}" in
 263                         yes) have_pam=yes ;;
 264                         no) have_pam=no ;;
 265                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 266                 esac],
 267                 [have_pam=auto])
 268
 269 if test "x${have_pam}" != xno ; then
 270         AC_CHECK_HEADERS(
 271                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 272                 [have_pam=yes],
 273                 [if test "x$have_pam" = xyes ; then
 274                         AC_MSG_ERROR([*** PAM headers not found.])
 275                 fi])
 276
 277         AC_CHECK_LIB(
 278                 [pam],
 279                 [pam_syslog],
 280                 [have_pam=yes],
 281                 [if test "x$have_pam" = xyes ; then
 282                         AC_MSG_ERROR([*** libpam not found.])
 283                 fi])
 284
 285         if test "x$have_pam" = xyes ; then
 286                 PAM_LIBS="-lpam -lpam_misc"
 287                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 288         else
 289                 have_pam=no
 290         fi
 291 else
 292         PAM_LIBS=
 293 fi
 294 AC_SUBST(PAM_LIBS)
 295 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 296
 297 # ------------------------------------------------------------------------------
 298 AC_ARG_ENABLE([acl],
 299         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 300                 [case "${enableval}" in
 301                         yes) have_acl=yes ;;
 302                         no) have_acl=no ;;
 303                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 304                 esac],
 305                 [have_acl=auto])
 306
 307 if test "x${have_acl}" != xno ; then
 308         AC_CHECK_HEADERS(
 309                 [sys/acl.h acl/libacl.h],
 310                 [have_acl=yes],
 311                 [if test "x$have_acl" = xyes ; then
 312                         AC_MSG_ERROR([*** ACL headers not found.])
 313                 fi])
 314
 315         AC_CHECK_LIB(
 316                 [acl],
 317                 [acl_get_file],
 318                 [have_acl=yes],
 319                 [if test "x$have_acl" = xyes ; then
 320                         AC_MSG_ERROR([*** libacl not found.])
 321                 fi])
 322
 323         if test "x$have_acl" = xyes ; then
 324                 ACL_LIBS="-lacl"
 325                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 326         else
 327                 have_acl=no
 328         fi
 329 else
 330         ACL_LIBS=
 331 fi
 332 AC_SUBST(ACL_LIBS)
 333 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 334
 335 # ------------------------------------------------------------------------------
 336 AC_ARG_ENABLE([gcrypt],
 337         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 338                 [case "${enableval}" in
 339                         yes) have_gcrypt=yes ;;
 340                         no) have_gcrypt=no ;;
 341                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 342                 esac],
 343                 [have_gcrypt=auto])
 344
 345 if test "x${have_gcrypt}" != xno ; then
 346         AM_PATH_LIBGCRYPT(
 347                 [1.4.5],
 348                 [have_gcrypt=yes],
 349                 [if test "x$have_gcrypt" = xyes ; then
 350                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 351                 fi])
 352
 353         if test "x$have_gcrypt" = xyes ; then
 354                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 355                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 356                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 357         else
 358                 have_gcrypt=no
 359         fi
 360 else
 361         GCRYPT_LIBS=
 362         GCRYPT_CFLAGS=
 363 fi
 364 AC_SUBST(GCRYPT_LIBS)
 365 AC_SUBST(GCRYPT_CFLAGS)
 366 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 367
 368 # ------------------------------------------------------------------------------
 369 AC_ARG_ENABLE([audit],
 370         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 371                 [case "${enableval}" in
 372                         yes) have_audit=yes ;;
 373                         no) have_audit=no ;;
 374                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 375                 esac],
 376                 [have_audit=auto])
 377
 378 if test "x${have_audit}" != xno ; then
 379         AC_CHECK_HEADERS(
 380                 [libaudit.h],
 381                 [have_audit=yes],
 382                 [if test "x$have_audit" = xyes ; then
 383                         AC_MSG_ERROR([*** AUDIT headers not found.])
 384                 fi])
 385
 386         AC_CHECK_LIB(
 387                 [audit],
 388                 [audit_open],
 389                 [have_audit=yes],
 390                 [if test "x$have_audit" = xyes ; then
 391                         AC_MSG_ERROR([*** libaudit not found.])
 392                 fi])
 393
 394         if test "x$have_audit" = xyes ; then
 395                 AUDIT_LIBS="-laudit"
 396                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 397         else
 398                 have_audit=no
 399         fi
 400 else
 401         AUDIT_LIBS=
 402 fi
 403 AC_SUBST(AUDIT_LIBS)
 404
 405 # ------------------------------------------------------------------------------
 406 have_libcryptsetup=no
 407 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 408 if test "x$enable_libcryptsetup" != "xno"; then
 409         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 410                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 411         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 412                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 413         fi
 414 fi
 415 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 416
 417 # ------------------------------------------------------------------------------
 418 have_qrencode=no
 419 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 420 if test "x$enable_qrencode" != "xno"; then
 421         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 422                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 423         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 424                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 425         fi
 426 fi
 427 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 428
 429 # ------------------------------------------------------------------------------
 430 have_microhttpd=no
 431 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 432 if test "x$enable_microhttpd" != "xno"; then
 433         PKG_CHECK_MODULES(MICROHTTPD, [ libmicrohttpd ],
 434                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 435         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 436                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 437         fi
 438 fi
 439 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 440
 441 # ------------------------------------------------------------------------------
 442 have_binfmt=no
 443 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 444 if test "x$enable_binfmt" != "xno"; then
 445         have_binfmt=yes
 446 fi
 447 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 448
 449 # ------------------------------------------------------------------------------
 450 have_vconsole=no
 451 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 452 if test "x$enable_vconsole" != "xno"; then
 453         have_vconsole=yes
 454 fi
 455 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 456
 457 # ------------------------------------------------------------------------------
 458 have_readahead=no
 459 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 460 if test "x$enable_readahead" != "xno"; then
 461         have_readahead=yes
 462 fi
 463 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 464
 465 # ------------------------------------------------------------------------------
 466 have_quotacheck=no
 467 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 468 if test "x$enable_quotacheck" != "xno"; then
 469         have_quotacheck=yes
 470 fi
 471 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 472
 473 # ------------------------------------------------------------------------------
 474 have_randomseed=no
 475 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 476 if test "x$enable_randomseed" != "xno"; then
 477         have_randomseed=yes
 478 fi
 479 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 480
 481 # ------------------------------------------------------------------------------
 482 have_logind=no
 483 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 484 if test "x$enable_logind" != "xno"; then
 485         have_logind=yes
 486 fi
 487 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 488 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 489
 490 # ------------------------------------------------------------------------------
 491 have_hostnamed=no
 492 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 493 if test "x$enable_hostnamed" != "xno"; then
 494         have_hostnamed=yes
 495 fi
 496 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 497
 498 # ------------------------------------------------------------------------------
 499 have_timedated=no
 500 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 501 if test "x$enable_timedated" != "xno"; then
 502         have_timedated=yes
 503 fi
 504 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 505
 506 # ------------------------------------------------------------------------------
 507 have_localed=no
 508 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 509 if test "x$enable_localed" != "xno"; then
 510         have_localed=yes
 511 fi
 512 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 513
 514 # ------------------------------------------------------------------------------
 515 have_coredump=no
 516 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 517 if test "x$enable_coredump" != "xno"; then
 518         have_coredump=yes
 519 fi
 520 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 521
 522 # ------------------------------------------------------------------------------
 523 AC_ARG_WITH(usb-ids-path,
 524         [AS_HELP_STRING([--with-usb-ids-path=DIR], [Path to usb.ids file])],
 525         [USB_DATABASE=${withval}],
 526         [if test -n "$usbids" ; then
 527                 USB_DATABASE="$usbids"
 528         else
 529                 PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
 530                 AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
 531         fi])
 532 AC_MSG_CHECKING([for USB database location])
 533 AC_MSG_RESULT([$USB_DATABASE])
 534 AC_SUBST(USB_DATABASE)
 535
 536 AC_ARG_WITH(pci-ids-path,
 537         [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 538         [PCI_DATABASE=${withval}],
 539         [if test -n "$pciids" ; then
 540                 PCI_DATABASE="$pciids"
 541         else
 542                 PKG_CHECK_MODULES(LIBPCI, libpci >= 3)
 543                 AC_SUBST([PCI_DATABASE], [$($PKG_CONFIG --variable=idsdir libpci)/pci.ids])
 544         fi])
 545 AC_MSG_CHECKING([for PCI database location])
 546 AC_MSG_RESULT([$PCI_DATABASE])
 547 AC_SUBST(PCI_DATABASE)
 548
 549 # ------------------------------------------------------------------------------
 550 AC_ARG_WITH(firmware-path,
 551        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 552           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 553        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 554 OLD_IFS=$IFS
 555 IFS=:
 556 for i in $with_firmware_path; do
 557        if test "x${FIRMWARE_PATH}" = "x"; then
 558               FIRMWARE_PATH="\\\"${i}/\\\""
 559        else
 560               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 561        fi
 562 done
 563 IFS=$OLD_IFS
 564 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 565
 566 # ------------------------------------------------------------------------------
 567 AC_ARG_ENABLE([gudev],
 568        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 569        [], [enable_gudev=yes])
 570 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 571 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 572
 573 # ------------------------------------------------------------------------------
 574 AC_ARG_ENABLE([keymap],
 575        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 576        [], [enable_keymap=yes])
 577 AS_IF([test "x$enable_keymap" = "xyes"], [
 578        AC_PATH_PROG([GPERF], [gperf])
 579        if test -z "$GPERF"; then
 580               AC_MSG_ERROR([gperf is needed])
 581        fi
 582
 583        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 584        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 585 ])
 586 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 587
 588 # ------------------------------------------------------------------------------
 589 have_manpages=no
 590 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 591 AS_IF([test "x$enable_manpages" != xno], [
 592         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 593                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 594         ])
 595         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 596 ])
 597 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 598
 599 # ------------------------------------------------------------------------------
 600
 601 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux, mandriva, mageia, angstrom or other]))
 602 if test "z$with_distro" = "z"; then
 603         if test "$cross_compiling" = yes; then
 604                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 605         else
 606                 with_distro=$($GREP '^ID=' /etc/os-release 2>/dev/null | $SED 's/ID=//');
 607         fi
 608         if test "z$with_distro" = "z"; then
 609                 with_distro=other
 610         fi
 611 fi
 612 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 613 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 614
 615 # Location of the init scripts as mandated by LSB
 616 SYSTEM_SYSVINIT_PATH=/etc/init.d
 617 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 618
 619 M4_DEFINES=
 620
 621 case $with_distro in
 622         fedora)
 623                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 624                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 625                 M4_DEFINES=-DTARGET_FEDORA=1
 626                 ;;
 627         opensuse|suse)
 628                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 629                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 630                 M4_DEFINES=-DTARGET_SUSE=1
 631                 ;;
 632         debian)
 633                 SYSTEM_SYSVRCND_PATH=/etc
 634                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 635                 M4_DEFINES=-DTARGET_DEBIAN=1
 636                 ;;
 637         ubuntu)
 638                 SYSTEM_SYSVRCND_PATH=/etc
 639                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 640                 M4_DEFINES=-DTARGET_UBUNTU=1
 641                 ;;
 642         arch)
 643                 SYSTEM_SYSVINIT_PATH=
 644                 SYSTEM_SYSVRCND_PATH=
 645                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 646                 M4_DEFINES=-DTARGET_ARCH=1
 647                 ;;
 648         gentoo)
 649                 SYSTEM_SYSVINIT_PATH=
 650                 SYSTEM_SYSVRCND_PATH=
 651                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 652                 M4_DEFINES=-DTARGET_GENTOO=1
 653                 ;;
 654         slackware)
 655                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 656                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 657                 M4_DEFINES=-DTARGET_SLACKWARE=1
 658                 ;;
 659         frugalware)
 660                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 661                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 662                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 663                 ;;
 664         altlinux)
 665                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 666                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 667                 M4_DEFINES=-DTARGET_ALTLINUX=1
 668                 ;;
 669         mandriva)
 670                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 671                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 672                 M4_DEFINES=-DTARGET_MANDRIVA=1
 673                 ;;
 674         angstrom)
 675                 SYSTEM_SYSVRCND_PATH=/etc
 676                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 677                 M4_DEFINES=-DTARGET_ANGSTROM=1
 678                 ;;
 679         mageia)
 680                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 681                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 682                 M4_DEFINES=-DTARGET_MAGEIA=1
 683                 ;;
 684         other)
 685                 ;;
 686         *)
 687                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 688                 ;;
 689 esac
 690
 691 AC_ARG_WITH([sysvinit-path],
 692         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 693                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 694         [SYSTEM_SYSVINIT_PATH="$withval"],
 695         [])
 696
 697 AC_ARG_WITH([sysvrcd-path],
 698         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 699                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 700         [SYSTEM_SYSVRCND_PATH="$withval"],
 701         [])
 702
 703 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 704 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 705 AC_SUBST(M4_DEFINES)
 706
 707 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 708         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 709         SYSTEM_SYSV_COMPAT="yes"
 710         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 711 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 712         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 713 else
 714         SYSTEM_SYSV_COMPAT="no"
 715 fi
 716
 717 AC_ARG_WITH([tty-gid],
 718         [AS_HELP_STRING([--with-tty-gid=GID],
 719                 [Specify the numeric GID of the 'tty' group])],
 720         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 721         [])
 722
 723 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 724 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 725 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 726 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 727 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 728 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 729 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 730 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 731 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 732 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 733 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 734 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 735 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 736
 737 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 738
 739 AC_ARG_WITH([dbuspolicydir],
 740         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 741         [],
 742         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 743
 744 AC_ARG_WITH([dbussessionservicedir],
 745         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 746         [],
 747         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 748
 749 AC_ARG_WITH([dbussystemservicedir],
 750         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 751         [],
 752         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 753
 754 AC_ARG_WITH([dbusinterfacedir],
 755         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 756         [],
 757         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 758
 759 AC_ARG_WITH([rootprefix],
 760         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 761         [], [with_rootprefix=${ac_default_prefix}])
 762
 763 AC_ARG_WITH([rootlibdir],
 764         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 765         [],
 766         [with_rootlibdir=${libdir}])
 767
 768 AC_ARG_WITH([pamlibdir],
 769         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 770         [],
 771         [with_pamlibdir=${with_rootlibdir}/security])
 772
 773 AC_ARG_ENABLE([split-usr],
 774         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 775         [],
 776         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 777                 enable_split_usr=yes
 778         ], [
 779                 enable_split_usr=no
 780         ])])
 781
 782 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 783         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 784 ])
 785
 786 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 787 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 788 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 789 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 790 AC_SUBST([pamlibdir], [$with_pamlibdir])
 791 AC_SUBST([rootprefix], [$with_rootprefix])
 792 AC_SUBST([rootlibdir], [$with_rootlibdir])
 793
 794 AC_CONFIG_FILES([
 795         Makefile po/Makefile.in
 796         docs/libudev/Makefile
 797         docs/libudev/version.xml
 798         docs/gudev/Makefile
 799         docs/gudev/version.xml
 800 ])
 801
 802 AC_OUTPUT
 803 AC_MSG_RESULT([
 804         $PACKAGE_NAME $VERSION
 805
 806         Distribution:            ${with_distro}
 807         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 808         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 809         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 810         libcryptsetup:           ${have_libcryptsetup}
 811         tcpwrap:                 ${have_tcpwrap}
 812         PAM:                     ${have_pam}
 813         AUDIT:                   ${have_audit}
 814         IMA:                     ${have_ima}
 815         SELinux:                 ${have_selinux}
 816         XZ:                      ${have_xz}
 817         ACL:                     ${have_acl}
 818         GCRYPT:                  ${have_gcrypt}
 819         QRENCODE:                ${have_qrencode}
 820         MICROHTTPD:              ${have_microhttpd}
 821         binfmt:                  ${have_binfmt}
 822         vconsole:                ${have_vconsole}
 823         readahead:               ${have_readahead}
 824         quotacheck:              ${have_quotacheck}
 825         randomseed:              ${have_randomseed}
 826         logind:                  ${have_logind}
 827         hostnamed:               ${have_hostnamed}
 828         timedated:               ${have_timedated}
 829         localed:                 ${have_localed}
 830         coredump:                ${have_coredump}
 831         firmware path:           ${FIRMWARE_PATH}
 832         usb.ids:                 ${USB_DATABASE}
 833         pci.ids:                 ${PCI_DATABASE}
 834         gudev:                   ${enable_gudev}
 835         gintrospection:          ${enable_introspection}
 836         keymap:                  ${enable_keymap}
 837         Python:                  ${have_python}
 838         Python Headers:          ${have_python_devel}
 839
 840         prefix:                  ${prefix}
 841         rootprefix:              ${with_rootprefix}
 842         sysconf dir:             ${sysconfdir}
 843         datarootdir:             ${datarootdir}
 844         includedir:              ${includedir}
 845         include_prefix:          ${INCLUDE_PREFIX}
 846         lib dir:                 ${libdir}
 847         rootlib dir:             ${with_rootlibdir}
 848         PAM modules dir:         ${with_pamlibdir}
 849         D-Bus policy dir:        ${with_dbuspolicydir}
 850         D-Bus session dir:       ${with_dbussessionservicedir}
 851         D-Bus system dir:        ${with_dbussystemservicedir}
 852         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 853         Split /usr:              ${enable_split_usr}
 854         man pages:               ${have_manpages}
 855         gtk-doc:                 ${enable_gtk_doc}
 856
 857         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 858         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 859         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 860 ])