dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $isuite;
  51 our $idistro;
  52 our $package;
  53 our @ropts;
  54
  55 our $sign = 1;
  56 our $dryrun_level = 0;
  57 our $changesfile;
  58 our $buildproductsdir = '..';
  59 our $new_package = 0;
  60 our $ignoredirty = 0;
  61 our $rmonerror = 1;
  62 our @deliberatelies;
  63 our %previously;
  64 our $existing_package = 'dpkg';
  65 our $cleanmode;
  66 our $changes_since_version;
  67 our $rmchanges;
  68 our $overwrite_version; # undef: not specified; '': check changelog
  69 our $quilt_mode;
  70 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  71 our $dodep14tag;
  72 our $split_brain_save;
  73 our $we_are_responder;
  74 our $we_are_initiator;
  75 our $initiator_tempdir;
  76 our $patches_applied_dirtily = 00;
  77 our $tagformat_want;
  78 our $tagformat;
  79 our $tagformatfn;
  80 our $chase_dsc_distro=1;
  81
  82 our %forceopts = map { $_=>0 }
  83     qw(unrepresentable unsupported-source-format
  84        dsc-changes-mismatch changes-origs-exactly
  85        import-gitapply-absurd
  86        import-gitapply-no-absurd
  87        import-dsc-with-dgit-field);
  88
  89 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  90
  91 our $suite_re = '[-+.0-9a-z]+';
  92 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  93 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  94 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  95 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  96
  97 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  98 our $splitbraincache = 'dgit-intern/quilt-cache';
  99 our $rewritemap = 'dgit-rewrite/map';
 100
 101 our (@git) = qw(git);
 102 our (@dget) = qw(dget);
 103 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 104 our (@dput) = qw(dput);
 105 our (@debsign) = qw(debsign);
 106 our (@gpg) = qw(gpg);
 107 our (@sbuild) = qw(sbuild);
 108 our (@ssh) = 'ssh';
 109 our (@dgit) = qw(dgit);
 110 our (@aptget) = qw(apt-get);
 111 our (@aptcache) = qw(apt-cache);
 112 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 113 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 114 our (@dpkggenchanges) = qw(dpkg-genchanges);
 115 our (@mergechanges) = qw(mergechanges -f);
 116 our (@gbp_build) = ('');
 117 our (@gbp_pq) = ('gbp pq');
 118 our (@changesopts) = ('');
 119
 120 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 121                      'curl' => \@curl,
 122                      'dput' => \@dput,
 123                      'debsign' => \@debsign,
 124                      'gpg' => \@gpg,
 125                      'sbuild' => \@sbuild,
 126                      'ssh' => \@ssh,
 127                      'dgit' => \@dgit,
 128                      'git' => \@git,
 129                      'apt-get' => \@aptget,
 130                      'apt-cache' => \@aptcache,
 131                      'dpkg-source' => \@dpkgsource,
 132                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 133                      'dpkg-genchanges' => \@dpkggenchanges,
 134                      'gbp-build' => \@gbp_build,
 135                      'gbp-pq' => \@gbp_pq,
 136                      'ch' => \@changesopts,
 137                      'mergechanges' => \@mergechanges);
 138
 139 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 140 our %opts_cfg_insertpos = map {
 141     $_,
 142     scalar @{ $opts_opt_map{$_} }
 143 } keys %opts_opt_map;
 144
 145 sub parseopts_late_defaults();
 146 sub setup_gitattrs(;$);
 147 sub check_gitattrs($$);
 148
 149 our $keyid;
 150
 151 autoflush STDOUT 1;
 152
 153 our $supplementary_message = '';
 154 our $need_split_build_invocation = 0;
 155 our $split_brain = 0;
 156
 157 END {
 158     local ($@, $?);
 159     return unless forkcheck_mainprocess();
 160     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 161 }
 162
 163 our $remotename = 'dgit';
 164 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 165 our $csuite;
 166 our $instead_distro;
 167
 168 if (!defined $absurdity) {
 169     $absurdity = $0;
 170     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 171 }
 172
 173 sub debiantag ($$) {
 174     my ($v,$distro) = @_;
 175     return $tagformatfn->($v, $distro);
 176 }
 177
 178 sub debiantag_maintview ($$) {
 179     my ($v,$distro) = @_;
 180     return "$distro/".dep14_version_mangle $v;
 181 }
 182
 183 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 184
 185 sub lbranch () { return "$branchprefix/$csuite"; }
 186 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 187 sub lref () { return "refs/heads/".lbranch(); }
 188 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 189 sub rrref () { return server_ref($csuite); }
 190
 191 sub stripepoch ($) {
 192     my ($vsn) = @_;
 193     $vsn =~ s/^\d+\://;
 194     return $vsn;
 195 }
 196
 197 sub srcfn ($$) {
 198     my ($vsn,$sfx) = @_;
 199     return "${package}_".(stripepoch $vsn).$sfx
 200 }
 201
 202 sub dscfn ($) {
 203     my ($vsn) = @_;
 204     return srcfn($vsn,".dsc");
 205 }
 206
 207 sub changespat ($;$) {
 208     my ($vsn, $arch) = @_;
 209     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 210 }
 211
 212 sub upstreamversion ($) {
 213     my ($vsn) = @_;
 214     $vsn =~ s/-[^-]+$//;
 215     return $vsn;
 216 }
 217
 218 our $us = 'dgit';
 219 initdebug('');
 220
 221 our @end;
 222 END {
 223     local ($?);
 224     return unless forkcheck_mainprocess();
 225     foreach my $f (@end) {
 226         eval { $f->(); };
 227         print STDERR "$us: cleanup: $@" if length $@;
 228     }
 229 };
 230
 231 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 232
 233 sub forceable_fail ($$) {
 234     my ($forceoptsl, $msg) = @_;
 235     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 236     print STDERR "warning: overriding problem due to --force:\n". $msg;
 237 }
 238
 239 sub forceing ($) {
 240     my ($forceoptsl) = @_;
 241     my @got = grep { $forceopts{$_} } @$forceoptsl;
 242     return 0 unless @got;
 243     print STDERR
 244  "warning: skipping checks or functionality due to --force-$got[0]\n";
 245 }
 246
 247 sub no_such_package () {
 248     print STDERR "$us: package $package does not exist in suite $isuite\n";
 249     exit 4;
 250 }
 251
 252 sub changedir ($) {
 253     my ($newdir) = @_;
 254     printdebug "CD $newdir\n";
 255     chdir $newdir or confess "chdir: $newdir: $!";
 256 }
 257
 258 sub deliberately ($) {
 259     my ($enquiry) = @_;
 260     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 261 }
 262
 263 sub deliberately_not_fast_forward () {
 264     foreach (qw(not-fast-forward fresh-repo)) {
 265         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 266     }
 267 }
 268
 269 sub quiltmode_splitbrain () {
 270     $quilt_mode =~ m/gbp|dpm|unapplied/;
 271 }
 272
 273 sub opts_opt_multi_cmd {
 274     my @cmd;
 275     push @cmd, split /\s+/, shift @_;
 276     push @cmd, @_;
 277     @cmd;
 278 }
 279
 280 sub gbp_pq {
 281     return opts_opt_multi_cmd @gbp_pq;
 282 }
 283
 284 #---------- remote protocol support, common ----------
 285
 286 # remote push initiator/responder protocol:
 287 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 288 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 289 #  < dgit-remote-push-ready <actual-proto-vsn>
 290 #
 291 # occasionally:
 292 #
 293 #  > progress NBYTES
 294 #  [NBYTES message]
 295 #
 296 #  > supplementary-message NBYTES          # $protovsn >= 3
 297 #  [NBYTES message]
 298 #
 299 # main sequence:
 300 #
 301 #  > file parsed-changelog
 302 #  [indicates that output of dpkg-parsechangelog follows]
 303 #  > data-block NBYTES
 304 #  > [NBYTES bytes of data (no newline)]
 305 #  [maybe some more blocks]
 306 #  > data-end
 307 #
 308 #  > file dsc
 309 #  [etc]
 310 #
 311 #  > file changes
 312 #  [etc]
 313 #
 314 #  > param head DGIT-VIEW-HEAD
 315 #  > param csuite SUITE
 316 #  > param tagformat old|new
 317 #  > param maint-view MAINT-VIEW-HEAD
 318 #
 319 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 320 #  > file buildinfo                             # for buildinfos to sign
 321 #
 322 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 323 #                                     # goes into tag, for replay prevention
 324 #
 325 #  > want signed-tag
 326 #  [indicates that signed tag is wanted]
 327 #  < data-block NBYTES
 328 #  < [NBYTES bytes of data (no newline)]
 329 #  [maybe some more blocks]
 330 #  < data-end
 331 #  < files-end
 332 #
 333 #  > want signed-dsc-changes
 334 #  < data-block NBYTES    [transfer of signed dsc]
 335 #  [etc]
 336 #  < data-block NBYTES    [transfer of signed changes]
 337 #  [etc]
 338 #  < data-block NBYTES    [transfer of each signed buildinfo
 339 #  [etc]                   same number and order as "file buildinfo"]
 340 #  ...
 341 #  < files-end
 342 #
 343 #  > complete
 344
 345 our $i_child_pid;
 346
 347 sub i_child_report () {
 348     # Sees if our child has died, and reap it if so.  Returns a string
 349     # describing how it died if it failed, or undef otherwise.
 350     return undef unless $i_child_pid;
 351     my $got = waitpid $i_child_pid, WNOHANG;
 352     return undef if $got <= 0;
 353     die unless $got == $i_child_pid;
 354     $i_child_pid = undef;
 355     return undef unless $?;
 356     return "build host child ".waitstatusmsg();
 357 }
 358
 359 sub badproto ($$) {
 360     my ($fh, $m) = @_;
 361     fail "connection lost: $!" if $fh->error;
 362     fail "protocol violation; $m not expected";
 363 }
 364
 365 sub badproto_badread ($$) {
 366     my ($fh, $wh) = @_;
 367     fail "connection lost: $!" if $!;
 368     my $report = i_child_report();
 369     fail $report if defined $report;
 370     badproto $fh, "eof (reading $wh)";
 371 }
 372
 373 sub protocol_expect (&$) {
 374     my ($match, $fh) = @_;
 375     local $_;
 376     $_ = <$fh>;
 377     defined && chomp or badproto_badread $fh, "protocol message";
 378     if (wantarray) {
 379         my @r = &$match;
 380         return @r if @r;
 381     } else {
 382         my $r = &$match;
 383         return $r if $r;
 384     }
 385     badproto $fh, "\`$_'";
 386 }
 387
 388 sub protocol_send_file ($$) {
 389     my ($fh, $ourfn) = @_;
 390     open PF, "<", $ourfn or die "$ourfn: $!";
 391     for (;;) {
 392         my $d;
 393         my $got = read PF, $d, 65536;
 394         die "$ourfn: $!" unless defined $got;
 395         last if !$got;
 396         print $fh "data-block ".length($d)."\n" or die $!;
 397         print $fh $d or die $!;
 398     }
 399     PF->error and die "$ourfn $!";
 400     print $fh "data-end\n" or die $!;
 401     close PF;
 402 }
 403
 404 sub protocol_read_bytes ($$) {
 405     my ($fh, $nbytes) = @_;
 406     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 407     my $d;
 408     my $got = read $fh, $d, $nbytes;
 409     $got==$nbytes or badproto_badread $fh, "data block";
 410     return $d;
 411 }
 412
 413 sub protocol_receive_file ($$) {
 414     my ($fh, $ourfn) = @_;
 415     printdebug "() $ourfn\n";
 416     open PF, ">", $ourfn or die "$ourfn: $!";
 417     for (;;) {
 418         my ($y,$l) = protocol_expect {
 419             m/^data-block (.*)$/ ? (1,$1) :
 420             m/^data-end$/ ? (0,) :
 421             ();
 422         } $fh;
 423         last unless $y;
 424         my $d = protocol_read_bytes $fh, $l;
 425         print PF $d or die $!;
 426     }
 427     close PF or die $!;
 428 }
 429
 430 #---------- remote protocol support, responder ----------
 431
 432 sub responder_send_command ($) {
 433     my ($command) = @_;
 434     return unless $we_are_responder;
 435     # called even without $we_are_responder
 436     printdebug ">> $command\n";
 437     print PO $command, "\n" or die $!;
 438 }
 439
 440 sub responder_send_file ($$) {
 441     my ($keyword, $ourfn) = @_;
 442     return unless $we_are_responder;
 443     printdebug "]] $keyword $ourfn\n";
 444     responder_send_command "file $keyword";
 445     protocol_send_file \*PO, $ourfn;
 446 }
 447
 448 sub responder_receive_files ($@) {
 449     my ($keyword, @ourfns) = @_;
 450     die unless $we_are_responder;
 451     printdebug "[[ $keyword @ourfns\n";
 452     responder_send_command "want $keyword";
 453     foreach my $fn (@ourfns) {
 454         protocol_receive_file \*PI, $fn;
 455     }
 456     printdebug "[[\$\n";
 457     protocol_expect { m/^files-end$/ } \*PI;
 458 }
 459
 460 #---------- remote protocol support, initiator ----------
 461
 462 sub initiator_expect (&) {
 463     my ($match) = @_;
 464     protocol_expect { &$match } \*RO;
 465 }
 466
 467 #---------- end remote code ----------
 468
 469 sub progress {
 470     if ($we_are_responder) {
 471         my $m = join '', @_;
 472         responder_send_command "progress ".length($m) or die $!;
 473         print PO $m or die $!;
 474     } else {
 475         print @_, "\n";
 476     }
 477 }
 478
 479 our $ua;
 480
 481 sub url_get {
 482     if (!$ua) {
 483         $ua = LWP::UserAgent->new();
 484         $ua->env_proxy;
 485     }
 486     my $what = $_[$#_];
 487     progress "downloading $what...";
 488     my $r = $ua->get(@_) or die $!;
 489     return undef if $r->code == 404;
 490     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 491     return $r->decoded_content(charset => 'none');
 492 }
 493
 494 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 495
 496 sub runcmd {
 497     debugcmd "+",@_;
 498     $!=0; $?=-1;
 499     failedcmd @_ if system @_;
 500 }
 501
 502 sub act_local () { return $dryrun_level <= 1; }
 503 sub act_scary () { return !$dryrun_level; }
 504
 505 sub printdone {
 506     if (!$dryrun_level) {
 507         progress "$us ok: @_";
 508     } else {
 509         progress "would be ok: @_ (but dry run only)";
 510     }
 511 }
 512
 513 sub dryrun_report {
 514     printcmd(\*STDERR,$debugprefix."#",@_);
 515 }
 516
 517 sub runcmd_ordryrun {
 518     if (act_scary()) {
 519         runcmd @_;
 520     } else {
 521         dryrun_report @_;
 522     }
 523 }
 524
 525 sub runcmd_ordryrun_local {
 526     if (act_local()) {
 527         runcmd @_;
 528     } else {
 529         dryrun_report @_;
 530     }
 531 }
 532
 533 sub shell_cmd {
 534     my ($first_shell, @cmd) = @_;
 535     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 536 }
 537
 538 our $helpmsg = <<END;
 539 main usages:
 540   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 541   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 542   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 543   dgit [dgit-opts] sbuild [sbuild-opts]
 544   dgit [dgit-opts] push [dgit-opts] [suite]
 545   dgit [dgit-opts] rpush build-host:build-dir ...
 546 important dgit options:
 547   -k<keyid>           sign tag and package with <keyid> instead of default
 548   --dry-run -n        do not change anything, but go through the motions
 549   --damp-run -L       like --dry-run but make local changes, without signing
 550   --new -N            allow introducing a new package
 551   --debug -D          increase debug level
 552   -c<name>=<value>    set git config option (used directly by dgit too)
 553 END
 554
 555 our $later_warning_msg = <<END;
 556 Perhaps the upload is stuck in incoming.  Using the version from git.
 557 END
 558
 559 sub badusage {
 560     print STDERR "$us: @_\n", $helpmsg or die $!;
 561     exit 8;
 562 }
 563
 564 sub nextarg {
 565     @ARGV or badusage "too few arguments";
 566     return scalar shift @ARGV;
 567 }
 568
 569 sub pre_help () {
 570     no_local_git_cfg();
 571 }
 572 sub cmd_help () {
 573     print $helpmsg or die $!;
 574     exit 0;
 575 }
 576
 577 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 578
 579 our %defcfg = ('dgit.default.distro' => 'debian',
 580                'dgit.default.default-suite' => 'unstable',
 581                'dgit.default.old-dsc-distro' => 'debian',
 582                'dgit-suite.*-security.distro' => 'debian-security',
 583                'dgit.default.username' => '',
 584                'dgit.default.archive-query-default-component' => 'main',
 585                'dgit.default.ssh' => 'ssh',
 586                'dgit.default.archive-query' => 'madison:',
 587                'dgit.default.sshpsql-dbname' => 'service=projectb',
 588                'dgit.default.aptget-components' => 'main',
 589                'dgit.default.dgit-tag-format' => 'new,old,maint',
 590                'dgit.dsc-url-proto-ok.http'    => 'true',
 591                'dgit.dsc-url-proto-ok.https'   => 'true',
 592                'dgit.dsc-url-proto-ok.git'     => 'true',
 593                'dgit.default.dsc-url-proto-ok' => 'false',
 594                # old means "repo server accepts pushes with old dgit tags"
 595                # new means "repo server accepts pushes with new dgit tags"
 596                # maint means "repo server accepts split brain pushes"
 597                # hist means "repo server may have old pushes without new tag"
 598                #   ("hist" is implied by "old")
 599                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 600                'dgit-distro.debian.git-check' => 'url',
 601                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 602                'dgit-distro.debian.new-private-pushers' => 't',
 603                'dgit-distro.debian/push.git-url' => '',
 604                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 605                'dgit-distro.debian/push.git-user-force' => 'dgit',
 606                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 607                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 608                'dgit-distro.debian/push.git-create' => 'true',
 609                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 610  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 611 # 'dgit-distro.debian.archive-query-tls-key',
 612 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 613 # ^ this does not work because curl is broken nowadays
 614 # Fixing #790093 properly will involve providing providing the key
 615 # in some pacagke and maybe updating these paths.
 616 #
 617 # 'dgit-distro.debian.archive-query-tls-curl-args',
 618 #   '--ca-path=/etc/ssl/ca-debian',
 619 # ^ this is a workaround but works (only) on DSA-administered machines
 620                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 621                'dgit-distro.debian.git-url-suffix' => '',
 622                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 623                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 624  'dgit-distro.debian-security.archive-query' => 'aptget:',
 625  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 626  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 627  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 628  'dgit-distro.debian-security.nominal-distro' => 'debian',
 629  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 630  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 631                'dgit-distro.ubuntu.git-check' => 'false',
 632  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 633                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 634                'dgit-distro.test-dummy.username' => "alice",
 635                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 636                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 637                'dgit-distro.test-dummy.git-url' => "$td/git",
 638                'dgit-distro.test-dummy.git-host' => "git",
 639                'dgit-distro.test-dummy.git-path' => "$td/git",
 640                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 641                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 642                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 643                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 644                );
 645
 646 our %gitcfgs;
 647 our @gitcfgsources = qw(cmdline local global system);
 648
 649 sub git_slurp_config () {
 650     local ($debuglevel) = $debuglevel-2;
 651     local $/="\0";
 652
 653     # This algoritm is a bit subtle, but this is needed so that for
 654     # options which we want to be single-valued, we allow the
 655     # different config sources to override properly.  See #835858.
 656     foreach my $src (@gitcfgsources) {
 657         next if $src eq 'cmdline';
 658         # we do this ourselves since git doesn't handle it
 659
 660         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 661         debugcmd "|",@cmd;
 662
 663         open GITS, "-|", @cmd or die $!;
 664         while (<GITS>) {
 665             chomp or die;
 666             printdebug "=> ", (messagequote $_), "\n";
 667             m/\n/ or die "$_ ?";
 668             push @{ $gitcfgs{$src}{$`} }, $'; #';
 669         }
 670         $!=0; $?=0;
 671         close GITS
 672             or ($!==0 && $?==256)
 673             or failedcmd @cmd;
 674     }
 675 }
 676
 677 sub git_get_config ($) {
 678     my ($c) = @_;
 679     foreach my $src (@gitcfgsources) {
 680         my $l = $gitcfgs{$src}{$c};
 681         confess "internal error ($l $c)" if $l && !ref $l;
 682         printdebug"C $c ".(defined $l ?
 683                            join " ", map { messagequote "'$_'" } @$l :
 684                            "undef")."\n"
 685             if $debuglevel >= 4;
 686         $l or next;
 687         @$l==1 or badcfg "multiple values for $c".
 688             " (in $src git config)" if @$l > 1;
 689         return $l->[0];
 690     }
 691     return undef;
 692 }
 693
 694 sub cfg {
 695     foreach my $c (@_) {
 696         return undef if $c =~ /RETURN-UNDEF/;
 697         printdebug "C? $c\n" if $debuglevel >= 5;
 698         my $v = git_get_config($c);
 699         return $v if defined $v;
 700         my $dv = $defcfg{$c};
 701         if (defined $dv) {
 702             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 703             return $dv;
 704         }
 705     }
 706     badcfg "need value for one of: @_\n".
 707         "$us: distro or suite appears not to be (properly) supported";
 708 }
 709
 710 sub no_local_git_cfg () {
 711     # needs to be called from pre_*
 712     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 713 }
 714
 715 sub access_basedistro__noalias () {
 716     if (defined $idistro) {
 717         return $idistro;
 718     } else {
 719         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 720         return $def if defined $def;
 721         foreach my $src (@gitcfgsources, 'internal') {
 722             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 723             next unless $kl;
 724             foreach my $k (keys %$kl) {
 725                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 726                 my $dpat = $1;
 727                 next unless match_glob $dpat, $isuite;
 728                 return $kl->{$k};
 729             }
 730         }
 731         return cfg("dgit.default.distro");
 732     }
 733 }
 734
 735 sub access_basedistro () {
 736     my $noalias = access_basedistro__noalias();
 737     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 738     return $canon // $noalias;
 739 }
 740
 741 sub access_nomdistro () {
 742     my $base = access_basedistro();
 743     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 744     $r =~ m/^$distro_re$/ or badcfg
 745  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 746     return $r;
 747 }
 748
 749 sub access_quirk () {
 750     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 751     my $basedistro = access_basedistro();
 752     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 753                               'RETURN-UNDEF');
 754     if (defined $backports_quirk) {
 755         my $re = $backports_quirk;
 756         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 757         $re =~ s/\*/.*/g;
 758         $re =~ s/\%/([-0-9a-z_]+)/
 759             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 760         if ($isuite =~ m/^$re$/) {
 761             return ('backports',"$basedistro-backports",$1);
 762         }
 763     }
 764     return ('none',undef);
 765 }
 766
 767 our $access_forpush;
 768
 769 sub parse_cfg_bool ($$$) {
 770     my ($what,$def,$v) = @_;
 771     $v //= $def;
 772     return
 773         $v =~ m/^[ty1]/ ? 1 :
 774         $v =~ m/^[fn0]/ ? 0 :
 775         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 776 }
 777
 778 sub access_forpush_config () {
 779     my $d = access_basedistro();
 780
 781     return 1 if
 782         $new_package &&
 783         parse_cfg_bool('new-private-pushers', 0,
 784                        cfg("dgit-distro.$d.new-private-pushers",
 785                            'RETURN-UNDEF'));
 786
 787     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 788     $v //= 'a';
 789     return
 790         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 791         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 792         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 793         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 794 }
 795
 796 sub access_forpush () {
 797     $access_forpush //= access_forpush_config();
 798     return $access_forpush;
 799 }
 800
 801 sub pushing () {
 802     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 803     badcfg "pushing but distro is configured readonly"
 804         if access_forpush_config() eq '0';
 805     $access_forpush = 1;
 806     $supplementary_message = <<'END' unless $we_are_responder;
 807 Push failed, before we got started.
 808 You can retry the push, after fixing the problem, if you like.
 809 END
 810     parseopts_late_defaults();
 811 }
 812
 813 sub notpushing () {
 814     parseopts_late_defaults();
 815 }
 816
 817 sub supplementary_message ($) {
 818     my ($msg) = @_;
 819     if (!$we_are_responder) {
 820         $supplementary_message = $msg;
 821         return;
 822     } elsif ($protovsn >= 3) {
 823         responder_send_command "supplementary-message ".length($msg)
 824             or die $!;
 825         print PO $msg or die $!;
 826     }
 827 }
 828
 829 sub access_distros () {
 830     # Returns list of distros to try, in order
 831     #
 832     # We want to try:
 833     #    0. `instead of' distro name(s) we have been pointed to
 834     #    1. the access_quirk distro, if any
 835     #    2a. the user's specified distro, or failing that  } basedistro
 836     #    2b. the distro calculated from the suite          }
 837     my @l = access_basedistro();
 838
 839     my (undef,$quirkdistro) = access_quirk();
 840     unshift @l, $quirkdistro;
 841     unshift @l, $instead_distro;
 842     @l = grep { defined } @l;
 843
 844     push @l, access_nomdistro();
 845
 846     if (access_forpush()) {
 847         @l = map { ("$_/push", $_) } @l;
 848     }
 849     @l;
 850 }
 851
 852 sub access_cfg_cfgs (@) {
 853     my (@keys) = @_;
 854     my @cfgs;
 855     # The nesting of these loops determines the search order.  We put
 856     # the key loop on the outside so that we search all the distros
 857     # for each key, before going on to the next key.  That means that
 858     # if access_cfg is called with a more specific, and then a less
 859     # specific, key, an earlier distro can override the less specific
 860     # without necessarily overriding any more specific keys.  (If the
 861     # distro wants to override the more specific keys it can simply do
 862     # so; whereas if we did the loop the other way around, it would be
 863     # impossible to for an earlier distro to override a less specific
 864     # key but not the more specific ones without restating the unknown
 865     # values of the more specific keys.
 866     my @realkeys;
 867     my @rundef;
 868     # We have to deal with RETURN-UNDEF specially, so that we don't
 869     # terminate the search prematurely.
 870     foreach (@keys) {
 871         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 872         push @realkeys, $_
 873     }
 874     foreach my $d (access_distros()) {
 875         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 876     }
 877     push @cfgs, map { "dgit.default.$_" } @realkeys;
 878     push @cfgs, @rundef;
 879     return @cfgs;
 880 }
 881
 882 sub access_cfg (@) {
 883     my (@keys) = @_;
 884     my (@cfgs) = access_cfg_cfgs(@keys);
 885     my $value = cfg(@cfgs);
 886     return $value;
 887 }
 888
 889 sub access_cfg_bool ($$) {
 890     my ($def, @keys) = @_;
 891     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 892 }
 893
 894 sub string_to_ssh ($) {
 895     my ($spec) = @_;
 896     if ($spec =~ m/\s/) {
 897         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 898     } else {
 899         return ($spec);
 900     }
 901 }
 902
 903 sub access_cfg_ssh () {
 904     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 905     if (!defined $gitssh) {
 906         return @ssh;
 907     } else {
 908         return string_to_ssh $gitssh;
 909     }
 910 }
 911
 912 sub access_runeinfo ($) {
 913     my ($info) = @_;
 914     return ": dgit ".access_basedistro()." $info ;";
 915 }
 916
 917 sub access_someuserhost ($) {
 918     my ($some) = @_;
 919     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 920     defined($user) && length($user) or
 921         $user = access_cfg("$some-user",'username');
 922     my $host = access_cfg("$some-host");
 923     return length($user) ? "$user\@$host" : $host;
 924 }
 925
 926 sub access_gituserhost () {
 927     return access_someuserhost('git');
 928 }
 929
 930 sub access_giturl (;$) {
 931     my ($optional) = @_;
 932     my $url = access_cfg('git-url','RETURN-UNDEF');
 933     my $suffix;
 934     if (!length $url) {
 935         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 936         return undef unless defined $proto;
 937         $url =
 938             $proto.
 939             access_gituserhost().
 940             access_cfg('git-path');
 941     } else {
 942         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 943     }
 944     $suffix //= '.git';
 945     return "$url/$package$suffix";
 946 }
 947
 948 sub parsecontrolfh ($$;$) {
 949     my ($fh, $desc, $allowsigned) = @_;
 950     our $dpkgcontrolhash_noissigned;
 951     my $c;
 952     for (;;) {
 953         my %opts = ('name' => $desc);
 954         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 955         $c = Dpkg::Control::Hash->new(%opts);
 956         $c->parse($fh,$desc) or die "parsing of $desc failed";
 957         last if $allowsigned;
 958         last if $dpkgcontrolhash_noissigned;
 959         my $issigned= $c->get_option('is_pgp_signed');
 960         if (!defined $issigned) {
 961             $dpkgcontrolhash_noissigned= 1;
 962             seek $fh, 0,0 or die "seek $desc: $!";
 963         } elsif ($issigned) {
 964             fail "control file $desc is (already) PGP-signed. ".
 965                 " Note that dgit push needs to modify the .dsc and then".
 966                 " do the signature itself";
 967         } else {
 968             last;
 969         }
 970     }
 971     return $c;
 972 }
 973
 974 sub parsecontrol {
 975     my ($file, $desc, $allowsigned) = @_;
 976     my $fh = new IO::Handle;
 977     open $fh, '<', $file or die "$file: $!";
 978     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 979     $fh->error and die $!;
 980     close $fh;
 981     return $c;
 982 }
 983
 984 sub getfield ($$) {
 985     my ($dctrl,$field) = @_;
 986     my $v = $dctrl->{$field};
 987     return $v if defined $v;
 988     fail "missing field $field in ".$dctrl->get_option('name');
 989 }
 990
 991 sub parsechangelog {
 992     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 993     my $p = new IO::Handle;
 994     my @cmd = (qw(dpkg-parsechangelog), @_);
 995     open $p, '-|', @cmd or die $!;
 996     $c->parse($p);
 997     $?=0; $!=0; close $p or failedcmd @cmd;
 998     return $c;
 999 }
1000
1001 sub commit_getclogp ($) {
1002     # Returns the parsed changelog hashref for a particular commit
1003     my ($objid) = @_;
1004     our %commit_getclogp_memo;
1005     my $memo = $commit_getclogp_memo{$objid};
1006     return $memo if $memo;
1007     mkpath '.git/dgit';
1008     my $mclog = ".git/dgit/clog-$objid";
1009     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
1010         "$objid:debian/changelog";
1011     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
1012 }
1013
1014 sub must_getcwd () {
1015     my $d = getcwd();
1016     defined $d or fail "getcwd failed: $!";
1017     return $d;
1018 }
1019
1020 sub parse_dscdata () {
1021     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1022     printdebug Dumper($dscdata) if $debuglevel>1;
1023     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1024     printdebug Dumper($dsc) if $debuglevel>1;
1025 }
1026
1027 our %rmad;
1028
1029 sub archive_query ($;@) {
1030     my ($method) = shift @_;
1031     fail "this operation does not support multiple comma-separated suites"
1032         if $isuite =~ m/,/;
1033     my $query = access_cfg('archive-query','RETURN-UNDEF');
1034     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1035     my $proto = $1;
1036     my $data = $'; #';
1037     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1038 }
1039
1040 sub archive_query_prepend_mirror {
1041     my $m = access_cfg('mirror');
1042     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1043 }
1044
1045 sub pool_dsc_subpath ($$) {
1046     my ($vsn,$component) = @_; # $package is implict arg
1047     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1048     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1049 }
1050
1051 sub cfg_apply_map ($$$) {
1052     my ($varref, $what, $mapspec) = @_;
1053     return unless $mapspec;
1054
1055     printdebug "config $what EVAL{ $mapspec; }\n";
1056     $_ = $$varref;
1057     eval "package Dgit::Config; $mapspec;";
1058     die $@ if $@;
1059     $$varref = $_;
1060 }
1061
1062 #---------- `ftpmasterapi' archive query method (nascent) ----------
1063
1064 sub archive_api_query_cmd ($) {
1065     my ($subpath) = @_;
1066     my @cmd = (@curl, qw(-sS));
1067     my $url = access_cfg('archive-query-url');
1068     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1069         my $host = $1;
1070         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1071         foreach my $key (split /\:/, $keys) {
1072             $key =~ s/\%HOST\%/$host/g;
1073             if (!stat $key) {
1074                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1075                 next;
1076             }
1077             fail "config requested specific TLS key but do not know".
1078                 " how to get curl to use exactly that EE key ($key)";
1079 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1080 #           # Sadly the above line does not work because of changes
1081 #           # to gnutls.   The real fix for #790093 may involve
1082 #           # new curl options.
1083             last;
1084         }
1085         # Fixing #790093 properly will involve providing a value
1086         # for this on clients.
1087         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1088         push @cmd, split / /, $kargs if defined $kargs;
1089     }
1090     push @cmd, $url.$subpath;
1091     return @cmd;
1092 }
1093
1094 sub api_query ($$;$) {
1095     use JSON;
1096     my ($data, $subpath, $ok404) = @_;
1097     badcfg "ftpmasterapi archive query method takes no data part"
1098         if length $data;
1099     my @cmd = archive_api_query_cmd($subpath);
1100     my $url = $cmd[$#cmd];
1101     push @cmd, qw(-w %{http_code});
1102     my $json = cmdoutput @cmd;
1103     unless ($json =~ s/\d+\d+\d$//) {
1104         failedcmd_report_cmd undef, @cmd;
1105         fail "curl failed to print 3-digit HTTP code";
1106     }
1107     my $code = $&;
1108     return undef if $code eq '404' && $ok404;
1109     fail "fetch of $url gave HTTP code $code"
1110         unless $url =~ m#^file://# or $code =~ m/^2/;
1111     return decode_json($json);
1112 }
1113
1114 sub canonicalise_suite_ftpmasterapi {
1115     my ($proto,$data) = @_;
1116     my $suites = api_query($data, 'suites');
1117     my @matched;
1118     foreach my $entry (@$suites) {
1119         next unless grep {
1120             my $v = $entry->{$_};
1121             defined $v && $v eq $isuite;
1122         } qw(codename name);
1123         push @matched, $entry;
1124     }
1125     fail "unknown suite $isuite" unless @matched;
1126     my $cn;
1127     eval {
1128         @matched==1 or die "multiple matches for suite $isuite\n";
1129         $cn = "$matched[0]{codename}";
1130         defined $cn or die "suite $isuite info has no codename\n";
1131         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1132     };
1133     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1134         if length $@;
1135     return $cn;
1136 }
1137
1138 sub archive_query_ftpmasterapi {
1139     my ($proto,$data) = @_;
1140     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1141     my @rows;
1142     my $digester = Digest::SHA->new(256);
1143     foreach my $entry (@$info) {
1144         eval {
1145             my $vsn = "$entry->{version}";
1146             my ($ok,$msg) = version_check $vsn;
1147             die "bad version: $msg\n" unless $ok;
1148             my $component = "$entry->{component}";
1149             $component =~ m/^$component_re$/ or die "bad component";
1150             my $filename = "$entry->{filename}";
1151             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1152                 or die "bad filename";
1153             my $sha256sum = "$entry->{sha256sum}";
1154             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1155             push @rows, [ $vsn, "/pool/$component/$filename",
1156                           $digester, $sha256sum ];
1157         };
1158         die "bad ftpmaster api response: $@\n".Dumper($entry)
1159             if length $@;
1160     }
1161     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1162     return archive_query_prepend_mirror @rows;
1163 }
1164
1165 sub file_in_archive_ftpmasterapi {
1166     my ($proto,$data,$filename) = @_;
1167     my $pat = $filename;
1168     $pat =~ s/_/\\_/g;
1169     $pat = "%/$pat";
1170     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1171     my $info = api_query($data, "file_in_archive/$pat", 1);
1172 }
1173
1174 #---------- `aptget' archive query method ----------
1175
1176 our $aptget_base;
1177 our $aptget_releasefile;
1178 our $aptget_configpath;
1179
1180 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1181 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1182
1183 sub aptget_cache_clean {
1184     runcmd_ordryrun_local qw(sh -ec),
1185         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1186         'x', $aptget_base;
1187 }
1188
1189 sub aptget_lock_acquire () {
1190     my $lockfile = "$aptget_base/lock";
1191     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1192     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1193 }
1194
1195 sub aptget_prep ($) {
1196     my ($data) = @_;
1197     return if defined $aptget_base;
1198
1199     badcfg "aptget archive query method takes no data part"
1200         if length $data;
1201
1202     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1203
1204     ensuredir $cache;
1205     ensuredir "$cache/dgit";
1206     my $cachekey =
1207         access_cfg('aptget-cachekey','RETURN-UNDEF')
1208         // access_nomdistro();
1209
1210     $aptget_base = "$cache/dgit/aptget";
1211     ensuredir $aptget_base;
1212
1213     my $quoted_base = $aptget_base;
1214     die "$quoted_base contains bad chars, cannot continue"
1215         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1216
1217     ensuredir $aptget_base;
1218
1219     aptget_lock_acquire();
1220
1221     aptget_cache_clean();
1222
1223     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1224     my $sourceslist = "source.list#$cachekey";
1225
1226     my $aptsuites = $isuite;
1227     cfg_apply_map(\$aptsuites, 'suite map',
1228                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1229
1230     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1231     printf SRCS "deb-src %s %s %s\n",
1232         access_cfg('mirror'),
1233         $aptsuites,
1234         access_cfg('aptget-components')
1235         or die $!;
1236
1237     ensuredir "$aptget_base/cache";
1238     ensuredir "$aptget_base/lists";
1239
1240     open CONF, ">", $aptget_configpath or die $!;
1241     print CONF <<END;
1242 Debug::NoLocking "true";
1243 APT::Get::List-Cleanup "false";
1244 #clear APT::Update::Post-Invoke-Success;
1245 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1246 Dir::State::Lists "$quoted_base/lists";
1247 Dir::Etc::preferences "$quoted_base/preferences";
1248 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1249 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1250 END
1251
1252     foreach my $key (qw(
1253                         Dir::Cache
1254                         Dir::State
1255                         Dir::Cache::Archives
1256                         Dir::Etc::SourceParts
1257                         Dir::Etc::preferencesparts
1258                       )) {
1259         ensuredir "$aptget_base/$key";
1260         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1261     };
1262
1263     my $oldatime = (time // die $!) - 1;
1264     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1265         next unless stat_exists $oldlist;
1266         my ($mtime) = (stat _)[9];
1267         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1268     }
1269
1270     runcmd_ordryrun_local aptget_aptget(), qw(update);
1271
1272     my @releasefiles;
1273     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1274         next unless stat_exists $oldlist;
1275         my ($atime) = (stat _)[8];
1276         next if $atime == $oldatime;
1277         push @releasefiles, $oldlist;
1278     }
1279     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1280     @releasefiles = @inreleasefiles if @inreleasefiles;
1281     die "apt updated wrong number of Release files (@releasefiles), erk"
1282         unless @releasefiles == 1;
1283
1284     ($aptget_releasefile) = @releasefiles;
1285 }
1286
1287 sub canonicalise_suite_aptget {
1288     my ($proto,$data) = @_;
1289     aptget_prep($data);
1290
1291     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1292
1293     foreach my $name (qw(Codename Suite)) {
1294         my $val = $release->{$name};
1295         if (defined $val) {
1296             printdebug "release file $name: $val\n";
1297             $val =~ m/^$suite_re$/o or fail
1298  "Release file ($aptget_releasefile) specifies intolerable $name";
1299             cfg_apply_map(\$val, 'suite rmap',
1300                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1301             return $val
1302         }
1303     }
1304     return $isuite;
1305 }
1306
1307 sub archive_query_aptget {
1308     my ($proto,$data) = @_;
1309     aptget_prep($data);
1310
1311     ensuredir "$aptget_base/source";
1312     foreach my $old (<$aptget_base/source/*.dsc>) {
1313         unlink $old or die "$old: $!";
1314     }
1315
1316     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1317     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1318     # avoids apt-get source failing with ambiguous error code
1319
1320     runcmd_ordryrun_local
1321         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1322         aptget_aptget(), qw(--download-only --only-source source), $package;
1323
1324     my @dscs = <$aptget_base/source/*.dsc>;
1325     fail "apt-get source did not produce a .dsc" unless @dscs;
1326     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1327
1328     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1329
1330     use URI::Escape;
1331     my $uri = "file://". uri_escape $dscs[0];
1332     $uri =~ s{\%2f}{/}gi;
1333     return [ (getfield $pre_dsc, 'Version'), $uri ];
1334 }
1335
1336 sub file_in_archive_aptget () { return undef; }
1337
1338 #---------- `dummyapicat' archive query method ----------
1339
1340 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1341 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1342
1343 sub file_in_archive_dummycatapi ($$$) {
1344     my ($proto,$data,$filename) = @_;
1345     my $mirror = access_cfg('mirror');
1346     $mirror =~ s#^file://#/# or die "$mirror ?";
1347     my @out;
1348     my @cmd = (qw(sh -ec), '
1349             cd "$1"
1350             find -name "$2" -print0 |
1351             xargs -0r sha256sum
1352         ', qw(x), $mirror, $filename);
1353     debugcmd "-|", @cmd;
1354     open FIA, "-|", @cmd or die $!;
1355     while (<FIA>) {
1356         chomp or die;
1357         printdebug "| $_\n";
1358         m/^(\w+)  (\S+)$/ or die "$_ ?";
1359         push @out, { sha256sum => $1, filename => $2 };
1360     }
1361     close FIA or die failedcmd @cmd;
1362     return \@out;
1363 }
1364
1365 #---------- `madison' archive query method ----------
1366
1367 sub archive_query_madison {
1368     return archive_query_prepend_mirror
1369         map { [ @$_[0..1] ] } madison_get_parse(@_);
1370 }
1371
1372 sub madison_get_parse {
1373     my ($proto,$data) = @_;
1374     die unless $proto eq 'madison';
1375     if (!length $data) {
1376         $data= access_cfg('madison-distro','RETURN-UNDEF');
1377         $data //= access_basedistro();
1378     }
1379     $rmad{$proto,$data,$package} ||= cmdoutput
1380         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1381     my $rmad = $rmad{$proto,$data,$package};
1382
1383     my @out;
1384     foreach my $l (split /\n/, $rmad) {
1385         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1386                   \s*( [^ \t|]+ )\s* \|
1387                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1388                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1389         $1 eq $package or die "$rmad $package ?";
1390         my $vsn = $2;
1391         my $newsuite = $3;
1392         my $component;
1393         if (defined $4) {
1394             $component = $4;
1395         } else {
1396             $component = access_cfg('archive-query-default-component');
1397         }
1398         $5 eq 'source' or die "$rmad ?";
1399         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1400     }
1401     return sort { -version_compare($a->[0],$b->[0]); } @out;
1402 }
1403
1404 sub canonicalise_suite_madison {
1405     # madison canonicalises for us
1406     my @r = madison_get_parse(@_);
1407     @r or fail
1408         "unable to canonicalise suite using package $package".
1409         " which does not appear to exist in suite $isuite;".
1410         " --existing-package may help";
1411     return $r[0][2];
1412 }
1413
1414 sub file_in_archive_madison { return undef; }
1415
1416 #---------- `sshpsql' archive query method ----------
1417
1418 sub sshpsql ($$$) {
1419     my ($data,$runeinfo,$sql) = @_;
1420     if (!length $data) {
1421         $data= access_someuserhost('sshpsql').':'.
1422             access_cfg('sshpsql-dbname');
1423     }
1424     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1425     my ($userhost,$dbname) = ($`,$'); #';
1426     my @rows;
1427     my @cmd = (access_cfg_ssh, $userhost,
1428                access_runeinfo("ssh-psql $runeinfo").
1429                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1430                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1431     debugcmd "|",@cmd;
1432     open P, "-|", @cmd or die $!;
1433     while (<P>) {
1434         chomp or die;
1435         printdebug(">|$_|\n");
1436         push @rows, $_;
1437     }
1438     $!=0; $?=0; close P or failedcmd @cmd;
1439     @rows or die;
1440     my $nrows = pop @rows;
1441     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1442     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1443     @rows = map { [ split /\|/, $_ ] } @rows;
1444     my $ncols = scalar @{ shift @rows };
1445     die if grep { scalar @$_ != $ncols } @rows;
1446     return @rows;
1447 }
1448
1449 sub sql_injection_check {
1450     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1451 }
1452
1453 sub archive_query_sshpsql ($$) {
1454     my ($proto,$data) = @_;
1455     sql_injection_check $isuite, $package;
1456     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1457         SELECT source.version, component.name, files.filename, files.sha256sum
1458           FROM source
1459           JOIN src_associations ON source.id = src_associations.source
1460           JOIN suite ON suite.id = src_associations.suite
1461           JOIN dsc_files ON dsc_files.source = source.id
1462           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1463           JOIN component ON component.id = files_archive_map.component_id
1464           JOIN files ON files.id = dsc_files.file
1465          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1466            AND source.source='$package'
1467            AND files.filename LIKE '%.dsc';
1468 END
1469     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1470     my $digester = Digest::SHA->new(256);
1471     @rows = map {
1472         my ($vsn,$component,$filename,$sha256sum) = @$_;
1473         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1474     } @rows;
1475     return archive_query_prepend_mirror @rows;
1476 }
1477
1478 sub canonicalise_suite_sshpsql ($$) {
1479     my ($proto,$data) = @_;
1480     sql_injection_check $isuite;
1481     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1482         SELECT suite.codename
1483           FROM suite where suite_name='$isuite' or codename='$isuite';
1484 END
1485     @rows = map { $_->[0] } @rows;
1486     fail "unknown suite $isuite" unless @rows;
1487     die "ambiguous $isuite: @rows ?" if @rows>1;
1488     return $rows[0];
1489 }
1490
1491 sub file_in_archive_sshpsql ($$$) { return undef; }
1492
1493 #---------- `dummycat' archive query method ----------
1494
1495 sub canonicalise_suite_dummycat ($$) {
1496     my ($proto,$data) = @_;
1497     my $dpath = "$data/suite.$isuite";
1498     if (!open C, "<", $dpath) {
1499         $!==ENOENT or die "$dpath: $!";
1500         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1501         return $isuite;
1502     }
1503     $!=0; $_ = <C>;
1504     chomp or die "$dpath: $!";
1505     close C;
1506     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1507     return $_;
1508 }
1509
1510 sub archive_query_dummycat ($$) {
1511     my ($proto,$data) = @_;
1512     canonicalise_suite();
1513     my $dpath = "$data/package.$csuite.$package";
1514     if (!open C, "<", $dpath) {
1515         $!==ENOENT or die "$dpath: $!";
1516         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1517         return ();
1518     }
1519     my @rows;
1520     while (<C>) {
1521         next if m/^\#/;
1522         next unless m/\S/;
1523         die unless chomp;
1524         printdebug "dummycat query $csuite $package $dpath | $_\n";
1525         my @row = split /\s+/, $_;
1526         @row==2 or die "$dpath: $_ ?";
1527         push @rows, \@row;
1528     }
1529     C->error and die "$dpath: $!";
1530     close C;
1531     return archive_query_prepend_mirror
1532         sort { -version_compare($a->[0],$b->[0]); } @rows;
1533 }
1534
1535 sub file_in_archive_dummycat () { return undef; }
1536
1537 #---------- tag format handling ----------
1538
1539 sub access_cfg_tagformats () {
1540     split /\,/, access_cfg('dgit-tag-format');
1541 }
1542
1543 sub access_cfg_tagformats_can_splitbrain () {
1544     my %y = map { $_ => 1 } access_cfg_tagformats;
1545     foreach my $needtf (qw(new maint)) {
1546         next if $y{$needtf};
1547         return 0;
1548     }
1549     return 1;
1550 }
1551
1552 sub need_tagformat ($$) {
1553     my ($fmt, $why) = @_;
1554     fail "need to use tag format $fmt ($why) but also need".
1555         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1556         " - no way to proceed"
1557         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1558     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1559 }
1560
1561 sub select_tagformat () {
1562     # sets $tagformatfn
1563     return if $tagformatfn && !$tagformat_want;
1564     die 'bug' if $tagformatfn && $tagformat_want;
1565     # ... $tagformat_want assigned after previous select_tagformat
1566
1567     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1568     printdebug "select_tagformat supported @supported\n";
1569
1570     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1571     printdebug "select_tagformat specified @$tagformat_want\n";
1572
1573     my ($fmt,$why,$override) = @$tagformat_want;
1574
1575     fail "target distro supports tag formats @supported".
1576         " but have to use $fmt ($why)"
1577         unless $override
1578             or grep { $_ eq $fmt } @supported;
1579
1580     $tagformat_want = undef;
1581     $tagformat = $fmt;
1582     $tagformatfn = ${*::}{"debiantag_$fmt"};
1583
1584     fail "trying to use unknown tag format \`$fmt' ($why) !"
1585         unless $tagformatfn;
1586 }
1587
1588 #---------- archive query entrypoints and rest of program ----------
1589
1590 sub canonicalise_suite () {
1591     return if defined $csuite;
1592     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1593     $csuite = archive_query('canonicalise_suite');
1594     if ($isuite ne $csuite) {
1595         progress "canonical suite name for $isuite is $csuite";
1596     } else {
1597         progress "canonical suite name is $csuite";
1598     }
1599 }
1600
1601 sub get_archive_dsc () {
1602     canonicalise_suite();
1603     my @vsns = archive_query('archive_query');
1604     foreach my $vinfo (@vsns) {
1605         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1606         $dscurl = $vsn_dscurl;
1607         $dscdata = url_get($dscurl);
1608         if (!$dscdata) {
1609             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1610             next;
1611         }
1612         if ($digester) {
1613             $digester->reset();
1614             $digester->add($dscdata);
1615             my $got = $digester->hexdigest();
1616             $got eq $digest or
1617                 fail "$dscurl has hash $got but".
1618                     " archive told us to expect $digest";
1619         }
1620         parse_dscdata();
1621         my $fmt = getfield $dsc, 'Format';
1622         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1623             "unsupported source format $fmt, sorry";
1624
1625         $dsc_checked = !!$digester;
1626         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1627         return;
1628     }
1629     $dsc = undef;
1630     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1631 }
1632
1633 sub check_for_git ();
1634 sub check_for_git () {
1635     # returns 0 or 1
1636     my $how = access_cfg('git-check');
1637     if ($how eq 'ssh-cmd') {
1638         my @cmd =
1639             (access_cfg_ssh, access_gituserhost(),
1640              access_runeinfo("git-check $package").
1641              " set -e; cd ".access_cfg('git-path').";".
1642              " if test -d $package.git; then echo 1; else echo 0; fi");
1643         my $r= cmdoutput @cmd;
1644         if (defined $r and $r =~ m/^divert (\w+)$/) {
1645             my $divert=$1;
1646             my ($usedistro,) = access_distros();
1647             # NB that if we are pushing, $usedistro will be $distro/push
1648             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1649             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1650             progress "diverting to $divert (using config for $instead_distro)";
1651             return check_for_git();
1652         }
1653         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1654         return $r+0;
1655     } elsif ($how eq 'url') {
1656         my $prefix = access_cfg('git-check-url','git-url');
1657         my $suffix = access_cfg('git-check-suffix','git-suffix',
1658                                 'RETURN-UNDEF') // '.git';
1659         my $url = "$prefix/$package$suffix";
1660         my @cmd = (@curl, qw(-sS -I), $url);
1661         my $result = cmdoutput @cmd;
1662         $result =~ s/^\S+ 200 .*\n\r?\n//;
1663         # curl -sS -I with https_proxy prints
1664         # HTTP/1.0 200 Connection established
1665         $result =~ m/^\S+ (404|200) /s or
1666             fail "unexpected results from git check query - ".
1667                 Dumper($prefix, $result);
1668         my $code = $1;
1669         if ($code eq '404') {
1670             return 0;
1671         } elsif ($code eq '200') {
1672             return 1;
1673         } else {
1674             die;
1675         }
1676     } elsif ($how eq 'true') {
1677         return 1;
1678     } elsif ($how eq 'false') {
1679         return 0;
1680     } else {
1681         badcfg "unknown git-check \`$how'";
1682     }
1683 }
1684
1685 sub create_remote_git_repo () {
1686     my $how = access_cfg('git-create');
1687     if ($how eq 'ssh-cmd') {
1688         runcmd_ordryrun
1689             (access_cfg_ssh, access_gituserhost(),
1690              access_runeinfo("git-create $package").
1691              "set -e; cd ".access_cfg('git-path').";".
1692              " cp -a _template $package.git");
1693     } elsif ($how eq 'true') {
1694         # nothing to do
1695     } else {
1696         badcfg "unknown git-create \`$how'";
1697     }
1698 }
1699
1700 our ($dsc_hash,$lastpush_mergeinput);
1701 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1702
1703 our $ud = '.git/dgit/unpack';
1704
1705 sub prep_ud (;$) {
1706     my ($d) = @_;
1707     $d //= $ud;
1708     rmtree($d);
1709     mkpath '.git/dgit';
1710     mkdir $d or die $!;
1711 }
1712
1713 sub mktree_in_ud_here () {
1714     runcmd qw(git init -q);
1715     runcmd qw(git config gc.auto 0);
1716     foreach my $copy (qw(user.email user.name user.useConfigOnly
1717                          core.sharedRepository
1718                          core.compression core.looseCompression
1719                          core.bigFileThreshold core.fsyncObjectFiles)) {
1720         my $v = $gitcfgs{local}{$copy};
1721         next unless $v;
1722         runcmd qw(git config), $copy, $_ foreach @$v;
1723     }
1724     rmtree('.git/objects');
1725     symlink '../../../../objects','.git/objects' or die $!;
1726     setup_gitattrs(1);
1727 }
1728
1729 sub git_write_tree () {
1730     my $tree = cmdoutput @git, qw(write-tree);
1731     $tree =~ m/^\w+$/ or die "$tree ?";
1732     return $tree;
1733 }
1734
1735 sub git_add_write_tree () {
1736     runcmd @git, qw(add -Af .);
1737     return git_write_tree();
1738 }
1739
1740 sub remove_stray_gits ($) {
1741     my ($what) = @_;
1742     my @gitscmd = qw(find -name .git -prune -print0);
1743     debugcmd "|",@gitscmd;
1744     open GITS, "-|", @gitscmd or die $!;
1745     {
1746         local $/="\0";
1747         while (<GITS>) {
1748             chomp or die;
1749             print STDERR "$us: warning: removing from $what: ",
1750                 (messagequote $_), "\n";
1751             rmtree $_;
1752         }
1753     }
1754     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1755 }
1756
1757 sub mktree_in_ud_from_only_subdir ($;$) {
1758     my ($what,$raw) = @_;
1759
1760     # changes into the subdir
1761     my (@dirs) = <*/.>;
1762     die "expected one subdir but found @dirs ?" unless @dirs==1;
1763     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1764     my $dir = $1;
1765     changedir $dir;
1766
1767     remove_stray_gits($what);
1768     mktree_in_ud_here();
1769     if (!$raw) {
1770         my ($format, $fopts) = get_source_format();
1771         if (madformat($format)) {
1772             rmtree '.pc';
1773         }
1774     }
1775
1776     my $tree=git_add_write_tree();
1777     return ($tree,$dir);
1778 }
1779
1780 our @files_csum_info_fields =
1781     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1782      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1783      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1784
1785 sub dsc_files_info () {
1786     foreach my $csumi (@files_csum_info_fields) {
1787         my ($fname, $module, $method) = @$csumi;
1788         my $field = $dsc->{$fname};
1789         next unless defined $field;
1790         eval "use $module; 1;" or die $@;
1791         my @out;
1792         foreach (split /\n/, $field) {
1793             next unless m/\S/;
1794             m/^(\w+) (\d+) (\S+)$/ or
1795                 fail "could not parse .dsc $fname line \`$_'";
1796             my $digester = eval "$module"."->$method;" or die $@;
1797             push @out, {
1798                 Hash => $1,
1799                 Bytes => $2,
1800                 Filename => $3,
1801                 Digester => $digester,
1802             };
1803         }
1804         return @out;
1805     }
1806     fail "missing any supported Checksums-* or Files field in ".
1807         $dsc->get_option('name');
1808 }
1809
1810 sub dsc_files () {
1811     map { $_->{Filename} } dsc_files_info();
1812 }
1813
1814 sub files_compare_inputs (@) {
1815     my $inputs = \@_;
1816     my %record;
1817     my %fchecked;
1818
1819     my $showinputs = sub {
1820         return join "; ", map { $_->get_option('name') } @$inputs;
1821     };
1822
1823     foreach my $in (@$inputs) {
1824         my $expected_files;
1825         my $in_name = $in->get_option('name');
1826
1827         printdebug "files_compare_inputs $in_name\n";
1828
1829         foreach my $csumi (@files_csum_info_fields) {
1830             my ($fname) = @$csumi;
1831             printdebug "files_compare_inputs $in_name $fname\n";
1832
1833             my $field = $in->{$fname};
1834             next unless defined $field;
1835
1836             my @files;
1837             foreach (split /\n/, $field) {
1838                 next unless m/\S/;
1839
1840                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1841                     fail "could not parse $in_name $fname line \`$_'";
1842
1843                 printdebug "files_compare_inputs $in_name $fname $f\n";
1844
1845                 push @files, $f;
1846
1847                 my $re = \ $record{$f}{$fname};
1848                 if (defined $$re) {
1849                     $fchecked{$f}{$in_name} = 1;
1850                     $$re eq $info or
1851                         fail "hash or size of $f varies in $fname fields".
1852                         " (between: ".$showinputs->().")";
1853                 } else {
1854                     $$re = $info;
1855                 }
1856             }
1857             @files = sort @files;
1858             $expected_files //= \@files;
1859             "@$expected_files" eq "@files" or
1860                 fail "file list in $in_name varies between hash fields!";
1861         }
1862         $expected_files or
1863             fail "$in_name has no files list field(s)";
1864     }
1865     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1866         if $debuglevel>=2;
1867
1868     grep { keys %$_ == @$inputs-1 } values %fchecked
1869         or fail "no file appears in all file lists".
1870         " (looked in: ".$showinputs->().")";
1871 }
1872
1873 sub is_orig_file_in_dsc ($$) {
1874     my ($f, $dsc_files_info) = @_;
1875     return 0 if @$dsc_files_info <= 1;
1876     # One file means no origs, and the filename doesn't have a "what
1877     # part of dsc" component.  (Consider versions ending `.orig'.)
1878     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1879     return 1;
1880 }
1881
1882 sub is_orig_file_of_vsn ($$) {
1883     my ($f, $upstreamvsn) = @_;
1884     my $base = srcfn $upstreamvsn, '';
1885     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1886     return 1;
1887 }
1888
1889 sub changes_update_origs_from_dsc ($$$$) {
1890     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1891     my %changes_f;
1892     printdebug "checking origs needed ($upstreamvsn)...\n";
1893     $_ = getfield $changes, 'Files';
1894     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1895         fail "cannot find section/priority from .changes Files field";
1896     my $placementinfo = $1;
1897     my %changed;
1898     printdebug "checking origs needed placement '$placementinfo'...\n";
1899     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1900         $l =~ m/\S+$/ or next;
1901         my $file = $&;
1902         printdebug "origs $file | $l\n";
1903         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1904         printdebug "origs $file is_orig\n";
1905         my $have = archive_query('file_in_archive', $file);
1906         if (!defined $have) {
1907             print STDERR <<END;
1908 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1909 END
1910             return;
1911         }
1912         my $found_same = 0;
1913         my @found_differ;
1914         printdebug "origs $file \$#\$have=$#$have\n";
1915         foreach my $h (@$have) {
1916             my $same = 0;
1917             my @differ;
1918             foreach my $csumi (@files_csum_info_fields) {
1919                 my ($fname, $module, $method, $archivefield) = @$csumi;
1920                 next unless defined $h->{$archivefield};
1921                 $_ = $dsc->{$fname};
1922                 next unless defined;
1923                 m/^(\w+) .* \Q$file\E$/m or
1924                     fail ".dsc $fname missing entry for $file";
1925                 if ($h->{$archivefield} eq $1) {
1926                     $same++;
1927                 } else {
1928                     push @differ,
1929  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1930                 }
1931             }
1932             die "$file ".Dumper($h)." ?!" if $same && @differ;
1933             $found_same++
1934                 if $same;
1935             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1936                 if @differ;
1937         }
1938         printdebug "origs $file f.same=$found_same".
1939             " #f._differ=$#found_differ\n";
1940         if (@found_differ && !$found_same) {
1941             fail join "\n",
1942                 "archive contains $file with different checksum",
1943                 @found_differ;
1944         }
1945         # Now we edit the changes file to add or remove it
1946         foreach my $csumi (@files_csum_info_fields) {
1947             my ($fname, $module, $method, $archivefield) = @$csumi;
1948             next unless defined $changes->{$fname};
1949             if ($found_same) {
1950                 # in archive, delete from .changes if it's there
1951                 $changed{$file} = "removed" if
1952                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1953             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1954                 # not in archive, but it's here in the .changes
1955             } else {
1956                 my $dsc_data = getfield $dsc, $fname;
1957                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1958                 my $extra = $1;
1959                 $extra =~ s/ \d+ /$&$placementinfo /
1960                     or die "$fname $extra >$dsc_data< ?"
1961                     if $fname eq 'Files';
1962                 $changes->{$fname} .= "\n". $extra;
1963                 $changed{$file} = "added";
1964             }
1965         }
1966     }
1967     if (%changed) {
1968         foreach my $file (keys %changed) {
1969             progress sprintf
1970                 "edited .changes for archive .orig contents: %s %s",
1971                 $changed{$file}, $file;
1972         }
1973         my $chtmp = "$changesfile.tmp";
1974         $changes->save($chtmp);
1975         if (act_local()) {
1976             rename $chtmp,$changesfile or die "$changesfile $!";
1977         } else {
1978             progress "[new .changes left in $changesfile]";
1979         }
1980     } else {
1981         progress "$changesfile already has appropriate .orig(s) (if any)";
1982     }
1983 }
1984
1985 sub make_commit ($) {
1986     my ($file) = @_;
1987     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1988 }
1989
1990 sub make_commit_text ($) {
1991     my ($text) = @_;
1992     my ($out, $in);
1993     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1994     debugcmd "|",@cmd;
1995     print Dumper($text) if $debuglevel > 1;
1996     my $child = open2($out, $in, @cmd) or die $!;
1997     my $h;
1998     eval {
1999         print $in $text or die $!;
2000         close $in or die $!;
2001         $h = <$out>;
2002         $h =~ m/^\w+$/ or die;
2003         $h = $&;
2004         printdebug "=> $h\n";
2005     };
2006     close $out;
2007     waitpid $child, 0 == $child or die "$child $!";
2008     $? and failedcmd @cmd;
2009     return $h;
2010 }
2011
2012 sub clogp_authline ($) {
2013     my ($clogp) = @_;
2014     my $author = getfield $clogp, 'Maintainer';
2015     if ($author =~ m/^[^"\@]+\,/) {
2016         # single entry Maintainer field with unquoted comma
2017         $author = ($& =~ y/,//rd).$'; # strip the comma
2018     }
2019     # git wants a single author; any remaining commas in $author
2020     # are by now preceded by @ (or ").  It seems safer to punt on
2021     # "..." for now rather than attempting to dequote or something.
2022     $author =~ s#,.*##ms unless $author =~ m/"/;
2023     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2024     my $authline = "$author $date";
2025     $authline =~ m/$git_authline_re/o or
2026         fail "unexpected commit author line format \`$authline'".
2027         " (was generated from changelog Maintainer field)";
2028     return ($1,$2,$3) if wantarray;
2029     return $authline;
2030 }
2031
2032 sub vendor_patches_distro ($$) {
2033     my ($checkdistro, $what) = @_;
2034     return unless defined $checkdistro;
2035
2036     my $series = "debian/patches/\L$checkdistro\E.series";
2037     printdebug "checking for vendor-specific $series ($what)\n";
2038
2039     if (!open SERIES, "<", $series) {
2040         die "$series $!" unless $!==ENOENT;
2041         return;
2042     }
2043     while (<SERIES>) {
2044         next unless m/\S/;
2045         next if m/^\s+\#/;
2046
2047         print STDERR <<END;
2048
2049 Unfortunately, this source package uses a feature of dpkg-source where
2050 the same source package unpacks to different source code on different
2051 distros.  dgit cannot safely operate on such packages on affected
2052 distros, because the meaning of source packages is not stable.
2053
2054 Please ask the distro/maintainer to remove the distro-specific series
2055 files and use a different technique (if necessary, uploading actually
2056 different packages, if different distros are supposed to have
2057 different code).
2058
2059 END
2060         fail "Found active distro-specific series file for".
2061             " $checkdistro ($what): $series, cannot continue";
2062     }
2063     die "$series $!" if SERIES->error;
2064     close SERIES;
2065 }
2066
2067 sub check_for_vendor_patches () {
2068     # This dpkg-source feature doesn't seem to be documented anywhere!
2069     # But it can be found in the changelog (reformatted):
2070
2071     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2072     #   Author: Raphael Hertzog <hertzog@debian.org>
2073     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2074
2075     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2076     #   series files
2077     #
2078     #   If you have debian/patches/ubuntu.series and you were
2079     #   unpacking the source package on ubuntu, quilt was still
2080     #   directed to debian/patches/series instead of
2081     #   debian/patches/ubuntu.series.
2082     #
2083     #   debian/changelog                        |    3 +++
2084     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2085     #   2 files changed, 6 insertions(+), 1 deletion(-)
2086
2087     use Dpkg::Vendor;
2088     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2089     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2090                          "Dpkg::Vendor \`current vendor'");
2091     vendor_patches_distro(access_basedistro(),
2092                           "(base) distro being accessed");
2093     vendor_patches_distro(access_nomdistro(),
2094                           "(nominal) distro being accessed");
2095 }
2096
2097 sub generate_commits_from_dsc () {
2098     # See big comment in fetch_from_archive, below.
2099     # See also README.dsc-import.
2100     prep_ud();
2101     changedir $ud;
2102
2103     my @dfi = dsc_files_info();
2104     foreach my $fi (@dfi) {
2105         my $f = $fi->{Filename};
2106         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2107         my $upper_f = "../../../../$f";
2108
2109         printdebug "considering reusing $f: ";
2110
2111         if (link_ltarget "$upper_f,fetch", $f) {
2112             printdebug "linked (using ...,fetch).\n";
2113         } elsif ((printdebug "($!) "),
2114                  $! != ENOENT) {
2115             fail "accessing ../$f,fetch: $!";
2116         } elsif (link_ltarget $upper_f, $f) {
2117             printdebug "linked.\n";
2118         } elsif ((printdebug "($!) "),
2119                  $! != ENOENT) {
2120             fail "accessing ../$f: $!";
2121         } else {
2122             printdebug "absent.\n";
2123         }
2124
2125         my $refetched;
2126         complete_file_from_dsc('.', $fi, \$refetched)
2127             or next;
2128
2129         printdebug "considering saving $f: ";
2130
2131         if (link $f, $upper_f) {
2132             printdebug "linked.\n";
2133         } elsif ((printdebug "($!) "),
2134                  $! != EEXIST) {
2135             fail "saving ../$f: $!";
2136         } elsif (!$refetched) {
2137             printdebug "no need.\n";
2138         } elsif (link $f, "$upper_f,fetch") {
2139             printdebug "linked (using ...,fetch).\n";
2140         } elsif ((printdebug "($!) "),
2141                  $! != EEXIST) {
2142             fail "saving ../$f,fetch: $!";
2143         } else {
2144             printdebug "cannot.\n";
2145         }
2146     }
2147
2148     # We unpack and record the orig tarballs first, so that we only
2149     # need disk space for one private copy of the unpacked source.
2150     # But we can't make them into commits until we have the metadata
2151     # from the debian/changelog, so we record the tree objects now and
2152     # make them into commits later.
2153     my @tartrees;
2154     my $upstreamv = upstreamversion $dsc->{version};
2155     my $orig_f_base = srcfn $upstreamv, '';
2156
2157     foreach my $fi (@dfi) {
2158         # We actually import, and record as a commit, every tarball
2159         # (unless there is only one file, in which case there seems
2160         # little point.
2161
2162         my $f = $fi->{Filename};
2163         printdebug "import considering $f ";
2164         (printdebug "only one dfi\n"), next if @dfi == 1;
2165         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2166         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2167         my $compr_ext = $1;
2168
2169         my ($orig_f_part) =
2170             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2171
2172         printdebug "Y ", (join ' ', map { $_//"(none)" }
2173                           $compr_ext, $orig_f_part
2174                          ), "\n";
2175
2176         my $input = new IO::File $f, '<' or die "$f $!";
2177         my $compr_pid;
2178         my @compr_cmd;
2179
2180         if (defined $compr_ext) {
2181             my $cname =
2182                 Dpkg::Compression::compression_guess_from_filename $f;
2183             fail "Dpkg::Compression cannot handle file $f in source package"
2184                 if defined $compr_ext && !defined $cname;
2185             my $compr_proc =
2186                 new Dpkg::Compression::Process compression => $cname;
2187             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2188             my $compr_fh = new IO::Handle;
2189             my $compr_pid = open $compr_fh, "-|" // die $!;
2190             if (!$compr_pid) {
2191                 open STDIN, "<&", $input or die $!;
2192                 exec @compr_cmd;
2193                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2194             }
2195             $input = $compr_fh;
2196         }
2197
2198         rmtree "_unpack-tar";
2199         mkdir "_unpack-tar" or die $!;
2200         my @tarcmd = qw(tar -x -f -
2201                         --no-same-owner --no-same-permissions
2202                         --no-acls --no-xattrs --no-selinux);
2203         my $tar_pid = fork // die $!;
2204         if (!$tar_pid) {
2205             chdir "_unpack-tar" or die $!;
2206             open STDIN, "<&", $input or die $!;
2207             exec @tarcmd;
2208             die "dgit (child): exec $tarcmd[0]: $!";
2209         }
2210         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2211         !$? or failedcmd @tarcmd;
2212
2213         close $input or
2214             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2215              : die $!);
2216         # finally, we have the results in "tarball", but maybe
2217         # with the wrong permissions
2218
2219         runcmd qw(chmod -R +rwX _unpack-tar);
2220         changedir "_unpack-tar";
2221         remove_stray_gits($f);
2222         mktree_in_ud_here();
2223
2224         my ($tree) = git_add_write_tree();
2225         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2226         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2227             $tree = $1;
2228             printdebug "one subtree $1\n";
2229         } else {
2230             printdebug "multiple subtrees\n";
2231         }
2232         changedir "..";
2233         rmtree "_unpack-tar";
2234
2235         my $ent = [ $f, $tree ];
2236         push @tartrees, {
2237             Orig => !!$orig_f_part,
2238             Sort => (!$orig_f_part         ? 2 :
2239                      $orig_f_part =~ m/-/g ? 1 :
2240                                              0),
2241             F => $f,
2242             Tree => $tree,
2243         };
2244     }
2245
2246     @tartrees = sort {
2247         # put any without "_" first (spec is not clear whether files
2248         # are always in the usual order).  Tarballs without "_" are
2249         # the main orig or the debian tarball.
2250         $a->{Sort} <=> $b->{Sort} or
2251         $a->{F}    cmp $b->{F}
2252     } @tartrees;
2253
2254     my $any_orig = grep { $_->{Orig} } @tartrees;
2255
2256     my $dscfn = "$package.dsc";
2257
2258     my $treeimporthow = 'package';
2259
2260     open D, ">", $dscfn or die "$dscfn: $!";
2261     print D $dscdata or die "$dscfn: $!";
2262     close D or die "$dscfn: $!";
2263     my @cmd = qw(dpkg-source);
2264     push @cmd, '--no-check' if $dsc_checked;
2265     if (madformat $dsc->{format}) {
2266         push @cmd, '--skip-patches';
2267         $treeimporthow = 'unpatched';
2268     }
2269     push @cmd, qw(-x --), $dscfn;
2270     runcmd @cmd;
2271
2272     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2273     if (madformat $dsc->{format}) {
2274         check_for_vendor_patches();
2275     }
2276
2277     my $dappliedtree;
2278     if (madformat $dsc->{format}) {
2279         my @pcmd = qw(dpkg-source --before-build .);
2280         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2281         rmtree '.pc';
2282         $dappliedtree = git_add_write_tree();
2283     }
2284
2285     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2286     debugcmd "|",@clogcmd;
2287     open CLOGS, "-|", @clogcmd or die $!;
2288
2289     my $clogp;
2290     my $r1clogp;
2291
2292     printdebug "import clog search...\n";
2293
2294     for (;;) {
2295         my $stanzatext = do { local $/=""; <CLOGS>; };
2296         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2297         last if !defined $stanzatext;
2298
2299         my $desc = "package changelog, entry no.$.";
2300         open my $stanzafh, "<", \$stanzatext or die;
2301         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2302         $clogp //= $thisstanza;
2303
2304         printdebug "import clog $thisstanza->{version} $desc...\n";
2305
2306         last if !$any_orig; # we don't need $r1clogp
2307
2308         # We look for the first (most recent) changelog entry whose
2309         # version number is lower than the upstream version of this
2310         # package.  Then the last (least recent) previous changelog
2311         # entry is treated as the one which introduced this upstream
2312         # version and used for the synthetic commits for the upstream
2313         # tarballs.
2314
2315         # One might think that a more sophisticated algorithm would be
2316         # necessary.  But: we do not want to scan the whole changelog
2317         # file.  Stopping when we see an earlier version, which
2318         # necessarily then is an earlier upstream version, is the only
2319         # realistic way to do that.  Then, either the earliest
2320         # changelog entry we have seen so far is indeed the earliest
2321         # upload of this upstream version; or there are only changelog
2322         # entries relating to later upstream versions (which is not
2323         # possible unless the changelog and .dsc disagree about the
2324         # version).  Then it remains to choose between the physically
2325         # last entry in the file, and the one with the lowest version
2326         # number.  If these are not the same, we guess that the
2327         # versions were created in a non-monotic order rather than
2328         # that the changelog entries have been misordered.
2329
2330         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2331
2332         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2333         $r1clogp = $thisstanza;
2334
2335         printdebug "import clog $r1clogp->{version} becomes r1\n";
2336     }
2337     die $! if CLOGS->error;
2338     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2339
2340     $clogp or fail "package changelog has no entries!";
2341
2342     my $authline = clogp_authline $clogp;
2343     my $changes = getfield $clogp, 'Changes';
2344     $changes =~ s/^\n//; # Changes: \n
2345     my $cversion = getfield $clogp, 'Version';
2346
2347     if (@tartrees) {
2348         $r1clogp //= $clogp; # maybe there's only one entry;
2349         my $r1authline = clogp_authline $r1clogp;
2350         # Strictly, r1authline might now be wrong if it's going to be
2351         # unused because !$any_orig.  Whatever.
2352
2353         printdebug "import tartrees authline   $authline\n";
2354         printdebug "import tartrees r1authline $r1authline\n";
2355
2356         foreach my $tt (@tartrees) {
2357             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2358
2359             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2360 tree $tt->{Tree}
2361 author $r1authline
2362 committer $r1authline
2363
2364 Import $tt->{F}
2365
2366 [dgit import orig $tt->{F}]
2367 END_O
2368 tree $tt->{Tree}
2369 author $authline
2370 committer $authline
2371
2372 Import $tt->{F}
2373
2374 [dgit import tarball $package $cversion $tt->{F}]
2375 END_T
2376         }
2377     }
2378
2379     printdebug "import main commit\n";
2380
2381     open C, ">../commit.tmp" or die $!;
2382     print C <<END or die $!;
2383 tree $tree
2384 END
2385     print C <<END or die $! foreach @tartrees;
2386 parent $_->{Commit}
2387 END
2388     print C <<END or die $!;
2389 author $authline
2390 committer $authline
2391
2392 $changes
2393
2394 [dgit import $treeimporthow $package $cversion]
2395 END
2396
2397     close C or die $!;
2398     my $rawimport_hash = make_commit qw(../commit.tmp);
2399
2400     if (madformat $dsc->{format}) {
2401         printdebug "import apply patches...\n";
2402
2403         # regularise the state of the working tree so that
2404         # the checkout of $rawimport_hash works nicely.
2405         my $dappliedcommit = make_commit_text(<<END);
2406 tree $dappliedtree
2407 author $authline
2408 committer $authline
2409
2410 [dgit dummy commit]
2411 END
2412         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2413
2414         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2415
2416         # We need the answers to be reproducible
2417         my @authline = clogp_authline($clogp);
2418         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2419         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2420         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2421         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2422         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2423         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2424
2425         my $path = $ENV{PATH} or die;
2426
2427         foreach my $use_absurd (qw(0 1)) {
2428             runcmd @git, qw(checkout -q unpa);
2429             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2430             local $ENV{PATH} = $path;
2431             if ($use_absurd) {
2432                 chomp $@;
2433                 progress "warning: $@";
2434                 $path = "$absurdity:$path";
2435                 progress "$us: trying slow absurd-git-apply...";
2436                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2437                     or $!==ENOENT
2438                     or die $!;
2439             }
2440             eval {
2441                 die "forbid absurd git-apply\n" if $use_absurd
2442                     && forceing [qw(import-gitapply-no-absurd)];
2443                 die "only absurd git-apply!\n" if !$use_absurd
2444                     && forceing [qw(import-gitapply-absurd)];
2445
2446                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2447                 local $ENV{PATH} = $path                    if $use_absurd;
2448
2449                 my @showcmd = (gbp_pq, qw(import));
2450                 my @realcmd = shell_cmd
2451                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2452                 debugcmd "+",@realcmd;
2453                 if (system @realcmd) {
2454                     die +(shellquote @showcmd).
2455                         " failed: ".
2456                         failedcmd_waitstatus()."\n";
2457                 }
2458
2459                 my $gapplied = git_rev_parse('HEAD');
2460                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2461                 $gappliedtree eq $dappliedtree or
2462                     fail <<END;
2463 gbp-pq import and dpkg-source disagree!
2464  gbp-pq import gave commit $gapplied
2465  gbp-pq import gave tree $gappliedtree
2466  dpkg-source --before-build gave tree $dappliedtree
2467 END
2468                 $rawimport_hash = $gapplied;
2469             };
2470             last unless $@;
2471         }
2472         if ($@) {
2473             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2474             die $@;
2475         }
2476     }
2477
2478     progress "synthesised git commit from .dsc $cversion";
2479
2480     my $rawimport_mergeinput = {
2481         Commit => $rawimport_hash,
2482         Info => "Import of source package",
2483     };
2484     my @output = ($rawimport_mergeinput);
2485
2486     if ($lastpush_mergeinput) {
2487         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2488         my $oversion = getfield $oldclogp, 'Version';
2489         my $vcmp =
2490             version_compare($oversion, $cversion);
2491         if ($vcmp < 0) {
2492             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2493                 { Message => <<END, ReverseParents => 1 });
2494 Record $package ($cversion) in archive suite $csuite
2495 END
2496         } elsif ($vcmp > 0) {
2497             print STDERR <<END or die $!;
2498
2499 Version actually in archive:   $cversion (older)
2500 Last version pushed with dgit: $oversion (newer or same)
2501 $later_warning_msg
2502 END
2503             @output = $lastpush_mergeinput;
2504         } else {
2505             # Same version.  Use what's in the server git branch,
2506             # discarding our own import.  (This could happen if the
2507             # server automatically imports all packages into git.)
2508             @output = $lastpush_mergeinput;
2509         }
2510     }
2511     changedir '../../../..';
2512     rmtree($ud);
2513     return @output;
2514 }
2515
2516 sub complete_file_from_dsc ($$;$) {
2517     our ($dstdir, $fi, $refetched) = @_;
2518     # Ensures that we have, in $dstdir, the file $fi, with the correct
2519     # contents.  (Downloading it from alongside $dscurl if necessary.)
2520     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2521     # and will set $$refetched=1 if it did so (or tried to).
2522
2523     my $f = $fi->{Filename};
2524     my $tf = "$dstdir/$f";
2525     my $downloaded = 0;
2526
2527     my $got;
2528     my $checkhash = sub {
2529         open F, "<", "$tf" or die "$tf: $!";
2530         $fi->{Digester}->reset();
2531         $fi->{Digester}->addfile(*F);
2532         F->error and die $!;
2533         $got = $fi->{Digester}->hexdigest();
2534         return $got eq $fi->{Hash};
2535     };
2536
2537     if (stat_exists $tf) {
2538         if ($checkhash->()) {
2539             progress "using existing $f";
2540             return 1;
2541         }
2542         if (!$refetched) {
2543             fail "file $f has hash $got but .dsc".
2544                 " demands hash $fi->{Hash} ".
2545                 "(perhaps you should delete this file?)";
2546         }
2547         progress "need to fetch correct version of $f";
2548         unlink $tf or die "$tf $!";
2549         $$refetched = 1;
2550     } else {
2551         printdebug "$tf does not exist, need to fetch\n";
2552     }
2553
2554     my $furl = $dscurl;
2555     $furl =~ s{/[^/]+$}{};
2556     $furl .= "/$f";
2557     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2558     die "$f ?" if $f =~ m#/#;
2559     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2560     return 0 if !act_local();
2561
2562     $checkhash->() or
2563         fail "file $f has hash $got but .dsc".
2564             " demands hash $fi->{Hash} ".
2565             "(got wrong file from archive!)";
2566
2567     return 1;
2568 }
2569
2570 sub ensure_we_have_orig () {
2571     my @dfi = dsc_files_info();
2572     foreach my $fi (@dfi) {
2573         my $f = $fi->{Filename};
2574         next unless is_orig_file_in_dsc($f, \@dfi);
2575         complete_file_from_dsc('..', $fi)
2576             or next;
2577     }
2578 }
2579
2580 #---------- git fetch ----------
2581
2582 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2583 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2584
2585 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2586 # locally fetched refs because they have unhelpful names and clutter
2587 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2588 # whether we have made another local ref which refers to this object).
2589 #
2590 # (If we deleted them unconditionally, then we might end up
2591 # re-fetching the same git objects each time dgit fetch was run.)
2592 #
2593 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2594 # in git_fetch_us to fetch the refs in question, and possibly a call
2595 # to lrfetchref_used.
2596
2597 our (%lrfetchrefs_f, %lrfetchrefs_d);
2598 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2599
2600 sub lrfetchref_used ($) {
2601     my ($fullrefname) = @_;
2602     my $objid = $lrfetchrefs_f{$fullrefname};
2603     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2604 }
2605
2606 sub git_lrfetch_sane {
2607     my ($url, $supplementary, @specs) = @_;
2608     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2609     # at least as regards @specs.  Also leave the results in
2610     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2611     # able to clean these up.
2612     #
2613     # With $supplementary==1, @specs must not contain wildcards
2614     # and we add to our previous fetches (non-atomically).
2615
2616     # This is rather miserable:
2617     # When git fetch --prune is passed a fetchspec ending with a *,
2618     # it does a plausible thing.  If there is no * then:
2619     # - it matches subpaths too, even if the supplied refspec
2620     #   starts refs, and behaves completely madly if the source
2621     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2622     # - if there is no matching remote ref, it bombs out the whole
2623     #   fetch.
2624     # We want to fetch a fixed ref, and we don't know in advance
2625     # if it exists, so this is not suitable.
2626     #
2627     # Our workaround is to use git ls-remote.  git ls-remote has its
2628     # own qairks.  Notably, it has the absurd multi-tail-matching
2629     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2630     # refs/refs/foo etc.
2631     #
2632     # Also, we want an idempotent snapshot, but we have to make two
2633     # calls to the remote: one to git ls-remote and to git fetch.  The
2634     # solution is use git ls-remote to obtain a target state, and
2635     # git fetch to try to generate it.  If we don't manage to generate
2636     # the target state, we try again.
2637
2638     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2639
2640     my $specre = join '|', map {
2641         my $x = $_;
2642         $x =~ s/\W/\\$&/g;
2643         my $wildcard = $x =~ s/\\\*$/.*/;
2644         die if $wildcard && $supplementary;
2645         "(?:refs/$x)";
2646     } @specs;
2647     printdebug "git_lrfetch_sane specre=$specre\n";
2648     my $wanted_rref = sub {
2649         local ($_) = @_;
2650         return m/^(?:$specre)$/;
2651     };
2652
2653     my $fetch_iteration = 0;
2654     FETCH_ITERATION:
2655     for (;;) {
2656         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2657         if (++$fetch_iteration > 10) {
2658             fail "too many iterations trying to get sane fetch!";
2659         }
2660
2661         my @look = map { "refs/$_" } @specs;
2662         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2663         debugcmd "|",@lcmd;
2664
2665         my %wantr;
2666         open GITLS, "-|", @lcmd or die $!;
2667         while (<GITLS>) {
2668             printdebug "=> ", $_;
2669             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2670             my ($objid,$rrefname) = ($1,$2);
2671             if (!$wanted_rref->($rrefname)) {
2672                 print STDERR <<END;
2673 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2674 END
2675                 next;
2676             }
2677             $wantr{$rrefname} = $objid;
2678         }
2679         $!=0; $?=0;
2680         close GITLS or failedcmd @lcmd;
2681
2682         # OK, now %want is exactly what we want for refs in @specs
2683         my @fspecs = map {
2684             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2685             "+refs/$_:".lrfetchrefs."/$_";
2686         } @specs;
2687
2688         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2689
2690         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2691         runcmd_ordryrun_local @fcmd if @fspecs;
2692
2693         if (!$supplementary) {
2694             %lrfetchrefs_f = ();
2695         }
2696         my %objgot;
2697
2698         git_for_each_ref(lrfetchrefs, sub {
2699             my ($objid,$objtype,$lrefname,$reftail) = @_;
2700             $lrfetchrefs_f{$lrefname} = $objid;
2701             $objgot{$objid} = 1;
2702         });
2703
2704         if ($supplementary) {
2705             last;
2706         }
2707
2708         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2709             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2710             if (!exists $wantr{$rrefname}) {
2711                 if ($wanted_rref->($rrefname)) {
2712                     printdebug <<END;
2713 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2714 END
2715                 } else {
2716                     print STDERR <<END
2717 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2718 END
2719                 }
2720                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2721                 delete $lrfetchrefs_f{$lrefname};
2722                 next;
2723             }
2724         }
2725         foreach my $rrefname (sort keys %wantr) {
2726             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2727             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2728             my $want = $wantr{$rrefname};
2729             next if $got eq $want;
2730             if (!defined $objgot{$want}) {
2731                 print STDERR <<END;
2732 warning: git ls-remote suggests we want $lrefname
2733 warning:  and it should refer to $want
2734 warning:  but git fetch didn't fetch that object to any relevant ref.
2735 warning:  This may be due to a race with someone updating the server.
2736 warning:  Will try again...
2737 END
2738                 next FETCH_ITERATION;
2739             }
2740             printdebug <<END;
2741 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2742 END
2743             runcmd_ordryrun_local @git, qw(update-ref -m),
2744                 "dgit fetch git fetch fixup", $lrefname, $want;
2745             $lrfetchrefs_f{$lrefname} = $want;
2746         }
2747         last;
2748     }
2749
2750     if (defined $csuite) {
2751         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2752         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2753             my ($objid,$objtype,$lrefname,$reftail) = @_;
2754             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2755             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2756         });
2757     }
2758
2759     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2760         Dumper(\%lrfetchrefs_f);
2761 }
2762
2763 sub git_fetch_us () {
2764     # Want to fetch only what we are going to use, unless
2765     # deliberately-not-ff, in which case we must fetch everything.
2766
2767     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2768         map { "tags/$_" }
2769         (quiltmode_splitbrain
2770          ? (map { $_->('*',access_nomdistro) }
2771             \&debiantag_new, \&debiantag_maintview)
2772          : debiantags('*',access_nomdistro));
2773     push @specs, server_branch($csuite);
2774     push @specs, $rewritemap;
2775     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2776
2777     my $url = access_giturl();
2778     git_lrfetch_sane $url, 0, @specs;
2779
2780     my %here;
2781     my @tagpats = debiantags('*',access_nomdistro);
2782
2783     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2784         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2785         printdebug "currently $fullrefname=$objid\n";
2786         $here{$fullrefname} = $objid;
2787     });
2788     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2789         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2790         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2791         printdebug "offered $lref=$objid\n";
2792         if (!defined $here{$lref}) {
2793             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2794             runcmd_ordryrun_local @upd;
2795             lrfetchref_used $fullrefname;
2796         } elsif ($here{$lref} eq $objid) {
2797             lrfetchref_used $fullrefname;
2798         } else {
2799             print STDERR
2800                 "Not updating $lref from $here{$lref} to $objid.\n";
2801         }
2802     });
2803 }
2804
2805 #---------- dsc and archive handling ----------
2806
2807 sub mergeinfo_getclogp ($) {
2808     # Ensures thit $mi->{Clogp} exists and returns it
2809     my ($mi) = @_;
2810     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2811 }
2812
2813 sub mergeinfo_version ($) {
2814     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2815 }
2816
2817 sub fetch_from_archive_record_1 ($) {
2818     my ($hash) = @_;
2819     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2820             'DGIT_ARCHIVE', $hash;
2821     cmdoutput @git, qw(log -n2), $hash;
2822     # ... gives git a chance to complain if our commit is malformed
2823 }
2824
2825 sub fetch_from_archive_record_2 ($) {
2826     my ($hash) = @_;
2827     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2828     if (act_local()) {
2829         cmdoutput @upd_cmd;
2830     } else {
2831         dryrun_report @upd_cmd;
2832     }
2833 }
2834
2835 sub parse_dsc_field_def_dsc_distro () {
2836     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2837                            dgit.default.distro);
2838 }
2839
2840 sub parse_dsc_field ($$) {
2841     my ($dsc, $what) = @_;
2842     my $f;
2843     foreach my $field (@ourdscfield) {
2844         $f = $dsc->{$field};
2845         last if defined $f;
2846     }
2847
2848     if (!defined $f) {
2849         progress "$what: NO git hash";
2850         parse_dsc_field_def_dsc_distro();
2851     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2852              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2853         progress "$what: specified git info ($dsc_distro)";
2854         $dsc_hint_tag = [ $dsc_hint_tag ];
2855     } elsif ($f =~ m/^\w+\s*$/) {
2856         $dsc_hash = $&;
2857         parse_dsc_field_def_dsc_distro();
2858         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2859                           $dsc_distro ];
2860         progress "$what: specified git hash";
2861     } else {
2862         fail "$what: invalid Dgit info";
2863     }
2864 }
2865
2866 sub resolve_dsc_field_commit ($$) {
2867     my ($already_distro, $already_mapref) = @_;
2868
2869     return unless defined $dsc_hash;
2870
2871     my $mapref =
2872         defined $already_mapref &&
2873         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2874         ? $already_mapref : undef;
2875
2876     my $do_fetch;
2877     $do_fetch = sub {
2878         my ($what, @fetch) = @_;
2879
2880         local $idistro = $dsc_distro;
2881         my $lrf = lrfetchrefs;
2882
2883         if (!$chase_dsc_distro) {
2884             progress
2885                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2886             return 0;
2887         }
2888
2889         progress
2890             ".dsc names distro $dsc_distro: fetching $what";
2891
2892         my $url = access_giturl();
2893         if (!defined $url) {
2894             defined $dsc_hint_url or fail <<END;
2895 .dsc Dgit metadata is in context of distro $dsc_distro
2896 for which we have no configured url and .dsc provides no hint
2897 END
2898             my $proto =
2899                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2900                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2901             parse_cfg_bool "dsc-url-proto-ok", 'false',
2902                 cfg("dgit.dsc-url-proto-ok.$proto",
2903                     "dgit.default.dsc-url-proto-ok")
2904                 or fail <<END;
2905 .dsc Dgit metadata is in context of distro $dsc_distro
2906 for which we have no configured url;
2907 .dsc provides hinted url with protocol $proto which is unsafe.
2908 (can be overridden by config - consult documentation)
2909 END
2910             $url = $dsc_hint_url;
2911         }
2912
2913         git_lrfetch_sane $url, 1, @fetch;
2914
2915         return $lrf;
2916     };
2917
2918     my $rewrite_enable = do {
2919         local $idistro = $dsc_distro;
2920         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2921     };
2922
2923     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2924         if (!defined $mapref) {
2925             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2926             $mapref = $lrf.'/'.$rewritemap;
2927         }
2928         my $rewritemapdata = git_cat_file $mapref.':map';
2929         if (defined $rewritemapdata
2930             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2931             progress
2932                 "server's git history rewrite map contains a relevant entry!";
2933
2934             $dsc_hash = $1;
2935             if (defined $dsc_hash) {
2936                 progress "using rewritten git hash in place of .dsc value";
2937             } else {
2938                 progress "server data says .dsc hash is to be disregarded";
2939             }
2940         }
2941     }
2942
2943     if (!defined git_cat_file $dsc_hash) {
2944         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2945         my $lrf = $do_fetch->("additional commits", @tags) &&
2946             defined git_cat_file $dsc_hash
2947             or fail <<END;
2948 .dsc Dgit metadata requires commit $dsc_hash
2949 but we could not obtain that object anywhere.
2950 END
2951         foreach my $t (@tags) {
2952             my $fullrefname = $lrf.'/'.$t;
2953 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2954             next unless $lrfetchrefs_f{$fullrefname};
2955             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2956             lrfetchref_used $fullrefname;
2957         }
2958     }
2959 }
2960
2961 sub fetch_from_archive () {
2962     ensure_setup_existing_tree();
2963
2964     # Ensures that lrref() is what is actually in the archive, one way
2965     # or another, according to us - ie this client's
2966     # appropritaely-updated archive view.  Also returns the commit id.
2967     # If there is nothing in the archive, leaves lrref alone and
2968     # returns undef.  git_fetch_us must have already been called.
2969     get_archive_dsc();
2970
2971     if ($dsc) {
2972         parse_dsc_field($dsc, 'last upload to archive');
2973         resolve_dsc_field_commit access_basedistro,
2974             lrfetchrefs."/".$rewritemap
2975     } else {
2976         progress "no version available from the archive";
2977     }
2978
2979     # If the archive's .dsc has a Dgit field, there are three
2980     # relevant git commitids we need to choose between and/or merge
2981     # together:
2982     #   1. $dsc_hash: the Dgit field from the archive
2983     #   2. $lastpush_hash: the suite branch on the dgit git server
2984     #   3. $lastfetch_hash: our local tracking brach for the suite
2985     #
2986     # These may all be distinct and need not be in any fast forward
2987     # relationship:
2988     #
2989     # If the dsc was pushed to this suite, then the server suite
2990     # branch will have been updated; but it might have been pushed to
2991     # a different suite and copied by the archive.  Conversely a more
2992     # recent version may have been pushed with dgit but not appeared
2993     # in the archive (yet).
2994     #
2995     # $lastfetch_hash may be awkward because archive imports
2996     # (particularly, imports of Dgit-less .dscs) are performed only as
2997     # needed on individual clients, so different clients may perform a
2998     # different subset of them - and these imports are only made
2999     # public during push.  So $lastfetch_hash may represent a set of
3000     # imports different to a subsequent upload by a different dgit
3001     # client.
3002     #
3003     # Our approach is as follows:
3004     #
3005     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3006     # descendant of $dsc_hash, then it was pushed by a dgit user who
3007     # had based their work on $dsc_hash, so we should prefer it.
3008     # Otherwise, $dsc_hash was installed into this suite in the
3009     # archive other than by a dgit push, and (necessarily) after the
3010     # last dgit push into that suite (since a dgit push would have
3011     # been descended from the dgit server git branch); thus, in that
3012     # case, we prefer the archive's version (and produce a
3013     # pseudo-merge to overwrite the dgit server git branch).
3014     #
3015     # (If there is no Dgit field in the archive's .dsc then
3016     # generate_commit_from_dsc uses the version numbers to decide
3017     # whether the suite branch or the archive is newer.  If the suite
3018     # branch is newer it ignores the archive's .dsc; otherwise it
3019     # generates an import of the .dsc, and produces a pseudo-merge to
3020     # overwrite the suite branch with the archive contents.)
3021     #
3022     # The outcome of that part of the algorithm is the `public view',
3023     # and is same for all dgit clients: it does not depend on any
3024     # unpublished history in the local tracking branch.
3025     #
3026     # As between the public view and the local tracking branch: The
3027     # local tracking branch is only updated by dgit fetch, and
3028     # whenever dgit fetch runs it includes the public view in the
3029     # local tracking branch.  Therefore if the public view is not
3030     # descended from the local tracking branch, the local tracking
3031     # branch must contain history which was imported from the archive
3032     # but never pushed; and, its tip is now out of date.  So, we make
3033     # a pseudo-merge to overwrite the old imports and stitch the old
3034     # history in.
3035     #
3036     # Finally: we do not necessarily reify the public view (as
3037     # described above).  This is so that we do not end up stacking two
3038     # pseudo-merges.  So what we actually do is figure out the inputs
3039     # to any public view pseudo-merge and put them in @mergeinputs.
3040
3041     my @mergeinputs;
3042     # $mergeinputs[]{Commit}
3043     # $mergeinputs[]{Info}
3044     # $mergeinputs[0] is the one whose tree we use
3045     # @mergeinputs is in the order we use in the actual commit)
3046     #
3047     # Also:
3048     # $mergeinputs[]{Message} is a commit message to use
3049     # $mergeinputs[]{ReverseParents} if def specifies that parent
3050     #                                list should be in opposite order
3051     # Such an entry has no Commit or Info.  It applies only when found
3052     # in the last entry.  (This ugliness is to support making
3053     # identical imports to previous dgit versions.)
3054
3055     my $lastpush_hash = git_get_ref(lrfetchref());
3056     printdebug "previous reference hash=$lastpush_hash\n";
3057     $lastpush_mergeinput = $lastpush_hash && {
3058         Commit => $lastpush_hash,
3059         Info => "dgit suite branch on dgit git server",
3060     };
3061
3062     my $lastfetch_hash = git_get_ref(lrref());
3063     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3064     my $lastfetch_mergeinput = $lastfetch_hash && {
3065         Commit => $lastfetch_hash,
3066         Info => "dgit client's archive history view",
3067     };
3068
3069     my $dsc_mergeinput = $dsc_hash && {
3070         Commit => $dsc_hash,
3071         Info => "Dgit field in .dsc from archive",
3072     };
3073
3074     my $cwd = getcwd();
3075     my $del_lrfetchrefs = sub {
3076         changedir $cwd;
3077         my $gur;
3078         printdebug "del_lrfetchrefs...\n";
3079         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3080             my $objid = $lrfetchrefs_d{$fullrefname};
3081             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3082             if (!$gur) {
3083                 $gur ||= new IO::Handle;
3084                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3085             }
3086             printf $gur "delete %s %s\n", $fullrefname, $objid;
3087         }
3088         if ($gur) {
3089             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3090         }
3091     };
3092
3093     if (defined $dsc_hash) {
3094         ensure_we_have_orig();
3095         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3096             @mergeinputs = $dsc_mergeinput
3097         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3098             print STDERR <<END or die $!;
3099
3100 Git commit in archive is behind the last version allegedly pushed/uploaded.
3101 Commit referred to by archive: $dsc_hash
3102 Last version pushed with dgit: $lastpush_hash
3103 $later_warning_msg
3104 END
3105             @mergeinputs = ($lastpush_mergeinput);
3106         } else {
3107             # Archive has .dsc which is not a descendant of the last dgit
3108             # push.  This can happen if the archive moves .dscs about.
3109             # Just follow its lead.
3110             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3111                 progress "archive .dsc names newer git commit";
3112                 @mergeinputs = ($dsc_mergeinput);
3113             } else {
3114                 progress "archive .dsc names other git commit, fixing up";
3115                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3116             }
3117         }
3118     } elsif ($dsc) {
3119         @mergeinputs = generate_commits_from_dsc();
3120         # We have just done an import.  Now, our import algorithm might
3121         # have been improved.  But even so we do not want to generate
3122         # a new different import of the same package.  So if the
3123         # version numbers are the same, just use our existing version.
3124         # If the version numbers are different, the archive has changed
3125         # (perhaps, rewound).
3126         if ($lastfetch_mergeinput &&
3127             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3128                               (mergeinfo_version $mergeinputs[0]) )) {
3129             @mergeinputs = ($lastfetch_mergeinput);
3130         }
3131     } elsif ($lastpush_hash) {
3132         # only in git, not in the archive yet
3133         @mergeinputs = ($lastpush_mergeinput);
3134         print STDERR <<END or die $!;
3135
3136 Package not found in the archive, but has allegedly been pushed using dgit.
3137 $later_warning_msg
3138 END
3139     } else {
3140         printdebug "nothing found!\n";
3141         if (defined $skew_warning_vsn) {
3142             print STDERR <<END or die $!;
3143
3144 Warning: relevant archive skew detected.
3145 Archive allegedly contains $skew_warning_vsn
3146 But we were not able to obtain any version from the archive or git.
3147
3148 END
3149         }
3150         unshift @end, $del_lrfetchrefs;
3151         return undef;
3152     }
3153
3154     if ($lastfetch_hash &&
3155         !grep {
3156             my $h = $_->{Commit};
3157             $h and is_fast_fwd($lastfetch_hash, $h);
3158             # If true, one of the existing parents of this commit
3159             # is a descendant of the $lastfetch_hash, so we'll
3160             # be ff from that automatically.
3161         } @mergeinputs
3162         ) {
3163         # Otherwise:
3164         push @mergeinputs, $lastfetch_mergeinput;
3165     }
3166
3167     printdebug "fetch mergeinfos:\n";
3168     foreach my $mi (@mergeinputs) {
3169         if ($mi->{Info}) {
3170             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3171         } else {
3172             printdebug sprintf " ReverseParents=%d Message=%s",
3173                 $mi->{ReverseParents}, $mi->{Message};
3174         }
3175     }
3176
3177     my $compat_info= pop @mergeinputs
3178         if $mergeinputs[$#mergeinputs]{Message};
3179
3180     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3181
3182     my $hash;
3183     if (@mergeinputs > 1) {
3184         # here we go, then:
3185         my $tree_commit = $mergeinputs[0]{Commit};
3186
3187         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3188         $tree =~ m/\n\n/;  $tree = $`;
3189         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3190         $tree = $1;
3191
3192         # We use the changelog author of the package in question the
3193         # author of this pseudo-merge.  This is (roughly) correct if
3194         # this commit is simply representing aa non-dgit upload.
3195         # (Roughly because it does not record sponsorship - but we
3196         # don't have sponsorship info because that's in the .changes,
3197         # which isn't in the archivw.)
3198         #
3199         # But, it might be that we are representing archive history
3200         # updates (including in-archive copies).  These are not really
3201         # the responsibility of the person who created the .dsc, but
3202         # there is no-one whose name we should better use.  (The
3203         # author of the .dsc-named commit is clearly worse.)
3204
3205         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3206         my $author = clogp_authline $useclogp;
3207         my $cversion = getfield $useclogp, 'Version';
3208
3209         my $mcf = ".git/dgit/mergecommit";
3210         open MC, ">", $mcf or die "$mcf $!";
3211         print MC <<END or die $!;
3212 tree $tree
3213 END
3214
3215         my @parents = grep { $_->{Commit} } @mergeinputs;
3216         @parents = reverse @parents if $compat_info->{ReverseParents};
3217         print MC <<END or die $! foreach @parents;
3218 parent $_->{Commit}
3219 END
3220
3221         print MC <<END or die $!;
3222 author $author
3223 committer $author
3224
3225 END
3226
3227         if (defined $compat_info->{Message}) {
3228             print MC $compat_info->{Message} or die $!;
3229         } else {
3230             print MC <<END or die $!;
3231 Record $package ($cversion) in archive suite $csuite
3232
3233 Record that
3234 END
3235             my $message_add_info = sub {
3236                 my ($mi) = (@_);
3237                 my $mversion = mergeinfo_version $mi;
3238                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3239                     or die $!;
3240             };
3241
3242             $message_add_info->($mergeinputs[0]);
3243             print MC <<END or die $!;
3244 should be treated as descended from
3245 END
3246             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3247         }
3248
3249         close MC or die $!;
3250         $hash = make_commit $mcf;
3251     } else {
3252         $hash = $mergeinputs[0]{Commit};
3253     }
3254     printdebug "fetch hash=$hash\n";
3255
3256     my $chkff = sub {
3257         my ($lasth, $what) = @_;
3258         return unless $lasth;
3259         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3260     };
3261
3262     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3263         if $lastpush_hash;
3264     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3265
3266     fetch_from_archive_record_1($hash);
3267
3268     if (defined $skew_warning_vsn) {
3269         mkpath '.git/dgit';
3270         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3271         my $gotclogp = commit_getclogp($hash);
3272         my $got_vsn = getfield $gotclogp, 'Version';
3273         printdebug "SKEW CHECK GOT $got_vsn\n";
3274         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3275             print STDERR <<END or die $!;
3276
3277 Warning: archive skew detected.  Using the available version:
3278 Archive allegedly contains    $skew_warning_vsn
3279 We were able to obtain only   $got_vsn
3280
3281 END
3282         }
3283     }
3284
3285     if ($lastfetch_hash ne $hash) {
3286         fetch_from_archive_record_2($hash);
3287     }
3288
3289     lrfetchref_used lrfetchref();
3290
3291     check_gitattrs($hash, "fetched source tree");
3292
3293     unshift @end, $del_lrfetchrefs;
3294     return $hash;
3295 }
3296
3297 sub set_local_git_config ($$) {
3298     my ($k, $v) = @_;
3299     runcmd @git, qw(config), $k, $v;
3300 }
3301
3302 sub setup_mergechangelogs (;$) {
3303     my ($always) = @_;
3304     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3305
3306     my $driver = 'dpkg-mergechangelogs';
3307     my $cb = "merge.$driver";
3308     my $attrs = '.git/info/attributes';
3309     ensuredir '.git/info';
3310
3311     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3312     if (!open ATTRS, "<", $attrs) {
3313         $!==ENOENT or die "$attrs: $!";
3314     } else {
3315         while (<ATTRS>) {
3316             chomp;
3317             next if m{^debian/changelog\s};
3318             print NATTRS $_, "\n" or die $!;
3319         }
3320         ATTRS->error and die $!;
3321         close ATTRS;
3322     }
3323     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3324     close NATTRS;
3325
3326     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3327     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3328
3329     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3330 }
3331
3332 sub setup_useremail (;$) {
3333     my ($always) = @_;
3334     return unless $always || access_cfg_bool(1, 'setup-useremail');
3335
3336     my $setup = sub {
3337         my ($k, $envvar) = @_;
3338         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3339         return unless defined $v;
3340         set_local_git_config "user.$k", $v;
3341     };
3342
3343     $setup->('email', 'DEBEMAIL');
3344     $setup->('name', 'DEBFULLNAME');
3345 }
3346
3347 sub ensure_setup_existing_tree () {
3348     my $k = "remote.$remotename.skipdefaultupdate";
3349     my $c = git_get_config $k;
3350     return if defined $c;
3351     set_local_git_config $k, 'true';
3352 }
3353
3354 sub open_gitattrs () {
3355     my $gai = new IO::File ".git/info/attributes"
3356         or $!==ENOENT
3357         or die "open .git/info/attributes: $!";
3358     return $gai;
3359 }
3360
3361 sub is_gitattrs_setup () {
3362     my $gai = open_gitattrs();
3363     return 0 unless $gai;
3364     while (<$gai>) {
3365         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3366     }
3367     $gai->error and die $!;
3368     return 0;
3369 }
3370
3371 sub setup_gitattrs (;$) {
3372     my ($always) = @_;
3373     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3374
3375     if (is_gitattrs_setup()) {
3376         progress <<END;
3377 [attr]dgit-defuse-attrs already found in .git/info/attributes
3378  not doing further gitattributes setup
3379 END
3380         return;
3381     }
3382     my $af = ".git/info/attributes";
3383     open GAO, "> $af.new" or die $!;
3384     print GAO <<END or die $!;
3385 *       dgit-defuse-attrs
3386 [attr]dgit-defuse-attrs -text -eol -crlf -ident -filter
3387 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3388 END
3389     my $gai = open_gitattrs();
3390     if ($gai) {
3391         while (<$gai>) {
3392             chomp;
3393             print GAO $_, "\n" or die $!;
3394         }
3395         $gai->error and die $!;
3396     }
3397     close GAO or die $!;
3398     rename "$af.new", "$af" or die "install $af: $!";
3399 }
3400
3401 sub setup_new_tree () {
3402     setup_mergechangelogs();
3403     setup_useremail();
3404     setup_gitattrs();
3405 }
3406
3407 sub check_gitattrs ($$) {
3408     my ($treeish, $what) = @_;
3409
3410     return if is_gitattrs_setup;
3411
3412     local $/="\0";
3413     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3414     debugcmd "|",@cmd;
3415     my $gafl = new IO::File;
3416     open $gafl, "-|", @cmd or die $!;
3417     while (<$gafl>) {
3418         chomp or die;
3419         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3420         next if $1 == 0;
3421         next unless m{(?:^|/)\.gitattributes$};
3422
3423         # oh dear, found one
3424         print STDERR <<END;
3425 dgit: warning: $what contains .gitattributes
3426 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3427 END
3428         close $gafl;
3429         return;
3430     }
3431     # tree contains no .gitattributes files
3432     $?=0; $!=0; close $gafl or failedcmd @cmd;
3433 }
3434
3435
3436 sub multisuite_suite_child ($$$) {
3437     my ($tsuite, $merginputs, $fn) = @_;
3438     # in child, sets things up, calls $fn->(), and returns undef
3439     # in parent, returns canonical suite name for $tsuite
3440     my $canonsuitefh = IO::File::new_tmpfile;
3441     my $pid = fork // die $!;
3442     if (!$pid) {
3443         forkcheck_setup();
3444         $isuite = $tsuite;
3445         $us .= " [$isuite]";
3446         $debugprefix .= " ";
3447         progress "fetching $tsuite...";
3448         canonicalise_suite();
3449         print $canonsuitefh $csuite, "\n" or die $!;
3450         close $canonsuitefh or die $!;
3451         $fn->();
3452         return undef;
3453     }
3454     waitpid $pid,0 == $pid or die $!;
3455     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3456     seek $canonsuitefh,0,0 or die $!;
3457     local $csuite = <$canonsuitefh>;
3458     die $! unless defined $csuite && chomp $csuite;
3459     if ($? == 256*4) {
3460         printdebug "multisuite $tsuite missing\n";
3461         return $csuite;
3462     }
3463     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3464     push @$merginputs, {
3465         Ref => lrref,
3466         Info => $csuite,
3467     };
3468     return $csuite;
3469 }
3470
3471 sub fork_for_multisuite ($) {
3472     my ($before_fetch_merge) = @_;
3473     # if nothing unusual, just returns ''
3474     #
3475     # if multisuite:
3476     # returns 0 to caller in child, to do first of the specified suites
3477     # in child, $csuite is not yet set
3478     #
3479     # returns 1 to caller in parent, to finish up anything needed after
3480     # in parent, $csuite is set to canonicalised portmanteau
3481
3482     my $org_isuite = $isuite;
3483     my @suites = split /\,/, $isuite;
3484     return '' unless @suites > 1;
3485     printdebug "fork_for_multisuite: @suites\n";
3486
3487     my @mergeinputs;
3488
3489     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3490                                             sub { });
3491     return 0 unless defined $cbasesuite;
3492
3493     fail "package $package missing in (base suite) $cbasesuite"
3494         unless @mergeinputs;
3495
3496     my @csuites = ($cbasesuite);
3497
3498     $before_fetch_merge->();
3499
3500     foreach my $tsuite (@suites[1..$#suites]) {
3501         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3502                                                sub {
3503             @end = ();
3504             fetch();
3505             exit 0;
3506         });
3507         # xxx collecte the ref here
3508
3509         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3510         push @csuites, $csubsuite;
3511     }
3512
3513     foreach my $mi (@mergeinputs) {
3514         my $ref = git_get_ref $mi->{Ref};
3515         die "$mi->{Ref} ?" unless length $ref;
3516         $mi->{Commit} = $ref;
3517     }
3518
3519     $csuite = join ",", @csuites;
3520
3521     my $previous = git_get_ref lrref;
3522     if ($previous) {
3523         unshift @mergeinputs, {
3524             Commit => $previous,
3525             Info => "local combined tracking branch",
3526             Warning =>
3527  "archive seems to have rewound: local tracking branch is ahead!",
3528         };
3529     }
3530
3531     foreach my $ix (0..$#mergeinputs) {
3532         $mergeinputs[$ix]{Index} = $ix;
3533     }
3534
3535     @mergeinputs = sort {
3536         -version_compare(mergeinfo_version $a,
3537                          mergeinfo_version $b) # highest version first
3538             or
3539         $a->{Index} <=> $b->{Index}; # earliest in spec first
3540     } @mergeinputs;
3541
3542     my @needed;
3543
3544   NEEDED:
3545     foreach my $mi (@mergeinputs) {
3546         printdebug "multisuite merge check $mi->{Info}\n";
3547         foreach my $previous (@needed) {
3548             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3549             printdebug "multisuite merge un-needed $previous->{Info}\n";
3550             next NEEDED;
3551         }
3552         push @needed, $mi;
3553         printdebug "multisuite merge this-needed\n";
3554         $mi->{Character} = '+';
3555     }
3556
3557     $needed[0]{Character} = '*';
3558
3559     my $output = $needed[0]{Commit};
3560
3561     if (@needed > 1) {
3562         printdebug "multisuite merge nontrivial\n";
3563         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3564
3565         my $commit = "tree $tree\n";
3566         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3567             "Input branches:\n";
3568
3569         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3570             printdebug "multisuite merge include $mi->{Info}\n";
3571             $mi->{Character} //= ' ';
3572             $commit .= "parent $mi->{Commit}\n";
3573             $msg .= sprintf " %s  %-25s %s\n",
3574                 $mi->{Character},
3575                 (mergeinfo_version $mi),
3576                 $mi->{Info};
3577         }
3578         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3579         $msg .= "\nKey\n".
3580             " * marks the highest version branch, which choose to use\n".
3581             " + marks each branch which was not already an ancestor\n\n".
3582             "[dgit multi-suite $csuite]\n";
3583         $commit .=
3584             "author $authline\n".
3585             "committer $authline\n\n";
3586         $output = make_commit_text $commit.$msg;
3587         printdebug "multisuite merge generated $output\n";
3588     }
3589
3590     fetch_from_archive_record_1($output);
3591     fetch_from_archive_record_2($output);
3592
3593     progress "calculated combined tracking suite $csuite";
3594
3595     return 1;
3596 }
3597
3598 sub clone_set_head () {
3599     open H, "> .git/HEAD" or die $!;
3600     print H "ref: ".lref()."\n" or die $!;
3601     close H or die $!;
3602 }
3603 sub clone_finish ($) {
3604     my ($dstdir) = @_;
3605     runcmd @git, qw(reset --hard), lrref();
3606     runcmd qw(bash -ec), <<'END';
3607         set -o pipefail
3608         git ls-tree -r --name-only -z HEAD | \
3609         xargs -0r touch -h -r . --
3610 END
3611     printdone "ready for work in $dstdir";
3612 }
3613
3614 sub clone ($) {
3615     my ($dstdir) = @_;
3616     badusage "dry run makes no sense with clone" unless act_local();
3617
3618     my $multi_fetched = fork_for_multisuite(sub {
3619         printdebug "multi clone before fetch merge\n";
3620         changedir $dstdir;
3621     });
3622     if ($multi_fetched) {
3623         printdebug "multi clone after fetch merge\n";
3624         clone_set_head();
3625         clone_finish($dstdir);
3626         exit 0;
3627     }
3628     printdebug "clone main body\n";
3629
3630     canonicalise_suite();
3631     my $hasgit = check_for_git();
3632     mkdir $dstdir or fail "create \`$dstdir': $!";
3633     changedir $dstdir;
3634     runcmd @git, qw(init -q);
3635     setup_new_tree();
3636     clone_set_head();
3637     my $giturl = access_giturl(1);
3638     if (defined $giturl) {
3639         runcmd @git, qw(remote add), 'origin', $giturl;
3640     }
3641     if ($hasgit) {
3642         progress "fetching existing git history";
3643         git_fetch_us();
3644         runcmd_ordryrun_local @git, qw(fetch origin);
3645     } else {
3646         progress "starting new git history";
3647     }
3648     fetch_from_archive() or no_such_package;
3649     my $vcsgiturl = $dsc->{'Vcs-Git'};
3650     if (length $vcsgiturl) {
3651         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3652         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3653     }
3654     clone_finish($dstdir);
3655 }
3656
3657 sub fetch () {
3658     canonicalise_suite();
3659     if (check_for_git()) {
3660         git_fetch_us();
3661     }
3662     fetch_from_archive() or no_such_package();
3663     printdone "fetched into ".lrref();
3664 }
3665
3666 sub pull () {
3667     my $multi_fetched = fork_for_multisuite(sub { });
3668     fetch() unless $multi_fetched; # parent
3669     return if $multi_fetched eq '0'; # child
3670     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3671         lrref();
3672     printdone "fetched to ".lrref()." and merged into HEAD";
3673 }
3674
3675 sub check_not_dirty () {
3676     foreach my $f (qw(local-options local-patch-header)) {
3677         if (stat_exists "debian/source/$f") {
3678             fail "git tree contains debian/source/$f";
3679         }
3680     }
3681
3682     return if $ignoredirty;
3683
3684     my @cmd = (@git, qw(diff --quiet HEAD));
3685     debugcmd "+",@cmd;
3686     $!=0; $?=-1; system @cmd;
3687     return if !$?;
3688     if ($?==256) {
3689         fail "working tree is dirty (does not match HEAD)";
3690     } else {
3691         failedcmd @cmd;
3692     }
3693 }
3694
3695 sub commit_admin ($) {
3696     my ($m) = @_;
3697     progress "$m";
3698     runcmd_ordryrun_local @git, qw(commit -m), $m;
3699 }
3700
3701 sub commit_quilty_patch () {
3702     my $output = cmdoutput @git, qw(status --porcelain);
3703     my %adds;
3704     foreach my $l (split /\n/, $output) {
3705         next unless $l =~ m/\S/;
3706         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3707             $adds{$1}++;
3708         }
3709     }
3710     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3711     if (!%adds) {
3712         progress "nothing quilty to commit, ok.";
3713         return;
3714     }
3715     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3716     runcmd_ordryrun_local @git, qw(add -f), @adds;
3717     commit_admin <<END
3718 Commit Debian 3.0 (quilt) metadata
3719
3720 [dgit ($our_version) quilt-fixup]
3721 END
3722 }
3723
3724 sub get_source_format () {
3725     my %options;
3726     if (open F, "debian/source/options") {
3727         while (<F>) {
3728             next if m/^\s*\#/;
3729             next unless m/\S/;
3730             s/\s+$//; # ignore missing final newline
3731             if (m/\s*\#\s*/) {
3732                 my ($k, $v) = ($`, $'); #');
3733                 $v =~ s/^"(.*)"$/$1/;
3734                 $options{$k} = $v;
3735             } else {
3736                 $options{$_} = 1;
3737             }
3738         }
3739         F->error and die $!;
3740         close F;
3741     } else {
3742         die $! unless $!==&ENOENT;
3743     }
3744
3745     if (!open F, "debian/source/format") {
3746         die $! unless $!==&ENOENT;
3747         return '';
3748     }
3749     $_ = <F>;
3750     F->error and die $!;
3751     chomp;
3752     return ($_, \%options);
3753 }
3754
3755 sub madformat_wantfixup ($) {
3756     my ($format) = @_;
3757     return 0 unless $format eq '3.0 (quilt)';
3758     our $quilt_mode_warned;
3759     if ($quilt_mode eq 'nocheck') {
3760         progress "Not doing any fixup of \`$format' due to".
3761             " ----no-quilt-fixup or --quilt=nocheck"
3762             unless $quilt_mode_warned++;
3763         return 0;
3764     }
3765     progress "Format \`$format', need to check/update patch stack"
3766         unless $quilt_mode_warned++;
3767     return 1;
3768 }
3769
3770 sub maybe_split_brain_save ($$$) {
3771     my ($headref, $dgitview, $msg) = @_;
3772     # => message fragment "$saved" describing disposition of $dgitview
3773     return "commit id $dgitview" unless defined $split_brain_save;
3774     my @cmd = (shell_cmd "cd ../../../..",
3775                @git, qw(update-ref -m),
3776                "dgit --dgit-view-save $msg HEAD=$headref",
3777                $split_brain_save, $dgitview);
3778     runcmd @cmd;
3779     return "and left in $split_brain_save";
3780 }
3781
3782 # An "infopair" is a tuple [ $thing, $what ]
3783 # (often $thing is a commit hash; $what is a description)
3784
3785 sub infopair_cond_equal ($$) {
3786     my ($x,$y) = @_;
3787     $x->[0] eq $y->[0] or fail <<END;
3788 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3789 END
3790 };
3791
3792 sub infopair_lrf_tag_lookup ($$) {
3793     my ($tagnames, $what) = @_;
3794     # $tagname may be an array ref
3795     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3796     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3797     foreach my $tagname (@tagnames) {
3798         my $lrefname = lrfetchrefs."/tags/$tagname";
3799         my $tagobj = $lrfetchrefs_f{$lrefname};
3800         next unless defined $tagobj;
3801         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3802         return [ git_rev_parse($tagobj), $what ];
3803     }
3804     fail @tagnames==1 ? <<END : <<END;
3805 Wanted tag $what (@tagnames) on dgit server, but not found
3806 END
3807 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3808 END
3809 }
3810
3811 sub infopair_cond_ff ($$) {
3812     my ($anc,$desc) = @_;
3813     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3814 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3815 END
3816 };
3817
3818 sub pseudomerge_version_check ($$) {
3819     my ($clogp, $archive_hash) = @_;
3820
3821     my $arch_clogp = commit_getclogp $archive_hash;
3822     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3823                      'version currently in archive' ];
3824     if (defined $overwrite_version) {
3825         if (length $overwrite_version) {
3826             infopair_cond_equal([ $overwrite_version,
3827                                   '--overwrite= version' ],
3828                                 $i_arch_v);
3829         } else {
3830             my $v = $i_arch_v->[0];
3831             progress "Checking package changelog for archive version $v ...";
3832             my $cd;
3833             eval {
3834                 my @xa = ("-f$v", "-t$v");
3835                 my $vclogp = parsechangelog @xa;
3836                 my $gf = sub {
3837                     my ($fn) = @_;
3838                     [ (getfield $vclogp, $fn),
3839                       "$fn field from dpkg-parsechangelog @xa" ];
3840                 };
3841                 my $cv = $gf->('Version');
3842                 infopair_cond_equal($i_arch_v, $cv);
3843                 $cd = $gf->('Distribution');
3844             };
3845             if ($@) {
3846                 $@ =~ s/^dgit: //gm;
3847                 fail "$@".
3848                     "Perhaps debian/changelog does not mention $v ?";
3849             }
3850             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3851 $cd->[1] is $cd->[0]
3852 Your tree seems to based on earlier (not uploaded) $v.
3853 END
3854         }
3855     }
3856
3857     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3858     return $i_arch_v;
3859 }
3860
3861 sub pseudomerge_make_commit ($$$$ $$) {
3862     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3863         $msg_cmd, $msg_msg) = @_;
3864     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3865
3866     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3867     my $authline = clogp_authline $clogp;
3868
3869     chomp $msg_msg;
3870     $msg_cmd .=
3871         !defined $overwrite_version ? ""
3872         : !length  $overwrite_version ? " --overwrite"
3873         : " --overwrite=".$overwrite_version;
3874
3875     mkpath '.git/dgit';
3876     my $pmf = ".git/dgit/pseudomerge";
3877     open MC, ">", $pmf or die "$pmf $!";
3878     print MC <<END or die $!;
3879 tree $tree
3880 parent $dgitview
3881 parent $archive_hash
3882 author $authline
3883 committer $authline
3884
3885 $msg_msg
3886
3887 [$msg_cmd]
3888 END
3889     close MC or die $!;
3890
3891     return make_commit($pmf);
3892 }
3893
3894 sub splitbrain_pseudomerge ($$$$) {
3895     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3896     # => $merged_dgitview
3897     printdebug "splitbrain_pseudomerge...\n";
3898     #
3899     #     We:      debian/PREVIOUS    HEAD($maintview)
3900     # expect:          o ----------------- o
3901     #                    \                   \
3902     #                     o                   o
3903     #                 a/d/PREVIOUS        $dgitview
3904     #                $archive_hash              \
3905     #  If so,                \                   \
3906     #  we do:                 `------------------ o
3907     #   this:                                   $dgitview'
3908     #
3909
3910     return $dgitview unless defined $archive_hash;
3911
3912     printdebug "splitbrain_pseudomerge...\n";
3913
3914     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3915
3916     if (!defined $overwrite_version) {
3917         progress "Checking that HEAD inciudes all changes in archive...";
3918     }
3919
3920     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3921
3922     if (defined $overwrite_version) {
3923     } elsif (!eval {
3924         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3925         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3926         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3927         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3928         my $i_archive = [ $archive_hash, "current archive contents" ];
3929
3930         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3931
3932         infopair_cond_equal($i_dgit, $i_archive);
3933         infopair_cond_ff($i_dep14, $i_dgit);
3934         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3935         1;
3936     }) {
3937         print STDERR <<END;
3938 $us: check failed (maybe --overwrite is needed, consult documentation)
3939 END
3940         die "$@";
3941     }
3942
3943     my $r = pseudomerge_make_commit
3944         $clogp, $dgitview, $archive_hash, $i_arch_v,
3945         "dgit --quilt=$quilt_mode",
3946         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3947 Declare fast forward from $i_arch_v->[0]
3948 END_OVERWR
3949 Make fast forward from $i_arch_v->[0]
3950 END_MAKEFF
3951
3952     maybe_split_brain_save $maintview, $r, "pseudomerge";
3953
3954     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3955     return $r;
3956 }
3957
3958 sub plain_overwrite_pseudomerge ($$$) {
3959     my ($clogp, $head, $archive_hash) = @_;
3960
3961     printdebug "plain_overwrite_pseudomerge...";
3962
3963     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3964
3965     return $head if is_fast_fwd $archive_hash, $head;
3966
3967     my $m = "Declare fast forward from $i_arch_v->[0]";
3968
3969     my $r = pseudomerge_make_commit
3970         $clogp, $head, $archive_hash, $i_arch_v,
3971         "dgit", $m;
3972
3973     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3974
3975     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3976     return $r;
3977 }
3978
3979 sub push_parse_changelog ($) {
3980     my ($clogpfn) = @_;
3981
3982     my $clogp = Dpkg::Control::Hash->new();
3983     $clogp->load($clogpfn) or die;
3984
3985     my $clogpackage = getfield $clogp, 'Source';
3986     $package //= $clogpackage;
3987     fail "-p specified $package but changelog specified $clogpackage"
3988         unless $package eq $clogpackage;
3989     my $cversion = getfield $clogp, 'Version';
3990
3991     if (!$we_are_initiator) {
3992         # rpush initiator can't do this because it doesn't have $isuite yet
3993         my $tag = debiantag($cversion, access_nomdistro);
3994         runcmd @git, qw(check-ref-format), $tag;
3995     }
3996
3997     my $dscfn = dscfn($cversion);
3998
3999     return ($clogp, $cversion, $dscfn);
4000 }
4001
4002 sub push_parse_dsc ($$$) {
4003     my ($dscfn,$dscfnwhat, $cversion) = @_;
4004     $dsc = parsecontrol($dscfn,$dscfnwhat);
4005     my $dversion = getfield $dsc, 'Version';
4006     my $dscpackage = getfield $dsc, 'Source';
4007     ($dscpackage eq $package && $dversion eq $cversion) or
4008         fail "$dscfn is for $dscpackage $dversion".
4009             " but debian/changelog is for $package $cversion";
4010 }
4011
4012 sub push_tagwants ($$$$) {
4013     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4014     my @tagwants;
4015     push @tagwants, {
4016         TagFn => \&debiantag,
4017         Objid => $dgithead,
4018         TfSuffix => '',
4019         View => 'dgit',
4020     };
4021     if (defined $maintviewhead) {
4022         push @tagwants, {
4023             TagFn => \&debiantag_maintview,
4024             Objid => $maintviewhead,
4025             TfSuffix => '-maintview',
4026             View => 'maint',
4027         };
4028     } elsif ($dodep14tag eq 'no' ? 0
4029              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
4030              : $dodep14tag eq 'always'
4031              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
4032 --dep14tag-always (or equivalent in config) means server must support
4033  both "new" and "maint" tag formats, but config says it doesn't.
4034 END
4035             : die "$dodep14tag ?") {
4036         push @tagwants, {
4037             TagFn => \&debiantag_maintview,
4038             Objid => $dgithead,
4039             TfSuffix => '-dgit',
4040             View => 'dgit',
4041         };
4042     };
4043     foreach my $tw (@tagwants) {
4044         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4045         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4046     }
4047     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4048     return @tagwants;
4049 }
4050
4051 sub push_mktags ($$ $$ $) {
4052     my ($clogp,$dscfn,
4053         $changesfile,$changesfilewhat,
4054         $tagwants) = @_;
4055
4056     die unless $tagwants->[0]{View} eq 'dgit';
4057
4058     my $declaredistro = access_nomdistro();
4059     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4060     $dsc->{$ourdscfield[0]} = join " ",
4061         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4062         $reader_giturl;
4063     $dsc->save("$dscfn.tmp") or die $!;
4064
4065     my $changes = parsecontrol($changesfile,$changesfilewhat);
4066     foreach my $field (qw(Source Distribution Version)) {
4067         $changes->{$field} eq $clogp->{$field} or
4068             fail "changes field $field \`$changes->{$field}'".
4069                 " does not match changelog \`$clogp->{$field}'";
4070     }
4071
4072     my $cversion = getfield $clogp, 'Version';
4073     my $clogsuite = getfield $clogp, 'Distribution';
4074
4075     # We make the git tag by hand because (a) that makes it easier
4076     # to control the "tagger" (b) we can do remote signing
4077     my $authline = clogp_authline $clogp;
4078     my $delibs = join(" ", "",@deliberatelies);
4079
4080     my $mktag = sub {
4081         my ($tw) = @_;
4082         my $tfn = $tw->{Tfn};
4083         my $head = $tw->{Objid};
4084         my $tag = $tw->{Tag};
4085
4086         open TO, '>', $tfn->('.tmp') or die $!;
4087         print TO <<END or die $!;
4088 object $head
4089 type commit
4090 tag $tag
4091 tagger $authline
4092
4093 END
4094         if ($tw->{View} eq 'dgit') {
4095             print TO <<END or die $!;
4096 $package release $cversion for $clogsuite ($csuite) [dgit]
4097 [dgit distro=$declaredistro$delibs]
4098 END
4099             foreach my $ref (sort keys %previously) {
4100                 print TO <<END or die $!;
4101 [dgit previously:$ref=$previously{$ref}]
4102 END
4103             }
4104         } elsif ($tw->{View} eq 'maint') {
4105             print TO <<END or die $!;
4106 $package release $cversion for $clogsuite ($csuite)
4107 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4108 END
4109         } else {
4110             die Dumper($tw)."?";
4111         }
4112
4113         close TO or die $!;
4114
4115         my $tagobjfn = $tfn->('.tmp');
4116         if ($sign) {
4117             if (!defined $keyid) {
4118                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4119             }
4120             if (!defined $keyid) {
4121                 $keyid = getfield $clogp, 'Maintainer';
4122             }
4123             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4124             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4125             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4126             push @sign_cmd, $tfn->('.tmp');
4127             runcmd_ordryrun @sign_cmd;
4128             if (act_scary()) {
4129                 $tagobjfn = $tfn->('.signed.tmp');
4130                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4131                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4132             }
4133         }
4134         return $tagobjfn;
4135     };
4136
4137     my @r = map { $mktag->($_); } @$tagwants;
4138     return @r;
4139 }
4140
4141 sub sign_changes ($) {
4142     my ($changesfile) = @_;
4143     if ($sign) {
4144         my @debsign_cmd = @debsign;
4145         push @debsign_cmd, "-k$keyid" if defined $keyid;
4146         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4147         push @debsign_cmd, $changesfile;
4148         runcmd_ordryrun @debsign_cmd;
4149     }
4150 }
4151
4152 sub dopush () {
4153     printdebug "actually entering push\n";
4154
4155     supplementary_message(<<'END');
4156 Push failed, while checking state of the archive.
4157 You can retry the push, after fixing the problem, if you like.
4158 END
4159     if (check_for_git()) {
4160         git_fetch_us();
4161     }
4162     my $archive_hash = fetch_from_archive();
4163     if (!$archive_hash) {
4164         $new_package or
4165             fail "package appears to be new in this suite;".
4166                 " if this is intentional, use --new";
4167     }
4168
4169     supplementary_message(<<'END');
4170 Push failed, while preparing your push.
4171 You can retry the push, after fixing the problem, if you like.
4172 END
4173
4174     need_tagformat 'new', "quilt mode $quilt_mode"
4175         if quiltmode_splitbrain;
4176
4177     prep_ud();
4178
4179     access_giturl(); # check that success is vaguely likely
4180     rpush_handle_protovsn_bothends() if $we_are_initiator;
4181     select_tagformat();
4182
4183     my $clogpfn = ".git/dgit/changelog.822.tmp";
4184     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4185
4186     responder_send_file('parsed-changelog', $clogpfn);
4187
4188     my ($clogp, $cversion, $dscfn) =
4189         push_parse_changelog("$clogpfn");
4190
4191     my $dscpath = "$buildproductsdir/$dscfn";
4192     stat_exists $dscpath or
4193         fail "looked for .dsc $dscpath, but $!;".
4194             " maybe you forgot to build";
4195
4196     responder_send_file('dsc', $dscpath);
4197
4198     push_parse_dsc($dscpath, $dscfn, $cversion);
4199
4200     my $format = getfield $dsc, 'Format';
4201     printdebug "format $format\n";
4202
4203     my $actualhead = git_rev_parse('HEAD');
4204     my $dgithead = $actualhead;
4205     my $maintviewhead = undef;
4206
4207     my $upstreamversion = upstreamversion $clogp->{Version};
4208
4209     if (madformat_wantfixup($format)) {
4210         # user might have not used dgit build, so maybe do this now:
4211         if (quiltmode_splitbrain()) {
4212             changedir $ud;
4213             quilt_make_fake_dsc($upstreamversion);
4214             my $cachekey;
4215             ($dgithead, $cachekey) =
4216                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4217             $dgithead or fail
4218  "--quilt=$quilt_mode but no cached dgit view:
4219  perhaps tree changed since dgit build[-source] ?";
4220             $split_brain = 1;
4221             $dgithead = splitbrain_pseudomerge($clogp,
4222                                                $actualhead, $dgithead,
4223                                                $archive_hash);
4224             $maintviewhead = $actualhead;
4225             changedir '../../../..';
4226             prep_ud(); # so _only_subdir() works, below
4227         } else {
4228             commit_quilty_patch();
4229         }
4230     }
4231
4232     if (defined $overwrite_version && !defined $maintviewhead) {
4233         $dgithead = plain_overwrite_pseudomerge($clogp,
4234                                                 $dgithead,
4235                                                 $archive_hash);
4236     }
4237
4238     check_not_dirty();
4239
4240     my $forceflag = '';
4241     if ($archive_hash) {
4242         if (is_fast_fwd($archive_hash, $dgithead)) {
4243             # ok
4244         } elsif (deliberately_not_fast_forward) {
4245             $forceflag = '+';
4246         } else {
4247             fail "dgit push: HEAD is not a descendant".
4248                 " of the archive's version.\n".
4249                 "To overwrite the archive's contents,".
4250                 " pass --overwrite[=VERSION].\n".
4251                 "To rewind history, if permitted by the archive,".
4252                 " use --deliberately-not-fast-forward.";
4253         }
4254     }
4255
4256     changedir $ud;
4257     progress "checking that $dscfn corresponds to HEAD";
4258     runcmd qw(dpkg-source -x --),
4259         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4260     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4261     check_for_vendor_patches() if madformat($dsc->{format});
4262     changedir '../../../..';
4263     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4264     debugcmd "+",@diffcmd;
4265     $!=0; $?=-1;
4266     my $r = system @diffcmd;
4267     if ($r) {
4268         if ($r==256) {
4269             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4270             fail <<END
4271 HEAD specifies a different tree to $dscfn:
4272 $diffs
4273 Perhaps you forgot to build.  Or perhaps there is a problem with your
4274  source tree (see dgit(7) for some hints).  To see a full diff, run
4275    git diff $tree HEAD
4276 END
4277         } else {
4278             failedcmd @diffcmd;
4279         }
4280     }
4281     if (!$changesfile) {
4282         my $pat = changespat $cversion;
4283         my @cs = glob "$buildproductsdir/$pat";
4284         fail "failed to find unique changes file".
4285             " (looked for $pat in $buildproductsdir);".
4286             " perhaps you need to use dgit -C"
4287             unless @cs==1;
4288         ($changesfile) = @cs;
4289     } else {
4290         $changesfile = "$buildproductsdir/$changesfile";
4291     }
4292
4293     # Check that changes and .dsc agree enough
4294     $changesfile =~ m{[^/]*$};
4295     my $changes = parsecontrol($changesfile,$&);
4296     files_compare_inputs($dsc, $changes)
4297         unless forceing [qw(dsc-changes-mismatch)];
4298
4299     # Perhaps adjust .dsc to contain right set of origs
4300     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4301                                   $changesfile)
4302         unless forceing [qw(changes-origs-exactly)];
4303
4304     # Checks complete, we're going to try and go ahead:
4305
4306     responder_send_file('changes',$changesfile);
4307     responder_send_command("param head $dgithead");
4308     responder_send_command("param csuite $csuite");
4309     responder_send_command("param isuite $isuite");
4310     responder_send_command("param tagformat $tagformat");
4311     if (defined $maintviewhead) {
4312         die unless ($protovsn//4) >= 4;
4313         responder_send_command("param maint-view $maintviewhead");
4314     }
4315
4316     # Perhaps send buildinfo(s) for signing
4317     my $changes_files = getfield $changes, 'Files';
4318     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4319     foreach my $bi (@buildinfos) {
4320         responder_send_command("param buildinfo-filename $bi");
4321         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4322     }
4323
4324     if (deliberately_not_fast_forward) {
4325         git_for_each_ref(lrfetchrefs, sub {
4326             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4327             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4328             responder_send_command("previously $rrefname=$objid");
4329             $previously{$rrefname} = $objid;
4330         });
4331     }
4332
4333     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4334                                  ".git/dgit/tag");
4335     my @tagobjfns;
4336
4337     supplementary_message(<<'END');
4338 Push failed, while signing the tag.
4339 You can retry the push, after fixing the problem, if you like.
4340 END
4341     # If we manage to sign but fail to record it anywhere, it's fine.
4342     if ($we_are_responder) {
4343         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4344         responder_receive_files('signed-tag', @tagobjfns);
4345     } else {
4346         @tagobjfns = push_mktags($clogp,$dscpath,
4347                               $changesfile,$changesfile,
4348                               \@tagwants);
4349     }
4350     supplementary_message(<<'END');
4351 Push failed, *after* signing the tag.
4352 If you want to try again, you should use a new version number.
4353 END
4354
4355     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4356
4357     foreach my $tw (@tagwants) {
4358         my $tag = $tw->{Tag};
4359         my $tagobjfn = $tw->{TagObjFn};
4360         my $tag_obj_hash =
4361             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4362         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4363         runcmd_ordryrun_local
4364             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4365     }
4366
4367     supplementary_message(<<'END');
4368 Push failed, while updating the remote git repository - see messages above.
4369 If you want to try again, you should use a new version number.
4370 END
4371     if (!check_for_git()) {
4372         create_remote_git_repo();
4373     }
4374
4375     my @pushrefs = $forceflag.$dgithead.":".rrref();
4376     foreach my $tw (@tagwants) {
4377         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4378     }
4379
4380     runcmd_ordryrun @git,
4381         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4382     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4383
4384     supplementary_message(<<'END');
4385 Push failed, while obtaining signatures on the .changes and .dsc.
4386 If it was just that the signature failed, you may try again by using
4387 debsign by hand to sign the changes
4388    $changesfile
4389 and then dput to complete the upload.
4390 If you need to change the package, you must use a new version number.
4391 END
4392     if ($we_are_responder) {
4393         my $dryrunsuffix = act_local() ? "" : ".tmp";
4394         my @rfiles = ($dscpath, $changesfile);
4395         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4396         responder_receive_files('signed-dsc-changes',
4397                                 map { "$_$dryrunsuffix" } @rfiles);
4398     } else {
4399         if (act_local()) {
4400             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4401         } else {
4402             progress "[new .dsc left in $dscpath.tmp]";
4403         }
4404         sign_changes $changesfile;
4405     }
4406
4407     supplementary_message(<<END);
4408 Push failed, while uploading package(s) to the archive server.
4409 You can retry the upload of exactly these same files with dput of:
4410   $changesfile
4411 If that .changes file is broken, you will need to use a new version
4412 number for your next attempt at the upload.
4413 END
4414     my $host = access_cfg('upload-host','RETURN-UNDEF');
4415     my @hostarg = defined($host) ? ($host,) : ();
4416     runcmd_ordryrun @dput, @hostarg, $changesfile;
4417     printdone "pushed and uploaded $cversion";
4418
4419     supplementary_message('');
4420     responder_send_command("complete");
4421 }
4422
4423 sub pre_clone () {
4424     no_local_git_cfg();
4425 }
4426 sub cmd_clone {
4427     parseopts();
4428     my $dstdir;
4429     badusage "-p is not allowed with clone; specify as argument instead"
4430         if defined $package;
4431     if (@ARGV==1) {
4432         ($package) = @ARGV;
4433     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4434         ($package,$isuite) = @ARGV;
4435     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4436         ($package,$dstdir) = @ARGV;
4437     } elsif (@ARGV==3) {
4438         ($package,$isuite,$dstdir) = @ARGV;
4439     } else {
4440         badusage "incorrect arguments to dgit clone";
4441     }
4442     notpushing();
4443
4444     $dstdir ||= "$package";
4445     if (stat_exists $dstdir) {
4446         fail "$dstdir already exists";
4447     }
4448
4449     my $cwd_remove;
4450     if ($rmonerror && !$dryrun_level) {
4451         $cwd_remove= getcwd();
4452         unshift @end, sub {
4453             return unless defined $cwd_remove;
4454             if (!chdir "$cwd_remove") {
4455                 return if $!==&ENOENT;
4456                 die "chdir $cwd_remove: $!";
4457             }
4458             printdebug "clone rmonerror removing $dstdir\n";
4459             if (stat $dstdir) {
4460                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4461             } elsif (grep { $! == $_ }
4462                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4463             } else {
4464                 print STDERR "check whether to remove $dstdir: $!\n";
4465             }
4466         };
4467     }
4468
4469     clone($dstdir);
4470     $cwd_remove = undef;
4471 }
4472
4473 sub branchsuite () {
4474     my @cmd = (@git, qw(symbolic-ref -q HEAD));
4475     my $branch = cmdoutput_errok @cmd;
4476     if (!defined $branch) {
4477         $?==256 or failedcmd @cmd;
4478         return undef;
4479     }
4480     if ($branch =~ m#$lbranch_re#o) {
4481         return $1;
4482     } else {
4483         return undef;
4484     }
4485 }
4486
4487 sub fetchpullargs () {
4488     if (!defined $package) {
4489         my $sourcep = parsecontrol('debian/control','debian/control');
4490         $package = getfield $sourcep, 'Source';
4491     }
4492     if (@ARGV==0) {
4493         $isuite = branchsuite();
4494         if (!$isuite) {
4495             my $clogp = parsechangelog();
4496             my $clogsuite = getfield $clogp, 'Distribution';
4497             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4498         }
4499     } elsif (@ARGV==1) {
4500         ($isuite) = @ARGV;
4501     } else {
4502         badusage "incorrect arguments to dgit fetch or dgit pull";
4503     }
4504     notpushing();
4505 }
4506
4507 sub cmd_fetch {
4508     parseopts();
4509     fetchpullargs();
4510     my $multi_fetched = fork_for_multisuite(sub { });
4511     exit 0 if $multi_fetched;
4512     fetch();
4513 }
4514
4515 sub cmd_pull {
4516     parseopts();
4517     fetchpullargs();
4518     if (quiltmode_splitbrain()) {
4519         my ($format, $fopts) = get_source_format();
4520         madformat($format) and fail <<END
4521 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4522 END
4523     }
4524     pull();
4525 }
4526
4527 sub cmd_push {
4528     parseopts();
4529     badusage "-p is not allowed with dgit push" if defined $package;
4530     check_not_dirty();
4531     my $clogp = parsechangelog();
4532     $package = getfield $clogp, 'Source';
4533     my $specsuite;
4534     if (@ARGV==0) {
4535     } elsif (@ARGV==1) {
4536         ($specsuite) = (@ARGV);
4537     } else {
4538         badusage "incorrect arguments to dgit push";
4539     }
4540     $isuite = getfield $clogp, 'Distribution';
4541     pushing();
4542     if ($new_package) {
4543         local ($package) = $existing_package; # this is a hack
4544         canonicalise_suite();
4545     } else {
4546         canonicalise_suite();
4547     }
4548     if (defined $specsuite &&
4549         $specsuite ne $isuite &&
4550         $specsuite ne $csuite) {
4551             fail "dgit push: changelog specifies $isuite ($csuite)".
4552                 " but command line specifies $specsuite";
4553     }
4554     dopush();
4555 }
4556
4557 #---------- remote commands' implementation ----------
4558
4559 sub pre_remote_push_build_host {
4560     my ($nrargs) = shift @ARGV;
4561     my (@rargs) = @ARGV[0..$nrargs-1];
4562     @ARGV = @ARGV[$nrargs..$#ARGV];
4563     die unless @rargs;
4564     my ($dir,$vsnwant) = @rargs;
4565     # vsnwant is a comma-separated list; we report which we have
4566     # chosen in our ready response (so other end can tell if they
4567     # offered several)
4568     $debugprefix = ' ';
4569     $we_are_responder = 1;
4570     $us .= " (build host)";
4571
4572     open PI, "<&STDIN" or die $!;
4573     open STDIN, "/dev/null" or die $!;
4574     open PO, ">&STDOUT" or die $!;
4575     autoflush PO 1;
4576     open STDOUT, ">&STDERR" or die $!;
4577     autoflush STDOUT 1;
4578
4579     $vsnwant //= 1;
4580     ($protovsn) = grep {
4581         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4582     } @rpushprotovsn_support;
4583
4584     fail "build host has dgit rpush protocol versions ".
4585         (join ",", @rpushprotovsn_support).
4586         " but invocation host has $vsnwant"
4587         unless defined $protovsn;
4588
4589     changedir $dir;
4590 }
4591 sub cmd_remote_push_build_host {
4592     responder_send_command("dgit-remote-push-ready $protovsn");
4593     &cmd_push;
4594 }
4595
4596 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4597 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4598 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4599 #     a good error message)
4600
4601 sub rpush_handle_protovsn_bothends () {
4602     if ($protovsn < 4) {
4603         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4604     }
4605     select_tagformat();
4606 }
4607
4608 our $i_tmp;
4609
4610 sub i_cleanup {
4611     local ($@, $?);
4612     my $report = i_child_report();
4613     if (defined $report) {
4614         printdebug "($report)\n";
4615     } elsif ($i_child_pid) {
4616         printdebug "(killing build host child $i_child_pid)\n";
4617         kill 15, $i_child_pid;
4618     }
4619     if (defined $i_tmp && !defined $initiator_tempdir) {
4620         changedir "/";
4621         eval { rmtree $i_tmp; };
4622     }
4623 }
4624
4625 END {
4626     return unless forkcheck_mainprocess();
4627     i_cleanup();
4628 }
4629
4630 sub i_method {
4631     my ($base,$selector,@args) = @_;
4632     $selector =~ s/\-/_/g;
4633     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4634 }
4635
4636 sub pre_rpush () {
4637     no_local_git_cfg();
4638 }
4639 sub cmd_rpush {
4640     my $host = nextarg;
4641     my $dir;
4642     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4643         $host = $1;
4644         $dir = $'; #';
4645     } else {
4646         $dir = nextarg;
4647     }
4648     $dir =~ s{^-}{./-};
4649     my @rargs = ($dir);
4650     push @rargs, join ",", @rpushprotovsn_support;
4651     my @rdgit;
4652     push @rdgit, @dgit;
4653     push @rdgit, @ropts;
4654     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4655     push @rdgit, @ARGV;
4656     my @cmd = (@ssh, $host, shellquote @rdgit);
4657     debugcmd "+",@cmd;
4658
4659     $we_are_initiator=1;
4660
4661     if (defined $initiator_tempdir) {
4662         rmtree $initiator_tempdir;
4663         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4664         $i_tmp = $initiator_tempdir;
4665     } else {
4666         $i_tmp = tempdir();
4667     }
4668     $i_child_pid = open2(\*RO, \*RI, @cmd);
4669     changedir $i_tmp;
4670     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4671     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4672     $supplementary_message = '' unless $protovsn >= 3;
4673
4674     for (;;) {
4675         my ($icmd,$iargs) = initiator_expect {
4676             m/^(\S+)(?: (.*))?$/;
4677             ($1,$2);
4678         };
4679         i_method "i_resp", $icmd, $iargs;
4680     }
4681 }
4682
4683 sub i_resp_progress ($) {
4684     my ($rhs) = @_;
4685     my $msg = protocol_read_bytes \*RO, $rhs;
4686     progress $msg;
4687 }
4688
4689 sub i_resp_supplementary_message ($) {
4690     my ($rhs) = @_;
4691     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4692 }
4693
4694 sub i_resp_complete {
4695     my $pid = $i_child_pid;
4696     $i_child_pid = undef; # prevents killing some other process with same pid
4697     printdebug "waiting for build host child $pid...\n";
4698     my $got = waitpid $pid, 0;
4699     die $! unless $got == $pid;
4700     die "build host child failed $?" if $?;
4701
4702     i_cleanup();
4703     printdebug "all done\n";
4704     exit 0;
4705 }
4706
4707 sub i_resp_file ($) {
4708     my ($keyword) = @_;
4709     my $localname = i_method "i_localname", $keyword;
4710     my $localpath = "$i_tmp/$localname";
4711     stat_exists $localpath and
4712         badproto \*RO, "file $keyword ($localpath) twice";
4713     protocol_receive_file \*RO, $localpath;
4714     i_method "i_file", $keyword;
4715 }
4716
4717 our %i_param;
4718
4719 sub i_resp_param ($) {
4720     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4721     $i_param{$1} = $2;
4722 }
4723
4724 sub i_resp_previously ($) {
4725     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4726         or badproto \*RO, "bad previously spec";
4727     my $r = system qw(git check-ref-format), $1;
4728     die "bad previously ref spec ($r)" if $r;
4729     $previously{$1} = $2;
4730 }
4731
4732 our %i_wanted;
4733
4734 sub i_resp_want ($) {
4735     my ($keyword) = @_;
4736     die "$keyword ?" if $i_wanted{$keyword}++;
4737
4738     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4739     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4740     die unless $isuite =~ m/^$suite_re$/;
4741
4742     pushing();
4743     rpush_handle_protovsn_bothends();
4744
4745     fail "rpush negotiated protocol version $protovsn".
4746         " which does not support quilt mode $quilt_mode"
4747         if quiltmode_splitbrain;
4748
4749     my @localpaths = i_method "i_want", $keyword;
4750     printdebug "[[  $keyword @localpaths\n";
4751     foreach my $localpath (@localpaths) {
4752         protocol_send_file \*RI, $localpath;
4753     }
4754     print RI "files-end\n" or die $!;
4755 }
4756
4757 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4758
4759 sub i_localname_parsed_changelog {
4760     return "remote-changelog.822";
4761 }
4762 sub i_file_parsed_changelog {
4763     ($i_clogp, $i_version, $i_dscfn) =
4764         push_parse_changelog "$i_tmp/remote-changelog.822";
4765     die if $i_dscfn =~ m#/|^\W#;
4766 }
4767
4768 sub i_localname_dsc {
4769     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4770     return $i_dscfn;
4771 }
4772 sub i_file_dsc { }
4773
4774 sub i_localname_buildinfo ($) {
4775     my $bi = $i_param{'buildinfo-filename'};
4776     defined $bi or badproto \*RO, "buildinfo before filename";
4777     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4778     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4779         or badproto \*RO, "improper buildinfo filename";
4780     return $&;
4781 }
4782 sub i_file_buildinfo {
4783     my $bi = $i_param{'buildinfo-filename'};
4784     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4785     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4786     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4787         files_compare_inputs($bd, $ch);
4788         (getfield $bd, $_) eq (getfield $ch, $_) or
4789             fail "buildinfo mismatch $_"
4790             foreach qw(Source Version);
4791         !defined $bd->{$_} or
4792             fail "buildinfo contains $_"
4793             foreach qw(Changes Changed-by Distribution);
4794     }
4795     push @i_buildinfos, $bi;
4796     delete $i_param{'buildinfo-filename'};
4797 }
4798
4799 sub i_localname_changes {
4800     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4801     $i_changesfn = $i_dscfn;
4802     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4803     return $i_changesfn;
4804 }
4805 sub i_file_changes { }
4806
4807 sub i_want_signed_tag {
4808     printdebug Dumper(\%i_param, $i_dscfn);
4809     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4810         && defined $i_param{'csuite'}
4811         or badproto \*RO, "premature desire for signed-tag";
4812     my $head = $i_param{'head'};
4813     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4814
4815     my $maintview = $i_param{'maint-view'};
4816     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4817
4818     select_tagformat();
4819     if ($protovsn >= 4) {
4820         my $p = $i_param{'tagformat'} // '<undef>';
4821         $p eq $tagformat
4822             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4823     }
4824
4825     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4826     $csuite = $&;
4827     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4828
4829     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4830
4831     return
4832         push_mktags $i_clogp, $i_dscfn,
4833             $i_changesfn, 'remote changes',
4834             \@tagwants;
4835 }
4836
4837 sub i_want_signed_dsc_changes {
4838     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4839     sign_changes $i_changesfn;
4840     return ($i_dscfn, $i_changesfn, @i_buildinfos);
4841 }
4842
4843 #---------- building etc. ----------
4844
4845 our $version;
4846 our $sourcechanges;
4847 our $dscfn;
4848
4849 #----- `3.0 (quilt)' handling -----
4850
4851 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4852
4853 sub quiltify_dpkg_commit ($$$;$) {
4854     my ($patchname,$author,$msg, $xinfo) = @_;
4855     $xinfo //= '';
4856
4857     mkpath '.git/dgit';
4858     my $descfn = ".git/dgit/quilt-description.tmp";
4859     open O, '>', $descfn or die "$descfn: $!";
4860     $msg =~ s/\n+/\n\n/;
4861     print O <<END or die $!;
4862 From: $author
4863 ${xinfo}Subject: $msg
4864 ---
4865
4866 END
4867     close O or die $!;
4868
4869     {
4870         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4871         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4872         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4873         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4874     }
4875 }
4876
4877 sub quiltify_trees_differ ($$;$$$) {
4878     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4879     # returns true iff the two tree objects differ other than in debian/
4880     # with $finegrained,
4881     # returns bitmask 01 - differ in upstream files except .gitignore
4882     #                 02 - differ in .gitignore
4883     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4884     #  is set for each modified .gitignore filename $fn
4885     # if $unrepres is defined, array ref to which is appeneded
4886     #  a list of unrepresentable changes (removals of upstream files
4887     #  (as messages)
4888     local $/=undef;
4889     my @cmd = (@git, qw(diff-tree -z));
4890     push @cmd, qw(--name-only) unless $unrepres;
4891     push @cmd, qw(-r) if $finegrained || $unrepres;
4892     push @cmd, $x, $y;
4893     my $diffs= cmdoutput @cmd;
4894     my $r = 0;
4895     my @lmodes;
4896     foreach my $f (split /\0/, $diffs) {
4897         if ($unrepres && !@lmodes) {
4898             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4899             next;
4900         }
4901         my ($oldmode,$newmode) = @lmodes;
4902         @lmodes = ();
4903
4904         next if $f =~ m#^debian(?:/.*)?$#s;
4905
4906         if ($unrepres) {
4907             eval {
4908                 die "not a plain file\n"
4909                     unless $newmode =~ m/^10\d{4}$/ ||
4910                            $oldmode =~ m/^10\d{4}$/;
4911                 if ($oldmode =~ m/[^0]/ &&
4912                     $newmode =~ m/[^0]/) {
4913                     die "mode changed\n" if $oldmode ne $newmode;
4914                 } else {
4915                     die "non-default mode\n"
4916                         unless $newmode =~ m/^100644$/ ||
4917                                $oldmode =~ m/^100644$/;
4918                 }
4919             };
4920             if ($@) {
4921                 local $/="\n"; chomp $@;
4922                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4923             }
4924         }
4925
4926         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4927         $r |= $isignore ? 02 : 01;
4928         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4929     }
4930     printdebug "quiltify_trees_differ $x $y => $r\n";
4931     return $r;
4932 }
4933
4934 sub quiltify_tree_sentinelfiles ($) {
4935     # lists the `sentinel' files present in the tree
4936     my ($x) = @_;
4937     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4938         qw(-- debian/rules debian/control);
4939     $r =~ s/\n/,/g;
4940     return $r;
4941 }
4942
4943 sub quiltify_splitbrain_needed () {
4944     if (!$split_brain) {
4945         progress "dgit view: changes are required...";
4946         runcmd @git, qw(checkout -q -b dgit-view);
4947         $split_brain = 1;
4948     }
4949 }
4950
4951 sub quiltify_splitbrain ($$$$$$) {
4952     my ($clogp, $unapplied, $headref, $diffbits,
4953         $editedignores, $cachekey) = @_;
4954     if ($quilt_mode !~ m/gbp|dpm/) {
4955         # treat .gitignore just like any other upstream file
4956         $diffbits = { %$diffbits };
4957         $_ = !!$_ foreach values %$diffbits;
4958     }
4959     # We would like any commits we generate to be reproducible
4960     my @authline = clogp_authline($clogp);
4961     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4962     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4963     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4964     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4965     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4966     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4967
4968     if ($quilt_mode =~ m/gbp|unapplied/ &&
4969         ($diffbits->{O2H} & 01)) {
4970         my $msg =
4971  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4972  " but git tree differs from orig in upstream files.";
4973         if (!stat_exists "debian/patches") {
4974             $msg .=
4975  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4976         }
4977         fail $msg;
4978     }
4979     if ($quilt_mode =~ m/dpm/ &&
4980         ($diffbits->{H2A} & 01)) {
4981         fail <<END;
4982 --quilt=$quilt_mode specified, implying patches-applied git tree
4983  but git tree differs from result of applying debian/patches to upstream
4984 END
4985     }
4986     if ($quilt_mode =~ m/gbp|unapplied/ &&
4987         ($diffbits->{O2A} & 01)) { # some patches
4988         quiltify_splitbrain_needed();
4989         progress "dgit view: creating patches-applied version using gbp pq";
4990         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4991         # gbp pq import creates a fresh branch; push back to dgit-view
4992         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4993         runcmd @git, qw(checkout -q dgit-view);
4994     }
4995     if ($quilt_mode =~ m/gbp|dpm/ &&
4996         ($diffbits->{O2A} & 02)) {
4997         fail <<END
4998 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4999  tool which does not create patches for changes to upstream
5000  .gitignores: but, such patches exist in debian/patches.
5001 END
5002     }
5003     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5004         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5005         quiltify_splitbrain_needed();
5006         progress "dgit view: creating patch to represent .gitignore changes";
5007         ensuredir "debian/patches";
5008         my $gipatch = "debian/patches/auto-gitignore";
5009         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
5010         stat GIPATCH or die "$gipatch: $!";
5011         fail "$gipatch already exists; but want to create it".
5012             " to record .gitignore changes" if (stat _)[7];
5013         print GIPATCH <<END or die "$gipatch: $!";
5014 Subject: Update .gitignore from Debian packaging branch
5015
5016 The Debian packaging git branch contains these updates to the upstream
5017 .gitignore file(s).  This patch is autogenerated, to provide these
5018 updates to users of the official Debian archive view of the package.
5019
5020 [dgit ($our_version) update-gitignore]
5021 ---
5022 END
5023         close GIPATCH or die "$gipatch: $!";
5024         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5025             $unapplied, $headref, "--", sort keys %$editedignores;
5026         open SERIES, "+>>", "debian/patches/series" or die $!;
5027         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
5028         my $newline;
5029         defined read SERIES, $newline, 1 or die $!;
5030         print SERIES "\n" or die $! unless $newline eq "\n";
5031         print SERIES "auto-gitignore\n" or die $!;
5032         close SERIES or die  $!;
5033         runcmd @git, qw(add -- debian/patches/series), $gipatch;
5034         commit_admin <<END
5035 Commit patch to update .gitignore
5036
5037 [dgit ($our_version) update-gitignore-quilt-fixup]
5038 END
5039     }
5040
5041     my $dgitview = git_rev_parse 'HEAD';
5042
5043     changedir '../../../..';
5044     # When we no longer need to support squeeze, use --create-reflog
5045     # instead of this:
5046     ensuredir ".git/logs/refs/dgit-intern";
5047     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
5048       or die $!;
5049
5050     my $oldcache = git_get_ref "refs/$splitbraincache";
5051     if ($oldcache eq $dgitview) {
5052         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
5053         # git update-ref doesn't always update, in this case.  *sigh*
5054         my $dummy = make_commit_text <<END;
5055 tree $tree
5056 parent $dgitview
5057 author Dgit <dgit\@example.com> 1000000000 +0000
5058 committer Dgit <dgit\@example.com> 1000000000 +0000
5059
5060 Dummy commit - do not use
5061 END
5062         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
5063             "refs/$splitbraincache", $dummy;
5064     }
5065     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
5066         $dgitview;
5067
5068     changedir '.git/dgit/unpack/work';
5069
5070     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5071     progress "dgit view: created ($saved)";
5072 }
5073
5074 sub quiltify ($$$$) {
5075     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5076
5077     # Quilt patchification algorithm
5078     #
5079     # We search backwards through the history of the main tree's HEAD
5080     # (T) looking for a start commit S whose tree object is identical
5081     # to to the patch tip tree (ie the tree corresponding to the
5082     # current dpkg-committed patch series).  For these purposes
5083     # `identical' disregards anything in debian/ - this wrinkle is
5084     # necessary because dpkg-source treates debian/ specially.
5085     #
5086     # We can only traverse edges where at most one of the ancestors'
5087     # trees differs (in changes outside in debian/).  And we cannot
5088     # handle edges which change .pc/ or debian/patches.  To avoid
5089     # going down a rathole we avoid traversing edges which introduce
5090     # debian/rules or debian/control.  And we set a limit on the
5091     # number of edges we are willing to look at.
5092     #
5093     # If we succeed, we walk forwards again.  For each traversed edge
5094     # PC (with P parent, C child) (starting with P=S and ending with
5095     # C=T) to we do this:
5096     #  - git checkout C
5097     #  - dpkg-source --commit with a patch name and message derived from C
5098     # After traversing PT, we git commit the changes which
5099     # should be contained within debian/patches.
5100
5101     # The search for the path S..T is breadth-first.  We maintain a
5102     # todo list containing search nodes.  A search node identifies a
5103     # commit, and looks something like this:
5104     #  $p = {
5105     #      Commit => $git_commit_id,
5106     #      Child => $c,                          # or undef if P=T
5107     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5108     #      Nontrivial => true iff $p..$c has relevant changes
5109     #  };
5110
5111     my @todo;
5112     my @nots;
5113     my $sref_S;
5114     my $max_work=100;
5115     my %considered; # saves being exponential on some weird graphs
5116
5117     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5118
5119     my $not = sub {
5120         my ($search,$whynot) = @_;
5121         printdebug " search NOT $search->{Commit} $whynot\n";
5122         $search->{Whynot} = $whynot;
5123         push @nots, $search;
5124         no warnings qw(exiting);
5125         next;
5126     };
5127
5128     push @todo, {
5129         Commit => $target,
5130     };
5131
5132     while (@todo) {
5133         my $c = shift @todo;
5134         next if $considered{$c->{Commit}}++;
5135
5136         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5137
5138         printdebug "quiltify investigate $c->{Commit}\n";
5139
5140         # are we done?
5141         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5142             printdebug " search finished hooray!\n";
5143             $sref_S = $c;
5144             last;
5145         }
5146
5147         if ($quilt_mode eq 'nofix') {
5148             fail "quilt fixup required but quilt mode is \`nofix'\n".
5149                 "HEAD commit $c->{Commit} differs from tree implied by ".
5150                 " debian/patches (tree object $oldtiptree)";
5151         }
5152         if ($quilt_mode eq 'smash') {
5153             printdebug " search quitting smash\n";
5154             last;
5155         }
5156
5157         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5158         $not->($c, "has $c_sentinels not $t_sentinels")
5159             if $c_sentinels ne $t_sentinels;
5160
5161         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5162         $commitdata =~ m/\n\n/;
5163         $commitdata =~ $`;
5164         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5165         @parents = map { { Commit => $_, Child => $c } } @parents;
5166
5167         $not->($c, "root commit") if !@parents;
5168
5169         foreach my $p (@parents) {
5170             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5171         }
5172         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5173         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5174
5175         foreach my $p (@parents) {
5176             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5177
5178             my @cmd= (@git, qw(diff-tree -r --name-only),
5179                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5180             my $patchstackchange = cmdoutput @cmd;
5181             if (length $patchstackchange) {
5182                 $patchstackchange =~ s/\n/,/g;
5183                 $not->($p, "changed $patchstackchange");
5184             }
5185
5186             printdebug " search queue P=$p->{Commit} ",
5187                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5188             push @todo, $p;
5189         }
5190     }
5191
5192     if (!$sref_S) {
5193         printdebug "quiltify want to smash\n";
5194
5195         my $abbrev = sub {
5196             my $x = $_[0]{Commit};
5197             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5198             return $x;
5199         };
5200         my $reportnot = sub {
5201             my ($notp) = @_;
5202             my $s = $abbrev->($notp);
5203             my $c = $notp->{Child};
5204             $s .= "..".$abbrev->($c) if $c;
5205             $s .= ": ".$notp->{Whynot};
5206             return $s;
5207         };
5208         if ($quilt_mode eq 'linear') {
5209             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5210             foreach my $notp (@nots) {
5211                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5212             }
5213             print STDERR "$us: $_\n" foreach @$failsuggestion;
5214             fail "quilt fixup naive history linearisation failed.\n".
5215  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5216         } elsif ($quilt_mode eq 'smash') {
5217         } elsif ($quilt_mode eq 'auto') {
5218             progress "quilt fixup cannot be linear, smashing...";
5219         } else {
5220             die "$quilt_mode ?";
5221         }
5222
5223         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5224         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5225         my $ncommits = 3;
5226         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5227
5228         quiltify_dpkg_commit "auto-$version-$target-$time",
5229             (getfield $clogp, 'Maintainer'),
5230             "Automatically generated patch ($clogp->{Version})\n".
5231             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5232         return;
5233     }
5234
5235     progress "quiltify linearisation planning successful, executing...";
5236
5237     for (my $p = $sref_S;
5238          my $c = $p->{Child};
5239          $p = $p->{Child}) {
5240         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5241         next unless $p->{Nontrivial};
5242
5243         my $cc = $c->{Commit};
5244
5245         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5246         $commitdata =~ m/\n\n/ or die "$c ?";
5247         $commitdata = $`;
5248         my $msg = $'; #';
5249         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5250         my $author = $1;
5251
5252         my $commitdate = cmdoutput
5253             @git, qw(log -n1 --pretty=format:%aD), $cc;
5254
5255         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5256
5257         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5258         $strip_nls->();
5259
5260         my $title = $1;
5261         my $patchname;
5262         my $patchdir;
5263
5264         my $gbp_check_suitable = sub {
5265             $_ = shift;
5266             my ($what) = @_;
5267
5268             eval {
5269                 die "contains unexpected slashes\n" if m{//} || m{/$};
5270                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5271                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5272                 die "too long" if length > 200;
5273             };
5274             return $_ unless $@;
5275             print STDERR "quiltifying commit $cc:".
5276                 " ignoring/dropping Gbp-Pq $what: $@";
5277             return undef;
5278         };
5279
5280         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5281                            gbp-pq-name: \s* )
5282                        (\S+) \s* \n //ixm) {
5283             $patchname = $gbp_check_suitable->($1, 'Name');
5284         }
5285         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5286                            gbp-pq-topic: \s* )
5287                        (\S+) \s* \n //ixm) {
5288             $patchdir = $gbp_check_suitable->($1, 'Topic');
5289         }
5290
5291         $strip_nls->();
5292
5293         if (!defined $patchname) {
5294             $patchname = $title;
5295             $patchname =~ s/[.:]$//;
5296             use Text::Iconv;
5297             eval {
5298                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5299                 my $translitname = $converter->convert($patchname);
5300                 die unless defined $translitname;
5301                 $patchname = $translitname;
5302             };
5303             print STDERR
5304                 "dgit: patch title transliteration error: $@"
5305                 if $@;
5306             $patchname =~ y/ A-Z/-a-z/;
5307             $patchname =~ y/-a-z0-9_.+=~//cd;
5308             $patchname =~ s/^\W/x-$&/;
5309             $patchname = substr($patchname,0,40);
5310         }
5311         if (!defined $patchdir) {
5312             $patchdir = '';
5313         }
5314         if (length $patchdir) {
5315             $patchname = "$patchdir/$patchname";
5316         }
5317         if ($patchname =~ m{^(.*)/}) {
5318             mkpath "debian/patches/$1";
5319         }
5320
5321         my $index;
5322         for ($index='';
5323              stat "debian/patches/$patchname$index";
5324              $index++) { }
5325         $!==ENOENT or die "$patchname$index $!";
5326
5327         runcmd @git, qw(checkout -q), $cc;
5328
5329         # We use the tip's changelog so that dpkg-source doesn't
5330         # produce complaining messages from dpkg-parsechangelog.  None
5331         # of the information dpkg-source gets from the changelog is
5332         # actually relevant - it gets put into the original message
5333         # which dpkg-source provides our stunt editor, and then
5334         # overwritten.
5335         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5336
5337         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5338             "Date: $commitdate\n".
5339             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5340
5341         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5342     }
5343
5344     runcmd @git, qw(checkout -q master);
5345 }
5346
5347 sub build_maybe_quilt_fixup () {
5348     my ($format,$fopts) = get_source_format;
5349     return unless madformat_wantfixup $format;
5350     # sigh
5351
5352     check_for_vendor_patches();
5353
5354     if (quiltmode_splitbrain) {
5355         fail <<END unless access_cfg_tagformats_can_splitbrain;
5356 quilt mode $quilt_mode requires split view so server needs to support
5357  both "new" and "maint" tag formats, but config says it doesn't.
5358 END
5359     }
5360
5361     my $clogp = parsechangelog();
5362     my $headref = git_rev_parse('HEAD');
5363
5364     prep_ud();
5365     changedir $ud;
5366
5367     my $upstreamversion = upstreamversion $version;
5368
5369     if ($fopts->{'single-debian-patch'}) {
5370         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5371     } else {
5372         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5373     }
5374
5375     die 'bug' if $split_brain && !$need_split_build_invocation;
5376
5377     changedir '../../../..';
5378     runcmd_ordryrun_local
5379         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5380 }
5381
5382 sub quilt_fixup_mkwork ($) {
5383     my ($headref) = @_;
5384
5385     mkdir "work" or die $!;
5386     changedir "work";
5387     mktree_in_ud_here();
5388     runcmd @git, qw(reset -q --hard), $headref;
5389 }
5390
5391 sub quilt_fixup_linkorigs ($$) {
5392     my ($upstreamversion, $fn) = @_;
5393     # calls $fn->($leafname);
5394
5395     foreach my $f (<../../../../*>) { #/){
5396         my $b=$f; $b =~ s{.*/}{};
5397         {
5398             local ($debuglevel) = $debuglevel-1;
5399             printdebug "QF linkorigs $b, $f ?\n";
5400         }
5401         next unless is_orig_file_of_vsn $b, $upstreamversion;
5402         printdebug "QF linkorigs $b, $f Y\n";
5403         link_ltarget $f, $b or die "$b $!";
5404         $fn->($b);
5405     }
5406 }
5407
5408 sub quilt_fixup_delete_pc () {
5409     runcmd @git, qw(rm -rqf .pc);
5410     commit_admin <<END
5411 Commit removal of .pc (quilt series tracking data)
5412
5413 [dgit ($our_version) upgrade quilt-remove-pc]
5414 END
5415 }
5416
5417 sub quilt_fixup_singlepatch ($$$) {
5418     my ($clogp, $headref, $upstreamversion) = @_;
5419
5420     progress "starting quiltify (single-debian-patch)";
5421
5422     # dpkg-source --commit generates new patches even if
5423     # single-debian-patch is in debian/source/options.  In order to
5424     # get it to generate debian/patches/debian-changes, it is
5425     # necessary to build the source package.
5426
5427     quilt_fixup_linkorigs($upstreamversion, sub { });
5428     quilt_fixup_mkwork($headref);
5429
5430     rmtree("debian/patches");
5431
5432     runcmd @dpkgsource, qw(-b .);
5433     changedir "..";
5434     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5435     rename srcfn("$upstreamversion", "/debian/patches"),
5436            "work/debian/patches";
5437
5438     changedir "work";
5439     commit_quilty_patch();
5440 }
5441
5442 sub quilt_make_fake_dsc ($) {
5443     my ($upstreamversion) = @_;
5444
5445     my $fakeversion="$upstreamversion-~~DGITFAKE";
5446
5447     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5448     print $fakedsc <<END or die $!;
5449 Format: 3.0 (quilt)
5450 Source: $package
5451 Version: $fakeversion
5452 Files:
5453 END
5454
5455     my $dscaddfile=sub {
5456         my ($b) = @_;
5457
5458         my $md = new Digest::MD5;
5459
5460         my $fh = new IO::File $b, '<' or die "$b $!";
5461         stat $fh or die $!;
5462         my $size = -s _;
5463
5464         $md->addfile($fh);
5465         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5466     };
5467
5468     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5469
5470     my @files=qw(debian/source/format debian/rules
5471                  debian/control debian/changelog);
5472     foreach my $maybe (qw(debian/patches debian/source/options
5473                           debian/tests/control)) {
5474         next unless stat_exists "../../../$maybe";
5475         push @files, $maybe;
5476     }
5477
5478     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5479     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5480
5481     $dscaddfile->($debtar);
5482     close $fakedsc or die $!;
5483 }
5484
5485 sub quilt_check_splitbrain_cache ($$) {
5486     my ($headref, $upstreamversion) = @_;
5487     # Called only if we are in (potentially) split brain mode.
5488     # Called in $ud.
5489     # Computes the cache key and looks in the cache.
5490     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5491
5492     my $splitbrain_cachekey;
5493
5494     progress
5495  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5496     # we look in the reflog of dgit-intern/quilt-cache
5497     # we look for an entry whose message is the key for the cache lookup
5498     my @cachekey = (qw(dgit), $our_version);
5499     push @cachekey, $upstreamversion;
5500     push @cachekey, $quilt_mode;
5501     push @cachekey, $headref;
5502
5503     push @cachekey, hashfile('fake.dsc');
5504
5505     my $srcshash = Digest::SHA->new(256);
5506     my %sfs = ( %INC, '$0(dgit)' => $0 );
5507     foreach my $sfk (sort keys %sfs) {
5508         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5509         $srcshash->add($sfk,"  ");
5510         $srcshash->add(hashfile($sfs{$sfk}));
5511         $srcshash->add("\n");
5512     }
5513     push @cachekey, $srcshash->hexdigest();
5514     $splitbrain_cachekey = "@cachekey";
5515
5516     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5517                $splitbraincache);
5518     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5519     debugcmd "|(probably)",@cmd;
5520     my $child = open GC, "-|";  defined $child or die $!;
5521     if (!$child) {
5522         chdir '../../..' or die $!;
5523         if (!stat ".git/logs/refs/$splitbraincache") {
5524             $! == ENOENT or die $!;
5525             printdebug ">(no reflog)\n";
5526             exit 0;
5527         }
5528         exec @cmd; die $!;
5529     }
5530     while (<GC>) {
5531         chomp;
5532         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5533         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5534
5535         my $cachehit = $1;
5536         quilt_fixup_mkwork($headref);
5537         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5538         if ($cachehit ne $headref) {
5539             progress "dgit view: found cached ($saved)";
5540             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5541             $split_brain = 1;
5542             return ($cachehit, $splitbrain_cachekey);
5543         }
5544         progress "dgit view: found cached, no changes required";
5545         return ($headref, $splitbrain_cachekey);
5546     }
5547     die $! if GC->error;
5548     failedcmd unless close GC;
5549
5550     printdebug "splitbrain cache miss\n";
5551     return (undef, $splitbrain_cachekey);
5552 }
5553
5554 sub quilt_fixup_multipatch ($$$) {
5555     my ($clogp, $headref, $upstreamversion) = @_;
5556
5557     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5558
5559     # Our objective is:
5560     #  - honour any existing .pc in case it has any strangeness
5561     #  - determine the git commit corresponding to the tip of
5562     #    the patch stack (if there is one)
5563     #  - if there is such a git commit, convert each subsequent
5564     #    git commit into a quilt patch with dpkg-source --commit
5565     #  - otherwise convert all the differences in the tree into
5566     #    a single git commit
5567     #
5568     # To do this we:
5569
5570     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5571     # dgit would include the .pc in the git tree.)  If there isn't
5572     # one, we need to generate one by unpacking the patches that we
5573     # have.
5574     #
5575     # We first look for a .pc in the git tree.  If there is one, we
5576     # will use it.  (This is not the normal case.)
5577     #
5578     # Otherwise need to regenerate .pc so that dpkg-source --commit
5579     # can work.  We do this as follows:
5580     #     1. Collect all relevant .orig from parent directory
5581     #     2. Generate a debian.tar.gz out of
5582     #         debian/{patches,rules,source/format,source/options}
5583     #     3. Generate a fake .dsc containing just these fields:
5584     #          Format Source Version Files
5585     #     4. Extract the fake .dsc
5586     #        Now the fake .dsc has a .pc directory.
5587     # (In fact we do this in every case, because in future we will
5588     # want to search for a good base commit for generating patches.)
5589     #
5590     # Then we can actually do the dpkg-source --commit
5591     #     1. Make a new working tree with the same object
5592     #        store as our main tree and check out the main
5593     #        tree's HEAD.
5594     #     2. Copy .pc from the fake's extraction, if necessary
5595     #     3. Run dpkg-source --commit
5596     #     4. If the result has changes to debian/, then
5597     #          - git add them them
5598     #          - git add .pc if we had a .pc in-tree
5599     #          - git commit
5600     #     5. If we had a .pc in-tree, delete it, and git commit
5601     #     6. Back in the main tree, fast forward to the new HEAD
5602
5603     # Another situation we may have to cope with is gbp-style
5604     # patches-unapplied trees.
5605     #
5606     # We would want to detect these, so we know to escape into
5607     # quilt_fixup_gbp.  However, this is in general not possible.
5608     # Consider a package with a one patch which the dgit user reverts
5609     # (with git revert or the moral equivalent).
5610     #
5611     # That is indistinguishable in contents from a patches-unapplied
5612     # tree.  And looking at the history to distinguish them is not
5613     # useful because the user might have made a confusing-looking git
5614     # history structure (which ought to produce an error if dgit can't
5615     # cope, not a silent reintroduction of an unwanted patch).
5616     #
5617     # So gbp users will have to pass an option.  But we can usually
5618     # detect their failure to do so: if the tree is not a clean
5619     # patches-applied tree, quilt linearisation fails, but the tree
5620     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5621     # they want --quilt=unapplied.
5622     #
5623     # To help detect this, when we are extracting the fake dsc, we
5624     # first extract it with --skip-patches, and then apply the patches
5625     # afterwards with dpkg-source --before-build.  That lets us save a
5626     # tree object corresponding to .origs.
5627
5628     my $splitbrain_cachekey;
5629
5630     quilt_make_fake_dsc($upstreamversion);
5631
5632     if (quiltmode_splitbrain()) {
5633         my $cachehit;
5634         ($cachehit, $splitbrain_cachekey) =
5635             quilt_check_splitbrain_cache($headref, $upstreamversion);
5636         return if $cachehit;
5637     }
5638
5639     runcmd qw(sh -ec),
5640         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5641
5642     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5643     rename $fakexdir, "fake" or die "$fakexdir $!";
5644
5645     changedir 'fake';
5646
5647     remove_stray_gits("source package");
5648     mktree_in_ud_here();
5649
5650     rmtree '.pc';
5651
5652     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5653     my $unapplied=git_add_write_tree();
5654     printdebug "fake orig tree object $unapplied\n";
5655
5656     ensuredir '.pc';
5657
5658     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5659     $!=0; $?=-1;
5660     if (system @bbcmd) {
5661         failedcmd @bbcmd if $? < 0;
5662         fail <<END;
5663 failed to apply your git tree's patch stack (from debian/patches/) to
5664  the corresponding upstream tarball(s).  Your source tree and .orig
5665  are probably too inconsistent.  dgit can only fix up certain kinds of
5666  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5667 END
5668     }
5669
5670     changedir '..';
5671
5672     quilt_fixup_mkwork($headref);
5673
5674     my $mustdeletepc=0;
5675     if (stat_exists ".pc") {
5676         -d _ or die;
5677         progress "Tree already contains .pc - will use it then delete it.";
5678         $mustdeletepc=1;
5679     } else {
5680         rename '../fake/.pc','.pc' or die $!;
5681     }
5682
5683     changedir '../fake';
5684     rmtree '.pc';
5685     my $oldtiptree=git_add_write_tree();
5686     printdebug "fake o+d/p tree object $unapplied\n";
5687     changedir '../work';
5688
5689
5690     # We calculate some guesswork now about what kind of tree this might
5691     # be.  This is mostly for error reporting.
5692
5693     my %editedignores;
5694     my @unrepres;
5695     my $diffbits = {
5696         # H = user's HEAD
5697         # O = orig, without patches applied
5698         # A = "applied", ie orig with H's debian/patches applied
5699         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5700                                      \%editedignores, \@unrepres),
5701         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5702         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5703     };
5704
5705     my @dl;
5706     foreach my $b (qw(01 02)) {
5707         foreach my $v (qw(O2H O2A H2A)) {
5708             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5709         }
5710     }
5711     printdebug "differences \@dl @dl.\n";
5712
5713     progress sprintf
5714 "$us: base trees orig=%.20s o+d/p=%.20s",
5715               $unapplied, $oldtiptree;
5716     progress sprintf
5717 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5718 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5719                              $dl[0], $dl[1],              $dl[3], $dl[4],
5720                                  $dl[2],                     $dl[5];
5721
5722     if (@unrepres) {
5723         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5724             foreach @unrepres;
5725         forceable_fail [qw(unrepresentable)], <<END;
5726 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5727 END
5728     }
5729
5730     my @failsuggestion;
5731     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5732         push @failsuggestion, "This might be a patches-unapplied branch.";
5733     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5734         push @failsuggestion, "This might be a patches-applied branch.";
5735     }
5736     push @failsuggestion, "Maybe you need to specify one of".
5737         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5738
5739     if (quiltmode_splitbrain()) {
5740         quiltify_splitbrain($clogp, $unapplied, $headref,
5741                             $diffbits, \%editedignores,
5742                             $splitbrain_cachekey);
5743         return;
5744     }
5745
5746     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5747     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5748
5749     if (!open P, '>>', ".pc/applied-patches") {
5750         $!==&ENOENT or die $!;
5751     } else {
5752         close P;
5753     }
5754
5755     commit_quilty_patch();
5756
5757     if ($mustdeletepc) {
5758         quilt_fixup_delete_pc();
5759     }
5760 }
5761
5762 sub quilt_fixup_editor () {
5763     my $descfn = $ENV{$fakeeditorenv};
5764     my $editing = $ARGV[$#ARGV];
5765     open I1, '<', $descfn or die "$descfn: $!";
5766     open I2, '<', $editing or die "$editing: $!";
5767     unlink $editing or die "$editing: $!";
5768     open O, '>', $editing or die "$editing: $!";
5769     while (<I1>) { print O or die $!; } I1->error and die $!;
5770     my $copying = 0;
5771     while (<I2>) {
5772         $copying ||= m/^\-\-\- /;
5773         next unless $copying;
5774         print O or die $!;
5775     }
5776     I2->error and die $!;
5777     close O or die $1;
5778     exit 0;
5779 }
5780
5781 sub maybe_apply_patches_dirtily () {
5782     return unless $quilt_mode =~ m/gbp|unapplied/;
5783     print STDERR <<END or die $!;
5784
5785 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5786 dgit: Have to apply the patches - making the tree dirty.
5787 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5788
5789 END
5790     $patches_applied_dirtily = 01;
5791     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5792     runcmd qw(dpkg-source --before-build .);
5793 }
5794
5795 sub maybe_unapply_patches_again () {
5796     progress "dgit: Unapplying patches again to tidy up the tree."
5797         if $patches_applied_dirtily;
5798     runcmd qw(dpkg-source --after-build .)
5799         if $patches_applied_dirtily & 01;
5800     rmtree '.pc'
5801         if $patches_applied_dirtily & 02;
5802     $patches_applied_dirtily = 0;
5803 }
5804
5805 #----- other building -----
5806
5807 our $clean_using_builder;
5808 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5809 #   clean the tree before building (perhaps invoked indirectly by
5810 #   whatever we are using to run the build), rather than separately
5811 #   and explicitly by us.
5812
5813 sub clean_tree () {
5814     return if $clean_using_builder;
5815     if ($cleanmode eq 'dpkg-source') {
5816         maybe_apply_patches_dirtily();
5817         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5818     } elsif ($cleanmode eq 'dpkg-source-d') {
5819         maybe_apply_patches_dirtily();
5820         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5821     } elsif ($cleanmode eq 'git') {
5822         runcmd_ordryrun_local @git, qw(clean -xdf);
5823     } elsif ($cleanmode eq 'git-ff') {
5824         runcmd_ordryrun_local @git, qw(clean -xdff);
5825     } elsif ($cleanmode eq 'check') {
5826         my $leftovers = cmdoutput @git, qw(clean -xdn);
5827         if (length $leftovers) {
5828             print STDERR $leftovers, "\n" or die $!;
5829             fail "tree contains uncommitted files and --clean=check specified";
5830         }
5831     } elsif ($cleanmode eq 'none') {
5832     } else {
5833         die "$cleanmode ?";
5834     }
5835 }
5836
5837 sub cmd_clean () {
5838     badusage "clean takes no additional arguments" if @ARGV;
5839     notpushing();
5840     clean_tree();
5841     maybe_unapply_patches_again();
5842 }
5843
5844 sub build_prep_early () {
5845     our $build_prep_early_done //= 0;
5846     return if $build_prep_early_done++;
5847     badusage "-p is not allowed when building" if defined $package;
5848     my $clogp = parsechangelog();
5849     $isuite = getfield $clogp, 'Distribution';
5850     $package = getfield $clogp, 'Source';
5851     $version = getfield $clogp, 'Version';
5852     notpushing();
5853     check_not_dirty();
5854 }
5855
5856 sub build_prep () {
5857     build_prep_early();
5858     clean_tree();
5859     build_maybe_quilt_fixup();
5860     if ($rmchanges) {
5861         my $pat = changespat $version;
5862         foreach my $f (glob "$buildproductsdir/$pat") {
5863             if (act_local()) {
5864                 unlink $f or fail "remove old changes file $f: $!";
5865             } else {
5866                 progress "would remove $f";
5867             }
5868         }
5869     }
5870 }
5871
5872 sub changesopts_initial () {
5873     my @opts =@changesopts[1..$#changesopts];
5874 }
5875
5876 sub changesopts_version () {
5877     if (!defined $changes_since_version) {
5878         my @vsns = archive_query('archive_query');
5879         my @quirk = access_quirk();
5880         if ($quirk[0] eq 'backports') {
5881             local $isuite = $quirk[2];
5882             local $csuite;
5883             canonicalise_suite();
5884             push @vsns, archive_query('archive_query');
5885         }
5886         if (@vsns) {
5887             @vsns = map { $_->[0] } @vsns;
5888             @vsns = sort { -version_compare($a, $b) } @vsns;
5889             $changes_since_version = $vsns[0];
5890             progress "changelog will contain changes since $vsns[0]";
5891         } else {
5892             $changes_since_version = '_';
5893             progress "package seems new, not specifying -v<version>";
5894         }
5895     }
5896     if ($changes_since_version ne '_') {
5897         return ("-v$changes_since_version");
5898     } else {
5899         return ();
5900     }
5901 }
5902
5903 sub changesopts () {
5904     return (changesopts_initial(), changesopts_version());
5905 }
5906
5907 sub massage_dbp_args ($;$) {
5908     my ($cmd,$xargs) = @_;
5909     # We need to:
5910     #
5911     #  - if we're going to split the source build out so we can
5912     #    do strange things to it, massage the arguments to dpkg-buildpackage
5913     #    so that the main build doessn't build source (or add an argument
5914     #    to stop it building source by default).
5915     #
5916     #  - add -nc to stop dpkg-source cleaning the source tree,
5917     #    unless we're not doing a split build and want dpkg-source
5918     #    as cleanmode, in which case we can do nothing
5919     #
5920     # return values:
5921     #    0 - source will NOT need to be built separately by caller
5922     #   +1 - source will need to be built separately by caller
5923     #   +2 - source will need to be built separately by caller AND
5924     #        dpkg-buildpackage should not in fact be run at all!
5925     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5926 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5927     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5928         $clean_using_builder = 1;
5929         return 0;
5930     }
5931     # -nc has the side effect of specifying -b if nothing else specified
5932     # and some combinations of -S, -b, et al, are errors, rather than
5933     # later simply overriding earlie.  So we need to:
5934     #  - search the command line for these options
5935     #  - pick the last one
5936     #  - perhaps add our own as a default
5937     #  - perhaps adjust it to the corresponding non-source-building version
5938     my $dmode = '-F';
5939     foreach my $l ($cmd, $xargs) {
5940         next unless $l;
5941         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5942     }
5943     push @$cmd, '-nc';
5944 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5945     my $r = 0;
5946     if ($need_split_build_invocation) {
5947         printdebug "massage split $dmode.\n";
5948         $r = $dmode =~ m/[S]/     ? +2 :
5949              $dmode =~ y/gGF/ABb/ ? +1 :
5950              $dmode =~ m/[ABb]/   ?  0 :
5951              die "$dmode ?";
5952     }
5953     printdebug "massage done $r $dmode.\n";
5954     push @$cmd, $dmode;
5955 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5956     return $r;
5957 }
5958
5959 sub in_parent (&) {
5960     my ($fn) = @_;
5961     my $wasdir = must_getcwd();
5962     changedir "..";
5963     $fn->();
5964     changedir $wasdir;
5965 }
5966
5967 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5968     my ($msg_if_onlyone) = @_;
5969     # If there is only one .changes file, fail with $msg_if_onlyone,
5970     # or if that is undef, be a no-op.
5971     # Returns the changes file to report to the user.
5972     my $pat = changespat $version;
5973     my @changesfiles = glob $pat;
5974     @changesfiles = sort {
5975         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5976             or $a cmp $b
5977     } @changesfiles;
5978     my $result;
5979     if (@changesfiles==1) {
5980         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5981 only one changes file from build (@changesfiles)
5982 END
5983         $result = $changesfiles[0];
5984     } elsif (@changesfiles==2) {
5985         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5986         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5987             fail "$l found in binaries changes file $binchanges"
5988                 if $l =~ m/\.dsc$/;
5989         }
5990         runcmd_ordryrun_local @mergechanges, @changesfiles;
5991         my $multichanges = changespat $version,'multi';
5992         if (act_local()) {
5993             stat_exists $multichanges or fail "$multichanges: $!";
5994             foreach my $cf (glob $pat) {
5995                 next if $cf eq $multichanges;
5996                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5997             }
5998         }
5999         $result = $multichanges;
6000     } else {
6001         fail "wrong number of different changes files (@changesfiles)";
6002     }
6003     printdone "build successful, results in $result\n" or die $!;
6004 }
6005
6006 sub midbuild_checkchanges () {
6007     my $pat = changespat $version;
6008     return if $rmchanges;
6009     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
6010     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
6011     fail <<END
6012 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
6013 Suggest you delete @unwanted.
6014 END
6015         if @unwanted;
6016 }
6017
6018 sub midbuild_checkchanges_vanilla ($) {
6019     my ($wantsrc) = @_;
6020     midbuild_checkchanges() if $wantsrc == 1;
6021 }
6022
6023 sub postbuild_mergechanges_vanilla ($) {
6024     my ($wantsrc) = @_;
6025     if ($wantsrc == 1) {
6026         in_parent {
6027             postbuild_mergechanges(undef);
6028         };
6029     } else {
6030         printdone "build successful\n";
6031     }
6032 }
6033
6034 sub cmd_build {
6035     build_prep_early();
6036     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6037     my $wantsrc = massage_dbp_args \@dbp;
6038     if ($wantsrc > 0) {
6039         build_source();
6040         midbuild_checkchanges_vanilla $wantsrc;
6041     } else {
6042         build_prep();
6043     }
6044     if ($wantsrc < 2) {
6045         push @dbp, changesopts_version();
6046         maybe_apply_patches_dirtily();
6047         runcmd_ordryrun_local @dbp;
6048     }
6049     maybe_unapply_patches_again();
6050     postbuild_mergechanges_vanilla $wantsrc;
6051 }
6052
6053 sub pre_gbp_build {
6054     $quilt_mode //= 'gbp';
6055 }
6056
6057 sub cmd_gbp_build {
6058     build_prep_early();
6059
6060     # gbp can make .origs out of thin air.  In my tests it does this
6061     # even for a 1.0 format package, with no origs present.  So I
6062     # guess it keys off just the version number.  We don't know
6063     # exactly what .origs ought to exist, but let's assume that we
6064     # should run gbp if: the version has an upstream part and the main
6065     # orig is absent.
6066     my $upstreamversion = upstreamversion $version;
6067     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6068     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
6069
6070     if ($gbp_make_orig) {
6071         clean_tree();
6072         $cleanmode = 'none'; # don't do it again
6073         $need_split_build_invocation = 1;
6074     }
6075
6076     my @dbp = @dpkgbuildpackage;
6077
6078     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6079
6080     if (!length $gbp_build[0]) {
6081         if (length executable_on_path('git-buildpackage')) {
6082             $gbp_build[0] = qw(git-buildpackage);
6083         } else {
6084             $gbp_build[0] = 'gbp buildpackage';
6085         }
6086     }
6087     my @cmd = opts_opt_multi_cmd @gbp_build;
6088
6089     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
6090
6091     if ($gbp_make_orig) {
6092         ensuredir '.git/dgit';
6093         my $ok = '.git/dgit/origs-gen-ok';
6094         unlink $ok or $!==&ENOENT or die $!;
6095         my @origs_cmd = @cmd;
6096         push @origs_cmd, qw(--git-cleaner=true);
6097         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
6098         push @origs_cmd, @ARGV;
6099         if (act_local()) {
6100             debugcmd @origs_cmd;
6101             system @origs_cmd;
6102             do { local $!; stat_exists $ok; }
6103                 or failedcmd @origs_cmd;
6104         } else {
6105             dryrun_report @origs_cmd;
6106         }
6107     }
6108
6109     if ($wantsrc > 0) {
6110         build_source();
6111         midbuild_checkchanges_vanilla $wantsrc;
6112     } else {
6113         if (!$clean_using_builder) {
6114             push @cmd, '--git-cleaner=true';
6115         }
6116         build_prep();
6117     }
6118     maybe_unapply_patches_again();
6119     if ($wantsrc < 2) {
6120         push @cmd, changesopts();
6121         runcmd_ordryrun_local @cmd, @ARGV;
6122     }
6123     postbuild_mergechanges_vanilla $wantsrc;
6124 }
6125 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6126
6127 sub build_source {
6128     build_prep_early();
6129     my $our_cleanmode = $cleanmode;
6130     if ($need_split_build_invocation) {
6131         # Pretend that clean is being done some other way.  This
6132         # forces us not to try to use dpkg-buildpackage to clean and
6133         # build source all in one go; and instead we run dpkg-source
6134         # (and build_prep() will do the clean since $clean_using_builder
6135         # is false).
6136         $our_cleanmode = 'ELSEWHERE';
6137     }
6138     if ($our_cleanmode =~ m/^dpkg-source/) {
6139         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6140         $clean_using_builder = 1;
6141     }
6142     build_prep();
6143     $sourcechanges = changespat $version,'source';
6144     if (act_local()) {
6145         unlink "../$sourcechanges" or $!==ENOENT
6146             or fail "remove $sourcechanges: $!";
6147     }
6148     $dscfn = dscfn($version);
6149     if ($our_cleanmode eq 'dpkg-source') {
6150         maybe_apply_patches_dirtily();
6151         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6152             changesopts();
6153     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6154         maybe_apply_patches_dirtily();
6155         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6156             changesopts();
6157     } else {
6158         my @cmd = (@dpkgsource, qw(-b --));
6159         if ($split_brain) {
6160             changedir $ud;
6161             runcmd_ordryrun_local @cmd, "work";
6162             my @udfiles = <${package}_*>;
6163             changedir "../../..";
6164             foreach my $f (@udfiles) {
6165                 printdebug "source copy, found $f\n";
6166                 next unless
6167                     $f eq $dscfn or
6168                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6169                      $f eq srcfn($version, $&));
6170                 printdebug "source copy, found $f - renaming\n";
6171                 rename "$ud/$f", "../$f" or $!==ENOENT
6172                     or fail "put in place new source file ($f): $!";
6173             }
6174         } else {
6175             my $pwd = must_getcwd();
6176             my $leafdir = basename $pwd;
6177             changedir "..";
6178             runcmd_ordryrun_local @cmd, $leafdir;
6179             changedir $pwd;
6180         }
6181         runcmd_ordryrun_local qw(sh -ec),
6182             'exec >$1; shift; exec "$@"','x',
6183             "../$sourcechanges",
6184             @dpkggenchanges, qw(-S), changesopts();
6185     }
6186 }
6187
6188 sub cmd_build_source {
6189     build_prep_early();
6190     badusage "build-source takes no additional arguments" if @ARGV;
6191     build_source();
6192     maybe_unapply_patches_again();
6193     printdone "source built, results in $dscfn and $sourcechanges";
6194 }
6195
6196 sub cmd_sbuild {
6197     build_source();
6198     midbuild_checkchanges();
6199     in_parent {
6200         if (act_local()) {
6201             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6202             stat_exists $sourcechanges
6203                 or fail "$sourcechanges (in parent directory): $!";
6204         }
6205         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6206     };
6207     maybe_unapply_patches_again();
6208     in_parent {
6209         postbuild_mergechanges(<<END);
6210 perhaps you need to pass -A ?  (sbuild's default is to build only
6211 arch-specific binaries; dgit 1.4 used to override that.)
6212 END
6213     };
6214 }
6215
6216 sub cmd_quilt_fixup {
6217     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6218     build_prep_early();
6219     clean_tree();
6220     build_maybe_quilt_fixup();
6221 }
6222
6223 sub import_dsc_result {
6224     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6225     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6226     runcmd @cmd;
6227     check_gitattrs($newhash, "source tree");
6228
6229     progress "dgit: import-dsc: $what_msg";
6230 }
6231
6232 sub cmd_import_dsc {
6233     my $needsig = 0;
6234
6235     while (@ARGV) {
6236         last unless $ARGV[0] =~ m/^-/;
6237         $_ = shift @ARGV;
6238         last if m/^--?$/;
6239         if (m/^--require-valid-signature$/) {
6240             $needsig = 1;
6241         } else {
6242             badusage "unknown dgit import-dsc sub-option \`$_'";
6243         }
6244     }
6245
6246     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6247     my ($dscfn, $dstbranch) = @ARGV;
6248
6249     badusage "dry run makes no sense with import-dsc" unless act_local();
6250
6251     my $force = $dstbranch =~ s/^\+//   ? +1 :
6252                 $dstbranch =~ s/^\.\.// ? -1 :
6253                                            0;
6254     my $info = $force ? " $&" : '';
6255     $info = "$dscfn$info";
6256
6257     my $specbranch = $dstbranch;
6258     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6259     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6260
6261     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6262     my $chead = cmdoutput_errok @symcmd;
6263     defined $chead or $?==256 or failedcmd @symcmd;
6264
6265     fail "$dstbranch is checked out - will not update it"
6266         if defined $chead and $chead eq $dstbranch;
6267
6268     my $oldhash = git_get_ref $dstbranch;
6269
6270     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6271     $dscdata = do { local $/ = undef; <D>; };
6272     D->error and fail "read $dscfn: $!";
6273     close C;
6274
6275     # we don't normally need this so import it here
6276     use Dpkg::Source::Package;
6277     my $dp = new Dpkg::Source::Package filename => $dscfn,
6278         require_valid_signature => $needsig;
6279     {
6280         local $SIG{__WARN__} = sub {
6281             print STDERR $_[0];
6282             return unless $needsig;
6283             fail "import-dsc signature check failed";
6284         };
6285         if (!$dp->is_signed()) {
6286             warn "$us: warning: importing unsigned .dsc\n";
6287         } else {
6288             my $r = $dp->check_signature();
6289             die "->check_signature => $r" if $needsig && $r;
6290         }
6291     }
6292
6293     parse_dscdata();
6294
6295     $package = getfield $dsc, 'Source';
6296
6297     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6298         unless forceing [qw(import-dsc-with-dgit-field)];
6299     parse_dsc_field_def_dsc_distro();
6300
6301     $isuite = 'DGIT-IMPORT-DSC';
6302     $idistro //= $dsc_distro;
6303
6304     notpushing();
6305
6306     if (defined $dsc_hash) {
6307         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6308         resolve_dsc_field_commit undef, undef;
6309     }
6310     if (defined $dsc_hash) {
6311         my @cmd = (qw(sh -ec),
6312                    "echo $dsc_hash | git cat-file --batch-check");
6313         my $objgot = cmdoutput @cmd;
6314         if ($objgot =~ m#^\w+ missing\b#) {
6315             fail <<END
6316 .dsc contains Dgit field referring to object $dsc_hash
6317 Your git tree does not have that object.  Try `git fetch' from a
6318 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6319 END
6320         }
6321         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6322             if ($force > 0) {
6323                 progress "Not fast forward, forced update.";
6324             } else {
6325                 fail "Not fast forward to $dsc_hash";
6326             }
6327         }
6328         import_dsc_result $dstbranch, $dsc_hash,
6329             "dgit import-dsc (Dgit): $info",
6330             "updated git ref $dstbranch";
6331         return 0;
6332     }
6333
6334     fail <<END
6335 Branch $dstbranch already exists
6336 Specify ..$specbranch for a pseudo-merge, binding in existing history
6337 Specify  +$specbranch to overwrite, discarding existing history
6338 END
6339         if $oldhash && !$force;
6340
6341     my @dfi = dsc_files_info();
6342     foreach my $fi (@dfi) {
6343         my $f = $fi->{Filename};
6344         my $here = "../$f";
6345         next if lstat $here;
6346         fail "stat $here: $!" unless $! == ENOENT;
6347         my $there = $dscfn;
6348         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6349             $there = $';
6350         } elsif ($dscfn =~ m#^/#) {
6351             $there = $dscfn;
6352         } else {
6353             fail "cannot import $dscfn which seems to be inside working tree!";
6354         }
6355         $there =~ s#/+[^/]+$## or
6356             fail "cannot import $dscfn which seems to not have a basename";
6357         $there .= "/$f";
6358         symlink $there, $here or fail "symlink $there to $here: $!";
6359         progress "made symlink $here -> $there";
6360 #       print STDERR Dumper($fi);
6361     }
6362     my @mergeinputs = generate_commits_from_dsc();
6363     die unless @mergeinputs == 1;
6364
6365     my $newhash = $mergeinputs[0]{Commit};
6366
6367     if ($oldhash) {
6368         if ($force > 0) {
6369             progress "Import, forced update - synthetic orphan git history.";
6370         } elsif ($force < 0) {
6371             progress "Import, merging.";
6372             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6373             my $version = getfield $dsc, 'Version';
6374             my $clogp = commit_getclogp $newhash;
6375             my $authline = clogp_authline $clogp;
6376             $newhash = make_commit_text <<END;
6377 tree $tree
6378 parent $newhash
6379 parent $oldhash
6380 author $authline
6381 committer $authline
6382
6383 Merge $package ($version) import into $dstbranch
6384 END
6385         } else {
6386             die; # caught earlier
6387         }
6388     }
6389
6390     import_dsc_result $dstbranch, $newhash,
6391         "dgit import-dsc: $info",
6392         "results are in in git ref $dstbranch";
6393 }
6394
6395 sub pre_archive_api_query () {
6396     no_local_git_cfg();
6397 }
6398 sub cmd_archive_api_query {
6399     badusage "need only 1 subpath argument" unless @ARGV==1;
6400     my ($subpath) = @ARGV;
6401     my @cmd = archive_api_query_cmd($subpath);
6402     push @cmd, qw(-f);
6403     debugcmd ">",@cmd;
6404     exec @cmd or fail "exec curl: $!\n";
6405 }
6406
6407 sub repos_server_url () {
6408     $package = '_dgit-repos-server';
6409     local $access_forpush = 1;
6410     local $isuite = 'DGIT-REPOS-SERVER';
6411     my $url = access_giturl();
6412 }
6413
6414 sub pre_clone_dgit_repos_server () {
6415     no_local_git_cfg();
6416 }
6417 sub cmd_clone_dgit_repos_server {
6418     badusage "need destination argument" unless @ARGV==1;
6419     my ($destdir) = @ARGV;
6420     my $url = repos_server_url();
6421     my @cmd = (@git, qw(clone), $url, $destdir);
6422     debugcmd ">",@cmd;
6423     exec @cmd or fail "exec git clone: $!\n";
6424 }
6425
6426 sub pre_print_dgit_repos_server_source_url () {
6427     no_local_git_cfg();
6428 }
6429 sub cmd_print_dgit_repos_server_source_url {
6430     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6431         if @ARGV;
6432     my $url = repos_server_url();
6433     print $url, "\n" or die $!;
6434 }
6435
6436 sub cmd_setup_mergechangelogs {
6437     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6438     local $isuite = 'DGIT-SETUP-TREE';
6439     setup_mergechangelogs(1);
6440 }
6441
6442 sub cmd_setup_useremail {
6443     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6444     local $isuite = 'DGIT-SETUP-TREE';
6445     setup_useremail(1);
6446 }
6447
6448 sub cmd_setup_gitattributes {
6449     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6450     local $isuite = 'DGIT-SETUP-TREE';
6451     setup_gitattrs(1);
6452 }
6453
6454 sub cmd_setup_new_tree {
6455     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6456     local $isuite = 'DGIT-SETUP-TREE';
6457     setup_new_tree();
6458 }
6459
6460 #---------- argument parsing and main program ----------
6461
6462 sub cmd_version {
6463     print "dgit version $our_version\n" or die $!;
6464     exit 0;
6465 }
6466
6467 our (%valopts_long, %valopts_short);
6468 our (%funcopts_long);
6469 our @rvalopts;
6470 our (@modeopt_cfgs);
6471
6472 sub defvalopt ($$$$) {
6473     my ($long,$short,$val_re,$how) = @_;
6474     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6475     $valopts_long{$long} = $oi;
6476     $valopts_short{$short} = $oi;
6477     # $how subref should:
6478     #   do whatever assignemnt or thing it likes with $_[0]
6479     #   if the option should not be passed on to remote, @rvalopts=()
6480     # or $how can be a scalar ref, meaning simply assign the value
6481 }
6482
6483 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6484 defvalopt '--distro',        '-d', '.+',      \$idistro;
6485 defvalopt '',                '-k', '.+',      \$keyid;
6486 defvalopt '--existing-package','', '.*',      \$existing_package;
6487 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6488 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6489 defvalopt '--package',   '-p',   $package_re, \$package;
6490 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6491
6492 defvalopt '', '-C', '.+', sub {
6493     ($changesfile) = (@_);
6494     if ($changesfile =~ s#^(.*)/##) {
6495         $buildproductsdir = $1;
6496     }
6497 };
6498
6499 defvalopt '--initiator-tempdir','','.*', sub {
6500     ($initiator_tempdir) = (@_);
6501     $initiator_tempdir =~ m#^/# or
6502         badusage "--initiator-tempdir must be used specify an".
6503         " absolute, not relative, directory."
6504 };
6505
6506 sub defoptmodes ($@) {
6507     my ($varref, $cfgkey, $default, %optmap) = @_;
6508     my %permit;
6509     while (my ($opt,$val) = each %optmap) {
6510         $funcopts_long{$opt} = sub { $$varref = $val; };
6511         $permit{$val} = $val;
6512     }
6513     push @modeopt_cfgs, {
6514         Var => $varref,
6515         Key => $cfgkey,
6516         Default => $default,
6517         Vals => \%permit
6518     };
6519 }
6520
6521 defoptmodes \$dodep14tag, qw( dep14tag          want
6522                               --dep14tag        want
6523                               --no-dep14tag     no
6524                               --always-dep14tag always );
6525
6526 sub parseopts () {
6527     my $om;
6528
6529     if (defined $ENV{'DGIT_SSH'}) {
6530         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6531     } elsif (defined $ENV{'GIT_SSH'}) {
6532         @ssh = ($ENV{'GIT_SSH'});
6533     }
6534
6535     my $oi;
6536     my $val;
6537     my $valopt = sub {
6538         my ($what) = @_;
6539         @rvalopts = ($_);
6540         if (!defined $val) {
6541             badusage "$what needs a value" unless @ARGV;
6542             $val = shift @ARGV;
6543             push @rvalopts, $val;
6544         }
6545         badusage "bad value \`$val' for $what" unless
6546             $val =~ m/^$oi->{Re}$(?!\n)/s;
6547         my $how = $oi->{How};
6548         if (ref($how) eq 'SCALAR') {
6549             $$how = $val;
6550         } else {
6551             $how->($val);
6552         }
6553         push @ropts, @rvalopts;
6554     };
6555
6556     while (@ARGV) {
6557         last unless $ARGV[0] =~ m/^-/;
6558         $_ = shift @ARGV;
6559         last if m/^--?$/;
6560         if (m/^--/) {
6561             if (m/^--dry-run$/) {
6562                 push @ropts, $_;
6563                 $dryrun_level=2;
6564             } elsif (m/^--damp-run$/) {
6565                 push @ropts, $_;
6566                 $dryrun_level=1;
6567             } elsif (m/^--no-sign$/) {
6568                 push @ropts, $_;
6569                 $sign=0;
6570             } elsif (m/^--help$/) {
6571                 cmd_help();
6572             } elsif (m/^--version$/) {
6573                 cmd_version();
6574             } elsif (m/^--new$/) {
6575                 push @ropts, $_;
6576                 $new_package=1;
6577             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6578                      ($om = $opts_opt_map{$1}) &&
6579                      length $om->[0]) {
6580                 push @ropts, $_;
6581                 $om->[0] = $2;
6582             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6583                      !$opts_opt_cmdonly{$1} &&
6584                      ($om = $opts_opt_map{$1})) {
6585                 push @ropts, $_;
6586                 push @$om, $2;
6587             } elsif (m/^--(gbp|dpm)$/s) {
6588                 push @ropts, "--quilt=$1";
6589                 $quilt_mode = $1;
6590             } elsif (m/^--ignore-dirty$/s) {
6591                 push @ropts, $_;
6592                 $ignoredirty = 1;
6593             } elsif (m/^--no-quilt-fixup$/s) {
6594                 push @ropts, $_;
6595                 $quilt_mode = 'nocheck';
6596             } elsif (m/^--no-rm-on-error$/s) {
6597                 push @ropts, $_;
6598                 $rmonerror = 0;
6599             } elsif (m/^--no-chase-dsc-distro$/s) {
6600                 push @ropts, $_;
6601                 $chase_dsc_distro = 0;
6602             } elsif (m/^--overwrite$/s) {
6603                 push @ropts, $_;
6604                 $overwrite_version = '';
6605             } elsif (m/^--overwrite=(.+)$/s) {
6606                 push @ropts, $_;
6607                 $overwrite_version = $1;
6608             } elsif (m/^--delayed=(\d+)$/s) {
6609                 push @ropts, $_;
6610                 push @dput, $_;
6611             } elsif (m/^--dgit-view-save=(.+)$/s) {
6612                 push @ropts, $_;
6613                 $split_brain_save = $1;
6614                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6615             } elsif (m/^--(no-)?rm-old-changes$/s) {
6616                 push @ropts, $_;
6617                 $rmchanges = !$1;
6618             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6619                 push @ropts, $_;
6620                 push @deliberatelies, $&;
6621             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6622                 push @ropts, $&;
6623                 $forceopts{$1} = 1;
6624                 $_='';
6625             } elsif (m/^--force-/) {
6626                 print STDERR
6627                     "$us: warning: ignoring unknown force option $_\n";
6628                 $_='';
6629             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6630                 # undocumented, for testing
6631                 push @ropts, $_;
6632                 $tagformat_want = [ $1, 'command line', 1 ];
6633                 # 1 menas overrides distro configuration
6634             } elsif (m/^--always-split-source-build$/s) {
6635                 # undocumented, for testing
6636                 push @ropts, $_;
6637                 $need_split_build_invocation = 1;
6638             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6639                 # undocumented, for testing
6640                 push @ropts, $_;
6641                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6642                 # ^ it's supposed to be an array ref
6643             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6644                 $val = $2 ? $' : undef; #';
6645                 $valopt->($oi->{Long});
6646             } elsif ($funcopts_long{$_}) {
6647                 push @ropts, $_;
6648                 $funcopts_long{$_}();
6649             } else {
6650                 badusage "unknown long option \`$_'";
6651             }
6652         } else {
6653             while (m/^-./s) {
6654                 if (s/^-n/-/) {
6655                     push @ropts, $&;
6656                     $dryrun_level=2;
6657                 } elsif (s/^-L/-/) {
6658                     push @ropts, $&;
6659                     $dryrun_level=1;
6660                 } elsif (s/^-h/-/) {
6661                     cmd_help();
6662                 } elsif (s/^-D/-/) {
6663                     push @ropts, $&;
6664                     $debuglevel++;
6665                     enabledebug();
6666                 } elsif (s/^-N/-/) {
6667                     push @ropts, $&;
6668                     $new_package=1;
6669                 } elsif (m/^-m/) {
6670                     push @ropts, $&;
6671                     push @changesopts, $_;
6672                     $_ = '';
6673                 } elsif (s/^-wn$//s) {
6674                     push @ropts, $&;
6675                     $cleanmode = 'none';
6676                 } elsif (s/^-wg$//s) {
6677                     push @ropts, $&;
6678                     $cleanmode = 'git';
6679                 } elsif (s/^-wgf$//s) {
6680                     push @ropts, $&;
6681                     $cleanmode = 'git-ff';
6682                 } elsif (s/^-wd$//s) {
6683                     push @ropts, $&;
6684                     $cleanmode = 'dpkg-source';
6685                 } elsif (s/^-wdd$//s) {
6686                     push @ropts, $&;
6687                     $cleanmode = 'dpkg-source-d';
6688                 } elsif (s/^-wc$//s) {
6689                     push @ropts, $&;
6690                     $cleanmode = 'check';
6691                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6692                     push @git, '-c', $&;
6693                     $gitcfgs{cmdline}{$1} = [ $2 ];
6694                 } elsif (s/^-c([^=]+)$//s) {
6695                     push @git, '-c', $&;
6696                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6697                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6698                     $val = $'; #';
6699                     $val = undef unless length $val;
6700                     $valopt->($oi->{Short});
6701                     $_ = '';
6702                 } else {
6703                     badusage "unknown short option \`$_'";
6704                 }
6705             }
6706         }
6707     }
6708 }
6709
6710 sub check_env_sanity () {
6711     my $blocked = new POSIX::SigSet;
6712     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6713
6714     eval {
6715         foreach my $name (qw(PIPE CHLD)) {
6716             my $signame = "SIG$name";
6717             my $signum = eval "POSIX::$signame" // die;
6718             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6719                 die "$signame is set to something other than SIG_DFL\n";
6720             $blocked->ismember($signum) and
6721                 die "$signame is blocked\n";
6722         }
6723     };
6724     return unless $@;
6725     chomp $@;
6726     fail <<END;
6727 On entry to dgit, $@
6728 This is a bug produced by something in in your execution environment.
6729 Giving up.
6730 END
6731 }
6732
6733
6734 sub parseopts_late_defaults () {
6735     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6736         if defined $idistro;
6737     $isuite //= cfg('dgit.default.default-suite');
6738
6739     foreach my $k (keys %opts_opt_map) {
6740         my $om = $opts_opt_map{$k};
6741
6742         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6743         if (defined $v) {
6744             badcfg "cannot set command for $k"
6745                 unless length $om->[0];
6746             $om->[0] = $v;
6747         }
6748
6749         foreach my $c (access_cfg_cfgs("opts-$k")) {
6750             my @vl =
6751                 map { $_ ? @$_ : () }
6752                 map { $gitcfgs{$_}{$c} }
6753                 reverse @gitcfgsources;
6754             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6755                 "\n" if $debuglevel >= 4;
6756             next unless @vl;
6757             badcfg "cannot configure options for $k"
6758                 if $opts_opt_cmdonly{$k};
6759             my $insertpos = $opts_cfg_insertpos{$k};
6760             @$om = ( @$om[0..$insertpos-1],
6761                      @vl,
6762                      @$om[$insertpos..$#$om] );
6763         }
6764     }
6765
6766     if (!defined $rmchanges) {
6767         local $access_forpush;
6768         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6769     }
6770
6771     if (!defined $quilt_mode) {
6772         local $access_forpush;
6773         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6774             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6775             // 'linear';
6776         $quilt_mode =~ m/^($quilt_modes_re)$/
6777             or badcfg "unknown quilt-mode \`$quilt_mode'";
6778         $quilt_mode = $1;
6779     }
6780
6781     foreach my $moc (@modeopt_cfgs) {
6782         local $access_forpush;
6783         my $vr = $moc->{Var};
6784         next if defined $$vr;
6785         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6786         my $v = $moc->{Vals}{$$vr};
6787         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6788         $$vr = $v;
6789     }
6790
6791     $need_split_build_invocation ||= quiltmode_splitbrain();
6792
6793     if (!defined $cleanmode) {
6794         local $access_forpush;
6795         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6796         $cleanmode //= 'dpkg-source';
6797
6798         badcfg "unknown clean-mode \`$cleanmode'" unless
6799             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6800     }
6801 }
6802
6803 if ($ENV{$fakeeditorenv}) {
6804     git_slurp_config();
6805     quilt_fixup_editor();
6806 }
6807
6808 parseopts();
6809 check_env_sanity();
6810
6811 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6812 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6813     if $dryrun_level == 1;
6814 if (!@ARGV) {
6815     print STDERR $helpmsg or die $!;
6816     exit 8;
6817 }
6818 my $cmd = shift @ARGV;
6819 $cmd =~ y/-/_/;
6820
6821 my $pre_fn = ${*::}{"pre_$cmd"};
6822 $pre_fn->() if $pre_fn;
6823
6824 git_slurp_config();
6825
6826 my $fn = ${*::}{"cmd_$cmd"};
6827 $fn or badusage "unknown operation $cmd";
6828 $fn->();