git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$) {
 267     my ($treeish, $keep_patches) = @_;
 268     my $save = cmdoutput @git, qw(write-tree --prefix=debian/);
 269     runcmd @git, qw(read-tree), $treeish;
 270     read_tree_subdir 'debian', $save;
 271     rm_subdir_cached 'debian/patches' unless $keep_patches;
 272 };
 273
 274 sub make_commit ($$) {
 275     my ($parents, $message_paras) = @_;
 276     my $tree = cmdoutput @git, qw(write-tree);
 277     my @cmd = (@git, qw(commit-tree), $tree);
 278     push @cmd, qw(-p), $_ foreach @$parents;
 279     push @cmd, qw(-m), $_ foreach @$message_paras;
 280     return cmdoutput @cmd;
 281 }
 282
 283 our @snag_force_opts;
 284 sub snag ($$;@) {
 285     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 286     if (grep { $_ eq $tag } @snag_force_opts) {
 287         $snags_forced++;
 288         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 289     } else {
 290         $snags_tripped++;
 291         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 292     }
 293 }
 294
 295 # Important: all mainline code must call snags_maybe_bail after
 296 # any point where snag might be called, but before making changes
 297 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 298 # may be called more than once if necessary (but this is not ideal
 299 # because then the messages about number of snags may be confusing).
 300 sub snags_maybe_bail () {
 301     return if all_snags_summarised();
 302     if ($snags_forced) {
 303         printf STDERR
 304             "%s: snags: %d overriden by individual -f options\n",
 305             $us, $snags_forced;
 306     }
 307     if ($snags_tripped) {
 308         if ($opt_force) {
 309             printf STDERR
 310                 "%s: snags: %d overriden by global --force\n",
 311                 $us, $snags_tripped;
 312         } else {
 313             fail sprintf
 314   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 315                 $us, $snags_tripped;
 316         }
 317     }
 318     $snags_summarised = $snags_forced + $snags_tripped;
 319 }
 320 sub snags_maybe_bail_early () {
 321     # useful to bail out early without doing a lot of work;
 322     # not a substitute for snags_maybe_bail.
 323     snags_maybe_bail() if $snags_tripped && !$opt_force;
 324 }
 325 sub any_snags () {
 326     return $snags_forced || $snags_tripped;
 327 }
 328
 329 sub gbp_pq_export ($$$) {
 330     my ($bname, $base, $tip) = @_;
 331     # must be run in a workarea.  $bname and patch-queue/$bname
 332     # ought not to exist.  Leaves you on patch-queue/$bname with
 333     # the patches staged but not committed.
 334     printdebug "gbp_pq_export $bname $base $tip\n";
 335     runcmd @git, qw(checkout -q -b), $bname, $base;
 336     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 337     my @gbp_cmd = (qw(gbp pq export));
 338     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 339     if ($r) {
 340         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 341         failedcmd @gbp_cmd;
 342     }
 343     runcmd @git, qw(add -f debian/patches);
 344 }
 345
 346
 347 # xxx allow merge separately from laundering
 348 #
 349 # xxx docs highlight forbidden things
 350 # xxx docs list allowable things ?
 351 # xxx docs explicitly forbid some rebase
 352 #
 353 # xxx provide a way for the user to help
 354 # xxx (eg, provide wreckage provide way to continue)
 355
 356 # later/rework?
 357 #  use git-format-patch?
 358 #  our own patch identification algorithm?
 359 #  this is an alternative strategy
 360
 361 sub merge_series ($$;@) {
 362     my ($newbase, $base_q, @input_qs) = @_;
 363     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 364     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 365     # ^ specifies several patch series (currently we only support exactly 2)
 366     # return value is a commit which is the result of
 367     # merging the two versions of the same topic branch
 368     #   $input_q[0] and $input_q[1]
 369     # with respect to the old version
 370     #   $base_q
 371     # all onto $newbase.
 372
 373     # Creates, in *_q, a key MR for its private use
 374
 375     printdebug "merge_series newbase=$newbase\n";
 376
 377     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 378     $base_q->{MR}{S} = 'base';
 379
 380     my %prereq;
 381     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 382     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 383     # $prereq{<patch filename>}               exists or not (even later)
 384
 385     my $result;
 386
 387     local $workarea = fresh_playground "$playprefix/merge";
 388     my $seriesfile = "debian/patches/series";
 389     in_workarea sub {
 390         playtree_setup();
 391         foreach my $q ($base_q, reverse @input_qs) {
 392             my $s = $q->{MR}{S};
 393             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 394             if (open S, $seriesfile) {
 395                 my @earlier;
 396                 while (my $patch = <S>) {
 397                     chomp $patch or die $!;
 398                     foreach my $earlier (@earlier) {
 399                         $prereq{$patch}{$earlier}{$s}++ and die;
 400                     }
 401                     push @earlier, $patch;
 402                     stat "debian/patches/$patch" or die "$patch ?";
 403                 }
 404                 S->error and die "$seriesfile $!";
 405                 close S;
 406             } else {
 407                 die "$seriesfile $!" unless $!==ENOENT;
 408             }
 409             read_tree_upstream $newbase, 1;
 410             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 411                 "Convert $s to patch queue for merging",
 412                 "[git-debrebase merge-innards patch-queue import:".
 413                 " $q->{SeriesTip}]"
 414             ];
 415             printdebug "merge_series  pec $pec ";
 416             runcmd @git, qw(rm -q --cached), $seriesfile;
 417             $pec = make_commit [ $pec ], [
 418                 "Drop series file from $s to avoid merge trouble",
 419                 "[git-debrebase merge-innards patch-queue prep:".
 420                 " $q->{SeriesTip}]"
 421             ];
 422             printdebug "pec' $pec\n";
 423             runcmd @git, qw(reset -q --hard), $pec;
 424             $q->{MR}{PEC} = $pec;
 425         }
 426         # now, because of reverse, we are on $input_q->{MR}{OQC}
 427         runcmd @git, qw(checkout -q -b merge);
 428         printdebug "merge_series merging...\n";
 429         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 430         debugcmd '+', @mergecmd;
 431         $!=0; $?=-1;
 432         if (system @mergecmd) {
 433             failedcmd @mergecmd;
 434         }
 435
 436         printdebug "merge_series merge ok, series...\n";
 437         # We need to construct a new series file
 438         # Firstly, resolve prereq
 439         foreach my $f (sort keys %prereq) {
 440             printdebug "merge_series  patch\t$f\t";
 441             if (!stat_exists "debian/patches/$f") {
 442                 print DEBUG " drop\n" if $debuglevel;
 443                 # git merge deleted it; that's how we tell it's not wanted
 444                 delete $prereq{$f};
 445                 next;
 446             }
 447             print DEBUG " keep\n" if $debuglevel;
 448             foreach my $g (sort keys %{ $prereq{$f} }) {
 449                 my $gfp = $prereq{$f}{$g};
 450                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 451                 if (!!$gfp->{0} == !!$gfp->{1}
 452                     ? $gfp->{0}
 453                     : !$gfp->{base}) {
 454                     print DEBUG "\tkeep\n" if $debuglevel;
 455                 } else {
 456                     print DEBUG "\tdrop\n" if $debuglevel;
 457                     delete $prereq{$f}{$g};
 458                 }
 459             }
 460         }
 461
 462         my $unsat = sub {
 463             my ($f) = @_;
 464             return scalar keys %{ $prereq{$f} };
 465         };
 466
 467         my $nodate = time + 1;
 468         my %authordate;
 469         # $authordate{<patch filename>};
 470         my $authordate = sub {
 471             my ($f) = @_;
 472             $authordate{$f} //= do {
 473                 open PF, "<", "debian/patches/$f" or die "$f $!";
 474                 while (<PF>) {
 475                     return $nodate if m/^$/;
 476                     last if s{^Date: }{};
 477                 }
 478                 chomp;
 479                 return cmdoutput qw(date +%s -d), $_;
 480             };
 481         };
 482
 483         open NS, '>', $seriesfile or die $!;
 484
 485         while (keys %prereq) {
 486             my $best;
 487             foreach my $try (sort keys %prereq) {
 488                 if ($best) {
 489                     next if (
 490                              $unsat->($try) <=> $unsat->($best) or
 491                              $authordate->($try) <=> $authordate->($best) or
 492                              $try cmp $best
 493                             ) >= 0;
 494                 }
 495                 $best = $try;
 496             }
 497             printdebug "merge_series series next $best\n";
 498             print NS "$best\n" or die $!;
 499             delete $prereq{$best};
 500             foreach my $gp (values %prereq) {
 501                 delete $gp->{$best};
 502             }
 503         }
 504
 505         runcmd @git, qw(add), $seriesfile;
 506         runcmd @git, qw(commit --quiet -m), 'Merged series';
 507
 508         printdebug "merge_series series gbp pq import\n";
 509         runcmd qw(gbp pq import);
 510
 511         # OK now we are on patch-queue/merge, and we need to rebase
 512         # onto the intended parent and drop the patches from each one
 513
 514         printdebug "merge_series series ok, building...\n";
 515         my $build = $newbase;
 516         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 517         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 518             my $commit = git_cat_file $c, 'commit';
 519             printdebug "merge_series series ok, building $c\n";
 520             read_tree_upstream $c;
 521             my $tree = cmdoutput @git, qw(write-tree);
 522             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 523             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 524             open C, ">", "../mcommit" or die $!;
 525             print C $commit or die $!;
 526             close C or die $!;
 527             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 528         }
 529         $result = $build;
 530         runcmd @git, qw(update-ref refs/heads/result), $result;
 531     };
 532     printdebug "merge_series returns $result\n";
 533     return $result;
 534 }
 535
 536 # classify returns an info hash like this
 537 #   CommitId => $objid
 538 #   Hdr => # commit headers, including 1 final newline
 539 #   Msg => # commit message (so one newline is dropped)
 540 #   Tree => $treeobjid
 541 #   Type => (see below)
 542 #   Parents = [ {
 543 #       Ix => $index # ie 0, 1, 2, ...
 544 #       CommitId
 545 #       Differs => return value from get_differs
 546 #       IsOrigin
 547 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 548 #     } ...]
 549 #   NewMsg => # commit message, but with any [dgit import ...] edited
 550 #             # to say "[was: ...]"
 551 #
 552 # Types:
 553 #   Packaging
 554 #   Changelog
 555 #   Upstream
 556 #   AddPatches
 557 #   Mixed
 558 #
 559 #   Pseudomerge
 560 #     has additional entres in classification result
 561 #       Overwritten = [ subset of Parents ]
 562 #       Contributor = $the_remaining_Parent
 563 #
 564 #   DgitImportUnpatched
 565 #     has additional entry in classification result
 566 #       OrigParents = [ subset of Parents ]
 567 #
 568 #   Anchor
 569 #     has additional entry in classification result
 570 #       OrigParents = [ subset of Parents ]  # singleton list
 571 #
 572 #   TreatAsAnchor
 573 #
 574 #   BreakwaterStart
 575 #
 576 #   Unknown
 577 #     has additional entry in classification result
 578 #       Why => "prose"
 579
 580 sub parsecommit ($;$) {
 581     my ($objid, $p_ref) = @_;
 582     # => hash with                   CommitId Hdr Msg Tree Parents
 583     #    Parents entries have only   Ix CommitId
 584     #    $p_ref, if provided, must be [] and is used as a base for Parents
 585
 586     $p_ref //= [];
 587     die if @$p_ref;
 588
 589     my ($h,$m) = get_commit $objid;
 590
 591     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 592     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 593
 594     my $r = {
 595         CommitId => $objid,
 596         Hdr => $h,
 597         Msg => $m,
 598         Tree => $t,
 599         Parents => $p_ref,
 600     };
 601
 602     foreach my $ph (@ph) {
 603         push @$p_ref, {
 604             Ix => scalar @$p_ref,
 605             CommitId => $ph,
 606         };
 607     }
 608
 609     return $r;
 610 }
 611
 612 sub classify ($) {
 613     my ($objid) = @_;
 614
 615     my @p;
 616     my $r = parsecommit($objid, \@p);
 617     my $t = $r->{Tree};
 618
 619     foreach my $p (@p) {
 620         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 621     }
 622
 623     printdebug "classify $objid \$t=$t \@p",
 624         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 625         "\n";
 626
 627     my $classify = sub {
 628         my ($type, @rest) = @_;
 629         $r = { %$r, Type => $type, @rest };
 630         if ($debuglevel) {
 631             printdebug " = $type ".(dd $r)."\n";
 632         }
 633         return $r;
 634     };
 635     my $unknown = sub {
 636         my ($why) = @_;
 637         $r = { %$r, Type => qw(Unknown), Why => $why };
 638         printdebug " ** Unknown\n";
 639         return $r;
 640     };
 641
 642     if (grep { $_ eq $objid } @opt_anchors) {
 643         return $classify->('TreatAsAnchor');
 644     }
 645
 646     my @identical = grep { !$_->{Differs} } @p;
 647     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 648     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 649
 650     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 651         # multi-orig upstreams are represented with an anchor merge
 652         # from a single upstream commit which combines the orig tarballs
 653
 654         # Every anchor tagged this way must be a merge.
 655         # We are relying on the
 656         #     [git-debrebase anchor: ...]
 657         # commit message annotation in "declare" anchor merges (which
 658         # do not have any upstream changes), to distinguish those
 659         # anchor merges from ordinary pseudomerges (which we might
 660         # just try to strip).
 661         #
 662         # However, the user is going to be doing git-rebase a lot.  We
 663         # really don't want them to rewrite an anchor commit.
 664         # git-rebase trips up on merges, so that is a useful safety
 665         # catch.
 666         #
 667         # BreakwaterStart commits are also anchors in the terminology
 668         # of git-debrebase(5), but they are untagged (and always
 669         # manually generated).
 670         #
 671         # We cannot not tolerate any tagged linear commit (ie,
 672         # BreakwaterStart commits tagged `[anchor:') because such a
 673         # thing could result from an erroneous linearising raw git
 674         # rebase of a merge anchor.  That would represent a corruption
 675         # of the branch. and we want to detect and reject the results
 676         # of such corruption before it makes it out anywhere.  If we
 677         # reject it here then we avoid making the pseudomerge which
 678         # would be needed to push it.
 679
 680         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 681         @p == 2 or return $badanchor->("has other than two parents");
 682         $haspatches and return $badanchor->("contains debian/patches");
 683
 684         # How to decide about l/r ordering of anchors ?  git
 685         # --topo-order prefers to expand 2nd parent first.  There's
 686         # already an easy rune to look for debian/ history anyway (git log
 687         # debian/) so debian breakwater branch should be 1st parent; that
 688         # way also there's also an easy rune to look for the upstream
 689         # patches (--topo-order).
 690
 691         # Also this makes --first-parent be slightly more likely to
 692         # be useful - it makes it provide a linearised breakwater history.
 693
 694         # Of course one can say somthing like
 695         #  gitk -- ':/' ':!/debian'
 696         # to get _just_ the commits touching upstream files, and by
 697         # the TREESAME logic in git-rev-list this will leave the
 698         # breakwater into upstream at the first anchor.  But that
 699         # doesn't report debian/ changes at all.
 700
 701         # Other observations about gitk: by default, gitk seems to
 702         # produce output in a different order to git-rev-list.  I
 703         # can't seem to find this documented anywhere.  gitk
 704         # --date-order DTRT.  But, gitk always seems to put the
 705         # parents from left to right, in order, so it's easy to see
 706         # which way round a pseudomerge is.
 707
 708         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 709         $p[1]{Differs} & ~DS_DEB and
 710             $badanchor->("upstream files differ from left parent");
 711         $p[0]{Differs} & ~D_UPS and
 712             $badanchor->("debian/ differs from right parent");
 713
 714         return $classify->(qw(Anchor),
 715                            OrigParents => [ $p[1] ]);
 716     }
 717
 718     if (@p == 1) {
 719         my $d = $r->{Parents}[0]{Differs};
 720         if ($d == D_PAT_ADD) {
 721             return $classify->(qw(AddPatches));
 722         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 723             return $unknown->("edits debian/patches");
 724         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 725             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 726             if ($ty eq 'tree') {
 727                 if ($d == D_DEB_CLOG) {
 728                     return $classify->(qw(Changelog));
 729                 } else {
 730                     return $classify->(qw(Packaging));
 731                 }
 732             } elsif ($ty eq 'missing') {
 733                 return $classify->(qw(BreakwaterStart));
 734             } else {
 735                 return $unknown->("parent's debian is not a directory");
 736             }
 737         } elsif ($d == D_UPS) {
 738             return $classify->(qw(Upstream));
 739         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 740             return $classify->(qw(Mixed));
 741         } elsif ($d == 0) {
 742             return $unknown->("no changes");
 743         } else {
 744             confess "internal error $objid ?";
 745         }
 746     }
 747     if (!@p) {
 748         return $unknown->("origin commit");
 749     }
 750
 751     if (@p == 2 && @identical == 1) {
 752         my @overwritten = grep { $_->{Differs} } @p;
 753         confess "internal error $objid ?" unless @overwritten==1;
 754         return $classify->(qw(Pseudomerge),
 755                            Overwritten => [ $overwritten[0] ],
 756                            Contributor => $identical[0]);
 757     }
 758     if (@p == 2 && @identical == 2) {
 759         my $get_t = sub {
 760             my ($ph,$pm) = get_commit $_[0]{CommitId};
 761             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 762             $1;
 763         };
 764         my @bytime = @p;
 765         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 766         if ($order > 0) { # newer first
 767         } elsif ($order < 0) {
 768             @bytime = reverse @bytime;
 769         } else {
 770             # same age, default to order made by -s ours
 771             # that is, commit was made by someone who preferred L
 772         }
 773         return $classify->(qw(Pseudomerge),
 774                            SubType => qw(Ambiguous),
 775                            Contributor => $bytime[0],
 776                            Overwritten => [ $bytime[1] ]);
 777     }
 778     foreach my $p (@p) {
 779         my ($p_h, $p_m) = get_commit $p->{CommitId};
 780         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 781         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 782     }
 783     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 784     my $m2 = $r->{Msg};
 785     if (!(grep { !$_->{IsOrigin} } @p) and
 786         (@orig_ps >= @p - 1) and
 787         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 788         $r->{NewMsg} = $m2;
 789         return $classify->(qw(DgitImportUnpatched),
 790                            OrigParents => \@orig_ps);
 791     }
 792
 793     if (@p == 2 and
 794         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 795         # xxx ^ metadata tag needs adding to (5)
 796         return $classify->("MergedBreakwaters");
 797     }
 798     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 799         return $unknown->("unknown kind of merge from $1");
 800     }
 801     if (@p > 2) {
 802         return $unknown->("octopus merge");
 803     }
 804
 805     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 806         return $unknown->("general two-parent merge");
 807     }
 808
 809     return $classify->("VanillaMerge");
 810 }
 811
 812 sub keycommits ($;$$$$) {
 813     my ($head, $furniture, $unclean, $trouble, $fatal) = @_;
 814     # => ($anchor, $breakwater)
 815
 816     # $unclean->("unclean-$tagsfx", $msg, $cl)
 817     # $furniture->("unclean-$tagsfx", $msg, $cl)
 818     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 819     #   is callled for each situation or commit that
 820     #   wouldn't be found in a laundered branch
 821     # $furniture is for furniture commits such as might be found on an
 822     #   interchange branch (pseudomerge, d/patches, changelog)
 823     # $trouble is for things whnich prevent the return of
 824     #   anchor and breakwater information; if that is ignored,
 825     #   then keycommits returns (undef, undef) instead.
 826     # $fatal is for unprocessable commits, and should normally cause
 827     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 828     #
 829     # If a callback is undef, fail is called instead.
 830     # If a callback is defined but false, the situation is ignored.
 831     # Callbacks may say:
 832     #   no warnings qw(exiting); last;
 833     # if the answer is no longer wanted.
 834
 835     my ($anchor, $breakwater);
 836     my $clogonly;
 837     my $cl;
 838     my $found_pm;
 839     $fatal //= sub { fail $_[1]; };
 840     my $x = sub {
 841         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 842         my $why = $mainwhy.$xwhy;
 843         my $m = "branch needs laundering (run git-debrebase): $why";
 844         fail $m unless defined $cb;
 845         return unless $cb;
 846         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 847     };
 848     for (;;) {
 849         $cl = classify $head;
 850         my $ty = $cl->{Type};
 851         if ($ty eq 'Packaging') {
 852             $breakwater //= $clogonly;
 853             $breakwater //= $head;
 854         } elsif ($ty eq 'Changelog') {
 855             # this is going to count as the tip of the breakwater
 856             # only if it has no upstream stuff before it
 857             $clogonly //= $head;
 858         } elsif ($ty eq 'Anchor' or
 859                  $ty eq 'TreatAsAnchor' or
 860                  $ty eq 'BreakwaterStart') {
 861             $anchor = $head;
 862             $breakwater //= $clogonly;
 863             $breakwater //= $head;
 864             last;
 865         } elsif ($ty eq 'Upstream') {
 866             $x->($unclean, 'ordering',
 867  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 868                 if defined $breakwater;
 869             $clogonly = undef;
 870             $breakwater = undef;
 871         } elsif ($ty eq 'Mixed') {
 872             $x->($unclean, 'mixed',
 873                  "found mixed upstream/packaging commit"," ($head)");
 874             $clogonly = undef;
 875             $breakwater = undef;
 876         } elsif ($ty eq 'Pseudomerge' or
 877                  $ty eq 'AddPatches') {
 878             my $found_pm = 1;
 879             $x->($furniture, (lc $ty),
 880                  "found interchange bureaucracy commit ($ty)"," ($head)");
 881         } elsif ($ty eq 'DgitImportUnpatched') {
 882             if ($found_pm) {
 883                 $x->($trouble, 'dgitimport',
 884                      "found dgit dsc import"," ($head)");
 885                 return (undef,undef);
 886             } else {
 887                 $x->($fatal, 'unprocessable',
 888                      "found bare dgit dsc import with no prior history",
 889                      " ($head)");
 890                 return (undef,undef);
 891             }
 892         } elsif ($ty eq 'VanillaMerge') {
 893             $x->($trouble, 'vanillamerge',
 894                  "found vanilla merge"," ($head)");
 895             return (undef,undef);
 896         } else {
 897             $x->($fatal, 'unprocessable',
 898                  "found unprocessable commit, cannot cope: $cl->{Why}",
 899                  " ($head)");
 900             return (undef,undef);
 901         }
 902         $head = $cl->{Parents}[0]{CommitId};
 903     }
 904     return ($anchor, $breakwater);
 905 }
 906
 907 sub walk ($;$$$);
 908 sub walk ($;$$$) {
 909     my ($input,
 910         $nogenerate,$report, $report_lprefix) = @_;
 911     # => ($tip, $breakwater_tip, $last_anchor)
 912     # (or nothing, if $nogenerate)
 913
 914     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 915     $report_lprefix //= '';
 916
 917     # go through commits backwards
 918     # we generate two lists of commits to apply:
 919     # breakwater branch and upstream patches
 920     my (@brw_cl, @upp_cl, @processed);
 921     my %found;
 922     my $upp_limit;
 923     my @pseudomerges;
 924
 925     my $cl;
 926     my $xmsg = sub {
 927         my ($prose, $info) = @_;
 928         my $ms = $cl->{Msg};
 929         chomp $ms;
 930         $info //= '';
 931         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 932         return (Msg => $ms);
 933     };
 934     my $rewrite_from_here = sub {
 935         my ($cl) = @_;
 936         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 937         push @$cl, $sp_cl;
 938         push @processed, $sp_cl;
 939     };
 940     my $cur = $input;
 941
 942     my $prdelim = "";
 943     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 944
 945     my $prline = sub {
 946         return unless $report;
 947         print $report $prdelim, $report_lprefix, @_;
 948         $prdelim = "\n";
 949     };
 950
 951     my $bomb = sub { # usage: return $bomb->();
 952         print $report " Unprocessable" if $report;
 953         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 954         $prprdelim->();
 955         if ($nogenerate) {
 956             return (undef,undef);
 957         }
 958         fail "found unprocessable commit, cannot cope".
 959             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
 960             " (commit $cur) (d.".
 961             (join ' ', map { sprintf "%#x", $_->{Differs} }
 962              @{ $cl->{Parents} }).
 963                  ")";
 964     };
 965
 966     my $build;
 967     my $breakwater;
 968
 969     my $build_start = sub {
 970         my ($msg, $parent) = @_;
 971         $prline->(" $msg");
 972         $build = $parent;
 973         no warnings qw(exiting); last;
 974     };
 975
 976     my $nomerge = sub {
 977         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
 978     };
 979
 980     my $last_anchor;
 981
 982     for (;;) {
 983         $cl = classify $cur;
 984         my $ty = $cl->{Type};
 985         my $st = $cl->{SubType};
 986         $prline->("$cl->{CommitId} $cl->{Type}");
 987         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 988         push @processed, $cl;
 989         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 990         if ($ty eq 'AddPatches') {
 991             $cur = $p0;
 992             $rewrite_from_here->(\@upp_cl);
 993             next;
 994         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 995             push @brw_cl, $cl;
 996             $cur = $p0;
 997             next;
 998         } elsif ($ty eq 'BreakwaterStart') {
 999             $last_anchor = $cur;
1000             $build_start->('FirstPackaging', $cur);
1001         } elsif ($ty eq 'Upstream') {
1002             push @upp_cl, $cl;
1003             $cur = $p0;
1004             next;
1005         } elsif ($ty eq 'Mixed') {
1006             my $queue = sub {
1007                 my ($q, $wh) = @_;
1008                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1009                 push @$q, $cls;
1010             };
1011             $queue->(\@brw_cl, "debian");
1012             $queue->(\@upp_cl, "upstream");
1013             $rewrite_from_here->(\@brw_cl);
1014             $cur = $p0;
1015             next;
1016         } elsif ($ty eq 'Pseudomerge') {
1017             my $contrib = $cl->{Contributor}{CommitId};
1018             print $report " Contributor=$contrib" if $report;
1019             push @pseudomerges, $cl;
1020             $rewrite_from_here->(\@upp_cl);
1021             $cur = $contrib;
1022             next;
1023         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1024             $last_anchor = $cur;
1025             $build_start->("Anchor", $cur);
1026         } elsif ($ty eq 'DgitImportUnpatched') {
1027             my $pm = $pseudomerges[-1];
1028             if (defined $pm) {
1029                 # To an extent, this is heuristic.  Imports don't have
1030                 # a useful history of the debian/ branch.  We assume
1031                 # that the first pseudomerge after an import has a
1032                 # useful history of debian/, and ignore the histories
1033                 # from later pseudomerges.  Often the first pseudomerge
1034                 # will be the dgit import of the upload to the actual
1035                 # suite intended by the non-dgit NMUer, and later
1036                 # pseudomerges may represent in-archive copies.
1037                 my $ovwrs = $pm->{Overwritten};
1038                 printf $report " PM=%s \@Overwr:%d",
1039                     $pm->{CommitId}, (scalar @$ovwrs)
1040                     if $report;
1041                 if (@$ovwrs != 1) {
1042                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1043                     return $bomb->();
1044                 }
1045                 my $ovwr = $ovwrs->[0]{CommitId};
1046                 printf $report " Overwr=%s", $ovwr if $report;
1047                 # This import has a tree which is just like a
1048                 # breakwater tree, but it has the wrong history.  It
1049                 # ought to have the previous breakwater (which the
1050                 # pseudomerge overwrote) as an ancestor.  That will
1051                 # make the history of the debian/ files correct.  As
1052                 # for the upstream version: either it's the same as
1053                 # was ovewritten (ie, same as the previous
1054                 # breakwater), in which case that history is precisely
1055                 # right; or, otherwise, it was a non-gitish upload of a
1056                 # new upstream version.  We can tell these apart by
1057                 # looking at the tree of the supposed upstream.
1058                 push @brw_cl, {
1059                     %$cl,
1060                     SpecialMethod => 'DgitImportDebianUpdate',
1061                     $xmsg->("convert dgit import: debian changes")
1062                 }, {
1063                     %$cl,
1064                     SpecialMethod => 'DgitImportUpstreamUpdate',
1065                     $xmsg->("convert dgit import: upstream update",
1066                             " anchor")
1067                 };
1068                 $prline->(" Import");
1069                 $rewrite_from_here->(\@brw_cl);
1070                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1071                 $cur = $ovwr;
1072                 next;
1073             } else {
1074                 # Everything is from this import.  This kind of import
1075                 # is already nearly in valid breakwater format, with the
1076                 # patches as commits.  Unfortunately it contains
1077                 # debian/patches/.
1078                 printdebug "*** WALK BOMB bare dgit import\n";
1079                 $cl->{Why} = "bare dgit dsc import";
1080                 return $bomb->();
1081             }
1082             die "$ty ?";
1083         } elsif ($ty eq 'VanillaMerge' or $ty eq 'MergedBreakwaters') {
1084             # xxx need to handle ffq if one side was unstitched
1085             # wait both of them may be!
1086             my $ok=1;
1087             my $best_anchor;
1088             # We expect to find a dominating anchor amongst the
1089             # inputs' anchors.  That will be the new anchor.
1090             #
1091             # More complicated is finding a merge base for the
1092             # breakwaters.  We need a merge base that is a breakwater
1093             # commit.  The ancestors of breakwater commits are more
1094             # breakwater commits and possibly upstream commits and the
1095             # ancestors of those upstream.  Upstreams might have
1096             # arbitrary ancestors.  But any upstream commit U is
1097             # either included in both anchors, in which case the
1098             # earlier anchor is a better merge base than any of U's
1099             # ancestors; or U is not included in the older anchor, in
1100             # which case U is not an ancestor of the vanilla merge at
1101             # all.  So no upstream commit, nor any ancestor thereof,
1102             # is a best merge base.  As for non-breakwater Debian
1103             # commits: these are never ancestors of any breakwater.
1104             #
1105             # So any best merge base as found by git-merge-base
1106             # is a suitable breakwater anchor.  Usually there will
1107             # be only one.
1108
1109             printdebug "*** MERGE\n";
1110
1111             # xxx avoid calling walk without nogenerate when
1112             # we have a MergedBreakwater; instead call keycommits ?
1113
1114             my @bwbcmd = (@git, qw(merge-base));
1115             my @ibcmd = (@git, qw(merge-base --all));
1116             my $might_be_in_bw = 1;
1117
1118             my $ps = $cl->{Parents};
1119
1120             foreach my $p (@$ps) {
1121                 $prline->(" VanillaMerge ".$p->{Ix});
1122                 $prprdelim->();
1123                 my ($ptip, $pbw, $panchor) =
1124                     walk $p->{CommitId}, 0, $report,
1125                          $report_lprefix.'  ';
1126                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1127                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1128                 $p->{Anchor} = $panchor;
1129
1130                 $best_anchor = $panchor if
1131                     !defined $best_anchor or
1132                     is_fast_fwd $best_anchor, $panchor;
1133
1134                 printdebug " MERGE BA best=".($best_anchor//'-').
1135                     " p=$panchor\n";
1136             }
1137
1138             foreach my $p (@$ps) {
1139                 $prline->(" VanillaMerge ".$p->{Ix});
1140                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1141                     $nomerge->('DivergentAnchor');
1142                 } elsif ($p->{Anchor} eq $best_anchor) {
1143                     print $report " SameAnchor" if $report;
1144                 } else {
1145                     print $report " SupersededAnchor" if $report;
1146                 }
1147                 if ($p->{Breakwater} eq $p->{CommitId}) {
1148                     # this parent commit was its own breakwater,
1149                     # ie it is part of the breakwater
1150                     print $report " Breakwater" if $report;
1151                 } else {
1152                     $might_be_in_bw = 0;
1153                 }
1154                 push @bwbcmd, $p->{Breakwater};
1155                 push @ibcmd, $p->{CommitId};
1156             }
1157
1158             if ($ok && $might_be_in_bw) {
1159                 $prline->(" VanillaMerge MergedBreakwaters");
1160                 $last_anchor = $best_anchor;
1161                 $build_start->('MergedBreakwaters', $cur);
1162             }
1163
1164             $nomerge->("alleged merged-breakwater is not a breakwater")
1165                 unless $ty eq 'VanillaMerge';
1166
1167             my $bwb = cmdoutput @bwbcmd;
1168
1169             # OK, now we have a breakwater base, but we need the merge
1170             # base for the interchange branch because we need the delta
1171             # queue.
1172             #
1173             # This a the best merge base of our inputs which has the
1174             # breakwater merge base as an ancestor.
1175
1176             my @ibs =
1177                 grep { is_fast_fwd $bwb, $_ }
1178                 grep /./,
1179                 split /\n/,
1180                 cmdoutput @ibcmd;
1181             my ($ib) = @ibs
1182                 or $nomerge->("no suitable interchange merge base");
1183
1184             $prline->("  VanillaMerge Base");
1185             $prprdelim->();
1186             my ($btip, $bbw, $banchor) =
1187                 walk $ib, 0, $report, $report_lprefix.'  ';
1188
1189             my $ibinfo = { SeriesTip => $btip,
1190                            SeriesBase => $bbw,
1191                            Anchor => $banchor };
1192             $bbw eq $bwb
1193                 or $nomerge->("interchange merge-base ($ib)'s".
1194                               " breakwater ($bbw)".
1195                               " != breakwaters' merge-base ($bwb)");
1196             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1197                  or $nomerge->("interchange merge-base ($ib)'s".
1198                                " anchor ($ibinfo->{SeriesBase})".
1199                                " != any merge input's anchor (".
1200                                (join ' ', map { $_->{Anchor} } @$ps).
1201                                ")");
1202
1203
1204             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1205             $cl->{MergeBestAnchor} = $best_anchor;
1206             push @brw_cl, {
1207                 %$cl,
1208                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1209                 $xmsg->('construct merged breakwater from vanilla merge'),
1210             };
1211             push @upp_cl, {
1212                 %$cl,
1213                 SpecialMethod => 'MergeMergeSeries',
1214             };
1215             $build_start->('MergeBreakwaters', $cur);
1216         } else {
1217             printdebug "*** WALK BOMB unrecognised\n";
1218             return $bomb->();
1219         }
1220     }
1221     $prprdelim->();
1222
1223     printdebug "*** WALK prep done cur=$cur".
1224         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1225
1226     return if $nogenerate;
1227
1228     # Now we build it back up again
1229
1230     fresh_workarea();
1231
1232     my $rewriting = 0;
1233
1234     $#upp_cl = $upp_limit if defined $upp_limit;
1235
1236     my $committer_authline = calculate_committer_authline();
1237
1238     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1239
1240     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1241
1242     in_workarea sub {
1243         mkdir $rd or $!==EEXIST or die $!;
1244         my $current_method;
1245         runcmd @git, qw(read-tree), $build;
1246         foreach my $cl (qw(Debian), (reverse @brw_cl),
1247                         { SpecialMethod => 'RecordBreakwaterTip' },
1248                         qw(Upstream), (reverse @upp_cl)) {
1249             if (!ref $cl) {
1250                 $current_method = $cl;
1251                 next;
1252             }
1253             my $method = $cl->{SpecialMethod} // $current_method;
1254             my @parents = ($build);
1255             my $cltree = $cl->{CommitId};
1256             printdebug "WALK BUILD ".($cltree//'undef').
1257                 " $method (rewriting=$rewriting)\n";
1258             if ($method eq 'Debian') {
1259                 read_tree_debian($cltree);
1260             } elsif ($method eq 'Upstream') {
1261                 read_tree_upstream($cltree);
1262             } elsif ($method eq 'StartRewrite') {
1263                 $rewriting = 1;
1264                 next;
1265             } elsif ($method eq 'RecordBreakwaterTip') {
1266                 $breakwater = $build;
1267                 next;
1268             } elsif ($method eq 'DgitImportDebianUpdate') {
1269                 read_tree_debian($cltree);
1270             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1271                 confess unless $rewriting;
1272                 my $differs = (get_differs $build, $cltree);
1273                 next unless $differs & D_UPS;
1274                 read_tree_upstream($cltree);
1275                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1276             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1277                 print "Found a general merge, will try to tidy it up.\n";
1278                 $rewriting = 1;
1279                 read_tree_upstream($cl->{MergeBestAnchor});
1280                 read_tree_upstream($cl->{MergeBestAnchor});
1281                 read_tree_debian($cltree);
1282                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1283             } elsif ($method eq 'MergeMergeSeries') {
1284                 print "Running merge resolution for $cl->{CommitId}...\n";
1285                 $build = merge_series
1286                     $build,
1287                     $cl->{MergeInterchangeBaseInfo},
1288                     @{ $cl->{Parents} };
1289                 $last_anchor = $cl->{MergeBestAnchor};
1290                 # xxx need to check the tree somehow
1291                 print "Merge resolution successful.\n";
1292                 next;
1293             } else {
1294                 confess "$method ?";
1295             }
1296             if (!$rewriting) {
1297                 my $procd = (pop @processed) // 'UNDEF';
1298                 if ($cl ne $procd) {
1299                     $rewriting = 1;
1300                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1301                 }
1302             }
1303             my $newtree = cmdoutput @git, qw(write-tree);
1304             my $ch = $cl->{Hdr};
1305             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1306             $ch =~ s{^parent .*\n}{}mg;
1307             $ch =~ s{(?=^author)}{
1308                 join '', map { "parent $_\n" } @parents
1309             }me or confess "$ch ?";
1310             if ($rewriting) {
1311                 $ch =~ s{^committer .*$}{$committer_authline}m
1312                     or confess "$ch ?";
1313             }
1314             my $cf = "$rd/m$rewriting";
1315             open CD, ">", $cf or die $!;
1316             print CD $ch, "\n", $cl->{Msg} or die $!;
1317             close CD or die $!;
1318             my @cmd = (@git, qw(hash-object));
1319             push @cmd, qw(-w) if $rewriting;
1320             push @cmd, qw(-t commit), $cf;
1321             my $newcommit = cmdoutput @cmd;
1322             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1323             $build = $newcommit;
1324             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1325                 $last_anchor = $cur;
1326             }
1327         }
1328     };
1329
1330     my $final_check = get_differs $build, $input;
1331     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1332         if $final_check & ~D_PAT_ADD;
1333
1334     my @r = ($build, $breakwater, $last_anchor);
1335     printdebug "*** WALK RETURN @r\n";
1336     return @r
1337 }
1338
1339 sub get_head () {
1340     git_check_unmodified();
1341     return git_rev_parse qw(HEAD);
1342 }
1343
1344 sub update_head ($$$) {
1345     my ($old, $new, $mrest) = @_;
1346     push @deferred_updates, "update HEAD $new $old";
1347     run_deferred_updates $mrest;
1348 }
1349
1350 sub update_head_checkout ($$$) {
1351     my ($old, $new, $mrest) = @_;
1352     update_head $old, $new, $mrest;
1353     runcmd @git, qw(reset --hard);
1354 }
1355
1356 sub update_head_postlaunder ($$$) {
1357     my ($old, $tip, $reflogmsg) = @_;
1358     return if $tip eq $old;
1359     print "git-debrebase: laundered (head was $old)\n";
1360     update_head $old, $tip, $reflogmsg;
1361     # no tree changes except debian/patches
1362     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1363 }
1364
1365 sub currently_rebasing() {
1366     foreach (qw(rebase-merge rebase-apply)) {
1367         return 1 if stat_exists "$maindir_gitdir/$_";
1368     }
1369     return 0;
1370 }
1371
1372 sub bail_if_rebasing() {
1373     fail "you are in the middle of a git-rebase already"
1374         if currently_rebasing();
1375 }
1376
1377 sub do_launder_head ($) {
1378     my ($reflogmsg) = @_;
1379     my $old = get_head();
1380     record_ffq_auto();
1381     my ($tip,$breakwater) = walk $old;
1382     snags_maybe_bail();
1383     update_head_postlaunder $old, $tip, $reflogmsg;
1384     return ($tip,$breakwater);
1385 }
1386
1387 sub cmd_launder_v0 () {
1388     badusage "no arguments to launder-v0 allowed" if @ARGV;
1389     my $old = get_head();
1390     my ($tip,$breakwater,$last_anchor) = walk $old;
1391     update_head_postlaunder $old, $tip, 'launder';
1392     printf "# breakwater tip\n%s\n", $breakwater;
1393     printf "# working tip\n%s\n", $tip;
1394     printf "# last anchor\n%s\n", $last_anchor;
1395 }
1396
1397 sub defaultcmd_rebase () {
1398     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1399     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1400     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1401 }
1402
1403 sub cmd_analyse () {
1404     badusage "analyse does not support any options"
1405         if @ARGV and $ARGV[0] =~ m/^-/;
1406     badusage "too many arguments to analyse" if @ARGV>1;
1407     my ($old) = @ARGV;
1408     if (defined $old) {
1409         $old = git_rev_parse $old;
1410     } else {
1411         $old = git_rev_parse 'HEAD';
1412     }
1413     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1414     STDOUT->error and die $!;
1415 }
1416
1417 sub ffq_prev_branchinfo () {
1418     my $current = git_get_symref();
1419     return gdr_ffq_prev_branchinfo($current);
1420 }
1421
1422 sub ffq_check ($;$$) {
1423     # calls $ff and/or $notff zero or more times
1424     # then returns either (status,message) where status is
1425     #    exists
1426     #    detached
1427     #    weird-symref
1428     #    notbranch
1429     # or (undef,undef, $ffq_prev,$gdrlast)
1430     # $ff and $notff are called like this:
1431     #   $ff->("message for stdout\n");
1432     #   $notff->('snag-name', $message);
1433     # normally $currentval should be HEAD
1434     my ($currentval, $ff, $notff) =@_;
1435
1436     $ff //= sub { print $_[0] or die $!; };
1437     $notff //= \&snag;
1438
1439     my ($status, $message, $current, $ffq_prev, $gdrlast)
1440         = ffq_prev_branchinfo();
1441     return ($status, $message) unless $status eq 'branch';
1442
1443     my $exists = git_get_ref $ffq_prev;
1444     return ('exists',"$ffq_prev already exists") if $exists;
1445
1446     return ('not-branch', 'HEAD symref is not to refs/heads/')
1447         unless $current =~ m{^refs/heads/};
1448     my $branch = $';
1449
1450     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1451     my %checked;
1452
1453     printdebug "ffq check_specs @check_specs\n";
1454
1455     my $check = sub {
1456         my ($lrref, $desc) = @_;
1457         printdebug "ffq might check $lrref ($desc)\n";
1458         my $invert;
1459         for my $chk (@check_specs) {
1460             my $glob = $chk;
1461             $invert = $glob =~ s{^[!^]}{};
1462             last if fnmatch $glob, $lrref;
1463         }
1464         return if $invert;
1465         my $lrval = git_get_ref $lrref;
1466         return unless length $lrval;
1467
1468         if (is_fast_fwd $lrval, $currentval) {
1469             $ff->("OK, you are ahead of $lrref\n");
1470             $checked{$lrref} = 1;
1471         } elsif (is_fast_fwd $currentval, $lrval) {
1472             $checked{$lrref} = -1;
1473             $notff->('behind', "you are behind $lrref, divergence risk");
1474         } else {
1475             $checked{$lrref} = -1;
1476             $notff->('diverged', "you have diverged from $lrref");
1477         }
1478     };
1479
1480     my $merge = cfg "branch.$branch.merge",1;
1481     if (defined $merge and $merge =~ m{^refs/heads/}) {
1482         my $rhs = $';
1483         printdebug "ffq merge $rhs\n";
1484         my $check_remote = sub {
1485             my ($remote, $desc) = @_;
1486             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1487             return unless defined $remote;
1488             $check->("refs/remotes/$remote/$rhs", $desc);
1489         };
1490         $check_remote->((scalar cfg "branch.$branch.remote",1),
1491                         'remote fetch/merge branch');
1492         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1493                         (scalar cfg "branch.$branch.pushDefault",1),
1494                         'remote push branch');
1495     }
1496     if ($branch =~ m{^dgit/}) {
1497         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1498     } elsif ($branch =~ m{^master$}) {
1499         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1500     }
1501     return (undef, undef, $ffq_prev, $gdrlast);
1502 }
1503
1504 sub record_ffq_prev_deferred () {
1505     # => ('status', "message")
1506     # 'status' may be
1507     #    deferred          message is undef
1508     #    exists
1509     #    detached
1510     #    weird-symref
1511     #    notbranch
1512     # if not ff from some branch we should be ff from, is an snag
1513     # if "deferred", will have added something about that to
1514     #   @deferred_update_messages, and also maybe printed (already)
1515     #   some messages about ff checks
1516     bail_if_rebasing();
1517     my $currentval = get_head();
1518
1519     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1520     return ($status,$message) if defined $status;
1521
1522     snags_maybe_bail();
1523
1524     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1525     push @deferred_updates, "delete $gdrlast";
1526     push @deferred_update_messages, "Recorded previous head for preservation";
1527     return ('deferred', undef);
1528 }
1529
1530 sub record_ffq_auto () {
1531     my ($status, $message) = record_ffq_prev_deferred();
1532     if ($status eq 'deferred' || $status eq 'exists') {
1533     } else {
1534         snag $status, "could not record ffq-prev: $message";
1535         snags_maybe_bail();
1536     }
1537 }
1538
1539 sub ffq_prev_info () {
1540     bail_if_rebasing();
1541     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1542     my ($status, $message, $current, $ffq_prev, $gdrlast)
1543         = ffq_prev_branchinfo();
1544     if ($status ne 'branch') {
1545         snag $status, "could not check ffq-prev: $message";
1546         snags_maybe_bail();
1547     }
1548     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1549     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1550 }
1551
1552 sub stitch ($$$$$) {
1553     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1554
1555     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1556
1557     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1558         my $differs = get_differs $old_head, $ffq_prev_commitish;
1559         unless ($differs & ~D_PAT_ADD) {
1560             # ffq-prev is ahead of us, and the only tree changes it has
1561             # are possibly addition of things in debian/patches/.
1562             # Just wind forwards rather than making a pointless pseudomerge.
1563             push @deferred_updates,
1564                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1565             update_head_checkout $old_head, $ffq_prev_commitish,
1566                 "stitch (fast forward)";
1567             return;
1568         }
1569     }
1570     fresh_workarea();
1571     # We make pseudomerges with L as the contributing parent.
1572     # This makes git rev-list --first-parent work properly.
1573     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1574         'Declare fast forward / record previous work',
1575         "[git-debrebase pseudomerge: $prose]",
1576     ];
1577     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1578     update_head $old_head, $new_head, "stitch: $prose";
1579 }
1580
1581 sub do_stitch ($;$) {
1582     my ($prose, $unclean) = @_;
1583
1584     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1585     if (!$ffq_prev_commitish) {
1586         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1587         return;
1588     }
1589     my $dangling_head = get_head();
1590
1591     keycommits $dangling_head, $unclean,$unclean,$unclean;
1592     snags_maybe_bail();
1593
1594     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1595 }
1596
1597 sub upstream_commitish_search ($$) {
1598     my ($upstream_version, $tried) = @_;
1599     # todo: at some point maybe use git-deborig to do this
1600     foreach my $tagpfx ('', 'v', 'upstream/') {
1601         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1602         my $new_upstream = git_get_ref "refs/tags/$tag";
1603         push @$tried, $tag;
1604         return $new_upstream if length $new_upstream;
1605     }
1606 }
1607
1608 sub resolve_upstream_version ($$) {
1609     my ($new_upstream, $upstream_version) = @_;
1610
1611     if (!defined $new_upstream) {
1612         my @tried;
1613         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1614         if (!length $new_upstream) {
1615             fail "Could not determine appropriate upstream commitish.\n".
1616                 " (Tried these tags: @tried)\n".
1617                 " Check version, and specify upstream commitish explicitly.";
1618         }
1619     }
1620     $new_upstream = git_rev_parse $new_upstream;
1621
1622     return $new_upstream;
1623 }
1624
1625 sub cmd_new_upstream () {
1626     # automatically and unconditionally launders before rebasing
1627     # if rebase --abort is used, laundering has still been done
1628
1629     my %pieces;
1630
1631     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1632
1633     # parse args - low commitment
1634     my $spec_version = shift @ARGV;
1635     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1636     fail "bad version number \`$spec_version'" unless defined $new_version;
1637     if ($new_version->is_native()) {
1638         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1639     }
1640
1641     my $new_upstream = shift @ARGV;
1642     my $new_upstream_version = upstreamversion  $new_version;
1643     $new_upstream =
1644         resolve_upstream_version $new_upstream, $new_upstream_version;
1645
1646     record_ffq_auto();
1647
1648     my $piece = sub {
1649         my ($n, @x) = @_; # may be ''
1650         my $pc = $pieces{$n} //= {
1651             Name => $n,
1652             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1653         };
1654         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1655         $pc;
1656     };
1657
1658     my @newpieces;
1659     my $newpiece = sub {
1660         my ($n, @x) = @_; # may be ''
1661         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1662         push @newpieces, $pc;
1663     };
1664
1665     $newpiece->('',
1666         OldIx => 0,
1667         New => $new_upstream,
1668     );
1669     while (@ARGV && $ARGV[0] !~ m{^-}) {
1670         my $n = shift @ARGV;
1671
1672         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1673             unless @ARGV && $ARGV[0] !~ m{^-};
1674
1675         my $c = git_rev_parse shift @ARGV;
1676         die unless $n =~ m/^$extra_orig_namepart_re$/;
1677         $newpiece->($n, New => $c);
1678     }
1679
1680     # now we need to investigate the branch this generates the
1681     # laundered version but we don't switch to it yet
1682     my $old_head = get_head();
1683     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1684
1685     my $old_bw_cl = classify $old_bw;
1686     my $old_anchor_cl = classify $old_anchor;
1687     my $old_upstream;
1688     if (!$old_anchor_cl->{OrigParents}) {
1689         snag 'anchor-treated',
1690             'old anchor is recognised due to --anchor, cannot check upstream';
1691     } else {
1692         $old_upstream = parsecommit
1693             $old_anchor_cl->{OrigParents}[0]{CommitId};
1694         $piece->('', Old => $old_upstream->{CommitId});
1695     }
1696
1697     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1698         if ($old_upstream->{Msg} =~
1699  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1700            ) {
1701             my @oldpieces = (split / /, $1);
1702             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1703             if ($old_n_parents != @oldpieces &&
1704                 $old_n_parents != @oldpieces + 1) {
1705                 snag 'upstream-confusing', sprintf
1706                     "previous upstream combine %s".
1707                     " mentions %d pieces (each implying one parent)".
1708                     " but has %d parents".
1709                     " (one per piece plus maybe a previous combine)",
1710                     $old_upstream->{CommitId},
1711                     (scalar @oldpieces),
1712                     $old_n_parents;
1713             } elsif ($oldpieces[0] ne '.') {
1714                 snag 'upstream-confusing', sprintf
1715                     "previous upstream combine %s".
1716                     " first piece is not \`.'",
1717                     $oldpieces[0];
1718             } else {
1719                 $oldpieces[0] = '';
1720                 foreach my $i (0..$#oldpieces) {
1721                     my $n = $oldpieces[$i];
1722                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1723                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1724                 }
1725             }
1726         } else {
1727             snag 'upstream-confusing',
1728                 "previous upstream $old_upstream->{CommitId} is from".
1729                " git-debrebase but not an \`upstream-combine' commit";
1730         }
1731     }
1732
1733     foreach my $pc (values %pieces) {
1734         if (!$old_upstream) {
1735             # we have complained already
1736         } elsif (!$pc->{Old}) {
1737             snag 'upstream-new-piece',
1738                 "introducing upstream piece \`$pc->{Name}'";
1739         } elsif (!$pc->{New}) {
1740             snag 'upstream-rm-piece',
1741                 "dropping upstream piece \`$pc->{Name}'";
1742         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1743             snag 'upstream-not-ff',
1744                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1745         }
1746     }
1747
1748     printdebug "%pieces = ", (dd \%pieces), "\n";
1749     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1750
1751     snags_maybe_bail();
1752
1753     my $new_bw;
1754
1755     fresh_workarea();
1756     in_workarea sub {
1757         my @upstream_merge_parents;
1758
1759         if (!any_snags()) {
1760             push @upstream_merge_parents, $old_upstream->{CommitId};
1761         }
1762
1763         foreach my $pc (@newpieces) { # always has '' first
1764             if ($pc->{Name}) {
1765                 read_tree_subdir $pc->{Name}, $pc->{New};
1766             } else {
1767                 runcmd @git, qw(read-tree), $pc->{New};
1768             }
1769             push @upstream_merge_parents, $pc->{New};
1770         }
1771
1772         # index now contains the new upstream
1773
1774         if (@newpieces > 1) {
1775             # need to make the upstream subtree merge commit
1776             $new_upstream = make_commit \@upstream_merge_parents,
1777                 [ "Combine upstreams for $new_upstream_version",
1778  ("[git-debrebase upstream-combine . ".
1779  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1780  ": new upstream]"),
1781                 ];
1782         }
1783
1784         # $new_upstream is either the single upstream commit, or the
1785         # combined commit we just made.  Either way it will be the
1786         # "upstream" parent of the anchor merge.
1787
1788         read_tree_subdir 'debian', "$old_bw:debian";
1789
1790         # index now contains the anchor merge contents
1791         $new_bw = make_commit [ $old_bw, $new_upstream ],
1792             [ "Update to upstream $new_upstream_version",
1793  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1794             ];
1795
1796         my $clogsignoff = cmdoutput qw(git show),
1797             '--pretty=format:%an <%ae>  %aD',
1798             $new_bw;
1799
1800         # Now we have to add a changelog stanza so the Debian version
1801         # is right.
1802         die if unlink "debian";
1803         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1804         unlink "debian/changelog" or $!==ENOENT or die $!;
1805         mkdir "debian" or die $!;
1806         open CN, ">", "debian/changelog" or die $!;
1807         my $oldclog = git_cat_file ":debian/changelog";
1808         $oldclog =~ m/^($package_re) \(\S+\) / or
1809             fail "cannot parse old changelog to get package name";
1810         my $p = $1;
1811         print CN <<END, $oldclog or die $!;
1812 $p ($new_version) UNRELEASED; urgency=medium
1813
1814   * Update to new upstream version $new_upstream_version.
1815
1816  -- $clogsignoff
1817
1818 END
1819         close CN or die $!;
1820         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1821
1822         # Now we have the final new breakwater branch in the index
1823         $new_bw = make_commit [ $new_bw ],
1824             [ "Update changelog for new upstream $new_upstream_version",
1825               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1826             ];
1827     };
1828
1829     # we have constructed the new breakwater. we now need to commit to
1830     # the laundering output, because git-rebase can't easily be made
1831     # to make a replay list which is based on some other branch
1832
1833     update_head_postlaunder $old_head, $old_laundered_tip,
1834         'launder for new upstream';
1835
1836     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1837     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1838         "debrebase new-upstream $new_version: rebase";
1839     runcmd @cmd;
1840     # now it's for the user to sort out
1841 }
1842
1843 sub cmd_record_ffq_prev () {
1844     badusage "no arguments allowed" if @ARGV;
1845     my ($status, $msg) = record_ffq_prev_deferred();
1846     if ($status eq 'exists' && $opt_noop_ok) {
1847         print "Previous head already recorded\n" or die $!;
1848     } elsif ($status eq 'deferred') {
1849         run_deferred_updates 'record-ffq-prev';
1850     } else {
1851         fail "Could not preserve: $msg";
1852     }
1853 }
1854
1855 sub cmd_anchor () {
1856     badusage "no arguments allowed" if @ARGV;
1857     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1858     print "$bw\n" or die $!;
1859 }
1860
1861 sub cmd_breakwater () {
1862     badusage "no arguments allowed" if @ARGV;
1863     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1864     print "$bw\n" or die $!;
1865 }
1866
1867 sub cmd_status () {
1868     badusage "no arguments allowed" if @ARGV;
1869
1870     # todo: gdr status should print divergence info
1871     # todo: gdr status should print upstream component(s) info
1872     # todo: gdr should leave/maintain some refs with this kind of info ?
1873
1874     my $oldest = { Badness => 0 };
1875     my $newest;
1876     my $note = sub {
1877         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1878         if ($oldest->{Badness} < $badness) {
1879             $oldest = $newest = undef;
1880         }
1881         $oldest = {
1882                    Badness => $badness,
1883                    CommitId => $cl->{CommitId},
1884                    OurMsg => $ourmsg,
1885                    KcMsg => $kcmsg,
1886                   };
1887         $newest //= $oldest;
1888     };
1889     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1890         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1891         sub { $note->(2, 'branch is unlaundered', @_); },
1892         sub { $note->(3, 'branch needs laundering', @_); },
1893         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1894
1895     my $prcommitinfo = sub {
1896         my ($cid) = @_;
1897         flush STDOUT or die $!;
1898         runcmd @git, qw(--no-pager log -n1),
1899             '--pretty=format:    %h %s%n',
1900             $cid;
1901     };
1902
1903     print "current branch contents, in git-debrebase terms:\n";
1904     if (!$oldest->{Badness}) {
1905         print "  branch is laundered\n";
1906     } else {
1907         print "  $oldest->{OurMsg}\n";
1908         my $printed = '';
1909         foreach my $info ($oldest, $newest) {
1910             my $cid = $info->{CommitId};
1911             next if $cid eq $printed;
1912             $printed = $cid;
1913             print "  $info->{KcMsg}\n";
1914             $prcommitinfo->($cid);
1915         }
1916     }
1917
1918     my $prab = sub {
1919         my ($cid, $what) = @_;
1920         if (!defined $cid) {
1921             print "  $what is not well-defined\n";
1922         } else {
1923             print "  $what\n";
1924             $prcommitinfo->($cid);
1925         }
1926     };
1927     print "key git-debrebase commits:\n";
1928     $prab->($anchor, 'anchor');
1929     $prab->($bw, 'breakwater');
1930
1931     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
1932         ffq_prev_branchinfo();
1933
1934     print "branch and ref status, in git-debrebase terms:\n";
1935     if ($ffq_msg) {
1936         print "  $ffq_msg\n";
1937     } else {
1938         $ffq_prev = git_get_ref $ffq_prev;
1939         $gdrlast = git_get_ref $gdrlast;
1940         if ($ffq_prev) {
1941             print "  unstitched; previous tip was:\n";
1942             $prcommitinfo->($ffq_prev);
1943         } elsif (!$gdrlast) {
1944             print "  stitched? (no record of git-debrebase work)\n";
1945         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
1946             print "  stitched\n";
1947         } else {
1948             print "  not git-debrebase (diverged since last stitch)\n"
1949         }
1950     }
1951     print "you are currently rebasing\n" if currently_rebasing();
1952 }
1953
1954 sub cmd_stitch () {
1955     my $prose = 'stitch';
1956     getoptions("stitch",
1957                'prose=s', \$prose);
1958     badusage "no arguments allowed" if @ARGV;
1959     do_stitch $prose, 0;
1960 }
1961 sub cmd_prepush () { cmd_stitch(); }
1962
1963 sub cmd_quick () {
1964     badusage "no arguments allowed" if @ARGV;
1965     do_launder_head 'launder for git-debrebase quick';
1966     do_stitch 'quick';
1967 }
1968
1969 sub cmd_conclude () {
1970     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1971     if (!$ffq_prev_commitish) {
1972         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1973         return;
1974     }
1975     my $dangling_head = get_head();
1976
1977     badusage "no arguments allowed" if @ARGV;
1978     do_launder_head 'launder for git-debrebase quick';
1979     do_stitch 'quick';
1980 }
1981
1982 sub cmd_scrap () {
1983     if (currently_rebasing()) {
1984         runcmd @git, qw(rebase --abort);
1985     }
1986     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1987     if (!$ffq_prev_commitish) {
1988         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1989         finish 0;
1990     }
1991     my $scrapping_head = get_head();
1992     badusage "no arguments allowed" if @ARGV;
1993     push @deferred_updates,
1994         "update $gdrlast $ffq_prev_commitish $git_null_obj",
1995         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
1996     snags_maybe_bail();
1997     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
1998 }
1999
2000 sub make_patches_staged ($) {
2001     my ($head) = @_;
2002     # Produces the patches that would result from $head if it were
2003     # laundered.
2004     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2005     fresh_workarea();
2006     in_workarea sub {
2007         gbp_pq_export 'bw', $secret_bw, $secret_head;
2008     };
2009 }
2010
2011 sub make_patches ($) {
2012     my ($head) = @_;
2013     keycommits $head, 0, \&snag;
2014     make_patches_staged $head;
2015     my $out;
2016     in_workarea sub {
2017         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2018         runcmd @git, qw(read-tree), $head;
2019         read_tree_subdir 'debian/patches', $ptree;
2020         $out = make_commit [$head], [
2021             'Commit patch queue (exported by git-debrebase)',
2022             '[git-debrebase: export and commit patches]',
2023         ];
2024     };
2025     return $out;
2026 }
2027
2028 sub cmd_make_patches () {
2029     my $opt_quiet_would_amend;
2030     getoptions("make-patches",
2031                'quiet-would-amend!', \$opt_quiet_would_amend);
2032     badusage "no arguments allowed" if @ARGV;
2033     bail_if_rebasing();
2034     my $old_head = get_head();
2035     my $new = make_patches $old_head;
2036     my $d = get_differs $old_head, $new;
2037     if ($d == 0) {
2038         fail "No (more) patches to export." unless $opt_noop_ok;
2039         return;
2040     } elsif ($d == D_PAT_ADD) {
2041         snags_maybe_bail();
2042         update_head_checkout $old_head, $new, 'make-patches';
2043     } else {
2044         print STDERR failmsg
2045             "Patch export produced patch amendments".
2046             " (abandoned output commit $new).".
2047             "  Try laundering first."
2048             unless $opt_quiet_would_amend;
2049         finish 7;
2050     }
2051 }
2052
2053 sub cmd_convert_from_gbp () {
2054     badusage "want only 1 optional argument, the upstream git commitish"
2055         unless @ARGV<=1;
2056
2057     my $clogp = parsechangelog();
2058     my $version = $clogp->{'Version'}
2059         // die "missing Version from changelog";
2060
2061     my ($upstream_spec) = @ARGV;
2062
2063     my $upstream_version = upstreamversion $version;
2064     my $upstream =
2065         resolve_upstream_version($upstream_spec, $upstream_version);
2066
2067     my $old_head = get_head();
2068
2069     my $upsdiff = get_differs $upstream, $old_head;
2070     if ($upsdiff & D_UPS) {
2071         runcmd @git, qw(--no-pager diff --stat),
2072             $upstream, $old_head,
2073             qw( -- :!/debian :/);
2074         fail <<END;
2075 upstream ($upstream_spec) and HEAD are not
2076 identical in upstream files.  See diffstat above, or run
2077   git diff $upstream_spec HEAD -- :!/debian :/
2078 END
2079     }
2080
2081     if (!is_fast_fwd $upstream, $old_head) {
2082         snag 'upstream-not-ancestor',
2083             "upstream ($upstream) is not an ancestor of HEAD";
2084     } else {
2085         my $wrong = cmdoutput
2086             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2087              qw(-- :/ :!/debian));
2088         if (length $wrong) {
2089             snag 'unexpected-upstream-changes',
2090                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2091             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2092         }
2093     }
2094
2095     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2096         snag 'upstream-has-debian',
2097             "upstream ($upstream) contains debian/ directory";
2098     }
2099
2100     my $previous_dgit_view = eval {
2101         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2102         my ($lvsn, $suite);
2103         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2104             my ($stz, $desc) = @_;
2105             no warnings qw(exiting);
2106             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2107             next unless $stz->{Date};
2108             next unless $stz->{Distribution} ne 'UNRELEASED';
2109             $lvsn = $stz->{Version};
2110             $suite = $stz->{Distribution};
2111             last;
2112         };
2113         die "neither of the first two changelog entries are released\n"
2114             unless defined $lvsn;
2115         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2116         my $mtag_pat = debiantag_maintview $lvsn, '*';
2117         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2118             $mtag_pat;
2119         die "could not find suitable maintainer view tag $mtag_pat\n"
2120             unless $mtag_pat =~ m{/};
2121         is_fast_fwd $mtag, 'HEAD' or
2122             die "HEAD is not FF from maintainer tag $mtag!";
2123         my $dtag = "archive/$mtag";
2124         is_fast_fwd $mtag, $dtag or
2125             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2126         print "will stitch in dgit view, $dtag\n";
2127         git_rev_parse $dtag;
2128     };
2129     if (!$previous_dgit_view) {
2130         $@ =~ s/^\n+//;
2131         chomp $@;
2132         print STDERR "cannot stitch in dgit view: $@\n";
2133     }
2134
2135     snags_maybe_bail_early();
2136
2137     my $work;
2138
2139     fresh_workarea();
2140     in_workarea sub {
2141         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2142         # make a branch out of the patch queue - we'll want this in a mo
2143         runcmd qw(gbp pq import);
2144         # strip the patches out
2145         runcmd @git, qw(checkout -q gdr-internal~0);
2146         rm_subdir_cached 'debian/patches';
2147         $work = make_commit ['HEAD'], [
2148  'git-debrebase convert-from-gbp: drop patches from tree',
2149  'Delete debian/patches, as part of converting to git-debrebase format.',
2150  '[git-debrebase convert-from-gbp: drop patches from tree]'
2151                               ];
2152         # make the anchor merge
2153         # the tree is already exactly right
2154         $work = make_commit [$work, $upstream], [
2155  'git-debrebase import: declare upstream',
2156  'First breakwater merge.',
2157  '[git-debrebase anchor: declare upstream]'
2158                               ];
2159
2160         # rebase the patch queue onto the new breakwater
2161         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2162         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2163         $work = git_rev_parse 'HEAD';
2164
2165         if ($previous_dgit_view) {
2166             $work = make_commit [$work, $previous_dgit_view], [
2167  'git-debrebase import: declare ff from dgit archive view',
2168  '[git-debrebase pseudomerge: import-from-gbp]',
2169             ];
2170         }
2171     };
2172
2173     ffq_check $work;
2174     snags_maybe_bail();
2175     update_head_checkout $old_head, $work, 'convert-from-gbp';
2176 }
2177
2178 sub cmd_convert_to_gbp () {
2179     badusage "no arguments allowed" if @ARGV;
2180     my $head = get_head();
2181     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2182     keycommits $head, 0;
2183     my $out;
2184     make_patches_staged $head;
2185     in_workarea sub {
2186         $out = make_commit ['HEAD'], [
2187             'Commit patch queue (converted from git-debrebase format)',
2188             '[git-debrebase convert-to-gbp: commit patches]',
2189         ];
2190     };
2191     if (defined $ffq) {
2192         push @deferred_updates, "delete $ffq";
2193         push @deferred_updates, "delete $gdrlast";
2194     }
2195     snags_maybe_bail();
2196     update_head_checkout $head, $out, "convert to gbp (v0)";
2197     print <<END or die $!;
2198 git-debrebase: converted to git-buildpackage branch format
2199 git-debrebase: WARNING: do not now run "git-debrebase" any more
2200 git-debrebase: WARNING: doing so would drop all upstream patches!
2201 END
2202 }
2203
2204 sub cmd_convert_from_dgit_view () {
2205     my $clogp = parsechangelog();
2206
2207     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2208     my $do_origs = 1;
2209     my $do_tags = 1;
2210     my $always = 0;
2211     my $diagnose = 0;
2212
2213     getoptions("convert-from-dgit-view",
2214                'diagnose!', \$diagnose,
2215                'build-products-dir:s', \$bpd,
2216                'origs!', \$do_origs,
2217                'tags!', \$do_tags,
2218                'always-convert-anyway!', \$always);
2219     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2220
2221     my @upstreams;
2222
2223     if (@ARGV) {
2224         my $spec = shift @ARGV;
2225         my $commit = git_rev_parse "$spec^{commit}";
2226         push @upstreams, { Commit => $commit,
2227                            Source => "$ARGV[0], from command line",
2228                            Only => 1,
2229                          };
2230     }
2231
2232     my $head = get_head();
2233
2234     if (!$always) {
2235         my $troubles = 0;
2236         my $trouble = sub { $troubles++; };
2237         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2238         printdebug "troubles=$troubles\n";
2239         if (!$troubles) {
2240             print STDERR <<END;
2241 $us: Branch already seems to be in git-debrebase format!
2242 $us: --always-convert-anyway would do the conversion operation anyway
2243 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2244 END
2245             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2246             finish 0;
2247         }
2248     }
2249
2250     snags_maybe_bail_early();
2251
2252     my $version = upstreamversion $clogp->{Version};
2253     print STDERR "Considering possible commits corresponding to upstream:\n";
2254
2255     if (!@upstreams) {
2256         if ($do_tags) {
2257             my @tried;
2258             my $ups_tag = upstream_commitish_search $version, \@tried;
2259             if ($ups_tag) {
2260                 my $this = "git tag $tried[-1]";
2261                 push @upstreams, { Commit => $ups_tag,
2262                                    Source => $this,
2263                                  };
2264             } else {
2265                 printf STDERR
2266                     " git tag: no suitable tag found (tried %s)\n",
2267                     "@tried";
2268             }
2269         }
2270         if ($do_origs) {
2271             my $p = $clogp->{'Source'};
2272             # we do a quick check to see if there are plausible origs
2273             my $something=0;
2274             if (!opendir BPD, $bpd) {
2275                 die "$bpd: opendir: $!" unless $!==ENOENT;
2276             } else {
2277                 while ($!=0, my $f = readdir BPD) {
2278                     next unless is_orig_file_of_p_v $f, $p, $version;
2279                     printf STDERR
2280                         " orig: found what looks like a .orig, %s\n",
2281                         "$bpd/$f";
2282                     $something=1;
2283                     last;
2284                 }
2285                 die "read $bpd: $!" if $!;
2286                 closedir BPD;
2287             }
2288             if ($something) {
2289                 my $tree = cmdoutput
2290                     @dgit, qw(--build-products-dir), $bpd,
2291                     qw(print-unapplied-treeish);
2292                 fresh_workarea();
2293                 in_workarea sub {
2294                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2295                     rm_subdir_cached 'debian';
2296                     $tree = cmdoutput @git, qw(write-tree);
2297                     my $ups_synth = make_commit [], [ <<END, <<END,
2298 Import effective orig tree for upstream version $version
2299 END
2300 This includes the contents of the .orig(s), minus any debian/ directory.
2301
2302 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2303 END
2304                                                     ];
2305                     push @upstreams, { Commit => $ups_synth,
2306                                        Source => "orig(s) imported via dgit",
2307                                      };
2308                 }
2309             } else {
2310                 printf STDERR
2311                     " orig: no suitable origs found (looked for %s in %s)\n",
2312                     "${p}_".(stripeoch $version)."...", $bpd;
2313             }
2314         }
2315     }
2316
2317     my $some_patches = stat_exists 'debian/patches/series';
2318
2319     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2320
2321     my $result;
2322     foreach my $u (@upstreams) {
2323         my $work = $head;
2324         fresh_workarea();
2325         in_workarea sub {
2326             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2327             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2328             runcmd @git, qw(clean -xdff);
2329             runcmd @git, qw(checkout), $head, qw(-- debian);
2330             if ($some_patches) {
2331                 rm_subdir_cached 'debian/patches';
2332                 $work = make_commit [ $work ], [
2333  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2334  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2335  "to git-debrebase format.  Upstream changes will appear as commits.",
2336  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2337                                            ];
2338             }
2339             $work = make_commit [ $work, $u->{Commit} ], [
2340  'git-debrebase convert-from-dgit-view: declare upstream',
2341  '(Re)constructed breakwater merge.',
2342  '[git-debrebase anchor: declare upstream]'
2343                                                          ];
2344             runcmd @git, qw(checkout --quiet -b mk), $work;
2345             if ($some_patches) {
2346                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2347                 runcmd @git, qw(reset --quiet);
2348                 my @gbp_cmd = (qw(gbp pq import));
2349                 if (!$diagnose) {
2350                     my $gbp_err = "../gbp-pq-err";
2351                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2352                 }
2353                 my $r = system @gbp_cmd;
2354                 if ($r) {
2355                     printf STDERR
2356                         " %s: couldn't apply patches: gbp pq %s",
2357                         $u->{Source}, waitstatusmsg();
2358                     return;
2359                 }
2360             }
2361             my $work = git_rev_parse qw(HEAD);
2362             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2363             if (length $diffout) {
2364                 print STDERR
2365                     " $u->{Source}: applying patches gives different tree\n";
2366                 print STDERR $diffout if $diagnose;
2367                 return;
2368             }
2369             # OMG!
2370             $u->{Result} = $work;
2371             $result = $u;
2372         };
2373         last if $result;
2374     }
2375
2376     if (!$result) {
2377         fail <<END;
2378 Could not find or construct a suitable upstream commit.
2379 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2380 upstream commmit explicitly or provide suitable origs.
2381 END
2382     }
2383
2384     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2385
2386     ffq_check $result->{Result};
2387     snags_maybe_bail();
2388     update_head_checkout $head, $result->{Result},
2389         'convert-from-dgit-view';
2390 }
2391
2392 sub cmd_downstream_rebase_launder_v0 () {
2393     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2394     my ($base) = @ARGV;
2395     $base = git_rev_parse $base;
2396     my $old_head = get_head();
2397     my $current = $old_head;
2398     my $topmost_keep;
2399     for (;;) {
2400         if ($current eq $base) {
2401             $topmost_keep //= $current;
2402             print " $current BASE stop\n";
2403             last;
2404         }
2405         my $cl = classify $current;
2406         print " $current $cl->{Type}";
2407         my $keep = 0;
2408         my $p0 = $cl->{Parents}[0]{CommitId};
2409         my $next;
2410         if ($cl->{Type} eq 'Pseudomerge') {
2411             print " ^".($cl->{Contributor}{Ix}+1);
2412             $next = $cl->{Contributor}{CommitId};
2413         } elsif ($cl->{Type} eq 'AddPatches' or
2414                  $cl->{Type} eq 'Changelog') {
2415             print " strip";
2416             $next = $p0;
2417         } else {
2418             print " keep";
2419             $next = $p0;
2420             $keep = 1;
2421         }
2422         print "\n";
2423         if ($keep) {
2424             $topmost_keep //= $current;
2425         } else {
2426             die "to-be stripped changes not on top of the branch\n"
2427                 if $topmost_keep;
2428         }
2429         $current = $next;
2430     }
2431     if ($topmost_keep eq $old_head) {
2432         print "unchanged\n";
2433     } else {
2434         print "updating to $topmost_keep\n";
2435         update_head_checkout
2436             $old_head, $topmost_keep,
2437             'downstream-rebase-launder-v0';
2438     }
2439 }
2440
2441 getoptions_main
2442           ("bad options\n",
2443            "D+" => \$debuglevel,
2444            'noop-ok', => \$opt_noop_ok,
2445            'f=s' => \@snag_force_opts,
2446            'anchor=s' => \@opt_anchors,
2447            '--dgit=s' => \($dgit[0]),
2448            'force!',
2449            '-i:s' => sub {
2450                my ($opt,$val) = @_;
2451                badusage "git-debrebase: no cuddling to -i for git-rebase"
2452                    if length $val;
2453                die if $opt_defaultcmd_interactive; # should not happen
2454                $opt_defaultcmd_interactive = [ qw(-i) ];
2455                # This access to @ARGV is excessive familiarity with
2456                # Getopt::Long, but there isn't another sensible
2457                # approach.  '-i=s{0,}' does not work with bundling.
2458                push @$opt_defaultcmd_interactive, @ARGV;
2459                @ARGV=();
2460            },
2461            'help' => sub { print $usage_message or die $!; finish 0; },
2462            );
2463
2464 initdebug('git-debrebase ');
2465 enabledebug if $debuglevel;
2466
2467 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2468 chdir $toplevel or die "chdir $toplevel: $!";
2469
2470 $rd = fresh_playground "$playprefix/misc";
2471
2472 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2473
2474 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2475     defaultcmd_rebase();
2476 } else {
2477     my $cmd = shift @ARGV;
2478     my $cmdfn = $cmd;
2479     $cmdfn =~ y/-/_/;
2480     $cmdfn = ${*::}{"cmd_$cmdfn"};
2481
2482     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2483     $cmdfn->();
2484 }
2485
2486 finish 0;