chiark / gitweb /
changelog: start 6.1
[dgit.git] / infra / dgit-repos-server
1 #!/usr/bin/perl -w
2 # dgit-repos-server
3 #
4 # git protocol proxy to check dgit pushes etc.
5 #
6 # Copyright (C) 2014-2016  Ian Jackson
7 #
8 #    This program is free software; you can redistribute it and/or modify
9 #    it under the terms of the GNU General Public License as published by
10 #    the Free Software Foundation; either version 3 of the License, or
11 #    (at your option) any later version.
12 #
13 #    This program is distributed in the hope that it will be useful,
14 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
15 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 #    GNU General Public License for more details.
17 #
18 #    You should have received a copy of the GNU General Public License
19 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
20
21 # usages:
22 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --ssh
23 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --cron
24 # settings
25 #   --repos=GIT-REPOS-DIR      default DISTRO-DIR/repos/
26 #   --suites=SUITES-FILE       default DISTRO-DIR/suites
27 #   --suites-master=SUITES-FILE default DISTRO-DIR/suites-master
28 #   --policy-hook=POLICY-HOOK  default DISTRO-DIR/policy-hook
29 #   --mirror-hook=MIRROR-HOOK  default DISTRO-DIR/mirror-hook
30 #   --dgit-live=DGIT-LIVE-DIR  default DISTRO-DIR/dgit-live
31 # (DISTRO-DIR is not used other than as default and to pass to policy
32 # and mirror hooks)
33 # internal usage:
34 #  .../dgit-repos-server --pre-receive-hook PACKAGE
35 #
36 # Invoked as the ssh restricted command
37 #
38 # Works like git-receive-pack
39 #
40 # SUITES-FILE is the name of a file which lists the permissible suites
41 # one per line (#-comments and blank lines ignored).  For --suites-master
42 # it is a list of the suite(s) which should, when pushed to, update
43 # `master' on the server (if fast forward).
44 #
45 # AUTH-SPEC is a :-separated list of
46 #   KEYRING.GPG,AUTH-SPEC
47 # where AUTH-SPEC is one of
48 #   a
49 #   mDM.TXT
50 # (With --cron AUTH-SPEC is not used and may be the empty string.)
51
52 use strict;
53
54 use Debian::Dgit::Infra; # must precede Debian::Dgit; - can change @INC!
55 use Debian::Dgit qw(:DEFAULT :policyflags);
56 setup_sigwarn();
57
58 # DGIT-REPOS-DIR contains:
59 # git tree (or other object)      lock (in acquisition order, outer first)
60 #
61 #  _tmp/PACKAGE_prospective       ! } SAME.lock, held during receive-pack
62 #
63 #  _tmp/PACKAGE_incoming$$        ! } SAME.lock, held during receive-pack
64 #  _tmp/PACKAGE_incoming$$_fresh  ! }
65 #
66 #  PACKAGE.git                      } PACKAGE.git.lock
67 #  PACKAGE_garbage                  }   (also covers executions of
68 #  PACKAGE_garbage-old              }    policy hook script for PACKAGE)
69 #  PACKAGE_garbage-tmp              }
70 #  policy*                          } (for policy hook script, covered by
71 #                                   }  lock only when invoked for a package)
72 #
73 # leaf locks, held during brief operaton only:
74 #
75 #  _empty                           } SAME.lock
76 #  _empty.new                       }
77 #
78 #  _template                        } SAME.lock
79 #
80 # locks marked ! may be held during client data transfer
81
82 # What we do on push is this:
83 #  - extract the destination repo name
84 #  - make a hardlink clone of the destination repo
85 #  - provide the destination with a stunt pre-receive hook
86 #  - run actual git-receive-pack with that new destination
87 #   as a result of this the stunt pre-receive hook runs; it does this:
88 #    + understand what refs we are allegedly updating and
89 #      check some correspondences:
90 #        * we are updating only refs/tags/[archive/]DISTRO/* and refs/dgit/*
91 #        * and only one of each
92 #        * and the tag does not already exist
93 #      and
94 #        * recover the suite name from the destination refs/dgit/ ref
95 #    + disassemble the signed tag into its various fields and signature
96 #      including:
97 #        * parsing the first line of the tag message to recover
98 #          the package name, version and suite
99 #        * checking that the package name corresponds to the dest repo name
100 #        * checking that the suite name is as recovered above
101 #    + verify the signature on the signed tag
102 #      and if necessary check that the keyid and package are listed in dm.txt
103 #    + check various correspondences:
104 #        * the signed tag must refer to a commit
105 #        * the signed tag commit must be the refs/dgit value
106 #        * the name in the signed tag must correspond to its ref name
107 #        * the tag name must be [archive/]debian/<version> (massaged as needed)
108 #        * the suite is one of those permitted
109 #        * the signed tag has a suitable name
110 #        * run the "push" policy hook
111 #        * replay prevention for --deliberately-not-fast-forward
112 #        * check the commit is a fast forward
113 #        * handle a request from the policy hook for a fresh repo
114 #    + push the signed tag and new dgit branch to the actual repo
115 #
116 # If the destination repo does not already exist, we need to make
117 # sure that we create it reasonably atomically, and also that
118 # we don't every have a destination repo containing no refs at all
119 # (because such a thing causes git-fetch-pack to barf).  So then we
120 # do as above, except:
121 #  - before starting, we take out our own lock for the destination repo
122 #  - we create a prospective new destination repo by making a copy
123 #    of _template
124 #  - we use the prospective new destination repo instead of the
125 #    actual new destination repo (since the latter doesn't exist)
126 #  - after git-receive-pack exits, we
127 #    + check that the prospective repo contains a tag and head
128 #    + rename the prospective destination repo into place
129 #
130 # Cleanup strategy:
131 #  - We are crash-only
132 #  - Temporary working trees and their locks are cleaned up
133 #    opportunistically by a program which tries to take each lock and
134 #    if successful deletes both the tree and the lockfile
135 #  - Prospective working trees and their locks are cleaned up by
136 #    a program which tries to take each lock and if successful
137 #    deletes any prospective working tree and the lock (but not
138 #    of course any actual tree)
139 #  - It is forbidden to _remove_ the lockfile without removing
140 #    the corresponding temporary tree, as the lockfile is also
141 #    a stampfile whose presence indicates that there may be
142 #    cleanup to do
143 #
144 # Policy hook scripts are invoked like this:
145 #   POLICY-HOOK-SCRIPT DISTRO DGIT-REPOS-DIR DGIT-LIVE-DIR DISTRO-DIR ACTION...
146 # ie.
147 #   POLICY-HOOK-SCRIPT ... check-list [...]
148 #   POLICY-HOOK-SCRIPT ... check-package PACKAGE [...]
149 #   POLICY-HOOK-SCRIPT ... push PACKAGE \
150 #         VERSION SUITE TAGNAME DELIBERATELIES [...]
151 #   POLICY-HOOK-SCRIPT ... push-confirm PACKAGE \
152 #         VERSION SUITE TAGNAME DELIBERATELIES FRESH-REPO|'' [...]
153 #
154 # DELIBERATELIES is like this: --deliberately-foo,--deliberately-bar,...
155 #
156 # Exit status of policy hook is a bitmask.
157 # Bit weight constants are defined in Dgit.pm.
158 #    NOFFCHECK   (2)
159 #         suppress dgit-repos-server's fast-forward check ("push" only)
160 #    FRESHREPO   (4)
161 #         blow away repo right away (ie, as if before push or fetch)
162 #         ("check-package" and "push" only)
163 #    NOCOMMITCHECK   (8)
164 #         suppress dgit-repos-server's check that commits do
165 #         not lack "committer" info (eg as produced by #849041)
166 #         ("push" only)
167 # any unexpected bits mean failure, and then known set bits are ignored
168 # if no unexpected bits set, operation continues (subject to meaning
169 # of any expected bits set).  So, eg, exit 0 means "continue normally"
170 # and would be appropriate for an unknown action.
171 #
172 # cwd for push and push-confirm is a temporary repo where the incoming
173 # objects have been received; TAGNAME is the version-based tag.
174 #
175 # FRESH-REPO is '' iff the repo for this package already existed, or
176 # the pathname of the newly-created repo which will be renamed into
177 # place if everything goes well.  (NB that this is generally not the
178 # same repo as the cwd, because the objects are first received into a
179 # temporary repo so they can be examined.)  In this case FRESH-REPO
180 # contains exactly the objects and refs that will appear in the
181 # destination if push-confirm approves.
182
183 # if push requested FRESHREPO, push-confirm happens in the old working
184 # repo and FRESH-REPO is guaranteed not to be ''.
185 #
186 # policy hook for a particular package will be invoked only once at
187 # a time - (see comments about DGIT-REPOS-DIR, above)
188 #
189 # check-list and check-package are invoked via the --cron option.
190 # First, without any locking, check-list is called.  It should produce
191 # a list of package names (one per line).  Then check-package will be
192 # invoked for each named package, in each case after taking an
193 # appropriate lock.
194 #
195 # If policy hook wants to run dgit (or something else in the dgit
196 # package), it should use DGIT-LIVE-DIR/dgit (etc.), or if that is
197 # ENOENT, use the installed version.
198 #
199 # Mirror hook scripts are invoked like this:
200 #   MIRROR-HOOK-SCRIPT DISTRO-DIR ACTION...
201 # and currently there is only one action invoked by dgit-repos-server:
202 #   MIRROR-HOOK-SCRIPT DISTRO-DIR updated-hook PACKAGE [...]
203 #
204 # Exit status of the mirror hook is advisory only.  The mirror hook
205 # runs too late to do anything useful about a problem, so the only
206 # effect of a mirror hook exiting nonzero is a warning message to
207 # stderr (which the pushing user should end up seeing).
208 #
209 # If the mirror hook does not exist, it is silently skipped.
210
211 use POSIX;
212 use Fcntl qw(:flock);
213 use File::Path qw(rmtree);
214 use File::Temp qw(tempfile);
215
216 initdebug('');
217
218 our $func;
219 our $dgitrepos;
220 our $package;
221 our $distro;
222 our $suitesfile;
223 our $suitesformasterfile;
224 our $policyhook;
225 our $mirrorhook;
226 our $dgitlive;
227 our $distrodir;
228 our $destrepo;
229 our $workrepo;
230 our $keyrings;
231 our @lockfhs;
232
233 our @deliberatelies;
234 our %previously;
235 our $policy;
236 our @policy_args;
237
238 #----- utilities -----
239
240 sub realdestrepo () { "$dgitrepos/$package.git"; }
241
242 sub acquirelock ($$) {
243     my ($lock, $must) = @_;
244     my $fh;
245     printdebug sprintf "locking %s %d\n", $lock, $must;
246     for (;;) {
247         close $fh if $fh;
248         $fh = new IO::File $lock, ">" or die "open $lock: $!";
249         my $ok = flock $fh, $must ? LOCK_EX : (LOCK_EX|LOCK_NB);
250         if (!$ok) {
251             die "flock $lock: $!" if $must;
252             printdebug " locking $lock failed\n";
253             return undef;
254         }
255         next unless stat_exists $lock;
256         my $want = (stat _)[1];
257         stat $fh or die $!;
258         my $got = (stat _)[1];
259         last if $got == $want;
260     }
261     return $fh;
262 }
263
264 sub acquirermtree ($$) {
265     my ($tree, $must) = @_;
266     my $fh = acquirelock("$tree.lock", $must);
267     if ($fh) {
268         push @lockfhs, $fh;
269         rmtree $tree;
270     }
271     return $fh;
272 }
273
274 sub locksometree ($) {
275     my ($tree) = @_;
276     acquirelock("$tree.lock", 1);
277 }
278
279 sub lockrealtree () {
280     locksometree(realdestrepo);
281 }
282
283 sub mkrepotmp () { ensuredir "$dgitrepos/_tmp" };
284
285 sub removedtagsfile () { "$dgitrepos/_removed-tags/$package"; }
286
287 sub recorderror ($) {
288     my ($why) = @_;
289     my $w = $ENV{'DGIT_DRS_WORK'}; # we are in stunthook
290     if (defined $w) {
291         chomp $why;
292         open ERR, ">", "$w/drs-error" or die $!;
293         print ERR $why, "\n" or die $!;
294         close ERR or die $!;
295         return 1;
296     }
297     return 0;
298 }
299
300 sub reject ($) {
301     my ($why) = @_;
302     recorderror "reject: $why";
303     die "\ndgit-repos-server: reject: $why\n\n";
304 }
305
306 sub policyhook {
307     my ($policyallowbits, @polargs) = @_;
308     # => ($exitstatuspolicybitmap);
309     die if $policyallowbits & ~0x3e;
310     my @cmd = ($policyhook,$distro,$dgitrepos,$dgitlive,$distrodir,@polargs);
311     debugcmd '+M',@cmd;
312     my $r = system @cmd;
313     die "system: $!" if $r < 0;
314     die "dgit-repos-server: policy hook failed (or rejected) ($?)\n"
315         if $r & ~($policyallowbits << 8);
316     printdebug sprintf "hook => %#x\n", $r;
317     return $r >> 8;
318 }
319
320 sub mkemptyrepo ($$) {
321     my ($dir,$sharedperm) = @_;
322     runcmd qw(git init --bare --quiet), "--shared=$sharedperm", $dir;
323 }
324
325 sub mkrepo_fromtemplate ($) {
326     my ($dir) = @_;
327     my $template = "$dgitrepos/_template";
328     my $templatelock = locksometree($template);
329     printdebug "copy template $template -> $dir\n";
330     my $r = system qw(cp -a --), $template, $dir;
331     !$r or die "create new repo $dir failed: $r $!";
332     close $templatelock;
333 }
334
335 sub movetogarbage () {
336     # realdestrepo must have been locked
337
338     my $real = realdestrepo;
339     return unless stat_exists $real;
340
341     my $garbagerepo = "$dgitrepos/${package}_garbage";
342     # We arrange to always keep at least one old tree, for recovery
343     # from mistakes.  This is either $garbage or $garbage-old.
344     if (stat_exists "$garbagerepo") {
345         printdebug "movetogarbage: rmtree $garbagerepo-tmp\n";
346         rmtree "$garbagerepo-tmp";
347         if (rename "$garbagerepo-old", "$garbagerepo-tmp") {
348             printdebug "movetogarbage: $garbagerepo-old -> -tmp, rmtree\n";
349             rmtree "$garbagerepo-tmp";
350         } else {
351             die "$garbagerepo $!" unless $!==ENOENT;
352             printdebug "movetogarbage: $garbagerepo-old -> -tmp\n";
353         }
354         printdebug "movetogarbage: $garbagerepo -> -old\n";
355         rename "$garbagerepo", "$garbagerepo-old" or die "$garbagerepo $!";
356     }
357
358     ensuredir "$dgitrepos/_removed-tags";
359     open PREVIOUS, ">>", removedtagsfile or die removedtagsfile." $!";
360     git_for_each_ref([ map { 'refs/tags/'.$_ } debiantags('*',$distro) ],
361                      sub {
362         my ($objid,$objtype,$fullrefname,$reftail) = @_;
363         print PREVIOUS "\n$objid $reftail .\n" or die $!;
364     }, $real);
365     close PREVIOUS or die $!;
366
367     printdebug "movetogarbage: $real -> $garbagerepo\n";
368     rename $real, $garbagerepo
369         or $! == ENOENT
370         or die "$garbagerepo $!";
371 }
372
373 sub policy_checkpackage () {
374     my $lfh = lockrealtree();
375
376     $policy = policyhook(FRESHREPO,'check-package',$package);
377     if ($policy & FRESHREPO) {
378         movetogarbage();
379     }
380
381     close $lfh;
382 }
383
384 #----- git-receive-pack -----
385
386 sub fixmissing__git_receive_pack () {
387     mkrepotmp();
388     $destrepo = "$dgitrepos/_tmp/${package}_prospective";
389     acquirermtree($destrepo, 1);
390     mkrepo_fromtemplate($destrepo);
391 }
392
393 sub makeworkingclone () {
394     mkrepotmp();
395     $workrepo = "$dgitrepos/_tmp/${package}_incoming$$";
396     acquirermtree($workrepo, 1);
397     my $lfh = lockrealtree();
398     runcmd qw(git clone -l -q --mirror), $destrepo, $workrepo;
399     close $lfh;
400     rmtree "${workrepo}_fresh";
401 }
402
403 sub mkscript ($$) {
404     my ($path,$contents) = @_;
405     my $fh = new IO::File $path, O_WRONLY|O_CREAT|O_TRUNC, 0777
406         or die "$path: $!";
407     print $fh $contents or die "$path: $!";
408     close $fh or die "$path: $!";
409 }
410
411 sub setupstunthook () {
412     my $prerecv = "$workrepo/hooks/pre-receive";
413     mkscript $prerecv, <<END;
414 #!/bin/sh
415 set -e
416 exec $0 --pre-receive-hook $package
417 END
418     $ENV{'DGIT_DRS_WORK'}= $workrepo;
419     $ENV{'DGIT_DRS_DEST'}= $destrepo;
420     printdebug " stunt hook set up $prerecv\n";
421 }
422
423 sub dealwithfreshrepo () {
424     my $freshrepo = "${workrepo}_fresh";
425     return unless stat_exists $freshrepo;
426     $destrepo = $freshrepo;
427 }
428
429 sub mirrorhook {
430     my @cmd = ($mirrorhook,$distrodir,@_);
431     debugcmd '+',@cmd;
432     return unless stat_exists $mirrorhook;
433     my $r = system @cmd;
434     if ($r) {
435         printf STDERR <<END,
436 dgit-repos-server: warning: mirror hook failed: %s
437 dgit-repos-server: push complete but may not fully visible.
438 END
439             ($r < 0 ? "exec: $!" :
440              $r == (124 << 8) ? "exited status 124 (timeout?)" :
441              !($r & ~0xff00) ? "exited ".($? >> 8) :
442              "wait status $?");
443     }
444 }
445
446 sub maybeinstallprospective () {
447     return if $destrepo eq realdestrepo;
448
449     if (open REJ, "<", "$workrepo/drs-error") {
450         local $/ = undef;
451         my $msg = <REJ>;
452         REJ->error and die $!;
453         print STDERR $msg;
454         exit 1;
455     } else {
456         $!==&ENOENT or die $!;
457     }
458
459     printdebug " show-ref ($destrepo) ...\n";
460
461     my $child = open SR, "-|";
462     defined $child or die $!;
463     if (!$child) {
464         chdir $destrepo or die $!;
465         exec qw(git show-ref);
466         die $!;
467     }
468     my %got = qw(newtag 0 omtag 0 head 0);
469     while (<SR>) {
470         chomp or die;
471         printdebug " show-refs| $_\n";
472         s/^\S*[1-9a-f]\S* (\S+)$/$1/ or die;
473         next if m{^refs/heads/master$};
474         my $wh =
475             m{^refs/tags/archive/} ? 'newtag' :
476             m{^refs/tags/} ? 'omtag' :
477             m{^refs/dgit/} ? 'head' :
478             die;
479         use Data::Dumper;
480         die if $got{$wh}++;
481     }
482     $!=0; $?=0; close SR or $?==256 or die "$? $!";
483
484     printdebug "installprospective ?\n";
485     die Dumper(\%got)." -- missing refs in new repo"
486         unless $got{head} && grep { m/tag$/ && $got{$_} } keys %got;
487
488     lockrealtree();
489
490     if ($destrepo eq "${workrepo}_fresh") {
491         movetogarbage;
492     }
493
494     printdebug "install $destrepo => ".realdestrepo."\n";
495     rename $destrepo, realdestrepo or die $!;
496     remove realdestrepo.".lock" or die $!;
497 }
498
499 sub main__git_receive_pack () {
500     makeworkingclone();
501     setupstunthook();
502     runcmd qw(git receive-pack), $workrepo;
503     dealwithfreshrepo();
504     maybeinstallprospective();
505     mirrorhook('updated-hook', $package);
506 }
507
508 #----- stunt post-receive hook -----
509
510 our ($tagname, $tagval, $suite, $oldcommit, $commit);
511 our ($version, %tagh);
512 our ($maint_tagname, $maint_tagval);
513
514 our ($tagexists_error);
515
516 sub readupdates () {
517     printdebug " updates ...\n";
518     my %tags;
519     while (<STDIN>) {
520         chomp or die;
521         printdebug " upd.| $_\n";
522         m/^(\S+) (\S+) (\S+)$/ or die "$_ ?";
523         my ($old, $sha1, $refname) = ($1, $2, $3);
524         if ($refname =~ m{^refs/tags/(?=(?:archive/)?$distro/)}) {
525             my $tn = $'; #';
526             $tags{$tn} = $sha1;
527             $tagexists_error= "tag $tn already exists -".
528                 " not replacing previously-pushed version"
529                 if $old =~ m/[^0]/;
530         } elsif ($refname =~ m{^refs/dgit/}) {
531             reject "pushing multiple heads!" if defined $suite;
532             $suite = $'; #';
533             $oldcommit = $old;
534             $commit = $sha1;
535         } else {
536             reject "pushing unexpected ref!";
537         }
538     }
539     STDIN->error and die $!;
540
541     reject "push is missing tag ref update" unless %tags;
542     my @newtags = grep { m#^archive/# } keys %tags;
543     my @omtags = grep { !m#^archive/# } keys %tags;
544     reject "pushing too many similar tags" if @newtags>1 || @omtags>1;
545     if (@newtags) {
546         ($tagname) = @newtags;
547         ($maint_tagname) = @omtags;
548     } else {
549         ($tagname) = @omtags or die;
550     }
551     $tagval = $tags{$tagname};
552     $maint_tagval = $tags{$maint_tagname // ''};
553
554     reject "push is missing head ref update" unless defined $suite;
555     printdebug " updates ok.\n";
556 }
557
558 sub parsetag () {
559     printdebug " parsetag...\n";
560     open PT, ">dgit-tmp/plaintext" or die $!;
561     open DS, ">dgit-tmp/plaintext.asc" or die $!;
562     open T, "-|", qw(git cat-file tag), $tagval or die $!;
563     for (;;) {
564         $!=0; $_=<T>; defined or die $!;
565         print PT or die $!;
566         if (m/^(\S+) (.*)/) {
567             push @{ $tagh{$1} }, $2;
568         } elsif (!m/\S/) {
569             last;
570         } else {
571             die;
572         }
573     }
574     $!=0; $_=<T>; defined or die $!;
575     m/^($package_re) release (\S+) for \S+ \((\S+)\) \[dgit\]$/ or
576         reject "tag message not in expected format";
577
578     die unless $1 eq $package;
579     $version = $2;
580     die "$3 != $suite " unless $3 eq $suite;
581
582     my $copyl = $_;
583     for (;;) {
584         print PT $copyl or die $!;
585         $!=0; $_=<T>; defined or die "missing signature? $!";
586         $copyl = $_;
587         if (m/^\[dgit ([^"].*)\]$/) { # [dgit "something"] is for future
588             $_ = $1." ";
589             while (length) {
590                 if (s/^distro\=(\S+) //) {
591                     die "$1 != $distro" unless $1 eq $distro;
592                 } elsif (s/^(--deliberately-$deliberately_re) //) {
593                     push @deliberatelies, $1;
594                 } elsif (s/^previously:(\S+)=(\w+) //) {
595                     die "previously $1 twice" if defined $previously{$1};
596                     $previously{$1} = $2;
597                 } elsif (s/^[-+.=0-9a-z]\S* //) {
598                 } else {
599                     die "unknown dgit info in tag ($_)";
600                 }
601             }
602             next;
603         }
604         last if m/^-----BEGIN PGP/;
605     }
606     $_ = $copyl;
607     for (;;) {
608         print DS or die $!;
609         $!=0; $_=<T>;
610         last if !defined;
611     }
612     T->error and die $!;
613     close PT or die $!;
614     close DS or die $!;
615     printdebug " parsetag ok.\n";
616 }
617
618 sub checksig_keyring ($) {
619     my ($keyringfile) = @_;
620     # returns primary-keyid if signed by a key in this keyring
621     # or undef if not
622     # or dies on other errors
623
624     my $ok = undef;
625
626     printdebug " checksig keyring $keyringfile...\n";
627
628     our @cmd = (qw(gpgv --status-fd=1 --keyring),
629                    $keyringfile,
630                    qw(dgit-tmp/plaintext.asc dgit-tmp/plaintext));
631     debugcmd '|',@cmd;
632
633     open P, "-|", @cmd
634         or die $!;
635
636     while (<P>) {
637         next unless s/^\[GNUPG:\] //;
638         chomp or die;
639         printdebug " checksig| $_\n";
640         my @l = split / /, $_;
641         if ($l[0] eq 'NO_PUBKEY') {
642             last;
643         } elsif ($l[0] eq 'VALIDSIG') {
644             my $sigtype = $l[9];
645             $sigtype eq '00' or reject "signature is not of type 00!";
646             $ok = $l[10];
647             die unless defined $ok;
648             last;
649         }
650     }
651     close P;
652
653     printdebug sprintf " checksig ok=%d\n", !!$ok;
654
655     return $ok;
656 }
657
658 sub dm_txt_check ($$) {
659     my ($keyid, $dmtxtfn) = @_;
660     printdebug " dm_txt_check $keyid $dmtxtfn\n";
661     open DT, '<', $dmtxtfn or die "$dmtxtfn $!";
662     while (<DT>) {
663         m/^fingerprint:\s+\Q$keyid\E$/oi
664             ..0 or next;
665         if (s/^allow:/ /i..0) {
666         } else {
667             m/^./
668                 or reject "key $keyid missing Allow section in permissions!";
669             next;
670         }
671         # in right stanza...
672         s/^[ \t]+//
673             or reject "package $package not allowed for key $keyid";
674         # in allow field...
675         s/\([^()]+\)//;
676         s/\,//;
677         chomp or die;
678         printdebug " dm_txt_check allow| $_\n";
679         foreach my $p (split /\s+/) {
680             if ($p eq $package) {
681                 # yay!
682                 printdebug " dm_txt_check ok\n";
683                 return;
684             }
685         }
686     }
687     DT->error and die $!;
688     close DT or die $!;
689     reject "key $keyid not in permissions list although in keyring!";
690 }
691
692 sub verifytag () {
693     foreach my $kas (split /:/, $keyrings) {
694         printdebug "verifytag $kas...\n";
695         $kas =~ s/^([^,]+),// or die;
696         my $keyid = checksig_keyring $1;
697         if (defined $keyid) {
698             if ($kas =~ m/^a$/) {
699                 printdebug "verifytag a ok\n";
700                 return; # yay
701             } elsif ($kas =~ m/^m([^,]+)$/) {
702                 dm_txt_check($keyid, $1);
703                 printdebug "verifytag m ok\n";
704                 return;
705             } else {
706                 die;
707             }
708         }   
709     }
710     reject "key not found in keyrings";
711 }
712
713 sub suite_is_in ($) {
714     my ($sf) = @_;
715     printdebug "suite_is_in ($sf)\n";
716     if (!open SUITES, "<", $sf) {
717         $!==ENOENT or die $!;
718         return 0;
719     }
720     while (<SUITES>) {
721         chomp;
722         next unless m/\S/;
723         next if m/^\#/;
724         s/\s+$//;
725         return 1 if $_ eq $suite;
726     }
727     die $! if SUITES->error;
728     return 0;
729 }
730
731 sub checksuite () {
732     printdebug "checksuite ($suitesfile)\n";
733     return if suite_is_in $suitesfile;
734     reject "unknown suite";
735 }
736
737 sub checktagnoreplay () {
738     # We need to prevent a replay attack using an earlier signed tag.
739     # We also want to archive in the history the object ids of
740     # anything we remove, even if we get rid of the actual objects.
741     #
742     # So, we check that the signed tag mentions the name and tag
743     # object id of:
744     #
745     # (a) In the case of FRESHREPO: all tags and refs/heads/* in
746     #     the repo.  That is, effectively, all the things we are
747     #     deleting.
748     #
749     #     This prevents any tag implying a FRESHREPO push
750     #     being replayed into a different state of the repo.
751     #
752     #     There is still the folowing risk: If a non-ff push is of a
753     #     head which is an ancestor of a previous ff-only push, the
754     #     previous push can be replayed.
755     #
756     #     So we keep a separate list, as a file in the repo, of all
757     #     the tag object ids we have ever seen and removed.  Any such
758     #     tag object id will be rejected even for ff-only pushes.
759     #
760     # (b) In the case of just NOFFCHECK: all tags referring to the
761     #     current head for the suite (there must be at least one).
762     #
763     #     This prevents any tag implying a NOFFCHECK push being
764     #     replayed to rewind from a different head.
765     #
766     #     The possibility of an earlier ff-only push being replayed is
767     #     eliminated as follows: the tag from such a push would still
768     #     be in our repo, and therefore the replayed push would be
769     #     rejected because the set of refs being updated would be
770     #     wrong.
771
772     if (!open PREVIOUS, "<", removedtagsfile) {
773         die removedtagsfile." $!" unless $!==ENOENT;
774     } else {
775         # Protocol for updating this file is to append to it, not
776         # write-new-and-rename.  So all updates are prefixed with \n
777         # and suffixed with " .\n" so that partial writes can be
778         # ignored.
779         while (<PREVIOUS>) {
780             next unless m/^(\w+) (.*) \.\n/;
781             next unless $1 eq $tagval;
782             reject "Replay of previously-rewound upload ($tagval $2)";
783         }
784         die removedtagsfile." $!" if PREVIOUS->error;
785         close PREVIOUS;
786     }
787
788     return unless $policy & (FRESHREPO|NOFFCHECK);
789
790     my $garbagerepo = "$dgitrepos/${package}_garbage";
791     lockrealtree();
792
793     my $nchecked = 0;
794     my @problems;
795
796     my $check_ref_previously= sub {
797         my ($objid,$objtype,$fullrefname,$reftail) = @_;
798         my $supkey = $fullrefname;
799         $supkey =~ s{^refs/}{} or die "$supkey $objid ?";
800         my $supobjid = $previously{$supkey};
801         if (!defined $supobjid) {
802             printdebug "checktagnoreply - missing\n";
803             push @problems, "does not declare previously $supkey";
804         } elsif ($supobjid ne $objid) {
805             push @problems, "declared previously $supkey=$supobjid".
806                 " but actually previously $supkey=$objid";
807         } else {
808             $nchecked++;
809         }
810     };
811
812     if ($policy & FRESHREPO) {
813         foreach my $kind (qw(tags heads)) {
814             git_for_each_ref("refs/$kind", $check_ref_previously);
815         }
816     } else {
817         my $branch= server_branch($suite);
818         my $branchhead= git_get_ref(server_ref($suite));
819         if (!length $branchhead) {
820             # No such branch - NOFFCHECK was unnecessary.  Oh well.
821             printdebug "checktagnoreplay - not FRESHREPO, new branch, ok\n";
822         } else {
823             printdebug "checktagnoreplay - not FRESHREPO,".
824                 " checking for overwriting refs/$branch=$branchhead\n";
825             git_for_each_tag_referring($branchhead, sub {
826                 my ($tagobjid,$refobjid,$fullrefname,$tagname) = @_;
827                 $check_ref_previously->($tagobjid,undef,$fullrefname,undef);
828             });
829             printdebug "checktagnoreplay - not FRESHREPO, nchecked=$nchecked";
830             push @problems, "does not declare previously any tag".
831                 " referring to branch head $branch=$branchhead"
832                 unless $nchecked;
833         }
834     }
835
836     if (@problems) {
837         reject "replay attack prevention check failed:".
838             " signed tag for $version: ".
839             join("; ", @problems).
840             "\n";
841     }
842     printdebug "checktagnoreplay - all ok ($tagval)\n"
843 }
844
845 sub tagh1 ($) {
846     my ($tag) = @_;
847     my $vals = $tagh{$tag};
848     reject "missing header $tag in signed tag object" unless $vals;
849     reject "multiple headers $tag in signed tag object" unless @$vals == 1;
850     return $vals->[0];
851 }
852
853 sub checks () {
854     printdebug "checks\n";
855
856     tagh1('type') eq 'commit' or reject "tag refers to wrong kind of object";
857     tagh1('object') eq $commit or reject "tag refers to wrong commit";
858     tagh1('tag') eq $tagname or reject "tag name in tag is wrong";
859
860     my @expecttagnames = debiantags($version, $distro);
861     printdebug "expected tag @expecttagnames\n";
862     grep { $tagname eq $_ } @expecttagnames or die;
863
864     foreach my $othertag (grep { $_ ne $tagname } @expecttagnames) {
865         reject "tag $othertag (pushed with differing dgit version)".
866             " already exists -".
867             " not replacing previously-pushed version"
868             if git_get_ref "refs/tags/".$othertag;
869     }
870
871     lockrealtree();
872
873     @policy_args = ($package,$version,$suite,$tagname,
874                     join(",",@deliberatelies));
875     $policy = policyhook(NOFFCHECK|FRESHREPO|NOCOMMITCHECK, 'push', @policy_args);
876
877     if (defined $tagexists_error) {
878         if ($policy & FRESHREPO) {
879             printdebug "ignoring tagexists_error: $tagexists_error\n";
880         } else {
881             reject $tagexists_error;
882         }
883     }
884
885     checktagnoreplay();
886     checksuite();
887
888     # check that our ref is being fast-forwarded
889     printdebug "oldcommit $oldcommit\n";
890     if (!($policy & NOFFCHECK) && $oldcommit =~ m/[^0]/) {
891         $?=0; $!=0; my $mb = `git merge-base $commit $oldcommit`;
892         chomp $mb;
893         $mb eq $oldcommit or reject "not fast forward on dgit branch";
894     }
895
896     # defend against commits generated by #849041
897     if (!($policy & NOCOMMITCHECK)) {
898         my @checks = qw(%at
899                         %ct);
900         my @chk = qw(git log -z);
901         push @chk, '--pretty=tformat:%H%n'.
902             (join "", map { $_, '%n' } @checks);
903         push @chk, "^$oldcommit" if $oldcommit =~ m/[^0]/;
904         push @chk, $commit;;
905         printdebug " ~NOCOMMITCHECK @chk\n";
906         open CHK, "-|", @chk or die $!;
907         local $/ = "\0";
908         while (<CHK>) {
909             next unless m/^$/m;
910             m/^\w+(?=\n)/ or die;
911             reject "corrupted object $& (missing metadata)";
912         }
913         $!=0; $?=0; close CHK or $?==256 or die "$? $!";
914     }
915
916     if ($policy & FRESHREPO) {
917         # It's a bit late to be discovering this here, isn't it ?
918         #
919         # What we do is: Generate a fresh destination repo right now,
920         # and arrange to treat it from now on as if it were a
921         # prospective repo.
922         #
923         # The presence of this fresh destination repo is detected by
924         # the parent, which responds by making a fresh master repo
925         # from the template.  (If the repo didn't already exist then
926         # $destrepo was _prospective, and we change it here.  This is
927         # OK because the parent's check for _fresh persuades it not to
928         # use _prospective.)
929         #
930         $destrepo = "${workrepo}_fresh"; # workrepo lock covers
931         mkrepo_fromtemplate $destrepo;
932     }
933 }
934
935 sub onwardpush () {
936     my @cmdbase = (qw(git send-pack), $destrepo);
937     push @cmdbase, qw(--force) if $policy & NOFFCHECK;
938
939     if ($ENV{GIT_QUARANTINE_PATH}) {
940         my $recv_wrapper = "$ENV{GIT_QUARANTINE_PATH}/dgit-recv-wrapper";
941         mkscript $recv_wrapper, <<'END';
942 #!/bin/sh
943 set -e
944 unset GIT_QUARANTINE_PATH
945 exec git receive-pack "$@"
946 END
947         push @cmdbase, "--receive-pack=$recv_wrapper";
948     }
949
950     my @cmd = @cmdbase;
951     push @cmd, "$commit:refs/dgit/$suite",
952                "$tagval:refs/tags/$tagname";
953     push @cmd, "$maint_tagval:refs/tags/$maint_tagname"
954         if defined $maint_tagname;
955     debugcmd '+',@cmd;
956     $!=0;
957     my $r = system @cmd;
958     !$r or die "onward push to $destrepo failed: $r $!";
959
960     if (suite_is_in $suitesformasterfile) {
961         @cmd = @cmdbase;
962         push @cmd, "$commit:refs/heads/master";
963         debugcmd '+', @cmd;
964         $!=0; my $r = system @cmd;
965         # tolerate errors (might be not ff)
966         !($r & ~0xff00) or die
967             "onward push to $destrepo#master failed: $r $!";
968     }
969 }
970
971 sub finalisepush () {
972     if ($destrepo eq realdestrepo) {
973         policyhook(0, 'push-confirm', @policy_args, '');
974         onwardpush();
975     } else {
976         # We are to receive the push into a new repo (perhaps
977         # because the policy push hook asked us to with FRESHREPO, or
978         # perhaps because the repo didn't exist before).
979         #
980         # We want to provide the policy push-confirm hook with a repo
981         # which looks like the one which is going to be installed.
982         # The working repo is no good because it might contain
983         # previous history.
984         #
985         # So we push the objects into the prospective new repo right
986         # away.  If the hook declines, we decline, and the prospective
987         # repo is never installed.
988         onwardpush();
989         policyhook(0, 'push-confirm', @policy_args, $destrepo);
990     }
991 }
992
993 sub stunthook () {
994     printdebug "stunthook in $workrepo\n";
995     chdir $workrepo or die "chdir $workrepo: $!";
996     mkdir "dgit-tmp" or $!==EEXIST or die $!;
997     readupdates();
998     parsetag();
999     verifytag();
1000     checks();
1001     finalisepush();
1002     printdebug "stunthook done.\n";
1003 }
1004
1005 #----- git-upload-pack -----
1006
1007 sub fixmissing__git_upload_pack () {
1008     $destrepo = "$dgitrepos/_empty";
1009     my $lfh = locksometree($destrepo);
1010     return if stat_exists $destrepo;
1011     rmtree "$destrepo.new";
1012     mkemptyrepo "$destrepo.new", "0644";
1013     rename "$destrepo.new", $destrepo or die $!;
1014     unlink "$destrepo.lock" or die $!;
1015     close $lfh;
1016 }
1017
1018 sub main__git_upload_pack () {
1019     my $lfh = locksometree($destrepo);
1020     printdebug "git-upload-pack in $destrepo\n";
1021     chdir $destrepo or die "$destrepo: $!";
1022     close $lfh;
1023     runcmd qw(git upload-pack), ".";
1024 }
1025
1026 #----- arg parsing and main program -----
1027
1028 sub argval () {
1029     die unless @ARGV;
1030     my $v = shift @ARGV;
1031     die if $v =~ m/^-/;
1032     return $v;
1033 }
1034
1035 our %indistrodir = (
1036     # keys are used for DGIT_DRS_XXX too
1037     'repos' => \$dgitrepos,
1038     'suites' => \$suitesfile,
1039     'suites-master' => \$suitesformasterfile,
1040     'policy-hook' => \$policyhook,
1041     'mirror-hook' => \$mirrorhook,
1042     'dgit-live' => \$dgitlive,
1043     );
1044
1045 our @hookenvs = qw(distro suitesfile suitesformasterfile policyhook
1046                    mirrorhook dgitlive keyrings dgitrepos distrodir);
1047
1048 # workrepo and destrepo handled ad-hoc
1049
1050 sub mode_ssh () {
1051     die if @ARGV;
1052
1053     my $cmd = $ENV{'SSH_ORIGINAL_COMMAND'};
1054     $cmd =~ m{
1055         ^
1056         (?: \S* / )?
1057         ( [-0-9a-z]+ )
1058         \s+
1059         '? (?: \S* / )?
1060         ($package_re) \.git
1061         '?$
1062     }ox 
1063     or reject "command string not understood";
1064     my $method = $1;
1065     $package = $2;
1066
1067     my $funcn = $method;
1068     $funcn =~ y/-/_/;
1069     my $mainfunc = $main::{"main__$funcn"};
1070
1071     reject "unknown method" unless $mainfunc;
1072
1073     policy_checkpackage();
1074
1075     if (stat_exists realdestrepo) {
1076         $destrepo = realdestrepo;
1077     } else {
1078         printdebug " fixmissing $funcn\n";
1079         my $fixfunc = $main::{"fixmissing__$funcn"};
1080         &$fixfunc;
1081     }
1082
1083     printdebug " running main $funcn\n";
1084     &$mainfunc;
1085 }
1086
1087 sub mode_cron () {
1088     die if @ARGV;
1089
1090     my $listfh = tempfile();
1091     open STDOUT, ">&", $listfh or die $!;
1092     policyhook(0,'check-list');
1093     open STDOUT, ">&STDERR" or die $!;
1094
1095     seek $listfh, 0, 0 or die $!;
1096     while (<$listfh>) {
1097         chomp or die;
1098         next if m/^\s*\#/;
1099         next unless m/\S/;
1100         die unless m/^($package_re)$/;
1101         
1102         $package = $1;
1103         policy_checkpackage();
1104     }
1105     die $! if $listfh->error;
1106 }    
1107
1108 sub parseargsdispatch () {
1109     die unless @ARGV;
1110
1111     delete $ENV{'GIT_DIR'}; # if not run via ssh, our parent git process
1112     delete $ENV{'GIT_PREFIX'}; # sets these and they mess things up
1113
1114     if ($ENV{'DGIT_DRS_DEBUG'}) {
1115         enabledebug();
1116     }
1117
1118     if ($ARGV[0] eq '--pre-receive-hook') {
1119         if ($debuglevel) {
1120             $debugprefix.="=";
1121             printdebug "in stunthook ".(shellquote @ARGV)."\n";
1122             foreach my $k (sort keys %ENV) {
1123                 printdebug "$k=$ENV{$k}\n" if $k =~  m/^DGIT/;
1124             }
1125         }
1126         shift @ARGV;
1127         @ARGV == 1 or die;
1128         $package = shift @ARGV;
1129         ${ $main::{$_} } = $ENV{"DGIT_DRS_\U$_"} foreach @hookenvs;
1130         defined($workrepo = $ENV{'DGIT_DRS_WORK'}) or die;
1131         defined($destrepo = $ENV{'DGIT_DRS_DEST'}) or die;
1132         open STDOUT, ">&STDERR" or die $!;
1133         eval {
1134             stunthook();
1135         };
1136         if ($@) {
1137             recorderror "$@" or die;
1138             die $@;
1139         }
1140         exit 0;
1141     }
1142
1143     $distro    = argval();
1144     $distrodir = argval();
1145     $keyrings  = argval();
1146
1147     foreach my $dk (keys %indistrodir) {
1148         ${ $indistrodir{$dk} } = "$distrodir/$dk";
1149     }
1150
1151     while (@ARGV && $ARGV[0] =~ m/^--([-0-9a-z]+)=/ && $indistrodir{$1}) {
1152         ${ $indistrodir{$1} } = $'; #';
1153         shift @ARGV;
1154     }
1155
1156     $ENV{"DGIT_DRS_\U$_"} = ${ $main::{$_} } foreach @hookenvs;
1157
1158     die unless @ARGV==1;
1159
1160     my $mode = shift @ARGV;
1161     die unless $mode =~ m/^--(\w+)$/;
1162     my $fn = ${*::}{"mode_$1"};
1163     die unless $fn;
1164     $fn->();
1165 }
1166
1167 sub unlockall () {
1168     while (my $fh = pop @lockfhs) { close $fh; }
1169 }
1170
1171 sub cleanup () {
1172     unlockall();
1173     if (!chdir "$dgitrepos/_tmp") {
1174         $!==ENOENT or die $!;
1175         return;
1176     }
1177     foreach my $lf (<*.lock>) {
1178         my $tree = $lf;
1179         $tree =~ s/\.lock$//;
1180         next unless acquirermtree($tree, 0);
1181         remove $lf or warn $!;
1182         unlockall();
1183     }
1184 }
1185
1186 parseargsdispatch();
1187 cleanup();