dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2018 Ian Jackson
   6 # Copyright (C)2017-2018 Sean Whitton
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23
  24 use strict;
  25
  26 use Debian::Dgit qw(:DEFAULT :playground);
  27 setup_sigwarn();
  28
  29 use IO::Handle;
  30 use Data::Dumper;
  31 use LWP::UserAgent;
  32 use Dpkg::Control::Hash;
  33 use File::Path;
  34 use File::Temp qw(tempdir);
  35 use File::Basename;
  36 use Dpkg::Version;
  37 use Dpkg::Compression;
  38 use Dpkg::Compression::Process;
  39 use POSIX;
  40 use IPC::Open2;
  41 use Digest::SHA;
  42 use Digest::MD5;
  43 use List::MoreUtils qw(pairwise);
  44 use Text::Glob qw(match_glob);
  45 use Fcntl qw(:DEFAULT :flock);
  46 use Carp;
  47
  48 use Debian::Dgit;
  49
  50 our $our_version = 'UNRELEASED'; ###substituted###
  51 our $absurdity = undef; ###substituted###
  52
  53 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  54 our $protovsn;
  55
  56 our $cmd;
  57 our $subcommand;
  58 our $isuite;
  59 our $idistro;
  60 our $package;
  61 our @ropts;
  62
  63 our $sign = 1;
  64 our $dryrun_level = 0;
  65 our $changesfile;
  66 our $buildproductsdir;
  67 our $bpd_glob;
  68 our $new_package = 0;
  69 our $includedirty = 0;
  70 our $rmonerror = 1;
  71 our @deliberatelies;
  72 our %previously;
  73 our $existing_package = 'dpkg';
  74 our $cleanmode;
  75 our $changes_since_version;
  76 our $rmchanges;
  77 our $overwrite_version; # undef: not specified; '': check changelog
  78 our $quilt_mode;
  79 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  80 our $dodep14tag;
  81 our %internal_object_save;
  82 our $we_are_responder;
  83 our $we_are_initiator;
  84 our $initiator_tempdir;
  85 our $patches_applied_dirtily = 00;
  86 our $tagformat_want;
  87 our $tagformat;
  88 our $tagformatfn;
  89 our $chase_dsc_distro=1;
  90
  91 our %forceopts = map { $_=>0 }
  92     qw(unrepresentable unsupported-source-format
  93        dsc-changes-mismatch changes-origs-exactly
  94        uploading-binaries uploading-source-only
  95        import-gitapply-absurd
  96        import-gitapply-no-absurd
  97        import-dsc-with-dgit-field);
  98
  99 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
 100
 101 our $suite_re = '[-+.0-9a-z]+';
 102 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
 103
 104 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 105 our $splitbraincache = 'dgit-intern/quilt-cache';
 106 our $rewritemap = 'dgit-rewrite/map';
 107
 108 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
 109
 110 our (@git) = qw(git);
 111 our (@dget) = qw(dget);
 112 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 113 our (@dput) = qw(dput);
 114 our (@debsign) = qw(debsign);
 115 our (@gpg) = qw(gpg);
 116 our (@sbuild) = qw(sbuild);
 117 our (@ssh) = 'ssh';
 118 our (@dgit) = qw(dgit);
 119 our (@git_debrebase) = qw(git-debrebase);
 120 our (@aptget) = qw(apt-get);
 121 our (@aptcache) = qw(apt-cache);
 122 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
 123 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
 124 our (@dpkggenchanges) = qw(dpkg-genchanges);
 125 our (@mergechanges) = qw(mergechanges -f);
 126 our (@gbp_build) = ('');
 127 our (@gbp_pq) = ('gbp pq');
 128 our (@changesopts) = ('');
 129 our (@pbuilder) = ("sudo -E pbuilder");
 130 our (@cowbuilder) = ("sudo -E cowbuilder");
 131
 132 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 133                      'curl' => \@curl,
 134                      'dput' => \@dput,
 135                      'debsign' => \@debsign,
 136                      'gpg' => \@gpg,
 137                      'sbuild' => \@sbuild,
 138                      'ssh' => \@ssh,
 139                      'dgit' => \@dgit,
 140                      'git' => \@git,
 141                      'git-debrebase' => \@git_debrebase,
 142                      'apt-get' => \@aptget,
 143                      'apt-cache' => \@aptcache,
 144                      'dpkg-source' => \@dpkgsource,
 145                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 146                      'dpkg-genchanges' => \@dpkggenchanges,
 147                      'gbp-build' => \@gbp_build,
 148                      'gbp-pq' => \@gbp_pq,
 149                      'ch' => \@changesopts,
 150                      'mergechanges' => \@mergechanges,
 151                      'pbuilder' => \@pbuilder,
 152                      'cowbuilder' => \@cowbuilder);
 153
 154 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 155 our %opts_cfg_insertpos = map {
 156     $_,
 157     scalar @{ $opts_opt_map{$_} }
 158 } keys %opts_opt_map;
 159
 160 sub parseopts_late_defaults();
 161 sub setup_gitattrs(;$);
 162 sub check_gitattrs($$);
 163
 164 our $playground;
 165 our $keyid;
 166
 167 autoflush STDOUT 1;
 168
 169 our $supplementary_message = '';
 170 our $split_brain = 0;
 171
 172 END {
 173     local ($@, $?);
 174     return unless forkcheck_mainprocess();
 175     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 176 }
 177
 178 our $remotename = 'dgit';
 179 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 180 our $csuite;
 181 our $instead_distro;
 182
 183 if (!defined $absurdity) {
 184     $absurdity = $0;
 185     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 186 }
 187
 188 sub debiantag ($$) {
 189     my ($v,$distro) = @_;
 190     return $tagformatfn->($v, $distro);
 191 }
 192
 193 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 194
 195 sub lbranch () { return "$branchprefix/$csuite"; }
 196 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 197 sub lref () { return "refs/heads/".lbranch(); }
 198 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 199 sub rrref () { return server_ref($csuite); }
 200
 201 sub srcfn ($$) {
 202     my ($vsn, $sfx) = @_;
 203     return &source_file_leafname($package, $vsn, $sfx);
 204 }
 205 sub is_orig_file_of_vsn ($$) {
 206     my ($f, $upstreamvsn) = @_;
 207     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
 208 }
 209
 210 sub dscfn ($) {
 211     my ($vsn) = @_;
 212     return srcfn($vsn,".dsc");
 213 }
 214
 215 sub changespat ($;$) {
 216     my ($vsn, $arch) = @_;
 217     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 218 }
 219
 220 our $us = 'dgit';
 221 initdebug('');
 222
 223 our @end;
 224 END {
 225     local ($?);
 226     return unless forkcheck_mainprocess();
 227     foreach my $f (@end) {
 228         eval { $f->(); };
 229         print STDERR "$us: cleanup: $@" if length $@;
 230     }
 231 };
 232
 233 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; finish 12; }
 234
 235 sub forceable_fail ($$) {
 236     my ($forceoptsl, $msg) = @_;
 237     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 238     print STDERR "warning: overriding problem due to --force:\n". $msg;
 239 }
 240
 241 sub forceing ($) {
 242     my ($forceoptsl) = @_;
 243     my @got = grep { $forceopts{$_} } @$forceoptsl;
 244     return 0 unless @got;
 245     print STDERR
 246  "warning: skipping checks or functionality due to --force-$got[0]\n";
 247 }
 248
 249 sub no_such_package () {
 250     print STDERR "$us: package $package does not exist in suite $isuite\n";
 251     finish 4;
 252 }
 253
 254 sub deliberately ($) {
 255     my ($enquiry) = @_;
 256     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 257 }
 258
 259 sub deliberately_not_fast_forward () {
 260     foreach (qw(not-fast-forward fresh-repo)) {
 261         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 262     }
 263 }
 264
 265 sub quiltmode_splitbrain () {
 266     $quilt_mode =~ m/gbp|dpm|unapplied/;
 267 }
 268
 269 sub opts_opt_multi_cmd {
 270     my $extra = shift;
 271     my @cmd;
 272     push @cmd, split /\s+/, shift @_;
 273     push @cmd, @$extra;
 274     push @cmd, @_;
 275     @cmd;
 276 }
 277
 278 sub gbp_pq {
 279     return opts_opt_multi_cmd [], @gbp_pq;
 280 }
 281
 282 sub dgit_privdir () {
 283     our $dgit_privdir_made //= ensure_a_playground 'dgit';
 284 }
 285
 286 sub bpd_abs () {
 287     my $r = $buildproductsdir;
 288     $r = "$maindir/$r" unless $r =~ m{^/};
 289     return $r;
 290 }
 291
 292 sub branch_gdr_info ($$) {
 293     my ($symref, $head) = @_;
 294     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
 295         gdr_ffq_prev_branchinfo($symref);
 296     return () unless $status eq 'branch';
 297     $ffq_prev = git_get_ref $ffq_prev;
 298     $gdrlast  = git_get_ref $gdrlast;
 299     $gdrlast &&= is_fast_fwd $gdrlast, $head;
 300     return ($ffq_prev, $gdrlast);
 301 }
 302
 303 sub branch_is_gdr ($$) {
 304     my ($symref, $head) = @_;
 305     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 306     return 0 unless $ffq_prev || $gdrlast;
 307     return 1;
 308 }
 309
 310 sub branch_is_gdr_unstitched_ff ($$$) {
 311     my ($symref, $head, $ancestor) = @_;
 312     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 313     return 0 unless $ffq_prev;
 314     return 0 unless is_fast_fwd $ancestor, $ffq_prev;
 315     return 1;
 316 }
 317
 318 #---------- remote protocol support, common ----------
 319
 320 # remote push initiator/responder protocol:
 321 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 322 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 323 #  < dgit-remote-push-ready <actual-proto-vsn>
 324 #
 325 # occasionally:
 326 #
 327 #  > progress NBYTES
 328 #  [NBYTES message]
 329 #
 330 #  > supplementary-message NBYTES          # $protovsn >= 3
 331 #  [NBYTES message]
 332 #
 333 # main sequence:
 334 #
 335 #  > file parsed-changelog
 336 #  [indicates that output of dpkg-parsechangelog follows]
 337 #  > data-block NBYTES
 338 #  > [NBYTES bytes of data (no newline)]
 339 #  [maybe some more blocks]
 340 #  > data-end
 341 #
 342 #  > file dsc
 343 #  [etc]
 344 #
 345 #  > file changes
 346 #  [etc]
 347 #
 348 #  > param head DGIT-VIEW-HEAD
 349 #  > param csuite SUITE
 350 #  > param tagformat old|new
 351 #  > param maint-view MAINT-VIEW-HEAD
 352 #
 353 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 354 #  > file buildinfo                             # for buildinfos to sign
 355 #
 356 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 357 #                                     # goes into tag, for replay prevention
 358 #
 359 #  > want signed-tag
 360 #  [indicates that signed tag is wanted]
 361 #  < data-block NBYTES
 362 #  < [NBYTES bytes of data (no newline)]
 363 #  [maybe some more blocks]
 364 #  < data-end
 365 #  < files-end
 366 #
 367 #  > want signed-dsc-changes
 368 #  < data-block NBYTES    [transfer of signed dsc]
 369 #  [etc]
 370 #  < data-block NBYTES    [transfer of signed changes]
 371 #  [etc]
 372 #  < data-block NBYTES    [transfer of each signed buildinfo
 373 #  [etc]                   same number and order as "file buildinfo"]
 374 #  ...
 375 #  < files-end
 376 #
 377 #  > complete
 378
 379 our $i_child_pid;
 380
 381 sub i_child_report () {
 382     # Sees if our child has died, and reap it if so.  Returns a string
 383     # describing how it died if it failed, or undef otherwise.
 384     return undef unless $i_child_pid;
 385     my $got = waitpid $i_child_pid, WNOHANG;
 386     return undef if $got <= 0;
 387     die unless $got == $i_child_pid;
 388     $i_child_pid = undef;
 389     return undef unless $?;
 390     return "build host child ".waitstatusmsg();
 391 }
 392
 393 sub badproto ($$) {
 394     my ($fh, $m) = @_;
 395     fail "connection lost: $!" if $fh->error;
 396     fail "protocol violation; $m not expected";
 397 }
 398
 399 sub badproto_badread ($$) {
 400     my ($fh, $wh) = @_;
 401     fail "connection lost: $!" if $!;
 402     my $report = i_child_report();
 403     fail $report if defined $report;
 404     badproto $fh, "eof (reading $wh)";
 405 }
 406
 407 sub protocol_expect (&$) {
 408     my ($match, $fh) = @_;
 409     local $_;
 410     $_ = <$fh>;
 411     defined && chomp or badproto_badread $fh, "protocol message";
 412     if (wantarray) {
 413         my @r = &$match;
 414         return @r if @r;
 415     } else {
 416         my $r = &$match;
 417         return $r if $r;
 418     }
 419     badproto $fh, "\`$_'";
 420 }
 421
 422 sub protocol_send_file ($$) {
 423     my ($fh, $ourfn) = @_;
 424     open PF, "<", $ourfn or die "$ourfn: $!";
 425     for (;;) {
 426         my $d;
 427         my $got = read PF, $d, 65536;
 428         die "$ourfn: $!" unless defined $got;
 429         last if !$got;
 430         print $fh "data-block ".length($d)."\n" or die $!;
 431         print $fh $d or die $!;
 432     }
 433     PF->error and die "$ourfn $!";
 434     print $fh "data-end\n" or die $!;
 435     close PF;
 436 }
 437
 438 sub protocol_read_bytes ($$) {
 439     my ($fh, $nbytes) = @_;
 440     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 441     my $d;
 442     my $got = read $fh, $d, $nbytes;
 443     $got==$nbytes or badproto_badread $fh, "data block";
 444     return $d;
 445 }
 446
 447 sub protocol_receive_file ($$) {
 448     my ($fh, $ourfn) = @_;
 449     printdebug "() $ourfn\n";
 450     open PF, ">", $ourfn or die "$ourfn: $!";
 451     for (;;) {
 452         my ($y,$l) = protocol_expect {
 453             m/^data-block (.*)$/ ? (1,$1) :
 454             m/^data-end$/ ? (0,) :
 455             ();
 456         } $fh;
 457         last unless $y;
 458         my $d = protocol_read_bytes $fh, $l;
 459         print PF $d or die $!;
 460     }
 461     close PF or die $!;
 462 }
 463
 464 #---------- remote protocol support, responder ----------
 465
 466 sub responder_send_command ($) {
 467     my ($command) = @_;
 468     return unless $we_are_responder;
 469     # called even without $we_are_responder
 470     printdebug ">> $command\n";
 471     print PO $command, "\n" or die $!;
 472 }
 473
 474 sub responder_send_file ($$) {
 475     my ($keyword, $ourfn) = @_;
 476     return unless $we_are_responder;
 477     printdebug "]] $keyword $ourfn\n";
 478     responder_send_command "file $keyword";
 479     protocol_send_file \*PO, $ourfn;
 480 }
 481
 482 sub responder_receive_files ($@) {
 483     my ($keyword, @ourfns) = @_;
 484     die unless $we_are_responder;
 485     printdebug "[[ $keyword @ourfns\n";
 486     responder_send_command "want $keyword";
 487     foreach my $fn (@ourfns) {
 488         protocol_receive_file \*PI, $fn;
 489     }
 490     printdebug "[[\$\n";
 491     protocol_expect { m/^files-end$/ } \*PI;
 492 }
 493
 494 #---------- remote protocol support, initiator ----------
 495
 496 sub initiator_expect (&) {
 497     my ($match) = @_;
 498     protocol_expect { &$match } \*RO;
 499 }
 500
 501 #---------- end remote code ----------
 502
 503 sub progress {
 504     if ($we_are_responder) {
 505         my $m = join '', @_;
 506         responder_send_command "progress ".length($m) or die $!;
 507         print PO $m or die $!;
 508     } else {
 509         print @_, "\n";
 510     }
 511 }
 512
 513 our $ua;
 514
 515 sub url_get {
 516     if (!$ua) {
 517         $ua = LWP::UserAgent->new();
 518         $ua->env_proxy;
 519     }
 520     my $what = $_[$#_];
 521     progress "downloading $what...";
 522     my $r = $ua->get(@_) or die $!;
 523     return undef if $r->code == 404;
 524     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 525     return $r->decoded_content(charset => 'none');
 526 }
 527
 528 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 529
 530 sub act_local () { return $dryrun_level <= 1; }
 531 sub act_scary () { return !$dryrun_level; }
 532
 533 sub printdone {
 534     if (!$dryrun_level) {
 535         progress "$us ok: @_";
 536     } else {
 537         progress "would be ok: @_ (but dry run only)";
 538     }
 539 }
 540
 541 sub dryrun_report {
 542     printcmd(\*STDERR,$debugprefix."#",@_);
 543 }
 544
 545 sub runcmd_ordryrun {
 546     if (act_scary()) {
 547         runcmd @_;
 548     } else {
 549         dryrun_report @_;
 550     }
 551 }
 552
 553 sub runcmd_ordryrun_local {
 554     if (act_local()) {
 555         runcmd @_;
 556     } else {
 557         dryrun_report @_;
 558     }
 559 }
 560
 561 our $helpmsg = <<END;
 562 main usages:
 563   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 564   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 565   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 566   dgit [dgit-opts] sbuild [sbuild-opts]
 567   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
 568   dgit [dgit-opts] push [dgit-opts] [suite]
 569   dgit [dgit-opts] push-source [dgit-opts] [suite]
 570   dgit [dgit-opts] rpush build-host:build-dir ...
 571 important dgit options:
 572   -k<keyid>           sign tag and package with <keyid> instead of default
 573   --dry-run -n        do not change anything, but go through the motions
 574   --damp-run -L       like --dry-run but make local changes, without signing
 575   --new -N            allow introducing a new package
 576   --debug -D          increase debug level
 577   -c<name>=<value>    set git config option (used directly by dgit too)
 578 END
 579
 580 our $later_warning_msg = <<END;
 581 Perhaps the upload is stuck in incoming.  Using the version from git.
 582 END
 583
 584 sub badusage {
 585     print STDERR "$us: @_\n", $helpmsg or die $!;
 586     finish 8;
 587 }
 588
 589 sub nextarg {
 590     @ARGV or badusage "too few arguments";
 591     return scalar shift @ARGV;
 592 }
 593
 594 sub pre_help () {
 595     not_necessarily_a_tree();
 596 }
 597 sub cmd_help () {
 598     print $helpmsg or die $!;
 599     finish 0;
 600 }
 601
 602 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 603
 604 our %defcfg = ('dgit.default.distro' => 'debian',
 605                'dgit.default.default-suite' => 'unstable',
 606                'dgit.default.old-dsc-distro' => 'debian',
 607                'dgit-suite.*-security.distro' => 'debian-security',
 608                'dgit.default.username' => '',
 609                'dgit.default.archive-query-default-component' => 'main',
 610                'dgit.default.ssh' => 'ssh',
 611                'dgit.default.archive-query' => 'madison:',
 612                'dgit.default.sshpsql-dbname' => 'service=projectb',
 613                'dgit.default.aptget-components' => 'main',
 614                'dgit.default.dgit-tag-format' => 'new,old,maint',
 615                'dgit.default.source-only-uploads' => 'ok',
 616                'dgit.dsc-url-proto-ok.http'    => 'true',
 617                'dgit.dsc-url-proto-ok.https'   => 'true',
 618                'dgit.dsc-url-proto-ok.git'     => 'true',
 619                'dgit.vcs-git.suites',          => 'sid', # ;-separated
 620                'dgit.default.dsc-url-proto-ok' => 'false',
 621                # old means "repo server accepts pushes with old dgit tags"
 622                # new means "repo server accepts pushes with new dgit tags"
 623                # maint means "repo server accepts split brain pushes"
 624                # hist means "repo server may have old pushes without new tag"
 625                #   ("hist" is implied by "old")
 626                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 627                'dgit-distro.debian.git-check' => 'url',
 628                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 629                'dgit-distro.debian.new-private-pushers' => 't',
 630                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
 631                'dgit-distro.debian/push.git-url' => '',
 632                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 633                'dgit-distro.debian/push.git-user-force' => 'dgit',
 634                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 635                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 636                'dgit-distro.debian/push.git-create' => 'true',
 637                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 638  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 639 # 'dgit-distro.debian.archive-query-tls-key',
 640 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 641 # ^ this does not work because curl is broken nowadays
 642 # Fixing #790093 properly will involve providing providing the key
 643 # in some pacagke and maybe updating these paths.
 644 #
 645 # 'dgit-distro.debian.archive-query-tls-curl-args',
 646 #   '--ca-path=/etc/ssl/ca-debian',
 647 # ^ this is a workaround but works (only) on DSA-administered machines
 648                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 649                'dgit-distro.debian.git-url-suffix' => '',
 650                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 651                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 652  'dgit-distro.debian-security.archive-query' => 'aptget:',
 653  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 654  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 655  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 656  'dgit-distro.debian-security.nominal-distro' => 'debian',
 657  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 658  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 659                'dgit-distro.ubuntu.git-check' => 'false',
 660  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 661                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 662                'dgit-distro.test-dummy.username' => "alice",
 663                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 664                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 665                'dgit-distro.test-dummy.git-url' => "$td/git",
 666                'dgit-distro.test-dummy.git-host' => "git",
 667                'dgit-distro.test-dummy.git-path' => "$td/git",
 668                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 669                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 670                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 671                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 672                );
 673
 674 our %gitcfgs;
 675 our @gitcfgsources = qw(cmdline local global system);
 676 our $invoked_in_git_tree = 1;
 677
 678 sub git_slurp_config () {
 679     # This algoritm is a bit subtle, but this is needed so that for
 680     # options which we want to be single-valued, we allow the
 681     # different config sources to override properly.  See #835858.
 682     foreach my $src (@gitcfgsources) {
 683         next if $src eq 'cmdline';
 684         # we do this ourselves since git doesn't handle it
 685
 686         $gitcfgs{$src} = git_slurp_config_src $src;
 687     }
 688 }
 689
 690 sub git_get_config ($) {
 691     my ($c) = @_;
 692     foreach my $src (@gitcfgsources) {
 693         my $l = $gitcfgs{$src}{$c};
 694         confess "internal error ($l $c)" if $l && !ref $l;
 695         printdebug"C $c ".(defined $l ?
 696                            join " ", map { messagequote "'$_'" } @$l :
 697                            "undef")."\n"
 698             if $debuglevel >= 4;
 699         $l or next;
 700         @$l==1 or badcfg "multiple values for $c".
 701             " (in $src git config)" if @$l > 1;
 702         return $l->[0];
 703     }
 704     return undef;
 705 }
 706
 707 sub cfg {
 708     foreach my $c (@_) {
 709         return undef if $c =~ /RETURN-UNDEF/;
 710         printdebug "C? $c\n" if $debuglevel >= 5;
 711         my $v = git_get_config($c);
 712         return $v if defined $v;
 713         my $dv = $defcfg{$c};
 714         if (defined $dv) {
 715             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 716             return $dv;
 717         }
 718     }
 719     badcfg "need value for one of: @_\n".
 720         "$us: distro or suite appears not to be (properly) supported";
 721 }
 722
 723 sub not_necessarily_a_tree () {
 724     # needs to be called from pre_*
 725     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 726     $invoked_in_git_tree = 0;
 727 }
 728
 729 sub access_basedistro__noalias () {
 730     if (defined $idistro) {
 731         return $idistro;
 732     } else {
 733         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 734         return $def if defined $def;
 735         foreach my $src (@gitcfgsources, 'internal') {
 736             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 737             next unless $kl;
 738             foreach my $k (keys %$kl) {
 739                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 740                 my $dpat = $1;
 741                 next unless match_glob $dpat, $isuite;
 742                 return $kl->{$k};
 743             }
 744         }
 745         return cfg("dgit.default.distro");
 746     }
 747 }
 748
 749 sub access_basedistro () {
 750     my $noalias = access_basedistro__noalias();
 751     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 752     return $canon // $noalias;
 753 }
 754
 755 sub access_nomdistro () {
 756     my $base = access_basedistro();
 757     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 758     $r =~ m/^$distro_re$/ or badcfg
 759  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 760     return $r;
 761 }
 762
 763 sub access_quirk () {
 764     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 765     my $basedistro = access_basedistro();
 766     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 767                               'RETURN-UNDEF');
 768     if (defined $backports_quirk) {
 769         my $re = $backports_quirk;
 770         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 771         $re =~ s/\*/.*/g;
 772         $re =~ s/\%/([-0-9a-z_]+)/
 773             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 774         if ($isuite =~ m/^$re$/) {
 775             return ('backports',"$basedistro-backports",$1);
 776         }
 777     }
 778     return ('none',undef);
 779 }
 780
 781 our $access_forpush;
 782
 783 sub parse_cfg_bool ($$$) {
 784     my ($what,$def,$v) = @_;
 785     $v //= $def;
 786     return
 787         $v =~ m/^[ty1]/ ? 1 :
 788         $v =~ m/^[fn0]/ ? 0 :
 789         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 790 }
 791
 792 sub access_forpush_config () {
 793     my $d = access_basedistro();
 794
 795     return 1 if
 796         $new_package &&
 797         parse_cfg_bool('new-private-pushers', 0,
 798                        cfg("dgit-distro.$d.new-private-pushers",
 799                            'RETURN-UNDEF'));
 800
 801     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 802     $v //= 'a';
 803     return
 804         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 805         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 806         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 807         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 808 }
 809
 810 sub access_forpush () {
 811     $access_forpush //= access_forpush_config();
 812     return $access_forpush;
 813 }
 814
 815 sub pushing () {
 816     confess 'internal error '.Dumper($access_forpush)," ?" if
 817         defined $access_forpush and !$access_forpush;
 818     badcfg "pushing but distro is configured readonly"
 819         if access_forpush_config() eq '0';
 820     $access_forpush = 1;
 821     $supplementary_message = <<'END' unless $we_are_responder;
 822 Push failed, before we got started.
 823 You can retry the push, after fixing the problem, if you like.
 824 END
 825     parseopts_late_defaults();
 826 }
 827
 828 sub notpushing () {
 829     parseopts_late_defaults();
 830 }
 831
 832 sub supplementary_message ($) {
 833     my ($msg) = @_;
 834     if (!$we_are_responder) {
 835         $supplementary_message = $msg;
 836         return;
 837     } elsif ($protovsn >= 3) {
 838         responder_send_command "supplementary-message ".length($msg)
 839             or die $!;
 840         print PO $msg or die $!;
 841     }
 842 }
 843
 844 sub access_distros () {
 845     # Returns list of distros to try, in order
 846     #
 847     # We want to try:
 848     #    0. `instead of' distro name(s) we have been pointed to
 849     #    1. the access_quirk distro, if any
 850     #    2a. the user's specified distro, or failing that  } basedistro
 851     #    2b. the distro calculated from the suite          }
 852     my @l = access_basedistro();
 853
 854     my (undef,$quirkdistro) = access_quirk();
 855     unshift @l, $quirkdistro;
 856     unshift @l, $instead_distro;
 857     @l = grep { defined } @l;
 858
 859     push @l, access_nomdistro();
 860
 861     if (access_forpush()) {
 862         @l = map { ("$_/push", $_) } @l;
 863     }
 864     @l;
 865 }
 866
 867 sub access_cfg_cfgs (@) {
 868     my (@keys) = @_;
 869     my @cfgs;
 870     # The nesting of these loops determines the search order.  We put
 871     # the key loop on the outside so that we search all the distros
 872     # for each key, before going on to the next key.  That means that
 873     # if access_cfg is called with a more specific, and then a less
 874     # specific, key, an earlier distro can override the less specific
 875     # without necessarily overriding any more specific keys.  (If the
 876     # distro wants to override the more specific keys it can simply do
 877     # so; whereas if we did the loop the other way around, it would be
 878     # impossible to for an earlier distro to override a less specific
 879     # key but not the more specific ones without restating the unknown
 880     # values of the more specific keys.
 881     my @realkeys;
 882     my @rundef;
 883     # We have to deal with RETURN-UNDEF specially, so that we don't
 884     # terminate the search prematurely.
 885     foreach (@keys) {
 886         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 887         push @realkeys, $_
 888     }
 889     foreach my $d (access_distros()) {
 890         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 891     }
 892     push @cfgs, map { "dgit.default.$_" } @realkeys;
 893     push @cfgs, @rundef;
 894     return @cfgs;
 895 }
 896
 897 sub access_cfg (@) {
 898     my (@keys) = @_;
 899     my (@cfgs) = access_cfg_cfgs(@keys);
 900     my $value = cfg(@cfgs);
 901     return $value;
 902 }
 903
 904 sub access_cfg_bool ($$) {
 905     my ($def, @keys) = @_;
 906     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 907 }
 908
 909 sub string_to_ssh ($) {
 910     my ($spec) = @_;
 911     if ($spec =~ m/\s/) {
 912         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 913     } else {
 914         return ($spec);
 915     }
 916 }
 917
 918 sub access_cfg_ssh () {
 919     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 920     if (!defined $gitssh) {
 921         return @ssh;
 922     } else {
 923         return string_to_ssh $gitssh;
 924     }
 925 }
 926
 927 sub access_runeinfo ($) {
 928     my ($info) = @_;
 929     return ": dgit ".access_basedistro()." $info ;";
 930 }
 931
 932 sub access_someuserhost ($) {
 933     my ($some) = @_;
 934     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 935     defined($user) && length($user) or
 936         $user = access_cfg("$some-user",'username');
 937     my $host = access_cfg("$some-host");
 938     return length($user) ? "$user\@$host" : $host;
 939 }
 940
 941 sub access_gituserhost () {
 942     return access_someuserhost('git');
 943 }
 944
 945 sub access_giturl (;$) {
 946     my ($optional) = @_;
 947     my $url = access_cfg('git-url','RETURN-UNDEF');
 948     my $suffix;
 949     if (!length $url) {
 950         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 951         return undef unless defined $proto;
 952         $url =
 953             $proto.
 954             access_gituserhost().
 955             access_cfg('git-path');
 956     } else {
 957         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 958     }
 959     $suffix //= '.git';
 960     return "$url/$package$suffix";
 961 }
 962
 963 sub commit_getclogp ($) {
 964     # Returns the parsed changelog hashref for a particular commit
 965     my ($objid) = @_;
 966     our %commit_getclogp_memo;
 967     my $memo = $commit_getclogp_memo{$objid};
 968     return $memo if $memo;
 969
 970     my $mclog = dgit_privdir()."clog";
 971     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 972         "$objid:debian/changelog";
 973     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 974 }
 975
 976 sub parse_dscdata () {
 977     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 978     printdebug Dumper($dscdata) if $debuglevel>1;
 979     $dsc = parsecontrolfh($dscfh,$dscurl,1);
 980     printdebug Dumper($dsc) if $debuglevel>1;
 981 }
 982
 983 our %rmad;
 984
 985 sub archive_query ($;@) {
 986     my ($method) = shift @_;
 987     fail "this operation does not support multiple comma-separated suites"
 988         if $isuite =~ m/,/;
 989     my $query = access_cfg('archive-query','RETURN-UNDEF');
 990     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 991     my $proto = $1;
 992     my $data = $'; #';
 993     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
 994 }
 995
 996 sub archive_query_prepend_mirror {
 997     my $m = access_cfg('mirror');
 998     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
 999 }
