chiark / gitweb /
Test suite: Move t-reporefs into lib
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013 Ian Jackson
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20 use strict;
21 $SIG{__WARN__} = sub { die $_[0]; };
22
23 use IO::Handle;
24 use Data::Dumper;
25 use LWP::UserAgent;
26 use Dpkg::Control::Hash;
27 use File::Path;
28 use File::Temp qw(tempdir);
29 use File::Basename;
30 use Dpkg::Version;
31 use POSIX;
32 use IPC::Open2;
33 use Digest::SHA;
34 use Digest::MD5;
35
36 use Debian::Dgit;
37
38 our $our_version = 'UNRELEASED'; ###substituted###
39
40 our $rpushprotovsn = 2;
41
42 our $isuite = 'unstable';
43 our $idistro;
44 our $package;
45 our @ropts;
46
47 our $sign = 1;
48 our $dryrun_level = 0;
49 our $changesfile;
50 our $buildproductsdir = '..';
51 our $new_package = 0;
52 our $ignoredirty = 0;
53 our $rmonerror = 1;
54 our @deliberatelies;
55 our %previously;
56 our $existing_package = 'dpkg';
57 our $cleanmode = 'dpkg-source';
58 our $changes_since_version;
59 our $quilt_mode;
60 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
61 our $we_are_responder;
62 our $initiator_tempdir;
63
64 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
65
66 our $suite_re = '[-+.0-9a-z]+';
67
68 our (@git) = qw(git);
69 our (@dget) = qw(dget);
70 our (@curl) = qw(curl -f);
71 our (@dput) = qw(dput);
72 our (@debsign) = qw(debsign);
73 our (@gpg) = qw(gpg);
74 our (@sbuild) = qw(sbuild -A);
75 our (@ssh) = 'ssh';
76 our (@dgit) = qw(dgit);
77 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
78 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
79 our (@dpkggenchanges) = qw(dpkg-genchanges);
80 our (@mergechanges) = qw(mergechanges -f);
81 our (@changesopts) = ('');
82
83 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
84                      'curl' => \@curl,
85                      'dput' => \@dput,
86                      'debsign' => \@debsign,
87                      'gpg' => \@gpg,
88                      'sbuild' => \@sbuild,
89                      'ssh' => \@ssh,
90                      'dgit' => \@dgit,
91                      'dpkg-source' => \@dpkgsource,
92                      'dpkg-buildpackage' => \@dpkgbuildpackage,
93                      'dpkg-genchanges' => \@dpkggenchanges,
94                      'ch' => \@changesopts,
95                      'mergechanges' => \@mergechanges);
96
97 our %opts_opt_cmdonly = ('gpg' => 1);
98
99 our $keyid;
100
101 autoflush STDOUT 1;
102
103 our $remotename = 'dgit';
104 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
105 our $csuite;
106 our $instead_distro;
107
108 sub lbranch () { return "$branchprefix/$csuite"; }
109 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
110 sub lref () { return "refs/heads/".lbranch(); }
111 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
112 sub rrref () { return server_ref($csuite); }
113
114 sub lrfetchrefs () { return "refs/dgit-fetch/$isuite"; }
115
116 sub stripepoch ($) {
117     my ($vsn) = @_;
118     $vsn =~ s/^\d+\://;
119     return $vsn;
120 }
121
122 sub srcfn ($$) {
123     my ($vsn,$sfx) = @_;
124     return "${package}_".(stripepoch $vsn).$sfx
125 }
126
127 sub dscfn ($) {
128     my ($vsn) = @_;
129     return srcfn($vsn,".dsc");
130 }
131
132 our $us = 'dgit';
133 initdebug('');
134
135 our @end;
136 END { 
137     local ($?);
138     foreach my $f (@end) {
139         eval { $f->(); };
140         warn "$us: cleanup: $@" if length $@;
141     }
142 };
143
144 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
145
146 sub no_such_package () {
147     print STDERR "$us: package $package does not exist in suite $isuite\n";
148     exit 4;
149 }
150
151 sub fetchspec () {
152     local $csuite = '*';
153     return  "+".rrref().":".lrref();
154 }
155
156 sub changedir ($) {
157     my ($newdir) = @_;
158     printdebug "CD $newdir\n";
159     chdir $newdir or die "chdir: $newdir: $!";
160 }
161
162 sub deliberately ($) {
163     my ($enquiry) = @_;
164     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
165 }
166
167 sub deliberately_not_fast_forward () {
168     foreach (qw(not-fast-forward fresh-repo)) {
169         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
170     }
171 }
172
173 #---------- remote protocol support, common ----------
174
175 # remote push initiator/responder protocol:
176 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
177 #
178 #  > file parsed-changelog
179 #  [indicates that output of dpkg-parsechangelog follows]
180 #  > data-block NBYTES
181 #  > [NBYTES bytes of data (no newline)]
182 #  [maybe some more blocks]
183 #  > data-end
184 #
185 #  > file dsc
186 #  [etc]
187 #
188 #  > file changes
189 #  [etc]
190 #
191 #  > param head HEAD
192 #
193 #  > want signed-tag
194 #  [indicates that signed tag is wanted]
195 #  < data-block NBYTES
196 #  < [NBYTES bytes of data (no newline)]
197 #  [maybe some more blocks]
198 #  < data-end
199 #  < files-end
200 #
201 #  > want signed-dsc-changes
202 #  < data-block NBYTES    [transfer of signed dsc]
203 #  [etc]
204 #  < data-block NBYTES    [transfer of signed changes]
205 #  [etc]
206 #  < files-end
207 #
208 #  > complete
209
210 our $i_child_pid;
211
212 sub i_child_report () {
213     # Sees if our child has died, and reap it if so.  Returns a string
214     # describing how it died if it failed, or undef otherwise.
215     return undef unless $i_child_pid;
216     my $got = waitpid $i_child_pid, WNOHANG;
217     return undef if $got <= 0;
218     die unless $got == $i_child_pid;
219     $i_child_pid = undef;
220     return undef unless $?;
221     return "build host child ".waitstatusmsg();
222 }
223
224 sub badproto ($$) {
225     my ($fh, $m) = @_;
226     fail "connection lost: $!" if $fh->error;
227     fail "protocol violation; $m not expected";
228 }
229
230 sub badproto_badread ($$) {
231     my ($fh, $wh) = @_;
232     fail "connection lost: $!" if $!;
233     my $report = i_child_report();
234     fail $report if defined $report;
235     badproto $fh, "eof (reading $wh)";
236 }
237
238 sub protocol_expect (&$) {
239     my ($match, $fh) = @_;
240     local $_;
241     $_ = <$fh>;
242     defined && chomp or badproto_badread $fh, "protocol message";
243     if (wantarray) {
244         my @r = &$match;
245         return @r if @r;
246     } else {
247         my $r = &$match;
248         return $r if $r;
249     }
250     badproto $fh, "\`$_'";
251 }
252
253 sub protocol_send_file ($$) {
254     my ($fh, $ourfn) = @_;
255     open PF, "<", $ourfn or die "$ourfn: $!";
256     for (;;) {
257         my $d;
258         my $got = read PF, $d, 65536;
259         die "$ourfn: $!" unless defined $got;
260         last if !$got;
261         print $fh "data-block ".length($d)."\n" or die $!;
262         print $fh $d or die $!;
263     }
264     PF->error and die "$ourfn $!";
265     print $fh "data-end\n" or die $!;
266     close PF;
267 }
268
269 sub protocol_read_bytes ($$) {
270     my ($fh, $nbytes) = @_;
271     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
272     my $d;
273     my $got = read $fh, $d, $nbytes;
274     $got==$nbytes or badproto_badread $fh, "data block";
275     return $d;
276 }
277
278 sub protocol_receive_file ($$) {
279     my ($fh, $ourfn) = @_;
280     printdebug "() $ourfn\n";
281     open PF, ">", $ourfn or die "$ourfn: $!";
282     for (;;) {
283         my ($y,$l) = protocol_expect {
284             m/^data-block (.*)$/ ? (1,$1) :
285             m/^data-end$/ ? (0,) :
286             ();
287         } $fh;
288         last unless $y;
289         my $d = protocol_read_bytes $fh, $l;
290         print PF $d or die $!;
291     }
292     close PF or die $!;
293 }
294
295 #---------- remote protocol support, responder ----------
296
297 sub responder_send_command ($) {
298     my ($command) = @_;
299     return unless $we_are_responder;
300     # called even without $we_are_responder
301     printdebug ">> $command\n";
302     print PO $command, "\n" or die $!;
303 }    
304
305 sub responder_send_file ($$) {
306     my ($keyword, $ourfn) = @_;
307     return unless $we_are_responder;
308     printdebug "]] $keyword $ourfn\n";
309     responder_send_command "file $keyword";
310     protocol_send_file \*PO, $ourfn;
311 }
312
313 sub responder_receive_files ($@) {
314     my ($keyword, @ourfns) = @_;
315     die unless $we_are_responder;
316     printdebug "[[ $keyword @ourfns\n";
317     responder_send_command "want $keyword";
318     foreach my $fn (@ourfns) {
319         protocol_receive_file \*PI, $fn;
320     }
321     printdebug "[[\$\n";
322     protocol_expect { m/^files-end$/ } \*PI;
323 }
324
325 #---------- remote protocol support, initiator ----------
326
327 sub initiator_expect (&) {
328     my ($match) = @_;
329     protocol_expect { &$match } \*RO;
330 }
331
332 #---------- end remote code ----------
333
334 sub progress {
335     if ($we_are_responder) {
336         my $m = join '', @_;
337         responder_send_command "progress ".length($m) or die $!;
338         print PO $m or die $!;
339     } else {
340         print @_, "\n";
341     }
342 }
343
344 our $ua;
345
346 sub url_get {
347     if (!$ua) {
348         $ua = LWP::UserAgent->new();
349         $ua->env_proxy;
350     }
351     my $what = $_[$#_];
352     progress "downloading $what...";
353     my $r = $ua->get(@_) or die $!;
354     return undef if $r->code == 404;
355     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
356     return $r->decoded_content(charset => 'none');
357 }
358
359 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
360
361 sub runcmd {
362     debugcmd "+",@_;
363     $!=0; $?=0;
364     failedcmd @_ if system @_;
365 }
366
367 sub act_local () { return $dryrun_level <= 1; }
368 sub act_scary () { return !$dryrun_level; }
369
370 sub printdone {
371     if (!$dryrun_level) {
372         progress "dgit ok: @_";
373     } else {
374         progress "would be ok: @_ (but dry run only)";
375     }
376 }
377
378 sub dryrun_report {
379     printcmd(\*STDERR,$debugprefix."#",@_);
380 }
381
382 sub runcmd_ordryrun {
383     if (act_scary()) {
384         runcmd @_;
385     } else {
386         dryrun_report @_;
387     }
388 }
389
390 sub runcmd_ordryrun_local {
391     if (act_local()) {
392         runcmd @_;
393     } else {
394         dryrun_report @_;
395     }
396 }
397
398 sub shell_cmd {
399     my ($first_shell, @cmd) = @_;
400     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
401 }
402
403 our $helpmsg = <<END;
404 main usages:
405   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
406   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
407   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
408   dgit [dgit-opts] push [dgit-opts] [suite]
409   dgit [dgit-opts] rpush build-host:build-dir ...
410 important dgit options:
411   -k<keyid>           sign tag and package with <keyid> instead of default
412   --dry-run -n        do not change anything, but go through the motions
413   --damp-run -L       like --dry-run but make local changes, without signing
414   --new -N            allow introducing a new package
415   --debug -D          increase debug level
416   -c<name>=<value>    set git config option (used directly by dgit too)
417 END
418
419 our $later_warning_msg = <<END;
420 Perhaps the upload is stuck in incoming.  Using the version from git.
421 END
422
423 sub badusage {
424     print STDERR "$us: @_\n", $helpmsg or die $!;
425     exit 8;
426 }
427
428 sub nextarg {
429     @ARGV or badusage "too few arguments";
430     return scalar shift @ARGV;
431 }
432
433 sub cmd_help () {
434     print $helpmsg or die $!;
435     exit 0;
436 }
437
438 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
439
440 our %defcfg = ('dgit.default.distro' => 'debian',
441                'dgit.default.username' => '',
442                'dgit.default.archive-query-default-component' => 'main',
443                'dgit.default.ssh' => 'ssh',
444                'dgit.default.archive-query' => 'madison:',
445                'dgit.default.sshpsql-dbname' => 'service=projectb',
446                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
447                'dgit-distro.debian.git-host' => 'dgit-git.debian.net',
448                'dgit-distro.debian.git-user-force' => 'dgit',
449                'dgit-distro.debian.git-proto' => 'git+ssh://',
450                'dgit-distro.debian.git-path' => '/dgit/debian/repos',
451                'dgit-distro.debian.git-check' => 'ssh-cmd',
452  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
453  'dgit-distro.debian.archive-query-tls-key',
454     '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
455                'dgit-distro.debian.diverts.alioth' => '/alioth',
456                'dgit-distro.debian/alioth.git-host' => 'git.debian.org',
457                'dgit-distro.debian/alioth.git-user-force' => '',
458                'dgit-distro.debian/alioth.git-proto' => 'git+ssh://',
459                'dgit-distro.debian/alioth.git-path' => '/git/dgit-repos/repos',
460                'dgit-distro.debian/alioth.git-create' => 'ssh-cmd',
461                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
462                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
463  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
464  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
465                'dgit-distro.ubuntu.git-check' => 'false',
466  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
467                'dgit-distro.test-dummy.ssh' => "$td/ssh",
468                'dgit-distro.test-dummy.username' => "alice",
469                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
470                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
471                'dgit-distro.test-dummy.git-url' => "$td/git",
472                'dgit-distro.test-dummy.git-host' => "git",
473                'dgit-distro.test-dummy.git-path' => "$td/git",
474                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
475                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
476                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
477                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
478                );
479
480 sub cfg {
481     foreach my $c (@_) {
482         return undef if $c =~ /RETURN-UNDEF/;
483         my @cmd = (@git, qw(config --), $c);
484         my $v;
485         {
486             local ($debuglevel) = $debuglevel-2;
487             $v = cmdoutput_errok @cmd;
488         };
489         if ($?==0) {
490             return $v;
491         } elsif ($?!=256) {
492             failedcmd @cmd;
493         }
494         my $dv = $defcfg{$c};
495         return $dv if defined $dv;
496     }
497     badcfg "need value for one of: @_\n".
498         "$us: distro or suite appears not to be (properly) supported";
499 }
500
501 sub access_basedistro () {
502     if (defined $idistro) {
503         return $idistro;
504     } else {    
505         return cfg("dgit-suite.$isuite.distro",
506                    "dgit.default.distro");
507     }
508 }
509
510 sub access_quirk () {
511     # returns (quirk name, distro to use instead or undef, quirk-specific info)
512     my $basedistro = access_basedistro();
513     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
514                               'RETURN-UNDEF');
515     if (defined $backports_quirk) {
516         my $re = $backports_quirk;
517         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
518         $re =~ s/\*/.*/g;
519         $re =~ s/\%/([-0-9a-z_]+)/
520             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
521         if ($isuite =~ m/^$re$/) {
522             return ('backports',"$basedistro-backports",$1);
523         }
524     }
525     return ('none',undef);
526 }
527
528 sub access_distros () {
529     # Returns list of distros to try, in order
530     #
531     # We want to try:
532     #    0. `instead of' distro name(s) we have been pointed to
533     #    1. the access_quirk distro, if any
534     #    2a. the user's specified distro, or failing that  } basedistro
535     #    2b. the distro calculated from the suite          }
536     my @l = access_basedistro();
537
538     my (undef,$quirkdistro) = access_quirk();
539     unshift @l, $quirkdistro;
540     unshift @l, $instead_distro;
541     return grep { defined } @l;
542 }
543
544 sub access_cfg (@) {
545     my (@keys) = @_;
546     my @cfgs;
547     # The nesting of these loops determines the search order.  We put
548     # the key loop on the outside so that we search all the distros
549     # for each key, before going on to the next key.  That means that
550     # if access_cfg is called with a more specific, and then a less
551     # specific, key, an earlier distro can override the less specific
552     # without necessarily overriding any more specific keys.  (If the
553     # distro wants to override the more specific keys it can simply do
554     # so; whereas if we did the loop the other way around, it would be
555     # impossible to for an earlier distro to override a less specific
556     # key but not the more specific ones without restating the unknown
557     # values of the more specific keys.
558     my @realkeys;
559     my @rundef;
560     # We have to deal with RETURN-UNDEF specially, so that we don't
561     # terminate the search prematurely.
562     foreach (@keys) {
563         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
564         push @realkeys, $_
565     }
566     foreach my $d (access_distros()) {
567         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
568     }
569     push @cfgs, map { "dgit.default.$_" } @realkeys;
570     push @cfgs, @rundef;
571     my $value = cfg(@cfgs);
572     return $value;
573 }
574
575 sub string_to_ssh ($) {
576     my ($spec) = @_;
577     if ($spec =~ m/\s/) {
578         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
579     } else {
580         return ($spec);
581     }
582 }
583
584 sub access_cfg_ssh () {
585     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
586     if (!defined $gitssh) {
587         return @ssh;
588     } else {
589         return string_to_ssh $gitssh;
590     }
591 }
592
593 sub access_runeinfo ($) {
594     my ($info) = @_;
595     return ": dgit ".access_basedistro()." $info ;";
596 }
597
598 sub access_someuserhost ($) {
599     my ($some) = @_;
600     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
601     defined($user) && length($user) or
602         $user = access_cfg("$some-user",'username');
603     my $host = access_cfg("$some-host");
604     return length($user) ? "$user\@$host" : $host;
605 }
606
607 sub access_gituserhost () {
608     return access_someuserhost('git');
609 }
610
611 sub access_giturl (;$) {
612     my ($optional) = @_;
613     my $url = access_cfg('git-url','RETURN-UNDEF');
614     if (!defined $url) {
615         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
616         return undef unless defined $proto;
617         $url =
618             $proto.
619             access_gituserhost().
620             access_cfg('git-path');
621     }
622     return "$url/$package.git";
623 }              
624
625 sub parsecontrolfh ($$;$) {
626     my ($fh, $desc, $allowsigned) = @_;
627     our $dpkgcontrolhash_noissigned;
628     my $c;
629     for (;;) {
630         my %opts = ('name' => $desc);
631         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
632         $c = Dpkg::Control::Hash->new(%opts);
633         $c->parse($fh,$desc) or die "parsing of $desc failed";
634         last if $allowsigned;
635         last if $dpkgcontrolhash_noissigned;
636         my $issigned= $c->get_option('is_pgp_signed');
637         if (!defined $issigned) {
638             $dpkgcontrolhash_noissigned= 1;
639             seek $fh, 0,0 or die "seek $desc: $!";
640         } elsif ($issigned) {
641             fail "control file $desc is (already) PGP-signed. ".
642                 " Note that dgit push needs to modify the .dsc and then".
643                 " do the signature itself";
644         } else {
645             last;
646         }
647     }
648     return $c;
649 }
650
651 sub parsecontrol {
652     my ($file, $desc) = @_;
653     my $fh = new IO::Handle;
654     open $fh, '<', $file or die "$file: $!";
655     my $c = parsecontrolfh($fh,$desc);
656     $fh->error and die $!;
657     close $fh;
658     return $c;
659 }
660
661 sub getfield ($$) {
662     my ($dctrl,$field) = @_;
663     my $v = $dctrl->{$field};
664     return $v if defined $v;
665     fail "missing field $field in ".$v->get_option('name');
666 }
667
668 sub parsechangelog {
669     my $c = Dpkg::Control::Hash->new();
670     my $p = new IO::Handle;
671     my @cmd = (qw(dpkg-parsechangelog), @_);
672     open $p, '-|', @cmd or die $!;
673     $c->parse($p);
674     $?=0; $!=0; close $p or failedcmd @cmd;
675     return $c;
676 }
677
678 sub must_getcwd () {
679     my $d = getcwd();
680     defined $d or fail "getcwd failed: $!";
681     return $d;
682 }
683
684 our %rmad;
685
686 sub archive_query ($) {
687     my ($method) = @_;
688     my $query = access_cfg('archive-query','RETURN-UNDEF');
689     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
690     my $proto = $1;
691     my $data = $'; #';
692     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
693 }
694
695 sub pool_dsc_subpath ($$) {
696     my ($vsn,$component) = @_; # $package is implict arg
697     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
698     return "/pool/$component/$prefix/$package/".dscfn($vsn);
699 }
700
701 #---------- `ftpmasterapi' archive query method (nascent) ----------
702
703 sub archive_api_query_cmd ($) {
704     my ($subpath) = @_;
705     my @cmd = qw(curl -sS);
706     my $url = access_cfg('archive-query-url');
707     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
708         my $host = $1;
709         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF');
710         foreach my $key (split /\:/, $keys) {
711             $key =~ s/\%HOST\%/$host/g;
712             if (!stat $key) {
713                 fail "for $url: stat $key: $!" unless $!==ENOENT;
714                 next;
715             }
716             push @cmd, "--ca-certificate=$key", "--ca-directory=/dev/enoent";
717             last;
718         }
719     }
720     push @cmd, $url.$subpath;
721     return @cmd;
722 }
723
724 sub api_query ($$) {
725     use JSON;
726     my ($data, $subpath) = @_;
727     badcfg "ftpmasterapi archive query method takes no data part"
728         if length $data;
729     my @cmd = archive_api_query_cmd($subpath);
730     my $json = cmdoutput @cmd;
731     return decode_json($json);
732 }
733
734 sub canonicalise_suite_ftpmasterapi () {
735     my ($proto,$data) = @_;
736     my $suites = api_query($data, 'suites');
737     my @matched;
738     foreach my $entry (@$suites) {
739         next unless grep { 
740             my $v = $entry->{$_};
741             defined $v && $v eq $isuite;
742         } qw(codename name);
743         push @matched, $entry;
744     }
745     fail "unknown suite $isuite" unless @matched;
746     my $cn;
747     eval {
748         @matched==1 or die "multiple matches for suite $isuite\n";
749         $cn = "$matched[0]{codename}";
750         defined $cn or die "suite $isuite info has no codename\n";
751         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
752     };
753     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
754         if length $@;
755     return $cn;
756 }
757
758 sub archive_query_ftpmasterapi () {
759     my ($proto,$data) = @_;
760     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
761     my @rows;
762     my $digester = Digest::SHA->new(256);
763     foreach my $entry (@$info) {
764         eval {
765             my $vsn = "$entry->{version}";
766             my ($ok,$msg) = version_check $vsn;
767             die "bad version: $msg\n" unless $ok;
768             my $component = "$entry->{component}";
769             $component =~ m/^$component_re$/ or die "bad component";
770             my $filename = "$entry->{filename}";
771             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
772                 or die "bad filename";
773             my $sha256sum = "$entry->{sha256sum}";
774             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
775             push @rows, [ $vsn, "/pool/$component/$filename",
776                           $digester, $sha256sum ];
777         };
778         die "bad ftpmaster api response: $@\n".Dumper($entry)
779             if length $@;
780     }
781     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
782     return @rows;
783 }
784
785 #---------- `madison' archive query method ----------
786
787 sub archive_query_madison {
788     return map { [ @$_[0..1] ] } madison_get_parse(@_);
789 }
790
791 sub madison_get_parse {
792     my ($proto,$data) = @_;
793     die unless $proto eq 'madison';
794     if (!length $data) {
795         $data= access_cfg('madison-distro','RETURN-UNDEF');
796         $data //= access_basedistro();
797     }
798     $rmad{$proto,$data,$package} ||= cmdoutput
799         qw(rmadison -asource),"-s$isuite","-u$data",$package;
800     my $rmad = $rmad{$proto,$data,$package};
801
802     my @out;
803     foreach my $l (split /\n/, $rmad) {
804         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
805                   \s*( [^ \t|]+ )\s* \|
806                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
807                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
808         $1 eq $package or die "$rmad $package ?";
809         my $vsn = $2;
810         my $newsuite = $3;
811         my $component;
812         if (defined $4) {
813             $component = $4;
814         } else {
815             $component = access_cfg('archive-query-default-component');
816         }
817         $5 eq 'source' or die "$rmad ?";
818         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
819     }
820     return sort { -version_compare($a->[0],$b->[0]); } @out;
821 }
822
823 sub canonicalise_suite_madison {
824     # madison canonicalises for us
825     my @r = madison_get_parse(@_);
826     @r or fail
827         "unable to canonicalise suite using package $package".
828         " which does not appear to exist in suite $isuite;".
829         " --existing-package may help";
830     return $r[0][2];
831 }
832
833 #---------- `sshpsql' archive query method ----------
834
835 sub sshpsql ($$$) {
836     my ($data,$runeinfo,$sql) = @_;
837     if (!length $data) {
838         $data= access_someuserhost('sshpsql').':'.
839             access_cfg('sshpsql-dbname');
840     }
841     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
842     my ($userhost,$dbname) = ($`,$'); #';
843     my @rows;
844     my @cmd = (access_cfg_ssh, $userhost,
845                access_runeinfo("ssh-psql $runeinfo").
846                " export LC_MESSAGES=C; export LC_CTYPE=C;".
847                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
848     debugcmd "|",@cmd;
849     open P, "-|", @cmd or die $!;
850     while (<P>) {
851         chomp or die;
852         printdebug("$debugprefix>|$_|\n");
853         push @rows, $_;
854     }
855     $!=0; $?=0; close P or failedcmd @cmd;
856     @rows or die;
857     my $nrows = pop @rows;
858     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
859     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
860     @rows = map { [ split /\|/, $_ ] } @rows;
861     my $ncols = scalar @{ shift @rows };
862     die if grep { scalar @$_ != $ncols } @rows;
863     return @rows;
864 }
865
866 sub sql_injection_check {
867     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
868 }
869
870 sub archive_query_sshpsql ($$) {
871     my ($proto,$data) = @_;
872     sql_injection_check $isuite, $package;
873     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
874         SELECT source.version, component.name, files.filename, files.sha256sum
875           FROM source
876           JOIN src_associations ON source.id = src_associations.source
877           JOIN suite ON suite.id = src_associations.suite
878           JOIN dsc_files ON dsc_files.source = source.id
879           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
880           JOIN component ON component.id = files_archive_map.component_id
881           JOIN files ON files.id = dsc_files.file
882          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
883            AND source.source='$package'
884            AND files.filename LIKE '%.dsc';
885 END
886     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
887     my $digester = Digest::SHA->new(256);
888     @rows = map {
889         my ($vsn,$component,$filename,$sha256sum) = @$_;
890         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
891     } @rows;
892     return @rows;
893 }
894
895 sub canonicalise_suite_sshpsql ($$) {
896     my ($proto,$data) = @_;
897     sql_injection_check $isuite;
898     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
899         SELECT suite.codename
900           FROM suite where suite_name='$isuite' or codename='$isuite';
901 END
902     @rows = map { $_->[0] } @rows;
903     fail "unknown suite $isuite" unless @rows;
904     die "ambiguous $isuite: @rows ?" if @rows>1;
905     return $rows[0];
906 }
907
908 #---------- `dummycat' archive query method ----------
909
910 sub canonicalise_suite_dummycat ($$) {
911     my ($proto,$data) = @_;
912     my $dpath = "$data/suite.$isuite";
913     if (!open C, "<", $dpath) {
914         $!==ENOENT or die "$dpath: $!";
915         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
916         return $isuite;
917     }
918     $!=0; $_ = <C>;
919     chomp or die "$dpath: $!";
920     close C;
921     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
922     return $_;
923 }
924
925 sub archive_query_dummycat ($$) {
926     my ($proto,$data) = @_;
927     canonicalise_suite();
928     my $dpath = "$data/package.$csuite.$package";
929     if (!open C, "<", $dpath) {
930         $!==ENOENT or die "$dpath: $!";
931         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
932         return ();
933     }
934     my @rows;
935     while (<C>) {
936         next if m/^\#/;
937         next unless m/\S/;
938         die unless chomp;
939         printdebug "dummycat query $csuite $package $dpath | $_\n";
940         my @row = split /\s+/, $_;
941         @row==2 or die "$dpath: $_ ?";
942         push @rows, \@row;
943     }
944     C->error and die "$dpath: $!";
945     close C;
946     return sort { -version_compare($a->[0],$b->[0]); } @rows;
947 }
948
949 #---------- archive query entrypoints and rest of program ----------
950
951 sub canonicalise_suite () {
952     return if defined $csuite;
953     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
954     $csuite = archive_query('canonicalise_suite');
955     if ($isuite ne $csuite) {
956         progress "canonical suite name for $isuite is $csuite";
957     }
958 }
959
960 sub get_archive_dsc () {
961     canonicalise_suite();
962     my @vsns = archive_query('archive_query');
963     foreach my $vinfo (@vsns) {
964         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
965         $dscurl = access_cfg('mirror').$subpath;
966         $dscdata = url_get($dscurl);
967         if (!$dscdata) {
968             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
969             next;
970         }
971         if ($digester) {
972             $digester->reset();
973             $digester->add($dscdata);
974             my $got = $digester->hexdigest();
975             $got eq $digest or
976                 fail "$dscurl has hash $got but".
977                     " archive told us to expect $digest";
978         }
979         my $dscfh = new IO::File \$dscdata, '<' or die $!;
980         printdebug Dumper($dscdata) if $debuglevel>1;
981         $dsc = parsecontrolfh($dscfh,$dscurl,1);
982         printdebug Dumper($dsc) if $debuglevel>1;
983         my $fmt = getfield $dsc, 'Format';
984         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
985         $dsc_checked = !!$digester;
986         return;
987     }
988     $dsc = undef;
989 }
990
991 sub check_for_git ();
992 sub check_for_git () {
993     # returns 0 or 1
994     my $how = access_cfg('git-check');
995     if ($how eq 'ssh-cmd') {
996         my @cmd =
997             (access_cfg_ssh, access_gituserhost(),
998              access_runeinfo("git-check $package").
999              " set -e; cd ".access_cfg('git-path').";".
1000              " if test -d $package.git; then echo 1; else echo 0; fi");
1001         my $r= cmdoutput @cmd;
1002         if ($r =~ m/^divert (\w+)$/) {
1003             my $divert=$1;
1004             my ($usedistro,) = access_distros();
1005             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1006             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1007             printdebug "diverting $divert so using distro $instead_distro\n";
1008             return check_for_git();
1009         }
1010         failedcmd @cmd unless $r =~ m/^[01]$/;
1011         return $r+0;
1012     } elsif ($how eq 'true') {
1013         return 1;
1014     } elsif ($how eq 'false') {
1015         return 0;
1016     } else {
1017         badcfg "unknown git-check \`$how'";
1018     }
1019 }
1020
1021 sub create_remote_git_repo () {
1022     my $how = access_cfg('git-create');
1023     if ($how eq 'ssh-cmd') {
1024         runcmd_ordryrun
1025             (access_cfg_ssh, access_gituserhost(),
1026              access_runeinfo("git-create $package").
1027              "set -e; cd ".access_cfg('git-path').";".
1028              " cp -a _template $package.git");
1029     } elsif ($how eq 'true') {
1030         # nothing to do
1031     } else {
1032         badcfg "unknown git-create \`$how'";
1033     }
1034 }
1035
1036 our ($dsc_hash,$lastpush_hash);
1037
1038 our $ud = '.git/dgit/unpack';
1039
1040 sub prep_ud () {
1041     rmtree($ud);
1042     mkpath '.git/dgit';
1043     mkdir $ud or die $!;
1044 }
1045
1046 sub mktree_in_ud_here () {
1047     runcmd qw(git init -q);
1048     rmtree('.git/objects');
1049     symlink '../../../../objects','.git/objects' or die $!;
1050 }
1051
1052 sub git_write_tree () {
1053     my $tree = cmdoutput @git, qw(write-tree);
1054     $tree =~ m/^\w+$/ or die "$tree ?";
1055     return $tree;
1056 }
1057
1058 sub mktree_in_ud_from_only_subdir () {
1059     # changes into the subdir
1060     my (@dirs) = <*/.>;
1061     die unless @dirs==1;
1062     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1063     my $dir = $1;
1064     changedir $dir;
1065     fail "source package contains .git directory" if stat_exists '.git';
1066     mktree_in_ud_here();
1067     my $format=get_source_format();
1068     if (madformat($format)) {
1069         rmtree '.pc';
1070     }
1071     runcmd @git, qw(add -Af);
1072     my $tree=git_write_tree();
1073     return ($tree,$dir);
1074 }
1075
1076 sub dsc_files_info () {
1077     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1078                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1079                        ['Files',           'Digest::MD5', 'new()']) {
1080         my ($fname, $module, $method) = @$csumi;
1081         my $field = $dsc->{$fname};
1082         next unless defined $field;
1083         eval "use $module; 1;" or die $@;
1084         my @out;
1085         foreach (split /\n/, $field) {
1086             next unless m/\S/;
1087             m/^(\w+) (\d+) (\S+)$/ or
1088                 fail "could not parse .dsc $fname line \`$_'";
1089             my $digester = eval "$module"."->$method;" or die $@;
1090             push @out, {
1091                 Hash => $1,
1092                 Bytes => $2,
1093                 Filename => $3,
1094                 Digester => $digester,
1095             };
1096         }
1097         return @out;
1098     }
1099     fail "missing any supported Checksums-* or Files field in ".
1100         $dsc->get_option('name');
1101 }
1102
1103 sub dsc_files () {
1104     map { $_->{Filename} } dsc_files_info();
1105 }
1106
1107 sub is_orig_file ($;$) {
1108     local ($_) = $_[0];
1109     my $base = $_[1];
1110     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1111     defined $base or return 1;
1112     return $` eq $base;
1113 }
1114
1115 sub make_commit ($) {
1116     my ($file) = @_;
1117     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1118 }
1119
1120 sub clogp_authline ($) {
1121     my ($clogp) = @_;
1122     my $author = getfield $clogp, 'Maintainer';
1123     $author =~ s#,.*##ms;
1124     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1125     my $authline = "$author $date";
1126     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1127         fail "unexpected commit author line format \`$authline'".
1128         " (was generated from changelog Maintainer field)";
1129     return $authline;
1130 }
1131
1132 sub generate_commit_from_dsc () {
1133     prep_ud();
1134     changedir $ud;
1135
1136     foreach my $fi (dsc_files_info()) {
1137         my $f = $fi->{Filename};
1138         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1139
1140         link "../../../$f", $f
1141             or $!==&ENOENT
1142             or die "$f $!";
1143
1144         complete_file_from_dsc('.', $fi);
1145
1146         if (is_orig_file($f)) {
1147             link $f, "../../../../$f"
1148                 or $!==&EEXIST
1149                 or die "$f $!";
1150         }
1151     }
1152
1153     my $dscfn = "$package.dsc";
1154
1155     open D, ">", $dscfn or die "$dscfn: $!";
1156     print D $dscdata or die "$dscfn: $!";
1157     close D or die "$dscfn: $!";
1158     my @cmd = qw(dpkg-source);
1159     push @cmd, '--no-check' if $dsc_checked;
1160     push @cmd, qw(-x --), $dscfn;
1161     runcmd @cmd;
1162
1163     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1164     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1165     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1166     my $authline = clogp_authline $clogp;
1167     my $changes = getfield $clogp, 'Changes';
1168     open C, ">../commit.tmp" or die $!;
1169     print C <<END or die $!;
1170 tree $tree
1171 author $authline
1172 committer $authline
1173
1174 $changes
1175
1176 # imported from the archive
1177 END
1178     close C or die $!;
1179     my $outputhash = make_commit qw(../commit.tmp);
1180     my $cversion = getfield $clogp, 'Version';
1181     progress "synthesised git commit from .dsc $cversion";
1182     if ($lastpush_hash) {
1183         runcmd @git, qw(reset --hard), $lastpush_hash;
1184         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1185         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1186         my $oversion = getfield $oldclogp, 'Version';
1187         my $vcmp =
1188             version_compare($oversion, $cversion);
1189         if ($vcmp < 0) {
1190             # git upload/ is earlier vsn than archive, use archive
1191             open C, ">../commit2.tmp" or die $!;
1192             print C <<END or die $!;
1193 tree $tree
1194 parent $lastpush_hash
1195 parent $outputhash
1196 author $authline
1197 committer $authline
1198
1199 Record $package ($cversion) in archive suite $csuite
1200 END
1201             $outputhash = make_commit qw(../commit2.tmp);
1202         } elsif ($vcmp > 0) {
1203             print STDERR <<END or die $!;
1204
1205 Version actually in archive:    $cversion (older)
1206 Last allegedly pushed/uploaded: $oversion (newer or same)
1207 $later_warning_msg
1208 END
1209             $outputhash = $lastpush_hash;
1210         } else {
1211             $outputhash = $lastpush_hash;
1212         }
1213     }
1214     changedir '../../../..';
1215     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1216             'DGIT_ARCHIVE', $outputhash;
1217     cmdoutput @git, qw(log -n2), $outputhash;
1218     # ... gives git a chance to complain if our commit is malformed
1219     rmtree($ud);
1220     return $outputhash;
1221 }
1222
1223 sub complete_file_from_dsc ($$) {
1224     our ($dstdir, $fi) = @_;
1225     # Ensures that we have, in $dir, the file $fi, with the correct
1226     # contents.  (Downloading it from alongside $dscurl if necessary.)
1227
1228     my $f = $fi->{Filename};
1229     my $tf = "$dstdir/$f";
1230     my $downloaded = 0;
1231
1232     if (stat_exists $tf) {
1233         progress "using existing $f";
1234     } else {
1235         my $furl = $dscurl;
1236         $furl =~ s{/[^/]+$}{};
1237         $furl .= "/$f";
1238         die "$f ?" unless $f =~ m/^${package}_/;
1239         die "$f ?" if $f =~ m#/#;
1240         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1241         next if !act_local();
1242         $downloaded = 1;
1243     }
1244
1245     open F, "<", "$tf" or die "$tf: $!";
1246     $fi->{Digester}->reset();
1247     $fi->{Digester}->addfile(*F);
1248     F->error and die $!;
1249     my $got = $fi->{Digester}->hexdigest();
1250     $got eq $fi->{Hash} or
1251         fail "file $f has hash $got but .dsc".
1252             " demands hash $fi->{Hash} ".
1253             ($downloaded ? "(got wrong file from archive!)"
1254              : "(perhaps you should delete this file?)");
1255 }
1256
1257 sub ensure_we_have_orig () {
1258     foreach my $fi (dsc_files_info()) {
1259         my $f = $fi->{Filename};
1260         next unless is_orig_file($f);
1261         complete_file_from_dsc('..', $fi);
1262     }
1263 }
1264
1265 sub git_fetch_us () {
1266     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1267     if (deliberately_not_fast_forward) {
1268         runcmd_ordryrun_local @git, qw(fetch -p), access_giturl(),
1269             map { "+refs/$_/*:".lrfetchrefs."/$_/*" }
1270             qw(tags heads);
1271     }
1272 }
1273
1274 sub fetch_from_archive () {
1275     # ensures that lrref() is what is actually in the archive,
1276     #  one way or another
1277     get_archive_dsc();
1278
1279     if ($dsc) {
1280         foreach my $field (@ourdscfield) {
1281             $dsc_hash = $dsc->{$field};
1282             last if defined $dsc_hash;
1283         }
1284         if (defined $dsc_hash) {
1285             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1286             $dsc_hash = $&;
1287             progress "last upload to archive specified git hash";
1288         } else {
1289             progress "last upload to archive has NO git hash";
1290         }
1291     } else {
1292         progress "no version available from the archive";
1293     }
1294
1295     $lastpush_hash = git_get_ref(lrref());
1296     printdebug "previous reference hash=$lastpush_hash\n";
1297     my $hash;
1298     if (defined $dsc_hash) {
1299         fail "missing remote git history even though dsc has hash -".
1300             " could not find ref ".lrref().
1301             " (should have been fetched from ".access_giturl()."#".rrref().")"
1302             unless $lastpush_hash;
1303         $hash = $dsc_hash;
1304         ensure_we_have_orig();
1305         if ($dsc_hash eq $lastpush_hash) {
1306         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1307             print STDERR <<END or die $!;
1308
1309 Git commit in archive is behind the last version allegedly pushed/uploaded.
1310 Commit referred to by archive:  $dsc_hash
1311 Last allegedly pushed/uploaded: $lastpush_hash
1312 $later_warning_msg
1313 END
1314             $hash = $lastpush_hash;
1315         } else {
1316             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1317                 "descendant of archive's .dsc hash ($dsc_hash)";
1318         }
1319     } elsif ($dsc) {
1320         $hash = generate_commit_from_dsc();
1321     } elsif ($lastpush_hash) {
1322         # only in git, not in the archive yet
1323         $hash = $lastpush_hash;
1324         print STDERR <<END or die $!;
1325
1326 Package not found in the archive, but has allegedly been pushed using dgit.
1327 $later_warning_msg
1328 END
1329     } else {
1330         printdebug "nothing found!\n";
1331         if (defined $skew_warning_vsn) {
1332             print STDERR <<END or die $!;
1333
1334 Warning: relevant archive skew detected.
1335 Archive allegedly contains $skew_warning_vsn
1336 But we were not able to obtain any version from the archive or git.
1337
1338 END
1339         }
1340         return 0;
1341     }
1342     printdebug "current hash=$hash\n";
1343     if ($lastpush_hash) {
1344         fail "not fast forward on last upload branch!".
1345             " (archive's version left in DGIT_ARCHIVE)"
1346             unless is_fast_fwd($lastpush_hash, $hash);
1347     }
1348     if (defined $skew_warning_vsn) {
1349         mkpath '.git/dgit';
1350         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1351         my $clogf = ".git/dgit/changelog.tmp";
1352         runcmd shell_cmd "exec >$clogf",
1353             @git, qw(cat-file blob), "$hash:debian/changelog";
1354         my $gotclogp = parsechangelog("-l$clogf");
1355         my $got_vsn = getfield $gotclogp, 'Version';
1356         printdebug "SKEW CHECK GOT $got_vsn\n";
1357         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1358             print STDERR <<END or die $!;
1359
1360 Warning: archive skew detected.  Using the available version:
1361 Archive allegedly contains    $skew_warning_vsn
1362 We were able to obtain only   $got_vsn
1363
1364 END
1365         }
1366     }
1367     if ($lastpush_hash ne $hash) {
1368         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1369         if (act_local()) {
1370             cmdoutput @upd_cmd;
1371         } else {
1372             dryrun_report @upd_cmd;
1373         }
1374     }
1375     return 1;
1376 }
1377
1378 sub clone ($) {
1379     my ($dstdir) = @_;
1380     canonicalise_suite();
1381     badusage "dry run makes no sense with clone" unless act_local();
1382     my $hasgit = check_for_git();
1383     mkdir $dstdir or die "$dstdir $!";
1384     changedir $dstdir;
1385     runcmd @git, qw(init -q);
1386     my $giturl = access_giturl(1);
1387     if (defined $giturl) {
1388         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1389         open H, "> .git/HEAD" or die $!;
1390         print H "ref: ".lref()."\n" or die $!;
1391         close H or die $!;
1392         runcmd @git, qw(remote add), 'origin', $giturl;
1393     }
1394     if ($hasgit) {
1395         progress "fetching existing git history";
1396         git_fetch_us();
1397         runcmd_ordryrun_local @git, qw(fetch origin);
1398     } else {
1399         progress "starting new git history";
1400     }
1401     fetch_from_archive() or no_such_package;
1402     my $vcsgiturl = $dsc->{'Vcs-Git'};
1403     if (length $vcsgiturl) {
1404         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1405         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1406     }
1407     runcmd @git, qw(reset --hard), lrref();
1408     printdone "ready for work in $dstdir";
1409 }
1410
1411 sub fetch () {
1412     if (check_for_git()) {
1413         git_fetch_us();
1414     }
1415     fetch_from_archive() or no_such_package();
1416     printdone "fetched into ".lrref();
1417 }
1418
1419 sub pull () {
1420     fetch();
1421     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1422         lrref();
1423     printdone "fetched to ".lrref()." and merged into HEAD";
1424 }
1425
1426 sub check_not_dirty () {
1427     return if $ignoredirty;
1428     my @cmd = (@git, qw(diff --quiet HEAD));
1429     debugcmd "+",@cmd;
1430     $!=0; $?=0; system @cmd;
1431     return if !$! && !$?;
1432     if (!$! && $?==256) {
1433         fail "working tree is dirty (does not match HEAD)";
1434     } else {
1435         failedcmd @cmd;
1436     }
1437 }
1438
1439 sub commit_admin ($) {
1440     my ($m) = @_;
1441     progress "$m";
1442     runcmd_ordryrun_local @git, qw(commit -m), $m;
1443 }
1444
1445 sub commit_quilty_patch () {
1446     my $output = cmdoutput @git, qw(status --porcelain);
1447     my %adds;
1448     foreach my $l (split /\n/, $output) {
1449         next unless $l =~ m/\S/;
1450         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1451             $adds{$1}++;
1452         }
1453     }
1454     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1455     if (!%adds) {
1456         progress "nothing quilty to commit, ok.";
1457         return;
1458     }
1459     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1460     commit_admin "Commit Debian 3.0 (quilt) metadata";
1461 }
1462
1463 sub get_source_format () {
1464     if (!open F, "debian/source/format") {
1465         die $! unless $!==&ENOENT;
1466         return '';
1467     }
1468     $_ = <F>;
1469     F->error and die $!;
1470     chomp;
1471     return $_;
1472 }
1473
1474 sub madformat ($) {
1475     my ($format) = @_;
1476     return 0 unless $format eq '3.0 (quilt)';
1477     if ($quilt_mode eq 'nocheck') {
1478         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1479         return 0;
1480     }
1481     progress "Format \`$format', checking/updating patch stack";
1482     return 1;
1483 }
1484
1485 sub push_parse_changelog ($) {
1486     my ($clogpfn) = @_;
1487
1488     my $clogp = Dpkg::Control::Hash->new();
1489     $clogp->load($clogpfn) or die;
1490
1491     $package = getfield $clogp, 'Source';
1492     my $cversion = getfield $clogp, 'Version';
1493     my $tag = debiantag($cversion);
1494     runcmd @git, qw(check-ref-format), $tag;
1495
1496     my $dscfn = dscfn($cversion);
1497
1498     return ($clogp, $cversion, $tag, $dscfn);
1499 }
1500
1501 sub push_parse_dsc ($$$) {
1502     my ($dscfn,$dscfnwhat, $cversion) = @_;
1503     $dsc = parsecontrol($dscfn,$dscfnwhat);
1504     my $dversion = getfield $dsc, 'Version';
1505     my $dscpackage = getfield $dsc, 'Source';
1506     ($dscpackage eq $package && $dversion eq $cversion) or
1507         fail "$dscfn is for $dscpackage $dversion".
1508             " but debian/changelog is for $package $cversion";
1509 }
1510
1511 sub push_mktag ($$$$$$$) {
1512     my ($head,$clogp,$tag,
1513         $dscfn,
1514         $changesfile,$changesfilewhat,
1515         $tfn) = @_;
1516
1517     $dsc->{$ourdscfield[0]} = $head;
1518     $dsc->save("$dscfn.tmp") or die $!;
1519
1520     my $changes = parsecontrol($changesfile,$changesfilewhat);
1521     foreach my $field (qw(Source Distribution Version)) {
1522         $changes->{$field} eq $clogp->{$field} or
1523             fail "changes field $field \`$changes->{$field}'".
1524                 " does not match changelog \`$clogp->{$field}'";
1525     }
1526
1527     my $cversion = getfield $clogp, 'Version';
1528     my $clogsuite = getfield $clogp, 'Distribution';
1529
1530     # We make the git tag by hand because (a) that makes it easier
1531     # to control the "tagger" (b) we can do remote signing
1532     my $authline = clogp_authline $clogp;
1533     my $delibs = join(" ", "",@deliberatelies);
1534     my $declaredistro = access_basedistro();
1535     open TO, '>', $tfn->('.tmp') or die $!;
1536     print TO <<END or die $!;
1537 object $head
1538 type commit
1539 tag $tag
1540 tagger $authline
1541
1542 $package release $cversion for $clogsuite ($csuite) [dgit]
1543 [dgit distro=$declaredistro$delibs]
1544 END
1545     foreach my $ref (sort keys %previously) {
1546                     print TO <<END or die $!;
1547 [dgit previously:$ref=$previously{$ref}]
1548 END
1549     }
1550
1551     close TO or die $!;
1552
1553     my $tagobjfn = $tfn->('.tmp');
1554     if ($sign) {
1555         if (!defined $keyid) {
1556             $keyid = access_cfg('keyid','RETURN-UNDEF');
1557         }
1558         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1559         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1560         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1561         push @sign_cmd, $tfn->('.tmp');
1562         runcmd_ordryrun @sign_cmd;
1563         if (act_scary()) {
1564             $tagobjfn = $tfn->('.signed.tmp');
1565             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1566                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1567         }
1568     }
1569
1570     return ($tagobjfn);
1571 }
1572
1573 sub sign_changes ($) {
1574     my ($changesfile) = @_;
1575     if ($sign) {
1576         my @debsign_cmd = @debsign;
1577         push @debsign_cmd, "-k$keyid" if defined $keyid;
1578         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1579         push @debsign_cmd, $changesfile;
1580         runcmd_ordryrun @debsign_cmd;
1581     }
1582 }
1583
1584 sub dopush ($) {
1585     my ($forceflag) = @_;
1586     printdebug "actually entering push\n";
1587     prep_ud();
1588
1589     access_giturl(); # check that success is vaguely likely
1590
1591     my $clogpfn = ".git/dgit/changelog.822.tmp";
1592     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1593
1594     responder_send_file('parsed-changelog', $clogpfn);
1595
1596     my ($clogp, $cversion, $tag, $dscfn) =
1597         push_parse_changelog("$clogpfn");
1598
1599     my $dscpath = "$buildproductsdir/$dscfn";
1600     stat_exists $dscpath or
1601         fail "looked for .dsc $dscfn, but $!;".
1602             " maybe you forgot to build";
1603
1604     responder_send_file('dsc', $dscpath);
1605
1606     push_parse_dsc($dscpath, $dscfn, $cversion);
1607
1608     my $format = getfield $dsc, 'Format';
1609     printdebug "format $format\n";
1610     if (madformat($format)) {
1611         commit_quilty_patch();
1612     }
1613     check_not_dirty();
1614     changedir $ud;
1615     progress "checking that $dscfn corresponds to HEAD";
1616     runcmd qw(dpkg-source -x --),
1617         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1618     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1619     changedir '../../../..';
1620     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1621     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1622     debugcmd "+",@diffcmd;
1623     $!=0; $?=0;
1624     my $r = system @diffcmd;
1625     if ($r) {
1626         if ($r==256) {
1627             fail "$dscfn specifies a different tree to your HEAD commit;".
1628                 " perhaps you forgot to build".
1629                 ($diffopt eq '--exit-code' ? "" :
1630                  " (run with -D to see full diff output)");
1631         } else {
1632             failedcmd @diffcmd;
1633         }
1634     }
1635 #fetch from alioth
1636 #do fast forward check and maybe fake merge
1637 #    if (!is_fast_fwd(mainbranch
1638 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1639 #        map { lref($_).":".rref($_) }
1640 #        (uploadbranch());
1641     my $head = git_rev_parse('HEAD');
1642     if (!$changesfile) {
1643         my $multi = "$buildproductsdir/".
1644             "${package}_".(stripepoch $cversion)."_multi.changes";
1645         if (stat_exists "$multi") {
1646             $changesfile = $multi;
1647         } else {
1648             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1649             my @cs = glob "$buildproductsdir/$pat";
1650             fail "failed to find unique changes file".
1651                 " (looked for $pat in $buildproductsdir, or $multi);".
1652                 " perhaps you need to use dgit -C"
1653                 unless @cs==1;
1654             ($changesfile) = @cs;
1655         }
1656     } else {
1657         $changesfile = "$buildproductsdir/$changesfile";
1658     }
1659
1660     responder_send_file('changes',$changesfile);
1661     responder_send_command("param head $head");
1662     responder_send_command("param csuite $csuite");
1663
1664     if (deliberately_not_fast_forward) {
1665         git_for_each_ref(lrfetchrefs, sub {
1666             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
1667             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
1668             responder_send_command("previously $rrefname=$objid");
1669             $previously{$rrefname} = $objid;
1670         });
1671     }
1672
1673     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1674     my $tagobjfn;
1675
1676     if ($we_are_responder) {
1677         $tagobjfn = $tfn->('.signed.tmp');
1678         responder_receive_files('signed-tag', $tagobjfn);
1679     } else {
1680         $tagobjfn =
1681             push_mktag($head,$clogp,$tag,
1682                        $dscpath,
1683                        $changesfile,$changesfile,
1684                        $tfn);
1685     }
1686
1687     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1688     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1689     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1690     runcmd_ordryrun @git, qw(tag -v --), $tag;
1691
1692     if (!check_for_git()) {
1693         create_remote_git_repo();
1694     }
1695     runcmd_ordryrun @git, qw(push),access_giturl(),
1696         $forceflag."HEAD:".rrref(), "refs/tags/$tag";
1697     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1698
1699     if ($we_are_responder) {
1700         my $dryrunsuffix = act_local() ? "" : ".tmp";
1701         responder_receive_files('signed-dsc-changes',
1702                                 "$dscpath$dryrunsuffix",
1703                                 "$changesfile$dryrunsuffix");
1704     } else {
1705         if (act_local()) {
1706             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1707         } else {
1708             progress "[new .dsc left in $dscpath.tmp]";
1709         }
1710         sign_changes $changesfile;
1711     }
1712
1713     my $host = access_cfg('upload-host','RETURN-UNDEF');
1714     my @hostarg = defined($host) ? ($host,) : ();
1715     runcmd_ordryrun @dput, @hostarg, $changesfile;
1716     printdone "pushed and uploaded $cversion";
1717
1718     responder_send_command("complete");
1719 }
1720
1721 sub cmd_clone {
1722     parseopts();
1723     my $dstdir;
1724     badusage "-p is not allowed with clone; specify as argument instead"
1725         if defined $package;
1726     if (@ARGV==1) {
1727         ($package) = @ARGV;
1728     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1729         ($package,$isuite) = @ARGV;
1730     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1731         ($package,$dstdir) = @ARGV;
1732     } elsif (@ARGV==3) {
1733         ($package,$isuite,$dstdir) = @ARGV;
1734     } else {
1735         badusage "incorrect arguments to dgit clone";
1736     }
1737     $dstdir ||= "$package";
1738
1739     if (stat_exists $dstdir) {
1740         fail "$dstdir already exists";
1741     }
1742
1743     my $cwd_remove;
1744     if ($rmonerror && !$dryrun_level) {
1745         $cwd_remove= getcwd();
1746         unshift @end, sub { 
1747             return unless defined $cwd_remove;
1748             if (!chdir "$cwd_remove") {
1749                 return if $!==&ENOENT;
1750                 die "chdir $cwd_remove: $!";
1751             }
1752             rmtree($dstdir) or die "remove $dstdir: $!\n";
1753         };
1754     }
1755
1756     clone($dstdir);
1757     $cwd_remove = undef;
1758 }
1759
1760 sub branchsuite () {
1761     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1762     if ($branch =~ m#$lbranch_re#o) {
1763         return $1;
1764     } else {
1765         return undef;
1766     }
1767 }
1768
1769 sub fetchpullargs () {
1770     if (!defined $package) {
1771         my $sourcep = parsecontrol('debian/control','debian/control');
1772         $package = getfield $sourcep, 'Source';
1773     }
1774     if (@ARGV==0) {
1775 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1776         if (!$isuite) {
1777             my $clogp = parsechangelog();
1778             $isuite = getfield $clogp, 'Distribution';
1779         }
1780         canonicalise_suite();
1781         progress "fetching from suite $csuite";
1782     } elsif (@ARGV==1) {
1783         ($isuite) = @ARGV;
1784         canonicalise_suite();
1785     } else {
1786         badusage "incorrect arguments to dgit fetch or dgit pull";
1787     }
1788 }
1789
1790 sub cmd_fetch {
1791     parseopts();
1792     fetchpullargs();
1793     fetch();
1794 }
1795
1796 sub cmd_pull {
1797     parseopts();
1798     fetchpullargs();
1799     pull();
1800 }
1801
1802 sub cmd_push {
1803     parseopts();
1804     badusage "-p is not allowed with dgit push" if defined $package;
1805     check_not_dirty();
1806     my $clogp = parsechangelog();
1807     $package = getfield $clogp, 'Source';
1808     my $specsuite;
1809     if (@ARGV==0) {
1810     } elsif (@ARGV==1) {
1811         ($specsuite) = (@ARGV);
1812     } else {
1813         badusage "incorrect arguments to dgit push";
1814     }
1815     $isuite = getfield $clogp, 'Distribution';
1816     if ($new_package) {
1817         local ($package) = $existing_package; # this is a hack
1818         canonicalise_suite();
1819     }
1820     if (defined $specsuite && $specsuite ne $isuite) {
1821         canonicalise_suite();
1822         $csuite eq $specsuite or
1823             fail "dgit push: changelog specifies $isuite ($csuite)".
1824                 " but command line specifies $specsuite";
1825     }
1826     if (check_for_git()) {
1827         git_fetch_us();
1828     }
1829     my $forceflag = '';
1830     if (fetch_from_archive()) {
1831         if (is_fast_fwd(lrref(), 'HEAD')) {
1832             # ok
1833         } elsif (deliberately_not_fast_forward) {
1834             $forceflag = '+';
1835         } else {
1836             fail "dgit push: HEAD is not a descendant".
1837                 " of the archive's version.\n".
1838                 "dgit: To overwrite its contents,".
1839                 " use git merge -s ours ".lrref().".\n".
1840                 "dgit: To rewind history, if permitted by the archive,".
1841                 " use --deliberately-not-fast-forward";
1842         }
1843     } else {
1844         $new_package or
1845             fail "package appears to be new in this suite;".
1846                 " if this is intentional, use --new";
1847     }
1848     dopush($forceflag);
1849 }
1850
1851 #---------- remote commands' implementation ----------
1852
1853 sub cmd_remote_push_build_host {
1854     my ($nrargs) = shift @ARGV;
1855     my (@rargs) = @ARGV[0..$nrargs-1];
1856     @ARGV = @ARGV[$nrargs..$#ARGV];
1857     die unless @rargs;
1858     my ($dir,$vsnwant) = @rargs;
1859     # vsnwant is a comma-separated list; we report which we have
1860     # chosen in our ready response (so other end can tell if they
1861     # offered several)
1862     $debugprefix = ' ';
1863     $we_are_responder = 1;
1864     $us .= " (build host)";
1865
1866     open PI, "<&STDIN" or die $!;
1867     open STDIN, "/dev/null" or die $!;
1868     open PO, ">&STDOUT" or die $!;
1869     autoflush PO 1;
1870     open STDOUT, ">&STDERR" or die $!;
1871     autoflush STDOUT 1;
1872
1873     $vsnwant //= 1;
1874     fail "build host has dgit rpush protocol version".
1875         " $rpushprotovsn but invocation host has $vsnwant"
1876         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1877
1878     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1879
1880     changedir $dir;
1881     &cmd_push;
1882 }
1883
1884 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1885 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1886 #     a good error message)
1887
1888 our $i_tmp;
1889
1890 sub i_cleanup {
1891     local ($@, $?);
1892     my $report = i_child_report();
1893     if (defined $report) {
1894         printdebug "($report)\n";
1895     } elsif ($i_child_pid) {
1896         printdebug "(killing build host child $i_child_pid)\n";
1897         kill 15, $i_child_pid;
1898     }
1899     if (defined $i_tmp && !defined $initiator_tempdir) {
1900         changedir "/";
1901         eval { rmtree $i_tmp; };
1902     }
1903 }
1904
1905 END { i_cleanup(); }
1906
1907 sub i_method {
1908     my ($base,$selector,@args) = @_;
1909     $selector =~ s/\-/_/g;
1910     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1911 }
1912
1913 sub cmd_rpush {
1914     my $host = nextarg;
1915     my $dir;
1916     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1917         $host = $1;
1918         $dir = $'; #';
1919     } else {
1920         $dir = nextarg;
1921     }
1922     $dir =~ s{^-}{./-};
1923     my @rargs = ($dir,$rpushprotovsn);
1924     my @rdgit;
1925     push @rdgit, @dgit;
1926     push @rdgit, @ropts;
1927     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1928     push @rdgit, @ARGV;
1929     my @cmd = (@ssh, $host, shellquote @rdgit);
1930     debugcmd "+",@cmd;
1931
1932     if (defined $initiator_tempdir) {
1933         rmtree $initiator_tempdir;
1934         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1935         $i_tmp = $initiator_tempdir;
1936     } else {
1937         $i_tmp = tempdir();
1938     }
1939     $i_child_pid = open2(\*RO, \*RI, @cmd);
1940     changedir $i_tmp;
1941     initiator_expect { m/^dgit-remote-push-ready/ };
1942     for (;;) {
1943         my ($icmd,$iargs) = initiator_expect {
1944             m/^(\S+)(?: (.*))?$/;
1945             ($1,$2);
1946         };
1947         i_method "i_resp", $icmd, $iargs;
1948     }
1949 }
1950
1951 sub i_resp_progress ($) {
1952     my ($rhs) = @_;
1953     my $msg = protocol_read_bytes \*RO, $rhs;
1954     progress $msg;
1955 }
1956
1957 sub i_resp_complete {
1958     my $pid = $i_child_pid;
1959     $i_child_pid = undef; # prevents killing some other process with same pid
1960     printdebug "waiting for build host child $pid...\n";
1961     my $got = waitpid $pid, 0;
1962     die $! unless $got == $pid;
1963     die "build host child failed $?" if $?;
1964
1965     i_cleanup();
1966     printdebug "all done\n";
1967     exit 0;
1968 }
1969
1970 sub i_resp_file ($) {
1971     my ($keyword) = @_;
1972     my $localname = i_method "i_localname", $keyword;
1973     my $localpath = "$i_tmp/$localname";
1974     stat_exists $localpath and
1975         badproto \*RO, "file $keyword ($localpath) twice";
1976     protocol_receive_file \*RO, $localpath;
1977     i_method "i_file", $keyword;
1978 }
1979
1980 our %i_param;
1981
1982 sub i_resp_param ($) {
1983     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1984     $i_param{$1} = $2;
1985 }
1986
1987 sub i_resp_previously ($) {
1988     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
1989         or badproto \*RO, "bad previously spec";
1990     my $r = system qw(git check-ref-format), $1;
1991     die "bad previously ref spec ($r)" if $r;
1992     $previously{$1} = $2;
1993 }
1994
1995 our %i_wanted;
1996
1997 sub i_resp_want ($) {
1998     my ($keyword) = @_;
1999     die "$keyword ?" if $i_wanted{$keyword}++;
2000     my @localpaths = i_method "i_want", $keyword;
2001     printdebug "[[  $keyword @localpaths\n";
2002     foreach my $localpath (@localpaths) {
2003         protocol_send_file \*RI, $localpath;
2004     }
2005     print RI "files-end\n" or die $!;
2006 }
2007
2008 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2009
2010 sub i_localname_parsed_changelog {
2011     return "remote-changelog.822";
2012 }
2013 sub i_file_parsed_changelog {
2014     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2015         push_parse_changelog "$i_tmp/remote-changelog.822";
2016     die if $i_dscfn =~ m#/|^\W#;
2017 }
2018
2019 sub i_localname_dsc {
2020     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2021     return $i_dscfn;
2022 }
2023 sub i_file_dsc { }
2024
2025 sub i_localname_changes {
2026     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2027     $i_changesfn = $i_dscfn;
2028     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2029     return $i_changesfn;
2030 }
2031 sub i_file_changes { }
2032
2033 sub i_want_signed_tag {
2034     printdebug Dumper(\%i_param, $i_dscfn);
2035     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2036         && defined $i_param{'csuite'}
2037         or badproto \*RO, "premature desire for signed-tag";
2038     my $head = $i_param{'head'};
2039     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2040
2041     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2042     $csuite = $&;
2043     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2044
2045     my $tagobjfn =
2046         push_mktag $head, $i_clogp, $i_tag,
2047             $i_dscfn,
2048             $i_changesfn, 'remote changes',
2049             sub { "tag$_[0]"; };
2050
2051     return $tagobjfn;
2052 }
2053
2054 sub i_want_signed_dsc_changes {
2055     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2056     sign_changes $i_changesfn;
2057     return ($i_dscfn, $i_changesfn);
2058 }
2059
2060 #---------- building etc. ----------
2061
2062 our $version;
2063 our $sourcechanges;
2064 our $dscfn;
2065
2066 #----- `3.0 (quilt)' handling -----
2067
2068 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2069
2070 sub quiltify_dpkg_commit ($$$;$) {
2071     my ($patchname,$author,$msg, $xinfo) = @_;
2072     $xinfo //= '';
2073
2074     mkpath '.git/dgit';
2075     my $descfn = ".git/dgit/quilt-description.tmp";
2076     open O, '>', $descfn or die "$descfn: $!";
2077     $msg =~ s/\s+$//g;
2078     $msg =~ s/\n/\n /g;
2079     $msg =~ s/^\s+$/ ./mg;
2080     print O <<END or die $!;
2081 Description: $msg
2082 Author: $author
2083 $xinfo
2084 ---
2085
2086 END
2087     close O or die $!;
2088
2089     {
2090         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2091         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2092         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2093         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2094     }
2095 }
2096
2097 sub quiltify_trees_differ ($$) {
2098     my ($x,$y) = @_;
2099     # returns 1 iff the two tree objects differ other than in debian/
2100     local $/=undef;
2101     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2102     my $diffs= cmdoutput @cmd;
2103     foreach my $f (split /\0/, $diffs) {
2104         next if $f eq 'debian';
2105         return 1;
2106     }
2107     return 0;
2108 }
2109
2110 sub quiltify_tree_sentinelfiles ($) {
2111     # lists the `sentinel' files present in the tree
2112     my ($x) = @_;
2113     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2114         qw(-- debian/rules debian/control);
2115     $r =~ s/\n/,/g;
2116     return $r;
2117 }
2118
2119 sub quiltify ($$) {
2120     my ($clogp,$target) = @_;
2121
2122     # Quilt patchification algorithm
2123     #
2124     # We search backwards through the history of the main tree's HEAD
2125     # (T) looking for a start commit S whose tree object is identical
2126     # to to the patch tip tree (ie the tree corresponding to the
2127     # current dpkg-committed patch series).  For these purposes
2128     # `identical' disregards anything in debian/ - this wrinkle is
2129     # necessary because dpkg-source treates debian/ specially.
2130     #
2131     # We can only traverse edges where at most one of the ancestors'
2132     # trees differs (in changes outside in debian/).  And we cannot
2133     # handle edges which change .pc/ or debian/patches.  To avoid
2134     # going down a rathole we avoid traversing edges which introduce
2135     # debian/rules or debian/control.  And we set a limit on the
2136     # number of edges we are willing to look at.
2137     #
2138     # If we succeed, we walk forwards again.  For each traversed edge
2139     # PC (with P parent, C child) (starting with P=S and ending with
2140     # C=T) to we do this:
2141     #  - git checkout C
2142     #  - dpkg-source --commit with a patch name and message derived from C
2143     # After traversing PT, we git commit the changes which
2144     # should be contained within debian/patches.
2145
2146     changedir '../fake';
2147     mktree_in_ud_here();
2148     rmtree '.pc';
2149     runcmd @git, 'add', '.';
2150     my $oldtiptree=git_write_tree();
2151     changedir '../work';
2152
2153     # The search for the path S..T is breadth-first.  We maintain a
2154     # todo list containing search nodes.  A search node identifies a
2155     # commit, and looks something like this:
2156     #  $p = {
2157     #      Commit => $git_commit_id,
2158     #      Child => $c,                          # or undef if P=T
2159     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2160     #      Nontrivial => true iff $p..$c has relevant changes
2161     #  };
2162
2163     my @todo;
2164     my @nots;
2165     my $sref_S;
2166     my $max_work=100;
2167     my %considered; # saves being exponential on some weird graphs
2168
2169     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2170
2171     my $not = sub {
2172         my ($search,$whynot) = @_;
2173         printdebug " search NOT $search->{Commit} $whynot\n";
2174         $search->{Whynot} = $whynot;
2175         push @nots, $search;
2176         no warnings qw(exiting);
2177         next;
2178     };
2179
2180     push @todo, {
2181         Commit => $target,
2182     };
2183
2184     while (@todo) {
2185         my $c = shift @todo;
2186         next if $considered{$c->{Commit}}++;
2187
2188         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2189
2190         printdebug "quiltify investigate $c->{Commit}\n";
2191
2192         # are we done?
2193         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2194             printdebug " search finished hooray!\n";
2195             $sref_S = $c;
2196             last;
2197         }
2198
2199         if ($quilt_mode eq 'nofix') {
2200             fail "quilt fixup required but quilt mode is \`nofix'\n".
2201                 "HEAD commit $c->{Commit} differs from tree implied by ".
2202                 " debian/patches (tree object $oldtiptree)";
2203         }
2204         if ($quilt_mode eq 'smash') {
2205             printdebug " search quitting smash\n";
2206             last;
2207         }
2208
2209         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2210         $not->($c, "has $c_sentinels not $t_sentinels")
2211             if $c_sentinels ne $t_sentinels;
2212
2213         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2214         $commitdata =~ m/\n\n/;
2215         $commitdata =~ $`;
2216         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2217         @parents = map { { Commit => $_, Child => $c } } @parents;
2218
2219         $not->($c, "root commit") if !@parents;
2220
2221         foreach my $p (@parents) {
2222             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2223         }
2224         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2225         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2226
2227         foreach my $p (@parents) {
2228             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2229
2230             my @cmd= (@git, qw(diff-tree -r --name-only),
2231                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2232             my $patchstackchange = cmdoutput @cmd;
2233             if (length $patchstackchange) {
2234                 $patchstackchange =~ s/\n/,/g;
2235                 $not->($p, "changed $patchstackchange");
2236             }
2237
2238             printdebug " search queue P=$p->{Commit} ",
2239                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2240             push @todo, $p;
2241         }
2242     }
2243
2244     if (!$sref_S) {
2245         printdebug "quiltify want to smash\n";
2246
2247         my $abbrev = sub {
2248             my $x = $_[0]{Commit};
2249             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2250             return $;
2251         };
2252         my $reportnot = sub {
2253             my ($notp) = @_;
2254             my $s = $abbrev->($notp);
2255             my $c = $notp->{Child};
2256             $s .= "..".$abbrev->($c) if $c;
2257             $s .= ": ".$c->{Whynot};
2258             return $s;
2259         };
2260         if ($quilt_mode eq 'linear') {
2261             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2262             foreach my $notp (@nots) {
2263                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2264             }
2265             fail "quilt fixup naive history linearisation failed.\n".
2266  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2267         } elsif ($quilt_mode eq 'smash') {
2268         } elsif ($quilt_mode eq 'auto') {
2269             progress "quilt fixup cannot be linear, smashing...";
2270         } else {
2271             die "$quilt_mode ?";
2272         }
2273
2274         my $time = time;
2275         my $ncommits = 3;
2276         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2277
2278         quiltify_dpkg_commit "auto-$version-$target-$time",
2279             (getfield $clogp, 'Maintainer'),
2280             "Automatically generated patch ($clogp->{Version})\n".
2281             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2282         return;
2283     }
2284
2285     progress "quiltify linearisation planning successful, executing...";
2286
2287     for (my $p = $sref_S;
2288          my $c = $p->{Child};
2289          $p = $p->{Child}) {
2290         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2291         next unless $p->{Nontrivial};
2292
2293         my $cc = $c->{Commit};
2294
2295         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2296         $commitdata =~ m/\n\n/ or die "$c ?";
2297         $commitdata = $`;
2298         my $msg = $'; #';
2299         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2300         my $author = $1;
2301
2302         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2303
2304         my $title = $1;
2305         my $patchname = $title;
2306         $patchname =~ s/[.:]$//;
2307         $patchname =~ y/ A-Z/-a-z/;
2308         $patchname =~ y/-a-z0-9_.+=~//cd;
2309         $patchname =~ s/^\W/x-$&/;
2310         $patchname = substr($patchname,0,40);
2311         my $index;
2312         for ($index='';
2313              stat "debian/patches/$patchname$index";
2314              $index++) { }
2315         $!==ENOENT or die "$patchname$index $!";
2316
2317         runcmd @git, qw(checkout -q), $cc;
2318
2319         # We use the tip's changelog so that dpkg-source doesn't
2320         # produce complaining messages from dpkg-parsechangelog.  None
2321         # of the information dpkg-source gets from the changelog is
2322         # actually relevant - it gets put into the original message
2323         # which dpkg-source provides our stunt editor, and then
2324         # overwritten.
2325         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2326
2327         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2328             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2329
2330         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2331     }
2332
2333     runcmd @git, qw(checkout -q master);
2334 }
2335
2336 sub build_maybe_quilt_fixup () {
2337     my $format=get_source_format;
2338     return unless madformat $format;
2339     # sigh
2340
2341     # Our objective is:
2342     #  - honour any existing .pc in case it has any strangeness
2343     #  - determine the git commit corresponding to the tip of
2344     #    the patch stack (if there is one)
2345     #  - if there is such a git commit, convert each subsequent
2346     #    git commit into a quilt patch with dpkg-source --commit
2347     #  - otherwise convert all the differences in the tree into
2348     #    a single git commit
2349     #
2350     # To do this we:
2351
2352     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2353     # dgit would include the .pc in the git tree.)  If there isn't
2354     # one, we need to generate one by unpacking the patches that we
2355     # have.
2356     #
2357     # We first look for a .pc in the git tree.  If there is one, we
2358     # will use it.  (This is not the normal case.)
2359     #
2360     # Otherwise need to regenerate .pc so that dpkg-source --commit
2361     # can work.  We do this as follows:
2362     #     1. Collect all relevant .orig from parent directory
2363     #     2. Generate a debian.tar.gz out of
2364     #         debian/{patches,rules,source/format}
2365     #     3. Generate a fake .dsc containing just these fields:
2366     #          Format Source Version Files
2367     #     4. Extract the fake .dsc
2368     #        Now the fake .dsc has a .pc directory.
2369     # (In fact we do this in every case, because in future we will
2370     # want to search for a good base commit for generating patches.)
2371     #
2372     # Then we can actually do the dpkg-source --commit
2373     #     1. Make a new working tree with the same object
2374     #        store as our main tree and check out the main
2375     #        tree's HEAD.
2376     #     2. Copy .pc from the fake's extraction, if necessary
2377     #     3. Run dpkg-source --commit
2378     #     4. If the result has changes to debian/, then
2379     #          - git-add them them
2380     #          - git-add .pc if we had a .pc in-tree
2381     #          - git-commit
2382     #     5. If we had a .pc in-tree, delete it, and git-commit
2383     #     6. Back in the main tree, fast forward to the new HEAD
2384
2385     my $clogp = parsechangelog();
2386     my $headref = git_rev_parse('HEAD');
2387
2388     prep_ud();
2389     changedir $ud;
2390
2391     my $upstreamversion=$version;
2392     $upstreamversion =~ s/-[^-]*$//;
2393
2394     my $fakeversion="$upstreamversion-~~DGITFAKE";
2395
2396     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2397     print $fakedsc <<END or die $!;
2398 Format: 3.0 (quilt)
2399 Source: $package
2400 Version: $fakeversion
2401 Files:
2402 END
2403
2404     my $dscaddfile=sub {
2405         my ($b) = @_;
2406         
2407         my $md = new Digest::MD5;
2408
2409         my $fh = new IO::File $b, '<' or die "$b $!";
2410         stat $fh or die $!;
2411         my $size = -s _;
2412
2413         $md->addfile($fh);
2414         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2415     };
2416
2417     foreach my $f (<../../../../*>) { #/){
2418         my $b=$f; $b =~ s{.*/}{};
2419         next unless is_orig_file $b, srcfn $upstreamversion,'';
2420         link $f, $b or die "$b $!";
2421         $dscaddfile->($b);
2422     }
2423
2424     my @files=qw(debian/source/format debian/rules);
2425     if (stat_exists '../../../debian/patches') {
2426         push @files, 'debian/patches';
2427     }
2428
2429     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2430     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2431
2432     $dscaddfile->($debtar);
2433     close $fakedsc or die $!;
2434
2435     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2436
2437     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2438     rename $fakexdir, "fake" or die "$fakexdir $!";
2439
2440     mkdir "work" or die $!;
2441     changedir "work";
2442     mktree_in_ud_here();
2443     runcmd @git, qw(reset --hard), $headref;
2444
2445     my $mustdeletepc=0;
2446     if (stat_exists ".pc") {
2447         -d _ or die;
2448         progress "Tree already contains .pc - will use it then delete it.";
2449         $mustdeletepc=1;
2450     } else {
2451         rename '../fake/.pc','.pc' or die $!;
2452     }
2453
2454     quiltify($clogp,$headref);
2455
2456     if (!open P, '>>', ".pc/applied-patches") {
2457         $!==&ENOENT or die $!;
2458     } else {
2459         close P;
2460     }
2461
2462     commit_quilty_patch();
2463
2464     if ($mustdeletepc) {
2465         runcmd @git, qw(rm -rq .pc);
2466         commit_admin "Commit removal of .pc (quilt series tracking data)";
2467     }
2468
2469     changedir '../../../..';
2470     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2471 }
2472
2473 sub quilt_fixup_editor () {
2474     my $descfn = $ENV{$fakeeditorenv};
2475     my $editing = $ARGV[$#ARGV];
2476     open I1, '<', $descfn or die "$descfn: $!";
2477     open I2, '<', $editing or die "$editing: $!";
2478     unlink $editing or die "$editing: $!";
2479     open O, '>', $editing or die "$editing: $!";
2480     while (<I1>) { print O or die $!; } I1->error and die $!;
2481     my $copying = 0;
2482     while (<I2>) {
2483         $copying ||= m/^\-\-\- /;
2484         next unless $copying;
2485         print O or die $!;
2486     }
2487     I2->error and die $!;
2488     close O or die $1;
2489     exit 0;
2490 }
2491
2492 #----- other building -----
2493
2494 sub clean_tree () {
2495     if ($cleanmode eq 'dpkg-source') {
2496         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2497     } elsif ($cleanmode eq 'git') {
2498         runcmd_ordryrun_local @git, qw(clean -xdf);
2499     } elsif ($cleanmode eq 'none') {
2500     } else {
2501         die "$cleanmode ?";
2502     }
2503 }
2504
2505 sub cmd_clean () {
2506     badusage "clean takes no additional arguments" if @ARGV;
2507     clean_tree();
2508 }
2509
2510 sub build_prep () {
2511     badusage "-p is not allowed when building" if defined $package;
2512     check_not_dirty();
2513     clean_tree();
2514     my $clogp = parsechangelog();
2515     $isuite = getfield $clogp, 'Distribution';
2516     $package = getfield $clogp, 'Source';
2517     $version = getfield $clogp, 'Version';
2518     build_maybe_quilt_fixup();
2519 }
2520
2521 sub changesopts () {
2522     my @opts =@changesopts[1..$#changesopts];
2523     if (!defined $changes_since_version) {
2524         my @vsns = archive_query('archive_query');
2525         my @quirk = access_quirk();
2526         if ($quirk[0] eq 'backports') {
2527             local $isuite = $quirk[2];
2528             local $csuite;
2529             canonicalise_suite();
2530             push @vsns, archive_query('archive_query');
2531         }
2532         if (@vsns) {
2533             @vsns = map { $_->[0] } @vsns;
2534             @vsns = sort { -version_compare($a, $b) } @vsns;
2535             $changes_since_version = $vsns[0];
2536             progress "changelog will contain changes since $vsns[0]";
2537         } else {
2538             $changes_since_version = '_';
2539             progress "package seems new, not specifying -v<version>";
2540         }
2541     }
2542     if ($changes_since_version ne '_') {
2543         unshift @opts, "-v$changes_since_version";
2544     }
2545     return @opts;
2546 }
2547
2548 sub cmd_build {
2549     build_prep();
2550     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2551     printdone "build successful\n";
2552 }
2553
2554 sub cmd_git_build {
2555     build_prep();
2556     my @cmd =
2557         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2558          "--git-builder=@dpkgbuildpackage");
2559     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2560         canonicalise_suite();
2561         push @cmd, "--git-debian-branch=".lbranch();
2562     }
2563     push @cmd, changesopts();
2564     runcmd_ordryrun_local @cmd, @ARGV;
2565     printdone "build successful\n";
2566 }
2567
2568 sub build_source {
2569     build_prep();
2570     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2571     $dscfn = dscfn($version);
2572     if ($cleanmode eq 'dpkg-source') {
2573         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2574             changesopts();
2575     } else {
2576         my $pwd = must_getcwd();
2577         my $leafdir = basename $pwd;
2578         changedir "..";
2579         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2580         changedir $pwd;
2581         runcmd_ordryrun_local qw(sh -ec),
2582             'exec >$1; shift; exec "$@"','x',
2583             "../$sourcechanges",
2584             @dpkggenchanges, qw(-S), changesopts();
2585     }
2586 }
2587
2588 sub cmd_build_source {
2589     badusage "build-source takes no additional arguments" if @ARGV;
2590     build_source();
2591     printdone "source built, results in $dscfn and $sourcechanges";
2592 }
2593
2594 sub cmd_sbuild {
2595     build_source();
2596     changedir "..";
2597     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2598     if (act_local()) {
2599         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2600         stat_exists $sourcechanges
2601             or fail "$sourcechanges (in parent directory): $!";
2602         foreach my $cf (glob $pat) {
2603             next if $cf eq $sourcechanges;
2604             unlink $cf or fail "remove $cf: $!";
2605         }
2606     }
2607     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2608     my @changesfiles = glob $pat;
2609     @changesfiles = sort {
2610         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2611             or $a cmp $b
2612     } @changesfiles;
2613     fail "wrong number of different changes files (@changesfiles)"
2614         unless @changesfiles;
2615     runcmd_ordryrun_local @mergechanges, @changesfiles;
2616     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2617     if (act_local()) {
2618         stat_exists $multichanges or fail "$multichanges: $!";
2619     }
2620     printdone "build successful, results in $multichanges\n" or die $!;
2621 }    
2622
2623 sub cmd_quilt_fixup {
2624     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2625     my $clogp = parsechangelog();
2626     $version = getfield $clogp, 'Version';
2627     $package = getfield $clogp, 'Source';
2628     build_maybe_quilt_fixup();
2629 }
2630
2631 sub cmd_archive_api_query {
2632     badusage "need only 1 subpath argument" unless @ARGV==1;
2633     my ($subpath) = @ARGV;
2634     my @cmd = archive_api_query_cmd($subpath);
2635     debugcmd ">",@cmd;
2636     exec @cmd or fail "exec curl: $!\n";
2637 }
2638
2639 #---------- argument parsing and main program ----------
2640
2641 sub cmd_version {
2642     print "dgit version $our_version\n" or die $!;
2643     exit 0;
2644 }
2645
2646 sub parseopts () {
2647     my $om;
2648
2649     if (defined $ENV{'DGIT_SSH'}) {
2650         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2651     } elsif (defined $ENV{'GIT_SSH'}) {
2652         @ssh = ($ENV{'GIT_SSH'});
2653     }
2654
2655     while (@ARGV) {
2656         last unless $ARGV[0] =~ m/^-/;
2657         $_ = shift @ARGV;
2658         last if m/^--?$/;
2659         if (m/^--/) {
2660             if (m/^--dry-run$/) {
2661                 push @ropts, $_;
2662                 $dryrun_level=2;
2663             } elsif (m/^--damp-run$/) {
2664                 push @ropts, $_;
2665                 $dryrun_level=1;
2666             } elsif (m/^--no-sign$/) {
2667                 push @ropts, $_;
2668                 $sign=0;
2669             } elsif (m/^--help$/) {
2670                 cmd_help();
2671             } elsif (m/^--version$/) {
2672                 cmd_version();
2673             } elsif (m/^--new$/) {
2674                 push @ropts, $_;
2675                 $new_package=1;
2676             } elsif (m/^--since-version=([^_]+|_)$/) {
2677                 push @ropts, $_;
2678                 $changes_since_version = $1;
2679             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2680                      ($om = $opts_opt_map{$1}) &&
2681                      length $om->[0]) {
2682                 push @ropts, $_;
2683                 $om->[0] = $2;
2684             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2685                      !$opts_opt_cmdonly{$1} &&
2686                      ($om = $opts_opt_map{$1})) {
2687                 push @ropts, $_;
2688                 push @$om, $2;
2689             } elsif (m/^--existing-package=(.*)/s) {
2690                 push @ropts, $_;
2691                 $existing_package = $1;
2692             } elsif (m/^--initiator-tempdir=(.*)/s) {
2693                 $initiator_tempdir = $1;
2694                 $initiator_tempdir =~ m#^/# or
2695                     badusage "--initiator-tempdir must be used specify an".
2696                         " absolute, not relative, directory."
2697             } elsif (m/^--distro=(.*)/s) {
2698                 push @ropts, $_;
2699                 $idistro = $1;
2700             } elsif (m/^--build-products-dir=(.*)/s) {
2701                 push @ropts, $_;
2702                 $buildproductsdir = $1;
2703             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2704                 push @ropts, $_;
2705                 $cleanmode = $1;
2706             } elsif (m/^--clean=(.*)$/s) {
2707                 badusage "unknown cleaning mode \`$1'";
2708             } elsif (m/^--quilt=($quilt_modes_re)$/s) {
2709                 push @ropts, $_;
2710                 $quilt_mode = $1;
2711             } elsif (m/^--quilt=(.*)$/s) {
2712                 badusage "unknown quilt fixup mode \`$1'";
2713             } elsif (m/^--ignore-dirty$/s) {
2714                 push @ropts, $_;
2715                 $ignoredirty = 1;
2716             } elsif (m/^--no-quilt-fixup$/s) {
2717                 push @ropts, $_;
2718                 $quilt_mode = 'nocheck';
2719             } elsif (m/^--no-rm-on-error$/s) {
2720                 push @ropts, $_;
2721                 $rmonerror = 0;
2722             } elsif (m/^--deliberately-($deliberately_re)$/s) {
2723                 push @ropts, $_;
2724                 push @deliberatelies, $&;
2725             } else {
2726                 badusage "unknown long option \`$_'";
2727             }
2728         } else {
2729             while (m/^-./s) {
2730                 if (s/^-n/-/) {
2731                     push @ropts, $&;
2732                     $dryrun_level=2;
2733                 } elsif (s/^-L/-/) {
2734                     push @ropts, $&;
2735                     $dryrun_level=1;
2736                 } elsif (s/^-h/-/) {
2737                     cmd_help();
2738                 } elsif (s/^-D/-/) {
2739                     push @ropts, $&;
2740                     $debuglevel++;
2741                     enabledebug();
2742                 } elsif (s/^-N/-/) {
2743                     push @ropts, $&;
2744                     $new_package=1;
2745                 } elsif (s/^-v([^_]+|_)$//s) {
2746                     push @ropts, $&;
2747                     $changes_since_version = $1;
2748                 } elsif (m/^-m/) {
2749                     push @ropts, $&;
2750                     push @changesopts, $_;
2751                     $_ = '';
2752                 } elsif (s/^-c(.*=.*)//s) {
2753                     push @ropts, $&;
2754                     push @git, '-c', $1;
2755                 } elsif (s/^-d(.+)//s) {
2756                     push @ropts, $&;
2757                     $idistro = $1;
2758                 } elsif (s/^-C(.+)//s) {
2759                     push @ropts, $&;
2760                     $changesfile = $1;
2761                     if ($changesfile =~ s#^(.*)/##) {
2762                         $buildproductsdir = $1;
2763                     }
2764                 } elsif (s/^-k(.+)//s) {
2765                     $keyid=$1;
2766                 } elsif (m/^-[vdCk]$/) {
2767                     badusage
2768  "option \`$_' requires an argument (and no space before the argument)";
2769                 } elsif (s/^-wn$//s) {
2770                     push @ropts, $&;
2771                     $cleanmode = 'none';
2772                 } elsif (s/^-wg$//s) {
2773                     push @ropts, $&;
2774                     $cleanmode = 'git';
2775                 } elsif (s/^-wd$//s) {
2776                     push @ropts, $&;
2777                     $cleanmode = 'dpkg-source';
2778                 } else {
2779                     badusage "unknown short option \`$_'";
2780                 }
2781             }
2782         }
2783     }
2784 }
2785
2786 if ($ENV{$fakeeditorenv}) {
2787     quilt_fixup_editor();
2788 }
2789
2790 parseopts();
2791 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2792 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2793     if $dryrun_level == 1;
2794 if (!@ARGV) {
2795     print STDERR $helpmsg or die $!;
2796     exit 8;
2797 }
2798 my $cmd = shift @ARGV;
2799 $cmd =~ y/-/_/;
2800
2801 if (!defined $quilt_mode) {
2802     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
2803         // access_cfg('quilt-mode', 'RETURN-UNDEF')
2804         // 'linear';
2805     $quilt_mode =~ m/^($quilt_modes_re)$/ 
2806         or badcfg "unknown quilt-mode \`$quilt_mode'";
2807     $quilt_mode = $1;
2808 }
2809
2810 my $fn = ${*::}{"cmd_$cmd"};
2811 $fn or badusage "unknown operation $cmd";
2812 $fn->();