git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # usages:
  23 #
  24 #    git-debrebase [<options>] new-upstream-v0 \
  25 #             <new-version> <orig-commitish> \
  26 #            [<extra-orig-name> <extra-orig-commitish> ...] \
  27 #            [<git-rebase options>...]
  28 #
  29 #    git-debrebase [<options> --] [<git-rebase options...>]
  30 #    git-debrebase [<options>] analyse
  31 #    git-debrebase [<options>] launder         # prints breakwater tip etc.
  32 #    git-debrebase [<options>] downstream-rebase-launder-v0  # experimental
  33 #
  34 #    git-debrebase [<options>] gbp2debrebase-v0 \
  35 #             <upstream>
  36
  37 # problems / outstanding questions:
  38 #
  39 #  *  dgit push with a `3.0 (quilt)' package means doing quilt
  40 #     fixup.  Usually this involves recommitting the whole patch
  41 #     series, one at a time, with dpkg-source --commit.  This is
  42 #     terribly terribly slow.  (Maybe this should be fixed in dgit.)
  43 #
  44 #  * dgit push usually needs to (re)make a pseudomerge.  The "first"
  45 #    git-debrebase stripped out the previous pseudomerge and could
  46 #    have remembeed the HEAD.  But it's not quite clear what history
  47 #    ought to be preserved and what should be discarded.  For now
  48 #    the user will have to tell dgit --overwrite.
  49 #
  50 #    To fix this, do we need a new push hook for dgit ?
  51 #
  52 #  * Workflow is currently clumsy.  Lots of spurious runes to type.
  53 #    There's not even a guide.
  54 #
  55 #  * There are no tests.
  56 #
  57 #  * new-upstream-v0 has a terrible UI.  You end up with giant
  58 #    runic command lines.
  59 #
  60 #    One consequence of the lack of richness it can need --force in
  61 #    fairly sensible situations and there is no way to tell it what
  62 #    you are really trying to do, other than just --force.  There
  63 #    should be an interface with some default branch names.
  64 #
  65 #  * There should be a standard convention for the version number,
  66 #    and unfinalised or not changelog, after new-upstream.
  67 #
  68 #  * Handing of multi-orig dgit new-upstream .dsc imports is known to
  69 #    be broken.  They may be not recognised, improperly converted, or
  70 #    their conversion may be unrecognised.
  71 #
  72 #  * Docs need writing and updating.  Even README.git-debrebase
  73 #    describes a design but may not reflect the implementation.
  74 #
  75 #  * We need to develop a plausible model that works for derivatives,
  76 #    who probably want to maintain their stack on top of Debian's.
  77 #    downstream-rebase-launder-v0 may be a starting point?
  78
  79 use strict;
  80
  81 use Debian::Dgit qw(:DEFAULT :playground);
  82 setup_sigwarn();
  83
  84 use Memoize;
  85 use Carp;
  86 use POSIX;
  87 use Data::Dumper;
  88 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  89 use Dpkg::Version;
  90 use File::FnMatch qw(:fnmatch);
  91
  92 our ($opt_force, $opt_noop_ok);
  93
  94 our $us = qw(git-debrebase);
  95
  96 sub badusage ($) {
  97     my ($m) = @_;
  98     die "bad usage: $m\n";
  99 }
 100
 101 sub cfg ($;$) {
 102     my ($k, $optional) = @_;
 103     $/ = "\0";
 104     my @cmd = qw(git config -z);
 105     push @cmd, qw(--get-all) if wantarray;
 106     push @cmd, $k;
 107     my $out = cmdoutput_errok @cmd;
 108     if (!defined $out) {
 109         fail "missing required git config $k" unless $optional;
 110         return ();
 111     }
 112     return split /\0/, $out;
 113 }
 114
 115 memoize('cfg');
 116
 117 sub dd ($) {
 118     my ($v) = @_;
 119     my $dd = new Data::Dumper [ $v ];
 120     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 121     return Dump $dd;
 122 }
 123
 124 sub get_commit ($) {
 125     my ($objid) = @_;
 126     my $data = (git_cat_file $objid, 'commit');
 127     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 128     return ($`,$');
 129 }
 130
 131 sub D_UPS ()      { 0x02; } # upstream files
 132 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 133 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 134 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 135 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 136 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 137
 138 our $playprefix = 'debrebase';
 139 our $rd;
 140 our $workarea;
 141
 142 our @git = qw(git);
 143
 144 sub in_workarea ($) {
 145     my ($sub) = @_;
 146     changedir $workarea;
 147     my $r = eval { $sub->(); };
 148     { local $@; changedir $maindir; }
 149     die $@ if $@;
 150 }
 151
 152 sub fresh_workarea () {
 153     $workarea = fresh_playground "$playprefix/work";
 154     in_workarea sub { playtree_setup };
 155 }
 156
 157 sub get_differs ($$) {
 158     my ($x,$y) = @_;
 159     # This resembles quiltify_trees_differ, in dgit, a bit.
 160     # But we don't care about modes, or dpkg-source-unrepresentable
 161     # changes, and we don't need the plethora of different modes.
 162     # Conversely we need to distinguish different kinds of changes to
 163     # debian/ and debian/patches/.
 164
 165     my $differs = 0;
 166
 167     my $rundiff = sub {
 168         my ($opts, $limits, $fn) = @_;
 169         my @cmd = (@git, qw(diff-tree -z --no-renames));
 170         push @cmd, @$opts;
 171         push @cmd, "$_:" foreach $x, $y;
 172         push @cmd, '--', @$limits;
 173         my $diffs = cmdoutput @cmd;
 174         foreach (split /\0/, $diffs) { $fn->(); }
 175     };
 176
 177     $rundiff->([qw(--name-only)], [], sub {
 178         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 179     });
 180
 181     if ($differs & DS_DEB) {
 182         $differs &= ~DS_DEB;
 183         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 184             $differs |=
 185                 m{^debian/patches/}      ? D_PAT_OTH  :
 186                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 187                                            D_DEB_OTH;
 188         });
 189         die "mysterious debian changes $x..$y"
 190             unless $differs & (D_PAT_OTH|DS_DEB);
 191     }
 192
 193     if ($differs & D_PAT_OTH) {
 194         my $mode;
 195         $differs &= ~D_PAT_OTH;
 196         my $pat_oth = sub {
 197             $differs |= D_PAT_OTH;
 198             no warnings qw(exiting);  last;
 199         };
 200         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 201             no warnings qw(exiting);
 202             if (!defined $mode) {
 203                 $mode = $_;  next;
 204             }
 205             die unless s{^debian/patches/}{};
 206             my $ok;
 207             if ($mode eq 'A' && !m/\.series$/s) {
 208                 $ok = 1;
 209             } elsif ($mode eq 'M' && $_ eq 'series') {
 210                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 211                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 212                 chomp $x_s;  $x_s .= "\n";
 213                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 214             } else {
 215                 # nope
 216             }
 217             $mode = undef;
 218             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 219         });
 220         die "mysterious debian/patches changes $x..$y"
 221             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 222     }
 223
 224     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 225
 226     return $differs;
 227 }
 228
 229 sub commit_pr_info ($) {
 230     my ($r) = @_;
 231     return Data::Dumper->dump([$r], [qw(commit)]);
 232 }
 233
 234 sub calculate_committer_authline () {
 235     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 236         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 237     my ($h,$m) = get_commit $c;
 238     $h =~ m/^committer .*$/m or confess "($h) ?";
 239     return $&;
 240 }
 241
 242 sub rm_subdir_cached ($) {
 243     my ($subdir) = @_;
 244     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 245 }
 246
 247 sub read_tree_subdir ($$) {
 248     my ($subdir, $new_tree_object) = @_;
 249     rm_subdir_cached $subdir;
 250     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 251 }
 252
 253 sub make_commit ($$) {
 254     my ($parents, $message_paras) = @_;
 255     my $tree = cmdoutput @git, qw(write-tree);
 256     my @cmd = (@git, qw(commit-tree), $tree);
 257     push @cmd, qw(-p), $_ foreach @$parents;
 258     push @cmd, qw(-m), $_ foreach @$message_paras;
 259     return cmdoutput @cmd;
 260 }
 261
 262 our @fproblem_force_opts;
 263 our $fproblems_forced;
 264 our $fproblems_tripped;
 265 sub fproblem ($$) {
 266     my ($tag,$msg) = @_;
 267     if (grep { $_ eq $tag } @fproblem_force_opts) {
 268         $fproblems_forced++;
 269         print STDERR "git-debrebase: safety catch overridden (-f$tag): $msg\n";
 270     } else {
 271         $fproblems_tripped++;
 272         print STDERR "git-debrebase: safety catch tripped (-f$tag): $msg\n";
 273     }
 274 }
 275
 276 sub fproblems_maybe_bail () {
 277     if ($fproblems_forced) {
 278         printf STDERR
 279             "%s: safety catch trips: %d overriden by individual -f options\n",
 280             $us, $fproblems_forced;
 281     }
 282     if ($fproblems_tripped) {
 283         if ($opt_force) {
 284             printf STDERR
 285                 "%s: safety catch trips: %d overriden by global --force\n",
 286                 $us, $fproblems_tripped;
 287         } else {
 288             fail sprintf
 289   "%s: safety catch trips: %d blockers (you could -f<tag>, or --force)",
 290                 $us, $fproblems_tripped;
 291         }
 292     }
 293 }
 294 sub any_fproblems () {
 295     return $fproblems_forced || $fproblems_tripped;
 296 }
 297
 298 # classify returns an info hash like this
 299 #   CommitId => $objid
 300 #   Hdr => # commit headers, including 1 final newline
 301 #   Msg => # commit message (so one newline is dropped)
 302 #   Tree => $treeobjid
 303 #   Type => (see below)
 304 #   Parents = [ {
 305 #       Ix => $index # ie 0, 1, 2, ...
 306 #       CommitId
 307 #       Differs => return value from get_differs
 308 #       IsOrigin
 309 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 310 #     } ...]
 311 #   NewMsg => # commit message, but with any [dgit import ...] edited
 312 #             # to say "[was: ...]"
 313 #
 314 # Types:
 315 #   Packaging
 316 #   Changelog
 317 #   Upstream
 318 #   AddPatches
 319 #   Mixed
 320 #   Unknown
 321 #
 322 #   Pseudomerge
 323 #     has additional entres in classification result
 324 #       Overwritten = [ subset of Parents ]
 325 #       Contributor = $the_remaining_Parent
 326 #
 327 #   DgitImportUnpatched
 328 #     has additional entry in classification result
 329 #       OrigParents = [ subset of Parents ]
 330 #
 331 #   BreakwaterUpstreamMerge
 332 #     has additional entry in classification result
 333 #       OrigParents = [ subset of Parents ]  # singleton list
 334
 335 sub parsecommit ($;$) {
 336     my ($objid, $p_ref) = @_;
 337     # => hash with                   CommitId Hdr Msg Tree Parents
 338     #    Parents entries have only   Ix CommitId
 339     #    $p_ref, if provided, must be [] and is used as a base for Parents
 340
 341     $p_ref //= [];
 342     die if @$p_ref;
 343
 344     my ($h,$m) = get_commit $objid;
 345
 346     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 347     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 348
 349     my $r = {
 350         CommitId => $objid,
 351         Hdr => $h,
 352         Msg => $m,
 353         Tree => $t,
 354         Parents => $p_ref,
 355     };
 356
 357     foreach my $ph (@ph) {
 358         push @$p_ref, {
 359             Ix => scalar @$p_ref,
 360             CommitId => $ph,
 361         };
 362     }
 363
 364     return $r;
 365 }
 366
 367 sub classify ($) {
 368     my ($objid) = @_;
 369
 370     my @p;
 371     my $r = parsecommit($objid, \@p);
 372     my $t = $r->{Tree};
 373
 374     foreach my $p (@p) {
 375         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 376     }
 377
 378     printdebug "classify $objid \$t=$t \@p",
 379         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 380         "\n";
 381
 382     my $classify = sub {
 383         my ($type, @rest) = @_;
 384         $r = { %$r, Type => $type, @rest };
 385         if ($debuglevel) {
 386             printdebug " = $type ".(dd $r)."\n";
 387         }
 388         return $r;
 389     };
 390     my $unknown = sub {
 391         my ($why) = @_;
 392         $r = { %$r, Type => qw(Unknown) };
 393         printdebug " ** Unknown\n";
 394         return $r;
 395     };
 396
 397     my $claims_to_be_breakwater =
 398         $r->{Msg} =~ m{^\[git-debrebase breakwater.*\]$}m;
 399
 400     if (@p == 1) {
 401         if ($claims_to_be_breakwater) {
 402             return $unknown->("single-parent git-debrebase breakwater \`merge'");
 403         }
 404         my $d = $r->{Parents}[0]{Differs};
 405         if ($d == D_PAT_ADD) {
 406             return $classify->(qw(AddPatches));
 407         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 408             return $unknown->("edits debian/patches");
 409         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 410             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 411             if ($ty eq 'tree') {
 412                 if ($d == D_DEB_CLOG) {
 413                     return $classify->(qw(Changelog));
 414                 } else {
 415                     return $classify->(qw(Packaging));
 416                 }
 417             } elsif ($ty eq 'missing') {
 418                 return $classify->(qw(BreakwaterStart));
 419             } else {
 420                 return $unknown->("parent's debian is not a directory");
 421             }
 422         } elsif ($d == D_UPS) {
 423             return $classify->(qw(Upstream));
 424         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 425             return $classify->(qw(Mixed));
 426         } elsif ($d == 0) {
 427             return $unknown->("no changes");
 428         } else {
 429             confess "internal error $objid ?";
 430         }
 431     }
 432     if (!@p) {
 433         return $unknown->("origin commit");
 434     }
 435
 436     my @identical = grep { !$_->{Differs} } @p;
 437     if (@p == 2 && @identical == 1 && !$claims_to_be_breakwater
 438         # breakwater merges can look like pseudomerges, if they are
 439         # "declare" commits (ie, there are no upstream changes)
 440        ) {
 441         my @overwritten = grep { $_->{Differs} } @p;
 442         confess "internal error $objid ?" unless @overwritten==1;
 443         return $classify->(qw(Pseudomerge),
 444                            Overwritten => $overwritten[0],
 445                            Contributor => $identical[0]);
 446     }
 447     if (@p == 2 && @identical == 2) {
 448         my @bytime = nsort_by {
 449             my ($ph,$pm) = get_commit $_->{CommitId};
 450             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 451             $1;
 452         } @p;
 453         return $classify->(qw(Pseudomerge),
 454                            SubType => qw(Ambiguous),
 455                            Overwritten => $bytime[0],
 456                            Contributor => $bytime[1]);
 457     }
 458     foreach my $p (@p) {
 459         my ($p_h, $p_m) = get_commit $p->{CommitId};
 460         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 461         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 462     }
 463     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 464     my $m2 = $r->{Msg};
 465     if (!(grep { !$_->{IsOrigin} } @p) and
 466         (@orig_ps >= @p - 1) and
 467         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 468         $r->{NewMsg} = $m2;
 469         return $classify->(qw(DgitImportUnpatched),
 470                            OrigParents => \@orig_ps);
 471     }
 472
 473     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 474     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 475
 476     # How to decide about l/r ordering of breakwater merges ?  git
 477     # --topo-order prefers to expand 2nd parent first.  There's
 478     # already an easy rune to look for debian/ history anyway (git log
 479     # debian/) so debian breakwater branch should be 1st parent; that
 480     # way also there's also an easy rune to look for the upstream
 481     # patches (--topo-order).
 482
 483     # The above tells us which way *we* will generate them.  But we
 484     # might encounter ad-hoc breakwater merges generated manually,
 485     # which might be the other way around.  In principle, in some odd
 486     # situations, a breakwater merge might have two identical parents.
 487     # In that case we guess which way round it is (ie, which parent
 488     # has the upstream history).  The order of the 2-iteration loop
 489     # controls which guess we make.
 490
 491     foreach my $prevbrw (qw(0 1)) {
 492         if (@p == 2 &&
 493             !$haspatches &&
 494             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 495             !($p[!$prevbrw]{Differs} & ~DS_DEB) && # no non-debian changess
 496             !($p[$prevbrw]{Differs} & ~D_UPS)) { # no non-upstream changes
 497             return $classify->(qw(BreakwaterUpstreamMerge),
 498                                OrigParents => [ $p[!$prevbrw] ]);
 499         }
 500     }
 501
 502     # multi-orig upstreams are represented with a breakwater merge
 503     # from a single upstream commit which combines the orig tarballs
 504
 505     return $unknown->("complex merge");
 506 }
 507
 508 sub walk ($;$$);
 509 sub walk ($;$$) {
 510     my ($input,
 511         $nogenerate,$report) = @_;
 512     # => ($tip, $breakwater_tip, $last_upstream_merge_in_breakwater)
 513     # (or nothing, if $nogenerate)
 514
 515     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 516
 517     # go through commits backwards
 518     # we generate two lists of commits to apply:
 519     # breakwater branch and upstream patches
 520     my (@brw_cl, @upp_cl, @processed);
 521     my %found;
 522     my $upp_limit;
 523     my @pseudomerges;
 524
 525     my $cl;
 526     my $xmsg = sub {
 527         my ($prose, $info) = @_;
 528         my $ms = $cl->{Msg};
 529         chomp $ms;
 530         $info //= '';
 531         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 532         return (Msg => $ms);
 533     };
 534     my $rewrite_from_here = sub {
 535         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 536         push @brw_cl, $sp_cl;
 537         push @processed, $sp_cl;
 538     };
 539     my $cur = $input;
 540
 541     my $prdelim = "";
 542     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 543
 544     my $prline = sub {
 545         return unless $report;
 546         print $report $prdelim, @_;
 547         $prdelim = "\n";
 548     };
 549
 550     my $bomb = sub { # usage: return $bomb->();
 551         print $report " Unprocessable" if $report;
 552         $prprdelim->();
 553         if ($nogenerate) {
 554             return (undef,undef);
 555         }
 556         die "commit $cur: Cannot cope with this commit (d.".
 557             (join ' ', map { sprintf "%#x", $_->{Differs} }
 558              @{ $cl->{Parents} }). ")";
 559     };
 560
 561     my $build;
 562     my $breakwater;
 563
 564     my $build_start = sub {
 565         my ($msg, $parent) = @_;
 566         $prline->(" $msg");
 567         $build = $parent;
 568         no warnings qw(exiting); last;
 569     };
 570
 571     my $last_upstream_update;
 572
 573     for (;;) {
 574         $cl = classify $cur;
 575         my $ty = $cl->{Type};
 576         my $st = $cl->{SubType};
 577         $prline->("$cl->{CommitId} $cl->{Type}");
 578         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 579         push @processed, $cl;
 580         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 581         if ($ty eq 'AddPatches') {
 582             $cur = $p0;
 583             $rewrite_from_here->();
 584             next;
 585         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 586             push @brw_cl, $cl;
 587             $cur = $p0;
 588             next;
 589         } elsif ($ty eq 'BreakwaterStart') {
 590             $last_upstream_update = $cur;
 591             $build_start->('FirstPackaging', $cur);
 592         } elsif ($ty eq 'Upstream') {
 593             push @upp_cl, $cl;
 594             $cur = $p0;
 595             next;
 596         } elsif ($ty eq 'Mixed') {
 597             my $queue = sub {
 598                 my ($q, $wh) = @_;
 599                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 600                 push @$q, $cls;
 601             };
 602             $queue->(\@brw_cl, "debian");
 603             $queue->(\@upp_cl, "upstream");
 604             $rewrite_from_here->();
 605             $cur = $p0;
 606             next;
 607         } elsif ($ty eq 'Pseudomerge') {
 608             my $contrib = $cl->{Contributor}{CommitId};
 609             print $report " Contributor=$contrib" if $report;
 610             push @pseudomerges, $cl;
 611             $rewrite_from_here->();
 612             $cur = $contrib;
 613             next;
 614         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 615             $last_upstream_update = $cur;
 616             $build_start->("PreviousBreakwater", $cur);
 617         } elsif ($ty eq 'DgitImportUnpatched') {
 618             my $pm = $pseudomerges[-1];
 619             if (defined $pm) {
 620                 # To an extent, this is heuristic.  Imports don't have
 621                 # a useful history of the debian/ branch.  We assume
 622                 # that the first pseudomerge after an import has a
 623                 # useful history of debian/, and ignore the histories
 624                 # from later pseudomerges.  Often the first pseudomerge
 625                 # will be the dgit import of the upload to the actual
 626                 # suite intended by the non-dgit NMUer, and later
 627                 # pseudomerges may represent in-archive copies.
 628                 my $ovwrs = $pm->{Overwritten};
 629                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 630                     if $report;
 631                 if (@$ovwrs != 1) {
 632                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 633                     return $bomb->();
 634                 }
 635                 my $ovwr = $ovwrs->[0]{CommitId};
 636                 printf $report " Overwr=%s", $ovwr if $report;
 637                 # This import has a tree which is just like a
 638                 # breakwater tree, but it has the wrong history.  It
 639                 # ought to have the previous breakwater (which the
 640                 # pseudomerge overwrote) as an ancestor.  That will
 641                 # make the history of the debian/ files correct.  As
 642                 # for the upstream version: either it's the same as
 643                 # was ovewritten (ie, same as the previous
 644                 # breakwater), in which case that history is precisely
 645                 # right; or, otherwise, it was a non-gitish upload of a
 646                 # new upstream version.  We can tell these apart by
 647                 # looking at the tree of the supposed upstream.
 648                 push @brw_cl, {
 649                     %$cl,
 650                     SpecialMethod => 'DgitImportDebianUpdate',
 651                     $xmsg->("convert dgit import: debian changes")
 652                 };
 653                 my $differs = (get_differs $ovwr, $cl->{Tree});
 654                 printf $report " Differs=%#x", $differs if $report;
 655                 if ($differs & D_UPS) {
 656                     printf $report " D_UPS" if $report;
 657                     # This will also trigger if a non-dgit git-based NMU
 658                     # deleted .gitignore (which is a thing that some of
 659                     # the existing git tools do if the user doesn't
 660                     # somehow tell them not to).  Ah well.
 661                     push @brw_cl, {
 662                         %$cl,
 663                         SpecialMethod => 'DgitImportUpstreamUpdate',
 664                         $xmsg->("convert dgit import: upstream changes",
 665                                 " breakwater")
 666                     };
 667                 }
 668                 $prline->(" Import");
 669                 $rewrite_from_here->();
 670                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 671                 die 'BUG $upp_limit is not used anywhere?';
 672                 $cur = $ovwr;
 673                 next;
 674             } else {
 675                 # Everything is from this import.  This kind of import
 676                 # is already in valid breakwater format, with the
 677                 # patches as commits.
 678                 printf $report " NoPM" if $report;
 679                 # last thing we processed will have been the first patch,
 680                 # if there is one; which is fine, so no need to rewrite
 681                 # on account of this import
 682                 $build_start->("ImportOrigin", $cur);
 683             }
 684             die "$ty ?";
 685         } else {
 686             printdebug "*** WALK BOMB unrecognised\n";
 687             return $bomb->();
 688         }
 689     }
 690     $prprdelim->();
 691
 692     printdebug "*** WALK prep done cur=$cur".
 693         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 694
 695     return if $nogenerate;
 696
 697     # Now we build it back up again
 698
 699     fresh_workarea();
 700
 701     my $rewriting = 0;
 702
 703     my $read_tree_debian = sub {
 704         my ($treeish) = @_;
 705         read_tree_subdir 'debian', "$treeish:debian";
 706         rm_subdir_cached 'debian/patches';
 707     };
 708     my $read_tree_upstream = sub {
 709         my ($treeish) = @_;
 710         runcmd @git, qw(read-tree), $treeish;
 711         $read_tree_debian->($build);
 712     };
 713
 714     my $committer_authline = calculate_committer_authline();
 715
 716     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 717
 718     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 719
 720     in_workarea sub {
 721         mkdir $rd or $!==EEXIST or die $!;
 722         my $current_method;
 723         runcmd @git, qw(read-tree), $build;
 724         foreach my $cl (qw(Debian), (reverse @brw_cl),
 725                         { SpecialMethod => 'RecordBreakwaterTip' },
 726                         qw(Upstream), (reverse @upp_cl)) {
 727             if (!ref $cl) {
 728                 $current_method = $cl;
 729                 next;
 730             }
 731             my $method = $cl->{SpecialMethod} // $current_method;
 732             my @parents = ($build);
 733             my $cltree = $cl->{CommitId};
 734             printdebug "WALK BUILD ".($cltree//'undef').
 735                 " $method (rewriting=$rewriting)\n";
 736             if ($method eq 'Debian') {
 737                 $read_tree_debian->($cltree);
 738             } elsif ($method eq 'Upstream') {
 739                 $read_tree_upstream->($cltree);
 740             } elsif ($method eq 'StartRewrite') {
 741                 $rewriting = 1;
 742                 next;
 743             } elsif ($method eq 'RecordBreakwaterTip') {
 744                 $breakwater = $build;
 745                 next;
 746             } elsif ($method eq 'DgitImportDebianUpdate') {
 747                 $read_tree_debian->($cltree);
 748                 rm_subdir_cached qw(debian/patches);
 749             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 750                 $read_tree_upstream->($cltree);
 751                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 752             } else {
 753                 confess "$method ?";
 754             }
 755             if (!$rewriting) {
 756                 my $procd = (pop @processed) // 'UNDEF';
 757                 if ($cl ne $procd) {
 758                     $rewriting = 1;
 759                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 760                 }
 761             }
 762             my $newtree = cmdoutput @git, qw(write-tree);
 763             my $ch = $cl->{Hdr};
 764             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 765             $ch =~ s{^parent .*\n}{}m;
 766             $ch =~ s{(?=^author)}{
 767                 join '', map { "parent $_\n" } @parents
 768             }me or confess "$ch ?";
 769             if ($rewriting) {
 770                 $ch =~ s{^committer .*$}{$committer_authline}m
 771                     or confess "$ch ?";
 772             }
 773             my $cf = "$rd/m$rewriting";
 774             open CD, ">", $cf or die $!;
 775             print CD $ch, "\n", $cl->{Msg} or die $!;
 776             close CD or die $!;
 777             my @cmd = (@git, qw(hash-object));
 778             push @cmd, qw(-w) if $rewriting;
 779             push @cmd, qw(-t commit), $cf;
 780             my $newcommit = cmdoutput @cmd;
 781             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 782             $build = $newcommit;
 783             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 784                 $last_upstream_update = $cur;
 785             }
 786         }
 787     };
 788
 789     my $final_check = get_differs $build, $input;
 790     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 791         if $final_check & ~D_PAT_ADD;
 792
 793     my @r = ($build, $breakwater, $last_upstream_update);
 794     printdebug "*** WALK RETURN @r\n";
 795     return @r
 796 }
 797
 798 sub get_head () {
 799     git_check_unmodified();
 800     return git_rev_parse qw(HEAD);
 801 }
 802
 803 sub update_head ($$$) {
 804     my ($old, $new, $mrest) = @_;
 805     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 806 }
 807
 808 sub update_head_checkout ($$$) {
 809     my ($old, $new, $mrest) = @_;
 810     update_head $old, $new, $mrest;
 811     runcmd @git, qw(reset --hard);
 812 }
 813
 814 sub update_head_postlaunder ($$$) {
 815     my ($old, $tip, $reflogmsg) = @_;
 816     return if $tip eq $old;
 817     print "git-debrebase: laundered (head was $old)\n";
 818     update_head $old, $tip, $reflogmsg;
 819     # no tree changes except debian/patches
 820     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 821 }
 822
 823 sub cmd_launder () {
 824     badusage "no arguments to launder allowed" if @ARGV;
 825     my $old = get_head();
 826     my ($tip,$breakwater,$last_upstream_merge) = walk $old;
 827     update_head_postlaunder $old, $tip, 'launder';
 828     printf "# breakwater tip\n%s\n", $breakwater;
 829     printf "# working tip\n%s\n", $tip;
 830     printf "# last upstream merge\n%s\n", $last_upstream_merge;
 831 }
 832
 833 sub defaultcmd_rebase () {
 834     my $old = get_head();
 835     my ($tip,$breakwater) = walk $old;
 836     update_head_postlaunder $old, $tip, 'launder for rebase';
 837     @ARGV = qw(-i) unless @ARGV; # make configurable
 838     runcmd @git, qw(rebase), @ARGV, $breakwater;
 839 }
 840
 841 sub cmd_analyse () {
 842     die if ($ARGV[0]//'') =~ m/^-/;
 843     badusage "too many arguments to analyse" if @ARGV>1;
 844     my ($old) = @ARGV;
 845     if (defined $old) {
 846         $old = git_rev_parse $old;
 847     } else {
 848         $old = git_rev_parse 'HEAD';
 849     }
 850     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 851     STDOUT->error and die $!;
 852 }
 853
 854 sub record_ffq_prev () {
 855     # => ('status', "message")
 856     # 'status' may be
 857     #    written          message is undef
 858     #    exists
 859     #    detached
 860     #    weird-symref
 861     #    notbranch
 862     # if not ff from some branch we should be ff from, is an fproblem
 863     # if "written", will have printed something about that to stdout,
 864     #   and also some messages about ff checks
 865     my $current = git_get_symref();
 866     return ('detached', 'detached HEAD') unless defined $current;
 867     return ('weird-symref', 'HEAD symref is not to refs/')
 868         unless $current =~ m{^refs/};
 869     my $ffq_prev = "refs/$ffq_refprefix/$'";
 870
 871     my $currentval = get_head();
 872
 873     my $exists = git_get_ref $ffq_prev;
 874     return ('exists',"$ffq_prev already exists") if $exists;
 875
 876     return ('not-branch', 'HEAD symref is not to refs/heads/')
 877         unless $current =~ m{^refs/heads/};
 878     my $branch = $';
 879
 880     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
 881     my %checked;
 882
 883     my $check = sub {
 884         my ($lrref, $desc) = @_;
 885         my $invert;
 886         for my $chk (@check_specs) {
 887             my $glob = $chk;
 888             $invert = $glob =~ s{^[^!]}{};
 889             last if fnmatch $glob, $lrref;
 890         }
 891         return if $invert;
 892         my $lrval = git_get_ref $lrref;
 893         return unless defined $lrval;
 894
 895         if (is_fast_fwd $lrval, $currentval) {
 896             print "OK, you are ahead of $lrref\n" or die $!;
 897             $checked{$lrref} = 1;
 898         } if (is_fast_fwd $currentval, $lrval) {
 899             $checked{$lrref} = -1;
 900             fproblem 'behind', "you are behind $lrref, divergence risk";
 901         } else {
 902             $checked{$lrref} = -1;
 903             fproblem 'diverged', "you have diverged from $lrref";
 904         }
 905     };
 906
 907     my $merge = cfg "branch.$branch.merge",1;
 908     if (defined $merge && $merge =~ m{^refs/heads/}) {
 909         my $rhs = $';
 910         my $check_remote = sub {
 911             my ($remote, $desc) = (@_);
 912             return unless defined $remote;
 913             $check->("refs/remotes/$remote/$rhs", $desc);
 914         };
 915         $check_remote->((cfg "branch.$branch.remote",1),
 916                         'remote fetch/merge branch');
 917         $check_remote->((cfg "branch.$branch.pushRemote",1) //
 918                         (cfg "branch.$branch.pushDefault",1),
 919                         'remote push branch');
 920     }
 921     if ($branch =~ m{^dgit/}) {
 922         $check->("remotes/dgit/$branch", 'remote dgit branch');
 923     } elsif ($branch =~ m{^master$}) {
 924         $check->("remotes/dgit/dgit/sid", 'remote dgit branch for sid');
 925     }
 926
 927     fproblems_maybe_bail();
 928     runcmd @git, qw(update-ref -m), "record current head for preservation",
 929         $ffq_prev, $currentval, $git_null_obj;
 930     print "Recorded current head for preservation\n" or die $!;
 931     return ('written', undef);
 932 }
 933
 934 sub cmd_new_upstream_v0 () {
 935     # automatically and unconditionally launders before rebasing
 936     # if rebase --abort is used, laundering has still been done
 937
 938     my %pieces;
 939
 940     badusage "need NEW-VERSION UPS-COMMITTISH" unless @ARGV >= 2;
 941
 942     # parse args - low commitment
 943     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
 944     my $new_upstream_version = $new_version->version();
 945
 946     my $new_upstream = git_rev_parse shift @ARGV;
 947
 948     my $piece = sub {
 949         my ($n, @x) = @_; # may be ''
 950         my $pc = $pieces{$n} //= {
 951             Name => $n,
 952             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
 953         };
 954         while (my $k = shift @x) { $pc->{$k} = shift @x; }
 955         $pc;
 956     };
 957
 958     my @newpieces;
 959     my $newpiece = sub {
 960         my ($n, @x) = @_; # may be ''
 961         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
 962         push @newpieces, $pc;
 963     };
 964
 965     $newpiece->('',
 966         OldIx => 0,
 967         New => $new_upstream,
 968     );
 969     while (@ARGV && $ARGV[0] !~ m{^-}) {
 970         my $n = shift @ARGV;
 971
 972         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
 973             unless @ARGV && $ARGV[0] !~ m{^-};
 974
 975         my $c = git_rev_parse shift @ARGV;
 976         die unless $n =~ m/^$extra_orig_namepart_re$/;
 977         $newpiece->($n, New => $c);
 978     }
 979
 980     # now we need to investigate the branch this generates the
 981     # laundered version but we don't switch to it yet
 982     my $old_head = get_head();
 983     my ($old_laundered_tip,$old_bw,$old_upstream_update) = walk $old_head;
 984
 985     my $old_bw_cl = classify $old_bw;
 986     my $old_upstream_update_cl = classify $old_upstream_update;
 987     confess unless $old_upstream_update_cl->{OrigParents};
 988     my $old_upstream = parsecommit
 989         $old_upstream_update_cl->{OrigParents}[0]{CommitId};
 990
 991     $piece->('', Old => $old_upstream->{CommitId});
 992
 993     if ($old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
 994         if ($old_upstream->{Msg} =~
 995  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
 996            ) {
 997             my @oldpieces = ('', split / /, $1);
 998             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
 999             foreach my $i (0..$#oldpieces) {
1000                 my $n = $oldpieces[$i];
1001                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
1002             }
1003         } else {
1004             fproblem 'upstream-confusing',
1005                 "previous upstream $old_upstream->{CommitId} is from".
1006                " git-debrebase but not an \`upstream-combine' commit";
1007         }
1008     }
1009
1010     foreach my $pc (values %pieces) {
1011         if (!$pc->{Old}) {
1012             fproblem 'upstream-new-piece',
1013                 "introducing upstream piece \`$pc->{Name}'";
1014         } elsif (!$pc->{New}) {
1015             fproblem 'upstream-rm-piece',
1016                 "dropping upstream piece \`$pc->{Name}'";
1017         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1018             fproblem 'upstream-not-ff',
1019                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1020         }
1021     }
1022
1023     printdebug "%pieces = ", (dd \%pieces), "\n";
1024     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1025
1026     fproblems_maybe_bail();
1027
1028     my $new_bw;
1029
1030     fresh_workarea();
1031     in_workarea sub {
1032         my @upstream_merge_parents;
1033
1034         if (!any_fproblems()) {
1035             push @upstream_merge_parents, $old_upstream->{CommitId};
1036         }
1037
1038         foreach my $pc (@newpieces) { # always has '' first
1039             if ($pc->{Name}) {
1040                 read_tree_subdir $pc->{Name}, $pc->{New};
1041             } else {
1042                 runcmd @git, qw(read-tree), $pc->{New};
1043             }
1044             push @upstream_merge_parents, $pc->{New};
1045         }
1046
1047         # index now contains the new upstream
1048
1049         if (@newpieces > 1) {
1050             # need to make the upstream subtree merge commit
1051             $new_upstream = make_commit \@upstream_merge_parents,
1052                 [ "Combine upstreams for $new_upstream_version",
1053  ("[git-debrebase upstream-combine . ".
1054  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1055  ": new upstream]"),
1056                 ];
1057         }
1058
1059         # $new_upstream is either the single upstream commit, or the
1060         # combined commit we just made.  Either way it will be the
1061         # "upstream" parent of the breakwater special merge.
1062
1063         read_tree_subdir 'debian', "$old_bw:debian";
1064
1065         # index now contains the breakwater merge contents
1066         $new_bw = make_commit [ $old_bw, $new_upstream ],
1067             [ "Update to upstream $new_upstream_version",
1068  "[git-debrebase breakwater: new upstream $new_upstream_version, merge]",
1069             ];
1070
1071         # Now we have to add a changelog stanza so the Debian version
1072         # is right.
1073         die if unlink "debian";
1074         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1075         unlink "debian/changelog" or $!==ENOENT or die $!;
1076         mkdir "debian" or die $!;
1077         open CN, ">", "debian/changelog" or die $!;
1078         my $oldclog = git_cat_file ":debian/changelog";
1079         $oldclog =~ m/^($package_re) \(\S+\) / or
1080             fail "cannot parse old changelog to get package name";
1081         my $p = $1;
1082         print CN <<END, $oldclog or die $!;
1083 $p ($new_version) UNRELEASED; urgency=medium
1084
1085   * Update to new upstream version $new_upstream_version.
1086
1087  --
1088
1089 END
1090         close CN or die $!;
1091         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1092
1093         # Now we have the final new breakwater branch in the index
1094         $new_bw = make_commit [ $new_bw ],
1095             [ "Update changelog for new upstream $new_upstream_version",
1096               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1097             ];
1098     };
1099
1100     # we have constructed the new breakwater. we now need to commit to
1101     # the laundering output, because git-rebase can't easily be made
1102     # to make a replay list which is based on some other branch
1103
1104     update_head_postlaunder $old_head, $old_laundered_tip,
1105         'launder for new upstream';
1106
1107     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1108     runcmd @cmd;
1109     # now it's for the user to sort out
1110 }
1111
1112 sub cmd_record_ffq_prev () {
1113     badusage "no arguments allowed" if @ARGV;
1114     my ($status, $msg) = record_ffq_prev();
1115     if ($status eq 'exists' && $opt_noop_ok) {
1116         print "Previous head already recorded\n" or die $!;
1117     } elsif ($status eq 'written') {
1118     } else {
1119         fail "Could not preserve: $msg";
1120     }
1121 }
1122
1123 sub cmd_gbp2debrebase () {
1124     badusage "needs 1 optional argument, the upstream" unless @ARGV<=1;
1125     my ($upstream_spec) = @ARGV;
1126     $upstream_spec //= 'refs/heads/upstream';
1127     my $upstream = git_rev_parse $upstream_spec;
1128     my $old_head = get_head();
1129
1130     my $upsdiff = get_differs $upstream, $old_head;
1131     if ($upsdiff & D_UPS) {
1132         runcmd @git, qw(--no-pager diff),
1133             $upstream, $old_head,
1134             qw( -- :!/debian :/);
1135  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1136     }
1137
1138     if (!is_fast_fwd $upstream, $old_head) {
1139         fproblem 'upstream-not-ancestor',
1140             "upstream ($upstream) is not an ancestor of HEAD";
1141     } else {
1142         my $wrong = cmdoutput
1143             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1144              qw(-- :/ :!/debian));
1145         if (length $wrong) {
1146             fproblem 'unexpected-upstream-changes',
1147                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1148             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1149         }
1150     }
1151
1152     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1153         fproblem 'upstream-has-debian',
1154             "upstream ($upstream) contains debian/ directory";
1155     }
1156
1157     fproblems_maybe_bail();
1158
1159     my $work;
1160
1161     fresh_workarea();
1162     in_workarea sub {
1163         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1164         # make a branch out of the patch queue - we'll want this in a mo
1165         runcmd qw(gbp pq import);
1166         # strip the patches out
1167         runcmd @git, qw(checkout -q gdr-internal~0);
1168         rm_subdir_cached 'debian/patches';
1169         $work = make_commit ['HEAD'], [
1170  'git-debrebase import: drop patch queue',
1171  'Delete debian/patches, as part of converting to git-debrebase format.',
1172  '[git-debrebase: gbp2debrebase, drop patches]'
1173                               ];
1174         # make the breakwater pseudomerge
1175         # the tree is already exactly right
1176         $work = make_commit [$work, $upstream], [
1177  'git-debrebase import: declare upstream',
1178  'First breakwater merge.',
1179  '[git-debrebase breakwater: declare upstream]'
1180                               ];
1181
1182         # rebase the patch queue onto the new breakwater
1183         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1184         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1185         $work = git_rev_parse 'HEAD';
1186     };
1187
1188     update_head_checkout $old_head, $work, 'gbp2debrebase';
1189 }
1190
1191 sub cmd_downstream_rebase_launder_v0 () {
1192     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1193     my ($base) = @ARGV;
1194     $base = git_rev_parse $base;
1195     my $old_head = get_head();
1196     my $current = $old_head;
1197     my $topmost_keep;
1198     for (;;) {
1199         if ($current eq $base) {
1200             $topmost_keep //= $current;
1201             print " $current BASE stop\n";
1202             last;
1203         }
1204         my $cl = classify $current;
1205         print " $current $cl->{Type}";
1206         my $keep = 0;
1207         my $p0 = $cl->{Parents}[0]{CommitId};
1208         my $next;
1209         if ($cl->{Type} eq 'Pseudomerge') {
1210             print " ^".($cl->{Contributor}{Ix}+1);
1211             $next = $cl->{Contributor}{CommitId};
1212         } elsif ($cl->{Type} eq 'AddPatches' or
1213                  $cl->{Type} eq 'Changelog') {
1214             print " strip";
1215             $next = $p0;
1216         } else {
1217             print " keep";
1218             $next = $p0;
1219             $keep = 1;
1220         }
1221         print "\n";
1222         if ($keep) {
1223             $topmost_keep //= $current;
1224         } else {
1225             die "to-be stripped changes not on top of the branch\n"
1226                 if $topmost_keep;
1227         }
1228         $current = $next;
1229     }
1230     if ($topmost_keep eq $old_head) {
1231         print "unchanged\n";
1232     } else {
1233         print "updating to $topmost_keep\n";
1234         update_head_checkout
1235             $old_head, $topmost_keep,
1236             'downstream-rebase-launder-v0';
1237     }
1238 }
1239
1240 GetOptions("D+" => \$debuglevel,
1241            'noop-ok', => \$opt_noop_ok,
1242            'f=s' => \@fproblem_force_opts,
1243            'force!') or die badusage "bad options\n";
1244 initdebug('git-debrebase ');
1245 enabledebug if $debuglevel;
1246
1247 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1248 chdir $toplevel or die "chdir $toplevel: $!";
1249
1250 $rd = fresh_playground "$playprefix/misc";
1251
1252 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1253     defaultcmd_rebase();
1254 } else {
1255     my $cmd = shift @ARGV;
1256     my $cmdfn = $cmd;
1257     $cmdfn =~ y/-/_/;
1258     $cmdfn = ${*::}{"cmd_$cmdfn"};
1259
1260     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1261     $cmdfn->();
1262 }