git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Debian::Dgit qw(:DEFAULT :playground);
 108 setup_sigwarn();
 109
 110 use Memoize;
 111 use Carp;
 112 use POSIX;
 113 use Data::Dumper;
 114 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 115
 116 sub badusage ($) {
 117     my ($m) = @_;
 118     die "bad usage: $m\n";
 119 }
 120
 121 sub cfg ($) {
 122     my ($k) = @_;
 123     $/ = "\0";
 124     my @cmd = qw(git config -z);
 125     push @cmd, qw(--get-all) if wantarray;
 126     push @cmd, $k;
 127     my $out = cmdoutput @cmd;
 128     return split /\0/, $out;
 129 }
 130
 131 memoize('cfg');
 132
 133 sub get_commit ($) {
 134     my ($objid) = @_;
 135     my $data = git_cat_file $objid, 'commit';
 136     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 137     return ($`,$');
 138 }
 139
 140 sub D_UPS ()      { 0x02; } # upstream files
 141 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 142 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 143 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 144 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 145 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 146
 147 our $playprefix = 'debrebase';
 148 our $rd;
 149 our $workarea;
 150
 151 our @git = qw(git);
 152
 153 sub in_workarea ($) {
 154     my ($sub) = @_;
 155     changedir $workarea;
 156     my $r = eval { $sub->(); };
 157     changedir $maindir;
 158 }
 159
 160 sub fresh_workarea () {
 161     $workarea = fresh_playground "$playprefix/work";
 162     in_workarea sub { playtree_setup };
 163 }
 164
 165 sub get_differs ($$) {
 166     my ($x,$y) = @_;
 167     # This resembles quiltify_trees_differ, in dgit, a bit.
 168     # But we don't care about modes, or dpkg-source-unrepresentable
 169     # changes, and we don't need the plethora of different modes.
 170     # Conversely we need to distinguish different kinds of changes to
 171     # debian/ and debian/patches/.
 172
 173     my $differs = 0;
 174
 175     my $rundiff = sub {
 176         my ($opts, $limits, $fn) = @_;
 177         my @cmd = (@git, qw(diff-tree -z --no-renames));
 178         push @cmd, @$opts;
 179         push @cmd, "$_:" foreach $x, $y;
 180         push @cmd, @$limits;
 181         my $diffs = cmdoutput @cmd;
 182         foreach (split /\0/, $diffs) { $fn->(); }
 183     };
 184
 185     $rundiff->([qw(--name-only)], [], sub {
 186         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 187     });
 188
 189     if ($differs & DS_DEB) {
 190         $differs &= ~DS_DEB;
 191         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 192             $differs |=
 193                 m{^debian/patches/}      ? D_PAT_OTH  :
 194                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 195                                            D_DEB_OTH;
 196         });
 197         die "mysterious debian changes $x..$y"
 198             unless $differs & (D_PAT_OTH|DS_DEB);
 199     }
 200
 201     if ($differs & D_PAT_OTH) {
 202         my $mode;
 203         $differs &= ~D_PAT_OTH;
 204         my $pat_oth = sub {
 205             $differs |= D_PAT_OTH;
 206             no warnings qw(exiting);  last;
 207         };
 208         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 209             no warnings qw(exiting);
 210             if (!defined $mode) {
 211                 $mode = $_;  next;
 212             }
 213             die unless s{^debian/patches/}{};
 214             my $ok;
 215             if ($mode eq 'A' && !m/\.series$/s) {
 216                 $ok = 1;
 217             } elsif ($mode eq 'M' && $_ eq 'series') {
 218                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 219                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 220                 chomp $x_s;  $x_s .= "\n";
 221                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 222             } else {
 223                 # nope
 224             }
 225             $mode = undef;
 226             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 227         });
 228         die "mysterious debian/patches changes $x..$y"
 229             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 230     }
 231
 232     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 233
 234     return $differs;
 235 }
 236
 237 sub commit_pr_info ($) {
 238     my ($r) = @_;
 239     return Data::Dumper->dump([$r], [qw(commit)]);
 240 }
 241
 242 sub calculate_committer_authline () {
 243     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 244         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 245     my ($h,$m) = get_commit $c;
 246     $h =~ m/^committer .*$/m or confess "($h) ?";
 247     return $&;
 248 }
 249
 250 # classify returns an info hash like this
 251 #   CommitId => $objid
 252 #   Hdr => # commit headers, including 1 final newline
 253 #   Msg => # commit message (so one newline is dropped)
 254 #   Tree => $treeobjid
 255 #   Type => (see below)
 256 #   Parents = [ {
 257 #       Ix => $index # ie 0, 1, 2, ...
 258 #       CommitId
 259 #       Differs => return value from get_differs
 260 #       IsOrigin
 261 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 262 #     } ...]
 263 #   NewMsg => # commit message, but with any [dgit import ...] edited
 264 #             # to say "[was: ...]"
 265 #
 266 # Types:
 267 #   Packaging
 268 #   Changelog
 269 #   Upstream
 270 #   AddPatches
 271 #   Mixed
 272 #   Unknown
 273 #
 274 #   Pseudomerge
 275 #     has additional entres in classification result
 276 #       Overwritten = [ subset of Parents ]
 277 #       Contributor = $the_remaining_Parent
 278 #
 279 #   DgitImportUnpatched
 280 #     has additional entry in classification result
 281 #       OrigParents = [ subset of Parents ]
 282 #
 283 #   BreakwaterUpstreamMerge
 284 #     has additional entry in classification result
 285 #       OrigParents = [ subset of Parents ]
 286
 287 sub classify ($) {
 288     my ($objid) = @_;
 289
 290     my ($h,$m) = get_commit $objid;
 291
 292     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 293     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 294     my @p;
 295
 296     my $r = {
 297         CommitId => $objid,
 298         Hdr => $h,
 299         Msg => $m,
 300         Tree => $t,
 301         Parents => \@p,
 302     };
 303
 304     foreach my $ph (@ph) {
 305         push @p, {
 306             Ix => $#p,
 307             CommitId => $ph,
 308             Differs => (get_differs $ph, $t),
 309         };
 310     }
 311
 312     printdebug "classify $objid \$t=$t \@p",
 313         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 314         "\n";
 315
 316     my $classify = sub {
 317         my ($type, @rest) = @_;
 318         $r = { %$r, Type => $type, @rest };
 319         if ($debuglevel) {
 320             my $dd = new Data::Dumper [ $r ];
 321             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 322             printdebug " = $type ".(Dump $dd)."\n";
 323         }
 324         return $r;
 325     };
 326     my $unknown = sub {
 327         my ($why) = @_;
 328         $r = { %$r, Type => qw(Unknown) };
 329         printdebug " ** Unknown\n";
 330         return $r;
 331     };
 332
 333     if (@p == 1) {
 334         my $d = $r->{Parents}[0]{Differs};
 335         if ($d == D_PAT_ADD) {
 336             return $classify->(qw(AddPatches));
 337         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 338             return $unknown->("edits debian/patches");
 339         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 340             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 341             if ($ty eq 'tree') {
 342                 if ($d == D_DEB_CLOG) {
 343                     return $classify->(qw(Changelog));
 344                 } else {
 345                     return $classify->(qw(Packaging));
 346                 }
 347             } elsif ($ty eq 'missing') {
 348                 return $classify->(qw(BreakwaterStart));
 349             } else {
 350                 return $unknown->("parent's debian is not a directory");
 351             }
 352         } elsif ($d == D_UPS) {
 353             return $classify->(qw(Upstream));
 354         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 355             return $classify->(qw(Mixed));
 356         } elsif ($d == 0) {
 357             return $unknown->("no changes");
 358         } else {
 359             confess "internal error $objid ?";
 360         }
 361     }
 362     if (!@p) {
 363         return $unknown->("origin commit");
 364     }
 365
 366     my @identical = grep { !$_->{Differs} } @p;
 367     if (@p == 2 && @identical == 1) {
 368         my @overwritten = grep { $_->{Differs} } @p;
 369         confess "internal error $objid ?" unless @overwritten==1;
 370         return $classify->(qw(Pseudomerge),
 371                            Overwritten => $overwritten[0],
 372                            Contributor => $identical[0]);
 373     }
 374     if (@p == 2 && @identical == 2) {
 375         my @bytime = nsort_by {
 376             my ($ph,$pm) = get_commit $_->{CommitId};
 377             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 378             $1;
 379         } @p;
 380         return $classify->(qw(Pseudomerge),
 381                            SubType => qw(Ambiguous),
 382                            Overwritten => $bytime[0],
 383                            Contributor => $bytime[1]);
 384     }
 385     foreach my $p (@p) {
 386         my ($p_h, $p_m) = get_commit $p->{CommitId};
 387         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 388         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 389     }
 390     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 391     my $m2 = $m;
 392     if (!(grep { !$_->{IsOrigin} } @p) and
 393         (@orig_ps >= @p - 1) and
 394         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 395         $r->{NewMsg} = $m2;
 396         return $classify->(qw(DgitImportUnpatched),
 397                            OrigParents => \@orig_ps);
 398     }
 399
 400     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 401     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 402
 403     # How to decide about l/r ordering of breakwater merges ?  git
 404     # --topo-order prefers to expand 2nd parent first.  There's
 405     # already an easy rune to look for debian/ history anyway (git log
 406     # debian/) so debian breakwater branch should be 1st parent; that
 407     # way also there's also an easy rune to look for the upstream
 408     # patches (--topo-order).
 409
 410     # The above tells us which way *we* will generate them.  But we
 411     # might encounter ad-hoc breakwater merges generated manually,
 412     # which might be the other way around.  In principle, in some odd
 413     # situations, a breakwater merge might have two identical parents.
 414     # In that case we guess which way round it is (ie, which parent
 415     # has the upstream history).  The order of the 2-iteration loop
 416     # controls which guess we make.
 417
 418     foreach my $prevbrw (qw(0 1)) {
 419         if (@p == 2 &&
 420             !$haspatches &&
 421             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 422             !($p[$prevbrw]{Differs} & ~DS_DEB) &&
 423             !($p[!$prevbrw]{Differs} & ~D_UPS)) {
 424             return $classify->(qw(BreakwaterUpstreamMerge),
 425                                OrigParents => [ $p[!$prevbrw] ]);
 426         }
 427         # xxx multi-.orig upstreams
 428     }
 429
 430     return $unknown->("complex merge");
 431 }
 432
 433 sub walk ($;$$);
 434 sub walk ($;$$) {
 435     my ($input,
 436         $nogenerate,$report) = @_;
 437     # => ($tip, $breakwater_tip)
 438     # (or nothing, if $nogenerate)
 439
 440     # go through commits backwards
 441     # we generate two lists of commits to apply:
 442     # breakwater branch and upstream patches
 443     my (@brw_cl, @upp_cl, @processed);
 444     my %found;
 445     my $upp_limit;
 446     my @pseudomerges;
 447
 448     my $cl;
 449     my $xmsg = sub {
 450         my ($appendinfo) = @_;
 451         my $ms = $cl->{Msg};
 452         chomp $ms;
 453         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 454         return (Msg => $ms);
 455     };
 456     my $rewrite_from_here = sub {
 457         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 458         push @brw_cl, $sp_cl;
 459         push @processed, $sp_cl;
 460     };
 461     my $cur = $input;
 462
 463     my $prdelim = "";
 464     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 465
 466     my $prline = sub {
 467         return unless $report;
 468         print $report $prdelim, @_;
 469         $prdelim = "\n";
 470     };
 471
 472     my $bomb = sub { # usage: return $bomb->();
 473         print $report " Unprocessable" if $report;
 474         $prprdelim->();
 475         if ($nogenerate) {
 476             return (undef,undef);
 477         }
 478         die "commit $cur: Cannot cope with this commit";
 479     };
 480
 481     my $build;
 482     my $breakwater;
 483
 484     my $build_start = sub {
 485         my ($msg, $parent) = @_;
 486         $prline->(" $msg");
 487         $build = $parent;
 488         no warnings qw(exiting); last;
 489     };
 490
 491     for (;;) {
 492         $cl = classify $cur;
 493         my $ty = $cl->{Type};
 494         my $st = $cl->{SubType};
 495         $prline->("$cl->{CommitId} $cl->{Type}");
 496         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 497         push @processed, $cl;
 498         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 499         if ($ty eq 'AddPatches') {
 500             $cur = $p0;
 501             $rewrite_from_here->();
 502             next;
 503         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 504             push @brw_cl, $cl;
 505             $cur = $p0;
 506             next;
 507         } elsif ($ty eq 'BreakwaterStart') {
 508             $build_start->('FirstPackaging', $cur);
 509         } elsif ($ty eq 'Upstream') {
 510             push @upp_cl, $cl;
 511             $cur = $p0;
 512             next;
 513         } elsif ($ty eq 'Mixed') {
 514             my $queue = sub {
 515                 my ($q, $wh) = @_;
 516                 my $cls = { $cl, $xmsg->("split mixed commit: $wh part") };
 517                 push @$q, $cls;
 518             };
 519             $queue->(\@brw_cl, "debian");
 520             $queue->(\@upp_cl, "upstream");
 521             $rewrite_from_here->();
 522             $cur = $p0;
 523             next;
 524         } elsif ($ty eq 'Pseudomerge') {
 525             my $contrib = $cl->{Contributor}{CommitId};
 526             print $report " Contributor=$contrib" if $report;
 527             push @pseudomerges, $cl;
 528             $rewrite_from_here->();
 529             $cur = $contrib;
 530             next;
 531         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 532             $build_start->("PreviousBreakwater", $cur);
 533         } elsif ($ty eq 'DgitImportUnpatched') {
 534             my $pm = $pseudomerges[-1];
 535             if (defined $pm) {
 536                 # To an extent, this is heuristic.  Imports don't have
 537                 # a useful history of the debian/ branch.  We assume
 538                 # that the first pseudomerge after an import has a
 539                 # useful history of debian/, and ignore the histories
 540                 # from later pseudomerges.  Often the first pseudomerge
 541                 # will be the dgit import of the upload to the actual
 542                 # suite intended by the non-dgit NMUer, and later
 543                 # pseudomerges may represent in-archive copies.
 544                 my $ovwrs = $pm->{Overwritten};
 545                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 546                     if $report;
 547                 if (@$ovwrs != 1) {
 548                     return $bomb->();
 549                 }
 550                 my $ovwr = $ovwrs->[0]{CommitId};
 551                 printf $report " Overwr=%s", $ovwr if $report;
 552                 # This import has a tree which is just like a
 553                 # breakwater tree, but it has the wrong history.  It
 554                 # ought to have the previous breakwater (which the
 555                 # pseudomerge overwrote) as an ancestor.  That will
 556                 # make the history of the debian/ files correct.  As
 557                 # for the upstream version: either it's the same as
 558                 # was ovewritten (ie, same as the previous
 559                 # breakwater), in which case that history is precisely
 560                 # right; or, otherwise, it was a non-gitish upload of a
 561                 # new upstream version.  We can tell these apart by
 562                 # looking at the tree of the supposed upstream.
 563                 push @brw_cl, {
 564                     %$cl,
 565                     SpecialMethod => 'DgitImportDebianUpdate',
 566                     $xmsg->("convert dgit import: debian changes")
 567                 };
 568                 my $differs = (get_differs $ovwr, $cl->{Tree});
 569                 printf $report " Differs=%#x", $differs if $report;
 570                 if ($differs & D_UPS) {
 571                     printf $report " D_UPS" if $report;
 572                     # This will also trigger if a non-dgit git-based NMU
 573                     # deleted .gitignore (which is a thing that some of
 574                     # the existing git tools do if the user doesn't
 575                     # somehow tell them not to).  Ah well.
 576                     push @brw_cl, {
 577                         %$cl,
 578                         SpecialMethod => 'DgitImportUpstreamUpdate',
 579                         $xmsg->("convert dgit import: upstream changes")
 580                     };
 581                 }
 582                 $prline->(" Import");
 583                 $rewrite_from_here->();
 584                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 585                 $cur = $ovwr;
 586                 next;
 587             } else {
 588                 # Everything is from this import.  This kind of import
 589                 # is already in valid breakwater format, with the
 590                 # patches as commits.
 591                 printf $report " NoPM" if $report;
 592                 # last thing we processed will have been the first patch,
 593                 # if there is one; which is fine, so no need to rewrite
 594                 # on account of this import
 595                 $build_start->("ImportOrigin", $cur);
 596             }
 597             die "$ty ?";
 598         } else {
 599             return $bomb->();
 600         }
 601     }
 602     $prprdelim->();
 603     return if $nogenerate;
 604
 605     # Now we build it back up again
 606
 607     fresh_workarea();
 608
 609     my $rewriting = 0;
 610
 611     my $rm_tree_cached = sub {
 612         my ($subdir) = @_;
 613         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 614     };
 615     my $read_tree_debian = sub {
 616         my ($treeish) = @_;
 617         $rm_tree_cached->(qw(debian));
 618         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 619     };
 620     my $read_tree_upstream = sub {
 621         my ($treeish) = @_;
 622         runcmd @git, qw(read-tree), $treeish;
 623         $read_tree_debian->($build);
 624     };
 625
 626     my $committer_authline = calculate_committer_authline();
 627
 628     in_workarea sub {
 629         mkdir $rd or $!==EEXIST or die $!;
 630         my $current_method;
 631         foreach my $cl (qw(Debian), (reverse @brw_cl),
 632                         { SpecialMethod => 'RecordBreakwaterTip' },
 633                         qw(Upstream), (reverse @upp_cl)) {
 634             if (!ref $cl) {
 635                 $current_method = $cl;
 636                 next;
 637             }
 638             my $method = $cl->{SpecialMethod} // $current_method;
 639             my @parents = ($build);
 640             my $cltree = $cl->{CommitId};
 641             if ($method eq 'Debian') {
 642                 $read_tree_debian->($cltree);
 643             } elsif ($method eq 'Upstream') {
 644                 $read_tree_upstream->($cltree);
 645             } elsif ($method eq 'StartRewrite') {
 646                 $rewriting = 1;
 647                 next;
 648             } elsif ($method eq 'RecordBreakwaterTip') {
 649                 $breakwater = $build;
 650                 next;
 651             } elsif ($method eq 'DgitImportDebianUpdate') {
 652                 $read_tree_debian->($cltree);
 653                 $rm_tree_cached->(qw(debian/patches));
 654             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 655                 $read_tree_upstream->($cltree);
 656                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 657             } else {
 658                 confess "$method ?";
 659             }
 660             $rewriting ||= $cl ne pop @processed;
 661             my $newtree = cmdoutput @git, qw(write-tree);
 662             my $ch = $cl->{Hdr};
 663             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 664             $ch =~ s{^parent .*\n}{}m;
 665             $ch =~ s{(?=^author)}{
 666                 map { "parent $_\n" } @parents
 667             }me or confess "$ch ?";
 668             if ($rewriting) {
 669                 $ch =~ s{^committer .*$}{$committer_authline}m
 670                     or confess "$ch ?";
 671             }
 672             my $cf = "$rd/m$rewriting";
 673             open CD, ">", $cf or die $!;
 674             print CD $ch, "\n", $cl->{Msg} or die $!;
 675             close CD or die $!;
 676             my @cmd = (@git, qw(hash-object));
 677             push @cmd, qw(-w) if $rewriting;
 678             push @cmd, qw(-t commit), $cf;
 679             my $newcommit = cmdoutput @cmd;
 680             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 681             $build = $newcommit;
 682         }
 683     };
 684
 685     runcmd @git, qw(diff-tree --quiet), $input, $build;
 686
 687     return ($build, $breakwater);
 688 }
 689
 690 sub get_head () { return git_rev_parse qw(HEAD); }
 691
 692 sub update_head ($$$) {
 693     my ($old, $new, $mrest) = @_;
 694     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 695 }
 696
 697 sub update_head_checkout ($$$) {
 698     my ($old, $new, $mrest) = @_;
 699     my $symref = git_get_symref();
 700     runcmd @git, qw(checkout), $new, qw(.);
 701     update_head $old, $new, $mrest;
 702 }
 703
 704 sub cmd_launder () {
 705     badusage "no arguments to launder allowed" if @ARGV;
 706     my $old = get_head();
 707     my ($tip,$breakwater) = walk $old;
 708     update_head $old, $tip, 'launder';
 709     # no tree changes except debian/patches
 710     runcmd @git, qw(rm --quiet -rf debian/patches);
 711     printf "# breakwater tip\n%s\n", $breakwater;
 712 }
 713
 714 sub cmd_analyse () {
 715     die if ($ARGV[0]//'') =~ m/^-/;
 716     badusage "too many arguments to analyse" if @ARGV>1;
 717     my ($old) = @ARGV;
 718     if (defined $old) {
 719         $old = git_rev_parse $old;
 720     } else {
 721         $old = get_head();
 722     }
 723     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 724     STDOUT->error and die $!;
 725 }
 726
 727 sub cmd_downstream_rebase_launder_v0 () {
 728     badusage "needs 1 argument, the baseline" unless @ARGV==1;
 729     my ($base) = @ARGV;
 730     $base = git_rev_parse $base;
 731     my $old_head = get_head();
 732     my $current = $old_head;
 733     my $topmost_keep;
 734     for (;;) {
 735         if ($current eq $base) {
 736             $topmost_keep //= $current;
 737             print " $current BASE stop\n";
 738             last;
 739         }
 740         my $cl = classify $current;
 741         print " $current $cl->{Type}";
 742         my $keep = 0;
 743         my $p0 = $cl->{Parents}[0]{CommitId};
 744         my $next;
 745         if ($cl->{Type} eq 'Pseudomerge') {
 746             print " ^".($cl->{Contributor}{Ix}+1);
 747             $next = $cl->{Contributor}{CommitId};
 748         } elsif ($cl->{Type} eq 'AddPatches' or
 749                  $cl->{Type} eq 'Changelog') {
 750             print " strip";
 751             $next = $p0;
 752         } else {
 753             print " keep";
 754             $next = $p0;
 755             $keep = 1;
 756         }
 757         print "\n";
 758         if ($keep) {
 759             $topmost_keep //= $current;
 760         } else {
 761             die "to-be stripped changes not on top of the branch\n"
 762                 if $topmost_keep;
 763         }
 764         $current = $next;
 765     }
 766     if ($topmost_keep eq $old_head) {
 767         print "unchanged\n";
 768     } else {
 769         print "updating to $topmost_keep\n";
 770         update_head_checkout
 771             $old_head, $topmost_keep,
 772             'downstream-rebase-launder-v0';
 773     }
 774 }
 775
 776 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 777 initdebug('git-debrebase ');
 778 enabledebug if $debuglevel;
 779
 780 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 781 chdir $toplevel or die "chdir $toplevel: $!";
 782
 783 $rd = fresh_playground "$playprefix/misc";
 784
 785 my $cmd = shift @ARGV;
 786 my $cmdfn = $cmd;
 787 $cmdfn =~ y/-/_/;
 788 $cmdfn = ${*::}{"cmd_$cmdfn"};
 789
 790 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 791 $cmdfn->();