git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_careful, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 $opt_careful = 0;
  57
  58 our $us = qw(git-debrebase);
  59
  60 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  61 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  62
  63 $|=1;
  64
  65 sub badusage ($) {
  66     my ($m) = @_;
  67     print STDERR "$us: bad usage: $m\n";
  68     finish 8;
  69 }
  70
  71 sub getoptions_main {
  72     my $m = shift;
  73     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  74     GetOptions @_ or badusage $m;
  75 }
  76 sub getoptions {
  77     my $sc = shift;
  78     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  79 }
  80
  81 sub cfg ($;$) {
  82     my ($k, $optional) = @_;
  83     local $/ = "\0";
  84     my @cmd = qw(git config -z);
  85     push @cmd, qw(--get-all) if wantarray;
  86     push @cmd, $k;
  87     my $out = cmdoutput_errok @cmd;
  88     if (!defined $out) {
  89         fail "missing required git config $k" unless $optional;
  90         return ();
  91     }
  92     my @l = split /\0/, $out;
  93     return wantarray ? @l : $l[0];
  94 }
  95
  96 memoize('cfg');
  97
  98 sub dd ($) {
  99     my ($v) = @_;
 100     my $dd = new Data::Dumper [ $v ];
 101     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 102     return Dump $dd;
 103 }
 104
 105 sub get_commit ($) {
 106     my ($objid) = @_;
 107     my $data = (git_cat_file $objid, 'commit');
 108     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 109     return ($`,$');
 110 }
 111
 112 sub D_UPS ()      { 0x02; } # upstream files
 113 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 114 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 115 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 116 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 117 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 118
 119 our $playprefix = 'debrebase';
 120 our $rd;
 121 our $workarea;
 122
 123 our @git = qw(git);
 124 our @dgit = qw(dgit);
 125
 126 sub in_workarea ($) {
 127     my ($sub) = @_;
 128     changedir $workarea;
 129     my $r = eval { $sub->(); };
 130     { local $@; changedir $maindir; }
 131     die $@ if $@;
 132 }
 133
 134 sub fresh_workarea (;$) {
 135     my ($subdir) = @_;
 136     $subdir //= 'work';
 137     $workarea = fresh_playground "$playprefix/$subdir";
 138     in_workarea sub { playtree_setup };
 139 }
 140
 141 sub run_ref_updates_now ($$) {
 142     my ($mrest, $updates) = @_;
 143     # @$updates is a list of lines for git-update-ref, without \ns
 144
 145     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 146     debugcmd '>|', @upd_cmd;
 147     open U, "|-", @upd_cmd or die $!;
 148     foreach (@$updates) {
 149         printdebug ">= ", $_, "\n";
 150         print U $_, "\n" or die $!;
 151     }
 152     printdebug ">\$\n";
 153     close U or failedcmd @upd_cmd;
 154 }
 155
 156 our $snags_forced = 0;
 157 our $snags_tripped = 0;
 158 our $snags_summarised = 0;
 159 our @deferred_updates;
 160 our @deferred_update_messages;
 161
 162 sub merge_wreckage_cleaning ($) {
 163     my ($updates) = @_;
 164     git_for_each_ref("$wrecknoteprefix/*", sub {
 165         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 166         push @$updates, "delete $fullrefname";
 167     });
 168 }
 169
 170 sub all_snags_summarised () {
 171     $snags_forced + $snags_tripped == $snags_summarised;
 172 }
 173 sub run_deferred_updates ($) {
 174     my ($mrest) = @_;
 175
 176     confess 'dangerous internal error' unless all_snags_summarised();
 177
 178     merge_wreckage_cleaning \@deferred_updates;
 179     run_ref_updates_now $mrest, \@deferred_updates;
 180     print $_, "\n" foreach @deferred_update_messages;
 181
 182     @deferred_updates = ();
 183     @deferred_update_messages = ();
 184 }
 185
 186 sub get_tree ($) {
 187     # tree object name => ([ $name, $info ], ...)
 188     # where $name is the sort key, ie has / at end for subtrees
 189     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 190     # will crash if $x does not exist, so don't do that
 191     my ($x) = @_;
 192     our (@get_tree_memo, %get_tree_memo);
 193     my $memo = $get_tree_memo{$x};
 194     return @$memo if $memo;
 195
 196     local $debugcmd_when_debuglevel = 3;
 197     my @l;
 198     my @cmd = (qw(git ls-tree -z --full-tree --), $x);
 199     my $o = cmdoutput @cmd;
 200     $o =~ s/\0$//s;
 201     my $last = '';
 202     foreach my $l (split /\0/, $o) {
 203         my ($i, $n) = split /\t/, $l, 2;
 204         $n .= '/' if $i =~ m/^\d+ tree /;
 205         push @l, [ $n, $i ];
 206         confess "$x need $last < $n ?" unless $last lt $n;
 207     }
 208     $get_tree_memo{$x} = \@l;
 209     push @get_tree_memo, $x;
 210     if (@get_tree_memo > 10) {
 211         delete $get_tree_memo{ shift @get_tree_memo };
 212     }
 213     return @l;
 214 }
 215
 216 sub trees_diff_walk ($$$;$) {
 217     # trees_diff_walk [$all,] $x, $y, sub {... }
 218     # calls sub->($name, $ix, $iy) for each difference (with $all, each name)
 219     # $x and $y are as for get_tree
 220     # where $name, $ix, $iy are $name and $info from get_tree
 221     my $all = shift @_ if @_>=4;
 222     my ($x,$y,$call) = @_;
 223     return if !$all and $x eq $y;
 224     my @x = get_tree $x;
 225     my @y = get_tree $y;
 226     while (@x || @y) {
 227         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 228              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 229         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 230         $ix=$iy='';
 231         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 232         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 233         next if !$all and $ix eq $iy;
 234         printdebug sprintf
 235             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 236             !!$all,$x,$y, $n,$ix,$iy
 237             if $debuglevel >= 2;
 238         $call->($n, $ix, $iy);
 239     }
 240 }
 241
 242 sub get_differs ($$) {
 243     my ($x,$y) = @_;
 244     # This resembles quiltify_trees_differ, in dgit, a bit.
 245     # But we don't care about modes, or dpkg-source-unrepresentable
 246     # changes, and we don't need the plethora of different modes.
 247     # Conversely we need to distinguish different kinds of changes to
 248     # debian/ and debian/patches/.
 249
 250     my $differs = 0;
 251
 252     my $rundiff = sub {
 253         my ($opts, $limits, $fn) = @_;
 254         my @cmd = (@git, qw(diff-tree -z --no-renames));
 255         push @cmd, @$opts;
 256         push @cmd, "$_:" foreach $x, $y;
 257         push @cmd, '--', @$limits;
 258         my $diffs = cmdoutput @cmd;
 259         foreach (split /\0/, $diffs) { $fn->(); }
 260     };
 261
 262     $rundiff->([qw(--name-only)], [], sub {
 263         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 264     });
 265
 266     if ($differs & DS_DEB) {
 267         $differs &= ~DS_DEB;
 268         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 269             $differs |=
 270                 m{^debian/patches/}      ? D_PAT_OTH  :
 271                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 272                                            D_DEB_OTH;
 273         });
 274         die "mysterious debian changes $x..$y"
 275             unless $differs & (D_PAT_OTH|DS_DEB);
 276     }
 277
 278     if ($differs & D_PAT_OTH) {
 279         my $mode;
 280         $differs &= ~D_PAT_OTH;
 281         my $pat_oth = sub {
 282             $differs |= D_PAT_OTH;
 283             no warnings qw(exiting);  last;
 284         };
 285         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 286             no warnings qw(exiting);
 287             if (!defined $mode) {
 288                 $mode = $_;  next;
 289             }
 290             die unless s{^debian/patches/}{};
 291             my $ok;
 292             if ($mode eq 'A' && !m/\.series$/s) {
 293                 $ok = 1;
 294             } elsif ($mode eq 'M' && $_ eq 'series') {
 295                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 296                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 297                 chomp $x_s;  $x_s .= "\n";
 298                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 299             } else {
 300                 # nope
 301             }
 302             $mode = undef;
 303             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 304         });
 305         die "mysterious debian/patches changes $x..$y"
 306             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 307     }
 308
 309     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 310
 311     return $differs;
 312 }
 313
 314 sub commit_pr_info ($) {
 315     my ($r) = @_;
 316     return Data::Dumper->dump([$r], [qw(commit)]);
 317 }
 318
 319 sub calculate_committer_authline () {
 320     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 321         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 322     my ($h,$m) = get_commit $c;
 323     $h =~ m/^committer .*$/m or confess "($h) ?";
 324     return $&;
 325 }
 326
 327 sub rm_subdir_cached ($) {
 328     my ($subdir) = @_;
 329     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 330 }
 331
 332 sub read_tree_subdir ($$) {
 333     my ($subdir, $new_tree_object) = @_;
 334     rm_subdir_cached $subdir;
 335     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 336 }
 337
 338 sub read_tree_debian ($) {
 339     my ($treeish) = @_;
 340     read_tree_subdir 'debian', "$treeish:debian";
 341     rm_subdir_cached 'debian/patches';
 342 }
 343
 344 sub read_tree_upstream ($;$$) {
 345     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 346     # if $tree_with_debian is supplied, will use that for debian/
 347     # otherwise will save and restore it.
 348     my $debian =
 349         $tree_with_debian ? "$tree_with_debian:debian"
 350         : cmdoutput @git, qw(write-tree --prefix=debian/);
 351     runcmd @git, qw(read-tree), $treeish;
 352     read_tree_subdir 'debian', $debian;
 353     rm_subdir_cached 'debian/patches' unless $keep_patches;
 354 };
 355
 356 sub make_commit ($$) {
 357     my ($parents, $message_paras) = @_;
 358     my $tree = cmdoutput @git, qw(write-tree);
 359     my @cmd = (@git, qw(commit-tree), $tree);
 360     push @cmd, qw(-p), $_ foreach @$parents;
 361     push @cmd, qw(-m), $_ foreach @$message_paras;
 362     return cmdoutput @cmd;
 363 }
 364
 365 our @snag_force_opts;
 366 sub snag ($$;@) {
 367     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 368     if (grep { $_ eq $tag } @snag_force_opts) {
 369         $snags_forced++;
 370         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 371     } else {
 372         $snags_tripped++;
 373         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 374     }
 375 }
 376
 377 # Important: all mainline code must call snags_maybe_bail after
 378 # any point where snag might be called, but before making changes
 379 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 380 # may be called more than once if necessary (but this is not ideal
 381 # because then the messages about number of snags may be confusing).
 382 sub snags_maybe_bail () {
 383     return if all_snags_summarised();
 384     if ($snags_forced) {
 385         printf STDERR
 386             "%s: snags: %d overriden by individual -f options\n",
 387             $us, $snags_forced;
 388     }
 389     if ($snags_tripped) {
 390         if ($opt_force) {
 391             printf STDERR
 392                 "%s: snags: %d overriden by global --force\n",
 393                 $us, $snags_tripped;
 394         } else {
 395             fail sprintf
 396   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 397                 $us, $snags_tripped;
 398         }
 399     }
 400     $snags_summarised = $snags_forced + $snags_tripped;
 401 }
 402 sub snags_maybe_bail_early () {
 403     # useful to bail out early without doing a lot of work;
 404     # not a substitute for snags_maybe_bail.
 405     snags_maybe_bail() if $snags_tripped && !$opt_force;
 406 }
 407 sub any_snags () {
 408     return $snags_forced || $snags_tripped;
 409 }
 410
 411 sub gbp_pq_export ($$$) {
 412     my ($bname, $base, $tip) = @_;
 413     # must be run in a workarea.  $bname and patch-queue/$bname
 414     # ought not to exist.  Leaves you on patch-queue/$bname with
 415     # the patches staged but not committed.
 416     printdebug "gbp_pq_export $bname $base $tip\n";
 417     runcmd @git, qw(checkout -q -b), $bname, $base;
 418     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 419     my @gbp_cmd = (qw(gbp pq export));
 420     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 421     if ($r) {
 422         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 423         failedcmd @gbp_cmd;
 424     }
 425     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 426 }
 427
 428
 429 # xxx allow merge resolution separately from laundering, before git merge
 430 #
 431 # xxx general gdr docs highlight forbidden things
 432 # xxx general gdr docs list allowable things ?
 433 # xxx general gdr docs explicitly forbid some rebase
 434
 435 # later/rework?
 436 #  use git-format-patch?
 437 #  our own patch identification algorithm?
 438 #  this is an alternative strategy
 439
 440 sub merge_failed ($$;@) {
 441     my ($wrecknotes, $emsg, @xmsgs) = @_;
 442     my @m;
 443     push @m, "Merge resolution failed: $emsg";
 444     push @m, @xmsgs;
 445
 446     changedir $maindir;
 447
 448     my @updates;
 449     merge_wreckage_cleaning \@updates;
 450     run_ref_updates_now "merge failed", \@updates;
 451
 452     @updates = ();
 453     keys %$wrecknotes;
 454     while (my ($k,$v) = each %$wrecknotes) {
 455         push @updates, "create $wrecknoteprefix/$k $v";
 456     }
 457     run_ref_updates_now "merge failed", \@updates;
 458     push @m, "Wreckage left in $wrecknoteprefix/*.";
 459
 460     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 461
 462     # use finish rather than fail, in case we are within an eval
 463     # (that can happen inside walk!)
 464     print STDERR "\n";
 465     print STDERR "$us: $_\n" foreach @m;
 466     finish 15;
 467 }
 468
 469 sub mwrecknote ($$$) {
 470     my ($wrecknotes, $reftail, $commitish) = @_;
 471     confess unless defined $commitish;
 472     printdebug "mwrecknote $reftail $commitish\n";
 473     $wrecknotes->{$reftail} = $commitish;
 474 }
 475
 476 sub merge_attempt_cmd {
 477     my $wrecknotes = shift @_;
 478     debugcmd '+', @_;
 479     $!=0; $?=-1;
 480     if (system @_) {
 481         merge_failed $wrecknotes,
 482             failedcmd_waitstatus(),
 483             "failed command: @_";
 484     }
 485 }
 486
 487 sub merge_series_patchqueue_convert ($$$);
 488
 489 sub merge_series ($$$;@) {
 490     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 491     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 492     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 493     # ^ specifies several patch series (currently we only support exactly 2)
 494     # return value is a commit which is the result of
 495     # merging the two versions of the same topic branch
 496     #   $input_q[0] and $input_q[1]
 497     # with respect to the old version
 498     #   $base_q
 499     # all onto $newbase.
 500
 501     # Creates, in *_q, a key MR for its private use
 502
 503     printdebug "merge_series newbase=$newbase\n";
 504
 505     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 506     $base_q->{MR}{S} = 'base';
 507
 508     my %prereq;
 509     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 510     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 511     # $prereq{<patch filename>}               exists or not (even later)
 512
 513     my $merged_pq;
 514
 515     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 516
 517     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 518
 519     local $workarea;
 520     fresh_workarea "merge";
 521     my $seriesfile = "debian/patches/series";
 522     in_workarea sub {
 523         playtree_setup();
 524         foreach my $q ($base_q, reverse @input_qs) {
 525             my $s = $q->{MR}{S};
 526             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 527             my @earlier;
 528             if (open S, $seriesfile) {
 529                 while (my $patch = <S>) {
 530                     chomp $patch or die $!;
 531                     $prereq{$patch} //= {};
 532                     foreach my $earlier (@earlier) {
 533                         $prereq{$patch}{$earlier}{$s}++ and die;
 534                     }
 535                     push @earlier, $patch;
 536                     stat "debian/patches/$patch" or die "$patch ?";
 537                 }
 538                 S->error and die "$seriesfile $!";
 539                 close S;
 540             } else {
 541                 die "$seriesfile $!" unless $!==ENOENT;
 542             }
 543             read_tree_upstream $newbase, 1;
 544             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 545                 "Convert $s to patch queue for merging",
 546                 "[git-debrebase merge-innards patch-queue import:".
 547                 " $q->{SeriesTip}]"
 548             ];
 549             printdebug "merge_series  pec $pec ";
 550             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 551             $pec = make_commit [ $pec ], [
 552                 "Drop series file from $s to avoid merge trouble",
 553                 "[git-debrebase merge-innards patch-queue prep:".
 554                 " $q->{SeriesTip}]"
 555             ];
 556
 557             read_tree_debian $newbase;
 558             if (@earlier) {
 559                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 560             } else {
 561                 rm_subdir_cached 'debian/patches';
 562             }
 563             $pec = make_commit [ $pec ], [
 564  "Update debian/ (excluding patches) to final to avoid re-merging",
 565  "debian/ was already merged and we need to just take that.",
 566                 "[git-debrebase merge-innards patch-queue packaging:".
 567                 " $q->{SeriesTip}]"
 568             ];
 569
 570             printdebug "pec' $pec\n";
 571             runcmd @git, qw(reset -q --hard), $pec;
 572             $q->{MR}{PEC} = $pec;
 573             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 574         }
 575         # now, because of reverse, we are on $input_q->{MR}{OQC}
 576         runcmd @git, qw(checkout -q -b merge);
 577         printdebug "merge_series merging...\n";
 578         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 579
 580         $attempt_cmd->(@mergecmd);
 581
 582         printdebug "merge_series merge ok, series...\n";
 583         # We need to construct a new series file
 584         # Firstly, resolve prereq
 585         foreach my $f (sort keys %prereq) {
 586             printdebug "merge_series  patch\t$f\t";
 587             if (!stat_exists "debian/patches/$f") {
 588                 print DEBUG " drop\n" if $debuglevel;
 589                 # git merge deleted it; that's how we tell it's not wanted
 590                 delete $prereq{$f};
 591                 next;
 592             }
 593             print DEBUG " keep\n" if $debuglevel;
 594             foreach my $g (sort keys %{ $prereq{$f} }) {
 595                 my $gfp = $prereq{$f}{$g};
 596                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 597                 if (!!$gfp->{0} == !!$gfp->{1}
 598                     ? $gfp->{0}
 599                     : !$gfp->{base}) {
 600                     print DEBUG "\tkeep\n" if $debuglevel;
 601                 } else {
 602                     print DEBUG "\tdrop\n" if $debuglevel;
 603                     delete $prereq{$f}{$g};
 604                 }
 605             }
 606         }
 607
 608         my $unsat = sub {
 609             my ($f) = @_;
 610             return scalar keys %{ $prereq{$f} };
 611         };
 612
 613         my $nodate = time + 1;
 614         my %authordate;
 615         # $authordate{<patch filename>};
 616         my $authordate = sub {
 617             my ($f) = @_;
 618             $authordate{$f} //= do {
 619                 open PF, "<", "debian/patches/$f" or die "$f $!";
 620                 while (<PF>) {
 621                     return $nodate if m/^$/;
 622                     last if s{^Date: }{};
 623                 }
 624                 chomp;
 625                 return cmdoutput qw(date +%s -d), $_;
 626             };
 627         };
 628
 629         open NS, '>', $seriesfile or die $!;
 630
 631         while (keys %prereq) {
 632             my $best;
 633             foreach my $try (sort keys %prereq) {
 634                 if ($best) {
 635                     next if (
 636                              $unsat->($try) <=> $unsat->($best) or
 637                              $authordate->($try) <=> $authordate->($best) or
 638                              $try cmp $best
 639                             ) >= 0;
 640                 }
 641                 $best = $try;
 642             }
 643             printdebug "merge_series series next $best\n";
 644             print NS "$best\n" or die $!;
 645             delete $prereq{$best};
 646             foreach my $gp (values %prereq) {
 647                 delete $gp->{$best};
 648             }
 649         }
 650
 651         runcmd @git, qw(add), $seriesfile;
 652         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 653         $merged_pq = git_rev_parse 'HEAD';
 654         $mwrecknote->('merged-patchqueue', $merged_pq);
 655     };
 656     return merge_series_patchqueue_convert
 657             $wrecknotes, $newbase, $merged_pq;
 658 }
 659
 660 sub merge_series_patchqueue_convert ($$$) {
 661     my ($wrecknotes, $newbase, $merged_pq) = @_;
 662
 663     my $result;
 664     in_workarea sub {
 665         playtree_setup();
 666         printdebug "merge_series series gbp pq import\n";
 667         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 668
 669         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 670
 671         # OK now we are on patch-queue/merge, and we need to rebase
 672         # onto the intended parent and drop the patches from each one
 673
 674         printdebug "merge_series series ok, building...\n";
 675         my $build = $newbase;
 676         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 677         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 678             my $commit = git_cat_file $c, 'commit';
 679             printdebug "merge_series series ok, building $c\n";
 680             read_tree_upstream $c, 0, $newbase;
 681             my $tree = cmdoutput @git, qw(write-tree);
 682             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 683             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 684             open C, ">", "../mcommit" or die $!;
 685             print C $commit or die $!;
 686             close C or die $!;
 687             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 688         }
 689         $result = $build;
 690         mwrecknote($wrecknotes, 'merged-result', $result);
 691
 692         runcmd @git, qw(update-ref refs/heads/result), $result;
 693
 694         runcmd @git, qw(checkout -q -b debug);
 695         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 696         runcmd @git, qw(add .);
 697         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 698         my $mdebug = git_rev_parse 'HEAD';
 699         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 700         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 701     };
 702     printdebug "merge_series returns $result\n";
 703     return $result;
 704 }
 705
 706 # classify returns an info hash like this
 707 #   CommitId => $objid
 708 #   Hdr => # commit headers, including 1 final newline
 709 #   Msg => # commit message (so one newline is dropped)
 710 #   Tree => $treeobjid
 711 #   Type => (see below)
 712 #   Parents = [ {
 713 #       Ix => $index # ie 0, 1, 2, ...
 714 #       CommitId
 715 #       Differs => return value from get_differs
 716 #       IsOrigin
 717 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 718 #     } ...]
 719 #   NewMsg => # commit message, but with any [dgit import ...] edited
 720 #             # to say "[was: ...]"
 721 #
 722 # Types:
 723 #   Packaging
 724 #   Changelog
 725 #   Upstream
 726 #   AddPatches
 727 #   Mixed
 728 #
 729 #   Pseudomerge
 730 #     has additional entres in classification result
 731 #       Overwritten = [ subset of Parents ]
 732 #       Contributor = $the_remaining_Parent
 733 #
 734 #   DgitImportUnpatched
 735 #     has additional entry in classification result
 736 #       OrigParents = [ subset of Parents ]
 737 #
 738 #   Anchor
 739 #     has additional entry in classification result
 740 #       OrigParents = [ subset of Parents ]  # singleton list
 741 #
 742 #   TreatAsAnchor
 743 #
 744 #   BreakwaterStart
 745 #
 746 #   Unknown
 747 #     has additional entry in classification result
 748 #       Why => "prose"
 749
 750 sub parsecommit ($;$) {
 751     my ($objid, $p_ref) = @_;
 752     # => hash with                   CommitId Hdr Msg Tree Parents
 753     #    Parents entries have only   Ix CommitId
 754     #    $p_ref, if provided, must be [] and is used as a base for Parents
 755
 756     $p_ref //= [];
 757     die if @$p_ref;
 758
 759     my ($h,$m) = get_commit $objid;
 760
 761     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 762     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 763
 764     my $r = {
 765         CommitId => $objid,
 766         Hdr => $h,
 767         Msg => $m,
 768         Tree => $t,
 769         Parents => $p_ref,
 770     };
 771
 772     foreach my $ph (@ph) {
 773         push @$p_ref, {
 774             Ix => scalar @$p_ref,
 775             CommitId => $ph,
 776         };
 777     }
 778
 779     return $r;
 780 }
 781
 782 sub classify ($) {
 783     my ($objid) = @_;
 784
 785     my @p;
 786     my $r = parsecommit($objid, \@p);
 787     my $t = $r->{Tree};
 788
 789     foreach my $p (@p) {
 790         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 791     }
 792
 793     printdebug "classify $objid \$t=$t \@p",
 794         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 795         "\n";
 796
 797     my $classify = sub {
 798         my ($type, @rest) = @_;
 799         $r = { %$r, Type => $type, @rest };
 800         if ($debuglevel) {
 801             printdebug " = $type ".(dd $r)."\n";
 802         }
 803         return $r;
 804     };
 805     my $unknown = sub {
 806         my ($why) = @_;
 807         $r = { %$r, Type => qw(Unknown), Why => $why };
 808         printdebug " ** Unknown\n";
 809         return $r;
 810     };
 811
 812     if (grep { $_ eq $objid } @opt_anchors) {
 813         return $classify->('TreatAsAnchor');
 814     }
 815
 816     my @identical = grep { !$_->{Differs} } @p;
 817     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 818     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 819
 820     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 821         # multi-orig upstreams are represented with an anchor merge
 822         # from a single upstream commit which combines the orig tarballs
 823
 824         # Every anchor tagged this way must be a merge.
 825         # We are relying on the
 826         #     [git-debrebase anchor: ...]
 827         # commit message annotation in "declare" anchor merges (which
 828         # do not have any upstream changes), to distinguish those
 829         # anchor merges from ordinary pseudomerges (which we might
 830         # just try to strip).
 831         #
 832         # However, the user is going to be doing git-rebase a lot.  We
 833         # really don't want them to rewrite an anchor commit.
 834         # git-rebase trips up on merges, so that is a useful safety
 835         # catch.
 836         #
 837         # BreakwaterStart commits are also anchors in the terminology
 838         # of git-debrebase(5), but they are untagged (and always
 839         # manually generated).
 840         #
 841         # We cannot not tolerate any tagged linear commit (ie,
 842         # BreakwaterStart commits tagged `[anchor:') because such a
 843         # thing could result from an erroneous linearising raw git
 844         # rebase of a merge anchor.  That would represent a corruption
 845         # of the branch. and we want to detect and reject the results
 846         # of such corruption before it makes it out anywhere.  If we
 847         # reject it here then we avoid making the pseudomerge which
 848         # would be needed to push it.
 849
 850         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 851         @p == 2 or return $badanchor->("has other than two parents");
 852         $haspatches and return $badanchor->("contains debian/patches");
 853
 854         # How to decide about l/r ordering of anchors ?  git
 855         # --topo-order prefers to expand 2nd parent first.  There's
 856         # already an easy rune to look for debian/ history anyway (git log
 857         # debian/) so debian breakwater branch should be 1st parent; that
 858         # way also there's also an easy rune to look for the upstream
 859         # patches (--topo-order).
 860
 861         # Also this makes --first-parent be slightly more likely to
 862         # be useful - it makes it provide a linearised breakwater history.
 863
 864         # Of course one can say somthing like
 865         #  gitk -- ':/' ':!/debian'
 866         # to get _just_ the commits touching upstream files, and by
 867         # the TREESAME logic in git-rev-list this will leave the
 868         # breakwater into upstream at the first anchor.  But that
 869         # doesn't report debian/ changes at all.
 870
 871         # Other observations about gitk: by default, gitk seems to
 872         # produce output in a different order to git-rev-list.  I
 873         # can't seem to find this documented anywhere.  gitk
 874         # --date-order DTRT.  But, gitk always seems to put the
 875         # parents from left to right, in order, so it's easy to see
 876         # which way round a pseudomerge is.
 877
 878         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 879         $p[1]{Differs} & ~DS_DEB and
 880             $badanchor->("upstream files differ from left parent");
 881         $p[0]{Differs} & ~D_UPS and
 882             $badanchor->("debian/ differs from right parent");
 883
 884         return $classify->(qw(Anchor),
 885                            OrigParents => [ $p[1] ]);
 886     }
 887
 888     if (@p == 1) {
 889         my $d = $r->{Parents}[0]{Differs};
 890         if ($d == D_PAT_ADD) {
 891             return $classify->(qw(AddPatches));
 892         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 893             return $unknown->("edits debian/patches");
 894         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 895             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 896             if ($ty eq 'tree') {
 897                 if ($d == D_DEB_CLOG) {
 898                     return $classify->(qw(Changelog));
 899                 } else {
 900                     return $classify->(qw(Packaging));
 901                 }
 902             } elsif ($ty eq 'missing') {
 903                 return $classify->(qw(BreakwaterStart));
 904             } else {
 905                 return $unknown->("parent's debian is not a directory");
 906             }
 907         } elsif ($d == D_UPS) {
 908             return $classify->(qw(Upstream));
 909         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 910             return $classify->(qw(Mixed));
 911         } elsif ($d == 0) {
 912             return $unknown->("no changes");
 913         } else {
 914             confess "internal error $objid ?";
 915         }
 916     }
 917     if (!@p) {
 918         return $unknown->("origin commit");
 919     }
 920
 921     if (@p == 2 && @identical == 1) {
 922         my @overwritten = grep { $_->{Differs} } @p;
 923         confess "internal error $objid ?" unless @overwritten==1;
 924         return $classify->(qw(Pseudomerge),
 925                            Overwritten => [ $overwritten[0] ],
 926                            Contributor => $identical[0]);
 927     }
 928     if (@p == 2 && @identical == 2) {
 929         my $get_t = sub {
 930             my ($ph,$pm) = get_commit $_[0]{CommitId};
 931             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 932             $1;
 933         };
 934         my @bytime = @p;
 935         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 936         if ($order > 0) { # newer first
 937         } elsif ($order < 0) {
 938             @bytime = reverse @bytime;
 939         } else {
 940             # same age, default to order made by -s ours
 941             # that is, commit was made by someone who preferred L
 942         }
 943         return $classify->(qw(Pseudomerge),
 944                            SubType => qw(Ambiguous),
 945                            Contributor => $bytime[0],
 946                            Overwritten => [ $bytime[1] ]);
 947     }
 948     foreach my $p (@p) {
 949         my ($p_h, $p_m) = get_commit $p->{CommitId};
 950         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 951         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 952     }
 953     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 954     my $m2 = $r->{Msg};
 955     if (!(grep { !$_->{IsOrigin} } @p) and
 956         (@orig_ps >= @p - 1) and
 957         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 958         $r->{NewMsg} = $m2;
 959         return $classify->(qw(DgitImportUnpatched),
 960                            OrigParents => \@orig_ps);
 961     }
 962
 963     if (@p == 2 and
 964         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 965         # xxx ^ metadata tag needs adding to (5)
 966         return $classify->("MergedBreakwaters");
 967     }
 968     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 969         return $unknown->("unknown kind of merge from $1");
 970     }
 971     if (@p > 2) {
 972         return $unknown->("octopus merge");
 973     }
 974
 975     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 976         return $unknown->("general two-parent merge");
 977     }
 978
 979     return $classify->("VanillaMerge");
 980 }
 981
 982 sub keycommits ($;$$$$$);
 983
 984 sub mergedbreakwaters_anchor ($) {
 985     my ($cl) = @_;
 986     my $best_anchor;
 987     foreach my $p (@{ $cl->{Parents} }) {
 988         my ($panchor, $pbw) = keycommits $p->{CommitId},
 989             undef,undef,undef,undef, 1;
 990         $best_anchor = $panchor
 991             if !defined $best_anchor
 992             or is_fast_fwd $best_anchor, $panchor;
 993         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 994             unless is_fast_fwd $panchor, $best_anchor;
 995     }
 996     return $best_anchor;
 997 }
 998
 999 sub keycommits ($;$$$$$) {
1000     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1001     # => ($anchor, $breakwater)
1002
1003     # $unclean->("unclean-$tagsfx", $msg, $cl)
1004     # $furniture->("unclean-$tagsfx", $msg, $cl)
1005     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
1006     #   is callled for each situation or commit that
1007     #   wouldn't be found in a laundered branch
1008     # $furniture is for furniture commits such as might be found on an
1009     #   interchange branch (pseudomerge, d/patches, changelog)
1010     # $trouble is for things whnich prevent the return of
1011     #   anchor and breakwater information; if that is ignored,
1012     #   then keycommits returns (undef, undef) instead.
1013     # $fatal is for unprocessable commits, and should normally cause
1014     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1015     #
1016     # If $claimed_bw, this is supposed to be a breakwater commit.
1017     #
1018     # If a callback is undef, fail is called instead.
1019     # If a callback is defined but false, the situation is ignored.
1020     # Callbacks may say:
1021     #   no warnings qw(exiting); last;
1022     # if the answer is no longer wanted.
1023
1024     my ($anchor, $breakwater);
1025     $breakwater = $head if $claimed_bw;
1026     my $clogonly;
1027     my $cl;
1028     my $found_pm;
1029     $fatal //= sub { fail $_[1]; };
1030     my $x = sub {
1031         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1032         my $why = $mainwhy.$xwhy;
1033         my $m = "branch needs laundering (run git-debrebase): $why";
1034         fail $m unless defined $cb;
1035         return unless $cb;
1036         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1037     };
1038     my $found_anchor = sub {
1039         ($anchor) = @_;
1040         $breakwater //= $clogonly;
1041         $breakwater //= $head;
1042         no warnings qw(exiting);
1043         last;
1044     };
1045     for (;;) {
1046         $cl = classify $head;
1047         my $ty = $cl->{Type};
1048         if ($ty eq 'Packaging') {
1049             $breakwater //= $clogonly;
1050             $breakwater //= $head;
1051         } elsif ($ty eq 'Changelog') {
1052             # this is going to count as the tip of the breakwater
1053             # only if it has no upstream stuff before it
1054             $clogonly //= $head;
1055         } elsif ($ty eq 'Anchor' or
1056                  $ty eq 'TreatAsAnchor' or
1057                  $ty eq 'BreakwaterStart') {
1058             $found_anchor->($head);
1059         } elsif ($ty eq 'Upstream') {
1060             $x->($unclean, 'ordering',
1061  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1062                 if defined $breakwater;
1063             $clogonly = undef;
1064             $breakwater = undef;
1065         } elsif ($ty eq 'Mixed') {
1066             $x->($unclean, 'mixed',
1067                  "found mixed upstream/packaging commit"," ($head)");
1068             $clogonly = undef;
1069             $breakwater = undef;
1070         } elsif ($ty eq 'Pseudomerge' or
1071                  $ty eq 'AddPatches') {
1072             my $found_pm = 1;
1073             $x->($furniture, (lc $ty),
1074                  "found interchange bureaucracy commit ($ty)"," ($head)");
1075         } elsif ($ty eq 'DgitImportUnpatched') {
1076             if ($found_pm) {
1077                 $x->($trouble, 'dgitimport',
1078                      "found dgit dsc import"," ($head)");
1079                 return (undef,undef);
1080             } else {
1081                 $x->($fatal, 'unprocessable',
1082                      "found bare dgit dsc import with no prior history",
1083                      " ($head)");
1084                 return (undef,undef);
1085             }
1086         } elsif ($ty eq 'VanillaMerge') {
1087             $x->($trouble, 'vanillamerge',
1088                  "found vanilla merge"," ($head)");
1089             return (undef,undef);
1090         } elsif ($ty eq 'MergedBreakwaters') {
1091             $found_anchor->(mergedbreakwaters_anchor $cl);
1092         } else {
1093             $x->($fatal, 'unprocessable',
1094                  "found unprocessable commit, cannot cope: $cl->{Why}",
1095                  " ($head)");
1096             return (undef,undef);
1097         }
1098         $head = $cl->{Parents}[0]{CommitId};
1099     }
1100     return ($anchor, $breakwater);
1101 }
1102
1103 sub walk ($;$$$);
1104 sub walk ($;$$$) {
1105     my ($input,
1106         $nogenerate,$report, $report_lprefix) = @_;
1107     # => ($tip, $breakwater_tip, $last_anchor)
1108     # (or nothing, if $nogenerate)
1109
1110     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1111     $report_lprefix //= '';
1112
1113     # go through commits backwards
1114     # we generate two lists of commits to apply:
1115     # breakwater branch and upstream patches
1116     my (@brw_cl, @upp_cl, @processed);
1117     my %found;
1118     my $upp_limit;
1119     my @pseudomerges;
1120
1121     my $cl;
1122     my $xmsg = sub {
1123         my ($prose, $info) = @_;
1124         my $ms = $cl->{Msg};
1125         chomp $ms;
1126         $info //= '';
1127         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1128         return (Msg => $ms);
1129     };
1130     my $rewrite_from_here = sub {
1131         my ($cl) = @_;
1132         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1133         push @$cl, $sp_cl;
1134         push @processed, $sp_cl;
1135     };
1136     my $cur = $input;
1137
1138     my $prdelim = "";
1139     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1140
1141     my $prline = sub {
1142         return unless $report;
1143         print $report $prdelim, $report_lprefix, @_;
1144         $prdelim = "\n";
1145     };
1146
1147     my $bomb = sub { # usage: return $bomb->();
1148         print $report " Unprocessable" if $report;
1149         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1150         $prprdelim->();
1151         if ($nogenerate) {
1152             return (undef,undef);
1153         }
1154         fail "found unprocessable commit, cannot cope".
1155             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1156             " (commit $cur) (d.".
1157             (join ' ', map { sprintf "%#x", $_->{Differs} }
1158              @{ $cl->{Parents} }).
1159                  ")";
1160     };
1161
1162     my $build;
1163     my $breakwater;
1164
1165     my $build_start = sub {
1166         my ($msg, $parent) = @_;
1167         $prline->(" $msg");
1168         $build = $parent;
1169         no warnings qw(exiting); last;
1170     };
1171
1172     my $nomerge = sub {
1173         my ($emsg) = @_;
1174         merge_failed $cl->{MergeWreckNotes}, $emsg;
1175     };
1176
1177     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1178
1179     my $last_anchor;
1180
1181     for (;;) {
1182         $cl = classify $cur;
1183         $cl->{MergeWreckNotes} //= {};
1184         my $ty = $cl->{Type};
1185         my $st = $cl->{SubType};
1186         $prline->("$cl->{CommitId} $cl->{Type}");
1187         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1188         push @processed, $cl;
1189         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1190         if ($ty eq 'AddPatches') {
1191             $cur = $p0;
1192             $rewrite_from_here->(\@upp_cl);
1193             next;
1194         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1195             push @brw_cl, $cl;
1196             $cur = $p0;
1197             next;
1198         } elsif ($ty eq 'BreakwaterStart') {
1199             $last_anchor = $cur;
1200             $build_start->('FirstPackaging', $cur);
1201         } elsif ($ty eq 'Upstream') {
1202             push @upp_cl, $cl;
1203             $cur = $p0;
1204             next;
1205         } elsif ($ty eq 'Mixed') {
1206             my $queue = sub {
1207                 my ($q, $wh) = @_;
1208                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1209                 push @$q, $cls;
1210             };
1211             $queue->(\@brw_cl, "debian");
1212             $queue->(\@upp_cl, "upstream");
1213             $rewrite_from_here->(\@brw_cl);
1214             $cur = $p0;
1215             next;
1216         } elsif ($ty eq 'Pseudomerge') {
1217             my $contrib = $cl->{Contributor}{CommitId};
1218             print $report " Contributor=$contrib" if $report;
1219             push @pseudomerges, $cl;
1220             $rewrite_from_here->(\@upp_cl);
1221             $cur = $contrib;
1222             next;
1223         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1224             $last_anchor = $cur;
1225             $build_start->("Anchor", $cur);
1226         } elsif ($ty eq 'DgitImportUnpatched') {
1227             my $pm = $pseudomerges[-1];
1228             if (defined $pm) {
1229                 # To an extent, this is heuristic.  Imports don't have
1230                 # a useful history of the debian/ branch.  We assume
1231                 # that the first pseudomerge after an import has a
1232                 # useful history of debian/, and ignore the histories
1233                 # from later pseudomerges.  Often the first pseudomerge
1234                 # will be the dgit import of the upload to the actual
1235                 # suite intended by the non-dgit NMUer, and later
1236                 # pseudomerges may represent in-archive copies.
1237                 my $ovwrs = $pm->{Overwritten};
1238                 printf $report " PM=%s \@Overwr:%d",
1239                     $pm->{CommitId}, (scalar @$ovwrs)
1240                     if $report;
1241                 if (@$ovwrs != 1) {
1242                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1243                     return $bomb->();
1244                 }
1245                 my $ovwr = $ovwrs->[0]{CommitId};
1246                 printf $report " Overwr=%s", $ovwr if $report;
1247                 # This import has a tree which is just like a
1248                 # breakwater tree, but it has the wrong history.  It
1249                 # ought to have the previous breakwater (which the
1250                 # pseudomerge overwrote) as an ancestor.  That will
1251                 # make the history of the debian/ files correct.  As
1252                 # for the upstream version: either it's the same as
1253                 # was ovewritten (ie, same as the previous
1254                 # breakwater), in which case that history is precisely
1255                 # right; or, otherwise, it was a non-gitish upload of a
1256                 # new upstream version.  We can tell these apart by
1257                 # looking at the tree of the supposed upstream.
1258                 push @brw_cl, {
1259                     %$cl,
1260                     SpecialMethod => 'DgitImportDebianUpdate',
1261                     $xmsg->("convert dgit import: debian changes")
1262                 }, {
1263                     %$cl,
1264                     SpecialMethod => 'DgitImportUpstreamUpdate',
1265                     $xmsg->("convert dgit import: upstream update",
1266                             " anchor")
1267                 };
1268                 $prline->(" Import");
1269                 $rewrite_from_here->(\@brw_cl);
1270                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1271                 $cur = $ovwr;
1272                 next;
1273             } else {
1274                 # Everything is from this import.  This kind of import
1275                 # is already nearly in valid breakwater format, with the
1276                 # patches as commits.  Unfortunately it contains
1277                 # debian/patches/.
1278                 printdebug "*** WALK BOMB bare dgit import\n";
1279                 $cl->{Why} = "bare dgit dsc import";
1280                 return $bomb->();
1281             }
1282             die "$ty ?";
1283         } elsif ($ty eq 'MergedBreakwaters') {
1284             $last_anchor = mergedbreakwaters_anchor $cl;
1285             $build_start->(' MergedBreakwaters', $cur);
1286             last;
1287         } elsif ($ty eq 'VanillaMerge') {
1288             # User may have merged unstitched branch(es).  We will
1289             # have now lost what ffq-prev was then (since the later
1290             # pseudomerge may introduce further changes).  The effect
1291             # of resolving such a merge is that we may have to go back
1292             # further in history to find a merge base, since the one
1293             # which was reachable via ffq-prev is no longer findable.
1294             # This is suboptimal, but if it all works we'll have done
1295             # the right thing.
1296             # xxx we should warn the user in the docs about this
1297
1298             my $ok=1;
1299             my $best_anchor;
1300             # We expect to find a dominating anchor amongst the
1301             # inputs' anchors.  That will be the new anchor.
1302             #
1303             # More complicated is finding a merge base for the
1304             # breakwaters.  We need a merge base that is a breakwater
1305             # commit.  The ancestors of breakwater commits are more
1306             # breakwater commits and possibly upstream commits and the
1307             # ancestors of those upstream.  Upstreams might have
1308             # arbitrary ancestors.  But any upstream commit U is
1309             # either included in both anchors, in which case the
1310             # earlier anchor is a better merge base than any of U's
1311             # ancestors; or U is not included in the older anchor, in
1312             # which case U is not an ancestor of the vanilla merge at
1313             # all.  So no upstream commit, nor any ancestor thereof,
1314             # is a best merge base.  As for non-breakwater Debian
1315             # commits: these are never ancestors of any breakwater.
1316             #
1317             # So any best merge base as found by git-merge-base
1318             # is a suitable breakwater anchor.  Usually there will
1319             # be only one.
1320
1321             printdebug "*** MERGE\n";
1322
1323             my @bwbcmd = (@git, qw(merge-base));
1324             my @ibcmd = (@git, qw(merge-base --all));
1325             my $might_be_in_bw = 1;
1326
1327             my $ps = $cl->{Parents};
1328
1329             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1330
1331             foreach my $p (@$ps) {
1332                 $prline->(" VanillaMerge ".$p->{Ix});
1333                 $prprdelim->();
1334                 my ($ptip, $pbw, $panchor) =
1335                     walk $p->{CommitId}, 0, $report,
1336                          $report_lprefix.'  ';
1337                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1338                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1339                 $p->{Anchor} = $panchor;
1340
1341                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1342                 $mwrecknote->("$lr-input", $p->{CommitId});
1343
1344                 my $mwrecknote_parent = sub {
1345                     my ($which) = @_;
1346                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1347                 };
1348                 $mwrecknote_parent->('Laundered');
1349                 $mwrecknote_parent->('Breakwater');
1350                 $mwrecknote_parent->('Anchor');
1351
1352                 $best_anchor = $panchor if
1353                     !defined $best_anchor or
1354                     is_fast_fwd $best_anchor, $panchor;
1355
1356                 printdebug " MERGE BA best=".($best_anchor//'-').
1357                     " p=$panchor\n";
1358             }
1359
1360             $mwrecknote->('result-anchor', $best_anchor);
1361
1362             foreach my $p (@$ps) {
1363                 $prline->(" VanillaMerge ".$p->{Ix});
1364                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1365                     $nomerge->('divergent anchors');
1366                 } elsif ($p->{Anchor} eq $best_anchor) {
1367                     print $report " SameAnchor" if $report;
1368                 } else {
1369                     print $report " SupersededAnchor" if $report;
1370                 }
1371                 if ($p->{Breakwater} eq $p->{CommitId}) {
1372                     # this parent commit was its own breakwater,
1373                     # ie it is part of the breakwater
1374                     print $report " Breakwater" if $report;
1375                 } else {
1376                     $might_be_in_bw = 0;
1377                 }
1378                 push @bwbcmd, $p->{Breakwater};
1379                 push @ibcmd, $p->{CommitId};
1380             }
1381
1382             if ($ok && $might_be_in_bw) {
1383                 # We could rewrite this to contaion the metadata
1384                 # declaring it to be MergedBreakwaters, but
1385                 # unnecessarily rewriting a merge seems unhelpful.
1386                 $prline->(" VanillaMerge MergedBreakwaters");
1387                 $last_anchor = $best_anchor;
1388                 $build_start->('MergedBreakwaters', $cur);
1389             }
1390
1391             my $bwb = cmdoutput @bwbcmd;
1392
1393             # OK, now we have a breakwater base, but we need the merge
1394             # base for the interchange branch because we need the delta
1395             # queue.
1396             #
1397             # This a the best merge base of our inputs which has the
1398             # breakwater merge base as an ancestor.
1399
1400             my @ibs =
1401                 grep /./,
1402                 split /\n/,
1403                 cmdoutput @ibcmd;
1404
1405             @ibs or confess 'internal error, expected anchor at least ?';
1406
1407             my $ib;
1408             my $ibleaf;
1409             foreach my $tibix (0..$#ibs) {
1410                 my $tib = $ibs[$tibix];
1411                 my $ff = is_fast_fwd $bwb, $tib;
1412                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1413                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1414                 $mwrecknote->($tibleaf, $tib);
1415                 next unless $ff;
1416                 next if $ib;
1417                 $ib = $tib;
1418                 $ibleaf = $tibleaf;
1419             }
1420
1421             $ib or $nomerge->("no suitable interchange merge base");
1422
1423             $prline->("  VanillaMerge Base");
1424             $prprdelim->();
1425             my ($btip, $bbw, $banchor) = eval {
1426                 walk $ib, 0, $report, $report_lprefix.'  ';
1427             };
1428             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1429                        $@)
1430                 if length $@;
1431
1432             $mwrecknote->("mergebase-laundered", $btip);
1433             $mwrecknote->("mergebase-breakwater", $bbw);
1434             $mwrecknote->("mergebase-anchor", $banchor);
1435
1436             my $ibinfo = { SeriesTip => $btip,
1437                            SeriesBase => $bbw,
1438                            Anchor => $banchor,
1439                            LeftRight => 'mergebase' };
1440
1441             $bbw eq $bwb
1442                 or $nomerge->("interchange merge-base ($ib)'s".
1443                               " breakwater ($bbw)".
1444                               " != breakwaters' merge-base ($bwb)");
1445
1446             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1447                  or $nomerge->("interchange merge-base ($ib)'s".
1448                                " anchor ($ibinfo->{SeriesBase})".
1449                                " != any merge input's anchor (".
1450                                (join ' ', map { $_->{Anchor} } @$ps).
1451                                ")");
1452
1453             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1454             $cl->{MergeBestAnchor} = $best_anchor;
1455             push @brw_cl, {
1456                 %$cl,
1457                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1458                 $xmsg->('constructed from vanilla merge',
1459                         ' merged-breakwater'),
1460             };
1461             push @upp_cl, {
1462                 %$cl,
1463                 SpecialMethod => 'MergeMergeSeries',
1464             };
1465             $build_start->('MergeBreakwaters', $cur);
1466         } else {
1467             printdebug "*** WALK BOMB unrecognised\n";
1468             return $bomb->();
1469         }
1470     }
1471     $prprdelim->();
1472
1473     printdebug "*** WALK prep done cur=$cur".
1474         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1475
1476     return if $nogenerate;
1477
1478     # Now we build it back up again
1479
1480     fresh_workarea();
1481
1482     my $rewriting = 0;
1483
1484     $#upp_cl = $upp_limit if defined $upp_limit;
1485
1486     my $committer_authline = calculate_committer_authline();
1487
1488     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1489
1490     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1491
1492     in_workarea sub {
1493         mkdir $rd or $!==EEXIST or die $!;
1494         my $current_method;
1495         my $want_debian = $build;
1496         my $want_upstream = $build;
1497
1498         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1499         my $read_tree_debian = sub { ($want_debian) = @_; };
1500
1501         foreach my $cl (qw(Debian), (reverse @brw_cl),
1502                         { SpecialMethod => 'RecordBreakwaterTip' },
1503                         qw(Upstream), (reverse @upp_cl)) {
1504             if (!ref $cl) {
1505                 $current_method = $cl;
1506                 next;
1507             }
1508             my $method = $cl->{SpecialMethod} // $current_method;
1509             my @parents = ($build);
1510             my $cltree = $cl->{CommitId};
1511             printdebug "WALK BUILD ".($cltree//'undef').
1512                 " $method (rewriting=$rewriting)\n";
1513             if ($method eq 'Debian') {
1514                 $read_tree_debian->($cltree);
1515             } elsif ($method eq 'Upstream') {
1516                 $read_tree_upstream->($cltree);
1517             } elsif ($method eq 'StartRewrite') {
1518                 $rewriting = 1;
1519                 next;
1520             } elsif ($method eq 'RecordBreakwaterTip') {
1521                 $breakwater = $build;
1522                 next;
1523             } elsif ($method eq 'DgitImportDebianUpdate') {
1524                 $read_tree_debian->($cltree);
1525             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1526                 confess unless $rewriting;
1527                 my $differs = (get_differs $build, $cltree);
1528                 next unless $differs & D_UPS;
1529                 $read_tree_upstream->($cltree);
1530                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1531             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1532                 print "Found a general merge, will try to tidy it up.\n";
1533                 $rewriting = 1;
1534                 $read_tree_upstream->($cl->{MergeBestAnchor});
1535                 $read_tree_debian->($cltree);
1536                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1537             } elsif ($method eq 'MergeMergeSeries') {
1538                 my $cachehit = reflog_cache_lookup
1539                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1540                 if ($cachehit) {
1541                     print "Using supplied resolution for $cl->{CommitId}...\n";
1542                     $build = $cachehit;
1543                     $mwrecknote->('cached-resolution', $build);
1544                 } else {
1545                     print "Running merge resolution for $cl->{CommitId}...\n";
1546                     $mwrecknote->('new-base', $build);
1547                     $build = merge_series
1548                         $build, $cl->{MergeWreckNotes},
1549                         $cl->{MergeInterchangeBaseInfo},
1550                         @{ $cl->{Parents} };
1551                 }
1552                 $last_anchor = $cl->{MergeBestAnchor};
1553
1554                 # Check for mismerges:
1555                 my $check = sub {
1556                     my ($against, $allow, $what) = @_;
1557                     my $differs = get_differs $build, $against;
1558                     $nomerge->(sprintf
1559        "merge misresolved: %s are not the same (%s %s d.%#x)",
1560                                $what, $against, $build, $differs)
1561                         if $differs & ~($allow | D_PAT_ADD);
1562                 };
1563
1564                 # Breakwater changes which were in each side of the
1565                 # merge will have been incorporated into the
1566                 # MergeCreateMergedBreakwaters output.  Because the
1567                 # upstream series was rebased onto the new breakwater,
1568                 # so should all of the packaging changes which were in
1569                 # the input.
1570                 $check->($input, D_UPS, 'debian files');
1571
1572                 # Upstream files are merge_series, which ought to
1573                 # have been identical to the original merge.
1574                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1575
1576                 print "Merge resolution successful.\n";
1577                 next;
1578             } else {
1579                 confess "$method ?";
1580             }
1581             if (!$rewriting) {
1582                 my $procd = (pop @processed) // 'UNDEF';
1583                 if ($cl ne $procd) {
1584                     $rewriting = 1;
1585                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1586                 }
1587             }
1588             if ($rewriting || $opt_careful) {
1589                 read_tree_upstream $want_upstream, 0, $want_debian;
1590
1591                 my $newtree = cmdoutput @git, qw(write-tree);
1592                 my $ch = $cl->{Hdr};
1593                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1594                 $ch =~ s{^parent .*\n}{}mg;
1595                 $ch =~ s{(?=^author)}{
1596                     join '', map { "parent $_\n" } @parents
1597                 }me or confess "$ch ?";
1598                 if ($rewriting) {
1599                     $ch =~ s{^committer .*$}{$committer_authline}m
1600                         or confess "$ch ?";
1601                 }
1602                 my $cf = "$rd/m$rewriting";
1603                 open CD, ">", $cf or die $!;
1604                 print CD $ch, "\n", $cl->{Msg} or die $!;
1605                 close CD or die $!;
1606                 my @cmd = (@git, qw(hash-object));
1607                 push @cmd, qw(-w) if $rewriting;
1608                 push @cmd, qw(-t commit), $cf;
1609                 my $newcommit = cmdoutput @cmd;
1610                 confess "$ch ?" unless $rewriting
1611                     or $newcommit eq $cl->{CommitId};
1612                 $build = $newcommit;
1613             } else {
1614                 $build = $cl->{CommitId};
1615                 trees_diff_walk "$want_upstream:", "$build:", sub {
1616                     my ($n) = @_;
1617                     no warnings qw(exiting);
1618                     next if $n eq 'debian/';
1619                     confess "mismatch @_ ?";
1620                 };
1621                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1622                     confess "mismatch @_ ?";
1623                 };
1624                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1625                 confess "mismatch @parents != @old_parents ?"
1626                     unless "@parents" eq "@old_parents";
1627             }
1628             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1629                 $last_anchor = $cur;
1630             }
1631         }
1632     };
1633
1634     my $final_check = get_differs $build, $input;
1635     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1636         if $final_check & ~D_PAT_ADD;
1637
1638     my @r = ($build, $breakwater, $last_anchor);
1639     printdebug "*** WALK RETURN @r\n";
1640     return @r
1641 }
1642
1643 sub get_head () {
1644     git_check_unmodified();
1645     return git_rev_parse qw(HEAD);
1646 }
1647
1648 sub update_head ($$$) {
1649     my ($old, $new, $mrest) = @_;
1650     push @deferred_updates, "update HEAD $new $old";
1651     run_deferred_updates $mrest;
1652 }
1653
1654 sub update_head_checkout ($$$) {
1655     my ($old, $new, $mrest) = @_;
1656     update_head $old, $new, $mrest;
1657     runcmd @git, qw(reset --hard);
1658 }
1659
1660 sub update_head_postlaunder ($$$) {
1661     my ($old, $tip, $reflogmsg) = @_;
1662     return if $tip eq $old;
1663     print "git-debrebase: laundered (head was $old)\n";
1664     update_head $old, $tip, $reflogmsg;
1665     # no tree changes except debian/patches
1666     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1667 }
1668
1669 sub currently_rebasing() {
1670     foreach (qw(rebase-merge rebase-apply)) {
1671         return 1 if stat_exists "$maindir_gitdir/$_";
1672     }
1673     return 0;
1674 }
1675
1676 sub bail_if_rebasing() {
1677     fail "you are in the middle of a git-rebase already"
1678         if currently_rebasing();
1679 }
1680
1681 sub do_launder_head ($) {
1682     my ($reflogmsg) = @_;
1683     my $old = get_head();
1684     record_ffq_auto();
1685     my ($tip,$breakwater) = walk $old;
1686     snags_maybe_bail();
1687     update_head_postlaunder $old, $tip, $reflogmsg;
1688     return ($tip,$breakwater);
1689 }
1690
1691 sub cmd_launder_v0 () {
1692     badusage "no arguments to launder-v0 allowed" if @ARGV;
1693     my $old = get_head();
1694     my ($tip,$breakwater,$last_anchor) = walk $old;
1695     update_head_postlaunder $old, $tip, 'launder';
1696     printf "# breakwater tip\n%s\n", $breakwater;
1697     printf "# working tip\n%s\n", $tip;
1698     printf "# last anchor\n%s\n", $last_anchor;
1699 }
1700
1701 sub defaultcmd_rebase () {
1702     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1703     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1704     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1705 }
1706
1707 sub cmd_analyse () {
1708     badusage "analyse does not support any options"
1709         if @ARGV and $ARGV[0] =~ m/^-/;
1710     badusage "too many arguments to analyse" if @ARGV>1;
1711     my ($old) = @ARGV;
1712     if (defined $old) {
1713         $old = git_rev_parse $old;
1714     } else {
1715         $old = git_rev_parse 'HEAD';
1716     }
1717     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1718     STDOUT->error and die $!;
1719 }
1720
1721 sub ffq_prev_branchinfo () {
1722     my $current = git_get_symref();
1723     return gdr_ffq_prev_branchinfo($current);
1724 }
1725
1726 sub ffq_check ($;$$) {
1727     # calls $ff and/or $notff zero or more times
1728     # then returns either (status,message) where status is
1729     #    exists
1730     #    detached
1731     #    weird-symref
1732     #    notbranch
1733     # or (undef,undef, $ffq_prev,$gdrlast)
1734     # $ff and $notff are called like this:
1735     #   $ff->("message for stdout\n");
1736     #   $notff->('snag-name', $message);
1737     # normally $currentval should be HEAD
1738     my ($currentval, $ff, $notff) =@_;
1739
1740     $ff //= sub { print $_[0] or die $!; };
1741     $notff //= \&snag;
1742
1743     my ($status, $message, $current, $ffq_prev, $gdrlast)
1744         = ffq_prev_branchinfo();
1745     return ($status, $message) unless $status eq 'branch';
1746
1747     my $exists = git_get_ref $ffq_prev;
1748     return ('exists',"$ffq_prev already exists") if $exists;
1749
1750     return ('not-branch', 'HEAD symref is not to refs/heads/')
1751         unless $current =~ m{^refs/heads/};
1752     my $branch = $';
1753
1754     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1755     my %checked;
1756
1757     printdebug "ffq check_specs @check_specs\n";
1758
1759     my $check = sub {
1760         my ($lrref, $desc) = @_;
1761         printdebug "ffq might check $lrref ($desc)\n";
1762         my $invert;
1763         for my $chk (@check_specs) {
1764             my $glob = $chk;
1765             $invert = $glob =~ s{^[!^]}{};
1766             last if fnmatch $glob, $lrref;
1767         }
1768         return if $invert;
1769         my $lrval = git_get_ref $lrref;
1770         return unless length $lrval;
1771
1772         if (is_fast_fwd $lrval, $currentval) {
1773             $ff->("OK, you are ahead of $lrref\n");
1774             $checked{$lrref} = 1;
1775         } elsif (is_fast_fwd $currentval, $lrval) {
1776             $checked{$lrref} = -1;
1777             $notff->('behind', "you are behind $lrref, divergence risk");
1778         } else {
1779             $checked{$lrref} = -1;
1780             $notff->('diverged', "you have diverged from $lrref");
1781         }
1782     };
1783
1784     my $merge = cfg "branch.$branch.merge",1;
1785     if (defined $merge and $merge =~ m{^refs/heads/}) {
1786         my $rhs = $';
1787         printdebug "ffq merge $rhs\n";
1788         my $check_remote = sub {
1789             my ($remote, $desc) = @_;
1790             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1791             return unless defined $remote;
1792             $check->("refs/remotes/$remote/$rhs", $desc);
1793         };
1794         $check_remote->((scalar cfg "branch.$branch.remote",1),
1795                         'remote fetch/merge branch');
1796         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1797                         (scalar cfg "branch.$branch.pushDefault",1),
1798                         'remote push branch');
1799     }
1800     if ($branch =~ m{^dgit/}) {
1801         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1802     } elsif ($branch =~ m{^master$}) {
1803         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1804     }
1805     return (undef, undef, $ffq_prev, $gdrlast);
1806 }
1807
1808 sub record_ffq_prev_deferred () {
1809     # => ('status', "message")
1810     # 'status' may be
1811     #    deferred          message is undef
1812     #    exists
1813     #    detached
1814     #    weird-symref
1815     #    notbranch
1816     # if not ff from some branch we should be ff from, is an snag
1817     # if "deferred", will have added something about that to
1818     #   @deferred_update_messages, and also maybe printed (already)
1819     #   some messages about ff checks
1820     bail_if_rebasing();
1821     my $currentval = get_head();
1822
1823     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1824     return ($status,$message) if defined $status;
1825
1826     snags_maybe_bail();
1827
1828     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1829     push @deferred_updates, "delete $gdrlast";
1830     push @deferred_update_messages, "Recorded previous head for preservation";
1831     return ('deferred', undef);
1832 }
1833
1834 sub record_ffq_auto () {
1835     my ($status, $message) = record_ffq_prev_deferred();
1836     if ($status eq 'deferred' || $status eq 'exists') {
1837     } else {
1838         snag $status, "could not record ffq-prev: $message";
1839         snags_maybe_bail();
1840     }
1841 }
1842
1843 sub ffq_prev_info () {
1844     bail_if_rebasing();
1845     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1846     my ($status, $message, $current, $ffq_prev, $gdrlast)
1847         = ffq_prev_branchinfo();
1848     if ($status ne 'branch') {
1849         snag $status, "could not check ffq-prev: $message";
1850         snags_maybe_bail();
1851     }
1852     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1853     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1854 }
1855
1856 sub stitch ($$$$$) {
1857     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1858
1859     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1860
1861     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1862         my $differs = get_differs $old_head, $ffq_prev_commitish;
1863         unless ($differs & ~D_PAT_ADD) {
1864             # ffq-prev is ahead of us, and the only tree changes it has
1865             # are possibly addition of things in debian/patches/.
1866             # Just wind forwards rather than making a pointless pseudomerge.
1867             push @deferred_updates,
1868                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1869             update_head_checkout $old_head, $ffq_prev_commitish,
1870                 "stitch (fast forward)";
1871             return;
1872         }
1873     }
1874     fresh_workarea();
1875     # We make pseudomerges with L as the contributing parent.
1876     # This makes git rev-list --first-parent work properly.
1877     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1878         'Declare fast forward / record previous work',
1879         "[git-debrebase pseudomerge: $prose]",
1880     ];
1881     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1882     update_head $old_head, $new_head, "stitch: $prose";
1883 }
1884
1885 sub do_stitch ($;$) {
1886     my ($prose, $unclean) = @_;
1887
1888     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1889     if (!$ffq_prev_commitish) {
1890         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1891         return;
1892     }
1893     my $dangling_head = get_head();
1894
1895     keycommits $dangling_head, $unclean,$unclean,$unclean;
1896     snags_maybe_bail();
1897
1898     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1899 }
1900
1901 sub upstream_commitish_search ($$) {
1902     my ($upstream_version, $tried) = @_;
1903     # todo: at some point maybe use git-deborig to do this
1904     foreach my $tagpfx ('', 'v', 'upstream/') {
1905         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1906         my $new_upstream = git_get_ref "refs/tags/$tag";
1907         push @$tried, $tag;
1908         return $new_upstream if length $new_upstream;
1909     }
1910 }
1911
1912 sub resolve_upstream_version ($$) {
1913     my ($new_upstream, $upstream_version) = @_;
1914
1915     if (!defined $new_upstream) {
1916         my @tried;
1917         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1918         if (!length $new_upstream) {
1919             fail "Could not determine appropriate upstream commitish.\n".
1920                 " (Tried these tags: @tried)\n".
1921                 " Check version, and specify upstream commitish explicitly.";
1922         }
1923     }
1924     $new_upstream = git_rev_parse $new_upstream;
1925
1926     return $new_upstream;
1927 }
1928
1929 sub cmd_new_upstream () {
1930     # automatically and unconditionally launders before rebasing
1931     # if rebase --abort is used, laundering has still been done
1932
1933     my %pieces;
1934
1935     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1936
1937     # parse args - low commitment
1938     my $spec_version = shift @ARGV;
1939     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1940     fail "bad version number \`$spec_version'" unless defined $new_version;
1941     if ($new_version->is_native()) {
1942         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1943     }
1944
1945     my $new_upstream = shift @ARGV;
1946     my $new_upstream_version = upstreamversion  $new_version;
1947     $new_upstream =
1948         resolve_upstream_version $new_upstream, $new_upstream_version;
1949
1950     record_ffq_auto();
1951
1952     my $piece = sub {
1953         my ($n, @x) = @_; # may be ''
1954         my $pc = $pieces{$n} //= {
1955             Name => $n,
1956             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1957         };
1958         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1959         $pc;
1960     };
1961
1962     my @newpieces;
1963     my $newpiece = sub {
1964         my ($n, @x) = @_; # may be ''
1965         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1966         push @newpieces, $pc;
1967     };
1968
1969     $newpiece->('',
1970         OldIx => 0,
1971         New => $new_upstream,
1972     );
1973     while (@ARGV && $ARGV[0] !~ m{^-}) {
1974         my $n = shift @ARGV;
1975
1976         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1977             unless @ARGV && $ARGV[0] !~ m{^-};
1978
1979         my $c = git_rev_parse shift @ARGV;
1980         die unless $n =~ m/^$extra_orig_namepart_re$/;
1981         $newpiece->($n, New => $c);
1982     }
1983
1984     # now we need to investigate the branch this generates the
1985     # laundered version but we don't switch to it yet
1986     my $old_head = get_head();
1987     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1988
1989     my $old_bw_cl = classify $old_bw;
1990     my $old_anchor_cl = classify $old_anchor;
1991     my $old_upstream;
1992     if (!$old_anchor_cl->{OrigParents}) {
1993         snag 'anchor-treated',
1994             'old anchor is recognised due to --anchor, cannot check upstream';
1995     } else {
1996         $old_upstream = parsecommit
1997             $old_anchor_cl->{OrigParents}[0]{CommitId};
1998         $piece->('', Old => $old_upstream->{CommitId});
1999     }
2000
2001     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2002         if ($old_upstream->{Msg} =~
2003  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2004            ) {
2005             my @oldpieces = (split / /, $1);
2006             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2007             if ($old_n_parents != @oldpieces &&
2008                 $old_n_parents != @oldpieces + 1) {
2009                 snag 'upstream-confusing', sprintf
2010                     "previous upstream combine %s".
2011                     " mentions %d pieces (each implying one parent)".
2012                     " but has %d parents".
2013                     " (one per piece plus maybe a previous combine)",
2014                     $old_upstream->{CommitId},
2015                     (scalar @oldpieces),
2016                     $old_n_parents;
2017             } elsif ($oldpieces[0] ne '.') {
2018                 snag 'upstream-confusing', sprintf
2019                     "previous upstream combine %s".
2020                     " first piece is not \`.'",
2021                     $oldpieces[0];
2022             } else {
2023                 $oldpieces[0] = '';
2024                 foreach my $i (0..$#oldpieces) {
2025                     my $n = $oldpieces[$i];
2026                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2027                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2028                 }
2029             }
2030         } else {
2031             snag 'upstream-confusing',
2032                 "previous upstream $old_upstream->{CommitId} is from".
2033                " git-debrebase but not an \`upstream-combine' commit";
2034         }
2035     }
2036
2037     foreach my $pc (values %pieces) {
2038         if (!$old_upstream) {
2039             # we have complained already
2040         } elsif (!$pc->{Old}) {
2041             snag 'upstream-new-piece',
2042                 "introducing upstream piece \`$pc->{Name}'";
2043         } elsif (!$pc->{New}) {
2044             snag 'upstream-rm-piece',
2045                 "dropping upstream piece \`$pc->{Name}'";
2046         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2047             snag 'upstream-not-ff',
2048                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2049         }
2050     }
2051
2052     printdebug "%pieces = ", (dd \%pieces), "\n";
2053     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2054
2055     snags_maybe_bail();
2056
2057     my $new_bw;
2058
2059     fresh_workarea();
2060     in_workarea sub {
2061         my @upstream_merge_parents;
2062
2063         if (!any_snags()) {
2064             push @upstream_merge_parents, $old_upstream->{CommitId};
2065         }
2066
2067         foreach my $pc (@newpieces) { # always has '' first
2068             if ($pc->{Name}) {
2069                 read_tree_subdir $pc->{Name}, $pc->{New};
2070             } else {
2071                 runcmd @git, qw(read-tree), $pc->{New};
2072             }
2073             push @upstream_merge_parents, $pc->{New};
2074         }
2075
2076         # index now contains the new upstream
2077
2078         if (@newpieces > 1) {
2079             # need to make the upstream subtree merge commit
2080             $new_upstream = make_commit \@upstream_merge_parents,
2081                 [ "Combine upstreams for $new_upstream_version",
2082  ("[git-debrebase upstream-combine . ".
2083  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2084  ": new upstream]"),
2085                 ];
2086         }
2087
2088         # $new_upstream is either the single upstream commit, or the
2089         # combined commit we just made.  Either way it will be the
2090         # "upstream" parent of the anchor merge.
2091
2092         read_tree_subdir 'debian', "$old_bw:debian";
2093
2094         # index now contains the anchor merge contents
2095         $new_bw = make_commit [ $old_bw, $new_upstream ],
2096             [ "Update to upstream $new_upstream_version",
2097  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2098             ];
2099
2100         my $clogsignoff = cmdoutput qw(git show),
2101             '--pretty=format:%an <%ae>  %aD',
2102             $new_bw;
2103
2104         # Now we have to add a changelog stanza so the Debian version
2105         # is right.
2106         die if unlink "debian";
2107         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2108         unlink "debian/changelog" or $!==ENOENT or die $!;
2109         mkdir "debian" or die $!;
2110         open CN, ">", "debian/changelog" or die $!;
2111         my $oldclog = git_cat_file ":debian/changelog";
2112         $oldclog =~ m/^($package_re) \(\S+\) / or
2113             fail "cannot parse old changelog to get package name";
2114         my $p = $1;
2115         print CN <<END, $oldclog or die $!;
2116 $p ($new_version) UNRELEASED; urgency=medium
2117
2118   * Update to new upstream version $new_upstream_version.
2119
2120  -- $clogsignoff
2121
2122 END
2123         close CN or die $!;
2124         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2125
2126         # Now we have the final new breakwater branch in the index
2127         $new_bw = make_commit [ $new_bw ],
2128             [ "Update changelog for new upstream $new_upstream_version",
2129               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2130             ];
2131     };
2132
2133     # we have constructed the new breakwater. we now need to commit to
2134     # the laundering output, because git-rebase can't easily be made
2135     # to make a replay list which is based on some other branch
2136
2137     update_head_postlaunder $old_head, $old_laundered_tip,
2138         'launder for new upstream';
2139
2140     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2141     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2142         "debrebase new-upstream $new_version: rebase";
2143     runcmd @cmd;
2144     # now it's for the user to sort out
2145 }
2146
2147 sub cmd_record_ffq_prev () {
2148     badusage "no arguments allowed" if @ARGV;
2149     my ($status, $msg) = record_ffq_prev_deferred();
2150     if ($status eq 'exists' && $opt_noop_ok) {
2151         print "Previous head already recorded\n" or die $!;
2152     } elsif ($status eq 'deferred') {
2153         run_deferred_updates 'record-ffq-prev';
2154     } else {
2155         fail "Could not preserve: $msg";
2156     }
2157 }
2158
2159 sub cmd_anchor () {
2160     badusage "no arguments allowed" if @ARGV;
2161     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2162     print "$bw\n" or die $!;
2163 }
2164
2165 sub cmd_breakwater () {
2166     badusage "no arguments allowed" if @ARGV;
2167     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2168     print "$bw\n" or die $!;
2169 }
2170
2171 sub cmd_status () {
2172     badusage "no arguments allowed" if @ARGV;
2173
2174     # todo: gdr status should print divergence info
2175     # todo: gdr status should print upstream component(s) info
2176     # todo: gdr should leave/maintain some refs with this kind of info ?
2177
2178     my $oldest = { Badness => 0 };
2179     my $newest;
2180     my $note = sub {
2181         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2182         if ($oldest->{Badness} < $badness) {
2183             $oldest = $newest = undef;
2184         }
2185         $oldest = {
2186                    Badness => $badness,
2187                    CommitId => $cl->{CommitId},
2188                    OurMsg => $ourmsg,
2189                    KcMsg => $kcmsg,
2190                   };
2191         $newest //= $oldest;
2192     };
2193     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2194         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2195         sub { $note->(2, 'branch is unlaundered', @_); },
2196         sub { $note->(3, 'branch needs laundering', @_); },
2197         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2198
2199     my $prcommitinfo = sub {
2200         my ($cid) = @_;
2201         flush STDOUT or die $!;
2202         runcmd @git, qw(--no-pager log -n1),
2203             '--pretty=format:    %h %s%n',
2204             $cid;
2205     };
2206
2207     print "current branch contents, in git-debrebase terms:\n";
2208     if (!$oldest->{Badness}) {
2209         print "  branch is laundered\n";
2210     } else {
2211         print "  $oldest->{OurMsg}\n";
2212         my $printed = '';
2213         foreach my $info ($oldest, $newest) {
2214             my $cid = $info->{CommitId};
2215             next if $cid eq $printed;
2216             $printed = $cid;
2217             print "  $info->{KcMsg}\n";
2218             $prcommitinfo->($cid);
2219         }
2220     }
2221
2222     my $prab = sub {
2223         my ($cid, $what) = @_;
2224         if (!defined $cid) {
2225             print "  $what is not well-defined\n";
2226         } else {
2227             print "  $what\n";
2228             $prcommitinfo->($cid);
2229         }
2230     };
2231     print "key git-debrebase commits:\n";
2232     $prab->($anchor, 'anchor');
2233     $prab->($bw, 'breakwater');
2234
2235     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2236         ffq_prev_branchinfo();
2237
2238     print "branch and ref status, in git-debrebase terms:\n";
2239     if ($ffq_msg) {
2240         print "  $ffq_msg\n";
2241     } else {
2242         $ffq_prev = git_get_ref $ffq_prev;
2243         $gdrlast = git_get_ref $gdrlast;
2244         if ($ffq_prev) {
2245             print "  unstitched; previous tip was:\n";
2246             $prcommitinfo->($ffq_prev);
2247         } elsif (!$gdrlast) {
2248             print "  stitched? (no record of git-debrebase work)\n";
2249         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2250             print "  stitched\n";
2251         } else {
2252             print "  not git-debrebase (diverged since last stitch)\n"
2253         }
2254     }
2255     print "you are currently rebasing\n" if currently_rebasing();
2256 }
2257
2258 sub cmd_stitch () {
2259     my $prose = 'stitch';
2260     getoptions("stitch",
2261                'prose=s', \$prose);
2262     badusage "no arguments allowed" if @ARGV;
2263     do_stitch $prose, 0;
2264 }
2265 sub cmd_prepush () { cmd_stitch(); }
2266
2267 sub cmd_quick () {
2268     badusage "no arguments allowed" if @ARGV;
2269     do_launder_head 'launder for git-debrebase quick';
2270     do_stitch 'quick';
2271 }
2272
2273 sub cmd_conclude () {
2274     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2275     if (!$ffq_prev_commitish) {
2276         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2277         return;
2278     }
2279     my $dangling_head = get_head();
2280
2281     badusage "no arguments allowed" if @ARGV;
2282     do_launder_head 'launder for git-debrebase quick';
2283     do_stitch 'quick';
2284 }
2285
2286 sub cmd_scrap () {
2287     if (currently_rebasing()) {
2288         runcmd @git, qw(rebase --abort);
2289         push @deferred_updates, 'verify HEAD HEAD';
2290         # noop, but stops us complaining that scrap was a noop
2291     }
2292     badusage "no arguments allowed" if @ARGV;
2293     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2294     my $scrapping_head;
2295     if ($ffq_prev_commitish) {
2296         $scrapping_head = get_head();
2297         push @deferred_updates,
2298             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2299             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2300     }
2301     if (git_get_ref $merge_cache_ref) {
2302         push @deferred_updates,
2303             "delete $merge_cache_ref";
2304     }
2305     if (!@deferred_updates) {
2306         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2307         finish 0;
2308     }
2309     snags_maybe_bail();
2310     if ($scrapping_head) {
2311         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2312     } else {
2313         run_deferred_updates "scrap";
2314     }
2315 }
2316
2317 sub make_patches_staged ($) {
2318     my ($head) = @_;
2319     # Produces the patches that would result from $head if it were
2320     # laundered.
2321     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2322     fresh_workarea();
2323     in_workarea sub {
2324         gbp_pq_export 'bw', $secret_bw, $secret_head;
2325     };
2326 }
2327
2328 sub make_patches ($) {
2329     my ($head) = @_;
2330     keycommits $head, 0, \&snag;
2331     make_patches_staged $head;
2332     my $out;
2333     in_workarea sub {
2334         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2335         runcmd @git, qw(read-tree), $head;
2336         read_tree_subdir 'debian/patches', $ptree;
2337         $out = make_commit [$head], [
2338             'Commit patch queue (exported by git-debrebase)',
2339             '[git-debrebase: export and commit patches]',
2340         ];
2341     };
2342     return $out;
2343 }
2344
2345 sub cmd_make_patches () {
2346     my $opt_quiet_would_amend;
2347     getoptions("make-patches",
2348                'quiet-would-amend!', \$opt_quiet_would_amend);
2349     badusage "no arguments allowed" if @ARGV;
2350     bail_if_rebasing();
2351     my $old_head = get_head();
2352     my $new = make_patches $old_head;
2353     my $d = get_differs $old_head, $new;
2354     if ($d == 0) {
2355         fail "No (more) patches to export." unless $opt_noop_ok;
2356         return;
2357     } elsif ($d == D_PAT_ADD) {
2358         snags_maybe_bail();
2359         update_head_checkout $old_head, $new, 'make-patches';
2360     } else {
2361         print STDERR failmsg
2362             "Patch export produced patch amendments".
2363             " (abandoned output commit $new).".
2364             "  Try laundering first."
2365             unless $opt_quiet_would_amend;
2366         finish 7;
2367     }
2368 }
2369
2370 sub cmd_convert_from_gbp () {
2371     badusage "want only 1 optional argument, the upstream git commitish"
2372         unless @ARGV<=1;
2373
2374     my $clogp = parsechangelog();
2375     my $version = $clogp->{'Version'}
2376         // die "missing Version from changelog";
2377
2378     my ($upstream_spec) = @ARGV;
2379
2380     my $upstream_version = upstreamversion $version;
2381     my $upstream =
2382         resolve_upstream_version($upstream_spec, $upstream_version);
2383
2384     my $old_head = get_head();
2385
2386     my $upsdiff = get_differs $upstream, $old_head;
2387     if ($upsdiff & D_UPS) {
2388         runcmd @git, qw(--no-pager diff --stat),
2389             $upstream, $old_head,
2390             qw( -- :!/debian :/);
2391         fail <<END;
2392 upstream ($upstream_spec) and HEAD are not
2393 identical in upstream files.  See diffstat above, or run
2394   git diff $upstream_spec HEAD -- :!/debian :/
2395 END
2396     }
2397
2398     if (!is_fast_fwd $upstream, $old_head) {
2399         snag 'upstream-not-ancestor',
2400             "upstream ($upstream) is not an ancestor of HEAD";
2401     } else {
2402         my $wrong = cmdoutput
2403             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2404              qw(-- :/ :!/debian));
2405         if (length $wrong) {
2406             snag 'unexpected-upstream-changes',
2407                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2408             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2409         }
2410     }
2411
2412     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2413         snag 'upstream-has-debian',
2414             "upstream ($upstream) contains debian/ directory";
2415     }
2416
2417     my $previous_dgit_view = eval {
2418         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2419         my ($lvsn, $suite);
2420         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2421             my ($stz, $desc) = @_;
2422             no warnings qw(exiting);
2423             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2424             next unless $stz->{Date};
2425             next unless $stz->{Distribution} ne 'UNRELEASED';
2426             $lvsn = $stz->{Version};
2427             $suite = $stz->{Distribution};
2428             last;
2429         };
2430         die "neither of the first two changelog entries are released\n"
2431             unless defined $lvsn;
2432         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2433         my $mtag_pat = debiantag_maintview $lvsn, '*';
2434         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2435             $mtag_pat;
2436         die "could not find suitable maintainer view tag $mtag_pat\n"
2437             unless $mtag_pat =~ m{/};
2438         is_fast_fwd $mtag, 'HEAD' or
2439             die "HEAD is not FF from maintainer tag $mtag!";
2440         my $dtag = "archive/$mtag";
2441         is_fast_fwd $mtag, $dtag or
2442             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2443         print "will stitch in dgit view, $dtag\n";
2444         git_rev_parse $dtag;
2445     };
2446     if (!$previous_dgit_view) {
2447         $@ =~ s/^\n+//;
2448         chomp $@;
2449         print STDERR "cannot stitch in dgit view: $@\n";
2450     }
2451
2452     snags_maybe_bail_early();
2453
2454     my $work;
2455
2456     fresh_workarea();
2457     in_workarea sub {
2458         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2459         # make a branch out of the patch queue - we'll want this in a mo
2460         runcmd qw(gbp pq import);
2461         # strip the patches out
2462         runcmd @git, qw(checkout -q gdr-internal~0);
2463         rm_subdir_cached 'debian/patches';
2464         $work = make_commit ['HEAD'], [
2465  'git-debrebase convert-from-gbp: drop patches from tree',
2466  'Delete debian/patches, as part of converting to git-debrebase format.',
2467  '[git-debrebase convert-from-gbp: drop patches from tree]'
2468                               ];
2469         # make the anchor merge
2470         # the tree is already exactly right
2471         $work = make_commit [$work, $upstream], [
2472  'git-debrebase import: declare upstream',
2473  'First breakwater merge.',
2474  '[git-debrebase anchor: declare upstream]'
2475                               ];
2476
2477         # rebase the patch queue onto the new breakwater
2478         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2479         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2480         $work = git_rev_parse 'HEAD';
2481
2482         if ($previous_dgit_view) {
2483             $work = make_commit [$work, $previous_dgit_view], [
2484  'git-debrebase import: declare ff from dgit archive view',
2485  '[git-debrebase pseudomerge: import-from-gbp]',
2486             ];
2487         }
2488     };
2489
2490     ffq_check $work;
2491     snags_maybe_bail();
2492     update_head_checkout $old_head, $work, 'convert-from-gbp';
2493 }
2494
2495 sub cmd_convert_to_gbp () {
2496     badusage "no arguments allowed" if @ARGV;
2497     my $head = get_head();
2498     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2499     keycommits $head, 0;
2500     my $out;
2501     make_patches_staged $head;
2502     in_workarea sub {
2503         $out = make_commit ['HEAD'], [
2504             'Commit patch queue (converted from git-debrebase format)',
2505             '[git-debrebase convert-to-gbp: commit patches]',
2506         ];
2507     };
2508     if (defined $ffq) {
2509         push @deferred_updates, "delete $ffq";
2510         push @deferred_updates, "delete $gdrlast";
2511     }
2512     snags_maybe_bail();
2513     update_head_checkout $head, $out, "convert to gbp (v0)";
2514     print <<END or die $!;
2515 git-debrebase: converted to git-buildpackage branch format
2516 git-debrebase: WARNING: do not now run "git-debrebase" any more
2517 git-debrebase: WARNING: doing so would drop all upstream patches!
2518 END
2519 }
2520
2521 sub cmd_convert_from_dgit_view () {
2522     my $clogp = parsechangelog();
2523
2524     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2525     my $do_origs = 1;
2526     my $do_tags = 1;
2527     my $always = 0;
2528     my $diagnose = 0;
2529
2530     getoptions("convert-from-dgit-view",
2531                'diagnose!', \$diagnose,
2532                'build-products-dir:s', \$bpd,
2533                'origs!', \$do_origs,
2534                'tags!', \$do_tags,
2535                'always-convert-anyway!', \$always);
2536     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2537
2538     my @upstreams;
2539
2540     if (@ARGV) {
2541         my $spec = shift @ARGV;
2542         my $commit = git_rev_parse "$spec^{commit}";
2543         push @upstreams, { Commit => $commit,
2544                            Source => "$ARGV[0], from command line",
2545                            Only => 1,
2546                          };
2547     }
2548
2549     my $head = get_head();
2550
2551     if (!$always) {
2552         my $troubles = 0;
2553         my $trouble = sub { $troubles++; };
2554         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2555         printdebug "troubles=$troubles\n";
2556         if (!$troubles) {
2557             print STDERR <<END;
2558 $us: Branch already seems to be in git-debrebase format!
2559 $us: --always-convert-anyway would do the conversion operation anyway
2560 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2561 END
2562             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2563             finish 0;
2564         }
2565     }
2566
2567     snags_maybe_bail_early();
2568
2569     my $version = upstreamversion $clogp->{Version};
2570     print STDERR "Considering possible commits corresponding to upstream:\n";
2571
2572     if (!@upstreams) {
2573         if ($do_tags) {
2574             my @tried;
2575             my $ups_tag = upstream_commitish_search $version, \@tried;
2576             if ($ups_tag) {
2577                 my $this = "git tag $tried[-1]";
2578                 push @upstreams, { Commit => $ups_tag,
2579                                    Source => $this,
2580                                  };
2581             } else {
2582                 printf STDERR
2583                     " git tag: no suitable tag found (tried %s)\n",
2584                     "@tried";
2585             }
2586         }
2587         if ($do_origs) {
2588             my $p = $clogp->{'Source'};
2589             # we do a quick check to see if there are plausible origs
2590             my $something=0;
2591             if (!opendir BPD, $bpd) {
2592                 die "$bpd: opendir: $!" unless $!==ENOENT;
2593             } else {
2594                 while ($!=0, my $f = readdir BPD) {
2595                     next unless is_orig_file_of_p_v $f, $p, $version;
2596                     printf STDERR
2597                         " orig: found what looks like a .orig, %s\n",
2598                         "$bpd/$f";
2599                     $something=1;
2600                     last;
2601                 }
2602                 die "read $bpd: $!" if $!;
2603                 closedir BPD;
2604             }
2605             if ($something) {
2606                 my $tree = cmdoutput
2607                     @dgit, qw(--build-products-dir), $bpd,
2608                     qw(print-unapplied-treeish);
2609                 fresh_workarea();
2610                 in_workarea sub {
2611                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2612                     rm_subdir_cached 'debian';
2613                     $tree = cmdoutput @git, qw(write-tree);
2614                     my $ups_synth = make_commit [], [ <<END, <<END,
2615 Import effective orig tree for upstream version $version
2616 END
2617 This includes the contents of the .orig(s), minus any debian/ directory.
2618
2619 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2620 END
2621                                                     ];
2622                     push @upstreams, { Commit => $ups_synth,
2623                                        Source => "orig(s) imported via dgit",
2624                                      };
2625                 }
2626             } else {
2627                 printf STDERR
2628                     " orig: no suitable origs found (looked for %s in %s)\n",
2629                     "${p}_".(stripeoch $version)."...", $bpd;
2630             }
2631         }
2632     }
2633
2634     my $some_patches = stat_exists 'debian/patches/series';
2635
2636     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2637
2638     my $result;
2639     foreach my $u (@upstreams) {
2640         my $work = $head;
2641         fresh_workarea();
2642         in_workarea sub {
2643             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2644             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2645             runcmd @git, qw(clean -xdff);
2646             runcmd @git, qw(checkout), $head, qw(-- debian);
2647             if ($some_patches) {
2648                 rm_subdir_cached 'debian/patches';
2649                 $work = make_commit [ $work ], [
2650  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2651  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2652  "to git-debrebase format.  Upstream changes will appear as commits.",
2653  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2654                                            ];
2655             }
2656             $work = make_commit [ $work, $u->{Commit} ], [
2657  'git-debrebase convert-from-dgit-view: declare upstream',
2658  '(Re)constructed breakwater merge.',
2659  '[git-debrebase anchor: declare upstream]'
2660                                                          ];
2661             runcmd @git, qw(checkout --quiet -b mk), $work;
2662             if ($some_patches) {
2663                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2664                 runcmd @git, qw(reset --quiet);
2665                 my @gbp_cmd = (qw(gbp pq import));
2666                 if (!$diagnose) {
2667                     my $gbp_err = "../gbp-pq-err";
2668                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2669                 }
2670                 my $r = system @gbp_cmd;
2671                 if ($r) {
2672                     printf STDERR
2673                         " %s: couldn't apply patches: gbp pq %s",
2674                         $u->{Source}, waitstatusmsg();
2675                     return;
2676                 }
2677             }
2678             my $work = git_rev_parse qw(HEAD);
2679             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2680             if (length $diffout) {
2681                 print STDERR
2682                     " $u->{Source}: applying patches gives different tree\n";
2683                 print STDERR $diffout if $diagnose;
2684                 return;
2685             }
2686             # OMG!
2687             $u->{Result} = $work;
2688             $result = $u;
2689         };
2690         last if $result;
2691     }
2692
2693     if (!$result) {
2694         fail <<END;
2695 Could not find or construct a suitable upstream commit.
2696 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2697 upstream commmit explicitly or provide suitable origs.
2698 END
2699     }
2700
2701     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2702
2703     ffq_check $result->{Result};
2704     snags_maybe_bail();
2705     update_head_checkout $head, $result->{Result},
2706         'convert-from-dgit-view';
2707 }
2708
2709 sub cmd_record_resolved_merge () {
2710     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2711     # xxx needs documentation
2712     my $new = get_head();
2713     my $method;
2714
2715     print "Checking how you have resolved the merge problem\n";
2716     my $nope = sub { print "Not $method: @_"; 0; };
2717
2718     my $maybe = sub { print "Seems to be $method.\n"; };
2719     my $yes = sub {
2720         my ($key, $ref) = @_;
2721         reflog_cache_insert $merge_cache_ref, $key, $ref;
2722         print "OK.  You can switch branches and try git-debrebase again.\n";
2723         1;
2724     };
2725
2726     fresh_workarea 'merge';
2727     sub {
2728         $method = 'vanilla-merge patchqueue';
2729         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2730         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2731         foreach my $lr (qw(left right)) {
2732             my $n = "$wrecknoteprefix/$lr-patchqueue";
2733             my $lrpq = git_get_ref $n;
2734             $lrpq or return $nope->("wreckage did not contain patchqueues");
2735             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2736         }
2737         $maybe->();
2738         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2739             or die "wreckage element $wrecknoteprefix/new-base missing";
2740         my $result = merge_series_patchqueue_convert
2741             {}, $newbase, $new;
2742         $yes->("vanilla-merge $vanilla", $result);
2743         1;
2744     }->() or sub {
2745         fail "No resolved merge method seems applicable.\n";
2746     }->();
2747 }
2748
2749 sub cmd_downstream_rebase_launder_v0 () {
2750     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2751     my ($base) = @ARGV;
2752     $base = git_rev_parse $base;
2753     my $old_head = get_head();
2754     my $current = $old_head;
2755     my $topmost_keep;
2756     for (;;) {
2757         if ($current eq $base) {
2758             $topmost_keep //= $current;
2759             print " $current BASE stop\n";
2760             last;
2761         }
2762         my $cl = classify $current;
2763         print " $current $cl->{Type}";
2764         my $keep = 0;
2765         my $p0 = $cl->{Parents}[0]{CommitId};
2766         my $next;
2767         if ($cl->{Type} eq 'Pseudomerge') {
2768             print " ^".($cl->{Contributor}{Ix}+1);
2769             $next = $cl->{Contributor}{CommitId};
2770         } elsif ($cl->{Type} eq 'AddPatches' or
2771                  $cl->{Type} eq 'Changelog') {
2772             print " strip";
2773             $next = $p0;
2774         } else {
2775             print " keep";
2776             $next = $p0;
2777             $keep = 1;
2778         }
2779         print "\n";
2780         if ($keep) {
2781             $topmost_keep //= $current;
2782         } else {
2783             die "to-be stripped changes not on top of the branch\n"
2784                 if $topmost_keep;
2785         }
2786         $current = $next;
2787     }
2788     if ($topmost_keep eq $old_head) {
2789         print "unchanged\n";
2790     } else {
2791         print "updating to $topmost_keep\n";
2792         update_head_checkout
2793             $old_head, $topmost_keep,
2794             'downstream-rebase-launder-v0';
2795     }
2796 }
2797
2798 getoptions_main
2799           ("bad options\n",
2800            "D+" => \$debuglevel,
2801            'noop-ok', => \$opt_noop_ok,
2802            'f=s' => \@snag_force_opts,
2803            'anchor=s' => \@opt_anchors,
2804            '--dgit=s' => \($dgit[0]),
2805            'force!',
2806            '-i:s' => sub {
2807                my ($opt,$val) = @_;
2808                badusage "git-debrebase: no cuddling to -i for git-rebase"
2809                    if length $val;
2810                die if $opt_defaultcmd_interactive; # should not happen
2811                $opt_defaultcmd_interactive = [ qw(-i) ];
2812                # This access to @ARGV is excessive familiarity with
2813                # Getopt::Long, but there isn't another sensible
2814                # approach.  '-i=s{0,}' does not work with bundling.
2815                push @$opt_defaultcmd_interactive, @ARGV;
2816                @ARGV=();
2817            },
2818            'help' => sub { print $usage_message or die $!; finish 0; },
2819            );
2820
2821 initdebug('git-debrebase ');
2822 enabledebug if $debuglevel;
2823
2824 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2825 chdir $toplevel or die "chdir $toplevel: $!";
2826
2827 $rd = fresh_playground "$playprefix/misc";
2828
2829 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2830
2831 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2832     defaultcmd_rebase();
2833 } else {
2834     my $cmd = shift @ARGV;
2835     my $cmdfn = $cmd;
2836     $cmdfn =~ y/-/_/;
2837     $cmdfn = ${*::}{"cmd_$cmdfn"};
2838
2839     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2840     $cmdfn->();
2841 }
2842
2843 finish 0;