dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2018 Ian Jackson
   6 # Copyright (C)2017-2018 Sean Whitton
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23 use Debian::Dgit::I18n;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use IO::Handle;
  31 use Data::Dumper;
  32 use LWP::UserAgent;
  33 use Dpkg::Control::Hash;
  34 use File::Path;
  35 use File::Temp qw(tempdir);
  36 use File::Basename;
  37 use Dpkg::Version;
  38 use Dpkg::Compression;
  39 use Dpkg::Compression::Process;
  40 use POSIX;
  41 use Locale::gettext;
  42 use IPC::Open2;
  43 use Digest::SHA;
  44 use Digest::MD5;
  45 use List::MoreUtils qw(pairwise);
  46 use Text::Glob qw(match_glob);
  47 use Fcntl qw(:DEFAULT :flock);
  48 use Carp;
  49
  50 use Debian::Dgit;
  51
  52 our $our_version = 'UNRELEASED'; ###substituted###
  53 our $absurdity = undef; ###substituted###
  54
  55 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  56 our $protovsn;
  57
  58 our $cmd;
  59 our $subcommand;
  60 our $isuite;
  61 our $idistro;
  62 our $package;
  63 our @ropts;
  64
  65 our $sign = 1;
  66 our $dryrun_level = 0;
  67 our $changesfile;
  68 our $buildproductsdir;
  69 our $bpd_glob;
  70 our $new_package = 0;
  71 our $includedirty = 0;
  72 our $rmonerror = 1;
  73 our @deliberatelies;
  74 our %previously;
  75 our $existing_package = 'dpkg';
  76 our $cleanmode;
  77 our $changes_since_version;
  78 our $rmchanges;
  79 our $overwrite_version; # undef: not specified; '': check changelog
  80 our $quilt_mode;
  81 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  82 our $dodep14tag;
  83 our %internal_object_save;
  84 our $we_are_responder;
  85 our $we_are_initiator;
  86 our $initiator_tempdir;
  87 our $patches_applied_dirtily = 00;
  88 our $tagformat_want;
  89 our $tagformat;
  90 our $tagformatfn;
  91 our $chase_dsc_distro=1;
  92
  93 our %forceopts = map { $_=>0 }
  94     qw(unrepresentable unsupported-source-format
  95        dsc-changes-mismatch changes-origs-exactly
  96        uploading-binaries uploading-source-only
  97        import-gitapply-absurd
  98        import-gitapply-no-absurd
  99        import-dsc-with-dgit-field);
 100
 101 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
 102
 103 our $suite_re = '[-+.0-9a-z]+';
 104 our $cleanmode_re = qr{(?: dpkg-source (?: -d )? (?: ,no-check | ,all-check )?
 105                      | (?: git | git-ff )
 106                          | check (?: ,ignores )?
 107                          | none
 108                          )}x;
 109
 110 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 111 our $splitbraincache = 'dgit-intern/quilt-cache';
 112 our $rewritemap = 'dgit-rewrite/map';
 113
 114 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
 115
 116 our (@git) = qw(git);
 117 our (@dget) = qw(dget);
 118 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 119 our (@dput) = qw(dput);
 120 our (@debsign) = qw(debsign);
 121 our (@gpg) = qw(gpg);
 122 our (@sbuild) = (qw(sbuild --no-source));
 123 our (@ssh) = 'ssh';
 124 our (@dgit) = qw(dgit);
 125 our (@git_debrebase) = qw(git-debrebase);
 126 our (@aptget) = qw(apt-get);
 127 our (@aptcache) = qw(apt-cache);
 128 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
 129 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
 130 our (@dpkggenchanges) = qw(dpkg-genchanges);
 131 our (@mergechanges) = qw(mergechanges -f);
 132 our (@gbp_build) = ('');
 133 our (@gbp_pq) = ('gbp pq');
 134 our (@changesopts) = ('');
 135 our (@pbuilder) = ("sudo -E pbuilder","--no-source-only-changes");
 136 our (@cowbuilder) = ("sudo -E cowbuilder","--no-source-only-changes");
 137
 138 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 139                      'curl' => \@curl,
 140                      'dput' => \@dput,
 141                      'debsign' => \@debsign,
 142                      'gpg' => \@gpg,
 143                      'sbuild' => \@sbuild,
 144                      'ssh' => \@ssh,
 145                      'dgit' => \@dgit,
 146                      'git' => \@git,
 147                      'git-debrebase' => \@git_debrebase,
 148                      'apt-get' => \@aptget,
 149                      'apt-cache' => \@aptcache,
 150                      'dpkg-source' => \@dpkgsource,
 151                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 152                      'dpkg-genchanges' => \@dpkggenchanges,
 153                      'gbp-build' => \@gbp_build,
 154                      'gbp-pq' => \@gbp_pq,
 155                      'ch' => \@changesopts,
 156                      'mergechanges' => \@mergechanges,
 157                      'pbuilder' => \@pbuilder,
 158                      'cowbuilder' => \@cowbuilder);
 159
 160 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 161 our %opts_cfg_insertpos = map {
 162     $_,
 163     scalar @{ $opts_opt_map{$_} }
 164 } keys %opts_opt_map;
 165
 166 sub parseopts_late_defaults();
 167 sub setup_gitattrs(;$);
 168 sub check_gitattrs($$);
 169
 170 our $playground;
 171 our $keyid;
 172
 173 autoflush STDOUT 1;
 174
 175 our $supplementary_message = '';
 176 our $split_brain = 0;
 177
 178 END {
 179     local ($@, $?);
 180     return unless forkcheck_mainprocess();
 181     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 182 }
 183
 184 our $remotename = 'dgit';
 185 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 186 our $csuite;
 187 our $instead_distro;
 188
 189 if (!defined $absurdity) {
 190     $absurdity = $0;
 191     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 192 }
 193
 194 sub debiantag ($$) {
 195     my ($v,$distro) = @_;
 196     return $tagformatfn->($v, $distro);
 197 }
 198
 199 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 200
 201 sub lbranch () { return "$branchprefix/$csuite"; }
 202 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 203 sub lref () { return "refs/heads/".lbranch(); }
 204 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 205 sub rrref () { return server_ref($csuite); }
 206
 207 sub srcfn ($$) {
 208     my ($vsn, $sfx) = @_;
 209     return &source_file_leafname($package, $vsn, $sfx);
 210 }
 211 sub is_orig_file_of_vsn ($$) {
 212     my ($f, $upstreamvsn) = @_;
 213     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
 214 }
 215
 216 sub dscfn ($) {
 217     my ($vsn) = @_;
 218     return srcfn($vsn,".dsc");
 219 }
 220
 221 sub changespat ($;$) {
 222     my ($vsn, $arch) = @_;
 223     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 224 }
 225
 226 our $us = 'dgit';
 227 initdebug('');
 228
 229 our @end;
 230 END {
 231     local ($?);
 232     return unless forkcheck_mainprocess();
 233     foreach my $f (@end) {
 234         eval { $f->(); };
 235         print STDERR "$us: cleanup: $@" if length $@;
 236     }
 237 };
 238
 239 sub badcfg {
 240     print STDERR f_ "%s: invalid configuration: %s\n", $us, "@_";
 241     finish 12;
 242 }
 243
 244 sub forceable_fail ($$) {
 245     my ($forceoptsl, $msg) = @_;
 246     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 247     print STDERR +(__ "warning: overriding problem due to --force:\n"). $msg;
 248 }
 249
 250 sub forceing ($) {
 251     my ($forceoptsl) = @_;
 252     my @got = grep { $forceopts{$_} } @$forceoptsl;
 253     return 0 unless @got;
 254     print STDERR f_
 255         "warning: skipping checks or functionality due to --force-%s\n",
 256         $got[0];
 257 }
 258
 259 sub no_such_package () {
 260     print STDERR f_ "%s: package %s does not exist in suite %s\n",
 261         $us, $package, $isuite;
 262     finish 4;
 263 }
 264
 265 sub deliberately ($) {
 266     my ($enquiry) = @_;
 267     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 268 }
 269
 270 sub deliberately_not_fast_forward () {
 271     foreach (qw(not-fast-forward fresh-repo)) {
 272         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 273     }
 274 }
 275
 276 sub quiltmode_splitbrain () {
 277     $quilt_mode =~ m/gbp|dpm|unapplied/;
 278 }
 279
 280 sub opts_opt_multi_cmd {
 281     my $extra = shift;
 282     my @cmd;
 283     push @cmd, split /\s+/, shift @_;
 284     push @cmd, @$extra;
 285     push @cmd, @_;
 286     @cmd;
 287 }
 288
 289 sub gbp_pq {
 290     return opts_opt_multi_cmd [], @gbp_pq;
 291 }
 292
 293 sub dgit_privdir () {
 294     our $dgit_privdir_made //= ensure_a_playground 'dgit';
 295 }
 296
 297 sub bpd_abs () {
 298     my $r = $buildproductsdir;
 299     $r = "$maindir/$r" unless $r =~ m{^/};
 300     return $r;
 301 }
 302
 303 sub get_tree_of_commit ($) {
 304     my ($commitish) = @_;
 305     my $cdata = cmdoutput @git, qw(cat-file commit), $commitish;
 306     $cdata =~ m/\n\n/;  $cdata = $`;
 307     $cdata =~ m/^tree (\w+)$/m or confess "cdata $cdata ?";
 308     return $1;
 309 }
 310
 311 sub branch_gdr_info ($$) {
 312     my ($symref, $head) = @_;
 313     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
 314         gdr_ffq_prev_branchinfo($symref);
 315     return () unless $status eq 'branch';
 316     $ffq_prev = git_get_ref $ffq_prev;
 317     $gdrlast  = git_get_ref $gdrlast;
 318     $gdrlast &&= is_fast_fwd $gdrlast, $head;
 319     return ($ffq_prev, $gdrlast);
 320 }
 321
 322 sub branch_is_gdr_unstitched_ff ($$$) {
 323     my ($symref, $head, $ancestor) = @_;
 324     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 325     return 0 unless $ffq_prev;
 326     return 0 unless !defined $ancestor or is_fast_fwd $ancestor, $ffq_prev;
 327     return 1;
 328 }
 329
 330 sub branch_is_gdr ($) {
 331     my ($head) = @_;
 332     # This is quite like git-debrebase's keycommits.
 333     # We have our own implementation because:
 334     #  - our algorighm can do fewer tests so is faster
 335     #  - it saves testing to see if gdr is installed
 336
 337     # NB we use this jsut for deciding whether to run gdr make-patches
 338     # Before reusing this algorithm for somthing else, its
 339     # suitability should be reconsidered.
 340
 341     my $walk = $head;
 342     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 343     printdebug "branch_is_gdr $head...\n";
 344     my $get_patches = sub {
 345         my $t = git_cat_file "$_[0]:debian/patches", [qw(missing tree)];
 346         return $t // '';
 347     };
 348     my $tip_patches = $get_patches->($head);
 349   WALK:
 350     for (;;) {
 351         my $cdata = git_cat_file $walk, 'commit';
 352         my ($hdrs,$msg) = $cdata =~ m{\n\n} ? ($`,$') : ($cdata,'');
 353         if ($msg =~ m{^\[git-debrebase\ (
 354                           anchor | changelog | make-patches |
 355                           merged-breakwater | pseudomerge
 356                       ) [: ] }mx) {
 357             # no need to analyse this - it's sufficient
 358             # (gdr classifications: Anchor, MergedBreakwaters)
 359             # (made by gdr: Pseudomerge, Changelog)
 360             printdebug "branch_is_gdr  $walk gdr $1 YES\n";
 361             return 1;
 362         }
 363         my @parents = ($hdrs =~ m/^parent (\w+)$/gm);
 364         if (@parents==2) {
 365             my $walk_tree = get_tree_of_commit $walk;
 366             foreach my $p (@parents) {
 367                 my $p_tree = get_tree_of_commit $p;
 368                 if ($p_tree eq $walk_tree) { # pseudomerge contriburor
 369                     # (gdr classification: Pseudomerge; not made by gdr)
 370                     printdebug "branch_is_gdr  $walk unmarked pseudomerge\n"
 371                         if $debuglevel >= 2;
 372                     $walk = $p;
 373                     next WALK;
 374                 }
 375             }
 376             # some other non-gdr merge
 377             # (gdr classification: VanillaMerge, DgitImportUnpatched, ?)
 378             printdebug "branch_is_gdr  $walk ?-2-merge NO\n";
 379             return 0;
 380         }
 381         if (@parents>2) {
 382             # (gdr classification: ?)
 383             printdebug "branch_is_gdr  $walk ?-octopus NO\n";
 384             return 0;
 385         }
 386         if (!@parents) {
 387             printdebug "branch_is_gdr  $walk origin\n";
 388             return 0;
 389         }
 390         if ($get_patches->($walk) ne $tip_patches) {
 391             # Our parent added, removed, or edited patches, and wasn't
 392             # a gdr make-patches commit.  gdr make-patches probably
 393             # won't do that well, then.
 394             # (gdr classification of parent: AddPatches or ?)
 395             printdebug "branch_is_gdr  $walk ?-patches NO\n";
 396             return 0;
 397         }
 398         if ($tip_patches eq '' and
 399             !defined git_cat_file "$walk:debian") {
 400             # (gdr classification of parent: BreakwaterStart
 401             printdebug "branch_is_gdr  $walk unmarked BreakwaterStart YES\n";
 402             return 1;
 403         }
 404         # (gdr classification: Upstream Packaging Mixed Changelog)
 405         printdebug "branch_is_gdr  $walk plain\n"
 406             if $debuglevel >= 2;
 407         $walk = $parents[0];
 408     }
 409 }
 410
 411 #---------- remote protocol support, common ----------
 412
 413 # remote push initiator/responder protocol:
 414 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 415 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 416 #  < dgit-remote-push-ready <actual-proto-vsn>
 417 #
 418 # occasionally:
 419 #
 420 #  > progress NBYTES
 421 #  [NBYTES message]
 422 #
 423 #  > supplementary-message NBYTES          # $protovsn >= 3
 424 #  [NBYTES message]
 425 #
 426 # main sequence:
 427 #
 428 #  > file parsed-changelog
 429 #  [indicates that output of dpkg-parsechangelog follows]
 430 #  > data-block NBYTES
 431 #  > [NBYTES bytes of data (no newline)]
 432 #  [maybe some more blocks]
 433 #  > data-end
 434 #
 435 #  > file dsc
 436 #  [etc]
 437 #
 438 #  > file changes
 439 #  [etc]
 440 #
 441 #  > param head DGIT-VIEW-HEAD
 442 #  > param csuite SUITE
 443 #  > param tagformat old|new
 444 #  > param maint-view MAINT-VIEW-HEAD
 445 #
 446 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 447 #  > file buildinfo                             # for buildinfos to sign
 448 #
 449 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 450 #                                     # goes into tag, for replay prevention
 451 #
 452 #  > want signed-tag
 453 #  [indicates that signed tag is wanted]
 454 #  < data-block NBYTES
 455 #  < [NBYTES bytes of data (no newline)]
 456 #  [maybe some more blocks]
 457 #  < data-end
 458 #  < files-end
 459 #
 460 #  > want signed-dsc-changes
 461 #  < data-block NBYTES    [transfer of signed dsc]
 462 #  [etc]
 463 #  < data-block NBYTES    [transfer of signed changes]
 464 #  [etc]
 465 #  < data-block NBYTES    [transfer of each signed buildinfo
 466 #  [etc]                   same number and order as "file buildinfo"]
 467 #  ...
 468 #  < files-end
 469 #
 470 #  > complete
 471
 472 our $i_child_pid;
 473
 474 sub i_child_report () {
 475     # Sees if our child has died, and reap it if so.  Returns a string
 476     # describing how it died if it failed, or undef otherwise.
 477     return undef unless $i_child_pid;
 478     my $got = waitpid $i_child_pid, WNOHANG;
 479     return undef if $got <= 0;
 480     die unless $got == $i_child_pid;
 481     $i_child_pid = undef;
 482     return undef unless $?;
 483     return f_ "build host child %s", waitstatusmsg();
 484 }
 485
 486 sub badproto ($$) {
 487     my ($fh, $m) = @_;
 488     fail f_ "connection lost: %s", $! if $fh->error;
 489     fail f_ "protocol violation; %s not expected", $m;
 490 }
 491
 492 sub badproto_badread ($$) {
 493     my ($fh, $wh) = @_;
 494     fail f_ "connection lost: %s", $! if $!;
 495     my $report = i_child_report();
 496     fail $report if defined $report;
 497     badproto $fh, f_ "eof (reading %s)", $wh;
 498 }
 499
 500 sub protocol_expect (&$) {
 501     my ($match, $fh) = @_;
 502     local $_;
 503     $_ = <$fh>;
 504     defined && chomp or badproto_badread $fh, __ "protocol message";
 505     if (wantarray) {
 506         my @r = &$match;
 507         return @r if @r;
 508     } else {
 509         my $r = &$match;
 510         return $r if $r;
 511     }
 512     badproto $fh, f_ "\`%s'", $_;
 513 }
 514
 515 sub protocol_send_file ($$) {
 516     my ($fh, $ourfn) = @_;
 517     open PF, "<", $ourfn or die "$ourfn: $!";
 518     for (;;) {
 519         my $d;
 520         my $got = read PF, $d, 65536;
 521         die "$ourfn: $!" unless defined $got;
 522         last if !$got;
 523         print $fh "data-block ".length($d)."\n" or confess $!;
 524         print $fh $d or confess $!;
 525     }
 526     PF->error and die "$ourfn $!";
 527     print $fh "data-end\n" or confess $!;
 528     close PF;
 529 }
 530
 531 sub protocol_read_bytes ($$) {
 532     my ($fh, $nbytes) = @_;
 533     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, __ "bad byte count";
 534     my $d;
 535     my $got = read $fh, $d, $nbytes;
 536     $got==$nbytes or badproto_badread $fh, __ "data block";
 537     return $d;
 538 }
 539
 540 sub protocol_receive_file ($$) {
 541     my ($fh, $ourfn) = @_;
 542     printdebug "() $ourfn\n";
 543     open PF, ">", $ourfn or die "$ourfn: $!";
 544     for (;;) {
 545         my ($y,$l) = protocol_expect {
 546             m/^data-block (.*)$/ ? (1,$1) :
 547             m/^data-end$/ ? (0,) :
 548             ();
 549         } $fh;
 550         last unless $y;
 551         my $d = protocol_read_bytes $fh, $l;
 552         print PF $d or confess $!;
 553     }
 554     close PF or confess $!;
 555 }
 556
 557 #---------- remote protocol support, responder ----------
 558
 559 sub responder_send_command ($) {
 560     my ($command) = @_;
 561     return unless $we_are_responder;
 562     # called even without $we_are_responder
 563     printdebug ">> $command\n";
 564     print PO $command, "\n" or confess $!;
 565 }
 566
 567 sub responder_send_file ($$) {
 568     my ($keyword, $ourfn) = @_;
 569     return unless $we_are_responder;
 570     printdebug "]] $keyword $ourfn\n";
 571     responder_send_command "file $keyword";
 572     protocol_send_file \*PO, $ourfn;
 573 }
 574
 575 sub responder_receive_files ($@) {
 576     my ($keyword, @ourfns) = @_;
 577     die unless $we_are_responder;
 578     printdebug "[[ $keyword @ourfns\n";
 579     responder_send_command "want $keyword";
 580     foreach my $fn (@ourfns) {
 581         protocol_receive_file \*PI, $fn;
 582     }
 583     printdebug "[[\$\n";
 584     protocol_expect { m/^files-end$/ } \*PI;
 585 }
 586
 587 #---------- remote protocol support, initiator ----------
 588
 589 sub initiator_expect (&) {
 590     my ($match) = @_;
 591     protocol_expect { &$match } \*RO;
 592 }
 593
 594 #---------- end remote code ----------
 595
 596 sub progress {
 597     if ($we_are_responder) {
 598         my $m = join '', @_;
 599         responder_send_command "progress ".length($m) or confess $!;
 600         print PO $m or confess $!;
 601     } else {
 602         print @_, "\n";
 603     }
 604 }
 605
 606 our $ua;
 607
 608 sub url_get {
 609     if (!$ua) {
 610         $ua = LWP::UserAgent->new();
 611         $ua->env_proxy;
 612     }
 613     my $what = $_[$#_];
 614     progress "downloading $what...";
 615     my $r = $ua->get(@_) or confess $!;
 616     return undef if $r->code == 404;
 617     $r->is_success or fail f_ "failed to fetch %s: %s",
 618         $what, $r->status_line;
 619     return $r->decoded_content(charset => 'none');
 620 }
 621
 622 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 623
 624 sub act_local () { return $dryrun_level <= 1; }
 625 sub act_scary () { return !$dryrun_level; }
 626
 627 sub printdone {
 628     if (!$dryrun_level) {
 629         progress f_ "%s ok: %s", $us, "@_";
 630     } else {
 631         progress f_ "would be ok: %s (but dry run only)", "@_";
 632     }
 633 }
 634
 635 sub dryrun_report {
 636     printcmd(\*STDERR,$debugprefix."#",@_);
 637 }
 638
 639 sub runcmd_ordryrun {
 640     if (act_scary()) {
 641         runcmd @_;
 642     } else {
 643         dryrun_report @_;
 644     }
 645 }
 646
 647 sub runcmd_ordryrun_local {
 648     if (act_local()) {
 649         runcmd @_;
 650     } else {
 651         dryrun_report @_;
 652     }
 653 }
 654
 655 our $helpmsg = i_ <<END;
 656 main usages:
 657   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 658   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 659   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 660   dgit [dgit-opts] sbuild [sbuild-opts]
 661   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
 662   dgit [dgit-opts] push [dgit-opts] [suite]
 663   dgit [dgit-opts] push-source [dgit-opts] [suite]
 664   dgit [dgit-opts] rpush build-host:build-dir ...
 665 important dgit options:
 666   -k<keyid>           sign tag and package with <keyid> instead of default
 667   --dry-run -n        do not change anything, but go through the motions
 668   --damp-run -L       like --dry-run but make local changes, without signing
 669   --new -N            allow introducing a new package
 670   --debug -D          increase debug level
 671   -c<name>=<value>    set git config option (used directly by dgit too)
 672 END
 673
 674 our $later_warning_msg = i_ <<END;
 675 Perhaps the upload is stuck in incoming.  Using the version from git.
 676 END
 677
 678 sub badusage {
 679     print STDERR f_ "%s: %s\n%s", $us, "@_", __ $helpmsg or confess $!;
 680     finish 8;
 681 }
 682
 683 sub nextarg {
 684     @ARGV or badusage __ "too few arguments";
 685     return scalar shift @ARGV;
 686 }
 687
 688 sub pre_help () {
 689     not_necessarily_a_tree();
 690 }
 691 sub cmd_help () {
 692     print __ $helpmsg or confess $!;
 693     finish 0;
 694 }
 695
 696 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 697
 698 our %defcfg = ('dgit.default.distro' => 'debian',
 699                'dgit.default.default-suite' => 'unstable',
 700                'dgit.default.old-dsc-distro' => 'debian',
 701                'dgit-suite.*-security.distro' => 'debian-security',
 702                'dgit.default.username' => '',
 703                'dgit.default.archive-query-default-component' => 'main',
 704                'dgit.default.ssh' => 'ssh',
 705                'dgit.default.archive-query' => 'madison:',
 706                'dgit.default.sshpsql-dbname' => 'service=projectb',
 707                'dgit.default.aptget-components' => 'main',
 708                'dgit.default.dgit-tag-format' => 'new,old,maint',
 709                'dgit.default.source-only-uploads' => 'ok',
 710                'dgit.dsc-url-proto-ok.http'    => 'true',
 711                'dgit.dsc-url-proto-ok.https'   => 'true',
 712                'dgit.dsc-url-proto-ok.git'     => 'true',
 713                'dgit.vcs-git.suites',          => 'sid', # ;-separated
 714                'dgit.default.dsc-url-proto-ok' => 'false',
 715                # old means "repo server accepts pushes with old dgit tags"
 716                # new means "repo server accepts pushes with new dgit tags"
 717                # maint means "repo server accepts split brain pushes"
 718                # hist means "repo server may have old pushes without new tag"
 719                #   ("hist" is implied by "old")
 720                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 721                'dgit-distro.debian.git-check' => 'url',
 722                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 723                'dgit-distro.debian.new-private-pushers' => 't',
 724                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
 725                'dgit-distro.debian/push.git-url' => '',
 726                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 727                'dgit-distro.debian/push.git-user-force' => 'dgit',
 728                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 729                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 730                'dgit-distro.debian/push.git-create' => 'true',
 731                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 732  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 733 # 'dgit-distro.debian.archive-query-tls-key',
 734 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 735 # ^ this does not work because curl is broken nowadays
 736 # Fixing #790093 properly will involve providing providing the key
 737 # in some pacagke and maybe updating these paths.
 738 #
 739 # 'dgit-distro.debian.archive-query-tls-curl-args',
 740 #   '--ca-path=/etc/ssl/ca-debian',
 741 # ^ this is a workaround but works (only) on DSA-administered machines
 742                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 743                'dgit-distro.debian.git-url-suffix' => '',
 744                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 745                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 746  'dgit-distro.debian-security.archive-query' => 'aptget:',
 747  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 748  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 749  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 750  'dgit-distro.debian-security.nominal-distro' => 'debian',
 751  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 752  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 753                'dgit-distro.ubuntu.git-check' => 'false',
 754  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 755                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 756                'dgit-distro.test-dummy.username' => "alice",
 757                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 758                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 759                'dgit-distro.test-dummy.git-url' => "$td/git",
 760                'dgit-distro.test-dummy.git-host' => "git",
 761                'dgit-distro.test-dummy.git-path' => "$td/git",
 762                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 763                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 764                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 765                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 766                );
 767
 768 our %gitcfgs;
 769 our @gitcfgsources = qw(cmdline local global system);
 770 our $invoked_in_git_tree = 1;
 771
 772 sub git_slurp_config () {
 773     # This algoritm is a bit subtle, but this is needed so that for
 774     # options which we want to be single-valued, we allow the
 775     # different config sources to override properly.  See #835858.
 776     foreach my $src (@gitcfgsources) {
 777         next if $src eq 'cmdline';
 778         # we do this ourselves since git doesn't handle it
 779
 780         $gitcfgs{$src} = git_slurp_config_src $src;
 781     }
 782 }
 783
 784 sub git_get_config ($) {
 785     my ($c) = @_;
 786     foreach my $src (@gitcfgsources) {
 787         my $l = $gitcfgs{$src}{$c};
 788         confess "internal error ($l $c)" if $l && !ref $l;
 789         printdebug"C $c ".(defined $l ?
 790                            join " ", map { messagequote "'$_'" } @$l :
 791                            "undef")."\n"
 792             if $debuglevel >= 4;
 793         $l or next;
 794         @$l==1 or badcfg
 795             f_ "multiple values for %s (in %s git config)", $c, $src
 796             if @$l > 1;
 797         $l->[0] =~ m/\n/ and badcfg f_
 798  "value for config option %s (in %s git config) contains newline(s)!",
 799             $c, $src;
 800         return $l->[0];
 801     }
 802     return undef;
 803 }
 804
 805 sub cfg {
 806     foreach my $c (@_) {
 807         return undef if $c =~ /RETURN-UNDEF/;
 808         printdebug "C? $c\n" if $debuglevel >= 5;
 809         my $v = git_get_config($c);
 810         return $v if defined $v;
 811         my $dv = $defcfg{$c};
 812         if (defined $dv) {
 813             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 814             return $dv;
 815         }
 816     }
 817     badcfg f_
 818         "need value for one of: %s\n".
 819         "%s: distro or suite appears not to be (properly) supported",
 820         "@_", $us;
 821 }
 822
 823 sub not_necessarily_a_tree () {
 824     # needs to be called from pre_*
 825     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 826     $invoked_in_git_tree = 0;
 827 }
 828
 829 sub access_basedistro__noalias () {
 830     if (defined $idistro) {
 831         return $idistro;
 832     } else {
 833         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 834         return $def if defined $def;
 835         foreach my $src (@gitcfgsources, 'internal') {
 836             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 837             next unless $kl;
 838             foreach my $k (keys %$kl) {
 839                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 840                 my $dpat = $1;
 841                 next unless match_glob $dpat, $isuite;
 842                 return $kl->{$k};
 843             }
 844         }
 845         return cfg("dgit.default.distro");
 846     }
 847 }
 848
 849 sub access_basedistro () {
 850     my $noalias = access_basedistro__noalias();
 851     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 852     return $canon // $noalias;
 853 }
 854
 855 sub access_nomdistro () {
 856     my $base = access_basedistro();
 857     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 858     $r =~ m/^$distro_re$/ or badcfg
 859         f_ "bad syntax for (nominal) distro \`%s' (does not match %s)",
 860         $r, "/^$distro_re$/";
 861     return $r;
 862 }
 863
 864 sub access_quirk () {
 865     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 866     my $basedistro = access_basedistro();
 867     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 868                               'RETURN-UNDEF');
 869     if (defined $backports_quirk) {
 870         my $re = $backports_quirk;
 871         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 872         $re =~ s/\*/.*/g;
 873         $re =~ s/\%/([-0-9a-z_]+)/
 874             or $re =~ m/[()]/ or badcfg __ "backports-quirk needs \% or ( )";
 875         if ($isuite =~ m/^$re$/) {
 876             return ('backports',"$basedistro-backports",$1);
 877         }
 878     }
 879     return ('none',undef);
 880 }
 881
 882 our $access_forpush;
 883
 884 sub parse_cfg_bool ($$$) {
 885     my ($what,$def,$v) = @_;
 886     $v //= $def;
 887     return
 888         $v =~ m/^[ty1]/ ? 1 :
 889         $v =~ m/^[fn0]/ ? 0 :
 890         badcfg f_ "%s needs t (true, y, 1) or f (false, n, 0) not \`%s'",
 891             $what, $v;
 892 }
 893
 894 sub access_forpush_config () {
 895     my $d = access_basedistro();
 896
 897     return 1 if
 898         $new_package &&
 899         parse_cfg_bool('new-private-pushers', 0,
 900                        cfg("dgit-distro.$d.new-private-pushers",
 901                            'RETURN-UNDEF'));
 902
 903     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 904     $v //= 'a';
 905     return
 906         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 907         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 908         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 909         badcfg __
 910             "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 911 }
 912
 913 sub access_forpush () {
 914     $access_forpush //= access_forpush_config();
 915     return $access_forpush;
 916 }
 917
 918 sub pushing () {
 919     confess +(__ 'internal error').' '.Dumper($access_forpush)," ?" if
 920         defined $access_forpush and !$access_forpush;
 921     badcfg __ "pushing but distro is configured readonly"
 922         if access_forpush_config() eq '0';
 923     $access_forpush = 1;
 924     $supplementary_message = __ <<'END' unless $we_are_responder;
 925 Push failed, before we got started.
 926 You can retry the push, after fixing the problem, if you like.
 927 END
 928     parseopts_late_defaults();
 929 }
 930
 931 sub notpushing () {
 932     parseopts_late_defaults();
 933 }
 934
 935 sub supplementary_message ($) {
 936     my ($msg) = @_;
 937     if (!$we_are_responder) {
 938         $supplementary_message = $msg;
 939         return;
 940     } elsif ($protovsn >= 3) {
 941         responder_send_command "supplementary-message ".length($msg)
 942             or confess $!;
 943         print PO $msg or confess $!;
 944     }
 945 }
 946
 947 sub access_distros () {
 948     # Returns list of distros to try, in order
 949     #
 950     # We want to try:
 951     #    0. `instead of' distro name(s) we have been pointed to
 952     #    1. the access_quirk distro, if any
 953     #    2a. the user's specified distro, or failing that  } basedistro
 954     #    2b. the distro calculated from the suite          }
 955     my @l = access_basedistro();
 956
 957     my (undef,$quirkdistro) = access_quirk();
 958     unshift @l, $quirkdistro;
 959     unshift @l, $instead_distro;
 960     @l = grep { defined } @l;
 961
 962     push @l, access_nomdistro();
 963
 964     if (access_forpush()) {
 965         @l = map { ("$_/push", $_) } @l;
 966     }
 967     @l;
 968 }
 969
 970 sub access_cfg_cfgs (@) {
 971     my (@keys) = @_;
 972     my @cfgs;
 973     # The nesting of these loops determines the search order.  We put
 974     # the key loop on the outside so that we search all the distros
 975     # for each key, before going on to the next key.  That means that
 976     # if access_cfg is called with a more specific, and then a less
 977     # specific, key, an earlier distro can override the less specific
 978     # without necessarily overriding any more specific keys.  (If the
 979     # distro wants to override the more specific keys it can simply do
 980     # so; whereas if we did the loop the other way around, it would be
 981     # impossible to for an earlier distro to override a less specific
 982     # key but not the more specific ones without restating the unknown
 983     # values of the more specific keys.
 984     my @realkeys;
 985     my @rundef;
 986     # We have to deal with RETURN-UNDEF specially, so that we don't
 987     # terminate the search prematurely.
 988     foreach (@keys) {
 989         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 990         push @realkeys, $_
 991     }
 992     foreach my $d (access_distros()) {
 993         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 994     }
 995     push @cfgs, map { "dgit.default.$_" } @realkeys;
 996     push @cfgs, @rundef;
 997     return @cfgs;
 998 }
 999
1000 sub access_cfg (@) {
1001     my (@keys) = @_;
1002     my (@cfgs) = access_cfg_cfgs(@keys);
1003     my $value = cfg(@cfgs);
1004     return $value;
1005 }
1006
1007 sub access_cfg_bool ($$) {
1008     my ($def, @keys) = @_;
1009     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
1010 }
1011
1012 sub string_to_ssh ($) {
1013     my ($spec) = @_;
1014     if ($spec =~ m/\s/) {
1015         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
1016     } else {
1017         return ($spec);
1018     }
1019 }
1020
1021 sub access_cfg_ssh () {
1022     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
1023     if (!defined $gitssh) {
1024         return @ssh;
1025     } else {
1026         return string_to_ssh $gitssh;
1027     }
1028 }
1029
1030 sub access_runeinfo ($) {
1031     my ($info) = @_;
1032     return ": dgit ".access_basedistro()." $info ;";
1033 }
1034
1035 sub access_someuserhost ($) {
1036     my ($some) = @_;
1037     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
1038     defined($user) && length($user) or
1039         $user = access_cfg("$some-user",'username');
1040     my $host = access_cfg("$some-host");
1041     return length($user) ? "$user\@$host" : $host;
1042 }
1043
1044 sub access_gituserhost () {
1045     return access_someuserhost('git');
1046 }
1047
1048 sub access_giturl (;$) {
1049     my ($optional) = @_;
1050     my $url = access_cfg('git-url','RETURN-UNDEF');
1051     my $suffix;
1052     if (!length $url) {
1053         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
1054         return undef unless defined $proto;
1055         $url =
1056             $proto.
1057             access_gituserhost().
1058             access_cfg('git-path');
1059     } else {
1060         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
1061     }
1062     $suffix //= '.git';
1063     return "$url/$package$suffix";
1064 }
1065
1066 sub commit_getclogp ($) {
1067     # Returns the parsed changelog hashref for a particular commit
1068     my ($objid) = @_;
1069     our %commit_getclogp_memo;
1070     my $memo = $commit_getclogp_memo{$objid};
1071     return $memo if $memo;
1072
1073     my $mclog = dgit_privdir()."clog";
1074     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
1075         "$objid:debian/changelog";
1076     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
1077 }
1078
1079 sub parse_dscdata () {
1080     my $dscfh = new IO::File \$dscdata, '<' or confess $!;
1081     printdebug Dumper($dscdata) if $debuglevel>1;
1082     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1083     printdebug Dumper($dsc) if $debuglevel>1;
1084 }
1085
1086 our %rmad;
1087
1088 sub archive_query ($;@) {
1089     my ($method) = shift @_;
1090     fail __ "this operation does not support multiple comma-separated suites"
1091         if $isuite =~ m/,/;
1092     my $query = access_cfg('archive-query','RETURN-UNDEF');
1093     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1094     my $proto = $1;
1095     my $data = $'; #';
1096     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1097 }
1098
1099 sub archive_query_prepend_mirror {
1100     my $m = access_cfg('mirror');
1101     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1102 }
1103
1104 sub pool_dsc_subpath ($$) {
1105     my ($vsn,$component) = @_; # $package is implict arg
1106     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1107     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1108 }
1109
1110 sub cfg_apply_map ($$$) {
1111     my ($varref, $what, $mapspec) = @_;
1112     return unless $mapspec;
1113
1114     printdebug "config $what EVAL{ $mapspec; }\n";
1115     $_ = $$varref;
1116     eval "package Dgit::Config; $mapspec;";
1117     die $@ if $@;
1118     $$varref = $_;
1119 }
1120
1121 #---------- `ftpmasterapi' archive query method (nascent) ----------
1122
1123 sub archive_api_query_cmd ($) {
1124     my ($subpath) = @_;
1125     my @cmd = (@curl, qw(-sS));
1126     my $url = access_cfg('archive-query-url');
1127     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1128         my $host = $1;
1129         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1130         foreach my $key (split /\:/, $keys) {
1131             $key =~ s/\%HOST\%/$host/g;
1132             if (!stat $key) {
1133                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1134                 next;
1135             }
1136             fail f_ "config requested specific TLS key but do not know".
1137                     " how to get curl to use exactly that EE key (%s)",
1138                     $key;
1139 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1140 #           # Sadly the above line does not work because of changes
1141 #           # to gnutls.   The real fix for #790093 may involve
1142 #           # new curl options.
1143             last;
1144         }
1145         # Fixing #790093 properly will involve providing a value
1146         # for this on clients.
1147         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1148         push @cmd, split / /, $kargs if defined $kargs;
1149     }
1150     push @cmd, $url.$subpath;
1151     return @cmd;
1152 }
1153
1154 sub api_query ($$;$) {
1155     use JSON;
1156     my ($data, $subpath, $ok404) = @_;
1157     badcfg __ "ftpmasterapi archive query method takes no data part"
1158         if length $data;
1159     my @cmd = archive_api_query_cmd($subpath);
1160     my $url = $cmd[$#cmd];
1161     push @cmd, qw(-w %{http_code});
1162     my $json = cmdoutput @cmd;
1163     unless ($json =~ s/\d+\d+\d$//) {
1164         failedcmd_report_cmd undef, @cmd;
1165         fail __ "curl failed to print 3-digit HTTP code";
1166     }
1167     my $code = $&;
1168     return undef if $code eq '404' && $ok404;
1169     fail f_ "fetch of %s gave HTTP code %s", $url, $code
1170         unless $url =~ m#^file://# or $code =~ m/^2/;
1171     return decode_json($json);
1172 }
1173
1174 sub canonicalise_suite_ftpmasterapi {
1175     my ($proto,$data) = @_;
1176     my $suites = api_query($data, 'suites');
1177     my @matched;
1178     foreach my $entry (@$suites) {
1179         next unless grep {
1180             my $v = $entry->{$_};
1181             defined $v && $v eq $isuite;
1182         } qw(codename name);
1183         push @matched, $entry;
1184     }
1185     fail f_ "unknown suite %s, maybe -d would help", $isuite
1186         unless @matched;
1187     my $cn;
1188     eval {
1189         @matched==1 or die f_ "multiple matches for suite %s\n", $isuite;
1190         $cn = "$matched[0]{codename}";
1191         defined $cn or die f_ "suite %s info has no codename\n", $isuite;
1192         $cn =~ m/^$suite_re$/
1193             or die f_ "suite %s maps to bad codename\n", $isuite;
1194     };
1195     die +(__ "bad ftpmaster api response: ")."$@\n".Dumper(\@matched)
1196         if length $@;
1197     return $cn;
1198 }
1199
1200 sub archive_query_ftpmasterapi {
1201     my ($proto,$data) = @_;
1202     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1203     my @rows;
1204     my $digester = Digest::SHA->new(256);
1205     foreach my $entry (@$info) {
1206         eval {
1207             my $vsn = "$entry->{version}";
1208             my ($ok,$msg) = version_check $vsn;
1209             die f_ "bad version: %s\n", $msg unless $ok;
1210             my $component = "$entry->{component}";
1211             $component =~ m/^$component_re$/ or die __ "bad component";
1212             my $filename = "$entry->{filename}";
1213             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1214                 or die __ "bad filename";
1215             my $sha256sum = "$entry->{sha256sum}";
1216             $sha256sum =~ m/^[0-9a-f]+$/ or die __ "bad sha256sum";
1217             push @rows, [ $vsn, "/pool/$component/$filename",
1218                           $digester, $sha256sum ];
1219         };
1220         die +(__ "bad ftpmaster api response: ")."$@\n".Dumper($entry)
1221             if length $@;
1222     }
1223     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1224     return archive_query_prepend_mirror @rows;
1225 }
1226
1227 sub file_in_archive_ftpmasterapi {
1228     my ($proto,$data,$filename) = @_;
1229     my $pat = $filename;
1230     $pat =~ s/_/\\_/g;
1231     $pat = "%/$pat";
1232     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1233     my $info = api_query($data, "file_in_archive/$pat", 1);
1234 }
1235
1236 sub package_not_wholly_new_ftpmasterapi {
1237     my ($proto,$data,$pkg) = @_;
1238     my $info = api_query($data,"madison?package=${pkg}&f=json");
1239     return !!@$info;
1240 }
1241
1242 #---------- `aptget' archive query method ----------
1243
1244 our $aptget_base;
1245 our $aptget_releasefile;
1246 our $aptget_configpath;
1247
1248 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1249 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1250
1251 sub aptget_cache_clean {
1252     runcmd_ordryrun_local qw(sh -ec),
1253         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1254         'x', $aptget_base;
1255 }
1256
1257 sub aptget_lock_acquire () {
1258     my $lockfile = "$aptget_base/lock";
1259     open APTGET_LOCK, '>', $lockfile or confess "open $lockfile: $!";
1260     flock APTGET_LOCK, LOCK_EX or confess "lock $lockfile: $!";
1261 }
1262
1263 sub aptget_prep ($) {
1264     my ($data) = @_;
1265     return if defined $aptget_base;
1266
1267     badcfg __ "aptget archive query method takes no data part"
1268         if length $data;
1269
1270     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1271
1272     ensuredir $cache;
1273     ensuredir "$cache/dgit";
1274     my $cachekey =
1275         access_cfg('aptget-cachekey','RETURN-UNDEF')
1276         // access_nomdistro();
1277
1278     $aptget_base = "$cache/dgit/aptget";
1279     ensuredir $aptget_base;
1280
1281     my $quoted_base = $aptget_base;
1282     confess "$quoted_base contains bad chars, cannot continue"
1283         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1284
1285     ensuredir $aptget_base;
1286
1287     aptget_lock_acquire();
1288
1289     aptget_cache_clean();
1290
1291     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1292     my $sourceslist = "source.list#$cachekey";
1293
1294     my $aptsuites = $isuite;
1295     cfg_apply_map(\$aptsuites, 'suite map',
1296                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1297
1298     open SRCS, ">", "$aptget_base/$sourceslist" or confess $!;
1299     printf SRCS "deb-src %s %s %s\n",
1300         access_cfg('mirror'),
1301         $aptsuites,
1302         access_cfg('aptget-components')
1303         or confess $!;
1304
1305     ensuredir "$aptget_base/cache";
1306     ensuredir "$aptget_base/lists";
1307
1308     open CONF, ">", $aptget_configpath or confess $!;
1309     print CONF <<END;
1310 Debug::NoLocking "true";
1311 APT::Get::List-Cleanup "false";
1312 #clear APT::Update::Post-Invoke-Success;
1313 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1314 Dir::State::Lists "$quoted_base/lists";
1315 Dir::Etc::preferences "$quoted_base/preferences";
1316 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1317 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1318 END
1319
1320     foreach my $key (qw(
1321                         Dir::Cache
1322                         Dir::State
1323                         Dir::Cache::Archives
1324                         Dir::Etc::SourceParts
1325                         Dir::Etc::preferencesparts
1326                       )) {
1327         ensuredir "$aptget_base/$key";
1328         print CONF "$key \"$quoted_base/$key\";\n" or confess $!;
1329     };
1330
1331     my $oldatime = (time // confess $!) - 1;
1332     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1333         next unless stat_exists $oldlist;
1334         my ($mtime) = (stat _)[9];
1335         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1336     }
1337
1338     runcmd_ordryrun_local aptget_aptget(), qw(update);
1339
1340     my @releasefiles;
1341     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1342         next unless stat_exists $oldlist;
1343         my ($atime) = (stat _)[8];
1344         next if $atime == $oldatime;
1345         push @releasefiles, $oldlist;
1346     }
1347     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1348     @releasefiles = @inreleasefiles if @inreleasefiles;
1349     if (!@releasefiles) {
1350         fail f_ <<END, $isuite, $cache;
1351 apt seemed to not to update dgit's cached Release files for %s.
1352 (Perhaps %s
1353  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1354 END
1355     }
1356     confess "apt updated too many Release files (@releasefiles), erk"
1357         unless @releasefiles == 1;
1358
1359     ($aptget_releasefile) = @releasefiles;
1360 }
1361
1362 sub canonicalise_suite_aptget {
1363     my ($proto,$data) = @_;
1364     aptget_prep($data);
1365
1366     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1367
1368     foreach my $name (qw(Codename Suite)) {
1369         my $val = $release->{$name};
1370         if (defined $val) {
1371             printdebug "release file $name: $val\n";
1372             $val =~ m/^$suite_re$/o or fail f_
1373                 "Release file (%s) specifies intolerable %s",
1374                 $aptget_releasefile, $name;
1375             cfg_apply_map(\$val, 'suite rmap',
1376                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1377             return $val
1378         }
1379     }
1380     return $isuite;
1381 }
1382
1383 sub archive_query_aptget {
1384     my ($proto,$data) = @_;
1385     aptget_prep($data);
1386
1387     ensuredir "$aptget_base/source";
1388     foreach my $old (<$aptget_base/source/*.dsc>) {
1389         unlink $old or die "$old: $!";
1390     }
1391
1392     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1393     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1394     # avoids apt-get source failing with ambiguous error code
1395
1396     runcmd_ordryrun_local
1397         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1398         aptget_aptget(), qw(--download-only --only-source source), $package;
1399
1400     my @dscs = <$aptget_base/source/*.dsc>;
1401     fail __ "apt-get source did not produce a .dsc" unless @dscs;
1402     fail f_ "apt-get source produced several .dscs (%s)", "@dscs"
1403         unless @dscs==1;
1404
1405     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1406
1407     use URI::Escape;
1408     my $uri = "file://". uri_escape $dscs[0];
1409     $uri =~ s{\%2f}{/}gi;
1410     return [ (getfield $pre_dsc, 'Version'), $uri ];
1411 }
1412
1413 sub file_in_archive_aptget () { return undef; }
1414 sub package_not_wholly_new_aptget () { return undef; }
1415
1416 #---------- `dummyapicat' archive query method ----------
1417 # (untranslated, because this is for testing purposes etc.)
1418
1419 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1420 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1421
1422 sub dummycatapi_run_in_mirror ($@) {
1423     # runs $fn with FIA open onto rune
1424     my ($rune, $argl, $fn) = @_;
1425
1426     my $mirror = access_cfg('mirror');
1427     $mirror =~ s#^file://#/# or die "$mirror ?";
1428     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1429                qw(x), $mirror, @$argl);
1430     debugcmd "-|", @cmd;
1431     open FIA, "-|", @cmd or confess $!;
1432     my $r = $fn->();
1433     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1434     return $r;
1435 }
1436
1437 sub file_in_archive_dummycatapi ($$$) {
1438     my ($proto,$data,$filename) = @_;
1439     my @out;
1440     dummycatapi_run_in_mirror '
1441             find -name "$1" -print0 |
1442             xargs -0r sha256sum
1443     ', [$filename], sub {
1444         while (<FIA>) {
1445             chomp or die;
1446             printdebug "| $_\n";
1447             m/^(\w+)  (\S+)$/ or die "$_ ?";
1448             push @out, { sha256sum => $1, filename => $2 };
1449         }
1450     };
1451     return \@out;
1452 }
1453
1454 sub package_not_wholly_new_dummycatapi {
1455     my ($proto,$data,$pkg) = @_;
1456     dummycatapi_run_in_mirror "
1457             find -name ${pkg}_*.dsc
1458     ", [], sub {
1459         local $/ = undef;
1460         !!<FIA>;
1461     };
1462 }
1463
1464 #---------- `madison' archive query method ----------
1465
1466 sub archive_query_madison {
1467     return archive_query_prepend_mirror
1468         map { [ @$_[0..1] ] } madison_get_parse(@_);
1469 }
1470
1471 sub madison_get_parse {
1472     my ($proto,$data) = @_;
1473     die unless $proto eq 'madison';
1474     if (!length $data) {
1475         $data= access_cfg('madison-distro','RETURN-UNDEF');
1476         $data //= access_basedistro();
1477     }
1478     $rmad{$proto,$data,$package} ||= cmdoutput
1479         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1480     my $rmad = $rmad{$proto,$data,$package};
1481
1482     my @out;
1483     foreach my $l (split /\n/, $rmad) {
1484         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1485                   \s*( [^ \t|]+ )\s* \|
1486                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1487                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1488         $1 eq $package or die "$rmad $package ?";
1489         my $vsn = $2;
1490         my $newsuite = $3;
1491         my $component;
1492         if (defined $4) {
1493             $component = $4;
1494         } else {
1495             $component = access_cfg('archive-query-default-component');
1496         }
1497         $5 eq 'source' or die "$rmad ?";
1498         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1499     }
1500     return sort { -version_compare($a->[0],$b->[0]); } @out;
1501 }
1502
1503 sub canonicalise_suite_madison {
1504     # madison canonicalises for us
1505     my @r = madison_get_parse(@_);
1506     @r or fail f_
1507         "unable to canonicalise suite using package %s".
1508         " which does not appear to exist in suite %s;".
1509         " --existing-package may help",
1510         $package, $isuite;
1511     return $r[0][2];
1512 }
1513
1514 sub file_in_archive_madison { return undef; }
1515 sub package_not_wholly_new_madison { return undef; }
1516
1517 #---------- `sshpsql' archive query method ----------
1518 # (untranslated, because this is obsolete)
1519
1520 sub sshpsql ($$$) {
1521     my ($data,$runeinfo,$sql) = @_;
1522     if (!length $data) {
1523         $data= access_someuserhost('sshpsql').':'.
1524             access_cfg('sshpsql-dbname');
1525     }
1526     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1527     my ($userhost,$dbname) = ($`,$'); #';
1528     my @rows;
1529     my @cmd = (access_cfg_ssh, $userhost,
1530                access_runeinfo("ssh-psql $runeinfo").
1531                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1532                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1533     debugcmd "|",@cmd;
1534     open P, "-|", @cmd or confess $!;
1535     while (<P>) {
1536         chomp or die;
1537         printdebug(">|$_|\n");
1538         push @rows, $_;
1539     }
1540     $!=0; $?=0; close P or failedcmd @cmd;
1541     @rows or die;
1542     my $nrows = pop @rows;
1543     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1544     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1545     @rows = map { [ split /\|/, $_ ] } @rows;
1546     my $ncols = scalar @{ shift @rows };
1547     die if grep { scalar @$_ != $ncols } @rows;
1548     return @rows;
1549 }
1550
1551 sub sql_injection_check {
1552     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1553 }
1554
1555 sub archive_query_sshpsql ($$) {
1556     my ($proto,$data) = @_;
1557     sql_injection_check $isuite, $package;
1558     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1559         SELECT source.version, component.name, files.filename, files.sha256sum
1560           FROM source
1561           JOIN src_associations ON source.id = src_associations.source
1562           JOIN suite ON suite.id = src_associations.suite
1563           JOIN dsc_files ON dsc_files.source = source.id
1564           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1565           JOIN component ON component.id = files_archive_map.component_id
1566           JOIN files ON files.id = dsc_files.file
1567          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1568            AND source.source='$package'
1569            AND files.filename LIKE '%.dsc';
1570 END
1571     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1572     my $digester = Digest::SHA->new(256);
1573     @rows = map {
1574         my ($vsn,$component,$filename,$sha256sum) = @$_;
1575         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1576     } @rows;
1577     return archive_query_prepend_mirror @rows;
1578 }
1579
1580 sub canonicalise_suite_sshpsql ($$) {
1581     my ($proto,$data) = @_;
1582     sql_injection_check $isuite;
1583     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1584         SELECT suite.codename
1585           FROM suite where suite_name='$isuite' or codename='$isuite';
1586 END
1587     @rows = map { $_->[0] } @rows;
1588     fail "unknown suite $isuite" unless @rows;
1589     die "ambiguous $isuite: @rows ?" if @rows>1;
1590     return $rows[0];
1591 }
1592
1593 sub file_in_archive_sshpsql ($$$) { return undef; }
1594 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1595
1596 #---------- `dummycat' archive query method ----------
1597 # (untranslated, because this is for testing purposes etc.)
1598
1599 sub canonicalise_suite_dummycat ($$) {
1600     my ($proto,$data) = @_;
1601     my $dpath = "$data/suite.$isuite";
1602     if (!open C, "<", $dpath) {
1603         $!==ENOENT or die "$dpath: $!";
1604         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1605         return $isuite;
1606     }
1607     $!=0; $_ = <C>;
1608     chomp or die "$dpath: $!";
1609     close C;
1610     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1611     return $_;
1612 }
1613
1614 sub archive_query_dummycat ($$) {
1615     my ($proto,$data) = @_;
1616     canonicalise_suite();
1617     my $dpath = "$data/package.$csuite.$package";
1618     if (!open C, "<", $dpath) {
1619         $!==ENOENT or die "$dpath: $!";
1620         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1621         return ();
1622     }
1623     my @rows;
1624     while (<C>) {
1625         next if m/^\#/;
1626         next unless m/\S/;
1627         die unless chomp;
1628         printdebug "dummycat query $csuite $package $dpath | $_\n";
1629         my @row = split /\s+/, $_;
1630         @row==2 or die "$dpath: $_ ?";
1631         push @rows, \@row;
1632     }
1633     C->error and die "$dpath: $!";
1634     close C;
1635     return archive_query_prepend_mirror
1636         sort { -version_compare($a->[0],$b->[0]); } @rows;
1637 }
1638
1639 sub file_in_archive_dummycat () { return undef; }
1640 sub package_not_wholly_new_dummycat () { return undef; }
1641
1642 #---------- tag format handling ----------
1643 # (untranslated, because everything should be new tag format by now)
1644
1645 sub access_cfg_tagformats () {
1646     split /\,/, access_cfg('dgit-tag-format');
1647 }
1648
1649 sub access_cfg_tagformats_can_splitbrain () {
1650     my %y = map { $_ => 1 } access_cfg_tagformats;
1651     foreach my $needtf (qw(new maint)) {
1652         next if $y{$needtf};
1653         return 0;
1654     }
1655     return 1;
1656 }
1657
1658 sub need_tagformat ($$) {
1659     my ($fmt, $why) = @_;
1660     fail "need to use tag format $fmt ($why) but also need".
1661         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1662         " - no way to proceed"
1663         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1664     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1665 }
1666
1667 sub select_tagformat () {
1668     # sets $tagformatfn
1669     return if $tagformatfn && !$tagformat_want;
1670     die 'bug' if $tagformatfn && $tagformat_want;
1671     # ... $tagformat_want assigned after previous select_tagformat
1672
1673     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1674     printdebug "select_tagformat supported @supported\n";
1675
1676     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1677     printdebug "select_tagformat specified @$tagformat_want\n";
1678
1679     my ($fmt,$why,$override) = @$tagformat_want;
1680
1681     fail "target distro supports tag formats @supported".
1682         " but have to use $fmt ($why)"
1683         unless $override
1684             or grep { $_ eq $fmt } @supported;
1685
1686     $tagformat_want = undef;
1687     $tagformat = $fmt;
1688     $tagformatfn = ${*::}{"debiantag_$fmt"};
1689
1690     fail "trying to use unknown tag format \`$fmt' ($why) !"
1691         unless $tagformatfn;
1692 }
1693
1694 #---------- archive query entrypoints and rest of program ----------
1695
1696 sub canonicalise_suite () {
1697     return if defined $csuite;
1698     fail f_ "cannot operate on %s suite", $isuite if $isuite eq 'UNRELEASED';
1699     $csuite = archive_query('canonicalise_suite');
1700     if ($isuite ne $csuite) {
1701         progress f_ "canonical suite name for %s is %s", $isuite, $csuite;
1702     } else {
1703         progress f_ "canonical suite name is %s", $csuite;
1704     }
1705 }
1706
1707 sub get_archive_dsc () {
1708     canonicalise_suite();
1709     my @vsns = archive_query('archive_query');
1710     foreach my $vinfo (@vsns) {
1711         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1712         $dscurl = $vsn_dscurl;
1713         $dscdata = url_get($dscurl);
1714         if (!$dscdata) {
1715             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1716             next;
1717         }
1718         if ($digester) {
1719             $digester->reset();
1720             $digester->add($dscdata);
1721             my $got = $digester->hexdigest();
1722             $got eq $digest or
1723                 fail f_ "%s has hash %s but archive told us to expect %s",
1724                         $dscurl, $got, $digest;
1725         }
1726         parse_dscdata();
1727         my $fmt = getfield $dsc, 'Format';
1728         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1729             f_ "unsupported source format %s, sorry", $fmt;
1730
1731         $dsc_checked = !!$digester;
1732         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1733         return;
1734     }
1735     $dsc = undef;
1736     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1737 }
1738
1739 sub check_for_git ();
1740 sub check_for_git () {
1741     # returns 0 or 1
1742     my $how = access_cfg('git-check');
1743     if ($how eq 'ssh-cmd') {
1744         my @cmd =
1745             (access_cfg_ssh, access_gituserhost(),
1746              access_runeinfo("git-check $package").
1747              " set -e; cd ".access_cfg('git-path').";".
1748              " if test -d $package.git; then echo 1; else echo 0; fi");
1749         my $r= cmdoutput @cmd;
1750         if (defined $r and $r =~ m/^divert (\w+)$/) {
1751             my $divert=$1;
1752             my ($usedistro,) = access_distros();
1753             # NB that if we are pushing, $usedistro will be $distro/push
1754             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1755             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1756             progress f_ "diverting to %s (using config for %s)",
1757                         $divert, $instead_distro;
1758             return check_for_git();
1759         }
1760         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1761         return $r+0;
1762     } elsif ($how eq 'url') {
1763         my $prefix = access_cfg('git-check-url','git-url');
1764         my $suffix = access_cfg('git-check-suffix','git-suffix',
1765                                 'RETURN-UNDEF') // '.git';
1766         my $url = "$prefix/$package$suffix";
1767         my @cmd = (@curl, qw(-sS -I), $url);
1768         my $result = cmdoutput @cmd;
1769         $result =~ s/^\S+ 200 .*\n\r?\n//;
1770         # curl -sS -I with https_proxy prints
1771         # HTTP/1.0 200 Connection established
1772         $result =~ m/^\S+ (404|200) /s or
1773             fail +(__ "unexpected results from git check query - ").
1774                 Dumper($prefix, $result);
1775         my $code = $1;
1776         if ($code eq '404') {
1777             return 0;
1778         } elsif ($code eq '200') {
1779             return 1;
1780         } else {
1781             die;
1782         }
1783     } elsif ($how eq 'true') {
1784         return 1;
1785     } elsif ($how eq 'false') {
1786         return 0;
1787     } else {
1788         badcfg f_ "unknown git-check \`%s'", $how;
1789     }
1790 }
1791
1792 sub create_remote_git_repo () {
1793     my $how = access_cfg('git-create');
1794     if ($how eq 'ssh-cmd') {
1795         runcmd_ordryrun
1796             (access_cfg_ssh, access_gituserhost(),
1797              access_runeinfo("git-create $package").
1798              "set -e; cd ".access_cfg('git-path').";".
1799              " cp -a _template $package.git");
1800     } elsif ($how eq 'true') {
1801         # nothing to do
1802     } else {
1803         badcfg f_ "unknown git-create \`%s'", $how;
1804     }
1805 }
1806
1807 our ($dsc_hash,$lastpush_mergeinput);
1808 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1809
1810
1811 sub prep_ud () {
1812     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1813     $playground = fresh_playground 'dgit/unpack';
1814 }
1815
1816 sub mktree_in_ud_here () {
1817     playtree_setup $gitcfgs{local};
1818 }
1819
1820 sub git_write_tree () {
1821     my $tree = cmdoutput @git, qw(write-tree);
1822     $tree =~ m/^\w+$/ or die "$tree ?";
1823     return $tree;
1824 }
1825
1826 sub git_add_write_tree () {
1827     runcmd @git, qw(add -Af .);
1828     return git_write_tree();
1829 }
1830
1831 sub remove_stray_gits ($) {
1832     my ($what) = @_;
1833     my @gitscmd = qw(find -name .git -prune -print0);
1834     debugcmd "|",@gitscmd;
1835     open GITS, "-|", @gitscmd or confess $!;
1836     {
1837         local $/="\0";
1838         while (<GITS>) {
1839             chomp or die;
1840             print STDERR f_ "%s: warning: removing from %s: %s\n",
1841                 $us, $what, (messagequote $_);
1842             rmtree $_;
1843         }
1844     }
1845     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1846 }
1847
1848 sub mktree_in_ud_from_only_subdir ($;$) {
1849     my ($what,$raw) = @_;
1850     # changes into the subdir
1851
1852     my (@dirs) = <*/.>;
1853     confess "expected one subdir but found @dirs ?" unless @dirs==1;
1854     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1855     my $dir = $1;
1856     changedir $dir;
1857
1858     remove_stray_gits($what);
1859     mktree_in_ud_here();
1860     if (!$raw) {
1861         my ($format, $fopts) = get_source_format();
1862         if (madformat($format)) {
1863             rmtree '.pc';
1864         }
1865     }
1866
1867     my $tree=git_add_write_tree();
1868     return ($tree,$dir);
1869 }
1870
1871 our @files_csum_info_fields =
1872     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1873      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1874      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1875
1876 sub dsc_files_info () {
1877     foreach my $csumi (@files_csum_info_fields) {
1878         my ($fname, $module, $method) = @$csumi;
1879         my $field = $dsc->{$fname};
1880         next unless defined $field;
1881         eval "use $module; 1;" or die $@;
1882         my @out;
1883         foreach (split /\n/, $field) {
1884             next unless m/\S/;
1885             m/^(\w+) (\d+) (\S+)$/ or
1886                 fail f_ "could not parse .dsc %s line \`%s'", $fname, $_;
1887             my $digester = eval "$module"."->$method;" or die $@;
1888             push @out, {
1889                 Hash => $1,
1890                 Bytes => $2,
1891                 Filename => $3,
1892                 Digester => $digester,
1893             };
1894         }
1895         return @out;
1896     }
1897     fail f_ "missing any supported Checksums-* or Files field in %s",
1898             $dsc->get_option('name');
1899 }
1900
1901 sub dsc_files () {
1902     map { $_->{Filename} } dsc_files_info();
1903 }
1904
1905 sub files_compare_inputs (@) {
1906     my $inputs = \@_;
1907     my %record;
1908     my %fchecked;
1909
1910     my $showinputs = sub {
1911         return join "; ", map { $_->get_option('name') } @$inputs;
1912     };
1913
1914     foreach my $in (@$inputs) {
1915         my $expected_files;
1916         my $in_name = $in->get_option('name');
1917
1918         printdebug "files_compare_inputs $in_name\n";
1919
1920         foreach my $csumi (@files_csum_info_fields) {
1921             my ($fname) = @$csumi;
1922             printdebug "files_compare_inputs $in_name $fname\n";
1923
1924             my $field = $in->{$fname};
1925             next unless defined $field;
1926
1927             my @files;
1928             foreach (split /\n/, $field) {
1929                 next unless m/\S/;
1930
1931                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1932                     fail "could not parse $in_name $fname line \`$_'";
1933
1934                 printdebug "files_compare_inputs $in_name $fname $f\n";
1935
1936                 push @files, $f;
1937
1938                 my $re = \ $record{$f}{$fname};
1939                 if (defined $$re) {
1940                     $fchecked{$f}{$in_name} = 1;
1941                     $$re eq $info or
1942                         fail f_
1943               "hash or size of %s varies in %s fields (between: %s)",
1944                                  $f, $fname, $showinputs->();
1945                 } else {
1946                     $$re = $info;
1947                 }
1948             }
1949             @files = sort @files;
1950             $expected_files //= \@files;
1951             "@$expected_files" eq "@files" or
1952                 fail f_ "file list in %s varies between hash fields!",
1953                         $in_name;
1954         }
1955         $expected_files or
1956             fail f_ "%s has no files list field(s)", $in_name;
1957     }
1958     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1959         if $debuglevel>=2;
1960
1961     grep { keys %$_ == @$inputs-1 } values %fchecked
1962         or fail f_ "no file appears in all file lists (looked in: %s)",
1963                    $showinputs->();
1964 }
1965
1966 sub is_orig_file_in_dsc ($$) {
1967     my ($f, $dsc_files_info) = @_;
1968     return 0 if @$dsc_files_info <= 1;
1969     # One file means no origs, and the filename doesn't have a "what
1970     # part of dsc" component.  (Consider versions ending `.orig'.)
1971     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1972     return 1;
1973 }
1974
1975 # This function determines whether a .changes file is source-only from
1976 # the point of view of dak.  Thus, it permits *_source.buildinfo
1977 # files.
1978 #
1979 # It does not, however, permit any other buildinfo files.  After a
1980 # source-only upload, the buildds will try to upload files like
1981 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1982 # named like this in their (otherwise) source-only upload, the uploads
1983 # of the buildd can be rejected by dak.  Fixing the resultant
1984 # situation can require manual intervention.  So we block such
1985 # .buildinfo files when the user tells us to perform a source-only
1986 # upload (such as when using the push-source subcommand with the -C
1987 # option, which calls this function).
1988 #
1989 # Note, though, that when dgit is told to prepare a source-only
1990 # upload, such as when subcommands like build-source and push-source
1991 # without -C are used, dgit has a more restrictive notion of
1992 # source-only .changes than dak: such uploads will never include
1993 # *_source.buildinfo files.  This is because there is no use for such
1994 # files when using a tool like dgit to produce the source package, as
1995 # dgit ensures the source is identical to git HEAD.
1996 sub test_source_only_changes ($) {
1997     my ($changes) = @_;
1998     foreach my $l (split /\n/, getfield $changes, 'Files') {
1999         $l =~ m/\S+$/ or next;
2000         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
2001         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
2002             print f_ "purportedly source-only changes polluted by %s\n", $&;
2003             return 0;
2004         }
2005     }
2006     return 1;
2007 }
2008
2009 sub changes_update_origs_from_dsc ($$$$) {
2010     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
2011     my %changes_f;
2012     printdebug "checking origs needed ($upstreamvsn)...\n";
2013     $_ = getfield $changes, 'Files';
2014     m/^\w+ \d+ (\S+ \S+) \S+$/m or
2015         fail __ "cannot find section/priority from .changes Files field";
2016     my $placementinfo = $1;
2017     my %changed;
2018     printdebug "checking origs needed placement '$placementinfo'...\n";
2019     foreach my $l (split /\n/, getfield $dsc, 'Files') {
2020         $l =~ m/\S+$/ or next;
2021         my $file = $&;
2022         printdebug "origs $file | $l\n";
2023         next unless is_orig_file_of_vsn $file, $upstreamvsn;
2024         printdebug "origs $file is_orig\n";
2025         my $have = archive_query('file_in_archive', $file);
2026         if (!defined $have) {
2027             print STDERR __ <<END;
2028 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
2029 END
2030             return;
2031         }
2032         my $found_same = 0;
2033         my @found_differ;
2034         printdebug "origs $file \$#\$have=$#$have\n";
2035         foreach my $h (@$have) {
2036             my $same = 0;
2037             my @differ;
2038             foreach my $csumi (@files_csum_info_fields) {
2039                 my ($fname, $module, $method, $archivefield) = @$csumi;
2040                 next unless defined $h->{$archivefield};
2041                 $_ = $dsc->{$fname};
2042                 next unless defined;
2043                 m/^(\w+) .* \Q$file\E$/m or
2044                     fail f_ ".dsc %s missing entry for %s", $fname, $file;
2045                 if ($h->{$archivefield} eq $1) {
2046                     $same++;
2047                 } else {
2048                     push @differ, f_
2049                         "%s: %s (archive) != %s (local .dsc)",
2050                         $archivefield, $h->{$archivefield}, $1;
2051                 }
2052             }
2053             confess "$file ".Dumper($h)." ?!" if $same && @differ;
2054             $found_same++
2055                 if $same;
2056             push @found_differ,
2057                 f_ "archive %s: %s", $h->{filename}, join "; ", @differ
2058                 if @differ;
2059         }
2060         printdebug "origs $file f.same=$found_same".
2061             " #f._differ=$#found_differ\n";
2062         if (@found_differ && !$found_same) {
2063             fail join "\n",
2064                 (f_ "archive contains %s with different checksum", $file),
2065                 @found_differ;
2066         }
2067         # Now we edit the changes file to add or remove it
2068         foreach my $csumi (@files_csum_info_fields) {
2069             my ($fname, $module, $method, $archivefield) = @$csumi;
2070             next unless defined $changes->{$fname};
2071             if ($found_same) {
2072                 # in archive, delete from .changes if it's there
2073                 $changed{$file} = "removed" if
2074                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
2075             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
2076                 # not in archive, but it's here in the .changes
2077             } else {
2078                 my $dsc_data = getfield $dsc, $fname;
2079                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
2080                 my $extra = $1;
2081                 $extra =~ s/ \d+ /$&$placementinfo /
2082                     or confess "$fname $extra >$dsc_data< ?"
2083                     if $fname eq 'Files';
2084                 $changes->{$fname} .= "\n". $extra;
2085                 $changed{$file} = "added";
2086             }
2087         }
2088     }
2089     if (%changed) {
2090         foreach my $file (keys %changed) {
2091             progress f_
2092                 "edited .changes for archive .orig contents: %s %s",
2093                 $changed{$file}, $file;
2094         }
2095         my $chtmp = "$changesfile.tmp";
2096         $changes->save($chtmp);
2097         if (act_local()) {
2098             rename $chtmp,$changesfile or die "$changesfile $!";
2099         } else {
2100             progress f_ "[new .changes left in %s]", $changesfile;
2101         }
2102     } else {
2103         progress f_ "%s already has appropriate .orig(s) (if any)",
2104                     $changesfile;
2105     }
2106 }
2107
2108 sub make_commit ($) {
2109     my ($file) = @_;
2110     return cmdoutput @git, qw(hash-object -w -t commit), $file;
2111 }
2112
2113 sub clogp_authline ($) {
2114     my ($clogp) = @_;
2115     my $author = getfield $clogp, 'Maintainer';
2116     if ($author =~ m/^[^"\@]+\,/) {
2117         # single entry Maintainer field with unquoted comma
2118         $author = ($& =~ y/,//rd).$'; # strip the comma
2119     }
2120     # git wants a single author; any remaining commas in $author
2121     # are by now preceded by @ (or ").  It seems safer to punt on
2122     # "..." for now rather than attempting to dequote or something.
2123     $author =~ s#,.*##ms unless $author =~ m/"/;
2124     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2125     my $authline = "$author $date";
2126     $authline =~ m/$git_authline_re/o or
2127         fail f_ "unexpected commit author line format \`%s'".
2128                 " (was generated from changelog Maintainer field)",
2129                 $authline;
2130     return ($1,$2,$3) if wantarray;
2131     return $authline;
2132 }
2133
2134 sub vendor_patches_distro ($$) {
2135     my ($checkdistro, $what) = @_;
2136     return unless defined $checkdistro;
2137
2138     my $series = "debian/patches/\L$checkdistro\E.series";
2139     printdebug "checking for vendor-specific $series ($what)\n";
2140
2141     if (!open SERIES, "<", $series) {
2142         confess "$series $!" unless $!==ENOENT;
2143         return;
2144     }
2145     while (<SERIES>) {
2146         next unless m/\S/;
2147         next if m/^\s+\#/;
2148
2149         print STDERR __ <<END;
2150
2151 Unfortunately, this source package uses a feature of dpkg-source where
2152 the same source package unpacks to different source code on different
2153 distros.  dgit cannot safely operate on such packages on affected
2154 distros, because the meaning of source packages is not stable.
2155
2156 Please ask the distro/maintainer to remove the distro-specific series
2157 files and use a different technique (if necessary, uploading actually
2158 different packages, if different distros are supposed to have
2159 different code).
2160
2161 END
2162         fail f_ "Found active distro-specific series file for".
2163                 " %s (%s): %s, cannot continue",
2164                 $checkdistro, $what, $series;
2165     }
2166     die "$series $!" if SERIES->error;
2167     close SERIES;
2168 }
2169
2170 sub check_for_vendor_patches () {
2171     # This dpkg-source feature doesn't seem to be documented anywhere!
2172     # But it can be found in the changelog (reformatted):
2173
2174     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2175     #   Author: Raphael Hertzog <hertzog@debian.org>
2176     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2177
2178     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2179     #   series files
2180     #
2181     #   If you have debian/patches/ubuntu.series and you were
2182     #   unpacking the source package on ubuntu, quilt was still
2183     #   directed to debian/patches/series instead of
2184     #   debian/patches/ubuntu.series.
2185     #
2186     #   debian/changelog                        |    3 +++
2187     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2188     #   2 files changed, 6 insertions(+), 1 deletion(-)
2189
2190     use Dpkg::Vendor;
2191     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2192     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2193                           __ "Dpkg::Vendor \`current vendor'");
2194     vendor_patches_distro(access_basedistro(),
2195                           __ "(base) distro being accessed");
2196     vendor_patches_distro(access_nomdistro(),
2197                           __ "(nominal) distro being accessed");
2198 }
2199
2200 sub check_bpd_exists () {
2201     stat $buildproductsdir
2202         or fail f_ "build-products-dir %s is not accessible: %s\n",
2203         $buildproductsdir, $!;
2204 }
2205
2206 sub generate_commits_from_dsc () {
2207     # See big comment in fetch_from_archive, below.
2208     # See also README.dsc-import.
2209     prep_ud();
2210     changedir $playground;
2211
2212     my @dfi = dsc_files_info();
2213     foreach my $fi (@dfi) {
2214         my $f = $fi->{Filename};
2215         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2216         my $upper_f = (bpd_abs()."/$f");
2217
2218         printdebug "considering reusing $f: ";
2219
2220         if (link_ltarget "$upper_f,fetch", $f) {
2221             printdebug "linked (using ...,fetch).\n";
2222         } elsif ((printdebug "($!) "),
2223                  $! != ENOENT) {
2224             fail f_ "accessing %s: %s", "$buildproductsdir/$f,fetch", $!;
2225         } elsif (link_ltarget $upper_f, $f) {
2226             printdebug "linked.\n";
2227         } elsif ((printdebug "($!) "),
2228                  $! != ENOENT) {
2229             fail f_ "accessing %s: %s", "$buildproductsdir/$f", $!;
2230         } else {
2231             printdebug "absent.\n";
2232         }
2233
2234         my $refetched;
2235         complete_file_from_dsc('.', $fi, \$refetched)
2236             or next;
2237
2238         printdebug "considering saving $f: ";
2239
2240         if (rename_link_xf 1, $f, $upper_f) {
2241             printdebug "linked.\n";
2242         } elsif ((printdebug "($@) "),
2243                  $! != EEXIST) {
2244             fail f_ "saving %s: %s", "$buildproductsdir/$f", $@;
2245         } elsif (!$refetched) {
2246             printdebug "no need.\n";
2247         } elsif (rename_link_xf 1, $f, "$upper_f,fetch") {
2248             printdebug "linked (using ...,fetch).\n";
2249         } elsif ((printdebug "($@) "),
2250                  $! != EEXIST) {
2251             fail f_ "saving %s: %s", "$buildproductsdir/$f,fetch", $@;
2252         } else {
2253             printdebug "cannot.\n";
2254         }
2255     }
2256
2257     # We unpack and record the orig tarballs first, so that we only
2258     # need disk space for one private copy of the unpacked source.
2259     # But we can't make them into commits until we have the metadata
2260     # from the debian/changelog, so we record the tree objects now and
2261     # make them into commits later.
2262     my @tartrees;
2263     my $upstreamv = upstreamversion $dsc->{version};
2264     my $orig_f_base = srcfn $upstreamv, '';
2265
2266     foreach my $fi (@dfi) {
2267         # We actually import, and record as a commit, every tarball
2268         # (unless there is only one file, in which case there seems
2269         # little point.
2270
2271         my $f = $fi->{Filename};
2272         printdebug "import considering $f ";
2273         (printdebug "only one dfi\n"), next if @dfi == 1;
2274         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2275         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2276         my $compr_ext = $1;
2277
2278         my ($orig_f_part) =
2279             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2280
2281         printdebug "Y ", (join ' ', map { $_//"(none)" }
2282                           $compr_ext, $orig_f_part
2283                          ), "\n";
2284
2285         my $input = new IO::File $f, '<' or die "$f $!";
2286         my $compr_pid;
2287         my @compr_cmd;
2288
2289         if (defined $compr_ext) {
2290             my $cname =
2291                 Dpkg::Compression::compression_guess_from_filename $f;
2292             fail "Dpkg::Compression cannot handle file $f in source package"
2293                 if defined $compr_ext && !defined $cname;
2294             my $compr_proc =
2295                 new Dpkg::Compression::Process compression => $cname;
2296             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2297             my $compr_fh = new IO::Handle;
2298             my $compr_pid = open $compr_fh, "-|" // confess $!;
2299             if (!$compr_pid) {
2300                 open STDIN, "<&", $input or confess $!;
2301                 exec @compr_cmd;
2302                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2303             }
2304             $input = $compr_fh;
2305         }
2306
2307         rmtree "_unpack-tar";
2308         mkdir "_unpack-tar" or confess $!;
2309         my @tarcmd = qw(tar -x -f -
2310                         --no-same-owner --no-same-permissions
2311                         --no-acls --no-xattrs --no-selinux);
2312         my $tar_pid = fork // confess $!;
2313         if (!$tar_pid) {
2314             chdir "_unpack-tar" or confess $!;
2315             open STDIN, "<&", $input or confess $!;
2316             exec @tarcmd;
2317             die f_ "dgit (child): exec %s: %s", $tarcmd[0], $!;
2318         }
2319         $!=0; (waitpid $tar_pid, 0) == $tar_pid or confess $!;
2320         !$? or failedcmd @tarcmd;
2321
2322         close $input or
2323             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2324              : confess $!);
2325         # finally, we have the results in "tarball", but maybe
2326         # with the wrong permissions
2327
2328         runcmd qw(chmod -R +rwX _unpack-tar);
2329         changedir "_unpack-tar";
2330         remove_stray_gits($f);
2331         mktree_in_ud_here();
2332
2333         my ($tree) = git_add_write_tree();
2334         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2335         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2336             $tree = $1;
2337             printdebug "one subtree $1\n";
2338         } else {
2339             printdebug "multiple subtrees\n";
2340         }
2341         changedir "..";
2342         rmtree "_unpack-tar";
2343
2344         my $ent = [ $f, $tree ];
2345         push @tartrees, {
2346             Orig => !!$orig_f_part,
2347             Sort => (!$orig_f_part         ? 2 :
2348                      $orig_f_part =~ m/-/g ? 1 :
2349                                              0),
2350             F => $f,
2351             Tree => $tree,
2352         };
2353     }
2354
2355     @tartrees = sort {
2356         # put any without "_" first (spec is not clear whether files
2357         # are always in the usual order).  Tarballs without "_" are
2358         # the main orig or the debian tarball.
2359         $a->{Sort} <=> $b->{Sort} or
2360         $a->{F}    cmp $b->{F}
2361     } @tartrees;
2362
2363     my $any_orig = grep { $_->{Orig} } @tartrees;
2364
2365     my $dscfn = "$package.dsc";
2366
2367     my $treeimporthow = 'package';
2368
2369     open D, ">", $dscfn or die "$dscfn: $!";
2370     print D $dscdata or die "$dscfn: $!";
2371     close D or die "$dscfn: $!";
2372     my @cmd = qw(dpkg-source);
2373     push @cmd, '--no-check' if $dsc_checked;
2374     if (madformat $dsc->{format}) {
2375         push @cmd, '--skip-patches';
2376         $treeimporthow = 'unpatched';
2377     }
2378     push @cmd, qw(-x --), $dscfn;
2379     runcmd @cmd;
2380
2381     my ($tree,$dir) = mktree_in_ud_from_only_subdir(__ "source package");
2382     if (madformat $dsc->{format}) {
2383         check_for_vendor_patches();
2384     }
2385
2386     my $dappliedtree;
2387     if (madformat $dsc->{format}) {
2388         my @pcmd = qw(dpkg-source --before-build .);
2389         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2390         rmtree '.pc';
2391         $dappliedtree = git_add_write_tree();
2392     }
2393
2394     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2395     my $clogp;
2396     my $r1clogp;
2397
2398     printdebug "import clog search...\n";
2399     parsechangelog_loop \@clogcmd, (__ "package changelog"), sub {
2400         my ($thisstanza, $desc) = @_;
2401         no warnings qw(exiting);
2402
2403         $clogp //= $thisstanza;
2404
2405         printdebug "import clog $thisstanza->{version} $desc...\n";
2406
2407         last if !$any_orig; # we don't need $r1clogp
2408
2409         # We look for the first (most recent) changelog entry whose
2410         # version number is lower than the upstream version of this
2411         # package.  Then the last (least recent) previous changelog
2412         # entry is treated as the one which introduced this upstream
2413         # version and used for the synthetic commits for the upstream
2414         # tarballs.
2415
2416         # One might think that a more sophisticated algorithm would be
2417         # necessary.  But: we do not want to scan the whole changelog
2418         # file.  Stopping when we see an earlier version, which
2419         # necessarily then is an earlier upstream version, is the only
2420         # realistic way to do that.  Then, either the earliest
2421         # changelog entry we have seen so far is indeed the earliest
2422         # upload of this upstream version; or there are only changelog
2423         # entries relating to later upstream versions (which is not
2424         # possible unless the changelog and .dsc disagree about the
2425         # version).  Then it remains to choose between the physically
2426         # last entry in the file, and the one with the lowest version
2427         # number.  If these are not the same, we guess that the
2428         # versions were created in a non-monotonic order rather than
2429         # that the changelog entries have been misordered.
2430
2431         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2432
2433         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2434         $r1clogp = $thisstanza;
2435
2436         printdebug "import clog $r1clogp->{version} becomes r1\n";
2437     };
2438
2439     $clogp or fail __ "package changelog has no entries!";
2440
2441     my $authline = clogp_authline $clogp;
2442     my $changes = getfield $clogp, 'Changes';
2443     $changes =~ s/^\n//; # Changes: \n
2444     my $cversion = getfield $clogp, 'Version';
2445
2446     if (@tartrees) {
2447         $r1clogp //= $clogp; # maybe there's only one entry;
2448         my $r1authline = clogp_authline $r1clogp;
2449         # Strictly, r1authline might now be wrong if it's going to be
2450         # unused because !$any_orig.  Whatever.
2451
2452         printdebug "import tartrees authline   $authline\n";
2453         printdebug "import tartrees r1authline $r1authline\n";
2454
2455         foreach my $tt (@tartrees) {
2456             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2457
2458             my $mbody = f_ "Import %s", $tt->{F};
2459             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2460 tree $tt->{Tree}
2461 author $r1authline
2462 committer $r1authline
2463
2464 $mbody
2465
2466 [dgit import orig $tt->{F}]
2467 END_O
2468 tree $tt->{Tree}
2469 author $authline
2470 committer $authline
2471
2472 $mbody
2473
2474 [dgit import tarball $package $cversion $tt->{F}]
2475 END_T
2476         }
2477     }
2478
2479     printdebug "import main commit\n";
2480
2481     open C, ">../commit.tmp" or confess $!;
2482     print C <<END or confess $!;
2483 tree $tree
2484 END
2485     print C <<END or confess $! foreach @tartrees;
2486 parent $_->{Commit}
2487 END
2488     print C <<END or confess $!;
2489 author $authline
2490 committer $authline
2491
2492 $changes
2493
2494 [dgit import $treeimporthow $package $cversion]
2495 END
2496
2497     close C or confess $!;
2498     my $rawimport_hash = make_commit qw(../commit.tmp);
2499
2500     if (madformat $dsc->{format}) {
2501         printdebug "import apply patches...\n";
2502
2503         # regularise the state of the working tree so that
2504         # the checkout of $rawimport_hash works nicely.
2505         my $dappliedcommit = make_commit_text(<<END);
2506 tree $dappliedtree
2507 author $authline
2508 committer $authline
2509
2510 [dgit dummy commit]
2511 END
2512         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2513
2514         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2515
2516         # We need the answers to be reproducible
2517         my @authline = clogp_authline($clogp);
2518         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2519         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2520         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2521         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2522         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2523         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2524
2525         my $path = $ENV{PATH} or die;
2526
2527         # we use ../../gbp-pq-output, which (given that we are in
2528         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2529         # is .git/dgit.
2530
2531         foreach my $use_absurd (qw(0 1)) {
2532             runcmd @git, qw(checkout -q unpa);
2533             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2534             local $ENV{PATH} = $path;
2535             if ($use_absurd) {
2536                 chomp $@;
2537                 progress "warning: $@";
2538                 $path = "$absurdity:$path";
2539                 progress f_ "%s: trying slow absurd-git-apply...", $us;
2540                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2541                     or $!==ENOENT
2542                     or confess $!;
2543             }
2544             eval {
2545                 die "forbid absurd git-apply\n" if $use_absurd
2546                     && forceing [qw(import-gitapply-no-absurd)];
2547                 die "only absurd git-apply!\n" if !$use_absurd
2548                     && forceing [qw(import-gitapply-absurd)];
2549
2550                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2551                 local $ENV{PATH} = $path                    if $use_absurd;
2552
2553                 my @showcmd = (gbp_pq, qw(import));
2554                 my @realcmd = shell_cmd
2555                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2556                 debugcmd "+",@realcmd;
2557                 if (system @realcmd) {
2558                     die f_ "%s failed: %s\n",
2559                         +(shellquote @showcmd),
2560                         failedcmd_waitstatus();
2561                 }
2562
2563                 my $gapplied = git_rev_parse('HEAD');
2564                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2565                 $gappliedtree eq $dappliedtree or
2566                     fail f_ <<END, $gapplied, $gappliedtree, $dappliedtree;
2567 gbp-pq import and dpkg-source disagree!
2568  gbp-pq import gave commit %s
2569  gbp-pq import gave tree %s
2570  dpkg-source --before-build gave tree %s
2571 END
2572                 $rawimport_hash = $gapplied;
2573             };
2574             last unless $@;
2575         }
2576         if ($@) {
2577             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2578             die $@;
2579         }
2580     }
2581
2582     progress f_ "synthesised git commit from .dsc %s", $cversion;
2583
2584     my $rawimport_mergeinput = {
2585         Commit => $rawimport_hash,
2586         Info => __ "Import of source package",
2587     };
2588     my @output = ($rawimport_mergeinput);
2589
2590     if ($lastpush_mergeinput) {
2591         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2592         my $oversion = getfield $oldclogp, 'Version';
2593         my $vcmp =
2594             version_compare($oversion, $cversion);
2595         if ($vcmp < 0) {
2596             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2597                 { ReverseParents => 1,
2598                   Message => (f_ <<END, $package, $cversion, $csuite) });
2599 Record %s (%s) in archive suite %s
2600 END
2601         } elsif ($vcmp > 0) {
2602             print STDERR f_ <<END, $cversion, $oversion,
2603
2604 Version actually in archive:   %s (older)
2605 Last version pushed with dgit: %s (newer or same)
2606 %s
2607 END
2608                 __ $later_warning_msg or confess $!;
2609             @output = $lastpush_mergeinput;
2610         } else {
2611             # Same version.  Use what's in the server git branch,
2612             # discarding our own import.  (This could happen if the
2613             # server automatically imports all packages into git.)
2614             @output = $lastpush_mergeinput;
2615         }
2616     }
2617     changedir $maindir;
2618     rmtree $playground;
2619     return @output;
2620 }
2621
2622 sub complete_file_from_dsc ($$;$) {
2623     our ($dstdir, $fi, $refetched) = @_;
2624     # Ensures that we have, in $dstdir, the file $fi, with the correct
2625     # contents.  (Downloading it from alongside $dscurl if necessary.)
2626     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2627     # and will set $$refetched=1 if it did so (or tried to).
2628
2629     my $f = $fi->{Filename};
2630     my $tf = "$dstdir/$f";
2631     my $downloaded = 0;
2632
2633     my $got;
2634     my $checkhash = sub {
2635         open F, "<", "$tf" or die "$tf: $!";
2636         $fi->{Digester}->reset();
2637         $fi->{Digester}->addfile(*F);
2638         F->error and confess $!;
2639         $got = $fi->{Digester}->hexdigest();
2640         return $got eq $fi->{Hash};
2641     };
2642
2643     if (stat_exists $tf) {
2644         if ($checkhash->()) {
2645             progress f_ "using existing %s", $f;
2646             return 1;
2647         }
2648         if (!$refetched) {
2649             fail f_ "file %s has hash %s but .dsc demands hash %s".
2650                     " (perhaps you should delete this file?)",
2651                     $f, $got, $fi->{Hash};
2652         }
2653         progress f_ "need to fetch correct version of %s", $f;
2654         unlink $tf or die "$tf $!";
2655         $$refetched = 1;
2656     } else {
2657         printdebug "$tf does not exist, need to fetch\n";
2658     }
2659
2660     my $furl = $dscurl;
2661     $furl =~ s{/[^/]+$}{};
2662     $furl .= "/$f";
2663     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2664     die "$f ?" if $f =~ m#/#;
2665     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2666     return 0 if !act_local();
2667
2668     $checkhash->() or
2669         fail f_ "file %s has hash %s but .dsc demands hash %s".
2670                 " (got wrong file from archive!)",
2671                 $f, $got, $fi->{Hash};
2672
2673     return 1;
2674 }
2675
2676 sub ensure_we_have_orig () {
2677     my @dfi = dsc_files_info();
2678     foreach my $fi (@dfi) {
2679         my $f = $fi->{Filename};
2680         next unless is_orig_file_in_dsc($f, \@dfi);
2681         complete_file_from_dsc($buildproductsdir, $fi)
2682             or next;
2683     }
2684 }
2685
2686 #---------- git fetch ----------
2687
2688 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2689 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2690
2691 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2692 # locally fetched refs because they have unhelpful names and clutter
2693 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2694 # whether we have made another local ref which refers to this object).
2695 #
2696 # (If we deleted them unconditionally, then we might end up
2697 # re-fetching the same git objects each time dgit fetch was run.)
2698 #
2699 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2700 # in git_fetch_us to fetch the refs in question, and possibly a call
2701 # to lrfetchref_used.
2702
2703 our (%lrfetchrefs_f, %lrfetchrefs_d);
2704 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2705
2706 sub lrfetchref_used ($) {
2707     my ($fullrefname) = @_;
2708     my $objid = $lrfetchrefs_f{$fullrefname};
2709     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2710 }
2711
2712 sub git_lrfetch_sane {
2713     my ($url, $supplementary, @specs) = @_;
2714     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2715     # at least as regards @specs.  Also leave the results in
2716     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2717     # able to clean these up.
2718     #
2719     # With $supplementary==1, @specs must not contain wildcards
2720     # and we add to our previous fetches (non-atomically).
2721
2722     # This is rather miserable:
2723     # When git fetch --prune is passed a fetchspec ending with a *,
2724     # it does a plausible thing.  If there is no * then:
2725     # - it matches subpaths too, even if the supplied refspec
2726     #   starts refs, and behaves completely madly if the source
2727     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2728     # - if there is no matching remote ref, it bombs out the whole
2729     #   fetch.
2730     # We want to fetch a fixed ref, and we don't know in advance
2731     # if it exists, so this is not suitable.
2732     #
2733     # Our workaround is to use git ls-remote.  git ls-remote has its
2734     # own qairks.  Notably, it has the absurd multi-tail-matching
2735     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2736     # refs/refs/foo etc.
2737     #
2738     # Also, we want an idempotent snapshot, but we have to make two
2739     # calls to the remote: one to git ls-remote and to git fetch.  The
2740     # solution is use git ls-remote to obtain a target state, and
2741     # git fetch to try to generate it.  If we don't manage to generate
2742     # the target state, we try again.
2743
2744     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2745
2746     my $specre = join '|', map {
2747         my $x = $_;
2748         $x =~ s/\W/\\$&/g;
2749         my $wildcard = $x =~ s/\\\*$/.*/;
2750         die if $wildcard && $supplementary;
2751         "(?:refs/$x)";
2752     } @specs;
2753     printdebug "git_lrfetch_sane specre=$specre\n";
2754     my $wanted_rref = sub {
2755         local ($_) = @_;
2756         return m/^(?:$specre)$/;
2757     };
2758
2759     my $fetch_iteration = 0;
2760     FETCH_ITERATION:
2761     for (;;) {
2762         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2763         if (++$fetch_iteration > 10) {
2764             fail __ "too many iterations trying to get sane fetch!";
2765         }
2766
2767         my @look = map { "refs/$_" } @specs;
2768         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2769         debugcmd "|",@lcmd;
2770
2771         my %wantr;
2772         open GITLS, "-|", @lcmd or confess $!;
2773         while (<GITLS>) {
2774             printdebug "=> ", $_;
2775             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2776             my ($objid,$rrefname) = ($1,$2);
2777             if (!$wanted_rref->($rrefname)) {
2778                 print STDERR f_ <<END, "@look", $rrefname;
2779 warning: git ls-remote %s reported %s; this is silly, ignoring it.
2780 END
2781                 next;
2782             }
2783             $wantr{$rrefname} = $objid;
2784         }
2785         $!=0; $?=0;
2786         close GITLS or failedcmd @lcmd;
2787
2788         # OK, now %want is exactly what we want for refs in @specs
2789         my @fspecs = map {
2790             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2791             "+refs/$_:".lrfetchrefs."/$_";
2792         } @specs;
2793
2794         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2795
2796         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2797         runcmd_ordryrun_local @fcmd if @fspecs;
2798
2799         if (!$supplementary) {
2800             %lrfetchrefs_f = ();
2801         }
2802         my %objgot;
2803
2804         git_for_each_ref(lrfetchrefs, sub {
2805             my ($objid,$objtype,$lrefname,$reftail) = @_;
2806             $lrfetchrefs_f{$lrefname} = $objid;
2807             $objgot{$objid} = 1;
2808         });
2809
2810         if ($supplementary) {
2811             last;
2812         }
2813
2814         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2815             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2816             if (!exists $wantr{$rrefname}) {
2817                 if ($wanted_rref->($rrefname)) {
2818                     printdebug <<END;
2819 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2820 END
2821                 } else {
2822                     print STDERR f_ <<END, "@fspecs", $lrefname
2823 warning: git fetch %s created %s; this is silly, deleting it.
2824 END
2825                 }
2826                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2827                 delete $lrfetchrefs_f{$lrefname};
2828                 next;
2829             }
2830         }
2831         foreach my $rrefname (sort keys %wantr) {
2832             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2833             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2834             my $want = $wantr{$rrefname};
2835             next if $got eq $want;
2836             if (!defined $objgot{$want}) {
2837                 fail __ <<END unless act_local();
2838 --dry-run specified but we actually wanted the results of git fetch,
2839 so this is not going to work.  Try running dgit fetch first,
2840 or using --damp-run instead of --dry-run.
2841 END
2842                 print STDERR f_ <<END, $lrefname, $want;
2843 warning: git ls-remote suggests we want %s
2844 warning:  and it should refer to %s
2845 warning:  but git fetch didn't fetch that object to any relevant ref.
2846 warning:  This may be due to a race with someone updating the server.
2847 warning:  Will try again...
2848 END
2849                 next FETCH_ITERATION;
2850             }
2851             printdebug <<END;
2852 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2853 END
2854             runcmd_ordryrun_local @git, qw(update-ref -m),
2855                 "dgit fetch git fetch fixup", $lrefname, $want;
2856             $lrfetchrefs_f{$lrefname} = $want;
2857         }
2858         last;
2859     }
2860
2861     if (defined $csuite) {
2862         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2863         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2864             my ($objid,$objtype,$lrefname,$reftail) = @_;
2865             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2866             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2867         });
2868     }
2869
2870     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2871         Dumper(\%lrfetchrefs_f);
2872 }
2873
2874 sub git_fetch_us () {
2875     # Want to fetch only what we are going to use, unless
2876     # deliberately-not-ff, in which case we must fetch everything.
2877
2878     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2879         map { "tags/$_" }
2880         (quiltmode_splitbrain
2881          ? (map { $_->('*',access_nomdistro) }
2882             \&debiantag_new, \&debiantag_maintview)
2883          : debiantags('*',access_nomdistro));
2884     push @specs, server_branch($csuite);
2885     push @specs, $rewritemap;
2886     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2887
2888     my $url = access_giturl();
2889     git_lrfetch_sane $url, 0, @specs;
2890
2891     my %here;
2892     my @tagpats = debiantags('*',access_nomdistro);
2893
2894     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2895         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2896         printdebug "currently $fullrefname=$objid\n";
2897         $here{$fullrefname} = $objid;
2898     });
2899     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2900         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2901         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2902         printdebug "offered $lref=$objid\n";
2903         if (!defined $here{$lref}) {
2904             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2905             runcmd_ordryrun_local @upd;
2906             lrfetchref_used $fullrefname;
2907         } elsif ($here{$lref} eq $objid) {
2908             lrfetchref_used $fullrefname;
2909         } else {
2910             print STDERR f_ "Not updating %s from %s to %s.\n",
2911                             $lref, $here{$lref}, $objid;
2912         }
2913     });
2914 }
2915
2916 #---------- dsc and archive handling ----------
2917
2918 sub mergeinfo_getclogp ($) {
2919     # Ensures thit $mi->{Clogp} exists and returns it
2920     my ($mi) = @_;
2921     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2922 }
2923
2924 sub mergeinfo_version ($) {
2925     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2926 }
2927
2928 sub fetch_from_archive_record_1 ($) {
2929     my ($hash) = @_;
2930     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
2931     cmdoutput @git, qw(log -n2), $hash;
2932     # ... gives git a chance to complain if our commit is malformed
2933 }
2934
2935 sub fetch_from_archive_record_2 ($) {
2936     my ($hash) = @_;
2937     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
2938     if (act_local()) {
2939         cmdoutput @upd_cmd;
2940     } else {
2941         dryrun_report @upd_cmd;
2942     }
2943 }
2944
2945 sub parse_dsc_field_def_dsc_distro () {
2946     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2947                            dgit.default.distro);
2948 }
2949
2950 sub parse_dsc_field ($$) {
2951     my ($dsc, $what) = @_;
2952     my $f;
2953     foreach my $field (@ourdscfield) {
2954         $f = $dsc->{$field};
2955         last if defined $f;
2956     }
2957
2958     if (!defined $f) {
2959         progress f_ "%s: NO git hash", $what;
2960         parse_dsc_field_def_dsc_distro();
2961     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2962              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2963         progress f_ "%s: specified git info (%s)", $what, $dsc_distro;
2964         $dsc_hint_tag = [ $dsc_hint_tag ];
2965     } elsif ($f =~ m/^\w+\s*$/) {
2966         $dsc_hash = $&;
2967         parse_dsc_field_def_dsc_distro();
2968         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2969                           $dsc_distro ];
2970         progress f_ "%s: specified git hash", $what;
2971     } else {
2972         fail f_ "%s: invalid Dgit info", $what;
2973     }
2974 }
2975
2976 sub resolve_dsc_field_commit ($$) {
2977     my ($already_distro, $already_mapref) = @_;
2978
2979     return unless defined $dsc_hash;
2980
2981     my $mapref =
2982         defined $already_mapref &&
2983         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2984         ? $already_mapref : undef;
2985
2986     my $do_fetch;
2987     $do_fetch = sub {
2988         my ($what, @fetch) = @_;
2989
2990         local $idistro = $dsc_distro;
2991         my $lrf = lrfetchrefs;
2992
2993         if (!$chase_dsc_distro) {
2994             progress f_ "not chasing .dsc distro %s: not fetching %s",
2995                         $dsc_distro, $what;
2996             return 0;
2997         }
2998
2999         progress f_ ".dsc names distro %s: fetching %s", $dsc_distro, $what;
3000
3001         my $url = access_giturl();
3002         if (!defined $url) {
3003             defined $dsc_hint_url or fail f_ <<END, $dsc_distro;
3004 .dsc Dgit metadata is in context of distro %s
3005 for which we have no configured url and .dsc provides no hint
3006 END
3007             my $proto =
3008                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
3009                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
3010             parse_cfg_bool "dsc-url-proto-ok", 'false',
3011                 cfg("dgit.dsc-url-proto-ok.$proto",
3012                     "dgit.default.dsc-url-proto-ok")
3013                 or fail f_ <<END, $dsc_distro, $proto;
3014 .dsc Dgit metadata is in context of distro %s
3015 for which we have no configured url;
3016 .dsc provides hinted url with protocol %s which is unsafe.
3017 (can be overridden by config - consult documentation)
3018 END
3019             $url = $dsc_hint_url;
3020         }
3021
3022         git_lrfetch_sane $url, 1, @fetch;
3023
3024         return $lrf;
3025     };
3026
3027     my $rewrite_enable = do {
3028         local $idistro = $dsc_distro;
3029         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
3030     };
3031
3032     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
3033         if (!defined $mapref) {
3034             my $lrf = $do_fetch->((__ "rewrite map"), $rewritemap) or return;
3035             $mapref = $lrf.'/'.$rewritemap;
3036         }
3037         my $rewritemapdata = git_cat_file $mapref.':map';
3038         if (defined $rewritemapdata
3039             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
3040             progress __
3041                 "server's git history rewrite map contains a relevant entry!";
3042
3043             $dsc_hash = $1;
3044             if (defined $dsc_hash) {
3045                 progress __ "using rewritten git hash in place of .dsc value";
3046             } else {
3047                 progress __ "server data says .dsc hash is to be disregarded";
3048             }
3049         }
3050     }
3051
3052     if (!defined git_cat_file $dsc_hash) {
3053         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
3054         my $lrf = $do_fetch->((__ "additional commits"), @tags) &&
3055             defined git_cat_file $dsc_hash
3056             or fail f_ <<END, $dsc_hash;
3057 .dsc Dgit metadata requires commit %s
3058 but we could not obtain that object anywhere.
3059 END
3060         foreach my $t (@tags) {
3061             my $fullrefname = $lrf.'/'.$t;
3062 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
3063             next unless $lrfetchrefs_f{$fullrefname};
3064             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
3065             lrfetchref_used $fullrefname;
3066         }
3067     }
3068 }
3069
3070 sub fetch_from_archive () {
3071     check_bpd_exists();
3072     ensure_setup_existing_tree();
3073
3074     # Ensures that lrref() is what is actually in the archive, one way
3075     # or another, according to us - ie this client's
3076     # appropritaely-updated archive view.  Also returns the commit id.
3077     # If there is nothing in the archive, leaves lrref alone and
3078     # returns undef.  git_fetch_us must have already been called.
3079     get_archive_dsc();
3080
3081     if ($dsc) {
3082         parse_dsc_field($dsc, __ 'last upload to archive');
3083         resolve_dsc_field_commit access_basedistro,
3084             lrfetchrefs."/".$rewritemap
3085     } else {
3086         progress __ "no version available from the archive";
3087     }
3088
3089     # If the archive's .dsc has a Dgit field, there are three
3090     # relevant git commitids we need to choose between and/or merge
3091     # together:
3092     #   1. $dsc_hash: the Dgit field from the archive
3093     #   2. $lastpush_hash: the suite branch on the dgit git server
3094     #   3. $lastfetch_hash: our local tracking brach for the suite
3095     #
3096     # These may all be distinct and need not be in any fast forward
3097     # relationship:
3098     #
3099     # If the dsc was pushed to this suite, then the server suite
3100     # branch will have been updated; but it might have been pushed to
3101     # a different suite and copied by the archive.  Conversely a more
3102     # recent version may have been pushed with dgit but not appeared
3103     # in the archive (yet).
3104     #
3105     # $lastfetch_hash may be awkward because archive imports
3106     # (particularly, imports of Dgit-less .dscs) are performed only as
3107     # needed on individual clients, so different clients may perform a
3108     # different subset of them - and these imports are only made
3109     # public during push.  So $lastfetch_hash may represent a set of
3110     # imports different to a subsequent upload by a different dgit
3111     # client.
3112     #
3113     # Our approach is as follows:
3114     #
3115     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3116     # descendant of $dsc_hash, then it was pushed by a dgit user who
3117     # had based their work on $dsc_hash, so we should prefer it.
3118     # Otherwise, $dsc_hash was installed into this suite in the
3119     # archive other than by a dgit push, and (necessarily) after the
3120     # last dgit push into that suite (since a dgit push would have
3121     # been descended from the dgit server git branch); thus, in that
3122     # case, we prefer the archive's version (and produce a
3123     # pseudo-merge to overwrite the dgit server git branch).
3124     #
3125     # (If there is no Dgit field in the archive's .dsc then
3126     # generate_commit_from_dsc uses the version numbers to decide
3127     # whether the suite branch or the archive is newer.  If the suite
3128     # branch is newer it ignores the archive's .dsc; otherwise it
3129     # generates an import of the .dsc, and produces a pseudo-merge to
3130     # overwrite the suite branch with the archive contents.)
3131     #
3132     # The outcome of that part of the algorithm is the `public view',
3133     # and is same for all dgit clients: it does not depend on any
3134     # unpublished history in the local tracking branch.
3135     #
3136     # As between the public view and the local tracking branch: The
3137     # local tracking branch is only updated by dgit fetch, and
3138     # whenever dgit fetch runs it includes the public view in the
3139     # local tracking branch.  Therefore if the public view is not
3140     # descended from the local tracking branch, the local tracking
3141     # branch must contain history which was imported from the archive
3142     # but never pushed; and, its tip is now out of date.  So, we make
3143     # a pseudo-merge to overwrite the old imports and stitch the old
3144     # history in.
3145     #
3146     # Finally: we do not necessarily reify the public view (as
3147     # described above).  This is so that we do not end up stacking two
3148     # pseudo-merges.  So what we actually do is figure out the inputs
3149     # to any public view pseudo-merge and put them in @mergeinputs.
3150
3151     my @mergeinputs;
3152     # $mergeinputs[]{Commit}
3153     # $mergeinputs[]{Info}
3154     # $mergeinputs[0] is the one whose tree we use
3155     # @mergeinputs is in the order we use in the actual commit)
3156     #
3157     # Also:
3158     # $mergeinputs[]{Message} is a commit message to use
3159     # $mergeinputs[]{ReverseParents} if def specifies that parent
3160     #                                list should be in opposite order
3161     # Such an entry has no Commit or Info.  It applies only when found
3162     # in the last entry.  (This ugliness is to support making
3163     # identical imports to previous dgit versions.)
3164
3165     my $lastpush_hash = git_get_ref(lrfetchref());
3166     printdebug "previous reference hash=$lastpush_hash\n";
3167     $lastpush_mergeinput = $lastpush_hash && {
3168         Commit => $lastpush_hash,
3169         Info => (__ "dgit suite branch on dgit git server"),
3170     };
3171
3172     my $lastfetch_hash = git_get_ref(lrref());
3173     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3174     my $lastfetch_mergeinput = $lastfetch_hash && {
3175         Commit => $lastfetch_hash,
3176         Info => (__ "dgit client's archive history view"),
3177     };
3178
3179     my $dsc_mergeinput = $dsc_hash && {
3180         Commit => $dsc_hash,
3181         Info => (__ "Dgit field in .dsc from archive"),
3182     };
3183
3184     my $cwd = getcwd();
3185     my $del_lrfetchrefs = sub {
3186         changedir $cwd;
3187         my $gur;
3188         printdebug "del_lrfetchrefs...\n";
3189         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3190             my $objid = $lrfetchrefs_d{$fullrefname};
3191             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3192             if (!$gur) {
3193                 $gur ||= new IO::Handle;
3194                 open $gur, "|-", qw(git update-ref --stdin) or confess $!;
3195             }
3196             printf $gur "delete %s %s\n", $fullrefname, $objid;
3197         }
3198         if ($gur) {
3199             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3200         }
3201     };
3202
3203     if (defined $dsc_hash) {
3204         ensure_we_have_orig();
3205         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3206             @mergeinputs = $dsc_mergeinput
3207         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3208             print STDERR f_ <<END, $dsc_hash, $lastpush_hash,
3209
3210 Git commit in archive is behind the last version allegedly pushed/uploaded.
3211 Commit referred to by archive: %s
3212 Last version pushed with dgit: %s
3213 %s
3214 END
3215                 __ $later_warning_msg or confess $!;
3216             @mergeinputs = ($lastpush_mergeinput);
3217         } else {
3218             # Archive has .dsc which is not a descendant of the last dgit
3219             # push.  This can happen if the archive moves .dscs about.
3220             # Just follow its lead.
3221             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3222                 progress __ "archive .dsc names newer git commit";
3223                 @mergeinputs = ($dsc_mergeinput);
3224             } else {
3225                 progress __ "archive .dsc names other git commit, fixing up";
3226                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3227             }
3228         }
3229     } elsif ($dsc) {
3230         @mergeinputs = generate_commits_from_dsc();
3231         # We have just done an import.  Now, our import algorithm might
3232         # have been improved.  But even so we do not want to generate
3233         # a new different import of the same package.  So if the
3234         # version numbers are the same, just use our existing version.
3235         # If the version numbers are different, the archive has changed
3236         # (perhaps, rewound).
3237         if ($lastfetch_mergeinput &&
3238             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3239                               (mergeinfo_version $mergeinputs[0]) )) {
3240             @mergeinputs = ($lastfetch_mergeinput);
3241         }
3242     } elsif ($lastpush_hash) {
3243         # only in git, not in the archive yet
3244         @mergeinputs = ($lastpush_mergeinput);
3245         print STDERR f_ <<END,
3246
3247 Package not found in the archive, but has allegedly been pushed using dgit.
3248 %s
3249 END
3250             __ $later_warning_msg or confess $!;
3251     } else {
3252         printdebug "nothing found!\n";
3253         if (defined $skew_warning_vsn) {
3254             print STDERR f_ <<END, $skew_warning_vsn or confess $!;
3255
3256 Warning: relevant archive skew detected.
3257 Archive allegedly contains %s
3258 But we were not able to obtain any version from the archive or git.
3259
3260 END
3261         }
3262         unshift @end, $del_lrfetchrefs;
3263         return undef;
3264     }
3265
3266     if ($lastfetch_hash &&
3267         !grep {
3268             my $h = $_->{Commit};
3269             $h and is_fast_fwd($lastfetch_hash, $h);
3270             # If true, one of the existing parents of this commit
3271             # is a descendant of the $lastfetch_hash, so we'll
3272             # be ff from that automatically.
3273         } @mergeinputs
3274         ) {
3275         # Otherwise:
3276         push @mergeinputs, $lastfetch_mergeinput;
3277     }
3278
3279     printdebug "fetch mergeinfos:\n";
3280     foreach my $mi (@mergeinputs) {
3281         if ($mi->{Info}) {
3282             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3283         } else {
3284             printdebug sprintf " ReverseParents=%d Message=%s",
3285                 $mi->{ReverseParents}, $mi->{Message};
3286         }
3287     }
3288
3289     my $compat_info= pop @mergeinputs
3290         if $mergeinputs[$#mergeinputs]{Message};
3291
3292     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3293
3294     my $hash;
3295     if (@mergeinputs > 1) {
3296         # here we go, then:
3297         my $tree_commit = $mergeinputs[0]{Commit};
3298
3299         my $tree = get_tree_of_commit $tree_commit;;
3300
3301         # We use the changelog author of the package in question the
3302         # author of this pseudo-merge.  This is (roughly) correct if
3303         # this commit is simply representing aa non-dgit upload.
3304         # (Roughly because it does not record sponsorship - but we
3305         # don't have sponsorship info because that's in the .changes,
3306         # which isn't in the archivw.)
3307         #
3308         # But, it might be that we are representing archive history
3309         # updates (including in-archive copies).  These are not really
3310         # the responsibility of the person who created the .dsc, but
3311         # there is no-one whose name we should better use.  (The
3312         # author of the .dsc-named commit is clearly worse.)
3313
3314         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3315         my $author = clogp_authline $useclogp;
3316         my $cversion = getfield $useclogp, 'Version';
3317
3318         my $mcf = dgit_privdir()."/mergecommit";
3319         open MC, ">", $mcf or die "$mcf $!";
3320         print MC <<END or confess $!;
3321 tree $tree
3322 END
3323
3324         my @parents = grep { $_->{Commit} } @mergeinputs;
3325         @parents = reverse @parents if $compat_info->{ReverseParents};
3326         print MC <<END or confess $! foreach @parents;
3327 parent $_->{Commit}
3328 END
3329
3330         print MC <<END or confess $!;
3331 author $author
3332 committer $author
3333
3334 END
3335
3336         if (defined $compat_info->{Message}) {
3337             print MC $compat_info->{Message} or confess $!;
3338         } else {
3339             print MC f_ <<END, $package, $cversion, $csuite or confess $!;
3340 Record %s (%s) in archive suite %s
3341
3342 Record that
3343 END
3344             my $message_add_info = sub {
3345                 my ($mi) = (@_);
3346                 my $mversion = mergeinfo_version $mi;
3347                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3348                     or confess $!;
3349             };
3350
3351             $message_add_info->($mergeinputs[0]);
3352             print MC __ <<END or confess $!;
3353 should be treated as descended from
3354 END
3355             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3356         }
3357
3358         close MC or confess $!;
3359         $hash = make_commit $mcf;
3360     } else {
3361         $hash = $mergeinputs[0]{Commit};
3362     }
3363     printdebug "fetch hash=$hash\n";
3364
3365     my $chkff = sub {
3366         my ($lasth, $what) = @_;
3367         return unless $lasth;
3368         confess "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3369     };
3370
3371     $chkff->($lastpush_hash, __ 'dgit repo server tip (last push)')
3372         if $lastpush_hash;
3373     $chkff->($lastfetch_hash, __ 'local tracking tip (last fetch)');
3374
3375     fetch_from_archive_record_1($hash);
3376
3377     if (defined $skew_warning_vsn) {
3378         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3379         my $gotclogp = commit_getclogp($hash);
3380         my $got_vsn = getfield $gotclogp, 'Version';
3381         printdebug "SKEW CHECK GOT $got_vsn\n";
3382         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3383             print STDERR f_ <<END, $skew_warning_vsn, $got_vsn or confess $!;
3384
3385 Warning: archive skew detected.  Using the available version:
3386 Archive allegedly contains    %s
3387 We were able to obtain only   %s
3388
3389 END
3390         }
3391     }
3392
3393     if ($lastfetch_hash ne $hash) {
3394         fetch_from_archive_record_2($hash);
3395     }
3396
3397     lrfetchref_used lrfetchref();
3398
3399     check_gitattrs($hash, __ "fetched source tree");
3400
3401     unshift @end, $del_lrfetchrefs;
3402     return $hash;
3403 }
3404
3405 sub set_local_git_config ($$) {
3406     my ($k, $v) = @_;
3407     runcmd @git, qw(config), $k, $v;
3408 }
3409
3410 sub setup_mergechangelogs (;$) {
3411     my ($always) = @_;
3412     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3413
3414     my $driver = 'dpkg-mergechangelogs';
3415     my $cb = "merge.$driver";
3416     confess unless defined $maindir;
3417     my $attrs = "$maindir_gitcommon/info/attributes";
3418     ensuredir "$maindir_gitcommon/info";
3419
3420     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3421     if (!open ATTRS, "<", $attrs) {
3422         $!==ENOENT or die "$attrs: $!";
3423     } else {
3424         while (<ATTRS>) {
3425             chomp;
3426             next if m{^debian/changelog\s};
3427             print NATTRS $_, "\n" or confess $!;
3428         }
3429         ATTRS->error and confess $!;
3430         close ATTRS;
3431     }
3432     print NATTRS "debian/changelog merge=$driver\n" or confess $!;
3433     close NATTRS;
3434
3435     set_local_git_config "$cb.name", __ 'debian/changelog merge driver';
3436     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3437
3438     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3439 }
3440
3441 sub setup_useremail (;$) {
3442     my ($always) = @_;
3443     return unless $always || access_cfg_bool(1, 'setup-useremail');
3444
3445     my $setup = sub {
3446         my ($k, $envvar) = @_;
3447         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3448         return unless defined $v;
3449         set_local_git_config "user.$k", $v;
3450     };
3451
3452     $setup->('email', 'DEBEMAIL');
3453     $setup->('name', 'DEBFULLNAME');
3454 }
3455
3456 sub ensure_setup_existing_tree () {
3457     my $k = "remote.$remotename.skipdefaultupdate";
3458     my $c = git_get_config $k;
3459     return if defined $c;
3460     set_local_git_config $k, 'true';
3461 }
3462
3463 sub open_main_gitattrs () {
3464     confess 'internal error no maindir' unless defined $maindir;
3465     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3466         or $!==ENOENT
3467         or die "open $maindir_gitcommon/info/attributes: $!";
3468     return $gai;
3469 }
3470
3471 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3472
3473 sub is_gitattrs_setup () {
3474     # return values:
3475     #  trueish
3476     #     1: gitattributes set up and should be left alone
3477     #  falseish
3478     #     0: there is a dgit-defuse-attrs but it needs fixing
3479     #     undef: there is none
3480     my $gai = open_main_gitattrs();
3481     return 0 unless $gai;
3482     while (<$gai>) {
3483         next unless m{$gitattrs_ourmacro_re};
3484         return 1 if m{\s-working-tree-encoding\s};
3485         printdebug "is_gitattrs_setup: found old macro\n";
3486         return 0;
3487     }
3488     $gai->error and confess $!;
3489     printdebug "is_gitattrs_setup: found nothing\n";
3490     return undef;
3491 }
3492
3493 sub setup_gitattrs (;$) {
3494     my ($always) = @_;
3495     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3496
3497     my $already = is_gitattrs_setup();
3498     if ($already) {
3499         progress __ <<END;
3500 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3501  not doing further gitattributes setup
3502 END
3503         return;
3504     }
3505     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3506     my $af = "$maindir_gitcommon/info/attributes";
3507     ensuredir "$maindir_gitcommon/info";
3508
3509     open GAO, "> $af.new" or confess $!;
3510     print GAO <<END, __ <<ENDT or confess $! unless defined $already;
3511 *       dgit-defuse-attrs
3512 $new
3513 END
3514 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3515 ENDT
3516     my $gai = open_main_gitattrs();
3517     if ($gai) {
3518         while (<$gai>) {
3519             if (m{$gitattrs_ourmacro_re}) {
3520                 die unless defined $already;
3521                 $_ = $new;
3522             }
3523             chomp;
3524             print GAO $_, "\n" or confess $!;
3525         }
3526         $gai->error and confess $!;
3527     }
3528     close GAO or confess $!;
3529     rename "$af.new", "$af" or fail f_ "install %s: %s", $af, $!;
3530 }
3531
3532 sub setup_new_tree () {
3533     setup_mergechangelogs();
3534     setup_useremail();
3535     setup_gitattrs();
3536 }
3537
3538 sub check_gitattrs ($$) {
3539     my ($treeish, $what) = @_;
3540
3541     return if is_gitattrs_setup;
3542
3543     local $/="\0";
3544     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3545     debugcmd "|",@cmd;
3546     my $gafl = new IO::File;
3547     open $gafl, "-|", @cmd or confess $!;
3548     while (<$gafl>) {
3549         chomp or die;
3550         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3551         next if $1 == 0;
3552         next unless m{(?:^|/)\.gitattributes$};
3553
3554         # oh dear, found one
3555         print STDERR f_ <<END, $what;
3556 dgit: warning: %s contains .gitattributes
3557 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3558 END
3559         close $gafl;
3560         return;
3561     }
3562     # tree contains no .gitattributes files
3563     $?=0; $!=0; close $gafl or failedcmd @cmd;
3564 }
3565
3566
3567 sub multisuite_suite_child ($$$) {
3568     my ($tsuite, $mergeinputs, $fn) = @_;
3569     # in child, sets things up, calls $fn->(), and returns undef
3570     # in parent, returns canonical suite name for $tsuite
3571     my $canonsuitefh = IO::File::new_tmpfile;
3572     my $pid = fork // confess $!;
3573     if (!$pid) {
3574         forkcheck_setup();
3575         $isuite = $tsuite;
3576         $us .= " [$isuite]";
3577         $debugprefix .= " ";
3578         progress f_ "fetching %s...", $tsuite;
3579         canonicalise_suite();
3580         print $canonsuitefh $csuite, "\n" or confess $!;
3581         close $canonsuitefh or confess $!;
3582         $fn->();
3583         return undef;
3584     }
3585     waitpid $pid,0 == $pid or confess $!;
3586     fail f_ "failed to obtain %s: %s", $tsuite, waitstatusmsg()
3587         if $? && $?!=256*4;
3588     seek $canonsuitefh,0,0 or confess $!;
3589     local $csuite = <$canonsuitefh>;
3590     confess $! unless defined $csuite && chomp $csuite;
3591     if ($? == 256*4) {
3592         printdebug "multisuite $tsuite missing\n";
3593         return $csuite;
3594     }
3595     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3596     push @$mergeinputs, {
3597         Ref => lrref,
3598         Info => $csuite,
3599     };
3600     return $csuite;
3601 }
3602
3603 sub fork_for_multisuite ($) {
3604     my ($before_fetch_merge) = @_;
3605     # if nothing unusual, just returns ''
3606     #
3607     # if multisuite:
3608     # returns 0 to caller in child, to do first of the specified suites
3609     # in child, $csuite is not yet set
3610     #
3611     # returns 1 to caller in parent, to finish up anything needed after
3612     # in parent, $csuite is set to canonicalised portmanteau
3613
3614     my $org_isuite = $isuite;
3615     my @suites = split /\,/, $isuite;
3616     return '' unless @suites > 1;
3617     printdebug "fork_for_multisuite: @suites\n";
3618
3619     my @mergeinputs;
3620
3621     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3622                                             sub { });
3623     return 0 unless defined $cbasesuite;
3624
3625     fail f_ "package %s missing in (base suite) %s", $package, $cbasesuite
3626         unless @mergeinputs;
3627
3628     my @csuites = ($cbasesuite);
3629
3630     $before_fetch_merge->();
3631
3632     foreach my $tsuite (@suites[1..$#suites]) {
3633         $tsuite =~ s/^-/$cbasesuite-/;
3634         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3635                                                sub {
3636             @end = ();
3637             fetch_one();
3638             finish 0;
3639         });
3640
3641         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3642         push @csuites, $csubsuite;
3643     }
3644
3645     foreach my $mi (@mergeinputs) {
3646         my $ref = git_get_ref $mi->{Ref};
3647         die "$mi->{Ref} ?" unless length $ref;
3648         $mi->{Commit} = $ref;
3649     }
3650
3651     $csuite = join ",", @csuites;
3652
3653     my $previous = git_get_ref lrref;
3654     if ($previous) {
3655         unshift @mergeinputs, {
3656             Commit => $previous,
3657             Info => (__ "local combined tracking branch"),
3658             Warning => (__
3659  "archive seems to have rewound: local tracking branch is ahead!"),
3660         };
3661     }
3662
3663     foreach my $ix (0..$#mergeinputs) {
3664         $mergeinputs[$ix]{Index} = $ix;
3665     }
3666
3667     @mergeinputs = sort {
3668         -version_compare(mergeinfo_version $a,
3669                          mergeinfo_version $b) # highest version first
3670             or
3671         $a->{Index} <=> $b->{Index}; # earliest in spec first
3672     } @mergeinputs;
3673
3674     my @needed;
3675
3676   NEEDED:
3677     foreach my $mi (@mergeinputs) {
3678         printdebug "multisuite merge check $mi->{Info}\n";
3679         foreach my $previous (@needed) {
3680             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3681             printdebug "multisuite merge un-needed $previous->{Info}\n";
3682             next NEEDED;
3683         }
3684         push @needed, $mi;
3685         printdebug "multisuite merge this-needed\n";
3686         $mi->{Character} = '+';
3687     }
3688
3689     $needed[0]{Character} = '*';
3690
3691     my $output = $needed[0]{Commit};
3692
3693     if (@needed > 1) {
3694         printdebug "multisuite merge nontrivial\n";
3695         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3696
3697         my $commit = "tree $tree\n";
3698         my $msg = f_ "Combine archive branches %s [dgit]\n\n".
3699                      "Input branches:\n",
3700                      $csuite;
3701
3702         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3703             printdebug "multisuite merge include $mi->{Info}\n";
3704             $mi->{Character} //= ' ';
3705             $commit .= "parent $mi->{Commit}\n";
3706             $msg .= sprintf " %s  %-25s %s\n",
3707                 $mi->{Character},
3708                 (mergeinfo_version $mi),
3709                 $mi->{Info};
3710         }
3711         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3712         $msg .= __ "\nKey\n".
3713             " * marks the highest version branch, which choose to use\n".
3714             " + marks each branch which was not already an ancestor\n\n";
3715         $msg .=
3716             "[dgit multi-suite $csuite]\n";
3717         $commit .=
3718             "author $authline\n".
3719             "committer $authline\n\n";
3720         $output = make_commit_text $commit.$msg;
3721         printdebug "multisuite merge generated $output\n";
3722     }
3723
3724     fetch_from_archive_record_1($output);
3725     fetch_from_archive_record_2($output);
3726
3727     progress f_ "calculated combined tracking suite %s", $csuite;
3728
3729     return 1;
3730 }
3731
3732 sub clone_set_head () {
3733     open H, "> .git/HEAD" or confess $!;
3734     print H "ref: ".lref()."\n" or confess $!;
3735     close H or confess $!;
3736 }
3737 sub clone_finish ($) {
3738     my ($dstdir) = @_;
3739     runcmd @git, qw(reset --hard), lrref();
3740     runcmd qw(bash -ec), <<'END';
3741         set -o pipefail
3742         git ls-tree -r --name-only -z HEAD | \
3743         xargs -0r touch -h -r . --
3744 END
3745     printdone f_ "ready for work in %s", $dstdir;
3746 }
3747
3748 sub clone ($) {
3749     # in multisuite, returns twice!
3750     # once in parent after first suite fetched,
3751     # and then again in child after everything is finished
3752     my ($dstdir) = @_;
3753     badusage __ "dry run makes no sense with clone" unless act_local();
3754
3755     my $multi_fetched = fork_for_multisuite(sub {
3756         printdebug "multi clone before fetch merge\n";
3757         changedir $dstdir;
3758         record_maindir();
3759     });
3760     if ($multi_fetched) {
3761         printdebug "multi clone after fetch merge\n";
3762         clone_set_head();
3763         clone_finish($dstdir);
3764         return;
3765     }
3766     printdebug "clone main body\n";
3767
3768     mkdir $dstdir or fail f_ "create \`%s': %s", $dstdir, $!;
3769     changedir $dstdir;
3770     check_bpd_exists();
3771
3772     canonicalise_suite();
3773     my $hasgit = check_for_git();
3774
3775     runcmd @git, qw(init -q);
3776     record_maindir();
3777     setup_new_tree();
3778     clone_set_head();
3779     my $giturl = access_giturl(1);
3780     if (defined $giturl) {
3781         runcmd @git, qw(remote add), 'origin', $giturl;
3782     }
3783     if ($hasgit) {
3784         progress __ "fetching existing git history";
3785         git_fetch_us();
3786         runcmd_ordryrun_local @git, qw(fetch origin);
3787     } else {
3788         progress __ "starting new git history";
3789     }
3790     fetch_from_archive() or no_such_package;
3791     my $vcsgiturl = $dsc->{'Vcs-Git'};
3792     if (length $vcsgiturl) {
3793         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3794         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3795     }
3796     clone_finish($dstdir);
3797 }
3798
3799 sub fetch_one () {
3800     canonicalise_suite();
3801     if (check_for_git()) {
3802         git_fetch_us();
3803     }
3804     fetch_from_archive() or no_such_package();
3805
3806     my $vcsgiturl = $dsc && $dsc->{'Vcs-Git'};
3807     if (length $vcsgiturl and
3808         (grep { $csuite eq $_ }
3809          split /\;/,
3810          cfg 'dgit.vcs-git.suites')) {
3811         my $current = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
3812         if (defined $current && $current ne $vcsgiturl) {
3813             print STDERR f_ <<END, $csuite;
3814 FYI: Vcs-Git in %s has different url to your vcs-git remote.
3815  Your vcs-git remote url may be out of date.  Use dgit update-vcs-git ?
3816 END
3817         }
3818     }
3819     printdone f_ "fetched into %s", lrref();
3820 }
3821
3822 sub dofetch () {
3823     my $multi_fetched = fork_for_multisuite(sub { });
3824     fetch_one() unless $multi_fetched; # parent
3825     finish 0 if $multi_fetched eq '0'; # child
3826 }
3827
3828 sub pull () {
3829     dofetch();
3830     runcmd_ordryrun_local @git, qw(merge -m),
3831         (f_ "Merge from %s [dgit]", $csuite),
3832         lrref();
3833     printdone f_ "fetched to %s and merged into HEAD", lrref();
3834 }
3835
3836 sub check_not_dirty () {
3837     my @forbid = qw(local-options local-patch-header);
3838     @forbid = map { "debian/source/$_" } @forbid;
3839     foreach my $f (@forbid) {
3840         if (stat_exists $f) {
3841             fail f_ "git tree contains %s", $f;
3842         }
3843     }
3844
3845     my @cmd = (@git, qw(status -uall --ignored --porcelain));
3846     push @cmd, qw(debian/source/format debian/source/options);
3847     push @cmd, @forbid;
3848
3849     my $bad = cmdoutput @cmd;
3850     if (length $bad) {
3851         fail +(__
3852  "you have uncommitted changes to critical files, cannot continue:\n").
3853               $bad;
3854     }
3855
3856     return if $includedirty;
3857
3858     git_check_unmodified();
3859 }
3860
3861 sub commit_admin ($) {
3862     my ($m) = @_;
3863     progress "$m";
3864     runcmd_ordryrun_local @git, qw(commit -m), $m;
3865 }
3866
3867 sub quiltify_nofix_bail ($$) {
3868     my ($headinfo, $xinfo) = @_;
3869     if ($quilt_mode eq 'nofix') {
3870         fail f_
3871             "quilt fixup required but quilt mode is \`nofix'\n".
3872             "HEAD commit%s differs from tree implied by debian/patches%s",
3873             $headinfo, $xinfo;
3874     }
3875 }
3876
3877 sub commit_quilty_patch () {
3878     my $output = cmdoutput @git, qw(status --ignored --porcelain);
3879     my %adds;
3880     foreach my $l (split /\n/, $output) {
3881         next unless $l =~ m/\S/;
3882         if ($l =~ m{^(?:[?!][?!]| [MADRC]) (.pc|debian/patches)}) {
3883             $adds{$1}++;
3884         }
3885     }
3886     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3887     if (!%adds) {
3888         progress __ "nothing quilty to commit, ok.";
3889         return;
3890     }
3891     quiltify_nofix_bail "", __ " (wanted to commit patch update)";
3892     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3893     runcmd_ordryrun_local @git, qw(add -f), @adds;
3894     commit_admin +(__ <<ENDT).<<END
3895 Commit Debian 3.0 (quilt) metadata
3896
3897 ENDT
3898 [dgit ($our_version) quilt-fixup]
3899 END
3900 }
3901
3902 sub get_source_format () {
3903     my %options;
3904     if (open F, "debian/source/options") {
3905         while (<F>) {
3906             next if m/^\s*\#/;
3907             next unless m/\S/;
3908             s/\s+$//; # ignore missing final newline
3909             if (m/\s*\#\s*/) {
3910                 my ($k, $v) = ($`, $'); #');
3911                 $v =~ s/^"(.*)"$/$1/;
3912                 $options{$k} = $v;
3913             } else {
3914                 $options{$_} = 1;
3915             }
3916         }
3917         F->error and confess $!;
3918         close F;
3919     } else {
3920         confess $! unless $!==&ENOENT;
3921     }
3922
3923     if (!open F, "debian/source/format") {
3924         confess $! unless $!==&ENOENT;
3925         return '';
3926     }
3927     $_ = <F>;
3928     F->error and confess $!;
3929     chomp;
3930     return ($_, \%options);
3931 }
3932
3933 sub madformat_wantfixup ($) {
3934     my ($format) = @_;
3935     return 0 unless $format eq '3.0 (quilt)';
3936     our $quilt_mode_warned;
3937     if ($quilt_mode eq 'nocheck') {
3938         progress f_ "Not doing any fixup of \`%s'".
3939             " due to ----no-quilt-fixup or --quilt=nocheck", $format
3940             unless $quilt_mode_warned++;
3941         return 0;
3942     }
3943     progress f_ "Format \`%s', need to check/update patch stack", $format
3944         unless $quilt_mode_warned++;
3945     return 1;
3946 }
3947
3948 sub maybe_split_brain_save ($$$) {
3949     my ($headref, $dgitview, $msg) = @_;
3950     # => message fragment "$saved" describing disposition of $dgitview
3951     #    (used inside parens, in the English texts)
3952     my $save = $internal_object_save{'dgit-view'};
3953     return f_ "commit id %s", $dgitview unless defined $save;
3954     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
3955                git_update_ref_cmd
3956                "dgit --dgit-view-save $msg HEAD=$headref",
3957                $save, $dgitview);
3958     runcmd @cmd;
3959     return f_ "and left in %s", $save;
3960 }
3961
3962 # An "infopair" is a tuple [ $thing, $what ]
3963 # (often $thing is a commit hash; $what is a description)
3964
3965 sub infopair_cond_equal ($$) {
3966     my ($x,$y) = @_;
3967     $x->[0] eq $y->[0] or fail <<END;
3968 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3969 END
3970 };
3971
3972 sub infopair_lrf_tag_lookup ($$) {
3973     my ($tagnames, $what) = @_;
3974     # $tagname may be an array ref
3975     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3976     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3977     foreach my $tagname (@tagnames) {
3978         my $lrefname = lrfetchrefs."/tags/$tagname";
3979         my $tagobj = $lrfetchrefs_f{$lrefname};
3980         next unless defined $tagobj;
3981         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3982         return [ git_rev_parse($tagobj), $what ];
3983     }
3984     fail @tagnames==1 ? (f_ <<END, $what, "@tagnames")
3985 Wanted tag %s (%s) on dgit server, but not found
3986 END
3987                       : (f_ <<END, $what, "@tagnames");
3988 Wanted tag %s (one of: %s) on dgit server, but not found
3989 END
3990 }
3991
3992 sub infopair_cond_ff ($$) {
3993     my ($anc,$desc) = @_;
3994     is_fast_fwd($anc->[0], $desc->[0]) or
3995         fail f_ <<END, $anc->[1], $anc->[0], $desc->[1], $desc->[0];
3996 %s (%s) .. %s (%s) is not fast forward
3997 END
3998 };
3999
4000 sub pseudomerge_version_check ($$) {
4001     my ($clogp, $archive_hash) = @_;
4002
4003     my $arch_clogp = commit_getclogp $archive_hash;
4004     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
4005                      __ 'version currently in archive' ];
4006     if (defined $overwrite_version) {
4007         if (length $overwrite_version) {
4008             infopair_cond_equal([ $overwrite_version,
4009                                   '--overwrite= version' ],
4010                                 $i_arch_v);
4011         } else {
4012             my $v = $i_arch_v->[0];
4013             progress f_
4014                 "Checking package changelog for archive version %s ...", $v;
4015             my $cd;
4016             eval {
4017                 my @xa = ("-f$v", "-t$v");
4018                 my $vclogp = parsechangelog @xa;
4019                 my $gf = sub {
4020                     my ($fn) = @_;
4021                     [ (getfield $vclogp, $fn),
4022                       (f_ "%s field from dpkg-parsechangelog %s",
4023                           $fn, "@xa") ];
4024                 };
4025                 my $cv = $gf->('Version');
4026                 infopair_cond_equal($i_arch_v, $cv);
4027                 $cd = $gf->('Distribution');
4028             };
4029             if ($@) {
4030                 $@ =~ s/^dgit: //gm;
4031                 fail "$@".
4032                     f_ "Perhaps debian/changelog does not mention %s ?", $v;
4033             }
4034             fail f_ <<END, $cd->[1], $cd->[0], $v
4035 %s is %s
4036 Your tree seems to based on earlier (not uploaded) %s.
4037 END
4038                 if $cd->[0] =~ m/UNRELEASED/;
4039         }
4040     }
4041
4042     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
4043     return $i_arch_v;
4044 }
4045
4046 sub pseudomerge_make_commit ($$$$ $$) {
4047     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
4048         $msg_cmd, $msg_msg) = @_;
4049     progress f_ "Declaring that HEAD includes all changes in %s...",
4050                  $i_arch_v->[0];
4051
4052     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
4053     my $authline = clogp_authline $clogp;
4054
4055     chomp $msg_msg;
4056     $msg_cmd .=
4057         !defined $overwrite_version ? ""
4058         : !length  $overwrite_version ? " --overwrite"
4059         : " --overwrite=".$overwrite_version;
4060
4061     # Contributing parent is the first parent - that makes
4062     # git rev-list --first-parent DTRT.
4063     my $pmf = dgit_privdir()."/pseudomerge";
4064     open MC, ">", $pmf or die "$pmf $!";
4065     print MC <<END or confess $!;
4066 tree $tree
4067 parent $dgitview
4068 parent $archive_hash
4069 author $authline
4070 committer $authline
4071
4072 $msg_msg
4073
4074 [$msg_cmd]
4075 END
4076     close MC or confess $!;
4077
4078     return make_commit($pmf);
4079 }
4080
4081 sub splitbrain_pseudomerge ($$$$) {
4082     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
4083     # => $merged_dgitview
4084     printdebug "splitbrain_pseudomerge...\n";
4085     #
4086     #     We:      debian/PREVIOUS    HEAD($maintview)
4087     # expect:          o ----------------- o
4088     #                    \                   \
4089     #                     o                   o
4090     #                 a/d/PREVIOUS        $dgitview
4091     #                $archive_hash              \
4092     #  If so,                \                   \
4093     #  we do:                 `------------------ o
4094     #   this:                                   $dgitview'
4095     #
4096
4097     return $dgitview unless defined $archive_hash;
4098     return $dgitview if deliberately_not_fast_forward();
4099
4100     printdebug "splitbrain_pseudomerge...\n";
4101
4102     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4103
4104     if (!defined $overwrite_version) {
4105         progress __ "Checking that HEAD includes all changes in archive...";
4106     }
4107
4108     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
4109
4110     if (defined $overwrite_version) {
4111     } elsif (!eval {
4112         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
4113         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14,
4114                                               __ "maintainer view tag");
4115         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
4116         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, __ "dgit view tag");
4117         my $i_archive = [ $archive_hash, __ "current archive contents" ];
4118
4119         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
4120
4121         infopair_cond_equal($i_dgit, $i_archive);
4122         infopair_cond_ff($i_dep14, $i_dgit);
4123         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
4124         1;
4125     }) {
4126         $@ =~ s/^\n//; chomp $@;
4127         print STDERR <<END.(__ <<ENDT);
4128 $@
4129 END
4130 | Not fast forward; maybe --overwrite is needed ?  Please see dgit(1).
4131 ENDT
4132         finish -1;
4133     }
4134
4135     my $arch_v = $i_arch_v->[0];
4136     my $r = pseudomerge_make_commit
4137         $clogp, $dgitview, $archive_hash, $i_arch_v,
4138         "dgit --quilt=$quilt_mode",
4139         (defined $overwrite_version
4140          ? f_ "Declare fast forward from %s\n", $arch_v
4141          : f_ "Make fast forward from %s\n",    $arch_v);
4142
4143     maybe_split_brain_save $maintview, $r, "pseudomerge";
4144
4145     progress f_ "Made pseudo-merge of %s into dgit view.", $arch_v;
4146     return $r;
4147 }
4148
4149 sub plain_overwrite_pseudomerge ($$$) {
4150     my ($clogp, $head, $archive_hash) = @_;
4151
4152     printdebug "plain_overwrite_pseudomerge...";
4153
4154     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4155
4156     return $head if is_fast_fwd $archive_hash, $head;
4157
4158     my $m = f_ "Declare fast forward from %s", $i_arch_v->[0];
4159
4160     my $r = pseudomerge_make_commit
4161         $clogp, $head, $archive_hash, $i_arch_v,
4162         "dgit", $m;
4163
4164     runcmd git_update_ref_cmd $m, 'HEAD', $r, $head;
4165
4166     progress f_ "Make pseudo-merge of %s into your HEAD.", $i_arch_v->[0];
4167     return $r;
4168 }
4169
4170 sub push_parse_changelog ($) {
4171     my ($clogpfn) = @_;
4172
4173     my $clogp = Dpkg::Control::Hash->new();
4174     $clogp->load($clogpfn) or die;
4175
4176     my $clogpackage = getfield $clogp, 'Source';
4177     $package //= $clogpackage;
4178     fail f_ "-p specified %s but changelog specified %s",
4179             $package, $clogpackage
4180         unless $package eq $clogpackage;
4181     my $cversion = getfield $clogp, 'Version';
4182
4183     if (!$we_are_initiator) {
4184         # rpush initiator can't do this because it doesn't have $isuite yet
4185         my $tag = debiantag($cversion, access_nomdistro);
4186         runcmd @git, qw(check-ref-format), $tag;
4187     }
4188
4189     my $dscfn = dscfn($cversion);
4190
4191     return ($clogp, $cversion, $dscfn);
4192 }
4193
4194 sub push_parse_dsc ($$$) {
4195     my ($dscfn,$dscfnwhat, $cversion) = @_;
4196     $dsc = parsecontrol($dscfn,$dscfnwhat);
4197     my $dversion = getfield $dsc, 'Version';
4198     my $dscpackage = getfield $dsc, 'Source';
4199     ($dscpackage eq $package && $dversion eq $cversion) or
4200         fail f_ "%s is for %s %s but debian/changelog is for %s %s",
4201                 $dscfn, $dscpackage, $dversion,
4202                         $package,    $cversion;
4203 }
4204
4205 sub push_tagwants ($$$$) {
4206     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4207     my @tagwants;
4208     push @tagwants, {
4209         TagFn => \&debiantag,
4210         Objid => $dgithead,
4211         TfSuffix => '',
4212         View => 'dgit',
4213     };
4214     if (defined $maintviewhead) {
4215         push @tagwants, {
4216             TagFn => \&debiantag_maintview,
4217             Objid => $maintviewhead,
4218             TfSuffix => '-maintview',
4219             View => 'maint',
4220         };
4221     } elsif ($dodep14tag eq 'no' ? 0
4222              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
4223              : $dodep14tag eq 'always'
4224              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
4225 --dep14tag-always (or equivalent in config) means server must support
4226  both "new" and "maint" tag formats, but config says it doesn't.
4227 END
4228             : die "$dodep14tag ?") {
4229         push @tagwants, {
4230             TagFn => \&debiantag_maintview,
4231             Objid => $dgithead,
4232             TfSuffix => '-dgit',
4233             View => 'dgit',
4234         };
4235     };
4236     foreach my $tw (@tagwants) {
4237         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4238         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4239     }
4240     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4241     return @tagwants;
4242 }
4243
4244 sub push_mktags ($$ $$ $) {
4245     my ($clogp,$dscfn,
4246         $changesfile,$changesfilewhat,
4247         $tagwants) = @_;
4248
4249     die unless $tagwants->[0]{View} eq 'dgit';
4250
4251     my $declaredistro = access_nomdistro();
4252     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4253     $dsc->{$ourdscfield[0]} = join " ",
4254         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4255         $reader_giturl;
4256     $dsc->save("$dscfn.tmp") or confess $!;
4257
4258     my $changes = parsecontrol($changesfile,$changesfilewhat);
4259     foreach my $field (qw(Source Distribution Version)) {
4260         $changes->{$field} eq $clogp->{$field} or
4261             fail f_ "changes field %s \`%s' does not match changelog \`%s'",
4262                     $field, $changes->{$field}, $clogp->{$field};
4263     }
4264
4265     my $cversion = getfield $clogp, 'Version';
4266     my $clogsuite = getfield $clogp, 'Distribution';
4267
4268     # We make the git tag by hand because (a) that makes it easier
4269     # to control the "tagger" (b) we can do remote signing
4270     my $authline = clogp_authline $clogp;
4271     my $delibs = join(" ", "",@deliberatelies);
4272
4273     my $mktag = sub {
4274         my ($tw) = @_;
4275         my $tfn = $tw->{Tfn};
4276         my $head = $tw->{Objid};
4277         my $tag = $tw->{Tag};
4278
4279         open TO, '>', $tfn->('.tmp') or confess $!;
4280         print TO <<END or confess $!;
4281 object $head
4282 type commit
4283 tag $tag
4284 tagger $authline
4285
4286 END
4287         if ($tw->{View} eq 'dgit') {
4288             print TO f_ <<ENDT, $package, $cversion, $clogsuite, $csuite
4289 %s release %s for %s (%s) [dgit]
4290 ENDT
4291                 or confess $!;
4292             print TO <<END or confess $!;
4293 [dgit distro=$declaredistro$delibs]
4294 END
4295             foreach my $ref (sort keys %previously) {
4296                 print TO <<END or confess $!;
4297 [dgit previously:$ref=$previously{$ref}]
4298 END
4299             }
4300         } elsif ($tw->{View} eq 'maint') {
4301             print TO f_ <<END, $package, $cversion, $clogsuite, $csuite,
4302 %s release %s for %s (%s)
4303 (maintainer view tag generated by dgit --quilt=%s)
4304 END
4305                 $quilt_mode
4306                 or confess $!;
4307         } else {
4308             confess Dumper($tw)."?";
4309         }
4310
4311         close TO or confess $!;
4312
4313         my $tagobjfn = $tfn->('.tmp');
4314         if ($sign) {
4315             if (!defined $keyid) {
4316                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4317             }
4318             if (!defined $keyid) {
4319                 $keyid = getfield $clogp, 'Maintainer';
4320             }
4321             unlink $tfn->('.tmp.asc') or $!==&ENOENT or confess $!;
4322             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4323             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4324             push @sign_cmd, $tfn->('.tmp');
4325             runcmd_ordryrun @sign_cmd;
4326             if (act_scary()) {
4327                 $tagobjfn = $tfn->('.signed.tmp');
4328                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4329                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4330             }
4331         }
4332         return $tagobjfn;
4333     };
4334
4335     my @r = map { $mktag->($_); } @$tagwants;
4336     return @r;
4337 }
4338
4339 sub sign_changes ($) {
4340     my ($changesfile) = @_;
4341     if ($sign) {
4342         my @debsign_cmd = @debsign;
4343         push @debsign_cmd, "-k$keyid" if defined $keyid;
4344         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4345         push @debsign_cmd, $changesfile;
4346         runcmd_ordryrun @debsign_cmd;
4347     }
4348 }
4349
4350 sub dopush () {
4351     printdebug "actually entering push\n";
4352
4353     supplementary_message(__ <<'END');
4354 Push failed, while checking state of the archive.
4355 You can retry the push, after fixing the problem, if you like.
4356 END
4357     if (check_for_git()) {
4358         git_fetch_us();
4359     }
4360     my $archive_hash = fetch_from_archive();
4361     if (!$archive_hash) {
4362         $new_package or
4363             fail __ "package appears to be new in this suite;".
4364                     " if this is intentional, use --new";
4365     }
4366
4367     supplementary_message(__ <<'END');
4368 Push failed, while preparing your push.
4369 You can retry the push, after fixing the problem, if you like.
4370 END
4371
4372     need_tagformat 'new', "quilt mode $quilt_mode"
4373         if quiltmode_splitbrain;
4374
4375     prep_ud();
4376
4377     access_giturl(); # check that success is vaguely likely
4378     rpush_handle_protovsn_bothends() if $we_are_initiator;
4379     select_tagformat();
4380
4381     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4382     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4383
4384     responder_send_file('parsed-changelog', $clogpfn);
4385
4386     my ($clogp, $cversion, $dscfn) =
4387         push_parse_changelog("$clogpfn");
4388
4389     my $dscpath = "$buildproductsdir/$dscfn";
4390     stat_exists $dscpath or
4391         fail f_ "looked for .dsc %s, but %s; maybe you forgot to build",
4392                 $dscpath, $!;
4393
4394     responder_send_file('dsc', $dscpath);
4395
4396     push_parse_dsc($dscpath, $dscfn, $cversion);
4397
4398     my $format = getfield $dsc, 'Format';
4399     printdebug "format $format\n";
4400
4401     my $symref = git_get_symref();
4402     my $actualhead = git_rev_parse('HEAD');
4403
4404     if (branch_is_gdr_unstitched_ff($symref, $actualhead, $archive_hash)) {
4405         if (quiltmode_splitbrain()) {
4406             my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $actualhead);
4407             fail f_ <<END, $ffq_prev, $quilt_mode;
4408 Branch is managed by git-debrebase (%s
4409 exists), but quilt mode (%s) implies a split view.
4410 Pass the right --quilt option or adjust your git config.
4411 Or, maybe, run git-debrebase forget-was-ever-debrebase.
4412 END
4413         }
4414         runcmd_ordryrun_local @git_debrebase, 'stitch';
4415         $actualhead = git_rev_parse('HEAD');
4416     }
4417
4418     my $dgithead = $actualhead;
4419     my $maintviewhead = undef;
4420
4421     my $upstreamversion = upstreamversion $clogp->{Version};
4422
4423     if (madformat_wantfixup($format)) {
4424         # user might have not used dgit build, so maybe do this now:
4425         if (quiltmode_splitbrain()) {
4426             changedir $playground;
4427             quilt_make_fake_dsc($upstreamversion);
4428             my $cachekey;
4429             ($dgithead, $cachekey) =
4430                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4431             $dgithead or fail f_
4432  "--quilt=%s but no cached dgit view:
4433  perhaps HEAD changed since dgit build[-source] ?",
4434                               $quilt_mode;
4435             $split_brain = 1;
4436             $dgithead = splitbrain_pseudomerge($clogp,
4437                                                $actualhead, $dgithead,
4438                                                $archive_hash);
4439             $maintviewhead = $actualhead;
4440             changedir $maindir;
4441             prep_ud(); # so _only_subdir() works, below
4442         } else {
4443             commit_quilty_patch();
4444         }
4445     }
4446
4447     if (defined $overwrite_version && !defined $maintviewhead
4448         && $archive_hash) {
4449         $dgithead = plain_overwrite_pseudomerge($clogp,
4450                                                 $dgithead,
4451                                                 $archive_hash);
4452     }
4453
4454     check_not_dirty();
4455
4456     my $forceflag = '';
4457     if ($archive_hash) {
4458         if (is_fast_fwd($archive_hash, $dgithead)) {
4459             # ok
4460         } elsif (deliberately_not_fast_forward) {
4461             $forceflag = '+';
4462         } else {
4463             fail __ "dgit push: HEAD is not a descendant".
4464                 " of the archive's version.\n".
4465                 "To overwrite the archive's contents,".
4466                 " pass --overwrite[=VERSION].\n".
4467                 "To rewind history, if permitted by the archive,".
4468                 " use --deliberately-not-fast-forward.";
4469         }
4470     }
4471
4472     changedir $playground;
4473     progress f_ "checking that %s corresponds to HEAD", $dscfn;
4474     runcmd qw(dpkg-source -x --),
4475         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4476     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4477     check_for_vendor_patches() if madformat($dsc->{format});
4478     changedir $maindir;
4479     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4480     debugcmd "+",@diffcmd;
4481     $!=0; $?=-1;
4482     my $r = system @diffcmd;
4483     if ($r) {
4484         if ($r==256) {
4485             my $referent = $split_brain ? $dgithead : 'HEAD';
4486             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4487
4488             my @mode_changes;
4489             my $raw = cmdoutput @git,
4490                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4491             my $changed;
4492             foreach (split /\0/, $raw) {
4493                 if (defined $changed) {
4494                     push @mode_changes, "$changed: $_\n" if $changed;
4495                     $changed = undef;
4496                     next;
4497                 } elsif (m/^:0+ 0+ /) {
4498                     $changed = '';
4499                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4500                     $changed = "Mode change from $1 to $2"
4501                 } else {
4502                     die "$_ ?";
4503                 }
4504             }
4505             if (@mode_changes) {
4506                 fail +(f_ <<ENDT, $dscfn).<<END
4507 HEAD specifies a different tree to %s:
4508 ENDT
4509 $diffs
4510 END
4511                     .(join '', @mode_changes)
4512                     .(f_ <<ENDT, $tree, $referent);
4513 There is a problem with your source tree (see dgit(7) for some hints).
4514 To see a full diff, run git diff %s %s
4515 ENDT
4516             }
4517
4518             fail +(f_ <<ENDT, $dscfn).<<END.(f_ <<ENDT, $tree, $referent);
4519 HEAD specifies a different tree to %s:
4520 ENDT
4521 $diffs
4522 END
4523 Perhaps you forgot to build.  Or perhaps there is a problem with your
4524  source tree (see dgit(7) for some hints).  To see a full diff, run
4525    git diff %s %s
4526 ENDT
4527         } else {
4528             failedcmd @diffcmd;
4529         }
4530     }
4531     if (!$changesfile) {
4532         my $pat = changespat $cversion;
4533         my @cs = glob "$buildproductsdir/$pat";
4534         fail f_ "failed to find unique changes file".
4535                 " (looked for %s in %s);".
4536                 " perhaps you need to use dgit -C",
4537                 $pat, $buildproductsdir
4538             unless @cs==1;
4539         ($changesfile) = @cs;
4540     } else {
4541         $changesfile = "$buildproductsdir/$changesfile";
4542     }
4543
4544     # Check that changes and .dsc agree enough
4545     $changesfile =~ m{[^/]*$};
4546     my $changes = parsecontrol($changesfile,$&);
4547     files_compare_inputs($dsc, $changes)
4548         unless forceing [qw(dsc-changes-mismatch)];
4549
4550     # Check whether this is a source only upload
4551     my $hasdebs = $changes->{Files} =~ m{\.deb$}m;
4552     my $sourceonlypolicy = access_cfg 'source-only-uploads';
4553     if ($sourceonlypolicy eq 'ok') {
4554     } elsif ($sourceonlypolicy eq 'always') {
4555         forceable_fail [qw(uploading-binaries)],
4556             __ "uploading binaries, although distro policy is source only"
4557             if $hasdebs;
4558     } elsif ($sourceonlypolicy eq 'never') {
4559         forceable_fail [qw(uploading-source-only)],
4560             __ "source-only upload, although distro policy requires .debs"
4561             if !$hasdebs;
4562     } elsif ($sourceonlypolicy eq 'not-wholly-new') {
4563         forceable_fail [qw(uploading-source-only)],
4564             f_ "source-only upload, even though package is entirely NEW\n".
4565                "(this is contrary to policy in %s)",
4566                access_nomdistro()
4567             if !$hasdebs
4568             && $new_package
4569             && !(archive_query('package_not_wholly_new', $package) // 1);
4570     } else {
4571         badcfg f_ "unknown source-only-uploads policy \`%s'",
4572                   $sourceonlypolicy;
4573     }
4574
4575     # Perhaps adjust .dsc to contain right set of origs
4576     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4577                                   $changesfile)
4578         unless forceing [qw(changes-origs-exactly)];
4579
4580     # Checks complete, we're going to try and go ahead:
4581
4582     responder_send_file('changes',$changesfile);
4583     responder_send_command("param head $dgithead");
4584     responder_send_command("param csuite $csuite");
4585     responder_send_command("param isuite $isuite");
4586     responder_send_command("param tagformat $tagformat");
4587     if (defined $maintviewhead) {
4588         confess "internal error (protovsn=$protovsn)"
4589             if defined $protovsn and $protovsn < 4;
4590         responder_send_command("param maint-view $maintviewhead");
4591     }
4592
4593     # Perhaps send buildinfo(s) for signing
4594     my $changes_files = getfield $changes, 'Files';
4595     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4596     foreach my $bi (@buildinfos) {
4597         responder_send_command("param buildinfo-filename $bi");
4598         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4599     }
4600
4601     if (deliberately_not_fast_forward) {
4602         git_for_each_ref(lrfetchrefs, sub {
4603             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4604             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4605             responder_send_command("previously $rrefname=$objid");
4606             $previously{$rrefname} = $objid;
4607         });
4608     }
4609
4610     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4611                                  dgit_privdir()."/tag");
4612     my @tagobjfns;
4613
4614     supplementary_message(__ <<'END');
4615 Push failed, while signing the tag.
4616 You can retry the push, after fixing the problem, if you like.
4617 END
4618     # If we manage to sign but fail to record it anywhere, it's fine.
4619     if ($we_are_responder) {
4620         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4621         responder_receive_files('signed-tag', @tagobjfns);
4622     } else {
4623         @tagobjfns = push_mktags($clogp,$dscpath,
4624                               $changesfile,$changesfile,
4625                               \@tagwants);
4626     }
4627     supplementary_message(__ <<'END');
4628 Push failed, *after* signing the tag.
4629 If you want to try again, you should use a new version number.
4630 END
4631
4632     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4633
4634     foreach my $tw (@tagwants) {
4635         my $tag = $tw->{Tag};
4636         my $tagobjfn = $tw->{TagObjFn};
4637         my $tag_obj_hash =
4638             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4639         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4640         runcmd_ordryrun_local
4641             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4642     }
4643
4644     supplementary_message(__ <<'END');
4645 Push failed, while updating the remote git repository - see messages above.
4646 If you want to try again, you should use a new version number.
4647 END
4648     if (!check_for_git()) {
4649         create_remote_git_repo();
4650     }
4651
4652     my @pushrefs = $forceflag.$dgithead.":".rrref();
4653     foreach my $tw (@tagwants) {
4654         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4655     }
4656
4657     runcmd_ordryrun @git,
4658         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4659     runcmd_ordryrun git_update_ref_cmd 'dgit push', lrref(), $dgithead;
4660
4661     supplementary_message(__ <<'END');
4662 Push failed, while obtaining signatures on the .changes and .dsc.
4663 If it was just that the signature failed, you may try again by using
4664 debsign by hand to sign the changes file (see the command dgit tried,
4665 above), and then dput that changes file to complete the upload.
4666 If you need to change the package, you must use a new version number.
4667 END
4668     if ($we_are_responder) {
4669         my $dryrunsuffix = act_local() ? "" : ".tmp";
4670         my @rfiles = ($dscpath, $changesfile);
4671         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4672         responder_receive_files('signed-dsc-changes',
4673                                 map { "$_$dryrunsuffix" } @rfiles);
4674     } else {
4675         if (act_local()) {
4676             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4677         } else {
4678             progress f_ "[new .dsc left in %s.tmp]", $dscpath;
4679         }
4680         sign_changes $changesfile;
4681     }
4682
4683     supplementary_message(f_ <<END, $changesfile);
4684 Push failed, while uploading package(s) to the archive server.
4685 You can retry the upload of exactly these same files with dput of:
4686   %s
4687 If that .changes file is broken, you will need to use a new version
4688 number for your next attempt at the upload.
4689 END
4690     my $host = access_cfg('upload-host','RETURN-UNDEF');
4691     my @hostarg = defined($host) ? ($host,) : ();
4692     runcmd_ordryrun @dput, @hostarg, $changesfile;
4693     printdone f_ "pushed and uploaded %s", $cversion;
4694
4695     supplementary_message('');
4696     responder_send_command("complete");
4697 }
4698
4699 sub pre_clone () {
4700     not_necessarily_a_tree();
4701 }
4702 sub cmd_clone {
4703     parseopts();
4704     my $dstdir;
4705     badusage __ "-p is not allowed with clone; specify as argument instead"
4706         if defined $package;
4707     if (@ARGV==1) {
4708         ($package) = @ARGV;
4709     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4710         ($package,$isuite) = @ARGV;
4711     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4712         ($package,$dstdir) = @ARGV;
4713     } elsif (@ARGV==3) {
4714         ($package,$isuite,$dstdir) = @ARGV;
4715     } else {
4716         badusage __ "incorrect arguments to dgit clone";
4717     }
4718     notpushing();
4719
4720     $dstdir ||= "$package";
4721     if (stat_exists $dstdir) {
4722         fail f_ "%s already exists", $dstdir;
4723     }
4724
4725     my $cwd_remove;
4726     if ($rmonerror && !$dryrun_level) {
4727         $cwd_remove= getcwd();
4728         unshift @end, sub {
4729             return unless defined $cwd_remove;
4730             if (!chdir "$cwd_remove") {
4731                 return if $!==&ENOENT;
4732                 confess "chdir $cwd_remove: $!";
4733             }
4734             printdebug "clone rmonerror removing $dstdir\n";
4735             if (stat $dstdir) {
4736                 rmtree($dstdir) or fail f_ "remove %s: %s\n", $dstdir, $!;
4737             } elsif (grep { $! == $_ }
4738                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4739             } else {
4740                 print STDERR f_ "check whether to remove %s: %s\n",
4741                                 $dstdir, $!;
4742             }
4743         };
4744     }
4745
4746     clone($dstdir);
4747     $cwd_remove = undef;
4748 }
4749
4750 sub branchsuite () {
4751     my $branch = git_get_symref();
4752     if (defined $branch && $branch =~ m#$lbranch_re#o) {
4753         return $1;
4754     } else {
4755         return undef;
4756     }
4757 }
4758
4759 sub package_from_d_control () {
4760     if (!defined $package) {
4761         my $sourcep = parsecontrol('debian/control','debian/control');
4762         $package = getfield $sourcep, 'Source';
4763     }
4764 }
4765
4766 sub fetchpullargs () {
4767     package_from_d_control();
4768     if (@ARGV==0) {
4769         $isuite = branchsuite();
4770         if (!$isuite) {
4771             my $clogp = parsechangelog();
4772             my $clogsuite = getfield $clogp, 'Distribution';
4773             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4774         }
4775     } elsif (@ARGV==1) {
4776         ($isuite) = @ARGV;
4777     } else {
4778         badusage __ "incorrect arguments to dgit fetch or dgit pull";
4779     }
4780     notpushing();
4781 }
4782
4783 sub cmd_fetch {
4784     parseopts();
4785     fetchpullargs();
4786     dofetch();
4787 }
4788
4789 sub cmd_pull {
4790     parseopts();
4791     fetchpullargs();
4792     if (quiltmode_splitbrain()) {
4793         my ($format, $fopts) = get_source_format();
4794         madformat($format) and fail f_ <<END, $quilt_mode
4795 dgit pull not yet supported in split view mode (--quilt=%s)
4796 END
4797     }
4798     pull();
4799 }
4800
4801 sub cmd_checkout {
4802     parseopts();
4803     package_from_d_control();
4804     @ARGV==1 or badusage __ "dgit checkout needs a suite argument";
4805     ($isuite) = @ARGV;
4806     notpushing();
4807
4808     foreach my $canon (qw(0 1)) {
4809         if (!$canon) {
4810             $csuite= $isuite;
4811         } else {
4812             undef $csuite;
4813             canonicalise_suite();
4814         }
4815         if (length git_get_ref lref()) {
4816             # local branch already exists, yay
4817             last;
4818         }
4819         if (!length git_get_ref lrref()) {
4820             if (!$canon) {
4821                 # nope
4822                 next;
4823             }
4824             dofetch();
4825         }
4826         # now lrref exists
4827         runcmd (@git, qw(update-ref), lref(), lrref(), '');
4828         last;
4829     }
4830     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
4831         "dgit checkout $isuite";
4832     runcmd (@git, qw(checkout), lbranch());
4833 }
4834
4835 sub cmd_update_vcs_git () {
4836     my $specsuite;
4837     if (@ARGV==0 || $ARGV[0] =~ m/^-/) {
4838         ($specsuite,) = split /\;/, cfg 'dgit.vcs-git.suites';
4839     } else {
4840         ($specsuite) = (@ARGV);
4841         shift @ARGV;
4842     }
4843     my $dofetch=1;
4844     if (@ARGV) {
4845         if ($ARGV[0] eq '-') {
4846             $dofetch = 0;
4847         } elsif ($ARGV[0] eq '-') {
4848             shift;
4849         }
4850     }
4851
4852     package_from_d_control();
4853     my $ctrl;
4854     if ($specsuite eq '.') {
4855         $ctrl = parsecontrol 'debian/control', 'debian/control';
4856     } else {
4857         $isuite = $specsuite;
4858         get_archive_dsc();
4859         $ctrl = $dsc;
4860     }
4861     my $url = getfield $ctrl, 'Vcs-Git';
4862
4863     my @cmd;
4864     my $orgurl = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
4865     if (!defined $orgurl) {
4866         print STDERR f_ "setting up vcs-git: %s\n", $url;
4867         @cmd = (@git, qw(remote add vcs-git), $url);
4868     } elsif ($orgurl eq $url) {
4869         print STDERR f_ "vcs git already configured: %s\n", $url;
4870     } else {
4871         print STDERR f_ "changing vcs-git url to: %s\n", $url;
4872         @cmd = (@git, qw(remote set-url vcs-git), $url);
4873     }
4874     runcmd_ordryrun_local @cmd;
4875     if ($dofetch) {
4876         print f_ "fetching (%s)\n", "@ARGV";
4877         runcmd_ordryrun_local @git, qw(fetch vcs-git), @ARGV;
4878     }
4879 }
4880
4881 sub prep_push () {
4882     parseopts();
4883     build_or_push_prep_early();
4884     pushing();
4885     check_not_dirty();
4886     my $specsuite;
4887     if (@ARGV==0) {
4888     } elsif (@ARGV==1) {
4889         ($specsuite) = (@ARGV);
4890     } else {
4891         badusage f_ "incorrect arguments to dgit %s", $subcommand;
4892     }
4893     if ($new_package) {
4894         local ($package) = $existing_package; # this is a hack
4895         canonicalise_suite();
4896     } else {
4897         canonicalise_suite();
4898     }
4899     if (defined $specsuite &&
4900         $specsuite ne $isuite &&
4901         $specsuite ne $csuite) {
4902             fail f_ "dgit %s: changelog specifies %s (%s)".
4903                     " but command line specifies %s",
4904                     $subcommand, $isuite, $csuite, $specsuite;
4905     }
4906 }
4907
4908 sub cmd_push {
4909     prep_push();
4910     dopush();
4911 }
4912
4913 #---------- remote commands' implementation ----------
4914
4915 sub pre_remote_push_build_host {
4916     my ($nrargs) = shift @ARGV;
4917     my (@rargs) = @ARGV[0..$nrargs-1];
4918     @ARGV = @ARGV[$nrargs..$#ARGV];
4919     die unless @rargs;
4920     my ($dir,$vsnwant) = @rargs;
4921     # vsnwant is a comma-separated list; we report which we have
4922     # chosen in our ready response (so other end can tell if they
4923     # offered several)
4924     $debugprefix = ' ';
4925     $we_are_responder = 1;
4926     $us .= " (build host)";
4927
4928     open PI, "<&STDIN" or confess $!;
4929     open STDIN, "/dev/null" or confess $!;
4930     open PO, ">&STDOUT" or confess $!;
4931     autoflush PO 1;
4932     open STDOUT, ">&STDERR" or confess $!;
4933     autoflush STDOUT 1;
4934
4935     $vsnwant //= 1;
4936     ($protovsn) = grep {
4937         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4938     } @rpushprotovsn_support;
4939
4940     fail f_ "build host has dgit rpush protocol versions %s".
4941             " but invocation host has %s",
4942             (join ",", @rpushprotovsn_support), $vsnwant
4943         unless defined $protovsn;
4944
4945     changedir $dir;
4946 }
4947 sub cmd_remote_push_build_host {
4948     responder_send_command("dgit-remote-push-ready $protovsn");
4949     &cmd_push;
4950 }
4951
4952 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4953 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4954 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4955 #     a good error message)
4956
4957 sub rpush_handle_protovsn_bothends () {
4958     if ($protovsn < 4) {
4959         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4960     }
4961     select_tagformat();
4962 }
4963
4964 our $i_tmp;
4965
4966 sub i_cleanup {
4967     local ($@, $?);
4968     my $report = i_child_report();
4969     if (defined $report) {
4970         printdebug "($report)\n";
4971     } elsif ($i_child_pid) {
4972         printdebug "(killing build host child $i_child_pid)\n";
4973         kill 15, $i_child_pid;
4974     }
4975     if (defined $i_tmp && !defined $initiator_tempdir) {
4976         changedir "/";
4977         eval { rmtree $i_tmp; };
4978     }
4979 }
4980
4981 END {
4982     return unless forkcheck_mainprocess();
4983     i_cleanup();
4984 }
4985
4986 sub i_method {
4987     my ($base,$selector,@args) = @_;
4988     $selector =~ s/\-/_/g;
4989     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4990 }
4991
4992 sub pre_rpush () {
4993     not_necessarily_a_tree();
4994 }
4995 sub cmd_rpush {
4996     my $host = nextarg;
4997     my $dir;
4998     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4999         $host = $1;
5000         $dir = $'; #';
5001     } else {
5002         $dir = nextarg;
5003     }
5004     $dir =~ s{^-}{./-};
5005     my @rargs = ($dir);
5006     push @rargs, join ",", @rpushprotovsn_support;
5007     my @rdgit;
5008     push @rdgit, @dgit;
5009     push @rdgit, @ropts;
5010     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
5011     push @rdgit, @ARGV;
5012     my @cmd = (@ssh, $host, shellquote @rdgit);
5013     debugcmd "+",@cmd;
5014
5015     $we_are_initiator=1;
5016
5017     if (defined $initiator_tempdir) {
5018         rmtree $initiator_tempdir;
5019         mkdir $initiator_tempdir, 0700
5020             or fail f_ "create %s: %s", $initiator_tempdir, $!;
5021         $i_tmp = $initiator_tempdir;
5022     } else {
5023         $i_tmp = tempdir();
5024     }
5025     $i_child_pid = open2(\*RO, \*RI, @cmd);
5026     changedir $i_tmp;
5027     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
5028     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
5029     $supplementary_message = '' unless $protovsn >= 3;
5030
5031     for (;;) {
5032         my ($icmd,$iargs) = initiator_expect {
5033             m/^(\S+)(?: (.*))?$/;
5034             ($1,$2);
5035         };
5036         i_method "i_resp", $icmd, $iargs;
5037     }
5038 }
5039
5040 sub i_resp_progress ($) {
5041     my ($rhs) = @_;
5042     my $msg = protocol_read_bytes \*RO, $rhs;
5043     progress $msg;
5044 }
5045
5046 sub i_resp_supplementary_message ($) {
5047     my ($rhs) = @_;
5048     $supplementary_message = protocol_read_bytes \*RO, $rhs;
5049 }
5050
5051 sub i_resp_complete {
5052     my $pid = $i_child_pid;
5053     $i_child_pid = undef; # prevents killing some other process with same pid
5054     printdebug "waiting for build host child $pid...\n";
5055     my $got = waitpid $pid, 0;
5056     confess $! unless $got == $pid;
5057     fail f_ "build host child failed: %s", waitstatusmsg() if $?;
5058
5059     i_cleanup();
5060     printdebug __ "all done\n";
5061     finish 0;
5062 }
5063
5064 sub i_resp_file ($) {
5065     my ($keyword) = @_;
5066     my $localname = i_method "i_localname", $keyword;
5067     my $localpath = "$i_tmp/$localname";
5068     stat_exists $localpath and
5069         badproto \*RO, f_ "file %s (%s) twice", $keyword, $localpath;
5070     protocol_receive_file \*RO, $localpath;
5071     i_method "i_file", $keyword;
5072 }
5073
5074 our %i_param;
5075
5076 sub i_resp_param ($) {
5077     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, __ "bad param spec";
5078     $i_param{$1} = $2;
5079 }
5080
5081 sub i_resp_previously ($) {
5082     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
5083         or badproto \*RO, __ "bad previously spec";
5084     my $r = system qw(git check-ref-format), $1;
5085     confess "bad previously ref spec ($r)" if $r;
5086     $previously{$1} = $2;
5087 }
5088
5089 our %i_wanted;
5090
5091 sub i_resp_want ($) {
5092     my ($keyword) = @_;
5093     die "$keyword ?" if $i_wanted{$keyword}++;
5094
5095     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
5096     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
5097     die unless $isuite =~ m/^$suite_re$/;
5098
5099     pushing();
5100     rpush_handle_protovsn_bothends();
5101
5102     fail f_ "rpush negotiated protocol version %s".
5103         " which does not support quilt mode %s",
5104         $protovsn, $quilt_mode
5105         if quiltmode_splitbrain;
5106
5107     my @localpaths = i_method "i_want", $keyword;
5108     printdebug "[[  $keyword @localpaths\n";
5109     foreach my $localpath (@localpaths) {
5110         protocol_send_file \*RI, $localpath;
5111     }
5112     print RI "files-end\n" or confess $!;
5113 }
5114
5115 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
5116
5117 sub i_localname_parsed_changelog {
5118     return "remote-changelog.822";
5119 }
5120 sub i_file_parsed_changelog {
5121     ($i_clogp, $i_version, $i_dscfn) =
5122         push_parse_changelog "$i_tmp/remote-changelog.822";
5123     die if $i_dscfn =~ m#/|^\W#;
5124 }
5125
5126 sub i_localname_dsc {
5127     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5128     return $i_dscfn;
5129 }
5130 sub i_file_dsc { }
5131
5132 sub i_localname_buildinfo ($) {
5133     my $bi = $i_param{'buildinfo-filename'};
5134     defined $bi or badproto \*RO, "buildinfo before filename";
5135     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
5136     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
5137         or badproto \*RO, "improper buildinfo filename";
5138     return $&;
5139 }
5140 sub i_file_buildinfo {
5141     my $bi = $i_param{'buildinfo-filename'};
5142     my $bd = parsecontrol "$i_tmp/$bi", $bi;
5143     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
5144     if (!forceing [qw(buildinfo-changes-mismatch)]) {
5145         files_compare_inputs($bd, $ch);
5146         (getfield $bd, $_) eq (getfield $ch, $_) or
5147             fail f_ "buildinfo mismatch in field %s", $_
5148             foreach qw(Source Version);
5149         !defined $bd->{$_} or
5150             fail f_ "buildinfo contains forbidden field %s", $_
5151             foreach qw(Changes Changed-by Distribution);
5152     }
5153     push @i_buildinfos, $bi;
5154     delete $i_param{'buildinfo-filename'};
5155 }
5156
5157 sub i_localname_changes {
5158     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5159     $i_changesfn = $i_dscfn;
5160     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
5161     return $i_changesfn;
5162 }
5163 sub i_file_changes { }
5164
5165 sub i_want_signed_tag {
5166     printdebug Dumper(\%i_param, $i_dscfn);
5167     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
5168         && defined $i_param{'csuite'}
5169         or badproto \*RO, "premature desire for signed-tag";
5170     my $head = $i_param{'head'};
5171     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
5172
5173     my $maintview = $i_param{'maint-view'};
5174     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
5175
5176     select_tagformat();
5177     if ($protovsn >= 4) {
5178         my $p = $i_param{'tagformat'} // '<undef>';
5179         $p eq $tagformat
5180             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
5181     }
5182
5183     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
5184     $csuite = $&;
5185     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
5186
5187     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
5188
5189     return
5190         push_mktags $i_clogp, $i_dscfn,
5191             $i_changesfn, (__ 'remote changes file'),
5192             \@tagwants;
5193 }
5194
5195 sub i_want_signed_dsc_changes {
5196     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
5197     sign_changes $i_changesfn;
5198     return ($i_dscfn, $i_changesfn, @i_buildinfos);
5199 }
5200
5201 #---------- building etc. ----------
5202
5203 our $version;
5204 our $sourcechanges;
5205 our $dscfn;
5206
5207 #----- `3.0 (quilt)' handling -----
5208
5209 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
5210
5211 sub quiltify_dpkg_commit ($$$;$) {
5212     my ($patchname,$author,$msg, $xinfo) = @_;
5213     $xinfo //= '';
5214
5215     mkpath '.git/dgit'; # we are in playtree
5216     my $descfn = ".git/dgit/quilt-description.tmp";
5217     open O, '>', $descfn or confess "$descfn: $!";
5218     $msg =~ s/\n+/\n\n/;
5219     print O <<END or confess $!;
5220 From: $author
5221 ${xinfo}Subject: $msg
5222 ---
5223
5224 END
5225     close O or confess $!;
5226
5227     {
5228         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
5229         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
5230         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
5231         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
5232     }
5233 }
5234
5235 sub quiltify_trees_differ ($$;$$$) {
5236     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
5237     # returns true iff the two tree objects differ other than in debian/
5238     # with $finegrained,
5239     # returns bitmask 01 - differ in upstream files except .gitignore
5240     #                 02 - differ in .gitignore
5241     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
5242     #  is set for each modified .gitignore filename $fn
5243     # if $unrepres is defined, array ref to which is appeneded
5244     #  a list of unrepresentable changes (removals of upstream files
5245     #  (as messages)
5246     local $/=undef;
5247     my @cmd = (@git, qw(diff-tree -z --no-renames));
5248     push @cmd, qw(--name-only) unless $unrepres;
5249     push @cmd, qw(-r) if $finegrained || $unrepres;
5250     push @cmd, $x, $y;
5251     my $diffs= cmdoutput @cmd;
5252     my $r = 0;
5253     my @lmodes;
5254     foreach my $f (split /\0/, $diffs) {
5255         if ($unrepres && !@lmodes) {
5256             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
5257             next;
5258         }
5259         my ($oldmode,$newmode) = @lmodes;
5260         @lmodes = ();
5261
5262         next if $f =~ m#^debian(?:/.*)?$#s;
5263
5264         if ($unrepres) {
5265             eval {
5266                 die __ "not a plain file or symlink\n"
5267                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
5268                            $oldmode =~ m/^(?:10|12)\d{4}$/;
5269                 if ($oldmode =~ m/[^0]/ &&
5270                     $newmode =~ m/[^0]/) {
5271                     # both old and new files exist
5272                     die __ "mode or type changed\n" if $oldmode ne $newmode;
5273                     die __ "modified symlink\n" unless $newmode =~ m/^10/;
5274                 } elsif ($oldmode =~ m/[^0]/) {
5275                     # deletion
5276                     die __ "deletion of symlink\n"
5277                         unless $oldmode =~ m/^10/;
5278                 } else {
5279                     # creation
5280                     die __ "creation with non-default mode\n"
5281                         unless $newmode =~ m/^100644$/ or
5282                                $newmode =~ m/^120000$/;
5283                 }
5284             };
5285             if ($@) {
5286                 local $/="\n"; chomp $@;
5287                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
5288             }
5289         }
5290
5291         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
5292         $r |= $isignore ? 02 : 01;
5293         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
5294     }
5295     printdebug "quiltify_trees_differ $x $y => $r\n";
5296     return $r;
5297 }
5298
5299 sub quiltify_tree_sentinelfiles ($) {
5300     # lists the `sentinel' files present in the tree
5301     my ($x) = @_;
5302     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
5303         qw(-- debian/rules debian/control);
5304     $r =~ s/\n/,/g;
5305     return $r;
5306 }
5307
5308 sub quiltify_splitbrain_needed () {
5309     if (!$split_brain) {
5310         progress __ "dgit view: changes are required...";
5311         runcmd @git, qw(checkout -q -b dgit-view);
5312         $split_brain = 1;
5313     }
5314 }
5315
5316 sub quiltify_splitbrain ($$$$$$$) {
5317     my ($clogp, $unapplied, $headref, $oldtiptree, $diffbits,
5318         $editedignores, $cachekey) = @_;
5319     my $gitignore_special = 1;
5320     if ($quilt_mode !~ m/gbp|dpm/) {
5321         # treat .gitignore just like any other upstream file
5322         $diffbits = { %$diffbits };
5323         $_ = !!$_ foreach values %$diffbits;
5324         $gitignore_special = 0;
5325     }
5326     # We would like any commits we generate to be reproducible
5327     my @authline = clogp_authline($clogp);
5328     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
5329     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
5330     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
5331     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
5332     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
5333     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
5334
5335     my $fulldiffhint = sub {
5336         my ($x,$y) = @_;
5337         my $cmd = "git diff $x $y -- :/ ':!debian'";
5338         $cmd .= " ':!/.gitignore' ':!*/.gitignore'" if $gitignore_special;
5339         return f_ "\nFor full diff showing the problem(s), type:\n %s\n",
5340                   $cmd;
5341     };
5342
5343     if ($quilt_mode =~ m/gbp|unapplied/ &&
5344         ($diffbits->{O2H} & 01)) {
5345         my $msg = f_
5346  "--quilt=%s specified, implying patches-unapplied git tree\n".
5347  " but git tree differs from orig in upstream files.",
5348                      $quilt_mode;
5349         $msg .= $fulldiffhint->($unapplied, 'HEAD');
5350         if (!stat_exists "debian/patches") {
5351             $msg .= __
5352  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
5353         }
5354         fail $msg;
5355     }
5356     if ($quilt_mode =~ m/dpm/ &&
5357         ($diffbits->{H2A} & 01)) {
5358         fail +(f_ <<END, $quilt_mode). $fulldiffhint->($oldtiptree,'HEAD');
5359 --quilt=%s specified, implying patches-applied git tree
5360  but git tree differs from result of applying debian/patches to upstream
5361 END
5362     }
5363     if ($quilt_mode =~ m/gbp|unapplied/ &&
5364         ($diffbits->{O2A} & 01)) { # some patches
5365         quiltify_splitbrain_needed();
5366         progress __ "dgit view: creating patches-applied version using gbp pq";
5367         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
5368         # gbp pq import creates a fresh branch; push back to dgit-view
5369         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
5370         runcmd @git, qw(checkout -q dgit-view);
5371     }
5372     if ($quilt_mode =~ m/gbp|dpm/ &&
5373         ($diffbits->{O2A} & 02)) {
5374         fail f_ <<END, $quilt_mode;
5375 --quilt=%s specified, implying that HEAD is for use with a
5376  tool which does not create patches for changes to upstream
5377  .gitignores: but, such patches exist in debian/patches.
5378 END
5379     }
5380     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5381         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5382         quiltify_splitbrain_needed();
5383         progress __
5384             "dgit view: creating patch to represent .gitignore changes";
5385         ensuredir "debian/patches";
5386         my $gipatch = "debian/patches/auto-gitignore";
5387         open GIPATCH, ">>", "$gipatch" or confess "$gipatch: $!";
5388         stat GIPATCH or confess "$gipatch: $!";
5389         fail f_ "%s already exists; but want to create it".
5390                 " to record .gitignore changes",
5391                 $gipatch
5392             if (stat _)[7];
5393         print GIPATCH +(__ <<END).<<ENDU or die "$gipatch: $!";
5394 Subject: Update .gitignore from Debian packaging branch
5395
5396 The Debian packaging git branch contains these updates to the upstream
5397 .gitignore file(s).  This patch is autogenerated, to provide these
5398 updates to users of the official Debian archive view of the package.
5399 END
5400
5401 [dgit ($our_version) update-gitignore]
5402 ---
5403 ENDU
5404         close GIPATCH or die "$gipatch: $!";
5405         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5406             $unapplied, $headref, "--", sort keys %$editedignores;
5407         open SERIES, "+>>", "debian/patches/series" or confess $!;
5408         defined seek SERIES, -1, 2 or $!==EINVAL or confess $!;
5409         my $newline;
5410         defined read SERIES, $newline, 1 or confess $!;
5411         print SERIES "\n" or confess $! unless $newline eq "\n";
5412         print SERIES "auto-gitignore\n" or confess $!;
5413         close SERIES or die  $!;
5414         runcmd @git, qw(add -f -- debian/patches/series), $gipatch;
5415         commit_admin +(__ <<END).<<ENDU
5416 Commit patch to update .gitignore
5417 END
5418
5419 [dgit ($our_version) update-gitignore-quilt-fixup]
5420 ENDU
5421     }
5422
5423     my $dgitview = git_rev_parse 'HEAD';
5424
5425     changedir $maindir;
5426     reflog_cache_insert "refs/$splitbraincache", $cachekey, $dgitview;
5427
5428     changedir "$playground/work";
5429
5430     my $saved = maybe_split_brain_save $headref, $dgitview, __ "converted";
5431     progress f_ "dgit view: created (%s)", $saved;
5432 }
5433
5434 sub quiltify ($$$$) {
5435     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5436
5437     # Quilt patchification algorithm
5438     #
5439     # We search backwards through the history of the main tree's HEAD
5440     # (T) looking for a start commit S whose tree object is identical
5441     # to to the patch tip tree (ie the tree corresponding to the
5442     # current dpkg-committed patch series).  For these purposes
5443     # `identical' disregards anything in debian/ - this wrinkle is
5444     # necessary because dpkg-source treates debian/ specially.
5445     #
5446     # We can only traverse edges where at most one of the ancestors'
5447     # trees differs (in changes outside in debian/).  And we cannot
5448     # handle edges which change .pc/ or debian/patches.  To avoid
5449     # going down a rathole we avoid traversing edges which introduce
5450     # debian/rules or debian/control.  And we set a limit on the
5451     # number of edges we are willing to look at.
5452     #
5453     # If we succeed, we walk forwards again.  For each traversed edge
5454     # PC (with P parent, C child) (starting with P=S and ending with
5455     # C=T) to we do this:
5456     #  - git checkout C
5457     #  - dpkg-source --commit with a patch name and message derived from C
5458     # After traversing PT, we git commit the changes which
5459     # should be contained within debian/patches.
5460
5461     # The search for the path S..T is breadth-first.  We maintain a
5462     # todo list containing search nodes.  A search node identifies a
5463     # commit, and looks something like this:
5464     #  $p = {
5465     #      Commit => $git_commit_id,
5466     #      Child => $c,                          # or undef if P=T
5467     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5468     #      Nontrivial => true iff $p..$c has relevant changes
5469     #  };
5470
5471     my @todo;
5472     my @nots;
5473     my $sref_S;
5474     my $max_work=100;
5475     my %considered; # saves being exponential on some weird graphs
5476
5477     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5478
5479     my $not = sub {
5480         my ($search,$whynot) = @_;
5481         printdebug " search NOT $search->{Commit} $whynot\n";
5482         $search->{Whynot} = $whynot;
5483         push @nots, $search;
5484         no warnings qw(exiting);
5485         next;
5486     };
5487
5488     push @todo, {
5489         Commit => $target,
5490     };
5491
5492     while (@todo) {
5493         my $c = shift @todo;
5494         next if $considered{$c->{Commit}}++;
5495
5496         $not->($c, __ "maximum search space exceeded") if --$max_work <= 0;
5497
5498         printdebug "quiltify investigate $c->{Commit}\n";
5499
5500         # are we done?
5501         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5502             printdebug " search finished hooray!\n";
5503             $sref_S = $c;
5504             last;
5505         }
5506
5507         quiltify_nofix_bail " $c->{Commit}", " (tree object $oldtiptree)";
5508         if ($quilt_mode eq 'smash') {
5509             printdebug " search quitting smash\n";
5510             last;
5511         }
5512
5513         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5514         $not->($c, f_ "has %s not %s", $c_sentinels, $t_sentinels)
5515             if $c_sentinels ne $t_sentinels;
5516
5517         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5518         $commitdata =~ m/\n\n/;
5519         $commitdata =~ $`;
5520         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5521         @parents = map { { Commit => $_, Child => $c } } @parents;
5522
5523         $not->($c, __ "root commit") if !@parents;
5524
5525         foreach my $p (@parents) {
5526             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5527         }
5528         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5529         $not->($c, f_ "merge (%s nontrivial parents)", $ndiffers)
5530             if $ndiffers > 1;
5531
5532         foreach my $p (@parents) {
5533             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5534
5535             my @cmd= (@git, qw(diff-tree -r --name-only),
5536                       $p->{Commit},$c->{Commit},
5537                       qw(-- debian/patches .pc debian/source/format));
5538             my $patchstackchange = cmdoutput @cmd;
5539             if (length $patchstackchange) {
5540                 $patchstackchange =~ s/\n/,/g;
5541                 $not->($p, f_ "changed %s", $patchstackchange);
5542             }
5543
5544             printdebug " search queue P=$p->{Commit} ",
5545                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5546             push @todo, $p;
5547         }
5548     }
5549
5550     if (!$sref_S) {
5551         printdebug "quiltify want to smash\n";
5552
5553         my $abbrev = sub {
5554             my $x = $_[0]{Commit};
5555             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5556             return $x;
5557         };
5558         if ($quilt_mode eq 'linear') {
5559             print STDERR f_
5560                 "\n%s: error: quilt fixup cannot be linear.  Stopped at:\n",
5561                 $us;
5562             my $all_gdr = !!@nots;
5563             foreach my $notp (@nots) {
5564                 my $c = $notp->{Child};
5565                 my $cprange = $abbrev->($notp);
5566                 $cprange .= "..".$abbrev->($c) if $c;
5567                 print STDERR f_ "%s:  %s: %s\n",
5568                     $us, $cprange, $notp->{Whynot};
5569                 $all_gdr &&= $notp->{Child} &&
5570                     (git_cat_file $notp->{Child}{Commit}, 'commit')
5571                     =~ m{^\[git-debrebase(?! split[: ]).*\]$}m;
5572             }
5573             print STDERR "\n";
5574             $failsuggestion =
5575                 [ grep { $_->[0] ne 'quilt-mode' } @$failsuggestion ]
5576                 if $all_gdr;
5577             print STDERR "$us: $_->[1]\n" foreach @$failsuggestion;
5578             fail __
5579  "quilt history linearisation failed.  Search \`quilt fixup' in dgit(7).\n";
5580         } elsif ($quilt_mode eq 'smash') {
5581         } elsif ($quilt_mode eq 'auto') {
5582             progress __ "quilt fixup cannot be linear, smashing...";
5583         } else {
5584             confess "$quilt_mode ?";
5585         }
5586
5587         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5588         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5589         my $ncommits = 3;
5590         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5591
5592         quiltify_dpkg_commit "auto-$version-$target-$time",
5593             (getfield $clogp, 'Maintainer'),
5594             (f_ "Automatically generated patch (%s)\n".
5595              "Last (up to) %s git changes, FYI:\n\n",
5596              $clogp->{Version}, $ncommits).
5597              $msg;
5598         return;
5599     }
5600
5601     progress __ "quiltify linearisation planning successful, executing...";
5602
5603     for (my $p = $sref_S;
5604          my $c = $p->{Child};
5605          $p = $p->{Child}) {
5606         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5607         next unless $p->{Nontrivial};
5608
5609         my $cc = $c->{Commit};
5610
5611         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5612         $commitdata =~ m/\n\n/ or die "$c ?";
5613         $commitdata = $`;
5614         my $msg = $'; #';
5615         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5616         my $author = $1;
5617
5618         my $commitdate = cmdoutput
5619             @git, qw(log -n1 --pretty=format:%aD), $cc;
5620
5621         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5622
5623         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5624         $strip_nls->();
5625
5626         my $title = $1;
5627         my $patchname;
5628         my $patchdir;
5629
5630         my $gbp_check_suitable = sub {
5631             $_ = shift;
5632             my ($what) = @_;
5633
5634             eval {
5635                 die __ "contains unexpected slashes\n" if m{//} || m{/$};
5636                 die __ "contains leading punctuation\n" if m{^\W} || m{/\W};
5637                 die __ "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5638                 die __ "is series file\n" if m{$series_filename_re}o;
5639                 die __ "too long\n" if length > 200;
5640             };
5641             return $_ unless $@;
5642             print STDERR f_
5643                 "quiltifying commit %s: ignoring/dropping Gbp-Pq %s: %s",
5644                 $cc, $what, $@;
5645             return undef;
5646         };
5647
5648         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5649                            gbp-pq-name: \s* )
5650                        (\S+) \s* \n //ixm) {
5651             $patchname = $gbp_check_suitable->($1, 'Name');
5652         }
5653         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5654                            gbp-pq-topic: \s* )
5655                        (\S+) \s* \n //ixm) {
5656             $patchdir = $gbp_check_suitable->($1, 'Topic');
5657         }
5658
5659         $strip_nls->();
5660
5661         if (!defined $patchname) {
5662             $patchname = $title;
5663             $patchname =~ s/[.:]$//;
5664             use Text::Iconv;
5665             eval {
5666                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5667                 my $translitname = $converter->convert($patchname);
5668                 die unless defined $translitname;
5669                 $patchname = $translitname;
5670             };
5671             print STDERR
5672                 +(f_ "dgit: patch title transliteration error: %s", $@)
5673                 if $@;
5674             $patchname =~ y/ A-Z/-a-z/;
5675             $patchname =~ y/-a-z0-9_.+=~//cd;
5676             $patchname =~ s/^\W/x-$&/;
5677             $patchname = substr($patchname,0,40);
5678             $patchname .= ".patch";
5679         }
5680         if (!defined $patchdir) {
5681             $patchdir = '';
5682         }
5683         if (length $patchdir) {
5684             $patchname = "$patchdir/$patchname";
5685         }
5686         if ($patchname =~ m{^(.*)/}) {
5687             mkpath "debian/patches/$1";
5688         }
5689
5690         my $index;
5691         for ($index='';
5692              stat "debian/patches/$patchname$index";
5693              $index++) { }
5694         $!==ENOENT or confess "$patchname$index $!";
5695
5696         runcmd @git, qw(checkout -q), $cc;
5697
5698         # We use the tip's changelog so that dpkg-source doesn't
5699         # produce complaining messages from dpkg-parsechangelog.  None
5700         # of the information dpkg-source gets from the changelog is
5701         # actually relevant - it gets put into the original message
5702         # which dpkg-source provides our stunt editor, and then
5703         # overwritten.
5704         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5705
5706         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5707             "Date: $commitdate\n".
5708             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5709
5710         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5711     }
5712
5713     runcmd @git, qw(checkout -q master);
5714 }
5715
5716 sub build_maybe_quilt_fixup () {
5717     my ($format,$fopts) = get_source_format;
5718     return unless madformat_wantfixup $format;
5719     # sigh
5720
5721     check_for_vendor_patches();
5722
5723     if (quiltmode_splitbrain) {
5724         fail <<END unless access_cfg_tagformats_can_splitbrain;
5725 quilt mode $quilt_mode requires split view so server needs to support
5726  both "new" and "maint" tag formats, but config says it doesn't.
5727 END
5728     }
5729
5730     my $clogp = parsechangelog();
5731     my $headref = git_rev_parse('HEAD');
5732     my $symref = git_get_symref();
5733
5734     if ($quilt_mode eq 'linear'
5735         && !$fopts->{'single-debian-patch'}
5736         && branch_is_gdr($headref)) {
5737         # This is much faster.  It also makes patches that gdr
5738         # likes better for future updates without laundering.
5739         #
5740         # However, it can fail in some casses where we would
5741         # succeed: if there are existing patches, which correspond
5742         # to a prefix of the branch, but are not in gbp/gdr
5743         # format, gdr will fail (exiting status 7), but we might
5744         # be able to figure out where to start linearising.  That
5745         # will be slower so hopefully there's not much to do.
5746         my @cmd = (@git_debrebase,
5747                    qw(--noop-ok -funclean-mixed -funclean-ordering
5748                       make-patches --quiet-would-amend));
5749         # We tolerate soe snags that gdr wouldn't, by default.
5750         if (act_local()) {
5751             debugcmd "+",@cmd;
5752             $!=0; $?=-1;
5753             failedcmd @cmd
5754                 if system @cmd
5755                 and not ($? == 7*256 or
5756                          $? == -1 && $!==ENOENT);
5757         } else {
5758             dryrun_report @cmd;
5759         }
5760         $headref = git_rev_parse('HEAD');
5761     }
5762
5763     prep_ud();
5764     changedir $playground;
5765
5766     my $upstreamversion = upstreamversion $version;
5767
5768     if ($fopts->{'single-debian-patch'}) {
5769         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5770     } else {
5771         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5772     }
5773
5774     changedir $maindir;
5775     runcmd_ordryrun_local
5776         @git, qw(pull --ff-only -q), "$playground/work", qw(master);
5777 }
5778
5779 sub unpack_playtree_mkwork ($) {
5780     my ($headref) = @_;
5781
5782     mkdir "work" or confess $!;
5783     changedir "work";
5784     mktree_in_ud_here();
5785     runcmd @git, qw(reset -q --hard), $headref;
5786 }
5787
5788 sub unpack_playtree_linkorigs ($$) {
5789     my ($upstreamversion, $fn) = @_;
5790     # calls $fn->($leafname);
5791
5792     my $bpd_abs = bpd_abs();
5793     opendir QFD, $bpd_abs or fail "buildproductsdir: $bpd_abs: $!";
5794     while ($!=0, defined(my $b = readdir QFD)) {
5795         my $f = bpd_abs()."/".$b;
5796         {
5797             local ($debuglevel) = $debuglevel-1;
5798             printdebug "QF linkorigs $b, $f ?\n";
5799         }
5800         next unless is_orig_file_of_vsn $b, $upstreamversion;
5801         printdebug "QF linkorigs $b, $f Y\n";
5802         link_ltarget $f, $b or die "$b $!";
5803         $fn->($b);
5804     }
5805     die "$buildproductsdir: $!" if $!;
5806     closedir QFD;
5807 }
5808
5809 sub quilt_fixup_delete_pc () {
5810     runcmd @git, qw(rm -rqf .pc);
5811     commit_admin +(__ <<END).<<ENDU
5812 Commit removal of .pc (quilt series tracking data)
5813 END
5814
5815 [dgit ($our_version) upgrade quilt-remove-pc]
5816 ENDU
5817 }
5818
5819 sub quilt_fixup_singlepatch ($$$) {
5820     my ($clogp, $headref, $upstreamversion) = @_;
5821
5822     progress __ "starting quiltify (single-debian-patch)";
5823
5824     # dpkg-source --commit generates new patches even if
5825     # single-debian-patch is in debian/source/options.  In order to
5826     # get it to generate debian/patches/debian-changes, it is
5827     # necessary to build the source package.
5828
5829     unpack_playtree_linkorigs($upstreamversion, sub { });
5830     unpack_playtree_mkwork($headref);
5831
5832     rmtree("debian/patches");
5833
5834     runcmd @dpkgsource, qw(-b .);
5835     changedir "..";
5836     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5837     rename srcfn("$upstreamversion", "/debian/patches"),
5838         "work/debian/patches"
5839         or $!==ENOENT
5840         or confess "install d/patches: $!";
5841
5842     changedir "work";
5843     commit_quilty_patch();
5844 }
5845
5846 sub quilt_make_fake_dsc ($) {
5847     my ($upstreamversion) = @_;
5848
5849     my $fakeversion="$upstreamversion-~~DGITFAKE";
5850
5851     my $fakedsc=new IO::File 'fake.dsc', '>' or confess $!;
5852     print $fakedsc <<END or confess $!;
5853 Format: 3.0 (quilt)
5854 Source: $package
5855 Version: $fakeversion
5856 Files:
5857 END
5858
5859     my $dscaddfile=sub {
5860         my ($b) = @_;
5861
5862         my $md = new Digest::MD5;
5863
5864         my $fh = new IO::File $b, '<' or die "$b $!";
5865         stat $fh or confess $!;
5866         my $size = -s _;
5867
5868         $md->addfile($fh);
5869         print $fakedsc " ".$md->hexdigest." $size $b\n" or confess $!;
5870     };
5871
5872     unpack_playtree_linkorigs($upstreamversion, $dscaddfile);
5873
5874     my @files=qw(debian/source/format debian/rules
5875                  debian/control debian/changelog);
5876     foreach my $maybe (qw(debian/patches debian/source/options
5877                           debian/tests/control)) {
5878         next unless stat_exists "$maindir/$maybe";
5879         push @files, $maybe;
5880     }
5881
5882     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5883     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C), $maindir, @files;
5884
5885     $dscaddfile->($debtar);
5886     close $fakedsc or confess $!;
5887 }
5888
5889 sub quilt_fakedsc2unapplied ($$) {
5890     my ($headref, $upstreamversion) = @_;
5891     # must be run in the playground
5892     # quilt_make_fake_dsc must have been called
5893
5894     runcmd qw(sh -ec),
5895         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5896
5897     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5898     rename $fakexdir, "fake" or die "$fakexdir $!";
5899
5900     changedir 'fake';
5901
5902     remove_stray_gits(__ "source package");
5903     mktree_in_ud_here();
5904
5905     rmtree '.pc';
5906
5907     rmtree 'debian'; # git checkout commitish paths does not delete!
5908     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5909     my $unapplied=git_add_write_tree();
5910     printdebug "fake orig tree object $unapplied\n";
5911     return $unapplied;
5912 }
5913
5914 sub quilt_check_splitbrain_cache ($$) {
5915     my ($headref, $upstreamversion) = @_;
5916     # Called only if we are in (potentially) split brain mode.
5917     # Called in playground.
5918     # Computes the cache key and looks in the cache.
5919     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5920
5921     my $splitbrain_cachekey;
5922
5923     progress f_
5924  "dgit: split brain (separate dgit view) may be needed (--quilt=%s).",
5925                 $quilt_mode;
5926     # we look in the reflog of dgit-intern/quilt-cache
5927     # we look for an entry whose message is the key for the cache lookup
5928     my @cachekey = (qw(dgit), $our_version);
5929     push @cachekey, $upstreamversion;
5930     push @cachekey, $quilt_mode;
5931     push @cachekey, $headref;
5932
5933     push @cachekey, hashfile('fake.dsc');
5934
5935     my $srcshash = Digest::SHA->new(256);
5936     my %sfs = ( %INC, '$0(dgit)' => $0 );
5937     foreach my $sfk (sort keys %sfs) {
5938         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5939         $srcshash->add($sfk,"  ");
5940         $srcshash->add(hashfile($sfs{$sfk}));
5941         $srcshash->add("\n");
5942     }
5943     push @cachekey, $srcshash->hexdigest();
5944     $splitbrain_cachekey = "@cachekey";
5945
5946     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5947
5948     my $cachehit = reflog_cache_lookup
5949         "refs/$splitbraincache", $splitbrain_cachekey;
5950
5951     if ($cachehit) {
5952         unpack_playtree_mkwork($headref);
5953         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5954         if ($cachehit ne $headref) {
5955             progress f_ "dgit view: found cached (%s)", $saved;
5956             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5957             $split_brain = 1;
5958             return ($cachehit, $splitbrain_cachekey);
5959         }
5960         progress __ "dgit view: found cached, no changes required";
5961         return ($headref, $splitbrain_cachekey);
5962     }
5963
5964     printdebug "splitbrain cache miss\n";
5965     return (undef, $splitbrain_cachekey);
5966 }
5967
5968 sub quilt_fixup_multipatch ($$$) {
5969     my ($clogp, $headref, $upstreamversion) = @_;
5970
5971     progress f_ "examining quilt state (multiple patches, %s mode)",
5972                 $quilt_mode;
5973
5974     # Our objective is:
5975     #  - honour any existing .pc in case it has any strangeness
5976     #  - determine the git commit corresponding to the tip of
5977     #    the patch stack (if there is one)
5978     #  - if there is such a git commit, convert each subsequent
5979     #    git commit into a quilt patch with dpkg-source --commit
5980     #  - otherwise convert all the differences in the tree into
5981     #    a single git commit
5982     #
5983     # To do this we:
5984
5985     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5986     # dgit would include the .pc in the git tree.)  If there isn't
5987     # one, we need to generate one by unpacking the patches that we
5988     # have.
5989     #
5990     # We first look for a .pc in the git tree.  If there is one, we
5991     # will use it.  (This is not the normal case.)
5992     #
5993     # Otherwise need to regenerate .pc so that dpkg-source --commit
5994     # can work.  We do this as follows:
5995     #     1. Collect all relevant .orig from parent directory
5996     #     2. Generate a debian.tar.gz out of
5997     #         debian/{patches,rules,source/format,source/options}
5998     #     3. Generate a fake .dsc containing just these fields:
5999     #          Format Source Version Files
6000     #     4. Extract the fake .dsc
6001     #        Now the fake .dsc has a .pc directory.
6002     # (In fact we do this in every case, because in future we will
6003     # want to search for a good base commit for generating patches.)
6004     #
6005     # Then we can actually do the dpkg-source --commit
6006     #     1. Make a new working tree with the same object
6007     #        store as our main tree and check out the main
6008     #        tree's HEAD.
6009     #     2. Copy .pc from the fake's extraction, if necessary
6010     #     3. Run dpkg-source --commit
6011     #     4. If the result has changes to debian/, then
6012     #          - git add them them
6013     #          - git add .pc if we had a .pc in-tree
6014     #          - git commit
6015     #     5. If we had a .pc in-tree, delete it, and git commit
6016     #     6. Back in the main tree, fast forward to the new HEAD
6017
6018     # Another situation we may have to cope with is gbp-style
6019     # patches-unapplied trees.
6020     #
6021     # We would want to detect these, so we know to escape into
6022     # quilt_fixup_gbp.  However, this is in general not possible.
6023     # Consider a package with a one patch which the dgit user reverts
6024     # (with git revert or the moral equivalent).
6025     #
6026     # That is indistinguishable in contents from a patches-unapplied
6027     # tree.  And looking at the history to distinguish them is not
6028     # useful because the user might have made a confusing-looking git
6029     # history structure (which ought to produce an error if dgit can't
6030     # cope, not a silent reintroduction of an unwanted patch).
6031     #
6032     # So gbp users will have to pass an option.  But we can usually
6033     # detect their failure to do so: if the tree is not a clean
6034     # patches-applied tree, quilt linearisation fails, but the tree
6035     # _is_ a clean patches-unapplied tree, we can suggest that maybe
6036     # they want --quilt=unapplied.
6037     #
6038     # To help detect this, when we are extracting the fake dsc, we
6039     # first extract it with --skip-patches, and then apply the patches
6040     # afterwards with dpkg-source --before-build.  That lets us save a
6041     # tree object corresponding to .origs.
6042
6043     my $splitbrain_cachekey;
6044
6045     quilt_make_fake_dsc($upstreamversion);
6046
6047     if (quiltmode_splitbrain()) {
6048         my $cachehit;
6049         ($cachehit, $splitbrain_cachekey) =
6050             quilt_check_splitbrain_cache($headref, $upstreamversion);
6051         return if $cachehit;
6052     }
6053     my $unapplied=quilt_fakedsc2unapplied($headref, $upstreamversion);
6054
6055     ensuredir '.pc';
6056
6057     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
6058     $!=0; $?=-1;
6059     if (system @bbcmd) {
6060         failedcmd @bbcmd if $? < 0;
6061         fail __ <<END;
6062 failed to apply your git tree's patch stack (from debian/patches/) to
6063  the corresponding upstream tarball(s).  Your source tree and .orig
6064  are probably too inconsistent.  dgit can only fix up certain kinds of
6065  anomaly (depending on the quilt mode).  Please see --quilt= in dgit(1).
6066 END
6067     }
6068
6069     changedir '..';
6070
6071     unpack_playtree_mkwork($headref);
6072
6073     my $mustdeletepc=0;
6074     if (stat_exists ".pc") {
6075         -d _ or die;
6076         progress __ "Tree already contains .pc - will use it then delete it.";
6077         $mustdeletepc=1;
6078     } else {
6079         rename '../fake/.pc','.pc' or confess $!;
6080     }
6081
6082     changedir '../fake';
6083     rmtree '.pc';
6084     my $oldtiptree=git_add_write_tree();
6085     printdebug "fake o+d/p tree object $unapplied\n";
6086     changedir '../work';
6087
6088
6089     # We calculate some guesswork now about what kind of tree this might
6090     # be.  This is mostly for error reporting.
6091
6092     my %editedignores;
6093     my @unrepres;
6094     my $diffbits = {
6095         # H = user's HEAD
6096         # O = orig, without patches applied
6097         # A = "applied", ie orig with H's debian/patches applied
6098         O2H => quiltify_trees_differ($unapplied,$headref,   1,
6099                                      \%editedignores, \@unrepres),
6100         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
6101         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
6102     };
6103
6104     my @dl;
6105     foreach my $b (qw(01 02)) {
6106         foreach my $v (qw(O2H O2A H2A)) {
6107             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
6108         }
6109     }
6110     printdebug "differences \@dl @dl.\n";
6111
6112     progress f_
6113 "%s: base trees orig=%.20s o+d/p=%.20s",
6114               $us, $unapplied, $oldtiptree;
6115     progress f_
6116 "%s: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
6117 "%s: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
6118   $us,                      $dl[0], $dl[1],              $dl[3], $dl[4],
6119   $us,                          $dl[2],                     $dl[5];
6120
6121     if (@unrepres) {
6122         print STDERR f_ "dgit:  cannot represent change: %s: %s\n",
6123                         $_->[1], $_->[0]
6124             foreach @unrepres;
6125         forceable_fail [qw(unrepresentable)], __ <<END;
6126 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
6127 END
6128     }
6129
6130     my @failsuggestion;
6131     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
6132         push @failsuggestion, [ 'unapplied', __
6133  "This might be a patches-unapplied branch." ];
6134     } elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
6135         push @failsuggestion, [ 'applied', __
6136  "This might be a patches-applied branch." ];
6137     }
6138     push @failsuggestion, [ 'quilt-mode', __
6139  "Maybe you need one of --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?" ];
6140
6141     push @failsuggestion, [ 'gitattrs', __
6142  "Warning: Tree has .gitattributes.  See GITATTRIBUTES in dgit(7)." ]
6143         if stat_exists '.gitattributes';
6144
6145     push @failsuggestion, [ 'origs', __
6146  "Maybe orig tarball(s) are not identical to git representation?" ];
6147
6148     if (quiltmode_splitbrain()) {
6149         quiltify_splitbrain($clogp, $unapplied, $headref, $oldtiptree,
6150                             $diffbits, \%editedignores,
6151                             $splitbrain_cachekey);
6152         return;
6153     }
6154
6155     progress f_ "starting quiltify (multiple patches, %s mode)", $quilt_mode;
6156     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
6157
6158     if (!open P, '>>', ".pc/applied-patches") {
6159         $!==&ENOENT or confess $!;
6160     } else {
6161         close P;
6162     }
6163
6164     commit_quilty_patch();
6165
6166     if ($mustdeletepc) {
6167         quilt_fixup_delete_pc();
6168     }
6169 }
6170
6171 sub quilt_fixup_editor () {
6172     my $descfn = $ENV{$fakeeditorenv};
6173     my $editing = $ARGV[$#ARGV];
6174     open I1, '<', $descfn or confess "$descfn: $!";
6175     open I2, '<', $editing or confess "$editing: $!";
6176     unlink $editing or confess "$editing: $!";
6177     open O, '>', $editing or confess "$editing: $!";
6178     while (<I1>) { print O or confess $!; } I1->error and confess $!;
6179     my $copying = 0;
6180     while (<I2>) {
6181         $copying ||= m/^\-\-\- /;
6182         next unless $copying;
6183         print O or confess $!;
6184     }
6185     I2->error and confess $!;
6186     close O or die $1;
6187     finish 0;
6188 }
6189
6190 sub maybe_apply_patches_dirtily () {
6191     return unless $quilt_mode =~ m/gbp|unapplied/;
6192     print STDERR __ <<END or confess $!;
6193
6194 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
6195 dgit: Have to apply the patches - making the tree dirty.
6196 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
6197
6198 END
6199     $patches_applied_dirtily = 01;
6200     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
6201     runcmd qw(dpkg-source --before-build .);
6202 }
6203
6204 sub maybe_unapply_patches_again () {
6205     progress __ "dgit: Unapplying patches again to tidy up the tree."
6206         if $patches_applied_dirtily;
6207     runcmd qw(dpkg-source --after-build .)
6208         if $patches_applied_dirtily & 01;
6209     rmtree '.pc'
6210         if $patches_applied_dirtily & 02;
6211     $patches_applied_dirtily = 0;
6212 }
6213
6214 #----- other building -----
6215
6216 sub clean_tree_check_git ($$) {
6217     my ($honour_ignores, $message) = @_;
6218     my @cmd = (@git, qw(clean -dn));
6219     push @cmd, qw(-x) unless $honour_ignores;
6220     my $leftovers = cmdoutput @cmd;
6221     if (length $leftovers) {
6222         print STDERR $leftovers, "\n" or confess $!;
6223         fail $message;
6224     }
6225 }
6226
6227 sub clean_tree_check_git_wd ($) {
6228     my ($message) = @_;
6229     return if $cleanmode =~ m{no-check};
6230     return if $patches_applied_dirtily; # yuk
6231     clean_tree_check_git +($cleanmode !~ m{all-check}),
6232                           (f_ <<END, $message);
6233 %s
6234 If this is just missing .gitignore entries, use a different clean
6235 mode, eg --clean=dpkg-source,no-check (-wdn/-wddn) to ignore them
6236 or --clean=git (-wg/-wgf) to use \`git clean' instead.
6237 END
6238 }
6239
6240 sub clean_tree_check () {
6241     # This function needs to not care about modified but tracked files.
6242     # That was done by check_not_dirty, and by now we may have run
6243     # the rules clean target which might modify tracked files (!)
6244     if ($cleanmode =~ m{^check}) {
6245         clean_tree_check_git +($cleanmode =~ m{ignores}), __
6246  "tree contains uncommitted files and --clean=check specified";
6247     } elsif ($cleanmode =~ m{^dpkg-source}) {
6248         clean_tree_check_git_wd __
6249  "tree contains uncommitted files (NB dgit didn't run rules clean)";
6250     } elsif ($cleanmode =~ m{^git}) {
6251         clean_tree_check_git_wd __
6252  "tree contains uncommitted files";
6253     } elsif ($cleanmode eq 'none') {
6254     } else {
6255         confess "$cleanmode ?";
6256     }
6257 }
6258
6259 sub clean_tree () {
6260     # We always clean the tree ourselves, rather than leave it to the
6261     # builder (dpkg-source, or soemthing which calls dpkg-source).
6262     if ($cleanmode =~ m{^dpkg-source}) {
6263         my @cmd = @dpkgbuildpackage;
6264         push @cmd, qw(-d) if $cleanmode =~ m{^dpkg-source-d};
6265         push @cmd, qw(-T clean);
6266         maybe_apply_patches_dirtily();
6267         runcmd_ordryrun_local @cmd;
6268         clean_tree_check_git_wd __
6269  "tree contains uncommitted files (after running rules clean)";
6270     } elsif ($cleanmode =~ m{^git(?!-)}) {
6271         runcmd_ordryrun_local @git, qw(clean -xdf);
6272     } elsif ($cleanmode =~ m{^git-ff}) {
6273         runcmd_ordryrun_local @git, qw(clean -xdff);
6274     } elsif ($cleanmode =~ m{^check}) {
6275         clean_tree_check();
6276     } elsif ($cleanmode eq 'none') {
6277     } else {
6278         confess "$cleanmode ?";
6279     }
6280 }
6281
6282 sub cmd_clean () {
6283     badusage __ "clean takes no additional arguments" if @ARGV;
6284     notpushing();
6285     clean_tree();
6286     maybe_unapply_patches_again();
6287 }
6288
6289 # return values from massage_dbp_args are one or both of these flags
6290 sub WANTSRC_SOURCE  () { 01; } # caller should build source (separately)
6291 sub WANTSRC_BUILDER () { 02; } # caller should run dpkg-buildpackage
6292
6293 sub build_or_push_prep_early () {
6294     our $build_or_push_prep_early_done //= 0;
6295     return if $build_or_push_prep_early_done++;
6296     badusage f_ "-p is not allowed with dgit %s", $subcommand
6297         if defined $package;
6298     my $clogp = parsechangelog();
6299     $isuite = getfield $clogp, 'Distribution';
6300     $package = getfield $clogp, 'Source';
6301     $version = getfield $clogp, 'Version';
6302     $dscfn = dscfn($version);
6303 }
6304
6305 sub build_prep_early () {
6306     build_or_push_prep_early();
6307     notpushing();
6308     check_not_dirty();
6309 }
6310
6311 sub build_prep ($) {
6312     my ($wantsrc) = @_;
6313     build_prep_early();
6314     check_bpd_exists();
6315     if (!building_source_in_playtree() || ($wantsrc & WANTSRC_BUILDER)) {
6316         # Clean the tree because we're going to use the contents of
6317         # $maindir.  (We trying to include dirty changes in the source
6318         # package, or we are running the builder in $maindir.)
6319         clean_tree();
6320     } else {
6321         # We don't actually need to do anything in $maindir, but we
6322         # should do some kind of cleanliness check because (i) the
6323         # user may have forgotten a `git add', and (ii) if the user
6324         # said -wc we should still do the check.
6325         clean_tree_check();
6326     }
6327     build_maybe_quilt_fixup();
6328     if ($rmchanges) {
6329         my $pat = changespat $version;
6330         foreach my $f (glob "$buildproductsdir/$pat") {
6331             if (act_local()) {
6332                 unlink $f or
6333                     fail f_ "remove old changes file %s: %s", $f, $!;
6334             } else {
6335                 progress f_ "would remove %s", $f;
6336             }
6337         }
6338     }
6339 }
6340
6341 sub changesopts_initial () {
6342     my @opts =@changesopts[1..$#changesopts];
6343 }
6344
6345 sub changesopts_version () {
6346     if (!defined $changes_since_version) {
6347         my @vsns;
6348         unless (eval {
6349             @vsns = archive_query('archive_query');
6350             my @quirk = access_quirk();
6351             if ($quirk[0] eq 'backports') {
6352                 local $isuite = $quirk[2];
6353                 local $csuite;
6354                 canonicalise_suite();
6355                 push @vsns, archive_query('archive_query');
6356             }
6357             1;
6358         }) {
6359             print STDERR $@;
6360             fail __
6361  "archive query failed (queried because --since-version not specified)";
6362         }
6363         if (@vsns) {
6364             @vsns = map { $_->[0] } @vsns;
6365             @vsns = sort { -version_compare($a, $b) } @vsns;
6366             $changes_since_version = $vsns[0];
6367             progress f_ "changelog will contain changes since %s", $vsns[0];
6368         } else {
6369             $changes_since_version = '_';
6370             progress __ "package seems new, not specifying -v<version>";
6371         }
6372     }
6373     if ($changes_since_version ne '_') {
6374         return ("-v$changes_since_version");
6375     } else {
6376         return ();
6377     }
6378 }
6379
6380 sub changesopts () {
6381     return (changesopts_initial(), changesopts_version());
6382 }
6383
6384 sub massage_dbp_args ($;$) {
6385     my ($cmd,$xargs) = @_;
6386     # Since we split the source build out so we can do strange things
6387     # to it, massage the arguments to dpkg-buildpackage so that the
6388     # main build doessn't build source (or add an argument to stop it
6389     # building source by default).
6390     debugcmd '#massaging#', @$cmd if $debuglevel>1;
6391     # -nc has the side effect of specifying -b if nothing else specified
6392     # and some combinations of -S, -b, et al, are errors, rather than
6393     # later simply overriding earlie.  So we need to:
6394     #  - search the command line for these options
6395     #  - pick the last one
6396     #  - perhaps add our own as a default
6397     #  - perhaps adjust it to the corresponding non-source-building version
6398     my $dmode = '-F';
6399     foreach my $l ($cmd, $xargs) {
6400         next unless $l;
6401         @$l = grep { !(m/^-[SgGFABb]$|^--build=/s and $dmode=$_) } @$l;
6402     }
6403     push @$cmd, '-nc';
6404 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
6405     my $r = WANTSRC_BUILDER;
6406     printdebug "massage split $dmode.\n";
6407     if ($dmode =~ s/^--build=//) {
6408         $r = 0;
6409         my @d = split /,/, $dmode;
6410         $r |= WANTSRC_SOURCE  if grep { s/^full$/binary/ } @d;
6411         $r |= WANTSRC_SOURCE  if grep { s/^source$// } @d;
6412         $r |= WANTSRC_BUILDER if grep { m/./ } @d;
6413         fail __ "Wanted to build nothing!" unless $r;
6414         $dmode = '--build='. join ',', grep m/./, @d;
6415     } else {
6416         $r =
6417           $dmode =~ m/[S]/     ?  WANTSRC_SOURCE :
6418           $dmode =~ y/gGF/ABb/ ?  WANTSRC_SOURCE | WANTSRC_BUILDER :
6419           $dmode =~ m/[ABb]/   ?                   WANTSRC_BUILDER :
6420           confess "$dmode ?";
6421     }
6422     printdebug "massage done $r $dmode.\n";
6423     push @$cmd, $dmode;
6424 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
6425     return $r;
6426 }
6427
6428 sub in_bpd (&) {
6429     my ($fn) = @_;
6430     my $wasdir = must_getcwd();
6431     changedir $buildproductsdir;
6432     $fn->();
6433     changedir $wasdir;
6434 }
6435
6436 # this sub must run with CWD=$buildproductsdir (eg in in_bpd)
6437 sub postbuild_mergechanges ($) {
6438     my ($msg_if_onlyone) = @_;
6439     # If there is only one .changes file, fail with $msg_if_onlyone,
6440     # or if that is undef, be a no-op.
6441     # Returns the changes file to report to the user.
6442     my $pat = changespat $version;
6443     my @changesfiles = grep { !m/_multi\.changes/ } glob $pat;
6444     @changesfiles = sort {
6445         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
6446             or $a cmp $b
6447     } @changesfiles;
6448     my $result;
6449     if (@changesfiles==1) {
6450         fail +(f_ <<END, "@changesfiles").$msg_if_onlyone
6451 only one changes file from build (%s)
6452 END
6453             if defined $msg_if_onlyone;
6454         $result = $changesfiles[0];
6455     } elsif (@changesfiles==2) {
6456         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
6457         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
6458             fail f_ "%s found in binaries changes file %s", $l, $binchanges
6459                 if $l =~ m/\.dsc$/;
6460         }
6461         runcmd_ordryrun_local @mergechanges, @changesfiles;
6462         my $multichanges = changespat $version,'multi';
6463         if (act_local()) {
6464             stat_exists $multichanges or fail f_
6465                 "%s unexpectedly not created by build", $multichanges;
6466             foreach my $cf (glob $pat) {
6467                 next if $cf eq $multichanges;
6468                 rename "$cf", "$cf.inmulti" or fail f_
6469                     "install new changes %s\{,.inmulti}: %s", $cf, $!;
6470             }
6471         }
6472         $result = $multichanges;
6473     } else {
6474         fail f_ "wrong number of different changes files (%s)",
6475                 "@changesfiles";
6476     }
6477     printdone f_ "build successful, results in %s\n", $result
6478         or confess $!;
6479 }
6480
6481 sub midbuild_checkchanges () {
6482     my $pat = changespat $version;
6483     return if $rmchanges;
6484     my @unwanted = map { s#.*/##; $_; } glob "$bpd_glob/$pat";
6485     @unwanted = grep {
6486         $_ ne changespat $version,'source' and
6487         $_ ne changespat $version,'multi'
6488     } @unwanted;
6489     fail +(f_ <<END, $pat, "@unwanted")
6490 changes files other than source matching %s already present; building would result in ambiguity about the intended results.
6491 Suggest you delete %s.
6492 END
6493         if @unwanted;
6494 }
6495
6496 sub midbuild_checkchanges_vanilla ($) {
6497     my ($wantsrc) = @_;
6498     midbuild_checkchanges() if $wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER);
6499 }
6500
6501 sub postbuild_mergechanges_vanilla ($) {
6502     my ($wantsrc) = @_;
6503     if ($wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER)) {
6504         in_bpd {
6505             postbuild_mergechanges(undef);
6506         };
6507     } else {
6508         printdone __ "build successful\n";
6509     }
6510 }
6511
6512 sub cmd_build {
6513     build_prep_early();
6514     $buildproductsdir eq '..' or print STDERR +(f_ <<END, $us, $us);
6515 %s: warning: build-products-dir set, but not supported by dpkg-buildpackage
6516 %s: warning: build-products-dir will be ignored; files will go to ..
6517 END
6518     $buildproductsdir = '..';
6519     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6520     my $wantsrc = massage_dbp_args \@dbp;
6521     build_prep($wantsrc);
6522     if ($wantsrc & WANTSRC_SOURCE) {
6523         build_source();
6524         midbuild_checkchanges_vanilla $wantsrc;
6525     }
6526     if ($wantsrc & WANTSRC_BUILDER) {
6527         push @dbp, changesopts_version();
6528         maybe_apply_patches_dirtily();
6529         runcmd_ordryrun_local @dbp;
6530     }
6531     maybe_unapply_patches_again();
6532     postbuild_mergechanges_vanilla $wantsrc;
6533 }
6534
6535 sub pre_gbp_build {
6536     $quilt_mode //= 'gbp';
6537 }
6538
6539 sub cmd_gbp_build {
6540     build_prep_early();
6541
6542     # gbp can make .origs out of thin air.  In my tests it does this
6543     # even for a 1.0 format package, with no origs present.  So I
6544     # guess it keys off just the version number.  We don't know
6545     # exactly what .origs ought to exist, but let's assume that we
6546     # should run gbp if: the version has an upstream part and the main
6547     # orig is absent.
6548     my $upstreamversion = upstreamversion $version;
6549     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6550     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "$bpd_glob/$origfnpat");
6551
6552     if ($gbp_make_orig) {
6553         clean_tree();
6554         $cleanmode = 'none'; # don't do it again
6555     }
6556
6557     my @dbp = @dpkgbuildpackage;
6558
6559     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6560
6561     if (!length $gbp_build[0]) {
6562         if (length executable_on_path('git-buildpackage')) {
6563             $gbp_build[0] = qw(git-buildpackage);
6564         } else {
6565             $gbp_build[0] = 'gbp buildpackage';
6566         }
6567     }
6568     my @cmd = opts_opt_multi_cmd [], @gbp_build;
6569
6570     push @cmd, (qw(-us -uc --git-no-sign-tags),
6571                 "--git-builder=".(shellquote @dbp));
6572
6573     if ($gbp_make_orig) {
6574         my $priv = dgit_privdir();
6575         my $ok = "$priv/origs-gen-ok";
6576         unlink $ok or $!==&ENOENT or confess $!;
6577         my @origs_cmd = @cmd;
6578         push @origs_cmd, qw(--git-cleaner=true);
6579         push @origs_cmd, "--git-prebuild=".
6580             "touch ".(shellquote $ok)." ".(shellquote "$priv/no-such-dir/ok");
6581         push @origs_cmd, @ARGV;
6582         if (act_local()) {
6583             debugcmd @origs_cmd;
6584             system @origs_cmd;
6585             do { local $!; stat_exists $ok; }
6586                 or failedcmd @origs_cmd;
6587         } else {
6588             dryrun_report @origs_cmd;
6589         }
6590     }
6591
6592     build_prep($wantsrc);
6593     if ($wantsrc & WANTSRC_SOURCE) {
6594         build_source();
6595         midbuild_checkchanges_vanilla $wantsrc;
6596     } else {
6597         push @cmd, '--git-cleaner=true';
6598     }
6599     maybe_unapply_patches_again();
6600     if ($wantsrc & WANTSRC_BUILDER) {
6601         push @cmd, changesopts();
6602         runcmd_ordryrun_local @cmd, @ARGV;
6603     }
6604     postbuild_mergechanges_vanilla $wantsrc;
6605 }
6606 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6607
6608 sub building_source_in_playtree {
6609     # If $includedirty, we have to build the source package from the
6610     # working tree, not a playtree, so that uncommitted changes are
6611     # included (copying or hardlinking them into the playtree could
6612     # cause trouble).
6613     #
6614     # Note that if we are building a source package in split brain
6615     # mode we do not support including uncommitted changes, because
6616     # that makes quilt fixup too hard.  I.e. ($split_brain && (dgit is
6617     # building a source package)) => !$includedirty
6618     return !$includedirty;
6619 }
6620
6621 sub build_source {
6622     $sourcechanges = changespat $version,'source';
6623     if (act_local()) {
6624         unlink "$buildproductsdir/$sourcechanges" or $!==ENOENT
6625             or fail f_ "remove %s: %s", $sourcechanges, $!;
6626     }
6627     my @cmd = (@dpkgsource, qw(-b --));
6628     my $leafdir;
6629     if (building_source_in_playtree()) {
6630         $leafdir = 'work';
6631         my $headref = git_rev_parse('HEAD');
6632         # If we are in split brain, there is already a playtree with
6633         # the thing we should package into a .dsc (thanks to quilt
6634         # fixup).  If not, make a playtree
6635         prep_ud() unless $split_brain;
6636         changedir $playground;
6637         unless ($split_brain) {
6638             my $upstreamversion = upstreamversion $version;
6639             unpack_playtree_linkorigs($upstreamversion, sub { });
6640             unpack_playtree_mkwork($headref);
6641             changedir '..';
6642         }
6643     } else {
6644         $leafdir = basename $maindir;
6645
6646         if ($buildproductsdir ne '..') {
6647             # Well, we are going to run dpkg-source -b which consumes
6648             # origs from .. and generates output there.  To make this
6649             # work when the bpd is not .. , we would have to (i) link
6650             # origs from bpd to .. , (ii) check for files that
6651             # dpkg-source -b would/might overwrite, and afterwards
6652             # (iii) move all the outputs back to the bpd (iv) except
6653             # for the origs which should be deleted from .. if they
6654             # weren't there beforehand.  And if there is an error and
6655             # we don't run to completion we would necessarily leave a
6656             # mess.  This is too much.  The real way to fix this
6657             # is for dpkg-source to have bpd support.
6658             confess unless $includedirty;
6659             fail __
6660  "--include-dirty not supported with --build-products-dir, sorry";
6661         }
6662
6663         changedir '..';
6664     }
6665     runcmd_ordryrun_local @cmd, $leafdir;
6666
6667     changedir $leafdir;
6668     runcmd_ordryrun_local qw(sh -ec),
6669       'exec >../$1; shift; exec "$@"','x', $sourcechanges,
6670       @dpkggenchanges, qw(-S), changesopts();
6671     changedir '..';
6672
6673     printdebug "moving $dscfn, $sourcechanges, etc. to ".bpd_abs()."\n";
6674     $dsc = parsecontrol($dscfn, "source package");
6675
6676     my $mv = sub {
6677         my ($why, $l) = @_;
6678         printdebug " renaming ($why) $l\n";
6679         rename_link_xf 0, "$l", bpd_abs()."/$l"
6680             or fail f_ "put in place new built file (%s): %s", $l, $@;
6681     };
6682     foreach my $l (split /\n/, getfield $dsc, 'Files') {
6683         $l =~ m/\S+$/ or next;
6684         $mv->('Files', $&);
6685     }
6686     $mv->('dsc', $dscfn);
6687     $mv->('changes', $sourcechanges);
6688
6689     changedir $maindir;
6690 }
6691
6692 sub cmd_build_source {
6693     badusage __ "build-source takes no additional arguments" if @ARGV;
6694     build_prep(WANTSRC_SOURCE);
6695     build_source();
6696     maybe_unapply_patches_again();
6697     printdone f_ "source built, results in %s and %s",
6698                  $dscfn, $sourcechanges;
6699 }
6700
6701 sub cmd_push_source {
6702     prep_push();
6703     fail __
6704         "dgit push-source: --include-dirty/--ignore-dirty does not make".
6705         "sense with push-source!"
6706         if $includedirty;
6707     build_maybe_quilt_fixup();
6708     if ($changesfile) {
6709         my $changes = parsecontrol("$buildproductsdir/$changesfile",
6710                                    __ "source changes file");
6711         unless (test_source_only_changes($changes)) {
6712             fail __ "user-specified changes file is not source-only";
6713         }
6714     } else {
6715         # Building a source package is very fast, so just do it
6716         build_source();
6717         confess "er, patches are applied dirtily but shouldn't be.."
6718             if $patches_applied_dirtily;
6719         $changesfile = $sourcechanges;
6720     }
6721     dopush();
6722 }
6723
6724 sub binary_builder {
6725     my ($bbuilder, $pbmc_msg, @args) = @_;
6726     build_prep(WANTSRC_SOURCE);
6727     build_source();
6728     midbuild_checkchanges();
6729     in_bpd {
6730         if (act_local()) {
6731             stat_exists $dscfn or fail f_
6732                 "%s (in build products dir): %s", $dscfn, $!;
6733             stat_exists $sourcechanges or fail f_
6734                 "%s (in build products dir): %s", $sourcechanges, $!;
6735         }
6736         runcmd_ordryrun_local @$bbuilder, @args;
6737     };
6738     maybe_unapply_patches_again();
6739     in_bpd {
6740         postbuild_mergechanges($pbmc_msg);
6741     };
6742 }
6743
6744 sub cmd_sbuild {
6745     build_prep_early();
6746     binary_builder(\@sbuild, (__ <<END), qw(-d), $isuite, @ARGV, $dscfn);
6747 perhaps you need to pass -A ?  (sbuild's default is to build only
6748 arch-specific binaries; dgit 1.4 used to override that.)
6749 END
6750 }
6751
6752 sub pbuilder ($) {
6753     my ($pbuilder) = @_;
6754     build_prep_early();
6755     # @ARGV is allowed to contain only things that should be passed to
6756     # pbuilder under debbuildopts; just massage those
6757     my $wantsrc = massage_dbp_args \@ARGV;
6758     fail __
6759         "you asked for a builder but your debbuildopts didn't ask for".
6760         " any binaries -- is this really what you meant?"
6761         unless $wantsrc & WANTSRC_BUILDER;
6762     fail __
6763         "we must build a .dsc to pass to the builder but your debbuiltopts".
6764         " forbids the building of a source package; cannot continue"
6765       unless $wantsrc & WANTSRC_SOURCE;
6766     # We do not want to include the verb "build" in @pbuilder because
6767     # the user can customise @pbuilder and they shouldn't be required
6768     # to include "build" in their customised value.  However, if the
6769     # user passes any additional args to pbuilder using the dgit
6770     # option --pbuilder:foo, such args need to come after the "build"
6771     # verb.  opts_opt_multi_cmd does all of that.
6772     binary_builder([opts_opt_multi_cmd ["build"], @$pbuilder], undef,
6773                    qw(--debbuildopts), "@ARGV", qw(--distribution), $isuite,
6774                    $dscfn);
6775 }
6776
6777 sub cmd_pbuilder {
6778     pbuilder(\@pbuilder);
6779 }
6780
6781 sub cmd_cowbuilder {
6782     pbuilder(\@cowbuilder);
6783 }
6784
6785 sub cmd_quilt_fixup {
6786     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6787     build_prep_early();
6788     clean_tree();
6789     build_maybe_quilt_fixup();
6790 }
6791
6792 sub cmd_print_unapplied_treeish {
6793     badusage __ "incorrect arguments to dgit print-unapplied-treeish"
6794         if @ARGV;
6795     my $headref = git_rev_parse('HEAD');
6796     my $clogp = commit_getclogp $headref;
6797     $package = getfield $clogp, 'Source';
6798     $version = getfield $clogp, 'Version';
6799     $isuite = getfield $clogp, 'Distribution';
6800     $csuite = $isuite; # we want this to be offline!
6801     notpushing();
6802
6803     prep_ud();
6804     changedir $playground;
6805     my $uv = upstreamversion $version;
6806     quilt_make_fake_dsc($uv);
6807     my $u = quilt_fakedsc2unapplied($headref, $uv);
6808     print $u, "\n" or confess $!;
6809 }
6810
6811 sub import_dsc_result {
6812     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6813     my @cmd = (git_update_ref_cmd $what_log, $dstref, $newhash);
6814     runcmd @cmd;
6815     check_gitattrs($newhash, __ "source tree");
6816
6817     progress f_ "dgit: import-dsc: %s", $what_msg;
6818 }
6819
6820 sub cmd_import_dsc {
6821     my $needsig = 0;
6822
6823     while (@ARGV) {
6824         last unless $ARGV[0] =~ m/^-/;
6825         $_ = shift @ARGV;
6826         last if m/^--?$/;
6827         if (m/^--require-valid-signature$/) {
6828             $needsig = 1;
6829         } else {
6830             badusage f_ "unknown dgit import-dsc sub-option \`%s'", $_;
6831         }
6832     }
6833
6834     badusage __ "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH"
6835         unless @ARGV==2;
6836     my ($dscfn, $dstbranch) = @ARGV;
6837
6838     badusage __ "dry run makes no sense with import-dsc"
6839         unless act_local();
6840
6841     my $force = $dstbranch =~ s/^\+//   ? +1 :
6842                 $dstbranch =~ s/^\.\.// ? -1 :
6843                                            0;
6844     my $info = $force ? " $&" : '';
6845     $info = "$dscfn$info";
6846
6847     my $specbranch = $dstbranch;
6848     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6849     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6850
6851     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6852     my $chead = cmdoutput_errok @symcmd;
6853     defined $chead or $?==256 or failedcmd @symcmd;
6854
6855     fail f_ "%s is checked out - will not update it", $dstbranch
6856         if defined $chead and $chead eq $dstbranch;
6857
6858     my $oldhash = git_get_ref $dstbranch;
6859
6860     open D, "<", $dscfn or fail f_ "open import .dsc (%s): %s", $dscfn, $!;
6861     $dscdata = do { local $/ = undef; <D>; };
6862     D->error and fail f_ "read %s: %s", $dscfn, $!;
6863     close C;
6864
6865     # we don't normally need this so import it here
6866     use Dpkg::Source::Package;
6867     my $dp = new Dpkg::Source::Package filename => $dscfn,
6868         require_valid_signature => $needsig;
6869     {
6870         local $SIG{__WARN__} = sub {
6871             print STDERR $_[0];
6872             return unless $needsig;
6873             fail __ "import-dsc signature check failed";
6874         };
6875         if (!$dp->is_signed()) {
6876             warn f_ "%s: warning: importing unsigned .dsc\n", $us;
6877         } else {
6878             my $r = $dp->check_signature();
6879             confess "->check_signature => $r" if $needsig && $r;
6880         }
6881     }
6882
6883     parse_dscdata();
6884
6885     $package = getfield $dsc, 'Source';
6886
6887     parse_dsc_field($dsc, __ "Dgit metadata in .dsc")
6888         unless forceing [qw(import-dsc-with-dgit-field)];
6889     parse_dsc_field_def_dsc_distro();
6890
6891     $isuite = 'DGIT-IMPORT-DSC';
6892     $idistro //= $dsc_distro;
6893
6894     notpushing();
6895
6896     if (defined $dsc_hash) {
6897         progress __
6898             "dgit: import-dsc of .dsc with Dgit field, using git hash";
6899         resolve_dsc_field_commit undef, undef;
6900     }
6901     if (defined $dsc_hash) {
6902         my @cmd = (qw(sh -ec),
6903                    "echo $dsc_hash | git cat-file --batch-check");
6904         my $objgot = cmdoutput @cmd;
6905         if ($objgot =~ m#^\w+ missing\b#) {
6906             fail f_ <<END, $dsc_hash
6907 .dsc contains Dgit field referring to object %s
6908 Your git tree does not have that object.  Try `git fetch' from a
6909 plausible server (browse.dgit.d.o? salsa?), and try the import-dsc again.
6910 END
6911         }
6912         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6913             if ($force > 0) {
6914                 progress __ "Not fast forward, forced update.";
6915             } else {
6916                 fail f_ "Not fast forward to %s", $dsc_hash;
6917             }
6918         }
6919         import_dsc_result $dstbranch, $dsc_hash,
6920             "dgit import-dsc (Dgit): $info",
6921             f_ "updated git ref %s", $dstbranch;
6922         return 0;
6923     }
6924
6925     fail f_ <<END, $dstbranch, $specbranch, $specbranch
6926 Branch %s already exists
6927 Specify ..%s for a pseudo-merge, binding in existing history
6928 Specify  +%s to overwrite, discarding existing history
6929 END
6930         if $oldhash && !$force;
6931
6932     my @dfi = dsc_files_info();
6933     foreach my $fi (@dfi) {
6934         my $f = $fi->{Filename};
6935         my $here = "$buildproductsdir/$f";
6936         if (lstat $here) {
6937             next if stat $here;
6938             fail f_ "lstat %s works but stat gives %s !", $here, $!;
6939         }
6940         fail f_ "stat %s: %s", $here, $! unless $! == ENOENT;
6941         my $there = $dscfn;
6942         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6943             $there = $';
6944         } elsif ($dscfn =~ m#^/#) {
6945             $there = $dscfn;
6946         } else {
6947             fail f_
6948                 "cannot import %s which seems to be inside working tree!",
6949                 $dscfn;
6950         }
6951         $there =~ s#/+[^/]+$## or fail f_
6952             "import %s requires .../%s, but it does not exist",
6953             $dscfn, $f;
6954         $there .= "/$f";
6955         my $test = $there =~ m{^/} ? $there : "../$there";
6956         stat $test or fail f_
6957             "import %s requires %s, but: %s", $dscfn, $test, $!;
6958         symlink $there, $here or fail f_
6959             "symlink %s to %s: %s", $there, $here, $!;
6960         progress f_ "made symlink %s -> %s", $here, $there;
6961 #       print STDERR Dumper($fi);
6962     }
6963     my @mergeinputs = generate_commits_from_dsc();
6964     die unless @mergeinputs == 1;
6965
6966     my $newhash = $mergeinputs[0]{Commit};
6967
6968     if ($oldhash) {
6969         if ($force > 0) {
6970             progress __
6971                 "Import, forced update - synthetic orphan git history.";
6972         } elsif ($force < 0) {
6973             progress __ "Import, merging.";
6974             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6975             my $version = getfield $dsc, 'Version';
6976             my $clogp = commit_getclogp $newhash;
6977             my $authline = clogp_authline $clogp;
6978             $newhash = make_commit_text <<ENDU
6979 tree $tree
6980 parent $newhash
6981 parent $oldhash
6982 author $authline
6983 committer $authline
6984
6985 ENDU
6986                 .(f_ <<END, $package, $version, $dstbranch);
6987 Merge %s (%s) import into %s
6988 END
6989         } else {
6990             die; # caught earlier
6991         }
6992     }
6993
6994     import_dsc_result $dstbranch, $newhash,
6995         "dgit import-dsc: $info",
6996         f_ "results are in git ref %s", $dstbranch;
6997 }
6998
6999 sub pre_archive_api_query () {
7000     not_necessarily_a_tree();
7001 }
7002 sub cmd_archive_api_query {
7003     badusage __ "need only 1 subpath argument" unless @ARGV==1;
7004     my ($subpath) = @ARGV;
7005     local $isuite = 'DGIT-API-QUERY-CMD';
7006     my @cmd = archive_api_query_cmd($subpath);
7007     push @cmd, qw(-f);
7008     debugcmd ">",@cmd;
7009     exec @cmd or fail f_ "exec curl: %s\n", $!;
7010 }
7011
7012 sub repos_server_url () {
7013     $package = '_dgit-repos-server';
7014     local $access_forpush = 1;
7015     local $isuite = 'DGIT-REPOS-SERVER';
7016     my $url = access_giturl();
7017 }
7018
7019 sub pre_clone_dgit_repos_server () {
7020     not_necessarily_a_tree();
7021 }
7022 sub cmd_clone_dgit_repos_server {
7023     badusage __ "need destination argument" unless @ARGV==1;
7024     my ($destdir) = @ARGV;
7025     my $url = repos_server_url();
7026     my @cmd = (@git, qw(clone), $url, $destdir);
7027     debugcmd ">",@cmd;
7028     exec @cmd or fail f_ "exec git clone: %s\n", $!;
7029 }
7030
7031 sub pre_print_dgit_repos_server_source_url () {
7032     not_necessarily_a_tree();
7033 }
7034 sub cmd_print_dgit_repos_server_source_url {
7035     badusage __
7036         "no arguments allowed to dgit print-dgit-repos-server-source-url"
7037         if @ARGV;
7038     my $url = repos_server_url();
7039     print $url, "\n" or confess $!;
7040 }
7041
7042 sub pre_print_dpkg_source_ignores {
7043     not_necessarily_a_tree();
7044 }
7045 sub cmd_print_dpkg_source_ignores {
7046     badusage __
7047         "no arguments allowed to dgit print-dpkg-source-ignores"
7048         if @ARGV;
7049     print "@dpkg_source_ignores\n" or confess $!;
7050 }
7051
7052 sub cmd_setup_mergechangelogs {
7053     badusage __ "no arguments allowed to dgit setup-mergechangelogs"
7054         if @ARGV;
7055     local $isuite = 'DGIT-SETUP-TREE';
7056     setup_mergechangelogs(1);
7057 }
7058
7059 sub cmd_setup_useremail {
7060     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7061     local $isuite = 'DGIT-SETUP-TREE';
7062     setup_useremail(1);
7063 }
7064
7065 sub cmd_setup_gitattributes {
7066     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7067     local $isuite = 'DGIT-SETUP-TREE';
7068     setup_gitattrs(1);
7069 }
7070
7071 sub cmd_setup_new_tree {
7072     badusage __ "no arguments allowed to dgit setup-tree" if @ARGV;
7073     local $isuite = 'DGIT-SETUP-TREE';
7074     setup_new_tree();
7075 }
7076
7077 #---------- argument parsing and main program ----------
7078
7079 sub cmd_version {
7080     print "dgit version $our_version\n" or confess $!;
7081     finish 0;
7082 }
7083
7084 our (%valopts_long, %valopts_short);
7085 our (%funcopts_long);
7086 our @rvalopts;
7087 our (@modeopt_cfgs);
7088
7089 sub defvalopt ($$$$) {
7090     my ($long,$short,$val_re,$how) = @_;
7091     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
7092     $valopts_long{$long} = $oi;
7093     $valopts_short{$short} = $oi;
7094     # $how subref should:
7095     #   do whatever assignemnt or thing it likes with $_[0]
7096     #   if the option should not be passed on to remote, @rvalopts=()
7097     # or $how can be a scalar ref, meaning simply assign the value
7098 }
7099
7100 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
7101 defvalopt '--distro',        '-d', '.+',      \$idistro;
7102 defvalopt '',                '-k', '.+',      \$keyid;
7103 defvalopt '--existing-package','', '.*',      \$existing_package;
7104 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
7105 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
7106 defvalopt '--package',   '-p',   $package_re, \$package;
7107 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
7108
7109 defvalopt '', '-C', '.+', sub {
7110     ($changesfile) = (@_);
7111     if ($changesfile =~ s#^(.*)/##) {
7112         $buildproductsdir = $1;
7113     }
7114 };
7115
7116 defvalopt '--initiator-tempdir','','.*', sub {
7117     ($initiator_tempdir) = (@_);
7118     $initiator_tempdir =~ m#^/# or
7119         badusage __ "--initiator-tempdir must be used specify an".
7120                     " absolute, not relative, directory."
7121 };
7122
7123 sub defoptmodes ($@) {
7124     my ($varref, $cfgkey, $default, %optmap) = @_;
7125     my %permit;
7126     while (my ($opt,$val) = each %optmap) {
7127         $funcopts_long{$opt} = sub { $$varref = $val; };
7128         $permit{$val} = $val;
7129     }
7130     push @modeopt_cfgs, {
7131         Var => $varref,
7132         Key => $cfgkey,
7133         Default => $default,
7134         Vals => \%permit
7135     };
7136 }
7137
7138 defoptmodes \$dodep14tag, qw( dep14tag          want
7139                               --dep14tag        want
7140                               --no-dep14tag     no
7141                               --always-dep14tag always );
7142
7143 sub parseopts () {
7144     my $om;
7145
7146     if (defined $ENV{'DGIT_SSH'}) {
7147         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
7148     } elsif (defined $ENV{'GIT_SSH'}) {
7149         @ssh = ($ENV{'GIT_SSH'});
7150     }
7151
7152     my $oi;
7153     my $val;
7154     my $valopt = sub {
7155         my ($what) = @_;
7156         @rvalopts = ($_);
7157         if (!defined $val) {
7158             badusage f_ "%s needs a value", $what unless @ARGV;
7159             $val = shift @ARGV;
7160             push @rvalopts, $val;
7161         }
7162         badusage f_ "bad value \`%s' for %s", $val, $what unless
7163             $val =~ m/^$oi->{Re}$(?!\n)/s;
7164         my $how = $oi->{How};
7165         if (ref($how) eq 'SCALAR') {
7166             $$how = $val;
7167         } else {
7168             $how->($val);
7169         }
7170         push @ropts, @rvalopts;
7171     };
7172
7173     while (@ARGV) {
7174         last unless $ARGV[0] =~ m/^-/;
7175         $_ = shift @ARGV;
7176         last if m/^--?$/;
7177         if (m/^--/) {
7178             if (m/^--dry-run$/) {
7179                 push @ropts, $_;
7180                 $dryrun_level=2;
7181             } elsif (m/^--damp-run$/) {
7182                 push @ropts, $_;
7183                 $dryrun_level=1;
7184             } elsif (m/^--no-sign$/) {
7185                 push @ropts, $_;
7186                 $sign=0;
7187             } elsif (m/^--help$/) {
7188                 cmd_help();
7189             } elsif (m/^--version$/) {
7190                 cmd_version();
7191             } elsif (m/^--new$/) {
7192                 push @ropts, $_;
7193                 $new_package=1;
7194             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
7195                      ($om = $opts_opt_map{$1}) &&
7196                      length $om->[0]) {
7197                 push @ropts, $_;
7198                 $om->[0] = $2;
7199             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
7200                      !$opts_opt_cmdonly{$1} &&
7201                      ($om = $opts_opt_map{$1})) {
7202                 push @ropts, $_;
7203                 push @$om, $2;
7204             } elsif (m/^--([-0-9a-z]+)\!:(.*)/s &&
7205                      !$opts_opt_cmdonly{$1} &&
7206                      ($om = $opts_opt_map{$1})) {
7207                 push @ropts, $_;
7208                 my $cmd = shift @$om;
7209                 @$om = ($cmd, grep { $_ ne $2 } @$om);
7210             } elsif (m/^--(gbp|dpm)$/s) {
7211                 push @ropts, "--quilt=$1";
7212                 $quilt_mode = $1;
7213             } elsif (m/^--(?:ignore|include)-dirty$/s) {
7214                 push @ropts, $_;
7215                 $includedirty = 1;
7216             } elsif (m/^--no-quilt-fixup$/s) {
7217                 push @ropts, $_;
7218                 $quilt_mode = 'nocheck';
7219             } elsif (m/^--no-rm-on-error$/s) {
7220                 push @ropts, $_;
7221                 $rmonerror = 0;
7222             } elsif (m/^--no-chase-dsc-distro$/s) {
7223                 push @ropts, $_;
7224                 $chase_dsc_distro = 0;
7225             } elsif (m/^--overwrite$/s) {
7226                 push @ropts, $_;
7227                 $overwrite_version = '';
7228             } elsif (m/^--overwrite=(.+)$/s) {
7229                 push @ropts, $_;
7230                 $overwrite_version = $1;
7231             } elsif (m/^--delayed=(\d+)$/s) {
7232                 push @ropts, $_;
7233                 push @dput, $_;
7234             } elsif (my ($k,$v) =
7235                      m/^--save-(dgit-view)=(.+)$/s ||
7236                      m/^--(dgit-view)-save=(.+)$/s
7237                      ) {
7238                 push @ropts, $_;
7239                 $v =~ s#^(?!refs/)#refs/heads/#;
7240                 $internal_object_save{$k} = $v;
7241             } elsif (m/^--(no-)?rm-old-changes$/s) {
7242                 push @ropts, $_;
7243                 $rmchanges = !$1;
7244             } elsif (m/^--deliberately-($deliberately_re)$/s) {
7245                 push @ropts, $_;
7246                 push @deliberatelies, $&;
7247             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
7248                 push @ropts, $&;
7249                 $forceopts{$1} = 1;
7250                 $_='';
7251             } elsif (m/^--force-/) {
7252                 print STDERR
7253                     f_ "%s: warning: ignoring unknown force option %s\n",
7254                        $us, $_;
7255                 $_='';
7256             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
7257                 # undocumented, for testing
7258                 push @ropts, $_;
7259                 $tagformat_want = [ $1, 'command line', 1 ];
7260                 # 1 menas overrides distro configuration
7261             } elsif (m/^--config-lookup-explode=(.+)$/s) {
7262                 # undocumented, for testing
7263                 push @ropts, $_;
7264                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
7265                 # ^ it's supposed to be an array ref
7266             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
7267                 $val = $2 ? $' : undef; #';
7268                 $valopt->($oi->{Long});
7269             } elsif ($funcopts_long{$_}) {
7270                 push @ropts, $_;
7271                 $funcopts_long{$_}();
7272             } else {
7273                 badusage f_ "unknown long option \`%s'", $_;
7274             }
7275         } else {
7276             while (m/^-./s) {
7277                 if (s/^-n/-/) {
7278                     push @ropts, $&;
7279                     $dryrun_level=2;
7280                 } elsif (s/^-L/-/) {
7281                     push @ropts, $&;
7282                     $dryrun_level=1;
7283                 } elsif (s/^-h/-/) {
7284                     cmd_help();
7285                 } elsif (s/^-D/-/) {
7286                     push @ropts, $&;
7287                     $debuglevel++;
7288                     enabledebug();
7289                 } elsif (s/^-N/-/) {
7290                     push @ropts, $&;
7291                     $new_package=1;
7292                 } elsif (m/^-m/) {
7293                     push @ropts, $&;
7294                     push @changesopts, $_;
7295                     $_ = '';
7296                 } elsif (s/^-wn$//s) {
7297                     push @ropts, $&;
7298                     $cleanmode = 'none';
7299                 } elsif (s/^-wg(f?)$//s) {
7300                     push @ropts, $&;
7301                     $cleanmode = 'git';
7302                     $cleanmode .= '-ff' if $1;
7303                 } elsif (s/^-wd(d?)([na]?)$//s) {
7304                     push @ropts, $&;
7305                     $cleanmode = 'dpkg-source';
7306                     $cleanmode .= '-d' if $1;
7307                     $cleanmode .= ',no-check' if $2 eq 'n';
7308                     $cleanmode .= ',all-check' if $2 eq 'a';
7309                 } elsif (s/^-wc$//s) {
7310                     push @ropts, $&;
7311                     $cleanmode = 'check';
7312                 } elsif (s/^-wci$//s) {
7313                     push @ropts, $&;
7314                     $cleanmode = 'check,ignores';
7315                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
7316                     push @git, '-c', $&;
7317                     $gitcfgs{cmdline}{$1} = [ $2 ];
7318                 } elsif (s/^-c([^=]+)$//s) {
7319                     push @git, '-c', $&;
7320                     $gitcfgs{cmdline}{$1} = [ 'true' ];
7321                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
7322                     $val = $'; #';
7323                     $val = undef unless length $val;
7324                     $valopt->($oi->{Short});
7325                     $_ = '';
7326                 } else {
7327                     badusage f_ "unknown short option \`%s'", $_;
7328                 }
7329             }
7330         }
7331     }
7332 }
7333
7334 sub check_env_sanity () {
7335     my $blocked = new POSIX::SigSet;
7336     sigprocmask SIG_UNBLOCK, $blocked, $blocked or confess $!;
7337
7338     eval {
7339         foreach my $name (qw(PIPE CHLD)) {
7340             my $signame = "SIG$name";
7341             my $signum = eval "POSIX::$signame" // die;
7342             die f_ "%s is set to something other than SIG_DFL\n",
7343                 $signame
7344                 if defined $SIG{$name} and $SIG{$name} ne 'DEFAULT';
7345             $blocked->ismember($signum) and
7346                 die f_ "%s is blocked\n", $signame;
7347         }
7348     };
7349     return unless $@;
7350     chomp $@;
7351     fail f_ <<END, $@;
7352 On entry to dgit, %s
7353 This is a bug produced by something in your execution environment.
7354 Giving up.
7355 END
7356 }
7357
7358
7359 sub parseopts_late_defaults () {
7360     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
7361         if defined $idistro;
7362     $isuite //= cfg('dgit.default.default-suite');
7363
7364     foreach my $k (keys %opts_opt_map) {
7365         my $om = $opts_opt_map{$k};
7366
7367         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
7368         if (defined $v) {
7369             badcfg f_ "cannot set command for %s", $k
7370                 unless length $om->[0];
7371             $om->[0] = $v;
7372         }
7373
7374         foreach my $c (access_cfg_cfgs("opts-$k")) {
7375             my @vl =
7376                 map { $_ ? @$_ : () }
7377                 map { $gitcfgs{$_}{$c} }
7378                 reverse @gitcfgsources;
7379             printdebug "CL $c ", (join " ", map { shellquote } @vl),
7380                 "\n" if $debuglevel >= 4;
7381             next unless @vl;
7382             badcfg f_ "cannot configure options for %s", $k
7383                 if $opts_opt_cmdonly{$k};
7384             my $insertpos = $opts_cfg_insertpos{$k};
7385             @$om = ( @$om[0..$insertpos-1],
7386                      @vl,
7387                      @$om[$insertpos..$#$om] );
7388         }
7389     }
7390
7391     if (!defined $rmchanges) {
7392         local $access_forpush;
7393         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
7394     }
7395
7396     if (!defined $quilt_mode) {
7397         local $access_forpush;
7398         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
7399             // access_cfg('quilt-mode', 'RETURN-UNDEF')
7400             // 'linear';
7401         $quilt_mode =~ m/^($quilt_modes_re)$/
7402             or badcfg f_ "unknown quilt-mode \`%s'", $quilt_mode;
7403         $quilt_mode = $1;
7404     }
7405
7406     foreach my $moc (@modeopt_cfgs) {
7407         local $access_forpush;
7408         my $vr = $moc->{Var};
7409         next if defined $$vr;
7410         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
7411         my $v = $moc->{Vals}{$$vr};
7412         badcfg f_ "unknown %s setting \`%s'", $moc->{Key}, $$vr
7413             unless defined $v;
7414         $$vr = $v;
7415     }
7416
7417     fail __ "dgit: --include-dirty is not supported in split view quilt mode"
7418         if $split_brain && $includedirty;
7419
7420     if (!defined $cleanmode) {
7421         local $access_forpush;
7422         $cleanmode = access_cfg('clean-mode-newer', 'RETURN-UNDEF');
7423         $cleanmode = undef if $cleanmode && $cleanmode !~ m/^$cleanmode_re$/;
7424
7425         $cleanmode //= access_cfg('clean-mode', 'RETURN-UNDEF');
7426         $cleanmode //= 'dpkg-source';
7427
7428         badcfg f_ "unknown clean-mode \`%s'", $cleanmode unless
7429             $cleanmode =~ m/$cleanmode_re/;
7430     }
7431
7432     $buildproductsdir //= access_cfg('build-products-dir', 'RETURN-UNDEF');
7433     $buildproductsdir //= '..';
7434     $bpd_glob = $buildproductsdir;
7435     $bpd_glob =~ s#[][\\{}*?~]#\\$&#g;
7436 }
7437
7438 setlocale(LC_MESSAGES, "");
7439 textdomain("dgit");
7440
7441 if ($ENV{$fakeeditorenv}) {
7442     git_slurp_config();
7443     quilt_fixup_editor();
7444 }
7445
7446 parseopts();
7447 check_env_sanity();
7448
7449 print STDERR __ "DRY RUN ONLY\n" if $dryrun_level > 1;
7450 print STDERR __ "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
7451     if $dryrun_level == 1;
7452 if (!@ARGV) {
7453     print STDERR __ $helpmsg or confess $!;
7454     finish 8;
7455 }
7456 $cmd = $subcommand = shift @ARGV;
7457 $cmd =~ y/-/_/;
7458
7459 my $pre_fn = ${*::}{"pre_$cmd"};
7460 $pre_fn->() if $pre_fn;
7461
7462 if ($invoked_in_git_tree) {
7463     changedir_git_toplevel();
7464     record_maindir();
7465 }
7466 git_slurp_config();
7467
7468 my $fn = ${*::}{"cmd_$cmd"};
7469 $fn or badusage f_ "unknown operation %s", $cmd;
7470 $fn->();
7471
7472 finish 0;