dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Text::Glob qw(match_glob);
  40 use Fcntl qw(:DEFAULT :flock);
  41 use Carp;
  42
  43 use Debian::Dgit;
  44
  45 our $our_version = 'UNRELEASED'; ###substituted###
  46 our $absurdity = undef; ###substituted###
  47
  48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  49 our $protovsn;
  50
  51 our $isuite = 'unstable';
  52 our $idistro;
  53 our $package;
  54 our @ropts;
  55
  56 our $sign = 1;
  57 our $dryrun_level = 0;
  58 our $changesfile;
  59 our $buildproductsdir = '..';
  60 our $new_package = 0;
  61 our $ignoredirty = 0;
  62 our $rmonerror = 1;
  63 our @deliberatelies;
  64 our %previously;
  65 our $existing_package = 'dpkg';
  66 our $cleanmode;
  67 our $changes_since_version;
  68 our $rmchanges;
  69 our $overwrite_version; # undef: not specified; '': check changelog
  70 our $quilt_mode;
  71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  72 our $dodep14tag;
  73 our $dodep14tag_re = 'want|no|always';
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $initiator_tempdir;
  77 our $patches_applied_dirtily = 00;
  78 our $tagformat_want;
  79 our $tagformat;
  80 our $tagformatfn;
  81 our $chase_dsc_distro=1; #xxx configurable
  82
  83 our %forceopts = map { $_=>0 }
  84     qw(unrepresentable unsupported-source-format
  85        dsc-changes-mismatch changes-origs-exactly
  86        import-gitapply-absurd
  87        import-gitapply-no-absurd
  88        import-dsc-with-dgit-field);
  89
  90 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  91
  92 our $suite_re = '[-+.0-9a-z]+';
  93 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  94 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  95 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  96 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  97
  98 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  99 our $splitbraincache = 'dgit-intern/quilt-cache';
 100 our $rewritemap = 'dgit-rewrite/map';
 101
 102 our (@git) = qw(git);
 103 our (@dget) = qw(dget);
 104 our (@curl) = qw(curl);
 105 our (@dput) = qw(dput);
 106 our (@debsign) = qw(debsign);
 107 our (@gpg) = qw(gpg);
 108 our (@sbuild) = qw(sbuild);
 109 our (@ssh) = 'ssh';
 110 our (@dgit) = qw(dgit);
 111 our (@aptget) = qw(apt-get);
 112 our (@aptcache) = qw(apt-cache);
 113 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 114 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 115 our (@dpkggenchanges) = qw(dpkg-genchanges);
 116 our (@mergechanges) = qw(mergechanges -f);
 117 our (@gbp_build) = ('');
 118 our (@gbp_pq) = ('gbp pq');
 119 our (@changesopts) = ('');
 120
 121 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 122                      'curl' => \@curl,
 123                      'dput' => \@dput,
 124                      'debsign' => \@debsign,
 125                      'gpg' => \@gpg,
 126                      'sbuild' => \@sbuild,
 127                      'ssh' => \@ssh,
 128                      'dgit' => \@dgit,
 129                      'git' => \@git,
 130                      'apt-get' => \@aptget,
 131                      'apt-cache' => \@aptcache,
 132                      'dpkg-source' => \@dpkgsource,
 133                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 134                      'dpkg-genchanges' => \@dpkggenchanges,
 135                      'gbp-build' => \@gbp_build,
 136                      'gbp-pq' => \@gbp_pq,
 137                      'ch' => \@changesopts,
 138                      'mergechanges' => \@mergechanges);
 139
 140 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 141 our %opts_cfg_insertpos = map {
 142     $_,
 143     scalar @{ $opts_opt_map{$_} }
 144 } keys %opts_opt_map;
 145
 146 sub parseopts_late_defaults();
 147
 148 our $keyid;
 149
 150 autoflush STDOUT 1;
 151
 152 our $supplementary_message = '';
 153 our $need_split_build_invocation = 0;
 154 our $split_brain = 0;
 155
 156 END {
 157     local ($@, $?);
 158     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 159 }
 160
 161 our $remotename = 'dgit';
 162 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 163 our $csuite;
 164 our $instead_distro;
 165
 166 if (!defined $absurdity) {
 167     $absurdity = $0;
 168     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 169 }
 170
 171 sub debiantag ($$) {
 172     my ($v,$distro) = @_;
 173     return $tagformatfn->($v, $distro);
 174 }
 175
 176 sub debiantag_maintview ($$) {
 177     my ($v,$distro) = @_;
 178     return "$distro/".dep14_version_mangle $v;
 179 }
 180
 181 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 182
 183 sub lbranch () { return "$branchprefix/$csuite"; }
 184 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 185 sub lref () { return "refs/heads/".lbranch(); }
 186 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 187 sub rrref () { return server_ref($csuite); }
 188
 189 sub stripepoch ($) {
 190     my ($vsn) = @_;
 191     $vsn =~ s/^\d+\://;
 192     return $vsn;
 193 }
 194
 195 sub srcfn ($$) {
 196     my ($vsn,$sfx) = @_;
 197     return "${package}_".(stripepoch $vsn).$sfx
 198 }
 199
 200 sub dscfn ($) {
 201     my ($vsn) = @_;
 202     return srcfn($vsn,".dsc");
 203 }
 204
 205 sub changespat ($;$) {
 206     my ($vsn, $arch) = @_;
 207     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 208 }
 209
 210 sub upstreamversion ($) {
 211     my ($vsn) = @_;
 212     $vsn =~ s/-[^-]+$//;
 213     return $vsn;
 214 }
 215
 216 our $us = 'dgit';
 217 initdebug('');
 218
 219 our @end;
 220 END {
 221     local ($?);
 222     foreach my $f (@end) {
 223         eval { $f->(); };
 224         print STDERR "$us: cleanup: $@" if length $@;
 225     }
 226 };
 227
 228 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 229
 230 sub forceable_fail ($$) {
 231     my ($forceoptsl, $msg) = @_;
 232     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 233     print STDERR "warning: overriding problem due to --force:\n". $msg;
 234 }
 235
 236 sub forceing ($) {
 237     my ($forceoptsl) = @_;
 238     my @got = grep { $forceopts{$_} } @$forceoptsl;
 239     return 0 unless @got;
 240     print STDERR
 241  "warning: skipping checks or functionality due to --force-$got[0]\n";
 242 }
 243
 244 sub no_such_package () {
 245     print STDERR "$us: package $package does not exist in suite $isuite\n";
 246     exit 4;
 247 }
 248
 249 sub changedir ($) {
 250     my ($newdir) = @_;
 251     printdebug "CD $newdir\n";
 252     chdir $newdir or confess "chdir: $newdir: $!";
 253 }
 254
 255 sub deliberately ($) {
 256     my ($enquiry) = @_;
 257     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 258 }
 259
 260 sub deliberately_not_fast_forward () {
 261     foreach (qw(not-fast-forward fresh-repo)) {
 262         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 263     }
 264 }
 265
 266 sub quiltmode_splitbrain () {
 267     $quilt_mode =~ m/gbp|dpm|unapplied/;
 268 }
 269
 270 sub opts_opt_multi_cmd {
 271     my @cmd;
 272     push @cmd, split /\s+/, shift @_;
 273     push @cmd, @_;
 274     @cmd;
 275 }
 276
 277 sub gbp_pq {
 278     return opts_opt_multi_cmd @gbp_pq;
 279 }
 280
 281 #---------- remote protocol support, common ----------
 282
 283 # remote push initiator/responder protocol:
 284 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 285 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 286 #  < dgit-remote-push-ready <actual-proto-vsn>
 287 #
 288 # occasionally:
 289 #
 290 #  > progress NBYTES
 291 #  [NBYTES message]
 292 #
 293 #  > supplementary-message NBYTES          # $protovsn >= 3
 294 #  [NBYTES message]
 295 #
 296 # main sequence:
 297 #
 298 #  > file parsed-changelog
 299 #  [indicates that output of dpkg-parsechangelog follows]
 300 #  > data-block NBYTES
 301 #  > [NBYTES bytes of data (no newline)]
 302 #  [maybe some more blocks]
 303 #  > data-end
 304 #
 305 #  > file dsc
 306 #  [etc]
 307 #
 308 #  > file changes
 309 #  [etc]
 310 #
 311 #  > param head DGIT-VIEW-HEAD
 312 #  > param csuite SUITE
 313 #  > param tagformat old|new
 314 #  > param maint-view MAINT-VIEW-HEAD
 315 #
 316 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 317 #                                     # goes into tag, for replay prevention
 318 #
 319 #  > want signed-tag
 320 #  [indicates that signed tag is wanted]
 321 #  < data-block NBYTES
 322 #  < [NBYTES bytes of data (no newline)]
 323 #  [maybe some more blocks]
 324 #  < data-end
 325 #  < files-end
 326 #
 327 #  > want signed-dsc-changes
 328 #  < data-block NBYTES    [transfer of signed dsc]
 329 #  [etc]
 330 #  < data-block NBYTES    [transfer of signed changes]
 331 #  [etc]
 332 #  < files-end
 333 #
 334 #  > complete
 335
 336 our $i_child_pid;
 337
 338 sub i_child_report () {
 339     # Sees if our child has died, and reap it if so.  Returns a string
 340     # describing how it died if it failed, or undef otherwise.
 341     return undef unless $i_child_pid;
 342     my $got = waitpid $i_child_pid, WNOHANG;
 343     return undef if $got <= 0;
 344     die unless $got == $i_child_pid;
 345     $i_child_pid = undef;
 346     return undef unless $?;
 347     return "build host child ".waitstatusmsg();
 348 }
 349
 350 sub badproto ($$) {
 351     my ($fh, $m) = @_;
 352     fail "connection lost: $!" if $fh->error;
 353     fail "protocol violation; $m not expected";
 354 }
 355
 356 sub badproto_badread ($$) {
 357     my ($fh, $wh) = @_;
 358     fail "connection lost: $!" if $!;
 359     my $report = i_child_report();
 360     fail $report if defined $report;
 361     badproto $fh, "eof (reading $wh)";
 362 }
 363
 364 sub protocol_expect (&$) {
 365     my ($match, $fh) = @_;
 366     local $_;
 367     $_ = <$fh>;
 368     defined && chomp or badproto_badread $fh, "protocol message";
 369     if (wantarray) {
 370         my @r = &$match;
 371         return @r if @r;
 372     } else {
 373         my $r = &$match;
 374         return $r if $r;
 375     }
 376     badproto $fh, "\`$_'";
 377 }
 378
 379 sub protocol_send_file ($$) {
 380     my ($fh, $ourfn) = @_;
 381     open PF, "<", $ourfn or die "$ourfn: $!";
 382     for (;;) {
 383         my $d;
 384         my $got = read PF, $d, 65536;
 385         die "$ourfn: $!" unless defined $got;
 386         last if !$got;
 387         print $fh "data-block ".length($d)."\n" or die $!;
 388         print $fh $d or die $!;
 389     }
 390     PF->error and die "$ourfn $!";
 391     print $fh "data-end\n" or die $!;
 392     close PF;
 393 }
 394
 395 sub protocol_read_bytes ($$) {
 396     my ($fh, $nbytes) = @_;
 397     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 398     my $d;
 399     my $got = read $fh, $d, $nbytes;
 400     $got==$nbytes or badproto_badread $fh, "data block";
 401     return $d;
 402 }
 403
 404 sub protocol_receive_file ($$) {
 405     my ($fh, $ourfn) = @_;
 406     printdebug "() $ourfn\n";
 407     open PF, ">", $ourfn or die "$ourfn: $!";
 408     for (;;) {
 409         my ($y,$l) = protocol_expect {
 410             m/^data-block (.*)$/ ? (1,$1) :
 411             m/^data-end$/ ? (0,) :
 412             ();
 413         } $fh;
 414         last unless $y;
 415         my $d = protocol_read_bytes $fh, $l;
 416         print PF $d or die $!;
 417     }
 418     close PF or die $!;
 419 }
 420
 421 #---------- remote protocol support, responder ----------
 422
 423 sub responder_send_command ($) {
 424     my ($command) = @_;
 425     return unless $we_are_responder;
 426     # called even without $we_are_responder
 427     printdebug ">> $command\n";
 428     print PO $command, "\n" or die $!;
 429 }
 430
 431 sub responder_send_file ($$) {
 432     my ($keyword, $ourfn) = @_;
 433     return unless $we_are_responder;
 434     printdebug "]] $keyword $ourfn\n";
 435     responder_send_command "file $keyword";
 436     protocol_send_file \*PO, $ourfn;
 437 }
 438
 439 sub responder_receive_files ($@) {
 440     my ($keyword, @ourfns) = @_;
 441     die unless $we_are_responder;
 442     printdebug "[[ $keyword @ourfns\n";
 443     responder_send_command "want $keyword";
 444     foreach my $fn (@ourfns) {
 445         protocol_receive_file \*PI, $fn;
 446     }
 447     printdebug "[[\$\n";
 448     protocol_expect { m/^files-end$/ } \*PI;
 449 }
 450
 451 #---------- remote protocol support, initiator ----------
 452
 453 sub initiator_expect (&) {
 454     my ($match) = @_;
 455     protocol_expect { &$match } \*RO;
 456 }
 457
 458 #---------- end remote code ----------
 459
 460 sub progress {
 461     if ($we_are_responder) {
 462         my $m = join '', @_;
 463         responder_send_command "progress ".length($m) or die $!;
 464         print PO $m or die $!;
 465     } else {
 466         print @_, "\n";
 467     }
 468 }
 469
 470 our $ua;
 471
 472 sub url_get {
 473     if (!$ua) {
 474         $ua = LWP::UserAgent->new();
 475         $ua->env_proxy;
 476     }
 477     my $what = $_[$#_];
 478     progress "downloading $what...";
 479     my $r = $ua->get(@_) or die $!;
 480     return undef if $r->code == 404;
 481     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 482     return $r->decoded_content(charset => 'none');
 483 }
 484
 485 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 486
 487 sub runcmd {
 488     debugcmd "+",@_;
 489     $!=0; $?=-1;
 490     failedcmd @_ if system @_;
 491 }
 492
 493 sub act_local () { return $dryrun_level <= 1; }
 494 sub act_scary () { return !$dryrun_level; }
 495
 496 sub printdone {
 497     if (!$dryrun_level) {
 498         progress "$us ok: @_";
 499     } else {
 500         progress "would be ok: @_ (but dry run only)";
 501     }
 502 }
 503
 504 sub dryrun_report {
 505     printcmd(\*STDERR,$debugprefix."#",@_);
 506 }
 507
 508 sub runcmd_ordryrun {
 509     if (act_scary()) {
 510         runcmd @_;
 511     } else {
 512         dryrun_report @_;
 513     }
 514 }
 515
 516 sub runcmd_ordryrun_local {
 517     if (act_local()) {
 518         runcmd @_;
 519     } else {
 520         dryrun_report @_;
 521     }
 522 }
 523
 524 sub shell_cmd {
 525     my ($first_shell, @cmd) = @_;
 526     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 527 }
 528
 529 our $helpmsg = <<END;
 530 main usages:
 531   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 532   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 533   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 534   dgit [dgit-opts] sbuild [sbuild-opts]
 535   dgit [dgit-opts] push [dgit-opts] [suite]
 536   dgit [dgit-opts] rpush build-host:build-dir ...
 537 important dgit options:
 538   -k<keyid>           sign tag and package with <keyid> instead of default
 539   --dry-run -n        do not change anything, but go through the motions
 540   --damp-run -L       like --dry-run but make local changes, without signing
 541   --new -N            allow introducing a new package
 542   --debug -D          increase debug level
 543   -c<name>=<value>    set git config option (used directly by dgit too)
 544 END
 545
 546 our $later_warning_msg = <<END;
 547 Perhaps the upload is stuck in incoming.  Using the version from git.
 548 END
 549
 550 sub badusage {
 551     print STDERR "$us: @_\n", $helpmsg or die $!;
 552     exit 8;
 553 }
 554
 555 sub nextarg {
 556     @ARGV or badusage "too few arguments";
 557     return scalar shift @ARGV;
 558 }
 559
 560 sub cmd_help () {
 561     print $helpmsg or die $!;
 562     exit 0;
 563 }
 564
 565 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 566
 567 our %defcfg = ('dgit.default.distro' => 'debian',
 568                'dgit-suite.*-security.distro' => 'debian-security',
 569                'dgit.default.username' => '',
 570                'dgit.default.archive-query-default-component' => 'main',
 571                'dgit.default.ssh' => 'ssh',
 572                'dgit.default.archive-query' => 'madison:',
 573                'dgit.default.sshpsql-dbname' => 'service=projectb',
 574                'dgit.default.aptget-components' => 'main',
 575                'dgit.default.dgit-tag-format' => 'new,old,maint',
 576                'dgit.dsc-url-proto-ok.http'    => 'true',
 577                'dgit.dsc-url-proto-ok.https'   => 'true',
 578                'dgit.dsc-url-proto-ok.git'     => 'true',
 579                'dgit.default.dsc-url-proto-ok' => 'false',
 580                # old means "repo server accepts pushes with old dgit tags"
 581                # new means "repo server accepts pushes with new dgit tags"
 582                # maint means "repo server accepts split brain pushes"
 583                # hist means "repo server may have old pushes without new tag"
 584                #   ("hist" is implied by "old")
 585                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 586                'dgit-distro.debian.git-check' => 'url',
 587                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 588                'dgit-distro.debian.new-private-pushers' => 't',
 589                'dgit-distro.debian/push.git-url' => '',
 590                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 591                'dgit-distro.debian/push.git-user-force' => 'dgit',
 592                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 593                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 594                'dgit-distro.debian/push.git-create' => 'true',
 595                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 596  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 597 # 'dgit-distro.debian.archive-query-tls-key',
 598 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 599 # ^ this does not work because curl is broken nowadays
 600 # Fixing #790093 properly will involve providing providing the key
 601 # in some pacagke and maybe updating these paths.
 602 #
 603 # 'dgit-distro.debian.archive-query-tls-curl-args',
 604 #   '--ca-path=/etc/ssl/ca-debian',
 605 # ^ this is a workaround but works (only) on DSA-administered machines
 606                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 607                'dgit-distro.debian.git-url-suffix' => '',
 608                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 609                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 610  'dgit-distro.debian-security.archive-query' => 'aptget:',
 611  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 612  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 613  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 614  'dgit-distro.debian-security.nominal-distro' => 'debian',
 615  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 616  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 617                'dgit-distro.ubuntu.git-check' => 'false',
 618  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 619                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 620                'dgit-distro.test-dummy.username' => "alice",
 621                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 622                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 623                'dgit-distro.test-dummy.git-url' => "$td/git",
 624                'dgit-distro.test-dummy.git-host' => "git",
 625                'dgit-distro.test-dummy.git-path' => "$td/git",
 626                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 627                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 628                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 629                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 630                );
 631
 632 our %gitcfgs;
 633 our @gitcfgsources = qw(cmdline local global system);
 634
 635 sub git_slurp_config () {
 636     local ($debuglevel) = $debuglevel-2;
 637     local $/="\0";
 638
 639     # This algoritm is a bit subtle, but this is needed so that for
 640     # options which we want to be single-valued, we allow the
 641     # different config sources to override properly.  See #835858.
 642     foreach my $src (@gitcfgsources) {
 643         next if $src eq 'cmdline';
 644         # we do this ourselves since git doesn't handle it
 645
 646         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 647         debugcmd "|",@cmd;
 648
 649         open GITS, "-|", @cmd or die $!;
 650         while (<GITS>) {
 651             chomp or die;
 652             printdebug "=> ", (messagequote $_), "\n";
 653             m/\n/ or die "$_ ?";
 654             push @{ $gitcfgs{$src}{$`} }, $'; #';
 655         }
 656         $!=0; $?=0;
 657         close GITS
 658             or ($!==0 && $?==256)
 659             or failedcmd @cmd;
 660     }
 661 }
 662
 663 sub git_get_config ($) {
 664     my ($c) = @_;
 665     foreach my $src (@gitcfgsources) {
 666         my $l = $gitcfgs{$src}{$c};
 667         printdebug"C $c ".(defined $l ?
 668                            join " ", map { messagequote "'$_'" } @$l :
 669                            "undef")."\n"
 670             if $debuglevel >= 4;
 671         $l or next;
 672         @$l==1 or badcfg "multiple values for $c".
 673             " (in $src git config)" if @$l > 1;
 674         return $l->[0];
 675     }
 676     return undef;
 677 }
 678
 679 sub cfg {
 680     foreach my $c (@_) {
 681         return undef if $c =~ /RETURN-UNDEF/;
 682         my $v = git_get_config($c);
 683         return $v if defined $v;
 684         my $dv = $defcfg{$c};
 685         if (defined $dv) {
 686             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 687             return $dv;
 688         }
 689     }
 690     badcfg "need value for one of: @_\n".
 691         "$us: distro or suite appears not to be (properly) supported";
 692 }
 693
 694 sub access_basedistro () {
 695     if (defined $idistro) {
 696         return $idistro;
 697     } else {
 698         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 699         return $def if defined $def;
 700         foreach my $src (@gitcfgsources, 'internal') {
 701             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 702             next unless $kl;
 703             foreach my $k (keys %$kl) {
 704                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 705                 my $dpat = $1;
 706                 next unless match_glob $dpat, $isuite;
 707                 return $kl->{$k};
 708             }
 709         }
 710         return cfg("dgit.default.distro");
 711     }
 712 }
 713
 714 sub access_nomdistro () {
 715     my $base = access_basedistro();
 716     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 717     $r =~ m/^$distro_re$/ or badcfg
 718  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 719     return $r;
 720 }
 721
 722 sub access_quirk () {
 723     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 724     my $basedistro = access_basedistro();
 725     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 726                               'RETURN-UNDEF');
 727     if (defined $backports_quirk) {
 728         my $re = $backports_quirk;
 729         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 730         $re =~ s/\*/.*/g;
 731         $re =~ s/\%/([-0-9a-z_]+)/
 732             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 733         if ($isuite =~ m/^$re$/) {
 734             return ('backports',"$basedistro-backports",$1);
 735         }
 736     }
 737     return ('none',undef);
 738 }
 739
 740 our $access_forpush;
 741
 742 sub parse_cfg_bool ($$$) {
 743     my ($what,$def,$v) = @_;
 744     $v //= $def;
 745     return
 746         $v =~ m/^[ty1]/ ? 1 :
 747         $v =~ m/^[fn0]/ ? 0 :
 748         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 749 }
 750
 751 sub access_forpush_config () {
 752     my $d = access_basedistro();
 753
 754     return 1 if
 755         $new_package &&
 756         parse_cfg_bool('new-private-pushers', 0,
 757                        cfg("dgit-distro.$d.new-private-pushers",
 758                            'RETURN-UNDEF'));
 759
 760     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 761     $v //= 'a';
 762     return
 763         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 764         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 765         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 766         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 767 }
 768
 769 sub access_forpush () {
 770     $access_forpush //= access_forpush_config();
 771     return $access_forpush;
 772 }
 773
 774 sub pushing () {
 775     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 776     badcfg "pushing but distro is configured readonly"
 777         if access_forpush_config() eq '0';
 778     $access_forpush = 1;
 779     $supplementary_message = <<'END' unless $we_are_responder;
 780 Push failed, before we got started.
 781 You can retry the push, after fixing the problem, if you like.
 782 END
 783     parseopts_late_defaults();
 784 }
 785
 786 sub notpushing () {
 787     parseopts_late_defaults();
 788 }
 789
 790 sub supplementary_message ($) {
 791     my ($msg) = @_;
 792     if (!$we_are_responder) {
 793         $supplementary_message = $msg;
 794         return;
 795     } elsif ($protovsn >= 3) {
 796         responder_send_command "supplementary-message ".length($msg)
 797             or die $!;
 798         print PO $msg or die $!;
 799     }
 800 }
 801
 802 sub access_distros () {
 803     # Returns list of distros to try, in order
 804     #
 805     # We want to try:
 806     #    0. `instead of' distro name(s) we have been pointed to
 807     #    1. the access_quirk distro, if any
 808     #    2a. the user's specified distro, or failing that  } basedistro
 809     #    2b. the distro calculated from the suite          }
 810     my @l = access_basedistro();
 811
 812     my (undef,$quirkdistro) = access_quirk();
 813     unshift @l, $quirkdistro;
 814     unshift @l, $instead_distro;
 815     @l = grep { defined } @l;
 816
 817     push @l, access_nomdistro();
 818
 819     if (access_forpush()) {
 820         @l = map { ("$_/push", $_) } @l;
 821     }
 822     @l;
 823 }
 824
 825 sub access_cfg_cfgs (@) {
 826     my (@keys) = @_;
 827     my @cfgs;
 828     # The nesting of these loops determines the search order.  We put
 829     # the key loop on the outside so that we search all the distros
 830     # for each key, before going on to the next key.  That means that
 831     # if access_cfg is called with a more specific, and then a less
 832     # specific, key, an earlier distro can override the less specific
 833     # without necessarily overriding any more specific keys.  (If the
 834     # distro wants to override the more specific keys it can simply do
 835     # so; whereas if we did the loop the other way around, it would be
 836     # impossible to for an earlier distro to override a less specific
 837     # key but not the more specific ones without restating the unknown
 838     # values of the more specific keys.
 839     my @realkeys;
 840     my @rundef;
 841     # We have to deal with RETURN-UNDEF specially, so that we don't
 842     # terminate the search prematurely.
 843     foreach (@keys) {
 844         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 845         push @realkeys, $_
 846     }
 847     foreach my $d (access_distros()) {
 848         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 849     }
 850     push @cfgs, map { "dgit.default.$_" } @realkeys;
 851     push @cfgs, @rundef;
 852     return @cfgs;
 853 }
 854
 855 sub access_cfg (@) {
 856     my (@keys) = @_;
 857     my (@cfgs) = access_cfg_cfgs(@keys);
 858     my $value = cfg(@cfgs);
 859     return $value;
 860 }
 861
 862 sub access_cfg_bool ($$) {
 863     my ($def, @keys) = @_;
 864     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 865 }
 866
 867 sub string_to_ssh ($) {
 868     my ($spec) = @_;
 869     if ($spec =~ m/\s/) {
 870         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 871     } else {
 872         return ($spec);
 873     }
 874 }
 875
 876 sub access_cfg_ssh () {
 877     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 878     if (!defined $gitssh) {
 879         return @ssh;
 880     } else {
 881         return string_to_ssh $gitssh;
 882     }
 883 }
 884
 885 sub access_runeinfo ($) {
 886     my ($info) = @_;
 887     return ": dgit ".access_basedistro()." $info ;";
 888 }
 889
 890 sub access_someuserhost ($) {
 891     my ($some) = @_;
 892     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 893     defined($user) && length($user) or
 894         $user = access_cfg("$some-user",'username');
 895     my $host = access_cfg("$some-host");
 896     return length($user) ? "$user\@$host" : $host;
 897 }
 898
 899 sub access_gituserhost () {
 900     return access_someuserhost('git');
 901 }
 902
 903 sub access_giturl (;$) {
 904     my ($optional) = @_;
 905     my $url = access_cfg('git-url','RETURN-UNDEF');
 906     my $suffix;
 907     if (!length $url) {
 908         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 909         return undef unless defined $proto;
 910         $url =
 911             $proto.
 912             access_gituserhost().
 913             access_cfg('git-path');
 914     } else {
 915         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 916     }
 917     $suffix //= '.git';
 918     return "$url/$package$suffix";
 919 }
 920
 921 sub parsecontrolfh ($$;$) {
 922     my ($fh, $desc, $allowsigned) = @_;
 923     our $dpkgcontrolhash_noissigned;
 924     my $c;
 925     for (;;) {
 926         my %opts = ('name' => $desc);
 927         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 928         $c = Dpkg::Control::Hash->new(%opts);
 929         $c->parse($fh,$desc) or die "parsing of $desc failed";
 930         last if $allowsigned;
 931         last if $dpkgcontrolhash_noissigned;
 932         my $issigned= $c->get_option('is_pgp_signed');
 933         if (!defined $issigned) {
 934             $dpkgcontrolhash_noissigned= 1;
 935             seek $fh, 0,0 or die "seek $desc: $!";
 936         } elsif ($issigned) {
 937             fail "control file $desc is (already) PGP-signed. ".
 938                 " Note that dgit push needs to modify the .dsc and then".
 939                 " do the signature itself";
 940         } else {
 941             last;
 942         }
 943     }
 944     return $c;
 945 }
 946
 947 sub parsecontrol {
 948     my ($file, $desc, $allowsigned) = @_;
 949     my $fh = new IO::Handle;
 950     open $fh, '<', $file or die "$file: $!";
 951     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 952     $fh->error and die $!;
 953     close $fh;
 954     return $c;
 955 }
 956
 957 sub getfield ($$) {
 958     my ($dctrl,$field) = @_;
 959     my $v = $dctrl->{$field};
 960     return $v if defined $v;
 961     fail "missing field $field in ".$dctrl->get_option('name');
 962 }
 963
 964 sub parsechangelog {
 965     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 966     my $p = new IO::Handle;
 967     my @cmd = (qw(dpkg-parsechangelog), @_);
 968     open $p, '-|', @cmd or die $!;
 969     $c->parse($p);
 970     $?=0; $!=0; close $p or failedcmd @cmd;
 971     return $c;
 972 }
 973
 974 sub commit_getclogp ($) {
 975     # Returns the parsed changelog hashref for a particular commit
 976     my ($objid) = @_;
 977     our %commit_getclogp_memo;
 978     my $memo = $commit_getclogp_memo{$objid};
 979     return $memo if $memo;
 980     mkpath '.git/dgit';
 981     my $mclog = ".git/dgit/clog-$objid";
 982     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 983         "$objid:debian/changelog";
 984     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 985 }
 986
 987 sub must_getcwd () {
 988     my $d = getcwd();
 989     defined $d or fail "getcwd failed: $!";
 990     return $d;
 991 }
 992
 993 sub parse_dscdata () {
 994     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 995     printdebug Dumper($dscdata) if $debuglevel>1;
 996     $dsc = parsecontrolfh($dscfh,$dscurl,1);
 997     printdebug Dumper($dsc) if $debuglevel>1;
 998 }
 999
1000 our %rmad;
1001
1002 sub archive_query ($;@) {
1003     my ($method) = shift @_;
1004     fail "this operation does not support multiple comma-separated suites"
1005         if $isuite =~ m/,/;
1006     my $query = access_cfg('archive-query','RETURN-UNDEF');
1007     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1008     my $proto = $1;
1009     my $data = $'; #';
1010     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1011 }
1012
1013 sub archive_query_prepend_mirror {
1014     my $m = access_cfg('mirror');
1015     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1016 }
1017
1018 sub pool_dsc_subpath ($$) {
1019     my ($vsn,$component) = @_; # $package is implict arg
1020     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1021     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1022 }
1023
1024 sub cfg_apply_map ($$$) {
1025     my ($varref, $what, $mapspec) = @_;
1026     return unless $mapspec;
1027
1028     printdebug "config $what EVAL{ $mapspec; }\n";
1029     $_ = $$varref;
1030     eval "package Dgit::Config; $mapspec;";
1031     die $@ if $@;
1032     $$varref = $_;
1033 }
1034
1035 #---------- `ftpmasterapi' archive query method (nascent) ----------
1036
1037 sub archive_api_query_cmd ($) {
1038     my ($subpath) = @_;
1039     my @cmd = (@curl, qw(-sS));
1040     my $url = access_cfg('archive-query-url');
1041     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1042         my $host = $1;
1043         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1044         foreach my $key (split /\:/, $keys) {
1045             $key =~ s/\%HOST\%/$host/g;
1046             if (!stat $key) {
1047                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1048                 next;
1049             }
1050             fail "config requested specific TLS key but do not know".
1051                 " how to get curl to use exactly that EE key ($key)";
1052 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1053 #           # Sadly the above line does not work because of changes
1054 #           # to gnutls.   The real fix for #790093 may involve
1055 #           # new curl options.
1056             last;
1057         }
1058         # Fixing #790093 properly will involve providing a value
1059         # for this on clients.
1060         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1061         push @cmd, split / /, $kargs if defined $kargs;
1062     }
1063     push @cmd, $url.$subpath;
1064     return @cmd;
1065 }
1066
1067 sub api_query ($$;$) {
1068     use JSON;
1069     my ($data, $subpath, $ok404) = @_;
1070     badcfg "ftpmasterapi archive query method takes no data part"
1071         if length $data;
1072     my @cmd = archive_api_query_cmd($subpath);
1073     my $url = $cmd[$#cmd];
1074     push @cmd, qw(-w %{http_code});
1075     my $json = cmdoutput @cmd;
1076     unless ($json =~ s/\d+\d+\d$//) {
1077         failedcmd_report_cmd undef, @cmd;
1078         fail "curl failed to print 3-digit HTTP code";
1079     }
1080     my $code = $&;
1081     return undef if $code eq '404' && $ok404;
1082     fail "fetch of $url gave HTTP code $code"
1083         unless $url =~ m#^file://# or $code =~ m/^2/;
1084     return decode_json($json);
1085 }
1086
1087 sub canonicalise_suite_ftpmasterapi {
1088     my ($proto,$data) = @_;
1089     my $suites = api_query($data, 'suites');
1090     my @matched;
1091     foreach my $entry (@$suites) {
1092         next unless grep {
1093             my $v = $entry->{$_};
1094             defined $v && $v eq $isuite;
1095         } qw(codename name);
1096         push @matched, $entry;
1097     }
1098     fail "unknown suite $isuite" unless @matched;
1099     my $cn;
1100     eval {
1101         @matched==1 or die "multiple matches for suite $isuite\n";
1102         $cn = "$matched[0]{codename}";
1103         defined $cn or die "suite $isuite info has no codename\n";
1104         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1105     };
1106     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1107         if length $@;
1108     return $cn;
1109 }
1110
1111 sub archive_query_ftpmasterapi {
1112     my ($proto,$data) = @_;
1113     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1114     my @rows;
1115     my $digester = Digest::SHA->new(256);
1116     foreach my $entry (@$info) {
1117         eval {
1118             my $vsn = "$entry->{version}";
1119             my ($ok,$msg) = version_check $vsn;
1120             die "bad version: $msg\n" unless $ok;
1121             my $component = "$entry->{component}";
1122             $component =~ m/^$component_re$/ or die "bad component";
1123             my $filename = "$entry->{filename}";
1124             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1125                 or die "bad filename";
1126             my $sha256sum = "$entry->{sha256sum}";
1127             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1128             push @rows, [ $vsn, "/pool/$component/$filename",
1129                           $digester, $sha256sum ];
1130         };
1131         die "bad ftpmaster api response: $@\n".Dumper($entry)
1132             if length $@;
1133     }
1134     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1135     return archive_query_prepend_mirror @rows;
1136 }
1137
1138 sub file_in_archive_ftpmasterapi {
1139     my ($proto,$data,$filename) = @_;
1140     my $pat = $filename;
1141     $pat =~ s/_/\\_/g;
1142     $pat = "%/$pat";
1143     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1144     my $info = api_query($data, "file_in_archive/$pat", 1);
1145 }
1146
1147 #---------- `aptget' archive query method ----------
1148
1149 our $aptget_base;
1150 our $aptget_releasefile;
1151 our $aptget_configpath;
1152
1153 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1154 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1155
1156 sub aptget_cache_clean {
1157     runcmd_ordryrun_local qw(sh -ec),
1158         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1159         'x', $aptget_base;
1160 }
1161
1162 sub aptget_lock_acquire () {
1163     my $lockfile = "$aptget_base/lock";
1164     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1165     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1166 }
1167
1168 sub aptget_prep ($) {
1169     my ($data) = @_;
1170     return if defined $aptget_base;
1171
1172     badcfg "aptget archive query method takes no data part"
1173         if length $data;
1174
1175     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1176
1177     ensuredir $cache;
1178     ensuredir "$cache/dgit";
1179     my $cachekey =
1180         access_cfg('aptget-cachekey','RETURN-UNDEF')
1181         // access_nomdistro();
1182
1183     $aptget_base = "$cache/dgit/aptget";
1184     ensuredir $aptget_base;
1185
1186     my $quoted_base = $aptget_base;
1187     die "$quoted_base contains bad chars, cannot continue"
1188         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1189
1190     ensuredir $aptget_base;
1191
1192     aptget_lock_acquire();
1193
1194     aptget_cache_clean();
1195
1196     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1197     my $sourceslist = "source.list#$cachekey";
1198
1199     my $aptsuites = $isuite;
1200     cfg_apply_map(\$aptsuites, 'suite map',
1201                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1202
1203     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1204     printf SRCS "deb-src %s %s %s\n",
1205         access_cfg('mirror'),
1206         $aptsuites,
1207         access_cfg('aptget-components')
1208         or die $!;
1209
1210     ensuredir "$aptget_base/cache";
1211     ensuredir "$aptget_base/lists";
1212
1213     open CONF, ">", $aptget_configpath or die $!;
1214     print CONF <<END;
1215 Debug::NoLocking "true";
1216 APT::Get::List-Cleanup "false";
1217 #clear APT::Update::Post-Invoke-Success;
1218 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1219 Dir::State::Lists "$quoted_base/lists";
1220 Dir::Etc::preferences "$quoted_base/preferences";
1221 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1222 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1223 END
1224
1225     foreach my $key (qw(
1226                         Dir::Cache
1227                         Dir::State
1228                         Dir::Cache::Archives
1229                         Dir::Etc::SourceParts
1230                         Dir::Etc::preferencesparts
1231                       )) {
1232         ensuredir "$aptget_base/$key";
1233         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1234     };
1235
1236     my $oldatime = (time // die $!) - 1;
1237     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1238         next unless stat_exists $oldlist;
1239         my ($mtime) = (stat _)[9];
1240         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1241     }
1242
1243     runcmd_ordryrun_local aptget_aptget(), qw(update);
1244
1245     my @releasefiles;
1246     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1247         next unless stat_exists $oldlist;
1248         my ($atime) = (stat _)[8];
1249         next if $atime == $oldatime;
1250         push @releasefiles, $oldlist;
1251     }
1252     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1253     @releasefiles = @inreleasefiles if @inreleasefiles;
1254     die "apt updated wrong number of Release files (@releasefiles), erk"
1255         unless @releasefiles == 1;
1256
1257     ($aptget_releasefile) = @releasefiles;
1258 }
1259
1260 sub canonicalise_suite_aptget {
1261     my ($proto,$data) = @_;
1262     aptget_prep($data);
1263
1264     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1265
1266     foreach my $name (qw(Codename Suite)) {
1267         my $val = $release->{$name};
1268         if (defined $val) {
1269             printdebug "release file $name: $val\n";
1270             $val =~ m/^$suite_re$/o or fail
1271  "Release file ($aptget_releasefile) specifies intolerable $name";
1272             cfg_apply_map(\$val, 'suite rmap',
1273                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1274             return $val
1275         }
1276     }
1277     return $isuite;
1278 }
1279
1280 sub archive_query_aptget {
1281     my ($proto,$data) = @_;
1282     aptget_prep($data);
1283
1284     ensuredir "$aptget_base/source";
1285     foreach my $old (<$aptget_base/source/*.dsc>) {
1286         unlink $old or die "$old: $!";
1287     }
1288
1289     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1290     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1291     # avoids apt-get source failing with ambiguous error code
1292
1293     runcmd_ordryrun_local
1294         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1295         aptget_aptget(), qw(--download-only --only-source source), $package;
1296
1297     my @dscs = <$aptget_base/source/*.dsc>;
1298     fail "apt-get source did not produce a .dsc" unless @dscs;
1299     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1300
1301     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1302
1303     use URI::Escape;
1304     my $uri = "file://". uri_escape $dscs[0];
1305     $uri =~ s{\%2f}{/}gi;
1306     return [ (getfield $pre_dsc, 'Version'), $uri ];
1307 }
1308
1309 #---------- `dummyapicat' archive query method ----------
1310
1311 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1312 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1313
1314 sub file_in_archive_dummycatapi ($$$) {
1315     my ($proto,$data,$filename) = @_;
1316     my $mirror = access_cfg('mirror');
1317     $mirror =~ s#^file://#/# or die "$mirror ?";
1318     my @out;
1319     my @cmd = (qw(sh -ec), '
1320             cd "$1"
1321             find -name "$2" -print0 |
1322             xargs -0r sha256sum
1323         ', qw(x), $mirror, $filename);
1324     debugcmd "-|", @cmd;
1325     open FIA, "-|", @cmd or die $!;
1326     while (<FIA>) {
1327         chomp or die;
1328         printdebug "| $_\n";
1329         m/^(\w+)  (\S+)$/ or die "$_ ?";
1330         push @out, { sha256sum => $1, filename => $2 };
1331     }
1332     close FIA or die failedcmd @cmd;
1333     return \@out;
1334 }
1335
1336 #---------- `madison' archive query method ----------
1337
1338 sub archive_query_madison {
1339     return archive_query_prepend_mirror
1340         map { [ @$_[0..1] ] } madison_get_parse(@_);
1341 }
1342
1343 sub madison_get_parse {
1344     my ($proto,$data) = @_;
1345     die unless $proto eq 'madison';
1346     if (!length $data) {
1347         $data= access_cfg('madison-distro','RETURN-UNDEF');
1348         $data //= access_basedistro();
1349     }
1350     $rmad{$proto,$data,$package} ||= cmdoutput
1351         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1352     my $rmad = $rmad{$proto,$data,$package};
1353
1354     my @out;
1355     foreach my $l (split /\n/, $rmad) {
1356         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1357                   \s*( [^ \t|]+ )\s* \|
1358                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1359                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1360         $1 eq $package or die "$rmad $package ?";
1361         my $vsn = $2;
1362         my $newsuite = $3;
1363         my $component;
1364         if (defined $4) {
1365             $component = $4;
1366         } else {
1367             $component = access_cfg('archive-query-default-component');
1368         }
1369         $5 eq 'source' or die "$rmad ?";
1370         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1371     }
1372     return sort { -version_compare($a->[0],$b->[0]); } @out;
1373 }
1374
1375 sub canonicalise_suite_madison {
1376     # madison canonicalises for us
1377     my @r = madison_get_parse(@_);
1378     @r or fail
1379         "unable to canonicalise suite using package $package".
1380         " which does not appear to exist in suite $isuite;".
1381         " --existing-package may help";
1382     return $r[0][2];
1383 }
1384
1385 sub file_in_archive_madison { return undef; }
1386
1387 #---------- `sshpsql' archive query method ----------
1388
1389 sub sshpsql ($$$) {
1390     my ($data,$runeinfo,$sql) = @_;
1391     if (!length $data) {
1392         $data= access_someuserhost('sshpsql').':'.
1393             access_cfg('sshpsql-dbname');
1394     }
1395     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1396     my ($userhost,$dbname) = ($`,$'); #';
1397     my @rows;
1398     my @cmd = (access_cfg_ssh, $userhost,
1399                access_runeinfo("ssh-psql $runeinfo").
1400                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1401                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1402     debugcmd "|",@cmd;
1403     open P, "-|", @cmd or die $!;
1404     while (<P>) {
1405         chomp or die;
1406         printdebug(">|$_|\n");
1407         push @rows, $_;
1408     }
1409     $!=0; $?=0; close P or failedcmd @cmd;
1410     @rows or die;
1411     my $nrows = pop @rows;
1412     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1413     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1414     @rows = map { [ split /\|/, $_ ] } @rows;
1415     my $ncols = scalar @{ shift @rows };
1416     die if grep { scalar @$_ != $ncols } @rows;
1417     return @rows;
1418 }
1419
1420 sub sql_injection_check {
1421     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1422 }
1423
1424 sub archive_query_sshpsql ($$) {
1425     my ($proto,$data) = @_;
1426     sql_injection_check $isuite, $package;
1427     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1428         SELECT source.version, component.name, files.filename, files.sha256sum
1429           FROM source
1430           JOIN src_associations ON source.id = src_associations.source
1431           JOIN suite ON suite.id = src_associations.suite
1432           JOIN dsc_files ON dsc_files.source = source.id
1433           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1434           JOIN component ON component.id = files_archive_map.component_id
1435           JOIN files ON files.id = dsc_files.file
1436          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1437            AND source.source='$package'
1438            AND files.filename LIKE '%.dsc';
1439 END
1440     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1441     my $digester = Digest::SHA->new(256);
1442     @rows = map {
1443         my ($vsn,$component,$filename,$sha256sum) = @$_;
1444         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1445     } @rows;
1446     return archive_query_prepend_mirror @rows;
1447 }
1448
1449 sub canonicalise_suite_sshpsql ($$) {
1450     my ($proto,$data) = @_;
1451     sql_injection_check $isuite;
1452     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1453         SELECT suite.codename
1454           FROM suite where suite_name='$isuite' or codename='$isuite';
1455 END
1456     @rows = map { $_->[0] } @rows;
1457     fail "unknown suite $isuite" unless @rows;
1458     die "ambiguous $isuite: @rows ?" if @rows>1;
1459     return $rows[0];
1460 }
1461
1462 sub file_in_archive_sshpsql ($$$) { return undef; }
1463
1464 #---------- `dummycat' archive query method ----------
1465
1466 sub canonicalise_suite_dummycat ($$) {
1467     my ($proto,$data) = @_;
1468     my $dpath = "$data/suite.$isuite";
1469     if (!open C, "<", $dpath) {
1470         $!==ENOENT or die "$dpath: $!";
1471         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1472         return $isuite;
1473     }
1474     $!=0; $_ = <C>;
1475     chomp or die "$dpath: $!";
1476     close C;
1477     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1478     return $_;
1479 }
1480
1481 sub archive_query_dummycat ($$) {
1482     my ($proto,$data) = @_;
1483     canonicalise_suite();
1484     my $dpath = "$data/package.$csuite.$package";
1485     if (!open C, "<", $dpath) {
1486         $!==ENOENT or die "$dpath: $!";
1487         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1488         return ();
1489     }
1490     my @rows;
1491     while (<C>) {
1492         next if m/^\#/;
1493         next unless m/\S/;
1494         die unless chomp;
1495         printdebug "dummycat query $csuite $package $dpath | $_\n";
1496         my @row = split /\s+/, $_;
1497         @row==2 or die "$dpath: $_ ?";
1498         push @rows, \@row;
1499     }
1500     C->error and die "$dpath: $!";
1501     close C;
1502     return archive_query_prepend_mirror
1503         sort { -version_compare($a->[0],$b->[0]); } @rows;
1504 }
1505
1506 sub file_in_archive_dummycat () { return undef; }
1507
1508 #---------- tag format handling ----------
1509
1510 sub access_cfg_tagformats () {
1511     split /\,/, access_cfg('dgit-tag-format');
1512 }
1513
1514 sub access_cfg_tagformats_can_splitbrain () {
1515     my %y = map { $_ => 1 } access_cfg_tagformats;
1516     foreach my $needtf (qw(new maint)) {
1517         next if $y{$needtf};
1518         return 0;
1519     }
1520     return 1;
1521 }
1522
1523 sub need_tagformat ($$) {
1524     my ($fmt, $why) = @_;
1525     fail "need to use tag format $fmt ($why) but also need".
1526         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1527         " - no way to proceed"
1528         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1529     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1530 }
1531
1532 sub select_tagformat () {
1533     # sets $tagformatfn
1534     return if $tagformatfn && !$tagformat_want;
1535     die 'bug' if $tagformatfn && $tagformat_want;
1536     # ... $tagformat_want assigned after previous select_tagformat
1537
1538     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1539     printdebug "select_tagformat supported @supported\n";
1540
1541     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1542     printdebug "select_tagformat specified @$tagformat_want\n";
1543
1544     my ($fmt,$why,$override) = @$tagformat_want;
1545
1546     fail "target distro supports tag formats @supported".
1547         " but have to use $fmt ($why)"
1548         unless $override
1549             or grep { $_ eq $fmt } @supported;
1550
1551     $tagformat_want = undef;
1552     $tagformat = $fmt;
1553     $tagformatfn = ${*::}{"debiantag_$fmt"};
1554
1555     fail "trying to use unknown tag format \`$fmt' ($why) !"
1556         unless $tagformatfn;
1557 }
1558
1559 #---------- archive query entrypoints and rest of program ----------
1560
1561 sub canonicalise_suite () {
1562     return if defined $csuite;
1563     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1564     $csuite = archive_query('canonicalise_suite');
1565     if ($isuite ne $csuite) {
1566         progress "canonical suite name for $isuite is $csuite";
1567     } else {
1568         progress "canonical suite name is $csuite";
1569     }
1570 }
1571
1572 sub get_archive_dsc () {
1573     canonicalise_suite();
1574     my @vsns = archive_query('archive_query');
1575     foreach my $vinfo (@vsns) {
1576         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1577         $dscurl = $vsn_dscurl;
1578         $dscdata = url_get($dscurl);
1579         if (!$dscdata) {
1580             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1581             next;
1582         }
1583         if ($digester) {
1584             $digester->reset();
1585             $digester->add($dscdata);
1586             my $got = $digester->hexdigest();
1587             $got eq $digest or
1588                 fail "$dscurl has hash $got but".
1589                     " archive told us to expect $digest";
1590         }
1591         parse_dscdata();
1592         my $fmt = getfield $dsc, 'Format';
1593         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1594             "unsupported source format $fmt, sorry";
1595
1596         $dsc_checked = !!$digester;
1597         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1598         return;
1599     }
1600     $dsc = undef;
1601     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1602 }
1603
1604 sub check_for_git ();
1605 sub check_for_git () {
1606     # returns 0 or 1
1607     my $how = access_cfg('git-check');
1608     if ($how eq 'ssh-cmd') {
1609         my @cmd =
1610             (access_cfg_ssh, access_gituserhost(),
1611              access_runeinfo("git-check $package").
1612              " set -e; cd ".access_cfg('git-path').";".
1613              " if test -d $package.git; then echo 1; else echo 0; fi");
1614         my $r= cmdoutput @cmd;
1615         if (defined $r and $r =~ m/^divert (\w+)$/) {
1616             my $divert=$1;
1617             my ($usedistro,) = access_distros();
1618             # NB that if we are pushing, $usedistro will be $distro/push
1619             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1620             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1621             progress "diverting to $divert (using config for $instead_distro)";
1622             return check_for_git();
1623         }
1624         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1625         return $r+0;
1626     } elsif ($how eq 'url') {
1627         my $prefix = access_cfg('git-check-url','git-url');
1628         my $suffix = access_cfg('git-check-suffix','git-suffix',
1629                                 'RETURN-UNDEF') // '.git';
1630         my $url = "$prefix/$package$suffix";
1631         my @cmd = (@curl, qw(-sS -I), $url);
1632         my $result = cmdoutput @cmd;
1633         $result =~ s/^\S+ 200 .*\n\r?\n//;
1634         # curl -sS -I with https_proxy prints
1635         # HTTP/1.0 200 Connection established
1636         $result =~ m/^\S+ (404|200) /s or
1637             fail "unexpected results from git check query - ".
1638                 Dumper($prefix, $result);
1639         my $code = $1;
1640         if ($code eq '404') {
1641             return 0;
1642         } elsif ($code eq '200') {
1643             return 1;
1644         } else {
1645             die;
1646         }
1647     } elsif ($how eq 'true') {
1648         return 1;
1649     } elsif ($how eq 'false') {
1650         return 0;
1651     } else {
1652         badcfg "unknown git-check \`$how'";
1653     }
1654 }
1655
1656 sub create_remote_git_repo () {
1657     my $how = access_cfg('git-create');
1658     if ($how eq 'ssh-cmd') {
1659         runcmd_ordryrun
1660             (access_cfg_ssh, access_gituserhost(),
1661              access_runeinfo("git-create $package").
1662              "set -e; cd ".access_cfg('git-path').";".
1663              " cp -a _template $package.git");
1664     } elsif ($how eq 'true') {
1665         # nothing to do
1666     } else {
1667         badcfg "unknown git-create \`$how'";
1668     }
1669 }
1670
1671 our ($dsc_hash,$lastpush_mergeinput);
1672 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1673
1674 our $ud = '.git/dgit/unpack';
1675
1676 sub prep_ud (;$) {
1677     my ($d) = @_;
1678     $d //= $ud;
1679     rmtree($d);
1680     mkpath '.git/dgit';
1681     mkdir $d or die $!;
1682 }
1683
1684 sub mktree_in_ud_here () {
1685     runcmd qw(git init -q);
1686     runcmd qw(git config gc.auto 0);
1687     rmtree('.git/objects');
1688     symlink '../../../../objects','.git/objects' or die $!;
1689 }
1690
1691 sub git_write_tree () {
1692     my $tree = cmdoutput @git, qw(write-tree);
1693     $tree =~ m/^\w+$/ or die "$tree ?";
1694     return $tree;
1695 }
1696
1697 sub git_add_write_tree () {
1698     runcmd @git, qw(add -Af .);
1699     return git_write_tree();
1700 }
1701
1702 sub remove_stray_gits ($) {
1703     my ($what) = @_;
1704     my @gitscmd = qw(find -name .git -prune -print0);
1705     debugcmd "|",@gitscmd;
1706     open GITS, "-|", @gitscmd or die $!;
1707     {
1708         local $/="\0";
1709         while (<GITS>) {
1710             chomp or die;
1711             print STDERR "$us: warning: removing from $what: ",
1712                 (messagequote $_), "\n";
1713             rmtree $_;
1714         }
1715     }
1716     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1717 }
1718
1719 sub mktree_in_ud_from_only_subdir ($;$) {
1720     my ($what,$raw) = @_;
1721
1722     # changes into the subdir
1723     my (@dirs) = <*/.>;
1724     die "expected one subdir but found @dirs ?" unless @dirs==1;
1725     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1726     my $dir = $1;
1727     changedir $dir;
1728
1729     remove_stray_gits($what);
1730     mktree_in_ud_here();
1731     if (!$raw) {
1732         my ($format, $fopts) = get_source_format();
1733         if (madformat($format)) {
1734             rmtree '.pc';
1735         }
1736     }
1737
1738     my $tree=git_add_write_tree();
1739     return ($tree,$dir);
1740 }
1741
1742 our @files_csum_info_fields =
1743     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1744      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1745      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1746
1747 sub dsc_files_info () {
1748     foreach my $csumi (@files_csum_info_fields) {
1749         my ($fname, $module, $method) = @$csumi;
1750         my $field = $dsc->{$fname};
1751         next unless defined $field;
1752         eval "use $module; 1;" or die $@;
1753         my @out;
1754         foreach (split /\n/, $field) {
1755             next unless m/\S/;
1756             m/^(\w+) (\d+) (\S+)$/ or
1757                 fail "could not parse .dsc $fname line \`$_'";
1758             my $digester = eval "$module"."->$method;" or die $@;
1759             push @out, {
1760                 Hash => $1,
1761                 Bytes => $2,
1762                 Filename => $3,
1763                 Digester => $digester,
1764             };
1765         }
1766         return @out;
1767     }
1768     fail "missing any supported Checksums-* or Files field in ".
1769         $dsc->get_option('name');
1770 }
1771
1772 sub dsc_files () {
1773     map { $_->{Filename} } dsc_files_info();
1774 }
1775
1776 sub files_compare_inputs (@) {
1777     my $inputs = \@_;
1778     my %record;
1779     my %fchecked;
1780
1781     my $showinputs = sub {
1782         return join "; ", map { $_->get_option('name') } @$inputs;
1783     };
1784
1785     foreach my $in (@$inputs) {
1786         my $expected_files;
1787         my $in_name = $in->get_option('name');
1788
1789         printdebug "files_compare_inputs $in_name\n";
1790
1791         foreach my $csumi (@files_csum_info_fields) {
1792             my ($fname) = @$csumi;
1793             printdebug "files_compare_inputs $in_name $fname\n";
1794
1795             my $field = $in->{$fname};
1796             next unless defined $field;
1797
1798             my @files;
1799             foreach (split /\n/, $field) {
1800                 next unless m/\S/;
1801
1802                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1803                     fail "could not parse $in_name $fname line \`$_'";
1804
1805                 printdebug "files_compare_inputs $in_name $fname $f\n";
1806
1807                 push @files, $f;
1808
1809                 my $re = \ $record{$f}{$fname};
1810                 if (defined $$re) {
1811                     $fchecked{$f}{$in_name} = 1;
1812                     $$re eq $info or
1813                         fail "hash or size of $f varies in $fname fields".
1814                         " (between: ".$showinputs->().")";
1815                 } else {
1816                     $$re = $info;
1817                 }
1818             }
1819             @files = sort @files;
1820             $expected_files //= \@files;
1821             "@$expected_files" eq "@files" or
1822                 fail "file list in $in_name varies between hash fields!";
1823         }
1824         $expected_files or
1825             fail "$in_name has no files list field(s)";
1826     }
1827     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1828         if $debuglevel>=2;
1829
1830     grep { keys %$_ == @$inputs-1 } values %fchecked
1831         or fail "no file appears in all file lists".
1832         " (looked in: ".$showinputs->().")";
1833 }
1834
1835 sub is_orig_file_in_dsc ($$) {
1836     my ($f, $dsc_files_info) = @_;
1837     return 0 if @$dsc_files_info <= 1;
1838     # One file means no origs, and the filename doesn't have a "what
1839     # part of dsc" component.  (Consider versions ending `.orig'.)
1840     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1841     return 1;
1842 }
1843
1844 sub is_orig_file_of_vsn ($$) {
1845     my ($f, $upstreamvsn) = @_;
1846     my $base = srcfn $upstreamvsn, '';
1847     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1848     return 1;
1849 }
1850
1851 sub changes_update_origs_from_dsc ($$$$) {
1852     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1853     my %changes_f;
1854     printdebug "checking origs needed ($upstreamvsn)...\n";
1855     $_ = getfield $changes, 'Files';
1856     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1857         fail "cannot find section/priority from .changes Files field";
1858     my $placementinfo = $1;
1859     my %changed;
1860     printdebug "checking origs needed placement '$placementinfo'...\n";
1861     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1862         $l =~ m/\S+$/ or next;
1863         my $file = $&;
1864         printdebug "origs $file | $l\n";
1865         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1866         printdebug "origs $file is_orig\n";
1867         my $have = archive_query('file_in_archive', $file);
1868         if (!defined $have) {
1869             print STDERR <<END;
1870 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1871 END
1872             return;
1873         }
1874         my $found_same = 0;
1875         my @found_differ;
1876         printdebug "origs $file \$#\$have=$#$have\n";
1877         foreach my $h (@$have) {
1878             my $same = 0;
1879             my @differ;
1880             foreach my $csumi (@files_csum_info_fields) {
1881                 my ($fname, $module, $method, $archivefield) = @$csumi;
1882                 next unless defined $h->{$archivefield};
1883                 $_ = $dsc->{$fname};
1884                 next unless defined;
1885                 m/^(\w+) .* \Q$file\E$/m or
1886                     fail ".dsc $fname missing entry for $file";
1887                 if ($h->{$archivefield} eq $1) {
1888                     $same++;
1889                 } else {
1890                     push @differ,
1891  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1892                 }
1893             }
1894             die "$file ".Dumper($h)." ?!" if $same && @differ;
1895             $found_same++
1896                 if $same;
1897             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1898                 if @differ;
1899         }
1900         printdebug "origs $file f.same=$found_same".
1901             " #f._differ=$#found_differ\n";
1902         if (@found_differ && !$found_same) {
1903             fail join "\n",
1904                 "archive contains $file with different checksum",
1905                 @found_differ;
1906         }
1907         # Now we edit the changes file to add or remove it
1908         foreach my $csumi (@files_csum_info_fields) {
1909             my ($fname, $module, $method, $archivefield) = @$csumi;
1910             next unless defined $changes->{$fname};
1911             if ($found_same) {
1912                 # in archive, delete from .changes if it's there
1913                 $changed{$file} = "removed" if
1914                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1915             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1916                 # not in archive, but it's here in the .changes
1917             } else {
1918                 my $dsc_data = getfield $dsc, $fname;
1919                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1920                 my $extra = $1;
1921                 $extra =~ s/ \d+ /$&$placementinfo /
1922                     or die "$fname $extra >$dsc_data< ?"
1923                     if $fname eq 'Files';
1924                 $changes->{$fname} .= "\n". $extra;
1925                 $changed{$file} = "added";
1926             }
1927         }
1928     }
1929     if (%changed) {
1930         foreach my $file (keys %changed) {
1931             progress sprintf
1932                 "edited .changes for archive .orig contents: %s %s",
1933                 $changed{$file}, $file;
1934         }
1935         my $chtmp = "$changesfile.tmp";
1936         $changes->save($chtmp);
1937         if (act_local()) {
1938             rename $chtmp,$changesfile or die "$changesfile $!";
1939         } else {
1940             progress "[new .changes left in $changesfile]";
1941         }
1942     } else {
1943         progress "$changesfile already has appropriate .orig(s) (if any)";
1944     }
1945 }
1946
1947 sub make_commit ($) {
1948     my ($file) = @_;
1949     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1950 }
1951
1952 sub make_commit_text ($) {
1953     my ($text) = @_;
1954     my ($out, $in);
1955     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1956     debugcmd "|",@cmd;
1957     print Dumper($text) if $debuglevel > 1;
1958     my $child = open2($out, $in, @cmd) or die $!;
1959     my $h;
1960     eval {
1961         print $in $text or die $!;
1962         close $in or die $!;
1963         $h = <$out>;
1964         $h =~ m/^\w+$/ or die;
1965         $h = $&;
1966         printdebug "=> $h\n";
1967     };
1968     close $out;
1969     waitpid $child, 0 == $child or die "$child $!";
1970     $? and failedcmd @cmd;
1971     return $h;
1972 }
1973
1974 sub clogp_authline ($) {
1975     my ($clogp) = @_;
1976     my $author = getfield $clogp, 'Maintainer';
1977     $author =~ s#,.*##ms;
1978     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1979     my $authline = "$author $date";
1980     $authline =~ m/$git_authline_re/o or
1981         fail "unexpected commit author line format \`$authline'".
1982         " (was generated from changelog Maintainer field)";
1983     return ($1,$2,$3) if wantarray;
1984     return $authline;
1985 }
1986
1987 sub vendor_patches_distro ($$) {
1988     my ($checkdistro, $what) = @_;
1989     return unless defined $checkdistro;
1990
1991     my $series = "debian/patches/\L$checkdistro\E.series";
1992     printdebug "checking for vendor-specific $series ($what)\n";
1993
1994     if (!open SERIES, "<", $series) {
1995         die "$series $!" unless $!==ENOENT;
1996         return;
1997     }
1998     while (<SERIES>) {
1999         next unless m/\S/;
2000         next if m/^\s+\#/;
2001
2002         print STDERR <<END;
2003
2004 Unfortunately, this source package uses a feature of dpkg-source where
2005 the same source package unpacks to different source code on different
2006 distros.  dgit cannot safely operate on such packages on affected
2007 distros, because the meaning of source packages is not stable.
2008
2009 Please ask the distro/maintainer to remove the distro-specific series
2010 files and use a different technique (if necessary, uploading actually
2011 different packages, if different distros are supposed to have
2012 different code).
2013
2014 END
2015         fail "Found active distro-specific series file for".
2016             " $checkdistro ($what): $series, cannot continue";
2017     }
2018     die "$series $!" if SERIES->error;
2019     close SERIES;
2020 }
2021
2022 sub check_for_vendor_patches () {
2023     # This dpkg-source feature doesn't seem to be documented anywhere!
2024     # But it can be found in the changelog (reformatted):
2025
2026     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2027     #   Author: Raphael Hertzog <hertzog@debian.org>
2028     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2029
2030     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2031     #   series files
2032     #
2033     #   If you have debian/patches/ubuntu.series and you were
2034     #   unpacking the source package on ubuntu, quilt was still
2035     #   directed to debian/patches/series instead of
2036     #   debian/patches/ubuntu.series.
2037     #
2038     #   debian/changelog                        |    3 +++
2039     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2040     #   2 files changed, 6 insertions(+), 1 deletion(-)
2041
2042     use Dpkg::Vendor;
2043     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2044     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2045                          "Dpkg::Vendor \`current vendor'");
2046     vendor_patches_distro(access_basedistro(),
2047                           "(base) distro being accessed");
2048     vendor_patches_distro(access_nomdistro(),
2049                           "(nominal) distro being accessed");
2050 }
2051
2052 sub generate_commits_from_dsc () {
2053     # See big comment in fetch_from_archive, below.
2054     # See also README.dsc-import.
2055     prep_ud();
2056     changedir $ud;
2057
2058     my @dfi = dsc_files_info();
2059     foreach my $fi (@dfi) {
2060         my $f = $fi->{Filename};
2061         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2062
2063         printdebug "considering linking $f: ";
2064
2065         link_ltarget "../../../../$f", $f
2066             or ((printdebug "($!) "), 0)
2067             or $!==&ENOENT
2068             or die "$f $!";
2069
2070         printdebug "linked.\n";
2071
2072         complete_file_from_dsc('.', $fi)
2073             or next;
2074
2075         if (is_orig_file_in_dsc($f, \@dfi)) {
2076             link $f, "../../../../$f"
2077                 or $!==&EEXIST
2078                 or die "$f $!";
2079         }
2080     }
2081
2082     # We unpack and record the orig tarballs first, so that we only
2083     # need disk space for one private copy of the unpacked source.
2084     # But we can't make them into commits until we have the metadata
2085     # from the debian/changelog, so we record the tree objects now and
2086     # make them into commits later.
2087     my @tartrees;
2088     my $upstreamv = upstreamversion $dsc->{version};
2089     my $orig_f_base = srcfn $upstreamv, '';
2090
2091     foreach my $fi (@dfi) {
2092         # We actually import, and record as a commit, every tarball
2093         # (unless there is only one file, in which case there seems
2094         # little point.
2095
2096         my $f = $fi->{Filename};
2097         printdebug "import considering $f ";
2098         (printdebug "only one dfi\n"), next if @dfi == 1;
2099         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2100         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2101         my $compr_ext = $1;
2102
2103         my ($orig_f_part) =
2104             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2105
2106         printdebug "Y ", (join ' ', map { $_//"(none)" }
2107                           $compr_ext, $orig_f_part
2108                          ), "\n";
2109
2110         my $input = new IO::File $f, '<' or die "$f $!";
2111         my $compr_pid;
2112         my @compr_cmd;
2113
2114         if (defined $compr_ext) {
2115             my $cname =
2116                 Dpkg::Compression::compression_guess_from_filename $f;
2117             fail "Dpkg::Compression cannot handle file $f in source package"
2118                 if defined $compr_ext && !defined $cname;
2119             my $compr_proc =
2120                 new Dpkg::Compression::Process compression => $cname;
2121             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2122             my $compr_fh = new IO::Handle;
2123             my $compr_pid = open $compr_fh, "-|" // die $!;
2124             if (!$compr_pid) {
2125                 open STDIN, "<&", $input or die $!;
2126                 exec @compr_cmd;
2127                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2128             }
2129             $input = $compr_fh;
2130         }
2131
2132         rmtree "_unpack-tar";
2133         mkdir "_unpack-tar" or die $!;
2134         my @tarcmd = qw(tar -x -f -
2135                         --no-same-owner --no-same-permissions
2136                         --no-acls --no-xattrs --no-selinux);
2137         my $tar_pid = fork // die $!;
2138         if (!$tar_pid) {
2139             chdir "_unpack-tar" or die $!;
2140             open STDIN, "<&", $input or die $!;
2141             exec @tarcmd;
2142             die "dgit (child): exec $tarcmd[0]: $!";
2143         }
2144         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2145         !$? or failedcmd @tarcmd;
2146
2147         close $input or
2148             (@compr_cmd ? failedcmd @compr_cmd
2149              : die $!);
2150         # finally, we have the results in "tarball", but maybe
2151         # with the wrong permissions
2152
2153         runcmd qw(chmod -R +rwX _unpack-tar);
2154         changedir "_unpack-tar";
2155         remove_stray_gits($f);
2156         mktree_in_ud_here();
2157
2158         my ($tree) = git_add_write_tree();
2159         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2160         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2161             $tree = $1;
2162             printdebug "one subtree $1\n";
2163         } else {
2164             printdebug "multiple subtrees\n";
2165         }
2166         changedir "..";
2167         rmtree "_unpack-tar";
2168
2169         my $ent = [ $f, $tree ];
2170         push @tartrees, {
2171             Orig => !!$orig_f_part,
2172             Sort => (!$orig_f_part         ? 2 :
2173                      $orig_f_part =~ m/-/g ? 1 :
2174                                              0),
2175             F => $f,
2176             Tree => $tree,
2177         };
2178     }
2179
2180     @tartrees = sort {
2181         # put any without "_" first (spec is not clear whether files
2182         # are always in the usual order).  Tarballs without "_" are
2183         # the main orig or the debian tarball.
2184         $a->{Sort} <=> $b->{Sort} or
2185         $a->{F}    cmp $b->{F}
2186     } @tartrees;
2187
2188     my $any_orig = grep { $_->{Orig} } @tartrees;
2189
2190     my $dscfn = "$package.dsc";
2191
2192     my $treeimporthow = 'package';
2193
2194     open D, ">", $dscfn or die "$dscfn: $!";
2195     print D $dscdata or die "$dscfn: $!";
2196     close D or die "$dscfn: $!";
2197     my @cmd = qw(dpkg-source);
2198     push @cmd, '--no-check' if $dsc_checked;
2199     if (madformat $dsc->{format}) {
2200         push @cmd, '--skip-patches';
2201         $treeimporthow = 'unpatched';
2202     }
2203     push @cmd, qw(-x --), $dscfn;
2204     runcmd @cmd;
2205
2206     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2207     if (madformat $dsc->{format}) {
2208         check_for_vendor_patches();
2209     }
2210
2211     my $dappliedtree;
2212     if (madformat $dsc->{format}) {
2213         my @pcmd = qw(dpkg-source --before-build .);
2214         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2215         rmtree '.pc';
2216         $dappliedtree = git_add_write_tree();
2217     }
2218
2219     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2220     debugcmd "|",@clogcmd;
2221     open CLOGS, "-|", @clogcmd or die $!;
2222
2223     my $clogp;
2224     my $r1clogp;
2225
2226     printdebug "import clog search...\n";
2227
2228     for (;;) {
2229         my $stanzatext = do { local $/=""; <CLOGS>; };
2230         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2231         last if !defined $stanzatext;
2232
2233         my $desc = "package changelog, entry no.$.";
2234         open my $stanzafh, "<", \$stanzatext or die;
2235         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2236         $clogp //= $thisstanza;
2237
2238         printdebug "import clog $thisstanza->{version} $desc...\n";
2239
2240         last if !$any_orig; # we don't need $r1clogp
2241
2242         # We look for the first (most recent) changelog entry whose
2243         # version number is lower than the upstream version of this
2244         # package.  Then the last (least recent) previous changelog
2245         # entry is treated as the one which introduced this upstream
2246         # version and used for the synthetic commits for the upstream
2247         # tarballs.
2248
2249         # One might think that a more sophisticated algorithm would be
2250         # necessary.  But: we do not want to scan the whole changelog
2251         # file.  Stopping when we see an earlier version, which
2252         # necessarily then is an earlier upstream version, is the only
2253         # realistic way to do that.  Then, either the earliest
2254         # changelog entry we have seen so far is indeed the earliest
2255         # upload of this upstream version; or there are only changelog
2256         # entries relating to later upstream versions (which is not
2257         # possible unless the changelog and .dsc disagree about the
2258         # version).  Then it remains to choose between the physically
2259         # last entry in the file, and the one with the lowest version
2260         # number.  If these are not the same, we guess that the
2261         # versions were created in a non-monotic order rather than
2262         # that the changelog entries have been misordered.
2263
2264         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2265
2266         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2267         $r1clogp = $thisstanza;
2268
2269         printdebug "import clog $r1clogp->{version} becomes r1\n";
2270     }
2271     die $! if CLOGS->error;
2272     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2273
2274     $clogp or fail "package changelog has no entries!";
2275
2276     my $authline = clogp_authline $clogp;
2277     my $changes = getfield $clogp, 'Changes';
2278     my $cversion = getfield $clogp, 'Version';
2279
2280     if (@tartrees) {
2281         $r1clogp //= $clogp; # maybe there's only one entry;
2282         my $r1authline = clogp_authline $r1clogp;
2283         # Strictly, r1authline might now be wrong if it's going to be
2284         # unused because !$any_orig.  Whatever.
2285
2286         printdebug "import tartrees authline   $authline\n";
2287         printdebug "import tartrees r1authline $r1authline\n";
2288
2289         foreach my $tt (@tartrees) {
2290             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2291
2292             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2293 tree $tt->{Tree}
2294 author $r1authline
2295 committer $r1authline
2296
2297 Import $tt->{F}
2298
2299 [dgit import orig $tt->{F}]
2300 END_O
2301 tree $tt->{Tree}
2302 author $authline
2303 committer $authline
2304
2305 Import $tt->{F}
2306
2307 [dgit import tarball $package $cversion $tt->{F}]
2308 END_T
2309         }
2310     }
2311
2312     printdebug "import main commit\n";
2313
2314     open C, ">../commit.tmp" or die $!;
2315     print C <<END or die $!;
2316 tree $tree
2317 END
2318     print C <<END or die $! foreach @tartrees;
2319 parent $_->{Commit}
2320 END
2321     print C <<END or die $!;
2322 author $authline
2323 committer $authline
2324
2325 $changes
2326
2327 [dgit import $treeimporthow $package $cversion]
2328 END
2329
2330     close C or die $!;
2331     my $rawimport_hash = make_commit qw(../commit.tmp);
2332
2333     if (madformat $dsc->{format}) {
2334         printdebug "import apply patches...\n";
2335
2336         # regularise the state of the working tree so that
2337         # the checkout of $rawimport_hash works nicely.
2338         my $dappliedcommit = make_commit_text(<<END);
2339 tree $dappliedtree
2340 author $authline
2341 committer $authline
2342
2343 [dgit dummy commit]
2344 END
2345         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2346
2347         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2348
2349         # We need the answers to be reproducible
2350         my @authline = clogp_authline($clogp);
2351         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2352         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2353         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2354         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2355         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2356         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2357
2358         my $path = $ENV{PATH} or die;
2359
2360         foreach my $use_absurd (qw(0 1)) {
2361             runcmd @git, qw(checkout -q unpa);
2362             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2363             local $ENV{PATH} = $path;
2364             if ($use_absurd) {
2365                 chomp $@;
2366                 progress "warning: $@";
2367                 $path = "$absurdity:$path";
2368                 progress "$us: trying slow absurd-git-apply...";
2369                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2370                     or $!==ENOENT
2371                     or die $!;
2372             }
2373             eval {
2374                 die "forbid absurd git-apply\n" if $use_absurd
2375                     && forceing [qw(import-gitapply-no-absurd)];
2376                 die "only absurd git-apply!\n" if !$use_absurd
2377                     && forceing [qw(import-gitapply-absurd)];
2378
2379                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2380                 local $ENV{PATH} = $path                    if $use_absurd;
2381
2382                 my @showcmd = (gbp_pq, qw(import));
2383                 my @realcmd = shell_cmd
2384                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2385                 debugcmd "+",@realcmd;
2386                 if (system @realcmd) {
2387                     die +(shellquote @showcmd).
2388                         " failed: ".
2389                         failedcmd_waitstatus()."\n";
2390                 }
2391
2392                 my $gapplied = git_rev_parse('HEAD');
2393                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2394                 $gappliedtree eq $dappliedtree or
2395                     fail <<END;
2396 gbp-pq import and dpkg-source disagree!
2397  gbp-pq import gave commit $gapplied
2398  gbp-pq import gave tree $gappliedtree
2399  dpkg-source --before-build gave tree $dappliedtree
2400 END
2401                 $rawimport_hash = $gapplied;
2402             };
2403             last unless $@;
2404         }
2405         if ($@) {
2406             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2407             die $@;
2408         }
2409     }
2410
2411     progress "synthesised git commit from .dsc $cversion";
2412
2413     my $rawimport_mergeinput = {
2414         Commit => $rawimport_hash,
2415         Info => "Import of source package",
2416     };
2417     my @output = ($rawimport_mergeinput);
2418
2419     if ($lastpush_mergeinput) {
2420         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2421         my $oversion = getfield $oldclogp, 'Version';
2422         my $vcmp =
2423             version_compare($oversion, $cversion);
2424         if ($vcmp < 0) {
2425             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2426                 { Message => <<END, ReverseParents => 1 });
2427 Record $package ($cversion) in archive suite $csuite
2428 END
2429         } elsif ($vcmp > 0) {
2430             print STDERR <<END or die $!;
2431
2432 Version actually in archive:   $cversion (older)
2433 Last version pushed with dgit: $oversion (newer or same)
2434 $later_warning_msg
2435 END
2436             @output = $lastpush_mergeinput;
2437         } else {
2438             # Same version.  Use what's in the server git branch,
2439             # discarding our own import.  (This could happen if the
2440             # server automatically imports all packages into git.)
2441             @output = $lastpush_mergeinput;
2442         }
2443     }
2444     changedir '../../../..';
2445     rmtree($ud);
2446     return @output;
2447 }
2448
2449 sub complete_file_from_dsc ($$) {
2450     our ($dstdir, $fi) = @_;
2451     # Ensures that we have, in $dir, the file $fi, with the correct
2452     # contents.  (Downloading it from alongside $dscurl if necessary.)
2453
2454     my $f = $fi->{Filename};
2455     my $tf = "$dstdir/$f";
2456     my $downloaded = 0;
2457
2458     if (stat_exists $tf) {
2459         progress "using existing $f";
2460     } else {
2461         printdebug "$tf does not exist, need to fetch\n";
2462         my $furl = $dscurl;
2463         $furl =~ s{/[^/]+$}{};
2464         $furl .= "/$f";
2465         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2466         die "$f ?" if $f =~ m#/#;
2467         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2468         return 0 if !act_local();
2469         $downloaded = 1;
2470     }
2471
2472     open F, "<", "$tf" or die "$tf: $!";
2473     $fi->{Digester}->reset();
2474     $fi->{Digester}->addfile(*F);
2475     F->error and die $!;
2476     my $got = $fi->{Digester}->hexdigest();
2477     $got eq $fi->{Hash} or
2478         fail "file $f has hash $got but .dsc".
2479             " demands hash $fi->{Hash} ".
2480             ($downloaded ? "(got wrong file from archive!)"
2481              : "(perhaps you should delete this file?)");
2482
2483     return 1;
2484 }
2485
2486 sub ensure_we_have_orig () {
2487     my @dfi = dsc_files_info();
2488     foreach my $fi (@dfi) {
2489         my $f = $fi->{Filename};
2490         next unless is_orig_file_in_dsc($f, \@dfi);
2491         complete_file_from_dsc('..', $fi)
2492             or next;
2493     }
2494 }
2495
2496 #---------- git fetch ----------
2497
2498 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2499 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2500
2501 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2502 # locally fetched refs because they have unhelpful names and clutter
2503 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2504 # whether we have made another local ref which refers to this object).
2505 #
2506 # (If we deleted them unconditionally, then we might end up
2507 # re-fetching the same git objects each time dgit fetch was run.)
2508 #
2509 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
2510 # in git_fetch_us to fetch the refs in question, and possibly a call
2511 # to lrfetchref_used.
2512
2513 our (%lrfetchrefs_f, %lrfetchrefs_d);
2514 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2515
2516 sub lrfetchref_used ($) {
2517     my ($fullrefname) = @_;
2518     my $objid = $lrfetchrefs_f{$fullrefname};
2519     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2520 }
2521
2522 sub git_lrfetch_sane {
2523     my ($supplementary, @specs) = @_;
2524     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2525     # at least as regards @specs.  Also leave the results in
2526     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2527     # able to clean these up.
2528     #
2529     # With $supplementary==1, @specs must not contain wildcards
2530     # and we add to our previous fetches (non-atomically).
2531
2532     # This is rather miserable:
2533     # When git fetch --prune is passed a fetchspec ending with a *,
2534     # it does a plausible thing.  If there is no * then:
2535     # - it matches subpaths too, even if the supplied refspec
2536     #   starts refs, and behaves completely madly if the source
2537     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2538     # - if there is no matching remote ref, it bombs out the whole
2539     #   fetch.
2540     # We want to fetch a fixed ref, and we don't know in advance
2541     # if it exists, so this is not suitable.
2542     #
2543     # Our workaround is to use git ls-remote.  git ls-remote has its
2544     # own qairks.  Notably, it has the absurd multi-tail-matching
2545     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2546     # refs/refs/foo etc.
2547     #
2548     # Also, we want an idempotent snapshot, but we have to make two
2549     # calls to the remote: one to git ls-remote and to git fetch.  The
2550     # solution is use git ls-remote to obtain a target state, and
2551     # git fetch to try to generate it.  If we don't manage to generate
2552     # the target state, we try again.
2553
2554     my $url = access_giturl();
2555
2556     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2557
2558     my $specre = join '|', map {
2559         my $x = $_;
2560         $x =~ s/\W/\\$&/g;
2561         my $wildcard = $x =~ s/\\\*$/.*/;
2562         die if $wildcard && $supplementary;
2563         "(?:refs/$x)";
2564     } @specs;
2565     printdebug "git_lrfetch_sane specre=$specre\n";
2566     my $wanted_rref = sub {
2567         local ($_) = @_;
2568         return m/^(?:$specre)$/;
2569     };
2570
2571     my $fetch_iteration = 0;
2572     FETCH_ITERATION:
2573     for (;;) {
2574         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2575         if (++$fetch_iteration > 10) {
2576             fail "too many iterations trying to get sane fetch!";
2577         }
2578
2579         my @look = map { "refs/$_" } @specs;
2580         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2581         debugcmd "|",@lcmd;
2582
2583         my %wantr;
2584         open GITLS, "-|", @lcmd or die $!;
2585         while (<GITLS>) {
2586             printdebug "=> ", $_;
2587             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2588             my ($objid,$rrefname) = ($1,$2);
2589             if (!$wanted_rref->($rrefname)) {
2590                 print STDERR <<END;
2591 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2592 END
2593                 next;
2594             }
2595             $wantr{$rrefname} = $objid;
2596         }
2597         $!=0; $?=0;
2598         close GITLS or failedcmd @lcmd;
2599
2600         # OK, now %want is exactly what we want for refs in @specs
2601         my @fspecs = map {
2602             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2603             "+refs/$_:".lrfetchrefs."/$_";
2604         } @specs;
2605
2606         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2607
2608         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2609         runcmd_ordryrun_local @fcmd if @fspecs;
2610
2611         if (!$supplementary) {
2612             %lrfetchrefs_f = ();
2613         }
2614         my %objgot;
2615
2616         git_for_each_ref(lrfetchrefs, sub {
2617             my ($objid,$objtype,$lrefname,$reftail) = @_;
2618             $lrfetchrefs_f{$lrefname} = $objid;
2619             $objgot{$objid} = 1;
2620         });
2621
2622         if ($supplementary) {
2623             last;
2624         }
2625
2626         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2627             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2628             if (!exists $wantr{$rrefname}) {
2629                 if ($wanted_rref->($rrefname)) {
2630                     printdebug <<END;
2631 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2632 END
2633                 } else {
2634                     print STDERR <<END
2635 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2636 END
2637                 }
2638                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2639                 delete $lrfetchrefs_f{$lrefname};
2640                 next;
2641             }
2642         }
2643         foreach my $rrefname (sort keys %wantr) {
2644             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2645             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2646             my $want = $wantr{$rrefname};
2647             next if $got eq $want;
2648             if (!defined $objgot{$want}) {
2649                 print STDERR <<END;
2650 warning: git ls-remote suggests we want $lrefname
2651 warning:  and it should refer to $want
2652 warning:  but git fetch didn't fetch that object to any relevant ref.
2653 warning:  This may be due to a race with someone updating the server.
2654 warning:  Will try again...
2655 END
2656                 next FETCH_ITERATION;
2657             }
2658             printdebug <<END;
2659 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2660 END
2661             runcmd_ordryrun_local @git, qw(update-ref -m),
2662                 "dgit fetch git fetch fixup", $lrefname, $want;
2663             $lrfetchrefs_f{$lrefname} = $want;
2664         }
2665         last;
2666     }
2667     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2668         Dumper(\%lrfetchrefs_f);
2669 }
2670
2671 sub git_fetch_us () {
2672     # Want to fetch only what we are going to use, unless
2673     # deliberately-not-ff, in which case we must fetch everything.
2674
2675     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2676         map { "tags/$_" }
2677         (quiltmode_splitbrain
2678          ? (map { $_->('*',access_nomdistro) }
2679             \&debiantag_new, \&debiantag_maintview)
2680          : debiantags('*',access_nomdistro));
2681     push @specs, server_branch($csuite);
2682     push @specs, $rewritemap;
2683     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2684
2685     git_lrfetch_sane 0, @specs;
2686
2687     my %here;
2688     my @tagpats = debiantags('*',access_nomdistro);
2689
2690     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2691         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2692         printdebug "currently $fullrefname=$objid\n";
2693         $here{$fullrefname} = $objid;
2694     });
2695     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2696         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2697         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2698         printdebug "offered $lref=$objid\n";
2699         if (!defined $here{$lref}) {
2700             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2701             runcmd_ordryrun_local @upd;
2702             lrfetchref_used $fullrefname;
2703         } elsif ($here{$lref} eq $objid) {
2704             lrfetchref_used $fullrefname;
2705         } else {
2706             print STDERR \
2707                 "Not updateting $lref from $here{$lref} to $objid.\n";
2708         }
2709     });
2710 }
2711
2712 #---------- dsc and archive handling ----------
2713
2714 sub mergeinfo_getclogp ($) {
2715     # Ensures thit $mi->{Clogp} exists and returns it
2716     my ($mi) = @_;
2717     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2718 }
2719
2720 sub mergeinfo_version ($) {
2721     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2722 }
2723
2724 sub fetch_from_archive_record_1 ($) {
2725     my ($hash) = @_;
2726     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2727             'DGIT_ARCHIVE', $hash;
2728     cmdoutput @git, qw(log -n2), $hash;
2729     # ... gives git a chance to complain if our commit is malformed
2730 }
2731
2732 sub fetch_from_archive_record_2 ($) {
2733     my ($hash) = @_;
2734     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2735     if (act_local()) {
2736         cmdoutput @upd_cmd;
2737     } else {
2738         dryrun_report @upd_cmd;
2739     }
2740 }
2741
2742 sub parse_dsc_field ($$) {
2743     my ($dsc, $what) = @_;
2744     my $f;
2745     foreach my $field (@ourdscfield) {
2746         $f = $dsc->{$field};
2747         last if defined $f;
2748     }
2749     if (!defined $f) {
2750         progress "$what: NO git hash";
2751     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2752              = $f =~ m/^(\w+) ($distro_re) ($versiontag_re) (\S+)(?:\s|$)/) {
2753         progress "$what: specified git info ($dsc_distro)";
2754         $dsc_hint_tag = [ $dsc_hint_tag ];
2755     } elsif ($f =~ m/^\w+\s*$/) {
2756         $dsc_hash = $&;
2757         $dsc_distro //= 'debian';
2758         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2759                           $dsc_distro ];
2760         progress "$what: specified git hash";
2761     } else {
2762         fail "$what: invalid Dgit info";
2763     }
2764 }
2765
2766 sub resolve_dsc_field_commit ($$) {
2767     my ($already_distro, $already_mapref) = @_;
2768
2769     return unless defined $dsc_hash;
2770
2771     my $mapref =
2772         defined $already_mapref &&
2773         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2774         ? $already_mapref : undef;
2775
2776     my $do_fetch;
2777     $do_fetch = sub {
2778         my ($what, @fetch) = @_;
2779
2780         local $idistro = $dsc_distro;
2781         my $lrf = lrfetchrefs;
2782
2783         if (!$chase_dsc_distro) {
2784             progress
2785                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2786             return 0;
2787         }
2788
2789         progress
2790             ".dsc names distro $dsc_distro: fetching $what";
2791
2792         my $url = access_giturl();
2793         if (!defined $url) {
2794             defined $dsc_hint_url or fail <<END;
2795 .dsc Dgit metadata is in context of distro $dsc_distro
2796 for which we have no configured url and .dsc provides no hint
2797 END
2798             my $proto =
2799                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2800                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2801             parse_cfg_bool "dsc-url-proto-ok", 'false',
2802                 cfg("dgit.dsc-url-proto-ok.$proto",
2803                     "dgit.default.dsc-url-proto-ok")
2804                 or fail <<END;
2805 .dsc Dgit metadata is in context of distro $dsc_distro
2806 for which we have no configured url;
2807 .dsc provices hinted url with protocol $proto which is unsafe.
2808 (can be overridden by config - consult documentation)
2809 END
2810             $url = $dsc_hint_url;
2811         }
2812
2813         git_lrfetch_sane 1, @fetch;
2814
2815         return $lrf;
2816     };
2817
2818     if (parse_cfg_bool 'rewrite-map-enable', 'true',
2819             access_cfg('rewrite-map-enable', 'RETURN-UNDEF')) {
2820         my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2821         $mapref = $lrf.'/'.$rewritemap;
2822         my $rewritemapdata = git_cat_file $mapref.':map';
2823         if (defined $rewritemapdata
2824             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2825             progress
2826                 "server's git history rewrite map contains a relevant entry!";
2827
2828             $dsc_hash = $1;
2829             if (defined $dsc_hash) {
2830                 progress "using rewritten git hash in place of .dsc value";
2831             } else {
2832                 progress "server data says .dsc hash is to be disregarded";
2833             }
2834         }
2835     }
2836
2837     if (!defined git_cat_file $dsc_hash) {
2838         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2839         my $lrf = $do_fetch->("additional commits", @tags) &&
2840             defined git_cat_file $dsc_hash
2841             or fail <<END;
2842 .dsc Dgit metadata requires commit $dsc_hash
2843 but we could not obtain that object anywhere.
2844 END
2845         foreach my $t (@tags) {
2846             my $fullrefname = $lrf.'/'.$t;
2847             print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2848             next unless $lrfetchrefs_f{$fullrefname};
2849             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2850             lrfetchref_used $fullrefname;
2851         }
2852     }
2853 }
2854
2855 sub fetch_from_archive () {
2856     ensure_setup_existing_tree();
2857
2858     # Ensures that lrref() is what is actually in the archive, one way
2859     # or another, according to us - ie this client's
2860     # appropritaely-updated archive view.  Also returns the commit id.
2861     # If there is nothing in the archive, leaves lrref alone and
2862     # returns undef.  git_fetch_us must have already been called.
2863     get_archive_dsc();
2864
2865     if ($dsc) {
2866         parse_dsc_field($dsc, 'last upload to archive');
2867         resolve_dsc_field_commit access_basedistro,
2868             lrfetchrefs."/".$rewritemap
2869     } else {
2870         progress "no version available from the archive";
2871     }
2872
2873     # If the archive's .dsc has a Dgit field, there are three
2874     # relevant git commitids we need to choose between and/or merge
2875     # together:
2876     #   1. $dsc_hash: the Dgit field from the archive
2877     #   2. $lastpush_hash: the suite branch on the dgit git server
2878     #   3. $lastfetch_hash: our local tracking brach for the suite
2879     #
2880     # These may all be distinct and need not be in any fast forward
2881     # relationship:
2882     #
2883     # If the dsc was pushed to this suite, then the server suite
2884     # branch will have been updated; but it might have been pushed to
2885     # a different suite and copied by the archive.  Conversely a more
2886     # recent version may have been pushed with dgit but not appeared
2887     # in the archive (yet).
2888     #
2889     # $lastfetch_hash may be awkward because archive imports
2890     # (particularly, imports of Dgit-less .dscs) are performed only as
2891     # needed on individual clients, so different clients may perform a
2892     # different subset of them - and these imports are only made
2893     # public during push.  So $lastfetch_hash may represent a set of
2894     # imports different to a subsequent upload by a different dgit
2895     # client.
2896     #
2897     # Our approach is as follows:
2898     #
2899     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2900     # descendant of $dsc_hash, then it was pushed by a dgit user who
2901     # had based their work on $dsc_hash, so we should prefer it.
2902     # Otherwise, $dsc_hash was installed into this suite in the
2903     # archive other than by a dgit push, and (necessarily) after the
2904     # last dgit push into that suite (since a dgit push would have
2905     # been descended from the dgit server git branch); thus, in that
2906     # case, we prefer the archive's version (and produce a
2907     # pseudo-merge to overwrite the dgit server git branch).
2908     #
2909     # (If there is no Dgit field in the archive's .dsc then
2910     # generate_commit_from_dsc uses the version numbers to decide
2911     # whether the suite branch or the archive is newer.  If the suite
2912     # branch is newer it ignores the archive's .dsc; otherwise it
2913     # generates an import of the .dsc, and produces a pseudo-merge to
2914     # overwrite the suite branch with the archive contents.)
2915     #
2916     # The outcome of that part of the algorithm is the `public view',
2917     # and is same for all dgit clients: it does not depend on any
2918     # unpublished history in the local tracking branch.
2919     #
2920     # As between the public view and the local tracking branch: The
2921     # local tracking branch is only updated by dgit fetch, and
2922     # whenever dgit fetch runs it includes the public view in the
2923     # local tracking branch.  Therefore if the public view is not
2924     # descended from the local tracking branch, the local tracking
2925     # branch must contain history which was imported from the archive
2926     # but never pushed; and, its tip is now out of date.  So, we make
2927     # a pseudo-merge to overwrite the old imports and stitch the old
2928     # history in.
2929     #
2930     # Finally: we do not necessarily reify the public view (as
2931     # described above).  This is so that we do not end up stacking two
2932     # pseudo-merges.  So what we actually do is figure out the inputs
2933     # to any public view pseudo-merge and put them in @mergeinputs.
2934
2935     my @mergeinputs;
2936     # $mergeinputs[]{Commit}
2937     # $mergeinputs[]{Info}
2938     # $mergeinputs[0] is the one whose tree we use
2939     # @mergeinputs is in the order we use in the actual commit)
2940     #
2941     # Also:
2942     # $mergeinputs[]{Message} is a commit message to use
2943     # $mergeinputs[]{ReverseParents} if def specifies that parent
2944     #                                list should be in opposite order
2945     # Such an entry has no Commit or Info.  It applies only when found
2946     # in the last entry.  (This ugliness is to support making
2947     # identical imports to previous dgit versions.)
2948
2949     my $lastpush_hash = git_get_ref(lrfetchref());
2950     printdebug "previous reference hash=$lastpush_hash\n";
2951     $lastpush_mergeinput = $lastpush_hash && {
2952         Commit => $lastpush_hash,
2953         Info => "dgit suite branch on dgit git server",
2954     };
2955
2956     my $lastfetch_hash = git_get_ref(lrref());
2957     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2958     my $lastfetch_mergeinput = $lastfetch_hash && {
2959         Commit => $lastfetch_hash,
2960         Info => "dgit client's archive history view",
2961     };
2962
2963     my $dsc_mergeinput = $dsc_hash && {
2964         Commit => $dsc_hash,
2965         Info => "Dgit field in .dsc from archive",
2966     };
2967
2968     my $cwd = getcwd();
2969     my $del_lrfetchrefs = sub {
2970         changedir $cwd;
2971         my $gur;
2972         printdebug "del_lrfetchrefs...\n";
2973         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2974             my $objid = $lrfetchrefs_d{$fullrefname};
2975             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
2976             if (!$gur) {
2977                 $gur ||= new IO::Handle;
2978                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
2979             }
2980             printf $gur "delete %s %s\n", $fullrefname, $objid;
2981         }
2982         if ($gur) {
2983             close $gur or failedcmd "git update-ref delete lrfetchrefs";
2984         }
2985     };
2986
2987     if (defined $dsc_hash) {
2988         ensure_we_have_orig();
2989         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
2990             @mergeinputs = $dsc_mergeinput
2991         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
2992             print STDERR <<END or die $!;
2993
2994 Git commit in archive is behind the last version allegedly pushed/uploaded.
2995 Commit referred to by archive: $dsc_hash
2996 Last version pushed with dgit: $lastpush_hash
2997 $later_warning_msg
2998 END
2999             @mergeinputs = ($lastpush_mergeinput);
3000         } else {
3001             # Archive has .dsc which is not a descendant of the last dgit
3002             # push.  This can happen if the archive moves .dscs about.
3003             # Just follow its lead.
3004             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3005                 progress "archive .dsc names newer git commit";
3006                 @mergeinputs = ($dsc_mergeinput);
3007             } else {
3008                 progress "archive .dsc names other git commit, fixing up";
3009                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3010             }
3011         }
3012     } elsif ($dsc) {
3013         @mergeinputs = generate_commits_from_dsc();
3014         # We have just done an import.  Now, our import algorithm might
3015         # have been improved.  But even so we do not want to generate
3016         # a new different import of the same package.  So if the
3017         # version numbers are the same, just use our existing version.
3018         # If the version numbers are different, the archive has changed
3019         # (perhaps, rewound).
3020         if ($lastfetch_mergeinput &&
3021             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3022                               (mergeinfo_version $mergeinputs[0]) )) {
3023             @mergeinputs = ($lastfetch_mergeinput);
3024         }
3025     } elsif ($lastpush_hash) {
3026         # only in git, not in the archive yet
3027         @mergeinputs = ($lastpush_mergeinput);
3028         print STDERR <<END or die $!;
3029
3030 Package not found in the archive, but has allegedly been pushed using dgit.
3031 $later_warning_msg
3032 END
3033     } else {
3034         printdebug "nothing found!\n";
3035         if (defined $skew_warning_vsn) {
3036             print STDERR <<END or die $!;
3037
3038 Warning: relevant archive skew detected.
3039 Archive allegedly contains $skew_warning_vsn
3040 But we were not able to obtain any version from the archive or git.
3041
3042 END
3043         }
3044         unshift @end, $del_lrfetchrefs;
3045         return undef;
3046     }
3047
3048     if ($lastfetch_hash &&
3049         !grep {
3050             my $h = $_->{Commit};
3051             $h and is_fast_fwd($lastfetch_hash, $h);
3052             # If true, one of the existing parents of this commit
3053             # is a descendant of the $lastfetch_hash, so we'll
3054             # be ff from that automatically.
3055         } @mergeinputs
3056         ) {
3057         # Otherwise:
3058         push @mergeinputs, $lastfetch_mergeinput;
3059     }
3060
3061     printdebug "fetch mergeinfos:\n";
3062     foreach my $mi (@mergeinputs) {
3063         if ($mi->{Info}) {
3064             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3065         } else {
3066             printdebug sprintf " ReverseParents=%d Message=%s",
3067                 $mi->{ReverseParents}, $mi->{Message};
3068         }
3069     }
3070
3071     my $compat_info= pop @mergeinputs
3072         if $mergeinputs[$#mergeinputs]{Message};
3073
3074     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3075
3076     my $hash;
3077     if (@mergeinputs > 1) {
3078         # here we go, then:
3079         my $tree_commit = $mergeinputs[0]{Commit};
3080
3081         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3082         $tree =~ m/\n\n/;  $tree = $`;
3083         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3084         $tree = $1;
3085
3086         # We use the changelog author of the package in question the
3087         # author of this pseudo-merge.  This is (roughly) correct if
3088         # this commit is simply representing aa non-dgit upload.
3089         # (Roughly because it does not record sponsorship - but we
3090         # don't have sponsorship info because that's in the .changes,
3091         # which isn't in the archivw.)
3092         #
3093         # But, it might be that we are representing archive history
3094         # updates (including in-archive copies).  These are not really
3095         # the responsibility of the person who created the .dsc, but
3096         # there is no-one whose name we should better use.  (The
3097         # author of the .dsc-named commit is clearly worse.)
3098
3099         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3100         my $author = clogp_authline $useclogp;
3101         my $cversion = getfield $useclogp, 'Version';
3102
3103         my $mcf = ".git/dgit/mergecommit";
3104         open MC, ">", $mcf or die "$mcf $!";
3105         print MC <<END or die $!;
3106 tree $tree
3107 END
3108
3109         my @parents = grep { $_->{Commit} } @mergeinputs;
3110         @parents = reverse @parents if $compat_info->{ReverseParents};
3111         print MC <<END or die $! foreach @parents;
3112 parent $_->{Commit}
3113 END
3114
3115         print MC <<END or die $!;
3116 author $author
3117 committer $author
3118
3119 END
3120
3121         if (defined $compat_info->{Message}) {
3122             print MC $compat_info->{Message} or die $!;
3123         } else {
3124             print MC <<END or die $!;
3125 Record $package ($cversion) in archive suite $csuite
3126
3127 Record that
3128 END
3129             my $message_add_info = sub {
3130                 my ($mi) = (@_);
3131                 my $mversion = mergeinfo_version $mi;
3132                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3133                     or die $!;
3134             };
3135
3136             $message_add_info->($mergeinputs[0]);
3137             print MC <<END or die $!;
3138 should be treated as descended from
3139 END
3140             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3141         }
3142
3143         close MC or die $!;
3144         $hash = make_commit $mcf;
3145     } else {
3146         $hash = $mergeinputs[0]{Commit};
3147     }
3148     printdebug "fetch hash=$hash\n";
3149
3150     my $chkff = sub {
3151         my ($lasth, $what) = @_;
3152         return unless $lasth;
3153         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3154     };
3155
3156     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3157         if $lastpush_hash;
3158     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3159
3160     fetch_from_archive_record_1($hash);
3161
3162     if (defined $skew_warning_vsn) {
3163         mkpath '.git/dgit';
3164         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3165         my $gotclogp = commit_getclogp($hash);
3166         my $got_vsn = getfield $gotclogp, 'Version';
3167         printdebug "SKEW CHECK GOT $got_vsn\n";
3168         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3169             print STDERR <<END or die $!;
3170
3171 Warning: archive skew detected.  Using the available version:
3172 Archive allegedly contains    $skew_warning_vsn
3173 We were able to obtain only   $got_vsn
3174
3175 END
3176         }
3177     }
3178
3179     if ($lastfetch_hash ne $hash) {
3180         fetch_from_archive_record_2($hash);
3181     }
3182
3183     lrfetchref_used lrfetchref();
3184
3185     unshift @end, $del_lrfetchrefs;
3186     return $hash;
3187 }
3188
3189 sub set_local_git_config ($$) {
3190     my ($k, $v) = @_;
3191     runcmd @git, qw(config), $k, $v;
3192 }
3193
3194 sub setup_mergechangelogs (;$) {
3195     my ($always) = @_;
3196     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3197
3198     my $driver = 'dpkg-mergechangelogs';
3199     my $cb = "merge.$driver";
3200     my $attrs = '.git/info/attributes';
3201     ensuredir '.git/info';
3202
3203     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3204     if (!open ATTRS, "<", $attrs) {
3205         $!==ENOENT or die "$attrs: $!";
3206     } else {
3207         while (<ATTRS>) {
3208             chomp;
3209             next if m{^debian/changelog\s};
3210             print NATTRS $_, "\n" or die $!;
3211         }
3212         ATTRS->error and die $!;
3213         close ATTRS;
3214     }
3215     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3216     close NATTRS;
3217
3218     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3219     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3220
3221     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3222 }
3223
3224 sub setup_useremail (;$) {
3225     my ($always) = @_;
3226     return unless $always || access_cfg_bool(1, 'setup-useremail');
3227
3228     my $setup = sub {
3229         my ($k, $envvar) = @_;
3230         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3231         return unless defined $v;
3232         set_local_git_config "user.$k", $v;
3233     };
3234
3235     $setup->('email', 'DEBEMAIL');
3236     $setup->('name', 'DEBFULLNAME');
3237 }
3238
3239 sub ensure_setup_existing_tree () {
3240     my $k = "remote.$remotename.skipdefaultupdate";
3241     my $c = git_get_config $k;
3242     return if defined $c;
3243     set_local_git_config $k, 'true';
3244 }
3245
3246 sub setup_new_tree () {
3247     setup_mergechangelogs();
3248     setup_useremail();
3249 }
3250
3251 sub multisuite_suite_child ($$$) {
3252     my ($tsuite, $merginputs, $fn) = @_;
3253     # in child, sets things up, calls $fn->(), and returns undef
3254     # in parent, returns canonical suite name for $tsuite
3255     my $canonsuitefh = IO::File::new_tmpfile;
3256     my $pid = fork // die $!;
3257     if (!$pid) {
3258         $isuite = $tsuite;
3259         $us .= " [$isuite]";
3260         $debugprefix .= " ";
3261         progress "fetching $tsuite...";
3262         canonicalise_suite();
3263         print $canonsuitefh $csuite, "\n" or die $!;
3264         close $canonsuitefh or die $!;
3265         $fn->();
3266         return undef;
3267     }
3268     waitpid $pid,0 == $pid or die $!;
3269     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3270     seek $canonsuitefh,0,0 or die $!;
3271     local $csuite = <$canonsuitefh>;
3272     die $! unless defined $csuite && chomp $csuite;
3273     if ($? == 256*4) {
3274         printdebug "multisuite $tsuite missing\n";
3275         return $csuite;
3276     }
3277     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3278     push @$merginputs, {
3279         Ref => lrref,
3280         Info => $csuite,
3281     };
3282     return $csuite;
3283 }
3284
3285 sub fork_for_multisuite ($) {
3286     my ($before_fetch_merge) = @_;
3287     # if nothing unusual, just returns ''
3288     #
3289     # if multisuite:
3290     # returns 0 to caller in child, to do first of the specified suites
3291     # in child, $csuite is not yet set
3292     #
3293     # returns 1 to caller in parent, to finish up anything needed after
3294     # in parent, $csuite is set to canonicalised portmanteau
3295
3296     my $org_isuite = $isuite;
3297     my @suites = split /\,/, $isuite;
3298     return '' unless @suites > 1;
3299     printdebug "fork_for_multisuite: @suites\n";
3300
3301     my @mergeinputs;
3302
3303     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3304                                             sub { });
3305     return 0 unless defined $cbasesuite;
3306
3307     fail "package $package missing in (base suite) $cbasesuite"
3308         unless @mergeinputs;
3309
3310     my @csuites = ($cbasesuite);
3311
3312     $before_fetch_merge->();
3313
3314     foreach my $tsuite (@suites[1..$#suites]) {
3315         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3316                                                sub {
3317             @end = ();
3318             fetch();
3319             exit 0;
3320         });
3321         # xxx collecte the ref here
3322
3323         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3324         push @csuites, $csubsuite;
3325     }
3326
3327     foreach my $mi (@mergeinputs) {
3328         my $ref = git_get_ref $mi->{Ref};
3329         die "$mi->{Ref} ?" unless length $ref;
3330         $mi->{Commit} = $ref;
3331     }
3332
3333     $csuite = join ",", @csuites;
3334
3335     my $previous = git_get_ref lrref;
3336     if ($previous) {
3337         unshift @mergeinputs, {
3338             Commit => $previous,
3339             Info => "local combined tracking branch",
3340             Warning =>
3341  "archive seems to have rewound: local tracking branch is ahead!",
3342         };
3343     }
3344
3345     foreach my $ix (0..$#mergeinputs) {
3346         $mergeinputs[$ix]{Index} = $ix;
3347     }
3348
3349     @mergeinputs = sort {
3350         -version_compare(mergeinfo_version $a,
3351                          mergeinfo_version $b) # highest version first
3352             or
3353         $a->{Index} <=> $b->{Index}; # earliest in spec first
3354     } @mergeinputs;
3355
3356     my @needed;
3357
3358   NEEDED:
3359     foreach my $mi (@mergeinputs) {
3360         printdebug "multisuite merge check $mi->{Info}\n";
3361         foreach my $previous (@needed) {
3362             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3363             printdebug "multisuite merge un-needed $previous->{Info}\n";
3364             next NEEDED;
3365         }
3366         push @needed, $mi;
3367         printdebug "multisuite merge this-needed\n";
3368         $mi->{Character} = '+';
3369     }
3370
3371     $needed[0]{Character} = '*';
3372
3373     my $output = $needed[0]{Commit};
3374
3375     if (@needed > 1) {
3376         printdebug "multisuite merge nontrivial\n";
3377         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3378
3379         my $commit = "tree $tree\n";
3380         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3381             "Input branches:\n";
3382
3383         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3384             printdebug "multisuite merge include $mi->{Info}\n";
3385             $mi->{Character} //= ' ';
3386             $commit .= "parent $mi->{Commit}\n";
3387             $msg .= sprintf " %s  %-25s %s\n",
3388                 $mi->{Character},
3389                 (mergeinfo_version $mi),
3390                 $mi->{Info};
3391         }
3392         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3393         $msg .= "\nKey\n".
3394             " * marks the highest version branch, which choose to use\n".
3395             " + marks each branch which was not already an ancestor\n\n".
3396             "[dgit multi-suite $csuite]\n";
3397         $commit .=
3398             "author $authline\n".
3399             "committer $authline\n\n";
3400         $output = make_commit_text $commit.$msg;
3401         printdebug "multisuite merge generated $output\n";
3402     }
3403
3404     fetch_from_archive_record_1($output);
3405     fetch_from_archive_record_2($output);
3406
3407     progress "calculated combined tracking suite $csuite";
3408
3409     return 1;
3410 }
3411
3412 sub clone_set_head () {
3413     open H, "> .git/HEAD" or die $!;
3414     print H "ref: ".lref()."\n" or die $!;
3415     close H or die $!;
3416 }
3417 sub clone_finish ($) {
3418     my ($dstdir) = @_;
3419     runcmd @git, qw(reset --hard), lrref();
3420     runcmd qw(bash -ec), <<'END';
3421         set -o pipefail
3422         git ls-tree -r --name-only -z HEAD | \
3423         xargs -0r touch -h -r . --
3424 END
3425     printdone "ready for work in $dstdir";
3426 }
3427
3428 sub clone ($) {
3429     my ($dstdir) = @_;
3430     badusage "dry run makes no sense with clone" unless act_local();
3431
3432     my $multi_fetched = fork_for_multisuite(sub {
3433         printdebug "multi clone before fetch merge\n";
3434         changedir $dstdir;
3435     });
3436     if ($multi_fetched) {
3437         printdebug "multi clone after fetch merge\n";
3438         clone_set_head();
3439         clone_finish($dstdir);
3440         exit 0;
3441     }
3442     printdebug "clone main body\n";
3443
3444     canonicalise_suite();
3445     my $hasgit = check_for_git();
3446     mkdir $dstdir or fail "create \`$dstdir': $!";
3447     changedir $dstdir;
3448     runcmd @git, qw(init -q);
3449     clone_set_head();
3450     my $giturl = access_giturl(1);
3451     if (defined $giturl) {
3452         runcmd @git, qw(remote add), 'origin', $giturl;
3453     }
3454     if ($hasgit) {
3455         progress "fetching existing git history";
3456         git_fetch_us();
3457         runcmd_ordryrun_local @git, qw(fetch origin);
3458     } else {
3459         progress "starting new git history";
3460     }
3461     fetch_from_archive() or no_such_package;
3462     my $vcsgiturl = $dsc->{'Vcs-Git'};
3463     if (length $vcsgiturl) {
3464         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3465         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3466     }
3467     setup_new_tree();
3468     clone_finish($dstdir);
3469 }
3470
3471 sub fetch () {
3472     canonicalise_suite();
3473     if (check_for_git()) {
3474         git_fetch_us();
3475     }
3476     fetch_from_archive() or no_such_package();
3477     printdone "fetched into ".lrref();
3478 }
3479
3480 sub pull () {
3481     my $multi_fetched = fork_for_multisuite(sub { });
3482     fetch() unless $multi_fetched; # parent
3483     return if $multi_fetched eq '0'; # child
3484     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3485         lrref();
3486     printdone "fetched to ".lrref()." and merged into HEAD";
3487 }
3488
3489 sub check_not_dirty () {
3490     foreach my $f (qw(local-options local-patch-header)) {
3491         if (stat_exists "debian/source/$f") {
3492             fail "git tree contains debian/source/$f";
3493         }
3494     }
3495
3496     return if $ignoredirty;
3497
3498     my @cmd = (@git, qw(diff --quiet HEAD));
3499     debugcmd "+",@cmd;
3500     $!=0; $?=-1; system @cmd;
3501     return if !$?;
3502     if ($?==256) {
3503         fail "working tree is dirty (does not match HEAD)";
3504     } else {
3505         failedcmd @cmd;
3506     }
3507 }
3508
3509 sub commit_admin ($) {
3510     my ($m) = @_;
3511     progress "$m";
3512     runcmd_ordryrun_local @git, qw(commit -m), $m;
3513 }
3514
3515 sub commit_quilty_patch () {
3516     my $output = cmdoutput @git, qw(status --porcelain);
3517     my %adds;
3518     foreach my $l (split /\n/, $output) {
3519         next unless $l =~ m/\S/;
3520         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3521             $adds{$1}++;
3522         }
3523     }
3524     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3525     if (!%adds) {
3526         progress "nothing quilty to commit, ok.";
3527         return;
3528     }
3529     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3530     runcmd_ordryrun_local @git, qw(add -f), @adds;
3531     commit_admin <<END
3532 Commit Debian 3.0 (quilt) metadata
3533
3534 [dgit ($our_version) quilt-fixup]
3535 END
3536 }
3537
3538 sub get_source_format () {
3539     my %options;
3540     if (open F, "debian/source/options") {
3541         while (<F>) {
3542             next if m/^\s*\#/;
3543             next unless m/\S/;
3544             s/\s+$//; # ignore missing final newline
3545             if (m/\s*\#\s*/) {
3546                 my ($k, $v) = ($`, $'); #');
3547                 $v =~ s/^"(.*)"$/$1/;
3548                 $options{$k} = $v;
3549             } else {
3550                 $options{$_} = 1;
3551             }
3552         }
3553         F->error and die $!;
3554         close F;
3555     } else {
3556         die $! unless $!==&ENOENT;
3557     }
3558
3559     if (!open F, "debian/source/format") {
3560         die $! unless $!==&ENOENT;
3561         return '';
3562     }
3563     $_ = <F>;
3564     F->error and die $!;
3565     chomp;
3566     return ($_, \%options);
3567 }
3568
3569 sub madformat_wantfixup ($) {
3570     my ($format) = @_;
3571     return 0 unless $format eq '3.0 (quilt)';
3572     our $quilt_mode_warned;
3573     if ($quilt_mode eq 'nocheck') {
3574         progress "Not doing any fixup of \`$format' due to".
3575             " ----no-quilt-fixup or --quilt=nocheck"
3576             unless $quilt_mode_warned++;
3577         return 0;
3578     }
3579     progress "Format \`$format', need to check/update patch stack"
3580         unless $quilt_mode_warned++;
3581     return 1;
3582 }
3583
3584 sub maybe_split_brain_save ($$$) {
3585     my ($headref, $dgitview, $msg) = @_;
3586     # => message fragment "$saved" describing disposition of $dgitview
3587     return "commit id $dgitview" unless defined $split_brain_save;
3588     my @cmd = (shell_cmd "cd ../../../..",
3589                @git, qw(update-ref -m),
3590                "dgit --dgit-view-save $msg HEAD=$headref",
3591                $split_brain_save, $dgitview);
3592     runcmd @cmd;
3593     return "and left in $split_brain_save";
3594 }
3595
3596 # An "infopair" is a tuple [ $thing, $what ]
3597 # (often $thing is a commit hash; $what is a description)
3598
3599 sub infopair_cond_equal ($$) {
3600     my ($x,$y) = @_;
3601     $x->[0] eq $y->[0] or fail <<END;
3602 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3603 END
3604 };
3605
3606 sub infopair_lrf_tag_lookup ($$) {
3607     my ($tagnames, $what) = @_;
3608     # $tagname may be an array ref
3609     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3610     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3611     foreach my $tagname (@tagnames) {
3612         my $lrefname = lrfetchrefs."/tags/$tagname";
3613         my $tagobj = $lrfetchrefs_f{$lrefname};
3614         next unless defined $tagobj;
3615         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3616         return [ git_rev_parse($tagobj), $what ];
3617     }
3618     fail @tagnames==1 ? <<END : <<END;
3619 Wanted tag $what (@tagnames) on dgit server, but not found
3620 END
3621 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3622 END
3623 }
3624
3625 sub infopair_cond_ff ($$) {
3626     my ($anc,$desc) = @_;
3627     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3628 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3629 END
3630 };
3631
3632 sub pseudomerge_version_check ($$) {
3633     my ($clogp, $archive_hash) = @_;
3634
3635     my $arch_clogp = commit_getclogp $archive_hash;
3636     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3637                      'version currently in archive' ];
3638     if (defined $overwrite_version) {
3639         if (length $overwrite_version) {
3640             infopair_cond_equal([ $overwrite_version,
3641                                   '--overwrite= version' ],
3642                                 $i_arch_v);
3643         } else {
3644             my $v = $i_arch_v->[0];
3645             progress "Checking package changelog for archive version $v ...";
3646             eval {
3647                 my @xa = ("-f$v", "-t$v");
3648                 my $vclogp = parsechangelog @xa;
3649                 my $cv = [ (getfield $vclogp, 'Version'),
3650                            "Version field from dpkg-parsechangelog @xa" ];
3651                 infopair_cond_equal($i_arch_v, $cv);
3652             };
3653             if ($@) {
3654                 $@ =~ s/^dgit: //gm;
3655                 fail "$@".
3656                     "Perhaps debian/changelog does not mention $v ?";
3657             }
3658         }
3659     }
3660
3661     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3662     return $i_arch_v;
3663 }
3664
3665 sub pseudomerge_make_commit ($$$$ $$) {
3666     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3667         $msg_cmd, $msg_msg) = @_;
3668     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3669
3670     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3671     my $authline = clogp_authline $clogp;
3672
3673     chomp $msg_msg;
3674     $msg_cmd .=
3675         !defined $overwrite_version ? ""
3676         : !length  $overwrite_version ? " --overwrite"
3677         : " --overwrite=".$overwrite_version;
3678
3679     mkpath '.git/dgit';
3680     my $pmf = ".git/dgit/pseudomerge";
3681     open MC, ">", $pmf or die "$pmf $!";
3682     print MC <<END or die $!;
3683 tree $tree
3684 parent $dgitview
3685 parent $archive_hash
3686 author $authline
3687 committer $authline
3688
3689 $msg_msg
3690
3691 [$msg_cmd]
3692 END
3693     close MC or die $!;
3694
3695     return make_commit($pmf);
3696 }
3697
3698 sub splitbrain_pseudomerge ($$$$) {
3699     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3700     # => $merged_dgitview
3701     printdebug "splitbrain_pseudomerge...\n";
3702     #
3703     #     We:      debian/PREVIOUS    HEAD($maintview)
3704     # expect:          o ----------------- o
3705     #                    \                   \
3706     #                     o                   o
3707     #                 a/d/PREVIOUS        $dgitview
3708     #                $archive_hash              \
3709     #  If so,                \                   \
3710     #  we do:                 `------------------ o
3711     #   this:                                   $dgitview'
3712     #
3713
3714     return $dgitview unless defined $archive_hash;
3715
3716     printdebug "splitbrain_pseudomerge...\n";
3717
3718     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3719
3720     if (!defined $overwrite_version) {
3721         progress "Checking that HEAD inciudes all changes in archive...";
3722     }
3723
3724     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3725
3726     if (defined $overwrite_version) {
3727     } elsif (!eval {
3728         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3729         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3730         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3731         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3732         my $i_archive = [ $archive_hash, "current archive contents" ];
3733
3734         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3735
3736         infopair_cond_equal($i_dgit, $i_archive);
3737         infopair_cond_ff($i_dep14, $i_dgit);
3738         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3739         1;
3740     }) {
3741         print STDERR <<END;
3742 $us: check failed (maybe --overwrite is needed, consult documentation)
3743 END
3744         die "$@";
3745     }
3746
3747     my $r = pseudomerge_make_commit
3748         $clogp, $dgitview, $archive_hash, $i_arch_v,
3749         "dgit --quilt=$quilt_mode",
3750         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3751 Declare fast forward from $i_arch_v->[0]
3752 END_OVERWR
3753 Make fast forward from $i_arch_v->[0]
3754 END_MAKEFF
3755
3756     maybe_split_brain_save $maintview, $r, "pseudomerge";
3757
3758     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3759     return $r;
3760 }
3761
3762 sub plain_overwrite_pseudomerge ($$$) {
3763     my ($clogp, $head, $archive_hash) = @_;
3764
3765     printdebug "plain_overwrite_pseudomerge...";
3766
3767     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3768
3769     return $head if is_fast_fwd $archive_hash, $head;
3770
3771     my $m = "Declare fast forward from $i_arch_v->[0]";
3772
3773     my $r = pseudomerge_make_commit
3774         $clogp, $head, $archive_hash, $i_arch_v,
3775         "dgit", $m;
3776
3777     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3778
3779     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3780     return $r;
3781 }
3782
3783 sub push_parse_changelog ($) {
3784     my ($clogpfn) = @_;
3785
3786     my $clogp = Dpkg::Control::Hash->new();
3787     $clogp->load($clogpfn) or die;
3788
3789     my $clogpackage = getfield $clogp, 'Source';
3790     $package //= $clogpackage;
3791     fail "-p specified $package but changelog specified $clogpackage"
3792         unless $package eq $clogpackage;
3793     my $cversion = getfield $clogp, 'Version';
3794     my $tag = debiantag($cversion, access_nomdistro);
3795     runcmd @git, qw(check-ref-format), $tag;
3796
3797     my $dscfn = dscfn($cversion);
3798
3799     return ($clogp, $cversion, $dscfn);
3800 }
3801
3802 sub push_parse_dsc ($$$) {
3803     my ($dscfn,$dscfnwhat, $cversion) = @_;
3804     $dsc = parsecontrol($dscfn,$dscfnwhat);
3805     my $dversion = getfield $dsc, 'Version';
3806     my $dscpackage = getfield $dsc, 'Source';
3807     ($dscpackage eq $package && $dversion eq $cversion) or
3808         fail "$dscfn is for $dscpackage $dversion".
3809             " but debian/changelog is for $package $cversion";
3810 }
3811
3812 sub push_tagwants ($$$$) {
3813     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3814     my @tagwants;
3815     push @tagwants, {
3816         TagFn => \&debiantag,
3817         Objid => $dgithead,
3818         TfSuffix => '',
3819         View => 'dgit',
3820     };
3821     if (defined $maintviewhead) {
3822         push @tagwants, {
3823             TagFn => \&debiantag_maintview,
3824             Objid => $maintviewhead,
3825             TfSuffix => '-maintview',
3826             View => 'maint',
3827         };
3828     } elsif ($dodep14tag eq 'no' ? 0
3829              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3830              : $dodep14tag eq 'always'
3831              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3832 --dep14tag-always (or equivalent in config) means server must support
3833  both "new" and "maint" tag formats, but config says it doesn't.
3834 END
3835             : die "$dodep14tag ?") {
3836         push @tagwants, {
3837             TagFn => \&debiantag_maintview,
3838             Objid => $dgithead,
3839             TfSuffix => '-dgit',
3840             View => 'dgit',
3841         };
3842     };
3843     foreach my $tw (@tagwants) {
3844         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3845         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3846     }
3847     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3848     return @tagwants;
3849 }
3850
3851 sub push_mktags ($$ $$ $) {
3852     my ($clogp,$dscfn,
3853         $changesfile,$changesfilewhat,
3854         $tagwants) = @_;
3855
3856     die unless $tagwants->[0]{View} eq 'dgit';
3857
3858     my $declaredistro = access_nomdistro();
3859     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3860     $dsc->{$ourdscfield[0]} = join " ",
3861         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3862         $reader_giturl;
3863     $dsc->save("$dscfn.tmp") or die $!;
3864
3865     my $changes = parsecontrol($changesfile,$changesfilewhat);
3866     foreach my $field (qw(Source Distribution Version)) {
3867         $changes->{$field} eq $clogp->{$field} or
3868             fail "changes field $field \`$changes->{$field}'".
3869                 " does not match changelog \`$clogp->{$field}'";
3870     }
3871
3872     my $cversion = getfield $clogp, 'Version';
3873     my $clogsuite = getfield $clogp, 'Distribution';
3874
3875     # We make the git tag by hand because (a) that makes it easier
3876     # to control the "tagger" (b) we can do remote signing
3877     my $authline = clogp_authline $clogp;
3878     my $delibs = join(" ", "",@deliberatelies);
3879
3880     my $mktag = sub {
3881         my ($tw) = @_;
3882         my $tfn = $tw->{Tfn};
3883         my $head = $tw->{Objid};
3884         my $tag = $tw->{Tag};
3885
3886         open TO, '>', $tfn->('.tmp') or die $!;
3887         print TO <<END or die $!;
3888 object $head
3889 type commit
3890 tag $tag
3891 tagger $authline
3892
3893 END
3894         if ($tw->{View} eq 'dgit') {
3895             print TO <<END or die $!;
3896 $package release $cversion for $clogsuite ($csuite) [dgit]
3897 [dgit distro=$declaredistro$delibs]
3898 END
3899             foreach my $ref (sort keys %previously) {
3900                 print TO <<END or die $!;
3901 [dgit previously:$ref=$previously{$ref}]
3902 END
3903             }
3904         } elsif ($tw->{View} eq 'maint') {
3905             print TO <<END or die $!;
3906 $package release $cversion for $clogsuite ($csuite)
3907 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3908 END
3909         } else {
3910             die Dumper($tw)."?";
3911         }
3912
3913         close TO or die $!;
3914
3915         my $tagobjfn = $tfn->('.tmp');
3916         if ($sign) {
3917             if (!defined $keyid) {
3918                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3919             }
3920             if (!defined $keyid) {
3921                 $keyid = getfield $clogp, 'Maintainer';
3922             }
3923             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3924             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3925             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3926             push @sign_cmd, $tfn->('.tmp');
3927             runcmd_ordryrun @sign_cmd;
3928             if (act_scary()) {
3929                 $tagobjfn = $tfn->('.signed.tmp');
3930                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3931                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3932             }
3933         }
3934         return $tagobjfn;
3935     };
3936
3937     my @r = map { $mktag->($_); } @$tagwants;
3938     return @r;
3939 }
3940
3941 sub sign_changes ($) {
3942     my ($changesfile) = @_;
3943     if ($sign) {
3944         my @debsign_cmd = @debsign;
3945         push @debsign_cmd, "-k$keyid" if defined $keyid;
3946         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3947         push @debsign_cmd, $changesfile;
3948         runcmd_ordryrun @debsign_cmd;
3949     }
3950 }
3951
3952 sub dopush () {
3953     printdebug "actually entering push\n";
3954
3955     supplementary_message(<<'END');
3956 Push failed, while checking state of the archive.
3957 You can retry the push, after fixing the problem, if you like.
3958 END
3959     if (check_for_git()) {
3960         git_fetch_us();
3961     }
3962     my $archive_hash = fetch_from_archive();
3963     if (!$archive_hash) {
3964         $new_package or
3965             fail "package appears to be new in this suite;".
3966                 " if this is intentional, use --new";
3967     }
3968
3969     supplementary_message(<<'END');
3970 Push failed, while preparing your push.
3971 You can retry the push, after fixing the problem, if you like.
3972 END
3973
3974     need_tagformat 'new', "quilt mode $quilt_mode"
3975         if quiltmode_splitbrain;
3976
3977     prep_ud();
3978
3979     access_giturl(); # check that success is vaguely likely
3980     select_tagformat();
3981
3982     my $clogpfn = ".git/dgit/changelog.822.tmp";
3983     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
3984
3985     responder_send_file('parsed-changelog', $clogpfn);
3986
3987     my ($clogp, $cversion, $dscfn) =
3988         push_parse_changelog("$clogpfn");
3989
3990     my $dscpath = "$buildproductsdir/$dscfn";
3991     stat_exists $dscpath or
3992         fail "looked for .dsc $dscpath, but $!;".
3993             " maybe you forgot to build";
3994
3995     responder_send_file('dsc', $dscpath);
3996
3997     push_parse_dsc($dscpath, $dscfn, $cversion);
3998
3999     my $format = getfield $dsc, 'Format';
4000     printdebug "format $format\n";
4001
4002     my $actualhead = git_rev_parse('HEAD');
4003     my $dgithead = $actualhead;
4004     my $maintviewhead = undef;
4005
4006     my $upstreamversion = upstreamversion $clogp->{Version};
4007
4008     if (madformat_wantfixup($format)) {
4009         # user might have not used dgit build, so maybe do this now:
4010         if (quiltmode_splitbrain()) {
4011             changedir $ud;
4012             quilt_make_fake_dsc($upstreamversion);
4013             my $cachekey;
4014             ($dgithead, $cachekey) =
4015                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4016             $dgithead or fail
4017  "--quilt=$quilt_mode but no cached dgit view:
4018  perhaps tree changed since dgit build[-source] ?";
4019             $split_brain = 1;
4020             $dgithead = splitbrain_pseudomerge($clogp,
4021                                                $actualhead, $dgithead,
4022                                                $archive_hash);
4023             $maintviewhead = $actualhead;
4024             changedir '../../../..';
4025             prep_ud(); # so _only_subdir() works, below
4026         } else {
4027             commit_quilty_patch();
4028         }
4029     }
4030
4031     if (defined $overwrite_version && !defined $maintviewhead) {
4032         $dgithead = plain_overwrite_pseudomerge($clogp,
4033                                                 $dgithead,
4034                                                 $archive_hash);
4035     }
4036
4037     check_not_dirty();
4038
4039     my $forceflag = '';
4040     if ($archive_hash) {
4041         if (is_fast_fwd($archive_hash, $dgithead)) {
4042             # ok
4043         } elsif (deliberately_not_fast_forward) {
4044             $forceflag = '+';
4045         } else {
4046             fail "dgit push: HEAD is not a descendant".
4047                 " of the archive's version.\n".
4048                 "To overwrite the archive's contents,".
4049                 " pass --overwrite[=VERSION].\n".
4050                 "To rewind history, if permitted by the archive,".
4051                 " use --deliberately-not-fast-forward.";
4052         }
4053     }
4054
4055     changedir $ud;
4056     progress "checking that $dscfn corresponds to HEAD";
4057     runcmd qw(dpkg-source -x --),
4058         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4059     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4060     check_for_vendor_patches() if madformat($dsc->{format});
4061     changedir '../../../..';
4062     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4063     debugcmd "+",@diffcmd;
4064     $!=0; $?=-1;
4065     my $r = system @diffcmd;
4066     if ($r) {
4067         if ($r==256) {
4068             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4069             fail <<END
4070 HEAD specifies a different tree to $dscfn:
4071 $diffs
4072 Perhaps you forgot to build.  Or perhaps there is a problem with your
4073  source tree (see dgit(7) for some hints).  To see a full diff, run
4074    git diff $tree HEAD
4075 END
4076         } else {
4077             failedcmd @diffcmd;
4078         }
4079     }
4080     if (!$changesfile) {
4081         my $pat = changespat $cversion;
4082         my @cs = glob "$buildproductsdir/$pat";
4083         fail "failed to find unique changes file".
4084             " (looked for $pat in $buildproductsdir);".
4085             " perhaps you need to use dgit -C"
4086             unless @cs==1;
4087         ($changesfile) = @cs;
4088     } else {
4089         $changesfile = "$buildproductsdir/$changesfile";
4090     }
4091
4092     # Check that changes and .dsc agree enough
4093     $changesfile =~ m{[^/]*$};
4094     my $changes = parsecontrol($changesfile,$&);
4095     files_compare_inputs($dsc, $changes)
4096         unless forceing [qw(dsc-changes-mismatch)];
4097
4098     # Perhaps adjust .dsc to contain right set of origs
4099     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4100                                   $changesfile)
4101         unless forceing [qw(changes-origs-exactly)];
4102
4103     # Checks complete, we're going to try and go ahead:
4104
4105     responder_send_file('changes',$changesfile);
4106     responder_send_command("param head $dgithead");
4107     responder_send_command("param csuite $csuite");
4108     responder_send_command("param tagformat $tagformat");
4109     if (defined $maintviewhead) {
4110         die unless ($protovsn//4) >= 4;
4111         responder_send_command("param maint-view $maintviewhead");
4112     }
4113
4114     if (deliberately_not_fast_forward) {
4115         git_for_each_ref(lrfetchrefs, sub {
4116             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4117             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4118             responder_send_command("previously $rrefname=$objid");
4119             $previously{$rrefname} = $objid;
4120         });
4121     }
4122
4123     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4124                                  ".git/dgit/tag");
4125     my @tagobjfns;
4126
4127     supplementary_message(<<'END');
4128 Push failed, while signing the tag.
4129 You can retry the push, after fixing the problem, if you like.
4130 END
4131     # If we manage to sign but fail to record it anywhere, it's fine.
4132     if ($we_are_responder) {
4133         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4134         responder_receive_files('signed-tag', @tagobjfns);
4135     } else {
4136         @tagobjfns = push_mktags($clogp,$dscpath,
4137                               $changesfile,$changesfile,
4138                               \@tagwants);
4139     }
4140     supplementary_message(<<'END');
4141 Push failed, *after* signing the tag.
4142 If you want to try again, you should use a new version number.
4143 END
4144
4145     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4146
4147     foreach my $tw (@tagwants) {
4148         my $tag = $tw->{Tag};
4149         my $tagobjfn = $tw->{TagObjFn};
4150         my $tag_obj_hash =
4151             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4152         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4153         runcmd_ordryrun_local
4154             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4155     }
4156
4157     supplementary_message(<<'END');
4158 Push failed, while updating the remote git repository - see messages above.
4159 If you want to try again, you should use a new version number.
4160 END
4161     if (!check_for_git()) {
4162         create_remote_git_repo();
4163     }
4164
4165     my @pushrefs = $forceflag.$dgithead.":".rrref();
4166     foreach my $tw (@tagwants) {
4167         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4168     }
4169
4170     runcmd_ordryrun @git,
4171         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4172     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4173
4174     supplementary_message(<<'END');
4175 Push failed, while obtaining signatures on the .changes and .dsc.
4176 If it was just that the signature failed, you may try again by using
4177 debsign by hand to sign the changes
4178    $changesfile
4179 and then dput to complete the upload.
4180 If you need to change the package, you must use a new version number.
4181 END
4182     if ($we_are_responder) {
4183         my $dryrunsuffix = act_local() ? "" : ".tmp";
4184         responder_receive_files('signed-dsc-changes',
4185                                 "$dscpath$dryrunsuffix",
4186                                 "$changesfile$dryrunsuffix");
4187     } else {
4188         if (act_local()) {
4189             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4190         } else {
4191             progress "[new .dsc left in $dscpath.tmp]";
4192         }
4193         sign_changes $changesfile;
4194     }
4195
4196     supplementary_message(<<END);
4197 Push failed, while uploading package(s) to the archive server.
4198 You can retry the upload of exactly these same files with dput of:
4199   $changesfile
4200 If that .changes file is broken, you will need to use a new version
4201 number for your next attempt at the upload.
4202 END
4203     my $host = access_cfg('upload-host','RETURN-UNDEF');
4204     my @hostarg = defined($host) ? ($host,) : ();
4205     runcmd_ordryrun @dput, @hostarg, $changesfile;
4206     printdone "pushed and uploaded $cversion";
4207
4208     supplementary_message('');
4209     responder_send_command("complete");
4210 }
4211
4212 sub cmd_clone {
4213     parseopts();
4214     my $dstdir;
4215     badusage "-p is not allowed with clone; specify as argument instead"
4216         if defined $package;
4217     if (@ARGV==1) {
4218         ($package) = @ARGV;
4219     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4220         ($package,$isuite) = @ARGV;
4221     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4222         ($package,$dstdir) = @ARGV;
4223     } elsif (@ARGV==3) {
4224         ($package,$isuite,$dstdir) = @ARGV;
4225     } else {
4226         badusage "incorrect arguments to dgit clone";
4227     }
4228     notpushing();
4229
4230     $dstdir ||= "$package";
4231     if (stat_exists $dstdir) {
4232         fail "$dstdir already exists";
4233     }
4234
4235     my $cwd_remove;
4236     if ($rmonerror && !$dryrun_level) {
4237         $cwd_remove= getcwd();
4238         unshift @end, sub {
4239             return unless defined $cwd_remove;
4240             if (!chdir "$cwd_remove") {
4241                 return if $!==&ENOENT;
4242                 die "chdir $cwd_remove: $!";
4243             }
4244             printdebug "clone rmonerror removing $dstdir\n";
4245             if (stat $dstdir) {
4246                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4247             } elsif (grep { $! == $_ }
4248                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4249             } else {
4250                 print STDERR "check whether to remove $dstdir: $!\n";
4251             }
4252         };
4253     }
4254
4255     clone($dstdir);
4256     $cwd_remove = undef;
4257 }
4258
4259 sub branchsuite () {
4260     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4261     if ($branch =~ m#$lbranch_re#o) {
4262         return $1;
4263     } else {
4264         return undef;
4265     }
4266 }
4267
4268 sub fetchpullargs () {
4269     if (!defined $package) {
4270         my $sourcep = parsecontrol('debian/control','debian/control');
4271         $package = getfield $sourcep, 'Source';
4272     }
4273     if (@ARGV==0) {
4274         $isuite = branchsuite();
4275         if (!$isuite) {
4276             my $clogp = parsechangelog();
4277             $isuite = getfield $clogp, 'Distribution';
4278         }
4279     } elsif (@ARGV==1) {
4280         ($isuite) = @ARGV;
4281     } else {
4282         badusage "incorrect arguments to dgit fetch or dgit pull";
4283     }
4284     notpushing();
4285 }
4286
4287 sub cmd_fetch {
4288     parseopts();
4289     fetchpullargs();
4290     my $multi_fetched = fork_for_multisuite(sub { });
4291     exit 0 if $multi_fetched;
4292     fetch();
4293 }
4294
4295 sub cmd_pull {
4296     parseopts();
4297     fetchpullargs();
4298     if (quiltmode_splitbrain()) {
4299         my ($format, $fopts) = get_source_format();
4300         madformat($format) and fail <<END
4301 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4302 END
4303     }
4304     pull();
4305 }
4306
4307 sub cmd_push {
4308     parseopts();
4309     pushing();
4310     badusage "-p is not allowed with dgit push" if defined $package;
4311     check_not_dirty();
4312     my $clogp = parsechangelog();
4313     $package = getfield $clogp, 'Source';
4314     my $specsuite;
4315     if (@ARGV==0) {
4316     } elsif (@ARGV==1) {
4317         ($specsuite) = (@ARGV);
4318     } else {
4319         badusage "incorrect arguments to dgit push";
4320     }
4321     $isuite = getfield $clogp, 'Distribution';
4322     if ($new_package) {
4323         local ($package) = $existing_package; # this is a hack
4324         canonicalise_suite();
4325     } else {
4326         canonicalise_suite();
4327     }
4328     if (defined $specsuite &&
4329         $specsuite ne $isuite &&
4330         $specsuite ne $csuite) {
4331             fail "dgit push: changelog specifies $isuite ($csuite)".
4332                 " but command line specifies $specsuite";
4333     }
4334     dopush();
4335 }
4336
4337 #---------- remote commands' implementation ----------
4338
4339 sub cmd_remote_push_build_host {
4340     my ($nrargs) = shift @ARGV;
4341     my (@rargs) = @ARGV[0..$nrargs-1];
4342     @ARGV = @ARGV[$nrargs..$#ARGV];
4343     die unless @rargs;
4344     my ($dir,$vsnwant) = @rargs;
4345     # vsnwant is a comma-separated list; we report which we have
4346     # chosen in our ready response (so other end can tell if they
4347     # offered several)
4348     $debugprefix = ' ';
4349     $we_are_responder = 1;
4350     $us .= " (build host)";
4351
4352     pushing();
4353
4354     open PI, "<&STDIN" or die $!;
4355     open STDIN, "/dev/null" or die $!;
4356     open PO, ">&STDOUT" or die $!;
4357     autoflush PO 1;
4358     open STDOUT, ">&STDERR" or die $!;
4359     autoflush STDOUT 1;
4360
4361     $vsnwant //= 1;
4362     ($protovsn) = grep {
4363         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4364     } @rpushprotovsn_support;
4365
4366     fail "build host has dgit rpush protocol versions ".
4367         (join ",", @rpushprotovsn_support).
4368         " but invocation host has $vsnwant"
4369         unless defined $protovsn;
4370
4371     responder_send_command("dgit-remote-push-ready $protovsn");
4372     rpush_handle_protovsn_bothends();
4373     changedir $dir;
4374     &cmd_push;
4375 }
4376
4377 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4378 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4379 #     a good error message)
4380
4381 sub rpush_handle_protovsn_bothends () {
4382     if ($protovsn < 4) {
4383         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4384     }
4385     select_tagformat();
4386 }
4387
4388 our $i_tmp;
4389
4390 sub i_cleanup {
4391     local ($@, $?);
4392     my $report = i_child_report();
4393     if (defined $report) {
4394         printdebug "($report)\n";
4395     } elsif ($i_child_pid) {
4396         printdebug "(killing build host child $i_child_pid)\n";
4397         kill 15, $i_child_pid;
4398     }
4399     if (defined $i_tmp && !defined $initiator_tempdir) {
4400         changedir "/";
4401         eval { rmtree $i_tmp; };
4402     }
4403 }
4404
4405 END { i_cleanup(); }
4406
4407 sub i_method {
4408     my ($base,$selector,@args) = @_;
4409     $selector =~ s/\-/_/g;
4410     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4411 }
4412
4413 sub cmd_rpush {
4414     pushing();
4415     my $host = nextarg;
4416     my $dir;
4417     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4418         $host = $1;
4419         $dir = $'; #';
4420     } else {
4421         $dir = nextarg;
4422     }
4423     $dir =~ s{^-}{./-};
4424     my @rargs = ($dir);
4425     push @rargs, join ",", @rpushprotovsn_support;
4426     my @rdgit;
4427     push @rdgit, @dgit;
4428     push @rdgit, @ropts;
4429     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4430     push @rdgit, @ARGV;
4431     my @cmd = (@ssh, $host, shellquote @rdgit);
4432     debugcmd "+",@cmd;
4433
4434     if (defined $initiator_tempdir) {
4435         rmtree $initiator_tempdir;
4436         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4437         $i_tmp = $initiator_tempdir;
4438     } else {
4439         $i_tmp = tempdir();
4440     }
4441     $i_child_pid = open2(\*RO, \*RI, @cmd);
4442     changedir $i_tmp;
4443     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4444     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4445     $supplementary_message = '' unless $protovsn >= 3;
4446
4447     fail "rpush negotiated protocol version $protovsn".
4448         " which does not support quilt mode $quilt_mode"
4449         if quiltmode_splitbrain;
4450
4451     rpush_handle_protovsn_bothends();
4452     for (;;) {
4453         my ($icmd,$iargs) = initiator_expect {
4454             m/^(\S+)(?: (.*))?$/;
4455             ($1,$2);
4456         };
4457         i_method "i_resp", $icmd, $iargs;
4458     }
4459 }
4460
4461 sub i_resp_progress ($) {
4462     my ($rhs) = @_;
4463     my $msg = protocol_read_bytes \*RO, $rhs;
4464     progress $msg;
4465 }
4466
4467 sub i_resp_supplementary_message ($) {
4468     my ($rhs) = @_;
4469     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4470 }
4471
4472 sub i_resp_complete {
4473     my $pid = $i_child_pid;
4474     $i_child_pid = undef; # prevents killing some other process with same pid
4475     printdebug "waiting for build host child $pid...\n";
4476     my $got = waitpid $pid, 0;
4477     die $! unless $got == $pid;
4478     die "build host child failed $?" if $?;
4479
4480     i_cleanup();
4481     printdebug "all done\n";
4482     exit 0;
4483 }
4484
4485 sub i_resp_file ($) {
4486     my ($keyword) = @_;
4487     my $localname = i_method "i_localname", $keyword;
4488     my $localpath = "$i_tmp/$localname";
4489     stat_exists $localpath and
4490         badproto \*RO, "file $keyword ($localpath) twice";
4491     protocol_receive_file \*RO, $localpath;
4492     i_method "i_file", $keyword;
4493 }
4494
4495 our %i_param;
4496
4497 sub i_resp_param ($) {
4498     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4499     $i_param{$1} = $2;
4500 }
4501
4502 sub i_resp_previously ($) {
4503     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4504         or badproto \*RO, "bad previously spec";
4505     my $r = system qw(git check-ref-format), $1;
4506     die "bad previously ref spec ($r)" if $r;
4507     $previously{$1} = $2;
4508 }
4509
4510 our %i_wanted;
4511
4512 sub i_resp_want ($) {
4513     my ($keyword) = @_;
4514     die "$keyword ?" if $i_wanted{$keyword}++;
4515     my @localpaths = i_method "i_want", $keyword;
4516     printdebug "[[  $keyword @localpaths\n";
4517     foreach my $localpath (@localpaths) {
4518         protocol_send_file \*RI, $localpath;
4519     }
4520     print RI "files-end\n" or die $!;
4521 }
4522
4523 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4524
4525 sub i_localname_parsed_changelog {
4526     return "remote-changelog.822";
4527 }
4528 sub i_file_parsed_changelog {
4529     ($i_clogp, $i_version, $i_dscfn) =
4530         push_parse_changelog "$i_tmp/remote-changelog.822";
4531     die if $i_dscfn =~ m#/|^\W#;
4532 }
4533
4534 sub i_localname_dsc {
4535     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4536     return $i_dscfn;
4537 }
4538 sub i_file_dsc { }
4539
4540 sub i_localname_changes {
4541     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4542     $i_changesfn = $i_dscfn;
4543     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4544     return $i_changesfn;
4545 }
4546 sub i_file_changes { }
4547
4548 sub i_want_signed_tag {
4549     printdebug Dumper(\%i_param, $i_dscfn);
4550     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4551         && defined $i_param{'csuite'}
4552         or badproto \*RO, "premature desire for signed-tag";
4553     my $head = $i_param{'head'};
4554     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4555
4556     my $maintview = $i_param{'maint-view'};
4557     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4558
4559     select_tagformat();
4560     if ($protovsn >= 4) {
4561         my $p = $i_param{'tagformat'} // '<undef>';
4562         $p eq $tagformat
4563             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4564     }
4565
4566     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4567     $csuite = $&;
4568     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4569
4570     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4571
4572     return
4573         push_mktags $i_clogp, $i_dscfn,
4574             $i_changesfn, 'remote changes',
4575             \@tagwants;
4576 }
4577
4578 sub i_want_signed_dsc_changes {
4579     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4580     sign_changes $i_changesfn;
4581     return ($i_dscfn, $i_changesfn);
4582 }
4583
4584 #---------- building etc. ----------
4585
4586 our $version;
4587 our $sourcechanges;
4588 our $dscfn;
4589
4590 #----- `3.0 (quilt)' handling -----
4591
4592 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4593
4594 sub quiltify_dpkg_commit ($$$;$) {
4595     my ($patchname,$author,$msg, $xinfo) = @_;
4596     $xinfo //= '';
4597
4598     mkpath '.git/dgit';
4599     my $descfn = ".git/dgit/quilt-description.tmp";
4600     open O, '>', $descfn or die "$descfn: $!";
4601     $msg =~ s/\n+/\n\n/;
4602     print O <<END or die $!;
4603 From: $author
4604 ${xinfo}Subject: $msg
4605 ---
4606
4607 END
4608     close O or die $!;
4609
4610     {
4611         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4612         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4613         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4614         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4615     }
4616 }
4617
4618 sub quiltify_trees_differ ($$;$$$) {
4619     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4620     # returns true iff the two tree objects differ other than in debian/
4621     # with $finegrained,
4622     # returns bitmask 01 - differ in upstream files except .gitignore
4623     #                 02 - differ in .gitignore
4624     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4625     #  is set for each modified .gitignore filename $fn
4626     # if $unrepres is defined, array ref to which is appeneded
4627     #  a list of unrepresentable changes (removals of upstream files
4628     #  (as messages)
4629     local $/=undef;
4630     my @cmd = (@git, qw(diff-tree -z));
4631     push @cmd, qw(--name-only) unless $unrepres;
4632     push @cmd, qw(-r) if $finegrained || $unrepres;
4633     push @cmd, $x, $y;
4634     my $diffs= cmdoutput @cmd;
4635     my $r = 0;
4636     my @lmodes;
4637     foreach my $f (split /\0/, $diffs) {
4638         if ($unrepres && !@lmodes) {
4639             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4640             next;
4641         }
4642         my ($oldmode,$newmode) = @lmodes;
4643         @lmodes = ();
4644
4645         next if $f =~ m#^debian(?:/.*)?$#s;
4646
4647         if ($unrepres) {
4648             eval {
4649                 die "not a plain file\n"
4650                     unless $newmode =~ m/^10\d{4}$/ ||
4651                            $oldmode =~ m/^10\d{4}$/;
4652                 if ($oldmode =~ m/[^0]/ &&
4653                     $newmode =~ m/[^0]/) {
4654                     die "mode changed\n" if $oldmode ne $newmode;
4655                 } else {
4656                     die "non-default mode\n"
4657                         unless $newmode =~ m/^100644$/ ||
4658                                $oldmode =~ m/^100644$/;
4659                 }
4660             };
4661             if ($@) {
4662                 local $/="\n"; chomp $@;
4663                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4664             }
4665         }
4666
4667         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4668         $r |= $isignore ? 02 : 01;
4669         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4670     }
4671     printdebug "quiltify_trees_differ $x $y => $r\n";
4672     return $r;
4673 }
4674
4675 sub quiltify_tree_sentinelfiles ($) {
4676     # lists the `sentinel' files present in the tree
4677     my ($x) = @_;
4678     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4679         qw(-- debian/rules debian/control);
4680     $r =~ s/\n/,/g;
4681     return $r;
4682 }
4683
4684 sub quiltify_splitbrain_needed () {
4685     if (!$split_brain) {
4686         progress "dgit view: changes are required...";
4687         runcmd @git, qw(checkout -q -b dgit-view);
4688         $split_brain = 1;
4689     }
4690 }
4691
4692 sub quiltify_splitbrain ($$$$$$) {
4693     my ($clogp, $unapplied, $headref, $diffbits,
4694         $editedignores, $cachekey) = @_;
4695     if ($quilt_mode !~ m/gbp|dpm/) {
4696         # treat .gitignore just like any other upstream file
4697         $diffbits = { %$diffbits };
4698         $_ = !!$_ foreach values %$diffbits;
4699     }
4700     # We would like any commits we generate to be reproducible
4701     my @authline = clogp_authline($clogp);
4702     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4703     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4704     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4705     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4706     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4707     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4708
4709     if ($quilt_mode =~ m/gbp|unapplied/ &&
4710         ($diffbits->{O2H} & 01)) {
4711         my $msg =
4712  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4713  " but git tree differs from orig in upstream files.";
4714         if (!stat_exists "debian/patches") {
4715             $msg .=
4716  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4717         }
4718         fail $msg;
4719     }
4720     if ($quilt_mode =~ m/dpm/ &&
4721         ($diffbits->{H2A} & 01)) {
4722         fail <<END;
4723 --quilt=$quilt_mode specified, implying patches-applied git tree
4724  but git tree differs from result of applying debian/patches to upstream
4725 END
4726     }
4727     if ($quilt_mode =~ m/gbp|unapplied/ &&
4728         ($diffbits->{O2A} & 01)) { # some patches
4729         quiltify_splitbrain_needed();
4730         progress "dgit view: creating patches-applied version using gbp pq";
4731         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4732         # gbp pq import creates a fresh branch; push back to dgit-view
4733         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4734         runcmd @git, qw(checkout -q dgit-view);
4735     }
4736     if ($quilt_mode =~ m/gbp|dpm/ &&
4737         ($diffbits->{O2A} & 02)) {
4738         fail <<END
4739 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4740  tool which does not create patches for changes to upstream
4741  .gitignores: but, such patches exist in debian/patches.
4742 END
4743     }
4744     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4745         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4746         quiltify_splitbrain_needed();
4747         progress "dgit view: creating patch to represent .gitignore changes";
4748         ensuredir "debian/patches";
4749         my $gipatch = "debian/patches/auto-gitignore";
4750         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4751         stat GIPATCH or die "$gipatch: $!";
4752         fail "$gipatch already exists; but want to create it".
4753             " to record .gitignore changes" if (stat _)[7];
4754         print GIPATCH <<END or die "$gipatch: $!";
4755 Subject: Update .gitignore from Debian packaging branch
4756
4757 The Debian packaging git branch contains these updates to the upstream
4758 .gitignore file(s).  This patch is autogenerated, to provide these
4759 updates to users of the official Debian archive view of the package.
4760
4761 [dgit ($our_version) update-gitignore]
4762 ---
4763 END
4764         close GIPATCH or die "$gipatch: $!";
4765         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4766             $unapplied, $headref, "--", sort keys %$editedignores;
4767         open SERIES, "+>>", "debian/patches/series" or die $!;
4768         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4769         my $newline;
4770         defined read SERIES, $newline, 1 or die $!;
4771         print SERIES "\n" or die $! unless $newline eq "\n";
4772         print SERIES "auto-gitignore\n" or die $!;
4773         close SERIES or die  $!;
4774         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4775         commit_admin <<END
4776 Commit patch to update .gitignore
4777
4778 [dgit ($our_version) update-gitignore-quilt-fixup]
4779 END
4780     }
4781
4782     my $dgitview = git_rev_parse 'HEAD';
4783
4784     changedir '../../../..';
4785     # When we no longer need to support squeeze, use --create-reflog
4786     # instead of this:
4787     ensuredir ".git/logs/refs/dgit-intern";
4788     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4789       or die $!;
4790
4791     my $oldcache = git_get_ref "refs/$splitbraincache";
4792     if ($oldcache eq $dgitview) {
4793         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4794         # git update-ref doesn't always update, in this case.  *sigh*
4795         my $dummy = make_commit_text <<END;
4796 tree $tree
4797 parent $dgitview
4798 author Dgit <dgit\@example.com> 1000000000 +0000
4799 committer Dgit <dgit\@example.com> 1000000000 +0000
4800
4801 Dummy commit - do not use
4802 END
4803         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4804             "refs/$splitbraincache", $dummy;
4805     }
4806     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4807         $dgitview;
4808
4809     changedir '.git/dgit/unpack/work';
4810
4811     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4812     progress "dgit view: created ($saved)";
4813 }
4814
4815 sub quiltify ($$$$) {
4816     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4817
4818     # Quilt patchification algorithm
4819     #
4820     # We search backwards through the history of the main tree's HEAD
4821     # (T) looking for a start commit S whose tree object is identical
4822     # to to the patch tip tree (ie the tree corresponding to the
4823     # current dpkg-committed patch series).  For these purposes
4824     # `identical' disregards anything in debian/ - this wrinkle is
4825     # necessary because dpkg-source treates debian/ specially.
4826     #
4827     # We can only traverse edges where at most one of the ancestors'
4828     # trees differs (in changes outside in debian/).  And we cannot
4829     # handle edges which change .pc/ or debian/patches.  To avoid
4830     # going down a rathole we avoid traversing edges which introduce
4831     # debian/rules or debian/control.  And we set a limit on the
4832     # number of edges we are willing to look at.
4833     #
4834     # If we succeed, we walk forwards again.  For each traversed edge
4835     # PC (with P parent, C child) (starting with P=S and ending with
4836     # C=T) to we do this:
4837     #  - git checkout C
4838     #  - dpkg-source --commit with a patch name and message derived from C
4839     # After traversing PT, we git commit the changes which
4840     # should be contained within debian/patches.
4841
4842     # The search for the path S..T is breadth-first.  We maintain a
4843     # todo list containing search nodes.  A search node identifies a
4844     # commit, and looks something like this:
4845     #  $p = {
4846     #      Commit => $git_commit_id,
4847     #      Child => $c,                          # or undef if P=T
4848     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4849     #      Nontrivial => true iff $p..$c has relevant changes
4850     #  };
4851
4852     my @todo;
4853     my @nots;
4854     my $sref_S;
4855     my $max_work=100;
4856     my %considered; # saves being exponential on some weird graphs
4857
4858     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4859
4860     my $not = sub {
4861         my ($search,$whynot) = @_;
4862         printdebug " search NOT $search->{Commit} $whynot\n";
4863         $search->{Whynot} = $whynot;
4864         push @nots, $search;
4865         no warnings qw(exiting);
4866         next;
4867     };
4868
4869     push @todo, {
4870         Commit => $target,
4871     };
4872
4873     while (@todo) {
4874         my $c = shift @todo;
4875         next if $considered{$c->{Commit}}++;
4876
4877         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
4878
4879         printdebug "quiltify investigate $c->{Commit}\n";
4880
4881         # are we done?
4882         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
4883             printdebug " search finished hooray!\n";
4884             $sref_S = $c;
4885             last;
4886         }
4887
4888         if ($quilt_mode eq 'nofix') {
4889             fail "quilt fixup required but quilt mode is \`nofix'\n".
4890                 "HEAD commit $c->{Commit} differs from tree implied by ".
4891                 " debian/patches (tree object $oldtiptree)";
4892         }
4893         if ($quilt_mode eq 'smash') {
4894             printdebug " search quitting smash\n";
4895             last;
4896         }
4897
4898         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
4899         $not->($c, "has $c_sentinels not $t_sentinels")
4900             if $c_sentinels ne $t_sentinels;
4901
4902         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
4903         $commitdata =~ m/\n\n/;
4904         $commitdata =~ $`;
4905         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
4906         @parents = map { { Commit => $_, Child => $c } } @parents;
4907
4908         $not->($c, "root commit") if !@parents;
4909
4910         foreach my $p (@parents) {
4911             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
4912         }
4913         my $ndiffers = grep { $_->{Nontrivial} } @parents;
4914         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
4915
4916         foreach my $p (@parents) {
4917             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
4918
4919             my @cmd= (@git, qw(diff-tree -r --name-only),
4920                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
4921             my $patchstackchange = cmdoutput @cmd;
4922             if (length $patchstackchange) {
4923                 $patchstackchange =~ s/\n/,/g;
4924                 $not->($p, "changed $patchstackchange");
4925             }
4926
4927             printdebug " search queue P=$p->{Commit} ",
4928                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
4929             push @todo, $p;
4930         }
4931     }
4932
4933     if (!$sref_S) {
4934         printdebug "quiltify want to smash\n";
4935
4936         my $abbrev = sub {
4937             my $x = $_[0]{Commit};
4938             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
4939             return $x;
4940         };
4941         my $reportnot = sub {
4942             my ($notp) = @_;
4943             my $s = $abbrev->($notp);
4944             my $c = $notp->{Child};
4945             $s .= "..".$abbrev->($c) if $c;
4946             $s .= ": ".$notp->{Whynot};
4947             return $s;
4948         };
4949         if ($quilt_mode eq 'linear') {
4950             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
4951             foreach my $notp (@nots) {
4952                 print STDERR "$us:  ", $reportnot->($notp), "\n";
4953             }
4954             print STDERR "$us: $_\n" foreach @$failsuggestion;
4955             fail "quilt fixup naive history linearisation failed.\n".
4956  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
4957         } elsif ($quilt_mode eq 'smash') {
4958         } elsif ($quilt_mode eq 'auto') {
4959             progress "quilt fixup cannot be linear, smashing...";
4960         } else {
4961             die "$quilt_mode ?";
4962         }
4963
4964         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
4965         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
4966         my $ncommits = 3;
4967         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
4968
4969         quiltify_dpkg_commit "auto-$version-$target-$time",
4970             (getfield $clogp, 'Maintainer'),
4971             "Automatically generated patch ($clogp->{Version})\n".
4972             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
4973         return;
4974     }
4975
4976     progress "quiltify linearisation planning successful, executing...";
4977
4978     for (my $p = $sref_S;
4979          my $c = $p->{Child};
4980          $p = $p->{Child}) {
4981         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
4982         next unless $p->{Nontrivial};
4983
4984         my $cc = $c->{Commit};
4985
4986         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
4987         $commitdata =~ m/\n\n/ or die "$c ?";
4988         $commitdata = $`;
4989         my $msg = $'; #';
4990         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
4991         my $author = $1;
4992
4993         my $commitdate = cmdoutput
4994             @git, qw(log -n1 --pretty=format:%aD), $cc;
4995
4996         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
4997
4998         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
4999         $strip_nls->();
5000
5001         my $title = $1;
5002         my $patchname;
5003         my $patchdir;
5004
5005         my $gbp_check_suitable = sub {
5006             $_ = shift;
5007             my ($what) = @_;
5008
5009             eval {
5010                 die "contains unexpected slashes\n" if m{//} || m{/$};
5011                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5012                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5013                 die "too long" if length > 200;
5014             };
5015             return $_ unless $@;
5016             print STDERR "quiltifying commit $cc:".
5017                 " ignoring/dropping Gbp-Pq $what: $@";
5018             return undef;
5019         };
5020
5021         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5022                            gbp-pq-name: \s* )
5023                        (\S+) \s* \n //ixm) {
5024             $patchname = $gbp_check_suitable->($1, 'Name');
5025         }
5026         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5027                            gbp-pq-topic: \s* )
5028                        (\S+) \s* \n //ixm) {
5029             $patchdir = $gbp_check_suitable->($1, 'Topic');
5030         }
5031
5032         $strip_nls->();
5033
5034         if (!defined $patchname) {
5035             $patchname = $title;
5036             $patchname =~ s/[.:]$//;
5037             use Text::Iconv;
5038             eval {
5039                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5040                 my $translitname = $converter->convert($patchname);
5041                 die unless defined $translitname;
5042                 $patchname = $translitname;
5043             };
5044             print STDERR
5045                 "dgit: patch title transliteration error: $@"
5046                 if $@;
5047             $patchname =~ y/ A-Z/-a-z/;
5048             $patchname =~ y/-a-z0-9_.+=~//cd;
5049             $patchname =~ s/^\W/x-$&/;
5050             $patchname = substr($patchname,0,40);
5051         }
5052         if (!defined $patchdir) {
5053             $patchdir = '';
5054         }
5055         if (length $patchdir) {
5056             $patchname = "$patchdir/$patchname";
5057         }
5058         if ($patchname =~ m{^(.*)/}) {
5059             mkpath "debian/patches/$1";
5060         }
5061
5062         my $index;
5063         for ($index='';
5064              stat "debian/patches/$patchname$index";
5065              $index++) { }
5066         $!==ENOENT or die "$patchname$index $!";
5067
5068         runcmd @git, qw(checkout -q), $cc;
5069
5070         # We use the tip's changelog so that dpkg-source doesn't
5071         # produce complaining messages from dpkg-parsechangelog.  None
5072         # of the information dpkg-source gets from the changelog is
5073         # actually relevant - it gets put into the original message
5074         # which dpkg-source provides our stunt editor, and then
5075         # overwritten.
5076         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5077
5078         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5079             "Date: $commitdate\n".
5080             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5081
5082         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5083     }
5084
5085     runcmd @git, qw(checkout -q master);
5086 }
5087
5088 sub build_maybe_quilt_fixup () {
5089     my ($format,$fopts) = get_source_format;
5090     return unless madformat_wantfixup $format;
5091     # sigh
5092
5093     check_for_vendor_patches();
5094
5095     if (quiltmode_splitbrain) {
5096         fail <<END unless access_cfg_tagformats_can_splitbrain;
5097 quilt mode $quilt_mode requires split view so server needs to support
5098  both "new" and "maint" tag formats, but config says it doesn't.
5099 END
5100     }
5101
5102     my $clogp = parsechangelog();
5103     my $headref = git_rev_parse('HEAD');
5104
5105     prep_ud();
5106     changedir $ud;
5107
5108     my $upstreamversion = upstreamversion $version;
5109
5110     if ($fopts->{'single-debian-patch'}) {
5111         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5112     } else {
5113         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5114     }
5115
5116     die 'bug' if $split_brain && !$need_split_build_invocation;
5117
5118     changedir '../../../..';
5119     runcmd_ordryrun_local
5120         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5121 }
5122
5123 sub quilt_fixup_mkwork ($) {
5124     my ($headref) = @_;
5125
5126     mkdir "work" or die $!;
5127     changedir "work";
5128     mktree_in_ud_here();
5129     runcmd @git, qw(reset -q --hard), $headref;
5130 }
5131
5132 sub quilt_fixup_linkorigs ($$) {
5133     my ($upstreamversion, $fn) = @_;
5134     # calls $fn->($leafname);
5135
5136     foreach my $f (<../../../../*>) { #/){
5137         my $b=$f; $b =~ s{.*/}{};
5138         {
5139             local ($debuglevel) = $debuglevel-1;
5140             printdebug "QF linkorigs $b, $f ?\n";
5141         }
5142         next unless is_orig_file_of_vsn $b, $upstreamversion;
5143         printdebug "QF linkorigs $b, $f Y\n";
5144         link_ltarget $f, $b or die "$b $!";
5145         $fn->($b);
5146     }
5147 }
5148
5149 sub quilt_fixup_delete_pc () {
5150     runcmd @git, qw(rm -rqf .pc);
5151     commit_admin <<END
5152 Commit removal of .pc (quilt series tracking data)
5153
5154 [dgit ($our_version) upgrade quilt-remove-pc]
5155 END
5156 }
5157
5158 sub quilt_fixup_singlepatch ($$$) {
5159     my ($clogp, $headref, $upstreamversion) = @_;
5160
5161     progress "starting quiltify (single-debian-patch)";
5162
5163     # dpkg-source --commit generates new patches even if
5164     # single-debian-patch is in debian/source/options.  In order to
5165     # get it to generate debian/patches/debian-changes, it is
5166     # necessary to build the source package.
5167
5168     quilt_fixup_linkorigs($upstreamversion, sub { });
5169     quilt_fixup_mkwork($headref);
5170
5171     rmtree("debian/patches");
5172
5173     runcmd @dpkgsource, qw(-b .);
5174     changedir "..";
5175     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5176     rename srcfn("$upstreamversion", "/debian/patches"),
5177            "work/debian/patches";
5178
5179     changedir "work";
5180     commit_quilty_patch();
5181 }
5182
5183 sub quilt_make_fake_dsc ($) {
5184     my ($upstreamversion) = @_;
5185
5186     my $fakeversion="$upstreamversion-~~DGITFAKE";
5187
5188     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5189     print $fakedsc <<END or die $!;
5190 Format: 3.0 (quilt)
5191 Source: $package
5192 Version: $fakeversion
5193 Files:
5194 END
5195
5196     my $dscaddfile=sub {
5197         my ($b) = @_;
5198
5199         my $md = new Digest::MD5;
5200
5201         my $fh = new IO::File $b, '<' or die "$b $!";
5202         stat $fh or die $!;
5203         my $size = -s _;
5204
5205         $md->addfile($fh);
5206         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5207     };
5208
5209     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5210
5211     my @files=qw(debian/source/format debian/rules
5212                  debian/control debian/changelog);
5213     foreach my $maybe (qw(debian/patches debian/source/options
5214                           debian/tests/control)) {
5215         next unless stat_exists "../../../$maybe";
5216         push @files, $maybe;
5217     }
5218
5219     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5220     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5221
5222     $dscaddfile->($debtar);
5223     close $fakedsc or die $!;
5224 }
5225
5226 sub quilt_check_splitbrain_cache ($$) {
5227     my ($headref, $upstreamversion) = @_;
5228     # Called only if we are in (potentially) split brain mode.
5229     # Called in $ud.
5230     # Computes the cache key and looks in the cache.
5231     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5232
5233     my $splitbrain_cachekey;
5234
5235     progress
5236  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5237     # we look in the reflog of dgit-intern/quilt-cache
5238     # we look for an entry whose message is the key for the cache lookup
5239     my @cachekey = (qw(dgit), $our_version);
5240     push @cachekey, $upstreamversion;
5241     push @cachekey, $quilt_mode;
5242     push @cachekey, $headref;
5243
5244     push @cachekey, hashfile('fake.dsc');
5245
5246     my $srcshash = Digest::SHA->new(256);
5247     my %sfs = ( %INC, '$0(dgit)' => $0 );
5248     foreach my $sfk (sort keys %sfs) {
5249         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5250         $srcshash->add($sfk,"  ");
5251         $srcshash->add(hashfile($sfs{$sfk}));
5252         $srcshash->add("\n");
5253     }
5254     push @cachekey, $srcshash->hexdigest();
5255     $splitbrain_cachekey = "@cachekey";
5256
5257     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5258                $splitbraincache);
5259     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5260     debugcmd "|(probably)",@cmd;
5261     my $child = open GC, "-|";  defined $child or die $!;
5262     if (!$child) {
5263         chdir '../../..' or die $!;
5264         if (!stat ".git/logs/refs/$splitbraincache") {
5265             $! == ENOENT or die $!;
5266             printdebug ">(no reflog)\n";
5267             exit 0;
5268         }
5269         exec @cmd; die $!;
5270     }
5271     while (<GC>) {
5272         chomp;
5273         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5274         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5275
5276         my $cachehit = $1;
5277         quilt_fixup_mkwork($headref);
5278         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5279         if ($cachehit ne $headref) {
5280             progress "dgit view: found cached ($saved)";
5281             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5282             $split_brain = 1;
5283             return ($cachehit, $splitbrain_cachekey);
5284         }
5285         progress "dgit view: found cached, no changes required";
5286         return ($headref, $splitbrain_cachekey);
5287     }
5288     die $! if GC->error;
5289     failedcmd unless close GC;
5290
5291     printdebug "splitbrain cache miss\n";
5292     return (undef, $splitbrain_cachekey);
5293 }
5294
5295 sub quilt_fixup_multipatch ($$$) {
5296     my ($clogp, $headref, $upstreamversion) = @_;
5297
5298     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5299
5300     # Our objective is:
5301     #  - honour any existing .pc in case it has any strangeness
5302     #  - determine the git commit corresponding to the tip of
5303     #    the patch stack (if there is one)
5304     #  - if there is such a git commit, convert each subsequent
5305     #    git commit into a quilt patch with dpkg-source --commit
5306     #  - otherwise convert all the differences in the tree into
5307     #    a single git commit
5308     #
5309     # To do this we:
5310
5311     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5312     # dgit would include the .pc in the git tree.)  If there isn't
5313     # one, we need to generate one by unpacking the patches that we
5314     # have.
5315     #
5316     # We first look for a .pc in the git tree.  If there is one, we
5317     # will use it.  (This is not the normal case.)
5318     #
5319     # Otherwise need to regenerate .pc so that dpkg-source --commit
5320     # can work.  We do this as follows:
5321     #     1. Collect all relevant .orig from parent directory
5322     #     2. Generate a debian.tar.gz out of
5323     #         debian/{patches,rules,source/format,source/options}
5324     #     3. Generate a fake .dsc containing just these fields:
5325     #          Format Source Version Files
5326     #     4. Extract the fake .dsc
5327     #        Now the fake .dsc has a .pc directory.
5328     # (In fact we do this in every case, because in future we will
5329     # want to search for a good base commit for generating patches.)
5330     #
5331     # Then we can actually do the dpkg-source --commit
5332     #     1. Make a new working tree with the same object
5333     #        store as our main tree and check out the main
5334     #        tree's HEAD.
5335     #     2. Copy .pc from the fake's extraction, if necessary
5336     #     3. Run dpkg-source --commit
5337     #     4. If the result has changes to debian/, then
5338     #          - git add them them
5339     #          - git add .pc if we had a .pc in-tree
5340     #          - git commit
5341     #     5. If we had a .pc in-tree, delete it, and git commit
5342     #     6. Back in the main tree, fast forward to the new HEAD
5343
5344     # Another situation we may have to cope with is gbp-style
5345     # patches-unapplied trees.
5346     #
5347     # We would want to detect these, so we know to escape into
5348     # quilt_fixup_gbp.  However, this is in general not possible.
5349     # Consider a package with a one patch which the dgit user reverts
5350     # (with git revert or the moral equivalent).
5351     #
5352     # That is indistinguishable in contents from a patches-unapplied
5353     # tree.  And looking at the history to distinguish them is not
5354     # useful because the user might have made a confusing-looking git
5355     # history structure (which ought to produce an error if dgit can't
5356     # cope, not a silent reintroduction of an unwanted patch).
5357     #
5358     # So gbp users will have to pass an option.  But we can usually
5359     # detect their failure to do so: if the tree is not a clean
5360     # patches-applied tree, quilt linearisation fails, but the tree
5361     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5362     # they want --quilt=unapplied.
5363     #
5364     # To help detect this, when we are extracting the fake dsc, we
5365     # first extract it with --skip-patches, and then apply the patches
5366     # afterwards with dpkg-source --before-build.  That lets us save a
5367     # tree object corresponding to .origs.
5368
5369     my $splitbrain_cachekey;
5370
5371     quilt_make_fake_dsc($upstreamversion);
5372
5373     if (quiltmode_splitbrain()) {
5374         my $cachehit;
5375         ($cachehit, $splitbrain_cachekey) =
5376             quilt_check_splitbrain_cache($headref, $upstreamversion);
5377         return if $cachehit;
5378     }
5379
5380     runcmd qw(sh -ec),
5381         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5382
5383     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5384     rename $fakexdir, "fake" or die "$fakexdir $!";
5385
5386     changedir 'fake';
5387
5388     remove_stray_gits("source package");
5389     mktree_in_ud_here();
5390
5391     rmtree '.pc';
5392
5393     my $unapplied=git_add_write_tree();
5394     printdebug "fake orig tree object $unapplied\n";
5395
5396     ensuredir '.pc';
5397
5398     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5399     $!=0; $?=-1;
5400     if (system @bbcmd) {
5401         failedcmd @bbcmd if $? < 0;
5402         fail <<END;
5403 failed to apply your git tree's patch stack (from debian/patches/) to
5404  the corresponding upstream tarball(s).  Your source tree and .orig
5405  are probably too inconsistent.  dgit can only fix up certain kinds of
5406  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5407 END
5408     }
5409
5410     changedir '..';
5411
5412     quilt_fixup_mkwork($headref);
5413
5414     my $mustdeletepc=0;
5415     if (stat_exists ".pc") {
5416         -d _ or die;
5417         progress "Tree already contains .pc - will use it then delete it.";
5418         $mustdeletepc=1;
5419     } else {
5420         rename '../fake/.pc','.pc' or die $!;
5421     }
5422
5423     changedir '../fake';
5424     rmtree '.pc';
5425     my $oldtiptree=git_add_write_tree();
5426     printdebug "fake o+d/p tree object $unapplied\n";
5427     changedir '../work';
5428
5429
5430     # We calculate some guesswork now about what kind of tree this might
5431     # be.  This is mostly for error reporting.
5432
5433     my %editedignores;
5434     my @unrepres;
5435     my $diffbits = {
5436         # H = user's HEAD
5437         # O = orig, without patches applied
5438         # A = "applied", ie orig with H's debian/patches applied
5439         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5440                                      \%editedignores, \@unrepres),
5441         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5442         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5443     };
5444
5445     my @dl;
5446     foreach my $b (qw(01 02)) {
5447         foreach my $v (qw(O2H O2A H2A)) {
5448             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5449         }
5450     }
5451     printdebug "differences \@dl @dl.\n";
5452
5453     progress sprintf
5454 "$us: base trees orig=%.20s o+d/p=%.20s",
5455               $unapplied, $oldtiptree;
5456     progress sprintf
5457 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5458 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5459                              $dl[0], $dl[1],              $dl[3], $dl[4],
5460                                  $dl[2],                     $dl[5];
5461
5462     if (@unrepres) {
5463         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5464             foreach @unrepres;
5465         forceable_fail [qw(unrepresentable)], <<END;
5466 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5467 END
5468     }
5469
5470     my @failsuggestion;
5471     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5472         push @failsuggestion, "This might be a patches-unapplied branch.";
5473     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5474         push @failsuggestion, "This might be a patches-applied branch.";
5475     }
5476     push @failsuggestion, "Maybe you need to specify one of".
5477         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5478
5479     if (quiltmode_splitbrain()) {
5480         quiltify_splitbrain($clogp, $unapplied, $headref,
5481                             $diffbits, \%editedignores,
5482                             $splitbrain_cachekey);
5483         return;
5484     }
5485
5486     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5487     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5488
5489     if (!open P, '>>', ".pc/applied-patches") {
5490         $!==&ENOENT or die $!;
5491     } else {
5492         close P;
5493     }
5494
5495     commit_quilty_patch();
5496
5497     if ($mustdeletepc) {
5498         quilt_fixup_delete_pc();
5499     }
5500 }
5501
5502 sub quilt_fixup_editor () {
5503     my $descfn = $ENV{$fakeeditorenv};
5504     my $editing = $ARGV[$#ARGV];
5505     open I1, '<', $descfn or die "$descfn: $!";
5506     open I2, '<', $editing or die "$editing: $!";
5507     unlink $editing or die "$editing: $!";
5508     open O, '>', $editing or die "$editing: $!";
5509     while (<I1>) { print O or die $!; } I1->error and die $!;
5510     my $copying = 0;
5511     while (<I2>) {
5512         $copying ||= m/^\-\-\- /;
5513         next unless $copying;
5514         print O or die $!;
5515     }
5516     I2->error and die $!;
5517     close O or die $1;
5518     exit 0;
5519 }
5520
5521 sub maybe_apply_patches_dirtily () {
5522     return unless $quilt_mode =~ m/gbp|unapplied/;
5523     print STDERR <<END or die $!;
5524
5525 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5526 dgit: Have to apply the patches - making the tree dirty.
5527 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5528
5529 END
5530     $patches_applied_dirtily = 01;
5531     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5532     runcmd qw(dpkg-source --before-build .);
5533 }
5534
5535 sub maybe_unapply_patches_again () {
5536     progress "dgit: Unapplying patches again to tidy up the tree."
5537         if $patches_applied_dirtily;
5538     runcmd qw(dpkg-source --after-build .)
5539         if $patches_applied_dirtily & 01;
5540     rmtree '.pc'
5541         if $patches_applied_dirtily & 02;
5542     $patches_applied_dirtily = 0;
5543 }
5544
5545 #----- other building -----
5546
5547 our $clean_using_builder;
5548 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5549 #   clean the tree before building (perhaps invoked indirectly by
5550 #   whatever we are using to run the build), rather than separately
5551 #   and explicitly by us.
5552
5553 sub clean_tree () {
5554     return if $clean_using_builder;
5555     if ($cleanmode eq 'dpkg-source') {
5556         maybe_apply_patches_dirtily();
5557         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5558     } elsif ($cleanmode eq 'dpkg-source-d') {
5559         maybe_apply_patches_dirtily();
5560         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5561     } elsif ($cleanmode eq 'git') {
5562         runcmd_ordryrun_local @git, qw(clean -xdf);
5563     } elsif ($cleanmode eq 'git-ff') {
5564         runcmd_ordryrun_local @git, qw(clean -xdff);
5565     } elsif ($cleanmode eq 'check') {
5566         my $leftovers = cmdoutput @git, qw(clean -xdn);
5567         if (length $leftovers) {
5568             print STDERR $leftovers, "\n" or die $!;
5569             fail "tree contains uncommitted files and --clean=check specified";
5570         }
5571     } elsif ($cleanmode eq 'none') {
5572     } else {
5573         die "$cleanmode ?";
5574     }
5575 }
5576
5577 sub cmd_clean () {
5578     badusage "clean takes no additional arguments" if @ARGV;
5579     notpushing();
5580     clean_tree();
5581     maybe_unapply_patches_again();
5582 }
5583
5584 sub build_prep_early () {
5585     our $build_prep_early_done //= 0;
5586     return if $build_prep_early_done++;
5587     notpushing();
5588     badusage "-p is not allowed when building" if defined $package;
5589     my $clogp = parsechangelog();
5590     $isuite = getfield $clogp, 'Distribution';
5591     $package = getfield $clogp, 'Source';
5592     $version = getfield $clogp, 'Version';
5593     check_not_dirty();
5594 }
5595
5596 sub build_prep () {
5597     build_prep_early();
5598     clean_tree();
5599     build_maybe_quilt_fixup();
5600     if ($rmchanges) {
5601         my $pat = changespat $version;
5602         foreach my $f (glob "$buildproductsdir/$pat") {
5603             if (act_local()) {
5604                 unlink $f or fail "remove old changes file $f: $!";
5605             } else {
5606                 progress "would remove $f";
5607             }
5608         }
5609     }
5610 }
5611
5612 sub changesopts_initial () {
5613     my @opts =@changesopts[1..$#changesopts];
5614 }
5615
5616 sub changesopts_version () {
5617     if (!defined $changes_since_version) {
5618         my @vsns = archive_query('archive_query');
5619         my @quirk = access_quirk();
5620         if ($quirk[0] eq 'backports') {
5621             local $isuite = $quirk[2];
5622             local $csuite;
5623             canonicalise_suite();
5624             push @vsns, archive_query('archive_query');
5625         }
5626         if (@vsns) {
5627             @vsns = map { $_->[0] } @vsns;
5628             @vsns = sort { -version_compare($a, $b) } @vsns;
5629             $changes_since_version = $vsns[0];
5630             progress "changelog will contain changes since $vsns[0]";
5631         } else {
5632             $changes_since_version = '_';
5633             progress "package seems new, not specifying -v<version>";
5634         }
5635     }
5636     if ($changes_since_version ne '_') {
5637         return ("-v$changes_since_version");
5638     } else {
5639         return ();
5640     }
5641 }
5642
5643 sub changesopts () {
5644     return (changesopts_initial(), changesopts_version());
5645 }
5646
5647 sub massage_dbp_args ($;$) {
5648     my ($cmd,$xargs) = @_;
5649     # We need to:
5650     #
5651     #  - if we're going to split the source build out so we can
5652     #    do strange things to it, massage the arguments to dpkg-buildpackage
5653     #    so that the main build doessn't build source (or add an argument
5654     #    to stop it building source by default).
5655     #
5656     #  - add -nc to stop dpkg-source cleaning the source tree,
5657     #    unless we're not doing a split build and want dpkg-source
5658     #    as cleanmode, in which case we can do nothing
5659     #
5660     # return values:
5661     #    0 - source will NOT need to be built separately by caller
5662     #   +1 - source will need to be built separately by caller
5663     #   +2 - source will need to be built separately by caller AND
5664     #        dpkg-buildpackage should not in fact be run at all!
5665     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5666 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5667     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5668         $clean_using_builder = 1;
5669         return 0;
5670     }
5671     # -nc has the side effect of specifying -b if nothing else specified
5672     # and some combinations of -S, -b, et al, are errors, rather than
5673     # later simply overriding earlie.  So we need to:
5674     #  - search the command line for these options
5675     #  - pick the last one
5676     #  - perhaps add our own as a default
5677     #  - perhaps adjust it to the corresponding non-source-building version
5678     my $dmode = '-F';
5679     foreach my $l ($cmd, $xargs) {
5680         next unless $l;
5681         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5682     }
5683     push @$cmd, '-nc';
5684 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5685     my $r = 0;
5686     if ($need_split_build_invocation) {
5687         printdebug "massage split $dmode.\n";
5688         $r = $dmode =~ m/[S]/     ? +2 :
5689              $dmode =~ y/gGF/ABb/ ? +1 :
5690              $dmode =~ m/[ABb]/   ?  0 :
5691              die "$dmode ?";
5692     }
5693     printdebug "massage done $r $dmode.\n";
5694     push @$cmd, $dmode;
5695 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5696     return $r;
5697 }
5698
5699 sub in_parent (&) {
5700     my ($fn) = @_;
5701     my $wasdir = must_getcwd();
5702     changedir "..";
5703     $fn->();
5704     changedir $wasdir;
5705 }
5706
5707 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5708     my ($msg_if_onlyone) = @_;
5709     # If there is only one .changes file, fail with $msg_if_onlyone,
5710     # or if that is undef, be a no-op.
5711     # Returns the changes file to report to the user.
5712     my $pat = changespat $version;
5713     my @changesfiles = glob $pat;
5714     @changesfiles = sort {
5715         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5716             or $a cmp $b
5717     } @changesfiles;
5718     my $result;
5719     if (@changesfiles==1) {
5720         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5721 only one changes file from build (@changesfiles)
5722 END
5723         $result = $changesfiles[0];
5724     } elsif (@changesfiles==2) {
5725         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5726         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5727             fail "$l found in binaries changes file $binchanges"
5728                 if $l =~ m/\.dsc$/;
5729         }
5730         runcmd_ordryrun_local @mergechanges, @changesfiles;
5731         my $multichanges = changespat $version,'multi';
5732         if (act_local()) {
5733             stat_exists $multichanges or fail "$multichanges: $!";
5734             foreach my $cf (glob $pat) {
5735                 next if $cf eq $multichanges;
5736                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5737             }
5738         }
5739         $result = $multichanges;
5740     } else {
5741         fail "wrong number of different changes files (@changesfiles)";
5742     }
5743     printdone "build successful, results in $result\n" or die $!;
5744 }
5745
5746 sub midbuild_checkchanges () {
5747     my $pat = changespat $version;
5748     return if $rmchanges;
5749     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5750     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5751     fail <<END
5752 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5753 Suggest you delete @unwanted.
5754 END
5755         if @unwanted;
5756 }
5757
5758 sub midbuild_checkchanges_vanilla ($) {
5759     my ($wantsrc) = @_;
5760     midbuild_checkchanges() if $wantsrc == 1;
5761 }
5762
5763 sub postbuild_mergechanges_vanilla ($) {
5764     my ($wantsrc) = @_;
5765     if ($wantsrc == 1) {
5766         in_parent {
5767             postbuild_mergechanges(undef);
5768         };
5769     } else {
5770         printdone "build successful\n";
5771     }
5772 }
5773
5774 sub cmd_build {
5775     build_prep_early();
5776     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5777     my $wantsrc = massage_dbp_args \@dbp;
5778     if ($wantsrc > 0) {
5779         build_source();
5780         midbuild_checkchanges_vanilla $wantsrc;
5781     } else {
5782         build_prep();
5783     }
5784     if ($wantsrc < 2) {
5785         push @dbp, changesopts_version();
5786         maybe_apply_patches_dirtily();
5787         runcmd_ordryrun_local @dbp;
5788     }
5789     maybe_unapply_patches_again();
5790     postbuild_mergechanges_vanilla $wantsrc;
5791 }
5792
5793 sub pre_gbp_build {
5794     $quilt_mode //= 'gbp';
5795 }
5796
5797 sub cmd_gbp_build {
5798     build_prep_early();
5799
5800     # gbp can make .origs out of thin air.  In my tests it does this
5801     # even for a 1.0 format package, with no origs present.  So I
5802     # guess it keys off just the version number.  We don't know
5803     # exactly what .origs ought to exist, but let's assume that we
5804     # should run gbp if: the version has an upstream part and the main
5805     # orig is absent.
5806     my $upstreamversion = upstreamversion $version;
5807     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5808     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5809
5810     if ($gbp_make_orig) {
5811         clean_tree();
5812         $cleanmode = 'none'; # don't do it again
5813         $need_split_build_invocation = 1;
5814     }
5815
5816     my @dbp = @dpkgbuildpackage;
5817
5818     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5819
5820     if (!length $gbp_build[0]) {
5821         if (length executable_on_path('git-buildpackage')) {
5822             $gbp_build[0] = qw(git-buildpackage);
5823         } else {
5824             $gbp_build[0] = 'gbp buildpackage';
5825         }
5826     }
5827     my @cmd = opts_opt_multi_cmd @gbp_build;
5828
5829     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5830
5831     if ($gbp_make_orig) {
5832         ensuredir '.git/dgit';
5833         my $ok = '.git/dgit/origs-gen-ok';
5834         unlink $ok or $!==&ENOENT or die $!;
5835         my @origs_cmd = @cmd;
5836         push @origs_cmd, qw(--git-cleaner=true);
5837         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5838         push @origs_cmd, @ARGV;
5839         if (act_local()) {
5840             debugcmd @origs_cmd;
5841             system @origs_cmd;
5842             do { local $!; stat_exists $ok; }
5843                 or failedcmd @origs_cmd;
5844         } else {
5845             dryrun_report @origs_cmd;
5846         }
5847     }
5848
5849     if ($wantsrc > 0) {
5850         build_source();
5851         midbuild_checkchanges_vanilla $wantsrc;
5852     } else {
5853         if (!$clean_using_builder) {
5854             push @cmd, '--git-cleaner=true';
5855         }
5856         build_prep();
5857     }
5858     maybe_unapply_patches_again();
5859     if ($wantsrc < 2) {
5860         push @cmd, changesopts();
5861         runcmd_ordryrun_local @cmd, @ARGV;
5862     }
5863     postbuild_mergechanges_vanilla $wantsrc;
5864 }
5865 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
5866
5867 sub build_source {
5868     build_prep_early();
5869     my $our_cleanmode = $cleanmode;
5870     if ($need_split_build_invocation) {
5871         # Pretend that clean is being done some other way.  This
5872         # forces us not to try to use dpkg-buildpackage to clean and
5873         # build source all in one go; and instead we run dpkg-source
5874         # (and build_prep() will do the clean since $clean_using_builder
5875         # is false).
5876         $our_cleanmode = 'ELSEWHERE';
5877     }
5878     if ($our_cleanmode =~ m/^dpkg-source/) {
5879         # dpkg-source invocation (below) will clean, so build_prep shouldn't
5880         $clean_using_builder = 1;
5881     }
5882     build_prep();
5883     $sourcechanges = changespat $version,'source';
5884     if (act_local()) {
5885         unlink "../$sourcechanges" or $!==ENOENT
5886             or fail "remove $sourcechanges: $!";
5887     }
5888     $dscfn = dscfn($version);
5889     if ($our_cleanmode eq 'dpkg-source') {
5890         maybe_apply_patches_dirtily();
5891         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
5892             changesopts();
5893     } elsif ($our_cleanmode eq 'dpkg-source-d') {
5894         maybe_apply_patches_dirtily();
5895         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
5896             changesopts();
5897     } else {
5898         my @cmd = (@dpkgsource, qw(-b --));
5899         if ($split_brain) {
5900             changedir $ud;
5901             runcmd_ordryrun_local @cmd, "work";
5902             my @udfiles = <${package}_*>;
5903             changedir "../../..";
5904             foreach my $f (@udfiles) {
5905                 printdebug "source copy, found $f\n";
5906                 next unless
5907                     $f eq $dscfn or
5908                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
5909                      $f eq srcfn($version, $&));
5910                 printdebug "source copy, found $f - renaming\n";
5911                 rename "$ud/$f", "../$f" or $!==ENOENT
5912                     or fail "put in place new source file ($f): $!";
5913             }
5914         } else {
5915             my $pwd = must_getcwd();
5916             my $leafdir = basename $pwd;
5917             changedir "..";
5918             runcmd_ordryrun_local @cmd, $leafdir;
5919             changedir $pwd;
5920         }
5921         runcmd_ordryrun_local qw(sh -ec),
5922             'exec >$1; shift; exec "$@"','x',
5923             "../$sourcechanges",
5924             @dpkggenchanges, qw(-S), changesopts();
5925     }
5926 }
5927
5928 sub cmd_build_source {
5929     build_prep_early();
5930     badusage "build-source takes no additional arguments" if @ARGV;
5931     build_source();
5932     maybe_unapply_patches_again();
5933     printdone "source built, results in $dscfn and $sourcechanges";
5934 }
5935
5936 sub cmd_sbuild {
5937     build_source();
5938     midbuild_checkchanges();
5939     in_parent {
5940         if (act_local()) {
5941             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
5942             stat_exists $sourcechanges
5943                 or fail "$sourcechanges (in parent directory): $!";
5944         }
5945         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
5946     };
5947     maybe_unapply_patches_again();
5948     in_parent {
5949         postbuild_mergechanges(<<END);
5950 perhaps you need to pass -A ?  (sbuild's default is to build only
5951 arch-specific binaries; dgit 1.4 used to override that.)
5952 END
5953     };
5954 }
5955
5956 sub cmd_quilt_fixup {
5957     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
5958     build_prep_early();
5959     clean_tree();
5960     build_maybe_quilt_fixup();
5961 }
5962
5963 sub cmd_import_dsc {
5964     my $needsig = 0;
5965
5966     while (@ARGV) {
5967         last unless $ARGV[0] =~ m/^-/;
5968         $_ = shift @ARGV;
5969         last if m/^--?$/;
5970         if (m/^--require-valid-signature$/) {
5971             $needsig = 1;
5972         } else {
5973             badusage "unknown dgit import-dsc sub-option \`$_'";
5974         }
5975     }
5976
5977     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
5978     my ($dscfn, $dstbranch) = @ARGV;
5979
5980     badusage "dry run makes no sense with import-dsc" unless act_local();
5981
5982     my $force = $dstbranch =~ s/^\+//   ? +1 :
5983                 $dstbranch =~ s/^\.\.// ? -1 :
5984                                            0;
5985     my $info = $force ? " $&" : '';
5986     $info = "$dscfn$info";
5987
5988     my $specbranch = $dstbranch;
5989     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
5990     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
5991
5992     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
5993     my $chead = cmdoutput_errok @symcmd;
5994     defined $chead or $?==256 or failedcmd @symcmd;
5995
5996     fail "$dstbranch is checked out - will not update it"
5997         if defined $chead and $chead eq $dstbranch;
5998
5999     my $oldhash = git_get_ref $dstbranch;
6000
6001     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6002     $dscdata = do { local $/ = undef; <D>; };
6003     D->error and fail "read $dscfn: $!";
6004     close C;
6005
6006     # we don't normally need this so import it here
6007     use Dpkg::Source::Package;
6008     my $dp = new Dpkg::Source::Package filename => $dscfn,
6009         require_valid_signature => $needsig;
6010     {
6011         local $SIG{__WARN__} = sub {
6012             print STDERR $_[0];
6013             return unless $needsig;
6014             fail "import-dsc signature check failed";
6015         };
6016         if (!$dp->is_signed()) {
6017             warn "$us: warning: importing unsigned .dsc\n";
6018         } else {
6019             my $r = $dp->check_signature();
6020             die "->check_signature => $r" if $needsig && $r;
6021         }
6022     }
6023
6024     parse_dscdata();
6025
6026     $package = getfield $dsc, 'Source';
6027
6028     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6029         unless forceing [qw(import-dsc-with-dgit-field)];
6030
6031     if (defined $dsc_hash) {
6032         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6033         resolve_dsc_field_commit undef, undef;
6034     }
6035     if (defined $dsc_hash) {
6036         my @cmd = (qw(sh -ec),
6037                    "echo $dsc_hash | git cat-file --batch-check");
6038         my $objgot = cmdoutput @cmd;
6039         if ($objgot =~ m#^\w+ missing\b#) {
6040             fail <<END
6041 .dsc contains Dgit field referring to object $dsc_hash
6042 Your git tree does not have that object.  Try `git fetch' from a
6043 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6044 END
6045         }
6046         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6047             if ($force > 0) {
6048                 progress "Not fast forward, forced update.";
6049             } else {
6050                 fail "Not fast forward to $dsc_hash";
6051             }
6052         }
6053         @cmd = (@git, qw(update-ref -m), "dgit import-dsc (Dgit): $info",
6054                 $dstbranch, $dsc_hash);
6055         runcmd @cmd;
6056         progress "dgit: import-dsc updated git ref $dstbranch";
6057         return 0;
6058     }
6059
6060     fail <<END
6061 Branch $dstbranch already exists
6062 Specify ..$specbranch for a pseudo-merge, binding in existing history
6063 Specify  +$specbranch to overwrite, discarding existing history
6064 END
6065         if $oldhash && !$force;
6066
6067     my @dfi = dsc_files_info();
6068     foreach my $fi (@dfi) {
6069         my $f = $fi->{Filename};
6070         my $here = "../$f";
6071         next if lstat $here;
6072         fail "stat $here: $!" unless $! == ENOENT;
6073         my $there = $dscfn;
6074         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6075             $there = $';
6076         } elsif ($dscfn =~ m#^/#) {
6077             $there = $dscfn;
6078         } else {
6079             fail "cannot import $dscfn which seems to be inside working tree!";
6080         }
6081         $there =~ s#/+[^/]+$## or
6082             fail "cannot import $dscfn which seems to not have a basename";
6083         $there .= "/$f";
6084         symlink $there, $here or fail "symlink $there to $here: $!";
6085         progress "made symlink $here -> $there";
6086 #       print STDERR Dumper($fi);
6087     }
6088     my @mergeinputs = generate_commits_from_dsc();
6089     die unless @mergeinputs == 1;
6090
6091     my $newhash = $mergeinputs[0]{Commit};
6092
6093     if ($oldhash) {
6094         if ($force > 0) {
6095             progress "Import, forced update - synthetic orphan git history.";
6096         } elsif ($force < 0) {
6097             progress "Import, merging.";
6098             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6099             my $version = getfield $dsc, 'Version';
6100             my $clogp = commit_getclogp $newhash;
6101             my $authline = clogp_authline $clogp;
6102             $newhash = make_commit_text <<END;
6103 tree $tree
6104 parent $newhash
6105 parent $oldhash
6106 author $authline
6107 committer $authline
6108
6109 Merge $package ($version) import into $dstbranch
6110 END
6111         } else {
6112             die; # caught earlier
6113         }
6114     }
6115
6116     my @cmd = (@git, qw(update-ref -m), "dgit import-dsc: $info",
6117                $dstbranch, $newhash);
6118     runcmd @cmd;
6119     progress "dgit: import-dsc results are in in git ref $dstbranch";
6120 }
6121
6122 sub cmd_archive_api_query {
6123     badusage "need only 1 subpath argument" unless @ARGV==1;
6124     my ($subpath) = @ARGV;
6125     my @cmd = archive_api_query_cmd($subpath);
6126     push @cmd, qw(-f);
6127     debugcmd ">",@cmd;
6128     exec @cmd or fail "exec curl: $!\n";
6129 }
6130
6131 sub cmd_clone_dgit_repos_server {
6132     badusage "need destination argument" unless @ARGV==1;
6133     my ($destdir) = @ARGV;
6134     $package = '_dgit-repos-server';
6135     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6136     debugcmd ">",@cmd;
6137     exec @cmd or fail "exec git clone: $!\n";
6138 }
6139
6140 sub cmd_setup_mergechangelogs {
6141     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6142     setup_mergechangelogs(1);
6143 }
6144
6145 sub cmd_setup_useremail {
6146     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6147     setup_useremail(1);
6148 }
6149
6150 sub cmd_setup_new_tree {
6151     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6152     setup_new_tree();
6153 }
6154
6155 #---------- argument parsing and main program ----------
6156
6157 sub cmd_version {
6158     print "dgit version $our_version\n" or die $!;
6159     exit 0;
6160 }
6161
6162 our (%valopts_long, %valopts_short);
6163 our @rvalopts;
6164
6165 sub defvalopt ($$$$) {
6166     my ($long,$short,$val_re,$how) = @_;
6167     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6168     $valopts_long{$long} = $oi;
6169     $valopts_short{$short} = $oi;
6170     # $how subref should:
6171     #   do whatever assignemnt or thing it likes with $_[0]
6172     #   if the option should not be passed on to remote, @rvalopts=()
6173     # or $how can be a scalar ref, meaning simply assign the value
6174 }
6175
6176 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6177 defvalopt '--distro',        '-d', '.+',      \$idistro;
6178 defvalopt '',                '-k', '.+',      \$keyid;
6179 defvalopt '--existing-package','', '.*',      \$existing_package;
6180 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6181 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6182 defvalopt '--package',   '-p',   $package_re, \$package;
6183 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6184
6185 defvalopt '', '-C', '.+', sub {
6186     ($changesfile) = (@_);
6187     if ($changesfile =~ s#^(.*)/##) {
6188         $buildproductsdir = $1;
6189     }
6190 };
6191
6192 defvalopt '--initiator-tempdir','','.*', sub {
6193     ($initiator_tempdir) = (@_);
6194     $initiator_tempdir =~ m#^/# or
6195         badusage "--initiator-tempdir must be used specify an".
6196         " absolute, not relative, directory."
6197 };
6198
6199 sub parseopts () {
6200     my $om;
6201
6202     if (defined $ENV{'DGIT_SSH'}) {
6203         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6204     } elsif (defined $ENV{'GIT_SSH'}) {
6205         @ssh = ($ENV{'GIT_SSH'});
6206     }
6207
6208     my $oi;
6209     my $val;
6210     my $valopt = sub {
6211         my ($what) = @_;
6212         @rvalopts = ($_);
6213         if (!defined $val) {
6214             badusage "$what needs a value" unless @ARGV;
6215             $val = shift @ARGV;
6216             push @rvalopts, $val;
6217         }
6218         badusage "bad value \`$val' for $what" unless
6219             $val =~ m/^$oi->{Re}$(?!\n)/s;
6220         my $how = $oi->{How};
6221         if (ref($how) eq 'SCALAR') {
6222             $$how = $val;
6223         } else {
6224             $how->($val);
6225         }
6226         push @ropts, @rvalopts;
6227     };
6228
6229     while (@ARGV) {
6230         last unless $ARGV[0] =~ m/^-/;
6231         $_ = shift @ARGV;
6232         last if m/^--?$/;
6233         if (m/^--/) {
6234             if (m/^--dry-run$/) {
6235                 push @ropts, $_;
6236                 $dryrun_level=2;
6237             } elsif (m/^--damp-run$/) {
6238                 push @ropts, $_;
6239                 $dryrun_level=1;
6240             } elsif (m/^--no-sign$/) {
6241                 push @ropts, $_;
6242                 $sign=0;
6243             } elsif (m/^--help$/) {
6244                 cmd_help();
6245             } elsif (m/^--version$/) {
6246                 cmd_version();
6247             } elsif (m/^--new$/) {
6248                 push @ropts, $_;
6249                 $new_package=1;
6250             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6251                      ($om = $opts_opt_map{$1}) &&
6252                      length $om->[0]) {
6253                 push @ropts, $_;
6254                 $om->[0] = $2;
6255             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6256                      !$opts_opt_cmdonly{$1} &&
6257                      ($om = $opts_opt_map{$1})) {
6258                 push @ropts, $_;
6259                 push @$om, $2;
6260             } elsif (m/^--(gbp|dpm)$/s) {
6261                 push @ropts, "--quilt=$1";
6262                 $quilt_mode = $1;
6263             } elsif (m/^--ignore-dirty$/s) {
6264                 push @ropts, $_;
6265                 $ignoredirty = 1;
6266             } elsif (m/^--no-quilt-fixup$/s) {
6267                 push @ropts, $_;
6268                 $quilt_mode = 'nocheck';
6269             } elsif (m/^--no-rm-on-error$/s) {
6270                 push @ropts, $_;
6271                 $rmonerror = 0;
6272             } elsif (m/^--overwrite$/s) {
6273                 push @ropts, $_;
6274                 $overwrite_version = '';
6275             } elsif (m/^--overwrite=(.+)$/s) {
6276                 push @ropts, $_;
6277                 $overwrite_version = $1;
6278             } elsif (m/^--dep14tag$/s) {
6279                 push @ropts, $_;
6280                 $dodep14tag= 'want';
6281             } elsif (m/^--no-dep14tag$/s) {
6282                 push @ropts, $_;
6283                 $dodep14tag= 'no';
6284             } elsif (m/^--always-dep14tag$/s) {
6285                 push @ropts, $_;
6286                 $dodep14tag= 'always';
6287             } elsif (m/^--delayed=(\d+)$/s) {
6288                 push @ropts, $_;
6289                 push @dput, $_;
6290             } elsif (m/^--dgit-view-save=(.+)$/s) {
6291                 push @ropts, $_;
6292                 $split_brain_save = $1;
6293                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6294             } elsif (m/^--(no-)?rm-old-changes$/s) {
6295                 push @ropts, $_;
6296                 $rmchanges = !$1;
6297             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6298                 push @ropts, $_;
6299                 push @deliberatelies, $&;
6300             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6301                 push @ropts, $&;
6302                 $forceopts{$1} = 1;
6303                 $_='';
6304             } elsif (m/^--force-/) {
6305                 print STDERR
6306                     "$us: warning: ignoring unknown force option $_\n";
6307                 $_='';
6308             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6309                 # undocumented, for testing
6310                 push @ropts, $_;
6311                 $tagformat_want = [ $1, 'command line', 1 ];
6312                 # 1 menas overrides distro configuration
6313             } elsif (m/^--always-split-source-build$/s) {
6314                 # undocumented, for testing
6315                 push @ropts, $_;
6316                 $need_split_build_invocation = 1;
6317             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6318                 $val = $2 ? $' : undef; #';
6319                 $valopt->($oi->{Long});
6320             } else {
6321                 badusage "unknown long option \`$_'";
6322             }
6323         } else {
6324             while (m/^-./s) {
6325                 if (s/^-n/-/) {
6326                     push @ropts, $&;
6327                     $dryrun_level=2;
6328                 } elsif (s/^-L/-/) {
6329                     push @ropts, $&;
6330                     $dryrun_level=1;
6331                 } elsif (s/^-h/-/) {
6332                     cmd_help();
6333                 } elsif (s/^-D/-/) {
6334                     push @ropts, $&;
6335                     $debuglevel++;
6336                     enabledebug();
6337                 } elsif (s/^-N/-/) {
6338                     push @ropts, $&;
6339                     $new_package=1;
6340                 } elsif (m/^-m/) {
6341                     push @ropts, $&;
6342                     push @changesopts, $_;
6343                     $_ = '';
6344                 } elsif (s/^-wn$//s) {
6345                     push @ropts, $&;
6346                     $cleanmode = 'none';
6347                 } elsif (s/^-wg$//s) {
6348                     push @ropts, $&;
6349                     $cleanmode = 'git';
6350                 } elsif (s/^-wgf$//s) {
6351                     push @ropts, $&;
6352                     $cleanmode = 'git-ff';
6353                 } elsif (s/^-wd$//s) {
6354                     push @ropts, $&;
6355                     $cleanmode = 'dpkg-source';
6356                 } elsif (s/^-wdd$//s) {
6357                     push @ropts, $&;
6358                     $cleanmode = 'dpkg-source-d';
6359                 } elsif (s/^-wc$//s) {
6360                     push @ropts, $&;
6361                     $cleanmode = 'check';
6362                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6363                     push @git, '-c', $&;
6364                     $gitcfgs{cmdline}{$1} = [ $2 ];
6365                 } elsif (s/^-c([^=]+)$//s) {
6366                     push @git, '-c', $&;
6367                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6368                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6369                     $val = $'; #';
6370                     $val = undef unless length $val;
6371                     $valopt->($oi->{Short});
6372                     $_ = '';
6373                 } else {
6374                     badusage "unknown short option \`$_'";
6375                 }
6376             }
6377         }
6378     }
6379 }
6380
6381 sub check_env_sanity () {
6382     my $blocked = new POSIX::SigSet;
6383     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6384
6385     eval {
6386         foreach my $name (qw(PIPE CHLD)) {
6387             my $signame = "SIG$name";
6388             my $signum = eval "POSIX::$signame" // die;
6389             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6390                 die "$signame is set to something other than SIG_DFL\n";
6391             $blocked->ismember($signum) and
6392                 die "$signame is blocked\n";
6393         }
6394     };
6395     return unless $@;
6396     chomp $@;
6397     fail <<END;
6398 On entry to dgit, $@
6399 This is a bug produced by something in in your execution environment.
6400 Giving up.
6401 END
6402 }
6403
6404
6405 sub parseopts_late_defaults () {
6406     foreach my $k (keys %opts_opt_map) {
6407         my $om = $opts_opt_map{$k};
6408
6409         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6410         if (defined $v) {
6411             badcfg "cannot set command for $k"
6412                 unless length $om->[0];
6413             $om->[0] = $v;
6414         }
6415
6416         foreach my $c (access_cfg_cfgs("opts-$k")) {
6417             my @vl =
6418                 map { $_ ? @$_ : () }
6419                 map { $gitcfgs{$_}{$c} }
6420                 reverse @gitcfgsources;
6421             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6422                 "\n" if $debuglevel >= 4;
6423             next unless @vl;
6424             badcfg "cannot configure options for $k"
6425                 if $opts_opt_cmdonly{$k};
6426             my $insertpos = $opts_cfg_insertpos{$k};
6427             @$om = ( @$om[0..$insertpos-1],
6428                      @vl,
6429                      @$om[$insertpos..$#$om] );
6430         }
6431     }
6432
6433     if (!defined $rmchanges) {
6434         local $access_forpush;
6435         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6436     }
6437
6438     if (!defined $quilt_mode) {
6439         local $access_forpush;
6440         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6441             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6442             // 'linear';
6443         $quilt_mode =~ m/^($quilt_modes_re)$/
6444             or badcfg "unknown quilt-mode \`$quilt_mode'";
6445         $quilt_mode = $1;
6446     }
6447
6448     if (!defined $dodep14tag) {
6449         local $access_forpush;
6450         $dodep14tag = access_cfg('dep14tag', 'RETURN-UNDEF') // 'want';
6451         $dodep14tag =~ m/^($dodep14tag_re)$/
6452             or badcfg "unknown dep14tag setting \`$dodep14tag'";
6453         $dodep14tag = $1;
6454     }
6455
6456     $need_split_build_invocation ||= quiltmode_splitbrain();
6457
6458     if (!defined $cleanmode) {
6459         local $access_forpush;
6460         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6461         $cleanmode //= 'dpkg-source';
6462
6463         badcfg "unknown clean-mode \`$cleanmode'" unless
6464             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6465     }
6466 }
6467
6468 if ($ENV{$fakeeditorenv}) {
6469     git_slurp_config();
6470     quilt_fixup_editor();
6471 }
6472
6473 parseopts();
6474 check_env_sanity();
6475 git_slurp_config();
6476
6477 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6478 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6479     if $dryrun_level == 1;
6480 if (!@ARGV) {
6481     print STDERR $helpmsg or die $!;
6482     exit 8;
6483 }
6484 my $cmd = shift @ARGV;
6485 $cmd =~ y/-/_/;
6486
6487 my $pre_fn = ${*::}{"pre_$cmd"};
6488 $pre_fn->() if $pre_fn;
6489
6490 my $fn = ${*::}{"cmd_$cmd"};
6491 $fn or badusage "unknown operation $cmd";
6492 $fn->();