git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$$) {
 267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 268     # if $tree_with_debian is supplied, will use that for debian/
 269     # otherwise will save and restore it.
 270     my $debian =
 271         $tree_with_debian ? "$tree_with_debian:debian"
 272         : cmdoutput @git, qw(write-tree --prefix=debian/);
 273     runcmd @git, qw(read-tree), $treeish;
 274     read_tree_subdir 'debian', $debian;
 275     rm_subdir_cached 'debian/patches' unless $keep_patches;
 276 };
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @snag_force_opts;
 288 sub snag ($$;@) {
 289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 290     if (grep { $_ eq $tag } @snag_force_opts) {
 291         $snags_forced++;
 292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 293     } else {
 294         $snags_tripped++;
 295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 296     }
 297 }
 298
 299 # Important: all mainline code must call snags_maybe_bail after
 300 # any point where snag might be called, but before making changes
 301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 302 # may be called more than once if necessary (but this is not ideal
 303 # because then the messages about number of snags may be confusing).
 304 sub snags_maybe_bail () {
 305     return if all_snags_summarised();
 306     if ($snags_forced) {
 307         printf STDERR
 308             "%s: snags: %d overriden by individual -f options\n",
 309             $us, $snags_forced;
 310     }
 311     if ($snags_tripped) {
 312         if ($opt_force) {
 313             printf STDERR
 314                 "%s: snags: %d overriden by global --force\n",
 315                 $us, $snags_tripped;
 316         } else {
 317             fail sprintf
 318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 319                 $us, $snags_tripped;
 320         }
 321     }
 322     $snags_summarised = $snags_forced + $snags_tripped;
 323 }
 324 sub snags_maybe_bail_early () {
 325     # useful to bail out early without doing a lot of work;
 326     # not a substitute for snags_maybe_bail.
 327     snags_maybe_bail() if $snags_tripped && !$opt_force;
 328 }
 329 sub any_snags () {
 330     return $snags_forced || $snags_tripped;
 331 }
 332
 333 sub gbp_pq_export ($$$) {
 334     my ($bname, $base, $tip) = @_;
 335     # must be run in a workarea.  $bname and patch-queue/$bname
 336     # ought not to exist.  Leaves you on patch-queue/$bname with
 337     # the patches staged but not committed.
 338     printdebug "gbp_pq_export $bname $base $tip\n";
 339     runcmd @git, qw(checkout -q -b), $bname, $base;
 340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 341     my @gbp_cmd = (qw(gbp pq export));
 342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 343     if ($r) {
 344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 345         failedcmd @gbp_cmd;
 346     }
 347     runcmd @git, qw(add -f debian/patches);
 348 }
 349
 350
 351 # xxx allow merge resolution separately from laundering, before git merge
 352 #
 353 # xxx general gdr docs highlight forbidden things
 354 # xxx general gdr docs list allowable things ?
 355 # xxx general gdr docs explicitly forbid some rebase
 356 #
 357 # xxx provide a way for the user to help
 358 # xxx (eg, provide wreckage provide way to continue)
 359
 360 # later/rework?
 361 #  use git-format-patch?
 362 #  our own patch identification algorithm?
 363 #  this is an alternative strategy
 364
 365 sub merge_series ($$;@) {
 366     my ($newbase, $base_q, @input_qs) = @_;
 367     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 368     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 369     # ^ specifies several patch series (currently we only support exactly 2)
 370     # return value is a commit which is the result of
 371     # merging the two versions of the same topic branch
 372     #   $input_q[0] and $input_q[1]
 373     # with respect to the old version
 374     #   $base_q
 375     # all onto $newbase.
 376
 377     # Creates, in *_q, a key MR for its private use
 378
 379     printdebug "merge_series newbase=$newbase\n";
 380
 381     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 382     $base_q->{MR}{S} = 'base';
 383
 384     my %prereq;
 385     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 386     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 387     # $prereq{<patch filename>}               exists or not (even later)
 388
 389     my $result;
 390
 391     local $workarea = fresh_playground "$playprefix/merge";
 392     my $seriesfile = "debian/patches/series";
 393     in_workarea sub {
 394         playtree_setup();
 395         foreach my $q ($base_q, reverse @input_qs) {
 396             my $s = $q->{MR}{S};
 397             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 398             my @earlier;
 399             if (open S, $seriesfile) {
 400                 while (my $patch = <S>) {
 401                     chomp $patch or die $!;
 402                     $prereq{$patch} //= {};
 403                     foreach my $earlier (@earlier) {
 404                         $prereq{$patch}{$earlier}{$s}++ and die;
 405                     }
 406                     push @earlier, $patch;
 407                     stat "debian/patches/$patch" or die "$patch ?";
 408                 }
 409                 S->error and die "$seriesfile $!";
 410                 close S;
 411             } else {
 412                 die "$seriesfile $!" unless $!==ENOENT;
 413             }
 414             read_tree_upstream $newbase, 1;
 415             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 416                 "Convert $s to patch queue for merging",
 417                 "[git-debrebase merge-innards patch-queue import:".
 418                 " $q->{SeriesTip}]"
 419             ];
 420             printdebug "merge_series  pec $pec ";
 421             runcmd @git, qw(rm -q --cached), $seriesfile;
 422             $pec = make_commit [ $pec ], [
 423                 "Drop series file from $s to avoid merge trouble",
 424                 "[git-debrebase merge-innards patch-queue prep:".
 425                 " $q->{SeriesTip}]"
 426             ];
 427
 428             read_tree_debian $newbase;
 429             if (@earlier) {
 430                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 431             } else {
 432                 rm_subdir_cached 'debian/patches';
 433             }
 434             $pec = make_commit [ $pec ], [
 435  "Update debian/ (excluding patches) to final to avoid re-merging",
 436  "debian/ was already merged and we need to just take that.",
 437                 "[git-debrebase merge-innards patch-queue packaging:".
 438                 " $q->{SeriesTip}]"
 439             ];
 440
 441             printdebug "pec' $pec\n";
 442             runcmd @git, qw(reset -q --hard), $pec;
 443             $q->{MR}{PEC} = $pec;
 444         }
 445         # now, because of reverse, we are on $input_q->{MR}{OQC}
 446         runcmd @git, qw(checkout -q -b merge);
 447         printdebug "merge_series merging...\n";
 448         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 449         debugcmd '+', @mergecmd;
 450         $!=0; $?=-1;
 451         if (system @mergecmd) {
 452             failedcmd @mergecmd;
 453         }
 454
 455         printdebug "merge_series merge ok, series...\n";
 456         # We need to construct a new series file
 457         # Firstly, resolve prereq
 458         foreach my $f (sort keys %prereq) {
 459             printdebug "merge_series  patch\t$f\t";
 460             if (!stat_exists "debian/patches/$f") {
 461                 print DEBUG " drop\n" if $debuglevel;
 462                 # git merge deleted it; that's how we tell it's not wanted
 463                 delete $prereq{$f};
 464                 next;
 465             }
 466             print DEBUG " keep\n" if $debuglevel;
 467             foreach my $g (sort keys %{ $prereq{$f} }) {
 468                 my $gfp = $prereq{$f}{$g};
 469                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 470                 if (!!$gfp->{0} == !!$gfp->{1}
 471                     ? $gfp->{0}
 472                     : !$gfp->{base}) {
 473                     print DEBUG "\tkeep\n" if $debuglevel;
 474                 } else {
 475                     print DEBUG "\tdrop\n" if $debuglevel;
 476                     delete $prereq{$f}{$g};
 477                 }
 478             }
 479         }
 480
 481         my $unsat = sub {
 482             my ($f) = @_;
 483             return scalar keys %{ $prereq{$f} };
 484         };
 485
 486         my $nodate = time + 1;
 487         my %authordate;
 488         # $authordate{<patch filename>};
 489         my $authordate = sub {
 490             my ($f) = @_;
 491             $authordate{$f} //= do {
 492                 open PF, "<", "debian/patches/$f" or die "$f $!";
 493                 while (<PF>) {
 494                     return $nodate if m/^$/;
 495                     last if s{^Date: }{};
 496                 }
 497                 chomp;
 498                 return cmdoutput qw(date +%s -d), $_;
 499             };
 500         };
 501
 502         open NS, '>', $seriesfile or die $!;
 503
 504         while (keys %prereq) {
 505             my $best;
 506             foreach my $try (sort keys %prereq) {
 507                 if ($best) {
 508                     next if (
 509                              $unsat->($try) <=> $unsat->($best) or
 510                              $authordate->($try) <=> $authordate->($best) or
 511                              $try cmp $best
 512                             ) >= 0;
 513                 }
 514                 $best = $try;
 515             }
 516             printdebug "merge_series series next $best\n";
 517             print NS "$best\n" or die $!;
 518             delete $prereq{$best};
 519             foreach my $gp (values %prereq) {
 520                 delete $gp->{$best};
 521             }
 522         }
 523
 524         runcmd @git, qw(add), $seriesfile;
 525         runcmd @git, qw(commit --quiet -m), 'Merged series';
 526
 527         printdebug "merge_series series gbp pq import\n";
 528         runcmd qw(gbp pq import);
 529
 530         # OK now we are on patch-queue/merge, and we need to rebase
 531         # onto the intended parent and drop the patches from each one
 532
 533         printdebug "merge_series series ok, building...\n";
 534         my $build = $newbase;
 535         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 536         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 537             my $commit = git_cat_file $c, 'commit';
 538             printdebug "merge_series series ok, building $c\n";
 539             read_tree_upstream $c, 0, $newbase;
 540             my $tree = cmdoutput @git, qw(write-tree);
 541             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 542             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 543             open C, ">", "../mcommit" or die $!;
 544             print C $commit or die $!;
 545             close C or die $!;
 546             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 547         }
 548         $result = $build;
 549         runcmd @git, qw(update-ref refs/heads/result), $result;
 550
 551         runcmd @git, qw(checkout -q -b debug);
 552         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 553         runcmd @git, qw(add .);
 554         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 555         printdebug sprintf "merge_series done debug=%s\n",
 556             git_rev_parse 'HEAD';
 557     };
 558     printdebug "merge_series returns $result\n";
 559     return $result;
 560 }
 561
 562 # classify returns an info hash like this
 563 #   CommitId => $objid
 564 #   Hdr => # commit headers, including 1 final newline
 565 #   Msg => # commit message (so one newline is dropped)
 566 #   Tree => $treeobjid
 567 #   Type => (see below)
 568 #   Parents = [ {
 569 #       Ix => $index # ie 0, 1, 2, ...
 570 #       CommitId
 571 #       Differs => return value from get_differs
 572 #       IsOrigin
 573 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 574 #     } ...]
 575 #   NewMsg => # commit message, but with any [dgit import ...] edited
 576 #             # to say "[was: ...]"
 577 #
 578 # Types:
 579 #   Packaging
 580 #   Changelog
 581 #   Upstream
 582 #   AddPatches
 583 #   Mixed
 584 #
 585 #   Pseudomerge
 586 #     has additional entres in classification result
 587 #       Overwritten = [ subset of Parents ]
 588 #       Contributor = $the_remaining_Parent
 589 #
 590 #   DgitImportUnpatched
 591 #     has additional entry in classification result
 592 #       OrigParents = [ subset of Parents ]
 593 #
 594 #   Anchor
 595 #     has additional entry in classification result
 596 #       OrigParents = [ subset of Parents ]  # singleton list
 597 #
 598 #   TreatAsAnchor
 599 #
 600 #   BreakwaterStart
 601 #
 602 #   Unknown
 603 #     has additional entry in classification result
 604 #       Why => "prose"
 605
 606 sub parsecommit ($;$) {
 607     my ($objid, $p_ref) = @_;
 608     # => hash with                   CommitId Hdr Msg Tree Parents
 609     #    Parents entries have only   Ix CommitId
 610     #    $p_ref, if provided, must be [] and is used as a base for Parents
 611
 612     $p_ref //= [];
 613     die if @$p_ref;
 614
 615     my ($h,$m) = get_commit $objid;
 616
 617     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 618     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 619
 620     my $r = {
 621         CommitId => $objid,
 622         Hdr => $h,
 623         Msg => $m,
 624         Tree => $t,
 625         Parents => $p_ref,
 626     };
 627
 628     foreach my $ph (@ph) {
 629         push @$p_ref, {
 630             Ix => scalar @$p_ref,
 631             CommitId => $ph,
 632         };
 633     }
 634
 635     return $r;
 636 }
 637
 638 sub classify ($) {
 639     my ($objid) = @_;
 640
 641     my @p;
 642     my $r = parsecommit($objid, \@p);
 643     my $t = $r->{Tree};
 644
 645     foreach my $p (@p) {
 646         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 647     }
 648
 649     printdebug "classify $objid \$t=$t \@p",
 650         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 651         "\n";
 652
 653     my $classify = sub {
 654         my ($type, @rest) = @_;
 655         $r = { %$r, Type => $type, @rest };
 656         if ($debuglevel) {
 657             printdebug " = $type ".(dd $r)."\n";
 658         }
 659         return $r;
 660     };
 661     my $unknown = sub {
 662         my ($why) = @_;
 663         $r = { %$r, Type => qw(Unknown), Why => $why };
 664         printdebug " ** Unknown\n";
 665         return $r;
 666     };
 667
 668     if (grep { $_ eq $objid } @opt_anchors) {
 669         return $classify->('TreatAsAnchor');
 670     }
 671
 672     my @identical = grep { !$_->{Differs} } @p;
 673     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 674     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 675
 676     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 677         # multi-orig upstreams are represented with an anchor merge
 678         # from a single upstream commit which combines the orig tarballs
 679
 680         # Every anchor tagged this way must be a merge.
 681         # We are relying on the
 682         #     [git-debrebase anchor: ...]
 683         # commit message annotation in "declare" anchor merges (which
 684         # do not have any upstream changes), to distinguish those
 685         # anchor merges from ordinary pseudomerges (which we might
 686         # just try to strip).
 687         #
 688         # However, the user is going to be doing git-rebase a lot.  We
 689         # really don't want them to rewrite an anchor commit.
 690         # git-rebase trips up on merges, so that is a useful safety
 691         # catch.
 692         #
 693         # BreakwaterStart commits are also anchors in the terminology
 694         # of git-debrebase(5), but they are untagged (and always
 695         # manually generated).
 696         #
 697         # We cannot not tolerate any tagged linear commit (ie,
 698         # BreakwaterStart commits tagged `[anchor:') because such a
 699         # thing could result from an erroneous linearising raw git
 700         # rebase of a merge anchor.  That would represent a corruption
 701         # of the branch. and we want to detect and reject the results
 702         # of such corruption before it makes it out anywhere.  If we
 703         # reject it here then we avoid making the pseudomerge which
 704         # would be needed to push it.
 705
 706         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 707         @p == 2 or return $badanchor->("has other than two parents");
 708         $haspatches and return $badanchor->("contains debian/patches");
 709
 710         # How to decide about l/r ordering of anchors ?  git
 711         # --topo-order prefers to expand 2nd parent first.  There's
 712         # already an easy rune to look for debian/ history anyway (git log
 713         # debian/) so debian breakwater branch should be 1st parent; that
 714         # way also there's also an easy rune to look for the upstream
 715         # patches (--topo-order).
 716
 717         # Also this makes --first-parent be slightly more likely to
 718         # be useful - it makes it provide a linearised breakwater history.
 719
 720         # Of course one can say somthing like
 721         #  gitk -- ':/' ':!/debian'
 722         # to get _just_ the commits touching upstream files, and by
 723         # the TREESAME logic in git-rev-list this will leave the
 724         # breakwater into upstream at the first anchor.  But that
 725         # doesn't report debian/ changes at all.
 726
 727         # Other observations about gitk: by default, gitk seems to
 728         # produce output in a different order to git-rev-list.  I
 729         # can't seem to find this documented anywhere.  gitk
 730         # --date-order DTRT.  But, gitk always seems to put the
 731         # parents from left to right, in order, so it's easy to see
 732         # which way round a pseudomerge is.
 733
 734         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 735         $p[1]{Differs} & ~DS_DEB and
 736             $badanchor->("upstream files differ from left parent");
 737         $p[0]{Differs} & ~D_UPS and
 738             $badanchor->("debian/ differs from right parent");
 739
 740         return $classify->(qw(Anchor),
 741                            OrigParents => [ $p[1] ]);
 742     }
 743
 744     if (@p == 1) {
 745         my $d = $r->{Parents}[0]{Differs};
 746         if ($d == D_PAT_ADD) {
 747             return $classify->(qw(AddPatches));
 748         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 749             return $unknown->("edits debian/patches");
 750         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 751             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 752             if ($ty eq 'tree') {
 753                 if ($d == D_DEB_CLOG) {
 754                     return $classify->(qw(Changelog));
 755                 } else {
 756                     return $classify->(qw(Packaging));
 757                 }
 758             } elsif ($ty eq 'missing') {
 759                 return $classify->(qw(BreakwaterStart));
 760             } else {
 761                 return $unknown->("parent's debian is not a directory");
 762             }
 763         } elsif ($d == D_UPS) {
 764             return $classify->(qw(Upstream));
 765         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 766             return $classify->(qw(Mixed));
 767         } elsif ($d == 0) {
 768             return $unknown->("no changes");
 769         } else {
 770             confess "internal error $objid ?";
 771         }
 772     }
 773     if (!@p) {
 774         return $unknown->("origin commit");
 775     }
 776
 777     if (@p == 2 && @identical == 1) {
 778         my @overwritten = grep { $_->{Differs} } @p;
 779         confess "internal error $objid ?" unless @overwritten==1;
 780         return $classify->(qw(Pseudomerge),
 781                            Overwritten => [ $overwritten[0] ],
 782                            Contributor => $identical[0]);
 783     }
 784     if (@p == 2 && @identical == 2) {
 785         my $get_t = sub {
 786             my ($ph,$pm) = get_commit $_[0]{CommitId};
 787             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 788             $1;
 789         };
 790         my @bytime = @p;
 791         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 792         if ($order > 0) { # newer first
 793         } elsif ($order < 0) {
 794             @bytime = reverse @bytime;
 795         } else {
 796             # same age, default to order made by -s ours
 797             # that is, commit was made by someone who preferred L
 798         }
 799         return $classify->(qw(Pseudomerge),
 800                            SubType => qw(Ambiguous),
 801                            Contributor => $bytime[0],
 802                            Overwritten => [ $bytime[1] ]);
 803     }
 804     foreach my $p (@p) {
 805         my ($p_h, $p_m) = get_commit $p->{CommitId};
 806         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 807         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 808     }
 809     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 810     my $m2 = $r->{Msg};
 811     if (!(grep { !$_->{IsOrigin} } @p) and
 812         (@orig_ps >= @p - 1) and
 813         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 814         $r->{NewMsg} = $m2;
 815         return $classify->(qw(DgitImportUnpatched),
 816                            OrigParents => \@orig_ps);
 817     }
 818
 819     if (@p == 2 and
 820         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 821         # xxx ^ metadata tag needs adding to (5)
 822         return $classify->("MergedBreakwaters");
 823     }
 824     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 825         return $unknown->("unknown kind of merge from $1");
 826     }
 827     if (@p > 2) {
 828         return $unknown->("octopus merge");
 829     }
 830
 831     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 832         return $unknown->("general two-parent merge");
 833     }
 834
 835     return $classify->("VanillaMerge");
 836 }
 837
 838 sub keycommits ($;$$$$$);
 839
 840 sub mergedbreakwaters_anchor ($) {
 841     my ($cl) = @_;
 842     my $best_anchor;
 843     foreach my $p (@{ $cl->{Parents} }) {
 844         my ($panchor, $pbw) = keycommits $p->{CommitId},
 845             undef,undef,undef,undef, 1;
 846         $best_anchor = $panchor
 847             if !defined $best_anchor
 848             or is_fast_fwd $best_anchor, $panchor;
 849         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 850             unless is_fast_fwd $panchor, $best_anchor;
 851     }
 852     return $best_anchor;
 853 }
 854
 855 sub keycommits ($;$$$$$) {
 856     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 857     # => ($anchor, $breakwater)
 858
 859     # $unclean->("unclean-$tagsfx", $msg, $cl)
 860     # $furniture->("unclean-$tagsfx", $msg, $cl)
 861     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 862     #   is callled for each situation or commit that
 863     #   wouldn't be found in a laundered branch
 864     # $furniture is for furniture commits such as might be found on an
 865     #   interchange branch (pseudomerge, d/patches, changelog)
 866     # $trouble is for things whnich prevent the return of
 867     #   anchor and breakwater information; if that is ignored,
 868     #   then keycommits returns (undef, undef) instead.
 869     # $fatal is for unprocessable commits, and should normally cause
 870     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 871     #
 872     # If $claimed_bw, this is supposed to be a breakwater commit.
 873     #
 874     # If a callback is undef, fail is called instead.
 875     # If a callback is defined but false, the situation is ignored.
 876     # Callbacks may say:
 877     #   no warnings qw(exiting); last;
 878     # if the answer is no longer wanted.
 879
 880     my ($anchor, $breakwater);
 881     $breakwater = $head if $claimed_bw;
 882     my $clogonly;
 883     my $cl;
 884     my $found_pm;
 885     $fatal //= sub { fail $_[1]; };
 886     my $x = sub {
 887         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 888         my $why = $mainwhy.$xwhy;
 889         my $m = "branch needs laundering (run git-debrebase): $why";
 890         fail $m unless defined $cb;
 891         return unless $cb;
 892         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 893     };
 894     my $found_anchor = sub {
 895         ($anchor) = @_;
 896         $breakwater //= $clogonly;
 897         $breakwater //= $head;
 898         no warnings qw(exiting);
 899         last;
 900     };
 901     for (;;) {
 902         $cl = classify $head;
 903         my $ty = $cl->{Type};
 904         if ($ty eq 'Packaging') {
 905             $breakwater //= $clogonly;
 906             $breakwater //= $head;
 907         } elsif ($ty eq 'Changelog') {
 908             # this is going to count as the tip of the breakwater
 909             # only if it has no upstream stuff before it
 910             $clogonly //= $head;
 911         } elsif ($ty eq 'Anchor' or
 912                  $ty eq 'TreatAsAnchor' or
 913                  $ty eq 'BreakwaterStart') {
 914             $found_anchor->($head);
 915         } elsif ($ty eq 'Upstream') {
 916             $x->($unclean, 'ordering',
 917  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 918                 if defined $breakwater;
 919             $clogonly = undef;
 920             $breakwater = undef;
 921         } elsif ($ty eq 'Mixed') {
 922             $x->($unclean, 'mixed',
 923                  "found mixed upstream/packaging commit"," ($head)");
 924             $clogonly = undef;
 925             $breakwater = undef;
 926         } elsif ($ty eq 'Pseudomerge' or
 927                  $ty eq 'AddPatches') {
 928             my $found_pm = 1;
 929             $x->($furniture, (lc $ty),
 930                  "found interchange bureaucracy commit ($ty)"," ($head)");
 931         } elsif ($ty eq 'DgitImportUnpatched') {
 932             if ($found_pm) {
 933                 $x->($trouble, 'dgitimport',
 934                      "found dgit dsc import"," ($head)");
 935                 return (undef,undef);
 936             } else {
 937                 $x->($fatal, 'unprocessable',
 938                      "found bare dgit dsc import with no prior history",
 939                      " ($head)");
 940                 return (undef,undef);
 941             }
 942         } elsif ($ty eq 'VanillaMerge') {
 943             $x->($trouble, 'vanillamerge',
 944                  "found vanilla merge"," ($head)");
 945             return (undef,undef);
 946         } elsif ($ty eq 'MergedBreakwaters') {
 947             $found_anchor->(mergedbreakwaters_anchor $cl);
 948         } else {
 949             $x->($fatal, 'unprocessable',
 950                  "found unprocessable commit, cannot cope: $cl->{Why}",
 951                  " ($head)");
 952             return (undef,undef);
 953         }
 954         $head = $cl->{Parents}[0]{CommitId};
 955     }
 956     return ($anchor, $breakwater);
 957 }
 958
 959 sub walk ($;$$$);
 960 sub walk ($;$$$) {
 961     my ($input,
 962         $nogenerate,$report, $report_lprefix) = @_;
 963     # => ($tip, $breakwater_tip, $last_anchor)
 964     # (or nothing, if $nogenerate)
 965
 966     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 967     $report_lprefix //= '';
 968
 969     # go through commits backwards
 970     # we generate two lists of commits to apply:
 971     # breakwater branch and upstream patches
 972     my (@brw_cl, @upp_cl, @processed);
 973     my %found;
 974     my $upp_limit;
 975     my @pseudomerges;
 976
 977     my $cl;
 978     my $xmsg = sub {
 979         my ($prose, $info) = @_;
 980         my $ms = $cl->{Msg};
 981         chomp $ms;
 982         $info //= '';
 983         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 984         return (Msg => $ms);
 985     };
 986     my $rewrite_from_here = sub {
 987         my ($cl) = @_;
 988         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 989         push @$cl, $sp_cl;
 990         push @processed, $sp_cl;
 991     };
 992     my $cur = $input;
 993
 994     my $prdelim = "";
 995     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 996
 997     my $prline = sub {
 998         return unless $report;
 999         print $report $prdelim, $report_lprefix, @_;
1000         $prdelim = "\n";
1001     };
1002
1003     my $bomb = sub { # usage: return $bomb->();
1004         print $report " Unprocessable" if $report;
1005         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1006         $prprdelim->();
1007         if ($nogenerate) {
1008             return (undef,undef);
1009         }
1010         fail "found unprocessable commit, cannot cope".
1011             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1012             " (commit $cur) (d.".
1013             (join ' ', map { sprintf "%#x", $_->{Differs} }
1014              @{ $cl->{Parents} }).
1015                  ")";
1016     };
1017
1018     my $build;
1019     my $breakwater;
1020
1021     my $build_start = sub {
1022         my ($msg, $parent) = @_;
1023         $prline->(" $msg");
1024         $build = $parent;
1025         no warnings qw(exiting); last;
1026     };
1027
1028     my $nomerge = sub {
1029         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1030     };
1031
1032     my $last_anchor;
1033
1034     for (;;) {
1035         $cl = classify $cur;
1036         my $ty = $cl->{Type};
1037         my $st = $cl->{SubType};
1038         $prline->("$cl->{CommitId} $cl->{Type}");
1039         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1040         push @processed, $cl;
1041         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1042         if ($ty eq 'AddPatches') {
1043             $cur = $p0;
1044             $rewrite_from_here->(\@upp_cl);
1045             next;
1046         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1047             push @brw_cl, $cl;
1048             $cur = $p0;
1049             next;
1050         } elsif ($ty eq 'BreakwaterStart') {
1051             $last_anchor = $cur;
1052             $build_start->('FirstPackaging', $cur);
1053         } elsif ($ty eq 'Upstream') {
1054             push @upp_cl, $cl;
1055             $cur = $p0;
1056             next;
1057         } elsif ($ty eq 'Mixed') {
1058             my $queue = sub {
1059                 my ($q, $wh) = @_;
1060                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1061                 push @$q, $cls;
1062             };
1063             $queue->(\@brw_cl, "debian");
1064             $queue->(\@upp_cl, "upstream");
1065             $rewrite_from_here->(\@brw_cl);
1066             $cur = $p0;
1067             next;
1068         } elsif ($ty eq 'Pseudomerge') {
1069             my $contrib = $cl->{Contributor}{CommitId};
1070             print $report " Contributor=$contrib" if $report;
1071             push @pseudomerges, $cl;
1072             $rewrite_from_here->(\@upp_cl);
1073             $cur = $contrib;
1074             next;
1075         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1076             $last_anchor = $cur;
1077             $build_start->("Anchor", $cur);
1078         } elsif ($ty eq 'DgitImportUnpatched') {
1079             my $pm = $pseudomerges[-1];
1080             if (defined $pm) {
1081                 # To an extent, this is heuristic.  Imports don't have
1082                 # a useful history of the debian/ branch.  We assume
1083                 # that the first pseudomerge after an import has a
1084                 # useful history of debian/, and ignore the histories
1085                 # from later pseudomerges.  Often the first pseudomerge
1086                 # will be the dgit import of the upload to the actual
1087                 # suite intended by the non-dgit NMUer, and later
1088                 # pseudomerges may represent in-archive copies.
1089                 my $ovwrs = $pm->{Overwritten};
1090                 printf $report " PM=%s \@Overwr:%d",
1091                     $pm->{CommitId}, (scalar @$ovwrs)
1092                     if $report;
1093                 if (@$ovwrs != 1) {
1094                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1095                     return $bomb->();
1096                 }
1097                 my $ovwr = $ovwrs->[0]{CommitId};
1098                 printf $report " Overwr=%s", $ovwr if $report;
1099                 # This import has a tree which is just like a
1100                 # breakwater tree, but it has the wrong history.  It
1101                 # ought to have the previous breakwater (which the
1102                 # pseudomerge overwrote) as an ancestor.  That will
1103                 # make the history of the debian/ files correct.  As
1104                 # for the upstream version: either it's the same as
1105                 # was ovewritten (ie, same as the previous
1106                 # breakwater), in which case that history is precisely
1107                 # right; or, otherwise, it was a non-gitish upload of a
1108                 # new upstream version.  We can tell these apart by
1109                 # looking at the tree of the supposed upstream.
1110                 push @brw_cl, {
1111                     %$cl,
1112                     SpecialMethod => 'DgitImportDebianUpdate',
1113                     $xmsg->("convert dgit import: debian changes")
1114                 }, {
1115                     %$cl,
1116                     SpecialMethod => 'DgitImportUpstreamUpdate',
1117                     $xmsg->("convert dgit import: upstream update",
1118                             " anchor")
1119                 };
1120                 $prline->(" Import");
1121                 $rewrite_from_here->(\@brw_cl);
1122                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1123                 $cur = $ovwr;
1124                 next;
1125             } else {
1126                 # Everything is from this import.  This kind of import
1127                 # is already nearly in valid breakwater format, with the
1128                 # patches as commits.  Unfortunately it contains
1129                 # debian/patches/.
1130                 printdebug "*** WALK BOMB bare dgit import\n";
1131                 $cl->{Why} = "bare dgit dsc import";
1132                 return $bomb->();
1133             }
1134             die "$ty ?";
1135         } elsif ($ty eq 'MergedBreakwaters') {
1136             $last_anchor = mergedbreakwaters_anchor $cl;
1137             $build_start->(' MergedBreakwaters', $cur);
1138             last;
1139         } elsif ($ty eq 'VanillaMerge') {
1140             # User may have merged unstitched branch(es).  We will
1141             # have now lost what ffq-prev was then (since the later
1142             # pseudomerge may introduce further changes).  The effect
1143             # of resolving such a merge is that we may have to go back
1144             # further in history to find a merge base, since the one
1145             # which was reachable via ffq-prev is no longer findable.
1146             # This is suboptimal, but if it all works we'll have done
1147             # the right thing.
1148             # xxx we should warn the user in the docs about this
1149
1150             my $ok=1;
1151             my $best_anchor;
1152             # We expect to find a dominating anchor amongst the
1153             # inputs' anchors.  That will be the new anchor.
1154             #
1155             # More complicated is finding a merge base for the
1156             # breakwaters.  We need a merge base that is a breakwater
1157             # commit.  The ancestors of breakwater commits are more
1158             # breakwater commits and possibly upstream commits and the
1159             # ancestors of those upstream.  Upstreams might have
1160             # arbitrary ancestors.  But any upstream commit U is
1161             # either included in both anchors, in which case the
1162             # earlier anchor is a better merge base than any of U's
1163             # ancestors; or U is not included in the older anchor, in
1164             # which case U is not an ancestor of the vanilla merge at
1165             # all.  So no upstream commit, nor any ancestor thereof,
1166             # is a best merge base.  As for non-breakwater Debian
1167             # commits: these are never ancestors of any breakwater.
1168             #
1169             # So any best merge base as found by git-merge-base
1170             # is a suitable breakwater anchor.  Usually there will
1171             # be only one.
1172
1173             printdebug "*** MERGE\n";
1174
1175             my @bwbcmd = (@git, qw(merge-base));
1176             my @ibcmd = (@git, qw(merge-base --all));
1177             my $might_be_in_bw = 1;
1178
1179             my $ps = $cl->{Parents};
1180
1181             foreach my $p (@$ps) {
1182                 $prline->(" VanillaMerge ".$p->{Ix});
1183                 $prprdelim->();
1184                 my ($ptip, $pbw, $panchor) =
1185                     walk $p->{CommitId}, 0, $report,
1186                          $report_lprefix.'  ';
1187                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1188                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1189                 $p->{Anchor} = $panchor;
1190
1191                 $best_anchor = $panchor if
1192                     !defined $best_anchor or
1193                     is_fast_fwd $best_anchor, $panchor;
1194
1195                 printdebug " MERGE BA best=".($best_anchor//'-').
1196                     " p=$panchor\n";
1197             }
1198
1199             foreach my $p (@$ps) {
1200                 $prline->(" VanillaMerge ".$p->{Ix});
1201                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1202                     $nomerge->('DivergentAnchor');
1203                 } elsif ($p->{Anchor} eq $best_anchor) {
1204                     print $report " SameAnchor" if $report;
1205                 } else {
1206                     print $report " SupersededAnchor" if $report;
1207                 }
1208                 if ($p->{Breakwater} eq $p->{CommitId}) {
1209                     # this parent commit was its own breakwater,
1210                     # ie it is part of the breakwater
1211                     print $report " Breakwater" if $report;
1212                 } else {
1213                     $might_be_in_bw = 0;
1214                 }
1215                 push @bwbcmd, $p->{Breakwater};
1216                 push @ibcmd, $p->{CommitId};
1217             }
1218
1219             if ($ok && $might_be_in_bw) {
1220                 $prline->(" VanillaMerge MergedBreakwaters");
1221                 $last_anchor = $best_anchor;
1222                 $build_start->('MergedBreakwaters', $cur);
1223             }
1224
1225             my $bwb = cmdoutput @bwbcmd;
1226
1227             # OK, now we have a breakwater base, but we need the merge
1228             # base for the interchange branch because we need the delta
1229             # queue.
1230             #
1231             # This a the best merge base of our inputs which has the
1232             # breakwater merge base as an ancestor.
1233
1234             my @ibs =
1235                 grep { is_fast_fwd $bwb, $_ }
1236                 grep /./,
1237                 split /\n/,
1238                 cmdoutput @ibcmd;
1239             my ($ib) = @ibs
1240                 or $nomerge->("no suitable interchange merge base");
1241
1242             $prline->("  VanillaMerge Base");
1243             $prprdelim->();
1244             my ($btip, $bbw, $banchor) =
1245                 walk $ib, 0, $report, $report_lprefix.'  ';
1246
1247             my $ibinfo = { SeriesTip => $btip,
1248                            SeriesBase => $bbw,
1249                            Anchor => $banchor };
1250             $bbw eq $bwb
1251                 or $nomerge->("interchange merge-base ($ib)'s".
1252                               " breakwater ($bbw)".
1253                               " != breakwaters' merge-base ($bwb)");
1254             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1255                  or $nomerge->("interchange merge-base ($ib)'s".
1256                                " anchor ($ibinfo->{SeriesBase})".
1257                                " != any merge input's anchor (".
1258                                (join ' ', map { $_->{Anchor} } @$ps).
1259                                ")");
1260
1261
1262             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1263             $cl->{MergeBestAnchor} = $best_anchor;
1264             push @brw_cl, {
1265                 %$cl,
1266                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1267                 $xmsg->('constructed from vanilla merge',
1268                         ' merged-breakwater'),
1269             };
1270             push @upp_cl, {
1271                 %$cl,
1272                 SpecialMethod => 'MergeMergeSeries',
1273             };
1274             $build_start->('MergeBreakwaters', $cur);
1275         } else {
1276             printdebug "*** WALK BOMB unrecognised\n";
1277             return $bomb->();
1278         }
1279     }
1280     $prprdelim->();
1281
1282     printdebug "*** WALK prep done cur=$cur".
1283         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1284
1285     return if $nogenerate;
1286
1287     # Now we build it back up again
1288
1289     fresh_workarea();
1290
1291     my $rewriting = 0;
1292
1293     my $read_tree_upstream = sub {
1294         my ($treeish) = @_;
1295         read_tree_upstream $treeish, 0, $build;
1296     };
1297
1298     $#upp_cl = $upp_limit if defined $upp_limit;
1299
1300     my $committer_authline = calculate_committer_authline();
1301
1302     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1303
1304     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1305
1306     in_workarea sub {
1307         mkdir $rd or $!==EEXIST or die $!;
1308         my $current_method;
1309         runcmd @git, qw(read-tree), $build;
1310         foreach my $cl (qw(Debian), (reverse @brw_cl),
1311                         { SpecialMethod => 'RecordBreakwaterTip' },
1312                         qw(Upstream), (reverse @upp_cl)) {
1313             if (!ref $cl) {
1314                 $current_method = $cl;
1315                 next;
1316             }
1317             my $method = $cl->{SpecialMethod} // $current_method;
1318             my @parents = ($build);
1319             my $cltree = $cl->{CommitId};
1320             printdebug "WALK BUILD ".($cltree//'undef').
1321                 " $method (rewriting=$rewriting)\n";
1322             if ($method eq 'Debian') {
1323                 read_tree_debian($cltree);
1324             } elsif ($method eq 'Upstream') {
1325                 $read_tree_upstream->($cltree);
1326             } elsif ($method eq 'StartRewrite') {
1327                 $rewriting = 1;
1328                 next;
1329             } elsif ($method eq 'RecordBreakwaterTip') {
1330                 $breakwater = $build;
1331                 next;
1332             } elsif ($method eq 'DgitImportDebianUpdate') {
1333                 read_tree_debian($cltree);
1334             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1335                 confess unless $rewriting;
1336                 my $differs = (get_differs $build, $cltree);
1337                 next unless $differs & D_UPS;
1338                 $read_tree_upstream->($cltree);
1339                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1340             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1341                 print "Found a general merge, will try to tidy it up.\n";
1342                 $rewriting = 1;
1343                 $read_tree_upstream->($cl->{MergeBestAnchor});
1344                 $read_tree_upstream->($cl->{MergeBestAnchor});
1345                 read_tree_debian($cltree);
1346                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1347             } elsif ($method eq 'MergeMergeSeries') {
1348                 print "Running merge resolution for $cl->{CommitId}...\n";
1349                 $build = merge_series
1350                     $build,
1351                     $cl->{MergeInterchangeBaseInfo},
1352                     @{ $cl->{Parents} };
1353                 $last_anchor = $cl->{MergeBestAnchor};
1354
1355                 # Check for mismerges:
1356                 my $check = sub {
1357                     my ($against, $allow, $what) = @_;
1358                     my $differs = get_differs $build, $against;
1359                     $nomerge->(sprintf
1360        "merge misresolved: %s are not the same (%s %s d.%#x)",
1361                                $what, $against, $build, $differs)
1362                         if $differs & ~($allow | D_PAT_ADD);
1363                 };
1364
1365                 # Breakwater changes which were in each side of the
1366                 # merge will have been incorporated into the
1367                 # MergeCreateMergedBreakwaters output.  Because the
1368                 # upstream series was rebased onto the new breakwater,
1369                 # so should all of the packaging changes which were in
1370                 # the input.
1371                 $check->($input, D_UPS, 'debian files');
1372
1373                 # Upstream files are merge_series, which ought to
1374                 # have been identical to the original merge.
1375                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1376
1377                 print "Merge resolution successful.\n";
1378                 next;
1379             } else {
1380                 confess "$method ?";
1381             }
1382             if (!$rewriting) {
1383                 my $procd = (pop @processed) // 'UNDEF';
1384                 if ($cl ne $procd) {
1385                     $rewriting = 1;
1386                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1387                 }
1388             }
1389             my $newtree = cmdoutput @git, qw(write-tree);
1390             my $ch = $cl->{Hdr};
1391             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1392             $ch =~ s{^parent .*\n}{}mg;
1393             $ch =~ s{(?=^author)}{
1394                 join '', map { "parent $_\n" } @parents
1395             }me or confess "$ch ?";
1396             if ($rewriting) {
1397                 $ch =~ s{^committer .*$}{$committer_authline}m
1398                     or confess "$ch ?";
1399             }
1400             my $cf = "$rd/m$rewriting";
1401             open CD, ">", $cf or die $!;
1402             print CD $ch, "\n", $cl->{Msg} or die $!;
1403             close CD or die $!;
1404             my @cmd = (@git, qw(hash-object));
1405             push @cmd, qw(-w) if $rewriting;
1406             push @cmd, qw(-t commit), $cf;
1407             my $newcommit = cmdoutput @cmd;
1408             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1409             $build = $newcommit;
1410             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1411                 $last_anchor = $cur;
1412             }
1413         }
1414     };
1415
1416     my $final_check = get_differs $build, $input;
1417     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1418         if $final_check & ~D_PAT_ADD;
1419
1420     my @r = ($build, $breakwater, $last_anchor);
1421     printdebug "*** WALK RETURN @r\n";
1422     return @r
1423 }
1424
1425 sub get_head () {
1426     git_check_unmodified();
1427     return git_rev_parse qw(HEAD);
1428 }
1429
1430 sub update_head ($$$) {
1431     my ($old, $new, $mrest) = @_;
1432     push @deferred_updates, "update HEAD $new $old";
1433     run_deferred_updates $mrest;
1434 }
1435
1436 sub update_head_checkout ($$$) {
1437     my ($old, $new, $mrest) = @_;
1438     update_head $old, $new, $mrest;
1439     runcmd @git, qw(reset --hard);
1440 }
1441
1442 sub update_head_postlaunder ($$$) {
1443     my ($old, $tip, $reflogmsg) = @_;
1444     return if $tip eq $old;
1445     print "git-debrebase: laundered (head was $old)\n";
1446     update_head $old, $tip, $reflogmsg;
1447     # no tree changes except debian/patches
1448     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1449 }
1450
1451 sub currently_rebasing() {
1452     foreach (qw(rebase-merge rebase-apply)) {
1453         return 1 if stat_exists "$maindir_gitdir/$_";
1454     }
1455     return 0;
1456 }
1457
1458 sub bail_if_rebasing() {
1459     fail "you are in the middle of a git-rebase already"
1460         if currently_rebasing();
1461 }
1462
1463 sub do_launder_head ($) {
1464     my ($reflogmsg) = @_;
1465     my $old = get_head();
1466     record_ffq_auto();
1467     my ($tip,$breakwater) = walk $old;
1468     snags_maybe_bail();
1469     update_head_postlaunder $old, $tip, $reflogmsg;
1470     return ($tip,$breakwater);
1471 }
1472
1473 sub cmd_launder_v0 () {
1474     badusage "no arguments to launder-v0 allowed" if @ARGV;
1475     my $old = get_head();
1476     my ($tip,$breakwater,$last_anchor) = walk $old;
1477     update_head_postlaunder $old, $tip, 'launder';
1478     printf "# breakwater tip\n%s\n", $breakwater;
1479     printf "# working tip\n%s\n", $tip;
1480     printf "# last anchor\n%s\n", $last_anchor;
1481 }
1482
1483 sub defaultcmd_rebase () {
1484     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1485     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1486     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1487 }
1488
1489 sub cmd_analyse () {
1490     badusage "analyse does not support any options"
1491         if @ARGV and $ARGV[0] =~ m/^-/;
1492     badusage "too many arguments to analyse" if @ARGV>1;
1493     my ($old) = @ARGV;
1494     if (defined $old) {
1495         $old = git_rev_parse $old;
1496     } else {
1497         $old = git_rev_parse 'HEAD';
1498     }
1499     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1500     STDOUT->error and die $!;
1501 }
1502
1503 sub ffq_prev_branchinfo () {
1504     my $current = git_get_symref();
1505     return gdr_ffq_prev_branchinfo($current);
1506 }
1507
1508 sub ffq_check ($;$$) {
1509     # calls $ff and/or $notff zero or more times
1510     # then returns either (status,message) where status is
1511     #    exists
1512     #    detached
1513     #    weird-symref
1514     #    notbranch
1515     # or (undef,undef, $ffq_prev,$gdrlast)
1516     # $ff and $notff are called like this:
1517     #   $ff->("message for stdout\n");
1518     #   $notff->('snag-name', $message);
1519     # normally $currentval should be HEAD
1520     my ($currentval, $ff, $notff) =@_;
1521
1522     $ff //= sub { print $_[0] or die $!; };
1523     $notff //= \&snag;
1524
1525     my ($status, $message, $current, $ffq_prev, $gdrlast)
1526         = ffq_prev_branchinfo();
1527     return ($status, $message) unless $status eq 'branch';
1528
1529     my $exists = git_get_ref $ffq_prev;
1530     return ('exists',"$ffq_prev already exists") if $exists;
1531
1532     return ('not-branch', 'HEAD symref is not to refs/heads/')
1533         unless $current =~ m{^refs/heads/};
1534     my $branch = $';
1535
1536     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1537     my %checked;
1538
1539     printdebug "ffq check_specs @check_specs\n";
1540
1541     my $check = sub {
1542         my ($lrref, $desc) = @_;
1543         printdebug "ffq might check $lrref ($desc)\n";
1544         my $invert;
1545         for my $chk (@check_specs) {
1546             my $glob = $chk;
1547             $invert = $glob =~ s{^[!^]}{};
1548             last if fnmatch $glob, $lrref;
1549         }
1550         return if $invert;
1551         my $lrval = git_get_ref $lrref;
1552         return unless length $lrval;
1553
1554         if (is_fast_fwd $lrval, $currentval) {
1555             $ff->("OK, you are ahead of $lrref\n");
1556             $checked{$lrref} = 1;
1557         } elsif (is_fast_fwd $currentval, $lrval) {
1558             $checked{$lrref} = -1;
1559             $notff->('behind', "you are behind $lrref, divergence risk");
1560         } else {
1561             $checked{$lrref} = -1;
1562             $notff->('diverged', "you have diverged from $lrref");
1563         }
1564     };
1565
1566     my $merge = cfg "branch.$branch.merge",1;
1567     if (defined $merge and $merge =~ m{^refs/heads/}) {
1568         my $rhs = $';
1569         printdebug "ffq merge $rhs\n";
1570         my $check_remote = sub {
1571             my ($remote, $desc) = @_;
1572             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1573             return unless defined $remote;
1574             $check->("refs/remotes/$remote/$rhs", $desc);
1575         };
1576         $check_remote->((scalar cfg "branch.$branch.remote",1),
1577                         'remote fetch/merge branch');
1578         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1579                         (scalar cfg "branch.$branch.pushDefault",1),
1580                         'remote push branch');
1581     }
1582     if ($branch =~ m{^dgit/}) {
1583         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1584     } elsif ($branch =~ m{^master$}) {
1585         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1586     }
1587     return (undef, undef, $ffq_prev, $gdrlast);
1588 }
1589
1590 sub record_ffq_prev_deferred () {
1591     # => ('status', "message")
1592     # 'status' may be
1593     #    deferred          message is undef
1594     #    exists
1595     #    detached
1596     #    weird-symref
1597     #    notbranch
1598     # if not ff from some branch we should be ff from, is an snag
1599     # if "deferred", will have added something about that to
1600     #   @deferred_update_messages, and also maybe printed (already)
1601     #   some messages about ff checks
1602     bail_if_rebasing();
1603     my $currentval = get_head();
1604
1605     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1606     return ($status,$message) if defined $status;
1607
1608     snags_maybe_bail();
1609
1610     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1611     push @deferred_updates, "delete $gdrlast";
1612     push @deferred_update_messages, "Recorded previous head for preservation";
1613     return ('deferred', undef);
1614 }
1615
1616 sub record_ffq_auto () {
1617     my ($status, $message) = record_ffq_prev_deferred();
1618     if ($status eq 'deferred' || $status eq 'exists') {
1619     } else {
1620         snag $status, "could not record ffq-prev: $message";
1621         snags_maybe_bail();
1622     }
1623 }
1624
1625 sub ffq_prev_info () {
1626     bail_if_rebasing();
1627     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1628     my ($status, $message, $current, $ffq_prev, $gdrlast)
1629         = ffq_prev_branchinfo();
1630     if ($status ne 'branch') {
1631         snag $status, "could not check ffq-prev: $message";
1632         snags_maybe_bail();
1633     }
1634     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1635     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1636 }
1637
1638 sub stitch ($$$$$) {
1639     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1640
1641     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1642
1643     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1644         my $differs = get_differs $old_head, $ffq_prev_commitish;
1645         unless ($differs & ~D_PAT_ADD) {
1646             # ffq-prev is ahead of us, and the only tree changes it has
1647             # are possibly addition of things in debian/patches/.
1648             # Just wind forwards rather than making a pointless pseudomerge.
1649             push @deferred_updates,
1650                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1651             update_head_checkout $old_head, $ffq_prev_commitish,
1652                 "stitch (fast forward)";
1653             return;
1654         }
1655     }
1656     fresh_workarea();
1657     # We make pseudomerges with L as the contributing parent.
1658     # This makes git rev-list --first-parent work properly.
1659     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1660         'Declare fast forward / record previous work',
1661         "[git-debrebase pseudomerge: $prose]",
1662     ];
1663     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1664     update_head $old_head, $new_head, "stitch: $prose";
1665 }
1666
1667 sub do_stitch ($;$) {
1668     my ($prose, $unclean) = @_;
1669
1670     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1671     if (!$ffq_prev_commitish) {
1672         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1673         return;
1674     }
1675     my $dangling_head = get_head();
1676
1677     keycommits $dangling_head, $unclean,$unclean,$unclean;
1678     snags_maybe_bail();
1679
1680     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1681 }
1682
1683 sub upstream_commitish_search ($$) {
1684     my ($upstream_version, $tried) = @_;
1685     # todo: at some point maybe use git-deborig to do this
1686     foreach my $tagpfx ('', 'v', 'upstream/') {
1687         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1688         my $new_upstream = git_get_ref "refs/tags/$tag";
1689         push @$tried, $tag;
1690         return $new_upstream if length $new_upstream;
1691     }
1692 }
1693
1694 sub resolve_upstream_version ($$) {
1695     my ($new_upstream, $upstream_version) = @_;
1696
1697     if (!defined $new_upstream) {
1698         my @tried;
1699         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1700         if (!length $new_upstream) {
1701             fail "Could not determine appropriate upstream commitish.\n".
1702                 " (Tried these tags: @tried)\n".
1703                 " Check version, and specify upstream commitish explicitly.";
1704         }
1705     }
1706     $new_upstream = git_rev_parse $new_upstream;
1707
1708     return $new_upstream;
1709 }
1710
1711 sub cmd_new_upstream () {
1712     # automatically and unconditionally launders before rebasing
1713     # if rebase --abort is used, laundering has still been done
1714
1715     my %pieces;
1716
1717     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1718
1719     # parse args - low commitment
1720     my $spec_version = shift @ARGV;
1721     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1722     fail "bad version number \`$spec_version'" unless defined $new_version;
1723     if ($new_version->is_native()) {
1724         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1725     }
1726
1727     my $new_upstream = shift @ARGV;
1728     my $new_upstream_version = upstreamversion  $new_version;
1729     $new_upstream =
1730         resolve_upstream_version $new_upstream, $new_upstream_version;
1731
1732     record_ffq_auto();
1733
1734     my $piece = sub {
1735         my ($n, @x) = @_; # may be ''
1736         my $pc = $pieces{$n} //= {
1737             Name => $n,
1738             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1739         };
1740         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1741         $pc;
1742     };
1743
1744     my @newpieces;
1745     my $newpiece = sub {
1746         my ($n, @x) = @_; # may be ''
1747         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1748         push @newpieces, $pc;
1749     };
1750
1751     $newpiece->('',
1752         OldIx => 0,
1753         New => $new_upstream,
1754     );
1755     while (@ARGV && $ARGV[0] !~ m{^-}) {
1756         my $n = shift @ARGV;
1757
1758         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1759             unless @ARGV && $ARGV[0] !~ m{^-};
1760
1761         my $c = git_rev_parse shift @ARGV;
1762         die unless $n =~ m/^$extra_orig_namepart_re$/;
1763         $newpiece->($n, New => $c);
1764     }
1765
1766     # now we need to investigate the branch this generates the
1767     # laundered version but we don't switch to it yet
1768     my $old_head = get_head();
1769     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1770
1771     my $old_bw_cl = classify $old_bw;
1772     my $old_anchor_cl = classify $old_anchor;
1773     my $old_upstream;
1774     if (!$old_anchor_cl->{OrigParents}) {
1775         snag 'anchor-treated',
1776             'old anchor is recognised due to --anchor, cannot check upstream';
1777     } else {
1778         $old_upstream = parsecommit
1779             $old_anchor_cl->{OrigParents}[0]{CommitId};
1780         $piece->('', Old => $old_upstream->{CommitId});
1781     }
1782
1783     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1784         if ($old_upstream->{Msg} =~
1785  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1786            ) {
1787             my @oldpieces = (split / /, $1);
1788             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1789             if ($old_n_parents != @oldpieces &&
1790                 $old_n_parents != @oldpieces + 1) {
1791                 snag 'upstream-confusing', sprintf
1792                     "previous upstream combine %s".
1793                     " mentions %d pieces (each implying one parent)".
1794                     " but has %d parents".
1795                     " (one per piece plus maybe a previous combine)",
1796                     $old_upstream->{CommitId},
1797                     (scalar @oldpieces),
1798                     $old_n_parents;
1799             } elsif ($oldpieces[0] ne '.') {
1800                 snag 'upstream-confusing', sprintf
1801                     "previous upstream combine %s".
1802                     " first piece is not \`.'",
1803                     $oldpieces[0];
1804             } else {
1805                 $oldpieces[0] = '';
1806                 foreach my $i (0..$#oldpieces) {
1807                     my $n = $oldpieces[$i];
1808                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1809                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1810                 }
1811             }
1812         } else {
1813             snag 'upstream-confusing',
1814                 "previous upstream $old_upstream->{CommitId} is from".
1815                " git-debrebase but not an \`upstream-combine' commit";
1816         }
1817     }
1818
1819     foreach my $pc (values %pieces) {
1820         if (!$old_upstream) {
1821             # we have complained already
1822         } elsif (!$pc->{Old}) {
1823             snag 'upstream-new-piece',
1824                 "introducing upstream piece \`$pc->{Name}'";
1825         } elsif (!$pc->{New}) {
1826             snag 'upstream-rm-piece',
1827                 "dropping upstream piece \`$pc->{Name}'";
1828         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1829             snag 'upstream-not-ff',
1830                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1831         }
1832     }
1833
1834     printdebug "%pieces = ", (dd \%pieces), "\n";
1835     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1836
1837     snags_maybe_bail();
1838
1839     my $new_bw;
1840
1841     fresh_workarea();
1842     in_workarea sub {
1843         my @upstream_merge_parents;
1844
1845         if (!any_snags()) {
1846             push @upstream_merge_parents, $old_upstream->{CommitId};
1847         }
1848
1849         foreach my $pc (@newpieces) { # always has '' first
1850             if ($pc->{Name}) {
1851                 read_tree_subdir $pc->{Name}, $pc->{New};
1852             } else {
1853                 runcmd @git, qw(read-tree), $pc->{New};
1854             }
1855             push @upstream_merge_parents, $pc->{New};
1856         }
1857
1858         # index now contains the new upstream
1859
1860         if (@newpieces > 1) {
1861             # need to make the upstream subtree merge commit
1862             $new_upstream = make_commit \@upstream_merge_parents,
1863                 [ "Combine upstreams for $new_upstream_version",
1864  ("[git-debrebase upstream-combine . ".
1865  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1866  ": new upstream]"),
1867                 ];
1868         }
1869
1870         # $new_upstream is either the single upstream commit, or the
1871         # combined commit we just made.  Either way it will be the
1872         # "upstream" parent of the anchor merge.
1873
1874         read_tree_subdir 'debian', "$old_bw:debian";
1875
1876         # index now contains the anchor merge contents
1877         $new_bw = make_commit [ $old_bw, $new_upstream ],
1878             [ "Update to upstream $new_upstream_version",
1879  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1880             ];
1881
1882         my $clogsignoff = cmdoutput qw(git show),
1883             '--pretty=format:%an <%ae>  %aD',
1884             $new_bw;
1885
1886         # Now we have to add a changelog stanza so the Debian version
1887         # is right.
1888         die if unlink "debian";
1889         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1890         unlink "debian/changelog" or $!==ENOENT or die $!;
1891         mkdir "debian" or die $!;
1892         open CN, ">", "debian/changelog" or die $!;
1893         my $oldclog = git_cat_file ":debian/changelog";
1894         $oldclog =~ m/^($package_re) \(\S+\) / or
1895             fail "cannot parse old changelog to get package name";
1896         my $p = $1;
1897         print CN <<END, $oldclog or die $!;
1898 $p ($new_version) UNRELEASED; urgency=medium
1899
1900   * Update to new upstream version $new_upstream_version.
1901
1902  -- $clogsignoff
1903
1904 END
1905         close CN or die $!;
1906         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1907
1908         # Now we have the final new breakwater branch in the index
1909         $new_bw = make_commit [ $new_bw ],
1910             [ "Update changelog for new upstream $new_upstream_version",
1911               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1912             ];
1913     };
1914
1915     # we have constructed the new breakwater. we now need to commit to
1916     # the laundering output, because git-rebase can't easily be made
1917     # to make a replay list which is based on some other branch
1918
1919     update_head_postlaunder $old_head, $old_laundered_tip,
1920         'launder for new upstream';
1921
1922     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1923     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1924         "debrebase new-upstream $new_version: rebase";
1925     runcmd @cmd;
1926     # now it's for the user to sort out
1927 }
1928
1929 sub cmd_record_ffq_prev () {
1930     badusage "no arguments allowed" if @ARGV;
1931     my ($status, $msg) = record_ffq_prev_deferred();
1932     if ($status eq 'exists' && $opt_noop_ok) {
1933         print "Previous head already recorded\n" or die $!;
1934     } elsif ($status eq 'deferred') {
1935         run_deferred_updates 'record-ffq-prev';
1936     } else {
1937         fail "Could not preserve: $msg";
1938     }
1939 }
1940
1941 sub cmd_anchor () {
1942     badusage "no arguments allowed" if @ARGV;
1943     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1944     print "$bw\n" or die $!;
1945 }
1946
1947 sub cmd_breakwater () {
1948     badusage "no arguments allowed" if @ARGV;
1949     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1950     print "$bw\n" or die $!;
1951 }
1952
1953 sub cmd_status () {
1954     badusage "no arguments allowed" if @ARGV;
1955
1956     # todo: gdr status should print divergence info
1957     # todo: gdr status should print upstream component(s) info
1958     # todo: gdr should leave/maintain some refs with this kind of info ?
1959
1960     my $oldest = { Badness => 0 };
1961     my $newest;
1962     my $note = sub {
1963         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1964         if ($oldest->{Badness} < $badness) {
1965             $oldest = $newest = undef;
1966         }
1967         $oldest = {
1968                    Badness => $badness,
1969                    CommitId => $cl->{CommitId},
1970                    OurMsg => $ourmsg,
1971                    KcMsg => $kcmsg,
1972                   };
1973         $newest //= $oldest;
1974     };
1975     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1976         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1977         sub { $note->(2, 'branch is unlaundered', @_); },
1978         sub { $note->(3, 'branch needs laundering', @_); },
1979         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1980
1981     my $prcommitinfo = sub {
1982         my ($cid) = @_;
1983         flush STDOUT or die $!;
1984         runcmd @git, qw(--no-pager log -n1),
1985             '--pretty=format:    %h %s%n',
1986             $cid;
1987     };
1988
1989     print "current branch contents, in git-debrebase terms:\n";
1990     if (!$oldest->{Badness}) {
1991         print "  branch is laundered\n";
1992     } else {
1993         print "  $oldest->{OurMsg}\n";
1994         my $printed = '';
1995         foreach my $info ($oldest, $newest) {
1996             my $cid = $info->{CommitId};
1997             next if $cid eq $printed;
1998             $printed = $cid;
1999             print "  $info->{KcMsg}\n";
2000             $prcommitinfo->($cid);
2001         }
2002     }
2003
2004     my $prab = sub {
2005         my ($cid, $what) = @_;
2006         if (!defined $cid) {
2007             print "  $what is not well-defined\n";
2008         } else {
2009             print "  $what\n";
2010             $prcommitinfo->($cid);
2011         }
2012     };
2013     print "key git-debrebase commits:\n";
2014     $prab->($anchor, 'anchor');
2015     $prab->($bw, 'breakwater');
2016
2017     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2018         ffq_prev_branchinfo();
2019
2020     print "branch and ref status, in git-debrebase terms:\n";
2021     if ($ffq_msg) {
2022         print "  $ffq_msg\n";
2023     } else {
2024         $ffq_prev = git_get_ref $ffq_prev;
2025         $gdrlast = git_get_ref $gdrlast;
2026         if ($ffq_prev) {
2027             print "  unstitched; previous tip was:\n";
2028             $prcommitinfo->($ffq_prev);
2029         } elsif (!$gdrlast) {
2030             print "  stitched? (no record of git-debrebase work)\n";
2031         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2032             print "  stitched\n";
2033         } else {
2034             print "  not git-debrebase (diverged since last stitch)\n"
2035         }
2036     }
2037     print "you are currently rebasing\n" if currently_rebasing();
2038 }
2039
2040 sub cmd_stitch () {
2041     my $prose = 'stitch';
2042     getoptions("stitch",
2043                'prose=s', \$prose);
2044     badusage "no arguments allowed" if @ARGV;
2045     do_stitch $prose, 0;
2046 }
2047 sub cmd_prepush () { cmd_stitch(); }
2048
2049 sub cmd_quick () {
2050     badusage "no arguments allowed" if @ARGV;
2051     do_launder_head 'launder for git-debrebase quick';
2052     do_stitch 'quick';
2053 }
2054
2055 sub cmd_conclude () {
2056     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2057     if (!$ffq_prev_commitish) {
2058         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2059         return;
2060     }
2061     my $dangling_head = get_head();
2062
2063     badusage "no arguments allowed" if @ARGV;
2064     do_launder_head 'launder for git-debrebase quick';
2065     do_stitch 'quick';
2066 }
2067
2068 sub cmd_scrap () {
2069     if (currently_rebasing()) {
2070         runcmd @git, qw(rebase --abort);
2071     }
2072     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2073     if (!$ffq_prev_commitish) {
2074         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2075         finish 0;
2076     }
2077     my $scrapping_head = get_head();
2078     badusage "no arguments allowed" if @ARGV;
2079     push @deferred_updates,
2080         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2081         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2082     snags_maybe_bail();
2083     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2084 }
2085
2086 sub make_patches_staged ($) {
2087     my ($head) = @_;
2088     # Produces the patches that would result from $head if it were
2089     # laundered.
2090     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2091     fresh_workarea();
2092     in_workarea sub {
2093         gbp_pq_export 'bw', $secret_bw, $secret_head;
2094     };
2095 }
2096
2097 sub make_patches ($) {
2098     my ($head) = @_;
2099     keycommits $head, 0, \&snag;
2100     make_patches_staged $head;
2101     my $out;
2102     in_workarea sub {
2103         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2104         runcmd @git, qw(read-tree), $head;
2105         read_tree_subdir 'debian/patches', $ptree;
2106         $out = make_commit [$head], [
2107             'Commit patch queue (exported by git-debrebase)',
2108             '[git-debrebase: export and commit patches]',
2109         ];
2110     };
2111     return $out;
2112 }
2113
2114 sub cmd_make_patches () {
2115     my $opt_quiet_would_amend;
2116     getoptions("make-patches",
2117                'quiet-would-amend!', \$opt_quiet_would_amend);
2118     badusage "no arguments allowed" if @ARGV;
2119     bail_if_rebasing();
2120     my $old_head = get_head();
2121     my $new = make_patches $old_head;
2122     my $d = get_differs $old_head, $new;
2123     if ($d == 0) {
2124         fail "No (more) patches to export." unless $opt_noop_ok;
2125         return;
2126     } elsif ($d == D_PAT_ADD) {
2127         snags_maybe_bail();
2128         update_head_checkout $old_head, $new, 'make-patches';
2129     } else {
2130         print STDERR failmsg
2131             "Patch export produced patch amendments".
2132             " (abandoned output commit $new).".
2133             "  Try laundering first."
2134             unless $opt_quiet_would_amend;
2135         finish 7;
2136     }
2137 }
2138
2139 sub cmd_convert_from_gbp () {
2140     badusage "want only 1 optional argument, the upstream git commitish"
2141         unless @ARGV<=1;
2142
2143     my $clogp = parsechangelog();
2144     my $version = $clogp->{'Version'}
2145         // die "missing Version from changelog";
2146
2147     my ($upstream_spec) = @ARGV;
2148
2149     my $upstream_version = upstreamversion $version;
2150     my $upstream =
2151         resolve_upstream_version($upstream_spec, $upstream_version);
2152
2153     my $old_head = get_head();
2154
2155     my $upsdiff = get_differs $upstream, $old_head;
2156     if ($upsdiff & D_UPS) {
2157         runcmd @git, qw(--no-pager diff --stat),
2158             $upstream, $old_head,
2159             qw( -- :!/debian :/);
2160         fail <<END;
2161 upstream ($upstream_spec) and HEAD are not
2162 identical in upstream files.  See diffstat above, or run
2163   git diff $upstream_spec HEAD -- :!/debian :/
2164 END
2165     }
2166
2167     if (!is_fast_fwd $upstream, $old_head) {
2168         snag 'upstream-not-ancestor',
2169             "upstream ($upstream) is not an ancestor of HEAD";
2170     } else {
2171         my $wrong = cmdoutput
2172             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2173              qw(-- :/ :!/debian));
2174         if (length $wrong) {
2175             snag 'unexpected-upstream-changes',
2176                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2177             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2178         }
2179     }
2180
2181     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2182         snag 'upstream-has-debian',
2183             "upstream ($upstream) contains debian/ directory";
2184     }
2185
2186     my $previous_dgit_view = eval {
2187         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2188         my ($lvsn, $suite);
2189         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2190             my ($stz, $desc) = @_;
2191             no warnings qw(exiting);
2192             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2193             next unless $stz->{Date};
2194             next unless $stz->{Distribution} ne 'UNRELEASED';
2195             $lvsn = $stz->{Version};
2196             $suite = $stz->{Distribution};
2197             last;
2198         };
2199         die "neither of the first two changelog entries are released\n"
2200             unless defined $lvsn;
2201         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2202         my $mtag_pat = debiantag_maintview $lvsn, '*';
2203         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2204             $mtag_pat;
2205         die "could not find suitable maintainer view tag $mtag_pat\n"
2206             unless $mtag_pat =~ m{/};
2207         is_fast_fwd $mtag, 'HEAD' or
2208             die "HEAD is not FF from maintainer tag $mtag!";
2209         my $dtag = "archive/$mtag";
2210         is_fast_fwd $mtag, $dtag or
2211             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2212         print "will stitch in dgit view, $dtag\n";
2213         git_rev_parse $dtag;
2214     };
2215     if (!$previous_dgit_view) {
2216         $@ =~ s/^\n+//;
2217         chomp $@;
2218         print STDERR "cannot stitch in dgit view: $@\n";
2219     }
2220
2221     snags_maybe_bail_early();
2222
2223     my $work;
2224
2225     fresh_workarea();
2226     in_workarea sub {
2227         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2228         # make a branch out of the patch queue - we'll want this in a mo
2229         runcmd qw(gbp pq import);
2230         # strip the patches out
2231         runcmd @git, qw(checkout -q gdr-internal~0);
2232         rm_subdir_cached 'debian/patches';
2233         $work = make_commit ['HEAD'], [
2234  'git-debrebase convert-from-gbp: drop patches from tree',
2235  'Delete debian/patches, as part of converting to git-debrebase format.',
2236  '[git-debrebase convert-from-gbp: drop patches from tree]'
2237                               ];
2238         # make the anchor merge
2239         # the tree is already exactly right
2240         $work = make_commit [$work, $upstream], [
2241  'git-debrebase import: declare upstream',
2242  'First breakwater merge.',
2243  '[git-debrebase anchor: declare upstream]'
2244                               ];
2245
2246         # rebase the patch queue onto the new breakwater
2247         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2248         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2249         $work = git_rev_parse 'HEAD';
2250
2251         if ($previous_dgit_view) {
2252             $work = make_commit [$work, $previous_dgit_view], [
2253  'git-debrebase import: declare ff from dgit archive view',
2254  '[git-debrebase pseudomerge: import-from-gbp]',
2255             ];
2256         }
2257     };
2258
2259     ffq_check $work;
2260     snags_maybe_bail();
2261     update_head_checkout $old_head, $work, 'convert-from-gbp';
2262 }
2263
2264 sub cmd_convert_to_gbp () {
2265     badusage "no arguments allowed" if @ARGV;
2266     my $head = get_head();
2267     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2268     keycommits $head, 0;
2269     my $out;
2270     make_patches_staged $head;
2271     in_workarea sub {
2272         $out = make_commit ['HEAD'], [
2273             'Commit patch queue (converted from git-debrebase format)',
2274             '[git-debrebase convert-to-gbp: commit patches]',
2275         ];
2276     };
2277     if (defined $ffq) {
2278         push @deferred_updates, "delete $ffq";
2279         push @deferred_updates, "delete $gdrlast";
2280     }
2281     snags_maybe_bail();
2282     update_head_checkout $head, $out, "convert to gbp (v0)";
2283     print <<END or die $!;
2284 git-debrebase: converted to git-buildpackage branch format
2285 git-debrebase: WARNING: do not now run "git-debrebase" any more
2286 git-debrebase: WARNING: doing so would drop all upstream patches!
2287 END
2288 }
2289
2290 sub cmd_convert_from_dgit_view () {
2291     my $clogp = parsechangelog();
2292
2293     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2294     my $do_origs = 1;
2295     my $do_tags = 1;
2296     my $always = 0;
2297     my $diagnose = 0;
2298
2299     getoptions("convert-from-dgit-view",
2300                'diagnose!', \$diagnose,
2301                'build-products-dir:s', \$bpd,
2302                'origs!', \$do_origs,
2303                'tags!', \$do_tags,
2304                'always-convert-anyway!', \$always);
2305     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2306
2307     my @upstreams;
2308
2309     if (@ARGV) {
2310         my $spec = shift @ARGV;
2311         my $commit = git_rev_parse "$spec^{commit}";
2312         push @upstreams, { Commit => $commit,
2313                            Source => "$ARGV[0], from command line",
2314                            Only => 1,
2315                          };
2316     }
2317
2318     my $head = get_head();
2319
2320     if (!$always) {
2321         my $troubles = 0;
2322         my $trouble = sub { $troubles++; };
2323         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2324         printdebug "troubles=$troubles\n";
2325         if (!$troubles) {
2326             print STDERR <<END;
2327 $us: Branch already seems to be in git-debrebase format!
2328 $us: --always-convert-anyway would do the conversion operation anyway
2329 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2330 END
2331             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2332             finish 0;
2333         }
2334     }
2335
2336     snags_maybe_bail_early();
2337
2338     my $version = upstreamversion $clogp->{Version};
2339     print STDERR "Considering possible commits corresponding to upstream:\n";
2340
2341     if (!@upstreams) {
2342         if ($do_tags) {
2343             my @tried;
2344             my $ups_tag = upstream_commitish_search $version, \@tried;
2345             if ($ups_tag) {
2346                 my $this = "git tag $tried[-1]";
2347                 push @upstreams, { Commit => $ups_tag,
2348                                    Source => $this,
2349                                  };
2350             } else {
2351                 printf STDERR
2352                     " git tag: no suitable tag found (tried %s)\n",
2353                     "@tried";
2354             }
2355         }
2356         if ($do_origs) {
2357             my $p = $clogp->{'Source'};
2358             # we do a quick check to see if there are plausible origs
2359             my $something=0;
2360             if (!opendir BPD, $bpd) {
2361                 die "$bpd: opendir: $!" unless $!==ENOENT;
2362             } else {
2363                 while ($!=0, my $f = readdir BPD) {
2364                     next unless is_orig_file_of_p_v $f, $p, $version;
2365                     printf STDERR
2366                         " orig: found what looks like a .orig, %s\n",
2367                         "$bpd/$f";
2368                     $something=1;
2369                     last;
2370                 }
2371                 die "read $bpd: $!" if $!;
2372                 closedir BPD;
2373             }
2374             if ($something) {
2375                 my $tree = cmdoutput
2376                     @dgit, qw(--build-products-dir), $bpd,
2377                     qw(print-unapplied-treeish);
2378                 fresh_workarea();
2379                 in_workarea sub {
2380                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2381                     rm_subdir_cached 'debian';
2382                     $tree = cmdoutput @git, qw(write-tree);
2383                     my $ups_synth = make_commit [], [ <<END, <<END,
2384 Import effective orig tree for upstream version $version
2385 END
2386 This includes the contents of the .orig(s), minus any debian/ directory.
2387
2388 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2389 END
2390                                                     ];
2391                     push @upstreams, { Commit => $ups_synth,
2392                                        Source => "orig(s) imported via dgit",
2393                                      };
2394                 }
2395             } else {
2396                 printf STDERR
2397                     " orig: no suitable origs found (looked for %s in %s)\n",
2398                     "${p}_".(stripeoch $version)."...", $bpd;
2399             }
2400         }
2401     }
2402
2403     my $some_patches = stat_exists 'debian/patches/series';
2404
2405     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2406
2407     my $result;
2408     foreach my $u (@upstreams) {
2409         my $work = $head;
2410         fresh_workarea();
2411         in_workarea sub {
2412             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2413             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2414             runcmd @git, qw(clean -xdff);
2415             runcmd @git, qw(checkout), $head, qw(-- debian);
2416             if ($some_patches) {
2417                 rm_subdir_cached 'debian/patches';
2418                 $work = make_commit [ $work ], [
2419  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2420  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2421  "to git-debrebase format.  Upstream changes will appear as commits.",
2422  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2423                                            ];
2424             }
2425             $work = make_commit [ $work, $u->{Commit} ], [
2426  'git-debrebase convert-from-dgit-view: declare upstream',
2427  '(Re)constructed breakwater merge.',
2428  '[git-debrebase anchor: declare upstream]'
2429                                                          ];
2430             runcmd @git, qw(checkout --quiet -b mk), $work;
2431             if ($some_patches) {
2432                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2433                 runcmd @git, qw(reset --quiet);
2434                 my @gbp_cmd = (qw(gbp pq import));
2435                 if (!$diagnose) {
2436                     my $gbp_err = "../gbp-pq-err";
2437                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2438                 }
2439                 my $r = system @gbp_cmd;
2440                 if ($r) {
2441                     printf STDERR
2442                         " %s: couldn't apply patches: gbp pq %s",
2443                         $u->{Source}, waitstatusmsg();
2444                     return;
2445                 }
2446             }
2447             my $work = git_rev_parse qw(HEAD);
2448             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2449             if (length $diffout) {
2450                 print STDERR
2451                     " $u->{Source}: applying patches gives different tree\n";
2452                 print STDERR $diffout if $diagnose;
2453                 return;
2454             }
2455             # OMG!
2456             $u->{Result} = $work;
2457             $result = $u;
2458         };
2459         last if $result;
2460     }
2461
2462     if (!$result) {
2463         fail <<END;
2464 Could not find or construct a suitable upstream commit.
2465 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2466 upstream commmit explicitly or provide suitable origs.
2467 END
2468     }
2469
2470     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2471
2472     ffq_check $result->{Result};
2473     snags_maybe_bail();
2474     update_head_checkout $head, $result->{Result},
2475         'convert-from-dgit-view';
2476 }
2477
2478 sub cmd_downstream_rebase_launder_v0 () {
2479     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2480     my ($base) = @ARGV;
2481     $base = git_rev_parse $base;
2482     my $old_head = get_head();
2483     my $current = $old_head;
2484     my $topmost_keep;
2485     for (;;) {
2486         if ($current eq $base) {
2487             $topmost_keep //= $current;
2488             print " $current BASE stop\n";
2489             last;
2490         }
2491         my $cl = classify $current;
2492         print " $current $cl->{Type}";
2493         my $keep = 0;
2494         my $p0 = $cl->{Parents}[0]{CommitId};
2495         my $next;
2496         if ($cl->{Type} eq 'Pseudomerge') {
2497             print " ^".($cl->{Contributor}{Ix}+1);
2498             $next = $cl->{Contributor}{CommitId};
2499         } elsif ($cl->{Type} eq 'AddPatches' or
2500                  $cl->{Type} eq 'Changelog') {
2501             print " strip";
2502             $next = $p0;
2503         } else {
2504             print " keep";
2505             $next = $p0;
2506             $keep = 1;
2507         }
2508         print "\n";
2509         if ($keep) {
2510             $topmost_keep //= $current;
2511         } else {
2512             die "to-be stripped changes not on top of the branch\n"
2513                 if $topmost_keep;
2514         }
2515         $current = $next;
2516     }
2517     if ($topmost_keep eq $old_head) {
2518         print "unchanged\n";
2519     } else {
2520         print "updating to $topmost_keep\n";
2521         update_head_checkout
2522             $old_head, $topmost_keep,
2523             'downstream-rebase-launder-v0';
2524     }
2525 }
2526
2527 getoptions_main
2528           ("bad options\n",
2529            "D+" => \$debuglevel,
2530            'noop-ok', => \$opt_noop_ok,
2531            'f=s' => \@snag_force_opts,
2532            'anchor=s' => \@opt_anchors,
2533            '--dgit=s' => \($dgit[0]),
2534            'force!',
2535            '-i:s' => sub {
2536                my ($opt,$val) = @_;
2537                badusage "git-debrebase: no cuddling to -i for git-rebase"
2538                    if length $val;
2539                die if $opt_defaultcmd_interactive; # should not happen
2540                $opt_defaultcmd_interactive = [ qw(-i) ];
2541                # This access to @ARGV is excessive familiarity with
2542                # Getopt::Long, but there isn't another sensible
2543                # approach.  '-i=s{0,}' does not work with bundling.
2544                push @$opt_defaultcmd_interactive, @ARGV;
2545                @ARGV=();
2546            },
2547            'help' => sub { print $usage_message or die $!; finish 0; },
2548            );
2549
2550 initdebug('git-debrebase ');
2551 enabledebug if $debuglevel;
2552
2553 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2554 chdir $toplevel or die "chdir $toplevel: $!";
2555
2556 $rd = fresh_playground "$playprefix/misc";
2557
2558 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2559
2560 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2561     defaultcmd_rebase();
2562 } else {
2563     my $cmd = shift @ARGV;
2564     my $cmdfn = $cmd;
2565     $cmdfn =~ y/-/_/;
2566     $cmdfn = ${*::}{"cmd_$cmdfn"};
2567
2568     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2569     $cmdfn->();
2570 }
2571
2572 finish 0;