configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[17],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  31
  32 AM_SILENT_RULES([yes])
  33
  34 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  35
  36 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  37         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  38         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  39 ])
  40
  41 AC_PROG_MKDIR_P
  42 AC_PROG_LN_S
  43 AC_PROG_SED
  44
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47 AM_PROG_CC_C_O
  48 AC_PROG_GCC_TRADITIONAL
  49 AC_USE_SYSTEM_EXTENSIONS
  50
  51 AC_CHECK_TOOL(OBJCOPY, objcopy)
  52 AC_CHECK_TOOL(STRINGS, strings)
  53
  54 CC_CHECK_CFLAGS_APPEND([ \
  55         -pipe \
  56         -Wall \
  57         -W \
  58         -Wextra \
  59         -Wno-inline \
  60         -Wvla \
  61         -Wundef \
  62         -Wformat=2 \
  63         -Wlogical-op \
  64         -Wsign-compare \
  65         -Wformat-security \
  66         -Wmissing-include-dirs \
  67         -Wformat-nonliteral \
  68         -Wold-style-definition \
  69         -Wpointer-arith \
  70         -Winit-self \
  71         -Wdeclaration-after-statement \
  72         -Wfloat-equal \
  73         -Wmissing-prototypes \
  74         -Wstrict-prototypes \
  75         -Wredundant-decls \
  76         -Wmissing-declarations \
  77         -Wmissing-noreturn \
  78         -Wshadow \
  79         -Wendif-labels \
  80         -Wcast-align \
  81         -Wstrict-aliasing=2 \
  82         -Wwrite-strings \
  83         -Wno-long-long \
  84         -Wno-overlength-strings \
  85         -Wno-unused-parameter \
  86         -Wno-missing-field-initializers \
  87         -Wno-unused-result \
  88         -Wp,-D_FORTIFY_SOURCE=2 \
  89         -ffast-math \
  90         -fno-common \
  91         -fdiagnostics-show-option \
  92         -fno-strict-aliasing \
  93         -fvisibility=hidden \
  94         -ffunction-sections \
  95         -fdata-sections \
  96         -Wl,--as-needed \
  97         -Wl,--gc-sections])
  98
  99 LT_PREREQ(2.2)
 100 LT_INIT
 101
 102 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 103 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 104 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 105 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 106
 107 # This makes sure pkg.m4 is available.
 108 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 109
 110 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
 111 AC_SUBST(UDEV_CFLAGS)
 112 AC_SUBST(UDEV_LIBS)
 113
 114 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 115 AC_SUBST(DBUS_CFLAGS)
 116 AC_SUBST(DBUS_LIBS)
 117
 118 have_selinux=no
 119 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 120 if test "x$enable_selinux" != "xno"; then
 121         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 122                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 123         AC_SUBST(SELINUX_CFLAGS)
 124         AC_SUBST(SELINUX_LIBS)
 125         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 126                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 127         fi
 128 fi
 129 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 130
 131 AC_ARG_ENABLE([tcpwrap],
 132         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 133                 [case "${enableval}" in
 134                         yes) have_tcpwrap=yes ;;
 135                         no) have_tcpwrap=no ;;
 136                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 137                 esac],
 138                 [have_tcpwrap=auto])
 139
 140 if test "x${have_tcpwrap}" != xno ; then
 141         ACX_LIBWRAP
 142         if test "x${LIBWRAP_LIBS}" = x ; then
 143                 if test "x$have_tcpwrap" = xyes ; then
 144                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 145                 fi
 146                 have_tcpwrap=no
 147         else
 148                 have_tcpwrap=yes
 149         fi
 150 else
 151         LIBWRAP_LIBS=
 152 fi
 153 AC_SUBST(LIBWRAP_LIBS)
 154
 155 AC_ARG_ENABLE([pam],
 156         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 157                 [case "${enableval}" in
 158                         yes) have_pam=yes ;;
 159                         no) have_pam=no ;;
 160                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 161                 esac],
 162                 [have_pam=auto])
 163
 164 if test "x${have_pam}" != xno ; then
 165         AC_CHECK_HEADERS(
 166                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 167                 [have_pam=yes],
 168                 [if test "x$have_pam" = xyes ; then
 169                         AC_MSG_ERROR([*** PAM headers not found.])
 170                 fi])
 171
 172         AC_CHECK_LIB(
 173                 [pam],
 174                 [pam_syslog],
 175                 [have_pam=yes],
 176                 [if test "x$have_pam" = xyes ; then
 177                         AC_MSG_ERROR([*** libpam not found.])
 178                 fi])
 179
 180         if test "x$have_pam" = xyes ; then
 181                 PAM_LIBS="-lpam -lpam_misc"
 182                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 183         else
 184                 have_pam=no
 185         fi
 186 else
 187         PAM_LIBS=
 188 fi
 189 AC_SUBST(PAM_LIBS)
 190 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 191
 192 AC_ARG_ENABLE([audit],
 193         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 194                 [case "${enableval}" in
 195                         yes) have_audit=yes ;;
 196                         no) have_audit=no ;;
 197                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 198                 esac],
 199                 [have_audit=auto])
 200
 201 if test "x${have_audit}" != xno ; then
 202         AC_CHECK_HEADERS(
 203                 [libaudit.h],
 204                 [have_audit=yes],
 205                 [if test "x$have_audit" = xyes ; then
 206                         AC_MSG_ERROR([*** AUDIT headers not found.])
 207                 fi])
 208
 209         AC_CHECK_LIB(
 210                 [audit],
 211                 [audit_open],
 212                 [have_audit=yes],
 213                 [if test "x$have_audit" = xyes ; then
 214                         AC_MSG_ERROR([*** libaudit not found.])
 215                 fi])
 216
 217         if test "x$have_audit" = xyes ; then
 218                 AUDIT_LIBS="-laudit"
 219                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 220         else
 221                 have_audit=no
 222         fi
 223 else
 224         AUDIT_LIBS=
 225 fi
 226 AC_SUBST(AUDIT_LIBS)
 227
 228 have_libcryptsetup=no
 229 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 230 if test "x$enable_libcryptsetup" != "xno"; then
 231         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 232                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 233         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
 234         AC_SUBST(LIBCRYPTSETUP_LIBS)
 235         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 236                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 237         fi
 238 fi
 239 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 240
 241 have_gtk=no
 242 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 243 if test "x$enable_gtk" != "xno"; then
 244         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
 245                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 246         AC_SUBST(GTK_CFLAGS)
 247         AC_SUBST(GTK_LIBS)
 248         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 249                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
 250         fi
 251 fi
 252 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 253
 254 if test "$have_gtk" = "yes"; then
 255         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 256         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
 257
 258         AC_SUBST(LIBNOTIFY_CFLAGS)
 259         AC_SUBST(LIBNOTIFY_LIBS)
 260 fi
 261 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
 262
 263 AM_PROG_VALAC([0.10])
 264 AC_SUBST(VAPIDIR)
 265 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 266
 267 AC_PATH_PROG([XSLTPROC], [xsltproc])
 268 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 269
 270 AC_PATH_PROG([M4], [m4])
 271
 272 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware or other]))
 273 if test "z$with_distro" = "z"; then
 274         if test "$cross_compiling" = yes; then
 275                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 276         else
 277                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 278                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 279                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 280                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 281                         with_distro="ubuntu"
 282                 fi
 283                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 284                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 285                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 286                 AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
 287         fi
 288         if test "z$with_distro" = "z"; then
 289                 with_distro=`uname -s`
 290         fi
 291 fi
 292 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 293 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 294
 295 # Default generic names
 296 SPECIAL_SYSLOG_SERVICE=syslog.service
 297
 298 # Location of the init scripts as mandated by LSB
 299 SYSTEM_SYSVINIT_PATH=/etc/init.d
 300
 301 M4_DISTRO_FLAG=
 302
 303 case $with_distro in
 304         fedora)
 305                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 306                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 307
 308                 # A little background why we define this special unit
 309                 # names here in configure.ac: SysV services currently
 310                 # cannot have aliases. As long as syslog is started
 311                 # via a SysV init script we hence define this name to
 312                 # the actual SysV name here. Later on when SysV init
 313                 # scripts are not used anymore it is advisable to use
 314                 # the generic name instead and use symlinks in the
 315                 # unit directories to point to the right native unit
 316                 # file.
 317
 318                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 319                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 320                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 321                 ;;
 322         suse)
 323                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 324                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 325                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 326                 ;;
 327         debian)
 328                 SYSTEM_SYSVRCND_PATH=/etc
 329                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 330                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 331                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 332                 ;;
 333         ubuntu)
 334                 SYSTEM_SYSVRCND_PATH=/etc
 335                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 336                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 337                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
 338                 ;;
 339         arch)
 340                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 341                 SYSTEM_SYSVRCND_PATH=/etc
 342                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 343                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 344                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 345                 ;;
 346         gentoo)
 347                 SYSTEM_SYSVINIT_PATH=
 348                 SYSTEM_SYSVRCND_PATH=
 349                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 350                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 351                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 352                 ;;
 353         slackware)
 354                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 355                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 356                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 357                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 358                 ;;
 359         frugalware)
 360                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 361                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 362                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 363                 M4_DISTRO_FLAG=-DTARGET_FRUGALWARE=1
 364                 ;;
 365         other)
 366                 AS_IF([test "x$with_syslog_service" = "x"],
 367                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 368                 ;;
 369         *)
 370                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 371                 ;;
 372 esac
 373
 374 AC_ARG_WITH([sysvinit-path],
 375         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 376                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 377         [SYSTEM_SYSVINIT_PATH="$withval"],
 378         [])
 379
 380 AC_ARG_WITH([sysvrcd-path],
 381         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 382                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 383         [SYSTEM_SYSVRCND_PATH="$withval"],
 384         [])
 385
 386 AC_ARG_WITH([syslog-service],
 387         [AS_HELP_STRING([--with-syslog-service=UNIT],
 388                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 389         [SPECIAL_SYSLOG_SERVICE="$withval"],
 390         [])
 391
 392 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 393 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 394 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 395 AC_SUBST(M4_DISTRO_FLAG)
 396
 397 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 398         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 399         SYSTEM_SYSV_COMPAT="yes"
 400 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 401         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 402 else
 403         SYSTEM_SYSV_COMPAT="no"
 404 fi
 405
 406 AC_ARG_WITH([tty-gid],
 407         [AS_HELP_STRING([--with-tty-gid=GID],
 408                 [Specify the numeric GID of the 'tty' group])],
 409         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 410         [])
 411
 412 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 413 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 414 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 415 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 416 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 417 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 418 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 419 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 420 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 421
 422 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 423
 424 AC_ARG_WITH([dbuspolicydir],
 425         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 426         [],
 427         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 428
 429 AC_ARG_WITH([dbussessionservicedir],
 430         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 431         [],
 432         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 433
 434 AC_ARG_WITH([dbussystemservicedir],
 435         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 436         [],
 437         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 438
 439 AC_ARG_WITH([dbusinterfacedir],
 440         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 441         [],
 442         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 443
 444 AC_ARG_WITH([udevrulesdir],
 445         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 446         [],
 447         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 448
 449 AC_ARG_WITH([pamlibdir],
 450         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 451         [],
 452         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 453
 454 AC_ARG_WITH([rootdir],
 455         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 456         [],
 457         [with_rootdir=${ac_default_prefix}])
 458
 459 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 460 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 461 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 462 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 463 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 464 AC_SUBST([pamlibdir], [$with_pamlibdir])
 465 AC_SUBST([rootdir], [$with_rootdir])
 466
 467 AC_CONFIG_FILES([Makefile])
 468 AC_OUTPUT
 469
 470 echo "
 471         $PACKAGE_NAME $VERSION
 472
 473         Distribution:            ${with_distro}
 474         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 475         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 476         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 477         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 478         Gtk:                     ${have_gtk}
 479         libcryptsetup:           ${have_libcryptsetup}
 480         tcpwrap:                 ${have_tcpwrap}
 481         PAM:                     ${have_pam}
 482         AUDIT:                   ${have_audit}
 483         SELinux:                 ${have_selinux}
 484         prefix:                  ${prefix}
 485         root dir:                ${with_rootdir}
 486         udev rules dir:          ${with_udevrulesdir}
 487         pam modules dir:         ${with_pamlibdir}
 488         dbus policy dir:         ${with_dbuspolicydir}
 489         dbus session dir:        ${with_dbussessionservicedir}
 490         dbus system dir:         ${with_dbussystemservicedir}
 491         dbus interfaces dir:     ${with_dbusinterfacedir}
 492 "