dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2018 Ian Jackson
   6 # Copyright (C)2017-2018 Sean Whitton
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23 use Debian::Dgit::I18n;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use IO::Handle;
  31 use Data::Dumper;
  32 use LWP::UserAgent;
  33 use Dpkg::Control::Hash;
  34 use File::Path;
  35 use File::Temp qw(tempdir);
  36 use File::Basename;
  37 use Dpkg::Version;
  38 use Dpkg::Compression;
  39 use Dpkg::Compression::Process;
  40 use POSIX;
  41 use Locale::gettext;
  42 use IPC::Open2;
  43 use Digest::SHA;
  44 use Digest::MD5;
  45 use List::MoreUtils qw(pairwise);
  46 use Text::Glob qw(match_glob);
  47 use Fcntl qw(:DEFAULT :flock);
  48 use Carp;
  49
  50 use Debian::Dgit;
  51
  52 our $our_version = 'UNRELEASED'; ###substituted###
  53 our $absurdity = undef; ###substituted###
  54
  55 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  56 our $protovsn;
  57
  58 our $cmd;
  59 our $subcommand;
  60 our $isuite;
  61 our $idistro;
  62 our $package;
  63 our @ropts;
  64
  65 our $sign = 1;
  66 our $dryrun_level = 0;
  67 our $changesfile;
  68 our $buildproductsdir;
  69 our $bpd_glob;
  70 our $new_package = 0;
  71 our $includedirty = 0;
  72 our $rmonerror = 1;
  73 our @deliberatelies;
  74 our %previously;
  75 our $existing_package = 'dpkg';
  76 our $cleanmode;
  77 our $changes_since_version;
  78 our $rmchanges;
  79 our $overwrite_version; # undef: not specified; '': check changelog
  80 our $quilt_mode;
  81 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  82 our $dodep14tag;
  83 our %internal_object_save;
  84 our $we_are_responder;
  85 our $we_are_initiator;
  86 our $initiator_tempdir;
  87 our $patches_applied_dirtily = 00;
  88 our $tagformat_want;
  89 our $tagformat;
  90 our $tagformatfn;
  91 our $chase_dsc_distro=1;
  92
  93 our %forceopts = map { $_=>0 }
  94     qw(unrepresentable unsupported-source-format
  95        dsc-changes-mismatch changes-origs-exactly
  96        uploading-binaries uploading-source-only
  97        import-gitapply-absurd
  98        import-gitapply-no-absurd
  99        import-dsc-with-dgit-field);
 100
 101 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
 102
 103 our $suite_re = '[-+.0-9a-z]+';
 104 our $cleanmode_re = qr{(?: dpkg-source (?: -d )? (?: ,no-check | ,all-check )?
 105                          | git | git-ff
 106                          | check (?: ,ignores )?
 107                          | none
 108                          )}x;
 109
 110 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 111 our $splitbraincache = 'dgit-intern/quilt-cache';
 112 our $rewritemap = 'dgit-rewrite/map';
 113
 114 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
 115
 116 our (@git) = qw(git);
 117 our (@dget) = qw(dget);
 118 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 119 our (@dput) = qw(dput);
 120 our (@debsign) = qw(debsign);
 121 our (@gpg) = qw(gpg);
 122 our (@sbuild) = (qw(sbuild --no-source));
 123 our (@ssh) = 'ssh';
 124 our (@dgit) = qw(dgit);
 125 our (@git_debrebase) = qw(git-debrebase);
 126 our (@aptget) = qw(apt-get);
 127 our (@aptcache) = qw(apt-cache);
 128 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
 129 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
 130 our (@dpkggenchanges) = qw(dpkg-genchanges);
 131 our (@mergechanges) = qw(mergechanges -f);
 132 our (@gbp_build) = ('');
 133 our (@gbp_pq) = ('gbp pq');
 134 our (@changesopts) = ('');
 135 our (@pbuilder) = ("sudo -E pbuilder");
 136 our (@cowbuilder) = ("sudo -E cowbuilder");
 137
 138 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 139                      'curl' => \@curl,
 140                      'dput' => \@dput,
 141                      'debsign' => \@debsign,
 142                      'gpg' => \@gpg,
 143                      'sbuild' => \@sbuild,
 144                      'ssh' => \@ssh,
 145                      'dgit' => \@dgit,
 146                      'git' => \@git,
 147                      'git-debrebase' => \@git_debrebase,
 148                      'apt-get' => \@aptget,
 149                      'apt-cache' => \@aptcache,
 150                      'dpkg-source' => \@dpkgsource,
 151                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 152                      'dpkg-genchanges' => \@dpkggenchanges,
 153                      'gbp-build' => \@gbp_build,
 154                      'gbp-pq' => \@gbp_pq,
 155                      'ch' => \@changesopts,
 156                      'mergechanges' => \@mergechanges,
 157                      'pbuilder' => \@pbuilder,
 158                      'cowbuilder' => \@cowbuilder);
 159
 160 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 161 our %opts_cfg_insertpos = map {
 162     $_,
 163     scalar @{ $opts_opt_map{$_} }
 164 } keys %opts_opt_map;
 165
 166 sub parseopts_late_defaults();
 167 sub setup_gitattrs(;$);
 168 sub check_gitattrs($$);
 169
 170 our $playground;
 171 our $keyid;
 172
 173 autoflush STDOUT 1;
 174
 175 our $supplementary_message = '';
 176 our $split_brain = 0;
 177
 178 END {
 179     local ($@, $?);
 180     return unless forkcheck_mainprocess();
 181     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 182 }
 183
 184 our $remotename = 'dgit';
 185 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 186 our $csuite;
 187 our $instead_distro;
 188
 189 if (!defined $absurdity) {
 190     $absurdity = $0;
 191     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 192 }
 193
 194 sub debiantag ($$) {
 195     my ($v,$distro) = @_;
 196     return $tagformatfn->($v, $distro);
 197 }
 198
 199 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 200
 201 sub lbranch () { return "$branchprefix/$csuite"; }
 202 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 203 sub lref () { return "refs/heads/".lbranch(); }
 204 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 205 sub rrref () { return server_ref($csuite); }
 206
 207 sub srcfn ($$) {
 208     my ($vsn, $sfx) = @_;
 209     return &source_file_leafname($package, $vsn, $sfx);
 210 }
 211 sub is_orig_file_of_vsn ($$) {
 212     my ($f, $upstreamvsn) = @_;
 213     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
 214 }
 215
 216 sub dscfn ($) {
 217     my ($vsn) = @_;
 218     return srcfn($vsn,".dsc");
 219 }
 220
 221 sub changespat ($;$) {
 222     my ($vsn, $arch) = @_;
 223     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 224 }
 225
 226 our $us = 'dgit';
 227 initdebug('');
 228
 229 our @end;
 230 END {
 231     local ($?);
 232     return unless forkcheck_mainprocess();
 233     foreach my $f (@end) {
 234         eval { $f->(); };
 235         print STDERR "$us: cleanup: $@" if length $@;
 236     }
 237 };
 238
 239 sub badcfg {
 240     print STDERR f_ "%s: invalid configuration: %s\n", $us, "@_";
 241     finish 12;
 242 }
 243
 244 sub forceable_fail ($$) {
 245     my ($forceoptsl, $msg) = @_;
 246     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 247     print STDERR +(__ "warning: overriding problem due to --force:\n"). $msg;
 248 }
 249
 250 sub forceing ($) {
 251     my ($forceoptsl) = @_;
 252     my @got = grep { $forceopts{$_} } @$forceoptsl;
 253     return 0 unless @got;
 254     print STDERR f_
 255         "warning: skipping checks or functionality due to --force-%s\n",
 256         $got[0];
 257 }
 258
 259 sub no_such_package () {
 260     print STDERR f_ "%s: package %s does not exist in suite %s\n",
 261         $us, $package, $isuite;
 262     finish 4;
 263 }
 264
 265 sub deliberately ($) {
 266     my ($enquiry) = @_;
 267     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 268 }
 269
 270 sub deliberately_not_fast_forward () {
 271     foreach (qw(not-fast-forward fresh-repo)) {
 272         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 273     }
 274 }
 275
 276 sub quiltmode_splitbrain () {
 277     $quilt_mode =~ m/gbp|dpm|unapplied/;
 278 }
 279
 280 sub opts_opt_multi_cmd {
 281     my $extra = shift;
 282     my @cmd;
 283     push @cmd, split /\s+/, shift @_;
 284     push @cmd, @$extra;
 285     push @cmd, @_;
 286     @cmd;
 287 }
 288
 289 sub gbp_pq {
 290     return opts_opt_multi_cmd [], @gbp_pq;
 291 }
 292
 293 sub dgit_privdir () {
 294     our $dgit_privdir_made //= ensure_a_playground 'dgit';
 295 }
 296
 297 sub bpd_abs () {
 298     my $r = $buildproductsdir;
 299     $r = "$maindir/$r" unless $r =~ m{^/};
 300     return $r;
 301 }
 302
 303 sub get_tree_of_commit ($) {
 304     my ($commitish) = @_;
 305     my $cdata = cmdoutput @git, qw(cat-file commit), $commitish;
 306     $cdata =~ m/\n\n/;  $cdata = $`;
 307     $cdata =~ m/^tree (\w+)$/m or confess "cdata $cdata ?";
 308     return $1;
 309 }
 310
 311 sub branch_gdr_info ($$) {
 312     my ($symref, $head) = @_;
 313     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
 314         gdr_ffq_prev_branchinfo($symref);
 315     return () unless $status eq 'branch';
 316     $ffq_prev = git_get_ref $ffq_prev;
 317     $gdrlast  = git_get_ref $gdrlast;
 318     $gdrlast &&= is_fast_fwd $gdrlast, $head;
 319     return ($ffq_prev, $gdrlast);
 320 }
 321
 322 sub branch_is_gdr_unstitched_ff ($$$) {
 323     my ($symref, $head, $ancestor) = @_;
 324     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 325     return 0 unless $ffq_prev;
 326     return 0 unless !defined $ancestor or is_fast_fwd $ancestor, $ffq_prev;
 327     return 1;
 328 }
 329
 330 sub branch_is_gdr ($) {
 331     my ($head) = @_;
 332     # This is quite like git-debrebase's keycommits.
 333     # We have our own implementation because:
 334     #  - our algorighm can do fewer tests so is faster
 335     #  - it saves testing to see if gdr is installed
 336
 337     # NB we use this jsut for deciding whether to run gdr make-patches
 338     # Before reusing this algorithm for somthing else, its
 339     # suitability should be reconsidered.
 340
 341     my $walk = $head;
 342     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 343     printdebug "branch_is_gdr $head...\n";
 344     my $get_patches = sub {
 345         my $t = git_cat_file "$_[0]:debian/patches", [qw(missing tree)];
 346         return $t // '';
 347     };
 348     my $tip_patches = $get_patches->($head);
 349   WALK:
 350     for (;;) {
 351         my $cdata = git_cat_file $walk, 'commit';
 352         my ($hdrs,$msg) = $cdata =~ m{\n\n} ? ($`,$') : ($cdata,'');
 353         if ($msg =~ m{^\[git-debrebase\ (
 354                           anchor | changelog | make-patches |
 355                           merged-breakwater | pseudomerge
 356                       ) [: ] }mx) {
 357             # no need to analyse this - it's sufficient
 358             # (gdr classifications: Anchor, MergedBreakwaters)
 359             # (made by gdr: Pseudomerge, Changelog)
 360             printdebug "branch_is_gdr  $walk gdr $1 YES\n";
 361             return 1;
 362         }
 363         my @parents = ($hdrs =~ m/^parent (\w+)$/gm);
 364         if (@parents==2) {
 365             my $walk_tree = get_tree_of_commit $walk;
 366             foreach my $p (@parents) {
 367                 my $p_tree = get_tree_of_commit $p;
 368                 if ($p_tree eq $walk_tree) { # pseudomerge contriburor
 369                     # (gdr classification: Pseudomerge; not made by gdr)
 370                     printdebug "branch_is_gdr  $walk unmarked pseudomerge\n"
 371                         if $debuglevel >= 2;
 372                     $walk = $p;
 373                     next WALK;
 374                 }
 375             }
 376             # some other non-gdr merge
 377             # (gdr classification: VanillaMerge, DgitImportUnpatched, ?)
 378             printdebug "branch_is_gdr  $walk ?-2-merge NO\n";
 379             return 0;
 380         }
 381         if (@parents>2) {
 382             # (gdr classification: ?)
 383             printdebug "branch_is_gdr  $walk ?-octopus NO\n";
 384             return 0;
 385         }
 386         if (!@parents) {
 387             printdebug "branch_is_gdr  $walk origin\n";
 388             return 0;
 389         }
 390         if ($get_patches->($walk) ne $tip_patches) {
 391             # Our parent added, removed, or edited patches, and wasn't
 392             # a gdr make-patches commit.  gdr make-patches probably
 393             # won't do that well, then.
 394             # (gdr classification of parent: AddPatches or ?)
 395             printdebug "branch_is_gdr  $walk ?-patches NO\n";
 396             return 0;
 397         }
 398         if ($tip_patches eq '' and
 399             !defined git_cat_file "$walk:debian") {
 400             # (gdr classification of parent: BreakwaterStart
 401             printdebug "branch_is_gdr  $walk unmarked BreakwaterStart YES\n";
 402             return 1;
 403         }
 404         # (gdr classification: Upstream Packaging Mixed Changelog)
 405         printdebug "branch_is_gdr  $walk plain\n"
 406             if $debuglevel >= 2;
 407         $walk = $parents[0];
 408     }
 409 }
 410
 411 #---------- remote protocol support, common ----------
 412
 413 # remote push initiator/responder protocol:
 414 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 415 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 416 #  < dgit-remote-push-ready <actual-proto-vsn>
 417 #
 418 # occasionally:
 419 #
 420 #  > progress NBYTES
 421 #  [NBYTES message]
 422 #
 423 #  > supplementary-message NBYTES          # $protovsn >= 3
 424 #  [NBYTES message]
 425 #
 426 # main sequence:
 427 #
 428 #  > file parsed-changelog
 429 #  [indicates that output of dpkg-parsechangelog follows]
 430 #  > data-block NBYTES
 431 #  > [NBYTES bytes of data (no newline)]
 432 #  [maybe some more blocks]
 433 #  > data-end
 434 #
 435 #  > file dsc
 436 #  [etc]
 437 #
 438 #  > file changes
 439 #  [etc]
 440 #
 441 #  > param head DGIT-VIEW-HEAD
 442 #  > param csuite SUITE
 443 #  > param tagformat old|new
 444 #  > param maint-view MAINT-VIEW-HEAD
 445 #
 446 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 447 #  > file buildinfo                             # for buildinfos to sign
 448 #
 449 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 450 #                                     # goes into tag, for replay prevention
 451 #
 452 #  > want signed-tag
 453 #  [indicates that signed tag is wanted]
 454 #  < data-block NBYTES
 455 #  < [NBYTES bytes of data (no newline)]
 456 #  [maybe some more blocks]
 457 #  < data-end
 458 #  < files-end
 459 #
 460 #  > want signed-dsc-changes
 461 #  < data-block NBYTES    [transfer of signed dsc]
 462 #  [etc]
 463 #  < data-block NBYTES    [transfer of signed changes]
 464 #  [etc]
 465 #  < data-block NBYTES    [transfer of each signed buildinfo
 466 #  [etc]                   same number and order as "file buildinfo"]
 467 #  ...
 468 #  < files-end
 469 #
 470 #  > complete
 471
 472 our $i_child_pid;
 473
 474 sub i_child_report () {
 475     # Sees if our child has died, and reap it if so.  Returns a string
 476     # describing how it died if it failed, or undef otherwise.
 477     return undef unless $i_child_pid;
 478     my $got = waitpid $i_child_pid, WNOHANG;
 479     return undef if $got <= 0;
 480     die unless $got == $i_child_pid;
 481     $i_child_pid = undef;
 482     return undef unless $?;
 483     return f_ "build host child %s", waitstatusmsg();
 484 }
 485
 486 sub badproto ($$) {
 487     my ($fh, $m) = @_;
 488     fail f_ "connection lost: %s", $! if $fh->error;
 489     fail f_ "protocol violation; %s not expected", $m;
 490 }
 491
 492 sub badproto_badread ($$) {
 493     my ($fh, $wh) = @_;
 494     fail f_ "connection lost: %s", $! if $!;
 495     my $report = i_child_report();
 496     fail $report if defined $report;
 497     badproto $fh, f_ "eof (reading %s)", $wh;
 498 }
 499
 500 sub protocol_expect (&$) {
 501     my ($match, $fh) = @_;
 502     local $_;
 503     $_ = <$fh>;
 504     defined && chomp or badproto_badread $fh, __ "protocol message";
 505     if (wantarray) {
 506         my @r = &$match;
 507         return @r if @r;
 508     } else {
 509         my $r = &$match;
 510         return $r if $r;
 511     }
 512     badproto $fh, f_ "\`%s'", $_;
 513 }
 514
 515 sub protocol_send_file ($$) {
 516     my ($fh, $ourfn) = @_;
 517     open PF, "<", $ourfn or die "$ourfn: $!";
 518     for (;;) {
 519         my $d;
 520         my $got = read PF, $d, 65536;
 521         die "$ourfn: $!" unless defined $got;
 522         last if !$got;
 523         print $fh "data-block ".length($d)."\n" or confess $!;
 524         print $fh $d or confess $!;
 525     }
 526     PF->error and die "$ourfn $!";
 527     print $fh "data-end\n" or confess $!;
 528     close PF;
 529 }
 530
 531 sub protocol_read_bytes ($$) {
 532     my ($fh, $nbytes) = @_;
 533     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, __ "bad byte count";
 534     my $d;
 535     my $got = read $fh, $d, $nbytes;
 536     $got==$nbytes or badproto_badread $fh, __ "data block";
 537     return $d;
 538 }
 539
 540 sub protocol_receive_file ($$) {
 541     my ($fh, $ourfn) = @_;
 542     printdebug "() $ourfn\n";
 543     open PF, ">", $ourfn or die "$ourfn: $!";
 544     for (;;) {
 545         my ($y,$l) = protocol_expect {
 546             m/^data-block (.*)$/ ? (1,$1) :
 547             m/^data-end$/ ? (0,) :
 548             ();
 549         } $fh;
 550         last unless $y;
 551         my $d = protocol_read_bytes $fh, $l;
 552         print PF $d or confess $!;
 553     }
 554     close PF or confess $!;
 555 }
 556
 557 #---------- remote protocol support, responder ----------
 558
 559 sub responder_send_command ($) {
 560     my ($command) = @_;
 561     return unless $we_are_responder;
 562     # called even without $we_are_responder
 563     printdebug ">> $command\n";
 564     print PO $command, "\n" or confess $!;
 565 }
 566
 567 sub responder_send_file ($$) {
 568     my ($keyword, $ourfn) = @_;
 569     return unless $we_are_responder;
 570     printdebug "]] $keyword $ourfn\n";
 571     responder_send_command "file $keyword";
 572     protocol_send_file \*PO, $ourfn;
 573 }
 574
 575 sub responder_receive_files ($@) {
 576     my ($keyword, @ourfns) = @_;
 577     die unless $we_are_responder;
 578     printdebug "[[ $keyword @ourfns\n";
 579     responder_send_command "want $keyword";
 580     foreach my $fn (@ourfns) {
 581         protocol_receive_file \*PI, $fn;
 582     }
 583     printdebug "[[\$\n";
 584     protocol_expect { m/^files-end$/ } \*PI;
 585 }
 586
 587 #---------- remote protocol support, initiator ----------
 588
 589 sub initiator_expect (&) {
 590     my ($match) = @_;
 591     protocol_expect { &$match } \*RO;
 592 }
 593
 594 #---------- end remote code ----------
 595
 596 sub progress {
 597     if ($we_are_responder) {
 598         my $m = join '', @_;
 599         responder_send_command "progress ".length($m) or confess $!;
 600         print PO $m or confess $!;
 601     } else {
 602         print @_, "\n";
 603     }
 604 }
 605
 606 our $ua;
 607
 608 sub url_get {
 609     if (!$ua) {
 610         $ua = LWP::UserAgent->new();
 611         $ua->env_proxy;
 612     }
 613     my $what = $_[$#_];
 614     progress "downloading $what...";
 615     my $r = $ua->get(@_) or confess $!;
 616     return undef if $r->code == 404;
 617     $r->is_success or fail f_ "failed to fetch %s: %s",
 618         $what, $r->status_line;
 619     return $r->decoded_content(charset => 'none');
 620 }
 621
 622 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 623
 624 sub act_local () { return $dryrun_level <= 1; }
 625 sub act_scary () { return !$dryrun_level; }
 626
 627 sub printdone {
 628     if (!$dryrun_level) {
 629         progress f_ "%s ok: %s", $us, "@_";
 630     } else {
 631         progress f_ "would be ok: %s (but dry run only)", "@_";
 632     }
 633 }
 634
 635 sub dryrun_report {
 636     printcmd(\*STDERR,$debugprefix."#",@_);
 637 }
 638
 639 sub runcmd_ordryrun {
 640     if (act_scary()) {
 641         runcmd @_;
 642     } else {
 643         dryrun_report @_;
 644     }
 645 }
 646
 647 sub runcmd_ordryrun_local {
 648     if (act_local()) {
 649         runcmd @_;
 650     } else {
 651         dryrun_report @_;
 652     }
 653 }
 654
 655 our $helpmsg = i_ <<END;
 656 main usages:
 657   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 658   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 659   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 660   dgit [dgit-opts] sbuild [sbuild-opts]
 661   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
 662   dgit [dgit-opts] push [dgit-opts] [suite]
 663   dgit [dgit-opts] push-source [dgit-opts] [suite]
 664   dgit [dgit-opts] rpush build-host:build-dir ...
 665 important dgit options:
 666   -k<keyid>           sign tag and package with <keyid> instead of default
 667   --dry-run -n        do not change anything, but go through the motions
 668   --damp-run -L       like --dry-run but make local changes, without signing
 669   --new -N            allow introducing a new package
 670   --debug -D          increase debug level
 671   -c<name>=<value>    set git config option (used directly by dgit too)
 672 END
 673
 674 our $later_warning_msg = i_ <<END;
 675 Perhaps the upload is stuck in incoming.  Using the version from git.
 676 END
 677
 678 sub badusage {
 679     print STDERR f_ "%s: %s\n%s", $us, "@_", __ $helpmsg or confess $!;
 680     finish 8;
 681 }
 682
 683 sub nextarg {
 684     @ARGV or badusage __ "too few arguments";
 685     return scalar shift @ARGV;
 686 }
 687
 688 sub pre_help () {
 689     not_necessarily_a_tree();
 690 }
 691 sub cmd_help () {
 692     print __ $helpmsg or confess $!;
 693     finish 0;
 694 }
 695
 696 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 697
 698 our %defcfg = ('dgit.default.distro' => 'debian',
 699                'dgit.default.default-suite' => 'unstable',
 700                'dgit.default.old-dsc-distro' => 'debian',
 701                'dgit-suite.*-security.distro' => 'debian-security',
 702                'dgit.default.username' => '',
 703                'dgit.default.archive-query-default-component' => 'main',
 704                'dgit.default.ssh' => 'ssh',
 705                'dgit.default.archive-query' => 'madison:',
 706                'dgit.default.sshpsql-dbname' => 'service=projectb',
 707                'dgit.default.aptget-components' => 'main',
 708                'dgit.default.dgit-tag-format' => 'new,old,maint',
 709                'dgit.default.source-only-uploads' => 'ok',
 710                'dgit.dsc-url-proto-ok.http'    => 'true',
 711                'dgit.dsc-url-proto-ok.https'   => 'true',
 712                'dgit.dsc-url-proto-ok.git'     => 'true',
 713                'dgit.vcs-git.suites',          => 'sid', # ;-separated
 714                'dgit.default.dsc-url-proto-ok' => 'false',
 715                # old means "repo server accepts pushes with old dgit tags"
 716                # new means "repo server accepts pushes with new dgit tags"
 717                # maint means "repo server accepts split brain pushes"
 718                # hist means "repo server may have old pushes without new tag"
 719                #   ("hist" is implied by "old")
 720                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 721                'dgit-distro.debian.git-check' => 'url',
 722                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 723                'dgit-distro.debian.new-private-pushers' => 't',
 724                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
 725                'dgit-distro.debian/push.git-url' => '',
 726                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 727                'dgit-distro.debian/push.git-user-force' => 'dgit',
 728                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 729                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 730                'dgit-distro.debian/push.git-create' => 'true',
 731                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 732  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 733 # 'dgit-distro.debian.archive-query-tls-key',
 734 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 735 # ^ this does not work because curl is broken nowadays
 736 # Fixing #790093 properly will involve providing providing the key
 737 # in some pacagke and maybe updating these paths.
 738 #
 739 # 'dgit-distro.debian.archive-query-tls-curl-args',
 740 #   '--ca-path=/etc/ssl/ca-debian',
 741 # ^ this is a workaround but works (only) on DSA-administered machines
 742                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 743                'dgit-distro.debian.git-url-suffix' => '',
 744                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 745                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 746  'dgit-distro.debian-security.archive-query' => 'aptget:',
 747  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 748  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 749  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 750  'dgit-distro.debian-security.nominal-distro' => 'debian',
 751  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 752  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 753                'dgit-distro.ubuntu.git-check' => 'false',
 754  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 755                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 756                'dgit-distro.test-dummy.username' => "alice",
 757                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 758                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 759                'dgit-distro.test-dummy.git-url' => "$td/git",
 760                'dgit-distro.test-dummy.git-host' => "git",
 761                'dgit-distro.test-dummy.git-path' => "$td/git",
 762                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 763                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 764                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 765                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 766                );
 767
 768 our %gitcfgs;
 769 our @gitcfgsources = qw(cmdline local global system);
 770 our $invoked_in_git_tree = 1;
 771
 772 sub git_slurp_config () {
 773     # This algoritm is a bit subtle, but this is needed so that for
 774     # options which we want to be single-valued, we allow the
 775     # different config sources to override properly.  See #835858.
 776     foreach my $src (@gitcfgsources) {
 777         next if $src eq 'cmdline';
 778         # we do this ourselves since git doesn't handle it
 779
 780         $gitcfgs{$src} = git_slurp_config_src $src;
 781     }
 782 }
 783
 784 sub git_get_config ($) {
 785     my ($c) = @_;
 786     foreach my $src (@gitcfgsources) {
 787         my $l = $gitcfgs{$src}{$c};
 788         confess "internal error ($l $c)" if $l && !ref $l;
 789         printdebug"C $c ".(defined $l ?
 790                            join " ", map { messagequote "'$_'" } @$l :
 791                            "undef")."\n"
 792             if $debuglevel >= 4;
 793         $l or next;
 794         @$l==1 or badcfg
 795             f_ "multiple values for %s (in %s git config)", $c, $src
 796             if @$l > 1;
 797         $l->[0] =~ m/\n/ and badcfg f_
 798  "value for config option %s (in %s git config) contains newline(s)!",
 799             $c, $src;
 800         return $l->[0];
 801     }
 802     return undef;
 803 }
 804
 805 sub cfg {
 806     foreach my $c (@_) {
 807         return undef if $c =~ /RETURN-UNDEF/;
 808         printdebug "C? $c\n" if $debuglevel >= 5;
 809         my $v = git_get_config($c);
 810         return $v if defined $v;
 811         my $dv = $defcfg{$c};
 812         if (defined $dv) {
 813             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 814             return $dv;
 815         }
 816     }
 817     badcfg f_
 818         "need value for one of: %s\n".
 819         "%s: distro or suite appears not to be (properly) supported",
 820         "@_", $us;
 821 }
 822
 823 sub not_necessarily_a_tree () {
 824     # needs to be called from pre_*
 825     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 826     $invoked_in_git_tree = 0;
 827 }
 828
 829 sub access_basedistro__noalias () {
 830     if (defined $idistro) {
 831         return $idistro;
 832     } else {
 833         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 834         return $def if defined $def;
 835         foreach my $src (@gitcfgsources, 'internal') {
 836             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 837             next unless $kl;
 838             foreach my $k (keys %$kl) {
 839                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 840                 my $dpat = $1;
 841                 next unless match_glob $dpat, $isuite;
 842                 return $kl->{$k};
 843             }
 844         }
 845         return cfg("dgit.default.distro");
 846     }
 847 }
 848
 849 sub access_basedistro () {
 850     my $noalias = access_basedistro__noalias();
 851     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 852     return $canon // $noalias;
 853 }
 854
 855 sub access_nomdistro () {
 856     my $base = access_basedistro();
 857     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 858     $r =~ m/^$distro_re$/ or badcfg
 859         f_ "bad syntax for (nominal) distro \`%s' (does not match %s)",
 860         $r, "/^$distro_re$/";
 861     return $r;
 862 }
 863
 864 sub access_quirk () {
 865     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 866     my $basedistro = access_basedistro();
 867     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 868                               'RETURN-UNDEF');
 869     if (defined $backports_quirk) {
 870         my $re = $backports_quirk;
 871         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 872         $re =~ s/\*/.*/g;
 873         $re =~ s/\%/([-0-9a-z_]+)/
 874             or $re =~ m/[()]/ or badcfg __ "backports-quirk needs \% or ( )";
 875         if ($isuite =~ m/^$re$/) {
 876             return ('backports',"$basedistro-backports",$1);
 877         }
 878     }
 879     return ('none',undef);
 880 }
 881
 882 our $access_forpush;
 883
 884 sub parse_cfg_bool ($$$) {
 885     my ($what,$def,$v) = @_;
 886     $v //= $def;
 887     return
 888         $v =~ m/^[ty1]/ ? 1 :
 889         $v =~ m/^[fn0]/ ? 0 :
 890         badcfg f_ "%s needs t (true, y, 1) or f (false, n, 0) not \`%s'",
 891             $what, $v;
 892 }
 893
 894 sub access_forpush_config () {
 895     my $d = access_basedistro();
 896
 897     return 1 if
 898         $new_package &&
 899         parse_cfg_bool('new-private-pushers', 0,
 900                        cfg("dgit-distro.$d.new-private-pushers",
 901                            'RETURN-UNDEF'));
 902
 903     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 904     $v //= 'a';
 905     return
 906         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 907         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 908         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 909         badcfg __
 910             "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 911 }
 912
 913 sub access_forpush () {
 914     $access_forpush //= access_forpush_config();
 915     return $access_forpush;
 916 }
 917
 918 sub pushing () {
 919     confess +(__ 'internal error').' '.Dumper($access_forpush)," ?" if
 920         defined $access_forpush and !$access_forpush;
 921     badcfg __ "pushing but distro is configured readonly"
 922         if access_forpush_config() eq '0';
 923     $access_forpush = 1;
 924     $supplementary_message = __ <<'END' unless $we_are_responder;
 925 Push failed, before we got started.
 926 You can retry the push, after fixing the problem, if you like.
 927 END
 928     parseopts_late_defaults();
 929 }
 930
 931 sub notpushing () {
 932     parseopts_late_defaults();
 933 }
 934
 935 sub supplementary_message ($) {
 936     my ($msg) = @_;
 937     if (!$we_are_responder) {
 938         $supplementary_message = $msg;
 939         return;
 940     } elsif ($protovsn >= 3) {
 941         responder_send_command "supplementary-message ".length($msg)
 942             or confess $!;
 943         print PO $msg or confess $!;
 944     }
 945 }
 946
 947 sub access_distros () {
 948     # Returns list of distros to try, in order
 949     #
 950     # We want to try:
 951     #    0. `instead of' distro name(s) we have been pointed to
 952     #    1. the access_quirk distro, if any
 953     #    2a. the user's specified distro, or failing that  } basedistro
 954     #    2b. the distro calculated from the suite          }
 955     my @l = access_basedistro();
 956
 957     my (undef,$quirkdistro) = access_quirk();
 958     unshift @l, $quirkdistro;
 959     unshift @l, $instead_distro;
 960     @l = grep { defined } @l;
 961
 962     push @l, access_nomdistro();
 963
 964     if (access_forpush()) {
 965         @l = map { ("$_/push", $_) } @l;
 966     }
 967     @l;
 968 }
 969
 970 sub access_cfg_cfgs (@) {
 971     my (@keys) = @_;
 972     my @cfgs;
 973     # The nesting of these loops determines the search order.  We put
 974     # the key loop on the outside so that we search all the distros
 975     # for each key, before going on to the next key.  That means that
 976     # if access_cfg is called with a more specific, and then a less
 977     # specific, key, an earlier distro can override the less specific
 978     # without necessarily overriding any more specific keys.  (If the
 979     # distro wants to override the more specific keys it can simply do
 980     # so; whereas if we did the loop the other way around, it would be
 981     # impossible to for an earlier distro to override a less specific
 982     # key but not the more specific ones without restating the unknown
 983     # values of the more specific keys.
 984     my @realkeys;
 985     my @rundef;
 986     # We have to deal with RETURN-UNDEF specially, so that we don't
 987     # terminate the search prematurely.
 988     foreach (@keys) {
 989         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 990         push @realkeys, $_
 991     }
 992     foreach my $d (access_distros()) {
 993         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 994     }
 995     push @cfgs, map { "dgit.default.$_" } @realkeys;
 996     push @cfgs, @rundef;
 997     return @cfgs;
 998 }
 999
1000 sub access_cfg (@) {
1001     my (@keys) = @_;
1002     my (@cfgs) = access_cfg_cfgs(@keys);
1003     my $value = cfg(@cfgs);
1004     return $value;
1005 }
1006
1007 sub access_cfg_bool ($$) {
1008     my ($def, @keys) = @_;
1009     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
1010 }
1011
1012 sub string_to_ssh ($) {
1013     my ($spec) = @_;
1014     if ($spec =~ m/\s/) {
1015         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
1016     } else {
1017         return ($spec);
1018     }
1019 }
1020
1021 sub access_cfg_ssh () {
1022     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
1023     if (!defined $gitssh) {
1024         return @ssh;
1025     } else {
1026         return string_to_ssh $gitssh;
1027     }
1028 }
1029
1030 sub access_runeinfo ($) {
1031     my ($info) = @_;
1032     return ": dgit ".access_basedistro()." $info ;";
1033 }
1034
1035 sub access_someuserhost ($) {
1036     my ($some) = @_;
1037     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
1038     defined($user) && length($user) or
1039         $user = access_cfg("$some-user",'username');
1040     my $host = access_cfg("$some-host");
1041     return length($user) ? "$user\@$host" : $host;
1042 }
1043
1044 sub access_gituserhost () {
1045     return access_someuserhost('git');
1046 }
1047
1048 sub access_giturl (;$) {
1049     my ($optional) = @_;
1050     my $url = access_cfg('git-url','RETURN-UNDEF');
1051     my $suffix;
1052     if (!length $url) {
1053         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
1054         return undef unless defined $proto;
1055         $url =
1056             $proto.
1057             access_gituserhost().
1058             access_cfg('git-path');
1059     } else {
1060         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
1061     }
1062     $suffix //= '.git';
1063     return "$url/$package$suffix";
1064 }
1065
1066 sub commit_getclogp ($) {
1067     # Returns the parsed changelog hashref for a particular commit
1068     my ($objid) = @_;
1069     our %commit_getclogp_memo;
1070     my $memo = $commit_getclogp_memo{$objid};
1071     return $memo if $memo;
1072
1073     my $mclog = dgit_privdir()."clog";
1074     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
1075         "$objid:debian/changelog";
1076     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
1077 }
1078
1079 sub parse_dscdata () {
1080     my $dscfh = new IO::File \$dscdata, '<' or confess $!;
1081     printdebug Dumper($dscdata) if $debuglevel>1;
1082     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1083     printdebug Dumper($dsc) if $debuglevel>1;
1084 }
1085
1086 our %rmad;
1087
1088 sub archive_query ($;@) {
1089     my ($method) = shift @_;
1090     fail __ "this operation does not support multiple comma-separated suites"
1091         if $isuite =~ m/,/;
1092     my $query = access_cfg('archive-query','RETURN-UNDEF');
1093     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1094     my $proto = $1;
1095     my $data = $'; #';
1096     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1097 }
1098
1099 sub archive_query_prepend_mirror {
1100     my $m = access_cfg('mirror');
1101     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1102 }
1103
1104 sub pool_dsc_subpath ($$) {
1105     my ($vsn,$component) = @_; # $package is implict arg
1106     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1107     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1108 }
1109
1110 sub cfg_apply_map ($$$) {
1111     my ($varref, $what, $mapspec) = @_;
1112     return unless $mapspec;
1113
1114     printdebug "config $what EVAL{ $mapspec; }\n";
1115     $_ = $$varref;
1116     eval "package Dgit::Config; $mapspec;";
1117     die $@ if $@;
1118     $$varref = $_;
1119 }
1120
1121 #---------- `ftpmasterapi' archive query method (nascent) ----------
1122
1123 sub archive_api_query_cmd ($) {
1124     my ($subpath) = @_;
1125     my @cmd = (@curl, qw(-sS));
1126     my $url = access_cfg('archive-query-url');
1127     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1128         my $host = $1;
1129         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1130         foreach my $key (split /\:/, $keys) {
1131             $key =~ s/\%HOST\%/$host/g;
1132             if (!stat $key) {
1133                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1134                 next;
1135             }
1136             fail f_ "config requested specific TLS key but do not know".
1137                     " how to get curl to use exactly that EE key (%s)",
1138                     $key;
1139 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1140 #           # Sadly the above line does not work because of changes
1141 #           # to gnutls.   The real fix for #790093 may involve
1142 #           # new curl options.
1143             last;
1144         }
1145         # Fixing #790093 properly will involve providing a value
1146         # for this on clients.
1147         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1148         push @cmd, split / /, $kargs if defined $kargs;
1149     }
1150     push @cmd, $url.$subpath;
1151     return @cmd;
1152 }
1153
1154 sub api_query ($$;$) {
1155     use JSON;
1156     my ($data, $subpath, $ok404) = @_;
1157     badcfg __ "ftpmasterapi archive query method takes no data part"
1158         if length $data;
1159     my @cmd = archive_api_query_cmd($subpath);
1160     my $url = $cmd[$#cmd];
1161     push @cmd, qw(-w %{http_code});
1162     my $json = cmdoutput @cmd;
1163     unless ($json =~ s/\d+\d+\d$//) {
1164         failedcmd_report_cmd undef, @cmd;
1165         fail __ "curl failed to print 3-digit HTTP code";
1166     }
1167     my $code = $&;
1168     return undef if $code eq '404' && $ok404;
1169     fail f_ "fetch of %s gave HTTP code %s", $url, $code
1170         unless $url =~ m#^file://# or $code =~ m/^2/;
1171     return decode_json($json);
1172 }
1173
1174 sub canonicalise_suite_ftpmasterapi {
1175     my ($proto,$data) = @_;
1176     my $suites = api_query($data, 'suites');
1177     my @matched;
1178     foreach my $entry (@$suites) {
1179         next unless grep {
1180             my $v = $entry->{$_};
1181             defined $v && $v eq $isuite;
1182         } qw(codename name);
1183         push @matched, $entry;
1184     }
1185     fail f_ "unknown suite %s, maybe -d would help", $isuite
1186         unless @matched;
1187     my $cn;
1188     eval {
1189         @matched==1 or die f_ "multiple matches for suite %s\n", $isuite;
1190         $cn = "$matched[0]{codename}";
1191         defined $cn or die f_ "suite %s info has no codename\n", $isuite;
1192         $cn =~ m/^$suite_re$/
1193             or die f_ "suite %s maps to bad codename\n", $isuite;
1194     };
1195     die +(__ "bad ftpmaster api response: ")."$@\n".Dumper(\@matched)
1196         if length $@;
1197     return $cn;
1198 }
1199
1200 sub archive_query_ftpmasterapi {
1201     my ($proto,$data) = @_;
1202     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1203     my @rows;
1204     my $digester = Digest::SHA->new(256);
1205     foreach my $entry (@$info) {
1206         eval {
1207             my $vsn = "$entry->{version}";
1208             my ($ok,$msg) = version_check $vsn;
1209             die f_ "bad version: %s\n", $msg unless $ok;
1210             my $component = "$entry->{component}";
1211             $component =~ m/^$component_re$/ or die __ "bad component";
1212             my $filename = "$entry->{filename}";
1213             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1214                 or die __ "bad filename";
1215             my $sha256sum = "$entry->{sha256sum}";
1216             $sha256sum =~ m/^[0-9a-f]+$/ or die __ "bad sha256sum";
1217             push @rows, [ $vsn, "/pool/$component/$filename",
1218                           $digester, $sha256sum ];
1219         };
1220         die +(__ "bad ftpmaster api response: ")."$@\n".Dumper($entry)
1221             if length $@;
1222     }
1223     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1224     return archive_query_prepend_mirror @rows;
1225 }
1226
1227 sub file_in_archive_ftpmasterapi {
1228     my ($proto,$data,$filename) = @_;
1229     my $pat = $filename;
1230     $pat =~ s/_/\\_/g;
1231     $pat = "%/$pat";
1232     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1233     my $info = api_query($data, "file_in_archive/$pat", 1);
1234 }
1235
1236 sub package_not_wholly_new_ftpmasterapi {
1237     my ($proto,$data,$pkg) = @_;
1238     my $info = api_query($data,"madison?package=${pkg}&f=json");
1239     return !!@$info;
1240 }
1241
1242 #---------- `aptget' archive query method ----------
1243
1244 our $aptget_base;
1245 our $aptget_releasefile;
1246 our $aptget_configpath;
1247
1248 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1249 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1250
1251 sub aptget_cache_clean {
1252     runcmd_ordryrun_local qw(sh -ec),
1253         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1254         'x', $aptget_base;
1255 }
1256
1257 sub aptget_lock_acquire () {
1258     my $lockfile = "$aptget_base/lock";
1259     open APTGET_LOCK, '>', $lockfile or confess "open $lockfile: $!";
1260     flock APTGET_LOCK, LOCK_EX or confess "lock $lockfile: $!";
1261 }
1262
1263 sub aptget_prep ($) {
1264     my ($data) = @_;
1265     return if defined $aptget_base;
1266
1267     badcfg __ "aptget archive query method takes no data part"
1268         if length $data;
1269
1270     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1271
1272     ensuredir $cache;
1273     ensuredir "$cache/dgit";
1274     my $cachekey =
1275         access_cfg('aptget-cachekey','RETURN-UNDEF')
1276         // access_nomdistro();
1277
1278     $aptget_base = "$cache/dgit/aptget";
1279     ensuredir $aptget_base;
1280
1281     my $quoted_base = $aptget_base;
1282     confess "$quoted_base contains bad chars, cannot continue"
1283         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1284
1285     ensuredir $aptget_base;
1286
1287     aptget_lock_acquire();
1288
1289     aptget_cache_clean();
1290
1291     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1292     my $sourceslist = "source.list#$cachekey";
1293
1294     my $aptsuites = $isuite;
1295     cfg_apply_map(\$aptsuites, 'suite map',
1296                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1297
1298     open SRCS, ">", "$aptget_base/$sourceslist" or confess $!;
1299     printf SRCS "deb-src %s %s %s\n",
1300         access_cfg('mirror'),
1301         $aptsuites,
1302         access_cfg('aptget-components')
1303         or confess $!;
1304
1305     ensuredir "$aptget_base/cache";
1306     ensuredir "$aptget_base/lists";
1307
1308     open CONF, ">", $aptget_configpath or confess $!;
1309     print CONF <<END;
1310 Debug::NoLocking "true";
1311 APT::Get::List-Cleanup "false";
1312 #clear APT::Update::Post-Invoke-Success;
1313 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1314 Dir::State::Lists "$quoted_base/lists";
1315 Dir::Etc::preferences "$quoted_base/preferences";
1316 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1317 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1318 END
1319
1320     foreach my $key (qw(
1321                         Dir::Cache
1322                         Dir::State
1323                         Dir::Cache::Archives
1324                         Dir::Etc::SourceParts
1325                         Dir::Etc::preferencesparts
1326                       )) {
1327         ensuredir "$aptget_base/$key";
1328         print CONF "$key \"$quoted_base/$key\";\n" or confess $!;
1329     };
1330
1331     my $oldatime = (time // confess $!) - 1;
1332     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1333         next unless stat_exists $oldlist;
1334         my ($mtime) = (stat _)[9];
1335         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1336     }
1337
1338     runcmd_ordryrun_local aptget_aptget(), qw(update);
1339
1340     my @releasefiles;
1341     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1342         next unless stat_exists $oldlist;
1343         my ($atime) = (stat _)[8];
1344         next if $atime == $oldatime;
1345         push @releasefiles, $oldlist;
1346     }
1347     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1348     @releasefiles = @inreleasefiles if @inreleasefiles;
1349     if (!@releasefiles) {
1350         fail f_ <<END, $isuite, $cache;
1351 apt seemed to not to update dgit's cached Release files for %s.
1352 (Perhaps %s
1353  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1354 END
1355     }
1356     confess "apt updated too many Release files (@releasefiles), erk"
1357         unless @releasefiles == 1;
1358
1359     ($aptget_releasefile) = @releasefiles;
1360 }
1361
1362 sub canonicalise_suite_aptget {
1363     my ($proto,$data) = @_;
1364     aptget_prep($data);
1365
1366     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1367
1368     foreach my $name (qw(Codename Suite)) {
1369         my $val = $release->{$name};
1370         if (defined $val) {
1371             printdebug "release file $name: $val\n";
1372             $val =~ m/^$suite_re$/o or fail f_
1373                 "Release file (%s) specifies intolerable %s",
1374                 $aptget_releasefile, $name;
1375             cfg_apply_map(\$val, 'suite rmap',
1376                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1377             return $val
1378         }
1379     }
1380     return $isuite;
1381 }
1382
1383 sub archive_query_aptget {
1384     my ($proto,$data) = @_;
1385     aptget_prep($data);
1386
1387     ensuredir "$aptget_base/source";
1388     foreach my $old (<$aptget_base/source/*.dsc>) {
1389         unlink $old or die "$old: $!";
1390     }
1391
1392     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1393     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1394     # avoids apt-get source failing with ambiguous error code
1395
1396     runcmd_ordryrun_local
1397         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1398         aptget_aptget(), qw(--download-only --only-source source), $package;
1399
1400     my @dscs = <$aptget_base/source/*.dsc>;
1401     fail __ "apt-get source did not produce a .dsc" unless @dscs;
1402     fail f_ "apt-get source produced several .dscs (%s)", "@dscs"
1403         unless @dscs==1;
1404
1405     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1406
1407     use URI::Escape;
1408     my $uri = "file://". uri_escape $dscs[0];
1409     $uri =~ s{\%2f}{/}gi;
1410     return [ (getfield $pre_dsc, 'Version'), $uri ];
1411 }
1412
1413 sub file_in_archive_aptget () { return undef; }
1414 sub package_not_wholly_new_aptget () { return undef; }
1415
1416 #---------- `dummyapicat' archive query method ----------
1417 # (untranslated, because this is for testing purposes etc.)
1418
1419 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1420 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1421
1422 sub dummycatapi_run_in_mirror ($@) {
1423     # runs $fn with FIA open onto rune
1424     my ($rune, $argl, $fn) = @_;
1425
1426     my $mirror = access_cfg('mirror');
1427     $mirror =~ s#^file://#/# or die "$mirror ?";
1428     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1429                qw(x), $mirror, @$argl);
1430     debugcmd "-|", @cmd;
1431     open FIA, "-|", @cmd or confess $!;
1432     my $r = $fn->();
1433     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1434     return $r;
1435 }
1436
1437 sub file_in_archive_dummycatapi ($$$) {
1438     my ($proto,$data,$filename) = @_;
1439     my @out;
1440     dummycatapi_run_in_mirror '
1441             find -name "$1" -print0 |
1442             xargs -0r sha256sum
1443     ', [$filename], sub {
1444         while (<FIA>) {
1445             chomp or die;
1446             printdebug "| $_\n";
1447             m/^(\w+)  (\S+)$/ or die "$_ ?";
1448             push @out, { sha256sum => $1, filename => $2 };
1449         }
1450     };
1451     return \@out;
1452 }
1453
1454 sub package_not_wholly_new_dummycatapi {
1455     my ($proto,$data,$pkg) = @_;
1456     dummycatapi_run_in_mirror "
1457             find -name ${pkg}_*.dsc
1458     ", [], sub {
1459         local $/ = undef;
1460         !!<FIA>;
1461     };
1462 }
1463
1464 #---------- `madison' archive query method ----------
1465
1466 sub archive_query_madison {
1467     return archive_query_prepend_mirror
1468         map { [ @$_[0..1] ] } madison_get_parse(@_);
1469 }
1470
1471 sub madison_get_parse {
1472     my ($proto,$data) = @_;
1473     die unless $proto eq 'madison';
1474     if (!length $data) {
1475         $data= access_cfg('madison-distro','RETURN-UNDEF');
1476         $data //= access_basedistro();
1477     }
1478     $rmad{$proto,$data,$package} ||= cmdoutput
1479         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1480     my $rmad = $rmad{$proto,$data,$package};
1481
1482     my @out;
1483     foreach my $l (split /\n/, $rmad) {
1484         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1485                   \s*( [^ \t|]+ )\s* \|
1486                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1487                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1488         $1 eq $package or die "$rmad $package ?";
1489         my $vsn = $2;
1490         my $newsuite = $3;
1491         my $component;
1492         if (defined $4) {
1493             $component = $4;
1494         } else {
1495             $component = access_cfg('archive-query-default-component');
1496         }
1497         $5 eq 'source' or die "$rmad ?";
1498         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1499     }
1500     return sort { -version_compare($a->[0],$b->[0]); } @out;
1501 }
1502
1503 sub canonicalise_suite_madison {
1504     # madison canonicalises for us
1505     my @r = madison_get_parse(@_);
1506     @r or fail f_
1507         "unable to canonicalise suite using package %s".
1508         " which does not appear to exist in suite %s;".
1509         " --existing-package may help",
1510         $package, $isuite;
1511     return $r[0][2];
1512 }
1513
1514 sub file_in_archive_madison { return undef; }
1515 sub package_not_wholly_new_madison { return undef; }
1516
1517 #---------- `sshpsql' archive query method ----------
1518 # (untranslated, because this is obsolete)
1519
1520 sub sshpsql ($$$) {
1521     my ($data,$runeinfo,$sql) = @_;
1522     if (!length $data) {
1523         $data= access_someuserhost('sshpsql').':'.
1524             access_cfg('sshpsql-dbname');
1525     }
1526     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1527     my ($userhost,$dbname) = ($`,$'); #';
1528     my @rows;
1529     my @cmd = (access_cfg_ssh, $userhost,
1530                access_runeinfo("ssh-psql $runeinfo").
1531                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1532                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1533     debugcmd "|",@cmd;
1534     open P, "-|", @cmd or confess $!;
1535     while (<P>) {
1536         chomp or die;
1537         printdebug(">|$_|\n");
1538         push @rows, $_;
1539     }
1540     $!=0; $?=0; close P or failedcmd @cmd;
1541     @rows or die;
1542     my $nrows = pop @rows;
1543     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1544     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1545     @rows = map { [ split /\|/, $_ ] } @rows;
1546     my $ncols = scalar @{ shift @rows };
1547     die if grep { scalar @$_ != $ncols } @rows;
1548     return @rows;
1549 }
1550
1551 sub sql_injection_check {
1552     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1553 }
1554
1555 sub archive_query_sshpsql ($$) {
1556     my ($proto,$data) = @_;
1557     sql_injection_check $isuite, $package;
1558     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1559         SELECT source.version, component.name, files.filename, files.sha256sum
1560           FROM source
1561           JOIN src_associations ON source.id = src_associations.source
1562           JOIN suite ON suite.id = src_associations.suite
1563           JOIN dsc_files ON dsc_files.source = source.id
1564           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1565           JOIN component ON component.id = files_archive_map.component_id
1566           JOIN files ON files.id = dsc_files.file
1567          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1568            AND source.source='$package'
1569            AND files.filename LIKE '%.dsc';
1570 END
1571     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1572     my $digester = Digest::SHA->new(256);
1573     @rows = map {
1574         my ($vsn,$component,$filename,$sha256sum) = @$_;
1575         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1576     } @rows;
1577     return archive_query_prepend_mirror @rows;
1578 }
1579
1580 sub canonicalise_suite_sshpsql ($$) {
1581     my ($proto,$data) = @_;
1582     sql_injection_check $isuite;
1583     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1584         SELECT suite.codename
1585           FROM suite where suite_name='$isuite' or codename='$isuite';
1586 END
1587     @rows = map { $_->[0] } @rows;
1588     fail "unknown suite $isuite" unless @rows;
1589     die "ambiguous $isuite: @rows ?" if @rows>1;
1590     return $rows[0];
1591 }
1592
1593 sub file_in_archive_sshpsql ($$$) { return undef; }
1594 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1595
1596 #---------- `dummycat' archive query method ----------
1597 # (untranslated, because this is for testing purposes etc.)
1598
1599 sub canonicalise_suite_dummycat ($$) {
1600     my ($proto,$data) = @_;
1601     my $dpath = "$data/suite.$isuite";
1602     if (!open C, "<", $dpath) {
1603         $!==ENOENT or die "$dpath: $!";
1604         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1605         return $isuite;
1606     }
1607     $!=0; $_ = <C>;
1608     chomp or die "$dpath: $!";
1609     close C;
1610     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1611     return $_;
1612 }
1613
1614 sub archive_query_dummycat ($$) {
1615     my ($proto,$data) = @_;
1616     canonicalise_suite();
1617     my $dpath = "$data/package.$csuite.$package";
1618     if (!open C, "<", $dpath) {
1619         $!==ENOENT or die "$dpath: $!";
1620         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1621         return ();
1622     }
1623     my @rows;
1624     while (<C>) {
1625         next if m/^\#/;
1626         next unless m/\S/;
1627         die unless chomp;
1628         printdebug "dummycat query $csuite $package $dpath | $_\n";
1629         my @row = split /\s+/, $_;
1630         @row==2 or die "$dpath: $_ ?";
1631         push @rows, \@row;
1632     }
1633     C->error and die "$dpath: $!";
1634     close C;
1635     return archive_query_prepend_mirror
1636         sort { -version_compare($a->[0],$b->[0]); } @rows;
1637 }
1638
1639 sub file_in_archive_dummycat () { return undef; }
1640 sub package_not_wholly_new_dummycat () { return undef; }
1641
1642 #---------- tag format handling ----------
1643 # (untranslated, because everything should be new tag format by now)
1644
1645 sub access_cfg_tagformats () {
1646     split /\,/, access_cfg('dgit-tag-format');
1647 }
1648
1649 sub access_cfg_tagformats_can_splitbrain () {
1650     my %y = map { $_ => 1 } access_cfg_tagformats;
1651     foreach my $needtf (qw(new maint)) {
1652         next if $y{$needtf};
1653         return 0;
1654     }
1655     return 1;
1656 }
1657
1658 sub need_tagformat ($$) {
1659     my ($fmt, $why) = @_;
1660     fail "need to use tag format $fmt ($why) but also need".
1661         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1662         " - no way to proceed"
1663         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1664     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1665 }
1666
1667 sub select_tagformat () {
1668     # sets $tagformatfn
1669     return if $tagformatfn && !$tagformat_want;
1670     die 'bug' if $tagformatfn && $tagformat_want;
1671     # ... $tagformat_want assigned after previous select_tagformat
1672
1673     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1674     printdebug "select_tagformat supported @supported\n";
1675
1676     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1677     printdebug "select_tagformat specified @$tagformat_want\n";
1678
1679     my ($fmt,$why,$override) = @$tagformat_want;
1680
1681     fail "target distro supports tag formats @supported".
1682         " but have to use $fmt ($why)"
1683         unless $override
1684             or grep { $_ eq $fmt } @supported;
1685
1686     $tagformat_want = undef;
1687     $tagformat = $fmt;
1688     $tagformatfn = ${*::}{"debiantag_$fmt"};
1689
1690     fail "trying to use unknown tag format \`$fmt' ($why) !"
1691         unless $tagformatfn;
1692 }
1693
1694 #---------- archive query entrypoints and rest of program ----------
1695
1696 sub canonicalise_suite () {
1697     return if defined $csuite;
1698     fail f_ "cannot operate on %s suite", $isuite if $isuite eq 'UNRELEASED';
1699     $csuite = archive_query('canonicalise_suite');
1700     if ($isuite ne $csuite) {
1701         progress f_ "canonical suite name for %s is %s", $isuite, $csuite;
1702     } else {
1703         progress f_ "canonical suite name is %s", $csuite;
1704     }
1705 }
1706
1707 sub get_archive_dsc () {
1708     canonicalise_suite();
1709     my @vsns = archive_query('archive_query');
1710     foreach my $vinfo (@vsns) {
1711         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1712         $dscurl = $vsn_dscurl;
1713         $dscdata = url_get($dscurl);
1714         if (!$dscdata) {
1715             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1716             next;
1717         }
1718         if ($digester) {
1719             $digester->reset();
1720             $digester->add($dscdata);
1721             my $got = $digester->hexdigest();
1722             $got eq $digest or
1723                 fail f_ "%s has hash %s but archive told us to expect %s",
1724                         $dscurl, $got, $digest;
1725         }
1726         parse_dscdata();
1727         my $fmt = getfield $dsc, 'Format';
1728         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1729             f_ "unsupported source format %s, sorry", $fmt;
1730
1731         $dsc_checked = !!$digester;
1732         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1733         return;
1734     }
1735     $dsc = undef;
1736     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1737 }
1738
1739 sub check_for_git ();
1740 sub check_for_git () {
1741     # returns 0 or 1
1742     my $how = access_cfg('git-check');
1743     if ($how eq 'ssh-cmd') {
1744         my @cmd =
1745             (access_cfg_ssh, access_gituserhost(),
1746              access_runeinfo("git-check $package").
1747              " set -e; cd ".access_cfg('git-path').";".
1748              " if test -d $package.git; then echo 1; else echo 0; fi");
1749         my $r= cmdoutput @cmd;
1750         if (defined $r and $r =~ m/^divert (\w+)$/) {
1751             my $divert=$1;
1752             my ($usedistro,) = access_distros();
1753             # NB that if we are pushing, $usedistro will be $distro/push
1754             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1755             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1756             progress f_ "diverting to %s (using config for %s)",
1757                         $divert, $instead_distro;
1758             return check_for_git();
1759         }
1760         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1761         return $r+0;
1762     } elsif ($how eq 'url') {
1763         my $prefix = access_cfg('git-check-url','git-url');
1764         my $suffix = access_cfg('git-check-suffix','git-suffix',
1765                                 'RETURN-UNDEF') // '.git';
1766         my $url = "$prefix/$package$suffix";
1767         my @cmd = (@curl, qw(-sS -I), $url);
1768         my $result = cmdoutput @cmd;
1769         $result =~ s/^\S+ 200 .*\n\r?\n//;
1770         # curl -sS -I with https_proxy prints
1771         # HTTP/1.0 200 Connection established
1772         $result =~ m/^\S+ (404|200) /s or
1773             fail +(__ "unexpected results from git check query - ").
1774                 Dumper($prefix, $result);
1775         my $code = $1;
1776         if ($code eq '404') {
1777             return 0;
1778         } elsif ($code eq '200') {
1779             return 1;
1780         } else {
1781             die;
1782         }
1783     } elsif ($how eq 'true') {
1784         return 1;
1785     } elsif ($how eq 'false') {
1786         return 0;
1787     } else {
1788         badcfg f_ "unknown git-check \`%s'", $how;
1789     }
1790 }
1791
1792 sub create_remote_git_repo () {
1793     my $how = access_cfg('git-create');
1794     if ($how eq 'ssh-cmd') {
1795         runcmd_ordryrun
1796             (access_cfg_ssh, access_gituserhost(),
1797              access_runeinfo("git-create $package").
1798              "set -e; cd ".access_cfg('git-path').";".
1799              " cp -a _template $package.git");
1800     } elsif ($how eq 'true') {
1801         # nothing to do
1802     } else {
1803         badcfg f_ "unknown git-create \`%s'", $how;
1804     }
1805 }
1806
1807 our ($dsc_hash,$lastpush_mergeinput);
1808 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1809
1810
1811 sub prep_ud () {
1812     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1813     $playground = fresh_playground 'dgit/unpack';
1814 }
1815
1816 sub mktree_in_ud_here () {
1817     playtree_setup $gitcfgs{local};
1818 }
1819
1820 sub git_write_tree () {
1821     my $tree = cmdoutput @git, qw(write-tree);
1822     $tree =~ m/^\w+$/ or die "$tree ?";
1823     return $tree;
1824 }
1825
1826 sub git_add_write_tree () {
1827     runcmd @git, qw(add -Af .);
1828     return git_write_tree();
1829 }
1830
1831 sub remove_stray_gits ($) {
1832     my ($what) = @_;
1833     my @gitscmd = qw(find -name .git -prune -print0);
1834     debugcmd "|",@gitscmd;
1835     open GITS, "-|", @gitscmd or confess $!;
1836     {
1837         local $/="\0";
1838         while (<GITS>) {
1839             chomp or die;
1840             print STDERR f_ "%s: warning: removing from %s: %s\n",
1841                 $us, $what, (messagequote $_);
1842             rmtree $_;
1843         }
1844     }
1845     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1846 }
1847
1848 sub mktree_in_ud_from_only_subdir ($;$) {
1849     my ($what,$raw) = @_;
1850     # changes into the subdir
1851
1852     my (@dirs) = <*/.>;
1853     confess "expected one subdir but found @dirs ?" unless @dirs==1;
1854     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1855     my $dir = $1;
1856     changedir $dir;
1857
1858     remove_stray_gits($what);
1859     mktree_in_ud_here();
1860     if (!$raw) {
1861         my ($format, $fopts) = get_source_format();
1862         if (madformat($format)) {
1863             rmtree '.pc';
1864         }
1865     }
1866
1867     my $tree=git_add_write_tree();
1868     return ($tree,$dir);
1869 }
1870
1871 our @files_csum_info_fields =
1872     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1873      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1874      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1875
1876 sub dsc_files_info () {
1877     foreach my $csumi (@files_csum_info_fields) {
1878         my ($fname, $module, $method) = @$csumi;
1879         my $field = $dsc->{$fname};
1880         next unless defined $field;
1881         eval "use $module; 1;" or die $@;
1882         my @out;
1883         foreach (split /\n/, $field) {
1884             next unless m/\S/;
1885             m/^(\w+) (\d+) (\S+)$/ or
1886                 fail f_ "could not parse .dsc %s line \`%s'", $fname, $_;
1887             my $digester = eval "$module"."->$method;" or die $@;
1888             push @out, {
1889                 Hash => $1,
1890                 Bytes => $2,
1891                 Filename => $3,
1892                 Digester => $digester,
1893             };
1894         }
1895         return @out;
1896     }
1897     fail f_ "missing any supported Checksums-* or Files field in %s",
1898             $dsc->get_option('name');
1899 }
1900
1901 sub dsc_files () {
1902     map { $_->{Filename} } dsc_files_info();
1903 }
1904
1905 sub files_compare_inputs (@) {
1906     my $inputs = \@_;
1907     my %record;
1908     my %fchecked;
1909
1910     my $showinputs = sub {
1911         return join "; ", map { $_->get_option('name') } @$inputs;
1912     };
1913
1914     foreach my $in (@$inputs) {
1915         my $expected_files;
1916         my $in_name = $in->get_option('name');
1917
1918         printdebug "files_compare_inputs $in_name\n";
1919
1920         foreach my $csumi (@files_csum_info_fields) {
1921             my ($fname) = @$csumi;
1922             printdebug "files_compare_inputs $in_name $fname\n";
1923
1924             my $field = $in->{$fname};
1925             next unless defined $field;
1926
1927             my @files;
1928             foreach (split /\n/, $field) {
1929                 next unless m/\S/;
1930
1931                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1932                     fail "could not parse $in_name $fname line \`$_'";
1933
1934                 printdebug "files_compare_inputs $in_name $fname $f\n";
1935
1936                 push @files, $f;
1937
1938                 my $re = \ $record{$f}{$fname};
1939                 if (defined $$re) {
1940                     $fchecked{$f}{$in_name} = 1;
1941                     $$re eq $info or
1942                         fail f_
1943               "hash or size of %s varies in %s fields (between: %s)",
1944                                  $f, $fname, $showinputs->();
1945                 } else {
1946                     $$re = $info;
1947                 }
1948             }
1949             @files = sort @files;
1950             $expected_files //= \@files;
1951             "@$expected_files" eq "@files" or
1952                 fail f_ "file list in %s varies between hash fields!",
1953                         $in_name;
1954         }
1955         $expected_files or
1956             fail f_ "%s has no files list field(s)", $in_name;
1957     }
1958     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1959         if $debuglevel>=2;
1960
1961     grep { keys %$_ == @$inputs-1 } values %fchecked
1962         or fail f_ "no file appears in all file lists (looked in: %s)",
1963                    $showinputs->();
1964 }
1965
1966 sub is_orig_file_in_dsc ($$) {
1967     my ($f, $dsc_files_info) = @_;
1968     return 0 if @$dsc_files_info <= 1;
1969     # One file means no origs, and the filename doesn't have a "what
1970     # part of dsc" component.  (Consider versions ending `.orig'.)
1971     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1972     return 1;
1973 }
1974
1975 # This function determines whether a .changes file is source-only from
1976 # the point of view of dak.  Thus, it permits *_source.buildinfo
1977 # files.
1978 #
1979 # It does not, however, permit any other buildinfo files.  After a
1980 # source-only upload, the buildds will try to upload files like
1981 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1982 # named like this in their (otherwise) source-only upload, the uploads
1983 # of the buildd can be rejected by dak.  Fixing the resultant
1984 # situation can require manual intervention.  So we block such
1985 # .buildinfo files when the user tells us to perform a source-only
1986 # upload (such as when using the push-source subcommand with the -C
1987 # option, which calls this function).
1988 #
1989 # Note, though, that when dgit is told to prepare a source-only
1990 # upload, such as when subcommands like build-source and push-source
1991 # without -C are used, dgit has a more restrictive notion of
1992 # source-only .changes than dak: such uploads will never include
1993 # *_source.buildinfo files.  This is because there is no use for such
1994 # files when using a tool like dgit to produce the source package, as
1995 # dgit ensures the source is identical to git HEAD.
1996 sub test_source_only_changes ($) {
1997     my ($changes) = @_;
1998     foreach my $l (split /\n/, getfield $changes, 'Files') {
1999         $l =~ m/\S+$/ or next;
2000         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
2001         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
2002             print f_ "purportedly source-only changes polluted by %s\n", $&;
2003             return 0;
2004         }
2005     }
2006     return 1;
2007 }
2008
2009 sub changes_update_origs_from_dsc ($$$$) {
2010     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
2011     my %changes_f;
2012     printdebug "checking origs needed ($upstreamvsn)...\n";
2013     $_ = getfield $changes, 'Files';
2014     m/^\w+ \d+ (\S+ \S+) \S+$/m or
2015         fail __ "cannot find section/priority from .changes Files field";
2016     my $placementinfo = $1;
2017     my %changed;
2018     printdebug "checking origs needed placement '$placementinfo'...\n";
2019     foreach my $l (split /\n/, getfield $dsc, 'Files') {
2020         $l =~ m/\S+$/ or next;
2021         my $file = $&;
2022         printdebug "origs $file | $l\n";
2023         next unless is_orig_file_of_vsn $file, $upstreamvsn;
2024         printdebug "origs $file is_orig\n";
2025         my $have = archive_query('file_in_archive', $file);
2026         if (!defined $have) {
2027             print STDERR __ <<END;
2028 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
2029 END
2030             return;
2031         }
2032         my $found_same = 0;
2033         my @found_differ;
2034         printdebug "origs $file \$#\$have=$#$have\n";
2035         foreach my $h (@$have) {
2036             my $same = 0;
2037             my @differ;
2038             foreach my $csumi (@files_csum_info_fields) {
2039                 my ($fname, $module, $method, $archivefield) = @$csumi;
2040                 next unless defined $h->{$archivefield};
2041                 $_ = $dsc->{$fname};
2042                 next unless defined;
2043                 m/^(\w+) .* \Q$file\E$/m or
2044                     fail f_ ".dsc %s missing entry for %s", $fname, $file;
2045                 if ($h->{$archivefield} eq $1) {
2046                     $same++;
2047                 } else {
2048                     push @differ, f_
2049                         "%s: %s (archive) != %s (local .dsc)",
2050                         $archivefield, $h->{$archivefield}, $1;
2051                 }
2052             }
2053             confess "$file ".Dumper($h)." ?!" if $same && @differ;
2054             $found_same++
2055                 if $same;
2056             push @found_differ,
2057                 f_ "archive %s: %s", $h->{filename}, join "; ", @differ
2058                 if @differ;
2059         }
2060         printdebug "origs $file f.same=$found_same".
2061             " #f._differ=$#found_differ\n";
2062         if (@found_differ && !$found_same) {
2063             fail join "\n",
2064                 (f_ "archive contains %s with different checksum", $file),
2065                 @found_differ;
2066         }
2067         # Now we edit the changes file to add or remove it
2068         foreach my $csumi (@files_csum_info_fields) {
2069             my ($fname, $module, $method, $archivefield) = @$csumi;
2070             next unless defined $changes->{$fname};
2071             if ($found_same) {
2072                 # in archive, delete from .changes if it's there
2073                 $changed{$file} = "removed" if
2074                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
2075             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
2076                 # not in archive, but it's here in the .changes
2077             } else {
2078                 my $dsc_data = getfield $dsc, $fname;
2079                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
2080                 my $extra = $1;
2081                 $extra =~ s/ \d+ /$&$placementinfo /
2082                     or confess "$fname $extra >$dsc_data< ?"
2083                     if $fname eq 'Files';
2084                 $changes->{$fname} .= "\n". $extra;
2085                 $changed{$file} = "added";
2086             }
2087         }
2088     }
2089     if (%changed) {
2090         foreach my $file (keys %changed) {
2091             progress f_
2092                 "edited .changes for archive .orig contents: %s %s",
2093                 $changed{$file}, $file;
2094         }
2095         my $chtmp = "$changesfile.tmp";
2096         $changes->save($chtmp);
2097         if (act_local()) {
2098             rename $chtmp,$changesfile or die "$changesfile $!";
2099         } else {
2100             progress f_ "[new .changes left in %s]", $changesfile;
2101         }
2102     } else {
2103         progress f_ "%s already has appropriate .orig(s) (if any)",
2104                     $changesfile;
2105     }
2106 }
2107
2108 sub make_commit ($) {
2109     my ($file) = @_;
2110     return cmdoutput @git, qw(hash-object -w -t commit), $file;
2111 }
2112
2113 sub clogp_authline ($) {
2114     my ($clogp) = @_;
2115     my $author = getfield $clogp, 'Maintainer';
2116     if ($author =~ m/^[^"\@]+\,/) {
2117         # single entry Maintainer field with unquoted comma
2118         $author = ($& =~ y/,//rd).$'; # strip the comma
2119     }
2120     # git wants a single author; any remaining commas in $author
2121     # are by now preceded by @ (or ").  It seems safer to punt on
2122     # "..." for now rather than attempting to dequote or something.
2123     $author =~ s#,.*##ms unless $author =~ m/"/;
2124     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2125     my $authline = "$author $date";
2126     $authline =~ m/$git_authline_re/o or
2127         fail f_ "unexpected commit author line format \`%s'".
2128                 " (was generated from changelog Maintainer field)",
2129                 $authline;
2130     return ($1,$2,$3) if wantarray;
2131     return $authline;
2132 }
2133
2134 sub vendor_patches_distro ($$) {
2135     my ($checkdistro, $what) = @_;
2136     return unless defined $checkdistro;
2137
2138     my $series = "debian/patches/\L$checkdistro\E.series";
2139     printdebug "checking for vendor-specific $series ($what)\n";
2140
2141     if (!open SERIES, "<", $series) {
2142         confess "$series $!" unless $!==ENOENT;
2143         return;
2144     }
2145     while (<SERIES>) {
2146         next unless m/\S/;
2147         next if m/^\s+\#/;
2148
2149         print STDERR __ <<END;
2150
2151 Unfortunately, this source package uses a feature of dpkg-source where
2152 the same source package unpacks to different source code on different
2153 distros.  dgit cannot safely operate on such packages on affected
2154 distros, because the meaning of source packages is not stable.
2155
2156 Please ask the distro/maintainer to remove the distro-specific series
2157 files and use a different technique (if necessary, uploading actually
2158 different packages, if different distros are supposed to have
2159 different code).
2160
2161 END
2162         fail f_ "Found active distro-specific series file for".
2163                 " %s (%s): %s, cannot continue",
2164                 $checkdistro, $what, $series;
2165     }
2166     die "$series $!" if SERIES->error;
2167     close SERIES;
2168 }
2169
2170 sub check_for_vendor_patches () {
2171     # This dpkg-source feature doesn't seem to be documented anywhere!
2172     # But it can be found in the changelog (reformatted):
2173
2174     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2175     #   Author: Raphael Hertzog <hertzog@debian.org>
2176     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2177
2178     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2179     #   series files
2180     #
2181     #   If you have debian/patches/ubuntu.series and you were
2182     #   unpacking the source package on ubuntu, quilt was still
2183     #   directed to debian/patches/series instead of
2184     #   debian/patches/ubuntu.series.
2185     #
2186     #   debian/changelog                        |    3 +++
2187     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2188     #   2 files changed, 6 insertions(+), 1 deletion(-)
2189
2190     use Dpkg::Vendor;
2191     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2192     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2193                           __ "Dpkg::Vendor \`current vendor'");
2194     vendor_patches_distro(access_basedistro(),
2195                           __ "(base) distro being accessed");
2196     vendor_patches_distro(access_nomdistro(),
2197                           __ "(nominal) distro being accessed");
2198 }
2199
2200 sub generate_commits_from_dsc () {
2201     # See big comment in fetch_from_archive, below.
2202     # See also README.dsc-import.
2203     prep_ud();
2204     changedir $playground;
2205
2206     my @dfi = dsc_files_info();
2207     foreach my $fi (@dfi) {
2208         my $f = $fi->{Filename};
2209         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2210         my $upper_f = (bpd_abs()."/$f");
2211
2212         printdebug "considering reusing $f: ";
2213
2214         if (link_ltarget "$upper_f,fetch", $f) {
2215             printdebug "linked (using ...,fetch).\n";
2216         } elsif ((printdebug "($!) "),
2217                  $! != ENOENT) {
2218             fail f_ "accessing %s: %s", "$buildproductsdir/$f,fetch", $!;
2219         } elsif (link_ltarget $upper_f, $f) {
2220             printdebug "linked.\n";
2221         } elsif ((printdebug "($!) "),
2222                  $! != ENOENT) {
2223             fail f_ "accessing %s: %s", "$buildproductsdir/$f", $!;
2224         } else {
2225             printdebug "absent.\n";
2226         }
2227
2228         my $refetched;
2229         complete_file_from_dsc('.', $fi, \$refetched)
2230             or next;
2231
2232         printdebug "considering saving $f: ";
2233
2234         if (rename_link_xf 1, $f, $upper_f) {
2235             printdebug "linked.\n";
2236         } elsif ((printdebug "($@) "),
2237                  $! != EEXIST) {
2238             fail f_ "saving %s: %s", "$buildproductsdir/$f", $@;
2239         } elsif (!$refetched) {
2240             printdebug "no need.\n";
2241         } elsif (rename_link_xf 1, $f, "$upper_f,fetch") {
2242             printdebug "linked (using ...,fetch).\n";
2243         } elsif ((printdebug "($@) "),
2244                  $! != EEXIST) {
2245             fail f_ "saving %s: %s", "$buildproductsdir/$f,fetch", $@;
2246         } else {
2247             printdebug "cannot.\n";
2248         }
2249     }
2250
2251     # We unpack and record the orig tarballs first, so that we only
2252     # need disk space for one private copy of the unpacked source.
2253     # But we can't make them into commits until we have the metadata
2254     # from the debian/changelog, so we record the tree objects now and
2255     # make them into commits later.
2256     my @tartrees;
2257     my $upstreamv = upstreamversion $dsc->{version};
2258     my $orig_f_base = srcfn $upstreamv, '';
2259
2260     foreach my $fi (@dfi) {
2261         # We actually import, and record as a commit, every tarball
2262         # (unless there is only one file, in which case there seems
2263         # little point.
2264
2265         my $f = $fi->{Filename};
2266         printdebug "import considering $f ";
2267         (printdebug "only one dfi\n"), next if @dfi == 1;
2268         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2269         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2270         my $compr_ext = $1;
2271
2272         my ($orig_f_part) =
2273             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2274
2275         printdebug "Y ", (join ' ', map { $_//"(none)" }
2276                           $compr_ext, $orig_f_part
2277                          ), "\n";
2278
2279         my $input = new IO::File $f, '<' or die "$f $!";
2280         my $compr_pid;
2281         my @compr_cmd;
2282
2283         if (defined $compr_ext) {
2284             my $cname =
2285                 Dpkg::Compression::compression_guess_from_filename $f;
2286             fail "Dpkg::Compression cannot handle file $f in source package"
2287                 if defined $compr_ext && !defined $cname;
2288             my $compr_proc =
2289                 new Dpkg::Compression::Process compression => $cname;
2290             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2291             my $compr_fh = new IO::Handle;
2292             my $compr_pid = open $compr_fh, "-|" // confess $!;
2293             if (!$compr_pid) {
2294                 open STDIN, "<&", $input or confess $!;
2295                 exec @compr_cmd;
2296                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2297             }
2298             $input = $compr_fh;
2299         }
2300
2301         rmtree "_unpack-tar";
2302         mkdir "_unpack-tar" or confess $!;
2303         my @tarcmd = qw(tar -x -f -
2304                         --no-same-owner --no-same-permissions
2305                         --no-acls --no-xattrs --no-selinux);
2306         my $tar_pid = fork // confess $!;
2307         if (!$tar_pid) {
2308             chdir "_unpack-tar" or confess $!;
2309             open STDIN, "<&", $input or confess $!;
2310             exec @tarcmd;
2311             die f_ "dgit (child): exec %s: %s", $tarcmd[0], $!;
2312         }
2313         $!=0; (waitpid $tar_pid, 0) == $tar_pid or confess $!;
2314         !$? or failedcmd @tarcmd;
2315
2316         close $input or
2317             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2318              : confess $!);
2319         # finally, we have the results in "tarball", but maybe
2320         # with the wrong permissions
2321
2322         runcmd qw(chmod -R +rwX _unpack-tar);
2323         changedir "_unpack-tar";
2324         remove_stray_gits($f);
2325         mktree_in_ud_here();
2326
2327         my ($tree) = git_add_write_tree();
2328         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2329         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2330             $tree = $1;
2331             printdebug "one subtree $1\n";
2332         } else {
2333             printdebug "multiple subtrees\n";
2334         }
2335         changedir "..";
2336         rmtree "_unpack-tar";
2337
2338         my $ent = [ $f, $tree ];
2339         push @tartrees, {
2340             Orig => !!$orig_f_part,
2341             Sort => (!$orig_f_part         ? 2 :
2342                      $orig_f_part =~ m/-/g ? 1 :
2343                                              0),
2344             F => $f,
2345             Tree => $tree,
2346         };
2347     }
2348
2349     @tartrees = sort {
2350         # put any without "_" first (spec is not clear whether files
2351         # are always in the usual order).  Tarballs without "_" are
2352         # the main orig or the debian tarball.
2353         $a->{Sort} <=> $b->{Sort} or
2354         $a->{F}    cmp $b->{F}
2355     } @tartrees;
2356
2357     my $any_orig = grep { $_->{Orig} } @tartrees;
2358
2359     my $dscfn = "$package.dsc";
2360
2361     my $treeimporthow = 'package';
2362
2363     open D, ">", $dscfn or die "$dscfn: $!";
2364     print D $dscdata or die "$dscfn: $!";
2365     close D or die "$dscfn: $!";
2366     my @cmd = qw(dpkg-source);
2367     push @cmd, '--no-check' if $dsc_checked;
2368     if (madformat $dsc->{format}) {
2369         push @cmd, '--skip-patches';
2370         $treeimporthow = 'unpatched';
2371     }
2372     push @cmd, qw(-x --), $dscfn;
2373     runcmd @cmd;
2374
2375     my ($tree,$dir) = mktree_in_ud_from_only_subdir(__ "source package");
2376     if (madformat $dsc->{format}) {
2377         check_for_vendor_patches();
2378     }
2379
2380     my $dappliedtree;
2381     if (madformat $dsc->{format}) {
2382         my @pcmd = qw(dpkg-source --before-build .);
2383         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2384         rmtree '.pc';
2385         $dappliedtree = git_add_write_tree();
2386     }
2387
2388     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2389     my $clogp;
2390     my $r1clogp;
2391
2392     printdebug "import clog search...\n";
2393     parsechangelog_loop \@clogcmd, (__ "package changelog"), sub {
2394         my ($thisstanza, $desc) = @_;
2395         no warnings qw(exiting);
2396
2397         $clogp //= $thisstanza;
2398
2399         printdebug "import clog $thisstanza->{version} $desc...\n";
2400
2401         last if !$any_orig; # we don't need $r1clogp
2402
2403         # We look for the first (most recent) changelog entry whose
2404         # version number is lower than the upstream version of this
2405         # package.  Then the last (least recent) previous changelog
2406         # entry is treated as the one which introduced this upstream
2407         # version and used for the synthetic commits for the upstream
2408         # tarballs.
2409
2410         # One might think that a more sophisticated algorithm would be
2411         # necessary.  But: we do not want to scan the whole changelog
2412         # file.  Stopping when we see an earlier version, which
2413         # necessarily then is an earlier upstream version, is the only
2414         # realistic way to do that.  Then, either the earliest
2415         # changelog entry we have seen so far is indeed the earliest
2416         # upload of this upstream version; or there are only changelog
2417         # entries relating to later upstream versions (which is not
2418         # possible unless the changelog and .dsc disagree about the
2419         # version).  Then it remains to choose between the physically
2420         # last entry in the file, and the one with the lowest version
2421         # number.  If these are not the same, we guess that the
2422         # versions were created in a non-monotonic order rather than
2423         # that the changelog entries have been misordered.
2424
2425         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2426
2427         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2428         $r1clogp = $thisstanza;
2429
2430         printdebug "import clog $r1clogp->{version} becomes r1\n";
2431     };
2432
2433     $clogp or fail __ "package changelog has no entries!";
2434
2435     my $authline = clogp_authline $clogp;
2436     my $changes = getfield $clogp, 'Changes';
2437     $changes =~ s/^\n//; # Changes: \n
2438     my $cversion = getfield $clogp, 'Version';
2439
2440     if (@tartrees) {
2441         $r1clogp //= $clogp; # maybe there's only one entry;
2442         my $r1authline = clogp_authline $r1clogp;
2443         # Strictly, r1authline might now be wrong if it's going to be
2444         # unused because !$any_orig.  Whatever.
2445
2446         printdebug "import tartrees authline   $authline\n";
2447         printdebug "import tartrees r1authline $r1authline\n";
2448
2449         foreach my $tt (@tartrees) {
2450             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2451
2452             my $mbody = f_ "Import %s", $tt->{F};
2453             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2454 tree $tt->{Tree}
2455 author $r1authline
2456 committer $r1authline
2457
2458 $mbody
2459
2460 [dgit import orig $tt->{F}]
2461 END_O
2462 tree $tt->{Tree}
2463 author $authline
2464 committer $authline
2465
2466 $mbody
2467
2468 [dgit import tarball $package $cversion $tt->{F}]
2469 END_T
2470         }
2471     }
2472
2473     printdebug "import main commit\n";
2474
2475     open C, ">../commit.tmp" or confess $!;
2476     print C <<END or confess $!;
2477 tree $tree
2478 END
2479     print C <<END or confess $! foreach @tartrees;
2480 parent $_->{Commit}
2481 END
2482     print C <<END or confess $!;
2483 author $authline
2484 committer $authline
2485
2486 $changes
2487
2488 [dgit import $treeimporthow $package $cversion]
2489 END
2490
2491     close C or confess $!;
2492     my $rawimport_hash = make_commit qw(../commit.tmp);
2493
2494     if (madformat $dsc->{format}) {
2495         printdebug "import apply patches...\n";
2496
2497         # regularise the state of the working tree so that
2498         # the checkout of $rawimport_hash works nicely.
2499         my $dappliedcommit = make_commit_text(<<END);
2500 tree $dappliedtree
2501 author $authline
2502 committer $authline
2503
2504 [dgit dummy commit]
2505 END
2506         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2507
2508         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2509
2510         # We need the answers to be reproducible
2511         my @authline = clogp_authline($clogp);
2512         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2513         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2514         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2515         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2516         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2517         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2518
2519         my $path = $ENV{PATH} or die;
2520
2521         # we use ../../gbp-pq-output, which (given that we are in
2522         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2523         # is .git/dgit.
2524
2525         foreach my $use_absurd (qw(0 1)) {
2526             runcmd @git, qw(checkout -q unpa);
2527             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2528             local $ENV{PATH} = $path;
2529             if ($use_absurd) {
2530                 chomp $@;
2531                 progress "warning: $@";
2532                 $path = "$absurdity:$path";
2533                 progress f_ "%s: trying slow absurd-git-apply...", $us;
2534                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2535                     or $!==ENOENT
2536                     or confess $!;
2537             }
2538             eval {
2539                 die "forbid absurd git-apply\n" if $use_absurd
2540                     && forceing [qw(import-gitapply-no-absurd)];
2541                 die "only absurd git-apply!\n" if !$use_absurd
2542                     && forceing [qw(import-gitapply-absurd)];
2543
2544                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2545                 local $ENV{PATH} = $path                    if $use_absurd;
2546
2547                 my @showcmd = (gbp_pq, qw(import));
2548                 my @realcmd = shell_cmd
2549                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2550                 debugcmd "+",@realcmd;
2551                 if (system @realcmd) {
2552                     die f_ "%s failed: %s\n",
2553                         +(shellquote @showcmd),
2554                         failedcmd_waitstatus();
2555                 }
2556
2557                 my $gapplied = git_rev_parse('HEAD');
2558                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2559                 $gappliedtree eq $dappliedtree or
2560                     fail f_ <<END, $gapplied, $gappliedtree, $dappliedtree;
2561 gbp-pq import and dpkg-source disagree!
2562  gbp-pq import gave commit %s
2563  gbp-pq import gave tree %s
2564  dpkg-source --before-build gave tree %s
2565 END
2566                 $rawimport_hash = $gapplied;
2567             };
2568             last unless $@;
2569         }
2570         if ($@) {
2571             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2572             die $@;
2573         }
2574     }
2575
2576     progress f_ "synthesised git commit from .dsc %s", $cversion;
2577
2578     my $rawimport_mergeinput = {
2579         Commit => $rawimport_hash,
2580         Info => __ "Import of source package",
2581     };
2582     my @output = ($rawimport_mergeinput);
2583
2584     if ($lastpush_mergeinput) {
2585         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2586         my $oversion = getfield $oldclogp, 'Version';
2587         my $vcmp =
2588             version_compare($oversion, $cversion);
2589         if ($vcmp < 0) {
2590             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2591                 { ReverseParents => 1,
2592                   Message => (f_ <<END, $package, $cversion, $csuite) });
2593 Record %s (%s) in archive suite %s
2594 END
2595         } elsif ($vcmp > 0) {
2596             print STDERR f_ <<END, $cversion, $oversion,
2597
2598 Version actually in archive:   %s (older)
2599 Last version pushed with dgit: %s (newer or same)
2600 %s
2601 END
2602                 __ $later_warning_msg or confess $!;
2603             @output = $lastpush_mergeinput;
2604         } else {
2605             # Same version.  Use what's in the server git branch,
2606             # discarding our own import.  (This could happen if the
2607             # server automatically imports all packages into git.)
2608             @output = $lastpush_mergeinput;
2609         }
2610     }
2611     changedir $maindir;
2612     rmtree $playground;
2613     return @output;
2614 }
2615
2616 sub complete_file_from_dsc ($$;$) {
2617     our ($dstdir, $fi, $refetched) = @_;
2618     # Ensures that we have, in $dstdir, the file $fi, with the correct
2619     # contents.  (Downloading it from alongside $dscurl if necessary.)
2620     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2621     # and will set $$refetched=1 if it did so (or tried to).
2622
2623     my $f = $fi->{Filename};
2624     my $tf = "$dstdir/$f";
2625     my $downloaded = 0;
2626
2627     my $got;
2628     my $checkhash = sub {
2629         open F, "<", "$tf" or die "$tf: $!";
2630         $fi->{Digester}->reset();
2631         $fi->{Digester}->addfile(*F);
2632         F->error and confess $!;
2633         $got = $fi->{Digester}->hexdigest();
2634         return $got eq $fi->{Hash};
2635     };
2636
2637     if (stat_exists $tf) {
2638         if ($checkhash->()) {
2639             progress f_ "using existing %s", $f;
2640             return 1;
2641         }
2642         if (!$refetched) {
2643             fail f_ "file %s has hash %s but .dsc demands hash %s".
2644                     " (perhaps you should delete this file?)",
2645                     $f, $got, $fi->{Hash};
2646         }
2647         progress f_ "need to fetch correct version of %s", $f;
2648         unlink $tf or die "$tf $!";
2649         $$refetched = 1;
2650     } else {
2651         printdebug "$tf does not exist, need to fetch\n";
2652     }
2653
2654     my $furl = $dscurl;
2655     $furl =~ s{/[^/]+$}{};
2656     $furl .= "/$f";
2657     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2658     die "$f ?" if $f =~ m#/#;
2659     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2660     return 0 if !act_local();
2661
2662     $checkhash->() or
2663         fail f_ "file %s has hash %s but .dsc demands hash %s".
2664                 " (got wrong file from archive!)",
2665                 $f, $got, $fi->{Hash};
2666
2667     return 1;
2668 }
2669
2670 sub ensure_we_have_orig () {
2671     my @dfi = dsc_files_info();
2672     foreach my $fi (@dfi) {
2673         my $f = $fi->{Filename};
2674         next unless is_orig_file_in_dsc($f, \@dfi);
2675         complete_file_from_dsc($buildproductsdir, $fi)
2676             or next;
2677     }
2678 }
2679
2680 #---------- git fetch ----------
2681
2682 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2683 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2684
2685 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2686 # locally fetched refs because they have unhelpful names and clutter
2687 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2688 # whether we have made another local ref which refers to this object).
2689 #
2690 # (If we deleted them unconditionally, then we might end up
2691 # re-fetching the same git objects each time dgit fetch was run.)
2692 #
2693 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2694 # in git_fetch_us to fetch the refs in question, and possibly a call
2695 # to lrfetchref_used.
2696
2697 our (%lrfetchrefs_f, %lrfetchrefs_d);
2698 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2699
2700 sub lrfetchref_used ($) {
2701     my ($fullrefname) = @_;
2702     my $objid = $lrfetchrefs_f{$fullrefname};
2703     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2704 }
2705
2706 sub git_lrfetch_sane {
2707     my ($url, $supplementary, @specs) = @_;
2708     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2709     # at least as regards @specs.  Also leave the results in
2710     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2711     # able to clean these up.
2712     #
2713     # With $supplementary==1, @specs must not contain wildcards
2714     # and we add to our previous fetches (non-atomically).
2715
2716     # This is rather miserable:
2717     # When git fetch --prune is passed a fetchspec ending with a *,
2718     # it does a plausible thing.  If there is no * then:
2719     # - it matches subpaths too, even if the supplied refspec
2720     #   starts refs, and behaves completely madly if the source
2721     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2722     # - if there is no matching remote ref, it bombs out the whole
2723     #   fetch.
2724     # We want to fetch a fixed ref, and we don't know in advance
2725     # if it exists, so this is not suitable.
2726     #
2727     # Our workaround is to use git ls-remote.  git ls-remote has its
2728     # own qairks.  Notably, it has the absurd multi-tail-matching
2729     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2730     # refs/refs/foo etc.
2731     #
2732     # Also, we want an idempotent snapshot, but we have to make two
2733     # calls to the remote: one to git ls-remote and to git fetch.  The
2734     # solution is use git ls-remote to obtain a target state, and
2735     # git fetch to try to generate it.  If we don't manage to generate
2736     # the target state, we try again.
2737
2738     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2739
2740     my $specre = join '|', map {
2741         my $x = $_;
2742         $x =~ s/\W/\\$&/g;
2743         my $wildcard = $x =~ s/\\\*$/.*/;
2744         die if $wildcard && $supplementary;
2745         "(?:refs/$x)";
2746     } @specs;
2747     printdebug "git_lrfetch_sane specre=$specre\n";
2748     my $wanted_rref = sub {
2749         local ($_) = @_;
2750         return m/^(?:$specre)$/;
2751     };
2752
2753     my $fetch_iteration = 0;
2754     FETCH_ITERATION:
2755     for (;;) {
2756         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2757         if (++$fetch_iteration > 10) {
2758             fail __ "too many iterations trying to get sane fetch!";
2759         }
2760
2761         my @look = map { "refs/$_" } @specs;
2762         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2763         debugcmd "|",@lcmd;
2764
2765         my %wantr;
2766         open GITLS, "-|", @lcmd or confess $!;
2767         while (<GITLS>) {
2768             printdebug "=> ", $_;
2769             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2770             my ($objid,$rrefname) = ($1,$2);
2771             if (!$wanted_rref->($rrefname)) {
2772                 print STDERR f_ <<END, "@look", $rrefname;
2773 warning: git ls-remote %s reported %s; this is silly, ignoring it.
2774 END
2775                 next;
2776             }
2777             $wantr{$rrefname} = $objid;
2778         }
2779         $!=0; $?=0;
2780         close GITLS or failedcmd @lcmd;
2781
2782         # OK, now %want is exactly what we want for refs in @specs
2783         my @fspecs = map {
2784             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2785             "+refs/$_:".lrfetchrefs."/$_";
2786         } @specs;
2787
2788         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2789
2790         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2791         runcmd_ordryrun_local @fcmd if @fspecs;
2792
2793         if (!$supplementary) {
2794             %lrfetchrefs_f = ();
2795         }
2796         my %objgot;
2797
2798         git_for_each_ref(lrfetchrefs, sub {
2799             my ($objid,$objtype,$lrefname,$reftail) = @_;
2800             $lrfetchrefs_f{$lrefname} = $objid;
2801             $objgot{$objid} = 1;
2802         });
2803
2804         if ($supplementary) {
2805             last;
2806         }
2807
2808         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2809             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2810             if (!exists $wantr{$rrefname}) {
2811                 if ($wanted_rref->($rrefname)) {
2812                     printdebug <<END;
2813 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2814 END
2815                 } else {
2816                     print STDERR f_ <<END, "@fspecs", $lrefname
2817 warning: git fetch %s created %s; this is silly, deleting it.
2818 END
2819                 }
2820                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2821                 delete $lrfetchrefs_f{$lrefname};
2822                 next;
2823             }
2824         }
2825         foreach my $rrefname (sort keys %wantr) {
2826             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2827             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2828             my $want = $wantr{$rrefname};
2829             next if $got eq $want;
2830             if (!defined $objgot{$want}) {
2831                 fail __ <<END unless act_local();
2832 --dry-run specified but we actually wanted the results of git fetch,
2833 so this is not going to work.  Try running dgit fetch first,
2834 or using --damp-run instead of --dry-run.
2835 END
2836                 print STDERR f_ <<END, $lrefname, $want;
2837 warning: git ls-remote suggests we want %s
2838 warning:  and it should refer to %s
2839 warning:  but git fetch didn't fetch that object to any relevant ref.
2840 warning:  This may be due to a race with someone updating the server.
2841 warning:  Will try again...
2842 END
2843                 next FETCH_ITERATION;
2844             }
2845             printdebug <<END;
2846 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2847 END
2848             runcmd_ordryrun_local @git, qw(update-ref -m),
2849                 "dgit fetch git fetch fixup", $lrefname, $want;
2850             $lrfetchrefs_f{$lrefname} = $want;
2851         }
2852         last;
2853     }
2854
2855     if (defined $csuite) {
2856         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2857         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2858             my ($objid,$objtype,$lrefname,$reftail) = @_;
2859             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2860             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2861         });
2862     }
2863
2864     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2865         Dumper(\%lrfetchrefs_f);
2866 }
2867
2868 sub git_fetch_us () {
2869     # Want to fetch only what we are going to use, unless
2870     # deliberately-not-ff, in which case we must fetch everything.
2871
2872     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2873         map { "tags/$_" }
2874         (quiltmode_splitbrain
2875          ? (map { $_->('*',access_nomdistro) }
2876             \&debiantag_new, \&debiantag_maintview)
2877          : debiantags('*',access_nomdistro));
2878     push @specs, server_branch($csuite);
2879     push @specs, $rewritemap;
2880     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2881
2882     my $url = access_giturl();
2883     git_lrfetch_sane $url, 0, @specs;
2884
2885     my %here;
2886     my @tagpats = debiantags('*',access_nomdistro);
2887
2888     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2889         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2890         printdebug "currently $fullrefname=$objid\n";
2891         $here{$fullrefname} = $objid;
2892     });
2893     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2894         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2895         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2896         printdebug "offered $lref=$objid\n";
2897         if (!defined $here{$lref}) {
2898             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2899             runcmd_ordryrun_local @upd;
2900             lrfetchref_used $fullrefname;
2901         } elsif ($here{$lref} eq $objid) {
2902             lrfetchref_used $fullrefname;
2903         } else {
2904             print STDERR f_ "Not updating %s from %s to %s.\n",
2905                             $lref, $here{$lref}, $objid;
2906         }
2907     });
2908 }
2909
2910 #---------- dsc and archive handling ----------
2911
2912 sub mergeinfo_getclogp ($) {
2913     # Ensures thit $mi->{Clogp} exists and returns it
2914     my ($mi) = @_;
2915     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2916 }
2917
2918 sub mergeinfo_version ($) {
2919     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2920 }
2921
2922 sub fetch_from_archive_record_1 ($) {
2923     my ($hash) = @_;
2924     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
2925     cmdoutput @git, qw(log -n2), $hash;
2926     # ... gives git a chance to complain if our commit is malformed
2927 }
2928
2929 sub fetch_from_archive_record_2 ($) {
2930     my ($hash) = @_;
2931     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
2932     if (act_local()) {
2933         cmdoutput @upd_cmd;
2934     } else {
2935         dryrun_report @upd_cmd;
2936     }
2937 }
2938
2939 sub parse_dsc_field_def_dsc_distro () {
2940     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2941                            dgit.default.distro);
2942 }
2943
2944 sub parse_dsc_field ($$) {
2945     my ($dsc, $what) = @_;
2946     my $f;
2947     foreach my $field (@ourdscfield) {
2948         $f = $dsc->{$field};
2949         last if defined $f;
2950     }
2951
2952     if (!defined $f) {
2953         progress f_ "%s: NO git hash", $what;
2954         parse_dsc_field_def_dsc_distro();
2955     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2956              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2957         progress f_ "%s: specified git info (%s)", $what, $dsc_distro;
2958         $dsc_hint_tag = [ $dsc_hint_tag ];
2959     } elsif ($f =~ m/^\w+\s*$/) {
2960         $dsc_hash = $&;
2961         parse_dsc_field_def_dsc_distro();
2962         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2963                           $dsc_distro ];
2964         progress f_ "%s: specified git hash", $what;
2965     } else {
2966         fail f_ "%s: invalid Dgit info", $what;
2967     }
2968 }
2969
2970 sub resolve_dsc_field_commit ($$) {
2971     my ($already_distro, $already_mapref) = @_;
2972
2973     return unless defined $dsc_hash;
2974
2975     my $mapref =
2976         defined $already_mapref &&
2977         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2978         ? $already_mapref : undef;
2979
2980     my $do_fetch;
2981     $do_fetch = sub {
2982         my ($what, @fetch) = @_;
2983
2984         local $idistro = $dsc_distro;
2985         my $lrf = lrfetchrefs;
2986
2987         if (!$chase_dsc_distro) {
2988             progress f_ "not chasing .dsc distro %s: not fetching %s",
2989                         $dsc_distro, $what;
2990             return 0;
2991         }
2992
2993         progress f_ ".dsc names distro %s: fetching %s", $dsc_distro, $what;
2994
2995         my $url = access_giturl();
2996         if (!defined $url) {
2997             defined $dsc_hint_url or fail f_ <<END, $dsc_distro;
2998 .dsc Dgit metadata is in context of distro %s
2999 for which we have no configured url and .dsc provides no hint
3000 END
3001             my $proto =
3002                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
3003                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
3004             parse_cfg_bool "dsc-url-proto-ok", 'false',
3005                 cfg("dgit.dsc-url-proto-ok.$proto",
3006                     "dgit.default.dsc-url-proto-ok")
3007                 or fail f_ <<END, $dsc_distro, $proto;
3008 .dsc Dgit metadata is in context of distro %s
3009 for which we have no configured url;
3010 .dsc provides hinted url with protocol %s which is unsafe.
3011 (can be overridden by config - consult documentation)
3012 END
3013             $url = $dsc_hint_url;
3014         }
3015
3016         git_lrfetch_sane $url, 1, @fetch;
3017
3018         return $lrf;
3019     };
3020
3021     my $rewrite_enable = do {
3022         local $idistro = $dsc_distro;
3023         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
3024     };
3025
3026     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
3027         if (!defined $mapref) {
3028             my $lrf = $do_fetch->((__ "rewrite map"), $rewritemap) or return;
3029             $mapref = $lrf.'/'.$rewritemap;
3030         }
3031         my $rewritemapdata = git_cat_file $mapref.':map';
3032         if (defined $rewritemapdata
3033             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
3034             progress __
3035                 "server's git history rewrite map contains a relevant entry!";
3036
3037             $dsc_hash = $1;
3038             if (defined $dsc_hash) {
3039                 progress __ "using rewritten git hash in place of .dsc value";
3040             } else {
3041                 progress __ "server data says .dsc hash is to be disregarded";
3042             }
3043         }
3044     }
3045
3046     if (!defined git_cat_file $dsc_hash) {
3047         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
3048         my $lrf = $do_fetch->((__ "additional commits"), @tags) &&
3049             defined git_cat_file $dsc_hash
3050             or fail f_ <<END, $dsc_hash;
3051 .dsc Dgit metadata requires commit %s
3052 but we could not obtain that object anywhere.
3053 END
3054         foreach my $t (@tags) {
3055             my $fullrefname = $lrf.'/'.$t;
3056 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
3057             next unless $lrfetchrefs_f{$fullrefname};
3058             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
3059             lrfetchref_used $fullrefname;
3060         }
3061     }
3062 }
3063
3064 sub fetch_from_archive () {
3065     ensure_setup_existing_tree();
3066
3067     # Ensures that lrref() is what is actually in the archive, one way
3068     # or another, according to us - ie this client's
3069     # appropritaely-updated archive view.  Also returns the commit id.
3070     # If there is nothing in the archive, leaves lrref alone and
3071     # returns undef.  git_fetch_us must have already been called.
3072     get_archive_dsc();
3073
3074     if ($dsc) {
3075         parse_dsc_field($dsc, __ 'last upload to archive');
3076         resolve_dsc_field_commit access_basedistro,
3077             lrfetchrefs."/".$rewritemap
3078     } else {
3079         progress __ "no version available from the archive";
3080     }
3081
3082     # If the archive's .dsc has a Dgit field, there are three
3083     # relevant git commitids we need to choose between and/or merge
3084     # together:
3085     #   1. $dsc_hash: the Dgit field from the archive
3086     #   2. $lastpush_hash: the suite branch on the dgit git server
3087     #   3. $lastfetch_hash: our local tracking brach for the suite
3088     #
3089     # These may all be distinct and need not be in any fast forward
3090     # relationship:
3091     #
3092     # If the dsc was pushed to this suite, then the server suite
3093     # branch will have been updated; but it might have been pushed to
3094     # a different suite and copied by the archive.  Conversely a more
3095     # recent version may have been pushed with dgit but not appeared
3096     # in the archive (yet).
3097     #
3098     # $lastfetch_hash may be awkward because archive imports
3099     # (particularly, imports of Dgit-less .dscs) are performed only as
3100     # needed on individual clients, so different clients may perform a
3101     # different subset of them - and these imports are only made
3102     # public during push.  So $lastfetch_hash may represent a set of
3103     # imports different to a subsequent upload by a different dgit
3104     # client.
3105     #
3106     # Our approach is as follows:
3107     #
3108     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3109     # descendant of $dsc_hash, then it was pushed by a dgit user who
3110     # had based their work on $dsc_hash, so we should prefer it.
3111     # Otherwise, $dsc_hash was installed into this suite in the
3112     # archive other than by a dgit push, and (necessarily) after the
3113     # last dgit push into that suite (since a dgit push would have
3114     # been descended from the dgit server git branch); thus, in that
3115     # case, we prefer the archive's version (and produce a
3116     # pseudo-merge to overwrite the dgit server git branch).
3117     #
3118     # (If there is no Dgit field in the archive's .dsc then
3119     # generate_commit_from_dsc uses the version numbers to decide
3120     # whether the suite branch or the archive is newer.  If the suite
3121     # branch is newer it ignores the archive's .dsc; otherwise it
3122     # generates an import of the .dsc, and produces a pseudo-merge to
3123     # overwrite the suite branch with the archive contents.)
3124     #
3125     # The outcome of that part of the algorithm is the `public view',
3126     # and is same for all dgit clients: it does not depend on any
3127     # unpublished history in the local tracking branch.
3128     #
3129     # As between the public view and the local tracking branch: The
3130     # local tracking branch is only updated by dgit fetch, and
3131     # whenever dgit fetch runs it includes the public view in the
3132     # local tracking branch.  Therefore if the public view is not
3133     # descended from the local tracking branch, the local tracking
3134     # branch must contain history which was imported from the archive
3135     # but never pushed; and, its tip is now out of date.  So, we make
3136     # a pseudo-merge to overwrite the old imports and stitch the old
3137     # history in.
3138     #
3139     # Finally: we do not necessarily reify the public view (as
3140     # described above).  This is so that we do not end up stacking two
3141     # pseudo-merges.  So what we actually do is figure out the inputs
3142     # to any public view pseudo-merge and put them in @mergeinputs.
3143
3144     my @mergeinputs;
3145     # $mergeinputs[]{Commit}
3146     # $mergeinputs[]{Info}
3147     # $mergeinputs[0] is the one whose tree we use
3148     # @mergeinputs is in the order we use in the actual commit)
3149     #
3150     # Also:
3151     # $mergeinputs[]{Message} is a commit message to use
3152     # $mergeinputs[]{ReverseParents} if def specifies that parent
3153     #                                list should be in opposite order
3154     # Such an entry has no Commit or Info.  It applies only when found
3155     # in the last entry.  (This ugliness is to support making
3156     # identical imports to previous dgit versions.)
3157
3158     my $lastpush_hash = git_get_ref(lrfetchref());
3159     printdebug "previous reference hash=$lastpush_hash\n";
3160     $lastpush_mergeinput = $lastpush_hash && {
3161         Commit => $lastpush_hash,
3162         Info => (__ "dgit suite branch on dgit git server"),
3163     };
3164
3165     my $lastfetch_hash = git_get_ref(lrref());
3166     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3167     my $lastfetch_mergeinput = $lastfetch_hash && {
3168         Commit => $lastfetch_hash,
3169         Info => (__ "dgit client's archive history view"),
3170     };
3171
3172     my $dsc_mergeinput = $dsc_hash && {
3173         Commit => $dsc_hash,
3174         Info => (__ "Dgit field in .dsc from archive"),
3175     };
3176
3177     my $cwd = getcwd();
3178     my $del_lrfetchrefs = sub {
3179         changedir $cwd;
3180         my $gur;
3181         printdebug "del_lrfetchrefs...\n";
3182         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3183             my $objid = $lrfetchrefs_d{$fullrefname};
3184             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3185             if (!$gur) {
3186                 $gur ||= new IO::Handle;
3187                 open $gur, "|-", qw(git update-ref --stdin) or confess $!;
3188             }
3189             printf $gur "delete %s %s\n", $fullrefname, $objid;
3190         }
3191         if ($gur) {
3192             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3193         }
3194     };
3195
3196     if (defined $dsc_hash) {
3197         ensure_we_have_orig();
3198         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3199             @mergeinputs = $dsc_mergeinput
3200         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3201             print STDERR f_ <<END, $dsc_hash, $lastpush_hash,
3202
3203 Git commit in archive is behind the last version allegedly pushed/uploaded.
3204 Commit referred to by archive: %s
3205 Last version pushed with dgit: %s
3206 %s
3207 END
3208                 __ $later_warning_msg or confess $!;
3209             @mergeinputs = ($lastpush_mergeinput);
3210         } else {
3211             # Archive has .dsc which is not a descendant of the last dgit
3212             # push.  This can happen if the archive moves .dscs about.
3213             # Just follow its lead.
3214             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3215                 progress __ "archive .dsc names newer git commit";
3216                 @mergeinputs = ($dsc_mergeinput);
3217             } else {
3218                 progress __ "archive .dsc names other git commit, fixing up";
3219                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3220             }
3221         }
3222     } elsif ($dsc) {
3223         @mergeinputs = generate_commits_from_dsc();
3224         # We have just done an import.  Now, our import algorithm might
3225         # have been improved.  But even so we do not want to generate
3226         # a new different import of the same package.  So if the
3227         # version numbers are the same, just use our existing version.
3228         # If the version numbers are different, the archive has changed
3229         # (perhaps, rewound).
3230         if ($lastfetch_mergeinput &&
3231             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3232                               (mergeinfo_version $mergeinputs[0]) )) {
3233             @mergeinputs = ($lastfetch_mergeinput);
3234         }
3235     } elsif ($lastpush_hash) {
3236         # only in git, not in the archive yet
3237         @mergeinputs = ($lastpush_mergeinput);
3238         print STDERR f_ <<END,
3239
3240 Package not found in the archive, but has allegedly been pushed using dgit.
3241 %s
3242 END
3243             __ $later_warning_msg or confess $!;
3244     } else {
3245         printdebug "nothing found!\n";
3246         if (defined $skew_warning_vsn) {
3247             print STDERR f_ <<END, $skew_warning_vsn or confess $!;
3248
3249 Warning: relevant archive skew detected.
3250 Archive allegedly contains %s
3251 But we were not able to obtain any version from the archive or git.
3252
3253 END
3254         }
3255         unshift @end, $del_lrfetchrefs;
3256         return undef;
3257     }
3258
3259     if ($lastfetch_hash &&
3260         !grep {
3261             my $h = $_->{Commit};
3262             $h and is_fast_fwd($lastfetch_hash, $h);
3263             # If true, one of the existing parents of this commit
3264             # is a descendant of the $lastfetch_hash, so we'll
3265             # be ff from that automatically.
3266         } @mergeinputs
3267         ) {
3268         # Otherwise:
3269         push @mergeinputs, $lastfetch_mergeinput;
3270     }
3271
3272     printdebug "fetch mergeinfos:\n";
3273     foreach my $mi (@mergeinputs) {
3274         if ($mi->{Info}) {
3275             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3276         } else {
3277             printdebug sprintf " ReverseParents=%d Message=%s",
3278                 $mi->{ReverseParents}, $mi->{Message};
3279         }
3280     }
3281
3282     my $compat_info= pop @mergeinputs
3283         if $mergeinputs[$#mergeinputs]{Message};
3284
3285     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3286
3287     my $hash;
3288     if (@mergeinputs > 1) {
3289         # here we go, then:
3290         my $tree_commit = $mergeinputs[0]{Commit};
3291
3292         my $tree = get_tree_of_commit $tree_commit;;
3293
3294         # We use the changelog author of the package in question the
3295         # author of this pseudo-merge.  This is (roughly) correct if
3296         # this commit is simply representing aa non-dgit upload.
3297         # (Roughly because it does not record sponsorship - but we
3298         # don't have sponsorship info because that's in the .changes,
3299         # which isn't in the archivw.)
3300         #
3301         # But, it might be that we are representing archive history
3302         # updates (including in-archive copies).  These are not really
3303         # the responsibility of the person who created the .dsc, but
3304         # there is no-one whose name we should better use.  (The
3305         # author of the .dsc-named commit is clearly worse.)
3306
3307         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3308         my $author = clogp_authline $useclogp;
3309         my $cversion = getfield $useclogp, 'Version';
3310
3311         my $mcf = dgit_privdir()."/mergecommit";
3312         open MC, ">", $mcf or die "$mcf $!";
3313         print MC <<END or confess $!;
3314 tree $tree
3315 END
3316
3317         my @parents = grep { $_->{Commit} } @mergeinputs;
3318         @parents = reverse @parents if $compat_info->{ReverseParents};
3319         print MC <<END or confess $! foreach @parents;
3320 parent $_->{Commit}
3321 END
3322
3323         print MC <<END or confess $!;
3324 author $author
3325 committer $author
3326
3327 END
3328
3329         if (defined $compat_info->{Message}) {
3330             print MC $compat_info->{Message} or confess $!;
3331         } else {
3332             print MC f_ <<END, $package, $cversion, $csuite or confess $!;
3333 Record %s (%s) in archive suite %s
3334
3335 Record that
3336 END
3337             my $message_add_info = sub {
3338                 my ($mi) = (@_);
3339                 my $mversion = mergeinfo_version $mi;
3340                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3341                     or confess $!;
3342             };
3343
3344             $message_add_info->($mergeinputs[0]);
3345             print MC __ <<END or confess $!;
3346 should be treated as descended from
3347 END
3348             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3349         }
3350
3351         close MC or confess $!;
3352         $hash = make_commit $mcf;
3353     } else {
3354         $hash = $mergeinputs[0]{Commit};
3355     }
3356     printdebug "fetch hash=$hash\n";
3357
3358     my $chkff = sub {
3359         my ($lasth, $what) = @_;
3360         return unless $lasth;
3361         confess "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3362     };
3363
3364     $chkff->($lastpush_hash, __ 'dgit repo server tip (last push)')
3365         if $lastpush_hash;
3366     $chkff->($lastfetch_hash, __ 'local tracking tip (last fetch)');
3367
3368     fetch_from_archive_record_1($hash);
3369
3370     if (defined $skew_warning_vsn) {
3371         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3372         my $gotclogp = commit_getclogp($hash);
3373         my $got_vsn = getfield $gotclogp, 'Version';
3374         printdebug "SKEW CHECK GOT $got_vsn\n";
3375         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3376             print STDERR f_ <<END, $skew_warning_vsn, $got_vsn or confess $!;
3377
3378 Warning: archive skew detected.  Using the available version:
3379 Archive allegedly contains    %s
3380 We were able to obtain only   %s
3381
3382 END
3383         }
3384     }
3385
3386     if ($lastfetch_hash ne $hash) {
3387         fetch_from_archive_record_2($hash);
3388     }
3389
3390     lrfetchref_used lrfetchref();
3391
3392     check_gitattrs($hash, __ "fetched source tree");
3393
3394     unshift @end, $del_lrfetchrefs;
3395     return $hash;
3396 }
3397
3398 sub set_local_git_config ($$) {
3399     my ($k, $v) = @_;
3400     runcmd @git, qw(config), $k, $v;
3401 }
3402
3403 sub setup_mergechangelogs (;$) {
3404     my ($always) = @_;
3405     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3406
3407     my $driver = 'dpkg-mergechangelogs';
3408     my $cb = "merge.$driver";
3409     confess unless defined $maindir;
3410     my $attrs = "$maindir_gitcommon/info/attributes";
3411     ensuredir "$maindir_gitcommon/info";
3412
3413     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3414     if (!open ATTRS, "<", $attrs) {
3415         $!==ENOENT or die "$attrs: $!";
3416     } else {
3417         while (<ATTRS>) {
3418             chomp;
3419             next if m{^debian/changelog\s};
3420             print NATTRS $_, "\n" or confess $!;
3421         }
3422         ATTRS->error and confess $!;
3423         close ATTRS;
3424     }
3425     print NATTRS "debian/changelog merge=$driver\n" or confess $!;
3426     close NATTRS;
3427
3428     set_local_git_config "$cb.name", __ 'debian/changelog merge driver';
3429     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3430
3431     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3432 }
3433
3434 sub setup_useremail (;$) {
3435     my ($always) = @_;
3436     return unless $always || access_cfg_bool(1, 'setup-useremail');
3437
3438     my $setup = sub {
3439         my ($k, $envvar) = @_;
3440         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3441         return unless defined $v;
3442         set_local_git_config "user.$k", $v;
3443     };
3444
3445     $setup->('email', 'DEBEMAIL');
3446     $setup->('name', 'DEBFULLNAME');
3447 }
3448
3449 sub ensure_setup_existing_tree () {
3450     my $k = "remote.$remotename.skipdefaultupdate";
3451     my $c = git_get_config $k;
3452     return if defined $c;
3453     set_local_git_config $k, 'true';
3454 }
3455
3456 sub open_main_gitattrs () {
3457     confess 'internal error no maindir' unless defined $maindir;
3458     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3459         or $!==ENOENT
3460         or die "open $maindir_gitcommon/info/attributes: $!";
3461     return $gai;
3462 }
3463
3464 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3465
3466 sub is_gitattrs_setup () {
3467     # return values:
3468     #  trueish
3469     #     1: gitattributes set up and should be left alone
3470     #  falseish
3471     #     0: there is a dgit-defuse-attrs but it needs fixing
3472     #     undef: there is none
3473     my $gai = open_main_gitattrs();
3474     return 0 unless $gai;
3475     while (<$gai>) {
3476         next unless m{$gitattrs_ourmacro_re};
3477         return 1 if m{\s-working-tree-encoding\s};
3478         printdebug "is_gitattrs_setup: found old macro\n";
3479         return 0;
3480     }
3481     $gai->error and confess $!;
3482     printdebug "is_gitattrs_setup: found nothing\n";
3483     return undef;
3484 }
3485
3486 sub setup_gitattrs (;$) {
3487     my ($always) = @_;
3488     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3489
3490     my $already = is_gitattrs_setup();
3491     if ($already) {
3492         progress __ <<END;
3493 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3494  not doing further gitattributes setup
3495 END
3496         return;
3497     }
3498     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3499     my $af = "$maindir_gitcommon/info/attributes";
3500     ensuredir "$maindir_gitcommon/info";
3501
3502     open GAO, "> $af.new" or confess $!;
3503     print GAO <<END, __ <<ENDT or confess $! unless defined $already;
3504 *       dgit-defuse-attrs
3505 $new
3506 END
3507 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3508 ENDT
3509     my $gai = open_main_gitattrs();
3510     if ($gai) {
3511         while (<$gai>) {
3512             if (m{$gitattrs_ourmacro_re}) {
3513                 die unless defined $already;
3514                 $_ = $new;
3515             }
3516             chomp;
3517             print GAO $_, "\n" or confess $!;
3518         }
3519         $gai->error and confess $!;
3520     }
3521     close GAO or confess $!;
3522     rename "$af.new", "$af" or fail f_ "install %s: %s", $af, $!;
3523 }
3524
3525 sub setup_new_tree () {
3526     setup_mergechangelogs();
3527     setup_useremail();
3528     setup_gitattrs();
3529 }
3530
3531 sub check_gitattrs ($$) {
3532     my ($treeish, $what) = @_;
3533
3534     return if is_gitattrs_setup;
3535
3536     local $/="\0";
3537     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3538     debugcmd "|",@cmd;
3539     my $gafl = new IO::File;
3540     open $gafl, "-|", @cmd or confess $!;
3541     while (<$gafl>) {
3542         chomp or die;
3543         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3544         next if $1 == 0;
3545         next unless m{(?:^|/)\.gitattributes$};
3546
3547         # oh dear, found one
3548         print STDERR f_ <<END, $what;
3549 dgit: warning: %s contains .gitattributes
3550 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3551 END
3552         close $gafl;
3553         return;
3554     }
3555     # tree contains no .gitattributes files
3556     $?=0; $!=0; close $gafl or failedcmd @cmd;
3557 }
3558
3559
3560 sub multisuite_suite_child ($$$) {
3561     my ($tsuite, $mergeinputs, $fn) = @_;
3562     # in child, sets things up, calls $fn->(), and returns undef
3563     # in parent, returns canonical suite name for $tsuite
3564     my $canonsuitefh = IO::File::new_tmpfile;
3565     my $pid = fork // confess $!;
3566     if (!$pid) {
3567         forkcheck_setup();
3568         $isuite = $tsuite;
3569         $us .= " [$isuite]";
3570         $debugprefix .= " ";
3571         progress f_ "fetching %s...", $tsuite;
3572         canonicalise_suite();
3573         print $canonsuitefh $csuite, "\n" or confess $!;
3574         close $canonsuitefh or confess $!;
3575         $fn->();
3576         return undef;
3577     }
3578     waitpid $pid,0 == $pid or confess $!;
3579     fail f_ "failed to obtain %s: %s", $tsuite, waitstatusmsg()
3580         if $? && $?!=256*4;
3581     seek $canonsuitefh,0,0 or confess $!;
3582     local $csuite = <$canonsuitefh>;
3583     confess $! unless defined $csuite && chomp $csuite;
3584     if ($? == 256*4) {
3585         printdebug "multisuite $tsuite missing\n";
3586         return $csuite;
3587     }
3588     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3589     push @$mergeinputs, {
3590         Ref => lrref,
3591         Info => $csuite,
3592     };
3593     return $csuite;
3594 }
3595
3596 sub fork_for_multisuite ($) {
3597     my ($before_fetch_merge) = @_;
3598     # if nothing unusual, just returns ''
3599     #
3600     # if multisuite:
3601     # returns 0 to caller in child, to do first of the specified suites
3602     # in child, $csuite is not yet set
3603     #
3604     # returns 1 to caller in parent, to finish up anything needed after
3605     # in parent, $csuite is set to canonicalised portmanteau
3606
3607     my $org_isuite = $isuite;
3608     my @suites = split /\,/, $isuite;
3609     return '' unless @suites > 1;
3610     printdebug "fork_for_multisuite: @suites\n";
3611
3612     my @mergeinputs;
3613
3614     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3615                                             sub { });
3616     return 0 unless defined $cbasesuite;
3617
3618     fail f_ "package %s missing in (base suite) %s", $package, $cbasesuite
3619         unless @mergeinputs;
3620
3621     my @csuites = ($cbasesuite);
3622
3623     $before_fetch_merge->();
3624
3625     foreach my $tsuite (@suites[1..$#suites]) {
3626         $tsuite =~ s/^-/$cbasesuite-/;
3627         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3628                                                sub {
3629             @end = ();
3630             fetch_one();
3631             finish 0;
3632         });
3633
3634         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3635         push @csuites, $csubsuite;
3636     }
3637
3638     foreach my $mi (@mergeinputs) {
3639         my $ref = git_get_ref $mi->{Ref};
3640         die "$mi->{Ref} ?" unless length $ref;
3641         $mi->{Commit} = $ref;
3642     }
3643
3644     $csuite = join ",", @csuites;
3645
3646     my $previous = git_get_ref lrref;
3647     if ($previous) {
3648         unshift @mergeinputs, {
3649             Commit => $previous,
3650             Info => (__ "local combined tracking branch"),
3651             Warning => (__
3652  "archive seems to have rewound: local tracking branch is ahead!"),
3653         };
3654     }
3655
3656     foreach my $ix (0..$#mergeinputs) {
3657         $mergeinputs[$ix]{Index} = $ix;
3658     }
3659
3660     @mergeinputs = sort {
3661         -version_compare(mergeinfo_version $a,
3662                          mergeinfo_version $b) # highest version first
3663             or
3664         $a->{Index} <=> $b->{Index}; # earliest in spec first
3665     } @mergeinputs;
3666
3667     my @needed;
3668
3669   NEEDED:
3670     foreach my $mi (@mergeinputs) {
3671         printdebug "multisuite merge check $mi->{Info}\n";
3672         foreach my $previous (@needed) {
3673             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3674             printdebug "multisuite merge un-needed $previous->{Info}\n";
3675             next NEEDED;
3676         }
3677         push @needed, $mi;
3678         printdebug "multisuite merge this-needed\n";
3679         $mi->{Character} = '+';
3680     }
3681
3682     $needed[0]{Character} = '*';
3683
3684     my $output = $needed[0]{Commit};
3685
3686     if (@needed > 1) {
3687         printdebug "multisuite merge nontrivial\n";
3688         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3689
3690         my $commit = "tree $tree\n";
3691         my $msg = f_ "Combine archive branches %s [dgit]\n\n".
3692                      "Input branches:\n",
3693                      $csuite;
3694
3695         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3696             printdebug "multisuite merge include $mi->{Info}\n";
3697             $mi->{Character} //= ' ';
3698             $commit .= "parent $mi->{Commit}\n";
3699             $msg .= sprintf " %s  %-25s %s\n",
3700                 $mi->{Character},
3701                 (mergeinfo_version $mi),
3702                 $mi->{Info};
3703         }
3704         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3705         $msg .= __ "\nKey\n".
3706             " * marks the highest version branch, which choose to use\n".
3707             " + marks each branch which was not already an ancestor\n\n";
3708         $msg .=
3709             "[dgit multi-suite $csuite]\n";
3710         $commit .=
3711             "author $authline\n".
3712             "committer $authline\n\n";
3713         $output = make_commit_text $commit.$msg;
3714         printdebug "multisuite merge generated $output\n";
3715     }
3716
3717     fetch_from_archive_record_1($output);
3718     fetch_from_archive_record_2($output);
3719
3720     progress f_ "calculated combined tracking suite %s", $csuite;
3721
3722     return 1;
3723 }
3724
3725 sub clone_set_head () {
3726     open H, "> .git/HEAD" or confess $!;
3727     print H "ref: ".lref()."\n" or confess $!;
3728     close H or confess $!;
3729 }
3730 sub clone_finish ($) {
3731     my ($dstdir) = @_;
3732     runcmd @git, qw(reset --hard), lrref();
3733     runcmd qw(bash -ec), <<'END';
3734         set -o pipefail
3735         git ls-tree -r --name-only -z HEAD | \
3736         xargs -0r touch -h -r . --
3737 END
3738     printdone f_ "ready for work in %s", $dstdir;
3739 }
3740
3741 sub clone ($) {
3742     # in multisuite, returns twice!
3743     # once in parent after first suite fetched,
3744     # and then again in child after everything is finished
3745     my ($dstdir) = @_;
3746     badusage __ "dry run makes no sense with clone" unless act_local();
3747
3748     my $multi_fetched = fork_for_multisuite(sub {
3749         printdebug "multi clone before fetch merge\n";
3750         changedir $dstdir;
3751         record_maindir();
3752     });
3753     if ($multi_fetched) {
3754         printdebug "multi clone after fetch merge\n";
3755         clone_set_head();
3756         clone_finish($dstdir);
3757         return;
3758     }
3759     printdebug "clone main body\n";
3760
3761     canonicalise_suite();
3762     my $hasgit = check_for_git();
3763     mkdir $dstdir or fail f_ "create \`%s': %s", $dstdir, $!;
3764     changedir $dstdir;
3765     runcmd @git, qw(init -q);
3766     record_maindir();
3767     setup_new_tree();
3768     clone_set_head();
3769     my $giturl = access_giturl(1);
3770     if (defined $giturl) {
3771         runcmd @git, qw(remote add), 'origin', $giturl;
3772     }
3773     if ($hasgit) {
3774         progress __ "fetching existing git history";
3775         git_fetch_us();
3776         runcmd_ordryrun_local @git, qw(fetch origin);
3777     } else {
3778         progress __ "starting new git history";
3779     }
3780     fetch_from_archive() or no_such_package;
3781     my $vcsgiturl = $dsc->{'Vcs-Git'};
3782     if (length $vcsgiturl) {
3783         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3784         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3785     }
3786     clone_finish($dstdir);
3787 }
3788
3789 sub fetch_one () {
3790     canonicalise_suite();
3791     if (check_for_git()) {
3792         git_fetch_us();
3793     }
3794     fetch_from_archive() or no_such_package();
3795
3796     my $vcsgiturl = $dsc && $dsc->{'Vcs-Git'};
3797     if (length $vcsgiturl and
3798         (grep { $csuite eq $_ }
3799          split /\;/,
3800          cfg 'dgit.vcs-git.suites')) {
3801         my $current = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
3802         if (defined $current && $current ne $vcsgiturl) {
3803             print STDERR f_ <<END, $csuite;
3804 FYI: Vcs-Git in %s has different url to your vcs-git remote.
3805  Your vcs-git remote url may be out of date.  Use dgit update-vcs-git ?
3806 END
3807         }
3808     }
3809     printdone f_ "fetched into %s", lrref();
3810 }
3811
3812 sub dofetch () {
3813     my $multi_fetched = fork_for_multisuite(sub { });
3814     fetch_one() unless $multi_fetched; # parent
3815     finish 0 if $multi_fetched eq '0'; # child
3816 }
3817
3818 sub pull () {
3819     dofetch();
3820     runcmd_ordryrun_local @git, qw(merge -m),
3821         (f_ "Merge from %s [dgit]", $csuite),
3822         lrref();
3823     printdone f_ "fetched to %s and merged into HEAD", lrref();
3824 }
3825
3826 sub check_not_dirty () {
3827     my @forbid = qw(local-options local-patch-header);
3828     @forbid = map { "debian/source/$_" } @forbid;
3829     foreach my $f (@forbid) {
3830         if (stat_exists $f) {
3831             fail f_ "git tree contains %s", $f;
3832         }
3833     }
3834
3835     my @cmd = (@git, qw(status -uall --ignored --porcelain));
3836     push @cmd, qw(debian/source/format debian/source/options);
3837     push @cmd, @forbid;
3838
3839     my $bad = cmdoutput @cmd;
3840     if (length $bad) {
3841         fail +(__
3842  "you have uncommitted changes to critical files, cannot continue:\n").
3843               $bad;
3844     }
3845
3846     return if $includedirty;
3847
3848     git_check_unmodified();
3849 }
3850
3851 sub commit_admin ($) {
3852     my ($m) = @_;
3853     progress "$m";
3854     runcmd_ordryrun_local @git, qw(commit -m), $m;
3855 }
3856
3857 sub quiltify_nofix_bail ($$) {
3858     my ($headinfo, $xinfo) = @_;
3859     if ($quilt_mode eq 'nofix') {
3860         fail f_
3861             "quilt fixup required but quilt mode is \`nofix'\n".
3862             "HEAD commit%s differs from tree implied by debian/patches%s",
3863             $headinfo, $xinfo;
3864     }
3865 }
3866
3867 sub commit_quilty_patch () {
3868     my $output = cmdoutput @git, qw(status --ignored --porcelain);
3869     my %adds;
3870     foreach my $l (split /\n/, $output) {
3871         next unless $l =~ m/\S/;
3872         if ($l =~ m{^(?:[?!][?!]| [MADRC]) (.pc|debian/patches)}) {
3873             $adds{$1}++;
3874         }
3875     }
3876     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3877     if (!%adds) {
3878         progress __ "nothing quilty to commit, ok.";
3879         return;
3880     }
3881     quiltify_nofix_bail "", __ " (wanted to commit patch update)";
3882     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3883     runcmd_ordryrun_local @git, qw(add -f), @adds;
3884     commit_admin +(__ <<ENDT).<<END
3885 Commit Debian 3.0 (quilt) metadata
3886
3887 ENDT
3888 [dgit ($our_version) quilt-fixup]
3889 END
3890 }
3891
3892 sub get_source_format () {
3893     my %options;
3894     if (open F, "debian/source/options") {
3895         while (<F>) {
3896             next if m/^\s*\#/;
3897             next unless m/\S/;
3898             s/\s+$//; # ignore missing final newline
3899             if (m/\s*\#\s*/) {
3900                 my ($k, $v) = ($`, $'); #');
3901                 $v =~ s/^"(.*)"$/$1/;
3902                 $options{$k} = $v;
3903             } else {
3904                 $options{$_} = 1;
3905             }
3906         }
3907         F->error and confess $!;
3908         close F;
3909     } else {
3910         confess $! unless $!==&ENOENT;
3911     }
3912
3913     if (!open F, "debian/source/format") {
3914         confess $! unless $!==&ENOENT;
3915         return '';
3916     }
3917     $_ = <F>;
3918     F->error and confess $!;
3919     chomp;
3920     return ($_, \%options);
3921 }
3922
3923 sub madformat_wantfixup ($) {
3924     my ($format) = @_;
3925     return 0 unless $format eq '3.0 (quilt)';
3926     our $quilt_mode_warned;
3927     if ($quilt_mode eq 'nocheck') {
3928         progress f_ "Not doing any fixup of \`%s'".
3929             " due to ----no-quilt-fixup or --quilt=nocheck", $format
3930             unless $quilt_mode_warned++;
3931         return 0;
3932     }
3933     progress f_ "Format \`%s', need to check/update patch stack", $format
3934         unless $quilt_mode_warned++;
3935     return 1;
3936 }
3937
3938 sub maybe_split_brain_save ($$$) {
3939     my ($headref, $dgitview, $msg) = @_;
3940     # => message fragment "$saved" describing disposition of $dgitview
3941     #    (used inside parens, in the English texts)
3942     my $save = $internal_object_save{'dgit-view'};
3943     return f_ "commit id %s", $dgitview unless defined $save;
3944     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
3945                git_update_ref_cmd
3946                "dgit --dgit-view-save $msg HEAD=$headref",
3947                $save, $dgitview);
3948     runcmd @cmd;
3949     return f_ "and left in %s", $save;
3950 }
3951
3952 # An "infopair" is a tuple [ $thing, $what ]
3953 # (often $thing is a commit hash; $what is a description)
3954
3955 sub infopair_cond_equal ($$) {
3956     my ($x,$y) = @_;
3957     $x->[0] eq $y->[0] or fail <<END;
3958 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3959 END
3960 };
3961
3962 sub infopair_lrf_tag_lookup ($$) {
3963     my ($tagnames, $what) = @_;
3964     # $tagname may be an array ref
3965     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3966     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3967     foreach my $tagname (@tagnames) {
3968         my $lrefname = lrfetchrefs."/tags/$tagname";
3969         my $tagobj = $lrfetchrefs_f{$lrefname};
3970         next unless defined $tagobj;
3971         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3972         return [ git_rev_parse($tagobj), $what ];
3973     }
3974     fail @tagnames==1 ? (f_ <<END, $what, "@tagnames")
3975 Wanted tag %s (%s) on dgit server, but not found
3976 END
3977                       : (f_ <<END, $what, "@tagnames");
3978 Wanted tag %s (one of: %s) on dgit server, but not found
3979 END
3980 }
3981
3982 sub infopair_cond_ff ($$) {
3983     my ($anc,$desc) = @_;
3984     is_fast_fwd($anc->[0], $desc->[0]) or
3985         fail f_ <<END, $anc->[1], $anc->[0], $desc->[1], $desc->[0];
3986 %s (%s) .. %s (%s) is not fast forward
3987 END
3988 };
3989
3990 sub pseudomerge_version_check ($$) {
3991     my ($clogp, $archive_hash) = @_;
3992
3993     my $arch_clogp = commit_getclogp $archive_hash;
3994     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3995                      __ 'version currently in archive' ];
3996     if (defined $overwrite_version) {
3997         if (length $overwrite_version) {
3998             infopair_cond_equal([ $overwrite_version,
3999                                   '--overwrite= version' ],
4000                                 $i_arch_v);
4001         } else {
4002             my $v = $i_arch_v->[0];
4003             progress f_
4004                 "Checking package changelog for archive version %s ...", $v;
4005             my $cd;
4006             eval {
4007                 my @xa = ("-f$v", "-t$v");
4008                 my $vclogp = parsechangelog @xa;
4009                 my $gf = sub {
4010                     my ($fn) = @_;
4011                     [ (getfield $vclogp, $fn),
4012                       (f_ "%s field from dpkg-parsechangelog %s",
4013                           $fn, "@xa") ];
4014                 };
4015                 my $cv = $gf->('Version');
4016                 infopair_cond_equal($i_arch_v, $cv);
4017                 $cd = $gf->('Distribution');
4018             };
4019             if ($@) {
4020                 $@ =~ s/^dgit: //gm;
4021                 fail "$@".
4022                     f_ "Perhaps debian/changelog does not mention %s ?", $v;
4023             }
4024             fail f_ <<END, $cd->[1], $cd->[0], $v
4025 %s is %s
4026 Your tree seems to based on earlier (not uploaded) %s.
4027 END
4028                 if $cd->[0] =~ m/UNRELEASED/;
4029         }
4030     }
4031
4032     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
4033     return $i_arch_v;
4034 }
4035
4036 sub pseudomerge_make_commit ($$$$ $$) {
4037     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
4038         $msg_cmd, $msg_msg) = @_;
4039     progress f_ "Declaring that HEAD includes all changes in %s...",
4040                  $i_arch_v->[0];
4041
4042     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
4043     my $authline = clogp_authline $clogp;
4044
4045     chomp $msg_msg;
4046     $msg_cmd .=
4047         !defined $overwrite_version ? ""
4048         : !length  $overwrite_version ? " --overwrite"
4049         : " --overwrite=".$overwrite_version;
4050
4051     # Contributing parent is the first parent - that makes
4052     # git rev-list --first-parent DTRT.
4053     my $pmf = dgit_privdir()."/pseudomerge";
4054     open MC, ">", $pmf or die "$pmf $!";
4055     print MC <<END or confess $!;
4056 tree $tree
4057 parent $dgitview
4058 parent $archive_hash
4059 author $authline
4060 committer $authline
4061
4062 $msg_msg
4063
4064 [$msg_cmd]
4065 END
4066     close MC or confess $!;
4067
4068     return make_commit($pmf);
4069 }
4070
4071 sub splitbrain_pseudomerge ($$$$) {
4072     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
4073     # => $merged_dgitview
4074     printdebug "splitbrain_pseudomerge...\n";
4075     #
4076     #     We:      debian/PREVIOUS    HEAD($maintview)
4077     # expect:          o ----------------- o
4078     #                    \                   \
4079     #                     o                   o
4080     #                 a/d/PREVIOUS        $dgitview
4081     #                $archive_hash              \
4082     #  If so,                \                   \
4083     #  we do:                 `------------------ o
4084     #   this:                                   $dgitview'
4085     #
4086
4087     return $dgitview unless defined $archive_hash;
4088     return $dgitview if deliberately_not_fast_forward();
4089
4090     printdebug "splitbrain_pseudomerge...\n";
4091
4092     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4093
4094     if (!defined $overwrite_version) {
4095         progress __ "Checking that HEAD includes all changes in archive...";
4096     }
4097
4098     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
4099
4100     if (defined $overwrite_version) {
4101     } elsif (!eval {
4102         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
4103         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14,
4104                                               __ "maintainer view tag");
4105         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
4106         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, __ "dgit view tag");
4107         my $i_archive = [ $archive_hash, __ "current archive contents" ];
4108
4109         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
4110
4111         infopair_cond_equal($i_dgit, $i_archive);
4112         infopair_cond_ff($i_dep14, $i_dgit);
4113         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
4114         1;
4115     }) {
4116         $@ =~ s/^\n//; chomp $@;
4117         print STDERR <<END.(__ <<ENDT);
4118 $@
4119 END
4120 | Not fast forward; maybe --overwrite is needed ?  Please see dgit(1).
4121 ENDT
4122         finish -1;
4123     }
4124
4125     my $arch_v = $i_arch_v->[0];
4126     my $r = pseudomerge_make_commit
4127         $clogp, $dgitview, $archive_hash, $i_arch_v,
4128         "dgit --quilt=$quilt_mode",
4129         (defined $overwrite_version
4130          ? f_ "Declare fast forward from %s\n", $arch_v
4131          : f_ "Make fast forward from %s\n",    $arch_v);
4132
4133     maybe_split_brain_save $maintview, $r, "pseudomerge";
4134
4135     progress f_ "Made pseudo-merge of %s into dgit view.", $arch_v;
4136     return $r;
4137 }
4138
4139 sub plain_overwrite_pseudomerge ($$$) {
4140     my ($clogp, $head, $archive_hash) = @_;
4141
4142     printdebug "plain_overwrite_pseudomerge...";
4143
4144     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4145
4146     return $head if is_fast_fwd $archive_hash, $head;
4147
4148     my $m = f_ "Declare fast forward from %s", $i_arch_v->[0];
4149
4150     my $r = pseudomerge_make_commit
4151         $clogp, $head, $archive_hash, $i_arch_v,
4152         "dgit", $m;
4153
4154     runcmd git_update_ref_cmd $m, 'HEAD', $r, $head;
4155
4156     progress f_ "Make pseudo-merge of %s into your HEAD.", $i_arch_v->[0];
4157     return $r;
4158 }
4159
4160 sub push_parse_changelog ($) {
4161     my ($clogpfn) = @_;
4162
4163     my $clogp = Dpkg::Control::Hash->new();
4164     $clogp->load($clogpfn) or die;
4165
4166     my $clogpackage = getfield $clogp, 'Source';
4167     $package //= $clogpackage;
4168     fail f_ "-p specified %s but changelog specified %s",
4169             $package, $clogpackage
4170         unless $package eq $clogpackage;
4171     my $cversion = getfield $clogp, 'Version';
4172
4173     if (!$we_are_initiator) {
4174         # rpush initiator can't do this because it doesn't have $isuite yet
4175         my $tag = debiantag($cversion, access_nomdistro);
4176         runcmd @git, qw(check-ref-format), $tag;
4177     }
4178
4179     my $dscfn = dscfn($cversion);
4180
4181     return ($clogp, $cversion, $dscfn);
4182 }
4183
4184 sub push_parse_dsc ($$$) {
4185     my ($dscfn,$dscfnwhat, $cversion) = @_;
4186     $dsc = parsecontrol($dscfn,$dscfnwhat);
4187     my $dversion = getfield $dsc, 'Version';
4188     my $dscpackage = getfield $dsc, 'Source';
4189     ($dscpackage eq $package && $dversion eq $cversion) or
4190         fail f_ "%s is for %s %s but debian/changelog is for %s %s",
4191                 $dscfn, $dscpackage, $dversion,
4192                         $package,    $cversion;
4193 }
4194
4195 sub push_tagwants ($$$$) {
4196     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4197     my @tagwants;
4198     push @tagwants, {
4199         TagFn => \&debiantag,
4200         Objid => $dgithead,
4201         TfSuffix => '',
4202         View => 'dgit',
4203     };
4204     if (defined $maintviewhead) {
4205         push @tagwants, {
4206             TagFn => \&debiantag_maintview,
4207             Objid => $maintviewhead,
4208             TfSuffix => '-maintview',
4209             View => 'maint',
4210         };
4211     } elsif ($dodep14tag eq 'no' ? 0
4212              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
4213              : $dodep14tag eq 'always'
4214              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
4215 --dep14tag-always (or equivalent in config) means server must support
4216  both "new" and "maint" tag formats, but config says it doesn't.
4217 END
4218             : die "$dodep14tag ?") {
4219         push @tagwants, {
4220             TagFn => \&debiantag_maintview,
4221             Objid => $dgithead,
4222             TfSuffix => '-dgit',
4223             View => 'dgit',
4224         };
4225     };
4226     foreach my $tw (@tagwants) {
4227         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4228         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4229     }
4230     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4231     return @tagwants;
4232 }
4233
4234 sub push_mktags ($$ $$ $) {
4235     my ($clogp,$dscfn,
4236         $changesfile,$changesfilewhat,
4237         $tagwants) = @_;
4238
4239     die unless $tagwants->[0]{View} eq 'dgit';
4240
4241     my $declaredistro = access_nomdistro();
4242     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4243     $dsc->{$ourdscfield[0]} = join " ",
4244         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4245         $reader_giturl;
4246     $dsc->save("$dscfn.tmp") or confess $!;
4247
4248     my $changes = parsecontrol($changesfile,$changesfilewhat);
4249     foreach my $field (qw(Source Distribution Version)) {
4250         $changes->{$field} eq $clogp->{$field} or
4251             fail f_ "changes field %s \`%s' does not match changelog \`%s'",
4252                     $field, $changes->{$field}, $clogp->{$field};
4253     }
4254
4255     my $cversion = getfield $clogp, 'Version';
4256     my $clogsuite = getfield $clogp, 'Distribution';
4257
4258     # We make the git tag by hand because (a) that makes it easier
4259     # to control the "tagger" (b) we can do remote signing
4260     my $authline = clogp_authline $clogp;
4261     my $delibs = join(" ", "",@deliberatelies);
4262
4263     my $mktag = sub {
4264         my ($tw) = @_;
4265         my $tfn = $tw->{Tfn};
4266         my $head = $tw->{Objid};
4267         my $tag = $tw->{Tag};
4268
4269         open TO, '>', $tfn->('.tmp') or confess $!;
4270         print TO <<END or confess $!;
4271 object $head
4272 type commit
4273 tag $tag
4274 tagger $authline
4275
4276 END
4277         if ($tw->{View} eq 'dgit') {
4278             print TO f_ <<ENDT, $package, $cversion, $clogsuite, $csuite
4279 %s release %s for %s (%s) [dgit]
4280 ENDT
4281                 or confess $!;
4282             print TO <<END or confess $!;
4283 [dgit distro=$declaredistro$delibs]
4284 END
4285             foreach my $ref (sort keys %previously) {
4286                 print TO <<END or confess $!;
4287 [dgit previously:$ref=$previously{$ref}]
4288 END
4289             }
4290         } elsif ($tw->{View} eq 'maint') {
4291             print TO f_ <<END, $package, $cversion, $clogsuite, $csuite,
4292 %s release %s for %s (%s)
4293 (maintainer view tag generated by dgit --quilt=%s)
4294 END
4295                 $quilt_mode
4296                 or confess $!;
4297         } else {
4298             confess Dumper($tw)."?";
4299         }
4300
4301         close TO or confess $!;
4302
4303         my $tagobjfn = $tfn->('.tmp');
4304         if ($sign) {
4305             if (!defined $keyid) {
4306                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4307             }
4308             if (!defined $keyid) {
4309                 $keyid = getfield $clogp, 'Maintainer';
4310             }
4311             unlink $tfn->('.tmp.asc') or $!==&ENOENT or confess $!;
4312             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4313             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4314             push @sign_cmd, $tfn->('.tmp');
4315             runcmd_ordryrun @sign_cmd;
4316             if (act_scary()) {
4317                 $tagobjfn = $tfn->('.signed.tmp');
4318                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4319                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4320             }
4321         }
4322         return $tagobjfn;
4323     };
4324
4325     my @r = map { $mktag->($_); } @$tagwants;
4326     return @r;
4327 }
4328
4329 sub sign_changes ($) {
4330     my ($changesfile) = @_;
4331     if ($sign) {
4332         my @debsign_cmd = @debsign;
4333         push @debsign_cmd, "-k$keyid" if defined $keyid;
4334         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4335         push @debsign_cmd, $changesfile;
4336         runcmd_ordryrun @debsign_cmd;
4337     }
4338 }
4339
4340 sub dopush () {
4341     printdebug "actually entering push\n";
4342
4343     supplementary_message(__ <<'END');
4344 Push failed, while checking state of the archive.
4345 You can retry the push, after fixing the problem, if you like.
4346 END
4347     if (check_for_git()) {
4348         git_fetch_us();
4349     }
4350     my $archive_hash = fetch_from_archive();
4351     if (!$archive_hash) {
4352         $new_package or
4353             fail __ "package appears to be new in this suite;".
4354                     " if this is intentional, use --new";
4355     }
4356
4357     supplementary_message(__ <<'END');
4358 Push failed, while preparing your push.
4359 You can retry the push, after fixing the problem, if you like.
4360 END
4361
4362     need_tagformat 'new', "quilt mode $quilt_mode"
4363         if quiltmode_splitbrain;
4364
4365     prep_ud();
4366
4367     access_giturl(); # check that success is vaguely likely
4368     rpush_handle_protovsn_bothends() if $we_are_initiator;
4369     select_tagformat();
4370
4371     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4372     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4373
4374     responder_send_file('parsed-changelog', $clogpfn);
4375
4376     my ($clogp, $cversion, $dscfn) =
4377         push_parse_changelog("$clogpfn");
4378
4379     my $dscpath = "$buildproductsdir/$dscfn";
4380     stat_exists $dscpath or
4381         fail f_ "looked for .dsc %s, but %s; maybe you forgot to build",
4382                 $dscpath, $!;
4383
4384     responder_send_file('dsc', $dscpath);
4385
4386     push_parse_dsc($dscpath, $dscfn, $cversion);
4387
4388     my $format = getfield $dsc, 'Format';
4389     printdebug "format $format\n";
4390
4391     my $symref = git_get_symref();
4392     my $actualhead = git_rev_parse('HEAD');
4393
4394     if (branch_is_gdr_unstitched_ff($symref, $actualhead, $archive_hash)) {
4395         if (quiltmode_splitbrain()) {
4396             my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $actualhead);
4397             fail f_ <<END, $ffq_prev, $quilt_mode;
4398 Branch is managed by git-debrebase (%s
4399 exists), but quilt mode (%s) implies a split view.
4400 Pass the right --quilt option or adjust your git config.
4401 Or, maybe, run git-debrebase forget-was-ever-debrebase.
4402 END
4403         }
4404         runcmd_ordryrun_local @git_debrebase, 'stitch';
4405         $actualhead = git_rev_parse('HEAD');
4406     }
4407
4408     my $dgithead = $actualhead;
4409     my $maintviewhead = undef;
4410
4411     my $upstreamversion = upstreamversion $clogp->{Version};
4412
4413     if (madformat_wantfixup($format)) {
4414         # user might have not used dgit build, so maybe do this now:
4415         if (quiltmode_splitbrain()) {
4416             changedir $playground;
4417             quilt_make_fake_dsc($upstreamversion);
4418             my $cachekey;
4419             ($dgithead, $cachekey) =
4420                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4421             $dgithead or fail f_
4422  "--quilt=%s but no cached dgit view:
4423  perhaps HEAD changed since dgit build[-source] ?",
4424                               $quilt_mode;
4425             $split_brain = 1;
4426             $dgithead = splitbrain_pseudomerge($clogp,
4427                                                $actualhead, $dgithead,
4428                                                $archive_hash);
4429             $maintviewhead = $actualhead;
4430             changedir $maindir;
4431             prep_ud(); # so _only_subdir() works, below
4432         } else {
4433             commit_quilty_patch();
4434         }
4435     }
4436
4437     if (defined $overwrite_version && !defined $maintviewhead
4438         && $archive_hash) {
4439         $dgithead = plain_overwrite_pseudomerge($clogp,
4440                                                 $dgithead,
4441                                                 $archive_hash);
4442     }
4443
4444     check_not_dirty();
4445
4446     my $forceflag = '';
4447     if ($archive_hash) {
4448         if (is_fast_fwd($archive_hash, $dgithead)) {
4449             # ok
4450         } elsif (deliberately_not_fast_forward) {
4451             $forceflag = '+';
4452         } else {
4453             fail __ "dgit push: HEAD is not a descendant".
4454                 " of the archive's version.\n".
4455                 "To overwrite the archive's contents,".
4456                 " pass --overwrite[=VERSION].\n".
4457                 "To rewind history, if permitted by the archive,".
4458                 " use --deliberately-not-fast-forward.";
4459         }
4460     }
4461
4462     changedir $playground;
4463     progress f_ "checking that %s corresponds to HEAD", $dscfn;
4464     runcmd qw(dpkg-source -x --),
4465         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4466     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4467     check_for_vendor_patches() if madformat($dsc->{format});
4468     changedir $maindir;
4469     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4470     debugcmd "+",@diffcmd;
4471     $!=0; $?=-1;
4472     my $r = system @diffcmd;
4473     if ($r) {
4474         if ($r==256) {
4475             my $referent = $split_brain ? $dgithead : 'HEAD';
4476             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4477
4478             my @mode_changes;
4479             my $raw = cmdoutput @git,
4480                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4481             my $changed;
4482             foreach (split /\0/, $raw) {
4483                 if (defined $changed) {
4484                     push @mode_changes, "$changed: $_\n" if $changed;
4485                     $changed = undef;
4486                     next;
4487                 } elsif (m/^:0+ 0+ /) {
4488                     $changed = '';
4489                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4490                     $changed = "Mode change from $1 to $2"
4491                 } else {
4492                     die "$_ ?";
4493                 }
4494             }
4495             if (@mode_changes) {
4496                 fail +(f_ <<ENDT, $dscfn).<<END
4497 HEAD specifies a different tree to %s:
4498 ENDT
4499 $diffs
4500 END
4501                     .(join '', @mode_changes)
4502                     .(f_ <<ENDT, $tree, $referent);
4503 There is a problem with your source tree (see dgit(7) for some hints).
4504 To see a full diff, run git diff %s %s
4505 ENDT
4506             }
4507
4508             fail +(f_ <<ENDT, $dscfn).<<END.(f_ <<ENDT, $tree, $referent);
4509 HEAD specifies a different tree to %s:
4510 ENDT
4511 $diffs
4512 END
4513 Perhaps you forgot to build.  Or perhaps there is a problem with your
4514  source tree (see dgit(7) for some hints).  To see a full diff, run
4515    git diff %s %s
4516 ENDT
4517         } else {
4518             failedcmd @diffcmd;
4519         }
4520     }
4521     if (!$changesfile) {
4522         my $pat = changespat $cversion;
4523         my @cs = glob "$buildproductsdir/$pat";
4524         fail f_ "failed to find unique changes file".
4525                 " (looked for %s in %s);".
4526                 " perhaps you need to use dgit -C",
4527                 $pat, $buildproductsdir
4528             unless @cs==1;
4529         ($changesfile) = @cs;
4530     } else {
4531         $changesfile = "$buildproductsdir/$changesfile";
4532     }
4533
4534     # Check that changes and .dsc agree enough
4535     $changesfile =~ m{[^/]*$};
4536     my $changes = parsecontrol($changesfile,$&);
4537     files_compare_inputs($dsc, $changes)
4538         unless forceing [qw(dsc-changes-mismatch)];
4539
4540     # Check whether this is a source only upload
4541     my $hasdebs = $changes->{Files} =~ m{\.deb$}m;
4542     my $sourceonlypolicy = access_cfg 'source-only-uploads';
4543     if ($sourceonlypolicy eq 'ok') {
4544     } elsif ($sourceonlypolicy eq 'always') {
4545         forceable_fail [qw(uploading-binaries)],
4546             __ "uploading binaries, although distro policy is source only"
4547             if $hasdebs;
4548     } elsif ($sourceonlypolicy eq 'never') {
4549         forceable_fail [qw(uploading-source-only)],
4550             __ "source-only upload, although distro policy requires .debs"
4551             if !$hasdebs;
4552     } elsif ($sourceonlypolicy eq 'not-wholly-new') {
4553         forceable_fail [qw(uploading-source-only)],
4554             f_ "source-only upload, even though package is entirely NEW\n".
4555                "(this is contrary to policy in %s)",
4556                access_nomdistro()
4557             if !$hasdebs
4558             && $new_package
4559             && !(archive_query('package_not_wholly_new', $package) // 1);
4560     } else {
4561         badcfg f_ "unknown source-only-uploads policy \`%s'",
4562                   $sourceonlypolicy;
4563     }
4564
4565     # Perhaps adjust .dsc to contain right set of origs
4566     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4567                                   $changesfile)
4568         unless forceing [qw(changes-origs-exactly)];
4569
4570     # Checks complete, we're going to try and go ahead:
4571
4572     responder_send_file('changes',$changesfile);
4573     responder_send_command("param head $dgithead");
4574     responder_send_command("param csuite $csuite");
4575     responder_send_command("param isuite $isuite");
4576     responder_send_command("param tagformat $tagformat");
4577     if (defined $maintviewhead) {
4578         confess "internal error (protovsn=$protovsn)"
4579             if defined $protovsn and $protovsn < 4;
4580         responder_send_command("param maint-view $maintviewhead");
4581     }
4582
4583     # Perhaps send buildinfo(s) for signing
4584     my $changes_files = getfield $changes, 'Files';
4585     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4586     foreach my $bi (@buildinfos) {
4587         responder_send_command("param buildinfo-filename $bi");
4588         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4589     }
4590
4591     if (deliberately_not_fast_forward) {
4592         git_for_each_ref(lrfetchrefs, sub {
4593             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4594             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4595             responder_send_command("previously $rrefname=$objid");
4596             $previously{$rrefname} = $objid;
4597         });
4598     }
4599
4600     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4601                                  dgit_privdir()."/tag");
4602     my @tagobjfns;
4603
4604     supplementary_message(__ <<'END');
4605 Push failed, while signing the tag.
4606 You can retry the push, after fixing the problem, if you like.
4607 END
4608     # If we manage to sign but fail to record it anywhere, it's fine.
4609     if ($we_are_responder) {
4610         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4611         responder_receive_files('signed-tag', @tagobjfns);
4612     } else {
4613         @tagobjfns = push_mktags($clogp,$dscpath,
4614                               $changesfile,$changesfile,
4615                               \@tagwants);
4616     }
4617     supplementary_message(__ <<'END');
4618 Push failed, *after* signing the tag.
4619 If you want to try again, you should use a new version number.
4620 END
4621
4622     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4623
4624     foreach my $tw (@tagwants) {
4625         my $tag = $tw->{Tag};
4626         my $tagobjfn = $tw->{TagObjFn};
4627         my $tag_obj_hash =
4628             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4629         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4630         runcmd_ordryrun_local
4631             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4632     }
4633
4634     supplementary_message(__ <<'END');
4635 Push failed, while updating the remote git repository - see messages above.
4636 If you want to try again, you should use a new version number.
4637 END
4638     if (!check_for_git()) {
4639         create_remote_git_repo();
4640     }
4641
4642     my @pushrefs = $forceflag.$dgithead.":".rrref();
4643     foreach my $tw (@tagwants) {
4644         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4645     }
4646
4647     runcmd_ordryrun @git,
4648         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4649     runcmd_ordryrun git_update_ref_cmd 'dgit push', lrref(), $dgithead;
4650
4651     supplementary_message(__ <<'END');
4652 Push failed, while obtaining signatures on the .changes and .dsc.
4653 If it was just that the signature failed, you may try again by using
4654 debsign by hand to sign the changes file (see the command dgit tried,
4655 above), and then dput that changes file to complete the upload.
4656 If you need to change the package, you must use a new version number.
4657 END
4658     if ($we_are_responder) {
4659         my $dryrunsuffix = act_local() ? "" : ".tmp";
4660         my @rfiles = ($dscpath, $changesfile);
4661         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4662         responder_receive_files('signed-dsc-changes',
4663                                 map { "$_$dryrunsuffix" } @rfiles);
4664     } else {
4665         if (act_local()) {
4666             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4667         } else {
4668             progress f_ "[new .dsc left in %s.tmp]", $dscpath;
4669         }
4670         sign_changes $changesfile;
4671     }
4672
4673     supplementary_message(f_ <<END, $changesfile);
4674 Push failed, while uploading package(s) to the archive server.
4675 You can retry the upload of exactly these same files with dput of:
4676   %s
4677 If that .changes file is broken, you will need to use a new version
4678 number for your next attempt at the upload.
4679 END
4680     my $host = access_cfg('upload-host','RETURN-UNDEF');
4681     my @hostarg = defined($host) ? ($host,) : ();
4682     runcmd_ordryrun @dput, @hostarg, $changesfile;
4683     printdone f_ "pushed and uploaded %s", $cversion;
4684
4685     supplementary_message('');
4686     responder_send_command("complete");
4687 }
4688
4689 sub pre_clone () {
4690     not_necessarily_a_tree();
4691 }
4692 sub cmd_clone {
4693     parseopts();
4694     my $dstdir;
4695     badusage __ "-p is not allowed with clone; specify as argument instead"
4696         if defined $package;
4697     if (@ARGV==1) {
4698         ($package) = @ARGV;
4699     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4700         ($package,$isuite) = @ARGV;
4701     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4702         ($package,$dstdir) = @ARGV;
4703     } elsif (@ARGV==3) {
4704         ($package,$isuite,$dstdir) = @ARGV;
4705     } else {
4706         badusage __ "incorrect arguments to dgit clone";
4707     }
4708     notpushing();
4709
4710     $dstdir ||= "$package";
4711     if (stat_exists $dstdir) {
4712         fail f_ "%s already exists", $dstdir;
4713     }
4714
4715     my $cwd_remove;
4716     if ($rmonerror && !$dryrun_level) {
4717         $cwd_remove= getcwd();
4718         unshift @end, sub {
4719             return unless defined $cwd_remove;
4720             if (!chdir "$cwd_remove") {
4721                 return if $!==&ENOENT;
4722                 confess "chdir $cwd_remove: $!";
4723             }
4724             printdebug "clone rmonerror removing $dstdir\n";
4725             if (stat $dstdir) {
4726                 rmtree($dstdir) or fail f_ "remove %s: %s\n", $dstdir, $!;
4727             } elsif (grep { $! == $_ }
4728                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4729             } else {
4730                 print STDERR f_ "check whether to remove %s: %s\n",
4731                                 $dstdir, $!;
4732             }
4733         };
4734     }
4735
4736     clone($dstdir);
4737     $cwd_remove = undef;
4738 }
4739
4740 sub branchsuite () {
4741     my $branch = git_get_symref();
4742     if (defined $branch && $branch =~ m#$lbranch_re#o) {
4743         return $1;
4744     } else {
4745         return undef;
4746     }
4747 }
4748
4749 sub package_from_d_control () {
4750     if (!defined $package) {
4751         my $sourcep = parsecontrol('debian/control','debian/control');
4752         $package = getfield $sourcep, 'Source';
4753     }
4754 }
4755
4756 sub fetchpullargs () {
4757     package_from_d_control();
4758     if (@ARGV==0) {
4759         $isuite = branchsuite();
4760         if (!$isuite) {
4761             my $clogp = parsechangelog();
4762             my $clogsuite = getfield $clogp, 'Distribution';
4763             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4764         }
4765     } elsif (@ARGV==1) {
4766         ($isuite) = @ARGV;
4767     } else {
4768         badusage __ "incorrect arguments to dgit fetch or dgit pull";
4769     }
4770     notpushing();
4771 }
4772
4773 sub cmd_fetch {
4774     parseopts();
4775     fetchpullargs();
4776     dofetch();
4777 }
4778
4779 sub cmd_pull {
4780     parseopts();
4781     fetchpullargs();
4782     if (quiltmode_splitbrain()) {
4783         my ($format, $fopts) = get_source_format();
4784         madformat($format) and fail f_ <<END, $quilt_mode
4785 dgit pull not yet supported in split view mode (--quilt=%s)
4786 END
4787     }
4788     pull();
4789 }
4790
4791 sub cmd_checkout {
4792     parseopts();
4793     package_from_d_control();
4794     @ARGV==1 or badusage __ "dgit checkout needs a suite argument";
4795     ($isuite) = @ARGV;
4796     notpushing();
4797
4798     foreach my $canon (qw(0 1)) {
4799         if (!$canon) {
4800             $csuite= $isuite;
4801         } else {
4802             undef $csuite;
4803             canonicalise_suite();
4804         }
4805         if (length git_get_ref lref()) {
4806             # local branch already exists, yay
4807             last;
4808         }
4809         if (!length git_get_ref lrref()) {
4810             if (!$canon) {
4811                 # nope
4812                 next;
4813             }
4814             dofetch();
4815         }
4816         # now lrref exists
4817         runcmd (@git, qw(update-ref), lref(), lrref(), '');
4818         last;
4819     }
4820     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
4821         "dgit checkout $isuite";
4822     runcmd (@git, qw(checkout), lbranch());
4823 }
4824
4825 sub cmd_update_vcs_git () {
4826     my $specsuite;
4827     if (@ARGV==0 || $ARGV[0] =~ m/^-/) {
4828         ($specsuite,) = split /\;/, cfg 'dgit.vcs-git.suites';
4829     } else {
4830         ($specsuite) = (@ARGV);
4831         shift @ARGV;
4832     }
4833     my $dofetch=1;
4834     if (@ARGV) {
4835         if ($ARGV[0] eq '-') {
4836             $dofetch = 0;
4837         } elsif ($ARGV[0] eq '-') {
4838             shift;
4839         }
4840     }
4841
4842     package_from_d_control();
4843     my $ctrl;
4844     if ($specsuite eq '.') {
4845         $ctrl = parsecontrol 'debian/control', 'debian/control';
4846     } else {
4847         $isuite = $specsuite;
4848         get_archive_dsc();
4849         $ctrl = $dsc;
4850     }
4851     my $url = getfield $ctrl, 'Vcs-Git';
4852
4853     my @cmd;
4854     my $orgurl = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
4855     if (!defined $orgurl) {
4856         print STDERR f_ "setting up vcs-git: %s\n", $url;
4857         @cmd = (@git, qw(remote add vcs-git), $url);
4858     } elsif ($orgurl eq $url) {
4859         print STDERR f_ "vcs git already configured: %s\n", $url;
4860     } else {
4861         print STDERR f_ "changing vcs-git url to: %s\n", $url;
4862         @cmd = (@git, qw(remote set-url vcs-git), $url);
4863     }
4864     runcmd_ordryrun_local @cmd;
4865     if ($dofetch) {
4866         print f_ "fetching (%s)\n", "@ARGV";
4867         runcmd_ordryrun_local @git, qw(fetch vcs-git), @ARGV;
4868     }
4869 }
4870
4871 sub prep_push () {
4872     parseopts();
4873     build_or_push_prep_early();
4874     pushing();
4875     check_not_dirty();
4876     my $specsuite;
4877     if (@ARGV==0) {
4878     } elsif (@ARGV==1) {
4879         ($specsuite) = (@ARGV);
4880     } else {
4881         badusage f_ "incorrect arguments to dgit %s", $subcommand;
4882     }
4883     if ($new_package) {
4884         local ($package) = $existing_package; # this is a hack
4885         canonicalise_suite();
4886     } else {
4887         canonicalise_suite();
4888     }
4889     if (defined $specsuite &&
4890         $specsuite ne $isuite &&
4891         $specsuite ne $csuite) {
4892             fail f_ "dgit %s: changelog specifies %s (%s)".
4893                     " but command line specifies %s",
4894                     $subcommand, $isuite, $csuite, $specsuite;
4895     }
4896 }
4897
4898 sub cmd_push {
4899     prep_push();
4900     dopush();
4901 }
4902
4903 #---------- remote commands' implementation ----------
4904
4905 sub pre_remote_push_build_host {
4906     my ($nrargs) = shift @ARGV;
4907     my (@rargs) = @ARGV[0..$nrargs-1];
4908     @ARGV = @ARGV[$nrargs..$#ARGV];
4909     die unless @rargs;
4910     my ($dir,$vsnwant) = @rargs;
4911     # vsnwant is a comma-separated list; we report which we have
4912     # chosen in our ready response (so other end can tell if they
4913     # offered several)
4914     $debugprefix = ' ';
4915     $we_are_responder = 1;
4916     $us .= " (build host)";
4917
4918     open PI, "<&STDIN" or confess $!;
4919     open STDIN, "/dev/null" or confess $!;
4920     open PO, ">&STDOUT" or confess $!;
4921     autoflush PO 1;
4922     open STDOUT, ">&STDERR" or confess $!;
4923     autoflush STDOUT 1;
4924
4925     $vsnwant //= 1;
4926     ($protovsn) = grep {
4927         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4928     } @rpushprotovsn_support;
4929
4930     fail f_ "build host has dgit rpush protocol versions %s".
4931             " but invocation host has %s",
4932             (join ",", @rpushprotovsn_support), $vsnwant
4933         unless defined $protovsn;
4934
4935     changedir $dir;
4936 }
4937 sub cmd_remote_push_build_host {
4938     responder_send_command("dgit-remote-push-ready $protovsn");
4939     &cmd_push;
4940 }
4941
4942 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4943 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4944 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4945 #     a good error message)
4946
4947 sub rpush_handle_protovsn_bothends () {
4948     if ($protovsn < 4) {
4949         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4950     }
4951     select_tagformat();
4952 }
4953
4954 our $i_tmp;
4955
4956 sub i_cleanup {
4957     local ($@, $?);
4958     my $report = i_child_report();
4959     if (defined $report) {
4960         printdebug "($report)\n";
4961     } elsif ($i_child_pid) {
4962         printdebug "(killing build host child $i_child_pid)\n";
4963         kill 15, $i_child_pid;
4964     }
4965     if (defined $i_tmp && !defined $initiator_tempdir) {
4966         changedir "/";
4967         eval { rmtree $i_tmp; };
4968     }
4969 }
4970
4971 END {
4972     return unless forkcheck_mainprocess();
4973     i_cleanup();
4974 }
4975
4976 sub i_method {
4977     my ($base,$selector,@args) = @_;
4978     $selector =~ s/\-/_/g;
4979     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4980 }
4981
4982 sub pre_rpush () {
4983     not_necessarily_a_tree();
4984 }
4985 sub cmd_rpush {
4986     my $host = nextarg;
4987     my $dir;
4988     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4989         $host = $1;
4990         $dir = $'; #';
4991     } else {
4992         $dir = nextarg;
4993     }
4994     $dir =~ s{^-}{./-};
4995     my @rargs = ($dir);
4996     push @rargs, join ",", @rpushprotovsn_support;
4997     my @rdgit;
4998     push @rdgit, @dgit;
4999     push @rdgit, @ropts;
5000     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
5001     push @rdgit, @ARGV;
5002     my @cmd = (@ssh, $host, shellquote @rdgit);
5003     debugcmd "+",@cmd;
5004
5005     $we_are_initiator=1;
5006
5007     if (defined $initiator_tempdir) {
5008         rmtree $initiator_tempdir;
5009         mkdir $initiator_tempdir, 0700
5010             or fail f_ "create %s: %s", $initiator_tempdir, $!;
5011         $i_tmp = $initiator_tempdir;
5012     } else {
5013         $i_tmp = tempdir();
5014     }
5015     $i_child_pid = open2(\*RO, \*RI, @cmd);
5016     changedir $i_tmp;
5017     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
5018     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
5019     $supplementary_message = '' unless $protovsn >= 3;
5020
5021     for (;;) {
5022         my ($icmd,$iargs) = initiator_expect {
5023             m/^(\S+)(?: (.*))?$/;
5024             ($1,$2);
5025         };
5026         i_method "i_resp", $icmd, $iargs;
5027     }
5028 }
5029
5030 sub i_resp_progress ($) {
5031     my ($rhs) = @_;
5032     my $msg = protocol_read_bytes \*RO, $rhs;
5033     progress $msg;
5034 }
5035
5036 sub i_resp_supplementary_message ($) {
5037     my ($rhs) = @_;
5038     $supplementary_message = protocol_read_bytes \*RO, $rhs;
5039 }
5040
5041 sub i_resp_complete {
5042     my $pid = $i_child_pid;
5043     $i_child_pid = undef; # prevents killing some other process with same pid
5044     printdebug "waiting for build host child $pid...\n";
5045     my $got = waitpid $pid, 0;
5046     confess $! unless $got == $pid;
5047     fail f_ "build host child failed: %s", waitstatusmsg() if $?;
5048
5049     i_cleanup();
5050     printdebug __ "all done\n";
5051     finish 0;
5052 }
5053
5054 sub i_resp_file ($) {
5055     my ($keyword) = @_;
5056     my $localname = i_method "i_localname", $keyword;
5057     my $localpath = "$i_tmp/$localname";
5058     stat_exists $localpath and
5059         badproto \*RO, f_ "file %s (%s) twice", $keyword, $localpath;
5060     protocol_receive_file \*RO, $localpath;
5061     i_method "i_file", $keyword;
5062 }
5063
5064 our %i_param;
5065
5066 sub i_resp_param ($) {
5067     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, __ "bad param spec";
5068     $i_param{$1} = $2;
5069 }
5070
5071 sub i_resp_previously ($) {
5072     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
5073         or badproto \*RO, __ "bad previously spec";
5074     my $r = system qw(git check-ref-format), $1;
5075     confess "bad previously ref spec ($r)" if $r;
5076     $previously{$1} = $2;
5077 }
5078
5079 our %i_wanted;
5080
5081 sub i_resp_want ($) {
5082     my ($keyword) = @_;
5083     die "$keyword ?" if $i_wanted{$keyword}++;
5084
5085     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
5086     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
5087     die unless $isuite =~ m/^$suite_re$/;
5088
5089     pushing();
5090     rpush_handle_protovsn_bothends();
5091
5092     fail f_ "rpush negotiated protocol version %s".
5093         " which does not support quilt mode %s",
5094         $protovsn, $quilt_mode
5095         if quiltmode_splitbrain;
5096
5097     my @localpaths = i_method "i_want", $keyword;
5098     printdebug "[[  $keyword @localpaths\n";
5099     foreach my $localpath (@localpaths) {
5100         protocol_send_file \*RI, $localpath;
5101     }
5102     print RI "files-end\n" or confess $!;
5103 }
5104
5105 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
5106
5107 sub i_localname_parsed_changelog {
5108     return "remote-changelog.822";
5109 }
5110 sub i_file_parsed_changelog {
5111     ($i_clogp, $i_version, $i_dscfn) =
5112         push_parse_changelog "$i_tmp/remote-changelog.822";
5113     die if $i_dscfn =~ m#/|^\W#;
5114 }
5115
5116 sub i_localname_dsc {
5117     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5118     return $i_dscfn;
5119 }
5120 sub i_file_dsc { }
5121
5122 sub i_localname_buildinfo ($) {
5123     my $bi = $i_param{'buildinfo-filename'};
5124     defined $bi or badproto \*RO, "buildinfo before filename";
5125     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
5126     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
5127         or badproto \*RO, "improper buildinfo filename";
5128     return $&;
5129 }
5130 sub i_file_buildinfo {
5131     my $bi = $i_param{'buildinfo-filename'};
5132     my $bd = parsecontrol "$i_tmp/$bi", $bi;
5133     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
5134     if (!forceing [qw(buildinfo-changes-mismatch)]) {
5135         files_compare_inputs($bd, $ch);
5136         (getfield $bd, $_) eq (getfield $ch, $_) or
5137             fail f_ "buildinfo mismatch in field %s", $_
5138             foreach qw(Source Version);
5139         !defined $bd->{$_} or
5140             fail f_ "buildinfo contains forbidden field %s", $_
5141             foreach qw(Changes Changed-by Distribution);
5142     }
5143     push @i_buildinfos, $bi;
5144     delete $i_param{'buildinfo-filename'};
5145 }
5146
5147 sub i_localname_changes {
5148     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5149     $i_changesfn = $i_dscfn;
5150     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
5151     return $i_changesfn;
5152 }
5153 sub i_file_changes { }
5154
5155 sub i_want_signed_tag {
5156     printdebug Dumper(\%i_param, $i_dscfn);
5157     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
5158         && defined $i_param{'csuite'}
5159         or badproto \*RO, "premature desire for signed-tag";
5160     my $head = $i_param{'head'};
5161     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
5162
5163     my $maintview = $i_param{'maint-view'};
5164     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
5165
5166     select_tagformat();
5167     if ($protovsn >= 4) {
5168         my $p = $i_param{'tagformat'} // '<undef>';
5169         $p eq $tagformat
5170             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
5171     }
5172
5173     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
5174     $csuite = $&;
5175     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
5176
5177     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
5178
5179     return
5180         push_mktags $i_clogp, $i_dscfn,
5181             $i_changesfn, (__ 'remote changes file'),
5182             \@tagwants;
5183 }
5184
5185 sub i_want_signed_dsc_changes {
5186     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
5187     sign_changes $i_changesfn;
5188     return ($i_dscfn, $i_changesfn, @i_buildinfos);
5189 }
5190
5191 #---------- building etc. ----------
5192
5193 our $version;
5194 our $sourcechanges;
5195 our $dscfn;
5196
5197 #----- `3.0 (quilt)' handling -----
5198
5199 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
5200
5201 sub quiltify_dpkg_commit ($$$;$) {
5202     my ($patchname,$author,$msg, $xinfo) = @_;
5203     $xinfo //= '';
5204
5205     mkpath '.git/dgit'; # we are in playtree
5206     my $descfn = ".git/dgit/quilt-description.tmp";
5207     open O, '>', $descfn or confess "$descfn: $!";
5208     $msg =~ s/\n+/\n\n/;
5209     print O <<END or confess $!;
5210 From: $author
5211 ${xinfo}Subject: $msg
5212 ---
5213
5214 END
5215     close O or confess $!;
5216
5217     {
5218         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
5219         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
5220         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
5221         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
5222     }
5223 }
5224
5225 sub quiltify_trees_differ ($$;$$$) {
5226     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
5227     # returns true iff the two tree objects differ other than in debian/
5228     # with $finegrained,
5229     # returns bitmask 01 - differ in upstream files except .gitignore
5230     #                 02 - differ in .gitignore
5231     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
5232     #  is set for each modified .gitignore filename $fn
5233     # if $unrepres is defined, array ref to which is appeneded
5234     #  a list of unrepresentable changes (removals of upstream files
5235     #  (as messages)
5236     local $/=undef;
5237     my @cmd = (@git, qw(diff-tree -z --no-renames));
5238     push @cmd, qw(--name-only) unless $unrepres;
5239     push @cmd, qw(-r) if $finegrained || $unrepres;
5240     push @cmd, $x, $y;
5241     my $diffs= cmdoutput @cmd;
5242     my $r = 0;
5243     my @lmodes;
5244     foreach my $f (split /\0/, $diffs) {
5245         if ($unrepres && !@lmodes) {
5246             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
5247             next;
5248         }
5249         my ($oldmode,$newmode) = @lmodes;
5250         @lmodes = ();
5251
5252         next if $f =~ m#^debian(?:/.*)?$#s;
5253
5254         if ($unrepres) {
5255             eval {
5256                 die __ "not a plain file or symlink\n"
5257                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
5258                            $oldmode =~ m/^(?:10|12)\d{4}$/;
5259                 if ($oldmode =~ m/[^0]/ &&
5260                     $newmode =~ m/[^0]/) {
5261                     # both old and new files exist
5262                     die __ "mode or type changed\n" if $oldmode ne $newmode;
5263                     die __ "modified symlink\n" unless $newmode =~ m/^10/;
5264                 } elsif ($oldmode =~ m/[^0]/) {
5265                     # deletion
5266                     die __ "deletion of symlink\n"
5267                         unless $oldmode =~ m/^10/;
5268                 } else {
5269                     # creation
5270                     die __ "creation with non-default mode\n"
5271                         unless $newmode =~ m/^100644$/ or
5272                                $newmode =~ m/^120000$/;
5273                 }
5274             };
5275             if ($@) {
5276                 local $/="\n"; chomp $@;
5277                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
5278             }
5279         }
5280
5281         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
5282         $r |= $isignore ? 02 : 01;
5283         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
5284     }
5285     printdebug "quiltify_trees_differ $x $y => $r\n";
5286     return $r;
5287 }
5288
5289 sub quiltify_tree_sentinelfiles ($) {
5290     # lists the `sentinel' files present in the tree
5291     my ($x) = @_;
5292     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
5293         qw(-- debian/rules debian/control);
5294     $r =~ s/\n/,/g;
5295     return $r;
5296 }
5297
5298 sub quiltify_splitbrain_needed () {
5299     if (!$split_brain) {
5300         progress __ "dgit view: changes are required...";
5301         runcmd @git, qw(checkout -q -b dgit-view);
5302         $split_brain = 1;
5303     }
5304 }
5305
5306 sub quiltify_splitbrain ($$$$$$$) {
5307     my ($clogp, $unapplied, $headref, $oldtiptree, $diffbits,
5308         $editedignores, $cachekey) = @_;
5309     my $gitignore_special = 1;
5310     if ($quilt_mode !~ m/gbp|dpm/) {
5311         # treat .gitignore just like any other upstream file
5312         $diffbits = { %$diffbits };
5313         $_ = !!$_ foreach values %$diffbits;
5314         $gitignore_special = 0;
5315     }
5316     # We would like any commits we generate to be reproducible
5317     my @authline = clogp_authline($clogp);
5318     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
5319     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
5320     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
5321     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
5322     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
5323     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
5324
5325     my $fulldiffhint = sub {
5326         my ($x,$y) = @_;
5327         my $cmd = "git diff $x $y -- :/ ':!debian'";
5328         $cmd .= " ':!/.gitignore' ':!*/.gitignore'" if $gitignore_special;
5329         return f_ "\nFor full diff showing the problem(s), type:\n %s\n",
5330                   $cmd;
5331     };
5332
5333     if ($quilt_mode =~ m/gbp|unapplied/ &&
5334         ($diffbits->{O2H} & 01)) {
5335         my $msg = f_
5336  "--quilt=%s specified, implying patches-unapplied git tree\n".
5337  " but git tree differs from orig in upstream files.",
5338                      $quilt_mode;
5339         $msg .= $fulldiffhint->($unapplied, 'HEAD');
5340         if (!stat_exists "debian/patches") {
5341             $msg .= __
5342  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
5343         }
5344         fail $msg;
5345     }
5346     if ($quilt_mode =~ m/dpm/ &&
5347         ($diffbits->{H2A} & 01)) {
5348         fail +(f_ <<END, $quilt_mode). $fulldiffhint->($oldtiptree,'HEAD');
5349 --quilt=%s specified, implying patches-applied git tree
5350  but git tree differs from result of applying debian/patches to upstream
5351 END
5352     }
5353     if ($quilt_mode =~ m/gbp|unapplied/ &&
5354         ($diffbits->{O2A} & 01)) { # some patches
5355         quiltify_splitbrain_needed();
5356         progress __ "dgit view: creating patches-applied version using gbp pq";
5357         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
5358         # gbp pq import creates a fresh branch; push back to dgit-view
5359         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
5360         runcmd @git, qw(checkout -q dgit-view);
5361     }
5362     if ($quilt_mode =~ m/gbp|dpm/ &&
5363         ($diffbits->{O2A} & 02)) {
5364         fail f_ <<END, $quilt_mode;
5365 --quilt=%s specified, implying that HEAD is for use with a
5366  tool which does not create patches for changes to upstream
5367  .gitignores: but, such patches exist in debian/patches.
5368 END
5369     }
5370     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5371         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5372         quiltify_splitbrain_needed();
5373         progress __
5374             "dgit view: creating patch to represent .gitignore changes";
5375         ensuredir "debian/patches";
5376         my $gipatch = "debian/patches/auto-gitignore";
5377         open GIPATCH, ">>", "$gipatch" or confess "$gipatch: $!";
5378         stat GIPATCH or confess "$gipatch: $!";
5379         fail f_ "%s already exists; but want to create it".
5380                 " to record .gitignore changes",
5381                 $gipatch
5382             if (stat _)[7];
5383         print GIPATCH +(__ <<END).<<ENDU or die "$gipatch: $!";
5384 Subject: Update .gitignore from Debian packaging branch
5385
5386 The Debian packaging git branch contains these updates to the upstream
5387 .gitignore file(s).  This patch is autogenerated, to provide these
5388 updates to users of the official Debian archive view of the package.
5389 END
5390
5391 [dgit ($our_version) update-gitignore]
5392 ---
5393 ENDU
5394         close GIPATCH or die "$gipatch: $!";
5395         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5396             $unapplied, $headref, "--", sort keys %$editedignores;
5397         open SERIES, "+>>", "debian/patches/series" or confess $!;
5398         defined seek SERIES, -1, 2 or $!==EINVAL or confess $!;
5399         my $newline;
5400         defined read SERIES, $newline, 1 or confess $!;
5401         print SERIES "\n" or confess $! unless $newline eq "\n";
5402         print SERIES "auto-gitignore\n" or confess $!;
5403         close SERIES or die  $!;
5404         runcmd @git, qw(add -f -- debian/patches/series), $gipatch;
5405         commit_admin +(__ <<END).<<ENDU
5406 Commit patch to update .gitignore
5407 END
5408
5409 [dgit ($our_version) update-gitignore-quilt-fixup]
5410 ENDU
5411     }
5412
5413     my $dgitview = git_rev_parse 'HEAD';
5414
5415     changedir $maindir;
5416     reflog_cache_insert "refs/$splitbraincache", $cachekey, $dgitview;
5417
5418     changedir "$playground/work";
5419
5420     my $saved = maybe_split_brain_save $headref, $dgitview, __ "converted";
5421     progress f_ "dgit view: created (%s)", $saved;
5422 }
5423
5424 sub quiltify ($$$$) {
5425     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5426
5427     # Quilt patchification algorithm
5428     #
5429     # We search backwards through the history of the main tree's HEAD
5430     # (T) looking for a start commit S whose tree object is identical
5431     # to to the patch tip tree (ie the tree corresponding to the
5432     # current dpkg-committed patch series).  For these purposes
5433     # `identical' disregards anything in debian/ - this wrinkle is
5434     # necessary because dpkg-source treates debian/ specially.
5435     #
5436     # We can only traverse edges where at most one of the ancestors'
5437     # trees differs (in changes outside in debian/).  And we cannot
5438     # handle edges which change .pc/ or debian/patches.  To avoid
5439     # going down a rathole we avoid traversing edges which introduce
5440     # debian/rules or debian/control.  And we set a limit on the
5441     # number of edges we are willing to look at.
5442     #
5443     # If we succeed, we walk forwards again.  For each traversed edge
5444     # PC (with P parent, C child) (starting with P=S and ending with
5445     # C=T) to we do this:
5446     #  - git checkout C
5447     #  - dpkg-source --commit with a patch name and message derived from C
5448     # After traversing PT, we git commit the changes which
5449     # should be contained within debian/patches.
5450
5451     # The search for the path S..T is breadth-first.  We maintain a
5452     # todo list containing search nodes.  A search node identifies a
5453     # commit, and looks something like this:
5454     #  $p = {
5455     #      Commit => $git_commit_id,
5456     #      Child => $c,                          # or undef if P=T
5457     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5458     #      Nontrivial => true iff $p..$c has relevant changes
5459     #  };
5460
5461     my @todo;
5462     my @nots;
5463     my $sref_S;
5464     my $max_work=100;
5465     my %considered; # saves being exponential on some weird graphs
5466
5467     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5468
5469     my $not = sub {
5470         my ($search,$whynot) = @_;
5471         printdebug " search NOT $search->{Commit} $whynot\n";
5472         $search->{Whynot} = $whynot;
5473         push @nots, $search;
5474         no warnings qw(exiting);
5475         next;
5476     };
5477
5478     push @todo, {
5479         Commit => $target,
5480     };
5481
5482     while (@todo) {
5483         my $c = shift @todo;
5484         next if $considered{$c->{Commit}}++;
5485
5486         $not->($c, __ "maximum search space exceeded") if --$max_work <= 0;
5487
5488         printdebug "quiltify investigate $c->{Commit}\n";
5489
5490         # are we done?
5491         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5492             printdebug " search finished hooray!\n";
5493             $sref_S = $c;
5494             last;
5495         }
5496
5497         quiltify_nofix_bail " $c->{Commit}", " (tree object $oldtiptree)";
5498         if ($quilt_mode eq 'smash') {
5499             printdebug " search quitting smash\n";
5500             last;
5501         }
5502
5503         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5504         $not->($c, f_ "has %s not %s", $c_sentinels, $t_sentinels)
5505             if $c_sentinels ne $t_sentinels;
5506
5507         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5508         $commitdata =~ m/\n\n/;
5509         $commitdata =~ $`;
5510         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5511         @parents = map { { Commit => $_, Child => $c } } @parents;
5512
5513         $not->($c, __ "root commit") if !@parents;
5514
5515         foreach my $p (@parents) {
5516             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5517         }
5518         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5519         $not->($c, f_ "merge (%s nontrivial parents)", $ndiffers)
5520             if $ndiffers > 1;
5521
5522         foreach my $p (@parents) {
5523             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5524
5525             my @cmd= (@git, qw(diff-tree -r --name-only),
5526                       $p->{Commit},$c->{Commit},
5527                       qw(-- debian/patches .pc debian/source/format));
5528             my $patchstackchange = cmdoutput @cmd;
5529             if (length $patchstackchange) {
5530                 $patchstackchange =~ s/\n/,/g;
5531                 $not->($p, f_ "changed %s", $patchstackchange);
5532             }
5533
5534             printdebug " search queue P=$p->{Commit} ",
5535                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5536             push @todo, $p;
5537         }
5538     }
5539
5540     if (!$sref_S) {
5541         printdebug "quiltify want to smash\n";
5542
5543         my $abbrev = sub {
5544             my $x = $_[0]{Commit};
5545             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5546             return $x;
5547         };
5548         if ($quilt_mode eq 'linear') {
5549             print STDERR f_
5550                 "\n%s: error: quilt fixup cannot be linear.  Stopped at:\n",
5551                 $us;
5552             my $all_gdr = !!@nots;
5553             foreach my $notp (@nots) {
5554                 my $c = $notp->{Child};
5555                 my $cprange = $abbrev->($notp);
5556                 $cprange .= "..".$abbrev->($c) if $c;
5557                 print STDERR f_ "%s:  %s: %s\n",
5558                     $us, $cprange, $notp->{Whynot};
5559                 $all_gdr &&= $notp->{Child} &&
5560                     (git_cat_file $notp->{Child}{Commit}, 'commit')
5561                     =~ m{^\[git-debrebase(?! split[: ]).*\]$}m;
5562             }
5563             print STDERR "\n";
5564             $failsuggestion =
5565                 [ grep { $_->[0] ne 'quilt-mode' } @$failsuggestion ]
5566                 if $all_gdr;
5567             print STDERR "$us: $_->[1]\n" foreach @$failsuggestion;
5568             fail __
5569  "quilt history linearisation failed.  Search \`quilt fixup' in dgit(7).\n";
5570         } elsif ($quilt_mode eq 'smash') {
5571         } elsif ($quilt_mode eq 'auto') {
5572             progress __ "quilt fixup cannot be linear, smashing...";
5573         } else {
5574             confess "$quilt_mode ?";
5575         }
5576
5577         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5578         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5579         my $ncommits = 3;
5580         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5581
5582         quiltify_dpkg_commit "auto-$version-$target-$time",
5583             (getfield $clogp, 'Maintainer'),
5584             (f_ "Automatically generated patch (%s)\n".
5585              "Last (up to) %s git changes, FYI:\n\n",
5586              $clogp->{Version}, $ncommits).
5587              $msg;
5588         return;
5589     }
5590
5591     progress __ "quiltify linearisation planning successful, executing...";
5592
5593     for (my $p = $sref_S;
5594          my $c = $p->{Child};
5595          $p = $p->{Child}) {
5596         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5597         next unless $p->{Nontrivial};
5598
5599         my $cc = $c->{Commit};
5600
5601         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5602         $commitdata =~ m/\n\n/ or die "$c ?";
5603         $commitdata = $`;
5604         my $msg = $'; #';
5605         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5606         my $author = $1;
5607
5608         my $commitdate = cmdoutput
5609             @git, qw(log -n1 --pretty=format:%aD), $cc;
5610
5611         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5612
5613         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5614         $strip_nls->();
5615
5616         my $title = $1;
5617         my $patchname;
5618         my $patchdir;
5619
5620         my $gbp_check_suitable = sub {
5621             $_ = shift;
5622             my ($what) = @_;
5623
5624             eval {
5625                 die __ "contains unexpected slashes\n" if m{//} || m{/$};
5626                 die __ "contains leading punctuation\n" if m{^\W} || m{/\W};
5627                 die __ "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5628                 die __ "is series file\n" if m{$series_filename_re}o;
5629                 die __ "too long\n" if length > 200;
5630             };
5631             return $_ unless $@;
5632             print STDERR f_
5633                 "quiltifying commit %s: ignoring/dropping Gbp-Pq %s: %s",
5634                 $cc, $what, $@;
5635             return undef;
5636         };
5637
5638         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5639                            gbp-pq-name: \s* )
5640                        (\S+) \s* \n //ixm) {
5641             $patchname = $gbp_check_suitable->($1, 'Name');
5642         }
5643         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5644                            gbp-pq-topic: \s* )
5645                        (\S+) \s* \n //ixm) {
5646             $patchdir = $gbp_check_suitable->($1, 'Topic');
5647         }
5648
5649         $strip_nls->();
5650
5651         if (!defined $patchname) {
5652             $patchname = $title;
5653             $patchname =~ s/[.:]$//;
5654             use Text::Iconv;
5655             eval {
5656                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5657                 my $translitname = $converter->convert($patchname);
5658                 die unless defined $translitname;
5659                 $patchname = $translitname;
5660             };
5661             print STDERR
5662                 +(f_ "dgit: patch title transliteration error: %s", $@)
5663                 if $@;
5664             $patchname =~ y/ A-Z/-a-z/;
5665             $patchname =~ y/-a-z0-9_.+=~//cd;
5666             $patchname =~ s/^\W/x-$&/;
5667             $patchname = substr($patchname,0,40);
5668             $patchname .= ".patch";
5669         }
5670         if (!defined $patchdir) {
5671             $patchdir = '';
5672         }
5673         if (length $patchdir) {
5674             $patchname = "$patchdir/$patchname";
5675         }
5676         if ($patchname =~ m{^(.*)/}) {
5677             mkpath "debian/patches/$1";
5678         }
5679
5680         my $index;
5681         for ($index='';
5682              stat "debian/patches/$patchname$index";
5683              $index++) { }
5684         $!==ENOENT or confess "$patchname$index $!";
5685
5686         runcmd @git, qw(checkout -q), $cc;
5687
5688         # We use the tip's changelog so that dpkg-source doesn't
5689         # produce complaining messages from dpkg-parsechangelog.  None
5690         # of the information dpkg-source gets from the changelog is
5691         # actually relevant - it gets put into the original message
5692         # which dpkg-source provides our stunt editor, and then
5693         # overwritten.
5694         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5695
5696         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5697             "Date: $commitdate\n".
5698             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5699
5700         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5701     }
5702
5703     runcmd @git, qw(checkout -q master);
5704 }
5705
5706 sub build_maybe_quilt_fixup () {
5707     my ($format,$fopts) = get_source_format;
5708     return unless madformat_wantfixup $format;
5709     # sigh
5710
5711     check_for_vendor_patches();
5712
5713     if (quiltmode_splitbrain) {
5714         fail <<END unless access_cfg_tagformats_can_splitbrain;
5715 quilt mode $quilt_mode requires split view so server needs to support
5716  both "new" and "maint" tag formats, but config says it doesn't.
5717 END
5718     }
5719
5720     my $clogp = parsechangelog();
5721     my $headref = git_rev_parse('HEAD');
5722     my $symref = git_get_symref();
5723
5724     if ($quilt_mode eq 'linear'
5725         && !$fopts->{'single-debian-patch'}
5726         && branch_is_gdr($headref)) {
5727         # This is much faster.  It also makes patches that gdr
5728         # likes better for future updates without laundering.
5729         #
5730         # However, it can fail in some casses where we would
5731         # succeed: if there are existing patches, which correspond
5732         # to a prefix of the branch, but are not in gbp/gdr
5733         # format, gdr will fail (exiting status 7), but we might
5734         # be able to figure out where to start linearising.  That
5735         # will be slower so hopefully there's not much to do.
5736         my @cmd = (@git_debrebase,
5737                    qw(--noop-ok -funclean-mixed -funclean-ordering
5738                       make-patches --quiet-would-amend));
5739         # We tolerate soe snags that gdr wouldn't, by default.
5740         if (act_local()) {
5741             debugcmd "+",@cmd;
5742             $!=0; $?=-1;
5743             failedcmd @cmd
5744                 if system @cmd
5745                 and not ($? == 7*256 or
5746                          $? == -1 && $!==ENOENT);
5747         } else {
5748             dryrun_report @cmd;
5749         }
5750         $headref = git_rev_parse('HEAD');
5751     }
5752
5753     prep_ud();
5754     changedir $playground;
5755
5756     my $upstreamversion = upstreamversion $version;
5757
5758     if ($fopts->{'single-debian-patch'}) {
5759         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5760     } else {
5761         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5762     }
5763
5764     changedir $maindir;
5765     runcmd_ordryrun_local
5766         @git, qw(pull --ff-only -q), "$playground/work", qw(master);
5767 }
5768
5769 sub unpack_playtree_mkwork ($) {
5770     my ($headref) = @_;
5771
5772     mkdir "work" or confess $!;
5773     changedir "work";
5774     mktree_in_ud_here();
5775     runcmd @git, qw(reset -q --hard), $headref;
5776 }
5777
5778 sub unpack_playtree_linkorigs ($$) {
5779     my ($upstreamversion, $fn) = @_;
5780     # calls $fn->($leafname);
5781
5782     my $bpd_abs = bpd_abs();
5783     opendir QFD, $bpd_abs or fail "buildproductsdir: $bpd_abs: $!";
5784     while ($!=0, defined(my $b = readdir QFD)) {
5785         my $f = bpd_abs()."/".$b;
5786         {
5787             local ($debuglevel) = $debuglevel-1;
5788             printdebug "QF linkorigs $b, $f ?\n";
5789         }
5790         next unless is_orig_file_of_vsn $b, $upstreamversion;
5791         printdebug "QF linkorigs $b, $f Y\n";
5792         link_ltarget $f, $b or die "$b $!";
5793         $fn->($b);
5794     }
5795     die "$buildproductsdir: $!" if $!;
5796     closedir QFD;
5797 }
5798
5799 sub quilt_fixup_delete_pc () {
5800     runcmd @git, qw(rm -rqf .pc);
5801     commit_admin +(__ <<END).<<ENDU
5802 Commit removal of .pc (quilt series tracking data)
5803 END
5804
5805 [dgit ($our_version) upgrade quilt-remove-pc]
5806 ENDU
5807 }
5808
5809 sub quilt_fixup_singlepatch ($$$) {
5810     my ($clogp, $headref, $upstreamversion) = @_;
5811
5812     progress __ "starting quiltify (single-debian-patch)";
5813
5814     # dpkg-source --commit generates new patches even if
5815     # single-debian-patch is in debian/source/options.  In order to
5816     # get it to generate debian/patches/debian-changes, it is
5817     # necessary to build the source package.
5818
5819     unpack_playtree_linkorigs($upstreamversion, sub { });
5820     unpack_playtree_mkwork($headref);
5821
5822     rmtree("debian/patches");
5823
5824     runcmd @dpkgsource, qw(-b .);
5825     changedir "..";
5826     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5827     rename srcfn("$upstreamversion", "/debian/patches"),
5828         "work/debian/patches"
5829         or $!==ENOENT
5830         or confess "install d/patches: $!";
5831
5832     changedir "work";
5833     commit_quilty_patch();
5834 }
5835
5836 sub quilt_make_fake_dsc ($) {
5837     my ($upstreamversion) = @_;
5838
5839     my $fakeversion="$upstreamversion-~~DGITFAKE";
5840
5841     my $fakedsc=new IO::File 'fake.dsc', '>' or confess $!;
5842     print $fakedsc <<END or confess $!;
5843 Format: 3.0 (quilt)
5844 Source: $package
5845 Version: $fakeversion
5846 Files:
5847 END
5848
5849     my $dscaddfile=sub {
5850         my ($b) = @_;
5851
5852         my $md = new Digest::MD5;
5853
5854         my $fh = new IO::File $b, '<' or die "$b $!";
5855         stat $fh or confess $!;
5856         my $size = -s _;
5857
5858         $md->addfile($fh);
5859         print $fakedsc " ".$md->hexdigest." $size $b\n" or confess $!;
5860     };
5861
5862     unpack_playtree_linkorigs($upstreamversion, $dscaddfile);
5863
5864     my @files=qw(debian/source/format debian/rules
5865                  debian/control debian/changelog);
5866     foreach my $maybe (qw(debian/patches debian/source/options
5867                           debian/tests/control)) {
5868         next unless stat_exists "$maindir/$maybe";
5869         push @files, $maybe;
5870     }
5871
5872     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5873     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C), $maindir, @files;
5874
5875     $dscaddfile->($debtar);
5876     close $fakedsc or confess $!;
5877 }
5878
5879 sub quilt_fakedsc2unapplied ($$) {
5880     my ($headref, $upstreamversion) = @_;
5881     # must be run in the playground
5882     # quilt_make_fake_dsc must have been called
5883
5884     runcmd qw(sh -ec),
5885         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5886
5887     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5888     rename $fakexdir, "fake" or die "$fakexdir $!";
5889
5890     changedir 'fake';
5891
5892     remove_stray_gits(__ "source package");
5893     mktree_in_ud_here();
5894
5895     rmtree '.pc';
5896
5897     rmtree 'debian'; # git checkout commitish paths does not delete!
5898     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5899     my $unapplied=git_add_write_tree();
5900     printdebug "fake orig tree object $unapplied\n";
5901     return $unapplied;
5902 }
5903
5904 sub quilt_check_splitbrain_cache ($$) {
5905     my ($headref, $upstreamversion) = @_;
5906     # Called only if we are in (potentially) split brain mode.
5907     # Called in playground.
5908     # Computes the cache key and looks in the cache.
5909     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5910
5911     my $splitbrain_cachekey;
5912
5913     progress f_
5914  "dgit: split brain (separate dgit view) may be needed (--quilt=%s).",
5915                 $quilt_mode;
5916     # we look in the reflog of dgit-intern/quilt-cache
5917     # we look for an entry whose message is the key for the cache lookup
5918     my @cachekey = (qw(dgit), $our_version);
5919     push @cachekey, $upstreamversion;
5920     push @cachekey, $quilt_mode;
5921     push @cachekey, $headref;
5922
5923     push @cachekey, hashfile('fake.dsc');
5924
5925     my $srcshash = Digest::SHA->new(256);
5926     my %sfs = ( %INC, '$0(dgit)' => $0 );
5927     foreach my $sfk (sort keys %sfs) {
5928         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5929         $srcshash->add($sfk,"  ");
5930         $srcshash->add(hashfile($sfs{$sfk}));
5931         $srcshash->add("\n");
5932     }
5933     push @cachekey, $srcshash->hexdigest();
5934     $splitbrain_cachekey = "@cachekey";
5935
5936     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5937
5938     my $cachehit = reflog_cache_lookup
5939         "refs/$splitbraincache", $splitbrain_cachekey;
5940
5941     if ($cachehit) {
5942         unpack_playtree_mkwork($headref);
5943         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5944         if ($cachehit ne $headref) {
5945             progress f_ "dgit view: found cached (%s)", $saved;
5946             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5947             $split_brain = 1;
5948             return ($cachehit, $splitbrain_cachekey);
5949         }
5950         progress __ "dgit view: found cached, no changes required";
5951         return ($headref, $splitbrain_cachekey);
5952     }
5953
5954     printdebug "splitbrain cache miss\n";
5955     return (undef, $splitbrain_cachekey);
5956 }
5957
5958 sub quilt_fixup_multipatch ($$$) {
5959     my ($clogp, $headref, $upstreamversion) = @_;
5960
5961     progress f_ "examining quilt state (multiple patches, %s mode)",
5962                 $quilt_mode;
5963
5964     # Our objective is:
5965     #  - honour any existing .pc in case it has any strangeness
5966     #  - determine the git commit corresponding to the tip of
5967     #    the patch stack (if there is one)
5968     #  - if there is such a git commit, convert each subsequent
5969     #    git commit into a quilt patch with dpkg-source --commit
5970     #  - otherwise convert all the differences in the tree into
5971     #    a single git commit
5972     #
5973     # To do this we:
5974
5975     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5976     # dgit would include the .pc in the git tree.)  If there isn't
5977     # one, we need to generate one by unpacking the patches that we
5978     # have.
5979     #
5980     # We first look for a .pc in the git tree.  If there is one, we
5981     # will use it.  (This is not the normal case.)
5982     #
5983     # Otherwise need to regenerate .pc so that dpkg-source --commit
5984     # can work.  We do this as follows:
5985     #     1. Collect all relevant .orig from parent directory
5986     #     2. Generate a debian.tar.gz out of
5987     #         debian/{patches,rules,source/format,source/options}
5988     #     3. Generate a fake .dsc containing just these fields:
5989     #          Format Source Version Files
5990     #     4. Extract the fake .dsc
5991     #        Now the fake .dsc has a .pc directory.
5992     # (In fact we do this in every case, because in future we will
5993     # want to search for a good base commit for generating patches.)
5994     #
5995     # Then we can actually do the dpkg-source --commit
5996     #     1. Make a new working tree with the same object
5997     #        store as our main tree and check out the main
5998     #        tree's HEAD.
5999     #     2. Copy .pc from the fake's extraction, if necessary
6000     #     3. Run dpkg-source --commit
6001     #     4. If the result has changes to debian/, then
6002     #          - git add them them
6003     #          - git add .pc if we had a .pc in-tree
6004     #          - git commit
6005     #     5. If we had a .pc in-tree, delete it, and git commit
6006     #     6. Back in the main tree, fast forward to the new HEAD
6007
6008     # Another situation we may have to cope with is gbp-style
6009     # patches-unapplied trees.
6010     #
6011     # We would want to detect these, so we know to escape into
6012     # quilt_fixup_gbp.  However, this is in general not possible.
6013     # Consider a package with a one patch which the dgit user reverts
6014     # (with git revert or the moral equivalent).
6015     #
6016     # That is indistinguishable in contents from a patches-unapplied
6017     # tree.  And looking at the history to distinguish them is not
6018     # useful because the user might have made a confusing-looking git
6019     # history structure (which ought to produce an error if dgit can't
6020     # cope, not a silent reintroduction of an unwanted patch).
6021     #
6022     # So gbp users will have to pass an option.  But we can usually
6023     # detect their failure to do so: if the tree is not a clean
6024     # patches-applied tree, quilt linearisation fails, but the tree
6025     # _is_ a clean patches-unapplied tree, we can suggest that maybe
6026     # they want --quilt=unapplied.
6027     #
6028     # To help detect this, when we are extracting the fake dsc, we
6029     # first extract it with --skip-patches, and then apply the patches
6030     # afterwards with dpkg-source --before-build.  That lets us save a
6031     # tree object corresponding to .origs.
6032
6033     my $splitbrain_cachekey;
6034
6035     quilt_make_fake_dsc($upstreamversion);
6036
6037     if (quiltmode_splitbrain()) {
6038         my $cachehit;
6039         ($cachehit, $splitbrain_cachekey) =
6040             quilt_check_splitbrain_cache($headref, $upstreamversion);
6041         return if $cachehit;
6042     }
6043     my $unapplied=quilt_fakedsc2unapplied($headref, $upstreamversion);
6044
6045     ensuredir '.pc';
6046
6047     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
6048     $!=0; $?=-1;
6049     if (system @bbcmd) {
6050         failedcmd @bbcmd if $? < 0;
6051         fail __ <<END;
6052 failed to apply your git tree's patch stack (from debian/patches/) to
6053  the corresponding upstream tarball(s).  Your source tree and .orig
6054  are probably too inconsistent.  dgit can only fix up certain kinds of
6055  anomaly (depending on the quilt mode).  Please see --quilt= in dgit(1).
6056 END
6057     }
6058
6059     changedir '..';
6060
6061     unpack_playtree_mkwork($headref);
6062
6063     my $mustdeletepc=0;
6064     if (stat_exists ".pc") {
6065         -d _ or die;
6066         progress __ "Tree already contains .pc - will use it then delete it.";
6067         $mustdeletepc=1;
6068     } else {
6069         rename '../fake/.pc','.pc' or confess $!;
6070     }
6071
6072     changedir '../fake';
6073     rmtree '.pc';
6074     my $oldtiptree=git_add_write_tree();
6075     printdebug "fake o+d/p tree object $unapplied\n";
6076     changedir '../work';
6077
6078
6079     # We calculate some guesswork now about what kind of tree this might
6080     # be.  This is mostly for error reporting.
6081
6082     my %editedignores;
6083     my @unrepres;
6084     my $diffbits = {
6085         # H = user's HEAD
6086         # O = orig, without patches applied
6087         # A = "applied", ie orig with H's debian/patches applied
6088         O2H => quiltify_trees_differ($unapplied,$headref,   1,
6089                                      \%editedignores, \@unrepres),
6090         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
6091         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
6092     };
6093
6094     my @dl;
6095     foreach my $b (qw(01 02)) {
6096         foreach my $v (qw(O2H O2A H2A)) {
6097             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
6098         }
6099     }
6100     printdebug "differences \@dl @dl.\n";
6101
6102     progress f_
6103 "%s: base trees orig=%.20s o+d/p=%.20s",
6104               $us, $unapplied, $oldtiptree;
6105     progress f_
6106 "%s: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
6107 "%s: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
6108   $us,                      $dl[0], $dl[1],              $dl[3], $dl[4],
6109   $us,                          $dl[2],                     $dl[5];
6110
6111     if (@unrepres) {
6112         print STDERR f_ "dgit:  cannot represent change: %s: %s\n",
6113                         $_->[1], $_->[0]
6114             foreach @unrepres;
6115         forceable_fail [qw(unrepresentable)], __ <<END;
6116 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
6117 END
6118     }
6119
6120     my @failsuggestion;
6121     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
6122         push @failsuggestion, [ 'unapplied', __
6123  "This might be a patches-unapplied branch." ];
6124     } elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
6125         push @failsuggestion, [ 'applied', __
6126  "This might be a patches-applied branch." ];
6127     }
6128     push @failsuggestion, [ 'quilt-mode', __
6129  "Maybe you need one of --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?" ];
6130
6131     push @failsuggestion, [ 'gitattrs', __
6132  "Warning: Tree has .gitattributes.  See GITATTRIBUTES in dgit(7)." ]
6133         if stat_exists '.gitattributes';
6134
6135     push @failsuggestion, [ 'origs', __
6136  "Maybe orig tarball(s) are not identical to git representation?" ];
6137
6138     if (quiltmode_splitbrain()) {
6139         quiltify_splitbrain($clogp, $unapplied, $headref, $oldtiptree,
6140                             $diffbits, \%editedignores,
6141                             $splitbrain_cachekey);
6142         return;
6143     }
6144
6145     progress f_ "starting quiltify (multiple patches, %s mode)", $quilt_mode;
6146     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
6147
6148     if (!open P, '>>', ".pc/applied-patches") {
6149         $!==&ENOENT or confess $!;
6150     } else {
6151         close P;
6152     }
6153
6154     commit_quilty_patch();
6155
6156     if ($mustdeletepc) {
6157         quilt_fixup_delete_pc();
6158     }
6159 }
6160
6161 sub quilt_fixup_editor () {
6162     my $descfn = $ENV{$fakeeditorenv};
6163     my $editing = $ARGV[$#ARGV];
6164     open I1, '<', $descfn or confess "$descfn: $!";
6165     open I2, '<', $editing or confess "$editing: $!";
6166     unlink $editing or confess "$editing: $!";
6167     open O, '>', $editing or confess "$editing: $!";
6168     while (<I1>) { print O or confess $!; } I1->error and confess $!;
6169     my $copying = 0;
6170     while (<I2>) {
6171         $copying ||= m/^\-\-\- /;
6172         next unless $copying;
6173         print O or confess $!;
6174     }
6175     I2->error and confess $!;
6176     close O or die $1;
6177     finish 0;
6178 }
6179
6180 sub maybe_apply_patches_dirtily () {
6181     return unless $quilt_mode =~ m/gbp|unapplied/;
6182     print STDERR __ <<END or confess $!;
6183
6184 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
6185 dgit: Have to apply the patches - making the tree dirty.
6186 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
6187
6188 END
6189     $patches_applied_dirtily = 01;
6190     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
6191     runcmd qw(dpkg-source --before-build .);
6192 }
6193
6194 sub maybe_unapply_patches_again () {
6195     progress __ "dgit: Unapplying patches again to tidy up the tree."
6196         if $patches_applied_dirtily;
6197     runcmd qw(dpkg-source --after-build .)
6198         if $patches_applied_dirtily & 01;
6199     rmtree '.pc'
6200         if $patches_applied_dirtily & 02;
6201     $patches_applied_dirtily = 0;
6202 }
6203
6204 #----- other building -----
6205
6206 sub clean_tree_check_git ($$) {
6207     my ($honour_ignores, $message) = @_;
6208     my @cmd = (@git, qw(clean -dn));
6209     push @cmd, qw(-x) unless $honour_ignores;
6210     my $leftovers = cmdoutput @cmd;
6211     if (length $leftovers) {
6212         print STDERR $leftovers, "\n" or confess $!;
6213         fail $message;
6214     }
6215 }
6216
6217 sub clean_tree_check_git_wd ($) {
6218     my ($message) = @_;
6219     return if $cleanmode =~ m{no-check};
6220     return if $patches_applied_dirtily; # yuk
6221     clean_tree_check_git +($cleanmode !~ m{all-check}),
6222                           (f_ <<END, $message);
6223 %s
6224 If this is just missing .gitignore entries, use a different clean
6225 mode, eg --clean=dpkg-source,no-check (-wdu/-wddu) to ignore them
6226 or --clean=git (-wg/-wgf) to use \`git clean' instead.
6227 END
6228 }
6229
6230 sub clean_tree_check () {
6231     # Not yet fully implemented.
6232     # This function needs to not care about modified but tracked files.
6233     # That was done by check_not_dirty, and by now we may have run
6234     # the rules clean target which might modify tracked files (!)
6235     if ($cleanmode =~ m{^check}) {
6236         clean_tree_check_git +($cleanmode =~ m{ignores}), __
6237  "tree contains uncommitted files and --clean=check specified";
6238     } elsif ($cleanmode =~ m{^dpkg-source}) {
6239         clean_tree_check_git_wd __
6240  "tree contains uncommitted files (NB dgit didn't run rules clean)";
6241     } elsif ($cleanmode =~ m{^git}) {
6242         # If we were actually cleaning these files would be summarily
6243         # deleted.  Since we're not, and not using the working tree
6244         # anyway, we can just ignore them - nothing will use them.
6245     } elsif ($cleanmode eq 'none') {
6246     } else {
6247         confess "$cleanmode ?";
6248     }
6249 }
6250
6251 sub clean_tree () {
6252     # We always clean the tree ourselves, rather than leave it to the
6253     # builder (dpkg-source, or soemthing which calls dpkg-source).
6254     if ($cleanmode =~ m{^dpkg-source}) {
6255         my @cmd = @dpkgbuildpackage;
6256         push @cmd, qw(-d) if $cleanmode =~ m{^dpkg-source-d};
6257         push @cmd, qw(-T clean);
6258         maybe_apply_patches_dirtily();
6259         runcmd_ordryrun_local @cmd;
6260         clean_tree_check_git_wd __
6261  "tree contains uncommitted files (after running rules clean)";
6262     } elsif ($cleanmode eq 'git') {
6263         runcmd_ordryrun_local @git, qw(clean -xdf);
6264     } elsif ($cleanmode eq 'git-ff') {
6265         runcmd_ordryrun_local @git, qw(clean -xdff);
6266     } elsif ($cleanmode =~ m{^check}) {
6267         clean_tree_check();
6268     } elsif ($cleanmode eq 'none') {
6269     } else {
6270         confess "$cleanmode ?";
6271     }
6272 }
6273
6274 sub cmd_clean () {
6275     badusage __ "clean takes no additional arguments" if @ARGV;
6276     notpushing();
6277     clean_tree();
6278     maybe_unapply_patches_again();
6279 }
6280
6281 # return values from massage_dbp_args are one or both of these flags
6282 sub WANTSRC_SOURCE  () { 01; } # caller should build source (separately)
6283 sub WANTSRC_BUILDER () { 02; } # caller should run dpkg-buildpackage
6284
6285 sub build_or_push_prep_early () {
6286     our $build_or_push_prep_early_done //= 0;
6287     return if $build_or_push_prep_early_done++;
6288     badusage f_ "-p is not allowed with dgit %s", $subcommand
6289         if defined $package;
6290     my $clogp = parsechangelog();
6291     $isuite = getfield $clogp, 'Distribution';
6292     $package = getfield $clogp, 'Source';
6293     $version = getfield $clogp, 'Version';
6294     $dscfn = dscfn($version);
6295 }
6296
6297 sub build_prep_early () {
6298     build_or_push_prep_early();
6299     notpushing();
6300     check_not_dirty();
6301 }
6302
6303 sub build_prep ($) {
6304     my ($wantsrc) = @_;
6305     build_prep_early();
6306     if (!building_source_in_playtree() || ($wantsrc & WANTSRC_BUILDER)) {
6307         # Clean the tree because we're going to use the contents of
6308         # $maindir.  (We trying to include dirty changes in the source
6309         # package, or we are running the builder in $maindir.)
6310         clean_tree();
6311     } else {
6312         # We don't actually need to do anything in $maindir, but we
6313         # should do some kind of cleanliness check because (i) the
6314         # user may have forgotten a `git add', and (ii) if the user
6315         # said -wc we should still do the check.
6316         clean_tree_check();
6317     }
6318     build_maybe_quilt_fixup();
6319     if ($rmchanges) {
6320         my $pat = changespat $version;
6321         foreach my $f (glob "$buildproductsdir/$pat") {
6322             if (act_local()) {
6323                 unlink $f or
6324                     fail f_ "remove old changes file %s: %s", $f, $!;
6325             } else {
6326                 progress f_ "would remove %s", $f;
6327             }
6328         }
6329     }
6330 }
6331
6332 sub changesopts_initial () {
6333     my @opts =@changesopts[1..$#changesopts];
6334 }
6335
6336 sub changesopts_version () {
6337     if (!defined $changes_since_version) {
6338         my @vsns;
6339         unless (eval {
6340             @vsns = archive_query('archive_query');
6341             my @quirk = access_quirk();
6342             if ($quirk[0] eq 'backports') {
6343                 local $isuite = $quirk[2];
6344                 local $csuite;
6345                 canonicalise_suite();
6346                 push @vsns, archive_query('archive_query');
6347             }
6348             1;
6349         }) {
6350             print STDERR $@;
6351             fail __
6352  "archive query failed (queried because --since-version not specified)";
6353         }
6354         if (@vsns) {
6355             @vsns = map { $_->[0] } @vsns;
6356             @vsns = sort { -version_compare($a, $b) } @vsns;
6357             $changes_since_version = $vsns[0];
6358             progress f_ "changelog will contain changes since %s", $vsns[0];
6359         } else {
6360             $changes_since_version = '_';
6361             progress __ "package seems new, not specifying -v<version>";
6362         }
6363     }
6364     if ($changes_since_version ne '_') {
6365         return ("-v$changes_since_version");
6366     } else {
6367         return ();
6368     }
6369 }
6370
6371 sub changesopts () {
6372     return (changesopts_initial(), changesopts_version());
6373 }
6374
6375 sub massage_dbp_args ($;$) {
6376     my ($cmd,$xargs) = @_;
6377     # Since we split the source build out so we can do strange things
6378     # to it, massage the arguments to dpkg-buildpackage so that the
6379     # main build doessn't build source (or add an argument to stop it
6380     # building source by default).
6381     debugcmd '#massaging#', @$cmd if $debuglevel>1;
6382     # -nc has the side effect of specifying -b if nothing else specified
6383     # and some combinations of -S, -b, et al, are errors, rather than
6384     # later simply overriding earlie.  So we need to:
6385     #  - search the command line for these options
6386     #  - pick the last one
6387     #  - perhaps add our own as a default
6388     #  - perhaps adjust it to the corresponding non-source-building version
6389     my $dmode = '-F';
6390     foreach my $l ($cmd, $xargs) {
6391         next unless $l;
6392         @$l = grep { !(m/^-[SgGFABb]$|^--build=/s and $dmode=$_) } @$l;
6393     }
6394     push @$cmd, '-nc';
6395 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
6396     my $r = WANTSRC_BUILDER;
6397     printdebug "massage split $dmode.\n";
6398     if ($dmode =~ s/^--build=//) {
6399         $r = 0;
6400         my @d = split /,/, $dmode;
6401         $r |= WANTSRC_SOURCE  if grep { s/^full$/binary/ } @d;
6402         $r |= WANTSRC_SOURCE  if grep { s/^source$// } @d;
6403         $r |= WANTSRC_BUILDER if grep { m/./ } @d;
6404         fail __ "Wanted to build nothing!" unless $r;
6405         $dmode = '--build='. join ',', grep m/./, @d;
6406     } else {
6407         $r =
6408           $dmode =~ m/[S]/     ?  WANTSRC_SOURCE :
6409           $dmode =~ y/gGF/ABb/ ?  WANTSRC_SOURCE | WANTSRC_BUILDER :
6410           $dmode =~ m/[ABb]/   ?                   WANTSRC_BUILDER :
6411           confess "$dmode ?";
6412     }
6413     printdebug "massage done $r $dmode.\n";
6414     push @$cmd, $dmode;
6415 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
6416     return $r;
6417 }
6418
6419 sub in_bpd (&) {
6420     my ($fn) = @_;
6421     my $wasdir = must_getcwd();
6422     changedir $buildproductsdir;
6423     $fn->();
6424     changedir $wasdir;
6425 }
6426
6427 # this sub must run with CWD=$buildproductsdir (eg in in_bpd)
6428 sub postbuild_mergechanges ($) {
6429     my ($msg_if_onlyone) = @_;
6430     # If there is only one .changes file, fail with $msg_if_onlyone,
6431     # or if that is undef, be a no-op.
6432     # Returns the changes file to report to the user.
6433     my $pat = changespat $version;
6434     my @changesfiles = grep { !m/_multi\.changes/ } glob $pat;
6435     @changesfiles = sort {
6436         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
6437             or $a cmp $b
6438     } @changesfiles;
6439     my $result;
6440     if (@changesfiles==1) {
6441         fail +(f_ <<END, "@changesfiles").$msg_if_onlyone
6442 only one changes file from build (%s)
6443 END
6444             if defined $msg_if_onlyone;
6445         $result = $changesfiles[0];
6446     } elsif (@changesfiles==2) {
6447         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
6448         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
6449             fail f_ "%s found in binaries changes file %s", $l, $binchanges
6450                 if $l =~ m/\.dsc$/;
6451         }
6452         runcmd_ordryrun_local @mergechanges, @changesfiles;
6453         my $multichanges = changespat $version,'multi';
6454         if (act_local()) {
6455             stat_exists $multichanges or fail f_
6456                 "%s unexpectedly not created by build", $multichanges;
6457             foreach my $cf (glob $pat) {
6458                 next if $cf eq $multichanges;
6459                 rename "$cf", "$cf.inmulti" or fail f_
6460                     "install new changes %s\{,.inmulti}: %s", $cf, $!;
6461             }
6462         }
6463         $result = $multichanges;
6464     } else {
6465         fail f_ "wrong number of different changes files (%s)",
6466                 "@changesfiles";
6467     }
6468     printdone f_ "build successful, results in %s\n", $result
6469         or confess $!;
6470 }
6471
6472 sub midbuild_checkchanges () {
6473     my $pat = changespat $version;
6474     return if $rmchanges;
6475     my @unwanted = map { s#.*/##; $_; } glob "$bpd_glob/$pat";
6476     @unwanted = grep {
6477         $_ ne changespat $version,'source' and
6478         $_ ne changespat $version,'multi'
6479     } @unwanted;
6480     fail +(f_ <<END, $pat, "@unwanted")
6481 changes files other than source matching %s already present; building would result in ambiguity about the intended results.
6482 Suggest you delete %s.
6483 END
6484         if @unwanted;
6485 }
6486
6487 sub midbuild_checkchanges_vanilla ($) {
6488     my ($wantsrc) = @_;
6489     midbuild_checkchanges() if $wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER);
6490 }
6491
6492 sub postbuild_mergechanges_vanilla ($) {
6493     my ($wantsrc) = @_;
6494     if ($wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER)) {
6495         in_bpd {
6496             postbuild_mergechanges(undef);
6497         };
6498     } else {
6499         printdone __ "build successful\n";
6500     }
6501 }
6502
6503 sub cmd_build {
6504     build_prep_early();
6505     $buildproductsdir eq '..' or print STDERR +(f_ <<END, $us, $us);
6506 %s: warning: build-products-dir set, but not supported by dpkg-buildpackage
6507 %s: warning: build-products-dir will be ignored; files will go to ..
6508 END
6509     $buildproductsdir = '..';
6510     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6511     my $wantsrc = massage_dbp_args \@dbp;
6512     build_prep($wantsrc);
6513     if ($wantsrc & WANTSRC_SOURCE) {
6514         build_source();
6515         midbuild_checkchanges_vanilla $wantsrc;
6516     }
6517     if ($wantsrc & WANTSRC_BUILDER) {
6518         push @dbp, changesopts_version();
6519         maybe_apply_patches_dirtily();
6520         runcmd_ordryrun_local @dbp;
6521     }
6522     maybe_unapply_patches_again();
6523     postbuild_mergechanges_vanilla $wantsrc;
6524 }
6525
6526 sub pre_gbp_build {
6527     $quilt_mode //= 'gbp';
6528 }
6529
6530 sub cmd_gbp_build {
6531     build_prep_early();
6532
6533     # gbp can make .origs out of thin air.  In my tests it does this
6534     # even for a 1.0 format package, with no origs present.  So I
6535     # guess it keys off just the version number.  We don't know
6536     # exactly what .origs ought to exist, but let's assume that we
6537     # should run gbp if: the version has an upstream part and the main
6538     # orig is absent.
6539     my $upstreamversion = upstreamversion $version;
6540     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6541     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "$bpd_glob/$origfnpat");
6542
6543     if ($gbp_make_orig) {
6544         clean_tree();
6545         $cleanmode = 'none'; # don't do it again
6546     }
6547
6548     my @dbp = @dpkgbuildpackage;
6549
6550     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6551
6552     if (!length $gbp_build[0]) {
6553         if (length executable_on_path('git-buildpackage')) {
6554             $gbp_build[0] = qw(git-buildpackage);
6555         } else {
6556             $gbp_build[0] = 'gbp buildpackage';
6557         }
6558     }
6559     my @cmd = opts_opt_multi_cmd [], @gbp_build;
6560
6561     push @cmd, (qw(-us -uc --git-no-sign-tags),
6562                 "--git-builder=".(shellquote @dbp));
6563
6564     if ($gbp_make_orig) {
6565         my $priv = dgit_privdir();
6566         my $ok = "$priv/origs-gen-ok";
6567         unlink $ok or $!==&ENOENT or confess $!;
6568         my @origs_cmd = @cmd;
6569         push @origs_cmd, qw(--git-cleaner=true);
6570         push @origs_cmd, "--git-prebuild=".
6571             "touch ".(shellquote $ok)." ".(shellquote "$priv/no-such-dir/ok");
6572         push @origs_cmd, @ARGV;
6573         if (act_local()) {
6574             debugcmd @origs_cmd;
6575             system @origs_cmd;
6576             do { local $!; stat_exists $ok; }
6577                 or failedcmd @origs_cmd;
6578         } else {
6579             dryrun_report @origs_cmd;
6580         }
6581     }
6582
6583     build_prep($wantsrc);
6584     if ($wantsrc & WANTSRC_SOURCE) {
6585         build_source();
6586         midbuild_checkchanges_vanilla $wantsrc;
6587     } else {
6588         push @cmd, '--git-cleaner=true';
6589     }
6590     maybe_unapply_patches_again();
6591     if ($wantsrc & WANTSRC_BUILDER) {
6592         push @cmd, changesopts();
6593         runcmd_ordryrun_local @cmd, @ARGV;
6594     }
6595     postbuild_mergechanges_vanilla $wantsrc;
6596 }
6597 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6598
6599 sub building_source_in_playtree {
6600     # If $includedirty, we have to build the source package from the
6601     # working tree, not a playtree, so that uncommitted changes are
6602     # included (copying or hardlinking them into the playtree could
6603     # cause trouble).
6604     #
6605     # Note that if we are building a source package in split brain
6606     # mode we do not support including uncommitted changes, because
6607     # that makes quilt fixup too hard.  I.e. ($split_brain && (dgit is
6608     # building a source package)) => !$includedirty
6609     return !$includedirty;
6610 }
6611
6612 sub build_source {
6613     $sourcechanges = changespat $version,'source';
6614     if (act_local()) {
6615         unlink "$buildproductsdir/$sourcechanges" or $!==ENOENT
6616             or fail f_ "remove %s: %s", $sourcechanges, $!;
6617     }
6618     my @cmd = (@dpkgsource, qw(-b --));
6619     my $leafdir;
6620     if (building_source_in_playtree()) {
6621         $leafdir = 'work';
6622         my $headref = git_rev_parse('HEAD');
6623         # If we are in split brain, there is already a playtree with
6624         # the thing we should package into a .dsc (thanks to quilt
6625         # fixup).  If not, make a playtree
6626         prep_ud() unless $split_brain;
6627         changedir $playground;
6628         unless ($split_brain) {
6629             my $upstreamversion = upstreamversion $version;
6630             unpack_playtree_linkorigs($upstreamversion, sub { });
6631             unpack_playtree_mkwork($headref);
6632             changedir '..';
6633         }
6634     } else {
6635         $leafdir = basename $maindir;
6636
6637         if ($buildproductsdir ne '..') {
6638             # Well, we are going to run dpkg-source -b which consumes
6639             # origs from .. and generates output there.  To make this
6640             # work when the bpd is not .. , we would have to (i) link
6641             # origs from bpd to .. , (ii) check for files that
6642             # dpkg-source -b would/might overwrite, and afterwards
6643             # (iii) move all the outputs back to the bpd (iv) except
6644             # for the origs which should be deleted from .. if they
6645             # weren't there beforehand.  And if there is an error and
6646             # we don't run to completion we would necessarily leave a
6647             # mess.  This is too much.  The real way to fix this
6648             # is for dpkg-source to have bpd support.
6649             confess unless $includedirty;
6650             fail __
6651  "--include-dirty not supported with --build-products-dir, sorry";
6652         }
6653
6654         changedir '..';
6655     }
6656     runcmd_ordryrun_local @cmd, $leafdir;
6657
6658     changedir $leafdir;
6659     runcmd_ordryrun_local qw(sh -ec),
6660       'exec >../$1; shift; exec "$@"','x', $sourcechanges,
6661       @dpkggenchanges, qw(-S), changesopts();
6662     changedir '..';
6663
6664     printdebug "moving $dscfn, $sourcechanges, etc. to ".bpd_abs()."\n";
6665     $dsc = parsecontrol($dscfn, "source package");
6666
6667     my $mv = sub {
6668         my ($why, $l) = @_;
6669         printdebug " renaming ($why) $l\n";
6670         rename_link_xf 0, "$l", bpd_abs()."/$l"
6671             or fail f_ "put in place new built file (%s): %s", $l, $@;
6672     };
6673     foreach my $l (split /\n/, getfield $dsc, 'Files') {
6674         $l =~ m/\S+$/ or next;
6675         $mv->('Files', $&);
6676     }
6677     $mv->('dsc', $dscfn);
6678     $mv->('changes', $sourcechanges);
6679
6680     changedir $maindir;
6681 }
6682
6683 sub cmd_build_source {
6684     badusage __ "build-source takes no additional arguments" if @ARGV;
6685     build_prep(WANTSRC_SOURCE);
6686     build_source();
6687     maybe_unapply_patches_again();
6688     printdone f_ "source built, results in %s and %s",
6689                  $dscfn, $sourcechanges;
6690 }
6691
6692 sub cmd_push_source {
6693     prep_push();
6694     fail __
6695         "dgit push-source: --include-dirty/--ignore-dirty does not make".
6696         "sense with push-source!"
6697         if $includedirty;
6698     build_maybe_quilt_fixup();
6699     if ($changesfile) {
6700         my $changes = parsecontrol("$buildproductsdir/$changesfile",
6701                                    __ "source changes file");
6702         unless (test_source_only_changes($changes)) {
6703             fail __ "user-specified changes file is not source-only";
6704         }
6705     } else {
6706         # Building a source package is very fast, so just do it
6707         build_source();
6708         confess "er, patches are applied dirtily but shouldn't be.."
6709             if $patches_applied_dirtily;
6710         $changesfile = $sourcechanges;
6711     }
6712     dopush();
6713 }
6714
6715 sub binary_builder {
6716     my ($bbuilder, $pbmc_msg, @args) = @_;
6717     build_prep(WANTSRC_SOURCE);
6718     build_source();
6719     midbuild_checkchanges();
6720     in_bpd {
6721         if (act_local()) {
6722             stat_exists $dscfn or fail f_
6723                 "%s (in build products dir): %s", $dscfn, $!;
6724             stat_exists $sourcechanges or fail f_
6725                 "%s (in build products dir): %s", $sourcechanges, $!;
6726         }
6727         runcmd_ordryrun_local @$bbuilder, @args;
6728     };
6729     maybe_unapply_patches_again();
6730     in_bpd {
6731         postbuild_mergechanges($pbmc_msg);
6732     };
6733 }
6734
6735 sub cmd_sbuild {
6736     build_prep_early();
6737     binary_builder(\@sbuild, (__ <<END), qw(-d), $isuite, @ARGV, $dscfn);
6738 perhaps you need to pass -A ?  (sbuild's default is to build only
6739 arch-specific binaries; dgit 1.4 used to override that.)
6740 END
6741 }
6742
6743 sub pbuilder ($) {
6744     my ($pbuilder) = @_;
6745     build_prep_early();
6746     # @ARGV is allowed to contain only things that should be passed to
6747     # pbuilder under debbuildopts; just massage those
6748     my $wantsrc = massage_dbp_args \@ARGV;
6749     fail __
6750         "you asked for a builder but your debbuildopts didn't ask for".
6751         " any binaries -- is this really what you meant?"
6752         unless $wantsrc & WANTSRC_BUILDER;
6753     fail __
6754         "we must build a .dsc to pass to the builder but your debbuiltopts".
6755         " forbids the building of a source package; cannot continue"
6756       unless $wantsrc & WANTSRC_SOURCE;
6757     # We do not want to include the verb "build" in @pbuilder because
6758     # the user can customise @pbuilder and they shouldn't be required
6759     # to include "build" in their customised value.  However, if the
6760     # user passes any additional args to pbuilder using the dgit
6761     # option --pbuilder:foo, such args need to come after the "build"
6762     # verb.  opts_opt_multi_cmd does all of that.
6763     binary_builder([opts_opt_multi_cmd ["build"], @$pbuilder], undef,
6764                    qw(--debbuildopts), "@ARGV", qw(--distribution), $isuite,
6765                    $dscfn);
6766 }
6767
6768 sub cmd_pbuilder {
6769     pbuilder(\@pbuilder);
6770 }
6771
6772 sub cmd_cowbuilder {
6773     pbuilder(\@cowbuilder);
6774 }
6775
6776 sub cmd_quilt_fixup {
6777     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6778     build_prep_early();
6779     clean_tree();
6780     build_maybe_quilt_fixup();
6781 }
6782
6783 sub cmd_print_unapplied_treeish {
6784     badusage __ "incorrect arguments to dgit print-unapplied-treeish"
6785         if @ARGV;
6786     my $headref = git_rev_parse('HEAD');
6787     my $clogp = commit_getclogp $headref;
6788     $package = getfield $clogp, 'Source';
6789     $version = getfield $clogp, 'Version';
6790     $isuite = getfield $clogp, 'Distribution';
6791     $csuite = $isuite; # we want this to be offline!
6792     notpushing();
6793
6794     prep_ud();
6795     changedir $playground;
6796     my $uv = upstreamversion $version;
6797     quilt_make_fake_dsc($uv);
6798     my $u = quilt_fakedsc2unapplied($headref, $uv);
6799     print $u, "\n" or confess $!;
6800 }
6801
6802 sub import_dsc_result {
6803     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6804     my @cmd = (git_update_ref_cmd $what_log, $dstref, $newhash);
6805     runcmd @cmd;
6806     check_gitattrs($newhash, __ "source tree");
6807
6808     progress f_ "dgit: import-dsc: %s", $what_msg;
6809 }
6810
6811 sub cmd_import_dsc {
6812     my $needsig = 0;
6813
6814     while (@ARGV) {
6815         last unless $ARGV[0] =~ m/^-/;
6816         $_ = shift @ARGV;
6817         last if m/^--?$/;
6818         if (m/^--require-valid-signature$/) {
6819             $needsig = 1;
6820         } else {
6821             badusage f_ "unknown dgit import-dsc sub-option \`%s'", $_;
6822         }
6823     }
6824
6825     badusage __ "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH"
6826         unless @ARGV==2;
6827     my ($dscfn, $dstbranch) = @ARGV;
6828
6829     badusage __ "dry run makes no sense with import-dsc"
6830         unless act_local();
6831
6832     my $force = $dstbranch =~ s/^\+//   ? +1 :
6833                 $dstbranch =~ s/^\.\.// ? -1 :
6834                                            0;
6835     my $info = $force ? " $&" : '';
6836     $info = "$dscfn$info";
6837
6838     my $specbranch = $dstbranch;
6839     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6840     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6841
6842     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6843     my $chead = cmdoutput_errok @symcmd;
6844     defined $chead or $?==256 or failedcmd @symcmd;
6845
6846     fail f_ "%s is checked out - will not update it", $dstbranch
6847         if defined $chead and $chead eq $dstbranch;
6848
6849     my $oldhash = git_get_ref $dstbranch;
6850
6851     open D, "<", $dscfn or fail f_ "open import .dsc (%s): %s", $dscfn, $!;
6852     $dscdata = do { local $/ = undef; <D>; };
6853     D->error and fail f_ "read %s: %s", $dscfn, $!;
6854     close C;
6855
6856     # we don't normally need this so import it here
6857     use Dpkg::Source::Package;
6858     my $dp = new Dpkg::Source::Package filename => $dscfn,
6859         require_valid_signature => $needsig;
6860     {
6861         local $SIG{__WARN__} = sub {
6862             print STDERR $_[0];
6863             return unless $needsig;
6864             fail __ "import-dsc signature check failed";
6865         };
6866         if (!$dp->is_signed()) {
6867             warn f_ "%s: warning: importing unsigned .dsc\n", $us;
6868         } else {
6869             my $r = $dp->check_signature();
6870             confess "->check_signature => $r" if $needsig && $r;
6871         }
6872     }
6873
6874     parse_dscdata();
6875
6876     $package = getfield $dsc, 'Source';
6877
6878     parse_dsc_field($dsc, __ "Dgit metadata in .dsc")
6879         unless forceing [qw(import-dsc-with-dgit-field)];
6880     parse_dsc_field_def_dsc_distro();
6881
6882     $isuite = 'DGIT-IMPORT-DSC';
6883     $idistro //= $dsc_distro;
6884
6885     notpushing();
6886
6887     if (defined $dsc_hash) {
6888         progress __
6889             "dgit: import-dsc of .dsc with Dgit field, using git hash";
6890         resolve_dsc_field_commit undef, undef;
6891     }
6892     if (defined $dsc_hash) {
6893         my @cmd = (qw(sh -ec),
6894                    "echo $dsc_hash | git cat-file --batch-check");
6895         my $objgot = cmdoutput @cmd;
6896         if ($objgot =~ m#^\w+ missing\b#) {
6897             fail f_ <<END, $dsc_hash
6898 .dsc contains Dgit field referring to object %s
6899 Your git tree does not have that object.  Try `git fetch' from a
6900 plausible server (browse.dgit.d.o? salsa?), and try the import-dsc again.
6901 END
6902         }
6903         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6904             if ($force > 0) {
6905                 progress __ "Not fast forward, forced update.";
6906             } else {
6907                 fail f_ "Not fast forward to %s", $dsc_hash;
6908             }
6909         }
6910         import_dsc_result $dstbranch, $dsc_hash,
6911             "dgit import-dsc (Dgit): $info",
6912             f_ "updated git ref %s", $dstbranch;
6913         return 0;
6914     }
6915
6916     fail f_ <<END, $dstbranch, $specbranch, $specbranch
6917 Branch %s already exists
6918 Specify ..%s for a pseudo-merge, binding in existing history
6919 Specify  +%s to overwrite, discarding existing history
6920 END
6921         if $oldhash && !$force;
6922
6923     my @dfi = dsc_files_info();
6924     foreach my $fi (@dfi) {
6925         my $f = $fi->{Filename};
6926         my $here = "$buildproductsdir/$f";
6927         if (lstat $here) {
6928             next if stat $here;
6929             fail f_ "lstat %s works but stat gives %s !", $here, $!;
6930         }
6931         fail f_ "stat %s: %s", $here, $! unless $! == ENOENT;
6932         my $there = $dscfn;
6933         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6934             $there = $';
6935         } elsif ($dscfn =~ m#^/#) {
6936             $there = $dscfn;
6937         } else {
6938             fail f_
6939                 "cannot import %s which seems to be inside working tree!",
6940                 $dscfn;
6941         }
6942         $there =~ s#/+[^/]+$## or fail f_
6943             "import %s requires .../%s, but it does not exist",
6944             $dscfn, $f;
6945         $there .= "/$f";
6946         my $test = $there =~ m{^/} ? $there : "../$there";
6947         stat $test or fail f_
6948             "import %s requires %s, but: %s", $dscfn, $test, $!;
6949         symlink $there, $here or fail f_
6950             "symlink %s to %s: %s", $there, $here, $!;
6951         progress f_ "made symlink %s -> %s", $here, $there;
6952 #       print STDERR Dumper($fi);
6953     }
6954     my @mergeinputs = generate_commits_from_dsc();
6955     die unless @mergeinputs == 1;
6956
6957     my $newhash = $mergeinputs[0]{Commit};
6958
6959     if ($oldhash) {
6960         if ($force > 0) {
6961             progress __
6962                 "Import, forced update - synthetic orphan git history.";
6963         } elsif ($force < 0) {
6964             progress __ "Import, merging.";
6965             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6966             my $version = getfield $dsc, 'Version';
6967             my $clogp = commit_getclogp $newhash;
6968             my $authline = clogp_authline $clogp;
6969             $newhash = make_commit_text <<ENDU
6970 tree $tree
6971 parent $newhash
6972 parent $oldhash
6973 author $authline
6974 committer $authline
6975
6976 ENDU
6977                 .(f_ <<END, $package, $version, $dstbranch);
6978 Merge %s (%s) import into %s
6979 END
6980         } else {
6981             die; # caught earlier
6982         }
6983     }
6984
6985     import_dsc_result $dstbranch, $newhash,
6986         "dgit import-dsc: $info",
6987         f_ "results are in git ref %s", $dstbranch;
6988 }
6989
6990 sub pre_archive_api_query () {
6991     not_necessarily_a_tree();
6992 }
6993 sub cmd_archive_api_query {
6994     badusage __ "need only 1 subpath argument" unless @ARGV==1;
6995     my ($subpath) = @ARGV;
6996     local $isuite = 'DGIT-API-QUERY-CMD';
6997     my @cmd = archive_api_query_cmd($subpath);
6998     push @cmd, qw(-f);
6999     debugcmd ">",@cmd;
7000     exec @cmd or fail f_ "exec curl: %s\n", $!;
7001 }
7002
7003 sub repos_server_url () {
7004     $package = '_dgit-repos-server';
7005     local $access_forpush = 1;
7006     local $isuite = 'DGIT-REPOS-SERVER';
7007     my $url = access_giturl();
7008 }
7009
7010 sub pre_clone_dgit_repos_server () {
7011     not_necessarily_a_tree();
7012 }
7013 sub cmd_clone_dgit_repos_server {
7014     badusage __ "need destination argument" unless @ARGV==1;
7015     my ($destdir) = @ARGV;
7016     my $url = repos_server_url();
7017     my @cmd = (@git, qw(clone), $url, $destdir);
7018     debugcmd ">",@cmd;
7019     exec @cmd or fail f_ "exec git clone: %s\n", $!;
7020 }
7021
7022 sub pre_print_dgit_repos_server_source_url () {
7023     not_necessarily_a_tree();
7024 }
7025 sub cmd_print_dgit_repos_server_source_url {
7026     badusage __
7027         "no arguments allowed to dgit print-dgit-repos-server-source-url"
7028         if @ARGV;
7029     my $url = repos_server_url();
7030     print $url, "\n" or confess $!;
7031 }
7032
7033 sub pre_print_dpkg_source_ignores {
7034     not_necessarily_a_tree();
7035 }
7036 sub cmd_print_dpkg_source_ignores {
7037     badusage __
7038         "no arguments allowed to dgit print-dpkg-source-ignores"
7039         if @ARGV;
7040     print "@dpkg_source_ignores\n" or confess $!;
7041 }
7042
7043 sub cmd_setup_mergechangelogs {
7044     badusage __ "no arguments allowed to dgit setup-mergechangelogs"
7045         if @ARGV;
7046     local $isuite = 'DGIT-SETUP-TREE';
7047     setup_mergechangelogs(1);
7048 }
7049
7050 sub cmd_setup_useremail {
7051     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7052     local $isuite = 'DGIT-SETUP-TREE';
7053     setup_useremail(1);
7054 }
7055
7056 sub cmd_setup_gitattributes {
7057     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7058     local $isuite = 'DGIT-SETUP-TREE';
7059     setup_gitattrs(1);
7060 }
7061
7062 sub cmd_setup_new_tree {
7063     badusage __ "no arguments allowed to dgit setup-tree" if @ARGV;
7064     local $isuite = 'DGIT-SETUP-TREE';
7065     setup_new_tree();
7066 }
7067
7068 #---------- argument parsing and main program ----------
7069
7070 sub cmd_version {
7071     print "dgit version $our_version\n" or confess $!;
7072     finish 0;
7073 }
7074
7075 our (%valopts_long, %valopts_short);
7076 our (%funcopts_long);
7077 our @rvalopts;
7078 our (@modeopt_cfgs);
7079
7080 sub defvalopt ($$$$) {
7081     my ($long,$short,$val_re,$how) = @_;
7082     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
7083     $valopts_long{$long} = $oi;
7084     $valopts_short{$short} = $oi;
7085     # $how subref should:
7086     #   do whatever assignemnt or thing it likes with $_[0]
7087     #   if the option should not be passed on to remote, @rvalopts=()
7088     # or $how can be a scalar ref, meaning simply assign the value
7089 }
7090
7091 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
7092 defvalopt '--distro',        '-d', '.+',      \$idistro;
7093 defvalopt '',                '-k', '.+',      \$keyid;
7094 defvalopt '--existing-package','', '.*',      \$existing_package;
7095 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
7096 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
7097 defvalopt '--package',   '-p',   $package_re, \$package;
7098 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
7099
7100 defvalopt '', '-C', '.+', sub {
7101     ($changesfile) = (@_);
7102     if ($changesfile =~ s#^(.*)/##) {
7103         $buildproductsdir = $1;
7104     }
7105 };
7106
7107 defvalopt '--initiator-tempdir','','.*', sub {
7108     ($initiator_tempdir) = (@_);
7109     $initiator_tempdir =~ m#^/# or
7110         badusage __ "--initiator-tempdir must be used specify an".
7111                     " absolute, not relative, directory."
7112 };
7113
7114 sub defoptmodes ($@) {
7115     my ($varref, $cfgkey, $default, %optmap) = @_;
7116     my %permit;
7117     while (my ($opt,$val) = each %optmap) {
7118         $funcopts_long{$opt} = sub { $$varref = $val; };
7119         $permit{$val} = $val;
7120     }
7121     push @modeopt_cfgs, {
7122         Var => $varref,
7123         Key => $cfgkey,
7124         Default => $default,
7125         Vals => \%permit
7126     };
7127 }
7128
7129 defoptmodes \$dodep14tag, qw( dep14tag          want
7130                               --dep14tag        want
7131                               --no-dep14tag     no
7132                               --always-dep14tag always );
7133
7134 sub parseopts () {
7135     my $om;
7136
7137     if (defined $ENV{'DGIT_SSH'}) {
7138         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
7139     } elsif (defined $ENV{'GIT_SSH'}) {
7140         @ssh = ($ENV{'GIT_SSH'});
7141     }
7142
7143     my $oi;
7144     my $val;
7145     my $valopt = sub {
7146         my ($what) = @_;
7147         @rvalopts = ($_);
7148         if (!defined $val) {
7149             badusage f_ "%s needs a value", $what unless @ARGV;
7150             $val = shift @ARGV;
7151             push @rvalopts, $val;
7152         }
7153         badusage f_ "bad value \`%s' for %s", $val, $what unless
7154             $val =~ m/^$oi->{Re}$(?!\n)/s;
7155         my $how = $oi->{How};
7156         if (ref($how) eq 'SCALAR') {
7157             $$how = $val;
7158         } else {
7159             $how->($val);
7160         }
7161         push @ropts, @rvalopts;
7162     };
7163
7164     while (@ARGV) {
7165         last unless $ARGV[0] =~ m/^-/;
7166         $_ = shift @ARGV;
7167         last if m/^--?$/;
7168         if (m/^--/) {
7169             if (m/^--dry-run$/) {
7170                 push @ropts, $_;
7171                 $dryrun_level=2;
7172             } elsif (m/^--damp-run$/) {
7173                 push @ropts, $_;
7174                 $dryrun_level=1;
7175             } elsif (m/^--no-sign$/) {
7176                 push @ropts, $_;
7177                 $sign=0;
7178             } elsif (m/^--help$/) {
7179                 cmd_help();
7180             } elsif (m/^--version$/) {
7181                 cmd_version();
7182             } elsif (m/^--new$/) {
7183                 push @ropts, $_;
7184                 $new_package=1;
7185             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
7186                      ($om = $opts_opt_map{$1}) &&
7187                      length $om->[0]) {
7188                 push @ropts, $_;
7189                 $om->[0] = $2;
7190             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
7191                      !$opts_opt_cmdonly{$1} &&
7192                      ($om = $opts_opt_map{$1})) {
7193                 push @ropts, $_;
7194                 push @$om, $2;
7195             } elsif (m/^--(gbp|dpm)$/s) {
7196                 push @ropts, "--quilt=$1";
7197                 $quilt_mode = $1;
7198             } elsif (m/^--(?:ignore|include)-dirty$/s) {
7199                 push @ropts, $_;
7200                 $includedirty = 1;
7201             } elsif (m/^--no-quilt-fixup$/s) {
7202                 push @ropts, $_;
7203                 $quilt_mode = 'nocheck';
7204             } elsif (m/^--no-rm-on-error$/s) {
7205                 push @ropts, $_;
7206                 $rmonerror = 0;
7207             } elsif (m/^--no-chase-dsc-distro$/s) {
7208                 push @ropts, $_;
7209                 $chase_dsc_distro = 0;
7210             } elsif (m/^--overwrite$/s) {
7211                 push @ropts, $_;
7212                 $overwrite_version = '';
7213             } elsif (m/^--overwrite=(.+)$/s) {
7214                 push @ropts, $_;
7215                 $overwrite_version = $1;
7216             } elsif (m/^--delayed=(\d+)$/s) {
7217                 push @ropts, $_;
7218                 push @dput, $_;
7219             } elsif (my ($k,$v) =
7220                      m/^--save-(dgit-view)=(.+)$/s ||
7221                      m/^--(dgit-view)-save=(.+)$/s
7222                      ) {
7223                 push @ropts, $_;
7224                 $v =~ s#^(?!refs/)#refs/heads/#;
7225                 $internal_object_save{$k} = $v;
7226             } elsif (m/^--(no-)?rm-old-changes$/s) {
7227                 push @ropts, $_;
7228                 $rmchanges = !$1;
7229             } elsif (m/^--deliberately-($deliberately_re)$/s) {
7230                 push @ropts, $_;
7231                 push @deliberatelies, $&;
7232             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
7233                 push @ropts, $&;
7234                 $forceopts{$1} = 1;
7235                 $_='';
7236             } elsif (m/^--force-/) {
7237                 print STDERR
7238                     f_ "%s: warning: ignoring unknown force option %s\n",
7239                        $us, $_;
7240                 $_='';
7241             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
7242                 # undocumented, for testing
7243                 push @ropts, $_;
7244                 $tagformat_want = [ $1, 'command line', 1 ];
7245                 # 1 menas overrides distro configuration
7246             } elsif (m/^--config-lookup-explode=(.+)$/s) {
7247                 # undocumented, for testing
7248                 push @ropts, $_;
7249                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
7250                 # ^ it's supposed to be an array ref
7251             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
7252                 $val = $2 ? $' : undef; #';
7253                 $valopt->($oi->{Long});
7254             } elsif ($funcopts_long{$_}) {
7255                 push @ropts, $_;
7256                 $funcopts_long{$_}();
7257             } else {
7258                 badusage f_ "unknown long option \`%s'", $_;
7259             }
7260         } else {
7261             while (m/^-./s) {
7262                 if (s/^-n/-/) {
7263                     push @ropts, $&;
7264                     $dryrun_level=2;
7265                 } elsif (s/^-L/-/) {
7266                     push @ropts, $&;
7267                     $dryrun_level=1;
7268                 } elsif (s/^-h/-/) {
7269                     cmd_help();
7270                 } elsif (s/^-D/-/) {
7271                     push @ropts, $&;
7272                     $debuglevel++;
7273                     enabledebug();
7274                 } elsif (s/^-N/-/) {
7275                     push @ropts, $&;
7276                     $new_package=1;
7277                 } elsif (m/^-m/) {
7278                     push @ropts, $&;
7279                     push @changesopts, $_;
7280                     $_ = '';
7281                 } elsif (s/^-wn$//s) {
7282                     push @ropts, $&;
7283                     $cleanmode = 'none';
7284                 } elsif (s/^-wg$//s) {
7285                     push @ropts, $&;
7286                     $cleanmode = 'git';
7287                 } elsif (s/^-wgf$//s) {
7288                     push @ropts, $&;
7289                     $cleanmode = 'git-ff';
7290                 } elsif (s/^-wd(d?)([na]?)$//s) {
7291                     push @ropts, $&;
7292                     $cleanmode = 'dpkg-source';
7293                     $cleanmode .= '-d' if $1;
7294                     $cleanmode .= ',no-check' if $2 eq 'n';
7295                     $cleanmode .= ',all-check' if $2 eq 'a';
7296                 } elsif (s/^-wc$//s) {
7297                     push @ropts, $&;
7298                     $cleanmode = 'check';
7299                 } elsif (s/^-wci$//s) {
7300                     push @ropts, $&;
7301                     $cleanmode = 'check,ignores';
7302                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
7303                     push @git, '-c', $&;
7304                     $gitcfgs{cmdline}{$1} = [ $2 ];
7305                 } elsif (s/^-c([^=]+)$//s) {
7306                     push @git, '-c', $&;
7307                     $gitcfgs{cmdline}{$1} = [ 'true' ];
7308                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
7309                     $val = $'; #';
7310                     $val = undef unless length $val;
7311                     $valopt->($oi->{Short});
7312                     $_ = '';
7313                 } else {
7314                     badusage f_ "unknown short option \`%s'", $_;
7315                 }
7316             }
7317         }
7318     }
7319 }
7320
7321 sub check_env_sanity () {
7322     my $blocked = new POSIX::SigSet;
7323     sigprocmask SIG_UNBLOCK, $blocked, $blocked or confess $!;
7324
7325     eval {
7326         foreach my $name (qw(PIPE CHLD)) {
7327             my $signame = "SIG$name";
7328             my $signum = eval "POSIX::$signame" // die;
7329             die f_ "%s is set to something other than SIG_DFL\n",
7330                 $signame
7331                 if defined $SIG{$name} and $SIG{$name} ne 'DEFAULT';
7332             $blocked->ismember($signum) and
7333                 die f_ "%s is blocked\n", $signame;
7334         }
7335     };
7336     return unless $@;
7337     chomp $@;
7338     fail f_ <<END, $@;
7339 On entry to dgit, %s
7340 This is a bug produced by something in your execution environment.
7341 Giving up.
7342 END
7343 }
7344
7345
7346 sub parseopts_late_defaults () {
7347     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
7348         if defined $idistro;
7349     $isuite //= cfg('dgit.default.default-suite');
7350
7351     foreach my $k (keys %opts_opt_map) {
7352         my $om = $opts_opt_map{$k};
7353
7354         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
7355         if (defined $v) {
7356             badcfg f_ "cannot set command for %s", $k
7357                 unless length $om->[0];
7358             $om->[0] = $v;
7359         }
7360
7361         foreach my $c (access_cfg_cfgs("opts-$k")) {
7362             my @vl =
7363                 map { $_ ? @$_ : () }
7364                 map { $gitcfgs{$_}{$c} }
7365                 reverse @gitcfgsources;
7366             printdebug "CL $c ", (join " ", map { shellquote } @vl),
7367                 "\n" if $debuglevel >= 4;
7368             next unless @vl;
7369             badcfg f_ "cannot configure options for %s", $k
7370                 if $opts_opt_cmdonly{$k};
7371             my $insertpos = $opts_cfg_insertpos{$k};
7372             @$om = ( @$om[0..$insertpos-1],
7373                      @vl,
7374                      @$om[$insertpos..$#$om] );
7375         }
7376     }
7377
7378     if (!defined $rmchanges) {
7379         local $access_forpush;
7380         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
7381     }
7382
7383     if (!defined $quilt_mode) {
7384         local $access_forpush;
7385         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
7386             // access_cfg('quilt-mode', 'RETURN-UNDEF')
7387             // 'linear';
7388         $quilt_mode =~ m/^($quilt_modes_re)$/
7389             or badcfg f_ "unknown quilt-mode \`%s'", $quilt_mode;
7390         $quilt_mode = $1;
7391     }
7392
7393     foreach my $moc (@modeopt_cfgs) {
7394         local $access_forpush;
7395         my $vr = $moc->{Var};
7396         next if defined $$vr;
7397         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
7398         my $v = $moc->{Vals}{$$vr};
7399         badcfg f_ "unknown %s setting \`%s'", $moc->{Key}, $$vr
7400             unless defined $v;
7401         $$vr = $v;
7402     }
7403
7404     fail __ "dgit: --include-dirty is not supported in split view quilt mode"
7405         if $split_brain && $includedirty;
7406
7407     if (!defined $cleanmode) {
7408         local $access_forpush;
7409         $cleanmode = access_cfg('clean-mode-newer', 'RETURN-UNDEF');
7410         $cleanmode = undef if $cleanmode && $cleanmode !~ m/^$cleanmode_re$/;
7411
7412         $cleanmode //= access_cfg('clean-mode', 'RETURN-UNDEF');
7413         $cleanmode //= 'dpkg-source';
7414
7415         badcfg f_ "unknown clean-mode \`%s'", $cleanmode unless
7416             $cleanmode =~ m/$cleanmode_re/;
7417     }
7418
7419     $buildproductsdir //= access_cfg('build-products-dir', 'RETURN-UNDEF');
7420     $buildproductsdir //= '..';
7421     $bpd_glob = $buildproductsdir;
7422     $bpd_glob =~ s#[][\\{}*?~]#\\$&#g;
7423 }
7424
7425 setlocale(LC_MESSAGES, "");
7426 textdomain("dgit");
7427
7428 if ($ENV{$fakeeditorenv}) {
7429     git_slurp_config();
7430     quilt_fixup_editor();
7431 }
7432
7433 parseopts();
7434 check_env_sanity();
7435
7436 print STDERR __ "DRY RUN ONLY\n" if $dryrun_level > 1;
7437 print STDERR __ "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
7438     if $dryrun_level == 1;
7439 if (!@ARGV) {
7440     print STDERR __ $helpmsg or confess $!;
7441     finish 8;
7442 }
7443 $cmd = $subcommand = shift @ARGV;
7444 $cmd =~ y/-/_/;
7445
7446 my $pre_fn = ${*::}{"pre_$cmd"};
7447 $pre_fn->() if $pre_fn;
7448
7449 if ($invoked_in_git_tree) {
7450     changedir_git_toplevel();
7451     record_maindir();
7452 }
7453 git_slurp_config();
7454
7455 my $fn = ${*::}{"cmd_$cmd"};
7456 $fn or badusage f_ "unknown operation %s", $cmd;
7457 $fn->();
7458
7459 finish 0;