git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$$) {
 267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 268     # if $tree_with_debian is supplied, will use that for debian/
 269     # otherwise will save and restore it.
 270     my $debian =
 271         $tree_with_debian ? "$tree_with_debian:debian"
 272         : cmdoutput @git, qw(write-tree --prefix=debian/);
 273     runcmd @git, qw(read-tree), $treeish;
 274     read_tree_subdir 'debian', $debian;
 275     rm_subdir_cached 'debian/patches' unless $keep_patches;
 276 };
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @snag_force_opts;
 288 sub snag ($$;@) {
 289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 290     if (grep { $_ eq $tag } @snag_force_opts) {
 291         $snags_forced++;
 292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 293     } else {
 294         $snags_tripped++;
 295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 296     }
 297 }
 298
 299 # Important: all mainline code must call snags_maybe_bail after
 300 # any point where snag might be called, but before making changes
 301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 302 # may be called more than once if necessary (but this is not ideal
 303 # because then the messages about number of snags may be confusing).
 304 sub snags_maybe_bail () {
 305     return if all_snags_summarised();
 306     if ($snags_forced) {
 307         printf STDERR
 308             "%s: snags: %d overriden by individual -f options\n",
 309             $us, $snags_forced;
 310     }
 311     if ($snags_tripped) {
 312         if ($opt_force) {
 313             printf STDERR
 314                 "%s: snags: %d overriden by global --force\n",
 315                 $us, $snags_tripped;
 316         } else {
 317             fail sprintf
 318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 319                 $us, $snags_tripped;
 320         }
 321     }
 322     $snags_summarised = $snags_forced + $snags_tripped;
 323 }
 324 sub snags_maybe_bail_early () {
 325     # useful to bail out early without doing a lot of work;
 326     # not a substitute for snags_maybe_bail.
 327     snags_maybe_bail() if $snags_tripped && !$opt_force;
 328 }
 329 sub any_snags () {
 330     return $snags_forced || $snags_tripped;
 331 }
 332
 333 sub gbp_pq_export ($$$) {
 334     my ($bname, $base, $tip) = @_;
 335     # must be run in a workarea.  $bname and patch-queue/$bname
 336     # ought not to exist.  Leaves you on patch-queue/$bname with
 337     # the patches staged but not committed.
 338     printdebug "gbp_pq_export $bname $base $tip\n";
 339     runcmd @git, qw(checkout -q -b), $bname, $base;
 340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 341     my @gbp_cmd = (qw(gbp pq export));
 342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 343     if ($r) {
 344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 345         failedcmd @gbp_cmd;
 346     }
 347     runcmd @git, qw(add -f debian/patches);
 348 }
 349
 350
 351 # xxx allow merge resolution separately from laundering, before git merge
 352 #
 353 # xxx general gdr docs highlight forbidden things
 354 # xxx general gdr docs list allowable things ?
 355 # xxx general gdr docs explicitly forbid some rebase
 356 #
 357 # xxx provide a way for the user to help
 358 # xxx (eg, provide wreckage provide way to continue)
 359
 360 # later/rework?
 361 #  use git-format-patch?
 362 #  our own patch identification algorithm?
 363 #  this is an alternative strategy
 364
 365 sub merge_series ($$;@) {
 366     my ($newbase, $base_q, @input_qs) = @_;
 367     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 368     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 369     # ^ specifies several patch series (currently we only support exactly 2)
 370     # return value is a commit which is the result of
 371     # merging the two versions of the same topic branch
 372     #   $input_q[0] and $input_q[1]
 373     # with respect to the old version
 374     #   $base_q
 375     # all onto $newbase.
 376
 377     # Creates, in *_q, a key MR for its private use
 378
 379     printdebug "merge_series newbase=$newbase\n";
 380
 381     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 382     $base_q->{MR}{S} = 'base';
 383
 384     my %prereq;
 385     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 386     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 387     # $prereq{<patch filename>}               exists or not (even later)
 388
 389     my $result;
 390
 391     local $workarea = fresh_playground "$playprefix/merge";
 392     my $seriesfile = "debian/patches/series";
 393     in_workarea sub {
 394         playtree_setup();
 395         foreach my $q ($base_q, reverse @input_qs) {
 396             my $s = $q->{MR}{S};
 397             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 398             # xxx avoid trying to merge debian/ again here, by
 399             # always using debian/ from newbase
 400             if (open S, $seriesfile) {
 401                 my @earlier;
 402                 while (my $patch = <S>) {
 403                     chomp $patch or die $!;
 404                     $prereq{$patch} //= {};
 405                     foreach my $earlier (@earlier) {
 406                         $prereq{$patch}{$earlier}{$s}++ and die;
 407                     }
 408                     push @earlier, $patch;
 409                     stat "debian/patches/$patch" or die "$patch ?";
 410                 }
 411                 S->error and die "$seriesfile $!";
 412                 close S;
 413             } else {
 414                 die "$seriesfile $!" unless $!==ENOENT;
 415             }
 416             read_tree_upstream $newbase, 1;
 417             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 418                 "Convert $s to patch queue for merging",
 419                 "[git-debrebase merge-innards patch-queue import:".
 420                 " $q->{SeriesTip}]"
 421             ];
 422             printdebug "merge_series  pec $pec ";
 423             runcmd @git, qw(rm -q --cached), $seriesfile;
 424             $pec = make_commit [ $pec ], [
 425                 "Drop series file from $s to avoid merge trouble",
 426                 "[git-debrebase merge-innards patch-queue prep:".
 427                 " $q->{SeriesTip}]"
 428             ];
 429             printdebug "pec' $pec\n";
 430             runcmd @git, qw(reset -q --hard), $pec;
 431             $q->{MR}{PEC} = $pec;
 432         }
 433         # now, because of reverse, we are on $input_q->{MR}{OQC}
 434         runcmd @git, qw(checkout -q -b merge);
 435         printdebug "merge_series merging...\n";
 436         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 437         debugcmd '+', @mergecmd;
 438         $!=0; $?=-1;
 439         if (system @mergecmd) {
 440             failedcmd @mergecmd;
 441         }
 442
 443         printdebug "merge_series merge ok, series...\n";
 444         # We need to construct a new series file
 445         # Firstly, resolve prereq
 446         foreach my $f (sort keys %prereq) {
 447             printdebug "merge_series  patch\t$f\t";
 448             if (!stat_exists "debian/patches/$f") {
 449                 print DEBUG " drop\n" if $debuglevel;
 450                 # git merge deleted it; that's how we tell it's not wanted
 451                 delete $prereq{$f};
 452                 next;
 453             }
 454             print DEBUG " keep\n" if $debuglevel;
 455             foreach my $g (sort keys %{ $prereq{$f} }) {
 456                 my $gfp = $prereq{$f}{$g};
 457                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 458                 if (!!$gfp->{0} == !!$gfp->{1}
 459                     ? $gfp->{0}
 460                     : !$gfp->{base}) {
 461                     print DEBUG "\tkeep\n" if $debuglevel;
 462                 } else {
 463                     print DEBUG "\tdrop\n" if $debuglevel;
 464                     delete $prereq{$f}{$g};
 465                 }
 466             }
 467         }
 468
 469         my $unsat = sub {
 470             my ($f) = @_;
 471             return scalar keys %{ $prereq{$f} };
 472         };
 473
 474         my $nodate = time + 1;
 475         my %authordate;
 476         # $authordate{<patch filename>};
 477         my $authordate = sub {
 478             my ($f) = @_;
 479             $authordate{$f} //= do {
 480                 open PF, "<", "debian/patches/$f" or die "$f $!";
 481                 while (<PF>) {
 482                     return $nodate if m/^$/;
 483                     last if s{^Date: }{};
 484                 }
 485                 chomp;
 486                 return cmdoutput qw(date +%s -d), $_;
 487             };
 488         };
 489
 490         open NS, '>', $seriesfile or die $!;
 491
 492         while (keys %prereq) {
 493             my $best;
 494             foreach my $try (sort keys %prereq) {
 495                 if ($best) {
 496                     next if (
 497                              $unsat->($try) <=> $unsat->($best) or
 498                              $authordate->($try) <=> $authordate->($best) or
 499                              $try cmp $best
 500                             ) >= 0;
 501                 }
 502                 $best = $try;
 503             }
 504             printdebug "merge_series series next $best\n";
 505             print NS "$best\n" or die $!;
 506             delete $prereq{$best};
 507             foreach my $gp (values %prereq) {
 508                 delete $gp->{$best};
 509             }
 510         }
 511
 512         runcmd @git, qw(add), $seriesfile;
 513         runcmd @git, qw(commit --quiet -m), 'Merged series';
 514
 515         printdebug "merge_series series gbp pq import\n";
 516         runcmd qw(gbp pq import);
 517
 518         # OK now we are on patch-queue/merge, and we need to rebase
 519         # onto the intended parent and drop the patches from each one
 520
 521         printdebug "merge_series series ok, building...\n";
 522         my $build = $newbase;
 523         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 524         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 525             my $commit = git_cat_file $c, 'commit';
 526             printdebug "merge_series series ok, building $c\n";
 527             read_tree_upstream $c, 0, $newbase;
 528             my $tree = cmdoutput @git, qw(write-tree);
 529             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 530             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 531             open C, ">", "../mcommit" or die $!;
 532             print C $commit or die $!;
 533             close C or die $!;
 534             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 535         }
 536         $result = $build;
 537         runcmd @git, qw(update-ref refs/heads/result), $result;
 538
 539         runcmd @git, qw(checkout -q -b debug);
 540         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 541         runcmd @git, qw(add .);
 542         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 543         printdebug sprintf "merge_series done debug=%s\n",
 544             git_rev_parse 'HEAD';
 545     };
 546     printdebug "merge_series returns $result\n";
 547     return $result;
 548 }
 549
 550 # classify returns an info hash like this
 551 #   CommitId => $objid
 552 #   Hdr => # commit headers, including 1 final newline
 553 #   Msg => # commit message (so one newline is dropped)
 554 #   Tree => $treeobjid
 555 #   Type => (see below)
 556 #   Parents = [ {
 557 #       Ix => $index # ie 0, 1, 2, ...
 558 #       CommitId
 559 #       Differs => return value from get_differs
 560 #       IsOrigin
 561 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 562 #     } ...]
 563 #   NewMsg => # commit message, but with any [dgit import ...] edited
 564 #             # to say "[was: ...]"
 565 #
 566 # Types:
 567 #   Packaging
 568 #   Changelog
 569 #   Upstream
 570 #   AddPatches
 571 #   Mixed
 572 #
 573 #   Pseudomerge
 574 #     has additional entres in classification result
 575 #       Overwritten = [ subset of Parents ]
 576 #       Contributor = $the_remaining_Parent
 577 #
 578 #   DgitImportUnpatched
 579 #     has additional entry in classification result
 580 #       OrigParents = [ subset of Parents ]
 581 #
 582 #   Anchor
 583 #     has additional entry in classification result
 584 #       OrigParents = [ subset of Parents ]  # singleton list
 585 #
 586 #   TreatAsAnchor
 587 #
 588 #   BreakwaterStart
 589 #
 590 #   Unknown
 591 #     has additional entry in classification result
 592 #       Why => "prose"
 593
 594 sub parsecommit ($;$) {
 595     my ($objid, $p_ref) = @_;
 596     # => hash with                   CommitId Hdr Msg Tree Parents
 597     #    Parents entries have only   Ix CommitId
 598     #    $p_ref, if provided, must be [] and is used as a base for Parents
 599
 600     $p_ref //= [];
 601     die if @$p_ref;
 602
 603     my ($h,$m) = get_commit $objid;
 604
 605     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 606     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 607
 608     my $r = {
 609         CommitId => $objid,
 610         Hdr => $h,
 611         Msg => $m,
 612         Tree => $t,
 613         Parents => $p_ref,
 614     };
 615
 616     foreach my $ph (@ph) {
 617         push @$p_ref, {
 618             Ix => scalar @$p_ref,
 619             CommitId => $ph,
 620         };
 621     }
 622
 623     return $r;
 624 }
 625
 626 sub classify ($) {
 627     my ($objid) = @_;
 628
 629     my @p;
 630     my $r = parsecommit($objid, \@p);
 631     my $t = $r->{Tree};
 632
 633     foreach my $p (@p) {
 634         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 635     }
 636
 637     printdebug "classify $objid \$t=$t \@p",
 638         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 639         "\n";
 640
 641     my $classify = sub {
 642         my ($type, @rest) = @_;
 643         $r = { %$r, Type => $type, @rest };
 644         if ($debuglevel) {
 645             printdebug " = $type ".(dd $r)."\n";
 646         }
 647         return $r;
 648     };
 649     my $unknown = sub {
 650         my ($why) = @_;
 651         $r = { %$r, Type => qw(Unknown), Why => $why };
 652         printdebug " ** Unknown\n";
 653         return $r;
 654     };
 655
 656     if (grep { $_ eq $objid } @opt_anchors) {
 657         return $classify->('TreatAsAnchor');
 658     }
 659
 660     my @identical = grep { !$_->{Differs} } @p;
 661     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 662     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 663
 664     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 665         # multi-orig upstreams are represented with an anchor merge
 666         # from a single upstream commit which combines the orig tarballs
 667
 668         # Every anchor tagged this way must be a merge.
 669         # We are relying on the
 670         #     [git-debrebase anchor: ...]
 671         # commit message annotation in "declare" anchor merges (which
 672         # do not have any upstream changes), to distinguish those
 673         # anchor merges from ordinary pseudomerges (which we might
 674         # just try to strip).
 675         #
 676         # However, the user is going to be doing git-rebase a lot.  We
 677         # really don't want them to rewrite an anchor commit.
 678         # git-rebase trips up on merges, so that is a useful safety
 679         # catch.
 680         #
 681         # BreakwaterStart commits are also anchors in the terminology
 682         # of git-debrebase(5), but they are untagged (and always
 683         # manually generated).
 684         #
 685         # We cannot not tolerate any tagged linear commit (ie,
 686         # BreakwaterStart commits tagged `[anchor:') because such a
 687         # thing could result from an erroneous linearising raw git
 688         # rebase of a merge anchor.  That would represent a corruption
 689         # of the branch. and we want to detect and reject the results
 690         # of such corruption before it makes it out anywhere.  If we
 691         # reject it here then we avoid making the pseudomerge which
 692         # would be needed to push it.
 693
 694         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 695         @p == 2 or return $badanchor->("has other than two parents");
 696         $haspatches and return $badanchor->("contains debian/patches");
 697
 698         # How to decide about l/r ordering of anchors ?  git
 699         # --topo-order prefers to expand 2nd parent first.  There's
 700         # already an easy rune to look for debian/ history anyway (git log
 701         # debian/) so debian breakwater branch should be 1st parent; that
 702         # way also there's also an easy rune to look for the upstream
 703         # patches (--topo-order).
 704
 705         # Also this makes --first-parent be slightly more likely to
 706         # be useful - it makes it provide a linearised breakwater history.
 707
 708         # Of course one can say somthing like
 709         #  gitk -- ':/' ':!/debian'
 710         # to get _just_ the commits touching upstream files, and by
 711         # the TREESAME logic in git-rev-list this will leave the
 712         # breakwater into upstream at the first anchor.  But that
 713         # doesn't report debian/ changes at all.
 714
 715         # Other observations about gitk: by default, gitk seems to
 716         # produce output in a different order to git-rev-list.  I
 717         # can't seem to find this documented anywhere.  gitk
 718         # --date-order DTRT.  But, gitk always seems to put the
 719         # parents from left to right, in order, so it's easy to see
 720         # which way round a pseudomerge is.
 721
 722         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 723         $p[1]{Differs} & ~DS_DEB and
 724             $badanchor->("upstream files differ from left parent");
 725         $p[0]{Differs} & ~D_UPS and
 726             $badanchor->("debian/ differs from right parent");
 727
 728         return $classify->(qw(Anchor),
 729                            OrigParents => [ $p[1] ]);
 730     }
 731
 732     if (@p == 1) {
 733         my $d = $r->{Parents}[0]{Differs};
 734         if ($d == D_PAT_ADD) {
 735             return $classify->(qw(AddPatches));
 736         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 737             return $unknown->("edits debian/patches");
 738         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 739             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 740             if ($ty eq 'tree') {
 741                 if ($d == D_DEB_CLOG) {
 742                     return $classify->(qw(Changelog));
 743                 } else {
 744                     return $classify->(qw(Packaging));
 745                 }
 746             } elsif ($ty eq 'missing') {
 747                 return $classify->(qw(BreakwaterStart));
 748             } else {
 749                 return $unknown->("parent's debian is not a directory");
 750             }
 751         } elsif ($d == D_UPS) {
 752             return $classify->(qw(Upstream));
 753         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 754             return $classify->(qw(Mixed));
 755         } elsif ($d == 0) {
 756             return $unknown->("no changes");
 757         } else {
 758             confess "internal error $objid ?";
 759         }
 760     }
 761     if (!@p) {
 762         return $unknown->("origin commit");
 763     }
 764
 765     if (@p == 2 && @identical == 1) {
 766         my @overwritten = grep { $_->{Differs} } @p;
 767         confess "internal error $objid ?" unless @overwritten==1;
 768         return $classify->(qw(Pseudomerge),
 769                            Overwritten => [ $overwritten[0] ],
 770                            Contributor => $identical[0]);
 771     }
 772     if (@p == 2 && @identical == 2) {
 773         my $get_t = sub {
 774             my ($ph,$pm) = get_commit $_[0]{CommitId};
 775             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 776             $1;
 777         };
 778         my @bytime = @p;
 779         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 780         if ($order > 0) { # newer first
 781         } elsif ($order < 0) {
 782             @bytime = reverse @bytime;
 783         } else {
 784             # same age, default to order made by -s ours
 785             # that is, commit was made by someone who preferred L
 786         }
 787         return $classify->(qw(Pseudomerge),
 788                            SubType => qw(Ambiguous),
 789                            Contributor => $bytime[0],
 790                            Overwritten => [ $bytime[1] ]);
 791     }
 792     foreach my $p (@p) {
 793         my ($p_h, $p_m) = get_commit $p->{CommitId};
 794         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 795         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 796     }
 797     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 798     my $m2 = $r->{Msg};
 799     if (!(grep { !$_->{IsOrigin} } @p) and
 800         (@orig_ps >= @p - 1) and
 801         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 802         $r->{NewMsg} = $m2;
 803         return $classify->(qw(DgitImportUnpatched),
 804                            OrigParents => \@orig_ps);
 805     }
 806
 807     if (@p == 2 and
 808         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 809         # xxx ^ metadata tag needs adding to (5)
 810         return $classify->("MergedBreakwaters");
 811     }
 812     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 813         return $unknown->("unknown kind of merge from $1");
 814     }
 815     if (@p > 2) {
 816         return $unknown->("octopus merge");
 817     }
 818
 819     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 820         return $unknown->("general two-parent merge");
 821     }
 822
 823     return $classify->("VanillaMerge");
 824 }
 825
 826 sub keycommits ($;$$$$$);
 827
 828 sub mergedbreakwaters_anchor ($) {
 829     my ($cl) = @_;
 830     my $best_anchor;
 831     foreach my $p (@{ $cl->{Parents} }) {
 832         my ($panchor, $pbw) = keycommits $p->{CommitId},
 833             undef,undef,undef,undef, 1;
 834         $best_anchor = $panchor
 835             if !defined $best_anchor
 836             or is_fast_fwd $best_anchor, $panchor;
 837     }
 838     return $best_anchor;
 839 }
 840
 841 sub keycommits ($;$$$$$) {
 842     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 843     # => ($anchor, $breakwater)
 844
 845     # $unclean->("unclean-$tagsfx", $msg, $cl)
 846     # $furniture->("unclean-$tagsfx", $msg, $cl)
 847     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 848     #   is callled for each situation or commit that
 849     #   wouldn't be found in a laundered branch
 850     # $furniture is for furniture commits such as might be found on an
 851     #   interchange branch (pseudomerge, d/patches, changelog)
 852     # $trouble is for things whnich prevent the return of
 853     #   anchor and breakwater information; if that is ignored,
 854     #   then keycommits returns (undef, undef) instead.
 855     # $fatal is for unprocessable commits, and should normally cause
 856     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 857     #
 858     # If $claimed_bw, this is supposed to be a breakwater commit.
 859     #
 860     # If a callback is undef, fail is called instead.
 861     # If a callback is defined but false, the situation is ignored.
 862     # Callbacks may say:
 863     #   no warnings qw(exiting); last;
 864     # if the answer is no longer wanted.
 865
 866     my ($anchor, $breakwater);
 867     $breakwater = $head if $claimed_bw;
 868     my $clogonly;
 869     my $cl;
 870     my $found_pm;
 871     $fatal //= sub { fail $_[1]; };
 872     my $x = sub {
 873         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 874         my $why = $mainwhy.$xwhy;
 875         my $m = "branch needs laundering (run git-debrebase): $why";
 876         fail $m unless defined $cb;
 877         return unless $cb;
 878         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 879     };
 880     my $found_anchor = sub {
 881         ($anchor) = @_;
 882         $breakwater //= $clogonly;
 883         $breakwater //= $head;
 884         no warnings qw(exiting);
 885         last;
 886     };
 887     for (;;) {
 888         $cl = classify $head;
 889         my $ty = $cl->{Type};
 890         if ($ty eq 'Packaging') {
 891             $breakwater //= $clogonly;
 892             $breakwater //= $head;
 893         } elsif ($ty eq 'Changelog') {
 894             # this is going to count as the tip of the breakwater
 895             # only if it has no upstream stuff before it
 896             $clogonly //= $head;
 897         } elsif ($ty eq 'Anchor' or
 898                  $ty eq 'TreatAsAnchor' or
 899                  $ty eq 'BreakwaterStart') {
 900             $found_anchor->($head);
 901         } elsif ($ty eq 'Upstream') {
 902             $x->($unclean, 'ordering',
 903  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 904                 if defined $breakwater;
 905             $clogonly = undef;
 906             $breakwater = undef;
 907         } elsif ($ty eq 'Mixed') {
 908             $x->($unclean, 'mixed',
 909                  "found mixed upstream/packaging commit"," ($head)");
 910             $clogonly = undef;
 911             $breakwater = undef;
 912         } elsif ($ty eq 'Pseudomerge' or
 913                  $ty eq 'AddPatches') {
 914             my $found_pm = 1;
 915             $x->($furniture, (lc $ty),
 916                  "found interchange bureaucracy commit ($ty)"," ($head)");
 917         } elsif ($ty eq 'DgitImportUnpatched') {
 918             if ($found_pm) {
 919                 $x->($trouble, 'dgitimport',
 920                      "found dgit dsc import"," ($head)");
 921                 return (undef,undef);
 922             } else {
 923                 $x->($fatal, 'unprocessable',
 924                      "found bare dgit dsc import with no prior history",
 925                      " ($head)");
 926                 return (undef,undef);
 927             }
 928         } elsif ($ty eq 'VanillaMerge') {
 929             $x->($trouble, 'vanillamerge',
 930                  "found vanilla merge"," ($head)");
 931             return (undef,undef);
 932         } elsif ($ty eq 'MergedBreakwaters') {
 933             $found_anchor->(mergedbreakwaters_anchor $cl);
 934         } else {
 935             $x->($fatal, 'unprocessable',
 936                  "found unprocessable commit, cannot cope: $cl->{Why}",
 937                  " ($head)");
 938             return (undef,undef);
 939         }
 940         $head = $cl->{Parents}[0]{CommitId};
 941     }
 942     return ($anchor, $breakwater);
 943 }
 944
 945 sub walk ($;$$$);
 946 sub walk ($;$$$) {
 947     my ($input,
 948         $nogenerate,$report, $report_lprefix) = @_;
 949     # => ($tip, $breakwater_tip, $last_anchor)
 950     # (or nothing, if $nogenerate)
 951
 952     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 953     $report_lprefix //= '';
 954
 955     # go through commits backwards
 956     # we generate two lists of commits to apply:
 957     # breakwater branch and upstream patches
 958     my (@brw_cl, @upp_cl, @processed);
 959     my %found;
 960     my $upp_limit;
 961     my @pseudomerges;
 962
 963     my $cl;
 964     my $xmsg = sub {
 965         my ($prose, $info) = @_;
 966         my $ms = $cl->{Msg};
 967         chomp $ms;
 968         $info //= '';
 969         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 970         return (Msg => $ms);
 971     };
 972     my $rewrite_from_here = sub {
 973         my ($cl) = @_;
 974         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 975         push @$cl, $sp_cl;
 976         push @processed, $sp_cl;
 977     };
 978     my $cur = $input;
 979
 980     my $prdelim = "";
 981     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 982
 983     my $prline = sub {
 984         return unless $report;
 985         print $report $prdelim, $report_lprefix, @_;
 986         $prdelim = "\n";
 987     };
 988
 989     my $bomb = sub { # usage: return $bomb->();
 990         print $report " Unprocessable" if $report;
 991         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 992         $prprdelim->();
 993         if ($nogenerate) {
 994             return (undef,undef);
 995         }
 996         fail "found unprocessable commit, cannot cope".
 997             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
 998             " (commit $cur) (d.".
 999             (join ' ', map { sprintf "%#x", $_->{Differs} }
1000              @{ $cl->{Parents} }).
1001                  ")";
1002     };
1003
1004     my $build;
1005     my $breakwater;
1006
1007     my $build_start = sub {
1008         my ($msg, $parent) = @_;
1009         $prline->(" $msg");
1010         $build = $parent;
1011         no warnings qw(exiting); last;
1012     };
1013
1014     my $nomerge = sub {
1015         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1016     };
1017
1018     my $last_anchor;
1019
1020     for (;;) {
1021         $cl = classify $cur;
1022         my $ty = $cl->{Type};
1023         my $st = $cl->{SubType};
1024         $prline->("$cl->{CommitId} $cl->{Type}");
1025         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1026         push @processed, $cl;
1027         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1028         if ($ty eq 'AddPatches') {
1029             $cur = $p0;
1030             $rewrite_from_here->(\@upp_cl);
1031             next;
1032         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1033             push @brw_cl, $cl;
1034             $cur = $p0;
1035             next;
1036         } elsif ($ty eq 'BreakwaterStart') {
1037             $last_anchor = $cur;
1038             $build_start->('FirstPackaging', $cur);
1039         } elsif ($ty eq 'Upstream') {
1040             push @upp_cl, $cl;
1041             $cur = $p0;
1042             next;
1043         } elsif ($ty eq 'Mixed') {
1044             my $queue = sub {
1045                 my ($q, $wh) = @_;
1046                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1047                 push @$q, $cls;
1048             };
1049             $queue->(\@brw_cl, "debian");
1050             $queue->(\@upp_cl, "upstream");
1051             $rewrite_from_here->(\@brw_cl);
1052             $cur = $p0;
1053             next;
1054         } elsif ($ty eq 'Pseudomerge') {
1055             my $contrib = $cl->{Contributor}{CommitId};
1056             print $report " Contributor=$contrib" if $report;
1057             push @pseudomerges, $cl;
1058             $rewrite_from_here->(\@upp_cl);
1059             $cur = $contrib;
1060             next;
1061         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1062             $last_anchor = $cur;
1063             $build_start->("Anchor", $cur);
1064         } elsif ($ty eq 'DgitImportUnpatched') {
1065             my $pm = $pseudomerges[-1];
1066             if (defined $pm) {
1067                 # To an extent, this is heuristic.  Imports don't have
1068                 # a useful history of the debian/ branch.  We assume
1069                 # that the first pseudomerge after an import has a
1070                 # useful history of debian/, and ignore the histories
1071                 # from later pseudomerges.  Often the first pseudomerge
1072                 # will be the dgit import of the upload to the actual
1073                 # suite intended by the non-dgit NMUer, and later
1074                 # pseudomerges may represent in-archive copies.
1075                 my $ovwrs = $pm->{Overwritten};
1076                 printf $report " PM=%s \@Overwr:%d",
1077                     $pm->{CommitId}, (scalar @$ovwrs)
1078                     if $report;
1079                 if (@$ovwrs != 1) {
1080                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1081                     return $bomb->();
1082                 }
1083                 my $ovwr = $ovwrs->[0]{CommitId};
1084                 printf $report " Overwr=%s", $ovwr if $report;
1085                 # This import has a tree which is just like a
1086                 # breakwater tree, but it has the wrong history.  It
1087                 # ought to have the previous breakwater (which the
1088                 # pseudomerge overwrote) as an ancestor.  That will
1089                 # make the history of the debian/ files correct.  As
1090                 # for the upstream version: either it's the same as
1091                 # was ovewritten (ie, same as the previous
1092                 # breakwater), in which case that history is precisely
1093                 # right; or, otherwise, it was a non-gitish upload of a
1094                 # new upstream version.  We can tell these apart by
1095                 # looking at the tree of the supposed upstream.
1096                 push @brw_cl, {
1097                     %$cl,
1098                     SpecialMethod => 'DgitImportDebianUpdate',
1099                     $xmsg->("convert dgit import: debian changes")
1100                 }, {
1101                     %$cl,
1102                     SpecialMethod => 'DgitImportUpstreamUpdate',
1103                     $xmsg->("convert dgit import: upstream update",
1104                             " anchor")
1105                 };
1106                 $prline->(" Import");
1107                 $rewrite_from_here->(\@brw_cl);
1108                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1109                 $cur = $ovwr;
1110                 next;
1111             } else {
1112                 # Everything is from this import.  This kind of import
1113                 # is already nearly in valid breakwater format, with the
1114                 # patches as commits.  Unfortunately it contains
1115                 # debian/patches/.
1116                 printdebug "*** WALK BOMB bare dgit import\n";
1117                 $cl->{Why} = "bare dgit dsc import";
1118                 return $bomb->();
1119             }
1120             die "$ty ?";
1121         } elsif ($ty eq 'VanillaMerge' or $ty eq 'MergedBreakwaters') {
1122             # User may have merged unstitched branch(es).  We will
1123             # have now lost what ffq-prev was then (since the later
1124             # pseudomerge may introduce further changes).  The effect
1125             # of resolving such a merge is that we may have to go back
1126             # further in history to find a merge base, since the one
1127             # which was reachable via ffq-prev is no longer findable.
1128             # This is suboptimal, but if it all works we'll have done
1129             # the right thing.
1130             # xxx we should warn the user in the docs about this
1131
1132             my $ok=1;
1133             my $best_anchor;
1134             # We expect to find a dominating anchor amongst the
1135             # inputs' anchors.  That will be the new anchor.
1136             #
1137             # More complicated is finding a merge base for the
1138             # breakwaters.  We need a merge base that is a breakwater
1139             # commit.  The ancestors of breakwater commits are more
1140             # breakwater commits and possibly upstream commits and the
1141             # ancestors of those upstream.  Upstreams might have
1142             # arbitrary ancestors.  But any upstream commit U is
1143             # either included in both anchors, in which case the
1144             # earlier anchor is a better merge base than any of U's
1145             # ancestors; or U is not included in the older anchor, in
1146             # which case U is not an ancestor of the vanilla merge at
1147             # all.  So no upstream commit, nor any ancestor thereof,
1148             # is a best merge base.  As for non-breakwater Debian
1149             # commits: these are never ancestors of any breakwater.
1150             #
1151             # So any best merge base as found by git-merge-base
1152             # is a suitable breakwater anchor.  Usually there will
1153             # be only one.
1154
1155             printdebug "*** MERGE\n";
1156
1157             # xxx avoid calling walk without nogenerate when
1158             # we have a MergedBreakwater; instead call keycommits ?
1159
1160             my @bwbcmd = (@git, qw(merge-base));
1161             my @ibcmd = (@git, qw(merge-base --all));
1162             my $might_be_in_bw = 1;
1163
1164             my $ps = $cl->{Parents};
1165
1166             foreach my $p (@$ps) {
1167                 $prline->(" VanillaMerge ".$p->{Ix});
1168                 $prprdelim->();
1169                 my ($ptip, $pbw, $panchor) =
1170                     walk $p->{CommitId}, 0, $report,
1171                          $report_lprefix.'  ';
1172                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1173                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1174                 $p->{Anchor} = $panchor;
1175
1176                 $best_anchor = $panchor if
1177                     !defined $best_anchor or
1178                     is_fast_fwd $best_anchor, $panchor;
1179
1180                 printdebug " MERGE BA best=".($best_anchor//'-').
1181                     " p=$panchor\n";
1182             }
1183
1184             foreach my $p (@$ps) {
1185                 $prline->(" VanillaMerge ".$p->{Ix});
1186                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1187                     $nomerge->('DivergentAnchor');
1188                 } elsif ($p->{Anchor} eq $best_anchor) {
1189                     print $report " SameAnchor" if $report;
1190                 } else {
1191                     print $report " SupersededAnchor" if $report;
1192                 }
1193                 if ($p->{Breakwater} eq $p->{CommitId}) {
1194                     # this parent commit was its own breakwater,
1195                     # ie it is part of the breakwater
1196                     print $report " Breakwater" if $report;
1197                 } else {
1198                     $might_be_in_bw = 0;
1199                 }
1200                 push @bwbcmd, $p->{Breakwater};
1201                 push @ibcmd, $p->{CommitId};
1202             }
1203
1204             if ($ok && $might_be_in_bw) {
1205                 $prline->(" VanillaMerge MergedBreakwaters");
1206                 $last_anchor = $best_anchor;
1207                 $build_start->('MergedBreakwaters', $cur);
1208             }
1209
1210             $nomerge->("alleged merged-breakwater is not a breakwater")
1211                 unless $ty eq 'VanillaMerge';
1212
1213             my $bwb = cmdoutput @bwbcmd;
1214
1215             # OK, now we have a breakwater base, but we need the merge
1216             # base for the interchange branch because we need the delta
1217             # queue.
1218             #
1219             # This a the best merge base of our inputs which has the
1220             # breakwater merge base as an ancestor.
1221
1222             my @ibs =
1223                 grep { is_fast_fwd $bwb, $_ }
1224                 grep /./,
1225                 split /\n/,
1226                 cmdoutput @ibcmd;
1227             my ($ib) = @ibs
1228                 or $nomerge->("no suitable interchange merge base");
1229
1230             $prline->("  VanillaMerge Base");
1231             $prprdelim->();
1232             my ($btip, $bbw, $banchor) =
1233                 walk $ib, 0, $report, $report_lprefix.'  ';
1234
1235             my $ibinfo = { SeriesTip => $btip,
1236                            SeriesBase => $bbw,
1237                            Anchor => $banchor };
1238             $bbw eq $bwb
1239                 or $nomerge->("interchange merge-base ($ib)'s".
1240                               " breakwater ($bbw)".
1241                               " != breakwaters' merge-base ($bwb)");
1242             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1243                  or $nomerge->("interchange merge-base ($ib)'s".
1244                                " anchor ($ibinfo->{SeriesBase})".
1245                                " != any merge input's anchor (".
1246                                (join ' ', map { $_->{Anchor} } @$ps).
1247                                ")");
1248
1249
1250             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1251             $cl->{MergeBestAnchor} = $best_anchor;
1252             push @brw_cl, {
1253                 %$cl,
1254                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1255                 $xmsg->('constructed from vanilla merge',
1256                         ' merged-breakwater'),
1257             };
1258             push @upp_cl, {
1259                 %$cl,
1260                 SpecialMethod => 'MergeMergeSeries',
1261             };
1262             $build_start->('MergeBreakwaters', $cur);
1263         } else {
1264             printdebug "*** WALK BOMB unrecognised\n";
1265             return $bomb->();
1266         }
1267     }
1268     $prprdelim->();
1269
1270     printdebug "*** WALK prep done cur=$cur".
1271         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1272
1273     return if $nogenerate;
1274
1275     # Now we build it back up again
1276
1277     fresh_workarea();
1278
1279     my $rewriting = 0;
1280
1281     my $read_tree_upstream = sub {
1282         my ($treeish) = @_;
1283         read_tree_upstream $treeish, 0, $build;
1284     };
1285
1286     $#upp_cl = $upp_limit if defined $upp_limit;
1287
1288     my $committer_authline = calculate_committer_authline();
1289
1290     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1291
1292     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1293
1294     in_workarea sub {
1295         mkdir $rd or $!==EEXIST or die $!;
1296         my $current_method;
1297         runcmd @git, qw(read-tree), $build;
1298         foreach my $cl (qw(Debian), (reverse @brw_cl),
1299                         { SpecialMethod => 'RecordBreakwaterTip' },
1300                         qw(Upstream), (reverse @upp_cl)) {
1301             if (!ref $cl) {
1302                 $current_method = $cl;
1303                 next;
1304             }
1305             my $method = $cl->{SpecialMethod} // $current_method;
1306             my @parents = ($build);
1307             my $cltree = $cl->{CommitId};
1308             printdebug "WALK BUILD ".($cltree//'undef').
1309                 " $method (rewriting=$rewriting)\n";
1310             if ($method eq 'Debian') {
1311                 read_tree_debian($cltree);
1312             } elsif ($method eq 'Upstream') {
1313                 $read_tree_upstream->($cltree);
1314             } elsif ($method eq 'StartRewrite') {
1315                 $rewriting = 1;
1316                 next;
1317             } elsif ($method eq 'RecordBreakwaterTip') {
1318                 $breakwater = $build;
1319                 next;
1320             } elsif ($method eq 'DgitImportDebianUpdate') {
1321                 read_tree_debian($cltree);
1322             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1323                 confess unless $rewriting;
1324                 my $differs = (get_differs $build, $cltree);
1325                 next unless $differs & D_UPS;
1326                 $read_tree_upstream->($cltree);
1327                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1328             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1329                 print "Found a general merge, will try to tidy it up.\n";
1330                 $rewriting = 1;
1331                 $read_tree_upstream->($cl->{MergeBestAnchor});
1332                 $read_tree_upstream->($cl->{MergeBestAnchor});
1333                 read_tree_debian($cltree);
1334                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1335             } elsif ($method eq 'MergeMergeSeries') {
1336                 print "Running merge resolution for $cl->{CommitId}...\n";
1337                 $build = merge_series
1338                     $build,
1339                     $cl->{MergeInterchangeBaseInfo},
1340                     @{ $cl->{Parents} };
1341                 $last_anchor = $cl->{MergeBestAnchor};
1342
1343                 # Check for mismerges:
1344                 my $check = sub {
1345                     my ($against, $allow, $what) = @_;
1346                     my $differs = get_differs $build, $against;
1347                     $nomerge->(sprintf
1348        "merge misresolved: %s are not the same (%s %s d.%#x)",
1349                                $what, $against, $build, $differs)
1350                         if $differs & ~($allow | D_PAT_ADD);
1351                 };
1352
1353                 # Breakwater changes which were in each side of the
1354                 # merge will have been incorporated into the
1355                 # MergeCreateMergedBreakwaters output.  Because the
1356                 # upstream series was rebased onto the new breakwater,
1357                 # so should all of the packaging changes which were in
1358                 # the input.
1359                 $check->($input, D_UPS, 'debian files');
1360
1361                 # Upstream files are merge_series, which ought to
1362                 # have been identical to the original merge.
1363                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1364
1365                 print "Merge resolution successful.\n";
1366                 next;
1367             } else {
1368                 confess "$method ?";
1369             }
1370             if (!$rewriting) {
1371                 my $procd = (pop @processed) // 'UNDEF';
1372                 if ($cl ne $procd) {
1373                     $rewriting = 1;
1374                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1375                 }
1376             }
1377             my $newtree = cmdoutput @git, qw(write-tree);
1378             my $ch = $cl->{Hdr};
1379             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1380             $ch =~ s{^parent .*\n}{}mg;
1381             $ch =~ s{(?=^author)}{
1382                 join '', map { "parent $_\n" } @parents
1383             }me or confess "$ch ?";
1384             if ($rewriting) {
1385                 $ch =~ s{^committer .*$}{$committer_authline}m
1386                     or confess "$ch ?";
1387             }
1388             my $cf = "$rd/m$rewriting";
1389             open CD, ">", $cf or die $!;
1390             print CD $ch, "\n", $cl->{Msg} or die $!;
1391             close CD or die $!;
1392             my @cmd = (@git, qw(hash-object));
1393             push @cmd, qw(-w) if $rewriting;
1394             push @cmd, qw(-t commit), $cf;
1395             my $newcommit = cmdoutput @cmd;
1396             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1397             $build = $newcommit;
1398             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1399                 $last_anchor = $cur;
1400             }
1401         }
1402     };
1403
1404     my $final_check = get_differs $build, $input;
1405     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1406         if $final_check & ~D_PAT_ADD;
1407
1408     my @r = ($build, $breakwater, $last_anchor);
1409     printdebug "*** WALK RETURN @r\n";
1410     return @r
1411 }
1412
1413 sub get_head () {
1414     git_check_unmodified();
1415     return git_rev_parse qw(HEAD);
1416 }
1417
1418 sub update_head ($$$) {
1419     my ($old, $new, $mrest) = @_;
1420     push @deferred_updates, "update HEAD $new $old";
1421     run_deferred_updates $mrest;
1422 }
1423
1424 sub update_head_checkout ($$$) {
1425     my ($old, $new, $mrest) = @_;
1426     update_head $old, $new, $mrest;
1427     runcmd @git, qw(reset --hard);
1428 }
1429
1430 sub update_head_postlaunder ($$$) {
1431     my ($old, $tip, $reflogmsg) = @_;
1432     return if $tip eq $old;
1433     print "git-debrebase: laundered (head was $old)\n";
1434     update_head $old, $tip, $reflogmsg;
1435     # no tree changes except debian/patches
1436     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1437 }
1438
1439 sub currently_rebasing() {
1440     foreach (qw(rebase-merge rebase-apply)) {
1441         return 1 if stat_exists "$maindir_gitdir/$_";
1442     }
1443     return 0;
1444 }
1445
1446 sub bail_if_rebasing() {
1447     fail "you are in the middle of a git-rebase already"
1448         if currently_rebasing();
1449 }
1450
1451 sub do_launder_head ($) {
1452     my ($reflogmsg) = @_;
1453     my $old = get_head();
1454     record_ffq_auto();
1455     my ($tip,$breakwater) = walk $old;
1456     snags_maybe_bail();
1457     update_head_postlaunder $old, $tip, $reflogmsg;
1458     return ($tip,$breakwater);
1459 }
1460
1461 sub cmd_launder_v0 () {
1462     badusage "no arguments to launder-v0 allowed" if @ARGV;
1463     my $old = get_head();
1464     my ($tip,$breakwater,$last_anchor) = walk $old;
1465     update_head_postlaunder $old, $tip, 'launder';
1466     printf "# breakwater tip\n%s\n", $breakwater;
1467     printf "# working tip\n%s\n", $tip;
1468     printf "# last anchor\n%s\n", $last_anchor;
1469 }
1470
1471 sub defaultcmd_rebase () {
1472     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1473     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1474     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1475 }
1476
1477 sub cmd_analyse () {
1478     badusage "analyse does not support any options"
1479         if @ARGV and $ARGV[0] =~ m/^-/;
1480     badusage "too many arguments to analyse" if @ARGV>1;
1481     my ($old) = @ARGV;
1482     if (defined $old) {
1483         $old = git_rev_parse $old;
1484     } else {
1485         $old = git_rev_parse 'HEAD';
1486     }
1487     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1488     STDOUT->error and die $!;
1489 }
1490
1491 sub ffq_prev_branchinfo () {
1492     my $current = git_get_symref();
1493     return gdr_ffq_prev_branchinfo($current);
1494 }
1495
1496 sub ffq_check ($;$$) {
1497     # calls $ff and/or $notff zero or more times
1498     # then returns either (status,message) where status is
1499     #    exists
1500     #    detached
1501     #    weird-symref
1502     #    notbranch
1503     # or (undef,undef, $ffq_prev,$gdrlast)
1504     # $ff and $notff are called like this:
1505     #   $ff->("message for stdout\n");
1506     #   $notff->('snag-name', $message);
1507     # normally $currentval should be HEAD
1508     my ($currentval, $ff, $notff) =@_;
1509
1510     $ff //= sub { print $_[0] or die $!; };
1511     $notff //= \&snag;
1512
1513     my ($status, $message, $current, $ffq_prev, $gdrlast)
1514         = ffq_prev_branchinfo();
1515     return ($status, $message) unless $status eq 'branch';
1516
1517     my $exists = git_get_ref $ffq_prev;
1518     return ('exists',"$ffq_prev already exists") if $exists;
1519
1520     return ('not-branch', 'HEAD symref is not to refs/heads/')
1521         unless $current =~ m{^refs/heads/};
1522     my $branch = $';
1523
1524     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1525     my %checked;
1526
1527     printdebug "ffq check_specs @check_specs\n";
1528
1529     my $check = sub {
1530         my ($lrref, $desc) = @_;
1531         printdebug "ffq might check $lrref ($desc)\n";
1532         my $invert;
1533         for my $chk (@check_specs) {
1534             my $glob = $chk;
1535             $invert = $glob =~ s{^[!^]}{};
1536             last if fnmatch $glob, $lrref;
1537         }
1538         return if $invert;
1539         my $lrval = git_get_ref $lrref;
1540         return unless length $lrval;
1541
1542         if (is_fast_fwd $lrval, $currentval) {
1543             $ff->("OK, you are ahead of $lrref\n");
1544             $checked{$lrref} = 1;
1545         } elsif (is_fast_fwd $currentval, $lrval) {
1546             $checked{$lrref} = -1;
1547             $notff->('behind', "you are behind $lrref, divergence risk");
1548         } else {
1549             $checked{$lrref} = -1;
1550             $notff->('diverged', "you have diverged from $lrref");
1551         }
1552     };
1553
1554     my $merge = cfg "branch.$branch.merge",1;
1555     if (defined $merge and $merge =~ m{^refs/heads/}) {
1556         my $rhs = $';
1557         printdebug "ffq merge $rhs\n";
1558         my $check_remote = sub {
1559             my ($remote, $desc) = @_;
1560             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1561             return unless defined $remote;
1562             $check->("refs/remotes/$remote/$rhs", $desc);
1563         };
1564         $check_remote->((scalar cfg "branch.$branch.remote",1),
1565                         'remote fetch/merge branch');
1566         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1567                         (scalar cfg "branch.$branch.pushDefault",1),
1568                         'remote push branch');
1569     }
1570     if ($branch =~ m{^dgit/}) {
1571         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1572     } elsif ($branch =~ m{^master$}) {
1573         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1574     }
1575     return (undef, undef, $ffq_prev, $gdrlast);
1576 }
1577
1578 sub record_ffq_prev_deferred () {
1579     # => ('status', "message")
1580     # 'status' may be
1581     #    deferred          message is undef
1582     #    exists
1583     #    detached
1584     #    weird-symref
1585     #    notbranch
1586     # if not ff from some branch we should be ff from, is an snag
1587     # if "deferred", will have added something about that to
1588     #   @deferred_update_messages, and also maybe printed (already)
1589     #   some messages about ff checks
1590     bail_if_rebasing();
1591     my $currentval = get_head();
1592
1593     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1594     return ($status,$message) if defined $status;
1595
1596     snags_maybe_bail();
1597
1598     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1599     push @deferred_updates, "delete $gdrlast";
1600     push @deferred_update_messages, "Recorded previous head for preservation";
1601     return ('deferred', undef);
1602 }
1603
1604 sub record_ffq_auto () {
1605     my ($status, $message) = record_ffq_prev_deferred();
1606     if ($status eq 'deferred' || $status eq 'exists') {
1607     } else {
1608         snag $status, "could not record ffq-prev: $message";
1609         snags_maybe_bail();
1610     }
1611 }
1612
1613 sub ffq_prev_info () {
1614     bail_if_rebasing();
1615     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1616     my ($status, $message, $current, $ffq_prev, $gdrlast)
1617         = ffq_prev_branchinfo();
1618     if ($status ne 'branch') {
1619         snag $status, "could not check ffq-prev: $message";
1620         snags_maybe_bail();
1621     }
1622     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1623     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1624 }
1625
1626 sub stitch ($$$$$) {
1627     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1628
1629     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1630
1631     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1632         my $differs = get_differs $old_head, $ffq_prev_commitish;
1633         unless ($differs & ~D_PAT_ADD) {
1634             # ffq-prev is ahead of us, and the only tree changes it has
1635             # are possibly addition of things in debian/patches/.
1636             # Just wind forwards rather than making a pointless pseudomerge.
1637             push @deferred_updates,
1638                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1639             update_head_checkout $old_head, $ffq_prev_commitish,
1640                 "stitch (fast forward)";
1641             return;
1642         }
1643     }
1644     fresh_workarea();
1645     # We make pseudomerges with L as the contributing parent.
1646     # This makes git rev-list --first-parent work properly.
1647     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1648         'Declare fast forward / record previous work',
1649         "[git-debrebase pseudomerge: $prose]",
1650     ];
1651     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1652     update_head $old_head, $new_head, "stitch: $prose";
1653 }
1654
1655 sub do_stitch ($;$) {
1656     my ($prose, $unclean) = @_;
1657
1658     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1659     if (!$ffq_prev_commitish) {
1660         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1661         return;
1662     }
1663     my $dangling_head = get_head();
1664
1665     keycommits $dangling_head, $unclean,$unclean,$unclean;
1666     snags_maybe_bail();
1667
1668     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1669 }
1670
1671 sub upstream_commitish_search ($$) {
1672     my ($upstream_version, $tried) = @_;
1673     # todo: at some point maybe use git-deborig to do this
1674     foreach my $tagpfx ('', 'v', 'upstream/') {
1675         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1676         my $new_upstream = git_get_ref "refs/tags/$tag";
1677         push @$tried, $tag;
1678         return $new_upstream if length $new_upstream;
1679     }
1680 }
1681
1682 sub resolve_upstream_version ($$) {
1683     my ($new_upstream, $upstream_version) = @_;
1684
1685     if (!defined $new_upstream) {
1686         my @tried;
1687         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1688         if (!length $new_upstream) {
1689             fail "Could not determine appropriate upstream commitish.\n".
1690                 " (Tried these tags: @tried)\n".
1691                 " Check version, and specify upstream commitish explicitly.";
1692         }
1693     }
1694     $new_upstream = git_rev_parse $new_upstream;
1695
1696     return $new_upstream;
1697 }
1698
1699 sub cmd_new_upstream () {
1700     # automatically and unconditionally launders before rebasing
1701     # if rebase --abort is used, laundering has still been done
1702
1703     my %pieces;
1704
1705     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1706
1707     # parse args - low commitment
1708     my $spec_version = shift @ARGV;
1709     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1710     fail "bad version number \`$spec_version'" unless defined $new_version;
1711     if ($new_version->is_native()) {
1712         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1713     }
1714
1715     my $new_upstream = shift @ARGV;
1716     my $new_upstream_version = upstreamversion  $new_version;
1717     $new_upstream =
1718         resolve_upstream_version $new_upstream, $new_upstream_version;
1719
1720     record_ffq_auto();
1721
1722     my $piece = sub {
1723         my ($n, @x) = @_; # may be ''
1724         my $pc = $pieces{$n} //= {
1725             Name => $n,
1726             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1727         };
1728         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1729         $pc;
1730     };
1731
1732     my @newpieces;
1733     my $newpiece = sub {
1734         my ($n, @x) = @_; # may be ''
1735         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1736         push @newpieces, $pc;
1737     };
1738
1739     $newpiece->('',
1740         OldIx => 0,
1741         New => $new_upstream,
1742     );
1743     while (@ARGV && $ARGV[0] !~ m{^-}) {
1744         my $n = shift @ARGV;
1745
1746         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1747             unless @ARGV && $ARGV[0] !~ m{^-};
1748
1749         my $c = git_rev_parse shift @ARGV;
1750         die unless $n =~ m/^$extra_orig_namepart_re$/;
1751         $newpiece->($n, New => $c);
1752     }
1753
1754     # now we need to investigate the branch this generates the
1755     # laundered version but we don't switch to it yet
1756     my $old_head = get_head();
1757     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1758
1759     my $old_bw_cl = classify $old_bw;
1760     my $old_anchor_cl = classify $old_anchor;
1761     my $old_upstream;
1762     if (!$old_anchor_cl->{OrigParents}) {
1763         snag 'anchor-treated',
1764             'old anchor is recognised due to --anchor, cannot check upstream';
1765     } else {
1766         $old_upstream = parsecommit
1767             $old_anchor_cl->{OrigParents}[0]{CommitId};
1768         $piece->('', Old => $old_upstream->{CommitId});
1769     }
1770
1771     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1772         if ($old_upstream->{Msg} =~
1773  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1774            ) {
1775             my @oldpieces = (split / /, $1);
1776             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1777             if ($old_n_parents != @oldpieces &&
1778                 $old_n_parents != @oldpieces + 1) {
1779                 snag 'upstream-confusing', sprintf
1780                     "previous upstream combine %s".
1781                     " mentions %d pieces (each implying one parent)".
1782                     " but has %d parents".
1783                     " (one per piece plus maybe a previous combine)",
1784                     $old_upstream->{CommitId},
1785                     (scalar @oldpieces),
1786                     $old_n_parents;
1787             } elsif ($oldpieces[0] ne '.') {
1788                 snag 'upstream-confusing', sprintf
1789                     "previous upstream combine %s".
1790                     " first piece is not \`.'",
1791                     $oldpieces[0];
1792             } else {
1793                 $oldpieces[0] = '';
1794                 foreach my $i (0..$#oldpieces) {
1795                     my $n = $oldpieces[$i];
1796                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1797                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1798                 }
1799             }
1800         } else {
1801             snag 'upstream-confusing',
1802                 "previous upstream $old_upstream->{CommitId} is from".
1803                " git-debrebase but not an \`upstream-combine' commit";
1804         }
1805     }
1806
1807     foreach my $pc (values %pieces) {
1808         if (!$old_upstream) {
1809             # we have complained already
1810         } elsif (!$pc->{Old}) {
1811             snag 'upstream-new-piece',
1812                 "introducing upstream piece \`$pc->{Name}'";
1813         } elsif (!$pc->{New}) {
1814             snag 'upstream-rm-piece',
1815                 "dropping upstream piece \`$pc->{Name}'";
1816         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1817             snag 'upstream-not-ff',
1818                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1819         }
1820     }
1821
1822     printdebug "%pieces = ", (dd \%pieces), "\n";
1823     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1824
1825     snags_maybe_bail();
1826
1827     my $new_bw;
1828
1829     fresh_workarea();
1830     in_workarea sub {
1831         my @upstream_merge_parents;
1832
1833         if (!any_snags()) {
1834             push @upstream_merge_parents, $old_upstream->{CommitId};
1835         }
1836
1837         foreach my $pc (@newpieces) { # always has '' first
1838             if ($pc->{Name}) {
1839                 read_tree_subdir $pc->{Name}, $pc->{New};
1840             } else {
1841                 runcmd @git, qw(read-tree), $pc->{New};
1842             }
1843             push @upstream_merge_parents, $pc->{New};
1844         }
1845
1846         # index now contains the new upstream
1847
1848         if (@newpieces > 1) {
1849             # need to make the upstream subtree merge commit
1850             $new_upstream = make_commit \@upstream_merge_parents,
1851                 [ "Combine upstreams for $new_upstream_version",
1852  ("[git-debrebase upstream-combine . ".
1853  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1854  ": new upstream]"),
1855                 ];
1856         }
1857
1858         # $new_upstream is either the single upstream commit, or the
1859         # combined commit we just made.  Either way it will be the
1860         # "upstream" parent of the anchor merge.
1861
1862         read_tree_subdir 'debian', "$old_bw:debian";
1863
1864         # index now contains the anchor merge contents
1865         $new_bw = make_commit [ $old_bw, $new_upstream ],
1866             [ "Update to upstream $new_upstream_version",
1867  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1868             ];
1869
1870         my $clogsignoff = cmdoutput qw(git show),
1871             '--pretty=format:%an <%ae>  %aD',
1872             $new_bw;
1873
1874         # Now we have to add a changelog stanza so the Debian version
1875         # is right.
1876         die if unlink "debian";
1877         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1878         unlink "debian/changelog" or $!==ENOENT or die $!;
1879         mkdir "debian" or die $!;
1880         open CN, ">", "debian/changelog" or die $!;
1881         my $oldclog = git_cat_file ":debian/changelog";
1882         $oldclog =~ m/^($package_re) \(\S+\) / or
1883             fail "cannot parse old changelog to get package name";
1884         my $p = $1;
1885         print CN <<END, $oldclog or die $!;
1886 $p ($new_version) UNRELEASED; urgency=medium
1887
1888   * Update to new upstream version $new_upstream_version.
1889
1890  -- $clogsignoff
1891
1892 END
1893         close CN or die $!;
1894         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1895
1896         # Now we have the final new breakwater branch in the index
1897         $new_bw = make_commit [ $new_bw ],
1898             [ "Update changelog for new upstream $new_upstream_version",
1899               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1900             ];
1901     };
1902
1903     # we have constructed the new breakwater. we now need to commit to
1904     # the laundering output, because git-rebase can't easily be made
1905     # to make a replay list which is based on some other branch
1906
1907     update_head_postlaunder $old_head, $old_laundered_tip,
1908         'launder for new upstream';
1909
1910     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1911     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1912         "debrebase new-upstream $new_version: rebase";
1913     runcmd @cmd;
1914     # now it's for the user to sort out
1915 }
1916
1917 sub cmd_record_ffq_prev () {
1918     badusage "no arguments allowed" if @ARGV;
1919     my ($status, $msg) = record_ffq_prev_deferred();
1920     if ($status eq 'exists' && $opt_noop_ok) {
1921         print "Previous head already recorded\n" or die $!;
1922     } elsif ($status eq 'deferred') {
1923         run_deferred_updates 'record-ffq-prev';
1924     } else {
1925         fail "Could not preserve: $msg";
1926     }
1927 }
1928
1929 sub cmd_anchor () {
1930     badusage "no arguments allowed" if @ARGV;
1931     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1932     print "$bw\n" or die $!;
1933 }
1934
1935 sub cmd_breakwater () {
1936     badusage "no arguments allowed" if @ARGV;
1937     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1938     print "$bw\n" or die $!;
1939 }
1940
1941 sub cmd_status () {
1942     badusage "no arguments allowed" if @ARGV;
1943
1944     # todo: gdr status should print divergence info
1945     # todo: gdr status should print upstream component(s) info
1946     # todo: gdr should leave/maintain some refs with this kind of info ?
1947
1948     my $oldest = { Badness => 0 };
1949     my $newest;
1950     my $note = sub {
1951         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1952         if ($oldest->{Badness} < $badness) {
1953             $oldest = $newest = undef;
1954         }
1955         $oldest = {
1956                    Badness => $badness,
1957                    CommitId => $cl->{CommitId},
1958                    OurMsg => $ourmsg,
1959                    KcMsg => $kcmsg,
1960                   };
1961         $newest //= $oldest;
1962     };
1963     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1964         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1965         sub { $note->(2, 'branch is unlaundered', @_); },
1966         sub { $note->(3, 'branch needs laundering', @_); },
1967         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1968
1969     my $prcommitinfo = sub {
1970         my ($cid) = @_;
1971         flush STDOUT or die $!;
1972         runcmd @git, qw(--no-pager log -n1),
1973             '--pretty=format:    %h %s%n',
1974             $cid;
1975     };
1976
1977     print "current branch contents, in git-debrebase terms:\n";
1978     if (!$oldest->{Badness}) {
1979         print "  branch is laundered\n";
1980     } else {
1981         print "  $oldest->{OurMsg}\n";
1982         my $printed = '';
1983         foreach my $info ($oldest, $newest) {
1984             my $cid = $info->{CommitId};
1985             next if $cid eq $printed;
1986             $printed = $cid;
1987             print "  $info->{KcMsg}\n";
1988             $prcommitinfo->($cid);
1989         }
1990     }
1991
1992     my $prab = sub {
1993         my ($cid, $what) = @_;
1994         if (!defined $cid) {
1995             print "  $what is not well-defined\n";
1996         } else {
1997             print "  $what\n";
1998             $prcommitinfo->($cid);
1999         }
2000     };
2001     print "key git-debrebase commits:\n";
2002     $prab->($anchor, 'anchor');
2003     $prab->($bw, 'breakwater');
2004
2005     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2006         ffq_prev_branchinfo();
2007
2008     print "branch and ref status, in git-debrebase terms:\n";
2009     if ($ffq_msg) {
2010         print "  $ffq_msg\n";
2011     } else {
2012         $ffq_prev = git_get_ref $ffq_prev;
2013         $gdrlast = git_get_ref $gdrlast;
2014         if ($ffq_prev) {
2015             print "  unstitched; previous tip was:\n";
2016             $prcommitinfo->($ffq_prev);
2017         } elsif (!$gdrlast) {
2018             print "  stitched? (no record of git-debrebase work)\n";
2019         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2020             print "  stitched\n";
2021         } else {
2022             print "  not git-debrebase (diverged since last stitch)\n"
2023         }
2024     }
2025     print "you are currently rebasing\n" if currently_rebasing();
2026 }
2027
2028 sub cmd_stitch () {
2029     my $prose = 'stitch';
2030     getoptions("stitch",
2031                'prose=s', \$prose);
2032     badusage "no arguments allowed" if @ARGV;
2033     do_stitch $prose, 0;
2034 }
2035 sub cmd_prepush () { cmd_stitch(); }
2036
2037 sub cmd_quick () {
2038     badusage "no arguments allowed" if @ARGV;
2039     do_launder_head 'launder for git-debrebase quick';
2040     do_stitch 'quick';
2041 }
2042
2043 sub cmd_conclude () {
2044     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2045     if (!$ffq_prev_commitish) {
2046         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2047         return;
2048     }
2049     my $dangling_head = get_head();
2050
2051     badusage "no arguments allowed" if @ARGV;
2052     do_launder_head 'launder for git-debrebase quick';
2053     do_stitch 'quick';
2054 }
2055
2056 sub cmd_scrap () {
2057     if (currently_rebasing()) {
2058         runcmd @git, qw(rebase --abort);
2059     }
2060     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2061     if (!$ffq_prev_commitish) {
2062         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2063         finish 0;
2064     }
2065     my $scrapping_head = get_head();
2066     badusage "no arguments allowed" if @ARGV;
2067     push @deferred_updates,
2068         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2069         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2070     snags_maybe_bail();
2071     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2072 }
2073
2074 sub make_patches_staged ($) {
2075     my ($head) = @_;
2076     # Produces the patches that would result from $head if it were
2077     # laundered.
2078     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2079     fresh_workarea();
2080     in_workarea sub {
2081         gbp_pq_export 'bw', $secret_bw, $secret_head;
2082     };
2083 }
2084
2085 sub make_patches ($) {
2086     my ($head) = @_;
2087     keycommits $head, 0, \&snag;
2088     make_patches_staged $head;
2089     my $out;
2090     in_workarea sub {
2091         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2092         runcmd @git, qw(read-tree), $head;
2093         read_tree_subdir 'debian/patches', $ptree;
2094         $out = make_commit [$head], [
2095             'Commit patch queue (exported by git-debrebase)',
2096             '[git-debrebase: export and commit patches]',
2097         ];
2098     };
2099     return $out;
2100 }
2101
2102 sub cmd_make_patches () {
2103     my $opt_quiet_would_amend;
2104     getoptions("make-patches",
2105                'quiet-would-amend!', \$opt_quiet_would_amend);
2106     badusage "no arguments allowed" if @ARGV;
2107     bail_if_rebasing();
2108     my $old_head = get_head();
2109     my $new = make_patches $old_head;
2110     my $d = get_differs $old_head, $new;
2111     if ($d == 0) {
2112         fail "No (more) patches to export." unless $opt_noop_ok;
2113         return;
2114     } elsif ($d == D_PAT_ADD) {
2115         snags_maybe_bail();
2116         update_head_checkout $old_head, $new, 'make-patches';
2117     } else {
2118         print STDERR failmsg
2119             "Patch export produced patch amendments".
2120             " (abandoned output commit $new).".
2121             "  Try laundering first."
2122             unless $opt_quiet_would_amend;
2123         finish 7;
2124     }
2125 }
2126
2127 sub cmd_convert_from_gbp () {
2128     badusage "want only 1 optional argument, the upstream git commitish"
2129         unless @ARGV<=1;
2130
2131     my $clogp = parsechangelog();
2132     my $version = $clogp->{'Version'}
2133         // die "missing Version from changelog";
2134
2135     my ($upstream_spec) = @ARGV;
2136
2137     my $upstream_version = upstreamversion $version;
2138     my $upstream =
2139         resolve_upstream_version($upstream_spec, $upstream_version);
2140
2141     my $old_head = get_head();
2142
2143     my $upsdiff = get_differs $upstream, $old_head;
2144     if ($upsdiff & D_UPS) {
2145         runcmd @git, qw(--no-pager diff --stat),
2146             $upstream, $old_head,
2147             qw( -- :!/debian :/);
2148         fail <<END;
2149 upstream ($upstream_spec) and HEAD are not
2150 identical in upstream files.  See diffstat above, or run
2151   git diff $upstream_spec HEAD -- :!/debian :/
2152 END
2153     }
2154
2155     if (!is_fast_fwd $upstream, $old_head) {
2156         snag 'upstream-not-ancestor',
2157             "upstream ($upstream) is not an ancestor of HEAD";
2158     } else {
2159         my $wrong = cmdoutput
2160             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2161              qw(-- :/ :!/debian));
2162         if (length $wrong) {
2163             snag 'unexpected-upstream-changes',
2164                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2165             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2166         }
2167     }
2168
2169     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2170         snag 'upstream-has-debian',
2171             "upstream ($upstream) contains debian/ directory";
2172     }
2173
2174     my $previous_dgit_view = eval {
2175         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2176         my ($lvsn, $suite);
2177         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2178             my ($stz, $desc) = @_;
2179             no warnings qw(exiting);
2180             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2181             next unless $stz->{Date};
2182             next unless $stz->{Distribution} ne 'UNRELEASED';
2183             $lvsn = $stz->{Version};
2184             $suite = $stz->{Distribution};
2185             last;
2186         };
2187         die "neither of the first two changelog entries are released\n"
2188             unless defined $lvsn;
2189         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2190         my $mtag_pat = debiantag_maintview $lvsn, '*';
2191         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2192             $mtag_pat;
2193         die "could not find suitable maintainer view tag $mtag_pat\n"
2194             unless $mtag_pat =~ m{/};
2195         is_fast_fwd $mtag, 'HEAD' or
2196             die "HEAD is not FF from maintainer tag $mtag!";
2197         my $dtag = "archive/$mtag";
2198         is_fast_fwd $mtag, $dtag or
2199             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2200         print "will stitch in dgit view, $dtag\n";
2201         git_rev_parse $dtag;
2202     };
2203     if (!$previous_dgit_view) {
2204         $@ =~ s/^\n+//;
2205         chomp $@;
2206         print STDERR "cannot stitch in dgit view: $@\n";
2207     }
2208
2209     snags_maybe_bail_early();
2210
2211     my $work;
2212
2213     fresh_workarea();
2214     in_workarea sub {
2215         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2216         # make a branch out of the patch queue - we'll want this in a mo
2217         runcmd qw(gbp pq import);
2218         # strip the patches out
2219         runcmd @git, qw(checkout -q gdr-internal~0);
2220         rm_subdir_cached 'debian/patches';
2221         $work = make_commit ['HEAD'], [
2222  'git-debrebase convert-from-gbp: drop patches from tree',
2223  'Delete debian/patches, as part of converting to git-debrebase format.',
2224  '[git-debrebase convert-from-gbp: drop patches from tree]'
2225                               ];
2226         # make the anchor merge
2227         # the tree is already exactly right
2228         $work = make_commit [$work, $upstream], [
2229  'git-debrebase import: declare upstream',
2230  'First breakwater merge.',
2231  '[git-debrebase anchor: declare upstream]'
2232                               ];
2233
2234         # rebase the patch queue onto the new breakwater
2235         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2236         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2237         $work = git_rev_parse 'HEAD';
2238
2239         if ($previous_dgit_view) {
2240             $work = make_commit [$work, $previous_dgit_view], [
2241  'git-debrebase import: declare ff from dgit archive view',
2242  '[git-debrebase pseudomerge: import-from-gbp]',
2243             ];
2244         }
2245     };
2246
2247     ffq_check $work;
2248     snags_maybe_bail();
2249     update_head_checkout $old_head, $work, 'convert-from-gbp';
2250 }
2251
2252 sub cmd_convert_to_gbp () {
2253     badusage "no arguments allowed" if @ARGV;
2254     my $head = get_head();
2255     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2256     keycommits $head, 0;
2257     my $out;
2258     make_patches_staged $head;
2259     in_workarea sub {
2260         $out = make_commit ['HEAD'], [
2261             'Commit patch queue (converted from git-debrebase format)',
2262             '[git-debrebase convert-to-gbp: commit patches]',
2263         ];
2264     };
2265     if (defined $ffq) {
2266         push @deferred_updates, "delete $ffq";
2267         push @deferred_updates, "delete $gdrlast";
2268     }
2269     snags_maybe_bail();
2270     update_head_checkout $head, $out, "convert to gbp (v0)";
2271     print <<END or die $!;
2272 git-debrebase: converted to git-buildpackage branch format
2273 git-debrebase: WARNING: do not now run "git-debrebase" any more
2274 git-debrebase: WARNING: doing so would drop all upstream patches!
2275 END
2276 }
2277
2278 sub cmd_convert_from_dgit_view () {
2279     my $clogp = parsechangelog();
2280
2281     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2282     my $do_origs = 1;
2283     my $do_tags = 1;
2284     my $always = 0;
2285     my $diagnose = 0;
2286
2287     getoptions("convert-from-dgit-view",
2288                'diagnose!', \$diagnose,
2289                'build-products-dir:s', \$bpd,
2290                'origs!', \$do_origs,
2291                'tags!', \$do_tags,
2292                'always-convert-anyway!', \$always);
2293     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2294
2295     my @upstreams;
2296
2297     if (@ARGV) {
2298         my $spec = shift @ARGV;
2299         my $commit = git_rev_parse "$spec^{commit}";
2300         push @upstreams, { Commit => $commit,
2301                            Source => "$ARGV[0], from command line",
2302                            Only => 1,
2303                          };
2304     }
2305
2306     my $head = get_head();
2307
2308     if (!$always) {
2309         my $troubles = 0;
2310         my $trouble = sub { $troubles++; };
2311         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2312         printdebug "troubles=$troubles\n";
2313         if (!$troubles) {
2314             print STDERR <<END;
2315 $us: Branch already seems to be in git-debrebase format!
2316 $us: --always-convert-anyway would do the conversion operation anyway
2317 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2318 END
2319             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2320             finish 0;
2321         }
2322     }
2323
2324     snags_maybe_bail_early();
2325
2326     my $version = upstreamversion $clogp->{Version};
2327     print STDERR "Considering possible commits corresponding to upstream:\n";
2328
2329     if (!@upstreams) {
2330         if ($do_tags) {
2331             my @tried;
2332             my $ups_tag = upstream_commitish_search $version, \@tried;
2333             if ($ups_tag) {
2334                 my $this = "git tag $tried[-1]";
2335                 push @upstreams, { Commit => $ups_tag,
2336                                    Source => $this,
2337                                  };
2338             } else {
2339                 printf STDERR
2340                     " git tag: no suitable tag found (tried %s)\n",
2341                     "@tried";
2342             }
2343         }
2344         if ($do_origs) {
2345             my $p = $clogp->{'Source'};
2346             # we do a quick check to see if there are plausible origs
2347             my $something=0;
2348             if (!opendir BPD, $bpd) {
2349                 die "$bpd: opendir: $!" unless $!==ENOENT;
2350             } else {
2351                 while ($!=0, my $f = readdir BPD) {
2352                     next unless is_orig_file_of_p_v $f, $p, $version;
2353                     printf STDERR
2354                         " orig: found what looks like a .orig, %s\n",
2355                         "$bpd/$f";
2356                     $something=1;
2357                     last;
2358                 }
2359                 die "read $bpd: $!" if $!;
2360                 closedir BPD;
2361             }
2362             if ($something) {
2363                 my $tree = cmdoutput
2364                     @dgit, qw(--build-products-dir), $bpd,
2365                     qw(print-unapplied-treeish);
2366                 fresh_workarea();
2367                 in_workarea sub {
2368                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2369                     rm_subdir_cached 'debian';
2370                     $tree = cmdoutput @git, qw(write-tree);
2371                     my $ups_synth = make_commit [], [ <<END, <<END,
2372 Import effective orig tree for upstream version $version
2373 END
2374 This includes the contents of the .orig(s), minus any debian/ directory.
2375
2376 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2377 END
2378                                                     ];
2379                     push @upstreams, { Commit => $ups_synth,
2380                                        Source => "orig(s) imported via dgit",
2381                                      };
2382                 }
2383             } else {
2384                 printf STDERR
2385                     " orig: no suitable origs found (looked for %s in %s)\n",
2386                     "${p}_".(stripeoch $version)."...", $bpd;
2387             }
2388         }
2389     }
2390
2391     my $some_patches = stat_exists 'debian/patches/series';
2392
2393     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2394
2395     my $result;
2396     foreach my $u (@upstreams) {
2397         my $work = $head;
2398         fresh_workarea();
2399         in_workarea sub {
2400             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2401             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2402             runcmd @git, qw(clean -xdff);
2403             runcmd @git, qw(checkout), $head, qw(-- debian);
2404             if ($some_patches) {
2405                 rm_subdir_cached 'debian/patches';
2406                 $work = make_commit [ $work ], [
2407  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2408  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2409  "to git-debrebase format.  Upstream changes will appear as commits.",
2410  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2411                                            ];
2412             }
2413             $work = make_commit [ $work, $u->{Commit} ], [
2414  'git-debrebase convert-from-dgit-view: declare upstream',
2415  '(Re)constructed breakwater merge.',
2416  '[git-debrebase anchor: declare upstream]'
2417                                                          ];
2418             runcmd @git, qw(checkout --quiet -b mk), $work;
2419             if ($some_patches) {
2420                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2421                 runcmd @git, qw(reset --quiet);
2422                 my @gbp_cmd = (qw(gbp pq import));
2423                 if (!$diagnose) {
2424                     my $gbp_err = "../gbp-pq-err";
2425                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2426                 }
2427                 my $r = system @gbp_cmd;
2428                 if ($r) {
2429                     printf STDERR
2430                         " %s: couldn't apply patches: gbp pq %s",
2431                         $u->{Source}, waitstatusmsg();
2432                     return;
2433                 }
2434             }
2435             my $work = git_rev_parse qw(HEAD);
2436             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2437             if (length $diffout) {
2438                 print STDERR
2439                     " $u->{Source}: applying patches gives different tree\n";
2440                 print STDERR $diffout if $diagnose;
2441                 return;
2442             }
2443             # OMG!
2444             $u->{Result} = $work;
2445             $result = $u;
2446         };
2447         last if $result;
2448     }
2449
2450     if (!$result) {
2451         fail <<END;
2452 Could not find or construct a suitable upstream commit.
2453 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2454 upstream commmit explicitly or provide suitable origs.
2455 END
2456     }
2457
2458     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2459
2460     ffq_check $result->{Result};
2461     snags_maybe_bail();
2462     update_head_checkout $head, $result->{Result},
2463         'convert-from-dgit-view';
2464 }
2465
2466 sub cmd_downstream_rebase_launder_v0 () {
2467     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2468     my ($base) = @ARGV;
2469     $base = git_rev_parse $base;
2470     my $old_head = get_head();
2471     my $current = $old_head;
2472     my $topmost_keep;
2473     for (;;) {
2474         if ($current eq $base) {
2475             $topmost_keep //= $current;
2476             print " $current BASE stop\n";
2477             last;
2478         }
2479         my $cl = classify $current;
2480         print " $current $cl->{Type}";
2481         my $keep = 0;
2482         my $p0 = $cl->{Parents}[0]{CommitId};
2483         my $next;
2484         if ($cl->{Type} eq 'Pseudomerge') {
2485             print " ^".($cl->{Contributor}{Ix}+1);
2486             $next = $cl->{Contributor}{CommitId};
2487         } elsif ($cl->{Type} eq 'AddPatches' or
2488                  $cl->{Type} eq 'Changelog') {
2489             print " strip";
2490             $next = $p0;
2491         } else {
2492             print " keep";
2493             $next = $p0;
2494             $keep = 1;
2495         }
2496         print "\n";
2497         if ($keep) {
2498             $topmost_keep //= $current;
2499         } else {
2500             die "to-be stripped changes not on top of the branch\n"
2501                 if $topmost_keep;
2502         }
2503         $current = $next;
2504     }
2505     if ($topmost_keep eq $old_head) {
2506         print "unchanged\n";
2507     } else {
2508         print "updating to $topmost_keep\n";
2509         update_head_checkout
2510             $old_head, $topmost_keep,
2511             'downstream-rebase-launder-v0';
2512     }
2513 }
2514
2515 getoptions_main
2516           ("bad options\n",
2517            "D+" => \$debuglevel,
2518            'noop-ok', => \$opt_noop_ok,
2519            'f=s' => \@snag_force_opts,
2520            'anchor=s' => \@opt_anchors,
2521            '--dgit=s' => \($dgit[0]),
2522            'force!',
2523            '-i:s' => sub {
2524                my ($opt,$val) = @_;
2525                badusage "git-debrebase: no cuddling to -i for git-rebase"
2526                    if length $val;
2527                die if $opt_defaultcmd_interactive; # should not happen
2528                $opt_defaultcmd_interactive = [ qw(-i) ];
2529                # This access to @ARGV is excessive familiarity with
2530                # Getopt::Long, but there isn't another sensible
2531                # approach.  '-i=s{0,}' does not work with bundling.
2532                push @$opt_defaultcmd_interactive, @ARGV;
2533                @ARGV=();
2534            },
2535            'help' => sub { print $usage_message or die $!; finish 0; },
2536            );
2537
2538 initdebug('git-debrebase ');
2539 enabledebug if $debuglevel;
2540
2541 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2542 chdir $toplevel or die "chdir $toplevel: $!";
2543
2544 $rd = fresh_playground "$playprefix/misc";
2545
2546 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2547
2548 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2549     defaultcmd_rebase();
2550 } else {
2551     my $cmd = shift @ARGV;
2552     my $cmdfn = $cmd;
2553     $cmdfn =~ y/-/_/;
2554     $cmdfn = ${*::}{"cmd_$cmdfn"};
2555
2556     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2557     $cmdfn->();
2558 }
2559
2560 finish 0;