chiark / gitweb /
test suite: gdr-convert-gbp: Break the start out into lib-gdr
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013-2018 Ian Jackson
6 # Copyright (C)2017-2018 Sean Whitton
7 #
8 # This program is free software: you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation, either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
20
21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
22 use Debian::Dgit::ExitStatus;
23
24 use strict;
25
26 use Debian::Dgit qw(:DEFAULT :playground);
27 setup_sigwarn();
28
29 use IO::Handle;
30 use Data::Dumper;
31 use LWP::UserAgent;
32 use Dpkg::Control::Hash;
33 use File::Path;
34 use File::Temp qw(tempdir);
35 use File::Basename;
36 use Dpkg::Version;
37 use Dpkg::Compression;
38 use Dpkg::Compression::Process;
39 use POSIX;
40 use IPC::Open2;
41 use Digest::SHA;
42 use Digest::MD5;
43 use List::MoreUtils qw(pairwise);
44 use Text::Glob qw(match_glob);
45 use Fcntl qw(:DEFAULT :flock);
46 use Carp;
47
48 use Debian::Dgit;
49
50 our $our_version = 'UNRELEASED'; ###substituted###
51 our $absurdity = undef; ###substituted###
52
53 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
54 our $protovsn;
55
56 our $cmd;
57 our $subcommand;
58 our $isuite;
59 our $idistro;
60 our $package;
61 our @ropts;
62
63 our $sign = 1;
64 our $dryrun_level = 0;
65 our $changesfile;
66 our $buildproductsdir;
67 our $bpd_glob;
68 our $new_package = 0;
69 our $includedirty = 0;
70 our $rmonerror = 1;
71 our @deliberatelies;
72 our %previously;
73 our $existing_package = 'dpkg';
74 our $cleanmode;
75 our $changes_since_version;
76 our $rmchanges;
77 our $overwrite_version; # undef: not specified; '': check changelog
78 our $quilt_mode;
79 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
80 our $dodep14tag;
81 our %internal_object_save;
82 our $we_are_responder;
83 our $we_are_initiator;
84 our $initiator_tempdir;
85 our $patches_applied_dirtily = 00;
86 our $tagformat_want;
87 our $tagformat;
88 our $tagformatfn;
89 our $chase_dsc_distro=1;
90
91 our %forceopts = map { $_=>0 }
92     qw(unrepresentable unsupported-source-format
93        dsc-changes-mismatch changes-origs-exactly
94        uploading-binaries uploading-source-only
95        import-gitapply-absurd
96        import-gitapply-no-absurd
97        import-dsc-with-dgit-field);
98
99 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
100
101 our $suite_re = '[-+.0-9a-z]+';
102 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
103
104 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
105 our $splitbraincache = 'dgit-intern/quilt-cache';
106 our $rewritemap = 'dgit-rewrite/map';
107
108 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
109
110 our (@git) = qw(git);
111 our (@dget) = qw(dget);
112 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
113 our (@dput) = qw(dput);
114 our (@debsign) = qw(debsign);
115 our (@gpg) = qw(gpg);
116 our (@sbuild) = qw(sbuild);
117 our (@ssh) = 'ssh';
118 our (@dgit) = qw(dgit);
119 our (@git_debrebase) = qw(git-debrebase);
120 our (@aptget) = qw(apt-get);
121 our (@aptcache) = qw(apt-cache);
122 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
123 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
124 our (@dpkggenchanges) = qw(dpkg-genchanges);
125 our (@mergechanges) = qw(mergechanges -f);
126 our (@gbp_build) = ('');
127 our (@gbp_pq) = ('gbp pq');
128 our (@changesopts) = ('');
129 our (@pbuilder) = ("sudo -E pbuilder");
130 our (@cowbuilder) = ("sudo -E cowbuilder");
131
132 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
133                      'curl' => \@curl,
134                      'dput' => \@dput,
135                      'debsign' => \@debsign,
136                      'gpg' => \@gpg,
137                      'sbuild' => \@sbuild,
138                      'ssh' => \@ssh,
139                      'dgit' => \@dgit,
140                      'git' => \@git,
141                      'git-debrebase' => \@git_debrebase,
142                      'apt-get' => \@aptget,
143                      'apt-cache' => \@aptcache,
144                      'dpkg-source' => \@dpkgsource,
145                      'dpkg-buildpackage' => \@dpkgbuildpackage,
146                      'dpkg-genchanges' => \@dpkggenchanges,
147                      'gbp-build' => \@gbp_build,
148                      'gbp-pq' => \@gbp_pq,
149                      'ch' => \@changesopts,
150                      'mergechanges' => \@mergechanges,
151                      'pbuilder' => \@pbuilder,
152                      'cowbuilder' => \@cowbuilder);
153
154 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
155 our %opts_cfg_insertpos = map {
156     $_,
157     scalar @{ $opts_opt_map{$_} }
158 } keys %opts_opt_map;
159
160 sub parseopts_late_defaults();
161 sub setup_gitattrs(;$);
162 sub check_gitattrs($$);
163
164 our $playground;
165 our $keyid;
166
167 autoflush STDOUT 1;
168
169 our $supplementary_message = '';
170 our $split_brain = 0;
171
172 END {
173     local ($@, $?);
174     return unless forkcheck_mainprocess();
175     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
176 }
177
178 our $remotename = 'dgit';
179 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
180 our $csuite;
181 our $instead_distro;
182
183 if (!defined $absurdity) {
184     $absurdity = $0;
185     $absurdity =~ s{/[^/]+$}{/absurd} or die;
186 }
187
188 sub debiantag ($$) {
189     my ($v,$distro) = @_;
190     return $tagformatfn->($v, $distro);
191 }
192
193 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
194
195 sub lbranch () { return "$branchprefix/$csuite"; }
196 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
197 sub lref () { return "refs/heads/".lbranch(); }
198 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
199 sub rrref () { return server_ref($csuite); }
200
201 sub srcfn ($$) {
202     my ($vsn, $sfx) = @_;
203     return &source_file_leafname($package, $vsn, $sfx);
204 }
205 sub is_orig_file_of_vsn ($$) {
206     my ($f, $upstreamvsn) = @_;
207     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
208 }
209
210 sub dscfn ($) {
211     my ($vsn) = @_;
212     return srcfn($vsn,".dsc");
213 }
214
215 sub changespat ($;$) {
216     my ($vsn, $arch) = @_;
217     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
218 }
219
220 our $us = 'dgit';
221 initdebug('');
222
223 our @end;
224 END { 
225     local ($?);
226     return unless forkcheck_mainprocess();
227     foreach my $f (@end) {
228         eval { $f->(); };
229         print STDERR "$us: cleanup: $@" if length $@;
230     }
231 };
232
233 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; finish 12; }
234
235 sub forceable_fail ($$) {
236     my ($forceoptsl, $msg) = @_;
237     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
238     print STDERR "warning: overriding problem due to --force:\n". $msg;
239 }
240
241 sub forceing ($) {
242     my ($forceoptsl) = @_;
243     my @got = grep { $forceopts{$_} } @$forceoptsl;
244     return 0 unless @got;
245     print STDERR
246  "warning: skipping checks or functionality due to --force-$got[0]\n";
247 }
248
249 sub no_such_package () {
250     print STDERR "$us: package $package does not exist in suite $isuite\n";
251     finish 4;
252 }
253
254 sub deliberately ($) {
255     my ($enquiry) = @_;
256     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
257 }
258
259 sub deliberately_not_fast_forward () {
260     foreach (qw(not-fast-forward fresh-repo)) {
261         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
262     }
263 }
264
265 sub quiltmode_splitbrain () {
266     $quilt_mode =~ m/gbp|dpm|unapplied/;
267 }
268
269 sub opts_opt_multi_cmd {
270     my $extra = shift;
271     my @cmd;
272     push @cmd, split /\s+/, shift @_;
273     push @cmd, @$extra;
274     push @cmd, @_;
275     @cmd;
276 }
277
278 sub gbp_pq {
279     return opts_opt_multi_cmd [], @gbp_pq;
280 }
281
282 sub dgit_privdir () {
283     our $dgit_privdir_made //= ensure_a_playground 'dgit';
284 }
285
286 sub bpd_abs () {
287     my $r = $buildproductsdir;
288     $r = "$maindir/$r" unless $r =~ m{^/};
289     return $r;
290 }
291
292 sub branch_gdr_info ($$) {
293     my ($symref, $head) = @_;
294     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
295         gdr_ffq_prev_branchinfo($symref);
296     return () unless $status eq 'branch';
297     $ffq_prev = git_get_ref $ffq_prev;
298     $gdrlast  = git_get_ref $gdrlast;
299     $gdrlast &&= is_fast_fwd $gdrlast, $head;
300     return ($ffq_prev, $gdrlast);
301 }
302
303 sub branch_is_gdr ($$) {
304     my ($symref, $head) = @_;
305     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
306     return 0 unless $ffq_prev || $gdrlast;
307     return 1;
308 }
309
310 sub branch_is_gdr_unstitched_ff ($$$) {
311     my ($symref, $head, $ancestor) = @_;
312     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
313     return 0 unless $ffq_prev;
314     return 0 unless is_fast_fwd $ancestor, $ffq_prev;
315     return 1;
316 }
317
318 #---------- remote protocol support, common ----------
319
320 # remote push initiator/responder protocol:
321 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
322 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
323 #  < dgit-remote-push-ready <actual-proto-vsn>
324 #
325 # occasionally:
326 #
327 #  > progress NBYTES
328 #  [NBYTES message]
329 #
330 #  > supplementary-message NBYTES          # $protovsn >= 3
331 #  [NBYTES message]
332 #
333 # main sequence:
334 #
335 #  > file parsed-changelog
336 #  [indicates that output of dpkg-parsechangelog follows]
337 #  > data-block NBYTES
338 #  > [NBYTES bytes of data (no newline)]
339 #  [maybe some more blocks]
340 #  > data-end
341 #
342 #  > file dsc
343 #  [etc]
344 #
345 #  > file changes
346 #  [etc]
347 #
348 #  > param head DGIT-VIEW-HEAD
349 #  > param csuite SUITE
350 #  > param tagformat old|new
351 #  > param maint-view MAINT-VIEW-HEAD
352 #
353 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
354 #  > file buildinfo                             # for buildinfos to sign
355 #
356 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
357 #                                     # goes into tag, for replay prevention
358 #
359 #  > want signed-tag
360 #  [indicates that signed tag is wanted]
361 #  < data-block NBYTES
362 #  < [NBYTES bytes of data (no newline)]
363 #  [maybe some more blocks]
364 #  < data-end
365 #  < files-end
366 #
367 #  > want signed-dsc-changes
368 #  < data-block NBYTES    [transfer of signed dsc]
369 #  [etc]
370 #  < data-block NBYTES    [transfer of signed changes]
371 #  [etc]
372 #  < data-block NBYTES    [transfer of each signed buildinfo
373 #  [etc]                   same number and order as "file buildinfo"]
374 #  ...
375 #  < files-end
376 #
377 #  > complete
378
379 our $i_child_pid;
380
381 sub i_child_report () {
382     # Sees if our child has died, and reap it if so.  Returns a string
383     # describing how it died if it failed, or undef otherwise.
384     return undef unless $i_child_pid;
385     my $got = waitpid $i_child_pid, WNOHANG;
386     return undef if $got <= 0;
387     die unless $got == $i_child_pid;
388     $i_child_pid = undef;
389     return undef unless $?;
390     return "build host child ".waitstatusmsg();
391 }
392
393 sub badproto ($$) {
394     my ($fh, $m) = @_;
395     fail "connection lost: $!" if $fh->error;
396     fail "protocol violation; $m not expected";
397 }
398
399 sub badproto_badread ($$) {
400     my ($fh, $wh) = @_;
401     fail "connection lost: $!" if $!;
402     my $report = i_child_report();
403     fail $report if defined $report;
404     badproto $fh, "eof (reading $wh)";
405 }
406
407 sub protocol_expect (&$) {
408     my ($match, $fh) = @_;
409     local $_;
410     $_ = <$fh>;
411     defined && chomp or badproto_badread $fh, "protocol message";
412     if (wantarray) {
413         my @r = &$match;
414         return @r if @r;
415     } else {
416         my $r = &$match;
417         return $r if $r;
418     }
419     badproto $fh, "\`$_'";
420 }
421
422 sub protocol_send_file ($$) {
423     my ($fh, $ourfn) = @_;
424     open PF, "<", $ourfn or die "$ourfn: $!";
425     for (;;) {
426         my $d;
427         my $got = read PF, $d, 65536;
428         die "$ourfn: $!" unless defined $got;
429         last if !$got;
430         print $fh "data-block ".length($d)."\n" or die $!;
431         print $fh $d or die $!;
432     }
433     PF->error and die "$ourfn $!";
434     print $fh "data-end\n" or die $!;
435     close PF;
436 }
437
438 sub protocol_read_bytes ($$) {
439     my ($fh, $nbytes) = @_;
440     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
441     my $d;
442     my $got = read $fh, $d, $nbytes;
443     $got==$nbytes or badproto_badread $fh, "data block";
444     return $d;
445 }
446
447 sub protocol_receive_file ($$) {
448     my ($fh, $ourfn) = @_;
449     printdebug "() $ourfn\n";
450     open PF, ">", $ourfn or die "$ourfn: $!";
451     for (;;) {
452         my ($y,$l) = protocol_expect {
453             m/^data-block (.*)$/ ? (1,$1) :
454             m/^data-end$/ ? (0,) :
455             ();
456         } $fh;
457         last unless $y;
458         my $d = protocol_read_bytes $fh, $l;
459         print PF $d or die $!;
460     }
461     close PF or die $!;
462 }
463
464 #---------- remote protocol support, responder ----------
465
466 sub responder_send_command ($) {
467     my ($command) = @_;
468     return unless $we_are_responder;
469     # called even without $we_are_responder
470     printdebug ">> $command\n";
471     print PO $command, "\n" or die $!;
472 }    
473
474 sub responder_send_file ($$) {
475     my ($keyword, $ourfn) = @_;
476     return unless $we_are_responder;
477     printdebug "]] $keyword $ourfn\n";
478     responder_send_command "file $keyword";
479     protocol_send_file \*PO, $ourfn;
480 }
481
482 sub responder_receive_files ($@) {
483     my ($keyword, @ourfns) = @_;
484     die unless $we_are_responder;
485     printdebug "[[ $keyword @ourfns\n";
486     responder_send_command "want $keyword";
487     foreach my $fn (@ourfns) {
488         protocol_receive_file \*PI, $fn;
489     }
490     printdebug "[[\$\n";
491     protocol_expect { m/^files-end$/ } \*PI;
492 }
493
494 #---------- remote protocol support, initiator ----------
495
496 sub initiator_expect (&) {
497     my ($match) = @_;
498     protocol_expect { &$match } \*RO;
499 }
500
501 #---------- end remote code ----------
502
503 sub progress {
504     if ($we_are_responder) {
505         my $m = join '', @_;
506         responder_send_command "progress ".length($m) or die $!;
507         print PO $m or die $!;
508     } else {
509         print @_, "\n";
510     }
511 }
512
513 our $ua;
514
515 sub url_get {
516     if (!$ua) {
517         $ua = LWP::UserAgent->new();
518         $ua->env_proxy;
519     }
520     my $what = $_[$#_];
521     progress "downloading $what...";
522     my $r = $ua->get(@_) or die $!;
523     return undef if $r->code == 404;
524     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
525     return $r->decoded_content(charset => 'none');
526 }
527
528 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
529
530 sub act_local () { return $dryrun_level <= 1; }
531 sub act_scary () { return !$dryrun_level; }
532
533 sub printdone {
534     if (!$dryrun_level) {
535         progress "$us ok: @_";
536     } else {
537         progress "would be ok: @_ (but dry run only)";
538     }
539 }
540
541 sub dryrun_report {
542     printcmd(\*STDERR,$debugprefix."#",@_);
543 }
544
545 sub runcmd_ordryrun {
546     if (act_scary()) {
547         runcmd @_;
548     } else {
549         dryrun_report @_;
550     }
551 }
552
553 sub runcmd_ordryrun_local {
554     if (act_local()) {
555         runcmd @_;
556     } else {
557         dryrun_report @_;
558     }
559 }
560
561 our $helpmsg = <<END;
562 main usages:
563   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
564   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
565   dgit [dgit-opts] build [dpkg-buildpackage-opts]
566   dgit [dgit-opts] sbuild [sbuild-opts]
567   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
568   dgit [dgit-opts] push [dgit-opts] [suite]
569   dgit [dgit-opts] push-source [dgit-opts] [suite]
570   dgit [dgit-opts] rpush build-host:build-dir ...
571 important dgit options:
572   -k<keyid>           sign tag and package with <keyid> instead of default
573   --dry-run -n        do not change anything, but go through the motions
574   --damp-run -L       like --dry-run but make local changes, without signing
575   --new -N            allow introducing a new package
576   --debug -D          increase debug level
577   -c<name>=<value>    set git config option (used directly by dgit too)
578 END
579
580 our $later_warning_msg = <<END;
581 Perhaps the upload is stuck in incoming.  Using the version from git.
582 END
583
584 sub badusage {
585     print STDERR "$us: @_\n", $helpmsg or die $!;
586     finish 8;
587 }
588
589 sub nextarg {
590     @ARGV or badusage "too few arguments";
591     return scalar shift @ARGV;
592 }
593
594 sub pre_help () {
595     not_necessarily_a_tree();
596 }
597 sub cmd_help () {
598     print $helpmsg or die $!;
599     finish 0;
600 }
601
602 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
603
604 our %defcfg = ('dgit.default.distro' => 'debian',
605                'dgit.default.default-suite' => 'unstable',
606                'dgit.default.old-dsc-distro' => 'debian',
607                'dgit-suite.*-security.distro' => 'debian-security',
608                'dgit.default.username' => '',
609                'dgit.default.archive-query-default-component' => 'main',
610                'dgit.default.ssh' => 'ssh',
611                'dgit.default.archive-query' => 'madison:',
612                'dgit.default.sshpsql-dbname' => 'service=projectb',
613                'dgit.default.aptget-components' => 'main',
614                'dgit.default.dgit-tag-format' => 'new,old,maint',
615                'dgit.default.source-only-uploads' => 'ok',
616                'dgit.dsc-url-proto-ok.http'    => 'true',
617                'dgit.dsc-url-proto-ok.https'   => 'true',
618                'dgit.dsc-url-proto-ok.git'     => 'true',
619                'dgit.vcs-git.suites',          => 'sid', # ;-separated
620                'dgit.default.dsc-url-proto-ok' => 'false',
621                # old means "repo server accepts pushes with old dgit tags"
622                # new means "repo server accepts pushes with new dgit tags"
623                # maint means "repo server accepts split brain pushes"
624                # hist means "repo server may have old pushes without new tag"
625                #   ("hist" is implied by "old")
626                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
627                'dgit-distro.debian.git-check' => 'url',
628                'dgit-distro.debian.git-check-suffix' => '/info/refs',
629                'dgit-distro.debian.new-private-pushers' => 't',
630                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
631                'dgit-distro.debian/push.git-url' => '',
632                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
633                'dgit-distro.debian/push.git-user-force' => 'dgit',
634                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
635                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
636                'dgit-distro.debian/push.git-create' => 'true',
637                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
638  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
639 # 'dgit-distro.debian.archive-query-tls-key',
640 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
641 # ^ this does not work because curl is broken nowadays
642 # Fixing #790093 properly will involve providing providing the key
643 # in some pacagke and maybe updating these paths.
644 #
645 # 'dgit-distro.debian.archive-query-tls-curl-args',
646 #   '--ca-path=/etc/ssl/ca-debian',
647 # ^ this is a workaround but works (only) on DSA-administered machines
648                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
649                'dgit-distro.debian.git-url-suffix' => '',
650                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
651                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
652  'dgit-distro.debian-security.archive-query' => 'aptget:',
653  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
654  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
655  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
656  'dgit-distro.debian-security.nominal-distro' => 'debian',
657  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
658  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
659                'dgit-distro.ubuntu.git-check' => 'false',
660  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
661                'dgit-distro.test-dummy.ssh' => "$td/ssh",
662                'dgit-distro.test-dummy.username' => "alice",
663                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
664                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
665                'dgit-distro.test-dummy.git-url' => "$td/git",
666                'dgit-distro.test-dummy.git-host' => "git",
667                'dgit-distro.test-dummy.git-path' => "$td/git",
668                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
669                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
670                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
671                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
672                );
673
674 our %gitcfgs;
675 our @gitcfgsources = qw(cmdline local global system);
676 our $invoked_in_git_tree = 1;
677
678 sub git_slurp_config () {
679     # This algoritm is a bit subtle, but this is needed so that for
680     # options which we want to be single-valued, we allow the
681     # different config sources to override properly.  See #835858.
682     foreach my $src (@gitcfgsources) {
683         next if $src eq 'cmdline';
684         # we do this ourselves since git doesn't handle it
685
686         $gitcfgs{$src} = git_slurp_config_src $src;
687     }
688 }
689
690 sub git_get_config ($) {
691     my ($c) = @_;
692     foreach my $src (@gitcfgsources) {
693         my $l = $gitcfgs{$src}{$c};
694         confess "internal error ($l $c)" if $l && !ref $l;
695         printdebug"C $c ".(defined $l ?
696                            join " ", map { messagequote "'$_'" } @$l :
697                            "undef")."\n"
698             if $debuglevel >= 4;
699         $l or next;
700         @$l==1 or badcfg "multiple values for $c".
701             " (in $src git config)" if @$l > 1;
702         return $l->[0];
703     }
704     return undef;
705 }
706
707 sub cfg {
708     foreach my $c (@_) {
709         return undef if $c =~ /RETURN-UNDEF/;
710         printdebug "C? $c\n" if $debuglevel >= 5;
711         my $v = git_get_config($c);
712         return $v if defined $v;
713         my $dv = $defcfg{$c};
714         if (defined $dv) {
715             printdebug "CD $c $dv\n" if $debuglevel >= 4;
716             return $dv;
717         }
718     }
719     badcfg "need value for one of: @_\n".
720         "$us: distro or suite appears not to be (properly) supported";
721 }
722
723 sub not_necessarily_a_tree () {
724     # needs to be called from pre_*
725     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
726     $invoked_in_git_tree = 0;
727 }
728
729 sub access_basedistro__noalias () {
730     if (defined $idistro) {
731         return $idistro;
732     } else {    
733         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
734         return $def if defined $def;
735         foreach my $src (@gitcfgsources, 'internal') {
736             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
737             next unless $kl;
738             foreach my $k (keys %$kl) {
739                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
740                 my $dpat = $1;
741                 next unless match_glob $dpat, $isuite;
742                 return $kl->{$k};
743             }
744         }
745         return cfg("dgit.default.distro");
746     }
747 }
748
749 sub access_basedistro () {
750     my $noalias = access_basedistro__noalias();
751     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
752     return $canon // $noalias;
753 }
754
755 sub access_nomdistro () {
756     my $base = access_basedistro();
757     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
758     $r =~ m/^$distro_re$/ or badcfg
759  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
760     return $r;
761 }
762
763 sub access_quirk () {
764     # returns (quirk name, distro to use instead or undef, quirk-specific info)
765     my $basedistro = access_basedistro();
766     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
767                               'RETURN-UNDEF');
768     if (defined $backports_quirk) {
769         my $re = $backports_quirk;
770         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
771         $re =~ s/\*/.*/g;
772         $re =~ s/\%/([-0-9a-z_]+)/
773             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
774         if ($isuite =~ m/^$re$/) {
775             return ('backports',"$basedistro-backports",$1);
776         }
777     }
778     return ('none',undef);
779 }
780
781 our $access_forpush;
782
783 sub parse_cfg_bool ($$$) {
784     my ($what,$def,$v) = @_;
785     $v //= $def;
786     return
787         $v =~ m/^[ty1]/ ? 1 :
788         $v =~ m/^[fn0]/ ? 0 :
789         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
790 }       
791
792 sub access_forpush_config () {
793     my $d = access_basedistro();
794
795     return 1 if
796         $new_package &&
797         parse_cfg_bool('new-private-pushers', 0,
798                        cfg("dgit-distro.$d.new-private-pushers",
799                            'RETURN-UNDEF'));
800
801     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
802     $v //= 'a';
803     return
804         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
805         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
806         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
807         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
808 }
809
810 sub access_forpush () {
811     $access_forpush //= access_forpush_config();
812     return $access_forpush;
813 }
814
815 sub pushing () {
816     confess 'internal error '.Dumper($access_forpush)," ?" if
817         defined $access_forpush and !$access_forpush;
818     badcfg "pushing but distro is configured readonly"
819         if access_forpush_config() eq '0';
820     $access_forpush = 1;
821     $supplementary_message = <<'END' unless $we_are_responder;
822 Push failed, before we got started.
823 You can retry the push, after fixing the problem, if you like.
824 END
825     parseopts_late_defaults();
826 }
827
828 sub notpushing () {
829     parseopts_late_defaults();
830 }
831
832 sub supplementary_message ($) {
833     my ($msg) = @_;
834     if (!$we_are_responder) {
835         $supplementary_message = $msg;
836         return;
837     } elsif ($protovsn >= 3) {
838         responder_send_command "supplementary-message ".length($msg)
839             or die $!;
840         print PO $msg or die $!;
841     }
842 }
843
844 sub access_distros () {
845     # Returns list of distros to try, in order
846     #
847     # We want to try:
848     #    0. `instead of' distro name(s) we have been pointed to
849     #    1. the access_quirk distro, if any
850     #    2a. the user's specified distro, or failing that  } basedistro
851     #    2b. the distro calculated from the suite          }
852     my @l = access_basedistro();
853
854     my (undef,$quirkdistro) = access_quirk();
855     unshift @l, $quirkdistro;
856     unshift @l, $instead_distro;
857     @l = grep { defined } @l;
858
859     push @l, access_nomdistro();
860
861     if (access_forpush()) {
862         @l = map { ("$_/push", $_) } @l;
863     }
864     @l;
865 }
866
867 sub access_cfg_cfgs (@) {
868     my (@keys) = @_;
869     my @cfgs;
870     # The nesting of these loops determines the search order.  We put
871     # the key loop on the outside so that we search all the distros
872     # for each key, before going on to the next key.  That means that
873     # if access_cfg is called with a more specific, and then a less
874     # specific, key, an earlier distro can override the less specific
875     # without necessarily overriding any more specific keys.  (If the
876     # distro wants to override the more specific keys it can simply do
877     # so; whereas if we did the loop the other way around, it would be
878     # impossible to for an earlier distro to override a less specific
879     # key but not the more specific ones without restating the unknown
880     # values of the more specific keys.
881     my @realkeys;
882     my @rundef;
883     # We have to deal with RETURN-UNDEF specially, so that we don't
884     # terminate the search prematurely.
885     foreach (@keys) {
886         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
887         push @realkeys, $_
888     }
889     foreach my $d (access_distros()) {
890         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
891     }
892     push @cfgs, map { "dgit.default.$_" } @realkeys;
893     push @cfgs, @rundef;
894     return @cfgs;
895 }
896
897 sub access_cfg (@) {
898     my (@keys) = @_;
899     my (@cfgs) = access_cfg_cfgs(@keys);
900     my $value = cfg(@cfgs);
901     return $value;
902 }
903
904 sub access_cfg_bool ($$) {
905     my ($def, @keys) = @_;
906     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
907 }
908
909 sub string_to_ssh ($) {
910     my ($spec) = @_;
911     if ($spec =~ m/\s/) {
912         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
913     } else {
914         return ($spec);
915     }
916 }
917
918 sub access_cfg_ssh () {
919     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
920     if (!defined $gitssh) {
921         return @ssh;
922     } else {
923         return string_to_ssh $gitssh;
924     }
925 }
926
927 sub access_runeinfo ($) {
928     my ($info) = @_;
929     return ": dgit ".access_basedistro()." $info ;";
930 }
931
932 sub access_someuserhost ($) {
933     my ($some) = @_;
934     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
935     defined($user) && length($user) or
936         $user = access_cfg("$some-user",'username');
937     my $host = access_cfg("$some-host");
938     return length($user) ? "$user\@$host" : $host;
939 }
940
941 sub access_gituserhost () {
942     return access_someuserhost('git');
943 }
944
945 sub access_giturl (;$) {
946     my ($optional) = @_;
947     my $url = access_cfg('git-url','RETURN-UNDEF');
948     my $suffix;
949     if (!length $url) {
950         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
951         return undef unless defined $proto;
952         $url =
953             $proto.
954             access_gituserhost().
955             access_cfg('git-path');
956     } else {
957         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
958     }
959     $suffix //= '.git';
960     return "$url/$package$suffix";
961 }              
962
963 sub commit_getclogp ($) {
964     # Returns the parsed changelog hashref for a particular commit
965     my ($objid) = @_;
966     our %commit_getclogp_memo;
967     my $memo = $commit_getclogp_memo{$objid};
968     return $memo if $memo;
969
970     my $mclog = dgit_privdir()."clog";
971     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
972         "$objid:debian/changelog";
973     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
974 }
975
976 sub parse_dscdata () {
977     my $dscfh = new IO::File \$dscdata, '<' or die $!;
978     printdebug Dumper($dscdata) if $debuglevel>1;
979     $dsc = parsecontrolfh($dscfh,$dscurl,1);
980     printdebug Dumper($dsc) if $debuglevel>1;
981 }
982
983 our %rmad;
984
985 sub archive_query ($;@) {
986     my ($method) = shift @_;
987     fail "this operation does not support multiple comma-separated suites"
988         if $isuite =~ m/,/;
989     my $query = access_cfg('archive-query','RETURN-UNDEF');
990     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
991     my $proto = $1;
992     my $data = $'; #';
993     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
994 }
995
996 sub archive_query_prepend_mirror {
997     my $m = access_cfg('mirror');
998     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
999 }
1000
1001 sub pool_dsc_subpath ($$) {
1002     my ($vsn,$component) = @_; # $package is implict arg
1003     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1004     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1005 }
1006
1007 sub cfg_apply_map ($$$) {
1008     my ($varref, $what, $mapspec) = @_;
1009     return unless $mapspec;
1010
1011     printdebug "config $what EVAL{ $mapspec; }\n";
1012     $_ = $$varref;
1013     eval "package Dgit::Config; $mapspec;";
1014     die $@ if $@;
1015     $$varref = $_;
1016 }
1017
1018 #---------- `ftpmasterapi' archive query method (nascent) ----------
1019
1020 sub archive_api_query_cmd ($) {
1021     my ($subpath) = @_;
1022     my @cmd = (@curl, qw(-sS));
1023     my $url = access_cfg('archive-query-url');
1024     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1025         my $host = $1;
1026         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1027         foreach my $key (split /\:/, $keys) {
1028             $key =~ s/\%HOST\%/$host/g;
1029             if (!stat $key) {
1030                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1031                 next;
1032             }
1033             fail "config requested specific TLS key but do not know".
1034                 " how to get curl to use exactly that EE key ($key)";
1035 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1036 #           # Sadly the above line does not work because of changes
1037 #           # to gnutls.   The real fix for #790093 may involve
1038 #           # new curl options.
1039             last;
1040         }
1041         # Fixing #790093 properly will involve providing a value
1042         # for this on clients.
1043         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1044         push @cmd, split / /, $kargs if defined $kargs;
1045     }
1046     push @cmd, $url.$subpath;
1047     return @cmd;
1048 }
1049
1050 sub api_query ($$;$) {
1051     use JSON;
1052     my ($data, $subpath, $ok404) = @_;
1053     badcfg "ftpmasterapi archive query method takes no data part"
1054         if length $data;
1055     my @cmd = archive_api_query_cmd($subpath);
1056     my $url = $cmd[$#cmd];
1057     push @cmd, qw(-w %{http_code});
1058     my $json = cmdoutput @cmd;
1059     unless ($json =~ s/\d+\d+\d$//) {
1060         failedcmd_report_cmd undef, @cmd;
1061         fail "curl failed to print 3-digit HTTP code";
1062     }
1063     my $code = $&;
1064     return undef if $code eq '404' && $ok404;
1065     fail "fetch of $url gave HTTP code $code"
1066         unless $url =~ m#^file://# or $code =~ m/^2/;
1067     return decode_json($json);
1068 }
1069
1070 sub canonicalise_suite_ftpmasterapi {
1071     my ($proto,$data) = @_;
1072     my $suites = api_query($data, 'suites');
1073     my @matched;
1074     foreach my $entry (@$suites) {
1075         next unless grep { 
1076             my $v = $entry->{$_};
1077             defined $v && $v eq $isuite;
1078         } qw(codename name);
1079         push @matched, $entry;
1080     }
1081     fail "unknown suite $isuite, maybe -d would help" unless @matched;
1082     my $cn;
1083     eval {
1084         @matched==1 or die "multiple matches for suite $isuite\n";
1085         $cn = "$matched[0]{codename}";
1086         defined $cn or die "suite $isuite info has no codename\n";
1087         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1088     };
1089     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1090         if length $@;
1091     return $cn;
1092 }
1093
1094 sub archive_query_ftpmasterapi {
1095     my ($proto,$data) = @_;
1096     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1097     my @rows;
1098     my $digester = Digest::SHA->new(256);
1099     foreach my $entry (@$info) {
1100         eval {
1101             my $vsn = "$entry->{version}";
1102             my ($ok,$msg) = version_check $vsn;
1103             die "bad version: $msg\n" unless $ok;
1104             my $component = "$entry->{component}";
1105             $component =~ m/^$component_re$/ or die "bad component";
1106             my $filename = "$entry->{filename}";
1107             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1108                 or die "bad filename";
1109             my $sha256sum = "$entry->{sha256sum}";
1110             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1111             push @rows, [ $vsn, "/pool/$component/$filename",
1112                           $digester, $sha256sum ];
1113         };
1114         die "bad ftpmaster api response: $@\n".Dumper($entry)
1115             if length $@;
1116     }
1117     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1118     return archive_query_prepend_mirror @rows;
1119 }
1120
1121 sub file_in_archive_ftpmasterapi {
1122     my ($proto,$data,$filename) = @_;
1123     my $pat = $filename;
1124     $pat =~ s/_/\\_/g;
1125     $pat = "%/$pat";
1126     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1127     my $info = api_query($data, "file_in_archive/$pat", 1);
1128 }
1129
1130 sub package_not_wholly_new_ftpmasterapi {
1131     my ($proto,$data,$pkg) = @_;
1132     my $info = api_query($data,"madison?package=${pkg}&f=json");
1133     return !!@$info;
1134 }
1135
1136 #---------- `aptget' archive query method ----------
1137
1138 our $aptget_base;
1139 our $aptget_releasefile;
1140 our $aptget_configpath;
1141
1142 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1143 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1144
1145 sub aptget_cache_clean {
1146     runcmd_ordryrun_local qw(sh -ec),
1147         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1148         'x', $aptget_base;
1149 }
1150
1151 sub aptget_lock_acquire () {
1152     my $lockfile = "$aptget_base/lock";
1153     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1154     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1155 }
1156
1157 sub aptget_prep ($) {
1158     my ($data) = @_;
1159     return if defined $aptget_base;
1160
1161     badcfg "aptget archive query method takes no data part"
1162         if length $data;
1163
1164     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1165
1166     ensuredir $cache;
1167     ensuredir "$cache/dgit";
1168     my $cachekey =
1169         access_cfg('aptget-cachekey','RETURN-UNDEF')
1170         // access_nomdistro();
1171
1172     $aptget_base = "$cache/dgit/aptget";
1173     ensuredir $aptget_base;
1174
1175     my $quoted_base = $aptget_base;
1176     die "$quoted_base contains bad chars, cannot continue"
1177         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1178
1179     ensuredir $aptget_base;
1180
1181     aptget_lock_acquire();
1182
1183     aptget_cache_clean();
1184
1185     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1186     my $sourceslist = "source.list#$cachekey";
1187
1188     my $aptsuites = $isuite;
1189     cfg_apply_map(\$aptsuites, 'suite map',
1190                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1191
1192     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1193     printf SRCS "deb-src %s %s %s\n",
1194         access_cfg('mirror'),
1195         $aptsuites,
1196         access_cfg('aptget-components')
1197         or die $!;
1198
1199     ensuredir "$aptget_base/cache";
1200     ensuredir "$aptget_base/lists";
1201
1202     open CONF, ">", $aptget_configpath or die $!;
1203     print CONF <<END;
1204 Debug::NoLocking "true";
1205 APT::Get::List-Cleanup "false";
1206 #clear APT::Update::Post-Invoke-Success;
1207 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1208 Dir::State::Lists "$quoted_base/lists";
1209 Dir::Etc::preferences "$quoted_base/preferences";
1210 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1211 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1212 END
1213
1214     foreach my $key (qw(
1215                         Dir::Cache
1216                         Dir::State
1217                         Dir::Cache::Archives
1218                         Dir::Etc::SourceParts
1219                         Dir::Etc::preferencesparts
1220                       )) {
1221         ensuredir "$aptget_base/$key";
1222         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1223     };
1224
1225     my $oldatime = (time // die $!) - 1;
1226     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1227         next unless stat_exists $oldlist;
1228         my ($mtime) = (stat _)[9];
1229         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1230     }
1231
1232     runcmd_ordryrun_local aptget_aptget(), qw(update);
1233
1234     my @releasefiles;
1235     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1236         next unless stat_exists $oldlist;
1237         my ($atime) = (stat _)[8];
1238         next if $atime == $oldatime;
1239         push @releasefiles, $oldlist;
1240     }
1241     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1242     @releasefiles = @inreleasefiles if @inreleasefiles;
1243     if (!@releasefiles) {
1244         fail <<END;
1245 apt seemed to not to update dgit's cached Release files for $isuite.
1246 (Perhaps $cache
1247  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1248 END
1249     }
1250     die "apt updated too many Release files (@releasefiles), erk"
1251         unless @releasefiles == 1;
1252
1253     ($aptget_releasefile) = @releasefiles;
1254 }
1255
1256 sub canonicalise_suite_aptget {
1257     my ($proto,$data) = @_;
1258     aptget_prep($data);
1259
1260     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1261
1262     foreach my $name (qw(Codename Suite)) {
1263         my $val = $release->{$name};
1264         if (defined $val) {
1265             printdebug "release file $name: $val\n";
1266             $val =~ m/^$suite_re$/o or fail
1267  "Release file ($aptget_releasefile) specifies intolerable $name";
1268             cfg_apply_map(\$val, 'suite rmap',
1269                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1270             return $val
1271         }
1272     }
1273     return $isuite;
1274 }
1275
1276 sub archive_query_aptget {
1277     my ($proto,$data) = @_;
1278     aptget_prep($data);
1279
1280     ensuredir "$aptget_base/source";
1281     foreach my $old (<$aptget_base/source/*.dsc>) {
1282         unlink $old or die "$old: $!";
1283     }
1284
1285     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1286     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1287     # avoids apt-get source failing with ambiguous error code
1288
1289     runcmd_ordryrun_local
1290         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1291         aptget_aptget(), qw(--download-only --only-source source), $package;
1292
1293     my @dscs = <$aptget_base/source/*.dsc>;
1294     fail "apt-get source did not produce a .dsc" unless @dscs;
1295     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1296
1297     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1298
1299     use URI::Escape;
1300     my $uri = "file://". uri_escape $dscs[0];
1301     $uri =~ s{\%2f}{/}gi;
1302     return [ (getfield $pre_dsc, 'Version'), $uri ];
1303 }
1304
1305 sub file_in_archive_aptget () { return undef; }
1306 sub package_not_wholly_new_aptget () { return undef; }
1307
1308 #---------- `dummyapicat' archive query method ----------
1309
1310 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1311 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1312
1313 sub dummycatapi_run_in_mirror ($@) {
1314     # runs $fn with FIA open onto rune
1315     my ($rune, $argl, $fn) = @_;
1316
1317     my $mirror = access_cfg('mirror');
1318     $mirror =~ s#^file://#/# or die "$mirror ?";
1319     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1320                qw(x), $mirror, @$argl);
1321     debugcmd "-|", @cmd;
1322     open FIA, "-|", @cmd or die $!;
1323     my $r = $fn->();
1324     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1325     return $r;
1326 }
1327
1328 sub file_in_archive_dummycatapi ($$$) {
1329     my ($proto,$data,$filename) = @_;
1330     my @out;
1331     dummycatapi_run_in_mirror '
1332             find -name "$1" -print0 |
1333             xargs -0r sha256sum
1334     ', [$filename], sub {
1335         while (<FIA>) {
1336             chomp or die;
1337             printdebug "| $_\n";
1338             m/^(\w+)  (\S+)$/ or die "$_ ?";
1339             push @out, { sha256sum => $1, filename => $2 };
1340         }
1341     };
1342     return \@out;
1343 }
1344
1345 sub package_not_wholly_new_dummycatapi {
1346     my ($proto,$data,$pkg) = @_;
1347     dummycatapi_run_in_mirror "
1348             find -name ${pkg}_*.dsc
1349     ", [], sub {
1350         local $/ = undef;
1351         !!<FIA>;
1352     };
1353 }
1354
1355 #---------- `madison' archive query method ----------
1356
1357 sub archive_query_madison {
1358     return archive_query_prepend_mirror
1359         map { [ @$_[0..1] ] } madison_get_parse(@_);
1360 }
1361
1362 sub madison_get_parse {
1363     my ($proto,$data) = @_;
1364     die unless $proto eq 'madison';
1365     if (!length $data) {
1366         $data= access_cfg('madison-distro','RETURN-UNDEF');
1367         $data //= access_basedistro();
1368     }
1369     $rmad{$proto,$data,$package} ||= cmdoutput
1370         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1371     my $rmad = $rmad{$proto,$data,$package};
1372
1373     my @out;
1374     foreach my $l (split /\n/, $rmad) {
1375         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1376                   \s*( [^ \t|]+ )\s* \|
1377                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1378                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1379         $1 eq $package or die "$rmad $package ?";
1380         my $vsn = $2;
1381         my $newsuite = $3;
1382         my $component;
1383         if (defined $4) {
1384             $component = $4;
1385         } else {
1386             $component = access_cfg('archive-query-default-component');
1387         }
1388         $5 eq 'source' or die "$rmad ?";
1389         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1390     }
1391     return sort { -version_compare($a->[0],$b->[0]); } @out;
1392 }
1393
1394 sub canonicalise_suite_madison {
1395     # madison canonicalises for us
1396     my @r = madison_get_parse(@_);
1397     @r or fail
1398         "unable to canonicalise suite using package $package".
1399         " which does not appear to exist in suite $isuite;".
1400         " --existing-package may help";
1401     return $r[0][2];
1402 }
1403
1404 sub file_in_archive_madison { return undef; }
1405 sub package_not_wholly_new_madison { return undef; }
1406
1407 #---------- `sshpsql' archive query method ----------
1408
1409 sub sshpsql ($$$) {
1410     my ($data,$runeinfo,$sql) = @_;
1411     if (!length $data) {
1412         $data= access_someuserhost('sshpsql').':'.
1413             access_cfg('sshpsql-dbname');
1414     }
1415     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1416     my ($userhost,$dbname) = ($`,$'); #';
1417     my @rows;
1418     my @cmd = (access_cfg_ssh, $userhost,
1419                access_runeinfo("ssh-psql $runeinfo").
1420                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1421                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1422     debugcmd "|",@cmd;
1423     open P, "-|", @cmd or die $!;
1424     while (<P>) {
1425         chomp or die;
1426         printdebug(">|$_|\n");
1427         push @rows, $_;
1428     }
1429     $!=0; $?=0; close P or failedcmd @cmd;
1430     @rows or die;
1431     my $nrows = pop @rows;
1432     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1433     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1434     @rows = map { [ split /\|/, $_ ] } @rows;
1435     my $ncols = scalar @{ shift @rows };
1436     die if grep { scalar @$_ != $ncols } @rows;
1437     return @rows;
1438 }
1439
1440 sub sql_injection_check {
1441     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1442 }
1443
1444 sub archive_query_sshpsql ($$) {
1445     my ($proto,$data) = @_;
1446     sql_injection_check $isuite, $package;
1447     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1448         SELECT source.version, component.name, files.filename, files.sha256sum
1449           FROM source
1450           JOIN src_associations ON source.id = src_associations.source
1451           JOIN suite ON suite.id = src_associations.suite
1452           JOIN dsc_files ON dsc_files.source = source.id
1453           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1454           JOIN component ON component.id = files_archive_map.component_id
1455           JOIN files ON files.id = dsc_files.file
1456          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1457            AND source.source='$package'
1458            AND files.filename LIKE '%.dsc';
1459 END
1460     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1461     my $digester = Digest::SHA->new(256);
1462     @rows = map {
1463         my ($vsn,$component,$filename,$sha256sum) = @$_;
1464         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1465     } @rows;
1466     return archive_query_prepend_mirror @rows;
1467 }
1468
1469 sub canonicalise_suite_sshpsql ($$) {
1470     my ($proto,$data) = @_;
1471     sql_injection_check $isuite;
1472     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1473         SELECT suite.codename
1474           FROM suite where suite_name='$isuite' or codename='$isuite';
1475 END
1476     @rows = map { $_->[0] } @rows;
1477     fail "unknown suite $isuite" unless @rows;
1478     die "ambiguous $isuite: @rows ?" if @rows>1;
1479     return $rows[0];
1480 }
1481
1482 sub file_in_archive_sshpsql ($$$) { return undef; }
1483 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1484
1485 #---------- `dummycat' archive query method ----------
1486
1487 sub canonicalise_suite_dummycat ($$) {
1488     my ($proto,$data) = @_;
1489     my $dpath = "$data/suite.$isuite";
1490     if (!open C, "<", $dpath) {
1491         $!==ENOENT or die "$dpath: $!";
1492         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1493         return $isuite;
1494     }
1495     $!=0; $_ = <C>;
1496     chomp or die "$dpath: $!";
1497     close C;
1498     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1499     return $_;
1500 }
1501
1502 sub archive_query_dummycat ($$) {
1503     my ($proto,$data) = @_;
1504     canonicalise_suite();
1505     my $dpath = "$data/package.$csuite.$package";
1506     if (!open C, "<", $dpath) {
1507         $!==ENOENT or die "$dpath: $!";
1508         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1509         return ();
1510     }
1511     my @rows;
1512     while (<C>) {
1513         next if m/^\#/;
1514         next unless m/\S/;
1515         die unless chomp;
1516         printdebug "dummycat query $csuite $package $dpath | $_\n";
1517         my @row = split /\s+/, $_;
1518         @row==2 or die "$dpath: $_ ?";
1519         push @rows, \@row;
1520     }
1521     C->error and die "$dpath: $!";
1522     close C;
1523     return archive_query_prepend_mirror
1524         sort { -version_compare($a->[0],$b->[0]); } @rows;
1525 }
1526
1527 sub file_in_archive_dummycat () { return undef; }
1528 sub package_not_wholly_new_dummycat () { return undef; }
1529
1530 #---------- tag format handling ----------
1531
1532 sub access_cfg_tagformats () {
1533     split /\,/, access_cfg('dgit-tag-format');
1534 }
1535
1536 sub access_cfg_tagformats_can_splitbrain () {
1537     my %y = map { $_ => 1 } access_cfg_tagformats;
1538     foreach my $needtf (qw(new maint)) {
1539         next if $y{$needtf};
1540         return 0;
1541     }
1542     return 1;
1543 }
1544
1545 sub need_tagformat ($$) {
1546     my ($fmt, $why) = @_;
1547     fail "need to use tag format $fmt ($why) but also need".
1548         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1549         " - no way to proceed"
1550         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1551     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1552 }
1553
1554 sub select_tagformat () {
1555     # sets $tagformatfn
1556     return if $tagformatfn && !$tagformat_want;
1557     die 'bug' if $tagformatfn && $tagformat_want;
1558     # ... $tagformat_want assigned after previous select_tagformat
1559
1560     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1561     printdebug "select_tagformat supported @supported\n";
1562
1563     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1564     printdebug "select_tagformat specified @$tagformat_want\n";
1565
1566     my ($fmt,$why,$override) = @$tagformat_want;
1567
1568     fail "target distro supports tag formats @supported".
1569         " but have to use $fmt ($why)"
1570         unless $override
1571             or grep { $_ eq $fmt } @supported;
1572
1573     $tagformat_want = undef;
1574     $tagformat = $fmt;
1575     $tagformatfn = ${*::}{"debiantag_$fmt"};
1576
1577     fail "trying to use unknown tag format \`$fmt' ($why) !"
1578         unless $tagformatfn;
1579 }
1580
1581 #---------- archive query entrypoints and rest of program ----------
1582
1583 sub canonicalise_suite () {
1584     return if defined $csuite;
1585     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1586     $csuite = archive_query('canonicalise_suite');
1587     if ($isuite ne $csuite) {
1588         progress "canonical suite name for $isuite is $csuite";
1589     } else {
1590         progress "canonical suite name is $csuite";
1591     }
1592 }
1593
1594 sub get_archive_dsc () {
1595     canonicalise_suite();
1596     my @vsns = archive_query('archive_query');
1597     foreach my $vinfo (@vsns) {
1598         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1599         $dscurl = $vsn_dscurl;
1600         $dscdata = url_get($dscurl);
1601         if (!$dscdata) {
1602             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1603             next;
1604         }
1605         if ($digester) {
1606             $digester->reset();
1607             $digester->add($dscdata);
1608             my $got = $digester->hexdigest();
1609             $got eq $digest or
1610                 fail "$dscurl has hash $got but".
1611                     " archive told us to expect $digest";
1612         }
1613         parse_dscdata();
1614         my $fmt = getfield $dsc, 'Format';
1615         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1616             "unsupported source format $fmt, sorry";
1617             
1618         $dsc_checked = !!$digester;
1619         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1620         return;
1621     }
1622     $dsc = undef;
1623     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1624 }
1625
1626 sub check_for_git ();
1627 sub check_for_git () {
1628     # returns 0 or 1
1629     my $how = access_cfg('git-check');
1630     if ($how eq 'ssh-cmd') {
1631         my @cmd =
1632             (access_cfg_ssh, access_gituserhost(),
1633              access_runeinfo("git-check $package").
1634              " set -e; cd ".access_cfg('git-path').";".
1635              " if test -d $package.git; then echo 1; else echo 0; fi");
1636         my $r= cmdoutput @cmd;
1637         if (defined $r and $r =~ m/^divert (\w+)$/) {
1638             my $divert=$1;
1639             my ($usedistro,) = access_distros();
1640             # NB that if we are pushing, $usedistro will be $distro/push
1641             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1642             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1643             progress "diverting to $divert (using config for $instead_distro)";
1644             return check_for_git();
1645         }
1646         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1647         return $r+0;
1648     } elsif ($how eq 'url') {
1649         my $prefix = access_cfg('git-check-url','git-url');
1650         my $suffix = access_cfg('git-check-suffix','git-suffix',
1651                                 'RETURN-UNDEF') // '.git';
1652         my $url = "$prefix/$package$suffix";
1653         my @cmd = (@curl, qw(-sS -I), $url);
1654         my $result = cmdoutput @cmd;
1655         $result =~ s/^\S+ 200 .*\n\r?\n//;
1656         # curl -sS -I with https_proxy prints
1657         # HTTP/1.0 200 Connection established
1658         $result =~ m/^\S+ (404|200) /s or
1659             fail "unexpected results from git check query - ".
1660                 Dumper($prefix, $result);
1661         my $code = $1;
1662         if ($code eq '404') {
1663             return 0;
1664         } elsif ($code eq '200') {
1665             return 1;
1666         } else {
1667             die;
1668         }
1669     } elsif ($how eq 'true') {
1670         return 1;
1671     } elsif ($how eq 'false') {
1672         return 0;
1673     } else {
1674         badcfg "unknown git-check \`$how'";
1675     }
1676 }
1677
1678 sub create_remote_git_repo () {
1679     my $how = access_cfg('git-create');
1680     if ($how eq 'ssh-cmd') {
1681         runcmd_ordryrun
1682             (access_cfg_ssh, access_gituserhost(),
1683              access_runeinfo("git-create $package").
1684              "set -e; cd ".access_cfg('git-path').";".
1685              " cp -a _template $package.git");
1686     } elsif ($how eq 'true') {
1687         # nothing to do
1688     } else {
1689         badcfg "unknown git-create \`$how'";
1690     }
1691 }
1692
1693 our ($dsc_hash,$lastpush_mergeinput);
1694 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1695
1696
1697 sub prep_ud () {
1698     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1699     $playground = fresh_playground 'dgit/unpack';
1700 }
1701
1702 sub mktree_in_ud_here () {
1703     playtree_setup $gitcfgs{local};
1704 }
1705
1706 sub git_write_tree () {
1707     my $tree = cmdoutput @git, qw(write-tree);
1708     $tree =~ m/^\w+$/ or die "$tree ?";
1709     return $tree;
1710 }
1711
1712 sub git_add_write_tree () {
1713     runcmd @git, qw(add -Af .);
1714     return git_write_tree();
1715 }
1716
1717 sub remove_stray_gits ($) {
1718     my ($what) = @_;
1719     my @gitscmd = qw(find -name .git -prune -print0);
1720     debugcmd "|",@gitscmd;
1721     open GITS, "-|", @gitscmd or die $!;
1722     {
1723         local $/="\0";
1724         while (<GITS>) {
1725             chomp or die;
1726             print STDERR "$us: warning: removing from $what: ",
1727                 (messagequote $_), "\n";
1728             rmtree $_;
1729         }
1730     }
1731     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1732 }
1733
1734 sub mktree_in_ud_from_only_subdir ($;$) {
1735     my ($what,$raw) = @_;
1736     # changes into the subdir
1737
1738     my (@dirs) = <*/.>;
1739     die "expected one subdir but found @dirs ?" unless @dirs==1;
1740     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1741     my $dir = $1;
1742     changedir $dir;
1743
1744     remove_stray_gits($what);
1745     mktree_in_ud_here();
1746     if (!$raw) {
1747         my ($format, $fopts) = get_source_format();
1748         if (madformat($format)) {
1749             rmtree '.pc';
1750         }
1751     }
1752
1753     my $tree=git_add_write_tree();
1754     return ($tree,$dir);
1755 }
1756
1757 our @files_csum_info_fields = 
1758     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1759      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1760      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1761
1762 sub dsc_files_info () {
1763     foreach my $csumi (@files_csum_info_fields) {
1764         my ($fname, $module, $method) = @$csumi;
1765         my $field = $dsc->{$fname};
1766         next unless defined $field;
1767         eval "use $module; 1;" or die $@;
1768         my @out;
1769         foreach (split /\n/, $field) {
1770             next unless m/\S/;
1771             m/^(\w+) (\d+) (\S+)$/ or
1772                 fail "could not parse .dsc $fname line \`$_'";
1773             my $digester = eval "$module"."->$method;" or die $@;
1774             push @out, {
1775                 Hash => $1,
1776                 Bytes => $2,
1777                 Filename => $3,
1778                 Digester => $digester,
1779             };
1780         }
1781         return @out;
1782     }
1783     fail "missing any supported Checksums-* or Files field in ".
1784         $dsc->get_option('name');
1785 }
1786
1787 sub dsc_files () {
1788     map { $_->{Filename} } dsc_files_info();
1789 }
1790
1791 sub files_compare_inputs (@) {
1792     my $inputs = \@_;
1793     my %record;
1794     my %fchecked;
1795
1796     my $showinputs = sub {
1797         return join "; ", map { $_->get_option('name') } @$inputs;
1798     };
1799
1800     foreach my $in (@$inputs) {
1801         my $expected_files;
1802         my $in_name = $in->get_option('name');
1803
1804         printdebug "files_compare_inputs $in_name\n";
1805
1806         foreach my $csumi (@files_csum_info_fields) {
1807             my ($fname) = @$csumi;
1808             printdebug "files_compare_inputs $in_name $fname\n";
1809
1810             my $field = $in->{$fname};
1811             next unless defined $field;
1812
1813             my @files;
1814             foreach (split /\n/, $field) {
1815                 next unless m/\S/;
1816
1817                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1818                     fail "could not parse $in_name $fname line \`$_'";
1819
1820                 printdebug "files_compare_inputs $in_name $fname $f\n";
1821
1822                 push @files, $f;
1823
1824                 my $re = \ $record{$f}{$fname};
1825                 if (defined $$re) {
1826                     $fchecked{$f}{$in_name} = 1;
1827                     $$re eq $info or
1828                         fail "hash or size of $f varies in $fname fields".
1829                         " (between: ".$showinputs->().")";
1830                 } else {
1831                     $$re = $info;
1832                 }
1833             }
1834             @files = sort @files;
1835             $expected_files //= \@files;
1836             "@$expected_files" eq "@files" or
1837                 fail "file list in $in_name varies between hash fields!";
1838         }
1839         $expected_files or
1840             fail "$in_name has no files list field(s)";
1841     }
1842     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1843         if $debuglevel>=2;
1844
1845     grep { keys %$_ == @$inputs-1 } values %fchecked
1846         or fail "no file appears in all file lists".
1847         " (looked in: ".$showinputs->().")";
1848 }
1849
1850 sub is_orig_file_in_dsc ($$) {
1851     my ($f, $dsc_files_info) = @_;
1852     return 0 if @$dsc_files_info <= 1;
1853     # One file means no origs, and the filename doesn't have a "what
1854     # part of dsc" component.  (Consider versions ending `.orig'.)
1855     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1856     return 1;
1857 }
1858
1859 # This function determines whether a .changes file is source-only from
1860 # the point of view of dak.  Thus, it permits *_source.buildinfo
1861 # files.
1862 #
1863 # It does not, however, permit any other buildinfo files.  After a
1864 # source-only upload, the buildds will try to upload files like
1865 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1866 # named like this in their (otherwise) source-only upload, the uploads
1867 # of the buildd can be rejected by dak.  Fixing the resultant
1868 # situation can require manual intervention.  So we block such
1869 # .buildinfo files when the user tells us to perform a source-only
1870 # upload (such as when using the push-source subcommand with the -C
1871 # option, which calls this function).
1872 #
1873 # Note, though, that when dgit is told to prepare a source-only
1874 # upload, such as when subcommands like build-source and push-source
1875 # without -C are used, dgit has a more restrictive notion of
1876 # source-only .changes than dak: such uploads will never include
1877 # *_source.buildinfo files.  This is because there is no use for such
1878 # files when using a tool like dgit to produce the source package, as
1879 # dgit ensures the source is identical to git HEAD.
1880 sub test_source_only_changes ($) {
1881     my ($changes) = @_;
1882     foreach my $l (split /\n/, getfield $changes, 'Files') {
1883         $l =~ m/\S+$/ or next;
1884         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
1885         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
1886             print "purportedly source-only changes polluted by $&\n";
1887             return 0;
1888         }
1889     }
1890     return 1;
1891 }
1892
1893 sub changes_update_origs_from_dsc ($$$$) {
1894     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1895     my %changes_f;
1896     printdebug "checking origs needed ($upstreamvsn)...\n";
1897     $_ = getfield $changes, 'Files';
1898     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1899         fail "cannot find section/priority from .changes Files field";
1900     my $placementinfo = $1;
1901     my %changed;
1902     printdebug "checking origs needed placement '$placementinfo'...\n";
1903     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1904         $l =~ m/\S+$/ or next;
1905         my $file = $&;
1906         printdebug "origs $file | $l\n";
1907         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1908         printdebug "origs $file is_orig\n";
1909         my $have = archive_query('file_in_archive', $file);
1910         if (!defined $have) {
1911             print STDERR <<END;
1912 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1913 END
1914             return;
1915         }
1916         my $found_same = 0;
1917         my @found_differ;
1918         printdebug "origs $file \$#\$have=$#$have\n";
1919         foreach my $h (@$have) {
1920             my $same = 0;
1921             my @differ;
1922             foreach my $csumi (@files_csum_info_fields) {
1923                 my ($fname, $module, $method, $archivefield) = @$csumi;
1924                 next unless defined $h->{$archivefield};
1925                 $_ = $dsc->{$fname};
1926                 next unless defined;
1927                 m/^(\w+) .* \Q$file\E$/m or
1928                     fail ".dsc $fname missing entry for $file";
1929                 if ($h->{$archivefield} eq $1) {
1930                     $same++;
1931                 } else {
1932                     push @differ,
1933  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1934                 }
1935             }
1936             die "$file ".Dumper($h)." ?!" if $same && @differ;
1937             $found_same++
1938                 if $same;
1939             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1940                 if @differ;
1941         }
1942         printdebug "origs $file f.same=$found_same".
1943             " #f._differ=$#found_differ\n";
1944         if (@found_differ && !$found_same) {
1945             fail join "\n",
1946                 "archive contains $file with different checksum",
1947                 @found_differ;
1948         }
1949         # Now we edit the changes file to add or remove it
1950         foreach my $csumi (@files_csum_info_fields) {
1951             my ($fname, $module, $method, $archivefield) = @$csumi;
1952             next unless defined $changes->{$fname};
1953             if ($found_same) {
1954                 # in archive, delete from .changes if it's there
1955                 $changed{$file} = "removed" if
1956                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
1957             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
1958                 # not in archive, but it's here in the .changes
1959             } else {
1960                 my $dsc_data = getfield $dsc, $fname;
1961                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
1962                 my $extra = $1;
1963                 $extra =~ s/ \d+ /$&$placementinfo /
1964                     or die "$fname $extra >$dsc_data< ?"
1965                     if $fname eq 'Files';
1966                 $changes->{$fname} .= "\n". $extra;
1967                 $changed{$file} = "added";
1968             }
1969         }
1970     }
1971     if (%changed) {
1972         foreach my $file (keys %changed) {
1973             progress sprintf
1974                 "edited .changes for archive .orig contents: %s %s",
1975                 $changed{$file}, $file;
1976         }
1977         my $chtmp = "$changesfile.tmp";
1978         $changes->save($chtmp);
1979         if (act_local()) {
1980             rename $chtmp,$changesfile or die "$changesfile $!";
1981         } else {
1982             progress "[new .changes left in $changesfile]";
1983         }
1984     } else {
1985         progress "$changesfile already has appropriate .orig(s) (if any)";
1986     }
1987 }
1988
1989 sub make_commit ($) {
1990     my ($file) = @_;
1991     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1992 }
1993
1994 sub clogp_authline ($) {
1995     my ($clogp) = @_;
1996     my $author = getfield $clogp, 'Maintainer';
1997     if ($author =~ m/^[^"\@]+\,/) {
1998         # single entry Maintainer field with unquoted comma
1999         $author = ($& =~ y/,//rd).$'; # strip the comma
2000     }
2001     # git wants a single author; any remaining commas in $author
2002     # are by now preceded by @ (or ").  It seems safer to punt on
2003     # "..." for now rather than attempting to dequote or something.
2004     $author =~ s#,.*##ms unless $author =~ m/"/;
2005     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2006     my $authline = "$author $date";
2007     $authline =~ m/$git_authline_re/o or
2008         fail "unexpected commit author line format \`$authline'".
2009         " (was generated from changelog Maintainer field)";
2010     return ($1,$2,$3) if wantarray;
2011     return $authline;
2012 }
2013
2014 sub vendor_patches_distro ($$) {
2015     my ($checkdistro, $what) = @_;
2016     return unless defined $checkdistro;
2017
2018     my $series = "debian/patches/\L$checkdistro\E.series";
2019     printdebug "checking for vendor-specific $series ($what)\n";
2020
2021     if (!open SERIES, "<", $series) {
2022         die "$series $!" unless $!==ENOENT;
2023         return;
2024     }
2025     while (<SERIES>) {
2026         next unless m/\S/;
2027         next if m/^\s+\#/;
2028
2029         print STDERR <<END;
2030
2031 Unfortunately, this source package uses a feature of dpkg-source where
2032 the same source package unpacks to different source code on different
2033 distros.  dgit cannot safely operate on such packages on affected
2034 distros, because the meaning of source packages is not stable.
2035
2036 Please ask the distro/maintainer to remove the distro-specific series
2037 files and use a different technique (if necessary, uploading actually
2038 different packages, if different distros are supposed to have
2039 different code).
2040
2041 END
2042         fail "Found active distro-specific series file for".
2043             " $checkdistro ($what): $series, cannot continue";
2044     }
2045     die "$series $!" if SERIES->error;
2046     close SERIES;
2047 }
2048
2049 sub check_for_vendor_patches () {
2050     # This dpkg-source feature doesn't seem to be documented anywhere!
2051     # But it can be found in the changelog (reformatted):
2052
2053     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2054     #   Author: Raphael Hertzog <hertzog@debian.org>
2055     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2056
2057     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2058     #   series files
2059     #   
2060     #   If you have debian/patches/ubuntu.series and you were
2061     #   unpacking the source package on ubuntu, quilt was still
2062     #   directed to debian/patches/series instead of
2063     #   debian/patches/ubuntu.series.
2064     #   
2065     #   debian/changelog                        |    3 +++
2066     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2067     #   2 files changed, 6 insertions(+), 1 deletion(-)
2068
2069     use Dpkg::Vendor;
2070     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2071     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2072                          "Dpkg::Vendor \`current vendor'");
2073     vendor_patches_distro(access_basedistro(),
2074                           "(base) distro being accessed");
2075     vendor_patches_distro(access_nomdistro(),
2076                           "(nominal) distro being accessed");
2077 }
2078
2079 sub generate_commits_from_dsc () {
2080     # See big comment in fetch_from_archive, below.
2081     # See also README.dsc-import.
2082     prep_ud();
2083     changedir $playground;
2084
2085     my @dfi = dsc_files_info();
2086     foreach my $fi (@dfi) {
2087         my $f = $fi->{Filename};
2088         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2089         my $upper_f = (bpd_abs()."/$f");
2090
2091         printdebug "considering reusing $f: ";
2092
2093         if (link_ltarget "$upper_f,fetch", $f) {
2094             printdebug "linked (using ...,fetch).\n";
2095         } elsif ((printdebug "($!) "),
2096                  $! != ENOENT) {
2097             fail "accessing $buildproductsdir/$f,fetch: $!";
2098         } elsif (link_ltarget $upper_f, $f) {
2099             printdebug "linked.\n";
2100         } elsif ((printdebug "($!) "),
2101                  $! != ENOENT) {
2102             fail "accessing $buildproductsdir/$f: $!";
2103         } else {
2104             printdebug "absent.\n";
2105         }
2106
2107         my $refetched;
2108         complete_file_from_dsc('.', $fi, \$refetched)
2109             or next;
2110
2111         printdebug "considering saving $f: ";
2112
2113         if (link $f, $upper_f) {
2114             printdebug "linked.\n";
2115         } elsif ((printdebug "($!) "),
2116                  $! != EEXIST) {
2117             fail "saving $buildproductsdir/$f: $!";
2118         } elsif (!$refetched) {
2119             printdebug "no need.\n";
2120         } elsif (link $f, "$upper_f,fetch") {
2121             printdebug "linked (using ...,fetch).\n";
2122         } elsif ((printdebug "($!) "),
2123                  $! != EEXIST) {
2124             fail "saving $buildproductsdir/$f,fetch: $!";
2125         } else {
2126             printdebug "cannot.\n";
2127         }
2128     }
2129
2130     # We unpack and record the orig tarballs first, so that we only
2131     # need disk space for one private copy of the unpacked source.
2132     # But we can't make them into commits until we have the metadata
2133     # from the debian/changelog, so we record the tree objects now and
2134     # make them into commits later.
2135     my @tartrees;
2136     my $upstreamv = upstreamversion $dsc->{version};
2137     my $orig_f_base = srcfn $upstreamv, '';
2138
2139     foreach my $fi (@dfi) {
2140         # We actually import, and record as a commit, every tarball
2141         # (unless there is only one file, in which case there seems
2142         # little point.
2143
2144         my $f = $fi->{Filename};
2145         printdebug "import considering $f ";
2146         (printdebug "only one dfi\n"), next if @dfi == 1;
2147         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2148         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2149         my $compr_ext = $1;
2150
2151         my ($orig_f_part) =
2152             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2153
2154         printdebug "Y ", (join ' ', map { $_//"(none)" }
2155                           $compr_ext, $orig_f_part
2156                          ), "\n";
2157
2158         my $input = new IO::File $f, '<' or die "$f $!";
2159         my $compr_pid;
2160         my @compr_cmd;
2161
2162         if (defined $compr_ext) {
2163             my $cname =
2164                 Dpkg::Compression::compression_guess_from_filename $f;
2165             fail "Dpkg::Compression cannot handle file $f in source package"
2166                 if defined $compr_ext && !defined $cname;
2167             my $compr_proc =
2168                 new Dpkg::Compression::Process compression => $cname;
2169             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2170             my $compr_fh = new IO::Handle;
2171             my $compr_pid = open $compr_fh, "-|" // die $!;
2172             if (!$compr_pid) {
2173                 open STDIN, "<&", $input or die $!;
2174                 exec @compr_cmd;
2175                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2176             }
2177             $input = $compr_fh;
2178         }
2179
2180         rmtree "_unpack-tar";
2181         mkdir "_unpack-tar" or die $!;
2182         my @tarcmd = qw(tar -x -f -
2183                         --no-same-owner --no-same-permissions
2184                         --no-acls --no-xattrs --no-selinux);
2185         my $tar_pid = fork // die $!;
2186         if (!$tar_pid) {
2187             chdir "_unpack-tar" or die $!;
2188             open STDIN, "<&", $input or die $!;
2189             exec @tarcmd;
2190             die "dgit (child): exec $tarcmd[0]: $!";
2191         }
2192         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2193         !$? or failedcmd @tarcmd;
2194
2195         close $input or
2196             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2197              : die $!);
2198         # finally, we have the results in "tarball", but maybe
2199         # with the wrong permissions
2200
2201         runcmd qw(chmod -R +rwX _unpack-tar);
2202         changedir "_unpack-tar";
2203         remove_stray_gits($f);
2204         mktree_in_ud_here();
2205         
2206         my ($tree) = git_add_write_tree();
2207         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2208         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2209             $tree = $1;
2210             printdebug "one subtree $1\n";
2211         } else {
2212             printdebug "multiple subtrees\n";
2213         }
2214         changedir "..";
2215         rmtree "_unpack-tar";
2216
2217         my $ent = [ $f, $tree ];
2218         push @tartrees, {
2219             Orig => !!$orig_f_part,
2220             Sort => (!$orig_f_part         ? 2 :
2221                      $orig_f_part =~ m/-/g ? 1 :
2222                                              0),
2223             F => $f,
2224             Tree => $tree,
2225         };
2226     }
2227
2228     @tartrees = sort {
2229         # put any without "_" first (spec is not clear whether files
2230         # are always in the usual order).  Tarballs without "_" are
2231         # the main orig or the debian tarball.
2232         $a->{Sort} <=> $b->{Sort} or
2233         $a->{F}    cmp $b->{F}
2234     } @tartrees;
2235
2236     my $any_orig = grep { $_->{Orig} } @tartrees;
2237
2238     my $dscfn = "$package.dsc";
2239
2240     my $treeimporthow = 'package';
2241
2242     open D, ">", $dscfn or die "$dscfn: $!";
2243     print D $dscdata or die "$dscfn: $!";
2244     close D or die "$dscfn: $!";
2245     my @cmd = qw(dpkg-source);
2246     push @cmd, '--no-check' if $dsc_checked;
2247     if (madformat $dsc->{format}) {
2248         push @cmd, '--skip-patches';
2249         $treeimporthow = 'unpatched';
2250     }
2251     push @cmd, qw(-x --), $dscfn;
2252     runcmd @cmd;
2253
2254     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2255     if (madformat $dsc->{format}) { 
2256         check_for_vendor_patches();
2257     }
2258
2259     my $dappliedtree;
2260     if (madformat $dsc->{format}) {
2261         my @pcmd = qw(dpkg-source --before-build .);
2262         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2263         rmtree '.pc';
2264         $dappliedtree = git_add_write_tree();
2265     }
2266
2267     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2268     my $clogp;
2269     my $r1clogp;
2270
2271     printdebug "import clog search...\n";
2272     parsechangelog_loop \@clogcmd, "package changelog", sub {
2273         my ($thisstanza, $desc) = @_;
2274         no warnings qw(exiting);
2275
2276         $clogp //= $thisstanza;
2277
2278         printdebug "import clog $thisstanza->{version} $desc...\n";
2279
2280         last if !$any_orig; # we don't need $r1clogp
2281
2282         # We look for the first (most recent) changelog entry whose
2283         # version number is lower than the upstream version of this
2284         # package.  Then the last (least recent) previous changelog
2285         # entry is treated as the one which introduced this upstream
2286         # version and used for the synthetic commits for the upstream
2287         # tarballs.
2288
2289         # One might think that a more sophisticated algorithm would be
2290         # necessary.  But: we do not want to scan the whole changelog
2291         # file.  Stopping when we see an earlier version, which
2292         # necessarily then is an earlier upstream version, is the only
2293         # realistic way to do that.  Then, either the earliest
2294         # changelog entry we have seen so far is indeed the earliest
2295         # upload of this upstream version; or there are only changelog
2296         # entries relating to later upstream versions (which is not
2297         # possible unless the changelog and .dsc disagree about the
2298         # version).  Then it remains to choose between the physically
2299         # last entry in the file, and the one with the lowest version
2300         # number.  If these are not the same, we guess that the
2301         # versions were created in a non-monotonic order rather than
2302         # that the changelog entries have been misordered.
2303
2304         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2305
2306         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2307         $r1clogp = $thisstanza;
2308
2309         printdebug "import clog $r1clogp->{version} becomes r1\n";
2310     };
2311
2312     $clogp or fail "package changelog has no entries!";
2313
2314     my $authline = clogp_authline $clogp;
2315     my $changes = getfield $clogp, 'Changes';
2316     $changes =~ s/^\n//; # Changes: \n
2317     my $cversion = getfield $clogp, 'Version';
2318
2319     if (@tartrees) {
2320         $r1clogp //= $clogp; # maybe there's only one entry;
2321         my $r1authline = clogp_authline $r1clogp;
2322         # Strictly, r1authline might now be wrong if it's going to be
2323         # unused because !$any_orig.  Whatever.
2324
2325         printdebug "import tartrees authline   $authline\n";
2326         printdebug "import tartrees r1authline $r1authline\n";
2327
2328         foreach my $tt (@tartrees) {
2329             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2330
2331             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2332 tree $tt->{Tree}
2333 author $r1authline
2334 committer $r1authline
2335
2336 Import $tt->{F}
2337
2338 [dgit import orig $tt->{F}]
2339 END_O
2340 tree $tt->{Tree}
2341 author $authline
2342 committer $authline
2343
2344 Import $tt->{F}
2345
2346 [dgit import tarball $package $cversion $tt->{F}]
2347 END_T
2348         }
2349     }
2350
2351     printdebug "import main commit\n";
2352
2353     open C, ">../commit.tmp" or die $!;
2354     print C <<END or die $!;
2355 tree $tree
2356 END
2357     print C <<END or die $! foreach @tartrees;
2358 parent $_->{Commit}
2359 END
2360     print C <<END or die $!;
2361 author $authline
2362 committer $authline
2363
2364 $changes
2365
2366 [dgit import $treeimporthow $package $cversion]
2367 END
2368
2369     close C or die $!;
2370     my $rawimport_hash = make_commit qw(../commit.tmp);
2371
2372     if (madformat $dsc->{format}) {
2373         printdebug "import apply patches...\n";
2374
2375         # regularise the state of the working tree so that
2376         # the checkout of $rawimport_hash works nicely.
2377         my $dappliedcommit = make_commit_text(<<END);
2378 tree $dappliedtree
2379 author $authline
2380 committer $authline
2381
2382 [dgit dummy commit]
2383 END
2384         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2385
2386         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2387
2388         # We need the answers to be reproducible
2389         my @authline = clogp_authline($clogp);
2390         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2391         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2392         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2393         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2394         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2395         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2396
2397         my $path = $ENV{PATH} or die;
2398
2399         # we use ../../gbp-pq-output, which (given that we are in
2400         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2401         # is .git/dgit.
2402
2403         foreach my $use_absurd (qw(0 1)) {
2404             runcmd @git, qw(checkout -q unpa);
2405             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2406             local $ENV{PATH} = $path;
2407             if ($use_absurd) {
2408                 chomp $@;
2409                 progress "warning: $@";
2410                 $path = "$absurdity:$path";
2411                 progress "$us: trying slow absurd-git-apply...";
2412                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2413                     or $!==ENOENT
2414                     or die $!;
2415             }
2416             eval {
2417                 die "forbid absurd git-apply\n" if $use_absurd
2418                     && forceing [qw(import-gitapply-no-absurd)];
2419                 die "only absurd git-apply!\n" if !$use_absurd
2420                     && forceing [qw(import-gitapply-absurd)];
2421
2422                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2423                 local $ENV{PATH} = $path                    if $use_absurd;
2424
2425                 my @showcmd = (gbp_pq, qw(import));
2426                 my @realcmd = shell_cmd
2427                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2428                 debugcmd "+",@realcmd;
2429                 if (system @realcmd) {
2430                     die +(shellquote @showcmd).
2431                         " failed: ".
2432                         failedcmd_waitstatus()."\n";
2433                 }
2434
2435                 my $gapplied = git_rev_parse('HEAD');
2436                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2437                 $gappliedtree eq $dappliedtree or
2438                     fail <<END;
2439 gbp-pq import and dpkg-source disagree!
2440  gbp-pq import gave commit $gapplied
2441  gbp-pq import gave tree $gappliedtree
2442  dpkg-source --before-build gave tree $dappliedtree
2443 END
2444                 $rawimport_hash = $gapplied;
2445             };
2446             last unless $@;
2447         }
2448         if ($@) {
2449             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2450             die $@;
2451         }
2452     }
2453
2454     progress "synthesised git commit from .dsc $cversion";
2455
2456     my $rawimport_mergeinput = {
2457         Commit => $rawimport_hash,
2458         Info => "Import of source package",
2459     };
2460     my @output = ($rawimport_mergeinput);
2461
2462     if ($lastpush_mergeinput) {
2463         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2464         my $oversion = getfield $oldclogp, 'Version';
2465         my $vcmp =
2466             version_compare($oversion, $cversion);
2467         if ($vcmp < 0) {
2468             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2469                 { Message => <<END, ReverseParents => 1 });
2470 Record $package ($cversion) in archive suite $csuite
2471 END
2472         } elsif ($vcmp > 0) {
2473             print STDERR <<END or die $!;
2474
2475 Version actually in archive:   $cversion (older)
2476 Last version pushed with dgit: $oversion (newer or same)
2477 $later_warning_msg
2478 END
2479             @output = $lastpush_mergeinput;
2480         } else {
2481             # Same version.  Use what's in the server git branch,
2482             # discarding our own import.  (This could happen if the
2483             # server automatically imports all packages into git.)
2484             @output = $lastpush_mergeinput;
2485         }
2486     }
2487     changedir $maindir;
2488     rmtree $playground;
2489     return @output;
2490 }
2491
2492 sub complete_file_from_dsc ($$;$) {
2493     our ($dstdir, $fi, $refetched) = @_;
2494     # Ensures that we have, in $dstdir, the file $fi, with the correct
2495     # contents.  (Downloading it from alongside $dscurl if necessary.)
2496     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2497     # and will set $$refetched=1 if it did so (or tried to).
2498
2499     my $f = $fi->{Filename};
2500     my $tf = "$dstdir/$f";
2501     my $downloaded = 0;
2502
2503     my $got;
2504     my $checkhash = sub {
2505         open F, "<", "$tf" or die "$tf: $!";
2506         $fi->{Digester}->reset();
2507         $fi->{Digester}->addfile(*F);
2508         F->error and die $!;
2509         $got = $fi->{Digester}->hexdigest();
2510         return $got eq $fi->{Hash};
2511     };
2512
2513     if (stat_exists $tf) {
2514         if ($checkhash->()) {
2515             progress "using existing $f";
2516             return 1;
2517         }
2518         if (!$refetched) {
2519             fail "file $f has hash $got but .dsc".
2520                 " demands hash $fi->{Hash} ".
2521                 "(perhaps you should delete this file?)";
2522         }
2523         progress "need to fetch correct version of $f";
2524         unlink $tf or die "$tf $!";
2525         $$refetched = 1;
2526     } else {
2527         printdebug "$tf does not exist, need to fetch\n";
2528     }
2529
2530     my $furl = $dscurl;
2531     $furl =~ s{/[^/]+$}{};
2532     $furl .= "/$f";
2533     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2534     die "$f ?" if $f =~ m#/#;
2535     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2536     return 0 if !act_local();
2537
2538     $checkhash->() or
2539         fail "file $f has hash $got but .dsc".
2540             " demands hash $fi->{Hash} ".
2541             "(got wrong file from archive!)";
2542
2543     return 1;
2544 }
2545
2546 sub ensure_we_have_orig () {
2547     my @dfi = dsc_files_info();
2548     foreach my $fi (@dfi) {
2549         my $f = $fi->{Filename};
2550         next unless is_orig_file_in_dsc($f, \@dfi);
2551         complete_file_from_dsc($buildproductsdir, $fi)
2552             or next;
2553     }
2554 }
2555
2556 #---------- git fetch ----------
2557
2558 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2559 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2560
2561 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2562 # locally fetched refs because they have unhelpful names and clutter
2563 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2564 # whether we have made another local ref which refers to this object).
2565 #
2566 # (If we deleted them unconditionally, then we might end up
2567 # re-fetching the same git objects each time dgit fetch was run.)
2568 #
2569 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2570 # in git_fetch_us to fetch the refs in question, and possibly a call
2571 # to lrfetchref_used.
2572
2573 our (%lrfetchrefs_f, %lrfetchrefs_d);
2574 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2575
2576 sub lrfetchref_used ($) {
2577     my ($fullrefname) = @_;
2578     my $objid = $lrfetchrefs_f{$fullrefname};
2579     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2580 }
2581
2582 sub git_lrfetch_sane {
2583     my ($url, $supplementary, @specs) = @_;
2584     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2585     # at least as regards @specs.  Also leave the results in
2586     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2587     # able to clean these up.
2588     #
2589     # With $supplementary==1, @specs must not contain wildcards
2590     # and we add to our previous fetches (non-atomically).
2591
2592     # This is rather miserable:
2593     # When git fetch --prune is passed a fetchspec ending with a *,
2594     # it does a plausible thing.  If there is no * then:
2595     # - it matches subpaths too, even if the supplied refspec
2596     #   starts refs, and behaves completely madly if the source
2597     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2598     # - if there is no matching remote ref, it bombs out the whole
2599     #   fetch.
2600     # We want to fetch a fixed ref, and we don't know in advance
2601     # if it exists, so this is not suitable.
2602     #
2603     # Our workaround is to use git ls-remote.  git ls-remote has its
2604     # own qairks.  Notably, it has the absurd multi-tail-matching
2605     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2606     # refs/refs/foo etc.
2607     #
2608     # Also, we want an idempotent snapshot, but we have to make two
2609     # calls to the remote: one to git ls-remote and to git fetch.  The
2610     # solution is use git ls-remote to obtain a target state, and
2611     # git fetch to try to generate it.  If we don't manage to generate
2612     # the target state, we try again.
2613
2614     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2615
2616     my $specre = join '|', map {
2617         my $x = $_;
2618         $x =~ s/\W/\\$&/g;
2619         my $wildcard = $x =~ s/\\\*$/.*/;
2620         die if $wildcard && $supplementary;
2621         "(?:refs/$x)";
2622     } @specs;
2623     printdebug "git_lrfetch_sane specre=$specre\n";
2624     my $wanted_rref = sub {
2625         local ($_) = @_;
2626         return m/^(?:$specre)$/;
2627     };
2628
2629     my $fetch_iteration = 0;
2630     FETCH_ITERATION:
2631     for (;;) {
2632         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2633         if (++$fetch_iteration > 10) {
2634             fail "too many iterations trying to get sane fetch!";
2635         }
2636
2637         my @look = map { "refs/$_" } @specs;
2638         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2639         debugcmd "|",@lcmd;
2640
2641         my %wantr;
2642         open GITLS, "-|", @lcmd or die $!;
2643         while (<GITLS>) {
2644             printdebug "=> ", $_;
2645             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2646             my ($objid,$rrefname) = ($1,$2);
2647             if (!$wanted_rref->($rrefname)) {
2648                 print STDERR <<END;
2649 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2650 END
2651                 next;
2652             }
2653             $wantr{$rrefname} = $objid;
2654         }
2655         $!=0; $?=0;
2656         close GITLS or failedcmd @lcmd;
2657
2658         # OK, now %want is exactly what we want for refs in @specs
2659         my @fspecs = map {
2660             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2661             "+refs/$_:".lrfetchrefs."/$_";
2662         } @specs;
2663
2664         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2665
2666         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2667         runcmd_ordryrun_local @fcmd if @fspecs;
2668
2669         if (!$supplementary) {
2670             %lrfetchrefs_f = ();
2671         }
2672         my %objgot;
2673
2674         git_for_each_ref(lrfetchrefs, sub {
2675             my ($objid,$objtype,$lrefname,$reftail) = @_;
2676             $lrfetchrefs_f{$lrefname} = $objid;
2677             $objgot{$objid} = 1;
2678         });
2679
2680         if ($supplementary) {
2681             last;
2682         }
2683
2684         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2685             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2686             if (!exists $wantr{$rrefname}) {
2687                 if ($wanted_rref->($rrefname)) {
2688                     printdebug <<END;
2689 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2690 END
2691                 } else {
2692                     print STDERR <<END
2693 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2694 END
2695                 }
2696                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2697                 delete $lrfetchrefs_f{$lrefname};
2698                 next;
2699             }
2700         }
2701         foreach my $rrefname (sort keys %wantr) {
2702             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2703             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2704             my $want = $wantr{$rrefname};
2705             next if $got eq $want;
2706             if (!defined $objgot{$want}) {
2707                 fail <<END unless act_local();
2708 --dry-run specified but we actually wanted the results of git fetch,
2709 so this is not going to work.  Try running dgit fetch first,
2710 or using --damp-run instead of --dry-run.
2711 END
2712                 print STDERR <<END;
2713 warning: git ls-remote suggests we want $lrefname
2714 warning:  and it should refer to $want
2715 warning:  but git fetch didn't fetch that object to any relevant ref.
2716 warning:  This may be due to a race with someone updating the server.
2717 warning:  Will try again...
2718 END
2719                 next FETCH_ITERATION;
2720             }
2721             printdebug <<END;
2722 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2723 END
2724             runcmd_ordryrun_local @git, qw(update-ref -m),
2725                 "dgit fetch git fetch fixup", $lrefname, $want;
2726             $lrfetchrefs_f{$lrefname} = $want;
2727         }
2728         last;
2729     }
2730
2731     if (defined $csuite) {
2732         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2733         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2734             my ($objid,$objtype,$lrefname,$reftail) = @_;
2735             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2736             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2737         });
2738     }
2739
2740     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2741         Dumper(\%lrfetchrefs_f);
2742 }
2743
2744 sub git_fetch_us () {
2745     # Want to fetch only what we are going to use, unless
2746     # deliberately-not-ff, in which case we must fetch everything.
2747
2748     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2749         map { "tags/$_" }
2750         (quiltmode_splitbrain
2751          ? (map { $_->('*',access_nomdistro) }
2752             \&debiantag_new, \&debiantag_maintview)
2753          : debiantags('*',access_nomdistro));
2754     push @specs, server_branch($csuite);
2755     push @specs, $rewritemap;
2756     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2757
2758     my $url = access_giturl();
2759     git_lrfetch_sane $url, 0, @specs;
2760
2761     my %here;
2762     my @tagpats = debiantags('*',access_nomdistro);
2763
2764     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2765         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2766         printdebug "currently $fullrefname=$objid\n";
2767         $here{$fullrefname} = $objid;
2768     });
2769     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2770         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2771         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2772         printdebug "offered $lref=$objid\n";
2773         if (!defined $here{$lref}) {
2774             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2775             runcmd_ordryrun_local @upd;
2776             lrfetchref_used $fullrefname;
2777         } elsif ($here{$lref} eq $objid) {
2778             lrfetchref_used $fullrefname;
2779         } else {
2780             print STDERR
2781                 "Not updating $lref from $here{$lref} to $objid.\n";
2782         }
2783     });
2784 }
2785
2786 #---------- dsc and archive handling ----------
2787
2788 sub mergeinfo_getclogp ($) {
2789     # Ensures thit $mi->{Clogp} exists and returns it
2790     my ($mi) = @_;
2791     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2792 }
2793
2794 sub mergeinfo_version ($) {
2795     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2796 }
2797
2798 sub fetch_from_archive_record_1 ($) {
2799     my ($hash) = @_;
2800     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
2801     cmdoutput @git, qw(log -n2), $hash;
2802     # ... gives git a chance to complain if our commit is malformed
2803 }
2804
2805 sub fetch_from_archive_record_2 ($) {
2806     my ($hash) = @_;
2807     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
2808     if (act_local()) {
2809         cmdoutput @upd_cmd;
2810     } else {
2811         dryrun_report @upd_cmd;
2812     }
2813 }
2814
2815 sub parse_dsc_field_def_dsc_distro () {
2816     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2817                            dgit.default.distro);
2818 }
2819
2820 sub parse_dsc_field ($$) {
2821     my ($dsc, $what) = @_;
2822     my $f;
2823     foreach my $field (@ourdscfield) {
2824         $f = $dsc->{$field};
2825         last if defined $f;
2826     }
2827
2828     if (!defined $f) {
2829         progress "$what: NO git hash";
2830         parse_dsc_field_def_dsc_distro();
2831     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2832              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2833         progress "$what: specified git info ($dsc_distro)";
2834         $dsc_hint_tag = [ $dsc_hint_tag ];
2835     } elsif ($f =~ m/^\w+\s*$/) {
2836         $dsc_hash = $&;
2837         parse_dsc_field_def_dsc_distro();
2838         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2839                           $dsc_distro ];
2840         progress "$what: specified git hash";
2841     } else {
2842         fail "$what: invalid Dgit info";
2843     }
2844 }
2845
2846 sub resolve_dsc_field_commit ($$) {
2847     my ($already_distro, $already_mapref) = @_;
2848
2849     return unless defined $dsc_hash;
2850
2851     my $mapref =
2852         defined $already_mapref &&
2853         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2854         ? $already_mapref : undef;
2855
2856     my $do_fetch;
2857     $do_fetch = sub {
2858         my ($what, @fetch) = @_;
2859
2860         local $idistro = $dsc_distro;
2861         my $lrf = lrfetchrefs;
2862
2863         if (!$chase_dsc_distro) {
2864             progress
2865                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2866             return 0;
2867         }
2868
2869         progress
2870             ".dsc names distro $dsc_distro: fetching $what";
2871
2872         my $url = access_giturl();
2873         if (!defined $url) {
2874             defined $dsc_hint_url or fail <<END;
2875 .dsc Dgit metadata is in context of distro $dsc_distro
2876 for which we have no configured url and .dsc provides no hint
2877 END
2878             my $proto =
2879                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2880                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2881             parse_cfg_bool "dsc-url-proto-ok", 'false',
2882                 cfg("dgit.dsc-url-proto-ok.$proto",
2883                     "dgit.default.dsc-url-proto-ok")
2884                 or fail <<END;
2885 .dsc Dgit metadata is in context of distro $dsc_distro
2886 for which we have no configured url;
2887 .dsc provides hinted url with protocol $proto which is unsafe.
2888 (can be overridden by config - consult documentation)
2889 END
2890             $url = $dsc_hint_url;
2891         }
2892
2893         git_lrfetch_sane $url, 1, @fetch;
2894
2895         return $lrf;
2896     };
2897
2898     my $rewrite_enable = do {
2899         local $idistro = $dsc_distro;
2900         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2901     };
2902
2903     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2904         if (!defined $mapref) {
2905             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2906             $mapref = $lrf.'/'.$rewritemap;
2907         }
2908         my $rewritemapdata = git_cat_file $mapref.':map';
2909         if (defined $rewritemapdata
2910             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2911             progress
2912                 "server's git history rewrite map contains a relevant entry!";
2913
2914             $dsc_hash = $1;
2915             if (defined $dsc_hash) {
2916                 progress "using rewritten git hash in place of .dsc value";
2917             } else {
2918                 progress "server data says .dsc hash is to be disregarded";
2919             }
2920         }
2921     }
2922
2923     if (!defined git_cat_file $dsc_hash) {
2924         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2925         my $lrf = $do_fetch->("additional commits", @tags) &&
2926             defined git_cat_file $dsc_hash
2927             or fail <<END;
2928 .dsc Dgit metadata requires commit $dsc_hash
2929 but we could not obtain that object anywhere.
2930 END
2931         foreach my $t (@tags) {
2932             my $fullrefname = $lrf.'/'.$t;
2933 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2934             next unless $lrfetchrefs_f{$fullrefname};
2935             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2936             lrfetchref_used $fullrefname;
2937         }
2938     }
2939 }
2940
2941 sub fetch_from_archive () {
2942     ensure_setup_existing_tree();
2943
2944     # Ensures that lrref() is what is actually in the archive, one way
2945     # or another, according to us - ie this client's
2946     # appropritaely-updated archive view.  Also returns the commit id.
2947     # If there is nothing in the archive, leaves lrref alone and
2948     # returns undef.  git_fetch_us must have already been called.
2949     get_archive_dsc();
2950
2951     if ($dsc) {
2952         parse_dsc_field($dsc, 'last upload to archive');
2953         resolve_dsc_field_commit access_basedistro,
2954             lrfetchrefs."/".$rewritemap
2955     } else {
2956         progress "no version available from the archive";
2957     }
2958
2959     # If the archive's .dsc has a Dgit field, there are three
2960     # relevant git commitids we need to choose between and/or merge
2961     # together:
2962     #   1. $dsc_hash: the Dgit field from the archive
2963     #   2. $lastpush_hash: the suite branch on the dgit git server
2964     #   3. $lastfetch_hash: our local tracking brach for the suite
2965     #
2966     # These may all be distinct and need not be in any fast forward
2967     # relationship:
2968     #
2969     # If the dsc was pushed to this suite, then the server suite
2970     # branch will have been updated; but it might have been pushed to
2971     # a different suite and copied by the archive.  Conversely a more
2972     # recent version may have been pushed with dgit but not appeared
2973     # in the archive (yet).
2974     #
2975     # $lastfetch_hash may be awkward because archive imports
2976     # (particularly, imports of Dgit-less .dscs) are performed only as
2977     # needed on individual clients, so different clients may perform a
2978     # different subset of them - and these imports are only made
2979     # public during push.  So $lastfetch_hash may represent a set of
2980     # imports different to a subsequent upload by a different dgit
2981     # client.
2982     #
2983     # Our approach is as follows:
2984     #
2985     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2986     # descendant of $dsc_hash, then it was pushed by a dgit user who
2987     # had based their work on $dsc_hash, so we should prefer it.
2988     # Otherwise, $dsc_hash was installed into this suite in the
2989     # archive other than by a dgit push, and (necessarily) after the
2990     # last dgit push into that suite (since a dgit push would have
2991     # been descended from the dgit server git branch); thus, in that
2992     # case, we prefer the archive's version (and produce a
2993     # pseudo-merge to overwrite the dgit server git branch).
2994     #
2995     # (If there is no Dgit field in the archive's .dsc then
2996     # generate_commit_from_dsc uses the version numbers to decide
2997     # whether the suite branch or the archive is newer.  If the suite
2998     # branch is newer it ignores the archive's .dsc; otherwise it
2999     # generates an import of the .dsc, and produces a pseudo-merge to
3000     # overwrite the suite branch with the archive contents.)
3001     #
3002     # The outcome of that part of the algorithm is the `public view',
3003     # and is same for all dgit clients: it does not depend on any
3004     # unpublished history in the local tracking branch.
3005     #
3006     # As between the public view and the local tracking branch: The
3007     # local tracking branch is only updated by dgit fetch, and
3008     # whenever dgit fetch runs it includes the public view in the
3009     # local tracking branch.  Therefore if the public view is not
3010     # descended from the local tracking branch, the local tracking
3011     # branch must contain history which was imported from the archive
3012     # but never pushed; and, its tip is now out of date.  So, we make
3013     # a pseudo-merge to overwrite the old imports and stitch the old
3014     # history in.
3015     #
3016     # Finally: we do not necessarily reify the public view (as
3017     # described above).  This is so that we do not end up stacking two
3018     # pseudo-merges.  So what we actually do is figure out the inputs
3019     # to any public view pseudo-merge and put them in @mergeinputs.
3020
3021     my @mergeinputs;
3022     # $mergeinputs[]{Commit}
3023     # $mergeinputs[]{Info}
3024     # $mergeinputs[0] is the one whose tree we use
3025     # @mergeinputs is in the order we use in the actual commit)
3026     #
3027     # Also:
3028     # $mergeinputs[]{Message} is a commit message to use
3029     # $mergeinputs[]{ReverseParents} if def specifies that parent
3030     #                                list should be in opposite order
3031     # Such an entry has no Commit or Info.  It applies only when found
3032     # in the last entry.  (This ugliness is to support making
3033     # identical imports to previous dgit versions.)
3034
3035     my $lastpush_hash = git_get_ref(lrfetchref());
3036     printdebug "previous reference hash=$lastpush_hash\n";
3037     $lastpush_mergeinput = $lastpush_hash && {
3038         Commit => $lastpush_hash,
3039         Info => "dgit suite branch on dgit git server",
3040     };
3041
3042     my $lastfetch_hash = git_get_ref(lrref());
3043     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3044     my $lastfetch_mergeinput = $lastfetch_hash && {
3045         Commit => $lastfetch_hash,
3046         Info => "dgit client's archive history view",
3047     };
3048
3049     my $dsc_mergeinput = $dsc_hash && {
3050         Commit => $dsc_hash,
3051         Info => "Dgit field in .dsc from archive",
3052     };
3053
3054     my $cwd = getcwd();
3055     my $del_lrfetchrefs = sub {
3056         changedir $cwd;
3057         my $gur;
3058         printdebug "del_lrfetchrefs...\n";
3059         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3060             my $objid = $lrfetchrefs_d{$fullrefname};
3061             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3062             if (!$gur) {
3063                 $gur ||= new IO::Handle;
3064                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3065             }
3066             printf $gur "delete %s %s\n", $fullrefname, $objid;
3067         }
3068         if ($gur) {
3069             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3070         }
3071     };
3072
3073     if (defined $dsc_hash) {
3074         ensure_we_have_orig();
3075         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3076             @mergeinputs = $dsc_mergeinput
3077         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3078             print STDERR <<END or die $!;
3079
3080 Git commit in archive is behind the last version allegedly pushed/uploaded.
3081 Commit referred to by archive: $dsc_hash
3082 Last version pushed with dgit: $lastpush_hash
3083 $later_warning_msg
3084 END
3085             @mergeinputs = ($lastpush_mergeinput);
3086         } else {
3087             # Archive has .dsc which is not a descendant of the last dgit
3088             # push.  This can happen if the archive moves .dscs about.
3089             # Just follow its lead.
3090             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3091                 progress "archive .dsc names newer git commit";
3092                 @mergeinputs = ($dsc_mergeinput);
3093             } else {
3094                 progress "archive .dsc names other git commit, fixing up";
3095                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3096             }
3097         }
3098     } elsif ($dsc) {
3099         @mergeinputs = generate_commits_from_dsc();
3100         # We have just done an import.  Now, our import algorithm might
3101         # have been improved.  But even so we do not want to generate
3102         # a new different import of the same package.  So if the
3103         # version numbers are the same, just use our existing version.
3104         # If the version numbers are different, the archive has changed
3105         # (perhaps, rewound).
3106         if ($lastfetch_mergeinput &&
3107             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3108                               (mergeinfo_version $mergeinputs[0]) )) {
3109             @mergeinputs = ($lastfetch_mergeinput);
3110         }
3111     } elsif ($lastpush_hash) {
3112         # only in git, not in the archive yet
3113         @mergeinputs = ($lastpush_mergeinput);
3114         print STDERR <<END or die $!;
3115
3116 Package not found in the archive, but has allegedly been pushed using dgit.
3117 $later_warning_msg
3118 END
3119     } else {
3120         printdebug "nothing found!\n";
3121         if (defined $skew_warning_vsn) {
3122             print STDERR <<END or die $!;
3123
3124 Warning: relevant archive skew detected.
3125 Archive allegedly contains $skew_warning_vsn
3126 But we were not able to obtain any version from the archive or git.
3127
3128 END
3129         }
3130         unshift @end, $del_lrfetchrefs;
3131         return undef;
3132     }
3133
3134     if ($lastfetch_hash &&
3135         !grep {
3136             my $h = $_->{Commit};
3137             $h and is_fast_fwd($lastfetch_hash, $h);
3138             # If true, one of the existing parents of this commit
3139             # is a descendant of the $lastfetch_hash, so we'll
3140             # be ff from that automatically.
3141         } @mergeinputs
3142         ) {
3143         # Otherwise:
3144         push @mergeinputs, $lastfetch_mergeinput;
3145     }
3146
3147     printdebug "fetch mergeinfos:\n";
3148     foreach my $mi (@mergeinputs) {
3149         if ($mi->{Info}) {
3150             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3151         } else {
3152             printdebug sprintf " ReverseParents=%d Message=%s",
3153                 $mi->{ReverseParents}, $mi->{Message};
3154         }
3155     }
3156
3157     my $compat_info= pop @mergeinputs
3158         if $mergeinputs[$#mergeinputs]{Message};
3159
3160     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3161
3162     my $hash;
3163     if (@mergeinputs > 1) {
3164         # here we go, then:
3165         my $tree_commit = $mergeinputs[0]{Commit};
3166
3167         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3168         $tree =~ m/\n\n/;  $tree = $`;
3169         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3170         $tree = $1;
3171
3172         # We use the changelog author of the package in question the
3173         # author of this pseudo-merge.  This is (roughly) correct if
3174         # this commit is simply representing aa non-dgit upload.
3175         # (Roughly because it does not record sponsorship - but we
3176         # don't have sponsorship info because that's in the .changes,
3177         # which isn't in the archivw.)
3178         #
3179         # But, it might be that we are representing archive history
3180         # updates (including in-archive copies).  These are not really
3181         # the responsibility of the person who created the .dsc, but
3182         # there is no-one whose name we should better use.  (The
3183         # author of the .dsc-named commit is clearly worse.)
3184
3185         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3186         my $author = clogp_authline $useclogp;
3187         my $cversion = getfield $useclogp, 'Version';
3188
3189         my $mcf = dgit_privdir()."/mergecommit";
3190         open MC, ">", $mcf or die "$mcf $!";
3191         print MC <<END or die $!;
3192 tree $tree
3193 END
3194
3195         my @parents = grep { $_->{Commit} } @mergeinputs;
3196         @parents = reverse @parents if $compat_info->{ReverseParents};
3197         print MC <<END or die $! foreach @parents;
3198 parent $_->{Commit}
3199 END
3200
3201         print MC <<END or die $!;
3202 author $author
3203 committer $author
3204
3205 END
3206
3207         if (defined $compat_info->{Message}) {
3208             print MC $compat_info->{Message} or die $!;
3209         } else {
3210             print MC <<END or die $!;
3211 Record $package ($cversion) in archive suite $csuite
3212
3213 Record that
3214 END
3215             my $message_add_info = sub {
3216                 my ($mi) = (@_);
3217                 my $mversion = mergeinfo_version $mi;
3218                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3219                     or die $!;
3220             };
3221
3222             $message_add_info->($mergeinputs[0]);
3223             print MC <<END or die $!;
3224 should be treated as descended from
3225 END
3226             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3227         }
3228
3229         close MC or die $!;
3230         $hash = make_commit $mcf;
3231     } else {
3232         $hash = $mergeinputs[0]{Commit};
3233     }
3234     printdebug "fetch hash=$hash\n";
3235
3236     my $chkff = sub {
3237         my ($lasth, $what) = @_;
3238         return unless $lasth;
3239         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3240     };
3241
3242     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3243         if $lastpush_hash;
3244     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3245
3246     fetch_from_archive_record_1($hash);
3247
3248     if (defined $skew_warning_vsn) {
3249         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3250         my $gotclogp = commit_getclogp($hash);
3251         my $got_vsn = getfield $gotclogp, 'Version';
3252         printdebug "SKEW CHECK GOT $got_vsn\n";
3253         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3254             print STDERR <<END or die $!;
3255
3256 Warning: archive skew detected.  Using the available version:
3257 Archive allegedly contains    $skew_warning_vsn
3258 We were able to obtain only   $got_vsn
3259
3260 END
3261         }
3262     }
3263
3264     if ($lastfetch_hash ne $hash) {
3265         fetch_from_archive_record_2($hash);
3266     }
3267
3268     lrfetchref_used lrfetchref();
3269
3270     check_gitattrs($hash, "fetched source tree");
3271
3272     unshift @end, $del_lrfetchrefs;
3273     return $hash;
3274 }
3275
3276 sub set_local_git_config ($$) {
3277     my ($k, $v) = @_;
3278     runcmd @git, qw(config), $k, $v;
3279 }
3280
3281 sub setup_mergechangelogs (;$) {
3282     my ($always) = @_;
3283     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3284
3285     my $driver = 'dpkg-mergechangelogs';
3286     my $cb = "merge.$driver";
3287     confess unless defined $maindir;
3288     my $attrs = "$maindir_gitcommon/info/attributes";
3289     ensuredir "$maindir_gitcommon/info";
3290
3291     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3292     if (!open ATTRS, "<", $attrs) {
3293         $!==ENOENT or die "$attrs: $!";
3294     } else {
3295         while (<ATTRS>) {
3296             chomp;
3297             next if m{^debian/changelog\s};
3298             print NATTRS $_, "\n" or die $!;
3299         }
3300         ATTRS->error and die $!;
3301         close ATTRS;
3302     }
3303     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3304     close NATTRS;
3305
3306     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3307     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3308
3309     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3310 }
3311
3312 sub setup_useremail (;$) {
3313     my ($always) = @_;
3314     return unless $always || access_cfg_bool(1, 'setup-useremail');
3315
3316     my $setup = sub {
3317         my ($k, $envvar) = @_;
3318         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3319         return unless defined $v;
3320         set_local_git_config "user.$k", $v;
3321     };
3322
3323     $setup->('email', 'DEBEMAIL');
3324     $setup->('name', 'DEBFULLNAME');
3325 }
3326
3327 sub ensure_setup_existing_tree () {
3328     my $k = "remote.$remotename.skipdefaultupdate";
3329     my $c = git_get_config $k;
3330     return if defined $c;
3331     set_local_git_config $k, 'true';
3332 }
3333
3334 sub open_main_gitattrs () {
3335     confess 'internal error no maindir' unless defined $maindir;
3336     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3337         or $!==ENOENT
3338         or die "open $maindir_gitcommon/info/attributes: $!";
3339     return $gai;
3340 }
3341
3342 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3343
3344 sub is_gitattrs_setup () {
3345     # return values:
3346     #  trueish
3347     #     1: gitattributes set up and should be left alone
3348     #  falseish
3349     #     0: there is a dgit-defuse-attrs but it needs fixing
3350     #     undef: there is none
3351     my $gai = open_main_gitattrs();
3352     return 0 unless $gai;
3353     while (<$gai>) {
3354         next unless m{$gitattrs_ourmacro_re};
3355         return 1 if m{\s-working-tree-encoding\s};
3356         printdebug "is_gitattrs_setup: found old macro\n";
3357         return 0;
3358     }
3359     $gai->error and die $!;
3360     printdebug "is_gitattrs_setup: found nothing\n";
3361     return undef;
3362 }    
3363
3364 sub setup_gitattrs (;$) {
3365     my ($always) = @_;
3366     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3367
3368     my $already = is_gitattrs_setup();
3369     if ($already) {
3370         progress <<END;
3371 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3372  not doing further gitattributes setup
3373 END
3374         return;
3375     }
3376     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3377     my $af = "$maindir_gitcommon/info/attributes";
3378     ensuredir "$maindir_gitcommon/info";
3379
3380     open GAO, "> $af.new" or die $!;
3381     print GAO <<END or die $! unless defined $already;
3382 *       dgit-defuse-attrs
3383 $new
3384 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3385 END
3386     my $gai = open_main_gitattrs();
3387     if ($gai) {
3388         while (<$gai>) {
3389             if (m{$gitattrs_ourmacro_re}) {
3390                 die unless defined $already;
3391                 $_ = $new;
3392             }
3393             chomp;
3394             print GAO $_, "\n" or die $!;
3395         }
3396         $gai->error and die $!;
3397     }
3398     close GAO or die $!;
3399     rename "$af.new", "$af" or die "install $af: $!";
3400 }
3401
3402 sub setup_new_tree () {
3403     setup_mergechangelogs();
3404     setup_useremail();
3405     setup_gitattrs();
3406 }
3407
3408 sub check_gitattrs ($$) {
3409     my ($treeish, $what) = @_;
3410
3411     return if is_gitattrs_setup;
3412
3413     local $/="\0";
3414     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3415     debugcmd "|",@cmd;
3416     my $gafl = new IO::File;
3417     open $gafl, "-|", @cmd or die $!;
3418     while (<$gafl>) {
3419         chomp or die;
3420         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3421         next if $1 == 0;
3422         next unless m{(?:^|/)\.gitattributes$};
3423
3424         # oh dear, found one
3425         print STDERR <<END;
3426 dgit: warning: $what contains .gitattributes
3427 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3428 END
3429         close $gafl;
3430         return;
3431     }
3432     # tree contains no .gitattributes files
3433     $?=0; $!=0; close $gafl or failedcmd @cmd;
3434 }
3435
3436
3437 sub multisuite_suite_child ($$$) {
3438     my ($tsuite, $mergeinputs, $fn) = @_;
3439     # in child, sets things up, calls $fn->(), and returns undef
3440     # in parent, returns canonical suite name for $tsuite
3441     my $canonsuitefh = IO::File::new_tmpfile;
3442     my $pid = fork // die $!;
3443     if (!$pid) {
3444         forkcheck_setup();
3445         $isuite = $tsuite;
3446         $us .= " [$isuite]";
3447         $debugprefix .= " ";
3448         progress "fetching $tsuite...";
3449         canonicalise_suite();
3450         print $canonsuitefh $csuite, "\n" or die $!;
3451         close $canonsuitefh or die $!;
3452         $fn->();
3453         return undef;
3454     }
3455     waitpid $pid,0 == $pid or die $!;
3456     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3457     seek $canonsuitefh,0,0 or die $!;
3458     local $csuite = <$canonsuitefh>;
3459     die $! unless defined $csuite && chomp $csuite;
3460     if ($? == 256*4) {
3461         printdebug "multisuite $tsuite missing\n";
3462         return $csuite;
3463     }
3464     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3465     push @$mergeinputs, {
3466         Ref => lrref,
3467         Info => $csuite,
3468     };
3469     return $csuite;
3470 }
3471
3472 sub fork_for_multisuite ($) {
3473     my ($before_fetch_merge) = @_;
3474     # if nothing unusual, just returns ''
3475     #
3476     # if multisuite:
3477     # returns 0 to caller in child, to do first of the specified suites
3478     # in child, $csuite is not yet set
3479     #
3480     # returns 1 to caller in parent, to finish up anything needed after
3481     # in parent, $csuite is set to canonicalised portmanteau
3482
3483     my $org_isuite = $isuite;
3484     my @suites = split /\,/, $isuite;
3485     return '' unless @suites > 1;
3486     printdebug "fork_for_multisuite: @suites\n";
3487
3488     my @mergeinputs;
3489
3490     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3491                                             sub { });
3492     return 0 unless defined $cbasesuite;
3493
3494     fail "package $package missing in (base suite) $cbasesuite"
3495         unless @mergeinputs;
3496
3497     my @csuites = ($cbasesuite);
3498
3499     $before_fetch_merge->();
3500
3501     foreach my $tsuite (@suites[1..$#suites]) {
3502         $tsuite =~ s/^-/$cbasesuite-/;
3503         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3504                                                sub {
3505             @end = ();
3506             fetch_one();
3507             finish 0;
3508         });
3509
3510         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3511         push @csuites, $csubsuite;
3512     }
3513
3514     foreach my $mi (@mergeinputs) {
3515         my $ref = git_get_ref $mi->{Ref};
3516         die "$mi->{Ref} ?" unless length $ref;
3517         $mi->{Commit} = $ref;
3518     }
3519
3520     $csuite = join ",", @csuites;
3521
3522     my $previous = git_get_ref lrref;
3523     if ($previous) {
3524         unshift @mergeinputs, {
3525             Commit => $previous,
3526             Info => "local combined tracking branch",
3527             Warning =>
3528  "archive seems to have rewound: local tracking branch is ahead!",
3529         };
3530     }
3531
3532     foreach my $ix (0..$#mergeinputs) {
3533         $mergeinputs[$ix]{Index} = $ix;
3534     }
3535
3536     @mergeinputs = sort {
3537         -version_compare(mergeinfo_version $a,
3538                          mergeinfo_version $b) # highest version first
3539             or
3540         $a->{Index} <=> $b->{Index}; # earliest in spec first
3541     } @mergeinputs;
3542
3543     my @needed;
3544
3545   NEEDED:
3546     foreach my $mi (@mergeinputs) {
3547         printdebug "multisuite merge check $mi->{Info}\n";
3548         foreach my $previous (@needed) {
3549             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3550             printdebug "multisuite merge un-needed $previous->{Info}\n";
3551             next NEEDED;
3552         }
3553         push @needed, $mi;
3554         printdebug "multisuite merge this-needed\n";
3555         $mi->{Character} = '+';
3556     }
3557
3558     $needed[0]{Character} = '*';
3559
3560     my $output = $needed[0]{Commit};
3561
3562     if (@needed > 1) {
3563         printdebug "multisuite merge nontrivial\n";
3564         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3565
3566         my $commit = "tree $tree\n";
3567         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3568             "Input branches:\n";
3569
3570         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3571             printdebug "multisuite merge include $mi->{Info}\n";
3572             $mi->{Character} //= ' ';
3573             $commit .= "parent $mi->{Commit}\n";
3574             $msg .= sprintf " %s  %-25s %s\n",
3575                 $mi->{Character},
3576                 (mergeinfo_version $mi),
3577                 $mi->{Info};
3578         }
3579         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3580         $msg .= "\nKey\n".
3581             " * marks the highest version branch, which choose to use\n".
3582             " + marks each branch which was not already an ancestor\n\n".
3583             "[dgit multi-suite $csuite]\n";
3584         $commit .=
3585             "author $authline\n".
3586             "committer $authline\n\n";
3587         $output = make_commit_text $commit.$msg;
3588         printdebug "multisuite merge generated $output\n";
3589     }
3590
3591     fetch_from_archive_record_1($output);
3592     fetch_from_archive_record_2($output);
3593
3594     progress "calculated combined tracking suite $csuite";
3595
3596     return 1;
3597 }
3598
3599 sub clone_set_head () {
3600     open H, "> .git/HEAD" or die $!;
3601     print H "ref: ".lref()."\n" or die $!;
3602     close H or die $!;
3603 }
3604 sub clone_finish ($) {
3605     my ($dstdir) = @_;
3606     runcmd @git, qw(reset --hard), lrref();
3607     runcmd qw(bash -ec), <<'END';
3608         set -o pipefail
3609         git ls-tree -r --name-only -z HEAD | \
3610         xargs -0r touch -h -r . --
3611 END
3612     printdone "ready for work in $dstdir";
3613 }
3614
3615 sub clone ($) {
3616     # in multisuite, returns twice!
3617     # once in parent after first suite fetched,
3618     # and then again in child after everything is finished
3619     my ($dstdir) = @_;
3620     badusage "dry run makes no sense with clone" unless act_local();
3621
3622     my $multi_fetched = fork_for_multisuite(sub {
3623         printdebug "multi clone before fetch merge\n";
3624         changedir $dstdir;
3625         record_maindir();
3626     });
3627     if ($multi_fetched) {
3628         printdebug "multi clone after fetch merge\n";
3629         clone_set_head();
3630         clone_finish($dstdir);
3631         return;
3632     }
3633     printdebug "clone main body\n";
3634
3635     canonicalise_suite();
3636     my $hasgit = check_for_git();
3637     mkdir $dstdir or fail "create \`$dstdir': $!";
3638     changedir $dstdir;
3639     runcmd @git, qw(init -q);
3640     record_maindir();
3641     setup_new_tree();
3642     clone_set_head();
3643     my $giturl = access_giturl(1);
3644     if (defined $giturl) {
3645         runcmd @git, qw(remote add), 'origin', $giturl;
3646     }
3647     if ($hasgit) {
3648         progress "fetching existing git history";
3649         git_fetch_us();
3650         runcmd_ordryrun_local @git, qw(fetch origin);
3651     } else {
3652         progress "starting new git history";
3653     }
3654     fetch_from_archive() or no_such_package;
3655     my $vcsgiturl = $dsc->{'Vcs-Git'};
3656     if (length $vcsgiturl) {
3657         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3658         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3659     }
3660     clone_finish($dstdir);
3661 }
3662
3663 sub fetch_one () {
3664     canonicalise_suite();
3665     if (check_for_git()) {
3666         git_fetch_us();
3667     }
3668     fetch_from_archive() or no_such_package();
3669     
3670     my $vcsgiturl = $dsc && $dsc->{'Vcs-Git'};
3671     if (length $vcsgiturl and
3672         (grep { $csuite eq $_ }
3673          split /\;/,
3674          cfg 'dgit.vcs-git.suites')) {
3675         my $current = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
3676         if (defined $current && $current ne $vcsgiturl) {
3677             print STDERR <<END;
3678 FYI: Vcs-Git in $csuite has different url to your vcs-git remote.
3679  Your vcs-git remote url may be out of date.  Use dgit update-vcs-git ?
3680 END
3681         }
3682     }
3683     printdone "fetched into ".lrref();
3684 }
3685
3686 sub dofetch () {
3687     my $multi_fetched = fork_for_multisuite(sub { });
3688     fetch_one() unless $multi_fetched; # parent
3689     finish 0 if $multi_fetched eq '0'; # child
3690 }
3691
3692 sub pull () {
3693     dofetch();
3694     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3695         lrref();
3696     printdone "fetched to ".lrref()." and merged into HEAD";
3697 }
3698
3699 sub check_not_dirty () {
3700     foreach my $f (qw(local-options local-patch-header)) {
3701         if (stat_exists "debian/source/$f") {
3702             fail "git tree contains debian/source/$f";
3703         }
3704     }
3705
3706     return if $includedirty;
3707
3708     git_check_unmodified();
3709 }
3710
3711 sub commit_admin ($) {
3712     my ($m) = @_;