git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Memoize;
 108 use Carp;
 109 use POSIX;
 110 use Data::Dumper;
 111 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 112
 113 use Debian::Dgit qw(:DEFAULT :playground);
 114
 115 sub badusage ($) {
 116     my ($m) = @_;
 117     die "bad usage: $m\n";
 118 }
 119
 120 sub cfg ($) {
 121     my ($k) = @_;
 122     $/ = "\0";
 123     my @cmd = qw(git config -z);
 124     push @cmd, qw(--get-all) if wantarray;
 125     push @cmd, $k;
 126     my $out = cmdoutput @cmd;
 127     return split /\0/, $out;
 128 }
 129
 130 memoize('cfg');
 131
 132 sub get_commit ($) {
 133     my ($objid) = @_;
 134     my $data = git_cat_file $objid, 'commit';
 135     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 136     return ($`,$');
 137 }
 138
 139 sub D_UPS ()      { 0x02; } # upstream files
 140 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 141 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 142 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 143 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 144 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 145
 146 our $playprefix = 'debrebase';
 147 our $rd;
 148 our $workarea;
 149
 150 our @git = qw(git);
 151
 152 sub in_workarea ($) {
 153     my ($sub) = @_;
 154     changedir $workarea;
 155     my $r = eval { $sub->(); };
 156     changedir $maindir;
 157 }
 158
 159 sub fresh_workarea () {
 160     $workarea = fresh_playground "$playprefix/work";
 161     in_workarea sub { playtree_setup };
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/(?:^|\.)series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 218                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 # classify returns an info hash like this
 250 #   CommitId => $objid
 251 #   Hdr => # commit headers, including 1 final newline
 252 #   Msg => # commit message (so one newline is dropped)
 253 #   Tree => $treeobjid
 254 #   Type => (see below)
 255 #   Parents = [ {
 256 #       Ix => $index # ie 0, 1, 2, ...
 257 #       CommitId
 258 #       Differs => return value from get_differs
 259 #       IsOrigin
 260 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 261 #     } ...]
 262 #   NewMsg => # commit message, but with any [dgit import ...] edited
 263 #             # to say "[was: ...]"
 264 #
 265 # Types:
 266 #   Packaging
 267 #   Changelog
 268 #   Upstream
 269 #   AddPatches
 270 #   Mixed
 271 #   Unknown
 272 #
 273 #   Pseudomerge
 274 #     has additional entres in classification result
 275 #       Overwritten = [ subset of Parents ]
 276 #       Contributor = $the_remaining_Parent
 277 #
 278 #   DgitImportUnpatched
 279 #     has additional entry in classification result
 280 #       OrigParents = [ subset of Parents ]
 281 #
 282 #   BreakwaterUpstreamMerge
 283 #     has additional entry in classification result
 284 #       OrigParents = [ subset of Parents ]
 285
 286 sub classify ($) {
 287     my ($objid) = @_;
 288
 289     my ($h,$m) = get_commit $objid;
 290
 291     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 292     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 293     my @p;
 294
 295     my $r = {
 296         CommitId => $objid,
 297         Hdr => $h,
 298         Msg => $m,
 299         Tree => $t,
 300         Parents => \@p,
 301     };
 302
 303     foreach my $ph (@ph) {
 304         push @p, {
 305             Ix => $#p,
 306             CommitId => $ph,
 307             Differs => (get_differs $t, $ph),
 308         };
 309     }
 310
 311     printdebug "classify $objid \$t=$t \@p",
 312         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 313         "\n";
 314
 315     my $classify = sub {
 316         my ($type, @rest) = @_;
 317         $r = { %$r, Type => $type, @rest };
 318         if ($debuglevel) {
 319             my $dd = new Data::Dumper [ $r ];
 320             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 321             printdebug " = $type ".(Dump $dd)."\n";
 322         }
 323         return $r;
 324     };
 325     my $unknown = sub {
 326         my ($why) = @_;
 327         $r = { %$r, Type => qw(Unknown) };
 328         printdebug " ** Unknown\n";
 329         return $r;
 330     };
 331
 332     if (@p == 1) {
 333         my $d = $r->{Parents}[0]{Differs};
 334         if ($d == D_PAT_ADD) {
 335             return $classify->(qw(AddPatches));
 336         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 337             return $unknown->("edits debian/patches");
 338         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 339             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 340             if ($ty eq 'tree') {
 341                 if ($d == D_DEB_CLOG) {
 342                     return $classify->(qw(Changelog));
 343                 } else {
 344                     return $classify->(qw(Packaging));
 345                 }
 346             } elsif ($ty eq 'missing') {
 347                 return $classify->(qw(BreakwaterStart));
 348             } else {
 349                 return $unknown->("parent's debian is not a directory");
 350             }
 351         } elsif ($d == D_UPS) {
 352             return $classify->(qw(Upstream));
 353         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 354             return $classify->(qw(Mixed));
 355         } elsif ($d == 0) {
 356             return $unknown->("no changes");
 357         } else {
 358             confess "internal error $objid ?";
 359         }
 360     }
 361     if (!@p) {
 362         return $unknown->("origin commit");
 363     }
 364
 365     my @identical = grep { !$_->{Differs} } @p;
 366     if (@p == 2 && @identical == 1) {
 367         my @overwritten = grep { $_->{Differs} } @p;
 368         confess "internal error $objid ?" unless @overwritten==1;
 369         return $classify->(qw(Pseudomerge),
 370                            Overwritten => $overwritten[0],
 371                            Contributor => $identical[0]);
 372     }
 373     if (@p == 2 && @identical == 2) {
 374         my @bytime = nsort_by {
 375             my ($ph,$pm) = get_commit $_->{CommitId};
 376             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 377             $1;
 378         } @p;
 379         return $classify->(qw(Pseudomerge),
 380                            SubType => qw(Ambiguous),
 381                            Overwritten => $bytime[0],
 382                            Contributor => $bytime[1]);
 383     }
 384     foreach my $p (@p) {
 385         my ($p_h, $p_m) = get_commit $p->{CommitId};
 386         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 387         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 388     }
 389     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 390     my $m2 = $m;
 391     if (!(grep { !$_->{IsOrigin} } @p) and
 392         (@orig_ps >= @p - 1) and
 393         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 394         $r->{NewMsg} = $m2;
 395         return $classify->(qw(DgitImportUnpatched),
 396                            OrigParents => \@orig_ps);
 397     }
 398
 399     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 400     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 401
 402     # How to decide about l/r ordering of breakwater merges ?  git
 403     # --topo-order prefers to expand 2nd parent first.  There's
 404     # already an easy rune to look for debian/ history anyway (git log
 405     # debian/) so debian breakwater branch should be 1st parent; that
 406     # way also there's also an easy rune to look for the upstream
 407     # patches (--topo-order).
 408
 409     # The above tells us which way *we* will generate them.  But we
 410     # might encounter ad-hoc breakwater merges generated manually,
 411     # which might be the other way around.  In principle, in some odd
 412     # situations, a breakwater merge might have two identical parents.
 413     # In that case we guess which way round it is (ie, which parent
 414     # has the upstream history).  The order of the 2-iteration loop
 415     # controls which guess we make.
 416
 417     foreach my $prevbrw (qw(0 1)) {
 418         if (@p == 2 &&
 419             !$haspatches &&
 420             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 421             !($p[$prevbrw]{Differs} & ~DS_DEB) &&
 422             !($p[!$prevbrw]{Differs} & ~D_UPS)) {
 423             return $classify->(qw(BreakwaterUpstreamMerge),
 424                                OrigParents => [ $p[!$prevbrw] ]);
 425         }
 426         # xxx multi-.orig upstreams
 427     }
 428
 429     return $unknown->("complex merge");
 430 }
 431
 432 sub walk ($;$$);
 433 sub walk ($;$$) {
 434     my ($input,
 435         $nogenerate,$report) = @_;
 436     # => ($tip, $breakwater_tip)
 437     # (or nothing, if $nogenerate)
 438
 439     # go through commits backwards
 440     # we generate two lists of commits to apply:
 441     # breakwater branch and upstream patches
 442     my (@brw_cl, @upp_cl, @processed);
 443     my %found;
 444     my $upp_limit;
 445     my @pseudomerges;
 446
 447     my $cl;
 448     my $xmsg = sub {
 449         my ($appendinfo) = @_;
 450         my $ms = $cl->{Msg};
 451         chomp $ms;
 452         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 453         return (Msg => $ms);
 454     };
 455     my $rewrite_from_here = sub {
 456         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 457         push @brw_cl, $sp_cl;
 458         push @processed, $sp_cl;
 459     };
 460     my $cur = $input;
 461
 462     my $prdelim = "";
 463     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 464
 465     my $prline = sub {
 466         return unless $report;
 467         print $report $prdelim, @_;
 468         $prdelim = "\n";
 469     };
 470
 471     my $bomb = sub { # usage: return $bomb->();
 472         print $report " Unprocessable" if $report;
 473         $prprdelim->();
 474         if ($nogenerate) {
 475             return (undef,undef);
 476         }
 477         die "commit $cur: Cannot cope with this commit";
 478     };
 479
 480     my $build;
 481     my $breakwater;
 482
 483     my $build_start = sub {
 484         my ($msg, $parent) = @_;
 485         $prline->(" $msg");
 486         $build = $parent;
 487         no warnings qw(exiting); last;
 488     };
 489
 490     for (;;) {
 491         $cl = classify $cur;
 492         my $ty = $cl->{Type};
 493         my $st = $cl->{SubType};
 494         $prline->("$cl->{CommitId} $cl->{Type}");
 495         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 496         push @processed, $cl;
 497         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 498         if ($ty eq 'AddPatches') {
 499             $cur = $p0;
 500             $rewrite_from_here->();
 501             next;
 502         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 503             push @brw_cl, $cl;
 504             $cur = $p0;
 505             next;
 506         } elsif ($ty eq 'BreakwaterStart') {
 507             $build_start->('FirstPackaging', $cur);
 508         } elsif ($ty eq 'Upstream') {
 509             push @upp_cl, $cl;
 510             $cur = $p0;
 511             next;
 512         } elsif ($ty eq 'Mixed') {
 513             my $queue = sub {
 514                 my ($q, $wh) = @_;
 515                 my $cls = { $cl, $xmsg->("split mixed commit: $wh part") };
 516                 push @$q, $cls;
 517             };
 518             $queue->(\@brw_cl, "debian");
 519             $queue->(\@upp_cl, "upstream");
 520             $rewrite_from_here->();
 521             $cur = $p0;
 522             next;
 523         } elsif ($ty eq 'Pseudomerge') {
 524             my $contrib = $cl->{Contributor}{CommitId};
 525             print $report " Contributor=$contrib" if $report;
 526             push @pseudomerges, $cl;
 527             $rewrite_from_here->();
 528             $cur = $contrib;
 529             next;
 530         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 531             $build_start->("PreviousBreakwater", $cur);
 532         } elsif ($ty eq 'DgitImportUnpatched') {
 533             my $pm = $pseudomerges[-1];
 534             if (defined $pm) {
 535                 # To an extent, this is heuristic.  Imports don't have
 536                 # a useful history of the debian/ branch.  We assume
 537                 # that the first pseudomerge after an import has a
 538                 # useful history of debian/, and ignore the histories
 539                 # from later pseudomerges.  Often the first pseudomerge
 540                 # will be the dgit import of the upload to the actual
 541                 # suite intended by the non-dgit NMUer, and later
 542                 # pseudomerges may represent in-archive copies.
 543                 my $ovwrs = $pm->{Overwritten};
 544                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 545                     if $report;
 546                 if (@$ovwrs != 1) {
 547                     return $bomb->();
 548                 }
 549                 my $ovwr = $ovwrs->[0]{CommitId};
 550                 printf $report " Overwr=%s", $ovwr if $report;
 551                 # This import has a tree which is just like a
 552                 # breakwater tree, but it has the wrong history.  It
 553                 # ought to have the previous breakwater (which the
 554                 # pseudomerge overwrote) as an ancestor.  That will
 555                 # make the history of the debian/ files correct.  As
 556                 # for the upstream version: either it's the same as
 557                 # was ovewritten (ie, same as the previous
 558                 # breakwater), in which case that history is precisely
 559                 # right; or, otherwise, it was a non-gitish upload of a
 560                 # new upstream version.  We can tell these apart by
 561                 # looking at the tree of the supposed upstream.
 562                 push @brw_cl, {
 563                     %$cl,
 564                     SpecialMethod => 'DgitImportDebianUpdate',
 565                     $xmsg->("convert dgit import: debian changes")
 566                 };
 567                 my $differs = (get_differs $ovwr, $cl->{Tree});
 568                 printf $report " Differs=%#x", $differs if $report;
 569                 if ($differs & D_UPS) {
 570                     printf $report " D_UPS" if $report;
 571                     # This will also trigger if a non-dgit git-based NMU
 572                     # deleted .gitignore (which is a thing that some of
 573                     # the existing git tools do if the user doesn't
 574                     # somehow tell them not to).  Ah well.
 575                     push @brw_cl, {
 576                         %$cl,
 577                         SpecialMethod => 'DgitImportUpstreamUpdate',
 578                         $xmsg->("convert dgit import: upstream changes")
 579                     };
 580                 }
 581                 $prline->(" Import");
 582                 $rewrite_from_here->();
 583                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 584                 $cur = $ovwr;
 585                 next;
 586             } else {
 587                 # Everything is from this import.  This kind of import
 588                 # is already in valid breakwater format, with the
 589                 # patches as commits.
 590                 printf $report " NoPM" if $report;
 591                 # last thing we processed will have been the first patch,
 592                 # if there is one; which is fine, so no need to rewrite
 593                 # on account of this import
 594                 $build_start->("ImportOrigin", $cur);
 595             }
 596             die "$ty ?";
 597         } else {
 598             return $bomb->();
 599         }
 600     }
 601     $prprdelim->();
 602     return if $nogenerate;
 603
 604     # Now we build it back up again
 605
 606     fresh_workarea();
 607
 608     my $rewriting = 0;
 609
 610     my $rm_tree_cached = sub {
 611         my ($subdir) = @_;
 612         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 613     };
 614     my $read_tree_debian = sub {
 615         my ($treeish) = @_;
 616         $rm_tree_cached->(qw(debian));
 617         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 618     };
 619     my $read_tree_upstream = sub {
 620         my ($treeish) = @_;
 621         runcmd @git, qw(read-tree), $treeish;
 622         $read_tree_debian->($build);
 623     };
 624
 625     my $committer_authline = calculate_committer_authline();
 626
 627     in_workarea sub {
 628         mkdir $rd or $!==EEXIST or die $!;
 629         my $current_method;
 630         foreach my $cl (qw(Debian), (reverse @brw_cl),
 631                         { SpecialMethod => 'RecordBreakwaterTip' },
 632                         qw(Upstream), (reverse @upp_cl)) {
 633             if (!ref $cl) {
 634                 $current_method = $cl;
 635                 next;
 636             }
 637             my $method = $cl->{SpecialMethod} // $current_method;
 638             my @parents = ($build);
 639             my $cltree = $cl->{CommitId};
 640             if ($method eq 'Debian') {
 641                 $read_tree_debian->($cltree);
 642             } elsif ($method eq 'Upstream') {
 643                 $read_tree_upstream->($cltree);
 644             } elsif ($method eq 'StartRewrite') {
 645                 $rewriting = 1;
 646                 next;
 647             } elsif ($method eq 'RecordBreakwaterTip') {
 648                 $breakwater = $build;
 649                 next;
 650             } elsif ($method eq 'DgitImportDebianUpdate') {
 651                 $read_tree_debian->($cltree);
 652                 $rm_tree_cached->(qw(debian/patches));
 653             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 654                 $read_tree_upstream->($cltree);
 655                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 656             } else {
 657                 confess "$method ?";
 658             }
 659             $rewriting ||= $cl ne pop @processed;
 660             my $newtree = cmdoutput @git, qw(write-tree);
 661             my $ch = $cl->{Hdr};
 662             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 663             $ch =~ s{^parent .*\n}{}m;
 664             $ch =~ s{(?=^author)}{
 665                 map { "parent $_\n" } @parents
 666             }me or confess "$ch ?";
 667             if ($rewriting) {
 668                 $ch =~ s{^committer .*$}{$committer_authline}m
 669                     or confess "$ch ?";
 670             }
 671             my $cf = "$rd/m$rewriting";
 672             open CD, ">", $cf or die $!;
 673             print CD $ch, "\n", $cl->{Msg} or die $!;
 674             close CD or die $!;
 675             my @cmd = (@git, qw(hash-object));
 676             push @cmd, qw(-w) if $rewriting;
 677             push @cmd, qw(-t commit), $cf;
 678             my $newcommit = cmdoutput @cmd;
 679             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 680             $build = $newcommit;
 681         }
 682     };
 683
 684     runcmd @git, qw(diff-tree --quiet), $input, $build;
 685
 686     return ($build, $breakwater);
 687 }
 688
 689 sub get_head () { return git_rev_parse qw(HEAD); }
 690
 691 sub update_head ($$$) {
 692     my ($old, $new, $mrest) = @_;
 693     runcmd @git, qw(update-ref -m), "git-debrebase $mrest", $new, $old;
 694 }
 695
 696 sub cmd_launder () {
 697     badusage "no arguments to launder allowed" if @ARGV;
 698     my $old = get_head();
 699     my ($tip,$breakwater) = walk $old;
 700     update_head $old, $tip, 'launder';
 701     # no tree changes except debian/patches
 702     runcmd @git, qw(rm --quiet -rf debian/patches);
 703     printf "# breakwater tip\n%s\n", $breakwater;
 704 }
 705
 706 sub cmd_analyse () {
 707     die if ($ARGV[0]//'') =~ m/^-/;
 708     badusage "too many arguments to analyse" if @ARGV>1;
 709     my ($old) = @ARGV;
 710     if (defined $old) {
 711         $old = git_rev_parse $old;
 712     } else {
 713         $old = get_head();
 714     }
 715     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 716     STDOUT->error and die $!;
 717 }
 718
 719 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 720 initdebug('git-debrebase ');
 721 enabledebug if $debuglevel;
 722
 723 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 724 chdir $toplevel or die "chdir $toplevel: $!";
 725
 726 $rd = fresh_playground "$playprefix/misc";
 727
 728 my $cmd = shift @ARGV;
 729 my $cmdfn = $cmd;
 730 $cmdfn =~ y/-/_/;
 731 $cmdfn = ${*::}{"cmd_$cmdfn"};
 732
 733 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 734 $cmdfn->();