git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # usages:
  23 #
  24 #    git-debrebase [<options>] new-upstream-v0 \
  25 #             <new-version> <orig-commitish> \
  26 #            [<extra-orig-name> <extra-orig-commitish> ...] \
  27 #            [<git-rebase options>...]
  28 #
  29 #    git-debrebase [<options> --] [<git-rebase options...>]
  30 #    git-debrebase [<options>] analyse
  31 #    git-debrebase [<options>] launder         # prints breakwater tip etc.
  32 #    git-debrebase [<options>] downstream-rebase-launder-v0  # experimental
  33 #
  34 #    git-debrebase [<options>] gbp2debrebase-v0 \
  35 #             <upstream>
  36
  37 # problems / outstanding questions:
  38 #
  39 #  *  dgit push with a `3.0 (quilt)' package means doing quilt
  40 #     fixup.  Usually this involves recommitting the whole patch
  41 #     series, one at a time, with dpkg-source --commit.  This is
  42 #     terribly terribly slow.  (Maybe this should be fixed in dgit.)
  43 #
  44 #  * dgit push usually needs to (re)make a pseudomerge.  The "first"
  45 #    git-debrebase stripped out the previous pseudomerge and could
  46 #    have remembeed the HEAD.  But it's not quite clear what history
  47 #    ought to be preserved and what should be discarded.  For now
  48 #    the user will have to tell dgit --overwrite.
  49 #
  50 #    To fix this, do we need a new push hook for dgit ?
  51 #
  52 #  * Workflow is currently clumsy.  Lots of spurious runes to type.
  53 #    There's not even a guide.
  54 #
  55 #  * There are no tests.
  56 #
  57 #  * new-upstream-v0 has a terrible UI.  You end up with giant
  58 #    runic command lines.
  59 #
  60 #    One consequence of the lack of richness it can need --force in
  61 #    fairly sensible situations and there is no way to tell it what
  62 #    you are really trying to do, other than just --force.  There
  63 #    should be an interface with some default branch names.
  64 #
  65 #  * There should be a standard convention for the version number,
  66 #    and unfinalised or not changelog, after new-upstream.
  67 #
  68 #  * Handing of multi-orig dgit new-upstream .dsc imports is known to
  69 #    be broken.  They may be not recognised, improperly converted, or
  70 #    their conversion may be unrecognised.
  71 #
  72 #  * Docs need writing and updating.  Even README.git-debrebase
  73 #    describes a design but may not reflect the implementation.
  74 #
  75 #  * We need to develop a plausible model that works for derivatives,
  76 #    who probably want to maintain their stack on top of Debian's.
  77 #    downstream-rebase-launder-v0 may be a starting point?
  78
  79 use strict;
  80
  81 use Debian::Dgit qw(:DEFAULT :playground);
  82 setup_sigwarn();
  83
  84 use Memoize;
  85 use Carp;
  86 use POSIX;
  87 use Data::Dumper;
  88 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  89 use Dpkg::Version;
  90
  91 our ($opt_force);
  92
  93 sub badusage ($) {
  94     my ($m) = @_;
  95     die "bad usage: $m\n";
  96 }
  97
  98 sub cfg ($) {
  99     my ($k) = @_;
 100     $/ = "\0";
 101     my @cmd = qw(git config -z);
 102     push @cmd, qw(--get-all) if wantarray;
 103     push @cmd, $k;
 104     my $out = cmdoutput @cmd;
 105     return split /\0/, $out;
 106 }
 107
 108 memoize('cfg');
 109
 110 sub dd ($) {
 111     my ($v) = @_;
 112     my $dd = new Data::Dumper [ $v ];
 113     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 114     return Dump $dd;
 115 }
 116
 117 sub get_commit ($) {
 118     my ($objid) = @_;
 119     my $data = (git_cat_file $objid, 'commit');
 120     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 121     return ($`,$');
 122 }
 123
 124 sub D_UPS ()      { 0x02; } # upstream files
 125 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 126 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 127 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 128 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 129 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 130
 131 our $playprefix = 'debrebase';
 132 our $rd;
 133 our $workarea;
 134
 135 our @git = qw(git);
 136
 137 sub in_workarea ($) {
 138     my ($sub) = @_;
 139     changedir $workarea;
 140     my $r = eval { $sub->(); };
 141     { local $@; changedir $maindir; }
 142     die $@ if $@;
 143 }
 144
 145 sub fresh_workarea () {
 146     $workarea = fresh_playground "$playprefix/work";
 147     in_workarea sub { playtree_setup };
 148 }
 149
 150 sub get_differs ($$) {
 151     my ($x,$y) = @_;
 152     # This resembles quiltify_trees_differ, in dgit, a bit.
 153     # But we don't care about modes, or dpkg-source-unrepresentable
 154     # changes, and we don't need the plethora of different modes.
 155     # Conversely we need to distinguish different kinds of changes to
 156     # debian/ and debian/patches/.
 157
 158     my $differs = 0;
 159
 160     my $rundiff = sub {
 161         my ($opts, $limits, $fn) = @_;
 162         my @cmd = (@git, qw(diff-tree -z --no-renames));
 163         push @cmd, @$opts;
 164         push @cmd, "$_:" foreach $x, $y;
 165         push @cmd, '--', @$limits;
 166         my $diffs = cmdoutput @cmd;
 167         foreach (split /\0/, $diffs) { $fn->(); }
 168     };
 169
 170     $rundiff->([qw(--name-only)], [], sub {
 171         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 172     });
 173
 174     if ($differs & DS_DEB) {
 175         $differs &= ~DS_DEB;
 176         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 177             $differs |=
 178                 m{^debian/patches/}      ? D_PAT_OTH  :
 179                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 180                                            D_DEB_OTH;
 181         });
 182         die "mysterious debian changes $x..$y"
 183             unless $differs & (D_PAT_OTH|DS_DEB);
 184     }
 185
 186     if ($differs & D_PAT_OTH) {
 187         my $mode;
 188         $differs &= ~D_PAT_OTH;
 189         my $pat_oth = sub {
 190             $differs |= D_PAT_OTH;
 191             no warnings qw(exiting);  last;
 192         };
 193         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 194             no warnings qw(exiting);
 195             if (!defined $mode) {
 196                 $mode = $_;  next;
 197             }
 198             die unless s{^debian/patches/}{};
 199             my $ok;
 200             if ($mode eq 'A' && !m/\.series$/s) {
 201                 $ok = 1;
 202             } elsif ($mode eq 'M' && $_ eq 'series') {
 203                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 204                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 205                 chomp $x_s;  $x_s .= "\n";
 206                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 207             } else {
 208                 # nope
 209             }
 210             $mode = undef;
 211             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 212         });
 213         die "mysterious debian/patches changes $x..$y"
 214             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 215     }
 216
 217     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 218
 219     return $differs;
 220 }
 221
 222 sub commit_pr_info ($) {
 223     my ($r) = @_;
 224     return Data::Dumper->dump([$r], [qw(commit)]);
 225 }
 226
 227 sub calculate_committer_authline () {
 228     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 229         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 230     my ($h,$m) = get_commit $c;
 231     $h =~ m/^committer .*$/m or confess "($h) ?";
 232     return $&;
 233 }
 234
 235 sub rm_subdir_cached ($) {
 236     my ($subdir) = @_;
 237     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 238 }
 239
 240 sub read_tree_subdir ($$) {
 241     my ($subdir, $new_tree_object) = @_;
 242     rm_subdir_cached $subdir;
 243     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 244 }
 245
 246 sub make_commit ($$) {
 247     my ($parents, $message_paras) = @_;
 248     my $tree = cmdoutput @git, qw(write-tree);
 249     my @cmd = (@git, qw(commit-tree), $tree);
 250     push @cmd, qw(-p), $_ foreach @$parents;
 251     push @cmd, qw(-m), $_ foreach @$message_paras;
 252     return cmdoutput @cmd;
 253 }
 254
 255 our $fproblems;
 256 sub fproblem ($) {
 257     my ($msg) = @_;
 258     $fproblems++;
 259     print STDERR "git-debrebase: safety catch tripped: $msg\n";
 260 }
 261 sub fproblems_maybe_bail () {
 262     if ($fproblems) {
 263         if ($opt_force) {
 264             printf STDERR
 265                 "safety catch trips (%d) overriden by --force\n",
 266                 $fproblems;
 267         } else {
 268             fail sprintf
 269                 "safety catch trips (%d) (you could --force)",
 270                 $fproblems;
 271         }
 272     }
 273 }
 274
 275 # classify returns an info hash like this
 276 #   CommitId => $objid
 277 #   Hdr => # commit headers, including 1 final newline
 278 #   Msg => # commit message (so one newline is dropped)
 279 #   Tree => $treeobjid
 280 #   Type => (see below)
 281 #   Parents = [ {
 282 #       Ix => $index # ie 0, 1, 2, ...
 283 #       CommitId
 284 #       Differs => return value from get_differs
 285 #       IsOrigin
 286 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 287 #     } ...]
 288 #   NewMsg => # commit message, but with any [dgit import ...] edited
 289 #             # to say "[was: ...]"
 290 #
 291 # Types:
 292 #   Packaging
 293 #   Changelog
 294 #   Upstream
 295 #   AddPatches
 296 #   Mixed
 297 #   Unknown
 298 #
 299 #   Pseudomerge
 300 #     has additional entres in classification result
 301 #       Overwritten = [ subset of Parents ]
 302 #       Contributor = $the_remaining_Parent
 303 #
 304 #   DgitImportUnpatched
 305 #     has additional entry in classification result
 306 #       OrigParents = [ subset of Parents ]
 307 #
 308 #   BreakwaterUpstreamMerge
 309 #     has additional entry in classification result
 310 #       OrigParents = [ subset of Parents ]  # singleton list
 311
 312 sub parsecommit ($;$) {
 313     my ($objid, $p_ref) = @_;
 314     # => hash with                   CommitId Hdr Msg Tree Parents
 315     #    Parents entries have only   Ix CommitId
 316     #    $p_ref, if provided, must be [] and is used as a base for Parents
 317
 318     $p_ref //= [];
 319     die if @$p_ref;
 320
 321     my ($h,$m) = get_commit $objid;
 322
 323     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 324     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 325
 326     my $r = {
 327         CommitId => $objid,
 328         Hdr => $h,
 329         Msg => $m,
 330         Tree => $t,
 331         Parents => $p_ref,
 332     };
 333
 334     foreach my $ph (@ph) {
 335         push @$p_ref, {
 336             Ix => scalar @$p_ref,
 337             CommitId => $ph,
 338         };
 339     }
 340
 341     return $r;
 342 }
 343
 344 sub classify ($) {
 345     my ($objid) = @_;
 346
 347     my @p;
 348     my $r = parsecommit($objid, \@p);
 349     my $t = $r->{Tree};
 350
 351     foreach my $p (@p) {
 352         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 353     }
 354
 355     printdebug "classify $objid \$t=$t \@p",
 356         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 357         "\n";
 358
 359     my $classify = sub {
 360         my ($type, @rest) = @_;
 361         $r = { %$r, Type => $type, @rest };
 362         if ($debuglevel) {
 363             printdebug " = $type ".(dd $r)."\n";
 364         }
 365         return $r;
 366     };
 367     my $unknown = sub {
 368         my ($why) = @_;
 369         $r = { %$r, Type => qw(Unknown) };
 370         printdebug " ** Unknown\n";
 371         return $r;
 372     };
 373
 374     my $claims_to_be_breakwater =
 375         $r->{Msg} =~ m{^\[git-debrebase breakwater.*\]$}m;
 376
 377     if (@p == 1) {
 378         my $d = $r->{Parents}[0]{Differs};
 379         if ($d == D_PAT_ADD) {
 380             return $classify->(qw(AddPatches));
 381         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 382             return $unknown->("edits debian/patches");
 383         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 384             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 385             if ($ty eq 'tree') {
 386                 if ($d == D_DEB_CLOG) {
 387                     return $classify->(qw(Changelog));
 388                 } else {
 389                     return $classify->(qw(Packaging));
 390                 }
 391             } elsif ($ty eq 'missing') {
 392                 return $classify->(qw(BreakwaterStart));
 393             } else {
 394                 return $unknown->("parent's debian is not a directory");
 395             }
 396         } elsif ($d == D_UPS) {
 397             return $classify->(qw(Upstream));
 398         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 399             return $classify->(qw(Mixed));
 400         } elsif ($d == 0) {
 401             return $unknown->("no changes");
 402         } else {
 403             confess "internal error $objid ?";
 404         }
 405     }
 406     if (!@p) {
 407         return $unknown->("origin commit");
 408     }
 409
 410     my @identical = grep { !$_->{Differs} } @p;
 411     if (@p == 2 && @identical == 1 && !$claims_to_be_breakwater
 412         # breakwater merges can look like pseudomerges, if they are
 413         # "declare" commits (ie, there are no upstream changes)
 414        ) {
 415         my @overwritten = grep { $_->{Differs} } @p;
 416         confess "internal error $objid ?" unless @overwritten==1;
 417         return $classify->(qw(Pseudomerge),
 418                            Overwritten => $overwritten[0],
 419                            Contributor => $identical[0]);
 420     }
 421     if (@p == 2 && @identical == 2) {
 422         my @bytime = nsort_by {
 423             my ($ph,$pm) = get_commit $_->{CommitId};
 424             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 425             $1;
 426         } @p;
 427         return $classify->(qw(Pseudomerge),
 428                            SubType => qw(Ambiguous),
 429                            Overwritten => $bytime[0],
 430                            Contributor => $bytime[1]);
 431     }
 432     foreach my $p (@p) {
 433         my ($p_h, $p_m) = get_commit $p->{CommitId};
 434         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 435         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 436     }
 437     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 438     my $m2 = $r->{Msg};
 439     if (!(grep { !$_->{IsOrigin} } @p) and
 440         (@orig_ps >= @p - 1) and
 441         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 442         $r->{NewMsg} = $m2;
 443         return $classify->(qw(DgitImportUnpatched),
 444                            OrigParents => \@orig_ps);
 445     }
 446
 447     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 448     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 449
 450     # How to decide about l/r ordering of breakwater merges ?  git
 451     # --topo-order prefers to expand 2nd parent first.  There's
 452     # already an easy rune to look for debian/ history anyway (git log
 453     # debian/) so debian breakwater branch should be 1st parent; that
 454     # way also there's also an easy rune to look for the upstream
 455     # patches (--topo-order).
 456
 457     # The above tells us which way *we* will generate them.  But we
 458     # might encounter ad-hoc breakwater merges generated manually,
 459     # which might be the other way around.  In principle, in some odd
 460     # situations, a breakwater merge might have two identical parents.
 461     # In that case we guess which way round it is (ie, which parent
 462     # has the upstream history).  The order of the 2-iteration loop
 463     # controls which guess we make.
 464
 465     foreach my $prevbrw (qw(0 1)) {
 466         if (@p == 2 &&
 467             !$haspatches &&
 468             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 469             !($p[!$prevbrw]{Differs} & ~DS_DEB) && # no non-debian changess
 470             !($p[$prevbrw]{Differs} & ~D_UPS)) { # no non-upstream changes
 471             return $classify->(qw(BreakwaterUpstreamMerge),
 472                                OrigParents => [ $p[!$prevbrw] ]);
 473         }
 474     }
 475
 476     # multi-orig upstreams are represented with a breakwater merge
 477     # from a single upstream commit which combines the orig tarballs
 478
 479     return $unknown->("complex merge");
 480 }
 481
 482 sub walk ($;$$);
 483 sub walk ($;$$) {
 484     my ($input,
 485         $nogenerate,$report) = @_;
 486     # => ($tip, $breakwater_tip, $last_upstream_merge_in_breakwater)
 487     # (or nothing, if $nogenerate)
 488
 489     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 490
 491     # go through commits backwards
 492     # we generate two lists of commits to apply:
 493     # breakwater branch and upstream patches
 494     my (@brw_cl, @upp_cl, @processed);
 495     my %found;
 496     my $upp_limit;
 497     my @pseudomerges;
 498
 499     my $cl;
 500     my $xmsg = sub {
 501         my ($prose, $info) = @_;
 502         my $ms = $cl->{Msg};
 503         chomp $ms;
 504         $info //= '';
 505         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 506         return (Msg => $ms);
 507     };
 508     my $rewrite_from_here = sub {
 509         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 510         push @brw_cl, $sp_cl;
 511         push @processed, $sp_cl;
 512     };
 513     my $cur = $input;
 514
 515     my $prdelim = "";
 516     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 517
 518     my $prline = sub {
 519         return unless $report;
 520         print $report $prdelim, @_;
 521         $prdelim = "\n";
 522     };
 523
 524     my $bomb = sub { # usage: return $bomb->();
 525         print $report " Unprocessable" if $report;
 526         $prprdelim->();
 527         if ($nogenerate) {
 528             return (undef,undef);
 529         }
 530         die "commit $cur: Cannot cope with this commit (d.".
 531             (join ' ', map { sprintf "%#x", $_->{Differs} }
 532              @{ $cl->{Parents} }). ")";
 533     };
 534
 535     my $build;
 536     my $breakwater;
 537
 538     my $build_start = sub {
 539         my ($msg, $parent) = @_;
 540         $prline->(" $msg");
 541         $build = $parent;
 542         no warnings qw(exiting); last;
 543     };
 544
 545     my $last_upstream_update;
 546
 547     for (;;) {
 548         $cl = classify $cur;
 549         my $ty = $cl->{Type};
 550         my $st = $cl->{SubType};
 551         $prline->("$cl->{CommitId} $cl->{Type}");
 552         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 553         push @processed, $cl;
 554         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 555         if ($ty eq 'AddPatches') {
 556             $cur = $p0;
 557             $rewrite_from_here->();
 558             next;
 559         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 560             push @brw_cl, $cl;
 561             $cur = $p0;
 562             next;
 563         } elsif ($ty eq 'BreakwaterStart') {
 564             $last_upstream_update = $cur;
 565             $build_start->('FirstPackaging', $cur);
 566         } elsif ($ty eq 'Upstream') {
 567             push @upp_cl, $cl;
 568             $cur = $p0;
 569             next;
 570         } elsif ($ty eq 'Mixed') {
 571             my $queue = sub {
 572                 my ($q, $wh) = @_;
 573                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 574                 push @$q, $cls;
 575             };
 576             $queue->(\@brw_cl, "debian");
 577             $queue->(\@upp_cl, "upstream");
 578             $rewrite_from_here->();
 579             $cur = $p0;
 580             next;
 581         } elsif ($ty eq 'Pseudomerge') {
 582             my $contrib = $cl->{Contributor}{CommitId};
 583             print $report " Contributor=$contrib" if $report;
 584             push @pseudomerges, $cl;
 585             $rewrite_from_here->();
 586             $cur = $contrib;
 587             next;
 588         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 589             $last_upstream_update = $cur;
 590             $build_start->("PreviousBreakwater", $cur);
 591         } elsif ($ty eq 'DgitImportUnpatched') {
 592             my $pm = $pseudomerges[-1];
 593             if (defined $pm) {
 594                 # To an extent, this is heuristic.  Imports don't have
 595                 # a useful history of the debian/ branch.  We assume
 596                 # that the first pseudomerge after an import has a
 597                 # useful history of debian/, and ignore the histories
 598                 # from later pseudomerges.  Often the first pseudomerge
 599                 # will be the dgit import of the upload to the actual
 600                 # suite intended by the non-dgit NMUer, and later
 601                 # pseudomerges may represent in-archive copies.
 602                 my $ovwrs = $pm->{Overwritten};
 603                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 604                     if $report;
 605                 if (@$ovwrs != 1) {
 606                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 607                     return $bomb->();
 608                 }
 609                 my $ovwr = $ovwrs->[0]{CommitId};
 610                 printf $report " Overwr=%s", $ovwr if $report;
 611                 # This import has a tree which is just like a
 612                 # breakwater tree, but it has the wrong history.  It
 613                 # ought to have the previous breakwater (which the
 614                 # pseudomerge overwrote) as an ancestor.  That will
 615                 # make the history of the debian/ files correct.  As
 616                 # for the upstream version: either it's the same as
 617                 # was ovewritten (ie, same as the previous
 618                 # breakwater), in which case that history is precisely
 619                 # right; or, otherwise, it was a non-gitish upload of a
 620                 # new upstream version.  We can tell these apart by
 621                 # looking at the tree of the supposed upstream.
 622                 push @brw_cl, {
 623                     %$cl,
 624                     SpecialMethod => 'DgitImportDebianUpdate',
 625                     $xmsg->("convert dgit import: debian changes")
 626                 };
 627                 my $differs = (get_differs $ovwr, $cl->{Tree});
 628                 printf $report " Differs=%#x", $differs if $report;
 629                 if ($differs & D_UPS) {
 630                     printf $report " D_UPS" if $report;
 631                     # This will also trigger if a non-dgit git-based NMU
 632                     # deleted .gitignore (which is a thing that some of
 633                     # the existing git tools do if the user doesn't
 634                     # somehow tell them not to).  Ah well.
 635                     push @brw_cl, {
 636                         %$cl,
 637                         SpecialMethod => 'DgitImportUpstreamUpdate',
 638                         $xmsg->("convert dgit import: upstream changes",
 639                                 " breakwater")
 640                     };
 641                 }
 642                 $prline->(" Import");
 643                 $rewrite_from_here->();
 644                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 645                 die 'BUG $upp_limit is not used anywhere?';
 646                 $cur = $ovwr;
 647                 next;
 648             } else {
 649                 # Everything is from this import.  This kind of import
 650                 # is already in valid breakwater format, with the
 651                 # patches as commits.
 652                 printf $report " NoPM" if $report;
 653                 # last thing we processed will have been the first patch,
 654                 # if there is one; which is fine, so no need to rewrite
 655                 # on account of this import
 656                 $build_start->("ImportOrigin", $cur);
 657             }
 658             die "$ty ?";
 659         } else {
 660             printdebug "*** WALK BOMB unrecognised\n";
 661             return $bomb->();
 662         }
 663     }
 664     $prprdelim->();
 665
 666     printdebug "*** WALK prep done cur=$cur".
 667         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 668
 669     return if $nogenerate;
 670
 671     # Now we build it back up again
 672
 673     fresh_workarea();
 674
 675     my $rewriting = 0;
 676
 677     my $read_tree_debian = sub {
 678         my ($treeish) = @_;
 679         read_tree_subdir 'debian', "$treeish:debian";
 680         rm_subdir_cached 'debian/patches';
 681     };
 682     my $read_tree_upstream = sub {
 683         my ($treeish) = @_;
 684         runcmd @git, qw(read-tree), $treeish;
 685         $read_tree_debian->($build);
 686     };
 687
 688     my $committer_authline = calculate_committer_authline();
 689
 690     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 691
 692     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 693
 694     in_workarea sub {
 695         mkdir $rd or $!==EEXIST or die $!;
 696         my $current_method;
 697         runcmd @git, qw(read-tree), $build;
 698         foreach my $cl (qw(Debian), (reverse @brw_cl),
 699                         { SpecialMethod => 'RecordBreakwaterTip' },
 700                         qw(Upstream), (reverse @upp_cl)) {
 701             if (!ref $cl) {
 702                 $current_method = $cl;
 703                 next;
 704             }
 705             my $method = $cl->{SpecialMethod} // $current_method;
 706             my @parents = ($build);
 707             my $cltree = $cl->{CommitId};
 708             printdebug "WALK BUILD ".($cltree//'undef').
 709                 " $method (rewriting=$rewriting)\n";
 710             if ($method eq 'Debian') {
 711                 $read_tree_debian->($cltree);
 712             } elsif ($method eq 'Upstream') {
 713                 $read_tree_upstream->($cltree);
 714             } elsif ($method eq 'StartRewrite') {
 715                 $rewriting = 1;
 716                 next;
 717             } elsif ($method eq 'RecordBreakwaterTip') {
 718                 $breakwater = $build;
 719                 next;
 720             } elsif ($method eq 'DgitImportDebianUpdate') {
 721                 $read_tree_debian->($cltree);
 722                 rm_subdir_cached qw(debian/patches);
 723             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 724                 $read_tree_upstream->($cltree);
 725                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 726             } else {
 727                 confess "$method ?";
 728             }
 729             if (!$rewriting) {
 730                 my $procd = (pop @processed) // 'UNDEF';
 731                 if ($cl ne $procd) {
 732                     $rewriting = 1;
 733                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 734                 }
 735             }
 736             my $newtree = cmdoutput @git, qw(write-tree);
 737             my $ch = $cl->{Hdr};
 738             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 739             $ch =~ s{^parent .*\n}{}m;
 740             $ch =~ s{(?=^author)}{
 741                 join '', map { "parent $_\n" } @parents
 742             }me or confess "$ch ?";
 743             if ($rewriting) {
 744                 $ch =~ s{^committer .*$}{$committer_authline}m
 745                     or confess "$ch ?";
 746             }
 747             my $cf = "$rd/m$rewriting";
 748             open CD, ">", $cf or die $!;
 749             print CD $ch, "\n", $cl->{Msg} or die $!;
 750             close CD or die $!;
 751             my @cmd = (@git, qw(hash-object));
 752             push @cmd, qw(-w) if $rewriting;
 753             push @cmd, qw(-t commit), $cf;
 754             my $newcommit = cmdoutput @cmd;
 755             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 756             $build = $newcommit;
 757             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 758                 $last_upstream_update = $cur;
 759             }
 760         }
 761     };
 762
 763     my $final_check = get_differs $build, $input;
 764     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 765         if $final_check & ~D_PAT_ADD;
 766
 767     my @r = ($build, $breakwater, $last_upstream_update);
 768     printdebug "*** WALK RETURN @r\n";
 769     return @r
 770 }
 771
 772 sub get_head () { return git_rev_parse qw(HEAD); }
 773
 774 sub update_head ($$$) {
 775     my ($old, $new, $mrest) = @_;
 776     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 777 }
 778
 779 sub update_head_checkout ($$$) {
 780     my ($old, $new, $mrest) = @_;
 781     update_head $old, $new, $mrest;
 782     runcmd @git, qw(reset --hard);
 783 }
 784
 785 sub update_head_postlaunder ($$$) {
 786     my ($old, $tip, $reflogmsg) = @_;
 787     return if $tip eq $old;
 788     print "git-debrebase: laundered (head was $old)\n";
 789     update_head $old, $tip, $reflogmsg;
 790     # no tree changes except debian/patches
 791     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 792 }
 793
 794 sub cmd_launder () {
 795     badusage "no arguments to launder allowed" if @ARGV;
 796     my $old = get_head();
 797     my ($tip,$breakwater,$last_upstream_merge) = walk $old;
 798     update_head_postlaunder $old, $tip, 'launder';
 799     printf "# breakwater tip\n%s\n", $breakwater;
 800     printf "# working tip\n%s\n", $tip;
 801     printf "# last upstream merge\n%s\n", $last_upstream_merge;
 802 }
 803
 804 sub defaultcmd_rebase () {
 805     my $old = get_head();
 806     my ($tip,$breakwater) = walk $old;
 807     update_head_postlaunder $old, $tip, 'launder for rebase';
 808     @ARGV = qw(-i) unless @ARGV; # make configurable
 809     runcmd @git, qw(rebase), @ARGV, $breakwater;
 810 }
 811
 812 sub cmd_analyse () {
 813     die if ($ARGV[0]//'') =~ m/^-/;
 814     badusage "too many arguments to analyse" if @ARGV>1;
 815     my ($old) = @ARGV;
 816     if (defined $old) {
 817         $old = git_rev_parse $old;
 818     } else {
 819         $old = get_head();
 820     }
 821     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 822     STDOUT->error and die $!;
 823 }
 824
 825 sub cmd_new_upstream_v0 () {
 826     # tree should be clean and this is not checked
 827     # automatically and unconditionally launders before rebasing
 828     # if rebase --abort is used, laundering has still been done
 829
 830     my %pieces;
 831
 832     badusage "need NEW-VERSION UPS-COMMITTISH" unless @ARGV >= 2;
 833
 834     # parse args - low commitment
 835     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
 836     my $new_upstream_version = $new_version->version();
 837
 838     my $new_upstream = git_rev_parse shift @ARGV;
 839
 840     my $piece = sub {
 841         my ($n, @x) = @_; # may be ''
 842         my $pc = $pieces{$n} //= {
 843             Name => $n,
 844             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
 845         };
 846         while (my $k = shift @x) { $pc->{$k} = shift @x; }
 847         $pc;
 848     };
 849
 850     my @newpieces;
 851     my $newpiece = sub {
 852         my ($n, @x) = @_; # may be ''
 853         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
 854         push @newpieces, $pc;
 855     };
 856
 857     $newpiece->('',
 858         OldIx => 0,
 859         New => $new_upstream,
 860     );
 861     while (@ARGV && $ARGV[0] !~ m{^-}) {
 862         my $n = shift @ARGV;
 863
 864         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
 865             unless @ARGV && $ARGV[0] !~ m{^-};
 866
 867         my $c = git_rev_parse shift @ARGV;
 868         die unless $n =~ m/^$extra_orig_namepart_re$/;
 869         $newpiece->($n, New => $c);
 870     }
 871
 872     # now we need to investigate the branch this generates the
 873     # laundered version but we don't switch to it yet
 874     my $old_head = get_head();
 875     my ($old_laundered_tip,$old_bw,$old_upstream_update) = walk $old_head;
 876
 877     my $old_bw_cl = classify $old_bw;
 878     my $old_upstream_update_cl = classify $old_upstream_update;
 879     confess unless $old_upstream_update_cl->{OrigParents};
 880     my $old_upstream = parsecommit
 881         $old_upstream_update_cl->{OrigParents}[0]{CommitId};
 882
 883     $piece->('', Old => $old_upstream->{CommitId});
 884
 885     if ($old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
 886         if ($old_upstream->{Msg} =~
 887  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
 888            ) {
 889             my @oldpieces = ('', split / /, $1);
 890             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
 891             foreach my $i (0..$#oldpieces) {
 892                 my $n = $oldpieces[$i];
 893                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
 894             }
 895         } else {
 896             fproblem "previous upstream $old_upstream->{CommitId} is from".
 897                  " git-debrebase but not an \`upstream-combine' commit";
 898         }
 899     }
 900
 901     foreach my $pc (values %pieces) {
 902         if (!$pc->{Old}) {
 903             fproblem "introducing upstream piece \`$pc->{Name}'";
 904         } elsif (!$pc->{New}) {
 905             fproblem "dropping upstream piece \`$pc->{Name}'";
 906         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
 907             fproblem "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
 908         }
 909     }
 910
 911     printdebug "%pieces = ", (dd \%pieces), "\n";
 912     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
 913
 914     fproblems_maybe_bail();
 915
 916     my $new_bw;
 917
 918     fresh_workarea();
 919     in_workarea sub {
 920         my @upstream_merge_parents;
 921
 922         if (!$fproblems) {
 923             push @upstream_merge_parents, $old_upstream->{CommitId};
 924         }
 925
 926         foreach my $pc (@newpieces) { # always has '' first
 927             if ($pc->{Name}) {
 928                 read_tree_subdir $pc->{Name}, $pc->{New};
 929             } else {
 930                 runcmd @git, qw(read-tree), $pc->{New};
 931             }
 932             push @upstream_merge_parents, $pc->{New};
 933         }
 934
 935         # index now contains the new upstream
 936
 937         if (@newpieces > 1) {
 938             # need to make the upstream subtree merge commit
 939             $new_upstream = make_commit \@upstream_merge_parents,
 940                 [ "Combine upstreams for $new_upstream_version",
 941  ("[git-debrebase upstream-combine . ".
 942  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
 943  ": new upstream]"),
 944                 ];
 945         }
 946
 947         # $new_upstream is either the single upstream commit, or the
 948         # combined commit we just made.  Either way it will be the
 949         # "upstream" parent of the breakwater special merge.
 950
 951         read_tree_subdir 'debian', "$old_bw:debian";
 952
 953         # index now contains the breakwater merge contents
 954         $new_bw = make_commit [ $old_bw, $new_upstream ],
 955             [ "Update to upstream $new_upstream_version",
 956  "[git-debrebase breakwater: new upstream $new_upstream_version, merge]",
 957             ];
 958
 959         # Now we have to add a changelog stanza so the Debian version
 960         # is right.
 961         die if unlink "debian";
 962         die $! unless $!==ENOENT or $!==ENOTEMPTY;
 963         unlink "debian/changelog" or $!==ENOENT or die $!;
 964         mkdir "debian" or die $!;
 965         open CN, ">", "debian/changelog" or die $!;
 966         my $oldclog = git_cat_file ":debian/changelog";
 967         $oldclog =~ m/^($package_re) \(\S+\) / or
 968             fail "cannot parse old changelog to get package name";
 969         my $p = $1;
 970         print CN <<END, $oldclog or die $!;
 971 $p ($new_version) UNRELEASED; urgency=medium
 972
 973   * Update to new upstream version $new_upstream_version.
 974
 975  --
 976
 977 END
 978         close CN or die $!;
 979         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
 980
 981         # Now we have the final new breakwater branch in the index
 982         $new_bw = make_commit [ $new_bw ],
 983             [ "Update changelog for new upstream $new_upstream_version",
 984               "[git-debrebase: new upstream $new_upstream_version, changelog]",
 985             ];
 986     };
 987
 988     # we have constructed the new breakwater. we now need to commit to
 989     # the laundering output, because git-rebase can't easily be made
 990     # to make a replay list which is based on some other branch
 991
 992     update_head_postlaunder $old_head, $old_laundered_tip,
 993         'launder for new upstream';
 994
 995     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
 996     runcmd @cmd;
 997     # now it's for the user to sort out
 998 }
 999
1000 sub cmd_gbp2debrebase () {
1001     badusage "needs 1 optional argument, the upstream" unless @ARGV<=1;
1002     my ($upstream_spec) = @ARGV;
1003     $upstream_spec //= 'refs/heads/upstream';
1004     my $upstream = git_rev_parse $upstream_spec;
1005     my $old_head = get_head();
1006
1007     my $upsdiff = get_differs $upstream, $old_head;
1008     if ($upsdiff & D_UPS) {
1009         runcmd @git, qw(--no-pager diff),
1010             $upstream, $old_head,
1011             qw( -- :!/debian :/);
1012  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1013     }
1014
1015     if (!is_fast_fwd $upstream, $old_head) {
1016         fproblem "upstream ($upstream) is not an ancestor of HEAD";
1017     } else {
1018         my $wrong = cmdoutput
1019             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1020              qw(-- :/ :!/debian));
1021         if (length $wrong) {
1022             fproblem "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1023             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1024         }
1025     }
1026
1027     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1028         fproblem "upstream ($upstream) contains debian/ directory";
1029     }
1030
1031     fproblems_maybe_bail();
1032
1033     my $work;
1034
1035     fresh_workarea();
1036     in_workarea sub {
1037         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1038         # make a branch out of the patch queue - we'll want this in a mo
1039         runcmd qw(gbp pq import);
1040         # strip the patches out
1041         runcmd @git, qw(checkout -q gdr-internal~0);
1042         rm_subdir_cached 'debian/patches';
1043         $work = make_commit ['HEAD'], [
1044  'git-debrebase import: drop patch queue',
1045  'Delete debian/patches, as part of converting to git-debrebase format.',
1046  '[git-debrebase: gbp2debrebase, drop patches]'
1047                               ];
1048         # make the breakwater pseudomerge
1049         # the tree is already exactly right
1050         $work = make_commit [$work, $upstream], [
1051  'git-debrebase import: declare upstream',
1052  'First breakwater merge.',
1053  '[git-debrebase breakwater: declare upstream]'
1054                               ];
1055
1056         # rebase the patch queue onto the new breakwater
1057         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1058         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1059         $work = get_head();
1060     };
1061
1062     update_head_checkout $old_head, $work, 'gbp2debrebase';
1063 }
1064
1065 sub cmd_downstream_rebase_launder_v0 () {
1066     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1067     my ($base) = @ARGV;
1068     $base = git_rev_parse $base;
1069     my $old_head = get_head();
1070     my $current = $old_head;
1071     my $topmost_keep;
1072     for (;;) {
1073         if ($current eq $base) {
1074             $topmost_keep //= $current;
1075             print " $current BASE stop\n";
1076             last;
1077         }
1078         my $cl = classify $current;
1079         print " $current $cl->{Type}";
1080         my $keep = 0;
1081         my $p0 = $cl->{Parents}[0]{CommitId};
1082         my $next;
1083         if ($cl->{Type} eq 'Pseudomerge') {
1084             print " ^".($cl->{Contributor}{Ix}+1);
1085             $next = $cl->{Contributor}{CommitId};
1086         } elsif ($cl->{Type} eq 'AddPatches' or
1087                  $cl->{Type} eq 'Changelog') {
1088             print " strip";
1089             $next = $p0;
1090         } else {
1091             print " keep";
1092             $next = $p0;
1093             $keep = 1;
1094         }
1095         print "\n";
1096         if ($keep) {
1097             $topmost_keep //= $current;
1098         } else {
1099             die "to-be stripped changes not on top of the branch\n"
1100                 if $topmost_keep;
1101         }
1102         $current = $next;
1103     }
1104     if ($topmost_keep eq $old_head) {
1105         print "unchanged\n";
1106     } else {
1107         print "updating to $topmost_keep\n";
1108         update_head_checkout
1109             $old_head, $topmost_keep,
1110             'downstream-rebase-launder-v0';
1111     }
1112 }
1113
1114 GetOptions("D+" => \$debuglevel,
1115            'force!') or die badusage "bad options\n";
1116 initdebug('git-debrebase ');
1117 enabledebug if $debuglevel;
1118
1119 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1120 chdir $toplevel or die "chdir $toplevel: $!";
1121
1122 $rd = fresh_playground "$playprefix/misc";
1123
1124 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1125     defaultcmd_rebase();
1126 } else {
1127     my $cmd = shift @ARGV;
1128     my $cmdfn = $cmd;
1129     $cmdfn =~ y/-/_/;
1130     $cmdfn = ${*::}{"cmd_$cmdfn"};
1131
1132     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1133     $cmdfn->();
1134 }