configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [204],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  78 m4_ifdef([GTK_DOC_CHECK], [
  79 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  80          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  81           enable_gtk_doc=no])
  82
  83 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  84         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  85 ])
  86
  87 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  88 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  89 ], [
  90    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  91    enable_introspection=no])
  92
  93 AC_CHECK_TOOL(OBJCOPY, objcopy)
  94 AC_CHECK_TOOL(STRINGS, strings)
  95 AC_CHECK_TOOL(GPERF, gperf)
  96 if test -z "$GPERF" ; then
  97         AC_MSG_ERROR([*** gperf not found])
  98 fi
  99
 100 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 101         -pipe \
 102         -Wall \
 103         -Wextra \
 104         -Wno-inline \
 105         -Wundef \
 106         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 107         -Wlogical-op \
 108         -Wsign-compare \
 109         -Wmissing-include-dirs \
 110         -Wold-style-definition \
 111         -Wpointer-arith \
 112         -Winit-self \
 113         -Wdeclaration-after-statement \
 114         -Wfloat-equal \
 115         -Wmissing-prototypes \
 116         -Wstrict-prototypes \
 117         -Wredundant-decls \
 118         -Wmissing-declarations \
 119         -Wmissing-noreturn \
 120         -Wshadow \
 121         -Wendif-labels \
 122         -Wcast-align \
 123         -Wstrict-aliasing=2 \
 124         -Wwrite-strings \
 125         -Wno-long-long \
 126         -Wno-overlength-strings \
 127         -Wno-unused-parameter \
 128         -Wno-missing-field-initializers \
 129         -Wno-unused-result \
 130         -Werror=overflow \
 131         -ffast-math \
 132         -fno-common \
 133         -fdiagnostics-show-option \
 134         -fdiagnostics-color \
 135         -fno-strict-aliasing \
 136         -fvisibility=hidden \
 137         -ffunction-sections \
 138         -fdata-sections \
 139         -fstack-protector \
 140         --param=ssp-buffer-size=4])
 141 AC_SUBST([OUR_CFLAGS], $with_cflags)
 142
 143 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
 144         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 145                -Wp,-D_FORTIFY_SOURCE=2])], [
 146         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 147         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 148 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 149
 150 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 151         -Wl,--as-needed \
 152         -Wl,--no-undefined \
 153         -Wl,--gc-sections \
 154         -Wl,-z,relro \
 155         -Wl,-z,now])
 156 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 157
 158 # ------------------------------------------------------------------------------
 159 # we use python to build the man page index, and for systemd-python
 160 have_python=no
 161 have_python_devel=no
 162
 163 AC_ARG_WITH([python],
 164         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 165
 166 AS_IF([test "x$with_python" != "xno"], [
 167         AM_PATH_PYTHON(,, [:])
 168         AS_IF([test "$PYTHON" != :], [have_python=yes])
 169 ])
 170 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 171 AS_IF([test "x$PYTHON_BINARY" = "x"],
 172       [AS_IF([test "x$have_python" = "xyes"],
 173              [PYTHON_BINARY="$(which "$PYTHON")"],
 174              [PYTHON_BINARY=/usr/bin/python])])
 175 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 176
 177 AS_IF([test "x$with_python" != "xno"], [
 178         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 179         AS_IF([test -n "$PYTHON_CONFIG"], [
 180               have_python_devel=yes
 181               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
 182               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
 183               AC_SUBST(PYTHON_CFLAGS)
 184               AC_SUBST(PYTHON_LIBS)
 185               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 186         ])
 187 ])
 188 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 189
 190 # ------------------------------------------------------------------------------
 191
 192 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 193 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 194
 195 save_LIBS="$LIBS"
 196 LIBS=
 197 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 198 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 199 CAP_LIBS="$LIBS"
 200 LIBS="$save_LIBS"
 201 AC_SUBST(CAP_LIBS)
 202
 203 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 204 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 205 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 206 #include <unistd.h>
 207 #include <sys/mount.h>
 208 #include <fcntl.h>]])
 209
 210 # This makes sure pkg.m4 is available.
 211 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 212
 213 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 214
 215 # ------------------------------------------------------------------------------
 216 have_kmod=no
 217 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 218 if test "x$enable_kmod" != "xno"; then
 219         PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ],
 220                 [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available]) have_kmod=yes], have_kmod=no)
 221         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 222                 AC_MSG_ERROR([*** kmod support requested but libraries not found])
 223         fi
 224 fi
 225 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 226
 227 # ------------------------------------------------------------------------------
 228 have_blkid=no
 229 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 230 if test "x$enable_blkid" != "xno"; then
 231         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 232                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 233         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 234                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 235         fi
 236 fi
 237 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 238
 239 # ------------------------------------------------------------------------------
 240 have_ima=yes
 241 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 242                 [case "${enableval}" in
 243                         yes) have_ima=yes ;;
 244                         no) have_ima=no ;;
 245                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 246                 esac],
 247                 [have_ima=yes])
 248
 249 if test "x${have_ima}" != xno ; then
 250         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 251 fi
 252
 253 # ------------------------------------------------------------------------------
 254 have_chkconfig=yes
 255 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 256                 [case "${enableval}" in
 257                         yes) have_chkconfig=yes ;;
 258                         no) have_chkconfig=no ;;
 259                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 260                 esac],
 261                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 262                 if test -z "$CHKCONFIG"; then
 263                         have_chkconfig=no
 264                 else
 265                         have_chkconfig=yes
 266                 fi])
 267
 268 if test "x${have_chkconfig}" != xno ; then
 269         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 270 fi
 271
 272 # ------------------------------------------------------------------------------
 273 have_selinux=no
 274 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 275 if test "x$enable_selinux" != "xno"; then
 276         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 277                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 278         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 279                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 280         fi
 281 fi
 282 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 283
 284 AC_ARG_WITH(debug-shell,
 285         AS_HELP_STRING([--with-debug-shell=PATH],
 286                 [Path to debug shell binary]),
 287         [SUSHELL="$withval"],[
 288         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 289
 290 AC_SUBST(SUSHELL)
 291
 292 AC_ARG_WITH([debug-tty],
 293         AS_HELP_STRING([--with-debug-tty=PATH],
 294                 [Specify the tty device for debug shell]),
 295         [DEBUGTTY="$withval"],
 296         [DEBUGTTY=/dev/tty9])
 297
 298 AC_SUBST(DEBUGTTY)
 299
 300 # ------------------------------------------------------------------------------
 301 have_xz=no
 302 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 303 if test "x$enable_xz" != "xno"; then
 304         PKG_CHECK_MODULES(XZ, [ liblzma ],
 305                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 306         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 307                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 308         fi
 309 fi
 310 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 311
 312 # ------------------------------------------------------------------------------
 313 AC_ARG_ENABLE([tcpwrap],
 314         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 315                 [case "${enableval}" in
 316                         yes) have_tcpwrap=yes ;;
 317                         no) have_tcpwrap=no ;;
 318                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 319                 esac],
 320                 [have_tcpwrap=auto])
 321
 322 if test "x${have_tcpwrap}" != xno ; then
 323         ACX_LIBWRAP
 324         if test "x${LIBWRAP_LIBS}" = x ; then
 325                 if test "x$have_tcpwrap" = xyes ; then
 326                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 327                 fi
 328                 have_tcpwrap=no
 329         else
 330                 have_tcpwrap=yes
 331         fi
 332 else
 333         LIBWRAP_LIBS=
 334 fi
 335 AC_SUBST(LIBWRAP_LIBS)
 336
 337 # ------------------------------------------------------------------------------
 338 AC_ARG_ENABLE([pam],
 339         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 340                 [case "${enableval}" in
 341                         yes) have_pam=yes ;;
 342                         no) have_pam=no ;;
 343                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 344                 esac],
 345                 [have_pam=auto])
 346
 347 if test "x${have_pam}" != xno ; then
 348         AC_CHECK_HEADERS(
 349                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 350                 [have_pam=yes],
 351                 [if test "x$have_pam" = xyes ; then
 352                         AC_MSG_ERROR([*** PAM headers not found.])
 353                 fi])
 354
 355         AC_CHECK_LIB(
 356                 [pam],
 357                 [pam_syslog],
 358                 [have_pam=yes],
 359                 [if test "x$have_pam" = xyes ; then
 360                         AC_MSG_ERROR([*** libpam not found.])
 361                 fi])
 362
 363         if test "x$have_pam" = xyes ; then
 364                 PAM_LIBS="-lpam -lpam_misc"
 365                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 366         else
 367                 have_pam=no
 368         fi
 369 else
 370         PAM_LIBS=
 371 fi
 372 AC_SUBST(PAM_LIBS)
 373 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 374
 375 # ------------------------------------------------------------------------------
 376 AC_ARG_ENABLE([acl],
 377         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 378                 [case "${enableval}" in
 379                         yes) have_acl=yes ;;
 380                         no) have_acl=no ;;
 381                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 382                 esac],
 383                 [have_acl=auto])
 384
 385 if test "x${have_acl}" != xno ; then
 386         AC_CHECK_HEADERS(
 387                 [sys/acl.h acl/libacl.h],
 388                 [have_acl=yes],
 389                 [if test "x$have_acl" = xyes ; then
 390                         AC_MSG_ERROR([*** ACL headers not found.])
 391                 fi])
 392
 393         AC_CHECK_LIB(
 394                 [acl],
 395                 [acl_get_file],
 396                 [have_acl=yes],
 397                 [if test "x$have_acl" = xyes ; then
 398                         AC_MSG_ERROR([*** libacl not found.])
 399                 fi])
 400
 401         if test "x$have_acl" = xyes ; then
 402                 ACL_LIBS="-lacl"
 403                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 404         else
 405                 have_acl=no
 406         fi
 407 else
 408         ACL_LIBS=
 409 fi
 410 AC_SUBST(ACL_LIBS)
 411 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 412
 413 # ------------------------------------------------------------------------------
 414 AC_ARG_ENABLE([xattr],
 415         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 416                 [case "${enableval}" in
 417                         yes) have_xattr=yes ;;
 418                         no) have_xattr=no ;;
 419                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 420                 esac],
 421                 [have_xattr=auto])
 422
 423 if test "x${have_xattr}" != xno ; then
 424         AC_CHECK_HEADERS(
 425                 [attr/xattr.h],
 426                 [have_xattr=yes],
 427                 [if test "x$have_xattr" = xyes ; then
 428                         AC_MSG_ERROR([*** XATTR headers not found.])
 429                 fi])
 430
 431         AC_CHECK_LIB(
 432                 [attr],
 433                 [fsetxattr],
 434                 [have_xattr=yes],
 435                 [if test "x$have_xattr" = xyes ; then
 436                         AC_MSG_ERROR([*** libattr not found.])
 437                 fi])
 438
 439         if test "x$have_xattr" = xyes ; then
 440                 XATTR_LIBS="-lattr"
 441                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 442         else
 443                 have_xattr=no
 444         fi
 445 else
 446         XATTR_LIBS=
 447 fi
 448 AC_SUBST(XATTR_LIBS)
 449 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 450
 451 # ------------------------------------------------------------------------------
 452 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 453                 [case "${enableval}" in
 454                         yes) have_smack=yes ;;
 455                         no) have_smack=no ;;
 456                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 457                 esac],
 458                 [have_smack=auto])
 459
 460 if test "x${have_xattr}" = xno; then
 461         if test "x${have_smack}" = xyes; then
 462                 AC_MSG_ERROR(SMACK requires xattr support)
 463         else
 464                 have_smack=no
 465         fi
 466 else
 467         if test "x${have_smack}" = xauto; then
 468                 have_smack=yes
 469         fi
 470 fi
 471
 472 if test "x${have_smack}" = xyes ; then
 473         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 474 fi
 475
 476 # ------------------------------------------------------------------------------
 477 AC_ARG_ENABLE([gcrypt],
 478         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 479                 [case "${enableval}" in
 480                         yes) have_gcrypt=yes ;;
 481                         no) have_gcrypt=no ;;
 482                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 483                 esac],
 484                 [have_gcrypt=auto])
 485
 486 if test "x${have_gcrypt}" != xno ; then
 487         AM_PATH_LIBGCRYPT(
 488                 [1.4.5],
 489                 [have_gcrypt=yes],
 490                 [if test "x$have_gcrypt" = xyes ; then
 491                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 492                 fi])
 493
 494         if test "x$have_gcrypt" = xyes ; then
 495                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 496                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 497                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 498         else
 499                 have_gcrypt=no
 500         fi
 501 else
 502         GCRYPT_LIBS=
 503         GCRYPT_CFLAGS=
 504 fi
 505 AC_SUBST(GCRYPT_LIBS)
 506 AC_SUBST(GCRYPT_CFLAGS)
 507 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 508
 509 # ------------------------------------------------------------------------------
 510 AC_ARG_ENABLE([audit],
 511         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 512                 [case "${enableval}" in
 513                         yes) have_audit=yes ;;
 514                         no) have_audit=no ;;
 515                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 516                 esac],
 517                 [have_audit=auto])
 518
 519 if test "x${have_audit}" != xno ; then
 520         AC_CHECK_HEADERS(
 521                 [libaudit.h],
 522                 [have_audit=yes],
 523                 [if test "x$have_audit" = xyes ; then
 524                         AC_MSG_ERROR([*** AUDIT headers not found.])
 525                 fi])
 526
 527         AC_CHECK_LIB(
 528                 [audit],
 529                 [audit_open],
 530                 [have_audit=yes],
 531                 [if test "x$have_audit" = xyes ; then
 532                         AC_MSG_ERROR([*** libaudit not found.])
 533                 fi])
 534
 535         if test "x$have_audit" = xyes ; then
 536                 AUDIT_LIBS="-laudit"
 537                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 538         else
 539                 have_audit=no
 540         fi
 541 else
 542         AUDIT_LIBS=
 543 fi
 544 AC_SUBST(AUDIT_LIBS)
 545
 546 # ------------------------------------------------------------------------------
 547 have_libcryptsetup=no
 548 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 549 if test "x$enable_libcryptsetup" != "xno"; then
 550         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 551                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 552         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 553                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 554         fi
 555 fi
 556 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 557
 558 # ------------------------------------------------------------------------------
 559 have_qrencode=no
 560 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 561 if test "x$enable_qrencode" != "xno"; then
 562         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 563                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 564         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 565                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 566         fi
 567 fi
 568 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 569
 570 # ------------------------------------------------------------------------------
 571 have_microhttpd=no
 572 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 573 if test "x$enable_microhttpd" != "xno"; then
 574         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 575                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 576         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 577                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 578         fi
 579 fi
 580 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 581
 582 # ------------------------------------------------------------------------------
 583 have_binfmt=no
 584 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 585 if test "x$enable_binfmt" != "xno"; then
 586         have_binfmt=yes
 587 fi
 588 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 589
 590 # ------------------------------------------------------------------------------
 591 have_vconsole=no
 592 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 593 if test "x$enable_vconsole" != "xno"; then
 594         have_vconsole=yes
 595 fi
 596 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 597
 598 # ------------------------------------------------------------------------------
 599 have_readahead=no
 600 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 601 if test "x$enable_readahead" != "xno"; then
 602         have_readahead=yes
 603 fi
 604 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 605
 606 # ------------------------------------------------------------------------------
 607 have_bootchart=no
 608 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 609 if test "x$enable_bootchart" != "xno"; then
 610         have_bootchart=yes
 611 fi
 612 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 613
 614 # ------------------------------------------------------------------------------
 615 have_quotacheck=no
 616 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 617 if test "x$enable_quotacheck" != "xno"; then
 618         have_quotacheck=yes
 619 fi
 620 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 621
 622 # ------------------------------------------------------------------------------
 623 have_tmpfiles=no
 624 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 625 if test "x$enable_tmpfiles" != "xno"; then
 626         have_tmpfiles=yes
 627 fi
 628 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 629
 630 # ------------------------------------------------------------------------------
 631 have_randomseed=no
 632 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 633 if test "x$enable_randomseed" != "xno"; then
 634         have_randomseed=yes
 635 fi
 636 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 637
 638 # ------------------------------------------------------------------------------
 639 have_logind=no
 640 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 641 if test "x$enable_logind" != "xno"; then
 642         have_logind=yes
 643 fi
 644 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 645 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 646
 647 # ------------------------------------------------------------------------------
 648 have_machined=no
 649 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 650 if test "x$enable_machined" != "xno"; then
 651         have_machined=yes
 652 fi
 653 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 654 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 655
 656 # ------------------------------------------------------------------------------
 657 have_hostnamed=no
 658 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 659 if test "x$enable_hostnamed" != "xno"; then
 660         have_hostnamed=yes
 661 fi
 662 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 663
 664 # ------------------------------------------------------------------------------
 665 have_timedated=no
 666 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 667 if test "x$enable_timedated" != "xno"; then
 668         have_timedated=yes
 669 fi
 670 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 671
 672 # ------------------------------------------------------------------------------
 673 have_localed=no
 674 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 675 if test "x$enable_localed" != "xno"; then
 676         have_localed=yes
 677 fi
 678 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 679
 680 # ------------------------------------------------------------------------------
 681 have_coredump=no
 682 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 683 if test "x$enable_coredump" != "xno"; then
 684         have_coredump=yes
 685 fi
 686 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 687
 688 # ------------------------------------------------------------------------------
 689 have_polkit=no
 690 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 691 if test "x$enable_polkit" != "xno"; then
 692         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 693         have_polkit=yes
 694 fi
 695 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 696
 697 # ------------------------------------------------------------------------------
 698 have_efi=no
 699 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 700 if test "x$enable_efi" != "xno"; then
 701         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 702         have_efi=yes
 703 fi
 704 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 705
 706 # ------------------------------------------------------------------------------
 707 AC_ARG_WITH(rc-local-script-path-start,
 708         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 709                 [Path to /etc/rc.local]),
 710         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 711         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 712
 713 AC_ARG_WITH(rc-local-script-path-stop,
 714         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 715                 [Path to /usr/sbin/halt.local]),
 716         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 717         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 718
 719 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 720 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 721
 722 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 723 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 724
 725 # ------------------------------------------------------------------------------
 726 AC_ARG_WITH(kbd-loadkeys,
 727         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 728                 [Path to loadkeys]),
 729         [KBD_LOADKEYS="$withval"],
 730         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 731
 732 AC_ARG_WITH(kbd-setfont,
 733         AS_HELP_STRING([--with-kbd-setfont=PATH],
 734                 [Path to setfont]),
 735         [KBD_SETFONT="$withval"],
 736         [KBD_SETFONT="/usr/bin/setfont"])
 737
 738 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 739 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 740
 741 AC_SUBST(KBD_LOADKEYS)
 742 AC_SUBST(KBD_SETFONT)
 743
 744 AC_ARG_WITH(telinit,
 745         AS_HELP_STRING([--with-telinit=PATH],
 746                 [Path to telinit]),
 747         [TELINIT="$withval"],
 748         [TELINIT="/lib/upstart/telinit"])
 749
 750 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 751
 752 AC_SUBST(TELINIT)
 753
 754 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 755
 756 # ------------------------------------------------------------------------------
 757 have_myhostname=no
 758 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 759 if test "x$enable_myhostname" != "xno"; then
 760         AC_HEADER_STDC
 761         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 762
 763         AC_C_CONST
 764         AC_TYPE_SIZE_T
 765         AC_HEADER_TIME
 766
 767         AC_FUNC_MALLOC
 768         AC_FUNC_SELECT_ARGTYPES
 769         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 770
 771         have_myhostname=yes
 772 fi
 773 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 774
 775 # ------------------------------------------------------------------------------
 776 AC_ARG_WITH(firmware-path,
 777        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 778           [Firmware search path (default="")]),
 779        [], [with_firmware_path=""])
 780 OLD_IFS=$IFS
 781 IFS=:
 782 for i in $with_firmware_path; do
 783        if test "x${FIRMWARE_PATH}" = "x"; then
 784               FIRMWARE_PATH="\\\"${i}/\\\""
 785        else
 786               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 787        fi
 788 done
 789 IFS=$OLD_IFS
 790 AC_SUBST(FIRMWARE_PATH)
 791 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 792 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 793
 794 # ------------------------------------------------------------------------------
 795 AC_ARG_ENABLE([gudev],
 796        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 797        [], [enable_gudev=yes])
 798 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 799 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 800 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 801
 802 # ------------------------------------------------------------------------------
 803 AC_ARG_ENABLE([keymap],
 804        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 805        [], [enable_keymap=yes])
 806 AS_IF([test "x$enable_keymap" = "xyes"], [
 807        AC_PATH_PROG([GPERF], [gperf])
 808        if test -z "$GPERF"; then
 809               AC_MSG_ERROR([gperf is needed])
 810        fi
 811
 812        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 813        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 814 ])
 815 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 816
 817 # ------------------------------------------------------------------------------
 818 have_manpages=no
 819 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 820 AS_IF([test "x$enable_manpages" != xno], [
 821         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 822                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 823         ])
 824         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 825 ])
 826 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 827
 828 # ------------------------------------------------------------------------------
 829
 830 # Location of the init scripts as mandated by LSB
 831 SYSTEM_SYSVINIT_PATH=/etc/init.d
 832 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 833 M4_DEFINES=
 834
 835 AC_ARG_WITH([sysvinit-path],
 836         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 837                 [Specify the path to where the SysV init scripts are located])],
 838         [SYSTEM_SYSVINIT_PATH="$withval"],
 839         [])
 840
 841 AC_ARG_WITH([sysvrcnd-path],
 842         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 843                 [Specify the path to the base directory for the SysV rcN.d directories])],
 844         [SYSTEM_SYSVRCND_PATH="$withval"],
 845         [])
 846
 847 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 848         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 849         SYSTEM_SYSV_COMPAT="yes"
 850         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 851 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 852         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 853 else
 854         SYSTEM_SYSV_COMPAT="no"
 855 fi
 856
 857 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 858 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 859 AC_SUBST(M4_DEFINES)
 860
 861 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 862
 863 AC_ARG_WITH([tty-gid],
 864         [AS_HELP_STRING([--with-tty-gid=GID],
 865                 [Specify the numeric GID of the 'tty' group])],
 866         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 867         [])
 868
 869 AC_ARG_WITH([dbuspolicydir],
 870         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 871         [],
 872         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 873
 874 AC_ARG_WITH([dbussessionservicedir],
 875         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 876         [],
 877         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 878
 879 AC_ARG_WITH([dbussystemservicedir],
 880         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 881         [],
 882         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 883
 884 AC_ARG_WITH([dbusinterfacedir],
 885         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 886         [],
 887         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 888
 889 AC_ARG_WITH([bashcompletiondir],
 890         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 891         [],
 892         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 893                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 894         ] , [
 895                 with_bashcompletiondir=${datadir}/bash-completion/completions
 896         ])])
 897
 898 AC_ARG_WITH([rootprefix],
 899         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 900         [], [with_rootprefix=${ac_default_prefix}])
 901
 902 AC_ARG_WITH([rootlibdir],
 903         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 904         [],
 905         [with_rootlibdir=${libdir}])
 906
 907 AC_ARG_WITH([pamlibdir],
 908         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 909         [],
 910         [with_pamlibdir=${with_rootlibdir}/security])
 911
 912 AC_ARG_ENABLE([split-usr],
 913         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 914         [],
 915         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 916                 enable_split_usr=yes
 917         ], [
 918                 enable_split_usr=no
 919         ])])
 920
 921 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 922         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 923 ])
 924
 925 # Work around intltoolize and gtk-doc problems in VPATH builds
 926 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 927                                        [Define to do gtk-doc tests])
 928 AS_IF([test "x$0" != "x./configure"], [
 929         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 930 ])
 931
 932 AC_ARG_ENABLE(tests,
 933        [AC_HELP_STRING([--disable-tests], [disable tests])],
 934        enable_tests=$enableval, enable_tests=yes)
 935 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 936
 937 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 938 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 939 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 940 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 941 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 942 AC_SUBST([pamlibdir], [$with_pamlibdir])
 943 AC_SUBST([rootprefix], [$with_rootprefix])
 944 AC_SUBST([rootlibdir], [$with_rootlibdir])
 945
 946 AC_CONFIG_FILES([
 947         Makefile po/Makefile.in
 948         docs/libudev/Makefile
 949         docs/libudev/version.xml
 950         docs/gudev/Makefile
 951         docs/gudev/version.xml
 952 ])
 953
 954 AC_OUTPUT
 955 AC_MSG_RESULT([
 956         $PACKAGE_NAME $VERSION
 957
 958         libcryptsetup:           ${have_libcryptsetup}
 959         tcpwrap:                 ${have_tcpwrap}
 960         PAM:                     ${have_pam}
 961         AUDIT:                   ${have_audit}
 962         IMA:                     ${have_ima}
 963         SELinux:                 ${have_selinux}
 964         SMACK:                   ${have_smack}
 965         XZ:                      ${have_xz}
 966         ACL:                     ${have_acl}
 967         XATTR:                   ${have_xattr}
 968         GCRYPT:                  ${have_gcrypt}
 969         QRENCODE:                ${have_qrencode}
 970         MICROHTTPD:              ${have_microhttpd}
 971         CHKCONFIG:               ${have_chkconfig}
 972         binfmt:                  ${have_binfmt}
 973         vconsole:                ${have_vconsole}
 974         readahead:               ${have_readahead}
 975         bootchart:               ${have_bootchart}
 976         quotacheck:              ${have_quotacheck}
 977         tmpfiles:                ${have_tmpfiles}
 978         randomseed:              ${have_randomseed}
 979         logind:                  ${have_logind}
 980         machined:                ${have_machined}
 981         hostnamed:               ${have_hostnamed}
 982         timedated:               ${have_timedated}
 983         localed:                 ${have_localed}
 984         coredump:                ${have_coredump}
 985         polkit:                  ${have_polkit}
 986         efi:                     ${have_efi}
 987         kmod:                    ${have_kmod}
 988         blkid:                   ${have_blkid}
 989         nss-myhostname:          ${have_myhostname}
 990         gudev:                   ${enable_gudev}
 991         gintrospection:          ${enable_introspection}
 992         keymap:                  ${enable_keymap}
 993         Python:                  ${have_python}
 994         Python Headers:          ${have_python_devel}
 995         man pages:               ${have_manpages}
 996         gtk-doc:                 ${enable_gtk_doc}
 997         Split /usr:              ${enable_split_usr}
 998         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 999
1000         prefix:                  ${prefix}
1001         rootprefix:              ${with_rootprefix}
1002         sysconf dir:             ${sysconfdir}
1003         datarootdir:             ${datarootdir}
1004         includedir:              ${includedir}
1005         include_prefix:          ${INCLUDE_PREFIX}
1006         lib dir:                 ${libdir}
1007         rootlib dir:             ${with_rootlibdir}
1008         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1009         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1010         Build Python:            ${PYTHON}
1011         Installation Python:     ${PYTHON_BINARY}
1012         firmware path:           ${FIRMWARE_PATH}
1013         PAM modules dir:         ${with_pamlibdir}
1014         D-Bus policy dir:        ${with_dbuspolicydir}
1015         D-Bus session dir:       ${with_dbussessionservicedir}
1016         D-Bus system dir:        ${with_dbussystemservicedir}
1017         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1018         Bash completions dir:    ${with_bashcompletiondir}
1019         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1020         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1021         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1022
1023         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1024         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1025         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1026         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
1027         PYTHON_LIBS:             ${PYTHON_LIBS}
1028 ])