dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Text::Glob qw(match_glob);
  40 use Fcntl qw(:DEFAULT :flock);
  41 use Carp;
  42
  43 use Debian::Dgit;
  44
  45 our $our_version = 'UNRELEASED'; ###substituted###
  46 our $absurdity = undef; ###substituted###
  47
  48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  49 our $protovsn;
  50
  51 our $isuite;
  52 our $idistro;
  53 our $package;
  54 our @ropts;
  55
  56 our $sign = 1;
  57 our $dryrun_level = 0;
  58 our $changesfile;
  59 our $buildproductsdir = '..';
  60 our $new_package = 0;
  61 our $ignoredirty = 0;
  62 our $rmonerror = 1;
  63 our @deliberatelies;
  64 our %previously;
  65 our $existing_package = 'dpkg';
  66 our $cleanmode;
  67 our $changes_since_version;
  68 our $rmchanges;
  69 our $overwrite_version; # undef: not specified; '': check changelog
  70 our $quilt_mode;
  71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  72 our $dodep14tag;
  73 our $dodep14tag_re = 'want|no|always';
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $initiator_tempdir;
  77 our $patches_applied_dirtily = 00;
  78 our $tagformat_want;
  79 our $tagformat;
  80 our $tagformatfn;
  81 our $chase_dsc_distro=1;
  82
  83 our %forceopts = map { $_=>0 }
  84     qw(unrepresentable unsupported-source-format
  85        dsc-changes-mismatch changes-origs-exactly
  86        import-gitapply-absurd
  87        import-gitapply-no-absurd
  88        import-dsc-with-dgit-field);
  89
  90 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  91
  92 our $suite_re = '[-+.0-9a-z]+';
  93 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  94 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  95 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  96 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  97
  98 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  99 our $splitbraincache = 'dgit-intern/quilt-cache';
 100 our $rewritemap = 'dgit-rewrite/map';
 101
 102 our (@git) = qw(git);
 103 our (@dget) = qw(dget);
 104 our (@curl) = qw(curl);
 105 our (@dput) = qw(dput);
 106 our (@debsign) = qw(debsign);
 107 our (@gpg) = qw(gpg);
 108 our (@sbuild) = qw(sbuild);
 109 our (@ssh) = 'ssh';
 110 our (@dgit) = qw(dgit);
 111 our (@aptget) = qw(apt-get);
 112 our (@aptcache) = qw(apt-cache);
 113 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 114 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 115 our (@dpkggenchanges) = qw(dpkg-genchanges);
 116 our (@mergechanges) = qw(mergechanges -f);
 117 our (@gbp_build) = ('');
 118 our (@gbp_pq) = ('gbp pq');
 119 our (@changesopts) = ('');
 120
 121 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 122                      'curl' => \@curl,
 123                      'dput' => \@dput,
 124                      'debsign' => \@debsign,
 125                      'gpg' => \@gpg,
 126                      'sbuild' => \@sbuild,
 127                      'ssh' => \@ssh,
 128                      'dgit' => \@dgit,
 129                      'git' => \@git,
 130                      'apt-get' => \@aptget,
 131                      'apt-cache' => \@aptcache,
 132                      'dpkg-source' => \@dpkgsource,
 133                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 134                      'dpkg-genchanges' => \@dpkggenchanges,
 135                      'gbp-build' => \@gbp_build,
 136                      'gbp-pq' => \@gbp_pq,
 137                      'ch' => \@changesopts,
 138                      'mergechanges' => \@mergechanges);
 139
 140 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 141 our %opts_cfg_insertpos = map {
 142     $_,
 143     scalar @{ $opts_opt_map{$_} }
 144 } keys %opts_opt_map;
 145
 146 sub parseopts_late_defaults();
 147
 148 our $keyid;
 149
 150 autoflush STDOUT 1;
 151
 152 our $supplementary_message = '';
 153 our $need_split_build_invocation = 0;
 154 our $split_brain = 0;
 155
 156 END {
 157     local ($@, $?);
 158     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 159 }
 160
 161 our $remotename = 'dgit';
 162 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 163 our $csuite;
 164 our $instead_distro;
 165
 166 if (!defined $absurdity) {
 167     $absurdity = $0;
 168     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 169 }
 170
 171 sub debiantag ($$) {
 172     my ($v,$distro) = @_;
 173     return $tagformatfn->($v, $distro);
 174 }
 175
 176 sub debiantag_maintview ($$) {
 177     my ($v,$distro) = @_;
 178     return "$distro/".dep14_version_mangle $v;
 179 }
 180
 181 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 182
 183 sub lbranch () { return "$branchprefix/$csuite"; }
 184 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 185 sub lref () { return "refs/heads/".lbranch(); }
 186 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 187 sub rrref () { return server_ref($csuite); }
 188
 189 sub stripepoch ($) {
 190     my ($vsn) = @_;
 191     $vsn =~ s/^\d+\://;
 192     return $vsn;
 193 }
 194
 195 sub srcfn ($$) {
 196     my ($vsn,$sfx) = @_;
 197     return "${package}_".(stripepoch $vsn).$sfx
 198 }
 199
 200 sub dscfn ($) {
 201     my ($vsn) = @_;
 202     return srcfn($vsn,".dsc");
 203 }
 204
 205 sub changespat ($;$) {
 206     my ($vsn, $arch) = @_;
 207     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 208 }
 209
 210 sub upstreamversion ($) {
 211     my ($vsn) = @_;
 212     $vsn =~ s/-[^-]+$//;
 213     return $vsn;
 214 }
 215
 216 our $us = 'dgit';
 217 initdebug('');
 218
 219 our @end;
 220 END {
 221     local ($?);
 222     foreach my $f (@end) {
 223         eval { $f->(); };
 224         print STDERR "$us: cleanup: $@" if length $@;
 225     }
 226 };
 227
 228 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 229
 230 sub forceable_fail ($$) {
 231     my ($forceoptsl, $msg) = @_;
 232     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 233     print STDERR "warning: overriding problem due to --force:\n". $msg;
 234 }
 235
 236 sub forceing ($) {
 237     my ($forceoptsl) = @_;
 238     my @got = grep { $forceopts{$_} } @$forceoptsl;
 239     return 0 unless @got;
 240     print STDERR
 241  "warning: skipping checks or functionality due to --force-$got[0]\n";
 242 }
 243
 244 sub no_such_package () {
 245     print STDERR "$us: package $package does not exist in suite $isuite\n";
 246     exit 4;
 247 }
 248
 249 sub changedir ($) {
 250     my ($newdir) = @_;
 251     printdebug "CD $newdir\n";
 252     chdir $newdir or confess "chdir: $newdir: $!";
 253 }
 254
 255 sub deliberately ($) {
 256     my ($enquiry) = @_;
 257     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 258 }
 259
 260 sub deliberately_not_fast_forward () {
 261     foreach (qw(not-fast-forward fresh-repo)) {
 262         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 263     }
 264 }
 265
 266 sub quiltmode_splitbrain () {
 267     $quilt_mode =~ m/gbp|dpm|unapplied/;
 268 }
 269
 270 sub opts_opt_multi_cmd {
 271     my @cmd;
 272     push @cmd, split /\s+/, shift @_;
 273     push @cmd, @_;
 274     @cmd;
 275 }
 276
 277 sub gbp_pq {
 278     return opts_opt_multi_cmd @gbp_pq;
 279 }
 280
 281 #---------- remote protocol support, common ----------
 282
 283 # remote push initiator/responder protocol:
 284 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 285 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 286 #  < dgit-remote-push-ready <actual-proto-vsn>
 287 #
 288 # occasionally:
 289 #
 290 #  > progress NBYTES
 291 #  [NBYTES message]
 292 #
 293 #  > supplementary-message NBYTES          # $protovsn >= 3
 294 #  [NBYTES message]
 295 #
 296 # main sequence:
 297 #
 298 #  > file parsed-changelog
 299 #  [indicates that output of dpkg-parsechangelog follows]
 300 #  > data-block NBYTES
 301 #  > [NBYTES bytes of data (no newline)]
 302 #  [maybe some more blocks]
 303 #  > data-end
 304 #
 305 #  > file dsc
 306 #  [etc]
 307 #
 308 #  > file changes
 309 #  [etc]
 310 #
 311 #  > param head DGIT-VIEW-HEAD
 312 #  > param csuite SUITE
 313 #  > param tagformat old|new
 314 #  > param maint-view MAINT-VIEW-HEAD
 315 #
 316 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 317 #                                     # goes into tag, for replay prevention
 318 #
 319 #  > want signed-tag
 320 #  [indicates that signed tag is wanted]
 321 #  < data-block NBYTES
 322 #  < [NBYTES bytes of data (no newline)]
 323 #  [maybe some more blocks]
 324 #  < data-end
 325 #  < files-end
 326 #
 327 #  > want signed-dsc-changes
 328 #  < data-block NBYTES    [transfer of signed dsc]
 329 #  [etc]
 330 #  < data-block NBYTES    [transfer of signed changes]
 331 #  [etc]
 332 #  < files-end
 333 #
 334 #  > complete
 335
 336 our $i_child_pid;
 337
 338 sub i_child_report () {
 339     # Sees if our child has died, and reap it if so.  Returns a string
 340     # describing how it died if it failed, or undef otherwise.
 341     return undef unless $i_child_pid;
 342     my $got = waitpid $i_child_pid, WNOHANG;
 343     return undef if $got <= 0;
 344     die unless $got == $i_child_pid;
 345     $i_child_pid = undef;
 346     return undef unless $?;
 347     return "build host child ".waitstatusmsg();
 348 }
 349
 350 sub badproto ($$) {
 351     my ($fh, $m) = @_;
 352     fail "connection lost: $!" if $fh->error;
 353     fail "protocol violation; $m not expected";
 354 }
 355
 356 sub badproto_badread ($$) {
 357     my ($fh, $wh) = @_;
 358     fail "connection lost: $!" if $!;
 359     my $report = i_child_report();
 360     fail $report if defined $report;
 361     badproto $fh, "eof (reading $wh)";
 362 }
 363
 364 sub protocol_expect (&$) {
 365     my ($match, $fh) = @_;
 366     local $_;
 367     $_ = <$fh>;
 368     defined && chomp or badproto_badread $fh, "protocol message";
 369     if (wantarray) {
 370         my @r = &$match;
 371         return @r if @r;
 372     } else {
 373         my $r = &$match;
 374         return $r if $r;
 375     }
 376     badproto $fh, "\`$_'";
 377 }
 378
 379 sub protocol_send_file ($$) {
 380     my ($fh, $ourfn) = @_;
 381     open PF, "<", $ourfn or die "$ourfn: $!";
 382     for (;;) {
 383         my $d;
 384         my $got = read PF, $d, 65536;
 385         die "$ourfn: $!" unless defined $got;
 386         last if !$got;
 387         print $fh "data-block ".length($d)."\n" or die $!;
 388         print $fh $d or die $!;
 389     }
 390     PF->error and die "$ourfn $!";
 391     print $fh "data-end\n" or die $!;
 392     close PF;
 393 }
 394
 395 sub protocol_read_bytes ($$) {
 396     my ($fh, $nbytes) = @_;
 397     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 398     my $d;
 399     my $got = read $fh, $d, $nbytes;
 400     $got==$nbytes or badproto_badread $fh, "data block";
 401     return $d;
 402 }
 403
 404 sub protocol_receive_file ($$) {
 405     my ($fh, $ourfn) = @_;
 406     printdebug "() $ourfn\n";
 407     open PF, ">", $ourfn or die "$ourfn: $!";
 408     for (;;) {
 409         my ($y,$l) = protocol_expect {
 410             m/^data-block (.*)$/ ? (1,$1) :
 411             m/^data-end$/ ? (0,) :
 412             ();
 413         } $fh;
 414         last unless $y;
 415         my $d = protocol_read_bytes $fh, $l;
 416         print PF $d or die $!;
 417     }
 418     close PF or die $!;
 419 }
 420
 421 #---------- remote protocol support, responder ----------
 422
 423 sub responder_send_command ($) {
 424     my ($command) = @_;
 425     return unless $we_are_responder;
 426     # called even without $we_are_responder
 427     printdebug ">> $command\n";
 428     print PO $command, "\n" or die $!;
 429 }
 430
 431 sub responder_send_file ($$) {
 432     my ($keyword, $ourfn) = @_;
 433     return unless $we_are_responder;
 434     printdebug "]] $keyword $ourfn\n";
 435     responder_send_command "file $keyword";
 436     protocol_send_file \*PO, $ourfn;
 437 }
 438
 439 sub responder_receive_files ($@) {
 440     my ($keyword, @ourfns) = @_;
 441     die unless $we_are_responder;
 442     printdebug "[[ $keyword @ourfns\n";
 443     responder_send_command "want $keyword";
 444     foreach my $fn (@ourfns) {
 445         protocol_receive_file \*PI, $fn;
 446     }
 447     printdebug "[[\$\n";
 448     protocol_expect { m/^files-end$/ } \*PI;
 449 }
 450
 451 #---------- remote protocol support, initiator ----------
 452
 453 sub initiator_expect (&) {
 454     my ($match) = @_;
 455     protocol_expect { &$match } \*RO;
 456 }
 457
 458 #---------- end remote code ----------
 459
 460 sub progress {
 461     if ($we_are_responder) {
 462         my $m = join '', @_;
 463         responder_send_command "progress ".length($m) or die $!;
 464         print PO $m or die $!;
 465     } else {
 466         print @_, "\n";
 467     }
 468 }
 469
 470 our $ua;
 471
 472 sub url_get {
 473     if (!$ua) {
 474         $ua = LWP::UserAgent->new();
 475         $ua->env_proxy;
 476     }
 477     my $what = $_[$#_];
 478     progress "downloading $what...";
 479     my $r = $ua->get(@_) or die $!;
 480     return undef if $r->code == 404;
 481     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 482     return $r->decoded_content(charset => 'none');
 483 }
 484
 485 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 486
 487 sub runcmd {
 488     debugcmd "+",@_;
 489     $!=0; $?=-1;
 490     failedcmd @_ if system @_;
 491 }
 492
 493 sub act_local () { return $dryrun_level <= 1; }
 494 sub act_scary () { return !$dryrun_level; }
 495
 496 sub printdone {
 497     if (!$dryrun_level) {
 498         progress "$us ok: @_";
 499     } else {
 500         progress "would be ok: @_ (but dry run only)";
 501     }
 502 }
 503
 504 sub dryrun_report {
 505     printcmd(\*STDERR,$debugprefix."#",@_);
 506 }
 507
 508 sub runcmd_ordryrun {
 509     if (act_scary()) {
 510         runcmd @_;
 511     } else {
 512         dryrun_report @_;
 513     }
 514 }
 515
 516 sub runcmd_ordryrun_local {
 517     if (act_local()) {
 518         runcmd @_;
 519     } else {
 520         dryrun_report @_;
 521     }
 522 }
 523
 524 sub shell_cmd {
 525     my ($first_shell, @cmd) = @_;
 526     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 527 }
 528
 529 our $helpmsg = <<END;
 530 main usages:
 531   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 532   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 533   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 534   dgit [dgit-opts] sbuild [sbuild-opts]
 535   dgit [dgit-opts] push [dgit-opts] [suite]
 536   dgit [dgit-opts] rpush build-host:build-dir ...
 537 important dgit options:
 538   -k<keyid>           sign tag and package with <keyid> instead of default
 539   --dry-run -n        do not change anything, but go through the motions
 540   --damp-run -L       like --dry-run but make local changes, without signing
 541   --new -N            allow introducing a new package
 542   --debug -D          increase debug level
 543   -c<name>=<value>    set git config option (used directly by dgit too)
 544 END
 545
 546 our $later_warning_msg = <<END;
 547 Perhaps the upload is stuck in incoming.  Using the version from git.
 548 END
 549
 550 sub badusage {
 551     print STDERR "$us: @_\n", $helpmsg or die $!;
 552     exit 8;
 553 }
 554
 555 sub nextarg {
 556     @ARGV or badusage "too few arguments";
 557     return scalar shift @ARGV;
 558 }
 559
 560 sub cmd_help () {
 561     print $helpmsg or die $!;
 562     exit 0;
 563 }
 564
 565 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 566
 567 our %defcfg = ('dgit.default.distro' => 'debian',
 568                'dgit.default.default-suite' => 'unstable',
 569                'dgit.default.old-dsc-distro' => 'debian',
 570                'dgit-suite.*-security.distro' => 'debian-security',
 571                'dgit.default.username' => '',
 572                'dgit.default.archive-query-default-component' => 'main',
 573                'dgit.default.ssh' => 'ssh',
 574                'dgit.default.archive-query' => 'madison:',
 575                'dgit.default.sshpsql-dbname' => 'service=projectb',
 576                'dgit.default.aptget-components' => 'main',
 577                'dgit.default.dgit-tag-format' => 'new,old,maint',
 578                'dgit.dsc-url-proto-ok.http'    => 'true',
 579                'dgit.dsc-url-proto-ok.https'   => 'true',
 580                'dgit.dsc-url-proto-ok.git'     => 'true',
 581                'dgit.default.dsc-url-proto-ok' => 'false',
 582                # old means "repo server accepts pushes with old dgit tags"
 583                # new means "repo server accepts pushes with new dgit tags"
 584                # maint means "repo server accepts split brain pushes"
 585                # hist means "repo server may have old pushes without new tag"
 586                #   ("hist" is implied by "old")
 587                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 588                'dgit-distro.debian.git-check' => 'url',
 589                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 590                'dgit-distro.debian.new-private-pushers' => 't',
 591                'dgit-distro.debian/push.git-url' => '',
 592                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 593                'dgit-distro.debian/push.git-user-force' => 'dgit',
 594                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 595                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 596                'dgit-distro.debian/push.git-create' => 'true',
 597                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 598  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 599 # 'dgit-distro.debian.archive-query-tls-key',
 600 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 601 # ^ this does not work because curl is broken nowadays
 602 # Fixing #790093 properly will involve providing providing the key
 603 # in some pacagke and maybe updating these paths.
 604 #
 605 # 'dgit-distro.debian.archive-query-tls-curl-args',
 606 #   '--ca-path=/etc/ssl/ca-debian',
 607 # ^ this is a workaround but works (only) on DSA-administered machines
 608                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 609                'dgit-distro.debian.git-url-suffix' => '',
 610                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 611                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 612  'dgit-distro.debian-security.archive-query' => 'aptget:',
 613  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 614  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 615  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 616  'dgit-distro.debian-security.nominal-distro' => 'debian',
 617  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 618  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 619                'dgit-distro.ubuntu.git-check' => 'false',
 620  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 621                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 622                'dgit-distro.test-dummy.username' => "alice",
 623                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 624                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 625                'dgit-distro.test-dummy.git-url' => "$td/git",
 626                'dgit-distro.test-dummy.git-host' => "git",
 627                'dgit-distro.test-dummy.git-path' => "$td/git",
 628                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 629                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 630                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 631                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 632                );
 633
 634 our %gitcfgs;
 635 our @gitcfgsources = qw(cmdline local global system);
 636
 637 sub git_slurp_config () {
 638     local ($debuglevel) = $debuglevel-2;
 639     local $/="\0";
 640
 641     # This algoritm is a bit subtle, but this is needed so that for
 642     # options which we want to be single-valued, we allow the
 643     # different config sources to override properly.  See #835858.
 644     foreach my $src (@gitcfgsources) {
 645         next if $src eq 'cmdline';
 646         # we do this ourselves since git doesn't handle it
 647
 648         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 649         debugcmd "|",@cmd;
 650
 651         open GITS, "-|", @cmd or die $!;
 652         while (<GITS>) {
 653             chomp or die;
 654             printdebug "=> ", (messagequote $_), "\n";
 655             m/\n/ or die "$_ ?";
 656             push @{ $gitcfgs{$src}{$`} }, $'; #';
 657         }
 658         $!=0; $?=0;
 659         close GITS
 660             or ($!==0 && $?==256)
 661             or failedcmd @cmd;
 662     }
 663 }
 664
 665 sub git_get_config ($) {
 666     my ($c) = @_;
 667     foreach my $src (@gitcfgsources) {
 668         my $l = $gitcfgs{$src}{$c};
 669         croak "$l $c" if $l && !ref $l;
 670         printdebug"C $c ".(defined $l ?
 671                            join " ", map { messagequote "'$_'" } @$l :
 672                            "undef")."\n"
 673             if $debuglevel >= 4;
 674         $l or next;
 675         @$l==1 or badcfg "multiple values for $c".
 676             " (in $src git config)" if @$l > 1;
 677         return $l->[0];
 678     }
 679     return undef;
 680 }
 681
 682 sub cfg {
 683     foreach my $c (@_) {
 684         return undef if $c =~ /RETURN-UNDEF/;
 685         printdebug "C? $c\n" if $debuglevel >= 5;
 686         my $v = git_get_config($c);
 687         return $v if defined $v;
 688         my $dv = $defcfg{$c};
 689         if (defined $dv) {
 690             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 691             return $dv;
 692         }
 693     }
 694     badcfg "need value for one of: @_\n".
 695         "$us: distro or suite appears not to be (properly) supported";
 696 }
 697
 698 sub access_basedistro__noalias () {
 699     if (defined $idistro) {
 700         return $idistro;
 701     } else {
 702         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 703         return $def if defined $def;
 704         foreach my $src (@gitcfgsources, 'internal') {
 705             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 706             next unless $kl;
 707             foreach my $k (keys %$kl) {
 708                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 709                 my $dpat = $1;
 710                 next unless match_glob $dpat, $isuite;
 711                 return $kl->{$k};
 712             }
 713         }
 714         return cfg("dgit.default.distro");
 715     }
 716 }
 717
 718 sub access_basedistro () {
 719     my $noalias = access_basedistro__noalias();
 720     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 721     return $canon // $noalias;
 722 }
 723
 724 sub access_nomdistro () {
 725     my $base = access_basedistro();
 726     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 727     $r =~ m/^$distro_re$/ or badcfg
 728  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 729     return $r;
 730 }
 731
 732 sub access_quirk () {
 733     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 734     my $basedistro = access_basedistro();
 735     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 736                               'RETURN-UNDEF');
 737     if (defined $backports_quirk) {
 738         my $re = $backports_quirk;
 739         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 740         $re =~ s/\*/.*/g;
 741         $re =~ s/\%/([-0-9a-z_]+)/
 742             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 743         if ($isuite =~ m/^$re$/) {
 744             return ('backports',"$basedistro-backports",$1);
 745         }
 746     }
 747     return ('none',undef);
 748 }
 749
 750 our $access_forpush;
 751
 752 sub parse_cfg_bool ($$$) {
 753     my ($what,$def,$v) = @_;
 754     $v //= $def;
 755     return
 756         $v =~ m/^[ty1]/ ? 1 :
 757         $v =~ m/^[fn0]/ ? 0 :
 758         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 759 }
 760
 761 sub access_forpush_config () {
 762     my $d = access_basedistro();
 763
 764     return 1 if
 765         $new_package &&
 766         parse_cfg_bool('new-private-pushers', 0,
 767                        cfg("dgit-distro.$d.new-private-pushers",
 768                            'RETURN-UNDEF'));
 769
 770     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 771     $v //= 'a';
 772     return
 773         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 774         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 775         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 776         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 777 }
 778
 779 sub access_forpush () {
 780     $access_forpush //= access_forpush_config();
 781     return $access_forpush;
 782 }
 783
 784 sub pushing () {
 785     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 786     badcfg "pushing but distro is configured readonly"
 787         if access_forpush_config() eq '0';
 788     $access_forpush = 1;
 789     $supplementary_message = <<'END' unless $we_are_responder;
 790 Push failed, before we got started.
 791 You can retry the push, after fixing the problem, if you like.
 792 END
 793     parseopts_late_defaults();
 794 }
 795
 796 sub notpushing () {
 797     parseopts_late_defaults();
 798 }
 799
 800 sub supplementary_message ($) {
 801     my ($msg) = @_;
 802     if (!$we_are_responder) {
 803         $supplementary_message = $msg;
 804         return;
 805     } elsif ($protovsn >= 3) {
 806         responder_send_command "supplementary-message ".length($msg)
 807             or die $!;
 808         print PO $msg or die $!;
 809     }
 810 }
 811
 812 sub access_distros () {
 813     # Returns list of distros to try, in order
 814     #
 815     # We want to try:
 816     #    0. `instead of' distro name(s) we have been pointed to
 817     #    1. the access_quirk distro, if any
 818     #    2a. the user's specified distro, or failing that  } basedistro
 819     #    2b. the distro calculated from the suite          }
 820     my @l = access_basedistro();
 821
 822     my (undef,$quirkdistro) = access_quirk();
 823     unshift @l, $quirkdistro;
 824     unshift @l, $instead_distro;
 825     @l = grep { defined } @l;
 826
 827     push @l, access_nomdistro();
 828
 829     if (access_forpush()) {
 830         @l = map { ("$_/push", $_) } @l;
 831     }
 832     @l;
 833 }
 834
 835 sub access_cfg_cfgs (@) {
 836     my (@keys) = @_;
 837     my @cfgs;
 838     # The nesting of these loops determines the search order.  We put
 839     # the key loop on the outside so that we search all the distros
 840     # for each key, before going on to the next key.  That means that
 841     # if access_cfg is called with a more specific, and then a less
 842     # specific, key, an earlier distro can override the less specific
 843     # without necessarily overriding any more specific keys.  (If the
 844     # distro wants to override the more specific keys it can simply do
 845     # so; whereas if we did the loop the other way around, it would be
 846     # impossible to for an earlier distro to override a less specific
 847     # key but not the more specific ones without restating the unknown
 848     # values of the more specific keys.
 849     my @realkeys;
 850     my @rundef;
 851     # We have to deal with RETURN-UNDEF specially, so that we don't
 852     # terminate the search prematurely.
 853     foreach (@keys) {
 854         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 855         push @realkeys, $_
 856     }
 857     foreach my $d (access_distros()) {
 858         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 859     }
 860     push @cfgs, map { "dgit.default.$_" } @realkeys;
 861     push @cfgs, @rundef;
 862     return @cfgs;
 863 }
 864
 865 sub access_cfg (@) {
 866     my (@keys) = @_;
 867     my (@cfgs) = access_cfg_cfgs(@keys);
 868     my $value = cfg(@cfgs);
 869     return $value;
 870 }
 871
 872 sub access_cfg_bool ($$) {
 873     my ($def, @keys) = @_;
 874     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 875 }
 876
 877 sub string_to_ssh ($) {
 878     my ($spec) = @_;
 879     if ($spec =~ m/\s/) {
 880         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 881     } else {
 882         return ($spec);
 883     }
 884 }
 885
 886 sub access_cfg_ssh () {
 887     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 888     if (!defined $gitssh) {
 889         return @ssh;
 890     } else {
 891         return string_to_ssh $gitssh;
 892     }
 893 }
 894
 895 sub access_runeinfo ($) {
 896     my ($info) = @_;
 897     return ": dgit ".access_basedistro()." $info ;";
 898 }
 899
 900 sub access_someuserhost ($) {
 901     my ($some) = @_;
 902     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 903     defined($user) && length($user) or
 904         $user = access_cfg("$some-user",'username');
 905     my $host = access_cfg("$some-host");
 906     return length($user) ? "$user\@$host" : $host;
 907 }
 908
 909 sub access_gituserhost () {
 910     return access_someuserhost('git');
 911 }
 912
 913 sub access_giturl (;$) {
 914     my ($optional) = @_;
 915     my $url = access_cfg('git-url','RETURN-UNDEF');
 916     my $suffix;
 917     if (!length $url) {
 918         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 919         return undef unless defined $proto;
 920         $url =
 921             $proto.
 922             access_gituserhost().
 923             access_cfg('git-path');
 924     } else {
 925         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 926     }
 927     $suffix //= '.git';
 928     return "$url/$package$suffix";
 929 }
 930
 931 sub parsecontrolfh ($$;$) {
 932     my ($fh, $desc, $allowsigned) = @_;
 933     our $dpkgcontrolhash_noissigned;
 934     my $c;
 935     for (;;) {
 936         my %opts = ('name' => $desc);
 937         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 938         $c = Dpkg::Control::Hash->new(%opts);
 939         $c->parse($fh,$desc) or die "parsing of $desc failed";
 940         last if $allowsigned;
 941         last if $dpkgcontrolhash_noissigned;
 942         my $issigned= $c->get_option('is_pgp_signed');
 943         if (!defined $issigned) {
 944             $dpkgcontrolhash_noissigned= 1;
 945             seek $fh, 0,0 or die "seek $desc: $!";
 946         } elsif ($issigned) {
 947             fail "control file $desc is (already) PGP-signed. ".
 948                 " Note that dgit push needs to modify the .dsc and then".
 949                 " do the signature itself";
 950         } else {
 951             last;
 952         }
 953     }
 954     return $c;
 955 }
 956
 957 sub parsecontrol {
 958     my ($file, $desc, $allowsigned) = @_;
 959     my $fh = new IO::Handle;
 960     open $fh, '<', $file or die "$file: $!";
 961     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 962     $fh->error and die $!;
 963     close $fh;
 964     return $c;
 965 }
 966
 967 sub getfield ($$) {
 968     my ($dctrl,$field) = @_;
 969     my $v = $dctrl->{$field};
 970     return $v if defined $v;
 971     fail "missing field $field in ".$dctrl->get_option('name');
 972 }
 973
 974 sub parsechangelog {
 975     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 976     my $p = new IO::Handle;
 977     my @cmd = (qw(dpkg-parsechangelog), @_);
 978     open $p, '-|', @cmd or die $!;
 979     $c->parse($p);
 980     $?=0; $!=0; close $p or failedcmd @cmd;
 981     return $c;
 982 }
 983
 984 sub commit_getclogp ($) {
 985     # Returns the parsed changelog hashref for a particular commit
 986     my ($objid) = @_;
 987     our %commit_getclogp_memo;
 988     my $memo = $commit_getclogp_memo{$objid};
 989     return $memo if $memo;
 990     mkpath '.git/dgit';
 991     my $mclog = ".git/dgit/clog-$objid";
 992     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 993         "$objid:debian/changelog";
 994     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 995 }
 996
 997 sub must_getcwd () {
 998     my $d = getcwd();
 999     defined $d or fail "getcwd failed: $!";
1000     return $d;
1001 }
1002
1003 sub parse_dscdata () {
1004     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1005     printdebug Dumper($dscdata) if $debuglevel>1;
1006     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1007     printdebug Dumper($dsc) if $debuglevel>1;
1008 }
1009
1010 our %rmad;
1011
1012 sub archive_query ($;@) {
1013     my ($method) = shift @_;
1014     fail "this operation does not support multiple comma-separated suites"
1015         if $isuite =~ m/,/;
1016     my $query = access_cfg('archive-query','RETURN-UNDEF');
1017     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1018     my $proto = $1;
1019     my $data = $'; #';
1020     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1021 }
1022
1023 sub archive_query_prepend_mirror {
1024     my $m = access_cfg('mirror');
1025     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1026 }
1027
1028 sub pool_dsc_subpath ($$) {
1029     my ($vsn,$component) = @_; # $package is implict arg
1030     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1031     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1032 }
1033
1034 sub cfg_apply_map ($$$) {
1035     my ($varref, $what, $mapspec) = @_;
1036     return unless $mapspec;
1037
1038     printdebug "config $what EVAL{ $mapspec; }\n";
1039     $_ = $$varref;
1040     eval "package Dgit::Config; $mapspec;";
1041     die $@ if $@;
1042     $$varref = $_;
1043 }
1044
1045 #---------- `ftpmasterapi' archive query method (nascent) ----------
1046
1047 sub archive_api_query_cmd ($) {
1048     my ($subpath) = @_;
1049     my @cmd = (@curl, qw(-sS));
1050     my $url = access_cfg('archive-query-url');
1051     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1052         my $host = $1;
1053         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1054         foreach my $key (split /\:/, $keys) {
1055             $key =~ s/\%HOST\%/$host/g;
1056             if (!stat $key) {
1057                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1058                 next;
1059             }
1060             fail "config requested specific TLS key but do not know".
1061                 " how to get curl to use exactly that EE key ($key)";
1062 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1063 #           # Sadly the above line does not work because of changes
1064 #           # to gnutls.   The real fix for #790093 may involve
1065 #           # new curl options.
1066             last;
1067         }
1068         # Fixing #790093 properly will involve providing a value
1069         # for this on clients.
1070         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1071         push @cmd, split / /, $kargs if defined $kargs;
1072     }
1073     push @cmd, $url.$subpath;
1074     return @cmd;
1075 }
1076
1077 sub api_query ($$;$) {
1078     use JSON;
1079     my ($data, $subpath, $ok404) = @_;
1080     badcfg "ftpmasterapi archive query method takes no data part"
1081         if length $data;
1082     my @cmd = archive_api_query_cmd($subpath);
1083     my $url = $cmd[$#cmd];
1084     push @cmd, qw(-w %{http_code});
1085     my $json = cmdoutput @cmd;
1086     unless ($json =~ s/\d+\d+\d$//) {
1087         failedcmd_report_cmd undef, @cmd;
1088         fail "curl failed to print 3-digit HTTP code";
1089     }
1090     my $code = $&;
1091     return undef if $code eq '404' && $ok404;
1092     fail "fetch of $url gave HTTP code $code"
1093         unless $url =~ m#^file://# or $code =~ m/^2/;
1094     return decode_json($json);
1095 }
1096
1097 sub canonicalise_suite_ftpmasterapi {
1098     my ($proto,$data) = @_;
1099     my $suites = api_query($data, 'suites');
1100     my @matched;
1101     foreach my $entry (@$suites) {
1102         next unless grep {
1103             my $v = $entry->{$_};
1104             defined $v && $v eq $isuite;
1105         } qw(codename name);
1106         push @matched, $entry;
1107     }
1108     fail "unknown suite $isuite" unless @matched;
1109     my $cn;
1110     eval {
1111         @matched==1 or die "multiple matches for suite $isuite\n";
1112         $cn = "$matched[0]{codename}";
1113         defined $cn or die "suite $isuite info has no codename\n";
1114         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1115     };
1116     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1117         if length $@;
1118     return $cn;
1119 }
1120
1121 sub archive_query_ftpmasterapi {
1122     my ($proto,$data) = @_;
1123     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1124     my @rows;
1125     my $digester = Digest::SHA->new(256);
1126     foreach my $entry (@$info) {
1127         eval {
1128             my $vsn = "$entry->{version}";
1129             my ($ok,$msg) = version_check $vsn;
1130             die "bad version: $msg\n" unless $ok;
1131             my $component = "$entry->{component}";
1132             $component =~ m/^$component_re$/ or die "bad component";
1133             my $filename = "$entry->{filename}";
1134             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1135                 or die "bad filename";
1136             my $sha256sum = "$entry->{sha256sum}";
1137             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1138             push @rows, [ $vsn, "/pool/$component/$filename",
1139                           $digester, $sha256sum ];
1140         };
1141         die "bad ftpmaster api response: $@\n".Dumper($entry)
1142             if length $@;
1143     }
1144     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1145     return archive_query_prepend_mirror @rows;
1146 }
1147
1148 sub file_in_archive_ftpmasterapi {
1149     my ($proto,$data,$filename) = @_;
1150     my $pat = $filename;
1151     $pat =~ s/_/\\_/g;
1152     $pat = "%/$pat";
1153     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1154     my $info = api_query($data, "file_in_archive/$pat", 1);
1155 }
1156
1157 #---------- `aptget' archive query method ----------
1158
1159 our $aptget_base;
1160 our $aptget_releasefile;
1161 our $aptget_configpath;
1162
1163 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1164 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1165
1166 sub aptget_cache_clean {
1167     runcmd_ordryrun_local qw(sh -ec),
1168         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1169         'x', $aptget_base;
1170 }
1171
1172 sub aptget_lock_acquire () {
1173     my $lockfile = "$aptget_base/lock";
1174     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1175     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1176 }
1177
1178 sub aptget_prep ($) {
1179     my ($data) = @_;
1180     return if defined $aptget_base;
1181
1182     badcfg "aptget archive query method takes no data part"
1183         if length $data;
1184
1185     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1186
1187     ensuredir $cache;
1188     ensuredir "$cache/dgit";
1189     my $cachekey =
1190         access_cfg('aptget-cachekey','RETURN-UNDEF')
1191         // access_nomdistro();
1192
1193     $aptget_base = "$cache/dgit/aptget";
1194     ensuredir $aptget_base;
1195
1196     my $quoted_base = $aptget_base;
1197     die "$quoted_base contains bad chars, cannot continue"
1198         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1199
1200     ensuredir $aptget_base;
1201
1202     aptget_lock_acquire();
1203
1204     aptget_cache_clean();
1205
1206     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1207     my $sourceslist = "source.list#$cachekey";
1208
1209     my $aptsuites = $isuite;
1210     cfg_apply_map(\$aptsuites, 'suite map',
1211                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1212
1213     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1214     printf SRCS "deb-src %s %s %s\n",
1215         access_cfg('mirror'),
1216         $aptsuites,
1217         access_cfg('aptget-components')
1218         or die $!;
1219
1220     ensuredir "$aptget_base/cache";
1221     ensuredir "$aptget_base/lists";
1222
1223     open CONF, ">", $aptget_configpath or die $!;
1224     print CONF <<END;
1225 Debug::NoLocking "true";
1226 APT::Get::List-Cleanup "false";
1227 #clear APT::Update::Post-Invoke-Success;
1228 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1229 Dir::State::Lists "$quoted_base/lists";
1230 Dir::Etc::preferences "$quoted_base/preferences";
1231 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1232 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1233 END
1234
1235     foreach my $key (qw(
1236                         Dir::Cache
1237                         Dir::State
1238                         Dir::Cache::Archives
1239                         Dir::Etc::SourceParts
1240                         Dir::Etc::preferencesparts
1241                       )) {
1242         ensuredir "$aptget_base/$key";
1243         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1244     };
1245
1246     my $oldatime = (time // die $!) - 1;
1247     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1248         next unless stat_exists $oldlist;
1249         my ($mtime) = (stat _)[9];
1250         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1251     }
1252
1253     runcmd_ordryrun_local aptget_aptget(), qw(update);
1254
1255     my @releasefiles;
1256     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1257         next unless stat_exists $oldlist;
1258         my ($atime) = (stat _)[8];
1259         next if $atime == $oldatime;
1260         push @releasefiles, $oldlist;
1261     }
1262     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1263     @releasefiles = @inreleasefiles if @inreleasefiles;
1264     die "apt updated wrong number of Release files (@releasefiles), erk"
1265         unless @releasefiles == 1;
1266
1267     ($aptget_releasefile) = @releasefiles;
1268 }
1269
1270 sub canonicalise_suite_aptget {
1271     my ($proto,$data) = @_;
1272     aptget_prep($data);
1273
1274     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1275
1276     foreach my $name (qw(Codename Suite)) {
1277         my $val = $release->{$name};
1278         if (defined $val) {
1279             printdebug "release file $name: $val\n";
1280             $val =~ m/^$suite_re$/o or fail
1281  "Release file ($aptget_releasefile) specifies intolerable $name";
1282             cfg_apply_map(\$val, 'suite rmap',
1283                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1284             return $val
1285         }
1286     }
1287     return $isuite;
1288 }
1289
1290 sub archive_query_aptget {
1291     my ($proto,$data) = @_;
1292     aptget_prep($data);
1293
1294     ensuredir "$aptget_base/source";
1295     foreach my $old (<$aptget_base/source/*.dsc>) {
1296         unlink $old or die "$old: $!";
1297     }
1298
1299     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1300     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1301     # avoids apt-get source failing with ambiguous error code
1302
1303     runcmd_ordryrun_local
1304         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1305         aptget_aptget(), qw(--download-only --only-source source), $package;
1306
1307     my @dscs = <$aptget_base/source/*.dsc>;
1308     fail "apt-get source did not produce a .dsc" unless @dscs;
1309     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1310
1311     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1312
1313     use URI::Escape;
1314     my $uri = "file://". uri_escape $dscs[0];
1315     $uri =~ s{\%2f}{/}gi;
1316     return [ (getfield $pre_dsc, 'Version'), $uri ];
1317 }
1318
1319 #---------- `dummyapicat' archive query method ----------
1320
1321 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1322 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1323
1324 sub file_in_archive_dummycatapi ($$$) {
1325     my ($proto,$data,$filename) = @_;
1326     my $mirror = access_cfg('mirror');
1327     $mirror =~ s#^file://#/# or die "$mirror ?";
1328     my @out;
1329     my @cmd = (qw(sh -ec), '
1330             cd "$1"
1331             find -name "$2" -print0 |
1332             xargs -0r sha256sum
1333         ', qw(x), $mirror, $filename);
1334     debugcmd "-|", @cmd;
1335     open FIA, "-|", @cmd or die $!;
1336     while (<FIA>) {
1337         chomp or die;
1338         printdebug "| $_\n";
1339         m/^(\w+)  (\S+)$/ or die "$_ ?";
1340         push @out, { sha256sum => $1, filename => $2 };
1341     }
1342     close FIA or die failedcmd @cmd;
1343     return \@out;
1344 }
1345
1346 #---------- `madison' archive query method ----------
1347
1348 sub archive_query_madison {
1349     return archive_query_prepend_mirror
1350         map { [ @$_[0..1] ] } madison_get_parse(@_);
1351 }
1352
1353 sub madison_get_parse {
1354     my ($proto,$data) = @_;
1355     die unless $proto eq 'madison';
1356     if (!length $data) {
1357         $data= access_cfg('madison-distro','RETURN-UNDEF');
1358         $data //= access_basedistro();
1359     }
1360     $rmad{$proto,$data,$package} ||= cmdoutput
1361         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1362     my $rmad = $rmad{$proto,$data,$package};
1363
1364     my @out;
1365     foreach my $l (split /\n/, $rmad) {
1366         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1367                   \s*( [^ \t|]+ )\s* \|
1368                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1369                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1370         $1 eq $package or die "$rmad $package ?";
1371         my $vsn = $2;
1372         my $newsuite = $3;
1373         my $component;
1374         if (defined $4) {
1375             $component = $4;
1376         } else {
1377             $component = access_cfg('archive-query-default-component');
1378         }
1379         $5 eq 'source' or die "$rmad ?";
1380         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1381     }
1382     return sort { -version_compare($a->[0],$b->[0]); } @out;
1383 }
1384
1385 sub canonicalise_suite_madison {
1386     # madison canonicalises for us
1387     my @r = madison_get_parse(@_);
1388     @r or fail
1389         "unable to canonicalise suite using package $package".
1390         " which does not appear to exist in suite $isuite;".
1391         " --existing-package may help";
1392     return $r[0][2];
1393 }
1394
1395 sub file_in_archive_madison { return undef; }
1396
1397 #---------- `sshpsql' archive query method ----------
1398
1399 sub sshpsql ($$$) {
1400     my ($data,$runeinfo,$sql) = @_;
1401     if (!length $data) {
1402         $data= access_someuserhost('sshpsql').':'.
1403             access_cfg('sshpsql-dbname');
1404     }
1405     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1406     my ($userhost,$dbname) = ($`,$'); #';
1407     my @rows;
1408     my @cmd = (access_cfg_ssh, $userhost,
1409                access_runeinfo("ssh-psql $runeinfo").
1410                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1411                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1412     debugcmd "|",@cmd;
1413     open P, "-|", @cmd or die $!;
1414     while (<P>) {
1415         chomp or die;
1416         printdebug(">|$_|\n");
1417         push @rows, $_;
1418     }
1419     $!=0; $?=0; close P or failedcmd @cmd;
1420     @rows or die;
1421     my $nrows = pop @rows;
1422     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1423     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1424     @rows = map { [ split /\|/, $_ ] } @rows;
1425     my $ncols = scalar @{ shift @rows };
1426     die if grep { scalar @$_ != $ncols } @rows;
1427     return @rows;
1428 }
1429
1430 sub sql_injection_check {
1431     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1432 }
1433
1434 sub archive_query_sshpsql ($$) {
1435     my ($proto,$data) = @_;
1436     sql_injection_check $isuite, $package;
1437     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1438         SELECT source.version, component.name, files.filename, files.sha256sum
1439           FROM source
1440           JOIN src_associations ON source.id = src_associations.source
1441           JOIN suite ON suite.id = src_associations.suite
1442           JOIN dsc_files ON dsc_files.source = source.id
1443           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1444           JOIN component ON component.id = files_archive_map.component_id
1445           JOIN files ON files.id = dsc_files.file
1446          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1447            AND source.source='$package'
1448            AND files.filename LIKE '%.dsc';
1449 END
1450     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1451     my $digester = Digest::SHA->new(256);
1452     @rows = map {
1453         my ($vsn,$component,$filename,$sha256sum) = @$_;
1454         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1455     } @rows;
1456     return archive_query_prepend_mirror @rows;
1457 }
1458
1459 sub canonicalise_suite_sshpsql ($$) {
1460     my ($proto,$data) = @_;
1461     sql_injection_check $isuite;
1462     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1463         SELECT suite.codename
1464           FROM suite where suite_name='$isuite' or codename='$isuite';
1465 END
1466     @rows = map { $_->[0] } @rows;
1467     fail "unknown suite $isuite" unless @rows;
1468     die "ambiguous $isuite: @rows ?" if @rows>1;
1469     return $rows[0];
1470 }
1471
1472 sub file_in_archive_sshpsql ($$$) { return undef; }
1473
1474 #---------- `dummycat' archive query method ----------
1475
1476 sub canonicalise_suite_dummycat ($$) {
1477     my ($proto,$data) = @_;
1478     my $dpath = "$data/suite.$isuite";
1479     if (!open C, "<", $dpath) {
1480         $!==ENOENT or die "$dpath: $!";
1481         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1482         return $isuite;
1483     }
1484     $!=0; $_ = <C>;
1485     chomp or die "$dpath: $!";
1486     close C;
1487     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1488     return $_;
1489 }
1490
1491 sub archive_query_dummycat ($$) {
1492     my ($proto,$data) = @_;
1493     canonicalise_suite();
1494     my $dpath = "$data/package.$csuite.$package";
1495     if (!open C, "<", $dpath) {
1496         $!==ENOENT or die "$dpath: $!";
1497         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1498         return ();
1499     }
1500     my @rows;
1501     while (<C>) {
1502         next if m/^\#/;
1503         next unless m/\S/;
1504         die unless chomp;
1505         printdebug "dummycat query $csuite $package $dpath | $_\n";
1506         my @row = split /\s+/, $_;
1507         @row==2 or die "$dpath: $_ ?";
1508         push @rows, \@row;
1509     }
1510     C->error and die "$dpath: $!";
1511     close C;
1512     return archive_query_prepend_mirror
1513         sort { -version_compare($a->[0],$b->[0]); } @rows;
1514 }
1515
1516 sub file_in_archive_dummycat () { return undef; }
1517
1518 #---------- tag format handling ----------
1519
1520 sub access_cfg_tagformats () {
1521     split /\,/, access_cfg('dgit-tag-format');
1522 }
1523
1524 sub access_cfg_tagformats_can_splitbrain () {
1525     my %y = map { $_ => 1 } access_cfg_tagformats;
1526     foreach my $needtf (qw(new maint)) {
1527         next if $y{$needtf};
1528         return 0;
1529     }
1530     return 1;
1531 }
1532
1533 sub need_tagformat ($$) {
1534     my ($fmt, $why) = @_;
1535     fail "need to use tag format $fmt ($why) but also need".
1536         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1537         " - no way to proceed"
1538         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1539     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1540 }
1541
1542 sub select_tagformat () {
1543     # sets $tagformatfn
1544     return if $tagformatfn && !$tagformat_want;
1545     die 'bug' if $tagformatfn && $tagformat_want;
1546     # ... $tagformat_want assigned after previous select_tagformat
1547
1548     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1549     printdebug "select_tagformat supported @supported\n";
1550
1551     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1552     printdebug "select_tagformat specified @$tagformat_want\n";
1553
1554     my ($fmt,$why,$override) = @$tagformat_want;
1555
1556     fail "target distro supports tag formats @supported".
1557         " but have to use $fmt ($why)"
1558         unless $override
1559             or grep { $_ eq $fmt } @supported;
1560
1561     $tagformat_want = undef;
1562     $tagformat = $fmt;
1563     $tagformatfn = ${*::}{"debiantag_$fmt"};
1564
1565     fail "trying to use unknown tag format \`$fmt' ($why) !"
1566         unless $tagformatfn;
1567 }
1568
1569 #---------- archive query entrypoints and rest of program ----------
1570
1571 sub canonicalise_suite () {
1572     return if defined $csuite;
1573     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1574     $csuite = archive_query('canonicalise_suite');
1575     if ($isuite ne $csuite) {
1576         progress "canonical suite name for $isuite is $csuite";
1577     } else {
1578         progress "canonical suite name is $csuite";
1579     }
1580 }
1581
1582 sub get_archive_dsc () {
1583     canonicalise_suite();
1584     my @vsns = archive_query('archive_query');
1585     foreach my $vinfo (@vsns) {
1586         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1587         $dscurl = $vsn_dscurl;
1588         $dscdata = url_get($dscurl);
1589         if (!$dscdata) {
1590             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1591             next;
1592         }
1593         if ($digester) {
1594             $digester->reset();
1595             $digester->add($dscdata);
1596             my $got = $digester->hexdigest();
1597             $got eq $digest or
1598                 fail "$dscurl has hash $got but".
1599                     " archive told us to expect $digest";
1600         }
1601         parse_dscdata();
1602         my $fmt = getfield $dsc, 'Format';
1603         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1604             "unsupported source format $fmt, sorry";
1605
1606         $dsc_checked = !!$digester;
1607         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1608         return;
1609     }
1610     $dsc = undef;
1611     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1612 }
1613
1614 sub check_for_git ();
1615 sub check_for_git () {
1616     # returns 0 or 1
1617     my $how = access_cfg('git-check');
1618     if ($how eq 'ssh-cmd') {
1619         my @cmd =
1620             (access_cfg_ssh, access_gituserhost(),
1621              access_runeinfo("git-check $package").
1622              " set -e; cd ".access_cfg('git-path').";".
1623              " if test -d $package.git; then echo 1; else echo 0; fi");
1624         my $r= cmdoutput @cmd;
1625         if (defined $r and $r =~ m/^divert (\w+)$/) {
1626             my $divert=$1;
1627             my ($usedistro,) = access_distros();
1628             # NB that if we are pushing, $usedistro will be $distro/push
1629             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1630             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1631             progress "diverting to $divert (using config for $instead_distro)";
1632             return check_for_git();
1633         }
1634         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1635         return $r+0;
1636     } elsif ($how eq 'url') {
1637         my $prefix = access_cfg('git-check-url','git-url');
1638         my $suffix = access_cfg('git-check-suffix','git-suffix',
1639                                 'RETURN-UNDEF') // '.git';
1640         my $url = "$prefix/$package$suffix";
1641         my @cmd = (@curl, qw(-sS -I), $url);
1642         my $result = cmdoutput @cmd;
1643         $result =~ s/^\S+ 200 .*\n\r?\n//;
1644         # curl -sS -I with https_proxy prints
1645         # HTTP/1.0 200 Connection established
1646         $result =~ m/^\S+ (404|200) /s or
1647             fail "unexpected results from git check query - ".
1648                 Dumper($prefix, $result);
1649         my $code = $1;
1650         if ($code eq '404') {
1651             return 0;
1652         } elsif ($code eq '200') {
1653             return 1;
1654         } else {
1655             die;
1656         }
1657     } elsif ($how eq 'true') {
1658         return 1;
1659     } elsif ($how eq 'false') {
1660         return 0;
1661     } else {
1662         badcfg "unknown git-check \`$how'";
1663     }
1664 }
1665
1666 sub create_remote_git_repo () {
1667     my $how = access_cfg('git-create');
1668     if ($how eq 'ssh-cmd') {
1669         runcmd_ordryrun
1670             (access_cfg_ssh, access_gituserhost(),
1671              access_runeinfo("git-create $package").
1672              "set -e; cd ".access_cfg('git-path').";".
1673              " cp -a _template $package.git");
1674     } elsif ($how eq 'true') {
1675         # nothing to do
1676     } else {
1677         badcfg "unknown git-create \`$how'";
1678     }
1679 }
1680
1681 our ($dsc_hash,$lastpush_mergeinput);
1682 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1683
1684 our $ud = '.git/dgit/unpack';
1685
1686 sub prep_ud (;$) {
1687     my ($d) = @_;
1688     $d //= $ud;
1689     rmtree($d);
1690     mkpath '.git/dgit';
1691     mkdir $d or die $!;
1692 }
1693
1694 sub mktree_in_ud_here () {
1695     runcmd qw(git init -q);
1696     runcmd qw(git config gc.auto 0);
1697     rmtree('.git/objects');
1698     symlink '../../../../objects','.git/objects' or die $!;
1699 }
1700
1701 sub git_write_tree () {
1702     my $tree = cmdoutput @git, qw(write-tree);
1703     $tree =~ m/^\w+$/ or die "$tree ?";
1704     return $tree;
1705 }
1706
1707 sub git_add_write_tree () {
1708     runcmd @git, qw(add -Af .);
1709     return git_write_tree();
1710 }
1711
1712 sub remove_stray_gits ($) {
1713     my ($what) = @_;
1714     my @gitscmd = qw(find -name .git -prune -print0);
1715     debugcmd "|",@gitscmd;
1716     open GITS, "-|", @gitscmd or die $!;
1717     {
1718         local $/="\0";
1719         while (<GITS>) {
1720             chomp or die;
1721             print STDERR "$us: warning: removing from $what: ",
1722                 (messagequote $_), "\n";
1723             rmtree $_;
1724         }
1725     }
1726     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1727 }
1728
1729 sub mktree_in_ud_from_only_subdir ($;$) {
1730     my ($what,$raw) = @_;
1731
1732     # changes into the subdir
1733     my (@dirs) = <*/.>;
1734     die "expected one subdir but found @dirs ?" unless @dirs==1;
1735     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1736     my $dir = $1;
1737     changedir $dir;
1738
1739     remove_stray_gits($what);
1740     mktree_in_ud_here();
1741     if (!$raw) {
1742         my ($format, $fopts) = get_source_format();
1743         if (madformat($format)) {
1744             rmtree '.pc';
1745         }
1746     }
1747
1748     my $tree=git_add_write_tree();
1749     return ($tree,$dir);
1750 }
1751
1752 our @files_csum_info_fields =
1753     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1754      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1755      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1756
1757 sub dsc_files_info () {
1758     foreach my $csumi (@files_csum_info_fields) {
1759         my ($fname, $module, $method) = @$csumi;
1760         my $field = $dsc->{$fname};
1761         next unless defined $field;
1762         eval "use $module; 1;" or die $@;
1763         my @out;
1764         foreach (split /\n/, $field) {
1765             next unless m/\S/;
1766             m/^(\w+) (\d+) (\S+)$/ or
1767                 fail "could not parse .dsc $fname line \`$_'";
1768             my $digester = eval "$module"."->$method;" or die $@;
1769             push @out, {
1770                 Hash => $1,
1771                 Bytes => $2,
1772                 Filename => $3,
1773                 Digester => $digester,
1774             };
1775         }
1776         return @out;
1777     }
1778     fail "missing any supported Checksums-* or Files field in ".
1779         $dsc->get_option('name');
1780 }
1781
1782 sub dsc_files () {
1783     map { $_->{Filename} } dsc_files_info();
1784 }
1785
1786 sub files_compare_inputs (@) {
1787     my $inputs = \@_;
1788     my %record;
1789     my %fchecked;
1790
1791     my $showinputs = sub {
1792         return join "; ", map { $_->get_option('name') } @$inputs;
1793     };
1794
1795     foreach my $in (@$inputs) {
1796         my $expected_files;
1797         my $in_name = $in->get_option('name');
1798
1799         printdebug "files_compare_inputs $in_name\n";
1800
1801         foreach my $csumi (@files_csum_info_fields) {
1802             my ($fname) = @$csumi;
1803             printdebug "files_compare_inputs $in_name $fname\n";
1804
1805             my $field = $in->{$fname};
1806             next unless defined $field;
1807
1808             my @files;
1809             foreach (split /\n/, $field) {
1810                 next unless m/\S/;
1811
1812                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1813                     fail "could not parse $in_name $fname line \`$_'";
1814
1815                 printdebug "files_compare_inputs $in_name $fname $f\n";
1816
1817                 push @files, $f;
1818
1819                 my $re = \ $record{$f}{$fname};
1820                 if (defined $$re) {
1821                     $fchecked{$f}{$in_name} = 1;
1822                     $$re eq $info or
1823                         fail "hash or size of $f varies in $fname fields".
1824                         " (between: ".$showinputs->().")";
1825                 } else {
1826                     $$re = $info;
1827                 }
1828             }
1829             @files = sort @files;
1830             $expected_files //= \@files;
1831             "@$expected_files" eq "@files" or
1832                 fail "file list in $in_name varies between hash fields!";
1833         }
1834         $expected_files or
1835             fail "$in_name has no files list field(s)";
1836     }
1837     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1838         if $debuglevel>=2;
1839
1840     grep { keys %$_ == @$inputs-1 } values %fchecked
1841         or fail "no file appears in all file lists".
1842         " (looked in: ".$showinputs->().")";
1843 }
1844
1845 sub is_orig_file_in_dsc ($$) {
1846     my ($f, $dsc_files_info) = @_;
1847     return 0 if @$dsc_files_info <= 1;
1848     # One file means no origs, and the filename doesn't have a "what
1849     # part of dsc" component.  (Consider versions ending `.orig'.)
1850     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1851     return 1;
1852 }
1853
1854 sub is_orig_file_of_vsn ($$) {
1855     my ($f, $upstreamvsn) = @_;
1856     my $base = srcfn $upstreamvsn, '';
1857     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1858     return 1;
1859 }
1860
1861 sub changes_update_origs_from_dsc ($$$$) {
1862     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1863     my %changes_f;
1864     printdebug "checking origs needed ($upstreamvsn)...\n";
1865     $_ = getfield $changes, 'Files';
1866     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1867         fail "cannot find section/priority from .changes Files field";
1868     my $placementinfo = $1;
1869     my %changed;
1870     printdebug "checking origs needed placement '$placementinfo'...\n";
1871     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1872         $l =~ m/\S+$/ or next;
1873         my $file = $&;
1874         printdebug "origs $file | $l\n";
1875         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1876         printdebug "origs $file is_orig\n";
1877         my $have = archive_query('file_in_archive', $file);
1878         if (!defined $have) {
1879             print STDERR <<END;
1880 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1881 END
1882             return;
1883         }
1884         my $found_same = 0;
1885         my @found_differ;
1886         printdebug "origs $file \$#\$have=$#$have\n";
1887         foreach my $h (@$have) {
1888             my $same = 0;
1889             my @differ;
1890             foreach my $csumi (@files_csum_info_fields) {
1891                 my ($fname, $module, $method, $archivefield) = @$csumi;
1892                 next unless defined $h->{$archivefield};
1893                 $_ = $dsc->{$fname};
1894                 next unless defined;
1895                 m/^(\w+) .* \Q$file\E$/m or
1896                     fail ".dsc $fname missing entry for $file";
1897                 if ($h->{$archivefield} eq $1) {
1898                     $same++;
1899                 } else {
1900                     push @differ,
1901  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1902                 }
1903             }
1904             die "$file ".Dumper($h)." ?!" if $same && @differ;
1905             $found_same++
1906                 if $same;
1907             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1908                 if @differ;
1909         }
1910         printdebug "origs $file f.same=$found_same".
1911             " #f._differ=$#found_differ\n";
1912         if (@found_differ && !$found_same) {
1913             fail join "\n",
1914                 "archive contains $file with different checksum",
1915                 @found_differ;
1916         }
1917         # Now we edit the changes file to add or remove it
1918         foreach my $csumi (@files_csum_info_fields) {
1919             my ($fname, $module, $method, $archivefield) = @$csumi;
1920             next unless defined $changes->{$fname};
1921             if ($found_same) {
1922                 # in archive, delete from .changes if it's there
1923                 $changed{$file} = "removed" if
1924                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1925             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1926                 # not in archive, but it's here in the .changes
1927             } else {
1928                 my $dsc_data = getfield $dsc, $fname;
1929                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1930                 my $extra = $1;
1931                 $extra =~ s/ \d+ /$&$placementinfo /
1932                     or die "$fname $extra >$dsc_data< ?"
1933                     if $fname eq 'Files';
1934                 $changes->{$fname} .= "\n". $extra;
1935                 $changed{$file} = "added";
1936             }
1937         }
1938     }
1939     if (%changed) {
1940         foreach my $file (keys %changed) {
1941             progress sprintf
1942                 "edited .changes for archive .orig contents: %s %s",
1943                 $changed{$file}, $file;
1944         }
1945         my $chtmp = "$changesfile.tmp";
1946         $changes->save($chtmp);
1947         if (act_local()) {
1948             rename $chtmp,$changesfile or die "$changesfile $!";
1949         } else {
1950             progress "[new .changes left in $changesfile]";
1951         }
1952     } else {
1953         progress "$changesfile already has appropriate .orig(s) (if any)";
1954     }
1955 }
1956
1957 sub make_commit ($) {
1958     my ($file) = @_;
1959     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1960 }
1961
1962 sub make_commit_text ($) {
1963     my ($text) = @_;
1964     my ($out, $in);
1965     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1966     debugcmd "|",@cmd;
1967     print Dumper($text) if $debuglevel > 1;
1968     my $child = open2($out, $in, @cmd) or die $!;
1969     my $h;
1970     eval {
1971         print $in $text or die $!;
1972         close $in or die $!;
1973         $h = <$out>;
1974         $h =~ m/^\w+$/ or die;
1975         $h = $&;
1976         printdebug "=> $h\n";
1977     };
1978     close $out;
1979     waitpid $child, 0 == $child or die "$child $!";
1980     $? and failedcmd @cmd;
1981     return $h;
1982 }
1983
1984 sub clogp_authline ($) {
1985     my ($clogp) = @_;
1986     my $author = getfield $clogp, 'Maintainer';
1987     $author =~ s#,.*##ms;
1988     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1989     my $authline = "$author $date";
1990     $authline =~ m/$git_authline_re/o or
1991         fail "unexpected commit author line format \`$authline'".
1992         " (was generated from changelog Maintainer field)";
1993     return ($1,$2,$3) if wantarray;
1994     return $authline;
1995 }
1996
1997 sub vendor_patches_distro ($$) {
1998     my ($checkdistro, $what) = @_;
1999     return unless defined $checkdistro;
2000
2001     my $series = "debian/patches/\L$checkdistro\E.series";
2002     printdebug "checking for vendor-specific $series ($what)\n";
2003
2004     if (!open SERIES, "<", $series) {
2005         die "$series $!" unless $!==ENOENT;
2006         return;
2007     }
2008     while (<SERIES>) {
2009         next unless m/\S/;
2010         next if m/^\s+\#/;
2011
2012         print STDERR <<END;
2013
2014 Unfortunately, this source package uses a feature of dpkg-source where
2015 the same source package unpacks to different source code on different
2016 distros.  dgit cannot safely operate on such packages on affected
2017 distros, because the meaning of source packages is not stable.
2018
2019 Please ask the distro/maintainer to remove the distro-specific series
2020 files and use a different technique (if necessary, uploading actually
2021 different packages, if different distros are supposed to have
2022 different code).
2023
2024 END
2025         fail "Found active distro-specific series file for".
2026             " $checkdistro ($what): $series, cannot continue";
2027     }
2028     die "$series $!" if SERIES->error;
2029     close SERIES;
2030 }
2031
2032 sub check_for_vendor_patches () {
2033     # This dpkg-source feature doesn't seem to be documented anywhere!
2034     # But it can be found in the changelog (reformatted):
2035
2036     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2037     #   Author: Raphael Hertzog <hertzog@debian.org>
2038     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2039
2040     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2041     #   series files
2042     #
2043     #   If you have debian/patches/ubuntu.series and you were
2044     #   unpacking the source package on ubuntu, quilt was still
2045     #   directed to debian/patches/series instead of
2046     #   debian/patches/ubuntu.series.
2047     #
2048     #   debian/changelog                        |    3 +++
2049     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2050     #   2 files changed, 6 insertions(+), 1 deletion(-)
2051
2052     use Dpkg::Vendor;
2053     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2054     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2055                          "Dpkg::Vendor \`current vendor'");
2056     vendor_patches_distro(access_basedistro(),
2057                           "(base) distro being accessed");
2058     vendor_patches_distro(access_nomdistro(),
2059                           "(nominal) distro being accessed");
2060 }
2061
2062 sub generate_commits_from_dsc () {
2063     # See big comment in fetch_from_archive, below.
2064     # See also README.dsc-import.
2065     prep_ud();
2066     changedir $ud;
2067
2068     my @dfi = dsc_files_info();
2069     foreach my $fi (@dfi) {
2070         my $f = $fi->{Filename};
2071         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2072
2073         printdebug "considering linking $f: ";
2074
2075         link_ltarget "../../../../$f", $f
2076             or ((printdebug "($!) "), 0)
2077             or $!==&ENOENT
2078             or die "$f $!";
2079
2080         printdebug "linked.\n";
2081
2082         complete_file_from_dsc('.', $fi)
2083             or next;
2084
2085         if (is_orig_file_in_dsc($f, \@dfi)) {
2086             link $f, "../../../../$f"
2087                 or $!==&EEXIST
2088                 or die "$f $!";
2089         }
2090     }
2091
2092     # We unpack and record the orig tarballs first, so that we only
2093     # need disk space for one private copy of the unpacked source.
2094     # But we can't make them into commits until we have the metadata
2095     # from the debian/changelog, so we record the tree objects now and
2096     # make them into commits later.
2097     my @tartrees;
2098     my $upstreamv = upstreamversion $dsc->{version};
2099     my $orig_f_base = srcfn $upstreamv, '';
2100
2101     foreach my $fi (@dfi) {
2102         # We actually import, and record as a commit, every tarball
2103         # (unless there is only one file, in which case there seems
2104         # little point.
2105
2106         my $f = $fi->{Filename};
2107         printdebug "import considering $f ";
2108         (printdebug "only one dfi\n"), next if @dfi == 1;
2109         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2110         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2111         my $compr_ext = $1;
2112
2113         my ($orig_f_part) =
2114             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2115
2116         printdebug "Y ", (join ' ', map { $_//"(none)" }
2117                           $compr_ext, $orig_f_part
2118                          ), "\n";
2119
2120         my $input = new IO::File $f, '<' or die "$f $!";
2121         my $compr_pid;
2122         my @compr_cmd;
2123
2124         if (defined $compr_ext) {
2125             my $cname =
2126                 Dpkg::Compression::compression_guess_from_filename $f;
2127             fail "Dpkg::Compression cannot handle file $f in source package"
2128                 if defined $compr_ext && !defined $cname;
2129             my $compr_proc =
2130                 new Dpkg::Compression::Process compression => $cname;
2131             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2132             my $compr_fh = new IO::Handle;
2133             my $compr_pid = open $compr_fh, "-|" // die $!;
2134             if (!$compr_pid) {
2135                 open STDIN, "<&", $input or die $!;
2136                 exec @compr_cmd;
2137                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2138             }
2139             $input = $compr_fh;
2140         }
2141
2142         rmtree "_unpack-tar";
2143         mkdir "_unpack-tar" or die $!;
2144         my @tarcmd = qw(tar -x -f -
2145                         --no-same-owner --no-same-permissions
2146                         --no-acls --no-xattrs --no-selinux);
2147         my $tar_pid = fork // die $!;
2148         if (!$tar_pid) {
2149             chdir "_unpack-tar" or die $!;
2150             open STDIN, "<&", $input or die $!;
2151             exec @tarcmd;
2152             die "dgit (child): exec $tarcmd[0]: $!";
2153         }
2154         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2155         !$? or failedcmd @tarcmd;
2156
2157         close $input or
2158             (@compr_cmd ? failedcmd @compr_cmd
2159              : die $!);
2160         # finally, we have the results in "tarball", but maybe
2161         # with the wrong permissions
2162
2163         runcmd qw(chmod -R +rwX _unpack-tar);
2164         changedir "_unpack-tar";
2165         remove_stray_gits($f);
2166         mktree_in_ud_here();
2167
2168         my ($tree) = git_add_write_tree();
2169         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2170         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2171             $tree = $1;
2172             printdebug "one subtree $1\n";
2173         } else {
2174             printdebug "multiple subtrees\n";
2175         }
2176         changedir "..";
2177         rmtree "_unpack-tar";
2178
2179         my $ent = [ $f, $tree ];
2180         push @tartrees, {
2181             Orig => !!$orig_f_part,
2182             Sort => (!$orig_f_part         ? 2 :
2183                      $orig_f_part =~ m/-/g ? 1 :
2184                                              0),
2185             F => $f,
2186             Tree => $tree,
2187         };
2188     }
2189
2190     @tartrees = sort {
2191         # put any without "_" first (spec is not clear whether files
2192         # are always in the usual order).  Tarballs without "_" are
2193         # the main orig or the debian tarball.
2194         $a->{Sort} <=> $b->{Sort} or
2195         $a->{F}    cmp $b->{F}
2196     } @tartrees;
2197
2198     my $any_orig = grep { $_->{Orig} } @tartrees;
2199
2200     my $dscfn = "$package.dsc";
2201
2202     my $treeimporthow = 'package';
2203
2204     open D, ">", $dscfn or die "$dscfn: $!";
2205     print D $dscdata or die "$dscfn: $!";
2206     close D or die "$dscfn: $!";
2207     my @cmd = qw(dpkg-source);
2208     push @cmd, '--no-check' if $dsc_checked;
2209     if (madformat $dsc->{format}) {
2210         push @cmd, '--skip-patches';
2211         $treeimporthow = 'unpatched';
2212     }
2213     push @cmd, qw(-x --), $dscfn;
2214     runcmd @cmd;
2215
2216     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2217     if (madformat $dsc->{format}) {
2218         check_for_vendor_patches();
2219     }
2220
2221     my $dappliedtree;
2222     if (madformat $dsc->{format}) {
2223         my @pcmd = qw(dpkg-source --before-build .);
2224         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2225         rmtree '.pc';
2226         $dappliedtree = git_add_write_tree();
2227     }
2228
2229     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2230     debugcmd "|",@clogcmd;
2231     open CLOGS, "-|", @clogcmd or die $!;
2232
2233     my $clogp;
2234     my $r1clogp;
2235
2236     printdebug "import clog search...\n";
2237
2238     for (;;) {
2239         my $stanzatext = do { local $/=""; <CLOGS>; };
2240         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2241         last if !defined $stanzatext;
2242
2243         my $desc = "package changelog, entry no.$.";
2244         open my $stanzafh, "<", \$stanzatext or die;
2245         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2246         $clogp //= $thisstanza;
2247
2248         printdebug "import clog $thisstanza->{version} $desc...\n";
2249
2250         last if !$any_orig; # we don't need $r1clogp
2251
2252         # We look for the first (most recent) changelog entry whose
2253         # version number is lower than the upstream version of this
2254         # package.  Then the last (least recent) previous changelog
2255         # entry is treated as the one which introduced this upstream
2256         # version and used for the synthetic commits for the upstream
2257         # tarballs.
2258
2259         # One might think that a more sophisticated algorithm would be
2260         # necessary.  But: we do not want to scan the whole changelog
2261         # file.  Stopping when we see an earlier version, which
2262         # necessarily then is an earlier upstream version, is the only
2263         # realistic way to do that.  Then, either the earliest
2264         # changelog entry we have seen so far is indeed the earliest
2265         # upload of this upstream version; or there are only changelog
2266         # entries relating to later upstream versions (which is not
2267         # possible unless the changelog and .dsc disagree about the
2268         # version).  Then it remains to choose between the physically
2269         # last entry in the file, and the one with the lowest version
2270         # number.  If these are not the same, we guess that the
2271         # versions were created in a non-monotic order rather than
2272         # that the changelog entries have been misordered.
2273
2274         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2275
2276         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2277         $r1clogp = $thisstanza;
2278
2279         printdebug "import clog $r1clogp->{version} becomes r1\n";
2280     }
2281     die $! if CLOGS->error;
2282     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2283
2284     $clogp or fail "package changelog has no entries!";
2285
2286     my $authline = clogp_authline $clogp;
2287     my $changes = getfield $clogp, 'Changes';
2288     my $cversion = getfield $clogp, 'Version';
2289
2290     if (@tartrees) {
2291         $r1clogp //= $clogp; # maybe there's only one entry;
2292         my $r1authline = clogp_authline $r1clogp;
2293         # Strictly, r1authline might now be wrong if it's going to be
2294         # unused because !$any_orig.  Whatever.
2295
2296         printdebug "import tartrees authline   $authline\n";
2297         printdebug "import tartrees r1authline $r1authline\n";
2298
2299         foreach my $tt (@tartrees) {
2300             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2301
2302             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2303 tree $tt->{Tree}
2304 author $r1authline
2305 committer $r1authline
2306
2307 Import $tt->{F}
2308
2309 [dgit import orig $tt->{F}]
2310 END_O
2311 tree $tt->{Tree}
2312 author $authline
2313 committer $authline
2314
2315 Import $tt->{F}
2316
2317 [dgit import tarball $package $cversion $tt->{F}]
2318 END_T
2319         }
2320     }
2321
2322     printdebug "import main commit\n";
2323
2324     open C, ">../commit.tmp" or die $!;
2325     print C <<END or die $!;
2326 tree $tree
2327 END
2328     print C <<END or die $! foreach @tartrees;
2329 parent $_->{Commit}
2330 END
2331     print C <<END or die $!;
2332 author $authline
2333 committer $authline
2334
2335 $changes
2336
2337 [dgit import $treeimporthow $package $cversion]
2338 END
2339
2340     close C or die $!;
2341     my $rawimport_hash = make_commit qw(../commit.tmp);
2342
2343     if (madformat $dsc->{format}) {
2344         printdebug "import apply patches...\n";
2345
2346         # regularise the state of the working tree so that
2347         # the checkout of $rawimport_hash works nicely.
2348         my $dappliedcommit = make_commit_text(<<END);
2349 tree $dappliedtree
2350 author $authline
2351 committer $authline
2352
2353 [dgit dummy commit]
2354 END
2355         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2356
2357         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2358
2359         # We need the answers to be reproducible
2360         my @authline = clogp_authline($clogp);
2361         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2362         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2363         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2364         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2365         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2366         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2367
2368         my $path = $ENV{PATH} or die;
2369
2370         foreach my $use_absurd (qw(0 1)) {
2371             runcmd @git, qw(checkout -q unpa);
2372             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2373             local $ENV{PATH} = $path;
2374             if ($use_absurd) {
2375                 chomp $@;
2376                 progress "warning: $@";
2377                 $path = "$absurdity:$path";
2378                 progress "$us: trying slow absurd-git-apply...";
2379                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2380                     or $!==ENOENT
2381                     or die $!;
2382             }
2383             eval {
2384                 die "forbid absurd git-apply\n" if $use_absurd
2385                     && forceing [qw(import-gitapply-no-absurd)];
2386                 die "only absurd git-apply!\n" if !$use_absurd
2387                     && forceing [qw(import-gitapply-absurd)];
2388
2389                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2390                 local $ENV{PATH} = $path                    if $use_absurd;
2391
2392                 my @showcmd = (gbp_pq, qw(import));
2393                 my @realcmd = shell_cmd
2394                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2395                 debugcmd "+",@realcmd;
2396                 if (system @realcmd) {
2397                     die +(shellquote @showcmd).
2398                         " failed: ".
2399                         failedcmd_waitstatus()."\n";
2400                 }
2401
2402                 my $gapplied = git_rev_parse('HEAD');
2403                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2404                 $gappliedtree eq $dappliedtree or
2405                     fail <<END;
2406 gbp-pq import and dpkg-source disagree!
2407  gbp-pq import gave commit $gapplied
2408  gbp-pq import gave tree $gappliedtree
2409  dpkg-source --before-build gave tree $dappliedtree
2410 END
2411                 $rawimport_hash = $gapplied;
2412             };
2413             last unless $@;
2414         }
2415         if ($@) {
2416             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2417             die $@;
2418         }
2419     }
2420
2421     progress "synthesised git commit from .dsc $cversion";
2422
2423     my $rawimport_mergeinput = {
2424         Commit => $rawimport_hash,
2425         Info => "Import of source package",
2426     };
2427     my @output = ($rawimport_mergeinput);
2428
2429     if ($lastpush_mergeinput) {
2430         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2431         my $oversion = getfield $oldclogp, 'Version';
2432         my $vcmp =
2433             version_compare($oversion, $cversion);
2434         if ($vcmp < 0) {
2435             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2436                 { Message => <<END, ReverseParents => 1 });
2437 Record $package ($cversion) in archive suite $csuite
2438 END
2439         } elsif ($vcmp > 0) {
2440             print STDERR <<END or die $!;
2441
2442 Version actually in archive:   $cversion (older)
2443 Last version pushed with dgit: $oversion (newer or same)
2444 $later_warning_msg
2445 END
2446             @output = $lastpush_mergeinput;
2447         } else {
2448             # Same version.  Use what's in the server git branch,
2449             # discarding our own import.  (This could happen if the
2450             # server automatically imports all packages into git.)
2451             @output = $lastpush_mergeinput;
2452         }
2453     }
2454     changedir '../../../..';
2455     rmtree($ud);
2456     return @output;
2457 }
2458
2459 sub complete_file_from_dsc ($$) {
2460     our ($dstdir, $fi) = @_;
2461     # Ensures that we have, in $dir, the file $fi, with the correct
2462     # contents.  (Downloading it from alongside $dscurl if necessary.)
2463
2464     my $f = $fi->{Filename};
2465     my $tf = "$dstdir/$f";
2466     my $downloaded = 0;
2467
2468     if (stat_exists $tf) {
2469         progress "using existing $f";
2470     } else {
2471         printdebug "$tf does not exist, need to fetch\n";
2472         my $furl = $dscurl;
2473         $furl =~ s{/[^/]+$}{};
2474         $furl .= "/$f";
2475         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2476         die "$f ?" if $f =~ m#/#;
2477         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2478         return 0 if !act_local();
2479         $downloaded = 1;
2480     }
2481
2482     open F, "<", "$tf" or die "$tf: $!";
2483     $fi->{Digester}->reset();
2484     $fi->{Digester}->addfile(*F);
2485     F->error and die $!;
2486     my $got = $fi->{Digester}->hexdigest();
2487     $got eq $fi->{Hash} or
2488         fail "file $f has hash $got but .dsc".
2489             " demands hash $fi->{Hash} ".
2490             ($downloaded ? "(got wrong file from archive!)"
2491              : "(perhaps you should delete this file?)");
2492
2493     return 1;
2494 }
2495
2496 sub ensure_we_have_orig () {
2497     my @dfi = dsc_files_info();
2498     foreach my $fi (@dfi) {
2499         my $f = $fi->{Filename};
2500         next unless is_orig_file_in_dsc($f, \@dfi);
2501         complete_file_from_dsc('..', $fi)
2502             or next;
2503     }
2504 }
2505
2506 #---------- git fetch ----------
2507
2508 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2509 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2510
2511 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2512 # locally fetched refs because they have unhelpful names and clutter
2513 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2514 # whether we have made another local ref which refers to this object).
2515 #
2516 # (If we deleted them unconditionally, then we might end up
2517 # re-fetching the same git objects each time dgit fetch was run.)
2518 #
2519 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
2520 # in git_fetch_us to fetch the refs in question, and possibly a call
2521 # to lrfetchref_used.
2522
2523 our (%lrfetchrefs_f, %lrfetchrefs_d);
2524 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2525
2526 sub lrfetchref_used ($) {
2527     my ($fullrefname) = @_;
2528     my $objid = $lrfetchrefs_f{$fullrefname};
2529     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2530 }
2531
2532 sub git_lrfetch_sane {
2533     my ($supplementary, @specs) = @_;
2534     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2535     # at least as regards @specs.  Also leave the results in
2536     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2537     # able to clean these up.
2538     #
2539     # With $supplementary==1, @specs must not contain wildcards
2540     # and we add to our previous fetches (non-atomically).
2541
2542     # This is rather miserable:
2543     # When git fetch --prune is passed a fetchspec ending with a *,
2544     # it does a plausible thing.  If there is no * then:
2545     # - it matches subpaths too, even if the supplied refspec
2546     #   starts refs, and behaves completely madly if the source
2547     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2548     # - if there is no matching remote ref, it bombs out the whole
2549     #   fetch.
2550     # We want to fetch a fixed ref, and we don't know in advance
2551     # if it exists, so this is not suitable.
2552     #
2553     # Our workaround is to use git ls-remote.  git ls-remote has its
2554     # own qairks.  Notably, it has the absurd multi-tail-matching
2555     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2556     # refs/refs/foo etc.
2557     #
2558     # Also, we want an idempotent snapshot, but we have to make two
2559     # calls to the remote: one to git ls-remote and to git fetch.  The
2560     # solution is use git ls-remote to obtain a target state, and
2561     # git fetch to try to generate it.  If we don't manage to generate
2562     # the target state, we try again.
2563
2564     my $url = access_giturl();
2565
2566     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2567
2568     my $specre = join '|', map {
2569         my $x = $_;
2570         $x =~ s/\W/\\$&/g;
2571         my $wildcard = $x =~ s/\\\*$/.*/;
2572         die if $wildcard && $supplementary;
2573         "(?:refs/$x)";
2574     } @specs;
2575     printdebug "git_lrfetch_sane specre=$specre\n";
2576     my $wanted_rref = sub {
2577         local ($_) = @_;
2578         return m/^(?:$specre)$/;
2579     };
2580
2581     my $fetch_iteration = 0;
2582     FETCH_ITERATION:
2583     for (;;) {
2584         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2585         if (++$fetch_iteration > 10) {
2586             fail "too many iterations trying to get sane fetch!";
2587         }
2588
2589         my @look = map { "refs/$_" } @specs;
2590         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2591         debugcmd "|",@lcmd;
2592
2593         my %wantr;
2594         open GITLS, "-|", @lcmd or die $!;
2595         while (<GITLS>) {
2596             printdebug "=> ", $_;
2597             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2598             my ($objid,$rrefname) = ($1,$2);
2599             if (!$wanted_rref->($rrefname)) {
2600                 print STDERR <<END;
2601 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2602 END
2603                 next;
2604             }
2605             $wantr{$rrefname} = $objid;
2606         }
2607         $!=0; $?=0;
2608         close GITLS or failedcmd @lcmd;
2609
2610         # OK, now %want is exactly what we want for refs in @specs
2611         my @fspecs = map {
2612             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2613             "+refs/$_:".lrfetchrefs."/$_";
2614         } @specs;
2615
2616         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2617
2618         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2619         runcmd_ordryrun_local @fcmd if @fspecs;
2620
2621         if (!$supplementary) {
2622             %lrfetchrefs_f = ();
2623         }
2624         my %objgot;
2625
2626         git_for_each_ref(lrfetchrefs, sub {
2627             my ($objid,$objtype,$lrefname,$reftail) = @_;
2628             $lrfetchrefs_f{$lrefname} = $objid;
2629             $objgot{$objid} = 1;
2630         });
2631
2632         if ($supplementary) {
2633             last;
2634         }
2635
2636         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2637             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2638             if (!exists $wantr{$rrefname}) {
2639                 if ($wanted_rref->($rrefname)) {
2640                     printdebug <<END;
2641 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2642 END
2643                 } else {
2644                     print STDERR <<END
2645 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2646 END
2647                 }
2648                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2649                 delete $lrfetchrefs_f{$lrefname};
2650                 next;
2651             }
2652         }
2653         foreach my $rrefname (sort keys %wantr) {
2654             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2655             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2656             my $want = $wantr{$rrefname};
2657             next if $got eq $want;
2658             if (!defined $objgot{$want}) {
2659                 print STDERR <<END;
2660 warning: git ls-remote suggests we want $lrefname
2661 warning:  and it should refer to $want
2662 warning:  but git fetch didn't fetch that object to any relevant ref.
2663 warning:  This may be due to a race with someone updating the server.
2664 warning:  Will try again...
2665 END
2666                 next FETCH_ITERATION;
2667             }
2668             printdebug <<END;
2669 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2670 END
2671             runcmd_ordryrun_local @git, qw(update-ref -m),
2672                 "dgit fetch git fetch fixup", $lrefname, $want;
2673             $lrfetchrefs_f{$lrefname} = $want;
2674         }
2675         last;
2676     }
2677
2678     if (defined $csuite) {
2679         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2680         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2681             my ($objid,$objtype,$lrefname,$reftail) = @_;
2682             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2683             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2684         });
2685     }
2686
2687     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2688         Dumper(\%lrfetchrefs_f);
2689 }
2690
2691 sub git_fetch_us () {
2692     # Want to fetch only what we are going to use, unless
2693     # deliberately-not-ff, in which case we must fetch everything.
2694
2695     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2696         map { "tags/$_" }
2697         (quiltmode_splitbrain
2698          ? (map { $_->('*',access_nomdistro) }
2699             \&debiantag_new, \&debiantag_maintview)
2700          : debiantags('*',access_nomdistro));
2701     push @specs, server_branch($csuite);
2702     push @specs, $rewritemap;
2703     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2704
2705     git_lrfetch_sane 0, @specs;
2706
2707     my %here;
2708     my @tagpats = debiantags('*',access_nomdistro);
2709
2710     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2711         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2712         printdebug "currently $fullrefname=$objid\n";
2713         $here{$fullrefname} = $objid;
2714     });
2715     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2716         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2717         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2718         printdebug "offered $lref=$objid\n";
2719         if (!defined $here{$lref}) {
2720             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2721             runcmd_ordryrun_local @upd;
2722             lrfetchref_used $fullrefname;
2723         } elsif ($here{$lref} eq $objid) {
2724             lrfetchref_used $fullrefname;
2725         } else {
2726             print STDERR \
2727                 "Not updateting $lref from $here{$lref} to $objid.\n";
2728         }
2729     });
2730 }
2731
2732 #---------- dsc and archive handling ----------
2733
2734 sub mergeinfo_getclogp ($) {
2735     # Ensures thit $mi->{Clogp} exists and returns it
2736     my ($mi) = @_;
2737     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2738 }
2739
2740 sub mergeinfo_version ($) {
2741     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2742 }
2743
2744 sub fetch_from_archive_record_1 ($) {
2745     my ($hash) = @_;
2746     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2747             'DGIT_ARCHIVE', $hash;
2748     cmdoutput @git, qw(log -n2), $hash;
2749     # ... gives git a chance to complain if our commit is malformed
2750 }
2751
2752 sub fetch_from_archive_record_2 ($) {
2753     my ($hash) = @_;
2754     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2755     if (act_local()) {
2756         cmdoutput @upd_cmd;
2757     } else {
2758         dryrun_report @upd_cmd;
2759     }
2760 }
2761
2762 sub parse_dsc_field ($$) {
2763     my ($dsc, $what) = @_;
2764     my $f;
2765     foreach my $field (@ourdscfield) {
2766         $f = $dsc->{$field};
2767         last if defined $f;
2768     }
2769     if (!defined $f) {
2770         progress "$what: NO git hash";
2771     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2772              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2773         progress "$what: specified git info ($dsc_distro)";
2774         $dsc_hint_tag = [ $dsc_hint_tag ];
2775     } elsif ($f =~ m/^\w+\s*$/) {
2776         $dsc_hash = $&;
2777         $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2778                                dgit.default.distro);
2779         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2780                           $dsc_distro ];
2781         progress "$what: specified git hash";
2782     } else {
2783         fail "$what: invalid Dgit info";
2784     }
2785 }
2786
2787 sub resolve_dsc_field_commit ($$) {
2788     my ($already_distro, $already_mapref) = @_;
2789
2790     return unless defined $dsc_hash;
2791
2792     my $mapref =
2793         defined $already_mapref &&
2794         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2795         ? $already_mapref : undef;
2796
2797     my $do_fetch;
2798     $do_fetch = sub {
2799         my ($what, @fetch) = @_;
2800
2801         local $idistro = $dsc_distro;
2802         my $lrf = lrfetchrefs;
2803
2804         if (!$chase_dsc_distro) {
2805             progress
2806                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2807             return 0;
2808         }
2809
2810         progress
2811             ".dsc names distro $dsc_distro: fetching $what";
2812
2813         my $url = access_giturl();
2814         if (!defined $url) {
2815             defined $dsc_hint_url or fail <<END;
2816 .dsc Dgit metadata is in context of distro $dsc_distro
2817 for which we have no configured url and .dsc provides no hint
2818 END
2819             my $proto =
2820                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2821                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2822             parse_cfg_bool "dsc-url-proto-ok", 'false',
2823                 cfg("dgit.dsc-url-proto-ok.$proto",
2824                     "dgit.default.dsc-url-proto-ok")
2825                 or fail <<END;
2826 .dsc Dgit metadata is in context of distro $dsc_distro
2827 for which we have no configured url;
2828 .dsc provices hinted url with protocol $proto which is unsafe.
2829 (can be overridden by config - consult documentation)
2830 END
2831             $url = $dsc_hint_url;
2832         }
2833
2834         git_lrfetch_sane 1, @fetch;
2835
2836         return $lrf;
2837     };
2838
2839     my $rewrite_enable = do {
2840         local $idistro = $dsc_distro;
2841         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2842     };
2843
2844     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2845         my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2846         $mapref = $lrf.'/'.$rewritemap;
2847         my $rewritemapdata = git_cat_file $mapref.':map';
2848         if (defined $rewritemapdata
2849             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2850             progress
2851                 "server's git history rewrite map contains a relevant entry!";
2852
2853             $dsc_hash = $1;
2854             if (defined $dsc_hash) {
2855                 progress "using rewritten git hash in place of .dsc value";
2856             } else {
2857                 progress "server data says .dsc hash is to be disregarded";
2858             }
2859         }
2860     }
2861
2862     if (!defined git_cat_file $dsc_hash) {
2863         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2864         my $lrf = $do_fetch->("additional commits", @tags) &&
2865             defined git_cat_file $dsc_hash
2866             or fail <<END;
2867 .dsc Dgit metadata requires commit $dsc_hash
2868 but we could not obtain that object anywhere.
2869 END
2870         foreach my $t (@tags) {
2871             my $fullrefname = $lrf.'/'.$t;
2872             print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2873             next unless $lrfetchrefs_f{$fullrefname};
2874             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2875             lrfetchref_used $fullrefname;
2876         }
2877     }
2878 }
2879
2880 sub fetch_from_archive () {
2881     ensure_setup_existing_tree();
2882
2883     # Ensures that lrref() is what is actually in the archive, one way
2884     # or another, according to us - ie this client's
2885     # appropritaely-updated archive view.  Also returns the commit id.
2886     # If there is nothing in the archive, leaves lrref alone and
2887     # returns undef.  git_fetch_us must have already been called.
2888     get_archive_dsc();
2889
2890     if ($dsc) {
2891         parse_dsc_field($dsc, 'last upload to archive');
2892         resolve_dsc_field_commit access_basedistro,
2893             lrfetchrefs."/".$rewritemap
2894     } else {
2895         progress "no version available from the archive";
2896     }
2897
2898     # If the archive's .dsc has a Dgit field, there are three
2899     # relevant git commitids we need to choose between and/or merge
2900     # together:
2901     #   1. $dsc_hash: the Dgit field from the archive
2902     #   2. $lastpush_hash: the suite branch on the dgit git server
2903     #   3. $lastfetch_hash: our local tracking brach for the suite
2904     #
2905     # These may all be distinct and need not be in any fast forward
2906     # relationship:
2907     #
2908     # If the dsc was pushed to this suite, then the server suite
2909     # branch will have been updated; but it might have been pushed to
2910     # a different suite and copied by the archive.  Conversely a more
2911     # recent version may have been pushed with dgit but not appeared
2912     # in the archive (yet).
2913     #
2914     # $lastfetch_hash may be awkward because archive imports
2915     # (particularly, imports of Dgit-less .dscs) are performed only as
2916     # needed on individual clients, so different clients may perform a
2917     # different subset of them - and these imports are only made
2918     # public during push.  So $lastfetch_hash may represent a set of
2919     # imports different to a subsequent upload by a different dgit
2920     # client.
2921     #
2922     # Our approach is as follows:
2923     #
2924     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2925     # descendant of $dsc_hash, then it was pushed by a dgit user who
2926     # had based their work on $dsc_hash, so we should prefer it.
2927     # Otherwise, $dsc_hash was installed into this suite in the
2928     # archive other than by a dgit push, and (necessarily) after the
2929     # last dgit push into that suite (since a dgit push would have
2930     # been descended from the dgit server git branch); thus, in that
2931     # case, we prefer the archive's version (and produce a
2932     # pseudo-merge to overwrite the dgit server git branch).
2933     #
2934     # (If there is no Dgit field in the archive's .dsc then
2935     # generate_commit_from_dsc uses the version numbers to decide
2936     # whether the suite branch or the archive is newer.  If the suite
2937     # branch is newer it ignores the archive's .dsc; otherwise it
2938     # generates an import of the .dsc, and produces a pseudo-merge to
2939     # overwrite the suite branch with the archive contents.)
2940     #
2941     # The outcome of that part of the algorithm is the `public view',
2942     # and is same for all dgit clients: it does not depend on any
2943     # unpublished history in the local tracking branch.
2944     #
2945     # As between the public view and the local tracking branch: The
2946     # local tracking branch is only updated by dgit fetch, and
2947     # whenever dgit fetch runs it includes the public view in the
2948     # local tracking branch.  Therefore if the public view is not
2949     # descended from the local tracking branch, the local tracking
2950     # branch must contain history which was imported from the archive
2951     # but never pushed; and, its tip is now out of date.  So, we make
2952     # a pseudo-merge to overwrite the old imports and stitch the old
2953     # history in.
2954     #
2955     # Finally: we do not necessarily reify the public view (as
2956     # described above).  This is so that we do not end up stacking two
2957     # pseudo-merges.  So what we actually do is figure out the inputs
2958     # to any public view pseudo-merge and put them in @mergeinputs.
2959
2960     my @mergeinputs;
2961     # $mergeinputs[]{Commit}
2962     # $mergeinputs[]{Info}
2963     # $mergeinputs[0] is the one whose tree we use
2964     # @mergeinputs is in the order we use in the actual commit)
2965     #
2966     # Also:
2967     # $mergeinputs[]{Message} is a commit message to use
2968     # $mergeinputs[]{ReverseParents} if def specifies that parent
2969     #                                list should be in opposite order
2970     # Such an entry has no Commit or Info.  It applies only when found
2971     # in the last entry.  (This ugliness is to support making
2972     # identical imports to previous dgit versions.)
2973
2974     my $lastpush_hash = git_get_ref(lrfetchref());
2975     printdebug "previous reference hash=$lastpush_hash\n";
2976     $lastpush_mergeinput = $lastpush_hash && {
2977         Commit => $lastpush_hash,
2978         Info => "dgit suite branch on dgit git server",
2979     };
2980
2981     my $lastfetch_hash = git_get_ref(lrref());
2982     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2983     my $lastfetch_mergeinput = $lastfetch_hash && {
2984         Commit => $lastfetch_hash,
2985         Info => "dgit client's archive history view",
2986     };
2987
2988     my $dsc_mergeinput = $dsc_hash && {
2989         Commit => $dsc_hash,
2990         Info => "Dgit field in .dsc from archive",
2991     };
2992
2993     my $cwd = getcwd();
2994     my $del_lrfetchrefs = sub {
2995         changedir $cwd;
2996         my $gur;
2997         printdebug "del_lrfetchrefs...\n";
2998         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2999             my $objid = $lrfetchrefs_d{$fullrefname};
3000             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3001             if (!$gur) {
3002                 $gur ||= new IO::Handle;
3003                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3004             }
3005             printf $gur "delete %s %s\n", $fullrefname, $objid;
3006         }
3007         if ($gur) {
3008             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3009         }
3010     };
3011
3012     if (defined $dsc_hash) {
3013         ensure_we_have_orig();
3014         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3015             @mergeinputs = $dsc_mergeinput
3016         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3017             print STDERR <<END or die $!;
3018
3019 Git commit in archive is behind the last version allegedly pushed/uploaded.
3020 Commit referred to by archive: $dsc_hash
3021 Last version pushed with dgit: $lastpush_hash
3022 $later_warning_msg
3023 END
3024             @mergeinputs = ($lastpush_mergeinput);
3025         } else {
3026             # Archive has .dsc which is not a descendant of the last dgit
3027             # push.  This can happen if the archive moves .dscs about.
3028             # Just follow its lead.
3029             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3030                 progress "archive .dsc names newer git commit";
3031                 @mergeinputs = ($dsc_mergeinput);
3032             } else {
3033                 progress "archive .dsc names other git commit, fixing up";
3034                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3035             }
3036         }
3037     } elsif ($dsc) {
3038         @mergeinputs = generate_commits_from_dsc();
3039         # We have just done an import.  Now, our import algorithm might
3040         # have been improved.  But even so we do not want to generate
3041         # a new different import of the same package.  So if the
3042         # version numbers are the same, just use our existing version.
3043         # If the version numbers are different, the archive has changed
3044         # (perhaps, rewound).
3045         if ($lastfetch_mergeinput &&
3046             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3047                               (mergeinfo_version $mergeinputs[0]) )) {
3048             @mergeinputs = ($lastfetch_mergeinput);
3049         }
3050     } elsif ($lastpush_hash) {
3051         # only in git, not in the archive yet
3052         @mergeinputs = ($lastpush_mergeinput);
3053         print STDERR <<END or die $!;
3054
3055 Package not found in the archive, but has allegedly been pushed using dgit.
3056 $later_warning_msg
3057 END
3058     } else {
3059         printdebug "nothing found!\n";
3060         if (defined $skew_warning_vsn) {
3061             print STDERR <<END or die $!;
3062
3063 Warning: relevant archive skew detected.
3064 Archive allegedly contains $skew_warning_vsn
3065 But we were not able to obtain any version from the archive or git.
3066
3067 END
3068         }
3069         unshift @end, $del_lrfetchrefs;
3070         return undef;
3071     }
3072
3073     if ($lastfetch_hash &&
3074         !grep {
3075             my $h = $_->{Commit};
3076             $h and is_fast_fwd($lastfetch_hash, $h);
3077             # If true, one of the existing parents of this commit
3078             # is a descendant of the $lastfetch_hash, so we'll
3079             # be ff from that automatically.
3080         } @mergeinputs
3081         ) {
3082         # Otherwise:
3083         push @mergeinputs, $lastfetch_mergeinput;
3084     }
3085
3086     printdebug "fetch mergeinfos:\n";
3087     foreach my $mi (@mergeinputs) {
3088         if ($mi->{Info}) {
3089             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3090         } else {
3091             printdebug sprintf " ReverseParents=%d Message=%s",
3092                 $mi->{ReverseParents}, $mi->{Message};
3093         }
3094     }
3095
3096     my $compat_info= pop @mergeinputs
3097         if $mergeinputs[$#mergeinputs]{Message};
3098
3099     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3100
3101     my $hash;
3102     if (@mergeinputs > 1) {
3103         # here we go, then:
3104         my $tree_commit = $mergeinputs[0]{Commit};
3105
3106         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3107         $tree =~ m/\n\n/;  $tree = $`;
3108         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3109         $tree = $1;
3110
3111         # We use the changelog author of the package in question the
3112         # author of this pseudo-merge.  This is (roughly) correct if
3113         # this commit is simply representing aa non-dgit upload.
3114         # (Roughly because it does not record sponsorship - but we
3115         # don't have sponsorship info because that's in the .changes,
3116         # which isn't in the archivw.)
3117         #
3118         # But, it might be that we are representing archive history
3119         # updates (including in-archive copies).  These are not really
3120         # the responsibility of the person who created the .dsc, but
3121         # there is no-one whose name we should better use.  (The
3122         # author of the .dsc-named commit is clearly worse.)
3123
3124         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3125         my $author = clogp_authline $useclogp;
3126         my $cversion = getfield $useclogp, 'Version';
3127
3128         my $mcf = ".git/dgit/mergecommit";
3129         open MC, ">", $mcf or die "$mcf $!";
3130         print MC <<END or die $!;
3131 tree $tree
3132 END
3133
3134         my @parents = grep { $_->{Commit} } @mergeinputs;
3135         @parents = reverse @parents if $compat_info->{ReverseParents};
3136         print MC <<END or die $! foreach @parents;
3137 parent $_->{Commit}
3138 END
3139
3140         print MC <<END or die $!;
3141 author $author
3142 committer $author
3143
3144 END
3145
3146         if (defined $compat_info->{Message}) {
3147             print MC $compat_info->{Message} or die $!;
3148         } else {
3149             print MC <<END or die $!;
3150 Record $package ($cversion) in archive suite $csuite
3151
3152 Record that
3153 END
3154             my $message_add_info = sub {
3155                 my ($mi) = (@_);
3156                 my $mversion = mergeinfo_version $mi;
3157                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3158                     or die $!;
3159             };
3160
3161             $message_add_info->($mergeinputs[0]);
3162             print MC <<END or die $!;
3163 should be treated as descended from
3164 END
3165             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3166         }
3167
3168         close MC or die $!;
3169         $hash = make_commit $mcf;
3170     } else {
3171         $hash = $mergeinputs[0]{Commit};
3172     }
3173     printdebug "fetch hash=$hash\n";
3174
3175     my $chkff = sub {
3176         my ($lasth, $what) = @_;
3177         return unless $lasth;
3178         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3179     };
3180
3181     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3182         if $lastpush_hash;
3183     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3184
3185     fetch_from_archive_record_1($hash);
3186
3187     if (defined $skew_warning_vsn) {
3188         mkpath '.git/dgit';
3189         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3190         my $gotclogp = commit_getclogp($hash);
3191         my $got_vsn = getfield $gotclogp, 'Version';
3192         printdebug "SKEW CHECK GOT $got_vsn\n";
3193         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3194             print STDERR <<END or die $!;
3195
3196 Warning: archive skew detected.  Using the available version:
3197 Archive allegedly contains    $skew_warning_vsn
3198 We were able to obtain only   $got_vsn
3199
3200 END
3201         }
3202     }
3203
3204     if ($lastfetch_hash ne $hash) {
3205         fetch_from_archive_record_2($hash);
3206     }
3207
3208     lrfetchref_used lrfetchref();
3209
3210     unshift @end, $del_lrfetchrefs;
3211     return $hash;
3212 }
3213
3214 sub set_local_git_config ($$) {
3215     my ($k, $v) = @_;
3216     runcmd @git, qw(config), $k, $v;
3217 }
3218
3219 sub setup_mergechangelogs (;$) {
3220     my ($always) = @_;
3221     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3222
3223     my $driver = 'dpkg-mergechangelogs';
3224     my $cb = "merge.$driver";
3225     my $attrs = '.git/info/attributes';
3226     ensuredir '.git/info';
3227
3228     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3229     if (!open ATTRS, "<", $attrs) {
3230         $!==ENOENT or die "$attrs: $!";
3231     } else {
3232         while (<ATTRS>) {
3233             chomp;
3234             next if m{^debian/changelog\s};
3235             print NATTRS $_, "\n" or die $!;
3236         }
3237         ATTRS->error and die $!;
3238         close ATTRS;
3239     }
3240     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3241     close NATTRS;
3242
3243     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3244     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3245
3246     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3247 }
3248
3249 sub setup_useremail (;$) {
3250     my ($always) = @_;
3251     return unless $always || access_cfg_bool(1, 'setup-useremail');
3252
3253     my $setup = sub {
3254         my ($k, $envvar) = @_;
3255         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3256         return unless defined $v;
3257         set_local_git_config "user.$k", $v;
3258     };
3259
3260     $setup->('email', 'DEBEMAIL');
3261     $setup->('name', 'DEBFULLNAME');
3262 }
3263
3264 sub ensure_setup_existing_tree () {
3265     my $k = "remote.$remotename.skipdefaultupdate";
3266     my $c = git_get_config $k;
3267     return if defined $c;
3268     set_local_git_config $k, 'true';
3269 }
3270
3271 sub setup_new_tree () {
3272     setup_mergechangelogs();
3273     setup_useremail();
3274 }
3275
3276 sub multisuite_suite_child ($$$) {
3277     my ($tsuite, $merginputs, $fn) = @_;
3278     # in child, sets things up, calls $fn->(), and returns undef
3279     # in parent, returns canonical suite name for $tsuite
3280     my $canonsuitefh = IO::File::new_tmpfile;
3281     my $pid = fork // die $!;
3282     if (!$pid) {
3283         $isuite = $tsuite;
3284         $us .= " [$isuite]";
3285         $debugprefix .= " ";
3286         progress "fetching $tsuite...";
3287         canonicalise_suite();
3288         print $canonsuitefh $csuite, "\n" or die $!;
3289         close $canonsuitefh or die $!;
3290         $fn->();
3291         return undef;
3292     }
3293     waitpid $pid,0 == $pid or die $!;
3294     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3295     seek $canonsuitefh,0,0 or die $!;
3296     local $csuite = <$canonsuitefh>;
3297     die $! unless defined $csuite && chomp $csuite;
3298     if ($? == 256*4) {
3299         printdebug "multisuite $tsuite missing\n";
3300         return $csuite;
3301     }
3302     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3303     push @$merginputs, {
3304         Ref => lrref,
3305         Info => $csuite,
3306     };
3307     return $csuite;
3308 }
3309
3310 sub fork_for_multisuite ($) {
3311     my ($before_fetch_merge) = @_;
3312     # if nothing unusual, just returns ''
3313     #
3314     # if multisuite:
3315     # returns 0 to caller in child, to do first of the specified suites
3316     # in child, $csuite is not yet set
3317     #
3318     # returns 1 to caller in parent, to finish up anything needed after
3319     # in parent, $csuite is set to canonicalised portmanteau
3320
3321     my $org_isuite = $isuite;
3322     my @suites = split /\,/, $isuite;
3323     return '' unless @suites > 1;
3324     printdebug "fork_for_multisuite: @suites\n";
3325
3326     my @mergeinputs;
3327
3328     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3329                                             sub { });
3330     return 0 unless defined $cbasesuite;
3331
3332     fail "package $package missing in (base suite) $cbasesuite"
3333         unless @mergeinputs;
3334
3335     my @csuites = ($cbasesuite);
3336
3337     $before_fetch_merge->();
3338
3339     foreach my $tsuite (@suites[1..$#suites]) {
3340         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3341                                                sub {
3342             @end = ();
3343             fetch();
3344             exit 0;
3345         });
3346         # xxx collecte the ref here
3347
3348         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3349         push @csuites, $csubsuite;
3350     }
3351
3352     foreach my $mi (@mergeinputs) {
3353         my $ref = git_get_ref $mi->{Ref};
3354         die "$mi->{Ref} ?" unless length $ref;
3355         $mi->{Commit} = $ref;
3356     }
3357
3358     $csuite = join ",", @csuites;
3359
3360     my $previous = git_get_ref lrref;
3361     if ($previous) {
3362         unshift @mergeinputs, {
3363             Commit => $previous,
3364             Info => "local combined tracking branch",
3365             Warning =>
3366  "archive seems to have rewound: local tracking branch is ahead!",
3367         };
3368     }
3369
3370     foreach my $ix (0..$#mergeinputs) {
3371         $mergeinputs[$ix]{Index} = $ix;
3372     }
3373
3374     @mergeinputs = sort {
3375         -version_compare(mergeinfo_version $a,
3376                          mergeinfo_version $b) # highest version first
3377             or
3378         $a->{Index} <=> $b->{Index}; # earliest in spec first
3379     } @mergeinputs;
3380
3381     my @needed;
3382
3383   NEEDED:
3384     foreach my $mi (@mergeinputs) {
3385         printdebug "multisuite merge check $mi->{Info}\n";
3386         foreach my $previous (@needed) {
3387             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3388             printdebug "multisuite merge un-needed $previous->{Info}\n";
3389             next NEEDED;
3390         }
3391         push @needed, $mi;
3392         printdebug "multisuite merge this-needed\n";
3393         $mi->{Character} = '+';
3394     }
3395
3396     $needed[0]{Character} = '*';
3397
3398     my $output = $needed[0]{Commit};
3399
3400     if (@needed > 1) {
3401         printdebug "multisuite merge nontrivial\n";
3402         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3403
3404         my $commit = "tree $tree\n";
3405         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3406             "Input branches:\n";
3407
3408         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3409             printdebug "multisuite merge include $mi->{Info}\n";
3410             $mi->{Character} //= ' ';
3411             $commit .= "parent $mi->{Commit}\n";
3412             $msg .= sprintf " %s  %-25s %s\n",
3413                 $mi->{Character},
3414                 (mergeinfo_version $mi),
3415                 $mi->{Info};
3416         }
3417         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3418         $msg .= "\nKey\n".
3419             " * marks the highest version branch, which choose to use\n".
3420             " + marks each branch which was not already an ancestor\n\n".
3421             "[dgit multi-suite $csuite]\n";
3422         $commit .=
3423             "author $authline\n".
3424             "committer $authline\n\n";
3425         $output = make_commit_text $commit.$msg;
3426         printdebug "multisuite merge generated $output\n";
3427     }
3428
3429     fetch_from_archive_record_1($output);
3430     fetch_from_archive_record_2($output);
3431
3432     progress "calculated combined tracking suite $csuite";
3433
3434     return 1;
3435 }
3436
3437 sub clone_set_head () {
3438     open H, "> .git/HEAD" or die $!;
3439     print H "ref: ".lref()."\n" or die $!;
3440     close H or die $!;
3441 }
3442 sub clone_finish ($) {
3443     my ($dstdir) = @_;
3444     runcmd @git, qw(reset --hard), lrref();
3445     runcmd qw(bash -ec), <<'END';
3446         set -o pipefail
3447         git ls-tree -r --name-only -z HEAD | \
3448         xargs -0r touch -h -r . --
3449 END
3450     printdone "ready for work in $dstdir";
3451 }
3452
3453 sub clone ($) {
3454     my ($dstdir) = @_;
3455     badusage "dry run makes no sense with clone" unless act_local();
3456
3457     my $multi_fetched = fork_for_multisuite(sub {
3458         printdebug "multi clone before fetch merge\n";
3459         changedir $dstdir;
3460     });
3461     if ($multi_fetched) {
3462         printdebug "multi clone after fetch merge\n";
3463         clone_set_head();
3464         clone_finish($dstdir);
3465         exit 0;
3466     }
3467     printdebug "clone main body\n";
3468
3469     canonicalise_suite();
3470     my $hasgit = check_for_git();
3471     mkdir $dstdir or fail "create \`$dstdir': $!";
3472     changedir $dstdir;
3473     runcmd @git, qw(init -q);
3474     clone_set_head();
3475     my $giturl = access_giturl(1);
3476     if (defined $giturl) {
3477         runcmd @git, qw(remote add), 'origin', $giturl;
3478     }
3479     if ($hasgit) {
3480         progress "fetching existing git history";
3481         git_fetch_us();
3482         runcmd_ordryrun_local @git, qw(fetch origin);
3483     } else {
3484         progress "starting new git history";
3485     }
3486     fetch_from_archive() or no_such_package;
3487     my $vcsgiturl = $dsc->{'Vcs-Git'};
3488     if (length $vcsgiturl) {
3489         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3490         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3491     }
3492     setup_new_tree();
3493     clone_finish($dstdir);
3494 }
3495
3496 sub fetch () {
3497     canonicalise_suite();
3498     if (check_for_git()) {
3499         git_fetch_us();
3500     }
3501     fetch_from_archive() or no_such_package();
3502     printdone "fetched into ".lrref();
3503 }
3504
3505 sub pull () {
3506     my $multi_fetched = fork_for_multisuite(sub { });
3507     fetch() unless $multi_fetched; # parent
3508     return if $multi_fetched eq '0'; # child
3509     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3510         lrref();
3511     printdone "fetched to ".lrref()." and merged into HEAD";
3512 }
3513
3514 sub check_not_dirty () {
3515     foreach my $f (qw(local-options local-patch-header)) {
3516         if (stat_exists "debian/source/$f") {
3517             fail "git tree contains debian/source/$f";
3518         }
3519     }
3520
3521     return if $ignoredirty;
3522
3523     my @cmd = (@git, qw(diff --quiet HEAD));
3524     debugcmd "+",@cmd;
3525     $!=0; $?=-1; system @cmd;
3526     return if !$?;
3527     if ($?==256) {
3528         fail "working tree is dirty (does not match HEAD)";
3529     } else {
3530         failedcmd @cmd;
3531     }
3532 }
3533
3534 sub commit_admin ($) {
3535     my ($m) = @_;
3536     progress "$m";
3537     runcmd_ordryrun_local @git, qw(commit -m), $m;
3538 }
3539
3540 sub commit_quilty_patch () {
3541     my $output = cmdoutput @git, qw(status --porcelain);
3542     my %adds;
3543     foreach my $l (split /\n/, $output) {
3544         next unless $l =~ m/\S/;
3545         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3546             $adds{$1}++;
3547         }
3548     }
3549     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3550     if (!%adds) {
3551         progress "nothing quilty to commit, ok.";
3552         return;
3553     }
3554     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3555     runcmd_ordryrun_local @git, qw(add -f), @adds;
3556     commit_admin <<END
3557 Commit Debian 3.0 (quilt) metadata
3558
3559 [dgit ($our_version) quilt-fixup]
3560 END
3561 }
3562
3563 sub get_source_format () {
3564     my %options;
3565     if (open F, "debian/source/options") {
3566         while (<F>) {
3567             next if m/^\s*\#/;
3568             next unless m/\S/;
3569             s/\s+$//; # ignore missing final newline
3570             if (m/\s*\#\s*/) {
3571                 my ($k, $v) = ($`, $'); #');
3572                 $v =~ s/^"(.*)"$/$1/;
3573                 $options{$k} = $v;
3574             } else {
3575                 $options{$_} = 1;
3576             }
3577         }
3578         F->error and die $!;
3579         close F;
3580     } else {
3581         die $! unless $!==&ENOENT;
3582     }
3583
3584     if (!open F, "debian/source/format") {
3585         die $! unless $!==&ENOENT;
3586         return '';
3587     }
3588     $_ = <F>;
3589     F->error and die $!;
3590     chomp;
3591     return ($_, \%options);
3592 }
3593
3594 sub madformat_wantfixup ($) {
3595     my ($format) = @_;
3596     return 0 unless $format eq '3.0 (quilt)';
3597     our $quilt_mode_warned;
3598     if ($quilt_mode eq 'nocheck') {
3599         progress "Not doing any fixup of \`$format' due to".
3600             " ----no-quilt-fixup or --quilt=nocheck"
3601             unless $quilt_mode_warned++;
3602         return 0;
3603     }
3604     progress "Format \`$format', need to check/update patch stack"
3605         unless $quilt_mode_warned++;
3606     return 1;
3607 }
3608
3609 sub maybe_split_brain_save ($$$) {
3610     my ($headref, $dgitview, $msg) = @_;
3611     # => message fragment "$saved" describing disposition of $dgitview
3612     return "commit id $dgitview" unless defined $split_brain_save;
3613     my @cmd = (shell_cmd "cd ../../../..",
3614                @git, qw(update-ref -m),
3615                "dgit --dgit-view-save $msg HEAD=$headref",
3616                $split_brain_save, $dgitview);
3617     runcmd @cmd;
3618     return "and left in $split_brain_save";
3619 }
3620
3621 # An "infopair" is a tuple [ $thing, $what ]
3622 # (often $thing is a commit hash; $what is a description)
3623
3624 sub infopair_cond_equal ($$) {
3625     my ($x,$y) = @_;
3626     $x->[0] eq $y->[0] or fail <<END;
3627 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3628 END
3629 };
3630
3631 sub infopair_lrf_tag_lookup ($$) {
3632     my ($tagnames, $what) = @_;
3633     # $tagname may be an array ref
3634     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3635     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3636     foreach my $tagname (@tagnames) {
3637         my $lrefname = lrfetchrefs."/tags/$tagname";
3638         my $tagobj = $lrfetchrefs_f{$lrefname};
3639         next unless defined $tagobj;
3640         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3641         return [ git_rev_parse($tagobj), $what ];
3642     }
3643     fail @tagnames==1 ? <<END : <<END;
3644 Wanted tag $what (@tagnames) on dgit server, but not found
3645 END
3646 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3647 END
3648 }
3649
3650 sub infopair_cond_ff ($$) {
3651     my ($anc,$desc) = @_;
3652     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3653 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3654 END
3655 };
3656
3657 sub pseudomerge_version_check ($$) {
3658     my ($clogp, $archive_hash) = @_;
3659
3660     my $arch_clogp = commit_getclogp $archive_hash;
3661     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3662                      'version currently in archive' ];
3663     if (defined $overwrite_version) {
3664         if (length $overwrite_version) {
3665             infopair_cond_equal([ $overwrite_version,
3666                                   '--overwrite= version' ],
3667                                 $i_arch_v);
3668         } else {
3669             my $v = $i_arch_v->[0];
3670             progress "Checking package changelog for archive version $v ...";
3671             eval {
3672                 my @xa = ("-f$v", "-t$v");
3673                 my $vclogp = parsechangelog @xa;
3674                 my $cv = [ (getfield $vclogp, 'Version'),
3675                            "Version field from dpkg-parsechangelog @xa" ];
3676                 infopair_cond_equal($i_arch_v, $cv);
3677             };
3678             if ($@) {
3679                 $@ =~ s/^dgit: //gm;
3680                 fail "$@".
3681                     "Perhaps debian/changelog does not mention $v ?";
3682             }
3683         }
3684     }
3685
3686     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3687     return $i_arch_v;
3688 }
3689
3690 sub pseudomerge_make_commit ($$$$ $$) {
3691     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3692         $msg_cmd, $msg_msg) = @_;
3693     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3694
3695     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3696     my $authline = clogp_authline $clogp;
3697
3698     chomp $msg_msg;
3699     $msg_cmd .=
3700         !defined $overwrite_version ? ""
3701         : !length  $overwrite_version ? " --overwrite"
3702         : " --overwrite=".$overwrite_version;
3703
3704     mkpath '.git/dgit';
3705     my $pmf = ".git/dgit/pseudomerge";
3706     open MC, ">", $pmf or die "$pmf $!";
3707     print MC <<END or die $!;
3708 tree $tree
3709 parent $dgitview
3710 parent $archive_hash
3711 author $authline
3712 committer $authline
3713
3714 $msg_msg
3715
3716 [$msg_cmd]
3717 END
3718     close MC or die $!;
3719
3720     return make_commit($pmf);
3721 }
3722
3723 sub splitbrain_pseudomerge ($$$$) {
3724     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3725     # => $merged_dgitview
3726     printdebug "splitbrain_pseudomerge...\n";
3727     #
3728     #     We:      debian/PREVIOUS    HEAD($maintview)
3729     # expect:          o ----------------- o
3730     #                    \                   \
3731     #                     o                   o
3732     #                 a/d/PREVIOUS        $dgitview
3733     #                $archive_hash              \
3734     #  If so,                \                   \
3735     #  we do:                 `------------------ o
3736     #   this:                                   $dgitview'
3737     #
3738
3739     return $dgitview unless defined $archive_hash;
3740
3741     printdebug "splitbrain_pseudomerge...\n";
3742
3743     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3744
3745     if (!defined $overwrite_version) {
3746         progress "Checking that HEAD inciudes all changes in archive...";
3747     }
3748
3749     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3750
3751     if (defined $overwrite_version) {
3752     } elsif (!eval {
3753         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3754         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3755         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3756         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3757         my $i_archive = [ $archive_hash, "current archive contents" ];
3758
3759         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3760
3761         infopair_cond_equal($i_dgit, $i_archive);
3762         infopair_cond_ff($i_dep14, $i_dgit);
3763         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3764         1;
3765     }) {
3766         print STDERR <<END;
3767 $us: check failed (maybe --overwrite is needed, consult documentation)
3768 END
3769         die "$@";
3770     }
3771
3772     my $r = pseudomerge_make_commit
3773         $clogp, $dgitview, $archive_hash, $i_arch_v,
3774         "dgit --quilt=$quilt_mode",
3775         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3776 Declare fast forward from $i_arch_v->[0]
3777 END_OVERWR
3778 Make fast forward from $i_arch_v->[0]
3779 END_MAKEFF
3780
3781     maybe_split_brain_save $maintview, $r, "pseudomerge";
3782
3783     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3784     return $r;
3785 }
3786
3787 sub plain_overwrite_pseudomerge ($$$) {
3788     my ($clogp, $head, $archive_hash) = @_;
3789
3790     printdebug "plain_overwrite_pseudomerge...";
3791
3792     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3793
3794     return $head if is_fast_fwd $archive_hash, $head;
3795
3796     my $m = "Declare fast forward from $i_arch_v->[0]";
3797
3798     my $r = pseudomerge_make_commit
3799         $clogp, $head, $archive_hash, $i_arch_v,
3800         "dgit", $m;
3801
3802     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3803
3804     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3805     return $r;
3806 }
3807
3808 sub push_parse_changelog ($) {
3809     my ($clogpfn) = @_;
3810
3811     my $clogp = Dpkg::Control::Hash->new();
3812     $clogp->load($clogpfn) or die;
3813
3814     my $clogpackage = getfield $clogp, 'Source';
3815     $package //= $clogpackage;
3816     fail "-p specified $package but changelog specified $clogpackage"
3817         unless $package eq $clogpackage;
3818     my $cversion = getfield $clogp, 'Version';
3819     my $tag = debiantag($cversion, access_nomdistro);
3820     runcmd @git, qw(check-ref-format), $tag;
3821
3822     my $dscfn = dscfn($cversion);
3823
3824     return ($clogp, $cversion, $dscfn);
3825 }
3826
3827 sub push_parse_dsc ($$$) {
3828     my ($dscfn,$dscfnwhat, $cversion) = @_;
3829     $dsc = parsecontrol($dscfn,$dscfnwhat);
3830     my $dversion = getfield $dsc, 'Version';
3831     my $dscpackage = getfield $dsc, 'Source';
3832     ($dscpackage eq $package && $dversion eq $cversion) or
3833         fail "$dscfn is for $dscpackage $dversion".
3834             " but debian/changelog is for $package $cversion";
3835 }
3836
3837 sub push_tagwants ($$$$) {
3838     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3839     my @tagwants;
3840     push @tagwants, {
3841         TagFn => \&debiantag,
3842         Objid => $dgithead,
3843         TfSuffix => '',
3844         View => 'dgit',
3845     };
3846     if (defined $maintviewhead) {
3847         push @tagwants, {
3848             TagFn => \&debiantag_maintview,
3849             Objid => $maintviewhead,
3850             TfSuffix => '-maintview',
3851             View => 'maint',
3852         };
3853     } elsif ($dodep14tag eq 'no' ? 0
3854              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3855              : $dodep14tag eq 'always'
3856              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3857 --dep14tag-always (or equivalent in config) means server must support
3858  both "new" and "maint" tag formats, but config says it doesn't.
3859 END
3860             : die "$dodep14tag ?") {
3861         push @tagwants, {
3862             TagFn => \&debiantag_maintview,
3863             Objid => $dgithead,
3864             TfSuffix => '-dgit',
3865             View => 'dgit',
3866         };
3867     };
3868     foreach my $tw (@tagwants) {
3869         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3870         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3871     }
3872     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3873     return @tagwants;
3874 }
3875
3876 sub push_mktags ($$ $$ $) {
3877     my ($clogp,$dscfn,
3878         $changesfile,$changesfilewhat,
3879         $tagwants) = @_;
3880
3881     die unless $tagwants->[0]{View} eq 'dgit';
3882
3883     my $declaredistro = access_nomdistro();
3884     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3885     $dsc->{$ourdscfield[0]} = join " ",
3886         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3887         $reader_giturl;
3888     $dsc->save("$dscfn.tmp") or die $!;
3889
3890     my $changes = parsecontrol($changesfile,$changesfilewhat);
3891     foreach my $field (qw(Source Distribution Version)) {
3892         $changes->{$field} eq $clogp->{$field} or
3893             fail "changes field $field \`$changes->{$field}'".
3894                 " does not match changelog \`$clogp->{$field}'";
3895     }
3896
3897     my $cversion = getfield $clogp, 'Version';
3898     my $clogsuite = getfield $clogp, 'Distribution';
3899
3900     # We make the git tag by hand because (a) that makes it easier
3901     # to control the "tagger" (b) we can do remote signing
3902     my $authline = clogp_authline $clogp;
3903     my $delibs = join(" ", "",@deliberatelies);
3904
3905     my $mktag = sub {
3906         my ($tw) = @_;
3907         my $tfn = $tw->{Tfn};
3908         my $head = $tw->{Objid};
3909         my $tag = $tw->{Tag};
3910
3911         open TO, '>', $tfn->('.tmp') or die $!;
3912         print TO <<END or die $!;
3913 object $head
3914 type commit
3915 tag $tag
3916 tagger $authline
3917
3918 END
3919         if ($tw->{View} eq 'dgit') {
3920             print TO <<END or die $!;
3921 $package release $cversion for $clogsuite ($csuite) [dgit]
3922 [dgit distro=$declaredistro$delibs]
3923 END
3924             foreach my $ref (sort keys %previously) {
3925                 print TO <<END or die $!;
3926 [dgit previously:$ref=$previously{$ref}]
3927 END
3928             }
3929         } elsif ($tw->{View} eq 'maint') {
3930             print TO <<END or die $!;
3931 $package release $cversion for $clogsuite ($csuite)
3932 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3933 END
3934         } else {
3935             die Dumper($tw)."?";
3936         }
3937
3938         close TO or die $!;
3939
3940         my $tagobjfn = $tfn->('.tmp');
3941         if ($sign) {
3942             if (!defined $keyid) {
3943                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3944             }
3945             if (!defined $keyid) {
3946                 $keyid = getfield $clogp, 'Maintainer';
3947             }
3948             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3949             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3950             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3951             push @sign_cmd, $tfn->('.tmp');
3952             runcmd_ordryrun @sign_cmd;
3953             if (act_scary()) {
3954                 $tagobjfn = $tfn->('.signed.tmp');
3955                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3956                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3957             }
3958         }
3959         return $tagobjfn;
3960     };
3961
3962     my @r = map { $mktag->($_); } @$tagwants;
3963     return @r;
3964 }
3965
3966 sub sign_changes ($) {
3967     my ($changesfile) = @_;
3968     if ($sign) {
3969         my @debsign_cmd = @debsign;
3970         push @debsign_cmd, "-k$keyid" if defined $keyid;
3971         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3972         push @debsign_cmd, $changesfile;
3973         runcmd_ordryrun @debsign_cmd;
3974     }
3975 }
3976
3977 sub dopush () {
3978     printdebug "actually entering push\n";
3979
3980     supplementary_message(<<'END');
3981 Push failed, while checking state of the archive.
3982 You can retry the push, after fixing the problem, if you like.
3983 END
3984     if (check_for_git()) {
3985         git_fetch_us();
3986     }
3987     my $archive_hash = fetch_from_archive();
3988     if (!$archive_hash) {
3989         $new_package or
3990             fail "package appears to be new in this suite;".
3991                 " if this is intentional, use --new";
3992     }
3993
3994     supplementary_message(<<'END');
3995 Push failed, while preparing your push.
3996 You can retry the push, after fixing the problem, if you like.
3997 END
3998
3999     need_tagformat 'new', "quilt mode $quilt_mode"
4000         if quiltmode_splitbrain;
4001
4002     prep_ud();
4003
4004     access_giturl(); # check that success is vaguely likely
4005     select_tagformat();
4006
4007     my $clogpfn = ".git/dgit/changelog.822.tmp";
4008     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4009
4010     responder_send_file('parsed-changelog', $clogpfn);
4011
4012     my ($clogp, $cversion, $dscfn) =
4013         push_parse_changelog("$clogpfn");
4014
4015     my $dscpath = "$buildproductsdir/$dscfn";
4016     stat_exists $dscpath or
4017         fail "looked for .dsc $dscpath, but $!;".
4018             " maybe you forgot to build";
4019
4020     responder_send_file('dsc', $dscpath);
4021
4022     push_parse_dsc($dscpath, $dscfn, $cversion);
4023
4024     my $format = getfield $dsc, 'Format';
4025     printdebug "format $format\n";
4026
4027     my $actualhead = git_rev_parse('HEAD');
4028     my $dgithead = $actualhead;
4029     my $maintviewhead = undef;
4030
4031     my $upstreamversion = upstreamversion $clogp->{Version};
4032
4033     if (madformat_wantfixup($format)) {
4034         # user might have not used dgit build, so maybe do this now:
4035         if (quiltmode_splitbrain()) {
4036             changedir $ud;
4037             quilt_make_fake_dsc($upstreamversion);
4038             my $cachekey;
4039             ($dgithead, $cachekey) =
4040                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4041             $dgithead or fail
4042  "--quilt=$quilt_mode but no cached dgit view:
4043  perhaps tree changed since dgit build[-source] ?";
4044             $split_brain = 1;
4045             $dgithead = splitbrain_pseudomerge($clogp,
4046                                                $actualhead, $dgithead,
4047                                                $archive_hash);
4048             $maintviewhead = $actualhead;
4049             changedir '../../../..';
4050             prep_ud(); # so _only_subdir() works, below
4051         } else {
4052             commit_quilty_patch();
4053         }
4054     }
4055
4056     if (defined $overwrite_version && !defined $maintviewhead) {
4057         $dgithead = plain_overwrite_pseudomerge($clogp,
4058                                                 $dgithead,
4059                                                 $archive_hash);
4060     }
4061
4062     check_not_dirty();
4063
4064     my $forceflag = '';
4065     if ($archive_hash) {
4066         if (is_fast_fwd($archive_hash, $dgithead)) {
4067             # ok
4068         } elsif (deliberately_not_fast_forward) {
4069             $forceflag = '+';
4070         } else {
4071             fail "dgit push: HEAD is not a descendant".
4072                 " of the archive's version.\n".
4073                 "To overwrite the archive's contents,".
4074                 " pass --overwrite[=VERSION].\n".
4075                 "To rewind history, if permitted by the archive,".
4076                 " use --deliberately-not-fast-forward.";
4077         }
4078     }
4079
4080     changedir $ud;
4081     progress "checking that $dscfn corresponds to HEAD";
4082     runcmd qw(dpkg-source -x --),
4083         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4084     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4085     check_for_vendor_patches() if madformat($dsc->{format});
4086     changedir '../../../..';
4087     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4088     debugcmd "+",@diffcmd;
4089     $!=0; $?=-1;
4090     my $r = system @diffcmd;
4091     if ($r) {
4092         if ($r==256) {
4093             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4094             fail <<END
4095 HEAD specifies a different tree to $dscfn:
4096 $diffs
4097 Perhaps you forgot to build.  Or perhaps there is a problem with your
4098  source tree (see dgit(7) for some hints).  To see a full diff, run
4099    git diff $tree HEAD
4100 END
4101         } else {
4102             failedcmd @diffcmd;
4103         }
4104     }
4105     if (!$changesfile) {
4106         my $pat = changespat $cversion;
4107         my @cs = glob "$buildproductsdir/$pat";
4108         fail "failed to find unique changes file".
4109             " (looked for $pat in $buildproductsdir);".
4110             " perhaps you need to use dgit -C"
4111             unless @cs==1;
4112         ($changesfile) = @cs;
4113     } else {
4114         $changesfile = "$buildproductsdir/$changesfile";
4115     }
4116
4117     # Check that changes and .dsc agree enough
4118     $changesfile =~ m{[^/]*$};
4119     my $changes = parsecontrol($changesfile,$&);
4120     files_compare_inputs($dsc, $changes)
4121         unless forceing [qw(dsc-changes-mismatch)];
4122
4123     # Perhaps adjust .dsc to contain right set of origs
4124     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4125                                   $changesfile)
4126         unless forceing [qw(changes-origs-exactly)];
4127
4128     # Checks complete, we're going to try and go ahead:
4129
4130     responder_send_file('changes',$changesfile);
4131     responder_send_command("param head $dgithead");
4132     responder_send_command("param csuite $csuite");
4133     responder_send_command("param tagformat $tagformat");
4134     if (defined $maintviewhead) {
4135         die unless ($protovsn//4) >= 4;
4136         responder_send_command("param maint-view $maintviewhead");
4137     }
4138
4139     if (deliberately_not_fast_forward) {
4140         git_for_each_ref(lrfetchrefs, sub {
4141             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4142             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4143             responder_send_command("previously $rrefname=$objid");
4144             $previously{$rrefname} = $objid;
4145         });
4146     }
4147
4148     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4149                                  ".git/dgit/tag");
4150     my @tagobjfns;
4151
4152     supplementary_message(<<'END');
4153 Push failed, while signing the tag.
4154 You can retry the push, after fixing the problem, if you like.
4155 END
4156     # If we manage to sign but fail to record it anywhere, it's fine.
4157     if ($we_are_responder) {
4158         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4159         responder_receive_files('signed-tag', @tagobjfns);
4160     } else {
4161         @tagobjfns = push_mktags($clogp,$dscpath,
4162                               $changesfile,$changesfile,
4163                               \@tagwants);
4164     }
4165     supplementary_message(<<'END');
4166 Push failed, *after* signing the tag.
4167 If you want to try again, you should use a new version number.
4168 END
4169
4170     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4171
4172     foreach my $tw (@tagwants) {
4173         my $tag = $tw->{Tag};
4174         my $tagobjfn = $tw->{TagObjFn};
4175         my $tag_obj_hash =
4176             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4177         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4178         runcmd_ordryrun_local
4179             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4180     }
4181
4182     supplementary_message(<<'END');
4183 Push failed, while updating the remote git repository - see messages above.
4184 If you want to try again, you should use a new version number.
4185 END
4186     if (!check_for_git()) {
4187         create_remote_git_repo();
4188     }
4189
4190     my @pushrefs = $forceflag.$dgithead.":".rrref();
4191     foreach my $tw (@tagwants) {
4192         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4193     }
4194
4195     runcmd_ordryrun @git,
4196         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4197     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4198
4199     supplementary_message(<<'END');
4200 Push failed, while obtaining signatures on the .changes and .dsc.
4201 If it was just that the signature failed, you may try again by using
4202 debsign by hand to sign the changes
4203    $changesfile
4204 and then dput to complete the upload.
4205 If you need to change the package, you must use a new version number.
4206 END
4207     if ($we_are_responder) {
4208         my $dryrunsuffix = act_local() ? "" : ".tmp";
4209         responder_receive_files('signed-dsc-changes',
4210                                 "$dscpath$dryrunsuffix",
4211                                 "$changesfile$dryrunsuffix");
4212     } else {
4213         if (act_local()) {
4214             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4215         } else {
4216             progress "[new .dsc left in $dscpath.tmp]";
4217         }
4218         sign_changes $changesfile;
4219     }
4220
4221     supplementary_message(<<END);
4222 Push failed, while uploading package(s) to the archive server.
4223 You can retry the upload of exactly these same files with dput of:
4224   $changesfile
4225 If that .changes file is broken, you will need to use a new version
4226 number for your next attempt at the upload.
4227 END
4228     my $host = access_cfg('upload-host','RETURN-UNDEF');
4229     my @hostarg = defined($host) ? ($host,) : ();
4230     runcmd_ordryrun @dput, @hostarg, $changesfile;
4231     printdone "pushed and uploaded $cversion";
4232
4233     supplementary_message('');
4234     responder_send_command("complete");
4235 }
4236
4237 sub cmd_clone {
4238     parseopts();
4239     my $dstdir;
4240     badusage "-p is not allowed with clone; specify as argument instead"
4241         if defined $package;
4242     if (@ARGV==1) {
4243         ($package) = @ARGV;
4244     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4245         ($package,$isuite) = @ARGV;
4246     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4247         ($package,$dstdir) = @ARGV;
4248     } elsif (@ARGV==3) {
4249         ($package,$isuite,$dstdir) = @ARGV;
4250     } else {
4251         badusage "incorrect arguments to dgit clone";
4252     }
4253     notpushing();
4254
4255     $dstdir ||= "$package";
4256     if (stat_exists $dstdir) {
4257         fail "$dstdir already exists";
4258     }
4259
4260     my $cwd_remove;
4261     if ($rmonerror && !$dryrun_level) {
4262         $cwd_remove= getcwd();
4263         unshift @end, sub {
4264             return unless defined $cwd_remove;
4265             if (!chdir "$cwd_remove") {
4266                 return if $!==&ENOENT;
4267                 die "chdir $cwd_remove: $!";
4268             }
4269             printdebug "clone rmonerror removing $dstdir\n";
4270             if (stat $dstdir) {
4271                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4272             } elsif (grep { $! == $_ }
4273                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4274             } else {
4275                 print STDERR "check whether to remove $dstdir: $!\n";
4276             }
4277         };
4278     }
4279
4280     clone($dstdir);
4281     $cwd_remove = undef;
4282 }
4283
4284 sub branchsuite () {
4285     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4286     if ($branch =~ m#$lbranch_re#o) {
4287         return $1;
4288     } else {
4289         return undef;
4290     }
4291 }
4292
4293 sub fetchpullargs () {
4294     if (!defined $package) {
4295         my $sourcep = parsecontrol('debian/control','debian/control');
4296         $package = getfield $sourcep, 'Source';
4297     }
4298     if (@ARGV==0) {
4299         $isuite = branchsuite();
4300         if (!$isuite) {
4301             my $clogp = parsechangelog();
4302             $isuite = getfield $clogp, 'Distribution';
4303         }
4304     } elsif (@ARGV==1) {
4305         ($isuite) = @ARGV;
4306     } else {
4307         badusage "incorrect arguments to dgit fetch or dgit pull";
4308     }
4309     notpushing();
4310 }
4311
4312 sub cmd_fetch {
4313     parseopts();
4314     fetchpullargs();
4315     my $multi_fetched = fork_for_multisuite(sub { });
4316     exit 0 if $multi_fetched;
4317     fetch();
4318 }
4319
4320 sub cmd_pull {
4321     parseopts();
4322     fetchpullargs();
4323     if (quiltmode_splitbrain()) {
4324         my ($format, $fopts) = get_source_format();
4325         madformat($format) and fail <<END
4326 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4327 END
4328     }
4329     pull();
4330 }
4331
4332 sub cmd_push {
4333     parseopts();
4334     pushing();
4335     badusage "-p is not allowed with dgit push" if defined $package;
4336     check_not_dirty();
4337     my $clogp = parsechangelog();
4338     $package = getfield $clogp, 'Source';
4339     my $specsuite;
4340     if (@ARGV==0) {
4341     } elsif (@ARGV==1) {
4342         ($specsuite) = (@ARGV);
4343     } else {
4344         badusage "incorrect arguments to dgit push";
4345     }
4346     $isuite = getfield $clogp, 'Distribution';
4347     if ($new_package) {
4348         local ($package) = $existing_package; # this is a hack
4349         canonicalise_suite();
4350     } else {
4351         canonicalise_suite();
4352     }
4353     if (defined $specsuite &&
4354         $specsuite ne $isuite &&
4355         $specsuite ne $csuite) {
4356             fail "dgit push: changelog specifies $isuite ($csuite)".
4357                 " but command line specifies $specsuite";
4358     }
4359     dopush();
4360 }
4361
4362 #---------- remote commands' implementation ----------
4363
4364 sub cmd_remote_push_build_host {
4365     my ($nrargs) = shift @ARGV;
4366     my (@rargs) = @ARGV[0..$nrargs-1];
4367     @ARGV = @ARGV[$nrargs..$#ARGV];
4368     die unless @rargs;
4369     my ($dir,$vsnwant) = @rargs;
4370     # vsnwant is a comma-separated list; we report which we have
4371     # chosen in our ready response (so other end can tell if they
4372     # offered several)
4373     $debugprefix = ' ';
4374     $we_are_responder = 1;
4375     $us .= " (build host)";
4376
4377     pushing();
4378
4379     open PI, "<&STDIN" or die $!;
4380     open STDIN, "/dev/null" or die $!;
4381     open PO, ">&STDOUT" or die $!;
4382     autoflush PO 1;
4383     open STDOUT, ">&STDERR" or die $!;
4384     autoflush STDOUT 1;
4385
4386     $vsnwant //= 1;
4387     ($protovsn) = grep {
4388         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4389     } @rpushprotovsn_support;
4390
4391     fail "build host has dgit rpush protocol versions ".
4392         (join ",", @rpushprotovsn_support).
4393         " but invocation host has $vsnwant"
4394         unless defined $protovsn;
4395
4396     responder_send_command("dgit-remote-push-ready $protovsn");
4397     rpush_handle_protovsn_bothends();
4398     changedir $dir;
4399     &cmd_push;
4400 }
4401
4402 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4403 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4404 #     a good error message)
4405
4406 sub rpush_handle_protovsn_bothends () {
4407     if ($protovsn < 4) {
4408         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4409     }
4410     select_tagformat();
4411 }
4412
4413 our $i_tmp;
4414
4415 sub i_cleanup {
4416     local ($@, $?);
4417     my $report = i_child_report();
4418     if (defined $report) {
4419         printdebug "($report)\n";
4420     } elsif ($i_child_pid) {
4421         printdebug "(killing build host child $i_child_pid)\n";
4422         kill 15, $i_child_pid;
4423     }
4424     if (defined $i_tmp && !defined $initiator_tempdir) {
4425         changedir "/";
4426         eval { rmtree $i_tmp; };
4427     }
4428 }
4429
4430 END { i_cleanup(); }
4431
4432 sub i_method {
4433     my ($base,$selector,@args) = @_;
4434     $selector =~ s/\-/_/g;
4435     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4436 }
4437
4438 sub cmd_rpush {
4439     pushing();
4440     my $host = nextarg;
4441     my $dir;
4442     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4443         $host = $1;
4444         $dir = $'; #';
4445     } else {
4446         $dir = nextarg;
4447     }
4448     $dir =~ s{^-}{./-};
4449     my @rargs = ($dir);
4450     push @rargs, join ",", @rpushprotovsn_support;
4451     my @rdgit;
4452     push @rdgit, @dgit;
4453     push @rdgit, @ropts;
4454     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4455     push @rdgit, @ARGV;
4456     my @cmd = (@ssh, $host, shellquote @rdgit);
4457     debugcmd "+",@cmd;
4458
4459     if (defined $initiator_tempdir) {
4460         rmtree $initiator_tempdir;
4461         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4462         $i_tmp = $initiator_tempdir;
4463     } else {
4464         $i_tmp = tempdir();
4465     }
4466     $i_child_pid = open2(\*RO, \*RI, @cmd);
4467     changedir $i_tmp;
4468     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4469     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4470     $supplementary_message = '' unless $protovsn >= 3;
4471
4472     fail "rpush negotiated protocol version $protovsn".
4473         " which does not support quilt mode $quilt_mode"
4474         if quiltmode_splitbrain;
4475
4476     rpush_handle_protovsn_bothends();
4477     for (;;) {
4478         my ($icmd,$iargs) = initiator_expect {
4479             m/^(\S+)(?: (.*))?$/;
4480             ($1,$2);
4481         };
4482         i_method "i_resp", $icmd, $iargs;
4483     }
4484 }
4485
4486 sub i_resp_progress ($) {
4487     my ($rhs) = @_;
4488     my $msg = protocol_read_bytes \*RO, $rhs;
4489     progress $msg;
4490 }
4491
4492 sub i_resp_supplementary_message ($) {
4493     my ($rhs) = @_;
4494     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4495 }
4496
4497 sub i_resp_complete {
4498     my $pid = $i_child_pid;
4499     $i_child_pid = undef; # prevents killing some other process with same pid
4500     printdebug "waiting for build host child $pid...\n";
4501     my $got = waitpid $pid, 0;
4502     die $! unless $got == $pid;
4503     die "build host child failed $?" if $?;
4504
4505     i_cleanup();
4506     printdebug "all done\n";
4507     exit 0;
4508 }
4509
4510 sub i_resp_file ($) {
4511     my ($keyword) = @_;
4512     my $localname = i_method "i_localname", $keyword;
4513     my $localpath = "$i_tmp/$localname";
4514     stat_exists $localpath and
4515         badproto \*RO, "file $keyword ($localpath) twice";
4516     protocol_receive_file \*RO, $localpath;
4517     i_method "i_file", $keyword;
4518 }
4519
4520 our %i_param;
4521
4522 sub i_resp_param ($) {
4523     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4524     $i_param{$1} = $2;
4525 }
4526
4527 sub i_resp_previously ($) {
4528     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4529         or badproto \*RO, "bad previously spec";
4530     my $r = system qw(git check-ref-format), $1;
4531     die "bad previously ref spec ($r)" if $r;
4532     $previously{$1} = $2;
4533 }
4534
4535 our %i_wanted;
4536
4537 sub i_resp_want ($) {
4538     my ($keyword) = @_;
4539     die "$keyword ?" if $i_wanted{$keyword}++;
4540     my @localpaths = i_method "i_want", $keyword;
4541     printdebug "[[  $keyword @localpaths\n";
4542     foreach my $localpath (@localpaths) {
4543         protocol_send_file \*RI, $localpath;
4544     }
4545     print RI "files-end\n" or die $!;
4546 }
4547
4548 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4549
4550 sub i_localname_parsed_changelog {
4551     return "remote-changelog.822";
4552 }
4553 sub i_file_parsed_changelog {
4554     ($i_clogp, $i_version, $i_dscfn) =
4555         push_parse_changelog "$i_tmp/remote-changelog.822";
4556     die if $i_dscfn =~ m#/|^\W#;
4557 }
4558
4559 sub i_localname_dsc {
4560     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4561     return $i_dscfn;
4562 }
4563 sub i_file_dsc { }
4564
4565 sub i_localname_changes {
4566     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4567     $i_changesfn = $i_dscfn;
4568     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4569     return $i_changesfn;
4570 }
4571 sub i_file_changes { }
4572
4573 sub i_want_signed_tag {
4574     printdebug Dumper(\%i_param, $i_dscfn);
4575     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4576         && defined $i_param{'csuite'}
4577         or badproto \*RO, "premature desire for signed-tag";
4578     my $head = $i_param{'head'};
4579     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4580
4581     my $maintview = $i_param{'maint-view'};
4582     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4583
4584     select_tagformat();
4585     if ($protovsn >= 4) {
4586         my $p = $i_param{'tagformat'} // '<undef>';
4587         $p eq $tagformat
4588             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4589     }
4590
4591     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4592     $csuite = $&;
4593     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4594
4595     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4596
4597     return
4598         push_mktags $i_clogp, $i_dscfn,
4599             $i_changesfn, 'remote changes',
4600             \@tagwants;
4601 }
4602
4603 sub i_want_signed_dsc_changes {
4604     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4605     sign_changes $i_changesfn;
4606     return ($i_dscfn, $i_changesfn);
4607 }
4608
4609 #---------- building etc. ----------
4610
4611 our $version;
4612 our $sourcechanges;
4613 our $dscfn;
4614
4615 #----- `3.0 (quilt)' handling -----
4616
4617 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4618
4619 sub quiltify_dpkg_commit ($$$;$) {
4620     my ($patchname,$author,$msg, $xinfo) = @_;
4621     $xinfo //= '';
4622
4623     mkpath '.git/dgit';
4624     my $descfn = ".git/dgit/quilt-description.tmp";
4625     open O, '>', $descfn or die "$descfn: $!";
4626     $msg =~ s/\n+/\n\n/;
4627     print O <<END or die $!;
4628 From: $author
4629 ${xinfo}Subject: $msg
4630 ---
4631
4632 END
4633     close O or die $!;
4634
4635     {
4636         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4637         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4638         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4639         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4640     }
4641 }
4642
4643 sub quiltify_trees_differ ($$;$$$) {
4644     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4645     # returns true iff the two tree objects differ other than in debian/
4646     # with $finegrained,
4647     # returns bitmask 01 - differ in upstream files except .gitignore
4648     #                 02 - differ in .gitignore
4649     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4650     #  is set for each modified .gitignore filename $fn
4651     # if $unrepres is defined, array ref to which is appeneded
4652     #  a list of unrepresentable changes (removals of upstream files
4653     #  (as messages)
4654     local $/=undef;
4655     my @cmd = (@git, qw(diff-tree -z));
4656     push @cmd, qw(--name-only) unless $unrepres;
4657     push @cmd, qw(-r) if $finegrained || $unrepres;
4658     push @cmd, $x, $y;
4659     my $diffs= cmdoutput @cmd;
4660     my $r = 0;
4661     my @lmodes;
4662     foreach my $f (split /\0/, $diffs) {
4663         if ($unrepres && !@lmodes) {
4664             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4665             next;
4666         }
4667         my ($oldmode,$newmode) = @lmodes;
4668         @lmodes = ();
4669
4670         next if $f =~ m#^debian(?:/.*)?$#s;
4671
4672         if ($unrepres) {
4673             eval {
4674                 die "not a plain file\n"
4675                     unless $newmode =~ m/^10\d{4}$/ ||
4676                            $oldmode =~ m/^10\d{4}$/;
4677                 if ($oldmode =~ m/[^0]/ &&
4678                     $newmode =~ m/[^0]/) {
4679                     die "mode changed\n" if $oldmode ne $newmode;
4680                 } else {
4681                     die "non-default mode\n"
4682                         unless $newmode =~ m/^100644$/ ||
4683                                $oldmode =~ m/^100644$/;
4684                 }
4685             };
4686             if ($@) {
4687                 local $/="\n"; chomp $@;
4688                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4689             }
4690         }
4691
4692         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4693         $r |= $isignore ? 02 : 01;
4694         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4695     }
4696     printdebug "quiltify_trees_differ $x $y => $r\n";
4697     return $r;
4698 }
4699
4700 sub quiltify_tree_sentinelfiles ($) {
4701     # lists the `sentinel' files present in the tree
4702     my ($x) = @_;
4703     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4704         qw(-- debian/rules debian/control);
4705     $r =~ s/\n/,/g;
4706     return $r;
4707 }
4708
4709 sub quiltify_splitbrain_needed () {
4710     if (!$split_brain) {
4711         progress "dgit view: changes are required...";
4712         runcmd @git, qw(checkout -q -b dgit-view);
4713         $split_brain = 1;
4714     }
4715 }
4716
4717 sub quiltify_splitbrain ($$$$$$) {
4718     my ($clogp, $unapplied, $headref, $diffbits,
4719         $editedignores, $cachekey) = @_;
4720     if ($quilt_mode !~ m/gbp|dpm/) {
4721         # treat .gitignore just like any other upstream file
4722         $diffbits = { %$diffbits };
4723         $_ = !!$_ foreach values %$diffbits;
4724     }
4725     # We would like any commits we generate to be reproducible
4726     my @authline = clogp_authline($clogp);
4727     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4728     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4729     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4730     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4731     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4732     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4733
4734     if ($quilt_mode =~ m/gbp|unapplied/ &&
4735         ($diffbits->{O2H} & 01)) {
4736         my $msg =
4737  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4738  " but git tree differs from orig in upstream files.";
4739         if (!stat_exists "debian/patches") {
4740             $msg .=
4741  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4742         }
4743         fail $msg;
4744     }
4745     if ($quilt_mode =~ m/dpm/ &&
4746         ($diffbits->{H2A} & 01)) {
4747         fail <<END;
4748 --quilt=$quilt_mode specified, implying patches-applied git tree
4749  but git tree differs from result of applying debian/patches to upstream
4750 END
4751     }
4752     if ($quilt_mode =~ m/gbp|unapplied/ &&
4753         ($diffbits->{O2A} & 01)) { # some patches
4754         quiltify_splitbrain_needed();
4755         progress "dgit view: creating patches-applied version using gbp pq";
4756         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4757         # gbp pq import creates a fresh branch; push back to dgit-view
4758         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4759         runcmd @git, qw(checkout -q dgit-view);
4760     }
4761     if ($quilt_mode =~ m/gbp|dpm/ &&
4762         ($diffbits->{O2A} & 02)) {
4763         fail <<END
4764 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4765  tool which does not create patches for changes to upstream
4766  .gitignores: but, such patches exist in debian/patches.
4767 END
4768     }
4769     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4770         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4771         quiltify_splitbrain_needed();
4772         progress "dgit view: creating patch to represent .gitignore changes";
4773         ensuredir "debian/patches";
4774         my $gipatch = "debian/patches/auto-gitignore";
4775         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4776         stat GIPATCH or die "$gipatch: $!";
4777         fail "$gipatch already exists; but want to create it".
4778             " to record .gitignore changes" if (stat _)[7];
4779         print GIPATCH <<END or die "$gipatch: $!";
4780 Subject: Update .gitignore from Debian packaging branch
4781
4782 The Debian packaging git branch contains these updates to the upstream
4783 .gitignore file(s).  This patch is autogenerated, to provide these
4784 updates to users of the official Debian archive view of the package.
4785
4786 [dgit ($our_version) update-gitignore]
4787 ---
4788 END
4789         close GIPATCH or die "$gipatch: $!";
4790         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4791             $unapplied, $headref, "--", sort keys %$editedignores;
4792         open SERIES, "+>>", "debian/patches/series" or die $!;
4793         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4794         my $newline;
4795         defined read SERIES, $newline, 1 or die $!;
4796         print SERIES "\n" or die $! unless $newline eq "\n";
4797         print SERIES "auto-gitignore\n" or die $!;
4798         close SERIES or die  $!;
4799         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4800         commit_admin <<END
4801 Commit patch to update .gitignore
4802
4803 [dgit ($our_version) update-gitignore-quilt-fixup]
4804 END
4805     }
4806
4807     my $dgitview = git_rev_parse 'HEAD';
4808
4809     changedir '../../../..';
4810     # When we no longer need to support squeeze, use --create-reflog
4811     # instead of this:
4812     ensuredir ".git/logs/refs/dgit-intern";
4813     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4814       or die $!;
4815
4816     my $oldcache = git_get_ref "refs/$splitbraincache";
4817     if ($oldcache eq $dgitview) {
4818         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4819         # git update-ref doesn't always update, in this case.  *sigh*
4820         my $dummy = make_commit_text <<END;
4821 tree $tree
4822 parent $dgitview
4823 author Dgit <dgit\@example.com> 1000000000 +0000
4824 committer Dgit <dgit\@example.com> 1000000000 +0000
4825
4826 Dummy commit - do not use
4827 END
4828         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4829             "refs/$splitbraincache", $dummy;
4830     }
4831     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4832         $dgitview;
4833
4834     changedir '.git/dgit/unpack/work';
4835
4836     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4837     progress "dgit view: created ($saved)";
4838 }
4839
4840 sub quiltify ($$$$) {
4841     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4842
4843     # Quilt patchification algorithm
4844     #
4845     # We search backwards through the history of the main tree's HEAD
4846     # (T) looking for a start commit S whose tree object is identical
4847     # to to the patch tip tree (ie the tree corresponding to the
4848     # current dpkg-committed patch series).  For these purposes
4849     # `identical' disregards anything in debian/ - this wrinkle is
4850     # necessary because dpkg-source treates debian/ specially.
4851     #
4852     # We can only traverse edges where at most one of the ancestors'
4853     # trees differs (in changes outside in debian/).  And we cannot
4854     # handle edges which change .pc/ or debian/patches.  To avoid
4855     # going down a rathole we avoid traversing edges which introduce
4856     # debian/rules or debian/control.  And we set a limit on the
4857     # number of edges we are willing to look at.
4858     #
4859     # If we succeed, we walk forwards again.  For each traversed edge
4860     # PC (with P parent, C child) (starting with P=S and ending with
4861     # C=T) to we do this:
4862     #  - git checkout C
4863     #  - dpkg-source --commit with a patch name and message derived from C
4864     # After traversing PT, we git commit the changes which
4865     # should be contained within debian/patches.
4866
4867     # The search for the path S..T is breadth-first.  We maintain a
4868     # todo list containing search nodes.  A search node identifies a
4869     # commit, and looks something like this:
4870     #  $p = {
4871     #      Commit => $git_commit_id,
4872     #      Child => $c,                          # or undef if P=T
4873     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4874     #      Nontrivial => true iff $p..$c has relevant changes
4875     #  };
4876
4877     my @todo;
4878     my @nots;
4879     my $sref_S;
4880     my $max_work=100;
4881     my %considered; # saves being exponential on some weird graphs
4882
4883     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4884
4885     my $not = sub {
4886         my ($search,$whynot) = @_;
4887         printdebug " search NOT $search->{Commit} $whynot\n";
4888         $search->{Whynot} = $whynot;
4889         push @nots, $search;
4890         no warnings qw(exiting);
4891         next;
4892     };
4893
4894     push @todo, {
4895         Commit => $target,
4896     };
4897
4898     while (@todo) {
4899         my $c = shift @todo;
4900         next if $considered{$c->{Commit}}++;
4901
4902         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
4903
4904         printdebug "quiltify investigate $c->{Commit}\n";
4905
4906         # are we done?
4907         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
4908             printdebug " search finished hooray!\n";
4909             $sref_S = $c;
4910             last;
4911         }
4912
4913         if ($quilt_mode eq 'nofix') {
4914             fail "quilt fixup required but quilt mode is \`nofix'\n".
4915                 "HEAD commit $c->{Commit} differs from tree implied by ".
4916                 " debian/patches (tree object $oldtiptree)";
4917         }
4918         if ($quilt_mode eq 'smash') {
4919             printdebug " search quitting smash\n";
4920             last;
4921         }
4922
4923         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
4924         $not->($c, "has $c_sentinels not $t_sentinels")
4925             if $c_sentinels ne $t_sentinels;
4926
4927         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
4928         $commitdata =~ m/\n\n/;
4929         $commitdata =~ $`;
4930         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
4931         @parents = map { { Commit => $_, Child => $c } } @parents;
4932
4933         $not->($c, "root commit") if !@parents;
4934
4935         foreach my $p (@parents) {
4936             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
4937         }
4938         my $ndiffers = grep { $_->{Nontrivial} } @parents;
4939         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
4940
4941         foreach my $p (@parents) {
4942             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
4943
4944             my @cmd= (@git, qw(diff-tree -r --name-only),
4945                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
4946             my $patchstackchange = cmdoutput @cmd;
4947             if (length $patchstackchange) {
4948                 $patchstackchange =~ s/\n/,/g;
4949                 $not->($p, "changed $patchstackchange");
4950             }
4951
4952             printdebug " search queue P=$p->{Commit} ",
4953                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
4954             push @todo, $p;
4955         }
4956     }
4957
4958     if (!$sref_S) {
4959         printdebug "quiltify want to smash\n";
4960
4961         my $abbrev = sub {
4962             my $x = $_[0]{Commit};
4963             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
4964             return $x;
4965         };
4966         my $reportnot = sub {
4967             my ($notp) = @_;
4968             my $s = $abbrev->($notp);
4969             my $c = $notp->{Child};
4970             $s .= "..".$abbrev->($c) if $c;
4971             $s .= ": ".$notp->{Whynot};
4972             return $s;
4973         };
4974         if ($quilt_mode eq 'linear') {
4975             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
4976             foreach my $notp (@nots) {
4977                 print STDERR "$us:  ", $reportnot->($notp), "\n";
4978             }
4979             print STDERR "$us: $_\n" foreach @$failsuggestion;
4980             fail "quilt fixup naive history linearisation failed.\n".
4981  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
4982         } elsif ($quilt_mode eq 'smash') {
4983         } elsif ($quilt_mode eq 'auto') {
4984             progress "quilt fixup cannot be linear, smashing...";
4985         } else {
4986             die "$quilt_mode ?";
4987         }
4988
4989         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
4990         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
4991         my $ncommits = 3;
4992         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
4993
4994         quiltify_dpkg_commit "auto-$version-$target-$time",
4995             (getfield $clogp, 'Maintainer'),
4996             "Automatically generated patch ($clogp->{Version})\n".
4997             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
4998         return;
4999     }
5000
5001     progress "quiltify linearisation planning successful, executing...";
5002
5003     for (my $p = $sref_S;
5004          my $c = $p->{Child};
5005          $p = $p->{Child}) {
5006         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5007         next unless $p->{Nontrivial};
5008
5009         my $cc = $c->{Commit};
5010
5011         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5012         $commitdata =~ m/\n\n/ or die "$c ?";
5013         $commitdata = $`;
5014         my $msg = $'; #';
5015         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5016         my $author = $1;
5017
5018         my $commitdate = cmdoutput
5019             @git, qw(log -n1 --pretty=format:%aD), $cc;
5020
5021         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5022
5023         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5024         $strip_nls->();
5025
5026         my $title = $1;
5027         my $patchname;
5028         my $patchdir;
5029
5030         my $gbp_check_suitable = sub {
5031             $_ = shift;
5032             my ($what) = @_;
5033
5034             eval {
5035                 die "contains unexpected slashes\n" if m{//} || m{/$};
5036                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5037                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5038                 die "too long" if length > 200;
5039             };
5040             return $_ unless $@;
5041             print STDERR "quiltifying commit $cc:".
5042                 " ignoring/dropping Gbp-Pq $what: $@";
5043             return undef;
5044         };
5045
5046         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5047                            gbp-pq-name: \s* )
5048                        (\S+) \s* \n //ixm) {
5049             $patchname = $gbp_check_suitable->($1, 'Name');
5050         }
5051         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5052                            gbp-pq-topic: \s* )
5053                        (\S+) \s* \n //ixm) {
5054             $patchdir = $gbp_check_suitable->($1, 'Topic');
5055         }
5056
5057         $strip_nls->();
5058
5059         if (!defined $patchname) {
5060             $patchname = $title;
5061             $patchname =~ s/[.:]$//;
5062             use Text::Iconv;
5063             eval {
5064                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5065                 my $translitname = $converter->convert($patchname);
5066                 die unless defined $translitname;
5067                 $patchname = $translitname;
5068             };
5069             print STDERR
5070                 "dgit: patch title transliteration error: $@"
5071                 if $@;
5072             $patchname =~ y/ A-Z/-a-z/;
5073             $patchname =~ y/-a-z0-9_.+=~//cd;
5074             $patchname =~ s/^\W/x-$&/;
5075             $patchname = substr($patchname,0,40);
5076         }
5077         if (!defined $patchdir) {
5078             $patchdir = '';
5079         }
5080         if (length $patchdir) {
5081             $patchname = "$patchdir/$patchname";
5082         }
5083         if ($patchname =~ m{^(.*)/}) {
5084             mkpath "debian/patches/$1";
5085         }
5086
5087         my $index;
5088         for ($index='';
5089              stat "debian/patches/$patchname$index";
5090              $index++) { }
5091         $!==ENOENT or die "$patchname$index $!";
5092
5093         runcmd @git, qw(checkout -q), $cc;
5094
5095         # We use the tip's changelog so that dpkg-source doesn't
5096         # produce complaining messages from dpkg-parsechangelog.  None
5097         # of the information dpkg-source gets from the changelog is
5098         # actually relevant - it gets put into the original message
5099         # which dpkg-source provides our stunt editor, and then
5100         # overwritten.
5101         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5102
5103         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5104             "Date: $commitdate\n".
5105             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5106
5107         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5108     }
5109
5110     runcmd @git, qw(checkout -q master);
5111 }
5112
5113 sub build_maybe_quilt_fixup () {
5114     my ($format,$fopts) = get_source_format;
5115     return unless madformat_wantfixup $format;
5116     # sigh
5117
5118     check_for_vendor_patches();
5119
5120     if (quiltmode_splitbrain) {
5121         fail <<END unless access_cfg_tagformats_can_splitbrain;
5122 quilt mode $quilt_mode requires split view so server needs to support
5123  both "new" and "maint" tag formats, but config says it doesn't.
5124 END
5125     }
5126
5127     my $clogp = parsechangelog();
5128     my $headref = git_rev_parse('HEAD');
5129
5130     prep_ud();
5131     changedir $ud;
5132
5133     my $upstreamversion = upstreamversion $version;
5134
5135     if ($fopts->{'single-debian-patch'}) {
5136         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5137     } else {
5138         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5139     }
5140
5141     die 'bug' if $split_brain && !$need_split_build_invocation;
5142
5143     changedir '../../../..';
5144     runcmd_ordryrun_local
5145         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5146 }
5147
5148 sub quilt_fixup_mkwork ($) {
5149     my ($headref) = @_;
5150
5151     mkdir "work" or die $!;
5152     changedir "work";
5153     mktree_in_ud_here();
5154     runcmd @git, qw(reset -q --hard), $headref;
5155 }
5156
5157 sub quilt_fixup_linkorigs ($$) {
5158     my ($upstreamversion, $fn) = @_;
5159     # calls $fn->($leafname);
5160
5161     foreach my $f (<../../../../*>) { #/){
5162         my $b=$f; $b =~ s{.*/}{};
5163         {
5164             local ($debuglevel) = $debuglevel-1;
5165             printdebug "QF linkorigs $b, $f ?\n";
5166         }
5167         next unless is_orig_file_of_vsn $b, $upstreamversion;
5168         printdebug "QF linkorigs $b, $f Y\n";
5169         link_ltarget $f, $b or die "$b $!";
5170         $fn->($b);
5171     }
5172 }
5173
5174 sub quilt_fixup_delete_pc () {
5175     runcmd @git, qw(rm -rqf .pc);
5176     commit_admin <<END
5177 Commit removal of .pc (quilt series tracking data)
5178
5179 [dgit ($our_version) upgrade quilt-remove-pc]
5180 END
5181 }
5182
5183 sub quilt_fixup_singlepatch ($$$) {
5184     my ($clogp, $headref, $upstreamversion) = @_;
5185
5186     progress "starting quiltify (single-debian-patch)";
5187
5188     # dpkg-source --commit generates new patches even if
5189     # single-debian-patch is in debian/source/options.  In order to
5190     # get it to generate debian/patches/debian-changes, it is
5191     # necessary to build the source package.
5192
5193     quilt_fixup_linkorigs($upstreamversion, sub { });
5194     quilt_fixup_mkwork($headref);
5195
5196     rmtree("debian/patches");
5197
5198     runcmd @dpkgsource, qw(-b .);
5199     changedir "..";
5200     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5201     rename srcfn("$upstreamversion", "/debian/patches"),
5202            "work/debian/patches";
5203
5204     changedir "work";
5205     commit_quilty_patch();
5206 }
5207
5208 sub quilt_make_fake_dsc ($) {
5209     my ($upstreamversion) = @_;
5210
5211     my $fakeversion="$upstreamversion-~~DGITFAKE";
5212
5213     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5214     print $fakedsc <<END or die $!;
5215 Format: 3.0 (quilt)
5216 Source: $package
5217 Version: $fakeversion
5218 Files:
5219 END
5220
5221     my $dscaddfile=sub {
5222         my ($b) = @_;
5223
5224         my $md = new Digest::MD5;
5225
5226         my $fh = new IO::File $b, '<' or die "$b $!";
5227         stat $fh or die $!;
5228         my $size = -s _;
5229
5230         $md->addfile($fh);
5231         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5232     };
5233
5234     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5235
5236     my @files=qw(debian/source/format debian/rules
5237                  debian/control debian/changelog);
5238     foreach my $maybe (qw(debian/patches debian/source/options
5239                           debian/tests/control)) {
5240         next unless stat_exists "../../../$maybe";
5241         push @files, $maybe;
5242     }
5243
5244     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5245     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5246
5247     $dscaddfile->($debtar);
5248     close $fakedsc or die $!;
5249 }
5250
5251 sub quilt_check_splitbrain_cache ($$) {
5252     my ($headref, $upstreamversion) = @_;
5253     # Called only if we are in (potentially) split brain mode.
5254     # Called in $ud.
5255     # Computes the cache key and looks in the cache.
5256     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5257
5258     my $splitbrain_cachekey;
5259
5260     progress
5261  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5262     # we look in the reflog of dgit-intern/quilt-cache
5263     # we look for an entry whose message is the key for the cache lookup
5264     my @cachekey = (qw(dgit), $our_version);
5265     push @cachekey, $upstreamversion;
5266     push @cachekey, $quilt_mode;
5267     push @cachekey, $headref;
5268
5269     push @cachekey, hashfile('fake.dsc');
5270
5271     my $srcshash = Digest::SHA->new(256);
5272     my %sfs = ( %INC, '$0(dgit)' => $0 );
5273     foreach my $sfk (sort keys %sfs) {
5274         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5275         $srcshash->add($sfk,"  ");
5276         $srcshash->add(hashfile($sfs{$sfk}));
5277         $srcshash->add("\n");
5278     }
5279     push @cachekey, $srcshash->hexdigest();
5280     $splitbrain_cachekey = "@cachekey";
5281
5282     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5283                $splitbraincache);
5284     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5285     debugcmd "|(probably)",@cmd;
5286     my $child = open GC, "-|";  defined $child or die $!;
5287     if (!$child) {
5288         chdir '../../..' or die $!;
5289         if (!stat ".git/logs/refs/$splitbraincache") {
5290             $! == ENOENT or die $!;
5291             printdebug ">(no reflog)\n";
5292             exit 0;
5293         }
5294         exec @cmd; die $!;
5295     }
5296     while (<GC>) {
5297         chomp;
5298         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5299         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5300
5301         my $cachehit = $1;
5302         quilt_fixup_mkwork($headref);
5303         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5304         if ($cachehit ne $headref) {
5305             progress "dgit view: found cached ($saved)";
5306             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5307             $split_brain = 1;
5308             return ($cachehit, $splitbrain_cachekey);
5309         }
5310         progress "dgit view: found cached, no changes required";
5311         return ($headref, $splitbrain_cachekey);
5312     }
5313     die $! if GC->error;
5314     failedcmd unless close GC;
5315
5316     printdebug "splitbrain cache miss\n";
5317     return (undef, $splitbrain_cachekey);
5318 }
5319
5320 sub quilt_fixup_multipatch ($$$) {
5321     my ($clogp, $headref, $upstreamversion) = @_;
5322
5323     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5324
5325     # Our objective is:
5326     #  - honour any existing .pc in case it has any strangeness
5327     #  - determine the git commit corresponding to the tip of
5328     #    the patch stack (if there is one)
5329     #  - if there is such a git commit, convert each subsequent
5330     #    git commit into a quilt patch with dpkg-source --commit
5331     #  - otherwise convert all the differences in the tree into
5332     #    a single git commit
5333     #
5334     # To do this we:
5335
5336     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5337     # dgit would include the .pc in the git tree.)  If there isn't
5338     # one, we need to generate one by unpacking the patches that we
5339     # have.
5340     #
5341     # We first look for a .pc in the git tree.  If there is one, we
5342     # will use it.  (This is not the normal case.)
5343     #
5344     # Otherwise need to regenerate .pc so that dpkg-source --commit
5345     # can work.  We do this as follows:
5346     #     1. Collect all relevant .orig from parent directory
5347     #     2. Generate a debian.tar.gz out of
5348     #         debian/{patches,rules,source/format,source/options}
5349     #     3. Generate a fake .dsc containing just these fields:
5350     #          Format Source Version Files
5351     #     4. Extract the fake .dsc
5352     #        Now the fake .dsc has a .pc directory.
5353     # (In fact we do this in every case, because in future we will
5354     # want to search for a good base commit for generating patches.)
5355     #
5356     # Then we can actually do the dpkg-source --commit
5357     #     1. Make a new working tree with the same object
5358     #        store as our main tree and check out the main
5359     #        tree's HEAD.
5360     #     2. Copy .pc from the fake's extraction, if necessary
5361     #     3. Run dpkg-source --commit
5362     #     4. If the result has changes to debian/, then
5363     #          - git add them them
5364     #          - git add .pc if we had a .pc in-tree
5365     #          - git commit
5366     #     5. If we had a .pc in-tree, delete it, and git commit
5367     #     6. Back in the main tree, fast forward to the new HEAD
5368
5369     # Another situation we may have to cope with is gbp-style
5370     # patches-unapplied trees.
5371     #
5372     # We would want to detect these, so we know to escape into
5373     # quilt_fixup_gbp.  However, this is in general not possible.
5374     # Consider a package with a one patch which the dgit user reverts
5375     # (with git revert or the moral equivalent).
5376     #
5377     # That is indistinguishable in contents from a patches-unapplied
5378     # tree.  And looking at the history to distinguish them is not
5379     # useful because the user might have made a confusing-looking git
5380     # history structure (which ought to produce an error if dgit can't
5381     # cope, not a silent reintroduction of an unwanted patch).
5382     #
5383     # So gbp users will have to pass an option.  But we can usually
5384     # detect their failure to do so: if the tree is not a clean
5385     # patches-applied tree, quilt linearisation fails, but the tree
5386     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5387     # they want --quilt=unapplied.
5388     #
5389     # To help detect this, when we are extracting the fake dsc, we
5390     # first extract it with --skip-patches, and then apply the patches
5391     # afterwards with dpkg-source --before-build.  That lets us save a
5392     # tree object corresponding to .origs.
5393
5394     my $splitbrain_cachekey;
5395
5396     quilt_make_fake_dsc($upstreamversion);
5397
5398     if (quiltmode_splitbrain()) {
5399         my $cachehit;
5400         ($cachehit, $splitbrain_cachekey) =
5401             quilt_check_splitbrain_cache($headref, $upstreamversion);
5402         return if $cachehit;
5403     }
5404
5405     runcmd qw(sh -ec),
5406         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5407
5408     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5409     rename $fakexdir, "fake" or die "$fakexdir $!";
5410
5411     changedir 'fake';
5412
5413     remove_stray_gits("source package");
5414     mktree_in_ud_here();
5415
5416     rmtree '.pc';
5417
5418     my $unapplied=git_add_write_tree();
5419     printdebug "fake orig tree object $unapplied\n";
5420
5421     ensuredir '.pc';
5422
5423     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5424     $!=0; $?=-1;
5425     if (system @bbcmd) {
5426         failedcmd @bbcmd if $? < 0;
5427         fail <<END;
5428 failed to apply your git tree's patch stack (from debian/patches/) to
5429  the corresponding upstream tarball(s).  Your source tree and .orig
5430  are probably too inconsistent.  dgit can only fix up certain kinds of
5431  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5432 END
5433     }
5434
5435     changedir '..';
5436
5437     quilt_fixup_mkwork($headref);
5438
5439     my $mustdeletepc=0;
5440     if (stat_exists ".pc") {
5441         -d _ or die;
5442         progress "Tree already contains .pc - will use it then delete it.";
5443         $mustdeletepc=1;
5444     } else {
5445         rename '../fake/.pc','.pc' or die $!;
5446     }
5447
5448     changedir '../fake';
5449     rmtree '.pc';
5450     my $oldtiptree=git_add_write_tree();
5451     printdebug "fake o+d/p tree object $unapplied\n";
5452     changedir '../work';
5453
5454
5455     # We calculate some guesswork now about what kind of tree this might
5456     # be.  This is mostly for error reporting.
5457
5458     my %editedignores;
5459     my @unrepres;
5460     my $diffbits = {
5461         # H = user's HEAD
5462         # O = orig, without patches applied
5463         # A = "applied", ie orig with H's debian/patches applied
5464         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5465                                      \%editedignores, \@unrepres),
5466         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5467         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5468     };
5469
5470     my @dl;
5471     foreach my $b (qw(01 02)) {
5472         foreach my $v (qw(O2H O2A H2A)) {
5473             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5474         }
5475     }
5476     printdebug "differences \@dl @dl.\n";
5477
5478     progress sprintf
5479 "$us: base trees orig=%.20s o+d/p=%.20s",
5480               $unapplied, $oldtiptree;
5481     progress sprintf
5482 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5483 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5484                              $dl[0], $dl[1],              $dl[3], $dl[4],
5485                                  $dl[2],                     $dl[5];
5486
5487     if (@unrepres) {
5488         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5489             foreach @unrepres;
5490         forceable_fail [qw(unrepresentable)], <<END;
5491 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5492 END
5493     }
5494
5495     my @failsuggestion;
5496     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5497         push @failsuggestion, "This might be a patches-unapplied branch.";
5498     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5499         push @failsuggestion, "This might be a patches-applied branch.";
5500     }
5501     push @failsuggestion, "Maybe you need to specify one of".
5502         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5503
5504     if (quiltmode_splitbrain()) {
5505         quiltify_splitbrain($clogp, $unapplied, $headref,
5506                             $diffbits, \%editedignores,
5507                             $splitbrain_cachekey);
5508         return;
5509     }
5510
5511     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5512     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5513
5514     if (!open P, '>>', ".pc/applied-patches") {
5515         $!==&ENOENT or die $!;
5516     } else {
5517         close P;
5518     }
5519
5520     commit_quilty_patch();
5521
5522     if ($mustdeletepc) {
5523         quilt_fixup_delete_pc();
5524     }
5525 }
5526
5527 sub quilt_fixup_editor () {
5528     my $descfn = $ENV{$fakeeditorenv};
5529     my $editing = $ARGV[$#ARGV];
5530     open I1, '<', $descfn or die "$descfn: $!";
5531     open I2, '<', $editing or die "$editing: $!";
5532     unlink $editing or die "$editing: $!";
5533     open O, '>', $editing or die "$editing: $!";
5534     while (<I1>) { print O or die $!; } I1->error and die $!;
5535     my $copying = 0;
5536     while (<I2>) {
5537         $copying ||= m/^\-\-\- /;
5538         next unless $copying;
5539         print O or die $!;
5540     }
5541     I2->error and die $!;
5542     close O or die $1;
5543     exit 0;
5544 }
5545
5546 sub maybe_apply_patches_dirtily () {
5547     return unless $quilt_mode =~ m/gbp|unapplied/;
5548     print STDERR <<END or die $!;
5549
5550 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5551 dgit: Have to apply the patches - making the tree dirty.
5552 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5553
5554 END
5555     $patches_applied_dirtily = 01;
5556     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5557     runcmd qw(dpkg-source --before-build .);
5558 }
5559
5560 sub maybe_unapply_patches_again () {
5561     progress "dgit: Unapplying patches again to tidy up the tree."
5562         if $patches_applied_dirtily;
5563     runcmd qw(dpkg-source --after-build .)
5564         if $patches_applied_dirtily & 01;
5565     rmtree '.pc'
5566         if $patches_applied_dirtily & 02;
5567     $patches_applied_dirtily = 0;
5568 }
5569
5570 #----- other building -----
5571
5572 our $clean_using_builder;
5573 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5574 #   clean the tree before building (perhaps invoked indirectly by
5575 #   whatever we are using to run the build), rather than separately
5576 #   and explicitly by us.
5577
5578 sub clean_tree () {
5579     return if $clean_using_builder;
5580     if ($cleanmode eq 'dpkg-source') {
5581         maybe_apply_patches_dirtily();
5582         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5583     } elsif ($cleanmode eq 'dpkg-source-d') {
5584         maybe_apply_patches_dirtily();
5585         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5586     } elsif ($cleanmode eq 'git') {
5587         runcmd_ordryrun_local @git, qw(clean -xdf);
5588     } elsif ($cleanmode eq 'git-ff') {
5589         runcmd_ordryrun_local @git, qw(clean -xdff);
5590     } elsif ($cleanmode eq 'check') {
5591         my $leftovers = cmdoutput @git, qw(clean -xdn);
5592         if (length $leftovers) {
5593             print STDERR $leftovers, "\n" or die $!;
5594             fail "tree contains uncommitted files and --clean=check specified";
5595         }
5596     } elsif ($cleanmode eq 'none') {
5597     } else {
5598         die "$cleanmode ?";
5599     }
5600 }
5601
5602 sub cmd_clean () {
5603     badusage "clean takes no additional arguments" if @ARGV;
5604     notpushing();
5605     clean_tree();
5606     maybe_unapply_patches_again();
5607 }
5608
5609 sub build_prep_early () {
5610     our $build_prep_early_done //= 0;
5611     return if $build_prep_early_done++;
5612     notpushing();
5613     badusage "-p is not allowed when building" if defined $package;
5614     my $clogp = parsechangelog();
5615     $isuite = getfield $clogp, 'Distribution';
5616     $package = getfield $clogp, 'Source';
5617     $version = getfield $clogp, 'Version';
5618     check_not_dirty();
5619 }
5620
5621 sub build_prep () {
5622     build_prep_early();
5623     clean_tree();
5624     build_maybe_quilt_fixup();
5625     if ($rmchanges) {
5626         my $pat = changespat $version;
5627         foreach my $f (glob "$buildproductsdir/$pat") {
5628             if (act_local()) {
5629                 unlink $f or fail "remove old changes file $f: $!";
5630             } else {
5631                 progress "would remove $f";
5632             }
5633         }
5634     }
5635 }
5636
5637 sub changesopts_initial () {
5638     my @opts =@changesopts[1..$#changesopts];
5639 }
5640
5641 sub changesopts_version () {
5642     if (!defined $changes_since_version) {
5643         my @vsns = archive_query('archive_query');
5644         my @quirk = access_quirk();
5645         if ($quirk[0] eq 'backports') {
5646             local $isuite = $quirk[2];
5647             local $csuite;
5648             canonicalise_suite();
5649             push @vsns, archive_query('archive_query');
5650         }
5651         if (@vsns) {
5652             @vsns = map { $_->[0] } @vsns;
5653             @vsns = sort { -version_compare($a, $b) } @vsns;
5654             $changes_since_version = $vsns[0];
5655             progress "changelog will contain changes since $vsns[0]";
5656         } else {
5657             $changes_since_version = '_';
5658             progress "package seems new, not specifying -v<version>";
5659         }
5660     }
5661     if ($changes_since_version ne '_') {
5662         return ("-v$changes_since_version");
5663     } else {
5664         return ();
5665     }
5666 }
5667
5668 sub changesopts () {
5669     return (changesopts_initial(), changesopts_version());
5670 }
5671
5672 sub massage_dbp_args ($;$) {
5673     my ($cmd,$xargs) = @_;
5674     # We need to:
5675     #
5676     #  - if we're going to split the source build out so we can
5677     #    do strange things to it, massage the arguments to dpkg-buildpackage
5678     #    so that the main build doessn't build source (or add an argument
5679     #    to stop it building source by default).
5680     #
5681     #  - add -nc to stop dpkg-source cleaning the source tree,
5682     #    unless we're not doing a split build and want dpkg-source
5683     #    as cleanmode, in which case we can do nothing
5684     #
5685     # return values:
5686     #    0 - source will NOT need to be built separately by caller
5687     #   +1 - source will need to be built separately by caller
5688     #   +2 - source will need to be built separately by caller AND
5689     #        dpkg-buildpackage should not in fact be run at all!
5690     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5691 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5692     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5693         $clean_using_builder = 1;
5694         return 0;
5695     }
5696     # -nc has the side effect of specifying -b if nothing else specified
5697     # and some combinations of -S, -b, et al, are errors, rather than
5698     # later simply overriding earlie.  So we need to:
5699     #  - search the command line for these options
5700     #  - pick the last one
5701     #  - perhaps add our own as a default
5702     #  - perhaps adjust it to the corresponding non-source-building version
5703     my $dmode = '-F';
5704     foreach my $l ($cmd, $xargs) {
5705         next unless $l;
5706         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5707     }
5708     push @$cmd, '-nc';
5709 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5710     my $r = 0;
5711     if ($need_split_build_invocation) {
5712         printdebug "massage split $dmode.\n";
5713         $r = $dmode =~ m/[S]/     ? +2 :
5714              $dmode =~ y/gGF/ABb/ ? +1 :
5715              $dmode =~ m/[ABb]/   ?  0 :
5716              die "$dmode ?";
5717     }
5718     printdebug "massage done $r $dmode.\n";
5719     push @$cmd, $dmode;
5720 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5721     return $r;
5722 }
5723
5724 sub in_parent (&) {
5725     my ($fn) = @_;
5726     my $wasdir = must_getcwd();
5727     changedir "..";
5728     $fn->();
5729     changedir $wasdir;
5730 }
5731
5732 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5733     my ($msg_if_onlyone) = @_;
5734     # If there is only one .changes file, fail with $msg_if_onlyone,
5735     # or if that is undef, be a no-op.
5736     # Returns the changes file to report to the user.
5737     my $pat = changespat $version;
5738     my @changesfiles = glob $pat;
5739     @changesfiles = sort {
5740         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5741             or $a cmp $b
5742     } @changesfiles;
5743     my $result;
5744     if (@changesfiles==1) {
5745         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5746 only one changes file from build (@changesfiles)
5747 END
5748         $result = $changesfiles[0];
5749     } elsif (@changesfiles==2) {
5750         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5751         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5752             fail "$l found in binaries changes file $binchanges"
5753                 if $l =~ m/\.dsc$/;
5754         }
5755         runcmd_ordryrun_local @mergechanges, @changesfiles;
5756         my $multichanges = changespat $version,'multi';
5757         if (act_local()) {
5758             stat_exists $multichanges or fail "$multichanges: $!";
5759             foreach my $cf (glob $pat) {
5760                 next if $cf eq $multichanges;
5761                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5762             }
5763         }
5764         $result = $multichanges;
5765     } else {
5766         fail "wrong number of different changes files (@changesfiles)";
5767     }
5768     printdone "build successful, results in $result\n" or die $!;
5769 }
5770
5771 sub midbuild_checkchanges () {
5772     my $pat = changespat $version;
5773     return if $rmchanges;
5774     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5775     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5776     fail <<END
5777 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5778 Suggest you delete @unwanted.
5779 END
5780         if @unwanted;
5781 }
5782
5783 sub midbuild_checkchanges_vanilla ($) {
5784     my ($wantsrc) = @_;
5785     midbuild_checkchanges() if $wantsrc == 1;
5786 }
5787
5788 sub postbuild_mergechanges_vanilla ($) {
5789     my ($wantsrc) = @_;
5790     if ($wantsrc == 1) {
5791         in_parent {
5792             postbuild_mergechanges(undef);
5793         };
5794     } else {
5795         printdone "build successful\n";
5796     }
5797 }
5798
5799 sub cmd_build {
5800     build_prep_early();
5801     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5802     my $wantsrc = massage_dbp_args \@dbp;
5803     if ($wantsrc > 0) {
5804         build_source();
5805         midbuild_checkchanges_vanilla $wantsrc;
5806     } else {
5807         build_prep();
5808     }
5809     if ($wantsrc < 2) {
5810         push @dbp, changesopts_version();
5811         maybe_apply_patches_dirtily();
5812         runcmd_ordryrun_local @dbp;
5813     }
5814     maybe_unapply_patches_again();
5815     postbuild_mergechanges_vanilla $wantsrc;
5816 }
5817
5818 sub pre_gbp_build {
5819     $quilt_mode //= 'gbp';
5820 }
5821
5822 sub cmd_gbp_build {
5823     build_prep_early();
5824
5825     # gbp can make .origs out of thin air.  In my tests it does this
5826     # even for a 1.0 format package, with no origs present.  So I
5827     # guess it keys off just the version number.  We don't know
5828     # exactly what .origs ought to exist, but let's assume that we
5829     # should run gbp if: the version has an upstream part and the main
5830     # orig is absent.
5831     my $upstreamversion = upstreamversion $version;
5832     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5833     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5834
5835     if ($gbp_make_orig) {
5836         clean_tree();
5837         $cleanmode = 'none'; # don't do it again
5838         $need_split_build_invocation = 1;
5839     }
5840
5841     my @dbp = @dpkgbuildpackage;
5842
5843     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5844
5845     if (!length $gbp_build[0]) {
5846         if (length executable_on_path('git-buildpackage')) {
5847             $gbp_build[0] = qw(git-buildpackage);
5848         } else {
5849             $gbp_build[0] = 'gbp buildpackage';
5850         }
5851     }
5852     my @cmd = opts_opt_multi_cmd @gbp_build;
5853
5854     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5855
5856     if ($gbp_make_orig) {
5857         ensuredir '.git/dgit';
5858         my $ok = '.git/dgit/origs-gen-ok';
5859         unlink $ok or $!==&ENOENT or die $!;
5860         my @origs_cmd = @cmd;
5861         push @origs_cmd, qw(--git-cleaner=true);
5862         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5863         push @origs_cmd, @ARGV;
5864         if (act_local()) {
5865             debugcmd @origs_cmd;
5866             system @origs_cmd;
5867             do { local $!; stat_exists $ok; }
5868                 or failedcmd @origs_cmd;
5869         } else {
5870             dryrun_report @origs_cmd;
5871         }
5872     }
5873
5874     if ($wantsrc > 0) {
5875         build_source();
5876         midbuild_checkchanges_vanilla $wantsrc;
5877     } else {
5878         if (!$clean_using_builder) {
5879             push @cmd, '--git-cleaner=true';
5880         }
5881         build_prep();
5882     }
5883     maybe_unapply_patches_again();
5884     if ($wantsrc < 2) {
5885         push @cmd, changesopts();
5886         runcmd_ordryrun_local @cmd, @ARGV;
5887     }
5888     postbuild_mergechanges_vanilla $wantsrc;
5889 }
5890 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
5891
5892 sub build_source {
5893     build_prep_early();
5894     my $our_cleanmode = $cleanmode;
5895     if ($need_split_build_invocation) {
5896         # Pretend that clean is being done some other way.  This
5897         # forces us not to try to use dpkg-buildpackage to clean and
5898         # build source all in one go; and instead we run dpkg-source
5899         # (and build_prep() will do the clean since $clean_using_builder
5900         # is false).
5901         $our_cleanmode = 'ELSEWHERE';
5902     }
5903     if ($our_cleanmode =~ m/^dpkg-source/) {
5904         # dpkg-source invocation (below) will clean, so build_prep shouldn't
5905         $clean_using_builder = 1;
5906     }
5907     build_prep();
5908     $sourcechanges = changespat $version,'source';
5909     if (act_local()) {
5910         unlink "../$sourcechanges" or $!==ENOENT
5911             or fail "remove $sourcechanges: $!";
5912     }
5913     $dscfn = dscfn($version);
5914     if ($our_cleanmode eq 'dpkg-source') {
5915         maybe_apply_patches_dirtily();
5916         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
5917             changesopts();
5918     } elsif ($our_cleanmode eq 'dpkg-source-d') {
5919         maybe_apply_patches_dirtily();
5920         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
5921             changesopts();
5922     } else {
5923         my @cmd = (@dpkgsource, qw(-b --));
5924         if ($split_brain) {
5925             changedir $ud;
5926             runcmd_ordryrun_local @cmd, "work";
5927             my @udfiles = <${package}_*>;
5928             changedir "../../..";
5929             foreach my $f (@udfiles) {
5930                 printdebug "source copy, found $f\n";
5931                 next unless
5932                     $f eq $dscfn or
5933                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
5934                      $f eq srcfn($version, $&));
5935                 printdebug "source copy, found $f - renaming\n";
5936                 rename "$ud/$f", "../$f" or $!==ENOENT
5937                     or fail "put in place new source file ($f): $!";
5938             }
5939         } else {
5940             my $pwd = must_getcwd();
5941             my $leafdir = basename $pwd;
5942             changedir "..";
5943             runcmd_ordryrun_local @cmd, $leafdir;
5944             changedir $pwd;
5945         }
5946         runcmd_ordryrun_local qw(sh -ec),
5947             'exec >$1; shift; exec "$@"','x',
5948             "../$sourcechanges",
5949             @dpkggenchanges, qw(-S), changesopts();
5950     }
5951 }
5952
5953 sub cmd_build_source {
5954     build_prep_early();
5955     badusage "build-source takes no additional arguments" if @ARGV;
5956     build_source();
5957     maybe_unapply_patches_again();
5958     printdone "source built, results in $dscfn and $sourcechanges";
5959 }
5960
5961 sub cmd_sbuild {
5962     build_source();
5963     midbuild_checkchanges();
5964     in_parent {
5965         if (act_local()) {
5966             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
5967             stat_exists $sourcechanges
5968                 or fail "$sourcechanges (in parent directory): $!";
5969         }
5970         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
5971     };
5972     maybe_unapply_patches_again();
5973     in_parent {
5974         postbuild_mergechanges(<<END);
5975 perhaps you need to pass -A ?  (sbuild's default is to build only
5976 arch-specific binaries; dgit 1.4 used to override that.)
5977 END
5978     };
5979 }
5980
5981 sub cmd_quilt_fixup {
5982     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
5983     build_prep_early();
5984     clean_tree();
5985     build_maybe_quilt_fixup();
5986 }
5987
5988 sub cmd_import_dsc {
5989     my $needsig = 0;
5990
5991     while (@ARGV) {
5992         last unless $ARGV[0] =~ m/^-/;
5993         $_ = shift @ARGV;
5994         last if m/^--?$/;
5995         if (m/^--require-valid-signature$/) {
5996             $needsig = 1;
5997         } else {
5998             badusage "unknown dgit import-dsc sub-option \`$_'";
5999         }
6000     }
6001
6002     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6003     my ($dscfn, $dstbranch) = @ARGV;
6004
6005     badusage "dry run makes no sense with import-dsc" unless act_local();
6006
6007     my $force = $dstbranch =~ s/^\+//   ? +1 :
6008                 $dstbranch =~ s/^\.\.// ? -1 :
6009                                            0;
6010     my $info = $force ? " $&" : '';
6011     $info = "$dscfn$info";
6012
6013     my $specbranch = $dstbranch;
6014     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6015     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6016
6017     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6018     my $chead = cmdoutput_errok @symcmd;
6019     defined $chead or $?==256 or failedcmd @symcmd;
6020
6021     fail "$dstbranch is checked out - will not update it"
6022         if defined $chead and $chead eq $dstbranch;
6023
6024     my $oldhash = git_get_ref $dstbranch;
6025
6026     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6027     $dscdata = do { local $/ = undef; <D>; };
6028     D->error and fail "read $dscfn: $!";
6029     close C;
6030
6031     # we don't normally need this so import it here
6032     use Dpkg::Source::Package;
6033     my $dp = new Dpkg::Source::Package filename => $dscfn,
6034         require_valid_signature => $needsig;
6035     {
6036         local $SIG{__WARN__} = sub {
6037             print STDERR $_[0];
6038             return unless $needsig;
6039             fail "import-dsc signature check failed";
6040         };
6041         if (!$dp->is_signed()) {
6042             warn "$us: warning: importing unsigned .dsc\n";
6043         } else {
6044             my $r = $dp->check_signature();
6045             die "->check_signature => $r" if $needsig && $r;
6046         }
6047     }
6048
6049     parse_dscdata();
6050
6051     $package = getfield $dsc, 'Source';
6052
6053     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6054         unless forceing [qw(import-dsc-with-dgit-field)];
6055
6056     if (defined $dsc_hash) {
6057         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6058         resolve_dsc_field_commit undef, undef;
6059     }
6060     if (defined $dsc_hash) {
6061         my @cmd = (qw(sh -ec),
6062                    "echo $dsc_hash | git cat-file --batch-check");
6063         my $objgot = cmdoutput @cmd;
6064         if ($objgot =~ m#^\w+ missing\b#) {
6065             fail <<END
6066 .dsc contains Dgit field referring to object $dsc_hash
6067 Your git tree does not have that object.  Try `git fetch' from a
6068 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6069 END
6070         }
6071         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6072             if ($force > 0) {
6073                 progress "Not fast forward, forced update.";
6074             } else {
6075                 fail "Not fast forward to $dsc_hash";
6076             }
6077         }
6078         @cmd = (@git, qw(update-ref -m), "dgit import-dsc (Dgit): $info",
6079                 $dstbranch, $dsc_hash);
6080         runcmd @cmd;
6081         progress "dgit: import-dsc updated git ref $dstbranch";
6082         return 0;
6083     }
6084
6085     fail <<END
6086 Branch $dstbranch already exists
6087 Specify ..$specbranch for a pseudo-merge, binding in existing history
6088 Specify  +$specbranch to overwrite, discarding existing history
6089 END
6090         if $oldhash && !$force;
6091
6092     my @dfi = dsc_files_info();
6093     foreach my $fi (@dfi) {
6094         my $f = $fi->{Filename};
6095         my $here = "../$f";
6096         next if lstat $here;
6097         fail "stat $here: $!" unless $! == ENOENT;
6098         my $there = $dscfn;
6099         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6100             $there = $';
6101         } elsif ($dscfn =~ m#^/#) {
6102             $there = $dscfn;
6103         } else {
6104             fail "cannot import $dscfn which seems to be inside working tree!";
6105         }
6106         $there =~ s#/+[^/]+$## or
6107             fail "cannot import $dscfn which seems to not have a basename";
6108         $there .= "/$f";
6109         symlink $there, $here or fail "symlink $there to $here: $!";
6110         progress "made symlink $here -> $there";
6111 #       print STDERR Dumper($fi);
6112     }
6113     my @mergeinputs = generate_commits_from_dsc();
6114     die unless @mergeinputs == 1;
6115
6116     my $newhash = $mergeinputs[0]{Commit};
6117
6118     if ($oldhash) {
6119         if ($force > 0) {
6120             progress "Import, forced update - synthetic orphan git history.";
6121         } elsif ($force < 0) {
6122             progress "Import, merging.";
6123             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6124             my $version = getfield $dsc, 'Version';
6125             my $clogp = commit_getclogp $newhash;
6126             my $authline = clogp_authline $clogp;
6127             $newhash = make_commit_text <<END;
6128 tree $tree
6129 parent $newhash
6130 parent $oldhash
6131 author $authline
6132 committer $authline
6133
6134 Merge $package ($version) import into $dstbranch
6135 END
6136         } else {
6137             die; # caught earlier
6138         }
6139     }
6140
6141     my @cmd = (@git, qw(update-ref -m), "dgit import-dsc: $info",
6142                $dstbranch, $newhash);
6143     runcmd @cmd;
6144     progress "dgit: import-dsc results are in in git ref $dstbranch";
6145 }
6146
6147 sub cmd_archive_api_query {
6148     badusage "need only 1 subpath argument" unless @ARGV==1;
6149     my ($subpath) = @ARGV;
6150     my @cmd = archive_api_query_cmd($subpath);
6151     push @cmd, qw(-f);
6152     debugcmd ">",@cmd;
6153     exec @cmd or fail "exec curl: $!\n";
6154 }
6155
6156 sub cmd_clone_dgit_repos_server {
6157     badusage "need destination argument" unless @ARGV==1;
6158     my ($destdir) = @ARGV;
6159     $package = '_dgit-repos-server';
6160     local $access_forpush = 0;
6161     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6162     debugcmd ">",@cmd;
6163     exec @cmd or fail "exec git clone: $!\n";
6164 }
6165
6166 sub cmd_print_dgit_repos_server_source_url {
6167     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6168         if @ARGV;
6169     $package = '_dgit-repos-server';
6170     local $access_forpush = 0;
6171     my $url = access_giturl();
6172     print $url, "\n" or die $!;
6173 }
6174
6175 sub cmd_setup_mergechangelogs {
6176     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6177     setup_mergechangelogs(1);
6178 }
6179
6180 sub cmd_setup_useremail {
6181     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6182     setup_useremail(1);
6183 }
6184
6185 sub cmd_setup_new_tree {
6186     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6187     setup_new_tree();
6188 }
6189
6190 #---------- argument parsing and main program ----------
6191
6192 sub cmd_version {
6193     print "dgit version $our_version\n" or die $!;
6194     exit 0;
6195 }
6196
6197 our (%valopts_long, %valopts_short);
6198 our @rvalopts;
6199
6200 sub defvalopt ($$$$) {
6201     my ($long,$short,$val_re,$how) = @_;
6202     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6203     $valopts_long{$long} = $oi;
6204     $valopts_short{$short} = $oi;
6205     # $how subref should:
6206     #   do whatever assignemnt or thing it likes with $_[0]
6207     #   if the option should not be passed on to remote, @rvalopts=()
6208     # or $how can be a scalar ref, meaning simply assign the value
6209 }
6210
6211 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6212 defvalopt '--distro',        '-d', '.+',      \$idistro;
6213 defvalopt '',                '-k', '.+',      \$keyid;
6214 defvalopt '--existing-package','', '.*',      \$existing_package;
6215 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6216 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6217 defvalopt '--package',   '-p',   $package_re, \$package;
6218 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6219
6220 defvalopt '', '-C', '.+', sub {
6221     ($changesfile) = (@_);
6222     if ($changesfile =~ s#^(.*)/##) {
6223         $buildproductsdir = $1;
6224     }
6225 };
6226
6227 defvalopt '--initiator-tempdir','','.*', sub {
6228     ($initiator_tempdir) = (@_);
6229     $initiator_tempdir =~ m#^/# or
6230         badusage "--initiator-tempdir must be used specify an".
6231         " absolute, not relative, directory."
6232 };
6233
6234 sub parseopts () {
6235     my $om;
6236
6237     if (defined $ENV{'DGIT_SSH'}) {
6238         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6239     } elsif (defined $ENV{'GIT_SSH'}) {
6240         @ssh = ($ENV{'GIT_SSH'});
6241     }
6242
6243     my $oi;
6244     my $val;
6245     my $valopt = sub {
6246         my ($what) = @_;
6247         @rvalopts = ($_);
6248         if (!defined $val) {
6249             badusage "$what needs a value" unless @ARGV;
6250             $val = shift @ARGV;
6251             push @rvalopts, $val;
6252         }
6253         badusage "bad value \`$val' for $what" unless
6254             $val =~ m/^$oi->{Re}$(?!\n)/s;
6255         my $how = $oi->{How};
6256         if (ref($how) eq 'SCALAR') {
6257             $$how = $val;
6258         } else {
6259             $how->($val);
6260         }
6261         push @ropts, @rvalopts;
6262     };
6263
6264     while (@ARGV) {
6265         last unless $ARGV[0] =~ m/^-/;
6266         $_ = shift @ARGV;
6267         last if m/^--?$/;
6268         if (m/^--/) {
6269             if (m/^--dry-run$/) {
6270                 push @ropts, $_;
6271                 $dryrun_level=2;
6272             } elsif (m/^--damp-run$/) {
6273                 push @ropts, $_;
6274                 $dryrun_level=1;
6275             } elsif (m/^--no-sign$/) {
6276                 push @ropts, $_;
6277                 $sign=0;
6278             } elsif (m/^--help$/) {
6279                 cmd_help();
6280             } elsif (m/^--version$/) {
6281                 cmd_version();
6282             } elsif (m/^--new$/) {
6283                 push @ropts, $_;
6284                 $new_package=1;
6285             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6286                      ($om = $opts_opt_map{$1}) &&
6287                      length $om->[0]) {
6288                 push @ropts, $_;
6289                 $om->[0] = $2;
6290             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6291                      !$opts_opt_cmdonly{$1} &&
6292                      ($om = $opts_opt_map{$1})) {
6293                 push @ropts, $_;
6294                 push @$om, $2;
6295             } elsif (m/^--(gbp|dpm)$/s) {
6296                 push @ropts, "--quilt=$1";
6297                 $quilt_mode = $1;
6298             } elsif (m/^--ignore-dirty$/s) {
6299                 push @ropts, $_;
6300                 $ignoredirty = 1;
6301             } elsif (m/^--no-quilt-fixup$/s) {
6302                 push @ropts, $_;
6303                 $quilt_mode = 'nocheck';
6304             } elsif (m/^--no-rm-on-error$/s) {
6305                 push @ropts, $_;
6306                 $rmonerror = 0;
6307             } elsif (m/^--no-chase-dsc-distro$/s) {
6308                 push @ropts, $_;
6309                 $chase_dsc_distro = 0;
6310             } elsif (m/^--overwrite$/s) {
6311                 push @ropts, $_;
6312                 $overwrite_version = '';
6313             } elsif (m/^--overwrite=(.+)$/s) {
6314                 push @ropts, $_;
6315                 $overwrite_version = $1;
6316             } elsif (m/^--dep14tag$/s) {
6317                 push @ropts, $_;
6318                 $dodep14tag= 'want';
6319             } elsif (m/^--no-dep14tag$/s) {
6320                 push @ropts, $_;
6321                 $dodep14tag= 'no';
6322             } elsif (m/^--always-dep14tag$/s) {
6323                 push @ropts, $_;
6324                 $dodep14tag= 'always';
6325             } elsif (m/^--delayed=(\d+)$/s) {
6326                 push @ropts, $_;
6327                 push @dput, $_;
6328             } elsif (m/^--dgit-view-save=(.+)$/s) {
6329                 push @ropts, $_;
6330                 $split_brain_save = $1;
6331                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6332             } elsif (m/^--(no-)?rm-old-changes$/s) {
6333                 push @ropts, $_;
6334                 $rmchanges = !$1;
6335             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6336                 push @ropts, $_;
6337                 push @deliberatelies, $&;
6338             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6339                 push @ropts, $&;
6340                 $forceopts{$1} = 1;
6341                 $_='';
6342             } elsif (m/^--force-/) {
6343                 print STDERR
6344                     "$us: warning: ignoring unknown force option $_\n";
6345                 $_='';
6346             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6347                 # undocumented, for testing
6348                 push @ropts, $_;
6349                 $tagformat_want = [ $1, 'command line', 1 ];
6350                 # 1 menas overrides distro configuration
6351             } elsif (m/^--always-split-source-build$/s) {
6352                 # undocumented, for testing
6353                 push @ropts, $_;
6354                 $need_split_build_invocation = 1;
6355             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6356                 # undocumented, for testing
6357                 push @ropts, $_;
6358                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6359                 # ^ it's supposed to be an array ref
6360             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6361                 $val = $2 ? $' : undef; #';
6362                 $valopt->($oi->{Long});
6363             } else {
6364                 badusage "unknown long option \`$_'";
6365             }
6366         } else {
6367             while (m/^-./s) {
6368                 if (s/^-n/-/) {
6369                     push @ropts, $&;
6370                     $dryrun_level=2;
6371                 } elsif (s/^-L/-/) {
6372                     push @ropts, $&;
6373                     $dryrun_level=1;
6374                 } elsif (s/^-h/-/) {
6375                     cmd_help();
6376                 } elsif (s/^-D/-/) {
6377                     push @ropts, $&;
6378                     $debuglevel++;
6379                     enabledebug();
6380                 } elsif (s/^-N/-/) {
6381                     push @ropts, $&;
6382                     $new_package=1;
6383                 } elsif (m/^-m/) {
6384                     push @ropts, $&;
6385                     push @changesopts, $_;
6386                     $_ = '';
6387                 } elsif (s/^-wn$//s) {
6388                     push @ropts, $&;
6389                     $cleanmode = 'none';
6390                 } elsif (s/^-wg$//s) {
6391                     push @ropts, $&;
6392                     $cleanmode = 'git';
6393                 } elsif (s/^-wgf$//s) {
6394                     push @ropts, $&;
6395                     $cleanmode = 'git-ff';
6396                 } elsif (s/^-wd$//s) {
6397                     push @ropts, $&;
6398                     $cleanmode = 'dpkg-source';
6399                 } elsif (s/^-wdd$//s) {
6400                     push @ropts, $&;
6401                     $cleanmode = 'dpkg-source-d';
6402                 } elsif (s/^-wc$//s) {
6403                     push @ropts, $&;
6404                     $cleanmode = 'check';
6405                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6406                     push @git, '-c', $&;
6407                     $gitcfgs{cmdline}{$1} = [ $2 ];
6408                 } elsif (s/^-c([^=]+)$//s) {
6409                     push @git, '-c', $&;
6410                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6411                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6412                     $val = $'; #';
6413                     $val = undef unless length $val;
6414                     $valopt->($oi->{Short});
6415                     $_ = '';
6416                 } else {
6417                     badusage "unknown short option \`$_'";
6418                 }
6419             }
6420         }
6421     }
6422 }
6423
6424 sub check_env_sanity () {
6425     my $blocked = new POSIX::SigSet;
6426     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6427
6428     eval {
6429         foreach my $name (qw(PIPE CHLD)) {
6430             my $signame = "SIG$name";
6431             my $signum = eval "POSIX::$signame" // die;
6432             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6433                 die "$signame is set to something other than SIG_DFL\n";
6434             $blocked->ismember($signum) and
6435                 die "$signame is blocked\n";
6436         }
6437     };
6438     return unless $@;
6439     chomp $@;
6440     fail <<END;
6441 On entry to dgit, $@
6442 This is a bug produced by something in in your execution environment.
6443 Giving up.
6444 END
6445 }
6446
6447
6448 sub parseopts_late_defaults () {
6449     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6450         if defined $idistro;
6451     $isuite //= cfg('dgit.default.default-suite');
6452
6453     foreach my $k (keys %opts_opt_map) {
6454         my $om = $opts_opt_map{$k};
6455
6456         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6457         if (defined $v) {
6458             badcfg "cannot set command for $k"
6459                 unless length $om->[0];
6460             $om->[0] = $v;
6461         }
6462
6463         foreach my $c (access_cfg_cfgs("opts-$k")) {
6464             my @vl =
6465                 map { $_ ? @$_ : () }
6466                 map { $gitcfgs{$_}{$c} }
6467                 reverse @gitcfgsources;
6468             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6469                 "\n" if $debuglevel >= 4;
6470             next unless @vl;
6471             badcfg "cannot configure options for $k"
6472                 if $opts_opt_cmdonly{$k};
6473             my $insertpos = $opts_cfg_insertpos{$k};
6474             @$om = ( @$om[0..$insertpos-1],
6475                      @vl,
6476                      @$om[$insertpos..$#$om] );
6477         }
6478     }
6479
6480     if (!defined $rmchanges) {
6481         local $access_forpush;
6482         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6483     }
6484
6485     if (!defined $quilt_mode) {
6486         local $access_forpush;
6487         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6488             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6489             // 'linear';
6490         $quilt_mode =~ m/^($quilt_modes_re)$/
6491             or badcfg "unknown quilt-mode \`$quilt_mode'";
6492         $quilt_mode = $1;
6493     }
6494
6495     if (!defined $dodep14tag) {
6496         local $access_forpush;
6497         $dodep14tag = access_cfg('dep14tag', 'RETURN-UNDEF') // 'want';
6498         $dodep14tag =~ m/^($dodep14tag_re)$/
6499             or badcfg "unknown dep14tag setting \`$dodep14tag'";
6500         $dodep14tag = $1;
6501     }
6502
6503     $need_split_build_invocation ||= quiltmode_splitbrain();
6504
6505     if (!defined $cleanmode) {
6506         local $access_forpush;
6507         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6508         $cleanmode //= 'dpkg-source';
6509
6510         badcfg "unknown clean-mode \`$cleanmode'" unless
6511             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6512     }
6513 }
6514
6515 if ($ENV{$fakeeditorenv}) {
6516     git_slurp_config();
6517     quilt_fixup_editor();
6518 }
6519
6520 parseopts();
6521 check_env_sanity();
6522 git_slurp_config();
6523
6524 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6525 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6526     if $dryrun_level == 1;
6527 if (!@ARGV) {
6528     print STDERR $helpmsg or die $!;
6529     exit 8;
6530 }
6531 my $cmd = shift @ARGV;
6532 $cmd =~ y/-/_/;
6533
6534 my $pre_fn = ${*::}{"pre_$cmd"};
6535 $pre_fn->() if $pre_fn;
6536
6537 my $fn = ${*::}{"cmd_$cmd"};
6538 $fn or badusage "unknown operation $cmd";
6539 $fn->();