git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$$) {
 267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 268     # if $tree_with_debian is supplied, will use that for debian/
 269     # otherwise will save and restore it.
 270     my $debian =
 271         $tree_with_debian ? "$tree_with_debian:debian"
 272         : cmdoutput @git, qw(write-tree --prefix=debian/);
 273     runcmd @git, qw(read-tree), $treeish;
 274     read_tree_subdir 'debian', $debian;
 275     rm_subdir_cached 'debian/patches' unless $keep_patches;
 276 };
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @snag_force_opts;
 288 sub snag ($$;@) {
 289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 290     if (grep { $_ eq $tag } @snag_force_opts) {
 291         $snags_forced++;
 292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 293     } else {
 294         $snags_tripped++;
 295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 296     }
 297 }
 298
 299 # Important: all mainline code must call snags_maybe_bail after
 300 # any point where snag might be called, but before making changes
 301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 302 # may be called more than once if necessary (but this is not ideal
 303 # because then the messages about number of snags may be confusing).
 304 sub snags_maybe_bail () {
 305     return if all_snags_summarised();
 306     if ($snags_forced) {
 307         printf STDERR
 308             "%s: snags: %d overriden by individual -f options\n",
 309             $us, $snags_forced;
 310     }
 311     if ($snags_tripped) {
 312         if ($opt_force) {
 313             printf STDERR
 314                 "%s: snags: %d overriden by global --force\n",
 315                 $us, $snags_tripped;
 316         } else {
 317             fail sprintf
 318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 319                 $us, $snags_tripped;
 320         }
 321     }
 322     $snags_summarised = $snags_forced + $snags_tripped;
 323 }
 324 sub snags_maybe_bail_early () {
 325     # useful to bail out early without doing a lot of work;
 326     # not a substitute for snags_maybe_bail.
 327     snags_maybe_bail() if $snags_tripped && !$opt_force;
 328 }
 329 sub any_snags () {
 330     return $snags_forced || $snags_tripped;
 331 }
 332
 333 sub gbp_pq_export ($$$) {
 334     my ($bname, $base, $tip) = @_;
 335     # must be run in a workarea.  $bname and patch-queue/$bname
 336     # ought not to exist.  Leaves you on patch-queue/$bname with
 337     # the patches staged but not committed.
 338     printdebug "gbp_pq_export $bname $base $tip\n";
 339     runcmd @git, qw(checkout -q -b), $bname, $base;
 340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 341     my @gbp_cmd = (qw(gbp pq export));
 342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 343     if ($r) {
 344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 345         failedcmd @gbp_cmd;
 346     }
 347     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 348 }
 349
 350
 351 # xxx allow merge resolution separately from laundering, before git merge
 352 #
 353 # xxx general gdr docs highlight forbidden things
 354 # xxx general gdr docs list allowable things ?
 355 # xxx general gdr docs explicitly forbid some rebase
 356 #
 357 # xxx provide a way for the user to help
 358 # xxx (eg, provide wreckage provide way to continue)
 359
 360 # later/rework?
 361 #  use git-format-patch?
 362 #  our own patch identification algorithm?
 363 #  this is an alternative strategy
 364
 365 sub mwrecknote ($$$) {
 366     my ($wrecknotes, $reftail, $commitish) = @_;
 367     $wrecknotes->{$reftail} = $commitish;
 368 }
 369
 370 sub merge_series ($$$;@) {
 371     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 372     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 373     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 374     # ^ specifies several patch series (currently we only support exactly 2)
 375     # return value is a commit which is the result of
 376     # merging the two versions of the same topic branch
 377     #   $input_q[0] and $input_q[1]
 378     # with respect to the old version
 379     #   $base_q
 380     # all onto $newbase.
 381
 382     # Creates, in *_q, a key MR for its private use
 383
 384     printdebug "merge_series newbase=$newbase\n";
 385
 386     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 387     $base_q->{MR}{S} = 'base';
 388
 389     my %prereq;
 390     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 391     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 392     # $prereq{<patch filename>}               exists or not (even later)
 393
 394     my $result;
 395
 396     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 397
 398     local $workarea = fresh_playground "$playprefix/merge";
 399     my $seriesfile = "debian/patches/series";
 400     in_workarea sub {
 401         playtree_setup();
 402         foreach my $q ($base_q, reverse @input_qs) {
 403             my $s = $q->{MR}{S};
 404             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 405             my @earlier;
 406             if (open S, $seriesfile) {
 407                 while (my $patch = <S>) {
 408                     chomp $patch or die $!;
 409                     $prereq{$patch} //= {};
 410                     foreach my $earlier (@earlier) {
 411                         $prereq{$patch}{$earlier}{$s}++ and die;
 412                     }
 413                     push @earlier, $patch;
 414                     stat "debian/patches/$patch" or die "$patch ?";
 415                 }
 416                 S->error and die "$seriesfile $!";
 417                 close S;
 418             } else {
 419                 die "$seriesfile $!" unless $!==ENOENT;
 420             }
 421             read_tree_upstream $newbase, 1;
 422             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 423                 "Convert $s to patch queue for merging",
 424                 "[git-debrebase merge-innards patch-queue import:".
 425                 " $q->{SeriesTip}]"
 426             ];
 427             printdebug "merge_series  pec $pec ";
 428             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 429             $pec = make_commit [ $pec ], [
 430                 "Drop series file from $s to avoid merge trouble",
 431                 "[git-debrebase merge-innards patch-queue prep:".
 432                 " $q->{SeriesTip}]"
 433             ];
 434
 435             read_tree_debian $newbase;
 436             if (@earlier) {
 437                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 438             } else {
 439                 rm_subdir_cached 'debian/patches';
 440             }
 441             $pec = make_commit [ $pec ], [
 442  "Update debian/ (excluding patches) to final to avoid re-merging",
 443  "debian/ was already merged and we need to just take that.",
 444                 "[git-debrebase merge-innards patch-queue packaging:".
 445                 " $q->{SeriesTip}]"
 446             ];
 447
 448             printdebug "pec' $pec\n";
 449             runcmd @git, qw(reset -q --hard), $pec;
 450             $q->{MR}{PEC} = $pec;
 451             $mwrecknote->("$q->{LeftRight}-patchqueue");
 452         }
 453         # now, because of reverse, we are on $input_q->{MR}{OQC}
 454         runcmd @git, qw(checkout -q -b merge);
 455         printdebug "merge_series merging...\n";
 456         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 457         debugcmd '+', @mergecmd;
 458         $!=0; $?=-1;
 459         if (system @mergecmd) {
 460             failedcmd @mergecmd;
 461         }
 462
 463         printdebug "merge_series merge ok, series...\n";
 464         # We need to construct a new series file
 465         # Firstly, resolve prereq
 466         foreach my $f (sort keys %prereq) {
 467             printdebug "merge_series  patch\t$f\t";
 468             if (!stat_exists "debian/patches/$f") {
 469                 print DEBUG " drop\n" if $debuglevel;
 470                 # git merge deleted it; that's how we tell it's not wanted
 471                 delete $prereq{$f};
 472                 next;
 473             }
 474             print DEBUG " keep\n" if $debuglevel;
 475             foreach my $g (sort keys %{ $prereq{$f} }) {
 476                 my $gfp = $prereq{$f}{$g};
 477                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 478                 if (!!$gfp->{0} == !!$gfp->{1}
 479                     ? $gfp->{0}
 480                     : !$gfp->{base}) {
 481                     print DEBUG "\tkeep\n" if $debuglevel;
 482                 } else {
 483                     print DEBUG "\tdrop\n" if $debuglevel;
 484                     delete $prereq{$f}{$g};
 485                 }
 486             }
 487         }
 488
 489         my $unsat = sub {
 490             my ($f) = @_;
 491             return scalar keys %{ $prereq{$f} };
 492         };
 493
 494         my $nodate = time + 1;
 495         my %authordate;
 496         # $authordate{<patch filename>};
 497         my $authordate = sub {
 498             my ($f) = @_;
 499             $authordate{$f} //= do {
 500                 open PF, "<", "debian/patches/$f" or die "$f $!";
 501                 while (<PF>) {
 502                     return $nodate if m/^$/;
 503                     last if s{^Date: }{};
 504                 }
 505                 chomp;
 506                 return cmdoutput qw(date +%s -d), $_;
 507             };
 508         };
 509
 510         open NS, '>', $seriesfile or die $!;
 511
 512         while (keys %prereq) {
 513             my $best;
 514             foreach my $try (sort keys %prereq) {
 515                 if ($best) {
 516                     next if (
 517                              $unsat->($try) <=> $unsat->($best) or
 518                              $authordate->($try) <=> $authordate->($best) or
 519                              $try cmp $best
 520                             ) >= 0;
 521                 }
 522                 $best = $try;
 523             }
 524             printdebug "merge_series series next $best\n";
 525             print NS "$best\n" or die $!;
 526             delete $prereq{$best};
 527             foreach my $gp (values %prereq) {
 528                 delete $gp->{$best};
 529             }
 530         }
 531
 532         runcmd @git, qw(add), $seriesfile;
 533         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 534         $mwrecknote->('merged-patchqueue', git_rev_parse 'HEAD');
 535
 536         printdebug "merge_series series gbp pq import\n";
 537         runcmd qw(gbp pq import);
 538
 539         # OK now we are on patch-queue/merge, and we need to rebase
 540         # onto the intended parent and drop the patches from each one
 541
 542         printdebug "merge_series series ok, building...\n";
 543         my $build = $newbase;
 544         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 545         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 546             my $commit = git_cat_file $c, 'commit';
 547             printdebug "merge_series series ok, building $c\n";
 548             read_tree_upstream $c, 0, $newbase;
 549             my $tree = cmdoutput @git, qw(write-tree);
 550             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 551             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 552             open C, ">", "../mcommit" or die $!;
 553             print C $commit or die $!;
 554             close C or die $!;
 555             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 556         }
 557         $result = $build;
 558         $mwrecknote->('merged-result', $result);
 559
 560         runcmd @git, qw(update-ref refs/heads/result), $result;
 561
 562         runcmd @git, qw(checkout -q -b debug);
 563         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 564         runcmd @git, qw(add .);
 565         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 566         my $mdebug = git_rev_parse 'HEAD';
 567         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 568         $mwrecknote->('merged-debug', $mdebug);
 569     };
 570     printdebug "merge_series returns $result\n";
 571     return $result;
 572 }
 573
 574 # classify returns an info hash like this
 575 #   CommitId => $objid
 576 #   Hdr => # commit headers, including 1 final newline
 577 #   Msg => # commit message (so one newline is dropped)
 578 #   Tree => $treeobjid
 579 #   Type => (see below)
 580 #   Parents = [ {
 581 #       Ix => $index # ie 0, 1, 2, ...
 582 #       CommitId
 583 #       Differs => return value from get_differs
 584 #       IsOrigin
 585 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 586 #     } ...]
 587 #   NewMsg => # commit message, but with any [dgit import ...] edited
 588 #             # to say "[was: ...]"
 589 #
 590 # Types:
 591 #   Packaging
 592 #   Changelog
 593 #   Upstream
 594 #   AddPatches
 595 #   Mixed
 596 #
 597 #   Pseudomerge
 598 #     has additional entres in classification result
 599 #       Overwritten = [ subset of Parents ]
 600 #       Contributor = $the_remaining_Parent
 601 #
 602 #   DgitImportUnpatched
 603 #     has additional entry in classification result
 604 #       OrigParents = [ subset of Parents ]
 605 #
 606 #   Anchor
 607 #     has additional entry in classification result
 608 #       OrigParents = [ subset of Parents ]  # singleton list
 609 #
 610 #   TreatAsAnchor
 611 #
 612 #   BreakwaterStart
 613 #
 614 #   Unknown
 615 #     has additional entry in classification result
 616 #       Why => "prose"
 617
 618 sub parsecommit ($;$) {
 619     my ($objid, $p_ref) = @_;
 620     # => hash with                   CommitId Hdr Msg Tree Parents
 621     #    Parents entries have only   Ix CommitId
 622     #    $p_ref, if provided, must be [] and is used as a base for Parents
 623
 624     $p_ref //= [];
 625     die if @$p_ref;
 626
 627     my ($h,$m) = get_commit $objid;
 628
 629     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 630     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 631
 632     my $r = {
 633         CommitId => $objid,
 634         Hdr => $h,
 635         Msg => $m,
 636         Tree => $t,
 637         Parents => $p_ref,
 638     };
 639
 640     foreach my $ph (@ph) {
 641         push @$p_ref, {
 642             Ix => scalar @$p_ref,
 643             CommitId => $ph,
 644         };
 645     }
 646
 647     return $r;
 648 }
 649
 650 sub classify ($) {
 651     my ($objid) = @_;
 652
 653     my @p;
 654     my $r = parsecommit($objid, \@p);
 655     my $t = $r->{Tree};
 656
 657     foreach my $p (@p) {
 658         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 659     }
 660
 661     printdebug "classify $objid \$t=$t \@p",
 662         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 663         "\n";
 664
 665     my $classify = sub {
 666         my ($type, @rest) = @_;
 667         $r = { %$r, Type => $type, @rest };
 668         if ($debuglevel) {
 669             printdebug " = $type ".(dd $r)."\n";
 670         }
 671         return $r;
 672     };
 673     my $unknown = sub {
 674         my ($why) = @_;
 675         $r = { %$r, Type => qw(Unknown), Why => $why };
 676         printdebug " ** Unknown\n";
 677         return $r;
 678     };
 679
 680     if (grep { $_ eq $objid } @opt_anchors) {
 681         return $classify->('TreatAsAnchor');
 682     }
 683
 684     my @identical = grep { !$_->{Differs} } @p;
 685     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 686     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 687
 688     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 689         # multi-orig upstreams are represented with an anchor merge
 690         # from a single upstream commit which combines the orig tarballs
 691
 692         # Every anchor tagged this way must be a merge.
 693         # We are relying on the
 694         #     [git-debrebase anchor: ...]
 695         # commit message annotation in "declare" anchor merges (which
 696         # do not have any upstream changes), to distinguish those
 697         # anchor merges from ordinary pseudomerges (which we might
 698         # just try to strip).
 699         #
 700         # However, the user is going to be doing git-rebase a lot.  We
 701         # really don't want them to rewrite an anchor commit.
 702         # git-rebase trips up on merges, so that is a useful safety
 703         # catch.
 704         #
 705         # BreakwaterStart commits are also anchors in the terminology
 706         # of git-debrebase(5), but they are untagged (and always
 707         # manually generated).
 708         #
 709         # We cannot not tolerate any tagged linear commit (ie,
 710         # BreakwaterStart commits tagged `[anchor:') because such a
 711         # thing could result from an erroneous linearising raw git
 712         # rebase of a merge anchor.  That would represent a corruption
 713         # of the branch. and we want to detect and reject the results
 714         # of such corruption before it makes it out anywhere.  If we
 715         # reject it here then we avoid making the pseudomerge which
 716         # would be needed to push it.
 717
 718         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 719         @p == 2 or return $badanchor->("has other than two parents");
 720         $haspatches and return $badanchor->("contains debian/patches");
 721
 722         # How to decide about l/r ordering of anchors ?  git
 723         # --topo-order prefers to expand 2nd parent first.  There's
 724         # already an easy rune to look for debian/ history anyway (git log
 725         # debian/) so debian breakwater branch should be 1st parent; that
 726         # way also there's also an easy rune to look for the upstream
 727         # patches (--topo-order).
 728
 729         # Also this makes --first-parent be slightly more likely to
 730         # be useful - it makes it provide a linearised breakwater history.
 731
 732         # Of course one can say somthing like
 733         #  gitk -- ':/' ':!/debian'
 734         # to get _just_ the commits touching upstream files, and by
 735         # the TREESAME logic in git-rev-list this will leave the
 736         # breakwater into upstream at the first anchor.  But that
 737         # doesn't report debian/ changes at all.
 738
 739         # Other observations about gitk: by default, gitk seems to
 740         # produce output in a different order to git-rev-list.  I
 741         # can't seem to find this documented anywhere.  gitk
 742         # --date-order DTRT.  But, gitk always seems to put the
 743         # parents from left to right, in order, so it's easy to see
 744         # which way round a pseudomerge is.
 745
 746         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 747         $p[1]{Differs} & ~DS_DEB and
 748             $badanchor->("upstream files differ from left parent");
 749         $p[0]{Differs} & ~D_UPS and
 750             $badanchor->("debian/ differs from right parent");
 751
 752         return $classify->(qw(Anchor),
 753                            OrigParents => [ $p[1] ]);
 754     }
 755
 756     if (@p == 1) {
 757         my $d = $r->{Parents}[0]{Differs};
 758         if ($d == D_PAT_ADD) {
 759             return $classify->(qw(AddPatches));
 760         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 761             return $unknown->("edits debian/patches");
 762         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 763             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 764             if ($ty eq 'tree') {
 765                 if ($d == D_DEB_CLOG) {
 766                     return $classify->(qw(Changelog));
 767                 } else {
 768                     return $classify->(qw(Packaging));
 769                 }
 770             } elsif ($ty eq 'missing') {
 771                 return $classify->(qw(BreakwaterStart));
 772             } else {
 773                 return $unknown->("parent's debian is not a directory");
 774             }
 775         } elsif ($d == D_UPS) {
 776             return $classify->(qw(Upstream));
 777         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 778             return $classify->(qw(Mixed));
 779         } elsif ($d == 0) {
 780             return $unknown->("no changes");
 781         } else {
 782             confess "internal error $objid ?";
 783         }
 784     }
 785     if (!@p) {
 786         return $unknown->("origin commit");
 787     }
 788
 789     if (@p == 2 && @identical == 1) {
 790         my @overwritten = grep { $_->{Differs} } @p;
 791         confess "internal error $objid ?" unless @overwritten==1;
 792         return $classify->(qw(Pseudomerge),
 793                            Overwritten => [ $overwritten[0] ],
 794                            Contributor => $identical[0]);
 795     }
 796     if (@p == 2 && @identical == 2) {
 797         my $get_t = sub {
 798             my ($ph,$pm) = get_commit $_[0]{CommitId};
 799             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 800             $1;
 801         };
 802         my @bytime = @p;
 803         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 804         if ($order > 0) { # newer first
 805         } elsif ($order < 0) {
 806             @bytime = reverse @bytime;
 807         } else {
 808             # same age, default to order made by -s ours
 809             # that is, commit was made by someone who preferred L
 810         }
 811         return $classify->(qw(Pseudomerge),
 812                            SubType => qw(Ambiguous),
 813                            Contributor => $bytime[0],
 814                            Overwritten => [ $bytime[1] ]);
 815     }
 816     foreach my $p (@p) {
 817         my ($p_h, $p_m) = get_commit $p->{CommitId};
 818         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 819         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 820     }
 821     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 822     my $m2 = $r->{Msg};
 823     if (!(grep { !$_->{IsOrigin} } @p) and
 824         (@orig_ps >= @p - 1) and
 825         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 826         $r->{NewMsg} = $m2;
 827         return $classify->(qw(DgitImportUnpatched),
 828                            OrigParents => \@orig_ps);
 829     }
 830
 831     if (@p == 2 and
 832         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 833         # xxx ^ metadata tag needs adding to (5)
 834         return $classify->("MergedBreakwaters");
 835     }
 836     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 837         return $unknown->("unknown kind of merge from $1");
 838     }
 839     if (@p > 2) {
 840         return $unknown->("octopus merge");
 841     }
 842
 843     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 844         return $unknown->("general two-parent merge");
 845     }
 846
 847     return $classify->("VanillaMerge");
 848 }
 849
 850 sub keycommits ($;$$$$$);
 851
 852 sub mergedbreakwaters_anchor ($) {
 853     my ($cl) = @_;
 854     my $best_anchor;
 855     foreach my $p (@{ $cl->{Parents} }) {
 856         my ($panchor, $pbw) = keycommits $p->{CommitId},
 857             undef,undef,undef,undef, 1;
 858         $best_anchor = $panchor
 859             if !defined $best_anchor
 860             or is_fast_fwd $best_anchor, $panchor;
 861         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 862             unless is_fast_fwd $panchor, $best_anchor;
 863     }
 864     return $best_anchor;
 865 }
 866
 867 sub keycommits ($;$$$$$) {
 868     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 869     # => ($anchor, $breakwater)
 870
 871     # $unclean->("unclean-$tagsfx", $msg, $cl)
 872     # $furniture->("unclean-$tagsfx", $msg, $cl)
 873     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 874     #   is callled for each situation or commit that
 875     #   wouldn't be found in a laundered branch
 876     # $furniture is for furniture commits such as might be found on an
 877     #   interchange branch (pseudomerge, d/patches, changelog)
 878     # $trouble is for things whnich prevent the return of
 879     #   anchor and breakwater information; if that is ignored,
 880     #   then keycommits returns (undef, undef) instead.
 881     # $fatal is for unprocessable commits, and should normally cause
 882     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 883     #
 884     # If $claimed_bw, this is supposed to be a breakwater commit.
 885     #
 886     # If a callback is undef, fail is called instead.
 887     # If a callback is defined but false, the situation is ignored.
 888     # Callbacks may say:
 889     #   no warnings qw(exiting); last;
 890     # if the answer is no longer wanted.
 891
 892     my ($anchor, $breakwater);
 893     $breakwater = $head if $claimed_bw;
 894     my $clogonly;
 895     my $cl;
 896     my $found_pm;
 897     $fatal //= sub { fail $_[1]; };
 898     my $x = sub {
 899         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 900         my $why = $mainwhy.$xwhy;
 901         my $m = "branch needs laundering (run git-debrebase): $why";
 902         fail $m unless defined $cb;
 903         return unless $cb;
 904         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 905     };
 906     my $found_anchor = sub {
 907         ($anchor) = @_;
 908         $breakwater //= $clogonly;
 909         $breakwater //= $head;
 910         no warnings qw(exiting);
 911         last;
 912     };
 913     for (;;) {
 914         $cl = classify $head;
 915         my $ty = $cl->{Type};
 916         if ($ty eq 'Packaging') {
 917             $breakwater //= $clogonly;
 918             $breakwater //= $head;
 919         } elsif ($ty eq 'Changelog') {
 920             # this is going to count as the tip of the breakwater
 921             # only if it has no upstream stuff before it
 922             $clogonly //= $head;
 923         } elsif ($ty eq 'Anchor' or
 924                  $ty eq 'TreatAsAnchor' or
 925                  $ty eq 'BreakwaterStart') {
 926             $found_anchor->($head);
 927         } elsif ($ty eq 'Upstream') {
 928             $x->($unclean, 'ordering',
 929  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 930                 if defined $breakwater;
 931             $clogonly = undef;
 932             $breakwater = undef;
 933         } elsif ($ty eq 'Mixed') {
 934             $x->($unclean, 'mixed',
 935                  "found mixed upstream/packaging commit"," ($head)");
 936             $clogonly = undef;
 937             $breakwater = undef;
 938         } elsif ($ty eq 'Pseudomerge' or
 939                  $ty eq 'AddPatches') {
 940             my $found_pm = 1;
 941             $x->($furniture, (lc $ty),
 942                  "found interchange bureaucracy commit ($ty)"," ($head)");
 943         } elsif ($ty eq 'DgitImportUnpatched') {
 944             if ($found_pm) {
 945                 $x->($trouble, 'dgitimport',
 946                      "found dgit dsc import"," ($head)");
 947                 return (undef,undef);
 948             } else {
 949                 $x->($fatal, 'unprocessable',
 950                      "found bare dgit dsc import with no prior history",
 951                      " ($head)");
 952                 return (undef,undef);
 953             }
 954         } elsif ($ty eq 'VanillaMerge') {
 955             $x->($trouble, 'vanillamerge',
 956                  "found vanilla merge"," ($head)");
 957             return (undef,undef);
 958         } elsif ($ty eq 'MergedBreakwaters') {
 959             $found_anchor->(mergedbreakwaters_anchor $cl);
 960         } else {
 961             $x->($fatal, 'unprocessable',
 962                  "found unprocessable commit, cannot cope: $cl->{Why}",
 963                  " ($head)");
 964             return (undef,undef);
 965         }
 966         $head = $cl->{Parents}[0]{CommitId};
 967     }
 968     return ($anchor, $breakwater);
 969 }
 970
 971 sub walk ($;$$$);
 972 sub walk ($;$$$) {
 973     my ($input,
 974         $nogenerate,$report, $report_lprefix) = @_;
 975     # => ($tip, $breakwater_tip, $last_anchor)
 976     # (or nothing, if $nogenerate)
 977
 978     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 979     $report_lprefix //= '';
 980
 981     # go through commits backwards
 982     # we generate two lists of commits to apply:
 983     # breakwater branch and upstream patches
 984     my (@brw_cl, @upp_cl, @processed);
 985     my %found;
 986     my $upp_limit;
 987     my @pseudomerges;
 988
 989     my $cl;
 990     my $xmsg = sub {
 991         my ($prose, $info) = @_;
 992         my $ms = $cl->{Msg};
 993         chomp $ms;
 994         $info //= '';
 995         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 996         return (Msg => $ms);
 997     };
 998     my $rewrite_from_here = sub {
 999         my ($cl) = @_;
1000         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1001         push @$cl, $sp_cl;
1002         push @processed, $sp_cl;
1003     };
1004     my $cur = $input;
1005
1006     my $prdelim = "";
1007     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1008
1009     my $prline = sub {
1010         return unless $report;
1011         print $report $prdelim, $report_lprefix, @_;
1012         $prdelim = "\n";
1013     };
1014
1015     my $bomb = sub { # usage: return $bomb->();
1016         print $report " Unprocessable" if $report;
1017         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1018         $prprdelim->();
1019         if ($nogenerate) {
1020             return (undef,undef);
1021         }
1022         fail "found unprocessable commit, cannot cope".
1023             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1024             " (commit $cur) (d.".
1025             (join ' ', map { sprintf "%#x", $_->{Differs} }
1026              @{ $cl->{Parents} }).
1027                  ")";
1028     };
1029
1030     my $build;
1031     my $breakwater;
1032
1033     my $build_start = sub {
1034         my ($msg, $parent) = @_;
1035         $prline->(" $msg");
1036         $build = $parent;
1037         no warnings qw(exiting); last;
1038     };
1039
1040     my $nomerge = sub {
1041         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1042     };
1043
1044     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1045
1046     my $last_anchor;
1047
1048     for (;;) {
1049         $cl = classify $cur;
1050         my $ty = $cl->{Type};
1051         my $st = $cl->{SubType};
1052         $prline->("$cl->{CommitId} $cl->{Type}");
1053         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1054         push @processed, $cl;
1055         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1056         if ($ty eq 'AddPatches') {
1057             $cur = $p0;
1058             $rewrite_from_here->(\@upp_cl);
1059             next;
1060         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1061             push @brw_cl, $cl;
1062             $cur = $p0;
1063             next;
1064         } elsif ($ty eq 'BreakwaterStart') {
1065             $last_anchor = $cur;
1066             $build_start->('FirstPackaging', $cur);
1067         } elsif ($ty eq 'Upstream') {
1068             push @upp_cl, $cl;
1069             $cur = $p0;
1070             next;
1071         } elsif ($ty eq 'Mixed') {
1072             my $queue = sub {
1073                 my ($q, $wh) = @_;
1074                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1075                 push @$q, $cls;
1076             };
1077             $queue->(\@brw_cl, "debian");
1078             $queue->(\@upp_cl, "upstream");
1079             $rewrite_from_here->(\@brw_cl);
1080             $cur = $p0;
1081             next;
1082         } elsif ($ty eq 'Pseudomerge') {
1083             my $contrib = $cl->{Contributor}{CommitId};
1084             print $report " Contributor=$contrib" if $report;
1085             push @pseudomerges, $cl;
1086             $rewrite_from_here->(\@upp_cl);
1087             $cur = $contrib;
1088             next;
1089         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1090             $last_anchor = $cur;
1091             $build_start->("Anchor", $cur);
1092         } elsif ($ty eq 'DgitImportUnpatched') {
1093             my $pm = $pseudomerges[-1];
1094             if (defined $pm) {
1095                 # To an extent, this is heuristic.  Imports don't have
1096                 # a useful history of the debian/ branch.  We assume
1097                 # that the first pseudomerge after an import has a
1098                 # useful history of debian/, and ignore the histories
1099                 # from later pseudomerges.  Often the first pseudomerge
1100                 # will be the dgit import of the upload to the actual
1101                 # suite intended by the non-dgit NMUer, and later
1102                 # pseudomerges may represent in-archive copies.
1103                 my $ovwrs = $pm->{Overwritten};
1104                 printf $report " PM=%s \@Overwr:%d",
1105                     $pm->{CommitId}, (scalar @$ovwrs)
1106                     if $report;
1107                 if (@$ovwrs != 1) {
1108                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1109                     return $bomb->();
1110                 }
1111                 my $ovwr = $ovwrs->[0]{CommitId};
1112                 printf $report " Overwr=%s", $ovwr if $report;
1113                 # This import has a tree which is just like a
1114                 # breakwater tree, but it has the wrong history.  It
1115                 # ought to have the previous breakwater (which the
1116                 # pseudomerge overwrote) as an ancestor.  That will
1117                 # make the history of the debian/ files correct.  As
1118                 # for the upstream version: either it's the same as
1119                 # was ovewritten (ie, same as the previous
1120                 # breakwater), in which case that history is precisely
1121                 # right; or, otherwise, it was a non-gitish upload of a
1122                 # new upstream version.  We can tell these apart by
1123                 # looking at the tree of the supposed upstream.
1124                 push @brw_cl, {
1125                     %$cl,
1126                     SpecialMethod => 'DgitImportDebianUpdate',
1127                     $xmsg->("convert dgit import: debian changes")
1128                 }, {
1129                     %$cl,
1130                     SpecialMethod => 'DgitImportUpstreamUpdate',
1131                     $xmsg->("convert dgit import: upstream update",
1132                             " anchor")
1133                 };
1134                 $prline->(" Import");
1135                 $rewrite_from_here->(\@brw_cl);
1136                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1137                 $cur = $ovwr;
1138                 next;
1139             } else {
1140                 # Everything is from this import.  This kind of import
1141                 # is already nearly in valid breakwater format, with the
1142                 # patches as commits.  Unfortunately it contains
1143                 # debian/patches/.
1144                 printdebug "*** WALK BOMB bare dgit import\n";
1145                 $cl->{Why} = "bare dgit dsc import";
1146                 return $bomb->();
1147             }
1148             die "$ty ?";
1149         } elsif ($ty eq 'MergedBreakwaters') {
1150             $last_anchor = mergedbreakwaters_anchor $cl;
1151             $build_start->(' MergedBreakwaters', $cur);
1152             last;
1153         } elsif ($ty eq 'VanillaMerge') {
1154             # User may have merged unstitched branch(es).  We will
1155             # have now lost what ffq-prev was then (since the later
1156             # pseudomerge may introduce further changes).  The effect
1157             # of resolving such a merge is that we may have to go back
1158             # further in history to find a merge base, since the one
1159             # which was reachable via ffq-prev is no longer findable.
1160             # This is suboptimal, but if it all works we'll have done
1161             # the right thing.
1162             # xxx we should warn the user in the docs about this
1163
1164             my $ok=1;
1165             my $best_anchor;
1166             # We expect to find a dominating anchor amongst the
1167             # inputs' anchors.  That will be the new anchor.
1168             #
1169             # More complicated is finding a merge base for the
1170             # breakwaters.  We need a merge base that is a breakwater
1171             # commit.  The ancestors of breakwater commits are more
1172             # breakwater commits and possibly upstream commits and the
1173             # ancestors of those upstream.  Upstreams might have
1174             # arbitrary ancestors.  But any upstream commit U is
1175             # either included in both anchors, in which case the
1176             # earlier anchor is a better merge base than any of U's
1177             # ancestors; or U is not included in the older anchor, in
1178             # which case U is not an ancestor of the vanilla merge at
1179             # all.  So no upstream commit, nor any ancestor thereof,
1180             # is a best merge base.  As for non-breakwater Debian
1181             # commits: these are never ancestors of any breakwater.
1182             #
1183             # So any best merge base as found by git-merge-base
1184             # is a suitable breakwater anchor.  Usually there will
1185             # be only one.
1186
1187             printdebug "*** MERGE\n";
1188
1189             my @bwbcmd = (@git, qw(merge-base));
1190             my @ibcmd = (@git, qw(merge-base --all));
1191             my $might_be_in_bw = 1;
1192
1193             my $ps = $cl->{Parents};
1194
1195             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1196
1197             foreach my $p (@$ps) {
1198                 $prline->(" VanillaMerge ".$p->{Ix});
1199                 $prprdelim->();
1200                 my ($ptip, $pbw, $panchor) =
1201                     walk $p->{CommitId}, 0, $report,
1202                          $report_lprefix.'  ';
1203                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1204                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1205                 $p->{Anchor} = $panchor;
1206
1207                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1208                 $mwrecknote->("$lr-input", $p->{CommitId});
1209
1210                 my $mwrecknote_parent = sub {
1211                     my ($which) = @_;
1212                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1213                 };
1214                 $mwrecknote_parent->('Laundered');
1215                 $mwrecknote_parent->('Breakwater');
1216                 $mwrecknote_parent->('Anchor');
1217
1218                 $best_anchor = $panchor if
1219                     !defined $best_anchor or
1220                     is_fast_fwd $best_anchor, $panchor;
1221
1222                 printdebug " MERGE BA best=".($best_anchor//'-').
1223                     " p=$panchor\n";
1224             }
1225
1226             $mwrecknote->('result-anchor', $best_anchor);
1227
1228             foreach my $p (@$ps) {
1229                 $prline->(" VanillaMerge ".$p->{Ix});
1230                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1231                     $nomerge->('divergent anchors');
1232                 } elsif ($p->{Anchor} eq $best_anchor) {
1233                     print $report " SameAnchor" if $report;
1234                 } else {
1235                     print $report " SupersededAnchor" if $report;
1236                 }
1237                 if ($p->{Breakwater} eq $p->{CommitId}) {
1238                     # this parent commit was its own breakwater,
1239                     # ie it is part of the breakwater
1240                     print $report " Breakwater" if $report;
1241                 } else {
1242                     $might_be_in_bw = 0;
1243                 }
1244                 push @bwbcmd, $p->{Breakwater};
1245                 push @ibcmd, $p->{CommitId};
1246             }
1247
1248             if ($ok && $might_be_in_bw) {
1249                 # We could rewrite this to contaion the metadata
1250                 # declaring it to be MergedBreakwaters, but
1251                 # unnecessarily rewriting a merge seems unhelpful.
1252                 $prline->(" VanillaMerge MergedBreakwaters");
1253                 $last_anchor = $best_anchor;
1254                 $build_start->('MergedBreakwaters', $cur);
1255             }
1256
1257             my $bwb = cmdoutput @bwbcmd;
1258
1259             # OK, now we have a breakwater base, but we need the merge
1260             # base for the interchange branch because we need the delta
1261             # queue.
1262             #
1263             # This a the best merge base of our inputs which has the
1264             # breakwater merge base as an ancestor.
1265
1266             my @ibs =
1267                 grep /./,
1268                 split /\n/,
1269                 cmdoutput @ibcmd;
1270
1271             @ibs or confess 'internal error, expected anchor at least ?';
1272
1273             my $ib;
1274             my $ibleaf;
1275             foreach my $tibix (0..$#ibs) {
1276                 my $tib = $ibs[$tibix];
1277                 my $ff = is_fast_fwd $bwb, $tib;
1278                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1279                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1280                 $mwrecknote->($tibleaf, $tib);
1281                 next unless $ff;
1282                 next if $ib;
1283                 $ib = $tib;
1284                 $ibleaf = $tibleaf;
1285             }
1286
1287             $ib or $nomerge->("no suitable interchange merge base");
1288
1289             $prline->("  VanillaMerge Base");
1290             $prprdelim->();
1291             my ($btip, $bbw, $banchor) = eval {
1292                 walk $ib, 0, $report, $report_lprefix.'  ';
1293             };
1294             $nomerge->("walking interchange branch merge base ($ibleaf): ".
1295                        $@) if length $@;
1296
1297             $mwrecknote->("mergebase-laundered", $btip);
1298             $mwrecknote->("mergebase-breakwater", $bbw);
1299             $mwrecknote->("mergebase-anchor", $banchor);
1300
1301             my $ibinfo = { SeriesTip => $btip,
1302                            SeriesBase => $bbw,
1303                            Anchor => $banchor,
1304                            LeftRight => 'mergebase' };
1305
1306             $bbw eq $bwb
1307                 or $nomerge->("interchange merge-base ($ib)'s".
1308                               " breakwater ($bbw)".
1309                               " != breakwaters' merge-base ($bwb)");
1310
1311             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1312                  or $nomerge->("interchange merge-base ($ib)'s".
1313                                " anchor ($ibinfo->{SeriesBase})".
1314                                " != any merge input's anchor (".
1315                                (join ' ', map { $_->{Anchor} } @$ps).
1316                                ")");
1317
1318             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1319             $cl->{MergeBestAnchor} = $best_anchor;
1320             push @brw_cl, {
1321                 %$cl,
1322                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1323                 $xmsg->('constructed from vanilla merge',
1324                         ' merged-breakwater'),
1325             };
1326             push @upp_cl, {
1327                 %$cl,
1328                 SpecialMethod => 'MergeMergeSeries',
1329             };
1330             $build_start->('MergeBreakwaters', $cur);
1331         } else {
1332             printdebug "*** WALK BOMB unrecognised\n";
1333             return $bomb->();
1334         }
1335     }
1336     $prprdelim->();
1337
1338     printdebug "*** WALK prep done cur=$cur".
1339         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1340
1341     return if $nogenerate;
1342
1343     # Now we build it back up again
1344
1345     fresh_workarea();
1346
1347     my $rewriting = 0;
1348
1349     my $read_tree_upstream = sub {
1350         my ($treeish) = @_;
1351         read_tree_upstream $treeish, 0, $build;
1352     };
1353
1354     $#upp_cl = $upp_limit if defined $upp_limit;
1355
1356     my $committer_authline = calculate_committer_authline();
1357
1358     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1359
1360     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1361
1362     in_workarea sub {
1363         mkdir $rd or $!==EEXIST or die $!;
1364         my $current_method;
1365         runcmd @git, qw(read-tree), $build;
1366         foreach my $cl (qw(Debian), (reverse @brw_cl),
1367                         { SpecialMethod => 'RecordBreakwaterTip' },
1368                         qw(Upstream), (reverse @upp_cl)) {
1369             if (!ref $cl) {
1370                 $current_method = $cl;
1371                 next;
1372             }
1373             my $method = $cl->{SpecialMethod} // $current_method;
1374             my @parents = ($build);
1375             my $cltree = $cl->{CommitId};
1376             printdebug "WALK BUILD ".($cltree//'undef').
1377                 " $method (rewriting=$rewriting)\n";
1378             if ($method eq 'Debian') {
1379                 read_tree_debian($cltree);
1380             } elsif ($method eq 'Upstream') {
1381                 $read_tree_upstream->($cltree);
1382             } elsif ($method eq 'StartRewrite') {
1383                 $rewriting = 1;
1384                 next;
1385             } elsif ($method eq 'RecordBreakwaterTip') {
1386                 $breakwater = $build;
1387                 next;
1388             } elsif ($method eq 'DgitImportDebianUpdate') {
1389                 read_tree_debian($cltree);
1390             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1391                 confess unless $rewriting;
1392                 my $differs = (get_differs $build, $cltree);
1393                 next unless $differs & D_UPS;
1394                 $read_tree_upstream->($cltree);
1395                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1396             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1397                 print "Found a general merge, will try to tidy it up.\n";
1398                 $rewriting = 1;
1399                 $read_tree_upstream->($cl->{MergeBestAnchor});
1400                 $read_tree_upstream->($cl->{MergeBestAnchor});
1401                 read_tree_debian($cltree);
1402                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1403             } elsif ($method eq 'MergeMergeSeries') {
1404                 print "Running merge resolution for $cl->{CommitId}...\n";
1405                 $build = merge_series
1406                     $build, $cl->{MergeWreckNotes},
1407                     $cl->{MergeInterchangeBaseInfo},
1408                     @{ $cl->{Parents} };
1409                 $last_anchor = $cl->{MergeBestAnchor};
1410
1411                 # Check for mismerges:
1412                 my $check = sub {
1413                     my ($against, $allow, $what) = @_;
1414                     my $differs = get_differs $build, $against;
1415                     $nomerge->(sprintf
1416        "merge misresolved: %s are not the same (%s %s d.%#x)",
1417                                $what, $against, $build, $differs)
1418                         if $differs & ~($allow | D_PAT_ADD);
1419                 };
1420
1421                 # Breakwater changes which were in each side of the
1422                 # merge will have been incorporated into the
1423                 # MergeCreateMergedBreakwaters output.  Because the
1424                 # upstream series was rebased onto the new breakwater,
1425                 # so should all of the packaging changes which were in
1426                 # the input.
1427                 $check->($input, D_UPS, 'debian files');
1428
1429                 # Upstream files are merge_series, which ought to
1430                 # have been identical to the original merge.
1431                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1432
1433                 print "Merge resolution successful.\n";
1434                 next;
1435             } else {
1436                 confess "$method ?";
1437             }
1438             if (!$rewriting) {
1439                 my $procd = (pop @processed) // 'UNDEF';
1440                 if ($cl ne $procd) {
1441                     $rewriting = 1;
1442                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1443                 }
1444             }
1445             my $newtree = cmdoutput @git, qw(write-tree);
1446             my $ch = $cl->{Hdr};
1447             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1448             $ch =~ s{^parent .*\n}{}mg;
1449             $ch =~ s{(?=^author)}{
1450                 join '', map { "parent $_\n" } @parents
1451             }me or confess "$ch ?";
1452             if ($rewriting) {
1453                 $ch =~ s{^committer .*$}{$committer_authline}m
1454                     or confess "$ch ?";
1455             }
1456             my $cf = "$rd/m$rewriting";
1457             open CD, ">", $cf or die $!;
1458             print CD $ch, "\n", $cl->{Msg} or die $!;
1459             close CD or die $!;
1460             my @cmd = (@git, qw(hash-object));
1461             push @cmd, qw(-w) if $rewriting;
1462             push @cmd, qw(-t commit), $cf;
1463             my $newcommit = cmdoutput @cmd;
1464             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1465             $build = $newcommit;
1466             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1467                 $last_anchor = $cur;
1468             }
1469         }
1470     };
1471
1472     my $final_check = get_differs $build, $input;
1473     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1474         if $final_check & ~D_PAT_ADD;
1475
1476     my @r = ($build, $breakwater, $last_anchor);
1477     printdebug "*** WALK RETURN @r\n";
1478     return @r
1479 }
1480
1481 sub get_head () {
1482     git_check_unmodified();
1483     return git_rev_parse qw(HEAD);
1484 }
1485
1486 sub update_head ($$$) {
1487     my ($old, $new, $mrest) = @_;
1488     push @deferred_updates, "update HEAD $new $old";
1489     run_deferred_updates $mrest;
1490 }
1491
1492 sub update_head_checkout ($$$) {
1493     my ($old, $new, $mrest) = @_;
1494     update_head $old, $new, $mrest;
1495     runcmd @git, qw(reset --hard);
1496 }
1497
1498 sub update_head_postlaunder ($$$) {
1499     my ($old, $tip, $reflogmsg) = @_;
1500     return if $tip eq $old;
1501     print "git-debrebase: laundered (head was $old)\n";
1502     update_head $old, $tip, $reflogmsg;
1503     # no tree changes except debian/patches
1504     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1505 }
1506
1507 sub currently_rebasing() {
1508     foreach (qw(rebase-merge rebase-apply)) {
1509         return 1 if stat_exists "$maindir_gitdir/$_";
1510     }
1511     return 0;
1512 }
1513
1514 sub bail_if_rebasing() {
1515     fail "you are in the middle of a git-rebase already"
1516         if currently_rebasing();
1517 }
1518
1519 sub do_launder_head ($) {
1520     my ($reflogmsg) = @_;
1521     my $old = get_head();
1522     record_ffq_auto();
1523     my ($tip,$breakwater) = walk $old;
1524     snags_maybe_bail();
1525     update_head_postlaunder $old, $tip, $reflogmsg;
1526     return ($tip,$breakwater);
1527 }
1528
1529 sub cmd_launder_v0 () {
1530     badusage "no arguments to launder-v0 allowed" if @ARGV;
1531     my $old = get_head();
1532     my ($tip,$breakwater,$last_anchor) = walk $old;
1533     update_head_postlaunder $old, $tip, 'launder';
1534     printf "# breakwater tip\n%s\n", $breakwater;
1535     printf "# working tip\n%s\n", $tip;
1536     printf "# last anchor\n%s\n", $last_anchor;
1537 }
1538
1539 sub defaultcmd_rebase () {
1540     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1541     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1542     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1543 }
1544
1545 sub cmd_analyse () {
1546     badusage "analyse does not support any options"
1547         if @ARGV and $ARGV[0] =~ m/^-/;
1548     badusage "too many arguments to analyse" if @ARGV>1;
1549     my ($old) = @ARGV;
1550     if (defined $old) {
1551         $old = git_rev_parse $old;
1552     } else {
1553         $old = git_rev_parse 'HEAD';
1554     }
1555     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1556     STDOUT->error and die $!;
1557 }
1558
1559 sub ffq_prev_branchinfo () {
1560     my $current = git_get_symref();
1561     return gdr_ffq_prev_branchinfo($current);
1562 }
1563
1564 sub ffq_check ($;$$) {
1565     # calls $ff and/or $notff zero or more times
1566     # then returns either (status,message) where status is
1567     #    exists
1568     #    detached
1569     #    weird-symref
1570     #    notbranch
1571     # or (undef,undef, $ffq_prev,$gdrlast)
1572     # $ff and $notff are called like this:
1573     #   $ff->("message for stdout\n");
1574     #   $notff->('snag-name', $message);
1575     # normally $currentval should be HEAD
1576     my ($currentval, $ff, $notff) =@_;
1577
1578     $ff //= sub { print $_[0] or die $!; };
1579     $notff //= \&snag;
1580
1581     my ($status, $message, $current, $ffq_prev, $gdrlast)
1582         = ffq_prev_branchinfo();
1583     return ($status, $message) unless $status eq 'branch';
1584
1585     my $exists = git_get_ref $ffq_prev;
1586     return ('exists',"$ffq_prev already exists") if $exists;
1587
1588     return ('not-branch', 'HEAD symref is not to refs/heads/')
1589         unless $current =~ m{^refs/heads/};
1590     my $branch = $';
1591
1592     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1593     my %checked;
1594
1595     printdebug "ffq check_specs @check_specs\n";
1596
1597     my $check = sub {
1598         my ($lrref, $desc) = @_;
1599         printdebug "ffq might check $lrref ($desc)\n";
1600         my $invert;
1601         for my $chk (@check_specs) {
1602             my $glob = $chk;
1603             $invert = $glob =~ s{^[!^]}{};
1604             last if fnmatch $glob, $lrref;
1605         }
1606         return if $invert;
1607         my $lrval = git_get_ref $lrref;
1608         return unless length $lrval;
1609
1610         if (is_fast_fwd $lrval, $currentval) {
1611             $ff->("OK, you are ahead of $lrref\n");
1612             $checked{$lrref} = 1;
1613         } elsif (is_fast_fwd $currentval, $lrval) {
1614             $checked{$lrref} = -1;
1615             $notff->('behind', "you are behind $lrref, divergence risk");
1616         } else {
1617             $checked{$lrref} = -1;
1618             $notff->('diverged', "you have diverged from $lrref");
1619         }
1620     };
1621
1622     my $merge = cfg "branch.$branch.merge",1;
1623     if (defined $merge and $merge =~ m{^refs/heads/}) {
1624         my $rhs = $';
1625         printdebug "ffq merge $rhs\n";
1626         my $check_remote = sub {
1627             my ($remote, $desc) = @_;
1628             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1629             return unless defined $remote;
1630             $check->("refs/remotes/$remote/$rhs", $desc);
1631         };
1632         $check_remote->((scalar cfg "branch.$branch.remote",1),
1633                         'remote fetch/merge branch');
1634         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1635                         (scalar cfg "branch.$branch.pushDefault",1),
1636                         'remote push branch');
1637     }
1638     if ($branch =~ m{^dgit/}) {
1639         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1640     } elsif ($branch =~ m{^master$}) {
1641         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1642     }
1643     return (undef, undef, $ffq_prev, $gdrlast);
1644 }
1645
1646 sub record_ffq_prev_deferred () {
1647     # => ('status', "message")
1648     # 'status' may be
1649     #    deferred          message is undef
1650     #    exists
1651     #    detached
1652     #    weird-symref
1653     #    notbranch
1654     # if not ff from some branch we should be ff from, is an snag
1655     # if "deferred", will have added something about that to
1656     #   @deferred_update_messages, and also maybe printed (already)
1657     #   some messages about ff checks
1658     bail_if_rebasing();
1659     my $currentval = get_head();
1660
1661     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1662     return ($status,$message) if defined $status;
1663
1664     snags_maybe_bail();
1665
1666     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1667     push @deferred_updates, "delete $gdrlast";
1668     push @deferred_update_messages, "Recorded previous head for preservation";
1669     return ('deferred', undef);
1670 }
1671
1672 sub record_ffq_auto () {
1673     my ($status, $message) = record_ffq_prev_deferred();
1674     if ($status eq 'deferred' || $status eq 'exists') {
1675     } else {
1676         snag $status, "could not record ffq-prev: $message";
1677         snags_maybe_bail();
1678     }
1679 }
1680
1681 sub ffq_prev_info () {
1682     bail_if_rebasing();
1683     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1684     my ($status, $message, $current, $ffq_prev, $gdrlast)
1685         = ffq_prev_branchinfo();
1686     if ($status ne 'branch') {
1687         snag $status, "could not check ffq-prev: $message";
1688         snags_maybe_bail();
1689     }
1690     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1691     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1692 }
1693
1694 sub stitch ($$$$$) {
1695     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1696
1697     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1698
1699     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1700         my $differs = get_differs $old_head, $ffq_prev_commitish;
1701         unless ($differs & ~D_PAT_ADD) {
1702             # ffq-prev is ahead of us, and the only tree changes it has
1703             # are possibly addition of things in debian/patches/.
1704             # Just wind forwards rather than making a pointless pseudomerge.
1705             push @deferred_updates,
1706                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1707             update_head_checkout $old_head, $ffq_prev_commitish,
1708                 "stitch (fast forward)";
1709             return;
1710         }
1711     }
1712     fresh_workarea();
1713     # We make pseudomerges with L as the contributing parent.
1714     # This makes git rev-list --first-parent work properly.
1715     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1716         'Declare fast forward / record previous work',
1717         "[git-debrebase pseudomerge: $prose]",
1718     ];
1719     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1720     update_head $old_head, $new_head, "stitch: $prose";
1721 }
1722
1723 sub do_stitch ($;$) {
1724     my ($prose, $unclean) = @_;
1725
1726     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1727     if (!$ffq_prev_commitish) {
1728         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1729         return;
1730     }
1731     my $dangling_head = get_head();
1732
1733     keycommits $dangling_head, $unclean,$unclean,$unclean;
1734     snags_maybe_bail();
1735
1736     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1737 }
1738
1739 sub upstream_commitish_search ($$) {
1740     my ($upstream_version, $tried) = @_;
1741     # todo: at some point maybe use git-deborig to do this
1742     foreach my $tagpfx ('', 'v', 'upstream/') {
1743         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1744         my $new_upstream = git_get_ref "refs/tags/$tag";
1745         push @$tried, $tag;
1746         return $new_upstream if length $new_upstream;
1747     }
1748 }
1749
1750 sub resolve_upstream_version ($$) {
1751     my ($new_upstream, $upstream_version) = @_;
1752
1753     if (!defined $new_upstream) {
1754         my @tried;
1755         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1756         if (!length $new_upstream) {
1757             fail "Could not determine appropriate upstream commitish.\n".
1758                 " (Tried these tags: @tried)\n".
1759                 " Check version, and specify upstream commitish explicitly.";
1760         }
1761     }
1762     $new_upstream = git_rev_parse $new_upstream;
1763
1764     return $new_upstream;
1765 }
1766
1767 sub cmd_new_upstream () {
1768     # automatically and unconditionally launders before rebasing
1769     # if rebase --abort is used, laundering has still been done
1770
1771     my %pieces;
1772
1773     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1774
1775     # parse args - low commitment
1776     my $spec_version = shift @ARGV;
1777     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1778     fail "bad version number \`$spec_version'" unless defined $new_version;
1779     if ($new_version->is_native()) {
1780         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1781     }
1782
1783     my $new_upstream = shift @ARGV;
1784     my $new_upstream_version = upstreamversion  $new_version;
1785     $new_upstream =
1786         resolve_upstream_version $new_upstream, $new_upstream_version;
1787
1788     record_ffq_auto();
1789
1790     my $piece = sub {
1791         my ($n, @x) = @_; # may be ''
1792         my $pc = $pieces{$n} //= {
1793             Name => $n,
1794             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1795         };
1796         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1797         $pc;
1798     };
1799
1800     my @newpieces;
1801     my $newpiece = sub {
1802         my ($n, @x) = @_; # may be ''
1803         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1804         push @newpieces, $pc;
1805     };
1806
1807     $newpiece->('',
1808         OldIx => 0,
1809         New => $new_upstream,
1810     );
1811     while (@ARGV && $ARGV[0] !~ m{^-}) {
1812         my $n = shift @ARGV;
1813
1814         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1815             unless @ARGV && $ARGV[0] !~ m{^-};
1816
1817         my $c = git_rev_parse shift @ARGV;
1818         die unless $n =~ m/^$extra_orig_namepart_re$/;
1819         $newpiece->($n, New => $c);
1820     }
1821
1822     # now we need to investigate the branch this generates the
1823     # laundered version but we don't switch to it yet
1824     my $old_head = get_head();
1825     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1826
1827     my $old_bw_cl = classify $old_bw;
1828     my $old_anchor_cl = classify $old_anchor;
1829     my $old_upstream;
1830     if (!$old_anchor_cl->{OrigParents}) {
1831         snag 'anchor-treated',
1832             'old anchor is recognised due to --anchor, cannot check upstream';
1833     } else {
1834         $old_upstream = parsecommit
1835             $old_anchor_cl->{OrigParents}[0]{CommitId};
1836         $piece->('', Old => $old_upstream->{CommitId});
1837     }
1838
1839     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1840         if ($old_upstream->{Msg} =~
1841  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1842            ) {
1843             my @oldpieces = (split / /, $1);
1844             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1845             if ($old_n_parents != @oldpieces &&
1846                 $old_n_parents != @oldpieces + 1) {
1847                 snag 'upstream-confusing', sprintf
1848                     "previous upstream combine %s".
1849                     " mentions %d pieces (each implying one parent)".
1850                     " but has %d parents".
1851                     " (one per piece plus maybe a previous combine)",
1852                     $old_upstream->{CommitId},
1853                     (scalar @oldpieces),
1854                     $old_n_parents;
1855             } elsif ($oldpieces[0] ne '.') {
1856                 snag 'upstream-confusing', sprintf
1857                     "previous upstream combine %s".
1858                     " first piece is not \`.'",
1859                     $oldpieces[0];
1860             } else {
1861                 $oldpieces[0] = '';
1862                 foreach my $i (0..$#oldpieces) {
1863                     my $n = $oldpieces[$i];
1864                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1865                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1866                 }
1867             }
1868         } else {
1869             snag 'upstream-confusing',
1870                 "previous upstream $old_upstream->{CommitId} is from".
1871                " git-debrebase but not an \`upstream-combine' commit";
1872         }
1873     }
1874
1875     foreach my $pc (values %pieces) {
1876         if (!$old_upstream) {
1877             # we have complained already
1878         } elsif (!$pc->{Old}) {
1879             snag 'upstream-new-piece',
1880                 "introducing upstream piece \`$pc->{Name}'";
1881         } elsif (!$pc->{New}) {
1882             snag 'upstream-rm-piece',
1883                 "dropping upstream piece \`$pc->{Name}'";
1884         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1885             snag 'upstream-not-ff',
1886                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1887         }
1888     }
1889
1890     printdebug "%pieces = ", (dd \%pieces), "\n";
1891     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1892
1893     snags_maybe_bail();
1894
1895     my $new_bw;
1896
1897     fresh_workarea();
1898     in_workarea sub {
1899         my @upstream_merge_parents;
1900
1901         if (!any_snags()) {
1902             push @upstream_merge_parents, $old_upstream->{CommitId};
1903         }
1904
1905         foreach my $pc (@newpieces) { # always has '' first
1906             if ($pc->{Name}) {
1907                 read_tree_subdir $pc->{Name}, $pc->{New};
1908             } else {
1909                 runcmd @git, qw(read-tree), $pc->{New};
1910             }
1911             push @upstream_merge_parents, $pc->{New};
1912         }
1913
1914         # index now contains the new upstream
1915
1916         if (@newpieces > 1) {
1917             # need to make the upstream subtree merge commit
1918             $new_upstream = make_commit \@upstream_merge_parents,
1919                 [ "Combine upstreams for $new_upstream_version",
1920  ("[git-debrebase upstream-combine . ".
1921  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1922  ": new upstream]"),
1923                 ];
1924         }
1925
1926         # $new_upstream is either the single upstream commit, or the
1927         # combined commit we just made.  Either way it will be the
1928         # "upstream" parent of the anchor merge.
1929
1930         read_tree_subdir 'debian', "$old_bw:debian";
1931
1932         # index now contains the anchor merge contents
1933         $new_bw = make_commit [ $old_bw, $new_upstream ],
1934             [ "Update to upstream $new_upstream_version",
1935  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1936             ];
1937
1938         my $clogsignoff = cmdoutput qw(git show),
1939             '--pretty=format:%an <%ae>  %aD',
1940             $new_bw;
1941
1942         # Now we have to add a changelog stanza so the Debian version
1943         # is right.
1944         die if unlink "debian";
1945         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1946         unlink "debian/changelog" or $!==ENOENT or die $!;
1947         mkdir "debian" or die $!;
1948         open CN, ">", "debian/changelog" or die $!;
1949         my $oldclog = git_cat_file ":debian/changelog";
1950         $oldclog =~ m/^($package_re) \(\S+\) / or
1951             fail "cannot parse old changelog to get package name";
1952         my $p = $1;
1953         print CN <<END, $oldclog or die $!;
1954 $p ($new_version) UNRELEASED; urgency=medium
1955
1956   * Update to new upstream version $new_upstream_version.
1957
1958  -- $clogsignoff
1959
1960 END
1961         close CN or die $!;
1962         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1963
1964         # Now we have the final new breakwater branch in the index
1965         $new_bw = make_commit [ $new_bw ],
1966             [ "Update changelog for new upstream $new_upstream_version",
1967               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1968             ];
1969     };
1970
1971     # we have constructed the new breakwater. we now need to commit to
1972     # the laundering output, because git-rebase can't easily be made
1973     # to make a replay list which is based on some other branch
1974
1975     update_head_postlaunder $old_head, $old_laundered_tip,
1976         'launder for new upstream';
1977
1978     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1979     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1980         "debrebase new-upstream $new_version: rebase";
1981     runcmd @cmd;
1982     # now it's for the user to sort out
1983 }
1984
1985 sub cmd_record_ffq_prev () {
1986     badusage "no arguments allowed" if @ARGV;
1987     my ($status, $msg) = record_ffq_prev_deferred();
1988     if ($status eq 'exists' && $opt_noop_ok) {
1989         print "Previous head already recorded\n" or die $!;
1990     } elsif ($status eq 'deferred') {
1991         run_deferred_updates 'record-ffq-prev';
1992     } else {
1993         fail "Could not preserve: $msg";
1994     }
1995 }
1996
1997 sub cmd_anchor () {
1998     badusage "no arguments allowed" if @ARGV;
1999     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2000     print "$bw\n" or die $!;
2001 }
2002
2003 sub cmd_breakwater () {
2004     badusage "no arguments allowed" if @ARGV;
2005     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2006     print "$bw\n" or die $!;
2007 }
2008
2009 sub cmd_status () {
2010     badusage "no arguments allowed" if @ARGV;
2011
2012     # todo: gdr status should print divergence info
2013     # todo: gdr status should print upstream component(s) info
2014     # todo: gdr should leave/maintain some refs with this kind of info ?
2015
2016     my $oldest = { Badness => 0 };
2017     my $newest;
2018     my $note = sub {
2019         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2020         if ($oldest->{Badness} < $badness) {
2021             $oldest = $newest = undef;
2022         }
2023         $oldest = {
2024                    Badness => $badness,
2025                    CommitId => $cl->{CommitId},
2026                    OurMsg => $ourmsg,
2027                    KcMsg => $kcmsg,
2028                   };
2029         $newest //= $oldest;
2030     };
2031     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2032         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2033         sub { $note->(2, 'branch is unlaundered', @_); },
2034         sub { $note->(3, 'branch needs laundering', @_); },
2035         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2036
2037     my $prcommitinfo = sub {
2038         my ($cid) = @_;
2039         flush STDOUT or die $!;
2040         runcmd @git, qw(--no-pager log -n1),
2041             '--pretty=format:    %h %s%n',
2042             $cid;
2043     };
2044
2045     print "current branch contents, in git-debrebase terms:\n";
2046     if (!$oldest->{Badness}) {
2047         print "  branch is laundered\n";
2048     } else {
2049         print "  $oldest->{OurMsg}\n";
2050         my $printed = '';
2051         foreach my $info ($oldest, $newest) {
2052             my $cid = $info->{CommitId};
2053             next if $cid eq $printed;
2054             $printed = $cid;
2055             print "  $info->{KcMsg}\n";
2056             $prcommitinfo->($cid);
2057         }
2058     }
2059
2060     my $prab = sub {
2061         my ($cid, $what) = @_;
2062         if (!defined $cid) {
2063             print "  $what is not well-defined\n";
2064         } else {
2065             print "  $what\n";
2066             $prcommitinfo->($cid);
2067         }
2068     };
2069     print "key git-debrebase commits:\n";
2070     $prab->($anchor, 'anchor');
2071     $prab->($bw, 'breakwater');
2072
2073     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2074         ffq_prev_branchinfo();
2075
2076     print "branch and ref status, in git-debrebase terms:\n";
2077     if ($ffq_msg) {
2078         print "  $ffq_msg\n";
2079     } else {
2080         $ffq_prev = git_get_ref $ffq_prev;
2081         $gdrlast = git_get_ref $gdrlast;
2082         if ($ffq_prev) {
2083             print "  unstitched; previous tip was:\n";
2084             $prcommitinfo->($ffq_prev);
2085         } elsif (!$gdrlast) {
2086             print "  stitched? (no record of git-debrebase work)\n";
2087         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2088             print "  stitched\n";
2089         } else {
2090             print "  not git-debrebase (diverged since last stitch)\n"
2091         }
2092     }
2093     print "you are currently rebasing\n" if currently_rebasing();
2094 }
2095
2096 sub cmd_stitch () {
2097     my $prose = 'stitch';
2098     getoptions("stitch",
2099                'prose=s', \$prose);
2100     badusage "no arguments allowed" if @ARGV;
2101     do_stitch $prose, 0;
2102 }
2103 sub cmd_prepush () { cmd_stitch(); }
2104
2105 sub cmd_quick () {
2106     badusage "no arguments allowed" if @ARGV;
2107     do_launder_head 'launder for git-debrebase quick';
2108     do_stitch 'quick';
2109 }
2110
2111 sub cmd_conclude () {
2112     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2113     if (!$ffq_prev_commitish) {
2114         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2115         return;
2116     }
2117     my $dangling_head = get_head();
2118
2119     badusage "no arguments allowed" if @ARGV;
2120     do_launder_head 'launder for git-debrebase quick';
2121     do_stitch 'quick';
2122 }
2123
2124 sub cmd_scrap () {
2125     if (currently_rebasing()) {
2126         runcmd @git, qw(rebase --abort);
2127     }
2128     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2129     if (!$ffq_prev_commitish) {
2130         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2131         finish 0;
2132     }
2133     my $scrapping_head = get_head();
2134     badusage "no arguments allowed" if @ARGV;
2135     push @deferred_updates,
2136         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2137         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2138     snags_maybe_bail();
2139     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2140 }
2141
2142 sub make_patches_staged ($) {
2143     my ($head) = @_;
2144     # Produces the patches that would result from $head if it were
2145     # laundered.
2146     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2147     fresh_workarea();
2148     in_workarea sub {
2149         gbp_pq_export 'bw', $secret_bw, $secret_head;
2150     };
2151 }
2152
2153 sub make_patches ($) {
2154     my ($head) = @_;
2155     keycommits $head, 0, \&snag;
2156     make_patches_staged $head;
2157     my $out;
2158     in_workarea sub {
2159         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2160         runcmd @git, qw(read-tree), $head;
2161         read_tree_subdir 'debian/patches', $ptree;
2162         $out = make_commit [$head], [
2163             'Commit patch queue (exported by git-debrebase)',
2164             '[git-debrebase: export and commit patches]',
2165         ];
2166     };
2167     return $out;
2168 }
2169
2170 sub cmd_make_patches () {
2171     my $opt_quiet_would_amend;
2172     getoptions("make-patches",
2173                'quiet-would-amend!', \$opt_quiet_would_amend);
2174     badusage "no arguments allowed" if @ARGV;
2175     bail_if_rebasing();
2176     my $old_head = get_head();
2177     my $new = make_patches $old_head;
2178     my $d = get_differs $old_head, $new;
2179     if ($d == 0) {
2180         fail "No (more) patches to export." unless $opt_noop_ok;
2181         return;
2182     } elsif ($d == D_PAT_ADD) {
2183         snags_maybe_bail();
2184         update_head_checkout $old_head, $new, 'make-patches';
2185     } else {
2186         print STDERR failmsg
2187             "Patch export produced patch amendments".
2188             " (abandoned output commit $new).".
2189             "  Try laundering first."
2190             unless $opt_quiet_would_amend;
2191         finish 7;
2192     }
2193 }
2194
2195 sub cmd_convert_from_gbp () {
2196     badusage "want only 1 optional argument, the upstream git commitish"
2197         unless @ARGV<=1;
2198
2199     my $clogp = parsechangelog();
2200     my $version = $clogp->{'Version'}
2201         // die "missing Version from changelog";
2202
2203     my ($upstream_spec) = @ARGV;
2204
2205     my $upstream_version = upstreamversion $version;
2206     my $upstream =
2207         resolve_upstream_version($upstream_spec, $upstream_version);
2208
2209     my $old_head = get_head();
2210
2211     my $upsdiff = get_differs $upstream, $old_head;
2212     if ($upsdiff & D_UPS) {
2213         runcmd @git, qw(--no-pager diff --stat),
2214             $upstream, $old_head,
2215             qw( -- :!/debian :/);
2216         fail <<END;
2217 upstream ($upstream_spec) and HEAD are not
2218 identical in upstream files.  See diffstat above, or run
2219   git diff $upstream_spec HEAD -- :!/debian :/
2220 END
2221     }
2222
2223     if (!is_fast_fwd $upstream, $old_head) {
2224         snag 'upstream-not-ancestor',
2225             "upstream ($upstream) is not an ancestor of HEAD";
2226     } else {
2227         my $wrong = cmdoutput
2228             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2229              qw(-- :/ :!/debian));
2230         if (length $wrong) {
2231             snag 'unexpected-upstream-changes',
2232                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2233             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2234         }
2235     }
2236
2237     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2238         snag 'upstream-has-debian',
2239             "upstream ($upstream) contains debian/ directory";
2240     }
2241
2242     my $previous_dgit_view = eval {
2243         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2244         my ($lvsn, $suite);
2245         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2246             my ($stz, $desc) = @_;
2247             no warnings qw(exiting);
2248             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2249             next unless $stz->{Date};
2250             next unless $stz->{Distribution} ne 'UNRELEASED';
2251             $lvsn = $stz->{Version};
2252             $suite = $stz->{Distribution};
2253             last;
2254         };
2255         die "neither of the first two changelog entries are released\n"
2256             unless defined $lvsn;
2257         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2258         my $mtag_pat = debiantag_maintview $lvsn, '*';
2259         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2260             $mtag_pat;
2261         die "could not find suitable maintainer view tag $mtag_pat\n"
2262             unless $mtag_pat =~ m{/};
2263         is_fast_fwd $mtag, 'HEAD' or
2264             die "HEAD is not FF from maintainer tag $mtag!";
2265         my $dtag = "archive/$mtag";
2266         is_fast_fwd $mtag, $dtag or
2267             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2268         print "will stitch in dgit view, $dtag\n";
2269         git_rev_parse $dtag;
2270     };
2271     if (!$previous_dgit_view) {
2272         $@ =~ s/^\n+//;
2273         chomp $@;
2274         print STDERR "cannot stitch in dgit view: $@\n";
2275     }
2276
2277     snags_maybe_bail_early();
2278
2279     my $work;
2280
2281     fresh_workarea();
2282     in_workarea sub {
2283         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2284         # make a branch out of the patch queue - we'll want this in a mo
2285         runcmd qw(gbp pq import);
2286         # strip the patches out
2287         runcmd @git, qw(checkout -q gdr-internal~0);
2288         rm_subdir_cached 'debian/patches';
2289         $work = make_commit ['HEAD'], [
2290  'git-debrebase convert-from-gbp: drop patches from tree',
2291  'Delete debian/patches, as part of converting to git-debrebase format.',
2292  '[git-debrebase convert-from-gbp: drop patches from tree]'
2293                               ];
2294         # make the anchor merge
2295         # the tree is already exactly right
2296         $work = make_commit [$work, $upstream], [
2297  'git-debrebase import: declare upstream',
2298  'First breakwater merge.',
2299  '[git-debrebase anchor: declare upstream]'
2300                               ];
2301
2302         # rebase the patch queue onto the new breakwater
2303         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2304         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2305         $work = git_rev_parse 'HEAD';
2306
2307         if ($previous_dgit_view) {
2308             $work = make_commit [$work, $previous_dgit_view], [
2309  'git-debrebase import: declare ff from dgit archive view',
2310  '[git-debrebase pseudomerge: import-from-gbp]',
2311             ];
2312         }
2313     };
2314
2315     ffq_check $work;
2316     snags_maybe_bail();
2317     update_head_checkout $old_head, $work, 'convert-from-gbp';
2318 }
2319
2320 sub cmd_convert_to_gbp () {
2321     badusage "no arguments allowed" if @ARGV;
2322     my $head = get_head();
2323     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2324     keycommits $head, 0;
2325     my $out;
2326     make_patches_staged $head;
2327     in_workarea sub {
2328         $out = make_commit ['HEAD'], [
2329             'Commit patch queue (converted from git-debrebase format)',
2330             '[git-debrebase convert-to-gbp: commit patches]',
2331         ];
2332     };
2333     if (defined $ffq) {
2334         push @deferred_updates, "delete $ffq";
2335         push @deferred_updates, "delete $gdrlast";
2336     }
2337     snags_maybe_bail();
2338     update_head_checkout $head, $out, "convert to gbp (v0)";
2339     print <<END or die $!;
2340 git-debrebase: converted to git-buildpackage branch format
2341 git-debrebase: WARNING: do not now run "git-debrebase" any more
2342 git-debrebase: WARNING: doing so would drop all upstream patches!
2343 END
2344 }
2345
2346 sub cmd_convert_from_dgit_view () {
2347     my $clogp = parsechangelog();
2348
2349     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2350     my $do_origs = 1;
2351     my $do_tags = 1;
2352     my $always = 0;
2353     my $diagnose = 0;
2354
2355     getoptions("convert-from-dgit-view",
2356                'diagnose!', \$diagnose,
2357                'build-products-dir:s', \$bpd,
2358                'origs!', \$do_origs,
2359                'tags!', \$do_tags,
2360                'always-convert-anyway!', \$always);
2361     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2362
2363     my @upstreams;
2364
2365     if (@ARGV) {
2366         my $spec = shift @ARGV;
2367         my $commit = git_rev_parse "$spec^{commit}";
2368         push @upstreams, { Commit => $commit,
2369                            Source => "$ARGV[0], from command line",
2370                            Only => 1,
2371                          };
2372     }
2373
2374     my $head = get_head();
2375
2376     if (!$always) {
2377         my $troubles = 0;
2378         my $trouble = sub { $troubles++; };
2379         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2380         printdebug "troubles=$troubles\n";
2381         if (!$troubles) {
2382             print STDERR <<END;
2383 $us: Branch already seems to be in git-debrebase format!
2384 $us: --always-convert-anyway would do the conversion operation anyway
2385 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2386 END
2387             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2388             finish 0;
2389         }
2390     }
2391
2392     snags_maybe_bail_early();
2393
2394     my $version = upstreamversion $clogp->{Version};
2395     print STDERR "Considering possible commits corresponding to upstream:\n";
2396
2397     if (!@upstreams) {
2398         if ($do_tags) {
2399             my @tried;
2400             my $ups_tag = upstream_commitish_search $version, \@tried;
2401             if ($ups_tag) {
2402                 my $this = "git tag $tried[-1]";
2403                 push @upstreams, { Commit => $ups_tag,
2404                                    Source => $this,
2405                                  };
2406             } else {
2407                 printf STDERR
2408                     " git tag: no suitable tag found (tried %s)\n",
2409                     "@tried";
2410             }
2411         }
2412         if ($do_origs) {
2413             my $p = $clogp->{'Source'};
2414             # we do a quick check to see if there are plausible origs
2415             my $something=0;
2416             if (!opendir BPD, $bpd) {
2417                 die "$bpd: opendir: $!" unless $!==ENOENT;
2418             } else {
2419                 while ($!=0, my $f = readdir BPD) {
2420                     next unless is_orig_file_of_p_v $f, $p, $version;
2421                     printf STDERR
2422                         " orig: found what looks like a .orig, %s\n",
2423                         "$bpd/$f";
2424                     $something=1;
2425                     last;
2426                 }
2427                 die "read $bpd: $!" if $!;
2428                 closedir BPD;
2429             }
2430             if ($something) {
2431                 my $tree = cmdoutput
2432                     @dgit, qw(--build-products-dir), $bpd,
2433                     qw(print-unapplied-treeish);
2434                 fresh_workarea();
2435                 in_workarea sub {
2436                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2437                     rm_subdir_cached 'debian';
2438                     $tree = cmdoutput @git, qw(write-tree);
2439                     my $ups_synth = make_commit [], [ <<END, <<END,
2440 Import effective orig tree for upstream version $version
2441 END
2442 This includes the contents of the .orig(s), minus any debian/ directory.
2443
2444 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2445 END
2446                                                     ];
2447                     push @upstreams, { Commit => $ups_synth,
2448                                        Source => "orig(s) imported via dgit",
2449                                      };
2450                 }
2451             } else {
2452                 printf STDERR
2453                     " orig: no suitable origs found (looked for %s in %s)\n",
2454                     "${p}_".(stripeoch $version)."...", $bpd;
2455             }
2456         }
2457     }
2458
2459     my $some_patches = stat_exists 'debian/patches/series';
2460
2461     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2462
2463     my $result;
2464     foreach my $u (@upstreams) {
2465         my $work = $head;
2466         fresh_workarea();
2467         in_workarea sub {
2468             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2469             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2470             runcmd @git, qw(clean -xdff);
2471             runcmd @git, qw(checkout), $head, qw(-- debian);
2472             if ($some_patches) {
2473                 rm_subdir_cached 'debian/patches';
2474                 $work = make_commit [ $work ], [
2475  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2476  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2477  "to git-debrebase format.  Upstream changes will appear as commits.",
2478  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2479                                            ];
2480             }
2481             $work = make_commit [ $work, $u->{Commit} ], [
2482  'git-debrebase convert-from-dgit-view: declare upstream',
2483  '(Re)constructed breakwater merge.',
2484  '[git-debrebase anchor: declare upstream]'
2485                                                          ];
2486             runcmd @git, qw(checkout --quiet -b mk), $work;
2487             if ($some_patches) {
2488                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2489                 runcmd @git, qw(reset --quiet);
2490                 my @gbp_cmd = (qw(gbp pq import));
2491                 if (!$diagnose) {
2492                     my $gbp_err = "../gbp-pq-err";
2493                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2494                 }
2495                 my $r = system @gbp_cmd;
2496                 if ($r) {
2497                     printf STDERR
2498                         " %s: couldn't apply patches: gbp pq %s",
2499                         $u->{Source}, waitstatusmsg();
2500                     return;
2501                 }
2502             }
2503             my $work = git_rev_parse qw(HEAD);
2504             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2505             if (length $diffout) {
2506                 print STDERR
2507                     " $u->{Source}: applying patches gives different tree\n";
2508                 print STDERR $diffout if $diagnose;
2509                 return;
2510             }
2511             # OMG!
2512             $u->{Result} = $work;
2513             $result = $u;
2514         };
2515         last if $result;
2516     }
2517
2518     if (!$result) {
2519         fail <<END;
2520 Could not find or construct a suitable upstream commit.
2521 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2522 upstream commmit explicitly or provide suitable origs.
2523 END
2524     }
2525
2526     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2527
2528     ffq_check $result->{Result};
2529     snags_maybe_bail();
2530     update_head_checkout $head, $result->{Result},
2531         'convert-from-dgit-view';
2532 }
2533
2534 sub cmd_downstream_rebase_launder_v0 () {
2535     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2536     my ($base) = @ARGV;
2537     $base = git_rev_parse $base;
2538     my $old_head = get_head();
2539     my $current = $old_head;
2540     my $topmost_keep;
2541     for (;;) {
2542         if ($current eq $base) {
2543             $topmost_keep //= $current;
2544             print " $current BASE stop\n";
2545             last;
2546         }
2547         my $cl = classify $current;
2548         print " $current $cl->{Type}";
2549         my $keep = 0;
2550         my $p0 = $cl->{Parents}[0]{CommitId};
2551         my $next;
2552         if ($cl->{Type} eq 'Pseudomerge') {
2553             print " ^".($cl->{Contributor}{Ix}+1);
2554             $next = $cl->{Contributor}{CommitId};
2555         } elsif ($cl->{Type} eq 'AddPatches' or
2556                  $cl->{Type} eq 'Changelog') {
2557             print " strip";
2558             $next = $p0;
2559         } else {
2560             print " keep";
2561             $next = $p0;
2562             $keep = 1;
2563         }
2564         print "\n";
2565         if ($keep) {
2566             $topmost_keep //= $current;
2567         } else {
2568             die "to-be stripped changes not on top of the branch\n"
2569                 if $topmost_keep;
2570         }
2571         $current = $next;
2572     }
2573     if ($topmost_keep eq $old_head) {
2574         print "unchanged\n";
2575     } else {
2576         print "updating to $topmost_keep\n";
2577         update_head_checkout
2578             $old_head, $topmost_keep,
2579             'downstream-rebase-launder-v0';
2580     }
2581 }
2582
2583 getoptions_main
2584           ("bad options\n",
2585            "D+" => \$debuglevel,
2586            'noop-ok', => \$opt_noop_ok,
2587            'f=s' => \@snag_force_opts,
2588            'anchor=s' => \@opt_anchors,
2589            '--dgit=s' => \($dgit[0]),
2590            'force!',
2591            '-i:s' => sub {
2592                my ($opt,$val) = @_;
2593                badusage "git-debrebase: no cuddling to -i for git-rebase"
2594                    if length $val;
2595                die if $opt_defaultcmd_interactive; # should not happen
2596                $opt_defaultcmd_interactive = [ qw(-i) ];
2597                # This access to @ARGV is excessive familiarity with
2598                # Getopt::Long, but there isn't another sensible
2599                # approach.  '-i=s{0,}' does not work with bundling.
2600                push @$opt_defaultcmd_interactive, @ARGV;
2601                @ARGV=();
2602            },
2603            'help' => sub { print $usage_message or die $!; finish 0; },
2604            );
2605
2606 initdebug('git-debrebase ');
2607 enabledebug if $debuglevel;
2608
2609 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2610 chdir $toplevel or die "chdir $toplevel: $!";
2611
2612 $rd = fresh_playground "$playprefix/misc";
2613
2614 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2615
2616 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2617     defaultcmd_rebase();
2618 } else {
2619     my $cmd = shift @ARGV;
2620     my $cmdfn = $cmd;
2621     $cmdfn =~ y/-/_/;
2622     $cmdfn = ${*::}{"cmd_$cmdfn"};
2623
2624     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2625     $cmdfn->();
2626 }
2627
2628 finish 0;