git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23
  24 use strict;
  25
  26 use Debian::Dgit qw(:DEFAULT :playground);
  27 setup_sigwarn();
  28
  29 use Memoize;
  30 use Carp;
  31 use POSIX;
  32 use Data::Dumper;
  33 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  34 use Dpkg::Version;
  35 use File::FnMatch qw(:fnmatch);
  36
  37 our ($opt_force, $opt_noop_ok, @opt_anchors);
  38 our ($opt_defaultcmd_interactive);
  39
  40 our $us = qw(git-debrebase);
  41
  42 sub badusage ($) {
  43     my ($m) = @_;
  44     print STDERR "bad usage: $m\n";
  45     finish 8;
  46 }
  47
  48 sub cfg ($;$) {
  49     my ($k, $optional) = @_;
  50     local $/ = "\0";
  51     my @cmd = qw(git config -z);
  52     push @cmd, qw(--get-all) if wantarray;
  53     push @cmd, $k;
  54     my $out = cmdoutput_errok @cmd;
  55     if (!defined $out) {
  56         fail "missing required git config $k" unless $optional;
  57         return ();
  58     }
  59     my @l = split /\0/, $out;
  60     return wantarray ? @l : $l[0];
  61 }
  62
  63 memoize('cfg');
  64
  65 sub dd ($) {
  66     my ($v) = @_;
  67     my $dd = new Data::Dumper [ $v ];
  68     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  69     return Dump $dd;
  70 }
  71
  72 sub get_commit ($) {
  73     my ($objid) = @_;
  74     my $data = (git_cat_file $objid, 'commit');
  75     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
  76     return ($`,$');
  77 }
  78
  79 sub D_UPS ()      { 0x02; } # upstream files
  80 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
  81 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
  82 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
  83 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
  84 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
  85
  86 our $playprefix = 'debrebase';
  87 our $rd;
  88 our $workarea;
  89
  90 our @git = qw(git);
  91
  92 sub in_workarea ($) {
  93     my ($sub) = @_;
  94     changedir $workarea;
  95     my $r = eval { $sub->(); };
  96     { local $@; changedir $maindir; }
  97     die $@ if $@;
  98 }
  99
 100 sub fresh_workarea () {
 101     $workarea = fresh_playground "$playprefix/work";
 102     in_workarea sub { playtree_setup };
 103 }
 104
 105 our $snags_forced = 0;
 106 our $snags_tripped = 0;
 107 our $snags_summarised = 0;
 108 our @deferred_updates;
 109 our @deferred_update_messages;
 110
 111 sub all_snags_summarised () {
 112     $snags_forced + $snags_tripped == $snags_summarised;
 113 }
 114 sub run_deferred_updates ($) {
 115     my ($mrest) = @_;
 116
 117     confess 'dangerous internal error' unless all_snags_summarised();
 118
 119     my @upd_cmd = (@git, qw(update-ref --stdin -m), "debrebase: $mrest");
 120     debugcmd '>|', @upd_cmd;
 121     open U, "|-", @upd_cmd or die $!;
 122     foreach (@deferred_updates) {
 123         printdebug ">= ", $_, "\n";
 124         print U $_, "\n" or die $!;
 125     }
 126     printdebug ">\$\n";
 127     close U or failedcmd @upd_cmd;
 128
 129     print $_, "\n" foreach @deferred_update_messages;
 130
 131     @deferred_updates = ();
 132     @deferred_update_messages = ();
 133 }
 134
 135 sub get_differs ($$) {
 136     my ($x,$y) = @_;
 137     # This resembles quiltify_trees_differ, in dgit, a bit.
 138     # But we don't care about modes, or dpkg-source-unrepresentable
 139     # changes, and we don't need the plethora of different modes.
 140     # Conversely we need to distinguish different kinds of changes to
 141     # debian/ and debian/patches/.
 142
 143     my $differs = 0;
 144
 145     my $rundiff = sub {
 146         my ($opts, $limits, $fn) = @_;
 147         my @cmd = (@git, qw(diff-tree -z --no-renames));
 148         push @cmd, @$opts;
 149         push @cmd, "$_:" foreach $x, $y;
 150         push @cmd, '--', @$limits;
 151         my $diffs = cmdoutput @cmd;
 152         foreach (split /\0/, $diffs) { $fn->(); }
 153     };
 154
 155     $rundiff->([qw(--name-only)], [], sub {
 156         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 157     });
 158
 159     if ($differs & DS_DEB) {
 160         $differs &= ~DS_DEB;
 161         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 162             $differs |=
 163                 m{^debian/patches/}      ? D_PAT_OTH  :
 164                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 165                                            D_DEB_OTH;
 166         });
 167         die "mysterious debian changes $x..$y"
 168             unless $differs & (D_PAT_OTH|DS_DEB);
 169     }
 170
 171     if ($differs & D_PAT_OTH) {
 172         my $mode;
 173         $differs &= ~D_PAT_OTH;
 174         my $pat_oth = sub {
 175             $differs |= D_PAT_OTH;
 176             no warnings qw(exiting);  last;
 177         };
 178         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 179             no warnings qw(exiting);
 180             if (!defined $mode) {
 181                 $mode = $_;  next;
 182             }
 183             die unless s{^debian/patches/}{};
 184             my $ok;
 185             if ($mode eq 'A' && !m/\.series$/s) {
 186                 $ok = 1;
 187             } elsif ($mode eq 'M' && $_ eq 'series') {
 188                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 189                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 190                 chomp $x_s;  $x_s .= "\n";
 191                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 192             } else {
 193                 # nope
 194             }
 195             $mode = undef;
 196             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 197         });
 198         die "mysterious debian/patches changes $x..$y"
 199             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 200     }
 201
 202     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 203
 204     return $differs;
 205 }
 206
 207 sub commit_pr_info ($) {
 208     my ($r) = @_;
 209     return Data::Dumper->dump([$r], [qw(commit)]);
 210 }
 211
 212 sub calculate_committer_authline () {
 213     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 214         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 215     my ($h,$m) = get_commit $c;
 216     $h =~ m/^committer .*$/m or confess "($h) ?";
 217     return $&;
 218 }
 219
 220 sub rm_subdir_cached ($) {
 221     my ($subdir) = @_;
 222     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 223 }
 224
 225 sub read_tree_subdir ($$) {
 226     my ($subdir, $new_tree_object) = @_;
 227     rm_subdir_cached $subdir;
 228     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 229 }
 230
 231 sub make_commit ($$) {
 232     my ($parents, $message_paras) = @_;
 233     my $tree = cmdoutput @git, qw(write-tree);
 234     my @cmd = (@git, qw(commit-tree), $tree);
 235     push @cmd, qw(-p), $_ foreach @$parents;
 236     push @cmd, qw(-m), $_ foreach @$message_paras;
 237     return cmdoutput @cmd;
 238 }
 239
 240 our @snag_force_opts;
 241 sub snag ($$) {
 242     my ($tag,$msg) = @_;
 243     if (grep { $_ eq $tag } @snag_force_opts) {
 244         $snags_forced++;
 245         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 246     } else {
 247         $snags_tripped++;
 248         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 249     }
 250 }
 251
 252 # Important: all mainline code must call snags_maybe_bail after
 253 # any point where snag might be called, but before making changes
 254 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 255 # may be called more than once if necessary (but this is not ideal
 256 # because then the messages about number of snags may be confusing).
 257 sub snags_maybe_bail () {
 258     return if all_snags_summarised();
 259     if ($snags_forced) {
 260         printf STDERR
 261             "%s: snags: %d overriden by individual -f options\n",
 262             $us, $snags_forced;
 263     }
 264     if ($snags_tripped) {
 265         if ($opt_force) {
 266             printf STDERR
 267                 "%s: snags: %d overriden by global --force\n",
 268                 $us, $snags_tripped;
 269         } else {
 270             fail sprintf
 271   "%s: snags: %d blockers (you could -f<tag>, or --force)",
 272                 $us, $snags_tripped;
 273         }
 274     }
 275     $snags_summarised = $snags_forced + $snags_tripped;
 276 }
 277 sub any_snags () {
 278     return $snags_forced || $snags_tripped;
 279 }
 280
 281 # classify returns an info hash like this
 282 #   CommitId => $objid
 283 #   Hdr => # commit headers, including 1 final newline
 284 #   Msg => # commit message (so one newline is dropped)
 285 #   Tree => $treeobjid
 286 #   Type => (see below)
 287 #   Parents = [ {
 288 #       Ix => $index # ie 0, 1, 2, ...
 289 #       CommitId
 290 #       Differs => return value from get_differs
 291 #       IsOrigin
 292 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 293 #     } ...]
 294 #   NewMsg => # commit message, but with any [dgit import ...] edited
 295 #             # to say "[was: ...]"
 296 #
 297 # Types:
 298 #   Packaging
 299 #   Changelog
 300 #   Upstream
 301 #   AddPatches
 302 #   Mixed
 303 #
 304 #   Pseudomerge
 305 #     has additional entres in classification result
 306 #       Overwritten = [ subset of Parents ]
 307 #       Contributor = $the_remaining_Parent
 308 #
 309 #   DgitImportUnpatched
 310 #     has additional entry in classification result
 311 #       OrigParents = [ subset of Parents ]
 312 #
 313 #   Anchor
 314 #     has additional entry in classification result
 315 #       OrigParents = [ subset of Parents ]  # singleton list
 316 #
 317 #   TreatAsAnchor
 318 #
 319 #   BreakwaterStart
 320 #
 321 #   Unknown
 322 #     has additional entry in classification result
 323 #       Why => "prose"
 324
 325 sub parsecommit ($;$) {
 326     my ($objid, $p_ref) = @_;
 327     # => hash with                   CommitId Hdr Msg Tree Parents
 328     #    Parents entries have only   Ix CommitId
 329     #    $p_ref, if provided, must be [] and is used as a base for Parents
 330
 331     $p_ref //= [];
 332     die if @$p_ref;
 333
 334     my ($h,$m) = get_commit $objid;
 335
 336     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 337     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 338
 339     my $r = {
 340         CommitId => $objid,
 341         Hdr => $h,
 342         Msg => $m,
 343         Tree => $t,
 344         Parents => $p_ref,
 345     };
 346
 347     foreach my $ph (@ph) {
 348         push @$p_ref, {
 349             Ix => scalar @$p_ref,
 350             CommitId => $ph,
 351         };
 352     }
 353
 354     return $r;
 355 }
 356
 357 sub classify ($) {
 358     my ($objid) = @_;
 359
 360     my @p;
 361     my $r = parsecommit($objid, \@p);
 362     my $t = $r->{Tree};
 363
 364     foreach my $p (@p) {
 365         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 366     }
 367
 368     printdebug "classify $objid \$t=$t \@p",
 369         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 370         "\n";
 371
 372     my $classify = sub {
 373         my ($type, @rest) = @_;
 374         $r = { %$r, Type => $type, @rest };
 375         if ($debuglevel) {
 376             printdebug " = $type ".(dd $r)."\n";
 377         }
 378         return $r;
 379     };
 380     my $unknown = sub {
 381         my ($why) = @_;
 382         $r = { %$r, Type => qw(Unknown), Why => $why };
 383         printdebug " ** Unknown\n";
 384         return $r;
 385     };
 386
 387     if (grep { $_ eq $objid } @opt_anchors) {
 388         return $classify->('TreatAsAnchor');
 389     }
 390
 391     my @identical = grep { !$_->{Differs} } @p;
 392     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 393     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 394
 395     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 396         # multi-orig upstreams are represented with an anchor merge
 397         # from a single upstream commit which combines the orig tarballs
 398
 399         # Every anchor tagged this way must be a merge.
 400         # We are relying on the
 401         #     [git-debrebase anchor: ...]
 402         # commit message annotation in "declare" anchor merges (which
 403         # do not have any upstream changes), to distinguish those
 404         # anchor merges from ordinary pseudomerges (which we might
 405         # just try to strip).
 406         #
 407         # However, the user is going to be doing git-rebase a lot.  We
 408         # really don't want them to rewrite an anchor commit.
 409         # git-rebase trips up on merges, so that is a useful safety
 410         # catch.
 411         #
 412         # BreakwaterStart commits are also anchors in the terminology
 413         # of git-debrebase(5), but they are untagged (and always
 414         # manually generated).
 415         #
 416         # We cannot not tolerate any tagged linear commit (ie,
 417         # BreakwaterStart commits tagged `[anchor:') because such a
 418         # thing could result from an erroneous linearising raw git
 419         # rebase of a merge anchor.  That would represent a corruption
 420         # of the branch. and we want to detect and reject the results
 421         # of such corruption before it makes it out anywhere.  If we
 422         # reject it here then we avoid making the pseudomerge which
 423         # would be needed to push it.
 424
 425         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 426         @p == 2 or return $badanchor->("has other than two parents");
 427         $haspatches and return $badanchor->("contains debian/patches");
 428
 429         # How to decide about l/r ordering of anchors ?  git
 430         # --topo-order prefers to expand 2nd parent first.  There's
 431         # already an easy rune to look for debian/ history anyway (git log
 432         # debian/) so debian breakwater branch should be 1st parent; that
 433         # way also there's also an easy rune to look for the upstream
 434         # patches (--topo-order).
 435
 436         # Also this makes --first-parent be slightly more likely to
 437         # be useful - it makes it provide a linearised breakwater history.
 438
 439         # Of course one can say somthing like
 440         #  gitk -- ':/' ':!/debian'
 441         # to get _just_ the commits touching upstream files, and by
 442         # the TREESAME logic in git-rev-list this will leave the
 443         # breakwater into upstream at the first anchor.  But that
 444         # doesn't report debian/ changes at all.
 445
 446         # Other observations about gitk: by default, gitk seems to
 447         # produce output in a different order to git-rev-list.  I
 448         # can't seem to find this documented anywhere.  gitk
 449         # --date-order DTRT.  But, gitk always seems to put the
 450         # parents from left to right, in order, so it's easy to see
 451         # which way round a pseudomerge is.
 452
 453         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 454         $p[1]{Differs} & ~DS_DEB and
 455             $badanchor->("upstream files differ from left parent");
 456         $p[0]{Differs} & ~D_UPS and
 457             $badanchor->("debian/ differs from right parent");
 458
 459         return $classify->(qw(Anchor),
 460                            OrigParents => [ $p[1] ]);
 461     }
 462
 463     if (@p == 1) {
 464         my $d = $r->{Parents}[0]{Differs};
 465         if ($d == D_PAT_ADD) {
 466             return $classify->(qw(AddPatches));
 467         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 468             return $unknown->("edits debian/patches");
 469         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 470             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 471             if ($ty eq 'tree') {
 472                 if ($d == D_DEB_CLOG) {
 473                     return $classify->(qw(Changelog));
 474                 } else {
 475                     return $classify->(qw(Packaging));
 476                 }
 477             } elsif ($ty eq 'missing') {
 478                 return $classify->(qw(BreakwaterStart));
 479             } else {
 480                 return $unknown->("parent's debian is not a directory");
 481             }
 482         } elsif ($d == D_UPS) {
 483             return $classify->(qw(Upstream));
 484         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 485             return $classify->(qw(Mixed));
 486         } elsif ($d == 0) {
 487             return $unknown->("no changes");
 488         } else {
 489             confess "internal error $objid ?";
 490         }
 491     }
 492     if (!@p) {
 493         return $unknown->("origin commit");
 494     }
 495
 496     if (@p == 2 && @identical == 1) {
 497         my @overwritten = grep { $_->{Differs} } @p;
 498         confess "internal error $objid ?" unless @overwritten==1;
 499         return $classify->(qw(Pseudomerge),
 500                            Overwritten => [ $overwritten[0] ],
 501                            Contributor => $identical[0]);
 502     }
 503     if (@p == 2 && @identical == 2) {
 504         my $get_t = sub {
 505             my ($ph,$pm) = get_commit $_[0]{CommitId};
 506             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 507             $1;
 508         };
 509         my @bytime = @p;
 510         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 511         if ($order > 0) { # newer first
 512         } elsif ($order < 0) {
 513             @bytime = reverse @bytime;
 514         } else {
 515             # same age, default to order made by -s ours
 516             # that is, commit was made by someone who preferred L
 517         }
 518         return $classify->(qw(Pseudomerge),
 519                            SubType => qw(Ambiguous),
 520                            Contributor => $bytime[0],
 521                            Overwritten => [ $bytime[1] ]);
 522     }
 523     foreach my $p (@p) {
 524         my ($p_h, $p_m) = get_commit $p->{CommitId};
 525         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 526         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 527     }
 528     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 529     my $m2 = $r->{Msg};
 530     if (!(grep { !$_->{IsOrigin} } @p) and
 531         (@orig_ps >= @p - 1) and
 532         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 533         $r->{NewMsg} = $m2;
 534         return $classify->(qw(DgitImportUnpatched),
 535                            OrigParents => \@orig_ps);
 536     }
 537
 538     return $unknown->("complex merge");
 539 }
 540
 541 sub keycommits ($;$$$) {
 542     my ($head, $furniture, $unclean, $trouble) = @_;
 543     # => ($anchor, $breakwater)
 544
 545     # $unclean->("unclean-$tagsfx", $msg)
 546     # $furniture->("unclean-$tagsfx", $msg)
 547     # $dgitimport->("unclean-$tagsfx", $msg)
 548     #   is callled for each situation or commit that
 549     #   wouldn't be found in a laundered branch
 550     # $furniture is for furniture commits such as might be found on an
 551     #   interchange branch (pseudomerge, d/patches, changelog)
 552     # $trouble is for things whnich prevent the return of
 553     #   anchor and breakwater information; if that is ignored,
 554     #   then keycommits returns (undef, undef) instead.
 555     #
 556     # If a callback is undef, fail is called instead.
 557     # If a callback is defined but false, the situation is ignored.
 558     # Callbacks may say:
 559     #   no warnings qw(exiting); last;
 560     # if the answer is no longer wanted.
 561
 562     my ($anchor, $breakwater);
 563     my $clogonly;
 564     my $x = sub {
 565         my ($cb, $tagsfx, $why) = @_;
 566         my $m = "branch needs laundering (run git-debrebase): $why";
 567         fail $m unless defined $cb;
 568         return unless $cb;
 569         $cb->("unclean-$tagsfx", $why);
 570     };
 571     for (;;) {
 572         my $cl = classify $head;
 573         my $ty = $cl->{Type};
 574         if ($ty eq 'Packaging') {
 575             $breakwater //= $clogonly;
 576             $breakwater //= $head;
 577         } elsif ($ty eq 'Changelog') {
 578             # this is going to count as the tip of the breakwater
 579             # only if it has no upstream stuff before it
 580             $clogonly //= $head;
 581         } elsif ($ty eq 'Anchor' or
 582                  $ty eq 'TreatAsAnchor' or
 583                  $ty eq 'BreakwaterStart') {
 584             $anchor = $head;
 585             $breakwater //= $clogonly;
 586             $breakwater //= $head;
 587             last;
 588         } elsif ($ty eq 'Upstream') {
 589             $x->($unclean, 'ordering',
 590  "packaging change ($breakwater) follows upstream change (eg $head)")
 591                 if defined $breakwater;
 592             $clogonly = undef;
 593             $breakwater = undef;
 594         } elsif ($ty eq 'Mixed') {
 595             $x->($unclean, 'mixed',
 596                  "found mixed upstream/packaging commit ($head)");
 597             $clogonly = undef;
 598             $breakwater = undef;
 599         } elsif ($ty eq 'Pseudomerge' or
 600                  $ty eq 'AddPatches') {
 601             $x->($furniture, (lc $ty),
 602                  "found interchange bureaucracy commit ($ty, $head)");
 603         } elsif ($ty eq 'DgitImportUnpatched') {
 604             $x->($trouble, 'dgitimport',
 605                  "found dgit dsc import ($head)");
 606             $breakwater = undef;
 607             $anchor = undef;
 608             no warnings qw(exiting);
 609             last;
 610         } else {
 611             fail "found unprocessable commit, cannot cope: $head; $cl->{Why}";
 612         }
 613         $head = $cl->{Parents}[0]{CommitId};
 614     }
 615     return ($anchor, $breakwater);
 616 }
 617
 618 sub walk ($;$$);
 619 sub walk ($;$$) {
 620     my ($input,
 621         $nogenerate,$report) = @_;
 622     # => ($tip, $breakwater_tip, $last_anchor)
 623     # (or nothing, if $nogenerate)
 624
 625     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 626
 627     # go through commits backwards
 628     # we generate two lists of commits to apply:
 629     # breakwater branch and upstream patches
 630     my (@brw_cl, @upp_cl, @processed);
 631     my %found;
 632     my $upp_limit;
 633     my @pseudomerges;
 634
 635     my $cl;
 636     my $xmsg = sub {
 637         my ($prose, $info) = @_;
 638         my $ms = $cl->{Msg};
 639         chomp $ms;
 640         $info //= '';
 641         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 642         return (Msg => $ms);
 643     };
 644     my $rewrite_from_here = sub {
 645         my ($cl) = @_;
 646         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 647         push @$cl, $sp_cl;
 648         push @processed, $sp_cl;
 649     };
 650     my $cur = $input;
 651
 652     my $prdelim = "";
 653     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 654
 655     my $prline = sub {
 656         return unless $report;
 657         print $report $prdelim, @_;
 658         $prdelim = "\n";
 659     };
 660
 661     my $bomb = sub { # usage: return $bomb->();
 662         print $report " Unprocessable" if $report;
 663         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 664         $prprdelim->();
 665         if ($nogenerate) {
 666             return (undef,undef);
 667         }
 668         die "commit $cur: Cannot cope with this commit (d.".
 669             (join ' ', map { sprintf "%#x", $_->{Differs} }
 670              @{ $cl->{Parents} }).
 671             (defined $cl->{Why} ? "; $cl->{Why}": '').
 672                  ")";
 673     };
 674
 675     my $build;
 676     my $breakwater;
 677
 678     my $build_start = sub {
 679         my ($msg, $parent) = @_;
 680         $prline->(" $msg");
 681         $build = $parent;
 682         no warnings qw(exiting); last;
 683     };
 684
 685     my $last_anchor;
 686
 687     for (;;) {
 688         $cl = classify $cur;
 689         my $ty = $cl->{Type};
 690         my $st = $cl->{SubType};
 691         $prline->("$cl->{CommitId} $cl->{Type}");
 692         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 693         push @processed, $cl;
 694         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 695         if ($ty eq 'AddPatches') {
 696             $cur = $p0;
 697             $rewrite_from_here->(\@upp_cl);
 698             next;
 699         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 700             push @brw_cl, $cl;
 701             $cur = $p0;
 702             next;
 703         } elsif ($ty eq 'BreakwaterStart') {
 704             $last_anchor = $cur;
 705             $build_start->('FirstPackaging', $cur);
 706         } elsif ($ty eq 'Upstream') {
 707             push @upp_cl, $cl;
 708             $cur = $p0;
 709             next;
 710         } elsif ($ty eq 'Mixed') {
 711             my $queue = sub {
 712                 my ($q, $wh) = @_;
 713                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 714                 push @$q, $cls;
 715             };
 716             $queue->(\@brw_cl, "debian");
 717             $queue->(\@upp_cl, "upstream");
 718             $rewrite_from_here->(\@brw_cl);
 719             $cur = $p0;
 720             next;
 721         } elsif ($ty eq 'Pseudomerge') {
 722             my $contrib = $cl->{Contributor}{CommitId};
 723             print $report " Contributor=$contrib" if $report;
 724             push @pseudomerges, $cl;
 725             $rewrite_from_here->(\@upp_cl);
 726             $cur = $contrib;
 727             next;
 728         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
 729             $last_anchor = $cur;
 730             $build_start->("Anchor", $cur);
 731         } elsif ($ty eq 'DgitImportUnpatched') {
 732             my $pm = $pseudomerges[-1];
 733             if (defined $pm) {
 734                 # To an extent, this is heuristic.  Imports don't have
 735                 # a useful history of the debian/ branch.  We assume
 736                 # that the first pseudomerge after an import has a
 737                 # useful history of debian/, and ignore the histories
 738                 # from later pseudomerges.  Often the first pseudomerge
 739                 # will be the dgit import of the upload to the actual
 740                 # suite intended by the non-dgit NMUer, and later
 741                 # pseudomerges may represent in-archive copies.
 742                 my $ovwrs = $pm->{Overwritten};
 743                 printf $report " PM=%s \@Overwr:%d",
 744                     $pm->{CommitId}, (scalar @$ovwrs)
 745                     if $report;
 746                 if (@$ovwrs != 1) {
 747                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 748                     return $bomb->();
 749                 }
 750                 my $ovwr = $ovwrs->[0]{CommitId};
 751                 printf $report " Overwr=%s", $ovwr if $report;
 752                 # This import has a tree which is just like a
 753                 # breakwater tree, but it has the wrong history.  It
 754                 # ought to have the previous breakwater (which the
 755                 # pseudomerge overwrote) as an ancestor.  That will
 756                 # make the history of the debian/ files correct.  As
 757                 # for the upstream version: either it's the same as
 758                 # was ovewritten (ie, same as the previous
 759                 # breakwater), in which case that history is precisely
 760                 # right; or, otherwise, it was a non-gitish upload of a
 761                 # new upstream version.  We can tell these apart by
 762                 # looking at the tree of the supposed upstream.
 763                 push @brw_cl, {
 764                     %$cl,
 765                     SpecialMethod => 'DgitImportDebianUpdate',
 766                     $xmsg->("convert dgit import: debian changes")
 767                 }, {
 768                     %$cl,
 769                     SpecialMethod => 'DgitImportUpstreamUpdate',
 770                     $xmsg->("convert dgit import: upstream update",
 771                             " anchor")
 772                 };
 773                 $prline->(" Import");
 774                 $rewrite_from_here->(\@brw_cl);
 775                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 776                 $cur = $ovwr;
 777                 next;
 778             } else {
 779                 # Everything is from this import.  This kind of import
 780                 # is already in valid breakwater format, with the
 781                 # patches as commits.
 782                 printf $report " NoPM" if $report;
 783                 # last thing we processed will have been the first patch,
 784                 # if there is one; which is fine, so no need to rewrite
 785                 # on account of this import
 786                 $build_start->("ImportOrigin", $cur);
 787             }
 788             die "$ty ?";
 789         } else {
 790             printdebug "*** WALK BOMB unrecognised\n";
 791             return $bomb->();
 792         }
 793     }
 794     $prprdelim->();
 795
 796     printdebug "*** WALK prep done cur=$cur".
 797         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 798
 799     return if $nogenerate;
 800
 801     # Now we build it back up again
 802
 803     fresh_workarea();
 804
 805     my $rewriting = 0;
 806
 807     my $read_tree_debian = sub {
 808         my ($treeish) = @_;
 809         read_tree_subdir 'debian', "$treeish:debian";
 810         rm_subdir_cached 'debian/patches';
 811     };
 812     my $read_tree_upstream = sub {
 813         my ($treeish) = @_;
 814         runcmd @git, qw(read-tree), $treeish;
 815         $read_tree_debian->($build);
 816     };
 817
 818     $#upp_cl = $upp_limit if defined $upp_limit;
 819
 820     my $committer_authline = calculate_committer_authline();
 821
 822     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 823
 824     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 825
 826     in_workarea sub {
 827         mkdir $rd or $!==EEXIST or die $!;
 828         my $current_method;
 829         runcmd @git, qw(read-tree), $build;
 830         foreach my $cl (qw(Debian), (reverse @brw_cl),
 831                         { SpecialMethod => 'RecordBreakwaterTip' },
 832                         qw(Upstream), (reverse @upp_cl)) {
 833             if (!ref $cl) {
 834                 $current_method = $cl;
 835                 next;
 836             }
 837             my $method = $cl->{SpecialMethod} // $current_method;
 838             my @parents = ($build);
 839             my $cltree = $cl->{CommitId};
 840             printdebug "WALK BUILD ".($cltree//'undef').
 841                 " $method (rewriting=$rewriting)\n";
 842             if ($method eq 'Debian') {
 843                 $read_tree_debian->($cltree);
 844             } elsif ($method eq 'Upstream') {
 845                 $read_tree_upstream->($cltree);
 846             } elsif ($method eq 'StartRewrite') {
 847                 $rewriting = 1;
 848                 next;
 849             } elsif ($method eq 'RecordBreakwaterTip') {
 850                 $breakwater = $build;
 851                 next;
 852             } elsif ($method eq 'DgitImportDebianUpdate') {
 853                 $read_tree_debian->($cltree);
 854             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 855                 confess unless $rewriting;
 856                 my $differs = (get_differs $build, $cltree);
 857                 next unless $differs & D_UPS;
 858                 $read_tree_upstream->($cltree);
 859                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 860             } else {
 861                 confess "$method ?";
 862             }
 863             if (!$rewriting) {
 864                 my $procd = (pop @processed) // 'UNDEF';
 865                 if ($cl ne $procd) {
 866                     $rewriting = 1;
 867                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 868                 }
 869             }
 870             my $newtree = cmdoutput @git, qw(write-tree);
 871             my $ch = $cl->{Hdr};
 872             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 873             $ch =~ s{^parent .*\n}{}mg;
 874             $ch =~ s{(?=^author)}{
 875                 join '', map { "parent $_\n" } @parents
 876             }me or confess "$ch ?";
 877             if ($rewriting) {
 878                 $ch =~ s{^committer .*$}{$committer_authline}m
 879                     or confess "$ch ?";
 880             }
 881             my $cf = "$rd/m$rewriting";
 882             open CD, ">", $cf or die $!;
 883             print CD $ch, "\n", $cl->{Msg} or die $!;
 884             close CD or die $!;
 885             my @cmd = (@git, qw(hash-object));
 886             push @cmd, qw(-w) if $rewriting;
 887             push @cmd, qw(-t commit), $cf;
 888             my $newcommit = cmdoutput @cmd;
 889             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 890             $build = $newcommit;
 891             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 892                 $last_anchor = $cur;
 893             }
 894         }
 895     };
 896
 897     my $final_check = get_differs $build, $input;
 898     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 899         if $final_check & ~D_PAT_ADD;
 900
 901     my @r = ($build, $breakwater, $last_anchor);
 902     printdebug "*** WALK RETURN @r\n";
 903     return @r
 904 }
 905
 906 sub get_head () {
 907     git_check_unmodified();
 908     return git_rev_parse qw(HEAD);
 909 }
 910
 911 sub update_head ($$$) {
 912     my ($old, $new, $mrest) = @_;
 913     push @deferred_updates, "update HEAD $new $old";
 914     run_deferred_updates $mrest;
 915 }
 916
 917 sub update_head_checkout ($$$) {
 918     my ($old, $new, $mrest) = @_;
 919     update_head $old, $new, $mrest;
 920     runcmd @git, qw(reset --hard);
 921 }
 922
 923 sub update_head_postlaunder ($$$) {
 924     my ($old, $tip, $reflogmsg) = @_;
 925     return if $tip eq $old;
 926     print "git-debrebase: laundered (head was $old)\n";
 927     update_head $old, $tip, $reflogmsg;
 928     # no tree changes except debian/patches
 929     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 930 }
 931
 932 sub do_launder_head ($) {
 933     my ($reflogmsg) = @_;
 934     my $old = get_head();
 935     record_ffq_auto();
 936     my ($tip,$breakwater) = walk $old;
 937     snags_maybe_bail();
 938     update_head_postlaunder $old, $tip, $reflogmsg;
 939     return ($tip,$breakwater);
 940 }
 941
 942 sub cmd_launder_v0 () {
 943     badusage "no arguments to launder-v0 allowed" if @ARGV;
 944     my $old = get_head();
 945     my ($tip,$breakwater,$last_anchor) = walk $old;
 946     update_head_postlaunder $old, $tip, 'launder';
 947     printf "# breakwater tip\n%s\n", $breakwater;
 948     printf "# working tip\n%s\n", $tip;
 949     printf "# last anchor\n%s\n", $last_anchor;
 950 }
 951
 952 sub defaultcmd_rebase () {
 953     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
 954     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
 955     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
 956 }
 957
 958 sub cmd_analyse () {
 959     die if ($ARGV[0]//'') =~ m/^-/;
 960     badusage "too many arguments to analyse" if @ARGV>1;
 961     my ($old) = @ARGV;
 962     if (defined $old) {
 963         $old = git_rev_parse $old;
 964     } else {
 965         $old = git_rev_parse 'HEAD';
 966     }
 967     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 968     STDOUT->error and die $!;
 969 }
 970
 971 sub ffq_prev_branchinfo () {
 972     # => ('status', "message", [$current, $ffq_prev, $gdrlast])
 973     # 'status' may be
 974     #    branch         message is undef
 975     #    weird-symref   } no $current,
 976     #    notbranch      }  no $ffq_prev
 977     my $current = git_get_symref();
 978     return ('detached', 'detached HEAD') unless defined $current;
 979     return ('weird-symref', 'HEAD symref is not to refs/')
 980         unless $current =~ m{^refs/};
 981     my $ffq_prev = "refs/$ffq_refprefix/$'";
 982     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 983     printdebug "ffq_prev_branchinfo branch current $current\n";
 984     return ('branch', undef, $current, $ffq_prev, $gdrlast);
 985 }
 986
 987 sub record_ffq_prev_deferred () {
 988     # => ('status', "message")
 989     # 'status' may be
 990     #    deferred          message is undef
 991     #    exists
 992     #    detached
 993     #    weird-symref
 994     #    notbranch
 995     # if not ff from some branch we should be ff from, is an snag
 996     # if "deferred", will have added something about that to
 997     #   @deferred_update_messages, and also maybe printed (already)
 998     #   some messages about ff checks
 999     my ($status, $message, $current, $ffq_prev, $gdrlast)
1000         = ffq_prev_branchinfo();
1001     return ($status, $message) unless $status eq 'branch';
1002
1003     my $currentval = get_head();
1004
1005     my $exists = git_get_ref $ffq_prev;
1006     return ('exists',"$ffq_prev already exists") if $exists;
1007
1008     return ('not-branch', 'HEAD symref is not to refs/heads/')
1009         unless $current =~ m{^refs/heads/};
1010     my $branch = $';
1011
1012     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1013     my %checked;
1014
1015     printdebug "ffq check_specs @check_specs\n";
1016
1017     my $check = sub {
1018         my ($lrref, $desc) = @_;
1019         printdebug "ffq might check $lrref ($desc)\n";
1020         my $invert;
1021         for my $chk (@check_specs) {
1022             my $glob = $chk;
1023             $invert = $glob =~ s{^[!^]}{};
1024             last if fnmatch $glob, $lrref;
1025         }
1026         return if $invert;
1027         my $lrval = git_get_ref $lrref;
1028         return unless defined $lrval;
1029
1030         if (is_fast_fwd $lrval, $currentval) {
1031             print "OK, you are ahead of $lrref\n" or die $!;
1032             $checked{$lrref} = 1;
1033         } elsif (is_fast_fwd $currentval, $lrval) {
1034             $checked{$lrref} = -1;
1035             snag 'behind', "you are behind $lrref, divergence risk";
1036         } else {
1037             $checked{$lrref} = -1;
1038             snag 'diverged', "you have diverged from $lrref";
1039         }
1040     };
1041
1042     my $merge = cfg "branch.$branch.merge",1;
1043     if (defined $merge and $merge =~ m{^refs/heads/}) {
1044         my $rhs = $';
1045         printdebug "ffq merge $rhs\n";
1046         my $check_remote = sub {
1047             my ($remote, $desc) = @_;
1048             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1049             return unless defined $remote;
1050             $check->("refs/remotes/$remote/$rhs", $desc);
1051         };
1052         $check_remote->((scalar cfg "branch.$branch.remote",1),
1053                         'remote fetch/merge branch');
1054         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1055                         (scalar cfg "branch.$branch.pushDefault",1),
1056                         'remote push branch');
1057     }
1058     if ($branch =~ m{^dgit/}) {
1059         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1060     } elsif ($branch =~ m{^master$}) {
1061         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1062     }
1063
1064     snags_maybe_bail();
1065
1066     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1067     push @deferred_updates, "delete $gdrlast";
1068     push @deferred_update_messages, "Recorded current head for preservation";
1069     return ('deferred', undef);
1070 }
1071
1072 sub record_ffq_auto () {
1073     my ($status, $message) = record_ffq_prev_deferred();
1074     if ($status eq 'deferred' || $status eq 'exists') {
1075     } else {
1076         snag $status, "could not record ffq-prev: $message";
1077         snags_maybe_bail();
1078     }
1079 }
1080
1081 sub ffq_prev_info () {
1082     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1083     my ($status, $message, $current, $ffq_prev, $gdrlast)
1084         = ffq_prev_branchinfo();
1085     if ($status ne 'branch') {
1086         snag $status, "could not check ffq-prev: $message";
1087         snags_maybe_bail();
1088     }
1089     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1090     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1091 }
1092
1093 sub stitch ($$$$$) {
1094     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1095
1096     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1097
1098     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1099         my $differs = get_differs $old_head, $ffq_prev_commitish;
1100         unless ($differs & ~D_PAT_ADD) {
1101             # ffq-prev is ahead of us, and the only tree changes it has
1102             # are possibly addition of things in debian/patches/.
1103             # Just wind forwards rather than making a pointless pseudomerge.
1104             push @deferred_updates,
1105                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1106             update_head_checkout $old_head, $ffq_prev_commitish,
1107                 "stitch (fast forward)";
1108             return;
1109         }
1110     }
1111     fresh_workarea();
1112     # We make pseudomerges with L as the contributing parent.
1113     # This makes git rev-list --first-parent work properly.
1114     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1115         'Declare fast forward / record previous work',
1116         "[git-debrebase pseudomerge: $prose]",
1117     ];
1118     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1119     update_head $old_head, $new_head, "stitch: $prose";
1120 }
1121
1122 sub do_stitch ($;$) {
1123     my ($prose, $unclean) = @_;
1124
1125     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1126     if (!$ffq_prev_commitish) {
1127         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1128         return;
1129     }
1130     my $dangling_head = get_head();
1131
1132     keycommits $dangling_head, $unclean,$unclean,$unclean;
1133     snags_maybe_bail();
1134
1135     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1136 }
1137
1138 sub cmd_new_upstream_v0 () {
1139     # automatically and unconditionally launders before rebasing
1140     # if rebase --abort is used, laundering has still been done
1141
1142     my %pieces;
1143
1144     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1145
1146     # parse args - low commitment
1147     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
1148     my $new_upstream_version = $new_version->version();
1149
1150     my $new_upstream = git_rev_parse (shift @ARGV // 'upstream');
1151
1152     record_ffq_auto();
1153
1154     my $piece = sub {
1155         my ($n, @x) = @_; # may be ''
1156         my $pc = $pieces{$n} //= {
1157             Name => $n,
1158             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1159         };
1160         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1161         $pc;
1162     };
1163
1164     my @newpieces;
1165     my $newpiece = sub {
1166         my ($n, @x) = @_; # may be ''
1167         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1168         push @newpieces, $pc;
1169     };
1170
1171     $newpiece->('',
1172         OldIx => 0,
1173         New => $new_upstream,
1174     );
1175     while (@ARGV && $ARGV[0] !~ m{^-}) {
1176         my $n = shift @ARGV;
1177
1178         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1179             unless @ARGV && $ARGV[0] !~ m{^-};
1180
1181         my $c = git_rev_parse shift @ARGV;
1182         die unless $n =~ m/^$extra_orig_namepart_re$/;
1183         $newpiece->($n, New => $c);
1184     }
1185
1186     # now we need to investigate the branch this generates the
1187     # laundered version but we don't switch to it yet
1188     my $old_head = get_head();
1189     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1190
1191     my $old_bw_cl = classify $old_bw;
1192     my $old_anchor_cl = classify $old_anchor;
1193     my $old_upstream;
1194     if (!$old_anchor_cl->{OrigParents}) {
1195         snag 'anchor-treated',
1196             'old anchor is recognised due to --anchor, cannot check upstream';
1197     } else {
1198         $old_upstream = parsecommit
1199             $old_anchor_cl->{OrigParents}[0]{CommitId};
1200         $piece->('', Old => $old_upstream->{CommitId});
1201     }
1202
1203     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1204         if ($old_upstream->{Msg} =~
1205  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
1206            ) {
1207             my @oldpieces = ('', split / /, $1);
1208             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
1209             foreach my $i (0..$#oldpieces) {
1210                 my $n = $oldpieces[$i];
1211                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
1212             }
1213         } else {
1214             snag 'upstream-confusing',
1215                 "previous upstream $old_upstream->{CommitId} is from".
1216                " git-debrebase but not an \`upstream-combine' commit";
1217         }
1218     }
1219
1220     foreach my $pc (values %pieces) {
1221         if (!$old_upstream) {
1222             # we have complained already
1223         } elsif (!$pc->{Old}) {
1224             snag 'upstream-new-piece',
1225                 "introducing upstream piece \`$pc->{Name}'";
1226         } elsif (!$pc->{New}) {
1227             snag 'upstream-rm-piece',
1228                 "dropping upstream piece \`$pc->{Name}'";
1229         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1230             snag 'upstream-not-ff',
1231                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1232         }
1233     }
1234
1235     printdebug "%pieces = ", (dd \%pieces), "\n";
1236     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1237
1238     snags_maybe_bail();
1239
1240     my $new_bw;
1241
1242     fresh_workarea();
1243     in_workarea sub {
1244         my @upstream_merge_parents;
1245
1246         if (!any_snags()) {
1247             push @upstream_merge_parents, $old_upstream->{CommitId};
1248         }
1249
1250         foreach my $pc (@newpieces) { # always has '' first
1251             if ($pc->{Name}) {
1252                 read_tree_subdir $pc->{Name}, $pc->{New};
1253             } else {
1254                 runcmd @git, qw(read-tree), $pc->{New};
1255             }
1256             push @upstream_merge_parents, $pc->{New};
1257         }
1258
1259         # index now contains the new upstream
1260
1261         if (@newpieces > 1) {
1262             # need to make the upstream subtree merge commit
1263             $new_upstream = make_commit \@upstream_merge_parents,
1264                 [ "Combine upstreams for $new_upstream_version",
1265  ("[git-debrebase upstream-combine . ".
1266  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1267  ": new upstream]"),
1268                 ];
1269         }
1270
1271         # $new_upstream is either the single upstream commit, or the
1272         # combined commit we just made.  Either way it will be the
1273         # "upstream" parent of the anchor merge.
1274
1275         read_tree_subdir 'debian', "$old_bw:debian";
1276
1277         # index now contains the anchor merge contents
1278         $new_bw = make_commit [ $old_bw, $new_upstream ],
1279             [ "Update to upstream $new_upstream_version",
1280  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1281             ];
1282
1283         my $clogsignoff = cmdoutput qw(git show),
1284             '--pretty=format:%an <%ae>  %aD',
1285             $new_bw;
1286
1287         # Now we have to add a changelog stanza so the Debian version
1288         # is right.
1289         die if unlink "debian";
1290         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1291         unlink "debian/changelog" or $!==ENOENT or die $!;
1292         mkdir "debian" or die $!;
1293         open CN, ">", "debian/changelog" or die $!;
1294         my $oldclog = git_cat_file ":debian/changelog";
1295         $oldclog =~ m/^($package_re) \(\S+\) / or
1296             fail "cannot parse old changelog to get package name";
1297         my $p = $1;
1298         print CN <<END, $oldclog or die $!;
1299 $p ($new_version) UNRELEASED; urgency=medium
1300
1301   * Update to new upstream version $new_upstream_version.
1302
1303  -- $clogsignoff
1304
1305 END
1306         close CN or die $!;
1307         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1308
1309         # Now we have the final new breakwater branch in the index
1310         $new_bw = make_commit [ $new_bw ],
1311             [ "Update changelog for new upstream $new_upstream_version",
1312               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1313             ];
1314     };
1315
1316     # we have constructed the new breakwater. we now need to commit to
1317     # the laundering output, because git-rebase can't easily be made
1318     # to make a replay list which is based on some other branch
1319
1320     update_head_postlaunder $old_head, $old_laundered_tip,
1321         'launder for new upstream';
1322
1323     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1324     runcmd @cmd;
1325     # now it's for the user to sort out
1326 }
1327
1328 sub cmd_record_ffq_prev () {
1329     badusage "no arguments allowed" if @ARGV;
1330     my ($status, $msg) = record_ffq_prev_deferred();
1331     if ($status eq 'exists' && $opt_noop_ok) {
1332         print "Previous head already recorded\n" or die $!;
1333     } elsif ($status eq 'deferred') {
1334         run_deferred_updates 'record-ffq-prev';
1335     } else {
1336         fail "Could not preserve: $msg";
1337     }
1338 }
1339
1340 sub cmd_anchor () {
1341     badusage "no arguments allowed" if @ARGV;
1342     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1343     print "$bw\n" or die $!;
1344 }
1345
1346 sub cmd_breakwater () {
1347     badusage "no arguments allowed" if @ARGV;
1348     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1349     print "$bw\n" or die $!;
1350 }
1351
1352 sub cmd_stitch () {
1353     my $prose = 'stitch';
1354     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1355     badusage "no arguments allowed" if @ARGV;
1356     do_stitch $prose, 0;
1357 }
1358 sub cmd_prepush () { cmd_stitch(); }
1359
1360 sub cmd_quick () {
1361     badusage "no arguments allowed" if @ARGV;
1362     do_launder_head 'launder for git-debrebase quick';
1363     do_stitch 'quick';
1364 }
1365
1366 sub cmd_conclude () {
1367     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1368     if (!$ffq_prev_commitish) {
1369         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1370         return;
1371     }
1372     my $dangling_head = get_head();
1373
1374     badusage "no arguments allowed" if @ARGV;
1375     do_launder_head 'launder for git-debrebase quick';
1376     do_stitch 'quick';
1377 }
1378
1379 sub make_patches_staged ($) {
1380     my ($head) = @_;
1381     # Produces the patches that would result from $head if it were
1382     # laundered.
1383     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
1384     fresh_workarea();
1385     in_workarea sub {
1386         runcmd @git, qw(checkout -q -b bw), $secret_bw;
1387         runcmd @git, qw(checkout -q -b patch-queue/bw), $secret_head;
1388         runcmd qw(gbp pq export);
1389         runcmd @git, qw(add debian/patches);
1390     };
1391 }
1392
1393 sub make_patches ($) {
1394     my ($head) = @_;
1395     keycommits $head, 0, \&snag;
1396     make_patches_staged $head;
1397     my $out;
1398     in_workarea sub {
1399         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
1400         runcmd @git, qw(read-tree), $head;
1401         read_tree_subdir 'debian/patches', $ptree;
1402         $out = make_commit [$head], [
1403             'Commit patch queue (exported by git-debrebase)',
1404             '[git-debrebase: export and commit patches]',
1405         ];
1406     };
1407     my $d = get_differs $head, $out;
1408     if ($d == 0) {
1409         return undef; # nothing to do
1410     } elsif ($d == D_PAT_ADD) {
1411         return $out; # OK
1412     } else {
1413         fail "Patch export produced patch amendments".
1414             " (abandoned output commit $out).".
1415             "  Try laundering first.";
1416     }
1417 }
1418
1419 sub cmd_make_patches () {
1420     badusage "no arguments allowed" if @ARGV;
1421     my $old_head = get_head();
1422     my $new = make_patches $old_head;
1423     snags_maybe_bail();
1424     if (!$new) {
1425         fail "No (more) patches to export." unless $opt_noop_ok;
1426         return;
1427     }
1428     update_head_checkout $old_head, $new, 'make-patches';
1429 }
1430
1431 sub cmd_convert_from_gbp () {
1432     badusage "needs 1 optional argument, the upstream git rev"
1433         unless @ARGV<=1;
1434     my ($upstream_spec) = @ARGV;
1435     $upstream_spec //= 'refs/heads/upstream';
1436     my $upstream = git_rev_parse $upstream_spec;
1437     my $old_head = get_head();
1438
1439     my $upsdiff = get_differs $upstream, $old_head;
1440     if ($upsdiff & D_UPS) {
1441         runcmd @git, qw(--no-pager diff),
1442             $upstream, $old_head,
1443             qw( -- :!/debian :/);
1444  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1445     }
1446
1447     if (!is_fast_fwd $upstream, $old_head) {
1448         snag 'upstream-not-ancestor',
1449             "upstream ($upstream) is not an ancestor of HEAD";
1450     } else {
1451         my $wrong = cmdoutput
1452             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1453              qw(-- :/ :!/debian));
1454         if (length $wrong) {
1455             snag 'unexpected-upstream-changes',
1456                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1457             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1458         }
1459     }
1460
1461     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1462         snag 'upstream-has-debian',
1463             "upstream ($upstream) contains debian/ directory";
1464     }
1465
1466     snags_maybe_bail();
1467
1468     my $work;
1469
1470     fresh_workarea();
1471     in_workarea sub {
1472         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1473         # make a branch out of the patch queue - we'll want this in a mo
1474         runcmd qw(gbp pq import);
1475         # strip the patches out
1476         runcmd @git, qw(checkout -q gdr-internal~0);
1477         rm_subdir_cached 'debian/patches';
1478         $work = make_commit ['HEAD'], [
1479  'git-debrebase convert-from-gbp: drop patches from tree',
1480  'Delete debian/patches, as part of converting to git-debrebase format.',
1481  '[git-debrebase convert-from-gbp: drop patches from tree]'
1482                               ];
1483         # make the anchor merge
1484         # the tree is already exactly right
1485         $work = make_commit [$work, $upstream], [
1486  'git-debrebase import: declare upstream',
1487  'First breakwater merge.',
1488  '[git-debrebase anchor: declare upstream]'
1489                               ];
1490
1491         # rebase the patch queue onto the new breakwater
1492         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1493         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1494         $work = git_rev_parse 'HEAD';
1495     };
1496
1497     update_head_checkout $old_head, $work, 'convert-from-gbp';
1498 }
1499
1500 sub cmd_convert_to_gbp () {
1501     badusage "no arguments allowed" if @ARGV;
1502     my $head = get_head();
1503     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
1504     keycommits $head, 0;
1505     my $out;
1506     make_patches_staged $head;
1507     in_workarea sub {
1508         $out = make_commit ['HEAD'], [
1509             'Commit patch queue (converted from git-debrebase format)',
1510             '[git-debrebase convert-to-gbp: commit patches]',
1511         ];
1512     };
1513     if (defined $ffq) {
1514         push @deferred_updates, "delete $ffq";
1515         push @deferred_updates, "delete $gdrlast";
1516     }
1517     snags_maybe_bail();
1518     update_head_checkout $head, $out, "convert to gbp (v0)";
1519     print <<END or die $!;
1520 git-debrebase: converted to git-buildpackage branch format
1521 git-debrebase: WARNING: do not now run "git-debrebase" any more
1522 git-debrebase: WARNING: doing so would drop all upstream patches!
1523 END
1524 }
1525
1526 sub cmd_downstream_rebase_launder_v0 () {
1527     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1528     my ($base) = @ARGV;
1529     $base = git_rev_parse $base;
1530     my $old_head = get_head();
1531     my $current = $old_head;
1532     my $topmost_keep;
1533     for (;;) {
1534         if ($current eq $base) {
1535             $topmost_keep //= $current;
1536             print " $current BASE stop\n";
1537             last;
1538         }
1539         my $cl = classify $current;
1540         print " $current $cl->{Type}";
1541         my $keep = 0;
1542         my $p0 = $cl->{Parents}[0]{CommitId};
1543         my $next;
1544         if ($cl->{Type} eq 'Pseudomerge') {
1545             print " ^".($cl->{Contributor}{Ix}+1);
1546             $next = $cl->{Contributor}{CommitId};
1547         } elsif ($cl->{Type} eq 'AddPatches' or
1548                  $cl->{Type} eq 'Changelog') {
1549             print " strip";
1550             $next = $p0;
1551         } else {
1552             print " keep";
1553             $next = $p0;
1554             $keep = 1;
1555         }
1556         print "\n";
1557         if ($keep) {
1558             $topmost_keep //= $current;
1559         } else {
1560             die "to-be stripped changes not on top of the branch\n"
1561                 if $topmost_keep;
1562         }
1563         $current = $next;
1564     }
1565     if ($topmost_keep eq $old_head) {
1566         print "unchanged\n";
1567     } else {
1568         print "updating to $topmost_keep\n";
1569         update_head_checkout
1570             $old_head, $topmost_keep,
1571             'downstream-rebase-launder-v0';
1572     }
1573 }
1574
1575 GetOptions("D+" => \$debuglevel,
1576            'noop-ok', => \$opt_noop_ok,
1577            'f=s' => \@snag_force_opts,
1578            'anchor=s' => \@opt_anchors,
1579            'force!',
1580            '-i:s' => sub {
1581                my ($opt,$val) = @_;
1582                badusage "git-debrebase: no cuddling to -i for git-rebase"
1583                    if length $val;
1584                die if $opt_defaultcmd_interactive; # should not happen
1585                $opt_defaultcmd_interactive = [ qw(-i) ];
1586                # This access to @ARGV is excessive familiarity with
1587                # Getopt::Long, but there isn't another sensible
1588                # approach.  '-i=s{0,}' does not work with bundling.
1589                push @$opt_defaultcmd_interactive, @ARGV;
1590                @ARGV=();
1591            }) or die badusage "bad options\n";
1592 initdebug('git-debrebase ');
1593 enabledebug if $debuglevel;
1594
1595 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1596 chdir $toplevel or die "chdir $toplevel: $!";
1597
1598 $rd = fresh_playground "$playprefix/misc";
1599
1600 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
1601
1602 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
1603     defaultcmd_rebase();
1604 } else {
1605     my $cmd = shift @ARGV;
1606     my $cmdfn = $cmd;
1607     $cmdfn =~ y/-/_/;
1608     $cmdfn = ${*::}{"cmd_$cmdfn"};
1609
1610     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1611     $cmdfn->();
1612 }
1613
1614 finish 0;