git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Memoize;
 108 use Carp;
 109 use POSIX;
 110 use Data::Dumper;
 111 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 112
 113 use Debian::Dgit qw(:DEFAULT $wa);
 114
 115 sub badusage ($) {
 116     my ($m) = @_;
 117     die "bad usage: $m\n";
 118 }
 119
 120 sub cfg ($) {
 121     my ($k) = @_;
 122     $/ = "\0";
 123     my @cmd = qw(git config -z);
 124     push @cmd, qw(--get-all) if wantarray;
 125     push @cmd, $k;
 126     my $out = cmdoutput @cmd;
 127     return split /\0/, $out;
 128 }
 129
 130 memoize('cfg');
 131
 132 sub get_commit ($) {
 133     my ($objid) = @_;
 134     my ($type,$data) = git_cat_file $objid;
 135     die unless $type eq 'commit';
 136     $data =~ m/(?<=\n)\n/;
 137     return ($`,$');
 138 }
 139
 140 sub D_DEB ()     { return 0x1; } # debian/ (not including debian/patches/)
 141 sub D_UPS ()     { return 0x2; } # upstream files
 142 sub D_PAT_ADD () { return 0x4; } # debian/patches/ extra patches at end
 143 sub D_PAT_OTH () { return 0x8; } # debian/patches other changes
 144
 145 our $rd = ".git/git-debrebase";
 146 our $ud = "$rd/work";
 147 our @git = qw(git);
 148
 149 sub get_differs ($$) {
 150     my ($x,$y) = @_;
 151     # This resembles quiltify_trees_differ, in dgit, a bit.
 152     # But we don't care about modes, or dpkg-source-unrepresentable
 153     # changes, and we don't need the plethora of different modes.
 154     # Conversely we need to distinguish different kinds of changes to
 155     # debian/ and debian/patches/.
 156
 157     my $differs = 0;
 158
 159     my $rundiff = sub {
 160         my ($opts, $sfx, $fn) = @_;
 161         $opts //= [qw(--name-only)];
 162         my @cmd = (@git, qw(diff-tree -z --no-renames));
 163         push @cmd, @$opts;
 164         push @cmd, "$_:$sfx" foreach $x, $y;
 165         my $diffs = cmdoutput @cmd;
 166         foreach (split /\0/, $diffs) { $fn->(); }
 167     };
 168
 169     $rundiff->(undef, '', sub {
 170         $differs |= $_ eq 'debian' ? D_DEB : D_UPS;
 171     });
 172
 173     if ($differs & D_DEB) {
 174         $differs &= ~D_DEB;
 175         $rundiff->(undef, ':debian', sub {
 176             $differs |= $_ eq 'patches' ? D_PAT_OTH : D_DEB;
 177         });
 178         die "mysterious debian changes $x..$y"
 179             unless $differs & (D_PAT_OTH|D_DEB);
 180     }
 181
 182     if ($differs & D_PAT_OTH) {
 183         my $mode;
 184         $differs &= ~D_PAT_OTH;
 185         my $pat_oth = sub {
 186             $differs |= D_PAT_OTH;
 187             no warnings qw(exiting);  last;
 188         };
 189         $rundiff->([qw(--name-status)], ':debian/patches', sub {
 190             no warnings qw(exiting);
 191             if (!defined $mode) {
 192                 $mode = $_;  next;
 193             }
 194             my $ok;
 195             if ($mode eq 'A' && !m/(?:^|\.)series$/s) {
 196                 $ok = 1;
 197             } elsif ($mode eq 'M' && $_ eq 'series') {
 198                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 199                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 200                 chomp $x_s;  $x_s .= "\n";
 201                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 202             } else {
 203                 # nope
 204             }
 205             $mode = undef;
 206             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 207         });
 208         die "mysterious debian/patches changes $x..$y"
 209             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 210     }
 211
 212     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 213
 214     return $differs;
 215 }
 216
 217 sub commit_pr_info ($) {
 218     my ($r) = @_;
 219     return Data::Dumper->dump([$r], [qw(commit)]);
 220 }
 221
 222 sub calculate_committer_authline () {
 223     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 224         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 225     my ($h,$m) = get_commit $c;
 226     $h =~ m/^committer .*$/m or confess "($h) ?";
 227     return $&;
 228 }
 229
 230 # classify returns an info hash like this
 231 #   CommitId => $objid
 232 #   Hdr => # commit headers, including 1 final newline
 233 #   Msg => # commit message (so one newline is dropped)
 234 #   Tree => $treeobjid
 235 #   Type => (see below)
 236 #   Parents = [ {
 237 #       Ix => $index # ie 0, 1, 2, ...
 238 #       CommitId
 239 #       Differs => return value from get_differs
 240 #       IsOrigin
 241 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 242 #     } ...]
 243 #   NewMsg => # commit message, but with any [dgit import ...] edited
 244 #             # to say "[was: ...]"
 245 #
 246 # Types:
 247 #   Packaging
 248 #   Upstream
 249 #   AddPatches
 250 #   Mixed
 251 #   Unknown
 252 #
 253 #   Pseudomerge
 254 #     has additional entres in classification result
 255 #       Overwritten = [ subset of Parents ]
 256 #       Contributor = $the_remaining_Parent
 257 #
 258 #   DgitImportUnpatched
 259 #     has additional entry in classification result
 260 #       OrigParents = [ subset of Parents ]
 261 #
 262 #   BreakwaterUpstreamMerge
 263 #     has additional entry in classification result
 264 #       OrigParents = [ subset of Parents ]
 265
 266 sub classify ($) {
 267     my ($objid) = @_;
 268
 269     my ($h,$m) = get_commit $objid;
 270
 271     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 272     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 273     my @p;
 274
 275     my $r = {
 276         CommitId => $objid,
 277         Hdr => $h,
 278         Msg => $m,
 279         Tree => $t,
 280         Parents => \@p,
 281     };
 282
 283     foreach my $ph (@ph) {
 284         push @p, {
 285             Ix => $#p,
 286             CommitId => $ph,
 287             Differs => (get_differs $t, $ph),
 288         };
 289     }
 290
 291     printdebug "classify $objid \$t=$t \@p",
 292         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 293         "\n";
 294
 295     my $classify = sub {
 296         my ($type, @rest) = @_;
 297         $r = { %$r, Type => $type, @rest };
 298         if ($debuglevel) {
 299             my $dd = new Data::Dumper [ $r ];
 300             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 301             printdebug " = $type ".(Dump $dd)."\n";
 302         }
 303         return $r;
 304     };
 305     my $unknown = sub {
 306         my ($why) = @_;
 307         $r = { %$r, Type => qw(Unknown) };
 308         printdebug " ** Unknown\n";
 309         return $r;
 310     };
 311
 312     if (@p == 1) {
 313         my $d = $r->{Parents}[0]{Differs};
 314         if ($d == D_PAT_ADD) {
 315             return $classify->(qw(AddPatches));
 316         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 317             return $unknown->("edits debian/patches");
 318         } elsif ($d == D_DEB) {
 319             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 320             if ($ty eq 'tree') {
 321                 return $classify->(qw(Packaging));
 322             } elsif ($ty eq 'missing') {
 323                 return $classify->(qw(BreakwaterStart));
 324             } else {
 325                 return $unknown->("parent's debian is not a directory");
 326             }
 327         } elsif ($d == D_UPS) {
 328             return $classify->(qw(Upstream));
 329         } elsif ($d == (D_DEB|D_UPS)) {
 330             return $classify->(qw(Mixed));
 331         } elsif ($d == 0) {
 332             return $unknown->("no changes");
 333         } else {
 334             confess "internal error $objid ?";
 335         }
 336     }
 337     if (!@p) {
 338         return $unknown->("origin commit");
 339     }
 340
 341     my @identical = grep { !$_->{Differs} } @p;
 342     if (@p == 2 && @identical == 1) {
 343         my @overwritten = grep { $_->{Differs} } @p;
 344         confess "internal error $objid ?" unless @overwritten==1;
 345         return $classify->(qw(Pseudomerge),
 346                            Overwritten => $overwritten[0],
 347                            Contributor => $identical[0]);
 348     }
 349     if (@p == 2 && @identical == 2) {
 350         my @bytime = nsort_by {
 351             my ($ph,$pm) = get_commit $_->{CommitId};
 352             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 353             $1;
 354         } @p;
 355         return $classify->(qw(Pseudomerge),
 356                            SubType => qw(Ambiguous),
 357                            Overwritten => $bytime[0],
 358                            Contributor => $bytime[1]);
 359     }
 360     foreach my $p (@p) {
 361         my ($p_h, $p_m) = get_commit $p;
 362         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 363         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 364     }
 365     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 366     my $m2 = $m;
 367     if (!(grep { !$_->{IsOrigin} } @p) and
 368         (@orig_ps >= @p - 1) and
 369         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 370         $r->{NewMsg} = $m2;
 371         return $classify->(qw(DgitImportUnpatched),
 372                            OrigParents => \@orig_ps);
 373     }
 374
 375     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 376     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 377
 378     # How to decide about l/r ordering of breakwater merges ?  git
 379     # --topo-order prefers to expand 2nd parent first.  There's
 380     # already an easy rune to look for debian/ history anyway (git log
 381     # debian/) so debian breakwater branch should be 1st parent; that
 382     # way also there's also an easy rune to look for the upstream
 383     # patches (--topo-order).
 384     if (@p == 2 &&
 385         !$haspatches &&
 386         !$p[0]{IsOrigin} && # breakwater merge never starts with an origin
 387         !($p[0]{Differs} & ~D_DEB) &&
 388         !($p[1]{Differs} & ~D_UPS)) {
 389         return $classify->(qw(BreakwaterUpstreamMerge),
 390                            OrigParents => [ $p[1] ]);
 391     }
 392     # xxx multi-.orig upstreams
 393
 394     return $unknown->("complex merge");
 395 }
 396
 397 sub walk ($;$$);
 398 sub walk ($;$$) {
 399     my ($input,
 400         $nogenerate,$report) = @_;
 401     # => ($tip, $breakwater_tip)
 402     # (or nothing, if $nogenerate)
 403
 404     # go through commits backwards
 405     # we generate two lists of commits to apply:
 406     # breakwater branch and upstream patches
 407     my (@brw_cl, @upp_cl, @processed);
 408     my %found;
 409     my $upp_limit;
 410     my @pseudomerges;
 411
 412     my $cl;
 413     my $xmsg = sub {
 414         my ($appendinfo) = @_;
 415         my $ms = $cl->{Msg};
 416         chomp $ms;
 417         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 418         return (Msg => $ms);
 419     };
 420     my $rewrite_from_here = sub {
 421         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 422         push @brw_cl, $sp_cl;
 423         push @processed, $sp_cl;
 424     };
 425     my $cur = $input;
 426
 427     my $prdelim = "";
 428     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 429
 430     my $prline = sub {
 431         return unless $report;
 432         print $report $prdelim, @_;
 433         $prdelim = "\n";
 434     };
 435
 436     my $bomb = sub { # usage: return $bomb->();
 437         print $report " Unprocessable" if $report;
 438         $prprdelim->();
 439         if ($nogenerate) {
 440             return (undef,undef);
 441         }
 442         die "commit $cur: Cannot cope with this commit";
 443     };
 444
 445     my $build;
 446     my $breakwater;
 447
 448     my $build_start = sub {
 449         my ($msg, $parent) = @_;
 450         $prline->(" $msg");
 451         $build = $parent;
 452         no warnings qw(exiting); last;
 453     };
 454
 455     for (;;) {
 456         $cl = classify $cur;
 457         my $ty = $cl->{Type};
 458         my $st = $cl->{SubType};
 459         $prline->("$cl->{CommitId} $cl->{Type}");
 460         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 461         push @processed, $cl;
 462         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 463         if ($ty eq 'AddPatches') {
 464             $cur = $p0;
 465             $rewrite_from_here->();
 466             next;
 467         } elsif ($ty eq 'Packaging') {
 468             push @brw_cl, $cl;
 469             $cur = $p0;
 470             next;
 471         } elsif ($ty eq 'BreakwaterStart') {
 472             $build_start->('FirstPackaging', $cur);
 473         } elsif ($ty eq 'Upstream') {
 474             push @upp_cl, $cl;
 475             $cur = $p0;
 476             next;
 477         } elsif ($ty eq 'Mixed') {
 478             my $queue = sub {
 479                 my ($q, $wh) = @_;
 480                 my $cls = { $cl, $xmsg->("split mixed commit: $wh part") };
 481                 push @$q, $cls;
 482             };
 483             $queue->(\@brw_cl, "debian");
 484             $queue->(\@upp_cl, "upstream");
 485             $rewrite_from_here->();
 486             $cur = $p0;
 487             next;
 488         } elsif ($ty eq 'Pseudomerge') {
 489             print $report " Contributor=$cl->{Contributor}" if $report;
 490             push @pseudomerges, $cl;
 491             $rewrite_from_here->();
 492             $cur = $ty->{Contributor};
 493             next;
 494         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 495             $build_start->("PreviousBreakwater", $cur);
 496         } elsif ($ty eq 'DgitImportUnpatched') {
 497             my $pm = $pseudomerges[-1];
 498             if (defined $pm) {
 499                 # To an extent, this is heuristic.  Imports don't have
 500                 # a useful history of the debian/ branch.  We assume
 501                 # that the first pseudomerge after an import has a
 502                 # useful history of debian/, and ignore the histories
 503                 # from later pseudomerges.  Often the first pseudomerge
 504                 # will be the dgit import of the upload to the actual
 505                 # suite intended by the non-dgit NMUer, and later
 506                 # pseudomerges may represent in-archive copies.
 507                 my $ovwrs = $pm->{Overwritten};
 508                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 509                     if $report;
 510                 if (@$ovwrs != 1) {
 511                     return $bomb->();
 512                 }
 513                 my $ovwr = $ovwrs->[0]{CommitId};
 514                 printf $report " Overwr=%s", $ovwr if $report;
 515                 # This import has a tree which is just like a
 516                 # breakwater tree, but it has the wrong history.  It
 517                 # ought to have the previous breakwater (which the
 518                 # pseudomerge overwrote) as an ancestor.  That will
 519                 # make the history of the debian/ files correct.  As
 520                 # for the upstream version: either it's the same as
 521                 # was ovewritten (ie, same as the previous
 522                 # breakwater), in which case that history is precisely
 523                 # right; or, otherwise, it was a non-gitish upload of a
 524                 # new upstream version.  We can tell these apart by
 525                 # looking at the tree of the supposed upstream.
 526                 push @brw_cl, {
 527                     %$cl,
 528                     SpecialMethod => 'DgitImportDebianUpdate',
 529                     $xmsg->("convert dgit import: debian changes")
 530                 };
 531                 my $differs = (get_differs $ovwr, $cl->{Tree});
 532                 printf $report " Differs=%#x", $differs if $report;
 533                 if ($differs & D_UPS) {
 534                     printf $report " D_UPS" if $report;
 535                     # This will also trigger if a non-dgit git-based NMU
 536                     # deleted .gitignore (which is a thing that some of
 537                     # the existing git tools do if the user doesn't
 538                     # somehow tell them not to).  Ah well.
 539                     push @brw_cl, {
 540                         %$cl,
 541                         SpecialMethod => 'DgitImportUpstreamUpdate',
 542                         $xmsg->("convert dgit import: upstream changes")
 543                     };
 544                 }
 545                 $prline->(" Import");
 546                 $rewrite_from_here->();
 547                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 548                 $cur = $ovwr;
 549                 next;
 550             } else {
 551                 # Everything is from this import.  This kind of import
 552                 # is already in valid breakwater format, with the
 553                 # patches as commits.
 554                 printf $report " NoPM" if $report;
 555                 # last thing we processed will have been the first patch,
 556                 # if there is one; which is fine, so no need to rewrite
 557                 # on account of this import
 558                 $build_start->("ImportOrigin", $cur);
 559             }
 560             die "$ty ?";
 561         } else {
 562             return $bomb->();
 563         }
 564     }
 565     $prprdelim->();
 566     return if $nogenerate;
 567
 568     # Now we build it back up again
 569
 570     workarea_fresh();
 571
 572     my $rewriting = 0;
 573
 574     my $rm_tree_cached = sub {
 575         my ($subdir) = @_;
 576         runcmd @git, qw(rm --quiet -rf --cached), $subdir;
 577     };
 578     my $read_tree_debian = sub {
 579         my ($treeish) = @_;
 580         $rm_tree_cached->(qw(debian));
 581         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 582     };
 583     my $read_tree_upstream = sub {
 584         my ($treeish) = @_;
 585         runcmd @git, qw(read-tree), $treeish;
 586         $read_tree_debian->($build);
 587     };
 588
 589     my $committer_authline = calculate_committer_authline();
 590
 591     in_workarea sub {
 592         mkdir $rd or $!==EEXIST or die $!;
 593         my $current_method;
 594         foreach my $cl (qw(Debian), (reverse @brw_cl),
 595                         { SpecialMethod => 'RecordBreakwaterTip' },
 596                         qw(Upstream), (reverse @upp_cl)) {
 597             if (!ref $cl) {
 598                 $current_method = $cl;
 599                 next;
 600             }
 601             my $method = $cl->{SpecialMethod} // $current_method;
 602             my @parents = ($build);
 603             my $cltree = $cl->{CommitId};
 604             if ($method eq 'Debian') {
 605                 $read_tree_debian->($cltree);
 606             } elsif ($method eq 'Upstream') {
 607                 $read_tree_upstream->($cltree);
 608             } elsif ($method eq 'StartRewrite') {
 609                 $rewriting = 1;
 610                 next;
 611             } elsif ($method eq 'RecordBreakwaterTip') {
 612                 $breakwater = $build;
 613                 next;
 614             } elsif ($method eq 'DgitImportDebianUpdate') {
 615                 $read_tree_debian->($cltree);
 616                 $rm_tree_cached->(qw(debian/patches));
 617             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 618                 $read_tree_upstream->($cltree);
 619                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 620             } else {
 621                 confess "$method ?";
 622             }
 623             $rewriting ||= $cl ne pop @processed;
 624             my $newtree = cmdoutput @git, qw(write-tree);
 625             my $ch = $cl->{Hdr};
 626             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 627             $ch =~ s{^parent .*\n}{}m;
 628             $ch =~ s{(?=^author)}{
 629                 map { "parent $_\n" } @parents
 630             }me or confess "$ch ?";
 631             if ($rewriting) {
 632                 $ch =~ s{^committer .*$}{$committer_authline}m
 633                     or confess "$ch ?";
 634             }
 635             my $cf = "$rd/m$rewriting";
 636             open CD, ">", $cf or die $!;
 637             print CD $ch, "\n", $cl->{Msg} or die $!;
 638             close CD or die $!;
 639             my @cmd = (@git, qw(hash-object));
 640             push @cmd, qw(-w) if $rewriting;
 641             push @cmd, qw(-t commit), $cf;
 642             my $newcommit = cmdoutput @cmd;
 643             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 644             $build = $newcommit;
 645         }
 646     };
 647
 648     runcmd @git, qw(diff-tree --quiet), $input, $build;
 649
 650     return ($build, $breakwater);
 651 }
 652
 653 sub get_head () { return git_rev_parse qw(HEAD); }
 654
 655 sub update_head ($$$) {
 656     my ($old, $new, $mrest) = @_;
 657     runcmd @git, qw(update-ref -m), "git-debrebase $mrest", $new, $old;
 658 }
 659
 660 sub cmd_launder () {
 661     badusage "no arguments to launder allowed";
 662     my $old = get_head();
 663     my ($tip,$breakwater) = walk $old;
 664     update_head $old, $tip, 'launder';
 665     # no tree changes except debian/patches
 666     runcmd @git, qw(rm --quiet -rf debian/patches);
 667     printf "# breakwater tip\n%s\n", $breakwater;
 668 }
 669
 670 sub cmd_analyse () {
 671     die if ($ARGV[0]//'') =~ m/^-/;
 672     badusage "too many arguments to analyse" if @ARGV>1;
 673     my ($old) = @ARGV;
 674     if (defined $old) {
 675         $old = git_rev_parse $old;
 676     } else {
 677         $old = get_head();
 678     }
 679     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 680     STDOUT->error and die $!;
 681 }
 682
 683 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 684 initdebug('git-debrebase ');
 685 enabledebug if $debuglevel;
 686
 687 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 688 chdir $toplevel or die "chdir $toplevel: $!";
 689
 690 my $cmd = shift @ARGV;
 691 my $cmdfn = $cmd;
 692 $cmdfn =~ y/-/_/;
 693 $cmdfn = ${*::}{"cmd_$cmdfn"};
 694
 695 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 696 $cmdfn->();