git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_careful, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 $opt_careful = 1;
  57
  58 our $us = qw(git-debrebase);
  59
  60 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  61 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  62
  63 $|=1;
  64
  65 sub badusage ($) {
  66     my ($m) = @_;
  67     print STDERR "$us: bad usage: $m\n";
  68     finish 8;
  69 }
  70
  71 sub getoptions_main {
  72     my $m = shift;
  73     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  74     GetOptions @_ or badusage $m;
  75 }
  76 sub getoptions {
  77     my $sc = shift;
  78     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  79 }
  80
  81 sub cfg ($;$) {
  82     my ($k, $optional) = @_;
  83     local $/ = "\0";
  84     my @cmd = qw(git config -z);
  85     push @cmd, qw(--get-all) if wantarray;
  86     push @cmd, $k;
  87     my $out = cmdoutput_errok @cmd;
  88     if (!defined $out) {
  89         fail "missing required git config $k" unless $optional;
  90         return ();
  91     }
  92     my @l = split /\0/, $out;
  93     return wantarray ? @l : $l[0];
  94 }
  95
  96 memoize('cfg');
  97
  98 sub dd ($) {
  99     my ($v) = @_;
 100     my $dd = new Data::Dumper [ $v ];
 101     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 102     return Dump $dd;
 103 }
 104
 105 sub get_commit ($) {
 106     my ($objid) = @_;
 107     my $data = (git_cat_file $objid, 'commit');
 108     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 109     return ($`,$');
 110 }
 111
 112 sub D_UPS ()      { 0x02; } # upstream files
 113 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 114 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 115 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 116 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 117 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 118
 119 our $playprefix = 'debrebase';
 120 our $rd;
 121 our $workarea;
 122
 123 our @git = qw(git);
 124 our @dgit = qw(dgit);
 125
 126 sub in_workarea ($) {
 127     my ($sub) = @_;
 128     changedir $workarea;
 129     my $r = eval { $sub->(); };
 130     { local $@; changedir $maindir; }
 131     die $@ if $@;
 132 }
 133
 134 sub fresh_workarea (;$) {
 135     my ($subdir) = @_;
 136     $subdir //= 'work';
 137     $workarea = fresh_playground "$playprefix/$subdir";
 138     in_workarea sub { playtree_setup };
 139 }
 140
 141 sub run_ref_updates_now ($$) {
 142     my ($mrest, $updates) = @_;
 143     # @$updates is a list of lines for git-update-ref, without \ns
 144
 145     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 146     debugcmd '>|', @upd_cmd;
 147     open U, "|-", @upd_cmd or die $!;
 148     foreach (@$updates) {
 149         printdebug ">= ", $_, "\n";
 150         print U $_, "\n" or die $!;
 151     }
 152     printdebug ">\$\n";
 153     close U or failedcmd @upd_cmd;
 154 }
 155
 156 our $snags_forced = 0;
 157 our $snags_tripped = 0;
 158 our $snags_summarised = 0;
 159 our @deferred_updates;
 160 our @deferred_update_messages;
 161
 162 sub merge_wreckage_cleaning ($) {
 163     my ($updates) = @_;
 164     git_for_each_ref("$wrecknoteprefix/*", sub {
 165         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 166         push @$updates, "delete $fullrefname";
 167     });
 168 }
 169
 170 sub all_snags_summarised () {
 171     $snags_forced + $snags_tripped == $snags_summarised;
 172 }
 173 sub run_deferred_updates ($) {
 174     my ($mrest) = @_;
 175
 176     confess 'dangerous internal error' unless all_snags_summarised();
 177
 178     merge_wreckage_cleaning \@deferred_updates;
 179     run_ref_updates_now $mrest, \@deferred_updates;
 180     print $_, "\n" foreach @deferred_update_messages;
 181
 182     @deferred_updates = ();
 183     @deferred_update_messages = ();
 184 }
 185
 186 sub get_differs ($$) {
 187     my ($x,$y) = @_;
 188     # This resembles quiltify_trees_differ, in dgit, a bit.
 189     # But we don't care about modes, or dpkg-source-unrepresentable
 190     # changes, and we don't need the plethora of different modes.
 191     # Conversely we need to distinguish different kinds of changes to
 192     # debian/ and debian/patches/.
 193
 194     my $differs = 0;
 195
 196     my $rundiff = sub {
 197         my ($opts, $limits, $fn) = @_;
 198         my @cmd = (@git, qw(diff-tree -z --no-renames));
 199         push @cmd, @$opts;
 200         push @cmd, "$_:" foreach $x, $y;
 201         push @cmd, '--', @$limits;
 202         my $diffs = cmdoutput @cmd;
 203         foreach (split /\0/, $diffs) { $fn->(); }
 204     };
 205
 206     $rundiff->([qw(--name-only)], [], sub {
 207         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 208     });
 209
 210     if ($differs & DS_DEB) {
 211         $differs &= ~DS_DEB;
 212         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 213             $differs |=
 214                 m{^debian/patches/}      ? D_PAT_OTH  :
 215                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 216                                            D_DEB_OTH;
 217         });
 218         die "mysterious debian changes $x..$y"
 219             unless $differs & (D_PAT_OTH|DS_DEB);
 220     }
 221
 222     if ($differs & D_PAT_OTH) {
 223         my $mode;
 224         $differs &= ~D_PAT_OTH;
 225         my $pat_oth = sub {
 226             $differs |= D_PAT_OTH;
 227             no warnings qw(exiting);  last;
 228         };
 229         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 230             no warnings qw(exiting);
 231             if (!defined $mode) {
 232                 $mode = $_;  next;
 233             }
 234             die unless s{^debian/patches/}{};
 235             my $ok;
 236             if ($mode eq 'A' && !m/\.series$/s) {
 237                 $ok = 1;
 238             } elsif ($mode eq 'M' && $_ eq 'series') {
 239                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 240                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 241                 chomp $x_s;  $x_s .= "\n";
 242                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 243             } else {
 244                 # nope
 245             }
 246             $mode = undef;
 247             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 248         });
 249         die "mysterious debian/patches changes $x..$y"
 250             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 251     }
 252
 253     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 254
 255     return $differs;
 256 }
 257
 258 sub commit_pr_info ($) {
 259     my ($r) = @_;
 260     return Data::Dumper->dump([$r], [qw(commit)]);
 261 }
 262
 263 sub calculate_committer_authline () {
 264     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 265         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 266     my ($h,$m) = get_commit $c;
 267     $h =~ m/^committer .*$/m or confess "($h) ?";
 268     return $&;
 269 }
 270
 271 sub rm_subdir_cached ($) {
 272     my ($subdir) = @_;
 273     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 274 }
 275
 276 sub read_tree_subdir ($$) {
 277     my ($subdir, $new_tree_object) = @_;
 278     rm_subdir_cached $subdir;
 279     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 280 }
 281
 282 sub read_tree_debian ($) {
 283     my ($treeish) = @_;
 284     read_tree_subdir 'debian', "$treeish:debian";
 285     rm_subdir_cached 'debian/patches';
 286 }
 287
 288 sub read_tree_upstream ($;$$) {
 289     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 290     # if $tree_with_debian is supplied, will use that for debian/
 291     # otherwise will save and restore it.
 292     my $debian =
 293         $tree_with_debian ? "$tree_with_debian:debian"
 294         : cmdoutput @git, qw(write-tree --prefix=debian/);
 295     runcmd @git, qw(read-tree), $treeish;
 296     read_tree_subdir 'debian', $debian;
 297     rm_subdir_cached 'debian/patches' unless $keep_patches;
 298 };
 299
 300 sub make_commit ($$) {
 301     my ($parents, $message_paras) = @_;
 302     my $tree = cmdoutput @git, qw(write-tree);
 303     my @cmd = (@git, qw(commit-tree), $tree);
 304     push @cmd, qw(-p), $_ foreach @$parents;
 305     push @cmd, qw(-m), $_ foreach @$message_paras;
 306     return cmdoutput @cmd;
 307 }
 308
 309 our @snag_force_opts;
 310 sub snag ($$;@) {
 311     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 312     if (grep { $_ eq $tag } @snag_force_opts) {
 313         $snags_forced++;
 314         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 315     } else {
 316         $snags_tripped++;
 317         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 318     }
 319 }
 320
 321 # Important: all mainline code must call snags_maybe_bail after
 322 # any point where snag might be called, but before making changes
 323 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 324 # may be called more than once if necessary (but this is not ideal
 325 # because then the messages about number of snags may be confusing).
 326 sub snags_maybe_bail () {
 327     return if all_snags_summarised();
 328     if ($snags_forced) {
 329         printf STDERR
 330             "%s: snags: %d overriden by individual -f options\n",
 331             $us, $snags_forced;
 332     }
 333     if ($snags_tripped) {
 334         if ($opt_force) {
 335             printf STDERR
 336                 "%s: snags: %d overriden by global --force\n",
 337                 $us, $snags_tripped;
 338         } else {
 339             fail sprintf
 340   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 341                 $us, $snags_tripped;
 342         }
 343     }
 344     $snags_summarised = $snags_forced + $snags_tripped;
 345 }
 346 sub snags_maybe_bail_early () {
 347     # useful to bail out early without doing a lot of work;
 348     # not a substitute for snags_maybe_bail.
 349     snags_maybe_bail() if $snags_tripped && !$opt_force;
 350 }
 351 sub any_snags () {
 352     return $snags_forced || $snags_tripped;
 353 }
 354
 355 sub gbp_pq_export ($$$) {
 356     my ($bname, $base, $tip) = @_;
 357     # must be run in a workarea.  $bname and patch-queue/$bname
 358     # ought not to exist.  Leaves you on patch-queue/$bname with
 359     # the patches staged but not committed.
 360     printdebug "gbp_pq_export $bname $base $tip\n";
 361     runcmd @git, qw(checkout -q -b), $bname, $base;
 362     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 363     my @gbp_cmd = (qw(gbp pq export));
 364     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 365     if ($r) {
 366         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 367         failedcmd @gbp_cmd;
 368     }
 369     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 370 }
 371
 372
 373 # xxx allow merge resolution separately from laundering, before git merge
 374 #
 375 # xxx general gdr docs highlight forbidden things
 376 # xxx general gdr docs list allowable things ?
 377 # xxx general gdr docs explicitly forbid some rebase
 378
 379 # later/rework?
 380 #  use git-format-patch?
 381 #  our own patch identification algorithm?
 382 #  this is an alternative strategy
 383
 384 sub merge_failed ($$;@) {
 385     my ($wrecknotes, $emsg, @xmsgs) = @_;
 386     my @m;
 387     push @m, "Merge resolution failed: $emsg";
 388     push @m, @xmsgs;
 389
 390     changedir $maindir;
 391
 392     my @updates;
 393     merge_wreckage_cleaning \@updates;
 394     run_ref_updates_now "merge failed", \@updates;
 395
 396     @updates = ();
 397     keys %$wrecknotes;
 398     while (my ($k,$v) = each %$wrecknotes) {
 399         push @updates, "create $wrecknoteprefix/$k $v";
 400     }
 401     run_ref_updates_now "merge failed", \@updates;
 402     push @m, "Wreckage left in $wrecknoteprefix/*.";
 403
 404     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 405
 406     # use finish rather than fail, in case we are within an eval
 407     # (that can happen inside walk!)
 408     print STDERR "\n";
 409     print STDERR "$us: $_\n" foreach @m;
 410     finish 15;
 411 }
 412
 413 sub mwrecknote ($$$) {
 414     my ($wrecknotes, $reftail, $commitish) = @_;
 415     confess unless defined $commitish;
 416     printdebug "mwrecknote $reftail $commitish\n";
 417     $wrecknotes->{$reftail} = $commitish;
 418 }
 419
 420 sub merge_attempt_cmd {
 421     my $wrecknotes = shift @_;
 422     debugcmd '+', @_;
 423     $!=0; $?=-1;
 424     if (system @_) {
 425         merge_failed $wrecknotes,
 426             failedcmd_waitstatus(),
 427             "failed command: @_";
 428     }
 429 }
 430
 431 sub merge_series_patchqueue_convert ($$$);
 432
 433 sub merge_series ($$$;@) {
 434     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 435     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 436     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 437     # ^ specifies several patch series (currently we only support exactly 2)
 438     # return value is a commit which is the result of
 439     # merging the two versions of the same topic branch
 440     #   $input_q[0] and $input_q[1]
 441     # with respect to the old version
 442     #   $base_q
 443     # all onto $newbase.
 444
 445     # Creates, in *_q, a key MR for its private use
 446
 447     printdebug "merge_series newbase=$newbase\n";
 448
 449     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 450     $base_q->{MR}{S} = 'base';
 451
 452     my %prereq;
 453     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 454     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 455     # $prereq{<patch filename>}               exists or not (even later)
 456
 457     my $merged_pq;
 458
 459     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 460
 461     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 462
 463     local $workarea;
 464     fresh_workarea "merge";
 465     my $seriesfile = "debian/patches/series";
 466     in_workarea sub {
 467         playtree_setup();
 468         foreach my $q ($base_q, reverse @input_qs) {
 469             my $s = $q->{MR}{S};
 470             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 471             my @earlier;
 472             if (open S, $seriesfile) {
 473                 while (my $patch = <S>) {
 474                     chomp $patch or die $!;
 475                     $prereq{$patch} //= {};
 476                     foreach my $earlier (@earlier) {
 477                         $prereq{$patch}{$earlier}{$s}++ and die;
 478                     }
 479                     push @earlier, $patch;
 480                     stat "debian/patches/$patch" or die "$patch ?";
 481                 }
 482                 S->error and die "$seriesfile $!";
 483                 close S;
 484             } else {
 485                 die "$seriesfile $!" unless $!==ENOENT;
 486             }
 487             read_tree_upstream $newbase, 1;
 488             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 489                 "Convert $s to patch queue for merging",
 490                 "[git-debrebase merge-innards patch-queue import:".
 491                 " $q->{SeriesTip}]"
 492             ];
 493             printdebug "merge_series  pec $pec ";
 494             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 495             $pec = make_commit [ $pec ], [
 496                 "Drop series file from $s to avoid merge trouble",
 497                 "[git-debrebase merge-innards patch-queue prep:".
 498                 " $q->{SeriesTip}]"
 499             ];
 500
 501             read_tree_debian $newbase;
 502             if (@earlier) {
 503                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 504             } else {
 505                 rm_subdir_cached 'debian/patches';
 506             }
 507             $pec = make_commit [ $pec ], [
 508  "Update debian/ (excluding patches) to final to avoid re-merging",
 509  "debian/ was already merged and we need to just take that.",
 510                 "[git-debrebase merge-innards patch-queue packaging:".
 511                 " $q->{SeriesTip}]"
 512             ];
 513
 514             printdebug "pec' $pec\n";
 515             runcmd @git, qw(reset -q --hard), $pec;
 516             $q->{MR}{PEC} = $pec;
 517             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 518         }
 519         # now, because of reverse, we are on $input_q->{MR}{OQC}
 520         runcmd @git, qw(checkout -q -b merge);
 521         printdebug "merge_series merging...\n";
 522         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 523
 524         $attempt_cmd->(@mergecmd);
 525
 526         printdebug "merge_series merge ok, series...\n";
 527         # We need to construct a new series file
 528         # Firstly, resolve prereq
 529         foreach my $f (sort keys %prereq) {
 530             printdebug "merge_series  patch\t$f\t";
 531             if (!stat_exists "debian/patches/$f") {
 532                 print DEBUG " drop\n" if $debuglevel;
 533                 # git merge deleted it; that's how we tell it's not wanted
 534                 delete $prereq{$f};
 535                 next;
 536             }
 537             print DEBUG " keep\n" if $debuglevel;
 538             foreach my $g (sort keys %{ $prereq{$f} }) {
 539                 my $gfp = $prereq{$f}{$g};
 540                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 541                 if (!!$gfp->{0} == !!$gfp->{1}
 542                     ? $gfp->{0}
 543                     : !$gfp->{base}) {
 544                     print DEBUG "\tkeep\n" if $debuglevel;
 545                 } else {
 546                     print DEBUG "\tdrop\n" if $debuglevel;
 547                     delete $prereq{$f}{$g};
 548                 }
 549             }
 550         }
 551
 552         my $unsat = sub {
 553             my ($f) = @_;
 554             return scalar keys %{ $prereq{$f} };
 555         };
 556
 557         my $nodate = time + 1;
 558         my %authordate;
 559         # $authordate{<patch filename>};
 560         my $authordate = sub {
 561             my ($f) = @_;
 562             $authordate{$f} //= do {
 563                 open PF, "<", "debian/patches/$f" or die "$f $!";
 564                 while (<PF>) {
 565                     return $nodate if m/^$/;
 566                     last if s{^Date: }{};
 567                 }
 568                 chomp;
 569                 return cmdoutput qw(date +%s -d), $_;
 570             };
 571         };
 572
 573         open NS, '>', $seriesfile or die $!;
 574
 575         while (keys %prereq) {
 576             my $best;
 577             foreach my $try (sort keys %prereq) {
 578                 if ($best) {
 579                     next if (
 580                              $unsat->($try) <=> $unsat->($best) or
 581                              $authordate->($try) <=> $authordate->($best) or
 582                              $try cmp $best
 583                             ) >= 0;
 584                 }
 585                 $best = $try;
 586             }
 587             printdebug "merge_series series next $best\n";
 588             print NS "$best\n" or die $!;
 589             delete $prereq{$best};
 590             foreach my $gp (values %prereq) {
 591                 delete $gp->{$best};
 592             }
 593         }
 594
 595         runcmd @git, qw(add), $seriesfile;
 596         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 597         $merged_pq = git_rev_parse 'HEAD';
 598         $mwrecknote->('merged-patchqueue', $merged_pq);
 599     };
 600     return merge_series_patchqueue_convert
 601             $wrecknotes, $newbase, $merged_pq;
 602 }
 603
 604 sub merge_series_patchqueue_convert ($$$) {
 605     my ($wrecknotes, $newbase, $merged_pq) = @_;
 606
 607     my $result;
 608     in_workarea sub {
 609         playtree_setup();
 610         printdebug "merge_series series gbp pq import\n";
 611         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 612
 613         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 614
 615         # OK now we are on patch-queue/merge, and we need to rebase
 616         # onto the intended parent and drop the patches from each one
 617
 618         printdebug "merge_series series ok, building...\n";
 619         my $build = $newbase;
 620         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 621         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 622             my $commit = git_cat_file $c, 'commit';
 623             printdebug "merge_series series ok, building $c\n";
 624             read_tree_upstream $c, 0, $newbase;
 625             my $tree = cmdoutput @git, qw(write-tree);
 626             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 627             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 628             open C, ">", "../mcommit" or die $!;
 629             print C $commit or die $!;
 630             close C or die $!;
 631             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 632         }
 633         $result = $build;
 634         mwrecknote($wrecknotes, 'merged-result', $result);
 635
 636         runcmd @git, qw(update-ref refs/heads/result), $result;
 637
 638         runcmd @git, qw(checkout -q -b debug);
 639         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 640         runcmd @git, qw(add .);
 641         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 642         my $mdebug = git_rev_parse 'HEAD';
 643         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 644         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 645     };
 646     printdebug "merge_series returns $result\n";
 647     return $result;
 648 }
 649
 650 # classify returns an info hash like this
 651 #   CommitId => $objid
 652 #   Hdr => # commit headers, including 1 final newline
 653 #   Msg => # commit message (so one newline is dropped)
 654 #   Tree => $treeobjid
 655 #   Type => (see below)
 656 #   Parents = [ {
 657 #       Ix => $index # ie 0, 1, 2, ...
 658 #       CommitId
 659 #       Differs => return value from get_differs
 660 #       IsOrigin
 661 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 662 #     } ...]
 663 #   NewMsg => # commit message, but with any [dgit import ...] edited
 664 #             # to say "[was: ...]"
 665 #
 666 # Types:
 667 #   Packaging
 668 #   Changelog
 669 #   Upstream
 670 #   AddPatches
 671 #   Mixed
 672 #
 673 #   Pseudomerge
 674 #     has additional entres in classification result
 675 #       Overwritten = [ subset of Parents ]
 676 #       Contributor = $the_remaining_Parent
 677 #
 678 #   DgitImportUnpatched
 679 #     has additional entry in classification result
 680 #       OrigParents = [ subset of Parents ]
 681 #
 682 #   Anchor
 683 #     has additional entry in classification result
 684 #       OrigParents = [ subset of Parents ]  # singleton list
 685 #
 686 #   TreatAsAnchor
 687 #
 688 #   BreakwaterStart
 689 #
 690 #   Unknown
 691 #     has additional entry in classification result
 692 #       Why => "prose"
 693
 694 sub parsecommit ($;$) {
 695     my ($objid, $p_ref) = @_;
 696     # => hash with                   CommitId Hdr Msg Tree Parents
 697     #    Parents entries have only   Ix CommitId
 698     #    $p_ref, if provided, must be [] and is used as a base for Parents
 699
 700     $p_ref //= [];
 701     die if @$p_ref;
 702
 703     my ($h,$m) = get_commit $objid;
 704
 705     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 706     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 707
 708     my $r = {
 709         CommitId => $objid,
 710         Hdr => $h,
 711         Msg => $m,
 712         Tree => $t,
 713         Parents => $p_ref,
 714     };
 715
 716     foreach my $ph (@ph) {
 717         push @$p_ref, {
 718             Ix => scalar @$p_ref,
 719             CommitId => $ph,
 720         };
 721     }
 722
 723     return $r;
 724 }
 725
 726 sub classify ($) {
 727     my ($objid) = @_;
 728
 729     my @p;
 730     my $r = parsecommit($objid, \@p);
 731     my $t = $r->{Tree};
 732
 733     foreach my $p (@p) {
 734         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 735     }
 736
 737     printdebug "classify $objid \$t=$t \@p",
 738         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 739         "\n";
 740
 741     my $classify = sub {
 742         my ($type, @rest) = @_;
 743         $r = { %$r, Type => $type, @rest };
 744         if ($debuglevel) {
 745             printdebug " = $type ".(dd $r)."\n";
 746         }
 747         return $r;
 748     };
 749     my $unknown = sub {
 750         my ($why) = @_;
 751         $r = { %$r, Type => qw(Unknown), Why => $why };
 752         printdebug " ** Unknown\n";
 753         return $r;
 754     };
 755
 756     if (grep { $_ eq $objid } @opt_anchors) {
 757         return $classify->('TreatAsAnchor');
 758     }
 759
 760     my @identical = grep { !$_->{Differs} } @p;
 761     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 762     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 763
 764     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 765         # multi-orig upstreams are represented with an anchor merge
 766         # from a single upstream commit which combines the orig tarballs
 767
 768         # Every anchor tagged this way must be a merge.
 769         # We are relying on the
 770         #     [git-debrebase anchor: ...]
 771         # commit message annotation in "declare" anchor merges (which
 772         # do not have any upstream changes), to distinguish those
 773         # anchor merges from ordinary pseudomerges (which we might
 774         # just try to strip).
 775         #
 776         # However, the user is going to be doing git-rebase a lot.  We
 777         # really don't want them to rewrite an anchor commit.
 778         # git-rebase trips up on merges, so that is a useful safety
 779         # catch.
 780         #
 781         # BreakwaterStart commits are also anchors in the terminology
 782         # of git-debrebase(5), but they are untagged (and always
 783         # manually generated).
 784         #
 785         # We cannot not tolerate any tagged linear commit (ie,
 786         # BreakwaterStart commits tagged `[anchor:') because such a
 787         # thing could result from an erroneous linearising raw git
 788         # rebase of a merge anchor.  That would represent a corruption
 789         # of the branch. and we want to detect and reject the results
 790         # of such corruption before it makes it out anywhere.  If we
 791         # reject it here then we avoid making the pseudomerge which
 792         # would be needed to push it.
 793
 794         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 795         @p == 2 or return $badanchor->("has other than two parents");
 796         $haspatches and return $badanchor->("contains debian/patches");
 797
 798         # How to decide about l/r ordering of anchors ?  git
 799         # --topo-order prefers to expand 2nd parent first.  There's
 800         # already an easy rune to look for debian/ history anyway (git log
 801         # debian/) so debian breakwater branch should be 1st parent; that
 802         # way also there's also an easy rune to look for the upstream
 803         # patches (--topo-order).
 804
 805         # Also this makes --first-parent be slightly more likely to
 806         # be useful - it makes it provide a linearised breakwater history.
 807
 808         # Of course one can say somthing like
 809         #  gitk -- ':/' ':!/debian'
 810         # to get _just_ the commits touching upstream files, and by
 811         # the TREESAME logic in git-rev-list this will leave the
 812         # breakwater into upstream at the first anchor.  But that
 813         # doesn't report debian/ changes at all.
 814
 815         # Other observations about gitk: by default, gitk seems to
 816         # produce output in a different order to git-rev-list.  I
 817         # can't seem to find this documented anywhere.  gitk
 818         # --date-order DTRT.  But, gitk always seems to put the
 819         # parents from left to right, in order, so it's easy to see
 820         # which way round a pseudomerge is.
 821
 822         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 823         $p[1]{Differs} & ~DS_DEB and
 824             $badanchor->("upstream files differ from left parent");
 825         $p[0]{Differs} & ~D_UPS and
 826             $badanchor->("debian/ differs from right parent");
 827
 828         return $classify->(qw(Anchor),
 829                            OrigParents => [ $p[1] ]);
 830     }
 831
 832     if (@p == 1) {
 833         my $d = $r->{Parents}[0]{Differs};
 834         if ($d == D_PAT_ADD) {
 835             return $classify->(qw(AddPatches));
 836         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 837             return $unknown->("edits debian/patches");
 838         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 839             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 840             if ($ty eq 'tree') {
 841                 if ($d == D_DEB_CLOG) {
 842                     return $classify->(qw(Changelog));
 843                 } else {
 844                     return $classify->(qw(Packaging));
 845                 }
 846             } elsif ($ty eq 'missing') {
 847                 return $classify->(qw(BreakwaterStart));
 848             } else {
 849                 return $unknown->("parent's debian is not a directory");
 850             }
 851         } elsif ($d == D_UPS) {
 852             return $classify->(qw(Upstream));
 853         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 854             return $classify->(qw(Mixed));
 855         } elsif ($d == 0) {
 856             return $unknown->("no changes");
 857         } else {
 858             confess "internal error $objid ?";
 859         }
 860     }
 861     if (!@p) {
 862         return $unknown->("origin commit");
 863     }
 864
 865     if (@p == 2 && @identical == 1) {
 866         my @overwritten = grep { $_->{Differs} } @p;
 867         confess "internal error $objid ?" unless @overwritten==1;
 868         return $classify->(qw(Pseudomerge),
 869                            Overwritten => [ $overwritten[0] ],
 870                            Contributor => $identical[0]);
 871     }
 872     if (@p == 2 && @identical == 2) {
 873         my $get_t = sub {
 874             my ($ph,$pm) = get_commit $_[0]{CommitId};
 875             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 876             $1;
 877         };
 878         my @bytime = @p;
 879         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 880         if ($order > 0) { # newer first
 881         } elsif ($order < 0) {
 882             @bytime = reverse @bytime;
 883         } else {
 884             # same age, default to order made by -s ours
 885             # that is, commit was made by someone who preferred L
 886         }
 887         return $classify->(qw(Pseudomerge),
 888                            SubType => qw(Ambiguous),
 889                            Contributor => $bytime[0],
 890                            Overwritten => [ $bytime[1] ]);
 891     }
 892     foreach my $p (@p) {
 893         my ($p_h, $p_m) = get_commit $p->{CommitId};
 894         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 895         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 896     }
 897     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 898     my $m2 = $r->{Msg};
 899     if (!(grep { !$_->{IsOrigin} } @p) and
 900         (@orig_ps >= @p - 1) and
 901         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 902         $r->{NewMsg} = $m2;
 903         return $classify->(qw(DgitImportUnpatched),
 904                            OrigParents => \@orig_ps);
 905     }
 906
 907     if (@p == 2 and
 908         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 909         # xxx ^ metadata tag needs adding to (5)
 910         return $classify->("MergedBreakwaters");
 911     }
 912     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 913         return $unknown->("unknown kind of merge from $1");
 914     }
 915     if (@p > 2) {
 916         return $unknown->("octopus merge");
 917     }
 918
 919     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 920         return $unknown->("general two-parent merge");
 921     }
 922
 923     return $classify->("VanillaMerge");
 924 }
 925
 926 sub keycommits ($;$$$$$);
 927
 928 sub mergedbreakwaters_anchor ($) {
 929     my ($cl) = @_;
 930     my $best_anchor;
 931     foreach my $p (@{ $cl->{Parents} }) {
 932         my ($panchor, $pbw) = keycommits $p->{CommitId},
 933             undef,undef,undef,undef, 1;
 934         $best_anchor = $panchor
 935             if !defined $best_anchor
 936             or is_fast_fwd $best_anchor, $panchor;
 937         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 938             unless is_fast_fwd $panchor, $best_anchor;
 939     }
 940     return $best_anchor;
 941 }
 942
 943 sub keycommits ($;$$$$$) {
 944     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 945     # => ($anchor, $breakwater)
 946
 947     # $unclean->("unclean-$tagsfx", $msg, $cl)
 948     # $furniture->("unclean-$tagsfx", $msg, $cl)
 949     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 950     #   is callled for each situation or commit that
 951     #   wouldn't be found in a laundered branch
 952     # $furniture is for furniture commits such as might be found on an
 953     #   interchange branch (pseudomerge, d/patches, changelog)
 954     # $trouble is for things whnich prevent the return of
 955     #   anchor and breakwater information; if that is ignored,
 956     #   then keycommits returns (undef, undef) instead.
 957     # $fatal is for unprocessable commits, and should normally cause
 958     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 959     #
 960     # If $claimed_bw, this is supposed to be a breakwater commit.
 961     #
 962     # If a callback is undef, fail is called instead.
 963     # If a callback is defined but false, the situation is ignored.
 964     # Callbacks may say:
 965     #   no warnings qw(exiting); last;
 966     # if the answer is no longer wanted.
 967
 968     my ($anchor, $breakwater);
 969     $breakwater = $head if $claimed_bw;
 970     my $clogonly;
 971     my $cl;
 972     my $found_pm;
 973     $fatal //= sub { fail $_[1]; };
 974     my $x = sub {
 975         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 976         my $why = $mainwhy.$xwhy;
 977         my $m = "branch needs laundering (run git-debrebase): $why";
 978         fail $m unless defined $cb;
 979         return unless $cb;
 980         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 981     };
 982     my $found_anchor = sub {
 983         ($anchor) = @_;
 984         $breakwater //= $clogonly;
 985         $breakwater //= $head;
 986         no warnings qw(exiting);
 987         last;
 988     };
 989     for (;;) {
 990         $cl = classify $head;
 991         my $ty = $cl->{Type};
 992         if ($ty eq 'Packaging') {
 993             $breakwater //= $clogonly;
 994             $breakwater //= $head;
 995         } elsif ($ty eq 'Changelog') {
 996             # this is going to count as the tip of the breakwater
 997             # only if it has no upstream stuff before it
 998             $clogonly //= $head;
 999         } elsif ($ty eq 'Anchor' or
1000                  $ty eq 'TreatAsAnchor' or
1001                  $ty eq 'BreakwaterStart') {
1002             $found_anchor->($head);
1003         } elsif ($ty eq 'Upstream') {
1004             $x->($unclean, 'ordering',
1005  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1006                 if defined $breakwater;
1007             $clogonly = undef;
1008             $breakwater = undef;
1009         } elsif ($ty eq 'Mixed') {
1010             $x->($unclean, 'mixed',
1011                  "found mixed upstream/packaging commit"," ($head)");
1012             $clogonly = undef;
1013             $breakwater = undef;
1014         } elsif ($ty eq 'Pseudomerge' or
1015                  $ty eq 'AddPatches') {
1016             my $found_pm = 1;
1017             $x->($furniture, (lc $ty),
1018                  "found interchange bureaucracy commit ($ty)"," ($head)");
1019         } elsif ($ty eq 'DgitImportUnpatched') {
1020             if ($found_pm) {
1021                 $x->($trouble, 'dgitimport',
1022                      "found dgit dsc import"," ($head)");
1023                 return (undef,undef);
1024             } else {
1025                 $x->($fatal, 'unprocessable',
1026                      "found bare dgit dsc import with no prior history",
1027                      " ($head)");
1028                 return (undef,undef);
1029             }
1030         } elsif ($ty eq 'VanillaMerge') {
1031             $x->($trouble, 'vanillamerge',
1032                  "found vanilla merge"," ($head)");
1033             return (undef,undef);
1034         } elsif ($ty eq 'MergedBreakwaters') {
1035             $found_anchor->(mergedbreakwaters_anchor $cl);
1036         } else {
1037             $x->($fatal, 'unprocessable',
1038                  "found unprocessable commit, cannot cope: $cl->{Why}",
1039                  " ($head)");
1040             return (undef,undef);
1041         }
1042         $head = $cl->{Parents}[0]{CommitId};
1043     }
1044     return ($anchor, $breakwater);
1045 }
1046
1047 sub walk ($;$$$);
1048 sub walk ($;$$$) {
1049     my ($input,
1050         $nogenerate,$report, $report_lprefix) = @_;
1051     # => ($tip, $breakwater_tip, $last_anchor)
1052     # (or nothing, if $nogenerate)
1053
1054     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1055     $report_lprefix //= '';
1056
1057     # go through commits backwards
1058     # we generate two lists of commits to apply:
1059     # breakwater branch and upstream patches
1060     my (@brw_cl, @upp_cl, @processed);
1061     my %found;
1062     my $upp_limit;
1063     my @pseudomerges;
1064
1065     my $cl;
1066     my $xmsg = sub {
1067         my ($prose, $info) = @_;
1068         my $ms = $cl->{Msg};
1069         chomp $ms;
1070         $info //= '';
1071         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1072         return (Msg => $ms);
1073     };
1074     my $rewrite_from_here = sub {
1075         my ($cl) = @_;
1076         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1077         push @$cl, $sp_cl;
1078         push @processed, $sp_cl;
1079     };
1080     my $cur = $input;
1081
1082     my $prdelim = "";
1083     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1084
1085     my $prline = sub {
1086         return unless $report;
1087         print $report $prdelim, $report_lprefix, @_;
1088         $prdelim = "\n";
1089     };
1090
1091     my $bomb = sub { # usage: return $bomb->();
1092         print $report " Unprocessable" if $report;
1093         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1094         $prprdelim->();
1095         if ($nogenerate) {
1096             return (undef,undef);
1097         }
1098         fail "found unprocessable commit, cannot cope".
1099             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1100             " (commit $cur) (d.".
1101             (join ' ', map { sprintf "%#x", $_->{Differs} }
1102              @{ $cl->{Parents} }).
1103                  ")";
1104     };
1105
1106     my $build;
1107     my $breakwater;
1108
1109     my $build_start = sub {
1110         my ($msg, $parent) = @_;
1111         $prline->(" $msg");
1112         $build = $parent;
1113         no warnings qw(exiting); last;
1114     };
1115
1116     my $nomerge = sub {
1117         my ($emsg) = @_;
1118         merge_failed $cl->{MergeWreckNotes}, $emsg;
1119     };
1120
1121     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1122
1123     my $last_anchor;
1124
1125     for (;;) {
1126         $cl = classify $cur;
1127         $cl->{MergeWreckNotes} //= {};
1128         my $ty = $cl->{Type};
1129         my $st = $cl->{SubType};
1130         $prline->("$cl->{CommitId} $cl->{Type}");
1131         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1132         push @processed, $cl;
1133         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1134         if ($ty eq 'AddPatches') {
1135             $cur = $p0;
1136             $rewrite_from_here->(\@upp_cl);
1137             next;
1138         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1139             push @brw_cl, $cl;
1140             $cur = $p0;
1141             next;
1142         } elsif ($ty eq 'BreakwaterStart') {
1143             $last_anchor = $cur;
1144             $build_start->('FirstPackaging', $cur);
1145         } elsif ($ty eq 'Upstream') {
1146             push @upp_cl, $cl;
1147             $cur = $p0;
1148             next;
1149         } elsif ($ty eq 'Mixed') {
1150             my $queue = sub {
1151                 my ($q, $wh) = @_;
1152                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1153                 push @$q, $cls;
1154             };
1155             $queue->(\@brw_cl, "debian");
1156             $queue->(\@upp_cl, "upstream");
1157             $rewrite_from_here->(\@brw_cl);
1158             $cur = $p0;
1159             next;
1160         } elsif ($ty eq 'Pseudomerge') {
1161             my $contrib = $cl->{Contributor}{CommitId};
1162             print $report " Contributor=$contrib" if $report;
1163             push @pseudomerges, $cl;
1164             $rewrite_from_here->(\@upp_cl);
1165             $cur = $contrib;
1166             next;
1167         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1168             $last_anchor = $cur;
1169             $build_start->("Anchor", $cur);
1170         } elsif ($ty eq 'DgitImportUnpatched') {
1171             my $pm = $pseudomerges[-1];
1172             if (defined $pm) {
1173                 # To an extent, this is heuristic.  Imports don't have
1174                 # a useful history of the debian/ branch.  We assume
1175                 # that the first pseudomerge after an import has a
1176                 # useful history of debian/, and ignore the histories
1177                 # from later pseudomerges.  Often the first pseudomerge
1178                 # will be the dgit import of the upload to the actual
1179                 # suite intended by the non-dgit NMUer, and later
1180                 # pseudomerges may represent in-archive copies.
1181                 my $ovwrs = $pm->{Overwritten};
1182                 printf $report " PM=%s \@Overwr:%d",
1183                     $pm->{CommitId}, (scalar @$ovwrs)
1184                     if $report;
1185                 if (@$ovwrs != 1) {
1186                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1187                     return $bomb->();
1188                 }
1189                 my $ovwr = $ovwrs->[0]{CommitId};
1190                 printf $report " Overwr=%s", $ovwr if $report;
1191                 # This import has a tree which is just like a
1192                 # breakwater tree, but it has the wrong history.  It
1193                 # ought to have the previous breakwater (which the
1194                 # pseudomerge overwrote) as an ancestor.  That will
1195                 # make the history of the debian/ files correct.  As
1196                 # for the upstream version: either it's the same as
1197                 # was ovewritten (ie, same as the previous
1198                 # breakwater), in which case that history is precisely
1199                 # right; or, otherwise, it was a non-gitish upload of a
1200                 # new upstream version.  We can tell these apart by
1201                 # looking at the tree of the supposed upstream.
1202                 push @brw_cl, {
1203                     %$cl,
1204                     SpecialMethod => 'DgitImportDebianUpdate',
1205                     $xmsg->("convert dgit import: debian changes")
1206                 }, {
1207                     %$cl,
1208                     SpecialMethod => 'DgitImportUpstreamUpdate',
1209                     $xmsg->("convert dgit import: upstream update",
1210                             " anchor")
1211                 };
1212                 $prline->(" Import");
1213                 $rewrite_from_here->(\@brw_cl);
1214                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1215                 $cur = $ovwr;
1216                 next;
1217             } else {
1218                 # Everything is from this import.  This kind of import
1219                 # is already nearly in valid breakwater format, with the
1220                 # patches as commits.  Unfortunately it contains
1221                 # debian/patches/.
1222                 printdebug "*** WALK BOMB bare dgit import\n";
1223                 $cl->{Why} = "bare dgit dsc import";
1224                 return $bomb->();
1225             }
1226             die "$ty ?";
1227         } elsif ($ty eq 'MergedBreakwaters') {
1228             $last_anchor = mergedbreakwaters_anchor $cl;
1229             $build_start->(' MergedBreakwaters', $cur);
1230             last;
1231         } elsif ($ty eq 'VanillaMerge') {
1232             # User may have merged unstitched branch(es).  We will
1233             # have now lost what ffq-prev was then (since the later
1234             # pseudomerge may introduce further changes).  The effect
1235             # of resolving such a merge is that we may have to go back
1236             # further in history to find a merge base, since the one
1237             # which was reachable via ffq-prev is no longer findable.
1238             # This is suboptimal, but if it all works we'll have done
1239             # the right thing.
1240             # xxx we should warn the user in the docs about this
1241
1242             my $ok=1;
1243             my $best_anchor;
1244             # We expect to find a dominating anchor amongst the
1245             # inputs' anchors.  That will be the new anchor.
1246             #
1247             # More complicated is finding a merge base for the
1248             # breakwaters.  We need a merge base that is a breakwater
1249             # commit.  The ancestors of breakwater commits are more
1250             # breakwater commits and possibly upstream commits and the
1251             # ancestors of those upstream.  Upstreams might have
1252             # arbitrary ancestors.  But any upstream commit U is
1253             # either included in both anchors, in which case the
1254             # earlier anchor is a better merge base than any of U's
1255             # ancestors; or U is not included in the older anchor, in
1256             # which case U is not an ancestor of the vanilla merge at
1257             # all.  So no upstream commit, nor any ancestor thereof,
1258             # is a best merge base.  As for non-breakwater Debian
1259             # commits: these are never ancestors of any breakwater.
1260             #
1261             # So any best merge base as found by git-merge-base
1262             # is a suitable breakwater anchor.  Usually there will
1263             # be only one.
1264
1265             printdebug "*** MERGE\n";
1266
1267             my @bwbcmd = (@git, qw(merge-base));
1268             my @ibcmd = (@git, qw(merge-base --all));
1269             my $might_be_in_bw = 1;
1270
1271             my $ps = $cl->{Parents};
1272
1273             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1274
1275             foreach my $p (@$ps) {
1276                 $prline->(" VanillaMerge ".$p->{Ix});
1277                 $prprdelim->();
1278                 my ($ptip, $pbw, $panchor) =
1279                     walk $p->{CommitId}, 0, $report,
1280                          $report_lprefix.'  ';
1281                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1282                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1283                 $p->{Anchor} = $panchor;
1284
1285                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1286                 $mwrecknote->("$lr-input", $p->{CommitId});
1287
1288                 my $mwrecknote_parent = sub {
1289                     my ($which) = @_;
1290                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1291                 };
1292                 $mwrecknote_parent->('Laundered');
1293                 $mwrecknote_parent->('Breakwater');
1294                 $mwrecknote_parent->('Anchor');
1295
1296                 $best_anchor = $panchor if
1297                     !defined $best_anchor or
1298                     is_fast_fwd $best_anchor, $panchor;
1299
1300                 printdebug " MERGE BA best=".($best_anchor//'-').
1301                     " p=$panchor\n";
1302             }
1303
1304             $mwrecknote->('result-anchor', $best_anchor);
1305
1306             foreach my $p (@$ps) {
1307                 $prline->(" VanillaMerge ".$p->{Ix});
1308                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1309                     $nomerge->('divergent anchors');
1310                 } elsif ($p->{Anchor} eq $best_anchor) {
1311                     print $report " SameAnchor" if $report;
1312                 } else {
1313                     print $report " SupersededAnchor" if $report;
1314                 }
1315                 if ($p->{Breakwater} eq $p->{CommitId}) {
1316                     # this parent commit was its own breakwater,
1317                     # ie it is part of the breakwater
1318                     print $report " Breakwater" if $report;
1319                 } else {
1320                     $might_be_in_bw = 0;
1321                 }
1322                 push @bwbcmd, $p->{Breakwater};
1323                 push @ibcmd, $p->{CommitId};
1324             }
1325
1326             if ($ok && $might_be_in_bw) {
1327                 # We could rewrite this to contaion the metadata
1328                 # declaring it to be MergedBreakwaters, but
1329                 # unnecessarily rewriting a merge seems unhelpful.
1330                 $prline->(" VanillaMerge MergedBreakwaters");
1331                 $last_anchor = $best_anchor;
1332                 $build_start->('MergedBreakwaters', $cur);
1333             }
1334
1335             my $bwb = cmdoutput @bwbcmd;
1336
1337             # OK, now we have a breakwater base, but we need the merge
1338             # base for the interchange branch because we need the delta
1339             # queue.
1340             #
1341             # This a the best merge base of our inputs which has the
1342             # breakwater merge base as an ancestor.
1343
1344             my @ibs =
1345                 grep /./,
1346                 split /\n/,
1347                 cmdoutput @ibcmd;
1348
1349             @ibs or confess 'internal error, expected anchor at least ?';
1350
1351             my $ib;
1352             my $ibleaf;
1353             foreach my $tibix (0..$#ibs) {
1354                 my $tib = $ibs[$tibix];
1355                 my $ff = is_fast_fwd $bwb, $tib;
1356                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1357                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1358                 $mwrecknote->($tibleaf, $tib);
1359                 next unless $ff;
1360                 next if $ib;
1361                 $ib = $tib;
1362                 $ibleaf = $tibleaf;
1363             }
1364
1365             $ib or $nomerge->("no suitable interchange merge base");
1366
1367             $prline->("  VanillaMerge Base");
1368             $prprdelim->();
1369             my ($btip, $bbw, $banchor) = eval {
1370                 walk $ib, 0, $report, $report_lprefix.'  ';
1371             };
1372             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1373                        $@)
1374                 if length $@;
1375
1376             $mwrecknote->("mergebase-laundered", $btip);
1377             $mwrecknote->("mergebase-breakwater", $bbw);
1378             $mwrecknote->("mergebase-anchor", $banchor);
1379
1380             my $ibinfo = { SeriesTip => $btip,
1381                            SeriesBase => $bbw,
1382                            Anchor => $banchor,
1383                            LeftRight => 'mergebase' };
1384
1385             $bbw eq $bwb
1386                 or $nomerge->("interchange merge-base ($ib)'s".
1387                               " breakwater ($bbw)".
1388                               " != breakwaters' merge-base ($bwb)");
1389
1390             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1391                  or $nomerge->("interchange merge-base ($ib)'s".
1392                                " anchor ($ibinfo->{SeriesBase})".
1393                                " != any merge input's anchor (".
1394                                (join ' ', map { $_->{Anchor} } @$ps).
1395                                ")");
1396
1397             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1398             $cl->{MergeBestAnchor} = $best_anchor;
1399             push @brw_cl, {
1400                 %$cl,
1401                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1402                 $xmsg->('constructed from vanilla merge',
1403                         ' merged-breakwater'),
1404             };
1405             push @upp_cl, {
1406                 %$cl,
1407                 SpecialMethod => 'MergeMergeSeries',
1408             };
1409             $build_start->('MergeBreakwaters', $cur);
1410         } else {
1411             printdebug "*** WALK BOMB unrecognised\n";
1412             return $bomb->();
1413         }
1414     }
1415     $prprdelim->();
1416
1417     printdebug "*** WALK prep done cur=$cur".
1418         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1419
1420     return if $nogenerate;
1421
1422     # Now we build it back up again
1423
1424     fresh_workarea();
1425
1426     my $rewriting = 0;
1427
1428     $#upp_cl = $upp_limit if defined $upp_limit;
1429
1430     my $committer_authline = calculate_committer_authline();
1431
1432     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1433
1434     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1435
1436     in_workarea sub {
1437         mkdir $rd or $!==EEXIST or die $!;
1438         my $current_method;
1439         my $want_debian = $build;
1440         my $want_upstream = $build;
1441
1442         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1443         my $read_tree_debian = sub { ($want_debian) = @_; };
1444
1445         foreach my $cl (qw(Debian), (reverse @brw_cl),
1446                         { SpecialMethod => 'RecordBreakwaterTip' },
1447                         qw(Upstream), (reverse @upp_cl)) {
1448             if (!ref $cl) {
1449                 $current_method = $cl;
1450                 next;
1451             }
1452             my $method = $cl->{SpecialMethod} // $current_method;
1453             my @parents = ($build);
1454             my $cltree = $cl->{CommitId};
1455             printdebug "WALK BUILD ".($cltree//'undef').
1456                 " $method (rewriting=$rewriting)\n";
1457             if ($method eq 'Debian') {
1458                 $read_tree_debian->($cltree);
1459             } elsif ($method eq 'Upstream') {
1460                 $read_tree_upstream->($cltree);
1461             } elsif ($method eq 'StartRewrite') {
1462                 $rewriting = 1;
1463                 next;
1464             } elsif ($method eq 'RecordBreakwaterTip') {
1465                 $breakwater = $build;
1466                 next;
1467             } elsif ($method eq 'DgitImportDebianUpdate') {
1468                 $read_tree_debian->($cltree);
1469             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1470                 confess unless $rewriting;
1471                 my $differs = (get_differs $build, $cltree);
1472                 next unless $differs & D_UPS;
1473                 $read_tree_upstream->($cltree);
1474                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1475             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1476                 print "Found a general merge, will try to tidy it up.\n";
1477                 $rewriting = 1;
1478                 $read_tree_upstream->($cl->{MergeBestAnchor});
1479                 $read_tree_debian->($cltree);
1480                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1481             } elsif ($method eq 'MergeMergeSeries') {
1482                 my $cachehit = reflog_cache_lookup
1483                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1484                 if ($cachehit) {
1485                     print "Using supplied resolution for $cl->{CommitId}...\n";
1486                     $build = $cachehit;
1487                     $mwrecknote->('cached-resolution', $build);
1488                 } else {
1489                     print "Running merge resolution for $cl->{CommitId}...\n";
1490                     $mwrecknote->('new-base', $build);
1491                     $build = merge_series
1492                         $build, $cl->{MergeWreckNotes},
1493                         $cl->{MergeInterchangeBaseInfo},
1494                         @{ $cl->{Parents} };
1495                 }
1496                 $last_anchor = $cl->{MergeBestAnchor};
1497
1498                 # Check for mismerges:
1499                 my $check = sub {
1500                     my ($against, $allow, $what) = @_;
1501                     my $differs = get_differs $build, $against;
1502                     $nomerge->(sprintf
1503        "merge misresolved: %s are not the same (%s %s d.%#x)",
1504                                $what, $against, $build, $differs)
1505                         if $differs & ~($allow | D_PAT_ADD);
1506                 };
1507
1508                 # Breakwater changes which were in each side of the
1509                 # merge will have been incorporated into the
1510                 # MergeCreateMergedBreakwaters output.  Because the
1511                 # upstream series was rebased onto the new breakwater,
1512                 # so should all of the packaging changes which were in
1513                 # the input.
1514                 $check->($input, D_UPS, 'debian files');
1515
1516                 # Upstream files are merge_series, which ought to
1517                 # have been identical to the original merge.
1518                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1519
1520                 print "Merge resolution successful.\n";
1521                 next;
1522             } else {
1523                 confess "$method ?";
1524             }
1525             if (!$rewriting) {
1526                 my $procd = (pop @processed) // 'UNDEF';
1527                 if ($cl ne $procd) {
1528                     $rewriting = 1;
1529                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1530                 }
1531             }
1532             if ($rewriting || $opt_careful) {
1533                 read_tree_upstream $want_upstream, 0, $want_debian;
1534
1535                 my $newtree = cmdoutput @git, qw(write-tree);
1536                 my $ch = $cl->{Hdr};
1537                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1538                 $ch =~ s{^parent .*\n}{}mg;
1539                 $ch =~ s{(?=^author)}{
1540                     join '', map { "parent $_\n" } @parents
1541                 }me or confess "$ch ?";
1542                 if ($rewriting) {
1543                     $ch =~ s{^committer .*$}{$committer_authline}m
1544                         or confess "$ch ?";
1545                 }
1546                 my $cf = "$rd/m$rewriting";
1547                 open CD, ">", $cf or die $!;
1548                 print CD $ch, "\n", $cl->{Msg} or die $!;
1549                 close CD or die $!;
1550                 my @cmd = (@git, qw(hash-object));
1551                 push @cmd, qw(-w) if $rewriting;
1552                 push @cmd, qw(-t commit), $cf;
1553                 my $newcommit = cmdoutput @cmd;
1554                 confess "$ch ?" unless $rewriting
1555                     or $newcommit eq $cl->{CommitId};
1556                 $build = $newcommit;
1557             } else {
1558                 $build = $cl->{CommitId};
1559             }
1560             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1561                 $last_anchor = $cur;
1562             }
1563         }
1564     };
1565
1566     my $final_check = get_differs $build, $input;
1567     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1568         if $final_check & ~D_PAT_ADD;
1569
1570     my @r = ($build, $breakwater, $last_anchor);
1571     printdebug "*** WALK RETURN @r\n";
1572     return @r
1573 }
1574
1575 sub get_head () {
1576     git_check_unmodified();
1577     return git_rev_parse qw(HEAD);
1578 }
1579
1580 sub update_head ($$$) {
1581     my ($old, $new, $mrest) = @_;
1582     push @deferred_updates, "update HEAD $new $old";
1583     run_deferred_updates $mrest;
1584 }
1585
1586 sub update_head_checkout ($$$) {
1587     my ($old, $new, $mrest) = @_;
1588     update_head $old, $new, $mrest;
1589     runcmd @git, qw(reset --hard);
1590 }
1591
1592 sub update_head_postlaunder ($$$) {
1593     my ($old, $tip, $reflogmsg) = @_;
1594     return if $tip eq $old;
1595     print "git-debrebase: laundered (head was $old)\n";
1596     update_head $old, $tip, $reflogmsg;
1597     # no tree changes except debian/patches
1598     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1599 }
1600
1601 sub currently_rebasing() {
1602     foreach (qw(rebase-merge rebase-apply)) {
1603         return 1 if stat_exists "$maindir_gitdir/$_";
1604     }
1605     return 0;
1606 }
1607
1608 sub bail_if_rebasing() {
1609     fail "you are in the middle of a git-rebase already"
1610         if currently_rebasing();
1611 }
1612
1613 sub do_launder_head ($) {
1614     my ($reflogmsg) = @_;
1615     my $old = get_head();
1616     record_ffq_auto();
1617     my ($tip,$breakwater) = walk $old;
1618     snags_maybe_bail();
1619     update_head_postlaunder $old, $tip, $reflogmsg;
1620     return ($tip,$breakwater);
1621 }
1622
1623 sub cmd_launder_v0 () {
1624     badusage "no arguments to launder-v0 allowed" if @ARGV;
1625     my $old = get_head();
1626     my ($tip,$breakwater,$last_anchor) = walk $old;
1627     update_head_postlaunder $old, $tip, 'launder';
1628     printf "# breakwater tip\n%s\n", $breakwater;
1629     printf "# working tip\n%s\n", $tip;
1630     printf "# last anchor\n%s\n", $last_anchor;
1631 }
1632
1633 sub defaultcmd_rebase () {
1634     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1635     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1636     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1637 }
1638
1639 sub cmd_analyse () {
1640     badusage "analyse does not support any options"
1641         if @ARGV and $ARGV[0] =~ m/^-/;
1642     badusage "too many arguments to analyse" if @ARGV>1;
1643     my ($old) = @ARGV;
1644     if (defined $old) {
1645         $old = git_rev_parse $old;
1646     } else {
1647         $old = git_rev_parse 'HEAD';
1648     }
1649     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1650     STDOUT->error and die $!;
1651 }
1652
1653 sub ffq_prev_branchinfo () {
1654     my $current = git_get_symref();
1655     return gdr_ffq_prev_branchinfo($current);
1656 }
1657
1658 sub ffq_check ($;$$) {
1659     # calls $ff and/or $notff zero or more times
1660     # then returns either (status,message) where status is
1661     #    exists
1662     #    detached
1663     #    weird-symref
1664     #    notbranch
1665     # or (undef,undef, $ffq_prev,$gdrlast)
1666     # $ff and $notff are called like this:
1667     #   $ff->("message for stdout\n");
1668     #   $notff->('snag-name', $message);
1669     # normally $currentval should be HEAD
1670     my ($currentval, $ff, $notff) =@_;
1671
1672     $ff //= sub { print $_[0] or die $!; };
1673     $notff //= \&snag;
1674
1675     my ($status, $message, $current, $ffq_prev, $gdrlast)
1676         = ffq_prev_branchinfo();
1677     return ($status, $message) unless $status eq 'branch';
1678
1679     my $exists = git_get_ref $ffq_prev;
1680     return ('exists',"$ffq_prev already exists") if $exists;
1681
1682     return ('not-branch', 'HEAD symref is not to refs/heads/')
1683         unless $current =~ m{^refs/heads/};
1684     my $branch = $';
1685
1686     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1687     my %checked;
1688
1689     printdebug "ffq check_specs @check_specs\n";
1690
1691     my $check = sub {
1692         my ($lrref, $desc) = @_;
1693         printdebug "ffq might check $lrref ($desc)\n";
1694         my $invert;
1695         for my $chk (@check_specs) {
1696             my $glob = $chk;
1697             $invert = $glob =~ s{^[!^]}{};
1698             last if fnmatch $glob, $lrref;
1699         }
1700         return if $invert;
1701         my $lrval = git_get_ref $lrref;
1702         return unless length $lrval;
1703
1704         if (is_fast_fwd $lrval, $currentval) {
1705             $ff->("OK, you are ahead of $lrref\n");
1706             $checked{$lrref} = 1;
1707         } elsif (is_fast_fwd $currentval, $lrval) {
1708             $checked{$lrref} = -1;
1709             $notff->('behind', "you are behind $lrref, divergence risk");
1710         } else {
1711             $checked{$lrref} = -1;
1712             $notff->('diverged', "you have diverged from $lrref");
1713         }
1714     };
1715
1716     my $merge = cfg "branch.$branch.merge",1;
1717     if (defined $merge and $merge =~ m{^refs/heads/}) {
1718         my $rhs = $';
1719         printdebug "ffq merge $rhs\n";
1720         my $check_remote = sub {
1721             my ($remote, $desc) = @_;
1722             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1723             return unless defined $remote;
1724             $check->("refs/remotes/$remote/$rhs", $desc);
1725         };
1726         $check_remote->((scalar cfg "branch.$branch.remote",1),
1727                         'remote fetch/merge branch');
1728         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1729                         (scalar cfg "branch.$branch.pushDefault",1),
1730                         'remote push branch');
1731     }
1732     if ($branch =~ m{^dgit/}) {
1733         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1734     } elsif ($branch =~ m{^master$}) {
1735         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1736     }
1737     return (undef, undef, $ffq_prev, $gdrlast);
1738 }
1739
1740 sub record_ffq_prev_deferred () {
1741     # => ('status', "message")
1742     # 'status' may be
1743     #    deferred          message is undef
1744     #    exists
1745     #    detached
1746     #    weird-symref
1747     #    notbranch
1748     # if not ff from some branch we should be ff from, is an snag
1749     # if "deferred", will have added something about that to
1750     #   @deferred_update_messages, and also maybe printed (already)
1751     #   some messages about ff checks
1752     bail_if_rebasing();
1753     my $currentval = get_head();
1754
1755     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1756     return ($status,$message) if defined $status;
1757
1758     snags_maybe_bail();
1759
1760     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1761     push @deferred_updates, "delete $gdrlast";
1762     push @deferred_update_messages, "Recorded previous head for preservation";
1763     return ('deferred', undef);
1764 }
1765
1766 sub record_ffq_auto () {
1767     my ($status, $message) = record_ffq_prev_deferred();
1768     if ($status eq 'deferred' || $status eq 'exists') {
1769     } else {
1770         snag $status, "could not record ffq-prev: $message";
1771         snags_maybe_bail();
1772     }
1773 }
1774
1775 sub ffq_prev_info () {
1776     bail_if_rebasing();
1777     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1778     my ($status, $message, $current, $ffq_prev, $gdrlast)
1779         = ffq_prev_branchinfo();
1780     if ($status ne 'branch') {
1781         snag $status, "could not check ffq-prev: $message";
1782         snags_maybe_bail();
1783     }
1784     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1785     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1786 }
1787
1788 sub stitch ($$$$$) {
1789     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1790
1791     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1792
1793     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1794         my $differs = get_differs $old_head, $ffq_prev_commitish;
1795         unless ($differs & ~D_PAT_ADD) {
1796             # ffq-prev is ahead of us, and the only tree changes it has
1797             # are possibly addition of things in debian/patches/.
1798             # Just wind forwards rather than making a pointless pseudomerge.
1799             push @deferred_updates,
1800                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1801             update_head_checkout $old_head, $ffq_prev_commitish,
1802                 "stitch (fast forward)";
1803             return;
1804         }
1805     }
1806     fresh_workarea();
1807     # We make pseudomerges with L as the contributing parent.
1808     # This makes git rev-list --first-parent work properly.
1809     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1810         'Declare fast forward / record previous work',
1811         "[git-debrebase pseudomerge: $prose]",
1812     ];
1813     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1814     update_head $old_head, $new_head, "stitch: $prose";
1815 }
1816
1817 sub do_stitch ($;$) {
1818     my ($prose, $unclean) = @_;
1819
1820     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1821     if (!$ffq_prev_commitish) {
1822         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1823         return;
1824     }
1825     my $dangling_head = get_head();
1826
1827     keycommits $dangling_head, $unclean,$unclean,$unclean;
1828     snags_maybe_bail();
1829
1830     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1831 }
1832
1833 sub upstream_commitish_search ($$) {
1834     my ($upstream_version, $tried) = @_;
1835     # todo: at some point maybe use git-deborig to do this
1836     foreach my $tagpfx ('', 'v', 'upstream/') {
1837         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1838         my $new_upstream = git_get_ref "refs/tags/$tag";
1839         push @$tried, $tag;
1840         return $new_upstream if length $new_upstream;
1841     }
1842 }
1843
1844 sub resolve_upstream_version ($$) {
1845     my ($new_upstream, $upstream_version) = @_;
1846
1847     if (!defined $new_upstream) {
1848         my @tried;
1849         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1850         if (!length $new_upstream) {
1851             fail "Could not determine appropriate upstream commitish.\n".
1852                 " (Tried these tags: @tried)\n".
1853                 " Check version, and specify upstream commitish explicitly.";
1854         }
1855     }
1856     $new_upstream = git_rev_parse $new_upstream;
1857
1858     return $new_upstream;
1859 }
1860
1861 sub cmd_new_upstream () {
1862     # automatically and unconditionally launders before rebasing
1863     # if rebase --abort is used, laundering has still been done
1864
1865     my %pieces;
1866
1867     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1868
1869     # parse args - low commitment
1870     my $spec_version = shift @ARGV;
1871     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1872     fail "bad version number \`$spec_version'" unless defined $new_version;
1873     if ($new_version->is_native()) {
1874         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1875     }
1876
1877     my $new_upstream = shift @ARGV;
1878     my $new_upstream_version = upstreamversion  $new_version;
1879     $new_upstream =
1880         resolve_upstream_version $new_upstream, $new_upstream_version;
1881
1882     record_ffq_auto();
1883
1884     my $piece = sub {
1885         my ($n, @x) = @_; # may be ''
1886         my $pc = $pieces{$n} //= {
1887             Name => $n,
1888             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1889         };
1890         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1891         $pc;
1892     };
1893
1894     my @newpieces;
1895     my $newpiece = sub {
1896         my ($n, @x) = @_; # may be ''
1897         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1898         push @newpieces, $pc;
1899     };
1900
1901     $newpiece->('',
1902         OldIx => 0,
1903         New => $new_upstream,
1904     );
1905     while (@ARGV && $ARGV[0] !~ m{^-}) {
1906         my $n = shift @ARGV;
1907
1908         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1909             unless @ARGV && $ARGV[0] !~ m{^-};
1910
1911         my $c = git_rev_parse shift @ARGV;
1912         die unless $n =~ m/^$extra_orig_namepart_re$/;
1913         $newpiece->($n, New => $c);
1914     }
1915
1916     # now we need to investigate the branch this generates the
1917     # laundered version but we don't switch to it yet
1918     my $old_head = get_head();
1919     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1920
1921     my $old_bw_cl = classify $old_bw;
1922     my $old_anchor_cl = classify $old_anchor;
1923     my $old_upstream;
1924     if (!$old_anchor_cl->{OrigParents}) {
1925         snag 'anchor-treated',
1926             'old anchor is recognised due to --anchor, cannot check upstream';
1927     } else {
1928         $old_upstream = parsecommit
1929             $old_anchor_cl->{OrigParents}[0]{CommitId};
1930         $piece->('', Old => $old_upstream->{CommitId});
1931     }
1932
1933     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1934         if ($old_upstream->{Msg} =~
1935  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1936            ) {
1937             my @oldpieces = (split / /, $1);
1938             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1939             if ($old_n_parents != @oldpieces &&
1940                 $old_n_parents != @oldpieces + 1) {
1941                 snag 'upstream-confusing', sprintf
1942                     "previous upstream combine %s".
1943                     " mentions %d pieces (each implying one parent)".
1944                     " but has %d parents".
1945                     " (one per piece plus maybe a previous combine)",
1946                     $old_upstream->{CommitId},
1947                     (scalar @oldpieces),
1948                     $old_n_parents;
1949             } elsif ($oldpieces[0] ne '.') {
1950                 snag 'upstream-confusing', sprintf
1951                     "previous upstream combine %s".
1952                     " first piece is not \`.'",
1953                     $oldpieces[0];
1954             } else {
1955                 $oldpieces[0] = '';
1956                 foreach my $i (0..$#oldpieces) {
1957                     my $n = $oldpieces[$i];
1958                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1959                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1960                 }
1961             }
1962         } else {
1963             snag 'upstream-confusing',
1964                 "previous upstream $old_upstream->{CommitId} is from".
1965                " git-debrebase but not an \`upstream-combine' commit";
1966         }
1967     }
1968
1969     foreach my $pc (values %pieces) {
1970         if (!$old_upstream) {
1971             # we have complained already
1972         } elsif (!$pc->{Old}) {
1973             snag 'upstream-new-piece',
1974                 "introducing upstream piece \`$pc->{Name}'";
1975         } elsif (!$pc->{New}) {
1976             snag 'upstream-rm-piece',
1977                 "dropping upstream piece \`$pc->{Name}'";
1978         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1979             snag 'upstream-not-ff',
1980                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1981         }
1982     }
1983
1984     printdebug "%pieces = ", (dd \%pieces), "\n";
1985     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1986
1987     snags_maybe_bail();
1988
1989     my $new_bw;
1990
1991     fresh_workarea();
1992     in_workarea sub {
1993         my @upstream_merge_parents;
1994
1995         if (!any_snags()) {
1996             push @upstream_merge_parents, $old_upstream->{CommitId};
1997         }
1998
1999         foreach my $pc (@newpieces) { # always has '' first
2000             if ($pc->{Name}) {
2001                 read_tree_subdir $pc->{Name}, $pc->{New};
2002             } else {
2003                 runcmd @git, qw(read-tree), $pc->{New};
2004             }
2005             push @upstream_merge_parents, $pc->{New};
2006         }
2007
2008         # index now contains the new upstream
2009
2010         if (@newpieces > 1) {
2011             # need to make the upstream subtree merge commit
2012             $new_upstream = make_commit \@upstream_merge_parents,
2013                 [ "Combine upstreams for $new_upstream_version",
2014  ("[git-debrebase upstream-combine . ".
2015  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2016  ": new upstream]"),
2017                 ];
2018         }
2019
2020         # $new_upstream is either the single upstream commit, or the
2021         # combined commit we just made.  Either way it will be the
2022         # "upstream" parent of the anchor merge.
2023
2024         read_tree_subdir 'debian', "$old_bw:debian";
2025
2026         # index now contains the anchor merge contents
2027         $new_bw = make_commit [ $old_bw, $new_upstream ],
2028             [ "Update to upstream $new_upstream_version",
2029  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2030             ];
2031
2032         my $clogsignoff = cmdoutput qw(git show),
2033             '--pretty=format:%an <%ae>  %aD',
2034             $new_bw;
2035
2036         # Now we have to add a changelog stanza so the Debian version
2037         # is right.
2038         die if unlink "debian";
2039         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2040         unlink "debian/changelog" or $!==ENOENT or die $!;
2041         mkdir "debian" or die $!;
2042         open CN, ">", "debian/changelog" or die $!;
2043         my $oldclog = git_cat_file ":debian/changelog";
2044         $oldclog =~ m/^($package_re) \(\S+\) / or
2045             fail "cannot parse old changelog to get package name";
2046         my $p = $1;
2047         print CN <<END, $oldclog or die $!;
2048 $p ($new_version) UNRELEASED; urgency=medium
2049
2050   * Update to new upstream version $new_upstream_version.
2051
2052  -- $clogsignoff
2053
2054 END
2055         close CN or die $!;
2056         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2057
2058         # Now we have the final new breakwater branch in the index
2059         $new_bw = make_commit [ $new_bw ],
2060             [ "Update changelog for new upstream $new_upstream_version",
2061               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2062             ];
2063     };
2064
2065     # we have constructed the new breakwater. we now need to commit to
2066     # the laundering output, because git-rebase can't easily be made
2067     # to make a replay list which is based on some other branch
2068
2069     update_head_postlaunder $old_head, $old_laundered_tip,
2070         'launder for new upstream';
2071
2072     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2073     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2074         "debrebase new-upstream $new_version: rebase";
2075     runcmd @cmd;
2076     # now it's for the user to sort out
2077 }
2078
2079 sub cmd_record_ffq_prev () {
2080     badusage "no arguments allowed" if @ARGV;
2081     my ($status, $msg) = record_ffq_prev_deferred();
2082     if ($status eq 'exists' && $opt_noop_ok) {
2083         print "Previous head already recorded\n" or die $!;
2084     } elsif ($status eq 'deferred') {
2085         run_deferred_updates 'record-ffq-prev';
2086     } else {
2087         fail "Could not preserve: $msg";
2088     }
2089 }
2090
2091 sub cmd_anchor () {
2092     badusage "no arguments allowed" if @ARGV;
2093     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2094     print "$bw\n" or die $!;
2095 }
2096
2097 sub cmd_breakwater () {
2098     badusage "no arguments allowed" if @ARGV;
2099     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2100     print "$bw\n" or die $!;
2101 }
2102
2103 sub cmd_status () {
2104     badusage "no arguments allowed" if @ARGV;
2105
2106     # todo: gdr status should print divergence info
2107     # todo: gdr status should print upstream component(s) info
2108     # todo: gdr should leave/maintain some refs with this kind of info ?
2109
2110     my $oldest = { Badness => 0 };
2111     my $newest;
2112     my $note = sub {
2113         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2114         if ($oldest->{Badness} < $badness) {
2115             $oldest = $newest = undef;
2116         }
2117         $oldest = {
2118                    Badness => $badness,
2119                    CommitId => $cl->{CommitId},
2120                    OurMsg => $ourmsg,
2121                    KcMsg => $kcmsg,
2122                   };
2123         $newest //= $oldest;
2124     };
2125     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2126         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2127         sub { $note->(2, 'branch is unlaundered', @_); },
2128         sub { $note->(3, 'branch needs laundering', @_); },
2129         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2130
2131     my $prcommitinfo = sub {
2132         my ($cid) = @_;
2133         flush STDOUT or die $!;
2134         runcmd @git, qw(--no-pager log -n1),
2135             '--pretty=format:    %h %s%n',
2136             $cid;
2137     };
2138
2139     print "current branch contents, in git-debrebase terms:\n";
2140     if (!$oldest->{Badness}) {
2141         print "  branch is laundered\n";
2142     } else {
2143         print "  $oldest->{OurMsg}\n";
2144         my $printed = '';
2145         foreach my $info ($oldest, $newest) {
2146             my $cid = $info->{CommitId};
2147             next if $cid eq $printed;
2148             $printed = $cid;
2149             print "  $info->{KcMsg}\n";
2150             $prcommitinfo->($cid);
2151         }
2152     }
2153
2154     my $prab = sub {
2155         my ($cid, $what) = @_;
2156         if (!defined $cid) {
2157             print "  $what is not well-defined\n";
2158         } else {
2159             print "  $what\n";
2160             $prcommitinfo->($cid);
2161         }
2162     };
2163     print "key git-debrebase commits:\n";
2164     $prab->($anchor, 'anchor');
2165     $prab->($bw, 'breakwater');
2166
2167     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2168         ffq_prev_branchinfo();
2169
2170     print "branch and ref status, in git-debrebase terms:\n";
2171     if ($ffq_msg) {
2172         print "  $ffq_msg\n";
2173     } else {
2174         $ffq_prev = git_get_ref $ffq_prev;
2175         $gdrlast = git_get_ref $gdrlast;
2176         if ($ffq_prev) {
2177             print "  unstitched; previous tip was:\n";
2178             $prcommitinfo->($ffq_prev);
2179         } elsif (!$gdrlast) {
2180             print "  stitched? (no record of git-debrebase work)\n";
2181         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2182             print "  stitched\n";
2183         } else {
2184             print "  not git-debrebase (diverged since last stitch)\n"
2185         }
2186     }
2187     print "you are currently rebasing\n" if currently_rebasing();
2188 }
2189
2190 sub cmd_stitch () {
2191     my $prose = 'stitch';
2192     getoptions("stitch",
2193                'prose=s', \$prose);
2194     badusage "no arguments allowed" if @ARGV;
2195     do_stitch $prose, 0;
2196 }
2197 sub cmd_prepush () { cmd_stitch(); }
2198
2199 sub cmd_quick () {
2200     badusage "no arguments allowed" if @ARGV;
2201     do_launder_head 'launder for git-debrebase quick';
2202     do_stitch 'quick';
2203 }
2204
2205 sub cmd_conclude () {
2206     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2207     if (!$ffq_prev_commitish) {
2208         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2209         return;
2210     }
2211     my $dangling_head = get_head();
2212
2213     badusage "no arguments allowed" if @ARGV;
2214     do_launder_head 'launder for git-debrebase quick';
2215     do_stitch 'quick';
2216 }
2217
2218 sub cmd_scrap () {
2219     if (currently_rebasing()) {
2220         runcmd @git, qw(rebase --abort);
2221         push @deferred_updates, 'verify HEAD HEAD';
2222         # noop, but stops us complaining that scrap was a noop
2223     }
2224     badusage "no arguments allowed" if @ARGV;
2225     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2226     my $scrapping_head;
2227     if ($ffq_prev_commitish) {
2228         $scrapping_head = get_head();
2229         push @deferred_updates,
2230             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2231             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2232     }
2233     if (git_get_ref $merge_cache_ref) {
2234         push @deferred_updates,
2235             "delete $merge_cache_ref";
2236     }
2237     if (!@deferred_updates) {
2238         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2239         finish 0;
2240     }
2241     snags_maybe_bail();
2242     if ($scrapping_head) {
2243         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2244     } else {
2245         run_deferred_updates "scrap";
2246     }
2247 }
2248
2249 sub make_patches_staged ($) {
2250     my ($head) = @_;
2251     # Produces the patches that would result from $head if it were
2252     # laundered.
2253     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2254     fresh_workarea();
2255     in_workarea sub {
2256         gbp_pq_export 'bw', $secret_bw, $secret_head;
2257     };
2258 }
2259
2260 sub make_patches ($) {
2261     my ($head) = @_;
2262     keycommits $head, 0, \&snag;
2263     make_patches_staged $head;
2264     my $out;
2265     in_workarea sub {
2266         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2267         runcmd @git, qw(read-tree), $head;
2268         read_tree_subdir 'debian/patches', $ptree;
2269         $out = make_commit [$head], [
2270             'Commit patch queue (exported by git-debrebase)',
2271             '[git-debrebase: export and commit patches]',
2272         ];
2273     };
2274     return $out;
2275 }
2276
2277 sub cmd_make_patches () {
2278     my $opt_quiet_would_amend;
2279     getoptions("make-patches",
2280                'quiet-would-amend!', \$opt_quiet_would_amend);
2281     badusage "no arguments allowed" if @ARGV;
2282     bail_if_rebasing();
2283     my $old_head = get_head();
2284     my $new = make_patches $old_head;
2285     my $d = get_differs $old_head, $new;
2286     if ($d == 0) {
2287         fail "No (more) patches to export." unless $opt_noop_ok;
2288         return;
2289     } elsif ($d == D_PAT_ADD) {
2290         snags_maybe_bail();
2291         update_head_checkout $old_head, $new, 'make-patches';
2292     } else {
2293         print STDERR failmsg
2294             "Patch export produced patch amendments".
2295             " (abandoned output commit $new).".
2296             "  Try laundering first."
2297             unless $opt_quiet_would_amend;
2298         finish 7;
2299     }
2300 }
2301
2302 sub cmd_convert_from_gbp () {
2303     badusage "want only 1 optional argument, the upstream git commitish"
2304         unless @ARGV<=1;
2305
2306     my $clogp = parsechangelog();
2307     my $version = $clogp->{'Version'}
2308         // die "missing Version from changelog";
2309
2310     my ($upstream_spec) = @ARGV;
2311
2312     my $upstream_version = upstreamversion $version;
2313     my $upstream =
2314         resolve_upstream_version($upstream_spec, $upstream_version);
2315
2316     my $old_head = get_head();
2317
2318     my $upsdiff = get_differs $upstream, $old_head;
2319     if ($upsdiff & D_UPS) {
2320         runcmd @git, qw(--no-pager diff --stat),
2321             $upstream, $old_head,
2322             qw( -- :!/debian :/);
2323         fail <<END;
2324 upstream ($upstream_spec) and HEAD are not
2325 identical in upstream files.  See diffstat above, or run
2326   git diff $upstream_spec HEAD -- :!/debian :/
2327 END
2328     }
2329
2330     if (!is_fast_fwd $upstream, $old_head) {
2331         snag 'upstream-not-ancestor',
2332             "upstream ($upstream) is not an ancestor of HEAD";
2333     } else {
2334         my $wrong = cmdoutput
2335             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2336              qw(-- :/ :!/debian));
2337         if (length $wrong) {
2338             snag 'unexpected-upstream-changes',
2339                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2340             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2341         }
2342     }
2343
2344     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2345         snag 'upstream-has-debian',
2346             "upstream ($upstream) contains debian/ directory";
2347     }
2348
2349     my $previous_dgit_view = eval {
2350         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2351         my ($lvsn, $suite);
2352         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2353             my ($stz, $desc) = @_;
2354             no warnings qw(exiting);
2355             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2356             next unless $stz->{Date};
2357             next unless $stz->{Distribution} ne 'UNRELEASED';
2358             $lvsn = $stz->{Version};
2359             $suite = $stz->{Distribution};
2360             last;
2361         };
2362         die "neither of the first two changelog entries are released\n"
2363             unless defined $lvsn;
2364         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2365         my $mtag_pat = debiantag_maintview $lvsn, '*';
2366         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2367             $mtag_pat;
2368         die "could not find suitable maintainer view tag $mtag_pat\n"
2369             unless $mtag_pat =~ m{/};
2370         is_fast_fwd $mtag, 'HEAD' or
2371             die "HEAD is not FF from maintainer tag $mtag!";
2372         my $dtag = "archive/$mtag";
2373         is_fast_fwd $mtag, $dtag or
2374             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2375         print "will stitch in dgit view, $dtag\n";
2376         git_rev_parse $dtag;
2377     };
2378     if (!$previous_dgit_view) {
2379         $@ =~ s/^\n+//;
2380         chomp $@;
2381         print STDERR "cannot stitch in dgit view: $@\n";
2382     }
2383
2384     snags_maybe_bail_early();
2385
2386     my $work;
2387
2388     fresh_workarea();
2389     in_workarea sub {
2390         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2391         # make a branch out of the patch queue - we'll want this in a mo
2392         runcmd qw(gbp pq import);
2393         # strip the patches out
2394         runcmd @git, qw(checkout -q gdr-internal~0);
2395         rm_subdir_cached 'debian/patches';
2396         $work = make_commit ['HEAD'], [
2397  'git-debrebase convert-from-gbp: drop patches from tree',
2398  'Delete debian/patches, as part of converting to git-debrebase format.',
2399  '[git-debrebase convert-from-gbp: drop patches from tree]'
2400                               ];
2401         # make the anchor merge
2402         # the tree is already exactly right
2403         $work = make_commit [$work, $upstream], [
2404  'git-debrebase import: declare upstream',
2405  'First breakwater merge.',
2406  '[git-debrebase anchor: declare upstream]'
2407                               ];
2408
2409         # rebase the patch queue onto the new breakwater
2410         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2411         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2412         $work = git_rev_parse 'HEAD';
2413
2414         if ($previous_dgit_view) {
2415             $work = make_commit [$work, $previous_dgit_view], [
2416  'git-debrebase import: declare ff from dgit archive view',
2417  '[git-debrebase pseudomerge: import-from-gbp]',
2418             ];
2419         }
2420     };
2421
2422     ffq_check $work;
2423     snags_maybe_bail();
2424     update_head_checkout $old_head, $work, 'convert-from-gbp';
2425 }
2426
2427 sub cmd_convert_to_gbp () {
2428     badusage "no arguments allowed" if @ARGV;
2429     my $head = get_head();
2430     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2431     keycommits $head, 0;
2432     my $out;
2433     make_patches_staged $head;
2434     in_workarea sub {
2435         $out = make_commit ['HEAD'], [
2436             'Commit patch queue (converted from git-debrebase format)',
2437             '[git-debrebase convert-to-gbp: commit patches]',
2438         ];
2439     };
2440     if (defined $ffq) {
2441         push @deferred_updates, "delete $ffq";
2442         push @deferred_updates, "delete $gdrlast";
2443     }
2444     snags_maybe_bail();
2445     update_head_checkout $head, $out, "convert to gbp (v0)";
2446     print <<END or die $!;
2447 git-debrebase: converted to git-buildpackage branch format
2448 git-debrebase: WARNING: do not now run "git-debrebase" any more
2449 git-debrebase: WARNING: doing so would drop all upstream patches!
2450 END
2451 }
2452
2453 sub cmd_convert_from_dgit_view () {
2454     my $clogp = parsechangelog();
2455
2456     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2457     my $do_origs = 1;
2458     my $do_tags = 1;
2459     my $always = 0;
2460     my $diagnose = 0;
2461
2462     getoptions("convert-from-dgit-view",
2463                'diagnose!', \$diagnose,
2464                'build-products-dir:s', \$bpd,
2465                'origs!', \$do_origs,
2466                'tags!', \$do_tags,
2467                'always-convert-anyway!', \$always);
2468     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2469
2470     my @upstreams;
2471
2472     if (@ARGV) {
2473         my $spec = shift @ARGV;
2474         my $commit = git_rev_parse "$spec^{commit}";
2475         push @upstreams, { Commit => $commit,
2476                            Source => "$ARGV[0], from command line",
2477                            Only => 1,
2478                          };
2479     }
2480
2481     my $head = get_head();
2482
2483     if (!$always) {
2484         my $troubles = 0;
2485         my $trouble = sub { $troubles++; };
2486         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2487         printdebug "troubles=$troubles\n";
2488         if (!$troubles) {
2489             print STDERR <<END;
2490 $us: Branch already seems to be in git-debrebase format!
2491 $us: --always-convert-anyway would do the conversion operation anyway
2492 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2493 END
2494             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2495             finish 0;
2496         }
2497     }
2498
2499     snags_maybe_bail_early();
2500
2501     my $version = upstreamversion $clogp->{Version};
2502     print STDERR "Considering possible commits corresponding to upstream:\n";
2503
2504     if (!@upstreams) {
2505         if ($do_tags) {
2506             my @tried;
2507             my $ups_tag = upstream_commitish_search $version, \@tried;
2508             if ($ups_tag) {
2509                 my $this = "git tag $tried[-1]";
2510                 push @upstreams, { Commit => $ups_tag,
2511                                    Source => $this,
2512                                  };
2513             } else {
2514                 printf STDERR
2515                     " git tag: no suitable tag found (tried %s)\n",
2516                     "@tried";
2517             }
2518         }
2519         if ($do_origs) {
2520             my $p = $clogp->{'Source'};
2521             # we do a quick check to see if there are plausible origs
2522             my $something=0;
2523             if (!opendir BPD, $bpd) {
2524                 die "$bpd: opendir: $!" unless $!==ENOENT;
2525             } else {
2526                 while ($!=0, my $f = readdir BPD) {
2527                     next unless is_orig_file_of_p_v $f, $p, $version;
2528                     printf STDERR
2529                         " orig: found what looks like a .orig, %s\n",
2530                         "$bpd/$f";
2531                     $something=1;
2532                     last;
2533                 }
2534                 die "read $bpd: $!" if $!;
2535                 closedir BPD;
2536             }
2537             if ($something) {
2538                 my $tree = cmdoutput
2539                     @dgit, qw(--build-products-dir), $bpd,
2540                     qw(print-unapplied-treeish);
2541                 fresh_workarea();
2542                 in_workarea sub {
2543                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2544                     rm_subdir_cached 'debian';
2545                     $tree = cmdoutput @git, qw(write-tree);
2546                     my $ups_synth = make_commit [], [ <<END, <<END,
2547 Import effective orig tree for upstream version $version
2548 END
2549 This includes the contents of the .orig(s), minus any debian/ directory.
2550
2551 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2552 END
2553                                                     ];
2554                     push @upstreams, { Commit => $ups_synth,
2555                                        Source => "orig(s) imported via dgit",
2556                                      };
2557                 }
2558             } else {
2559                 printf STDERR
2560                     " orig: no suitable origs found (looked for %s in %s)\n",
2561                     "${p}_".(stripeoch $version)."...", $bpd;
2562             }
2563         }
2564     }
2565
2566     my $some_patches = stat_exists 'debian/patches/series';
2567
2568     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2569
2570     my $result;
2571     foreach my $u (@upstreams) {
2572         my $work = $head;
2573         fresh_workarea();
2574         in_workarea sub {
2575             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2576             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2577             runcmd @git, qw(clean -xdff);
2578             runcmd @git, qw(checkout), $head, qw(-- debian);
2579             if ($some_patches) {
2580                 rm_subdir_cached 'debian/patches';
2581                 $work = make_commit [ $work ], [
2582  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2583  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2584  "to git-debrebase format.  Upstream changes will appear as commits.",
2585  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2586                                            ];
2587             }
2588             $work = make_commit [ $work, $u->{Commit} ], [
2589  'git-debrebase convert-from-dgit-view: declare upstream',
2590  '(Re)constructed breakwater merge.',
2591  '[git-debrebase anchor: declare upstream]'
2592                                                          ];
2593             runcmd @git, qw(checkout --quiet -b mk), $work;
2594             if ($some_patches) {
2595                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2596                 runcmd @git, qw(reset --quiet);
2597                 my @gbp_cmd = (qw(gbp pq import));
2598                 if (!$diagnose) {
2599                     my $gbp_err = "../gbp-pq-err";
2600                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2601                 }
2602                 my $r = system @gbp_cmd;
2603                 if ($r) {
2604                     printf STDERR
2605                         " %s: couldn't apply patches: gbp pq %s",
2606                         $u->{Source}, waitstatusmsg();
2607                     return;
2608                 }
2609             }
2610             my $work = git_rev_parse qw(HEAD);
2611             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2612             if (length $diffout) {
2613                 print STDERR
2614                     " $u->{Source}: applying patches gives different tree\n";
2615                 print STDERR $diffout if $diagnose;
2616                 return;
2617             }
2618             # OMG!
2619             $u->{Result} = $work;
2620             $result = $u;
2621         };
2622         last if $result;
2623     }
2624
2625     if (!$result) {
2626         fail <<END;
2627 Could not find or construct a suitable upstream commit.
2628 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2629 upstream commmit explicitly or provide suitable origs.
2630 END
2631     }
2632
2633     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2634
2635     ffq_check $result->{Result};
2636     snags_maybe_bail();
2637     update_head_checkout $head, $result->{Result},
2638         'convert-from-dgit-view';
2639 }
2640
2641 sub cmd_record_resolved_merge () {
2642     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2643     # xxx needs documentation
2644     my $new = get_head();
2645     my $method;
2646
2647     print "Checking how you have resolved the merge problem\n";
2648     my $nope = sub { print "Not $method: @_"; 0; };
2649
2650     my $maybe = sub { print "Seems to be $method.\n"; };
2651     my $yes = sub {
2652         my ($key, $ref) = @_;
2653         reflog_cache_insert $merge_cache_ref, $key, $ref;
2654         print "OK.  You can switch branches and try git-debrebase again.\n";
2655         1;
2656     };
2657
2658     fresh_workarea 'merge';
2659     sub {
2660         $method = 'vanilla-merge patchqueue';
2661         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2662         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2663         foreach my $lr (qw(left right)) {
2664             my $n = "$wrecknoteprefix/$lr-patchqueue";
2665             my $lrpq = git_get_ref $n;
2666             $lrpq or return $nope->("wreckage did not contain patchqueues");
2667             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2668         }
2669         $maybe->();
2670         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2671             or die "wreckage element $wrecknoteprefix/new-base missing";
2672         my $result = merge_series_patchqueue_convert
2673             {}, $newbase, $new;
2674         $yes->("vanilla-merge $vanilla", $result);
2675         1;
2676     }->() or sub {
2677         fail "No resolved merge method seems applicable.\n";
2678     }->();
2679 }
2680
2681 sub cmd_downstream_rebase_launder_v0 () {
2682     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2683     my ($base) = @ARGV;
2684     $base = git_rev_parse $base;
2685     my $old_head = get_head();
2686     my $current = $old_head;
2687     my $topmost_keep;
2688     for (;;) {
2689         if ($current eq $base) {
2690             $topmost_keep //= $current;
2691             print " $current BASE stop\n";
2692             last;
2693         }
2694         my $cl = classify $current;
2695         print " $current $cl->{Type}";
2696         my $keep = 0;
2697         my $p0 = $cl->{Parents}[0]{CommitId};
2698         my $next;
2699         if ($cl->{Type} eq 'Pseudomerge') {
2700             print " ^".($cl->{Contributor}{Ix}+1);
2701             $next = $cl->{Contributor}{CommitId};
2702         } elsif ($cl->{Type} eq 'AddPatches' or
2703                  $cl->{Type} eq 'Changelog') {
2704             print " strip";
2705             $next = $p0;
2706         } else {
2707             print " keep";
2708             $next = $p0;
2709             $keep = 1;
2710         }
2711         print "\n";
2712         if ($keep) {
2713             $topmost_keep //= $current;
2714         } else {
2715             die "to-be stripped changes not on top of the branch\n"
2716                 if $topmost_keep;
2717         }
2718         $current = $next;
2719     }
2720     if ($topmost_keep eq $old_head) {
2721         print "unchanged\n";
2722     } else {
2723         print "updating to $topmost_keep\n";
2724         update_head_checkout
2725             $old_head, $topmost_keep,
2726             'downstream-rebase-launder-v0';
2727     }
2728 }
2729
2730 getoptions_main
2731           ("bad options\n",
2732            "D+" => \$debuglevel,
2733            'noop-ok', => \$opt_noop_ok,
2734            'f=s' => \@snag_force_opts,
2735            'anchor=s' => \@opt_anchors,
2736            '--dgit=s' => \($dgit[0]),
2737            'force!',
2738            '-i:s' => sub {
2739                my ($opt,$val) = @_;
2740                badusage "git-debrebase: no cuddling to -i for git-rebase"
2741                    if length $val;
2742                die if $opt_defaultcmd_interactive; # should not happen
2743                $opt_defaultcmd_interactive = [ qw(-i) ];
2744                # This access to @ARGV is excessive familiarity with
2745                # Getopt::Long, but there isn't another sensible
2746                # approach.  '-i=s{0,}' does not work with bundling.
2747                push @$opt_defaultcmd_interactive, @ARGV;
2748                @ARGV=();
2749            },
2750            'help' => sub { print $usage_message or die $!; finish 0; },
2751            );
2752
2753 initdebug('git-debrebase ');
2754 enabledebug if $debuglevel;
2755
2756 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2757 chdir $toplevel or die "chdir $toplevel: $!";
2758
2759 $rd = fresh_playground "$playprefix/misc";
2760
2761 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2762
2763 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2764     defaultcmd_rebase();
2765 } else {
2766     my $cmd = shift @ARGV;
2767     my $cmdfn = $cmd;
2768     $cmdfn =~ y/-/_/;
2769     $cmdfn = ${*::}{"cmd_$cmdfn"};
2770
2771     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2772     $cmdfn->();
2773 }
2774
2775 finish 0;