git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_careful, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 $opt_careful = 0;
  57
  58 our $us = qw(git-debrebase);
  59
  60 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  61 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  62
  63 $|=1;
  64
  65 sub badusage ($) {
  66     my ($m) = @_;
  67     print STDERR "$us: bad usage: $m\n";
  68     finish 8;
  69 }
  70
  71 sub getoptions_main {
  72     my $m = shift;
  73     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  74     GetOptions @_ or badusage $m;
  75 }
  76 sub getoptions {
  77     my $sc = shift;
  78     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  79 }
  80
  81 sub cfg ($;$) {
  82     my ($k, $optional) = @_;
  83     local $/ = "\0";
  84     my @cmd = qw(git config -z);
  85     push @cmd, qw(--get-all) if wantarray;
  86     push @cmd, $k;
  87     my $out = cmdoutput_errok @cmd;
  88     if (!defined $out) {
  89         fail "missing required git config $k" unless $optional;
  90         return ();
  91     }
  92     my @l = split /\0/, $out;
  93     return wantarray ? @l : $l[0];
  94 }
  95
  96 memoize('cfg');
  97
  98 sub dd ($) {
  99     my ($v) = @_;
 100     my $dd = new Data::Dumper [ $v ];
 101     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 102     return Dump $dd;
 103 }
 104
 105 sub get_commit ($) {
 106     my ($objid) = @_;
 107     my $data = (git_cat_file $objid, 'commit');
 108     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 109     return ($`,$');
 110 }
 111
 112 sub D_UPS ()      { 0x02; } # upstream files
 113 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 114 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 115 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 116 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 117 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 118
 119 our $playprefix = 'debrebase';
 120 our $rd;
 121 our $workarea;
 122
 123 our @git = qw(git);
 124 our @dgit = qw(dgit);
 125
 126 sub in_workarea ($) {
 127     my ($sub) = @_;
 128     changedir $workarea;
 129     my $r = eval { $sub->(); };
 130     { local $@; changedir $maindir; }
 131     die $@ if $@;
 132 }
 133
 134 sub fresh_workarea (;$) {
 135     my ($subdir) = @_;
 136     $subdir //= 'work';
 137     $workarea = fresh_playground "$playprefix/$subdir";
 138     in_workarea sub { playtree_setup };
 139 }
 140
 141 sub run_ref_updates_now ($$) {
 142     my ($mrest, $updates) = @_;
 143     # @$updates is a list of lines for git-update-ref, without \ns
 144
 145     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 146     debugcmd '>|', @upd_cmd;
 147     open U, "|-", @upd_cmd or die $!;
 148     foreach (@$updates) {
 149         printdebug ">= ", $_, "\n";
 150         print U $_, "\n" or die $!;
 151     }
 152     printdebug ">\$\n";
 153     close U or failedcmd @upd_cmd;
 154 }
 155
 156 our $snags_forced = 0;
 157 our $snags_tripped = 0;
 158 our $snags_summarised = 0;
 159 our @deferred_updates;
 160 our @deferred_update_messages;
 161
 162 sub merge_wreckage_cleaning ($) {
 163     my ($updates) = @_;
 164     git_for_each_ref("$wrecknoteprefix/*", sub {
 165         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 166         push @$updates, "delete $fullrefname";
 167     });
 168 }
 169
 170 sub all_snags_summarised () {
 171     $snags_forced + $snags_tripped == $snags_summarised;
 172 }
 173 sub run_deferred_updates ($) {
 174     my ($mrest) = @_;
 175
 176     confess 'dangerous internal error' unless all_snags_summarised();
 177
 178     merge_wreckage_cleaning \@deferred_updates;
 179     run_ref_updates_now $mrest, \@deferred_updates;
 180     print $_, "\n" foreach @deferred_update_messages;
 181
 182     @deferred_updates = ();
 183     @deferred_update_messages = ();
 184 }
 185
 186 sub get_tree ($;$$) {
 187     # tree object name => ([ $name, $info ], ...)
 188     # where $name is the sort key, ie has / at end for subtrees
 189     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 190     # without $precheck, will crash if $x does not exist, so don't do that;
 191     # instead pass '' to get ().
 192     my ($x, $precheck, $recurse) = @_;
 193
 194     return () if !length $x;
 195
 196     if ($precheck) {
 197         my ($type, $dummy) = git_cat_file $x, [qw(tree missing)];
 198         return () if $type eq 'missing';
 199     }
 200
 201     our (@get_tree_memo, %get_tree_memo);
 202     my $memo = $get_tree_memo{$x};
 203     return @$memo if $memo;
 204
 205     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 206     my @l;
 207     my @cmd = (qw(git ls-tree -z --full-tree));
 208     push @cmd, qw(-r) if $recurse;
 209     push @cmd, qw(--), $x;
 210     my $o = cmdoutput @cmd;
 211     $o =~ s/\0$//s;
 212     my $last = '';
 213     foreach my $l (split /\0/, $o) {
 214         my ($i, $n) = split /\t/, $l, 2;
 215         $n .= '/' if $i =~ m/^\d+ tree /;
 216         push @l, [ $n, $i ];
 217         confess "$x need $last < $n ?" unless $last lt $n;
 218     }
 219     $get_tree_memo{$x} = \@l;
 220     push @get_tree_memo, $x;
 221     if (@get_tree_memo > 10) {
 222         delete $get_tree_memo{ shift @get_tree_memo };
 223     }
 224     return @l;
 225 }
 226
 227 sub trees_diff_walk ($$$;$) {
 228     # trees_diff_walk [$all,] $x, $y, sub {... }
 229     # calls sub->($name, $ix, $iy) for each difference (with $all, each name)
 230     # $x and $y are as for get_tree
 231     # where $name, $ix, $iy are $name and $info from get_tree
 232     my $all = shift @_ if @_>=4;
 233     my ($x,$y,$call) = @_;
 234     return if !$all and $x eq $y;
 235     my @x = get_tree $x;
 236     my @y = get_tree $y;
 237     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 238         if $debuglevel >= 3;
 239     while (@x || @y) {
 240         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 241              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 242         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 243         $ix=$iy='';
 244         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 245             if $debuglevel >= 3;
 246         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 247         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 248         next if !$all and $ix eq $iy;
 249         printdebug sprintf
 250             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 251             !!$all,$x,$y, $n,$ix,$iy
 252             if $debuglevel >= 2;
 253         $call->($n, $ix, $iy);
 254     }
 255 }
 256
 257 sub get_differs ($$) {
 258     my ($x,$y) = @_;
 259     # This does a similar job to quiltify_trees_differ, in dgit, a bit.
 260     # But we don't care about modes, or dpkg-source-unrepresentable
 261     # changes, and we don't need the plethora of different modes.
 262     # Conversely we need to distinguish different kinds of changes to
 263     # debian/ and debian/patches/.
 264     # Also, here we have, and want to use, trees_diff_walk, because
 265     # we may be calling this an awful lot and we want it to be fast.
 266
 267     my $differs = 0;
 268     my @debian_info;
 269
 270     no warnings qw(exiting);
 271
 272     my $plain = sub { $_[0] =~ m{^(100|0*)644 blob }s; };
 273
 274     trees_diff_walk "$x:", "$y:", sub {
 275         my ($n,$ix,$iy) = @_;
 276
 277         # analyse difference at the toplevel
 278
 279         if ($n ne 'debian/') {
 280             $differs |= D_UPS;
 281             next;
 282         }
 283         if ($n eq 'debian') {
 284             # one side has a non-tree for ./debian !
 285             $differs |= D_DEB_OTH;
 286             next;
 287         }
 288
 289         my $xd = $ix && "$x:debian";
 290         my $yd = $iy && "$y:debian";
 291         trees_diff_walk $xd, $yd, sub {
 292             my ($n,$ix,$iy) = @_;
 293
 294             # analyse difference in debian/
 295
 296             if ($n eq 'changelog' && (!$ix || $plain->($ix))
 297                                   &&          $plain->($iy) ) {
 298                 $differs |= D_DEB_CLOG;
 299                 next;
 300             }
 301             if ($n ne 'patches/') {
 302                 $differs |= D_DEB_OTH;
 303                 next;
 304             }
 305
 306             my $xp = $ix && "$xd/patches";
 307             my $yp = $iy && "$yd/patches";
 308             trees_diff_walk $xp, $yp, sub {
 309                 my ($n,$ix,$iy) = @_;
 310
 311                 # analyse difference in debian/patches
 312
 313                 my $ok;
 314                 if ($n !~ m/\.series$/s && !$ix && $plain->($iy)) {
 315                     $ok = 1;
 316                 } elsif ($n eq 'series' && $plain->($ix) && $plain->($iy)) {
 317                     my $x_s = (git_cat_file "$xp/series", 'blob');
 318                     my $y_s = (git_cat_file "$yp/series", 'blob');
 319                     chomp $x_s;  $x_s .= "\n";
 320                     $ok = $x_s eq substr($y_s, 0, length $x_s);
 321                 } else {
 322                     # nope
 323                 }
 324                 $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 325             };
 326         };
 327     };
 328
 329     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 330
 331     return $differs;
 332 }
 333
 334 sub commit_pr_info ($) {
 335     my ($r) = @_;
 336     return Data::Dumper->dump([$r], [qw(commit)]);
 337 }
 338
 339 sub calculate_committer_authline () {
 340     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 341         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 342     my ($h,$m) = get_commit $c;
 343     $h =~ m/^committer .*$/m or confess "($h) ?";
 344     return $&;
 345 }
 346
 347 sub rm_subdir_cached ($) {
 348     my ($subdir) = @_;
 349     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 350 }
 351
 352 sub read_tree_subdir ($$) {
 353     my ($subdir, $new_tree_object) = @_;
 354     rm_subdir_cached $subdir;
 355     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 356 }
 357
 358 sub read_tree_debian ($) {
 359     my ($treeish) = @_;
 360     read_tree_subdir 'debian', "$treeish:debian";
 361     rm_subdir_cached 'debian/patches';
 362 }
 363
 364 sub read_tree_upstream ($;$$) {
 365     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 366     # if $tree_with_debian is supplied, will use that for debian/
 367     # otherwise will save and restore it.
 368     my $debian =
 369         $tree_with_debian ? "$tree_with_debian:debian"
 370         : cmdoutput @git, qw(write-tree --prefix=debian/);
 371     runcmd @git, qw(read-tree), $treeish;
 372     read_tree_subdir 'debian', $debian;
 373     rm_subdir_cached 'debian/patches' unless $keep_patches;
 374 };
 375
 376 sub make_commit ($$) {
 377     my ($parents, $message_paras) = @_;
 378     my $tree = cmdoutput @git, qw(write-tree);
 379     my @cmd = (@git, qw(commit-tree), $tree);
 380     push @cmd, qw(-p), $_ foreach @$parents;
 381     push @cmd, qw(-m), $_ foreach @$message_paras;
 382     return cmdoutput @cmd;
 383 }
 384
 385 our @snag_force_opts;
 386 sub snag ($$;@) {
 387     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 388     if (grep { $_ eq $tag } @snag_force_opts) {
 389         $snags_forced++;
 390         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 391     } else {
 392         $snags_tripped++;
 393         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 394     }
 395 }
 396
 397 # Important: all mainline code must call snags_maybe_bail after
 398 # any point where snag might be called, but before making changes
 399 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 400 # may be called more than once if necessary (but this is not ideal
 401 # because then the messages about number of snags may be confusing).
 402 sub snags_maybe_bail () {
 403     return if all_snags_summarised();
 404     if ($snags_forced) {
 405         printf STDERR
 406             "%s: snags: %d overriden by individual -f options\n",
 407             $us, $snags_forced;
 408     }
 409     if ($snags_tripped) {
 410         if ($opt_force) {
 411             printf STDERR
 412                 "%s: snags: %d overriden by global --force\n",
 413                 $us, $snags_tripped;
 414         } else {
 415             fail sprintf
 416   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 417                 $us, $snags_tripped;
 418         }
 419     }
 420     $snags_summarised = $snags_forced + $snags_tripped;
 421 }
 422 sub snags_maybe_bail_early () {
 423     # useful to bail out early without doing a lot of work;
 424     # not a substitute for snags_maybe_bail.
 425     snags_maybe_bail() if $snags_tripped && !$opt_force;
 426 }
 427 sub any_snags () {
 428     return $snags_forced || $snags_tripped;
 429 }
 430
 431 sub gbp_pq_export ($$$) {
 432     my ($bname, $base, $tip) = @_;
 433     # must be run in a workarea.  $bname and patch-queue/$bname
 434     # ought not to exist.  Leaves you on patch-queue/$bname with
 435     # the patches staged but not committed.
 436     printdebug "gbp_pq_export $bname $base $tip\n";
 437     runcmd @git, qw(checkout -q -b), $bname, $base;
 438     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 439     my @gbp_cmd = (qw(gbp pq export));
 440     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 441     if ($r) {
 442         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 443         failedcmd @gbp_cmd;
 444     }
 445     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 446 }
 447
 448
 449 # xxx allow merge resolution separately from laundering, before git merge
 450 #
 451 # xxx general gdr docs highlight forbidden things
 452 # xxx general gdr docs list allowable things ?
 453 # xxx general gdr docs explicitly forbid some rebase
 454
 455 # later/rework?
 456 #  use git-format-patch?
 457 #  our own patch identification algorithm?
 458 #  this is an alternative strategy
 459
 460 sub merge_failed ($$;@) {
 461     my ($wrecknotes, $emsg, @xmsgs) = @_;
 462     my @m;
 463     push @m, "Merge resolution failed: $emsg";
 464     push @m, @xmsgs;
 465
 466     changedir $maindir;
 467
 468     my @updates;
 469     merge_wreckage_cleaning \@updates;
 470     run_ref_updates_now "merge failed", \@updates;
 471
 472     @updates = ();
 473     keys %$wrecknotes;
 474     while (my ($k,$v) = each %$wrecknotes) {
 475         push @updates, "create $wrecknoteprefix/$k $v";
 476     }
 477     run_ref_updates_now "merge failed", \@updates;
 478     push @m, "Wreckage left in $wrecknoteprefix/*.";
 479
 480     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 481
 482     # use finish rather than fail, in case we are within an eval
 483     # (that can happen inside walk!)
 484     print STDERR "\n";
 485     print STDERR "$us: $_\n" foreach @m;
 486     finish 15;
 487 }
 488
 489 sub mwrecknote ($$$) {
 490     my ($wrecknotes, $reftail, $commitish) = @_;
 491     confess unless defined $commitish;
 492     printdebug "mwrecknote $reftail $commitish\n";
 493     $wrecknotes->{$reftail} = $commitish;
 494 }
 495
 496 sub merge_attempt_cmd {
 497     my $wrecknotes = shift @_;
 498     debugcmd '+', @_;
 499     $!=0; $?=-1;
 500     if (system @_) {
 501         merge_failed $wrecknotes,
 502             failedcmd_waitstatus(),
 503             "failed command: @_";
 504     }
 505 }
 506
 507 sub merge_series_patchqueue_convert ($$$);
 508
 509 sub merge_series ($$$;@) {
 510     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 511     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 512     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 513     # ^ specifies several patch series (currently we only support exactly 2)
 514     # return value is a commit which is the result of
 515     # merging the two versions of the same topic branch
 516     #   $input_q[0] and $input_q[1]
 517     # with respect to the old version
 518     #   $base_q
 519     # all onto $newbase.
 520
 521     # Creates, in *_q, a key MR for its private use
 522
 523     printdebug "merge_series newbase=$newbase\n";
 524
 525     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 526     $base_q->{MR}{S} = 'base';
 527
 528     my %prereq;
 529     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 530     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 531     # $prereq{<patch filename>}               exists or not (even later)
 532
 533     my $merged_pq;
 534
 535     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 536
 537     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 538
 539     local $workarea;
 540     fresh_workarea "merge";
 541     my $seriesfile = "debian/patches/series";
 542     in_workarea sub {
 543         playtree_setup();
 544         foreach my $q ($base_q, reverse @input_qs) {
 545             my $s = $q->{MR}{S};
 546             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 547             my @earlier;
 548             if (open S, $seriesfile) {
 549                 while (my $patch = <S>) {
 550                     chomp $patch or die $!;
 551                     $prereq{$patch} //= {};
 552                     foreach my $earlier (@earlier) {
 553                         $prereq{$patch}{$earlier}{$s}++ and die;
 554                     }
 555                     push @earlier, $patch;
 556                     stat "debian/patches/$patch" or die "$patch ?";
 557                 }
 558                 S->error and die "$seriesfile $!";
 559                 close S;
 560             } else {
 561                 die "$seriesfile $!" unless $!==ENOENT;
 562             }
 563             read_tree_upstream $newbase, 1;
 564             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 565                 "Convert $s to patch queue for merging",
 566                 "[git-debrebase merge-innards patch-queue import:".
 567                 " $q->{SeriesTip}]"
 568             ];
 569             printdebug "merge_series  pec $pec ";
 570             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 571             $pec = make_commit [ $pec ], [
 572                 "Drop series file from $s to avoid merge trouble",
 573                 "[git-debrebase merge-innards patch-queue prep:".
 574                 " $q->{SeriesTip}]"
 575             ];
 576
 577             read_tree_debian $newbase;
 578             if (@earlier) {
 579                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 580             } else {
 581                 rm_subdir_cached 'debian/patches';
 582             }
 583             $pec = make_commit [ $pec ], [
 584  "Update debian/ (excluding patches) to final to avoid re-merging",
 585  "debian/ was already merged and we need to just take that.",
 586                 "[git-debrebase merge-innards patch-queue packaging:".
 587                 " $q->{SeriesTip}]"
 588             ];
 589
 590             printdebug "pec' $pec\n";
 591             runcmd @git, qw(reset -q --hard), $pec;
 592             $q->{MR}{PEC} = $pec;
 593             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 594         }
 595         # now, because of reverse, we are on $input_q->{MR}{OQC}
 596         runcmd @git, qw(checkout -q -b merge);
 597         printdebug "merge_series merging...\n";
 598         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 599
 600         $attempt_cmd->(@mergecmd);
 601
 602         printdebug "merge_series merge ok, series...\n";
 603         # We need to construct a new series file
 604         # Firstly, resolve prereq
 605         foreach my $f (sort keys %prereq) {
 606             printdebug "merge_series  patch\t$f\t";
 607             if (!stat_exists "debian/patches/$f") {
 608                 print DEBUG " drop\n" if $debuglevel;
 609                 # git merge deleted it; that's how we tell it's not wanted
 610                 delete $prereq{$f};
 611                 next;
 612             }
 613             print DEBUG " keep\n" if $debuglevel;
 614             foreach my $g (sort keys %{ $prereq{$f} }) {
 615                 my $gfp = $prereq{$f}{$g};
 616                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 617                 if (!!$gfp->{0} == !!$gfp->{1}
 618                     ? $gfp->{0}
 619                     : !$gfp->{base}) {
 620                     print DEBUG "\tkeep\n" if $debuglevel;
 621                 } else {
 622                     print DEBUG "\tdrop\n" if $debuglevel;
 623                     delete $prereq{$f}{$g};
 624                 }
 625             }
 626         }
 627
 628         my $unsat = sub {
 629             my ($f) = @_;
 630             return scalar keys %{ $prereq{$f} };
 631         };
 632
 633         my $nodate = time + 1;
 634         my %authordate;
 635         # $authordate{<patch filename>};
 636         my $authordate = sub {
 637             my ($f) = @_;
 638             $authordate{$f} //= do {
 639                 open PF, "<", "debian/patches/$f" or die "$f $!";
 640                 while (<PF>) {
 641                     return $nodate if m/^$/;
 642                     last if s{^Date: }{};
 643                 }
 644                 chomp;
 645                 return cmdoutput qw(date +%s -d), $_;
 646             };
 647         };
 648
 649         open NS, '>', $seriesfile or die $!;
 650
 651         while (keys %prereq) {
 652             my $best;
 653             foreach my $try (sort keys %prereq) {
 654                 if ($best) {
 655                     next if (
 656                              $unsat->($try) <=> $unsat->($best) or
 657                              $authordate->($try) <=> $authordate->($best) or
 658                              $try cmp $best
 659                             ) >= 0;
 660                 }
 661                 $best = $try;
 662             }
 663             printdebug "merge_series series next $best\n";
 664             print NS "$best\n" or die $!;
 665             delete $prereq{$best};
 666             foreach my $gp (values %prereq) {
 667                 delete $gp->{$best};
 668             }
 669         }
 670
 671         runcmd @git, qw(add), $seriesfile;
 672         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 673         $merged_pq = git_rev_parse 'HEAD';
 674         $mwrecknote->('merged-patchqueue', $merged_pq);
 675     };
 676     return merge_series_patchqueue_convert
 677             $wrecknotes, $newbase, $merged_pq;
 678 }
 679
 680 sub merge_series_patchqueue_convert ($$$) {
 681     my ($wrecknotes, $newbase, $merged_pq) = @_;
 682
 683     my $result;
 684     in_workarea sub {
 685         playtree_setup();
 686         printdebug "merge_series series gbp pq import\n";
 687         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 688
 689         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 690
 691         # OK now we are on patch-queue/merge, and we need to rebase
 692         # onto the intended parent and drop the patches from each one
 693
 694         printdebug "merge_series series ok, building...\n";
 695         my $build = $newbase;
 696         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 697         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 698             my $commit = git_cat_file $c, 'commit';
 699             printdebug "merge_series series ok, building $c\n";
 700             read_tree_upstream $c, 0, $newbase;
 701             my $tree = cmdoutput @git, qw(write-tree);
 702             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 703             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 704             open C, ">", "../mcommit" or die $!;
 705             print C $commit or die $!;
 706             close C or die $!;
 707             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 708         }
 709         $result = $build;
 710         mwrecknote($wrecknotes, 'merged-result', $result);
 711
 712         runcmd @git, qw(update-ref refs/heads/result), $result;
 713
 714         runcmd @git, qw(checkout -q -b debug);
 715         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 716         runcmd @git, qw(add .);
 717         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 718         my $mdebug = git_rev_parse 'HEAD';
 719         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 720         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 721     };
 722     printdebug "merge_series returns $result\n";
 723     return $result;
 724 }
 725
 726 # classify returns an info hash like this
 727 #   CommitId => $objid
 728 #   Hdr => # commit headers, including 1 final newline
 729 #   Msg => # commit message (so one newline is dropped)
 730 #   Tree => $treeobjid
 731 #   Type => (see below)
 732 #   Parents = [ {
 733 #       Ix => $index # ie 0, 1, 2, ...
 734 #       CommitId
 735 #       Differs => return value from get_differs
 736 #       IsOrigin
 737 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 738 #     } ...]
 739 #   NewMsg => # commit message, but with any [dgit import ...] edited
 740 #             # to say "[was: ...]"
 741 #
 742 # Types:
 743 #   Packaging
 744 #   Changelog
 745 #   Upstream
 746 #   AddPatches
 747 #   Mixed
 748 #
 749 #   Pseudomerge
 750 #     has additional entres in classification result
 751 #       Overwritten = [ subset of Parents ]
 752 #       Contributor = $the_remaining_Parent
 753 #
 754 #   DgitImportUnpatched
 755 #     has additional entry in classification result
 756 #       OrigParents = [ subset of Parents ]
 757 #
 758 #   Anchor
 759 #     has additional entry in classification result
 760 #       OrigParents = [ subset of Parents ]  # singleton list
 761 #
 762 #   TreatAsAnchor
 763 #
 764 #   BreakwaterStart
 765 #
 766 #   Unknown
 767 #     has additional entry in classification result
 768 #       Why => "prose"
 769
 770 sub parsecommit ($;$) {
 771     my ($objid, $p_ref) = @_;
 772     # => hash with                   CommitId Hdr Msg Tree Parents
 773     #    Parents entries have only   Ix CommitId
 774     #    $p_ref, if provided, must be [] and is used as a base for Parents
 775
 776     $p_ref //= [];
 777     die if @$p_ref;
 778
 779     my ($h,$m) = get_commit $objid;
 780
 781     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 782     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 783
 784     my $r = {
 785         CommitId => $objid,
 786         Hdr => $h,
 787         Msg => $m,
 788         Tree => $t,
 789         Parents => $p_ref,
 790     };
 791
 792     foreach my $ph (@ph) {
 793         push @$p_ref, {
 794             Ix => scalar @$p_ref,
 795             CommitId => $ph,
 796         };
 797     }
 798
 799     return $r;
 800 }
 801
 802 sub classify ($) {
 803     my ($objid) = @_;
 804
 805     my @p;
 806     my $r = parsecommit($objid, \@p);
 807     my $t = $r->{Tree};
 808
 809     foreach my $p (@p) {
 810         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 811     }
 812
 813     printdebug "classify $objid \$t=$t \@p",
 814         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 815         "\n";
 816
 817     my $classify = sub {
 818         my ($type, @rest) = @_;
 819         $r = { %$r, Type => $type, @rest };
 820         if ($debuglevel) {
 821             printdebug " = $type ".(dd $r)."\n";
 822         }
 823         return $r;
 824     };
 825     my $unknown = sub {
 826         my ($why) = @_;
 827         $r = { %$r, Type => qw(Unknown), Why => $why };
 828         printdebug " ** Unknown\n";
 829         return $r;
 830     };
 831
 832     if (grep { $_ eq $objid } @opt_anchors) {
 833         return $classify->('TreatAsAnchor');
 834     }
 835
 836     my @identical = grep { !$_->{Differs} } @p;
 837     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 838     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 839
 840     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 841         # multi-orig upstreams are represented with an anchor merge
 842         # from a single upstream commit which combines the orig tarballs
 843
 844         # Every anchor tagged this way must be a merge.
 845         # We are relying on the
 846         #     [git-debrebase anchor: ...]
 847         # commit message annotation in "declare" anchor merges (which
 848         # do not have any upstream changes), to distinguish those
 849         # anchor merges from ordinary pseudomerges (which we might
 850         # just try to strip).
 851         #
 852         # However, the user is going to be doing git-rebase a lot.  We
 853         # really don't want them to rewrite an anchor commit.
 854         # git-rebase trips up on merges, so that is a useful safety
 855         # catch.
 856         #
 857         # BreakwaterStart commits are also anchors in the terminology
 858         # of git-debrebase(5), but they are untagged (and always
 859         # manually generated).
 860         #
 861         # We cannot not tolerate any tagged linear commit (ie,
 862         # BreakwaterStart commits tagged `[anchor:') because such a
 863         # thing could result from an erroneous linearising raw git
 864         # rebase of a merge anchor.  That would represent a corruption
 865         # of the branch. and we want to detect and reject the results
 866         # of such corruption before it makes it out anywhere.  If we
 867         # reject it here then we avoid making the pseudomerge which
 868         # would be needed to push it.
 869
 870         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 871         @p == 2 or return $badanchor->("has other than two parents");
 872         $haspatches and return $badanchor->("contains debian/patches");
 873
 874         # How to decide about l/r ordering of anchors ?  git
 875         # --topo-order prefers to expand 2nd parent first.  There's
 876         # already an easy rune to look for debian/ history anyway (git log
 877         # debian/) so debian breakwater branch should be 1st parent; that
 878         # way also there's also an easy rune to look for the upstream
 879         # patches (--topo-order).
 880
 881         # Also this makes --first-parent be slightly more likely to
 882         # be useful - it makes it provide a linearised breakwater history.
 883
 884         # Of course one can say somthing like
 885         #  gitk -- ':/' ':!/debian'
 886         # to get _just_ the commits touching upstream files, and by
 887         # the TREESAME logic in git-rev-list this will leave the
 888         # breakwater into upstream at the first anchor.  But that
 889         # doesn't report debian/ changes at all.
 890
 891         # Other observations about gitk: by default, gitk seems to
 892         # produce output in a different order to git-rev-list.  I
 893         # can't seem to find this documented anywhere.  gitk
 894         # --date-order DTRT.  But, gitk always seems to put the
 895         # parents from left to right, in order, so it's easy to see
 896         # which way round a pseudomerge is.
 897
 898         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 899         $p[1]{Differs} & ~DS_DEB and
 900             $badanchor->("upstream files differ from left parent");
 901         $p[0]{Differs} & ~D_UPS and
 902             $badanchor->("debian/ differs from right parent");
 903
 904         return $classify->(qw(Anchor),
 905                            OrigParents => [ $p[1] ]);
 906     }
 907
 908     if (@p == 1) {
 909         my $d = $r->{Parents}[0]{Differs};
 910         if ($d == D_PAT_ADD) {
 911             return $classify->(qw(AddPatches));
 912         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 913             return $unknown->("edits debian/patches");
 914         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 915             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 916             if ($ty eq 'tree') {
 917                 if ($d == D_DEB_CLOG) {
 918                     return $classify->(qw(Changelog));
 919                 } else {
 920                     return $classify->(qw(Packaging));
 921                 }
 922             } elsif ($ty eq 'missing') {
 923                 return $classify->(qw(BreakwaterStart));
 924             } else {
 925                 return $unknown->("parent's debian is not a directory");
 926             }
 927         } elsif ($d == D_UPS) {
 928             return $classify->(qw(Upstream));
 929         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 930             return $classify->(qw(Mixed));
 931         } elsif ($d == 0) {
 932             return $unknown->("no changes");
 933         } else {
 934             confess "internal error $objid ?";
 935         }
 936     }
 937     if (!@p) {
 938         return $unknown->("origin commit");
 939     }
 940
 941     if (@p == 2 && @identical == 1) {
 942         my @overwritten = grep { $_->{Differs} } @p;
 943         confess "internal error $objid ?" unless @overwritten==1;
 944         return $classify->(qw(Pseudomerge),
 945                            Overwritten => [ $overwritten[0] ],
 946                            Contributor => $identical[0]);
 947     }
 948     if (@p == 2 && @identical == 2) {
 949         my $get_t = sub {
 950             my ($ph,$pm) = get_commit $_[0]{CommitId};
 951             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 952             $1;
 953         };
 954         my @bytime = @p;
 955         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 956         if ($order > 0) { # newer first
 957         } elsif ($order < 0) {
 958             @bytime = reverse @bytime;
 959         } else {
 960             # same age, default to order made by -s ours
 961             # that is, commit was made by someone who preferred L
 962         }
 963         return $classify->(qw(Pseudomerge),
 964                            SubType => qw(Ambiguous),
 965                            Contributor => $bytime[0],
 966                            Overwritten => [ $bytime[1] ]);
 967     }
 968     foreach my $p (@p) {
 969         my ($p_h, $p_m) = get_commit $p->{CommitId};
 970         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 971         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 972     }
 973     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 974     my $m2 = $r->{Msg};
 975     if (!(grep { !$_->{IsOrigin} } @p) and
 976         (@orig_ps >= @p - 1) and
 977         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 978         $r->{NewMsg} = $m2;
 979         return $classify->(qw(DgitImportUnpatched),
 980                            OrigParents => \@orig_ps);
 981     }
 982
 983     if (@p == 2 and
 984         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 985         # xxx ^ metadata tag needs adding to (5)
 986         return $classify->("MergedBreakwaters");
 987     }
 988     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 989         return $unknown->("unknown kind of merge from $1");
 990     }
 991     if (@p > 2) {
 992         return $unknown->("octopus merge");
 993     }
 994
 995     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 996         return $unknown->("general two-parent merge");
 997     }
 998
 999     return $classify->("VanillaMerge");
