git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$$) {
 267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 268     # if $tree_with_debian is supplied, will use that for debian/
 269     # otherwise will save and restore it.
 270     my $debian =
 271         $tree_with_debian ? "$tree_with_debian:debian"
 272         : cmdoutput @git, qw(write-tree --prefix=debian/);
 273     runcmd @git, qw(read-tree), $treeish;
 274     read_tree_subdir 'debian', $debian;
 275     rm_subdir_cached 'debian/patches' unless $keep_patches;
 276 };
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @snag_force_opts;
 288 sub snag ($$;@) {
 289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 290     if (grep { $_ eq $tag } @snag_force_opts) {
 291         $snags_forced++;
 292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 293     } else {
 294         $snags_tripped++;
 295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 296     }
 297 }
 298
 299 # Important: all mainline code must call snags_maybe_bail after
 300 # any point where snag might be called, but before making changes
 301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 302 # may be called more than once if necessary (but this is not ideal
 303 # because then the messages about number of snags may be confusing).
 304 sub snags_maybe_bail () {
 305     return if all_snags_summarised();
 306     if ($snags_forced) {
 307         printf STDERR
 308             "%s: snags: %d overriden by individual -f options\n",
 309             $us, $snags_forced;
 310     }
 311     if ($snags_tripped) {
 312         if ($opt_force) {
 313             printf STDERR
 314                 "%s: snags: %d overriden by global --force\n",
 315                 $us, $snags_tripped;
 316         } else {
 317             fail sprintf
 318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 319                 $us, $snags_tripped;
 320         }
 321     }
 322     $snags_summarised = $snags_forced + $snags_tripped;
 323 }
 324 sub snags_maybe_bail_early () {
 325     # useful to bail out early without doing a lot of work;
 326     # not a substitute for snags_maybe_bail.
 327     snags_maybe_bail() if $snags_tripped && !$opt_force;
 328 }
 329 sub any_snags () {
 330     return $snags_forced || $snags_tripped;
 331 }
 332
 333 sub gbp_pq_export ($$$) {
 334     my ($bname, $base, $tip) = @_;
 335     # must be run in a workarea.  $bname and patch-queue/$bname
 336     # ought not to exist.  Leaves you on patch-queue/$bname with
 337     # the patches staged but not committed.
 338     printdebug "gbp_pq_export $bname $base $tip\n";
 339     runcmd @git, qw(checkout -q -b), $bname, $base;
 340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 341     my @gbp_cmd = (qw(gbp pq export));
 342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 343     if ($r) {
 344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 345         failedcmd @gbp_cmd;
 346     }
 347     runcmd @git, qw(add -f debian/patches);
 348 }
 349
 350
 351 # xxx allow merge resolution separately from laundering, before git merge
 352 #
 353 # xxx general gdr docs highlight forbidden things
 354 # xxx general gdr docs list allowable things ?
 355 # xxx general gdr docs explicitly forbid some rebase
 356 #
 357 # xxx provide a way for the user to help
 358 # xxx (eg, provide wreckage provide way to continue)
 359
 360 # later/rework?
 361 #  use git-format-patch?
 362 #  our own patch identification algorithm?
 363 #  this is an alternative strategy
 364
 365 sub merge_series ($$;@) {
 366     my ($newbase, $base_q, @input_qs) = @_;
 367     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 368     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 369     # ^ specifies several patch series (currently we only support exactly 2)
 370     # return value is a commit which is the result of
 371     # merging the two versions of the same topic branch
 372     #   $input_q[0] and $input_q[1]
 373     # with respect to the old version
 374     #   $base_q
 375     # all onto $newbase.
 376
 377     # Creates, in *_q, a key MR for its private use
 378
 379     printdebug "merge_series newbase=$newbase\n";
 380
 381     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 382     $base_q->{MR}{S} = 'base';
 383
 384     my %prereq;
 385     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 386     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 387     # $prereq{<patch filename>}               exists or not (even later)
 388
 389     my $result;
 390
 391     local $workarea = fresh_playground "$playprefix/merge";
 392     my $seriesfile = "debian/patches/series";
 393     in_workarea sub {
 394         playtree_setup();
 395         foreach my $q ($base_q, reverse @input_qs) {
 396             my $s = $q->{MR}{S};
 397             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 398             my @earlier;
 399             if (open S, $seriesfile) {
 400                 while (my $patch = <S>) {
 401                     chomp $patch or die $!;
 402                     $prereq{$patch} //= {};
 403                     foreach my $earlier (@earlier) {
 404                         $prereq{$patch}{$earlier}{$s}++ and die;
 405                     }
 406                     push @earlier, $patch;
 407                     stat "debian/patches/$patch" or die "$patch ?";
 408                 }
 409                 S->error and die "$seriesfile $!";
 410                 close S;
 411             } else {
 412                 die "$seriesfile $!" unless $!==ENOENT;
 413             }
 414             read_tree_upstream $newbase, 1;
 415             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 416                 "Convert $s to patch queue for merging",
 417                 "[git-debrebase merge-innards patch-queue import:".
 418                 " $q->{SeriesTip}]"
 419             ];
 420             printdebug "merge_series  pec $pec ";
 421             runcmd @git, qw(rm -q --cached), $seriesfile;
 422             $pec = make_commit [ $pec ], [
 423                 "Drop series file from $s to avoid merge trouble",
 424                 "[git-debrebase merge-innards patch-queue prep:".
 425                 " $q->{SeriesTip}]"
 426             ];
 427
 428             read_tree_debian $newbase;
 429             if (@earlier) {
 430                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 431             } else {
 432                 rm_subdir_cached 'debian/patches';
 433             }
 434             $pec = make_commit [ $pec ], [
 435  "Update debian/ (excluding patches) to final to avoid re-merging",
 436  "debian/ was already merged and we need to just take that.",
 437                 "[git-debrebase merge-innards patch-queue packaging:".
 438                 " $q->{SeriesTip}]"
 439             ];
 440
 441             printdebug "pec' $pec\n";
 442             runcmd @git, qw(reset -q --hard), $pec;
 443             $q->{MR}{PEC} = $pec;
 444         }
 445         # now, because of reverse, we are on $input_q->{MR}{OQC}
 446         runcmd @git, qw(checkout -q -b merge);
 447         printdebug "merge_series merging...\n";
 448         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 449         debugcmd '+', @mergecmd;
 450         $!=0; $?=-1;
 451         if (system @mergecmd) {
 452             failedcmd @mergecmd;
 453         }
 454
 455         printdebug "merge_series merge ok, series...\n";
 456         # We need to construct a new series file
 457         # Firstly, resolve prereq
 458         foreach my $f (sort keys %prereq) {
 459             printdebug "merge_series  patch\t$f\t";
 460             if (!stat_exists "debian/patches/$f") {
 461                 print DEBUG " drop\n" if $debuglevel;
 462                 # git merge deleted it; that's how we tell it's not wanted
 463                 delete $prereq{$f};
 464                 next;
 465             }
 466             print DEBUG " keep\n" if $debuglevel;
 467             foreach my $g (sort keys %{ $prereq{$f} }) {
 468                 my $gfp = $prereq{$f}{$g};
 469                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 470                 if (!!$gfp->{0} == !!$gfp->{1}
 471                     ? $gfp->{0}
 472                     : !$gfp->{base}) {
 473                     print DEBUG "\tkeep\n" if $debuglevel;
 474                 } else {
 475                     print DEBUG "\tdrop\n" if $debuglevel;
 476                     delete $prereq{$f}{$g};
 477                 }
 478             }
 479         }
 480
 481         my $unsat = sub {
 482             my ($f) = @_;
 483             return scalar keys %{ $prereq{$f} };
 484         };
 485
 486         my $nodate = time + 1;
 487         my %authordate;
 488         # $authordate{<patch filename>};
 489         my $authordate = sub {
 490             my ($f) = @_;
 491             $authordate{$f} //= do {
 492                 open PF, "<", "debian/patches/$f" or die "$f $!";
 493                 while (<PF>) {
 494                     return $nodate if m/^$/;
 495                     last if s{^Date: }{};
 496                 }
 497                 chomp;
 498                 return cmdoutput qw(date +%s -d), $_;
 499             };
 500         };
 501
 502         open NS, '>', $seriesfile or die $!;
 503
 504         while (keys %prereq) {
 505             my $best;
 506             foreach my $try (sort keys %prereq) {
 507                 if ($best) {
 508                     next if (
 509                              $unsat->($try) <=> $unsat->($best) or
 510                              $authordate->($try) <=> $authordate->($best) or
 511                              $try cmp $best
 512                             ) >= 0;
 513                 }
 514                 $best = $try;
 515             }
 516             printdebug "merge_series series next $best\n";
 517             print NS "$best\n" or die $!;
 518             delete $prereq{$best};
 519             foreach my $gp (values %prereq) {
 520                 delete $gp->{$best};
 521             }
 522         }
 523
 524         runcmd @git, qw(add), $seriesfile;
 525         runcmd @git, qw(commit --quiet -m), 'Merged series';
 526
 527         printdebug "merge_series series gbp pq import\n";
 528         runcmd qw(gbp pq import);
 529
 530         # OK now we are on patch-queue/merge, and we need to rebase
 531         # onto the intended parent and drop the patches from each one
 532
 533         printdebug "merge_series series ok, building...\n";
 534         my $build = $newbase;
 535         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 536         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 537             my $commit = git_cat_file $c, 'commit';
 538             printdebug "merge_series series ok, building $c\n";
 539             read_tree_upstream $c, 0, $newbase;
 540             my $tree = cmdoutput @git, qw(write-tree);
 541             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 542             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 543             open C, ">", "../mcommit" or die $!;
 544             print C $commit or die $!;
 545             close C or die $!;
 546             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 547         }
 548         $result = $build;
 549         runcmd @git, qw(update-ref refs/heads/result), $result;
 550
 551         runcmd @git, qw(checkout -q -b debug);
 552         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 553         runcmd @git, qw(add .);
 554         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 555         printdebug sprintf "merge_series done debug=%s\n",
 556             git_rev_parse 'HEAD';
 557     };
 558     printdebug "merge_series returns $result\n";
 559     return $result;
 560 }
 561
 562 # classify returns an info hash like this
 563 #   CommitId => $objid
 564 #   Hdr => # commit headers, including 1 final newline
 565 #   Msg => # commit message (so one newline is dropped)
 566 #   Tree => $treeobjid
 567 #   Type => (see below)
 568 #   Parents = [ {
 569 #       Ix => $index # ie 0, 1, 2, ...
 570 #       CommitId
 571 #       Differs => return value from get_differs
 572 #       IsOrigin
 573 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 574 #     } ...]
 575 #   NewMsg => # commit message, but with any [dgit import ...] edited
 576 #             # to say "[was: ...]"
 577 #
 578 # Types:
 579 #   Packaging
 580 #   Changelog
 581 #   Upstream
 582 #   AddPatches
 583 #   Mixed
 584 #
 585 #   Pseudomerge
 586 #     has additional entres in classification result
 587 #       Overwritten = [ subset of Parents ]
 588 #       Contributor = $the_remaining_Parent
 589 #
 590 #   DgitImportUnpatched
 591 #     has additional entry in classification result
 592 #       OrigParents = [ subset of Parents ]
 593 #
 594 #   Anchor
 595 #     has additional entry in classification result
 596 #       OrigParents = [ subset of Parents ]  # singleton list
 597 #
 598 #   TreatAsAnchor
 599 #
 600 #   BreakwaterStart
 601 #
 602 #   Unknown
 603 #     has additional entry in classification result
 604 #       Why => "prose"
 605
 606 sub parsecommit ($;$) {
 607     my ($objid, $p_ref) = @_;
 608     # => hash with                   CommitId Hdr Msg Tree Parents
 609     #    Parents entries have only   Ix CommitId
 610     #    $p_ref, if provided, must be [] and is used as a base for Parents
 611
 612     $p_ref //= [];
 613     die if @$p_ref;
 614
 615     my ($h,$m) = get_commit $objid;
 616
 617     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 618     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 619
 620     my $r = {
 621         CommitId => $objid,
 622         Hdr => $h,
 623         Msg => $m,
 624         Tree => $t,
 625         Parents => $p_ref,
 626     };
 627
 628     foreach my $ph (@ph) {
 629         push @$p_ref, {
 630             Ix => scalar @$p_ref,
 631             CommitId => $ph,
 632         };
 633     }
 634
 635     return $r;
 636 }
 637
 638 sub classify ($) {
 639     my ($objid) = @_;
 640
 641     my @p;
 642     my $r = parsecommit($objid, \@p);
 643     my $t = $r->{Tree};
 644
 645     foreach my $p (@p) {
 646         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 647     }
 648
 649     printdebug "classify $objid \$t=$t \@p",
 650         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 651         "\n";
 652
 653     my $classify = sub {
 654         my ($type, @rest) = @_;
 655         $r = { %$r, Type => $type, @rest };
 656         if ($debuglevel) {
 657             printdebug " = $type ".(dd $r)."\n";
 658         }
 659         return $r;
 660     };
 661     my $unknown = sub {
 662         my ($why) = @_;
 663         $r = { %$r, Type => qw(Unknown), Why => $why };
 664         printdebug " ** Unknown\n";
 665         return $r;
 666     };
 667
 668     if (grep { $_ eq $objid } @opt_anchors) {
 669         return $classify->('TreatAsAnchor');
 670     }
 671
 672     my @identical = grep { !$_->{Differs} } @p;
 673     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 674     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 675
 676     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 677         # multi-orig upstreams are represented with an anchor merge
 678         # from a single upstream commit which combines the orig tarballs
 679
 680         # Every anchor tagged this way must be a merge.
 681         # We are relying on the
 682         #     [git-debrebase anchor: ...]
 683         # commit message annotation in "declare" anchor merges (which
 684         # do not have any upstream changes), to distinguish those
 685         # anchor merges from ordinary pseudomerges (which we might
 686         # just try to strip).
 687         #
 688         # However, the user is going to be doing git-rebase a lot.  We
 689         # really don't want them to rewrite an anchor commit.
 690         # git-rebase trips up on merges, so that is a useful safety
 691         # catch.
 692         #
 693         # BreakwaterStart commits are also anchors in the terminology
 694         # of git-debrebase(5), but they are untagged (and always
 695         # manually generated).
 696         #
 697         # We cannot not tolerate any tagged linear commit (ie,
 698         # BreakwaterStart commits tagged `[anchor:') because such a
 699         # thing could result from an erroneous linearising raw git
 700         # rebase of a merge anchor.  That would represent a corruption
 701         # of the branch. and we want to detect and reject the results
 702         # of such corruption before it makes it out anywhere.  If we
 703         # reject it here then we avoid making the pseudomerge which
 704         # would be needed to push it.
 705
 706         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 707         @p == 2 or return $badanchor->("has other than two parents");
 708         $haspatches and return $badanchor->("contains debian/patches");
 709
 710         # How to decide about l/r ordering of anchors ?  git
 711         # --topo-order prefers to expand 2nd parent first.  There's
 712         # already an easy rune to look for debian/ history anyway (git log
 713         # debian/) so debian breakwater branch should be 1st parent; that
 714         # way also there's also an easy rune to look for the upstream
 715         # patches (--topo-order).
 716
 717         # Also this makes --first-parent be slightly more likely to
 718         # be useful - it makes it provide a linearised breakwater history.
 719
 720         # Of course one can say somthing like
 721         #  gitk -- ':/' ':!/debian'
 722         # to get _just_ the commits touching upstream files, and by
 723         # the TREESAME logic in git-rev-list this will leave the
 724         # breakwater into upstream at the first anchor.  But that
 725         # doesn't report debian/ changes at all.
 726
 727         # Other observations about gitk: by default, gitk seems to
 728         # produce output in a different order to git-rev-list.  I
 729         # can't seem to find this documented anywhere.  gitk
 730         # --date-order DTRT.  But, gitk always seems to put the
 731         # parents from left to right, in order, so it's easy to see
 732         # which way round a pseudomerge is.
 733
 734         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 735         $p[1]{Differs} & ~DS_DEB and
 736             $badanchor->("upstream files differ from left parent");
 737         $p[0]{Differs} & ~D_UPS and
 738             $badanchor->("debian/ differs from right parent");
 739
 740         return $classify->(qw(Anchor),
 741                            OrigParents => [ $p[1] ]);
 742     }
 743
 744     if (@p == 1) {
 745         my $d = $r->{Parents}[0]{Differs};
 746         if ($d == D_PAT_ADD) {
 747             return $classify->(qw(AddPatches));
 748         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 749             return $unknown->("edits debian/patches");
 750         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 751             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 752             if ($ty eq 'tree') {
 753                 if ($d == D_DEB_CLOG) {
 754                     return $classify->(qw(Changelog));
 755                 } else {
 756                     return $classify->(qw(Packaging));
 757                 }
 758             } elsif ($ty eq 'missing') {
 759                 return $classify->(qw(BreakwaterStart));
 760             } else {
 761                 return $unknown->("parent's debian is not a directory");
 762             }
 763         } elsif ($d == D_UPS) {
 764             return $classify->(qw(Upstream));
 765         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 766             return $classify->(qw(Mixed));
 767         } elsif ($d == 0) {
 768             return $unknown->("no changes");
 769         } else {
 770             confess "internal error $objid ?";
 771         }
 772     }
 773     if (!@p) {
 774         return $unknown->("origin commit");
 775     }
 776
 777     if (@p == 2 && @identical == 1) {
 778         my @overwritten = grep { $_->{Differs} } @p;
 779         confess "internal error $objid ?" unless @overwritten==1;
 780         return $classify->(qw(Pseudomerge),
 781                            Overwritten => [ $overwritten[0] ],
 782                            Contributor => $identical[0]);
 783     }
 784     if (@p == 2 && @identical == 2) {
 785         my $get_t = sub {
 786             my ($ph,$pm) = get_commit $_[0]{CommitId};
 787             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 788             $1;
 789         };
 790         my @bytime = @p;
 791         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 792         if ($order > 0) { # newer first
 793         } elsif ($order < 0) {
 794             @bytime = reverse @bytime;
 795         } else {
 796             # same age, default to order made by -s ours
 797             # that is, commit was made by someone who preferred L
 798         }
 799         return $classify->(qw(Pseudomerge),
 800                            SubType => qw(Ambiguous),
 801                            Contributor => $bytime[0],
 802                            Overwritten => [ $bytime[1] ]);
 803     }
 804     foreach my $p (@p) {
 805         my ($p_h, $p_m) = get_commit $p->{CommitId};
 806         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 807         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 808     }
 809     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 810     my $m2 = $r->{Msg};
 811     if (!(grep { !$_->{IsOrigin} } @p) and
 812         (@orig_ps >= @p - 1) and
 813         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 814         $r->{NewMsg} = $m2;
 815         return $classify->(qw(DgitImportUnpatched),
 816                            OrigParents => \@orig_ps);
 817     }
 818
 819     if (@p == 2 and
 820         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 821         # xxx ^ metadata tag needs adding to (5)
 822         return $classify->("MergedBreakwaters");
 823     }
 824     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 825         return $unknown->("unknown kind of merge from $1");
 826     }
 827     if (@p > 2) {
 828         return $unknown->("octopus merge");
 829     }
 830
 831     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 832         return $unknown->("general two-parent merge");
 833     }
 834
 835     return $classify->("VanillaMerge");
 836 }
 837
 838 sub keycommits ($;$$$$$);
 839
 840 sub mergedbreakwaters_anchor ($) {
 841     my ($cl) = @_;
 842     my $best_anchor;
 843     foreach my $p (@{ $cl->{Parents} }) {
 844         my ($panchor, $pbw) = keycommits $p->{CommitId},
 845             undef,undef,undef,undef, 1;
 846         $best_anchor = $panchor
 847             if !defined $best_anchor
 848             or is_fast_fwd $best_anchor, $panchor;
 849         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 850             unless is_fast_fwd $panchor, $best_anchor;
 851     }
 852     return $best_anchor;
 853 }
 854
 855 sub keycommits ($;$$$$$) {
 856     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 857     # => ($anchor, $breakwater)
 858
 859     # $unclean->("unclean-$tagsfx", $msg, $cl)
 860     # $furniture->("unclean-$tagsfx", $msg, $cl)
 861     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 862     #   is callled for each situation or commit that
 863     #   wouldn't be found in a laundered branch
 864     # $furniture is for furniture commits such as might be found on an
 865     #   interchange branch (pseudomerge, d/patches, changelog)
 866     # $trouble is for things whnich prevent the return of
 867     #   anchor and breakwater information; if that is ignored,
 868     #   then keycommits returns (undef, undef) instead.
 869     # $fatal is for unprocessable commits, and should normally cause
 870     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 871     #
 872     # If $claimed_bw, this is supposed to be a breakwater commit.
 873     #
 874     # If a callback is undef, fail is called instead.
 875     # If a callback is defined but false, the situation is ignored.
 876     # Callbacks may say:
 877     #   no warnings qw(exiting); last;
 878     # if the answer is no longer wanted.
 879
 880     my ($anchor, $breakwater);
 881     $breakwater = $head if $claimed_bw;
 882     my $clogonly;
 883     my $cl;
 884     my $found_pm;
 885     $fatal //= sub { fail $_[1]; };
 886     my $x = sub {
 887         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 888         my $why = $mainwhy.$xwhy;
 889         my $m = "branch needs laundering (run git-debrebase): $why";
 890         fail $m unless defined $cb;
 891         return unless $cb;
 892         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 893     };
 894     my $found_anchor = sub {
 895         ($anchor) = @_;
 896         $breakwater //= $clogonly;
 897         $breakwater //= $head;
 898         no warnings qw(exiting);
 899         last;
 900     };
 901     for (;;) {
 902         $cl = classify $head;
 903         my $ty = $cl->{Type};
 904         if ($ty eq 'Packaging') {
 905             $breakwater //= $clogonly;
 906             $breakwater //= $head;
 907         } elsif ($ty eq 'Changelog') {
 908             # this is going to count as the tip of the breakwater
 909             # only if it has no upstream stuff before it
 910             $clogonly //= $head;
 911         } elsif ($ty eq 'Anchor' or
 912                  $ty eq 'TreatAsAnchor' or
 913                  $ty eq 'BreakwaterStart') {
 914             $found_anchor->($head);
 915         } elsif ($ty eq 'Upstream') {
 916             $x->($unclean, 'ordering',
 917  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 918                 if defined $breakwater;
 919             $clogonly = undef;
 920             $breakwater = undef;
 921         } elsif ($ty eq 'Mixed') {
 922             $x->($unclean, 'mixed',
 923                  "found mixed upstream/packaging commit"," ($head)");
 924             $clogonly = undef;
 925             $breakwater = undef;
 926         } elsif ($ty eq 'Pseudomerge' or
 927                  $ty eq 'AddPatches') {
 928             my $found_pm = 1;
 929             $x->($furniture, (lc $ty),
 930                  "found interchange bureaucracy commit ($ty)"," ($head)");
 931         } elsif ($ty eq 'DgitImportUnpatched') {
 932             if ($found_pm) {
 933                 $x->($trouble, 'dgitimport',
 934                      "found dgit dsc import"," ($head)");
 935                 return (undef,undef);
 936             } else {
 937                 $x->($fatal, 'unprocessable',
 938                      "found bare dgit dsc import with no prior history",
 939                      " ($head)");
 940                 return (undef,undef);
 941             }
 942         } elsif ($ty eq 'VanillaMerge') {
 943             $x->($trouble, 'vanillamerge',
 944                  "found vanilla merge"," ($head)");
 945             return (undef,undef);
 946         } elsif ($ty eq 'MergedBreakwaters') {
 947             $found_anchor->(mergedbreakwaters_anchor $cl);
 948         } else {
 949             $x->($fatal, 'unprocessable',
 950                  "found unprocessable commit, cannot cope: $cl->{Why}",
 951                  " ($head)");
 952             return (undef,undef);
 953         }
 954         $head = $cl->{Parents}[0]{CommitId};
 955     }
 956     return ($anchor, $breakwater);
 957 }
 958
 959 sub walk ($;$$$);
 960 sub walk ($;$$$) {
 961     my ($input,
 962         $nogenerate,$report, $report_lprefix) = @_;
 963     # => ($tip, $breakwater_tip, $last_anchor)
 964     # (or nothing, if $nogenerate)
 965
 966     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 967     $report_lprefix //= '';
 968
 969     # go through commits backwards
 970     # we generate two lists of commits to apply:
 971     # breakwater branch and upstream patches
 972     my (@brw_cl, @upp_cl, @processed);
 973     my %found;
 974     my $upp_limit;
 975     my @pseudomerges;
 976
 977     my $cl;
 978     my $xmsg = sub {
 979         my ($prose, $info) = @_;
 980         my $ms = $cl->{Msg};
 981         chomp $ms;
 982         $info //= '';
 983         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 984         return (Msg => $ms);
 985     };
 986     my $rewrite_from_here = sub {
 987         my ($cl) = @_;
 988         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 989         push @$cl, $sp_cl;
 990         push @processed, $sp_cl;
 991     };
 992     my $cur = $input;
 993
 994     my $prdelim = "";
 995     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 996
 997     my $prline = sub {
 998         return unless $report;
 999         print $report $prdelim, $report_lprefix, @_;
1000         $prdelim = "\n";
1001     };
1002
1003     my $bomb = sub { # usage: return $bomb->();
1004         print $report " Unprocessable" if $report;
1005         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1006         $prprdelim->();
1007         if ($nogenerate) {
1008             return (undef,undef);
1009         }
1010         fail "found unprocessable commit, cannot cope".
1011             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1012             " (commit $cur) (d.".
1013             (join ' ', map { sprintf "%#x", $_->{Differs} }
1014              @{ $cl->{Parents} }).
1015                  ")";
1016     };
1017
1018     my $build;
1019     my $breakwater;
1020
1021     my $build_start = sub {
1022         my ($msg, $parent) = @_;
1023         $prline->(" $msg");
1024         $build = $parent;
1025         no warnings qw(exiting); last;
1026     };
1027
1028     my $nomerge = sub {
1029         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1030     };
1031
1032     my $last_anchor;
1033
1034     for (;;) {
1035         $cl = classify $cur;
1036         my $ty = $cl->{Type};
1037         my $st = $cl->{SubType};
1038         $prline->("$cl->{CommitId} $cl->{Type}");
1039         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1040         push @processed, $cl;
1041         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1042         if ($ty eq 'AddPatches') {
1043             $cur = $p0;
1044             $rewrite_from_here->(\@upp_cl);
1045             next;
1046         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1047             push @brw_cl, $cl;
1048             $cur = $p0;
1049             next;
1050         } elsif ($ty eq 'BreakwaterStart') {
1051             $last_anchor = $cur;
1052             $build_start->('FirstPackaging', $cur);
1053         } elsif ($ty eq 'Upstream') {
1054             push @upp_cl, $cl;
1055             $cur = $p0;
1056             next;
1057         } elsif ($ty eq 'Mixed') {
1058             my $queue = sub {
1059                 my ($q, $wh) = @_;
1060                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1061                 push @$q, $cls;
1062             };
1063             $queue->(\@brw_cl, "debian");
1064             $queue->(\@upp_cl, "upstream");
1065             $rewrite_from_here->(\@brw_cl);
1066             $cur = $p0;
1067             next;
1068         } elsif ($ty eq 'Pseudomerge') {
1069             my $contrib = $cl->{Contributor}{CommitId};
1070             print $report " Contributor=$contrib" if $report;
1071             push @pseudomerges, $cl;
1072             $rewrite_from_here->(\@upp_cl);
1073             $cur = $contrib;
1074             next;
1075         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1076             $last_anchor = $cur;
1077             $build_start->("Anchor", $cur);
1078         } elsif ($ty eq 'DgitImportUnpatched') {
1079             my $pm = $pseudomerges[-1];
1080             if (defined $pm) {
1081                 # To an extent, this is heuristic.  Imports don't have
1082                 # a useful history of the debian/ branch.  We assume
1083                 # that the first pseudomerge after an import has a
1084                 # useful history of debian/, and ignore the histories
1085                 # from later pseudomerges.  Often the first pseudomerge
1086                 # will be the dgit import of the upload to the actual
1087                 # suite intended by the non-dgit NMUer, and later
1088                 # pseudomerges may represent in-archive copies.
1089                 my $ovwrs = $pm->{Overwritten};
1090                 printf $report " PM=%s \@Overwr:%d",
1091                     $pm->{CommitId}, (scalar @$ovwrs)
1092                     if $report;
1093                 if (@$ovwrs != 1) {
1094                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1095                     return $bomb->();
1096                 }
1097                 my $ovwr = $ovwrs->[0]{CommitId};
1098                 printf $report " Overwr=%s", $ovwr if $report;
1099                 # This import has a tree which is just like a
1100                 # breakwater tree, but it has the wrong history.  It
1101                 # ought to have the previous breakwater (which the
1102                 # pseudomerge overwrote) as an ancestor.  That will
1103                 # make the history of the debian/ files correct.  As
1104                 # for the upstream version: either it's the same as
1105                 # was ovewritten (ie, same as the previous
1106                 # breakwater), in which case that history is precisely
1107                 # right; or, otherwise, it was a non-gitish upload of a
1108                 # new upstream version.  We can tell these apart by
1109                 # looking at the tree of the supposed upstream.
1110                 push @brw_cl, {
1111                     %$cl,
1112                     SpecialMethod => 'DgitImportDebianUpdate',
1113                     $xmsg->("convert dgit import: debian changes")
1114                 }, {
1115                     %$cl,
1116                     SpecialMethod => 'DgitImportUpstreamUpdate',
1117                     $xmsg->("convert dgit import: upstream update",
1118                             " anchor")
1119                 };
1120                 $prline->(" Import");
1121                 $rewrite_from_here->(\@brw_cl);
1122                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1123                 $cur = $ovwr;
1124                 next;
1125             } else {
1126                 # Everything is from this import.  This kind of import
1127                 # is already nearly in valid breakwater format, with the
1128                 # patches as commits.  Unfortunately it contains
1129                 # debian/patches/.
1130                 printdebug "*** WALK BOMB bare dgit import\n";
1131                 $cl->{Why} = "bare dgit dsc import";
1132                 return $bomb->();
1133             }
1134             die "$ty ?";
1135         } elsif ($ty eq 'MergedBreakwaters') {
1136             $last_anchor = mergedbreakwaters_anchor $cl;
1137             $build_start->(' MergedBreakwaters', $cur);
1138             last;
1139         } elsif ($ty eq 'VanillaMerge') {
1140             # User may have merged unstitched branch(es).  We will
1141             # have now lost what ffq-prev was then (since the later
1142             # pseudomerge may introduce further changes).  The effect
1143             # of resolving such a merge is that we may have to go back
1144             # further in history to find a merge base, since the one
1145             # which was reachable via ffq-prev is no longer findable.
1146             # This is suboptimal, but if it all works we'll have done
1147             # the right thing.
1148             # xxx we should warn the user in the docs about this
1149
1150             my $ok=1;
1151             my $best_anchor;
1152             # We expect to find a dominating anchor amongst the
1153             # inputs' anchors.  That will be the new anchor.
1154             #
1155             # More complicated is finding a merge base for the
1156             # breakwaters.  We need a merge base that is a breakwater
1157             # commit.  The ancestors of breakwater commits are more
1158             # breakwater commits and possibly upstream commits and the
1159             # ancestors of those upstream.  Upstreams might have
1160             # arbitrary ancestors.  But any upstream commit U is
1161             # either included in both anchors, in which case the
1162             # earlier anchor is a better merge base than any of U's
1163             # ancestors; or U is not included in the older anchor, in
1164             # which case U is not an ancestor of the vanilla merge at
1165             # all.  So no upstream commit, nor any ancestor thereof,
1166             # is a best merge base.  As for non-breakwater Debian
1167             # commits: these are never ancestors of any breakwater.
1168             #
1169             # So any best merge base as found by git-merge-base
1170             # is a suitable breakwater anchor.  Usually there will
1171             # be only one.
1172
1173             printdebug "*** MERGE\n";
1174
1175             my @bwbcmd = (@git, qw(merge-base));
1176             my @ibcmd = (@git, qw(merge-base --all));
1177             my $might_be_in_bw = 1;
1178
1179             my $ps = $cl->{Parents};
1180
1181             foreach my $p (@$ps) {
1182                 $prline->(" VanillaMerge ".$p->{Ix});
1183                 $prprdelim->();
1184                 my ($ptip, $pbw, $panchor) =
1185                     walk $p->{CommitId}, 0, $report,
1186                          $report_lprefix.'  ';
1187                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1188                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1189                 $p->{Anchor} = $panchor;
1190
1191                 $best_anchor = $panchor if
1192                     !defined $best_anchor or
1193                     is_fast_fwd $best_anchor, $panchor;
1194
1195                 printdebug " MERGE BA best=".($best_anchor//'-').
1196                     " p=$panchor\n";
1197             }
1198
1199             foreach my $p (@$ps) {
1200                 $prline->(" VanillaMerge ".$p->{Ix});
1201                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1202                     $nomerge->('divergent anchors');
1203                 } elsif ($p->{Anchor} eq $best_anchor) {
1204                     print $report " SameAnchor" if $report;
1205                 } else {
1206                     print $report " SupersededAnchor" if $report;
1207                 }
1208                 if ($p->{Breakwater} eq $p->{CommitId}) {
1209                     # this parent commit was its own breakwater,
1210                     # ie it is part of the breakwater
1211                     print $report " Breakwater" if $report;
1212                 } else {
1213                     $might_be_in_bw = 0;
1214                 }
1215                 push @bwbcmd, $p->{Breakwater};
1216                 push @ibcmd, $p->{CommitId};
1217             }
1218
1219             if ($ok && $might_be_in_bw) {
1220                 # We could rewrite this to contaion the metadata
1221                 # declaring it to be MergedBreakwaters, but
1222                 # unnecessarily rewriting a merge seems unhelpful.
1223                 $prline->(" VanillaMerge MergedBreakwaters");
1224                 $last_anchor = $best_anchor;
1225                 $build_start->('MergedBreakwaters', $cur);
1226             }
1227
1228             my $bwb = cmdoutput @bwbcmd;
1229
1230             # OK, now we have a breakwater base, but we need the merge
1231             # base for the interchange branch because we need the delta
1232             # queue.
1233             #
1234             # This a the best merge base of our inputs which has the
1235             # breakwater merge base as an ancestor.
1236
1237             my @ibs =
1238                 grep /./,
1239                 split /\n/,
1240                 cmdoutput @ibcmd;
1241
1242             @ibs or confess 'internal error, expected anchor at least ?';
1243
1244             my $ib;
1245             foreach my $tibix (0..$#ibs) {
1246                 my $tib = $ibs[$tibix];
1247                 my $ff = is_fast_fwd $bwb, $tib;
1248                 next unless $ff;
1249                 next if $ib;
1250                 $ib = $tib;
1251             }
1252
1253             $ib or $nomerge->("no suitable interchange merge base");
1254
1255             $prline->("  VanillaMerge Base");
1256             $prprdelim->();
1257             my ($btip, $bbw, $banchor) =
1258                 walk $ib, 0, $report, $report_lprefix.'  ';
1259
1260             my $ibinfo = { SeriesTip => $btip,
1261                            SeriesBase => $bbw,
1262                            Anchor => $banchor };
1263             $bbw eq $bwb
1264                 or $nomerge->("interchange merge-base ($ib)'s".
1265                               " breakwater ($bbw)".
1266                               " != breakwaters' merge-base ($bwb)");
1267             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1268                  or $nomerge->("interchange merge-base ($ib)'s".
1269                                " anchor ($ibinfo->{SeriesBase})".
1270                                " != any merge input's anchor (".
1271                                (join ' ', map { $_->{Anchor} } @$ps).
1272                                ")");
1273
1274
1275             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1276             $cl->{MergeBestAnchor} = $best_anchor;
1277             push @brw_cl, {
1278                 %$cl,
1279                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1280                 $xmsg->('constructed from vanilla merge',
1281                         ' merged-breakwater'),
1282             };
1283             push @upp_cl, {
1284                 %$cl,
1285                 SpecialMethod => 'MergeMergeSeries',
1286             };
1287             $build_start->('MergeBreakwaters', $cur);
1288         } else {
1289             printdebug "*** WALK BOMB unrecognised\n";
1290             return $bomb->();
1291         }
1292     }
1293     $prprdelim->();
1294
1295     printdebug "*** WALK prep done cur=$cur".
1296         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1297
1298     return if $nogenerate;
1299
1300     # Now we build it back up again
1301
1302     fresh_workarea();
1303
1304     my $rewriting = 0;
1305
1306     my $read_tree_upstream = sub {
1307         my ($treeish) = @_;
1308         read_tree_upstream $treeish, 0, $build;
1309     };
1310
1311     $#upp_cl = $upp_limit if defined $upp_limit;
1312
1313     my $committer_authline = calculate_committer_authline();
1314
1315     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1316
1317     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1318
1319     in_workarea sub {
1320         mkdir $rd or $!==EEXIST or die $!;
1321         my $current_method;
1322         runcmd @git, qw(read-tree), $build;
1323         foreach my $cl (qw(Debian), (reverse @brw_cl),
1324                         { SpecialMethod => 'RecordBreakwaterTip' },
1325                         qw(Upstream), (reverse @upp_cl)) {
1326             if (!ref $cl) {
1327                 $current_method = $cl;
1328                 next;
1329             }
1330             my $method = $cl->{SpecialMethod} // $current_method;
1331             my @parents = ($build);
1332             my $cltree = $cl->{CommitId};
1333             printdebug "WALK BUILD ".($cltree//'undef').
1334                 " $method (rewriting=$rewriting)\n";
1335             if ($method eq 'Debian') {
1336                 read_tree_debian($cltree);
1337             } elsif ($method eq 'Upstream') {
1338                 $read_tree_upstream->($cltree);
1339             } elsif ($method eq 'StartRewrite') {
1340                 $rewriting = 1;
1341                 next;
1342             } elsif ($method eq 'RecordBreakwaterTip') {
1343                 $breakwater = $build;
1344                 next;
1345             } elsif ($method eq 'DgitImportDebianUpdate') {
1346                 read_tree_debian($cltree);
1347             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1348                 confess unless $rewriting;
1349                 my $differs = (get_differs $build, $cltree);
1350                 next unless $differs & D_UPS;
1351                 $read_tree_upstream->($cltree);
1352                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1353             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1354                 print "Found a general merge, will try to tidy it up.\n";
1355                 $rewriting = 1;
1356                 $read_tree_upstream->($cl->{MergeBestAnchor});
1357                 $read_tree_upstream->($cl->{MergeBestAnchor});
1358                 read_tree_debian($cltree);
1359                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1360             } elsif ($method eq 'MergeMergeSeries') {
1361                 print "Running merge resolution for $cl->{CommitId}...\n";
1362                 $build = merge_series
1363                     $build,
1364                     $cl->{MergeInterchangeBaseInfo},
1365                     @{ $cl->{Parents} };
1366                 $last_anchor = $cl->{MergeBestAnchor};
1367
1368                 # Check for mismerges:
1369                 my $check = sub {
1370                     my ($against, $allow, $what) = @_;
1371                     my $differs = get_differs $build, $against;
1372                     $nomerge->(sprintf
1373        "merge misresolved: %s are not the same (%s %s d.%#x)",
1374                                $what, $against, $build, $differs)
1375                         if $differs & ~($allow | D_PAT_ADD);
1376                 };
1377
1378                 # Breakwater changes which were in each side of the
1379                 # merge will have been incorporated into the
1380                 # MergeCreateMergedBreakwaters output.  Because the
1381                 # upstream series was rebased onto the new breakwater,
1382                 # so should all of the packaging changes which were in
1383                 # the input.
1384                 $check->($input, D_UPS, 'debian files');
1385
1386                 # Upstream files are merge_series, which ought to
1387                 # have been identical to the original merge.
1388                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1389
1390                 print "Merge resolution successful.\n";
1391                 next;
1392             } else {
1393                 confess "$method ?";
1394             }
1395             if (!$rewriting) {
1396                 my $procd = (pop @processed) // 'UNDEF';
1397                 if ($cl ne $procd) {
1398                     $rewriting = 1;
1399                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1400                 }
1401             }
1402             my $newtree = cmdoutput @git, qw(write-tree);
1403             my $ch = $cl->{Hdr};
1404             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1405             $ch =~ s{^parent .*\n}{}mg;
1406             $ch =~ s{(?=^author)}{
1407                 join '', map { "parent $_\n" } @parents
1408             }me or confess "$ch ?";
1409             if ($rewriting) {
1410                 $ch =~ s{^committer .*$}{$committer_authline}m
1411                     or confess "$ch ?";
1412             }
1413             my $cf = "$rd/m$rewriting";
1414             open CD, ">", $cf or die $!;
1415             print CD $ch, "\n", $cl->{Msg} or die $!;
1416             close CD or die $!;
1417             my @cmd = (@git, qw(hash-object));
1418             push @cmd, qw(-w) if $rewriting;
1419             push @cmd, qw(-t commit), $cf;
1420             my $newcommit = cmdoutput @cmd;
1421             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1422             $build = $newcommit;
1423             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1424                 $last_anchor = $cur;
1425             }
1426         }
1427     };
1428
1429     my $final_check = get_differs $build, $input;
1430     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1431         if $final_check & ~D_PAT_ADD;
1432
1433     my @r = ($build, $breakwater, $last_anchor);
1434     printdebug "*** WALK RETURN @r\n";
1435     return @r
1436 }
1437
1438 sub get_head () {
1439     git_check_unmodified();
1440     return git_rev_parse qw(HEAD);
1441 }
1442
1443 sub update_head ($$$) {
1444     my ($old, $new, $mrest) = @_;
1445     push @deferred_updates, "update HEAD $new $old";
1446     run_deferred_updates $mrest;
1447 }
1448
1449 sub update_head_checkout ($$$) {
1450     my ($old, $new, $mrest) = @_;
1451     update_head $old, $new, $mrest;
1452     runcmd @git, qw(reset --hard);
1453 }
1454
1455 sub update_head_postlaunder ($$$) {
1456     my ($old, $tip, $reflogmsg) = @_;
1457     return if $tip eq $old;
1458     print "git-debrebase: laundered (head was $old)\n";
1459     update_head $old, $tip, $reflogmsg;
1460     # no tree changes except debian/patches
1461     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1462 }
1463
1464 sub currently_rebasing() {
1465     foreach (qw(rebase-merge rebase-apply)) {
1466         return 1 if stat_exists "$maindir_gitdir/$_";
1467     }
1468     return 0;
1469 }
1470
1471 sub bail_if_rebasing() {
1472     fail "you are in the middle of a git-rebase already"
1473         if currently_rebasing();
1474 }
1475
1476 sub do_launder_head ($) {
1477     my ($reflogmsg) = @_;
1478     my $old = get_head();
1479     record_ffq_auto();
1480     my ($tip,$breakwater) = walk $old;
1481     snags_maybe_bail();
1482     update_head_postlaunder $old, $tip, $reflogmsg;
1483     return ($tip,$breakwater);
1484 }
1485
1486 sub cmd_launder_v0 () {
1487     badusage "no arguments to launder-v0 allowed" if @ARGV;
1488     my $old = get_head();
1489     my ($tip,$breakwater,$last_anchor) = walk $old;
1490     update_head_postlaunder $old, $tip, 'launder';
1491     printf "# breakwater tip\n%s\n", $breakwater;
1492     printf "# working tip\n%s\n", $tip;
1493     printf "# last anchor\n%s\n", $last_anchor;
1494 }
1495
1496 sub defaultcmd_rebase () {
1497     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1498     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1499     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1500 }
1501
1502 sub cmd_analyse () {
1503     badusage "analyse does not support any options"
1504         if @ARGV and $ARGV[0] =~ m/^-/;
1505     badusage "too many arguments to analyse" if @ARGV>1;
1506     my ($old) = @ARGV;
1507     if (defined $old) {
1508         $old = git_rev_parse $old;
1509     } else {
1510         $old = git_rev_parse 'HEAD';
1511     }
1512     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1513     STDOUT->error and die $!;
1514 }
1515
1516 sub ffq_prev_branchinfo () {
1517     my $current = git_get_symref();
1518     return gdr_ffq_prev_branchinfo($current);
1519 }
1520
1521 sub ffq_check ($;$$) {
1522     # calls $ff and/or $notff zero or more times
1523     # then returns either (status,message) where status is
1524     #    exists
1525     #    detached
1526     #    weird-symref
1527     #    notbranch
1528     # or (undef,undef, $ffq_prev,$gdrlast)
1529     # $ff and $notff are called like this:
1530     #   $ff->("message for stdout\n");
1531     #   $notff->('snag-name', $message);
1532     # normally $currentval should be HEAD
1533     my ($currentval, $ff, $notff) =@_;
1534
1535     $ff //= sub { print $_[0] or die $!; };
1536     $notff //= \&snag;
1537
1538     my ($status, $message, $current, $ffq_prev, $gdrlast)
1539         = ffq_prev_branchinfo();
1540     return ($status, $message) unless $status eq 'branch';
1541
1542     my $exists = git_get_ref $ffq_prev;
1543     return ('exists',"$ffq_prev already exists") if $exists;
1544
1545     return ('not-branch', 'HEAD symref is not to refs/heads/')
1546         unless $current =~ m{^refs/heads/};
1547     my $branch = $';
1548
1549     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1550     my %checked;
1551
1552     printdebug "ffq check_specs @check_specs\n";
1553
1554     my $check = sub {
1555         my ($lrref, $desc) = @_;
1556         printdebug "ffq might check $lrref ($desc)\n";
1557         my $invert;
1558         for my $chk (@check_specs) {
1559             my $glob = $chk;
1560             $invert = $glob =~ s{^[!^]}{};
1561             last if fnmatch $glob, $lrref;
1562         }
1563         return if $invert;
1564         my $lrval = git_get_ref $lrref;
1565         return unless length $lrval;
1566
1567         if (is_fast_fwd $lrval, $currentval) {
1568             $ff->("OK, you are ahead of $lrref\n");
1569             $checked{$lrref} = 1;
1570         } elsif (is_fast_fwd $currentval, $lrval) {
1571             $checked{$lrref} = -1;
1572             $notff->('behind', "you are behind $lrref, divergence risk");
1573         } else {
1574             $checked{$lrref} = -1;
1575             $notff->('diverged', "you have diverged from $lrref");
1576         }
1577     };
1578
1579     my $merge = cfg "branch.$branch.merge",1;
1580     if (defined $merge and $merge =~ m{^refs/heads/}) {
1581         my $rhs = $';
1582         printdebug "ffq merge $rhs\n";
1583         my $check_remote = sub {
1584             my ($remote, $desc) = @_;
1585             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1586             return unless defined $remote;
1587             $check->("refs/remotes/$remote/$rhs", $desc);
1588         };
1589         $check_remote->((scalar cfg "branch.$branch.remote",1),
1590                         'remote fetch/merge branch');
1591         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1592                         (scalar cfg "branch.$branch.pushDefault",1),
1593                         'remote push branch');
1594     }
1595     if ($branch =~ m{^dgit/}) {
1596         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1597     } elsif ($branch =~ m{^master$}) {
1598         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1599     }
1600     return (undef, undef, $ffq_prev, $gdrlast);
1601 }
1602
1603 sub record_ffq_prev_deferred () {
1604     # => ('status', "message")
1605     # 'status' may be
1606     #    deferred          message is undef
1607     #    exists
1608     #    detached
1609     #    weird-symref
1610     #    notbranch
1611     # if not ff from some branch we should be ff from, is an snag
1612     # if "deferred", will have added something about that to
1613     #   @deferred_update_messages, and also maybe printed (already)
1614     #   some messages about ff checks
1615     bail_if_rebasing();
1616     my $currentval = get_head();
1617
1618     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1619     return ($status,$message) if defined $status;
1620
1621     snags_maybe_bail();
1622
1623     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1624     push @deferred_updates, "delete $gdrlast";
1625     push @deferred_update_messages, "Recorded previous head for preservation";
1626     return ('deferred', undef);
1627 }
1628
1629 sub record_ffq_auto () {
1630     my ($status, $message) = record_ffq_prev_deferred();
1631     if ($status eq 'deferred' || $status eq 'exists') {
1632     } else {
1633         snag $status, "could not record ffq-prev: $message";
1634         snags_maybe_bail();
1635     }
1636 }
1637
1638 sub ffq_prev_info () {
1639     bail_if_rebasing();
1640     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1641     my ($status, $message, $current, $ffq_prev, $gdrlast)
1642         = ffq_prev_branchinfo();
1643     if ($status ne 'branch') {
1644         snag $status, "could not check ffq-prev: $message";
1645         snags_maybe_bail();
1646     }
1647     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1648     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1649 }
1650
1651 sub stitch ($$$$$) {
1652     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1653
1654     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1655
1656     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1657         my $differs = get_differs $old_head, $ffq_prev_commitish;
1658         unless ($differs & ~D_PAT_ADD) {
1659             # ffq-prev is ahead of us, and the only tree changes it has
1660             # are possibly addition of things in debian/patches/.
1661             # Just wind forwards rather than making a pointless pseudomerge.
1662             push @deferred_updates,
1663                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1664             update_head_checkout $old_head, $ffq_prev_commitish,
1665                 "stitch (fast forward)";
1666             return;
1667         }
1668     }
1669     fresh_workarea();
1670     # We make pseudomerges with L as the contributing parent.
1671     # This makes git rev-list --first-parent work properly.
1672     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1673         'Declare fast forward / record previous work',
1674         "[git-debrebase pseudomerge: $prose]",
1675     ];
1676     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1677     update_head $old_head, $new_head, "stitch: $prose";
1678 }
1679
1680 sub do_stitch ($;$) {
1681     my ($prose, $unclean) = @_;
1682
1683     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1684     if (!$ffq_prev_commitish) {
1685         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1686         return;
1687     }
1688     my $dangling_head = get_head();
1689
1690     keycommits $dangling_head, $unclean,$unclean,$unclean;
1691     snags_maybe_bail();
1692
1693     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1694 }
1695
1696 sub upstream_commitish_search ($$) {
1697     my ($upstream_version, $tried) = @_;
1698     # todo: at some point maybe use git-deborig to do this
1699     foreach my $tagpfx ('', 'v', 'upstream/') {
1700         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1701         my $new_upstream = git_get_ref "refs/tags/$tag";
1702         push @$tried, $tag;
1703         return $new_upstream if length $new_upstream;
1704     }
1705 }
1706
1707 sub resolve_upstream_version ($$) {
1708     my ($new_upstream, $upstream_version) = @_;
1709
1710     if (!defined $new_upstream) {
1711         my @tried;
1712         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1713         if (!length $new_upstream) {
1714             fail "Could not determine appropriate upstream commitish.\n".
1715                 " (Tried these tags: @tried)\n".
1716                 " Check version, and specify upstream commitish explicitly.";
1717         }
1718     }
1719     $new_upstream = git_rev_parse $new_upstream;
1720
1721     return $new_upstream;
1722 }
1723
1724 sub cmd_new_upstream () {
1725     # automatically and unconditionally launders before rebasing
1726     # if rebase --abort is used, laundering has still been done
1727
1728     my %pieces;
1729
1730     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1731
1732     # parse args - low commitment
1733     my $spec_version = shift @ARGV;
1734     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1735     fail "bad version number \`$spec_version'" unless defined $new_version;
1736     if ($new_version->is_native()) {
1737         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1738     }
1739
1740     my $new_upstream = shift @ARGV;
1741     my $new_upstream_version = upstreamversion  $new_version;
1742     $new_upstream =
1743         resolve_upstream_version $new_upstream, $new_upstream_version;
1744
1745     record_ffq_auto();
1746
1747     my $piece = sub {
1748         my ($n, @x) = @_; # may be ''
1749         my $pc = $pieces{$n} //= {
1750             Name => $n,
1751             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1752         };
1753         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1754         $pc;
1755     };
1756
1757     my @newpieces;
1758     my $newpiece = sub {
1759         my ($n, @x) = @_; # may be ''
1760         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1761         push @newpieces, $pc;
1762     };
1763
1764     $newpiece->('',
1765         OldIx => 0,
1766         New => $new_upstream,
1767     );
1768     while (@ARGV && $ARGV[0] !~ m{^-}) {
1769         my $n = shift @ARGV;
1770
1771         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1772             unless @ARGV && $ARGV[0] !~ m{^-};
1773
1774         my $c = git_rev_parse shift @ARGV;
1775         die unless $n =~ m/^$extra_orig_namepart_re$/;
1776         $newpiece->($n, New => $c);
1777     }
1778
1779     # now we need to investigate the branch this generates the
1780     # laundered version but we don't switch to it yet
1781     my $old_head = get_head();
1782     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1783
1784     my $old_bw_cl = classify $old_bw;
1785     my $old_anchor_cl = classify $old_anchor;
1786     my $old_upstream;
1787     if (!$old_anchor_cl->{OrigParents}) {
1788         snag 'anchor-treated',
1789             'old anchor is recognised due to --anchor, cannot check upstream';
1790     } else {
1791         $old_upstream = parsecommit
1792             $old_anchor_cl->{OrigParents}[0]{CommitId};
1793         $piece->('', Old => $old_upstream->{CommitId});
1794     }
1795
1796     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1797         if ($old_upstream->{Msg} =~
1798  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1799            ) {
1800             my @oldpieces = (split / /, $1);
1801             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1802             if ($old_n_parents != @oldpieces &&
1803                 $old_n_parents != @oldpieces + 1) {
1804                 snag 'upstream-confusing', sprintf
1805                     "previous upstream combine %s".
1806                     " mentions %d pieces (each implying one parent)".
1807                     " but has %d parents".
1808                     " (one per piece plus maybe a previous combine)",
1809                     $old_upstream->{CommitId},
1810                     (scalar @oldpieces),
1811                     $old_n_parents;
1812             } elsif ($oldpieces[0] ne '.') {
1813                 snag 'upstream-confusing', sprintf
1814                     "previous upstream combine %s".
1815                     " first piece is not \`.'",
1816                     $oldpieces[0];
1817             } else {
1818                 $oldpieces[0] = '';
1819                 foreach my $i (0..$#oldpieces) {
1820                     my $n = $oldpieces[$i];
1821                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1822                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1823                 }
1824             }
1825         } else {
1826             snag 'upstream-confusing',
1827                 "previous upstream $old_upstream->{CommitId} is from".
1828                " git-debrebase but not an \`upstream-combine' commit";
1829         }
1830     }
1831
1832     foreach my $pc (values %pieces) {
1833         if (!$old_upstream) {
1834             # we have complained already
1835         } elsif (!$pc->{Old}) {
1836             snag 'upstream-new-piece',
1837                 "introducing upstream piece \`$pc->{Name}'";
1838         } elsif (!$pc->{New}) {
1839             snag 'upstream-rm-piece',
1840                 "dropping upstream piece \`$pc->{Name}'";
1841         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1842             snag 'upstream-not-ff',
1843                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1844         }
1845     }
1846
1847     printdebug "%pieces = ", (dd \%pieces), "\n";
1848     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1849
1850     snags_maybe_bail();
1851
1852     my $new_bw;
1853
1854     fresh_workarea();
1855     in_workarea sub {
1856         my @upstream_merge_parents;
1857
1858         if (!any_snags()) {
1859             push @upstream_merge_parents, $old_upstream->{CommitId};
1860         }
1861
1862         foreach my $pc (@newpieces) { # always has '' first
1863             if ($pc->{Name}) {
1864                 read_tree_subdir $pc->{Name}, $pc->{New};
1865             } else {
1866                 runcmd @git, qw(read-tree), $pc->{New};
1867             }
1868             push @upstream_merge_parents, $pc->{New};
1869         }
1870
1871         # index now contains the new upstream
1872
1873         if (@newpieces > 1) {
1874             # need to make the upstream subtree merge commit
1875             $new_upstream = make_commit \@upstream_merge_parents,
1876                 [ "Combine upstreams for $new_upstream_version",
1877  ("[git-debrebase upstream-combine . ".
1878  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1879  ": new upstream]"),
1880                 ];
1881         }
1882
1883         # $new_upstream is either the single upstream commit, or the
1884         # combined commit we just made.  Either way it will be the
1885         # "upstream" parent of the anchor merge.
1886
1887         read_tree_subdir 'debian', "$old_bw:debian";
1888
1889         # index now contains the anchor merge contents
1890         $new_bw = make_commit [ $old_bw, $new_upstream ],
1891             [ "Update to upstream $new_upstream_version",
1892  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1893             ];
1894
1895         my $clogsignoff = cmdoutput qw(git show),
1896             '--pretty=format:%an <%ae>  %aD',
1897             $new_bw;
1898
1899         # Now we have to add a changelog stanza so the Debian version
1900         # is right.
1901         die if unlink "debian";
1902         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1903         unlink "debian/changelog" or $!==ENOENT or die $!;
1904         mkdir "debian" or die $!;
1905         open CN, ">", "debian/changelog" or die $!;
1906         my $oldclog = git_cat_file ":debian/changelog";
1907         $oldclog =~ m/^($package_re) \(\S+\) / or
1908             fail "cannot parse old changelog to get package name";
1909         my $p = $1;
1910         print CN <<END, $oldclog or die $!;
1911 $p ($new_version) UNRELEASED; urgency=medium
1912
1913   * Update to new upstream version $new_upstream_version.
1914
1915  -- $clogsignoff
1916
1917 END
1918         close CN or die $!;
1919         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1920
1921         # Now we have the final new breakwater branch in the index
1922         $new_bw = make_commit [ $new_bw ],
1923             [ "Update changelog for new upstream $new_upstream_version",
1924               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1925             ];
1926     };
1927
1928     # we have constructed the new breakwater. we now need to commit to
1929     # the laundering output, because git-rebase can't easily be made
1930     # to make a replay list which is based on some other branch
1931
1932     update_head_postlaunder $old_head, $old_laundered_tip,
1933         'launder for new upstream';
1934
1935     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1936     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1937         "debrebase new-upstream $new_version: rebase";
1938     runcmd @cmd;
1939     # now it's for the user to sort out
1940 }
1941
1942 sub cmd_record_ffq_prev () {
1943     badusage "no arguments allowed" if @ARGV;
1944     my ($status, $msg) = record_ffq_prev_deferred();
1945     if ($status eq 'exists' && $opt_noop_ok) {
1946         print "Previous head already recorded\n" or die $!;
1947     } elsif ($status eq 'deferred') {
1948         run_deferred_updates 'record-ffq-prev';
1949     } else {
1950         fail "Could not preserve: $msg";
1951     }
1952 }
1953
1954 sub cmd_anchor () {
1955     badusage "no arguments allowed" if @ARGV;
1956     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1957     print "$bw\n" or die $!;
1958 }
1959
1960 sub cmd_breakwater () {
1961     badusage "no arguments allowed" if @ARGV;
1962     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1963     print "$bw\n" or die $!;
1964 }
1965
1966 sub cmd_status () {
1967     badusage "no arguments allowed" if @ARGV;
1968
1969     # todo: gdr status should print divergence info
1970     # todo: gdr status should print upstream component(s) info
1971     # todo: gdr should leave/maintain some refs with this kind of info ?
1972
1973     my $oldest = { Badness => 0 };
1974     my $newest;
1975     my $note = sub {
1976         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1977         if ($oldest->{Badness} < $badness) {
1978             $oldest = $newest = undef;
1979         }
1980         $oldest = {
1981                    Badness => $badness,
1982                    CommitId => $cl->{CommitId},
1983                    OurMsg => $ourmsg,
1984                    KcMsg => $kcmsg,
1985                   };
1986         $newest //= $oldest;
1987     };
1988     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1989         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1990         sub { $note->(2, 'branch is unlaundered', @_); },
1991         sub { $note->(3, 'branch needs laundering', @_); },
1992         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1993
1994     my $prcommitinfo = sub {
1995         my ($cid) = @_;
1996         flush STDOUT or die $!;
1997         runcmd @git, qw(--no-pager log -n1),
1998             '--pretty=format:    %h %s%n',
1999             $cid;
2000     };
2001
2002     print "current branch contents, in git-debrebase terms:\n";
2003     if (!$oldest->{Badness}) {
2004         print "  branch is laundered\n";
2005     } else {
2006         print "  $oldest->{OurMsg}\n";
2007         my $printed = '';
2008         foreach my $info ($oldest, $newest) {
2009             my $cid = $info->{CommitId};
2010             next if $cid eq $printed;
2011             $printed = $cid;
2012             print "  $info->{KcMsg}\n";
2013             $prcommitinfo->($cid);
2014         }
2015     }
2016
2017     my $prab = sub {
2018         my ($cid, $what) = @_;
2019         if (!defined $cid) {
2020             print "  $what is not well-defined\n";
2021         } else {
2022             print "  $what\n";
2023             $prcommitinfo->($cid);
2024         }
2025     };
2026     print "key git-debrebase commits:\n";
2027     $prab->($anchor, 'anchor');
2028     $prab->($bw, 'breakwater');
2029
2030     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2031         ffq_prev_branchinfo();
2032
2033     print "branch and ref status, in git-debrebase terms:\n";
2034     if ($ffq_msg) {
2035         print "  $ffq_msg\n";
2036     } else {
2037         $ffq_prev = git_get_ref $ffq_prev;
2038         $gdrlast = git_get_ref $gdrlast;
2039         if ($ffq_prev) {
2040             print "  unstitched; previous tip was:\n";
2041             $prcommitinfo->($ffq_prev);
2042         } elsif (!$gdrlast) {
2043             print "  stitched? (no record of git-debrebase work)\n";
2044         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2045             print "  stitched\n";
2046         } else {
2047             print "  not git-debrebase (diverged since last stitch)\n"
2048         }
2049     }
2050     print "you are currently rebasing\n" if currently_rebasing();
2051 }
2052
2053 sub cmd_stitch () {
2054     my $prose = 'stitch';
2055     getoptions("stitch",
2056                'prose=s', \$prose);
2057     badusage "no arguments allowed" if @ARGV;
2058     do_stitch $prose, 0;
2059 }
2060 sub cmd_prepush () { cmd_stitch(); }
2061
2062 sub cmd_quick () {
2063     badusage "no arguments allowed" if @ARGV;
2064     do_launder_head 'launder for git-debrebase quick';
2065     do_stitch 'quick';
2066 }
2067
2068 sub cmd_conclude () {
2069     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2070     if (!$ffq_prev_commitish) {
2071         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2072         return;
2073     }
2074     my $dangling_head = get_head();
2075
2076     badusage "no arguments allowed" if @ARGV;
2077     do_launder_head 'launder for git-debrebase quick';
2078     do_stitch 'quick';
2079 }
2080
2081 sub cmd_scrap () {
2082     if (currently_rebasing()) {
2083         runcmd @git, qw(rebase --abort);
2084     }
2085     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2086     if (!$ffq_prev_commitish) {
2087         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2088         finish 0;
2089     }
2090     my $scrapping_head = get_head();
2091     badusage "no arguments allowed" if @ARGV;
2092     push @deferred_updates,
2093         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2094         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2095     snags_maybe_bail();
2096     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2097 }
2098
2099 sub make_patches_staged ($) {
2100     my ($head) = @_;
2101     # Produces the patches that would result from $head if it were
2102     # laundered.
2103     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2104     fresh_workarea();
2105     in_workarea sub {
2106         gbp_pq_export 'bw', $secret_bw, $secret_head;
2107     };
2108 }
2109
2110 sub make_patches ($) {
2111     my ($head) = @_;
2112     keycommits $head, 0, \&snag;
2113     make_patches_staged $head;
2114     my $out;
2115     in_workarea sub {
2116         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2117         runcmd @git, qw(read-tree), $head;
2118         read_tree_subdir 'debian/patches', $ptree;
2119         $out = make_commit [$head], [
2120             'Commit patch queue (exported by git-debrebase)',
2121             '[git-debrebase: export and commit patches]',
2122         ];
2123     };
2124     return $out;
2125 }
2126
2127 sub cmd_make_patches () {
2128     my $opt_quiet_would_amend;
2129     getoptions("make-patches",
2130                'quiet-would-amend!', \$opt_quiet_would_amend);
2131     badusage "no arguments allowed" if @ARGV;
2132     bail_if_rebasing();
2133     my $old_head = get_head();
2134     my $new = make_patches $old_head;
2135     my $d = get_differs $old_head, $new;
2136     if ($d == 0) {
2137         fail "No (more) patches to export." unless $opt_noop_ok;
2138         return;
2139     } elsif ($d == D_PAT_ADD) {
2140         snags_maybe_bail();
2141         update_head_checkout $old_head, $new, 'make-patches';
2142     } else {
2143         print STDERR failmsg
2144             "Patch export produced patch amendments".
2145             " (abandoned output commit $new).".
2146             "  Try laundering first."
2147             unless $opt_quiet_would_amend;
2148         finish 7;
2149     }
2150 }
2151
2152 sub cmd_convert_from_gbp () {
2153     badusage "want only 1 optional argument, the upstream git commitish"
2154         unless @ARGV<=1;
2155
2156     my $clogp = parsechangelog();
2157     my $version = $clogp->{'Version'}
2158         // die "missing Version from changelog";
2159
2160     my ($upstream_spec) = @ARGV;
2161
2162     my $upstream_version = upstreamversion $version;
2163     my $upstream =
2164         resolve_upstream_version($upstream_spec, $upstream_version);
2165
2166     my $old_head = get_head();
2167
2168     my $upsdiff = get_differs $upstream, $old_head;
2169     if ($upsdiff & D_UPS) {
2170         runcmd @git, qw(--no-pager diff --stat),
2171             $upstream, $old_head,
2172             qw( -- :!/debian :/);
2173         fail <<END;
2174 upstream ($upstream_spec) and HEAD are not
2175 identical in upstream files.  See diffstat above, or run
2176   git diff $upstream_spec HEAD -- :!/debian :/
2177 END
2178     }
2179
2180     if (!is_fast_fwd $upstream, $old_head) {
2181         snag 'upstream-not-ancestor',
2182             "upstream ($upstream) is not an ancestor of HEAD";
2183     } else {
2184         my $wrong = cmdoutput
2185             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2186              qw(-- :/ :!/debian));
2187         if (length $wrong) {
2188             snag 'unexpected-upstream-changes',
2189                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2190             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2191         }
2192     }
2193
2194     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2195         snag 'upstream-has-debian',
2196             "upstream ($upstream) contains debian/ directory";
2197     }
2198
2199     my $previous_dgit_view = eval {
2200         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2201         my ($lvsn, $suite);
2202         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2203             my ($stz, $desc) = @_;
2204             no warnings qw(exiting);
2205             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2206             next unless $stz->{Date};
2207             next unless $stz->{Distribution} ne 'UNRELEASED';
2208             $lvsn = $stz->{Version};
2209             $suite = $stz->{Distribution};
2210             last;
2211         };
2212         die "neither of the first two changelog entries are released\n"
2213             unless defined $lvsn;
2214         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2215         my $mtag_pat = debiantag_maintview $lvsn, '*';
2216         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2217             $mtag_pat;
2218         die "could not find suitable maintainer view tag $mtag_pat\n"
2219             unless $mtag_pat =~ m{/};
2220         is_fast_fwd $mtag, 'HEAD' or
2221             die "HEAD is not FF from maintainer tag $mtag!";
2222         my $dtag = "archive/$mtag";
2223         is_fast_fwd $mtag, $dtag or
2224             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2225         print "will stitch in dgit view, $dtag\n";
2226         git_rev_parse $dtag;
2227     };
2228     if (!$previous_dgit_view) {
2229         $@ =~ s/^\n+//;
2230         chomp $@;
2231         print STDERR "cannot stitch in dgit view: $@\n";
2232     }
2233
2234     snags_maybe_bail_early();
2235
2236     my $work;
2237
2238     fresh_workarea();
2239     in_workarea sub {
2240         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2241         # make a branch out of the patch queue - we'll want this in a mo
2242         runcmd qw(gbp pq import);
2243         # strip the patches out
2244         runcmd @git, qw(checkout -q gdr-internal~0);
2245         rm_subdir_cached 'debian/patches';
2246         $work = make_commit ['HEAD'], [
2247  'git-debrebase convert-from-gbp: drop patches from tree',
2248  'Delete debian/patches, as part of converting to git-debrebase format.',
2249  '[git-debrebase convert-from-gbp: drop patches from tree]'
2250                               ];
2251         # make the anchor merge
2252         # the tree is already exactly right
2253         $work = make_commit [$work, $upstream], [
2254  'git-debrebase import: declare upstream',
2255  'First breakwater merge.',
2256  '[git-debrebase anchor: declare upstream]'
2257                               ];
2258
2259         # rebase the patch queue onto the new breakwater
2260         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2261         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2262         $work = git_rev_parse 'HEAD';
2263
2264         if ($previous_dgit_view) {
2265             $work = make_commit [$work, $previous_dgit_view], [
2266  'git-debrebase import: declare ff from dgit archive view',
2267  '[git-debrebase pseudomerge: import-from-gbp]',
2268             ];
2269         }
2270     };
2271
2272     ffq_check $work;
2273     snags_maybe_bail();
2274     update_head_checkout $old_head, $work, 'convert-from-gbp';
2275 }
2276
2277 sub cmd_convert_to_gbp () {
2278     badusage "no arguments allowed" if @ARGV;
2279     my $head = get_head();
2280     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2281     keycommits $head, 0;
2282     my $out;
2283     make_patches_staged $head;
2284     in_workarea sub {
2285         $out = make_commit ['HEAD'], [
2286             'Commit patch queue (converted from git-debrebase format)',
2287             '[git-debrebase convert-to-gbp: commit patches]',
2288         ];
2289     };
2290     if (defined $ffq) {
2291         push @deferred_updates, "delete $ffq";
2292         push @deferred_updates, "delete $gdrlast";
2293     }
2294     snags_maybe_bail();
2295     update_head_checkout $head, $out, "convert to gbp (v0)";
2296     print <<END or die $!;
2297 git-debrebase: converted to git-buildpackage branch format
2298 git-debrebase: WARNING: do not now run "git-debrebase" any more
2299 git-debrebase: WARNING: doing so would drop all upstream patches!
2300 END
2301 }
2302
2303 sub cmd_convert_from_dgit_view () {
2304     my $clogp = parsechangelog();
2305
2306     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2307     my $do_origs = 1;
2308     my $do_tags = 1;
2309     my $always = 0;
2310     my $diagnose = 0;
2311
2312     getoptions("convert-from-dgit-view",
2313                'diagnose!', \$diagnose,
2314                'build-products-dir:s', \$bpd,
2315                'origs!', \$do_origs,
2316                'tags!', \$do_tags,
2317                'always-convert-anyway!', \$always);
2318     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2319
2320     my @upstreams;
2321
2322     if (@ARGV) {
2323         my $spec = shift @ARGV;
2324         my $commit = git_rev_parse "$spec^{commit}";
2325         push @upstreams, { Commit => $commit,
2326                            Source => "$ARGV[0], from command line",
2327                            Only => 1,
2328                          };
2329     }
2330
2331     my $head = get_head();
2332
2333     if (!$always) {
2334         my $troubles = 0;
2335         my $trouble = sub { $troubles++; };
2336         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2337         printdebug "troubles=$troubles\n";
2338         if (!$troubles) {
2339             print STDERR <<END;
2340 $us: Branch already seems to be in git-debrebase format!
2341 $us: --always-convert-anyway would do the conversion operation anyway
2342 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2343 END
2344             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2345             finish 0;
2346         }
2347     }
2348
2349     snags_maybe_bail_early();
2350
2351     my $version = upstreamversion $clogp->{Version};
2352     print STDERR "Considering possible commits corresponding to upstream:\n";
2353
2354     if (!@upstreams) {
2355         if ($do_tags) {
2356             my @tried;
2357             my $ups_tag = upstream_commitish_search $version, \@tried;
2358             if ($ups_tag) {
2359                 my $this = "git tag $tried[-1]";
2360                 push @upstreams, { Commit => $ups_tag,
2361                                    Source => $this,
2362                                  };
2363             } else {
2364                 printf STDERR
2365                     " git tag: no suitable tag found (tried %s)\n",
2366                     "@tried";
2367             }
2368         }
2369         if ($do_origs) {
2370             my $p = $clogp->{'Source'};
2371             # we do a quick check to see if there are plausible origs
2372             my $something=0;
2373             if (!opendir BPD, $bpd) {
2374                 die "$bpd: opendir: $!" unless $!==ENOENT;
2375             } else {
2376                 while ($!=0, my $f = readdir BPD) {
2377                     next unless is_orig_file_of_p_v $f, $p, $version;
2378                     printf STDERR
2379                         " orig: found what looks like a .orig, %s\n",
2380                         "$bpd/$f";
2381                     $something=1;
2382                     last;
2383                 }
2384                 die "read $bpd: $!" if $!;
2385                 closedir BPD;
2386             }
2387             if ($something) {
2388                 my $tree = cmdoutput
2389                     @dgit, qw(--build-products-dir), $bpd,
2390                     qw(print-unapplied-treeish);
2391                 fresh_workarea();
2392                 in_workarea sub {
2393                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2394                     rm_subdir_cached 'debian';
2395                     $tree = cmdoutput @git, qw(write-tree);
2396                     my $ups_synth = make_commit [], [ <<END, <<END,
2397 Import effective orig tree for upstream version $version
2398 END
2399 This includes the contents of the .orig(s), minus any debian/ directory.
2400
2401 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2402 END
2403                                                     ];
2404                     push @upstreams, { Commit => $ups_synth,
2405                                        Source => "orig(s) imported via dgit",
2406                                      };
2407                 }
2408             } else {
2409                 printf STDERR
2410                     " orig: no suitable origs found (looked for %s in %s)\n",
2411                     "${p}_".(stripeoch $version)."...", $bpd;
2412             }
2413         }
2414     }
2415
2416     my $some_patches = stat_exists 'debian/patches/series';
2417
2418     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2419
2420     my $result;
2421     foreach my $u (@upstreams) {
2422         my $work = $head;
2423         fresh_workarea();
2424         in_workarea sub {
2425             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2426             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2427             runcmd @git, qw(clean -xdff);
2428             runcmd @git, qw(checkout), $head, qw(-- debian);
2429             if ($some_patches) {
2430                 rm_subdir_cached 'debian/patches';
2431                 $work = make_commit [ $work ], [
2432  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2433  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2434  "to git-debrebase format.  Upstream changes will appear as commits.",
2435  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2436                                            ];
2437             }
2438             $work = make_commit [ $work, $u->{Commit} ], [
2439  'git-debrebase convert-from-dgit-view: declare upstream',
2440  '(Re)constructed breakwater merge.',
2441  '[git-debrebase anchor: declare upstream]'
2442                                                          ];
2443             runcmd @git, qw(checkout --quiet -b mk), $work;
2444             if ($some_patches) {
2445                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2446                 runcmd @git, qw(reset --quiet);
2447                 my @gbp_cmd = (qw(gbp pq import));
2448                 if (!$diagnose) {
2449                     my $gbp_err = "../gbp-pq-err";
2450                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2451                 }
2452                 my $r = system @gbp_cmd;
2453                 if ($r) {
2454                     printf STDERR
2455                         " %s: couldn't apply patches: gbp pq %s",
2456                         $u->{Source}, waitstatusmsg();
2457                     return;
2458                 }
2459             }
2460             my $work = git_rev_parse qw(HEAD);
2461             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2462             if (length $diffout) {
2463                 print STDERR
2464                     " $u->{Source}: applying patches gives different tree\n";
2465                 print STDERR $diffout if $diagnose;
2466                 return;
2467             }
2468             # OMG!
2469             $u->{Result} = $work;
2470             $result = $u;
2471         };
2472         last if $result;
2473     }
2474
2475     if (!$result) {
2476         fail <<END;
2477 Could not find or construct a suitable upstream commit.
2478 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2479 upstream commmit explicitly or provide suitable origs.
2480 END
2481     }
2482
2483     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2484
2485     ffq_check $result->{Result};
2486     snags_maybe_bail();
2487     update_head_checkout $head, $result->{Result},
2488         'convert-from-dgit-view';
2489 }
2490
2491 sub cmd_downstream_rebase_launder_v0 () {
2492     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2493     my ($base) = @ARGV;
2494     $base = git_rev_parse $base;
2495     my $old_head = get_head();
2496     my $current = $old_head;
2497     my $topmost_keep;
2498     for (;;) {
2499         if ($current eq $base) {
2500             $topmost_keep //= $current;
2501             print " $current BASE stop\n";
2502             last;
2503         }
2504         my $cl = classify $current;
2505         print " $current $cl->{Type}";
2506         my $keep = 0;
2507         my $p0 = $cl->{Parents}[0]{CommitId};
2508         my $next;
2509         if ($cl->{Type} eq 'Pseudomerge') {
2510             print " ^".($cl->{Contributor}{Ix}+1);
2511             $next = $cl->{Contributor}{CommitId};
2512         } elsif ($cl->{Type} eq 'AddPatches' or
2513                  $cl->{Type} eq 'Changelog') {
2514             print " strip";
2515             $next = $p0;
2516         } else {
2517             print " keep";
2518             $next = $p0;
2519             $keep = 1;
2520         }
2521         print "\n";
2522         if ($keep) {
2523             $topmost_keep //= $current;
2524         } else {
2525             die "to-be stripped changes not on top of the branch\n"
2526                 if $topmost_keep;
2527         }
2528         $current = $next;
2529     }
2530     if ($topmost_keep eq $old_head) {
2531         print "unchanged\n";
2532     } else {
2533         print "updating to $topmost_keep\n";
2534         update_head_checkout
2535             $old_head, $topmost_keep,
2536             'downstream-rebase-launder-v0';
2537     }
2538 }
2539
2540 getoptions_main
2541           ("bad options\n",
2542            "D+" => \$debuglevel,
2543            'noop-ok', => \$opt_noop_ok,
2544            'f=s' => \@snag_force_opts,
2545            'anchor=s' => \@opt_anchors,
2546            '--dgit=s' => \($dgit[0]),
2547            'force!',
2548            '-i:s' => sub {
2549                my ($opt,$val) = @_;
2550                badusage "git-debrebase: no cuddling to -i for git-rebase"
2551                    if length $val;
2552                die if $opt_defaultcmd_interactive; # should not happen
2553                $opt_defaultcmd_interactive = [ qw(-i) ];
2554                # This access to @ARGV is excessive familiarity with
2555                # Getopt::Long, but there isn't another sensible
2556                # approach.  '-i=s{0,}' does not work with bundling.
2557                push @$opt_defaultcmd_interactive, @ARGV;
2558                @ARGV=();
2559            },
2560            'help' => sub { print $usage_message or die $!; finish 0; },
2561            );
2562
2563 initdebug('git-debrebase ');
2564 enabledebug if $debuglevel;
2565
2566 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2567 chdir $toplevel or die "chdir $toplevel: $!";
2568
2569 $rd = fresh_playground "$playprefix/misc";
2570
2571 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2572
2573 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2574     defaultcmd_rebase();
2575 } else {
2576     my $cmd = shift @ARGV;
2577     my $cmdfn = $cmd;
2578     $cmdfn =~ y/-/_/;
2579     $cmdfn = ${*::}{"cmd_$cmdfn"};
2580
2581     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2582     $cmdfn->();
2583 }
2584
2585 finish 0;