chiark / gitweb /
3d74d0ebc3876f1cb9ca677e56c9eaf88e80d3de
[dgit.git] / git-debrebase
1 #!/usr/bin/perl -w
2 # git-debrebase
3 # Script helping make fast-forwarding histories while still rebasing
4 # upstream deltas when working on Debian packaging
5 #
6 # Copyright (C)2017,2018 Ian Jackson
7 #
8 # This program is free software: you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation, either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
20
21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
22 use Debian::Dgit::GDR;
23 use Debian::Dgit::ExitStatus;
24
25 use strict;
26
27 use Debian::Dgit qw(:DEFAULT :playground);
28 setup_sigwarn();
29
30 use Memoize;
31 use Carp;
32 use POSIX;
33 use Data::Dumper;
34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
35 use Dpkg::Version;
36 use File::FnMatch qw(:fnmatch);
37 use File::Copy;
38
39 $debugcmd_when_debuglevel = 2;
40
41 our ($usage_message) = <<'END';
42 usages:
43   git-debrebase [<options>] [--|-i <git rebase options...>]
44   git-debrebase [<options>] status
45   git-debrebase [<options>] prepush [--prose=...]
46   git-debrebase [<options>] quick|conclude
47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
49   ...
50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
51 END
52
53 our ($opt_force, $opt_noop_ok, @opt_anchors);
54 our ($opt_defaultcmd_interactive);
55
56 our $us = qw(git-debrebase);
57
58 $|=1;
59
60 sub badusage ($) {
61     my ($m) = @_;
62     print STDERR "$us: bad usage: $m\n";
63     finish 8;
64 }
65
66 sub getoptions_main {
67     my $m = shift;
68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
69     GetOptions @_ or badusage $m;
70 }
71 sub getoptions {
72     my $sc = shift;
73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
74 }
75
76 sub cfg ($;$) {
77     my ($k, $optional) = @_;
78     local $/ = "\0";
79     my @cmd = qw(git config -z);
80     push @cmd, qw(--get-all) if wantarray;
81     push @cmd, $k;
82     my $out = cmdoutput_errok @cmd;
83     if (!defined $out) {
84         fail "missing required git config $k" unless $optional;
85         return ();
86     }
87     my @l = split /\0/, $out;
88     return wantarray ? @l : $l[0];
89 }
90
91 memoize('cfg');
92
93 sub dd ($) {
94     my ($v) = @_;
95     my $dd = new Data::Dumper [ $v ];
96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
97     return Dump $dd;
98 }
99
100 sub get_commit ($) {
101     my ($objid) = @_;
102     my $data = (git_cat_file $objid, 'commit');
103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
104     return ($`,$');
105 }
106
107 sub D_UPS ()      { 0x02; } # upstream files
108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
113
114 our $playprefix = 'debrebase';
115 our $rd;
116 our $workarea;
117
118 our @git = qw(git);
119 our @dgit = qw(dgit);
120
121 sub in_workarea ($) {
122     my ($sub) = @_;
123     changedir $workarea;
124     my $r = eval { $sub->(); };
125     { local $@; changedir $maindir; }
126     die $@ if $@;
127 }
128
129 sub fresh_workarea () {
130     $workarea = fresh_playground "$playprefix/work";
131     in_workarea sub { playtree_setup };
132 }
133
134 our $snags_forced = 0;
135 our $snags_tripped = 0;
136 our $snags_summarised = 0;
137 our @deferred_updates;
138 our @deferred_update_messages;
139
140 sub all_snags_summarised () {
141     $snags_forced + $snags_tripped == $snags_summarised;
142 }
143 sub run_deferred_updates ($) {
144     my ($mrest) = @_;
145
146     confess 'dangerous internal error' unless all_snags_summarised();
147
148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
149     debugcmd '>|', @upd_cmd;
150     open U, "|-", @upd_cmd or die $!;
151     foreach (@deferred_updates) {
152         printdebug ">= ", $_, "\n";
153         print U $_, "\n" or die $!;
154     }
155     printdebug ">\$\n";
156     close U or failedcmd @upd_cmd;
157
158     print $_, "\n" foreach @deferred_update_messages;
159
160     @deferred_updates = ();
161     @deferred_update_messages = ();
162 }
163
164 sub get_differs ($$) {
165     my ($x,$y) = @_;
166     # This resembles quiltify_trees_differ, in dgit, a bit.
167     # But we don't care about modes, or dpkg-source-unrepresentable
168     # changes, and we don't need the plethora of different modes.
169     # Conversely we need to distinguish different kinds of changes to
170     # debian/ and debian/patches/.
171
172     my $differs = 0;
173
174     my $rundiff = sub {
175         my ($opts, $limits, $fn) = @_;
176         my @cmd = (@git, qw(diff-tree -z --no-renames));
177         push @cmd, @$opts;
178         push @cmd, "$_:" foreach $x, $y;
179         push @cmd, '--', @$limits;
180         my $diffs = cmdoutput @cmd;
181         foreach (split /\0/, $diffs) { $fn->(); }
182     };
183
184     $rundiff->([qw(--name-only)], [], sub {
185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
186     });
187
188     if ($differs & DS_DEB) {
189         $differs &= ~DS_DEB;
190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
191             $differs |=
192                 m{^debian/patches/}      ? D_PAT_OTH  :
193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
194                                            D_DEB_OTH;
195         });
196         die "mysterious debian changes $x..$y"
197             unless $differs & (D_PAT_OTH|DS_DEB);
198     }
199
200     if ($differs & D_PAT_OTH) {
201         my $mode;
202         $differs &= ~D_PAT_OTH;
203         my $pat_oth = sub {
204             $differs |= D_PAT_OTH;
205             no warnings qw(exiting);  last;
206         };
207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
208             no warnings qw(exiting);
209             if (!defined $mode) {
210                 $mode = $_;  next;
211             }
212             die unless s{^debian/patches/}{};
213             my $ok;
214             if ($mode eq 'A' && !m/\.series$/s) {
215                 $ok = 1;
216             } elsif ($mode eq 'M' && $_ eq 'series') {
217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
219                 chomp $x_s;  $x_s .= "\n";
220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
221             } else {
222                 # nope
223             }
224             $mode = undef;
225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
226         });
227         die "mysterious debian/patches changes $x..$y"
228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
229     }
230
231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
232
233     return $differs;
234 }
235
236 sub commit_pr_info ($) {
237     my ($r) = @_;
238     return Data::Dumper->dump([$r], [qw(commit)]);
239 }
240
241 sub calculate_committer_authline () {
242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
244     my ($h,$m) = get_commit $c;
245     $h =~ m/^committer .*$/m or confess "($h) ?";
246     return $&;
247 }
248
249 sub rm_subdir_cached ($) {
250     my ($subdir) = @_;
251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
252 }
253
254 sub read_tree_subdir ($$) {
255     my ($subdir, $new_tree_object) = @_;
256     rm_subdir_cached $subdir;
257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
258 }
259
260 sub read_tree_debian ($) {
261     my ($treeish) = @_;
262     read_tree_subdir 'debian', "$treeish:debian";
263     rm_subdir_cached 'debian/patches';
264 }
265
266 sub read_tree_upstream ($;$$) {
267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
268     # if $tree_with_debian is supplied, will use that for debian/
269     # otherwise will save and restore it.
270     my $debian =
271         $tree_with_debian ? "$tree_with_debian:debian"
272         : cmdoutput @git, qw(write-tree --prefix=debian/);
273     runcmd @git, qw(read-tree), $treeish;
274     read_tree_subdir 'debian', $debian;
275     rm_subdir_cached 'debian/patches' unless $keep_patches;
276 };
277
278 sub make_commit ($$) {
279     my ($parents, $message_paras) = @_;
280     my $tree = cmdoutput @git, qw(write-tree);
281     my @cmd = (@git, qw(commit-tree), $tree);
282     push @cmd, qw(-p), $_ foreach @$parents;
283     push @cmd, qw(-m), $_ foreach @$message_paras;
284     return cmdoutput @cmd;
285 }
286
287 our @snag_force_opts;
288 sub snag ($$;@) {
289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
290     if (grep { $_ eq $tag } @snag_force_opts) {
291         $snags_forced++;
292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
293     } else {
294         $snags_tripped++;
295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
296     }
297 }
298
299 # Important: all mainline code must call snags_maybe_bail after
300 # any point where snag might be called, but before making changes
301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
302 # may be called more than once if necessary (but this is not ideal
303 # because then the messages about number of snags may be confusing).
304 sub snags_maybe_bail () {
305     return if all_snags_summarised();
306     if ($snags_forced) {
307         printf STDERR
308             "%s: snags: %d overriden by individual -f options\n",
309             $us, $snags_forced;
310     }
311     if ($snags_tripped) {
312         if ($opt_force) {
313             printf STDERR
314                 "%s: snags: %d overriden by global --force\n",
315                 $us, $snags_tripped;
316         } else {
317             fail sprintf
318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
319                 $us, $snags_tripped;
320         }
321     }
322     $snags_summarised = $snags_forced + $snags_tripped;
323 }
324 sub snags_maybe_bail_early () {
325     # useful to bail out early without doing a lot of work;
326     # not a substitute for snags_maybe_bail.
327     snags_maybe_bail() if $snags_tripped && !$opt_force;
328 }
329 sub any_snags () {
330     return $snags_forced || $snags_tripped;
331 }
332
333 sub gbp_pq_export ($$$) {
334     my ($bname, $base, $tip) = @_;
335     # must be run in a workarea.  $bname and patch-queue/$bname
336     # ought not to exist.  Leaves you on patch-queue/$bname with
337     # the patches staged but not committed.
338     printdebug "gbp_pq_export $bname $base $tip\n";
339     runcmd @git, qw(checkout -q -b), $bname, $base;
340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
341     my @gbp_cmd = (qw(gbp pq export));
342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
343     if ($r) {
344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
345         failedcmd @gbp_cmd;
346     }
347     runcmd @git, qw(add -f debian/patches);
348 }
349
350
351 # xxx allow merge resolution separately from laundering, before git merge
352 #
353 # xxx general gdr docs highlight forbidden things
354 # xxx general gdr docs list allowable things ?
355 # xxx general gdr docs explicitly forbid some rebase
356 #
357 # xxx provide a way for the user to help
358 # xxx (eg, provide wreckage provide way to continue)
359
360 # later/rework?
361 #  use git-format-patch?
362 #  our own patch identification algorithm?
363 #  this is an alternative strategy
364
365 sub merge_series ($$$;@) {
366     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
367     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
368     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
369     # ^ specifies several patch series (currently we only support exactly 2)
370     # return value is a commit which is the result of
371     # merging the two versions of the same topic branch
372     #   $input_q[0] and $input_q[1]
373     # with respect to the old version
374     #   $base_q
375     # all onto $newbase.
376
377     # Creates, in *_q, a key MR for its private use
378
379     printdebug "merge_series newbase=$newbase\n";
380
381     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
382     $base_q->{MR}{S} = 'base';
383
384     my %prereq;
385     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
386     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
387     # $prereq{<patch filename>}               exists or not (even later)
388
389     my $result;
390
391     my $mwrecknote = sub {
392         my ($reftail, $commitish) = @_;
393         $wrecknotes->{$reftail} = $commitish;
394     };
395
396     local $workarea = fresh_playground "$playprefix/merge";
397     my $seriesfile = "debian/patches/series";
398     in_workarea sub {
399         playtree_setup();
400         foreach my $q ($base_q, reverse @input_qs) {
401             my $s = $q->{MR}{S};
402             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
403             my @earlier;
404             if (open S, $seriesfile) {
405                 while (my $patch = <S>) {
406                     chomp $patch or die $!;
407                     $prereq{$patch} //= {};
408                     foreach my $earlier (@earlier) {
409                         $prereq{$patch}{$earlier}{$s}++ and die;
410                     }
411                     push @earlier, $patch;
412                     stat "debian/patches/$patch" or die "$patch ?";
413                 }
414                 S->error and die "$seriesfile $!";
415                 close S;
416             } else {
417                 die "$seriesfile $!" unless $!==ENOENT;
418             }
419             read_tree_upstream $newbase, 1;
420             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
421                 "Convert $s to patch queue for merging",
422                 "[git-debrebase merge-innards patch-queue import:".
423                 " $q->{SeriesTip}]"
424             ];
425             printdebug "merge_series  pec $pec ";
426             runcmd @git, qw(rm -q --cached), $seriesfile;
427             $pec = make_commit [ $pec ], [
428                 "Drop series file from $s to avoid merge trouble",
429                 "[git-debrebase merge-innards patch-queue prep:".
430                 " $q->{SeriesTip}]"
431             ];
432
433             read_tree_debian $newbase;
434             if (@earlier) {
435                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
436             } else {
437                 rm_subdir_cached 'debian/patches';
438             }
439             $pec = make_commit [ $pec ], [
440  "Update debian/ (excluding patches) to final to avoid re-merging",
441  "debian/ was already merged and we need to just take that.",
442                 "[git-debrebase merge-innards patch-queue packaging:".
443                 " $q->{SeriesTip}]"
444             ];
445
446             printdebug "pec' $pec\n";
447             runcmd @git, qw(reset -q --hard), $pec;
448             $q->{MR}{PEC} = $pec;
449             $mwrecknote->("$q->{LeftRight}-patchqueue");
450         }
451         # now, because of reverse, we are on $input_q->{MR}{OQC}
452         runcmd @git, qw(checkout -q -b merge);
453         printdebug "merge_series merging...\n";
454         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
455         debugcmd '+', @mergecmd;
456         $!=0; $?=-1;
457         if (system @mergecmd) {
458             failedcmd @mergecmd;
459         }
460
461         printdebug "merge_series merge ok, series...\n";
462         # We need to construct a new series file
463         # Firstly, resolve prereq
464         foreach my $f (sort keys %prereq) {
465             printdebug "merge_series  patch\t$f\t";
466             if (!stat_exists "debian/patches/$f") {
467                 print DEBUG " drop\n" if $debuglevel;
468                 # git merge deleted it; that's how we tell it's not wanted
469                 delete $prereq{$f};
470                 next;
471             }
472             print DEBUG " keep\n" if $debuglevel;
473             foreach my $g (sort keys %{ $prereq{$f} }) {
474                 my $gfp = $prereq{$f}{$g};
475                 printdebug "merge_series  prereq\t$f\t-> $g\t";
476                 if (!!$gfp->{0} == !!$gfp->{1}
477                     ? $gfp->{0}
478                     : !$gfp->{base}) {
479                     print DEBUG "\tkeep\n" if $debuglevel;
480                 } else {
481                     print DEBUG "\tdrop\n" if $debuglevel;
482                     delete $prereq{$f}{$g};
483                 }
484             }
485         }
486
487         my $unsat = sub {
488             my ($f) = @_;
489             return scalar keys %{ $prereq{$f} };
490         };
491
492         my $nodate = time + 1;
493         my %authordate;
494         # $authordate{<patch filename>};
495         my $authordate = sub {
496             my ($f) = @_;
497             $authordate{$f} //= do {
498                 open PF, "<", "debian/patches/$f" or die "$f $!";
499                 while (<PF>) {
500                     return $nodate if m/^$/;
501                     last if s{^Date: }{};
502                 }
503                 chomp;
504                 return cmdoutput qw(date +%s -d), $_;
505             };
506         };
507
508         open NS, '>', $seriesfile or die $!;
509
510         while (keys %prereq) {
511             my $best;
512             foreach my $try (sort keys %prereq) {
513                 if ($best) {
514                     next if (
515                              $unsat->($try) <=> $unsat->($best) or
516                              $authordate->($try) <=> $authordate->($best) or
517                              $try cmp $best
518                             ) >= 0;
519                 }
520                 $best = $try;
521             }
522             printdebug "merge_series series next $best\n";
523             print NS "$best\n" or die $!;
524             delete $prereq{$best};
525             foreach my $gp (values %prereq) {
526                 delete $gp->{$best};
527             }
528         }
529
530         runcmd @git, qw(add), $seriesfile;
531         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
532         $mwrecknote->('merged-patchqueue', git_rev_parse 'HEAD');
533
534         printdebug "merge_series series gbp pq import\n";
535         runcmd qw(gbp pq import);
536
537         # OK now we are on patch-queue/merge, and we need to rebase
538         # onto the intended parent and drop the patches from each one
539
540         printdebug "merge_series series ok, building...\n";
541         my $build = $newbase;
542         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
543         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
544             my $commit = git_cat_file $c, 'commit';
545             printdebug "merge_series series ok, building $c\n";
546             read_tree_upstream $c, 0, $newbase;
547             my $tree = cmdoutput @git, qw(write-tree);
548             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
549             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
550             open C, ">", "../mcommit" or die $!;
551             print C $commit or die $!;
552             close C or die $!;
553             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
554         }
555         $result = $build;
556         $mwrecknote->('merged-result', $result);
557
558         runcmd @git, qw(update-ref refs/heads/result), $result;
559
560         runcmd @git, qw(checkout -q -b debug);
561         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
562         runcmd @git, qw(add .);
563         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
564         my $mdebug = git_rev_parse 'HEAD';
565         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
566         $mwrecknote->('merged-debug', $mdebug);
567     };
568     printdebug "merge_series returns $result\n";
569     return $result;
570 }
571
572 # classify returns an info hash like this
573 #   CommitId => $objid
574 #   Hdr => # commit headers, including 1 final newline
575 #   Msg => # commit message (so one newline is dropped)
576 #   Tree => $treeobjid
577 #   Type => (see below)
578 #   Parents = [ {
579 #       Ix => $index # ie 0, 1, 2, ...
580 #       CommitId
581 #       Differs => return value from get_differs
582 #       IsOrigin
583 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
584 #     } ...]
585 #   NewMsg => # commit message, but with any [dgit import ...] edited
586 #             # to say "[was: ...]"
587 #
588 # Types:
589 #   Packaging
590 #   Changelog
591 #   Upstream
592 #   AddPatches
593 #   Mixed
594 #
595 #   Pseudomerge
596 #     has additional entres in classification result
597 #       Overwritten = [ subset of Parents ]
598 #       Contributor = $the_remaining_Parent
599 #
600 #   DgitImportUnpatched
601 #     has additional entry in classification result
602 #       OrigParents = [ subset of Parents ]
603 #
604 #   Anchor
605 #     has additional entry in classification result
606 #       OrigParents = [ subset of Parents ]  # singleton list
607 #
608 #   TreatAsAnchor
609 #
610 #   BreakwaterStart
611 #
612 #   Unknown
613 #     has additional entry in classification result
614 #       Why => "prose"
615
616 sub parsecommit ($;$) {
617     my ($objid, $p_ref) = @_;
618     # => hash with                   CommitId Hdr Msg Tree Parents
619     #    Parents entries have only   Ix CommitId
620     #    $p_ref, if provided, must be [] and is used as a base for Parents
621
622     $p_ref //= [];
623     die if @$p_ref;
624
625     my ($h,$m) = get_commit $objid;
626
627     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
628     my (@ph) = $h =~ m/^parent (\w+)$/mg;
629
630     my $r = {
631         CommitId => $objid,
632         Hdr => $h,
633         Msg => $m,
634         Tree => $t,
635         Parents => $p_ref,
636     };
637
638     foreach my $ph (@ph) {
639         push @$p_ref, {
640             Ix => scalar @$p_ref,
641             CommitId => $ph,
642         };
643     }
644
645     return $r;
646 }    
647
648 sub classify ($) {
649     my ($objid) = @_;
650
651     my @p;
652     my $r = parsecommit($objid, \@p);
653     my $t = $r->{Tree};
654
655     foreach my $p (@p) {
656         $p->{Differs} = (get_differs $p->{CommitId}, $t),
657     }
658
659     printdebug "classify $objid \$t=$t \@p",
660         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
661         "\n";
662
663     my $classify = sub {
664         my ($type, @rest) = @_;
665         $r = { %$r, Type => $type, @rest };
666         if ($debuglevel) {
667             printdebug " = $type ".(dd $r)."\n";
668         }
669         return $r;
670     };
671     my $unknown = sub {
672         my ($why) = @_;
673         $r = { %$r, Type => qw(Unknown), Why => $why };
674         printdebug " ** Unknown\n";
675         return $r;
676     };
677
678     if (grep { $_ eq $objid } @opt_anchors) {
679         return $classify->('TreatAsAnchor');
680     }
681
682     my @identical = grep { !$_->{Differs} } @p;
683     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
684     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
685
686     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
687         # multi-orig upstreams are represented with an anchor merge
688         # from a single upstream commit which combines the orig tarballs
689
690         # Every anchor tagged this way must be a merge.
691         # We are relying on the
692         #     [git-debrebase anchor: ...]
693         # commit message annotation in "declare" anchor merges (which
694         # do not have any upstream changes), to distinguish those
695         # anchor merges from ordinary pseudomerges (which we might
696         # just try to strip).
697         #
698         # However, the user is going to be doing git-rebase a lot.  We
699         # really don't want them to rewrite an anchor commit.
700         # git-rebase trips up on merges, so that is a useful safety
701         # catch.
702         #
703         # BreakwaterStart commits are also anchors in the terminology
704         # of git-debrebase(5), but they are untagged (and always
705         # manually generated).
706         #
707         # We cannot not tolerate any tagged linear commit (ie,
708         # BreakwaterStart commits tagged `[anchor:') because such a
709         # thing could result from an erroneous linearising raw git
710         # rebase of a merge anchor.  That would represent a corruption
711         # of the branch. and we want to detect and reject the results
712         # of such corruption before it makes it out anywhere.  If we
713         # reject it here then we avoid making the pseudomerge which
714         # would be needed to push it.
715
716         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
717         @p == 2 or return $badanchor->("has other than two parents");
718         $haspatches and return $badanchor->("contains debian/patches");
719
720         # How to decide about l/r ordering of anchors ?  git
721         # --topo-order prefers to expand 2nd parent first.  There's
722         # already an easy rune to look for debian/ history anyway (git log
723         # debian/) so debian breakwater branch should be 1st parent; that
724         # way also there's also an easy rune to look for the upstream
725         # patches (--topo-order).
726
727         # Also this makes --first-parent be slightly more likely to
728         # be useful - it makes it provide a linearised breakwater history.
729
730         # Of course one can say somthing like
731         #  gitk -- ':/' ':!/debian'
732         # to get _just_ the commits touching upstream files, and by
733         # the TREESAME logic in git-rev-list this will leave the
734         # breakwater into upstream at the first anchor.  But that
735         # doesn't report debian/ changes at all.
736
737         # Other observations about gitk: by default, gitk seems to
738         # produce output in a different order to git-rev-list.  I
739         # can't seem to find this documented anywhere.  gitk
740         # --date-order DTRT.  But, gitk always seems to put the
741         # parents from left to right, in order, so it's easy to see
742         # which way round a pseudomerge is.
743
744         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
745         $p[1]{Differs} & ~DS_DEB and
746             $badanchor->("upstream files differ from left parent");
747         $p[0]{Differs} & ~D_UPS and
748             $badanchor->("debian/ differs from right parent");
749
750         return $classify->(qw(Anchor),
751                            OrigParents => [ $p[1] ]);
752     }
753
754     if (@p == 1) {
755         my $d = $r->{Parents}[0]{Differs};
756         if ($d == D_PAT_ADD) {
757             return $classify->(qw(AddPatches));
758         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
759             return $unknown->("edits debian/patches");
760         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
761             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
762             if ($ty eq 'tree') {
763                 if ($d == D_DEB_CLOG) {
764                     return $classify->(qw(Changelog));
765                 } else {
766                     return $classify->(qw(Packaging));
767                 }
768             } elsif ($ty eq 'missing') {
769                 return $classify->(qw(BreakwaterStart));
770             } else {
771                 return $unknown->("parent's debian is not a directory");
772             }
773         } elsif ($d == D_UPS) {
774             return $classify->(qw(Upstream));
775         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
776             return $classify->(qw(Mixed));
777         } elsif ($d == 0) {
778             return $unknown->("no changes");
779         } else {
780             confess "internal error $objid ?";
781         }
782     }
783     if (!@p) {
784         return $unknown->("origin commit");
785     }
786
787     if (@p == 2 && @identical == 1) {
788         my @overwritten = grep { $_->{Differs} } @p;
789         confess "internal error $objid ?" unless @overwritten==1;
790         return $classify->(qw(Pseudomerge),
791                            Overwritten => [ $overwritten[0] ],
792                            Contributor => $identical[0]);
793     }
794     if (@p == 2 && @identical == 2) {
795         my $get_t = sub {
796             my ($ph,$pm) = get_commit $_[0]{CommitId};
797             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
798             $1;
799         };
800         my @bytime = @p;
801         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
802         if ($order > 0) { # newer first
803         } elsif ($order < 0) {
804             @bytime = reverse @bytime;
805         } else {
806             # same age, default to order made by -s ours
807             # that is, commit was made by someone who preferred L
808         }
809         return $classify->(qw(Pseudomerge),
810                            SubType => qw(Ambiguous),
811                            Contributor => $bytime[0],
812                            Overwritten => [ $bytime[1] ]);
813     }
814     foreach my $p (@p) {
815         my ($p_h, $p_m) = get_commit $p->{CommitId};
816         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
817         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
818     }
819     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
820     my $m2 = $r->{Msg};
821     if (!(grep { !$_->{IsOrigin} } @p) and
822         (@orig_ps >= @p - 1) and
823         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
824         $r->{NewMsg} = $m2;
825         return $classify->(qw(DgitImportUnpatched),
826                            OrigParents => \@orig_ps);
827     }
828
829     if (@p == 2 and
830         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
831         # xxx ^ metadata tag needs adding to (5)
832         return $classify->("MergedBreakwaters");
833     }
834     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
835         return $unknown->("unknown kind of merge from $1");
836     }
837     if (@p > 2) {
838         return $unknown->("octopus merge");
839     }
840
841     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
842         return $unknown->("general two-parent merge");
843     }
844
845     return $classify->("VanillaMerge");
846 }
847
848 sub keycommits ($;$$$$$);
849
850 sub mergedbreakwaters_anchor ($) {
851     my ($cl) = @_;
852     my $best_anchor;
853     foreach my $p (@{ $cl->{Parents} }) {
854         my ($panchor, $pbw) = keycommits $p->{CommitId},
855             undef,undef,undef,undef, 1;
856         $best_anchor = $panchor
857             if !defined $best_anchor
858             or is_fast_fwd $best_anchor, $panchor;
859         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
860             unless is_fast_fwd $panchor, $best_anchor;
861     }
862     return $best_anchor;
863 }
864
865 sub keycommits ($;$$$$$) {
866     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
867     # => ($anchor, $breakwater)
868
869     # $unclean->("unclean-$tagsfx", $msg, $cl)
870     # $furniture->("unclean-$tagsfx", $msg, $cl)
871     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
872     #   is callled for each situation or commit that
873     #   wouldn't be found in a laundered branch
874     # $furniture is for furniture commits such as might be found on an
875     #   interchange branch (pseudomerge, d/patches, changelog)
876     # $trouble is for things whnich prevent the return of
877     #   anchor and breakwater information; if that is ignored,
878     #   then keycommits returns (undef, undef) instead.
879     # $fatal is for unprocessable commits, and should normally cause
880     #    a failure.  If ignored, agaion, (undef, undef) is returned.
881     #
882     # If $claimed_bw, this is supposed to be a breakwater commit.
883     #
884     # If a callback is undef, fail is called instead.
885     # If a callback is defined but false, the situation is ignored.
886     # Callbacks may say:
887     #   no warnings qw(exiting); last;
888     # if the answer is no longer wanted.
889
890     my ($anchor, $breakwater);
891     $breakwater = $head if $claimed_bw;
892     my $clogonly;
893     my $cl;
894     my $found_pm;
895     $fatal //= sub { fail $_[1]; };
896     my $x = sub {
897         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
898         my $why = $mainwhy.$xwhy;
899         my $m = "branch needs laundering (run git-debrebase): $why";
900         fail $m unless defined $cb;
901         return unless $cb;
902         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
903     };
904     my $found_anchor = sub {
905         ($anchor) = @_;
906         $breakwater //= $clogonly;
907         $breakwater //= $head;
908         no warnings qw(exiting);
909         last;
910     };
911     for (;;) {
912         $cl = classify $head;
913         my $ty = $cl->{Type};
914         if ($ty eq 'Packaging') {
915             $breakwater //= $clogonly;
916             $breakwater //= $head;
917         } elsif ($ty eq 'Changelog') {
918             # this is going to count as the tip of the breakwater
919             # only if it has no upstream stuff before it
920             $clogonly //= $head;
921         } elsif ($ty eq 'Anchor' or
922                  $ty eq 'TreatAsAnchor' or
923                  $ty eq 'BreakwaterStart') {
924             $found_anchor->($head);
925         } elsif ($ty eq 'Upstream') {
926             $x->($unclean, 'ordering',
927  "packaging change ($breakwater) follows upstream change"," (eg $head)")
928                 if defined $breakwater;
929             $clogonly = undef;
930             $breakwater = undef;
931         } elsif ($ty eq 'Mixed') {
932             $x->($unclean, 'mixed',
933                  "found mixed upstream/packaging commit"," ($head)");
934             $clogonly = undef;
935             $breakwater = undef;
936         } elsif ($ty eq 'Pseudomerge' or
937                  $ty eq 'AddPatches') {
938             my $found_pm = 1;
939             $x->($furniture, (lc $ty),
940                  "found interchange bureaucracy commit ($ty)"," ($head)");
941         } elsif ($ty eq 'DgitImportUnpatched') {
942             if ($found_pm) {
943                 $x->($trouble, 'dgitimport',
944                      "found dgit dsc import"," ($head)");
945                 return (undef,undef);
946             } else {
947                 $x->($fatal, 'unprocessable',
948                      "found bare dgit dsc import with no prior history",
949                      " ($head)");
950                 return (undef,undef);
951             }
952         } elsif ($ty eq 'VanillaMerge') {
953             $x->($trouble, 'vanillamerge',
954                  "found vanilla merge"," ($head)");
955             return (undef,undef);
956         } elsif ($ty eq 'MergedBreakwaters') {
957             $found_anchor->(mergedbreakwaters_anchor $cl);
958         } else {
959             $x->($fatal, 'unprocessable',
960                  "found unprocessable commit, cannot cope: $cl->{Why}",
961                  " ($head)");
962             return (undef,undef);
963         }
964         $head = $cl->{Parents}[0]{CommitId};
965     }
966     return ($anchor, $breakwater);
967 }
968
969 sub walk ($;$$$);
970 sub walk ($;$$$) {
971     my ($input,
972         $nogenerate,$report, $report_lprefix) = @_;
973     # => ($tip, $breakwater_tip, $last_anchor)
974     # (or nothing, if $nogenerate)
975
976     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
977     $report_lprefix //= '';
978
979     # go through commits backwards
980     # we generate two lists of commits to apply:
981     # breakwater branch and upstream patches
982     my (@brw_cl, @upp_cl, @processed);
983     my %found;
984     my $upp_limit;
985     my @pseudomerges;
986
987     my $cl;
988     my $xmsg = sub {
989         my ($prose, $info) = @_;
990         my $ms = $cl->{Msg};
991         chomp $ms;
992         $info //= '';
993         $ms .= "\n\n[git-debrebase$info: $prose]\n";
994         return (Msg => $ms);
995     };
996     my $rewrite_from_here = sub {
997         my ($cl) = @_;
998         my $sp_cl = { SpecialMethod => 'StartRewrite' };
999         push @$cl, $sp_cl;
1000         push @processed, $sp_cl;
1001     };
1002     my $cur = $input;
1003
1004     my $prdelim = "";
1005     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1006
1007     my $prline = sub {
1008         return unless $report;
1009         print $report $prdelim, $report_lprefix, @_;
1010         $prdelim = "\n";
1011     };
1012
1013     my $bomb = sub { # usage: return $bomb->();
1014         print $report " Unprocessable" if $report;
1015         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1016         $prprdelim->();
1017         if ($nogenerate) {
1018             return (undef,undef);
1019         }
1020         fail "found unprocessable commit, cannot cope".
1021             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1022             " (commit $cur) (d.".
1023             (join ' ', map { sprintf "%#x", $_->{Differs} }
1024              @{ $cl->{Parents} }).
1025                  ")";
1026     };
1027
1028     my $build;
1029     my $breakwater;
1030
1031     my $build_start = sub {
1032         my ($msg, $parent) = @_;
1033         $prline->(" $msg");
1034         $build = $parent;
1035         no warnings qw(exiting); last;
1036     };
1037
1038     my $nomerge = sub {
1039         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1040     };
1041
1042     my $mwrecknote = sub {
1043         my ($reftail, $commitish) = @_;
1044         $cl->{MergeWreckNotes}{$reftail} = $commitish;
1045     };
1046
1047     my $last_anchor;
1048
1049     for (;;) {
1050         $cl = classify $cur;
1051         my $ty = $cl->{Type};
1052         my $st = $cl->{SubType};
1053         $prline->("$cl->{CommitId} $cl->{Type}");
1054         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1055         push @processed, $cl;
1056         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1057         if ($ty eq 'AddPatches') {
1058             $cur = $p0;
1059             $rewrite_from_here->(\@upp_cl);
1060             next;
1061         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1062             push @brw_cl, $cl;
1063             $cur = $p0;
1064             next;
1065         } elsif ($ty eq 'BreakwaterStart') {
1066             $last_anchor = $cur;
1067             $build_start->('FirstPackaging', $cur);
1068         } elsif ($ty eq 'Upstream') {
1069             push @upp_cl, $cl;
1070             $cur = $p0;
1071             next;
1072         } elsif ($ty eq 'Mixed') {
1073             my $queue = sub {
1074                 my ($q, $wh) = @_;
1075                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1076                 push @$q, $cls;
1077             };
1078             $queue->(\@brw_cl, "debian");
1079             $queue->(\@upp_cl, "upstream");
1080             $rewrite_from_here->(\@brw_cl);
1081             $cur = $p0;
1082             next;
1083         } elsif ($ty eq 'Pseudomerge') {
1084             my $contrib = $cl->{Contributor}{CommitId};
1085             print $report " Contributor=$contrib" if $report;
1086             push @pseudomerges, $cl;
1087             $rewrite_from_here->(\@upp_cl);
1088             $cur = $contrib;
1089             next;
1090         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1091             $last_anchor = $cur;
1092             $build_start->("Anchor", $cur);
1093         } elsif ($ty eq 'DgitImportUnpatched') {
1094             my $pm = $pseudomerges[-1];
1095             if (defined $pm) {
1096                 # To an extent, this is heuristic.  Imports don't have
1097                 # a useful history of the debian/ branch.  We assume
1098                 # that the first pseudomerge after an import has a
1099                 # useful history of debian/, and ignore the histories
1100                 # from later pseudomerges.  Often the first pseudomerge
1101                 # will be the dgit import of the upload to the actual
1102                 # suite intended by the non-dgit NMUer, and later
1103                 # pseudomerges may represent in-archive copies.
1104                 my $ovwrs = $pm->{Overwritten};
1105                 printf $report " PM=%s \@Overwr:%d",
1106                     $pm->{CommitId}, (scalar @$ovwrs)
1107                     if $report;
1108                 if (@$ovwrs != 1) {
1109                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1110                     return $bomb->();
1111                 }
1112                 my $ovwr = $ovwrs->[0]{CommitId};
1113                 printf $report " Overwr=%s", $ovwr if $report;
1114                 # This import has a tree which is just like a
1115                 # breakwater tree, but it has the wrong history.  It
1116                 # ought to have the previous breakwater (which the
1117                 # pseudomerge overwrote) as an ancestor.  That will
1118                 # make the history of the debian/ files correct.  As
1119                 # for the upstream version: either it's the same as
1120                 # was ovewritten (ie, same as the previous
1121                 # breakwater), in which case that history is precisely
1122                 # right; or, otherwise, it was a non-gitish upload of a
1123                 # new upstream version.  We can tell these apart by
1124                 # looking at the tree of the supposed upstream.
1125                 push @brw_cl, {
1126                     %$cl,
1127                     SpecialMethod => 'DgitImportDebianUpdate',
1128                     $xmsg->("convert dgit import: debian changes")
1129                 }, {
1130                     %$cl,
1131                     SpecialMethod => 'DgitImportUpstreamUpdate',
1132                     $xmsg->("convert dgit import: upstream update",
1133                             " anchor")
1134                 };
1135                 $prline->(" Import");
1136                 $rewrite_from_here->(\@brw_cl);
1137                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1138                 $cur = $ovwr;
1139                 next;
1140             } else {
1141                 # Everything is from this import.  This kind of import
1142                 # is already nearly in valid breakwater format, with the
1143                 # patches as commits.  Unfortunately it contains
1144                 # debian/patches/.
1145                 printdebug "*** WALK BOMB bare dgit import\n";
1146                 $cl->{Why} = "bare dgit dsc import";
1147                 return $bomb->();
1148             }
1149             die "$ty ?";
1150         } elsif ($ty eq 'MergedBreakwaters') {
1151             $last_anchor = mergedbreakwaters_anchor $cl;
1152             $build_start->(' MergedBreakwaters', $cur);
1153             last;
1154         } elsif ($ty eq 'VanillaMerge') {
1155             # User may have merged unstitched branch(es).  We will
1156             # have now lost what ffq-prev was then (since the later
1157             # pseudomerge may introduce further changes).  The effect
1158             # of resolving such a merge is that we may have to go back
1159             # further in history to find a merge base, since the one
1160             # which was reachable via ffq-prev is no longer findable.
1161             # This is suboptimal, but if it all works we'll have done
1162             # the right thing.
1163             # xxx we should warn the user in the docs about this
1164
1165             my $ok=1;
1166             my $best_anchor;
1167             # We expect to find a dominating anchor amongst the
1168             # inputs' anchors.  That will be the new anchor.
1169             #
1170             # More complicated is finding a merge base for the
1171             # breakwaters.  We need a merge base that is a breakwater
1172             # commit.  The ancestors of breakwater commits are more
1173             # breakwater commits and possibly upstream commits and the
1174             # ancestors of those upstream.  Upstreams might have
1175             # arbitrary ancestors.  But any upstream commit U is
1176             # either included in both anchors, in which case the
1177             # earlier anchor is a better merge base than any of U's
1178             # ancestors; or U is not included in the older anchor, in
1179             # which case U is not an ancestor of the vanilla merge at
1180             # all.  So no upstream commit, nor any ancestor thereof,
1181             # is a best merge base.  As for non-breakwater Debian
1182             # commits: these are never ancestors of any breakwater.
1183             #
1184             # So any best merge base as found by git-merge-base
1185             # is a suitable breakwater anchor.  Usually there will
1186             # be only one.
1187
1188             printdebug "*** MERGE\n";
1189
1190             my @bwbcmd = (@git, qw(merge-base));
1191             my @ibcmd = (@git, qw(merge-base --all));
1192             my $might_be_in_bw = 1;
1193
1194             my $ps = $cl->{Parents};
1195
1196             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1197
1198             foreach my $p (@$ps) {
1199                 $prline->(" VanillaMerge ".$p->{Ix});
1200                 $prprdelim->();
1201                 my ($ptip, $pbw, $panchor) =
1202                     walk $p->{CommitId}, 0, $report,
1203                          $report_lprefix.'  ';
1204                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1205                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1206                 $p->{Anchor} = $panchor;
1207
1208                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1209                 $mwrecknote->("$lr-input", $p->{CommitId});
1210
1211                 my $mwrecknote_parent = sub {
1212                     my ($which) = @_;
1213                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1214                 };
1215                 $mwrecknote_parent->('Laundered');
1216                 $mwrecknote_parent->('Breakwater');
1217                 $mwrecknote_parent->('Anchor');
1218
1219                 $best_anchor = $panchor if
1220                     !defined $best_anchor or
1221                     is_fast_fwd $best_anchor, $panchor;
1222
1223                 printdebug " MERGE BA best=".($best_anchor//'-').
1224                     " p=$panchor\n";
1225             }
1226
1227             $mwrecknote->('result-anchor', $best_anchor);
1228
1229             foreach my $p (@$ps) {
1230                 $prline->(" VanillaMerge ".$p->{Ix});
1231                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1232                     $nomerge->('divergent anchors');
1233                 } elsif ($p->{Anchor} eq $best_anchor) {
1234                     print $report " SameAnchor" if $report;
1235                 } else {
1236                     print $report " SupersededAnchor" if $report;
1237                 }
1238                 if ($p->{Breakwater} eq $p->{CommitId}) {
1239                     # this parent commit was its own breakwater,
1240                     # ie it is part of the breakwater
1241                     print $report " Breakwater" if $report;
1242                 } else {
1243                     $might_be_in_bw = 0;
1244                 }
1245                 push @bwbcmd, $p->{Breakwater};
1246                 push @ibcmd, $p->{CommitId};
1247             }
1248
1249             if ($ok && $might_be_in_bw) {
1250                 # We could rewrite this to contaion the metadata
1251                 # declaring it to be MergedBreakwaters, but
1252                 # unnecessarily rewriting a merge seems unhelpful.
1253                 $prline->(" VanillaMerge MergedBreakwaters");
1254                 $last_anchor = $best_anchor;
1255                 $build_start->('MergedBreakwaters', $cur);
1256             }
1257
1258             my $bwb = cmdoutput @bwbcmd;
1259
1260             # OK, now we have a breakwater base, but we need the merge
1261             # base for the interchange branch because we need the delta
1262             # queue.
1263             #
1264             # This a the best merge base of our inputs which has the
1265             # breakwater merge base as an ancestor.
1266
1267             my @ibs =
1268                 grep /./,
1269                 split /\n/,
1270                 cmdoutput @ibcmd;
1271
1272             @ibs or confess 'internal error, expected anchor at least ?';
1273
1274             my $ib;
1275             my $ibleaf;
1276             foreach my $tibix (0..$#ibs) {
1277                 my $tib = $ibs[$tibix];
1278                 my $ff = is_fast_fwd $bwb, $tib;
1279                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1280                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1281                 $mwrecknote->($tibleaf, $tib);
1282                 next unless $ff;
1283                 next if $ib;
1284                 $ib = $tib;
1285                 $ibleaf = $tibleaf;
1286             }
1287
1288             $ib or $nomerge->("no suitable interchange merge base");
1289
1290             $prline->("  VanillaMerge Base");
1291             $prprdelim->();
1292             my ($btip, $bbw, $banchor) = eval {
1293                 walk $ib, 0, $report, $report_lprefix.'  ';
1294             };
1295             $nomerge->("walking interchange branch merge base ($ibleaf): ".
1296                        $@) if length $@;
1297
1298             $mwrecknote->("mergebase-laundered", $btip);
1299             $mwrecknote->("mergebase-breakwater", $bbw);
1300             $mwrecknote->("mergebase-anchor", $banchor);
1301
1302             my $ibinfo = { SeriesTip => $btip,
1303                            SeriesBase => $bbw,
1304                            Anchor => $banchor,
1305                            LeftRight => 'mergebase' };
1306
1307             $bbw eq $bwb
1308                 or $nomerge->("interchange merge-base ($ib)'s".
1309                               " breakwater ($bbw)".
1310                               " != breakwaters' merge-base ($bwb)");
1311
1312             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1313                  or $nomerge->("interchange merge-base ($ib)'s".
1314                                " anchor ($ibinfo->{SeriesBase})".
1315                                " != any merge input's anchor (".
1316                                (join ' ', map { $_->{Anchor} } @$ps).
1317                                ")");
1318
1319             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1320             $cl->{MergeBestAnchor} = $best_anchor;
1321             push @brw_cl, {
1322                 %$cl,
1323                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1324                 $xmsg->('constructed from vanilla merge',
1325                         ' merged-breakwater'),
1326             };
1327             push @upp_cl, {
1328                 %$cl,
1329                 SpecialMethod => 'MergeMergeSeries',
1330             };
1331             $build_start->('MergeBreakwaters', $cur);
1332         } else {
1333             printdebug "*** WALK BOMB unrecognised\n";
1334             return $bomb->();
1335         }
1336     }
1337     $prprdelim->();
1338
1339     printdebug "*** WALK prep done cur=$cur".
1340         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1341
1342     return if $nogenerate;
1343
1344     # Now we build it back up again
1345
1346     fresh_workarea();
1347
1348     my $rewriting = 0;
1349
1350     my $read_tree_upstream = sub {
1351         my ($treeish) = @_;
1352         read_tree_upstream $treeish, 0, $build;
1353     };
1354
1355     $#upp_cl = $upp_limit if defined $upp_limit;
1356  
1357     my $committer_authline = calculate_committer_authline();
1358
1359     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1360
1361     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1362
1363     in_workarea sub {
1364         mkdir $rd or $!==EEXIST or die $!;
1365         my $current_method;
1366         runcmd @git, qw(read-tree), $build;
1367         foreach my $cl (qw(Debian), (reverse @brw_cl),
1368                         { SpecialMethod => 'RecordBreakwaterTip' },
1369                         qw(Upstream), (reverse @upp_cl)) {
1370             if (!ref $cl) {
1371                 $current_method = $cl;
1372                 next;
1373             }
1374             my $method = $cl->{SpecialMethod} // $current_method;
1375             my @parents = ($build);
1376             my $cltree = $cl->{CommitId};
1377             printdebug "WALK BUILD ".($cltree//'undef').
1378                 " $method (rewriting=$rewriting)\n";
1379             if ($method eq 'Debian') {
1380                 read_tree_debian($cltree);
1381             } elsif ($method eq 'Upstream') {
1382                 $read_tree_upstream->($cltree);
1383             } elsif ($method eq 'StartRewrite') {
1384                 $rewriting = 1;
1385                 next;
1386             } elsif ($method eq 'RecordBreakwaterTip') {
1387                 $breakwater = $build;
1388                 next;
1389             } elsif ($method eq 'DgitImportDebianUpdate') {
1390                 read_tree_debian($cltree);
1391             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1392                 confess unless $rewriting;
1393                 my $differs = (get_differs $build, $cltree);
1394                 next unless $differs & D_UPS;
1395                 $read_tree_upstream->($cltree);
1396                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1397             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1398                 print "Found a general merge, will try to tidy it up.\n";
1399                 $rewriting = 1;
1400                 $read_tree_upstream->($cl->{MergeBestAnchor});
1401                 $read_tree_upstream->($cl->{MergeBestAnchor});
1402                 read_tree_debian($cltree);
1403                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1404             } elsif ($method eq 'MergeMergeSeries') {
1405                 print "Running merge resolution for $cl->{CommitId}...\n";
1406                 $build = merge_series
1407                     $build, $cl->{MergeWreckNotes},
1408                     $cl->{MergeInterchangeBaseInfo},
1409                     @{ $cl->{Parents} };
1410                 $last_anchor = $cl->{MergeBestAnchor};
1411
1412                 # Check for mismerges:
1413                 my $check = sub {
1414                     my ($against, $allow, $what) = @_;
1415                     my $differs = get_differs $build, $against;
1416                     $nomerge->(sprintf
1417        "merge misresolved: %s are not the same (%s %s d.%#x)",
1418                                $what, $against, $build, $differs)
1419                         if $differs & ~($allow | D_PAT_ADD);
1420                 };
1421
1422                 # Breakwater changes which were in each side of the
1423                 # merge will have been incorporated into the
1424                 # MergeCreateMergedBreakwaters output.  Because the
1425                 # upstream series was rebased onto the new breakwater,
1426                 # so should all of the packaging changes which were in
1427                 # the input.
1428                 $check->($input, D_UPS, 'debian files');
1429
1430                 # Upstream files are merge_series, which ought to
1431                 # have been identical to the original merge.
1432                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1433
1434                 print "Merge resolution successful.\n";
1435                 next;
1436             } else {
1437                 confess "$method ?";
1438             }
1439             if (!$rewriting) {
1440                 my $procd = (pop @processed) // 'UNDEF';
1441                 if ($cl ne $procd) {
1442                     $rewriting = 1;
1443                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1444                 }
1445             }
1446             my $newtree = cmdoutput @git, qw(write-tree);
1447             my $ch = $cl->{Hdr};
1448             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1449             $ch =~ s{^parent .*\n}{}mg;
1450             $ch =~ s{(?=^author)}{
1451                 join '', map { "parent $_\n" } @parents
1452             }me or confess "$ch ?";
1453             if ($rewriting) {
1454                 $ch =~ s{^committer .*$}{$committer_authline}m
1455                     or confess "$ch ?";
1456             }
1457             my $cf = "$rd/m$rewriting";
1458             open CD, ">", $cf or die $!;
1459             print CD $ch, "\n", $cl->{Msg} or die $!;
1460             close CD or die $!;
1461             my @cmd = (@git, qw(hash-object));
1462             push @cmd, qw(-w) if $rewriting;
1463             push @cmd, qw(-t commit), $cf;
1464             my $newcommit = cmdoutput @cmd;
1465             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1466             $build = $newcommit;
1467             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1468                 $last_anchor = $cur;
1469             }
1470         }
1471     };
1472
1473     my $final_check = get_differs $build, $input;
1474     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1475         if $final_check & ~D_PAT_ADD;
1476
1477     my @r = ($build, $breakwater, $last_anchor);
1478     printdebug "*** WALK RETURN @r\n";
1479     return @r
1480 }
1481
1482 sub get_head () {
1483     git_check_unmodified();
1484     return git_rev_parse qw(HEAD);
1485 }
1486
1487 sub update_head ($$$) {
1488     my ($old, $new, $mrest) = @_;
1489     push @deferred_updates, "update HEAD $new $old";
1490     run_deferred_updates $mrest;
1491 }
1492
1493 sub update_head_checkout ($$$) {
1494     my ($old, $new, $mrest) = @_;
1495     update_head $old, $new, $mrest;
1496     runcmd @git, qw(reset --hard);
1497 }
1498
1499 sub update_head_postlaunder ($$$) {
1500     my ($old, $tip, $reflogmsg) = @_;
1501     return if $tip eq $old;
1502     print "git-debrebase: laundered (head was $old)\n";
1503     update_head $old, $tip, $reflogmsg;
1504     # no tree changes except debian/patches
1505     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1506 }
1507
1508 sub currently_rebasing() {
1509     foreach (qw(rebase-merge rebase-apply)) {
1510         return 1 if stat_exists "$maindir_gitdir/$_";
1511     }
1512     return 0;
1513 }
1514
1515 sub bail_if_rebasing() {
1516     fail "you are in the middle of a git-rebase already"
1517         if currently_rebasing();
1518 }
1519
1520 sub do_launder_head ($) {
1521     my ($reflogmsg) = @_;
1522     my $old = get_head();
1523     record_ffq_auto();
1524     my ($tip,$breakwater) = walk $old;
1525     snags_maybe_bail();
1526     update_head_postlaunder $old, $tip, $reflogmsg;
1527     return ($tip,$breakwater);
1528 }
1529
1530 sub cmd_launder_v0 () {
1531     badusage "no arguments to launder-v0 allowed" if @ARGV;
1532     my $old = get_head();
1533     my ($tip,$breakwater,$last_anchor) = walk $old;
1534     update_head_postlaunder $old, $tip, 'launder';
1535     printf "# breakwater tip\n%s\n", $breakwater;
1536     printf "# working tip\n%s\n", $tip;
1537     printf "# last anchor\n%s\n", $last_anchor;
1538 }
1539
1540 sub defaultcmd_rebase () {
1541     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1542     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1543     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1544 }
1545
1546 sub cmd_analyse () {
1547     badusage "analyse does not support any options"
1548         if @ARGV and $ARGV[0] =~ m/^-/;
1549     badusage "too many arguments to analyse" if @ARGV>1;
1550     my ($old) = @ARGV;
1551     if (defined $old) {
1552         $old = git_rev_parse $old;
1553     } else {
1554         $old = git_rev_parse 'HEAD';
1555     }
1556     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1557     STDOUT->error and die $!;
1558 }
1559
1560 sub ffq_prev_branchinfo () {
1561     my $current = git_get_symref();
1562     return gdr_ffq_prev_branchinfo($current);
1563 }
1564
1565 sub ffq_check ($;$$) {
1566     # calls $ff and/or $notff zero or more times
1567     # then returns either (status,message) where status is
1568     #    exists
1569     #    detached
1570     #    weird-symref
1571     #    notbranch
1572     # or (undef,undef, $ffq_prev,$gdrlast)
1573     # $ff and $notff are called like this:
1574     #   $ff->("message for stdout\n");
1575     #   $notff->('snag-name', $message);
1576     # normally $currentval should be HEAD
1577     my ($currentval, $ff, $notff) =@_;
1578
1579     $ff //= sub { print $_[0] or die $!; };
1580     $notff //= \&snag;
1581
1582     my ($status, $message, $current, $ffq_prev, $gdrlast)
1583         = ffq_prev_branchinfo();
1584     return ($status, $message) unless $status eq 'branch';
1585
1586     my $exists = git_get_ref $ffq_prev;
1587     return ('exists',"$ffq_prev already exists") if $exists;
1588
1589     return ('not-branch', 'HEAD symref is not to refs/heads/')
1590         unless $current =~ m{^refs/heads/};
1591     my $branch = $';
1592
1593     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1594     my %checked;
1595
1596     printdebug "ffq check_specs @check_specs\n";
1597
1598     my $check = sub {
1599         my ($lrref, $desc) = @_;
1600         printdebug "ffq might check $lrref ($desc)\n";
1601         my $invert;
1602         for my $chk (@check_specs) {
1603             my $glob = $chk;
1604             $invert = $glob =~ s{^[!^]}{};
1605             last if fnmatch $glob, $lrref;
1606         }
1607         return if $invert;
1608         my $lrval = git_get_ref $lrref;
1609         return unless length $lrval;
1610
1611         if (is_fast_fwd $lrval, $currentval) {
1612             $ff->("OK, you are ahead of $lrref\n");
1613             $checked{$lrref} = 1;
1614         } elsif (is_fast_fwd $currentval, $lrval) {
1615             $checked{$lrref} = -1;
1616             $notff->('behind', "you are behind $lrref, divergence risk");
1617         } else {
1618             $checked{$lrref} = -1;
1619             $notff->('diverged', "you have diverged from $lrref");
1620         }
1621     };
1622
1623     my $merge = cfg "branch.$branch.merge",1;
1624     if (defined $merge and $merge =~ m{^refs/heads/}) {
1625         my $rhs = $';
1626         printdebug "ffq merge $rhs\n";
1627         my $check_remote = sub {
1628             my ($remote, $desc) = @_;
1629             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1630             return unless defined $remote;
1631             $check->("refs/remotes/$remote/$rhs", $desc);
1632         };
1633         $check_remote->((scalar cfg "branch.$branch.remote",1),
1634                         'remote fetch/merge branch');
1635         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1636                         (scalar cfg "branch.$branch.pushDefault",1),
1637                         'remote push branch');
1638     }
1639     if ($branch =~ m{^dgit/}) {
1640         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1641     } elsif ($branch =~ m{^master$}) {
1642         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1643     }
1644     return (undef, undef, $ffq_prev, $gdrlast);
1645 }
1646
1647 sub record_ffq_prev_deferred () {
1648     # => ('status', "message")
1649     # 'status' may be
1650     #    deferred          message is undef
1651     #    exists
1652     #    detached
1653     #    weird-symref
1654     #    notbranch
1655     # if not ff from some branch we should be ff from, is an snag
1656     # if "deferred", will have added something about that to
1657     #   @deferred_update_messages, and also maybe printed (already)
1658     #   some messages about ff checks
1659     bail_if_rebasing();
1660     my $currentval = get_head();
1661
1662     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1663     return ($status,$message) if defined $status;
1664
1665     snags_maybe_bail();
1666
1667     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1668     push @deferred_updates, "delete $gdrlast";
1669     push @deferred_update_messages, "Recorded previous head for preservation";
1670     return ('deferred', undef);
1671 }
1672
1673 sub record_ffq_auto () {
1674     my ($status, $message) = record_ffq_prev_deferred();
1675     if ($status eq 'deferred' || $status eq 'exists') {
1676     } else {
1677         snag $status, "could not record ffq-prev: $message";
1678         snags_maybe_bail();
1679     }
1680 }
1681
1682 sub ffq_prev_info () {
1683     bail_if_rebasing();
1684     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1685     my ($status, $message, $current, $ffq_prev, $gdrlast)
1686         = ffq_prev_branchinfo();
1687     if ($status ne 'branch') {
1688         snag $status, "could not check ffq-prev: $message";
1689         snags_maybe_bail();
1690     }
1691     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1692     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1693 }
1694
1695 sub stitch ($$$$$) {
1696     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1697
1698     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1699
1700     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1701         my $differs = get_differs $old_head, $ffq_prev_commitish;
1702         unless ($differs & ~D_PAT_ADD) {
1703             # ffq-prev is ahead of us, and the only tree changes it has
1704             # are possibly addition of things in debian/patches/.
1705             # Just wind forwards rather than making a pointless pseudomerge.
1706             push @deferred_updates,
1707                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1708             update_head_checkout $old_head, $ffq_prev_commitish,
1709                 "stitch (fast forward)";
1710             return;
1711         }
1712     }
1713     fresh_workarea();
1714     # We make pseudomerges with L as the contributing parent.
1715     # This makes git rev-list --first-parent work properly.
1716     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1717         'Declare fast forward / record previous work',
1718         "[git-debrebase pseudomerge: $prose]",
1719     ];
1720     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1721     update_head $old_head, $new_head, "stitch: $prose";
1722 }
1723
1724 sub do_stitch ($;$) {
1725     my ($prose, $unclean) = @_;
1726
1727     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1728     if (!$ffq_prev_commitish) {
1729         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1730         return;
1731     }
1732     my $dangling_head = get_head();
1733
1734     keycommits $dangling_head, $unclean,$unclean,$unclean;
1735     snags_maybe_bail();
1736
1737     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1738 }
1739
1740 sub upstream_commitish_search ($$) {
1741     my ($upstream_version, $tried) = @_;
1742     # todo: at some point maybe use git-deborig to do this
1743     foreach my $tagpfx ('', 'v', 'upstream/') {
1744         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1745         my $new_upstream = git_get_ref "refs/tags/$tag";
1746         push @$tried, $tag;
1747         return $new_upstream if length $new_upstream;
1748     }
1749 }
1750
1751 sub resolve_upstream_version ($$) {
1752     my ($new_upstream, $upstream_version) = @_;
1753
1754     if (!defined $new_upstream) {
1755         my @tried;
1756         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1757         if (!length $new_upstream) {
1758             fail "Could not determine appropriate upstream commitish.\n".
1759                 " (Tried these tags: @tried)\n".
1760                 " Check version, and specify upstream commitish explicitly.";
1761         }
1762     }
1763     $new_upstream = git_rev_parse $new_upstream;
1764
1765     return $new_upstream;
1766 }
1767
1768 sub cmd_new_upstream () {
1769     # automatically and unconditionally launders before rebasing
1770     # if rebase --abort is used, laundering has still been done
1771
1772     my %pieces;
1773
1774     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1775
1776     # parse args - low commitment
1777     my $spec_version = shift @ARGV;
1778     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1779     fail "bad version number \`$spec_version'" unless defined $new_version;
1780     if ($new_version->is_native()) {
1781         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1782     }
1783
1784     my $new_upstream = shift @ARGV;
1785     my $new_upstream_version = upstreamversion  $new_version;
1786     $new_upstream =
1787         resolve_upstream_version $new_upstream, $new_upstream_version;
1788
1789     record_ffq_auto();
1790
1791     my $piece = sub {
1792         my ($n, @x) = @_; # may be ''
1793         my $pc = $pieces{$n} //= {
1794             Name => $n,
1795             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1796         };
1797         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1798         $pc;
1799     };
1800
1801     my @newpieces;
1802     my $newpiece = sub {
1803         my ($n, @x) = @_; # may be ''
1804         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1805         push @newpieces, $pc;
1806     };
1807
1808     $newpiece->('',
1809         OldIx => 0,
1810         New => $new_upstream,
1811     );
1812     while (@ARGV && $ARGV[0] !~ m{^-}) {
1813         my $n = shift @ARGV;
1814
1815         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1816             unless @ARGV && $ARGV[0] !~ m{^-};
1817
1818         my $c = git_rev_parse shift @ARGV;
1819         die unless $n =~ m/^$extra_orig_namepart_re$/;
1820         $newpiece->($n, New => $c);
1821     }
1822
1823     # now we need to investigate the branch this generates the
1824     # laundered version but we don't switch to it yet
1825     my $old_head = get_head();
1826     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1827
1828     my $old_bw_cl = classify $old_bw;
1829     my $old_anchor_cl = classify $old_anchor;
1830     my $old_upstream;
1831     if (!$old_anchor_cl->{OrigParents}) {
1832         snag 'anchor-treated',
1833             'old anchor is recognised due to --anchor, cannot check upstream';
1834     } else {
1835         $old_upstream = parsecommit
1836             $old_anchor_cl->{OrigParents}[0]{CommitId};
1837         $piece->('', Old => $old_upstream->{CommitId});
1838     }
1839
1840     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1841         if ($old_upstream->{Msg} =~
1842  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1843            ) {
1844             my @oldpieces = (split / /, $1);
1845             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1846             if ($old_n_parents != @oldpieces &&
1847                 $old_n_parents != @oldpieces + 1) {
1848                 snag 'upstream-confusing', sprintf
1849                     "previous upstream combine %s".
1850                     " mentions %d pieces (each implying one parent)".
1851                     " but has %d parents".
1852                     " (one per piece plus maybe a previous combine)",
1853                     $old_upstream->{CommitId},
1854                     (scalar @oldpieces),
1855                     $old_n_parents;
1856             } elsif ($oldpieces[0] ne '.') {
1857                 snag 'upstream-confusing', sprintf
1858                     "previous upstream combine %s".
1859                     " first piece is not \`.'",
1860                     $oldpieces[0];
1861             } else {
1862                 $oldpieces[0] = '';
1863                 foreach my $i (0..$#oldpieces) {
1864                     my $n = $oldpieces[$i];
1865                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1866                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1867                 }
1868             }
1869         } else {
1870             snag 'upstream-confusing',
1871                 "previous upstream $old_upstream->{CommitId} is from".
1872                " git-debrebase but not an \`upstream-combine' commit";
1873         }
1874     }
1875
1876     foreach my $pc (values %pieces) {
1877         if (!$old_upstream) {
1878             # we have complained already
1879         } elsif (!$pc->{Old}) {
1880             snag 'upstream-new-piece',
1881                 "introducing upstream piece \`$pc->{Name}'";
1882         } elsif (!$pc->{New}) {
1883             snag 'upstream-rm-piece',
1884                 "dropping upstream piece \`$pc->{Name}'";
1885         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1886             snag 'upstream-not-ff',
1887                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1888         }
1889     }
1890
1891     printdebug "%pieces = ", (dd \%pieces), "\n";
1892     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1893
1894     snags_maybe_bail();
1895
1896     my $new_bw;
1897
1898     fresh_workarea();
1899     in_workarea sub {
1900         my @upstream_merge_parents;
1901
1902         if (!any_snags()) {
1903             push @upstream_merge_parents, $old_upstream->{CommitId};
1904         }
1905
1906         foreach my $pc (@newpieces) { # always has '' first
1907             if ($pc->{Name}) {
1908                 read_tree_subdir $pc->{Name}, $pc->{New};
1909             } else {
1910                 runcmd @git, qw(read-tree), $pc->{New};
1911             }
1912             push @upstream_merge_parents, $pc->{New};
1913         }
1914
1915         # index now contains the new upstream
1916
1917         if (@newpieces > 1) {
1918             # need to make the upstream subtree merge commit
1919             $new_upstream = make_commit \@upstream_merge_parents,
1920                 [ "Combine upstreams for $new_upstream_version",
1921  ("[git-debrebase upstream-combine . ".
1922  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1923  ": new upstream]"),
1924                 ];
1925         }
1926
1927         # $new_upstream is either the single upstream commit, or the
1928         # combined commit we just made.  Either way it will be the
1929         # "upstream" parent of the anchor merge.
1930
1931         read_tree_subdir 'debian', "$old_bw:debian";
1932
1933         # index now contains the anchor merge contents
1934         $new_bw = make_commit [ $old_bw, $new_upstream ],
1935             [ "Update to upstream $new_upstream_version",
1936  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1937             ];
1938
1939         my $clogsignoff = cmdoutput qw(git show),
1940             '--pretty=format:%an <%ae>  %aD',
1941             $new_bw;
1942
1943         # Now we have to add a changelog stanza so the Debian version
1944         # is right.
1945         die if unlink "debian";
1946         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1947         unlink "debian/changelog" or $!==ENOENT or die $!;
1948         mkdir "debian" or die $!;
1949         open CN, ">", "debian/changelog" or die $!;
1950         my $oldclog = git_cat_file ":debian/changelog";
1951         $oldclog =~ m/^($package_re) \(\S+\) / or
1952             fail "cannot parse old changelog to get package name";
1953         my $p = $1;
1954         print CN <<END, $oldclog or die $!;
1955 $p ($new_version) UNRELEASED; urgency=medium
1956
1957   * Update to new upstream version $new_upstream_version.
1958
1959  -- $clogsignoff
1960
1961 END
1962         close CN or die $!;
1963         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1964
1965         # Now we have the final new breakwater branch in the index
1966         $new_bw = make_commit [ $new_bw ],
1967             [ "Update changelog for new upstream $new_upstream_version",
1968               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1969             ];
1970     };
1971
1972     # we have constructed the new breakwater. we now need to commit to
1973     # the laundering output, because git-rebase can't easily be made
1974     # to make a replay list which is based on some other branch
1975
1976     update_head_postlaunder $old_head, $old_laundered_tip,
1977         'launder for new upstream';
1978
1979     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1980     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1981         "debrebase new-upstream $new_version: rebase";
1982     runcmd @cmd;
1983     # now it's for the user to sort out
1984 }
1985
1986 sub cmd_record_ffq_prev () {
1987     badusage "no arguments allowed" if @ARGV;
1988     my ($status, $msg) = record_ffq_prev_deferred();
1989     if ($status eq 'exists' && $opt_noop_ok) {
1990         print "Previous head already recorded\n" or die $!;
1991     } elsif ($status eq 'deferred') {
1992         run_deferred_updates 'record-ffq-prev';
1993     } else {
1994         fail "Could not preserve: $msg";
1995     }
1996 }
1997
1998 sub cmd_anchor () {
1999     badusage "no arguments allowed" if @ARGV;
2000     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2001     print "$bw\n" or die $!;
2002 }
2003
2004 sub cmd_breakwater () {
2005     badusage "no arguments allowed" if @ARGV;
2006     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2007     print "$bw\n" or die $!;
2008 }
2009
2010 sub cmd_status () {
2011     badusage "no arguments allowed" if @ARGV;
2012
2013     # todo: gdr status should print divergence info
2014     # todo: gdr status should print upstream component(s) info
2015     # todo: gdr should leave/maintain some refs with this kind of info ?
2016
2017     my $oldest = { Badness => 0 };
2018     my $newest;
2019     my $note = sub {
2020         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2021         if ($oldest->{Badness} < $badness) {
2022             $oldest = $newest = undef;
2023         }
2024         $oldest = {
2025                    Badness => $badness,
2026                    CommitId => $cl->{CommitId},
2027                    OurMsg => $ourmsg,
2028                    KcMsg => $kcmsg,
2029                   };
2030         $newest //= $oldest;
2031     };
2032     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2033         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2034         sub { $note->(2, 'branch is unlaundered', @_); },
2035         sub { $note->(3, 'branch needs laundering', @_); },
2036         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2037
2038     my $prcommitinfo = sub {
2039         my ($cid) = @_;
2040         flush STDOUT or die $!;
2041         runcmd @git, qw(--no-pager log -n1),
2042             '--pretty=format:    %h %s%n',
2043             $cid;
2044     };
2045
2046     print "current branch contents, in git-debrebase terms:\n";
2047     if (!$oldest->{Badness}) {
2048         print "  branch is laundered\n";
2049     } else {
2050         print "  $oldest->{OurMsg}\n";
2051         my $printed = '';
2052         foreach my $info ($oldest, $newest) {
2053             my $cid = $info->{CommitId};
2054             next if $cid eq $printed;
2055             $printed = $cid;
2056             print "  $info->{KcMsg}\n";
2057             $prcommitinfo->($cid);
2058         }
2059     }
2060
2061     my $prab = sub {
2062         my ($cid, $what) = @_;
2063         if (!defined $cid) {
2064             print "  $what is not well-defined\n";
2065         } else {
2066             print "  $what\n";
2067             $prcommitinfo->($cid);
2068         }
2069     };
2070     print "key git-debrebase commits:\n";
2071     $prab->($anchor, 'anchor');
2072     $prab->($bw, 'breakwater');
2073
2074     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2075         ffq_prev_branchinfo();
2076
2077     print "branch and ref status, in git-debrebase terms:\n";
2078     if ($ffq_msg) {
2079         print "  $ffq_msg\n";
2080     } else {
2081         $ffq_prev = git_get_ref $ffq_prev;
2082         $gdrlast = git_get_ref $gdrlast;
2083         if ($ffq_prev) {
2084             print "  unstitched; previous tip was:\n";
2085             $prcommitinfo->($ffq_prev);
2086         } elsif (!$gdrlast) {
2087             print "  stitched? (no record of git-debrebase work)\n";
2088         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2089             print "  stitched\n";
2090         } else {
2091             print "  not git-debrebase (diverged since last stitch)\n"
2092         }
2093     }
2094     print "you are currently rebasing\n" if currently_rebasing();
2095 }
2096
2097 sub cmd_stitch () {
2098     my $prose = 'stitch';
2099     getoptions("stitch",
2100                'prose=s', \$prose);
2101     badusage "no arguments allowed" if @ARGV;
2102     do_stitch $prose, 0;
2103 }
2104 sub cmd_prepush () { cmd_stitch(); }
2105
2106 sub cmd_quick () {
2107     badusage "no arguments allowed" if @ARGV;
2108     do_launder_head 'launder for git-debrebase quick';
2109     do_stitch 'quick';
2110 }
2111
2112 sub cmd_conclude () {
2113     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2114     if (!$ffq_prev_commitish) {
2115         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2116         return;
2117     }
2118     my $dangling_head = get_head();
2119     
2120     badusage "no arguments allowed" if @ARGV;
2121     do_launder_head 'launder for git-debrebase quick';
2122     do_stitch 'quick';
2123 }
2124
2125 sub cmd_scrap () {
2126     if (currently_rebasing()) {
2127         runcmd @git, qw(rebase --abort);
2128     }
2129     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2130     if (!$ffq_prev_commitish) {
2131         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2132         finish 0;
2133     }
2134     my $scrapping_head = get_head();
2135     badusage "no arguments allowed" if @ARGV;
2136     push @deferred_updates,
2137         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2138         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2139     snags_maybe_bail();
2140     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2141 }
2142
2143 sub make_patches_staged ($) {
2144     my ($head) = @_;
2145     # Produces the patches that would result from $head if it were
2146     # laundered.
2147     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2148     fresh_workarea();
2149     in_workarea sub {
2150         gbp_pq_export 'bw', $secret_bw, $secret_head;
2151     };
2152 }
2153
2154 sub make_patches ($) {
2155     my ($head) = @_;
2156     keycommits $head, 0, \&snag;
2157     make_patches_staged $head;
2158     my $out;
2159     in_workarea sub {
2160         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2161         runcmd @git, qw(read-tree), $head;
2162         read_tree_subdir 'debian/patches', $ptree;
2163         $out = make_commit [$head], [
2164             'Commit patch queue (exported by git-debrebase)',
2165             '[git-debrebase: export and commit patches]',
2166         ];
2167     };
2168     return $out;
2169 }
2170
2171 sub cmd_make_patches () {
2172     my $opt_quiet_would_amend;
2173     getoptions("make-patches",
2174                'quiet-would-amend!', \$opt_quiet_would_amend);
2175     badusage "no arguments allowed" if @ARGV;
2176     bail_if_rebasing();
2177     my $old_head = get_head();
2178     my $new = make_patches $old_head;
2179     my $d = get_differs $old_head, $new;
2180     if ($d == 0) {
2181         fail "No (more) patches to export." unless $opt_noop_ok;
2182         return;
2183     } elsif ($d == D_PAT_ADD) {
2184         snags_maybe_bail();
2185         update_head_checkout $old_head, $new, 'make-patches';
2186     } else {
2187         print STDERR failmsg
2188             "Patch export produced patch amendments".
2189             " (abandoned output commit $new).".
2190             "  Try laundering first."
2191             unless $opt_quiet_would_amend;
2192         finish 7;
2193     }
2194 }
2195
2196 sub cmd_convert_from_gbp () {
2197     badusage "want only 1 optional argument, the upstream git commitish"
2198         unless @ARGV<=1;
2199
2200     my $clogp = parsechangelog();
2201     my $version = $clogp->{'Version'}
2202         // die "missing Version from changelog";
2203
2204     my ($upstream_spec) = @ARGV;
2205
2206     my $upstream_version = upstreamversion $version;
2207     my $upstream =
2208         resolve_upstream_version($upstream_spec, $upstream_version);
2209
2210     my $old_head = get_head();
2211
2212     my $upsdiff = get_differs $upstream, $old_head;
2213     if ($upsdiff & D_UPS) {
2214         runcmd @git, qw(--no-pager diff --stat),
2215             $upstream, $old_head,
2216             qw( -- :!/debian :/);
2217         fail <<END;
2218 upstream ($upstream_spec) and HEAD are not
2219 identical in upstream files.  See diffstat above, or run
2220   git diff $upstream_spec HEAD -- :!/debian :/
2221 END
2222     }
2223
2224     if (!is_fast_fwd $upstream, $old_head) {
2225         snag 'upstream-not-ancestor',
2226             "upstream ($upstream) is not an ancestor of HEAD";
2227     } else {
2228         my $wrong = cmdoutput
2229             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2230              qw(-- :/ :!/debian));
2231         if (length $wrong) {
2232             snag 'unexpected-upstream-changes',
2233                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2234             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2235         }
2236     }
2237
2238     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2239         snag 'upstream-has-debian',
2240             "upstream ($upstream) contains debian/ directory";
2241     }
2242
2243     my $previous_dgit_view = eval {
2244         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2245         my ($lvsn, $suite);
2246         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2247             my ($stz, $desc) = @_;
2248             no warnings qw(exiting);
2249             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2250             next unless $stz->{Date};
2251             next unless $stz->{Distribution} ne 'UNRELEASED';
2252             $lvsn = $stz->{Version};
2253             $suite = $stz->{Distribution};
2254             last;
2255         };
2256         die "neither of the first two changelog entries are released\n"
2257             unless defined $lvsn;
2258         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2259         my $mtag_pat = debiantag_maintview $lvsn, '*';
2260         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2261             $mtag_pat;
2262         die "could not find suitable maintainer view tag $mtag_pat\n"
2263             unless $mtag_pat =~ m{/};
2264         is_fast_fwd $mtag, 'HEAD' or
2265             die "HEAD is not FF from maintainer tag $mtag!";
2266         my $dtag = "archive/$mtag";
2267         is_fast_fwd $mtag, $dtag or
2268             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2269         print "will stitch in dgit view, $dtag\n";
2270         git_rev_parse $dtag;
2271     };
2272     if (!$previous_dgit_view) {
2273         $@ =~ s/^\n+//;
2274         chomp $@;
2275         print STDERR "cannot stitch in dgit view: $@\n";
2276     }
2277
2278     snags_maybe_bail_early();
2279
2280     my $work;
2281
2282     fresh_workarea();
2283     in_workarea sub {
2284         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2285         # make a branch out of the patch queue - we'll want this in a mo
2286         runcmd qw(gbp pq import);
2287         # strip the patches out
2288         runcmd @git, qw(checkout -q gdr-internal~0);
2289         rm_subdir_cached 'debian/patches';
2290         $work = make_commit ['HEAD'], [
2291  'git-debrebase convert-from-gbp: drop patches from tree',
2292  'Delete debian/patches, as part of converting to git-debrebase format.',
2293  '[git-debrebase convert-from-gbp: drop patches from tree]'
2294                               ];
2295         # make the anchor merge
2296         # the tree is already exactly right
2297         $work = make_commit [$work, $upstream], [
2298  'git-debrebase import: declare upstream',
2299  'First breakwater merge.',
2300  '[git-debrebase anchor: declare upstream]'
2301                               ];
2302
2303         # rebase the patch queue onto the new breakwater
2304         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2305         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2306         $work = git_rev_parse 'HEAD';
2307
2308         if ($previous_dgit_view) {
2309             $work = make_commit [$work, $previous_dgit_view], [
2310  'git-debrebase import: declare ff from dgit archive view',
2311  '[git-debrebase pseudomerge: import-from-gbp]',
2312             ];
2313         }
2314     };
2315
2316     ffq_check $work;
2317     snags_maybe_bail();
2318     update_head_checkout $old_head, $work, 'convert-from-gbp';
2319 }
2320
2321 sub cmd_convert_to_gbp () {
2322     badusage "no arguments allowed" if @ARGV;
2323     my $head = get_head();
2324     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2325     keycommits $head, 0;
2326     my $out;
2327     make_patches_staged $head;
2328     in_workarea sub {
2329         $out = make_commit ['HEAD'], [
2330             'Commit patch queue (converted from git-debrebase format)',
2331             '[git-debrebase convert-to-gbp: commit patches]',
2332         ];
2333     };
2334     if (defined $ffq) {
2335         push @deferred_updates, "delete $ffq";
2336         push @deferred_updates, "delete $gdrlast";
2337     }
2338     snags_maybe_bail();
2339     update_head_checkout $head, $out, "convert to gbp (v0)";
2340     print <<END or die $!;
2341 git-debrebase: converted to git-buildpackage branch format
2342 git-debrebase: WARNING: do not now run "git-debrebase" any more
2343 git-debrebase: WARNING: doing so would drop all upstream patches!
2344 END
2345 }
2346
2347 sub cmd_convert_from_dgit_view () { 
2348     my $clogp = parsechangelog();
2349
2350     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2351     my $do_origs = 1;
2352     my $do_tags = 1;
2353     my $always = 0;
2354     my $diagnose = 0;
2355
2356     getoptions("convert-from-dgit-view",
2357                'diagnose!', \$diagnose,
2358                'build-products-dir:s', \$bpd,
2359                'origs!', \$do_origs,
2360                'tags!', \$do_tags,
2361                'always-convert-anyway!', \$always);
2362     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2363
2364     my @upstreams;
2365
2366     if (@ARGV) {
2367         my $spec = shift @ARGV;
2368         my $commit = git_rev_parse "$spec^{commit}";
2369         push @upstreams, { Commit => $commit,
2370                            Source => "$ARGV[0], from command line",
2371                            Only => 1,
2372                          };
2373     }
2374
2375     my $head = get_head();
2376
2377     if (!$always) {
2378         my $troubles = 0;
2379         my $trouble = sub { $troubles++; };
2380         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2381         printdebug "troubles=$troubles\n";
2382         if (!$troubles) {
2383             print STDERR <<END;
2384 $us: Branch already seems to be in git-debrebase format!
2385 $us: --always-convert-anyway would do the conversion operation anyway
2386 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2387 END
2388             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2389             finish 0;
2390         }
2391     }
2392
2393     snags_maybe_bail_early();
2394
2395     my $version = upstreamversion $clogp->{Version};
2396     print STDERR "Considering possible commits corresponding to upstream:\n";
2397
2398     if (!@upstreams) {
2399         if ($do_tags) {
2400             my @tried;
2401             my $ups_tag = upstream_commitish_search $version, \@tried;
2402             if ($ups_tag) {
2403                 my $this = "git tag $tried[-1]";
2404                 push @upstreams, { Commit => $ups_tag,
2405                                    Source => $this,
2406                                  };
2407             } else {
2408                 printf STDERR
2409                     " git tag: no suitable tag found (tried %s)\n",
2410                     "@tried";
2411             }
2412         }
2413         if ($do_origs) {
2414             my $p = $clogp->{'Source'};
2415             # we do a quick check to see if there are plausible origs
2416             my $something=0;
2417             if (!opendir BPD, $bpd) {
2418                 die "$bpd: opendir: $!" unless $!==ENOENT;
2419             } else {
2420                 while ($!=0, my $f = readdir BPD) {
2421                     next unless is_orig_file_of_p_v $f, $p, $version;
2422                     printf STDERR
2423                         " orig: found what looks like a .orig, %s\n",
2424                         "$bpd/$f";
2425                     $something=1;
2426                     last;
2427                 }
2428                 die "read $bpd: $!" if $!;
2429                 closedir BPD;
2430             }
2431             if ($something) {
2432                 my $tree = cmdoutput
2433                     @dgit, qw(--build-products-dir), $bpd,
2434                     qw(print-unapplied-treeish);
2435                 fresh_workarea();
2436                 in_workarea sub {
2437                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2438                     rm_subdir_cached 'debian';
2439                     $tree = cmdoutput @git, qw(write-tree);
2440                     my $ups_synth = make_commit [], [ <<END, <<END,
2441 Import effective orig tree for upstream version $version
2442 END
2443 This includes the contents of the .orig(s), minus any debian/ directory.
2444
2445 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2446 END
2447                                                     ];
2448                     push @upstreams, { Commit => $ups_synth,
2449                                        Source => "orig(s) imported via dgit",
2450                                      };
2451                 }
2452             } else {
2453                 printf STDERR
2454                     " orig: no suitable origs found (looked for %s in %s)\n",
2455                     "${p}_".(stripeoch $version)."...", $bpd;
2456             }
2457         }
2458     }
2459
2460     my $some_patches = stat_exists 'debian/patches/series';
2461
2462     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2463
2464     my $result;
2465     foreach my $u (@upstreams) {
2466         my $work = $head;
2467         fresh_workarea();
2468         in_workarea sub {
2469             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2470             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2471             runcmd @git, qw(clean -xdff);
2472             runcmd @git, qw(checkout), $head, qw(-- debian);
2473             if ($some_patches) {
2474                 rm_subdir_cached 'debian/patches';
2475                 $work = make_commit [ $work ], [
2476  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2477  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2478  "to git-debrebase format.  Upstream changes will appear as commits.",
2479  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2480                                            ];
2481             }
2482             $work = make_commit [ $work, $u->{Commit} ], [
2483  'git-debrebase convert-from-dgit-view: declare upstream',
2484  '(Re)constructed breakwater merge.',
2485  '[git-debrebase anchor: declare upstream]'
2486                                                          ];
2487             runcmd @git, qw(checkout --quiet -b mk), $work;
2488             if ($some_patches) {
2489                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2490                 runcmd @git, qw(reset --quiet);
2491                 my @gbp_cmd = (qw(gbp pq import));
2492                 if (!$diagnose) {
2493                     my $gbp_err = "../gbp-pq-err";
2494                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2495                 }
2496                 my $r = system @gbp_cmd;
2497                 if ($r) {
2498                     printf STDERR
2499                         " %s: couldn't apply patches: gbp pq %s",
2500                         $u->{Source}, waitstatusmsg();
2501                     return;
2502                 }
2503             }
2504             my $work = git_rev_parse qw(HEAD);
2505             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2506             if (length $diffout) {
2507                 print STDERR
2508                     " $u->{Source}: applying patches gives different tree\n";
2509                 print STDERR $diffout if $diagnose;
2510                 return;
2511             }
2512             # OMG!
2513             $u->{Result} = $work;
2514             $result = $u;
2515         };
2516         last if $result;
2517     }
2518
2519     if (!$result) {
2520         fail <<END;
2521 Could not find or construct a suitable upstream commit.
2522 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2523 upstream commmit explicitly or provide suitable origs.
2524 END
2525     }
2526
2527     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2528
2529     ffq_check $result->{Result};
2530     snags_maybe_bail();
2531     update_head_checkout $head, $result->{Result},
2532         'convert-from-dgit-view';
2533 }
2534
2535 sub cmd_downstream_rebase_launder_v0 () {
2536     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2537     my ($base) = @ARGV;
2538     $base = git_rev_parse $base;
2539     my $old_head = get_head();
2540     my $current = $old_head;
2541     my $topmost_keep;
2542     for (;;) {
2543         if ($current eq $base) {
2544             $topmost_keep //= $current;
2545             print " $current BASE stop\n";
2546             last;
2547         }
2548         my $cl = classify $current;
2549         print " $current $cl->{Type}";
2550         my $keep = 0;
2551         my $p0 = $cl->{Parents}[0]{CommitId};
2552         my $next;
2553         if ($cl->{Type} eq 'Pseudomerge') {
2554             print " ^".($cl->{Contributor}{Ix}+1);
2555             $next = $cl->{Contributor}{CommitId};
2556         } elsif ($cl->{Type} eq 'AddPatches' or
2557                  $cl->{Type} eq 'Changelog') {
2558             print " strip";
2559             $next = $p0;
2560         } else {
2561             print " keep";
2562             $next = $p0;
2563             $keep = 1;
2564         }
2565         print "\n";
2566         if ($keep) {
2567             $topmost_keep //= $current;
2568         } else {
2569             die "to-be stripped changes not on top of the branch\n"
2570                 if $topmost_keep;
2571         }
2572         $current = $next;
2573     }
2574     if ($topmost_keep eq $old_head) {
2575         print "unchanged\n";
2576     } else {
2577         print "updating to $topmost_keep\n";
2578         update_head_checkout
2579             $old_head, $topmost_keep,
2580             'downstream-rebase-launder-v0';
2581     }
2582 }
2583
2584 getoptions_main
2585           ("bad options\n",
2586            "D+" => \$debuglevel,
2587            'noop-ok', => \$opt_noop_ok,
2588            'f=s' => \@snag_force_opts,
2589            'anchor=s' => \@opt_anchors,
2590            '--dgit=s' => \($dgit[0]),
2591            'force!',
2592            '-i:s' => sub {
2593                my ($opt,$val) = @_;
2594                badusage "git-debrebase: no cuddling to -i for git-rebase"
2595                    if length $val;
2596                die if $opt_defaultcmd_interactive; # should not happen
2597                $opt_defaultcmd_interactive = [ qw(-i) ];
2598                # This access to @ARGV is excessive familiarity with
2599                # Getopt::Long, but there isn't another sensible
2600                # approach.  '-i=s{0,}' does not work with bundling.
2601                push @$opt_defaultcmd_interactive, @ARGV;
2602                @ARGV=();
2603            },
2604            'help' => sub { print $usage_message or die $!; finish 0; },
2605            );
2606
2607 initdebug('git-debrebase ');
2608 enabledebug if $debuglevel;
2609
2610 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2611 chdir $toplevel or die "chdir $toplevel: $!";
2612
2613 $rd = fresh_playground "$playprefix/misc";
2614
2615 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2616
2617 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2618     defaultcmd_rebase();
2619 } else {
2620     my $cmd = shift @ARGV;
2621     my $cmdfn = $cmd;
2622     $cmdfn =~ y/-/_/;
2623     $cmdfn = ${*::}{"cmd_$cmdfn"};
2624
2625     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2626     $cmdfn->();
2627 }
2628
2629 finish 0;