git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$) {
 267     my ($treeish, $keep_patches) = @_;
 268     my $save = cmdoutput @git, qw(write-tree --prefix=debian/);
 269     runcmd @git, qw(read-tree), $treeish;
 270     read_tree_subdir 'debian', $save;
 271     rm_subdir_cached 'debian/patches' unless $keep_patches;
 272 };
 273
 274 sub make_commit ($$) {
 275     my ($parents, $message_paras) = @_;
 276     my $tree = cmdoutput @git, qw(write-tree);
 277     my @cmd = (@git, qw(commit-tree), $tree);
 278     push @cmd, qw(-p), $_ foreach @$parents;
 279     push @cmd, qw(-m), $_ foreach @$message_paras;
 280     return cmdoutput @cmd;
 281 }
 282
 283 our @snag_force_opts;
 284 sub snag ($$;@) {
 285     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 286     if (grep { $_ eq $tag } @snag_force_opts) {
 287         $snags_forced++;
 288         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 289     } else {
 290         $snags_tripped++;
 291         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 292     }
 293 }
 294
 295 # Important: all mainline code must call snags_maybe_bail after
 296 # any point where snag might be called, but before making changes
 297 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 298 # may be called more than once if necessary (but this is not ideal
 299 # because then the messages about number of snags may be confusing).
 300 sub snags_maybe_bail () {
 301     return if all_snags_summarised();
 302     if ($snags_forced) {
 303         printf STDERR
 304             "%s: snags: %d overriden by individual -f options\n",
 305             $us, $snags_forced;
 306     }
 307     if ($snags_tripped) {
 308         if ($opt_force) {
 309             printf STDERR
 310                 "%s: snags: %d overriden by global --force\n",
 311                 $us, $snags_tripped;
 312         } else {
 313             fail sprintf
 314   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 315                 $us, $snags_tripped;
 316         }
 317     }
 318     $snags_summarised = $snags_forced + $snags_tripped;
 319 }
 320 sub snags_maybe_bail_early () {
 321     # useful to bail out early without doing a lot of work;
 322     # not a substitute for snags_maybe_bail.
 323     snags_maybe_bail() if $snags_tripped && !$opt_force;
 324 }
 325 sub any_snags () {
 326     return $snags_forced || $snags_tripped;
 327 }
 328
 329 sub gbp_pq_export ($$$) {
 330     my ($bname, $base, $tip) = @_;
 331     # must be run in a workarea.  $bname and patch-queue/$bname
 332     # ought not to exist.  Leaves you on patch-queue/$bname with
 333     # the patches staged but not committed.
 334     printdebug "gbp_pq_export $bname $base $tip\n";
 335     runcmd @git, qw(checkout -q -b), $bname, $base;
 336     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 337     my @gbp_cmd = (qw(gbp pq export));
 338     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 339     if ($r) {
 340         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 341         failedcmd @gbp_cmd;
 342     }
 343     runcmd @git, qw(add -f debian/patches);
 344 }
 345
 346
 347 # xxx allow merge resolution separately from laundering, before git merge
 348 #
 349 # xxx general gdr docs highlight forbidden things
 350 # xxx general gdr docs list allowable things ?
 351 # xxx general gdr docs explicitly forbid some rebase
 352 #
 353 # xxx provide a way for the user to help
 354 # xxx (eg, provide wreckage provide way to continue)
 355
 356 # later/rework?
 357 #  use git-format-patch?
 358 #  our own patch identification algorithm?
 359 #  this is an alternative strategy
 360
 361 sub merge_series ($$;@) {
 362     my ($newbase, $base_q, @input_qs) = @_;
 363     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 364     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 365     # ^ specifies several patch series (currently we only support exactly 2)
 366     # return value is a commit which is the result of
 367     # merging the two versions of the same topic branch
 368     #   $input_q[0] and $input_q[1]
 369     # with respect to the old version
 370     #   $base_q
 371     # all onto $newbase.
 372
 373     # Creates, in *_q, a key MR for its private use
 374
 375     printdebug "merge_series newbase=$newbase\n";
 376
 377     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 378     $base_q->{MR}{S} = 'base';
 379
 380     my %prereq;
 381     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 382     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 383     # $prereq{<patch filename>}               exists or not (even later)
 384
 385     my $result;
 386
 387     local $workarea = fresh_playground "$playprefix/merge";
 388     my $seriesfile = "debian/patches/series";
 389     in_workarea sub {
 390         playtree_setup();
 391         foreach my $q ($base_q, reverse @input_qs) {
 392             my $s = $q->{MR}{S};
 393             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 394             if (open S, $seriesfile) {
 395                 my @earlier;
 396                 while (my $patch = <S>) {
 397                     chomp $patch or die $!;
 398                     $prereq{$patch} //= {};
 399                     foreach my $earlier (@earlier) {
 400                         $prereq{$patch}{$earlier}{$s}++ and die;
 401                     }
 402                     push @earlier, $patch;
 403                     stat "debian/patches/$patch" or die "$patch ?";
 404                 }
 405                 S->error and die "$seriesfile $!";
 406                 close S;
 407             } else {
 408                 die "$seriesfile $!" unless $!==ENOENT;
 409             }
 410             read_tree_upstream $newbase, 1;
 411             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 412                 "Convert $s to patch queue for merging",
 413                 "[git-debrebase merge-innards patch-queue import:".
 414                 " $q->{SeriesTip}]"
 415             ];
 416             printdebug "merge_series  pec $pec ";
 417             runcmd @git, qw(rm -q --cached), $seriesfile;
 418             $pec = make_commit [ $pec ], [
 419                 "Drop series file from $s to avoid merge trouble",
 420                 "[git-debrebase merge-innards patch-queue prep:".
 421                 " $q->{SeriesTip}]"
 422             ];
 423             printdebug "pec' $pec\n";
 424             runcmd @git, qw(reset -q --hard), $pec;
 425             $q->{MR}{PEC} = $pec;
 426         }
 427         # now, because of reverse, we are on $input_q->{MR}{OQC}
 428         runcmd @git, qw(checkout -q -b merge);
 429         printdebug "merge_series merging...\n";
 430         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 431         debugcmd '+', @mergecmd;
 432         $!=0; $?=-1;
 433         if (system @mergecmd) {
 434             failedcmd @mergecmd;
 435         }
 436
 437         printdebug "merge_series merge ok, series...\n";
 438         # We need to construct a new series file
 439         # Firstly, resolve prereq
 440         foreach my $f (sort keys %prereq) {
 441             printdebug "merge_series  patch\t$f\t";
 442             if (!stat_exists "debian/patches/$f") {
 443                 print DEBUG " drop\n" if $debuglevel;
 444                 # git merge deleted it; that's how we tell it's not wanted
 445                 delete $prereq{$f};
 446                 next;
 447             }
 448             print DEBUG " keep\n" if $debuglevel;
 449             foreach my $g (sort keys %{ $prereq{$f} }) {
 450                 my $gfp = $prereq{$f}{$g};
 451                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 452                 if (!!$gfp->{0} == !!$gfp->{1}
 453                     ? $gfp->{0}
 454                     : !$gfp->{base}) {
 455                     print DEBUG "\tkeep\n" if $debuglevel;
 456                 } else {
 457                     print DEBUG "\tdrop\n" if $debuglevel;
 458                     delete $prereq{$f}{$g};
 459                 }
 460             }
 461         }
 462
 463         my $unsat = sub {
 464             my ($f) = @_;
 465             return scalar keys %{ $prereq{$f} };
 466         };
 467
 468         my $nodate = time + 1;
 469         my %authordate;
 470         # $authordate{<patch filename>};
 471         my $authordate = sub {
 472             my ($f) = @_;
 473             $authordate{$f} //= do {
 474                 open PF, "<", "debian/patches/$f" or die "$f $!";
 475                 while (<PF>) {
 476                     return $nodate if m/^$/;
 477                     last if s{^Date: }{};
 478                 }
 479                 chomp;
 480                 return cmdoutput qw(date +%s -d), $_;
 481             };
 482         };
 483
 484         open NS, '>', $seriesfile or die $!;
 485
 486         while (keys %prereq) {
 487             my $best;
 488             foreach my $try (sort keys %prereq) {
 489                 if ($best) {
 490                     next if (
 491                              $unsat->($try) <=> $unsat->($best) or
 492                              $authordate->($try) <=> $authordate->($best) or
 493                              $try cmp $best
 494                             ) >= 0;
 495                 }
 496                 $best = $try;
 497             }
 498             printdebug "merge_series series next $best\n";
 499             print NS "$best\n" or die $!;
 500             delete $prereq{$best};
 501             foreach my $gp (values %prereq) {
 502                 delete $gp->{$best};
 503             }
 504         }
 505
 506         runcmd @git, qw(add), $seriesfile;
 507         runcmd @git, qw(commit --quiet -m), 'Merged series';
 508
 509         printdebug "merge_series series gbp pq import\n";
 510         runcmd qw(gbp pq import);
 511
 512         # OK now we are on patch-queue/merge, and we need to rebase
 513         # onto the intended parent and drop the patches from each one
 514
 515         printdebug "merge_series series ok, building...\n";
 516         my $build = $newbase;
 517         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 518         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 519             my $commit = git_cat_file $c, 'commit';
 520             printdebug "merge_series series ok, building $c\n";
 521             read_tree_upstream $c;
 522             my $tree = cmdoutput @git, qw(write-tree);
 523             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 524             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 525             open C, ">", "../mcommit" or die $!;
 526             print C $commit or die $!;
 527             close C or die $!;
 528             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 529         }
 530         $result = $build;
 531         runcmd @git, qw(update-ref refs/heads/result), $result;
 532     };
 533     printdebug "merge_series returns $result\n";
 534     return $result;
 535 }
 536
 537 # classify returns an info hash like this
 538 #   CommitId => $objid
 539 #   Hdr => # commit headers, including 1 final newline
 540 #   Msg => # commit message (so one newline is dropped)
 541 #   Tree => $treeobjid
 542 #   Type => (see below)
 543 #   Parents = [ {
 544 #       Ix => $index # ie 0, 1, 2, ...
 545 #       CommitId
 546 #       Differs => return value from get_differs
 547 #       IsOrigin
 548 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 549 #     } ...]
 550 #   NewMsg => # commit message, but with any [dgit import ...] edited
 551 #             # to say "[was: ...]"
 552 #
 553 # Types:
 554 #   Packaging
 555 #   Changelog
 556 #   Upstream
 557 #   AddPatches
 558 #   Mixed
 559 #
 560 #   Pseudomerge
 561 #     has additional entres in classification result
 562 #       Overwritten = [ subset of Parents ]
 563 #       Contributor = $the_remaining_Parent
 564 #
 565 #   DgitImportUnpatched
 566 #     has additional entry in classification result
 567 #       OrigParents = [ subset of Parents ]
 568 #
 569 #   Anchor
 570 #     has additional entry in classification result
 571 #       OrigParents = [ subset of Parents ]  # singleton list
 572 #
 573 #   TreatAsAnchor
 574 #
 575 #   BreakwaterStart
 576 #
 577 #   Unknown
 578 #     has additional entry in classification result
 579 #       Why => "prose"
 580
 581 sub parsecommit ($;$) {
 582     my ($objid, $p_ref) = @_;
 583     # => hash with                   CommitId Hdr Msg Tree Parents
 584     #    Parents entries have only   Ix CommitId
 585     #    $p_ref, if provided, must be [] and is used as a base for Parents
 586
 587     $p_ref //= [];
 588     die if @$p_ref;
 589
 590     my ($h,$m) = get_commit $objid;
 591
 592     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 593     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 594
 595     my $r = {
 596         CommitId => $objid,
 597         Hdr => $h,
 598         Msg => $m,
 599         Tree => $t,
 600         Parents => $p_ref,
 601     };
 602
 603     foreach my $ph (@ph) {
 604         push @$p_ref, {
 605             Ix => scalar @$p_ref,
 606             CommitId => $ph,
 607         };
 608     }
 609
 610     return $r;
 611 }
 612
 613 sub classify ($) {
 614     my ($objid) = @_;
 615
 616     my @p;
 617     my $r = parsecommit($objid, \@p);
 618     my $t = $r->{Tree};
 619
 620     foreach my $p (@p) {
 621         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 622     }
 623
 624     printdebug "classify $objid \$t=$t \@p",
 625         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 626         "\n";
 627
 628     my $classify = sub {
 629         my ($type, @rest) = @_;
 630         $r = { %$r, Type => $type, @rest };
 631         if ($debuglevel) {
 632             printdebug " = $type ".(dd $r)."\n";
 633         }
 634         return $r;
 635     };
 636     my $unknown = sub {
 637         my ($why) = @_;
 638         $r = { %$r, Type => qw(Unknown), Why => $why };
 639         printdebug " ** Unknown\n";
 640         return $r;
 641     };
 642
 643     if (grep { $_ eq $objid } @opt_anchors) {
 644         return $classify->('TreatAsAnchor');
 645     }
 646
 647     my @identical = grep { !$_->{Differs} } @p;
 648     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 649     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 650
 651     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 652         # multi-orig upstreams are represented with an anchor merge
 653         # from a single upstream commit which combines the orig tarballs
 654
 655         # Every anchor tagged this way must be a merge.
 656         # We are relying on the
 657         #     [git-debrebase anchor: ...]
 658         # commit message annotation in "declare" anchor merges (which
 659         # do not have any upstream changes), to distinguish those
 660         # anchor merges from ordinary pseudomerges (which we might
 661         # just try to strip).
 662         #
 663         # However, the user is going to be doing git-rebase a lot.  We
 664         # really don't want them to rewrite an anchor commit.
 665         # git-rebase trips up on merges, so that is a useful safety
 666         # catch.
 667         #
 668         # BreakwaterStart commits are also anchors in the terminology
 669         # of git-debrebase(5), but they are untagged (and always
 670         # manually generated).
 671         #
 672         # We cannot not tolerate any tagged linear commit (ie,
 673         # BreakwaterStart commits tagged `[anchor:') because such a
 674         # thing could result from an erroneous linearising raw git
 675         # rebase of a merge anchor.  That would represent a corruption
 676         # of the branch. and we want to detect and reject the results
 677         # of such corruption before it makes it out anywhere.  If we
 678         # reject it here then we avoid making the pseudomerge which
 679         # would be needed to push it.
 680
 681         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 682         @p == 2 or return $badanchor->("has other than two parents");
 683         $haspatches and return $badanchor->("contains debian/patches");
 684
 685         # How to decide about l/r ordering of anchors ?  git
 686         # --topo-order prefers to expand 2nd parent first.  There's
 687         # already an easy rune to look for debian/ history anyway (git log
 688         # debian/) so debian breakwater branch should be 1st parent; that
 689         # way also there's also an easy rune to look for the upstream
 690         # patches (--topo-order).
 691
 692         # Also this makes --first-parent be slightly more likely to
 693         # be useful - it makes it provide a linearised breakwater history.
 694
 695         # Of course one can say somthing like
 696         #  gitk -- ':/' ':!/debian'
 697         # to get _just_ the commits touching upstream files, and by
 698         # the TREESAME logic in git-rev-list this will leave the
 699         # breakwater into upstream at the first anchor.  But that
 700         # doesn't report debian/ changes at all.
 701
 702         # Other observations about gitk: by default, gitk seems to
 703         # produce output in a different order to git-rev-list.  I
 704         # can't seem to find this documented anywhere.  gitk
 705         # --date-order DTRT.  But, gitk always seems to put the
 706         # parents from left to right, in order, so it's easy to see
 707         # which way round a pseudomerge is.
 708
 709         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 710         $p[1]{Differs} & ~DS_DEB and
 711             $badanchor->("upstream files differ from left parent");
 712         $p[0]{Differs} & ~D_UPS and
 713             $badanchor->("debian/ differs from right parent");
 714
 715         return $classify->(qw(Anchor),
 716                            OrigParents => [ $p[1] ]);
 717     }
 718
 719     if (@p == 1) {
 720         my $d = $r->{Parents}[0]{Differs};
 721         if ($d == D_PAT_ADD) {
 722             return $classify->(qw(AddPatches));
 723         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 724             return $unknown->("edits debian/patches");
 725         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 726             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 727             if ($ty eq 'tree') {
 728                 if ($d == D_DEB_CLOG) {
 729                     return $classify->(qw(Changelog));
 730                 } else {
 731                     return $classify->(qw(Packaging));
 732                 }
 733             } elsif ($ty eq 'missing') {
 734                 return $classify->(qw(BreakwaterStart));
 735             } else {
 736                 return $unknown->("parent's debian is not a directory");
 737             }
 738         } elsif ($d == D_UPS) {
 739             return $classify->(qw(Upstream));
 740         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 741             return $classify->(qw(Mixed));
 742         } elsif ($d == 0) {
 743             return $unknown->("no changes");
 744         } else {
 745             confess "internal error $objid ?";
 746         }
 747     }
 748     if (!@p) {
 749         return $unknown->("origin commit");
 750     }
 751
 752     if (@p == 2 && @identical == 1) {
 753         my @overwritten = grep { $_->{Differs} } @p;
 754         confess "internal error $objid ?" unless @overwritten==1;
 755         return $classify->(qw(Pseudomerge),
 756                            Overwritten => [ $overwritten[0] ],
 757                            Contributor => $identical[0]);
 758     }
 759     if (@p == 2 && @identical == 2) {
 760         my $get_t = sub {
 761             my ($ph,$pm) = get_commit $_[0]{CommitId};
 762             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 763             $1;
 764         };
 765         my @bytime = @p;
 766         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 767         if ($order > 0) { # newer first
 768         } elsif ($order < 0) {
 769             @bytime = reverse @bytime;
 770         } else {
 771             # same age, default to order made by -s ours
 772             # that is, commit was made by someone who preferred L
 773         }
 774         return $classify->(qw(Pseudomerge),
 775                            SubType => qw(Ambiguous),
 776                            Contributor => $bytime[0],
 777                            Overwritten => [ $bytime[1] ]);
 778     }
 779     foreach my $p (@p) {
 780         my ($p_h, $p_m) = get_commit $p->{CommitId};
 781         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 782         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 783     }
 784     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 785     my $m2 = $r->{Msg};
 786     if (!(grep { !$_->{IsOrigin} } @p) and
 787         (@orig_ps >= @p - 1) and
 788         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 789         $r->{NewMsg} = $m2;
 790         return $classify->(qw(DgitImportUnpatched),
 791                            OrigParents => \@orig_ps);
 792     }
 793
 794     if (@p == 2 and
 795         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 796         # xxx ^ metadata tag needs adding to (5)
 797         return $classify->("MergedBreakwaters");
 798     }
 799     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 800         return $unknown->("unknown kind of merge from $1");
 801     }
 802     if (@p > 2) {
 803         return $unknown->("octopus merge");
 804     }
 805
 806     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 807         return $unknown->("general two-parent merge");
 808     }
 809
 810     return $classify->("VanillaMerge");
 811 }
 812
 813 sub keycommits ($;$$$$) {
 814     my ($head, $furniture, $unclean, $trouble, $fatal) = @_;
 815     # => ($anchor, $breakwater)
 816
 817     # $unclean->("unclean-$tagsfx", $msg, $cl)
 818     # $furniture->("unclean-$tagsfx", $msg, $cl)
 819     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 820     #   is callled for each situation or commit that
 821     #   wouldn't be found in a laundered branch
 822     # $furniture is for furniture commits such as might be found on an
 823     #   interchange branch (pseudomerge, d/patches, changelog)
 824     # $trouble is for things whnich prevent the return of
 825     #   anchor and breakwater information; if that is ignored,
 826     #   then keycommits returns (undef, undef) instead.
 827     # $fatal is for unprocessable commits, and should normally cause
 828     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 829     #
 830     # If a callback is undef, fail is called instead.
 831     # If a callback is defined but false, the situation is ignored.
 832     # Callbacks may say:
 833     #   no warnings qw(exiting); last;
 834     # if the answer is no longer wanted.
 835
 836     my ($anchor, $breakwater);
 837     my $clogonly;
 838     my $cl;
 839     my $found_pm;
 840     $fatal //= sub { fail $_[1]; };
 841     my $x = sub {
 842         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 843         my $why = $mainwhy.$xwhy;
 844         my $m = "branch needs laundering (run git-debrebase): $why";
 845         fail $m unless defined $cb;
 846         return unless $cb;
 847         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 848     };
 849     my $found_anchor = sub {
 850         ($anchor) = @_;
 851         $breakwater //= $clogonly;
 852         $breakwater //= $head;
 853         no warnings qw(exiting);
 854         last;
 855     };
 856     for (;;) {
 857         $cl = classify $head;
 858         my $ty = $cl->{Type};
 859         if ($ty eq 'Packaging') {
 860             $breakwater //= $clogonly;
 861             $breakwater //= $head;
 862         } elsif ($ty eq 'Changelog') {
 863             # this is going to count as the tip of the breakwater
 864             # only if it has no upstream stuff before it
 865             $clogonly //= $head;
 866         } elsif ($ty eq 'Anchor' or
 867                  $ty eq 'TreatAsAnchor' or
 868                  $ty eq 'BreakwaterStart') {
 869             $found_anchor->($head);
 870         } elsif ($ty eq 'Upstream') {
 871             $x->($unclean, 'ordering',
 872  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 873                 if defined $breakwater;
 874             $clogonly = undef;
 875             $breakwater = undef;
 876         } elsif ($ty eq 'Mixed') {
 877             $x->($unclean, 'mixed',
 878                  "found mixed upstream/packaging commit"," ($head)");
 879             $clogonly = undef;
 880             $breakwater = undef;
 881         } elsif ($ty eq 'Pseudomerge' or
 882                  $ty eq 'AddPatches') {
 883             my $found_pm = 1;
 884             $x->($furniture, (lc $ty),
 885                  "found interchange bureaucracy commit ($ty)"," ($head)");
 886         } elsif ($ty eq 'DgitImportUnpatched') {
 887             if ($found_pm) {
 888                 $x->($trouble, 'dgitimport',
 889                      "found dgit dsc import"," ($head)");
 890                 return (undef,undef);
 891             } else {
 892                 $x->($fatal, 'unprocessable',
 893                      "found bare dgit dsc import with no prior history",
 894                      " ($head)");
 895                 return (undef,undef);
 896             }
 897         } elsif ($ty eq 'VanillaMerge') {
 898             $x->($trouble, 'vanillamerge',
 899                  "found vanilla merge"," ($head)");
 900             return (undef,undef);
 901         } else {
 902             $x->($fatal, 'unprocessable',
 903                  "found unprocessable commit, cannot cope: $cl->{Why}",
 904                  " ($head)");
 905             return (undef,undef);
 906         }
 907         $head = $cl->{Parents}[0]{CommitId};
 908     }
 909     return ($anchor, $breakwater);
 910 }
 911
 912 sub walk ($;$$$);
 913 sub walk ($;$$$) {
 914     my ($input,
 915         $nogenerate,$report, $report_lprefix) = @_;
 916     # => ($tip, $breakwater_tip, $last_anchor)
 917     # (or nothing, if $nogenerate)
 918
 919     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 920     $report_lprefix //= '';
 921
 922     # go through commits backwards
 923     # we generate two lists of commits to apply:
 924     # breakwater branch and upstream patches
 925     my (@brw_cl, @upp_cl, @processed);
 926     my %found;
 927     my $upp_limit;
 928     my @pseudomerges;
 929
 930     my $cl;
 931     my $xmsg = sub {
 932         my ($prose, $info) = @_;
 933         my $ms = $cl->{Msg};
 934         chomp $ms;
 935         $info //= '';
 936         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 937         return (Msg => $ms);
 938     };
 939     my $rewrite_from_here = sub {
 940         my ($cl) = @_;
 941         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 942         push @$cl, $sp_cl;
 943         push @processed, $sp_cl;
 944     };
 945     my $cur = $input;
 946
 947     my $prdelim = "";
 948     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 949
 950     my $prline = sub {
 951         return unless $report;
 952         print $report $prdelim, $report_lprefix, @_;
 953         $prdelim = "\n";
 954     };
 955
 956     my $bomb = sub { # usage: return $bomb->();
 957         print $report " Unprocessable" if $report;
 958         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 959         $prprdelim->();
 960         if ($nogenerate) {
 961             return (undef,undef);
 962         }
 963         fail "found unprocessable commit, cannot cope".
 964             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
 965             " (commit $cur) (d.".
 966             (join ' ', map { sprintf "%#x", $_->{Differs} }
 967              @{ $cl->{Parents} }).
 968                  ")";
 969     };
 970
 971     my $build;
 972     my $breakwater;
 973
 974     my $build_start = sub {
 975         my ($msg, $parent) = @_;
 976         $prline->(" $msg");
 977         $build = $parent;
 978         no warnings qw(exiting); last;
 979     };
 980
 981     my $nomerge = sub {
 982         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
 983     };
 984
 985     my $last_anchor;
 986
 987     for (;;) {
 988         $cl = classify $cur;
 989         my $ty = $cl->{Type};
 990         my $st = $cl->{SubType};
 991         $prline->("$cl->{CommitId} $cl->{Type}");
 992         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 993         push @processed, $cl;
 994         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 995         if ($ty eq 'AddPatches') {
 996             $cur = $p0;
 997             $rewrite_from_here->(\@upp_cl);
 998             next;
 999         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1000             push @brw_cl, $cl;
1001             $cur = $p0;
1002             next;
1003         } elsif ($ty eq 'BreakwaterStart') {
1004             $last_anchor = $cur;
1005             $build_start->('FirstPackaging', $cur);
1006         } elsif ($ty eq 'Upstream') {
1007             push @upp_cl, $cl;
1008             $cur = $p0;
1009             next;
1010         } elsif ($ty eq 'Mixed') {
1011             my $queue = sub {
1012                 my ($q, $wh) = @_;
1013                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1014                 push @$q, $cls;
1015             };
1016             $queue->(\@brw_cl, "debian");
1017             $queue->(\@upp_cl, "upstream");
1018             $rewrite_from_here->(\@brw_cl);
1019             $cur = $p0;
1020             next;
1021         } elsif ($ty eq 'Pseudomerge') {
1022             my $contrib = $cl->{Contributor}{CommitId};
1023             print $report " Contributor=$contrib" if $report;
1024             push @pseudomerges, $cl;
1025             $rewrite_from_here->(\@upp_cl);
1026             $cur = $contrib;
1027             next;
1028         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1029             $last_anchor = $cur;
1030             $build_start->("Anchor", $cur);
1031         } elsif ($ty eq 'DgitImportUnpatched') {
1032             my $pm = $pseudomerges[-1];
1033             if (defined $pm) {
1034                 # To an extent, this is heuristic.  Imports don't have
1035                 # a useful history of the debian/ branch.  We assume
1036                 # that the first pseudomerge after an import has a
1037                 # useful history of debian/, and ignore the histories
1038                 # from later pseudomerges.  Often the first pseudomerge
1039                 # will be the dgit import of the upload to the actual
1040                 # suite intended by the non-dgit NMUer, and later
1041                 # pseudomerges may represent in-archive copies.
1042                 my $ovwrs = $pm->{Overwritten};
1043                 printf $report " PM=%s \@Overwr:%d",
1044                     $pm->{CommitId}, (scalar @$ovwrs)
1045                     if $report;
1046                 if (@$ovwrs != 1) {
1047                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1048                     return $bomb->();
1049                 }
1050                 my $ovwr = $ovwrs->[0]{CommitId};
1051                 printf $report " Overwr=%s", $ovwr if $report;
1052                 # This import has a tree which is just like a
1053                 # breakwater tree, but it has the wrong history.  It
1054                 # ought to have the previous breakwater (which the
1055                 # pseudomerge overwrote) as an ancestor.  That will
1056                 # make the history of the debian/ files correct.  As
1057                 # for the upstream version: either it's the same as
1058                 # was ovewritten (ie, same as the previous
1059                 # breakwater), in which case that history is precisely
1060                 # right; or, otherwise, it was a non-gitish upload of a
1061                 # new upstream version.  We can tell these apart by
1062                 # looking at the tree of the supposed upstream.
1063                 push @brw_cl, {
1064                     %$cl,
1065                     SpecialMethod => 'DgitImportDebianUpdate',
1066                     $xmsg->("convert dgit import: debian changes")
1067                 }, {
1068                     %$cl,
1069                     SpecialMethod => 'DgitImportUpstreamUpdate',
1070                     $xmsg->("convert dgit import: upstream update",
1071                             " anchor")
1072                 };
1073                 $prline->(" Import");
1074                 $rewrite_from_here->(\@brw_cl);
1075                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1076                 $cur = $ovwr;
1077                 next;
1078             } else {
1079                 # Everything is from this import.  This kind of import
1080                 # is already nearly in valid breakwater format, with the
1081                 # patches as commits.  Unfortunately it contains
1082                 # debian/patches/.
1083                 printdebug "*** WALK BOMB bare dgit import\n";
1084                 $cl->{Why} = "bare dgit dsc import";
1085                 return $bomb->();
1086             }
1087             die "$ty ?";
1088         } elsif ($ty eq 'VanillaMerge' or $ty eq 'MergedBreakwaters') {
1089             # User may have merged unstitched branch(es).  We will
1090             # have now lost what ffq-prev was then (since the later
1091             # pseudomerge may introduce further changes).  The effect
1092             # of resolving such a merge is that we may have to go back
1093             # further in history to find a merge base, since the one
1094             # which was reachable via ffq-prev is no longer findable.
1095             # This is suboptimal, but if it all works we'll have done
1096             # the right thing.
1097             # xxx we should warn the user in the docs about this
1098
1099             my $ok=1;
1100             my $best_anchor;
1101             # We expect to find a dominating anchor amongst the
1102             # inputs' anchors.  That will be the new anchor.
1103             #
1104             # More complicated is finding a merge base for the
1105             # breakwaters.  We need a merge base that is a breakwater
1106             # commit.  The ancestors of breakwater commits are more
1107             # breakwater commits and possibly upstream commits and the
1108             # ancestors of those upstream.  Upstreams might have
1109             # arbitrary ancestors.  But any upstream commit U is
1110             # either included in both anchors, in which case the
1111             # earlier anchor is a better merge base than any of U's
1112             # ancestors; or U is not included in the older anchor, in
1113             # which case U is not an ancestor of the vanilla merge at
1114             # all.  So no upstream commit, nor any ancestor thereof,
1115             # is a best merge base.  As for non-breakwater Debian
1116             # commits: these are never ancestors of any breakwater.
1117             #
1118             # So any best merge base as found by git-merge-base
1119             # is a suitable breakwater anchor.  Usually there will
1120             # be only one.
1121
1122             printdebug "*** MERGE\n";
1123
1124             # xxx avoid calling walk without nogenerate when
1125             # we have a MergedBreakwater; instead call keycommits ?
1126
1127             my @bwbcmd = (@git, qw(merge-base));
1128             my @ibcmd = (@git, qw(merge-base --all));
1129             my $might_be_in_bw = 1;
1130
1131             my $ps = $cl->{Parents};
1132
1133             foreach my $p (@$ps) {
1134                 $prline->(" VanillaMerge ".$p->{Ix});
1135                 $prprdelim->();
1136                 my ($ptip, $pbw, $panchor) =
1137                     walk $p->{CommitId}, 0, $report,
1138                          $report_lprefix.'  ';
1139                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1140                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1141                 $p->{Anchor} = $panchor;
1142
1143                 $best_anchor = $panchor if
1144                     !defined $best_anchor or
1145                     is_fast_fwd $best_anchor, $panchor;
1146
1147                 printdebug " MERGE BA best=".($best_anchor//'-').
1148                     " p=$panchor\n";
1149             }
1150
1151             foreach my $p (@$ps) {
1152                 $prline->(" VanillaMerge ".$p->{Ix});
1153                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1154                     $nomerge->('DivergentAnchor');
1155                 } elsif ($p->{Anchor} eq $best_anchor) {
1156                     print $report " SameAnchor" if $report;
1157                 } else {
1158                     print $report " SupersededAnchor" if $report;
1159                 }
1160                 if ($p->{Breakwater} eq $p->{CommitId}) {
1161                     # this parent commit was its own breakwater,
1162                     # ie it is part of the breakwater
1163                     print $report " Breakwater" if $report;
1164                 } else {
1165                     $might_be_in_bw = 0;
1166                 }
1167                 push @bwbcmd, $p->{Breakwater};
1168                 push @ibcmd, $p->{CommitId};
1169             }
1170
1171             if ($ok && $might_be_in_bw) {
1172                 $prline->(" VanillaMerge MergedBreakwaters");
1173                 $last_anchor = $best_anchor;
1174                 $build_start->('MergedBreakwaters', $cur);
1175             }
1176
1177             $nomerge->("alleged merged-breakwater is not a breakwater")
1178                 unless $ty eq 'VanillaMerge';
1179
1180             my $bwb = cmdoutput @bwbcmd;
1181
1182             # OK, now we have a breakwater base, but we need the merge
1183             # base for the interchange branch because we need the delta
1184             # queue.
1185             #
1186             # This a the best merge base of our inputs which has the
1187             # breakwater merge base as an ancestor.
1188
1189             my @ibs =
1190                 grep { is_fast_fwd $bwb, $_ }
1191                 grep /./,
1192                 split /\n/,
1193                 cmdoutput @ibcmd;
1194             my ($ib) = @ibs
1195                 or $nomerge->("no suitable interchange merge base");
1196
1197             $prline->("  VanillaMerge Base");
1198             $prprdelim->();
1199             my ($btip, $bbw, $banchor) =
1200                 walk $ib, 0, $report, $report_lprefix.'  ';
1201
1202             my $ibinfo = { SeriesTip => $btip,
1203                            SeriesBase => $bbw,
1204                            Anchor => $banchor };
1205             $bbw eq $bwb
1206                 or $nomerge->("interchange merge-base ($ib)'s".
1207                               " breakwater ($bbw)".
1208                               " != breakwaters' merge-base ($bwb)");
1209             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1210                  or $nomerge->("interchange merge-base ($ib)'s".
1211                                " anchor ($ibinfo->{SeriesBase})".
1212                                " != any merge input's anchor (".
1213                                (join ' ', map { $_->{Anchor} } @$ps).
1214                                ")");
1215
1216
1217             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1218             $cl->{MergeBestAnchor} = $best_anchor;
1219             push @brw_cl, {
1220                 %$cl,
1221                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1222                 $xmsg->('construct merged breakwater from vanilla merge'),
1223             };
1224             push @upp_cl, {
1225                 %$cl,
1226                 SpecialMethod => 'MergeMergeSeries',
1227             };
1228             $build_start->('MergeBreakwaters', $cur);
1229         } else {
1230             printdebug "*** WALK BOMB unrecognised\n";
1231             return $bomb->();
1232         }
1233     }
1234     $prprdelim->();
1235
1236     printdebug "*** WALK prep done cur=$cur".
1237         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1238
1239     return if $nogenerate;
1240
1241     # Now we build it back up again
1242
1243     fresh_workarea();
1244
1245     my $rewriting = 0;
1246
1247     $#upp_cl = $upp_limit if defined $upp_limit;
1248
1249     my $committer_authline = calculate_committer_authline();
1250
1251     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1252
1253     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1254
1255     in_workarea sub {
1256         mkdir $rd or $!==EEXIST or die $!;
1257         my $current_method;
1258         runcmd @git, qw(read-tree), $build;
1259         foreach my $cl (qw(Debian), (reverse @brw_cl),
1260                         { SpecialMethod => 'RecordBreakwaterTip' },
1261                         qw(Upstream), (reverse @upp_cl)) {
1262             if (!ref $cl) {
1263                 $current_method = $cl;
1264                 next;
1265             }
1266             my $method = $cl->{SpecialMethod} // $current_method;
1267             my @parents = ($build);
1268             my $cltree = $cl->{CommitId};
1269             printdebug "WALK BUILD ".($cltree//'undef').
1270                 " $method (rewriting=$rewriting)\n";
1271             if ($method eq 'Debian') {
1272                 read_tree_debian($cltree);
1273             } elsif ($method eq 'Upstream') {
1274                 read_tree_upstream($cltree);
1275             } elsif ($method eq 'StartRewrite') {
1276                 $rewriting = 1;
1277                 next;
1278             } elsif ($method eq 'RecordBreakwaterTip') {
1279                 $breakwater = $build;
1280                 next;
1281             } elsif ($method eq 'DgitImportDebianUpdate') {
1282                 read_tree_debian($cltree);
1283             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1284                 confess unless $rewriting;
1285                 my $differs = (get_differs $build, $cltree);
1286                 next unless $differs & D_UPS;
1287                 read_tree_upstream($cltree);
1288                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1289             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1290                 print "Found a general merge, will try to tidy it up.\n";
1291                 $rewriting = 1;
1292                 read_tree_upstream($cl->{MergeBestAnchor});
1293                 read_tree_upstream($cl->{MergeBestAnchor});
1294                 read_tree_debian($cltree);
1295                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1296             } elsif ($method eq 'MergeMergeSeries') {
1297                 print "Running merge resolution for $cl->{CommitId}...\n";
1298                 $build = merge_series
1299                     $build,
1300                     $cl->{MergeInterchangeBaseInfo},
1301                     @{ $cl->{Parents} };
1302                 $last_anchor = $cl->{MergeBestAnchor};
1303                 my $check_differs = get_differs $build, $cl->{CommitId};
1304                 # Breakwater changes which were in each side of the
1305                 # merge should be in MergeCreateMergedBreakwaters
1306                 # output.  Upstream changes are exactly the result
1307                 # of merge_series.  So the only difference should
1308                 # be potential laundry results.
1309                 $nomerge->(sprintf
1310                     "merge misresolved: tree is not the same (%s %s d.%#x)",
1311                            $cl->{CommitId}, $build, $check_differs)
1312                     if $check_differs & ~D_PAT_ADD;
1313                 print "Merge resolution successful.\n";
1314                 next;
1315             } else {
1316                 confess "$method ?";
1317             }
1318             if (!$rewriting) {
1319                 my $procd = (pop @processed) // 'UNDEF';
1320                 if ($cl ne $procd) {
1321                     $rewriting = 1;
1322                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1323                 }
1324             }
1325             my $newtree = cmdoutput @git, qw(write-tree);
1326             my $ch = $cl->{Hdr};
1327             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1328             $ch =~ s{^parent .*\n}{}mg;
1329             $ch =~ s{(?=^author)}{
1330                 join '', map { "parent $_\n" } @parents
1331             }me or confess "$ch ?";
1332             if ($rewriting) {
1333                 $ch =~ s{^committer .*$}{$committer_authline}m
1334                     or confess "$ch ?";
1335             }
1336             my $cf = "$rd/m$rewriting";
1337             open CD, ">", $cf or die $!;
1338             print CD $ch, "\n", $cl->{Msg} or die $!;
1339             close CD or die $!;
1340             my @cmd = (@git, qw(hash-object));
1341             push @cmd, qw(-w) if $rewriting;
1342             push @cmd, qw(-t commit), $cf;
1343             my $newcommit = cmdoutput @cmd;
1344             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1345             $build = $newcommit;
1346             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1347                 $last_anchor = $cur;
1348             }
1349         }
1350     };
1351
1352     my $final_check = get_differs $build, $input;
1353     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1354         if $final_check & ~D_PAT_ADD;
1355
1356     my @r = ($build, $breakwater, $last_anchor);
1357     printdebug "*** WALK RETURN @r\n";
1358     return @r
1359 }
1360
1361 sub get_head () {
1362     git_check_unmodified();
1363     return git_rev_parse qw(HEAD);
1364 }
1365
1366 sub update_head ($$$) {
1367     my ($old, $new, $mrest) = @_;
1368     push @deferred_updates, "update HEAD $new $old";
1369     run_deferred_updates $mrest;
1370 }
1371
1372 sub update_head_checkout ($$$) {
1373     my ($old, $new, $mrest) = @_;
1374     update_head $old, $new, $mrest;
1375     runcmd @git, qw(reset --hard);
1376 }
1377
1378 sub update_head_postlaunder ($$$) {
1379     my ($old, $tip, $reflogmsg) = @_;
1380     return if $tip eq $old;
1381     print "git-debrebase: laundered (head was $old)\n";
1382     update_head $old, $tip, $reflogmsg;
1383     # no tree changes except debian/patches
1384     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1385 }
1386
1387 sub currently_rebasing() {
1388     foreach (qw(rebase-merge rebase-apply)) {
1389         return 1 if stat_exists "$maindir_gitdir/$_";
1390     }
1391     return 0;
1392 }
1393
1394 sub bail_if_rebasing() {
1395     fail "you are in the middle of a git-rebase already"
1396         if currently_rebasing();
1397 }
1398
1399 sub do_launder_head ($) {
1400     my ($reflogmsg) = @_;
1401     my $old = get_head();
1402     record_ffq_auto();
1403     my ($tip,$breakwater) = walk $old;
1404     snags_maybe_bail();
1405     update_head_postlaunder $old, $tip, $reflogmsg;
1406     return ($tip,$breakwater);
1407 }
1408
1409 sub cmd_launder_v0 () {
1410     badusage "no arguments to launder-v0 allowed" if @ARGV;
1411     my $old = get_head();
1412     my ($tip,$breakwater,$last_anchor) = walk $old;
1413     update_head_postlaunder $old, $tip, 'launder';
1414     printf "# breakwater tip\n%s\n", $breakwater;
1415     printf "# working tip\n%s\n", $tip;
1416     printf "# last anchor\n%s\n", $last_anchor;
1417 }
1418
1419 sub defaultcmd_rebase () {
1420     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1421     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1422     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1423 }
1424
1425 sub cmd_analyse () {
1426     badusage "analyse does not support any options"
1427         if @ARGV and $ARGV[0] =~ m/^-/;
1428     badusage "too many arguments to analyse" if @ARGV>1;
1429     my ($old) = @ARGV;
1430     if (defined $old) {
1431         $old = git_rev_parse $old;
1432     } else {
1433         $old = git_rev_parse 'HEAD';
1434     }
1435     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1436     STDOUT->error and die $!;
1437 }
1438
1439 sub ffq_prev_branchinfo () {
1440     my $current = git_get_symref();
1441     return gdr_ffq_prev_branchinfo($current);
1442 }
1443
1444 sub ffq_check ($;$$) {
1445     # calls $ff and/or $notff zero or more times
1446     # then returns either (status,message) where status is
1447     #    exists
1448     #    detached
1449     #    weird-symref
1450     #    notbranch
1451     # or (undef,undef, $ffq_prev,$gdrlast)
1452     # $ff and $notff are called like this:
1453     #   $ff->("message for stdout\n");
1454     #   $notff->('snag-name', $message);
1455     # normally $currentval should be HEAD
1456     my ($currentval, $ff, $notff) =@_;
1457
1458     $ff //= sub { print $_[0] or die $!; };
1459     $notff //= \&snag;
1460
1461     my ($status, $message, $current, $ffq_prev, $gdrlast)
1462         = ffq_prev_branchinfo();
1463     return ($status, $message) unless $status eq 'branch';
1464
1465     my $exists = git_get_ref $ffq_prev;
1466     return ('exists',"$ffq_prev already exists") if $exists;
1467
1468     return ('not-branch', 'HEAD symref is not to refs/heads/')
1469         unless $current =~ m{^refs/heads/};
1470     my $branch = $';
1471
1472     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1473     my %checked;
1474
1475     printdebug "ffq check_specs @check_specs\n";
1476
1477     my $check = sub {
1478         my ($lrref, $desc) = @_;
1479         printdebug "ffq might check $lrref ($desc)\n";
1480         my $invert;
1481         for my $chk (@check_specs) {
1482             my $glob = $chk;
1483             $invert = $glob =~ s{^[!^]}{};
1484             last if fnmatch $glob, $lrref;
1485         }
1486         return if $invert;
1487         my $lrval = git_get_ref $lrref;
1488         return unless length $lrval;
1489
1490         if (is_fast_fwd $lrval, $currentval) {
1491             $ff->("OK, you are ahead of $lrref\n");
1492             $checked{$lrref} = 1;
1493         } elsif (is_fast_fwd $currentval, $lrval) {
1494             $checked{$lrref} = -1;
1495             $notff->('behind', "you are behind $lrref, divergence risk");
1496         } else {
1497             $checked{$lrref} = -1;
1498             $notff->('diverged', "you have diverged from $lrref");
1499         }
1500     };
1501
1502     my $merge = cfg "branch.$branch.merge",1;
1503     if (defined $merge and $merge =~ m{^refs/heads/}) {
1504         my $rhs = $';
1505         printdebug "ffq merge $rhs\n";
1506         my $check_remote = sub {
1507             my ($remote, $desc) = @_;
1508             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1509             return unless defined $remote;
1510             $check->("refs/remotes/$remote/$rhs", $desc);
1511         };
1512         $check_remote->((scalar cfg "branch.$branch.remote",1),
1513                         'remote fetch/merge branch');
1514         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1515                         (scalar cfg "branch.$branch.pushDefault",1),
1516                         'remote push branch');
1517     }
1518     if ($branch =~ m{^dgit/}) {
1519         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1520     } elsif ($branch =~ m{^master$}) {
1521         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1522     }
1523     return (undef, undef, $ffq_prev, $gdrlast);
1524 }
1525
1526 sub record_ffq_prev_deferred () {
1527     # => ('status', "message")
1528     # 'status' may be
1529     #    deferred          message is undef
1530     #    exists
1531     #    detached
1532     #    weird-symref
1533     #    notbranch
1534     # if not ff from some branch we should be ff from, is an snag
1535     # if "deferred", will have added something about that to
1536     #   @deferred_update_messages, and also maybe printed (already)
1537     #   some messages about ff checks
1538     bail_if_rebasing();
1539     my $currentval = get_head();
1540
1541     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1542     return ($status,$message) if defined $status;
1543
1544     snags_maybe_bail();
1545
1546     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1547     push @deferred_updates, "delete $gdrlast";
1548     push @deferred_update_messages, "Recorded previous head for preservation";
1549     return ('deferred', undef);
1550 }
1551
1552 sub record_ffq_auto () {
1553     my ($status, $message) = record_ffq_prev_deferred();
1554     if ($status eq 'deferred' || $status eq 'exists') {
1555     } else {
1556         snag $status, "could not record ffq-prev: $message";
1557         snags_maybe_bail();
1558     }
1559 }
1560
1561 sub ffq_prev_info () {
1562     bail_if_rebasing();
1563     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1564     my ($status, $message, $current, $ffq_prev, $gdrlast)
1565         = ffq_prev_branchinfo();
1566     if ($status ne 'branch') {
1567         snag $status, "could not check ffq-prev: $message";
1568         snags_maybe_bail();
1569     }
1570     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1571     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1572 }
1573
1574 sub stitch ($$$$$) {
1575     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1576
1577     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1578
1579     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1580         my $differs = get_differs $old_head, $ffq_prev_commitish;
1581         unless ($differs & ~D_PAT_ADD) {
1582             # ffq-prev is ahead of us, and the only tree changes it has
1583             # are possibly addition of things in debian/patches/.
1584             # Just wind forwards rather than making a pointless pseudomerge.
1585             push @deferred_updates,
1586                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1587             update_head_checkout $old_head, $ffq_prev_commitish,
1588                 "stitch (fast forward)";
1589             return;
1590         }
1591     }
1592     fresh_workarea();
1593     # We make pseudomerges with L as the contributing parent.
1594     # This makes git rev-list --first-parent work properly.
1595     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1596         'Declare fast forward / record previous work',
1597         "[git-debrebase pseudomerge: $prose]",
1598     ];
1599     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1600     update_head $old_head, $new_head, "stitch: $prose";
1601 }
1602
1603 sub do_stitch ($;$) {
1604     my ($prose, $unclean) = @_;
1605
1606     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1607     if (!$ffq_prev_commitish) {
1608         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1609         return;
1610     }
1611     my $dangling_head = get_head();
1612
1613     keycommits $dangling_head, $unclean,$unclean,$unclean;
1614     snags_maybe_bail();
1615
1616     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1617 }
1618
1619 sub upstream_commitish_search ($$) {
1620     my ($upstream_version, $tried) = @_;
1621     # todo: at some point maybe use git-deborig to do this
1622     foreach my $tagpfx ('', 'v', 'upstream/') {
1623         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1624         my $new_upstream = git_get_ref "refs/tags/$tag";
1625         push @$tried, $tag;
1626         return $new_upstream if length $new_upstream;
1627     }
1628 }
1629
1630 sub resolve_upstream_version ($$) {
1631     my ($new_upstream, $upstream_version) = @_;
1632
1633     if (!defined $new_upstream) {
1634         my @tried;
1635         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1636         if (!length $new_upstream) {
1637             fail "Could not determine appropriate upstream commitish.\n".
1638                 " (Tried these tags: @tried)\n".
1639                 " Check version, and specify upstream commitish explicitly.";
1640         }
1641     }
1642     $new_upstream = git_rev_parse $new_upstream;
1643
1644     return $new_upstream;
1645 }
1646
1647 sub cmd_new_upstream () {
1648     # automatically and unconditionally launders before rebasing
1649     # if rebase --abort is used, laundering has still been done
1650
1651     my %pieces;
1652
1653     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1654
1655     # parse args - low commitment
1656     my $spec_version = shift @ARGV;
1657     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1658     fail "bad version number \`$spec_version'" unless defined $new_version;
1659     if ($new_version->is_native()) {
1660         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1661     }
1662
1663     my $new_upstream = shift @ARGV;
1664     my $new_upstream_version = upstreamversion  $new_version;
1665     $new_upstream =
1666         resolve_upstream_version $new_upstream, $new_upstream_version;
1667
1668     record_ffq_auto();
1669
1670     my $piece = sub {
1671         my ($n, @x) = @_; # may be ''
1672         my $pc = $pieces{$n} //= {
1673             Name => $n,
1674             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1675         };
1676         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1677         $pc;
1678     };
1679
1680     my @newpieces;
1681     my $newpiece = sub {
1682         my ($n, @x) = @_; # may be ''
1683         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1684         push @newpieces, $pc;
1685     };
1686
1687     $newpiece->('',
1688         OldIx => 0,
1689         New => $new_upstream,
1690     );
1691     while (@ARGV && $ARGV[0] !~ m{^-}) {
1692         my $n = shift @ARGV;
1693
1694         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1695             unless @ARGV && $ARGV[0] !~ m{^-};
1696
1697         my $c = git_rev_parse shift @ARGV;
1698         die unless $n =~ m/^$extra_orig_namepart_re$/;
1699         $newpiece->($n, New => $c);
1700     }
1701
1702     # now we need to investigate the branch this generates the
1703     # laundered version but we don't switch to it yet
1704     my $old_head = get_head();
1705     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1706
1707     my $old_bw_cl = classify $old_bw;
1708     my $old_anchor_cl = classify $old_anchor;
1709     my $old_upstream;
1710     if (!$old_anchor_cl->{OrigParents}) {
1711         snag 'anchor-treated',
1712             'old anchor is recognised due to --anchor, cannot check upstream';
1713     } else {
1714         $old_upstream = parsecommit
1715             $old_anchor_cl->{OrigParents}[0]{CommitId};
1716         $piece->('', Old => $old_upstream->{CommitId});
1717     }
1718
1719     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1720         if ($old_upstream->{Msg} =~
1721  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1722            ) {
1723             my @oldpieces = (split / /, $1);
1724             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1725             if ($old_n_parents != @oldpieces &&
1726                 $old_n_parents != @oldpieces + 1) {
1727                 snag 'upstream-confusing', sprintf
1728                     "previous upstream combine %s".
1729                     " mentions %d pieces (each implying one parent)".
1730                     " but has %d parents".
1731                     " (one per piece plus maybe a previous combine)",
1732                     $old_upstream->{CommitId},
1733                     (scalar @oldpieces),
1734                     $old_n_parents;
1735             } elsif ($oldpieces[0] ne '.') {
1736                 snag 'upstream-confusing', sprintf
1737                     "previous upstream combine %s".
1738                     " first piece is not \`.'",
1739                     $oldpieces[0];
1740             } else {
1741                 $oldpieces[0] = '';
1742                 foreach my $i (0..$#oldpieces) {
1743                     my $n = $oldpieces[$i];
1744                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1745                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1746                 }
1747             }
1748         } else {
1749             snag 'upstream-confusing',
1750                 "previous upstream $old_upstream->{CommitId} is from".
1751                " git-debrebase but not an \`upstream-combine' commit";
1752         }
1753     }
1754
1755     foreach my $pc (values %pieces) {
1756         if (!$old_upstream) {
1757             # we have complained already
1758         } elsif (!$pc->{Old}) {
1759             snag 'upstream-new-piece',
1760                 "introducing upstream piece \`$pc->{Name}'";
1761         } elsif (!$pc->{New}) {
1762             snag 'upstream-rm-piece',
1763                 "dropping upstream piece \`$pc->{Name}'";
1764         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1765             snag 'upstream-not-ff',
1766                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1767         }
1768     }
1769
1770     printdebug "%pieces = ", (dd \%pieces), "\n";
1771     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1772
1773     snags_maybe_bail();
1774
1775     my $new_bw;
1776
1777     fresh_workarea();
1778     in_workarea sub {
1779         my @upstream_merge_parents;
1780
1781         if (!any_snags()) {
1782             push @upstream_merge_parents, $old_upstream->{CommitId};
1783         }
1784
1785         foreach my $pc (@newpieces) { # always has '' first
1786             if ($pc->{Name}) {
1787                 read_tree_subdir $pc->{Name}, $pc->{New};
1788             } else {
1789                 runcmd @git, qw(read-tree), $pc->{New};
1790             }
1791             push @upstream_merge_parents, $pc->{New};
1792         }
1793
1794         # index now contains the new upstream
1795
1796         if (@newpieces > 1) {
1797             # need to make the upstream subtree merge commit
1798             $new_upstream = make_commit \@upstream_merge_parents,
1799                 [ "Combine upstreams for $new_upstream_version",
1800  ("[git-debrebase upstream-combine . ".
1801  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1802  ": new upstream]"),
1803                 ];
1804         }
1805
1806         # $new_upstream is either the single upstream commit, or the
1807         # combined commit we just made.  Either way it will be the
1808         # "upstream" parent of the anchor merge.
1809
1810         read_tree_subdir 'debian', "$old_bw:debian";
1811
1812         # index now contains the anchor merge contents
1813         $new_bw = make_commit [ $old_bw, $new_upstream ],
1814             [ "Update to upstream $new_upstream_version",
1815  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1816             ];
1817
1818         my $clogsignoff = cmdoutput qw(git show),
1819             '--pretty=format:%an <%ae>  %aD',
1820             $new_bw;
1821
1822         # Now we have to add a changelog stanza so the Debian version
1823         # is right.
1824         die if unlink "debian";
1825         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1826         unlink "debian/changelog" or $!==ENOENT or die $!;
1827         mkdir "debian" or die $!;
1828         open CN, ">", "debian/changelog" or die $!;
1829         my $oldclog = git_cat_file ":debian/changelog";
1830         $oldclog =~ m/^($package_re) \(\S+\) / or
1831             fail "cannot parse old changelog to get package name";
1832         my $p = $1;
1833         print CN <<END, $oldclog or die $!;
1834 $p ($new_version) UNRELEASED; urgency=medium
1835
1836   * Update to new upstream version $new_upstream_version.
1837
1838  -- $clogsignoff
1839
1840 END
1841         close CN or die $!;
1842         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1843
1844         # Now we have the final new breakwater branch in the index
1845         $new_bw = make_commit [ $new_bw ],
1846             [ "Update changelog for new upstream $new_upstream_version",
1847               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1848             ];
1849     };
1850
1851     # we have constructed the new breakwater. we now need to commit to
1852     # the laundering output, because git-rebase can't easily be made
1853     # to make a replay list which is based on some other branch
1854
1855     update_head_postlaunder $old_head, $old_laundered_tip,
1856         'launder for new upstream';
1857
1858     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1859     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1860         "debrebase new-upstream $new_version: rebase";
1861     runcmd @cmd;
1862     # now it's for the user to sort out
1863 }
1864
1865 sub cmd_record_ffq_prev () {
1866     badusage "no arguments allowed" if @ARGV;
1867     my ($status, $msg) = record_ffq_prev_deferred();
1868     if ($status eq 'exists' && $opt_noop_ok) {
1869         print "Previous head already recorded\n" or die $!;
1870     } elsif ($status eq 'deferred') {
1871         run_deferred_updates 'record-ffq-prev';
1872     } else {
1873         fail "Could not preserve: $msg";
1874     }
1875 }
1876
1877 sub cmd_anchor () {
1878     badusage "no arguments allowed" if @ARGV;
1879     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1880     print "$bw\n" or die $!;
1881 }
1882
1883 sub cmd_breakwater () {
1884     badusage "no arguments allowed" if @ARGV;
1885     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1886     print "$bw\n" or die $!;
1887 }
1888
1889 sub cmd_status () {
1890     badusage "no arguments allowed" if @ARGV;
1891
1892     # todo: gdr status should print divergence info
1893     # todo: gdr status should print upstream component(s) info
1894     # todo: gdr should leave/maintain some refs with this kind of info ?
1895
1896     my $oldest = { Badness => 0 };
1897     my $newest;
1898     my $note = sub {
1899         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1900         if ($oldest->{Badness} < $badness) {
1901             $oldest = $newest = undef;
1902         }
1903         $oldest = {
1904                    Badness => $badness,
1905                    CommitId => $cl->{CommitId},
1906                    OurMsg => $ourmsg,
1907                    KcMsg => $kcmsg,
1908                   };
1909         $newest //= $oldest;
1910     };
1911     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1912         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1913         sub { $note->(2, 'branch is unlaundered', @_); },
1914         sub { $note->(3, 'branch needs laundering', @_); },
1915         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1916
1917     my $prcommitinfo = sub {
1918         my ($cid) = @_;
1919         flush STDOUT or die $!;
1920         runcmd @git, qw(--no-pager log -n1),
1921             '--pretty=format:    %h %s%n',
1922             $cid;
1923     };
1924
1925     print "current branch contents, in git-debrebase terms:\n";
1926     if (!$oldest->{Badness}) {
1927         print "  branch is laundered\n";
1928     } else {
1929         print "  $oldest->{OurMsg}\n";
1930         my $printed = '';
1931         foreach my $info ($oldest, $newest) {
1932             my $cid = $info->{CommitId};
1933             next if $cid eq $printed;
1934             $printed = $cid;
1935             print "  $info->{KcMsg}\n";
1936             $prcommitinfo->($cid);
1937         }
1938     }
1939
1940     my $prab = sub {
1941         my ($cid, $what) = @_;
1942         if (!defined $cid) {
1943             print "  $what is not well-defined\n";
1944         } else {
1945             print "  $what\n";
1946             $prcommitinfo->($cid);
1947         }
1948     };
1949     print "key git-debrebase commits:\n";
1950     $prab->($anchor, 'anchor');
1951     $prab->($bw, 'breakwater');
1952
1953     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
1954         ffq_prev_branchinfo();
1955
1956     print "branch and ref status, in git-debrebase terms:\n";
1957     if ($ffq_msg) {
1958         print "  $ffq_msg\n";
1959     } else {
1960         $ffq_prev = git_get_ref $ffq_prev;
1961         $gdrlast = git_get_ref $gdrlast;
1962         if ($ffq_prev) {
1963             print "  unstitched; previous tip was:\n";
1964             $prcommitinfo->($ffq_prev);
1965         } elsif (!$gdrlast) {
1966             print "  stitched? (no record of git-debrebase work)\n";
1967         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
1968             print "  stitched\n";
1969         } else {
1970             print "  not git-debrebase (diverged since last stitch)\n"
1971         }
1972     }
1973     print "you are currently rebasing\n" if currently_rebasing();
1974 }
1975
1976 sub cmd_stitch () {
1977     my $prose = 'stitch';
1978     getoptions("stitch",
1979                'prose=s', \$prose);
1980     badusage "no arguments allowed" if @ARGV;
1981     do_stitch $prose, 0;
1982 }
1983 sub cmd_prepush () { cmd_stitch(); }
1984
1985 sub cmd_quick () {
1986     badusage "no arguments allowed" if @ARGV;
1987     do_launder_head 'launder for git-debrebase quick';
1988     do_stitch 'quick';
1989 }
1990
1991 sub cmd_conclude () {
1992     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1993     if (!$ffq_prev_commitish) {
1994         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1995         return;
1996     }
1997     my $dangling_head = get_head();
1998
1999     badusage "no arguments allowed" if @ARGV;
2000     do_launder_head 'launder for git-debrebase quick';
2001     do_stitch 'quick';
2002 }
2003
2004 sub cmd_scrap () {
2005     if (currently_rebasing()) {
2006         runcmd @git, qw(rebase --abort);
2007     }
2008     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2009     if (!$ffq_prev_commitish) {
2010         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2011         finish 0;
2012     }
2013     my $scrapping_head = get_head();
2014     badusage "no arguments allowed" if @ARGV;
2015     push @deferred_updates,
2016         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2017         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2018     snags_maybe_bail();
2019     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2020 }
2021
2022 sub make_patches_staged ($) {
2023     my ($head) = @_;
2024     # Produces the patches that would result from $head if it were
2025     # laundered.
2026     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2027     fresh_workarea();
2028     in_workarea sub {
2029         gbp_pq_export 'bw', $secret_bw, $secret_head;
2030     };
2031 }
2032
2033 sub make_patches ($) {
2034     my ($head) = @_;
2035     keycommits $head, 0, \&snag;
2036     make_patches_staged $head;
2037     my $out;
2038     in_workarea sub {
2039         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2040         runcmd @git, qw(read-tree), $head;
2041         read_tree_subdir 'debian/patches', $ptree;
2042         $out = make_commit [$head], [
2043             'Commit patch queue (exported by git-debrebase)',
2044             '[git-debrebase: export and commit patches]',
2045         ];
2046     };
2047     return $out;
2048 }
2049
2050 sub cmd_make_patches () {
2051     my $opt_quiet_would_amend;
2052     getoptions("make-patches",
2053                'quiet-would-amend!', \$opt_quiet_would_amend);
2054     badusage "no arguments allowed" if @ARGV;
2055     bail_if_rebasing();
2056     my $old_head = get_head();
2057     my $new = make_patches $old_head;
2058     my $d = get_differs $old_head, $new;
2059     if ($d == 0) {
2060         fail "No (more) patches to export." unless $opt_noop_ok;
2061         return;
2062     } elsif ($d == D_PAT_ADD) {
2063         snags_maybe_bail();
2064         update_head_checkout $old_head, $new, 'make-patches';
2065     } else {
2066         print STDERR failmsg
2067             "Patch export produced patch amendments".
2068             " (abandoned output commit $new).".
2069             "  Try laundering first."
2070             unless $opt_quiet_would_amend;
2071         finish 7;
2072     }
2073 }
2074
2075 sub cmd_convert_from_gbp () {
2076     badusage "want only 1 optional argument, the upstream git commitish"
2077         unless @ARGV<=1;
2078
2079     my $clogp = parsechangelog();
2080     my $version = $clogp->{'Version'}
2081         // die "missing Version from changelog";
2082
2083     my ($upstream_spec) = @ARGV;
2084
2085     my $upstream_version = upstreamversion $version;
2086     my $upstream =
2087         resolve_upstream_version($upstream_spec, $upstream_version);
2088
2089     my $old_head = get_head();
2090
2091     my $upsdiff = get_differs $upstream, $old_head;
2092     if ($upsdiff & D_UPS) {
2093         runcmd @git, qw(--no-pager diff --stat),
2094             $upstream, $old_head,
2095             qw( -- :!/debian :/);
2096         fail <<END;
2097 upstream ($upstream_spec) and HEAD are not
2098 identical in upstream files.  See diffstat above, or run
2099   git diff $upstream_spec HEAD -- :!/debian :/
2100 END
2101     }
2102
2103     if (!is_fast_fwd $upstream, $old_head) {
2104         snag 'upstream-not-ancestor',
2105             "upstream ($upstream) is not an ancestor of HEAD";
2106     } else {
2107         my $wrong = cmdoutput
2108             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2109              qw(-- :/ :!/debian));
2110         if (length $wrong) {
2111             snag 'unexpected-upstream-changes',
2112                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2113             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2114         }
2115     }
2116
2117     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2118         snag 'upstream-has-debian',
2119             "upstream ($upstream) contains debian/ directory";
2120     }
2121
2122     my $previous_dgit_view = eval {
2123         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2124         my ($lvsn, $suite);
2125         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2126             my ($stz, $desc) = @_;
2127             no warnings qw(exiting);
2128             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2129             next unless $stz->{Date};
2130             next unless $stz->{Distribution} ne 'UNRELEASED';
2131             $lvsn = $stz->{Version};
2132             $suite = $stz->{Distribution};
2133             last;
2134         };
2135         die "neither of the first two changelog entries are released\n"
2136             unless defined $lvsn;
2137         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2138         my $mtag_pat = debiantag_maintview $lvsn, '*';
2139         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2140             $mtag_pat;
2141         die "could not find suitable maintainer view tag $mtag_pat\n"
2142             unless $mtag_pat =~ m{/};
2143         is_fast_fwd $mtag, 'HEAD' or
2144             die "HEAD is not FF from maintainer tag $mtag!";
2145         my $dtag = "archive/$mtag";
2146         is_fast_fwd $mtag, $dtag or
2147             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2148         print "will stitch in dgit view, $dtag\n";
2149         git_rev_parse $dtag;
2150     };
2151     if (!$previous_dgit_view) {
2152         $@ =~ s/^\n+//;
2153         chomp $@;
2154         print STDERR "cannot stitch in dgit view: $@\n";
2155     }
2156
2157     snags_maybe_bail_early();
2158
2159     my $work;
2160
2161     fresh_workarea();
2162     in_workarea sub {
2163         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2164         # make a branch out of the patch queue - we'll want this in a mo
2165         runcmd qw(gbp pq import);
2166         # strip the patches out
2167         runcmd @git, qw(checkout -q gdr-internal~0);
2168         rm_subdir_cached 'debian/patches';
2169         $work = make_commit ['HEAD'], [
2170  'git-debrebase convert-from-gbp: drop patches from tree',
2171  'Delete debian/patches, as part of converting to git-debrebase format.',
2172  '[git-debrebase convert-from-gbp: drop patches from tree]'
2173                               ];
2174         # make the anchor merge
2175         # the tree is already exactly right
2176         $work = make_commit [$work, $upstream], [
2177  'git-debrebase import: declare upstream',
2178  'First breakwater merge.',
2179  '[git-debrebase anchor: declare upstream]'
2180                               ];
2181
2182         # rebase the patch queue onto the new breakwater
2183         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2184         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2185         $work = git_rev_parse 'HEAD';
2186
2187         if ($previous_dgit_view) {
2188             $work = make_commit [$work, $previous_dgit_view], [
2189  'git-debrebase import: declare ff from dgit archive view',
2190  '[git-debrebase pseudomerge: import-from-gbp]',
2191             ];
2192         }
2193     };
2194
2195     ffq_check $work;
2196     snags_maybe_bail();
2197     update_head_checkout $old_head, $work, 'convert-from-gbp';
2198 }
2199
2200 sub cmd_convert_to_gbp () {
2201     badusage "no arguments allowed" if @ARGV;
2202     my $head = get_head();
2203     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2204     keycommits $head, 0;
2205     my $out;
2206     make_patches_staged $head;
2207     in_workarea sub {
2208         $out = make_commit ['HEAD'], [
2209             'Commit patch queue (converted from git-debrebase format)',
2210             '[git-debrebase convert-to-gbp: commit patches]',
2211         ];
2212     };
2213     if (defined $ffq) {
2214         push @deferred_updates, "delete $ffq";
2215         push @deferred_updates, "delete $gdrlast";
2216     }
2217     snags_maybe_bail();
2218     update_head_checkout $head, $out, "convert to gbp (v0)";
2219     print <<END or die $!;
2220 git-debrebase: converted to git-buildpackage branch format
2221 git-debrebase: WARNING: do not now run "git-debrebase" any more
2222 git-debrebase: WARNING: doing so would drop all upstream patches!
2223 END
2224 }
2225
2226 sub cmd_convert_from_dgit_view () {
2227     my $clogp = parsechangelog();
2228
2229     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2230     my $do_origs = 1;
2231     my $do_tags = 1;
2232     my $always = 0;
2233     my $diagnose = 0;
2234
2235     getoptions("convert-from-dgit-view",
2236                'diagnose!', \$diagnose,
2237                'build-products-dir:s', \$bpd,
2238                'origs!', \$do_origs,
2239                'tags!', \$do_tags,
2240                'always-convert-anyway!', \$always);
2241     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2242
2243     my @upstreams;
2244
2245     if (@ARGV) {
2246         my $spec = shift @ARGV;
2247         my $commit = git_rev_parse "$spec^{commit}";
2248         push @upstreams, { Commit => $commit,
2249                            Source => "$ARGV[0], from command line",
2250                            Only => 1,
2251                          };
2252     }
2253
2254     my $head = get_head();
2255
2256     if (!$always) {
2257         my $troubles = 0;
2258         my $trouble = sub { $troubles++; };
2259         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2260         printdebug "troubles=$troubles\n";
2261         if (!$troubles) {
2262             print STDERR <<END;
2263 $us: Branch already seems to be in git-debrebase format!
2264 $us: --always-convert-anyway would do the conversion operation anyway
2265 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2266 END
2267             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2268             finish 0;
2269         }
2270     }
2271
2272     snags_maybe_bail_early();
2273
2274     my $version = upstreamversion $clogp->{Version};
2275     print STDERR "Considering possible commits corresponding to upstream:\n";
2276
2277     if (!@upstreams) {
2278         if ($do_tags) {
2279             my @tried;
2280             my $ups_tag = upstream_commitish_search $version, \@tried;
2281             if ($ups_tag) {
2282                 my $this = "git tag $tried[-1]";
2283                 push @upstreams, { Commit => $ups_tag,
2284                                    Source => $this,
2285                                  };
2286             } else {
2287                 printf STDERR
2288                     " git tag: no suitable tag found (tried %s)\n",
2289                     "@tried";
2290             }
2291         }
2292         if ($do_origs) {
2293             my $p = $clogp->{'Source'};
2294             # we do a quick check to see if there are plausible origs
2295             my $something=0;
2296             if (!opendir BPD, $bpd) {
2297                 die "$bpd: opendir: $!" unless $!==ENOENT;
2298             } else {
2299                 while ($!=0, my $f = readdir BPD) {
2300                     next unless is_orig_file_of_p_v $f, $p, $version;
2301                     printf STDERR
2302                         " orig: found what looks like a .orig, %s\n",
2303                         "$bpd/$f";
2304                     $something=1;
2305                     last;
2306                 }
2307                 die "read $bpd: $!" if $!;
2308                 closedir BPD;
2309             }
2310             if ($something) {
2311                 my $tree = cmdoutput
2312                     @dgit, qw(--build-products-dir), $bpd,
2313                     qw(print-unapplied-treeish);
2314                 fresh_workarea();
2315                 in_workarea sub {
2316                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2317                     rm_subdir_cached 'debian';
2318                     $tree = cmdoutput @git, qw(write-tree);
2319                     my $ups_synth = make_commit [], [ <<END, <<END,
2320 Import effective orig tree for upstream version $version
2321 END
2322 This includes the contents of the .orig(s), minus any debian/ directory.
2323
2324 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2325 END
2326                                                     ];
2327                     push @upstreams, { Commit => $ups_synth,
2328                                        Source => "orig(s) imported via dgit",
2329                                      };
2330                 }
2331             } else {
2332                 printf STDERR
2333                     " orig: no suitable origs found (looked for %s in %s)\n",
2334                     "${p}_".(stripeoch $version)."...", $bpd;
2335             }
2336         }
2337     }
2338
2339     my $some_patches = stat_exists 'debian/patches/series';
2340
2341     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2342
2343     my $result;
2344     foreach my $u (@upstreams) {
2345         my $work = $head;
2346         fresh_workarea();
2347         in_workarea sub {
2348             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2349             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2350             runcmd @git, qw(clean -xdff);
2351             runcmd @git, qw(checkout), $head, qw(-- debian);
2352             if ($some_patches) {
2353                 rm_subdir_cached 'debian/patches';
2354                 $work = make_commit [ $work ], [
2355  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2356  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2357  "to git-debrebase format.  Upstream changes will appear as commits.",
2358  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2359                                            ];
2360             }
2361             $work = make_commit [ $work, $u->{Commit} ], [
2362  'git-debrebase convert-from-dgit-view: declare upstream',
2363  '(Re)constructed breakwater merge.',
2364  '[git-debrebase anchor: declare upstream]'
2365                                                          ];
2366             runcmd @git, qw(checkout --quiet -b mk), $work;
2367             if ($some_patches) {
2368                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2369                 runcmd @git, qw(reset --quiet);
2370                 my @gbp_cmd = (qw(gbp pq import));
2371                 if (!$diagnose) {
2372                     my $gbp_err = "../gbp-pq-err";
2373                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2374                 }
2375                 my $r = system @gbp_cmd;
2376                 if ($r) {
2377                     printf STDERR
2378                         " %s: couldn't apply patches: gbp pq %s",
2379                         $u->{Source}, waitstatusmsg();
2380                     return;
2381                 }
2382             }
2383             my $work = git_rev_parse qw(HEAD);
2384             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2385             if (length $diffout) {
2386                 print STDERR
2387                     " $u->{Source}: applying patches gives different tree\n";
2388                 print STDERR $diffout if $diagnose;
2389                 return;
2390             }
2391             # OMG!
2392             $u->{Result} = $work;
2393             $result = $u;
2394         };
2395         last if $result;
2396     }
2397
2398     if (!$result) {
2399         fail <<END;
2400 Could not find or construct a suitable upstream commit.
2401 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2402 upstream commmit explicitly or provide suitable origs.
2403 END
2404     }
2405
2406     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2407
2408     ffq_check $result->{Result};
2409     snags_maybe_bail();
2410     update_head_checkout $head, $result->{Result},
2411         'convert-from-dgit-view';
2412 }
2413
2414 sub cmd_downstream_rebase_launder_v0 () {
2415     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2416     my ($base) = @ARGV;
2417     $base = git_rev_parse $base;
2418     my $old_head = get_head();
2419     my $current = $old_head;
2420     my $topmost_keep;
2421     for (;;) {
2422         if ($current eq $base) {
2423             $topmost_keep //= $current;
2424             print " $current BASE stop\n";
2425             last;
2426         }
2427         my $cl = classify $current;
2428         print " $current $cl->{Type}";
2429         my $keep = 0;
2430         my $p0 = $cl->{Parents}[0]{CommitId};
2431         my $next;
2432         if ($cl->{Type} eq 'Pseudomerge') {
2433             print " ^".($cl->{Contributor}{Ix}+1);
2434             $next = $cl->{Contributor}{CommitId};
2435         } elsif ($cl->{Type} eq 'AddPatches' or
2436                  $cl->{Type} eq 'Changelog') {
2437             print " strip";
2438             $next = $p0;
2439         } else {
2440             print " keep";
2441             $next = $p0;
2442             $keep = 1;
2443         }
2444         print "\n";
2445         if ($keep) {
2446             $topmost_keep //= $current;
2447         } else {
2448             die "to-be stripped changes not on top of the branch\n"
2449                 if $topmost_keep;
2450         }
2451         $current = $next;
2452     }
2453     if ($topmost_keep eq $old_head) {
2454         print "unchanged\n";
2455     } else {
2456         print "updating to $topmost_keep\n";
2457         update_head_checkout
2458             $old_head, $topmost_keep,
2459             'downstream-rebase-launder-v0';
2460     }
2461 }
2462
2463 getoptions_main
2464           ("bad options\n",
2465            "D+" => \$debuglevel,
2466            'noop-ok', => \$opt_noop_ok,
2467            'f=s' => \@snag_force_opts,
2468            'anchor=s' => \@opt_anchors,
2469            '--dgit=s' => \($dgit[0]),
2470            'force!',
2471            '-i:s' => sub {
2472                my ($opt,$val) = @_;
2473                badusage "git-debrebase: no cuddling to -i for git-rebase"
2474                    if length $val;
2475                die if $opt_defaultcmd_interactive; # should not happen
2476                $opt_defaultcmd_interactive = [ qw(-i) ];
2477                # This access to @ARGV is excessive familiarity with
2478                # Getopt::Long, but there isn't another sensible
2479                # approach.  '-i=s{0,}' does not work with bundling.
2480                push @$opt_defaultcmd_interactive, @ARGV;
2481                @ARGV=();
2482            },
2483            'help' => sub { print $usage_message or die $!; finish 0; },
2484            );
2485
2486 initdebug('git-debrebase ');
2487 enabledebug if $debuglevel;
2488
2489 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2490 chdir $toplevel or die "chdir $toplevel: $!";
2491
2492 $rd = fresh_playground "$playprefix/misc";
2493
2494 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2495
2496 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2497     defaultcmd_rebase();
2498 } else {
2499     my $cmd = shift @ARGV;
2500     my $cmdfn = $cmd;
2501     $cmdfn =~ y/-/_/;
2502     $cmdfn = ${*::}{"cmd_$cmdfn"};
2503
2504     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2505     $cmdfn->();
2506 }
2507
2508 finish 0;