git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # usages:
  23 #
  24 #    git-debrebase [<options>] new-upstream-v0 \
  25 #             <new-version> [<orig-commitish> \
  26 #            [<extra-orig-name> <extra-orig-commitish> ...] \
  27 #            [<git-rebase options>...]]
  28 #
  29 #    git-debrebase [<options> --] [<git-rebase options...>]
  30 #    git-debrebase [<options>] analyse
  31 #    git-debrebase [<options>] breakwater      # prints breakwater tip only
  32 #    git-debrebase [<options>] stitch [--prose=<for commit message>]
  33 #    git-debrebase [<options>] launder-v0      # prints breakwater tip etc.
  34 #    git-debrebase [<options>] downstream-rebase-launder-v0  # experimental
  35 #
  36 #    git-debrebase [<options>] convert-from-gbp [<upstream-git-rev>]
  37 #    git-debrebase [<options>] convert-to-gbp
  38
  39 # problems / outstanding questions:
  40 #
  41 #  *  dgit push with a `3.0 (quilt)' package means doing quilt
  42 #     fixup.  Usually this involves recommitting the whole patch
  43 #     series, one at a time, with dpkg-source --commit.  This is
  44 #     terribly terribly slow.  (Maybe this should be fixed in dgit.)
  45 #
  46 #  * dgit push usually needs to (re)make a pseudomerge.  The "first"
  47 #    git-debrebase stripped out the previous pseudomerge and could
  48 #    have remembeed the HEAD.  But it's not quite clear what history
  49 #    ought to be preserved and what should be discarded.  For now
  50 #    the user will have to tell dgit --overwrite.
  51 #
  52 #    To fix this, do we need a new push hook for dgit ?
  53 #
  54 #  * Workflow is currently clumsy.  Lots of spurious runes to type.
  55 #    There's not even a guide.
  56 #
  57 #  * There are no tests.
  58 #
  59 #  * new-upstream-v0 has a terrible UI.  You end up with giant
  60 #    runic command lines.
  61 #
  62 #    One consequence of the lack of richness it can need --force in
  63 #    fairly sensible situations and there is no way to tell it what
  64 #    you are really trying to do, other than just --force.  There
  65 #    should be an interface with some default branch names.
  66 #
  67 #  * There should be a standard convention for the version number,
  68 #    and unfinalised or not changelog, after new-upstream.
  69 #
  70 #  * Handing of multi-orig dgit new-upstream .dsc imports is known to
  71 #    be broken.  They may be not recognised, improperly converted, or
  72 #    their conversion may be unrecognised.
  73 #
  74 #  * Docs need writing and updating.  Even README.git-debrebase
  75 #    describes a design but may not reflect the implementation.
  76 #
  77 #  * We need to develop a plausible model that works for derivatives,
  78 #    who probably want to maintain their stack on top of Debian's.
  79 #    downstream-rebase-launder-v0 may be a starting point?
  80
  81 use strict;
  82
  83 use Debian::Dgit qw(:DEFAULT :playground);
  84 setup_sigwarn();
  85
  86 use Memoize;
  87 use Carp;
  88 use POSIX;
  89 use Data::Dumper;
  90 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  91 use Dpkg::Version;
  92 use File::FnMatch qw(:fnmatch);
  93
  94 our ($opt_force, $opt_noop_ok, @opt_anchors);
  95
  96 our $us = qw(git-debrebase);
  97
  98 sub badusage ($) {
  99     my ($m) = @_;
 100     die "bad usage: $m\n";
 101 }
 102
 103 sub cfg ($;$) {
 104     my ($k, $optional) = @_;
 105     local $/ = "\0";
 106     my @cmd = qw(git config -z);
 107     push @cmd, qw(--get-all) if wantarray;
 108     push @cmd, $k;
 109     my $out = cmdoutput_errok @cmd;
 110     if (!defined $out) {
 111         fail "missing required git config $k" unless $optional;
 112         return ();
 113     }
 114     my @l = split /\0/, $out;
 115     return wantarray ? @l : $l[0];
 116 }
 117
 118 memoize('cfg');
 119
 120 sub dd ($) {
 121     my ($v) = @_;
 122     my $dd = new Data::Dumper [ $v ];
 123     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 124     return Dump $dd;
 125 }
 126
 127 sub get_commit ($) {
 128     my ($objid) = @_;
 129     my $data = (git_cat_file $objid, 'commit');
 130     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 131     return ($`,$');
 132 }
 133
 134 sub D_UPS ()      { 0x02; } # upstream files
 135 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 136 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 137 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 138 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 139 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 140
 141 our $playprefix = 'debrebase';
 142 our $rd;
 143 our $workarea;
 144
 145 our @git = qw(git);
 146
 147 sub in_workarea ($) {
 148     my ($sub) = @_;
 149     changedir $workarea;
 150     my $r = eval { $sub->(); };
 151     { local $@; changedir $maindir; }
 152     die $@ if $@;
 153 }
 154
 155 sub fresh_workarea () {
 156     $workarea = fresh_playground "$playprefix/work";
 157     in_workarea sub { playtree_setup };
 158 }
 159
 160 our @deferred_updates;
 161 our @deferred_update_messages;
 162
 163 sub run_deferred_updates ($) {
 164     my ($mrest) = @_;
 165
 166     my @upd_cmd = (@git, qw(update-ref --stdin -m), "debrebase: $mrest");
 167     debugcmd '>|', @upd_cmd;
 168     open U, "|-", @upd_cmd or die $!;
 169     foreach (@deferred_updates) {
 170         printdebug ">= ", $_, "\n";
 171         print U $_, "\n" or die $!;
 172     }
 173     printdebug ">\$\n";
 174     close U or failedcmd @upd_cmd;
 175
 176     print $_, "\n" foreach @deferred_update_messages;
 177
 178     @deferred_updates = ();
 179     @deferred_update_messages = ();
 180 }
 181
 182 sub get_differs ($$) {
 183     my ($x,$y) = @_;
 184     # This resembles quiltify_trees_differ, in dgit, a bit.
 185     # But we don't care about modes, or dpkg-source-unrepresentable
 186     # changes, and we don't need the plethora of different modes.
 187     # Conversely we need to distinguish different kinds of changes to
 188     # debian/ and debian/patches/.
 189
 190     my $differs = 0;
 191
 192     my $rundiff = sub {
 193         my ($opts, $limits, $fn) = @_;
 194         my @cmd = (@git, qw(diff-tree -z --no-renames));
 195         push @cmd, @$opts;
 196         push @cmd, "$_:" foreach $x, $y;
 197         push @cmd, '--', @$limits;
 198         my $diffs = cmdoutput @cmd;
 199         foreach (split /\0/, $diffs) { $fn->(); }
 200     };
 201
 202     $rundiff->([qw(--name-only)], [], sub {
 203         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 204     });
 205
 206     if ($differs & DS_DEB) {
 207         $differs &= ~DS_DEB;
 208         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 209             $differs |=
 210                 m{^debian/patches/}      ? D_PAT_OTH  :
 211                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 212                                            D_DEB_OTH;
 213         });
 214         die "mysterious debian changes $x..$y"
 215             unless $differs & (D_PAT_OTH|DS_DEB);
 216     }
 217
 218     if ($differs & D_PAT_OTH) {
 219         my $mode;
 220         $differs &= ~D_PAT_OTH;
 221         my $pat_oth = sub {
 222             $differs |= D_PAT_OTH;
 223             no warnings qw(exiting);  last;
 224         };
 225         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 226             no warnings qw(exiting);
 227             if (!defined $mode) {
 228                 $mode = $_;  next;
 229             }
 230             die unless s{^debian/patches/}{};
 231             my $ok;
 232             if ($mode eq 'A' && !m/\.series$/s) {
 233                 $ok = 1;
 234             } elsif ($mode eq 'M' && $_ eq 'series') {
 235                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 236                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 237                 chomp $x_s;  $x_s .= "\n";
 238                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 239             } else {
 240                 # nope
 241             }
 242             $mode = undef;
 243             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 244         });
 245         die "mysterious debian/patches changes $x..$y"
 246             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 247     }
 248
 249     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 250
 251     return $differs;
 252 }
 253
 254 sub commit_pr_info ($) {
 255     my ($r) = @_;
 256     return Data::Dumper->dump([$r], [qw(commit)]);
 257 }
 258
 259 sub calculate_committer_authline () {
 260     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 261         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 262     my ($h,$m) = get_commit $c;
 263     $h =~ m/^committer .*$/m or confess "($h) ?";
 264     return $&;
 265 }
 266
 267 sub rm_subdir_cached ($) {
 268     my ($subdir) = @_;
 269     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 270 }
 271
 272 sub read_tree_subdir ($$) {
 273     my ($subdir, $new_tree_object) = @_;
 274     rm_subdir_cached $subdir;
 275     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 276 }
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @fproblem_force_opts;
 288 our $fproblems_forced;
 289 our $fproblems_tripped;
 290 sub fproblem ($$) {
 291     my ($tag,$msg) = @_;
 292     if (grep { $_ eq $tag } @fproblem_force_opts) {
 293         $fproblems_forced++;
 294         print STDERR "git-debrebase: safety catch overridden (-f$tag): $msg\n";
 295     } else {
 296         $fproblems_tripped++;
 297         print STDERR "git-debrebase: safety catch tripped (-f$tag): $msg\n";
 298     }
 299 }
 300
 301 sub fproblems_maybe_bail () {
 302     if ($fproblems_forced) {
 303         printf STDERR
 304             "%s: safety catch trips: %d overriden by individual -f options\n",
 305             $us, $fproblems_forced;
 306     }
 307     if ($fproblems_tripped) {
 308         if ($opt_force) {
 309             printf STDERR
 310                 "%s: safety catch trips: %d overriden by global --force\n",
 311                 $us, $fproblems_tripped;
 312         } else {
 313             fail sprintf
 314   "%s: safety catch trips: %d blockers (you could -f<tag>, or --force)",
 315                 $us, $fproblems_tripped;
 316         }
 317     }
 318 }
 319 sub any_fproblems () {
 320     return $fproblems_forced || $fproblems_tripped;
 321 }
 322
 323 # classify returns an info hash like this
 324 #   CommitId => $objid
 325 #   Hdr => # commit headers, including 1 final newline
 326 #   Msg => # commit message (so one newline is dropped)
 327 #   Tree => $treeobjid
 328 #   Type => (see below)
 329 #   Parents = [ {
 330 #       Ix => $index # ie 0, 1, 2, ...
 331 #       CommitId
 332 #       Differs => return value from get_differs
 333 #       IsOrigin
 334 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 335 #     } ...]
 336 #   NewMsg => # commit message, but with any [dgit import ...] edited
 337 #             # to say "[was: ...]"
 338 #
 339 # Types:
 340 #   Packaging
 341 #   Changelog
 342 #   Upstream
 343 #   AddPatches
 344 #   Mixed
 345 #
 346 #   Pseudomerge
 347 #     has additional entres in classification result
 348 #       Overwritten = [ subset of Parents ]
 349 #       Contributor = $the_remaining_Parent
 350 #
 351 #   DgitImportUnpatched
 352 #     has additional entry in classification result
 353 #       OrigParents = [ subset of Parents ]
 354 #
 355 #   Anchor
 356 #     has additional entry in classification result
 357 #       OrigParents = [ subset of Parents ]  # singleton list
 358 #
 359 #   TreatAsAnchor
 360 #
 361 #   BreakwaterStart
 362 #
 363 #   Unknown
 364 #     has additional entry in classification result
 365 #       Why => "prose"
 366
 367 sub parsecommit ($;$) {
 368     my ($objid, $p_ref) = @_;
 369     # => hash with                   CommitId Hdr Msg Tree Parents
 370     #    Parents entries have only   Ix CommitId
 371     #    $p_ref, if provided, must be [] and is used as a base for Parents
 372
 373     $p_ref //= [];
 374     die if @$p_ref;
 375
 376     my ($h,$m) = get_commit $objid;
 377
 378     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 379     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 380
 381     my $r = {
 382         CommitId => $objid,
 383         Hdr => $h,
 384         Msg => $m,
 385         Tree => $t,
 386         Parents => $p_ref,
 387     };
 388
 389     foreach my $ph (@ph) {
 390         push @$p_ref, {
 391             Ix => scalar @$p_ref,
 392             CommitId => $ph,
 393         };
 394     }
 395
 396     return $r;
 397 }
 398
 399 sub classify ($) {
 400     my ($objid) = @_;
 401
 402     my @p;
 403     my $r = parsecommit($objid, \@p);
 404     my $t = $r->{Tree};
 405
 406     foreach my $p (@p) {
 407         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 408     }
 409
 410     printdebug "classify $objid \$t=$t \@p",
 411         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 412         "\n";
 413
 414     my $classify = sub {
 415         my ($type, @rest) = @_;
 416         $r = { %$r, Type => $type, @rest };
 417         if ($debuglevel) {
 418             printdebug " = $type ".(dd $r)."\n";
 419         }
 420         return $r;
 421     };
 422     my $unknown = sub {
 423         my ($why) = @_;
 424         $r = { %$r, Type => qw(Unknown), Why => $why };
 425         printdebug " ** Unknown\n";
 426         return $r;
 427     };
 428
 429     if (grep { $_ eq $objid } @opt_anchors) {
 430         return $classify->('TreatAsAnchor');
 431     }
 432
 433     my @identical = grep { !$_->{Differs} } @p;
 434     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 435     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 436
 437     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 438         # multi-orig upstreams are represented with an anchor merge
 439         # from a single upstream commit which combines the orig tarballs
 440
 441         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 442         @p == 2 or return $badanchor->("has other than two parents");
 443         $haspatches and return $badanchor->("contains debian/patches");
 444
 445         # How to decide about l/r ordering of anchors ?  git
 446         # --topo-order prefers to expand 2nd parent first.  There's
 447         # already an easy rune to look for debian/ history anyway (git log
 448         # debian/) so debian breakwater branch should be 1st parent; that
 449         # way also there's also an easy rune to look for the upstream
 450         # patches (--topo-order).
 451
 452         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 453         $p[1]{Differs} & ~DS_DEB and
 454             $badanchor->("upstream files differ from left parent");
 455         $p[0]{Differs} & ~D_UPS and
 456             $badanchor->("debian/ differs from right parent");
 457
 458         return $classify->(qw(Anchor),
 459                            OrigParents => [ $p[1] ]);
 460     }
 461
 462     if (@p == 1) {
 463         my $d = $r->{Parents}[0]{Differs};
 464         if ($d == D_PAT_ADD) {
 465             return $classify->(qw(AddPatches));
 466         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 467             return $unknown->("edits debian/patches");
 468         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 469             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 470             if ($ty eq 'tree') {
 471                 if ($d == D_DEB_CLOG) {
 472                     return $classify->(qw(Changelog));
 473                 } else {
 474                     return $classify->(qw(Packaging));
 475                 }
 476             } elsif ($ty eq 'missing') {
 477                 return $classify->(qw(BreakwaterStart));
 478             } else {
 479                 return $unknown->("parent's debian is not a directory");
 480             }
 481         } elsif ($d == D_UPS) {
 482             return $classify->(qw(Upstream));
 483         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 484             return $classify->(qw(Mixed));
 485         } elsif ($d == 0) {
 486             return $unknown->("no changes");
 487         } else {
 488             confess "internal error $objid ?";
 489         }
 490     }
 491     if (!@p) {
 492         return $unknown->("origin commit");
 493     }
 494
 495     if (@p == 2 && @identical == 1) {
 496         my @overwritten = grep { $_->{Differs} } @p;
 497         confess "internal error $objid ?" unless @overwritten==1;
 498         return $classify->(qw(Pseudomerge),
 499                            Overwritten => [ $overwritten[0] ],
 500                            Contributor => $identical[0]);
 501     }
 502     if (@p == 2 && @identical == 2) {
 503         my $get_t = sub {
 504             my ($ph,$pm) = get_commit $_[0]{CommitId};
 505             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 506             $1;
 507         };
 508         my @bytime = @p;
 509         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 510         if ($order > 0) { # newer first
 511         } elsif ($order < 0) {
 512             @bytime = reverse @bytime;
 513         } else {
 514             # same age, default to order made by -s ours
 515             # that is, commit was made by someone who preferred L
 516         }
 517         return $classify->(qw(Pseudomerge),
 518                            SubType => qw(Ambiguous),
 519                            Contributor => $bytime[0],
 520                            Overwritten => [ $bytime[1] ]);
 521     }
 522     foreach my $p (@p) {
 523         my ($p_h, $p_m) = get_commit $p->{CommitId};
 524         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 525         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 526     }
 527     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 528     my $m2 = $r->{Msg};
 529     if (!(grep { !$_->{IsOrigin} } @p) and
 530         (@orig_ps >= @p - 1) and
 531         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 532         $r->{NewMsg} = $m2;
 533         return $classify->(qw(DgitImportUnpatched),
 534                            OrigParents => \@orig_ps);
 535     }
 536
 537     return $unknown->("complex merge");
 538 }
 539
 540 sub breakwater_of ($) {
 541     my ($head) = @_; # must be laundered
 542     my $breakwater;
 543     my $unclean = sub {
 544         my ($why) = @_;
 545         fail "branch needs laundering (run git-debrebase): $why";
 546     };
 547     for (;;) {
 548         my $cl = classify $head;
 549         my $ty = $cl->{Type};
 550         if ($ty eq 'Packaging' or
 551             $ty eq 'Changelog') {
 552             $breakwater //= $head;
 553         } elsif ($ty eq 'Anchor' or
 554                  $ty eq 'TreatAsAnchor' or
 555                  $ty eq 'BreakwaterStart') {
 556             $breakwater //= $head;
 557             last;
 558         } elsif ($ty eq 'Upstream') {
 559             $unclean->("packaging change ($breakwater)".
 560                        " follows upstream change (eg $head)")
 561                 if defined $breakwater;
 562         } elsif ($ty eq 'Mixed') {
 563             $unclean->('found mixed upstream/packaging commit ($head)');
 564         } elsif ($ty eq 'Pseudomerge' or
 565                  $ty eq 'AddPatches') {
 566             $unclean->("found interchange conversion commit ($ty, $head)");
 567         } elsif ($ty eq 'DgitImportUnpatched') {
 568             $unclean->("found dgit dsc import ($head)");
 569         } else {
 570             fail "found unprocessable commit, cannot cope: $head; $cl->{Why}";
 571         }
 572         $head = $cl->{Parents}[0]{CommitId};
 573     }
 574     return $breakwater;
 575 }
 576
 577 sub walk ($;$$);
 578 sub walk ($;$$) {
 579     my ($input,
 580         $nogenerate,$report) = @_;
 581     # => ($tip, $breakwater_tip, $last_anchor)
 582     # (or nothing, if $nogenerate)
 583
 584     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 585
 586     # go through commits backwards
 587     # we generate two lists of commits to apply:
 588     # breakwater branch and upstream patches
 589     my (@brw_cl, @upp_cl, @processed);
 590     my %found;
 591     my $upp_limit;
 592     my @pseudomerges;
 593
 594     my $cl;
 595     my $xmsg = sub {
 596         my ($prose, $info) = @_;
 597         my $ms = $cl->{Msg};
 598         chomp $ms;
 599         $info //= '';
 600         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 601         return (Msg => $ms);
 602     };
 603     my $rewrite_from_here = sub {
 604         my ($cl) = @_;
 605         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 606         push @$cl, $sp_cl;
 607         push @processed, $sp_cl;
 608     };
 609     my $cur = $input;
 610
 611     my $prdelim = "";
 612     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 613
 614     my $prline = sub {
 615         return unless $report;
 616         print $report $prdelim, @_;
 617         $prdelim = "\n";
 618     };
 619
 620     my $bomb = sub { # usage: return $bomb->();
 621         print $report " Unprocessable" if $report;
 622         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 623         $prprdelim->();
 624         if ($nogenerate) {
 625             return (undef,undef);
 626         }
 627         die "commit $cur: Cannot cope with this commit (d.".
 628             (join ' ', map { sprintf "%#x", $_->{Differs} }
 629              @{ $cl->{Parents} }).
 630             (defined $cl->{Why} ? "; $cl->{Why}": '').
 631                  ")";
 632     };
 633
 634     my $build;
 635     my $breakwater;
 636
 637     my $build_start = sub {
 638         my ($msg, $parent) = @_;
 639         $prline->(" $msg");
 640         $build = $parent;
 641         no warnings qw(exiting); last;
 642     };
 643
 644     my $last_anchor;
 645
 646     for (;;) {
 647         $cl = classify $cur;
 648         my $ty = $cl->{Type};
 649         my $st = $cl->{SubType};
 650         $prline->("$cl->{CommitId} $cl->{Type}");
 651         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 652         push @processed, $cl;
 653         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 654         if ($ty eq 'AddPatches') {
 655             $cur = $p0;
 656             $rewrite_from_here->(\@upp_cl);
 657             next;
 658         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 659             push @brw_cl, $cl;
 660             $cur = $p0;
 661             next;
 662         } elsif ($ty eq 'BreakwaterStart') {
 663             $last_anchor = $cur;
 664             $build_start->('FirstPackaging', $cur);
 665         } elsif ($ty eq 'Upstream') {
 666             push @upp_cl, $cl;
 667             $cur = $p0;
 668             next;
 669         } elsif ($ty eq 'Mixed') {
 670             my $queue = sub {
 671                 my ($q, $wh) = @_;
 672                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 673                 push @$q, $cls;
 674             };
 675             $queue->(\@brw_cl, "debian");
 676             $queue->(\@upp_cl, "upstream");
 677             $rewrite_from_here->(\@brw_cl);
 678             $cur = $p0;
 679             next;
 680         } elsif ($ty eq 'Pseudomerge') {
 681             my $contrib = $cl->{Contributor}{CommitId};
 682             print $report " Contributor=$contrib" if $report;
 683             push @pseudomerges, $cl;
 684             $rewrite_from_here->(\@upp_cl);
 685             $cur = $contrib;
 686             next;
 687         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
 688             $last_anchor = $cur;
 689             $build_start->("Anchor", $cur);
 690         } elsif ($ty eq 'DgitImportUnpatched') {
 691             my $pm = $pseudomerges[-1];
 692             if (defined $pm) {
 693                 # To an extent, this is heuristic.  Imports don't have
 694                 # a useful history of the debian/ branch.  We assume
 695                 # that the first pseudomerge after an import has a
 696                 # useful history of debian/, and ignore the histories
 697                 # from later pseudomerges.  Often the first pseudomerge
 698                 # will be the dgit import of the upload to the actual
 699                 # suite intended by the non-dgit NMUer, and later
 700                 # pseudomerges may represent in-archive copies.
 701                 my $ovwrs = $pm->{Overwritten};
 702                 printf $report " PM=%s \@Overwr:%d",
 703                     $pm->{CommitId}, (scalar @$ovwrs)
 704                     if $report;
 705                 if (@$ovwrs != 1) {
 706                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 707                     return $bomb->();
 708                 }
 709                 my $ovwr = $ovwrs->[0]{CommitId};
 710                 printf $report " Overwr=%s", $ovwr if $report;
 711                 # This import has a tree which is just like a
 712                 # breakwater tree, but it has the wrong history.  It
 713                 # ought to have the previous breakwater (which the
 714                 # pseudomerge overwrote) as an ancestor.  That will
 715                 # make the history of the debian/ files correct.  As
 716                 # for the upstream version: either it's the same as
 717                 # was ovewritten (ie, same as the previous
 718                 # breakwater), in which case that history is precisely
 719                 # right; or, otherwise, it was a non-gitish upload of a
 720                 # new upstream version.  We can tell these apart by
 721                 # looking at the tree of the supposed upstream.
 722                 push @brw_cl, {
 723                     %$cl,
 724                     SpecialMethod => 'DgitImportDebianUpdate',
 725                     $xmsg->("convert dgit import: debian changes")
 726                 }, {
 727                     %$cl,
 728                     SpecialMethod => 'DgitImportUpstreamUpdate',
 729                     $xmsg->("convert dgit import: upstream update",
 730                             " anchor")
 731                 };
 732                 $prline->(" Import");
 733                 $rewrite_from_here->(\@brw_cl);
 734                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 735                 $cur = $ovwr;
 736                 next;
 737             } else {
 738                 # Everything is from this import.  This kind of import
 739                 # is already in valid breakwater format, with the
 740                 # patches as commits.
 741                 printf $report " NoPM" if $report;
 742                 # last thing we processed will have been the first patch,
 743                 # if there is one; which is fine, so no need to rewrite
 744                 # on account of this import
 745                 $build_start->("ImportOrigin", $cur);
 746             }
 747             die "$ty ?";
 748         } else {
 749             printdebug "*** WALK BOMB unrecognised\n";
 750             return $bomb->();
 751         }
 752     }
 753     $prprdelim->();
 754
 755     printdebug "*** WALK prep done cur=$cur".
 756         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 757
 758     return if $nogenerate;
 759
 760     # Now we build it back up again
 761
 762     fresh_workarea();
 763
 764     my $rewriting = 0;
 765
 766     my $read_tree_debian = sub {
 767         my ($treeish) = @_;
 768         read_tree_subdir 'debian', "$treeish:debian";
 769         rm_subdir_cached 'debian/patches';
 770     };
 771     my $read_tree_upstream = sub {
 772         my ($treeish) = @_;
 773         runcmd @git, qw(read-tree), $treeish;
 774         $read_tree_debian->($build);
 775     };
 776
 777     $#upp_cl = $upp_limit if defined $upp_limit;
 778
 779     my $committer_authline = calculate_committer_authline();
 780
 781     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 782
 783     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 784
 785     in_workarea sub {
 786         mkdir $rd or $!==EEXIST or die $!;
 787         my $current_method;
 788         runcmd @git, qw(read-tree), $build;
 789         foreach my $cl (qw(Debian), (reverse @brw_cl),
 790                         { SpecialMethod => 'RecordBreakwaterTip' },
 791                         qw(Upstream), (reverse @upp_cl)) {
 792             if (!ref $cl) {
 793                 $current_method = $cl;
 794                 next;
 795             }
 796             my $method = $cl->{SpecialMethod} // $current_method;
 797             my @parents = ($build);
 798             my $cltree = $cl->{CommitId};
 799             printdebug "WALK BUILD ".($cltree//'undef').
 800                 " $method (rewriting=$rewriting)\n";
 801             if ($method eq 'Debian') {
 802                 $read_tree_debian->($cltree);
 803             } elsif ($method eq 'Upstream') {
 804                 $read_tree_upstream->($cltree);
 805             } elsif ($method eq 'StartRewrite') {
 806                 $rewriting = 1;
 807                 next;
 808             } elsif ($method eq 'RecordBreakwaterTip') {
 809                 $breakwater = $build;
 810                 next;
 811             } elsif ($method eq 'DgitImportDebianUpdate') {
 812                 $read_tree_debian->($cltree);
 813             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 814                 confess unless $rewriting;
 815                 my $differs = (get_differs $build, $cltree);
 816                 next unless $differs & D_UPS;
 817                 $read_tree_upstream->($cltree);
 818                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 819             } else {
 820                 confess "$method ?";
 821             }
 822             if (!$rewriting) {
 823                 my $procd = (pop @processed) // 'UNDEF';
 824                 if ($cl ne $procd) {
 825                     $rewriting = 1;
 826                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 827                 }
 828             }
 829             my $newtree = cmdoutput @git, qw(write-tree);
 830             my $ch = $cl->{Hdr};
 831             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 832             $ch =~ s{^parent .*\n}{}mg;
 833             $ch =~ s{(?=^author)}{
 834                 join '', map { "parent $_\n" } @parents
 835             }me or confess "$ch ?";
 836             if ($rewriting) {
 837                 $ch =~ s{^committer .*$}{$committer_authline}m
 838                     or confess "$ch ?";
 839             }
 840             my $cf = "$rd/m$rewriting";
 841             open CD, ">", $cf or die $!;
 842             print CD $ch, "\n", $cl->{Msg} or die $!;
 843             close CD or die $!;
 844             my @cmd = (@git, qw(hash-object));
 845             push @cmd, qw(-w) if $rewriting;
 846             push @cmd, qw(-t commit), $cf;
 847             my $newcommit = cmdoutput @cmd;
 848             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 849             $build = $newcommit;
 850             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 851                 $last_anchor = $cur;
 852             }
 853         }
 854     };
 855
 856     my $final_check = get_differs $build, $input;
 857     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 858         if $final_check & ~D_PAT_ADD;
 859
 860     my @r = ($build, $breakwater, $last_anchor);
 861     printdebug "*** WALK RETURN @r\n";
 862     return @r
 863 }
 864
 865 sub get_head () {
 866     git_check_unmodified();
 867     return git_rev_parse qw(HEAD);
 868 }
 869
 870 sub update_head ($$$) {
 871     my ($old, $new, $mrest) = @_;
 872     push @deferred_updates, "update HEAD $new $old";
 873     run_deferred_updates $mrest;
 874 }
 875
 876 sub update_head_checkout ($$$) {
 877     my ($old, $new, $mrest) = @_;
 878     update_head $old, $new, $mrest;
 879     runcmd @git, qw(reset --hard);
 880 }
 881
 882 sub update_head_postlaunder ($$$) {
 883     my ($old, $tip, $reflogmsg) = @_;
 884     return if $tip eq $old;
 885     print "git-debrebase: laundered (head was $old)\n";
 886     update_head $old, $tip, $reflogmsg;
 887     # no tree changes except debian/patches
 888     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 889 }
 890
 891 sub cmd_launder_v0 () {
 892     badusage "no arguments to launder-v0 allowed" if @ARGV;
 893     my $old = get_head();
 894     my ($tip,$breakwater,$last_anchor) = walk $old;
 895     update_head_postlaunder $old, $tip, 'launder';
 896     printf "# breakwater tip\n%s\n", $breakwater;
 897     printf "# working tip\n%s\n", $tip;
 898     printf "# last anchor\n%s\n", $last_anchor;
 899 }
 900
 901 sub defaultcmd_rebase () {
 902     my $old = get_head();
 903     record_ffq_auto();
 904     my ($tip,$breakwater) = walk $old;
 905     update_head_postlaunder $old, $tip, 'launder for rebase';
 906     runcmd @git, qw(rebase), @ARGV, $breakwater;
 907 }
 908
 909 sub cmd_analyse () {
 910     die if ($ARGV[0]//'') =~ m/^-/;
 911     badusage "too many arguments to analyse" if @ARGV>1;
 912     my ($old) = @ARGV;
 913     if (defined $old) {
 914         $old = git_rev_parse $old;
 915     } else {
 916         $old = git_rev_parse 'HEAD';
 917     }
 918     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 919     STDOUT->error and die $!;
 920 }
 921
 922 sub ffq_prev_branchinfo () {
 923     # => ('status', "message", [$current, $ffq_prev])
 924     # 'status' may be
 925     #    branch         message is undef
 926     #    weird-symref   } no $current,
 927     #    notbranch      }  no $ffq_prev
 928     my $current = git_get_symref();
 929     return ('detached', 'detached HEAD') unless defined $current;
 930     return ('weird-symref', 'HEAD symref is not to refs/')
 931         unless $current =~ m{^refs/};
 932     my $ffq_prev = "refs/$ffq_refprefix/$'";
 933     printdebug "ffq_prev_branchinfo branch current $current\n";
 934     return ('branch', undef, $current, $ffq_prev);
 935 }
 936
 937 sub record_ffq_prev_deferred () {
 938     # => ('status', "message")
 939     # 'status' may be
 940     #    deferred          message is undef
 941     #    exists
 942     #    detached
 943     #    weird-symref
 944     #    notbranch
 945     # if not ff from some branch we should be ff from, is an fproblem
 946     # if "deferred", will have added something about that to
 947     #   @deferred_update_messages, and also maybe printed (already)
 948     #   some messages about ff checks
 949     my ($status, $message, $current, $ffq_prev) = ffq_prev_branchinfo();
 950     return ($status, $message) unless $status eq 'branch';
 951
 952     my $currentval = get_head();
 953
 954     my $exists = git_get_ref $ffq_prev;
 955     return ('exists',"$ffq_prev already exists") if $exists;
 956
 957     return ('not-branch', 'HEAD symref is not to refs/heads/')
 958         unless $current =~ m{^refs/heads/};
 959     my $branch = $';
 960
 961     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
 962     my %checked;
 963
 964     printdebug "ffq check_specs @check_specs\n";
 965
 966     my $check = sub {
 967         my ($lrref, $desc) = @_;
 968         printdebug "ffq might check $lrref ($desc)\n";
 969         my $invert;
 970         for my $chk (@check_specs) {
 971             my $glob = $chk;
 972             $invert = $glob =~ s{^[!^]}{};
 973             last if fnmatch $glob, $lrref;
 974         }
 975         return if $invert;
 976         my $lrval = git_get_ref $lrref;
 977         return unless defined $lrval;
 978
 979         if (is_fast_fwd $lrval, $currentval) {
 980             print "OK, you are ahead of $lrref\n" or die $!;
 981             $checked{$lrref} = 1;
 982         } elsif (is_fast_fwd $currentval, $lrval) {
 983             $checked{$lrref} = -1;
 984             fproblem 'behind', "you are behind $lrref, divergence risk";
 985         } else {
 986             $checked{$lrref} = -1;
 987             fproblem 'diverged', "you have diverged from $lrref";
 988         }
 989     };
 990
 991     my $merge = cfg "branch.$branch.merge",1;
 992     if (defined $merge and $merge =~ m{^refs/heads/}) {
 993         my $rhs = $';
 994         printdebug "ffq merge $rhs\n";
 995         my $check_remote = sub {
 996             my ($remote, $desc) = @_;
 997             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
 998             return unless defined $remote;
 999             $check->("refs/remotes/$remote/$rhs", $desc);
1000         };
1001         $check_remote->((scalar cfg "branch.$branch.remote",1),
1002                         'remote fetch/merge branch');
1003         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1004                         (scalar cfg "branch.$branch.pushDefault",1),
1005                         'remote push branch');
1006     }
1007     if ($branch =~ m{^dgit/}) {
1008         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1009     } elsif ($branch =~ m{^master$}) {
1010         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1011     }
1012
1013     fproblems_maybe_bail();
1014
1015     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1016     push @deferred_update_messages, "Recorded current head for preservation";
1017     return ('deferred', undef);
1018 }
1019
1020 sub record_ffq_auto () {
1021     my ($status, $message) = record_ffq_prev_deferred();
1022     if ($status eq 'deferred' || $status eq 'exists') {
1023     } else {
1024         fproblem $status, "could not record ffq-prev: $message";
1025         fproblems_maybe_bail();
1026     }
1027 }
1028
1029 sub cmd_new_upstream_v0 () {
1030     # automatically and unconditionally launders before rebasing
1031     # if rebase --abort is used, laundering has still been done
1032
1033     my %pieces;
1034
1035     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1036
1037     # parse args - low commitment
1038     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
1039     my $new_upstream_version = $new_version->version();
1040
1041     my $new_upstream = git_rev_parse (shift @ARGV // 'upstream');
1042
1043     record_ffq_auto();
1044
1045     my $piece = sub {
1046         my ($n, @x) = @_; # may be ''
1047         my $pc = $pieces{$n} //= {
1048             Name => $n,
1049             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1050         };
1051         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1052         $pc;
1053     };
1054
1055     my @newpieces;
1056     my $newpiece = sub {
1057         my ($n, @x) = @_; # may be ''
1058         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1059         push @newpieces, $pc;
1060     };
1061
1062     $newpiece->('',
1063         OldIx => 0,
1064         New => $new_upstream,
1065     );
1066     while (@ARGV && $ARGV[0] !~ m{^-}) {
1067         my $n = shift @ARGV;
1068
1069         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1070             unless @ARGV && $ARGV[0] !~ m{^-};
1071
1072         my $c = git_rev_parse shift @ARGV;
1073         die unless $n =~ m/^$extra_orig_namepart_re$/;
1074         $newpiece->($n, New => $c);
1075     }
1076
1077     # now we need to investigate the branch this generates the
1078     # laundered version but we don't switch to it yet
1079     my $old_head = get_head();
1080     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1081
1082     my $old_bw_cl = classify $old_bw;
1083     my $old_anchor_cl = classify $old_anchor;
1084     my $old_upstream;
1085     if (!$old_anchor_cl->{OrigParents}) {
1086         fproblem 'anchor-treated',
1087             'old anchor is recognised due to --anchor, cannot check upstream';
1088     } else {
1089         $old_upstream = parsecommit
1090             $old_anchor_cl->{OrigParents}[0]{CommitId};
1091         $piece->('', Old => $old_upstream->{CommitId});
1092     }
1093
1094     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1095         if ($old_upstream->{Msg} =~
1096  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
1097            ) {
1098             my @oldpieces = ('', split / /, $1);
1099             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
1100             foreach my $i (0..$#oldpieces) {
1101                 my $n = $oldpieces[$i];
1102                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
1103             }
1104         } else {
1105             fproblem 'upstream-confusing',
1106                 "previous upstream $old_upstream->{CommitId} is from".
1107                " git-debrebase but not an \`upstream-combine' commit";
1108         }
1109     }
1110
1111     foreach my $pc (values %pieces) {
1112         if (!$old_upstream) {
1113             # we have complained already
1114         } elsif (!$pc->{Old}) {
1115             fproblem 'upstream-new-piece',
1116                 "introducing upstream piece \`$pc->{Name}'";
1117         } elsif (!$pc->{New}) {
1118             fproblem 'upstream-rm-piece',
1119                 "dropping upstream piece \`$pc->{Name}'";
1120         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1121             fproblem 'upstream-not-ff',
1122                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1123         }
1124     }
1125
1126     printdebug "%pieces = ", (dd \%pieces), "\n";
1127     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1128
1129     fproblems_maybe_bail();
1130
1131     my $new_bw;
1132
1133     fresh_workarea();
1134     in_workarea sub {
1135         my @upstream_merge_parents;
1136
1137         if (!any_fproblems()) {
1138             push @upstream_merge_parents, $old_upstream->{CommitId};
1139         }
1140
1141         foreach my $pc (@newpieces) { # always has '' first
1142             if ($pc->{Name}) {
1143                 read_tree_subdir $pc->{Name}, $pc->{New};
1144             } else {
1145                 runcmd @git, qw(read-tree), $pc->{New};
1146             }
1147             push @upstream_merge_parents, $pc->{New};
1148         }
1149
1150         # index now contains the new upstream
1151
1152         if (@newpieces > 1) {
1153             # need to make the upstream subtree merge commit
1154             $new_upstream = make_commit \@upstream_merge_parents,
1155                 [ "Combine upstreams for $new_upstream_version",
1156  ("[git-debrebase upstream-combine . ".
1157  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1158  ": new upstream]"),
1159                 ];
1160         }
1161
1162         # $new_upstream is either the single upstream commit, or the
1163         # combined commit we just made.  Either way it will be the
1164         # "upstream" parent of the anchor merge.
1165
1166         read_tree_subdir 'debian', "$old_bw:debian";
1167
1168         # index now contains the anchor merge contents
1169         $new_bw = make_commit [ $old_bw, $new_upstream ],
1170             [ "Update to upstream $new_upstream_version",
1171  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1172             ];
1173
1174         # Now we have to add a changelog stanza so the Debian version
1175         # is right.
1176         die if unlink "debian";
1177         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1178         unlink "debian/changelog" or $!==ENOENT or die $!;
1179         mkdir "debian" or die $!;
1180         open CN, ">", "debian/changelog" or die $!;
1181         my $oldclog = git_cat_file ":debian/changelog";
1182         $oldclog =~ m/^($package_re) \(\S+\) / or
1183             fail "cannot parse old changelog to get package name";
1184         my $p = $1;
1185         print CN <<END, $oldclog or die $!;
1186 $p ($new_version) UNRELEASED; urgency=medium
1187
1188   * Update to new upstream version $new_upstream_version.
1189
1190  --
1191
1192 END
1193         close CN or die $!;
1194         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1195
1196         # Now we have the final new breakwater branch in the index
1197         $new_bw = make_commit [ $new_bw ],
1198             [ "Update changelog for new upstream $new_upstream_version",
1199               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1200             ];
1201     };
1202
1203     # we have constructed the new breakwater. we now need to commit to
1204     # the laundering output, because git-rebase can't easily be made
1205     # to make a replay list which is based on some other branch
1206
1207     update_head_postlaunder $old_head, $old_laundered_tip,
1208         'launder for new upstream';
1209
1210     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1211     runcmd @cmd;
1212     # now it's for the user to sort out
1213 }
1214
1215 sub cmd_record_ffq_prev () {
1216     badusage "no arguments allowed" if @ARGV;
1217     my ($status, $msg) = record_ffq_prev_deferred();
1218     if ($status eq 'exists' && $opt_noop_ok) {
1219         print "Previous head already recorded\n" or die $!;
1220     } elsif ($status eq 'deferred') {
1221         run_deferred_updates 'record-ffq-prev';
1222     } else {
1223         fail "Could not preserve: $msg";
1224     }
1225 }
1226
1227 sub cmd_breakwater () {
1228     badusage "no arguments allowed" if @ARGV;
1229     my $bw = breakwater_of git_rev_parse 'HEAD';
1230     print "$bw\n" or die $!;
1231 }
1232
1233 sub cmd_stitch () {
1234     my $prose = '';
1235     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1236     badusage "no arguments allowed" if @ARGV;
1237     my ($status, $message, $current, $ffq_prev) = ffq_prev_branchinfo();
1238     if ($status ne 'branch') {
1239         fproblem $status, "could not check ffq-prev: $message";
1240         fproblems_maybe_bail();
1241     }
1242     my $prev = $ffq_prev && git_get_ref $ffq_prev;
1243     if (!$prev) {
1244         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1245     }
1246     push @deferred_updates, "delete $ffq_prev $prev";
1247
1248     my $old_head = get_head();
1249     if (is_fast_fwd $old_head, $prev) {
1250         my $differs = get_differs $old_head, $prev;
1251         unless ($differs & ~D_PAT_ADD) {
1252             # ffq-prev is ahead of us, and the only tree changes it has
1253             # are possibly addition of things in debian/patches/.
1254             # Just wind forwards rather than making a pointless pseudomerge.
1255             update_head_checkout $old_head, $prev, "stitch (fast forward)";
1256             return;
1257         }
1258     }
1259     fresh_workarea();
1260     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1261         'Declare fast forward / record previous work',
1262         "[git-debrebase pseudomerge: stitch$prose]",
1263     ];
1264     update_head $old_head, $new_head, "stitch";
1265 }
1266
1267 sub cmd_convert_from_gbp () {
1268     badusage "needs 1 optional argument, the upstream git rev"
1269         unless @ARGV<=1;
1270     my ($upstream_spec) = @ARGV;
1271     $upstream_spec //= 'refs/heads/upstream';
1272     my $upstream = git_rev_parse $upstream_spec;
1273     my $old_head = get_head();
1274
1275     my $upsdiff = get_differs $upstream, $old_head;
1276     if ($upsdiff & D_UPS) {
1277         runcmd @git, qw(--no-pager diff),
1278             $upstream, $old_head,
1279             qw( -- :!/debian :/);
1280  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1281     }
1282
1283     if (!is_fast_fwd $upstream, $old_head) {
1284         fproblem 'upstream-not-ancestor',
1285             "upstream ($upstream) is not an ancestor of HEAD";
1286     } else {
1287         my $wrong = cmdoutput
1288             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1289              qw(-- :/ :!/debian));
1290         if (length $wrong) {
1291             fproblem 'unexpected-upstream-changes',
1292                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1293             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1294         }
1295     }
1296
1297     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1298         fproblem 'upstream-has-debian',
1299             "upstream ($upstream) contains debian/ directory";
1300     }
1301
1302     fproblems_maybe_bail();
1303
1304     my $work;
1305
1306     fresh_workarea();
1307     in_workarea sub {
1308         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1309         # make a branch out of the patch queue - we'll want this in a mo
1310         runcmd qw(gbp pq import);
1311         # strip the patches out
1312         runcmd @git, qw(checkout -q gdr-internal~0);
1313         rm_subdir_cached 'debian/patches';
1314         $work = make_commit ['HEAD'], [
1315  'git-debrebase convert-from-gbp: drop patches from tree',
1316  'Delete debian/patches, as part of converting to git-debrebase format.',
1317  '[git-debrebase convert-from-gbp: drop patches from tree]'
1318                               ];
1319         # make the anchor merge
1320         # the tree is already exactly right
1321         $work = make_commit [$work, $upstream], [
1322  'git-debrebase import: declare upstream',
1323  'First breakwater merge.',
1324  '[git-debrebase anchor: declare upstream]'
1325                               ];
1326
1327         # rebase the patch queue onto the new breakwater
1328         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1329         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1330         $work = git_rev_parse 'HEAD';
1331     };
1332
1333     update_head_checkout $old_head, $work, 'convert-from-gbp';
1334 }
1335
1336 sub cmd_convert_to_gbp () {
1337     badusage "no arguments allowed" if @ARGV;
1338     my $head = get_head();
1339     my $ffq = (ffq_prev_branchinfo())[3];
1340     my $bw = breakwater_of $head;
1341     fresh_workarea();
1342     my $out;
1343     in_workarea sub {
1344         runcmd @git, qw(checkout -q -b bw), $bw;
1345         runcmd @git, qw(checkout -q -b patch-queue/bw), $head;
1346         runcmd qw(gbp pq export);
1347         runcmd @git, qw(add debian/patches);
1348         $out = make_commit ['HEAD'], [
1349             'Commit patch queue (converted from git-debrebase format)',
1350             '[git-debrebase convert-to-gbp: commit patches]',
1351         ];
1352     };
1353     if (defined $ffq) {
1354         push @deferred_updates, "delete $ffq";
1355     }
1356     update_head_checkout $head, $out, "convert to gbp (v0)";
1357     print <<END or die $!;
1358 git-debrebase: converted to git-buildpackage branch format
1359 git-debrebase: WARNING: do not now run "git-debrebase" any more
1360 git-debrebase: WARNING: doing so would drop all upstream patches!
1361 END
1362 }
1363
1364 sub cmd_downstream_rebase_launder_v0 () {
1365     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1366     my ($base) = @ARGV;
1367     $base = git_rev_parse $base;
1368     my $old_head = get_head();
1369     my $current = $old_head;
1370     my $topmost_keep;
1371     for (;;) {
1372         if ($current eq $base) {
1373             $topmost_keep //= $current;
1374             print " $current BASE stop\n";
1375             last;
1376         }
1377         my $cl = classify $current;
1378         print " $current $cl->{Type}";
1379         my $keep = 0;
1380         my $p0 = $cl->{Parents}[0]{CommitId};
1381         my $next;
1382         if ($cl->{Type} eq 'Pseudomerge') {
1383             print " ^".($cl->{Contributor}{Ix}+1);
1384             $next = $cl->{Contributor}{CommitId};
1385         } elsif ($cl->{Type} eq 'AddPatches' or
1386                  $cl->{Type} eq 'Changelog') {
1387             print " strip";
1388             $next = $p0;
1389         } else {
1390             print " keep";
1391             $next = $p0;
1392             $keep = 1;
1393         }
1394         print "\n";
1395         if ($keep) {
1396             $topmost_keep //= $current;
1397         } else {
1398             die "to-be stripped changes not on top of the branch\n"
1399                 if $topmost_keep;
1400         }
1401         $current = $next;
1402     }
1403     if ($topmost_keep eq $old_head) {
1404         print "unchanged\n";
1405     } else {
1406         print "updating to $topmost_keep\n";
1407         update_head_checkout
1408             $old_head, $topmost_keep,
1409             'downstream-rebase-launder-v0';
1410     }
1411 }
1412
1413 GetOptions("D+" => \$debuglevel,
1414            'noop-ok', => \$opt_noop_ok,
1415            'f=s' => \@fproblem_force_opts,
1416            'anchor=s' => \@opt_anchors,
1417            'force!') or die badusage "bad options\n";
1418 initdebug('git-debrebase ');
1419 enabledebug if $debuglevel;
1420
1421 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1422 chdir $toplevel or die "chdir $toplevel: $!";
1423
1424 $rd = fresh_playground "$playprefix/misc";
1425
1426 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
1427
1428 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1429     defaultcmd_rebase();
1430 } else {
1431     my $cmd = shift @ARGV;
1432     my $cmdfn = $cmd;
1433     $cmdfn =~ y/-/_/;
1434     $cmdfn = ${*::}{"cmd_$cmdfn"};
1435
1436     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1437     $cmdfn->();
1438 }