dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use POSIX;
  28
  29 our $suite = 'sid';
  30 our $package;
  31
  32 our $sign = 1;
  33 our $dryrun = 0;
  34 our $changesfile;
  35
  36 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  37
  38 our (@git) = qw(git);
  39 our (@dget) = qw(dget);
  40 our (@dput) = qw(dput);
  41 our (@debsign) = qw(debsign);
  42 our $keyid;
  43
  44 our $debug = 0;
  45 open DEBUG, ">/dev/null" or die $!;
  46
  47 our %opts_opt_map = ('dget' => \@dget,
  48                      'dput' => \@dput,
  49                      'debsign' => \@debsign);
  50
  51 our $remotename = 'dgit';
  52 our $ourdscfield = 'Vcs-Dgit-Master';
  53 our $branchprefix = 'dgit';
  54
  55 sub lbranch () { return "$branchprefix/$suite"; }
  56 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
  57 sub lref () { return "refs/heads/".lbranch(); }
  58 sub lrref () { return "refs/remotes/$remotename/$suite"; }
  59 sub rrref () { return "refs/$branchprefix/$suite"; }
  60 sub debiantag ($) { return "debian/$_[0]"; }
  61
  62 sub fetchspec () {
  63     local $suite = '*';
  64     return  "+".rrref().":".lrref();
  65 }
  66
  67 our $ua;
  68
  69 sub url_get {
  70     if (!$ua) {
  71         $ua = LWP::UserAgent->new();
  72         $ua->env_proxy;
  73     }
  74     print "downloading @_...\n";
  75     my $r = $ua->get(@_) or die $!;
  76     die "$_[0]: ".$r->status_line."; failed.\n" unless $r->is_success;
  77     return $r->decoded_content();
  78 }
  79
  80 our ($dscdata,$dscurl,$dsc);
  81
  82 sub printcmd {
  83     my $fh = shift @_;
  84     my $intro = shift @_;
  85     print $fh $intro or die $!;
  86     local $_;
  87     foreach my $a (@_) {
  88         $_ = $a;
  89         if (s{['\\]}{\\$&}g || m{\s} || m{[^-_./0-9a-z]}i) {
  90             print $fh " '$_'" or die $!;
  91         } else {
  92             print $fh " $_" or die $!;
  93         }
  94     }
  95     print $fh "\n" or die $!;
  96 }
  97
  98 sub runcmd {
  99     printcmd(\*DEBUG,"+",@_) if $debug>0;
 100     $!=0; $?=0;
 101     die "@_ $! $?" if system @_;
 102 }
 103
 104 sub cmdoutput_errok {
 105     die Dumper(\@_)." ?" if grep { !defined } @_;
 106     printcmd(\*DEBUG,"|",@_) if $debug>0;
 107     open P, "-|", @_ or die $!;
 108     my $d;
 109     $!=0; $?=0;
 110     { local $/ = undef; $d = <P>; }
 111     die if P->error;
 112     close P or return undef;
 113     chomp $d;
 114     return $d;
 115 }
 116
 117 sub cmdoutput {
 118     my $d = cmdoutput_errok @_;
 119     defined $d or die "@_ $? $!";
 120     return $d;
 121 }
 122
 123 sub dryrun_report {
 124     printcmd(\*STDOUT,"#",@_);
 125 }
 126
 127 sub runcmd_ordryrun {
 128     if (!$dryrun) {
 129         runcmd @_;
 130     } else {
 131         dryrun_report @_;
 132     }
 133 }
 134
 135 our %defcfg = ('dgit.default.distro' => 'debian',
 136                'dgit.default.username' => '',
 137                'dgit.default.archive-query-default-component' => 'main',
 138                'dgit.default.ssh' => 'ssh',
 139                'dgit-distro.debian.git-host' => 'git.debian.org',
 140                'dgit-distro.debian.git-proto' => 'git+ssh://',
 141                'dgit-distro.debian.git-path' => '/git/dgit-repos',
 142                'dgit-distro.debian.git-check' => 'ssh-cmd',
 143                'dgit-distro.debian.git-create' => 'ssh-cmd',
 144                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/');
 145
 146 sub cfg {
 147     foreach my $c (@_) {
 148         my $v;
 149         {
 150             local ($debug) = $debug-1;
 151             $v = cmdoutput_errok(@git, qw(config --), $c);
 152         };
 153         if ($?==0) {
 154             chomp $v;
 155             return $v;
 156         } elsif ($?!=256) {
 157             die "$c $?";
 158         }
 159         my $dv = $defcfg{$c};
 160         return $dv if defined $dv;
 161     }
 162     return undef;
 163 }
 164
 165 sub access_distro () {
 166     return cfg("dgit-suite.$suite.distro",
 167                "dgit.default.distro");
 168 }
 169
 170 sub access_cfg ($) {
 171     my ($key) = @_;
 172     my $distro = access_distro();
 173     my $value = cfg("dgit-distro.$distro.$key",
 174                     "dgit.default.$key");
 175     return $value;
 176 }
 177
 178 sub access_gituserhost () {
 179     my $user = access_cfg('git-user');
 180     my $host = access_cfg('git-host');
 181     return defined($user) && length($user) ? "$user\@$host" : $host;
 182 }
 183
 184 sub access_giturl () {
 185     my $url = access_cfg('git-url');
 186     if (!defined $url) {
 187         $url =
 188             access_cfg('git-proto').
 189             access_gituserhost().
 190             access_cfg('git-path');
 191     }
 192     return "$url/$package.git";
 193 }
 194
 195 sub parsecontrol {
 196     my $c = Dpkg::Control::Hash->new();
 197     $c->load(@_) or return undef;
 198     return $c;
 199 }
 200
 201 sub parsechangelog {
 202     my $c = Dpkg::Control::Hash->new();
 203     my $p = new IO::Handle;
 204     open $p, '-|', qw(dpkg-parsechangelog) or die $!;
 205     $c->parse($p);
 206     $?=0; $!=0; close $p or die "$! $?";
 207     return $c;
 208 }
 209
 210 our $rmad;
 211
 212 sub archive_query () {
 213     my $query = access_cfg('archive-query');
 214     $query ||= "madison:".access_distro();
 215     $query =~ s/^(\w+):// or die "$query ?";
 216     my $proto = $1;
 217     my $url = $'; #';
 218     die unless $proto eq 'madison';
 219     $rmad ||= cmdoutput qw(rmadison -asource),"-s$suite","-u$url",$package;
 220     $rmad =~ m{^ \s*( [^ \t|]+ )\s* \|
 221                  \s*( [^ \t|]+ )\s* \|
 222                  \s*( [^ \t|/]+ )(?:/([^ \t|/]+)) \s* \|
 223                  \s*( [^ \t|]+ )\s* }x or die "$rmad $?";
 224     $1 eq $package or die "$rmad $package ?";
 225     my $vsn = $2;
 226     if ($suite ne $3) {
 227         # madison canonicalises for us
 228         print "canonical suite name for $suite is $3\n";
 229         $suite = $3;
 230     }
 231     my $component;
 232     if (defined $4) {
 233         $component = $4;
 234     } else {
 235         $component = access_cfg('archive-query-default-component');
 236     }
 237     $5 eq 'source' or die "$rmad ?";
 238     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 239     my $subpath = "/pool/$component/$prefix/$package/${package}_$vsn.dsc";
 240     return ($vsn,$subpath);
 241 }
 242
 243 sub canonicalise_suite () {
 244     archive_query();
 245 }
 246
 247 sub get_archive_dsc () {
 248     my ($vsn,$subpath) = archive_query();
 249     $dscurl = access_cfg('mirror').$subpath;
 250     $dscdata = url_get($dscurl);
 251     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 252     print DEBUG Dumper($dscdata) if $debug>1;
 253     $dsc = Dpkg::Control::Hash->new(allow_pgp=>1);
 254     $dsc->parse($dscfh, 'dsc') or die "parsing of $dscurl failed\n";
 255     print DEBUG Dumper($dsc) if $debug>1;
 256     my $fmt = $dsc->{Format};
 257     die "unsupported format $fmt, sorry\n" unless $format_ok{$fmt};
 258 }
 259
 260 sub check_for_git () {
 261     # returns 0 or 1
 262     my $how = access_cfg('git-check');
 263     if ($how eq 'ssh-cmd') {
 264         my $r= cmdoutput
 265             (access_cfg('ssh'),access_gituserhost(),
 266              " set -e; cd ".access_cfg('git-path').";".
 267              " if test -d $package.git; then echo 1; else echo 0; fi");
 268         print DEBUG "got \`$r'\n";
 269         die "$r $! $?" unless $r =~ m/^[01]$/;
 270         return $r+0;
 271     } else {
 272         die "unknown git-check $how ?";
 273     }
 274 }
 275
 276 sub create_remote_git_repo () {
 277     my $how = access_cfg('git-create');
 278     if ($how eq 'ssh-cmd') {
 279         runcmd_ordryrun
 280             (access_cfg('ssh'),access_gituserhost(),
 281              "set -e; cd ".access_cfg('git-path').";".
 282              " mkdir -p $package.git;".
 283              " cd $package.git;".
 284              " if ! test -d objects; then git init --bare; fi");
 285     } else {
 286         die "unknown git-create $how ?";
 287     }
 288 }
 289
 290 our ($dsc_hash,$upload_hash);
 291
 292 our $ud = '.git/dgit/unpack';
 293
 294 sub prep_ud () {
 295     rmtree($ud);
 296     mkpath '.git/dgit';
 297     mkdir $ud or die $!;
 298 }
 299
 300 sub mktree_in_ud_from_only_subdir () {
 301     # changes into the subdir
 302     my (@dirs) = <*/.>;
 303     die unless @dirs==1;
 304     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 305     my $dir = $1;
 306     chdir $dir or die "$dir $!";
 307     die if stat '.git';
 308     die $! unless $!==&ENOENT;
 309     runcmd qw(git init -q);
 310     rmtree('.git/objects');
 311     symlink '../../../../objects','.git/objects' or die $!;
 312     runcmd @git, qw(add -Af);
 313     my $tree = cmdoutput @git, qw(write-tree);
 314     chomp $tree; $tree =~ m/^\w+$/ or die "$tree ?";
 315     return ($tree,$dir);
 316 }
 317
 318 sub dsc_files () {
 319     map {
 320         m/^\w+ \d+ (\S+)$/ or die "$_ ?";
 321         $1;
 322     } grep m/\S/, split /\n/, ($dsc->{'Checksums-Sha256'} || $dsc->{Files});
 323 }
 324
 325 sub is_orig_file ($) {
 326     local ($_) = @_;
 327     m/\.orig(?:-\w+)?\.tar\.\w+$/;
 328 }
 329
 330 sub generate_commit_from_dsc () {
 331     prep_ud();
 332     chdir $ud or die $!;
 333     my @files;
 334     foreach my $f (dsc_files()) {
 335         die if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
 336         push @files, $f;
 337         link "../../../$f", $f
 338             or $!==&ENOENT
 339             or die "$f $!";
 340     }
 341     runcmd @dget, qw(--), $dscurl;
 342     foreach my $f (grep { is_orig_file($_) } @files) {
 343         link $f, "../../../../$f"
 344             or $!==&EEXIST
 345             or die "$f $!";
 346     }
 347     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 348     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
 349     my $clogp = parsecontrol('../changelog.tmp','changelog') or die;
 350     my $date = cmdoutput qw(date), '+%s %z', qw(-d),$clogp->{Date};
 351     my $author = $clogp->{Maintainer};
 352     $author =~ s#,.*##ms;
 353     my $authline = "$author $date";
 354     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or die $authline;
 355     open C, ">../commit.tmp" or die $!;
 356     print C "tree $tree\n" or die $!;
 357     print C "parent $upload_hash\n" or die $! if $upload_hash;
 358     print C <<END or die $!;
 359 author $authline
 360 committer $authline
 361
 362 $clogp->{Changes}
 363
 364 # imported by dgit from the archive
 365 END
 366     close C or die $!;
 367     my $commithash = cmdoutput @git, qw(hash-object -w -t commit ../commit.tmp);
 368     print "synthesised git commit from .dsc $clogp->{Version}\n";
 369     chdir '../../../..' or die $!;
 370     cmdoutput @git, qw(update-ref -m),"dgit synthesise $clogp->{Version}",
 371               'DGIT_ARCHIVE', $commithash;
 372     cmdoutput @git, qw(log -n2), $commithash;
 373     # ... gives git a chance to complain if our commit is malformed
 374     my $outputhash = $commithash;
 375     if ($upload_hash) {
 376         chdir "$ud/$dir" or die $!;
 377         runcmd @git, qw(reset --hard), $upload_hash;
 378         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
 379         my $oldclogp = Dpkg::Control::Hash->new();
 380         $oldclogp->parse('../changelogold.tmp','previous changelog') or die;
 381         my $vcmp =
 382             version_compare_string($oldclogp->{Version}, $clogp->{Version});
 383         if ($vcmp < 0) {
 384             # git upload/ is earlier vsn than archive, use archive
 385         } elsif ($vcmp >= 0) {
 386             print STDERR <<END or die $!;
 387 Version actually in archive:    $clogp->{Version} (older)
 388 Last allegedly pushed/uploaded: $oldclogp->{Version} (newer or same)
 389 Perhaps the upload is stuck in incoming.  Using the version from git.
 390 END
 391         } else {
 392             die "version in archive is same as version in git".
 393                 " to-be-uploaded (upload/) branch but archive".
 394                 " version hash no commit hash?!\n";
 395         }
 396         chdir '../../../..' or die $!;
 397     }
 398     rmtree($ud);
 399     return $outputhash;
 400 }
 401
 402 sub ensure_we_have_orig () {
 403     foreach my $f (dsc_files()) {
 404         next unless is_orig_file($f);
 405         if (stat "../$f") {
 406             die "$f ?" unless -f _;
 407         } else {
 408             die "$f $!" unless $!==&ENOENT;
 409         }
 410         my $origurl = $dscurl;
 411         $origurl =~ s{/[^/]+$}{};
 412         $origurl .= "/$f";
 413         die "$f ?" unless $f =~ m/^${package}_/;
 414         die "$f ?" if $f =~ m#/#;
 415         runcmd_ordryrun qw(sh -ec),'cd ..; exec "$@"','x',
 416             @dget,'--',$origurl;
 417     }
 418 }
 419
 420 sub rev_parse ($) {
 421     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
 422 }
 423
 424 sub is_fast_fwd ($$) {
 425     my ($ancestor,$child) = @_;
 426     my $mb = cmdoutput @git, qw(merge-base), $dsc_hash, $upload_hash;
 427     return rev_parse($mb) eq rev_parse($ancestor);
 428 }
 429
 430 sub git_fetch_us () {
 431     die "cannot dry run with fetch" if $dryrun;
 432     runcmd @git, qw(fetch),access_giturl(),fetchspec();
 433 }
 434
 435 sub fetch_from_archive () {
 436     # ensures that lrref() is what is actually in the archive,
 437     #  one way or another
 438     get_archive_dsc();
 439     $dsc_hash = $dsc->{$ourdscfield};
 440     if (defined $dsc_hash) {
 441         $dsc_hash =~ m/\w+/ or die "$dsc_hash $?";
 442         $dsc_hash = $&;
 443         print "last upload to archive specified git hash\n";
 444     } else {
 445         print "last upload to archive has NO git hash\n";
 446     }
 447
 448     $!=0; $upload_hash =
 449         cmdoutput_errok @git, qw(show-ref --heads), lrref();
 450     if ($?==0) {
 451         die unless chomp $upload_hash;
 452     } elsif ($?==256) {
 453         $upload_hash = '';
 454     } else {
 455         die $?;
 456     }
 457     my $hash;
 458     if (defined $dsc_hash) {
 459         die "missing git history even though dsc has hash"
 460             unless $upload_hash;
 461         $hash = $dsc_hash;
 462         ensure_we_have_orig();
 463     } else {
 464         $hash = generate_commit_from_dsc();
 465     }
 466     if ($upload_hash) {
 467         die "not fast forward on last upload branch!".
 468             " (archive's version left in DGIT_ARCHIVE)"
 469             unless is_fast_fwd($dsc_hash, $upload_hash);
 470     }
 471     if ($upload_hash ne $hash) {
 472         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
 473         if (!$dryrun) {
 474             cmdoutput @upd_cmd;
 475         } else {
 476             dryrun_report @upd_cmd;
 477         }
 478     }
 479 }
 480
 481 sub clone ($) {
 482     my ($dstdir) = @_;
 483     die "dry run makes no sense with clone" if $dryrun;
 484     mkdir $dstdir or die "$dstdir $!";
 485     chdir "$dstdir" or die "$dstdir $!";
 486     runcmd @git, qw(init -q);
 487     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
 488     open H, "> .git/HEAD" or die $!;
 489     print H "ref: ".lref()."\n" or die $!;
 490     close H or die $!;
 491     runcmd @git, qw(remote add), 'origin', access_giturl();
 492     if (check_for_git()) {
 493         print "fetching existing git history\n";
 494         git_fetch_us();
 495         runcmd @git, qw(fetch origin);
 496     } else {
 497         print "starting new git history\n";
 498     }
 499     fetch_from_archive();
 500     runcmd @git, qw(reset --hard), lrref();
 501     print "ready for work in $dstdir\n";
 502 }
 503
 504 sub fetch () {
 505     if (check_for_git()) {
 506         git_fetch_us();
 507     }
 508     fetch_from_archive();
 509 }
 510
 511 sub pull () {
 512     fetch();
 513     runcmd_ordryrun @git, qw(merge -m),"Merge from $suite [dgit]",
 514         lrref();
 515 }
 516
 517 sub dopush () {
 518     runcmd @git, qw(diff --quiet HEAD);
 519     my $clogp = parsechangelog();
 520     $package = $clogp->{Source};
 521     my $dscfn = "${package}_$clogp->{Version}.dsc";
 522     stat "../$dscfn" or die "$dscfn $!";
 523     $dsc = parsecontrol("../$dscfn");
 524     prep_ud();
 525     chdir $ud or die $!;
 526     print "checking that $dscfn corresponds to HEAD\n";
 527     runcmd qw(dpkg-source -x --), "../../../../$dscfn";
 528     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 529     chdir '../../../..' or die $!;
 530     runcmd @git, qw(diff --exit-code), $tree;
 531 #fetch from alioth
 532 #do fast forward check and maybe fake merge
 533 #    if (!is_fast_fwd(mainbranch
 534 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
 535 #        map { lref($_).":".rref($_) }
 536 #        (uploadbranch());
 537     $dsc->{$ourdscfield} = rev_parse('HEAD');
 538     $dsc->save("../$dscfn.tmp") or die $!;
 539     if (!$dryrun) {
 540         rename "../$dscfn.tmp","../$dscfn" or die "$dscfn $!";
 541     } else {
 542         print "[new .dsc left in $dscfn.tmp]\n";
 543     }
 544     if (!$changesfile) {
 545         my $pat = "../${package}_$clogp->{Version}_*.changes";
 546         my @cs = glob $pat;
 547         die "$pat ?" unless @cs==1;
 548         ($changesfile) = @cs;
 549     }
 550     my $tag = debiantag($dsc->{Version});
 551     if (!check_for_git()) {
 552         create_remote_git_repo();
 553     }
 554     runcmd_ordryrun @git, qw(push),access_giturl(),"HEAD:".rrref();
 555     if ($sign) {
 556         my @tag_cmd = (@git, qw(tag -s -m),
 557                        "Release $dsc->{Version} for $suite [dgit]");
 558         push @tag_cmd, qw(-u),$keyid if defined $keyid;
 559         push @tag_cmd, $tag;
 560         runcmd_ordryrun @tag_cmd;
 561         my @debsign_cmd = @debsign;
 562         push @debsign_cmd, "-k$keyid" if defined $keyid;
 563         push @debsign_cmd, $changesfile;
 564         runcmd_ordryrun @debsign_cmd;
 565     }
 566     runcmd_ordryrun @git, qw(push),access_giturl(),"refs/tags/$tag";
 567     my $host = access_cfg('upload-host');
 568     my @hostarg = defined($host) ? ($host,) : ();
 569     runcmd_ordryrun @dput, @hostarg, $changesfile;
 570 }
 571
 572 sub cmd_clone {
 573     my $dstdir;
 574     die if defined $package;
 575     if (@ARGV==1) {
 576         ($package) = @ARGV;
 577     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
 578         ($package,$suite) = @ARGV;
 579     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
 580         ($package,$dstdir) = @ARGV;
 581     } elsif (@ARGV==3) {
 582         ($package,$suite,$dstdir) = @ARGV;
 583     } else {
 584         die;
 585     }
 586     $dstdir ||= "$package";
 587     clone($dstdir);
 588 }
 589
 590 sub branchsuite () {
 591     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
 592     chomp $branch;
 593     if ($branch =~ m#$lbranch_re#o) {
 594         return $1;
 595     } else {
 596         return undef;
 597     }
 598 }
 599
 600 sub fetchpullargs () {
 601     if (!defined $package) {
 602         my $sourcep = parsecontrol('debian/control');
 603         $package = $sourcep->{Source};
 604     }
 605     if (@ARGV==0) {
 606         $suite = branchsuite();
 607         if (!$suite) {
 608             my $clogp = parsechangelog();
 609             $suite = $clogp->{Distribution};
 610         }
 611         canonicalise_suite();
 612         print "fetching from suite $suite\n";
 613     } elsif (@ARGV==1) {
 614         ($suite) = @ARGV;
 615         canonicalise_suite();
 616     } else {
 617         die;
 618     }
 619 }
 620
 621 sub cmd_fetch {
 622     fetchpullargs();
 623     fetch();
 624 }
 625
 626 sub cmd_pull {
 627     fetchpullargs();
 628     pull();
 629 }
 630
 631 sub cmd_push {
 632     die if defined $package;
 633     my $clogp = parsechangelog();
 634     $package = $clogp->{Source};
 635     if (@ARGV==0) {
 636         $suite = $clogp->{Distribution};
 637         canonicalise_suite();
 638     } else {
 639         die;
 640     }
 641     dopush();
 642 }
 643
 644 sub cmd_build {
 645     die if defined $package;
 646     my $clogp = parsechangelog();
 647     $suite = $clogp->{Distribution};
 648     $package = $clogp->{Source};
 649     canonicalise_suite();
 650     runcmd_ordryrun
 651         qw(git-buildpackage -us -uc --git-no-sign-tags),
 652             "--git-debian-branch=".lbranch(),
 653             @ARGV;
 654 }
 655
 656 sub parseopts () {
 657     my $om;
 658     while (@ARGV) {
 659         last unless $ARGV[0] =~ m/^-/;
 660         $_ = shift @ARGV;
 661         last if m/^--?$/;
 662         if (m/^--/) {
 663             if (m/^--dry-run$/) {
 664                 $dryrun=1;
 665             } elsif (m/^--no-sign$/) {
 666                 $sign=0;
 667             } elsif (m/^--(\w+)=(.*)/s && ($om = $opts_opt_map{$1})) {
 668                 $om->[0] = $2;
 669             } elsif (m/^--(\w+):(.*)/s && ($om = $opts_opt_map{$1})) {
 670                 push @$om, $2;
 671             } else {
 672                 die "$_ ?";
 673             }
 674         } else {
 675             while (m/^-./s) {
 676                 if (s/^-n/-/) {
 677                     $dryrun=1;
 678                 } elsif (s/^-D/-/) {
 679                     open DEBUG, ">&STDERR" or die $!;
 680                     $debug++;
 681                 } elsif (s/^-c(.*=.*)//s) {
 682                     push @git, '-c', $1;
 683                 } elsif (s/^-C(.*)//s) {
 684                     $changesfile = $1;
 685                 } elsif (s/^-k(.*)//s) {
 686                     $keyid=$1;
 687                 } else {
 688                     die "$_ ?";
 689                 }
 690             }
 691         }
 692     }
 693 }
 694
 695 parseopts();
 696 die unless @ARGV;
 697 my $cmd = shift @ARGV;
 698 parseopts();
 699
 700 { no strict qw(refs); &{"cmd_$cmd"}(); }