1000
1001 sub pool_dsc_subpath ($$) {
1002     my ($vsn,$component) = @_; # $package is implict arg
1003     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1004     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1005 }
1006
1007 sub cfg_apply_map ($$$) {
1008     my ($varref, $what, $mapspec) = @_;
1009     return unless $mapspec;
1010
1011     printdebug "config $what EVAL{ $mapspec; }\n";
1012     $_ = $$varref;
1013     eval "package Dgit::Config; $mapspec;";
1014     die $@ if $@;
1015     $$varref = $_;
1016 }
1017
1018 #---------- `ftpmasterapi' archive query method (nascent) ----------
1019
1020 sub archive_api_query_cmd ($) {
1021     my ($subpath) = @_;
1022     my @cmd = (@curl, qw(-sS));
1023     my $url = access_cfg('archive-query-url');
1024     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1025         my $host = $1;
1026         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1027         foreach my $key (split /\:/, $keys) {
1028             $key =~ s/\%HOST\%/$host/g;
1029             if (!stat $key) {
1030                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1031                 next;
1032             }
1033             fail "config requested specific TLS key but do not know".
1034                 " how to get curl to use exactly that EE key ($key)";
1035 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1036 #           # Sadly the above line does not work because of changes
1037 #           # to gnutls.   The real fix for #790093 may involve
1038 #           # new curl options.
1039             last;
1040         }
1041         # Fixing #790093 properly will involve providing a value
1042         # for this on clients.
1043         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1044         push @cmd, split / /, $kargs if defined $kargs;
1045     }
1046     push @cmd, $url.$subpath;
1047     return @cmd;
1048 }
1049
1050 sub api_query ($$;$) {
1051     use JSON;
1052     my ($data, $subpath, $ok404) = @_;
1053     badcfg "ftpmasterapi archive query method takes no data part"
1054         if length $data;
1055     my @cmd = archive_api_query_cmd($subpath);
1056     my $url = $cmd[$#cmd];
1057     push @cmd, qw(-w %{http_code});
1058     my $json = cmdoutput @cmd;
1059     unless ($json =~ s/\d+\d+\d$//) {
1060         failedcmd_report_cmd undef, @cmd;
1061         fail "curl failed to print 3-digit HTTP code";
1062     }
1063     my $code = $&;
1064     return undef if $code eq '404' && $ok404;
1065     fail "fetch of $url gave HTTP code $code"
1066         unless $url =~ m#^file://# or $code =~ m/^2/;
1067     return decode_json($json);
1068 }
1069
1070 sub canonicalise_suite_ftpmasterapi {
1071     my ($proto,$data) = @_;
1072     my $suites = api_query($data, 'suites');
1073     my @matched;
1074     foreach my $entry (@$suites) {
1075         next unless grep {
1076             my $v = $entry->{$_};
1077             defined $v && $v eq $isuite;
1078         } qw(codename name);
1079         push @matched, $entry;
1080     }
1081     fail "unknown suite $isuite, maybe -d would help" unless @matched;
1082     my $cn;
1083     eval {
1084         @matched==1 or die "multiple matches for suite $isuite\n";
1085         $cn = "$matched[0]{codename}";
1086         defined $cn or die "suite $isuite info has no codename\n";
1087         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1088     };
1089     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1090         if length $@;
1091     return $cn;
1092 }
1093
1094 sub archive_query_ftpmasterapi {
1095     my ($proto,$data) = @_;
1096     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1097     my @rows;
1098     my $digester = Digest::SHA->new(256);
1099     foreach my $entry (@$info) {
1100         eval {
1101             my $vsn = "$entry->{version}";
1102             my ($ok,$msg) = version_check $vsn;
1103             die "bad version: $msg\n" unless $ok;
1104             my $component = "$entry->{component}";
1105             $component =~ m/^$component_re$/ or die "bad component";
1106             my $filename = "$entry->{filename}";
1107             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1108                 or die "bad filename";
1109             my $sha256sum = "$entry->{sha256sum}";
1110             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1111             push @rows, [ $vsn, "/pool/$component/$filename",
1112                           $digester, $sha256sum ];
1113         };
1114         die "bad ftpmaster api response: $@\n".Dumper($entry)
1115             if length $@;
1116     }
1117     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1118     return archive_query_prepend_mirror @rows;
1119 }
1120
1121 sub file_in_archive_ftpmasterapi {
1122     my ($proto,$data,$filename) = @_;
1123     my $pat = $filename;
1124     $pat =~ s/_/\\_/g;
1125     $pat = "%/$pat";
1126     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1127     my $info = api_query($data, "file_in_archive/$pat", 1);
1128 }
1129
1130 sub package_not_wholly_new_ftpmasterapi {
1131     my ($proto,$data,$pkg) = @_;
1132     my $info = api_query($data,"madison?package=${pkg}&f=json");
1133     return !!@$info;
1134 }
1135
1136 #---------- `aptget' archive query method ----------
1137
1138 our $aptget_base;
1139 our $aptget_releasefile;
1140 our $aptget_configpath;
1141
1142 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1143 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1144
1145 sub aptget_cache_clean {
1146     runcmd_ordryrun_local qw(sh -ec),
1147         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1148         'x', $aptget_base;
1149 }
1150
1151 sub aptget_lock_acquire () {
1152     my $lockfile = "$aptget_base/lock";
1153     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1154     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1155 }
1156
1157 sub aptget_prep ($) {
1158     my ($data) = @_;
1159     return if defined $aptget_base;
1160
1161     badcfg "aptget archive query method takes no data part"
1162         if length $data;
1163
1164     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1165
1166     ensuredir $cache;
1167     ensuredir "$cache/dgit";
1168     my $cachekey =
1169         access_cfg('aptget-cachekey','RETURN-UNDEF')
1170         // access_nomdistro();
1171
1172     $aptget_base = "$cache/dgit/aptget";
1173     ensuredir $aptget_base;
1174
1175     my $quoted_base = $aptget_base;
1176     die "$quoted_base contains bad chars, cannot continue"
1177         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1178
1179     ensuredir $aptget_base;
1180
1181     aptget_lock_acquire();
1182
1183     aptget_cache_clean();
1184
1185     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1186     my $sourceslist = "source.list#$cachekey";
1187
1188     my $aptsuites = $isuite;
1189     cfg_apply_map(\$aptsuites, 'suite map',
1190                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1191
1192     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1193     printf SRCS "deb-src %s %s %s\n",
1194         access_cfg('mirror'),
1195         $aptsuites,
1196         access_cfg('aptget-components')
1197         or die $!;
1198
1199     ensuredir "$aptget_base/cache";
1200     ensuredir "$aptget_base/lists";
1201
1202     open CONF, ">", $aptget_configpath or die $!;
1203     print CONF <<END;
1204 Debug::NoLocking "true";
1205 APT::Get::List-Cleanup "false";
1206 #clear APT::Update::Post-Invoke-Success;
1207 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1208 Dir::State::Lists "$quoted_base/lists";
1209 Dir::Etc::preferences "$quoted_base/preferences";
1210 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1211 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1212 END
1213
1214     foreach my $key (qw(
1215                         Dir::Cache
1216                         Dir::State
1217                         Dir::Cache::Archives
1218                         Dir::Etc::SourceParts
1219                         Dir::Etc::preferencesparts
1220                       )) {
1221         ensuredir "$aptget_base/$key";
1222         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1223     };
1224
1225     my $oldatime = (time // die $!) - 1;
1226     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1227         next unless stat_exists $oldlist;
1228         my ($mtime) = (stat _)[9];
1229         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1230     }
1231
1232     runcmd_ordryrun_local aptget_aptget(), qw(update);
1233
1234     my @releasefiles;
1235     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1236         next unless stat_exists $oldlist;
1237         my ($atime) = (stat _)[8];
1238         next if $atime == $oldatime;
1239         push @releasefiles, $oldlist;
1240     }
1241     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1242     @releasefiles = @inreleasefiles if @inreleasefiles;
1243     if (!@releasefiles) {
1244         fail <<END;
1245 apt seemed to not to update dgit's cached Release files for $isuite.
1246 (Perhaps $cache
1247  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1248 END
1249     }
1250     die "apt updated too many Release files (@releasefiles), erk"
1251         unless @releasefiles == 1;
1252
1253     ($aptget_releasefile) = @releasefiles;
1254 }
1255
1256 sub canonicalise_suite_aptget {
1257     my ($proto,$data) = @_;
1258     aptget_prep($data);
1259
1260     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1261
1262     foreach my $name (qw(Codename Suite)) {
1263         my $val = $release->{$name};
1264         if (defined $val) {
1265             printdebug "release file $name: $val\n";
1266             $val =~ m/^$suite_re$/o or fail
1267  "Release file ($aptget_releasefile) specifies intolerable $name";
1268             cfg_apply_map(\$val, 'suite rmap',
1269                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1270             return $val
1271         }
1272     }
1273     return $isuite;
1274 }
1275
1276 sub archive_query_aptget {
1277     my ($proto,$data) = @_;
1278     aptget_prep($data);
1279
1280     ensuredir "$aptget_base/source";
1281     foreach my $old (<$aptget_base/source/*.dsc>) {
1282         unlink $old or die "$old: $!";
1283     }
1284
1285     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1286     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1287     # avoids apt-get source failing with ambiguous error code
1288
1289     runcmd_ordryrun_local
1290         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1291         aptget_aptget(), qw(--download-only --only-source source), $package;
1292
1293     my @dscs = <$aptget_base/source/*.dsc>;
1294     fail "apt-get source did not produce a .dsc" unless @dscs;
1295     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1296
1297     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1298
1299     use URI::Escape;
1300     my $uri = "file://". uri_escape $dscs[0];
1301     $uri =~ s{\%2f}{/}gi;
1302     return [ (getfield $pre_dsc, 'Version'), $uri ];
1303 }
1304
1305 sub file_in_archive_aptget () { return undef; }
1306 sub package_not_wholly_new_aptget () { return undef; }
1307
1308 #---------- `dummyapicat' archive query method ----------
1309
1310 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1311 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1312
1313 sub dummycatapi_run_in_mirror ($@) {
1314     # runs $fn with FIA open onto rune
1315     my ($rune, $argl, $fn) = @_;
1316
1317     my $mirror = access_cfg('mirror');
1318     $mirror =~ s#^file://#/# or die "$mirror ?";
1319     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1320                qw(x), $mirror, @$argl);
1321     debugcmd "-|", @cmd;
1322     open FIA, "-|", @cmd or die $!;
1323     my $r = $fn->();
1324     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1325     return $r;
1326 }
1327
1328 sub file_in_archive_dummycatapi ($$$) {
1329     my ($proto,$data,$filename) = @_;
1330     my @out;
1331     dummycatapi_run_in_mirror '
1332             find -name "$1" -print0 |
1333             xargs -0r sha256sum
1334     ', [$filename], sub {
1335         while (<FIA>) {
1336             chomp or die;
1337             printdebug "| $_\n";
1338             m/^(\w+)  (\S+)$/ or die "$_ ?";
1339             push @out, { sha256sum => $1, filename => $2 };
1340         }
1341     };
1342     return \@out;
1343 }
1344
1345 sub package_not_wholly_new_dummycatapi {
1346     my ($proto,$data,$pkg) = @_;
1347     dummycatapi_run_in_mirror "
1348             find -name ${pkg}_*.dsc
1349     ", [], sub {
1350         local $/ = undef;
1351         !!<FIA>;
1352     };
1353 }
1354
1355 #---------- `madison' archive query method ----------
1356
1357 sub archive_query_madison {
1358     return archive_query_prepend_mirror
1359         map { [ @$_[0..1] ] } madison_get_parse(@_);
1360 }
1361
1362 sub madison_get_parse {
1363     my ($proto,$data) = @_;
1364     die unless $proto eq 'madison';
1365     if (!length $data) {
1366         $data= access_cfg('madison-distro','RETURN-UNDEF');
1367         $data //= access_basedistro();
1368     }
1369     $rmad{$proto,$data,$package} ||= cmdoutput
1370         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1371     my $rmad = $rmad{$proto,$data,$package};
1372
1373     my @out;
1374     foreach my $l (split /\n/, $rmad) {
1375         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1376                   \s*( [^ \t|]+ )\s* \|
1377                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1378                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1379         $1 eq $package or die "$rmad $package ?";
1380         my $vsn = $2;
1381         my $newsuite = $3;
1382         my $component;
1383         if (defined $4) {
1384             $component = $4;
1385         } else {
1386             $component = access_cfg('archive-query-default-component');
1387         }
1388         $5 eq 'source' or die "$rmad ?";
1389         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1390     }
1391     return sort { -version_compare($a->[0],$b->[0]); } @out;
1392 }
1393
1394 sub canonicalise_suite_madison {
1395     # madison canonicalises for us
1396     my @r = madison_get_parse(@_);
1397     @r or fail
1398         "unable to canonicalise suite using package $package".
1399         " which does not appear to exist in suite $isuite;".
1400         " --existing-package may help";
1401     return $r[0][2];
1402 }
1403
1404 sub file_in_archive_madison { return undef; }
1405 sub package_not_wholly_new_madison { return undef; }
1406
1407 #---------- `sshpsql' archive query method ----------
1408
1409 sub sshpsql ($$$) {
1410     my ($data,$runeinfo,$sql) = @_;
1411     if (!length $data) {
1412         $data= access_someuserhost('sshpsql').':'.
1413             access_cfg('sshpsql-dbname');
1414     }
1415     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1416     my ($userhost,$dbname) = ($`,$'); #';
1417     my @rows;
1418     my @cmd = (access_cfg_ssh, $userhost,
1419                access_runeinfo("ssh-psql $runeinfo").
1420                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1421                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1422     debugcmd "|",@cmd;
1423     open P, "-|", @cmd or die $!;
1424     while (<P>) {
1425         chomp or die;
1426         printdebug(">|$_|\n");
1427         push @rows, $_;
1428     }
1429     $!=0; $?=0; close P or failedcmd @cmd;
1430     @rows or die;
1431     my $nrows = pop @rows;
1432     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1433     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1434     @rows = map { [ split /\|/, $_ ] } @rows;
1435     my $ncols = scalar @{ shift @rows };
1436     die if grep { scalar @$_ != $ncols } @rows;
1437     return @rows;
1438 }
1439
1440 sub sql_injection_check {
1441     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1442 }
1443
1444 sub archive_query_sshpsql ($$) {
1445     my ($proto,$data) = @_;
1446     sql_injection_check $isuite, $package;
1447     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1448         SELECT source.version, component.name, files.filename, files.sha256sum
1449           FROM source
1450           JOIN src_associations ON source.id = src_associations.source
1451           JOIN suite ON suite.id = src_associations.suite
1452           JOIN dsc_files ON dsc_files.source = source.id
1453           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1454           JOIN component ON component.id = files_archive_map.component_id
1455           JOIN files ON files.id = dsc_files.file
1456          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1457            AND source.source='$package'
1458            AND files.filename LIKE '%.dsc';
1459 END
1460     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1461     my $digester = Digest::SHA->new(256);
1462     @rows = map {
1463         my ($vsn,$component,$filename,$sha256sum) = @$_;
1464         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1465     } @rows;
1466     return archive_query_prepend_mirror @rows;
1467 }
1468
1469 sub canonicalise_suite_sshpsql ($$) {
1470     my ($proto,$data) = @_;
1471     sql_injection_check $isuite;
1472     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1473         SELECT suite.codename
1474           FROM suite where suite_name='$isuite' or codename='$isuite';
1475 END
1476     @rows = map { $_->[0] } @rows;
1477     fail "unknown suite $isuite" unless @rows;
1478     die "ambiguous $isuite: @rows ?" if @rows>1;
1479     return $rows[0];
1480 }
1481
1482 sub file_in_archive_sshpsql ($$$) { return undef; }
1483 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1484
1485 #---------- `dummycat' archive query method ----------
1486
1487 sub canonicalise_suite_dummycat ($$) {
1488     my ($proto,$data) = @_;
1489     my $dpath = "$data/suite.$isuite";
1490     if (!open C, "<", $dpath) {
1491         $!==ENOENT or die "$dpath: $!";
1492         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1493         return $isuite;
1494     }
1495     $!=0; $_ = <C>;
1496     chomp or die "$dpath: $!";
1497     close C;
1498     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1499     return $_;
1500 }
1501
1502 sub archive_query_dummycat ($$) {
1503     my ($proto,$data) = @_;
1504     canonicalise_suite();
1505     my $dpath = "$data/package.$csuite.$package";
1506     if (!open C, "<", $dpath) {
1507         $!==ENOENT or die "$dpath: $!";
1508         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1509         return ();
1510     }
1511     my @rows;
1512     while (<C>) {
1513         next if m/^\#/;
1514         next unless m/\S/;
1515         die unless chomp;
1516         printdebug "dummycat query $csuite $package $dpath | $_\n";
1517         my @row = split /\s+/, $_;
1518         @row==2 or die "$dpath: $_ ?";
1519         push @rows, \@row;
1520     }
1521     C->error and die "$dpath: $!";
1522     close C;
1523     return archive_query_prepend_mirror
1524         sort { -version_compare($a->[0],$b->[0]); } @rows;
1525 }
1526
1527 sub file_in_archive_dummycat () { return undef; }
1528 sub package_not_wholly_new_dummycat () { return undef; }
1529
1530 #---------- tag format handling ----------
1531
1532 sub access_cfg_tagformats () {
1533     split /\,/, access_cfg('dgit-tag-format');
1534 }
1535
1536 sub access_cfg_tagformats_can_splitbrain () {
1537     my %y = map { $_ => 1 } access_cfg_tagformats;
1538     foreach my $needtf (qw(new maint)) {
1539         next if $y{$needtf};
1540         return 0;
1541     }
1542     return 1;
1543 }
1544
1545 sub need_tagformat ($$) {
1546     my ($fmt, $why) = @_;
1547     fail "need to use tag format $fmt ($why) but also need".
1548         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1549         " - no way to proceed"
1550         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1551     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1552 }
1553
1554 sub select_tagformat () {
1555     # sets $tagformatfn
1556     return if $tagformatfn && !$tagformat_want;
1557     die 'bug' if $tagformatfn && $tagformat_want;
1558     # ... $tagformat_want assigned after previous select_tagformat
1559
1560     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1561     printdebug "select_tagformat supported @supported\n";
1562
1563     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1564     printdebug "select_tagformat specified @$tagformat_want\n";
1565
1566     my ($fmt,$why,$override) = @$tagformat_want;
1567
1568     fail "target distro supports tag formats @supported".
1569         " but have to use $fmt ($why)"
1570         unless $override
1571             or grep { $_ eq $fmt } @supported;
1572
1573     $tagformat_want = undef;
1574     $tagformat = $fmt;
1575     $tagformatfn = ${*::}{"debiantag_$fmt"};
1576
1577     fail "trying to use unknown tag format \`$fmt' ($why) !"
1578         unless $tagformatfn;
1579 }
1580
1581 #---------- archive query entrypoints and rest of program ----------
1582
1583 sub canonicalise_suite () {
1584     return if defined $csuite;
1585     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1586     $csuite = archive_query('canonicalise_suite');
1587     if ($isuite ne $csuite) {
1588         progress "canonical suite name for $isuite is $csuite";
1589     } else {
1590         progress "canonical suite name is $csuite";
1591     }
1592 }
1593
1594 sub get_archive_dsc () {
1595     canonicalise_suite();
1596     my @vsns = archive_query('archive_query');
1597     foreach my $vinfo (@vsns) {
1598         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1599         $dscurl = $vsn_dscurl;
1600         $dscdata = url_get($dscurl);
1601         if (!$dscdata) {
1602             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1603             next;
1604         }
1605         if ($digester) {
1606             $digester->reset();
1607             $digester->add($dscdata);
1608             my $got = $digester->hexdigest();
1609             $got eq $digest or
1610                 fail "$dscurl has hash $got but".
1611                     " archive told us to expect $digest";
1612         }
1613         parse_dscdata();
1614         my $fmt = getfield $dsc, 'Format';
1615         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1616             "unsupported source format $fmt, sorry";
1617
1618         $dsc_checked = !!$digester;
1619         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1620         return;
1621     }
1622     $dsc = undef;
1623     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1624 }
1625
1626 sub check_for_git ();
1627 sub check_for_git () {
1628     # returns 0 or 1
1629     my $how = access_cfg('git-check');
1630     if ($how eq 'ssh-cmd') {
1631         my @cmd =
1632             (access_cfg_ssh, access_gituserhost(),
1633              access_runeinfo("git-check $package").
1634              " set -e; cd ".access_cfg('git-path').";".
1635              " if test -d $package.git; then echo 1; else echo 0; fi");
1636         my $r= cmdoutput @cmd;
1637         if (defined $r and $r =~ m/^divert (\w+)$/) {
1638             my $divert=$1;
1639             my ($usedistro,) = access_distros();
1640             # NB that if we are pushing, $usedistro will be $distro/push
1641             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1642             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1643             progress "diverting to $divert (using config for $instead_distro)";
1644             return check_for_git();
1645         }
1646         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1647         return $r+0;
1648     } elsif ($how eq 'url') {
1649         my $prefix = access_cfg('git-check-url','git-url');
1650         my $suffix = access_cfg('git-check-suffix','git-suffix',
1651                                 'RETURN-UNDEF') // '.git';
1652         my $url = "$prefix/$package$suffix";
1653         my @cmd = (@curl, qw(-sS -I), $url);
1654         my $result = cmdoutput @cmd;
1655         $result =~ s/^\S+ 200 .*\n\r?\n//;
1656         # curl -sS -I with https_proxy prints
1657         # HTTP/1.0 200 Connection established
1658         $result =~ m/^\S+ (404|200) /s or
1659             fail "unexpected results from git check query - ".
1660                 Dumper($prefix, $result);
1661         my $code = $1;
1662         if ($code eq '404') {
1663             return 0;
1664         } elsif ($code eq '200') {
1665             return 1;
1666         } else {
1667             die;
1668         }
1669     } elsif ($how eq 'true') {
1670         return 1;
1671     } elsif ($how eq 'false') {
1672         return 0;
1673     } else {
1674         badcfg "unknown git-check \`$how'";
1675     }
1676 }
1677
1678 sub create_remote_git_repo () {
1679     my $how = access_cfg('git-create');
1680     if ($how eq 'ssh-cmd') {
1681         runcmd_ordryrun
1682             (access_cfg_ssh, access_gituserhost(),
1683              access_runeinfo("git-create $package").
1684              "set -e; cd ".access_cfg('git-path').";".
1685              " cp -a _template $package.git");
1686     } elsif ($how eq 'true') {
1687         # nothing to do
1688     } else {
1689         badcfg "unknown git-create \`$how'";
1690     }
1691 }
1692
1693 our ($dsc_hash,$lastpush_mergeinput);
1694 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1695
1696
1697 sub prep_ud () {
1698     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1699     $playground = fresh_playground 'dgit/unpack';
1700 }
1701
1702 sub mktree_in_ud_here () {
1703     playtree_setup $gitcfgs{local};
1704 }
1705
1706 sub git_write_tree () {
1707     my $tree = cmdoutput @git, qw(write-tree);
1708     $tree =~ m/^\w+$/ or die "$tree ?";
1709     return $tree;
1710 }
1711
1712 sub git_add_write_tree () {
1713     runcmd @git, qw(add -Af .);
1714     return git_write_tree();
1715 }
1716
1717 sub remove_stray_gits ($) {
1718     my ($what) = @_;
1719     my @gitscmd = qw(find -name .git -prune -print0);
1720     debugcmd "|",@gitscmd;
1721     open GITS, "-|", @gitscmd or die $!;
1722     {
1723         local $/="\0";
1724         while (<GITS>) {
1725             chomp or die;
1726             print STDERR "$us: warning: removing from $what: ",
1727                 (messagequote $_), "\n";
1728             rmtree $_;
1729         }
1730     }
1731     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1732 }
1733
1734 sub mktree_in_ud_from_only_subdir ($;$) {
1735     my ($what,$raw) = @_;
1736     # changes into the subdir
1737
1738     my (@dirs) = <*/.>;
1739     die "expected one subdir but found @dirs ?" unless @dirs==1;
1740     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1741     my $dir = $1;
1742     changedir $dir;
1743
1744     remove_stray_gits($what);
1745     mktree_in_ud_here();
1746     if (!$raw) {
1747         my ($format, $fopts) = get_source_format();
1748         if (madformat($format)) {
1749             rmtree '.pc';
1750         }
1751     }
1752
1753     my $tree=git_add_write_tree();
1754     return ($tree,$dir);
1755 }
1756
1757 our @files_csum_info_fields =
1758     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1759      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1760      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1761
1762 sub dsc_files_info () {
1763     foreach my $csumi (@files_csum_info_fields) {
1764         my ($fname, $module, $method) = @$csumi;
1765         my $field = $dsc->{$fname};
1766         next unless defined $field;
1767         eval "use $module; 1;" or die $@;
1768         my @out;
1769         foreach (split /\n/, $field) {
1770             next unless m/\S/;
1771             m/^(\w+) (\d+) (\S+)$/ or
1772                 fail "could not parse .dsc $fname line \`$_'";
1773             my $digester = eval "$module"."->$method;" or die $@;
1774             push @out, {
1775                 Hash => $1,
1776                 Bytes => $2,
1777                 Filename => $3,
1778                 Digester => $digester,
1779             };
1780         }
1781         return @out;
1782     }
1783     fail "missing any supported Checksums-* or Files field in ".
1784         $dsc->get_option('name');
1785 }
1786
1787 sub dsc_files () {
1788     map { $_->{Filename} } dsc_files_info();
1789 }
1790
1791 sub files_compare_inputs (@) {
1792     my $inputs = \@_;
1793     my %record;
1794     my %fchecked;
1795
1796     my $showinputs = sub {
1797         return join "; ", map { $_->get_option('name') } @$inputs;
1798     };
1799
1800     foreach my $in (@$inputs) {
1801         my $expected_files;
1802         my $in_name = $in->get_option('name');
1803
1804         printdebug "files_compare_inputs $in_name\n";
1805
1806         foreach my $csumi (@files_csum_info_fields) {
1807             my ($fname) = @$csumi;
1808             printdebug "files_compare_inputs $in_name $fname\n";
1809
1810             my $field = $in->{$fname};
1811             next unless defined $field;
1812
1813             my @files;
1814             foreach (split /\n/, $field) {
1815                 next unless m/\S/;
1816
1817                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1818                     fail "could not parse $in_name $fname line \`$_'";
1819
1820                 printdebug "files_compare_inputs $in_name $fname $f\n";
1821
1822                 push @files, $f;
1823
1824                 my $re = \ $record{$f}{$fname};
1825                 if (defined $$re) {
1826                     $fchecked{$f}{$in_name} = 1;
1827                     $$re eq $info or
1828                         fail "hash or size of $f varies in $fname fields".
1829                         " (between: ".$showinputs->().")";
1830                 } else {
1831                     $$re = $info;
1832                 }
1833             }
1834             @files = sort @files;
1835             $expected_files //= \@files;
1836             "@$expected_files" eq "@files" or
1837                 fail "file list in $in_name varies between hash fields!";
1838         }
1839         $expected_files or
1840             fail "$in_name has no files list field(s)";
1841     }
1842     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1843         if $debuglevel>=2;
1844
1845     grep { keys %$_ == @$inputs-1 } values %fchecked
1846         or fail "no file appears in all file lists".
1847         " (looked in: ".$showinputs->().")";
1848 }
1849
1850 sub is_orig_file_in_dsc ($$) {
1851     my ($f, $dsc_files_info) = @_;
1852     return 0 if @$dsc_files_info <= 1;
1853     # One file means no origs, and the filename doesn't have a "what
1854     # part of dsc" component.  (Consider versions ending `.orig'.)
1855     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1856     return 1;
1857 }
1858
1859 # This function determines whether a .changes file is source-only from
1860 # the point of view of dak.  Thus, it permits *_source.buildinfo
1861 # files.
1862 #
1863 # It does not, however, permit any other buildinfo files.  After a
1864 # source-only upload, the buildds will try to upload files like
1865 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1866 # named like this in their (otherwise) source-only upload, the uploads
1867 # of the buildd can be rejected by dak.  Fixing the resultant
1868 # situation can require manual intervention.  So we block such
1869 # .buildinfo files when the user tells us to perform a source-only
1870 # upload (such as when using the push-source subcommand with the -C
1871 # option, which calls this function).
1872 #
1873 # Note, though, that when dgit is told to prepare a source-only
1874 # upload, such as when subcommands like build-source and push-source
1875 # without -C are used, dgit has a more restrictive notion of
1876 # source-only .changes than dak: such uploads will never include
1877 # *_source.buildinfo files.  This is because there is no use for such
1878 # files when using a tool like dgit to produce the source package, as
1879 # dgit ensures the source is identical to git HEAD.
1880 sub test_source_only_changes ($) {
1881     my ($changes) = @_;
1882     foreach my $l (split /\n/, getfield $changes, 'Files') {
1883         $l =~ m/\S+$/ or next;
1884         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
1885         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
1886             print "purportedly source-only changes polluted by $&\n";
1887             return 0;
1888         }
1889     }
1890     return 1;
1891 }
1892
1893 sub changes_update_origs_from_dsc ($$$$) {
1894     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1895     my %changes_f;
1896     printdebug "checking origs needed ($upstreamvsn)...\n";
1897     $_ = getfield $changes, 'Files';
1898     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1899         fail "cannot find section/priority from .changes Files field";
1900     my $placementinfo = $1;
1901     my %changed;
1902     printdebug "checking origs needed placement '$placementinfo'...\n";
1903     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1904         $l =~ m/\S+$/ or next;
1905         my $file = $&;
1906         printdebug "origs $file | $l\n";
1907         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1908         printdebug "origs $file is_orig\n";
1909         my $have = archive_query('file_in_archive', $file);
1910         if (!defined $have) {
1911             print STDERR <<END;
1912 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1913 END
1914             return;
1915         }
1916         my $found_same = 0;
1917         my @found_differ;
1918         printdebug "origs $file \$#\$have=$#$have\n";
1919         foreach my $h (@$have) {
1920             my $same = 0;
1921             my @differ;
1922             foreach my $csumi (@files_csum_info_fields) {
1923                 my ($fname, $module, $method, $archivefield) = @$csumi;
1924                 next unless defined $h->{$archivefield};
1925                 $_ = $dsc->{$fname};
1926                 next unless defined;
1927                 m/^(\w+) .* \Q$file\E$/m or
1928                     fail ".dsc $fname missing entry for $file";
1929                 if ($h->{$archivefield} eq $1) {
1930                     $same++;
1931                 } else {
1932                     push @differ,
1933  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1934                 }
1935             }
1936             die "$file ".Dumper($h)." ?!" if $same && @differ;
1937             $found_same++
1938                 if $same;
1939             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1940                 if @differ;
1941         }
1942         printdebug "origs $file f.same=$found_same".
1943             " #f._differ=$#found_differ\n";
1944         if (@found_differ && !$found_same) {
1945             fail join "\n",
1946                 "archive contains $file with different checksum",
1947                 @found_differ;
1948         }
1949         # Now we edit the changes file to add or remove it
1950         foreach my $csumi (@files_csum_info_fields) {
1951             my ($fname, $module, $method, $archivefield) = @$csumi;
1952             next unless defined $changes->{$fname};
1953             if ($found_same) {
1954                 # in archive, delete from .changes if it's there
1955                 $changed{$file} = "removed" if
1956                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
1957             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
1958                 # not in archive, but it's here in the .changes
1959             } else {
1960                 my $dsc_data = getfield $dsc, $fname;
1961                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
1962                 my $extra = $1;
1963                 $extra =~ s/ \d+ /$&$placementinfo /
1964                     or die "$fname $extra >$dsc_data< ?"
1965                     if $fname eq 'Files';
1966                 $changes->{$fname} .= "\n". $extra;
1967                 $changed{$file} = "added";
1968             }
1969         }
1970     }
1971     if (%changed) {
1972         foreach my $file (keys %changed) {
1973             progress sprintf
1974                 "edited .changes for archive .orig contents: %s %s",
1975                 $changed{$file}, $file;
1976         }
1977         my $chtmp = "$changesfile.tmp";
1978         $changes->save($chtmp);
1979         if (act_local()) {
1980             rename $chtmp,$changesfile or die "$changesfile $!";
1981         } else {
1982             progress "[new .changes left in $changesfile]";
1983         }
1984     } else {
1985         progress "$changesfile already has appropriate .orig(s) (if any)";
1986     }
1987 }
1988
1989 sub make_commit ($) {
1990     my ($file) = @_;
1991     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1992 }
1993
1994 sub make_commit_text ($) {
1995     my ($text) = @_;
1996     my ($out, $in);
1997     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1998     debugcmd "|",@cmd;
1999     print Dumper($text) if $debuglevel > 1;
2000     my $child = open2($out, $in, @cmd) or die $!;
2001     my $h;
2002     eval {
2003         print $in $text or die $!;
2004         close $in or die $!;
2005         $h = <$out>;
2006         $h =~ m/^\w+$/ or die;
2007         $h = $&;
2008         printdebug "=> $h\n";
2009     };
2010     close $out;
2011     waitpid $child, 0 == $child or die "$child $!";
2012     $? and failedcmd @cmd;
2013     return $h;
2014 }
2015
2016 sub clogp_authline ($) {
2017     my ($clogp) = @_;
2018     my $author = getfield $clogp, 'Maintainer';
2019     if ($author =~ m/^[^"\@]+\,/) {
2020         # single entry Maintainer field with unquoted comma
2021         $author = ($& =~ y/,//rd).$'; # strip the comma
2022     }
2023     # git wants a single author; any remaining commas in $author
2024     # are by now preceded by @ (or ").  It seems safer to punt on
2025     # "..." for now rather than attempting to dequote or something.
2026     $author =~ s#,.*##ms unless $author =~ m/"/;
2027     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2028     my $authline = "$author $date";
2029     $authline =~ m/$git_authline_re/o or
2030         fail "unexpected commit author line format \`$authline'".
2031         " (was generated from changelog Maintainer field)";
2032     return ($1,$2,$3) if wantarray;
2033     return $authline;
2034 }
2035
2036 sub vendor_patches_distro ($$) {
2037     my ($checkdistro, $what) = @_;
2038     return unless defined $checkdistro;
2039
2040     my $series = "debian/patches/\L$checkdistro\E.series";
2041     printdebug "checking for vendor-specific $series ($what)\n";
2042
2043     if (!open SERIES, "<", $series) {
2044         die "$series $!" unless $!==ENOENT;
2045         return;
2046     }
2047     while (<SERIES>) {
2048         next unless m/\S/;
2049         next if m/^\s+\#/;
2050
2051         print STDERR <<END;
2052
2053 Unfortunately, this source package uses a feature of dpkg-source where
2054 the same source package unpacks to different source code on different
2055 distros.  dgit cannot safely operate on such packages on affected
2056 distros, because the meaning of source packages is not stable.
2057
2058 Please ask the distro/maintainer to remove the distro-specific series
2059 files and use a different technique (if necessary, uploading actually
2060 different packages, if different distros are supposed to have
2061 different code).
2062
2063 END
2064         fail "Found active distro-specific series file for".
2065             " $checkdistro ($what): $series, cannot continue";
2066     }
2067     die "$series $!" if SERIES->error;
2068     close SERIES;
2069 }
2070
2071 sub check_for_vendor_patches () {
2072     # This dpkg-source feature doesn't seem to be documented anywhere!
2073     # But it can be found in the changelog (reformatted):
2074
2075     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2076     #   Author: Raphael Hertzog <hertzog@debian.org>
2077     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2078
2079     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2080     #   series files
2081     #
2082     #   If you have debian/patches/ubuntu.series and you were
2083     #   unpacking the source package on ubuntu, quilt was still
2084     #   directed to debian/patches/series instead of
2085     #   debian/patches/ubuntu.series.
2086     #
2087     #   debian/changelog                        |    3 +++
2088     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2089     #   2 files changed, 6 insertions(+), 1 deletion(-)
2090
2091     use Dpkg::Vendor;
2092     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2093     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2094                          "Dpkg::Vendor \`current vendor'");
2095     vendor_patches_distro(access_basedistro(),
2096                           "(base) distro being accessed");
2097     vendor_patches_distro(access_nomdistro(),
2098                           "(nominal) distro being accessed");
2099 }
2100
2101 sub generate_commits_from_dsc () {
2102     # See big comment in fetch_from_archive, below.
2103     # See also README.dsc-import.
2104     prep_ud();
2105     changedir $playground;
2106
2107     my @dfi = dsc_files_info();
2108     foreach my $fi (@dfi) {
2109         my $f = $fi->{Filename};
2110         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2111         my $upper_f = (bpd_abs()."/$f");
2112
2113         printdebug "considering reusing $f: ";
2114
2115         if (link_ltarget "$upper_f,fetch", $f) {
2116             printdebug "linked (using ...,fetch).\n";
2117         } elsif ((printdebug "($!) "),
2118                  $! != ENOENT) {
2119             fail "accessing $buildproductsdir/$f,fetch: $!";
2120         } elsif (link_ltarget $upper_f, $f) {
2121             printdebug "linked.\n";
2122         } elsif ((printdebug "($!) "),
2123                  $! != ENOENT) {
2124             fail "accessing $buildproductsdir/$f: $!";
2125         } else {
2126             printdebug "absent.\n";
2127         }
2128
2129         my $refetched;
2130         complete_file_from_dsc('.', $fi, \$refetched)
2131             or next;
2132
2133         printdebug "considering saving $f: ";
2134
2135         if (link $f, $upper_f) {
2136             printdebug "linked.\n";
2137         } elsif ((printdebug "($!) "),
2138                  $! != EEXIST) {
2139             fail "saving $buildproductsdir/$f: $!";
2140         } elsif (!$refetched) {
2141             printdebug "no need.\n";
2142         } elsif (link $f, "$upper_f,fetch") {
2143             printdebug "linked (using ...,fetch).\n";
2144         } elsif ((printdebug "($!) "),
2145                  $! != EEXIST) {
2146             fail "saving $buildproductsdir/$f,fetch: $!";
2147         } else {
2148             printdebug "cannot.\n";
2149         }
2150     }
2151
2152     # We unpack and record the orig tarballs first, so that we only
2153     # need disk space for one private copy of the unpacked source.
2154     # But we can't make them into commits until we have the metadata
2155     # from the debian/changelog, so we record the tree objects now and
2156     # make them into commits later.
2157     my @tartrees;
2158     my $upstreamv = upstreamversion $dsc->{version};
2159     my $orig_f_base = srcfn $upstreamv, '';
2160
2161     foreach my $fi (@dfi) {
2162         # We actually import, and record as a commit, every tarball
2163         # (unless there is only one file, in which case there seems
2164         # little point.
2165
2166         my $f = $fi->{Filename};
2167         printdebug "import considering $f ";
2168         (printdebug "only one dfi\n"), next if @dfi == 1;
2169         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2170         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2171         my $compr_ext = $1;
2172
2173         my ($orig_f_part) =
2174             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2175
2176         printdebug "Y ", (join ' ', map { $_//"(none)" }
2177                           $compr_ext, $orig_f_part
2178                          ), "\n";
2179
2180         my $input = new IO::File $f, '<' or die "$f $!";
2181         my $compr_pid;
2182         my @compr_cmd;
2183
2184         if (defined $compr_ext) {
2185             my $cname =
2186                 Dpkg::Compression::compression_guess_from_filename $f;
2187             fail "Dpkg::Compression cannot handle file $f in source package"
2188                 if defined $compr_ext && !defined $cname;
2189             my $compr_proc =
2190                 new Dpkg::Compression::Process compression => $cname;
2191             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2192             my $compr_fh = new IO::Handle;
2193             my $compr_pid = open $compr_fh, "-|" // die $!;
2194             if (!$compr_pid) {
2195                 open STDIN, "<&", $input or die $!;
2196                 exec @compr_cmd;
2197                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2198             }
2199             $input = $compr_fh;
2200         }
2201
2202         rmtree "_unpack-tar";
2203         mkdir "_unpack-tar" or die $!;
2204         my @tarcmd = qw(tar -x -f -
2205                         --no-same-owner --no-same-permissions
2206                         --no-acls --no-xattrs --no-selinux);
2207         my $tar_pid = fork // die $!;
2208         if (!$tar_pid) {
2209             chdir "_unpack-tar" or die $!;
2210             open STDIN, "<&", $input or die $!;
2211             exec @tarcmd;
2212             die "dgit (child): exec $tarcmd[0]: $!";
2213         }
2214         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2215         !$? or failedcmd @tarcmd;
2216
2217         close $input or
2218             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2219              : die $!);
2220         # finally, we have the results in "tarball", but maybe
2221         # with the wrong permissions
2222
2223         runcmd qw(chmod -R +rwX _unpack-tar);
2224         changedir "_unpack-tar";
2225         remove_stray_gits($f);
2226         mktree_in_ud_here();
2227
2228         my ($tree) = git_add_write_tree();
2229         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2230         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2231             $tree = $1;
2232             printdebug "one subtree $1\n";
2233         } else {
2234             printdebug "multiple subtrees\n";
2235         }
2236         changedir "..";
2237         rmtree "_unpack-tar";
2238
2239         my $ent = [ $f, $tree ];
2240         push @tartrees, {
2241             Orig => !!$orig_f_part,
2242             Sort => (!$orig_f_part         ? 2 :
2243                      $orig_f_part =~ m/-/g ? 1 :
2244                                              0),
2245             F => $f,
2246             Tree => $tree,
2247         };
2248     }
2249
2250     @tartrees = sort {
2251         # put any without "_" first (spec is not clear whether files
2252         # are always in the usual order).  Tarballs without "_" are
2253         # the main orig or the debian tarball.
2254         $a->{Sort} <=> $b->{Sort} or
2255         $a->{F}    cmp $b->{F}
2256     } @tartrees;
2257
2258     my $any_orig = grep { $_->{Orig} } @tartrees;
2259
2260     my $dscfn = "$package.dsc";
2261
2262     my $treeimporthow = 'package';
2263
2264     open D, ">", $dscfn or die "$dscfn: $!";
2265     print D $dscdata or die "$dscfn: $!";
2266     close D or die "$dscfn: $!";
2267     my @cmd = qw(dpkg-source);
2268     push @cmd, '--no-check' if $dsc_checked;
2269     if (madformat $dsc->{format}) {
2270         push @cmd, '--skip-patches';
2271         $treeimporthow = 'unpatched';
2272     }
2273     push @cmd, qw(-x --), $dscfn;
2274     runcmd @cmd;
2275
2276     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2277     if (madformat $dsc->{format}) {
2278         check_for_vendor_patches();
2279     }
2280
2281     my $dappliedtree;
2282     if (madformat $dsc->{format}) {
2283         my @pcmd = qw(dpkg-source --before-build .);
2284         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2285         rmtree '.pc';
2286         $dappliedtree = git_add_write_tree();
2287     }
2288
2289     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2290     my $clogp;
2291     my $r1clogp;
2292
2293     printdebug "import clog search...\n";
2294     parsechangelog_loop \@clogcmd, "package changelog", sub {
2295         my ($thisstanza, $desc) = @_;
2296         no warnings qw(exiting);
2297
2298         $clogp //= $thisstanza;
2299
2300         printdebug "import clog $thisstanza->{version} $desc...\n";
2301
2302         last if !$any_orig; # we don't need $r1clogp
2303
2304         # We look for the first (most recent) changelog entry whose
2305         # version number is lower than the upstream version of this
2306         # package.  Then the last (least recent) previous changelog
2307         # entry is treated as the one which introduced this upstream
2308         # version and used for the synthetic commits for the upstream
2309         # tarballs.
2310
2311         # One might think that a more sophisticated algorithm would be
2312         # necessary.  But: we do not want to scan the whole changelog
2313         # file.  Stopping when we see an earlier version, which
2314         # necessarily then is an earlier upstream version, is the only
2315         # realistic way to do that.  Then, either the earliest
2316         # changelog entry we have seen so far is indeed the earliest
2317         # upload of this upstream version; or there are only changelog
2318         # entries relating to later upstream versions (which is not
2319         # possible unless the changelog and .dsc disagree about the
2320         # version).  Then it remains to choose between the physically
2321         # last entry in the file, and the one with the lowest version
2322         # number.  If these are not the same, we guess that the
2323         # versions were created in a non-monotonic order rather than
2324         # that the changelog entries have been misordered.
2325
2326         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2327
2328         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2329         $r1clogp = $thisstanza;
2330
2331         printdebug "import clog $r1clogp->{version} becomes r1\n";
2332     };
2333
2334     $clogp or fail "package changelog has no entries!";
2335
2336     my $authline = clogp_authline $clogp;
2337     my $changes = getfield $clogp, 'Changes';
2338     $changes =~ s/^\n//; # Changes: \n
2339     my $cversion = getfield $clogp, 'Version';
2340
2341     if (@tartrees) {
2342         $r1clogp //= $clogp; # maybe there's only one entry;
2343         my $r1authline = clogp_authline $r1clogp;
2344         # Strictly, r1authline might now be wrong if it's going to be
2345         # unused because !$any_orig.  Whatever.
2346
2347         printdebug "import tartrees authline   $authline\n";
2348         printdebug "import tartrees r1authline $r1authline\n";
2349
2350         foreach my $tt (@tartrees) {
2351             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2352
2353             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2354 tree $tt->{Tree}
2355 author $r1authline
2356 committer $r1authline
2357
2358 Import $tt->{F}
2359
2360 [dgit import orig $tt->{F}]
2361 END_O
2362 tree $tt->{Tree}
2363 author $authline
2364 committer $authline
2365
2366 Import $tt->{F}
2367
2368 [dgit import tarball $package $cversion $tt->{F}]
2369 END_T
2370         }
2371     }
2372
2373     printdebug "import main commit\n";
2374
2375     open C, ">../commit.tmp" or die $!;
2376     print C <<END or die $!;
2377 tree $tree
2378 END
2379     print C <<END or die $! foreach @tartrees;
2380 parent $_->{Commit}
2381 END
2382     print C <<END or die $!;
2383 author $authline
2384 committer $authline
2385
2386 $changes
2387
2388 [dgit import $treeimporthow $package $cversion]
2389 END
2390
2391     close C or die $!;
2392     my $rawimport_hash = make_commit qw(../commit.tmp);
2393
2394     if (madformat $dsc->{format}) {
2395         printdebug "import apply patches...\n";
2396
2397         # regularise the state of the working tree so that
2398         # the checkout of $rawimport_hash works nicely.
2399         my $dappliedcommit = make_commit_text(<<END);
2400 tree $dappliedtree
2401 author $authline
2402 committer $authline
2403
2404 [dgit dummy commit]
2405 END
2406         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2407
2408         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2409
2410         # We need the answers to be reproducible
2411         my @authline = clogp_authline($clogp);
2412         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2413         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2414         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2415         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2416         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2417         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2418
2419         my $path = $ENV{PATH} or die;
2420
2421         # we use ../../gbp-pq-output, which (given that we are in
2422         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2423         # is .git/dgit.
2424
2425         foreach my $use_absurd (qw(0 1)) {
2426             runcmd @git, qw(checkout -q unpa);
2427             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2428             local $ENV{PATH} = $path;
2429             if ($use_absurd) {
2430                 chomp $@;
2431                 progress "warning: $@";
2432                 $path = "$absurdity:$path";
2433                 progress "$us: trying slow absurd-git-apply...";
2434                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2435                     or $!==ENOENT
2436                     or die $!;
2437             }
2438             eval {
2439                 die "forbid absurd git-apply\n" if $use_absurd
2440                     && forceing [qw(import-gitapply-no-absurd)];
2441                 die "only absurd git-apply!\n" if !$use_absurd
2442                     && forceing [qw(import-gitapply-absurd)];
2443
2444                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2445                 local $ENV{PATH} = $path                    if $use_absurd;
2446
2447                 my @showcmd = (gbp_pq, qw(import));
2448                 my @realcmd = shell_cmd
2449                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2450                 debugcmd "+",@realcmd;
2451                 if (system @realcmd) {
2452                     die +(shellquote @showcmd).
2453                         " failed: ".
2454                         failedcmd_waitstatus()."\n";
2455                 }
2456
2457                 my $gapplied = git_rev_parse('HEAD');
2458                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2459                 $gappliedtree eq $dappliedtree or
2460                     fail <<END;
2461 gbp-pq import and dpkg-source disagree!
2462  gbp-pq import gave commit $gapplied
2463  gbp-pq import gave tree $gappliedtree
2464  dpkg-source --before-build gave tree $dappliedtree
2465 END
2466                 $rawimport_hash = $gapplied;
2467             };
2468             last unless $@;
2469         }
2470         if ($@) {
2471             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2472             die $@;
2473         }
2474     }
2475
2476     progress "synthesised git commit from .dsc $cversion";
2477
2478     my $rawimport_mergeinput = {
2479         Commit => $rawimport_hash,
2480         Info => "Import of source package",
2481     };
2482     my @output = ($rawimport_mergeinput);
2483
2484     if ($lastpush_mergeinput) {
2485         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2486         my $oversion = getfield $oldclogp, 'Version';
2487         my $vcmp =
2488             version_compare($oversion, $cversion);
2489         if ($vcmp < 0) {
2490             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2491                 { Message => <<END, ReverseParents => 1 });
2492 Record $package ($cversion) in archive suite $csuite
2493 END
2494         } elsif ($vcmp > 0) {
2495             print STDERR <<END or die $!;
2496
2497 Version actually in archive:   $cversion (older)
2498 Last version pushed with dgit: $oversion (newer or same)
2499 $later_warning_msg
2500 END
2501             @output = $lastpush_mergeinput;
2502         } else {
2503             # Same version.  Use what's in the server git branch,
2504             # discarding our own import.  (This could happen if the
2505             # server automatically imports all packages into git.)
2506             @output = $lastpush_mergeinput;
2507         }
2508     }
2509     changedir $maindir;
2510     rmtree $playground;
2511     return @output;
2512 }
2513
2514 sub complete_file_from_dsc ($$;$) {
2515     our ($dstdir, $fi, $refetched) = @_;
2516     # Ensures that we have, in $dstdir, the file $fi, with the correct
2517     # contents.  (Downloading it from alongside $dscurl if necessary.)
2518     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2519     # and will set $$refetched=1 if it did so (or tried to).
2520
2521     my $f = $fi->{Filename};
2522     my $tf = "$dstdir/$f";
2523     my $downloaded = 0;
2524
2525     my $got;
2526     my $checkhash = sub {
2527         open F, "<", "$tf" or die "$tf: $!";
2528         $fi->{Digester}->reset();
2529         $fi->{Digester}->addfile(*F);
2530         F->error and die $!;
2531         $got = $fi->{Digester}->hexdigest();
2532         return $got eq $fi->{Hash};
2533     };
2534
2535     if (stat_exists $tf) {
2536         if ($checkhash->()) {
2537             progress "using existing $f";
2538             return 1;
2539         }
2540         if (!$refetched) {
2541             fail "file $f has hash $got but .dsc".
2542                 " demands hash $fi->{Hash} ".
2543                 "(perhaps you should delete this file?)";
2544         }
2545         progress "need to fetch correct version of $f";
2546         unlink $tf or die "$tf $!";
2547         $$refetched = 1;
2548     } else {
2549         printdebug "$tf does not exist, need to fetch\n";
2550     }
2551
2552     my $furl = $dscurl;
2553     $furl =~ s{/[^/]+$}{};
2554     $furl .= "/$f";
2555     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2556     die "$f ?" if $f =~ m#/#;
2557     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2558     return 0 if !act_local();
2559
2560     $checkhash->() or
2561         fail "file $f has hash $got but .dsc".
2562             " demands hash $fi->{Hash} ".
2563             "(got wrong file from archive!)";
2564
2565     return 1;
2566 }
2567
2568 sub ensure_we_have_orig () {
2569     my @dfi = dsc_files_info();
2570     foreach my $fi (@dfi) {
2571         my $f = $fi->{Filename};
2572         next unless is_orig_file_in_dsc($f, \@dfi);
2573         complete_file_from_dsc($buildproductsdir, $fi)
2574             or next;
2575     }
2576 }
2577
2578 #---------- git fetch ----------
2579
2580 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2581 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2582
2583 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2584 # locally fetched refs because they have unhelpful names and clutter
2585 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2586 # whether we have made another local ref which refers to this object).
2587 #
2588 # (If we deleted them unconditionally, then we might end up
2589 # re-fetching the same git objects each time dgit fetch was run.)
2590 #
2591 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2592 # in git_fetch_us to fetch the refs in question, and possibly a call
2593 # to lrfetchref_used.
2594
2595 our (%lrfetchrefs_f, %lrfetchrefs_d);
2596 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2597
2598 sub lrfetchref_used ($) {
2599     my ($fullrefname) = @_;
2600     my $objid = $lrfetchrefs_f{$fullrefname};
2601     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2602 }
2603
2604 sub git_lrfetch_sane {
2605     my ($url, $supplementary, @specs) = @_;
2606     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2607     # at least as regards @specs.  Also leave the results in
2608     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2609     # able to clean these up.
2610     #
2611     # With $supplementary==1, @specs must not contain wildcards
2612     # and we add to our previous fetches (non-atomically).
2613
2614     # This is rather miserable:
2615     # When git fetch --prune is passed a fetchspec ending with a *,
2616     # it does a plausible thing.  If there is no * then:
2617     # - it matches subpaths too, even if the supplied refspec
2618     #   starts refs, and behaves completely madly if the source
2619     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2620     # - if there is no matching remote ref, it bombs out the whole
2621     #   fetch.
2622     # We want to fetch a fixed ref, and we don't know in advance
2623     # if it exists, so this is not suitable.
2624     #
2625     # Our workaround is to use git ls-remote.  git ls-remote has its
2626     # own qairks.  Notably, it has the absurd multi-tail-matching
2627     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2628     # refs/refs/foo etc.
2629     #
2630     # Also, we want an idempotent snapshot, but we have to make two
2631     # calls to the remote: one to git ls-remote and to git fetch.  The
2632     # solution is use git ls-remote to obtain a target state, and
2633     # git fetch to try to generate it.  If we don't manage to generate
2634     # the target state, we try again.
2635
2636     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2637
2638     my $specre = join '|', map {
2639         my $x = $_;
2640         $x =~ s/\W/\\$&/g;
2641         my $wildcard = $x =~ s/\\\*$/.*/;
2642         die if $wildcard && $supplementary;
2643         "(?:refs/$x)";
2644     } @specs;
2645     printdebug "git_lrfetch_sane specre=$specre\n";
2646     my $wanted_rref = sub {
2647         local ($_) = @_;
2648         return m/^(?:$specre)$/;
2649     };
2650
2651     my $fetch_iteration = 0;
2652     FETCH_ITERATION:
2653     for (;;) {
2654         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2655         if (++$fetch_iteration > 10) {
2656             fail "too many iterations trying to get sane fetch!";
2657         }
2658
2659         my @look = map { "refs/$_" } @specs;
2660         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2661         debugcmd "|",@lcmd;
2662
2663         my %wantr;
2664         open GITLS, "-|", @lcmd or die $!;
2665         while (<GITLS>) {
2666             printdebug "=> ", $_;
2667             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2668             my ($objid,$rrefname) = ($1,$2);
2669             if (!$wanted_rref->($rrefname)) {
2670                 print STDERR <<END;
2671 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2672 END
2673                 next;
2674             }
2675             $wantr{$rrefname} = $objid;
2676         }
2677         $!=0; $?=0;
2678         close GITLS or failedcmd @lcmd;
2679
2680         # OK, now %want is exactly what we want for refs in @specs
2681         my @fspecs = map {
2682             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2683             "+refs/$_:".lrfetchrefs."/$_";
2684         } @specs;
2685
2686         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2687
2688         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2689         runcmd_ordryrun_local @fcmd if @fspecs;
2690
2691         if (!$supplementary) {
2692             %lrfetchrefs_f = ();
2693         }
2694         my %objgot;
2695
2696         git_for_each_ref(lrfetchrefs, sub {
2697             my ($objid,$objtype,$lrefname,$reftail) = @_;
2698             $lrfetchrefs_f{$lrefname} = $objid;
2699             $objgot{$objid} = 1;
2700         });
2701
2702         if ($supplementary) {
2703             last;
2704         }
2705
2706         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2707             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2708             if (!exists $wantr{$rrefname}) {
2709                 if ($wanted_rref->($rrefname)) {
2710                     printdebug <<END;
2711 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2712 END
2713                 } else {
2714                     print STDERR <<END
2715 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2716 END
2717                 }
2718                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2719                 delete $lrfetchrefs_f{$lrefname};
2720                 next;
2721             }
2722         }
2723         foreach my $rrefname (sort keys %wantr) {
2724             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2725             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2726             my $want = $wantr{$rrefname};
2727             next if $got eq $want;
2728             if (!defined $objgot{$want}) {
2729                 fail <<END unless act_local();
2730 --dry-run specified but we actually wanted the results of git fetch,
2731 so this is not going to work.  Try running dgit fetch first,
2732 or using --damp-run instead of --dry-run.
2733 END
2734                 print STDERR <<END;
2735 warning: git ls-remote suggests we want $lrefname
2736 warning:  and it should refer to $want
2737 warning:  but git fetch didn't fetch that object to any relevant ref.
2738 warning:  This may be due to a race with someone updating the server.
2739 warning:  Will try again...
2740 END
2741                 next FETCH_ITERATION;
2742             }
2743             printdebug <<END;
2744 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2745 END
2746             runcmd_ordryrun_local @git, qw(update-ref -m),
2747                 "dgit fetch git fetch fixup", $lrefname, $want;
2748             $lrfetchrefs_f{$lrefname} = $want;
2749         }
2750         last;
2751     }
2752
2753     if (defined $csuite) {
2754         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2755         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2756             my ($objid,$objtype,$lrefname,$reftail) = @_;
2757             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2758             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2759         });
2760     }
2761
2762     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2763         Dumper(\%lrfetchrefs_f);
2764 }
2765
2766 sub git_fetch_us () {
2767     # Want to fetch only what we are going to use, unless
2768     # deliberately-not-ff, in which case we must fetch everything.
2769
2770     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2771         map { "tags/$_" }
2772         (quiltmode_splitbrain
2773          ? (map { $_->('*',access_nomdistro) }
2774             \&debiantag_new, \&debiantag_maintview)
2775          : debiantags('*',access_nomdistro));
2776     push @specs, server_branch($csuite);
2777     push @specs, $rewritemap;
2778     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2779
2780     my $url = access_giturl();
2781     git_lrfetch_sane $url, 0, @specs;
2782
2783     my %here;
2784     my @tagpats = debiantags('*',access_nomdistro);
2785
2786     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2787         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2788         printdebug "currently $fullrefname=$objid\n";
2789         $here{$fullrefname} = $objid;
2790     });
2791     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2792         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2793         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2794         printdebug "offered $lref=$objid\n";
2795         if (!defined $here{$lref}) {
2796             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2797             runcmd_ordryrun_local @upd;
2798             lrfetchref_used $fullrefname;
2799         } elsif ($here{$lref} eq $objid) {
2800             lrfetchref_used $fullrefname;
2801         } else {
2802             print STDERR
2803                 "Not updating $lref from $here{$lref} to $objid.\n";
2804         }
2805     });
2806 }
2807
2808 #---------- dsc and archive handling ----------
2809
2810 sub mergeinfo_getclogp ($) {
2811     # Ensures thit $mi->{Clogp} exists and returns it
2812     my ($mi) = @_;
2813     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2814 }
2815
2816 sub mergeinfo_version ($) {
2817     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2818 }
2819
2820 sub fetch_from_archive_record_1 ($) {
2821     my ($hash) = @_;
2822     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
2823     cmdoutput @git, qw(log -n2), $hash;
2824     # ... gives git a chance to complain if our commit is malformed
2825 }
2826
2827 sub fetch_from_archive_record_2 ($) {
2828     my ($hash) = @_;
2829     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
2830     if (act_local()) {
2831         cmdoutput @upd_cmd;
2832     } else {
2833         dryrun_report @upd_cmd;
2834     }
2835 }
2836
2837 sub parse_dsc_field_def_dsc_distro () {
2838     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2839                            dgit.default.distro);
2840 }
2841
2842 sub parse_dsc_field ($$) {
2843     my ($dsc, $what) = @_;
2844     my $f;
2845     foreach my $field (@ourdscfield) {
2846         $f = $dsc->{$field};
2847         last if defined $f;
2848     }
2849
2850     if (!defined $f) {
2851         progress "$what: NO git hash";
2852         parse_dsc_field_def_dsc_distro();
2853     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2854              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2855         progress "$what: specified git info ($dsc_distro)";
2856         $dsc_hint_tag = [ $dsc_hint_tag ];
2857     } elsif ($f =~ m/^\w+\s*$/) {
2858         $dsc_hash = $&;
2859         parse_dsc_field_def_dsc_distro();
2860         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2861                           $dsc_distro ];
2862         progress "$what: specified git hash";
2863     } else {
2864         fail "$what: invalid Dgit info";
2865     }
2866 }
2867
2868 sub resolve_dsc_field_commit ($$) {
2869     my ($already_distro, $already_mapref) = @_;
2870
2871     return unless defined $dsc_hash;
2872
2873     my $mapref =
2874         defined $already_mapref &&
2875         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2876         ? $already_mapref : undef;
2877
2878     my $do_fetch;
2879     $do_fetch = sub {
2880         my ($what, @fetch) = @_;
2881
2882         local $idistro = $dsc_distro;
2883         my $lrf = lrfetchrefs;
2884
2885         if (!$chase_dsc_distro) {
2886             progress
2887                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2888             return 0;
2889         }
2890
2891         progress
2892             ".dsc names distro $dsc_distro: fetching $what";
2893
2894         my $url = access_giturl();
2895         if (!defined $url) {
2896             defined $dsc_hint_url or fail <<END;
2897 .dsc Dgit metadata is in context of distro $dsc_distro
2898 for which we have no configured url and .dsc provides no hint
2899 END
2900             my $proto =
2901                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2902                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2903             parse_cfg_bool "dsc-url-proto-ok", 'false',
2904                 cfg("dgit.dsc-url-proto-ok.$proto",
2905                     "dgit.default.dsc-url-proto-ok")
2906                 or fail <<END;
2907 .dsc Dgit metadata is in context of distro $dsc_distro
2908 for which we have no configured url;
2909 .dsc provides hinted url with protocol $proto which is unsafe.
2910 (can be overridden by config - consult documentation)
2911 END
2912             $url = $dsc_hint_url;
2913         }
2914
2915         git_lrfetch_sane $url, 1, @fetch;
2916
2917         return $lrf;
2918     };
2919
2920     my $rewrite_enable = do {
2921         local $idistro = $dsc_distro;
2922         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2923     };
2924
2925     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2926         if (!defined $mapref) {
2927             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2928             $mapref = $lrf.'/'.$rewritemap;
2929         }
2930         my $rewritemapdata = git_cat_file $mapref.':map';
2931         if (defined $rewritemapdata
2932             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2933             progress
2934                 "server's git history rewrite map contains a relevant entry!";
2935
2936             $dsc_hash = $1;
2937             if (defined $dsc_hash) {
2938                 progress "using rewritten git hash in place of .dsc value";
2939             } else {
2940                 progress "server data says .dsc hash is to be disregarded";
2941             }
2942         }
2943     }
2944
2945     if (!defined git_cat_file $dsc_hash) {
2946         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2947         my $lrf = $do_fetch->("additional commits", @tags) &&
2948             defined git_cat_file $dsc_hash
2949             or fail <<END;
2950 .dsc Dgit metadata requires commit $dsc_hash
2951 but we could not obtain that object anywhere.
2952 END
2953         foreach my $t (@tags) {
2954             my $fullrefname = $lrf.'/'.$t;
2955 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2956             next unless $lrfetchrefs_f{$fullrefname};
2957             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2958             lrfetchref_used $fullrefname;
2959         }
2960     }
2961 }
2962
2963 sub fetch_from_archive () {
2964     ensure_setup_existing_tree();
2965
2966     # Ensures that lrref() is what is actually in the archive, one way
2967     # or another, according to us - ie this client's
2968     # appropritaely-updated archive view.  Also returns the commit id.
2969     # If there is nothing in the archive, leaves lrref alone and
2970     # returns undef.  git_fetch_us must have already been called.
2971     get_archive_dsc();
2972
2973     if ($dsc) {
2974         parse_dsc_field($dsc, 'last upload to archive');
2975         resolve_dsc_field_commit access_basedistro,
2976             lrfetchrefs."/".$rewritemap
2977     } else {
2978         progress "no version available from the archive";
2979     }
2980
2981     # If the archive's .dsc has a Dgit field, there are three
2982     # relevant git commitids we need to choose between and/or merge
2983     # together:
2984     #   1. $dsc_hash: the Dgit field from the archive
2985     #   2. $lastpush_hash: the suite branch on the dgit git server
2986     #   3. $lastfetch_hash: our local tracking brach for the suite
2987     #
2988     # These may all be distinct and need not be in any fast forward
2989     # relationship:
2990     #
2991     # If the dsc was pushed to this suite, then the server suite
2992     # branch will have been updated; but it might have been pushed to
2993     # a different suite and copied by the archive.  Conversely a more
2994     # recent version may have been pushed with dgit but not appeared
2995     # in the archive (yet).
2996     #
2997     # $lastfetch_hash may be awkward because archive imports
2998     # (particularly, imports of Dgit-less .dscs) are performed only as
2999     # needed on individual clients, so different clients may perform a
3000     # different subset of them - and these imports are only made
3001     # public during push.  So $lastfetch_hash may represent a set of
3002     # imports different to a subsequent upload by a different dgit
3003     # client.
3004     #
3005     # Our approach is as follows:
3006     #
3007     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3008     # descendant of $dsc_hash, then it was pushed by a dgit user who
3009     # had based their work on $dsc_hash, so we should prefer it.
3010     # Otherwise, $dsc_hash was installed into this suite in the
3011     # archive other than by a dgit push, and (necessarily) after the
3012     # last dgit push into that suite (since a dgit push would have
3013     # been descended from the dgit server git branch); thus, in that
3014     # case, we prefer the archive's version (and produce a
3015     # pseudo-merge to overwrite the dgit server git branch).
3016     #
3017     # (If there is no Dgit field in the archive's .dsc then
3018     # generate_commit_from_dsc uses the version numbers to decide
3019     # whether the suite branch or the archive is newer.  If the suite
3020     # branch is newer it ignores the archive's .dsc; otherwise it
3021     # generates an import of the .dsc, and produces a pseudo-merge to
3022     # overwrite the suite branch with the archive contents.)
3023     #
3024     # The outcome of that part of the algorithm is the `public view',
3025     # and is same for all dgit clients: it does not depend on any
3026     # unpublished history in the local tracking branch.
3027     #
3028     # As between the public view and the local tracking branch: The
3029     # local tracking branch is only updated by dgit fetch, and
3030     # whenever dgit fetch runs it includes the public view in the
3031     # local tracking branch.  Therefore if the public view is not
3032     # descended from the local tracking branch, the local tracking
3033     # branch must contain history which was imported from the archive
3034     # but never pushed; and, its tip is now out of date.  So, we make
3035     # a pseudo-merge to overwrite the old imports and stitch the old
3036     # history in.
3037     #
3038     # Finally: we do not necessarily reify the public view (as
3039     # described above).  This is so that we do not end up stacking two
3040     # pseudo-merges.  So what we actually do is figure out the inputs
3041     # to any public view pseudo-merge and put them in @mergeinputs.
3042
3043     my @mergeinputs;
3044     # $mergeinputs[]{Commit}
3045     # $mergeinputs[]{Info}
3046     # $mergeinputs[0] is the one whose tree we use
3047     # @mergeinputs is in the order we use in the actual commit)
3048     #
3049     # Also:
3050     # $mergeinputs[]{Message} is a commit message to use
3051     # $mergeinputs[]{ReverseParents} if def specifies that parent
3052     #                                list should be in opposite order
3053     # Such an entry has no Commit or Info.  It applies only when found
3054     # in the last entry.  (This ugliness is to support making
3055     # identical imports to previous dgit versions.)
3056
3057     my $lastpush_hash = git_get_ref(lrfetchref());
3058     printdebug "previous reference hash=$lastpush_hash\n";
3059     $lastpush_mergeinput = $lastpush_hash && {
3060         Commit => $lastpush_hash,
3061         Info => "dgit suite branch on dgit git server",
3062     };
3063
3064     my $lastfetch_hash = git_get_ref(lrref());
3065     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3066     my $lastfetch_mergeinput = $lastfetch_hash && {
3067         Commit => $lastfetch_hash,
3068         Info => "dgit client's archive history view",
3069     };
3070
3071     my $dsc_mergeinput = $dsc_hash && {
3072         Commit => $dsc_hash,
3073         Info => "Dgit field in .dsc from archive",
3074     };
3075
3076     my $cwd = getcwd();
3077     my $del_lrfetchrefs = sub {
3078         changedir $cwd;
3079         my $gur;
3080         printdebug "del_lrfetchrefs...\n";
3081         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3082             my $objid = $lrfetchrefs_d{$fullrefname};
3083             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3084             if (!$gur) {
3085                 $gur ||= new IO::Handle;
3086                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3087             }
3088             printf $gur "delete %s %s\n", $fullrefname, $objid;
3089         }
3090         if ($gur) {
3091             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3092         }
3093     };
3094
3095     if (defined $dsc_hash) {
3096         ensure_we_have_orig();
3097         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3098             @mergeinputs = $dsc_mergeinput
3099         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3100             print STDERR <<END or die $!;
3101
3102 Git commit in archive is behind the last version allegedly pushed/uploaded.
3103 Commit referred to by archive: $dsc_hash
3104 Last version pushed with dgit: $lastpush_hash
3105 $later_warning_msg
3106 END
3107             @mergeinputs = ($lastpush_mergeinput);
3108         } else {
3109             # Archive has .dsc which is not a descendant of the last dgit
3110             # push.  This can happen if the archive moves .dscs about.
3111             # Just follow its lead.
3112             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3113                 progress "archive .dsc names newer git commit";
3114                 @mergeinputs = ($dsc_mergeinput);
3115             } else {
3116                 progress "archive .dsc names other git commit, fixing up";
3117                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3118             }
3119         }
3120     } elsif ($dsc) {
3121         @mergeinputs = generate_commits_from_dsc();
3122         # We have just done an import.  Now, our import algorithm might
3123         # have been improved.  But even so we do not want to generate
3124         # a new different import of the same package.  So if the
3125         # version numbers are the same, just use our existing version.
3126         # If the version numbers are different, the archive has changed
3127         # (perhaps, rewound).
3128         if ($lastfetch_mergeinput &&
3129             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3130                               (mergeinfo_version $mergeinputs[0]) )) {
3131             @mergeinputs = ($lastfetch_mergeinput);
3132         }
3133     } elsif ($lastpush_hash) {
3134         # only in git, not in the archive yet
3135         @mergeinputs = ($lastpush_mergeinput);
3136         print STDERR <<END or die $!;
3137
3138 Package not found in the archive, but has allegedly been pushed using dgit.
3139 $later_warning_msg
3140 END
3141     } else {
3142         printdebug "nothing found!\n";
3143         if (defined $skew_warning_vsn) {
3144             print STDERR <<END or die $!;
3145
3146 Warning: relevant archive skew detected.
3147 Archive allegedly contains $skew_warning_vsn
3148 But we were not able to obtain any version from the archive or git.
3149
3150 END
3151         }
3152         unshift @end, $del_lrfetchrefs;
3153         return undef;
3154     }
3155
3156     if ($lastfetch_hash &&
3157         !grep {
3158             my $h = $_->{Commit};
3159             $h and is_fast_fwd($lastfetch_hash, $h);
3160             # If true, one of the existing parents of this commit
3161             # is a descendant of the $lastfetch_hash, so we'll
3162             # be ff from that automatically.
3163         } @mergeinputs
3164         ) {
3165         # Otherwise:
3166         push @mergeinputs, $lastfetch_mergeinput;
3167     }
3168
3169     printdebug "fetch mergeinfos:\n";
3170     foreach my $mi (@mergeinputs) {
3171         if ($mi->{Info}) {
3172             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3173         } else {
3174             printdebug sprintf " ReverseParents=%d Message=%s",
3175                 $mi->{ReverseParents}, $mi->{Message};
3176         }
3177     }
3178
3179     my $compat_info= pop @mergeinputs
3180         if $mergeinputs[$#mergeinputs]{Message};
3181
3182     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3183
3184     my $hash;
3185     if (@mergeinputs > 1) {
3186         # here we go, then:
3187         my $tree_commit = $mergeinputs[0]{Commit};
3188
3189         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3190         $tree =~ m/\n\n/;  $tree = $`;
3191         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3192         $tree = $1;
3193
3194         # We use the changelog author of the package in question the
3195         # author of this pseudo-merge.  This is (roughly) correct if
3196         # this commit is simply representing aa non-dgit upload.
3197         # (Roughly because it does not record sponsorship - but we
3198         # don't have sponsorship info because that's in the .changes,
3199         # which isn't in the archivw.)
3200         #
3201         # But, it might be that we are representing archive history
3202         # updates (including in-archive copies).  These are not really
3203         # the responsibility of the person who created the .dsc, but
3204         # there is no-one whose name we should better use.  (The
3205         # author of the .dsc-named commit is clearly worse.)
3206
3207         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3208         my $author = clogp_authline $useclogp;
3209         my $cversion = getfield $useclogp, 'Version';
3210
3211         my $mcf = dgit_privdir()."/mergecommit";
3212         open MC, ">", $mcf or die "$mcf $!";
3213         print MC <<END or die $!;
3214 tree $tree
3215 END
3216
3217         my @parents = grep { $_->{Commit} } @mergeinputs;
3218         @parents = reverse @parents if $compat_info->{ReverseParents};
3219         print MC <<END or die $! foreach @parents;
3220 parent $_->{Commit}
3221 END
3222
3223         print MC <<END or die $!;
3224 author $author
3225 committer $author
3226
3227 END
3228
3229         if (defined $compat_info->{Message}) {
3230             print MC $compat_info->{Message} or die $!;
3231         } else {
3232             print MC <<END or die $!;
3233 Record $package ($cversion) in archive suite $csuite
3234
3235 Record that
3236 END
3237             my $message_add_info = sub {
3238                 my ($mi) = (@_);
3239                 my $mversion = mergeinfo_version $mi;
3240                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3241                     or die $!;
3242             };
3243
3244             $message_add_info->($mergeinputs[0]);
3245             print MC <<END or die $!;
3246 should be treated as descended from
3247 END
3248             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3249         }
3250
3251         close MC or die $!;
3252         $hash = make_commit $mcf;
3253     } else {
3254         $hash = $mergeinputs[0]{Commit};
3255     }
3256     printdebug "fetch hash=$hash\n";
3257
3258     my $chkff = sub {
3259         my ($lasth, $what) = @_;
3260         return unless $lasth;
3261         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3262     };
3263
3264     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3265         if $lastpush_hash;
3266     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3267
3268     fetch_from_archive_record_1($hash);
3269
3270     if (defined $skew_warning_vsn) {
3271         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3272         my $gotclogp = commit_getclogp($hash);
3273         my $got_vsn = getfield $gotclogp, 'Version';
3274         printdebug "SKEW CHECK GOT $got_vsn\n";
3275         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3276             print STDERR <<END or die $!;
3277
3278 Warning: archive skew detected.  Using the available version:
3279 Archive allegedly contains    $skew_warning_vsn
3280 We were able to obtain only   $got_vsn
3281
3282 END
3283         }
3284     }
3285
3286     if ($lastfetch_hash ne $hash) {
3287         fetch_from_archive_record_2($hash);
3288     }
3289
3290     lrfetchref_used lrfetchref();
3291
3292     check_gitattrs($hash, "fetched source tree");
3293
3294     unshift @end, $del_lrfetchrefs;
3295     return $hash;
3296 }
3297
3298 sub set_local_git_config ($$) {
3299     my ($k, $v) = @_;
3300     runcmd @git, qw(config), $k, $v;
3301 }
3302
3303 sub setup_mergechangelogs (;$) {
3304     my ($always) = @_;
3305     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3306
3307     my $driver = 'dpkg-mergechangelogs';
3308     my $cb = "merge.$driver";
3309     confess unless defined $maindir;
3310     my $attrs = "$maindir_gitcommon/info/attributes";
3311     ensuredir "$maindir_gitcommon/info";
3312
3313     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3314     if (!open ATTRS, "<", $attrs) {
3315         $!==ENOENT or die "$attrs: $!";
3316     } else {
3317         while (<ATTRS>) {
3318             chomp;
3319             next if m{^debian/changelog\s};
3320             print NATTRS $_, "\n" or die $!;
3321         }
3322         ATTRS->error and die $!;
3323         close ATTRS;
3324     }
3325     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3326     close NATTRS;
3327
3328     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3329     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3330
3331     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3332 }
3333
3334 sub setup_useremail (;$) {
3335     my ($always) = @_;
3336     return unless $always || access_cfg_bool(1, 'setup-useremail');
3337
3338     my $setup = sub {
3339         my ($k, $envvar) = @_;
3340         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3341         return unless defined $v;
3342         set_local_git_config "user.$k", $v;
3343     };
3344
3345     $setup->('email', 'DEBEMAIL');
3346     $setup->('name', 'DEBFULLNAME');
3347 }
3348
3349 sub ensure_setup_existing_tree () {
3350     my $k = "remote.$remotename.skipdefaultupdate";
3351     my $c = git_get_config $k;
3352     return if defined $c;
3353     set_local_git_config $k, 'true';
3354 }
3355
3356 sub open_main_gitattrs () {
3357     confess 'internal error no maindir' unless defined $maindir;
3358     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3359         or $!==ENOENT
3360         or die "open $maindir_gitcommon/info/attributes: $!";
3361     return $gai;
3362 }
3363
3364 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3365
3366 sub is_gitattrs_setup () {
3367     # return values:
3368     #  trueish
3369     #     1: gitattributes set up and should be left alone
3370     #  falseish
3371     #     0: there is a dgit-defuse-attrs but it needs fixing
3372     #     undef: there is none
3373     my $gai = open_main_gitattrs();
3374     return 0 unless $gai;
3375     while (<$gai>) {
3376         next unless m{$gitattrs_ourmacro_re};
3377         return 1 if m{\s-working-tree-encoding\s};
3378         printdebug "is_gitattrs_setup: found old macro\n";
3379         return 0;
3380     }
3381     $gai->error and die $!;
3382     printdebug "is_gitattrs_setup: found nothing\n";
3383     return undef;
3384 }
3385
3386 sub setup_gitattrs (;$) {
3387     my ($always) = @_;
3388     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3389
3390     my $already = is_gitattrs_setup();
3391     if ($already) {
3392         progress <<END;
3393 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3394  not doing further gitattributes setup
3395 END
3396         return;
3397     }
3398     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3399     my $af = "$maindir_gitcommon/info/attributes";
3400     ensuredir "$maindir_gitcommon/info";
3401
3402     open GAO, "> $af.new" or die $!;
3403     print GAO <<END or die $! unless defined $already;
3404 *       dgit-defuse-attrs
3405 $new
3406 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3407 END
3408     my $gai = open_main_gitattrs();
3409     if ($gai) {
3410         while (<$gai>) {
3411             if (m{$gitattrs_ourmacro_re}) {
3412                 die unless defined $already;
3413                 $_ = $new;
3414             }
3415             chomp;
3416             print GAO $_, "\n" or die $!;
3417         }
3418         $gai->error and die $!;
3419     }
3420     close GAO or die $!;
3421     rename "$af.new", "$af" or die "install $af: $!";
3422 }
3423
3424 sub setup_new_tree () {
3425     setup_mergechangelogs();
3426     setup_useremail();
3427     setup_gitattrs();
3428 }
3429
3430 sub check_gitattrs ($$) {
3431     my ($treeish, $what) = @_;
3432
3433     return if is_gitattrs_setup;
3434
3435     local $/="\0";
3436     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3437     debugcmd "|",@cmd;
3438     my $gafl = new IO::File;
3439     open $gafl, "-|", @cmd or die $!;
3440     while (<$gafl>) {
3441         chomp or die;
3442         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3443         next if $1 == 0;
3444         next unless m{(?:^|/)\.gitattributes$};
3445
3446         # oh dear, found one
3447         print STDERR <<END;
3448 dgit: warning: $what contains .gitattributes
3449 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3450 END
3451         close $gafl;
3452         return;
3453     }
3454     # tree contains no .gitattributes files
3455     $?=0; $!=0; close $gafl or failedcmd @cmd;
3456 }
3457
3458
3459 sub multisuite_suite_child ($$$) {
3460     my ($tsuite, $mergeinputs, $fn) = @_;
3461     # in child, sets things up, calls $fn->(), and returns undef
3462     # in parent, returns canonical suite name for $tsuite
3463     my $canonsuitefh = IO::File::new_tmpfile;
3464     my $pid = fork // die $!;
3465     if (!$pid) {
3466         forkcheck_setup();
3467         $isuite = $tsuite;
3468         $us .= " [$isuite]";
3469         $debugprefix .= " ";
3470         progress "fetching $tsuite...";
3471         canonicalise_suite();
3472         print $canonsuitefh $csuite, "\n" or die $!;
3473         close $canonsuitefh or die $!;
3474         $fn->();
3475         return undef;
3476     }
3477     waitpid $pid,0 == $pid or die $!;
3478     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3479     seek $canonsuitefh,0,0 or die $!;
3480     local $csuite = <$canonsuitefh>;
3481     die $! unless defined $csuite && chomp $csuite;
3482     if ($? == 256*4) {
3483         printdebug "multisuite $tsuite missing\n";
3484         return $csuite;
3485     }
3486     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3487     push @$mergeinputs, {
3488         Ref => lrref,
3489         Info => $csuite,
3490     };
3491     return $csuite;
3492 }
3493
3494 sub fork_for_multisuite ($) {
3495     my ($before_fetch_merge) = @_;
3496     # if nothing unusual, just returns ''
3497     #
3498     # if multisuite:
3499     # returns 0 to caller in child, to do first of the specified suites
3500     # in child, $csuite is not yet set
3501     #
3502     # returns 1 to caller in parent, to finish up anything needed after
3503     # in parent, $csuite is set to canonicalised portmanteau
3504
3505     my $org_isuite = $isuite;
3506     my @suites = split /\,/, $isuite;
3507     return '' unless @suites > 1;
3508     printdebug "fork_for_multisuite: @suites\n";
3509
3510     my @mergeinputs;
3511
3512     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3513                                             sub { });
3514     return 0 unless defined $cbasesuite;
3515
3516     fail "package $package missing in (base suite) $cbasesuite"
3517         unless @mergeinputs;
3518
3519     my @csuites = ($cbasesuite);
3520
3521     $before_fetch_merge->();
3522
3523     foreach my $tsuite (@suites[1..$#suites]) {
3524         $tsuite =~ s/^-/$cbasesuite-/;
3525         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3526                                                sub {
3527             @end = ();
3528             fetch_one();
3529             finish 0;
3530         });
3531
3532         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3533         push @csuites, $csubsuite;
3534     }
3535
3536     foreach my $mi (@mergeinputs) {
3537         my $ref = git_get_ref $mi->{Ref};
3538         die "$mi->{Ref} ?" unless length $ref;
3539         $mi->{Commit} = $ref;
3540     }
3541
3542     $csuite = join ",", @csuites;
3543
3544     my $previous = git_get_ref lrref;
3545     if ($previous) {
3546         unshift @mergeinputs, {
3547             Commit => $previous,
3548             Info => "local combined tracking branch",
3549             Warning =>
3550  "archive seems to have rewound: local tracking branch is ahead!",
3551         };
3552     }
3553
3554     foreach my $ix (0..$#mergeinputs) {
3555         $mergeinputs[$ix]{Index} = $ix;
3556     }
3557
3558     @mergeinputs = sort {
3559         -version_compare(mergeinfo_version $a,
3560                          mergeinfo_version $b) # highest version first
3561             or
3562         $a->{Index} <=> $b->{Index}; # earliest in spec first
3563     } @mergeinputs;
3564
3565     my @needed;
3566
3567   NEEDED:
3568     foreach my $mi (@mergeinputs) {
3569         printdebug "multisuite merge check $mi->{Info}\n";
3570         foreach my $previous (@needed) {
3571             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3572             printdebug "multisuite merge un-needed $previous->{Info}\n";
3573             next NEEDED;
3574         }
3575         push @needed, $mi;
3576         printdebug "multisuite merge this-needed\n";
3577         $mi->{Character} = '+';
3578     }
3579
3580     $needed[0]{Character} = '*';
3581
3582     my $output = $needed[0]{Commit};
3583
3584     if (@needed > 1) {
3585         printdebug "multisuite merge nontrivial\n";
3586         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3587
3588         my $commit = "tree $tree\n";
3589         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3590             "Input branches:\n";
3591
3592         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3593             printdebug "multisuite merge include $mi->{Info}\n";
3594             $mi->{Character} //= ' ';
3595             $commit .= "parent $mi->{Commit}\n";
3596             $msg .= sprintf " %s  %-25s %s\n",
3597                 $mi->{Character},
3598                 (mergeinfo_version $mi),
3599                 $mi->{Info};
3600         }
3601         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3602         $msg .= "\nKey\n".
3603             " * marks the highest version branch, which choose to use\n".
3604             " + marks each branch which was not already an ancestor\n\n".
3605             "[dgit multi-suite $csuite]\n";
3606         $commit .=
3607             "author $authline\n".
3608             "committer $authline\n\n";
3609         $output = make_commit_text $commit.$msg;
3610         printdebug "multisuite merge generated $output\n";
3611     }
3612
3613     fetch_from_archive_record_1($output);
3614     fetch_from_archive_record_2($output);
3615
3616     progress "calculated combined tracking suite $csuite";
3617
3618     return 1;
3619 }
3620
3621 sub clone_set_head () {
3622     open H, "> .git/HEAD" or die $!;
3623     print H "ref: ".lref()."\n" or die $!;
3624     close H or die $!;
3625 }
3626 sub clone_finish ($) {
3627     my ($dstdir) = @_;
3628     runcmd @git, qw(reset --hard), lrref();
3629     runcmd qw(bash -ec), <<'END';
3630         set -o pipefail
3631         git ls-tree -r --name-only -z HEAD | \
3632         xargs -0r touch -h -r . --
3633 END
3634     printdone "ready for work in $dstdir";
3635 }
3636
3637 sub clone ($) {
3638     # in multisuite, returns twice!
3639     # once in parent after first suite fetched,
3640     # and then again in child after everything is finished
3641     my ($dstdir) = @_;
3642     badusage "dry run makes no sense with clone" unless act_local();
3643
3644     my $multi_fetched = fork_for_multisuite(sub {
3645         printdebug "multi clone before fetch merge\n";
3646         changedir $dstdir;
3647         record_maindir();
3648     });
3649     if ($multi_fetched) {
3650         printdebug "multi clone after fetch merge\n";
3651         clone_set_head();
3652         clone_finish($dstdir);
3653         return;
3654     }
3655     printdebug "clone main body\n";
3656
3657     canonicalise_suite();
3658     my $hasgit = check_for_git();
3659     mkdir $dstdir or fail "create \`$dstdir': $!";
3660     changedir $dstdir;
3661     runcmd @git, qw(init -q);
3662     record_maindir();
3663     setup_new_tree();
3664     clone_set_head();
3665     my $giturl = access_giturl(1);
3666     if (defined $giturl) {
3667         runcmd @git, qw(remote add), 'origin', $giturl;
3668     }
3669     if ($hasgit) {
3670         progress "fetching existing git history";
3671         git_fetch_us();
3672         runcmd_ordryrun_local @git, qw(fetch origin);
3673     } else {
3674         progress "starting new git history";
3675     }
3676     fetch_from_archive() or no_such_package;
3677     my $vcsgiturl = $dsc->{'Vcs-Git'};
3678     if (length $vcsgiturl) {
3679         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3680         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3681     }
3682     clone_finish($dstdir);
3683 }
3684
3685 sub fetch_one () {
3686     canonicalise_suite();
3687     if (check_for_git()) {
3688         git_fetch_us();
3689     }
3690     fetch_from_archive() or no_such_package();
3691
3692     my $vcsgiturl = $dsc && $dsc->{'Vcs-Git'};
3693     if (length $vcsgiturl and
3694         (grep { $csuite eq $_ }
3695          split /\;/,
3696          cfg 'dgit.vcs-git.suites')) {
3697         my $current = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
3698         if (defined $current && $current ne $vcsgiturl) {
3699             print STDERR <<END;
3700 FYI: Vcs-Git in $csuite has different url to your vcs-git remote.
3701  Your vcs-git remote url may be out of date.  Use dgit update-vcs-git ?
3702 END
3703         }
3704     }
3705     printdone "fetched into ".lrref();
3706 }
3707
3708 sub dofetch () {
3709     my $multi_fetched = fork_for_multisuite(sub { });
3710     fetch_one() unless $multi_fetched; # parent
3711     finish 0 if $multi_fetched eq '0'; # child
3712 }
3713
3714 sub pull () {
3715     dofetch();
3716     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3717         lrref();
3718     printdone "fetched to ".lrref()." and merged into HEAD";
3719 }
3720
3721 sub check_not_dirty () {
3722     foreach my $f (qw(local-options local-patch-header)) {
3723         if (stat_exists "debian/source/$f") {
3724             fail "git tree contains debian/source/$f";
3725         }
3726     }
3727
3728     return if $includedirty;
3729
3730     git_check_unmodified();
3731 }
3732
3733 sub commit_admin ($) {
3734     my ($m) = @_;
3735     progress "$m";
3736     runcmd_ordryrun_local @git, qw(commit -m), $m;
3737 }
3738
3739 sub quiltify_nofix_bail ($$) {
3740     my ($headinfo, $xinfo) = @_;
3741     if ($quilt_mode eq 'nofix') {
3742         fail "quilt fixup required but quilt mode is \`nofix'\n".
3743             "HEAD commit".$headinfo." differs from tree implied by ".
3744             " debian/patches".$xinfo;
3745     }
3746 }
3747
3748 sub commit_quilty_patch () {
3749     my $output = cmdoutput @git, qw(status --ignored --porcelain);
3750     my %adds;
3751     foreach my $l (split /\n/, $output) {
3752         next unless $l =~ m/\S/;
3753         if ($l =~ m{^(?:[?!][?!]| [MADRC]) (.pc|debian/patches)}) {
3754             $adds{$1}++;
3755         }
3756     }
3757     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3758     if (!%adds) {
3759         progress "nothing quilty to commit, ok.";
3760         return;
3761     }
3762     quiltify_nofix_bail "", " (wanted to commit patch update)";
3763     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3764     runcmd_ordryrun_local @git, qw(add -f), @adds;
3765     commit_admin <<END
3766 Commit Debian 3.0 (quilt) metadata
3767
3768 [dgit ($our_version) quilt-fixup]
3769 END
3770 }
3771
3772 sub get_source_format () {
3773     my %options;
3774     if (open F, "debian/source/options") {
3775         while (<F>) {
3776             next if m/^\s*\#/;
3777             next unless m/\S/;
3778             s/\s+$//; # ignore missing final newline
3779             if (m/\s*\#\s*/) {
3780                 my ($k, $v) = ($`, $'); #');
3781                 $v =~ s/^"(.*)"$/$1/;
3782                 $options{$k} = $v;
3783             } else {
3784                 $options{$_} = 1;
3785             }
3786         }
3787         F->error and die $!;
3788         close F;
3789     } else {
3790         die $! unless $!==&ENOENT;
3791     }
3792
3793     if (!open F, "debian/source/format") {
3794         die $! unless $!==&ENOENT;
3795         return '';
3796     }
3797     $_ = <F>;
3798     F->error and die $!;
3799     chomp;
3800     return ($_, \%options);
3801 }
3802
3803 sub madformat_wantfixup ($) {
3804     my ($format) = @_;
3805     return 0 unless $format eq '3.0 (quilt)';
3806     our $quilt_mode_warned;
3807     if ($quilt_mode eq 'nocheck') {
3808         progress "Not doing any fixup of \`$format' due to".
3809             " ----no-quilt-fixup or --quilt=nocheck"
3810             unless $quilt_mode_warned++;
3811         return 0;
3812     }
3813     progress "Format \`$format', need to check/update patch stack"
3814         unless $quilt_mode_warned++;
3815     return 1;
3816 }
3817
3818 sub maybe_split_brain_save ($$$) {
3819     my ($headref, $dgitview, $msg) = @_;
3820     # => message fragment "$saved" describing disposition of $dgitview
3821     my $save = $internal_object_save{'dgit-view'};
3822     return "commit id $dgitview" unless defined $save;
3823     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
3824                git_update_ref_cmd
3825                "dgit --dgit-view-save $msg HEAD=$headref",
3826                $save, $dgitview);
3827     runcmd @cmd;
3828     return "and left in $save";
3829 }
3830
3831 # An "infopair" is a tuple [ $thing, $what ]
3832 # (often $thing is a commit hash; $what is a description)
3833
3834 sub infopair_cond_equal ($$) {
3835     my ($x,$y) = @_;
3836     $x->[0] eq $y->[0] or fail <<END;
3837 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3838 END
3839 };
3840
3841 sub infopair_lrf_tag_lookup ($$) {
3842     my ($tagnames, $what) = @_;
3843     # $tagname may be an array ref
3844     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3845     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3846     foreach my $tagname (@tagnames) {
3847         my $lrefname = lrfetchrefs."/tags/$tagname";
3848         my $tagobj = $lrfetchrefs_f{$lrefname};
3849         next unless defined $tagobj;
3850         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3851         return [ git_rev_parse($tagobj), $what ];
3852     }
3853     fail @tagnames==1 ? <<END : <<END;
3854 Wanted tag $what (@tagnames) on dgit server, but not found
3855 END
3856 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3857 END
3858 }
3859
3860 sub infopair_cond_ff ($$) {
3861     my ($anc,$desc) = @_;
3862     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3863 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3864 END
3865 };
3866
3867 sub pseudomerge_version_check ($$) {
3868     my ($clogp, $archive_hash) = @_;
3869
3870     my $arch_clogp = commit_getclogp $archive_hash;
3871     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3872                      'version currently in archive' ];
3873     if (defined $overwrite_version) {
3874         if (length $overwrite_version) {
3875             infopair_cond_equal([ $overwrite_version,
3876                                   '--overwrite= version' ],
3877                                 $i_arch_v);
3878         } else {
3879             my $v = $i_arch_v->[0];
3880             progress "Checking package changelog for archive version $v ...";
3881             my $cd;
3882             eval {
3883                 my @xa = ("-f$v", "-t$v");
3884                 my $vclogp = parsechangelog @xa;
3885                 my $gf = sub {
3886                     my ($fn) = @_;
3887                     [ (getfield $vclogp, $fn),
3888                       "$fn field from dpkg-parsechangelog @xa" ];
3889                 };
3890                 my $cv = $gf->('Version');
3891                 infopair_cond_equal($i_arch_v, $cv);
3892                 $cd = $gf->('Distribution');
3893             };
3894             if ($@) {
3895                 $@ =~ s/^dgit: //gm;
3896                 fail "$@".
3897                     "Perhaps debian/changelog does not mention $v ?";
3898             }
3899             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3900 $cd->[1] is $cd->[0]
3901 Your tree seems to based on earlier (not uploaded) $v.
3902 END
3903         }
3904     }
3905
3906     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3907     return $i_arch_v;
3908 }
3909
3910 sub pseudomerge_make_commit ($$$$ $$) {
3911     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3912         $msg_cmd, $msg_msg) = @_;
3913     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3914
3915     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3916     my $authline = clogp_authline $clogp;
3917
3918     chomp $msg_msg;
3919     $msg_cmd .=
3920         !defined $overwrite_version ? ""
3921         : !length  $overwrite_version ? " --overwrite"
3922         : " --overwrite=".$overwrite_version;
3923
3924     # Contributing parent is the first parent - that makes
3925     # git rev-list --first-parent DTRT.
3926     my $pmf = dgit_privdir()."/pseudomerge";
3927     open MC, ">", $pmf or die "$pmf $!";
3928     print MC <<END or die $!;
3929 tree $tree
3930 parent $dgitview
3931 parent $archive_hash
3932 author $authline
3933 committer $authline
3934
3935 $msg_msg
3936
3937 [$msg_cmd]
3938 END
3939     close MC or die $!;
3940
3941     return make_commit($pmf);
3942 }
3943
3944 sub splitbrain_pseudomerge ($$$$) {
3945     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3946     # => $merged_dgitview
3947     printdebug "splitbrain_pseudomerge...\n";
3948     #
3949     #     We:      debian/PREVIOUS    HEAD($maintview)
3950     # expect:          o ----------------- o
3951     #                    \                   \
3952     #                     o                   o
3953     #                 a/d/PREVIOUS        $dgitview
3954     #                $archive_hash              \
3955     #  If so,                \                   \
3956     #  we do:                 `------------------ o
3957     #   this:                                   $dgitview'
3958     #
3959
3960     return $dgitview unless defined $archive_hash;
3961     return $dgitview if deliberately_not_fast_forward();
3962
3963     printdebug "splitbrain_pseudomerge...\n";
3964
3965     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3966
3967     if (!defined $overwrite_version) {
3968         progress "Checking that HEAD inciudes all changes in archive...";
3969     }
3970
3971     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3972
3973     if (defined $overwrite_version) {
3974     } elsif (!eval {
3975         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3976         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3977         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3978         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3979         my $i_archive = [ $archive_hash, "current archive contents" ];
3980
3981         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3982
3983         infopair_cond_equal($i_dgit, $i_archive);
3984         infopair_cond_ff($i_dep14, $i_dgit);
3985         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3986         1;
3987     }) {
3988         $@ =~ s/^\n//; chomp $@;
3989         print STDERR <<END;
3990 $@
3991 | Not fast forward; maybe --overwrite is needed ?  Please see dgit(1).
3992 END
3993         finish -1;
3994     }
3995
3996     my $r = pseudomerge_make_commit
3997         $clogp, $dgitview, $archive_hash, $i_arch_v,
3998         "dgit --quilt=$quilt_mode",
3999         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
4000 Declare fast forward from $i_arch_v->[0]
4001 END_OVERWR
4002 Make fast forward from $i_arch_v->[0]
4003 END_MAKEFF
4004
4005     maybe_split_brain_save $maintview, $r, "pseudomerge";
4006
4007     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
4008     return $r;
4009 }
4010
4011 sub plain_overwrite_pseudomerge ($$$) {
4012     my ($clogp, $head, $archive_hash) = @_;
4013
4014     printdebug "plain_overwrite_pseudomerge...";
4015
4016     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4017
4018     return $head if is_fast_fwd $archive_hash, $head;
4019
4020     my $m = "Declare fast forward from $i_arch_v->[0]";
4021
4022     my $r = pseudomerge_make_commit
4023         $clogp, $head, $archive_hash, $i_arch_v,
4024         "dgit", $m;
4025
4026     runcmd git_update_ref_cmd $m, 'HEAD', $r, $head;
4027
4028     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
4029     return $r;
4030 }
4031
4032 sub push_parse_changelog ($) {
4033     my ($clogpfn) = @_;
4034
4035     my $clogp = Dpkg::Control::Hash->new();
4036     $clogp->load($clogpfn) or die;
4037
4038     my $clogpackage = getfield $clogp, 'Source';
4039     $package //= $clogpackage;
4040     fail "-p specified $package but changelog specified $clogpackage"
4041         unless $package eq $clogpackage;
4042     my $cversion = getfield $clogp, 'Version';
4043
4044     if (!$we_are_initiator) {
4045         # rpush initiator can't do this because it doesn't have $isuite yet
4046         my $tag = debiantag($cversion, access_nomdistro);
4047         runcmd @git, qw(check-ref-format), $tag;
4048     }
4049
4050     my $dscfn = dscfn($cversion);
4051
4052     return ($clogp, $cversion, $dscfn);
4053 }
4054
4055 sub push_parse_dsc ($$$) {
4056     my ($dscfn,$dscfnwhat, $cversion) = @_;
4057     $dsc = parsecontrol($dscfn,$dscfnwhat);
4058     my $dversion = getfield $dsc, 'Version';
4059     my $dscpackage = getfield $dsc, 'Source';
4060     ($dscpackage eq $package && $dversion eq $cversion) or
4061         fail "$dscfn is for $dscpackage $dversion".
4062             " but debian/changelog is for $package $cversion";
4063 }
4064
4065 sub push_tagwants ($$$$) {
4066     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4067     my @tagwants;
4068     push @tagwants, {
4069         TagFn => \&debiantag,
4070         Objid => $dgithead,
4071         TfSuffix => '',
4072         View => 'dgit',
4073     };
4074     if (defined $maintviewhead) {
4075         push @tagwants, {
4076             TagFn => \&debiantag_maintview,
4077             Objid => $maintviewhead,
4078             TfSuffix => '-maintview',
4079             View => 'maint',
4080         };
4081     } elsif ($dodep14tag eq 'no' ? 0
4082              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
4083              : $dodep14tag eq 'always'
4084              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
4085 --dep14tag-always (or equivalent in config) means server must support
4086  both "new" and "maint" tag formats, but config says it doesn't.
4087 END
4088             : die "$dodep14tag ?") {
4089         push @tagwants, {
4090             TagFn => \&debiantag_maintview,
4091             Objid => $dgithead,
4092             TfSuffix => '-dgit',
4093             View => 'dgit',
4094         };
4095     };
4096     foreach my $tw (@tagwants) {
4097         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4098         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4099     }
4100     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4101     return @tagwants;
4102 }
4103
4104 sub push_mktags ($$ $$ $) {
4105     my ($clogp,$dscfn,
4106         $changesfile,$changesfilewhat,
4107         $tagwants) = @_;
4108
4109     die unless $tagwants->[0]{View} eq 'dgit';
4110
4111     my $declaredistro = access_nomdistro();
4112     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4113     $dsc->{$ourdscfield[0]} = join " ",
4114         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4115         $reader_giturl;
4116     $dsc->save("$dscfn.tmp") or die $!;
4117
4118     my $changes = parsecontrol($changesfile,$changesfilewhat);
4119     foreach my $field (qw(Source Distribution Version)) {
4120         $changes->{$field} eq $clogp->{$field} or
4121             fail "changes field $field \`$changes->{$field}'".
4122                 " does not match changelog \`$clogp->{$field}'";
4123     }
4124
4125     my $cversion = getfield $clogp, 'Version';
4126     my $clogsuite = getfield $clogp, 'Distribution';
4127
4128     # We make the git tag by hand because (a) that makes it easier
4129     # to control the "tagger" (b) we can do remote signing
4130     my $authline = clogp_authline $clogp;
4131     my $delibs = join(" ", "",@deliberatelies);
4132
4133     my $mktag = sub {
4134         my ($tw) = @_;
4135         my $tfn = $tw->{Tfn};
4136         my $head = $tw->{Objid};
4137         my $tag = $tw->{Tag};
4138
4139         open TO, '>', $tfn->('.tmp') or die $!;
4140         print TO <<END or die $!;
4141 object $head
4142 type commit
4143 tag $tag
4144 tagger $authline
4145
4146 END
4147         if ($tw->{View} eq 'dgit') {
4148             print TO <<END or die $!;
4149 $package release $cversion for $clogsuite ($csuite) [dgit]
4150 [dgit distro=$declaredistro$delibs]
4151 END
4152             foreach my $ref (sort keys %previously) {
4153                 print TO <<END or die $!;
4154 [dgit previously:$ref=$previously{$ref}]
4155 END
4156             }
4157         } elsif ($tw->{View} eq 'maint') {
4158             print TO <<END or die $!;
4159 $package release $cversion for $clogsuite ($csuite)
4160 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4161 END
4162         } else {
4163             die Dumper($tw)."?";
4164         }
4165
4166         close TO or die $!;
4167
4168         my $tagobjfn = $tfn->('.tmp');
4169         if ($sign) {
4170             if (!defined $keyid) {
4171                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4172             }
4173             if (!defined $keyid) {
4174                 $keyid = getfield $clogp, 'Maintainer';
4175             }
4176             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4177             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4178             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4179             push @sign_cmd, $tfn->('.tmp');
4180             runcmd_ordryrun @sign_cmd;
4181             if (act_scary()) {
4182                 $tagobjfn = $tfn->('.signed.tmp');
4183                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4184                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4185             }
4186         }
4187         return $tagobjfn;
4188     };
4189
4190     my @r = map { $mktag->($_); } @$tagwants;
4191     return @r;
4192 }
4193
4194 sub sign_changes ($) {
4195     my ($changesfile) = @_;
4196     if ($sign) {
4197         my @debsign_cmd = @debsign;
4198         push @debsign_cmd, "-k$keyid" if defined $keyid;
4199         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4200         push @debsign_cmd, $changesfile;
4201         runcmd_ordryrun @debsign_cmd;
4202     }
4203 }
4204
4205 sub dopush () {
4206     printdebug "actually entering push\n";
4207
4208     supplementary_message(<<'END');
4209 Push failed, while checking state of the archive.
4210 You can retry the push, after fixing the problem, if you like.
4211 END
4212     if (check_for_git()) {
4213         git_fetch_us();
4214     }
4215     my $archive_hash = fetch_from_archive();
4216     if (!$archive_hash) {
4217         $new_package or
4218             fail "package appears to be new in this suite;".
4219                 " if this is intentional, use --new";
4220     }
4221
4222     supplementary_message(<<'END');
4223 Push failed, while preparing your push.
4224 You can retry the push, after fixing the problem, if you like.
4225 END
4226
4227     need_tagformat 'new', "quilt mode $quilt_mode"
4228         if quiltmode_splitbrain;
4229
4230     prep_ud();
4231
4232     access_giturl(); # check that success is vaguely likely
4233     rpush_handle_protovsn_bothends() if $we_are_initiator;
4234     select_tagformat();
4235
4236     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4237     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4238
4239     responder_send_file('parsed-changelog', $clogpfn);
4240
4241     my ($clogp, $cversion, $dscfn) =
4242         push_parse_changelog("$clogpfn");
4243
4244     my $dscpath = "$buildproductsdir/$dscfn";
4245     stat_exists $dscpath or
4246         fail "looked for .dsc $dscpath, but $!;".
4247             " maybe you forgot to build";
4248
4249     responder_send_file('dsc', $dscpath);
4250
4251     push_parse_dsc($dscpath, $dscfn, $cversion);
4252
4253     my $format = getfield $dsc, 'Format';
4254     printdebug "format $format\n";
4255
4256     my $symref = git_get_symref();
4257     my $actualhead = git_rev_parse('HEAD');
4258
4259     if (branch_is_gdr_unstitched_ff($symref, $actualhead, $archive_hash)) {
4260         runcmd_ordryrun_local @git_debrebase, 'stitch';
4261         $actualhead = git_rev_parse('HEAD');
4262     }
4263
4264     my $dgithead = $actualhead;
4265     my $maintviewhead = undef;
4266
4267     my $upstreamversion = upstreamversion $clogp->{Version};
4268
4269     if (madformat_wantfixup($format)) {
4270         # user might have not used dgit build, so maybe do this now:
4271         if (quiltmode_splitbrain()) {
4272             changedir $playground;
4273             quilt_make_fake_dsc($upstreamversion);
4274             my $cachekey;
4275             ($dgithead, $cachekey) =
4276                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4277             $dgithead or fail
4278  "--quilt=$quilt_mode but no cached dgit view:
4279  perhaps HEAD changed since dgit build[-source] ?";
4280             $split_brain = 1;
4281             $dgithead = splitbrain_pseudomerge($clogp,
4282                                                $actualhead, $dgithead,
4283                                                $archive_hash);
4284             $maintviewhead = $actualhead;
4285             changedir $maindir;
4286             prep_ud(); # so _only_subdir() works, below
4287         } else {
4288             commit_quilty_patch();
4289         }
4290     }
4291
4292     if (defined $overwrite_version && !defined $maintviewhead
4293         && $archive_hash) {
4294         $dgithead = plain_overwrite_pseudomerge($clogp,
4295                                                 $dgithead,
4296                                                 $archive_hash);
4297     }
4298
4299     check_not_dirty();
4300
4301     my $forceflag = '';
4302     if ($archive_hash) {
4303         if (is_fast_fwd($archive_hash, $dgithead)) {
4304             # ok
4305         } elsif (deliberately_not_fast_forward) {
4306             $forceflag = '+';
4307         } else {
4308             fail "dgit push: HEAD is not a descendant".
4309                 " of the archive's version.\n".
4310                 "To overwrite the archive's contents,".
4311                 " pass --overwrite[=VERSION].\n".
4312                 "To rewind history, if permitted by the archive,".
4313                 " use --deliberately-not-fast-forward.";
4314         }
4315     }
4316
4317     changedir $playground;
4318     progress "checking that $dscfn corresponds to HEAD";
4319     runcmd qw(dpkg-source -x --),
4320         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4321     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4322     check_for_vendor_patches() if madformat($dsc->{format});
4323     changedir $maindir;
4324     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4325     debugcmd "+",@diffcmd;
4326     $!=0; $?=-1;
4327     my $r = system @diffcmd;
4328     if ($r) {
4329         if ($r==256) {
4330             my $referent = $split_brain ? $dgithead : 'HEAD';
4331             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4332
4333             my @mode_changes;
4334             my $raw = cmdoutput @git,
4335                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4336             my $changed;
4337             foreach (split /\0/, $raw) {
4338                 if (defined $changed) {
4339                     push @mode_changes, "$changed: $_\n" if $changed;
4340                     $changed = undef;
4341                     next;
4342                 } elsif (m/^:0+ 0+ /) {
4343                     $changed = '';
4344                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4345                     $changed = "Mode change from $1 to $2"
4346                 } else {
4347                     die "$_ ?";
4348                 }
4349             }
4350             if (@mode_changes) {
4351                 fail <<END.(join '', @mode_changes).<<END;
4352 HEAD specifies a different tree to $dscfn:
4353 $diffs
4354 END
4355 There is a problem with your source tree (see dgit(7) for some hints).
4356 To see a full diff, run git diff $tree $referent
4357 END
4358             }
4359
4360             fail <<END;
4361 HEAD specifies a different tree to $dscfn:
4362 $diffs
4363 Perhaps you forgot to build.  Or perhaps there is a problem with your
4364  source tree (see dgit(7) for some hints).  To see a full diff, run
4365    git diff $tree $referent
4366 END
4367         } else {
4368             failedcmd @diffcmd;
4369         }
4370     }
4371     if (!$changesfile) {
4372         my $pat = changespat $cversion;
4373         my @cs = glob "$buildproductsdir/$pat";
4374         fail "failed to find unique changes file".
4375             " (looked for $pat in $buildproductsdir);".
4376             " perhaps you need to use dgit -C"
4377             unless @cs==1;
4378         ($changesfile) = @cs;
4379     } else {
4380         $changesfile = "$buildproductsdir/$changesfile";
4381     }
4382
4383     # Check that changes and .dsc agree enough
4384     $changesfile =~ m{[^/]*$};
4385     my $changes = parsecontrol($changesfile,$&);
4386     files_compare_inputs($dsc, $changes)
4387         unless forceing [qw(dsc-changes-mismatch)];
4388
4389     # Check whether this is a source only upload
4390     my $hasdebs = $changes->{Files} =~ m{\.deb$}m;
4391     my $sourceonlypolicy = access_cfg 'source-only-uploads';
4392     if ($sourceonlypolicy eq 'ok') {
4393     } elsif ($sourceonlypolicy eq 'always') {
4394         forceable_fail [qw(uploading-binaries)],
4395             "uploading binaries, although distroy policy is source only"
4396             if $hasdebs;
4397     } elsif ($sourceonlypolicy eq 'never') {
4398         forceable_fail [qw(uploading-source-only)],
4399             "source-only upload, although distroy policy requires .debs"
4400             if !$hasdebs;
4401     } elsif ($sourceonlypolicy eq 'not-wholly-new') {
4402         forceable_fail [qw(uploading-source-only)],
4403             "source-only upload, even though package is entirely NEW\n".
4404             "(this is contrary to policy in ".(access_nomdistro()).")"
4405             if !$hasdebs
4406             && $new_package
4407             && !(archive_query('package_not_wholly_new', $package) // 1);
4408     } else {
4409         badcfg "unknown source-only-uploads policy \`$sourceonlypolicy'";
4410     }
4411
4412     # Perhaps adjust .dsc to contain right set of origs
4413     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4414                                   $changesfile)
4415         unless forceing [qw(changes-origs-exactly)];
4416
4417     # Checks complete, we're going to try and go ahead:
4418
4419     responder_send_file('changes',$changesfile);
4420     responder_send_command("param head $dgithead");
4421     responder_send_command("param csuite $csuite");
4422     responder_send_command("param isuite $isuite");
4423     responder_send_command("param tagformat $tagformat");
4424     if (defined $maintviewhead) {
4425         confess "internal error (protovsn=$protovsn)"
4426             if defined $protovsn and $protovsn < 4;
4427         responder_send_command("param maint-view $maintviewhead");
4428     }
4429
4430     # Perhaps send buildinfo(s) for signing
4431     my $changes_files = getfield $changes, 'Files';
4432     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4433     foreach my $bi (@buildinfos) {
4434         responder_send_command("param buildinfo-filename $bi");
4435         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4436     }
4437
4438     if (deliberately_not_fast_forward) {
4439         git_for_each_ref(lrfetchrefs, sub {
4440             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4441             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4442             responder_send_command("previously $rrefname=$objid");
4443             $previously{$rrefname} = $objid;
4444         });
4445     }
4446
4447     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4448                                  dgit_privdir()."/tag");
4449     my @tagobjfns;
4450
4451     supplementary_message(<<'END');
4452 Push failed, while signing the tag.
4453 You can retry the push, after fixing the problem, if you like.
4454 END
4455     # If we manage to sign but fail to record it anywhere, it's fine.
4456     if ($we_are_responder) {
4457         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4458         responder_receive_files('signed-tag', @tagobjfns);
4459     } else {
4460         @tagobjfns = push_mktags($clogp,$dscpath,
4461                               $changesfile,$changesfile,
4462                               \@tagwants);
4463     }
4464     supplementary_message(<<'END');
4465 Push failed, *after* signing the tag.
4466 If you want to try again, you should use a new version number.
4467 END
4468
4469     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4470
4471     foreach my $tw (@tagwants) {
4472         my $tag = $tw->{Tag};
4473         my $tagobjfn = $tw->{TagObjFn};
4474         my $tag_obj_hash =
4475             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4476         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4477         runcmd_ordryrun_local
4478             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4479     }
4480
4481     supplementary_message(<<'END');
4482 Push failed, while updating the remote git repository - see messages above.
4483 If you want to try again, you should use a new version number.
4484 END
4485     if (!check_for_git()) {
4486         create_remote_git_repo();
4487     }
4488
4489     my @pushrefs = $forceflag.$dgithead.":".rrref();
4490     foreach my $tw (@tagwants) {
4491         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4492     }
4493
4494     runcmd_ordryrun @git,
4495         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4496     runcmd_ordryrun git_update_ref_cmd 'dgit push', lrref(), $dgithead;
4497
4498     supplementary_message(<<'END');
4499 Push failed, while obtaining signatures on the .changes and .dsc.
4500 If it was just that the signature failed, you may try again by using
4501 debsign by hand to sign the changes
4502    $changesfile
4503 and then dput to complete the upload.
4504 If you need to change the package, you must use a new version number.
4505 END
4506     if ($we_are_responder) {
4507         my $dryrunsuffix = act_local() ? "" : ".tmp";
4508         my @rfiles = ($dscpath, $changesfile);
4509         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4510         responder_receive_files('signed-dsc-changes',
4511                                 map { "$_$dryrunsuffix" } @rfiles);
4512     } else {
4513         if (act_local()) {
4514             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4515         } else {
4516             progress "[new .dsc left in $dscpath.tmp]";
4517         }
4518         sign_changes $changesfile;
4519     }
4520
4521     supplementary_message(<<END);
4522 Push failed, while uploading package(s) to the archive server.
4523 You can retry the upload of exactly these same files with dput of:
4524   $changesfile
4525 If that .changes file is broken, you will need to use a new version
4526 number for your next attempt at the upload.
4527 END
4528     my $host = access_cfg('upload-host','RETURN-UNDEF');
4529     my @hostarg = defined($host) ? ($host,) : ();
4530     runcmd_ordryrun @dput, @hostarg, $changesfile;
4531     printdone "pushed and uploaded $cversion";
4532
4533     supplementary_message('');
4534     responder_send_command("complete");
4535 }
4536
4537 sub pre_clone () {
4538     not_necessarily_a_tree();
4539 }
4540 sub cmd_clone {
4541     parseopts();
4542     my $dstdir;
4543     badusage "-p is not allowed with clone; specify as argument instead"
4544         if defined $package;
4545     if (@ARGV==1) {
4546         ($package) = @ARGV;
4547     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4548         ($package,$isuite) = @ARGV;
4549     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4550         ($package,$dstdir) = @ARGV;
4551     } elsif (@ARGV==3) {
4552         ($package,$isuite,$dstdir) = @ARGV;
4553     } else {
4554         badusage "incorrect arguments to dgit clone";
4555     }
4556     notpushing();
4557
4558     $dstdir ||= "$package";
4559     if (stat_exists $dstdir) {
4560         fail "$dstdir already exists";
4561     }
4562
4563     my $cwd_remove;
4564     if ($rmonerror && !$dryrun_level) {
4565         $cwd_remove= getcwd();
4566         unshift @end, sub {
4567             return unless defined $cwd_remove;
4568             if (!chdir "$cwd_remove") {
4569                 return if $!==&ENOENT;
4570                 die "chdir $cwd_remove: $!";
4571             }
4572             printdebug "clone rmonerror removing $dstdir\n";
4573             if (stat $dstdir) {
4574                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4575             } elsif (grep { $! == $_ }
4576                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4577             } else {
4578                 print STDERR "check whether to remove $dstdir: $!\n";
4579             }
4580         };
4581     }
4582
4583     clone($dstdir);
4584     $cwd_remove = undef;
4585 }
4586
4587 sub branchsuite () {
4588     my $branch = git_get_symref();
4589     if (defined $branch && $branch =~ m#$lbranch_re#o) {
4590         return $1;
4591     } else {
4592         return undef;
4593     }
4594 }
4595
4596 sub package_from_d_control () {
4597     if (!defined $package) {
4598         my $sourcep = parsecontrol('debian/control','debian/control');
4599         $package = getfield $sourcep, 'Source';
4600     }
4601 }
4602
4603 sub fetchpullargs () {
4604     package_from_d_control();
4605     if (@ARGV==0) {
4606         $isuite = branchsuite();
4607         if (!$isuite) {
4608             my $clogp = parsechangelog();
4609             my $clogsuite = getfield $clogp, 'Distribution';
4610             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4611         }
4612     } elsif (@ARGV==1) {
4613         ($isuite) = @ARGV;
4614     } else {
4615         badusage "incorrect arguments to dgit fetch or dgit pull";
4616     }
4617     notpushing();
4618 }
4619
4620 sub cmd_fetch {
4621     parseopts();
4622     fetchpullargs();
4623     dofetch();
4624 }
4625
4626 sub cmd_pull {
4627     parseopts();
4628     fetchpullargs();
4629     if (quiltmode_splitbrain()) {
4630         my ($format, $fopts) = get_source_format();
4631         madformat($format) and fail <<END
4632 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4633 END
4634     }
4635     pull();
4636 }
4637
4638 sub cmd_checkout {
4639     parseopts();
4640     package_from_d_control();
4641     @ARGV==1 or badusage "dgit checkout needs a suite argument";
4642     ($isuite) = @ARGV;
4643     notpushing();
4644
4645     foreach my $canon (qw(0 1)) {
4646         if (!$canon) {
4647             $csuite= $isuite;
4648         } else {
4649             undef $csuite;
4650             canonicalise_suite();
4651         }
4652         if (length git_get_ref lref()) {
4653             # local branch already exists, yay
4654             last;
4655         }
4656         if (!length git_get_ref lrref()) {
4657             if (!$canon) {
4658                 # nope
4659                 next;
4660             }
4661             dofetch();
4662         }
4663         # now lrref exists
4664         runcmd (@git, qw(update-ref), lref(), lrref(), '');
4665         last;
4666     }
4667     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
4668         "dgit checkout $isuite";
4669     runcmd (@git, qw(checkout), lbranch());
4670 }
4671
4672 sub cmd_update_vcs_git () {
4673     my $specsuite;
4674     if (@ARGV==0 || $ARGV[0] =~ m/^-/) {
4675         ($specsuite,) = split /\;/, cfg 'dgit.vcs-git.suites';
4676     } else {
4677         ($specsuite) = (@ARGV);
4678         shift @ARGV;
4679     }
4680     my $dofetch=1;
4681     if (@ARGV) {
4682         if ($ARGV[0] eq '-') {
4683             $dofetch = 0;
4684         } elsif ($ARGV[0] eq '-') {
4685             shift;
4686         }
4687     }
4688
4689     package_from_d_control();
4690     my $ctrl;
4691     if ($specsuite eq '.') {
4692         $ctrl = parsecontrol 'debian/control', 'debian/control';
4693     } else {
4694         $isuite = $specsuite;
4695         get_archive_dsc();
4696         $ctrl = $dsc;
4697     }
4698     my $url = getfield $ctrl, 'Vcs-Git';
4699
4700     my @cmd;
4701     my $orgurl = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
4702     if (!defined $orgurl) {
4703         print STDERR "setting up vcs-git: $url\n";
4704         @cmd = (@git, qw(remote add vcs-git), $url);
4705     } elsif ($orgurl eq $url) {
4706         print STDERR "vcs git already configured: $url\n";
4707     } else {
4708         print STDERR "changing vcs-git url to: $url\n";
4709         @cmd = (@git, qw(remote set-url vcs-git), $url);
4710     }
4711     runcmd_ordryrun_local @cmd;
4712     if ($dofetch) {
4713         print "fetching (@ARGV)\n";
4714         runcmd_ordryrun_local @git, qw(fetch vcs-git), @ARGV;
4715     }
4716 }
4717
4718 sub prep_push () {
4719     parseopts();
4720     build_or_push_prep_early();
4721     pushing();
4722     check_not_dirty();
4723     my $specsuite;
4724     if (@ARGV==0) {
4725     } elsif (@ARGV==1) {
4726         ($specsuite) = (@ARGV);
4727     } else {
4728         badusage "incorrect arguments to dgit $subcommand";
4729     }
4730     if ($new_package) {
4731         local ($package) = $existing_package; # this is a hack
4732         canonicalise_suite();
4733     } else {
4734         canonicalise_suite();
4735     }
4736     if (defined $specsuite &&
4737         $specsuite ne $isuite &&
4738         $specsuite ne $csuite) {
4739             fail "dgit $subcommand: changelog specifies $isuite ($csuite)".
4740                 " but command line specifies $specsuite";
4741     }
4742 }
4743
4744 sub cmd_push {
4745     prep_push();
4746     dopush();
4747 }
4748
4749 #---------- remote commands' implementation ----------
4750
4751 sub pre_remote_push_build_host {
4752     my ($nrargs) = shift @ARGV;
4753     my (@rargs) = @ARGV[0..$nrargs-1];
4754     @ARGV = @ARGV[$nrargs..$#ARGV];
4755     die unless @rargs;
4756     my ($dir,$vsnwant) = @rargs;
4757     # vsnwant is a comma-separated list; we report which we have
4758     # chosen in our ready response (so other end can tell if they
4759     # offered several)
4760     $debugprefix = ' ';
4761     $we_are_responder = 1;
4762     $us .= " (build host)";
4763
4764     open PI, "<&STDIN" or die $!;
4765     open STDIN, "/dev/null" or die $!;
4766     open PO, ">&STDOUT" or die $!;
4767     autoflush PO 1;
4768     open STDOUT, ">&STDERR" or die $!;
4769     autoflush STDOUT 1;
4770
4771     $vsnwant //= 1;
4772     ($protovsn) = grep {
4773         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4774     } @rpushprotovsn_support;
4775
4776     fail "build host has dgit rpush protocol versions ".
4777         (join ",", @rpushprotovsn_support).
4778         " but invocation host has $vsnwant"
4779         unless defined $protovsn;
4780
4781     changedir $dir;
4782 }
4783 sub cmd_remote_push_build_host {
4784     responder_send_command("dgit-remote-push-ready $protovsn");
4785     &cmd_push;
4786 }
4787
4788 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4789 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4790 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4791 #     a good error message)
4792
4793 sub rpush_handle_protovsn_bothends () {
4794     if ($protovsn < 4) {
4795         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4796     }
4797     select_tagformat();
4798 }
4799
4800 our $i_tmp;
4801
4802 sub i_cleanup {
4803     local ($@, $?);
4804     my $report = i_child_report();
4805     if (defined $report) {
4806         printdebug "($report)\n";
4807     } elsif ($i_child_pid) {
4808         printdebug "(killing build host child $i_child_pid)\n";
4809         kill 15, $i_child_pid;
4810     }
4811     if (defined $i_tmp && !defined $initiator_tempdir) {
4812         changedir "/";
4813         eval { rmtree $i_tmp; };
4814     }
4815 }
4816
4817 END {
4818     return unless forkcheck_mainprocess();
4819     i_cleanup();
4820 }
4821
4822 sub i_method {
4823     my ($base,$selector,@args) = @_;
4824     $selector =~ s/\-/_/g;
4825     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4826 }
4827
4828 sub pre_rpush () {
4829     not_necessarily_a_tree();
4830 }
4831 sub cmd_rpush {
4832     my $host = nextarg;
4833     my $dir;
4834     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4835         $host = $1;
4836         $dir = $'; #';
4837     } else {
4838         $dir = nextarg;
4839     }
4840     $dir =~ s{^-}{./-};
4841     my @rargs = ($dir);
4842     push @rargs, join ",", @rpushprotovsn_support;
4843     my @rdgit;
4844     push @rdgit, @dgit;
4845     push @rdgit, @ropts;
4846     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4847     push @rdgit, @ARGV;
4848     my @cmd = (@ssh, $host, shellquote @rdgit);
4849     debugcmd "+",@cmd;
4850
4851     $we_are_initiator=1;
4852
4853     if (defined $initiator_tempdir) {
4854         rmtree $initiator_tempdir;
4855         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4856         $i_tmp = $initiator_tempdir;
4857     } else {
4858         $i_tmp = tempdir();
4859     }
4860     $i_child_pid = open2(\*RO, \*RI, @cmd);
4861     changedir $i_tmp;
4862     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4863     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4864     $supplementary_message = '' unless $protovsn >= 3;
4865
4866     for (;;) {
4867         my ($icmd,$iargs) = initiator_expect {
4868             m/^(\S+)(?: (.*))?$/;
4869             ($1,$2);
4870         };
4871         i_method "i_resp", $icmd, $iargs;
4872     }
4873 }
4874
4875 sub i_resp_progress ($) {
4876     my ($rhs) = @_;
4877     my $msg = protocol_read_bytes \*RO, $rhs;
4878     progress $msg;
4879 }
4880
4881 sub i_resp_supplementary_message ($) {
4882     my ($rhs) = @_;
4883     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4884 }
4885
4886 sub i_resp_complete {
4887     my $pid = $i_child_pid;
4888     $i_child_pid = undef; # prevents killing some other process with same pid
4889     printdebug "waiting for build host child $pid...\n";
4890     my $got = waitpid $pid, 0;
4891     die $! unless $got == $pid;
4892     die "build host child failed $?" if $?;
4893
4894     i_cleanup();
4895     printdebug "all done\n";
4896     finish 0;
4897 }
4898
4899 sub i_resp_file ($) {
4900     my ($keyword) = @_;
4901     my $localname = i_method "i_localname", $keyword;
4902     my $localpath = "$i_tmp/$localname";
4903     stat_exists $localpath and
4904         badproto \*RO, "file $keyword ($localpath) twice";
4905     protocol_receive_file \*RO, $localpath;
4906     i_method "i_file", $keyword;
4907 }
4908
4909 our %i_param;
4910
4911 sub i_resp_param ($) {
4912     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4913     $i_param{$1} = $2;
4914 }
4915
4916 sub i_resp_previously ($) {
4917     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4918         or badproto \*RO, "bad previously spec";
4919     my $r = system qw(git check-ref-format), $1;
4920     die "bad previously ref spec ($r)" if $r;
4921     $previously{$1} = $2;
4922 }
4923
4924 our %i_wanted;
4925
4926 sub i_resp_want ($) {
4927     my ($keyword) = @_;
4928     die "$keyword ?" if $i_wanted{$keyword}++;
4929
4930     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4931     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4932     die unless $isuite =~ m/^$suite_re$/;
4933
4934     pushing();
4935     rpush_handle_protovsn_bothends();
4936
4937     fail "rpush negotiated protocol version $protovsn".
4938         " which does not support quilt mode $quilt_mode"
4939         if quiltmode_splitbrain;
4940
4941     my @localpaths = i_method "i_want", $keyword;
4942     printdebug "[[  $keyword @localpaths\n";
4943     foreach my $localpath (@localpaths) {
4944         protocol_send_file \*RI, $localpath;
4945     }
4946     print RI "files-end\n" or die $!;
4947 }
4948
4949 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4950
4951 sub i_localname_parsed_changelog {
4952     return "remote-changelog.822";
4953 }
4954 sub i_file_parsed_changelog {
4955     ($i_clogp, $i_version, $i_dscfn) =
4956         push_parse_changelog "$i_tmp/remote-changelog.822";
4957     die if $i_dscfn =~ m#/|^\W#;
4958 }
4959
4960 sub i_localname_dsc {
4961     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4962     return $i_dscfn;
4963 }
4964 sub i_file_dsc { }
4965
4966 sub i_localname_buildinfo ($) {
4967     my $bi = $i_param{'buildinfo-filename'};
4968     defined $bi or badproto \*RO, "buildinfo before filename";
4969     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4970     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4971         or badproto \*RO, "improper buildinfo filename";
4972     return $&;
4973 }
4974 sub i_file_buildinfo {
4975     my $bi = $i_param{'buildinfo-filename'};
4976     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4977     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4978     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4979         files_compare_inputs($bd, $ch);
4980         (getfield $bd, $_) eq (getfield $ch, $_) or
4981             fail "buildinfo mismatch $_"
4982             foreach qw(Source Version);
4983         !defined $bd->{$_} or
4984             fail "buildinfo contains $_"
4985             foreach qw(Changes Changed-by Distribution);
4986     }
4987     push @i_buildinfos, $bi;
4988     delete $i_param{'buildinfo-filename'};
4989 }
4990
4991 sub i_localname_changes {
4992     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4993     $i_changesfn = $i_dscfn;
4994     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4995     return $i_changesfn;
4996 }
4997 sub i_file_changes { }
4998
4999 sub i_want_signed_tag {
5000     printdebug Dumper(\%i_param, $i_dscfn);
5001     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
5002         && defined $i_param{'csuite'}
5003         or badproto \*RO, "premature desire for signed-tag";
5004     my $head = $i_param{'head'};
5005     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
5006
5007     my $maintview = $i_param{'maint-view'};
5008     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
5009
5010     select_tagformat();
5011     if ($protovsn >= 4) {
5012         my $p = $i_param{'tagformat'} // '<undef>';
5013         $p eq $tagformat
5014             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
5015     }
5016
5017     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
5018     $csuite = $&;
5019     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
5020
5021     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
5022
5023     return
5024         push_mktags $i_clogp, $i_dscfn,
5025             $i_changesfn, 'remote changes',
5026             \@tagwants;
5027 }
5028
5029 sub i_want_signed_dsc_changes {
5030     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
5031     sign_changes $i_changesfn;
5032     return ($i_dscfn, $i_changesfn, @i_buildinfos);
5033 }
5034
5035 #---------- building etc. ----------
5036
5037 our $version;
5038 our $sourcechanges;
5039 our $dscfn;
5040
5041 #----- `3.0 (quilt)' handling -----
5042
5043 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
5044
5045 sub quiltify_dpkg_commit ($$$;$) {
5046     my ($patchname,$author,$msg, $xinfo) = @_;
5047     $xinfo //= '';
5048
5049     mkpath '.git/dgit'; # we are in playtree
5050     my $descfn = ".git/dgit/quilt-description.tmp";
5051     open O, '>', $descfn or die "$descfn: $!";
5052     $msg =~ s/\n+/\n\n/;
5053     print O <<END or die $!;
5054 From: $author
5055 ${xinfo}Subject: $msg
5056 ---
5057
5058 END
5059     close O or die $!;
5060
5061     {
5062         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
5063         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
5064         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
5065         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
5066     }
5067 }
5068
5069 sub quiltify_trees_differ ($$;$$$) {
5070     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
5071     # returns true iff the two tree objects differ other than in debian/
5072     # with $finegrained,
5073     # returns bitmask 01 - differ in upstream files except .gitignore
5074     #                 02 - differ in .gitignore
5075     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
5076     #  is set for each modified .gitignore filename $fn
5077     # if $unrepres is defined, array ref to which is appeneded
5078     #  a list of unrepresentable changes (removals of upstream files
5079     #  (as messages)
5080     local $/=undef;
5081     my @cmd = (@git, qw(diff-tree -z --no-renames));
5082     push @cmd, qw(--name-only) unless $unrepres;
5083     push @cmd, qw(-r) if $finegrained || $unrepres;
5084     push @cmd, $x, $y;
5085     my $diffs= cmdoutput @cmd;
5086     my $r = 0;
5087     my @lmodes;
5088     foreach my $f (split /\0/, $diffs) {
5089         if ($unrepres && !@lmodes) {
5090             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
5091             next;
5092         }
5093         my ($oldmode,$newmode) = @lmodes;
5094         @lmodes = ();
5095
5096         next if $f =~ m#^debian(?:/.*)?$#s;
5097
5098         if ($unrepres) {
5099             eval {
5100                 die "not a plain file or symlink\n"
5101                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
5102                            $oldmode =~ m/^(?:10|12)\d{4}$/;
5103                 if ($oldmode =~ m/[^0]/ &&
5104                     $newmode =~ m/[^0]/) {
5105                     # both old and new files exist
5106                     die "mode or type changed\n" if $oldmode ne $newmode;
5107                     die "modified symlink\n" unless $newmode =~ m/^10/;
5108                 } elsif ($oldmode =~ m/[^0]/) {
5109                     # deletion
5110                     die "deletion of symlink\n"
5111                         unless $oldmode =~ m/^10/;
5112                 } else {
5113                     # creation
5114                     die "creation with non-default mode\n"
5115                         unless $newmode =~ m/^100644$/ or
5116                                $newmode =~ m/^120000$/;
5117                 }
5118             };
5119             if ($@) {
5120                 local $/="\n"; chomp $@;
5121                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
5122             }
5123         }
5124
5125         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
5126         $r |= $isignore ? 02 : 01;
5127         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
5128     }
5129     printdebug "quiltify_trees_differ $x $y => $r\n";
5130     return $r;
5131 }
5132
5133 sub quiltify_tree_sentinelfiles ($) {
5134     # lists the `sentinel' files present in the tree
5135     my ($x) = @_;
5136     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
5137         qw(-- debian/rules debian/control);
5138     $r =~ s/\n/,/g;
5139     return $r;
5140 }
5141
5142 sub quiltify_splitbrain_needed () {
5143     if (!$split_brain) {
5144         progress "dgit view: changes are required...";
5145         runcmd @git, qw(checkout -q -b dgit-view);
5146         $split_brain = 1;
5147     }
5148 }
5149
5150 sub quiltify_splitbrain ($$$$$$$) {
5151     my ($clogp, $unapplied, $headref, $oldtiptree, $diffbits,
5152         $editedignores, $cachekey) = @_;
5153     my $gitignore_special = 1;
5154     if ($quilt_mode !~ m/gbp|dpm/) {
5155         # treat .gitignore just like any other upstream file
5156         $diffbits = { %$diffbits };
5157         $_ = !!$_ foreach values %$diffbits;
5158         $gitignore_special = 0;
5159     }
5160     # We would like any commits we generate to be reproducible
5161     my @authline = clogp_authline($clogp);
5162     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
5163     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
5164     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
5165     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
5166     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
5167     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
5168
5169     my $fulldiffhint = sub {
5170         my ($x,$y) = @_;
5171         my $cmd = "git diff $x $y -- :/ ':!debian'";
5172         $cmd .= " ':!/.gitignore' ':!*/.gitignore'" if $gitignore_special;
5173         return "\nFor full diff showing the problem(s), type:\n $cmd\n";
5174     };
5175
5176     if ($quilt_mode =~ m/gbp|unapplied/ &&
5177         ($diffbits->{O2H} & 01)) {
5178         my $msg =
5179  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
5180  " but git tree differs from orig in upstream files.";
5181         $msg .= $fulldiffhint->($unapplied, 'HEAD');
5182         if (!stat_exists "debian/patches") {
5183             $msg .=
5184  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
5185         }
5186         fail $msg;
5187     }
5188     if ($quilt_mode =~ m/dpm/ &&
5189         ($diffbits->{H2A} & 01)) {
5190         fail <<END. $fulldiffhint->($oldtiptree,'HEAD');
5191 --quilt=$quilt_mode specified, implying patches-applied git tree
5192  but git tree differs from result of applying debian/patches to upstream
5193 END
5194     }
5195     if ($quilt_mode =~ m/gbp|unapplied/ &&
5196         ($diffbits->{O2A} & 01)) { # some patches
5197         quiltify_splitbrain_needed();
5198         progress "dgit view: creating patches-applied version using gbp pq";
5199         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
5200         # gbp pq import creates a fresh branch; push back to dgit-view
5201         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
5202         runcmd @git, qw(checkout -q dgit-view);
5203     }
5204     if ($quilt_mode =~ m/gbp|dpm/ &&
5205         ($diffbits->{O2A} & 02)) {
5206         fail <<END;
5207 --quilt=$quilt_mode specified, implying that HEAD is for use with a
5208  tool which does not create patches for changes to upstream
5209  .gitignores: but, such patches exist in debian/patches.
5210 END
5211     }
5212     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5213         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5214         quiltify_splitbrain_needed();
5215         progress "dgit view: creating patch to represent .gitignore changes";
5216         ensuredir "debian/patches";
5217         my $gipatch = "debian/patches/auto-gitignore";
5218         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
5219         stat GIPATCH or die "$gipatch: $!";
5220         fail "$gipatch already exists; but want to create it".
5221             " to record .gitignore changes" if (stat _)[7];
5222         print GIPATCH <<END or die "$gipatch: $!";
5223 Subject: Update .gitignore from Debian packaging branch
5224
5225 The Debian packaging git branch contains these updates to the upstream
5226 .gitignore file(s).  This patch is autogenerated, to provide these
5227 updates to users of the official Debian archive view of the package.
5228
5229 [dgit ($our_version) update-gitignore]
5230 ---
5231 END
5232         close GIPATCH or die "$gipatch: $!";
5233         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5234             $unapplied, $headref, "--", sort keys %$editedignores;
5235         open SERIES, "+>>", "debian/patches/series" or die $!;
5236         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
5237         my $newline;
5238         defined read SERIES, $newline, 1 or die $!;
5239         print SERIES "\n" or die $! unless $newline eq "\n";
5240         print SERIES "auto-gitignore\n" or die $!;
5241         close SERIES or die  $!;
5242         runcmd @git, qw(add -f -- debian/patches/series), $gipatch;
5243         commit_admin <<END
5244 Commit patch to update .gitignore
5245
5246 [dgit ($our_version) update-gitignore-quilt-fixup]
5247 END
5248     }
5249
5250     my $dgitview = git_rev_parse 'HEAD';
5251
5252     changedir $maindir;
5253     # When we no longer need to support squeeze, use --create-reflog
5254     # instead of this:
5255     ensuredir "$maindir_gitcommon/logs/refs/dgit-intern";
5256     my $makelogfh = new IO::File "$maindir_gitcommon/logs/refs/$splitbraincache", '>>'
5257       or die $!;
5258
5259     my $oldcache = git_get_ref "refs/$splitbraincache";
5260     if ($oldcache eq $dgitview) {
5261         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
5262         # git update-ref doesn't always update, in this case.  *sigh*
5263         my $dummy = make_commit_text <<END;
5264 tree $tree
5265 parent $dgitview
5266 author Dgit <dgit\@example.com> 1000000000 +0000
5267 committer Dgit <dgit\@example.com> 1000000000 +0000
5268
5269 Dummy commit - do not use
5270 END
5271         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
5272             "refs/$splitbraincache", $dummy;
5273     }
5274     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
5275         $dgitview;
5276
5277     changedir "$playground/work";
5278
5279     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5280     progress "dgit view: created ($saved)";
5281 }
5282
5283 sub quiltify ($$$$) {
5284     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5285
5286     # Quilt patchification algorithm
5287     #
5288     # We search backwards through the history of the main tree's HEAD
5289     # (T) looking for a start commit S whose tree object is identical
5290     # to to the patch tip tree (ie the tree corresponding to the
5291     # current dpkg-committed patch series).  For these purposes
5292     # `identical' disregards anything in debian/ - this wrinkle is
5293     # necessary because dpkg-source treates debian/ specially.
5294     #
5295     # We can only traverse edges where at most one of the ancestors'
5296     # trees differs (in changes outside in debian/).  And we cannot
5297     # handle edges which change .pc/ or debian/patches.  To avoid
5298     # going down a rathole we avoid traversing edges which introduce
5299     # debian/rules or debian/control.  And we set a limit on the
5300     # number of edges we are willing to look at.
5301     #
5302     # If we succeed, we walk forwards again.  For each traversed edge
5303     # PC (with P parent, C child) (starting with P=S and ending with
5304     # C=T) to we do this:
5305     #  - git checkout C
5306     #  - dpkg-source --commit with a patch name and message derived from C
5307     # After traversing PT, we git commit the changes which
5308     # should be contained within debian/patches.
5309
5310     # The search for the path S..T is breadth-first.  We maintain a
5311     # todo list containing search nodes.  A search node identifies a
5312     # commit, and looks something like this:
5313     #  $p = {
5314     #      Commit => $git_commit_id,
5315     #      Child => $c,                          # or undef if P=T
5316     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5317     #      Nontrivial => true iff $p..$c has relevant changes
5318     #  };
5319
5320     my @todo;
5321     my @nots;
5322     my $sref_S;
5323     my $max_work=100;
5324     my %considered; # saves being exponential on some weird graphs
5325
5326     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5327
5328     my $not = sub {
5329         my ($search,$whynot) = @_;
5330         printdebug " search NOT $search->{Commit} $whynot\n";
5331         $search->{Whynot} = $whynot;
5332         push @nots, $search;
5333         no warnings qw(exiting);
5334         next;
5335     };
5336
5337     push @todo, {
5338         Commit => $target,
5339     };
5340
5341     while (@todo) {
5342         my $c = shift @todo;
5343         next if $considered{$c->{Commit}}++;
5344
5345         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5346
5347         printdebug "quiltify investigate $c->{Commit}\n";
5348
5349         # are we done?
5350         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5351             printdebug " search finished hooray!\n";
5352             $sref_S = $c;
5353             last;
5354         }
5355
5356         quiltify_nofix_bail " $c->{Commit}", " (tree object $oldtiptree)";
5357         if ($quilt_mode eq 'smash') {
5358             printdebug " search quitting smash\n";
5359             last;
5360         }
5361
5362         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5363         $not->($c, "has $c_sentinels not $t_sentinels")
5364             if $c_sentinels ne $t_sentinels;
5365
5366         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5367         $commitdata =~ m/\n\n/;
5368         $commitdata =~ $`;
5369         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5370         @parents = map { { Commit => $_, Child => $c } } @parents;
5371
5372         $not->($c, "root commit") if !@parents;
5373
5374         foreach my $p (@parents) {
5375             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5376         }
5377         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5378         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5379
5380         foreach my $p (@parents) {
5381             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5382
5383             my @cmd= (@git, qw(diff-tree -r --name-only),
5384                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5385             my $patchstackchange = cmdoutput @cmd;
5386             if (length $patchstackchange) {
5387                 $patchstackchange =~ s/\n/,/g;
5388                 $not->($p, "changed $patchstackchange");
5389             }
5390
5391             printdebug " search queue P=$p->{Commit} ",
5392                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5393             push @todo, $p;
5394         }
5395     }
5396
5397     if (!$sref_S) {
5398         printdebug "quiltify want to smash\n";
5399
5400         my $abbrev = sub {
5401             my $x = $_[0]{Commit};
5402             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5403             return $x;
5404         };
5405         my $reportnot = sub {
5406             my ($notp) = @_;
5407             my $s = $abbrev->($notp);
5408             my $c = $notp->{Child};
5409             $s .= "..".$abbrev->($c) if $c;
5410             $s .= ": ".$notp->{Whynot};
5411             return $s;
5412         };
5413         if ($quilt_mode eq 'linear') {
5414             print STDERR "\n$us: error: quilt fixup cannot be linear.  Stopped at:\n";
5415             foreach my $notp (@nots) {
5416                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5417             }
5418             print STDERR "$us: $_\n" foreach @$failsuggestion;
5419             fail
5420  "quilt history linearisation failed.  Search \`quilt fixup' in dgit(7).\n".
5421  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5422         } elsif ($quilt_mode eq 'smash') {
5423         } elsif ($quilt_mode eq 'auto') {
5424             progress "quilt fixup cannot be linear, smashing...";
5425         } else {
5426             die "$quilt_mode ?";
5427         }
5428
5429         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5430         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5431         my $ncommits = 3;
5432         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5433
5434         quiltify_dpkg_commit "auto-$version-$target-$time",
5435             (getfield $clogp, 'Maintainer'),
5436             "Automatically generated patch ($clogp->{Version})\n".
5437             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5438         return;
5439     }
5440
5441     progress "quiltify linearisation planning successful, executing...";
5442
5443     for (my $p = $sref_S;
5444          my $c = $p->{Child};
5445          $p = $p->{Child}) {
5446         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5447         next unless $p->{Nontrivial};
5448
5449         my $cc = $c->{Commit};
5450
5451         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5452         $commitdata =~ m/\n\n/ or die "$c ?";
5453         $commitdata = $`;
5454         my $msg = $'; #';
5455         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5456         my $author = $1;
5457
5458         my $commitdate = cmdoutput
5459             @git, qw(log -n1 --pretty=format:%aD), $cc;
5460
5461         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5462
5463         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5464         $strip_nls->();
5465
5466         my $title = $1;
5467         my $patchname;
5468         my $patchdir;
5469
5470         my $gbp_check_suitable = sub {
5471             $_ = shift;
5472             my ($what) = @_;
5473
5474             eval {
5475                 die "contains unexpected slashes\n" if m{//} || m{/$};
5476                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5477                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5478                 die "is series file\n" if m{$series_filename_re}o;
5479                 die "too long" if length > 200;
5480             };
5481             return $_ unless $@;
5482             print STDERR "quiltifying commit $cc:".
5483                 " ignoring/dropping Gbp-Pq $what: $@";
5484             return undef;
5485         };
5486
5487         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5488                            gbp-pq-name: \s* )
5489                        (\S+) \s* \n //ixm) {
5490             $patchname = $gbp_check_suitable->($1, 'Name');
5491         }
5492         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5493                            gbp-pq-topic: \s* )
5494                        (\S+) \s* \n //ixm) {
5495             $patchdir = $gbp_check_suitable->($1, 'Topic');
5496         }
5497
5498         $strip_nls->();
5499
5500         if (!defined $patchname) {
5501             $patchname = $title;
5502             $patchname =~ s/[.:]$//;
5503             use Text::Iconv;
5504             eval {
5505                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5506                 my $translitname = $converter->convert($patchname);
5507                 die unless defined $translitname;
5508                 $patchname = $translitname;
5509             };
5510             print STDERR
5511                 "dgit: patch title transliteration error: $@"
5512                 if $@;
5513             $patchname =~ y/ A-Z/-a-z/;
5514             $patchname =~ y/-a-z0-9_.+=~//cd;
5515             $patchname =~ s/^\W/x-$&/;
5516             $patchname = substr($patchname,0,40);
5517             $patchname .= ".patch";
5518         }
5519         if (!defined $patchdir) {
5520             $patchdir = '';
5521         }
5522         if (length $patchdir) {
5523             $patchname = "$patchdir/$patchname";
5524         }
5525         if ($patchname =~ m{^(.*)/}) {
5526             mkpath "debian/patches/$1";
5527         }
5528
5529         my $index;
5530         for ($index='';
5531              stat "debian/patches/$patchname$index";
5532              $index++) { }
5533         $!==ENOENT or die "$patchname$index $!";
5534
5535         runcmd @git, qw(checkout -q), $cc;
5536
5537         # We use the tip's changelog so that dpkg-source doesn't
5538         # produce complaining messages from dpkg-parsechangelog.  None
5539         # of the information dpkg-source gets from the changelog is
5540         # actually relevant - it gets put into the original message
5541         # which dpkg-source provides our stunt editor, and then
5542         # overwritten.
5543         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5544
5545         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5546             "Date: $commitdate\n".
5547             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5548
5549         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5550     }
5551
5552     runcmd @git, qw(checkout -q master);
5553 }
5554
5555 sub build_maybe_quilt_fixup () {
5556     my ($format,$fopts) = get_source_format;
5557     return unless madformat_wantfixup $format;
5558     # sigh
5559
5560     check_for_vendor_patches();
5561
5562     if (quiltmode_splitbrain) {
5563         fail <<END unless access_cfg_tagformats_can_splitbrain;
5564 quilt mode $quilt_mode requires split view so server needs to support
5565  both "new" and "maint" tag formats, but config says it doesn't.
5566 END
5567     }
5568
5569     my $clogp = parsechangelog();
5570     my $headref = git_rev_parse('HEAD');
5571     my $symref = git_get_symref();
5572
5573     if ($quilt_mode eq 'linear'
5574         && !$fopts->{'single-debian-patch'}
5575         && branch_is_gdr($symref, $headref)) {
5576         # This is much faster.  It also makes patches that gdr
5577         # likes better for future updates without laundering.
5578         #
5579         # However, it can fail in some casses where we would
5580         # succeed: if there are existing patches, which correspond
5581         # to a prefix of the branch, but are not in gbp/gdr
5582         # format, gdr will fail (exiting status 7), but we might
5583         # be able to figure out where to start linearising.  That
5584         # will be slower so hopefully there's not much to do.
5585         my @cmd = (@git_debrebase,
5586                    qw(--noop-ok -funclean-mixed -funclean-ordering
5587                       make-patches --quiet-would-amend));
5588         # We tolerate soe snags that gdr wouldn't, by default.
5589         if (act_local()) {
5590             debugcmd "+",@cmd;
5591             $!=0; $?=-1;
5592             failedcmd @cmd if system @cmd and $?!=7*256;
5593         } else {
5594             dryrun_report @cmd;
5595         }
5596         $headref = git_rev_parse('HEAD');
5597     }
5598
5599     prep_ud();
5600     changedir $playground;
5601
5602     my $upstreamversion = upstreamversion $version;
5603
5604     if ($fopts->{'single-debian-patch'}) {
5605         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5606     } else {
5607         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5608     }
5609
5610     changedir $maindir;
5611     runcmd_ordryrun_local
5612         @git, qw(pull --ff-only -q), "$playground/work", qw(master);
5613 }
5614
5615 sub unpack_playtree_mkwork ($) {
5616     my ($headref) = @_;
5617
5618     mkdir "work" or die $!;
5619     changedir "work";
5620     mktree_in_ud_here();
5621     runcmd @git, qw(reset -q --hard), $headref;
5622 }
5623
5624 sub unpack_playtree_linkorigs ($$) {
5625     my ($upstreamversion, $fn) = @_;
5626     # calls $fn->($leafname);
5627
5628     my $bpd_abs = bpd_abs();
5629     opendir QFD, $bpd_abs or fail "buildproductsdir: $bpd_abs: $!";
5630     while ($!=0, defined(my $b = readdir QFD)) {
5631         my $f = bpd_abs()."/".$b;
5632         {
5633             local ($debuglevel) = $debuglevel-1;
5634             printdebug "QF linkorigs $b, $f ?\n";
5635         }
5636         next unless is_orig_file_of_vsn $b, $upstreamversion;
5637         printdebug "QF linkorigs $b, $f Y\n";
5638         link_ltarget $f, $b or die "$b $!";
5639         $fn->($b);
5640     }
5641     die "$buildproductsdir: $!" if $!;
5642     closedir QFD;
5643 }
5644
5645 sub quilt_fixup_delete_pc () {
5646     runcmd @git, qw(rm -rqf .pc);
5647     commit_admin <<END
5648 Commit removal of .pc (quilt series tracking data)
5649
5650 [dgit ($our_version) upgrade quilt-remove-pc]
5651 END
5652 }
5653
5654 sub quilt_fixup_singlepatch ($$$) {
5655     my ($clogp, $headref, $upstreamversion) = @_;
5656
5657     progress "starting quiltify (single-debian-patch)";
5658
5659     # dpkg-source --commit generates new patches even if
5660     # single-debian-patch is in debian/source/options.  In order to
5661     # get it to generate debian/patches/debian-changes, it is
5662     # necessary to build the source package.
5663
5664     unpack_playtree_linkorigs($upstreamversion, sub { });
5665     unpack_playtree_mkwork($headref);
5666
5667     rmtree("debian/patches");
5668
5669     runcmd @dpkgsource, qw(-b .);
5670     changedir "..";
5671     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5672     rename srcfn("$upstreamversion", "/debian/patches"),
5673            "work/debian/patches";
5674
5675     changedir "work";
5676     commit_quilty_patch();
5677 }
5678
5679 sub quilt_make_fake_dsc ($) {
5680     my ($upstreamversion) = @_;
5681
5682     my $fakeversion="$upstreamversion-~~DGITFAKE";
5683
5684     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5685     print $fakedsc <<END or die $!;
5686 Format: 3.0 (quilt)
5687 Source: $package
5688 Version: $fakeversion
5689 Files:
5690 END
5691
5692     my $dscaddfile=sub {
5693         my ($b) = @_;
5694
5695         my $md = new Digest::MD5;
5696
5697         my $fh = new IO::File $b, '<' or die "$b $!";
5698         stat $fh or die $!;
5699         my $size = -s _;
5700
5701         $md->addfile($fh);
5702         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5703     };
5704
5705     unpack_playtree_linkorigs($upstreamversion, $dscaddfile);
5706
5707     my @files=qw(debian/source/format debian/rules
5708                  debian/control debian/changelog);
5709     foreach my $maybe (qw(debian/patches debian/source/options
5710                           debian/tests/control)) {
5711         next unless stat_exists "$maindir/$maybe";
5712         push @files, $maybe;
5713     }
5714
5715     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5716     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C), $maindir, @files;
5717
5718     $dscaddfile->($debtar);
5719     close $fakedsc or die $!;
5720 }
5721
5722 sub quilt_fakedsc2unapplied ($$) {
5723     my ($headref, $upstreamversion) = @_;
5724     # must be run in the playground
5725     # quilt_make_fake_dsc must have been called
5726
5727     runcmd qw(sh -ec),
5728         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5729
5730     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5731     rename $fakexdir, "fake" or die "$fakexdir $!";
5732
5733     changedir 'fake';
5734
5735     remove_stray_gits("source package");
5736     mktree_in_ud_here();
5737
5738     rmtree '.pc';
5739
5740     rmtree 'debian'; # git checkout commitish paths does not delete!
5741     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5742     my $unapplied=git_add_write_tree();
5743     printdebug "fake orig tree object $unapplied\n";
5744     return $unapplied;
5745 }
5746
5747 sub quilt_check_splitbrain_cache ($$) {
5748     my ($headref, $upstreamversion) = @_;
5749     # Called only if we are in (potentially) split brain mode.
5750     # Called in playground.
5751     # Computes the cache key and looks in the cache.
5752     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5753
5754     my $splitbrain_cachekey;
5755
5756     progress
5757  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5758     # we look in the reflog of dgit-intern/quilt-cache
5759     # we look for an entry whose message is the key for the cache lookup
5760     my @cachekey = (qw(dgit), $our_version);
5761     push @cachekey, $upstreamversion;
5762     push @cachekey, $quilt_mode;
5763     push @cachekey, $headref;
5764
5765     push @cachekey, hashfile('fake.dsc');
5766
5767     my $srcshash = Digest::SHA->new(256);
5768     my %sfs = ( %INC, '$0(dgit)' => $0 );
5769     foreach my $sfk (sort keys %sfs) {
5770         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5771         $srcshash->add($sfk,"  ");
5772         $srcshash->add(hashfile($sfs{$sfk}));
5773         $srcshash->add("\n");
5774     }
5775     push @cachekey, $srcshash->hexdigest();
5776     $splitbrain_cachekey = "@cachekey";
5777
5778     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5779                $splitbraincache);
5780     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5781     debugcmd "|(probably)",@cmd;
5782     my $child = open GC, "-|";  defined $child or die $!;
5783     if (!$child) {
5784         chdir $maindir or die $!;
5785         if (!stat "$maindir_gitcommon/logs/refs/$splitbraincache") {
5786             $! == ENOENT or die $!;
5787             printdebug ">(no reflog)\n";
5788             finish 0;
5789         }
5790         exec @cmd; die $!;
5791     }
5792     while (<GC>) {
5793         chomp;
5794         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5795         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5796
5797         my $cachehit = $1;
5798         unpack_playtree_mkwork($headref);
5799         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5800         if ($cachehit ne $headref) {
5801             progress "dgit view: found cached ($saved)";
5802             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5803             $split_brain = 1;
5804             return ($cachehit, $splitbrain_cachekey);
5805         }
5806         progress "dgit view: found cached, no changes required";
5807         return ($headref, $splitbrain_cachekey);
5808     }
5809     die $! if GC->error;
5810     failedcmd unless close GC;
5811
5812     printdebug "splitbrain cache miss\n";
5813     return (undef, $splitbrain_cachekey);
5814 }
5815
5816 sub quilt_fixup_multipatch ($$$) {
5817     my ($clogp, $headref, $upstreamversion) = @_;
5818
5819     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5820
5821     # Our objective is:
5822     #  - honour any existing .pc in case it has any strangeness
5823     #  - determine the git commit corresponding to the tip of
5824     #    the patch stack (if there is one)
5825     #  - if there is such a git commit, convert each subsequent
5826     #    git commit into a quilt patch with dpkg-source --commit
5827     #  - otherwise convert all the differences in the tree into
5828     #    a single git commit
5829     #
5830     # To do this we:
5831
5832     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5833     # dgit would include the .pc in the git tree.)  If there isn't
5834     # one, we need to generate one by unpacking the patches that we
5835     # have.
5836     #
5837     # We first look for a .pc in the git tree.  If there is one, we
5838     # will use it.  (This is not the normal case.)
5839     #
5840     # Otherwise need to regenerate .pc so that dpkg-source --commit
5841     # can work.  We do this as follows:
5842     #     1. Collect all relevant .orig from parent directory
5843     #     2. Generate a debian.tar.gz out of
5844     #         debian/{patches,rules,source/format,source/options}
5845     #     3. Generate a fake .dsc containing just these fields:
5846     #          Format Source Version Files
5847     #     4. Extract the fake .dsc
5848     #        Now the fake .dsc has a .pc directory.
5849     # (In fact we do this in every case, because in future we will
5850     # want to search for a good base commit for generating patches.)
5851     #
5852     # Then we can actually do the dpkg-source --commit
5853     #     1. Make a new working tree with the same object
5854     #        store as our main tree and check out the main
5855     #        tree's HEAD.
5856     #     2. Copy .pc from the fake's extraction, if necessary
5857     #     3. Run dpkg-source --commit
5858     #     4. If the result has changes to debian/, then
5859     #          - git add them them
5860     #          - git add .pc if we had a .pc in-tree
5861     #          - git commit
5862     #     5. If we had a .pc in-tree, delete it, and git commit
5863     #     6. Back in the main tree, fast forward to the new HEAD
5864
5865     # Another situation we may have to cope with is gbp-style
5866     # patches-unapplied trees.
5867     #
5868     # We would want to detect these, so we know to escape into
5869     # quilt_fixup_gbp.  However, this is in general not possible.
5870     # Consider a package with a one patch which the dgit user reverts
5871     # (with git revert or the moral equivalent).
5872     #
5873     # That is indistinguishable in contents from a patches-unapplied
5874     # tree.  And looking at the history to distinguish them is not
5875     # useful because the user might have made a confusing-looking git
5876     # history structure (which ought to produce an error if dgit can't
5877     # cope, not a silent reintroduction of an unwanted patch).
5878     #
5879     # So gbp users will have to pass an option.  But we can usually
5880     # detect their failure to do so: if the tree is not a clean
5881     # patches-applied tree, quilt linearisation fails, but the tree
5882     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5883     # they want --quilt=unapplied.
5884     #
5885     # To help detect this, when we are extracting the fake dsc, we
5886     # first extract it with --skip-patches, and then apply the patches
5887     # afterwards with dpkg-source --before-build.  That lets us save a
5888     # tree object corresponding to .origs.
5889
5890     my $splitbrain_cachekey;
5891
5892     quilt_make_fake_dsc($upstreamversion);
5893
5894     if (quiltmode_splitbrain()) {
5895         my $cachehit;
5896         ($cachehit, $splitbrain_cachekey) =
5897             quilt_check_splitbrain_cache($headref, $upstreamversion);
5898         return if $cachehit;
5899     }
5900     my $unapplied=quilt_fakedsc2unapplied($headref, $upstreamversion);
5901
5902     ensuredir '.pc';
5903
5904     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5905     $!=0; $?=-1;
5906     if (system @bbcmd) {
5907         failedcmd @bbcmd if $? < 0;
5908         fail <<END;
5909 failed to apply your git tree's patch stack (from debian/patches/) to
5910  the corresponding upstream tarball(s).  Your source tree and .orig
5911  are probably too inconsistent.  dgit can only fix up certain kinds of
5912  anomaly (depending on the quilt mode).  Please see --quilt= in dgit(1).
5913 END
5914     }
5915
5916     changedir '..';
5917
5918     unpack_playtree_mkwork($headref);
5919
5920     my $mustdeletepc=0;
5921     if (stat_exists ".pc") {
5922         -d _ or die;
5923         progress "Tree already contains .pc - will use it then delete it.";
5924         $mustdeletepc=1;
5925     } else {
5926         rename '../fake/.pc','.pc' or die $!;
5927     }
5928
5929     changedir '../fake';
5930     rmtree '.pc';
5931     my $oldtiptree=git_add_write_tree();
5932     printdebug "fake o+d/p tree object $unapplied\n";
5933     changedir '../work';
5934
5935
5936     # We calculate some guesswork now about what kind of tree this might
5937     # be.  This is mostly for error reporting.
5938
5939     my %editedignores;
5940     my @unrepres;
5941     my $diffbits = {
5942         # H = user's HEAD
5943         # O = orig, without patches applied
5944         # A = "applied", ie orig with H's debian/patches applied
5945         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5946                                      \%editedignores, \@unrepres),
5947         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5948         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5949     };
5950
5951     my @dl;
5952     foreach my $b (qw(01 02)) {
5953         foreach my $v (qw(O2H O2A H2A)) {
5954             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5955         }
5956     }
5957     printdebug "differences \@dl @dl.\n";
5958
5959     progress sprintf
5960 "$us: base trees orig=%.20s o+d/p=%.20s",
5961               $unapplied, $oldtiptree;
5962     progress sprintf
5963 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5964 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5965                              $dl[0], $dl[1],              $dl[3], $dl[4],
5966                                  $dl[2],                     $dl[5];
5967
5968     if (@unrepres) {
5969         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5970             foreach @unrepres;
5971         forceable_fail [qw(unrepresentable)], <<END;
5972 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5973 END
5974     }
5975
5976     my @failsuggestion;
5977     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5978         push @failsuggestion, "This might be a patches-unapplied branch.";
5979     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5980         push @failsuggestion, "This might be a patches-applied branch.";
5981     }
5982     push @failsuggestion, "Maybe you need to specify one of".
5983         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5984
5985     if (quiltmode_splitbrain()) {
5986         quiltify_splitbrain($clogp, $unapplied, $headref, $oldtiptree,
5987                             $diffbits, \%editedignores,
5988                             $splitbrain_cachekey);
5989         return;
5990     }
5991
5992     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5993     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5994
5995     if (!open P, '>>', ".pc/applied-patches") {
5996         $!==&ENOENT or die $!;
5997     } else {
5998         close P;
5999     }
6000
6001     commit_quilty_patch();
6002
6003     if ($mustdeletepc) {
6004         quilt_fixup_delete_pc();
6005     }
6006 }
6007
6008 sub quilt_fixup_editor () {
6009     my $descfn = $ENV{$fakeeditorenv};
6010     my $editing = $ARGV[$#ARGV];
6011     open I1, '<', $descfn or die "$descfn: $!";
6012     open I2, '<', $editing or die "$editing: $!";
6013     unlink $editing or die "$editing: $!";
6014     open O, '>', $editing or die "$editing: $!";
6015     while (<I1>) { print O or die $!; } I1->error and die $!;
6016     my $copying = 0;
6017     while (<I2>) {
6018         $copying ||= m/^\-\-\- /;
6019         next unless $copying;
6020         print O or die $!;
6021     }
6022     I2->error and die $!;
6023     close O or die $1;
6024     finish 0;
6025 }
6026
6027 sub maybe_apply_patches_dirtily () {
6028     return unless $quilt_mode =~ m/gbp|unapplied/;
6029     print STDERR <<END or die $!;
6030
6031 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
6032 dgit: Have to apply the patches - making the tree dirty.
6033 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
6034
6035 END
6036     $patches_applied_dirtily = 01;
6037     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
6038     runcmd qw(dpkg-source --before-build .);
6039 }
6040
6041 sub maybe_unapply_patches_again () {
6042     progress "dgit: Unapplying patches again to tidy up the tree."
6043         if $patches_applied_dirtily;
6044     runcmd qw(dpkg-source --after-build .)
6045         if $patches_applied_dirtily & 01;
6046     rmtree '.pc'
6047         if $patches_applied_dirtily & 02;
6048     $patches_applied_dirtily = 0;
6049 }
6050
6051 #----- other building -----
6052
6053 our $clean_using_builder;
6054 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
6055 #   clean the tree before building (perhaps invoked indirectly by
6056 #   whatever we are using to run the build), rather than separately
6057 #   and explicitly by us.
6058
6059 sub clean_tree () {
6060     return if $clean_using_builder;
6061     if ($cleanmode eq 'dpkg-source') {
6062         maybe_apply_patches_dirtily();
6063         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
6064     } elsif ($cleanmode eq 'dpkg-source-d') {
6065         maybe_apply_patches_dirtily();
6066         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
6067     } elsif ($cleanmode eq 'git') {
6068         runcmd_ordryrun_local @git, qw(clean -xdf);
6069     } elsif ($cleanmode eq 'git-ff') {
6070         runcmd_ordryrun_local @git, qw(clean -xdff);
6071     } elsif ($cleanmode eq 'check') {
6072         my $leftovers = cmdoutput @git, qw(clean -xdn);
6073         if (length $leftovers) {
6074             print STDERR $leftovers, "\n" or die $!;
6075             fail "tree contains uncommitted files and --clean=check specified";
6076         }
6077     } elsif ($cleanmode eq 'none') {
6078     } else {
6079         die "$cleanmode ?";
6080     }
6081 }
6082
6083 sub cmd_clean () {
6084     badusage "clean takes no additional arguments" if @ARGV;
6085     notpushing();
6086     clean_tree();
6087     maybe_unapply_patches_again();
6088 }
6089
6090 # return values from massage_dbp_args are one or both of these flags
6091 sub WANTSRC_SOURCE  () { 01; } # caller should build source (separately)
6092 sub WANTSRC_BUILDER () { 02; } # caller should run dpkg-buildpackage
6093
6094 sub build_or_push_prep_early () {
6095     our $build_or_push_prep_early_done //= 0;
6096     return if $build_or_push_prep_early_done++;
6097     badusage "-p is not allowed with dgit $subcommand" if defined $package;
6098     my $clogp = parsechangelog();
6099     $isuite = getfield $clogp, 'Distribution';
6100     $package = getfield $clogp, 'Source';
6101     $version = getfield $clogp, 'Version';
6102     $dscfn = dscfn($version);
6103 }
6104
6105 sub build_prep_early () {
6106     build_or_push_prep_early();
6107     notpushing();
6108     check_not_dirty();
6109 }
6110
6111 sub build_prep ($) {
6112     my ($wantsrc) = @_;
6113     build_prep_early();
6114     # clean the tree if we're trying to include dirty changes in the
6115     # source package, or we are running the builder in $maindir
6116     clean_tree() if $includedirty || ($wantsrc & WANTSRC_BUILDER);
6117     build_maybe_quilt_fixup();
6118     if ($rmchanges) {
6119         my $pat = changespat $version;
6120         foreach my $f (glob "$buildproductsdir/$pat") {
6121             if (act_local()) {
6122                 unlink $f or fail "remove old changes file $f: $!";
6123             } else {
6124                 progress "would remove $f";
6125             }
6126         }
6127     }
6128 }
6129
6130 sub changesopts_initial () {
6131     my @opts =@changesopts[1..$#changesopts];
6132 }
6133
6134 sub changesopts_version () {
6135     if (!defined $changes_since_version) {
6136         my @vsns;
6137         unless (eval {
6138             @vsns = archive_query('archive_query');
6139             my @quirk = access_quirk();
6140             if ($quirk[0] eq 'backports') {
6141                 local $isuite = $quirk[2];
6142                 local $csuite;
6143                 canonicalise_suite();
6144                 push @vsns, archive_query('archive_query');
6145             }
6146             1;
6147         }) {
6148             print STDERR $@;
6149             fail
6150  "archive query failed (queried because --since-version not specified)";
6151         }
6152         if (@vsns) {
6153             @vsns = map { $_->[0] } @vsns;
6154             @vsns = sort { -version_compare($a, $b) } @vsns;
6155             $changes_since_version = $vsns[0];
6156             progress "changelog will contain changes since $vsns[0]";
6157         } else {
6158             $changes_since_version = '_';
6159             progress "package seems new, not specifying -v<version>";
6160         }
6161     }
6162     if ($changes_since_version ne '_') {
6163         return ("-v$changes_since_version");
6164     } else {
6165         return ();
6166     }
6167 }
6168
6169 sub changesopts () {
6170     return (changesopts_initial(), changesopts_version());
6171 }
6172
6173 sub massage_dbp_args ($;$) {
6174     my ($cmd,$xargs) = @_;
6175     # Since we split the source build out so we can do strange things
6176     # to it, massage the arguments to dpkg-buildpackage so that the
6177     # main build doessn't build source (or add an argument to stop it
6178     # building source by default).
6179     debugcmd '#massaging#', @$cmd if $debuglevel>1;
6180     # -nc has the side effect of specifying -b if nothing else specified
6181     # and some combinations of -S, -b, et al, are errors, rather than
6182     # later simply overriding earlie.  So we need to:
6183     #  - search the command line for these options
6184     #  - pick the last one
6185     #  - perhaps add our own as a default
6186     #  - perhaps adjust it to the corresponding non-source-building version
6187     my $dmode = '-F';
6188     foreach my $l ($cmd, $xargs) {
6189         next unless $l;
6190         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
6191     }
6192     push @$cmd, '-nc';
6193 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
6194     my $r = WANTSRC_BUILDER;
6195     printdebug "massage split $dmode.\n";
6196     $r = $dmode =~ m/[S]/  ?  WANTSRC_SOURCE :
6197       $dmode =~ y/gGF/ABb/ ?  WANTSRC_SOURCE | WANTSRC_BUILDER :
6198       $dmode =~ m/[ABb]/   ?                   WANTSRC_BUILDER :
6199       die "$dmode ?";
6200     printdebug "massage done $r $dmode.\n";
6201     push @$cmd, $dmode;
6202 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
6203     return $r;
6204 }
6205
6206 sub in_bpd (&) {
6207     my ($fn) = @_;
6208     my $wasdir = must_getcwd();
6209     changedir $buildproductsdir;
6210     $fn->();
6211     changedir $wasdir;
6212 }
6213
6214 # this sub must run with CWD=$buildproductsdir (eg in in_bpd)
6215 sub postbuild_mergechanges ($) {
6216     my ($msg_if_onlyone) = @_;
6217     # If there is only one .changes file, fail with $msg_if_onlyone,
6218     # or if that is undef, be a no-op.
6219     # Returns the changes file to report to the user.
6220     my $pat = changespat $version;
6221     my @changesfiles = grep { !m/_multi\.changes/ } glob $pat;
6222     @changesfiles = sort {
6223         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
6224             or $a cmp $b
6225     } @changesfiles;
6226     my $result;
6227     if (@changesfiles==1) {
6228         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
6229 only one changes file from build (@changesfiles)
6230 END
6231         $result = $changesfiles[0];
6232     } elsif (@changesfiles==2) {
6233         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
6234         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
6235             fail "$l found in binaries changes file $binchanges"
6236                 if $l =~ m/\.dsc$/;
6237         }
6238         runcmd_ordryrun_local @mergechanges, @changesfiles;
6239         my $multichanges = changespat $version,'multi';
6240         if (act_local()) {
6241             stat_exists $multichanges or fail "$multichanges: $!";
6242             foreach my $cf (glob $pat) {
6243                 next if $cf eq $multichanges;
6244                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
6245             }
6246         }
6247         $result = $multichanges;
6248     } else {
6249         fail "wrong number of different changes files (@changesfiles)";
6250     }
6251     printdone "build successful, results in $result\n" or die $!;
6252 }
6253
6254 sub midbuild_checkchanges () {
6255     my $pat = changespat $version;
6256     return if $rmchanges;
6257     my @unwanted = map { s#.*/##; $_; } glob "$bpd_glob/$pat";
6258     @unwanted = grep {
6259         $_ ne changespat $version,'source' and
6260         $_ ne changespat $version,'multi'
6261     } @unwanted;
6262     fail <<END
6263 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
6264 Suggest you delete @unwanted.
6265 END
6266         if @unwanted;
6267 }
6268
6269 sub midbuild_checkchanges_vanilla ($) {
6270     my ($wantsrc) = @_;
6271     midbuild_checkchanges() if $wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER);
6272 }
6273
6274 sub postbuild_mergechanges_vanilla ($) {
6275     my ($wantsrc) = @_;
6276     if ($wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER)) {
6277         in_bpd {
6278             postbuild_mergechanges(undef);
6279         };
6280     } else {
6281         printdone "build successful\n";
6282     }
6283 }
6284
6285 sub cmd_build {
6286     build_prep_early();
6287     $buildproductsdir eq '..' or print STDERR <<END;
6288 $us: warning: build-products-dir set, but not supported by dgit build
6289 $us: warning: things may go wrong or files may go to the wrong place
6290 END
6291     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6292     my $wantsrc = massage_dbp_args \@dbp;
6293     build_prep($wantsrc);
6294     if ($wantsrc & WANTSRC_SOURCE) {
6295         build_source();
6296         midbuild_checkchanges_vanilla $wantsrc;
6297     }
6298     if ($wantsrc & WANTSRC_BUILDER) {
6299         push @dbp, changesopts_version();
6300         maybe_apply_patches_dirtily();
6301         runcmd_ordryrun_local @dbp;
6302     }
6303     maybe_unapply_patches_again();
6304     postbuild_mergechanges_vanilla $wantsrc;
6305 }
6306
6307 sub pre_gbp_build {
6308     $quilt_mode //= 'gbp';
6309 }
6310
6311 sub cmd_gbp_build {
6312     build_prep_early();
6313
6314     # gbp can make .origs out of thin air.  In my tests it does this
6315     # even for a 1.0 format package, with no origs present.  So I
6316     # guess it keys off just the version number.  We don't know
6317     # exactly what .origs ought to exist, but let's assume that we
6318     # should run gbp if: the version has an upstream part and the main
6319     # orig is absent.
6320     my $upstreamversion = upstreamversion $version;
6321     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6322     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "$bpd_glob/$origfnpat");
6323
6324     if ($gbp_make_orig) {
6325         clean_tree();
6326         $cleanmode = 'none'; # don't do it again
6327     }
6328
6329     my @dbp = @dpkgbuildpackage;
6330
6331     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6332
6333     if (!length $gbp_build[0]) {
6334         if (length executable_on_path('git-buildpackage')) {
6335             $gbp_build[0] = qw(git-buildpackage);
6336         } else {
6337             $gbp_build[0] = 'gbp buildpackage';
6338         }
6339     }
6340     my @cmd = opts_opt_multi_cmd [], @gbp_build;
6341
6342     push @cmd, (qw(-us -uc --git-no-sign-tags),
6343                 "--git-builder=".(shellquote @dbp));
6344
6345     if ($gbp_make_orig) {
6346         my $priv = dgit_privdir();
6347         my $ok = "$priv/origs-gen-ok";
6348         unlink $ok or $!==&ENOENT or die $!;
6349         my @origs_cmd = @cmd;
6350         push @origs_cmd, qw(--git-cleaner=true);
6351         push @origs_cmd, "--git-prebuild=".
6352             "touch ".(shellquote $ok)." ".(shellquote "$priv/no-such-dir/ok");
6353         push @origs_cmd, @ARGV;
6354         if (act_local()) {
6355             debugcmd @origs_cmd;
6356             system @origs_cmd;
6357             do { local $!; stat_exists $ok; }
6358                 or failedcmd @origs_cmd;
6359         } else {
6360             dryrun_report @origs_cmd;
6361         }
6362     }
6363
6364     build_prep($wantsrc);
6365     if ($wantsrc & WANTSRC_SOURCE) {
6366         build_source();
6367         midbuild_checkchanges_vanilla $wantsrc;
6368     } else {
6369         if (!$clean_using_builder) {
6370             push @cmd, '--git-cleaner=true';
6371         }
6372     }
6373     maybe_unapply_patches_again();
6374     if ($wantsrc & WANTSRC_BUILDER) {
6375         push @cmd, changesopts();
6376         runcmd_ordryrun_local @cmd, @ARGV;
6377     }
6378     postbuild_mergechanges_vanilla $wantsrc;
6379 }
6380 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6381
6382 sub building_source_in_playtree {
6383     # If $includedirty, we have to build the source package from the
6384     # working tree, not a playtree, so that uncommitted changes are
6385     # included (copying or hardlinking them into the playtree could
6386     # cause trouble).
6387     #
6388     # Note that if we are building a source package in split brain
6389     # mode we do not support including uncommitted changes, because
6390     # that makes quilt fixup too hard.  I.e. ($split_brain && (dgit is
6391     # building a source package)) => !$includedirty
6392     return !$includedirty;
6393 }
6394
6395 sub build_source {
6396     $sourcechanges = changespat $version,'source';
6397     if (act_local()) {
6398         unlink "$buildproductsdir/$sourcechanges" or $!==ENOENT
6399             or fail "remove $sourcechanges: $!";
6400     }
6401     my @cmd = (@dpkgsource, qw(-b --));
6402     my $leafdir;
6403     if (building_source_in_playtree()) {
6404         $leafdir = 'work';
6405         my $headref = git_rev_parse('HEAD');
6406         # If we are in split brain, there is already a playtree with
6407         # the thing we should package into a .dsc (thanks to quilt
6408         # fixup).  If not, make a playtree
6409         prep_ud() unless $split_brain;
6410         changedir $playground;
6411         unless ($split_brain) {
6412             my $upstreamversion = upstreamversion $version;
6413             unpack_playtree_linkorigs($upstreamversion, sub { });
6414             unpack_playtree_mkwork($headref);
6415             changedir '..';
6416         }
6417     } else {
6418         $leafdir = basename $maindir;
6419         changedir '..';
6420     }
6421     runcmd_ordryrun_local @cmd, $leafdir;
6422
6423     changedir $leafdir;
6424     runcmd_ordryrun_local qw(sh -ec),
6425       'exec >../$1; shift; exec "$@"','x', $sourcechanges,
6426       @dpkggenchanges, qw(-S), changesopts();
6427     changedir '..';
6428
6429     printdebug "moving $dscfn, $sourcechanges, etc. to ".bpd_abs()."\n";
6430     $dsc = parsecontrol($dscfn, "source package");
6431
6432     my $mv = sub {
6433         my ($why, $l) = @_;
6434         printdebug " renaming ($why) $l\n";
6435         rename "$l", bpd_abs()."/$l"
6436             or fail "put in place new built file ($l): $!";
6437     };
6438     foreach my $l (split /\n/, getfield $dsc, 'Files') {
6439         $l =~ m/\S+$/ or next;
6440         $mv->('Files', $&);
6441     }
6442     $mv->('dsc', $dscfn);
6443     $mv->('changes', $sourcechanges);
6444
6445     changedir $maindir;
6446 }
6447
6448 sub cmd_build_source {
6449     badusage "build-source takes no additional arguments" if @ARGV;
6450     build_prep(WANTSRC_SOURCE);
6451     build_source();
6452     maybe_unapply_patches_again();
6453     printdone "source built, results in $dscfn and $sourcechanges";
6454 }
6455
6456 sub cmd_push_source {
6457     prep_push();
6458     fail "dgit push-source: --include-dirty/--ignore-dirty does not make".
6459       "sense with push-source!" if $includedirty;
6460     build_maybe_quilt_fixup();
6461     if ($changesfile) {
6462         my $changes = parsecontrol("$buildproductsdir/$changesfile",
6463                                    "source changes file");
6464         unless (test_source_only_changes($changes)) {
6465             fail "user-specified changes file is not source-only";
6466         }
6467     } else {
6468         # Building a source package is very fast, so just do it
6469         build_source();
6470         die "er, patches are applied dirtily but shouldn't be.."
6471             if $patches_applied_dirtily;
6472         $changesfile = $sourcechanges;
6473     }
6474     dopush();
6475 }
6476
6477 sub binary_builder {
6478     my ($bbuilder, $pbmc_msg, @args) = @_;
6479     build_prep(WANTSRC_SOURCE);
6480     build_source();
6481     midbuild_checkchanges();
6482     in_bpd {
6483         if (act_local()) {
6484             stat_exists $dscfn or fail "$dscfn (in build products dir): $!";
6485             stat_exists $sourcechanges
6486                 or fail "$sourcechanges (in build products dir): $!";
6487         }
6488         runcmd_ordryrun_local @$bbuilder, @args;
6489     };
6490     maybe_unapply_patches_again();
6491     in_bpd {
6492         postbuild_mergechanges($pbmc_msg);
6493     };
6494 }
6495
6496 sub cmd_sbuild {
6497     build_prep_early();
6498     binary_builder(\@sbuild, <<END, qw(-d), $isuite, @ARGV, $dscfn);
6499 perhaps you need to pass -A ?  (sbuild's default is to build only
6500 arch-specific binaries; dgit 1.4 used to override that.)
6501 END
6502 }
6503
6504 sub pbuilder ($) {
6505     my ($pbuilder) = @_;
6506     build_prep_early();
6507     # @ARGV is allowed to contain only things that should be passed to
6508     # pbuilder under debbuildopts; just massage those
6509     my $wantsrc = massage_dbp_args \@ARGV;
6510     fail "you asked for a builder but your debbuildopts didn't ask for".
6511       " any binaries -- is this really what you meant?"
6512       unless $wantsrc & WANTSRC_BUILDER;
6513     fail "we must build a .dsc to pass to the builder but your debbuiltopts".
6514       " forbids the building of a source package; cannot continue"
6515       unless $wantsrc & WANTSRC_SOURCE;
6516     # We do not want to include the verb "build" in @pbuilder because
6517     # the user can customise @pbuilder and they shouldn't be required
6518     # to include "build" in their customised value.  However, if the
6519     # user passes any additional args to pbuilder using the dgit
6520     # option --pbuilder:foo, such args need to come after the "build"
6521     # verb.  opts_opt_multi_cmd does all of that.
6522     binary_builder([opts_opt_multi_cmd ["build"], @$pbuilder], undef,
6523                    qw(--debbuildopts), "@ARGV", qw(--distribution), $isuite,
6524                    $dscfn);
6525 }
6526
6527 sub cmd_pbuilder {
6528     pbuilder(\@pbuilder);
6529 }
6530
6531 sub cmd_cowbuilder {
6532     pbuilder(\@cowbuilder);
6533 }
6534
6535 sub cmd_quilt_fixup {
6536     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6537     build_prep_early();
6538     clean_tree();
6539     build_maybe_quilt_fixup();
6540 }
6541
6542 sub cmd_print_unapplied_treeish {
6543     badusage "incorrect arguments to dgit print-unapplied-treeish" if @ARGV;
6544     my $headref = git_rev_parse('HEAD');
6545     my $clogp = commit_getclogp $headref;
6546     $package = getfield $clogp, 'Source';
6547     $version = getfield $clogp, 'Version';
6548     $isuite = getfield $clogp, 'Distribution';
6549     $csuite = $isuite; # we want this to be offline!
6550     notpushing();
6551
6552     prep_ud();
6553     changedir $playground;
6554     my $uv = upstreamversion $version;
6555     quilt_make_fake_dsc($uv);
6556     my $u = quilt_fakedsc2unapplied($headref, $uv);
6557     print $u, "\n" or die $!;
6558 }
6559
6560 sub import_dsc_result {
6561     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6562     my @cmd = (git_update_ref_cmd $what_log, $dstref, $newhash);
6563     runcmd @cmd;
6564     check_gitattrs($newhash, "source tree");
6565
6566     progress "dgit: import-dsc: $what_msg";
6567 }
6568
6569 sub cmd_import_dsc {
6570     my $needsig = 0;
6571
6572     while (@ARGV) {
6573         last unless $ARGV[0] =~ m/^-/;
6574         $_ = shift @ARGV;
6575         last if m/^--?$/;
6576         if (m/^--require-valid-signature$/) {
6577             $needsig = 1;
6578         } else {
6579             badusage "unknown dgit import-dsc sub-option \`$_'";
6580         }
6581     }
6582
6583     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6584     my ($dscfn, $dstbranch) = @ARGV;
6585
6586     badusage "dry run makes no sense with import-dsc" unless act_local();
6587
6588     my $force = $dstbranch =~ s/^\+//   ? +1 :
6589                 $dstbranch =~ s/^\.\.// ? -1 :
6590                                            0;
6591     my $info = $force ? " $&" : '';
6592     $info = "$dscfn$info";
6593
6594     my $specbranch = $dstbranch;
6595     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6596     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6597
6598     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6599     my $chead = cmdoutput_errok @symcmd;
6600     defined $chead or $?==256 or failedcmd @symcmd;
6601
6602     fail "$dstbranch is checked out - will not update it"
6603         if defined $chead and $chead eq $dstbranch;
6604
6605     my $oldhash = git_get_ref $dstbranch;
6606
6607     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6608     $dscdata = do { local $/ = undef; <D>; };
6609     D->error and fail "read $dscfn: $!";
6610     close C;
6611
6612     # we don't normally need this so import it here
6613     use Dpkg::Source::Package;
6614     my $dp = new Dpkg::Source::Package filename => $dscfn,
6615         require_valid_signature => $needsig;
6616     {
6617         local $SIG{__WARN__} = sub {
6618             print STDERR $_[0];
6619             return unless $needsig;
6620             fail "import-dsc signature check failed";
6621         };
6622         if (!$dp->is_signed()) {
6623             warn "$us: warning: importing unsigned .dsc\n";
6624         } else {
6625             my $r = $dp->check_signature();
6626             die "->check_signature => $r" if $needsig && $r;
6627         }
6628     }
6629
6630     parse_dscdata();
6631
6632     $package = getfield $dsc, 'Source';
6633
6634     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6635         unless forceing [qw(import-dsc-with-dgit-field)];
6636     parse_dsc_field_def_dsc_distro();
6637
6638     $isuite = 'DGIT-IMPORT-DSC';
6639     $idistro //= $dsc_distro;
6640
6641     notpushing();
6642
6643     if (defined $dsc_hash) {
6644         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6645         resolve_dsc_field_commit undef, undef;
6646     }
6647     if (defined $dsc_hash) {
6648         my @cmd = (qw(sh -ec),
6649                    "echo $dsc_hash | git cat-file --batch-check");
6650         my $objgot = cmdoutput @cmd;
6651         if ($objgot =~ m#^\w+ missing\b#) {
6652             fail <<END
6653 .dsc contains Dgit field referring to object $dsc_hash
6654 Your git tree does not have that object.  Try `git fetch' from a
6655 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6656 END
6657         }
6658         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6659             if ($force > 0) {
6660                 progress "Not fast forward, forced update.";
6661             } else {
6662                 fail "Not fast forward to $dsc_hash";
6663             }
6664         }
6665         import_dsc_result $dstbranch, $dsc_hash,
6666             "dgit import-dsc (Dgit): $info",
6667             "updated git ref $dstbranch";
6668         return 0;
6669     }
6670
6671     fail <<END
6672 Branch $dstbranch already exists
6673 Specify ..$specbranch for a pseudo-merge, binding in existing history
6674 Specify  +$specbranch to overwrite, discarding existing history
6675 END
6676         if $oldhash && !$force;
6677
6678     my @dfi = dsc_files_info();
6679     foreach my $fi (@dfi) {
6680         my $f = $fi->{Filename};
6681         my $here = "$buildproductsdir/$f";
6682         if (lstat $here) {
6683             next if stat $here;
6684             fail "lstat $here works but stat gives $! !";
6685         }
6686         fail "stat $here: $!" unless $! == ENOENT;
6687         my $there = $dscfn;
6688         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6689             $there = $';
6690         } elsif ($dscfn =~ m#^/#) {
6691             $there = $dscfn;
6692         } else {
6693             fail "cannot import $dscfn which seems to be inside working tree!";
6694         }
6695         $there =~ s#/+[^/]+$## or
6696             fail "import $dscfn requires ../$f, but it does not exist";
6697         $there .= "/$f";
6698         my $test = $there =~ m{^/} ? $there : "../$there";
6699         stat $test or fail "import $dscfn requires $test, but: $!";
6700         symlink $there, $here or fail "symlink $there to $here: $!";
6701         progress "made symlink $here -> $there";
6702 #       print STDERR Dumper($fi);
6703     }
6704     my @mergeinputs = generate_commits_from_dsc();
6705     die unless @mergeinputs == 1;
6706
6707     my $newhash = $mergeinputs[0]{Commit};
6708
6709     if ($oldhash) {
6710         if ($force > 0) {
6711             progress "Import, forced update - synthetic orphan git history.";
6712         } elsif ($force < 0) {
6713             progress "Import, merging.";
6714             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6715             my $version = getfield $dsc, 'Version';
6716             my $clogp = commit_getclogp $newhash;
6717             my $authline = clogp_authline $clogp;
6718             $newhash = make_commit_text <<END;
6719 tree $tree
6720 parent $newhash
6721 parent $oldhash
6722 author $authline
6723 committer $authline
6724
6725 Merge $package ($version) import into $dstbranch
6726 END
6727         } else {
6728             die; # caught earlier
6729         }
6730     }
6731
6732     import_dsc_result $dstbranch, $newhash,
6733         "dgit import-dsc: $info",
6734         "results are in in git ref $dstbranch";
6735 }
6736
6737 sub pre_archive_api_query () {
6738     not_necessarily_a_tree();
6739 }
6740 sub cmd_archive_api_query {
6741     badusage "need only 1 subpath argument" unless @ARGV==1;
6742     my ($subpath) = @ARGV;
6743     local $isuite = 'DGIT-API-QUERY-CMD';
6744     my @cmd = archive_api_query_cmd($subpath);
6745     push @cmd, qw(-f);
6746     debugcmd ">",@cmd;
6747     exec @cmd or fail "exec curl: $!\n";
6748 }
6749
6750 sub repos_server_url () {
6751     $package = '_dgit-repos-server';
6752     local $access_forpush = 1;
6753     local $isuite = 'DGIT-REPOS-SERVER';
6754     my $url = access_giturl();
6755 }
6756
6757 sub pre_clone_dgit_repos_server () {
6758     not_necessarily_a_tree();
6759 }
6760 sub cmd_clone_dgit_repos_server {
6761     badusage "need destination argument" unless @ARGV==1;
6762     my ($destdir) = @ARGV;
6763     my $url = repos_server_url();
6764     my @cmd = (@git, qw(clone), $url, $destdir);
6765     debugcmd ">",@cmd;
6766     exec @cmd or fail "exec git clone: $!\n";
6767 }
6768
6769 sub pre_print_dgit_repos_server_source_url () {
6770     not_necessarily_a_tree();
6771 }
6772 sub cmd_print_dgit_repos_server_source_url {
6773     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6774         if @ARGV;
6775     my $url = repos_server_url();
6776     print $url, "\n" or die $!;
6777 }
6778
6779 sub pre_print_dpkg_source_ignores {
6780     not_necessarily_a_tree();
6781 }
6782 sub cmd_print_dpkg_source_ignores {
6783     badusage "no arguments allowed to dgit print-dpkg-source-ignores"
6784         if @ARGV;
6785     print "@dpkg_source_ignores\n" or die $!;
6786 }
6787
6788 sub cmd_setup_mergechangelogs {
6789     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6790     local $isuite = 'DGIT-SETUP-TREE';
6791     setup_mergechangelogs(1);
6792 }
6793
6794 sub cmd_setup_useremail {
6795     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6796     local $isuite = 'DGIT-SETUP-TREE';
6797     setup_useremail(1);
6798 }
6799
6800 sub cmd_setup_gitattributes {
6801     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6802     local $isuite = 'DGIT-SETUP-TREE';
6803     setup_gitattrs(1);
6804 }
6805
6806 sub cmd_setup_new_tree {
6807     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6808     local $isuite = 'DGIT-SETUP-TREE';
6809     setup_new_tree();
6810 }
6811
6812 #---------- argument parsing and main program ----------
6813
6814 sub cmd_version {
6815     print "dgit version $our_version\n" or die $!;
6816     finish 0;
6817 }
6818
6819 our (%valopts_long, %valopts_short);
6820 our (%funcopts_long);
6821 our @rvalopts;
6822 our (@modeopt_cfgs);
6823
6824 sub defvalopt ($$$$) {
6825     my ($long,$short,$val_re,$how) = @_;
6826     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6827     $valopts_long{$long} = $oi;
6828     $valopts_short{$short} = $oi;
6829     # $how subref should:
6830     #   do whatever assignemnt or thing it likes with $_[0]
6831     #   if the option should not be passed on to remote, @rvalopts=()
6832     # or $how can be a scalar ref, meaning simply assign the value
6833 }
6834
6835 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6836 defvalopt '--distro',        '-d', '.+',      \$idistro;
6837 defvalopt '',                '-k', '.+',      \$keyid;
6838 defvalopt '--existing-package','', '.*',      \$existing_package;
6839 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6840 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6841 defvalopt '--package',   '-p',   $package_re, \$package;
6842 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6843
6844 defvalopt '', '-C', '.+', sub {
6845     ($changesfile) = (@_);
6846     if ($changesfile =~ s#^(.*)/##) {
6847         $buildproductsdir = $1;
6848     }
6849 };
6850
6851 defvalopt '--initiator-tempdir','','.*', sub {
6852     ($initiator_tempdir) = (@_);
6853     $initiator_tempdir =~ m#^/# or
6854         badusage "--initiator-tempdir must be used specify an".
6855         " absolute, not relative, directory."
6856 };
6857
6858 sub defoptmodes ($@) {
6859     my ($varref, $cfgkey, $default, %optmap) = @_;
6860     my %permit;
6861     while (my ($opt,$val) = each %optmap) {
6862         $funcopts_long{$opt} = sub { $$varref = $val; };
6863         $permit{$val} = $val;
6864     }
6865     push @modeopt_cfgs, {
6866         Var => $varref,
6867         Key => $cfgkey,
6868         Default => $default,
6869         Vals => \%permit
6870     };
6871 }
6872
6873 defoptmodes \$dodep14tag, qw( dep14tag          want
6874                               --dep14tag        want
6875                               --no-dep14tag     no
6876                               --always-dep14tag always );
6877
6878 sub parseopts () {
6879     my $om;
6880
6881     if (defined $ENV{'DGIT_SSH'}) {
6882         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6883     } elsif (defined $ENV{'GIT_SSH'}) {
6884         @ssh = ($ENV{'GIT_SSH'});
6885     }
6886
6887     my $oi;
6888     my $val;
6889     my $valopt = sub {
6890         my ($what) = @_;
6891         @rvalopts = ($_);
6892         if (!defined $val) {
6893             badusage "$what needs a value" unless @ARGV;
6894             $val = shift @ARGV;
6895             push @rvalopts, $val;
6896         }
6897         badusage "bad value \`$val' for $what" unless
6898             $val =~ m/^$oi->{Re}$(?!\n)/s;
6899         my $how = $oi->{How};
6900         if (ref($how) eq 'SCALAR') {
6901             $$how = $val;
6902         } else {
6903             $how->($val);
6904         }
6905         push @ropts, @rvalopts;
6906     };
6907
6908     while (@ARGV) {
6909         last unless $ARGV[0] =~ m/^-/;
6910         $_ = shift @ARGV;
6911         last if m/^--?$/;
6912         if (m/^--/) {
6913             if (m/^--dry-run$/) {
6914                 push @ropts, $_;
6915                 $dryrun_level=2;
6916             } elsif (m/^--damp-run$/) {
6917                 push @ropts, $_;
6918                 $dryrun_level=1;
6919             } elsif (m/^--no-sign$/) {
6920                 push @ropts, $_;
6921                 $sign=0;
6922             } elsif (m/^--help$/) {
6923                 cmd_help();
6924             } elsif (m/^--version$/) {
6925                 cmd_version();
6926             } elsif (m/^--new$/) {
6927                 push @ropts, $_;
6928                 $new_package=1;
6929             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6930                      ($om = $opts_opt_map{$1}) &&
6931                      length $om->[0]) {
6932                 push @ropts, $_;
6933                 $om->[0] = $2;
6934             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6935                      !$opts_opt_cmdonly{$1} &&
6936                      ($om = $opts_opt_map{$1})) {
6937                 push @ropts, $_;
6938                 push @$om, $2;
6939             } elsif (m/^--(gbp|dpm)$/s) {
6940                 push @ropts, "--quilt=$1";
6941                 $quilt_mode = $1;
6942             } elsif (m/^--(?:ignore|include)-dirty$/s) {
6943                 push @ropts, $_;
6944                 $includedirty = 1;
6945             } elsif (m/^--no-quilt-fixup$/s) {
6946                 push @ropts, $_;
6947                 $quilt_mode = 'nocheck';
6948             } elsif (m/^--no-rm-on-error$/s) {
6949                 push @ropts, $_;
6950                 $rmonerror = 0;
6951             } elsif (m/^--no-chase-dsc-distro$/s) {
6952                 push @ropts, $_;
6953                 $chase_dsc_distro = 0;
6954             } elsif (m/^--overwrite$/s) {
6955                 push @ropts, $_;
6956                 $overwrite_version = '';
6957             } elsif (m/^--overwrite=(.+)$/s) {
6958                 push @ropts, $_;
6959                 $overwrite_version = $1;
6960             } elsif (m/^--delayed=(\d+)$/s) {
6961                 push @ropts, $_;
6962                 push @dput, $_;
6963             } elsif (my ($k,$v) =
6964                      m/^--save-(dgit-view)=(.+)$/s ||
6965                      m/^--(dgit-view)-save=(.+)$/s
6966                      ) {
6967                 push @ropts, $_;
6968                 $v =~ s#^(?!refs/)#refs/heads/#;
6969                 $internal_object_save{$k} = $v;
6970             } elsif (m/^--(no-)?rm-old-changes$/s) {
6971                 push @ropts, $_;
6972                 $rmchanges = !$1;
6973             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6974                 push @ropts, $_;
6975                 push @deliberatelies, $&;
6976             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6977                 push @ropts, $&;
6978                 $forceopts{$1} = 1;
6979                 $_='';
6980             } elsif (m/^--force-/) {
6981                 print STDERR
6982                     "$us: warning: ignoring unknown force option $_\n";
6983                 $_='';
6984             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6985                 # undocumented, for testing
6986                 push @ropts, $_;
6987                 $tagformat_want = [ $1, 'command line', 1 ];
6988                 # 1 menas overrides distro configuration
6989             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6990                 # undocumented, for testing
6991                 push @ropts, $_;
6992                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6993                 # ^ it's supposed to be an array ref
6994             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6995                 $val = $2 ? $' : undef; #';
6996                 $valopt->($oi->{Long});
6997             } elsif ($funcopts_long{$_}) {
6998                 push @ropts, $_;
6999                 $funcopts_long{$_}();
7000             } else {
7001                 badusage "unknown long option \`$_'";
7002             }
7003         } else {
7004             while (m/^-./s) {
7005                 if (s/^-n/-/) {
7006                     push @ropts, $&;
7007                     $dryrun_level=2;
7008                 } elsif (s/^-L/-/) {
7009                     push @ropts, $&;
7010                     $dryrun_level=1;
7011                 } elsif (s/^-h/-/) {
7012                     cmd_help();
7013                 } elsif (s/^-D/-/) {
7014                     push @ropts, $&;
7015                     $debuglevel++;
7016                     enabledebug();
7017                 } elsif (s/^-N/-/) {
7018                     push @ropts, $&;
7019                     $new_package=1;
7020                 } elsif (m/^-m/) {
7021                     push @ropts, $&;
7022                     push @changesopts, $_;
7023                     $_ = '';
7024                 } elsif (s/^-wn$//s) {
7025                     push @ropts, $&;
7026                     $cleanmode = 'none';
7027                 } elsif (s/^-wg$//s) {
7028                     push @ropts, $&;
7029                     $cleanmode = 'git';
7030                 } elsif (s/^-wgf$//s) {
7031                     push @ropts, $&;
7032                     $cleanmode = 'git-ff';
7033                 } elsif (s/^-wd$//s) {
7034                     push @ropts, $&;
7035                     $cleanmode = 'dpkg-source';
7036                 } elsif (s/^-wdd$//s) {
7037                     push @ropts, $&;
7038                     $cleanmode = 'dpkg-source-d';
7039                 } elsif (s/^-wc$//s) {
7040                     push @ropts, $&;
7041                     $cleanmode = 'check';
7042                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
7043                     push @git, '-c', $&;
7044                     $gitcfgs{cmdline}{$1} = [ $2 ];
7045                 } elsif (s/^-c([^=]+)$//s) {
7046                     push @git, '-c', $&;
7047                     $gitcfgs{cmdline}{$1} = [ 'true' ];
7048                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
7049                     $val = $'; #';
7050                     $val = undef unless length $val;
7051                     $valopt->($oi->{Short});
7052                     $_ = '';
7053                 } else {
7054                     badusage "unknown short option \`$_'";
7055                 }
7056             }
7057         }
7058     }
7059 }
7060
7061 sub check_env_sanity () {
7062     my $blocked = new POSIX::SigSet;
7063     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
7064
7065     eval {
7066         foreach my $name (qw(PIPE CHLD)) {
7067             my $signame = "SIG$name";
7068             my $signum = eval "POSIX::$signame" // die;
7069             die "$signame is set to something other than SIG_DFL\n"
7070                 if defined $SIG{$name} and $SIG{$name} ne 'DEFAULT';
7071             $blocked->ismember($signum) and
7072                 die "$signame is blocked\n";
7073         }
7074     };
7075     return unless $@;
7076     chomp $@;
7077     fail <<END;
7078 On entry to dgit, $@
7079 This is a bug produced by something in in your execution environment.
7080 Giving up.
7081 END
7082 }
7083
7084
7085 sub parseopts_late_defaults () {
7086     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
7087         if defined $idistro;
7088     $isuite //= cfg('dgit.default.default-suite');
7089
7090     foreach my $k (keys %opts_opt_map) {
7091         my $om = $opts_opt_map{$k};
7092
7093         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
7094         if (defined $v) {
7095             badcfg "cannot set command for $k"
7096                 unless length $om->[0];
7097             $om->[0] = $v;
7098         }
7099
7100         foreach my $c (access_cfg_cfgs("opts-$k")) {
7101             my @vl =
7102                 map { $_ ? @$_ : () }
7103                 map { $gitcfgs{$_}{$c} }
7104                 reverse @gitcfgsources;
7105             printdebug "CL $c ", (join " ", map { shellquote } @vl),
7106                 "\n" if $debuglevel >= 4;
7107             next unless @vl;
7108             badcfg "cannot configure options for $k"
7109                 if $opts_opt_cmdonly{$k};
7110             my $insertpos = $opts_cfg_insertpos{$k};
7111             @$om = ( @$om[0..$insertpos-1],
7112                      @vl,
7113                      @$om[$insertpos..$#$om] );
7114         }
7115     }
7116
7117     if (!defined $rmchanges) {
7118         local $access_forpush;
7119         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
7120     }
7121
7122     if (!defined $quilt_mode) {
7123         local $access_forpush;
7124         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
7125             // access_cfg('quilt-mode', 'RETURN-UNDEF')
7126             // 'linear';
7127         $quilt_mode =~ m/^($quilt_modes_re)$/
7128             or badcfg "unknown quilt-mode \`$quilt_mode'";
7129         $quilt_mode = $1;
7130     }
7131
7132     foreach my $moc (@modeopt_cfgs) {
7133         local $access_forpush;
7134         my $vr = $moc->{Var};
7135         next if defined $$vr;
7136         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
7137         my $v = $moc->{Vals}{$$vr};
7138         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
7139         $$vr = $v;
7140     }
7141
7142     fail "dgit: --include-dirty is not supported in split view quilt mode"
7143         if $split_brain && $includedirty;
7144
7145     if (!defined $cleanmode) {
7146         local $access_forpush;
7147         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
7148         $cleanmode //= 'dpkg-source';
7149
7150         badcfg "unknown clean-mode \`$cleanmode'" unless
7151             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
7152     }
7153
7154     $buildproductsdir //= access_cfg('build-products-dir', 'RETURN-UNDEF');
7155     $buildproductsdir //= '..';
7156     $bpd_glob = $buildproductsdir;
7157     $bpd_glob =~ s#[][\\{}*?~]#\\$&#g;
7158 }
7159
7160 if ($ENV{$fakeeditorenv}) {
7161     git_slurp_config();
7162     quilt_fixup_editor();
7163 }
7164
7165 parseopts();
7166 check_env_sanity();
7167
7168 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
7169 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
7170     if $dryrun_level == 1;
7171 if (!@ARGV) {
7172     print STDERR $helpmsg or die $!;
7173     finish 8;
7174 }
7175 $cmd = $subcommand = shift @ARGV;
7176 $cmd =~ y/-/_/;
7177
7178 my $pre_fn = ${*::}{"pre_$cmd"};
7179 $pre_fn->() if $pre_fn;
7180
7181 record_maindir if $invoked_in_git_tree;
7182 git_slurp_config();
7183
7184 my $fn = ${*::}{"cmd_$cmd"};
7185 $fn or badusage "unknown operation $cmd";
7186 $fn->();
7187
7188 finish 0;