git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Memoize;
 108 use Carp;
 109 use POSIX;
 110 use Data::Dumper;
 111 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 112
 113 use Debian::Dgit qw(:DEFAULT $wa);
 114
 115 $wa = '.git/debrebase/work';
 116
 117 sub badusage ($) {
 118     my ($m) = @_;
 119     die "bad usage: $m\n";
 120 }
 121
 122 sub cfg ($) {
 123     my ($k) = @_;
 124     $/ = "\0";
 125     my @cmd = qw(git config -z);
 126     push @cmd, qw(--get-all) if wantarray;
 127     push @cmd, $k;
 128     my $out = cmdoutput @cmd;
 129     return split /\0/, $out;
 130 }
 131
 132 memoize('cfg');
 133
 134 sub get_commit ($) {
 135     my ($objid) = @_;
 136     my $data = git_cat_file $objid, 'commit';
 137     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 138     return ($`,$');
 139 }
 140
 141 sub D_DEB ()     { return 0x1; } # debian/ (not including debian/patches/)
 142 sub D_UPS ()     { return 0x2; } # upstream files
 143 sub D_PAT_ADD () { return 0x4; } # debian/patches/ extra patches at end
 144 sub D_PAT_OTH () { return 0x8; } # debian/patches other changes
 145
 146 our $rd = ".git/git-debrebase";
 147 our $ud = "$rd/work";
 148 our @git = qw(git);
 149
 150 sub get_differs ($$) {
 151     my ($x,$y) = @_;
 152     # This resembles quiltify_trees_differ, in dgit, a bit.
 153     # But we don't care about modes, or dpkg-source-unrepresentable
 154     # changes, and we don't need the plethora of different modes.
 155     # Conversely we need to distinguish different kinds of changes to
 156     # debian/ and debian/patches/.
 157
 158     my $differs = 0;
 159
 160     my $rundiff = sub {
 161         my ($opts, $limits, $fn) = @_;
 162         my @cmd = (@git, qw(diff-tree -z --no-renames));
 163         push @cmd, @$opts;
 164         push @cmd, "$_:" foreach $x, $y;
 165         push @cmd, @$limits;
 166         my $diffs = cmdoutput @cmd;
 167         foreach (split /\0/, $diffs) { $fn->(); }
 168     };
 169
 170     $rundiff->([qw(--name-only)], [], sub {
 171         $differs |= $_ eq 'debian' ? D_DEB : D_UPS;
 172     });
 173
 174     if ($differs & D_DEB) {
 175         $differs &= ~D_DEB;
 176         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 177             $differs |= $_ eq m{^debian/patches/} ? D_PAT_OTH : D_DEB;
 178         });
 179         die "mysterious debian changes $x..$y"
 180             unless $differs & (D_PAT_OTH|D_DEB);
 181     }
 182
 183     if ($differs & D_PAT_OTH) {
 184         my $mode;
 185         $differs &= ~D_PAT_OTH;
 186         my $pat_oth = sub {
 187             $differs |= D_PAT_OTH;
 188             no warnings qw(exiting);  last;
 189         };
 190         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 191             no warnings qw(exiting);
 192             if (!defined $mode) {
 193                 $mode = $_;  next;
 194             }
 195             die unless s{^debian/patches/}{};
 196             my $ok;
 197             if ($mode eq 'A' && !m/(?:^|\.)series$/s) {
 198                 $ok = 1;
 199             } elsif ($mode eq 'M' && $_ eq 'series') {
 200                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 201                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 202                 chomp $x_s;  $x_s .= "\n";
 203                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 204             } else {
 205                 # nope
 206             }
 207             $mode = undef;
 208             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 209         });
 210         die "mysterious debian/patches changes $x..$y"
 211             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 212     }
 213
 214     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 215
 216     return $differs;
 217 }
 218
 219 sub commit_pr_info ($) {
 220     my ($r) = @_;
 221     return Data::Dumper->dump([$r], [qw(commit)]);
 222 }
 223
 224 sub calculate_committer_authline () {
 225     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 226         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 227     my ($h,$m) = get_commit $c;
 228     $h =~ m/^committer .*$/m or confess "($h) ?";
 229     return $&;
 230 }
 231
 232 # classify returns an info hash like this
 233 #   CommitId => $objid
 234 #   Hdr => # commit headers, including 1 final newline
 235 #   Msg => # commit message (so one newline is dropped)
 236 #   Tree => $treeobjid
 237 #   Type => (see below)
 238 #   Parents = [ {
 239 #       Ix => $index # ie 0, 1, 2, ...
 240 #       CommitId
 241 #       Differs => return value from get_differs
 242 #       IsOrigin
 243 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 244 #     } ...]
 245 #   NewMsg => # commit message, but with any [dgit import ...] edited
 246 #             # to say "[was: ...]"
 247 #
 248 # Types:
 249 #   Packaging
 250 #   Upstream
 251 #   AddPatches
 252 #   Mixed
 253 #   Unknown
 254 #
 255 #   Pseudomerge
 256 #     has additional entres in classification result
 257 #       Overwritten = [ subset of Parents ]
 258 #       Contributor = $the_remaining_Parent
 259 #
 260 #   DgitImportUnpatched
 261 #     has additional entry in classification result
 262 #       OrigParents = [ subset of Parents ]
 263 #
 264 #   BreakwaterUpstreamMerge
 265 #     has additional entry in classification result
 266 #       OrigParents = [ subset of Parents ]
 267
 268 sub classify ($) {
 269     my ($objid) = @_;
 270
 271     my ($h,$m) = get_commit $objid;
 272
 273     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 274     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 275     my @p;
 276
 277     my $r = {
 278         CommitId => $objid,
 279         Hdr => $h,
 280         Msg => $m,
 281         Tree => $t,
 282         Parents => \@p,
 283     };
 284
 285     foreach my $ph (@ph) {
 286         push @p, {
 287             Ix => $#p,
 288             CommitId => $ph,
 289             Differs => (get_differs $t, $ph),
 290         };
 291     }
 292
 293     printdebug "classify $objid \$t=$t \@p",
 294         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 295         "\n";
 296
 297     my $classify = sub {
 298         my ($type, @rest) = @_;
 299         $r = { %$r, Type => $type, @rest };
 300         if ($debuglevel) {
 301             my $dd = new Data::Dumper [ $r ];
 302             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 303             printdebug " = $type ".(Dump $dd)."\n";
 304         }
 305         return $r;
 306     };
 307     my $unknown = sub {
 308         my ($why) = @_;
 309         $r = { %$r, Type => qw(Unknown) };
 310         printdebug " ** Unknown\n";
 311         return $r;
 312     };
 313
 314     if (@p == 1) {
 315         my $d = $r->{Parents}[0]{Differs};
 316         if ($d == D_PAT_ADD) {
 317             return $classify->(qw(AddPatches));
 318         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 319             return $unknown->("edits debian/patches");
 320         } elsif ($d == D_DEB) {
 321             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 322             if ($ty eq 'tree') {
 323                 return $classify->(qw(Packaging));
 324             } elsif ($ty eq 'missing') {
 325                 return $classify->(qw(BreakwaterStart));
 326             } else {
 327                 return $unknown->("parent's debian is not a directory");
 328             }
 329         } elsif ($d == D_UPS) {
 330             return $classify->(qw(Upstream));
 331         } elsif ($d == (D_DEB|D_UPS)) {
 332             return $classify->(qw(Mixed));
 333         } elsif ($d == 0) {
 334             return $unknown->("no changes");
 335         } else {
 336             confess "internal error $objid ?";
 337         }
 338     }
 339     if (!@p) {
 340         return $unknown->("origin commit");
 341     }
 342
 343     my @identical = grep { !$_->{Differs} } @p;
 344     if (@p == 2 && @identical == 1) {
 345         my @overwritten = grep { $_->{Differs} } @p;
 346         confess "internal error $objid ?" unless @overwritten==1;
 347         return $classify->(qw(Pseudomerge),
 348                            Overwritten => $overwritten[0],
 349                            Contributor => $identical[0]);
 350     }
 351     if (@p == 2 && @identical == 2) {
 352         my @bytime = nsort_by {
 353             my ($ph,$pm) = get_commit $_->{CommitId};
 354             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 355             $1;
 356         } @p;
 357         return $classify->(qw(Pseudomerge),
 358                            SubType => qw(Ambiguous),
 359                            Overwritten => $bytime[0],
 360                            Contributor => $bytime[1]);
 361     }
 362     foreach my $p (@p) {
 363         my ($p_h, $p_m) = get_commit $p->{CommitId};
 364         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 365         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 366     }
 367     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 368     my $m2 = $m;
 369     if (!(grep { !$_->{IsOrigin} } @p) and
 370         (@orig_ps >= @p - 1) and
 371         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 372         $r->{NewMsg} = $m2;
 373         return $classify->(qw(DgitImportUnpatched),
 374                            OrigParents => \@orig_ps);
 375     }
 376
 377     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 378     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 379
 380 @p = reverse @p; #xxx
 381
 382     # How to decide about l/r ordering of breakwater merges ?  git
 383     # --topo-order prefers to expand 2nd parent first.  There's
 384     # already an easy rune to look for debian/ history anyway (git log
 385     # debian/) so debian breakwater branch should be 1st parent; that
 386     # way also there's also an easy rune to look for the upstream
 387     # patches (--topo-order).
 388     if (@p == 2 &&
 389         !$haspatches &&
 390         !$p[0]{IsOrigin} && # breakwater merge never starts with an origin
 391         !($p[0]{Differs} & ~D_DEB) &&
 392         !($p[1]{Differs} & ~D_UPS)) {
 393         return $classify->(qw(BreakwaterUpstreamMerge),
 394                            OrigParents => [ $p[1] ]);
 395     }
 396     # xxx multi-.orig upstreams
 397
 398     return $unknown->("complex merge");
 399 }
 400
 401 sub walk ($;$$);
 402 sub walk ($;$$) {
 403     my ($input,
 404         $nogenerate,$report) = @_;
 405     # => ($tip, $breakwater_tip)
 406     # (or nothing, if $nogenerate)
 407
 408     # go through commits backwards
 409     # we generate two lists of commits to apply:
 410     # breakwater branch and upstream patches
 411     my (@brw_cl, @upp_cl, @processed);
 412     my %found;
 413     my $upp_limit;
 414     my @pseudomerges;
 415
 416     my $cl;
 417     my $xmsg = sub {
 418         my ($appendinfo) = @_;
 419         my $ms = $cl->{Msg};
 420         chomp $ms;
 421         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 422         return (Msg => $ms);
 423     };
 424     my $rewrite_from_here = sub {
 425         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 426         push @brw_cl, $sp_cl;
 427         push @processed, $sp_cl;
 428     };
 429     my $cur = $input;
 430
 431     my $prdelim = "";
 432     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 433
 434     my $prline = sub {
 435         return unless $report;
 436         print $report $prdelim, @_;
 437         $prdelim = "\n";
 438     };
 439
 440     my $bomb = sub { # usage: return $bomb->();
 441         print $report " Unprocessable" if $report;
 442         $prprdelim->();
 443         if ($nogenerate) {
 444             return (undef,undef);
 445         }
 446         die "commit $cur: Cannot cope with this commit";
 447     };
 448
 449     my $build;
 450     my $breakwater;
 451
 452     my $build_start = sub {
 453         my ($msg, $parent) = @_;
 454         $prline->(" $msg");
 455         $build = $parent;
 456         no warnings qw(exiting); last;
 457     };
 458
 459     for (;;) {
 460         $cl = classify $cur;
 461         my $ty = $cl->{Type};
 462         my $st = $cl->{SubType};
 463         $prline->("$cl->{CommitId} $cl->{Type}");
 464         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 465         push @processed, $cl;
 466         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 467         if ($ty eq 'AddPatches') {
 468             $cur = $p0;
 469             $rewrite_from_here->();
 470             next;
 471         } elsif ($ty eq 'Packaging') {
 472             push @brw_cl, $cl;
 473             $cur = $p0;
 474             next;
 475         } elsif ($ty eq 'BreakwaterStart') {
 476             $build_start->('FirstPackaging', $cur);
 477         } elsif ($ty eq 'Upstream') {
 478             push @upp_cl, $cl;
 479             $cur = $p0;
 480             next;
 481         } elsif ($ty eq 'Mixed') {
 482             my $queue = sub {
 483                 my ($q, $wh) = @_;
 484                 my $cls = { $cl, $xmsg->("split mixed commit: $wh part") };
 485                 push @$q, $cls;
 486             };
 487             $queue->(\@brw_cl, "debian");
 488             $queue->(\@upp_cl, "upstream");
 489             $rewrite_from_here->();
 490             $cur = $p0;
 491             next;
 492         } elsif ($ty eq 'Pseudomerge') {
 493             my $contrib = $cl->{Contributor}{CommitId};
 494             print $report " Contributor=$contrib" if $report;
 495             push @pseudomerges, $cl;
 496             $rewrite_from_here->();
 497             $cur = $contrib;
 498             next;
 499         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 500             $build_start->("PreviousBreakwater", $cur);
 501         } elsif ($ty eq 'DgitImportUnpatched') {
 502             my $pm = $pseudomerges[-1];
 503             if (defined $pm) {
 504                 # To an extent, this is heuristic.  Imports don't have
 505                 # a useful history of the debian/ branch.  We assume
 506                 # that the first pseudomerge after an import has a
 507                 # useful history of debian/, and ignore the histories
 508                 # from later pseudomerges.  Often the first pseudomerge
 509                 # will be the dgit import of the upload to the actual
 510                 # suite intended by the non-dgit NMUer, and later
 511                 # pseudomerges may represent in-archive copies.
 512                 my $ovwrs = $pm->{Overwritten};
 513                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 514                     if $report;
 515                 if (@$ovwrs != 1) {
 516                     return $bomb->();
 517                 }
 518                 my $ovwr = $ovwrs->[0]{CommitId};
 519                 printf $report " Overwr=%s", $ovwr if $report;
 520                 # This import has a tree which is just like a
 521                 # breakwater tree, but it has the wrong history.  It
 522                 # ought to have the previous breakwater (which the
 523                 # pseudomerge overwrote) as an ancestor.  That will
 524                 # make the history of the debian/ files correct.  As
 525                 # for the upstream version: either it's the same as
 526                 # was ovewritten (ie, same as the previous
 527                 # breakwater), in which case that history is precisely
 528                 # right; or, otherwise, it was a non-gitish upload of a
 529                 # new upstream version.  We can tell these apart by
 530                 # looking at the tree of the supposed upstream.
 531                 push @brw_cl, {
 532                     %$cl,
 533                     SpecialMethod => 'DgitImportDebianUpdate',
 534                     $xmsg->("convert dgit import: debian changes")
 535                 };
 536                 my $differs = (get_differs $ovwr, $cl->{Tree});
 537                 printf $report " Differs=%#x", $differs if $report;
 538                 if ($differs & D_UPS) {
 539                     printf $report " D_UPS" if $report;
 540                     # This will also trigger if a non-dgit git-based NMU
 541                     # deleted .gitignore (which is a thing that some of
 542                     # the existing git tools do if the user doesn't
 543                     # somehow tell them not to).  Ah well.
 544                     push @brw_cl, {
 545                         %$cl,
 546                         SpecialMethod => 'DgitImportUpstreamUpdate',
 547                         $xmsg->("convert dgit import: upstream changes")
 548                     };
 549                 }
 550                 $prline->(" Import");
 551                 $rewrite_from_here->();
 552                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 553                 $cur = $ovwr;
 554                 next;
 555             } else {
 556                 # Everything is from this import.  This kind of import
 557                 # is already in valid breakwater format, with the
 558                 # patches as commits.
 559                 printf $report " NoPM" if $report;
 560                 # last thing we processed will have been the first patch,
 561                 # if there is one; which is fine, so no need to rewrite
 562                 # on account of this import
 563                 $build_start->("ImportOrigin", $cur);
 564             }
 565             die "$ty ?";
 566         } else {
 567             return $bomb->();
 568         }
 569     }
 570     $prprdelim->();
 571     return if $nogenerate;
 572
 573     # Now we build it back up again
 574
 575     fresh_workarea();
 576
 577     my $rewriting = 0;
 578
 579     my $rm_tree_cached = sub {
 580         my ($subdir) = @_;
 581         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 582     };
 583     my $read_tree_debian = sub {
 584         my ($treeish) = @_;
 585         $rm_tree_cached->(qw(debian));
 586         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 587     };
 588     my $read_tree_upstream = sub {
 589         my ($treeish) = @_;
 590         runcmd @git, qw(read-tree), $treeish;
 591         $read_tree_debian->($build);
 592     };
 593
 594     my $committer_authline = calculate_committer_authline();
 595
 596     in_workarea sub {
 597         mkdir $rd or $!==EEXIST or die $!;
 598         my $current_method;
 599         foreach my $cl (qw(Debian), (reverse @brw_cl),
 600                         { SpecialMethod => 'RecordBreakwaterTip' },
 601                         qw(Upstream), (reverse @upp_cl)) {
 602             if (!ref $cl) {
 603                 $current_method = $cl;
 604                 next;
 605             }
 606             my $method = $cl->{SpecialMethod} // $current_method;
 607             my @parents = ($build);
 608             my $cltree = $cl->{CommitId};
 609             if ($method eq 'Debian') {
 610                 $read_tree_debian->($cltree);
 611             } elsif ($method eq 'Upstream') {
 612                 $read_tree_upstream->($cltree);
 613             } elsif ($method eq 'StartRewrite') {
 614                 $rewriting = 1;
 615                 next;
 616             } elsif ($method eq 'RecordBreakwaterTip') {
 617                 $breakwater = $build;
 618                 next;
 619             } elsif ($method eq 'DgitImportDebianUpdate') {
 620                 $read_tree_debian->($cltree);
 621                 $rm_tree_cached->(qw(debian/patches));
 622             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 623                 $read_tree_upstream->($cltree);
 624                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 625             } else {
 626                 confess "$method ?";
 627             }
 628             $rewriting ||= $cl ne pop @processed;
 629             my $newtree = cmdoutput @git, qw(write-tree);
 630             my $ch = $cl->{Hdr};
 631             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 632             $ch =~ s{^parent .*\n}{}m;
 633             $ch =~ s{(?=^author)}{
 634                 map { "parent $_\n" } @parents
 635             }me or confess "$ch ?";
 636             if ($rewriting) {
 637                 $ch =~ s{^committer .*$}{$committer_authline}m
 638                     or confess "$ch ?";
 639             }
 640             my $cf = "$rd/m$rewriting";
 641             open CD, ">", $cf or die $!;
 642             print CD $ch, "\n", $cl->{Msg} or die $!;
 643             close CD or die $!;
 644             my @cmd = (@git, qw(hash-object));
 645             push @cmd, qw(-w) if $rewriting;
 646             push @cmd, qw(-t commit), $cf;
 647             my $newcommit = cmdoutput @cmd;
 648             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 649             $build = $newcommit;
 650         }
 651     };
 652
 653     runcmd @git, qw(diff-tree --quiet), $input, $build;
 654
 655     return ($build, $breakwater);
 656 }
 657
 658 sub get_head () { return git_rev_parse qw(HEAD); }
 659
 660 sub update_head ($$$) {
 661     my ($old, $new, $mrest) = @_;
 662     runcmd @git, qw(update-ref -m), "git-debrebase $mrest", $new, $old;
 663 }
 664
 665 sub cmd_launder () {
 666     badusage "no arguments to launder allowed" if @ARGV;
 667     my $old = get_head();
 668     my ($tip,$breakwater) = walk $old;
 669     update_head $old, $tip, 'launder';
 670     # no tree changes except debian/patches
 671     runcmd @git, qw(rm --quiet -rf debian/patches);
 672     printf "# breakwater tip\n%s\n", $breakwater;
 673 }
 674
 675 sub cmd_analyse () {
 676     die if ($ARGV[0]//'') =~ m/^-/;
 677     badusage "too many arguments to analyse" if @ARGV>1;
 678     my ($old) = @ARGV;
 679     if (defined $old) {
 680         $old = git_rev_parse $old;
 681     } else {
 682         $old = get_head();
 683     }
 684     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 685     STDOUT->error and die $!;
 686 }
 687
 688 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 689 initdebug('git-debrebase ');
 690 enabledebug if $debuglevel;
 691
 692 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 693 chdir $toplevel or die "chdir $toplevel: $!";
 694
 695 my $cmd = shift @ARGV;
 696 my $cmdfn = $cmd;
 697 $cmdfn =~ y/-/_/;
 698 $cmdfn = ${*::}{"cmd_$cmdfn"};
 699
 700 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 701 $cmdfn->();