chiark / gitweb /
dgit: clone-dgit-repos-server: Set $access_forpush
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013-2016 Ian Jackson
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20 use strict;
21
22 use Debian::Dgit;
23 setup_sigwarn();
24
25 use IO::Handle;
26 use Data::Dumper;
27 use LWP::UserAgent;
28 use Dpkg::Control::Hash;
29 use File::Path;
30 use File::Temp qw(tempdir);
31 use File::Basename;
32 use Dpkg::Version;
33 use POSIX;
34 use IPC::Open2;
35 use Digest::SHA;
36 use Digest::MD5;
37 use List::Util qw(any);
38 use List::MoreUtils qw(pairwise);
39 use Text::Glob qw(match_glob);
40 use Fcntl qw(:DEFAULT :flock);
41 use Carp;
42
43 use Debian::Dgit;
44
45 our $our_version = 'UNRELEASED'; ###substituted###
46 our $absurdity = undef; ###substituted###
47
48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
49 our $protovsn;
50
51 our $isuite = 'unstable';
52 our $idistro;
53 our $package;
54 our @ropts;
55
56 our $sign = 1;
57 our $dryrun_level = 0;
58 our $changesfile;
59 our $buildproductsdir = '..';
60 our $new_package = 0;
61 our $ignoredirty = 0;
62 our $rmonerror = 1;
63 our @deliberatelies;
64 our %previously;
65 our $existing_package = 'dpkg';
66 our $cleanmode;
67 our $changes_since_version;
68 our $rmchanges;
69 our $overwrite_version; # undef: not specified; '': check changelog
70 our $quilt_mode;
71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
72 our $dodep14tag;
73 our $dodep14tag_re = 'want|no|always';
74 our $split_brain_save;
75 our $we_are_responder;
76 our $initiator_tempdir;
77 our $patches_applied_dirtily = 00;
78 our $tagformat_want;
79 our $tagformat;
80 our $tagformatfn;
81 our $chase_dsc_distro=1;
82
83 our %forceopts = map { $_=>0 }
84     qw(unrepresentable unsupported-source-format
85        dsc-changes-mismatch changes-origs-exactly
86        import-gitapply-absurd
87        import-gitapply-no-absurd
88        import-dsc-with-dgit-field);
89
90 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
91
92 our $suite_re = '[-+.0-9a-z]+';
93 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
94 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
95 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
96 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
97
98 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
99 our $splitbraincache = 'dgit-intern/quilt-cache';
100 our $rewritemap = 'dgit-rewrite/map';
101
102 our (@git) = qw(git);
103 our (@dget) = qw(dget);
104 our (@curl) = qw(curl);
105 our (@dput) = qw(dput);
106 our (@debsign) = qw(debsign);
107 our (@gpg) = qw(gpg);
108 our (@sbuild) = qw(sbuild);
109 our (@ssh) = 'ssh';
110 our (@dgit) = qw(dgit);
111 our (@aptget) = qw(apt-get);
112 our (@aptcache) = qw(apt-cache);
113 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
114 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
115 our (@dpkggenchanges) = qw(dpkg-genchanges);
116 our (@mergechanges) = qw(mergechanges -f);
117 our (@gbp_build) = ('');
118 our (@gbp_pq) = ('gbp pq');
119 our (@changesopts) = ('');
120
121 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
122                      'curl' => \@curl,
123                      'dput' => \@dput,
124                      'debsign' => \@debsign,
125                      'gpg' => \@gpg,
126                      'sbuild' => \@sbuild,
127                      'ssh' => \@ssh,
128                      'dgit' => \@dgit,
129                      'git' => \@git,
130                      'apt-get' => \@aptget,
131                      'apt-cache' => \@aptcache,
132                      'dpkg-source' => \@dpkgsource,
133                      'dpkg-buildpackage' => \@dpkgbuildpackage,
134                      'dpkg-genchanges' => \@dpkggenchanges,
135                      'gbp-build' => \@gbp_build,
136                      'gbp-pq' => \@gbp_pq,
137                      'ch' => \@changesopts,
138                      'mergechanges' => \@mergechanges);
139
140 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
141 our %opts_cfg_insertpos = map {
142     $_,
143     scalar @{ $opts_opt_map{$_} }
144 } keys %opts_opt_map;
145
146 sub parseopts_late_defaults();
147
148 our $keyid;
149
150 autoflush STDOUT 1;
151
152 our $supplementary_message = '';
153 our $need_split_build_invocation = 0;
154 our $split_brain = 0;
155
156 END {
157     local ($@, $?);
158     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
159 }
160
161 our $remotename = 'dgit';
162 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
163 our $csuite;
164 our $instead_distro;
165
166 if (!defined $absurdity) {
167     $absurdity = $0;
168     $absurdity =~ s{/[^/]+$}{/absurd} or die;
169 }
170
171 sub debiantag ($$) {
172     my ($v,$distro) = @_;
173     return $tagformatfn->($v, $distro);
174 }
175
176 sub debiantag_maintview ($$) { 
177     my ($v,$distro) = @_;
178     return "$distro/".dep14_version_mangle $v;
179 }
180
181 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
182
183 sub lbranch () { return "$branchprefix/$csuite"; }
184 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
185 sub lref () { return "refs/heads/".lbranch(); }
186 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
187 sub rrref () { return server_ref($csuite); }
188
189 sub stripepoch ($) {
190     my ($vsn) = @_;
191     $vsn =~ s/^\d+\://;
192     return $vsn;
193 }
194
195 sub srcfn ($$) {
196     my ($vsn,$sfx) = @_;
197     return "${package}_".(stripepoch $vsn).$sfx
198 }
199
200 sub dscfn ($) {
201     my ($vsn) = @_;
202     return srcfn($vsn,".dsc");
203 }
204
205 sub changespat ($;$) {
206     my ($vsn, $arch) = @_;
207     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
208 }
209
210 sub upstreamversion ($) {
211     my ($vsn) = @_;
212     $vsn =~ s/-[^-]+$//;
213     return $vsn;
214 }
215
216 our $us = 'dgit';
217 initdebug('');
218
219 our @end;
220 END { 
221     local ($?);
222     foreach my $f (@end) {
223         eval { $f->(); };
224         print STDERR "$us: cleanup: $@" if length $@;
225     }
226 };
227
228 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
229
230 sub forceable_fail ($$) {
231     my ($forceoptsl, $msg) = @_;
232     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
233     print STDERR "warning: overriding problem due to --force:\n". $msg;
234 }
235
236 sub forceing ($) {
237     my ($forceoptsl) = @_;
238     my @got = grep { $forceopts{$_} } @$forceoptsl;
239     return 0 unless @got;
240     print STDERR
241  "warning: skipping checks or functionality due to --force-$got[0]\n";
242 }
243
244 sub no_such_package () {
245     print STDERR "$us: package $package does not exist in suite $isuite\n";
246     exit 4;
247 }
248
249 sub changedir ($) {
250     my ($newdir) = @_;
251     printdebug "CD $newdir\n";
252     chdir $newdir or confess "chdir: $newdir: $!";
253 }
254
255 sub deliberately ($) {
256     my ($enquiry) = @_;
257     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
258 }
259
260 sub deliberately_not_fast_forward () {
261     foreach (qw(not-fast-forward fresh-repo)) {
262         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
263     }
264 }
265
266 sub quiltmode_splitbrain () {
267     $quilt_mode =~ m/gbp|dpm|unapplied/;
268 }
269
270 sub opts_opt_multi_cmd {
271     my @cmd;
272     push @cmd, split /\s+/, shift @_;
273     push @cmd, @_;
274     @cmd;
275 }
276
277 sub gbp_pq {
278     return opts_opt_multi_cmd @gbp_pq;
279 }
280
281 #---------- remote protocol support, common ----------
282
283 # remote push initiator/responder protocol:
284 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
285 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
286 #  < dgit-remote-push-ready <actual-proto-vsn>
287 #
288 # occasionally:
289 #
290 #  > progress NBYTES
291 #  [NBYTES message]
292 #
293 #  > supplementary-message NBYTES          # $protovsn >= 3
294 #  [NBYTES message]
295 #
296 # main sequence:
297 #
298 #  > file parsed-changelog
299 #  [indicates that output of dpkg-parsechangelog follows]
300 #  > data-block NBYTES
301 #  > [NBYTES bytes of data (no newline)]
302 #  [maybe some more blocks]
303 #  > data-end
304 #
305 #  > file dsc
306 #  [etc]
307 #
308 #  > file changes
309 #  [etc]
310 #
311 #  > param head DGIT-VIEW-HEAD
312 #  > param csuite SUITE
313 #  > param tagformat old|new
314 #  > param maint-view MAINT-VIEW-HEAD
315 #
316 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
317 #                                     # goes into tag, for replay prevention
318 #
319 #  > want signed-tag
320 #  [indicates that signed tag is wanted]
321 #  < data-block NBYTES
322 #  < [NBYTES bytes of data (no newline)]
323 #  [maybe some more blocks]
324 #  < data-end
325 #  < files-end
326 #
327 #  > want signed-dsc-changes
328 #  < data-block NBYTES    [transfer of signed dsc]
329 #  [etc]
330 #  < data-block NBYTES    [transfer of signed changes]
331 #  [etc]
332 #  < files-end
333 #
334 #  > complete
335
336 our $i_child_pid;
337
338 sub i_child_report () {
339     # Sees if our child has died, and reap it if so.  Returns a string
340     # describing how it died if it failed, or undef otherwise.
341     return undef unless $i_child_pid;
342     my $got = waitpid $i_child_pid, WNOHANG;
343     return undef if $got <= 0;
344     die unless $got == $i_child_pid;
345     $i_child_pid = undef;
346     return undef unless $?;
347     return "build host child ".waitstatusmsg();
348 }
349
350 sub badproto ($$) {
351     my ($fh, $m) = @_;
352     fail "connection lost: $!" if $fh->error;
353     fail "protocol violation; $m not expected";
354 }
355
356 sub badproto_badread ($$) {
357     my ($fh, $wh) = @_;
358     fail "connection lost: $!" if $!;
359     my $report = i_child_report();
360     fail $report if defined $report;
361     badproto $fh, "eof (reading $wh)";
362 }
363
364 sub protocol_expect (&$) {
365     my ($match, $fh) = @_;
366     local $_;
367     $_ = <$fh>;
368     defined && chomp or badproto_badread $fh, "protocol message";
369     if (wantarray) {
370         my @r = &$match;
371         return @r if @r;
372     } else {
373         my $r = &$match;
374         return $r if $r;
375     }
376     badproto $fh, "\`$_'";
377 }
378
379 sub protocol_send_file ($$) {
380     my ($fh, $ourfn) = @_;
381     open PF, "<", $ourfn or die "$ourfn: $!";
382     for (;;) {
383         my $d;
384         my $got = read PF, $d, 65536;
385         die "$ourfn: $!" unless defined $got;
386         last if !$got;
387         print $fh "data-block ".length($d)."\n" or die $!;
388         print $fh $d or die $!;
389     }
390     PF->error and die "$ourfn $!";
391     print $fh "data-end\n" or die $!;
392     close PF;
393 }
394
395 sub protocol_read_bytes ($$) {
396     my ($fh, $nbytes) = @_;
397     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
398     my $d;
399     my $got = read $fh, $d, $nbytes;
400     $got==$nbytes or badproto_badread $fh, "data block";
401     return $d;
402 }
403
404 sub protocol_receive_file ($$) {
405     my ($fh, $ourfn) = @_;
406     printdebug "() $ourfn\n";
407     open PF, ">", $ourfn or die "$ourfn: $!";
408     for (;;) {
409         my ($y,$l) = protocol_expect {
410             m/^data-block (.*)$/ ? (1,$1) :
411             m/^data-end$/ ? (0,) :
412             ();
413         } $fh;
414         last unless $y;
415         my $d = protocol_read_bytes $fh, $l;
416         print PF $d or die $!;
417     }
418     close PF or die $!;
419 }
420
421 #---------- remote protocol support, responder ----------
422
423 sub responder_send_command ($) {
424     my ($command) = @_;
425     return unless $we_are_responder;
426     # called even without $we_are_responder
427     printdebug ">> $command\n";
428     print PO $command, "\n" or die $!;
429 }    
430
431 sub responder_send_file ($$) {
432     my ($keyword, $ourfn) = @_;
433     return unless $we_are_responder;
434     printdebug "]] $keyword $ourfn\n";
435     responder_send_command "file $keyword";
436     protocol_send_file \*PO, $ourfn;
437 }
438
439 sub responder_receive_files ($@) {
440     my ($keyword, @ourfns) = @_;
441     die unless $we_are_responder;
442     printdebug "[[ $keyword @ourfns\n";
443     responder_send_command "want $keyword";
444     foreach my $fn (@ourfns) {
445         protocol_receive_file \*PI, $fn;
446     }
447     printdebug "[[\$\n";
448     protocol_expect { m/^files-end$/ } \*PI;
449 }
450
451 #---------- remote protocol support, initiator ----------
452
453 sub initiator_expect (&) {
454     my ($match) = @_;
455     protocol_expect { &$match } \*RO;
456 }
457
458 #---------- end remote code ----------
459
460 sub progress {
461     if ($we_are_responder) {
462         my $m = join '', @_;
463         responder_send_command "progress ".length($m) or die $!;
464         print PO $m or die $!;
465     } else {
466         print @_, "\n";
467     }
468 }
469
470 our $ua;
471
472 sub url_get {
473     if (!$ua) {
474         $ua = LWP::UserAgent->new();
475         $ua->env_proxy;
476     }
477     my $what = $_[$#_];
478     progress "downloading $what...";
479     my $r = $ua->get(@_) or die $!;
480     return undef if $r->code == 404;
481     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
482     return $r->decoded_content(charset => 'none');
483 }
484
485 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
486
487 sub runcmd {
488     debugcmd "+",@_;
489     $!=0; $?=-1;
490     failedcmd @_ if system @_;
491 }
492
493 sub act_local () { return $dryrun_level <= 1; }
494 sub act_scary () { return !$dryrun_level; }
495
496 sub printdone {
497     if (!$dryrun_level) {
498         progress "$us ok: @_";
499     } else {
500         progress "would be ok: @_ (but dry run only)";
501     }
502 }
503
504 sub dryrun_report {
505     printcmd(\*STDERR,$debugprefix."#",@_);
506 }
507
508 sub runcmd_ordryrun {
509     if (act_scary()) {
510         runcmd @_;
511     } else {
512         dryrun_report @_;
513     }
514 }
515
516 sub runcmd_ordryrun_local {
517     if (act_local()) {
518         runcmd @_;
519     } else {
520         dryrun_report @_;
521     }
522 }
523
524 sub shell_cmd {
525     my ($first_shell, @cmd) = @_;
526     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
527 }
528
529 our $helpmsg = <<END;
530 main usages:
531   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
532   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
533   dgit [dgit-opts] build [dpkg-buildpackage-opts]
534   dgit [dgit-opts] sbuild [sbuild-opts]
535   dgit [dgit-opts] push [dgit-opts] [suite]
536   dgit [dgit-opts] rpush build-host:build-dir ...
537 important dgit options:
538   -k<keyid>           sign tag and package with <keyid> instead of default
539   --dry-run -n        do not change anything, but go through the motions
540   --damp-run -L       like --dry-run but make local changes, without signing
541   --new -N            allow introducing a new package
542   --debug -D          increase debug level
543   -c<name>=<value>    set git config option (used directly by dgit too)
544 END
545
546 our $later_warning_msg = <<END;
547 Perhaps the upload is stuck in incoming.  Using the version from git.
548 END
549
550 sub badusage {
551     print STDERR "$us: @_\n", $helpmsg or die $!;
552     exit 8;
553 }
554
555 sub nextarg {
556     @ARGV or badusage "too few arguments";
557     return scalar shift @ARGV;
558 }
559
560 sub cmd_help () {
561     print $helpmsg or die $!;
562     exit 0;
563 }
564
565 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
566
567 our %defcfg = ('dgit.default.distro' => 'debian',
568                'dgit.default.old-dsc-distro' => 'debian',
569                'dgit-suite.*-security.distro' => 'debian-security',
570                'dgit.default.username' => '',
571                'dgit.default.archive-query-default-component' => 'main',
572                'dgit.default.ssh' => 'ssh',
573                'dgit.default.archive-query' => 'madison:',
574                'dgit.default.sshpsql-dbname' => 'service=projectb',
575                'dgit.default.aptget-components' => 'main',
576                'dgit.default.dgit-tag-format' => 'new,old,maint',
577                'dgit.dsc-url-proto-ok.http'    => 'true',
578                'dgit.dsc-url-proto-ok.https'   => 'true',
579                'dgit.dsc-url-proto-ok.git'     => 'true',
580                'dgit.default.dsc-url-proto-ok' => 'false',
581                # old means "repo server accepts pushes with old dgit tags"
582                # new means "repo server accepts pushes with new dgit tags"
583                # maint means "repo server accepts split brain pushes"
584                # hist means "repo server may have old pushes without new tag"
585                #   ("hist" is implied by "old")
586                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
587                'dgit-distro.debian.git-check' => 'url',
588                'dgit-distro.debian.git-check-suffix' => '/info/refs',
589                'dgit-distro.debian.new-private-pushers' => 't',
590                'dgit-distro.debian/push.git-url' => '',
591                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
592                'dgit-distro.debian/push.git-user-force' => 'dgit',
593                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
594                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
595                'dgit-distro.debian/push.git-create' => 'true',
596                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
597  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
598 # 'dgit-distro.debian.archive-query-tls-key',
599 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
600 # ^ this does not work because curl is broken nowadays
601 # Fixing #790093 properly will involve providing providing the key
602 # in some pacagke and maybe updating these paths.
603 #
604 # 'dgit-distro.debian.archive-query-tls-curl-args',
605 #   '--ca-path=/etc/ssl/ca-debian',
606 # ^ this is a workaround but works (only) on DSA-administered machines
607                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
608                'dgit-distro.debian.git-url-suffix' => '',
609                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
610                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
611  'dgit-distro.debian-security.archive-query' => 'aptget:',
612  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
613  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
614  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
615  'dgit-distro.debian-security.nominal-distro' => 'debian',
616  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
617  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
618                'dgit-distro.ubuntu.git-check' => 'false',
619  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
620                'dgit-distro.test-dummy.ssh' => "$td/ssh",
621                'dgit-distro.test-dummy.username' => "alice",
622                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
623                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
624                'dgit-distro.test-dummy.git-url' => "$td/git",
625                'dgit-distro.test-dummy.git-host' => "git",
626                'dgit-distro.test-dummy.git-path' => "$td/git",
627                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
628                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
629                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
630                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
631                );
632
633 our %gitcfgs;
634 our @gitcfgsources = qw(cmdline local global system);
635
636 sub git_slurp_config () {
637     local ($debuglevel) = $debuglevel-2;
638     local $/="\0";
639
640     # This algoritm is a bit subtle, but this is needed so that for
641     # options which we want to be single-valued, we allow the
642     # different config sources to override properly.  See #835858.
643     foreach my $src (@gitcfgsources) {
644         next if $src eq 'cmdline';
645         # we do this ourselves since git doesn't handle it
646         
647         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
648         debugcmd "|",@cmd;
649
650         open GITS, "-|", @cmd or die $!;
651         while (<GITS>) {
652             chomp or die;
653             printdebug "=> ", (messagequote $_), "\n";
654             m/\n/ or die "$_ ?";
655             push @{ $gitcfgs{$src}{$`} }, $'; #';
656         }
657         $!=0; $?=0;
658         close GITS
659             or ($!==0 && $?==256)
660             or failedcmd @cmd;
661     }
662 }
663
664 sub git_get_config ($) {
665     my ($c) = @_;
666     foreach my $src (@gitcfgsources) {
667         my $l = $gitcfgs{$src}{$c};
668         croak "$l $c" if $l && !ref $l;
669         printdebug"C $c ".(defined $l ?
670                            join " ", map { messagequote "'$_'" } @$l :
671                            "undef")."\n"
672             if $debuglevel >= 4;
673         $l or next;
674         @$l==1 or badcfg "multiple values for $c".
675             " (in $src git config)" if @$l > 1;
676         return $l->[0];
677     }
678     return undef;
679 }
680
681 sub cfg {
682     foreach my $c (@_) {
683         return undef if $c =~ /RETURN-UNDEF/;
684         printdebug "C? $c\n" if $debuglevel >= 5;
685         my $v = git_get_config($c);
686         return $v if defined $v;
687         my $dv = $defcfg{$c};
688         if (defined $dv) {
689             printdebug "CD $c $dv\n" if $debuglevel >= 4;
690             return $dv;
691         }
692     }
693     badcfg "need value for one of: @_\n".
694         "$us: distro or suite appears not to be (properly) supported";
695 }
696
697 sub access_basedistro__noalias () {
698     if (defined $idistro) {
699         return $idistro;
700     } else {    
701         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
702         return $def if defined $def;
703         foreach my $src (@gitcfgsources, 'internal') {
704             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
705             next unless $kl;
706             foreach my $k (keys %$kl) {
707                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
708                 my $dpat = $1;
709                 next unless match_glob $dpat, $isuite;
710                 return $kl->{$k};
711             }
712         }
713         return cfg("dgit.default.distro");
714     }
715 }
716
717 sub access_basedistro () {
718     my $noalias = access_basedistro__noalias();
719     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
720     return $canon // $noalias;
721 }
722
723 sub access_nomdistro () {
724     my $base = access_basedistro();
725     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
726     $r =~ m/^$distro_re$/ or badcfg
727  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
728     return $r;
729 }
730
731 sub access_quirk () {
732     # returns (quirk name, distro to use instead or undef, quirk-specific info)
733     my $basedistro = access_basedistro();
734     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
735                               'RETURN-UNDEF');
736     if (defined $backports_quirk) {
737         my $re = $backports_quirk;
738         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
739         $re =~ s/\*/.*/g;
740         $re =~ s/\%/([-0-9a-z_]+)/
741             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
742         if ($isuite =~ m/^$re$/) {
743             return ('backports',"$basedistro-backports",$1);
744         }
745     }
746     return ('none',undef);
747 }
748
749 our $access_forpush;
750
751 sub parse_cfg_bool ($$$) {
752     my ($what,$def,$v) = @_;
753     $v //= $def;
754     return
755         $v =~ m/^[ty1]/ ? 1 :
756         $v =~ m/^[fn0]/ ? 0 :
757         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
758 }       
759
760 sub access_forpush_config () {
761     my $d = access_basedistro();
762
763     return 1 if
764         $new_package &&
765         parse_cfg_bool('new-private-pushers', 0,
766                        cfg("dgit-distro.$d.new-private-pushers",
767                            'RETURN-UNDEF'));
768
769     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
770     $v //= 'a';
771     return
772         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
773         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
774         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
775         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
776 }
777
778 sub access_forpush () {
779     $access_forpush //= access_forpush_config();
780     return $access_forpush;
781 }
782
783 sub pushing () {
784     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
785     badcfg "pushing but distro is configured readonly"
786         if access_forpush_config() eq '0';
787     $access_forpush = 1;
788     $supplementary_message = <<'END' unless $we_are_responder;
789 Push failed, before we got started.
790 You can retry the push, after fixing the problem, if you like.
791 END
792     parseopts_late_defaults();
793 }
794
795 sub notpushing () {
796     parseopts_late_defaults();
797 }
798
799 sub supplementary_message ($) {
800     my ($msg) = @_;
801     if (!$we_are_responder) {
802         $supplementary_message = $msg;
803         return;
804     } elsif ($protovsn >= 3) {
805         responder_send_command "supplementary-message ".length($msg)
806             or die $!;
807         print PO $msg or die $!;
808     }
809 }
810
811 sub access_distros () {
812     # Returns list of distros to try, in order
813     #
814     # We want to try:
815     #    0. `instead of' distro name(s) we have been pointed to
816     #    1. the access_quirk distro, if any
817     #    2a. the user's specified distro, or failing that  } basedistro
818     #    2b. the distro calculated from the suite          }
819     my @l = access_basedistro();
820
821     my (undef,$quirkdistro) = access_quirk();
822     unshift @l, $quirkdistro;
823     unshift @l, $instead_distro;
824     @l = grep { defined } @l;
825
826     push @l, access_nomdistro();
827
828     if (access_forpush()) {
829         @l = map { ("$_/push", $_) } @l;
830     }
831     @l;
832 }
833
834 sub access_cfg_cfgs (@) {
835     my (@keys) = @_;
836     my @cfgs;
837     # The nesting of these loops determines the search order.  We put
838     # the key loop on the outside so that we search all the distros
839     # for each key, before going on to the next key.  That means that
840     # if access_cfg is called with a more specific, and then a less
841     # specific, key, an earlier distro can override the less specific
842     # without necessarily overriding any more specific keys.  (If the
843     # distro wants to override the more specific keys it can simply do
844     # so; whereas if we did the loop the other way around, it would be
845     # impossible to for an earlier distro to override a less specific
846     # key but not the more specific ones without restating the unknown
847     # values of the more specific keys.
848     my @realkeys;
849     my @rundef;
850     # We have to deal with RETURN-UNDEF specially, so that we don't
851     # terminate the search prematurely.
852     foreach (@keys) {
853         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
854         push @realkeys, $_
855     }
856     foreach my $d (access_distros()) {
857         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
858     }
859     push @cfgs, map { "dgit.default.$_" } @realkeys;
860     push @cfgs, @rundef;
861     return @cfgs;
862 }
863
864 sub access_cfg (@) {
865     my (@keys) = @_;
866     my (@cfgs) = access_cfg_cfgs(@keys);
867     my $value = cfg(@cfgs);
868     return $value;
869 }
870
871 sub access_cfg_bool ($$) {
872     my ($def, @keys) = @_;
873     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
874 }
875
876 sub string_to_ssh ($) {
877     my ($spec) = @_;
878     if ($spec =~ m/\s/) {
879         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
880     } else {
881         return ($spec);
882     }
883 }
884
885 sub access_cfg_ssh () {
886     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
887     if (!defined $gitssh) {
888         return @ssh;
889     } else {
890         return string_to_ssh $gitssh;
891     }
892 }
893
894 sub access_runeinfo ($) {
895     my ($info) = @_;
896     return ": dgit ".access_basedistro()." $info ;";
897 }
898
899 sub access_someuserhost ($) {
900     my ($some) = @_;
901     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
902     defined($user) && length($user) or
903         $user = access_cfg("$some-user",'username');
904     my $host = access_cfg("$some-host");
905     return length($user) ? "$user\@$host" : $host;
906 }
907
908 sub access_gituserhost () {
909     return access_someuserhost('git');
910 }
911
912 sub access_giturl (;$) {
913     my ($optional) = @_;
914     my $url = access_cfg('git-url','RETURN-UNDEF');
915     my $suffix;
916     if (!length $url) {
917         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
918         return undef unless defined $proto;
919         $url =
920             $proto.
921             access_gituserhost().
922             access_cfg('git-path');
923     } else {
924         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
925     }
926     $suffix //= '.git';
927     return "$url/$package$suffix";
928 }              
929
930 sub parsecontrolfh ($$;$) {
931     my ($fh, $desc, $allowsigned) = @_;
932     our $dpkgcontrolhash_noissigned;
933     my $c;
934     for (;;) {
935         my %opts = ('name' => $desc);
936         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
937         $c = Dpkg::Control::Hash->new(%opts);
938         $c->parse($fh,$desc) or die "parsing of $desc failed";
939         last if $allowsigned;
940         last if $dpkgcontrolhash_noissigned;
941         my $issigned= $c->get_option('is_pgp_signed');
942         if (!defined $issigned) {
943             $dpkgcontrolhash_noissigned= 1;
944             seek $fh, 0,0 or die "seek $desc: $!";
945         } elsif ($issigned) {
946             fail "control file $desc is (already) PGP-signed. ".
947                 " Note that dgit push needs to modify the .dsc and then".
948                 " do the signature itself";
949         } else {
950             last;
951         }
952     }
953     return $c;
954 }
955
956 sub parsecontrol {
957     my ($file, $desc, $allowsigned) = @_;
958     my $fh = new IO::Handle;
959     open $fh, '<', $file or die "$file: $!";
960     my $c = parsecontrolfh($fh,$desc,$allowsigned);
961     $fh->error and die $!;
962     close $fh;
963     return $c;
964 }
965
966 sub getfield ($$) {
967     my ($dctrl,$field) = @_;
968     my $v = $dctrl->{$field};
969     return $v if defined $v;
970     fail "missing field $field in ".$dctrl->get_option('name');
971 }
972
973 sub parsechangelog {
974     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
975     my $p = new IO::Handle;
976     my @cmd = (qw(dpkg-parsechangelog), @_);
977     open $p, '-|', @cmd or die $!;
978     $c->parse($p);
979     $?=0; $!=0; close $p or failedcmd @cmd;
980     return $c;
981 }
982
983 sub commit_getclogp ($) {
984     # Returns the parsed changelog hashref for a particular commit
985     my ($objid) = @_;
986     our %commit_getclogp_memo;
987     my $memo = $commit_getclogp_memo{$objid};
988     return $memo if $memo;
989     mkpath '.git/dgit';
990     my $mclog = ".git/dgit/clog-$objid";
991     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
992         "$objid:debian/changelog";
993     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
994 }
995
996 sub must_getcwd () {
997     my $d = getcwd();
998     defined $d or fail "getcwd failed: $!";
999     return $d;
1000 }
1001
1002 sub parse_dscdata () {
1003     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1004     printdebug Dumper($dscdata) if $debuglevel>1;
1005     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1006     printdebug Dumper($dsc) if $debuglevel>1;
1007 }
1008
1009 our %rmad;
1010
1011 sub archive_query ($;@) {
1012     my ($method) = shift @_;
1013     fail "this operation does not support multiple comma-separated suites"
1014         if $isuite =~ m/,/;
1015     my $query = access_cfg('archive-query','RETURN-UNDEF');
1016     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1017     my $proto = $1;
1018     my $data = $'; #';
1019     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1020 }
1021
1022 sub archive_query_prepend_mirror {
1023     my $m = access_cfg('mirror');
1024     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1025 }
1026
1027 sub pool_dsc_subpath ($$) {
1028     my ($vsn,$component) = @_; # $package is implict arg
1029     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1030     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1031 }
1032
1033 sub cfg_apply_map ($$$) {
1034     my ($varref, $what, $mapspec) = @_;
1035     return unless $mapspec;
1036
1037     printdebug "config $what EVAL{ $mapspec; }\n";
1038     $_ = $$varref;
1039     eval "package Dgit::Config; $mapspec;";
1040     die $@ if $@;
1041     $$varref = $_;
1042 }
1043
1044 #---------- `ftpmasterapi' archive query method (nascent) ----------
1045
1046 sub archive_api_query_cmd ($) {
1047     my ($subpath) = @_;
1048     my @cmd = (@curl, qw(-sS));
1049     my $url = access_cfg('archive-query-url');
1050     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1051         my $host = $1;
1052         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1053         foreach my $key (split /\:/, $keys) {
1054             $key =~ s/\%HOST\%/$host/g;
1055             if (!stat $key) {
1056                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1057                 next;
1058             }
1059             fail "config requested specific TLS key but do not know".
1060                 " how to get curl to use exactly that EE key ($key)";
1061 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1062 #           # Sadly the above line does not work because of changes
1063 #           # to gnutls.   The real fix for #790093 may involve
1064 #           # new curl options.
1065             last;
1066         }
1067         # Fixing #790093 properly will involve providing a value
1068         # for this on clients.
1069         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1070         push @cmd, split / /, $kargs if defined $kargs;
1071     }
1072     push @cmd, $url.$subpath;
1073     return @cmd;
1074 }
1075
1076 sub api_query ($$;$) {
1077     use JSON;
1078     my ($data, $subpath, $ok404) = @_;
1079     badcfg "ftpmasterapi archive query method takes no data part"
1080         if length $data;
1081     my @cmd = archive_api_query_cmd($subpath);
1082     my $url = $cmd[$#cmd];
1083     push @cmd, qw(-w %{http_code});
1084     my $json = cmdoutput @cmd;
1085     unless ($json =~ s/\d+\d+\d$//) {
1086         failedcmd_report_cmd undef, @cmd;
1087         fail "curl failed to print 3-digit HTTP code";
1088     }
1089     my $code = $&;
1090     return undef if $code eq '404' && $ok404;
1091     fail "fetch of $url gave HTTP code $code"
1092         unless $url =~ m#^file://# or $code =~ m/^2/;
1093     return decode_json($json);
1094 }
1095
1096 sub canonicalise_suite_ftpmasterapi {
1097     my ($proto,$data) = @_;
1098     my $suites = api_query($data, 'suites');
1099     my @matched;
1100     foreach my $entry (@$suites) {
1101         next unless grep { 
1102             my $v = $entry->{$_};
1103             defined $v && $v eq $isuite;
1104         } qw(codename name);
1105         push @matched, $entry;
1106     }
1107     fail "unknown suite $isuite" unless @matched;
1108     my $cn;
1109     eval {
1110         @matched==1 or die "multiple matches for suite $isuite\n";
1111         $cn = "$matched[0]{codename}";
1112         defined $cn or die "suite $isuite info has no codename\n";
1113         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1114     };
1115     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1116         if length $@;
1117     return $cn;
1118 }
1119
1120 sub archive_query_ftpmasterapi {
1121     my ($proto,$data) = @_;
1122     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1123     my @rows;
1124     my $digester = Digest::SHA->new(256);
1125     foreach my $entry (@$info) {
1126         eval {
1127             my $vsn = "$entry->{version}";
1128             my ($ok,$msg) = version_check $vsn;
1129             die "bad version: $msg\n" unless $ok;
1130             my $component = "$entry->{component}";
1131             $component =~ m/^$component_re$/ or die "bad component";
1132             my $filename = "$entry->{filename}";
1133             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1134                 or die "bad filename";
1135             my $sha256sum = "$entry->{sha256sum}";
1136             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1137             push @rows, [ $vsn, "/pool/$component/$filename",
1138                           $digester, $sha256sum ];
1139         };
1140         die "bad ftpmaster api response: $@\n".Dumper($entry)
1141             if length $@;
1142     }
1143     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1144     return archive_query_prepend_mirror @rows;
1145 }
1146
1147 sub file_in_archive_ftpmasterapi {
1148     my ($proto,$data,$filename) = @_;
1149     my $pat = $filename;
1150     $pat =~ s/_/\\_/g;
1151     $pat = "%/$pat";
1152     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1153     my $info = api_query($data, "file_in_archive/$pat", 1);
1154 }
1155
1156 #---------- `aptget' archive query method ----------
1157
1158 our $aptget_base;
1159 our $aptget_releasefile;
1160 our $aptget_configpath;
1161
1162 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1163 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1164
1165 sub aptget_cache_clean {
1166     runcmd_ordryrun_local qw(sh -ec),
1167         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1168         'x', $aptget_base;
1169 }
1170
1171 sub aptget_lock_acquire () {
1172     my $lockfile = "$aptget_base/lock";
1173     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1174     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1175 }
1176
1177 sub aptget_prep ($) {
1178     my ($data) = @_;
1179     return if defined $aptget_base;
1180
1181     badcfg "aptget archive query method takes no data part"
1182         if length $data;
1183
1184     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1185
1186     ensuredir $cache;
1187     ensuredir "$cache/dgit";
1188     my $cachekey =
1189         access_cfg('aptget-cachekey','RETURN-UNDEF')
1190         // access_nomdistro();
1191
1192     $aptget_base = "$cache/dgit/aptget";
1193     ensuredir $aptget_base;
1194
1195     my $quoted_base = $aptget_base;
1196     die "$quoted_base contains bad chars, cannot continue"
1197         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1198
1199     ensuredir $aptget_base;
1200
1201     aptget_lock_acquire();
1202
1203     aptget_cache_clean();
1204
1205     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1206     my $sourceslist = "source.list#$cachekey";
1207
1208     my $aptsuites = $isuite;
1209     cfg_apply_map(\$aptsuites, 'suite map',
1210                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1211
1212     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1213     printf SRCS "deb-src %s %s %s\n",
1214         access_cfg('mirror'),
1215         $aptsuites,
1216         access_cfg('aptget-components')
1217         or die $!;
1218
1219     ensuredir "$aptget_base/cache";
1220     ensuredir "$aptget_base/lists";
1221
1222     open CONF, ">", $aptget_configpath or die $!;
1223     print CONF <<END;
1224 Debug::NoLocking "true";
1225 APT::Get::List-Cleanup "false";
1226 #clear APT::Update::Post-Invoke-Success;
1227 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1228 Dir::State::Lists "$quoted_base/lists";
1229 Dir::Etc::preferences "$quoted_base/preferences";
1230 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1231 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1232 END
1233
1234     foreach my $key (qw(
1235                         Dir::Cache
1236                         Dir::State
1237                         Dir::Cache::Archives
1238                         Dir::Etc::SourceParts
1239                         Dir::Etc::preferencesparts
1240                       )) {
1241         ensuredir "$aptget_base/$key";
1242         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1243     };
1244
1245     my $oldatime = (time // die $!) - 1;
1246     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1247         next unless stat_exists $oldlist;
1248         my ($mtime) = (stat _)[9];
1249         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1250     }
1251
1252     runcmd_ordryrun_local aptget_aptget(), qw(update);
1253
1254     my @releasefiles;
1255     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1256         next unless stat_exists $oldlist;
1257         my ($atime) = (stat _)[8];
1258         next if $atime == $oldatime;
1259         push @releasefiles, $oldlist;
1260     }
1261     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1262     @releasefiles = @inreleasefiles if @inreleasefiles;
1263     die "apt updated wrong number of Release files (@releasefiles), erk"
1264         unless @releasefiles == 1;
1265
1266     ($aptget_releasefile) = @releasefiles;
1267 }
1268
1269 sub canonicalise_suite_aptget {
1270     my ($proto,$data) = @_;
1271     aptget_prep($data);
1272
1273     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1274
1275     foreach my $name (qw(Codename Suite)) {
1276         my $val = $release->{$name};
1277         if (defined $val) {
1278             printdebug "release file $name: $val\n";
1279             $val =~ m/^$suite_re$/o or fail
1280  "Release file ($aptget_releasefile) specifies intolerable $name";
1281             cfg_apply_map(\$val, 'suite rmap',
1282                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1283             return $val
1284         }
1285     }
1286     return $isuite;
1287 }
1288
1289 sub archive_query_aptget {
1290     my ($proto,$data) = @_;
1291     aptget_prep($data);
1292
1293     ensuredir "$aptget_base/source";
1294     foreach my $old (<$aptget_base/source/*.dsc>) {
1295         unlink $old or die "$old: $!";
1296     }
1297
1298     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1299     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1300     # avoids apt-get source failing with ambiguous error code
1301
1302     runcmd_ordryrun_local
1303         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1304         aptget_aptget(), qw(--download-only --only-source source), $package;
1305
1306     my @dscs = <$aptget_base/source/*.dsc>;
1307     fail "apt-get source did not produce a .dsc" unless @dscs;
1308     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1309
1310     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1311
1312     use URI::Escape;
1313     my $uri = "file://". uri_escape $dscs[0];
1314     $uri =~ s{\%2f}{/}gi;
1315     return [ (getfield $pre_dsc, 'Version'), $uri ];
1316 }
1317
1318 #---------- `dummyapicat' archive query method ----------
1319
1320 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1321 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1322
1323 sub file_in_archive_dummycatapi ($$$) {
1324     my ($proto,$data,$filename) = @_;
1325     my $mirror = access_cfg('mirror');
1326     $mirror =~ s#^file://#/# or die "$mirror ?";
1327     my @out;
1328     my @cmd = (qw(sh -ec), '
1329             cd "$1"
1330             find -name "$2" -print0 |
1331             xargs -0r sha256sum
1332         ', qw(x), $mirror, $filename);
1333     debugcmd "-|", @cmd;
1334     open FIA, "-|", @cmd or die $!;
1335     while (<FIA>) {
1336         chomp or die;
1337         printdebug "| $_\n";
1338         m/^(\w+)  (\S+)$/ or die "$_ ?";
1339         push @out, { sha256sum => $1, filename => $2 };
1340     }
1341     close FIA or die failedcmd @cmd;
1342     return \@out;
1343 }
1344
1345 #---------- `madison' archive query method ----------
1346
1347 sub archive_query_madison {
1348     return archive_query_prepend_mirror
1349         map { [ @$_[0..1] ] } madison_get_parse(@_);
1350 }
1351
1352 sub madison_get_parse {
1353     my ($proto,$data) = @_;
1354     die unless $proto eq 'madison';
1355     if (!length $data) {
1356         $data= access_cfg('madison-distro','RETURN-UNDEF');
1357         $data //= access_basedistro();
1358     }
1359     $rmad{$proto,$data,$package} ||= cmdoutput
1360         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1361     my $rmad = $rmad{$proto,$data,$package};
1362
1363     my @out;
1364     foreach my $l (split /\n/, $rmad) {
1365         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1366                   \s*( [^ \t|]+ )\s* \|
1367                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1368                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1369         $1 eq $package or die "$rmad $package ?";
1370         my $vsn = $2;
1371         my $newsuite = $3;
1372         my $component;
1373         if (defined $4) {
1374             $component = $4;
1375         } else {
1376             $component = access_cfg('archive-query-default-component');
1377         }
1378         $5 eq 'source' or die "$rmad ?";
1379         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1380     }
1381     return sort { -version_compare($a->[0],$b->[0]); } @out;
1382 }
1383
1384 sub canonicalise_suite_madison {
1385     # madison canonicalises for us
1386     my @r = madison_get_parse(@_);
1387     @r or fail
1388         "unable to canonicalise suite using package $package".
1389         " which does not appear to exist in suite $isuite;".
1390         " --existing-package may help";
1391     return $r[0][2];
1392 }
1393
1394 sub file_in_archive_madison { return undef; }
1395
1396 #---------- `sshpsql' archive query method ----------
1397
1398 sub sshpsql ($$$) {
1399     my ($data,$runeinfo,$sql) = @_;
1400     if (!length $data) {
1401         $data= access_someuserhost('sshpsql').':'.
1402             access_cfg('sshpsql-dbname');
1403     }
1404     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1405     my ($userhost,$dbname) = ($`,$'); #';
1406     my @rows;
1407     my @cmd = (access_cfg_ssh, $userhost,
1408                access_runeinfo("ssh-psql $runeinfo").
1409                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1410                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1411     debugcmd "|",@cmd;
1412     open P, "-|", @cmd or die $!;
1413     while (<P>) {
1414         chomp or die;
1415         printdebug(">|$_|\n");
1416         push @rows, $_;
1417     }
1418     $!=0; $?=0; close P or failedcmd @cmd;
1419     @rows or die;
1420     my $nrows = pop @rows;
1421     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1422     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1423     @rows = map { [ split /\|/, $_ ] } @rows;
1424     my $ncols = scalar @{ shift @rows };
1425     die if grep { scalar @$_ != $ncols } @rows;
1426     return @rows;
1427 }
1428
1429 sub sql_injection_check {
1430     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1431 }
1432
1433 sub archive_query_sshpsql ($$) {
1434     my ($proto,$data) = @_;
1435     sql_injection_check $isuite, $package;
1436     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1437         SELECT source.version, component.name, files.filename, files.sha256sum
1438           FROM source
1439           JOIN src_associations ON source.id = src_associations.source
1440           JOIN suite ON suite.id = src_associations.suite
1441           JOIN dsc_files ON dsc_files.source = source.id
1442           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1443           JOIN component ON component.id = files_archive_map.component_id
1444           JOIN files ON files.id = dsc_files.file
1445          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1446            AND source.source='$package'
1447            AND files.filename LIKE '%.dsc';
1448 END
1449     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1450     my $digester = Digest::SHA->new(256);
1451     @rows = map {
1452         my ($vsn,$component,$filename,$sha256sum) = @$_;
1453         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1454     } @rows;
1455     return archive_query_prepend_mirror @rows;
1456 }
1457
1458 sub canonicalise_suite_sshpsql ($$) {
1459     my ($proto,$data) = @_;
1460     sql_injection_check $isuite;
1461     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1462         SELECT suite.codename
1463           FROM suite where suite_name='$isuite' or codename='$isuite';
1464 END
1465     @rows = map { $_->[0] } @rows;
1466     fail "unknown suite $isuite" unless @rows;
1467     die "ambiguous $isuite: @rows ?" if @rows>1;
1468     return $rows[0];
1469 }
1470
1471 sub file_in_archive_sshpsql ($$$) { return undef; }
1472
1473 #---------- `dummycat' archive query method ----------
1474
1475 sub canonicalise_suite_dummycat ($$) {
1476     my ($proto,$data) = @_;
1477     my $dpath = "$data/suite.$isuite";
1478     if (!open C, "<", $dpath) {
1479         $!==ENOENT or die "$dpath: $!";
1480         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1481         return $isuite;
1482     }
1483     $!=0; $_ = <C>;
1484     chomp or die "$dpath: $!";
1485     close C;
1486     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1487     return $_;
1488 }
1489
1490 sub archive_query_dummycat ($$) {
1491     my ($proto,$data) = @_;
1492     canonicalise_suite();
1493     my $dpath = "$data/package.$csuite.$package";
1494     if (!open C, "<", $dpath) {
1495         $!==ENOENT or die "$dpath: $!";
1496         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1497         return ();
1498     }
1499     my @rows;
1500     while (<C>) {
1501         next if m/^\#/;
1502         next unless m/\S/;
1503         die unless chomp;
1504         printdebug "dummycat query $csuite $package $dpath | $_\n";
1505         my @row = split /\s+/, $_;
1506         @row==2 or die "$dpath: $_ ?";
1507         push @rows, \@row;
1508     }
1509     C->error and die "$dpath: $!";
1510     close C;
1511     return archive_query_prepend_mirror
1512         sort { -version_compare($a->[0],$b->[0]); } @rows;
1513 }
1514
1515 sub file_in_archive_dummycat () { return undef; }
1516
1517 #---------- tag format handling ----------
1518
1519 sub access_cfg_tagformats () {
1520     split /\,/, access_cfg('dgit-tag-format');
1521 }
1522
1523 sub access_cfg_tagformats_can_splitbrain () {
1524     my %y = map { $_ => 1 } access_cfg_tagformats;
1525     foreach my $needtf (qw(new maint)) {
1526         next if $y{$needtf};
1527         return 0;
1528     }
1529     return 1;
1530 }
1531
1532 sub need_tagformat ($$) {
1533     my ($fmt, $why) = @_;
1534     fail "need to use tag format $fmt ($why) but also need".
1535         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1536         " - no way to proceed"
1537         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1538     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1539 }
1540
1541 sub select_tagformat () {
1542     # sets $tagformatfn
1543     return if $tagformatfn && !$tagformat_want;
1544     die 'bug' if $tagformatfn && $tagformat_want;
1545     # ... $tagformat_want assigned after previous select_tagformat
1546
1547     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1548     printdebug "select_tagformat supported @supported\n";
1549
1550     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1551     printdebug "select_tagformat specified @$tagformat_want\n";
1552
1553     my ($fmt,$why,$override) = @$tagformat_want;
1554
1555     fail "target distro supports tag formats @supported".
1556         " but have to use $fmt ($why)"
1557         unless $override
1558             or grep { $_ eq $fmt } @supported;
1559
1560     $tagformat_want = undef;
1561     $tagformat = $fmt;
1562     $tagformatfn = ${*::}{"debiantag_$fmt"};
1563
1564     fail "trying to use unknown tag format \`$fmt' ($why) !"
1565         unless $tagformatfn;
1566 }
1567
1568 #---------- archive query entrypoints and rest of program ----------
1569
1570 sub canonicalise_suite () {
1571     return if defined $csuite;
1572     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1573     $csuite = archive_query('canonicalise_suite');
1574     if ($isuite ne $csuite) {
1575         progress "canonical suite name for $isuite is $csuite";
1576     } else {
1577         progress "canonical suite name is $csuite";
1578     }
1579 }
1580
1581 sub get_archive_dsc () {
1582     canonicalise_suite();
1583     my @vsns = archive_query('archive_query');
1584     foreach my $vinfo (@vsns) {
1585         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1586         $dscurl = $vsn_dscurl;
1587         $dscdata = url_get($dscurl);
1588         if (!$dscdata) {
1589             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1590             next;
1591         }
1592         if ($digester) {
1593             $digester->reset();
1594             $digester->add($dscdata);
1595             my $got = $digester->hexdigest();
1596             $got eq $digest or
1597                 fail "$dscurl has hash $got but".
1598                     " archive told us to expect $digest";
1599         }
1600         parse_dscdata();
1601         my $fmt = getfield $dsc, 'Format';
1602         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1603             "unsupported source format $fmt, sorry";
1604             
1605         $dsc_checked = !!$digester;
1606         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1607         return;
1608     }
1609     $dsc = undef;
1610     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1611 }
1612
1613 sub check_for_git ();
1614 sub check_for_git () {
1615     # returns 0 or 1
1616     my $how = access_cfg('git-check');
1617     if ($how eq 'ssh-cmd') {
1618         my @cmd =
1619             (access_cfg_ssh, access_gituserhost(),
1620              access_runeinfo("git-check $package").
1621              " set -e; cd ".access_cfg('git-path').";".
1622              " if test -d $package.git; then echo 1; else echo 0; fi");
1623         my $r= cmdoutput @cmd;
1624         if (defined $r and $r =~ m/^divert (\w+)$/) {
1625             my $divert=$1;
1626             my ($usedistro,) = access_distros();
1627             # NB that if we are pushing, $usedistro will be $distro/push
1628             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1629             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1630             progress "diverting to $divert (using config for $instead_distro)";
1631             return check_for_git();
1632         }
1633         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1634         return $r+0;
1635     } elsif ($how eq 'url') {
1636         my $prefix = access_cfg('git-check-url','git-url');
1637         my $suffix = access_cfg('git-check-suffix','git-suffix',
1638                                 'RETURN-UNDEF') // '.git';
1639         my $url = "$prefix/$package$suffix";
1640         my @cmd = (@curl, qw(-sS -I), $url);
1641         my $result = cmdoutput @cmd;
1642         $result =~ s/^\S+ 200 .*\n\r?\n//;
1643         # curl -sS -I with https_proxy prints
1644         # HTTP/1.0 200 Connection established
1645         $result =~ m/^\S+ (404|200) /s or
1646             fail "unexpected results from git check query - ".
1647                 Dumper($prefix, $result);
1648         my $code = $1;
1649         if ($code eq '404') {
1650             return 0;
1651         } elsif ($code eq '200') {
1652             return 1;
1653         } else {
1654             die;
1655         }
1656     } elsif ($how eq 'true') {
1657         return 1;
1658     } elsif ($how eq 'false') {
1659         return 0;
1660     } else {
1661         badcfg "unknown git-check \`$how'";
1662     }
1663 }
1664
1665 sub create_remote_git_repo () {
1666     my $how = access_cfg('git-create');
1667     if ($how eq 'ssh-cmd') {
1668         runcmd_ordryrun
1669             (access_cfg_ssh, access_gituserhost(),
1670              access_runeinfo("git-create $package").
1671              "set -e; cd ".access_cfg('git-path').";".
1672              " cp -a _template $package.git");
1673     } elsif ($how eq 'true') {
1674         # nothing to do
1675     } else {
1676         badcfg "unknown git-create \`$how'";
1677     }
1678 }
1679
1680 our ($dsc_hash,$lastpush_mergeinput);
1681 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1682
1683 our $ud = '.git/dgit/unpack';
1684
1685 sub prep_ud (;$) {
1686     my ($d) = @_;
1687     $d //= $ud;
1688     rmtree($d);
1689     mkpath '.git/dgit';
1690     mkdir $d or die $!;
1691 }
1692
1693 sub mktree_in_ud_here () {
1694     runcmd qw(git init -q);
1695     runcmd qw(git config gc.auto 0);
1696     rmtree('.git/objects');
1697     symlink '../../../../objects','.git/objects' or die $!;
1698 }
1699
1700 sub git_write_tree () {
1701     my $tree = cmdoutput @git, qw(write-tree);
1702     $tree =~ m/^\w+$/ or die "$tree ?";
1703     return $tree;
1704 }
1705
1706 sub git_add_write_tree () {
1707     runcmd @git, qw(add -Af .);
1708     return git_write_tree();
1709 }
1710
1711 sub remove_stray_gits ($) {
1712     my ($what) = @_;
1713     my @gitscmd = qw(find -name .git -prune -print0);
1714     debugcmd "|",@gitscmd;
1715     open GITS, "-|", @gitscmd or die $!;
1716     {
1717         local $/="\0";
1718         while (<GITS>) {
1719             chomp or die;
1720             print STDERR "$us: warning: removing from $what: ",
1721                 (messagequote $_), "\n";
1722             rmtree $_;
1723         }
1724     }
1725     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1726 }
1727
1728 sub mktree_in_ud_from_only_subdir ($;$) {
1729     my ($what,$raw) = @_;
1730
1731     # changes into the subdir
1732     my (@dirs) = <*/.>;
1733     die "expected one subdir but found @dirs ?" unless @dirs==1;
1734     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1735     my $dir = $1;
1736     changedir $dir;
1737
1738     remove_stray_gits($what);
1739     mktree_in_ud_here();
1740     if (!$raw) {
1741         my ($format, $fopts) = get_source_format();
1742         if (madformat($format)) {
1743             rmtree '.pc';
1744         }
1745     }
1746
1747     my $tree=git_add_write_tree();
1748     return ($tree,$dir);
1749 }
1750
1751 our @files_csum_info_fields = 
1752     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1753      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1754      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1755
1756 sub dsc_files_info () {
1757     foreach my $csumi (@files_csum_info_fields) {
1758         my ($fname, $module, $method) = @$csumi;
1759         my $field = $dsc->{$fname};
1760         next unless defined $field;
1761         eval "use $module; 1;" or die $@;
1762         my @out;
1763         foreach (split /\n/, $field) {
1764             next unless m/\S/;
1765             m/^(\w+) (\d+) (\S+)$/ or
1766                 fail "could not parse .dsc $fname line \`$_'";
1767             my $digester = eval "$module"."->$method;" or die $@;
1768             push @out, {
1769                 Hash => $1,
1770                 Bytes => $2,
1771                 Filename => $3,
1772                 Digester => $digester,
1773             };
1774         }
1775         return @out;
1776     }
1777     fail "missing any supported Checksums-* or Files field in ".
1778         $dsc->get_option('name');
1779 }
1780
1781 sub dsc_files () {
1782     map { $_->{Filename} } dsc_files_info();
1783 }
1784
1785 sub files_compare_inputs (@) {
1786     my $inputs = \@_;
1787     my %record;
1788     my %fchecked;
1789
1790     my $showinputs = sub {
1791         return join "; ", map { $_->get_option('name') } @$inputs;
1792     };
1793
1794     foreach my $in (@$inputs) {
1795         my $expected_files;
1796         my $in_name = $in->get_option('name');
1797
1798         printdebug "files_compare_inputs $in_name\n";
1799
1800         foreach my $csumi (@files_csum_info_fields) {
1801             my ($fname) = @$csumi;
1802             printdebug "files_compare_inputs $in_name $fname\n";
1803
1804             my $field = $in->{$fname};
1805             next unless defined $field;
1806
1807             my @files;
1808             foreach (split /\n/, $field) {
1809                 next unless m/\S/;
1810
1811                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1812                     fail "could not parse $in_name $fname line \`$_'";
1813
1814                 printdebug "files_compare_inputs $in_name $fname $f\n";
1815
1816                 push @files, $f;
1817
1818                 my $re = \ $record{$f}{$fname};
1819                 if (defined $$re) {
1820                     $fchecked{$f}{$in_name} = 1;
1821                     $$re eq $info or
1822                         fail "hash or size of $f varies in $fname fields".
1823                         " (between: ".$showinputs->().")";
1824                 } else {
1825                     $$re = $info;
1826                 }
1827             }
1828             @files = sort @files;
1829             $expected_files //= \@files;
1830             "@$expected_files" eq "@files" or
1831                 fail "file list in $in_name varies between hash fields!";
1832         }
1833         $expected_files or
1834             fail "$in_name has no files list field(s)";
1835     }
1836     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1837         if $debuglevel>=2;
1838
1839     grep { keys %$_ == @$inputs-1 } values %fchecked
1840         or fail "no file appears in all file lists".
1841         " (looked in: ".$showinputs->().")";
1842 }
1843
1844 sub is_orig_file_in_dsc ($$) {
1845     my ($f, $dsc_files_info) = @_;
1846     return 0 if @$dsc_files_info <= 1;
1847     # One file means no origs, and the filename doesn't have a "what
1848     # part of dsc" component.  (Consider versions ending `.orig'.)
1849     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1850     return 1;
1851 }
1852
1853 sub is_orig_file_of_vsn ($$) {
1854     my ($f, $upstreamvsn) = @_;
1855     my $base = srcfn $upstreamvsn, '';
1856     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1857     return 1;
1858 }
1859
1860 sub changes_update_origs_from_dsc ($$$$) {
1861     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1862     my %changes_f;
1863     printdebug "checking origs needed ($upstreamvsn)...\n";
1864     $_ = getfield $changes, 'Files';
1865     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1866         fail "cannot find section/priority from .changes Files field";
1867     my $placementinfo = $1;
1868     my %changed;
1869     printdebug "checking origs needed placement '$placementinfo'...\n";
1870     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1871         $l =~ m/\S+$/ or next;
1872         my $file = $&;
1873         printdebug "origs $file | $l\n";
1874         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1875         printdebug "origs $file is_orig\n";
1876         my $have = archive_query('file_in_archive', $file);
1877         if (!defined $have) {
1878             print STDERR <<END;
1879 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1880 END
1881             return;
1882         }
1883         my $found_same = 0;
1884         my @found_differ;
1885         printdebug "origs $file \$#\$have=$#$have\n";
1886         foreach my $h (@$have) {
1887             my $same = 0;
1888             my @differ;
1889             foreach my $csumi (@files_csum_info_fields) {
1890                 my ($fname, $module, $method, $archivefield) = @$csumi;
1891                 next unless defined $h->{$archivefield};
1892                 $_ = $dsc->{$fname};
1893                 next unless defined;
1894                 m/^(\w+) .* \Q$file\E$/m or
1895                     fail ".dsc $fname missing entry for $file";
1896                 if ($h->{$archivefield} eq $1) {
1897                     $same++;
1898                 } else {
1899                     push @differ,
1900  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1901                 }
1902             }
1903             die "$file ".Dumper($h)." ?!" if $same && @differ;
1904             $found_same++
1905                 if $same;
1906             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1907                 if @differ;
1908         }
1909         printdebug "origs $file f.same=$found_same".
1910             " #f._differ=$#found_differ\n";
1911         if (@found_differ && !$found_same) {
1912             fail join "\n",
1913                 "archive contains $file with different checksum",
1914                 @found_differ;
1915         }
1916         # Now we edit the changes file to add or remove it
1917         foreach my $csumi (@files_csum_info_fields) {
1918             my ($fname, $module, $method, $archivefield) = @$csumi;
1919             next unless defined $changes->{$fname};
1920             if ($found_same) {
1921                 # in archive, delete from .changes if it's there
1922                 $changed{$file} = "removed" if
1923                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1924             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1925                 # not in archive, but it's here in the .changes
1926             } else {
1927                 my $dsc_data = getfield $dsc, $fname;
1928                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1929                 my $extra = $1;
1930                 $extra =~ s/ \d+ /$&$placementinfo /
1931                     or die "$fname $extra >$dsc_data< ?"
1932                     if $fname eq 'Files';
1933                 $changes->{$fname} .= "\n". $extra;
1934                 $changed{$file} = "added";
1935             }
1936         }
1937     }
1938     if (%changed) {
1939         foreach my $file (keys %changed) {
1940             progress sprintf
1941                 "edited .changes for archive .orig contents: %s %s",
1942                 $changed{$file}, $file;
1943         }
1944         my $chtmp = "$changesfile.tmp";
1945         $changes->save($chtmp);
1946         if (act_local()) {
1947             rename $chtmp,$changesfile or die "$changesfile $!";
1948         } else {
1949             progress "[new .changes left in $changesfile]";
1950         }
1951     } else {
1952         progress "$changesfile already has appropriate .orig(s) (if any)";
1953     }
1954 }
1955
1956 sub make_commit ($) {
1957     my ($file) = @_;
1958     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1959 }
1960
1961 sub make_commit_text ($) {
1962     my ($text) = @_;
1963     my ($out, $in);
1964     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1965     debugcmd "|",@cmd;
1966     print Dumper($text) if $debuglevel > 1;
1967     my $child = open2($out, $in, @cmd) or die $!;
1968     my $h;
1969     eval {
1970         print $in $text or die $!;
1971         close $in or die $!;
1972         $h = <$out>;
1973         $h =~ m/^\w+$/ or die;
1974         $h = $&;
1975         printdebug "=> $h\n";
1976     };
1977     close $out;
1978     waitpid $child, 0 == $child or die "$child $!";
1979     $? and failedcmd @cmd;
1980     return $h;
1981 }
1982
1983 sub clogp_authline ($) {
1984     my ($clogp) = @_;
1985     my $author = getfield $clogp, 'Maintainer';
1986     $author =~ s#,.*##ms;
1987     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1988     my $authline = "$author $date";
1989     $authline =~ m/$git_authline_re/o or
1990         fail "unexpected commit author line format \`$authline'".
1991         " (was generated from changelog Maintainer field)";
1992     return ($1,$2,$3) if wantarray;
1993     return $authline;
1994 }
1995
1996 sub vendor_patches_distro ($$) {
1997     my ($checkdistro, $what) = @_;
1998     return unless defined $checkdistro;
1999
2000     my $series = "debian/patches/\L$checkdistro\E.series";
2001     printdebug "checking for vendor-specific $series ($what)\n";
2002
2003     if (!open SERIES, "<", $series) {
2004         die "$series $!" unless $!==ENOENT;
2005         return;
2006     }
2007     while (<SERIES>) {
2008         next unless m/\S/;
2009         next if m/^\s+\#/;
2010
2011         print STDERR <<END;
2012
2013 Unfortunately, this source package uses a feature of dpkg-source where
2014 the same source package unpacks to different source code on different
2015 distros.  dgit cannot safely operate on such packages on affected
2016 distros, because the meaning of source packages is not stable.
2017
2018 Please ask the distro/maintainer to remove the distro-specific series
2019 files and use a different technique (if necessary, uploading actually
2020 different packages, if different distros are supposed to have
2021 different code).
2022
2023 END
2024         fail "Found active distro-specific series file for".
2025             " $checkdistro ($what): $series, cannot continue";
2026     }
2027     die "$series $!" if SERIES->error;
2028     close SERIES;
2029 }
2030
2031 sub check_for_vendor_patches () {
2032     # This dpkg-source feature doesn't seem to be documented anywhere!
2033     # But it can be found in the changelog (reformatted):
2034
2035     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2036     #   Author: Raphael Hertzog <hertzog@debian.org>
2037     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2038
2039     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2040     #   series files
2041     #   
2042     #   If you have debian/patches/ubuntu.series and you were
2043     #   unpacking the source package on ubuntu, quilt was still
2044     #   directed to debian/patches/series instead of
2045     #   debian/patches/ubuntu.series.
2046     #   
2047     #   debian/changelog                        |    3 +++
2048     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2049     #   2 files changed, 6 insertions(+), 1 deletion(-)
2050
2051     use Dpkg::Vendor;
2052     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2053     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2054                          "Dpkg::Vendor \`current vendor'");
2055     vendor_patches_distro(access_basedistro(),
2056                           "(base) distro being accessed");
2057     vendor_patches_distro(access_nomdistro(),
2058                           "(nominal) distro being accessed");
2059 }
2060
2061 sub generate_commits_from_dsc () {
2062     # See big comment in fetch_from_archive, below.
2063     # See also README.dsc-import.
2064     prep_ud();
2065     changedir $ud;
2066
2067     my @dfi = dsc_files_info();
2068     foreach my $fi (@dfi) {
2069         my $f = $fi->{Filename};
2070         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2071
2072         printdebug "considering linking $f: ";
2073
2074         link_ltarget "../../../../$f", $f
2075             or ((printdebug "($!) "), 0)
2076             or $!==&ENOENT
2077             or die "$f $!";
2078
2079         printdebug "linked.\n";
2080
2081         complete_file_from_dsc('.', $fi)
2082             or next;
2083
2084         if (is_orig_file_in_dsc($f, \@dfi)) {
2085             link $f, "../../../../$f"
2086                 or $!==&EEXIST
2087                 or die "$f $!";
2088         }
2089     }
2090
2091     # We unpack and record the orig tarballs first, so that we only
2092     # need disk space for one private copy of the unpacked source.
2093     # But we can't make them into commits until we have the metadata
2094     # from the debian/changelog, so we record the tree objects now and
2095     # make them into commits later.
2096     my @tartrees;
2097     my $upstreamv = upstreamversion $dsc->{version};
2098     my $orig_f_base = srcfn $upstreamv, '';
2099
2100     foreach my $fi (@dfi) {
2101         # We actually import, and record as a commit, every tarball
2102         # (unless there is only one file, in which case there seems
2103         # little point.
2104
2105         my $f = $fi->{Filename};
2106         printdebug "import considering $f ";
2107         (printdebug "only one dfi\n"), next if @dfi == 1;
2108         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2109         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2110         my $compr_ext = $1;
2111
2112         my ($orig_f_part) =
2113             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2114
2115         printdebug "Y ", (join ' ', map { $_//"(none)" }
2116                           $compr_ext, $orig_f_part
2117                          ), "\n";
2118
2119         my $input = new IO::File $f, '<' or die "$f $!";
2120         my $compr_pid;
2121         my @compr_cmd;
2122
2123         if (defined $compr_ext) {
2124             my $cname =
2125                 Dpkg::Compression::compression_guess_from_filename $f;
2126             fail "Dpkg::Compression cannot handle file $f in source package"
2127                 if defined $compr_ext && !defined $cname;
2128             my $compr_proc =
2129                 new Dpkg::Compression::Process compression => $cname;
2130             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2131             my $compr_fh = new IO::Handle;
2132             my $compr_pid = open $compr_fh, "-|" // die $!;
2133             if (!$compr_pid) {
2134                 open STDIN, "<&", $input or die $!;
2135                 exec @compr_cmd;
2136                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2137             }
2138             $input = $compr_fh;
2139         }
2140
2141         rmtree "_unpack-tar";
2142         mkdir "_unpack-tar" or die $!;
2143         my @tarcmd = qw(tar -x -f -
2144                         --no-same-owner --no-same-permissions
2145                         --no-acls --no-xattrs --no-selinux);
2146         my $tar_pid = fork // die $!;
2147         if (!$tar_pid) {
2148             chdir "_unpack-tar" or die $!;
2149             open STDIN, "<&", $input or die $!;
2150             exec @tarcmd;
2151             die "dgit (child): exec $tarcmd[0]: $!";
2152         }
2153         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2154         !$? or failedcmd @tarcmd;
2155
2156         close $input or
2157             (@compr_cmd ? failedcmd @compr_cmd
2158              : die $!);
2159         # finally, we have the results in "tarball", but maybe
2160         # with the wrong permissions
2161
2162         runcmd qw(chmod -R +rwX _unpack-tar);
2163         changedir "_unpack-tar";
2164         remove_stray_gits($f);
2165         mktree_in_ud_here();
2166         
2167         my ($tree) = git_add_write_tree();
2168         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2169         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2170             $tree = $1;
2171             printdebug "one subtree $1\n";
2172         } else {
2173             printdebug "multiple subtrees\n";
2174         }
2175         changedir "..";
2176         rmtree "_unpack-tar";
2177
2178         my $ent = [ $f, $tree ];
2179         push @tartrees, {
2180             Orig => !!$orig_f_part,
2181             Sort => (!$orig_f_part         ? 2 :
2182                      $orig_f_part =~ m/-/g ? 1 :
2183                                              0),
2184             F => $f,
2185             Tree => $tree,
2186         };
2187     }
2188
2189     @tartrees = sort {
2190         # put any without "_" first (spec is not clear whether files
2191         # are always in the usual order).  Tarballs without "_" are
2192         # the main orig or the debian tarball.
2193         $a->{Sort} <=> $b->{Sort} or
2194         $a->{F}    cmp $b->{F}
2195     } @tartrees;
2196
2197     my $any_orig = grep { $_->{Orig} } @tartrees;
2198
2199     my $dscfn = "$package.dsc";
2200
2201     my $treeimporthow = 'package';
2202
2203     open D, ">", $dscfn or die "$dscfn: $!";
2204     print D $dscdata or die "$dscfn: $!";
2205     close D or die "$dscfn: $!";
2206     my @cmd = qw(dpkg-source);
2207     push @cmd, '--no-check' if $dsc_checked;
2208     if (madformat $dsc->{format}) {
2209         push @cmd, '--skip-patches';
2210         $treeimporthow = 'unpatched';
2211     }
2212     push @cmd, qw(-x --), $dscfn;
2213     runcmd @cmd;
2214
2215     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2216     if (madformat $dsc->{format}) { 
2217         check_for_vendor_patches();
2218     }
2219
2220     my $dappliedtree;
2221     if (madformat $dsc->{format}) {
2222         my @pcmd = qw(dpkg-source --before-build .);
2223         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2224         rmtree '.pc';
2225         $dappliedtree = git_add_write_tree();
2226     }
2227
2228     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2229     debugcmd "|",@clogcmd;
2230     open CLOGS, "-|", @clogcmd or die $!;
2231
2232     my $clogp;
2233     my $r1clogp;
2234
2235     printdebug "import clog search...\n";
2236
2237     for (;;) {
2238         my $stanzatext = do { local $/=""; <CLOGS>; };
2239         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2240         last if !defined $stanzatext;
2241
2242         my $desc = "package changelog, entry no.$.";
2243         open my $stanzafh, "<", \$stanzatext or die;
2244         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2245         $clogp //= $thisstanza;
2246
2247         printdebug "import clog $thisstanza->{version} $desc...\n";
2248
2249         last if !$any_orig; # we don't need $r1clogp
2250
2251         # We look for the first (most recent) changelog entry whose
2252         # version number is lower than the upstream version of this
2253         # package.  Then the last (least recent) previous changelog
2254         # entry is treated as the one which introduced this upstream
2255         # version and used for the synthetic commits for the upstream
2256         # tarballs.
2257
2258         # One might think that a more sophisticated algorithm would be
2259         # necessary.  But: we do not want to scan the whole changelog
2260         # file.  Stopping when we see an earlier version, which
2261         # necessarily then is an earlier upstream version, is the only
2262         # realistic way to do that.  Then, either the earliest
2263         # changelog entry we have seen so far is indeed the earliest
2264         # upload of this upstream version; or there are only changelog
2265         # entries relating to later upstream versions (which is not
2266         # possible unless the changelog and .dsc disagree about the
2267         # version).  Then it remains to choose between the physically
2268         # last entry in the file, and the one with the lowest version
2269         # number.  If these are not the same, we guess that the
2270         # versions were created in a non-monotic order rather than
2271         # that the changelog entries have been misordered.
2272
2273         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2274
2275         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2276         $r1clogp = $thisstanza;
2277
2278         printdebug "import clog $r1clogp->{version} becomes r1\n";
2279     }
2280     die $! if CLOGS->error;
2281     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2282
2283     $clogp or fail "package changelog has no entries!";
2284
2285     my $authline = clogp_authline $clogp;
2286     my $changes = getfield $clogp, 'Changes';
2287     my $cversion = getfield $clogp, 'Version';
2288
2289     if (@tartrees) {
2290         $r1clogp //= $clogp; # maybe there's only one entry;
2291         my $r1authline = clogp_authline $r1clogp;
2292         # Strictly, r1authline might now be wrong if it's going to be
2293         # unused because !$any_orig.  Whatever.
2294
2295         printdebug "import tartrees authline   $authline\n";
2296         printdebug "import tartrees r1authline $r1authline\n";
2297
2298         foreach my $tt (@tartrees) {
2299             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2300
2301             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2302 tree $tt->{Tree}
2303 author $r1authline
2304 committer $r1authline
2305
2306 Import $tt->{F}
2307
2308 [dgit import orig $tt->{F}]
2309 END_O
2310 tree $tt->{Tree}
2311 author $authline
2312 committer $authline
2313
2314 Import $tt->{F}
2315
2316 [dgit import tarball $package $cversion $tt->{F}]
2317 END_T
2318         }
2319     }
2320
2321     printdebug "import main commit\n";
2322
2323     open C, ">../commit.tmp" or die $!;
2324     print C <<END or die $!;
2325 tree $tree
2326 END
2327     print C <<END or die $! foreach @tartrees;
2328 parent $_->{Commit}
2329 END
2330     print C <<END or die $!;
2331 author $authline
2332 committer $authline
2333
2334 $changes
2335
2336 [dgit import $treeimporthow $package $cversion]
2337 END
2338
2339     close C or die $!;
2340     my $rawimport_hash = make_commit qw(../commit.tmp);
2341
2342     if (madformat $dsc->{format}) {
2343         printdebug "import apply patches...\n";
2344
2345         # regularise the state of the working tree so that
2346         # the checkout of $rawimport_hash works nicely.
2347         my $dappliedcommit = make_commit_text(<<END);
2348 tree $dappliedtree
2349 author $authline
2350 committer $authline
2351
2352 [dgit dummy commit]
2353 END
2354         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2355
2356         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2357
2358         # We need the answers to be reproducible
2359         my @authline = clogp_authline($clogp);
2360         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2361         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2362         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2363         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2364         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2365         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2366
2367         my $path = $ENV{PATH} or die;
2368
2369         foreach my $use_absurd (qw(0 1)) {
2370             runcmd @git, qw(checkout -q unpa);
2371             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2372             local $ENV{PATH} = $path;
2373             if ($use_absurd) {
2374                 chomp $@;
2375                 progress "warning: $@";
2376                 $path = "$absurdity:$path";
2377                 progress "$us: trying slow absurd-git-apply...";
2378                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2379                     or $!==ENOENT
2380                     or die $!;
2381             }
2382             eval {
2383                 die "forbid absurd git-apply\n" if $use_absurd
2384                     && forceing [qw(import-gitapply-no-absurd)];
2385                 die "only absurd git-apply!\n" if !$use_absurd
2386                     && forceing [qw(import-gitapply-absurd)];
2387
2388                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2389                 local $ENV{PATH} = $path                    if $use_absurd;
2390
2391                 my @showcmd = (gbp_pq, qw(import));
2392                 my @realcmd = shell_cmd
2393                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2394                 debugcmd "+",@realcmd;
2395                 if (system @realcmd) {
2396                     die +(shellquote @showcmd).
2397                         " failed: ".
2398                         failedcmd_waitstatus()."\n";
2399                 }
2400
2401                 my $gapplied = git_rev_parse('HEAD');
2402                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2403                 $gappliedtree eq $dappliedtree or
2404                     fail <<END;
2405 gbp-pq import and dpkg-source disagree!
2406  gbp-pq import gave commit $gapplied
2407  gbp-pq import gave tree $gappliedtree
2408  dpkg-source --before-build gave tree $dappliedtree
2409 END
2410                 $rawimport_hash = $gapplied;
2411             };
2412             last unless $@;
2413         }
2414         if ($@) {
2415             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2416             die $@;
2417         }
2418     }
2419
2420     progress "synthesised git commit from .dsc $cversion";
2421
2422     my $rawimport_mergeinput = {
2423         Commit => $rawimport_hash,
2424         Info => "Import of source package",
2425     };
2426     my @output = ($rawimport_mergeinput);
2427
2428     if ($lastpush_mergeinput) {
2429         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2430         my $oversion = getfield $oldclogp, 'Version';
2431         my $vcmp =
2432             version_compare($oversion, $cversion);
2433         if ($vcmp < 0) {
2434             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2435                 { Message => <<END, ReverseParents => 1 });
2436 Record $package ($cversion) in archive suite $csuite
2437 END
2438         } elsif ($vcmp > 0) {
2439             print STDERR <<END or die $!;
2440
2441 Version actually in archive:   $cversion (older)
2442 Last version pushed with dgit: $oversion (newer or same)
2443 $later_warning_msg
2444 END
2445             @output = $lastpush_mergeinput;
2446         } else {
2447             # Same version.  Use what's in the server git branch,
2448             # discarding our own import.  (This could happen if the
2449             # server automatically imports all packages into git.)
2450             @output = $lastpush_mergeinput;
2451         }
2452     }
2453     changedir '../../../..';
2454     rmtree($ud);
2455     return @output;
2456 }
2457
2458 sub complete_file_from_dsc ($$) {
2459     our ($dstdir, $fi) = @_;
2460     # Ensures that we have, in $dir, the file $fi, with the correct
2461     # contents.  (Downloading it from alongside $dscurl if necessary.)
2462
2463     my $f = $fi->{Filename};
2464     my $tf = "$dstdir/$f";
2465     my $downloaded = 0;
2466
2467     if (stat_exists $tf) {
2468         progress "using existing $f";
2469     } else {
2470         printdebug "$tf does not exist, need to fetch\n";
2471         my $furl = $dscurl;
2472         $furl =~ s{/[^/]+$}{};
2473         $furl .= "/$f";
2474         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2475         die "$f ?" if $f =~ m#/#;
2476         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2477         return 0 if !act_local();
2478         $downloaded = 1;
2479     }
2480
2481     open F, "<", "$tf" or die "$tf: $!";
2482     $fi->{Digester}->reset();
2483     $fi->{Digester}->addfile(*F);
2484     F->error and die $!;
2485     my $got = $fi->{Digester}->hexdigest();
2486     $got eq $fi->{Hash} or
2487         fail "file $f has hash $got but .dsc".
2488             " demands hash $fi->{Hash} ".
2489             ($downloaded ? "(got wrong file from archive!)"
2490              : "(perhaps you should delete this file?)");
2491
2492     return 1;
2493 }
2494
2495 sub ensure_we_have_orig () {
2496     my @dfi = dsc_files_info();
2497     foreach my $fi (@dfi) {
2498         my $f = $fi->{Filename};
2499         next unless is_orig_file_in_dsc($f, \@dfi);
2500         complete_file_from_dsc('..', $fi)
2501             or next;
2502     }
2503 }
2504
2505 #---------- git fetch ----------
2506
2507 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2508 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2509
2510 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2511 # locally fetched refs because they have unhelpful names and clutter
2512 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2513 # whether we have made another local ref which refers to this object).
2514 #
2515 # (If we deleted them unconditionally, then we might end up
2516 # re-fetching the same git objects each time dgit fetch was run.)
2517 #
2518 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
2519 # in git_fetch_us to fetch the refs in question, and possibly a call
2520 # to lrfetchref_used.
2521
2522 our (%lrfetchrefs_f, %lrfetchrefs_d);
2523 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2524
2525 sub lrfetchref_used ($) {
2526     my ($fullrefname) = @_;
2527     my $objid = $lrfetchrefs_f{$fullrefname};
2528     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2529 }
2530
2531 sub git_lrfetch_sane {
2532     my ($supplementary, @specs) = @_;
2533     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2534     # at least as regards @specs.  Also leave the results in
2535     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2536     # able to clean these up.
2537     #
2538     # With $supplementary==1, @specs must not contain wildcards
2539     # and we add to our previous fetches (non-atomically).
2540
2541     # This is rather miserable:
2542     # When git fetch --prune is passed a fetchspec ending with a *,
2543     # it does a plausible thing.  If there is no * then:
2544     # - it matches subpaths too, even if the supplied refspec
2545     #   starts refs, and behaves completely madly if the source
2546     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2547     # - if there is no matching remote ref, it bombs out the whole
2548     #   fetch.
2549     # We want to fetch a fixed ref, and we don't know in advance
2550     # if it exists, so this is not suitable.
2551     #
2552     # Our workaround is to use git ls-remote.  git ls-remote has its
2553     # own qairks.  Notably, it has the absurd multi-tail-matching
2554     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2555     # refs/refs/foo etc.
2556     #
2557     # Also, we want an idempotent snapshot, but we have to make two
2558     # calls to the remote: one to git ls-remote and to git fetch.  The
2559     # solution is use git ls-remote to obtain a target state, and
2560     # git fetch to try to generate it.  If we don't manage to generate
2561     # the target state, we try again.
2562
2563     my $url = access_giturl();
2564
2565     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2566
2567     my $specre = join '|', map {
2568         my $x = $_;
2569         $x =~ s/\W/\\$&/g;
2570         my $wildcard = $x =~ s/\\\*$/.*/;
2571         die if $wildcard && $supplementary;
2572         "(?:refs/$x)";
2573     } @specs;
2574     printdebug "git_lrfetch_sane specre=$specre\n";
2575     my $wanted_rref = sub {
2576         local ($_) = @_;
2577         return m/^(?:$specre)$/;
2578     };
2579
2580     my $fetch_iteration = 0;
2581     FETCH_ITERATION:
2582     for (;;) {
2583         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2584         if (++$fetch_iteration > 10) {
2585             fail "too many iterations trying to get sane fetch!";
2586         }
2587
2588         my @look = map { "refs/$_" } @specs;
2589         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2590         debugcmd "|",@lcmd;
2591
2592         my %wantr;
2593         open GITLS, "-|", @lcmd or die $!;
2594         while (<GITLS>) {
2595             printdebug "=> ", $_;
2596             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2597             my ($objid,$rrefname) = ($1,$2);
2598             if (!$wanted_rref->($rrefname)) {
2599                 print STDERR <<END;
2600 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2601 END
2602                 next;
2603             }
2604             $wantr{$rrefname} = $objid;
2605         }
2606         $!=0; $?=0;
2607         close GITLS or failedcmd @lcmd;
2608
2609         # OK, now %want is exactly what we want for refs in @specs
2610         my @fspecs = map {
2611             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2612             "+refs/$_:".lrfetchrefs."/$_";
2613         } @specs;
2614
2615         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2616
2617         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2618         runcmd_ordryrun_local @fcmd if @fspecs;
2619
2620         if (!$supplementary) {
2621             %lrfetchrefs_f = ();
2622         }
2623         my %objgot;
2624
2625         git_for_each_ref(lrfetchrefs, sub {
2626             my ($objid,$objtype,$lrefname,$reftail) = @_;
2627             $lrfetchrefs_f{$lrefname} = $objid;
2628             $objgot{$objid} = 1;
2629         });
2630
2631         if ($supplementary) {
2632             last;
2633         }
2634
2635         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2636             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2637             if (!exists $wantr{$rrefname}) {
2638                 if ($wanted_rref->($rrefname)) {
2639                     printdebug <<END;
2640 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2641 END
2642                 } else {
2643                     print STDERR <<END
2644 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2645 END
2646                 }
2647                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2648                 delete $lrfetchrefs_f{$lrefname};
2649                 next;
2650             }
2651         }
2652         foreach my $rrefname (sort keys %wantr) {
2653             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2654             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2655             my $want = $wantr{$rrefname};
2656             next if $got eq $want;
2657             if (!defined $objgot{$want}) {
2658                 print STDERR <<END;
2659 warning: git ls-remote suggests we want $lrefname
2660 warning:  and it should refer to $want
2661 warning:  but git fetch didn't fetch that object to any relevant ref.
2662 warning:  This may be due to a race with someone updating the server.
2663 warning:  Will try again...
2664 END
2665                 next FETCH_ITERATION;
2666             }
2667             printdebug <<END;
2668 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2669 END
2670             runcmd_ordryrun_local @git, qw(update-ref -m),
2671                 "dgit fetch git fetch fixup", $lrefname, $want;
2672             $lrfetchrefs_f{$lrefname} = $want;
2673         }
2674         last;
2675     }
2676
2677     if (defined $csuite) {
2678         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2679         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2680             my ($objid,$objtype,$lrefname,$reftail) = @_;
2681             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2682             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2683         });
2684     }
2685
2686     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2687         Dumper(\%lrfetchrefs_f);
2688 }
2689
2690 sub git_fetch_us () {
2691     # Want to fetch only what we are going to use, unless
2692     # deliberately-not-ff, in which case we must fetch everything.
2693
2694     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2695         map { "tags/$_" }
2696         (quiltmode_splitbrain
2697          ? (map { $_->('*',access_nomdistro) }
2698             \&debiantag_new, \&debiantag_maintview)
2699          : debiantags('*',access_nomdistro));
2700     push @specs, server_branch($csuite);
2701     push @specs, $rewritemap;
2702     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2703
2704     git_lrfetch_sane 0, @specs;
2705
2706     my %here;
2707     my @tagpats = debiantags('*',access_nomdistro);
2708
2709     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2710         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2711         printdebug "currently $fullrefname=$objid\n";
2712         $here{$fullrefname} = $objid;
2713     });
2714     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2715         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2716         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2717         printdebug "offered $lref=$objid\n";
2718         if (!defined $here{$lref}) {
2719             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2720             runcmd_ordryrun_local @upd;
2721             lrfetchref_used $fullrefname;
2722         } elsif ($here{$lref} eq $objid) {
2723             lrfetchref_used $fullrefname;
2724         } else {
2725             print STDERR \
2726                 "Not updateting $lref from $here{$lref} to $objid.\n";
2727         }
2728     });
2729 }
2730
2731 #---------- dsc and archive handling ----------
2732
2733 sub mergeinfo_getclogp ($) {
2734     # Ensures thit $mi->{Clogp} exists and returns it
2735     my ($mi) = @_;
2736     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2737 }
2738
2739 sub mergeinfo_version ($) {
2740     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2741 }
2742
2743 sub fetch_from_archive_record_1 ($) {
2744     my ($hash) = @_;
2745     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2746             'DGIT_ARCHIVE', $hash;
2747     cmdoutput @git, qw(log -n2), $hash;
2748     # ... gives git a chance to complain if our commit is malformed
2749 }
2750
2751 sub fetch_from_archive_record_2 ($) {
2752     my ($hash) = @_;
2753     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2754     if (act_local()) {
2755         cmdoutput @upd_cmd;
2756     } else {
2757         dryrun_report @upd_cmd;
2758     }
2759 }
2760
2761 sub parse_dsc_field ($$) {
2762     my ($dsc, $what) = @_;
2763     my $f;
2764     foreach my $field (@ourdscfield) {
2765         $f = $dsc->{$field};
2766         last if defined $f;
2767     }
2768     if (!defined $f) {
2769         progress "$what: NO git hash";
2770     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2771              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2772         progress "$what: specified git info ($dsc_distro)";
2773         $dsc_hint_tag = [ $dsc_hint_tag ];
2774     } elsif ($f =~ m/^\w+\s*$/) {
2775         $dsc_hash = $&;
2776         $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2777                                dgit.default.distro);
2778         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2779                           $dsc_distro ];
2780         progress "$what: specified git hash";
2781     } else {
2782         fail "$what: invalid Dgit info";
2783     }
2784 }
2785
2786 sub resolve_dsc_field_commit ($$) {
2787     my ($already_distro, $already_mapref) = @_;
2788
2789     return unless defined $dsc_hash;
2790
2791     my $mapref =
2792         defined $already_mapref &&
2793         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2794         ? $already_mapref : undef;
2795
2796     my $do_fetch;
2797     $do_fetch = sub {
2798         my ($what, @fetch) = @_;
2799
2800         local $idistro = $dsc_distro;
2801         my $lrf = lrfetchrefs;
2802
2803         if (!$chase_dsc_distro) {
2804             progress
2805                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2806             return 0;
2807         }
2808
2809         progress
2810             ".dsc names distro $dsc_distro: fetching $what";
2811
2812         my $url = access_giturl();
2813         if (!defined $url) {
2814             defined $dsc_hint_url or fail <<END;
2815 .dsc Dgit metadata is in context of distro $dsc_distro
2816 for which we have no configured url and .dsc provides no hint
2817 END
2818             my $proto =
2819                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2820                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2821             parse_cfg_bool "dsc-url-proto-ok", 'false',
2822                 cfg("dgit.dsc-url-proto-ok.$proto",
2823                     "dgit.default.dsc-url-proto-ok")
2824                 or fail <<END;
2825 .dsc Dgit metadata is in context of distro $dsc_distro
2826 for which we have no configured url;
2827 .dsc provices hinted url with protocol $proto which is unsafe.
2828 (can be overridden by config - consult documentation)
2829 END
2830             $url = $dsc_hint_url;
2831         }
2832
2833         git_lrfetch_sane 1, @fetch;
2834
2835         return $lrf;
2836     };
2837
2838     my $rewrite_enable = do {
2839         local $idistro = $dsc_distro;
2840         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2841     };
2842
2843     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2844         my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2845         $mapref = $lrf.'/'.$rewritemap;
2846         my $rewritemapdata = git_cat_file $mapref.':map';
2847         if (defined $rewritemapdata
2848             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2849             progress
2850                 "server's git history rewrite map contains a relevant entry!";
2851
2852             $dsc_hash = $1;
2853             if (defined $dsc_hash) {
2854                 progress "using rewritten git hash in place of .dsc value";
2855             } else {
2856                 progress "server data says .dsc hash is to be disregarded";
2857             }
2858         }
2859     }
2860
2861     if (!defined git_cat_file $dsc_hash) {
2862         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2863         my $lrf = $do_fetch->("additional commits", @tags) &&
2864             defined git_cat_file $dsc_hash
2865             or fail <<END;
2866 .dsc Dgit metadata requires commit $dsc_hash
2867 but we could not obtain that object anywhere.
2868 END
2869         foreach my $t (@tags) {
2870             my $fullrefname = $lrf.'/'.$t;
2871             print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2872             next unless $lrfetchrefs_f{$fullrefname};
2873             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2874             lrfetchref_used $fullrefname;
2875         }
2876     }
2877 }
2878
2879 sub fetch_from_archive () {
2880     ensure_setup_existing_tree();
2881
2882     # Ensures that lrref() is what is actually in the archive, one way
2883     # or another, according to us - ie this client's
2884     # appropritaely-updated archive view.  Also returns the commit id.
2885     # If there is nothing in the archive, leaves lrref alone and
2886     # returns undef.  git_fetch_us must have already been called.
2887     get_archive_dsc();
2888
2889     if ($dsc) {
2890         parse_dsc_field($dsc, 'last upload to archive');
2891         resolve_dsc_field_commit access_basedistro,
2892             lrfetchrefs."/".$rewritemap
2893     } else {
2894         progress "no version available from the archive";
2895     }
2896
2897     # If the archive's .dsc has a Dgit field, there are three
2898     # relevant git commitids we need to choose between and/or merge
2899     # together:
2900     #   1. $dsc_hash: the Dgit field from the archive
2901     #   2. $lastpush_hash: the suite branch on the dgit git server
2902     #   3. $lastfetch_hash: our local tracking brach for the suite
2903     #
2904     # These may all be distinct and need not be in any fast forward
2905     # relationship:
2906     #
2907     # If the dsc was pushed to this suite, then the server suite
2908     # branch will have been updated; but it might have been pushed to
2909     # a different suite and copied by the archive.  Conversely a more
2910     # recent version may have been pushed with dgit but not appeared
2911     # in the archive (yet).
2912     #
2913     # $lastfetch_hash may be awkward because archive imports
2914     # (particularly, imports of Dgit-less .dscs) are performed only as
2915     # needed on individual clients, so different clients may perform a
2916     # different subset of them - and these imports are only made
2917     # public during push.  So $lastfetch_hash may represent a set of
2918     # imports different to a subsequent upload by a different dgit
2919     # client.
2920     #
2921     # Our approach is as follows:
2922     #
2923     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2924     # descendant of $dsc_hash, then it was pushed by a dgit user who
2925     # had based their work on $dsc_hash, so we should prefer it.
2926     # Otherwise, $dsc_hash was installed into this suite in the
2927     # archive other than by a dgit push, and (necessarily) after the
2928     # last dgit push into that suite (since a dgit push would have
2929     # been descended from the dgit server git branch); thus, in that
2930     # case, we prefer the archive's version (and produce a
2931     # pseudo-merge to overwrite the dgit server git branch).
2932     #
2933     # (If there is no Dgit field in the archive's .dsc then
2934     # generate_commit_from_dsc uses the version numbers to decide
2935     # whether the suite branch or the archive is newer.  If the suite
2936     # branch is newer it ignores the archive's .dsc; otherwise it
2937     # generates an import of the .dsc, and produces a pseudo-merge to
2938     # overwrite the suite branch with the archive contents.)
2939     #
2940     # The outcome of that part of the algorithm is the `public view',
2941     # and is same for all dgit clients: it does not depend on any
2942     # unpublished history in the local tracking branch.
2943     #
2944     # As between the public view and the local tracking branch: The
2945     # local tracking branch is only updated by dgit fetch, and
2946     # whenever dgit fetch runs it includes the public view in the
2947     # local tracking branch.  Therefore if the public view is not
2948     # descended from the local tracking branch, the local tracking
2949     # branch must contain history which was imported from the archive
2950     # but never pushed; and, its tip is now out of date.  So, we make
2951     # a pseudo-merge to overwrite the old imports and stitch the old
2952     # history in.
2953     #
2954     # Finally: we do not necessarily reify the public view (as
2955     # described above).  This is so that we do not end up stacking two
2956     # pseudo-merges.  So what we actually do is figure out the inputs
2957     # to any public view pseudo-merge and put them in @mergeinputs.
2958
2959     my @mergeinputs;
2960     # $mergeinputs[]{Commit}
2961     # $mergeinputs[]{Info}
2962     # $mergeinputs[0] is the one whose tree we use
2963     # @mergeinputs is in the order we use in the actual commit)
2964     #
2965     # Also:
2966     # $mergeinputs[]{Message} is a commit message to use
2967     # $mergeinputs[]{ReverseParents} if def specifies that parent
2968     #                                list should be in opposite order
2969     # Such an entry has no Commit or Info.  It applies only when found
2970     # in the last entry.  (This ugliness is to support making
2971     # identical imports to previous dgit versions.)
2972
2973     my $lastpush_hash = git_get_ref(lrfetchref());
2974     printdebug "previous reference hash=$lastpush_hash\n";
2975     $lastpush_mergeinput = $lastpush_hash && {
2976         Commit => $lastpush_hash,
2977         Info => "dgit suite branch on dgit git server",
2978     };
2979
2980     my $lastfetch_hash = git_get_ref(lrref());
2981     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2982     my $lastfetch_mergeinput = $lastfetch_hash && {
2983         Commit => $lastfetch_hash,
2984         Info => "dgit client's archive history view",
2985     };
2986
2987     my $dsc_mergeinput = $dsc_hash && {
2988         Commit => $dsc_hash,
2989         Info => "Dgit field in .dsc from archive",
2990     };
2991
2992     my $cwd = getcwd();
2993     my $del_lrfetchrefs = sub {
2994         changedir $cwd;
2995         my $gur;
2996         printdebug "del_lrfetchrefs...\n";
2997         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2998             my $objid = $lrfetchrefs_d{$fullrefname};
2999             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3000             if (!$gur) {
3001                 $gur ||= new IO::Handle;
3002                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3003             }
3004             printf $gur "delete %s %s\n", $fullrefname, $objid;
3005         }
3006         if ($gur) {
3007             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3008         }
3009     };
3010
3011     if (defined $dsc_hash) {
3012         ensure_we_have_orig();
3013         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3014             @mergeinputs = $dsc_mergeinput
3015         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3016             print STDERR <<END or die $!;
3017
3018 Git commit in archive is behind the last version allegedly pushed/uploaded.
3019 Commit referred to by archive: $dsc_hash
3020 Last version pushed with dgit: $lastpush_hash
3021 $later_warning_msg
3022 END
3023             @mergeinputs = ($lastpush_mergeinput);
3024         } else {
3025             # Archive has .dsc which is not a descendant of the last dgit
3026             # push.  This can happen if the archive moves .dscs about.
3027             # Just follow its lead.
3028             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3029                 progress "archive .dsc names newer git commit";
3030                 @mergeinputs = ($dsc_mergeinput);
3031             } else {
3032                 progress "archive .dsc names other git commit, fixing up";
3033                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3034             }
3035         }
3036     } elsif ($dsc) {
3037         @mergeinputs = generate_commits_from_dsc();
3038         # We have just done an import.  Now, our import algorithm might
3039         # have been improved.  But even so we do not want to generate
3040         # a new different import of the same package.  So if the
3041         # version numbers are the same, just use our existing version.
3042         # If the version numbers are different, the archive has changed
3043         # (perhaps, rewound).
3044         if ($lastfetch_mergeinput &&
3045             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3046                               (mergeinfo_version $mergeinputs[0]) )) {
3047             @mergeinputs = ($lastfetch_mergeinput);
3048         }
3049     } elsif ($lastpush_hash) {
3050         # only in git, not in the archive yet
3051         @mergeinputs = ($lastpush_mergeinput);
3052         print STDERR <<END or die $!;
3053
3054 Package not found in the archive, but has allegedly been pushed using dgit.
3055 $later_warning_msg
3056 END
3057     } else {
3058         printdebug "nothing found!\n";
3059         if (defined $skew_warning_vsn) {
3060             print STDERR <<END or die $!;
3061
3062 Warning: relevant archive skew detected.
3063 Archive allegedly contains $skew_warning_vsn
3064 But we were not able to obtain any version from the archive or git.
3065
3066 END
3067         }
3068         unshift @end, $del_lrfetchrefs;
3069         return undef;
3070     }
3071
3072     if ($lastfetch_hash &&
3073         !grep {
3074             my $h = $_->{Commit};
3075             $h and is_fast_fwd($lastfetch_hash, $h);
3076             # If true, one of the existing parents of this commit
3077             # is a descendant of the $lastfetch_hash, so we'll
3078             # be ff from that automatically.
3079         } @mergeinputs
3080         ) {
3081         # Otherwise:
3082         push @mergeinputs, $lastfetch_mergeinput;
3083     }
3084
3085     printdebug "fetch mergeinfos:\n";
3086     foreach my $mi (@mergeinputs) {
3087         if ($mi->{Info}) {
3088             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3089         } else {
3090             printdebug sprintf " ReverseParents=%d Message=%s",
3091                 $mi->{ReverseParents}, $mi->{Message};
3092         }
3093     }
3094
3095     my $compat_info= pop @mergeinputs
3096         if $mergeinputs[$#mergeinputs]{Message};
3097
3098     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3099
3100     my $hash;
3101     if (@mergeinputs > 1) {
3102         # here we go, then:
3103         my $tree_commit = $mergeinputs[0]{Commit};
3104
3105         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3106         $tree =~ m/\n\n/;  $tree = $`;
3107         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3108         $tree = $1;
3109
3110         # We use the changelog author of the package in question the
3111         # author of this pseudo-merge.  This is (roughly) correct if
3112         # this commit is simply representing aa non-dgit upload.
3113         # (Roughly because it does not record sponsorship - but we
3114         # don't have sponsorship info because that's in the .changes,
3115         # which isn't in the archivw.)
3116         #
3117         # But, it might be that we are representing archive history
3118         # updates (including in-archive copies).  These are not really
3119         # the responsibility of the person who created the .dsc, but
3120         # there is no-one whose name we should better use.  (The
3121         # author of the .dsc-named commit is clearly worse.)
3122
3123         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3124         my $author = clogp_authline $useclogp;
3125         my $cversion = getfield $useclogp, 'Version';
3126
3127         my $mcf = ".git/dgit/mergecommit";
3128         open MC, ">", $mcf or die "$mcf $!";
3129         print MC <<END or die $!;
3130 tree $tree
3131 END
3132
3133         my @parents = grep { $_->{Commit} } @mergeinputs;
3134         @parents = reverse @parents if $compat_info->{ReverseParents};
3135         print MC <<END or die $! foreach @parents;
3136 parent $_->{Commit}
3137 END
3138
3139         print MC <<END or die $!;
3140 author $author
3141 committer $author
3142
3143 END
3144
3145         if (defined $compat_info->{Message}) {
3146             print MC $compat_info->{Message} or die $!;
3147         } else {
3148             print MC <<END or die $!;
3149 Record $package ($cversion) in archive suite $csuite
3150
3151 Record that
3152 END
3153             my $message_add_info = sub {
3154                 my ($mi) = (@_);
3155                 my $mversion = mergeinfo_version $mi;
3156                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3157                     or die $!;
3158             };
3159
3160             $message_add_info->($mergeinputs[0]);
3161             print MC <<END or die $!;
3162 should be treated as descended from
3163 END
3164             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3165         }
3166
3167         close MC or die $!;
3168         $hash = make_commit $mcf;
3169     } else {
3170         $hash = $mergeinputs[0]{Commit};
3171     }
3172     printdebug "fetch hash=$hash\n";
3173
3174     my $chkff = sub {
3175         my ($lasth, $what) = @_;
3176         return unless $lasth;
3177         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3178     };
3179
3180     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3181         if $lastpush_hash;
3182     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3183
3184     fetch_from_archive_record_1($hash);
3185
3186     if (defined $skew_warning_vsn) {
3187         mkpath '.git/dgit';
3188         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3189         my $gotclogp = commit_getclogp($hash);
3190         my $got_vsn = getfield $gotclogp, 'Version';
3191         printdebug "SKEW CHECK GOT $got_vsn\n";
3192         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3193             print STDERR <<END or die $!;
3194
3195 Warning: archive skew detected.  Using the available version:
3196 Archive allegedly contains    $skew_warning_vsn
3197 We were able to obtain only   $got_vsn
3198
3199 END
3200         }
3201     }
3202
3203     if ($lastfetch_hash ne $hash) {
3204         fetch_from_archive_record_2($hash);
3205     }
3206
3207     lrfetchref_used lrfetchref();
3208
3209     unshift @end, $del_lrfetchrefs;
3210     return $hash;
3211 }
3212
3213 sub set_local_git_config ($$) {
3214     my ($k, $v) = @_;
3215     runcmd @git, qw(config), $k, $v;
3216 }
3217
3218 sub setup_mergechangelogs (;$) {
3219     my ($always) = @_;
3220     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3221
3222     my $driver = 'dpkg-mergechangelogs';
3223     my $cb = "merge.$driver";
3224     my $attrs = '.git/info/attributes';
3225     ensuredir '.git/info';
3226
3227     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3228     if (!open ATTRS, "<", $attrs) {
3229         $!==ENOENT or die "$attrs: $!";
3230     } else {
3231         while (<ATTRS>) {
3232             chomp;
3233             next if m{^debian/changelog\s};
3234             print NATTRS $_, "\n" or die $!;
3235         }
3236         ATTRS->error and die $!;
3237         close ATTRS;
3238     }
3239     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3240     close NATTRS;
3241
3242     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3243     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3244
3245     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3246 }
3247
3248 sub setup_useremail (;$) {
3249     my ($always) = @_;
3250     return unless $always || access_cfg_bool(1, 'setup-useremail');
3251
3252     my $setup = sub {
3253         my ($k, $envvar) = @_;
3254         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3255         return unless defined $v;
3256         set_local_git_config "user.$k", $v;
3257     };
3258
3259     $setup->('email', 'DEBEMAIL');
3260     $setup->('name', 'DEBFULLNAME');
3261 }
3262
3263 sub ensure_setup_existing_tree () {
3264     my $k = "remote.$remotename.skipdefaultupdate";
3265     my $c = git_get_config $k;
3266     return if defined $c;
3267     set_local_git_config $k, 'true';
3268 }
3269
3270 sub setup_new_tree () {
3271     setup_mergechangelogs();
3272     setup_useremail();
3273 }
3274
3275 sub multisuite_suite_child ($$$) {
3276     my ($tsuite, $merginputs, $fn) = @_;
3277     # in child, sets things up, calls $fn->(), and returns undef
3278     # in parent, returns canonical suite name for $tsuite
3279     my $canonsuitefh = IO::File::new_tmpfile;
3280     my $pid = fork // die $!;
3281     if (!$pid) {
3282         $isuite = $tsuite;
3283         $us .= " [$isuite]";
3284         $debugprefix .= " ";
3285         progress "fetching $tsuite...";
3286         canonicalise_suite();
3287         print $canonsuitefh $csuite, "\n" or die $!;
3288         close $canonsuitefh or die $!;
3289         $fn->();
3290         return undef;
3291     }
3292     waitpid $pid,0 == $pid or die $!;
3293     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3294     seek $canonsuitefh,0,0 or die $!;
3295     local $csuite = <$canonsuitefh>;
3296     die $! unless defined $csuite && chomp $csuite;
3297     if ($? == 256*4) {
3298         printdebug "multisuite $tsuite missing\n";
3299         return $csuite;
3300     }
3301     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3302     push @$merginputs, {
3303         Ref => lrref,
3304         Info => $csuite,
3305     };
3306     return $csuite;
3307 }
3308
3309 sub fork_for_multisuite ($) {
3310     my ($before_fetch_merge) = @_;
3311     # if nothing unusual, just returns ''
3312     #
3313     # if multisuite:
3314     # returns 0 to caller in child, to do first of the specified suites
3315     # in child, $csuite is not yet set
3316     #
3317     # returns 1 to caller in parent, to finish up anything needed after
3318     # in parent, $csuite is set to canonicalised portmanteau
3319
3320     my $org_isuite = $isuite;
3321     my @suites = split /\,/, $isuite;
3322     return '' unless @suites > 1;
3323     printdebug "fork_for_multisuite: @suites\n";
3324
3325     my @mergeinputs;
3326
3327     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3328                                             sub { });
3329     return 0 unless defined $cbasesuite;
3330
3331     fail "package $package missing in (base suite) $cbasesuite"
3332         unless @mergeinputs;
3333
3334     my @csuites = ($cbasesuite);
3335
3336     $before_fetch_merge->();
3337
3338     foreach my $tsuite (@suites[1..$#suites]) {
3339         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3340                                                sub {
3341             @end = ();
3342             fetch();
3343             exit 0;
3344         });
3345         # xxx collecte the ref here
3346
3347         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3348         push @csuites, $csubsuite;
3349     }
3350
3351     foreach my $mi (@mergeinputs) {
3352         my $ref = git_get_ref $mi->{Ref};
3353         die "$mi->{Ref} ?" unless length $ref;
3354         $mi->{Commit} = $ref;
3355     }
3356
3357     $csuite = join ",", @csuites;
3358
3359     my $previous = git_get_ref lrref;
3360     if ($previous) {
3361         unshift @mergeinputs, {
3362             Commit => $previous,
3363             Info => "local combined tracking branch",
3364             Warning =>
3365  "archive seems to have rewound: local tracking branch is ahead!",
3366         };
3367     }
3368
3369     foreach my $ix (0..$#mergeinputs) {
3370         $mergeinputs[$ix]{Index} = $ix;
3371     }
3372
3373     @mergeinputs = sort {
3374         -version_compare(mergeinfo_version $a,
3375                          mergeinfo_version $b) # highest version first
3376             or
3377         $a->{Index} <=> $b->{Index}; # earliest in spec first
3378     } @mergeinputs;
3379
3380     my @needed;
3381
3382   NEEDED:
3383     foreach my $mi (@mergeinputs) {
3384         printdebug "multisuite merge check $mi->{Info}\n";
3385         foreach my $previous (@needed) {
3386             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3387             printdebug "multisuite merge un-needed $previous->{Info}\n";
3388             next NEEDED;
3389         }
3390         push @needed, $mi;
3391         printdebug "multisuite merge this-needed\n";
3392         $mi->{Character} = '+';
3393     }
3394
3395     $needed[0]{Character} = '*';
3396
3397     my $output = $needed[0]{Commit};
3398
3399     if (@needed > 1) {
3400         printdebug "multisuite merge nontrivial\n";
3401         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3402
3403         my $commit = "tree $tree\n";
3404         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3405             "Input branches:\n";
3406
3407         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3408             printdebug "multisuite merge include $mi->{Info}\n";
3409             $mi->{Character} //= ' ';
3410             $commit .= "parent $mi->{Commit}\n";
3411             $msg .= sprintf " %s  %-25s %s\n",
3412                 $mi->{Character},
3413                 (mergeinfo_version $mi),
3414                 $mi->{Info};
3415         }
3416         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3417         $msg .= "\nKey\n".
3418             " * marks the highest version branch, which choose to use\n".
3419             " + marks each branch which was not already an ancestor\n\n".
3420             "[dgit multi-suite $csuite]\n";
3421         $commit .=
3422             "author $authline\n".
3423             "committer $authline\n\n";
3424         $output = make_commit_text $commit.$msg;
3425         printdebug "multisuite merge generated $output\n";
3426     }
3427
3428     fetch_from_archive_record_1($output);
3429     fetch_from_archive_record_2($output);
3430
3431     progress "calculated combined tracking suite $csuite";
3432
3433     return 1;
3434 }
3435
3436 sub clone_set_head () {
3437     open H, "> .git/HEAD" or die $!;
3438     print H "ref: ".lref()."\n" or die $!;
3439     close H or die $!;
3440 }
3441 sub clone_finish ($) {
3442     my ($dstdir) = @_;
3443     runcmd @git, qw(reset --hard), lrref();
3444     runcmd qw(bash -ec), <<'END';
3445         set -o pipefail
3446         git ls-tree -r --name-only -z HEAD | \
3447         xargs -0r touch -h -r . --
3448 END
3449     printdone "ready for work in $dstdir";
3450 }
3451
3452 sub clone ($) {
3453     my ($dstdir) = @_;
3454     badusage "dry run makes no sense with clone" unless act_local();
3455
3456     my $multi_fetched = fork_for_multisuite(sub {
3457         printdebug "multi clone before fetch merge\n";
3458         changedir $dstdir;
3459     });
3460     if ($multi_fetched) {
3461         printdebug "multi clone after fetch merge\n";
3462         clone_set_head();
3463         clone_finish($dstdir);
3464         exit 0;
3465     }
3466     printdebug "clone main body\n";
3467
3468     canonicalise_suite();
3469     my $hasgit = check_for_git();
3470     mkdir $dstdir or fail "create \`$dstdir': $!";
3471     changedir $dstdir;
3472     runcmd @git, qw(init -q);
3473     clone_set_head();
3474     my $giturl = access_giturl(1);
3475     if (defined $giturl) {
3476         runcmd @git, qw(remote add), 'origin', $giturl;
3477     }
3478     if ($hasgit) {
3479         progress "fetching existing git history";
3480         git_fetch_us();
3481         runcmd_ordryrun_local @git, qw(fetch origin);
3482     } else {
3483         progress "starting new git history";
3484     }
3485     fetch_from_archive() or no_such_package;
3486     my $vcsgiturl = $dsc->{'Vcs-Git'};
3487     if (length $vcsgiturl) {
3488         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3489         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3490     }
3491     setup_new_tree();
3492     clone_finish($dstdir);
3493 }
3494
3495 sub fetch () {
3496     canonicalise_suite();
3497     if (check_for_git()) {
3498         git_fetch_us();
3499     }
3500     fetch_from_archive() or no_such_package();
3501     printdone "fetched into ".lrref();
3502 }
3503
3504 sub pull () {
3505     my $multi_fetched = fork_for_multisuite(sub { });
3506     fetch() unless $multi_fetched; # parent
3507     return if $multi_fetched eq '0'; # child
3508     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3509         lrref();
3510     printdone "fetched to ".lrref()." and merged into HEAD";
3511 }
3512
3513 sub check_not_dirty () {
3514     foreach my $f (qw(local-options local-patch-header)) {
3515         if (stat_exists "debian/source/$f") {
3516             fail "git tree contains debian/source/$f";
3517         }
3518     }
3519
3520     return if $ignoredirty;
3521
3522     my @cmd = (@git, qw(diff --quiet HEAD));
3523     debugcmd "+",@cmd;
3524     $!=0; $?=-1; system @cmd;
3525     return if !$?;
3526     if ($?==256) {
3527         fail "working tree is dirty (does not match HEAD)";
3528     } else {
3529         failedcmd @cmd;
3530     }
3531 }
3532
3533 sub commit_admin ($) {
3534     my ($m) = @_;
3535     progress "$m";
3536     runcmd_ordryrun_local @git, qw(commit -m), $m;
3537 }
3538
3539 sub commit_quilty_patch () {
3540     my $output = cmdoutput @git, qw(status --porcelain);
3541     my %adds;
3542     foreach my $l (split /\n/, $output) {
3543         next unless $l =~ m/\S/;
3544         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3545             $adds{$1}++;
3546         }
3547     }
3548     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3549     if (!%adds) {
3550         progress "nothing quilty to commit, ok.";
3551         return;
3552     }
3553     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3554     runcmd_ordryrun_local @git, qw(add -f), @adds;
3555     commit_admin <<END
3556 Commit Debian 3.0 (quilt) metadata
3557
3558 [dgit ($our_version) quilt-fixup]
3559 END
3560 }
3561
3562 sub get_source_format () {
3563     my %options;
3564     if (open F, "debian/source/options") {
3565         while (<F>) {
3566             next if m/^\s*\#/;
3567             next unless m/\S/;
3568             s/\s+$//; # ignore missing final newline
3569             if (m/\s*\#\s*/) {
3570                 my ($k, $v) = ($`, $'); #');
3571                 $v =~ s/^"(.*)"$/$1/;
3572                 $options{$k} = $v;
3573             } else {
3574                 $options{$_} = 1;
3575             }
3576         }
3577         F->error and die $!;
3578         close F;
3579     } else {
3580         die $! unless $!==&ENOENT;
3581     }
3582
3583     if (!open F, "debian/source/format") {
3584         die $! unless $!==&ENOENT;
3585         return '';
3586     }
3587     $_ = <F>;
3588     F->error and die $!;
3589     chomp;
3590     return ($_, \%options);
3591 }
3592
3593 sub madformat_wantfixup ($) {
3594     my ($format) = @_;
3595     return 0 unless $format eq '3.0 (quilt)';
3596     our $quilt_mode_warned;
3597     if ($quilt_mode eq 'nocheck') {
3598         progress "Not doing any fixup of \`$format' due to".
3599             " ----no-quilt-fixup or --quilt=nocheck"
3600             unless $quilt_mode_warned++;
3601         return 0;
3602     }
3603     progress "Format \`$format', need to check/update patch stack"
3604         unless $quilt_mode_warned++;
3605     return 1;
3606 }
3607
3608 sub maybe_split_brain_save ($$$) {
3609     my ($headref, $dgitview, $msg) = @_;
3610     # => message fragment "$saved" describing disposition of $dgitview
3611     return "commit id $dgitview" unless defined $split_brain_save;
3612     my @cmd = (shell_cmd "cd ../../../..",
3613                @git, qw(update-ref -m),
3614                "dgit --dgit-view-save $msg HEAD=$headref",
3615                $split_brain_save, $dgitview);
3616     runcmd @cmd;
3617     return "and left in $split_brain_save";
3618 }
3619
3620 # An "infopair" is a tuple [ $thing, $what ]
3621 # (often $thing is a commit hash; $what is a description)
3622
3623 sub infopair_cond_equal ($$) {
3624     my ($x,$y) = @_;
3625     $x->[0] eq $y->[0] or fail <<END;
3626 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3627 END
3628 };
3629
3630 sub infopair_lrf_tag_lookup ($$) {
3631     my ($tagnames, $what) = @_;
3632     # $tagname may be an array ref
3633     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3634     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3635     foreach my $tagname (@tagnames) {
3636         my $lrefname = lrfetchrefs."/tags/$tagname";
3637         my $tagobj = $lrfetchrefs_f{$lrefname};
3638         next unless defined $tagobj;
3639         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3640         return [ git_rev_parse($tagobj), $what ];
3641     }
3642     fail @tagnames==1 ? <<END : <<END;
3643 Wanted tag $what (@tagnames) on dgit server, but not found
3644 END
3645 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3646 END
3647 }
3648
3649 sub infopair_cond_ff ($$) {
3650     my ($anc,$desc) = @_;
3651     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3652 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3653 END
3654 };
3655
3656 sub pseudomerge_version_check ($$) {
3657     my ($clogp, $archive_hash) = @_;
3658
3659     my $arch_clogp = commit_getclogp $archive_hash;
3660     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3661                      'version currently in archive' ];
3662     if (defined $overwrite_version) {
3663         if (length $overwrite_version) {
3664             infopair_cond_equal([ $overwrite_version,
3665                                   '--overwrite= version' ],
3666                                 $i_arch_v);
3667         } else {
3668             my $v = $i_arch_v->[0];
3669             progress "Checking package changelog for archive version $v ...";
3670             eval {
3671                 my @xa = ("-f$v", "-t$v");
3672                 my $vclogp = parsechangelog @xa;
3673                 my $cv = [ (getfield $vclogp, 'Version'),
3674                            "Version field from dpkg-parsechangelog @xa" ];
3675                 infopair_cond_equal($i_arch_v, $cv);
3676             };
3677             if ($@) {
3678                 $@ =~ s/^dgit: //gm;
3679                 fail "$@".
3680                     "Perhaps debian/changelog does not mention $v ?";
3681             }
3682         }
3683     }
3684     
3685     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3686     return $i_arch_v;
3687 }
3688
3689 sub pseudomerge_make_commit ($$$$ $$) {
3690     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3691         $msg_cmd, $msg_msg) = @_;
3692     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3693
3694     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3695     my $authline = clogp_authline $clogp;
3696
3697     chomp $msg_msg;
3698     $msg_cmd .=
3699         !defined $overwrite_version ? ""
3700         : !length  $overwrite_version ? " --overwrite"
3701         : " --overwrite=".$overwrite_version;
3702
3703     mkpath '.git/dgit';
3704     my $pmf = ".git/dgit/pseudomerge";
3705     open MC, ">", $pmf or die "$pmf $!";
3706     print MC <<END or die $!;
3707 tree $tree
3708 parent $dgitview
3709 parent $archive_hash
3710 author $authline
3711 committer $authline
3712
3713 $msg_msg
3714
3715 [$msg_cmd]
3716 END
3717     close MC or die $!;
3718
3719     return make_commit($pmf);
3720 }
3721
3722 sub splitbrain_pseudomerge ($$$$) {
3723     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3724     # => $merged_dgitview
3725     printdebug "splitbrain_pseudomerge...\n";
3726     #
3727     #     We:      debian/PREVIOUS    HEAD($maintview)
3728     # expect:          o ----------------- o
3729     #                    \                   \
3730     #                     o                   o
3731     #                 a/d/PREVIOUS        $dgitview
3732     #                $archive_hash              \
3733     #  If so,                \                   \
3734     #  we do:                 `------------------ o
3735     #   this:                                   $dgitview'
3736     #
3737
3738     return $dgitview unless defined $archive_hash;
3739
3740     printdebug "splitbrain_pseudomerge...\n";
3741
3742     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3743
3744     if (!defined $overwrite_version) {
3745         progress "Checking that HEAD inciudes all changes in archive...";
3746     }
3747
3748     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3749
3750     if (defined $overwrite_version) {
3751     } elsif (!eval {
3752         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3753         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3754         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3755         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3756         my $i_archive = [ $archive_hash, "current archive contents" ];
3757
3758         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3759
3760         infopair_cond_equal($i_dgit, $i_archive);
3761         infopair_cond_ff($i_dep14, $i_dgit);
3762         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3763         1;
3764     }) {
3765         print STDERR <<END;
3766 $us: check failed (maybe --overwrite is needed, consult documentation)
3767 END
3768         die "$@";
3769     }
3770
3771     my $r = pseudomerge_make_commit
3772         $clogp, $dgitview, $archive_hash, $i_arch_v,
3773         "dgit --quilt=$quilt_mode",
3774         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3775 Declare fast forward from $i_arch_v->[0]
3776 END_OVERWR
3777 Make fast forward from $i_arch_v->[0]
3778 END_MAKEFF
3779
3780     maybe_split_brain_save $maintview, $r, "pseudomerge";
3781
3782     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3783     return $r;
3784 }       
3785
3786 sub plain_overwrite_pseudomerge ($$$) {
3787     my ($clogp, $head, $archive_hash) = @_;
3788
3789     printdebug "plain_overwrite_pseudomerge...";
3790
3791     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3792
3793     return $head if is_fast_fwd $archive_hash, $head;
3794
3795     my $m = "Declare fast forward from $i_arch_v->[0]";
3796
3797     my $r = pseudomerge_make_commit
3798         $clogp, $head, $archive_hash, $i_arch_v,
3799         "dgit", $m;
3800
3801     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3802
3803     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3804     return $r;
3805 }
3806
3807 sub push_parse_changelog ($) {
3808     my ($clogpfn) = @_;
3809
3810     my $clogp = Dpkg::Control::Hash->new();
3811     $clogp->load($clogpfn) or die;
3812
3813     my $clogpackage = getfield $clogp, 'Source';
3814     $package //= $clogpackage;
3815     fail "-p specified $package but changelog specified $clogpackage"
3816         unless $package eq $clogpackage;
3817     my $cversion = getfield $clogp, 'Version';
3818     my $tag = debiantag($cversion, access_nomdistro);
3819     runcmd @git, qw(check-ref-format), $tag;
3820
3821     my $dscfn = dscfn($cversion);
3822
3823     return ($clogp, $cversion, $dscfn);
3824 }
3825
3826 sub push_parse_dsc ($$$) {
3827     my ($dscfn,$dscfnwhat, $cversion) = @_;
3828     $dsc = parsecontrol($dscfn,$dscfnwhat);
3829     my $dversion = getfield $dsc, 'Version';
3830     my $dscpackage = getfield $dsc, 'Source';
3831     ($dscpackage eq $package && $dversion eq $cversion) or
3832         fail "$dscfn is for $dscpackage $dversion".
3833             " but debian/changelog is for $package $cversion";
3834 }
3835
3836 sub push_tagwants ($$$$) {
3837     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3838     my @tagwants;
3839     push @tagwants, {
3840         TagFn => \&debiantag,
3841         Objid => $dgithead,
3842         TfSuffix => '',
3843         View => 'dgit',
3844     };
3845     if (defined $maintviewhead) {
3846         push @tagwants, {
3847             TagFn => \&debiantag_maintview,
3848             Objid => $maintviewhead,
3849             TfSuffix => '-maintview',
3850             View => 'maint',
3851         };
3852     } elsif ($dodep14tag eq 'no' ? 0
3853              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3854              : $dodep14tag eq 'always'
3855              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3856 --dep14tag-always (or equivalent in config) means server must support
3857  both "new" and "maint" tag formats, but config says it doesn't.
3858 END
3859             : die "$dodep14tag ?") {
3860         push @tagwants, {
3861             TagFn => \&debiantag_maintview,
3862             Objid => $dgithead,
3863             TfSuffix => '-dgit',
3864             View => 'dgit',
3865         };
3866     };
3867     foreach my $tw (@tagwants) {
3868         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3869         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3870     }
3871     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3872     return @tagwants;
3873 }
3874
3875 sub push_mktags ($$ $$ $) {
3876     my ($clogp,$dscfn,
3877         $changesfile,$changesfilewhat,
3878         $tagwants) = @_;
3879
3880     die unless $tagwants->[0]{View} eq 'dgit';
3881
3882     my $declaredistro = access_nomdistro();
3883     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3884     $dsc->{$ourdscfield[0]} = join " ",
3885         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3886         $reader_giturl;
3887     $dsc->save("$dscfn.tmp") or die $!;
3888
3889     my $changes = parsecontrol($changesfile,$changesfilewhat);
3890     foreach my $field (qw(Source Distribution Version)) {
3891         $changes->{$field} eq $clogp->{$field} or
3892             fail "changes field $field \`$changes->{$field}'".
3893                 " does not match changelog \`$clogp->{$field}'";
3894     }
3895
3896     my $cversion = getfield $clogp, 'Version';
3897     my $clogsuite = getfield $clogp, 'Distribution';
3898
3899     # We make the git tag by hand because (a) that makes it easier
3900     # to control the "tagger" (b) we can do remote signing
3901     my $authline = clogp_authline $clogp;
3902     my $delibs = join(" ", "",@deliberatelies);
3903
3904     my $mktag = sub {
3905         my ($tw) = @_;
3906         my $tfn = $tw->{Tfn};
3907         my $head = $tw->{Objid};
3908         my $tag = $tw->{Tag};
3909
3910         open TO, '>', $tfn->('.tmp') or die $!;
3911         print TO <<END or die $!;
3912 object $head
3913 type commit
3914 tag $tag
3915 tagger $authline
3916
3917 END
3918         if ($tw->{View} eq 'dgit') {
3919             print TO <<END or die $!;
3920 $package release $cversion for $clogsuite ($csuite) [dgit]
3921 [dgit distro=$declaredistro$delibs]
3922 END
3923             foreach my $ref (sort keys %previously) {
3924                 print TO <<END or die $!;
3925 [dgit previously:$ref=$previously{$ref}]
3926 END
3927             }
3928         } elsif ($tw->{View} eq 'maint') {
3929             print TO <<END or die $!;
3930 $package release $cversion for $clogsuite ($csuite)
3931 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3932 END
3933         } else {
3934             die Dumper($tw)."?";
3935         }
3936
3937         close TO or die $!;
3938
3939         my $tagobjfn = $tfn->('.tmp');
3940         if ($sign) {
3941             if (!defined $keyid) {
3942                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3943             }
3944             if (!defined $keyid) {
3945                 $keyid = getfield $clogp, 'Maintainer';
3946             }
3947             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3948             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3949             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3950             push @sign_cmd, $tfn->('.tmp');
3951             runcmd_ordryrun @sign_cmd;
3952             if (act_scary()) {
3953                 $tagobjfn = $tfn->('.signed.tmp');
3954                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3955                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3956             }
3957         }
3958         return $tagobjfn;
3959     };
3960
3961     my @r = map { $mktag->($_); } @$tagwants;
3962     return @r;
3963 }
3964
3965 sub sign_changes ($) {
3966     my ($changesfile) = @_;
3967     if ($sign) {
3968         my @debsign_cmd = @debsign;
3969         push @debsign_cmd, "-k$keyid" if defined $keyid;
3970         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3971         push @debsign_cmd, $changesfile;
3972         runcmd_ordryrun @debsign_cmd;
3973     }
3974 }
3975
3976 sub dopush () {
3977     printdebug "actually entering push\n";
3978
3979     supplementary_message(<<'END');
3980 Push failed, while checking state of the archive.
3981 You can retry the push, after fixing the problem, if you like.
3982 END
3983     if (check_for_git()) {
3984         git_fetch_us();
3985     }
3986     my $archive_hash = fetch_from_archive();
3987     if (!$archive_hash) {
3988         $new_package or
3989             fail "package appears to be new in this suite;".
3990                 " if this is intentional, use --new";
3991     }
3992
3993     supplementary_message(<<'END');
3994 Push failed, while preparing your push.
3995 You can retry the push, after fixing the problem, if you like.
3996 END
3997
3998     need_tagformat 'new', "quilt mode $quilt_mode"
3999         if quiltmode_splitbrain;
4000
4001     prep_ud();
4002
4003     access_giturl(); # check that success is vaguely likely
4004     select_tagformat();
4005
4006     my $clogpfn = ".git/dgit/changelog.822.tmp";
4007     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4008
4009     responder_send_file('parsed-changelog', $clogpfn);
4010
4011     my ($clogp, $cversion, $dscfn) =
4012         push_parse_changelog("$clogpfn");
4013
4014     my $dscpath = "$buildproductsdir/$dscfn";
4015     stat_exists $dscpath or
4016         fail "looked for .dsc $dscpath, but $!;".
4017             " maybe you forgot to build";
4018
4019     responder_send_file('dsc', $dscpath);
4020
4021     push_parse_dsc($dscpath, $dscfn, $cversion);
4022
4023     my $format = getfield $dsc, 'Format';
4024     printdebug "format $format\n";
4025
4026     my $actualhead = git_rev_parse('HEAD');
4027     my $dgithead = $actualhead;
4028     my $maintviewhead = undef;
4029
4030     my $upstreamversion = upstreamversion $clogp->{Version};
4031
4032     if (madformat_wantfixup($format)) {
4033         # user might have not used dgit build, so maybe do this now:
4034         if (quiltmode_splitbrain()) {
4035             changedir $ud;
4036             quilt_make_fake_dsc($upstreamversion);
4037             my $cachekey;
4038             ($dgithead, $cachekey) =
4039                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4040             $dgithead or fail
4041  "--quilt=$quilt_mode but no cached dgit view:
4042  perhaps tree changed since dgit build[-source] ?";
4043             $split_brain = 1;
4044             $dgithead = splitbrain_pseudomerge($clogp,
4045                                                $actualhead, $dgithead,
4046                                                $archive_hash);
4047             $maintviewhead = $actualhead;
4048             changedir '../../../..';
4049             prep_ud(); # so _only_subdir() works, below
4050         } else {
4051             commit_quilty_patch();
4052         }
4053     }
4054
4055     if (defined $overwrite_version && !defined $maintviewhead) {
4056         $dgithead = plain_overwrite_pseudomerge($clogp,
4057                                                 $dgithead,
4058                                                 $archive_hash);
4059     }
4060
4061     check_not_dirty();
4062
4063     my $forceflag = '';
4064     if ($archive_hash) {
4065         if (is_fast_fwd($archive_hash, $dgithead)) {
4066             # ok
4067         } elsif (deliberately_not_fast_forward) {
4068             $forceflag = '+';
4069         } else {
4070             fail "dgit push: HEAD is not a descendant".
4071                 " of the archive's version.\n".
4072                 "To overwrite the archive's contents,".
4073                 " pass --overwrite[=VERSION].\n".
4074                 "To rewind history, if permitted by the archive,".
4075                 " use --deliberately-not-fast-forward.";
4076         }
4077     }
4078
4079     changedir $ud;
4080     progress "checking that $dscfn corresponds to HEAD";
4081     runcmd qw(dpkg-source -x --),
4082         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4083     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4084     check_for_vendor_patches() if madformat($dsc->{format});
4085     changedir '../../../..';
4086     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4087     debugcmd "+",@diffcmd;
4088     $!=0; $?=-1;
4089     my $r = system @diffcmd;
4090     if ($r) {
4091         if ($r==256) {
4092             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4093             fail <<END
4094 HEAD specifies a different tree to $dscfn:
4095 $diffs
4096 Perhaps you forgot to build.  Or perhaps there is a problem with your
4097  source tree (see dgit(7) for some hints).  To see a full diff, run
4098    git diff $tree HEAD
4099 END
4100         } else {
4101             failedcmd @diffcmd;
4102         }
4103     }
4104     if (!$changesfile) {
4105         my $pat = changespat $cversion;
4106         my @cs = glob "$buildproductsdir/$pat";
4107         fail "failed to find unique changes file".
4108             " (looked for $pat in $buildproductsdir);".
4109             " perhaps you need to use dgit -C"
4110             unless @cs==1;
4111         ($changesfile) = @cs;
4112     } else {
4113         $changesfile = "$buildproductsdir/$changesfile";
4114     }
4115
4116     # Check that changes and .dsc agree enough
4117     $changesfile =~ m{[^/]*$};
4118     my $changes = parsecontrol($changesfile,$&);
4119     files_compare_inputs($dsc, $changes)
4120         unless forceing [qw(dsc-changes-mismatch)];
4121
4122     # Perhaps adjust .dsc to contain right set of origs
4123     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4124                                   $changesfile)
4125         unless forceing [qw(changes-origs-exactly)];
4126
4127     # Checks complete, we're going to try and go ahead:
4128
4129     responder_send_file('changes',$changesfile);
4130     responder_send_command("param head $dgithead");
4131     responder_send_command("param csuite $csuite");
4132     responder_send_command("param tagformat $tagformat");
4133     if (defined $maintviewhead) {
4134         die unless ($protovsn//4) >= 4;
4135         responder_send_command("param maint-view $maintviewhead");
4136     }
4137
4138     if (deliberately_not_fast_forward) {
4139         git_for_each_ref(lrfetchrefs, sub {
4140             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4141             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4142             responder_send_command("previously $rrefname=$objid");
4143             $previously{$rrefname} = $objid;
4144         });
4145     }
4146
4147     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4148                                  ".git/dgit/tag");
4149     my @tagobjfns;
4150
4151     supplementary_message(<<'END');
4152 Push failed, while signing the tag.
4153 You can retry the push, after fixing the problem, if you like.
4154 END
4155     # If we manage to sign but fail to record it anywhere, it's fine.
4156     if ($we_are_responder) {
4157         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4158         responder_receive_files('signed-tag', @tagobjfns);
4159     } else {
4160         @tagobjfns = push_mktags($clogp,$dscpath,
4161                               $changesfile,$changesfile,
4162                               \@tagwants);
4163     }
4164     supplementary_message(<<'END');
4165 Push failed, *after* signing the tag.
4166 If you want to try again, you should use a new version number.
4167 END
4168
4169     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4170
4171     foreach my $tw (@tagwants) {
4172         my $tag = $tw->{Tag};
4173         my $tagobjfn = $tw->{TagObjFn};
4174         my $tag_obj_hash =
4175             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4176         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4177         runcmd_ordryrun_local
4178             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4179     }
4180
4181     supplementary_message(<<'END');
4182 Push failed, while updating the remote git repository - see messages above.
4183 If you want to try again, you should use a new version number.
4184 END
4185     if (!check_for_git()) {
4186         create_remote_git_repo();
4187     }
4188
4189     my @pushrefs = $forceflag.$dgithead.":".rrref();
4190     foreach my $tw (@tagwants) {
4191         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4192     }
4193
4194     runcmd_ordryrun @git,
4195         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4196     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4197
4198     supplementary_message(<<'END');
4199 Push failed, while obtaining signatures on the .changes and .dsc.
4200 If it was just that the signature failed, you may try again by using
4201 debsign by hand to sign the changes
4202    $changesfile
4203 and then dput to complete the upload.
4204 If you need to change the package, you must use a new version number.
4205 END
4206     if ($we_are_responder) {
4207         my $dryrunsuffix = act_local() ? "" : ".tmp";
4208         responder_receive_files('signed-dsc-changes',
4209                                 "$dscpath$dryrunsuffix",
4210                                 "$changesfile$dryrunsuffix");
4211     } else {
4212         if (act_local()) {
4213             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4214         } else {
4215             progress "[new .dsc left in $dscpath.tmp]";
4216         }
4217         sign_changes $changesfile;
4218     }
4219
4220     supplementary_message(<<END);
4221 Push failed, while uploading package(s) to the archive server.
4222 You can retry the upload of exactly these same files with dput of:
4223   $changesfile
4224 If that .changes file is broken, you will need to use a new version
4225 number for your next attempt at the upload.
4226 END
4227     my $host = access_cfg('upload-host','RETURN-UNDEF');
4228     my @hostarg = defined($host) ? ($host,) : ();
4229     runcmd_ordryrun @dput, @hostarg, $changesfile;
4230     printdone "pushed and uploaded $cversion";
4231
4232     supplementary_message('');
4233     responder_send_command("complete");
4234 }
4235
4236 sub cmd_clone {
4237     parseopts();
4238     my $dstdir;
4239     badusage "-p is not allowed with clone; specify as argument instead"
4240         if defined $package;
4241     if (@ARGV==1) {
4242         ($package) = @ARGV;
4243     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4244         ($package,$isuite) = @ARGV;
4245     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4246         ($package,$dstdir) = @ARGV;
4247     } elsif (@ARGV==3) {
4248         ($package,$isuite,$dstdir) = @ARGV;
4249     } else {
4250         badusage "incorrect arguments to dgit clone";
4251     }
4252     notpushing();
4253
4254     $dstdir ||= "$package";
4255     if (stat_exists $dstdir) {
4256         fail "$dstdir already exists";
4257     }
4258
4259     my $cwd_remove;
4260     if ($rmonerror && !$dryrun_level) {
4261         $cwd_remove= getcwd();
4262         unshift @end, sub { 
4263             return unless defined $cwd_remove;
4264             if (!chdir "$cwd_remove") {
4265                 return if $!==&ENOENT;
4266                 die "chdir $cwd_remove: $!";
4267             }
4268             printdebug "clone rmonerror removing $dstdir\n";
4269             if (stat $dstdir) {
4270                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4271             } elsif (grep { $! == $_ }
4272                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4273             } else {
4274                 print STDERR "check whether to remove $dstdir: $!\n";
4275             }
4276         };
4277     }
4278
4279     clone($dstdir);
4280     $cwd_remove = undef;
4281 }
4282
4283 sub branchsuite () {
4284     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4285     if ($branch =~ m#$lbranch_re#o) {
4286         return $1;
4287     } else {
4288         return undef;
4289     }
4290 }
4291
4292 sub fetchpullargs () {
4293     if (!defined $package) {
4294         my $sourcep = parsecontrol('debian/control','debian/control');
4295         $package = getfield $sourcep, 'Source';
4296     }
4297     if (@ARGV==0) {
4298         $isuite = branchsuite();
4299         if (!$isuite) {
4300             my $clogp = parsechangelog();
4301             $isuite = getfield $clogp, 'Distribution';
4302         }
4303     } elsif (@ARGV==1) {
4304         ($isuite) = @ARGV;
4305     } else {
4306         badusage "incorrect arguments to dgit fetch or dgit pull";
4307     }
4308     notpushing();
4309 }
4310
4311 sub cmd_fetch {
4312     parseopts();
4313     fetchpullargs();
4314     my $multi_fetched = fork_for_multisuite(sub { });
4315     exit 0 if $multi_fetched;
4316     fetch();
4317 }
4318
4319 sub cmd_pull {
4320     parseopts();
4321     fetchpullargs();
4322     if (quiltmode_splitbrain()) {
4323         my ($format, $fopts) = get_source_format();
4324         madformat($format) and fail <<END
4325 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4326 END
4327     }
4328     pull();
4329 }
4330
4331 sub cmd_push {
4332     parseopts();
4333     pushing();
4334     badusage "-p is not allowed with dgit push" if defined $package;
4335     check_not_dirty();
4336     my $clogp = parsechangelog();
4337     $package = getfield $clogp, 'Source';
4338     my $specsuite;
4339     if (@ARGV==0) {
4340     } elsif (@ARGV==1) {
4341         ($specsuite) = (@ARGV);
4342     } else {
4343         badusage "incorrect arguments to dgit push";
4344     }
4345     $isuite = getfield $clogp, 'Distribution';
4346     if ($new_package) {
4347         local ($package) = $existing_package; # this is a hack
4348         canonicalise_suite();
4349     } else {
4350         canonicalise_suite();
4351     }
4352     if (defined $specsuite &&
4353         $specsuite ne $isuite &&
4354         $specsuite ne $csuite) {
4355             fail "dgit push: changelog specifies $isuite ($csuite)".
4356                 " but command line specifies $specsuite";
4357     }
4358     dopush();
4359 }
4360
4361 #---------- remote commands' implementation ----------
4362
4363 sub cmd_remote_push_build_host {
4364     my ($nrargs) = shift @ARGV;
4365     my (@rargs) = @ARGV[0..$nrargs-1];
4366     @ARGV = @ARGV[$nrargs..$#ARGV];
4367     die unless @rargs;
4368     my ($dir,$vsnwant) = @rargs;
4369     # vsnwant is a comma-separated list; we report which we have
4370     # chosen in our ready response (so other end can tell if they
4371     # offered several)
4372     $debugprefix = ' ';
4373     $we_are_responder = 1;
4374     $us .= " (build host)";
4375
4376     pushing();
4377
4378     open PI, "<&STDIN" or die $!;
4379     open STDIN, "/dev/null" or die $!;
4380     open PO, ">&STDOUT" or die $!;
4381     autoflush PO 1;
4382     open STDOUT, ">&STDERR" or die $!;
4383     autoflush STDOUT 1;
4384
4385     $vsnwant //= 1;
4386     ($protovsn) = grep {
4387         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4388     } @rpushprotovsn_support;
4389
4390     fail "build host has dgit rpush protocol versions ".