chiark / gitweb /
dgit: build_source bypasses dpkg-buildpackage
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013-2016 Ian Jackson
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20 use strict;
21
22 use Debian::Dgit qw(:DEFAULT :playground);
23 setup_sigwarn();
24
25 use IO::Handle;
26 use Data::Dumper;
27 use LWP::UserAgent;
28 use Dpkg::Control::Hash;
29 use File::Path;
30 use File::Temp qw(tempdir);
31 use File::Basename;
32 use Dpkg::Version;
33 use Dpkg::Compression;
34 use Dpkg::Compression::Process;
35 use POSIX;
36 use IPC::Open2;
37 use Digest::SHA;
38 use Digest::MD5;
39 use List::MoreUtils qw(pairwise);
40 use Text::Glob qw(match_glob);
41 use Fcntl qw(:DEFAULT :flock);
42 use Carp;
43
44 use Debian::Dgit;
45
46 our $our_version = 'UNRELEASED'; ###substituted###
47 our $absurdity = undef; ###substituted###
48
49 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
50 our $protovsn;
51
52 our $cmd;
53 our $subcommand;
54 our $isuite;
55 our $idistro;
56 our $package;
57 our @ropts;
58
59 our $sign = 1;
60 our $dryrun_level = 0;
61 our $changesfile;
62 our $buildproductsdir = '..';
63 our $new_package = 0;
64 our $ignoredirty = 0;
65 our $rmonerror = 1;
66 our @deliberatelies;
67 our %previously;
68 our $existing_package = 'dpkg';
69 our $cleanmode;
70 our $changes_since_version;
71 our $rmchanges;
72 our $overwrite_version; # undef: not specified; '': check changelog
73 our $quilt_mode;
74 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
75 our $dodep14tag;
76 our $split_brain_save;
77 our $we_are_responder;
78 our $we_are_initiator;
79 our $initiator_tempdir;
80 our $patches_applied_dirtily = 00;
81 our $tagformat_want;
82 our $tagformat;
83 our $tagformatfn;
84 our $chase_dsc_distro=1;
85
86 our %forceopts = map { $_=>0 }
87     qw(unrepresentable unsupported-source-format
88        dsc-changes-mismatch changes-origs-exactly
89        import-gitapply-absurd
90        import-gitapply-no-absurd
91        import-dsc-with-dgit-field);
92
93 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
94
95 our $suite_re = '[-+.0-9a-z]+';
96 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
97 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
98 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
99 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
100
101 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
102 our $splitbraincache = 'dgit-intern/quilt-cache';
103 our $rewritemap = 'dgit-rewrite/map';
104
105 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
106
107 our (@git) = qw(git);
108 our (@dget) = qw(dget);
109 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
110 our (@dput) = qw(dput);
111 our (@debsign) = qw(debsign);
112 our (@gpg) = qw(gpg);
113 our (@sbuild) = qw(sbuild);
114 our (@ssh) = 'ssh';
115 our (@dgit) = qw(dgit);
116 our (@aptget) = qw(apt-get);
117 our (@aptcache) = qw(apt-cache);
118 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
119 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
120 our (@dpkggenchanges) = qw(dpkg-genchanges);
121 our (@mergechanges) = qw(mergechanges -f);
122 our (@gbp_build) = ('');
123 our (@gbp_pq) = ('gbp pq');
124 our (@changesopts) = ('');
125
126 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
127                      'curl' => \@curl,
128                      'dput' => \@dput,
129                      'debsign' => \@debsign,
130                      'gpg' => \@gpg,
131                      'sbuild' => \@sbuild,
132                      'ssh' => \@ssh,
133                      'dgit' => \@dgit,
134                      'git' => \@git,
135                      'apt-get' => \@aptget,
136                      'apt-cache' => \@aptcache,
137                      'dpkg-source' => \@dpkgsource,
138                      'dpkg-buildpackage' => \@dpkgbuildpackage,
139                      'dpkg-genchanges' => \@dpkggenchanges,
140                      'gbp-build' => \@gbp_build,
141                      'gbp-pq' => \@gbp_pq,
142                      'ch' => \@changesopts,
143                      'mergechanges' => \@mergechanges);
144
145 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
146 our %opts_cfg_insertpos = map {
147     $_,
148     scalar @{ $opts_opt_map{$_} }
149 } keys %opts_opt_map;
150
151 sub parseopts_late_defaults();
152 sub setup_gitattrs(;$);
153 sub check_gitattrs($$);
154
155 our $keyid;
156
157 autoflush STDOUT 1;
158
159 our $supplementary_message = '';
160 our $need_split_build_invocation = 0;
161 our $split_brain = 0;
162
163 END {
164     local ($@, $?);
165     return unless forkcheck_mainprocess();
166     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
167 }
168
169 our $remotename = 'dgit';
170 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
171 our $csuite;
172 our $instead_distro;
173
174 if (!defined $absurdity) {
175     $absurdity = $0;
176     $absurdity =~ s{/[^/]+$}{/absurd} or die;
177 }
178
179 sub debiantag ($$) {
180     my ($v,$distro) = @_;
181     return $tagformatfn->($v, $distro);
182 }
183
184 sub debiantag_maintview ($$) { 
185     my ($v,$distro) = @_;
186     return "$distro/".dep14_version_mangle $v;
187 }
188
189 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
190
191 sub lbranch () { return "$branchprefix/$csuite"; }
192 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
193 sub lref () { return "refs/heads/".lbranch(); }
194 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
195 sub rrref () { return server_ref($csuite); }
196
197 sub stripepoch ($) {
198     my ($vsn) = @_;
199     $vsn =~ s/^\d+\://;
200     return $vsn;
201 }
202
203 sub srcfn ($$) {
204     my ($vsn,$sfx) = @_;
205     return "${package}_".(stripepoch $vsn).$sfx
206 }
207
208 sub dscfn ($) {
209     my ($vsn) = @_;
210     return srcfn($vsn,".dsc");
211 }
212
213 sub changespat ($;$) {
214     my ($vsn, $arch) = @_;
215     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
216 }
217
218 sub upstreamversion ($) {
219     my ($vsn) = @_;
220     $vsn =~ s/-[^-]+$//;
221     return $vsn;
222 }
223
224 our $us = 'dgit';
225 initdebug('');
226
227 our @end;
228 END { 
229     local ($?);
230     return unless forkcheck_mainprocess();
231     foreach my $f (@end) {
232         eval { $f->(); };
233         print STDERR "$us: cleanup: $@" if length $@;
234     }
235 };
236
237 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
238
239 sub forceable_fail ($$) {
240     my ($forceoptsl, $msg) = @_;
241     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
242     print STDERR "warning: overriding problem due to --force:\n". $msg;
243 }
244
245 sub forceing ($) {
246     my ($forceoptsl) = @_;
247     my @got = grep { $forceopts{$_} } @$forceoptsl;
248     return 0 unless @got;
249     print STDERR
250  "warning: skipping checks or functionality due to --force-$got[0]\n";
251 }
252
253 sub no_such_package () {
254     print STDERR "$us: package $package does not exist in suite $isuite\n";
255     exit 4;
256 }
257
258 sub deliberately ($) {
259     my ($enquiry) = @_;
260     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
261 }
262
263 sub deliberately_not_fast_forward () {
264     foreach (qw(not-fast-forward fresh-repo)) {
265         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
266     }
267 }
268
269 sub quiltmode_splitbrain () {
270     $quilt_mode =~ m/gbp|dpm|unapplied/;
271 }
272
273 sub opts_opt_multi_cmd {
274     my @cmd;
275     push @cmd, split /\s+/, shift @_;
276     push @cmd, @_;
277     @cmd;
278 }
279
280 sub gbp_pq {
281     return opts_opt_multi_cmd @gbp_pq;
282 }
283
284 sub dgit_privdir () {
285     our $dgit_privdir_made //= ensure_a_playground 'dgit';
286 }
287
288 #---------- remote protocol support, common ----------
289
290 # remote push initiator/responder protocol:
291 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
292 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
293 #  < dgit-remote-push-ready <actual-proto-vsn>
294 #
295 # occasionally:
296 #
297 #  > progress NBYTES
298 #  [NBYTES message]
299 #
300 #  > supplementary-message NBYTES          # $protovsn >= 3
301 #  [NBYTES message]
302 #
303 # main sequence:
304 #
305 #  > file parsed-changelog
306 #  [indicates that output of dpkg-parsechangelog follows]
307 #  > data-block NBYTES
308 #  > [NBYTES bytes of data (no newline)]
309 #  [maybe some more blocks]
310 #  > data-end
311 #
312 #  > file dsc
313 #  [etc]
314 #
315 #  > file changes
316 #  [etc]
317 #
318 #  > param head DGIT-VIEW-HEAD
319 #  > param csuite SUITE
320 #  > param tagformat old|new
321 #  > param maint-view MAINT-VIEW-HEAD
322 #
323 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
324 #  > file buildinfo                             # for buildinfos to sign
325 #
326 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
327 #                                     # goes into tag, for replay prevention
328 #
329 #  > want signed-tag
330 #  [indicates that signed tag is wanted]
331 #  < data-block NBYTES
332 #  < [NBYTES bytes of data (no newline)]
333 #  [maybe some more blocks]
334 #  < data-end
335 #  < files-end
336 #
337 #  > want signed-dsc-changes
338 #  < data-block NBYTES    [transfer of signed dsc]
339 #  [etc]
340 #  < data-block NBYTES    [transfer of signed changes]
341 #  [etc]
342 #  < data-block NBYTES    [transfer of each signed buildinfo
343 #  [etc]                   same number and order as "file buildinfo"]
344 #  ...
345 #  < files-end
346 #
347 #  > complete
348
349 our $i_child_pid;
350
351 sub i_child_report () {
352     # Sees if our child has died, and reap it if so.  Returns a string
353     # describing how it died if it failed, or undef otherwise.
354     return undef unless $i_child_pid;
355     my $got = waitpid $i_child_pid, WNOHANG;
356     return undef if $got <= 0;
357     die unless $got == $i_child_pid;
358     $i_child_pid = undef;
359     return undef unless $?;
360     return "build host child ".waitstatusmsg();
361 }
362
363 sub badproto ($$) {
364     my ($fh, $m) = @_;
365     fail "connection lost: $!" if $fh->error;
366     fail "protocol violation; $m not expected";
367 }
368
369 sub badproto_badread ($$) {
370     my ($fh, $wh) = @_;
371     fail "connection lost: $!" if $!;
372     my $report = i_child_report();
373     fail $report if defined $report;
374     badproto $fh, "eof (reading $wh)";
375 }
376
377 sub protocol_expect (&$) {
378     my ($match, $fh) = @_;
379     local $_;
380     $_ = <$fh>;
381     defined && chomp or badproto_badread $fh, "protocol message";
382     if (wantarray) {
383         my @r = &$match;
384         return @r if @r;
385     } else {
386         my $r = &$match;
387         return $r if $r;
388     }
389     badproto $fh, "\`$_'";
390 }
391
392 sub protocol_send_file ($$) {
393     my ($fh, $ourfn) = @_;
394     open PF, "<", $ourfn or die "$ourfn: $!";
395     for (;;) {
396         my $d;
397         my $got = read PF, $d, 65536;
398         die "$ourfn: $!" unless defined $got;
399         last if !$got;
400         print $fh "data-block ".length($d)."\n" or die $!;
401         print $fh $d or die $!;
402     }
403     PF->error and die "$ourfn $!";
404     print $fh "data-end\n" or die $!;
405     close PF;
406 }
407
408 sub protocol_read_bytes ($$) {
409     my ($fh, $nbytes) = @_;
410     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
411     my $d;
412     my $got = read $fh, $d, $nbytes;
413     $got==$nbytes or badproto_badread $fh, "data block";
414     return $d;
415 }
416
417 sub protocol_receive_file ($$) {
418     my ($fh, $ourfn) = @_;
419     printdebug "() $ourfn\n";
420     open PF, ">", $ourfn or die "$ourfn: $!";
421     for (;;) {
422         my ($y,$l) = protocol_expect {
423             m/^data-block (.*)$/ ? (1,$1) :
424             m/^data-end$/ ? (0,) :
425             ();
426         } $fh;
427         last unless $y;
428         my $d = protocol_read_bytes $fh, $l;
429         print PF $d or die $!;
430     }
431     close PF or die $!;
432 }
433
434 #---------- remote protocol support, responder ----------
435
436 sub responder_send_command ($) {
437     my ($command) = @_;
438     return unless $we_are_responder;
439     # called even without $we_are_responder
440     printdebug ">> $command\n";
441     print PO $command, "\n" or die $!;
442 }    
443
444 sub responder_send_file ($$) {
445     my ($keyword, $ourfn) = @_;
446     return unless $we_are_responder;
447     printdebug "]] $keyword $ourfn\n";
448     responder_send_command "file $keyword";
449     protocol_send_file \*PO, $ourfn;
450 }
451
452 sub responder_receive_files ($@) {
453     my ($keyword, @ourfns) = @_;
454     die unless $we_are_responder;
455     printdebug "[[ $keyword @ourfns\n";
456     responder_send_command "want $keyword";
457     foreach my $fn (@ourfns) {
458         protocol_receive_file \*PI, $fn;
459     }
460     printdebug "[[\$\n";
461     protocol_expect { m/^files-end$/ } \*PI;
462 }
463
464 #---------- remote protocol support, initiator ----------
465
466 sub initiator_expect (&) {
467     my ($match) = @_;
468     protocol_expect { &$match } \*RO;
469 }
470
471 #---------- end remote code ----------
472
473 sub progress {
474     if ($we_are_responder) {
475         my $m = join '', @_;
476         responder_send_command "progress ".length($m) or die $!;
477         print PO $m or die $!;
478     } else {
479         print @_, "\n";
480     }
481 }
482
483 our $ua;
484
485 sub url_get {
486     if (!$ua) {
487         $ua = LWP::UserAgent->new();
488         $ua->env_proxy;
489     }
490     my $what = $_[$#_];
491     progress "downloading $what...";
492     my $r = $ua->get(@_) or die $!;
493     return undef if $r->code == 404;
494     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
495     return $r->decoded_content(charset => 'none');
496 }
497
498 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
499
500 sub act_local () { return $dryrun_level <= 1; }
501 sub act_scary () { return !$dryrun_level; }
502
503 sub printdone {
504     if (!$dryrun_level) {
505         progress "$us ok: @_";
506     } else {
507         progress "would be ok: @_ (but dry run only)";
508     }
509 }
510
511 sub dryrun_report {
512     printcmd(\*STDERR,$debugprefix."#",@_);
513 }
514
515 sub runcmd_ordryrun {
516     if (act_scary()) {
517         runcmd @_;
518     } else {
519         dryrun_report @_;
520     }
521 }
522
523 sub runcmd_ordryrun_local {
524     if (act_local()) {
525         runcmd @_;
526     } else {
527         dryrun_report @_;
528     }
529 }
530
531 sub shell_cmd {
532     my ($first_shell, @cmd) = @_;
533     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
534 }
535
536 our $helpmsg = <<END;
537 main usages:
538   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
539   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
540   dgit [dgit-opts] build [dpkg-buildpackage-opts]
541   dgit [dgit-opts] sbuild [sbuild-opts]
542   dgit [dgit-opts] push [dgit-opts] [suite]
543   dgit [dgit-opts] rpush build-host:build-dir ...
544 important dgit options:
545   -k<keyid>           sign tag and package with <keyid> instead of default
546   --dry-run -n        do not change anything, but go through the motions
547   --damp-run -L       like --dry-run but make local changes, without signing
548   --new -N            allow introducing a new package
549   --debug -D          increase debug level
550   -c<name>=<value>    set git config option (used directly by dgit too)
551 END
552
553 our $later_warning_msg = <<END;
554 Perhaps the upload is stuck in incoming.  Using the version from git.
555 END
556
557 sub badusage {
558     print STDERR "$us: @_\n", $helpmsg or die $!;
559     exit 8;
560 }
561
562 sub nextarg {
563     @ARGV or badusage "too few arguments";
564     return scalar shift @ARGV;
565 }
566
567 sub pre_help () {
568     not_necessarily_a_tree();
569 }
570 sub cmd_help () {
571     print $helpmsg or die $!;
572     exit 0;
573 }
574
575 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
576
577 our %defcfg = ('dgit.default.distro' => 'debian',
578                'dgit.default.default-suite' => 'unstable',
579                'dgit.default.old-dsc-distro' => 'debian',
580                'dgit-suite.*-security.distro' => 'debian-security',
581                'dgit.default.username' => '',
582                'dgit.default.archive-query-default-component' => 'main',
583                'dgit.default.ssh' => 'ssh',
584                'dgit.default.archive-query' => 'madison:',
585                'dgit.default.sshpsql-dbname' => 'service=projectb',
586                'dgit.default.aptget-components' => 'main',
587                'dgit.default.dgit-tag-format' => 'new,old,maint',
588                'dgit.dsc-url-proto-ok.http'    => 'true',
589                'dgit.dsc-url-proto-ok.https'   => 'true',
590                'dgit.dsc-url-proto-ok.git'     => 'true',
591                'dgit.default.dsc-url-proto-ok' => 'false',
592                # old means "repo server accepts pushes with old dgit tags"
593                # new means "repo server accepts pushes with new dgit tags"
594                # maint means "repo server accepts split brain pushes"
595                # hist means "repo server may have old pushes without new tag"
596                #   ("hist" is implied by "old")
597                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
598                'dgit-distro.debian.git-check' => 'url',
599                'dgit-distro.debian.git-check-suffix' => '/info/refs',
600                'dgit-distro.debian.new-private-pushers' => 't',
601                'dgit-distro.debian/push.git-url' => '',
602                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
603                'dgit-distro.debian/push.git-user-force' => 'dgit',
604                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
605                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
606                'dgit-distro.debian/push.git-create' => 'true',
607                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
608  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
609 # 'dgit-distro.debian.archive-query-tls-key',
610 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
611 # ^ this does not work because curl is broken nowadays
612 # Fixing #790093 properly will involve providing providing the key
613 # in some pacagke and maybe updating these paths.
614 #
615 # 'dgit-distro.debian.archive-query-tls-curl-args',
616 #   '--ca-path=/etc/ssl/ca-debian',
617 # ^ this is a workaround but works (only) on DSA-administered machines
618                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
619                'dgit-distro.debian.git-url-suffix' => '',
620                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
621                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
622  'dgit-distro.debian-security.archive-query' => 'aptget:',
623  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
624  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
625  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
626  'dgit-distro.debian-security.nominal-distro' => 'debian',
627  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
628  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
629                'dgit-distro.ubuntu.git-check' => 'false',
630  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
631                'dgit-distro.test-dummy.ssh' => "$td/ssh",
632                'dgit-distro.test-dummy.username' => "alice",
633                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
634                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
635                'dgit-distro.test-dummy.git-url' => "$td/git",
636                'dgit-distro.test-dummy.git-host' => "git",
637                'dgit-distro.test-dummy.git-path' => "$td/git",
638                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
639                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
640                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
641                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
642                );
643
644 our %gitcfgs;
645 our @gitcfgsources = qw(cmdline local global system);
646 our $invoked_in_git_tree = 1;
647
648 sub git_slurp_config () {
649     # This algoritm is a bit subtle, but this is needed so that for
650     # options which we want to be single-valued, we allow the
651     # different config sources to override properly.  See #835858.
652     foreach my $src (@gitcfgsources) {
653         next if $src eq 'cmdline';
654         # we do this ourselves since git doesn't handle it
655
656         $gitcfgs{$src} = git_slurp_config_src $src;
657     }
658 }
659
660 sub git_get_config ($) {
661     my ($c) = @_;
662     foreach my $src (@gitcfgsources) {
663         my $l = $gitcfgs{$src}{$c};
664         confess "internal error ($l $c)" if $l && !ref $l;
665         printdebug"C $c ".(defined $l ?
666                            join " ", map { messagequote "'$_'" } @$l :
667                            "undef")."\n"
668             if $debuglevel >= 4;
669         $l or next;
670         @$l==1 or badcfg "multiple values for $c".
671             " (in $src git config)" if @$l > 1;
672         return $l->[0];
673     }
674     return undef;
675 }
676
677 sub cfg {
678     foreach my $c (@_) {
679         return undef if $c =~ /RETURN-UNDEF/;
680         printdebug "C? $c\n" if $debuglevel >= 5;
681         my $v = git_get_config($c);
682         return $v if defined $v;
683         my $dv = $defcfg{$c};
684         if (defined $dv) {
685             printdebug "CD $c $dv\n" if $debuglevel >= 4;
686             return $dv;
687         }
688     }
689     badcfg "need value for one of: @_\n".
690         "$us: distro or suite appears not to be (properly) supported";
691 }
692
693 sub not_necessarily_a_tree () {
694     # needs to be called from pre_*
695     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
696     $invoked_in_git_tree = 0;
697 }
698
699 sub access_basedistro__noalias () {
700     if (defined $idistro) {
701         return $idistro;
702     } else {    
703         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
704         return $def if defined $def;
705         foreach my $src (@gitcfgsources, 'internal') {
706             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
707             next unless $kl;
708             foreach my $k (keys %$kl) {
709                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
710                 my $dpat = $1;
711                 next unless match_glob $dpat, $isuite;
712                 return $kl->{$k};
713             }
714         }
715         return cfg("dgit.default.distro");
716     }
717 }
718
719 sub access_basedistro () {
720     my $noalias = access_basedistro__noalias();
721     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
722     return $canon // $noalias;
723 }
724
725 sub access_nomdistro () {
726     my $base = access_basedistro();
727     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
728     $r =~ m/^$distro_re$/ or badcfg
729  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
730     return $r;
731 }
732
733 sub access_quirk () {
734     # returns (quirk name, distro to use instead or undef, quirk-specific info)
735     my $basedistro = access_basedistro();
736     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
737                               'RETURN-UNDEF');
738     if (defined $backports_quirk) {
739         my $re = $backports_quirk;
740         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
741         $re =~ s/\*/.*/g;
742         $re =~ s/\%/([-0-9a-z_]+)/
743             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
744         if ($isuite =~ m/^$re$/) {
745             return ('backports',"$basedistro-backports",$1);
746         }
747     }
748     return ('none',undef);
749 }
750
751 our $access_forpush;
752
753 sub parse_cfg_bool ($$$) {
754     my ($what,$def,$v) = @_;
755     $v //= $def;
756     return
757         $v =~ m/^[ty1]/ ? 1 :
758         $v =~ m/^[fn0]/ ? 0 :
759         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
760 }       
761
762 sub access_forpush_config () {
763     my $d = access_basedistro();
764
765     return 1 if
766         $new_package &&
767         parse_cfg_bool('new-private-pushers', 0,
768                        cfg("dgit-distro.$d.new-private-pushers",
769                            'RETURN-UNDEF'));
770
771     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
772     $v //= 'a';
773     return
774         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
775         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
776         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
777         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
778 }
779
780 sub access_forpush () {
781     $access_forpush //= access_forpush_config();
782     return $access_forpush;
783 }
784
785 sub pushing () {
786     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
787     badcfg "pushing but distro is configured readonly"
788         if access_forpush_config() eq '0';
789     $access_forpush = 1;
790     $supplementary_message = <<'END' unless $we_are_responder;
791 Push failed, before we got started.
792 You can retry the push, after fixing the problem, if you like.
793 END
794     parseopts_late_defaults();
795 }
796
797 sub notpushing () {
798     parseopts_late_defaults();
799 }
800
801 sub supplementary_message ($) {
802     my ($msg) = @_;
803     if (!$we_are_responder) {
804         $supplementary_message = $msg;
805         return;
806     } elsif ($protovsn >= 3) {
807         responder_send_command "supplementary-message ".length($msg)
808             or die $!;
809         print PO $msg or die $!;
810     }
811 }
812
813 sub access_distros () {
814     # Returns list of distros to try, in order
815     #
816     # We want to try:
817     #    0. `instead of' distro name(s) we have been pointed to
818     #    1. the access_quirk distro, if any
819     #    2a. the user's specified distro, or failing that  } basedistro
820     #    2b. the distro calculated from the suite          }
821     my @l = access_basedistro();
822
823     my (undef,$quirkdistro) = access_quirk();
824     unshift @l, $quirkdistro;
825     unshift @l, $instead_distro;
826     @l = grep { defined } @l;
827
828     push @l, access_nomdistro();
829
830     if (access_forpush()) {
831         @l = map { ("$_/push", $_) } @l;
832     }
833     @l;
834 }
835
836 sub access_cfg_cfgs (@) {
837     my (@keys) = @_;
838     my @cfgs;
839     # The nesting of these loops determines the search order.  We put
840     # the key loop on the outside so that we search all the distros
841     # for each key, before going on to the next key.  That means that
842     # if access_cfg is called with a more specific, and then a less
843     # specific, key, an earlier distro can override the less specific
844     # without necessarily overriding any more specific keys.  (If the
845     # distro wants to override the more specific keys it can simply do
846     # so; whereas if we did the loop the other way around, it would be
847     # impossible to for an earlier distro to override a less specific
848     # key but not the more specific ones without restating the unknown
849     # values of the more specific keys.
850     my @realkeys;
851     my @rundef;
852     # We have to deal with RETURN-UNDEF specially, so that we don't
853     # terminate the search prematurely.
854     foreach (@keys) {
855         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
856         push @realkeys, $_
857     }
858     foreach my $d (access_distros()) {
859         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
860     }
861     push @cfgs, map { "dgit.default.$_" } @realkeys;
862     push @cfgs, @rundef;
863     return @cfgs;
864 }
865
866 sub access_cfg (@) {
867     my (@keys) = @_;
868     my (@cfgs) = access_cfg_cfgs(@keys);
869     my $value = cfg(@cfgs);
870     return $value;
871 }
872
873 sub access_cfg_bool ($$) {
874     my ($def, @keys) = @_;
875     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
876 }
877
878 sub string_to_ssh ($) {
879     my ($spec) = @_;
880     if ($spec =~ m/\s/) {
881         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
882     } else {
883         return ($spec);
884     }
885 }
886
887 sub access_cfg_ssh () {
888     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
889     if (!defined $gitssh) {
890         return @ssh;
891     } else {
892         return string_to_ssh $gitssh;
893     }
894 }
895
896 sub access_runeinfo ($) {
897     my ($info) = @_;
898     return ": dgit ".access_basedistro()." $info ;";
899 }
900
901 sub access_someuserhost ($) {
902     my ($some) = @_;
903     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
904     defined($user) && length($user) or
905         $user = access_cfg("$some-user",'username');
906     my $host = access_cfg("$some-host");
907     return length($user) ? "$user\@$host" : $host;
908 }
909
910 sub access_gituserhost () {
911     return access_someuserhost('git');
912 }
913
914 sub access_giturl (;$) {
915     my ($optional) = @_;
916     my $url = access_cfg('git-url','RETURN-UNDEF');
917     my $suffix;
918     if (!length $url) {
919         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
920         return undef unless defined $proto;
921         $url =
922             $proto.
923             access_gituserhost().
924             access_cfg('git-path');
925     } else {
926         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
927     }
928     $suffix //= '.git';
929     return "$url/$package$suffix";
930 }              
931
932 sub parsecontrolfh ($$;$) {
933     my ($fh, $desc, $allowsigned) = @_;
934     our $dpkgcontrolhash_noissigned;
935     my $c;
936     for (;;) {
937         my %opts = ('name' => $desc);
938         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
939         $c = Dpkg::Control::Hash->new(%opts);
940         $c->parse($fh,$desc) or die "parsing of $desc failed";
941         last if $allowsigned;
942         last if $dpkgcontrolhash_noissigned;
943         my $issigned= $c->get_option('is_pgp_signed');
944         if (!defined $issigned) {
945             $dpkgcontrolhash_noissigned= 1;
946             seek $fh, 0,0 or die "seek $desc: $!";
947         } elsif ($issigned) {
948             fail "control file $desc is (already) PGP-signed. ".
949                 " Note that dgit push needs to modify the .dsc and then".
950                 " do the signature itself";
951         } else {
952             last;
953         }
954     }
955     return $c;
956 }
957
958 sub parsecontrol {
959     my ($file, $desc, $allowsigned) = @_;
960     my $fh = new IO::Handle;
961     open $fh, '<', $file or die "$file: $!";
962     my $c = parsecontrolfh($fh,$desc,$allowsigned);
963     $fh->error and die $!;
964     close $fh;
965     return $c;
966 }
967
968 sub getfield ($$) {
969     my ($dctrl,$field) = @_;
970     my $v = $dctrl->{$field};
971     return $v if defined $v;
972     fail "missing field $field in ".$dctrl->get_option('name');
973 }
974
975 sub parsechangelog {
976     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
977     my $p = new IO::Handle;
978     my @cmd = (qw(dpkg-parsechangelog), @_);
979     open $p, '-|', @cmd or die $!;
980     $c->parse($p);
981     $?=0; $!=0; close $p or failedcmd @cmd;
982     return $c;
983 }
984
985 sub commit_getclogp ($) {
986     # Returns the parsed changelog hashref for a particular commit
987     my ($objid) = @_;
988     our %commit_getclogp_memo;
989     my $memo = $commit_getclogp_memo{$objid};
990     return $memo if $memo;
991
992     my $mclog = dgit_privdir()."clog";
993     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
994         "$objid:debian/changelog";
995     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
996 }
997
998 sub parse_dscdata () {
999     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1000     printdebug Dumper($dscdata) if $debuglevel>1;
1001     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1002     printdebug Dumper($dsc) if $debuglevel>1;
1003 }
1004
1005 our %rmad;
1006
1007 sub archive_query ($;@) {
1008     my ($method) = shift @_;
1009     fail "this operation does not support multiple comma-separated suites"
1010         if $isuite =~ m/,/;
1011     my $query = access_cfg('archive-query','RETURN-UNDEF');
1012     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1013     my $proto = $1;
1014     my $data = $'; #';
1015     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1016 }
1017
1018 sub archive_query_prepend_mirror {
1019     my $m = access_cfg('mirror');
1020     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1021 }
1022
1023 sub pool_dsc_subpath ($$) {
1024     my ($vsn,$component) = @_; # $package is implict arg
1025     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1026     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1027 }
1028
1029 sub cfg_apply_map ($$$) {
1030     my ($varref, $what, $mapspec) = @_;
1031     return unless $mapspec;
1032
1033     printdebug "config $what EVAL{ $mapspec; }\n";
1034     $_ = $$varref;
1035     eval "package Dgit::Config; $mapspec;";
1036     die $@ if $@;
1037     $$varref = $_;
1038 }
1039
1040 #---------- `ftpmasterapi' archive query method (nascent) ----------
1041
1042 sub archive_api_query_cmd ($) {
1043     my ($subpath) = @_;
1044     my @cmd = (@curl, qw(-sS));
1045     my $url = access_cfg('archive-query-url');
1046     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1047         my $host = $1;
1048         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1049         foreach my $key (split /\:/, $keys) {
1050             $key =~ s/\%HOST\%/$host/g;
1051             if (!stat $key) {
1052                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1053                 next;
1054             }
1055             fail "config requested specific TLS key but do not know".
1056                 " how to get curl to use exactly that EE key ($key)";
1057 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1058 #           # Sadly the above line does not work because of changes
1059 #           # to gnutls.   The real fix for #790093 may involve
1060 #           # new curl options.
1061             last;
1062         }
1063         # Fixing #790093 properly will involve providing a value
1064         # for this on clients.
1065         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1066         push @cmd, split / /, $kargs if defined $kargs;
1067     }
1068     push @cmd, $url.$subpath;
1069     return @cmd;
1070 }
1071
1072 sub api_query ($$;$) {
1073     use JSON;
1074     my ($data, $subpath, $ok404) = @_;
1075     badcfg "ftpmasterapi archive query method takes no data part"
1076         if length $data;
1077     my @cmd = archive_api_query_cmd($subpath);
1078     my $url = $cmd[$#cmd];
1079     push @cmd, qw(-w %{http_code});
1080     my $json = cmdoutput @cmd;
1081     unless ($json =~ s/\d+\d+\d$//) {
1082         failedcmd_report_cmd undef, @cmd;
1083         fail "curl failed to print 3-digit HTTP code";
1084     }
1085     my $code = $&;
1086     return undef if $code eq '404' && $ok404;
1087     fail "fetch of $url gave HTTP code $code"
1088         unless $url =~ m#^file://# or $code =~ m/^2/;
1089     return decode_json($json);
1090 }
1091
1092 sub canonicalise_suite_ftpmasterapi {
1093     my ($proto,$data) = @_;
1094     my $suites = api_query($data, 'suites');
1095     my @matched;
1096     foreach my $entry (@$suites) {
1097         next unless grep { 
1098             my $v = $entry->{$_};
1099             defined $v && $v eq $isuite;
1100         } qw(codename name);
1101         push @matched, $entry;
1102     }
1103     fail "unknown suite $isuite" unless @matched;
1104     my $cn;
1105     eval {
1106         @matched==1 or die "multiple matches for suite $isuite\n";
1107         $cn = "$matched[0]{codename}";
1108         defined $cn or die "suite $isuite info has no codename\n";
1109         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1110     };
1111     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1112         if length $@;
1113     return $cn;
1114 }
1115
1116 sub archive_query_ftpmasterapi {
1117     my ($proto,$data) = @_;
1118     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1119     my @rows;
1120     my $digester = Digest::SHA->new(256);
1121     foreach my $entry (@$info) {
1122         eval {
1123             my $vsn = "$entry->{version}";
1124             my ($ok,$msg) = version_check $vsn;
1125             die "bad version: $msg\n" unless $ok;
1126             my $component = "$entry->{component}";
1127             $component =~ m/^$component_re$/ or die "bad component";
1128             my $filename = "$entry->{filename}";
1129             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1130                 or die "bad filename";
1131             my $sha256sum = "$entry->{sha256sum}";
1132             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1133             push @rows, [ $vsn, "/pool/$component/$filename",
1134                           $digester, $sha256sum ];
1135         };
1136         die "bad ftpmaster api response: $@\n".Dumper($entry)
1137             if length $@;
1138     }
1139     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1140     return archive_query_prepend_mirror @rows;
1141 }
1142
1143 sub file_in_archive_ftpmasterapi {
1144     my ($proto,$data,$filename) = @_;
1145     my $pat = $filename;
1146     $pat =~ s/_/\\_/g;
1147     $pat = "%/$pat";
1148     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1149     my $info = api_query($data, "file_in_archive/$pat", 1);
1150 }
1151
1152 #---------- `aptget' archive query method ----------
1153
1154 our $aptget_base;
1155 our $aptget_releasefile;
1156 our $aptget_configpath;
1157
1158 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1159 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1160
1161 sub aptget_cache_clean {
1162     runcmd_ordryrun_local qw(sh -ec),
1163         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1164         'x', $aptget_base;
1165 }
1166
1167 sub aptget_lock_acquire () {
1168     my $lockfile = "$aptget_base/lock";
1169     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1170     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1171 }
1172
1173 sub aptget_prep ($) {
1174     my ($data) = @_;
1175     return if defined $aptget_base;
1176
1177     badcfg "aptget archive query method takes no data part"
1178         if length $data;
1179
1180     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1181
1182     ensuredir $cache;
1183     ensuredir "$cache/dgit";
1184     my $cachekey =
1185         access_cfg('aptget-cachekey','RETURN-UNDEF')
1186         // access_nomdistro();
1187
1188     $aptget_base = "$cache/dgit/aptget";
1189     ensuredir $aptget_base;
1190
1191     my $quoted_base = $aptget_base;
1192     die "$quoted_base contains bad chars, cannot continue"
1193         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1194
1195     ensuredir $aptget_base;
1196
1197     aptget_lock_acquire();
1198
1199     aptget_cache_clean();
1200
1201     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1202     my $sourceslist = "source.list#$cachekey";
1203
1204     my $aptsuites = $isuite;
1205     cfg_apply_map(\$aptsuites, 'suite map',
1206                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1207
1208     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1209     printf SRCS "deb-src %s %s %s\n",
1210         access_cfg('mirror'),
1211         $aptsuites,
1212         access_cfg('aptget-components')
1213         or die $!;
1214
1215     ensuredir "$aptget_base/cache";
1216     ensuredir "$aptget_base/lists";
1217
1218     open CONF, ">", $aptget_configpath or die $!;
1219     print CONF <<END;
1220 Debug::NoLocking "true";
1221 APT::Get::List-Cleanup "false";
1222 #clear APT::Update::Post-Invoke-Success;
1223 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1224 Dir::State::Lists "$quoted_base/lists";
1225 Dir::Etc::preferences "$quoted_base/preferences";
1226 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1227 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1228 END
1229
1230     foreach my $key (qw(
1231                         Dir::Cache
1232                         Dir::State
1233                         Dir::Cache::Archives
1234                         Dir::Etc::SourceParts
1235                         Dir::Etc::preferencesparts
1236                       )) {
1237         ensuredir "$aptget_base/$key";
1238         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1239     };
1240
1241     my $oldatime = (time // die $!) - 1;
1242     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1243         next unless stat_exists $oldlist;
1244         my ($mtime) = (stat _)[9];
1245         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1246     }
1247
1248     runcmd_ordryrun_local aptget_aptget(), qw(update);
1249
1250     my @releasefiles;
1251     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1252         next unless stat_exists $oldlist;
1253         my ($atime) = (stat _)[8];
1254         next if $atime == $oldatime;
1255         push @releasefiles, $oldlist;
1256     }
1257     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1258     @releasefiles = @inreleasefiles if @inreleasefiles;
1259     die "apt updated wrong number of Release files (@releasefiles), erk"
1260         unless @releasefiles == 1;
1261
1262     ($aptget_releasefile) = @releasefiles;
1263 }
1264
1265 sub canonicalise_suite_aptget {
1266     my ($proto,$data) = @_;
1267     aptget_prep($data);
1268
1269     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1270
1271     foreach my $name (qw(Codename Suite)) {
1272         my $val = $release->{$name};
1273         if (defined $val) {
1274             printdebug "release file $name: $val\n";
1275             $val =~ m/^$suite_re$/o or fail
1276  "Release file ($aptget_releasefile) specifies intolerable $name";
1277             cfg_apply_map(\$val, 'suite rmap',
1278                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1279             return $val
1280         }
1281     }
1282     return $isuite;
1283 }
1284
1285 sub archive_query_aptget {
1286     my ($proto,$data) = @_;
1287     aptget_prep($data);
1288
1289     ensuredir "$aptget_base/source";
1290     foreach my $old (<$aptget_base/source/*.dsc>) {
1291         unlink $old or die "$old: $!";
1292     }
1293
1294     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1295     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1296     # avoids apt-get source failing with ambiguous error code
1297
1298     runcmd_ordryrun_local
1299         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1300         aptget_aptget(), qw(--download-only --only-source source), $package;
1301
1302     my @dscs = <$aptget_base/source/*.dsc>;
1303     fail "apt-get source did not produce a .dsc" unless @dscs;
1304     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1305
1306     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1307
1308     use URI::Escape;
1309     my $uri = "file://". uri_escape $dscs[0];
1310     $uri =~ s{\%2f}{/}gi;
1311     return [ (getfield $pre_dsc, 'Version'), $uri ];
1312 }
1313
1314 sub file_in_archive_aptget () { return undef; }
1315
1316 #---------- `dummyapicat' archive query method ----------
1317
1318 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1319 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1320
1321 sub file_in_archive_dummycatapi ($$$) {
1322     my ($proto,$data,$filename) = @_;
1323     my $mirror = access_cfg('mirror');
1324     $mirror =~ s#^file://#/# or die "$mirror ?";
1325     my @out;
1326     my @cmd = (qw(sh -ec), '
1327             cd "$1"
1328             find -name "$2" -print0 |
1329             xargs -0r sha256sum
1330         ', qw(x), $mirror, $filename);
1331     debugcmd "-|", @cmd;
1332     open FIA, "-|", @cmd or die $!;
1333     while (<FIA>) {
1334         chomp or die;
1335         printdebug "| $_\n";
1336         m/^(\w+)  (\S+)$/ or die "$_ ?";
1337         push @out, { sha256sum => $1, filename => $2 };
1338     }
1339     close FIA or die failedcmd @cmd;
1340     return \@out;
1341 }
1342
1343 #---------- `madison' archive query method ----------
1344
1345 sub archive_query_madison {
1346     return archive_query_prepend_mirror
1347         map { [ @$_[0..1] ] } madison_get_parse(@_);
1348 }
1349
1350 sub madison_get_parse {
1351     my ($proto,$data) = @_;
1352     die unless $proto eq 'madison';
1353     if (!length $data) {
1354         $data= access_cfg('madison-distro','RETURN-UNDEF');
1355         $data //= access_basedistro();
1356     }
1357     $rmad{$proto,$data,$package} ||= cmdoutput
1358         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1359     my $rmad = $rmad{$proto,$data,$package};
1360
1361     my @out;
1362     foreach my $l (split /\n/, $rmad) {
1363         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1364                   \s*( [^ \t|]+ )\s* \|
1365                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1366                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1367         $1 eq $package or die "$rmad $package ?";
1368         my $vsn = $2;
1369         my $newsuite = $3;
1370         my $component;
1371         if (defined $4) {
1372             $component = $4;
1373         } else {
1374             $component = access_cfg('archive-query-default-component');
1375         }
1376         $5 eq 'source' or die "$rmad ?";
1377         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1378     }
1379     return sort { -version_compare($a->[0],$b->[0]); } @out;
1380 }
1381
1382 sub canonicalise_suite_madison {
1383     # madison canonicalises for us
1384     my @r = madison_get_parse(@_);
1385     @r or fail
1386         "unable to canonicalise suite using package $package".
1387         " which does not appear to exist in suite $isuite;".
1388         " --existing-package may help";
1389     return $r[0][2];
1390 }
1391
1392 sub file_in_archive_madison { return undef; }
1393
1394 #---------- `sshpsql' archive query method ----------
1395
1396 sub sshpsql ($$$) {
1397     my ($data,$runeinfo,$sql) = @_;
1398     if (!length $data) {
1399         $data= access_someuserhost('sshpsql').':'.
1400             access_cfg('sshpsql-dbname');
1401     }
1402     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1403     my ($userhost,$dbname) = ($`,$'); #';
1404     my @rows;
1405     my @cmd = (access_cfg_ssh, $userhost,
1406                access_runeinfo("ssh-psql $runeinfo").
1407                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1408                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1409     debugcmd "|",@cmd;
1410     open P, "-|", @cmd or die $!;
1411     while (<P>) {
1412         chomp or die;
1413         printdebug(">|$_|\n");
1414         push @rows, $_;
1415     }
1416     $!=0; $?=0; close P or failedcmd @cmd;
1417     @rows or die;
1418     my $nrows = pop @rows;
1419     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1420     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1421     @rows = map { [ split /\|/, $_ ] } @rows;
1422     my $ncols = scalar @{ shift @rows };
1423     die if grep { scalar @$_ != $ncols } @rows;
1424     return @rows;
1425 }
1426
1427 sub sql_injection_check {
1428     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1429 }
1430
1431 sub archive_query_sshpsql ($$) {
1432     my ($proto,$data) = @_;
1433     sql_injection_check $isuite, $package;
1434     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1435         SELECT source.version, component.name, files.filename, files.sha256sum
1436           FROM source
1437           JOIN src_associations ON source.id = src_associations.source
1438           JOIN suite ON suite.id = src_associations.suite
1439           JOIN dsc_files ON dsc_files.source = source.id
1440           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1441           JOIN component ON component.id = files_archive_map.component_id
1442           JOIN files ON files.id = dsc_files.file
1443          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1444            AND source.source='$package'
1445            AND files.filename LIKE '%.dsc';
1446 END
1447     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1448     my $digester = Digest::SHA->new(256);
1449     @rows = map {
1450         my ($vsn,$component,$filename,$sha256sum) = @$_;
1451         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1452     } @rows;
1453     return archive_query_prepend_mirror @rows;
1454 }
1455
1456 sub canonicalise_suite_sshpsql ($$) {
1457     my ($proto,$data) = @_;
1458     sql_injection_check $isuite;
1459     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1460         SELECT suite.codename
1461           FROM suite where suite_name='$isuite' or codename='$isuite';
1462 END
1463     @rows = map { $_->[0] } @rows;
1464     fail "unknown suite $isuite" unless @rows;
1465     die "ambiguous $isuite: @rows ?" if @rows>1;
1466     return $rows[0];
1467 }
1468
1469 sub file_in_archive_sshpsql ($$$) { return undef; }
1470
1471 #---------- `dummycat' archive query method ----------
1472
1473 sub canonicalise_suite_dummycat ($$) {
1474     my ($proto,$data) = @_;
1475     my $dpath = "$data/suite.$isuite";
1476     if (!open C, "<", $dpath) {
1477         $!==ENOENT or die "$dpath: $!";
1478         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1479         return $isuite;
1480     }
1481     $!=0; $_ = <C>;
1482     chomp or die "$dpath: $!";
1483     close C;
1484     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1485     return $_;
1486 }
1487
1488 sub archive_query_dummycat ($$) {
1489     my ($proto,$data) = @_;
1490     canonicalise_suite();
1491     my $dpath = "$data/package.$csuite.$package";
1492     if (!open C, "<", $dpath) {
1493         $!==ENOENT or die "$dpath: $!";
1494         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1495         return ();
1496     }
1497     my @rows;
1498     while (<C>) {
1499         next if m/^\#/;
1500         next unless m/\S/;
1501         die unless chomp;
1502         printdebug "dummycat query $csuite $package $dpath | $_\n";
1503         my @row = split /\s+/, $_;
1504         @row==2 or die "$dpath: $_ ?";
1505         push @rows, \@row;
1506     }
1507     C->error and die "$dpath: $!";
1508     close C;
1509     return archive_query_prepend_mirror
1510         sort { -version_compare($a->[0],$b->[0]); } @rows;
1511 }
1512
1513 sub file_in_archive_dummycat () { return undef; }
1514
1515 #---------- tag format handling ----------
1516
1517 sub access_cfg_tagformats () {
1518     split /\,/, access_cfg('dgit-tag-format');
1519 }
1520
1521 sub access_cfg_tagformats_can_splitbrain () {
1522     my %y = map { $_ => 1 } access_cfg_tagformats;
1523     foreach my $needtf (qw(new maint)) {
1524         next if $y{$needtf};
1525         return 0;
1526     }
1527     return 1;
1528 }
1529
1530 sub need_tagformat ($$) {
1531     my ($fmt, $why) = @_;
1532     fail "need to use tag format $fmt ($why) but also need".
1533         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1534         " - no way to proceed"
1535         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1536     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1537 }
1538
1539 sub select_tagformat () {
1540     # sets $tagformatfn
1541     return if $tagformatfn && !$tagformat_want;
1542     die 'bug' if $tagformatfn && $tagformat_want;
1543     # ... $tagformat_want assigned after previous select_tagformat
1544
1545     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1546     printdebug "select_tagformat supported @supported\n";
1547
1548     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1549     printdebug "select_tagformat specified @$tagformat_want\n";
1550
1551     my ($fmt,$why,$override) = @$tagformat_want;
1552
1553     fail "target distro supports tag formats @supported".
1554         " but have to use $fmt ($why)"
1555         unless $override
1556             or grep { $_ eq $fmt } @supported;
1557
1558     $tagformat_want = undef;
1559     $tagformat = $fmt;
1560     $tagformatfn = ${*::}{"debiantag_$fmt"};
1561
1562     fail "trying to use unknown tag format \`$fmt' ($why) !"
1563         unless $tagformatfn;
1564 }
1565
1566 #---------- archive query entrypoints and rest of program ----------
1567
1568 sub canonicalise_suite () {
1569     return if defined $csuite;
1570     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1571     $csuite = archive_query('canonicalise_suite');
1572     if ($isuite ne $csuite) {
1573         progress "canonical suite name for $isuite is $csuite";
1574     } else {
1575         progress "canonical suite name is $csuite";
1576     }
1577 }
1578
1579 sub get_archive_dsc () {
1580     canonicalise_suite();
1581     my @vsns = archive_query('archive_query');
1582     foreach my $vinfo (@vsns) {
1583         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1584         $dscurl = $vsn_dscurl;
1585         $dscdata = url_get($dscurl);
1586         if (!$dscdata) {
1587             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1588             next;
1589         }
1590         if ($digester) {
1591             $digester->reset();
1592             $digester->add($dscdata);
1593             my $got = $digester->hexdigest();
1594             $got eq $digest or
1595                 fail "$dscurl has hash $got but".
1596                     " archive told us to expect $digest";
1597         }
1598         parse_dscdata();
1599         my $fmt = getfield $dsc, 'Format';
1600         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1601             "unsupported source format $fmt, sorry";
1602             
1603         $dsc_checked = !!$digester;
1604         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1605         return;
1606     }
1607     $dsc = undef;
1608     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1609 }
1610
1611 sub check_for_git ();
1612 sub check_for_git () {
1613     # returns 0 or 1
1614     my $how = access_cfg('git-check');
1615     if ($how eq 'ssh-cmd') {
1616         my @cmd =
1617             (access_cfg_ssh, access_gituserhost(),
1618              access_runeinfo("git-check $package").
1619              " set -e; cd ".access_cfg('git-path').";".
1620              " if test -d $package.git; then echo 1; else echo 0; fi");
1621         my $r= cmdoutput @cmd;
1622         if (defined $r and $r =~ m/^divert (\w+)$/) {
1623             my $divert=$1;
1624             my ($usedistro,) = access_distros();
1625             # NB that if we are pushing, $usedistro will be $distro/push
1626             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1627             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1628             progress "diverting to $divert (using config for $instead_distro)";
1629             return check_for_git();
1630         }
1631         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1632         return $r+0;
1633     } elsif ($how eq 'url') {
1634         my $prefix = access_cfg('git-check-url','git-url');
1635         my $suffix = access_cfg('git-check-suffix','git-suffix',
1636                                 'RETURN-UNDEF') // '.git';
1637         my $url = "$prefix/$package$suffix";
1638         my @cmd = (@curl, qw(-sS -I), $url);
1639         my $result = cmdoutput @cmd;
1640         $result =~ s/^\S+ 200 .*\n\r?\n//;
1641         # curl -sS -I with https_proxy prints
1642         # HTTP/1.0 200 Connection established
1643         $result =~ m/^\S+ (404|200) /s or
1644             fail "unexpected results from git check query - ".
1645                 Dumper($prefix, $result);
1646         my $code = $1;
1647         if ($code eq '404') {
1648             return 0;
1649         } elsif ($code eq '200') {
1650             return 1;
1651         } else {
1652             die;
1653         }
1654     } elsif ($how eq 'true') {
1655         return 1;
1656     } elsif ($how eq 'false') {
1657         return 0;
1658     } else {
1659         badcfg "unknown git-check \`$how'";
1660     }
1661 }
1662
1663 sub create_remote_git_repo () {
1664     my $how = access_cfg('git-create');
1665     if ($how eq 'ssh-cmd') {
1666         runcmd_ordryrun
1667             (access_cfg_ssh, access_gituserhost(),
1668              access_runeinfo("git-create $package").
1669              "set -e; cd ".access_cfg('git-path').";".
1670              " cp -a _template $package.git");
1671     } elsif ($how eq 'true') {
1672         # nothing to do
1673     } else {
1674         badcfg "unknown git-create \`$how'";
1675     }
1676 }
1677
1678 our ($dsc_hash,$lastpush_mergeinput);
1679 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1680
1681
1682 sub prep_ud () {
1683     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1684     fresh_playground 'dgit/unpack';
1685 }
1686
1687 sub mktree_in_ud_here () {
1688     playtree_setup $gitcfgs{local};
1689 }
1690
1691 sub git_write_tree () {
1692     my $tree = cmdoutput @git, qw(write-tree);
1693     $tree =~ m/^\w+$/ or die "$tree ?";
1694     return $tree;
1695 }
1696
1697 sub git_add_write_tree () {
1698     runcmd @git, qw(add -Af .);
1699     return git_write_tree();
1700 }
1701
1702 sub remove_stray_gits ($) {
1703     my ($what) = @_;
1704     my @gitscmd = qw(find -name .git -prune -print0);
1705     debugcmd "|",@gitscmd;
1706     open GITS, "-|", @gitscmd or die $!;
1707     {
1708         local $/="\0";
1709         while (<GITS>) {
1710             chomp or die;
1711             print STDERR "$us: warning: removing from $what: ",
1712                 (messagequote $_), "\n";
1713             rmtree $_;
1714         }
1715     }
1716     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1717 }
1718
1719 sub mktree_in_ud_from_only_subdir ($;$) {
1720     my ($what,$raw) = @_;
1721     # changes into the subdir
1722
1723     my (@dirs) = <*/.>;
1724     die "expected one subdir but found @dirs ?" unless @dirs==1;
1725     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1726     my $dir = $1;
1727     changedir $dir;
1728
1729     remove_stray_gits($what);
1730     mktree_in_ud_here();
1731     if (!$raw) {
1732         my ($format, $fopts) = get_source_format();
1733         if (madformat($format)) {
1734             rmtree '.pc';
1735         }
1736     }
1737
1738     my $tree=git_add_write_tree();
1739     return ($tree,$dir);
1740 }
1741
1742 our @files_csum_info_fields = 
1743     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1744      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1745      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1746
1747 sub dsc_files_info () {
1748     foreach my $csumi (@files_csum_info_fields) {
1749         my ($fname, $module, $method) = @$csumi;
1750         my $field = $dsc->{$fname};
1751         next unless defined $field;
1752         eval "use $module; 1;" or die $@;
1753         my @out;
1754         foreach (split /\n/, $field) {
1755             next unless m/\S/;
1756             m/^(\w+) (\d+) (\S+)$/ or
1757                 fail "could not parse .dsc $fname line \`$_'";
1758             my $digester = eval "$module"."->$method;" or die $@;
1759             push @out, {
1760                 Hash => $1,
1761                 Bytes => $2,
1762                 Filename => $3,
1763                 Digester => $digester,
1764             };
1765         }
1766         return @out;
1767     }
1768     fail "missing any supported Checksums-* or Files field in ".
1769         $dsc->get_option('name');
1770 }
1771
1772 sub dsc_files () {
1773     map { $_->{Filename} } dsc_files_info();
1774 }
1775
1776 sub files_compare_inputs (@) {
1777     my $inputs = \@_;
1778     my %record;
1779     my %fchecked;
1780
1781     my $showinputs = sub {
1782         return join "; ", map { $_->get_option('name') } @$inputs;
1783     };
1784
1785     foreach my $in (@$inputs) {
1786         my $expected_files;
1787         my $in_name = $in->get_option('name');
1788
1789         printdebug "files_compare_inputs $in_name\n";
1790
1791         foreach my $csumi (@files_csum_info_fields) {
1792             my ($fname) = @$csumi;
1793             printdebug "files_compare_inputs $in_name $fname\n";
1794
1795             my $field = $in->{$fname};
1796             next unless defined $field;
1797
1798             my @files;
1799             foreach (split /\n/, $field) {
1800                 next unless m/\S/;
1801
1802                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1803                     fail "could not parse $in_name $fname line \`$_'";
1804
1805                 printdebug "files_compare_inputs $in_name $fname $f\n";
1806
1807                 push @files, $f;
1808
1809                 my $re = \ $record{$f}{$fname};
1810                 if (defined $$re) {
1811                     $fchecked{$f}{$in_name} = 1;
1812                     $$re eq $info or
1813                         fail "hash or size of $f varies in $fname fields".
1814                         " (between: ".$showinputs->().")";
1815                 } else {
1816                     $$re = $info;
1817                 }
1818             }
1819             @files = sort @files;
1820             $expected_files //= \@files;
1821             "@$expected_files" eq "@files" or
1822                 fail "file list in $in_name varies between hash fields!";
1823         }
1824         $expected_files or
1825             fail "$in_name has no files list field(s)";
1826     }
1827     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1828         if $debuglevel>=2;
1829
1830     grep { keys %$_ == @$inputs-1 } values %fchecked
1831         or fail "no file appears in all file lists".
1832         " (looked in: ".$showinputs->().")";
1833 }
1834
1835 sub is_orig_file_in_dsc ($$) {
1836     my ($f, $dsc_files_info) = @_;
1837     return 0 if @$dsc_files_info <= 1;
1838     # One file means no origs, and the filename doesn't have a "what
1839     # part of dsc" component.  (Consider versions ending `.orig'.)
1840     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1841     return 1;
1842 }
1843
1844 sub is_orig_file_of_vsn ($$) {
1845     my ($f, $upstreamvsn) = @_;
1846     my $base = srcfn $upstreamvsn, '';
1847     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1848     return 1;
1849 }
1850
1851 sub changes_update_origs_from_dsc ($$$$) {
1852     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1853     my %changes_f;
1854     printdebug "checking origs needed ($upstreamvsn)...\n";
1855     $_ = getfield $changes, 'Files';
1856     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1857         fail "cannot find section/priority from .changes Files field";
1858     my $placementinfo = $1;
1859     my %changed;
1860     printdebug "checking origs needed placement '$placementinfo'...\n";
1861     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1862         $l =~ m/\S+$/ or next;
1863         my $file = $&;
1864         printdebug "origs $file | $l\n";
1865         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1866         printdebug "origs $file is_orig\n";
1867         my $have = archive_query('file_in_archive', $file);
1868         if (!defined $have) {
1869             print STDERR <<END;
1870 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1871 END
1872             return;
1873         }
1874         my $found_same = 0;
1875         my @found_differ;
1876         printdebug "origs $file \$#\$have=$#$have\n";
1877         foreach my $h (@$have) {
1878             my $same = 0;
1879             my @differ;
1880             foreach my $csumi (@files_csum_info_fields) {
1881                 my ($fname, $module, $method, $archivefield) = @$csumi;
1882                 next unless defined $h->{$archivefield};
1883                 $_ = $dsc->{$fname};
1884                 next unless defined;
1885                 m/^(\w+) .* \Q$file\E$/m or
1886                     fail ".dsc $fname missing entry for $file";
1887                 if ($h->{$archivefield} eq $1) {
1888                     $same++;
1889                 } else {
1890                     push @differ,
1891  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1892                 }
1893             }
1894             die "$file ".Dumper($h)." ?!" if $same && @differ;
1895             $found_same++
1896                 if $same;
1897             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1898                 if @differ;
1899         }
1900         printdebug "origs $file f.same=$found_same".
1901             " #f._differ=$#found_differ\n";
1902         if (@found_differ && !$found_same) {
1903             fail join "\n",
1904                 "archive contains $file with different checksum",
1905                 @found_differ;
1906         }
1907         # Now we edit the changes file to add or remove it
1908         foreach my $csumi (@files_csum_info_fields) {
1909             my ($fname, $module, $method, $archivefield) = @$csumi;
1910             next unless defined $changes->{$fname};
1911             if ($found_same) {
1912                 # in archive, delete from .changes if it's there
1913                 $changed{$file} = "removed" if
1914                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1915             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1916                 # not in archive, but it's here in the .changes
1917             } else {
1918                 my $dsc_data = getfield $dsc, $fname;
1919                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1920                 my $extra = $1;
1921                 $extra =~ s/ \d+ /$&$placementinfo /
1922                     or die "$fname $extra >$dsc_data< ?"
1923                     if $fname eq 'Files';
1924                 $changes->{$fname} .= "\n". $extra;
1925                 $changed{$file} = "added";
1926             }
1927         }
1928     }
1929     if (%changed) {
1930         foreach my $file (keys %changed) {
1931             progress sprintf
1932                 "edited .changes for archive .orig contents: %s %s",
1933                 $changed{$file}, $file;
1934         }
1935         my $chtmp = "$changesfile.tmp";
1936         $changes->save($chtmp);
1937         if (act_local()) {
1938             rename $chtmp,$changesfile or die "$changesfile $!";
1939         } else {
1940             progress "[new .changes left in $changesfile]";
1941         }
1942     } else {
1943         progress "$changesfile already has appropriate .orig(s) (if any)";
1944     }
1945 }
1946
1947 sub make_commit ($) {
1948     my ($file) = @_;
1949     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1950 }
1951
1952 sub make_commit_text ($) {
1953     my ($text) = @_;
1954     my ($out, $in);
1955     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1956     debugcmd "|",@cmd;
1957     print Dumper($text) if $debuglevel > 1;
1958     my $child = open2($out, $in, @cmd) or die $!;
1959     my $h;
1960     eval {
1961         print $in $text or die $!;
1962         close $in or die $!;
1963         $h = <$out>;
1964         $h =~ m/^\w+$/ or die;
1965         $h = $&;
1966         printdebug "=> $h\n";
1967     };
1968     close $out;
1969     waitpid $child, 0 == $child or die "$child $!";
1970     $? and failedcmd @cmd;
1971     return $h;
1972 }
1973
1974 sub clogp_authline ($) {
1975     my ($clogp) = @_;
1976     my $author = getfield $clogp, 'Maintainer';
1977     if ($author =~ m/^[^"\@]+\,/) {
1978         # single entry Maintainer field with unquoted comma
1979         $author = ($& =~ y/,//rd).$'; # strip the comma
1980     }
1981     # git wants a single author; any remaining commas in $author
1982     # are by now preceded by @ (or ").  It seems safer to punt on
1983     # "..." for now rather than attempting to dequote or something.
1984     $author =~ s#,.*##ms unless $author =~ m/"/;
1985     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1986     my $authline = "$author $date";
1987     $authline =~ m/$git_authline_re/o or
1988         fail "unexpected commit author line format \`$authline'".
1989         " (was generated from changelog Maintainer field)";
1990     return ($1,$2,$3) if wantarray;
1991     return $authline;
1992 }
1993
1994 sub vendor_patches_distro ($$) {
1995     my ($checkdistro, $what) = @_;
1996     return unless defined $checkdistro;
1997
1998     my $series = "debian/patches/\L$checkdistro\E.series";
1999     printdebug "checking for vendor-specific $series ($what)\n";
2000
2001     if (!open SERIES, "<", $series) {
2002         die "$series $!" unless $!==ENOENT;
2003         return;
2004     }
2005     while (<SERIES>) {
2006         next unless m/\S/;
2007         next if m/^\s+\#/;
2008
2009         print STDERR <<END;
2010
2011 Unfortunately, this source package uses a feature of dpkg-source where
2012 the same source package unpacks to different source code on different
2013 distros.  dgit cannot safely operate on such packages on affected
2014 distros, because the meaning of source packages is not stable.
2015
2016 Please ask the distro/maintainer to remove the distro-specific series
2017 files and use a different technique (if necessary, uploading actually
2018 different packages, if different distros are supposed to have
2019 different code).
2020
2021 END
2022         fail "Found active distro-specific series file for".
2023             " $checkdistro ($what): $series, cannot continue";
2024     }
2025     die "$series $!" if SERIES->error;
2026     close SERIES;
2027 }
2028
2029 sub check_for_vendor_patches () {
2030     # This dpkg-source feature doesn't seem to be documented anywhere!
2031     # But it can be found in the changelog (reformatted):
2032
2033     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2034     #   Author: Raphael Hertzog <hertzog@debian.org>
2035     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2036
2037     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2038     #   series files
2039     #   
2040     #   If you have debian/patches/ubuntu.series and you were
2041     #   unpacking the source package on ubuntu, quilt was still
2042     #   directed to debian/patches/series instead of
2043     #   debian/patches/ubuntu.series.
2044     #   
2045     #   debian/changelog                        |    3 +++
2046     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2047     #   2 files changed, 6 insertions(+), 1 deletion(-)
2048
2049     use Dpkg::Vendor;
2050     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2051     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2052                          "Dpkg::Vendor \`current vendor'");
2053     vendor_patches_distro(access_basedistro(),
2054                           "(base) distro being accessed");
2055     vendor_patches_distro(access_nomdistro(),
2056                           "(nominal) distro being accessed");
2057 }
2058
2059 sub generate_commits_from_dsc () {
2060     # See big comment in fetch_from_archive, below.
2061     # See also README.dsc-import.
2062     prep_ud();
2063     changedir $playground;
2064
2065     my @dfi = dsc_files_info();
2066     foreach my $fi (@dfi) {
2067         my $f = $fi->{Filename};
2068         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2069         my $upper_f = "$maindir/../$f";
2070
2071         printdebug "considering reusing $f: ";
2072
2073         if (link_ltarget "$upper_f,fetch", $f) {
2074             printdebug "linked (using ...,fetch).\n";
2075         } elsif ((printdebug "($!) "),
2076                  $! != ENOENT) {
2077             fail "accessing ../$f,fetch: $!";
2078         } elsif (link_ltarget $upper_f, $f) {
2079             printdebug "linked.\n";
2080         } elsif ((printdebug "($!) "),
2081                  $! != ENOENT) {
2082             fail "accessing ../$f: $!";
2083         } else {
2084             printdebug "absent.\n";
2085         }
2086
2087         my $refetched;
2088         complete_file_from_dsc('.', $fi, \$refetched)
2089             or next;
2090
2091         printdebug "considering saving $f: ";
2092
2093         if (link $f, $upper_f) {
2094             printdebug "linked.\n";
2095         } elsif ((printdebug "($!) "),
2096                  $! != EEXIST) {
2097             fail "saving ../$f: $!";
2098         } elsif (!$refetched) {
2099             printdebug "no need.\n";
2100         } elsif (link $f, "$upper_f,fetch") {
2101             printdebug "linked (using ...,fetch).\n";
2102         } elsif ((printdebug "($!) "),
2103                  $! != EEXIST) {
2104             fail "saving ../$f,fetch: $!";
2105         } else {
2106             printdebug "cannot.\n";
2107         }
2108     }
2109
2110     # We unpack and record the orig tarballs first, so that we only
2111     # need disk space for one private copy of the unpacked source.
2112     # But we can't make them into commits until we have the metadata
2113     # from the debian/changelog, so we record the tree objects now and
2114     # make them into commits later.
2115     my @tartrees;
2116     my $upstreamv = upstreamversion $dsc->{version};
2117     my $orig_f_base = srcfn $upstreamv, '';
2118
2119     foreach my $fi (@dfi) {
2120         # We actually import, and record as a commit, every tarball
2121         # (unless there is only one file, in which case there seems
2122         # little point.
2123
2124         my $f = $fi->{Filename};
2125         printdebug "import considering $f ";
2126         (printdebug "only one dfi\n"), next if @dfi == 1;
2127         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2128         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2129         my $compr_ext = $1;
2130
2131         my ($orig_f_part) =
2132             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2133
2134         printdebug "Y ", (join ' ', map { $_//"(none)" }
2135                           $compr_ext, $orig_f_part
2136                          ), "\n";
2137
2138         my $input = new IO::File $f, '<' or die "$f $!";
2139         my $compr_pid;
2140         my @compr_cmd;
2141
2142         if (defined $compr_ext) {
2143             my $cname =
2144                 Dpkg::Compression::compression_guess_from_filename $f;
2145             fail "Dpkg::Compression cannot handle file $f in source package"
2146                 if defined $compr_ext && !defined $cname;
2147             my $compr_proc =
2148                 new Dpkg::Compression::Process compression => $cname;
2149             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2150             my $compr_fh = new IO::Handle;
2151             my $compr_pid = open $compr_fh, "-|" // die $!;
2152             if (!$compr_pid) {
2153                 open STDIN, "<&", $input or die $!;
2154                 exec @compr_cmd;
2155                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2156             }
2157             $input = $compr_fh;
2158         }
2159
2160         rmtree "_unpack-tar";
2161         mkdir "_unpack-tar" or die $!;
2162         my @tarcmd = qw(tar -x -f -
2163                         --no-same-owner --no-same-permissions
2164                         --no-acls --no-xattrs --no-selinux);
2165         my $tar_pid = fork // die $!;
2166         if (!$tar_pid) {
2167             chdir "_unpack-tar" or die $!;
2168             open STDIN, "<&", $input or die $!;
2169             exec @tarcmd;
2170             die "dgit (child): exec $tarcmd[0]: $!";
2171         }
2172         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2173         !$? or failedcmd @tarcmd;
2174
2175         close $input or
2176             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2177              : die $!);
2178         # finally, we have the results in "tarball", but maybe
2179         # with the wrong permissions
2180
2181         runcmd qw(chmod -R +rwX _unpack-tar);
2182         changedir "_unpack-tar";
2183         remove_stray_gits($f);
2184         mktree_in_ud_here();
2185         
2186         my ($tree) = git_add_write_tree();
2187         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2188         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2189             $tree = $1;
2190             printdebug "one subtree $1\n";
2191         } else {
2192             printdebug "multiple subtrees\n";
2193         }
2194         changedir "..";
2195         rmtree "_unpack-tar";
2196
2197         my $ent = [ $f, $tree ];
2198         push @tartrees, {
2199             Orig => !!$orig_f_part,
2200             Sort => (!$orig_f_part         ? 2 :
2201                      $orig_f_part =~ m/-/g ? 1 :
2202                                              0),
2203             F => $f,
2204             Tree => $tree,
2205         };
2206     }
2207
2208     @tartrees = sort {
2209         # put any without "_" first (spec is not clear whether files
2210         # are always in the usual order).  Tarballs without "_" are
2211         # the main orig or the debian tarball.
2212         $a->{Sort} <=> $b->{Sort} or
2213         $a->{F}    cmp $b->{F}
2214     } @tartrees;
2215
2216     my $any_orig = grep { $_->{Orig} } @tartrees;
2217
2218     my $dscfn = "$package.dsc";
2219
2220     my $treeimporthow = 'package';
2221
2222     open D, ">", $dscfn or die "$dscfn: $!";
2223     print D $dscdata or die "$dscfn: $!";
2224     close D or die "$dscfn: $!";
2225     my @cmd = qw(dpkg-source);
2226     push @cmd, '--no-check' if $dsc_checked;
2227     if (madformat $dsc->{format}) {
2228         push @cmd, '--skip-patches';
2229         $treeimporthow = 'unpatched';
2230     }
2231     push @cmd, qw(-x --), $dscfn;
2232     runcmd @cmd;
2233
2234     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2235     if (madformat $dsc->{format}) { 
2236         check_for_vendor_patches();
2237     }
2238
2239     my $dappliedtree;
2240     if (madformat $dsc->{format}) {
2241         my @pcmd = qw(dpkg-source --before-build .);
2242         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2243         rmtree '.pc';
2244         $dappliedtree = git_add_write_tree();
2245     }
2246
2247     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2248     debugcmd "|",@clogcmd;
2249     open CLOGS, "-|", @clogcmd or die $!;
2250
2251     my $clogp;
2252     my $r1clogp;
2253
2254     printdebug "import clog search...\n";
2255
2256     for (;;) {
2257         my $stanzatext = do { local $/=""; <CLOGS>; };
2258         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2259         last if !defined $stanzatext;
2260
2261         my $desc = "package changelog, entry no.$.";
2262         open my $stanzafh, "<", \$stanzatext or die;
2263         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2264         $clogp //= $thisstanza;
2265
2266         printdebug "import clog $thisstanza->{version} $desc...\n";
2267
2268         last if !$any_orig; # we don't need $r1clogp
2269
2270         # We look for the first (most recent) changelog entry whose
2271         # version number is lower than the upstream version of this
2272         # package.  Then the last (least recent) previous changelog
2273         # entry is treated as the one which introduced this upstream
2274         # version and used for the synthetic commits for the upstream
2275         # tarballs.
2276
2277         # One might think that a more sophisticated algorithm would be
2278         # necessary.  But: we do not want to scan the whole changelog
2279         # file.  Stopping when we see an earlier version, which
2280         # necessarily then is an earlier upstream version, is the only
2281         # realistic way to do that.  Then, either the earliest
2282         # changelog entry we have seen so far is indeed the earliest
2283         # upload of this upstream version; or there are only changelog
2284         # entries relating to later upstream versions (which is not
2285         # possible unless the changelog and .dsc disagree about the
2286         # version).  Then it remains to choose between the physically
2287         # last entry in the file, and the one with the lowest version
2288         # number.  If these are not the same, we guess that the
2289         # versions were created in a non-monotic order rather than
2290         # that the changelog entries have been misordered.
2291
2292         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2293
2294         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2295         $r1clogp = $thisstanza;
2296
2297         printdebug "import clog $r1clogp->{version} becomes r1\n";
2298     }
2299     die $! if CLOGS->error;
2300     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2301
2302     $clogp or fail "package changelog has no entries!";
2303
2304     my $authline = clogp_authline $clogp;
2305     my $changes = getfield $clogp, 'Changes';
2306     $changes =~ s/^\n//; # Changes: \n
2307     my $cversion = getfield $clogp, 'Version';
2308
2309     if (@tartrees) {
2310         $r1clogp //= $clogp; # maybe there's only one entry;
2311         my $r1authline = clogp_authline $r1clogp;
2312         # Strictly, r1authline might now be wrong if it's going to be
2313         # unused because !$any_orig.  Whatever.
2314
2315         printdebug "import tartrees authline   $authline\n";
2316         printdebug "import tartrees r1authline $r1authline\n";
2317
2318         foreach my $tt (@tartrees) {
2319             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2320
2321             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2322 tree $tt->{Tree}
2323 author $r1authline
2324 committer $r1authline
2325
2326 Import $tt->{F}
2327
2328 [dgit import orig $tt->{F}]
2329 END_O
2330 tree $tt->{Tree}
2331 author $authline
2332 committer $authline
2333
2334 Import $tt->{F}
2335
2336 [dgit import tarball $package $cversion $tt->{F}]
2337 END_T
2338         }
2339     }
2340
2341     printdebug "import main commit\n";
2342
2343     open C, ">../commit.tmp" or die $!;
2344     print C <<END or die $!;
2345 tree $tree
2346 END
2347     print C <<END or die $! foreach @tartrees;
2348 parent $_->{Commit}
2349 END
2350     print C <<END or die $!;
2351 author $authline
2352 committer $authline
2353
2354 $changes
2355
2356 [dgit import $treeimporthow $package $cversion]
2357 END
2358
2359     close C or die $!;
2360     my $rawimport_hash = make_commit qw(../commit.tmp);
2361
2362     if (madformat $dsc->{format}) {
2363         printdebug "import apply patches...\n";
2364
2365         # regularise the state of the working tree so that
2366         # the checkout of $rawimport_hash works nicely.
2367         my $dappliedcommit = make_commit_text(<<END);
2368 tree $dappliedtree
2369 author $authline
2370 committer $authline
2371
2372 [dgit dummy commit]
2373 END
2374         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2375
2376         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2377
2378         # We need the answers to be reproducible
2379         my @authline = clogp_authline($clogp);
2380         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2381         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2382         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2383         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2384         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2385         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2386
2387         my $path = $ENV{PATH} or die;
2388
2389         # we use ../../gbp-pq-output, which (given that we are in
2390         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2391         # is .git/dgit.
2392
2393         foreach my $use_absurd (qw(0 1)) {
2394             runcmd @git, qw(checkout -q unpa);
2395             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2396             local $ENV{PATH} = $path;
2397             if ($use_absurd) {
2398                 chomp $@;
2399                 progress "warning: $@";
2400                 $path = "$absurdity:$path";
2401                 progress "$us: trying slow absurd-git-apply...";
2402                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2403                     or $!==ENOENT
2404                     or die $!;
2405             }
2406             eval {
2407                 die "forbid absurd git-apply\n" if $use_absurd
2408                     && forceing [qw(import-gitapply-no-absurd)];
2409                 die "only absurd git-apply!\n" if !$use_absurd
2410                     && forceing [qw(import-gitapply-absurd)];
2411
2412                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2413                 local $ENV{PATH} = $path                    if $use_absurd;
2414
2415                 my @showcmd = (gbp_pq, qw(import));
2416                 my @realcmd = shell_cmd
2417                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2418                 debugcmd "+",@realcmd;
2419                 if (system @realcmd) {
2420                     die +(shellquote @showcmd).
2421                         " failed: ".
2422                         failedcmd_waitstatus()."\n";
2423                 }
2424
2425                 my $gapplied = git_rev_parse('HEAD');
2426                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2427                 $gappliedtree eq $dappliedtree or
2428                     fail <<END;
2429 gbp-pq import and dpkg-source disagree!
2430  gbp-pq import gave commit $gapplied
2431  gbp-pq import gave tree $gappliedtree
2432  dpkg-source --before-build gave tree $dappliedtree
2433 END
2434                 $rawimport_hash = $gapplied;
2435             };
2436             last unless $@;
2437         }
2438         if ($@) {
2439             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2440             die $@;
2441         }
2442     }
2443
2444     progress "synthesised git commit from .dsc $cversion";
2445
2446     my $rawimport_mergeinput = {
2447         Commit => $rawimport_hash,
2448         Info => "Import of source package",
2449     };
2450     my @output = ($rawimport_mergeinput);
2451
2452     if ($lastpush_mergeinput) {
2453         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2454         my $oversion = getfield $oldclogp, 'Version';
2455         my $vcmp =
2456             version_compare($oversion, $cversion);
2457         if ($vcmp < 0) {
2458             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2459                 { Message => <<END, ReverseParents => 1 });
2460 Record $package ($cversion) in archive suite $csuite
2461 END
2462         } elsif ($vcmp > 0) {
2463             print STDERR <<END or die $!;
2464
2465 Version actually in archive:   $cversion (older)
2466 Last version pushed with dgit: $oversion (newer or same)
2467 $later_warning_msg
2468 END
2469             @output = $lastpush_mergeinput;
2470         } else {
2471             # Same version.  Use what's in the server git branch,
2472             # discarding our own import.  (This could happen if the
2473             # server automatically imports all packages into git.)
2474             @output = $lastpush_mergeinput;
2475         }
2476     }
2477     changedir $maindir;
2478     rmtree $playground;
2479     return @output;
2480 }
2481
2482 sub complete_file_from_dsc ($$;$) {
2483     our ($dstdir, $fi, $refetched) = @_;
2484     # Ensures that we have, in $dstdir, the file $fi, with the correct
2485     # contents.  (Downloading it from alongside $dscurl if necessary.)
2486     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2487     # and will set $$refetched=1 if it did so (or tried to).
2488
2489     my $f = $fi->{Filename};
2490     my $tf = "$dstdir/$f";
2491     my $downloaded = 0;
2492
2493     my $got;
2494     my $checkhash = sub {
2495         open F, "<", "$tf" or die "$tf: $!";
2496         $fi->{Digester}->reset();
2497         $fi->{Digester}->addfile(*F);
2498         F->error and die $!;
2499         $got = $fi->{Digester}->hexdigest();
2500         return $got eq $fi->{Hash};
2501     };
2502
2503     if (stat_exists $tf) {
2504         if ($checkhash->()) {
2505             progress "using existing $f";
2506             return 1;
2507         }
2508         if (!$refetched) {
2509             fail "file $f has hash $got but .dsc".
2510                 " demands hash $fi->{Hash} ".
2511                 "(perhaps you should delete this file?)";
2512         }
2513         progress "need to fetch correct version of $f";
2514         unlink $tf or die "$tf $!";
2515         $$refetched = 1;
2516     } else {
2517         printdebug "$tf does not exist, need to fetch\n";
2518     }
2519
2520     my $furl = $dscurl;
2521     $furl =~ s{/[^/]+$}{};
2522     $furl .= "/$f";
2523     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2524     die "$f ?" if $f =~ m#/#;
2525     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2526     return 0 if !act_local();
2527
2528     $checkhash->() or
2529         fail "file $f has hash $got but .dsc".
2530             " demands hash $fi->{Hash} ".
2531             "(got wrong file from archive!)";
2532
2533     return 1;
2534 }
2535
2536 sub ensure_we_have_orig () {
2537     my @dfi = dsc_files_info();
2538     foreach my $fi (@dfi) {
2539         my $f = $fi->{Filename};
2540         next unless is_orig_file_in_dsc($f, \@dfi);
2541         complete_file_from_dsc('..', $fi)
2542             or next;
2543     }
2544 }
2545
2546 #---------- git fetch ----------
2547
2548 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2549 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2550
2551 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2552 # locally fetched refs because they have unhelpful names and clutter
2553 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2554 # whether we have made another local ref which refers to this object).
2555 #
2556 # (If we deleted them unconditionally, then we might end up
2557 # re-fetching the same git objects each time dgit fetch was run.)
2558 #
2559 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2560 # in git_fetch_us to fetch the refs in question, and possibly a call
2561 # to lrfetchref_used.
2562
2563 our (%lrfetchrefs_f, %lrfetchrefs_d);
2564 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2565
2566 sub lrfetchref_used ($) {
2567     my ($fullrefname) = @_;
2568     my $objid = $lrfetchrefs_f{$fullrefname};
2569     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2570 }
2571
2572 sub git_lrfetch_sane {
2573     my ($url, $supplementary, @specs) = @_;
2574     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2575     # at least as regards @specs.  Also leave the results in
2576     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2577     # able to clean these up.
2578     #
2579     # With $supplementary==1, @specs must not contain wildcards
2580     # and we add to our previous fetches (non-atomically).
2581
2582     # This is rather miserable:
2583     # When git fetch --prune is passed a fetchspec ending with a *,
2584     # it does a plausible thing.  If there is no * then:
2585     # - it matches subpaths too, even if the supplied refspec
2586     #   starts refs, and behaves completely madly if the source
2587     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2588     # - if there is no matching remote ref, it bombs out the whole
2589     #   fetch.
2590     # We want to fetch a fixed ref, and we don't know in advance
2591     # if it exists, so this is not suitable.
2592     #
2593     # Our workaround is to use git ls-remote.  git ls-remote has its
2594     # own qairks.  Notably, it has the absurd multi-tail-matching
2595     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2596     # refs/refs/foo etc.
2597     #
2598     # Also, we want an idempotent snapshot, but we have to make two
2599     # calls to the remote: one to git ls-remote and to git fetch.  The
2600     # solution is use git ls-remote to obtain a target state, and
2601     # git fetch to try to generate it.  If we don't manage to generate
2602     # the target state, we try again.
2603
2604     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2605
2606     my $specre = join '|', map {
2607         my $x = $_;
2608         $x =~ s/\W/\\$&/g;
2609         my $wildcard = $x =~ s/\\\*$/.*/;
2610         die if $wildcard && $supplementary;
2611         "(?:refs/$x)";
2612     } @specs;
2613     printdebug "git_lrfetch_sane specre=$specre\n";
2614     my $wanted_rref = sub {
2615         local ($_) = @_;
2616         return m/^(?:$specre)$/;
2617     };
2618
2619     my $fetch_iteration = 0;
2620     FETCH_ITERATION:
2621     for (;;) {
2622         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2623         if (++$fetch_iteration > 10) {
2624             fail "too many iterations trying to get sane fetch!";
2625         }
2626
2627         my @look = map { "refs/$_" } @specs;
2628         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2629         debugcmd "|",@lcmd;
2630
2631         my %wantr;
2632         open GITLS, "-|", @lcmd or die $!;
2633         while (<GITLS>) {
2634             printdebug "=> ", $_;
2635             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2636             my ($objid,$rrefname) = ($1,$2);
2637             if (!$wanted_rref->($rrefname)) {
2638                 print STDERR <<END;
2639 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2640 END
2641                 next;
2642             }
2643             $wantr{$rrefname} = $objid;
2644         }
2645         $!=0; $?=0;
2646         close GITLS or failedcmd @lcmd;
2647
2648         # OK, now %want is exactly what we want for refs in @specs
2649         my @fspecs = map {
2650             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2651             "+refs/$_:".lrfetchrefs."/$_";
2652         } @specs;
2653
2654         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2655
2656         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2657         runcmd_ordryrun_local @fcmd if @fspecs;
2658
2659         if (!$supplementary) {
2660             %lrfetchrefs_f = ();
2661         }
2662         my %objgot;
2663
2664         git_for_each_ref(lrfetchrefs, sub {
2665             my ($objid,$objtype,$lrefname,$reftail) = @_;
2666             $lrfetchrefs_f{$lrefname} = $objid;
2667             $objgot{$objid} = 1;
2668         });
2669
2670         if ($supplementary) {
2671             last;
2672         }
2673
2674         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2675             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2676             if (!exists $wantr{$rrefname}) {
2677                 if ($wanted_rref->($rrefname)) {
2678                     printdebug <<END;
2679 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2680 END
2681                 } else {
2682                     print STDERR <<END
2683 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2684 END
2685                 }
2686                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2687                 delete $lrfetchrefs_f{$lrefname};
2688                 next;
2689             }
2690         }
2691         foreach my $rrefname (sort keys %wantr) {
2692             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2693             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2694             my $want = $wantr{$rrefname};
2695             next if $got eq $want;
2696             if (!defined $objgot{$want}) {
2697                 print STDERR <<END;
2698 warning: git ls-remote suggests we want $lrefname
2699 warning:  and it should refer to $want
2700 warning:  but git fetch didn't fetch that object to any relevant ref.
2701 warning:  This may be due to a race with someone updating the server.
2702 warning:  Will try again...
2703 END
2704                 next FETCH_ITERATION;
2705             }
2706             printdebug <<END;
2707 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2708 END
2709             runcmd_ordryrun_local @git, qw(update-ref -m),
2710                 "dgit fetch git fetch fixup", $lrefname, $want;
2711             $lrfetchrefs_f{$lrefname} = $want;
2712         }
2713         last;
2714     }
2715
2716     if (defined $csuite) {
2717         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2718         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2719             my ($objid,$objtype,$lrefname,$reftail) = @_;
2720             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2721             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2722         });
2723     }
2724
2725     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2726         Dumper(\%lrfetchrefs_f);
2727 }
2728
2729 sub git_fetch_us () {
2730     # Want to fetch only what we are going to use, unless
2731     # deliberately-not-ff, in which case we must fetch everything.
2732
2733     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2734         map { "tags/$_" }
2735         (quiltmode_splitbrain
2736          ? (map { $_->('*',access_nomdistro) }
2737             \&debiantag_new, \&debiantag_maintview)
2738          : debiantags('*',access_nomdistro));
2739     push @specs, server_branch($csuite);
2740     push @specs, $rewritemap;
2741     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2742
2743     my $url = access_giturl();
2744     git_lrfetch_sane $url, 0, @specs;
2745
2746     my %here;
2747     my @tagpats = debiantags('*',access_nomdistro);
2748
2749     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2750         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2751         printdebug "currently $fullrefname=$objid\n";
2752         $here{$fullrefname} = $objid;
2753     });
2754     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2755         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2756         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2757         printdebug "offered $lref=$objid\n";
2758         if (!defined $here{$lref}) {
2759             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2760             runcmd_ordryrun_local @upd;
2761             lrfetchref_used $fullrefname;
2762         } elsif ($here{$lref} eq $objid) {
2763             lrfetchref_used $fullrefname;
2764         } else {
2765             print STDERR
2766                 "Not updating $lref from $here{$lref} to $objid.\n";
2767         }
2768     });
2769 }
2770
2771 #---------- dsc and archive handling ----------
2772
2773 sub mergeinfo_getclogp ($) {
2774     # Ensures thit $mi->{Clogp} exists and returns it
2775     my ($mi) = @_;
2776     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2777 }
2778
2779 sub mergeinfo_version ($) {
2780     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2781 }
2782
2783 sub fetch_from_archive_record_1 ($) {
2784     my ($hash) = @_;
2785     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2786             'DGIT_ARCHIVE', $hash;
2787     cmdoutput @git, qw(log -n2), $hash;
2788     # ... gives git a chance to complain if our commit is malformed
2789 }
2790
2791 sub fetch_from_archive_record_2 ($) {
2792     my ($hash) = @_;
2793     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2794     if (act_local()) {
2795         cmdoutput @upd_cmd;
2796     } else {
2797         dryrun_report @upd_cmd;
2798     }
2799 }
2800
2801 sub parse_dsc_field_def_dsc_distro () {
2802     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2803                            dgit.default.distro);
2804 }
2805
2806 sub parse_dsc_field ($$) {
2807     my ($dsc, $what) = @_;
2808     my $f;
2809     foreach my $field (@ourdscfield) {
2810         $f = $dsc->{$field};
2811         last if defined $f;
2812     }
2813
2814     if (!defined $f) {
2815         progress "$what: NO git hash";
2816         parse_dsc_field_def_dsc_distro();
2817     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2818              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2819         progress "$what: specified git info ($dsc_distro)";
2820         $dsc_hint_tag = [ $dsc_hint_tag ];
2821     } elsif ($f =~ m/^\w+\s*$/) {
2822         $dsc_hash = $&;
2823         parse_dsc_field_def_dsc_distro();
2824         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2825                           $dsc_distro ];
2826         progress "$what: specified git hash";
2827     } else {
2828         fail "$what: invalid Dgit info";
2829     }
2830 }
2831
2832 sub resolve_dsc_field_commit ($$) {
2833     my ($already_distro, $already_mapref) = @_;
2834
2835     return unless defined $dsc_hash;
2836
2837     my $mapref =
2838         defined $already_mapref &&
2839         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2840         ? $already_mapref : undef;
2841
2842     my $do_fetch;
2843     $do_fetch = sub {
2844         my ($what, @fetch) = @_;
2845
2846         local $idistro = $dsc_distro;
2847         my $lrf = lrfetchrefs;
2848
2849         if (!$chase_dsc_distro) {
2850             progress
2851                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2852             return 0;
2853         }
2854
2855         progress
2856             ".dsc names distro $dsc_distro: fetching $what";
2857
2858         my $url = access_giturl();
2859         if (!defined $url) {
2860             defined $dsc_hint_url or fail <<END;
2861 .dsc Dgit metadata is in context of distro $dsc_distro
2862 for which we have no configured url and .dsc provides no hint
2863 END
2864             my $proto =
2865                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2866                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2867             parse_cfg_bool "dsc-url-proto-ok", 'false',
2868                 cfg("dgit.dsc-url-proto-ok.$proto",
2869                     "dgit.default.dsc-url-proto-ok")
2870                 or fail <<END;
2871 .dsc Dgit metadata is in context of distro $dsc_distro
2872 for which we have no configured url;
2873 .dsc provides hinted url with protocol $proto which is unsafe.
2874 (can be overridden by config - consult documentation)
2875 END
2876             $url = $dsc_hint_url;
2877         }
2878
2879         git_lrfetch_sane $url, 1, @fetch;
2880
2881         return $lrf;
2882     };
2883
2884     my $rewrite_enable = do {
2885         local $idistro = $dsc_distro;
2886         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2887     };
2888
2889     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2890         if (!defined $mapref) {
2891             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2892             $mapref = $lrf.'/'.$rewritemap;
2893         }
2894         my $rewritemapdata = git_cat_file $mapref.':map';
2895         if (defined $rewritemapdata
2896             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2897             progress
2898                 "server's git history rewrite map contains a relevant entry!";
2899
2900             $dsc_hash = $1;
2901             if (defined $dsc_hash) {
2902                 progress "using rewritten git hash in place of .dsc value";
2903             } else {
2904                 progress "server data says .dsc hash is to be disregarded";
2905             }
2906         }
2907     }
2908
2909     if (!defined git_cat_file $dsc_hash) {
2910         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2911         my $lrf = $do_fetch->("additional commits", @tags) &&
2912             defined git_cat_file $dsc_hash
2913             or fail <<END;
2914 .dsc Dgit metadata requires commit $dsc_hash
2915 but we could not obtain that object anywhere.
2916 END
2917         foreach my $t (@tags) {
2918             my $fullrefname = $lrf.'/'.$t;
2919 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2920             next unless $lrfetchrefs_f{$fullrefname};
2921             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2922             lrfetchref_used $fullrefname;
2923         }
2924     }
2925 }
2926
2927 sub fetch_from_archive () {
2928     ensure_setup_existing_tree();
2929
2930     # Ensures that lrref() is what is actually in the archive, one way
2931     # or another, according to us - ie this client's
2932     # appropritaely-updated archive view.  Also returns the commit id.
2933     # If there is nothing in the archive, leaves lrref alone and
2934     # returns undef.  git_fetch_us must have already been called.
2935     get_archive_dsc();
2936
2937     if ($dsc) {
2938         parse_dsc_field($dsc, 'last upload to archive');
2939         resolve_dsc_field_commit access_basedistro,
2940             lrfetchrefs."/".$rewritemap
2941     } else {
2942         progress "no version available from the archive";
2943     }
2944
2945     # If the archive's .dsc has a Dgit field, there are three
2946     # relevant git commitids we need to choose between and/or merge
2947     # together:
2948     #   1. $dsc_hash: the Dgit field from the archive
2949     #   2. $lastpush_hash: the suite branch on the dgit git server
2950     #   3. $lastfetch_hash: our local tracking brach for the suite
2951     #
2952     # These may all be distinct and need not be in any fast forward
2953     # relationship:
2954     #
2955     # If the dsc was pushed to this suite, then the server suite
2956     # branch will have been updated; but it might have been pushed to
2957     # a different suite and copied by the archive.  Conversely a more
2958     # recent version may have been pushed with dgit but not appeared
2959     # in the archive (yet).
2960     #
2961     # $lastfetch_hash may be awkward because archive imports
2962     # (particularly, imports of Dgit-less .dscs) are performed only as
2963     # needed on individual clients, so different clients may perform a
2964     # different subset of them - and these imports are only made
2965     # public during push.  So $lastfetch_hash may represent a set of
2966     # imports different to a subsequent upload by a different dgit
2967     # client.
2968     #
2969     # Our approach is as follows:
2970     #
2971     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2972     # descendant of $dsc_hash, then it was pushed by a dgit user who
2973     # had based their work on $dsc_hash, so we should prefer it.
2974     # Otherwise, $dsc_hash was installed into this suite in the
2975     # archive other than by a dgit push, and (necessarily) after the
2976     # last dgit push into that suite (since a dgit push would have
2977     # been descended from the dgit server git branch); thus, in that
2978     # case, we prefer the archive's version (and produce a
2979     # pseudo-merge to overwrite the dgit server git branch).
2980     #
2981     # (If there is no Dgit field in the archive's .dsc then
2982     # generate_commit_from_dsc uses the version numbers to decide
2983     # whether the suite branch or the archive is newer.  If the suite
2984     # branch is newer it ignores the archive's .dsc; otherwise it
2985     # generates an import of the .dsc, and produces a pseudo-merge to
2986     # overwrite the suite branch with the archive contents.)
2987     #
2988     # The outcome of that part of the algorithm is the `public view',
2989     # and is same for all dgit clients: it does not depend on any
2990     # unpublished history in the local tracking branch.
2991     #
2992     # As between the public view and the local tracking branch: The
2993     # local tracking branch is only updated by dgit fetch, and
2994     # whenever dgit fetch runs it includes the public view in the
2995     # local tracking branch.  Therefore if the public view is not
2996     # descended from the local tracking branch, the local tracking
2997     # branch must contain history which was imported from the archive
2998     # but never pushed; and, its tip is now out of date.  So, we make
2999     # a pseudo-merge to overwrite the old imports and stitch the old
3000     # history in.
3001     #
3002     # Finally: we do not necessarily reify the public view (as
3003     # described above).  This is so that we do not end up stacking two
3004     # pseudo-merges.  So what we actually do is figure out the inputs
3005     # to any public view pseudo-merge and put them in @mergeinputs.
3006
3007     my @mergeinputs;
3008     # $mergeinputs[]{Commit}
3009     # $mergeinputs[]{Info}
3010     # $mergeinputs[0] is the one whose tree we use
3011     # @mergeinputs is in the order we use in the actual commit)
3012     #
3013     # Also:
3014     # $mergeinputs[]{Message} is a commit message to use
3015     # $mergeinputs[]{ReverseParents} if def specifies that parent
3016     #                                list should be in opposite order
3017     # Such an entry has no Commit or Info.  It applies only when found
3018     # in the last entry.  (This ugliness is to support making
3019     # identical imports to previous dgit versions.)
3020
3021     my $lastpush_hash = git_get_ref(lrfetchref());
3022     printdebug "previous reference hash=$lastpush_hash\n";
3023     $lastpush_mergeinput = $lastpush_hash && {
3024         Commit => $lastpush_hash,
3025         Info => "dgit suite branch on dgit git server",
3026     };
3027
3028     my $lastfetch_hash = git_get_ref(lrref());
3029     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3030     my $lastfetch_mergeinput = $lastfetch_hash && {
3031         Commit => $lastfetch_hash,
3032         Info => "dgit client's archive history view",
3033     };
3034
3035     my $dsc_mergeinput = $dsc_hash && {
3036         Commit => $dsc_hash,
3037         Info => "Dgit field in .dsc from archive",
3038     };
3039
3040     my $cwd = getcwd();
3041     my $del_lrfetchrefs = sub {
3042         changedir $cwd;
3043         my $gur;
3044         printdebug "del_lrfetchrefs...\n";
3045         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3046             my $objid = $lrfetchrefs_d{$fullrefname};
3047             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3048             if (!$gur) {
3049                 $gur ||= new IO::Handle;
3050                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3051             }
3052             printf $gur "delete %s %s\n", $fullrefname, $objid;
3053         }
3054         if ($gur) {
3055             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3056         }
3057     };
3058
3059     if (defined $dsc_hash) {
3060         ensure_we_have_orig();
3061         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3062             @mergeinputs = $dsc_mergeinput
3063         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3064             print STDERR <<END or die $!;
3065
3066 Git commit in archive is behind the last version allegedly pushed/uploaded.
3067 Commit referred to by archive: $dsc_hash
3068 Last version pushed with dgit: $lastpush_hash
3069 $later_warning_msg
3070 END
3071             @mergeinputs = ($lastpush_mergeinput);
3072         } else {
3073             # Archive has .dsc which is not a descendant of the last dgit
3074             # push.  This can happen if the archive moves .dscs about.
3075             # Just follow its lead.
3076             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3077                 progress "archive .dsc names newer git commit";
3078                 @mergeinputs = ($dsc_mergeinput);
3079             } else {
3080                 progress "archive .dsc names other git commit, fixing up";
3081                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3082             }
3083         }
3084     } elsif ($dsc) {
3085         @mergeinputs = generate_commits_from_dsc();
3086         # We have just done an import.  Now, our import algorithm might
3087         # have been improved.  But even so we do not want to generate
3088         # a new different import of the same package.  So if the
3089         # version numbers are the same, just use our existing version.
3090         # If the version numbers are different, the archive has changed
3091         # (perhaps, rewound).
3092         if ($lastfetch_mergeinput &&
3093             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3094                               (mergeinfo_version $mergeinputs[0]) )) {
3095             @mergeinputs = ($lastfetch_mergeinput);
3096         }
3097     } elsif ($lastpush_hash) {
3098         # only in git, not in the archive yet
3099         @mergeinputs = ($lastpush_mergeinput);
3100         print STDERR <<END or die $!;
3101
3102 Package not found in the archive, but has allegedly been pushed using dgit.
3103 $later_warning_msg
3104 END
3105     } else {
3106         printdebug "nothing found!\n";
3107         if (defined $skew_warning_vsn) {
3108             print STDERR <<END or die $!;
3109
3110 Warning: relevant archive skew detected.
3111 Archive allegedly contains $skew_warning_vsn
3112 But we were not able to obtain any version from the archive or git.
3113
3114 END
3115         }
3116         unshift @end, $del_lrfetchrefs;
3117         return undef;
3118     }
3119
3120     if ($lastfetch_hash &&
3121         !grep {
3122             my $h = $_->{Commit};
3123             $h and is_fast_fwd($lastfetch_hash, $h);
3124             # If true, one of the existing parents of this commit
3125             # is a descendant of the $lastfetch_hash, so we'll
3126             # be ff from that automatically.
3127         } @mergeinputs
3128         ) {
3129         # Otherwise:
3130         push @mergeinputs, $lastfetch_mergeinput;
3131     }
3132
3133     printdebug "fetch mergeinfos:\n";
3134     foreach my $mi (@mergeinputs) {
3135         if ($mi->{Info}) {
3136             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3137         } else {
3138             printdebug sprintf " ReverseParents=%d Message=%s",
3139                 $mi->{ReverseParents}, $mi->{Message};
3140         }
3141     }
3142
3143     my $compat_info= pop @mergeinputs
3144         if $mergeinputs[$#mergeinputs]{Message};
3145
3146     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3147
3148     my $hash;
3149     if (@mergeinputs > 1) {
3150         # here we go, then:
3151         my $tree_commit = $mergeinputs[0]{Commit};
3152
3153         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3154         $tree =~ m/\n\n/;  $tree = $`;
3155         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3156         $tree = $1;
3157
3158         # We use the changelog author of the package in question the
3159         # author of this pseudo-merge.  This is (roughly) correct if
3160         # this commit is simply representing aa non-dgit upload.
3161         # (Roughly because it does not record sponsorship - but we
3162         # don't have sponsorship info because that's in the .changes,
3163         # which isn't in the archivw.)
3164         #
3165         # But, it might be that we are representing archive history
3166         # updates (including in-archive copies).  These are not really
3167         # the responsibility of the person who created the .dsc, but
3168         # there is no-one whose name we should better use.  (The
3169         # author of the .dsc-named commit is clearly worse.)
3170
3171         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3172         my $author = clogp_authline $useclogp;
3173         my $cversion = getfield $useclogp, 'Version';
3174
3175         my $mcf = dgit_privdir()."/mergecommit";
3176         open MC, ">", $mcf or die "$mcf $!";
3177         print MC <<END or die $!;
3178 tree $tree
3179 END
3180
3181         my @parents = grep { $_->{Commit} } @mergeinputs;
3182         @parents = reverse @parents if $compat_info->{ReverseParents};
3183         print MC <<END or die $! foreach @parents;
3184 parent $_->{Commit}
3185 END
3186
3187         print MC <<END or die $!;
3188 author $author
3189 committer $author
3190
3191 END
3192
3193         if (defined $compat_info->{Message}) {
3194             print MC $compat_info->{Message} or die $!;
3195         } else {
3196             print MC <<END or die $!;
3197 Record $package ($cversion) in archive suite $csuite
3198
3199 Record that
3200 END
3201             my $message_add_info = sub {
3202                 my ($mi) = (@_);
3203                 my $mversion = mergeinfo_version $mi;
3204                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3205                     or die $!;
3206             };
3207
3208             $message_add_info->($mergeinputs[0]);
3209             print MC <<END or die $!;
3210 should be treated as descended from
3211 END
3212             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3213         }
3214
3215         close MC or die $!;
3216         $hash = make_commit $mcf;
3217     } else {
3218         $hash = $mergeinputs[0]{Commit};
3219     }
3220     printdebug "fetch hash=$hash\n";
3221
3222     my $chkff = sub {
3223         my ($lasth, $what) = @_;
3224         return unless $lasth;
3225         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3226     };
3227
3228     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3229         if $lastpush_hash;
3230     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3231
3232     fetch_from_archive_record_1($hash);
3233
3234     if (defined $skew_warning_vsn) {
3235         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3236         my $gotclogp = commit_getclogp($hash);
3237         my $got_vsn = getfield $gotclogp, 'Version';
3238         printdebug "SKEW CHECK GOT $got_vsn\n";
3239         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3240             print STDERR <<END or die $!;
3241
3242 Warning: archive skew detected.  Using the available version:
3243 Archive allegedly contains    $skew_warning_vsn
3244 We were able to obtain only   $got_vsn
3245
3246 END
3247         }
3248     }
3249
3250     if ($lastfetch_hash ne $hash) {
3251         fetch_from_archive_record_2($hash);
3252     }
3253
3254     lrfetchref_used lrfetchref();
3255
3256     check_gitattrs($hash, "fetched source tree");
3257
3258     unshift @end, $del_lrfetchrefs;
3259     return $hash;
3260 }
3261
3262 sub set_local_git_config ($$) {
3263     my ($k, $v) = @_;
3264     runcmd @git, qw(config), $k, $v;
3265 }
3266
3267 sub setup_mergechangelogs (;$) {
3268     my ($always) = @_;
3269     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3270
3271     my $driver = 'dpkg-mergechangelogs';
3272     my $cb = "merge.$driver";
3273     confess unless defined $maindir;
3274     my $attrs = "$maindir_gitcommon/info/attributes";
3275     ensuredir "$maindir_gitcommon/info";
3276
3277     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3278     if (!open ATTRS, "<", $attrs) {
3279         $!==ENOENT or die "$attrs: $!";
3280     } else {
3281         while (<ATTRS>) {
3282             chomp;
3283             next if m{^debian/changelog\s};
3284             print NATTRS $_, "\n" or die $!;
3285         }
3286         ATTRS->error and die $!;
3287         close ATTRS;
3288     }
3289     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3290     close NATTRS;
3291
3292     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3293     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3294
3295     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3296 }
3297
3298 sub setup_useremail (;$) {
3299     my ($always) = @_;
3300     return unless $always || access_cfg_bool(1, 'setup-useremail');
3301
3302     my $setup = sub {
3303         my ($k, $envvar) = @_;
3304         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3305         return unless defined $v;
3306         set_local_git_config "user.$k", $v;
3307     };
3308
3309     $setup->('email', 'DEBEMAIL');
3310     $setup->('name', 'DEBFULLNAME');
3311 }
3312
3313 sub ensure_setup_existing_tree () {
3314     my $k = "remote.$remotename.skipdefaultupdate";
3315     my $c = git_get_config $k;
3316     return if defined $c;
3317     set_local_git_config $k, 'true';
3318 }
3319
3320 sub open_main_gitattrs () {
3321     confess 'internal error no maindir' unless defined $maindir;
3322     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3323         or $!==ENOENT
3324         or die "open $maindir_gitcommon/info/attributes: $!";
3325     return $gai;
3326 }
3327
3328 sub is_gitattrs_setup () {
3329     my $gai = open_main_gitattrs();
3330     return 0 unless $gai;
3331     while (<$gai>) {
3332         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3333     }
3334     $gai->error and die $!;
3335     return 0;
3336 }    
3337
3338 sub setup_gitattrs (;$) {
3339     my ($always) = @_;
3340     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3341
3342     if (is_gitattrs_setup()) {
3343         progress <<END;
3344 [attr]dgit-defuse-attrs already found in .git/info/attributes
3345  not doing further gitattributes setup
3346 END
3347         return;
3348     }
3349     my $af = "$maindir_gitcommon/info/attributes";
3350     ensuredir "$maindir_gitcommon/info";
3351     open GAO, "> $af.new" or die $!;
3352     print GAO <<END or die $!;
3353 *       dgit-defuse-attrs
3354 [attr]dgit-defuse-attrs $negate_harmful_gitattrs
3355 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3356 END
3357     my $gai = open_main_gitattrs();
3358     if ($gai) {
3359         while (<$gai>) {
3360             chomp;
3361             print GAO $_, "\n" or die $!;
3362         }
3363         $gai->error and die $!;
3364     }
3365     close GAO or die $!;
3366     rename "$af.new", "$af" or die "install $af: $!";
3367 }
3368
3369 sub setup_new_tree () {
3370     setup_mergechangelogs();
3371     setup_useremail();
3372     setup_gitattrs();
3373 }
3374
3375 sub check_gitattrs ($$) {
3376     my ($treeish, $what) = @_;
3377
3378     return if is_gitattrs_setup;
3379
3380     local $/="\0";
3381     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3382     debugcmd "|",@cmd;
3383     my $gafl = new IO::File;
3384     open $gafl, "-|", @cmd or die $!;
3385     while (<$gafl>) {
3386         chomp or die;
3387         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3388         next if $1 == 0;
3389         next unless m{(?:^|/)\.gitattributes$};
3390
3391         # oh dear, found one
3392         print STDERR <<END;
3393 dgit: warning: $what contains .gitattributes
3394 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3395 END
3396         close $gafl;
3397         return;
3398     }
3399     # tree contains no .gitattributes files
3400     $?=0; $!=0; close $gafl or failedcmd @cmd;
3401 }
3402
3403
3404 sub multisuite_suite_child ($$$) {
3405     my ($tsuite, $merginputs, $fn) = @_;
3406     # in child, sets things up, calls $fn->(), and returns undef
3407     # in parent, returns canonical suite name for $tsuite
3408     my $canonsuitefh = IO::File::new_tmpfile;
3409     my $pid = fork // die $!;
3410     if (!$pid) {
3411         forkcheck_setup();
3412         $isuite = $tsuite;
3413         $us .= " [$isuite]";
3414         $debugprefix .= " ";
3415         progress "fetching $tsuite...";
3416         canonicalise_suite();
3417         print $canonsuitefh $csuite, "\n" or die $!;
3418         close $canonsuitefh or die $!;
3419         $fn->();
3420         return undef;
3421     }
3422     waitpid $pid,0 == $pid or die $!;
3423     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3424     seek $canonsuitefh,0,0 or die $!;
3425     local $csuite = <$canonsuitefh>;
3426     die $! unless defined $csuite && chomp $csuite;
3427     if ($? == 256*4) {
3428         printdebug "multisuite $tsuite missing\n";
3429         return $csuite;
3430     }
3431     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3432     push @$merginputs, {
3433         Ref => lrref,
3434         Info => $csuite,
3435     };
3436     return $csuite;
3437 }
3438
3439 sub fork_for_multisuite ($) {
3440     my ($before_fetch_merge) = @_;
3441     # if nothing unusual, just returns ''
3442     #
3443     # if multisuite:
3444     # returns 0 to caller in child, to do first of the specified suites
3445     # in child, $csuite is not yet set
3446     #
3447     # returns 1 to caller in parent, to finish up anything needed after
3448     # in parent, $csuite is set to canonicalised portmanteau
3449
3450     my $org_isuite = $isuite;
3451     my @suites = split /\,/, $isuite;
3452     return '' unless @suites > 1;
3453     printdebug "fork_for_multisuite: @suites\n";
3454
3455     my @mergeinputs;
3456
3457     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3458                                             sub { });
3459     return 0 unless defined $cbasesuite;
3460
3461     fail "package $package missing in (base suite) $cbasesuite"
3462         unless @mergeinputs;
3463
3464     my @csuites = ($cbasesuite);
3465
3466     $before_fetch_merge->();
3467
3468     foreach my $tsuite (@suites[1..$#suites]) {
3469         $tsuite =~ s/^-/$cbasesuite-/;
3470         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3471                                                sub {
3472             @end = ();
3473             fetch();
3474             exit 0;
3475         });
3476         # xxx collecte the ref here
3477
3478         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3479         push @csuites, $csubsuite;
3480     }
3481
3482     foreach my $mi (@mergeinputs) {
3483         my $ref = git_get_ref $mi->{Ref};
3484         die "$mi->{Ref} ?" unless length $ref;
3485         $mi->{Commit} = $ref;
3486     }
3487
3488     $csuite = join ",", @csuites;
3489
3490     my $previous = git_get_ref lrref;
3491     if ($previous) {
3492         unshift @mergeinputs, {
3493             Commit => $previous,
3494             Info => "local combined tracking branch",
3495             Warning =>
3496  "archive seems to have rewound: local tracking branch is ahead!",
3497         };
3498     }
3499
3500     foreach my $ix (0..$#mergeinputs) {
3501         $mergeinputs[$ix]{Index} = $ix;
3502     }
3503
3504     @mergeinputs = sort {
3505         -version_compare(mergeinfo_version $a,
3506                          mergeinfo_version $b) # highest version first
3507             or
3508         $a->{Index} <=> $b->{Index}; # earliest in spec first
3509     } @mergeinputs;
3510
3511     my @needed;
3512
3513   NEEDED:
3514     foreach my $mi (@mergeinputs) {
3515         printdebug "multisuite merge check $mi->{Info}\n";
3516         foreach my $previous (@needed) {
3517             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3518             printdebug "multisuite merge un-needed $previous->{Info}\n";
3519             next NEEDED;
3520         }
3521         push @needed, $mi;
3522         printdebug "multisuite merge this-needed\n";
3523         $mi->{Character} = '+';
3524     }
3525
3526     $needed[0]{Character} = '*';
3527
3528     my $output = $needed[0]{Commit};
3529
3530     if (@needed > 1) {
3531         printdebug "multisuite merge nontrivial\n";
3532         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3533
3534         my $commit = "tree $tree\n";
3535         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3536             "Input branches:\n";
3537
3538         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3539             printdebug "multisuite merge include $mi->{Info}\n";
3540             $mi->{Character} //= ' ';
3541             $commit .= "parent $mi->{Commit}\n";
3542             $msg .= sprintf " %s  %-25s %s\n",
3543                 $mi->{Character},
3544                 (mergeinfo_version $mi),
3545                 $mi->{Info};
3546         }
3547         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3548         $msg .= "\nKey\n".
3549             " * marks the highest version branch, which choose to use\n".
3550             " + marks each branch which was not already an ancestor\n\n".
3551             "[dgit multi-suite $csuite]\n";
3552         $commit .=
3553             "author $authline\n".
3554             "committer $authline\n\n";
3555         $output = make_commit_text $commit.$msg;
3556         printdebug "multisuite merge generated $output\n";
3557     }
3558
3559     fetch_from_archive_record_1($output);
3560     fetch_from_archive_record_2($output);
3561
3562     progress "calculated combined tracking suite $csuite";
3563
3564     return 1;
3565 }
3566
3567 sub clone_set_head () {
3568     open H, "> .git/HEAD" or die $!;
3569     print H "ref: ".lref()."\n" or die $!;
3570     close H or die $!;
3571 }
3572 sub clone_finish ($) {
3573     my ($dstdir) = @_;
3574     runcmd @git, qw(reset --hard), lrref();
3575     runcmd qw(bash -ec), <<'END';
3576         set -o pipefail
3577         git ls-tree -r --name-only -z HEAD | \
3578         xargs -0r touch -h -r . --
3579 END
3580     printdone "ready for work in $dstdir";
3581 }
3582
3583 sub clone ($) {
3584     # in multisuite, returns twice!
3585     # once in parent after first suite fetched,
3586     # and then again in child after everything is finished
3587     my ($dstdir) = @_;
3588     badusage "dry run makes no sense with clone" unless act_local();
3589
3590     my $multi_fetched = fork_for_multisuite(sub {
3591         printdebug "multi clone before fetch merge\n";
3592         changedir $dstdir;
3593         record_maindir();
3594     });
3595     if ($multi_fetched) {
3596         printdebug "multi clone after fetch merge\n";
3597         clone_set_head();
3598         clone_finish($dstdir);
3599         return;
3600     }
3601     printdebug "clone main body\n";
3602
3603     canonicalise_suite();
3604     my $hasgit = check_for_git();
3605     mkdir $dstdir or fail "create \`$dstdir': $!";
3606     changedir $dstdir;
3607     runcmd @git, qw(init -q);
3608     record_maindir();
3609     setup_new_tree();
3610     clone_set_head();
3611     my $giturl = access_giturl(1);
3612     if (defined $giturl) {
3613         runcmd @git, qw(remote add), 'origin', $giturl;
3614     }
3615     if ($hasgit) {
3616         progress "fetching existing git history";
3617         git_fetch_us();
3618         runcmd_ordryrun_local @git, qw(fetch origin);
3619     } else {
3620         progress "starting new git history";
3621     }
3622     fetch_from_archive() or no_such_package;
3623     my $vcsgiturl = $dsc->{'Vcs-Git'};
3624     if (length $vcsgiturl) {
3625         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3626         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3627     }
3628     clone_finish($dstdir);
3629 }
3630
3631 sub fetch () {
3632     canonicalise_suite();
3633     if (check_for_git()) {
3634         git_fetch_us();
3635     }
3636     fetch_from_archive() or no_such_package();
3637     printdone "fetched into ".lrref();
3638 }
3639
3640 sub pull () {
3641     my $multi_fetched = fork_for_multisuite(sub { });
3642     fetch() unless $multi_fetched; # parent
3643     return if $multi_fetched eq '0'; # child
3644     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3645         lrref();
3646     printdone "fetched to ".lrref()." and merged into HEAD";
3647 }
3648
3649 sub check_not_dirty () {
3650     foreach my $f (qw(local-options local-patch-header)) {
3651         if (stat_exists "debian/source/$f") {
3652             fail "git tree contains debian/source/$f";
3653         }
3654     }
3655
3656     return if $ignoredirty;
3657
3658     my @cmd = (@git, qw(diff --quiet HEAD));
3659     debugcmd "+",@cmd;
3660     $!=0; $?=-1; system @cmd;
3661     return if !$?;
3662     if ($?==256) {
3663         fail "working tree is dirty (does not match HEAD)";
3664     } else {
3665         failedcmd @cmd;
3666     }
3667 }
3668
3669 sub commit_admin ($) {
3670     my ($m) = @_;
3671     progress "$m";
3672     runcmd_ordryrun_local @git, qw(commit -m), $m;
3673 }
3674
3675 sub commit_quilty_patch () {
3676     my $output = cmdoutput @git, qw(status --porcelain);
3677     my %adds;
3678     foreach my $l (split /\n/, $output) {
3679         next unless $l =~ m/\S/;
3680         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3681             $adds{$1}++;
3682         }
3683     }
3684     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3685     if (!%adds) {
3686         progress "nothing quilty to commit, ok.";
3687         return;
3688     }
3689     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3690     runcmd_ordryrun_local @git, qw(add -f), @adds;
3691     commit_admin <<END
3692 Commit Debian 3.0 (quilt) metadata
3693
3694 [dgit ($our_version) quilt-fixup]
3695 END
3696 }
3697
3698 sub get_source_format () {
3699     my %options;
3700     if (open F, "debian/source/options") {
3701         while (<F>) {
3702             next if m/^\s*\#/;
3703             next unless m/\S/;
3704             s/\s+$//; # ignore missing final newline
3705             if (m/\s*\#\s*/) {
3706                 my ($k, $v) = ($`, $'); #');
3707                 $v =~ s/^"(.*)"$/$1/;
3708                 $options{$k} = $v;
3709             } else {
3710                 $options{$_} = 1;
3711             }
3712         }
3713         F->error and die $!;
3714         close F;
3715     } else {
3716         die $! unless $!==&ENOENT;
3717     }
3718
3719     if (!open F, "debian/source/format") {
3720         die $! unless $!==&ENOENT;
3721         return '';
3722     }
3723     $_ = <F>;
3724     F->error and die $!;
3725     chomp;
3726     return ($_, \%options);
3727 }
3728
3729 sub madformat_wantfixup ($) {
3730     my ($format) = @_;
3731     return 0 unless $format eq '3.0 (quilt)';
3732     our $quilt_mode_warned;
3733     if ($quilt_mode eq 'nocheck') {
3734         progress "Not doing any fixup of \`$format' due to".
3735             " ----no-quilt-fixup or --quilt=nocheck"
3736             unless $quilt_mode_warned++;
3737         return 0;
3738     }
3739     progress "Format \`$format', need to check/update patch stack"
3740         unless $quilt_mode_warned++;
3741     return 1;
3742 }
3743
3744 sub maybe_split_brain_save ($$$) {
3745     my ($headref, $dgitview, $msg) = @_;
3746     # => message fragment "$saved" describing disposition of $dgitview
3747     return "commit id $dgitview" unless defined $split_brain_save;
3748     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
3749                @git, qw(update-ref -m),
3750                "dgit --dgit-view-save $msg HEAD=$headref",
3751                $split_brain_save, $dgitview);
3752     runcmd @cmd;
3753     return "and left in $split_brain_save";
3754 }
3755
3756 # An "infopair" is a tuple [ $thing, $what ]
3757 # (often $thing is a commit hash; $what is a description)
3758
3759 sub infopair_cond_equal ($$) {
3760     my ($x,$y) = @_;
3761     $x->[0] eq $y->[0] or fail <<END;
3762 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3763 END
3764 };
3765
3766 sub infopair_lrf_tag_lookup ($$) {
3767     my ($tagnames, $what) = @_;
3768     # $tagname may be an array ref
3769     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3770     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3771     foreach my $tagname (@tagnames) {
3772         my $lrefname = lrfetchrefs."/tags/$tagname";
3773         my $tagobj = $lrfetchrefs_f{$lrefname};
3774         next unless defined $tagobj;
3775         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3776         return [ git_rev_parse($tagobj), $what ];
3777     }
3778     fail @tagnames==1 ? <<END : <<END;
3779 Wanted tag $what (@tagnames) on dgit server, but not found
3780 END
3781 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3782 END
3783 }
3784
3785 sub infopair_cond_ff ($$) {
3786     my ($anc,$desc) = @_;
3787     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3788 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3789 END
3790 };
3791
3792 sub pseudomerge_version_check ($$) {
3793     my ($clogp, $archive_hash) = @_;
3794
3795     my $arch_clogp = commit_getclogp $archive_hash;
3796     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3797                      'version currently in archive' ];
3798     if (defined $overwrite_version) {
3799         if (length $overwrite_version) {
3800             infopair_cond_equal([ $overwrite_version,
3801                                   '--overwrite= version' ],
3802                                 $i_arch_v);
3803         } else {
3804             my $v = $i_arch_v->[0];
3805             progress "Checking package changelog for archive version $v ...";
3806             my $cd;
3807             eval {
3808                 my @xa = ("-f$v", "-t$v");
3809                 my $vclogp = parsechangelog @xa;
3810                 my $gf = sub {
3811                     my ($fn) = @_;
3812                     [ (getfield $vclogp, $fn),
3813                       "$fn field from dpkg-parsechangelog @xa" ];
3814                 };
3815                 my $cv = $gf->('Version');
3816                 infopair_cond_equal($i_arch_v, $cv);
3817                 $cd = $gf->('Distribution');
3818             };
3819             if ($@) {
3820                 $@ =~ s/^dgit: //gm;
3821                 fail "$@".
3822                     "Perhaps debian/changelog does not mention $v ?";
3823             }
3824             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3825 $cd->[1] is $cd->[0]
3826 Your tree seems to based on earlier (not uploaded) $v.
3827 END
3828         }
3829     }
3830     
3831     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3832     return $i_arch_v;
3833 }
3834
3835 sub pseudomerge_make_commit ($$$$ $$) {
3836     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3837         $msg_cmd, $msg_msg) = @_;
3838     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3839
3840     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3841     my $authline = clogp_authline $clogp;
3842
3843     chomp $msg_msg;
3844     $msg_cmd .=
3845         !defined $overwrite_version ? ""
3846         : !length  $overwrite_version ? " --overwrite"
3847         : " --overwrite=".$overwrite_version;
3848
3849     my $pmf = dgit_privdir()."/pseudomerge";
3850     open MC, ">", $pmf or die "$pmf $!";
3851     print MC <<END or die $!;
3852 tree $tree
3853 parent $dgitview
3854 parent $archive_hash
3855 author $authline
3856 committer $authline
3857
3858 $msg_msg
3859
3860 [$msg_cmd]
3861 END
3862     close MC or die $!;
3863
3864     return make_commit($pmf);
3865 }
3866
3867 sub splitbrain_pseudomerge ($$$$) {
3868     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3869     # => $merged_dgitview
3870     printdebug "splitbrain_pseudomerge...\n";
3871     #
3872     #     We:      debian/PREVIOUS    HEAD($maintview)
3873     # expect:          o ----------------- o
3874     #                    \                   \
3875     #                     o                   o
3876     #                 a/d/PREVIOUS        $dgitview
3877     #                $archive_hash              \
3878     #  If so,                \                   \
3879     #  we do:                 `------------------ o
3880     #   this:                                   $dgitview'
3881     #
3882
3883     return $dgitview unless defined $archive_hash;
3884     return $dgitview if deliberately_not_fast_forward();
3885
3886     printdebug "splitbrain_pseudomerge...\n";
3887
3888     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3889
3890     if (!defined $overwrite_version) {
3891         progress "Checking that HEAD inciudes all changes in archive...";
3892     }
3893
3894     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3895
3896     if (defined $overwrite_version) {
3897     } elsif (!eval {
3898         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3899         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3900         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3901         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3902         my $i_archive = [ $archive_hash, "current archive contents" ];
3903
3904         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3905
3906         infopair_cond_equal($i_dgit, $i_archive);
3907         infopair_cond_ff($i_dep14, $i_dgit);
3908         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3909         1;
3910     }) {
3911         print STDERR <<END;
3912 $us: check failed (maybe --overwrite is needed, consult documentation)
3913 END
3914         die "$@";
3915     }
3916
3917     my $r = pseudomerge_make_commit
3918         $clogp, $dgitview, $archive_hash, $i_arch_v,
3919         "dgit --quilt=$quilt_mode",
3920         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3921 Declare fast forward from $i_arch_v->[0]
3922 END_OVERWR
3923 Make fast forward from $i_arch_v->[0]
3924 END_MAKEFF
3925
3926     maybe_split_brain_save $maintview, $r, "pseudomerge";
3927
3928     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3929     return $r;
3930 }       
3931
3932 sub plain_overwrite_pseudomerge ($$$) {
3933     my ($clogp, $head, $archive_hash) = @_;
3934
3935     printdebug "plain_overwrite_pseudomerge...";
3936
3937     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3938
3939     return $head if is_fast_fwd $archive_hash, $head;
3940
3941     my $m = "Declare fast forward from $i_arch_v->[0]";
3942
3943     my $r = pseudomerge_make_commit
3944         $clogp, $head, $archive_hash, $i_arch_v,
3945         "dgit", $m;
3946
3947     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3948
3949     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3950     return $r;
3951 }
3952
3953 sub push_parse_changelog ($) {
3954     my ($clogpfn) = @_;
3955
3956     my $clogp = Dpkg::Control::Hash->new();
3957     $clogp->load($clogpfn) or die;
3958
3959     my $clogpackage = getfield $clogp, 'Source';
3960     $package //= $clogpackage;
3961     fail "-p specified $package but changelog specified $clogpackage"
3962         unless $package eq $clogpackage;
3963     my $cversion = getfield $clogp, 'Version';
3964
3965     if (!$we_are_initiator) {
3966         # rpush initiator can't do this because it doesn't have $isuite yet
3967         my $tag = debiantag($cversion, access_nomdistro);
3968         runcmd @git, qw(check-ref-format), $tag;
3969     }
3970
3971     my $dscfn = dscfn($cversion);
3972
3973     return ($clogp, $cversion, $dscfn);
3974 }
3975
3976 sub push_parse_dsc ($$$) {
3977     my ($dscfn,$dscfnwhat, $cversion) = @_;
3978     $dsc = parsecontrol($dscfn,$dscfnwhat);
3979     my $dversion = getfield $dsc, 'Version';
3980     my $dscpackage = getfield $dsc, 'Source';
3981     ($dscpackage eq $package && $dversion eq $cversion) or
3982         fail "$dscfn is for $dscpackage $dversion".
3983             " but debian/changelog is for $package $cversion";
3984 }
3985
3986 sub push_tagwants ($$$$) {
3987     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3988     my @tagwants;
3989     push @tagwants, {
3990         TagFn => \&debiantag,
3991         Objid => $dgithead,
3992         TfSuffix => '',
3993         View => 'dgit',
3994     };
3995     if (defined $maintviewhead) {
3996         push @tagwants, {
3997             TagFn => \&debiantag_maintview,
3998             Objid => $maintviewhead,
3999             TfSuffix => '-maintview',
4000             View => 'maint',
4001         };
4002     } elsif ($dodep14tag eq 'no' ? 0
4003              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
4004              : $dodep14tag eq 'always'
4005              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
4006 --dep14tag-always (or equivalent in config) means server must support
4007  both "new" and "maint" tag formats, but config says it doesn't.
4008 END
4009             : die "$dodep14tag ?") {
4010         push @tagwants, {
4011             TagFn => \&debiantag_maintview,
4012             Objid => $dgithead,
4013             TfSuffix => '-dgit',
4014             View => 'dgit',
4015         };
4016     };
4017     foreach my $tw (@tagwants) {
4018         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4019         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4020     }
4021     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4022     return @tagwants;
4023 }
4024
4025 sub push_mktags ($$ $$ $) {
4026     my ($clogp,$dscfn,
4027         $changesfile,$changesfilewhat,
4028         $tagwants) = @_;
4029
4030     die unless $tagwants->[0]{View} eq 'dgit';
4031
4032     my $declaredistro = access_nomdistro();
4033     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4034     $dsc->{$ourdscfield[0]} = join " ",
4035         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4036         $reader_giturl;
4037     $dsc->save("$dscfn.tmp") or die $!;
4038
4039     my $changes = parsecontrol($changesfile,$changesfilewhat);
4040     foreach my $field (qw(Source Distribution Version)) {
4041         $changes->{$field} eq $clogp->{$field} or
4042             fail "changes field $field \`$changes->{$field}'".
4043                 " does not match changelog \`$clogp->{$field}'";
4044     }
4045
4046     my $cversion = getfield $clogp, 'Version';
4047     my $clogsuite = getfield $clogp, 'Distribution';
4048
4049     # We make the git tag by hand because (a) that makes it easier
4050     # to control the "tagger" (b) we can do remote signing
4051     my $authline = clogp_authline $clogp;
4052     my $delibs = join(" ", "",@deliberatelies);
4053
4054     my $mktag = sub {
4055         my ($tw) = @_;
4056         my $tfn = $tw->{Tfn};
4057         my $head = $tw->{Objid};
4058         my $tag = $tw->{Tag};
4059
4060         open TO, '>', $tfn->('.tmp') or die $!;
4061         print TO <<END or die $!;
4062 object $head
4063 type commit
4064 tag $tag
4065 tagger $authline
4066
4067 END
4068         if ($tw->{View} eq 'dgit') {
4069             print TO <<END or die $!;
4070 $package release $cversion for $clogsuite ($csuite) [dgit]
4071 [dgit distro=$declaredistro$delibs]
4072 END
4073             foreach my $ref (sort keys %previously) {
4074                 print TO <<END or die $!;
4075 [dgit previously:$ref=$previously{$ref}]
4076 END
4077             }
4078         } elsif ($tw->{View} eq 'maint') {
4079             print TO <<END or die $!;
4080 $package release $cversion for $clogsuite ($csuite)
4081 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4082 END
4083         } else {
4084             die Dumper($tw)."?";
4085         }
4086
4087         close TO or die $!;
4088
4089         my $tagobjfn = $tfn->('.tmp');
4090         if ($sign) {
4091             if (!defined $keyid) {
4092                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4093             }
4094             if (!defined $keyid) {
4095                 $keyid = getfield $clogp, 'Maintainer';
4096             }
4097             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4098             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4099             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4100             push @sign_cmd, $tfn->('.tmp');
4101             runcmd_ordryrun @sign_cmd;
4102             if (act_scary()) {
4103                 $tagobjfn = $tfn->('.signed.tmp');
4104                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4105                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4106             }
4107         }
4108         return $tagobjfn;
4109     };
4110
4111     my @r = map { $mktag->($_); } @$tagwants;
4112     return @r;
4113 }
4114
4115 sub sign_changes ($) {
4116     my ($changesfile) = @_;
4117     if ($sign) {
4118         my @debsign_cmd = @debsign;
4119         push @debsign_cmd, "-k$keyid" if defined $keyid;
4120         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4121         push @debsign_cmd, $changesfile;
4122         runcmd_ordryrun @debsign_cmd;
4123     }
4124 }
4125
4126 sub dopush () {
4127     printdebug "actually entering push\n";
4128
4129     supplementary_message(<<'END');
4130 Push failed, while checking state of the archive.
4131 You can retry the push, after fixing the problem, if you like.
4132 END
4133     if (check_for_git()) {
4134         git_fetch_us();
4135     }
4136     my $archive_hash = fetch_from_archive();
4137     if (!$archive_hash) {
4138         $new_package or
4139             fail "package appears to be new in this suite;".
4140                 " if this is intentional, use --new";
4141     }
4142
4143     supplementary_message(<<'END');
4144 Push failed, while preparing your push.
4145 You can retry the push, after fixing the problem, if you like.
4146 END
4147
4148     need_tagformat 'new', "quilt mode $quilt_mode"
4149         if quiltmode_splitbrain;
4150
4151     prep_ud();
4152
4153     access_giturl(); # check that success is vaguely likely
4154     rpush_handle_protovsn_bothends() if $we_are_initiator;
4155     select_tagformat();
4156
4157     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4158     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4159
4160     responder_send_file('parsed-changelog', $clogpfn);
4161
4162     my ($clogp, $cversion, $dscfn) =
4163         push_parse_changelog("$clogpfn");
4164
4165     my $dscpath = "$buildproductsdir/$dscfn";
4166     stat_exists $dscpath or
4167         fail "looked for .dsc $dscpath, but $!;".
4168             " maybe you forgot to build";
4169
4170     responder_send_file('dsc', $dscpath);
4171
4172     push_parse_dsc($dscpath, $dscfn, $cversion);
4173
4174     my $format = getfield $dsc, 'Format';
4175     printdebug "format $format\n";
4176
4177     my $actualhead = git_rev_parse('HEAD');
4178     my $dgithead = $actualhead;
4179     my $maintviewhead = undef;
4180
4181     my $upstreamversion = upstreamversion $clogp->{Version};
4182
4183     if (madformat_wantfixup($format)) {
4184         # user might have not used dgit build, so maybe do this now:
4185         if (quiltmode_splitbrain()) {
4186             changedir $playground;
4187             quilt_make_fake_dsc($upstreamversion);
4188             my $cachekey;
4189             ($dgithead, $cachekey) =
4190                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4191             $dgithead or fail
4192  "--quilt=$quilt_mode but no cached dgit view:
4193  perhaps HEAD changed since dgit build[-source] ?";
4194             $split_brain = 1;
4195             $dgithead = splitbrain_pseudomerge($clogp,
4196                                                $actualhead, $dgithead,
4197                                                $archive_hash);
4198             $maintviewhead = $actualhead;
4199             changedir $maindir;
4200             prep_ud(); # so _only_subdir() works, below
4201         } else {
4202             commit_quilty_patch();
4203         }
4204     }
4205
4206     if (defined $overwrite_version && !defined $maintviewhead) {
4207         $dgithead = plain_overwrite_pseudomerge($clogp,
4208                                                 $dgithead,
4209                                                 $archive_hash);
4210     }
4211
4212     check_not_dirty();
4213
4214     my $forceflag = '';
4215     if ($archive_hash) {
4216         if (is_fast_fwd($archive_hash, $dgithead)) {
4217             # ok
4218         } elsif (deliberately_not_fast_forward) {
4219             $forceflag = '+';
4220         } else {
4221             fail "dgit push: HEAD is not a descendant".
4222                 " of the archive's version.\n".
4223                 "To overwrite the archive's contents,".
4224                 " pass --overwrite[=VERSION].\n".
4225                 "To rewind history, if permitted by the archive,".
4226                 " use --deliberately-not-fast-forward.";
4227         }
4228     }
4229
4230     changedir $playground;
4231     progress "checking that $dscfn corresponds to HEAD";
4232     runcmd qw(dpkg-source -x --),
4233         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4234     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4235     check_for_vendor_patches() if madformat($dsc->{format});
4236     changedir $maindir;
4237     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4238     debugcmd "+",@diffcmd;
4239     $!=0; $?=-1;
4240     my $r = system @diffcmd;
4241     if ($r) {
4242         if ($r==256) {
4243             my $referent = $split_brain ? $dgithead : 'HEAD';
4244             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4245
4246             my @mode_changes;
4247             my $raw = cmdoutput @git,
4248                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4249             my $changed;
4250             foreach (split /\0/, $raw) {
4251                 if (defined $changed) {
4252                     push @mode_changes, "$changed: $_\n" if $changed;
4253                     $changed = undef;
4254                     next;
4255                 } elsif (m/^:0+ 0+ /) {
4256                     $changed = '';
4257                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4258                     $changed = "Mode change from $1 to $2"
4259                 } else {
4260                     die "$_ ?";
4261                 }
4262             }
4263             if (@mode_changes) {
4264                 fail <<END.(join '', @mode_changes).<<END;
4265 HEAD specifies a different tree to $dscfn:
4266 $diffs
4267 END
4268 There is a problem with your source tree (see dgit(7) for some hints).
4269 To see a full diff, run git diff $tree $referent
4270 END
4271             }
4272
4273             fail <<END;
4274 HEAD specifies a different tree to $dscfn:
4275 $diffs
4276 Perhaps you forgot to build.  Or perhaps there is a problem with your
4277  source tree (see dgit(7) for some hints).  To see a full diff, run
4278    git diff $tree $referent
4279 END
4280         } else {
4281             failedcmd @diffcmd;
4282         }
4283     }
4284     if (!$changesfile) {
4285         my $pat = changespat $cversion;
4286         my @cs = glob "$buildproductsdir/$pat";
4287         fail "failed to find unique changes file".
4288             " (looked for $pat in $buildproductsdir);".
4289             " perhaps you need to use dgit -C"
4290             unless @cs==1;
4291         ($changesfile) = @cs;
4292     } else {
4293         $changesfile = "$buildproductsdir/$changesfile";
4294     }
4295
4296     # Check that changes and .dsc agree enough
4297     $changesfile =~ m{[^/]*$};
4298     my $changes = parsecontrol($changesfile,$&);
4299     files_compare_inputs($dsc, $changes)
4300         unless forceing [qw(dsc-changes-mismatch)];
4301
4302     # Perhaps adjust .dsc to contain right set of origs
4303     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4304                                   $changesfile)
4305         unless forceing [qw(changes-origs-exactly)];
4306
4307     # Checks complete, we're going to try and go ahead:
4308
4309     responder_send_file('changes',$changesfile);
4310     responder_send_command("param head $dgithead");
4311     responder_send_command("param csuite $csuite");
4312     responder_send_command("param isuite $isuite");
4313     responder_send_command("param tagformat $tagformat");
4314     if (defined $maintviewhead) {
4315         die unless ($protovsn//4) >= 4;
4316         responder_send_command("param maint-view $maintviewhead");
4317     }
4318
4319     # Perhaps send buildinfo(s) for signing
4320     my $changes_files = getfield $changes, 'Files';
4321     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4322     foreach my $bi (@buildinfos) {
4323         responder_send_command("param buildinfo-filename $bi");
4324         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4325     }
4326
4327     if (deliberately_not_fast_forward) {
4328         git_for_each_ref(lrfetchrefs, sub {
4329             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4330             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4331             responder_send_command("previously $rrefname=$objid");
4332             $previously{$rrefname} = $objid;
4333         });
4334     }
4335
4336     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4337                                  dgit_privdir()."/tag");
4338     my @tagobjfns;
4339
4340     supplementary_message(<<'END');
4341 Push failed, while signing the tag.
4342 You can retry the push, after fixing the problem, if you like.
4343 END
4344     # If we manage to sign but fail to record it anywhere, it's fine.
4345     if ($we_are_responder) {
4346         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4347         responder_receive_files('signed-tag', @tagobjfns);
4348     } else {
4349         @tagobjfns = push_mktags($clogp,$dscpath,
4350                               $changesfile,$changesfile,
4351                               \@tagwants);
4352     }
4353     supplementary_message(<<'END');
4354 Push failed, *after* signing the tag.
4355 If you want to try again, you should use a new version number.
4356 END
4357
4358     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4359
4360     foreach my $tw (@tagwants) {
4361         my $tag = $tw->{Tag};
4362         my $tagobjfn = $tw->{TagObjFn};
4363         my $tag_obj_hash =
4364             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4365         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4366         runcmd_ordryrun_local
4367             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4368     }
4369
4370     supplementary_message(<<'END');
4371 Push failed, while updating the remote git repository - see messages above.
4372 If you want to try again, you should use a new version number.
4373 END
4374     if (!check_for_git()) {
4375         create_remote_git_repo();
4376     }
4377
4378     my @pushrefs = $forceflag.$dgithead.":".rrref();
4379