dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2015 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Carp;
  40
  41 use Debian::Dgit;
  42
  43 our $our_version = 'UNRELEASED'; ###substituted###
  44
  45 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  46 our $protovsn;
  47
  48 our $isuite = 'unstable';
  49 our $idistro;
  50 our $package;
  51 our @ropts;
  52
  53 our $sign = 1;
  54 our $dryrun_level = 0;
  55 our $changesfile;
  56 our $buildproductsdir = '..';
  57 our $new_package = 0;
  58 our $ignoredirty = 0;
  59 our $rmonerror = 1;
  60 our @deliberatelies;
  61 our %previously;
  62 our $existing_package = 'dpkg';
  63 our $cleanmode;
  64 our $changes_since_version;
  65 our $rmchanges;
  66 our $overwrite_version;
  67 our $quilt_mode;
  68 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  69 our $we_are_responder;
  70 our $initiator_tempdir;
  71 our $patches_applied_dirtily = 00;
  72 our $tagformat_want;
  73 our $tagformat;
  74 our $tagformatfn;
  75
  76 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  77
  78 our $suite_re = '[-+.0-9a-z]+';
  79 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  80
  81 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  82 our $splitbraincache = 'dgit-intern/quilt-cache';
  83
  84 our (@git) = qw(git);
  85 our (@dget) = qw(dget);
  86 our (@curl) = qw(curl -f);
  87 our (@dput) = qw(dput);
  88 our (@debsign) = qw(debsign);
  89 our (@gpg) = qw(gpg);
  90 our (@sbuild) = qw(sbuild);
  91 our (@ssh) = 'ssh';
  92 our (@dgit) = qw(dgit);
  93 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  94 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  95 our (@dpkggenchanges) = qw(dpkg-genchanges);
  96 our (@mergechanges) = qw(mergechanges -f);
  97 our (@gbp) = qw(gbp);
  98 our (@changesopts) = ('');
  99
 100 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 101                      'curl' => \@curl,
 102                      'dput' => \@dput,
 103                      'debsign' => \@debsign,
 104                      'gpg' => \@gpg,
 105                      'sbuild' => \@sbuild,
 106                      'ssh' => \@ssh,
 107                      'dgit' => \@dgit,
 108                      'git' => \@git,
 109                      'dpkg-source' => \@dpkgsource,
 110                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 111                      'dpkg-genchanges' => \@dpkggenchanges,
 112                      'gbp' => \@gbp,
 113                      'ch' => \@changesopts,
 114                      'mergechanges' => \@mergechanges);
 115
 116 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 117 our %opts_cfg_insertpos = map {
 118     $_,
 119     scalar @{ $opts_opt_map{$_} }
 120 } keys %opts_opt_map;
 121
 122 sub finalise_opts_opts();
 123
 124 our $keyid;
 125
 126 autoflush STDOUT 1;
 127
 128 our $supplementary_message = '';
 129 our $need_split_build_invocation = 0;
 130 our $split_brain = 0;
 131
 132 END {
 133     local ($@, $?);
 134     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 135 }
 136
 137 our $remotename = 'dgit';
 138 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 139 our $csuite;
 140 our $instead_distro;
 141
 142 sub debiantag ($$) {
 143     my ($v,$distro) = @_;
 144     return $tagformatfn->($v, $distro);
 145 }
 146
 147 sub debiantag_maintview ($$) {
 148     my ($v,$distro) = @_;
 149     $v =~ y/~:/_%/;
 150     return "$distro/$v";
 151 }
 152
 153 sub lbranch () { return "$branchprefix/$csuite"; }
 154 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 155 sub lref () { return "refs/heads/".lbranch(); }
 156 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 157 sub rrref () { return server_ref($csuite); }
 158
 159 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
 160 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
 161
 162 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
 163 # locally fetched refs because they have unhelpful names and clutter
 164 # up gitk etc.  So we track whether we have "used up" head ref (ie,
 165 # whether we have made another local ref which refers to this object).
 166 #
 167 # (If we deleted them unconditionally, then we might end up
 168 # re-fetching the same git objects each time dgit fetch was run.)
 169 #
 170 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
 171 # in git_fetch_us to fetch the refs in question, and possibly a call
 172 # to lrfetchref_used.
 173
 174 our (%lrfetchrefs_f, %lrfetchrefs_d);
 175 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
 176
 177 sub lrfetchref_used ($) {
 178     my ($fullrefname) = @_;
 179     my $objid = $lrfetchrefs_f{$fullrefname};
 180     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
 181 }
 182
 183 sub stripepoch ($) {
 184     my ($vsn) = @_;
 185     $vsn =~ s/^\d+\://;
 186     return $vsn;
 187 }
 188
 189 sub srcfn ($$) {
 190     my ($vsn,$sfx) = @_;
 191     return "${package}_".(stripepoch $vsn).$sfx
 192 }
 193
 194 sub dscfn ($) {
 195     my ($vsn) = @_;
 196     return srcfn($vsn,".dsc");
 197 }
 198
 199 sub changespat ($;$) {
 200     my ($vsn, $arch) = @_;
 201     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 202 }
 203
 204 our $us = 'dgit';
 205 initdebug('');
 206
 207 our @end;
 208 END {
 209     local ($?);
 210     foreach my $f (@end) {
 211         eval { $f->(); };
 212         print STDERR "$us: cleanup: $@" if length $@;
 213     }
 214 };
 215
 216 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 217
 218 sub no_such_package () {
 219     print STDERR "$us: package $package does not exist in suite $isuite\n";
 220     exit 4;
 221 }
 222
 223 sub changedir ($) {
 224     my ($newdir) = @_;
 225     printdebug "CD $newdir\n";
 226     chdir $newdir or confess "chdir: $newdir: $!";
 227 }
 228
 229 sub deliberately ($) {
 230     my ($enquiry) = @_;
 231     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 232 }
 233
 234 sub deliberately_not_fast_forward () {
 235     foreach (qw(not-fast-forward fresh-repo)) {
 236         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 237     }
 238 }
 239
 240 sub quiltmode_splitbrain () {
 241     $quilt_mode =~ m/gbp|dpm|unapplied/;
 242 }
 243
 244 #---------- remote protocol support, common ----------
 245
 246 # remote push initiator/responder protocol:
 247 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 248 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 249 #  < dgit-remote-push-ready <actual-proto-vsn>
 250 #
 251 # occasionally:
 252 #
 253 #  > progress NBYTES
 254 #  [NBYTES message]
 255 #
 256 #  > supplementary-message NBYTES          # $protovsn >= 3
 257 #  [NBYTES message]
 258 #
 259 # main sequence:
 260 #
 261 #  > file parsed-changelog
 262 #  [indicates that output of dpkg-parsechangelog follows]
 263 #  > data-block NBYTES
 264 #  > [NBYTES bytes of data (no newline)]
 265 #  [maybe some more blocks]
 266 #  > data-end
 267 #
 268 #  > file dsc
 269 #  [etc]
 270 #
 271 #  > file changes
 272 #  [etc]
 273 #
 274 #  > param head DGIT-VIEW-HEAD
 275 #  > param csuite SUITE
 276 #  > param tagformat old|new
 277 #  > param maint-view MAINT-VIEW-HEAD
 278 #
 279 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 280 #                                     # goes into tag, for replay prevention
 281 #
 282 #  > want signed-tag
 283 #  [indicates that signed tag is wanted]
 284 #  < data-block NBYTES
 285 #  < [NBYTES bytes of data (no newline)]
 286 #  [maybe some more blocks]
 287 #  < data-end
 288 #  < files-end
 289 #
 290 #  > want signed-dsc-changes
 291 #  < data-block NBYTES    [transfer of signed dsc]
 292 #  [etc]
 293 #  < data-block NBYTES    [transfer of signed changes]
 294 #  [etc]
 295 #  < files-end
 296 #
 297 #  > complete
 298
 299 our $i_child_pid;
 300
 301 sub i_child_report () {
 302     # Sees if our child has died, and reap it if so.  Returns a string
 303     # describing how it died if it failed, or undef otherwise.
 304     return undef unless $i_child_pid;
 305     my $got = waitpid $i_child_pid, WNOHANG;
 306     return undef if $got <= 0;
 307     die unless $got == $i_child_pid;
 308     $i_child_pid = undef;
 309     return undef unless $?;
 310     return "build host child ".waitstatusmsg();
 311 }
 312
 313 sub badproto ($$) {
 314     my ($fh, $m) = @_;
 315     fail "connection lost: $!" if $fh->error;
 316     fail "protocol violation; $m not expected";
 317 }
 318
 319 sub badproto_badread ($$) {
 320     my ($fh, $wh) = @_;
 321     fail "connection lost: $!" if $!;
 322     my $report = i_child_report();
 323     fail $report if defined $report;
 324     badproto $fh, "eof (reading $wh)";
 325 }
 326
 327 sub protocol_expect (&$) {
 328     my ($match, $fh) = @_;
 329     local $_;
 330     $_ = <$fh>;
 331     defined && chomp or badproto_badread $fh, "protocol message";
 332     if (wantarray) {
 333         my @r = &$match;
 334         return @r if @r;
 335     } else {
 336         my $r = &$match;
 337         return $r if $r;
 338     }
 339     badproto $fh, "\`$_'";
 340 }
 341
 342 sub protocol_send_file ($$) {
 343     my ($fh, $ourfn) = @_;
 344     open PF, "<", $ourfn or die "$ourfn: $!";
 345     for (;;) {
 346         my $d;
 347         my $got = read PF, $d, 65536;
 348         die "$ourfn: $!" unless defined $got;
 349         last if !$got;
 350         print $fh "data-block ".length($d)."\n" or die $!;
 351         print $fh $d or die $!;
 352     }
 353     PF->error and die "$ourfn $!";
 354     print $fh "data-end\n" or die $!;
 355     close PF;
 356 }
 357
 358 sub protocol_read_bytes ($$) {
 359     my ($fh, $nbytes) = @_;
 360     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 361     my $d;
 362     my $got = read $fh, $d, $nbytes;
 363     $got==$nbytes or badproto_badread $fh, "data block";
 364     return $d;
 365 }
 366
 367 sub protocol_receive_file ($$) {
 368     my ($fh, $ourfn) = @_;
 369     printdebug "() $ourfn\n";
 370     open PF, ">", $ourfn or die "$ourfn: $!";
 371     for (;;) {
 372         my ($y,$l) = protocol_expect {
 373             m/^data-block (.*)$/ ? (1,$1) :
 374             m/^data-end$/ ? (0,) :
 375             ();
 376         } $fh;
 377         last unless $y;
 378         my $d = protocol_read_bytes $fh, $l;
 379         print PF $d or die $!;
 380     }
 381     close PF or die $!;
 382 }
 383
 384 #---------- remote protocol support, responder ----------
 385
 386 sub responder_send_command ($) {
 387     my ($command) = @_;
 388     return unless $we_are_responder;
 389     # called even without $we_are_responder
 390     printdebug ">> $command\n";
 391     print PO $command, "\n" or die $!;
 392 }
 393
 394 sub responder_send_file ($$) {
 395     my ($keyword, $ourfn) = @_;
 396     return unless $we_are_responder;
 397     printdebug "]] $keyword $ourfn\n";
 398     responder_send_command "file $keyword";
 399     protocol_send_file \*PO, $ourfn;
 400 }
 401
 402 sub responder_receive_files ($@) {
 403     my ($keyword, @ourfns) = @_;
 404     die unless $we_are_responder;
 405     printdebug "[[ $keyword @ourfns\n";
 406     responder_send_command "want $keyword";
 407     foreach my $fn (@ourfns) {
 408         protocol_receive_file \*PI, $fn;
 409     }
 410     printdebug "[[\$\n";
 411     protocol_expect { m/^files-end$/ } \*PI;
 412 }
 413
 414 #---------- remote protocol support, initiator ----------
 415
 416 sub initiator_expect (&) {
 417     my ($match) = @_;
 418     protocol_expect { &$match } \*RO;
 419 }
 420
 421 #---------- end remote code ----------
 422
 423 sub progress {
 424     if ($we_are_responder) {
 425         my $m = join '', @_;
 426         responder_send_command "progress ".length($m) or die $!;
 427         print PO $m or die $!;
 428     } else {
 429         print @_, "\n";
 430     }
 431 }
 432
 433 our $ua;
 434
 435 sub url_get {
 436     if (!$ua) {
 437         $ua = LWP::UserAgent->new();
 438         $ua->env_proxy;
 439     }
 440     my $what = $_[$#_];
 441     progress "downloading $what...";
 442     my $r = $ua->get(@_) or die $!;
 443     return undef if $r->code == 404;
 444     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 445     return $r->decoded_content(charset => 'none');
 446 }
 447
 448 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 449
 450 sub runcmd {
 451     debugcmd "+",@_;
 452     $!=0; $?=-1;
 453     failedcmd @_ if system @_;
 454 }
 455
 456 sub act_local () { return $dryrun_level <= 1; }
 457 sub act_scary () { return !$dryrun_level; }
 458
 459 sub printdone {
 460     if (!$dryrun_level) {
 461         progress "dgit ok: @_";
 462     } else {
 463         progress "would be ok: @_ (but dry run only)";
 464     }
 465 }
 466
 467 sub dryrun_report {
 468     printcmd(\*STDERR,$debugprefix."#",@_);
 469 }
 470
 471 sub runcmd_ordryrun {
 472     if (act_scary()) {
 473         runcmd @_;
 474     } else {
 475         dryrun_report @_;
 476     }
 477 }
 478
 479 sub runcmd_ordryrun_local {
 480     if (act_local()) {
 481         runcmd @_;
 482     } else {
 483         dryrun_report @_;
 484     }
 485 }
 486
 487 sub shell_cmd {
 488     my ($first_shell, @cmd) = @_;
 489     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 490 }
 491
 492 our $helpmsg = <<END;
 493 main usages:
 494   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 495   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 496   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 497   dgit [dgit-opts] sbuild [sbuild-opts]
 498   dgit [dgit-opts] push [dgit-opts] [suite]
 499   dgit [dgit-opts] rpush build-host:build-dir ...
 500 important dgit options:
 501   -k<keyid>           sign tag and package with <keyid> instead of default
 502   --dry-run -n        do not change anything, but go through the motions
 503   --damp-run -L       like --dry-run but make local changes, without signing
 504   --new -N            allow introducing a new package
 505   --debug -D          increase debug level
 506   -c<name>=<value>    set git config option (used directly by dgit too)
 507 END
 508
 509 our $later_warning_msg = <<END;
 510 Perhaps the upload is stuck in incoming.  Using the version from git.
 511 END
 512
 513 sub badusage {
 514     print STDERR "$us: @_\n", $helpmsg or die $!;
 515     exit 8;
 516 }
 517
 518 sub nextarg {
 519     @ARGV or badusage "too few arguments";
 520     return scalar shift @ARGV;
 521 }
 522
 523 sub cmd_help () {
 524     print $helpmsg or die $!;
 525     exit 0;
 526 }
 527
 528 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 529
 530 our %defcfg = ('dgit.default.distro' => 'debian',
 531                'dgit.default.username' => '',
 532                'dgit.default.archive-query-default-component' => 'main',
 533                'dgit.default.ssh' => 'ssh',
 534                'dgit.default.archive-query' => 'madison:',
 535                'dgit.default.sshpsql-dbname' => 'service=projectb',
 536                'dgit.default.dgit-tag-format' => 'old,new,maint',
 537                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 538                'dgit-distro.debian.git-check' => 'url',
 539                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 540                'dgit-distro.debian.new-private-pushers' => 't',
 541                'dgit-distro.debian.dgit-tag-format' => 'old',
 542                'dgit-distro.debian/push.git-url' => '',
 543                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 544                'dgit-distro.debian/push.git-user-force' => 'dgit',
 545                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 546                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 547                'dgit-distro.debian/push.git-create' => 'true',
 548                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 549  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 550 # 'dgit-distro.debian.archive-query-tls-key',
 551 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 552 # ^ this does not work because curl is broken nowadays
 553 # Fixing #790093 properly will involve providing providing the key
 554 # in some pacagke and maybe updating these paths.
 555 #
 556 # 'dgit-distro.debian.archive-query-tls-curl-args',
 557 #   '--ca-path=/etc/ssl/ca-debian',
 558 # ^ this is a workaround but works (only) on DSA-administered machines
 559                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 560                'dgit-distro.debian.git-url-suffix' => '',
 561                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 562                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 563  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 564  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 565                'dgit-distro.ubuntu.git-check' => 'false',
 566  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 567                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 568                'dgit-distro.test-dummy.username' => "alice",
 569                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 570                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 571                'dgit-distro.test-dummy.git-url' => "$td/git",
 572                'dgit-distro.test-dummy.git-host' => "git",
 573                'dgit-distro.test-dummy.git-path' => "$td/git",
 574                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 575                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 576                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 577                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 578                );
 579
 580 our %gitcfg;
 581
 582 sub git_slurp_config () {
 583     local ($debuglevel) = $debuglevel-2;
 584     local $/="\0";
 585
 586     my @cmd = (@git, qw(config -z --get-regexp .*));
 587     debugcmd "|",@cmd;
 588
 589     open GITS, "-|", @cmd or die $!;
 590     while (<GITS>) {
 591         chomp or die;
 592         printdebug "=> ", (messagequote $_), "\n";
 593         m/\n/ or die "$_ ?";
 594         push @{ $gitcfg{$`} }, $'; #';
 595     }
 596     $!=0; $?=0;
 597     close GITS
 598         or ($!==0 && $?==256)
 599         or failedcmd @cmd;
 600 }
 601
 602 sub git_get_config ($) {
 603     my ($c) = @_;
 604     my $l = $gitcfg{$c};
 605     printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
 606         if $debuglevel >= 4;
 607     $l or return undef;
 608     @$l==1 or badcfg "multiple values for $c" if @$l > 1;
 609     return $l->[0];
 610 }
 611
 612 sub cfg {
 613     foreach my $c (@_) {
 614         return undef if $c =~ /RETURN-UNDEF/;
 615         my $v = git_get_config($c);
 616         return $v if defined $v;
 617         my $dv = $defcfg{$c};
 618         return $dv if defined $dv;
 619     }
 620     badcfg "need value for one of: @_\n".
 621         "$us: distro or suite appears not to be (properly) supported";
 622 }
 623
 624 sub access_basedistro () {
 625     if (defined $idistro) {
 626         return $idistro;
 627     } else {
 628         return cfg("dgit-suite.$isuite.distro",
 629                    "dgit.default.distro");
 630     }
 631 }
 632
 633 sub access_quirk () {
 634     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 635     my $basedistro = access_basedistro();
 636     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 637                               'RETURN-UNDEF');
 638     if (defined $backports_quirk) {
 639         my $re = $backports_quirk;
 640         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 641         $re =~ s/\*/.*/g;
 642         $re =~ s/\%/([-0-9a-z_]+)/
 643             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 644         if ($isuite =~ m/^$re$/) {
 645             return ('backports',"$basedistro-backports",$1);
 646         }
 647     }
 648     return ('none',undef);
 649 }
 650
 651 our $access_forpush;
 652
 653 sub parse_cfg_bool ($$$) {
 654     my ($what,$def,$v) = @_;
 655     $v //= $def;
 656     return
 657         $v =~ m/^[ty1]/ ? 1 :
 658         $v =~ m/^[fn0]/ ? 0 :
 659         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 660 }
 661
 662 sub access_forpush_config () {
 663     my $d = access_basedistro();
 664
 665     return 1 if
 666         $new_package &&
 667         parse_cfg_bool('new-private-pushers', 0,
 668                        cfg("dgit-distro.$d.new-private-pushers",
 669                            'RETURN-UNDEF'));
 670
 671     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 672     $v //= 'a';
 673     return
 674         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 675         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 676         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 677         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 678 }
 679
 680 sub access_forpush () {
 681     $access_forpush //= access_forpush_config();
 682     return $access_forpush;
 683 }
 684
 685 sub pushing () {
 686     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 687     badcfg "pushing but distro is configured readonly"
 688         if access_forpush_config() eq '0';
 689     $access_forpush = 1;
 690     $supplementary_message = <<'END' unless $we_are_responder;
 691 Push failed, before we got started.
 692 You can retry the push, after fixing the problem, if you like.
 693 END
 694     finalise_opts_opts();
 695 }
 696
 697 sub notpushing () {
 698     finalise_opts_opts();
 699 }
 700
 701 sub supplementary_message ($) {
 702     my ($msg) = @_;
 703     if (!$we_are_responder) {
 704         $supplementary_message = $msg;
 705         return;
 706     } elsif ($protovsn >= 3) {
 707         responder_send_command "supplementary-message ".length($msg)
 708             or die $!;
 709         print PO $msg or die $!;
 710     }
 711 }
 712
 713 sub access_distros () {
 714     # Returns list of distros to try, in order
 715     #
 716     # We want to try:
 717     #    0. `instead of' distro name(s) we have been pointed to
 718     #    1. the access_quirk distro, if any
 719     #    2a. the user's specified distro, or failing that  } basedistro
 720     #    2b. the distro calculated from the suite          }
 721     my @l = access_basedistro();
 722
 723     my (undef,$quirkdistro) = access_quirk();
 724     unshift @l, $quirkdistro;
 725     unshift @l, $instead_distro;
 726     @l = grep { defined } @l;
 727
 728     if (access_forpush()) {
 729         @l = map { ("$_/push", $_) } @l;
 730     }
 731     @l;
 732 }
 733
 734 sub access_cfg_cfgs (@) {
 735     my (@keys) = @_;
 736     my @cfgs;
 737     # The nesting of these loops determines the search order.  We put
 738     # the key loop on the outside so that we search all the distros
 739     # for each key, before going on to the next key.  That means that
 740     # if access_cfg is called with a more specific, and then a less
 741     # specific, key, an earlier distro can override the less specific
 742     # without necessarily overriding any more specific keys.  (If the
 743     # distro wants to override the more specific keys it can simply do
 744     # so; whereas if we did the loop the other way around, it would be
 745     # impossible to for an earlier distro to override a less specific
 746     # key but not the more specific ones without restating the unknown
 747     # values of the more specific keys.
 748     my @realkeys;
 749     my @rundef;
 750     # We have to deal with RETURN-UNDEF specially, so that we don't
 751     # terminate the search prematurely.
 752     foreach (@keys) {
 753         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 754         push @realkeys, $_
 755     }
 756     foreach my $d (access_distros()) {
 757         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 758     }
 759     push @cfgs, map { "dgit.default.$_" } @realkeys;
 760     push @cfgs, @rundef;
 761     return @cfgs;
 762 }
 763
 764 sub access_cfg (@) {
 765     my (@keys) = @_;
 766     my (@cfgs) = access_cfg_cfgs(@keys);
 767     my $value = cfg(@cfgs);
 768     return $value;
 769 }
 770
 771 sub access_cfg_bool ($$) {
 772     my ($def, @keys) = @_;
 773     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 774 }
 775
 776 sub string_to_ssh ($) {
 777     my ($spec) = @_;
 778     if ($spec =~ m/\s/) {
 779         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 780     } else {
 781         return ($spec);
 782     }
 783 }
 784
 785 sub access_cfg_ssh () {
 786     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 787     if (!defined $gitssh) {
 788         return @ssh;
 789     } else {
 790         return string_to_ssh $gitssh;
 791     }
 792 }
 793
 794 sub access_runeinfo ($) {
 795     my ($info) = @_;
 796     return ": dgit ".access_basedistro()." $info ;";
 797 }
 798
 799 sub access_someuserhost ($) {
 800     my ($some) = @_;
 801     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 802     defined($user) && length($user) or
 803         $user = access_cfg("$some-user",'username');
 804     my $host = access_cfg("$some-host");
 805     return length($user) ? "$user\@$host" : $host;
 806 }
 807
 808 sub access_gituserhost () {
 809     return access_someuserhost('git');
 810 }
 811
 812 sub access_giturl (;$) {
 813     my ($optional) = @_;
 814     my $url = access_cfg('git-url','RETURN-UNDEF');
 815     my $suffix;
 816     if (!length $url) {
 817         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 818         return undef unless defined $proto;
 819         $url =
 820             $proto.
 821             access_gituserhost().
 822             access_cfg('git-path');
 823     } else {
 824         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 825     }
 826     $suffix //= '.git';
 827     return "$url/$package$suffix";
 828 }
 829
 830 sub parsecontrolfh ($$;$) {
 831     my ($fh, $desc, $allowsigned) = @_;
 832     our $dpkgcontrolhash_noissigned;
 833     my $c;
 834     for (;;) {
 835         my %opts = ('name' => $desc);
 836         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 837         $c = Dpkg::Control::Hash->new(%opts);
 838         $c->parse($fh,$desc) or die "parsing of $desc failed";
 839         last if $allowsigned;
 840         last if $dpkgcontrolhash_noissigned;
 841         my $issigned= $c->get_option('is_pgp_signed');
 842         if (!defined $issigned) {
 843             $dpkgcontrolhash_noissigned= 1;
 844             seek $fh, 0,0 or die "seek $desc: $!";
 845         } elsif ($issigned) {
 846             fail "control file $desc is (already) PGP-signed. ".
 847                 " Note that dgit push needs to modify the .dsc and then".
 848                 " do the signature itself";
 849         } else {
 850             last;
 851         }
 852     }
 853     return $c;
 854 }
 855
 856 sub parsecontrol {
 857     my ($file, $desc) = @_;
 858     my $fh = new IO::Handle;
 859     open $fh, '<', $file or die "$file: $!";
 860     my $c = parsecontrolfh($fh,$desc);
 861     $fh->error and die $!;
 862     close $fh;
 863     return $c;
 864 }
 865
 866 sub getfield ($$) {
 867     my ($dctrl,$field) = @_;
 868     my $v = $dctrl->{$field};
 869     return $v if defined $v;
 870     fail "missing field $field in ".$v->get_option('name');
 871 }
 872
 873 sub parsechangelog {
 874     my $c = Dpkg::Control::Hash->new();
 875     my $p = new IO::Handle;
 876     my @cmd = (qw(dpkg-parsechangelog), @_);
 877     open $p, '-|', @cmd or die $!;
 878     $c->parse($p);
 879     $?=0; $!=0; close $p or failedcmd @cmd;
 880     return $c;
 881 }
 882
 883 sub commit_getclogp ($) {
 884     # Returns the parsed changelog hashref for a particular commit
 885     my ($objid) = @_;
 886     our %commit_getclogp_memo;
 887     my $memo = $commit_getclogp_memo{$objid};
 888     return $memo if $memo;
 889     mkpath '.git/dgit';
 890     my $mclog = ".git/dgit/clog-$objid";
 891     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 892         "$objid:debian/changelog";
 893     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 894 }
 895
 896 sub must_getcwd () {
 897     my $d = getcwd();
 898     defined $d or fail "getcwd failed: $!";
 899     return $d;
 900 }
 901
 902 our %rmad;
 903
 904 sub archive_query ($) {
 905     my ($method) = @_;
 906     my $query = access_cfg('archive-query','RETURN-UNDEF');
 907     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 908     my $proto = $1;
 909     my $data = $'; #';
 910     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 911 }
 912
 913 sub pool_dsc_subpath ($$) {
 914     my ($vsn,$component) = @_; # $package is implict arg
 915     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 916     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 917 }
 918
 919 #---------- `ftpmasterapi' archive query method (nascent) ----------
 920
 921 sub archive_api_query_cmd ($) {
 922     my ($subpath) = @_;
 923     my @cmd = qw(curl -sS);
 924     my $url = access_cfg('archive-query-url');
 925     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 926         my $host = $1;
 927         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
 928         foreach my $key (split /\:/, $keys) {
 929             $key =~ s/\%HOST\%/$host/g;
 930             if (!stat $key) {
 931                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 932                 next;
 933             }
 934             fail "config requested specific TLS key but do not know".
 935                 " how to get curl to use exactly that EE key ($key)";
 936 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
 937 #           # Sadly the above line does not work because of changes
 938 #           # to gnutls.   The real fix for #790093 may involve
 939 #           # new curl options.
 940             last;
 941         }
 942         # Fixing #790093 properly will involve providing a value
 943         # for this on clients.
 944         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
 945         push @cmd, split / /, $kargs if defined $kargs;
 946     }
 947     push @cmd, $url.$subpath;
 948     return @cmd;
 949 }
 950
 951 sub api_query ($$) {
 952     use JSON;
 953     my ($data, $subpath) = @_;
 954     badcfg "ftpmasterapi archive query method takes no data part"
 955         if length $data;
 956     my @cmd = archive_api_query_cmd($subpath);
 957     my $json = cmdoutput @cmd;
 958     return decode_json($json);
 959 }
 960
 961 sub canonicalise_suite_ftpmasterapi () {
 962     my ($proto,$data) = @_;
 963     my $suites = api_query($data, 'suites');
 964     my @matched;
 965     foreach my $entry (@$suites) {
 966         next unless grep {
 967             my $v = $entry->{$_};
 968             defined $v && $v eq $isuite;
 969         } qw(codename name);
 970         push @matched, $entry;
 971     }
 972     fail "unknown suite $isuite" unless @matched;
 973     my $cn;
 974     eval {
 975         @matched==1 or die "multiple matches for suite $isuite\n";
 976         $cn = "$matched[0]{codename}";
 977         defined $cn or die "suite $isuite info has no codename\n";
 978         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 979     };
 980     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 981         if length $@;
 982     return $cn;
 983 }
 984
 985 sub archive_query_ftpmasterapi () {
 986     my ($proto,$data) = @_;
 987     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 988     my @rows;
 989     my $digester = Digest::SHA->new(256);
 990     foreach my $entry (@$info) {
 991         eval {
 992             my $vsn = "$entry->{version}";
 993             my ($ok,$msg) = version_check $vsn;
 994             die "bad version: $msg\n" unless $ok;
 995             my $component = "$entry->{component}";
 996             $component =~ m/^$component_re$/ or die "bad component";
 997             my $filename = "$entry->{filename}";
 998             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 999                 or die "bad filename";
1000             my $sha256sum = "$entry->{sha256sum}";
1001             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1002             push @rows, [ $vsn, "/pool/$component/$filename",
1003                           $digester, $sha256sum ];
1004         };
1005         die "bad ftpmaster api response: $@\n".Dumper($entry)
1006             if length $@;
1007     }
1008     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1009     return @rows;
1010 }
1011
1012 #---------- `madison' archive query method ----------
1013
1014 sub archive_query_madison {
1015     return map { [ @$_[0..1] ] } madison_get_parse(@_);
1016 }
1017
1018 sub madison_get_parse {
1019     my ($proto,$data) = @_;
1020     die unless $proto eq 'madison';
1021     if (!length $data) {
1022         $data= access_cfg('madison-distro','RETURN-UNDEF');
1023         $data //= access_basedistro();
1024     }
1025     $rmad{$proto,$data,$package} ||= cmdoutput
1026         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1027     my $rmad = $rmad{$proto,$data,$package};
1028
1029     my @out;
1030     foreach my $l (split /\n/, $rmad) {
1031         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1032                   \s*( [^ \t|]+ )\s* \|
1033                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1034                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1035         $1 eq $package or die "$rmad $package ?";
1036         my $vsn = $2;
1037         my $newsuite = $3;
1038         my $component;
1039         if (defined $4) {
1040             $component = $4;
1041         } else {
1042             $component = access_cfg('archive-query-default-component');
1043         }
1044         $5 eq 'source' or die "$rmad ?";
1045         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1046     }
1047     return sort { -version_compare($a->[0],$b->[0]); } @out;
1048 }
1049
1050 sub canonicalise_suite_madison {
1051     # madison canonicalises for us
1052     my @r = madison_get_parse(@_);
1053     @r or fail
1054         "unable to canonicalise suite using package $package".
1055         " which does not appear to exist in suite $isuite;".
1056         " --existing-package may help";
1057     return $r[0][2];
1058 }
1059
1060 #---------- `sshpsql' archive query method ----------
1061
1062 sub sshpsql ($$$) {
1063     my ($data,$runeinfo,$sql) = @_;
1064     if (!length $data) {
1065         $data= access_someuserhost('sshpsql').':'.
1066             access_cfg('sshpsql-dbname');
1067     }
1068     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1069     my ($userhost,$dbname) = ($`,$'); #';
1070     my @rows;
1071     my @cmd = (access_cfg_ssh, $userhost,
1072                access_runeinfo("ssh-psql $runeinfo").
1073                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1074                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1075     debugcmd "|",@cmd;
1076     open P, "-|", @cmd or die $!;
1077     while (<P>) {
1078         chomp or die;
1079         printdebug(">|$_|\n");
1080         push @rows, $_;
1081     }
1082     $!=0; $?=0; close P or failedcmd @cmd;
1083     @rows or die;
1084     my $nrows = pop @rows;
1085     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1086     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1087     @rows = map { [ split /\|/, $_ ] } @rows;
1088     my $ncols = scalar @{ shift @rows };
1089     die if grep { scalar @$_ != $ncols } @rows;
1090     return @rows;
1091 }
1092
1093 sub sql_injection_check {
1094     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1095 }
1096
1097 sub archive_query_sshpsql ($$) {
1098     my ($proto,$data) = @_;
1099     sql_injection_check $isuite, $package;
1100     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1101         SELECT source.version, component.name, files.filename, files.sha256sum
1102           FROM source
1103           JOIN src_associations ON source.id = src_associations.source
1104           JOIN suite ON suite.id = src_associations.suite
1105           JOIN dsc_files ON dsc_files.source = source.id
1106           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1107           JOIN component ON component.id = files_archive_map.component_id
1108           JOIN files ON files.id = dsc_files.file
1109          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1110            AND source.source='$package'
1111            AND files.filename LIKE '%.dsc';
1112 END
1113     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1114     my $digester = Digest::SHA->new(256);
1115     @rows = map {
1116         my ($vsn,$component,$filename,$sha256sum) = @$_;
1117         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1118     } @rows;
1119     return @rows;
1120 }
1121
1122 sub canonicalise_suite_sshpsql ($$) {
1123     my ($proto,$data) = @_;
1124     sql_injection_check $isuite;
1125     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1126         SELECT suite.codename
1127           FROM suite where suite_name='$isuite' or codename='$isuite';
1128 END
1129     @rows = map { $_->[0] } @rows;
1130     fail "unknown suite $isuite" unless @rows;
1131     die "ambiguous $isuite: @rows ?" if @rows>1;
1132     return $rows[0];
1133 }
1134
1135 #---------- `dummycat' archive query method ----------
1136
1137 sub canonicalise_suite_dummycat ($$) {
1138     my ($proto,$data) = @_;
1139     my $dpath = "$data/suite.$isuite";
1140     if (!open C, "<", $dpath) {
1141         $!==ENOENT or die "$dpath: $!";
1142         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1143         return $isuite;
1144     }
1145     $!=0; $_ = <C>;
1146     chomp or die "$dpath: $!";
1147     close C;
1148     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1149     return $_;
1150 }
1151
1152 sub archive_query_dummycat ($$) {
1153     my ($proto,$data) = @_;
1154     canonicalise_suite();
1155     my $dpath = "$data/package.$csuite.$package";
1156     if (!open C, "<", $dpath) {
1157         $!==ENOENT or die "$dpath: $!";
1158         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1159         return ();
1160     }
1161     my @rows;
1162     while (<C>) {
1163         next if m/^\#/;
1164         next unless m/\S/;
1165         die unless chomp;
1166         printdebug "dummycat query $csuite $package $dpath | $_\n";
1167         my @row = split /\s+/, $_;
1168         @row==2 or die "$dpath: $_ ?";
1169         push @rows, \@row;
1170     }
1171     C->error and die "$dpath: $!";
1172     close C;
1173     return sort { -version_compare($a->[0],$b->[0]); } @rows;
1174 }
1175
1176 #---------- tag format handling ----------
1177
1178 sub access_cfg_tagformats () {
1179     split /\,/, access_cfg('dgit-tag-format');
1180 }
1181
1182 sub need_tagformat ($$) {
1183     my ($fmt, $why) = @_;
1184     fail "need to use tag format $fmt ($why) but also need".
1185         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1186         " - no way to proceed"
1187         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1188     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1189 }
1190
1191 sub select_tagformat () {
1192     # sets $tagformatfn
1193     return if $tagformatfn && !$tagformat_want;
1194     die 'bug' if $tagformatfn && $tagformat_want;
1195     # ... $tagformat_want assigned after previous select_tagformat
1196
1197     my (@supported) = grep { $_ ne 'maint' } access_cfg_tagformats();
1198     printdebug "select_tagformat supported @supported\n";
1199
1200     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1201     printdebug "select_tagformat specified @$tagformat_want\n";
1202
1203     my ($fmt,$why,$override) = @$tagformat_want;
1204
1205     fail "target distro supports tag formats @supported".
1206         " but have to use $fmt ($why)"
1207         unless $override
1208             or grep { $_ eq $fmt } @supported;
1209
1210     $tagformat_want = undef;
1211     $tagformat = $fmt;
1212     $tagformatfn = ${*::}{"debiantag_$fmt"};
1213
1214     fail "trying to use unknown tag format \`$fmt' ($why) !"
1215         unless $tagformatfn;
1216 }
1217
1218 #---------- archive query entrypoints and rest of program ----------
1219
1220 sub canonicalise_suite () {
1221     return if defined $csuite;
1222     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1223     $csuite = archive_query('canonicalise_suite');
1224     if ($isuite ne $csuite) {
1225         progress "canonical suite name for $isuite is $csuite";
1226     }
1227 }
1228
1229 sub get_archive_dsc () {
1230     canonicalise_suite();
1231     my @vsns = archive_query('archive_query');
1232     foreach my $vinfo (@vsns) {
1233         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
1234         $dscurl = access_cfg('mirror').$subpath;
1235         $dscdata = url_get($dscurl);
1236         if (!$dscdata) {
1237             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1238             next;
1239         }
1240         if ($digester) {
1241             $digester->reset();
1242             $digester->add($dscdata);
1243             my $got = $digester->hexdigest();
1244             $got eq $digest or
1245                 fail "$dscurl has hash $got but".
1246                     " archive told us to expect $digest";
1247         }
1248         my $dscfh = new IO::File \$dscdata, '<' or die $!;
1249         printdebug Dumper($dscdata) if $debuglevel>1;
1250         $dsc = parsecontrolfh($dscfh,$dscurl,1);
1251         printdebug Dumper($dsc) if $debuglevel>1;
1252         my $fmt = getfield $dsc, 'Format';
1253         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
1254         $dsc_checked = !!$digester;
1255         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1256         return;
1257     }
1258     $dsc = undef;
1259     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1260 }
1261
1262 sub check_for_git ();
1263 sub check_for_git () {
1264     # returns 0 or 1
1265     my $how = access_cfg('git-check');
1266     if ($how eq 'ssh-cmd') {
1267         my @cmd =
1268             (access_cfg_ssh, access_gituserhost(),
1269              access_runeinfo("git-check $package").
1270              " set -e; cd ".access_cfg('git-path').";".
1271              " if test -d $package.git; then echo 1; else echo 0; fi");
1272         my $r= cmdoutput @cmd;
1273         if (defined $r and $r =~ m/^divert (\w+)$/) {
1274             my $divert=$1;
1275             my ($usedistro,) = access_distros();
1276             # NB that if we are pushing, $usedistro will be $distro/push
1277             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1278             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1279             progress "diverting to $divert (using config for $instead_distro)";
1280             return check_for_git();
1281         }
1282         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1283         return $r+0;
1284     } elsif ($how eq 'url') {
1285         my $prefix = access_cfg('git-check-url','git-url');
1286         my $suffix = access_cfg('git-check-suffix','git-suffix',
1287                                 'RETURN-UNDEF') // '.git';
1288         my $url = "$prefix/$package$suffix";
1289         my @cmd = (qw(curl -sS -I), $url);
1290         my $result = cmdoutput @cmd;
1291         $result =~ s/^\S+ 200 .*\n\r?\n//;
1292         # curl -sS -I with https_proxy prints
1293         # HTTP/1.0 200 Connection established
1294         $result =~ m/^\S+ (404|200) /s or
1295             fail "unexpected results from git check query - ".
1296                 Dumper($prefix, $result);
1297         my $code = $1;
1298         if ($code eq '404') {
1299             return 0;
1300         } elsif ($code eq '200') {
1301             return 1;
1302         } else {
1303             die;
1304         }
1305     } elsif ($how eq 'true') {
1306         return 1;
1307     } elsif ($how eq 'false') {
1308         return 0;
1309     } else {
1310         badcfg "unknown git-check \`$how'";
1311     }
1312 }
1313
1314 sub create_remote_git_repo () {
1315     my $how = access_cfg('git-create');
1316     if ($how eq 'ssh-cmd') {
1317         runcmd_ordryrun
1318             (access_cfg_ssh, access_gituserhost(),
1319              access_runeinfo("git-create $package").
1320              "set -e; cd ".access_cfg('git-path').";".
1321              " cp -a _template $package.git");
1322     } elsif ($how eq 'true') {
1323         # nothing to do
1324     } else {
1325         badcfg "unknown git-create \`$how'";
1326     }
1327 }
1328
1329 our ($dsc_hash,$lastpush_mergeinput);
1330
1331 our $ud = '.git/dgit/unpack';
1332
1333 sub prep_ud (;$) {
1334     my ($d) = @_;
1335     $d //= $ud;
1336     rmtree($d);
1337     mkpath '.git/dgit';
1338     mkdir $d or die $!;
1339 }
1340
1341 sub mktree_in_ud_here () {
1342     runcmd qw(git init -q);
1343     runcmd qw(git config gc.auto 0);
1344     rmtree('.git/objects');
1345     symlink '../../../../objects','.git/objects' or die $!;
1346 }
1347
1348 sub git_write_tree () {
1349     my $tree = cmdoutput @git, qw(write-tree);
1350     $tree =~ m/^\w+$/ or die "$tree ?";
1351     return $tree;
1352 }
1353
1354 sub remove_stray_gits () {
1355     my @gitscmd = qw(find -name .git -prune -print0);
1356     debugcmd "|",@gitscmd;
1357     open GITS, "-|", @gitscmd or die $!;
1358     {
1359         local $/="\0";
1360         while (<GITS>) {
1361             chomp or die;
1362             print STDERR "$us: warning: removing from source package: ",
1363                 (messagequote $_), "\n";
1364             rmtree $_;
1365         }
1366     }
1367     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1368 }
1369
1370 sub mktree_in_ud_from_only_subdir () {
1371     # changes into the subdir
1372     my (@dirs) = <*/.>;
1373     die "@dirs ?" unless @dirs==1;
1374     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1375     my $dir = $1;
1376     changedir $dir;
1377
1378     remove_stray_gits();
1379     mktree_in_ud_here();
1380     my ($format, $fopts) = get_source_format();
1381     if (madformat($format)) {
1382         rmtree '.pc';
1383     }
1384     runcmd @git, qw(add -Af);
1385     my $tree=git_write_tree();
1386     return ($tree,$dir);
1387 }
1388
1389 sub dsc_files_info () {
1390     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1391                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1392                        ['Files',           'Digest::MD5', 'new()']) {
1393         my ($fname, $module, $method) = @$csumi;
1394         my $field = $dsc->{$fname};
1395         next unless defined $field;
1396         eval "use $module; 1;" or die $@;
1397         my @out;
1398         foreach (split /\n/, $field) {
1399             next unless m/\S/;
1400             m/^(\w+) (\d+) (\S+)$/ or
1401                 fail "could not parse .dsc $fname line \`$_'";
1402             my $digester = eval "$module"."->$method;" or die $@;
1403             push @out, {
1404                 Hash => $1,
1405                 Bytes => $2,
1406                 Filename => $3,
1407                 Digester => $digester,
1408             };
1409         }
1410         return @out;
1411     }
1412     fail "missing any supported Checksums-* or Files field in ".
1413         $dsc->get_option('name');
1414 }
1415
1416 sub dsc_files () {
1417     map { $_->{Filename} } dsc_files_info();
1418 }
1419
1420 sub is_orig_file ($;$) {
1421     local ($_) = $_[0];
1422     my $base = $_[1];
1423     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1424     defined $base or return 1;
1425     return $` eq $base;
1426 }
1427
1428 sub make_commit ($) {
1429     my ($file) = @_;
1430     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1431 }
1432
1433 sub clogp_authline ($) {
1434     my ($clogp) = @_;
1435     my $author = getfield $clogp, 'Maintainer';
1436     $author =~ s#,.*##ms;
1437     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1438     my $authline = "$author $date";
1439     $authline =~ m/$git_authline_re/o or
1440         fail "unexpected commit author line format \`$authline'".
1441         " (was generated from changelog Maintainer field)";
1442     return ($1,$2,$3) if wantarray;
1443     return $authline;
1444 }
1445
1446 sub vendor_patches_distro ($$) {
1447     my ($checkdistro, $what) = @_;
1448     return unless defined $checkdistro;
1449
1450     my $series = "debian/patches/\L$checkdistro\E.series";
1451     printdebug "checking for vendor-specific $series ($what)\n";
1452
1453     if (!open SERIES, "<", $series) {
1454         die "$series $!" unless $!==ENOENT;
1455         return;
1456     }
1457     while (<SERIES>) {
1458         next unless m/\S/;
1459         next if m/^\s+\#/;
1460
1461         print STDERR <<END;
1462
1463 Unfortunately, this source package uses a feature of dpkg-source where
1464 the same source package unpacks to different source code on different
1465 distros.  dgit cannot safely operate on such packages on affected
1466 distros, because the meaning of source packages is not stable.
1467
1468 Please ask the distro/maintainer to remove the distro-specific series
1469 files and use a different technique (if necessary, uploading actually
1470 different packages, if different distros are supposed to have
1471 different code).
1472
1473 END
1474         fail "Found active distro-specific series file for".
1475             " $checkdistro ($what): $series, cannot continue";
1476     }
1477     die "$series $!" if SERIES->error;
1478     close SERIES;
1479 }
1480
1481 sub check_for_vendor_patches () {
1482     # This dpkg-source feature doesn't seem to be documented anywhere!
1483     # But it can be found in the changelog (reformatted):
1484
1485     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
1486     #   Author: Raphael Hertzog <hertzog@debian.org>
1487     #   Date: Sun  Oct  3  09:36:48  2010 +0200
1488
1489     #   dpkg-source: correctly create .pc/.quilt_series with alternate
1490     #   series files
1491     #
1492     #   If you have debian/patches/ubuntu.series and you were
1493     #   unpacking the source package on ubuntu, quilt was still
1494     #   directed to debian/patches/series instead of
1495     #   debian/patches/ubuntu.series.
1496     #
1497     #   debian/changelog                        |    3 +++
1498     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
1499     #   2 files changed, 6 insertions(+), 1 deletion(-)
1500
1501     use Dpkg::Vendor;
1502     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
1503     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
1504                          "Dpkg::Vendor \`current vendor'");
1505     vendor_patches_distro(access_basedistro(),
1506                           "distro being accessed");
1507 }
1508
1509 sub generate_commits_from_dsc () {
1510     # See big comment in fetch_from_archive, below.
1511     prep_ud();
1512     changedir $ud;
1513
1514     foreach my $fi (dsc_files_info()) {
1515         my $f = $fi->{Filename};
1516         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1517
1518         link_ltarget "../../../$f", $f
1519             or $!==&ENOENT
1520             or die "$f $!";
1521
1522         complete_file_from_dsc('.', $fi)
1523             or next;
1524
1525         if (is_orig_file($f)) {
1526             link $f, "../../../../$f"
1527                 or $!==&EEXIST
1528                 or die "$f $!";
1529         }
1530     }
1531
1532     my $dscfn = "$package.dsc";
1533
1534     open D, ">", $dscfn or die "$dscfn: $!";
1535     print D $dscdata or die "$dscfn: $!";
1536     close D or die "$dscfn: $!";
1537     my @cmd = qw(dpkg-source);
1538     push @cmd, '--no-check' if $dsc_checked;
1539     push @cmd, qw(-x --), $dscfn;
1540     runcmd @cmd;
1541
1542     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1543     check_for_vendor_patches() if madformat($dsc->{format});
1544     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1545     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1546     my $authline = clogp_authline $clogp;
1547     my $changes = getfield $clogp, 'Changes';
1548     open C, ">../commit.tmp" or die $!;
1549     print C <<END or die $!;
1550 tree $tree
1551 author $authline
1552 committer $authline
1553
1554 $changes
1555
1556 # imported from the archive
1557 END
1558     close C or die $!;
1559     my $rawimport_hash = make_commit qw(../commit.tmp);
1560     my $cversion = getfield $clogp, 'Version';
1561     my $rawimport_mergeinput = {
1562         Commit => $rawimport_hash,
1563         Info => "Import of source package",
1564     };
1565     my @output = ($rawimport_mergeinput);
1566     progress "synthesised git commit from .dsc $cversion";
1567     if ($lastpush_mergeinput) {
1568         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
1569         my $oversion = getfield $oldclogp, 'Version';
1570         my $vcmp =
1571             version_compare($oversion, $cversion);
1572         if ($vcmp < 0) {
1573             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
1574                 { Message => <<END, ReverseParents => 1 });
1575 Record $package ($cversion) in archive suite $csuite
1576 END
1577         } elsif ($vcmp > 0) {
1578             print STDERR <<END or die $!;
1579
1580 Version actually in archive:   $cversion (older)
1581 Last version pushed with dgit: $oversion (newer or same)
1582 $later_warning_msg
1583 END
1584             @output = $lastpush_mergeinput;
1585         } else {
1586             # Same version.  Use what's in the server git branch,
1587             # discarding our own import.  (This could happen if the
1588             # server automatically imports all packages into git.)
1589             @output = $lastpush_mergeinput;
1590         }
1591     }
1592     changedir '../../../..';
1593     rmtree($ud);
1594     return @output;
1595 }
1596
1597 sub complete_file_from_dsc ($$) {
1598     our ($dstdir, $fi) = @_;
1599     # Ensures that we have, in $dir, the file $fi, with the correct
1600     # contents.  (Downloading it from alongside $dscurl if necessary.)
1601
1602     my $f = $fi->{Filename};
1603     my $tf = "$dstdir/$f";
1604     my $downloaded = 0;
1605
1606     if (stat_exists $tf) {
1607         progress "using existing $f";
1608     } else {
1609         my $furl = $dscurl;
1610         $furl =~ s{/[^/]+$}{};
1611         $furl .= "/$f";
1612         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
1613         die "$f ?" if $f =~ m#/#;
1614         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1615         return 0 if !act_local();
1616         $downloaded = 1;
1617     }
1618
1619     open F, "<", "$tf" or die "$tf: $!";
1620     $fi->{Digester}->reset();
1621     $fi->{Digester}->addfile(*F);
1622     F->error and die $!;
1623     my $got = $fi->{Digester}->hexdigest();
1624     $got eq $fi->{Hash} or
1625         fail "file $f has hash $got but .dsc".
1626             " demands hash $fi->{Hash} ".
1627             ($downloaded ? "(got wrong file from archive!)"
1628              : "(perhaps you should delete this file?)");
1629
1630     return 1;
1631 }
1632
1633 sub ensure_we_have_orig () {
1634     foreach my $fi (dsc_files_info()) {
1635         my $f = $fi->{Filename};
1636         next unless is_orig_file($f);
1637         complete_file_from_dsc('..', $fi)
1638             or next;
1639     }
1640 }
1641
1642 sub git_fetch_us () {
1643     # Want to fetch only what we are going to use, unless
1644     # deliberately-not-ff, in which case we must fetch everything.
1645
1646     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
1647         map { "tags/$_" }
1648         (quiltmode_splitbrain
1649          ? (map { $_->('*',access_basedistro) }
1650             \&debiantag_new, \&debiantag_maintview)
1651          : debiantags('*',access_basedistro));
1652     push @specs, server_branch($csuite);
1653     push @specs, qw(heads/*) if deliberately_not_fast_forward;
1654
1655     # This is rather miserable:
1656     # When git-fetch --prune is passed a fetchspec ending with a *,
1657     # it does a plausible thing.  If there is no * then:
1658     # - it matches subpaths too, even if the supplied refspec
1659     #   starts refs, and behaves completely madly if the source
1660     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
1661     # - if there is no matching remote ref, it bombs out the whole
1662     #   fetch.
1663     # We want to fetch a fixed ref, and we don't know in advance
1664     # if it exists, so this is not suitable.
1665     #
1666     # Our workaround is to use git-ls-remote.  git-ls-remote has its
1667     # own qairks.  Notably, it has the absurd multi-tail-matching
1668     # behaviour: git-ls-remote R refs/foo can report refs/foo AND
1669     # refs/refs/foo etc.
1670     #
1671     # Also, we want an idempotent snapshot, but we have to make two
1672     # calls to the remote: one to git-ls-remote and to git-fetch.  The
1673     # solution is use git-ls-remote to obtain a target state, and
1674     # git-fetch to try to generate it.  If we don't manage to generate
1675     # the target state, we try again.
1676
1677     my $specre = join '|', map {
1678         my $x = $_;
1679         $x =~ s/\W/\\$&/g;
1680         $x =~ s/\\\*$/.*/;
1681         "(?:refs/$x)";
1682     } @specs;
1683     printdebug "git_fetch_us specre=$specre\n";
1684     my $wanted_rref = sub {
1685         local ($_) = @_;
1686         return m/^(?:$specre)$/o;
1687     };
1688
1689     my $fetch_iteration = 0;
1690     FETCH_ITERATION:
1691     for (;;) {
1692         if (++$fetch_iteration > 10) {
1693             fail "too many iterations trying to get sane fetch!";
1694         }
1695
1696         my @look = map { "refs/$_" } @specs;
1697         my @lcmd = (@git, qw(ls-remote -q --refs), access_giturl(), @look);
1698         debugcmd "|",@lcmd;
1699
1700         my %wantr;
1701         open GITLS, "-|", @lcmd or die $!;
1702         while (<GITLS>) {
1703             printdebug "=> ", $_;
1704             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
1705             my ($objid,$rrefname) = ($1,$2);
1706             if (!$wanted_rref->($rrefname)) {
1707                 print STDERR <<END;
1708 warning: git-ls-remote @look reported $rrefname; this is silly, ignoring it.
1709 END
1710                 next;
1711             }
1712             $wantr{$rrefname} = $objid;
1713         }
1714         $!=0; $?=0;
1715         close GITLS or failedcmd @lcmd;
1716
1717         # OK, now %want is exactly what we want for refs in @specs
1718         my @fspecs = map {
1719             return () if !m/\*$/ && !exists $wantr{"refs/$_"};
1720             "+refs/$_:".lrfetchrefs."/$_";
1721         } @specs;
1722
1723         my @fcmd = (@git, qw(fetch -p -n -q), access_giturl(), @fspecs);
1724         runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(),
1725             @fspecs;
1726
1727         %lrfetchrefs_f = ();
1728         my %objgot;
1729
1730         git_for_each_ref(lrfetchrefs, sub {
1731             my ($objid,$objtype,$lrefname,$reftail) = @_;
1732             $lrfetchrefs_f{$lrefname} = $objid;
1733             $objgot{$objid} = 1;
1734         });
1735
1736         foreach my $lrefname (sort keys %lrfetchrefs_f) {
1737             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
1738             if (!exists $wantr{$rrefname}) {
1739                 if ($wanted_rref->($rrefname)) {
1740                     printdebug <<END;
1741 git-fetch @fspecs created $lrefname which git-ls-remote @look didn't list.
1742 END
1743                 } else {
1744                     print STDERR <<END
1745 warning: git-fetch @fspecs created $lrefname; this is silly, deleting it.
1746 END
1747                 }
1748                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
1749                 delete $lrfetchrefs_f{$lrefname};
1750                 next;
1751             }
1752         }
1753         foreach my $rrefname (sort keys %wantr) {
1754             my $lrefname = lrfetchrefs.substr($rrefname, 4);
1755             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
1756             my $want = $wantr{$rrefname};
1757             next if $got eq $want;
1758             if (!defined $objgot{$want}) {
1759                 print STDERR <<END;
1760 warning: git-ls-remote suggests we want $lrefname
1761 warning:  and it should refer to $want
1762 warning:  but git-fetch didn't fetch that object to any relevant ref.
1763 warning:  This may be due to a race with someone updating the server.
1764 warning:  Will try again...
1765 END
1766                 next FETCH_ITERATION;
1767             }
1768             printdebug <<END;
1769 git-fetch @fspecs made $lrefname=$got but want git-ls-remote @look says $want
1770 END
1771             runcmd_ordryrun_local @git, qw(update-ref -m),
1772                 "dgit fetch git-fetch fixup", $lrefname, $want;
1773             $lrfetchrefs_f{$lrefname} = $want;
1774         }
1775         last;
1776     }
1777     printdebug "git_fetch_us: git-fetch --no-insane emulation complete\n",
1778         Dumper(\%lrfetchrefs_f);
1779
1780     my %here;
1781     my @tagpats = debiantags('*',access_basedistro);
1782
1783     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
1784         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1785         printdebug "currently $fullrefname=$objid\n";
1786         $here{$fullrefname} = $objid;
1787     });
1788     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
1789         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1790         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
1791         printdebug "offered $lref=$objid\n";
1792         if (!defined $here{$lref}) {
1793             my @upd = (@git, qw(update-ref), $lref, $objid, '');
1794             runcmd_ordryrun_local @upd;
1795             lrfetchref_used $fullrefname;
1796         } elsif ($here{$lref} eq $objid) {
1797             lrfetchref_used $fullrefname;
1798         } else {
1799             print STDERR \
1800                 "Not updateting $lref from $here{$lref} to $objid.\n";
1801         }
1802     });
1803 }
1804
1805 sub mergeinfo_getclogp ($) {
1806     # Ensures thit $mi->{Clogp} exists and returns it
1807     my ($mi) = @_;
1808     $mi->{Clogp} = commit_getclogp($mi->{Commit});
1809 }
1810
1811 sub mergeinfo_version ($) {
1812     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
1813 }
1814
1815 sub fetch_from_archive () {
1816     # Ensures that lrref() is what is actually in the archive, one way
1817     # or another, according to us - ie this client's
1818     # appropritaely-updated archive view.  Also returns the commit id.
1819     # If there is nothing in the archive, leaves lrref alone and
1820     # returns undef.  git_fetch_us must have already been called.
1821     get_archive_dsc();
1822
1823     if ($dsc) {
1824         foreach my $field (@ourdscfield) {
1825             $dsc_hash = $dsc->{$field};
1826             last if defined $dsc_hash;
1827         }
1828         if (defined $dsc_hash) {
1829             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1830             $dsc_hash = $&;
1831             progress "last upload to archive specified git hash";
1832         } else {
1833             progress "last upload to archive has NO git hash";
1834         }
1835     } else {
1836         progress "no version available from the archive";
1837     }
1838
1839     # If the archive's .dsc has a Dgit field, there are three
1840     # relevant git commitids we need to choose between and/or merge
1841     # together:
1842     #   1. $dsc_hash: the Dgit field from the archive
1843     #   2. $lastpush_hash: the suite branch on the dgit git server
1844     #   3. $lastfetch_hash: our local tracking brach for the suite
1845     #
1846     # These may all be distinct and need not be in any fast forward
1847     # relationship:
1848     #
1849     # If the dsc was pushed to this suite, then the server suite
1850     # branch will have been updated; but it might have been pushed to
1851     # a different suite and copied by the archive.  Conversely a more
1852     # recent version may have been pushed with dgit but not appeared
1853     # in the archive (yet).
1854     #
1855     # $lastfetch_hash may be awkward because archive imports
1856     # (particularly, imports of Dgit-less .dscs) are performed only as
1857     # needed on individual clients, so different clients may perform a
1858     # different subset of them - and these imports are only made
1859     # public during push.  So $lastfetch_hash may represent a set of
1860     # imports different to a subsequent upload by a different dgit
1861     # client.
1862     #
1863     # Our approach is as follows:
1864     #
1865     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
1866     # descendant of $dsc_hash, then it was pushed by a dgit user who
1867     # had based their work on $dsc_hash, so we should prefer it.
1868     # Otherwise, $dsc_hash was installed into this suite in the
1869     # archive other than by a dgit push, and (necessarily) after the
1870     # last dgit push into that suite (since a dgit push would have
1871     # been descended from the dgit server git branch); thus, in that
1872     # case, we prefer the archive's version (and produce a
1873     # pseudo-merge to overwrite the dgit server git branch).
1874     #
1875     # (If there is no Dgit field in the archive's .dsc then
1876     # generate_commit_from_dsc uses the version numbers to decide
1877     # whether the suite branch or the archive is newer.  If the suite
1878     # branch is newer it ignores the archive's .dsc; otherwise it
1879     # generates an import of the .dsc, and produces a pseudo-merge to
1880     # overwrite the suite branch with the archive contents.)
1881     #
1882     # The outcome of that part of the algorithm is the `public view',
1883     # and is same for all dgit clients: it does not depend on any
1884     # unpublished history in the local tracking branch.
1885     #
1886     # As between the public view and the local tracking branch: The
1887     # local tracking branch is only updated by dgit fetch, and
1888     # whenever dgit fetch runs it includes the public view in the
1889     # local tracking branch.  Therefore if the public view is not
1890     # descended from the local tracking branch, the local tracking
1891     # branch must contain history which was imported from the archive
1892     # but never pushed; and, its tip is now out of date.  So, we make
1893     # a pseudo-merge to overwrite the old imports and stitch the old
1894     # history in.
1895     #
1896     # Finally: we do not necessarily reify the public view (as
1897     # described above).  This is so that we do not end up stacking two
1898     # pseudo-merges.  So what we actually do is figure out the inputs
1899     # to any public view pseudo-merge and put them in @mergeinputs.
1900
1901     my @mergeinputs;
1902     # $mergeinputs[]{Commit}
1903     # $mergeinputs[]{Info}
1904     # $mergeinputs[0] is the one whose tree we use
1905     # @mergeinputs is in the order we use in the actual commit)
1906     #
1907     # Also:
1908     # $mergeinputs[]{Message} is a commit message to use
1909     # $mergeinputs[]{ReverseParents} if def specifies that parent
1910     #                                list should be in opposite order
1911     # Such an entry has no Commit or Info.  It applies only when found
1912     # in the last entry.  (This ugliness is to support making
1913     # identical imports to previous dgit versions.)
1914
1915     my $lastpush_hash = git_get_ref(lrfetchref());
1916     printdebug "previous reference hash=$lastpush_hash\n";
1917     $lastpush_mergeinput = $lastpush_hash && {
1918         Commit => $lastpush_hash,
1919         Info => "dgit suite branch on dgit git server",
1920     };
1921
1922     my $lastfetch_hash = git_get_ref(lrref());
1923     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
1924     my $lastfetch_mergeinput = $lastfetch_hash && {
1925         Commit => $lastfetch_hash,
1926         Info => "dgit client's archive history view",
1927     };
1928
1929     my $dsc_mergeinput = $dsc_hash && {
1930         Commit => $dsc_hash,
1931         Info => "Dgit field in .dsc from archive",
1932     };
1933
1934     my $cwd = getcwd();
1935     my $del_lrfetchrefs = sub {
1936         changedir $cwd;
1937         my $gur;
1938         printdebug "del_lrfetchrefs...\n";
1939         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
1940             my $objid = $lrfetchrefs_d{$fullrefname};
1941             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
1942             if (!$gur) {
1943                 $gur ||= new IO::Handle;
1944                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
1945             }
1946             printf $gur "delete %s %s\n", $fullrefname, $objid;
1947         }
1948         if ($gur) {
1949             close $gur or failedcmd "git update-ref delete lrfetchrefs";
1950         }
1951     };
1952
1953     if (defined $dsc_hash) {
1954         fail "missing remote git history even though dsc has hash -".
1955             " could not find ref ".rref()." at ".access_giturl()
1956             unless $lastpush_hash;
1957         ensure_we_have_orig();
1958         if ($dsc_hash eq $lastpush_hash) {
1959             @mergeinputs = $dsc_mergeinput
1960         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1961             print STDERR <<END or die $!;
1962
1963 Git commit in archive is behind the last version allegedly pushed/uploaded.
1964 Commit referred to by archive: $dsc_hash
1965 Last version pushed with dgit: $lastpush_hash
1966 $later_warning_msg
1967 END
1968             @mergeinputs = ($lastpush_mergeinput);
1969         } else {
1970             # Archive has .dsc which is not a descendant of the last dgit
1971             # push.  This can happen if the archive moves .dscs about.
1972             # Just follow its lead.
1973             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
1974                 progress "archive .dsc names newer git commit";
1975                 @mergeinputs = ($dsc_mergeinput);
1976             } else {
1977                 progress "archive .dsc names other git commit, fixing up";
1978                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
1979             }
1980         }
1981     } elsif ($dsc) {
1982         @mergeinputs = generate_commits_from_dsc();
1983         # We have just done an import.  Now, our import algorithm might
1984         # have been improved.  But even so we do not want to generate
1985         # a new different import of the same package.  So if the
1986         # version numbers are the same, just use our existing version.
1987         # If the version numbers are different, the archive has changed
1988         # (perhaps, rewound).
1989         if ($lastfetch_mergeinput &&
1990             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
1991                               (mergeinfo_version $mergeinputs[0]) )) {
1992             @mergeinputs = ($lastfetch_mergeinput);
1993         }
1994     } elsif ($lastpush_hash) {
1995         # only in git, not in the archive yet
1996         @mergeinputs = ($lastpush_mergeinput);
1997         print STDERR <<END or die $!;
1998
1999 Package not found in the archive, but has allegedly been pushed using dgit.
2000 $later_warning_msg
2001 END
2002     } else {
2003         printdebug "nothing found!\n";
2004         if (defined $skew_warning_vsn) {
2005             print STDERR <<END or die $!;
2006
2007 Warning: relevant archive skew detected.
2008 Archive allegedly contains $skew_warning_vsn
2009 But we were not able to obtain any version from the archive or git.
2010
2011 END
2012         }
2013         unshift @end, $del_lrfetchrefs;
2014         return undef;
2015     }
2016
2017     if ($lastfetch_hash &&
2018         !grep {
2019             my $h = $_->{Commit};
2020             $h and is_fast_fwd($lastfetch_hash, $h);
2021             # If true, one of the existing parents of this commit
2022             # is a descendant of the $lastfetch_hash, so we'll
2023             # be ff from that automatically.
2024         } @mergeinputs
2025         ) {
2026         # Otherwise:
2027         push @mergeinputs, $lastfetch_mergeinput;
2028     }
2029
2030     printdebug "fetch mergeinfos:\n";
2031     foreach my $mi (@mergeinputs) {
2032         if ($mi->{Info}) {
2033             printdebug " commit $mi->{Commit} $mi->{Info}\n";
2034         } else {
2035             printdebug sprintf " ReverseParents=%d Message=%s",
2036                 $mi->{ReverseParents}, $mi->{Message};
2037         }
2038     }
2039
2040     my $compat_info= pop @mergeinputs
2041         if $mergeinputs[$#mergeinputs]{Message};
2042
2043     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
2044
2045     my $hash;
2046     if (@mergeinputs > 1) {
2047         # here we go, then:
2048         my $tree_commit = $mergeinputs[0]{Commit};
2049
2050         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
2051         $tree =~ m/\n\n/;  $tree = $`;
2052         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
2053         $tree = $1;
2054
2055         # We use the changelog author of the package in question the
2056         # author of this pseudo-merge.  This is (roughly) correct if
2057         # this commit is simply representing aa non-dgit upload.
2058         # (Roughly because it does not record sponsorship - but we
2059         # don't have sponsorship info because that's in the .changes,
2060         # which isn't in the archivw.)
2061         #
2062         # But, it might be that we are representing archive history
2063         # updates (including in-archive copies).  These are not really
2064         # the responsibility of the person who created the .dsc, but
2065         # there is no-one whose name we should better use.  (The
2066         # author of the .dsc-named commit is clearly worse.)
2067
2068         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
2069         my $author = clogp_authline $useclogp;
2070         my $cversion = getfield $useclogp, 'Version';
2071
2072         my $mcf = ".git/dgit/mergecommit";
2073         open MC, ">", $mcf or die "$mcf $!";
2074         print MC <<END or die $!;
2075 tree $tree
2076 END
2077
2078         my @parents = grep { $_->{Commit} } @mergeinputs;
2079         @parents = reverse @parents if $compat_info->{ReverseParents};
2080         print MC <<END or die $! foreach @parents;
2081 parent $_->{Commit}
2082 END
2083
2084         print MC <<END or die $!;
2085 author $author
2086 committer $author
2087
2088 END
2089
2090         if (defined $compat_info->{Message}) {
2091             print MC $compat_info->{Message} or die $!;
2092         } else {
2093             print MC <<END or die $!;
2094 Record $package ($cversion) in archive suite $csuite
2095
2096 Record that
2097 END
2098             my $message_add_info = sub {
2099                 my ($mi) = (@_);
2100                 my $mversion = mergeinfo_version $mi;
2101                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
2102                     or die $!;
2103             };
2104
2105             $message_add_info->($mergeinputs[0]);
2106             print MC <<END or die $!;
2107 should be treated as descended from
2108 END
2109             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
2110         }
2111
2112         close MC or die $!;
2113         $hash = make_commit $mcf;
2114     } else {
2115         $hash = $mergeinputs[0]{Commit};
2116     }
2117     progress "fetch hash=$hash\n";
2118
2119     my $chkff = sub {
2120         my ($lasth, $what) = @_;
2121         return unless $lasth;
2122         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
2123     };
2124
2125     $chkff->($lastpush_hash, 'dgit repo server tip (last push)');
2126     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
2127
2128     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2129             'DGIT_ARCHIVE', $hash;
2130     cmdoutput @git, qw(log -n2), $hash;
2131     # ... gives git a chance to complain if our commit is malformed
2132
2133     if (defined $skew_warning_vsn) {
2134         mkpath '.git/dgit';
2135         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
2136         my $gotclogp = commit_getclogp($hash);
2137         my $got_vsn = getfield $gotclogp, 'Version';
2138         printdebug "SKEW CHECK GOT $got_vsn\n";
2139         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
2140             print STDERR <<END or die $!;
2141
2142 Warning: archive skew detected.  Using the available version:
2143 Archive allegedly contains    $skew_warning_vsn
2144 We were able to obtain only   $got_vsn
2145
2146 END
2147         }
2148     }
2149
2150     if ($lastfetch_hash ne $hash) {
2151         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2152         if (act_local()) {
2153             cmdoutput @upd_cmd;
2154         } else {
2155             dryrun_report @upd_cmd;
2156         }
2157     }
2158
2159     lrfetchref_used lrfetchref();
2160
2161     unshift @end, $del_lrfetchrefs;
2162     return $hash;
2163 }
2164
2165 sub set_local_git_config ($$) {
2166     my ($k, $v) = @_;
2167     runcmd @git, qw(config), $k, $v;
2168 }
2169
2170 sub setup_mergechangelogs (;$) {
2171     my ($always) = @_;
2172     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
2173
2174     my $driver = 'dpkg-mergechangelogs';
2175     my $cb = "merge.$driver";
2176     my $attrs = '.git/info/attributes';
2177     ensuredir '.git/info';
2178
2179     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
2180     if (!open ATTRS, "<", $attrs) {
2181         $!==ENOENT or die "$attrs: $!";
2182     } else {
2183         while (<ATTRS>) {
2184             chomp;
2185             next if m{^debian/changelog\s};
2186             print NATTRS $_, "\n" or die $!;
2187         }
2188         ATTRS->error and die $!;
2189         close ATTRS;
2190     }
2191     print NATTRS "debian/changelog merge=$driver\n" or die $!;
2192     close NATTRS;
2193
2194     set_local_git_config "$cb.name", 'debian/changelog merge driver';
2195     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
2196
2197     rename "$attrs.new", "$attrs" or die "$attrs: $!";
2198 }
2199
2200 sub setup_useremail (;$) {
2201     my ($always) = @_;
2202     return unless $always || access_cfg_bool(1, 'setup-useremail');
2203
2204     my $setup = sub {
2205         my ($k, $envvar) = @_;
2206         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
2207         return unless defined $v;
2208         set_local_git_config "user.$k", $v;
2209     };
2210
2211     $setup->('email', 'DEBEMAIL');
2212     $setup->('name', 'DEBFULLNAME');
2213 }
2214
2215 sub setup_new_tree () {
2216     setup_mergechangelogs();
2217     setup_useremail();
2218 }
2219
2220 sub clone ($) {
2221     my ($dstdir) = @_;
2222     canonicalise_suite();
2223     badusage "dry run makes no sense with clone" unless act_local();
2224     my $hasgit = check_for_git();
2225     mkdir $dstdir or fail "create \`$dstdir': $!";
2226     changedir $dstdir;
2227     runcmd @git, qw(init -q);
2228     my $giturl = access_giturl(1);
2229     if (defined $giturl) {
2230         open H, "> .git/HEAD" or die $!;
2231         print H "ref: ".lref()."\n" or die $!;
2232         close H or die $!;
2233         runcmd @git, qw(remote add), 'origin', $giturl;
2234     }
2235     if ($hasgit) {
2236         progress "fetching existing git history";
2237         git_fetch_us();
2238         runcmd_ordryrun_local @git, qw(fetch origin);
2239     } else {
2240         progress "starting new git history";
2241     }
2242     fetch_from_archive() or no_such_package;
2243     my $vcsgiturl = $dsc->{'Vcs-Git'};
2244     if (length $vcsgiturl) {
2245         $vcsgiturl =~ s/\s+-b\s+\S+//g;
2246         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
2247     }
2248     setup_new_tree();
2249     runcmd @git, qw(reset --hard), lrref();
2250     printdone "ready for work in $dstdir";
2251 }
2252
2253 sub fetch () {
2254     if (check_for_git()) {
2255         git_fetch_us();
2256     }
2257     fetch_from_archive() or no_such_package();
2258     printdone "fetched into ".lrref();
2259 }
2260
2261 sub pull () {
2262     fetch();
2263     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
2264         lrref();
2265     printdone "fetched to ".lrref()." and merged into HEAD";
2266 }
2267
2268 sub check_not_dirty () {
2269     foreach my $f (qw(local-options local-patch-header)) {
2270         if (stat_exists "debian/source/$f") {
2271             fail "git tree contains debian/source/$f";
2272         }
2273     }
2274
2275     return if $ignoredirty;
2276
2277     my @cmd = (@git, qw(diff --quiet HEAD));
2278     debugcmd "+",@cmd;
2279     $!=0; $?=-1; system @cmd;
2280     return if !$?;
2281     if ($?==256) {
2282         fail "working tree is dirty (does not match HEAD)";
2283     } else {
2284         failedcmd @cmd;
2285     }
2286 }
2287
2288 sub commit_admin ($) {
2289     my ($m) = @_;
2290     progress "$m";
2291     runcmd_ordryrun_local @git, qw(commit -m), $m;
2292 }
2293
2294 sub commit_quilty_patch () {
2295     my $output = cmdoutput @git, qw(status --porcelain);
2296     my %adds;
2297     foreach my $l (split /\n/, $output) {
2298         next unless $l =~ m/\S/;
2299         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
2300             $adds{$1}++;
2301         }
2302     }
2303     delete $adds{'.pc'}; # if there wasn't one before, don't add it
2304     if (!%adds) {
2305         progress "nothing quilty to commit, ok.";
2306         return;
2307     }
2308     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
2309     runcmd_ordryrun_local @git, qw(add -f), @adds;
2310     commit_admin "Commit Debian 3.0 (quilt) metadata";
2311 }
2312
2313 sub get_source_format () {
2314     my %options;
2315     if (open F, "debian/source/options") {
2316         while (<F>) {
2317             next if m/^\s*\#/;
2318             next unless m/\S/;
2319             s/\s+$//; # ignore missing final newline
2320             if (m/\s*\#\s*/) {
2321                 my ($k, $v) = ($`, $'); #');
2322                 $v =~ s/^"(.*)"$/$1/;
2323                 $options{$k} = $v;
2324             } else {
2325                 $options{$_} = 1;
2326             }
2327         }
2328         F->error and die $!;
2329         close F;
2330     } else {
2331         die $! unless $!==&ENOENT;
2332     }
2333
2334     if (!open F, "debian/source/format") {
2335         die $! unless $!==&ENOENT;
2336         return '';
2337     }
2338     $_ = <F>;
2339     F->error and die $!;
2340     chomp;
2341     return ($_, \%options);
2342 }
2343
2344 sub madformat ($) {
2345     my ($format) = @_;
2346     return 0 unless $format eq '3.0 (quilt)';
2347     our $quilt_mode_warned;
2348     if ($quilt_mode eq 'nocheck') {
2349         progress "Not doing any fixup of \`$format' due to".
2350             " ----no-quilt-fixup or --quilt=nocheck"
2351             unless $quilt_mode_warned++;
2352         return 0;
2353     }
2354     progress "Format \`$format', need to check/update patch stack"
2355         unless $quilt_mode_warned++;
2356     return 1;
2357 }
2358
2359 sub splitbrain_pseudomerge ($$$$) {
2360     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
2361     # => $merged_dgitview
2362     printdebug "splitbrain_pseudomerge...\n";
2363     #
2364     #     We:      debian/PREVIOUS    HEAD($maintview)
2365     # expect:          o ----------------- o
2366     #                    \                   \
2367     #                     o                   o
2368     #                 a/d/PREVIOUS        $dgitview
2369     #                $archive_hash              \
2370     #  If so,                \                   \
2371     #  we do:                 `------------------ o
2372     #   this:                                   $dgitview'
2373     #
2374
2375     # We work with tuples [ $thing, $what ]
2376     # (often $thing is a commit hash; $what is a description)
2377
2378     my $tag_lookup = sub {
2379         my ($tagname, $what) = @_;
2380         printdebug "splitbrain_pseudomerge tag_lookup $what\n";
2381         my $lrefname = lrfetchrefs."/tags/$tagname";
2382         my $tagobj = $lrfetchrefs_f{$lrefname};
2383         defined $tagobj or fail <<END;
2384 Wanted tag $tagname ($what) on dgit server, but not found
2385 END
2386         printdebug "splitbrain_pseudomerge tag_lookup $tagobj $what\n";
2387         return [ git_rev_parse($tagobj), $what ];
2388     };
2389
2390     my $cond_equal = sub {
2391         my ($x,$y) = @_;
2392         $x->[0] eq $y->[0] or fail <<END;
2393 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
2394 END
2395     };
2396     my $cond_ff = sub {
2397         my ($anc,$desc) = @_;
2398         is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
2399 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
2400 END
2401     };
2402
2403     my $arch_clogp = commit_getclogp $archive_hash;
2404     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
2405                      'version currently in archive' ];
2406
2407     printdebug "splitbrain_pseudomerge i_arch_v @$i_arch_v\n";
2408
2409     return $dgitview unless defined $archive_hash;
2410
2411     if ($overwrite_version) {
2412         progress "Declaring that HEAD inciudes all changes in archive...";
2413         progress "Checking that $overwrite_version does so...";
2414         $cond_equal->([ $overwrite_version, '--overwrite= version' ],
2415                       $i_arch_v);
2416     } else {
2417         progress "Checking that HEAD inciudes all changes in archive...";
2418     }
2419
2420     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
2421
2422     my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_basedistro;
2423     my $i_dep14 = $tag_lookup->($t_dep14, "maintainer view tag");
2424     my $t_dgit = debiantag_new $i_arch_v->[0], access_basedistro;
2425     my $i_dgit = $tag_lookup->($t_dgit, "dgit view tag");
2426     my $i_archive = [ $archive_hash, "current archive contents" ];
2427
2428     printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
2429
2430     $cond_equal->($i_dgit, $i_archive);
2431     $cond_ff->($i_dep14, $i_dgit);
2432     $overwrite_version or $cond_ff->($i_dep14, [ $maintview, 'HEAD' ]);
2433
2434     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
2435     my $authline = clogp_authline $clogp;
2436
2437     mkpath '.git/dgit';
2438     my $pmf = ".git/dgit/pseudomerge";
2439     open MC, ">", $pmf or die "$pmf $!";
2440     print MC <<END or die $!;
2441 tree $tree
2442 parent $dgitview
2443 parent $archive_hash
2444 author $authline
2445 commiter $authline
2446
2447 END
2448     if ($overwrite_version) {
2449         print MC <<END;
2450 Declare fast forward from $overwrite_version
2451
2452 [dgit --quilt=$quilt_mode --overwrite-version=$overwrite_version]
2453 END
2454     } else {
2455         print MC <<END;
2456 Make fast forward from $i_arch_v->[0]
2457
2458 [dgit --quilt=$quilt_mode]
2459 END
2460     }
2461     close MC or die $!;
2462
2463     progress "Making pseudo-merge of $i_arch_v->[0] into dgit view.";
2464     return make_commit($pmf);
2465 }
2466
2467 sub push_parse_changelog ($) {
2468     my ($clogpfn) = @_;
2469
2470     my $clogp = Dpkg::Control::Hash->new();
2471     $clogp->load($clogpfn) or die;
2472
2473     $package = getfield $clogp, 'Source';
2474     my $cversion = getfield $clogp, 'Version';
2475     my $tag = debiantag($cversion, access_basedistro);
2476     runcmd @git, qw(check-ref-format), $tag;
2477
2478     my $dscfn = dscfn($cversion);
2479
2480     return ($clogp, $cversion, $dscfn);
2481 }
2482
2483 sub push_parse_dsc ($$$) {
2484     my ($dscfn,$dscfnwhat, $cversion) = @_;
2485     $dsc = parsecontrol($dscfn,$dscfnwhat);
2486     my $dversion = getfield $dsc, 'Version';
2487     my $dscpackage = getfield $dsc, 'Source';
2488     ($dscpackage eq $package && $dversion eq $cversion) or
2489         fail "$dscfn is for $dscpackage $dversion".
2490             " but debian/changelog is for $package $cversion";
2491 }
2492
2493 sub push_tagwants ($$$$) {
2494     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
2495     my @tagwants;
2496     push @tagwants, {
2497         TagFn => \&debiantag,
2498         Objid => $dgithead,
2499         TfSuffix => '',
2500         View => 'dgit',
2501     };
2502     if (defined $maintviewhead) {
2503         push @tagwants, {
2504             TagFn => \&debiantag_maintview,
2505             Objid => $maintviewhead,
2506             TfSuffix => '-maintview',
2507             View => 'maint',
2508         };
2509     }
2510     foreach my $tw (@tagwants) {
2511         $tw->{Tag} = $tw->{TagFn}($cversion, access_basedistro);
2512         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
2513     }
2514     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
2515     return @tagwants;
2516 }
2517
2518 sub push_mktags ($$ $$ $) {
2519     my ($clogp,$dscfn,
2520         $changesfile,$changesfilewhat,
2521         $tagwants) = @_;
2522
2523     die unless $tagwants->[0]{View} eq 'dgit';
2524
2525     $dsc->{$ourdscfield[0]} = $tagwants->[0]{Objid};
2526     $dsc->save("$dscfn.tmp") or die $!;
2527
2528     my $changes = parsecontrol($changesfile,$changesfilewhat);
2529     foreach my $field (qw(Source Distribution Version)) {
2530         $changes->{$field} eq $clogp->{$field} or
2531             fail "changes field $field \`$changes->{$field}'".
2532                 " does not match changelog \`$clogp->{$field}'";
2533     }
2534
2535     my $cversion = getfield $clogp, 'Version';
2536     my $clogsuite = getfield $clogp, 'Distribution';
2537
2538     # We make the git tag by hand because (a) that makes it easier
2539     # to control the "tagger" (b) we can do remote signing
2540     my $authline = clogp_authline $clogp;
2541     my $delibs = join(" ", "",@deliberatelies);
2542     my $declaredistro = access_basedistro();
2543
2544     my $mktag = sub {
2545         my ($tw) = @_;
2546         my $tfn = $tw->{Tfn};
2547         my $head = $tw->{Objid};
2548         my $tag = $tw->{Tag};
2549
2550         open TO, '>', $tfn->('.tmp') or die $!;
2551         print TO <<END or die $!;
2552 object $head
2553 type commit
2554 tag $tag
2555 tagger $authline
2556
2557 END
2558         if ($tw->{View} eq 'dgit') {
2559             print TO <<END or die $!;
2560 $package release $cversion for $clogsuite ($csuite) [dgit]
2561 [dgit distro=$declaredistro$delibs]
2562 END
2563             foreach my $ref (sort keys %previously) {
2564                 print TO <<END or die $!;
2565 [dgit previously:$ref=$previously{$ref}]
2566 END
2567             }
2568         } elsif ($tw->{View} eq 'maint') {
2569             print TO <<END or die $!;
2570 $package release $cversion for $clogsuite ($csuite)
2571 (maintainer view tag generated by dgit --quilt=$quilt_mode)
2572 END
2573         } else {
2574             die Dumper($tw)."?";
2575         }
2576
2577         close TO or die $!;
2578
2579         my $tagobjfn = $tfn->('.tmp');
2580         if ($sign) {
2581             if (!defined $keyid) {
2582                 $keyid = access_cfg('keyid','RETURN-UNDEF');
2583             }
2584             if (!defined $keyid) {
2585                 $keyid = getfield $clogp, 'Maintainer';
2586             }
2587             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
2588             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
2589             push @sign_cmd, qw(-u),$keyid if defined $keyid;
2590             push @sign_cmd, $tfn->('.tmp');
2591             runcmd_ordryrun @sign_cmd;
2592             if (act_scary()) {
2593                 $tagobjfn = $tfn->('.signed.tmp');
2594                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
2595                     $tfn->('.tmp'), $tfn->('.tmp.asc');
2596             }
2597         }
2598         return $tagobjfn;
2599     };
2600
2601     my @r = map { $mktag->($_); } @$tagwants;
2602     return @r;
2603 }
2604
2605 sub sign_changes ($) {
2606     my ($changesfile) = @_;
2607     if ($sign) {
2608         my @debsign_cmd = @debsign;
2609         push @debsign_cmd, "-k$keyid" if defined $keyid;
2610         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
2611         push @debsign_cmd, $changesfile;
2612         runcmd_ordryrun @debsign_cmd;
2613     }
2614 }
2615
2616 sub dopush () {
2617     printdebug "actually entering push\n";
2618
2619     supplementary_message(<<'END');
2620 Push failed, while checking state of the archive.
2621 You can retry the push, after fixing the problem, if you like.
2622 END
2623     if (check_for_git()) {
2624         git_fetch_us();
2625     }
2626     my $archive_hash = fetch_from_archive();
2627     if (!$archive_hash) {
2628         $new_package or
2629             fail "package appears to be new in this suite;".
2630                 " if this is intentional, use --new";
2631     }
2632
2633     supplementary_message(<<'END');
2634 Push failed, while preparing your push.
2635 You can retry the push, after fixing the problem, if you like.
2636 END
2637
2638     need_tagformat 'new', "quilt mode $quilt_mode"
2639         if quiltmode_splitbrain;
2640
2641     prep_ud();
2642
2643     access_giturl(); # check that success is vaguely likely
2644     select_tagformat();
2645
2646     my $clogpfn = ".git/dgit/changelog.822.tmp";
2647     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
2648
2649     responder_send_file('parsed-changelog', $clogpfn);
2650
2651     my ($clogp, $cversion, $dscfn) =
2652         push_parse_changelog("$clogpfn");
2653
2654     my $dscpath = "$buildproductsdir/$dscfn";
2655     stat_exists $dscpath or
2656         fail "looked for .dsc $dscfn, but $!;".
2657             " maybe you forgot to build";
2658
2659     responder_send_file('dsc', $dscpath);
2660
2661     push_parse_dsc($dscpath, $dscfn, $cversion);
2662
2663     my $format = getfield $dsc, 'Format';
2664     printdebug "format $format\n";
2665
2666     my $actualhead = git_rev_parse('HEAD');
2667     my $dgithead = $actualhead;
2668     my $maintviewhead = undef;
2669
2670     if (madformat($format)) {
2671         # user might have not used dgit build, so maybe do this now:
2672         if (quiltmode_splitbrain()) {
2673             my $upstreamversion = $clogp->{Version};
2674             $upstreamversion =~ s/-[^-]*$//;
2675             changedir $ud;
2676             quilt_make_fake_dsc($upstreamversion);
2677             my ($dgitview, $cachekey) =
2678                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
2679             $dgitview or fail
2680  "--quilt=$quilt_mode but no cached dgit view:
2681  perhaps tree changed since dgit build[-source] ?";
2682             $split_brain = 1;
2683             $dgithead = splitbrain_pseudomerge($clogp,
2684                                                $actualhead, $dgitview,
2685                                                $archive_hash);
2686             $maintviewhead = $actualhead;
2687             changedir '../../../..';
2688             prep_ud(); # so _only_subdir() works, below
2689         } else {
2690             commit_quilty_patch();
2691         }
2692     }
2693
2694     check_not_dirty();
2695
2696     my $forceflag = '';
2697     if ($archive_hash) {
2698         if (is_fast_fwd($archive_hash, $dgithead)) {
2699             # ok
2700         } elsif (deliberately_not_fast_forward) {
2701             $forceflag = '+';
2702         } else {
2703             fail "dgit push: HEAD is not a descendant".
2704                 " of the archive's version.\n".
2705                 "dgit: To overwrite its contents,".
2706                 " use git merge -s ours ".lrref().".\n".
2707                 "dgit: To rewind history, if permitted by the archive,".
2708                 " use --deliberately-not-fast-forward";
2709         }
2710     }
2711
2712     changedir $ud;
2713     progress "checking that $dscfn corresponds to HEAD";
2714     runcmd qw(dpkg-source -x --),
2715         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
2716     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
2717     check_for_vendor_patches() if madformat($dsc->{format});
2718     changedir '../../../..';
2719     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
2720     my @diffcmd = (@git, qw(diff), $diffopt, $tree, $dgithead);
2721     debugcmd "+",@diffcmd;
2722     $!=0; $?=-1;
2723     my $r = system @diffcmd;
2724     if ($r) {
2725         if ($r==256) {
2726             fail "$dscfn specifies a different tree to your HEAD commit;".
2727                 " perhaps you forgot to build".
2728                 ($diffopt eq '--exit-code' ? "" :
2729                  " (run with -D to see full diff output)");
2730         } else {
2731             failedcmd @diffcmd;
2732         }
2733     }
2734     if (!$changesfile) {
2735         my $pat = changespat $cversion;
2736         my @cs = glob "$buildproductsdir/$pat";
2737         fail "failed to find unique changes file".
2738             " (looked for $pat in $buildproductsdir);".
2739             " perhaps you need to use dgit -C"
2740             unless @cs==1;
2741         ($changesfile) = @cs;
2742     } else {
2743         $changesfile = "$buildproductsdir/$changesfile";
2744     }
2745
2746     # Checks complete, we're going to try and go ahead:
2747
2748     responder_send_file('changes',$changesfile);
2749     responder_send_command("param head $dgithead");
2750     responder_send_command("param csuite $csuite");
2751     responder_send_command("param tagformat $tagformat");
2752     if (defined $maintviewhead) {
2753         die unless ($protovsn//4) >= 4;
2754         responder_send_command("param maint-view $maintviewhead");
2755     }
2756
2757     if (deliberately_not_fast_forward) {
2758         git_for_each_ref(lrfetchrefs, sub {
2759             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
2760             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
2761             responder_send_command("previously $rrefname=$objid");
2762             $previously{$rrefname} = $objid;
2763         });
2764     }
2765
2766     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
2767                                  ".git/dgit/tag");
2768     my @tagobjfns;
2769
2770     supplementary_message(<<'END');
2771 Push failed, while signing the tag.
2772 You can retry the push, after fixing the problem, if you like.
2773 END
2774     # If we manage to sign but fail to record it anywhere, it's fine.
2775     if ($we_are_responder) {
2776         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
2777         responder_receive_files('signed-tag', @tagobjfns);
2778     } else {
2779         @tagobjfns = push_mktags($clogp,$dscpath,
2780                               $changesfile,$changesfile,
2781                               \@tagwants);
2782     }
2783     supplementary_message(<<'END');
2784 Push failed, *after* signing the tag.
2785 If you want to try again, you should use a new version number.
2786 END
2787
2788     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
2789
2790     foreach my $tw (@tagwants) {
2791         my $tag = $tw->{Tag};
2792         my $tagobjfn = $tw->{TagObjFn};
2793         my $tag_obj_hash =
2794             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
2795         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
2796         runcmd_ordryrun_local
2797             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
2798     }
2799
2800     supplementary_message(<<'END');
2801 Push failed, while updating the remote git repository - see messages above.
2802 If you want to try again, you should use a new version number.
2803 END
2804     if (!check_for_git()) {
2805         create_remote_git_repo();
2806     }
2807
2808     my @pushrefs = $forceflag.$dgithead.":".rrref();
2809     foreach my $tw (@tagwants) {
2810         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
2811     }
2812
2813     runcmd_ordryrun @git, qw(push),access_giturl(), @pushrefs;
2814     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
2815
2816     supplementary_message(<<'END');
2817 Push failed, after updating the remote git repository.
2818 If you want to try again, you must use a new version number.
2819 END
2820     if ($we_are_responder) {
2821         my $dryrunsuffix = act_local() ? "" : ".tmp";
2822         responder_receive_files('signed-dsc-changes',
2823                                 "$dscpath$dryrunsuffix",
2824                                 "$changesfile$dryrunsuffix");
2825     } else {
2826         if (act_local()) {
2827             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
2828         } else {
2829             progress "[new .dsc left in $dscpath.tmp]";
2830         }
2831         sign_changes $changesfile;
2832     }
2833
2834     supplementary_message(<<END);
2835 Push failed, while uploading package(s) to the archive server.
2836 You can retry the upload of exactly these same files with dput of:
2837   $changesfile
2838 If that .changes file is broken, you will need to use a new version
2839 number for your next attempt at the upload.
2840 END
2841     my $host = access_cfg('upload-host','RETURN-UNDEF');
2842     my @hostarg = defined($host) ? ($host,) : ();
2843     runcmd_ordryrun @dput, @hostarg, $changesfile;
2844     printdone "pushed and uploaded $cversion";
2845
2846     supplementary_message('');
2847     responder_send_command("complete");
2848 }
2849
2850 sub cmd_clone {
2851     parseopts();
2852     notpushing();
2853     my $dstdir;
2854     badusage "-p is not allowed with clone; specify as argument instead"
2855         if defined $package;
2856     if (@ARGV==1) {
2857         ($package) = @ARGV;
2858     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
2859         ($package,$isuite) = @ARGV;
2860     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
2861         ($package,$dstdir) = @ARGV;
2862     } elsif (@ARGV==3) {
2863         ($package,$isuite,$dstdir) = @ARGV;
2864     } else {
2865         badusage "incorrect arguments to dgit clone";
2866     }
2867     $dstdir ||= "$package";
2868
2869     if (stat_exists $dstdir) {
2870         fail "$dstdir already exists";
2871     }
2872
2873     my $cwd_remove;
2874     if ($rmonerror && !$dryrun_level) {
2875         $cwd_remove= getcwd();
2876         unshift @end, sub {
2877             return unless defined $cwd_remove;
2878             if (!chdir "$cwd_remove") {
2879                 return if $!==&ENOENT;
2880                 die "chdir $cwd_remove: $!";
2881             }
2882             if (stat $dstdir) {
2883                 rmtree($dstdir) or die "remove $dstdir: $!\n";
2884             } elsif (!grep { $! == $_ }
2885                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
2886             } else {
2887                 print STDERR "check whether to remove $dstdir: $!\n";
2888             }
2889         };
2890     }
2891
2892     clone($dstdir);
2893     $cwd_remove = undef;
2894 }
2895
2896 sub branchsuite () {
2897     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
2898     if ($branch =~ m#$lbranch_re#o) {
2899         return $1;
2900     } else {
2901         return undef;
2902     }
2903 }
2904
2905 sub fetchpullargs () {
2906     notpushing();
2907     if (!defined $package) {
2908         my $sourcep = parsecontrol('debian/control','debian/control');
2909         $package = getfield $sourcep, 'Source';
2910     }
2911     if (@ARGV==0) {
2912 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
2913         if (!$isuite) {
2914             my $clogp = parsechangelog();
2915             $isuite = getfield $clogp, 'Distribution';
2916         }
2917         canonicalise_suite();
2918         progress "fetching from suite $csuite";
2919     } elsif (@ARGV==1) {
2920         ($isuite) = @ARGV;
2921         canonicalise_suite();
2922     } else {
2923         badusage "incorrect arguments to dgit fetch or dgit pull";
2924     }
2925 }
2926
2927 sub cmd_fetch {
2928     parseopts();
2929     fetchpullargs();
2930     fetch();
2931 }
2932
2933 sub cmd_pull {
2934     parseopts();
2935     fetchpullargs();
2936     pull();
2937 }
2938
2939 sub cmd_push {
2940     parseopts();
2941     pushing();
2942     badusage "-p is not allowed with dgit push" if defined $package;
2943     check_not_dirty();
2944     my $clogp = parsechangelog();
2945     $package = getfield $clogp, 'Source';
2946     my $specsuite;
2947     if (@ARGV==0) {
2948     } elsif (@ARGV==1) {
2949         ($specsuite) = (@ARGV);
2950     } else {
2951         badusage "incorrect arguments to dgit push";
2952     }
2953     $isuite = getfield $clogp, 'Distribution';
2954     if ($new_package) {
2955         local ($package) = $existing_package; # this is a hack
2956         canonicalise_suite();
2957     } else {
2958         canonicalise_suite();
2959     }
2960     if (defined $specsuite &&
2961         $specsuite ne $isuite &&
2962         $specsuite ne $csuite) {
2963             fail "dgit push: changelog specifies $isuite ($csuite)".
2964                 " but command line specifies $specsuite";
2965     }
2966     dopush();
2967 }
2968
2969 #---------- remote commands' implementation ----------
2970
2971 sub cmd_remote_push_build_host {
2972     my ($nrargs) = shift @ARGV;
2973     my (@rargs) = @ARGV[0..$nrargs-1];
2974     @ARGV = @ARGV[$nrargs..$#ARGV];
2975     die unless @rargs;
2976     my ($dir,$vsnwant) = @rargs;
2977     # vsnwant is a comma-separated list; we report which we have
2978     # chosen in our ready response (so other end can tell if they
2979     # offered several)
2980     $debugprefix = ' ';
2981     $we_are_responder = 1;
2982     $us .= " (build host)";
2983
2984     pushing();
2985
2986     open PI, "<&STDIN" or die $!;
2987     open STDIN, "/dev/null" or die $!;
2988     open PO, ">&STDOUT" or die $!;
2989     autoflush PO 1;
2990     open STDOUT, ">&STDERR" or die $!;
2991     autoflush STDOUT 1;
2992
2993     $vsnwant //= 1;
2994     ($protovsn) = grep {
2995         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
2996     } @rpushprotovsn_support;
2997
2998     fail "build host has dgit rpush protocol versions ".
2999         (join ",", @rpushprotovsn_support).
3000         " but invocation host has $vsnwant"
3001         unless defined $protovsn;
3002
3003     responder_send_command("dgit-remote-push-ready $protovsn");
3004     rpush_handle_protovsn_bothends();
3005     changedir $dir;
3006     &cmd_push;
3007 }
3008
3009 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
3010 # ... for compatibility with proto vsn.1 dgit (just so that user gets
3011 #     a good error message)
3012
3013 sub rpush_handle_protovsn_bothends () {
3014     if ($protovsn < 4) {
3015         need_tagformat 'old', "rpush negotiated protocol $protovsn";
3016     }
3017     select_tagformat();
3018 }
3019
3020 our $i_tmp;
3021
3022 sub i_cleanup {
3023     local ($@, $?);
3024     my $report = i_child_report();
3025     if (defined $report) {
3026         printdebug "($report)\n";
3027     } elsif ($i_child_pid) {
3028         printdebug "(killing build host child $i_child_pid)\n";
3029         kill 15, $i_child_pid;
3030     }
3031     if (defined $i_tmp && !defined $initiator_tempdir) {
3032         changedir "/";
3033         eval { rmtree $i_tmp; };
3034     }
3035 }
3036
3037 END { i_cleanup(); }
3038
3039 sub i_method {
3040     my ($base,$selector,@args) = @_;
3041     $selector =~ s/\-/_/g;
3042     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
3043 }
3044
3045 sub cmd_rpush {
3046     pushing();
3047     my $host = nextarg;
3048     my $dir;
3049     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
3050         $host = $1;
3051         $dir = $'; #';
3052     } else {
3053         $dir = nextarg;
3054     }
3055     $dir =~ s{^-}{./-};
3056     my @rargs = ($dir);
3057     push @rargs, join ",", @rpushprotovsn_support;
3058     my @rdgit;
3059     push @rdgit, @dgit;
3060     push @rdgit, @ropts;
3061     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
3062     push @rdgit, @ARGV;
3063     my @cmd = (@ssh, $host, shellquote @rdgit);
3064     debugcmd "+",@cmd;
3065
3066     if (defined $initiator_tempdir) {
3067         rmtree $initiator_tempdir;
3068         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
3069         $i_tmp = $initiator_tempdir;
3070     } else {
3071         $i_tmp = tempdir();
3072     }
3073     $i_child_pid = open2(\*RO, \*RI, @cmd);
3074     changedir $i_tmp;
3075     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
3076     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
3077     $supplementary_message = '' unless $protovsn >= 3;
3078
3079     fail "rpush negotiated protocol version $protovsn".
3080         " which does not support quilt mode $quilt_mode"
3081         if quiltmode_splitbrain;
3082
3083     rpush_handle_protovsn_bothends();
3084     for (;;) {
3085         my ($icmd,$iargs) = initiator_expect {
3086             m/^(\S+)(?: (.*))?$/;
3087             ($1,$2);
3088         };
3089         i_method "i_resp", $icmd, $iargs;
3090     }
3091 }
3092
3093 sub i_resp_progress ($) {
3094     my ($rhs) = @_;
3095     my $msg = protocol_read_bytes \*RO, $rhs;
3096     progress $msg;
3097 }
3098
3099 sub i_resp_supplementary_message ($) {
3100     my ($rhs) = @_;
3101     $supplementary_message = protocol_read_bytes \*RO, $rhs;
3102 }
3103
3104 sub i_resp_complete {
3105     my $pid = $i_child_pid;
3106     $i_child_pid = undef; # prevents killing some other process with same pid
3107     printdebug "waiting for build host child $pid...\n";
3108     my $got = waitpid $pid, 0;
3109     die $! unless $got == $pid;
3110     die "build host child failed $?" if $?;
3111
3112     i_cleanup();
3113     printdebug "all done\n";
3114     exit 0;
3115 }
3116
3117 sub i_resp_file ($) {
3118     my ($keyword) = @_;
3119     my $localname = i_method "i_localname", $keyword;
3120     my $localpath = "$i_tmp/$localname";
3121     stat_exists $localpath and
3122         badproto \*RO, "file $keyword ($localpath) twice";
3123     protocol_receive_file \*RO, $localpath;
3124     i_method "i_file", $keyword;
3125 }
3126
3127 our %i_param;
3128
3129 sub i_resp_param ($) {
3130     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
3131     $i_param{$1} = $2;
3132 }
3133
3134 sub i_resp_previously ($) {
3135     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
3136         or badproto \*RO, "bad previously spec";
3137     my $r = system qw(git check-ref-format), $1;
3138     die "bad previously ref spec ($r)" if $r;
3139     $previously{$1} = $2;
3140 }
3141
3142 our %i_wanted;
3143
3144 sub i_resp_want ($) {
3145     my ($keyword) = @_;
3146     die "$keyword ?" if $i_wanted{$keyword}++;
3147     my @localpaths = i_method "i_want", $keyword;
3148     printdebug "[[  $keyword @localpaths\n";
3149     foreach my $localpath (@localpaths) {
3150         protocol_send_file \*RI, $localpath;
3151     }
3152     print RI "files-end\n" or die $!;
3153 }
3154
3155 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
3156
3157 sub i_localname_parsed_changelog {
3158     return "remote-changelog.822";
3159 }
3160 sub i_file_parsed_changelog {
3161     ($i_clogp, $i_version, $i_dscfn) =
3162         push_parse_changelog "$i_tmp/remote-changelog.822";
3163     die if $i_dscfn =~ m#/|^\W#;
3164 }
3165
3166 sub i_localname_dsc {
3167     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
3168     return $i_dscfn;
3169 }
3170 sub i_file_dsc { }
3171
3172 sub i_localname_changes {
3173     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
3174     $i_changesfn = $i_dscfn;
3175     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
3176     return $i_changesfn;
3177 }
3178 sub i_file_changes { }
3179
3180 sub i_want_signed_tag {
3181     printdebug Dumper(\%i_param, $i_dscfn);
3182     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
3183         && defined $i_param{'csuite'}
3184         or badproto \*RO, "premature desire for signed-tag";
3185     my $head = $i_param{'head'};
3186     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
3187
3188     my $maintview = $i_param{'maint-view'};
3189     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
3190
3191     select_tagformat();
3192     if ($protovsn >= 4) {
3193         my $p = $i_param{'tagformat'} // '<undef>';
3194         $p eq $tagformat
3195             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
3196     }
3197
3198     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
3199     $csuite = $&;
3200     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
3201
3202     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
3203
3204     return
3205         push_mktags $i_clogp, $i_dscfn,
3206             $i_changesfn, 'remote changes',
3207             \@tagwants;
3208 }
3209
3210 sub i_want_signed_dsc_changes {
3211     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
3212     sign_changes $i_changesfn;
3213     return ($i_dscfn, $i_changesfn);
3214 }
3215
3216 #---------- building etc. ----------
3217
3218 our $version;
3219 our $sourcechanges;
3220 our $dscfn;
3221
3222 #----- `3.0 (quilt)' handling -----
3223
3224 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
3225
3226 sub quiltify_dpkg_commit ($$$;$) {
3227     my ($patchname,$author,$msg, $xinfo) = @_;
3228     $xinfo //= '';
3229
3230     mkpath '.git/dgit';
3231     my $descfn = ".git/dgit/quilt-description.tmp";
3232     open O, '>', $descfn or die "$descfn: $!";
3233     $msg =~ s/\s+$//g;
3234     $msg =~ s/\n/\n /g;
3235     $msg =~ s/^\s+$/ ./mg;
3236     print O <<END or die $!;
3237 Description: $msg
3238 Author: $author
3239 $xinfo
3240 ---
3241
3242 END
3243     close O or die $!;
3244
3245     {
3246         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
3247         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
3248         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
3249         runcmd @dpkgsource, qw(--commit .), $patchname;
3250     }
3251 }
3252
3253 sub quiltify_trees_differ ($$;$$) {
3254     my ($x,$y,$finegrained,$ignorenamesr) = @_;
3255     # returns true iff the two tree objects differ other than in debian/
3256     # with $finegrained,
3257     # returns bitmask 01 - differ in upstream files except .gitignore
3258     #                 02 - differ in .gitignore
3259     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
3260     #  is set for each modified .gitignore filename $fn
3261     local $/=undef;
3262     my @cmd = (@git, qw(diff-tree --name-only -z));
3263     push @cmd, qw(-r) if $finegrained;
3264     push @cmd, $x, $y;
3265     my $diffs= cmdoutput @cmd;
3266     my $r = 0;
3267     foreach my $f (split /\0/, $diffs) {
3268         next if $f =~ m#^debian(?:/.*)?$#s;
3269         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
3270         $r |= $isignore ? 02 : 01;
3271         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
3272     }
3273     printdebug "quiltify_trees_differ $x $y => $r\n";
3274     return $r;
3275 }
3276
3277 sub quiltify_tree_sentinelfiles ($) {
3278     # lists the `sentinel' files present in the tree
3279     my ($x) = @_;
3280     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
3281         qw(-- debian/rules debian/control);
3282     $r =~ s/\n/,/g;
3283     return $r;
3284 }
3285
3286 sub quiltify_splitbrain_needed () {
3287     if (!$split_brain) {
3288         progress "dgit view: changes are required...";
3289         runcmd @git, qw(checkout -q -b dgit-view);
3290         $split_brain = 1;
3291     }
3292 }
3293
3294 sub quiltify_splitbrain ($$$$$$) {
3295     my ($clogp, $unapplied, $headref, $diffbits,
3296         $editedignores, $cachekey) = @_;
3297     if ($quilt_mode !~ m/gbp|dpm/) {
3298         # treat .gitignore just like any other upstream file
3299         $diffbits = { %$diffbits };
3300         $_ = !!$_ foreach values %$diffbits;
3301     }
3302     # We would like any commits we generate to be reproducible
3303     my @authline = clogp_authline($clogp);
3304     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
3305     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
3306     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
3307
3308     if ($quilt_mode =~ m/gbp|unapplied/ &&
3309         ($diffbits->{H2O} & 01)) {
3310         my $msg =
3311  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
3312  " but git tree differs from orig in upstream files.";
3313         if (!stat_exists "debian/patches") {
3314             $msg .=
3315  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
3316         }
3317         fail $msg;
3318     }
3319     if ($quilt_mode =~ m/dpm/ &&
3320         ($diffbits->{H2A} & 01)) {
3321         fail <<END;
3322 --quilt=$quilt_mode specified, implying patches-applied git tree
3323  but git tree differs from result of applying debian/patches to upstream
3324 END
3325     }
3326     if ($quilt_mode =~ m/gbp|unapplied/ &&
3327         ($diffbits->{O2A} & 01)) { # some patches
3328         quiltify_splitbrain_needed();
3329         progress "dgit view: creating patches-applied version using gbp pq";
3330         runcmd shell_cmd 'exec >/dev/null', @gbp, qw(pq import);
3331         # gbp pq import creates a fresh branch; push back to dgit-view
3332         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
3333         runcmd @git, qw(checkout -q dgit-view);
3334     }
3335     if ($quilt_mode =~ m/gbp|dpm/ &&
3336         ($diffbits->{O2A} & 02)) {
3337         fail <<END
3338 --quilt=$quilt_mode specified, implying that HEAD is for use with a
3339  tool which does not create patches for changes to upstream
3340  .gitignores: but, such patches exist in debian/patches.
3341 END
3342     }
3343     if (($diffbits->{H2O} & 02) && # user has modified .gitignore
3344         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
3345         quiltify_splitbrain_needed();
3346         progress "dgit view: creating patch to represent .gitignore changes";
3347         ensuredir "debian/patches";
3348         my $gipatch = "debian/patches/auto-gitignore";
3349         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
3350         stat GIPATCH or die "$gipatch: $!";
3351         fail "$gipatch already exists; but want to create it".
3352             " to record .gitignore changes" if (stat _)[7];
3353         print GIPATCH <<END or die "$gipatch: $!";
3354 Subject: Update .gitignore from Debian packaging branch
3355
3356 The Debian packaging git branch contains these updates to the upstream
3357 .gitignore file(s).  This patch is autogenerated, to provide these
3358 updates to users of the official Debian archive view of the package.
3359
3360 [dgit version $our_version]
3361 ---
3362 END
3363         close GIPATCH or die "$gipatch: $!";
3364         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
3365             $unapplied, $headref, "--", sort keys %$editedignores;
3366         open SERIES, "+>>", "debian/patches/series" or die $!;
3367         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
3368         my $newline;
3369         defined read SERIES, $newline, 1 or die $!;
3370         print SERIES "\n" or die $! unless $newline eq "\n";
3371         print SERIES "auto-gitignore\n" or die $!;
3372         close SERIES or die  $!;
3373         runcmd @git, qw(add -- debian/patches/series), $gipatch;
3374         commit_admin "Commit patch to update .gitignore";
3375     }
3376
3377     my $dgitview = git_rev_parse 'refs/heads/dgit-view';
3378
3379     changedir '../../../..';
3380     ensuredir ".git/logs/refs/dgit-intern";
3381     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
3382       or die $!;
3383     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
3384         $dgitview;
3385
3386     progress "dgit view: created (commit id $dgitview)";
3387
3388     changedir '.git/dgit/unpack/work';
3389 }
3390
3391 sub quiltify ($$$$) {
3392     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
3393
3394     # Quilt patchification algorithm
3395     #
3396     # We search backwards through the history of the main tree's HEAD
3397     # (T) looking for a start commit S whose tree object is identical
3398     # to to the patch tip tree (ie the tree corresponding to the
3399     # current dpkg-committed patch series).  For these purposes
3400     # `identical' disregards anything in debian/ - this wrinkle is
3401     # necessary because dpkg-source treates debian/ specially.
3402     #
3403     # We can only traverse edges where at most one of the ancestors'
3404     # trees differs (in changes outside in debian/).  And we cannot
3405     # handle edges which change .pc/ or debian/patches.  To avoid
3406     # going down a rathole we avoid traversing edges which introduce
3407     # debian/rules or debian/control.  And we set a limit on the
3408     # number of edges we are willing to look at.
3409     #
3410     # If we succeed, we walk forwards again.  For each traversed edge
3411     # PC (with P parent, C child) (starting with P=S and ending with
3412     # C=T) to we do this:
3413     #  - git checkout C
3414     #  - dpkg-source --commit with a patch name and message derived from C
3415     # After traversing PT, we git commit the changes which
3416     # should be contained within debian/patches.
3417
3418     # The search for the path S..T is breadth-first.  We maintain a
3419     # todo list containing search nodes.  A search node identifies a
3420     # commit, and looks something like this:
3421     #  $p = {
3422     #      Commit => $git_commit_id,
3423     #      Child => $c,                          # or undef if P=T
3424     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
3425     #      Nontrivial => true iff $p..$c has relevant changes
3426     #  };
3427
3428     my @todo;
3429     my @nots;
3430     my $sref_S;
3431     my $max_work=100;
3432     my %considered; # saves being exponential on some weird graphs
3433
3434     my $t_sentinels = quiltify_tree_sentinelfiles $target;
3435
3436     my $not = sub {
3437         my ($search,$whynot) = @_;
3438         printdebug " search NOT $search->{Commit} $whynot\n";
3439         $search->{Whynot} = $whynot;
3440         push @nots, $search;
3441         no warnings qw(exiting);
3442         next;
3443     };
3444
3445     push @todo, {
3446         Commit => $target,
3447     };
3448
3449     while (@todo) {
3450         my $c = shift @todo;
3451         next if $considered{$c->{Commit}}++;
3452
3453         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
3454
3455         printdebug "quiltify investigate $c->{Commit}\n";
3456
3457         # are we done?
3458         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
3459             printdebug " search finished hooray!\n";
3460             $sref_S = $c;
3461             last;
3462         }
3463
3464         if ($quilt_mode eq 'nofix') {
3465             fail "quilt fixup required but quilt mode is \`nofix'\n".
3466                 "HEAD commit $c->{Commit} differs from tree implied by ".
3467                 " debian/patches (tree object $oldtiptree)";
3468         }
3469         if ($quilt_mode eq 'smash') {
3470             printdebug " search quitting smash\n";
3471             last;
3472         }
3473
3474         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
3475         $not->($c, "has $c_sentinels not $t_sentinels")
3476             if $c_sentinels ne $t_sentinels;
3477
3478         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
3479         $commitdata =~ m/\n\n/;
3480         $commitdata =~ $`;
3481         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
3482         @parents = map { { Commit => $_, Child => $c } } @parents;
3483
3484         $not->($c, "root commit") if !@parents;
3485
3486         foreach my $p (@parents) {
3487             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
3488         }
3489         my $ndiffers = grep { $_->{Nontrivial} } @parents;
3490         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
3491
3492         foreach my $p (@parents) {
3493             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
3494
3495             my @cmd= (@git, qw(diff-tree -r --name-only),
3496                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
3497             my $patchstackchange = cmdoutput @cmd;
3498             if (length $patchstackchange) {
3499                 $patchstackchange =~ s/\n/,/g;
3500                 $not->($p, "changed $patchstackchange");
3501             }
3502
3503             printdebug " search queue P=$p->{Commit} ",
3504                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
3505             push @todo, $p;
3506         }
3507     }
3508
3509     if (!$sref_S) {
3510         printdebug "quiltify want to smash\n";
3511
3512         my $abbrev = sub {
3513             my $x = $_[0]{Commit};
3514             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
3515             return $x;
3516         };
3517         my $reportnot = sub {
3518             my ($notp) = @_;
3519             my $s = $abbrev->($notp);
3520             my $c = $notp->{Child};
3521             $s .= "..".$abbrev->($c) if $c;
3522             $s .= ": ".$notp->{Whynot};
3523             return $s;
3524         };
3525         if ($quilt_mode eq 'linear') {
3526             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
3527             foreach my $notp (@nots) {
3528                 print STDERR "$us:  ", $reportnot->($notp), "\n";
3529             }
3530             print STDERR "$us: $_\n" foreach @$failsuggestion;
3531             fail "quilt fixup naive history linearisation failed.\n".
3532  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
3533         } elsif ($quilt_mode eq 'smash') {
3534         } elsif ($quilt_mode eq 'auto') {
3535             progress "quilt fixup cannot be linear, smashing...";
3536         } else {
3537             die "$quilt_mode ?";
3538         }
3539
3540         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
3541         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
3542         my $ncommits = 3;
3543         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
3544
3545         quiltify_dpkg_commit "auto-$version-$target-$time",
3546             (getfield $clogp, 'Maintainer'),
3547             "Automatically generated patch ($clogp->{Version})\n".
3548             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
3549         return;
3550     }
3551
3552     progress "quiltify linearisation planning successful, executing...";
3553
3554     for (my $p = $sref_S;
3555          my $c = $p->{Child};
3556          $p = $p->{Child}) {
3557         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
3558         next unless $p->{Nontrivial};
3559
3560         my $cc = $c->{Commit};
3561
3562         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
3563         $commitdata =~ m/\n\n/ or die "$c ?";
3564         $commitdata = $`;
3565         my $msg = $'; #';
3566         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
3567         my $author = $1;
3568
3569         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
3570
3571         my $title = $1;
3572         my $patchname = $title;
3573         $patchname =~ s/[.:]$//;
3574         $patchname =~ y/ A-Z/-a-z/;
3575         $patchname =~ y/-a-z0-9_.+=~//cd;
3576         $patchname =~ s/^\W/x-$&/;
3577         $patchname = substr($patchname,0,40);
3578         my $index;
3579         for ($index='';
3580              stat "debian/patches/$patchname$index";
3581              $index++) { }
3582         $!==ENOENT or die "$patchname$index $!";
3583
3584         runcmd @git, qw(checkout -q), $cc;
3585
3586         # We use the tip's changelog so that dpkg-source doesn't
3587         # produce complaining messages from dpkg-parsechangelog.  None
3588         # of the information dpkg-source gets from the changelog is
3589         # actually relevant - it gets put into the original message
3590         # which dpkg-source provides our stunt editor, and then
3591         # overwritten.
3592         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
3593
3594         quiltify_dpkg_commit "$patchname$index", $author, $msg,
3595             "X-Dgit-Generated: $clogp->{Version} $cc\n";
3596
3597         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
3598     }
3599
3600     runcmd @git, qw(checkout -q master);
3601 }
3602
3603 sub build_maybe_quilt_fixup () {
3604     my ($format,$fopts) = get_source_format;
3605     return unless madformat $format;
3606     # sigh
3607
3608     check_for_vendor_patches();
3609
3610     my $clogp = parsechangelog();
3611     my $headref = git_rev_parse('HEAD');
3612
3613     prep_ud();
3614     changedir $ud;
3615
3616     my $upstreamversion=$version;
3617     $upstreamversion =~ s/-[^-]*$//;
3618
3619     if ($fopts->{'single-debian-patch'}) {
3620         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
3621     } else {
3622         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
3623     }
3624
3625     die 'bug' if $split_brain && !$need_split_build_invocation;
3626
3627     changedir '../../../..';
3628     runcmd_ordryrun_local
3629         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
3630 }
3631
3632 sub quilt_fixup_mkwork ($) {
3633     my ($headref) = @_;
3634
3635     mkdir "work" or die $!;
3636     changedir "work";
3637     mktree_in_ud_here();
3638     runcmd @git, qw(reset -q --hard), $headref;
3639 }
3640
3641 sub quilt_fixup_linkorigs ($$) {
3642     my ($upstreamversion, $fn) = @_;
3643     # calls $fn->($leafname);
3644
3645     foreach my $f (<../../../../*>) { #/){
3646         my $b=$f; $b =~ s{.*/}{};
3647         {
3648             local ($debuglevel) = $debuglevel-1;
3649             printdebug "QF linkorigs $b, $f ?\n";
3650         }
3651         next unless is_orig_file $b, srcfn $upstreamversion,'';
3652         printdebug "QF linkorigs $b, $f Y\n";
3653         link_ltarget $f, $b or die "$b $!";
3654         $fn->($b);
3655     }
3656 }
3657
3658 sub quilt_fixup_delete_pc () {
3659     runcmd @git, qw(rm -rqf .pc);
3660     commit_admin "Commit removal of .pc (quilt series tracking data)";
3661 }
3662
3663 sub quilt_fixup_singlepatch ($$$) {
3664     my ($clogp, $headref, $upstreamversion) = @_;
3665
3666     progress "starting quiltify (single-debian-patch)";
3667
3668     # dpkg-source --commit generates new patches even if
3669     # single-debian-patch is in debian/source/options.  In order to
3670     # get it to generate debian/patches/debian-changes, it is
3671     # necessary to build the source package.
3672
3673     quilt_fixup_linkorigs($upstreamversion, sub { });
3674     quilt_fixup_mkwork($headref);
3675
3676     rmtree("debian/patches");
3677
3678     runcmd @dpkgsource, qw(-b .);
3679     chdir "..";
3680     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
3681     rename srcfn("$upstreamversion", "/debian/patches"),
3682            "work/debian/patches";
3683
3684     chdir "work";
3685     commit_quilty_patch();
3686 }
3687
3688 sub quilt_make_fake_dsc ($) {
3689     my ($upstreamversion) = @_;
3690
3691     my $fakeversion="$upstreamversion-~~DGITFAKE";
3692
3693     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
3694     print $fakedsc <<END or die $!;
3695 Format: 3.0 (quilt)
3696 Source: $package
3697 Version: $fakeversion
3698 Files:
3699 END
3700
3701     my $dscaddfile=sub {
3702         my ($b) = @_;
3703
3704         my $md = new Digest::MD5;
3705
3706         my $fh = new IO::File $b, '<' or die "$b $!";
3707         stat $fh or die $!;
3708         my $size = -s _;
3709
3710         $md->addfile($fh);
3711         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
3712     };
3713
3714     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
3715
3716     my @files=qw(debian/source/format debian/rules
3717                  debian/control debian/changelog);
3718     foreach my $maybe (qw(debian/patches debian/source/options
3719                           debian/tests/control)) {
3720         next unless stat_exists "../../../$maybe";
3721         push @files, $maybe;
3722     }
3723
3724     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
3725     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
3726
3727     $dscaddfile->($debtar);
3728     close $fakedsc or die $!;
3729 }
3730
3731 sub quilt_check_splitbrain_cache ($$) {
3732     my ($headref, $upstreamversion) = @_;
3733     # Called only if we are in (potentially) split brain mode.
3734     # Called in $ud.
3735     # Computes the cache key and looks in the cache.
3736     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
3737
3738     my $splitbrain_cachekey;
3739
3740     progress
3741  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
3742     # we look in the reflog of dgit-intern/quilt-cache
3743     # we look for an entry whose message is the key for the cache lookup
3744     my @cachekey = (qw(dgit), $our_version);
3745     push @cachekey, $upstreamversion;
3746     push @cachekey, $quilt_mode;
3747     push @cachekey, $headref;
3748
3749     push @cachekey, hashfile('fake.dsc');
3750
3751     my $srcshash = Digest::SHA->new(256);
3752     my %sfs = ( %INC, '$0(dgit)' => $0 );
3753     foreach my $sfk (sort keys %sfs) {
3754         next unless m/^\$0\b/ || m{^Debian/Dgit\b};
3755         $srcshash->add($sfk,"  ");
3756         $srcshash->add(hashfile($sfs{$sfk}));
3757         $srcshash->add("\n");
3758     }
3759     push @cachekey, $srcshash->hexdigest();
3760     $splitbrain_cachekey = "@cachekey";
3761
3762     my @cmd = (@git, qw(reflog), '--pretty=format:%H %gs',
3763                $splitbraincache);
3764     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
3765     debugcmd "|(probably)",@cmd;
3766     my $child = open GC, "-|";  defined $child or die $!;
3767     if (!$child) {
3768         chdir '../../..' or die $!;
3769         if (!stat ".git/logs/refs/$splitbraincache") {
3770             $! == ENOENT or die $!;
3771             printdebug ">(no reflog)\n";
3772             exit 0;
3773         }
3774         exec @cmd; die $!;
3775     }
3776     while (<GC>) {
3777         chomp;
3778         printdebug ">| ", $_, "\n" if $debuglevel > 1;
3779         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
3780
3781         my $cachehit = $1;
3782         quilt_fixup_mkwork($headref);
3783         if ($cachehit ne $headref) {
3784             progress "dgit view: found cached (commit id $cachehit)";
3785             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
3786             $split_brain = 1;
3787             return ($cachehit, $splitbrain_cachekey);
3788         }
3789         progress "dgit view: found cached, no changes required";
3790         return ($headref, $splitbrain_cachekey);
3791     }
3792     die $! if GC->error;
3793     failedcmd unless close GC;
3794
3795     printdebug "splitbrain cache miss\n";
3796     return (undef, $splitbrain_cachekey);
3797 }
3798
3799 sub quilt_fixup_multipatch ($$$) {
3800     my ($clogp, $headref, $upstreamversion) = @_;
3801
3802     progress "examining quilt state (multiple patches, $quilt_mode mode)";
3803
3804     # Our objective is:
3805     #  - honour any existing .pc in case it has any strangeness
3806     #  - determine the git commit corresponding to the tip of
3807     #    the patch stack (if there is one)
3808     #  - if there is such a git commit, convert each subsequent
3809     #    git commit into a quilt patch with dpkg-source --commit
3810     #  - otherwise convert all the differences in the tree into
3811     #    a single git commit
3812     #
3813     # To do this we:
3814
3815     # Our git tree doesn't necessarily contain .pc.  (Some versions of
3816     # dgit would include the .pc in the git tree.)  If there isn't
3817     # one, we need to generate one by unpacking the patches that we
3818     # have.
3819     #
3820     # We first look for a .pc in the git tree.  If there is one, we
3821     # will use it.  (This is not the normal case.)
3822     #
3823     # Otherwise need to regenerate .pc so that dpkg-source --commit
3824     # can work.  We do this as follows:
3825     #     1. Collect all relevant .orig from parent directory
3826     #     2. Generate a debian.tar.gz out of
3827     #         debian/{patches,rules,source/format,source/options}
3828     #     3. Generate a fake .dsc containing just these fields:
3829     #          Format Source Version Files
3830     #     4. Extract the fake .dsc
3831     #        Now the fake .dsc has a .pc directory.
3832     # (In fact we do this in every case, because in future we will
3833     # want to search for a good base commit for generating patches.)
3834     #
3835     # Then we can actually do the dpkg-source --commit
3836     #     1. Make a new working tree with the same object
3837     #        store as our main tree and check out the main
3838     #        tree's HEAD.
3839     #     2. Copy .pc from the fake's extraction, if necessary
3840     #     3. Run dpkg-source --commit
3841     #     4. If the result has changes to debian/, then
3842     #          - git-add them them
3843     #          - git-add .pc if we had a .pc in-tree
3844     #          - git-commit
3845     #     5. If we had a .pc in-tree, delete it, and git-commit
3846     #     6. Back in the main tree, fast forward to the new HEAD
3847
3848     # Another situation we may have to cope with is gbp-style
3849     # patches-unapplied trees.
3850     #
3851     # We would want to detect these, so we know to escape into
3852     # quilt_fixup_gbp.  However, this is in general not possible.
3853     # Consider a package with a one patch which the dgit user reverts
3854     # (with git-revert or the moral equivalent).
3855     #
3856     # That is indistinguishable in contents from a patches-unapplied
3857     # tree.  And looking at the history to distinguish them is not
3858     # useful because the user might have made a confusing-looking git
3859     # history structure (which ought to produce an error if dgit can't
3860     # cope, not a silent reintroduction of an unwanted patch).
3861     #
3862     # So gbp users will have to pass an option.  But we can usually
3863     # detect their failure to do so: if the tree is not a clean
3864     # patches-applied tree, quilt linearisation fails, but the tree
3865     # _is_ a clean patches-unapplied tree, we can suggest that maybe
3866     # they want --quilt=unapplied.
3867     #
3868     # To help detect this, when we are extracting the fake dsc, we
3869     # first extract it with --skip-patches, and then apply the patches
3870     # afterwards with dpkg-source --before-build.  That lets us save a
3871     # tree object corresponding to .origs.
3872
3873     my $splitbrain_cachekey;
3874
3875     quilt_make_fake_dsc($upstreamversion);
3876
3877     if (quiltmode_splitbrain()) {
3878         my $cachehit;
3879         ($cachehit, $splitbrain_cachekey) =
3880             quilt_check_splitbrain_cache($headref, $upstreamversion);
3881         return if $cachehit;
3882     }
3883
3884     runcmd qw(sh -ec),
3885         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
3886
3887     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
3888     rename $fakexdir, "fake" or die "$fakexdir $!";
3889
3890     changedir 'fake';
3891
3892     remove_stray_gits();
3893     mktree_in_ud_here();
3894
3895     rmtree '.pc';
3896
3897     runcmd @git, qw(add -Af .);
3898     my $unapplied=git_write_tree();
3899     printdebug "fake orig tree object $unapplied\n";
3900
3901     ensuredir '.pc';
3902
3903     runcmd qw(sh -ec),
3904         'exec dpkg-source --before-build . >/dev/null';
3905
3906     changedir '..';
3907
3908     quilt_fixup_mkwork($headref);
3909
3910     my $mustdeletepc=0;
3911     if (stat_exists ".pc") {
3912         -d _ or die;
3913         progress "Tree already contains .pc - will use it then delete it.";
3914         $mustdeletepc=1;
3915     } else {
3916         rename '../fake/.pc','.pc' or die $!;
3917     }
3918
3919     changedir '../fake';
3920     rmtree '.pc';
3921     runcmd @git, qw(add -Af .);
3922     my $oldtiptree=git_write_tree();
3923     printdebug "fake o+d/p tree object $unapplied\n";
3924     changedir '../work';
3925
3926
3927     # We calculate some guesswork now about what kind of tree this might
3928     # be.  This is mostly for error reporting.
3929
3930     my %editedignores;
3931     my $diffbits = {
3932         # H = user's HEAD
3933         # O = orig, without patches applied
3934         # A = "applied", ie orig with H's debian/patches applied
3935         H2O => quiltify_trees_differ($headref,  $unapplied, 1,\%editedignores),
3936         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
3937         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
3938     };
3939
3940     my @dl;
3941     foreach my $b (qw(01 02)) {
3942         foreach my $v (qw(H2O O2A H2A)) {
3943             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
3944         }
3945     }
3946     printdebug "differences \@dl @dl.\n";
3947
3948     progress sprintf
3949 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
3950 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
3951                              $dl[0], $dl[1],              $dl[3], $dl[4],
3952                                  $dl[2],                     $dl[5];
3953
3954     my @failsuggestion;
3955     if (!($diffbits->{H2O} & $diffbits->{O2A})) {
3956         push @failsuggestion, "This might be a patches-unapplied branch.";
3957     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
3958         push @failsuggestion, "This might be a patches-applied branch.";
3959     }
3960     push @failsuggestion, "Maybe you need to specify one of".
3961         " --quilt=gbp --quilt=dpm --quilt=unapplied ?";
3962
3963     if (quiltmode_splitbrain()) {
3964         quiltify_splitbrain($clogp, $unapplied, $headref,
3965                             $diffbits, \%editedignores,
3966                             $splitbrain_cachekey);
3967         return;
3968     }
3969
3970     progress "starting quiltify (multiple patches, $quilt_mode mode)";
3971     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
3972
3973     if (!open P, '>>', ".pc/applied-patches") {
3974         $!==&ENOENT or die $!;
3975     } else {
3976         close P;
3977     }
3978
3979     commit_quilty_patch();
3980
3981     if ($mustdeletepc) {
3982         quilt_fixup_delete_pc();
3983     }
3984 }
3985
3986 sub quilt_fixup_editor () {
3987     my $descfn = $ENV{$fakeeditorenv};
3988     my $editing = $ARGV[$#ARGV];
3989     open I1, '<', $descfn or die "$descfn: $!";
3990     open I2, '<', $editing or die "$editing: $!";
3991     unlink $editing or die "$editing: $!";
3992     open O, '>', $editing or die "$editing: $!";
3993     while (<I1>) { print O or die $!; } I1->error and die $!;
3994     my $copying = 0;
3995     while (<I2>) {
3996         $copying ||= m/^\-\-\- /;
3997         next unless $copying;
3998         print O or die $!;
3999     }
4000     I2->error and die $!;
4001     close O or die $1;
4002     exit 0;
4003 }
4004
4005 sub maybe_apply_patches_dirtily () {
4006     return unless $quilt_mode =~ m/gbp|unapplied/;
4007     print STDERR <<END or die $!;
4008
4009 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
4010 dgit: Have to apply the patches - making the tree dirty.
4011 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
4012
4013 END
4014     $patches_applied_dirtily = 01;
4015     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
4016     runcmd qw(dpkg-source --before-build .);
4017 }
4018
4019 sub maybe_unapply_patches_again () {
4020     progress "dgit: Unapplying patches again to tidy up the tree."
4021         if $patches_applied_dirtily;
4022     runcmd qw(dpkg-source --after-build .)
4023         if $patches_applied_dirtily & 01;
4024     rmtree '.pc'
4025         if $patches_applied_dirtily & 02;
4026     $patches_applied_dirtily = 0;
4027 }
4028
4029 #----- other building -----
4030
4031 our $clean_using_builder;
4032 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
4033 #   clean the tree before building (perhaps invoked indirectly by
4034 #   whatever we are using to run the build), rather than separately
4035 #   and explicitly by us.
4036
4037 sub clean_tree () {
4038     return if $clean_using_builder;
4039     if ($cleanmode eq 'dpkg-source') {
4040         maybe_apply_patches_dirtily();
4041         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
4042     } elsif ($cleanmode eq 'dpkg-source-d') {
4043         maybe_apply_patches_dirtily();
4044         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
4045     } elsif ($cleanmode eq 'git') {
4046         runcmd_ordryrun_local @git, qw(clean -xdf);
4047     } elsif ($cleanmode eq 'git-ff') {
4048         runcmd_ordryrun_local @git, qw(clean -xdff);
4049     } elsif ($cleanmode eq 'check') {
4050         my $leftovers = cmdoutput @git, qw(clean -xdn);
4051         if (length $leftovers) {
4052             print STDERR $leftovers, "\n" or die $!;
4053             fail "tree contains uncommitted files and --clean=check specified";
4054         }
4055     } elsif ($cleanmode eq 'none') {
4056     } else {
4057         die "$cleanmode ?";
4058     }
4059 }
4060
4061 sub cmd_clean () {
4062     badusage "clean takes no additional arguments" if @ARGV;
4063     notpushing();
4064     clean_tree();
4065     maybe_unapply_patches_again();
4066 }
4067
4068 sub build_prep () {
4069     notpushing();
4070     badusage "-p is not allowed when building" if defined $package;
4071     check_not_dirty();
4072     clean_tree();
4073     my $clogp = parsechangelog();
4074     $isuite = getfield $clogp, 'Distribution';
4075     $package = getfield $clogp, 'Source';
4076     $version = getfield $clogp, 'Version';
4077     build_maybe_quilt_fixup();
4078     if ($rmchanges) {
4079         my $pat = changespat $version;
4080         foreach my $f (glob "$buildproductsdir/$pat") {
4081             if (act_local()) {
4082                 unlink $f or fail "remove old changes file $f: $!";
4083             } else {
4084                 progress "would remove $f";
4085             }
4086         }
4087     }
4088 }
4089
4090 sub changesopts_initial () {
4091     my @opts =@changesopts[1..$#changesopts];
4092 }
4093
4094 sub changesopts_version () {
4095     if (!defined $changes_since_version) {
4096         my @vsns = archive_query('archive_query');
4097         my @quirk = access_quirk();
4098         if ($quirk[0] eq 'backports') {
4099             local $isuite = $quirk[2];
4100             local $csuite;
4101             canonicalise_suite();
4102             push @vsns, archive_query('archive_query');
4103         }
4104         if (@vsns) {
4105             @vsns = map { $_->[0] } @vsns;
4106             @vsns = sort { -version_compare($a, $b) } @vsns;
4107             $changes_since_version = $vsns[0];
4108             progress "changelog will contain changes since $vsns[0]";
4109         } else {
4110             $changes_since_version = '_';
4111             progress "package seems new, not specifying -v<version>";
4112         }
4113     }
4114     if ($changes_since_version ne '_') {
4115         return ("-v$changes_since_version");
4116     } else {
4117         return ();
4118     }
4119 }
4120
4121 sub changesopts () {
4122     return (changesopts_initial(), changesopts_version());
4123 }
4124
4125 sub massage_dbp_args ($;$) {
4126     my ($cmd,$xargs) = @_;
4127     # We need to:
4128     #
4129     #  - if we're going to split the source build out so we can
4130     #    do strange things to it, massage the arguments to dpkg-buildpackage
4131     #    so that the main build doessn't build source (or add an argument
4132     #    to stop it building source by default).
4133     #
4134     #  - add -nc to stop dpkg-source cleaning the source tree,
4135     #    unless we're not doing a split build and want dpkg-source
4136     #    as cleanmode, in which case we can do nothing
4137     #
4138     # return values:
4139     #    0 - source will NOT need to be built separately by caller
4140     #   +1 - source will need to be built separately by caller
4141     #   +2 - source will need to be built separately by caller AND
4142     #        dpkg-buildpackage should not in fact be run at all!
4143     debugcmd '#massaging#', @$cmd if $debuglevel>1;
4144 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
4145     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
4146         $clean_using_builder = 1;
4147         return 0;
4148     }
4149     # -nc has the side effect of specifying -b if nothing else specified
4150     # and some combinations of -S, -b, et al, are errors, rather than
4151     # later simply overriding earlie.  So we need to:
4152     #  - search the command line for these options
4153     #  - pick the last one
4154     #  - perhaps add our own as a default
4155     #  - perhaps adjust it to the corresponding non-source-building version
4156     my $dmode = '-F';
4157     foreach my $l ($cmd, $xargs) {
4158         next unless $l;
4159         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
4160     }
4161     push @$cmd, '-nc';
4162 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
4163     my $r = 0;
4164     if ($need_split_build_invocation) {
4165         printdebug "massage split $dmode.\n";
4166         $r = $dmode =~ m/[S]/     ? +2 :
4167              $dmode =~ y/gGF/ABb/ ? +1 :
4168              $dmode =~ m/[ABb]/   ?  0 :
4169              die "$dmode ?";
4170     }
4171     printdebug "massage done $r $dmode.\n";
4172     push @$cmd, $dmode;
4173 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
4174     return $r;
4175 }
4176
4177 sub cmd_build {
4178     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
4179     my $wantsrc = massage_dbp_args \@dbp;
4180     if ($wantsrc > 0) {
4181         build_source();
4182     } else {
4183         build_prep();
4184     }
4185     if ($wantsrc < 2) {
4186         push @dbp, changesopts_version();
4187         maybe_apply_patches_dirtily();
4188         runcmd_ordryrun_local @dbp;
4189     }
4190     maybe_unapply_patches_again();
4191     printdone "build successful\n";
4192 }
4193
4194 sub cmd_gbp_build {
4195     my @dbp = @dpkgbuildpackage;
4196
4197     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
4198
4199     my @cmd;
4200     if (length executable_on_path('git-buildpackage')) {
4201         @cmd = qw(git-buildpackage);
4202     } else {
4203         @cmd = qw(gbp buildpackage);
4204     }
4205     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
4206
4207     if ($wantsrc > 0) {
4208         build_source();
4209     } else {
4210         if (!$clean_using_builder) {
4211             push @cmd, '--git-cleaner=true';
4212         }
4213         build_prep();
4214     }
4215     maybe_unapply_patches_again();
4216     if ($wantsrc < 2) {
4217         unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
4218             canonicalise_suite();
4219             push @cmd, "--git-debian-branch=".lbranch();
4220         }
4221         push @cmd, changesopts();
4222         runcmd_ordryrun_local @cmd, @ARGV;
4223     }
4224     printdone "build successful\n";
4225 }
4226 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
4227
4228 sub build_source {
4229     my $our_cleanmode = $cleanmode;
4230     if ($need_split_build_invocation) {
4231         # Pretend that clean is being done some other way.  This
4232         # forces us not to try to use dpkg-buildpackage to clean and
4233         # build source all in one go; and instead we run dpkg-source
4234         # (and build_prep() will do the clean since $clean_using_builder
4235         # is false).
4236         $our_cleanmode = 'ELSEWHERE';
4237     }
4238     if ($our_cleanmode =~ m/^dpkg-source/) {
4239         # dpkg-source invocation (below) will clean, so build_prep shouldn't
4240         $clean_using_builder = 1;
4241     }
4242     build_prep();
4243     $sourcechanges = changespat $version,'source';
4244     if (act_local()) {
4245         unlink "../$sourcechanges" or $!==ENOENT
4246             or fail "remove $sourcechanges: $!";
4247     }
4248     $dscfn = dscfn($version);
4249     if ($our_cleanmode eq 'dpkg-source') {
4250         maybe_apply_patches_dirtily();
4251         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
4252             changesopts();
4253     } elsif ($our_cleanmode eq 'dpkg-source-d') {
4254         maybe_apply_patches_dirtily();
4255         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
4256             changesopts();
4257     } else {
4258         my @cmd = (@dpkgsource, qw(-b --));
4259         if ($split_brain) {
4260             changedir $ud;
4261             runcmd_ordryrun_local @cmd, "work";
4262             my @udfiles = <${package}_*>;
4263             changedir "../../..";
4264             foreach my $f (@udfiles) {
4265                 printdebug "source copy, found $f\n";
4266                 next unless
4267                     $f eq $dscfn or
4268                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
4269                      $f eq srcfn($version, $&));
4270                 printdebug "source copy, found $f - renaming\n";
4271                 rename "$ud/$f", "../$f" or $!==ENOENT
4272                     or fail "put in place new source file ($f): $!";
4273             }
4274         } else {
4275             my $pwd = must_getcwd();
4276             my $leafdir = basename $pwd;
4277             changedir "..";
4278             runcmd_ordryrun_local @cmd, $leafdir;
4279             changedir $pwd;
4280         }
4281         runcmd_ordryrun_local qw(sh -ec),
4282             'exec >$1; shift; exec "$@"','x',
4283             "../$sourcechanges",
4284             @dpkggenchanges, qw(-S), changesopts();
4285     }
4286 }
4287
4288 sub cmd_build_source {
4289     badusage "build-source takes no additional arguments" if @ARGV;
4290     build_source();
4291     maybe_unapply_patches_again();
4292     printdone "source built, results in $dscfn and $sourcechanges";
4293 }
4294
4295 sub cmd_sbuild {
4296     build_source();
4297     my $pat = changespat $version;
4298     if (!$rmchanges) {
4299         my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
4300         @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
4301         fail "changes files other than source matching $pat".
4302             " already present (@unwanted);".
4303             " building would result in ambiguity about the intended results"
4304             if @unwanted;
4305     }
4306     my $wasdir = must_getcwd();
4307     changedir "..";
4308     if (act_local()) {
4309         stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
4310         stat_exists $sourcechanges
4311             or fail "$sourcechanges (in parent directory): $!";
4312     }
4313     runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
4314     my @changesfiles = glob $pat;
4315     @changesfiles = sort {
4316         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
4317             or $a cmp $b
4318     } @changesfiles;
4319     fail "wrong number of different changes files (@changesfiles)"
4320         unless @changesfiles==2;
4321     my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
4322     foreach my $l (split /\n/, getfield $binchanges, 'Files') {
4323         fail "$l found in binaries changes file $binchanges"
4324             if $l =~ m/\.dsc$/;
4325     }
4326     runcmd_ordryrun_local @mergechanges, @changesfiles;
4327     my $multichanges = changespat $version,'multi';
4328     if (act_local()) {
4329         stat_exists $multichanges or fail "$multichanges: $!";
4330         foreach my $cf (glob $pat) {
4331             next if $cf eq $multichanges;
4332             rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
4333         }
4334     }
4335     changedir $wasdir;
4336     maybe_unapply_patches_again();
4337     printdone "build successful, results in $multichanges\n" or die $!;
4338 }
4339
4340 sub cmd_quilt_fixup {
4341     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
4342     my $clogp = parsechangelog();
4343     $version = getfield $clogp, 'Version';
4344     $package = getfield $clogp, 'Source';
4345     check_not_dirty();
4346     clean_tree();
4347     build_maybe_quilt_fixup();
4348 }
4349
4350 sub cmd_archive_api_query {
4351     badusage "need only 1 subpath argument" unless @ARGV==1;
4352     my ($subpath) = @ARGV;
4353     my @cmd = archive_api_query_cmd($subpath);
4354     debugcmd ">",@cmd;
4355     exec @cmd or fail "exec curl: $!\n";
4356 }
4357
4358 sub cmd_clone_dgit_repos_server {
4359     badusage "need destination argument" unless @ARGV==1;
4360     my ($destdir) = @ARGV;
4361     $package = '_dgit-repos-server';
4362     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
4363     debugcmd ">",@cmd;
4364     exec @cmd or fail "exec git clone: $!\n";
4365 }
4366
4367 sub cmd_setup_mergechangelogs {
4368     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
4369     setup_mergechangelogs(1);
4370 }
4371
4372 sub cmd_setup_useremail {
4373     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
4374     setup_useremail(1);
4375 }
4376
4377 sub cmd_setup_new_tree {
4378     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
4379     setup_new_tree();
4380 }
4381
4382 #---------- argument parsing and main program ----------
4383
4384 sub cmd_version {
4385     print "dgit version $our_version\n" or die $!;
4386     exit 0;
4387 }
4388
4389 our (%valopts_long, %valopts_short);
4390 our @rvalopts;
4391
4392 sub defvalopt ($$$$) {
4393     my ($long,$short,$val_re,$how) = @_;
4394     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
4395     $valopts_long{$long} = $oi;
4396     $valopts_short{$short} = $oi;
4397     # $how subref should:
4398     #   do whatever assignemnt or thing it likes with $_[0]
4399     #   if the option should not be passed on to remote, @rvalopts=()
4400     # or $how can be a scalar ref, meaning simply assign the value
4401 }
4402
4403 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
4404 defvalopt '--distro',        '-d', '.+',      \$idistro;
4405 defvalopt '',                '-k', '.+',      \$keyid;
4406 defvalopt '--existing-package','', '.*',      \$existing_package;
4407 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
4408 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
4409 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
4410
4411 defvalopt '', '-c', '.*=.*', sub { push @git, '-c', @_; };
4412
4413 defvalopt '', '-C', '.+', sub {
4414     ($changesfile) = (@_);
4415     if ($changesfile =~ s#^(.*)/##) {
4416         $buildproductsdir = $1;
4417     }
4418 };
4419
4420 defvalopt '--initiator-tempdir','','.*', sub {
4421     ($initiator_tempdir) = (@_);
4422     $initiator_tempdir =~ m#^/# or
4423         badusage "--initiator-tempdir must be used specify an".
4424         " absolute, not relative, directory."
4425 };
4426
4427 sub parseopts () {
4428     my $om;
4429
4430     if (defined $ENV{'DGIT_SSH'}) {
4431         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
4432     } elsif (defined $ENV{'GIT_SSH'}) {
4433         @ssh = ($ENV{'GIT_SSH'});
4434     }
4435
4436     my $oi;
4437     my $val;
4438     my $valopt = sub {
4439         my ($what) = @_;
4440         @rvalopts = ($_);
4441         if (!defined $val) {
4442             badusage "$what needs a value" unless @ARGV;
4443             $val = shift @ARGV;
4444             push @rvalopts, $val;
4445         }
4446         badusage "bad value \`$val' for $what" unless
4447             $val =~ m/^$oi->{Re}$(?!\n)/s;
4448         my $how = $oi->{How};
4449         if (ref($how) eq 'SCALAR') {
4450             $$how = $val;
4451         } else {
4452             $how->($val);
4453         }
4454         push @ropts, @rvalopts;
4455     };
4456
4457     while (@ARGV) {
4458         last unless $ARGV[0] =~ m/^-/;
4459         $_ = shift @ARGV;
4460         last if m/^--?$/;
4461         if (m/^--/) {
4462             if (m/^--dry-run$/) {
4463                 push @ropts, $_;
4464                 $dryrun_level=2;
4465             } elsif (m/^--damp-run$/) {
4466                 push @ropts, $_;
4467                 $dryrun_level=1;
4468             } elsif (m/^--no-sign$/) {
4469                 push @ropts, $_;
4470                 $sign=0;
4471             } elsif (m/^--help$/) {
4472                 cmd_help();
4473             } elsif (m/^--version$/) {
4474                 cmd_version();
4475             } elsif (m/^--new$/) {
4476                 push @ropts, $_;
4477                 $new_package=1;
4478             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
4479                      ($om = $opts_opt_map{$1}) &&
4480                      length $om->[0]) {
4481                 push @ropts, $_;
4482                 $om->[0] = $2;
4483             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
4484                      !$opts_opt_cmdonly{$1} &&
4485                      ($om = $opts_opt_map{$1})) {
4486                 push @ropts, $_;
4487                 push @$om, $2;
4488             } elsif (m/^--ignore-dirty$/s) {
4489                 push @ropts, $_;
4490                 $ignoredirty = 1;
4491             } elsif (m/^--no-quilt-fixup$/s) {
4492                 push @ropts, $_;
4493                 $quilt_mode = 'nocheck';
4494             } elsif (m/^--no-rm-on-error$/s) {
4495                 push @ropts, $_;
4496                 $rmonerror = 0;
4497             } elsif (m/^--(no-)?rm-old-changes$/s) {
4498                 push @ropts, $_;
4499                 $rmchanges = !$1;
4500             } elsif (m/^--deliberately-($deliberately_re)$/s) {
4501                 push @ropts, $_;
4502                 push @deliberatelies, $&;
4503             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
4504                 # undocumented, for testing
4505                 push @ropts, $_;
4506                 $tagformat_want = [ $1, 'command line', 1 ];
4507                 # 1 menas overrides distro configuration
4508             } elsif (m/^--always-split-source-build$/s) {
4509                 # undocumented, for testing
4510                 push @ropts, $_;
4511                 $need_split_build_invocation = 1;
4512             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
4513                 $val = $2 ? $' : undef; #';
4514                 $valopt->($oi->{Long});
4515             } else {
4516                 badusage "unknown long option \`$_'";
4517             }
4518         } else {
4519             while (m/^-./s) {
4520                 if (s/^-n/-/) {
4521                     push @ropts, $&;
4522                     $dryrun_level=2;
4523                 } elsif (s/^-L/-/) {
4524                     push @ropts, $&;
4525                     $dryrun_level=1;
4526                 } elsif (s/^-h/-/) {
4527                     cmd_help();
4528                 } elsif (s/^-D/-/) {
4529                     push @ropts, $&;
4530                     $debuglevel++;
4531                     enabledebug();
4532                 } elsif (s/^-N/-/) {
4533                     push @ropts, $&;
4534                     $new_package=1;
4535                 } elsif (m/^-m/) {
4536                     push @ropts, $&;
4537                     push @changesopts, $_;
4538                     $_ = '';
4539                 } elsif (s/^-wn$//s) {
4540                     push @ropts, $&;
4541                     $cleanmode = 'none';
4542                 } elsif (s/^-wg$//s) {
4543                     push @ropts, $&;
4544                     $cleanmode = 'git';
4545                 } elsif (s/^-wgf$//s) {
4546                     push @ropts, $&;
4547                     $cleanmode = 'git-ff';
4548                 } elsif (s/^-wd$//s) {
4549                     push @ropts, $&;
4550                     $cleanmode = 'dpkg-source';
4551                 } elsif (s/^-wdd$//s) {
4552                     push @ropts, $&;
4553                     $cleanmode = 'dpkg-source-d';
4554                 } elsif (s/^-wc$//s) {
4555                     push @ropts, $&;
4556                     $cleanmode = 'check';
4557                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
4558                     $val = $'; #';
4559                     $val = undef unless length $val;
4560                     $valopt->($oi->{Short});
4561                     $_ = '';
4562                 } else {
4563                     badusage "unknown short option \`$_'";
4564                 }
4565             }
4566         }
4567     }
4568 }
4569
4570 sub finalise_opts_opts () {
4571     foreach my $k (keys %opts_opt_map) {
4572         my $om = $opts_opt_map{$k};
4573
4574         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
4575         if (defined $v) {
4576             badcfg "cannot set command for $k"
4577                 unless length $om->[0];
4578             $om->[0] = $v;
4579         }
4580
4581         foreach my $c (access_cfg_cfgs("opts-$k")) {
4582             my $vl = $gitcfg{$c};
4583             printdebug "CL $c ",
4584                 ($vl ? join " ", map { shellquote } @$vl : ""),
4585                 "\n" if $debuglevel >= 4;
4586             next unless $vl;
4587             badcfg "cannot configure options for $k"
4588                 if $opts_opt_cmdonly{$k};
4589             my $insertpos = $opts_cfg_insertpos{$k};
4590             @$om = ( @$om[0..$insertpos-1],
4591                      @$vl,
4592                      @$om[$insertpos..$#$om] );
4593         }
4594     }
4595 }
4596
4597 if ($ENV{$fakeeditorenv}) {
4598     git_slurp_config();
4599     quilt_fixup_editor();
4600 }
4601
4602 parseopts();
4603 git_slurp_config();
4604
4605 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
4606 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
4607     if $dryrun_level == 1;
4608 if (!@ARGV) {
4609     print STDERR $helpmsg or die $!;
4610     exit 8;
4611 }
4612 my $cmd = shift @ARGV;
4613 $cmd =~ y/-/_/;
4614
4615 if (!defined $rmchanges) {
4616     local $access_forpush;
4617     $rmchanges = access_cfg_bool(0, 'rm-old-changes');
4618 }
4619
4620 if (!defined $quilt_mode) {
4621     local $access_forpush;
4622     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
4623         // access_cfg('quilt-mode', 'RETURN-UNDEF')
4624         // 'linear';
4625     $quilt_mode =~ m/^($quilt_modes_re)$/
4626         or badcfg "unknown quilt-mode \`$quilt_mode'";
4627     $quilt_mode = $1;
4628 }
4629
4630 $need_split_build_invocation ||= quiltmode_splitbrain();
4631
4632 if (!defined $cleanmode) {
4633     local $access_forpush;
4634     $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
4635     $cleanmode //= 'dpkg-source';
4636
4637     badcfg "unknown clean-mode \`$cleanmode'" unless
4638         $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
4639 }
4640
4641 my $fn = ${*::}{"cmd_$cmd"};
4642 $fn or badusage "unknown operation $cmd";
4643 $fn->();