dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2015 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 $SIG{__WARN__} = sub { die $_[0]; };
  22
  23 use IO::Handle;
  24 use Data::Dumper;
  25 use LWP::UserAgent;
  26 use Dpkg::Control::Hash;
  27 use File::Path;
  28 use File::Temp qw(tempdir);
  29 use File::Basename;
  30 use Dpkg::Version;
  31 use POSIX;
  32 use IPC::Open2;
  33 use Digest::SHA;
  34 use Digest::MD5;
  35
  36 use Debian::Dgit;
  37
  38 our $our_version = 'UNRELEASED'; ###substituted###
  39
  40 our $rpushprotovsn = 2;
  41
  42 our $isuite = 'unstable';
  43 our $idistro;
  44 our $package;
  45 our @ropts;
  46
  47 our $sign = 1;
  48 our $dryrun_level = 0;
  49 our $changesfile;
  50 our $buildproductsdir = '..';
  51 our $new_package = 0;
  52 our $ignoredirty = 0;
  53 our $rmonerror = 1;
  54 our @deliberatelies;
  55 our %previously;
  56 our $existing_package = 'dpkg';
  57 our $cleanmode = 'dpkg-source';
  58 our $changes_since_version;
  59 our $quilt_mode;
  60 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  61 our $we_are_responder;
  62 our $initiator_tempdir;
  63
  64 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  65
  66 our $suite_re = '[-+.0-9a-z]+';
  67
  68 our (@git) = qw(git);
  69 our (@dget) = qw(dget);
  70 our (@curl) = qw(curl -f);
  71 our (@dput) = qw(dput);
  72 our (@debsign) = qw(debsign);
  73 our (@gpg) = qw(gpg);
  74 our (@sbuild) = qw(sbuild -A);
  75 our (@ssh) = 'ssh';
  76 our (@dgit) = qw(dgit);
  77 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  78 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  79 our (@dpkggenchanges) = qw(dpkg-genchanges);
  80 our (@mergechanges) = qw(mergechanges -f);
  81 our (@changesopts) = ('');
  82
  83 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  84                      'curl' => \@curl,
  85                      'dput' => \@dput,
  86                      'debsign' => \@debsign,
  87                      'gpg' => \@gpg,
  88                      'sbuild' => \@sbuild,
  89                      'ssh' => \@ssh,
  90                      'dgit' => \@dgit,
  91                      'dpkg-source' => \@dpkgsource,
  92                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  93                      'dpkg-genchanges' => \@dpkggenchanges,
  94                      'ch' => \@changesopts,
  95                      'mergechanges' => \@mergechanges);
  96
  97 our %opts_opt_cmdonly = ('gpg' => 1);
  98
  99 our $keyid;
 100
 101 autoflush STDOUT 1;
 102
 103 our $remotename = 'dgit';
 104 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 105 our $csuite;
 106 our $instead_distro;
 107
 108 sub lbranch () { return "$branchprefix/$csuite"; }
 109 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 110 sub lref () { return "refs/heads/".lbranch(); }
 111 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 112 sub rrref () { return server_ref($csuite); }
 113
 114 sub lrfetchrefs () { return "refs/dgit-fetch/$isuite"; }
 115
 116 sub stripepoch ($) {
 117     my ($vsn) = @_;
 118     $vsn =~ s/^\d+\://;
 119     return $vsn;
 120 }
 121
 122 sub srcfn ($$) {
 123     my ($vsn,$sfx) = @_;
 124     return "${package}_".(stripepoch $vsn).$sfx
 125 }
 126
 127 sub dscfn ($) {
 128     my ($vsn) = @_;
 129     return srcfn($vsn,".dsc");
 130 }
 131
 132 our $us = 'dgit';
 133 initdebug('');
 134
 135 our @end;
 136 END {
 137     local ($?);
 138     foreach my $f (@end) {
 139         eval { $f->(); };
 140         warn "$us: cleanup: $@" if length $@;
 141     }
 142 };
 143
 144 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 145
 146 sub no_such_package () {
 147     print STDERR "$us: package $package does not exist in suite $isuite\n";
 148     exit 4;
 149 }
 150
 151 sub fetchspec () {
 152     local $csuite = '*';
 153     return  "+".rrref().":".lrref();
 154 }
 155
 156 sub changedir ($) {
 157     my ($newdir) = @_;
 158     printdebug "CD $newdir\n";
 159     chdir $newdir or die "chdir: $newdir: $!";
 160 }
 161
 162 sub deliberately ($) {
 163     my ($enquiry) = @_;
 164     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 165 }
 166
 167 sub deliberately_not_fast_forward () {
 168     foreach (qw(not-fast-forward fresh-repo)) {
 169         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 170     }
 171 }
 172
 173 #---------- remote protocol support, common ----------
 174
 175 # remote push initiator/responder protocol:
 176 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 177 #
 178 #  > file parsed-changelog
 179 #  [indicates that output of dpkg-parsechangelog follows]
 180 #  > data-block NBYTES
 181 #  > [NBYTES bytes of data (no newline)]
 182 #  [maybe some more blocks]
 183 #  > data-end
 184 #
 185 #  > file dsc
 186 #  [etc]
 187 #
 188 #  > file changes
 189 #  [etc]
 190 #
 191 #  > param head HEAD
 192 #
 193 #  > want signed-tag
 194 #  [indicates that signed tag is wanted]
 195 #  < data-block NBYTES
 196 #  < [NBYTES bytes of data (no newline)]
 197 #  [maybe some more blocks]
 198 #  < data-end
 199 #  < files-end
 200 #
 201 #  > want signed-dsc-changes
 202 #  < data-block NBYTES    [transfer of signed dsc]
 203 #  [etc]
 204 #  < data-block NBYTES    [transfer of signed changes]
 205 #  [etc]
 206 #  < files-end
 207 #
 208 #  > complete
 209
 210 our $i_child_pid;
 211
 212 sub i_child_report () {
 213     # Sees if our child has died, and reap it if so.  Returns a string
 214     # describing how it died if it failed, or undef otherwise.
 215     return undef unless $i_child_pid;
 216     my $got = waitpid $i_child_pid, WNOHANG;
 217     return undef if $got <= 0;
 218     die unless $got == $i_child_pid;
 219     $i_child_pid = undef;
 220     return undef unless $?;
 221     return "build host child ".waitstatusmsg();
 222 }
 223
 224 sub badproto ($$) {
 225     my ($fh, $m) = @_;
 226     fail "connection lost: $!" if $fh->error;
 227     fail "protocol violation; $m not expected";
 228 }
 229
 230 sub badproto_badread ($$) {
 231     my ($fh, $wh) = @_;
 232     fail "connection lost: $!" if $!;
 233     my $report = i_child_report();
 234     fail $report if defined $report;
 235     badproto $fh, "eof (reading $wh)";
 236 }
 237
 238 sub protocol_expect (&$) {
 239     my ($match, $fh) = @_;
 240     local $_;
 241     $_ = <$fh>;
 242     defined && chomp or badproto_badread $fh, "protocol message";
 243     if (wantarray) {
 244         my @r = &$match;
 245         return @r if @r;
 246     } else {
 247         my $r = &$match;
 248         return $r if $r;
 249     }
 250     badproto $fh, "\`$_'";
 251 }
 252
 253 sub protocol_send_file ($$) {
 254     my ($fh, $ourfn) = @_;
 255     open PF, "<", $ourfn or die "$ourfn: $!";
 256     for (;;) {
 257         my $d;
 258         my $got = read PF, $d, 65536;
 259         die "$ourfn: $!" unless defined $got;
 260         last if !$got;
 261         print $fh "data-block ".length($d)."\n" or die $!;
 262         print $fh $d or die $!;
 263     }
 264     PF->error and die "$ourfn $!";
 265     print $fh "data-end\n" or die $!;
 266     close PF;
 267 }
 268
 269 sub protocol_read_bytes ($$) {
 270     my ($fh, $nbytes) = @_;
 271     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 272     my $d;
 273     my $got = read $fh, $d, $nbytes;
 274     $got==$nbytes or badproto_badread $fh, "data block";
 275     return $d;
 276 }
 277
 278 sub protocol_receive_file ($$) {
 279     my ($fh, $ourfn) = @_;
 280     printdebug "() $ourfn\n";
 281     open PF, ">", $ourfn or die "$ourfn: $!";
 282     for (;;) {
 283         my ($y,$l) = protocol_expect {
 284             m/^data-block (.*)$/ ? (1,$1) :
 285             m/^data-end$/ ? (0,) :
 286             ();
 287         } $fh;
 288         last unless $y;
 289         my $d = protocol_read_bytes $fh, $l;
 290         print PF $d or die $!;
 291     }
 292     close PF or die $!;
 293 }
 294
 295 #---------- remote protocol support, responder ----------
 296
 297 sub responder_send_command ($) {
 298     my ($command) = @_;
 299     return unless $we_are_responder;
 300     # called even without $we_are_responder
 301     printdebug ">> $command\n";
 302     print PO $command, "\n" or die $!;
 303 }
 304
 305 sub responder_send_file ($$) {
 306     my ($keyword, $ourfn) = @_;
 307     return unless $we_are_responder;
 308     printdebug "]] $keyword $ourfn\n";
 309     responder_send_command "file $keyword";
 310     protocol_send_file \*PO, $ourfn;
 311 }
 312
 313 sub responder_receive_files ($@) {
 314     my ($keyword, @ourfns) = @_;
 315     die unless $we_are_responder;
 316     printdebug "[[ $keyword @ourfns\n";
 317     responder_send_command "want $keyword";
 318     foreach my $fn (@ourfns) {
 319         protocol_receive_file \*PI, $fn;
 320     }
 321     printdebug "[[\$\n";
 322     protocol_expect { m/^files-end$/ } \*PI;
 323 }
 324
 325 #---------- remote protocol support, initiator ----------
 326
 327 sub initiator_expect (&) {
 328     my ($match) = @_;
 329     protocol_expect { &$match } \*RO;
 330 }
 331
 332 #---------- end remote code ----------
 333
 334 sub progress {
 335     if ($we_are_responder) {
 336         my $m = join '', @_;
 337         responder_send_command "progress ".length($m) or die $!;
 338         print PO $m or die $!;
 339     } else {
 340         print @_, "\n";
 341     }
 342 }
 343
 344 our $ua;
 345
 346 sub url_get {
 347     if (!$ua) {
 348         $ua = LWP::UserAgent->new();
 349         $ua->env_proxy;
 350     }
 351     my $what = $_[$#_];
 352     progress "downloading $what...";
 353     my $r = $ua->get(@_) or die $!;
 354     return undef if $r->code == 404;
 355     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 356     return $r->decoded_content(charset => 'none');
 357 }
 358
 359 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 360
 361 sub runcmd {
 362     debugcmd "+",@_;
 363     $!=0; $?=0;
 364     failedcmd @_ if system @_;
 365 }
 366
 367 sub act_local () { return $dryrun_level <= 1; }
 368 sub act_scary () { return !$dryrun_level; }
 369
 370 sub printdone {
 371     if (!$dryrun_level) {
 372         progress "dgit ok: @_";
 373     } else {
 374         progress "would be ok: @_ (but dry run only)";
 375     }
 376 }
 377
 378 sub dryrun_report {
 379     printcmd(\*STDERR,$debugprefix."#",@_);
 380 }
 381
 382 sub runcmd_ordryrun {
 383     if (act_scary()) {
 384         runcmd @_;
 385     } else {
 386         dryrun_report @_;
 387     }
 388 }
 389
 390 sub runcmd_ordryrun_local {
 391     if (act_local()) {
 392         runcmd @_;
 393     } else {
 394         dryrun_report @_;
 395     }
 396 }
 397
 398 sub shell_cmd {
 399     my ($first_shell, @cmd) = @_;
 400     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 401 }
 402
 403 our $helpmsg = <<END;
 404 main usages:
 405   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 406   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 407   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 408   dgit [dgit-opts] push [dgit-opts] [suite]
 409   dgit [dgit-opts] rpush build-host:build-dir ...
 410 important dgit options:
 411   -k<keyid>           sign tag and package with <keyid> instead of default
 412   --dry-run -n        do not change anything, but go through the motions
 413   --damp-run -L       like --dry-run but make local changes, without signing
 414   --new -N            allow introducing a new package
 415   --debug -D          increase debug level
 416   -c<name>=<value>    set git config option (used directly by dgit too)
 417 END
 418
 419 our $later_warning_msg = <<END;
 420 Perhaps the upload is stuck in incoming.  Using the version from git.
 421 END
 422
 423 sub badusage {
 424     print STDERR "$us: @_\n", $helpmsg or die $!;
 425     exit 8;
 426 }
 427
 428 sub nextarg {
 429     @ARGV or badusage "too few arguments";
 430     return scalar shift @ARGV;
 431 }
 432
 433 sub cmd_help () {
 434     print $helpmsg or die $!;
 435     exit 0;
 436 }
 437
 438 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 439
 440 our %defcfg = ('dgit.default.distro' => 'debian',
 441                'dgit.default.username' => '',
 442                'dgit.default.archive-query-default-component' => 'main',
 443                'dgit.default.ssh' => 'ssh',
 444                'dgit.default.archive-query' => 'madison:',
 445                'dgit.default.sshpsql-dbname' => 'service=projectb',
 446                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 447                'dgit-distro.debian.git-host' => 'dgit-git.debian.net',
 448                'dgit-distro.debian.git-user-force' => 'dgit',
 449                'dgit-distro.debian.git-proto' => 'git+ssh://',
 450                'dgit-distro.debian.git-path' => '/dgit/debian/repos',
 451                'dgit-distro.debian.git-check' => 'ssh-cmd',
 452  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 453  'dgit-distro.debian.archive-query-tls-key',
 454     '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 455 #
 456 # 'dgit-distro.debian.archive-query-tls-curl-args',
 457 #   '--ca-path=/etc/ssl/ca-debian',
 458 # ^ this is a workaround but works (only) on DSA-administered machines
 459                'dgit-distro.debian.diverts.alioth' => '/alioth',
 460                'dgit-distro.debian/alioth.git-host' => 'git.debian.org',
 461                'dgit-distro.debian/alioth.git-user-force' => '',
 462                'dgit-distro.debian/alioth.git-proto' => 'git+ssh://',
 463                'dgit-distro.debian/alioth.git-path' => '/git/dgit-repos/repos',
 464                'dgit-distro.debian/alioth.git-create' => 'ssh-cmd',
 465                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 466                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 467  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 468  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 469                'dgit-distro.ubuntu.git-check' => 'false',
 470  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 471                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 472                'dgit-distro.test-dummy.username' => "alice",
 473                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 474                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 475                'dgit-distro.test-dummy.git-url' => "$td/git",
 476                'dgit-distro.test-dummy.git-host' => "git",
 477                'dgit-distro.test-dummy.git-path' => "$td/git",
 478                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 479                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 480                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 481                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 482                );
 483
 484 sub cfg {
 485     foreach my $c (@_) {
 486         return undef if $c =~ /RETURN-UNDEF/;
 487         my @cmd = (@git, qw(config --), $c);
 488         my $v;
 489         {
 490             local ($debuglevel) = $debuglevel-2;
 491             $v = cmdoutput_errok @cmd;
 492         };
 493         if ($?==0) {
 494             return $v;
 495         } elsif ($?!=256) {
 496             failedcmd @cmd;
 497         }
 498         my $dv = $defcfg{$c};
 499         return $dv if defined $dv;
 500     }
 501     badcfg "need value for one of: @_\n".
 502         "$us: distro or suite appears not to be (properly) supported";
 503 }
 504
 505 sub access_basedistro () {
 506     if (defined $idistro) {
 507         return $idistro;
 508     } else {
 509         return cfg("dgit-suite.$isuite.distro",
 510                    "dgit.default.distro");
 511     }
 512 }
 513
 514 sub access_quirk () {
 515     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 516     my $basedistro = access_basedistro();
 517     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 518                               'RETURN-UNDEF');
 519     if (defined $backports_quirk) {
 520         my $re = $backports_quirk;
 521         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 522         $re =~ s/\*/.*/g;
 523         $re =~ s/\%/([-0-9a-z_]+)/
 524             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 525         if ($isuite =~ m/^$re$/) {
 526             return ('backports',"$basedistro-backports",$1);
 527         }
 528     }
 529     return ('none',undef);
 530 }
 531
 532 sub access_distros () {
 533     # Returns list of distros to try, in order
 534     #
 535     # We want to try:
 536     #    0. `instead of' distro name(s) we have been pointed to
 537     #    1. the access_quirk distro, if any
 538     #    2a. the user's specified distro, or failing that  } basedistro
 539     #    2b. the distro calculated from the suite          }
 540     my @l = access_basedistro();
 541
 542     my (undef,$quirkdistro) = access_quirk();
 543     unshift @l, $quirkdistro;
 544     unshift @l, $instead_distro;
 545     return grep { defined } @l;
 546 }
 547
 548 sub access_cfg (@) {
 549     my (@keys) = @_;
 550     my @cfgs;
 551     # The nesting of these loops determines the search order.  We put
 552     # the key loop on the outside so that we search all the distros
 553     # for each key, before going on to the next key.  That means that
 554     # if access_cfg is called with a more specific, and then a less
 555     # specific, key, an earlier distro can override the less specific
 556     # without necessarily overriding any more specific keys.  (If the
 557     # distro wants to override the more specific keys it can simply do
 558     # so; whereas if we did the loop the other way around, it would be
 559     # impossible to for an earlier distro to override a less specific
 560     # key but not the more specific ones without restating the unknown
 561     # values of the more specific keys.
 562     my @realkeys;
 563     my @rundef;
 564     # We have to deal with RETURN-UNDEF specially, so that we don't
 565     # terminate the search prematurely.
 566     foreach (@keys) {
 567         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 568         push @realkeys, $_
 569     }
 570     foreach my $d (access_distros()) {
 571         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 572     }
 573     push @cfgs, map { "dgit.default.$_" } @realkeys;
 574     push @cfgs, @rundef;
 575     my $value = cfg(@cfgs);
 576     return $value;
 577 }
 578
 579 sub string_to_ssh ($) {
 580     my ($spec) = @_;
 581     if ($spec =~ m/\s/) {
 582         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 583     } else {
 584         return ($spec);
 585     }
 586 }
 587
 588 sub access_cfg_ssh () {
 589     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 590     if (!defined $gitssh) {
 591         return @ssh;
 592     } else {
 593         return string_to_ssh $gitssh;
 594     }
 595 }
 596
 597 sub access_runeinfo ($) {
 598     my ($info) = @_;
 599     return ": dgit ".access_basedistro()." $info ;";
 600 }
 601
 602 sub access_someuserhost ($) {
 603     my ($some) = @_;
 604     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 605     defined($user) && length($user) or
 606         $user = access_cfg("$some-user",'username');
 607     my $host = access_cfg("$some-host");
 608     return length($user) ? "$user\@$host" : $host;
 609 }
 610
 611 sub access_gituserhost () {
 612     return access_someuserhost('git');
 613 }
 614
 615 sub access_giturl (;$) {
 616     my ($optional) = @_;
 617     my $url = access_cfg('git-url','RETURN-UNDEF');
 618     if (!defined $url) {
 619         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 620         return undef unless defined $proto;
 621         $url =
 622             $proto.
 623             access_gituserhost().
 624             access_cfg('git-path');
 625     }
 626     return "$url/$package.git";
 627 }
 628
 629 sub parsecontrolfh ($$;$) {
 630     my ($fh, $desc, $allowsigned) = @_;
 631     our $dpkgcontrolhash_noissigned;
 632     my $c;
 633     for (;;) {
 634         my %opts = ('name' => $desc);
 635         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 636         $c = Dpkg::Control::Hash->new(%opts);
 637         $c->parse($fh,$desc) or die "parsing of $desc failed";
 638         last if $allowsigned;
 639         last if $dpkgcontrolhash_noissigned;
 640         my $issigned= $c->get_option('is_pgp_signed');
 641         if (!defined $issigned) {
 642             $dpkgcontrolhash_noissigned= 1;
 643             seek $fh, 0,0 or die "seek $desc: $!";
 644         } elsif ($issigned) {
 645             fail "control file $desc is (already) PGP-signed. ".
 646                 " Note that dgit push needs to modify the .dsc and then".
 647                 " do the signature itself";
 648         } else {
 649             last;
 650         }
 651     }
 652     return $c;
 653 }
 654
 655 sub parsecontrol {
 656     my ($file, $desc) = @_;
 657     my $fh = new IO::Handle;
 658     open $fh, '<', $file or die "$file: $!";
 659     my $c = parsecontrolfh($fh,$desc);
 660     $fh->error and die $!;
 661     close $fh;
 662     return $c;
 663 }
 664
 665 sub getfield ($$) {
 666     my ($dctrl,$field) = @_;
 667     my $v = $dctrl->{$field};
 668     return $v if defined $v;
 669     fail "missing field $field in ".$v->get_option('name');
 670 }
 671
 672 sub parsechangelog {
 673     my $c = Dpkg::Control::Hash->new();
 674     my $p = new IO::Handle;
 675     my @cmd = (qw(dpkg-parsechangelog), @_);
 676     open $p, '-|', @cmd or die $!;
 677     $c->parse($p);
 678     $?=0; $!=0; close $p or failedcmd @cmd;
 679     return $c;
 680 }
 681
 682 sub must_getcwd () {
 683     my $d = getcwd();
 684     defined $d or fail "getcwd failed: $!";
 685     return $d;
 686 }
 687
 688 our %rmad;
 689
 690 sub archive_query ($) {
 691     my ($method) = @_;
 692     my $query = access_cfg('archive-query','RETURN-UNDEF');
 693     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 694     my $proto = $1;
 695     my $data = $'; #';
 696     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 697 }
 698
 699 sub pool_dsc_subpath ($$) {
 700     my ($vsn,$component) = @_; # $package is implict arg
 701     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 702     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 703 }
 704
 705 #---------- `ftpmasterapi' archive query method (nascent) ----------
 706
 707 sub archive_api_query_cmd ($) {
 708     my ($subpath) = @_;
 709     my @cmd = qw(curl -sS);
 710     my $url = access_cfg('archive-query-url');
 711     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 712         my $host = $1;
 713         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
 714         foreach my $key (split /\:/, $keys) {
 715             $key =~ s/\%HOST\%/$host/g;
 716             if (!stat $key) {
 717                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 718                 next;
 719             }
 720             push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
 721             last;
 722         }
 723         # Fixing #790093 properly will involve providing a value
 724         # for this on clients.
 725         my $keys = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
 726         push @cmd, split / /, $keys if defined $keys;
 727     }
 728     push @cmd, $url.$subpath;
 729     return @cmd;
 730 }
 731
 732 sub api_query ($$) {
 733     use JSON;
 734     my ($data, $subpath) = @_;
 735     badcfg "ftpmasterapi archive query method takes no data part"
 736         if length $data;
 737     my @cmd = archive_api_query_cmd($subpath);
 738     my $json = cmdoutput @cmd;
 739     return decode_json($json);
 740 }
 741
 742 sub canonicalise_suite_ftpmasterapi () {
 743     my ($proto,$data) = @_;
 744     my $suites = api_query($data, 'suites');
 745     my @matched;
 746     foreach my $entry (@$suites) {
 747         next unless grep {
 748             my $v = $entry->{$_};
 749             defined $v && $v eq $isuite;
 750         } qw(codename name);
 751         push @matched, $entry;
 752     }
 753     fail "unknown suite $isuite" unless @matched;
 754     my $cn;
 755     eval {
 756         @matched==1 or die "multiple matches for suite $isuite\n";
 757         $cn = "$matched[0]{codename}";
 758         defined $cn or die "suite $isuite info has no codename\n";
 759         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 760     };
 761     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 762         if length $@;
 763     return $cn;
 764 }
 765
 766 sub archive_query_ftpmasterapi () {
 767     my ($proto,$data) = @_;
 768     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 769     my @rows;
 770     my $digester = Digest::SHA->new(256);
 771     foreach my $entry (@$info) {
 772         eval {
 773             my $vsn = "$entry->{version}";
 774             my ($ok,$msg) = version_check $vsn;
 775             die "bad version: $msg\n" unless $ok;
 776             my $component = "$entry->{component}";
 777             $component =~ m/^$component_re$/ or die "bad component";
 778             my $filename = "$entry->{filename}";
 779             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 780                 or die "bad filename";
 781             my $sha256sum = "$entry->{sha256sum}";
 782             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 783             push @rows, [ $vsn, "/pool/$component/$filename",
 784                           $digester, $sha256sum ];
 785         };
 786         die "bad ftpmaster api response: $@\n".Dumper($entry)
 787             if length $@;
 788     }
 789     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 790     return @rows;
 791 }
 792
 793 #---------- `madison' archive query method ----------
 794
 795 sub archive_query_madison {
 796     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 797 }
 798
 799 sub madison_get_parse {
 800     my ($proto,$data) = @_;
 801     die unless $proto eq 'madison';
 802     if (!length $data) {
 803         $data= access_cfg('madison-distro','RETURN-UNDEF');
 804         $data //= access_basedistro();
 805     }
 806     $rmad{$proto,$data,$package} ||= cmdoutput
 807         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 808     my $rmad = $rmad{$proto,$data,$package};
 809
 810     my @out;
 811     foreach my $l (split /\n/, $rmad) {
 812         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 813                   \s*( [^ \t|]+ )\s* \|
 814                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 815                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 816         $1 eq $package or die "$rmad $package ?";
 817         my $vsn = $2;
 818         my $newsuite = $3;
 819         my $component;
 820         if (defined $4) {
 821             $component = $4;
 822         } else {
 823             $component = access_cfg('archive-query-default-component');
 824         }
 825         $5 eq 'source' or die "$rmad ?";
 826         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 827     }
 828     return sort { -version_compare($a->[0],$b->[0]); } @out;
 829 }
 830
 831 sub canonicalise_suite_madison {
 832     # madison canonicalises for us
 833     my @r = madison_get_parse(@_);
 834     @r or fail
 835         "unable to canonicalise suite using package $package".
 836         " which does not appear to exist in suite $isuite;".
 837         " --existing-package may help";
 838     return $r[0][2];
 839 }
 840
 841 #---------- `sshpsql' archive query method ----------
 842
 843 sub sshpsql ($$$) {
 844     my ($data,$runeinfo,$sql) = @_;
 845     if (!length $data) {
 846         $data= access_someuserhost('sshpsql').':'.
 847             access_cfg('sshpsql-dbname');
 848     }
 849     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 850     my ($userhost,$dbname) = ($`,$'); #';
 851     my @rows;
 852     my @cmd = (access_cfg_ssh, $userhost,
 853                access_runeinfo("ssh-psql $runeinfo").
 854                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 855                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 856     debugcmd "|",@cmd;
 857     open P, "-|", @cmd or die $!;
 858     while (<P>) {
 859         chomp or die;
 860         printdebug("$debugprefix>|$_|\n");
 861         push @rows, $_;
 862     }
 863     $!=0; $?=0; close P or failedcmd @cmd;
 864     @rows or die;
 865     my $nrows = pop @rows;
 866     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 867     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 868     @rows = map { [ split /\|/, $_ ] } @rows;
 869     my $ncols = scalar @{ shift @rows };
 870     die if grep { scalar @$_ != $ncols } @rows;
 871     return @rows;
 872 }
 873
 874 sub sql_injection_check {
 875     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
 876 }
 877
 878 sub archive_query_sshpsql ($$) {
 879     my ($proto,$data) = @_;
 880     sql_injection_check $isuite, $package;
 881     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
 882         SELECT source.version, component.name, files.filename, files.sha256sum
 883           FROM source
 884           JOIN src_associations ON source.id = src_associations.source
 885           JOIN suite ON suite.id = src_associations.suite
 886           JOIN dsc_files ON dsc_files.source = source.id
 887           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 888           JOIN component ON component.id = files_archive_map.component_id
 889           JOIN files ON files.id = dsc_files.file
 890          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 891            AND source.source='$package'
 892            AND files.filename LIKE '%.dsc';
 893 END
 894     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 895     my $digester = Digest::SHA->new(256);
 896     @rows = map {
 897         my ($vsn,$component,$filename,$sha256sum) = @$_;
 898         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 899     } @rows;
 900     return @rows;
 901 }
 902
 903 sub canonicalise_suite_sshpsql ($$) {
 904     my ($proto,$data) = @_;
 905     sql_injection_check $isuite;
 906     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
 907         SELECT suite.codename
 908           FROM suite where suite_name='$isuite' or codename='$isuite';
 909 END
 910     @rows = map { $_->[0] } @rows;
 911     fail "unknown suite $isuite" unless @rows;
 912     die "ambiguous $isuite: @rows ?" if @rows>1;
 913     return $rows[0];
 914 }
 915
 916 #---------- `dummycat' archive query method ----------
 917
 918 sub canonicalise_suite_dummycat ($$) {
 919     my ($proto,$data) = @_;
 920     my $dpath = "$data/suite.$isuite";
 921     if (!open C, "<", $dpath) {
 922         $!==ENOENT or die "$dpath: $!";
 923         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 924         return $isuite;
 925     }
 926     $!=0; $_ = <C>;
 927     chomp or die "$dpath: $!";
 928     close C;
 929     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 930     return $_;
 931 }
 932
 933 sub archive_query_dummycat ($$) {
 934     my ($proto,$data) = @_;
 935     canonicalise_suite();
 936     my $dpath = "$data/package.$csuite.$package";
 937     if (!open C, "<", $dpath) {
 938         $!==ENOENT or die "$dpath: $!";
 939         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 940         return ();
 941     }
 942     my @rows;
 943     while (<C>) {
 944         next if m/^\#/;
 945         next unless m/\S/;
 946         die unless chomp;
 947         printdebug "dummycat query $csuite $package $dpath | $_\n";
 948         my @row = split /\s+/, $_;
 949         @row==2 or die "$dpath: $_ ?";
 950         push @rows, \@row;
 951     }
 952     C->error and die "$dpath: $!";
 953     close C;
 954     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 955 }
 956
 957 #---------- archive query entrypoints and rest of program ----------
 958
 959 sub canonicalise_suite () {
 960     return if defined $csuite;
 961     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 962     $csuite = archive_query('canonicalise_suite');
 963     if ($isuite ne $csuite) {
 964         progress "canonical suite name for $isuite is $csuite";
 965     }
 966 }
 967
 968 sub get_archive_dsc () {
 969     canonicalise_suite();
 970     my @vsns = archive_query('archive_query');
 971     foreach my $vinfo (@vsns) {
 972         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 973         $dscurl = access_cfg('mirror').$subpath;
 974         $dscdata = url_get($dscurl);
 975         if (!$dscdata) {
 976             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 977             next;
 978         }
 979         if ($digester) {
 980             $digester->reset();
 981             $digester->add($dscdata);
 982             my $got = $digester->hexdigest();
 983             $got eq $digest or
 984                 fail "$dscurl has hash $got but".
 985                     " archive told us to expect $digest";
 986         }
 987         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 988         printdebug Dumper($dscdata) if $debuglevel>1;
 989         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 990         printdebug Dumper($dsc) if $debuglevel>1;
 991         my $fmt = getfield $dsc, 'Format';
 992         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 993         $dsc_checked = !!$digester;
 994         return;
 995     }
 996     $dsc = undef;
 997 }
 998
 999 sub check_for_git ();
1000 sub check_for_git () {
1001     # returns 0 or 1
1002     my $how = access_cfg('git-check');
1003     if ($how eq 'ssh-cmd') {
1004         my @cmd =
1005             (access_cfg_ssh, access_gituserhost(),
1006              access_runeinfo("git-check $package").
1007              " set -e; cd ".access_cfg('git-path').";".
1008              " if test -d $package.git; then echo 1; else echo 0; fi");
1009         my $r= cmdoutput @cmd;
1010         if ($r =~ m/^divert (\w+)$/) {
1011             my $divert=$1;
1012             my ($usedistro,) = access_distros();
1013             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1014             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1015             printdebug "diverting $divert so using distro $instead_distro\n";
1016             return check_for_git();
1017         }
1018         failedcmd @cmd unless $r =~ m/^[01]$/;
1019         return $r+0;
1020     } elsif ($how eq 'true') {
1021         return 1;
1022     } elsif ($how eq 'false') {
1023         return 0;
1024     } else {
1025         badcfg "unknown git-check \`$how'";
1026     }
1027 }
1028
1029 sub create_remote_git_repo () {
1030     my $how = access_cfg('git-create');
1031     if ($how eq 'ssh-cmd') {
1032         runcmd_ordryrun
1033             (access_cfg_ssh, access_gituserhost(),
1034              access_runeinfo("git-create $package").
1035              "set -e; cd ".access_cfg('git-path').";".
1036              " cp -a _template $package.git");
1037     } elsif ($how eq 'true') {
1038         # nothing to do
1039     } else {
1040         badcfg "unknown git-create \`$how'";
1041     }
1042 }
1043
1044 our ($dsc_hash,$lastpush_hash);
1045
1046 our $ud = '.git/dgit/unpack';
1047
1048 sub prep_ud () {
1049     rmtree($ud);
1050     mkpath '.git/dgit';
1051     mkdir $ud or die $!;
1052 }
1053
1054 sub mktree_in_ud_here () {
1055     runcmd qw(git init -q);
1056     rmtree('.git/objects');
1057     symlink '../../../../objects','.git/objects' or die $!;
1058 }
1059
1060 sub git_write_tree () {
1061     my $tree = cmdoutput @git, qw(write-tree);
1062     $tree =~ m/^\w+$/ or die "$tree ?";
1063     return $tree;
1064 }
1065
1066 sub mktree_in_ud_from_only_subdir () {
1067     # changes into the subdir
1068     my (@dirs) = <*/.>;
1069     die unless @dirs==1;
1070     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1071     my $dir = $1;
1072     changedir $dir;
1073     fail "source package contains .git directory" if stat_exists '.git';
1074     mktree_in_ud_here();
1075     my $format=get_source_format();
1076     if (madformat($format)) {
1077         rmtree '.pc';
1078     }
1079     runcmd @git, qw(add -Af);
1080     my $tree=git_write_tree();
1081     return ($tree,$dir);
1082 }
1083
1084 sub dsc_files_info () {
1085     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1086                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1087                        ['Files',           'Digest::MD5', 'new()']) {
1088         my ($fname, $module, $method) = @$csumi;
1089         my $field = $dsc->{$fname};
1090         next unless defined $field;
1091         eval "use $module; 1;" or die $@;
1092         my @out;
1093         foreach (split /\n/, $field) {
1094             next unless m/\S/;
1095             m/^(\w+) (\d+) (\S+)$/ or
1096                 fail "could not parse .dsc $fname line \`$_'";
1097             my $digester = eval "$module"."->$method;" or die $@;
1098             push @out, {
1099                 Hash => $1,
1100                 Bytes => $2,
1101                 Filename => $3,
1102                 Digester => $digester,
1103             };
1104         }
1105         return @out;
1106     }
1107     fail "missing any supported Checksums-* or Files field in ".
1108         $dsc->get_option('name');
1109 }
1110
1111 sub dsc_files () {
1112     map { $_->{Filename} } dsc_files_info();
1113 }
1114
1115 sub is_orig_file ($;$) {
1116     local ($_) = $_[0];
1117     my $base = $_[1];
1118     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1119     defined $base or return 1;
1120     return $` eq $base;
1121 }
1122
1123 sub make_commit ($) {
1124     my ($file) = @_;
1125     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1126 }
1127
1128 sub clogp_authline ($) {
1129     my ($clogp) = @_;
1130     my $author = getfield $clogp, 'Maintainer';
1131     $author =~ s#,.*##ms;
1132     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1133     my $authline = "$author $date";
1134     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1135         fail "unexpected commit author line format \`$authline'".
1136         " (was generated from changelog Maintainer field)";
1137     return $authline;
1138 }
1139
1140 sub generate_commit_from_dsc () {
1141     prep_ud();
1142     changedir $ud;
1143
1144     foreach my $fi (dsc_files_info()) {
1145         my $f = $fi->{Filename};
1146         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1147
1148         link "../../../$f", $f
1149             or $!==&ENOENT
1150             or die "$f $!";
1151
1152         complete_file_from_dsc('.', $fi);
1153
1154         if (is_orig_file($f)) {
1155             link $f, "../../../../$f"
1156                 or $!==&EEXIST
1157                 or die "$f $!";
1158         }
1159     }
1160
1161     my $dscfn = "$package.dsc";
1162
1163     open D, ">", $dscfn or die "$dscfn: $!";
1164     print D $dscdata or die "$dscfn: $!";
1165     close D or die "$dscfn: $!";
1166     my @cmd = qw(dpkg-source);
1167     push @cmd, '--no-check' if $dsc_checked;
1168     push @cmd, qw(-x --), $dscfn;
1169     runcmd @cmd;
1170
1171     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1172     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1173     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1174     my $authline = clogp_authline $clogp;
1175     my $changes = getfield $clogp, 'Changes';
1176     open C, ">../commit.tmp" or die $!;
1177     print C <<END or die $!;
1178 tree $tree
1179 author $authline
1180 committer $authline
1181
1182 $changes
1183
1184 # imported from the archive
1185 END
1186     close C or die $!;
1187     my $outputhash = make_commit qw(../commit.tmp);
1188     my $cversion = getfield $clogp, 'Version';
1189     progress "synthesised git commit from .dsc $cversion";
1190     if ($lastpush_hash) {
1191         runcmd @git, qw(reset --hard), $lastpush_hash;
1192         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1193         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1194         my $oversion = getfield $oldclogp, 'Version';
1195         my $vcmp =
1196             version_compare($oversion, $cversion);
1197         if ($vcmp < 0) {
1198             # git upload/ is earlier vsn than archive, use archive
1199             open C, ">../commit2.tmp" or die $!;
1200             print C <<END or die $!;
1201 tree $tree
1202 parent $lastpush_hash
1203 parent $outputhash
1204 author $authline
1205 committer $authline
1206
1207 Record $package ($cversion) in archive suite $csuite
1208 END
1209             $outputhash = make_commit qw(../commit2.tmp);
1210         } elsif ($vcmp > 0) {
1211             print STDERR <<END or die $!;
1212
1213 Version actually in archive:    $cversion (older)
1214 Last allegedly pushed/uploaded: $oversion (newer or same)
1215 $later_warning_msg
1216 END
1217             $outputhash = $lastpush_hash;
1218         } else {
1219             $outputhash = $lastpush_hash;
1220         }
1221     }
1222     changedir '../../../..';
1223     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1224             'DGIT_ARCHIVE', $outputhash;
1225     cmdoutput @git, qw(log -n2), $outputhash;
1226     # ... gives git a chance to complain if our commit is malformed
1227     rmtree($ud);
1228     return $outputhash;
1229 }
1230
1231 sub complete_file_from_dsc ($$) {
1232     our ($dstdir, $fi) = @_;
1233     # Ensures that we have, in $dir, the file $fi, with the correct
1234     # contents.  (Downloading it from alongside $dscurl if necessary.)
1235
1236     my $f = $fi->{Filename};
1237     my $tf = "$dstdir/$f";
1238     my $downloaded = 0;
1239
1240     if (stat_exists $tf) {
1241         progress "using existing $f";
1242     } else {
1243         my $furl = $dscurl;
1244         $furl =~ s{/[^/]+$}{};
1245         $furl .= "/$f";
1246         die "$f ?" unless $f =~ m/^${package}_/;
1247         die "$f ?" if $f =~ m#/#;
1248         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1249         next if !act_local();
1250         $downloaded = 1;
1251     }
1252
1253     open F, "<", "$tf" or die "$tf: $!";
1254     $fi->{Digester}->reset();
1255     $fi->{Digester}->addfile(*F);
1256     F->error and die $!;
1257     my $got = $fi->{Digester}->hexdigest();
1258     $got eq $fi->{Hash} or
1259         fail "file $f has hash $got but .dsc".
1260             " demands hash $fi->{Hash} ".
1261             ($downloaded ? "(got wrong file from archive!)"
1262              : "(perhaps you should delete this file?)");
1263 }
1264
1265 sub ensure_we_have_orig () {
1266     foreach my $fi (dsc_files_info()) {
1267         my $f = $fi->{Filename};
1268         next unless is_orig_file($f);
1269         complete_file_from_dsc('..', $fi);
1270     }
1271 }
1272
1273 sub git_fetch_us () {
1274     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1275     if (deliberately_not_fast_forward) {
1276         runcmd_ordryrun_local @git, qw(fetch -p), access_giturl(),
1277             map { "+refs/$_/*:".lrfetchrefs."/$_/*" }
1278             qw(tags heads);
1279     }
1280 }
1281
1282 sub fetch_from_archive () {
1283     # ensures that lrref() is what is actually in the archive,
1284     #  one way or another
1285     get_archive_dsc();
1286
1287     if ($dsc) {
1288         foreach my $field (@ourdscfield) {
1289             $dsc_hash = $dsc->{$field};
1290             last if defined $dsc_hash;
1291         }
1292         if (defined $dsc_hash) {
1293             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1294             $dsc_hash = $&;
1295             progress "last upload to archive specified git hash";
1296         } else {
1297             progress "last upload to archive has NO git hash";
1298         }
1299     } else {
1300         progress "no version available from the archive";
1301     }
1302
1303     $lastpush_hash = git_get_ref(lrref());
1304     printdebug "previous reference hash=$lastpush_hash\n";
1305     my $hash;
1306     if (defined $dsc_hash) {
1307         fail "missing remote git history even though dsc has hash -".
1308             " could not find ref ".lrref().
1309             " (should have been fetched from ".access_giturl()."#".rrref().")"
1310             unless $lastpush_hash;
1311         $hash = $dsc_hash;
1312         ensure_we_have_orig();
1313         if ($dsc_hash eq $lastpush_hash) {
1314         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1315             print STDERR <<END or die $!;
1316
1317 Git commit in archive is behind the last version allegedly pushed/uploaded.
1318 Commit referred to by archive:  $dsc_hash
1319 Last allegedly pushed/uploaded: $lastpush_hash
1320 $later_warning_msg
1321 END
1322             $hash = $lastpush_hash;
1323         } else {
1324             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1325                 "descendant of archive's .dsc hash ($dsc_hash)";
1326         }
1327     } elsif ($dsc) {
1328         $hash = generate_commit_from_dsc();
1329     } elsif ($lastpush_hash) {
1330         # only in git, not in the archive yet
1331         $hash = $lastpush_hash;
1332         print STDERR <<END or die $!;
1333
1334 Package not found in the archive, but has allegedly been pushed using dgit.
1335 $later_warning_msg
1336 END
1337     } else {
1338         printdebug "nothing found!\n";
1339         if (defined $skew_warning_vsn) {
1340             print STDERR <<END or die $!;
1341
1342 Warning: relevant archive skew detected.
1343 Archive allegedly contains $skew_warning_vsn
1344 But we were not able to obtain any version from the archive or git.
1345
1346 END
1347         }
1348         return 0;
1349     }
1350     printdebug "current hash=$hash\n";
1351     if ($lastpush_hash) {
1352         fail "not fast forward on last upload branch!".
1353             " (archive's version left in DGIT_ARCHIVE)"
1354             unless is_fast_fwd($lastpush_hash, $hash);
1355     }
1356     if (defined $skew_warning_vsn) {
1357         mkpath '.git/dgit';
1358         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1359         my $clogf = ".git/dgit/changelog.tmp";
1360         runcmd shell_cmd "exec >$clogf",
1361             @git, qw(cat-file blob), "$hash:debian/changelog";
1362         my $gotclogp = parsechangelog("-l$clogf");
1363         my $got_vsn = getfield $gotclogp, 'Version';
1364         printdebug "SKEW CHECK GOT $got_vsn\n";
1365         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1366             print STDERR <<END or die $!;
1367
1368 Warning: archive skew detected.  Using the available version:
1369 Archive allegedly contains    $skew_warning_vsn
1370 We were able to obtain only   $got_vsn
1371
1372 END
1373         }
1374     }
1375     if ($lastpush_hash ne $hash) {
1376         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1377         if (act_local()) {
1378             cmdoutput @upd_cmd;
1379         } else {
1380             dryrun_report @upd_cmd;
1381         }
1382     }
1383     return 1;
1384 }
1385
1386 sub clone ($) {
1387     my ($dstdir) = @_;
1388     canonicalise_suite();
1389     badusage "dry run makes no sense with clone" unless act_local();
1390     my $hasgit = check_for_git();
1391     mkdir $dstdir or die "$dstdir $!";
1392     changedir $dstdir;
1393     runcmd @git, qw(init -q);
1394     my $giturl = access_giturl(1);
1395     if (defined $giturl) {
1396         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1397         open H, "> .git/HEAD" or die $!;
1398         print H "ref: ".lref()."\n" or die $!;
1399         close H or die $!;
1400         runcmd @git, qw(remote add), 'origin', $giturl;
1401     }
1402     if ($hasgit) {
1403         progress "fetching existing git history";
1404         git_fetch_us();
1405         runcmd_ordryrun_local @git, qw(fetch origin);
1406     } else {
1407         progress "starting new git history";
1408     }
1409     fetch_from_archive() or no_such_package;
1410     my $vcsgiturl = $dsc->{'Vcs-Git'};
1411     if (length $vcsgiturl) {
1412         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1413         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1414     }
1415     runcmd @git, qw(reset --hard), lrref();
1416     printdone "ready for work in $dstdir";
1417 }
1418
1419 sub fetch () {
1420     if (check_for_git()) {
1421         git_fetch_us();
1422     }
1423     fetch_from_archive() or no_such_package();
1424     printdone "fetched into ".lrref();
1425 }
1426
1427 sub pull () {
1428     fetch();
1429     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1430         lrref();
1431     printdone "fetched to ".lrref()." and merged into HEAD";
1432 }
1433
1434 sub check_not_dirty () {
1435     return if $ignoredirty;
1436     my @cmd = (@git, qw(diff --quiet HEAD));
1437     debugcmd "+",@cmd;
1438     $!=0; $?=0; system @cmd;
1439     return if !$! && !$?;
1440     if (!$! && $?==256) {
1441         fail "working tree is dirty (does not match HEAD)";
1442     } else {
1443         failedcmd @cmd;
1444     }
1445 }
1446
1447 sub commit_admin ($) {
1448     my ($m) = @_;
1449     progress "$m";
1450     runcmd_ordryrun_local @git, qw(commit -m), $m;
1451 }
1452
1453 sub commit_quilty_patch () {
1454     my $output = cmdoutput @git, qw(status --porcelain);
1455     my %adds;
1456     foreach my $l (split /\n/, $output) {
1457         next unless $l =~ m/\S/;
1458         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1459             $adds{$1}++;
1460         }
1461     }
1462     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1463     if (!%adds) {
1464         progress "nothing quilty to commit, ok.";
1465         return;
1466     }
1467     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1468     commit_admin "Commit Debian 3.0 (quilt) metadata";
1469 }
1470
1471 sub get_source_format () {
1472     if (!open F, "debian/source/format") {
1473         die $! unless $!==&ENOENT;
1474         return '';
1475     }
1476     $_ = <F>;
1477     F->error and die $!;
1478     chomp;
1479     return $_;
1480 }
1481
1482 sub madformat ($) {
1483     my ($format) = @_;
1484     return 0 unless $format eq '3.0 (quilt)';
1485     if ($quilt_mode eq 'nocheck') {
1486         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1487         return 0;
1488     }
1489     progress "Format \`$format', checking/updating patch stack";
1490     return 1;
1491 }
1492
1493 sub push_parse_changelog ($) {
1494     my ($clogpfn) = @_;
1495
1496     my $clogp = Dpkg::Control::Hash->new();
1497     $clogp->load($clogpfn) or die;
1498
1499     $package = getfield $clogp, 'Source';
1500     my $cversion = getfield $clogp, 'Version';
1501     my $tag = debiantag($cversion);
1502     runcmd @git, qw(check-ref-format), $tag;
1503
1504     my $dscfn = dscfn($cversion);
1505
1506     return ($clogp, $cversion, $tag, $dscfn);
1507 }
1508
1509 sub push_parse_dsc ($$$) {
1510     my ($dscfn,$dscfnwhat, $cversion) = @_;
1511     $dsc = parsecontrol($dscfn,$dscfnwhat);
1512     my $dversion = getfield $dsc, 'Version';
1513     my $dscpackage = getfield $dsc, 'Source';
1514     ($dscpackage eq $package && $dversion eq $cversion) or
1515         fail "$dscfn is for $dscpackage $dversion".
1516             " but debian/changelog is for $package $cversion";
1517 }
1518
1519 sub push_mktag ($$$$$$$) {
1520     my ($head,$clogp,$tag,
1521         $dscfn,
1522         $changesfile,$changesfilewhat,
1523         $tfn) = @_;
1524
1525     $dsc->{$ourdscfield[0]} = $head;
1526     $dsc->save("$dscfn.tmp") or die $!;
1527
1528     my $changes = parsecontrol($changesfile,$changesfilewhat);
1529     foreach my $field (qw(Source Distribution Version)) {
1530         $changes->{$field} eq $clogp->{$field} or
1531             fail "changes field $field \`$changes->{$field}'".
1532                 " does not match changelog \`$clogp->{$field}'";
1533     }
1534
1535     my $cversion = getfield $clogp, 'Version';
1536     my $clogsuite = getfield $clogp, 'Distribution';
1537
1538     # We make the git tag by hand because (a) that makes it easier
1539     # to control the "tagger" (b) we can do remote signing
1540     my $authline = clogp_authline $clogp;
1541     my $delibs = join(" ", "",@deliberatelies);
1542     my $declaredistro = access_basedistro();
1543     open TO, '>', $tfn->('.tmp') or die $!;
1544     print TO <<END or die $!;
1545 object $head
1546 type commit
1547 tag $tag
1548 tagger $authline
1549
1550 $package release $cversion for $clogsuite ($csuite) [dgit]
1551 [dgit distro=$declaredistro$delibs]
1552 END
1553     foreach my $ref (sort keys %previously) {
1554                     print TO <<END or die $!;
1555 [dgit previously:$ref=$previously{$ref}]
1556 END
1557     }
1558
1559     close TO or die $!;
1560
1561     my $tagobjfn = $tfn->('.tmp');
1562     if ($sign) {
1563         if (!defined $keyid) {
1564             $keyid = access_cfg('keyid','RETURN-UNDEF');
1565         }
1566         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1567         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1568         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1569         push @sign_cmd, $tfn->('.tmp');
1570         runcmd_ordryrun @sign_cmd;
1571         if (act_scary()) {
1572             $tagobjfn = $tfn->('.signed.tmp');
1573             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1574                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1575         }
1576     }
1577
1578     return ($tagobjfn);
1579 }
1580
1581 sub sign_changes ($) {
1582     my ($changesfile) = @_;
1583     if ($sign) {
1584         my @debsign_cmd = @debsign;
1585         push @debsign_cmd, "-k$keyid" if defined $keyid;
1586         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1587         push @debsign_cmd, $changesfile;
1588         runcmd_ordryrun @debsign_cmd;
1589     }
1590 }
1591
1592 sub dopush ($) {
1593     my ($forceflag) = @_;
1594     printdebug "actually entering push\n";
1595     prep_ud();
1596
1597     access_giturl(); # check that success is vaguely likely
1598
1599     my $clogpfn = ".git/dgit/changelog.822.tmp";
1600     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1601
1602     responder_send_file('parsed-changelog', $clogpfn);
1603
1604     my ($clogp, $cversion, $tag, $dscfn) =
1605         push_parse_changelog("$clogpfn");
1606
1607     my $dscpath = "$buildproductsdir/$dscfn";
1608     stat_exists $dscpath or
1609         fail "looked for .dsc $dscfn, but $!;".
1610             " maybe you forgot to build";
1611
1612     responder_send_file('dsc', $dscpath);
1613
1614     push_parse_dsc($dscpath, $dscfn, $cversion);
1615
1616     my $format = getfield $dsc, 'Format';
1617     printdebug "format $format\n";
1618     if (madformat($format)) {
1619         commit_quilty_patch();
1620     }
1621     check_not_dirty();
1622     changedir $ud;
1623     progress "checking that $dscfn corresponds to HEAD";
1624     runcmd qw(dpkg-source -x --),
1625         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1626     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1627     changedir '../../../..';
1628     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1629     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1630     debugcmd "+",@diffcmd;
1631     $!=0; $?=0;
1632     my $r = system @diffcmd;
1633     if ($r) {
1634         if ($r==256) {
1635             fail "$dscfn specifies a different tree to your HEAD commit;".
1636                 " perhaps you forgot to build".
1637                 ($diffopt eq '--exit-code' ? "" :
1638                  " (run with -D to see full diff output)");
1639         } else {
1640             failedcmd @diffcmd;
1641         }
1642     }
1643 #fetch from alioth
1644 #do fast forward check and maybe fake merge
1645 #    if (!is_fast_fwd(mainbranch
1646 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1647 #        map { lref($_).":".rref($_) }
1648 #        (uploadbranch());
1649     my $head = git_rev_parse('HEAD');
1650     if (!$changesfile) {
1651         my $multi = "$buildproductsdir/".
1652             "${package}_".(stripepoch $cversion)."_multi.changes";
1653         if (stat_exists "$multi") {
1654             $changesfile = $multi;
1655         } else {
1656             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1657             my @cs = glob "$buildproductsdir/$pat";
1658             fail "failed to find unique changes file".
1659                 " (looked for $pat in $buildproductsdir, or $multi);".
1660                 " perhaps you need to use dgit -C"
1661                 unless @cs==1;
1662             ($changesfile) = @cs;
1663         }
1664     } else {
1665         $changesfile = "$buildproductsdir/$changesfile";
1666     }
1667
1668     responder_send_file('changes',$changesfile);
1669     responder_send_command("param head $head");
1670     responder_send_command("param csuite $csuite");
1671
1672     if (deliberately_not_fast_forward) {
1673         git_for_each_ref(lrfetchrefs, sub {
1674             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
1675             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
1676             responder_send_command("previously $rrefname=$objid");
1677             $previously{$rrefname} = $objid;
1678         });
1679     }
1680
1681     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1682     my $tagobjfn;
1683
1684     if ($we_are_responder) {
1685         $tagobjfn = $tfn->('.signed.tmp');
1686         responder_receive_files('signed-tag', $tagobjfn);
1687     } else {
1688         $tagobjfn =
1689             push_mktag($head,$clogp,$tag,
1690                        $dscpath,
1691                        $changesfile,$changesfile,
1692                        $tfn);
1693     }
1694
1695     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1696     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1697     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1698     runcmd_ordryrun @git, qw(tag -v --), $tag;
1699
1700     if (!check_for_git()) {
1701         create_remote_git_repo();
1702     }
1703     runcmd_ordryrun @git, qw(push),access_giturl(),
1704         $forceflag."HEAD:".rrref(), $forceflag."refs/tags/$tag";
1705     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1706
1707     if ($we_are_responder) {
1708         my $dryrunsuffix = act_local() ? "" : ".tmp";
1709         responder_receive_files('signed-dsc-changes',
1710                                 "$dscpath$dryrunsuffix",
1711                                 "$changesfile$dryrunsuffix");
1712     } else {
1713         if (act_local()) {
1714             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1715         } else {
1716             progress "[new .dsc left in $dscpath.tmp]";
1717         }
1718         sign_changes $changesfile;
1719     }
1720
1721     my $host = access_cfg('upload-host','RETURN-UNDEF');
1722     my @hostarg = defined($host) ? ($host,) : ();
1723     runcmd_ordryrun @dput, @hostarg, $changesfile;
1724     printdone "pushed and uploaded $cversion";
1725
1726     responder_send_command("complete");
1727 }
1728
1729 sub cmd_clone {
1730     parseopts();
1731     my $dstdir;
1732     badusage "-p is not allowed with clone; specify as argument instead"
1733         if defined $package;
1734     if (@ARGV==1) {
1735         ($package) = @ARGV;
1736     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1737         ($package,$isuite) = @ARGV;
1738     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1739         ($package,$dstdir) = @ARGV;
1740     } elsif (@ARGV==3) {
1741         ($package,$isuite,$dstdir) = @ARGV;
1742     } else {
1743         badusage "incorrect arguments to dgit clone";
1744     }
1745     $dstdir ||= "$package";
1746
1747     if (stat_exists $dstdir) {
1748         fail "$dstdir already exists";
1749     }
1750
1751     my $cwd_remove;
1752     if ($rmonerror && !$dryrun_level) {
1753         $cwd_remove= getcwd();
1754         unshift @end, sub {
1755             return unless defined $cwd_remove;
1756             if (!chdir "$cwd_remove") {
1757                 return if $!==&ENOENT;
1758                 die "chdir $cwd_remove: $!";
1759             }
1760             rmtree($dstdir) or die "remove $dstdir: $!\n";
1761         };
1762     }
1763
1764     clone($dstdir);
1765     $cwd_remove = undef;
1766 }
1767
1768 sub branchsuite () {
1769     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1770     if ($branch =~ m#$lbranch_re#o) {
1771         return $1;
1772     } else {
1773         return undef;
1774     }
1775 }
1776
1777 sub fetchpullargs () {
1778     if (!defined $package) {
1779         my $sourcep = parsecontrol('debian/control','debian/control');
1780         $package = getfield $sourcep, 'Source';
1781     }
1782     if (@ARGV==0) {
1783 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1784         if (!$isuite) {
1785             my $clogp = parsechangelog();
1786             $isuite = getfield $clogp, 'Distribution';
1787         }
1788         canonicalise_suite();
1789         progress "fetching from suite $csuite";
1790     } elsif (@ARGV==1) {
1791         ($isuite) = @ARGV;
1792         canonicalise_suite();
1793     } else {
1794         badusage "incorrect arguments to dgit fetch or dgit pull";
1795     }
1796 }
1797
1798 sub cmd_fetch {
1799     parseopts();
1800     fetchpullargs();
1801     fetch();
1802 }
1803
1804 sub cmd_pull {
1805     parseopts();
1806     fetchpullargs();
1807     pull();
1808 }
1809
1810 sub cmd_push {
1811     parseopts();
1812     badusage "-p is not allowed with dgit push" if defined $package;
1813     check_not_dirty();
1814     my $clogp = parsechangelog();
1815     $package = getfield $clogp, 'Source';
1816     my $specsuite;
1817     if (@ARGV==0) {
1818     } elsif (@ARGV==1) {
1819         ($specsuite) = (@ARGV);
1820     } else {
1821         badusage "incorrect arguments to dgit push";
1822     }
1823     $isuite = getfield $clogp, 'Distribution';
1824     if ($new_package) {
1825         local ($package) = $existing_package; # this is a hack
1826         canonicalise_suite();
1827     }
1828     if (defined $specsuite && $specsuite ne $isuite) {
1829         canonicalise_suite();
1830         $csuite eq $specsuite or
1831             fail "dgit push: changelog specifies $isuite ($csuite)".
1832                 " but command line specifies $specsuite";
1833     }
1834     if (check_for_git()) {
1835         git_fetch_us();
1836     }
1837     my $forceflag = '';
1838     if (fetch_from_archive()) {
1839         if (is_fast_fwd(lrref(), 'HEAD')) {
1840             # ok
1841         } elsif (deliberately_not_fast_forward) {
1842             $forceflag = '+';
1843         } else {
1844             fail "dgit push: HEAD is not a descendant".
1845                 " of the archive's version.\n".
1846                 "dgit: To overwrite its contents,".
1847                 " use git merge -s ours ".lrref().".\n".
1848                 "dgit: To rewind history, if permitted by the archive,".
1849                 " use --deliberately-not-fast-forward";
1850         }
1851     } else {
1852         $new_package or
1853             fail "package appears to be new in this suite;".
1854                 " if this is intentional, use --new";
1855     }
1856     dopush($forceflag);
1857 }
1858
1859 #---------- remote commands' implementation ----------
1860
1861 sub cmd_remote_push_build_host {
1862     my ($nrargs) = shift @ARGV;
1863     my (@rargs) = @ARGV[0..$nrargs-1];
1864     @ARGV = @ARGV[$nrargs..$#ARGV];
1865     die unless @rargs;
1866     my ($dir,$vsnwant) = @rargs;
1867     # vsnwant is a comma-separated list; we report which we have
1868     # chosen in our ready response (so other end can tell if they
1869     # offered several)
1870     $debugprefix = ' ';
1871     $we_are_responder = 1;
1872     $us .= " (build host)";
1873
1874     open PI, "<&STDIN" or die $!;
1875     open STDIN, "/dev/null" or die $!;
1876     open PO, ">&STDOUT" or die $!;
1877     autoflush PO 1;
1878     open STDOUT, ">&STDERR" or die $!;
1879     autoflush STDOUT 1;
1880
1881     $vsnwant //= 1;
1882     fail "build host has dgit rpush protocol version".
1883         " $rpushprotovsn but invocation host has $vsnwant"
1884         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1885
1886     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1887
1888     changedir $dir;
1889     &cmd_push;
1890 }
1891
1892 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1893 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1894 #     a good error message)
1895
1896 our $i_tmp;
1897
1898 sub i_cleanup {
1899     local ($@, $?);
1900     my $report = i_child_report();
1901     if (defined $report) {
1902         printdebug "($report)\n";
1903     } elsif ($i_child_pid) {
1904         printdebug "(killing build host child $i_child_pid)\n";
1905         kill 15, $i_child_pid;
1906     }
1907     if (defined $i_tmp && !defined $initiator_tempdir) {
1908         changedir "/";
1909         eval { rmtree $i_tmp; };
1910     }
1911 }
1912
1913 END { i_cleanup(); }
1914
1915 sub i_method {
1916     my ($base,$selector,@args) = @_;
1917     $selector =~ s/\-/_/g;
1918     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1919 }
1920
1921 sub cmd_rpush {
1922     my $host = nextarg;
1923     my $dir;
1924     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1925         $host = $1;
1926         $dir = $'; #';
1927     } else {
1928         $dir = nextarg;
1929     }
1930     $dir =~ s{^-}{./-};
1931     my @rargs = ($dir,$rpushprotovsn);
1932     my @rdgit;
1933     push @rdgit, @dgit;
1934     push @rdgit, @ropts;
1935     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1936     push @rdgit, @ARGV;
1937     my @cmd = (@ssh, $host, shellquote @rdgit);
1938     debugcmd "+",@cmd;
1939
1940     if (defined $initiator_tempdir) {
1941         rmtree $initiator_tempdir;
1942         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1943         $i_tmp = $initiator_tempdir;
1944     } else {
1945         $i_tmp = tempdir();
1946     }
1947     $i_child_pid = open2(\*RO, \*RI, @cmd);
1948     changedir $i_tmp;
1949     initiator_expect { m/^dgit-remote-push-ready/ };
1950     for (;;) {
1951         my ($icmd,$iargs) = initiator_expect {
1952             m/^(\S+)(?: (.*))?$/;
1953             ($1,$2);
1954         };
1955         i_method "i_resp", $icmd, $iargs;
1956     }
1957 }
1958
1959 sub i_resp_progress ($) {
1960     my ($rhs) = @_;
1961     my $msg = protocol_read_bytes \*RO, $rhs;
1962     progress $msg;
1963 }
1964
1965 sub i_resp_complete {
1966     my $pid = $i_child_pid;
1967     $i_child_pid = undef; # prevents killing some other process with same pid
1968     printdebug "waiting for build host child $pid...\n";
1969     my $got = waitpid $pid, 0;
1970     die $! unless $got == $pid;
1971     die "build host child failed $?" if $?;
1972
1973     i_cleanup();
1974     printdebug "all done\n";
1975     exit 0;
1976 }
1977
1978 sub i_resp_file ($) {
1979     my ($keyword) = @_;
1980     my $localname = i_method "i_localname", $keyword;
1981     my $localpath = "$i_tmp/$localname";
1982     stat_exists $localpath and
1983         badproto \*RO, "file $keyword ($localpath) twice";
1984     protocol_receive_file \*RO, $localpath;
1985     i_method "i_file", $keyword;
1986 }
1987
1988 our %i_param;
1989
1990 sub i_resp_param ($) {
1991     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1992     $i_param{$1} = $2;
1993 }
1994
1995 sub i_resp_previously ($) {
1996     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
1997         or badproto \*RO, "bad previously spec";
1998     my $r = system qw(git check-ref-format), $1;
1999     die "bad previously ref spec ($r)" if $r;
2000     $previously{$1} = $2;
2001 }
2002
2003 our %i_wanted;
2004
2005 sub i_resp_want ($) {
2006     my ($keyword) = @_;
2007     die "$keyword ?" if $i_wanted{$keyword}++;
2008     my @localpaths = i_method "i_want", $keyword;
2009     printdebug "[[  $keyword @localpaths\n";
2010     foreach my $localpath (@localpaths) {
2011         protocol_send_file \*RI, $localpath;
2012     }
2013     print RI "files-end\n" or die $!;
2014 }
2015
2016 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2017
2018 sub i_localname_parsed_changelog {
2019     return "remote-changelog.822";
2020 }
2021 sub i_file_parsed_changelog {
2022     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2023         push_parse_changelog "$i_tmp/remote-changelog.822";
2024     die if $i_dscfn =~ m#/|^\W#;
2025 }
2026
2027 sub i_localname_dsc {
2028     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2029     return $i_dscfn;
2030 }
2031 sub i_file_dsc { }
2032
2033 sub i_localname_changes {
2034     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2035     $i_changesfn = $i_dscfn;
2036     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2037     return $i_changesfn;
2038 }
2039 sub i_file_changes { }
2040
2041 sub i_want_signed_tag {
2042     printdebug Dumper(\%i_param, $i_dscfn);
2043     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2044         && defined $i_param{'csuite'}
2045         or badproto \*RO, "premature desire for signed-tag";
2046     my $head = $i_param{'head'};
2047     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2048
2049     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2050     $csuite = $&;
2051     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2052
2053     my $tagobjfn =
2054         push_mktag $head, $i_clogp, $i_tag,
2055             $i_dscfn,
2056             $i_changesfn, 'remote changes',
2057             sub { "tag$_[0]"; };
2058
2059     return $tagobjfn;
2060 }
2061
2062 sub i_want_signed_dsc_changes {
2063     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2064     sign_changes $i_changesfn;
2065     return ($i_dscfn, $i_changesfn);
2066 }
2067
2068 #---------- building etc. ----------
2069
2070 our $version;
2071 our $sourcechanges;
2072 our $dscfn;
2073
2074 #----- `3.0 (quilt)' handling -----
2075
2076 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2077
2078 sub quiltify_dpkg_commit ($$$;$) {
2079     my ($patchname,$author,$msg, $xinfo) = @_;
2080     $xinfo //= '';
2081
2082     mkpath '.git/dgit';
2083     my $descfn = ".git/dgit/quilt-description.tmp";
2084     open O, '>', $descfn or die "$descfn: $!";
2085     $msg =~ s/\s+$//g;
2086     $msg =~ s/\n/\n /g;
2087     $msg =~ s/^\s+$/ ./mg;
2088     print O <<END or die $!;
2089 Description: $msg
2090 Author: $author
2091 $xinfo
2092 ---
2093
2094 END
2095     close O or die $!;
2096
2097     {
2098         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2099         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2100         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2101         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2102     }
2103 }
2104
2105 sub quiltify_trees_differ ($$) {
2106     my ($x,$y) = @_;
2107     # returns 1 iff the two tree objects differ other than in debian/
2108     local $/=undef;
2109     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2110     my $diffs= cmdoutput @cmd;
2111     foreach my $f (split /\0/, $diffs) {
2112         next if $f eq 'debian';
2113         return 1;
2114     }
2115     return 0;
2116 }
2117
2118 sub quiltify_tree_sentinelfiles ($) {
2119     # lists the `sentinel' files present in the tree
2120     my ($x) = @_;
2121     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2122         qw(-- debian/rules debian/control);
2123     $r =~ s/\n/,/g;
2124     return $r;
2125 }
2126
2127 sub quiltify ($$) {
2128     my ($clogp,$target) = @_;
2129
2130     # Quilt patchification algorithm
2131     #
2132     # We search backwards through the history of the main tree's HEAD
2133     # (T) looking for a start commit S whose tree object is identical
2134     # to to the patch tip tree (ie the tree corresponding to the
2135     # current dpkg-committed patch series).  For these purposes
2136     # `identical' disregards anything in debian/ - this wrinkle is
2137     # necessary because dpkg-source treates debian/ specially.
2138     #
2139     # We can only traverse edges where at most one of the ancestors'
2140     # trees differs (in changes outside in debian/).  And we cannot
2141     # handle edges which change .pc/ or debian/patches.  To avoid
2142     # going down a rathole we avoid traversing edges which introduce
2143     # debian/rules or debian/control.  And we set a limit on the
2144     # number of edges we are willing to look at.
2145     #
2146     # If we succeed, we walk forwards again.  For each traversed edge
2147     # PC (with P parent, C child) (starting with P=S and ending with
2148     # C=T) to we do this:
2149     #  - git checkout C
2150     #  - dpkg-source --commit with a patch name and message derived from C
2151     # After traversing PT, we git commit the changes which
2152     # should be contained within debian/patches.
2153
2154     changedir '../fake';
2155     mktree_in_ud_here();
2156     rmtree '.pc';
2157     runcmd @git, 'add', '.';
2158     my $oldtiptree=git_write_tree();
2159     changedir '../work';
2160
2161     # The search for the path S..T is breadth-first.  We maintain a
2162     # todo list containing search nodes.  A search node identifies a
2163     # commit, and looks something like this:
2164     #  $p = {
2165     #      Commit => $git_commit_id,
2166     #      Child => $c,                          # or undef if P=T
2167     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2168     #      Nontrivial => true iff $p..$c has relevant changes
2169     #  };
2170
2171     my @todo;
2172     my @nots;
2173     my $sref_S;
2174     my $max_work=100;
2175     my %considered; # saves being exponential on some weird graphs
2176
2177     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2178
2179     my $not = sub {
2180         my ($search,$whynot) = @_;
2181         printdebug " search NOT $search->{Commit} $whynot\n";
2182         $search->{Whynot} = $whynot;
2183         push @nots, $search;
2184         no warnings qw(exiting);
2185         next;
2186     };
2187
2188     push @todo, {
2189         Commit => $target,
2190     };
2191
2192     while (@todo) {
2193         my $c = shift @todo;
2194         next if $considered{$c->{Commit}}++;
2195
2196         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2197
2198         printdebug "quiltify investigate $c->{Commit}\n";
2199
2200         # are we done?
2201         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2202             printdebug " search finished hooray!\n";
2203             $sref_S = $c;
2204             last;
2205         }
2206
2207         if ($quilt_mode eq 'nofix') {
2208             fail "quilt fixup required but quilt mode is \`nofix'\n".
2209                 "HEAD commit $c->{Commit} differs from tree implied by ".
2210                 " debian/patches (tree object $oldtiptree)";
2211         }
2212         if ($quilt_mode eq 'smash') {
2213             printdebug " search quitting smash\n";
2214             last;
2215         }
2216
2217         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2218         $not->($c, "has $c_sentinels not $t_sentinels")
2219             if $c_sentinels ne $t_sentinels;
2220
2221         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2222         $commitdata =~ m/\n\n/;
2223         $commitdata =~ $`;
2224         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2225         @parents = map { { Commit => $_, Child => $c } } @parents;
2226
2227         $not->($c, "root commit") if !@parents;
2228
2229         foreach my $p (@parents) {
2230             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2231         }
2232         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2233         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2234
2235         foreach my $p (@parents) {
2236             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2237
2238             my @cmd= (@git, qw(diff-tree -r --name-only),
2239                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2240             my $patchstackchange = cmdoutput @cmd;
2241             if (length $patchstackchange) {
2242                 $patchstackchange =~ s/\n/,/g;
2243                 $not->($p, "changed $patchstackchange");
2244             }
2245
2246             printdebug " search queue P=$p->{Commit} ",
2247                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2248             push @todo, $p;
2249         }
2250     }
2251
2252     if (!$sref_S) {
2253         printdebug "quiltify want to smash\n";
2254
2255         my $abbrev = sub {
2256             my $x = $_[0]{Commit};
2257             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2258             return $;
2259         };
2260         my $reportnot = sub {
2261             my ($notp) = @_;
2262             my $s = $abbrev->($notp);
2263             my $c = $notp->{Child};
2264             $s .= "..".$abbrev->($c) if $c;
2265             $s .= ": ".$c->{Whynot};
2266             return $s;
2267         };
2268         if ($quilt_mode eq 'linear') {
2269             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2270             foreach my $notp (@nots) {
2271                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2272             }
2273             fail "quilt fixup naive history linearisation failed.\n".
2274  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2275         } elsif ($quilt_mode eq 'smash') {
2276         } elsif ($quilt_mode eq 'auto') {
2277             progress "quilt fixup cannot be linear, smashing...";
2278         } else {
2279             die "$quilt_mode ?";
2280         }
2281
2282         my $time = time;
2283         my $ncommits = 3;
2284         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2285
2286         quiltify_dpkg_commit "auto-$version-$target-$time",
2287             (getfield $clogp, 'Maintainer'),
2288             "Automatically generated patch ($clogp->{Version})\n".
2289             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2290         return;
2291     }
2292
2293     progress "quiltify linearisation planning successful, executing...";
2294
2295     for (my $p = $sref_S;
2296          my $c = $p->{Child};
2297          $p = $p->{Child}) {
2298         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2299         next unless $p->{Nontrivial};
2300
2301         my $cc = $c->{Commit};
2302
2303         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2304         $commitdata =~ m/\n\n/ or die "$c ?";
2305         $commitdata = $`;
2306         my $msg = $'; #';
2307         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2308         my $author = $1;
2309
2310         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2311
2312         my $title = $1;
2313         my $patchname = $title;
2314         $patchname =~ s/[.:]$//;
2315         $patchname =~ y/ A-Z/-a-z/;
2316         $patchname =~ y/-a-z0-9_.+=~//cd;
2317         $patchname =~ s/^\W/x-$&/;
2318         $patchname = substr($patchname,0,40);
2319         my $index;
2320         for ($index='';
2321              stat "debian/patches/$patchname$index";
2322              $index++) { }
2323         $!==ENOENT or die "$patchname$index $!";
2324
2325         runcmd @git, qw(checkout -q), $cc;
2326
2327         # We use the tip's changelog so that dpkg-source doesn't
2328         # produce complaining messages from dpkg-parsechangelog.  None
2329         # of the information dpkg-source gets from the changelog is
2330         # actually relevant - it gets put into the original message
2331         # which dpkg-source provides our stunt editor, and then
2332         # overwritten.
2333         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2334
2335         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2336             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2337
2338         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2339     }
2340
2341     runcmd @git, qw(checkout -q master);
2342 }
2343
2344 sub build_maybe_quilt_fixup () {
2345     my $format=get_source_format;
2346     return unless madformat $format;
2347     # sigh
2348
2349     # Our objective is:
2350     #  - honour any existing .pc in case it has any strangeness
2351     #  - determine the git commit corresponding to the tip of
2352     #    the patch stack (if there is one)
2353     #  - if there is such a git commit, convert each subsequent
2354     #    git commit into a quilt patch with dpkg-source --commit
2355     #  - otherwise convert all the differences in the tree into
2356     #    a single git commit
2357     #
2358     # To do this we:
2359
2360     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2361     # dgit would include the .pc in the git tree.)  If there isn't
2362     # one, we need to generate one by unpacking the patches that we
2363     # have.
2364     #
2365     # We first look for a .pc in the git tree.  If there is one, we
2366     # will use it.  (This is not the normal case.)
2367     #
2368     # Otherwise need to regenerate .pc so that dpkg-source --commit
2369     # can work.  We do this as follows:
2370     #     1. Collect all relevant .orig from parent directory
2371     #     2. Generate a debian.tar.gz out of
2372     #         debian/{patches,rules,source/format}
2373     #     3. Generate a fake .dsc containing just these fields:
2374     #          Format Source Version Files
2375     #     4. Extract the fake .dsc
2376     #        Now the fake .dsc has a .pc directory.
2377     # (In fact we do this in every case, because in future we will
2378     # want to search for a good base commit for generating patches.)
2379     #
2380     # Then we can actually do the dpkg-source --commit
2381     #     1. Make a new working tree with the same object
2382     #        store as our main tree and check out the main
2383     #        tree's HEAD.
2384     #     2. Copy .pc from the fake's extraction, if necessary
2385     #     3. Run dpkg-source --commit
2386     #     4. If the result has changes to debian/, then
2387     #          - git-add them them
2388     #          - git-add .pc if we had a .pc in-tree
2389     #          - git-commit
2390     #     5. If we had a .pc in-tree, delete it, and git-commit
2391     #     6. Back in the main tree, fast forward to the new HEAD
2392
2393     my $clogp = parsechangelog();
2394     my $headref = git_rev_parse('HEAD');
2395
2396     prep_ud();
2397     changedir $ud;
2398
2399     my $upstreamversion=$version;
2400     $upstreamversion =~ s/-[^-]*$//;
2401
2402     my $fakeversion="$upstreamversion-~~DGITFAKE";
2403
2404     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2405     print $fakedsc <<END or die $!;
2406 Format: 3.0 (quilt)
2407 Source: $package
2408 Version: $fakeversion
2409 Files:
2410 END
2411
2412     my $dscaddfile=sub {
2413         my ($b) = @_;
2414
2415         my $md = new Digest::MD5;
2416
2417         my $fh = new IO::File $b, '<' or die "$b $!";
2418         stat $fh or die $!;
2419         my $size = -s _;
2420
2421         $md->addfile($fh);
2422         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2423     };
2424
2425     foreach my $f (<../../../../*>) { #/){
2426         my $b=$f; $b =~ s{.*/}{};
2427         next unless is_orig_file $b, srcfn $upstreamversion,'';
2428         link $f, $b or die "$b $!";
2429         $dscaddfile->($b);
2430     }
2431
2432     my @files=qw(debian/source/format debian/rules);
2433     if (stat_exists '../../../debian/patches') {
2434         push @files, 'debian/patches';
2435     }
2436
2437     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2438     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2439
2440     $dscaddfile->($debtar);
2441     close $fakedsc or die $!;
2442
2443     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2444
2445     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2446     rename $fakexdir, "fake" or die "$fakexdir $!";
2447
2448     mkdir "work" or die $!;
2449     changedir "work";
2450     mktree_in_ud_here();
2451     runcmd @git, qw(reset --hard), $headref;
2452
2453     my $mustdeletepc=0;
2454     if (stat_exists ".pc") {
2455         -d _ or die;
2456         progress "Tree already contains .pc - will use it then delete it.";
2457         $mustdeletepc=1;
2458     } else {
2459         rename '../fake/.pc','.pc' or die $!;
2460     }
2461
2462     quiltify($clogp,$headref);
2463
2464     if (!open P, '>>', ".pc/applied-patches") {
2465         $!==&ENOENT or die $!;
2466     } else {
2467         close P;
2468     }
2469
2470     commit_quilty_patch();
2471
2472     if ($mustdeletepc) {
2473         runcmd @git, qw(rm -rq .pc);
2474         commit_admin "Commit removal of .pc (quilt series tracking data)";
2475     }
2476
2477     changedir '../../../..';
2478     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2479 }
2480
2481 sub quilt_fixup_editor () {
2482     my $descfn = $ENV{$fakeeditorenv};
2483     my $editing = $ARGV[$#ARGV];
2484     open I1, '<', $descfn or die "$descfn: $!";
2485     open I2, '<', $editing or die "$editing: $!";
2486     unlink $editing or die "$editing: $!";
2487     open O, '>', $editing or die "$editing: $!";
2488     while (<I1>) { print O or die $!; } I1->error and die $!;
2489     my $copying = 0;
2490     while (<I2>) {
2491         $copying ||= m/^\-\-\- /;
2492         next unless $copying;
2493         print O or die $!;
2494     }
2495     I2->error and die $!;
2496     close O or die $1;
2497     exit 0;
2498 }
2499
2500 #----- other building -----
2501
2502 sub clean_tree () {
2503     if ($cleanmode eq 'dpkg-source') {
2504         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2505     } elsif ($cleanmode eq 'git') {
2506         runcmd_ordryrun_local @git, qw(clean -xdf);
2507     } elsif ($cleanmode eq 'none') {
2508     } else {
2509         die "$cleanmode ?";
2510     }
2511 }
2512
2513 sub cmd_clean () {
2514     badusage "clean takes no additional arguments" if @ARGV;
2515     clean_tree();
2516 }
2517
2518 sub build_prep () {
2519     badusage "-p is not allowed when building" if defined $package;
2520     check_not_dirty();
2521     clean_tree();
2522     my $clogp = parsechangelog();
2523     $isuite = getfield $clogp, 'Distribution';
2524     $package = getfield $clogp, 'Source';
2525     $version = getfield $clogp, 'Version';
2526     build_maybe_quilt_fixup();
2527 }
2528
2529 sub changesopts () {
2530     my @opts =@changesopts[1..$#changesopts];
2531     if (!defined $changes_since_version) {
2532         my @vsns = archive_query('archive_query');
2533         my @quirk = access_quirk();
2534         if ($quirk[0] eq 'backports') {
2535             local $isuite = $quirk[2];
2536             local $csuite;
2537             canonicalise_suite();
2538             push @vsns, archive_query('archive_query');
2539         }
2540         if (@vsns) {
2541             @vsns = map { $_->[0] } @vsns;
2542             @vsns = sort { -version_compare($a, $b) } @vsns;
2543             $changes_since_version = $vsns[0];
2544             progress "changelog will contain changes since $vsns[0]";
2545         } else {
2546             $changes_since_version = '_';
2547             progress "package seems new, not specifying -v<version>";
2548         }
2549     }
2550     if ($changes_since_version ne '_') {
2551         unshift @opts, "-v$changes_since_version";
2552     }
2553     return @opts;
2554 }
2555
2556 sub cmd_build {
2557     build_prep();
2558     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2559     printdone "build successful\n";
2560 }
2561
2562 sub cmd_git_build {
2563     build_prep();
2564     my @cmd =
2565         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2566          "--git-builder=@dpkgbuildpackage");
2567     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2568         canonicalise_suite();
2569         push @cmd, "--git-debian-branch=".lbranch();
2570     }
2571     push @cmd, changesopts();
2572     runcmd_ordryrun_local @cmd, @ARGV;
2573     printdone "build successful\n";
2574 }
2575
2576 sub build_source {
2577     build_prep();
2578     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2579     $dscfn = dscfn($version);
2580     if ($cleanmode eq 'dpkg-source') {
2581         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2582             changesopts();
2583     } else {
2584         my $pwd = must_getcwd();
2585         my $leafdir = basename $pwd;
2586         changedir "..";
2587         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2588         changedir $pwd;
2589         runcmd_ordryrun_local qw(sh -ec),
2590             'exec >$1; shift; exec "$@"','x',
2591             "../$sourcechanges",
2592             @dpkggenchanges, qw(-S), changesopts();
2593     }
2594 }
2595
2596 sub cmd_build_source {
2597     badusage "build-source takes no additional arguments" if @ARGV;
2598     build_source();
2599     printdone "source built, results in $dscfn and $sourcechanges";
2600 }
2601
2602 sub cmd_sbuild {
2603     build_source();
2604     changedir "..";
2605     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2606     if (act_local()) {
2607         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2608         stat_exists $sourcechanges
2609             or fail "$sourcechanges (in parent directory): $!";
2610         foreach my $cf (glob $pat) {
2611             next if $cf eq $sourcechanges;
2612             unlink $cf or fail "remove $cf: $!";
2613         }
2614     }
2615     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2616     my @changesfiles = glob $pat;
2617     @changesfiles = sort {
2618         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2619             or $a cmp $b
2620     } @changesfiles;
2621     fail "wrong number of different changes files (@changesfiles)"
2622         unless @changesfiles;
2623     runcmd_ordryrun_local @mergechanges, @changesfiles;
2624     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2625     if (act_local()) {
2626         stat_exists $multichanges or fail "$multichanges: $!";
2627     }
2628     printdone "build successful, results in $multichanges\n" or die $!;
2629 }
2630
2631 sub cmd_quilt_fixup {
2632     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2633     my $clogp = parsechangelog();
2634     $version = getfield $clogp, 'Version';
2635     $package = getfield $clogp, 'Source';
2636     build_maybe_quilt_fixup();
2637 }
2638
2639 sub cmd_archive_api_query {
2640     badusage "need only 1 subpath argument" unless @ARGV==1;
2641     my ($subpath) = @ARGV;
2642     my @cmd = archive_api_query_cmd($subpath);
2643     debugcmd ">",@cmd;
2644     exec @cmd or fail "exec curl: $!\n";
2645 }
2646
2647 sub cmd_clone_dgit_repos_server {
2648     badusage "need destination argument" unless @ARGV==1;
2649     my ($destdir) = @ARGV;
2650     $package = '_dgit-repos-server';
2651     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
2652     debugcmd ">",@cmd;
2653     exec @cmd or fail "exec git clone: $!\n";
2654 }
2655
2656 #---------- argument parsing and main program ----------
2657
2658 sub cmd_version {
2659     print "dgit version $our_version\n" or die $!;
2660     exit 0;
2661 }
2662
2663 sub parseopts () {
2664     my $om;
2665
2666     if (defined $ENV{'DGIT_SSH'}) {
2667         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2668     } elsif (defined $ENV{'GIT_SSH'}) {
2669         @ssh = ($ENV{'GIT_SSH'});
2670     }
2671
2672     while (@ARGV) {
2673         last unless $ARGV[0] =~ m/^-/;
2674         $_ = shift @ARGV;
2675         last if m/^--?$/;
2676         if (m/^--/) {
2677             if (m/^--dry-run$/) {
2678                 push @ropts, $_;
2679                 $dryrun_level=2;
2680             } elsif (m/^--damp-run$/) {
2681                 push @ropts, $_;
2682                 $dryrun_level=1;
2683             } elsif (m/^--no-sign$/) {
2684                 push @ropts, $_;
2685                 $sign=0;
2686             } elsif (m/^--help$/) {
2687                 cmd_help();
2688             } elsif (m/^--version$/) {
2689                 cmd_version();
2690             } elsif (m/^--new$/) {
2691                 push @ropts, $_;
2692                 $new_package=1;
2693             } elsif (m/^--since-version=([^_]+|_)$/) {
2694                 push @ropts, $_;
2695                 $changes_since_version = $1;
2696             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2697                      ($om = $opts_opt_map{$1}) &&
2698                      length $om->[0]) {
2699                 push @ropts, $_;
2700                 $om->[0] = $2;
2701             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2702                      !$opts_opt_cmdonly{$1} &&
2703                      ($om = $opts_opt_map{$1})) {
2704                 push @ropts, $_;
2705                 push @$om, $2;
2706             } elsif (m/^--existing-package=(.*)/s) {
2707                 push @ropts, $_;
2708                 $existing_package = $1;
2709             } elsif (m/^--initiator-tempdir=(.*)/s) {
2710                 $initiator_tempdir = $1;
2711                 $initiator_tempdir =~ m#^/# or
2712                     badusage "--initiator-tempdir must be used specify an".
2713                         " absolute, not relative, directory."
2714             } elsif (m/^--distro=(.*)/s) {
2715                 push @ropts, $_;
2716                 $idistro = $1;
2717             } elsif (m/^--build-products-dir=(.*)/s) {
2718                 push @ropts, $_;
2719                 $buildproductsdir = $1;
2720             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2721                 push @ropts, $_;
2722                 $cleanmode = $1;
2723             } elsif (m/^--clean=(.*)$/s) {
2724                 badusage "unknown cleaning mode \`$1'";
2725             } elsif (m/^--quilt=($quilt_modes_re)$/s) {
2726                 push @ropts, $_;
2727                 $quilt_mode = $1;
2728             } elsif (m/^--quilt=(.*)$/s) {
2729                 badusage "unknown quilt fixup mode \`$1'";
2730             } elsif (m/^--ignore-dirty$/s) {
2731                 push @ropts, $_;
2732                 $ignoredirty = 1;
2733             } elsif (m/^--no-quilt-fixup$/s) {
2734                 push @ropts, $_;
2735                 $quilt_mode = 'nocheck';
2736             } elsif (m/^--no-rm-on-error$/s) {
2737                 push @ropts, $_;
2738                 $rmonerror = 0;
2739             } elsif (m/^--deliberately-($deliberately_re)$/s) {
2740                 push @ropts, $_;
2741                 push @deliberatelies, $&;
2742             } else {
2743                 badusage "unknown long option \`$_'";
2744             }
2745         } else {
2746             while (m/^-./s) {
2747                 if (s/^-n/-/) {
2748                     push @ropts, $&;
2749                     $dryrun_level=2;
2750                 } elsif (s/^-L/-/) {
2751                     push @ropts, $&;
2752                     $dryrun_level=1;
2753                 } elsif (s/^-h/-/) {
2754                     cmd_help();
2755                 } elsif (s/^-D/-/) {
2756                     push @ropts, $&;
2757                     $debuglevel++;
2758                     enabledebug();
2759                 } elsif (s/^-N/-/) {
2760                     push @ropts, $&;
2761                     $new_package=1;
2762                 } elsif (s/^-v([^_]+|_)$//s) {
2763                     push @ropts, $&;
2764                     $changes_since_version = $1;
2765                 } elsif (m/^-m/) {
2766                     push @ropts, $&;
2767                     push @changesopts, $_;
2768                     $_ = '';
2769                 } elsif (s/^-c(.*=.*)//s) {
2770                     push @ropts, $&;
2771                     push @git, '-c', $1;
2772                 } elsif (s/^-d(.+)//s) {
2773                     push @ropts, $&;
2774                     $idistro = $1;
2775                 } elsif (s/^-C(.+)//s) {
2776                     push @ropts, $&;
2777                     $changesfile = $1;
2778                     if ($changesfile =~ s#^(.*)/##) {
2779                         $buildproductsdir = $1;
2780                     }
2781                 } elsif (s/^-k(.+)//s) {
2782                     $keyid=$1;
2783                 } elsif (m/^-[vdCk]$/) {
2784                     badusage
2785  "option \`$_' requires an argument (and no space before the argument)";
2786                 } elsif (s/^-wn$//s) {
2787                     push @ropts, $&;
2788                     $cleanmode = 'none';
2789                 } elsif (s/^-wg$//s) {
2790                     push @ropts, $&;
2791                     $cleanmode = 'git';
2792                 } elsif (s/^-wd$//s) {
2793                     push @ropts, $&;
2794                     $cleanmode = 'dpkg-source';
2795                 } else {
2796                     badusage "unknown short option \`$_'";
2797                 }
2798             }
2799         }
2800     }
2801 }
2802
2803 if ($ENV{$fakeeditorenv}) {
2804     quilt_fixup_editor();
2805 }
2806
2807 parseopts();
2808 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2809 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2810     if $dryrun_level == 1;
2811 if (!@ARGV) {
2812     print STDERR $helpmsg or die $!;
2813     exit 8;
2814 }
2815 my $cmd = shift @ARGV;
2816 $cmd =~ y/-/_/;
2817
2818 if (!defined $quilt_mode) {
2819     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
2820         // access_cfg('quilt-mode', 'RETURN-UNDEF')
2821         // 'linear';
2822     $quilt_mode =~ m/^($quilt_modes_re)$/
2823         or badcfg "unknown quilt-mode \`$quilt_mode'";
2824     $quilt_mode = $1;
2825 }
2826
2827 my $fn = ${*::}{"cmd_$cmd"};
2828 $fn or badusage "unknown operation $cmd";
2829 $fn->();