git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea (;$) {
 132     my ($subdir) = @_;
 133     $subdir //= 'work';
 134     $workarea = fresh_playground "$playprefix/$subdir";
 135     in_workarea sub { playtree_setup };
 136 }
 137
 138 sub run_ref_updates_now ($$) {
 139     my ($mrest, $updates) = @_;
 140     # @$updates is a list of lines for git-update-ref, without \ns
 141
 142     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 143     debugcmd '>|', @upd_cmd;
 144     open U, "|-", @upd_cmd or die $!;
 145     foreach (@$updates) {
 146         printdebug ">= ", $_, "\n";
 147         print U $_, "\n" or die $!;
 148     }
 149     printdebug ">\$\n";
 150     close U or failedcmd @upd_cmd;
 151 }
 152
 153 our $snags_forced = 0;
 154 our $snags_tripped = 0;
 155 our $snags_summarised = 0;
 156 our @deferred_updates;
 157 our @deferred_update_messages;
 158
 159 sub merge_wreckage_cleaning ($) {
 160     my ($updates) = @_;
 161     git_for_each_ref("$wrecknoteprefix/*", sub {
 162         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 163         push @$updates, "delete $fullrefname";
 164     });
 165 }
 166
 167 sub all_snags_summarised () {
 168     $snags_forced + $snags_tripped == $snags_summarised;
 169 }
 170 sub run_deferred_updates ($) {
 171     my ($mrest) = @_;
 172
 173     confess 'dangerous internal error' unless all_snags_summarised();
 174
 175     merge_wreckage_cleaning \@deferred_updates;
 176     run_ref_updates_now $mrest, \@deferred_updates;
 177     print $_, "\n" foreach @deferred_update_messages;
 178
 179     @deferred_updates = ();
 180     @deferred_update_messages = ();
 181 }
 182
 183 sub get_differs ($$) {
 184     my ($x,$y) = @_;
 185     # This resembles quiltify_trees_differ, in dgit, a bit.
 186     # But we don't care about modes, or dpkg-source-unrepresentable
 187     # changes, and we don't need the plethora of different modes.
 188     # Conversely we need to distinguish different kinds of changes to
 189     # debian/ and debian/patches/.
 190
 191     my $differs = 0;
 192
 193     my $rundiff = sub {
 194         my ($opts, $limits, $fn) = @_;
 195         my @cmd = (@git, qw(diff-tree -z --no-renames));
 196         push @cmd, @$opts;
 197         push @cmd, "$_:" foreach $x, $y;
 198         push @cmd, '--', @$limits;
 199         my $diffs = cmdoutput @cmd;
 200         foreach (split /\0/, $diffs) { $fn->(); }
 201     };
 202
 203     $rundiff->([qw(--name-only)], [], sub {
 204         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 205     });
 206
 207     if ($differs & DS_DEB) {
 208         $differs &= ~DS_DEB;
 209         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 210             $differs |=
 211                 m{^debian/patches/}      ? D_PAT_OTH  :
 212                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 213                                            D_DEB_OTH;
 214         });
 215         die "mysterious debian changes $x..$y"
 216             unless $differs & (D_PAT_OTH|DS_DEB);
 217     }
 218
 219     if ($differs & D_PAT_OTH) {
 220         my $mode;
 221         $differs &= ~D_PAT_OTH;
 222         my $pat_oth = sub {
 223             $differs |= D_PAT_OTH;
 224             no warnings qw(exiting);  last;
 225         };
 226         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 227             no warnings qw(exiting);
 228             if (!defined $mode) {
 229                 $mode = $_;  next;
 230             }
 231             die unless s{^debian/patches/}{};
 232             my $ok;
 233             if ($mode eq 'A' && !m/\.series$/s) {
 234                 $ok = 1;
 235             } elsif ($mode eq 'M' && $_ eq 'series') {
 236                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 237                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 238                 chomp $x_s;  $x_s .= "\n";
 239                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 240             } else {
 241                 # nope
 242             }
 243             $mode = undef;
 244             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 245         });
 246         die "mysterious debian/patches changes $x..$y"
 247             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 248     }
 249
 250     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 251
 252     return $differs;
 253 }
 254
 255 sub commit_pr_info ($) {
 256     my ($r) = @_;
 257     return Data::Dumper->dump([$r], [qw(commit)]);
 258 }
 259
 260 sub calculate_committer_authline () {
 261     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 262         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 263     my ($h,$m) = get_commit $c;
 264     $h =~ m/^committer .*$/m or confess "($h) ?";
 265     return $&;
 266 }
 267
 268 sub rm_subdir_cached ($) {
 269     my ($subdir) = @_;
 270     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 271 }
 272
 273 sub read_tree_subdir ($$) {
 274     my ($subdir, $new_tree_object) = @_;
 275     rm_subdir_cached $subdir;
 276     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 277 }
 278
 279 sub read_tree_debian ($) {
 280     my ($treeish) = @_;
 281     read_tree_subdir 'debian', "$treeish:debian";
 282     rm_subdir_cached 'debian/patches';
 283 }
 284
 285 sub read_tree_upstream ($;$$) {
 286     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 287     # if $tree_with_debian is supplied, will use that for debian/
 288     # otherwise will save and restore it.
 289     my $debian =
 290         $tree_with_debian ? "$tree_with_debian:debian"
 291         : cmdoutput @git, qw(write-tree --prefix=debian/);
 292     runcmd @git, qw(read-tree), $treeish;
 293     read_tree_subdir 'debian', $debian;
 294     rm_subdir_cached 'debian/patches' unless $keep_patches;
 295 };
 296
 297 sub make_commit ($$) {
 298     my ($parents, $message_paras) = @_;
 299     my $tree = cmdoutput @git, qw(write-tree);
 300     my @cmd = (@git, qw(commit-tree), $tree);
 301     push @cmd, qw(-p), $_ foreach @$parents;
 302     push @cmd, qw(-m), $_ foreach @$message_paras;
 303     return cmdoutput @cmd;
 304 }
 305
 306 our @snag_force_opts;
 307 sub snag ($$;@) {
 308     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 309     if (grep { $_ eq $tag } @snag_force_opts) {
 310         $snags_forced++;
 311         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 312     } else {
 313         $snags_tripped++;
 314         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 315     }
 316 }
 317
 318 # Important: all mainline code must call snags_maybe_bail after
 319 # any point where snag might be called, but before making changes
 320 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 321 # may be called more than once if necessary (but this is not ideal
 322 # because then the messages about number of snags may be confusing).
 323 sub snags_maybe_bail () {
 324     return if all_snags_summarised();
 325     if ($snags_forced) {
 326         printf STDERR
 327             "%s: snags: %d overriden by individual -f options\n",
 328             $us, $snags_forced;
 329     }
 330     if ($snags_tripped) {
 331         if ($opt_force) {
 332             printf STDERR
 333                 "%s: snags: %d overriden by global --force\n",
 334                 $us, $snags_tripped;
 335         } else {
 336             fail sprintf
 337   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 338                 $us, $snags_tripped;
 339         }
 340     }
 341     $snags_summarised = $snags_forced + $snags_tripped;
 342 }
 343 sub snags_maybe_bail_early () {
 344     # useful to bail out early without doing a lot of work;
 345     # not a substitute for snags_maybe_bail.
 346     snags_maybe_bail() if $snags_tripped && !$opt_force;
 347 }
 348 sub any_snags () {
 349     return $snags_forced || $snags_tripped;
 350 }
 351
 352 sub gbp_pq_export ($$$) {
 353     my ($bname, $base, $tip) = @_;
 354     # must be run in a workarea.  $bname and patch-queue/$bname
 355     # ought not to exist.  Leaves you on patch-queue/$bname with
 356     # the patches staged but not committed.
 357     printdebug "gbp_pq_export $bname $base $tip\n";
 358     runcmd @git, qw(checkout -q -b), $bname, $base;
 359     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 360     my @gbp_cmd = (qw(gbp pq export));
 361     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 362     if ($r) {
 363         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 364         failedcmd @gbp_cmd;
 365     }
 366     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 367 }
 368
 369
 370 # xxx allow merge resolution separately from laundering, before git merge
 371 #
 372 # xxx general gdr docs highlight forbidden things
 373 # xxx general gdr docs list allowable things ?
 374 # xxx general gdr docs explicitly forbid some rebase
 375 #
 376 # xxx provide a way for the user to help
 377 # xxx (eg, provide wreckage provide way to continue)
 378
 379 # later/rework?
 380 #  use git-format-patch?
 381 #  our own patch identification algorithm?
 382 #  this is an alternative strategy
 383
 384 sub merge_failed ($$;@) {
 385     my ($wrecknotes, $emsg, @xmsgs) = @_;
 386     my @m;
 387     push @m, "Merge resolution failed: $emsg";
 388     push @m, @xmsgs;
 389
 390     changedir $maindir;
 391
 392     my @updates;
 393     merge_wreckage_cleaning \@updates;
 394     run_ref_updates_now "merge failed", \@updates;
 395
 396     @updates = ();
 397     keys %$wrecknotes;
 398     while (my ($k,$v) = each %$wrecknotes) {
 399         push @updates, "create $wrecknoteprefix/$k $v";
 400     }
 401     run_ref_updates_now "merge failed", \@updates;
 402     push @m, "Wreckage left in $wrecknoteprefix/*.";
 403
 404     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 405
 406     # use finish rather than fail, in case we are within an eval
 407     # (that can happen inside walk!)
 408     print STDERR "\n";
 409     print STDERR "$us: $_\n" foreach @m;
 410     finish 15;
 411 }
 412
 413 sub mwrecknote ($$$) {
 414     my ($wrecknotes, $reftail, $commitish) = @_;
 415     confess unless defined $commitish;
 416     printdebug "mwrecknote $reftail $commitish\n";
 417     $wrecknotes->{$reftail} = $commitish;
 418 }
 419
 420 sub merge_attempt_cmd {
 421     my $wrecknotes = shift @_;
 422     debugcmd '+', @_;
 423     $!=0; $?=-1;
 424     if (system @_) {
 425         merge_failed $wrecknotes,
 426             failedcmd_waitstatus(),
 427             "failed command: @_";
 428     }
 429 }
 430
 431 sub merge_series_patchqueue_convert ($$$);
 432
 433 sub merge_series ($$$;@) {
 434     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 435     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 436     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 437     # ^ specifies several patch series (currently we only support exactly 2)
 438     # return value is a commit which is the result of
 439     # merging the two versions of the same topic branch
 440     #   $input_q[0] and $input_q[1]
 441     # with respect to the old version
 442     #   $base_q
 443     # all onto $newbase.
 444
 445     # Creates, in *_q, a key MR for its private use
 446
 447     printdebug "merge_series newbase=$newbase\n";
 448
 449     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 450     $base_q->{MR}{S} = 'base';
 451
 452     my %prereq;
 453     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 454     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 455     # $prereq{<patch filename>}               exists or not (even later)
 456
 457     my $merged_pq;
 458
 459     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 460
 461     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 462
 463     local $workarea;
 464     fresh_workarea "merge";
 465     my $seriesfile = "debian/patches/series";
 466     in_workarea sub {
 467         playtree_setup();
 468         foreach my $q ($base_q, reverse @input_qs) {
 469             my $s = $q->{MR}{S};
 470             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 471             my @earlier;
 472             if (open S, $seriesfile) {
 473                 while (my $patch = <S>) {
 474                     chomp $patch or die $!;
 475                     $prereq{$patch} //= {};
 476                     foreach my $earlier (@earlier) {
 477                         $prereq{$patch}{$earlier}{$s}++ and die;
 478                     }
 479                     push @earlier, $patch;
 480                     stat "debian/patches/$patch" or die "$patch ?";
 481                 }
 482                 S->error and die "$seriesfile $!";
 483                 close S;
 484             } else {
 485                 die "$seriesfile $!" unless $!==ENOENT;
 486             }
 487             read_tree_upstream $newbase, 1;
 488             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 489                 "Convert $s to patch queue for merging",
 490                 "[git-debrebase merge-innards patch-queue import:".
 491                 " $q->{SeriesTip}]"
 492             ];
 493             printdebug "merge_series  pec $pec ";
 494             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 495             $pec = make_commit [ $pec ], [
 496                 "Drop series file from $s to avoid merge trouble",
 497                 "[git-debrebase merge-innards patch-queue prep:".
 498                 " $q->{SeriesTip}]"
 499             ];
 500
 501             read_tree_debian $newbase;
 502             if (@earlier) {
 503                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 504             } else {
 505                 rm_subdir_cached 'debian/patches';
 506             }
 507             $pec = make_commit [ $pec ], [
 508  "Update debian/ (excluding patches) to final to avoid re-merging",
 509  "debian/ was already merged and we need to just take that.",
 510                 "[git-debrebase merge-innards patch-queue packaging:".
 511                 " $q->{SeriesTip}]"
 512             ];
 513
 514             printdebug "pec' $pec\n";
 515             runcmd @git, qw(reset -q --hard), $pec;
 516             $q->{MR}{PEC} = $pec;
 517             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 518         }
 519         # now, because of reverse, we are on $input_q->{MR}{OQC}
 520         runcmd @git, qw(checkout -q -b merge);
 521         printdebug "merge_series merging...\n";
 522         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 523
 524         $attempt_cmd->(@mergecmd);
 525
 526         printdebug "merge_series merge ok, series...\n";
 527         # We need to construct a new series file
 528         # Firstly, resolve prereq
 529         foreach my $f (sort keys %prereq) {
 530             printdebug "merge_series  patch\t$f\t";
 531             if (!stat_exists "debian/patches/$f") {
 532                 print DEBUG " drop\n" if $debuglevel;
 533                 # git merge deleted it; that's how we tell it's not wanted
 534                 delete $prereq{$f};
 535                 next;
 536             }
 537             print DEBUG " keep\n" if $debuglevel;
 538             foreach my $g (sort keys %{ $prereq{$f} }) {
 539                 my $gfp = $prereq{$f}{$g};
 540                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 541                 if (!!$gfp->{0} == !!$gfp->{1}
 542                     ? $gfp->{0}
 543                     : !$gfp->{base}) {
 544                     print DEBUG "\tkeep\n" if $debuglevel;
 545                 } else {
 546                     print DEBUG "\tdrop\n" if $debuglevel;
 547                     delete $prereq{$f}{$g};
 548                 }
 549             }
 550         }
 551
 552         my $unsat = sub {
 553             my ($f) = @_;
 554             return scalar keys %{ $prereq{$f} };
 555         };
 556
 557         my $nodate = time + 1;
 558         my %authordate;
 559         # $authordate{<patch filename>};
 560         my $authordate = sub {
 561             my ($f) = @_;
 562             $authordate{$f} //= do {
 563                 open PF, "<", "debian/patches/$f" or die "$f $!";
 564                 while (<PF>) {
 565                     return $nodate if m/^$/;
 566                     last if s{^Date: }{};
 567                 }
 568                 chomp;
 569                 return cmdoutput qw(date +%s -d), $_;
 570             };
 571         };
 572
 573         open NS, '>', $seriesfile or die $!;
 574
 575         while (keys %prereq) {
 576             my $best;
 577             foreach my $try (sort keys %prereq) {
 578                 if ($best) {
 579                     next if (
 580                              $unsat->($try) <=> $unsat->($best) or
 581                              $authordate->($try) <=> $authordate->($best) or
 582                              $try cmp $best
 583                             ) >= 0;
 584                 }
 585                 $best = $try;
 586             }
 587             printdebug "merge_series series next $best\n";
 588             print NS "$best\n" or die $!;
 589             delete $prereq{$best};
 590             foreach my $gp (values %prereq) {
 591                 delete $gp->{$best};
 592             }
 593         }
 594
 595         runcmd @git, qw(add), $seriesfile;
 596         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 597         $merged_pq = git_rev_parse 'HEAD';
 598         $mwrecknote->('merged-patchqueue', $merged_pq);
 599     };
 600     return merge_series_patchqueue_convert
 601             $wrecknotes, $newbase, $merged_pq;
 602 }
 603
 604 sub merge_series_patchqueue_convert ($$$) {
 605     my ($wrecknotes, $newbase, $merged_pq) = @_;
 606
 607     my $result;
 608     in_workarea sub {
 609         playtree_setup();
 610         printdebug "merge_series series gbp pq import\n";
 611         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 612
 613         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 614
 615         # OK now we are on patch-queue/merge, and we need to rebase
 616         # onto the intended parent and drop the patches from each one
 617
 618         printdebug "merge_series series ok, building...\n";
 619         my $build = $newbase;
 620         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 621         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 622             my $commit = git_cat_file $c, 'commit';
 623             printdebug "merge_series series ok, building $c\n";
 624             read_tree_upstream $c, 0, $newbase;
 625             my $tree = cmdoutput @git, qw(write-tree);
 626             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 627             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 628             open C, ">", "../mcommit" or die $!;
 629             print C $commit or die $!;
 630             close C or die $!;
 631             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 632         }
 633         $result = $build;
 634         mwrecknote($wrecknotes, 'merged-result', $result);
 635
 636         runcmd @git, qw(update-ref refs/heads/result), $result;
 637
 638         runcmd @git, qw(checkout -q -b debug);
 639         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 640         runcmd @git, qw(add .);
 641         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 642         my $mdebug = git_rev_parse 'HEAD';
 643         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 644         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 645     };
 646     printdebug "merge_series returns $result\n";
 647     return $result;
 648 }
 649
 650 # classify returns an info hash like this
 651 #   CommitId => $objid
 652 #   Hdr => # commit headers, including 1 final newline
 653 #   Msg => # commit message (so one newline is dropped)
 654 #   Tree => $treeobjid
 655 #   Type => (see below)
 656 #   Parents = [ {
 657 #       Ix => $index # ie 0, 1, 2, ...
 658 #       CommitId
 659 #       Differs => return value from get_differs
 660 #       IsOrigin
 661 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 662 #     } ...]
 663 #   NewMsg => # commit message, but with any [dgit import ...] edited
 664 #             # to say "[was: ...]"
 665 #
 666 # Types:
 667 #   Packaging
 668 #   Changelog
 669 #   Upstream
 670 #   AddPatches
 671 #   Mixed
 672 #
 673 #   Pseudomerge
 674 #     has additional entres in classification result
 675 #       Overwritten = [ subset of Parents ]
 676 #       Contributor = $the_remaining_Parent
 677 #
 678 #   DgitImportUnpatched
 679 #     has additional entry in classification result
 680 #       OrigParents = [ subset of Parents ]
 681 #
 682 #   Anchor
 683 #     has additional entry in classification result
 684 #       OrigParents = [ subset of Parents ]  # singleton list
 685 #
 686 #   TreatAsAnchor
 687 #
 688 #   BreakwaterStart
 689 #
 690 #   Unknown
 691 #     has additional entry in classification result
 692 #       Why => "prose"
 693
 694 sub parsecommit ($;$) {
 695     my ($objid, $p_ref) = @_;
 696     # => hash with                   CommitId Hdr Msg Tree Parents
 697     #    Parents entries have only   Ix CommitId
 698     #    $p_ref, if provided, must be [] and is used as a base for Parents
 699
 700     $p_ref //= [];
 701     die if @$p_ref;
 702
 703     my ($h,$m) = get_commit $objid;
 704
 705     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 706     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 707
 708     my $r = {
 709         CommitId => $objid,
 710         Hdr => $h,
 711         Msg => $m,
 712         Tree => $t,
 713         Parents => $p_ref,
 714     };
 715
 716     foreach my $ph (@ph) {
 717         push @$p_ref, {
 718             Ix => scalar @$p_ref,
 719             CommitId => $ph,
 720         };
 721     }
 722
 723     return $r;
 724 }
 725
 726 sub classify ($) {
 727     my ($objid) = @_;
 728
 729     my @p;
 730     my $r = parsecommit($objid, \@p);
 731     my $t = $r->{Tree};
 732
 733     foreach my $p (@p) {
 734         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 735     }
 736
 737     printdebug "classify $objid \$t=$t \@p",
 738         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 739         "\n";
 740
 741     my $classify = sub {
 742         my ($type, @rest) = @_;
 743         $r = { %$r, Type => $type, @rest };
 744         if ($debuglevel) {
 745             printdebug " = $type ".(dd $r)."\n";
 746         }
 747         return $r;
 748     };
 749     my $unknown = sub {
 750         my ($why) = @_;
 751         $r = { %$r, Type => qw(Unknown), Why => $why };
 752         printdebug " ** Unknown\n";
 753         return $r;
 754     };
 755
 756     if (grep { $_ eq $objid } @opt_anchors) {
 757         return $classify->('TreatAsAnchor');
 758     }
 759
 760     my @identical = grep { !$_->{Differs} } @p;
 761     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 762     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 763
 764     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 765         # multi-orig upstreams are represented with an anchor merge
 766         # from a single upstream commit which combines the orig tarballs
 767
 768         # Every anchor tagged this way must be a merge.
 769         # We are relying on the
 770         #     [git-debrebase anchor: ...]
 771         # commit message annotation in "declare" anchor merges (which
 772         # do not have any upstream changes), to distinguish those
 773         # anchor merges from ordinary pseudomerges (which we might
 774         # just try to strip).
 775         #
 776         # However, the user is going to be doing git-rebase a lot.  We
 777         # really don't want them to rewrite an anchor commit.
 778         # git-rebase trips up on merges, so that is a useful safety
 779         # catch.
 780         #
 781         # BreakwaterStart commits are also anchors in the terminology
 782         # of git-debrebase(5), but they are untagged (and always
 783         # manually generated).
 784         #
 785         # We cannot not tolerate any tagged linear commit (ie,
 786         # BreakwaterStart commits tagged `[anchor:') because such a
 787         # thing could result from an erroneous linearising raw git
 788         # rebase of a merge anchor.  That would represent a corruption
 789         # of the branch. and we want to detect and reject the results
 790         # of such corruption before it makes it out anywhere.  If we
 791         # reject it here then we avoid making the pseudomerge which
 792         # would be needed to push it.
 793
 794         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 795         @p == 2 or return $badanchor->("has other than two parents");
 796         $haspatches and return $badanchor->("contains debian/patches");
 797
 798         # How to decide about l/r ordering of anchors ?  git
 799         # --topo-order prefers to expand 2nd parent first.  There's
 800         # already an easy rune to look for debian/ history anyway (git log
 801         # debian/) so debian breakwater branch should be 1st parent; that
 802         # way also there's also an easy rune to look for the upstream
 803         # patches (--topo-order).
 804
 805         # Also this makes --first-parent be slightly more likely to
 806         # be useful - it makes it provide a linearised breakwater history.
 807
 808         # Of course one can say somthing like
 809         #  gitk -- ':/' ':!/debian'
 810         # to get _just_ the commits touching upstream files, and by
 811         # the TREESAME logic in git-rev-list this will leave the
 812         # breakwater into upstream at the first anchor.  But that
 813         # doesn't report debian/ changes at all.
 814
 815         # Other observations about gitk: by default, gitk seems to
 816         # produce output in a different order to git-rev-list.  I
 817         # can't seem to find this documented anywhere.  gitk
 818         # --date-order DTRT.  But, gitk always seems to put the
 819         # parents from left to right, in order, so it's easy to see
 820         # which way round a pseudomerge is.
 821
 822         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 823         $p[1]{Differs} & ~DS_DEB and
 824             $badanchor->("upstream files differ from left parent");
 825         $p[0]{Differs} & ~D_UPS and
 826             $badanchor->("debian/ differs from right parent");
 827
 828         return $classify->(qw(Anchor),
 829                            OrigParents => [ $p[1] ]);
 830     }
 831
 832     if (@p == 1) {
 833         my $d = $r->{Parents}[0]{Differs};
 834         if ($d == D_PAT_ADD) {
 835             return $classify->(qw(AddPatches));
 836         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 837             return $unknown->("edits debian/patches");
 838         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 839             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 840             if ($ty eq 'tree') {
 841                 if ($d == D_DEB_CLOG) {
 842                     return $classify->(qw(Changelog));
 843                 } else {
 844                     return $classify->(qw(Packaging));
 845                 }
 846             } elsif ($ty eq 'missing') {
 847                 return $classify->(qw(BreakwaterStart));
 848             } else {
 849                 return $unknown->("parent's debian is not a directory");
 850             }
 851         } elsif ($d == D_UPS) {
 852             return $classify->(qw(Upstream));
 853         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 854             return $classify->(qw(Mixed));
 855         } elsif ($d == 0) {
 856             return $unknown->("no changes");
 857         } else {
 858             confess "internal error $objid ?";
 859         }
 860     }
 861     if (!@p) {
 862         return $unknown->("origin commit");
 863     }
 864
 865     if (@p == 2 && @identical == 1) {
 866         my @overwritten = grep { $_->{Differs} } @p;
 867         confess "internal error $objid ?" unless @overwritten==1;
 868         return $classify->(qw(Pseudomerge),
 869                            Overwritten => [ $overwritten[0] ],
 870                            Contributor => $identical[0]);
 871     }
 872     if (@p == 2 && @identical == 2) {
 873         my $get_t = sub {
 874             my ($ph,$pm) = get_commit $_[0]{CommitId};
 875             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 876             $1;
 877         };
 878         my @bytime = @p;
 879         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 880         if ($order > 0) { # newer first
 881         } elsif ($order < 0) {
 882             @bytime = reverse @bytime;
 883         } else {
 884             # same age, default to order made by -s ours
 885             # that is, commit was made by someone who preferred L
 886         }
 887         return $classify->(qw(Pseudomerge),
 888                            SubType => qw(Ambiguous),
 889                            Contributor => $bytime[0],
 890                            Overwritten => [ $bytime[1] ]);
 891     }
 892     foreach my $p (@p) {
 893         my ($p_h, $p_m) = get_commit $p->{CommitId};
 894         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 895         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 896     }
 897     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 898     my $m2 = $r->{Msg};
 899     if (!(grep { !$_->{IsOrigin} } @p) and
 900         (@orig_ps >= @p - 1) and
 901         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 902         $r->{NewMsg} = $m2;
 903         return $classify->(qw(DgitImportUnpatched),
 904                            OrigParents => \@orig_ps);
 905     }
 906
 907     if (@p == 2 and
 908         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 909         # xxx ^ metadata tag needs adding to (5)
 910         return $classify->("MergedBreakwaters");
 911     }
 912     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 913         return $unknown->("unknown kind of merge from $1");
 914     }
 915     if (@p > 2) {
 916         return $unknown->("octopus merge");
 917     }
 918
 919     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 920         return $unknown->("general two-parent merge");
 921     }
 922
 923     return $classify->("VanillaMerge");
 924 }
 925
 926 sub keycommits ($;$$$$$);
 927
 928 sub mergedbreakwaters_anchor ($) {
 929     my ($cl) = @_;
 930     my $best_anchor;
 931     foreach my $p (@{ $cl->{Parents} }) {
 932         my ($panchor, $pbw) = keycommits $p->{CommitId},
 933             undef,undef,undef,undef, 1;
 934         $best_anchor = $panchor
 935             if !defined $best_anchor
 936             or is_fast_fwd $best_anchor, $panchor;
 937         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 938             unless is_fast_fwd $panchor, $best_anchor;
 939     }
 940     return $best_anchor;
 941 }
 942
 943 sub keycommits ($;$$$$$) {
 944     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 945     # => ($anchor, $breakwater)
 946
 947     # $unclean->("unclean-$tagsfx", $msg, $cl)
 948     # $furniture->("unclean-$tagsfx", $msg, $cl)
 949     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 950     #   is callled for each situation or commit that
 951     #   wouldn't be found in a laundered branch
 952     # $furniture is for furniture commits such as might be found on an
 953     #   interchange branch (pseudomerge, d/patches, changelog)
 954     # $trouble is for things whnich prevent the return of
 955     #   anchor and breakwater information; if that is ignored,
 956     #   then keycommits returns (undef, undef) instead.
 957     # $fatal is for unprocessable commits, and should normally cause
 958     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 959     #
 960     # If $claimed_bw, this is supposed to be a breakwater commit.
 961     #
 962     # If a callback is undef, fail is called instead.
 963     # If a callback is defined but false, the situation is ignored.
 964     # Callbacks may say:
 965     #   no warnings qw(exiting); last;
 966     # if the answer is no longer wanted.
 967
 968     my ($anchor, $breakwater);
 969     $breakwater = $head if $claimed_bw;
 970     my $clogonly;
 971     my $cl;
 972     my $found_pm;
 973     $fatal //= sub { fail $_[1]; };
 974     my $x = sub {
 975         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 976         my $why = $mainwhy.$xwhy;
 977         my $m = "branch needs laundering (run git-debrebase): $why";
 978         fail $m unless defined $cb;
 979         return unless $cb;
 980         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 981     };
 982     my $found_anchor = sub {
 983         ($anchor) = @_;
 984         $breakwater //= $clogonly;
 985         $breakwater //= $head;
 986         no warnings qw(exiting);
 987         last;
 988     };
 989     for (;;) {
 990         $cl = classify $head;
 991         my $ty = $cl->{Type};
 992         if ($ty eq 'Packaging') {
 993             $breakwater //= $clogonly;
 994             $breakwater //= $head;
 995         } elsif ($ty eq 'Changelog') {
 996             # this is going to count as the tip of the breakwater
 997             # only if it has no upstream stuff before it
 998             $clogonly //= $head;
 999         } elsif ($ty eq 'Anchor' or
1000                  $ty eq 'TreatAsAnchor' or
1001                  $ty eq 'BreakwaterStart') {
1002             $found_anchor->($head);
1003         } elsif ($ty eq 'Upstream') {
1004             $x->($unclean, 'ordering',
1005  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1006                 if defined $breakwater;
1007             $clogonly = undef;
1008             $breakwater = undef;
1009         } elsif ($ty eq 'Mixed') {
1010             $x->($unclean, 'mixed',
1011                  "found mixed upstream/packaging commit"," ($head)");
1012             $clogonly = undef;
1013             $breakwater = undef;
1014         } elsif ($ty eq 'Pseudomerge' or
1015                  $ty eq 'AddPatches') {
1016             my $found_pm = 1;
1017             $x->($furniture, (lc $ty),
1018                  "found interchange bureaucracy commit ($ty)"," ($head)");
1019         } elsif ($ty eq 'DgitImportUnpatched') {
1020             if ($found_pm) {
1021                 $x->($trouble, 'dgitimport',
1022                      "found dgit dsc import"," ($head)");
1023                 return (undef,undef);
1024             } else {
1025                 $x->($fatal, 'unprocessable',
1026                      "found bare dgit dsc import with no prior history",
1027                      " ($head)");
1028                 return (undef,undef);
1029             }
1030         } elsif ($ty eq 'VanillaMerge') {
1031             $x->($trouble, 'vanillamerge',
1032                  "found vanilla merge"," ($head)");
1033             return (undef,undef);
1034         } elsif ($ty eq 'MergedBreakwaters') {
1035             $found_anchor->(mergedbreakwaters_anchor $cl);
1036         } else {
1037             $x->($fatal, 'unprocessable',
1038                  "found unprocessable commit, cannot cope: $cl->{Why}",
1039                  " ($head)");
1040             return (undef,undef);
1041         }
1042         $head = $cl->{Parents}[0]{CommitId};
1043     }
1044     return ($anchor, $breakwater);
1045 }
1046
1047 sub walk ($;$$$);
1048 sub walk ($;$$$) {
1049     my ($input,
1050         $nogenerate,$report, $report_lprefix) = @_;
1051     # => ($tip, $breakwater_tip, $last_anchor)
1052     # (or nothing, if $nogenerate)
1053
1054     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1055     $report_lprefix //= '';
1056
1057     # go through commits backwards
1058     # we generate two lists of commits to apply:
1059     # breakwater branch and upstream patches
1060     my (@brw_cl, @upp_cl, @processed);
1061     my %found;
1062     my $upp_limit;
1063     my @pseudomerges;
1064
1065     my $cl;
1066     my $xmsg = sub {
1067         my ($prose, $info) = @_;
1068         my $ms = $cl->{Msg};
1069         chomp $ms;
1070         $info //= '';
1071         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1072         return (Msg => $ms);
1073     };
1074     my $rewrite_from_here = sub {
1075         my ($cl) = @_;
1076         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1077         push @$cl, $sp_cl;
1078         push @processed, $sp_cl;
1079     };
1080     my $cur = $input;
1081
1082     my $prdelim = "";
1083     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1084
1085     my $prline = sub {
1086         return unless $report;
1087         print $report $prdelim, $report_lprefix, @_;
1088         $prdelim = "\n";
1089     };
1090
1091     my $bomb = sub { # usage: return $bomb->();
1092         print $report " Unprocessable" if $report;
1093         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1094         $prprdelim->();
1095         if ($nogenerate) {
1096             return (undef,undef);
1097         }
1098         fail "found unprocessable commit, cannot cope".
1099             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1100             " (commit $cur) (d.".
1101             (join ' ', map { sprintf "%#x", $_->{Differs} }
1102              @{ $cl->{Parents} }).
1103                  ")";
1104     };
1105
1106     my $build;
1107     my $breakwater;
1108
1109     my $build_start = sub {
1110         my ($msg, $parent) = @_;
1111         $prline->(" $msg");
1112         $build = $parent;
1113         no warnings qw(exiting); last;
1114     };
1115
1116     my $nomerge = sub {
1117         my ($emsg) = @_;
1118         merge_failed $cl->{MergeWreckNotes}, $emsg;
1119     };
1120
1121     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1122
1123     my $last_anchor;
1124
1125     for (;;) {
1126         $cl = classify $cur;
1127         $cl->{MergeWreckNotes} //= {};
1128         my $ty = $cl->{Type};
1129         my $st = $cl->{SubType};
1130         $prline->("$cl->{CommitId} $cl->{Type}");
1131         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1132         push @processed, $cl;
1133         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1134         if ($ty eq 'AddPatches') {
1135             $cur = $p0;
1136             $rewrite_from_here->(\@upp_cl);
1137             next;
1138         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1139             push @brw_cl, $cl;
1140             $cur = $p0;
1141             next;
1142         } elsif ($ty eq 'BreakwaterStart') {
1143             $last_anchor = $cur;
1144             $build_start->('FirstPackaging', $cur);
1145         } elsif ($ty eq 'Upstream') {
1146             push @upp_cl, $cl;
1147             $cur = $p0;
1148             next;
1149         } elsif ($ty eq 'Mixed') {
1150             my $queue = sub {
1151                 my ($q, $wh) = @_;
1152                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1153                 push @$q, $cls;
1154             };
1155             $queue->(\@brw_cl, "debian");
1156             $queue->(\@upp_cl, "upstream");
1157             $rewrite_from_here->(\@brw_cl);
1158             $cur = $p0;
1159             next;
1160         } elsif ($ty eq 'Pseudomerge') {
1161             my $contrib = $cl->{Contributor}{CommitId};
1162             print $report " Contributor=$contrib" if $report;
1163             push @pseudomerges, $cl;
1164             $rewrite_from_here->(\@upp_cl);
1165             $cur = $contrib;
1166             next;
1167         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1168             $last_anchor = $cur;
1169             $build_start->("Anchor", $cur);
1170         } elsif ($ty eq 'DgitImportUnpatched') {
1171             my $pm = $pseudomerges[-1];
1172             if (defined $pm) {
1173                 # To an extent, this is heuristic.  Imports don't have
1174                 # a useful history of the debian/ branch.  We assume
1175                 # that the first pseudomerge after an import has a
1176                 # useful history of debian/, and ignore the histories
1177                 # from later pseudomerges.  Often the first pseudomerge
1178                 # will be the dgit import of the upload to the actual
1179                 # suite intended by the non-dgit NMUer, and later
1180                 # pseudomerges may represent in-archive copies.
1181                 my $ovwrs = $pm->{Overwritten};
1182                 printf $report " PM=%s \@Overwr:%d",
1183                     $pm->{CommitId}, (scalar @$ovwrs)
1184                     if $report;
1185                 if (@$ovwrs != 1) {
1186                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1187                     return $bomb->();
1188                 }
1189                 my $ovwr = $ovwrs->[0]{CommitId};
1190                 printf $report " Overwr=%s", $ovwr if $report;
1191                 # This import has a tree which is just like a
1192                 # breakwater tree, but it has the wrong history.  It
1193                 # ought to have the previous breakwater (which the
1194                 # pseudomerge overwrote) as an ancestor.  That will
1195                 # make the history of the debian/ files correct.  As
1196                 # for the upstream version: either it's the same as
1197                 # was ovewritten (ie, same as the previous
1198                 # breakwater), in which case that history is precisely
1199                 # right; or, otherwise, it was a non-gitish upload of a
1200                 # new upstream version.  We can tell these apart by
1201                 # looking at the tree of the supposed upstream.
1202                 push @brw_cl, {
1203                     %$cl,
1204                     SpecialMethod => 'DgitImportDebianUpdate',
1205                     $xmsg->("convert dgit import: debian changes")
1206                 }, {
1207                     %$cl,
1208                     SpecialMethod => 'DgitImportUpstreamUpdate',
1209                     $xmsg->("convert dgit import: upstream update",
1210                             " anchor")
1211                 };
1212                 $prline->(" Import");
1213                 $rewrite_from_here->(\@brw_cl);
1214                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1215                 $cur = $ovwr;
1216                 next;
1217             } else {
1218                 # Everything is from this import.  This kind of import
1219                 # is already nearly in valid breakwater format, with the
1220                 # patches as commits.  Unfortunately it contains
1221                 # debian/patches/.
1222                 printdebug "*** WALK BOMB bare dgit import\n";
1223                 $cl->{Why} = "bare dgit dsc import";
1224                 return $bomb->();
1225             }
1226             die "$ty ?";
1227         } elsif ($ty eq 'MergedBreakwaters') {
1228             $last_anchor = mergedbreakwaters_anchor $cl;
1229             $build_start->(' MergedBreakwaters', $cur);
1230             last;
1231         } elsif ($ty eq 'VanillaMerge') {
1232             # User may have merged unstitched branch(es).  We will
1233             # have now lost what ffq-prev was then (since the later
1234             # pseudomerge may introduce further changes).  The effect
1235             # of resolving such a merge is that we may have to go back
1236             # further in history to find a merge base, since the one
1237             # which was reachable via ffq-prev is no longer findable.
1238             # This is suboptimal, but if it all works we'll have done
1239             # the right thing.
1240             # xxx we should warn the user in the docs about this
1241
1242             my $ok=1;
1243             my $best_anchor;
1244             # We expect to find a dominating anchor amongst the
1245             # inputs' anchors.  That will be the new anchor.
1246             #
1247             # More complicated is finding a merge base for the
1248             # breakwaters.  We need a merge base that is a breakwater
1249             # commit.  The ancestors of breakwater commits are more
1250             # breakwater commits and possibly upstream commits and the
1251             # ancestors of those upstream.  Upstreams might have
1252             # arbitrary ancestors.  But any upstream commit U is
1253             # either included in both anchors, in which case the
1254             # earlier anchor is a better merge base than any of U's
1255             # ancestors; or U is not included in the older anchor, in
1256             # which case U is not an ancestor of the vanilla merge at
1257             # all.  So no upstream commit, nor any ancestor thereof,
1258             # is a best merge base.  As for non-breakwater Debian
1259             # commits: these are never ancestors of any breakwater.
1260             #
1261             # So any best merge base as found by git-merge-base
1262             # is a suitable breakwater anchor.  Usually there will
1263             # be only one.
1264
1265             printdebug "*** MERGE\n";
1266
1267             my @bwbcmd = (@git, qw(merge-base));
1268             my @ibcmd = (@git, qw(merge-base --all));
1269             my $might_be_in_bw = 1;
1270
1271             my $ps = $cl->{Parents};
1272
1273             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1274
1275             foreach my $p (@$ps) {
1276                 $prline->(" VanillaMerge ".$p->{Ix});
1277                 $prprdelim->();
1278                 my ($ptip, $pbw, $panchor) =
1279                     walk $p->{CommitId}, 0, $report,
1280                          $report_lprefix.'  ';
1281                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1282                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1283                 $p->{Anchor} = $panchor;
1284
1285                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1286                 $mwrecknote->("$lr-input", $p->{CommitId});
1287
1288                 my $mwrecknote_parent = sub {
1289                     my ($which) = @_;
1290                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1291                 };
1292                 $mwrecknote_parent->('Laundered');
1293                 $mwrecknote_parent->('Breakwater');
1294                 $mwrecknote_parent->('Anchor');
1295
1296                 $best_anchor = $panchor if
1297                     !defined $best_anchor or
1298                     is_fast_fwd $best_anchor, $panchor;
1299
1300                 printdebug " MERGE BA best=".($best_anchor//'-').
1301                     " p=$panchor\n";
1302             }
1303
1304             $mwrecknote->('result-anchor', $best_anchor);
1305
1306             foreach my $p (@$ps) {
1307                 $prline->(" VanillaMerge ".$p->{Ix});
1308                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1309                     $nomerge->('divergent anchors');
1310                 } elsif ($p->{Anchor} eq $best_anchor) {
1311                     print $report " SameAnchor" if $report;
1312                 } else {
1313                     print $report " SupersededAnchor" if $report;
1314                 }
1315                 if ($p->{Breakwater} eq $p->{CommitId}) {
1316                     # this parent commit was its own breakwater,
1317                     # ie it is part of the breakwater
1318                     print $report " Breakwater" if $report;
1319                 } else {
1320                     $might_be_in_bw = 0;
1321                 }
1322                 push @bwbcmd, $p->{Breakwater};
1323                 push @ibcmd, $p->{CommitId};
1324             }
1325
1326             if ($ok && $might_be_in_bw) {
1327                 # We could rewrite this to contaion the metadata
1328                 # declaring it to be MergedBreakwaters, but
1329                 # unnecessarily rewriting a merge seems unhelpful.
1330                 $prline->(" VanillaMerge MergedBreakwaters");
1331                 $last_anchor = $best_anchor;
1332                 $build_start->('MergedBreakwaters', $cur);
1333             }
1334
1335             my $bwb = cmdoutput @bwbcmd;
1336
1337             # OK, now we have a breakwater base, but we need the merge
1338             # base for the interchange branch because we need the delta
1339             # queue.
1340             #
1341             # This a the best merge base of our inputs which has the
1342             # breakwater merge base as an ancestor.
1343
1344             my @ibs =
1345                 grep /./,
1346                 split /\n/,
1347                 cmdoutput @ibcmd;
1348
1349             @ibs or confess 'internal error, expected anchor at least ?';
1350
1351             my $ib;
1352             my $ibleaf;
1353             foreach my $tibix (0..$#ibs) {
1354                 my $tib = $ibs[$tibix];
1355                 my $ff = is_fast_fwd $bwb, $tib;
1356                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1357                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1358                 $mwrecknote->($tibleaf, $tib);
1359                 next unless $ff;
1360                 next if $ib;
1361                 $ib = $tib;
1362                 $ibleaf = $tibleaf;
1363             }
1364
1365             $ib or $nomerge->("no suitable interchange merge base");
1366
1367             $prline->("  VanillaMerge Base");
1368             $prprdelim->();
1369             my ($btip, $bbw, $banchor) = eval {
1370                 walk $ib, 0, $report, $report_lprefix.'  ';
1371             };
1372             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1373                        $@)
1374                 if length $@;
1375
1376             $mwrecknote->("mergebase-laundered", $btip);
1377             $mwrecknote->("mergebase-breakwater", $bbw);
1378             $mwrecknote->("mergebase-anchor", $banchor);
1379
1380             my $ibinfo = { SeriesTip => $btip,
1381                            SeriesBase => $bbw,
1382                            Anchor => $banchor,
1383                            LeftRight => 'mergebase' };
1384
1385             $bbw eq $bwb
1386                 or $nomerge->("interchange merge-base ($ib)'s".
1387                               " breakwater ($bbw)".
1388                               " != breakwaters' merge-base ($bwb)");
1389
1390             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1391                  or $nomerge->("interchange merge-base ($ib)'s".
1392                                " anchor ($ibinfo->{SeriesBase})".
1393                                " != any merge input's anchor (".
1394                                (join ' ', map { $_->{Anchor} } @$ps).
1395                                ")");
1396
1397             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1398             $cl->{MergeBestAnchor} = $best_anchor;
1399             push @brw_cl, {
1400                 %$cl,
1401                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1402                 $xmsg->('constructed from vanilla merge',
1403                         ' merged-breakwater'),
1404             };
1405             push @upp_cl, {
1406                 %$cl,
1407                 SpecialMethod => 'MergeMergeSeries',
1408             };
1409             $build_start->('MergeBreakwaters', $cur);
1410         } else {
1411             printdebug "*** WALK BOMB unrecognised\n";
1412             return $bomb->();
1413         }
1414     }
1415     $prprdelim->();
1416
1417     printdebug "*** WALK prep done cur=$cur".
1418         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1419
1420     return if $nogenerate;
1421
1422     # Now we build it back up again
1423
1424     fresh_workarea();
1425
1426     my $rewriting = 0;
1427
1428     my $read_tree_upstream = sub {
1429         my ($treeish) = @_;
1430         read_tree_upstream $treeish, 0, $build;
1431     };
1432
1433     $#upp_cl = $upp_limit if defined $upp_limit;
1434
1435     my $committer_authline = calculate_committer_authline();
1436
1437     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1438
1439     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1440
1441     in_workarea sub {
1442         mkdir $rd or $!==EEXIST or die $!;
1443         my $current_method;
1444         runcmd @git, qw(read-tree), $build;
1445         foreach my $cl (qw(Debian), (reverse @brw_cl),
1446                         { SpecialMethod => 'RecordBreakwaterTip' },
1447                         qw(Upstream), (reverse @upp_cl)) {
1448             if (!ref $cl) {
1449                 $current_method = $cl;
1450                 next;
1451             }
1452             my $method = $cl->{SpecialMethod} // $current_method;
1453             my @parents = ($build);
1454             my $cltree = $cl->{CommitId};
1455             printdebug "WALK BUILD ".($cltree//'undef').
1456                 " $method (rewriting=$rewriting)\n";
1457             if ($method eq 'Debian') {
1458                 read_tree_debian($cltree);
1459             } elsif ($method eq 'Upstream') {
1460                 $read_tree_upstream->($cltree);
1461             } elsif ($method eq 'StartRewrite') {
1462                 $rewriting = 1;
1463                 next;
1464             } elsif ($method eq 'RecordBreakwaterTip') {
1465                 $breakwater = $build;
1466                 next;
1467             } elsif ($method eq 'DgitImportDebianUpdate') {
1468                 read_tree_debian($cltree);
1469             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1470                 confess unless $rewriting;
1471                 my $differs = (get_differs $build, $cltree);
1472                 next unless $differs & D_UPS;
1473                 $read_tree_upstream->($cltree);
1474                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1475             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1476                 print "Found a general merge, will try to tidy it up.\n";
1477                 $rewriting = 1;
1478                 $read_tree_upstream->($cl->{MergeBestAnchor});
1479                 $read_tree_upstream->($cl->{MergeBestAnchor});
1480                 read_tree_debian($cltree);
1481                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1482             } elsif ($method eq 'MergeMergeSeries') {
1483                 print "Running merge resolution for $cl->{CommitId}...\n";
1484                 $mwrecknote->('new-base', $build);
1485                 $build = merge_series
1486                     $build, $cl->{MergeWreckNotes},
1487                     $cl->{MergeInterchangeBaseInfo},
1488                     @{ $cl->{Parents} };
1489                 $last_anchor = $cl->{MergeBestAnchor};
1490
1491                 # Check for mismerges:
1492                 my $check = sub {
1493                     my ($against, $allow, $what) = @_;
1494                     my $differs = get_differs $build, $against;
1495                     $nomerge->(sprintf
1496        "merge misresolved: %s are not the same (%s %s d.%#x)",
1497                                $what, $against, $build, $differs)
1498                         if $differs & ~($allow | D_PAT_ADD);
1499                 };
1500
1501                 # Breakwater changes which were in each side of the
1502                 # merge will have been incorporated into the
1503                 # MergeCreateMergedBreakwaters output.  Because the
1504                 # upstream series was rebased onto the new breakwater,
1505                 # so should all of the packaging changes which were in
1506                 # the input.
1507                 $check->($input, D_UPS, 'debian files');
1508
1509                 # Upstream files are merge_series, which ought to
1510                 # have been identical to the original merge.
1511                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1512
1513                 print "Merge resolution successful.\n";
1514                 next;
1515             } else {
1516                 confess "$method ?";
1517             }
1518             if (!$rewriting) {
1519                 my $procd = (pop @processed) // 'UNDEF';
1520                 if ($cl ne $procd) {
1521                     $rewriting = 1;
1522                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1523                 }
1524             }
1525             my $newtree = cmdoutput @git, qw(write-tree);
1526             my $ch = $cl->{Hdr};
1527             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1528             $ch =~ s{^parent .*\n}{}mg;
1529             $ch =~ s{(?=^author)}{
1530                 join '', map { "parent $_\n" } @parents
1531             }me or confess "$ch ?";
1532             if ($rewriting) {
1533                 $ch =~ s{^committer .*$}{$committer_authline}m
1534                     or confess "$ch ?";
1535             }
1536             my $cf = "$rd/m$rewriting";
1537             open CD, ">", $cf or die $!;
1538             print CD $ch, "\n", $cl->{Msg} or die $!;
1539             close CD or die $!;
1540             my @cmd = (@git, qw(hash-object));
1541             push @cmd, qw(-w) if $rewriting;
1542             push @cmd, qw(-t commit), $cf;
1543             my $newcommit = cmdoutput @cmd;
1544             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1545             $build = $newcommit;
1546             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1547                 $last_anchor = $cur;
1548             }
1549         }
1550     };
1551
1552     my $final_check = get_differs $build, $input;
1553     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1554         if $final_check & ~D_PAT_ADD;
1555
1556     my @r = ($build, $breakwater, $last_anchor);
1557     printdebug "*** WALK RETURN @r\n";
1558     return @r
1559 }
1560
1561 sub get_head () {
1562     git_check_unmodified();
1563     return git_rev_parse qw(HEAD);
1564 }
1565
1566 sub update_head ($$$) {
1567     my ($old, $new, $mrest) = @_;
1568     push @deferred_updates, "update HEAD $new $old";
1569     run_deferred_updates $mrest;
1570 }
1571
1572 sub update_head_checkout ($$$) {
1573     my ($old, $new, $mrest) = @_;
1574     update_head $old, $new, $mrest;
1575     runcmd @git, qw(reset --hard);
1576 }
1577
1578 sub update_head_postlaunder ($$$) {
1579     my ($old, $tip, $reflogmsg) = @_;
1580     return if $tip eq $old;
1581     print "git-debrebase: laundered (head was $old)\n";
1582     update_head $old, $tip, $reflogmsg;
1583     # no tree changes except debian/patches
1584     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1585 }
1586
1587 sub currently_rebasing() {
1588     foreach (qw(rebase-merge rebase-apply)) {
1589         return 1 if stat_exists "$maindir_gitdir/$_";
1590     }
1591     return 0;
1592 }
1593
1594 sub bail_if_rebasing() {
1595     fail "you are in the middle of a git-rebase already"
1596         if currently_rebasing();
1597 }
1598
1599 sub do_launder_head ($) {
1600     my ($reflogmsg) = @_;
1601     my $old = get_head();
1602     record_ffq_auto();
1603     my ($tip,$breakwater) = walk $old;
1604     snags_maybe_bail();
1605     update_head_postlaunder $old, $tip, $reflogmsg;
1606     return ($tip,$breakwater);
1607 }
1608
1609 sub cmd_launder_v0 () {
1610     badusage "no arguments to launder-v0 allowed" if @ARGV;
1611     my $old = get_head();
1612     my ($tip,$breakwater,$last_anchor) = walk $old;
1613     update_head_postlaunder $old, $tip, 'launder';
1614     printf "# breakwater tip\n%s\n", $breakwater;
1615     printf "# working tip\n%s\n", $tip;
1616     printf "# last anchor\n%s\n", $last_anchor;
1617 }
1618
1619 sub defaultcmd_rebase () {
1620     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1621     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1622     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1623 }
1624
1625 sub cmd_analyse () {
1626     badusage "analyse does not support any options"
1627         if @ARGV and $ARGV[0] =~ m/^-/;
1628     badusage "too many arguments to analyse" if @ARGV>1;
1629     my ($old) = @ARGV;
1630     if (defined $old) {
1631         $old = git_rev_parse $old;
1632     } else {
1633         $old = git_rev_parse 'HEAD';
1634     }
1635     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1636     STDOUT->error and die $!;
1637 }
1638
1639 sub ffq_prev_branchinfo () {
1640     my $current = git_get_symref();
1641     return gdr_ffq_prev_branchinfo($current);
1642 }
1643
1644 sub ffq_check ($;$$) {
1645     # calls $ff and/or $notff zero or more times
1646     # then returns either (status,message) where status is
1647     #    exists
1648     #    detached
1649     #    weird-symref
1650     #    notbranch
1651     # or (undef,undef, $ffq_prev,$gdrlast)
1652     # $ff and $notff are called like this:
1653     #   $ff->("message for stdout\n");
1654     #   $notff->('snag-name', $message);
1655     # normally $currentval should be HEAD
1656     my ($currentval, $ff, $notff) =@_;
1657
1658     $ff //= sub { print $_[0] or die $!; };
1659     $notff //= \&snag;
1660
1661     my ($status, $message, $current, $ffq_prev, $gdrlast)
1662         = ffq_prev_branchinfo();
1663     return ($status, $message) unless $status eq 'branch';
1664
1665     my $exists = git_get_ref $ffq_prev;
1666     return ('exists',"$ffq_prev already exists") if $exists;
1667
1668     return ('not-branch', 'HEAD symref is not to refs/heads/')
1669         unless $current =~ m{^refs/heads/};
1670     my $branch = $';
1671
1672     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1673     my %checked;
1674
1675     printdebug "ffq check_specs @check_specs\n";
1676
1677     my $check = sub {
1678         my ($lrref, $desc) = @_;
1679         printdebug "ffq might check $lrref ($desc)\n";
1680         my $invert;
1681         for my $chk (@check_specs) {
1682             my $glob = $chk;
1683             $invert = $glob =~ s{^[!^]}{};
1684             last if fnmatch $glob, $lrref;
1685         }
1686         return if $invert;
1687         my $lrval = git_get_ref $lrref;
1688         return unless length $lrval;
1689
1690         if (is_fast_fwd $lrval, $currentval) {
1691             $ff->("OK, you are ahead of $lrref\n");
1692             $checked{$lrref} = 1;
1693         } elsif (is_fast_fwd $currentval, $lrval) {
1694             $checked{$lrref} = -1;
1695             $notff->('behind', "you are behind $lrref, divergence risk");
1696         } else {
1697             $checked{$lrref} = -1;
1698             $notff->('diverged', "you have diverged from $lrref");
1699         }
1700     };
1701
1702     my $merge = cfg "branch.$branch.merge",1;
1703     if (defined $merge and $merge =~ m{^refs/heads/}) {
1704         my $rhs = $';
1705         printdebug "ffq merge $rhs\n";
1706         my $check_remote = sub {
1707             my ($remote, $desc) = @_;
1708             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1709             return unless defined $remote;
1710             $check->("refs/remotes/$remote/$rhs", $desc);
1711         };
1712         $check_remote->((scalar cfg "branch.$branch.remote",1),
1713                         'remote fetch/merge branch');
1714         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1715                         (scalar cfg "branch.$branch.pushDefault",1),
1716                         'remote push branch');
1717     }
1718     if ($branch =~ m{^dgit/}) {
1719         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1720     } elsif ($branch =~ m{^master$}) {
1721         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1722     }
1723     return (undef, undef, $ffq_prev, $gdrlast);
1724 }
1725
1726 sub record_ffq_prev_deferred () {
1727     # => ('status', "message")
1728     # 'status' may be
1729     #    deferred          message is undef
1730     #    exists
1731     #    detached
1732     #    weird-symref
1733     #    notbranch
1734     # if not ff from some branch we should be ff from, is an snag
1735     # if "deferred", will have added something about that to
1736     #   @deferred_update_messages, and also maybe printed (already)
1737     #   some messages about ff checks
1738     bail_if_rebasing();
1739     my $currentval = get_head();
1740
1741     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1742     return ($status,$message) if defined $status;
1743
1744     snags_maybe_bail();
1745
1746     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1747     push @deferred_updates, "delete $gdrlast";
1748     push @deferred_update_messages, "Recorded previous head for preservation";
1749     return ('deferred', undef);
1750 }
1751
1752 sub record_ffq_auto () {
1753     my ($status, $message) = record_ffq_prev_deferred();
1754     if ($status eq 'deferred' || $status eq 'exists') {
1755     } else {
1756         snag $status, "could not record ffq-prev: $message";
1757         snags_maybe_bail();
1758     }
1759 }
1760
1761 sub ffq_prev_info () {
1762     bail_if_rebasing();
1763     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1764     my ($status, $message, $current, $ffq_prev, $gdrlast)
1765         = ffq_prev_branchinfo();
1766     if ($status ne 'branch') {
1767         snag $status, "could not check ffq-prev: $message";
1768         snags_maybe_bail();
1769     }
1770     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1771     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1772 }
1773
1774 sub stitch ($$$$$) {
1775     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1776
1777     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1778
1779     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1780         my $differs = get_differs $old_head, $ffq_prev_commitish;
1781         unless ($differs & ~D_PAT_ADD) {
1782             # ffq-prev is ahead of us, and the only tree changes it has
1783             # are possibly addition of things in debian/patches/.
1784             # Just wind forwards rather than making a pointless pseudomerge.
1785             push @deferred_updates,
1786                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1787             update_head_checkout $old_head, $ffq_prev_commitish,
1788                 "stitch (fast forward)";
1789             return;
1790         }
1791     }
1792     fresh_workarea();
1793     # We make pseudomerges with L as the contributing parent.
1794     # This makes git rev-list --first-parent work properly.
1795     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1796         'Declare fast forward / record previous work',
1797         "[git-debrebase pseudomerge: $prose]",
1798     ];
1799     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1800     update_head $old_head, $new_head, "stitch: $prose";
1801 }
1802
1803 sub do_stitch ($;$) {
1804     my ($prose, $unclean) = @_;
1805
1806     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1807     if (!$ffq_prev_commitish) {
1808         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1809         return;
1810     }
1811     my $dangling_head = get_head();
1812
1813     keycommits $dangling_head, $unclean,$unclean,$unclean;
1814     snags_maybe_bail();
1815
1816     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1817 }
1818
1819 sub upstream_commitish_search ($$) {
1820     my ($upstream_version, $tried) = @_;
1821     # todo: at some point maybe use git-deborig to do this
1822     foreach my $tagpfx ('', 'v', 'upstream/') {
1823         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1824         my $new_upstream = git_get_ref "refs/tags/$tag";
1825         push @$tried, $tag;
1826         return $new_upstream if length $new_upstream;
1827     }
1828 }
1829
1830 sub resolve_upstream_version ($$) {
1831     my ($new_upstream, $upstream_version) = @_;
1832
1833     if (!defined $new_upstream) {
1834         my @tried;
1835         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1836         if (!length $new_upstream) {
1837             fail "Could not determine appropriate upstream commitish.\n".
1838                 " (Tried these tags: @tried)\n".
1839                 " Check version, and specify upstream commitish explicitly.";
1840         }
1841     }
1842     $new_upstream = git_rev_parse $new_upstream;
1843
1844     return $new_upstream;
1845 }
1846
1847 sub cmd_new_upstream () {
1848     # automatically and unconditionally launders before rebasing
1849     # if rebase --abort is used, laundering has still been done
1850
1851     my %pieces;
1852
1853     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1854
1855     # parse args - low commitment
1856     my $spec_version = shift @ARGV;
1857     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1858     fail "bad version number \`$spec_version'" unless defined $new_version;
1859     if ($new_version->is_native()) {
1860         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1861     }
1862
1863     my $new_upstream = shift @ARGV;
1864     my $new_upstream_version = upstreamversion  $new_version;
1865     $new_upstream =
1866         resolve_upstream_version $new_upstream, $new_upstream_version;
1867
1868     record_ffq_auto();
1869
1870     my $piece = sub {
1871         my ($n, @x) = @_; # may be ''
1872         my $pc = $pieces{$n} //= {
1873             Name => $n,
1874             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1875         };
1876         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1877         $pc;
1878     };
1879
1880     my @newpieces;
1881     my $newpiece = sub {
1882         my ($n, @x) = @_; # may be ''
1883         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1884         push @newpieces, $pc;
1885     };
1886
1887     $newpiece->('',
1888         OldIx => 0,
1889         New => $new_upstream,
1890     );
1891     while (@ARGV && $ARGV[0] !~ m{^-}) {
1892         my $n = shift @ARGV;
1893
1894         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1895             unless @ARGV && $ARGV[0] !~ m{^-};
1896
1897         my $c = git_rev_parse shift @ARGV;
1898         die unless $n =~ m/^$extra_orig_namepart_re$/;
1899         $newpiece->($n, New => $c);
1900     }
1901
1902     # now we need to investigate the branch this generates the
1903     # laundered version but we don't switch to it yet
1904     my $old_head = get_head();
1905     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1906
1907     my $old_bw_cl = classify $old_bw;
1908     my $old_anchor_cl = classify $old_anchor;
1909     my $old_upstream;
1910     if (!$old_anchor_cl->{OrigParents}) {
1911         snag 'anchor-treated',
1912             'old anchor is recognised due to --anchor, cannot check upstream';
1913     } else {
1914         $old_upstream = parsecommit
1915             $old_anchor_cl->{OrigParents}[0]{CommitId};
1916         $piece->('', Old => $old_upstream->{CommitId});
1917     }
1918
1919     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1920         if ($old_upstream->{Msg} =~
1921  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1922            ) {
1923             my @oldpieces = (split / /, $1);
1924             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1925             if ($old_n_parents != @oldpieces &&
1926                 $old_n_parents != @oldpieces + 1) {
1927                 snag 'upstream-confusing', sprintf
1928                     "previous upstream combine %s".
1929                     " mentions %d pieces (each implying one parent)".
1930                     " but has %d parents".
1931                     " (one per piece plus maybe a previous combine)",
1932                     $old_upstream->{CommitId},
1933                     (scalar @oldpieces),
1934                     $old_n_parents;
1935             } elsif ($oldpieces[0] ne '.') {
1936                 snag 'upstream-confusing', sprintf
1937                     "previous upstream combine %s".
1938                     " first piece is not \`.'",
1939                     $oldpieces[0];
1940             } else {
1941                 $oldpieces[0] = '';
1942                 foreach my $i (0..$#oldpieces) {
1943                     my $n = $oldpieces[$i];
1944                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1945                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1946                 }
1947             }
1948         } else {
1949             snag 'upstream-confusing',
1950                 "previous upstream $old_upstream->{CommitId} is from".
1951                " git-debrebase but not an \`upstream-combine' commit";
1952         }
1953     }
1954
1955     foreach my $pc (values %pieces) {
1956         if (!$old_upstream) {
1957             # we have complained already
1958         } elsif (!$pc->{Old}) {
1959             snag 'upstream-new-piece',
1960                 "introducing upstream piece \`$pc->{Name}'";
1961         } elsif (!$pc->{New}) {
1962             snag 'upstream-rm-piece',
1963                 "dropping upstream piece \`$pc->{Name}'";
1964         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1965             snag 'upstream-not-ff',
1966                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1967         }
1968     }
1969
1970     printdebug "%pieces = ", (dd \%pieces), "\n";
1971     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1972
1973     snags_maybe_bail();
1974
1975     my $new_bw;
1976
1977     fresh_workarea();
1978     in_workarea sub {
1979         my @upstream_merge_parents;
1980
1981         if (!any_snags()) {
1982             push @upstream_merge_parents, $old_upstream->{CommitId};
1983         }
1984
1985         foreach my $pc (@newpieces) { # always has '' first
1986             if ($pc->{Name}) {
1987                 read_tree_subdir $pc->{Name}, $pc->{New};
1988             } else {
1989                 runcmd @git, qw(read-tree), $pc->{New};
1990             }
1991             push @upstream_merge_parents, $pc->{New};
1992         }
1993
1994         # index now contains the new upstream
1995
1996         if (@newpieces > 1) {
1997             # need to make the upstream subtree merge commit
1998             $new_upstream = make_commit \@upstream_merge_parents,
1999                 [ "Combine upstreams for $new_upstream_version",
2000  ("[git-debrebase upstream-combine . ".
2001  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2002  ": new upstream]"),
2003                 ];
2004         }
2005
2006         # $new_upstream is either the single upstream commit, or the
2007         # combined commit we just made.  Either way it will be the
2008         # "upstream" parent of the anchor merge.
2009
2010         read_tree_subdir 'debian', "$old_bw:debian";
2011
2012         # index now contains the anchor merge contents
2013         $new_bw = make_commit [ $old_bw, $new_upstream ],
2014             [ "Update to upstream $new_upstream_version",
2015  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2016             ];
2017
2018         my $clogsignoff = cmdoutput qw(git show),
2019             '--pretty=format:%an <%ae>  %aD',
2020             $new_bw;
2021
2022         # Now we have to add a changelog stanza so the Debian version
2023         # is right.
2024         die if unlink "debian";
2025         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2026         unlink "debian/changelog" or $!==ENOENT or die $!;
2027         mkdir "debian" or die $!;
2028         open CN, ">", "debian/changelog" or die $!;
2029         my $oldclog = git_cat_file ":debian/changelog";
2030         $oldclog =~ m/^($package_re) \(\S+\) / or
2031             fail "cannot parse old changelog to get package name";
2032         my $p = $1;
2033         print CN <<END, $oldclog or die $!;
2034 $p ($new_version) UNRELEASED; urgency=medium
2035
2036   * Update to new upstream version $new_upstream_version.
2037
2038  -- $clogsignoff
2039
2040 END
2041         close CN or die $!;
2042         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2043
2044         # Now we have the final new breakwater branch in the index
2045         $new_bw = make_commit [ $new_bw ],
2046             [ "Update changelog for new upstream $new_upstream_version",
2047               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2048             ];
2049     };
2050
2051     # we have constructed the new breakwater. we now need to commit to
2052     # the laundering output, because git-rebase can't easily be made
2053     # to make a replay list which is based on some other branch
2054
2055     update_head_postlaunder $old_head, $old_laundered_tip,
2056         'launder for new upstream';
2057
2058     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2059     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2060         "debrebase new-upstream $new_version: rebase";
2061     runcmd @cmd;
2062     # now it's for the user to sort out
2063 }
2064
2065 sub cmd_record_ffq_prev () {
2066     badusage "no arguments allowed" if @ARGV;
2067     my ($status, $msg) = record_ffq_prev_deferred();
2068     if ($status eq 'exists' && $opt_noop_ok) {
2069         print "Previous head already recorded\n" or die $!;
2070     } elsif ($status eq 'deferred') {
2071         run_deferred_updates 'record-ffq-prev';
2072     } else {
2073         fail "Could not preserve: $msg";
2074     }
2075 }
2076
2077 sub cmd_anchor () {
2078     badusage "no arguments allowed" if @ARGV;
2079     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2080     print "$bw\n" or die $!;
2081 }
2082
2083 sub cmd_breakwater () {
2084     badusage "no arguments allowed" if @ARGV;
2085     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2086     print "$bw\n" or die $!;
2087 }
2088
2089 sub cmd_status () {
2090     badusage "no arguments allowed" if @ARGV;
2091
2092     # todo: gdr status should print divergence info
2093     # todo: gdr status should print upstream component(s) info
2094     # todo: gdr should leave/maintain some refs with this kind of info ?
2095
2096     my $oldest = { Badness => 0 };
2097     my $newest;
2098     my $note = sub {
2099         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2100         if ($oldest->{Badness} < $badness) {
2101             $oldest = $newest = undef;
2102         }
2103         $oldest = {
2104                    Badness => $badness,
2105                    CommitId => $cl->{CommitId},
2106                    OurMsg => $ourmsg,
2107                    KcMsg => $kcmsg,
2108                   };
2109         $newest //= $oldest;
2110     };
2111     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2112         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2113         sub { $note->(2, 'branch is unlaundered', @_); },
2114         sub { $note->(3, 'branch needs laundering', @_); },
2115         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2116
2117     my $prcommitinfo = sub {
2118         my ($cid) = @_;
2119         flush STDOUT or die $!;
2120         runcmd @git, qw(--no-pager log -n1),
2121             '--pretty=format:    %h %s%n',
2122             $cid;
2123     };
2124
2125     print "current branch contents, in git-debrebase terms:\n";
2126     if (!$oldest->{Badness}) {
2127         print "  branch is laundered\n";
2128     } else {
2129         print "  $oldest->{OurMsg}\n";
2130         my $printed = '';
2131         foreach my $info ($oldest, $newest) {
2132             my $cid = $info->{CommitId};
2133             next if $cid eq $printed;
2134             $printed = $cid;
2135             print "  $info->{KcMsg}\n";
2136             $prcommitinfo->($cid);
2137         }
2138     }
2139
2140     my $prab = sub {
2141         my ($cid, $what) = @_;
2142         if (!defined $cid) {
2143             print "  $what is not well-defined\n";
2144         } else {
2145             print "  $what\n";
2146             $prcommitinfo->($cid);
2147         }
2148     };
2149     print "key git-debrebase commits:\n";
2150     $prab->($anchor, 'anchor');
2151     $prab->($bw, 'breakwater');
2152
2153     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2154         ffq_prev_branchinfo();
2155
2156     print "branch and ref status, in git-debrebase terms:\n";
2157     if ($ffq_msg) {
2158         print "  $ffq_msg\n";
2159     } else {
2160         $ffq_prev = git_get_ref $ffq_prev;
2161         $gdrlast = git_get_ref $gdrlast;
2162         if ($ffq_prev) {
2163             print "  unstitched; previous tip was:\n";
2164             $prcommitinfo->($ffq_prev);
2165         } elsif (!$gdrlast) {
2166             print "  stitched? (no record of git-debrebase work)\n";
2167         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2168             print "  stitched\n";
2169         } else {
2170             print "  not git-debrebase (diverged since last stitch)\n"
2171         }
2172     }
2173     print "you are currently rebasing\n" if currently_rebasing();
2174 }
2175
2176 sub cmd_stitch () {
2177     my $prose = 'stitch';
2178     getoptions("stitch",
2179                'prose=s', \$prose);
2180     badusage "no arguments allowed" if @ARGV;
2181     do_stitch $prose, 0;
2182 }
2183 sub cmd_prepush () { cmd_stitch(); }
2184
2185 sub cmd_quick () {
2186     badusage "no arguments allowed" if @ARGV;
2187     do_launder_head 'launder for git-debrebase quick';
2188     do_stitch 'quick';
2189 }
2190
2191 sub cmd_conclude () {
2192     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2193     if (!$ffq_prev_commitish) {
2194         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2195         return;
2196     }
2197     my $dangling_head = get_head();
2198
2199     badusage "no arguments allowed" if @ARGV;
2200     do_launder_head 'launder for git-debrebase quick';
2201     do_stitch 'quick';
2202 }
2203
2204 sub cmd_scrap () {
2205     if (currently_rebasing()) {
2206         runcmd @git, qw(rebase --abort);
2207         push @deferred_updates, 'verify HEAD HEAD';
2208         # noop, but stops us complaining that scrap was a noop
2209     }
2210     badusage "no arguments allowed" if @ARGV;
2211     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2212     my $scrapping_head;
2213     if ($ffq_prev_commitish) {
2214         $scrapping_head = get_head();
2215         push @deferred_updates,
2216             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2217             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2218     }
2219     if (!@deferred_updates) {
2220         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2221         finish 0;
2222     }
2223     snags_maybe_bail();
2224     if ($scrapping_head) {
2225         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2226     } else {
2227         run_deferred_updates "scrap";
2228     }
2229 }
2230
2231 sub make_patches_staged ($) {
2232     my ($head) = @_;
2233     # Produces the patches that would result from $head if it were
2234     # laundered.
2235     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2236     fresh_workarea();
2237     in_workarea sub {
2238         gbp_pq_export 'bw', $secret_bw, $secret_head;
2239     };
2240 }
2241
2242 sub make_patches ($) {
2243     my ($head) = @_;
2244     keycommits $head, 0, \&snag;
2245     make_patches_staged $head;
2246     my $out;
2247     in_workarea sub {
2248         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2249         runcmd @git, qw(read-tree), $head;
2250         read_tree_subdir 'debian/patches', $ptree;
2251         $out = make_commit [$head], [
2252             'Commit patch queue (exported by git-debrebase)',
2253             '[git-debrebase: export and commit patches]',
2254         ];
2255     };
2256     return $out;
2257 }
2258
2259 sub cmd_make_patches () {
2260     my $opt_quiet_would_amend;
2261     getoptions("make-patches",
2262                'quiet-would-amend!', \$opt_quiet_would_amend);
2263     badusage "no arguments allowed" if @ARGV;
2264     bail_if_rebasing();
2265     my $old_head = get_head();
2266     my $new = make_patches $old_head;
2267     my $d = get_differs $old_head, $new;
2268     if ($d == 0) {
2269         fail "No (more) patches to export." unless $opt_noop_ok;
2270         return;
2271     } elsif ($d == D_PAT_ADD) {
2272         snags_maybe_bail();
2273         update_head_checkout $old_head, $new, 'make-patches';
2274     } else {
2275         print STDERR failmsg
2276             "Patch export produced patch amendments".
2277             " (abandoned output commit $new).".
2278             "  Try laundering first."
2279             unless $opt_quiet_would_amend;
2280         finish 7;
2281     }
2282 }
2283
2284 sub cmd_convert_from_gbp () {
2285     badusage "want only 1 optional argument, the upstream git commitish"
2286         unless @ARGV<=1;
2287
2288     my $clogp = parsechangelog();
2289     my $version = $clogp->{'Version'}
2290         // die "missing Version from changelog";
2291
2292     my ($upstream_spec) = @ARGV;
2293
2294     my $upstream_version = upstreamversion $version;
2295     my $upstream =
2296         resolve_upstream_version($upstream_spec, $upstream_version);
2297
2298     my $old_head = get_head();
2299
2300     my $upsdiff = get_differs $upstream, $old_head;
2301     if ($upsdiff & D_UPS) {
2302         runcmd @git, qw(--no-pager diff --stat),
2303             $upstream, $old_head,
2304             qw( -- :!/debian :/);
2305         fail <<END;
2306 upstream ($upstream_spec) and HEAD are not
2307 identical in upstream files.  See diffstat above, or run
2308   git diff $upstream_spec HEAD -- :!/debian :/
2309 END
2310     }
2311
2312     if (!is_fast_fwd $upstream, $old_head) {
2313         snag 'upstream-not-ancestor',
2314             "upstream ($upstream) is not an ancestor of HEAD";
2315     } else {
2316         my $wrong = cmdoutput
2317             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2318              qw(-- :/ :!/debian));
2319         if (length $wrong) {
2320             snag 'unexpected-upstream-changes',
2321                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2322             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2323         }
2324     }
2325
2326     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2327         snag 'upstream-has-debian',
2328             "upstream ($upstream) contains debian/ directory";
2329     }
2330
2331     my $previous_dgit_view = eval {
2332         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2333         my ($lvsn, $suite);
2334         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2335             my ($stz, $desc) = @_;
2336             no warnings qw(exiting);
2337             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2338             next unless $stz->{Date};
2339             next unless $stz->{Distribution} ne 'UNRELEASED';
2340             $lvsn = $stz->{Version};
2341             $suite = $stz->{Distribution};
2342             last;
2343         };
2344         die "neither of the first two changelog entries are released\n"
2345             unless defined $lvsn;
2346         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2347         my $mtag_pat = debiantag_maintview $lvsn, '*';
2348         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2349             $mtag_pat;
2350         die "could not find suitable maintainer view tag $mtag_pat\n"
2351             unless $mtag_pat =~ m{/};
2352         is_fast_fwd $mtag, 'HEAD' or
2353             die "HEAD is not FF from maintainer tag $mtag!";
2354         my $dtag = "archive/$mtag";
2355         is_fast_fwd $mtag, $dtag or
2356             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2357         print "will stitch in dgit view, $dtag\n";
2358         git_rev_parse $dtag;
2359     };
2360     if (!$previous_dgit_view) {
2361         $@ =~ s/^\n+//;
2362         chomp $@;
2363         print STDERR "cannot stitch in dgit view: $@\n";
2364     }
2365
2366     snags_maybe_bail_early();
2367
2368     my $work;
2369
2370     fresh_workarea();
2371     in_workarea sub {
2372         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2373         # make a branch out of the patch queue - we'll want this in a mo
2374         runcmd qw(gbp pq import);
2375         # strip the patches out
2376         runcmd @git, qw(checkout -q gdr-internal~0);
2377         rm_subdir_cached 'debian/patches';
2378         $work = make_commit ['HEAD'], [
2379  'git-debrebase convert-from-gbp: drop patches from tree',
2380  'Delete debian/patches, as part of converting to git-debrebase format.',
2381  '[git-debrebase convert-from-gbp: drop patches from tree]'
2382                               ];
2383         # make the anchor merge
2384         # the tree is already exactly right
2385         $work = make_commit [$work, $upstream], [
2386  'git-debrebase import: declare upstream',
2387  'First breakwater merge.',
2388  '[git-debrebase anchor: declare upstream]'
2389                               ];
2390
2391         # rebase the patch queue onto the new breakwater
2392         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2393         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2394         $work = git_rev_parse 'HEAD';
2395
2396         if ($previous_dgit_view) {
2397             $work = make_commit [$work, $previous_dgit_view], [
2398  'git-debrebase import: declare ff from dgit archive view',
2399  '[git-debrebase pseudomerge: import-from-gbp]',
2400             ];
2401         }
2402     };
2403
2404     ffq_check $work;
2405     snags_maybe_bail();
2406     update_head_checkout $old_head, $work, 'convert-from-gbp';
2407 }
2408
2409 sub cmd_convert_to_gbp () {
2410     badusage "no arguments allowed" if @ARGV;
2411     my $head = get_head();
2412     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2413     keycommits $head, 0;
2414     my $out;
2415     make_patches_staged $head;
2416     in_workarea sub {
2417         $out = make_commit ['HEAD'], [
2418             'Commit patch queue (converted from git-debrebase format)',
2419             '[git-debrebase convert-to-gbp: commit patches]',
2420         ];
2421     };
2422     if (defined $ffq) {
2423         push @deferred_updates, "delete $ffq";
2424         push @deferred_updates, "delete $gdrlast";
2425     }
2426     snags_maybe_bail();
2427     update_head_checkout $head, $out, "convert to gbp (v0)";
2428     print <<END or die $!;
2429 git-debrebase: converted to git-buildpackage branch format
2430 git-debrebase: WARNING: do not now run "git-debrebase" any more
2431 git-debrebase: WARNING: doing so would drop all upstream patches!
2432 END
2433 }
2434
2435 sub cmd_convert_from_dgit_view () {
2436     my $clogp = parsechangelog();
2437
2438     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2439     my $do_origs = 1;
2440     my $do_tags = 1;
2441     my $always = 0;
2442     my $diagnose = 0;
2443
2444     getoptions("convert-from-dgit-view",
2445                'diagnose!', \$diagnose,
2446                'build-products-dir:s', \$bpd,
2447                'origs!', \$do_origs,
2448                'tags!', \$do_tags,
2449                'always-convert-anyway!', \$always);
2450     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2451
2452     my @upstreams;
2453
2454     if (@ARGV) {
2455         my $spec = shift @ARGV;
2456         my $commit = git_rev_parse "$spec^{commit}";
2457         push @upstreams, { Commit => $commit,
2458                            Source => "$ARGV[0], from command line",
2459                            Only => 1,
2460                          };
2461     }
2462
2463     my $head = get_head();
2464
2465     if (!$always) {
2466         my $troubles = 0;
2467         my $trouble = sub { $troubles++; };
2468         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2469         printdebug "troubles=$troubles\n";
2470         if (!$troubles) {
2471             print STDERR <<END;
2472 $us: Branch already seems to be in git-debrebase format!
2473 $us: --always-convert-anyway would do the conversion operation anyway
2474 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2475 END
2476             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2477             finish 0;
2478         }
2479     }
2480
2481     snags_maybe_bail_early();
2482
2483     my $version = upstreamversion $clogp->{Version};
2484     print STDERR "Considering possible commits corresponding to upstream:\n";
2485
2486     if (!@upstreams) {
2487         if ($do_tags) {
2488             my @tried;
2489             my $ups_tag = upstream_commitish_search $version, \@tried;
2490             if ($ups_tag) {
2491                 my $this = "git tag $tried[-1]";
2492                 push @upstreams, { Commit => $ups_tag,
2493                                    Source => $this,
2494                                  };
2495             } else {
2496                 printf STDERR
2497                     " git tag: no suitable tag found (tried %s)\n",
2498                     "@tried";
2499             }
2500         }
2501         if ($do_origs) {
2502             my $p = $clogp->{'Source'};
2503             # we do a quick check to see if there are plausible origs
2504             my $something=0;
2505             if (!opendir BPD, $bpd) {
2506                 die "$bpd: opendir: $!" unless $!==ENOENT;
2507             } else {
2508                 while ($!=0, my $f = readdir BPD) {
2509                     next unless is_orig_file_of_p_v $f, $p, $version;
2510                     printf STDERR
2511                         " orig: found what looks like a .orig, %s\n",
2512                         "$bpd/$f";
2513                     $something=1;
2514                     last;
2515                 }
2516                 die "read $bpd: $!" if $!;
2517                 closedir BPD;
2518             }
2519             if ($something) {
2520                 my $tree = cmdoutput
2521                     @dgit, qw(--build-products-dir), $bpd,
2522                     qw(print-unapplied-treeish);
2523                 fresh_workarea();
2524                 in_workarea sub {
2525                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2526                     rm_subdir_cached 'debian';
2527                     $tree = cmdoutput @git, qw(write-tree);
2528                     my $ups_synth = make_commit [], [ <<END, <<END,
2529 Import effective orig tree for upstream version $version
2530 END
2531 This includes the contents of the .orig(s), minus any debian/ directory.
2532
2533 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2534 END
2535                                                     ];
2536                     push @upstreams, { Commit => $ups_synth,
2537                                        Source => "orig(s) imported via dgit",
2538                                      };
2539                 }
2540             } else {
2541                 printf STDERR
2542                     " orig: no suitable origs found (looked for %s in %s)\n",
2543                     "${p}_".(stripeoch $version)."...", $bpd;
2544             }
2545         }
2546     }
2547
2548     my $some_patches = stat_exists 'debian/patches/series';
2549
2550     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2551
2552     my $result;
2553     foreach my $u (@upstreams) {
2554         my $work = $head;
2555         fresh_workarea();
2556         in_workarea sub {
2557             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2558             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2559             runcmd @git, qw(clean -xdff);
2560             runcmd @git, qw(checkout), $head, qw(-- debian);
2561             if ($some_patches) {
2562                 rm_subdir_cached 'debian/patches';
2563                 $work = make_commit [ $work ], [
2564  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2565  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2566  "to git-debrebase format.  Upstream changes will appear as commits.",
2567  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2568                                            ];
2569             }
2570             $work = make_commit [ $work, $u->{Commit} ], [
2571  'git-debrebase convert-from-dgit-view: declare upstream',
2572  '(Re)constructed breakwater merge.',
2573  '[git-debrebase anchor: declare upstream]'
2574                                                          ];
2575             runcmd @git, qw(checkout --quiet -b mk), $work;
2576             if ($some_patches) {
2577                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2578                 runcmd @git, qw(reset --quiet);
2579                 my @gbp_cmd = (qw(gbp pq import));
2580                 if (!$diagnose) {
2581                     my $gbp_err = "../gbp-pq-err";
2582                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2583                 }
2584                 my $r = system @gbp_cmd;
2585                 if ($r) {
2586                     printf STDERR
2587                         " %s: couldn't apply patches: gbp pq %s",
2588                         $u->{Source}, waitstatusmsg();
2589                     return;
2590                 }
2591             }
2592             my $work = git_rev_parse qw(HEAD);
2593             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2594             if (length $diffout) {
2595                 print STDERR
2596                     " $u->{Source}: applying patches gives different tree\n";
2597                 print STDERR $diffout if $diagnose;
2598                 return;
2599             }
2600             # OMG!
2601             $u->{Result} = $work;
2602             $result = $u;
2603         };
2604         last if $result;
2605     }
2606
2607     if (!$result) {
2608         fail <<END;
2609 Could not find or construct a suitable upstream commit.
2610 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2611 upstream commmit explicitly or provide suitable origs.
2612 END
2613     }
2614
2615     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2616
2617     ffq_check $result->{Result};
2618     snags_maybe_bail();
2619     update_head_checkout $head, $result->{Result},
2620         'convert-from-dgit-view';
2621 }
2622
2623 sub cmd_record_resolved_merge () {
2624     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2625     my $new = get_head();
2626     my $method;
2627
2628     print "Checking how you have resolved the merge problem\n";
2629     my $nope = sub { print "Not $method: @_"; 0; };
2630
2631     my $maybe = sub { print "Seems to be $method.\n"; };
2632     my $yes = sub {
2633         my ($key, $ref) = @_;
2634         print "OK.  You can switch branches and try git-debrebase again.\n";
2635         confess "todo $ref"; # xxx
2636         1;
2637     };
2638
2639     fresh_workarea 'merge';
2640     sub {
2641         $method = 'vanilla-merge patchqueue';
2642         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2643         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2644         foreach my $lr (qw(left right)) {
2645             my $n = "$wrecknoteprefix/$lr-patchqueue";
2646             my $lrpq = git_get_ref $n;
2647             $lrpq or return $nope->("wreckage did not contain patchqueues");
2648             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2649         }
2650         $maybe->();
2651         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2652             or die "wreckage element $wrecknoteprefix/new-base missing";
2653         my $result = merge_series_patchqueue_convert
2654             {}, $newbase, $new;
2655         $yes->("vanilla-merge $vanilla", $result);
2656         1;
2657     }->() or sub {
2658         fail "No resolved merge method seems applicable.\n";
2659     }->();
2660 }
2661
2662 sub cmd_downstream_rebase_launder_v0 () {
2663     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2664     my ($base) = @ARGV;
2665     $base = git_rev_parse $base;
2666     my $old_head = get_head();
2667     my $current = $old_head;
2668     my $topmost_keep;
2669     for (;;) {
2670         if ($current eq $base) {
2671             $topmost_keep //= $current;
2672             print " $current BASE stop\n";
2673             last;
2674         }
2675         my $cl = classify $current;
2676         print " $current $cl->{Type}";
2677         my $keep = 0;
2678         my $p0 = $cl->{Parents}[0]{CommitId};
2679         my $next;
2680         if ($cl->{Type} eq 'Pseudomerge') {
2681             print " ^".($cl->{Contributor}{Ix}+1);
2682             $next = $cl->{Contributor}{CommitId};
2683         } elsif ($cl->{Type} eq 'AddPatches' or
2684                  $cl->{Type} eq 'Changelog') {
2685             print " strip";
2686             $next = $p0;
2687         } else {
2688             print " keep";
2689             $next = $p0;
2690             $keep = 1;
2691         }
2692         print "\n";
2693         if ($keep) {
2694             $topmost_keep //= $current;
2695         } else {
2696             die "to-be stripped changes not on top of the branch\n"
2697                 if $topmost_keep;
2698         }
2699         $current = $next;
2700     }
2701     if ($topmost_keep eq $old_head) {
2702         print "unchanged\n";
2703     } else {
2704         print "updating to $topmost_keep\n";
2705         update_head_checkout
2706             $old_head, $topmost_keep,
2707             'downstream-rebase-launder-v0';
2708     }
2709 }
2710
2711 getoptions_main
2712           ("bad options\n",
2713            "D+" => \$debuglevel,
2714            'noop-ok', => \$opt_noop_ok,
2715            'f=s' => \@snag_force_opts,
2716            'anchor=s' => \@opt_anchors,
2717            '--dgit=s' => \($dgit[0]),
2718            'force!',
2719            '-i:s' => sub {
2720                my ($opt,$val) = @_;
2721                badusage "git-debrebase: no cuddling to -i for git-rebase"
2722                    if length $val;
2723                die if $opt_defaultcmd_interactive; # should not happen
2724                $opt_defaultcmd_interactive = [ qw(-i) ];
2725                # This access to @ARGV is excessive familiarity with
2726                # Getopt::Long, but there isn't another sensible
2727                # approach.  '-i=s{0,}' does not work with bundling.
2728                push @$opt_defaultcmd_interactive, @ARGV;
2729                @ARGV=();
2730            },
2731            'help' => sub { print $usage_message or die $!; finish 0; },
2732            );
2733
2734 initdebug('git-debrebase ');
2735 enabledebug if $debuglevel;
2736
2737 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2738 chdir $toplevel or die "chdir $toplevel: $!";
2739
2740 $rd = fresh_playground "$playprefix/misc";
2741
2742 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2743
2744 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2745     defaultcmd_rebase();
2746 } else {
2747     my $cmd = shift @ARGV;
2748     my $cmdfn = $cmd;
2749     $cmdfn =~ y/-/_/;
2750     $cmdfn = ${*::}{"cmd_$cmdfn"};
2751
2752     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2753     $cmdfn->();
2754 }
2755
2756 finish 0;