1000 }
1001
1002 sub keycommits ($;$$$$$);
1003
1004 sub mergedbreakwaters_anchor ($) {
1005     my ($cl) = @_;
1006     my $best_anchor;
1007     foreach my $p (@{ $cl->{Parents} }) {
1008         my ($panchor, $pbw) = keycommits $p->{CommitId},
1009             undef,undef,undef,undef, 1;
1010         $best_anchor = $panchor
1011             if !defined $best_anchor
1012             or is_fast_fwd $best_anchor, $panchor;
1013         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
1014             unless is_fast_fwd $panchor, $best_anchor;
1015     }
1016     return $best_anchor;
1017 }
1018
1019 sub keycommits ($;$$$$$) {
1020     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1021     # => ($anchor, $breakwater)
1022
1023     # $unclean->("unclean-$tagsfx", $msg, $cl)
1024     # $furniture->("unclean-$tagsfx", $msg, $cl)
1025     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
1026     #   is callled for each situation or commit that
1027     #   wouldn't be found in a laundered branch
1028     # $furniture is for furniture commits such as might be found on an
1029     #   interchange branch (pseudomerge, d/patches, changelog)
1030     # $trouble is for things whnich prevent the return of
1031     #   anchor and breakwater information; if that is ignored,
1032     #   then keycommits returns (undef, undef) instead.
1033     # $fatal is for unprocessable commits, and should normally cause
1034     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1035     #
1036     # If $claimed_bw, this is supposed to be a breakwater commit.
1037     #
1038     # If a callback is undef, fail is called instead.
1039     # If a callback is defined but false, the situation is ignored.
1040     # Callbacks may say:
1041     #   no warnings qw(exiting); last;
1042     # if the answer is no longer wanted.
1043
1044     my ($anchor, $breakwater);
1045     $breakwater = $head if $claimed_bw;
1046     my $clogonly;
1047     my $cl;
1048     my $found_pm;
1049     $fatal //= sub { fail $_[1]; };
1050     my $x = sub {
1051         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1052         my $why = $mainwhy.$xwhy;
1053         my $m = "branch needs laundering (run git-debrebase): $why";
1054         fail $m unless defined $cb;
1055         return unless $cb;
1056         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1057     };
1058     my $found_anchor = sub {
1059         ($anchor) = @_;
1060         $breakwater //= $clogonly;
1061         $breakwater //= $head;
1062         no warnings qw(exiting);
1063         last;
1064     };
1065     for (;;) {
1066         $cl = classify $head;
1067         my $ty = $cl->{Type};
1068         if ($ty eq 'Packaging') {
1069             $breakwater //= $clogonly;
1070             $breakwater //= $head;
1071         } elsif ($ty eq 'Changelog') {
1072             # this is going to count as the tip of the breakwater
1073             # only if it has no upstream stuff before it
1074             $clogonly //= $head;
1075         } elsif ($ty eq 'Anchor' or
1076                  $ty eq 'TreatAsAnchor' or
1077                  $ty eq 'BreakwaterStart') {
1078             $found_anchor->($head);
1079         } elsif ($ty eq 'Upstream') {
1080             $x->($unclean, 'ordering',
1081  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1082                 if defined $breakwater;
1083             $clogonly = undef;
1084             $breakwater = undef;
1085         } elsif ($ty eq 'Mixed') {
1086             $x->($unclean, 'mixed',
1087                  "found mixed upstream/packaging commit"," ($head)");
1088             $clogonly = undef;
1089             $breakwater = undef;
1090         } elsif ($ty eq 'Pseudomerge' or
1091                  $ty eq 'AddPatches') {
1092             my $found_pm = 1;
1093             $x->($furniture, (lc $ty),
1094                  "found interchange bureaucracy commit ($ty)"," ($head)");
1095         } elsif ($ty eq 'DgitImportUnpatched') {
1096             if ($found_pm) {
1097                 $x->($trouble, 'dgitimport',
1098                      "found dgit dsc import"," ($head)");
1099                 return (undef,undef);
1100             } else {
1101                 $x->($fatal, 'unprocessable',
1102                      "found bare dgit dsc import with no prior history",
1103                      " ($head)");
1104                 return (undef,undef);
1105             }
1106         } elsif ($ty eq 'VanillaMerge') {
1107             $x->($trouble, 'vanillamerge',
1108                  "found vanilla merge"," ($head)");
1109             return (undef,undef);
1110         } elsif ($ty eq 'MergedBreakwaters') {
1111             $found_anchor->(mergedbreakwaters_anchor $cl);
1112         } else {
1113             $x->($fatal, 'unprocessable',
1114                  "found unprocessable commit, cannot cope: $cl->{Why}",
1115                  " ($head)");
1116             return (undef,undef);
1117         }
1118         $head = $cl->{Parents}[0]{CommitId};
1119     }
1120     return ($anchor, $breakwater);
1121 }
1122
1123 sub walk ($;$$$);
1124 sub walk ($;$$$) {
1125     my ($input,
1126         $nogenerate,$report, $report_lprefix) = @_;
1127     # => ($tip, $breakwater_tip, $last_anchor)
1128     # (or nothing, if $nogenerate)
1129
1130     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1131     $report_lprefix //= '';
1132
1133     # go through commits backwards
1134     # we generate two lists of commits to apply:
1135     # breakwater branch and upstream patches
1136     my (@brw_cl, @upp_cl, @processed);
1137     my %found;
1138     my $upp_limit;
1139     my @pseudomerges;
1140
1141     my $cl;
1142     my $xmsg = sub {
1143         my ($prose, $info) = @_;
1144         my $ms = $cl->{Msg};
1145         chomp $ms;
1146         $info //= '';
1147         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1148         return (Msg => $ms);
1149     };
1150     my $rewrite_from_here = sub {
1151         my ($cl) = @_;
1152         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1153         push @$cl, $sp_cl;
1154         push @processed, $sp_cl;
1155     };
1156     my $cur = $input;
1157
1158     my $prdelim = "";
1159     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1160
1161     my $prline = sub {
1162         return unless $report;
1163         print $report $prdelim, $report_lprefix, @_;
1164         $prdelim = "\n";
1165     };
1166
1167     my $bomb = sub { # usage: return $bomb->();
1168         print $report " Unprocessable" if $report;
1169         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1170         $prprdelim->();
1171         if ($nogenerate) {
1172             return (undef,undef);
1173         }
1174         fail "found unprocessable commit, cannot cope".
1175             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1176             " (commit $cur) (d.".
1177             (join ' ', map { sprintf "%#x", $_->{Differs} }
1178              @{ $cl->{Parents} }).
1179                  ")";
1180     };
1181
1182     my $build;
1183     my $breakwater;
1184
1185     my $build_start = sub {
1186         my ($msg, $parent) = @_;
1187         $prline->(" $msg");
1188         $build = $parent;
1189         no warnings qw(exiting); last;
1190     };
1191
1192     my $nomerge = sub {
1193         my ($emsg) = @_;
1194         merge_failed $cl->{MergeWreckNotes}, $emsg;
1195     };
1196
1197     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1198
1199     my $last_anchor;
1200
1201     for (;;) {
1202         $cl = classify $cur;
1203         $cl->{MergeWreckNotes} //= {};
1204         my $ty = $cl->{Type};
1205         my $st = $cl->{SubType};
1206         $prline->("$cl->{CommitId} $cl->{Type}");
1207         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1208         push @processed, $cl;
1209         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1210         if ($ty eq 'AddPatches') {
1211             $cur = $p0;
1212             $rewrite_from_here->(\@upp_cl);
1213             next;
1214         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1215             push @brw_cl, $cl;
1216             $cur = $p0;
1217             next;
1218         } elsif ($ty eq 'BreakwaterStart') {
1219             $last_anchor = $cur;
1220             $build_start->('FirstPackaging', $cur);
1221         } elsif ($ty eq 'Upstream') {
1222             push @upp_cl, $cl;
1223             $cur = $p0;
1224             next;
1225         } elsif ($ty eq 'Mixed') {
1226             my $queue = sub {
1227                 my ($q, $wh) = @_;
1228                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1229                 push @$q, $cls;
1230             };
1231             $queue->(\@brw_cl, "debian");
1232             $queue->(\@upp_cl, "upstream");
1233             $rewrite_from_here->(\@brw_cl);
1234             $cur = $p0;
1235             next;
1236         } elsif ($ty eq 'Pseudomerge') {
1237             my $contrib = $cl->{Contributor}{CommitId};
1238             print $report " Contributor=$contrib" if $report;
1239             push @pseudomerges, $cl;
1240             $rewrite_from_here->(\@upp_cl);
1241             $cur = $contrib;
1242             next;
1243         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1244             $last_anchor = $cur;
1245             $build_start->("Anchor", $cur);
1246         } elsif ($ty eq 'DgitImportUnpatched') {
1247             my $pm = $pseudomerges[-1];
1248             if (defined $pm) {
1249                 # To an extent, this is heuristic.  Imports don't have
1250                 # a useful history of the debian/ branch.  We assume
1251                 # that the first pseudomerge after an import has a
1252                 # useful history of debian/, and ignore the histories
1253                 # from later pseudomerges.  Often the first pseudomerge
1254                 # will be the dgit import of the upload to the actual
1255                 # suite intended by the non-dgit NMUer, and later
1256                 # pseudomerges may represent in-archive copies.
1257                 my $ovwrs = $pm->{Overwritten};
1258                 printf $report " PM=%s \@Overwr:%d",
1259                     $pm->{CommitId}, (scalar @$ovwrs)
1260                     if $report;
1261                 if (@$ovwrs != 1) {
1262                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1263                     return $bomb->();
1264                 }
1265                 my $ovwr = $ovwrs->[0]{CommitId};
1266                 printf $report " Overwr=%s", $ovwr if $report;
1267                 # This import has a tree which is just like a
1268                 # breakwater tree, but it has the wrong history.  It
1269                 # ought to have the previous breakwater (which the
1270                 # pseudomerge overwrote) as an ancestor.  That will
1271                 # make the history of the debian/ files correct.  As
1272                 # for the upstream version: either it's the same as
1273                 # was ovewritten (ie, same as the previous
1274                 # breakwater), in which case that history is precisely
1275                 # right; or, otherwise, it was a non-gitish upload of a
1276                 # new upstream version.  We can tell these apart by
1277                 # looking at the tree of the supposed upstream.
1278                 push @brw_cl, {
1279                     %$cl,
1280                     SpecialMethod => 'DgitImportDebianUpdate',
1281                     $xmsg->("convert dgit import: debian changes")
1282                 }, {
1283                     %$cl,
1284                     SpecialMethod => 'DgitImportUpstreamUpdate',
1285                     $xmsg->("convert dgit import: upstream update",
1286                             " anchor")
1287                 };
1288                 $prline->(" Import");
1289                 $rewrite_from_here->(\@brw_cl);
1290                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1291                 $cur = $ovwr;
1292                 next;
1293             } else {
1294                 # Everything is from this import.  This kind of import
1295                 # is already nearly in valid breakwater format, with the
1296                 # patches as commits.  Unfortunately it contains
1297                 # debian/patches/.
1298                 printdebug "*** WALK BOMB bare dgit import\n";
1299                 $cl->{Why} = "bare dgit dsc import";
1300                 return $bomb->();
1301             }
1302             die "$ty ?";
1303         } elsif ($ty eq 'MergedBreakwaters') {
1304             $last_anchor = mergedbreakwaters_anchor $cl;
1305             $build_start->(' MergedBreakwaters', $cur);
1306             last;
1307         } elsif ($ty eq 'VanillaMerge') {
1308             # User may have merged unstitched branch(es).  We will
1309             # have now lost what ffq-prev was then (since the later
1310             # pseudomerge may introduce further changes).  The effect
1311             # of resolving such a merge is that we may have to go back
1312             # further in history to find a merge base, since the one
1313             # which was reachable via ffq-prev is no longer findable.
1314             # This is suboptimal, but if it all works we'll have done
1315             # the right thing.
1316             # xxx we should warn the user in the docs about this
1317
1318             my $ok=1;
1319             my $best_anchor;
1320             # We expect to find a dominating anchor amongst the
1321             # inputs' anchors.  That will be the new anchor.
1322             #
1323             # More complicated is finding a merge base for the
1324             # breakwaters.  We need a merge base that is a breakwater
1325             # commit.  The ancestors of breakwater commits are more
1326             # breakwater commits and possibly upstream commits and the
1327             # ancestors of those upstream.  Upstreams might have
1328             # arbitrary ancestors.  But any upstream commit U is
1329             # either included in both anchors, in which case the
1330             # earlier anchor is a better merge base than any of U's
1331             # ancestors; or U is not included in the older anchor, in
1332             # which case U is not an ancestor of the vanilla merge at
1333             # all.  So no upstream commit, nor any ancestor thereof,
1334             # is a best merge base.  As for non-breakwater Debian
1335             # commits: these are never ancestors of any breakwater.
1336             #
1337             # So any best merge base as found by git-merge-base
1338             # is a suitable breakwater anchor.  Usually there will
1339             # be only one.
1340
1341             printdebug "*** MERGE\n";
1342
1343             my @bwbcmd = (@git, qw(merge-base));
1344             my @ibcmd = (@git, qw(merge-base --all));
1345             my $might_be_in_bw = 1;
1346
1347             my $ps = $cl->{Parents};
1348
1349             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1350
1351             foreach my $p (@$ps) {
1352                 $prline->(" VanillaMerge ".$p->{Ix});
1353                 $prprdelim->();
1354                 my ($ptip, $pbw, $panchor) =
1355                     walk $p->{CommitId}, 0, $report,
1356                          $report_lprefix.'  ';
1357                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1358                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1359                 $p->{Anchor} = $panchor;
1360
1361                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1362                 $mwrecknote->("$lr-input", $p->{CommitId});
1363
1364                 my $mwrecknote_parent = sub {
1365                     my ($which) = @_;
1366                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1367                 };
1368                 $mwrecknote_parent->('Laundered');
1369                 $mwrecknote_parent->('Breakwater');
1370                 $mwrecknote_parent->('Anchor');
1371
1372                 $best_anchor = $panchor if
1373                     !defined $best_anchor or
1374                     is_fast_fwd $best_anchor, $panchor;
1375
1376                 printdebug " MERGE BA best=".($best_anchor//'-').
1377                     " p=$panchor\n";
1378             }
1379
1380             $mwrecknote->('result-anchor', $best_anchor);
1381
1382             foreach my $p (@$ps) {
1383                 $prline->(" VanillaMerge ".$p->{Ix});
1384                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1385                     $nomerge->('divergent anchors');
1386                 } elsif ($p->{Anchor} eq $best_anchor) {
1387                     print $report " SameAnchor" if $report;
1388                 } else {
1389                     print $report " SupersededAnchor" if $report;
1390                 }
1391                 if ($p->{Breakwater} eq $p->{CommitId}) {
1392                     # this parent commit was its own breakwater,
1393                     # ie it is part of the breakwater
1394                     print $report " Breakwater" if $report;
1395                 } else {
1396                     $might_be_in_bw = 0;
1397                 }
1398                 push @bwbcmd, $p->{Breakwater};
1399                 push @ibcmd, $p->{CommitId};
1400             }
1401
1402             if ($ok && $might_be_in_bw) {
1403                 # We could rewrite this to contaion the metadata
1404                 # declaring it to be MergedBreakwaters, but
1405                 # unnecessarily rewriting a merge seems unhelpful.
1406                 $prline->(" VanillaMerge MergedBreakwaters");
1407                 $last_anchor = $best_anchor;
1408                 $build_start->('MergedBreakwaters', $cur);
1409             }
1410
1411             my $bwb = cmdoutput @bwbcmd;
1412
1413             # OK, now we have a breakwater base, but we need the merge
1414             # base for the interchange branch because we need the delta
1415             # queue.
1416             #
1417             # This a the best merge base of our inputs which has the
1418             # breakwater merge base as an ancestor.
1419
1420             my @ibs =
1421                 grep /./,
1422                 split /\n/,
1423                 cmdoutput @ibcmd;
1424
1425             @ibs or confess 'internal error, expected anchor at least ?';
1426
1427             my $ib;
1428             my $ibleaf;
1429             foreach my $tibix (0..$#ibs) {
1430                 my $tib = $ibs[$tibix];
1431                 my $ff = is_fast_fwd $bwb, $tib;
1432                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1433                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1434                 $mwrecknote->($tibleaf, $tib);
1435                 next unless $ff;
1436                 next if $ib;
1437                 $ib = $tib;
1438                 $ibleaf = $tibleaf;
1439             }
1440
1441             $ib or $nomerge->("no suitable interchange merge base");
1442
1443             $prline->("  VanillaMerge Base");
1444             $prprdelim->();
1445             my ($btip, $bbw, $banchor) = eval {
1446                 walk $ib, 0, $report, $report_lprefix.'  ';
1447             };
1448             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1449                        $@)
1450                 if length $@;
1451
1452             $mwrecknote->("mergebase-laundered", $btip);
1453             $mwrecknote->("mergebase-breakwater", $bbw);
1454             $mwrecknote->("mergebase-anchor", $banchor);
1455
1456             my $ibinfo = { SeriesTip => $btip,
1457                            SeriesBase => $bbw,
1458                            Anchor => $banchor,
1459                            LeftRight => 'mergebase' };
1460
1461             $bbw eq $bwb
1462                 or $nomerge->("interchange merge-base ($ib)'s".
1463                               " breakwater ($bbw)".
1464                               " != breakwaters' merge-base ($bwb)");
1465
1466             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1467                  or $nomerge->("interchange merge-base ($ib)'s".
1468                                " anchor ($ibinfo->{SeriesBase})".
1469                                " != any merge input's anchor (".
1470                                (join ' ', map { $_->{Anchor} } @$ps).
1471                                ")");
1472
1473             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1474             $cl->{MergeBestAnchor} = $best_anchor;
1475             push @brw_cl, {
1476                 %$cl,
1477                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1478                 $xmsg->('constructed from vanilla merge',
1479                         ' merged-breakwater'),
1480             };
1481             push @upp_cl, {
1482                 %$cl,
1483                 SpecialMethod => 'MergeMergeSeries',
1484             };
1485             $build_start->('MergeBreakwaters', $cur);
1486         } else {
1487             printdebug "*** WALK BOMB unrecognised\n";
1488             return $bomb->();
1489         }
1490     }
1491     $prprdelim->();
1492
1493     printdebug "*** WALK prep done cur=$cur".
1494         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1495
1496     return if $nogenerate;
1497
1498     # Now we build it back up again
1499
1500     fresh_workarea();
1501
1502     my $rewriting = 0;
1503
1504     $#upp_cl = $upp_limit if defined $upp_limit;
1505
1506     my $committer_authline = calculate_committer_authline();
1507
1508     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1509
1510     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1511
1512     in_workarea sub {
1513         mkdir $rd or $!==EEXIST or die $!;
1514         my $current_method;
1515         my $want_debian = $build;
1516         my $want_upstream = $build;
1517
1518         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1519         my $read_tree_debian = sub { ($want_debian) = @_; };
1520
1521         foreach my $cl (qw(Debian), (reverse @brw_cl),
1522                         { SpecialMethod => 'RecordBreakwaterTip' },
1523                         qw(Upstream), (reverse @upp_cl)) {
1524             if (!ref $cl) {
1525                 $current_method = $cl;
1526                 next;
1527             }
1528             my $method = $cl->{SpecialMethod} // $current_method;
1529             my @parents = ($build);
1530             my $cltree = $cl->{CommitId};
1531             printdebug "WALK BUILD ".($cltree//'undef').
1532                 " $method (rewriting=$rewriting)\n";
1533             if ($method eq 'Debian') {
1534                 $read_tree_debian->($cltree);
1535             } elsif ($method eq 'Upstream') {
1536                 $read_tree_upstream->($cltree);
1537             } elsif ($method eq 'StartRewrite') {
1538                 $rewriting = 1;
1539                 next;
1540             } elsif ($method eq 'RecordBreakwaterTip') {
1541                 $breakwater = $build;
1542                 next;
1543             } elsif ($method eq 'DgitImportDebianUpdate') {
1544                 $read_tree_debian->($cltree);
1545             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1546                 confess unless $rewriting;
1547                 my $differs = (get_differs $build, $cltree);
1548                 next unless $differs & D_UPS;
1549                 $read_tree_upstream->($cltree);
1550                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1551             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1552                 print "Found a general merge, will try to tidy it up.\n";
1553                 $rewriting = 1;
1554                 $read_tree_upstream->($cl->{MergeBestAnchor});
1555                 $read_tree_debian->($cltree);
1556                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1557             } elsif ($method eq 'MergeMergeSeries') {
1558                 my $cachehit = reflog_cache_lookup
1559                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1560                 if ($cachehit) {
1561                     print "Using supplied resolution for $cl->{CommitId}...\n";
1562                     $build = $cachehit;
1563                     $mwrecknote->('cached-resolution', $build);
1564                 } else {
1565                     print "Running merge resolution for $cl->{CommitId}...\n";
1566                     $mwrecknote->('new-base', $build);
1567                     $build = merge_series
1568                         $build, $cl->{MergeWreckNotes},
1569                         $cl->{MergeInterchangeBaseInfo},
1570                         @{ $cl->{Parents} };
1571                 }
1572                 $last_anchor = $cl->{MergeBestAnchor};
1573
1574                 # Check for mismerges:
1575                 my $check = sub {
1576                     my ($against, $allow, $what) = @_;
1577                     my $differs = get_differs $build, $against;
1578                     $nomerge->(sprintf
1579        "merge misresolved: %s are not the same (%s %s d.%#x)",
1580                                $what, $against, $build, $differs)
1581                         if $differs & ~($allow | D_PAT_ADD);
1582                 };
1583
1584                 # Breakwater changes which were in each side of the
1585                 # merge will have been incorporated into the
1586                 # MergeCreateMergedBreakwaters output.  Because the
1587                 # upstream series was rebased onto the new breakwater,
1588                 # so should all of the packaging changes which were in
1589                 # the input.
1590                 $check->($input, D_UPS, 'debian files');
1591
1592                 # Upstream files are merge_series, which ought to
1593                 # have been identical to the original merge.
1594                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1595
1596                 print "Merge resolution successful.\n";
1597                 next;
1598             } else {
1599                 confess "$method ?";
1600             }
1601             if (!$rewriting) {
1602                 my $procd = (pop @processed) // 'UNDEF';
1603                 if ($cl ne $procd) {
1604                     $rewriting = 1;
1605                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1606                 }
1607             }
1608             if ($rewriting || $opt_careful) {
1609                 read_tree_upstream $want_upstream, 0, $want_debian;
1610
1611                 my $newtree = cmdoutput @git, qw(write-tree);
1612                 my $ch = $cl->{Hdr};
1613                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1614                 $ch =~ s{^parent .*\n}{}mg;
1615                 $ch =~ s{(?=^author)}{
1616                     join '', map { "parent $_\n" } @parents
1617                 }me or confess "$ch ?";
1618                 if ($rewriting) {
1619                     $ch =~ s{^committer .*$}{$committer_authline}m
1620                         or confess "$ch ?";
1621                 }
1622                 my $cf = "$rd/m$rewriting";
1623                 open CD, ">", $cf or die $!;
1624                 print CD $ch, "\n", $cl->{Msg} or die $!;
1625                 close CD or die $!;
1626                 my @cmd = (@git, qw(hash-object));
1627                 push @cmd, qw(-w) if $rewriting;
1628                 push @cmd, qw(-t commit), $cf;
1629                 my $newcommit = cmdoutput @cmd;
1630                 confess "$ch ?" unless $rewriting
1631                     or $newcommit eq $cl->{CommitId};
1632                 $build = $newcommit;
1633             } else {
1634                 $build = $cl->{CommitId};
1635                 trees_diff_walk "$want_upstream:", "$build:", sub {
1636                     my ($n) = @_;
1637                     no warnings qw(exiting);
1638                     next if $n eq 'debian/';
1639                     confess "mismatch @_ ?";
1640                 };
1641                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1642                     confess "mismatch @_ ?";
1643                 };
1644                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1645                 confess "mismatch @parents != @old_parents ?"
1646                     unless "@parents" eq "@old_parents";
1647             }
1648             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1649                 $last_anchor = $cur;
1650             }
1651         }
1652     };
1653
1654     my $final_check = get_differs $build, $input;
1655     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1656         if $final_check & ~D_PAT_ADD;
1657
1658     my @r = ($build, $breakwater, $last_anchor);
1659     printdebug "*** WALK RETURN @r\n";
1660     return @r
1661 }
1662
1663 sub get_head () {
1664     git_check_unmodified();
1665     return git_rev_parse qw(HEAD);
1666 }
1667
1668 sub update_head ($$$) {
1669     my ($old, $new, $mrest) = @_;
1670     push @deferred_updates, "update HEAD $new $old";
1671     run_deferred_updates $mrest;
1672 }
1673
1674 sub update_head_checkout ($$$) {
1675     my ($old, $new, $mrest) = @_;
1676     update_head $old, $new, $mrest;
1677     runcmd @git, qw(reset --hard);
1678 }
1679
1680 sub update_head_postlaunder ($$$) {
1681     my ($old, $tip, $reflogmsg) = @_;
1682     return if $tip eq $old && !@deferred_updates;
1683     print "git-debrebase: laundered (head was $old)\n";
1684     update_head $old, $tip, $reflogmsg;
1685     # no tree changes except debian/patches
1686     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1687 }
1688
1689 sub currently_rebasing() {
1690     foreach (qw(rebase-merge rebase-apply)) {
1691         return 1 if stat_exists "$maindir_gitdir/$_";
1692     }
1693     return 0;
1694 }
1695
1696 sub bail_if_rebasing() {
1697     fail "you are in the middle of a git-rebase already"
1698         if currently_rebasing();
1699 }
1700
1701 sub do_launder_head ($) {
1702     my ($reflogmsg) = @_;
1703     my $old = get_head();
1704     record_ffq_auto();
1705     my ($tip,$breakwater) = walk $old;
1706     snags_maybe_bail();
1707     update_head_postlaunder $old, $tip, $reflogmsg;
1708     return ($tip,$breakwater);
1709 }
1710
1711 sub cmd_launder_v0 () {
1712     badusage "no arguments to launder-v0 allowed" if @ARGV;
1713     my $old = get_head();
1714     my ($tip,$breakwater,$last_anchor) = walk $old;
1715     update_head_postlaunder $old, $tip, 'launder';
1716     printf "# breakwater tip\n%s\n", $breakwater;
1717     printf "# working tip\n%s\n", $tip;
1718     printf "# last anchor\n%s\n", $last_anchor;
1719 }
1720
1721 sub defaultcmd_rebase () {
1722     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1723     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1724     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1725 }
1726
1727 sub cmd_analyse () {
1728     badusage "analyse does not support any options"
1729         if @ARGV and $ARGV[0] =~ m/^-/;
1730     badusage "too many arguments to analyse" if @ARGV>1;
1731     my ($old) = @ARGV;
1732     if (defined $old) {
1733         $old = git_rev_parse $old;
1734     } else {
1735         $old = git_rev_parse 'HEAD';
1736     }
1737     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1738     STDOUT->error and die $!;
1739 }
1740
1741 sub ffq_prev_branchinfo () {
1742     my $current = git_get_symref();
1743     return gdr_ffq_prev_branchinfo($current);
1744 }
1745
1746 sub ffq_check ($;$$) {
1747     # calls $ff and/or $notff zero or more times
1748     # then returns either (status,message) where status is
1749     #    exists
1750     #    detached
1751     #    weird-symref
1752     #    notbranch
1753     # or (undef,undef, $ffq_prev,$gdrlast)
1754     # $ff and $notff are called like this:
1755     #   $ff->("message for stdout\n");
1756     #   $notff->('snag-name', $message);
1757     # normally $currentval should be HEAD
1758     my ($currentval, $ff, $notff) =@_;
1759
1760     $ff //= sub { print $_[0] or die $!; };
1761     $notff //= \&snag;
1762
1763     my ($status, $message, $current, $ffq_prev, $gdrlast)
1764         = ffq_prev_branchinfo();
1765     return ($status, $message) unless $status eq 'branch';
1766
1767     my $exists = git_get_ref $ffq_prev;
1768     return ('exists',"$ffq_prev already exists") if $exists;
1769
1770     return ('not-branch', 'HEAD symref is not to refs/heads/')
1771         unless $current =~ m{^refs/heads/};
1772     my $branch = $';
1773
1774     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1775     my %checked;
1776
1777     printdebug "ffq check_specs @check_specs\n";
1778
1779     my $check = sub {
1780         my ($lrref, $desc) = @_;
1781         printdebug "ffq might check $lrref ($desc)\n";
1782         my $invert;
1783         for my $chk (@check_specs) {
1784             my $glob = $chk;
1785             $invert = $glob =~ s{^[!^]}{};
1786             last if fnmatch $glob, $lrref;
1787         }
1788         return if $invert;
1789         my $lrval = git_get_ref $lrref;
1790         return unless length $lrval;
1791
1792         if (is_fast_fwd $lrval, $currentval) {
1793             $ff->("OK, you are ahead of $lrref\n");
1794             $checked{$lrref} = 1;
1795         } elsif (is_fast_fwd $currentval, $lrval) {
1796             $checked{$lrref} = -1;
1797             $notff->('behind', "you are behind $lrref, divergence risk");
1798         } else {
1799             $checked{$lrref} = -1;
1800             $notff->('diverged', "you have diverged from $lrref");
1801         }
1802     };
1803
1804     my $merge = cfg "branch.$branch.merge",1;
1805     if (defined $merge and $merge =~ m{^refs/heads/}) {
1806         my $rhs = $';
1807         printdebug "ffq merge $rhs\n";
1808         my $check_remote = sub {
1809             my ($remote, $desc) = @_;
1810             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1811             return unless defined $remote;
1812             $check->("refs/remotes/$remote/$rhs", $desc);
1813         };
1814         $check_remote->((scalar cfg "branch.$branch.remote",1),
1815                         'remote fetch/merge branch');
1816         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1817                         (scalar cfg "branch.$branch.pushDefault",1),
1818                         'remote push branch');
1819     }
1820     if ($branch =~ m{^dgit/}) {
1821         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1822     } elsif ($branch =~ m{^master$}) {
1823         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1824     }
1825     return (undef, undef, $ffq_prev, $gdrlast);
1826 }
1827
1828 sub record_ffq_prev_deferred () {
1829     # => ('status', "message")
1830     # 'status' may be
1831     #    deferred          message is undef
1832     #    exists
1833     #    detached
1834     #    weird-symref
1835     #    notbranch
1836     # if not ff from some branch we should be ff from, is an snag
1837     # if "deferred", will have added something about that to
1838     #   @deferred_update_messages, and also maybe printed (already)
1839     #   some messages about ff checks
1840     bail_if_rebasing();
1841     my $currentval = get_head();
1842
1843     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1844     return ($status,$message) if defined $status;
1845
1846     snags_maybe_bail();
1847
1848     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1849     push @deferred_updates, "delete $gdrlast";
1850     push @deferred_update_messages, "Recorded previous head for preservation";
1851     return ('deferred', undef);
1852 }
1853
1854 sub record_ffq_auto () {
1855     my ($status, $message) = record_ffq_prev_deferred();
1856     if ($status eq 'deferred' || $status eq 'exists') {
1857     } else {
1858         snag $status, "could not record ffq-prev: $message";
1859         snags_maybe_bail();
1860     }
1861 }
1862
1863 sub ffq_prev_info () {
1864     bail_if_rebasing();
1865     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1866     my ($status, $message, $current, $ffq_prev, $gdrlast)
1867         = ffq_prev_branchinfo();
1868     if ($status ne 'branch') {
1869         snag $status, "could not check ffq-prev: $message";
1870         snags_maybe_bail();
1871     }
1872     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1873     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1874 }
1875
1876 sub stitch ($$$$$) {
1877     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1878
1879     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1880
1881     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1882         my $differs = get_differs $old_head, $ffq_prev_commitish;
1883         unless ($differs & ~D_PAT_ADD) {
1884             # ffq-prev is ahead of us, and the only tree changes it has
1885             # are possibly addition of things in debian/patches/.
1886             # Just wind forwards rather than making a pointless pseudomerge.
1887             push @deferred_updates,
1888                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1889             update_head_checkout $old_head, $ffq_prev_commitish,
1890                 "stitch (fast forward)";
1891             return;
1892         }
1893     }
1894     fresh_workarea();
1895     # We make pseudomerges with L as the contributing parent.
1896     # This makes git rev-list --first-parent work properly.
1897     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1898         'Declare fast forward / record previous work',
1899         "[git-debrebase pseudomerge: $prose]",
1900     ];
1901     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1902     update_head $old_head, $new_head, "stitch: $prose";
1903 }
1904
1905 sub do_stitch ($;$) {
1906     my ($prose, $unclean) = @_;
1907
1908     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1909     if (!$ffq_prev_commitish) {
1910         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1911         return;
1912     }
1913     my $dangling_head = get_head();
1914
1915     keycommits $dangling_head, $unclean,$unclean,$unclean;
1916     snags_maybe_bail();
1917
1918     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1919 }
1920
1921 sub upstream_commitish_search ($$) {
1922     my ($upstream_version, $tried) = @_;
1923     # todo: at some point maybe use git-deborig to do this
1924     foreach my $tagpfx ('', 'v', 'upstream/') {
1925         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1926         my $new_upstream = git_get_ref "refs/tags/$tag";
1927         push @$tried, $tag;
1928         return $new_upstream if length $new_upstream;
1929     }
1930 }
1931
1932 sub resolve_upstream_version ($$) {
1933     my ($new_upstream, $upstream_version) = @_;
1934
1935     if (!defined $new_upstream) {
1936         my @tried;
1937         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1938         if (!length $new_upstream) {
1939             fail "Could not determine appropriate upstream commitish.\n".
1940                 " (Tried these tags: @tried)\n".
1941                 " Check version, and specify upstream commitish explicitly.";
1942         }
1943     }
1944     $new_upstream = git_rev_parse $new_upstream;
1945
1946     return $new_upstream;
1947 }
1948
1949 sub cmd_new_upstream () {
1950     # automatically and unconditionally launders before rebasing
1951     # if rebase --abort is used, laundering has still been done
1952
1953     my %pieces;
1954
1955     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1956
1957     # parse args - low commitment
1958     my $spec_version = shift @ARGV;
1959     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1960     fail "bad version number \`$spec_version'" unless defined $new_version;
1961     if ($new_version->is_native()) {
1962         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1963     }
1964
1965     my $new_upstream = shift @ARGV;
1966     my $new_upstream_version = upstreamversion  $new_version;
1967     $new_upstream =
1968         resolve_upstream_version $new_upstream, $new_upstream_version;
1969
1970     record_ffq_auto();
1971
1972     my $piece = sub {
1973         my ($n, @x) = @_; # may be ''
1974         my $pc = $pieces{$n} //= {
1975             Name => $n,
1976             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1977         };
1978         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1979         $pc;
1980     };
1981
1982     my @newpieces;
1983     my $newpiece = sub {
1984         my ($n, @x) = @_; # may be ''
1985         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1986         push @newpieces, $pc;
1987     };
1988
1989     $newpiece->('',
1990         OldIx => 0,
1991         New => $new_upstream,
1992     );
1993     while (@ARGV && $ARGV[0] !~ m{^-}) {
1994         my $n = shift @ARGV;
1995
1996         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1997             unless @ARGV && $ARGV[0] !~ m{^-};
1998
1999         my $c = git_rev_parse shift @ARGV;
2000         die unless $n =~ m/^$extra_orig_namepart_re$/;
2001         $newpiece->($n, New => $c);
2002     }
2003
2004     # now we need to investigate the branch this generates the
2005     # laundered version but we don't switch to it yet
2006     my $old_head = get_head();
2007     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
2008
2009     my $old_bw_cl = classify $old_bw;
2010     my $old_anchor_cl = classify $old_anchor;
2011     my $old_upstream;
2012     if (!$old_anchor_cl->{OrigParents}) {
2013         snag 'anchor-treated',
2014             'old anchor is recognised due to --anchor, cannot check upstream';
2015     } else {
2016         $old_upstream = parsecommit
2017             $old_anchor_cl->{OrigParents}[0]{CommitId};
2018         $piece->('', Old => $old_upstream->{CommitId});
2019     }
2020
2021     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2022         if ($old_upstream->{Msg} =~
2023  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2024            ) {
2025             my @oldpieces = (split / /, $1);
2026             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2027             if ($old_n_parents != @oldpieces &&
2028                 $old_n_parents != @oldpieces + 1) {
2029                 snag 'upstream-confusing', sprintf
2030                     "previous upstream combine %s".
2031                     " mentions %d pieces (each implying one parent)".
2032                     " but has %d parents".
2033                     " (one per piece plus maybe a previous combine)",
2034                     $old_upstream->{CommitId},
2035                     (scalar @oldpieces),
2036                     $old_n_parents;
2037             } elsif ($oldpieces[0] ne '.') {
2038                 snag 'upstream-confusing', sprintf
2039                     "previous upstream combine %s".
2040                     " first piece is not \`.'",
2041                     $oldpieces[0];
2042             } else {
2043                 $oldpieces[0] = '';
2044                 foreach my $i (0..$#oldpieces) {
2045                     my $n = $oldpieces[$i];
2046                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2047                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2048                 }
2049             }
2050         } else {
2051             snag 'upstream-confusing',
2052                 "previous upstream $old_upstream->{CommitId} is from".
2053                " git-debrebase but not an \`upstream-combine' commit";
2054         }
2055     }
2056
2057     foreach my $pc (values %pieces) {
2058         if (!$old_upstream) {
2059             # we have complained already
2060         } elsif (!$pc->{Old}) {
2061             snag 'upstream-new-piece',
2062                 "introducing upstream piece \`$pc->{Name}'";
2063         } elsif (!$pc->{New}) {
2064             snag 'upstream-rm-piece',
2065                 "dropping upstream piece \`$pc->{Name}'";
2066         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2067             snag 'upstream-not-ff',
2068                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2069         }
2070     }
2071
2072     printdebug "%pieces = ", (dd \%pieces), "\n";
2073     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2074
2075     snags_maybe_bail();
2076
2077     my $new_bw;
2078
2079     fresh_workarea();
2080     in_workarea sub {
2081         my @upstream_merge_parents;
2082
2083         if (!any_snags()) {
2084             push @upstream_merge_parents, $old_upstream->{CommitId};
2085         }
2086
2087         foreach my $pc (@newpieces) { # always has '' first
2088             if ($pc->{Name}) {
2089                 read_tree_subdir $pc->{Name}, $pc->{New};
2090             } else {
2091                 runcmd @git, qw(read-tree), $pc->{New};
2092             }
2093             push @upstream_merge_parents, $pc->{New};
2094         }
2095
2096         # index now contains the new upstream
2097
2098         if (@newpieces > 1) {
2099             # need to make the upstream subtree merge commit
2100             $new_upstream = make_commit \@upstream_merge_parents,
2101                 [ "Combine upstreams for $new_upstream_version",
2102  ("[git-debrebase upstream-combine . ".
2103  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2104  ": new upstream]"),
2105                 ];
2106         }
2107
2108         # $new_upstream is either the single upstream commit, or the
2109         # combined commit we just made.  Either way it will be the
2110         # "upstream" parent of the anchor merge.
2111
2112         read_tree_subdir 'debian', "$old_bw:debian";
2113
2114         # index now contains the anchor merge contents
2115         $new_bw = make_commit [ $old_bw, $new_upstream ],
2116             [ "Update to upstream $new_upstream_version",
2117  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2118             ];
2119
2120         my $clogsignoff = cmdoutput qw(git show),
2121             '--pretty=format:%an <%ae>  %aD',
2122             $new_bw;
2123
2124         # Now we have to add a changelog stanza so the Debian version
2125         # is right.
2126         die if unlink "debian";
2127         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2128         unlink "debian/changelog" or $!==ENOENT or die $!;
2129         mkdir "debian" or die $!;
2130         open CN, ">", "debian/changelog" or die $!;
2131         my $oldclog = git_cat_file ":debian/changelog";
2132         $oldclog =~ m/^($package_re) \(\S+\) / or
2133             fail "cannot parse old changelog to get package name";
2134         my $p = $1;
2135         print CN <<END, $oldclog or die $!;
2136 $p ($new_version) UNRELEASED; urgency=medium
2137
2138   * Update to new upstream version $new_upstream_version.
2139
2140  -- $clogsignoff
2141
2142 END
2143         close CN or die $!;
2144         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2145
2146         # Now we have the final new breakwater branch in the index
2147         $new_bw = make_commit [ $new_bw ],
2148             [ "Update changelog for new upstream $new_upstream_version",
2149               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2150             ];
2151     };
2152
2153     # we have constructed the new breakwater. we now need to commit to
2154     # the laundering output, because git-rebase can't easily be made
2155     # to make a replay list which is based on some other branch
2156
2157     update_head_postlaunder $old_head, $old_laundered_tip,
2158         'launder for new upstream';
2159
2160     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2161     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2162         "debrebase new-upstream $new_version: rebase";
2163     runcmd @cmd;
2164     # now it's for the user to sort out
2165 }
2166
2167 sub cmd_record_ffq_prev () {
2168     badusage "no arguments allowed" if @ARGV;
2169     my ($status, $msg) = record_ffq_prev_deferred();
2170     if ($status eq 'exists' && $opt_noop_ok) {
2171         print "Previous head already recorded\n" or die $!;
2172     } elsif ($status eq 'deferred') {
2173         run_deferred_updates 'record-ffq-prev';
2174     } else {
2175         fail "Could not preserve: $msg";
2176     }
2177 }
2178
2179 sub cmd_anchor () {
2180     badusage "no arguments allowed" if @ARGV;
2181     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2182     print "$bw\n" or die $!;
2183 }
2184
2185 sub cmd_breakwater () {
2186     badusage "no arguments allowed" if @ARGV;
2187     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2188     print "$bw\n" or die $!;
2189 }
2190
2191 sub cmd_status () {
2192     badusage "no arguments allowed" if @ARGV;
2193
2194     # todo: gdr status should print divergence info
2195     # todo: gdr status should print upstream component(s) info
2196     # todo: gdr should leave/maintain some refs with this kind of info ?
2197
2198     my $oldest = { Badness => 0 };
2199     my $newest;
2200     my $note = sub {
2201         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2202         if ($oldest->{Badness} < $badness) {
2203             $oldest = $newest = undef;
2204         }
2205         $oldest = {
2206                    Badness => $badness,
2207                    CommitId => $cl->{CommitId},
2208                    OurMsg => $ourmsg,
2209                    KcMsg => $kcmsg,
2210                   };
2211         $newest //= $oldest;
2212     };
2213     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2214         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2215         sub { $note->(2, 'branch is unlaundered', @_); },
2216         sub { $note->(3, 'branch needs laundering', @_); },
2217         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2218
2219     my $prcommitinfo = sub {
2220         my ($cid) = @_;
2221         flush STDOUT or die $!;
2222         runcmd @git, qw(--no-pager log -n1),
2223             '--pretty=format:    %h %s%n',
2224             $cid;
2225     };
2226
2227     print "current branch contents, in git-debrebase terms:\n";
2228     if (!$oldest->{Badness}) {
2229         print "  branch is laundered\n";
2230     } else {
2231         print "  $oldest->{OurMsg}\n";
2232         my $printed = '';
2233         foreach my $info ($oldest, $newest) {
2234             my $cid = $info->{CommitId};
2235             next if $cid eq $printed;
2236             $printed = $cid;
2237             print "  $info->{KcMsg}\n";
2238             $prcommitinfo->($cid);
2239         }
2240     }
2241
2242     my $prab = sub {
2243         my ($cid, $what) = @_;
2244         if (!defined $cid) {
2245             print "  $what is not well-defined\n";
2246         } else {
2247             print "  $what\n";
2248             $prcommitinfo->($cid);
2249         }
2250     };
2251     print "key git-debrebase commits:\n";
2252     $prab->($anchor, 'anchor');
2253     $prab->($bw, 'breakwater');
2254
2255     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2256         ffq_prev_branchinfo();
2257
2258     print "branch and ref status, in git-debrebase terms:\n";
2259     if ($ffq_msg) {
2260         print "  $ffq_msg\n";
2261     } else {
2262         $ffq_prev = git_get_ref $ffq_prev;
2263         $gdrlast = git_get_ref $gdrlast;
2264         if ($ffq_prev) {
2265             print "  unstitched; previous tip was:\n";
2266             $prcommitinfo->($ffq_prev);
2267         } elsif (!$gdrlast) {
2268             print "  stitched? (no record of git-debrebase work)\n";
2269         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2270             print "  stitched\n";
2271         } else {
2272             print "  not git-debrebase (diverged since last stitch)\n"
2273         }
2274     }
2275     print "you are currently rebasing\n" if currently_rebasing();
2276 }
2277
2278 sub cmd_stitch () {
2279     my $prose = 'stitch';
2280     getoptions("stitch",
2281                'prose=s', \$prose);
2282     badusage "no arguments allowed" if @ARGV;
2283     do_stitch $prose, 0;
2284 }
2285 sub cmd_prepush () {
2286     $opt_noop_ok = 1;
2287     cmd_stitch();
2288 }
2289
2290 sub cmd_quick () {
2291     badusage "no arguments allowed" if @ARGV;
2292     do_launder_head 'launder for git-debrebase quick';
2293     do_stitch 'quick';
2294 }
2295
2296 sub cmd_conclude () {
2297     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2298     if (!$ffq_prev_commitish) {
2299         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2300         return;
2301     }
2302     my $dangling_head = get_head();
2303
2304     badusage "no arguments allowed" if @ARGV;
2305     do_launder_head 'launder for git-debrebase quick';
2306     do_stitch 'quick';
2307 }
2308
2309 sub cmd_scrap () {
2310     if (currently_rebasing()) {
2311         runcmd @git, qw(rebase --abort);
2312         push @deferred_updates, 'verify HEAD HEAD';
2313         # noop, but stops us complaining that scrap was a noop
2314     }
2315     badusage "no arguments allowed" if @ARGV;
2316     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2317     my $scrapping_head;
2318     if ($ffq_prev_commitish) {
2319         $scrapping_head = get_head();
2320         push @deferred_updates,
2321             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2322             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2323     }
2324     if (git_get_ref $merge_cache_ref) {
2325         push @deferred_updates,
2326             "delete $merge_cache_ref";
2327     }
2328     if (!@deferred_updates) {
2329         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2330         finish 0;
2331     }
2332     snags_maybe_bail();
2333     if ($scrapping_head) {
2334         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2335     } else {
2336         run_deferred_updates "scrap";
2337     }
2338 }
2339
2340 sub make_patches_staged ($) {
2341     my ($head) = @_;
2342     # Produces the patches that would result from $head if it were
2343     # laundered.
2344     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2345     fresh_workarea();
2346     in_workarea sub {
2347         gbp_pq_export 'bw', $secret_bw, $secret_head;
2348     };
2349 }
2350
2351 sub make_patches ($) {
2352     my ($head) = @_;
2353     keycommits $head, 0, \&snag;
2354     make_patches_staged $head;
2355     my $out;
2356     in_workarea sub {
2357         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2358         runcmd @git, qw(read-tree), $head;
2359         read_tree_subdir 'debian/patches', $ptree;
2360         $out = make_commit [$head], [
2361             'Commit patch queue (exported by git-debrebase)',
2362             '[git-debrebase: export and commit patches]',
2363         ];
2364     };
2365     return $out;
2366 }
2367
2368 sub cmd_make_patches () {
2369     my $opt_quiet_would_amend;
2370     getoptions("make-patches",
2371                'quiet-would-amend!', \$opt_quiet_would_amend);
2372     badusage "no arguments allowed" if @ARGV;
2373     bail_if_rebasing();
2374     my $old_head = get_head();
2375     my $new = make_patches $old_head;
2376     my $d = get_differs $old_head, $new;
2377     if ($d == 0) {
2378         fail "No (more) patches to export." unless $opt_noop_ok;
2379         return;
2380     } elsif ($d == D_PAT_ADD) {
2381         snags_maybe_bail();
2382         update_head_checkout $old_head, $new, 'make-patches';
2383     } else {
2384         print STDERR failmsg
2385             "Patch export produced patch amendments".
2386             " (abandoned output commit $new).".
2387             "  Try laundering first."
2388             unless $opt_quiet_would_amend;
2389         finish 7;
2390     }
2391 }
2392
2393 sub check_series_has_all_patches ($) {
2394     my ($head) = @_;
2395     my $seriesfn = 'debian/patches/series';
2396     my ($dummy, $series) = git_cat_file "$head:$seriesfn",
2397         [qw(blob missing)];
2398     $series //= '';
2399     my %series;
2400     foreach my $f (grep /\S/, grep {!m/^\s\#/} split /\n/, $series) {
2401         fail "patch $f repeated in $seriesfn !" if $series{$f}++;
2402     }
2403     foreach my $patchfile (get_tree "$head:debian/patches", 1,1) {
2404         my ($f,$i) = @$patchfile;
2405         next if $series{$f};
2406         next if $f eq 'series';
2407         snag 'unused-patches', "Unused patch file $f will be discarded";
2408     }
2409 }
2410
2411 sub cmd_convert_from_gbp () {
2412     badusage "want only 1 optional argument, the upstream git commitish"
2413         unless @ARGV<=1;
2414
2415     my $clogp = parsechangelog();
2416     my $version = $clogp->{'Version'}
2417         // die "missing Version from changelog";
2418
2419     my ($upstream_spec) = @ARGV;
2420
2421     my $upstream_version = upstreamversion $version;
2422     my $upstream =
2423         resolve_upstream_version($upstream_spec, $upstream_version);
2424
2425     my $old_head = get_head();
2426
2427     my $upsdiff = get_differs $upstream, $old_head;
2428     if ($upsdiff & D_UPS) {
2429         runcmd @git, qw(--no-pager diff --stat),
2430             $upstream, $old_head,
2431             qw( -- :!/debian :/);
2432         fail <<END;
2433 upstream ($upstream_spec) and HEAD are not
2434 identical in upstream files.  See diffstat above, or run
2435   git diff $upstream_spec HEAD -- :!/debian :/
2436 END
2437     }
2438
2439     if (!is_fast_fwd $upstream, $old_head) {
2440         snag 'upstream-not-ancestor',
2441             "upstream ($upstream) is not an ancestor of HEAD";
2442     } else {
2443         my $wrong = cmdoutput
2444             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2445              qw(-- :/ :!/debian));
2446         if (length $wrong) {
2447             snag 'unexpected-upstream-changes',
2448                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2449             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2450         }
2451     }
2452
2453     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2454         snag 'upstream-has-debian',
2455             "upstream ($upstream) contains debian/ directory";
2456     }
2457
2458     check_series_has_all_patches $old_head;
2459
2460     my $previous_dgit_view = eval {
2461         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2462         my ($lvsn, $suite);
2463         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2464             my ($stz, $desc) = @_;
2465             no warnings qw(exiting);
2466             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2467             next unless $stz->{Date};
2468             next unless $stz->{Distribution} ne 'UNRELEASED';
2469             $lvsn = $stz->{Version};
2470             $suite = $stz->{Distribution};
2471             last;
2472         };
2473         die "neither of the first two changelog entries are released\n"
2474             unless defined $lvsn;
2475         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2476         my $mtag_pat = debiantag_maintview $lvsn, '*';
2477         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2478             $mtag_pat;
2479         die "could not find suitable maintainer view tag $mtag_pat\n"
2480             unless $mtag_pat =~ m{/};
2481         is_fast_fwd $mtag, 'HEAD' or
2482             die "HEAD is not FF from maintainer tag $mtag!";
2483         my $dtag = "archive/$mtag";
2484         is_fast_fwd $mtag, $dtag or
2485             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2486         print "will stitch in dgit view, $dtag\n";
2487         git_rev_parse $dtag;
2488     };
2489     if (!$previous_dgit_view) {
2490         $@ =~ s/^\n+//;
2491         chomp $@;
2492         print STDERR "cannot stitch in dgit view: $@\n";
2493     }
2494
2495     snags_maybe_bail_early();
2496
2497     my $work;
2498
2499     fresh_workarea();
2500     in_workarea sub {
2501         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2502         # make a branch out of the patch queue - we'll want this in a mo
2503         runcmd qw(gbp pq import);
2504         # strip the patches out
2505         runcmd @git, qw(checkout -q gdr-internal~0);
2506         rm_subdir_cached 'debian/patches';
2507         $work = make_commit ['HEAD'], [
2508  'git-debrebase convert-from-gbp: drop patches from tree',
2509  'Delete debian/patches, as part of converting to git-debrebase format.',
2510  '[git-debrebase convert-from-gbp: drop patches from tree]'
2511                               ];
2512         # make the anchor merge
2513         # the tree is already exactly right
2514         $work = make_commit [$work, $upstream], [
2515  'git-debrebase import: declare upstream',
2516  'First breakwater merge.',
2517  '[git-debrebase anchor: declare upstream]'
2518                               ];
2519
2520         # rebase the patch queue onto the new breakwater
2521         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2522         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2523         $work = git_rev_parse 'HEAD';
2524
2525         if ($previous_dgit_view) {
2526             $work = make_commit [$work, $previous_dgit_view], [
2527  'git-debrebase import: declare ff from dgit archive view',
2528  '[git-debrebase pseudomerge: import-from-gbp]',
2529             ];
2530         }
2531     };
2532
2533     ffq_check $work;
2534     snags_maybe_bail();
2535     update_head_checkout $old_head, $work, 'convert-from-gbp';
2536 }
2537
2538 sub cmd_convert_to_gbp () {
2539     badusage "no arguments allowed" if @ARGV;
2540     my $head = get_head();
2541     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2542     keycommits $head, 0;
2543     my $out;
2544     make_patches_staged $head;
2545     in_workarea sub {
2546         $out = make_commit ['HEAD'], [
2547             'Commit patch queue (converted from git-debrebase format)',
2548             '[git-debrebase convert-to-gbp: commit patches]',
2549         ];
2550     };
2551     if (defined $ffq) {
2552         push @deferred_updates, "delete $ffq";
2553         push @deferred_updates, "delete $gdrlast";
2554     }
2555     snags_maybe_bail();
2556     update_head_checkout $head, $out, "convert to gbp (v0)";
2557     print <<END or die $!;
2558 git-debrebase: converted to git-buildpackage branch format
2559 git-debrebase: WARNING: do not now run "git-debrebase" any more
2560 git-debrebase: WARNING: doing so would drop all upstream patches!
2561 END
2562 }
2563
2564 sub cmd_convert_from_dgit_view () {
2565     my $clogp = parsechangelog();
2566
2567     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2568     my $do_origs = 1;
2569     my $do_tags = 1;
2570     my $always = 0;
2571     my $diagnose = 0;
2572
2573     getoptions("convert-from-dgit-view",
2574                'diagnose!', \$diagnose,
2575                'build-products-dir:s', \$bpd,
2576                'origs!', \$do_origs,
2577                'tags!', \$do_tags,
2578                'always-convert-anyway!', \$always);
2579     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2580
2581     my @upstreams;
2582
2583     if (@ARGV) {
2584         my $spec = shift @ARGV;
2585         my $commit = git_rev_parse "$spec^{commit}";
2586         push @upstreams, { Commit => $commit,
2587                            Source => "$ARGV[0], from command line",
2588                            Only => 1,
2589                          };
2590     }
2591
2592     my $head = get_head();
2593
2594     if (!$always) {
2595         my $troubles = 0;
2596         my $trouble = sub { $troubles++; };
2597         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2598         printdebug "troubles=$troubles\n";
2599         if (!$troubles) {
2600             print STDERR <<END;
2601 $us: Branch already seems to be in git-debrebase format!
2602 $us: --always-convert-anyway would do the conversion operation anyway
2603 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2604 END
2605             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2606             finish 0;
2607         }
2608     }
2609
2610     check_series_has_all_patches $head;
2611
2612     snags_maybe_bail_early();
2613
2614     my $version = upstreamversion $clogp->{Version};
2615     print STDERR "Considering possible commits corresponding to upstream:\n";
2616
2617     if (!@upstreams) {
2618         if ($do_tags) {
2619             my @tried;
2620             my $ups_tag = upstream_commitish_search $version, \@tried;
2621             if ($ups_tag) {
2622                 my $this = "git tag $tried[-1]";
2623                 push @upstreams, { Commit => $ups_tag,
2624                                    Source => $this,
2625                                  };
2626             } else {
2627                 printf STDERR
2628                     " git tag: no suitable tag found (tried %s)\n",
2629                     "@tried";
2630             }
2631         }
2632         if ($do_origs) {
2633             my $p = $clogp->{'Source'};
2634             # we do a quick check to see if there are plausible origs
2635             my $something=0;
2636             if (!opendir BPD, $bpd) {
2637                 die "$bpd: opendir: $!" unless $!==ENOENT;
2638             } else {
2639                 while ($!=0, my $f = readdir BPD) {
2640                     next unless is_orig_file_of_p_v $f, $p, $version;
2641                     printf STDERR
2642                         " orig: found what looks like a .orig, %s\n",
2643                         "$bpd/$f";
2644                     $something=1;
2645                     last;
2646                 }
2647                 die "read $bpd: $!" if $!;
2648                 closedir BPD;
2649             }
2650             if ($something) {
2651                 my $tree = cmdoutput
2652                     @dgit, qw(--build-products-dir), $bpd,
2653                     qw(print-unapplied-treeish);
2654                 fresh_workarea();
2655                 in_workarea sub {
2656                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2657                     rm_subdir_cached 'debian';
2658                     $tree = cmdoutput @git, qw(write-tree);
2659                     my $ups_synth = make_commit [], [ <<END, <<END,
2660 Import effective orig tree for upstream version $version
2661 END
2662 This includes the contents of the .orig(s), minus any debian/ directory.
2663
2664 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2665 END
2666                                                     ];
2667                     push @upstreams, { Commit => $ups_synth,
2668                                        Source => "orig(s) imported via dgit",
2669                                      };
2670                 }
2671             } else {
2672                 printf STDERR
2673                     " orig: no suitable origs found (looked for %s in %s)\n",
2674                     "${p}_".(stripeoch $version)."...", $bpd;
2675             }
2676         }
2677     }
2678
2679     my $some_patches = stat_exists 'debian/patches/series';
2680
2681     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2682
2683     my $result;
2684     foreach my $u (@upstreams) {
2685         my $work = $head;
2686         fresh_workarea();
2687         in_workarea sub {
2688             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2689             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2690             runcmd @git, qw(clean -xdff);
2691             runcmd @git, qw(checkout), $head, qw(-- debian);
2692             if ($some_patches) {
2693                 rm_subdir_cached 'debian/patches';
2694                 $work = make_commit [ $work ], [
2695  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2696  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2697  "to git-debrebase format.  Upstream changes will appear as commits.",
2698  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2699                                            ];
2700             }
2701             $work = make_commit [ $work, $u->{Commit} ], [
2702  'git-debrebase convert-from-dgit-view: declare upstream',
2703  '(Re)constructed breakwater merge.',
2704  '[git-debrebase anchor: declare upstream]'
2705                                                          ];
2706             runcmd @git, qw(checkout --quiet -b mk), $work;
2707             if ($some_patches) {
2708                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2709                 runcmd @git, qw(reset --quiet);
2710                 my @gbp_cmd = (qw(gbp pq import));
2711                 if (!$diagnose) {
2712                     my $gbp_err = "../gbp-pq-err";
2713                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2714                 }
2715                 my $r = system @gbp_cmd;
2716                 if ($r) {
2717                     printf STDERR
2718                         " %s: couldn't apply patches: gbp pq %s",
2719                         $u->{Source}, waitstatusmsg();
2720                     return;
2721                 }
2722             }
2723             my $work = git_rev_parse qw(HEAD);
2724             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2725             if (length $diffout) {
2726                 print STDERR
2727                     " $u->{Source}: applying patches gives different tree\n";
2728                 print STDERR $diffout if $diagnose;
2729                 return;
2730             }
2731             # OMG!
2732             $u->{Result} = $work;
2733             $result = $u;
2734         };
2735         last if $result;
2736     }
2737
2738     if (!$result) {
2739         fail <<END;
2740 Could not find or construct a suitable upstream commit.
2741 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2742 upstream commmit explicitly or provide suitable origs.
2743 END
2744     }
2745
2746     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2747
2748     ffq_check $result->{Result};
2749     snags_maybe_bail();
2750     update_head_checkout $head, $result->{Result},
2751         'convert-from-dgit-view';
2752 }
2753
2754 sub cmd_record_resolved_merge () {
2755     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2756     # xxx needs documentation
2757     my $new = get_head();
2758     my $method;
2759
2760     print "Checking how you have resolved the merge problem\n";
2761     my $nope = sub { print "Not $method: @_"; 0; };
2762
2763     my $maybe = sub { print "Seems to be $method.\n"; };
2764     my $yes = sub {
2765         my ($key, $ref) = @_;
2766         reflog_cache_insert $merge_cache_ref, $key, $ref;
2767         print "OK.  You can switch branches and try git-debrebase again.\n";
2768         1;
2769     };
2770
2771     fresh_workarea 'merge';
2772     sub {
2773         $method = 'vanilla-merge patchqueue';
2774         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2775         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2776         foreach my $lr (qw(left right)) {
2777             my $n = "$wrecknoteprefix/$lr-patchqueue";
2778             my $lrpq = git_get_ref $n;
2779             $lrpq or return $nope->("wreckage did not contain patchqueues");
2780             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2781         }
2782         $maybe->();
2783         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2784             or die "wreckage element $wrecknoteprefix/new-base missing";
2785         my $result = merge_series_patchqueue_convert
2786             {}, $newbase, $new;
2787         $yes->("vanilla-merge $vanilla", $result);
2788         1;
2789     }->() or sub {
2790         fail "No resolved merge method seems applicable.\n";
2791     }->();
2792 }
2793
2794 sub cmd_downstream_rebase_launder_v0 () {
2795     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2796     my ($base) = @ARGV;
2797     $base = git_rev_parse $base;
2798     my $old_head = get_head();
2799     my $current = $old_head;
2800     my $topmost_keep;
2801     for (;;) {
2802         if ($current eq $base) {
2803             $topmost_keep //= $current;
2804             print " $current BASE stop\n";
2805             last;
2806         }
2807         my $cl = classify $current;
2808         print " $current $cl->{Type}";
2809         my $keep = 0;
2810         my $p0 = $cl->{Parents}[0]{CommitId};
2811         my $next;
2812         if ($cl->{Type} eq 'Pseudomerge') {
2813             print " ^".($cl->{Contributor}{Ix}+1);
2814             $next = $cl->{Contributor}{CommitId};
2815         } elsif ($cl->{Type} eq 'AddPatches' or
2816                  $cl->{Type} eq 'Changelog') {
2817             print " strip";
2818             $next = $p0;
2819         } else {
2820             print " keep";
2821             $next = $p0;
2822             $keep = 1;
2823         }
2824         print "\n";
2825         if ($keep) {
2826             $topmost_keep //= $current;
2827         } else {
2828             die "to-be stripped changes not on top of the branch\n"
2829                 if $topmost_keep;
2830         }
2831         $current = $next;
2832     }
2833     if ($topmost_keep eq $old_head) {
2834         print "unchanged\n";
2835     } else {
2836         print "updating to $topmost_keep\n";
2837         update_head_checkout
2838             $old_head, $topmost_keep,
2839             'downstream-rebase-launder-v0';
2840     }
2841 }
2842
2843 getoptions_main
2844           ("bad options\n",
2845            "D+" => \$debuglevel,
2846            'noop-ok', => \$opt_noop_ok,
2847            'f=s' => \@snag_force_opts,
2848            'anchor=s' => \@opt_anchors,
2849            '--dgit=s' => \($dgit[0]),
2850            'force!',
2851            '-i:s' => sub {
2852                my ($opt,$val) = @_;
2853                badusage "git-debrebase: no cuddling to -i for git-rebase"
2854                    if length $val;
2855                die if $opt_defaultcmd_interactive; # should not happen
2856                $opt_defaultcmd_interactive = [ qw(-i) ];
2857                # This access to @ARGV is excessive familiarity with
2858                # Getopt::Long, but there isn't another sensible
2859                # approach.  '-i=s{0,}' does not work with bundling.
2860                push @$opt_defaultcmd_interactive, @ARGV;
2861                @ARGV=();
2862            },
2863            'help' => sub { print $usage_message or die $!; finish 0; },
2864            );
2865
2866 initdebug('git-debrebase ');
2867 enabledebug if $debuglevel;
2868
2869 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2870 chdir $toplevel or die "chdir $toplevel: $!";
2871
2872 $rd = fresh_playground "$playprefix/misc";
2873
2874 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2875
2876 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2877     defaultcmd_rebase();
2878 } else {
2879     my $cmd = shift @ARGV;
2880     my $cmdfn = $cmd;
2881     $cmdfn =~ y/-/_/;
2882     $cmdfn = ${*::}{"cmd_$cmdfn"};
2883
2884     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2885     $cmdfn->();
2886 }
2887
2888 finish 0;