+our @git = qw(git);
+
+sub in_workarea ($) {
+ my ($sub) = @_;
+ changedir $workarea;
+ my $r = eval { $sub->(); };
+ { local $@; changedir $maindir; }
+ die $@ if $@;
+}
+
+sub fresh_workarea () {
+ $workarea = fresh_playground "$playprefix/work";
+ in_workarea sub { playtree_setup };
+}
+
+sub get_differs ($$) {
+ my ($x,$y) = @_;
+ # This resembles quiltify_trees_differ, in dgit, a bit.
+ # But we don't care about modes, or dpkg-source-unrepresentable
+ # changes, and we don't need the plethora of different modes.
+ # Conversely we need to distinguish different kinds of changes to
+ # debian/ and debian/patches/.
+
+ my $differs = 0;
+
+ my $rundiff = sub {
+ my ($opts, $limits, $fn) = @_;
+ my @cmd = (@git, qw(diff-tree -z --no-renames));
+ push @cmd, @$opts;
+ push @cmd, "$_:" foreach $x, $y;
+ push @cmd, @$limits;
+ my $diffs = cmdoutput @cmd;
+ foreach (split /\0/, $diffs) { $fn->(); }
+ };
+
+ $rundiff->([qw(--name-only)], [], sub {
+ $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
+ });
+
+ if ($differs & DS_DEB) {
+ $differs &= ~DS_DEB;
+ $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
+ $differs |=
+ m{^debian/patches/} ? D_PAT_OTH :
+ $_ eq 'debian/changelog' ? D_DEB_CLOG :
+ D_DEB_OTH;
+ });
+ die "mysterious debian changes $x..$y"
+ unless $differs & (D_PAT_OTH|DS_DEB);
+ }
+
+ if ($differs & D_PAT_OTH) {
+ my $mode;
+ $differs &= ~D_PAT_OTH;
+ my $pat_oth = sub {
+ $differs |= D_PAT_OTH;
+ no warnings qw(exiting); last;
+ };
+ $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
+ no warnings qw(exiting);
+ if (!defined $mode) {
+ $mode = $_; next;
+ }
+ die unless s{^debian/patches/}{};
+ my $ok;
+ if ($mode eq 'A' && !m/\.series$/s) {
+ $ok = 1;
+ } elsif ($mode eq 'M' && $_ eq 'series') {
+ my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
+ my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
+ chomp $x_s; $x_s .= "\n";
+ $ok = $x_s eq substr($y_s, 0, length $x_s);
+ } else {
+ # nope
+ }
+ $mode = undef;
+ $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
+ });
+ die "mysterious debian/patches changes $x..$y"
+ unless $differs & (D_PAT_ADD|D_PAT_OTH);
+ }
+
+ printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
+
+ return $differs;
+}
+
+sub commit_pr_info ($) {
+ my ($r) = @_;
+ return Data::Dumper->dump([$r], [qw(commit)]);
+}
+
+sub calculate_committer_authline () {
+ my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
+ 'DUMMY COMMIT (git-debrebase)', "HEAD:";
+ my ($h,$m) = get_commit $c;
+ $h =~ m/^committer .*$/m or confess "($h) ?";
+ return $&;
+}
+
+sub rm_subdir_cached ($) {
+ my ($subdir) = @_;
+ runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
+}
+
+sub read_tree_subdir ($$) {
+ my ($subdir, $new_tree_object) = @_;
+ rm_subdir_cached $subdir;
+ runcmd @git, qw(read-tree), "--prefix=$subdir/";
+}
+
+# classify returns an info hash like this
+# CommitId => $objid
+# Hdr => # commit headers, including 1 final newline
+# Msg => # commit message (so one newline is dropped)
+# Tree => $treeobjid
+# Type => (see below)
+# Parents = [ {
+# Ix => $index # ie 0, 1, 2, ...
+# CommitId
+# Differs => return value from get_differs
+# IsOrigin
+# IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
+# } ...]
+# NewMsg => # commit message, but with any [dgit import ...] edited
+# # to say "[was: ...]"
+#
+# Types:
+# Packaging
+# Changelog
+# Upstream
+# AddPatches
+# Mixed
+# Unknown
+#
+# Pseudomerge
+# has additional entres in classification result
+# Overwritten = [ subset of Parents ]
+# Contributor = $the_remaining_Parent
+#
+# DgitImportUnpatched
+# has additional entry in classification result
+# OrigParents = [ subset of Parents ]
+#
+# BreakwaterUpstreamMerge
+# has additional entry in classification result
+# OrigParents = [ subset of Parents ] # singleton list
+
+sub parsecommit ($;$) {
+ my ($objid, $p_ref) = @_;
+ # => hash with CommitId Hdr Msg Tree Parents
+ # Parents entries have only Ix CommitId
+ # $p_ref, if provided, must be [] and is used as a base for Parents
+
+ $p_ref //= [];
+ die if @$p_ref;
+
+ my ($h,$m) = get_commit $objid;
+
+ my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
+ my (@ph) = $h =~ m/^parent (\w+)$/mg;
+
+ my $r = {
+ CommitId => $objid,
+ Hdr => $h,
+ Msg => $m,
+ Tree => $t,
+ Parents => $p_ref,
+ };
+
+ foreach my $ph (@ph) {
+ push @$p_ref, {
+ Ix => $#$p_ref,
+ CommitId => $ph,
+ };
+ }
+
+ return $r;
+}
+
+sub classify ($) {
+ my ($objid) = @_;
+
+ my @p;
+ my $r = parsecommit($objid, \@p);
+ my $t = $r->{Tree};
+
+ foreach my $p (@p) {
+ $p->{Differs} = (get_differs $p->{CommitId}, $t),
+ }
+
+ printdebug "classify $objid \$t=$t \@p",
+ (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
+ "\n";
+
+ my $classify = sub {
+ my ($type, @rest) = @_;
+ $r = { %$r, Type => $type, @rest };
+ if ($debuglevel) {
+ my $dd = new Data::Dumper [ $r ];
+ Terse $dd 1; Indent $dd 0; Useqq $dd 1;
+ printdebug " = $type ".(Dump $dd)."\n";
+ }
+ return $r;
+ };
+ my $unknown = sub {
+ my ($why) = @_;
+ $r = { %$r, Type => qw(Unknown) };
+ printdebug " ** Unknown\n";
+ return $r;
+ };
+
+ if (@p == 1) {
+ my $d = $r->{Parents}[0]{Differs};
+ if ($d == D_PAT_ADD) {
+ return $classify->(qw(AddPatches));
+ } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
+ return $unknown->("edits debian/patches");
+ } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
+ my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
+ if ($ty eq 'tree') {
+ if ($d == D_DEB_CLOG) {
+ return $classify->(qw(Changelog));
+ } else {
+ return $classify->(qw(Packaging));
+ }
+ } elsif ($ty eq 'missing') {
+ return $classify->(qw(BreakwaterStart));
+ } else {
+ return $unknown->("parent's debian is not a directory");
+ }
+ } elsif ($d == D_UPS) {
+ return $classify->(qw(Upstream));
+ } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
+ return $classify->(qw(Mixed));
+ } elsif ($d == 0) {
+ return $unknown->("no changes");
+ } else {
+ confess "internal error $objid ?";
+ }
+ }
+ if (!@p) {
+ return $unknown->("origin commit");
+ }
+
+ my @identical = grep { !$_->{Differs} } @p;
+ if (@p == 2 && @identical == 1) {
+ my @overwritten = grep { $_->{Differs} } @p;
+ confess "internal error $objid ?" unless @overwritten==1;
+ return $classify->(qw(Pseudomerge),
+ Overwritten => $overwritten[0],
+ Contributor => $identical[0]);
+ }
+ if (@p == 2 && @identical == 2) {
+ my @bytime = nsort_by {
+ my ($ph,$pm) = get_commit $_->{CommitId};
+ $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
+ $1;
+ } @p;
+ return $classify->(qw(Pseudomerge),
+ SubType => qw(Ambiguous),
+ Overwritten => $bytime[0],
+ Contributor => $bytime[1]);
+ }
+ foreach my $p (@p) {
+ my ($p_h, $p_m) = get_commit $p->{CommitId};
+ $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
+ ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
+ }
+ my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
+ my $m2 = $r->{Msg};
+ if (!(grep { !$_->{IsOrigin} } @p) and
+ (@orig_ps >= @p - 1) and
+ $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
+ $r->{NewMsg} = $m2;
+ return $classify->(qw(DgitImportUnpatched),
+ OrigParents => \@orig_ps);
+ }
+
+ my ($stype, $series) = git_cat_file "$t:debian/patches/series";
+ my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
+
+ # How to decide about l/r ordering of breakwater merges ? git
+ # --topo-order prefers to expand 2nd parent first. There's
+ # already an easy rune to look for debian/ history anyway (git log
+ # debian/) so debian breakwater branch should be 1st parent; that
+ # way also there's also an easy rune to look for the upstream
+ # patches (--topo-order).
+
+ # The above tells us which way *we* will generate them. But we
+ # might encounter ad-hoc breakwater merges generated manually,
+ # which might be the other way around. In principle, in some odd
+ # situations, a breakwater merge might have two identical parents.
+ # In that case we guess which way round it is (ie, which parent
+ # has the upstream history). The order of the 2-iteration loop
+ # controls which guess we make.
+
+ foreach my $prevbrw (qw(0 1)) {
+ if (@p == 2 &&
+ !$haspatches &&
+ !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
+ !($p[$prevbrw]{Differs} & ~DS_DEB) &&
+ !($p[!$prevbrw]{Differs} & ~D_UPS)) {
+ return $classify->(qw(BreakwaterUpstreamMerge),
+ OrigParents => [ $p[!$prevbrw] ]);
+ }
+ }
+
+ # multi-orig upstreams are represented with a breakwater merge
+ # from a single upstream commit which combines the orig tarballs
+
+ return $unknown->("complex merge");
+}
+
+sub walk ($;$$);
+sub walk ($;$$) {
+ my ($input,
+ $nogenerate,$report) = @_;
+ # => ($tip, $breakwater_tip)
+ # (or nothing, if $nogenerate)