chiark / gitweb /
git-debrebase: test suite: gdr-import-dgit: test a new upstream non-gdr upload too
[dgit.git] / git-debrebase
1 #!/usr/bin/perl -w
2 # git-debrebase
3 # Script helping make fast-forwarding histories while still rebasing
4 # upstream deltas when working on Debian packaging
5 #
6 # Copyright (C)2017,2018 Ian Jackson
7 #
8 # This program is free software: you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation, either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
20
21
22 # usages:
23 #
24 #    git-debrebase [<options>] new-upstream-v0 \
25 #             <new-version> <orig-commitish> \
26 #            [<extra-orig-name> <extra-orig-commitish> ...] \
27 #            [<git-rebase options>...]
28 #
29 #    git-debrebase [<options> --] [<git-rebase options...>]
30 #    git-debrebase [<options>] analyse
31 #    git-debrebase [<options>] breakwater      # prints breakwater tip only
32 #    git-debrebase [<options>] launder         # prints breakwater tip etc.
33 #    git-debrebase [<options>] stitch [--prose=<for commit message>]
34 #    git-debrebase [<options>] downstream-rebase-launder-v0  # experimental
35 #
36 #    git-debrebase [<options>] convert-from-gbp [<upstream-git-rev>]
37 #    git-debrebase [<options>] convert-to-gbp
38
39 # problems / outstanding questions:
40 #
41 #  *  dgit push with a `3.0 (quilt)' package means doing quilt
42 #     fixup.  Usually this involves recommitting the whole patch
43 #     series, one at a time, with dpkg-source --commit.  This is
44 #     terribly terribly slow.  (Maybe this should be fixed in dgit.)
45 #
46 #  * dgit push usually needs to (re)make a pseudomerge.  The "first"
47 #    git-debrebase stripped out the previous pseudomerge and could
48 #    have remembeed the HEAD.  But it's not quite clear what history
49 #    ought to be preserved and what should be discarded.  For now
50 #    the user will have to tell dgit --overwrite.
51 #
52 #    To fix this, do we need a new push hook for dgit ?
53 #
54 #  * Workflow is currently clumsy.  Lots of spurious runes to type.
55 #    There's not even a guide.
56 #
57 #  * There are no tests.
58 #
59 #  * new-upstream-v0 has a terrible UI.  You end up with giant
60 #    runic command lines.
61 #
62 #    One consequence of the lack of richness it can need --force in
63 #    fairly sensible situations and there is no way to tell it what
64 #    you are really trying to do, other than just --force.  There
65 #    should be an interface with some default branch names.
66 #
67 #  * There should be a standard convention for the version number,
68 #    and unfinalised or not changelog, after new-upstream.
69 #
70 #  * Handing of multi-orig dgit new-upstream .dsc imports is known to
71 #    be broken.  They may be not recognised, improperly converted, or
72 #    their conversion may be unrecognised.
73 #
74 #  * Docs need writing and updating.  Even README.git-debrebase
75 #    describes a design but may not reflect the implementation.
76 #
77 #  * We need to develop a plausible model that works for derivatives,
78 #    who probably want to maintain their stack on top of Debian's.
79 #    downstream-rebase-launder-v0 may be a starting point?
80
81 use strict;
82
83 use Debian::Dgit qw(:DEFAULT :playground);
84 setup_sigwarn();
85
86 use Memoize;
87 use Carp;
88 use POSIX;
89 use Data::Dumper;
90 use Getopt::Long qw(:config posix_default gnu_compat bundling);
91 use Dpkg::Version;
92 use File::FnMatch qw(:fnmatch);
93
94 our ($opt_force, $opt_noop_ok);
95
96 our $us = qw(git-debrebase);
97
98 sub badusage ($) {
99     my ($m) = @_;
100     die "bad usage: $m\n";
101 }
102
103 sub cfg ($;$) {
104     my ($k, $optional) = @_;
105     local $/ = "\0";
106     my @cmd = qw(git config -z);
107     push @cmd, qw(--get-all) if wantarray;
108     push @cmd, $k;
109     my $out = cmdoutput_errok @cmd;
110     if (!defined $out) {
111         fail "missing required git config $k" unless $optional;
112         return ();
113     }
114     return split /\0/, $out;
115 }
116
117 memoize('cfg');
118
119 sub dd ($) {
120     my ($v) = @_;
121     my $dd = new Data::Dumper [ $v ];
122     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
123     return Dump $dd;
124 }
125
126 sub get_commit ($) {
127     my ($objid) = @_;
128     my $data = (git_cat_file $objid, 'commit');
129     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
130     return ($`,$');
131 }
132
133 sub D_UPS ()      { 0x02; } # upstream files
134 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
135 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
136 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
137 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
138 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
139
140 our $playprefix = 'debrebase';
141 our $rd;
142 our $workarea;
143
144 our @git = qw(git);
145
146 sub in_workarea ($) {
147     my ($sub) = @_;
148     changedir $workarea;
149     my $r = eval { $sub->(); };
150     { local $@; changedir $maindir; }
151     die $@ if $@;
152 }
153
154 sub fresh_workarea () {
155     $workarea = fresh_playground "$playprefix/work";
156     in_workarea sub { playtree_setup };
157 }
158
159 sub get_differs ($$) {
160     my ($x,$y) = @_;
161     # This resembles quiltify_trees_differ, in dgit, a bit.
162     # But we don't care about modes, or dpkg-source-unrepresentable
163     # changes, and we don't need the plethora of different modes.
164     # Conversely we need to distinguish different kinds of changes to
165     # debian/ and debian/patches/.
166
167     my $differs = 0;
168
169     my $rundiff = sub {
170         my ($opts, $limits, $fn) = @_;
171         my @cmd = (@git, qw(diff-tree -z --no-renames));
172         push @cmd, @$opts;
173         push @cmd, "$_:" foreach $x, $y;
174         push @cmd, '--', @$limits;
175         my $diffs = cmdoutput @cmd;
176         foreach (split /\0/, $diffs) { $fn->(); }
177     };
178
179     $rundiff->([qw(--name-only)], [], sub {
180         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
181     });
182
183     if ($differs & DS_DEB) {
184         $differs &= ~DS_DEB;
185         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
186             $differs |=
187                 m{^debian/patches/}      ? D_PAT_OTH  :
188                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
189                                            D_DEB_OTH;
190         });
191         die "mysterious debian changes $x..$y"
192             unless $differs & (D_PAT_OTH|DS_DEB);
193     }
194
195     if ($differs & D_PAT_OTH) {
196         my $mode;
197         $differs &= ~D_PAT_OTH;
198         my $pat_oth = sub {
199             $differs |= D_PAT_OTH;
200             no warnings qw(exiting);  last;
201         };
202         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
203             no warnings qw(exiting);
204             if (!defined $mode) {
205                 $mode = $_;  next;
206             }
207             die unless s{^debian/patches/}{};
208             my $ok;
209             if ($mode eq 'A' && !m/\.series$/s) {
210                 $ok = 1;
211             } elsif ($mode eq 'M' && $_ eq 'series') {
212                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
213                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
214                 chomp $x_s;  $x_s .= "\n";
215                 $ok = $x_s eq substr($y_s, 0, length $x_s);
216             } else {
217                 # nope
218             }
219             $mode = undef;
220             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
221         });
222         die "mysterious debian/patches changes $x..$y"
223             unless $differs & (D_PAT_ADD|D_PAT_OTH);
224     }
225
226     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
227
228     return $differs;
229 }
230
231 sub commit_pr_info ($) {
232     my ($r) = @_;
233     return Data::Dumper->dump([$r], [qw(commit)]);
234 }
235
236 sub calculate_committer_authline () {
237     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
238         'DUMMY COMMIT (git-debrebase)', "HEAD:";
239     my ($h,$m) = get_commit $c;
240     $h =~ m/^committer .*$/m or confess "($h) ?";
241     return $&;
242 }
243
244 sub rm_subdir_cached ($) {
245     my ($subdir) = @_;
246     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
247 }
248
249 sub read_tree_subdir ($$) {
250     my ($subdir, $new_tree_object) = @_;
251     rm_subdir_cached $subdir;
252     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
253 }
254
255 sub make_commit ($$) {
256     my ($parents, $message_paras) = @_;
257     my $tree = cmdoutput @git, qw(write-tree);
258     my @cmd = (@git, qw(commit-tree), $tree);
259     push @cmd, qw(-p), $_ foreach @$parents;
260     push @cmd, qw(-m), $_ foreach @$message_paras;
261     return cmdoutput @cmd;
262 }
263
264 our @fproblem_force_opts;
265 our $fproblems_forced;
266 our $fproblems_tripped;
267 sub fproblem ($$) {
268     my ($tag,$msg) = @_;
269     if (grep { $_ eq $tag } @fproblem_force_opts) {
270         $fproblems_forced++;
271         print STDERR "git-debrebase: safety catch overridden (-f$tag): $msg\n";
272     } else {
273         $fproblems_tripped++;
274         print STDERR "git-debrebase: safety catch tripped (-f$tag): $msg\n";
275     }
276 }
277
278 sub fproblems_maybe_bail () {
279     if ($fproblems_forced) {
280         printf STDERR
281             "%s: safety catch trips: %d overriden by individual -f options\n",
282             $us, $fproblems_forced;
283     }
284     if ($fproblems_tripped) {
285         if ($opt_force) {
286             printf STDERR
287                 "%s: safety catch trips: %d overriden by global --force\n",
288                 $us, $fproblems_tripped;
289         } else {
290             fail sprintf
291   "%s: safety catch trips: %d blockers (you could -f<tag>, or --force)",
292                 $us, $fproblems_tripped;
293         }
294     }
295 }
296 sub any_fproblems () {
297     return $fproblems_forced || $fproblems_tripped;
298 }
299
300 # classify returns an info hash like this
301 #   CommitId => $objid
302 #   Hdr => # commit headers, including 1 final newline
303 #   Msg => # commit message (so one newline is dropped)
304 #   Tree => $treeobjid
305 #   Type => (see below)
306 #   Parents = [ {
307 #       Ix => $index # ie 0, 1, 2, ...
308 #       CommitId
309 #       Differs => return value from get_differs
310 #       IsOrigin
311 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
312 #     } ...]
313 #   NewMsg => # commit message, but with any [dgit import ...] edited
314 #             # to say "[was: ...]"
315 #
316 # Types:
317 #   Packaging
318 #   Changelog
319 #   Upstream
320 #   AddPatches
321 #   Mixed
322 #
323 #   Pseudomerge
324 #     has additional entres in classification result
325 #       Overwritten = [ subset of Parents ]
326 #       Contributor = $the_remaining_Parent
327 #
328 #   DgitImportUnpatched
329 #     has additional entry in classification result
330 #       OrigParents = [ subset of Parents ]
331 #
332 #   BreakwaterUpstreamMerge
333 #     has additional entry in classification result
334 #       OrigParents = [ subset of Parents ]  # singleton list
335 #
336 #   Unknown
337 #     has additional entry in classification result
338 #       Why => "prose"
339
340 sub parsecommit ($;$) {
341     my ($objid, $p_ref) = @_;
342     # => hash with                   CommitId Hdr Msg Tree Parents
343     #    Parents entries have only   Ix CommitId
344     #    $p_ref, if provided, must be [] and is used as a base for Parents
345
346     $p_ref //= [];
347     die if @$p_ref;
348
349     my ($h,$m) = get_commit $objid;
350
351     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
352     my (@ph) = $h =~ m/^parent (\w+)$/mg;
353
354     my $r = {
355         CommitId => $objid,
356         Hdr => $h,
357         Msg => $m,
358         Tree => $t,
359         Parents => $p_ref,
360     };
361
362     foreach my $ph (@ph) {
363         push @$p_ref, {
364             Ix => scalar @$p_ref,
365             CommitId => $ph,
366         };
367     }
368
369     return $r;
370 }    
371
372 sub classify ($) {
373     my ($objid) = @_;
374
375     my @p;
376     my $r = parsecommit($objid, \@p);
377     my $t = $r->{Tree};
378
379     foreach my $p (@p) {
380         $p->{Differs} = (get_differs $p->{CommitId}, $t),
381     }
382
383     printdebug "classify $objid \$t=$t \@p",
384         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
385         "\n";
386
387     my $classify = sub {
388         my ($type, @rest) = @_;
389         $r = { %$r, Type => $type, @rest };
390         if ($debuglevel) {
391             printdebug " = $type ".(dd $r)."\n";
392         }
393         return $r;
394     };
395     my $unknown = sub {
396         my ($why) = @_;
397         $r = { %$r, Type => qw(Unknown), Why => $why };
398         printdebug " ** Unknown\n";
399         return $r;
400     };
401
402     my $claims_to_be_breakwater =
403         $r->{Msg} =~ m{^\[git-debrebase breakwater.*\]$}m;
404
405     if (@p == 1) {
406         if ($claims_to_be_breakwater) {
407             return $unknown->("single-parent git-debrebase breakwater \`merge'");
408         }
409         my $d = $r->{Parents}[0]{Differs};
410         if ($d == D_PAT_ADD) {
411             return $classify->(qw(AddPatches));
412         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
413             return $unknown->("edits debian/patches");
414         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
415             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
416             if ($ty eq 'tree') {
417                 if ($d == D_DEB_CLOG) {
418                     return $classify->(qw(Changelog));
419                 } else {
420                     return $classify->(qw(Packaging));
421                 }
422             } elsif ($ty eq 'missing') {
423                 return $classify->(qw(BreakwaterStart));
424             } else {
425                 return $unknown->("parent's debian is not a directory");
426             }
427         } elsif ($d == D_UPS) {
428             return $classify->(qw(Upstream));
429         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
430             return $classify->(qw(Mixed));
431         } elsif ($d == 0) {
432             return $unknown->("no changes");
433         } else {
434             confess "internal error $objid ?";
435         }
436     }
437     if (!@p) {
438         return $unknown->("origin commit");
439     }
440
441     my @identical = grep { !$_->{Differs} } @p;
442     if (@p == 2 && @identical == 1 && !$claims_to_be_breakwater
443         # breakwater merges can look like pseudomerges, if they are
444         # "declare" commits (ie, there are no upstream changes)
445        ) {
446         my @overwritten = grep { $_->{Differs} } @p;
447         confess "internal error $objid ?" unless @overwritten==1;
448         return $classify->(qw(Pseudomerge),
449                            Overwritten => [ $overwritten[0] ],
450                            Contributor => $identical[0]);
451     }
452     if (@p == 2 && @identical == 2) {
453         my @bytime = nsort_by {
454             my ($ph,$pm) = get_commit $_->{CommitId};
455             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
456             $1;
457         } @p;
458         return $classify->(qw(Pseudomerge),
459                            SubType => qw(Ambiguous),
460                            Overwritten => [ $bytime[0] ],
461                            Contributor => $bytime[1]);
462     }
463     foreach my $p (@p) {
464         my ($p_h, $p_m) = get_commit $p->{CommitId};
465         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
466         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
467     }
468     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
469     my $m2 = $r->{Msg};
470     if (!(grep { !$_->{IsOrigin} } @p) and
471         (@orig_ps >= @p - 1) and
472         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
473         $r->{NewMsg} = $m2;
474         return $classify->(qw(DgitImportUnpatched),
475                            OrigParents => \@orig_ps);
476     }
477
478     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
479     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
480
481     # How to decide about l/r ordering of breakwater merges ?  git
482     # --topo-order prefers to expand 2nd parent first.  There's
483     # already an easy rune to look for debian/ history anyway (git log
484     # debian/) so debian breakwater branch should be 1st parent; that
485     # way also there's also an easy rune to look for the upstream
486     # patches (--topo-order).
487
488     # The above tells us which way *we* will generate them.  But we
489     # might encounter ad-hoc breakwater merges generated manually,
490     # which might be the other way around.  In principle, in some odd
491     # situations, a breakwater merge might have two identical parents.
492     # In that case we guess which way round it is (ie, which parent
493     # has the upstream history).  The order of the 2-iteration loop
494     # controls which guess we make.
495
496     foreach my $prevbrw (qw(0 1)) {
497         if (@p == 2 &&
498             !$haspatches &&
499             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
500             !($p[!$prevbrw]{Differs} & ~DS_DEB) && # no non-debian changess
501             !($p[$prevbrw]{Differs} & ~D_UPS)) { # no non-upstream changes
502             return $classify->(qw(BreakwaterUpstreamMerge),
503                                OrigParents => [ $p[!$prevbrw] ]);
504         }
505     }
506
507     # multi-orig upstreams are represented with a breakwater merge
508     # from a single upstream commit which combines the orig tarballs
509
510     return $unknown->("complex merge");
511 }
512
513 sub breakwater_of ($) {
514     my ($head) = @_; # must be laundered
515     my $breakwater;
516     my $unclean = sub {
517         my ($why) = @_;
518         fail "branch needs laundering (run git-debrebase): $why";
519     };
520     for (;;) {
521         my $cl = classify $head;
522         my $ty = $cl->{Type};
523         if ($ty eq 'Packaging' or
524             $ty eq 'Changelog') {
525             $breakwater //= $head;
526         } elsif ($ty eq 'BreakwaterUpstreamMerge' or
527                  $ty eq 'BreakwaterStart') {
528             $breakwater //= $head;
529             last;
530         } elsif ($ty eq 'Upstream') {
531             $unclean->("packaging change ($breakwater)".
532                        " follows upstream change (eg $head)")
533                 if defined $breakwater;
534         } elsif ($ty eq 'Mixed') {
535             $unclean->('found mixed upstream/packaging commit ($head)');
536         } elsif ($ty eq 'Pseudomerge' or
537                  $ty eq 'AddPatches') {
538             $unclean->("found interchange conversion commit ($ty, $head)");
539         } elsif ($ty eq 'DgitImportUnpatched') {
540             $unclean->("found dgit dsc import ($head)");
541         } else {
542             fail "found unprocessable commit, cannot cope: $head; $cl->{Why}";
543         }
544         $head = $cl->{Parents}[0]{CommitId};
545     }
546     return $breakwater;
547 }
548
549 sub walk ($;$$);
550 sub walk ($;$$) {
551     my ($input,
552         $nogenerate,$report) = @_;
553     # => ($tip, $breakwater_tip, $last_upstream_merge_in_breakwater)
554     # (or nothing, if $nogenerate)
555
556     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
557
558     # go through commits backwards
559     # we generate two lists of commits to apply:
560     # breakwater branch and upstream patches
561     my (@brw_cl, @upp_cl, @processed);
562     my %found;
563     my $upp_limit;
564     my @pseudomerges;
565
566     my $cl;
567     my $xmsg = sub {
568         my ($prose, $info) = @_;
569         my $ms = $cl->{Msg};
570         chomp $ms;
571         $info //= '';
572         $ms .= "\n\n[git-debrebase$info: $prose]\n";
573         return (Msg => $ms);
574     };
575     my $rewrite_from_here = sub {
576         my $sp_cl = { SpecialMethod => 'StartRewrite' };
577         push @brw_cl, $sp_cl;
578         push @processed, $sp_cl;
579     };
580     my $cur = $input;
581
582     my $prdelim = "";
583     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
584
585     my $prline = sub {
586         return unless $report;
587         print $report $prdelim, @_;
588         $prdelim = "\n";
589     };
590
591     my $bomb = sub { # usage: return $bomb->();
592         print $report " Unprocessable" if $report;
593         $prprdelim->();
594         if ($nogenerate) {
595             return (undef,undef);
596         }
597         die "commit $cur: Cannot cope with this commit (d.".
598             (join ' ', map { sprintf "%#x", $_->{Differs} }
599              @{ $cl->{Parents} }). ")";
600     };
601
602     my $build;
603     my $breakwater;
604
605     my $build_start = sub {
606         my ($msg, $parent) = @_;
607         $prline->(" $msg");
608         $build = $parent;
609         no warnings qw(exiting); last;
610     };
611
612     my $last_upstream_update;
613
614     for (;;) {
615         $cl = classify $cur;
616         my $ty = $cl->{Type};
617         my $st = $cl->{SubType};
618         $prline->("$cl->{CommitId} $cl->{Type}");
619         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
620         push @processed, $cl;
621         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
622         if ($ty eq 'AddPatches') {
623             $cur = $p0;
624             $rewrite_from_here->();
625             next;
626         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
627             push @brw_cl, $cl;
628             $cur = $p0;
629             next;
630         } elsif ($ty eq 'BreakwaterStart') {
631             $last_upstream_update = $cur;
632             $build_start->('FirstPackaging', $cur);
633         } elsif ($ty eq 'Upstream') {
634             push @upp_cl, $cl;
635             $cur = $p0;
636             next;
637         } elsif ($ty eq 'Mixed') {
638             my $queue = sub {
639                 my ($q, $wh) = @_;
640                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
641                 push @$q, $cls;
642             };
643             $queue->(\@brw_cl, "debian");
644             $queue->(\@upp_cl, "upstream");
645             $rewrite_from_here->();
646             $cur = $p0;
647             next;
648         } elsif ($ty eq 'Pseudomerge') {
649             my $contrib = $cl->{Contributor}{CommitId};
650             print $report " Contributor=$contrib" if $report;
651             push @pseudomerges, $cl;
652             $rewrite_from_here->();
653             $cur = $contrib;
654             next;
655         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
656             $last_upstream_update = $cur;
657             $build_start->("PreviousBreakwater", $cur);
658         } elsif ($ty eq 'DgitImportUnpatched') {
659             my $pm = $pseudomerges[-1];
660             if (defined $pm) {
661                 # To an extent, this is heuristic.  Imports don't have
662                 # a useful history of the debian/ branch.  We assume
663                 # that the first pseudomerge after an import has a
664                 # useful history of debian/, and ignore the histories
665                 # from later pseudomerges.  Often the first pseudomerge
666                 # will be the dgit import of the upload to the actual
667                 # suite intended by the non-dgit NMUer, and later
668                 # pseudomerges may represent in-archive copies.
669                 my $ovwrs = $pm->{Overwritten};
670                 printf $report " PM=%s \@Overwr:%d",
671                     $pm->{CommitId}, (scalar @$ovwrs)
672                     if $report;
673                 if (@$ovwrs != 1) {
674                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
675                     return $bomb->();
676                 }
677                 my $ovwr = $ovwrs->[0]{CommitId};
678                 printf $report " Overwr=%s", $ovwr if $report;
679                 # This import has a tree which is just like a
680                 # breakwater tree, but it has the wrong history.  It
681                 # ought to have the previous breakwater (which the
682                 # pseudomerge overwrote) as an ancestor.  That will
683                 # make the history of the debian/ files correct.  As
684                 # for the upstream version: either it's the same as
685                 # was ovewritten (ie, same as the previous
686                 # breakwater), in which case that history is precisely
687                 # right; or, otherwise, it was a non-gitish upload of a
688                 # new upstream version.  We can tell these apart by
689                 # looking at the tree of the supposed upstream.
690                 push @brw_cl, {
691                     %$cl,
692                     SpecialMethod => 'DgitImportDebianUpdate',
693                     $xmsg->("convert dgit import: debian changes")
694                 }, {
695                     %$cl,
696                     SpecialMethod => 'DgitImportUpstreamUpdate',
697                     $xmsg->("convert dgit import: upstream update",
698                             " breakwater")
699                 };
700                 $prline->(" Import");
701                 $rewrite_from_here->();
702                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
703                 $cur = $ovwr;
704                 next;
705             } else {
706                 # Everything is from this import.  This kind of import
707                 # is already in valid breakwater format, with the
708                 # patches as commits.
709                 printf $report " NoPM" if $report;
710                 # last thing we processed will have been the first patch,
711                 # if there is one; which is fine, so no need to rewrite
712                 # on account of this import
713                 $build_start->("ImportOrigin", $cur);
714             }
715             die "$ty ?";
716         } else {
717             printdebug "*** WALK BOMB unrecognised\n";
718             return $bomb->();
719         }
720     }
721     $prprdelim->();
722
723     printdebug "*** WALK prep done cur=$cur".
724         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
725
726     return if $nogenerate;
727
728     # Now we build it back up again
729
730     fresh_workarea();
731
732     my $rewriting = 0;
733
734     my $read_tree_debian = sub {
735         my ($treeish) = @_;
736         read_tree_subdir 'debian', "$treeish:debian";
737         rm_subdir_cached 'debian/patches';
738     };
739     my $read_tree_upstream = sub {
740         my ($treeish) = @_;
741         runcmd @git, qw(read-tree), $treeish;
742         $read_tree_debian->($build);
743     };
744
745     $#upp_cl = $upp_limit if defined $upp_limit;
746  
747     my $committer_authline = calculate_committer_authline();
748
749     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
750
751     confess "internal error" unless $build eq (pop @processed)->{CommitId};
752
753     in_workarea sub {
754         mkdir $rd or $!==EEXIST or die $!;
755         my $current_method;
756         runcmd @git, qw(read-tree), $build;
757         foreach my $cl (qw(Debian), (reverse @brw_cl),
758                         { SpecialMethod => 'RecordBreakwaterTip' },
759                         qw(Upstream), (reverse @upp_cl)) {
760             if (!ref $cl) {
761                 $current_method = $cl;
762                 next;
763             }
764             my $method = $cl->{SpecialMethod} // $current_method;
765             my @parents = ($build);
766             my $cltree = $cl->{CommitId};
767             printdebug "WALK BUILD ".($cltree//'undef').
768                 " $method (rewriting=$rewriting)\n";
769             if ($method eq 'Debian') {
770                 $read_tree_debian->($cltree);
771             } elsif ($method eq 'Upstream') {
772                 $read_tree_upstream->($cltree);
773             } elsif ($method eq 'StartRewrite') {
774                 $rewriting = 1;
775                 next;
776             } elsif ($method eq 'RecordBreakwaterTip') {
777                 $breakwater = $build;
778                 next;
779             } elsif ($method eq 'DgitImportDebianUpdate') {
780                 $read_tree_debian->($cltree);
781             } elsif ($method eq 'DgitImportUpstreamUpdate') {
782                 confess unless $rewriting;
783                 my $differs = (get_differs $build, $cltree);
784                 next unless $differs & D_UPS;
785                 $read_tree_upstream->($cltree);
786                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
787             } else {
788                 confess "$method ?";
789             }
790             if (!$rewriting) {
791                 my $procd = (pop @processed) // 'UNDEF';
792                 if ($cl ne $procd) {
793                     $rewriting = 1;
794                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
795                 }
796             }
797             my $newtree = cmdoutput @git, qw(write-tree);
798             my $ch = $cl->{Hdr};
799             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
800             $ch =~ s{^parent .*\n}{}mg;
801             $ch =~ s{(?=^author)}{
802                 join '', map { "parent $_\n" } @parents
803             }me or confess "$ch ?";
804             if ($rewriting) {
805                 $ch =~ s{^committer .*$}{$committer_authline}m
806                     or confess "$ch ?";
807             }
808             my $cf = "$rd/m$rewriting";
809             open CD, ">", $cf or die $!;
810             print CD $ch, "\n", $cl->{Msg} or die $!;
811             close CD or die $!;
812             my @cmd = (@git, qw(hash-object));
813             push @cmd, qw(-w) if $rewriting;
814             push @cmd, qw(-t commit), $cf;
815             my $newcommit = cmdoutput @cmd;
816             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
817             $build = $newcommit;
818             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
819                 $last_upstream_update = $cur;
820             }
821         }
822     };
823
824     my $final_check = get_differs $build, $input;
825     die sprintf "internal error %#x %s %s", $final_check, $build, $input
826         if $final_check & ~D_PAT_ADD;
827
828     my @r = ($build, $breakwater, $last_upstream_update);
829     printdebug "*** WALK RETURN @r\n";
830     return @r
831 }
832
833 sub get_head () {
834     git_check_unmodified();
835     return git_rev_parse qw(HEAD);
836 }
837
838 sub update_head ($$$) {
839     my ($old, $new, $mrest) = @_;
840     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
841 }
842
843 sub update_head_checkout ($$$) {
844     my ($old, $new, $mrest) = @_;
845     update_head $old, $new, $mrest;
846     runcmd @git, qw(reset --hard);
847 }
848
849 sub update_head_postlaunder ($$$) {
850     my ($old, $tip, $reflogmsg) = @_;
851     return if $tip eq $old;
852     print "git-debrebase: laundered (head was $old)\n";
853     update_head $old, $tip, $reflogmsg;
854     # no tree changes except debian/patches
855     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
856 }
857
858 sub cmd_launder () {
859     badusage "no arguments to launder allowed" if @ARGV;
860     my $old = get_head();
861     my ($tip,$breakwater,$last_upstream_merge) = walk $old;
862     update_head_postlaunder $old, $tip, 'launder';
863     printf "# breakwater tip\n%s\n", $breakwater;
864     printf "# working tip\n%s\n", $tip;
865     printf "# last upstream merge\n%s\n", $last_upstream_merge;
866 }
867
868 sub defaultcmd_rebase () {
869     my $old = get_head();
870     my ($status, $message) = record_ffq_prev();
871     if ($status eq 'written' || $status eq 'exists') {
872     } else {
873         fproblem $status, "could not record ffq-prev: $message";
874         fproblems_maybe_bail();
875     }
876     my ($tip,$breakwater) = walk $old;
877     update_head_postlaunder $old, $tip, 'launder for rebase';
878     runcmd @git, qw(rebase), @ARGV, $breakwater;
879 }
880
881 sub cmd_analyse () {
882     die if ($ARGV[0]//'') =~ m/^-/;
883     badusage "too many arguments to analyse" if @ARGV>1;
884     my ($old) = @ARGV;
885     if (defined $old) {
886         $old = git_rev_parse $old;
887     } else {
888         $old = git_rev_parse 'HEAD';
889     }
890     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
891     STDOUT->error and die $!;
892 }
893
894 sub ffq_prev_branchinfo () {
895     # => ('status', "message", [$current, $ffq_prev])
896     # 'status' may be
897     #    branch         message is undef
898     #    weird-symref   } no $current,
899     #    notbranch      }  no $ffq_prev
900     my $current = git_get_symref();
901     return ('detached', 'detached HEAD') unless defined $current;
902     return ('weird-symref', 'HEAD symref is not to refs/')
903         unless $current =~ m{^refs/};
904     my $ffq_prev = "refs/$ffq_refprefix/$'";
905     return ('branch', undef, $current, $ffq_prev);
906 }
907
908 sub record_ffq_prev () {
909     # => ('status', "message")
910     # 'status' may be
911     #    written          message is undef
912     #    exists
913     #    detached
914     #    weird-symref
915     #    notbranch
916     # if not ff from some branch we should be ff from, is an fproblem
917     # if "written", will have printed something about that to stdout,
918     #   and also some messages about ff checks
919     my ($status, $message, $current, $ffq_prev) = ffq_prev_branchinfo();
920     return ($status, $message) unless $status eq 'branch';
921
922     my $currentval = get_head();
923
924     my $exists = git_get_ref $ffq_prev;
925     return ('exists',"$ffq_prev already exists") if $exists;
926
927     return ('not-branch', 'HEAD symref is not to refs/heads/')
928         unless $current =~ m{^refs/heads/};
929     my $branch = $';
930
931     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
932     my %checked;
933
934     my $check = sub {
935         my ($lrref, $desc) = @_;
936         my $invert;
937         for my $chk (@check_specs) {
938             my $glob = $chk;
939             $invert = $glob =~ s{^[^!]}{};
940             last if fnmatch $glob, $lrref;
941         }
942         return if $invert;
943         my $lrval = git_get_ref $lrref;
944         return unless defined $lrval;
945
946         if (is_fast_fwd $lrval, $currentval) {
947             print "OK, you are ahead of $lrref\n" or die $!;
948             $checked{$lrref} = 1;
949         } if (is_fast_fwd $currentval, $lrval) {
950             $checked{$lrref} = -1;
951             fproblem 'behind', "you are behind $lrref, divergence risk";
952         } else {
953             $checked{$lrref} = -1;
954             fproblem 'diverged', "you have diverged from $lrref";
955         }
956     };
957
958     my $merge = cfg "branch.$branch.merge",1;
959     if (defined $merge && $merge =~ m{^refs/heads/}) {
960         my $rhs = $';
961         my $check_remote = sub {
962             my ($remote, $desc) = (@_);
963             return unless defined $remote;
964             $check->("refs/remotes/$remote/$rhs", $desc);
965         };
966         $check_remote->((cfg "branch.$branch.remote",1),
967                         'remote fetch/merge branch');
968         $check_remote->((cfg "branch.$branch.pushRemote",1) //
969                         (cfg "branch.$branch.pushDefault",1),
970                         'remote push branch');
971     }
972     if ($branch =~ m{^dgit/}) {
973         $check->("remotes/dgit/$branch", 'remote dgit branch');
974     } elsif ($branch =~ m{^master$}) {
975         $check->("remotes/dgit/dgit/sid", 'remote dgit branch for sid');
976     }
977
978     fproblems_maybe_bail();
979     runcmd @git, qw(update-ref -m), "record current head for preservation",
980         $ffq_prev, $currentval, $git_null_obj;
981     print "Recorded current head for preservation\n" or die $!;
982     return ('written', undef);
983 }
984
985 sub cmd_new_upstream_v0 () {
986     # automatically and unconditionally launders before rebasing
987     # if rebase --abort is used, laundering has still been done
988
989     my %pieces;
990
991     badusage "need NEW-VERSION UPS-COMMITTISH" unless @ARGV >= 2;
992
993     # parse args - low commitment
994     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
995     my $new_upstream_version = $new_version->version();
996
997     my $new_upstream = git_rev_parse shift @ARGV;
998
999     my $piece = sub {
1000         my ($n, @x) = @_; # may be ''
1001         my $pc = $pieces{$n} //= {
1002             Name => $n,
1003             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1004         };
1005         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1006         $pc;
1007     };
1008
1009     my @newpieces;
1010     my $newpiece = sub {
1011         my ($n, @x) = @_; # may be ''
1012         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1013         push @newpieces, $pc;
1014     };
1015
1016     $newpiece->('',
1017         OldIx => 0,
1018         New => $new_upstream,
1019     );
1020     while (@ARGV && $ARGV[0] !~ m{^-}) {
1021         my $n = shift @ARGV;
1022
1023         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1024             unless @ARGV && $ARGV[0] !~ m{^-};
1025
1026         my $c = git_rev_parse shift @ARGV;
1027         die unless $n =~ m/^$extra_orig_namepart_re$/;
1028         $newpiece->($n, New => $c);
1029     }
1030
1031     # now we need to investigate the branch this generates the
1032     # laundered version but we don't switch to it yet
1033     my $old_head = get_head();
1034     my ($old_laundered_tip,$old_bw,$old_upstream_update) = walk $old_head;
1035
1036     my $old_bw_cl = classify $old_bw;
1037     my $old_upstream_update_cl = classify $old_upstream_update;
1038     confess unless $old_upstream_update_cl->{OrigParents};
1039     my $old_upstream = parsecommit
1040         $old_upstream_update_cl->{OrigParents}[0]{CommitId};
1041
1042     $piece->('', Old => $old_upstream->{CommitId});
1043
1044     if ($old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1045         if ($old_upstream->{Msg} =~
1046  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
1047            ) {
1048             my @oldpieces = ('', split / /, $1);
1049             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
1050             foreach my $i (0..$#oldpieces) {
1051                 my $n = $oldpieces[$i];
1052                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
1053             }
1054         } else {
1055             fproblem 'upstream-confusing',
1056                 "previous upstream $old_upstream->{CommitId} is from".
1057                " git-debrebase but not an \`upstream-combine' commit";
1058         }
1059     }
1060
1061     foreach my $pc (values %pieces) {
1062         if (!$pc->{Old}) {
1063             fproblem 'upstream-new-piece',
1064                 "introducing upstream piece \`$pc->{Name}'";
1065         } elsif (!$pc->{New}) {
1066             fproblem 'upstream-rm-piece',
1067                 "dropping upstream piece \`$pc->{Name}'";
1068         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1069             fproblem 'upstream-not-ff',
1070                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1071         }
1072     }
1073
1074     printdebug "%pieces = ", (dd \%pieces), "\n";
1075     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1076
1077     fproblems_maybe_bail();
1078
1079     my $new_bw;
1080
1081     fresh_workarea();
1082     in_workarea sub {
1083         my @upstream_merge_parents;
1084
1085         if (!any_fproblems()) {
1086             push @upstream_merge_parents, $old_upstream->{CommitId};
1087         }
1088
1089         foreach my $pc (@newpieces) { # always has '' first
1090             if ($pc->{Name}) {
1091                 read_tree_subdir $pc->{Name}, $pc->{New};
1092             } else {
1093                 runcmd @git, qw(read-tree), $pc->{New};
1094             }
1095             push @upstream_merge_parents, $pc->{New};
1096         }
1097
1098         # index now contains the new upstream
1099
1100         if (@newpieces > 1) {
1101             # need to make the upstream subtree merge commit
1102             $new_upstream = make_commit \@upstream_merge_parents,
1103                 [ "Combine upstreams for $new_upstream_version",
1104  ("[git-debrebase upstream-combine . ".
1105  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1106  ": new upstream]"),
1107                 ];
1108         }
1109
1110         # $new_upstream is either the single upstream commit, or the
1111         # combined commit we just made.  Either way it will be the
1112         # "upstream" parent of the breakwater special merge.
1113
1114         read_tree_subdir 'debian', "$old_bw:debian";
1115
1116         # index now contains the breakwater merge contents
1117         $new_bw = make_commit [ $old_bw, $new_upstream ],
1118             [ "Update to upstream $new_upstream_version",
1119  "[git-debrebase breakwater: new upstream $new_upstream_version, merge]",
1120             ];
1121
1122         # Now we have to add a changelog stanza so the Debian version
1123         # is right.
1124         die if unlink "debian";
1125         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1126         unlink "debian/changelog" or $!==ENOENT or die $!;
1127         mkdir "debian" or die $!;
1128         open CN, ">", "debian/changelog" or die $!;
1129         my $oldclog = git_cat_file ":debian/changelog";
1130         $oldclog =~ m/^($package_re) \(\S+\) / or
1131             fail "cannot parse old changelog to get package name";
1132         my $p = $1;
1133         print CN <<END, $oldclog or die $!;
1134 $p ($new_version) UNRELEASED; urgency=medium
1135
1136   * Update to new upstream version $new_upstream_version.
1137
1138  -- 
1139
1140 END
1141         close CN or die $!;
1142         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1143
1144         # Now we have the final new breakwater branch in the index
1145         $new_bw = make_commit [ $new_bw ],
1146             [ "Update changelog for new upstream $new_upstream_version",
1147               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1148             ];
1149     };
1150
1151     # we have constructed the new breakwater. we now need to commit to
1152     # the laundering output, because git-rebase can't easily be made
1153     # to make a replay list which is based on some other branch
1154
1155     update_head_postlaunder $old_head, $old_laundered_tip,
1156         'launder for new upstream';
1157
1158     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1159     runcmd @cmd;
1160     # now it's for the user to sort out
1161 }
1162
1163 sub cmd_record_ffq_prev () {
1164     badusage "no arguments allowed" if @ARGV;
1165     my ($status, $msg) = record_ffq_prev();
1166     if ($status eq 'exists' && $opt_noop_ok) {
1167         print "Previous head already recorded\n" or die $!;
1168     } elsif ($status eq 'written') {
1169     } else {
1170         fail "Could not preserve: $msg";
1171     }
1172 }
1173
1174 sub cmd_breakwater () {
1175     badusage "no arguments allowed" if @ARGV;
1176     my $bw = breakwater_of git_rev_parse 'HEAD';
1177     print "$bw\n" or die $!;
1178 }
1179
1180 sub cmd_stitch () {
1181     my $prose = '';
1182     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1183     badusage "no arguments allowed" if @ARGV;
1184     my ($status, $message, $current, $ffq_prev) = ffq_prev_branchinfo();
1185     if ($status ne 'branch') {
1186         fproblem $status, "could not check ffq-prev: $message";
1187         fproblems_maybe_bail();
1188     }
1189     my $prev = $ffq_prev && git_get_ref $ffq_prev;
1190     if (!$prev) {
1191         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1192     }
1193     fresh_workarea();
1194     my $old_head = get_head();
1195     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1196         'Declare fast forward / record previous work',
1197         "[git-debrebase pseudomerge: stitch$prose]",
1198     ];
1199     my @upd_cmd = (@git, qw(update-ref --stdin));
1200     debugcmd '>|', @upd_cmd;
1201     open U, "|-", @upd_cmd or die $!;
1202     my $u = <<END;
1203 update HEAD $new_head $old_head
1204 delete $ffq_prev $prev
1205 END
1206     printdebug ">= ", $_, "\n" foreach split /\n/, $u;
1207     print U $u;
1208     printdebug ">\$\n";
1209     close U or failedcmd @upd_cmd;
1210 }
1211
1212 sub cmd_convert_from_gbp () {
1213     badusage "needs 1 optional argument, the upstream git rev"
1214         unless @ARGV<=1;
1215     my ($upstream_spec) = @ARGV;
1216     $upstream_spec //= 'refs/heads/upstream';
1217     my $upstream = git_rev_parse $upstream_spec;
1218     my $old_head = get_head();
1219
1220     my $upsdiff = get_differs $upstream, $old_head;
1221     if ($upsdiff & D_UPS) {
1222         runcmd @git, qw(--no-pager diff),
1223             $upstream, $old_head,
1224             qw( -- :!/debian :/);
1225  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1226     }
1227
1228     if (!is_fast_fwd $upstream, $old_head) {
1229         fproblem 'upstream-not-ancestor',
1230             "upstream ($upstream) is not an ancestor of HEAD";
1231     } else {
1232         my $wrong = cmdoutput
1233             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1234              qw(-- :/ :!/debian));
1235         if (length $wrong) {
1236             fproblem 'unexpected-upstream-changes',
1237                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1238             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1239         }
1240     }
1241
1242     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1243         fproblem 'upstream-has-debian',
1244             "upstream ($upstream) contains debian/ directory";
1245     }
1246
1247     fproblems_maybe_bail();
1248
1249     my $work;
1250
1251     fresh_workarea();
1252     in_workarea sub {
1253         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1254         # make a branch out of the patch queue - we'll want this in a mo
1255         runcmd qw(gbp pq import);
1256         # strip the patches out
1257         runcmd @git, qw(checkout -q gdr-internal~0);
1258         rm_subdir_cached 'debian/patches';
1259         $work = make_commit ['HEAD'], [
1260  'git-debrebase convert-from-gbp: drop patches from tree',
1261  'Delete debian/patches, as part of converting to git-debrebase format.',
1262  '[git-debrebase convert-from-gbp: drop patches from tree]'
1263                               ];
1264         # make the breakwater pseudomerge
1265         # the tree is already exactly right
1266         $work = make_commit [$work, $upstream], [
1267  'git-debrebase import: declare upstream',
1268  'First breakwater merge.',
1269  '[git-debrebase breakwater: declare upstream]'
1270                               ];
1271
1272         # rebase the patch queue onto the new breakwater
1273         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1274         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1275         $work = git_rev_parse 'HEAD';
1276     };
1277
1278     update_head_checkout $old_head, $work, 'convert-from-gbp';
1279 }
1280
1281 sub cmd_convert_to_gbp () {
1282     badusage "no arguments allowed" if @ARGV;
1283     my $head = get_head();
1284     my $ffq = (ffq_prev_branchinfo())[3];
1285     my $bw = breakwater_of $head;
1286     fresh_workarea();
1287     my $out;
1288     in_workarea sub {
1289         runcmd @git, qw(checkout -q -b bw), $bw;
1290         runcmd @git, qw(checkout -q -b patch-queue/bw), $head;
1291         runcmd qw(gbp pq export);
1292         runcmd @git, qw(add debian/patches);
1293         $out = make_commit ['HEAD'], [
1294             'Commit patch queue (converted from git-debrebase format)',
1295             '[git-debrebase convert-to-gbp: commit patches]',
1296         ];
1297     };
1298     if (defined $ffq) {
1299         runcmd @git, qw(update-ref -m),
1300             "debrebase: converting corresponding main branch to gbp format",
1301             $ffq, $git_null_obj;
1302     }
1303     update_head_checkout $head, $out, "convert to gbp (v0)";
1304     print <<END or die $!;
1305 git-debrebase: converted to git-buildpackage branch format
1306 git-debrebase: WARNING: do not now run "git-debrebase" any more
1307 git-debrebase: WARNING: doing so would drop all upstream patches!
1308 END
1309 }
1310
1311 sub cmd_downstream_rebase_launder_v0 () {
1312     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1313     my ($base) = @ARGV;
1314     $base = git_rev_parse $base;
1315     my $old_head = get_head();
1316     my $current = $old_head;
1317     my $topmost_keep;
1318     for (;;) {
1319         if ($current eq $base) {
1320             $topmost_keep //= $current;
1321             print " $current BASE stop\n";
1322             last;
1323         }
1324         my $cl = classify $current;
1325         print " $current $cl->{Type}";
1326         my $keep = 0;
1327         my $p0 = $cl->{Parents}[0]{CommitId};
1328         my $next;
1329         if ($cl->{Type} eq 'Pseudomerge') {
1330             print " ^".($cl->{Contributor}{Ix}+1);
1331             $next = $cl->{Contributor}{CommitId};
1332         } elsif ($cl->{Type} eq 'AddPatches' or
1333                  $cl->{Type} eq 'Changelog') {
1334             print " strip";
1335             $next = $p0;
1336         } else {
1337             print " keep";
1338             $next = $p0;
1339             $keep = 1;
1340         }
1341         print "\n";
1342         if ($keep) {
1343             $topmost_keep //= $current;
1344         } else {
1345             die "to-be stripped changes not on top of the branch\n"
1346                 if $topmost_keep;
1347         }
1348         $current = $next;
1349     }
1350     if ($topmost_keep eq $old_head) {
1351         print "unchanged\n";
1352     } else {
1353         print "updating to $topmost_keep\n";
1354         update_head_checkout
1355             $old_head, $topmost_keep,
1356             'downstream-rebase-launder-v0';
1357     }
1358 }
1359
1360 GetOptions("D+" => \$debuglevel,
1361            'noop-ok', => \$opt_noop_ok,
1362            'f=s' => \@fproblem_force_opts,
1363            'force!') or die badusage "bad options\n";
1364 initdebug('git-debrebase ');
1365 enabledebug if $debuglevel;
1366
1367 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1368 chdir $toplevel or die "chdir $toplevel: $!";
1369
1370 $rd = fresh_playground "$playprefix/misc";
1371
1372 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1373     defaultcmd_rebase();
1374 } else {
1375     my $cmd = shift @ARGV;
1376     my $cmdfn = $cmd;
1377     $cmdfn =~ y/-/_/;
1378     $cmdfn = ${*::}{"cmd_$cmdfn"};
1379
1380     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1381     $cmdfn->();
1382 }