dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2018 Ian Jackson
   6 # Copyright (C)2017-2018 Sean Whitton
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23
  24 use strict;
  25
  26 use Debian::Dgit qw(:DEFAULT :playground);
  27 setup_sigwarn();
  28
  29 use IO::Handle;
  30 use Data::Dumper;
  31 use LWP::UserAgent;
  32 use Dpkg::Control::Hash;
  33 use File::Path;
  34 use File::Temp qw(tempdir);
  35 use File::Basename;
  36 use Dpkg::Version;
  37 use Dpkg::Compression;
  38 use Dpkg::Compression::Process;
  39 use POSIX;
  40 use IPC::Open2;
  41 use Digest::SHA;
  42 use Digest::MD5;
  43 use List::MoreUtils qw(pairwise);
  44 use Text::Glob qw(match_glob);
  45 use Fcntl qw(:DEFAULT :flock);
  46 use Carp;
  47
  48 use Debian::Dgit;
  49
  50 our $our_version = 'UNRELEASED'; ###substituted###
  51 our $absurdity = undef; ###substituted###
  52
  53 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  54 our $protovsn;
  55
  56 our $cmd;
  57 our $subcommand;
  58 our $isuite;
  59 our $idistro;
  60 our $package;
  61 our @ropts;
  62
  63 our $sign = 1;
  64 our $dryrun_level = 0;
  65 our $changesfile;
  66 our $buildproductsdir;
  67 our $bpd_glob;
  68 our $new_package = 0;
  69 our $includedirty = 0;
  70 our $rmonerror = 1;
  71 our @deliberatelies;
  72 our %previously;
  73 our $existing_package = 'dpkg';
  74 our $cleanmode;
  75 our $changes_since_version;
  76 our $rmchanges;
  77 our $overwrite_version; # undef: not specified; '': check changelog
  78 our $quilt_mode;
  79 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  80 our $dodep14tag;
  81 our %internal_object_save;
  82 our $we_are_responder;
  83 our $we_are_initiator;
  84 our $initiator_tempdir;
  85 our $patches_applied_dirtily = 00;
  86 our $tagformat_want;
  87 our $tagformat;
  88 our $tagformatfn;
  89 our $chase_dsc_distro=1;
  90
  91 our %forceopts = map { $_=>0 }
  92     qw(unrepresentable unsupported-source-format
  93        dsc-changes-mismatch changes-origs-exactly
  94        uploading-binaries uploading-source-only
  95        import-gitapply-absurd
  96        import-gitapply-no-absurd
  97        import-dsc-with-dgit-field);
  98
  99 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
 100
 101 our $suite_re = '[-+.0-9a-z]+';
 102 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
 103
 104 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 105 our $splitbraincache = 'dgit-intern/quilt-cache';
 106 our $rewritemap = 'dgit-rewrite/map';
 107
 108 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
 109
 110 our (@git) = qw(git);
 111 our (@dget) = qw(dget);
 112 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 113 our (@dput) = qw(dput);
 114 our (@debsign) = qw(debsign);
 115 our (@gpg) = qw(gpg);
 116 our (@sbuild) = qw(sbuild);
 117 our (@ssh) = 'ssh';
 118 our (@dgit) = qw(dgit);
 119 our (@git_debrebase) = qw(git-debrebase);
 120 our (@aptget) = qw(apt-get);
 121 our (@aptcache) = qw(apt-cache);
 122 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
 123 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
 124 our (@dpkggenchanges) = qw(dpkg-genchanges);
 125 our (@mergechanges) = qw(mergechanges -f);
 126 our (@gbp_build) = ('');
 127 our (@gbp_pq) = ('gbp pq');
 128 our (@changesopts) = ('');
 129 our (@pbuilder) = ("sudo -E pbuilder");
 130 our (@cowbuilder) = ("sudo -E cowbuilder");
 131
 132 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 133                      'curl' => \@curl,
 134                      'dput' => \@dput,
 135                      'debsign' => \@debsign,
 136                      'gpg' => \@gpg,
 137                      'sbuild' => \@sbuild,
 138                      'ssh' => \@ssh,
 139                      'dgit' => \@dgit,
 140                      'git' => \@git,
 141                      'git-debrebase' => \@git_debrebase,
 142                      'apt-get' => \@aptget,
 143                      'apt-cache' => \@aptcache,
 144                      'dpkg-source' => \@dpkgsource,
 145                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 146                      'dpkg-genchanges' => \@dpkggenchanges,
 147                      'gbp-build' => \@gbp_build,
 148                      'gbp-pq' => \@gbp_pq,
 149                      'ch' => \@changesopts,
 150                      'mergechanges' => \@mergechanges,
 151                      'pbuilder' => \@pbuilder,
 152                      'cowbuilder' => \@cowbuilder);
 153
 154 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 155 our %opts_cfg_insertpos = map {
 156     $_,
 157     scalar @{ $opts_opt_map{$_} }
 158 } keys %opts_opt_map;
 159
 160 sub parseopts_late_defaults();
 161 sub setup_gitattrs(;$);
 162 sub check_gitattrs($$);
 163
 164 our $playground;
 165 our $keyid;
 166
 167 autoflush STDOUT 1;
 168
 169 our $supplementary_message = '';
 170 our $split_brain = 0;
 171
 172 END {
 173     local ($@, $?);
 174     return unless forkcheck_mainprocess();
 175     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 176 }
 177
 178 our $remotename = 'dgit';
 179 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 180 our $csuite;
 181 our $instead_distro;
 182
 183 if (!defined $absurdity) {
 184     $absurdity = $0;
 185     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 186 }
 187
 188 sub debiantag ($$) {
 189     my ($v,$distro) = @_;
 190     return $tagformatfn->($v, $distro);
 191 }
 192
 193 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 194
 195 sub lbranch () { return "$branchprefix/$csuite"; }
 196 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 197 sub lref () { return "refs/heads/".lbranch(); }
 198 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 199 sub rrref () { return server_ref($csuite); }
 200
 201 sub srcfn ($$) {
 202     my ($vsn, $sfx) = @_;
 203     return &source_file_leafname($package, $vsn, $sfx);
 204 }
 205 sub is_orig_file_of_vsn ($$) {
 206     my ($f, $upstreamvsn) = @_;
 207     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
 208 }
 209
 210 sub dscfn ($) {
 211     my ($vsn) = @_;
 212     return srcfn($vsn,".dsc");
 213 }
 214
 215 sub changespat ($;$) {
 216     my ($vsn, $arch) = @_;
 217     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 218 }
 219
 220 our $us = 'dgit';
 221 initdebug('');
 222
 223 our @end;
 224 END {
 225     local ($?);
 226     return unless forkcheck_mainprocess();
 227     foreach my $f (@end) {
 228         eval { $f->(); };
 229         print STDERR "$us: cleanup: $@" if length $@;
 230     }
 231 };
 232
 233 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; finish 12; }
 234
 235 sub forceable_fail ($$) {
 236     my ($forceoptsl, $msg) = @_;
 237     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 238     print STDERR "warning: overriding problem due to --force:\n". $msg;
 239 }
 240
 241 sub forceing ($) {
 242     my ($forceoptsl) = @_;
 243     my @got = grep { $forceopts{$_} } @$forceoptsl;
 244     return 0 unless @got;
 245     print STDERR
 246  "warning: skipping checks or functionality due to --force-$got[0]\n";
 247 }
 248
 249 sub no_such_package () {
 250     print STDERR "$us: package $package does not exist in suite $isuite\n";
 251     finish 4;
 252 }
 253
 254 sub deliberately ($) {
 255     my ($enquiry) = @_;
 256     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 257 }
 258
 259 sub deliberately_not_fast_forward () {
 260     foreach (qw(not-fast-forward fresh-repo)) {
 261         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 262     }
 263 }
 264
 265 sub quiltmode_splitbrain () {
 266     $quilt_mode =~ m/gbp|dpm|unapplied/;
 267 }
 268
 269 sub opts_opt_multi_cmd {
 270     my $extra = shift;
 271     my @cmd;
 272     push @cmd, split /\s+/, shift @_;
 273     push @cmd, @$extra;
 274     push @cmd, @_;
 275     @cmd;
 276 }
 277
 278 sub gbp_pq {
 279     return opts_opt_multi_cmd [], @gbp_pq;
 280 }
 281
 282 sub dgit_privdir () {
 283     our $dgit_privdir_made //= ensure_a_playground 'dgit';
 284 }
 285
 286 sub bpd_abs () {
 287     my $r = $buildproductsdir;
 288     $r = "$maindir/$r" unless $r =~ m{^/};
 289     return $r;
 290 }
 291
 292 sub branch_gdr_info ($$) {
 293     my ($symref, $head) = @_;
 294     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
 295         gdr_ffq_prev_branchinfo($symref);
 296     return () unless $status eq 'branch';
 297     $ffq_prev = git_get_ref $ffq_prev;
 298     $gdrlast  = git_get_ref $gdrlast;
 299     $gdrlast &&= is_fast_fwd $gdrlast, $head;
 300     return ($ffq_prev, $gdrlast);
 301 }
 302
 303 sub branch_is_gdr ($$) {
 304     my ($symref, $head) = @_;
 305     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 306     return 0 unless $ffq_prev || $gdrlast;
 307     return 1;
 308 }
 309
 310 sub branch_is_gdr_unstitched_ff ($$$) {
 311     my ($symref, $head, $ancestor) = @_;
 312     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 313     return 0 unless $ffq_prev;
 314     return 0 unless !defined $ancestor or is_fast_fwd $ancestor, $ffq_prev;
 315     return 1;
 316 }
 317
 318 #---------- remote protocol support, common ----------
 319
 320 # remote push initiator/responder protocol:
 321 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 322 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 323 #  < dgit-remote-push-ready <actual-proto-vsn>
 324 #
 325 # occasionally:
 326 #
 327 #  > progress NBYTES
 328 #  [NBYTES message]
 329 #
 330 #  > supplementary-message NBYTES          # $protovsn >= 3
 331 #  [NBYTES message]
 332 #
 333 # main sequence:
 334 #
 335 #  > file parsed-changelog
 336 #  [indicates that output of dpkg-parsechangelog follows]
 337 #  > data-block NBYTES
 338 #  > [NBYTES bytes of data (no newline)]
 339 #  [maybe some more blocks]
 340 #  > data-end
 341 #
 342 #  > file dsc
 343 #  [etc]
 344 #
 345 #  > file changes
 346 #  [etc]
 347 #
 348 #  > param head DGIT-VIEW-HEAD
 349 #  > param csuite SUITE
 350 #  > param tagformat old|new
 351 #  > param maint-view MAINT-VIEW-HEAD
 352 #
 353 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 354 #  > file buildinfo                             # for buildinfos to sign
 355 #
 356 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 357 #                                     # goes into tag, for replay prevention
 358 #
 359 #  > want signed-tag
 360 #  [indicates that signed tag is wanted]
 361 #  < data-block NBYTES
 362 #  < [NBYTES bytes of data (no newline)]
 363 #  [maybe some more blocks]
 364 #  < data-end
 365 #  < files-end
 366 #
 367 #  > want signed-dsc-changes
 368 #  < data-block NBYTES    [transfer of signed dsc]
 369 #  [etc]
 370 #  < data-block NBYTES    [transfer of signed changes]
 371 #  [etc]
 372 #  < data-block NBYTES    [transfer of each signed buildinfo
 373 #  [etc]                   same number and order as "file buildinfo"]
 374 #  ...
 375 #  < files-end
 376 #
 377 #  > complete
 378
 379 our $i_child_pid;
 380
 381 sub i_child_report () {
 382     # Sees if our child has died, and reap it if so.  Returns a string
 383     # describing how it died if it failed, or undef otherwise.
 384     return undef unless $i_child_pid;
 385     my $got = waitpid $i_child_pid, WNOHANG;
 386     return undef if $got <= 0;
 387     die unless $got == $i_child_pid;
 388     $i_child_pid = undef;
 389     return undef unless $?;
 390     return "build host child ".waitstatusmsg();
 391 }
 392
 393 sub badproto ($$) {
 394     my ($fh, $m) = @_;
 395     fail "connection lost: $!" if $fh->error;
 396     fail "protocol violation; $m not expected";
 397 }
 398
 399 sub badproto_badread ($$) {
 400     my ($fh, $wh) = @_;
 401     fail "connection lost: $!" if $!;
 402     my $report = i_child_report();
 403     fail $report if defined $report;
 404     badproto $fh, "eof (reading $wh)";
 405 }
 406
 407 sub protocol_expect (&$) {
 408     my ($match, $fh) = @_;
 409     local $_;
 410     $_ = <$fh>;
 411     defined && chomp or badproto_badread $fh, "protocol message";
 412     if (wantarray) {
 413         my @r = &$match;
 414         return @r if @r;
 415     } else {
 416         my $r = &$match;
 417         return $r if $r;
 418     }
 419     badproto $fh, "\`$_'";
 420 }
 421
 422 sub protocol_send_file ($$) {
 423     my ($fh, $ourfn) = @_;
 424     open PF, "<", $ourfn or die "$ourfn: $!";
 425     for (;;) {
 426         my $d;
 427         my $got = read PF, $d, 65536;
 428         die "$ourfn: $!" unless defined $got;
 429         last if !$got;
 430         print $fh "data-block ".length($d)."\n" or die $!;
 431         print $fh $d or die $!;
 432     }
 433     PF->error and die "$ourfn $!";
 434     print $fh "data-end\n" or die $!;
 435     close PF;
 436 }
 437
 438 sub protocol_read_bytes ($$) {
 439     my ($fh, $nbytes) = @_;
 440     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 441     my $d;
 442     my $got = read $fh, $d, $nbytes;
 443     $got==$nbytes or badproto_badread $fh, "data block";
 444     return $d;
 445 }
 446
 447 sub protocol_receive_file ($$) {
 448     my ($fh, $ourfn) = @_;
 449     printdebug "() $ourfn\n";
 450     open PF, ">", $ourfn or die "$ourfn: $!";
 451     for (;;) {
 452         my ($y,$l) = protocol_expect {
 453             m/^data-block (.*)$/ ? (1,$1) :
 454             m/^data-end$/ ? (0,) :
 455             ();
 456         } $fh;
 457         last unless $y;
 458         my $d = protocol_read_bytes $fh, $l;
 459         print PF $d or die $!;
 460     }
 461     close PF or die $!;
 462 }
 463
 464 #---------- remote protocol support, responder ----------
 465
 466 sub responder_send_command ($) {
 467     my ($command) = @_;
 468     return unless $we_are_responder;
 469     # called even without $we_are_responder
 470     printdebug ">> $command\n";
 471     print PO $command, "\n" or die $!;
 472 }
 473
 474 sub responder_send_file ($$) {
 475     my ($keyword, $ourfn) = @_;
 476     return unless $we_are_responder;
 477     printdebug "]] $keyword $ourfn\n";
 478     responder_send_command "file $keyword";
 479     protocol_send_file \*PO, $ourfn;
 480 }
 481
 482 sub responder_receive_files ($@) {
 483     my ($keyword, @ourfns) = @_;
 484     die unless $we_are_responder;
 485     printdebug "[[ $keyword @ourfns\n";
 486     responder_send_command "want $keyword";
 487     foreach my $fn (@ourfns) {
 488         protocol_receive_file \*PI, $fn;
 489     }
 490     printdebug "[[\$\n";
 491     protocol_expect { m/^files-end$/ } \*PI;
 492 }
 493
 494 #---------- remote protocol support, initiator ----------
 495
 496 sub initiator_expect (&) {
 497     my ($match) = @_;
 498     protocol_expect { &$match } \*RO;
 499 }
 500
 501 #---------- end remote code ----------
 502
 503 sub progress {
 504     if ($we_are_responder) {
 505         my $m = join '', @_;
 506         responder_send_command "progress ".length($m) or die $!;
 507         print PO $m or die $!;
 508     } else {
 509         print @_, "\n";
 510     }
 511 }
 512
 513 our $ua;
 514
 515 sub url_get {
 516     if (!$ua) {
 517         $ua = LWP::UserAgent->new();
 518         $ua->env_proxy;
 519     }
 520     my $what = $_[$#_];
 521     progress "downloading $what...";
 522     my $r = $ua->get(@_) or die $!;
 523     return undef if $r->code == 404;
 524     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 525     return $r->decoded_content(charset => 'none');
 526 }
 527
 528 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 529
 530 sub act_local () { return $dryrun_level <= 1; }
 531 sub act_scary () { return !$dryrun_level; }
 532
 533 sub printdone {
 534     if (!$dryrun_level) {
 535         progress "$us ok: @_";
 536     } else {
 537         progress "would be ok: @_ (but dry run only)";
 538     }
 539 }
 540
 541 sub dryrun_report {
 542     printcmd(\*STDERR,$debugprefix."#",@_);
 543 }
 544
 545 sub runcmd_ordryrun {
 546     if (act_scary()) {
 547         runcmd @_;
 548     } else {
 549         dryrun_report @_;
 550     }
 551 }
 552
 553 sub runcmd_ordryrun_local {
 554     if (act_local()) {
 555         runcmd @_;
 556     } else {
 557         dryrun_report @_;
 558     }
 559 }
 560
 561 our $helpmsg = <<END;
 562 main usages:
 563   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 564   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 565   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 566   dgit [dgit-opts] sbuild [sbuild-opts]
 567   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
 568   dgit [dgit-opts] push [dgit-opts] [suite]
 569   dgit [dgit-opts] push-source [dgit-opts] [suite]
 570   dgit [dgit-opts] rpush build-host:build-dir ...
 571 important dgit options:
 572   -k<keyid>           sign tag and package with <keyid> instead of default
 573   --dry-run -n        do not change anything, but go through the motions
 574   --damp-run -L       like --dry-run but make local changes, without signing
 575   --new -N            allow introducing a new package
 576   --debug -D          increase debug level
 577   -c<name>=<value>    set git config option (used directly by dgit too)
 578 END
 579
 580 our $later_warning_msg = <<END;
 581 Perhaps the upload is stuck in incoming.  Using the version from git.
 582 END
 583
 584 sub badusage {
 585     print STDERR "$us: @_\n", $helpmsg or die $!;
 586     finish 8;
 587 }
 588
 589 sub nextarg {
 590     @ARGV or badusage "too few arguments";
 591     return scalar shift @ARGV;
 592 }
 593
 594 sub pre_help () {
 595     not_necessarily_a_tree();
 596 }
 597 sub cmd_help () {
 598     print $helpmsg or die $!;
 599     finish 0;
 600 }
 601
 602 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 603
 604 our %defcfg = ('dgit.default.distro' => 'debian',
 605                'dgit.default.default-suite' => 'unstable',
 606                'dgit.default.old-dsc-distro' => 'debian',
 607                'dgit-suite.*-security.distro' => 'debian-security',
 608                'dgit.default.username' => '',
 609                'dgit.default.archive-query-default-component' => 'main',
 610                'dgit.default.ssh' => 'ssh',
 611                'dgit.default.archive-query' => 'madison:',
 612                'dgit.default.sshpsql-dbname' => 'service=projectb',
 613                'dgit.default.aptget-components' => 'main',
 614                'dgit.default.dgit-tag-format' => 'new,old,maint',
 615                'dgit.default.source-only-uploads' => 'ok',
 616                'dgit.dsc-url-proto-ok.http'    => 'true',
 617                'dgit.dsc-url-proto-ok.https'   => 'true',
 618                'dgit.dsc-url-proto-ok.git'     => 'true',
 619                'dgit.vcs-git.suites',          => 'sid', # ;-separated
 620                'dgit.default.dsc-url-proto-ok' => 'false',
 621                # old means "repo server accepts pushes with old dgit tags"
 622                # new means "repo server accepts pushes with new dgit tags"
 623                # maint means "repo server accepts split brain pushes"
 624                # hist means "repo server may have old pushes without new tag"
 625                #   ("hist" is implied by "old")
 626                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 627                'dgit-distro.debian.git-check' => 'url',
 628                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 629                'dgit-distro.debian.new-private-pushers' => 't',
 630                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
 631                'dgit-distro.debian/push.git-url' => '',
 632                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 633                'dgit-distro.debian/push.git-user-force' => 'dgit',
 634                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 635                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 636                'dgit-distro.debian/push.git-create' => 'true',
 637                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 638  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 639 # 'dgit-distro.debian.archive-query-tls-key',
 640 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 641 # ^ this does not work because curl is broken nowadays
 642 # Fixing #790093 properly will involve providing providing the key
 643 # in some pacagke and maybe updating these paths.
 644 #
 645 # 'dgit-distro.debian.archive-query-tls-curl-args',
 646 #   '--ca-path=/etc/ssl/ca-debian',
 647 # ^ this is a workaround but works (only) on DSA-administered machines
 648                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 649                'dgit-distro.debian.git-url-suffix' => '',
 650                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 651                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 652  'dgit-distro.debian-security.archive-query' => 'aptget:',
 653  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 654  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 655  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 656  'dgit-distro.debian-security.nominal-distro' => 'debian',
 657  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 658  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 659                'dgit-distro.ubuntu.git-check' => 'false',
 660  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 661                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 662                'dgit-distro.test-dummy.username' => "alice",
 663                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 664                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 665                'dgit-distro.test-dummy.git-url' => "$td/git",
 666                'dgit-distro.test-dummy.git-host' => "git",
 667                'dgit-distro.test-dummy.git-path' => "$td/git",
 668                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 669                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 670                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 671                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 672                );
 673
 674 our %gitcfgs;
 675 our @gitcfgsources = qw(cmdline local global system);
 676 our $invoked_in_git_tree = 1;
 677
 678 sub git_slurp_config () {
 679     # This algoritm is a bit subtle, but this is needed so that for
 680     # options which we want to be single-valued, we allow the
 681     # different config sources to override properly.  See #835858.
 682     foreach my $src (@gitcfgsources) {
 683         next if $src eq 'cmdline';
 684         # we do this ourselves since git doesn't handle it
 685
 686         $gitcfgs{$src} = git_slurp_config_src $src;
 687     }
 688 }
 689
 690 sub git_get_config ($) {
 691     my ($c) = @_;
 692     foreach my $src (@gitcfgsources) {
 693         my $l = $gitcfgs{$src}{$c};
 694         confess "internal error ($l $c)" if $l && !ref $l;
 695         printdebug"C $c ".(defined $l ?
 696                            join " ", map { messagequote "'$_'" } @$l :
 697                            "undef")."\n"
 698             if $debuglevel >= 4;
 699         $l or next;
 700         @$l==1 or badcfg "multiple values for $c".
 701             " (in $src git config)" if @$l > 1;
 702         return $l->[0];
 703     }
 704     return undef;
 705 }
 706
 707 sub cfg {
 708     foreach my $c (@_) {
 709         return undef if $c =~ /RETURN-UNDEF/;
 710         printdebug "C? $c\n" if $debuglevel >= 5;
 711         my $v = git_get_config($c);
 712         return $v if defined $v;
 713         my $dv = $defcfg{$c};
 714         if (defined $dv) {
 715             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 716             return $dv;
 717         }
 718     }
 719     badcfg "need value for one of: @_\n".
 720         "$us: distro or suite appears not to be (properly) supported";
 721 }
 722
 723 sub not_necessarily_a_tree () {
 724     # needs to be called from pre_*
 725     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 726     $invoked_in_git_tree = 0;
 727 }
 728
 729 sub access_basedistro__noalias () {
 730     if (defined $idistro) {
 731         return $idistro;
 732     } else {
 733         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 734         return $def if defined $def;
 735         foreach my $src (@gitcfgsources, 'internal') {
 736             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 737             next unless $kl;
 738             foreach my $k (keys %$kl) {
 739                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 740                 my $dpat = $1;
 741                 next unless match_glob $dpat, $isuite;
 742                 return $kl->{$k};
 743             }
 744         }
 745         return cfg("dgit.default.distro");
 746     }
 747 }
 748
 749 sub access_basedistro () {
 750     my $noalias = access_basedistro__noalias();
 751     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 752     return $canon // $noalias;
 753 }
 754
 755 sub access_nomdistro () {
 756     my $base = access_basedistro();
 757     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 758     $r =~ m/^$distro_re$/ or badcfg
 759  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 760     return $r;
 761 }
 762
 763 sub access_quirk () {
 764     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 765     my $basedistro = access_basedistro();
 766     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 767                               'RETURN-UNDEF');
 768     if (defined $backports_quirk) {
 769         my $re = $backports_quirk;
 770         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 771         $re =~ s/\*/.*/g;
 772         $re =~ s/\%/([-0-9a-z_]+)/
 773             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 774         if ($isuite =~ m/^$re$/) {
 775             return ('backports',"$basedistro-backports",$1);
 776         }
 777     }
 778     return ('none',undef);
 779 }
 780
 781 our $access_forpush;
 782
 783 sub parse_cfg_bool ($$$) {
 784     my ($what,$def,$v) = @_;
 785     $v //= $def;
 786     return
 787         $v =~ m/^[ty1]/ ? 1 :
 788         $v =~ m/^[fn0]/ ? 0 :
 789         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 790 }
 791
 792 sub access_forpush_config () {
 793     my $d = access_basedistro();
 794
 795     return 1 if
 796         $new_package &&
 797         parse_cfg_bool('new-private-pushers', 0,
 798                        cfg("dgit-distro.$d.new-private-pushers",
 799                            'RETURN-UNDEF'));
 800
 801     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 802     $v //= 'a';
 803     return
 804         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 805         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 806         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 807         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 808 }
 809
 810 sub access_forpush () {
 811     $access_forpush //= access_forpush_config();
 812     return $access_forpush;
 813 }
 814
 815 sub pushing () {
 816     confess 'internal error '.Dumper($access_forpush)," ?" if
 817         defined $access_forpush and !$access_forpush;
 818     badcfg "pushing but distro is configured readonly"
 819         if access_forpush_config() eq '0';
 820     $access_forpush = 1;
 821     $supplementary_message = <<'END' unless $we_are_responder;
 822 Push failed, before we got started.
 823 You can retry the push, after fixing the problem, if you like.
 824 END
 825     parseopts_late_defaults();
 826 }
 827
 828 sub notpushing () {
 829     parseopts_late_defaults();
 830 }
 831
 832 sub supplementary_message ($) {
 833     my ($msg) = @_;
 834     if (!$we_are_responder) {
 835         $supplementary_message = $msg;
 836         return;
 837     } elsif ($protovsn >= 3) {
 838         responder_send_command "supplementary-message ".length($msg)
 839             or die $!;
 840         print PO $msg or die $!;
 841     }
 842 }
 843
 844 sub access_distros () {
 845     # Returns list of distros to try, in order
 846     #
 847     # We want to try:
 848     #    0. `instead of' distro name(s) we have been pointed to
 849     #    1. the access_quirk distro, if any
 850     #    2a. the user's specified distro, or failing that  } basedistro
 851     #    2b. the distro calculated from the suite          }
 852     my @l = access_basedistro();
 853
 854     my (undef,$quirkdistro) = access_quirk();
 855     unshift @l, $quirkdistro;
 856     unshift @l, $instead_distro;
 857     @l = grep { defined } @l;
 858
 859     push @l, access_nomdistro();
 860
 861     if (access_forpush()) {
 862         @l = map { ("$_/push", $_) } @l;
 863     }
 864     @l;
 865 }
 866
 867 sub access_cfg_cfgs (@) {
 868     my (@keys) = @_;
 869     my @cfgs;
 870     # The nesting of these loops determines the search order.  We put
 871     # the key loop on the outside so that we search all the distros
 872     # for each key, before going on to the next key.  That means that
 873     # if access_cfg is called with a more specific, and then a less
 874     # specific, key, an earlier distro can override the less specific
 875     # without necessarily overriding any more specific keys.  (If the
 876     # distro wants to override the more specific keys it can simply do
 877     # so; whereas if we did the loop the other way around, it would be
 878     # impossible to for an earlier distro to override a less specific
 879     # key but not the more specific ones without restating the unknown
 880     # values of the more specific keys.
 881     my @realkeys;
 882     my @rundef;
 883     # We have to deal with RETURN-UNDEF specially, so that we don't
 884     # terminate the search prematurely.
 885     foreach (@keys) {
 886         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 887         push @realkeys, $_
 888     }
 889     foreach my $d (access_distros()) {
 890         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 891     }
 892     push @cfgs, map { "dgit.default.$_" } @realkeys;
 893     push @cfgs, @rundef;
 894     return @cfgs;
 895 }
 896
 897 sub access_cfg (@) {
 898     my (@keys) = @_;
 899     my (@cfgs) = access_cfg_cfgs(@keys);
 900     my $value = cfg(@cfgs);
 901     return $value;
 902 }
 903
 904 sub access_cfg_bool ($$) {
 905     my ($def, @keys) = @_;
 906     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 907 }
 908
 909 sub string_to_ssh ($) {
 910     my ($spec) = @_;
 911     if ($spec =~ m/\s/) {
 912         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 913     } else {
 914         return ($spec);
 915     }
 916 }
 917
 918 sub access_cfg_ssh () {
 919     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 920     if (!defined $gitssh) {
 921         return @ssh;
 922     } else {
 923         return string_to_ssh $gitssh;
 924     }
 925 }
 926
 927 sub access_runeinfo ($) {
 928     my ($info) = @_;
 929     return ": dgit ".access_basedistro()." $info ;";
 930 }
 931
 932 sub access_someuserhost ($) {
 933     my ($some) = @_;
 934     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 935     defined($user) && length($user) or
 936         $user = access_cfg("$some-user",'username');
 937     my $host = access_cfg("$some-host");
 938     return length($user) ? "$user\@$host" : $host;
 939 }
 940
 941 sub access_gituserhost () {
 942     return access_someuserhost('git');
 943 }
 944
 945 sub access_giturl (;$) {
 946     my ($optional) = @_;
 947     my $url = access_cfg('git-url','RETURN-UNDEF');
 948     my $suffix;
 949     if (!length $url) {
 950         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 951         return undef unless defined $proto;
 952         $url =
 953             $proto.
 954             access_gituserhost().
 955             access_cfg('git-path');
 956     } else {
 957         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 958     }
 959     $suffix //= '.git';
 960     return "$url/$package$suffix";
 961 }
 962
 963 sub commit_getclogp ($) {
 964     # Returns the parsed changelog hashref for a particular commit
 965     my ($objid) = @_;
 966     our %commit_getclogp_memo;
 967     my $memo = $commit_getclogp_memo{$objid};
 968     return $memo if $memo;
 969
 970     my $mclog = dgit_privdir()."clog";
 971     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 972         "$objid:debian/changelog";
 973     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 974 }
 975
 976 sub parse_dscdata () {
 977     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 978     printdebug Dumper($dscdata) if $debuglevel>1;
 979     $dsc = parsecontrolfh($dscfh,$dscurl,1);
 980     printdebug Dumper($dsc) if $debuglevel>1;
 981 }
 982
 983 our %rmad;
 984
 985 sub archive_query ($;@) {
 986     my ($method) = shift @_;
 987     fail "this operation does not support multiple comma-separated suites"
 988         if $isuite =~ m/,/;
 989     my $query = access_cfg('archive-query','RETURN-UNDEF');
 990     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 991     my $proto = $1;
 992     my $data = $'; #';
 993     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
 994 }
 995
 996 sub archive_query_prepend_mirror {
 997     my $m = access_cfg('mirror');
 998     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
 999 }
1000
1001 sub pool_dsc_subpath ($$) {
1002     my ($vsn,$component) = @_; # $package is implict arg
1003     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1004     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1005 }
1006
1007 sub cfg_apply_map ($$$) {
1008     my ($varref, $what, $mapspec) = @_;
1009     return unless $mapspec;
1010
1011     printdebug "config $what EVAL{ $mapspec; }\n";
1012     $_ = $$varref;
1013     eval "package Dgit::Config; $mapspec;";
1014     die $@ if $@;
1015     $$varref = $_;
1016 }
1017
1018 #---------- `ftpmasterapi' archive query method (nascent) ----------
1019
1020 sub archive_api_query_cmd ($) {
1021     my ($subpath) = @_;
1022     my @cmd = (@curl, qw(-sS));
1023     my $url = access_cfg('archive-query-url');
1024     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1025         my $host = $1;
1026         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1027         foreach my $key (split /\:/, $keys) {
1028             $key =~ s/\%HOST\%/$host/g;
1029             if (!stat $key) {
1030                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1031                 next;
1032             }
1033             fail "config requested specific TLS key but do not know".
1034                 " how to get curl to use exactly that EE key ($key)";
1035 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1036 #           # Sadly the above line does not work because of changes
1037 #           # to gnutls.   The real fix for #790093 may involve
1038 #           # new curl options.
1039             last;
1040         }
1041         # Fixing #790093 properly will involve providing a value
1042         # for this on clients.
1043         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1044         push @cmd, split / /, $kargs if defined $kargs;
1045     }
1046     push @cmd, $url.$subpath;
1047     return @cmd;
1048 }
1049
1050 sub api_query ($$;$) {
1051     use JSON;
1052     my ($data, $subpath, $ok404) = @_;
1053     badcfg "ftpmasterapi archive query method takes no data part"
1054         if length $data;
1055     my @cmd = archive_api_query_cmd($subpath);
1056     my $url = $cmd[$#cmd];
1057     push @cmd, qw(-w %{http_code});
1058     my $json = cmdoutput @cmd;
1059     unless ($json =~ s/\d+\d+\d$//) {
1060         failedcmd_report_cmd undef, @cmd;
1061         fail "curl failed to print 3-digit HTTP code";
1062     }
1063     my $code = $&;
1064     return undef if $code eq '404' && $ok404;
1065     fail "fetch of $url gave HTTP code $code"
1066         unless $url =~ m#^file://# or $code =~ m/^2/;
1067     return decode_json($json);
1068 }
1069
1070 sub canonicalise_suite_ftpmasterapi {
1071     my ($proto,$data) = @_;
1072     my $suites = api_query($data, 'suites');
1073     my @matched;
1074     foreach my $entry (@$suites) {
1075         next unless grep {
1076             my $v = $entry->{$_};
1077             defined $v && $v eq $isuite;
1078         } qw(codename name);
1079         push @matched, $entry;
1080     }
1081     fail "unknown suite $isuite, maybe -d would help" unless @matched;
1082     my $cn;
1083     eval {
1084         @matched==1 or die "multiple matches for suite $isuite\n";
1085         $cn = "$matched[0]{codename}";
1086         defined $cn or die "suite $isuite info has no codename\n";
1087         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1088     };
1089     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1090         if length $@;
1091     return $cn;
1092 }
1093
1094 sub archive_query_ftpmasterapi {
1095     my ($proto,$data) = @_;
1096     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1097     my @rows;
1098     my $digester = Digest::SHA->new(256);
1099     foreach my $entry (@$info) {
1100         eval {
1101             my $vsn = "$entry->{version}";
1102             my ($ok,$msg) = version_check $vsn;
1103             die "bad version: $msg\n" unless $ok;
1104             my $component = "$entry->{component}";
1105             $component =~ m/^$component_re$/ or die "bad component";
1106             my $filename = "$entry->{filename}";
1107             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1108                 or die "bad filename";
1109             my $sha256sum = "$entry->{sha256sum}";
1110             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1111             push @rows, [ $vsn, "/pool/$component/$filename",
1112                           $digester, $sha256sum ];
1113         };
1114         die "bad ftpmaster api response: $@\n".Dumper($entry)
1115             if length $@;
1116     }
1117     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1118     return archive_query_prepend_mirror @rows;
1119 }
1120
1121 sub file_in_archive_ftpmasterapi {
1122     my ($proto,$data,$filename) = @_;
1123     my $pat = $filename;
1124     $pat =~ s/_/\\_/g;
1125     $pat = "%/$pat";
1126     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1127     my $info = api_query($data, "file_in_archive/$pat", 1);
1128 }
1129
1130 sub package_not_wholly_new_ftpmasterapi {
1131     my ($proto,$data,$pkg) = @_;
1132     my $info = api_query($data,"madison?package=${pkg}&f=json");
1133     return !!@$info;
1134 }
1135
1136 #---------- `aptget' archive query method ----------
1137
1138 our $aptget_base;
1139 our $aptget_releasefile;
1140 our $aptget_configpath;
1141
1142 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1143 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1144
1145 sub aptget_cache_clean {
1146     runcmd_ordryrun_local qw(sh -ec),
1147         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1148         'x', $aptget_base;
1149 }
1150
1151 sub aptget_lock_acquire () {
1152     my $lockfile = "$aptget_base/lock";
1153     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1154     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1155 }
1156
1157 sub aptget_prep ($) {
1158     my ($data) = @_;
1159     return if defined $aptget_base;
1160
1161     badcfg "aptget archive query method takes no data part"
1162         if length $data;
1163
1164     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1165
1166     ensuredir $cache;
1167     ensuredir "$cache/dgit";
1168     my $cachekey =
1169         access_cfg('aptget-cachekey','RETURN-UNDEF')
1170         // access_nomdistro();
1171
1172     $aptget_base = "$cache/dgit/aptget";
1173     ensuredir $aptget_base;
1174
1175     my $quoted_base = $aptget_base;
1176     die "$quoted_base contains bad chars, cannot continue"
1177         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1178
1179     ensuredir $aptget_base;
1180
1181     aptget_lock_acquire();
1182
1183     aptget_cache_clean();
1184
1185     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1186     my $sourceslist = "source.list#$cachekey";
1187
1188     my $aptsuites = $isuite;
1189     cfg_apply_map(\$aptsuites, 'suite map',
1190                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1191
1192     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1193     printf SRCS "deb-src %s %s %s\n",
1194         access_cfg('mirror'),
1195         $aptsuites,
1196         access_cfg('aptget-components')
1197         or die $!;
1198
1199     ensuredir "$aptget_base/cache";
1200     ensuredir "$aptget_base/lists";
1201
1202     open CONF, ">", $aptget_configpath or die $!;
1203     print CONF <<END;
1204 Debug::NoLocking "true";
1205 APT::Get::List-Cleanup "false";
1206 #clear APT::Update::Post-Invoke-Success;
1207 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1208 Dir::State::Lists "$quoted_base/lists";
1209 Dir::Etc::preferences "$quoted_base/preferences";
1210 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1211 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1212 END
1213
1214     foreach my $key (qw(
1215                         Dir::Cache
1216                         Dir::State
1217                         Dir::Cache::Archives
1218                         Dir::Etc::SourceParts
1219                         Dir::Etc::preferencesparts
1220                       )) {
1221         ensuredir "$aptget_base/$key";
1222         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1223     };
1224
1225     my $oldatime = (time // die $!) - 1;
1226     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1227         next unless stat_exists $oldlist;
1228         my ($mtime) = (stat _)[9];
1229         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1230     }
1231
1232     runcmd_ordryrun_local aptget_aptget(), qw(update);
1233
1234     my @releasefiles;
1235     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1236         next unless stat_exists $oldlist;
1237         my ($atime) = (stat _)[8];
1238         next if $atime == $oldatime;
1239         push @releasefiles, $oldlist;
1240     }
1241     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1242     @releasefiles = @inreleasefiles if @inreleasefiles;
1243     if (!@releasefiles) {
1244         fail <<END;
1245 apt seemed to not to update dgit's cached Release files for $isuite.
1246 (Perhaps $cache
1247  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1248 END
1249     }
1250     die "apt updated too many Release files (@releasefiles), erk"
1251         unless @releasefiles == 1;
1252
1253     ($aptget_releasefile) = @releasefiles;
1254 }
1255
1256 sub canonicalise_suite_aptget {
1257     my ($proto,$data) = @_;
1258     aptget_prep($data);
1259
1260     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1261
1262     foreach my $name (qw(Codename Suite)) {
1263         my $val = $release->{$name};
1264         if (defined $val) {
1265             printdebug "release file $name: $val\n";
1266             $val =~ m/^$suite_re$/o or fail
1267  "Release file ($aptget_releasefile) specifies intolerable $name";
1268             cfg_apply_map(\$val, 'suite rmap',
1269                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1270             return $val
1271         }
1272     }
1273     return $isuite;
1274 }
1275
1276 sub archive_query_aptget {
1277     my ($proto,$data) = @_;
1278     aptget_prep($data);
1279
1280     ensuredir "$aptget_base/source";
1281     foreach my $old (<$aptget_base/source/*.dsc>) {
1282         unlink $old or die "$old: $!";
1283     }
1284
1285     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1286     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1287     # avoids apt-get source failing with ambiguous error code
1288
1289     runcmd_ordryrun_local
1290         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1291         aptget_aptget(), qw(--download-only --only-source source), $package;
1292
1293     my @dscs = <$aptget_base/source/*.dsc>;
1294     fail "apt-get source did not produce a .dsc" unless @dscs;
1295     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1296
1297     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1298
1299     use URI::Escape;
1300     my $uri = "file://". uri_escape $dscs[0];
1301     $uri =~ s{\%2f}{/}gi;
1302     return [ (getfield $pre_dsc, 'Version'), $uri ];
1303 }
1304
1305 sub file_in_archive_aptget () { return undef; }
1306 sub package_not_wholly_new_aptget () { return undef; }
1307
1308 #---------- `dummyapicat' archive query method ----------
1309
1310 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1311 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1312
1313 sub dummycatapi_run_in_mirror ($@) {
1314     # runs $fn with FIA open onto rune
1315     my ($rune, $argl, $fn) = @_;
1316
1317     my $mirror = access_cfg('mirror');
1318     $mirror =~ s#^file://#/# or die "$mirror ?";
1319     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1320                qw(x), $mirror, @$argl);
1321     debugcmd "-|", @cmd;
1322     open FIA, "-|", @cmd or die $!;
1323     my $r = $fn->();
1324     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1325     return $r;
1326 }
1327
1328 sub file_in_archive_dummycatapi ($$$) {
1329     my ($proto,$data,$filename) = @_;
1330     my @out;
1331     dummycatapi_run_in_mirror '
1332             find -name "$1" -print0 |
1333             xargs -0r sha256sum
1334     ', [$filename], sub {
1335         while (<FIA>) {
1336             chomp or die;
1337             printdebug "| $_\n";
1338             m/^(\w+)  (\S+)$/ or die "$_ ?";
1339             push @out, { sha256sum => $1, filename => $2 };
1340         }
1341     };
1342     return \@out;
1343 }
1344
1345 sub package_not_wholly_new_dummycatapi {
1346     my ($proto,$data,$pkg) = @_;
1347     dummycatapi_run_in_mirror "
1348             find -name ${pkg}_*.dsc
1349     ", [], sub {
1350         local $/ = undef;
1351         !!<FIA>;
1352     };
1353 }
1354
1355 #---------- `madison' archive query method ----------
1356
1357 sub archive_query_madison {
1358     return archive_query_prepend_mirror
1359         map { [ @$_[0..1] ] } madison_get_parse(@_);
1360 }
1361
1362 sub madison_get_parse {
1363     my ($proto,$data) = @_;
1364     die unless $proto eq 'madison';
1365     if (!length $data) {
1366         $data= access_cfg('madison-distro','RETURN-UNDEF');
1367         $data //= access_basedistro();
1368     }
1369     $rmad{$proto,$data,$package} ||= cmdoutput
1370         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1371     my $rmad = $rmad{$proto,$data,$package};
1372
1373     my @out;
1374     foreach my $l (split /\n/, $rmad) {
1375         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1376                   \s*( [^ \t|]+ )\s* \|
1377                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1378                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1379         $1 eq $package or die "$rmad $package ?";
1380         my $vsn = $2;
1381         my $newsuite = $3;
1382         my $component;
1383         if (defined $4) {
1384             $component = $4;
1385         } else {
1386             $component = access_cfg('archive-query-default-component');
1387         }
1388         $5 eq 'source' or die "$rmad ?";
1389         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1390     }
1391     return sort { -version_compare($a->[0],$b->[0]); } @out;
1392 }
1393
1394 sub canonicalise_suite_madison {
1395     # madison canonicalises for us
1396     my @r = madison_get_parse(@_);
1397     @r or fail
1398         "unable to canonicalise suite using package $package".
1399         " which does not appear to exist in suite $isuite;".
1400         " --existing-package may help";
1401     return $r[0][2];
1402 }
1403
1404 sub file_in_archive_madison { return undef; }
1405 sub package_not_wholly_new_madison { return undef; }
1406
1407 #---------- `sshpsql' archive query method ----------
1408
1409 sub sshpsql ($$$) {
1410     my ($data,$runeinfo,$sql) = @_;
1411     if (!length $data) {
1412         $data= access_someuserhost('sshpsql').':'.
1413             access_cfg('sshpsql-dbname');
1414     }
1415     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1416     my ($userhost,$dbname) = ($`,$'); #';
1417     my @rows;
1418     my @cmd = (access_cfg_ssh, $userhost,
1419                access_runeinfo("ssh-psql $runeinfo").
1420                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1421                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1422     debugcmd "|",@cmd;
1423     open P, "-|", @cmd or die $!;
1424     while (<P>) {
1425         chomp or die;
1426         printdebug(">|$_|\n");
1427         push @rows, $_;
1428     }
1429     $!=0; $?=0; close P or failedcmd @cmd;
1430     @rows or die;
1431     my $nrows = pop @rows;
1432     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1433     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1434     @rows = map { [ split /\|/, $_ ] } @rows;
1435     my $ncols = scalar @{ shift @rows };
1436     die if grep { scalar @$_ != $ncols } @rows;
1437     return @rows;
1438 }
1439
1440 sub sql_injection_check {
1441     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1442 }
1443
1444 sub archive_query_sshpsql ($$) {
1445     my ($proto,$data) = @_;
1446     sql_injection_check $isuite, $package;
1447     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1448         SELECT source.version, component.name, files.filename, files.sha256sum
1449           FROM source
1450           JOIN src_associations ON source.id = src_associations.source
1451           JOIN suite ON suite.id = src_associations.suite
1452           JOIN dsc_files ON dsc_files.source = source.id
1453           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1454           JOIN component ON component.id = files_archive_map.component_id
1455           JOIN files ON files.id = dsc_files.file
1456          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1457            AND source.source='$package'
1458            AND files.filename LIKE '%.dsc';
1459 END
1460     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1461     my $digester = Digest::SHA->new(256);
1462     @rows = map {
1463         my ($vsn,$component,$filename,$sha256sum) = @$_;
1464         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1465     } @rows;
1466     return archive_query_prepend_mirror @rows;
1467 }
1468
1469 sub canonicalise_suite_sshpsql ($$) {
1470     my ($proto,$data) = @_;
1471     sql_injection_check $isuite;
1472     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1473         SELECT suite.codename
1474           FROM suite where suite_name='$isuite' or codename='$isuite';
1475 END
1476     @rows = map { $_->[0] } @rows;
1477     fail "unknown suite $isuite" unless @rows;
1478     die "ambiguous $isuite: @rows ?" if @rows>1;
1479     return $rows[0];
1480 }
1481
1482 sub file_in_archive_sshpsql ($$$) { return undef; }
1483 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1484
1485 #---------- `dummycat' archive query method ----------
1486
1487 sub canonicalise_suite_dummycat ($$) {
1488     my ($proto,$data) = @_;
1489     my $dpath = "$data/suite.$isuite";
1490     if (!open C, "<", $dpath) {
1491         $!==ENOENT or die "$dpath: $!";
1492         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1493         return $isuite;
1494     }
1495     $!=0; $_ = <C>;
1496     chomp or die "$dpath: $!";
1497     close C;
1498     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1499     return $_;
1500 }
1501
1502 sub archive_query_dummycat ($$) {
1503     my ($proto,$data) = @_;
1504     canonicalise_suite();
1505     my $dpath = "$data/package.$csuite.$package";
1506     if (!open C, "<", $dpath) {
1507         $!==ENOENT or die "$dpath: $!";
1508         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1509         return ();
1510     }
1511     my @rows;
1512     while (<C>) {
1513         next if m/^\#/;
1514         next unless m/\S/;
1515         die unless chomp;
1516         printdebug "dummycat query $csuite $package $dpath | $_\n";
1517         my @row = split /\s+/, $_;
1518         @row==2 or die "$dpath: $_ ?";
1519         push @rows, \@row;
1520     }
1521     C->error and die "$dpath: $!";
1522     close C;
1523     return archive_query_prepend_mirror
1524         sort { -version_compare($a->[0],$b->[0]); } @rows;
1525 }
1526
1527 sub file_in_archive_dummycat () { return undef; }
1528 sub package_not_wholly_new_dummycat () { return undef; }
1529
1530 #---------- tag format handling ----------
1531
1532 sub access_cfg_tagformats () {
1533     split /\,/, access_cfg('dgit-tag-format');
1534 }
1535
1536 sub access_cfg_tagformats_can_splitbrain () {
1537     my %y = map { $_ => 1 } access_cfg_tagformats;
1538     foreach my $needtf (qw(new maint)) {
1539         next if $y{$needtf};
1540         return 0;
1541     }
1542     return 1;
1543 }
1544
1545 sub need_tagformat ($$) {
1546     my ($fmt, $why) = @_;
1547     fail "need to use tag format $fmt ($why) but also need".
1548         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1549         " - no way to proceed"
1550         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1551     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1552 }
1553
1554 sub select_tagformat () {
1555     # sets $tagformatfn
1556     return if $tagformatfn && !$tagformat_want;
1557     die 'bug' if $tagformatfn && $tagformat_want;
1558     # ... $tagformat_want assigned after previous select_tagformat
1559
1560     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1561     printdebug "select_tagformat supported @supported\n";
1562
1563     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1564     printdebug "select_tagformat specified @$tagformat_want\n";
1565
1566     my ($fmt,$why,$override) = @$tagformat_want;
1567
1568     fail "target distro supports tag formats @supported".
1569         " but have to use $fmt ($why)"
1570         unless $override
1571             or grep { $_ eq $fmt } @supported;
1572
1573     $tagformat_want = undef;
1574     $tagformat = $fmt;
1575     $tagformatfn = ${*::}{"debiantag_$fmt"};
1576
1577     fail "trying to use unknown tag format \`$fmt' ($why) !"
1578         unless $tagformatfn;
1579 }
1580
1581 #---------- archive query entrypoints and rest of program ----------
1582
1583 sub canonicalise_suite () {
1584     return if defined $csuite;
1585     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1586     $csuite = archive_query('canonicalise_suite');
1587     if ($isuite ne $csuite) {
1588         progress "canonical suite name for $isuite is $csuite";
1589     } else {
1590         progress "canonical suite name is $csuite";
1591     }
1592 }
1593
1594 sub get_archive_dsc () {
1595     canonicalise_suite();
1596     my @vsns = archive_query('archive_query');
1597     foreach my $vinfo (@vsns) {
1598         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1599         $dscurl = $vsn_dscurl;
1600         $dscdata = url_get($dscurl);
1601         if (!$dscdata) {
1602             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1603             next;
1604         }
1605         if ($digester) {
1606             $digester->reset();
1607             $digester->add($dscdata);
1608             my $got = $digester->hexdigest();
1609             $got eq $digest or
1610                 fail "$dscurl has hash $got but".
1611                     " archive told us to expect $digest";
1612         }
1613         parse_dscdata();
1614         my $fmt = getfield $dsc, 'Format';
1615         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1616             "unsupported source format $fmt, sorry";
1617
1618         $dsc_checked = !!$digester;
1619         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1620         return;
1621     }
1622     $dsc = undef;
1623     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1624 }
1625
1626 sub check_for_git ();
1627 sub check_for_git () {
1628     # returns 0 or 1
1629     my $how = access_cfg('git-check');
1630     if ($how eq 'ssh-cmd') {
1631         my @cmd =
1632             (access_cfg_ssh, access_gituserhost(),
1633              access_runeinfo("git-check $package").
1634              " set -e; cd ".access_cfg('git-path').";".
1635              " if test -d $package.git; then echo 1; else echo 0; fi");
1636         my $r= cmdoutput @cmd;
1637         if (defined $r and $r =~ m/^divert (\w+)$/) {
1638             my $divert=$1;
1639             my ($usedistro,) = access_distros();
1640             # NB that if we are pushing, $usedistro will be $distro/push
1641             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1642             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1643             progress "diverting to $divert (using config for $instead_distro)";
1644             return check_for_git();
1645         }
1646         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1647         return $r+0;
1648     } elsif ($how eq 'url') {
1649         my $prefix = access_cfg('git-check-url','git-url');
1650         my $suffix = access_cfg('git-check-suffix','git-suffix',
1651                                 'RETURN-UNDEF') // '.git';
1652         my $url = "$prefix/$package$suffix";
1653         my @cmd = (@curl, qw(-sS -I), $url);
1654         my $result = cmdoutput @cmd;
1655         $result =~ s/^\S+ 200 .*\n\r?\n//;
1656         # curl -sS -I with https_proxy prints
1657         # HTTP/1.0 200 Connection established
1658         $result =~ m/^\S+ (404|200) /s or
1659             fail "unexpected results from git check query - ".
1660                 Dumper($prefix, $result);
1661         my $code = $1;
1662         if ($code eq '404') {
1663             return 0;
1664         } elsif ($code eq '200') {
1665             return 1;
1666         } else {
1667             die;
1668         }
1669     } elsif ($how eq 'true') {
1670         return 1;
1671     } elsif ($how eq 'false') {
1672         return 0;
1673     } else {
1674         badcfg "unknown git-check \`$how'";
1675     }
1676 }
1677
1678 sub create_remote_git_repo () {
1679     my $how = access_cfg('git-create');
1680     if ($how eq 'ssh-cmd') {
1681         runcmd_ordryrun
1682             (access_cfg_ssh, access_gituserhost(),
1683              access_runeinfo("git-create $package").
1684              "set -e; cd ".access_cfg('git-path').";".
1685              " cp -a _template $package.git");
1686     } elsif ($how eq 'true') {
1687         # nothing to do
1688     } else {
1689         badcfg "unknown git-create \`$how'";
1690     }
1691 }
1692
1693 our ($dsc_hash,$lastpush_mergeinput);
1694 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1695
1696
1697 sub prep_ud () {
1698     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1699     $playground = fresh_playground 'dgit/unpack';
1700 }
1701
1702 sub mktree_in_ud_here () {
1703     playtree_setup $gitcfgs{local};
1704 }
1705
1706 sub git_write_tree () {
1707     my $tree = cmdoutput @git, qw(write-tree);
1708     $tree =~ m/^\w+$/ or die "$tree ?";
1709     return $tree;
1710 }
1711
1712 sub git_add_write_tree () {
1713     runcmd @git, qw(add -Af .);
1714     return git_write_tree();
1715 }
1716
1717 sub remove_stray_gits ($) {
1718     my ($what) = @_;
1719     my @gitscmd = qw(find -name .git -prune -print0);
1720     debugcmd "|",@gitscmd;
1721     open GITS, "-|", @gitscmd or die $!;
1722     {
1723         local $/="\0";
1724         while (<GITS>) {
1725             chomp or die;
1726             print STDERR "$us: warning: removing from $what: ",
1727                 (messagequote $_), "\n";
1728             rmtree $_;
1729         }
1730     }
1731     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1732 }
1733
1734 sub mktree_in_ud_from_only_subdir ($;$) {
1735     my ($what,$raw) = @_;
1736     # changes into the subdir
1737
1738     my (@dirs) = <*/.>;
1739     die "expected one subdir but found @dirs ?" unless @dirs==1;
1740     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1741     my $dir = $1;
1742     changedir $dir;
1743
1744     remove_stray_gits($what);
1745     mktree_in_ud_here();
1746     if (!$raw) {
1747         my ($format, $fopts) = get_source_format();
1748         if (madformat($format)) {
1749             rmtree '.pc';
1750         }
1751     }
1752
1753     my $tree=git_add_write_tree();
1754     return ($tree,$dir);
1755 }
1756
1757 our @files_csum_info_fields =
1758     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1759      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1760      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1761
1762 sub dsc_files_info () {
1763     foreach my $csumi (@files_csum_info_fields) {
1764         my ($fname, $module, $method) = @$csumi;
1765         my $field = $dsc->{$fname};
1766         next unless defined $field;
1767         eval "use $module; 1;" or die $@;
1768         my @out;
1769         foreach (split /\n/, $field) {
1770             next unless m/\S/;
1771             m/^(\w+) (\d+) (\S+)$/ or
1772                 fail "could not parse .dsc $fname line \`$_'";
1773             my $digester = eval "$module"."->$method;" or die $@;
1774             push @out, {
1775                 Hash => $1,
1776                 Bytes => $2,
1777                 Filename => $3,
1778                 Digester => $digester,
1779             };
1780         }
1781         return @out;
1782     }
1783     fail "missing any supported Checksums-* or Files field in ".
1784         $dsc->get_option('name');
1785 }
1786
1787 sub dsc_files () {
1788     map { $_->{Filename} } dsc_files_info();
1789 }
1790
1791 sub files_compare_inputs (@) {
1792     my $inputs = \@_;
1793     my %record;
1794     my %fchecked;
1795
1796     my $showinputs = sub {
1797         return join "; ", map { $_->get_option('name') } @$inputs;
1798     };
1799
1800     foreach my $in (@$inputs) {
1801         my $expected_files;
1802         my $in_name = $in->get_option('name');
1803
1804         printdebug "files_compare_inputs $in_name\n";
1805
1806         foreach my $csumi (@files_csum_info_fields) {
1807             my ($fname) = @$csumi;
1808             printdebug "files_compare_inputs $in_name $fname\n";
1809
1810             my $field = $in->{$fname};
1811             next unless defined $field;
1812
1813             my @files;
1814             foreach (split /\n/, $field) {
1815                 next unless m/\S/;
1816
1817                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1818                     fail "could not parse $in_name $fname line \`$_'";
1819
1820                 printdebug "files_compare_inputs $in_name $fname $f\n";
1821
1822                 push @files, $f;
1823
1824                 my $re = \ $record{$f}{$fname};
1825                 if (defined $$re) {
1826                     $fchecked{$f}{$in_name} = 1;
1827                     $$re eq $info or
1828                         fail "hash or size of $f varies in $fname fields".
1829                         " (between: ".$showinputs->().")";
1830                 } else {
1831                     $$re = $info;
1832                 }
1833             }
1834             @files = sort @files;
1835             $expected_files //= \@files;
1836             "@$expected_files" eq "@files" or
1837                 fail "file list in $in_name varies between hash fields!";
1838         }
1839         $expected_files or
1840             fail "$in_name has no files list field(s)";
1841     }
1842     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1843         if $debuglevel>=2;
1844
1845     grep { keys %$_ == @$inputs-1 } values %fchecked
1846         or fail "no file appears in all file lists".
1847         " (looked in: ".$showinputs->().")";
1848 }
1849
1850 sub is_orig_file_in_dsc ($$) {
1851     my ($f, $dsc_files_info) = @_;
1852     return 0 if @$dsc_files_info <= 1;
1853     # One file means no origs, and the filename doesn't have a "what
1854     # part of dsc" component.  (Consider versions ending `.orig'.)
1855     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1856     return 1;
1857 }
1858
1859 # This function determines whether a .changes file is source-only from
1860 # the point of view of dak.  Thus, it permits *_source.buildinfo
1861 # files.
1862 #
1863 # It does not, however, permit any other buildinfo files.  After a
1864 # source-only upload, the buildds will try to upload files like
1865 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1866 # named like this in their (otherwise) source-only upload, the uploads
1867 # of the buildd can be rejected by dak.  Fixing the resultant
1868 # situation can require manual intervention.  So we block such
1869 # .buildinfo files when the user tells us to perform a source-only
1870 # upload (such as when using the push-source subcommand with the -C
1871 # option, which calls this function).
1872 #
1873 # Note, though, that when dgit is told to prepare a source-only
1874 # upload, such as when subcommands like build-source and push-source
1875 # without -C are used, dgit has a more restrictive notion of
1876 # source-only .changes than dak: such uploads will never include
1877 # *_source.buildinfo files.  This is because there is no use for such
1878 # files when using a tool like dgit to produce the source package, as
1879 # dgit ensures the source is identical to git HEAD.
1880 sub test_source_only_changes ($) {
1881     my ($changes) = @_;
1882     foreach my $l (split /\n/, getfield $changes, 'Files') {
1883         $l =~ m/\S+$/ or next;
1884         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
1885         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
1886             print "purportedly source-only changes polluted by $&\n";
1887             return 0;
1888         }
1889     }
1890     return 1;
1891 }
1892
1893 sub changes_update_origs_from_dsc ($$$$) {
1894     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1895     my %changes_f;
1896     printdebug "checking origs needed ($upstreamvsn)...\n";
1897     $_ = getfield $changes, 'Files';
1898     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1899         fail "cannot find section/priority from .changes Files field";
1900     my $placementinfo = $1;
1901     my %changed;
1902     printdebug "checking origs needed placement '$placementinfo'...\n";
1903     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1904         $l =~ m/\S+$/ or next;
1905         my $file = $&;
1906         printdebug "origs $file | $l\n";
1907         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1908         printdebug "origs $file is_orig\n";
1909         my $have = archive_query('file_in_archive', $file);
1910         if (!defined $have) {
1911             print STDERR <<END;
1912 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1913 END
1914             return;
1915         }
1916         my $found_same = 0;
1917         my @found_differ;
1918         printdebug "origs $file \$#\$have=$#$have\n";
1919         foreach my $h (@$have) {
1920             my $same = 0;
1921             my @differ;
1922             foreach my $csumi (@files_csum_info_fields) {
1923                 my ($fname, $module, $method, $archivefield) = @$csumi;
1924                 next unless defined $h->{$archivefield};
1925                 $_ = $dsc->{$fname};
1926                 next unless defined;
1927                 m/^(\w+) .* \Q$file\E$/m or
1928                     fail ".dsc $fname missing entry for $file";
1929                 if ($h->{$archivefield} eq $1) {
1930                     $same++;
1931                 } else {
1932                     push @differ,
1933  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1934                 }
1935             }
1936             die "$file ".Dumper($h)." ?!" if $same && @differ;
1937             $found_same++
1938                 if $same;
1939             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1940                 if @differ;
1941         }
1942         printdebug "origs $file f.same=$found_same".
1943             " #f._differ=$#found_differ\n";
1944         if (@found_differ && !$found_same) {
1945             fail join "\n",
1946                 "archive contains $file with different checksum",
1947                 @found_differ;
1948         }
1949         # Now we edit the changes file to add or remove it
1950         foreach my $csumi (@files_csum_info_fields) {
1951             my ($fname, $module, $method, $archivefield) = @$csumi;
1952             next unless defined $changes->{$fname};
1953             if ($found_same) {
1954                 # in archive, delete from .changes if it's there
1955                 $changed{$file} = "removed" if
1956                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
1957             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
1958                 # not in archive, but it's here in the .changes
1959             } else {
1960                 my $dsc_data = getfield $dsc, $fname;
1961                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
1962                 my $extra = $1;
1963                 $extra =~ s/ \d+ /$&$placementinfo /
1964                     or die "$fname $extra >$dsc_data< ?"
1965                     if $fname eq 'Files';
1966                 $changes->{$fname} .= "\n". $extra;
1967                 $changed{$file} = "added";
1968             }
1969         }
1970     }
1971     if (%changed) {
1972         foreach my $file (keys %changed) {
1973             progress sprintf
1974                 "edited .changes for archive .orig contents: %s %s",
1975                 $changed{$file}, $file;
1976         }
1977         my $chtmp = "$changesfile.tmp";
1978         $changes->save($chtmp);
1979         if (act_local()) {
1980             rename $chtmp,$changesfile or die "$changesfile $!";
1981         } else {
1982             progress "[new .changes left in $changesfile]";
1983         }
1984     } else {
1985         progress "$changesfile already has appropriate .orig(s) (if any)";
1986     }
1987 }
1988
1989 sub make_commit ($) {
1990     my ($file) = @_;
1991     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1992 }
1993
1994 sub clogp_authline ($) {
1995     my ($clogp) = @_;
1996     my $author = getfield $clogp, 'Maintainer';
1997     if ($author =~ m/^[^"\@]+\,/) {
1998         # single entry Maintainer field with unquoted comma
1999         $author = ($& =~ y/,//rd).$'; # strip the comma
2000     }
2001     # git wants a single author; any remaining commas in $author
2002     # are by now preceded by @ (or ").  It seems safer to punt on
2003     # "..." for now rather than attempting to dequote or something.
2004     $author =~ s#,.*##ms unless $author =~ m/"/;
2005     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2006     my $authline = "$author $date";
2007     $authline =~ m/$git_authline_re/o or
2008         fail "unexpected commit author line format \`$authline'".
2009         " (was generated from changelog Maintainer field)";
2010     return ($1,$2,$3) if wantarray;
2011     return $authline;
2012 }
2013
2014 sub vendor_patches_distro ($$) {
2015     my ($checkdistro, $what) = @_;
2016     return unless defined $checkdistro;
2017
2018     my $series = "debian/patches/\L$checkdistro\E.series";
2019     printdebug "checking for vendor-specific $series ($what)\n";
2020
2021     if (!open SERIES, "<", $series) {
2022         die "$series $!" unless $!==ENOENT;
2023         return;
2024     }
2025     while (<SERIES>) {
2026         next unless m/\S/;
2027         next if m/^\s+\#/;
2028
2029         print STDERR <<END;
2030
2031 Unfortunately, this source package uses a feature of dpkg-source where
2032 the same source package unpacks to different source code on different
2033 distros.  dgit cannot safely operate on such packages on affected
2034 distros, because the meaning of source packages is not stable.
2035
2036 Please ask the distro/maintainer to remove the distro-specific series
2037 files and use a different technique (if necessary, uploading actually
2038 different packages, if different distros are supposed to have
2039 different code).
2040
2041 END
2042         fail "Found active distro-specific series file for".
2043             " $checkdistro ($what): $series, cannot continue";
2044     }
2045     die "$series $!" if SERIES->error;
2046     close SERIES;
2047 }
2048
2049 sub check_for_vendor_patches () {
2050     # This dpkg-source feature doesn't seem to be documented anywhere!
2051     # But it can be found in the changelog (reformatted):
2052
2053     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2054     #   Author: Raphael Hertzog <hertzog@debian.org>
2055     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2056
2057     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2058     #   series files
2059     #
2060     #   If you have debian/patches/ubuntu.series and you were
2061     #   unpacking the source package on ubuntu, quilt was still
2062     #   directed to debian/patches/series instead of
2063     #   debian/patches/ubuntu.series.
2064     #
2065     #   debian/changelog                        |    3 +++
2066     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2067     #   2 files changed, 6 insertions(+), 1 deletion(-)
2068
2069     use Dpkg::Vendor;
2070     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2071     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2072                          "Dpkg::Vendor \`current vendor'");
2073     vendor_patches_distro(access_basedistro(),
2074                           "(base) distro being accessed");
2075     vendor_patches_distro(access_nomdistro(),
2076                           "(nominal) distro being accessed");
2077 }
2078
2079 sub generate_commits_from_dsc () {
2080     # See big comment in fetch_from_archive, below.
2081     # See also README.dsc-import.
2082     prep_ud();
2083     changedir $playground;
2084
2085     my @dfi = dsc_files_info();
2086     foreach my $fi (@dfi) {
2087         my $f = $fi->{Filename};
2088         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2089         my $upper_f = (bpd_abs()."/$f");
2090
2091         printdebug "considering reusing $f: ";
2092
2093         if (link_ltarget "$upper_f,fetch", $f) {
2094             printdebug "linked (using ...,fetch).\n";
2095         } elsif ((printdebug "($!) "),
2096                  $! != ENOENT) {
2097             fail "accessing $buildproductsdir/$f,fetch: $!";
2098         } elsif (link_ltarget $upper_f, $f) {
2099             printdebug "linked.\n";
2100         } elsif ((printdebug "($!) "),
2101                  $! != ENOENT) {
2102             fail "accessing $buildproductsdir/$f: $!";
2103         } else {
2104             printdebug "absent.\n";
2105         }
2106
2107         my $refetched;
2108         complete_file_from_dsc('.', $fi, \$refetched)
2109             or next;
2110
2111         printdebug "considering saving $f: ";
2112
2113         if (link $f, $upper_f) {
2114             printdebug "linked.\n";
2115         } elsif ((printdebug "($!) "),
2116                  $! != EEXIST) {
2117             fail "saving $buildproductsdir/$f: $!";
2118         } elsif (!$refetched) {
2119             printdebug "no need.\n";
2120         } elsif (link $f, "$upper_f,fetch") {
2121             printdebug "linked (using ...,fetch).\n";
2122         } elsif ((printdebug "($!) "),
2123                  $! != EEXIST) {
2124             fail "saving $buildproductsdir/$f,fetch: $!";
2125         } else {
2126             printdebug "cannot.\n";
2127         }
2128     }
2129
2130     # We unpack and record the orig tarballs first, so that we only
2131     # need disk space for one private copy of the unpacked source.
2132     # But we can't make them into commits until we have the metadata
2133     # from the debian/changelog, so we record the tree objects now and
2134     # make them into commits later.
2135     my @tartrees;
2136     my $upstreamv = upstreamversion $dsc->{version};
2137     my $orig_f_base = srcfn $upstreamv, '';
2138
2139     foreach my $fi (@dfi) {
2140         # We actually import, and record as a commit, every tarball
2141         # (unless there is only one file, in which case there seems
2142         # little point.
2143
2144         my $f = $fi->{Filename};
2145         printdebug "import considering $f ";
2146         (printdebug "only one dfi\n"), next if @dfi == 1;
2147         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2148         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2149         my $compr_ext = $1;
2150
2151         my ($orig_f_part) =
2152             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2153
2154         printdebug "Y ", (join ' ', map { $_//"(none)" }
2155                           $compr_ext, $orig_f_part
2156                          ), "\n";
2157
2158         my $input = new IO::File $f, '<' or die "$f $!";
2159         my $compr_pid;
2160         my @compr_cmd;
2161
2162         if (defined $compr_ext) {
2163             my $cname =
2164                 Dpkg::Compression::compression_guess_from_filename $f;
2165             fail "Dpkg::Compression cannot handle file $f in source package"
2166                 if defined $compr_ext && !defined $cname;
2167             my $compr_proc =
2168                 new Dpkg::Compression::Process compression => $cname;
2169             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2170             my $compr_fh = new IO::Handle;
2171             my $compr_pid = open $compr_fh, "-|" // die $!;
2172             if (!$compr_pid) {
2173                 open STDIN, "<&", $input or die $!;
2174                 exec @compr_cmd;
2175                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2176             }
2177             $input = $compr_fh;
2178         }
2179
2180         rmtree "_unpack-tar";
2181         mkdir "_unpack-tar" or die $!;
2182         my @tarcmd = qw(tar -x -f -
2183                         --no-same-owner --no-same-permissions
2184                         --no-acls --no-xattrs --no-selinux);
2185         my $tar_pid = fork // die $!;
2186         if (!$tar_pid) {
2187             chdir "_unpack-tar" or die $!;
2188             open STDIN, "<&", $input or die $!;
2189             exec @tarcmd;
2190             die "dgit (child): exec $tarcmd[0]: $!";
2191         }
2192         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2193         !$? or failedcmd @tarcmd;
2194
2195         close $input or
2196             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2197              : die $!);
2198         # finally, we have the results in "tarball", but maybe
2199         # with the wrong permissions
2200
2201         runcmd qw(chmod -R +rwX _unpack-tar);
2202         changedir "_unpack-tar";
2203         remove_stray_gits($f);
2204         mktree_in_ud_here();
2205
2206         my ($tree) = git_add_write_tree();
2207         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2208         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2209             $tree = $1;
2210             printdebug "one subtree $1\n";
2211         } else {
2212             printdebug "multiple subtrees\n";
2213         }
2214         changedir "..";
2215         rmtree "_unpack-tar";
2216
2217         my $ent = [ $f, $tree ];
2218         push @tartrees, {
2219             Orig => !!$orig_f_part,
2220             Sort => (!$orig_f_part         ? 2 :
2221                      $orig_f_part =~ m/-/g ? 1 :
2222                                              0),
2223             F => $f,
2224             Tree => $tree,
2225         };
2226     }
2227
2228     @tartrees = sort {
2229         # put any without "_" first (spec is not clear whether files
2230         # are always in the usual order).  Tarballs without "_" are
2231         # the main orig or the debian tarball.
2232         $a->{Sort} <=> $b->{Sort} or
2233         $a->{F}    cmp $b->{F}
2234     } @tartrees;
2235
2236     my $any_orig = grep { $_->{Orig} } @tartrees;
2237
2238     my $dscfn = "$package.dsc";
2239
2240     my $treeimporthow = 'package';
2241
2242     open D, ">", $dscfn or die "$dscfn: $!";
2243     print D $dscdata or die "$dscfn: $!";
2244     close D or die "$dscfn: $!";
2245     my @cmd = qw(dpkg-source);
2246     push @cmd, '--no-check' if $dsc_checked;
2247     if (madformat $dsc->{format}) {
2248         push @cmd, '--skip-patches';
2249         $treeimporthow = 'unpatched';
2250     }
2251     push @cmd, qw(-x --), $dscfn;
2252     runcmd @cmd;
2253
2254     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2255     if (madformat $dsc->{format}) {
2256         check_for_vendor_patches();
2257     }
2258
2259     my $dappliedtree;
2260     if (madformat $dsc->{format}) {
2261         my @pcmd = qw(dpkg-source --before-build .);
2262         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2263         rmtree '.pc';
2264         $dappliedtree = git_add_write_tree();
2265     }
2266
2267     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2268     my $clogp;
2269     my $r1clogp;
2270
2271     printdebug "import clog search...\n";
2272     parsechangelog_loop \@clogcmd, "package changelog", sub {
2273         my ($thisstanza, $desc) = @_;
2274         no warnings qw(exiting);
2275
2276         $clogp //= $thisstanza;
2277
2278         printdebug "import clog $thisstanza->{version} $desc...\n";
2279
2280         last if !$any_orig; # we don't need $r1clogp
2281
2282         # We look for the first (most recent) changelog entry whose
2283         # version number is lower than the upstream version of this
2284         # package.  Then the last (least recent) previous changelog
2285         # entry is treated as the one which introduced this upstream
2286         # version and used for the synthetic commits for the upstream
2287         # tarballs.
2288
2289         # One might think that a more sophisticated algorithm would be
2290         # necessary.  But: we do not want to scan the whole changelog
2291         # file.  Stopping when we see an earlier version, which
2292         # necessarily then is an earlier upstream version, is the only
2293         # realistic way to do that.  Then, either the earliest
2294         # changelog entry we have seen so far is indeed the earliest
2295         # upload of this upstream version; or there are only changelog
2296         # entries relating to later upstream versions (which is not
2297         # possible unless the changelog and .dsc disagree about the
2298         # version).  Then it remains to choose between the physically
2299         # last entry in the file, and the one with the lowest version
2300         # number.  If these are not the same, we guess that the
2301         # versions were created in a non-monotonic order rather than
2302         # that the changelog entries have been misordered.
2303
2304         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2305
2306         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2307         $r1clogp = $thisstanza;
2308
2309         printdebug "import clog $r1clogp->{version} becomes r1\n";
2310     };
2311
2312     $clogp or fail "package changelog has no entries!";
2313
2314     my $authline = clogp_authline $clogp;
2315     my $changes = getfield $clogp, 'Changes';
2316     $changes =~ s/^\n//; # Changes: \n
2317     my $cversion = getfield $clogp, 'Version';
2318
2319     if (@tartrees) {
2320         $r1clogp //= $clogp; # maybe there's only one entry;
2321         my $r1authline = clogp_authline $r1clogp;
2322         # Strictly, r1authline might now be wrong if it's going to be
2323         # unused because !$any_orig.  Whatever.
2324
2325         printdebug "import tartrees authline   $authline\n";
2326         printdebug "import tartrees r1authline $r1authline\n";
2327
2328         foreach my $tt (@tartrees) {
2329             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2330
2331             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2332 tree $tt->{Tree}
2333 author $r1authline
2334 committer $r1authline
2335
2336 Import $tt->{F}
2337
2338 [dgit import orig $tt->{F}]
2339 END_O
2340 tree $tt->{Tree}
2341 author $authline
2342 committer $authline
2343
2344 Import $tt->{F}
2345
2346 [dgit import tarball $package $cversion $tt->{F}]
2347 END_T
2348         }
2349     }
2350
2351     printdebug "import main commit\n";
2352
2353     open C, ">../commit.tmp" or die $!;
2354     print C <<END or die $!;
2355 tree $tree
2356 END
2357     print C <<END or die $! foreach @tartrees;
2358 parent $_->{Commit}
2359 END
2360     print C <<END or die $!;
2361 author $authline
2362 committer $authline
2363
2364 $changes
2365
2366 [dgit import $treeimporthow $package $cversion]
2367 END
2368
2369     close C or die $!;
2370     my $rawimport_hash = make_commit qw(../commit.tmp);
2371
2372     if (madformat $dsc->{format}) {
2373         printdebug "import apply patches...\n";
2374
2375         # regularise the state of the working tree so that
2376         # the checkout of $rawimport_hash works nicely.
2377         my $dappliedcommit = make_commit_text(<<END);
2378 tree $dappliedtree
2379 author $authline
2380 committer $authline
2381
2382 [dgit dummy commit]
2383 END
2384         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2385
2386         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2387
2388         # We need the answers to be reproducible
2389         my @authline = clogp_authline($clogp);
2390         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2391         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2392         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2393         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2394         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2395         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2396
2397         my $path = $ENV{PATH} or die;
2398
2399         # we use ../../gbp-pq-output, which (given that we are in
2400         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2401         # is .git/dgit.
2402
2403         foreach my $use_absurd (qw(0 1)) {
2404             runcmd @git, qw(checkout -q unpa);
2405             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2406             local $ENV{PATH} = $path;
2407             if ($use_absurd) {
2408                 chomp $@;
2409                 progress "warning: $@";
2410                 $path = "$absurdity:$path";
2411                 progress "$us: trying slow absurd-git-apply...";
2412                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2413                     or $!==ENOENT
2414                     or die $!;
2415             }
2416             eval {
2417                 die "forbid absurd git-apply\n" if $use_absurd
2418                     && forceing [qw(import-gitapply-no-absurd)];
2419                 die "only absurd git-apply!\n" if !$use_absurd
2420                     && forceing [qw(import-gitapply-absurd)];
2421
2422                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2423                 local $ENV{PATH} = $path                    if $use_absurd;
2424
2425                 my @showcmd = (gbp_pq, qw(import));
2426                 my @realcmd = shell_cmd
2427                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2428                 debugcmd "+",@realcmd;
2429                 if (system @realcmd) {
2430                     die +(shellquote @showcmd).
2431                         " failed: ".
2432                         failedcmd_waitstatus()."\n";
2433                 }
2434
2435                 my $gapplied = git_rev_parse('HEAD');
2436                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2437                 $gappliedtree eq $dappliedtree or
2438                     fail <<END;
2439 gbp-pq import and dpkg-source disagree!
2440  gbp-pq import gave commit $gapplied
2441  gbp-pq import gave tree $gappliedtree
2442  dpkg-source --before-build gave tree $dappliedtree
2443 END
2444                 $rawimport_hash = $gapplied;
2445             };
2446             last unless $@;
2447         }
2448         if ($@) {
2449             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2450             die $@;
2451         }
2452     }
2453
2454     progress "synthesised git commit from .dsc $cversion";
2455
2456     my $rawimport_mergeinput = {
2457         Commit => $rawimport_hash,
2458         Info => "Import of source package",
2459     };
2460     my @output = ($rawimport_mergeinput);
2461
2462     if ($lastpush_mergeinput) {
2463         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2464         my $oversion = getfield $oldclogp, 'Version';
2465         my $vcmp =
2466             version_compare($oversion, $cversion);
2467         if ($vcmp < 0) {
2468             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2469                 { Message => <<END, ReverseParents => 1 });
2470 Record $package ($cversion) in archive suite $csuite
2471 END
2472         } elsif ($vcmp > 0) {
2473             print STDERR <<END or die $!;
2474
2475 Version actually in archive:   $cversion (older)
2476 Last version pushed with dgit: $oversion (newer or same)
2477 $later_warning_msg
2478 END
2479             @output = $lastpush_mergeinput;
2480         } else {
2481             # Same version.  Use what's in the server git branch,
2482             # discarding our own import.  (This could happen if the
2483             # server automatically imports all packages into git.)
2484             @output = $lastpush_mergeinput;
2485         }
2486     }
2487     changedir $maindir;
2488     rmtree $playground;
2489     return @output;
2490 }
2491
2492 sub complete_file_from_dsc ($$;$) {
2493     our ($dstdir, $fi, $refetched) = @_;
2494     # Ensures that we have, in $dstdir, the file $fi, with the correct
2495     # contents.  (Downloading it from alongside $dscurl if necessary.)
2496     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2497     # and will set $$refetched=1 if it did so (or tried to).
2498
2499     my $f = $fi->{Filename};
2500     my $tf = "$dstdir/$f";
2501     my $downloaded = 0;
2502
2503     my $got;
2504     my $checkhash = sub {
2505         open F, "<", "$tf" or die "$tf: $!";
2506         $fi->{Digester}->reset();
2507         $fi->{Digester}->addfile(*F);
2508         F->error and die $!;
2509         $got = $fi->{Digester}->hexdigest();
2510         return $got eq $fi->{Hash};
2511     };
2512
2513     if (stat_exists $tf) {
2514         if ($checkhash->()) {
2515             progress "using existing $f";
2516             return 1;
2517         }
2518         if (!$refetched) {
2519             fail "file $f has hash $got but .dsc".
2520                 " demands hash $fi->{Hash} ".
2521                 "(perhaps you should delete this file?)";
2522         }
2523         progress "need to fetch correct version of $f";
2524         unlink $tf or die "$tf $!";
2525         $$refetched = 1;
2526     } else {
2527         printdebug "$tf does not exist, need to fetch\n";
2528     }
2529
2530     my $furl = $dscurl;
2531     $furl =~ s{/[^/]+$}{};
2532     $furl .= "/$f";
2533     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2534     die "$f ?" if $f =~ m#/#;
2535     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2536     return 0 if !act_local();
2537
2538     $checkhash->() or
2539         fail "file $f has hash $got but .dsc".
2540             " demands hash $fi->{Hash} ".
2541             "(got wrong file from archive!)";
2542
2543     return 1;
2544 }
2545
2546 sub ensure_we_have_orig () {
2547     my @dfi = dsc_files_info();
2548     foreach my $fi (@dfi) {
2549         my $f = $fi->{Filename};
2550         next unless is_orig_file_in_dsc($f, \@dfi);
2551         complete_file_from_dsc($buildproductsdir, $fi)
2552             or next;
2553     }
2554 }
2555
2556 #---------- git fetch ----------
2557
2558 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2559 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2560
2561 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2562 # locally fetched refs because they have unhelpful names and clutter
2563 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2564 # whether we have made another local ref which refers to this object).
2565 #
2566 # (If we deleted them unconditionally, then we might end up
2567 # re-fetching the same git objects each time dgit fetch was run.)
2568 #
2569 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2570 # in git_fetch_us to fetch the refs in question, and possibly a call
2571 # to lrfetchref_used.
2572
2573 our (%lrfetchrefs_f, %lrfetchrefs_d);
2574 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2575
2576 sub lrfetchref_used ($) {
2577     my ($fullrefname) = @_;
2578     my $objid = $lrfetchrefs_f{$fullrefname};
2579     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2580 }
2581
2582 sub git_lrfetch_sane {
2583     my ($url, $supplementary, @specs) = @_;
2584     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2585     # at least as regards @specs.  Also leave the results in
2586     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2587     # able to clean these up.
2588     #
2589     # With $supplementary==1, @specs must not contain wildcards
2590     # and we add to our previous fetches (non-atomically).
2591
2592     # This is rather miserable:
2593     # When git fetch --prune is passed a fetchspec ending with a *,
2594     # it does a plausible thing.  If there is no * then:
2595     # - it matches subpaths too, even if the supplied refspec
2596     #   starts refs, and behaves completely madly if the source
2597     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2598     # - if there is no matching remote ref, it bombs out the whole
2599     #   fetch.
2600     # We want to fetch a fixed ref, and we don't know in advance
2601     # if it exists, so this is not suitable.
2602     #
2603     # Our workaround is to use git ls-remote.  git ls-remote has its
2604     # own qairks.  Notably, it has the absurd multi-tail-matching
2605     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2606     # refs/refs/foo etc.
2607     #
2608     # Also, we want an idempotent snapshot, but we have to make two
2609     # calls to the remote: one to git ls-remote and to git fetch.  The
2610     # solution is use git ls-remote to obtain a target state, and
2611     # git fetch to try to generate it.  If we don't manage to generate
2612     # the target state, we try again.
2613
2614     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2615
2616     my $specre = join '|', map {
2617         my $x = $_;
2618         $x =~ s/\W/\\$&/g;
2619         my $wildcard = $x =~ s/\\\*$/.*/;
2620         die if $wildcard && $supplementary;
2621         "(?:refs/$x)";
2622     } @specs;
2623     printdebug "git_lrfetch_sane specre=$specre\n";
2624     my $wanted_rref = sub {
2625         local ($_) = @_;
2626         return m/^(?:$specre)$/;
2627     };
2628
2629     my $fetch_iteration = 0;
2630     FETCH_ITERATION:
2631     for (;;) {
2632         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2633         if (++$fetch_iteration > 10) {
2634             fail "too many iterations trying to get sane fetch!";
2635         }
2636
2637         my @look = map { "refs/$_" } @specs;
2638         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2639         debugcmd "|",@lcmd;
2640
2641         my %wantr;
2642         open GITLS, "-|", @lcmd or die $!;
2643         while (<GITLS>) {
2644             printdebug "=> ", $_;
2645             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2646             my ($objid,$rrefname) = ($1,$2);
2647             if (!$wanted_rref->($rrefname)) {
2648                 print STDERR <<END;
2649 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2650 END
2651                 next;
2652             }
2653             $wantr{$rrefname} = $objid;
2654         }
2655         $!=0; $?=0;
2656         close GITLS or failedcmd @lcmd;
2657
2658         # OK, now %want is exactly what we want for refs in @specs
2659         my @fspecs = map {
2660             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2661             "+refs/$_:".lrfetchrefs."/$_";
2662         } @specs;
2663
2664         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2665
2666         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2667         runcmd_ordryrun_local @fcmd if @fspecs;
2668
2669         if (!$supplementary) {
2670             %lrfetchrefs_f = ();
2671         }
2672         my %objgot;
2673
2674         git_for_each_ref(lrfetchrefs, sub {
2675             my ($objid,$objtype,$lrefname,$reftail) = @_;
2676             $lrfetchrefs_f{$lrefname} = $objid;
2677             $objgot{$objid} = 1;
2678         });
2679
2680         if ($supplementary) {
2681             last;
2682         }
2683
2684         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2685             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2686             if (!exists $wantr{$rrefname}) {
2687                 if ($wanted_rref->($rrefname)) {
2688                     printdebug <<END;
2689 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2690 END
2691                 } else {
2692                     print STDERR <<END
2693 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2694 END
2695                 }
2696                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2697                 delete $lrfetchrefs_f{$lrefname};
2698                 next;
2699             }
2700         }
2701         foreach my $rrefname (sort keys %wantr) {
2702             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2703             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2704             my $want = $wantr{$rrefname};
2705             next if $got eq $want;
2706             if (!defined $objgot{$want}) {
2707                 fail <<END unless act_local();
2708 --dry-run specified but we actually wanted the results of git fetch,
2709 so this is not going to work.  Try running dgit fetch first,
2710 or using --damp-run instead of --dry-run.
2711 END
2712                 print STDERR <<END;
2713 warning: git ls-remote suggests we want $lrefname
2714 warning:  and it should refer to $want
2715 warning:  but git fetch didn't fetch that object to any relevant ref.
2716 warning:  This may be due to a race with someone updating the server.
2717 warning:  Will try again...
2718 END
2719                 next FETCH_ITERATION;
2720             }
2721             printdebug <<END;
2722 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2723 END
2724             runcmd_ordryrun_local @git, qw(update-ref -m),
2725                 "dgit fetch git fetch fixup", $lrefname, $want;
2726             $lrfetchrefs_f{$lrefname} = $want;
2727         }
2728         last;
2729     }
2730
2731     if (defined $csuite) {
2732         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2733         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2734             my ($objid,$objtype,$lrefname,$reftail) = @_;
2735             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2736             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2737         });
2738     }
2739
2740     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2741         Dumper(\%lrfetchrefs_f);
2742 }
2743
2744 sub git_fetch_us () {
2745     # Want to fetch only what we are going to use, unless
2746     # deliberately-not-ff, in which case we must fetch everything.
2747
2748     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2749         map { "tags/$_" }
2750         (quiltmode_splitbrain
2751          ? (map { $_->('*',access_nomdistro) }
2752             \&debiantag_new, \&debiantag_maintview)
2753          : debiantags('*',access_nomdistro));
2754     push @specs, server_branch($csuite);
2755     push @specs, $rewritemap;
2756     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2757
2758     my $url = access_giturl();
2759     git_lrfetch_sane $url, 0, @specs;
2760
2761     my %here;
2762     my @tagpats = debiantags('*',access_nomdistro);
2763
2764     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2765         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2766         printdebug "currently $fullrefname=$objid\n";
2767         $here{$fullrefname} = $objid;
2768     });
2769     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2770         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2771         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2772         printdebug "offered $lref=$objid\n";
2773         if (!defined $here{$lref}) {
2774             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2775             runcmd_ordryrun_local @upd;
2776             lrfetchref_used $fullrefname;
2777         } elsif ($here{$lref} eq $objid) {
2778             lrfetchref_used $fullrefname;
2779         } else {
2780             print STDERR
2781                 "Not updating $lref from $here{$lref} to $objid.\n";
2782         }
2783     });
2784 }
2785
2786 #---------- dsc and archive handling ----------
2787
2788 sub mergeinfo_getclogp ($) {
2789     # Ensures thit $mi->{Clogp} exists and returns it
2790     my ($mi) = @_;
2791     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2792 }
2793
2794 sub mergeinfo_version ($) {
2795     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2796 }
2797
2798 sub fetch_from_archive_record_1 ($) {
2799     my ($hash) = @_;
2800     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
2801     cmdoutput @git, qw(log -n2), $hash;
2802     # ... gives git a chance to complain if our commit is malformed
2803 }
2804
2805 sub fetch_from_archive_record_2 ($) {
2806     my ($hash) = @_;
2807     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
2808     if (act_local()) {
2809         cmdoutput @upd_cmd;
2810     } else {
2811         dryrun_report @upd_cmd;
2812     }
2813 }
2814
2815 sub parse_dsc_field_def_dsc_distro () {
2816     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2817                            dgit.default.distro);
2818 }
2819
2820 sub parse_dsc_field ($$) {
2821     my ($dsc, $what) = @_;
2822     my $f;
2823     foreach my $field (@ourdscfield) {
2824         $f = $dsc->{$field};
2825         last if defined $f;
2826     }
2827
2828     if (!defined $f) {
2829         progress "$what: NO git hash";
2830         parse_dsc_field_def_dsc_distro();
2831     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2832              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2833         progress "$what: specified git info ($dsc_distro)";
2834         $dsc_hint_tag = [ $dsc_hint_tag ];
2835     } elsif ($f =~ m/^\w+\s*$/) {
2836         $dsc_hash = $&;
2837         parse_dsc_field_def_dsc_distro();
2838         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2839                           $dsc_distro ];
2840         progress "$what: specified git hash";
2841     } else {
2842         fail "$what: invalid Dgit info";
2843     }
2844 }
2845
2846 sub resolve_dsc_field_commit ($$) {
2847     my ($already_distro, $already_mapref) = @_;
2848
2849     return unless defined $dsc_hash;
2850
2851     my $mapref =
2852         defined $already_mapref &&
2853         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2854         ? $already_mapref : undef;
2855
2856     my $do_fetch;
2857     $do_fetch = sub {
2858         my ($what, @fetch) = @_;
2859
2860         local $idistro = $dsc_distro;
2861         my $lrf = lrfetchrefs;
2862
2863         if (!$chase_dsc_distro) {
2864             progress
2865                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2866             return 0;
2867         }
2868
2869         progress
2870             ".dsc names distro $dsc_distro: fetching $what";
2871
2872         my $url = access_giturl();
2873         if (!defined $url) {
2874             defined $dsc_hint_url or fail <<END;
2875 .dsc Dgit metadata is in context of distro $dsc_distro
2876 for which we have no configured url and .dsc provides no hint
2877 END
2878             my $proto =
2879                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2880                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2881             parse_cfg_bool "dsc-url-proto-ok", 'false',
2882                 cfg("dgit.dsc-url-proto-ok.$proto",
2883                     "dgit.default.dsc-url-proto-ok")
2884                 or fail <<END;
2885 .dsc Dgit metadata is in context of distro $dsc_distro
2886 for which we have no configured url;
2887 .dsc provides hinted url with protocol $proto which is unsafe.
2888 (can be overridden by config - consult documentation)
2889 END
2890             $url = $dsc_hint_url;
2891         }
2892
2893         git_lrfetch_sane $url, 1, @fetch;
2894
2895         return $lrf;
2896     };
2897
2898     my $rewrite_enable = do {
2899         local $idistro = $dsc_distro;
2900         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2901     };
2902
2903     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2904         if (!defined $mapref) {
2905             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2906             $mapref = $lrf.'/'.$rewritemap;
2907         }
2908         my $rewritemapdata = git_cat_file $mapref.':map';
2909         if (defined $rewritemapdata
2910             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2911             progress
2912                 "server's git history rewrite map contains a relevant entry!";
2913
2914             $dsc_hash = $1;
2915             if (defined $dsc_hash) {
2916                 progress "using rewritten git hash in place of .dsc value";
2917             } else {
2918                 progress "server data says .dsc hash is to be disregarded";
2919             }
2920         }
2921     }
2922
2923     if (!defined git_cat_file $dsc_hash) {
2924         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2925         my $lrf = $do_fetch->("additional commits", @tags) &&
2926             defined git_cat_file $dsc_hash
2927             or fail <<END;
2928 .dsc Dgit metadata requires commit $dsc_hash
2929 but we could not obtain that object anywhere.
2930 END
2931         foreach my $t (@tags) {
2932             my $fullrefname = $lrf.'/'.$t;
2933 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2934             next unless $lrfetchrefs_f{$fullrefname};
2935             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2936             lrfetchref_used $fullrefname;
2937         }
2938     }
2939 }
2940
2941 sub fetch_from_archive () {
2942     ensure_setup_existing_tree();
2943
2944     # Ensures that lrref() is what is actually in the archive, one way
2945     # or another, according to us - ie this client's
2946     # appropritaely-updated archive view.  Also returns the commit id.
2947     # If there is nothing in the archive, leaves lrref alone and
2948     # returns undef.  git_fetch_us must have already been called.
2949     get_archive_dsc();
2950
2951     if ($dsc) {
2952         parse_dsc_field($dsc, 'last upload to archive');
2953         resolve_dsc_field_commit access_basedistro,
2954             lrfetchrefs."/".$rewritemap
2955     } else {
2956         progress "no version available from the archive";
2957     }
2958
2959     # If the archive's .dsc has a Dgit field, there are three
2960     # relevant git commitids we need to choose between and/or merge
2961     # together:
2962     #   1. $dsc_hash: the Dgit field from the archive
2963     #   2. $lastpush_hash: the suite branch on the dgit git server
2964     #   3. $lastfetch_hash: our local tracking brach for the suite
2965     #
2966     # These may all be distinct and need not be in any fast forward
2967     # relationship:
2968     #
2969     # If the dsc was pushed to this suite, then the server suite
2970     # branch will have been updated; but it might have been pushed to
2971     # a different suite and copied by the archive.  Conversely a more
2972     # recent version may have been pushed with dgit but not appeared
2973     # in the archive (yet).
2974     #
2975     # $lastfetch_hash may be awkward because archive imports
2976     # (particularly, imports of Dgit-less .dscs) are performed only as
2977     # needed on individual clients, so different clients may perform a
2978     # different subset of them - and these imports are only made
2979     # public during push.  So $lastfetch_hash may represent a set of
2980     # imports different to a subsequent upload by a different dgit
2981     # client.
2982     #
2983     # Our approach is as follows:
2984     #
2985     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2986     # descendant of $dsc_hash, then it was pushed by a dgit user who
2987     # had based their work on $dsc_hash, so we should prefer it.
2988     # Otherwise, $dsc_hash was installed into this suite in the
2989     # archive other than by a dgit push, and (necessarily) after the
2990     # last dgit push into that suite (since a dgit push would have
2991     # been descended from the dgit server git branch); thus, in that
2992     # case, we prefer the archive's version (and produce a
2993     # pseudo-merge to overwrite the dgit server git branch).
2994     #
2995     # (If there is no Dgit field in the archive's .dsc then
2996     # generate_commit_from_dsc uses the version numbers to decide
2997     # whether the suite branch or the archive is newer.  If the suite
2998     # branch is newer it ignores the archive's .dsc; otherwise it
2999     # generates an import of the .dsc, and produces a pseudo-merge to
3000     # overwrite the suite branch with the archive contents.)
3001     #
3002     # The outcome of that part of the algorithm is the `public view',
3003     # and is same for all dgit clients: it does not depend on any
3004     # unpublished history in the local tracking branch.
3005     #
3006     # As between the public view and the local tracking branch: The
3007     # local tracking branch is only updated by dgit fetch, and
3008     # whenever dgit fetch runs it includes the public view in the
3009     # local tracking branch.  Therefore if the public view is not
3010     # descended from the local tracking branch, the local tracking
3011     # branch must contain history which was imported from the archive
3012     # but never pushed; and, its tip is now out of date.  So, we make
3013     # a pseudo-merge to overwrite the old imports and stitch the old
3014     # history in.
3015     #
3016     # Finally: we do not necessarily reify the public view (as
3017     # described above).  This is so that we do not end up stacking two
3018     # pseudo-merges.  So what we actually do is figure out the inputs
3019     # to any public view pseudo-merge and put them in @mergeinputs.
3020
3021     my @mergeinputs;
3022     # $mergeinputs[]{Commit}
3023     # $mergeinputs[]{Info}
3024     # $mergeinputs[0] is the one whose tree we use
3025     # @mergeinputs is in the order we use in the actual commit)
3026     #
3027     # Also:
3028     # $mergeinputs[]{Message} is a commit message to use
3029     # $mergeinputs[]{ReverseParents} if def specifies that parent
3030     #                                list should be in opposite order
3031     # Such an entry has no Commit or Info.  It applies only when found
3032     # in the last entry.  (This ugliness is to support making
3033     # identical imports to previous dgit versions.)
3034
3035     my $lastpush_hash = git_get_ref(lrfetchref());
3036     printdebug "previous reference hash=$lastpush_hash\n";
3037     $lastpush_mergeinput = $lastpush_hash && {
3038         Commit => $lastpush_hash,
3039         Info => "dgit suite branch on dgit git server",
3040     };
3041
3042     my $lastfetch_hash = git_get_ref(lrref());
3043     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3044     my $lastfetch_mergeinput = $lastfetch_hash && {
3045         Commit => $lastfetch_hash,
3046         Info => "dgit client's archive history view",
3047     };
3048
3049     my $dsc_mergeinput = $dsc_hash && {
3050         Commit => $dsc_hash,
3051         Info => "Dgit field in .dsc from archive",
3052     };
3053
3054     my $cwd = getcwd();
3055     my $del_lrfetchrefs = sub {
3056         changedir $cwd;
3057         my $gur;
3058         printdebug "del_lrfetchrefs...\n";
3059         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3060             my $objid = $lrfetchrefs_d{$fullrefname};
3061             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3062             if (!$gur) {
3063                 $gur ||= new IO::Handle;
3064                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3065             }
3066             printf $gur "delete %s %s\n", $fullrefname, $objid;
3067         }
3068         if ($gur) {
3069             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3070         }
3071     };
3072
3073     if (defined $dsc_hash) {
3074         ensure_we_have_orig();
3075         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3076             @mergeinputs = $dsc_mergeinput
3077         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3078             print STDERR <<END or die $!;
3079
3080 Git commit in archive is behind the last version allegedly pushed/uploaded.
3081 Commit referred to by archive: $dsc_hash
3082 Last version pushed with dgit: $lastpush_hash
3083 $later_warning_msg
3084 END
3085             @mergeinputs = ($lastpush_mergeinput);
3086         } else {
3087             # Archive has .dsc which is not a descendant of the last dgit
3088             # push.  This can happen if the archive moves .dscs about.
3089             # Just follow its lead.
3090             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3091                 progress "archive .dsc names newer git commit";
3092                 @mergeinputs = ($dsc_mergeinput);
3093             } else {
3094                 progress "archive .dsc names other git commit, fixing up";
3095                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3096             }
3097         }
3098     } elsif ($dsc) {
3099         @mergeinputs = generate_commits_from_dsc();
3100         # We have just done an import.  Now, our import algorithm might
3101         # have been improved.  But even so we do not want to generate
3102         # a new different import of the same package.  So if the
3103         # version numbers are the same, just use our existing version.
3104         # If the version numbers are different, the archive has changed
3105         # (perhaps, rewound).
3106         if ($lastfetch_mergeinput &&
3107             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3108                               (mergeinfo_version $mergeinputs[0]) )) {
3109             @mergeinputs = ($lastfetch_mergeinput);
3110         }
3111     } elsif ($lastpush_hash) {
3112         # only in git, not in the archive yet
3113         @mergeinputs = ($lastpush_mergeinput);
3114         print STDERR <<END or die $!;
3115
3116 Package not found in the archive, but has allegedly been pushed using dgit.
3117 $later_warning_msg
3118 END
3119     } else {
3120         printdebug "nothing found!\n";
3121         if (defined $skew_warning_vsn) {
3122             print STDERR <<END or die $!;
3123
3124 Warning: relevant archive skew detected.
3125 Archive allegedly contains $skew_warning_vsn
3126 But we were not able to obtain any version from the archive or git.
3127
3128 END
3129         }
3130         unshift @end, $del_lrfetchrefs;
3131         return undef;
3132     }
3133
3134     if ($lastfetch_hash &&
3135         !grep {
3136             my $h = $_->{Commit};
3137             $h and is_fast_fwd($lastfetch_hash, $h);
3138             # If true, one of the existing parents of this commit
3139             # is a descendant of the $lastfetch_hash, so we'll
3140             # be ff from that automatically.
3141         } @mergeinputs
3142         ) {
3143         # Otherwise:
3144         push @mergeinputs, $lastfetch_mergeinput;
3145     }
3146
3147     printdebug "fetch mergeinfos:\n";
3148     foreach my $mi (@mergeinputs) {
3149         if ($mi->{Info}) {
3150             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3151         } else {
3152             printdebug sprintf " ReverseParents=%d Message=%s",
3153                 $mi->{ReverseParents}, $mi->{Message};
3154         }
3155     }
3156
3157     my $compat_info= pop @mergeinputs
3158         if $mergeinputs[$#mergeinputs]{Message};
3159
3160     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3161
3162     my $hash;
3163     if (@mergeinputs > 1) {
3164         # here we go, then:
3165         my $tree_commit = $mergeinputs[0]{Commit};
3166
3167         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3168         $tree =~ m/\n\n/;  $tree = $`;
3169         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3170         $tree = $1;
3171
3172         # We use the changelog author of the package in question the
3173         # author of this pseudo-merge.  This is (roughly) correct if
3174         # this commit is simply representing aa non-dgit upload.
3175         # (Roughly because it does not record sponsorship - but we
3176         # don't have sponsorship info because that's in the .changes,
3177         # which isn't in the archivw.)
3178         #
3179         # But, it might be that we are representing archive history
3180         # updates (including in-archive copies).  These are not really
3181         # the responsibility of the person who created the .dsc, but
3182         # there is no-one whose name we should better use.  (The
3183         # author of the .dsc-named commit is clearly worse.)
3184
3185         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3186         my $author = clogp_authline $useclogp;
3187         my $cversion = getfield $useclogp, 'Version';
3188
3189         my $mcf = dgit_privdir()."/mergecommit";
3190         open MC, ">", $mcf or die "$mcf $!";
3191         print MC <<END or die $!;
3192 tree $tree
3193 END
3194
3195         my @parents = grep { $_->{Commit} } @mergeinputs;
3196         @parents = reverse @parents if $compat_info->{ReverseParents};
3197         print MC <<END or die $! foreach @parents;
3198 parent $_->{Commit}
3199 END
3200
3201         print MC <<END or die $!;
3202 author $author
3203 committer $author
3204
3205 END
3206
3207         if (defined $compat_info->{Message}) {
3208             print MC $compat_info->{Message} or die $!;
3209         } else {
3210             print MC <<END or die $!;
3211 Record $package ($cversion) in archive suite $csuite
3212
3213 Record that
3214 END
3215             my $message_add_info = sub {
3216                 my ($mi) = (@_);
3217                 my $mversion = mergeinfo_version $mi;
3218                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3219                     or die $!;
3220             };
3221
3222             $message_add_info->($mergeinputs[0]);
3223             print MC <<END or die $!;
3224 should be treated as descended from
3225 END
3226             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3227         }
3228
3229         close MC or die $!;
3230         $hash = make_commit $mcf;
3231     } else {
3232         $hash = $mergeinputs[0]{Commit};
3233     }
3234     printdebug "fetch hash=$hash\n";
3235
3236     my $chkff = sub {
3237         my ($lasth, $what) = @_;
3238         return unless $lasth;
3239         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3240     };
3241
3242     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3243         if $lastpush_hash;
3244     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3245
3246     fetch_from_archive_record_1($hash);
3247
3248     if (defined $skew_warning_vsn) {
3249         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3250         my $gotclogp = commit_getclogp($hash);
3251         my $got_vsn = getfield $gotclogp, 'Version';
3252         printdebug "SKEW CHECK GOT $got_vsn\n";
3253         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3254             print STDERR <<END or die $!;
3255
3256 Warning: archive skew detected.  Using the available version:
3257 Archive allegedly contains    $skew_warning_vsn
3258 We were able to obtain only   $got_vsn
3259
3260 END
3261         }
3262     }
3263
3264     if ($lastfetch_hash ne $hash) {
3265         fetch_from_archive_record_2($hash);
3266     }
3267
3268     lrfetchref_used lrfetchref();
3269
3270     check_gitattrs($hash, "fetched source tree");
3271
3272     unshift @end, $del_lrfetchrefs;
3273     return $hash;
3274 }
3275
3276 sub set_local_git_config ($$) {
3277     my ($k, $v) = @_;
3278     runcmd @git, qw(config), $k, $v;
3279 }
3280
3281 sub setup_mergechangelogs (;$) {
3282     my ($always) = @_;
3283     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3284
3285     my $driver = 'dpkg-mergechangelogs';
3286     my $cb = "merge.$driver";
3287     confess unless defined $maindir;
3288     my $attrs = "$maindir_gitcommon/info/attributes";
3289     ensuredir "$maindir_gitcommon/info";
3290
3291     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3292     if (!open ATTRS, "<", $attrs) {
3293         $!==ENOENT or die "$attrs: $!";
3294     } else {
3295         while (<ATTRS>) {
3296             chomp;
3297             next if m{^debian/changelog\s};
3298             print NATTRS $_, "\n" or die $!;
3299         }
3300         ATTRS->error and die $!;
3301         close ATTRS;
3302     }
3303     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3304     close NATTRS;
3305
3306     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3307     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3308
3309     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3310 }
3311
3312 sub setup_useremail (;$) {
3313     my ($always) = @_;
3314     return unless $always || access_cfg_bool(1, 'setup-useremail');
3315
3316     my $setup = sub {
3317         my ($k, $envvar) = @_;
3318         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3319         return unless defined $v;
3320         set_local_git_config "user.$k", $v;
3321     };
3322
3323     $setup->('email', 'DEBEMAIL');
3324     $setup->('name', 'DEBFULLNAME');
3325 }
3326
3327 sub ensure_setup_existing_tree () {
3328     my $k = "remote.$remotename.skipdefaultupdate";
3329     my $c = git_get_config $k;
3330     return if defined $c;
3331     set_local_git_config $k, 'true';
3332 }
3333
3334 sub open_main_gitattrs () {
3335     confess 'internal error no maindir' unless defined $maindir;
3336     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3337         or $!==ENOENT
3338         or die "open $maindir_gitcommon/info/attributes: $!";
3339     return $gai;
3340 }
3341
3342 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3343
3344 sub is_gitattrs_setup () {
3345     # return values:
3346     #  trueish
3347     #     1: gitattributes set up and should be left alone
3348     #  falseish
3349     #     0: there is a dgit-defuse-attrs but it needs fixing
3350     #     undef: there is none
3351     my $gai = open_main_gitattrs();
3352     return 0 unless $gai;
3353     while (<$gai>) {
3354         next unless m{$gitattrs_ourmacro_re};
3355         return 1 if m{\s-working-tree-encoding\s};
3356         printdebug "is_gitattrs_setup: found old macro\n";
3357         return 0;
3358     }
3359     $gai->error and die $!;
3360     printdebug "is_gitattrs_setup: found nothing\n";
3361     return undef;
3362 }
3363
3364 sub setup_gitattrs (;$) {
3365     my ($always) = @_;
3366     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3367
3368     my $already = is_gitattrs_setup();
3369     if ($already) {
3370         progress <<END;
3371 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3372  not doing further gitattributes setup
3373 END
3374         return;
3375     }
3376     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3377     my $af = "$maindir_gitcommon/info/attributes";
3378     ensuredir "$maindir_gitcommon/info";
3379
3380     open GAO, "> $af.new" or die $!;
3381     print GAO <<END or die $! unless defined $already;
3382 *       dgit-defuse-attrs
3383 $new
3384 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3385 END
3386     my $gai = open_main_gitattrs();
3387     if ($gai) {
3388         while (<$gai>) {
3389             if (m{$gitattrs_ourmacro_re}) {
3390                 die unless defined $already;
3391                 $_ = $new;
3392             }
3393             chomp;
3394             print GAO $_, "\n" or die $!;
3395         }
3396         $gai->error and die $!;
3397     }
3398     close GAO or die $!;
3399     rename "$af.new", "$af" or die "install $af: $!";
3400 }
3401
3402 sub setup_new_tree () {
3403     setup_mergechangelogs();
3404     setup_useremail();
3405     setup_gitattrs();
3406 }
3407
3408 sub check_gitattrs ($$) {
3409     my ($treeish, $what) = @_;
3410
3411     return if is_gitattrs_setup;
3412
3413     local $/="\0";
3414     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3415     debugcmd "|",@cmd;
3416     my $gafl = new IO::File;
3417     open $gafl, "-|", @cmd or die $!;
3418     while (<$gafl>) {
3419         chomp or die;
3420         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3421         next if $1 == 0;
3422         next unless m{(?:^|/)\.gitattributes$};
3423
3424         # oh dear, found one
3425         print STDERR <<END;
3426 dgit: warning: $what contains .gitattributes
3427 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3428 END
3429         close $gafl;
3430         return;
3431     }
3432     # tree contains no .gitattributes files
3433     $?=0; $!=0; close $gafl or failedcmd @cmd;
3434 }
3435
3436
3437 sub multisuite_suite_child ($$$) {
3438     my ($tsuite, $mergeinputs, $fn) = @_;
3439     # in child, sets things up, calls $fn->(), and returns undef
3440     # in parent, returns canonical suite name for $tsuite
3441     my $canonsuitefh = IO::File::new_tmpfile;
3442     my $pid = fork // die $!;
3443     if (!$pid) {
3444         forkcheck_setup();
3445         $isuite = $tsuite;
3446         $us .= " [$isuite]";
3447         $debugprefix .= " ";
3448         progress "fetching $tsuite...";
3449         canonicalise_suite();
3450         print $canonsuitefh $csuite, "\n" or die $!;
3451         close $canonsuitefh or die $!;
3452         $fn->();
3453         return undef;
3454     }
3455     waitpid $pid,0 == $pid or die $!;
3456     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3457     seek $canonsuitefh,0,0 or die $!;
3458     local $csuite = <$canonsuitefh>;
3459     die $! unless defined $csuite && chomp $csuite;
3460     if ($? == 256*4) {
3461         printdebug "multisuite $tsuite missing\n";
3462         return $csuite;
3463     }
3464     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3465     push @$mergeinputs, {
3466         Ref => lrref,
3467         Info => $csuite,
3468     };
3469     return $csuite;
3470 }
3471
3472 sub fork_for_multisuite ($) {
3473     my ($before_fetch_merge) = @_;
3474     # if nothing unusual, just returns ''
3475     #
3476     # if multisuite:
3477     # returns 0 to caller in child, to do first of the specified suites
3478     # in child, $csuite is not yet set
3479     #
3480     # returns 1 to caller in parent, to finish up anything needed after
3481     # in parent, $csuite is set to canonicalised portmanteau
3482
3483     my $org_isuite = $isuite;
3484     my @suites = split /\,/, $isuite;
3485     return '' unless @suites > 1;
3486     printdebug "fork_for_multisuite: @suites\n";
3487
3488     my @mergeinputs;
3489
3490     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3491                                             sub { });
3492     return 0 unless defined $cbasesuite;
3493
3494     fail "package $package missing in (base suite) $cbasesuite"
3495         unless @mergeinputs;
3496
3497     my @csuites = ($cbasesuite);
3498
3499     $before_fetch_merge->();
3500
3501     foreach my $tsuite (@suites[1..$#suites]) {
3502         $tsuite =~ s/^-/$cbasesuite-/;
3503         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3504                                                sub {
3505             @end = ();
3506             fetch_one();
3507             finish 0;
3508         });
3509
3510         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3511         push @csuites, $csubsuite;
3512     }
3513
3514     foreach my $mi (@mergeinputs) {
3515         my $ref = git_get_ref $mi->{Ref};
3516         die "$mi->{Ref} ?" unless length $ref;
3517         $mi->{Commit} = $ref;
3518     }
3519
3520     $csuite = join ",", @csuites;
3521
3522     my $previous = git_get_ref lrref;
3523     if ($previous) {
3524         unshift @mergeinputs, {
3525             Commit => $previous,
3526             Info => "local combined tracking branch",
3527             Warning =>
3528  "archive seems to have rewound: local tracking branch is ahead!",
3529         };
3530     }
3531
3532     foreach my $ix (0..$#mergeinputs) {
3533         $mergeinputs[$ix]{Index} = $ix;
3534     }
3535
3536     @mergeinputs = sort {
3537         -version_compare(mergeinfo_version $a,
3538                          mergeinfo_version $b) # highest version first
3539             or
3540         $a->{Index} <=> $b->{Index}; # earliest in spec first
3541     } @mergeinputs;
3542
3543     my @needed;
3544
3545   NEEDED:
3546     foreach my $mi (@mergeinputs) {
3547         printdebug "multisuite merge check $mi->{Info}\n";
3548         foreach my $previous (@needed) {
3549             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3550             printdebug "multisuite merge un-needed $previous->{Info}\n";
3551             next NEEDED;
3552         }
3553         push @needed, $mi;
3554         printdebug "multisuite merge this-needed\n";
3555         $mi->{Character} = '+';
3556     }
3557
3558     $needed[0]{Character} = '*';
3559
3560     my $output = $needed[0]{Commit};
3561
3562     if (@needed > 1) {
3563         printdebug "multisuite merge nontrivial\n";
3564         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3565
3566         my $commit = "tree $tree\n";
3567         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3568             "Input branches:\n";
3569
3570         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3571             printdebug "multisuite merge include $mi->{Info}\n";
3572             $mi->{Character} //= ' ';
3573             $commit .= "parent $mi->{Commit}\n";
3574             $msg .= sprintf " %s  %-25s %s\n",
3575                 $mi->{Character},
3576                 (mergeinfo_version $mi),
3577                 $mi->{Info};
3578         }
3579         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3580         $msg .= "\nKey\n".
3581             " * marks the highest version branch, which choose to use\n".
3582             " + marks each branch which was not already an ancestor\n\n".
3583             "[dgit multi-suite $csuite]\n";
3584         $commit .=
3585             "author $authline\n".
3586             "committer $authline\n\n";
3587         $output = make_commit_text $commit.$msg;
3588         printdebug "multisuite merge generated $output\n";
3589     }
3590
3591     fetch_from_archive_record_1($output);
3592     fetch_from_archive_record_2($output);
3593
3594     progress "calculated combined tracking suite $csuite";
3595
3596     return 1;
3597 }
3598
3599 sub clone_set_head () {
3600     open H, "> .git/HEAD" or die $!;
3601     print H "ref: ".lref()."\n" or die $!;
3602     close H or die $!;
3603 }
3604 sub clone_finish ($) {
3605     my ($dstdir) = @_;
3606     runcmd @git, qw(reset --hard), lrref();
3607     runcmd qw(bash -ec), <<'END';
3608         set -o pipefail
3609         git ls-tree -r --name-only -z HEAD | \
3610         xargs -0r touch -h -r . --
3611 END
3612     printdone "ready for work in $dstdir";
3613 }
3614
3615 sub clone ($) {
3616     # in multisuite, returns twice!
3617     # once in parent after first suite fetched,
3618     # and then again in child after everything is finished
3619     my ($dstdir) = @_;
3620     badusage "dry run makes no sense with clone" unless act_local();
3621
3622     my $multi_fetched = fork_for_multisuite(sub {
3623         printdebug "multi clone before fetch merge\n";
3624         changedir $dstdir;
3625         record_maindir();
3626     });
3627     if ($multi_fetched) {
3628         printdebug "multi clone after fetch merge\n";
3629         clone_set_head();
3630         clone_finish($dstdir);
3631         return;
3632     }
3633     printdebug "clone main body\n";
3634
3635     canonicalise_suite();
3636     my $hasgit = check_for_git();
3637     mkdir $dstdir or fail "create \`$dstdir': $!";
3638     changedir $dstdir;
3639     runcmd @git, qw(init -q);
3640     record_maindir();
3641     setup_new_tree();
3642     clone_set_head();
3643     my $giturl = access_giturl(1);
3644     if (defined $giturl) {
3645         runcmd @git, qw(remote add), 'origin', $giturl;
3646     }
3647     if ($hasgit) {
3648         progress "fetching existing git history";
3649         git_fetch_us();
3650         runcmd_ordryrun_local @git, qw(fetch origin);
3651     } else {
3652         progress "starting new git history";
3653     }
3654     fetch_from_archive() or no_such_package;
3655     my $vcsgiturl = $dsc->{'Vcs-Git'};
3656     if (length $vcsgiturl) {
3657         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3658         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3659     }
3660     clone_finish($dstdir);
3661 }
3662
3663 sub fetch_one () {
3664     canonicalise_suite();
3665     if (check_for_git()) {
3666         git_fetch_us();
3667     }
3668     fetch_from_archive() or no_such_package();
3669
3670     my $vcsgiturl = $dsc && $dsc->{'Vcs-Git'};
3671     if (length $vcsgiturl and
3672         (grep { $csuite eq $_ }
3673          split /\;/,
3674          cfg 'dgit.vcs-git.suites')) {
3675         my $current = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
3676         if (defined $current && $current ne $vcsgiturl) {
3677             print STDERR <<END;
3678 FYI: Vcs-Git in $csuite has different url to your vcs-git remote.
3679  Your vcs-git remote url may be out of date.  Use dgit update-vcs-git ?
3680 END
3681         }
3682     }
3683     printdone "fetched into ".lrref();
3684 }
3685
3686 sub dofetch () {
3687     my $multi_fetched = fork_for_multisuite(sub { });
3688     fetch_one() unless $multi_fetched; # parent
3689     finish 0 if $multi_fetched eq '0'; # child
3690 }
3691
3692 sub pull () {
3693     dofetch();
3694     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3695         lrref();
3696     printdone "fetched to ".lrref()." and merged into HEAD";
3697 }
3698
3699 sub check_not_dirty () {
3700     foreach my $f (qw(local-options local-patch-header)) {
3701         if (stat_exists "debian/source/$f") {
3702             fail "git tree contains debian/source/$f";
3703         }
3704     }
3705
3706     return if $includedirty;
3707
3708     git_check_unmodified();
3709 }
3710
3711 sub commit_admin ($) {
3712     my ($m) = @_;
3713     progress "$m";
3714     runcmd_ordryrun_local @git, qw(commit -m), $m;
3715 }
3716
3717 sub quiltify_nofix_bail ($$) {
3718     my ($headinfo, $xinfo) = @_;
3719     if ($quilt_mode eq 'nofix') {
3720         fail "quilt fixup required but quilt mode is \`nofix'\n".
3721             "HEAD commit".$headinfo." differs from tree implied by ".
3722             " debian/patches".$xinfo;
3723     }
3724 }
3725
3726 sub commit_quilty_patch () {
3727     my $output = cmdoutput @git, qw(status --ignored --porcelain);
3728     my %adds;
3729     foreach my $l (split /\n/, $output) {
3730         next unless $l =~ m/\S/;
3731         if ($l =~ m{^(?:[?!][?!]| [MADRC]) (.pc|debian/patches)}) {
3732             $adds{$1}++;
3733         }
3734     }
3735     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3736     if (!%adds) {
3737         progress "nothing quilty to commit, ok.";
3738         return;
3739     }
3740     quiltify_nofix_bail "", " (wanted to commit patch update)";
3741     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3742     runcmd_ordryrun_local @git, qw(add -f), @adds;
3743     commit_admin <<END
3744 Commit Debian 3.0 (quilt) metadata
3745
3746 [dgit ($our_version) quilt-fixup]
3747 END
3748 }
3749
3750 sub get_source_format () {
3751     my %options;
3752     if (open F, "debian/source/options") {
3753         while (<F>) {
3754             next if m/^\s*\#/;
3755             next unless m/\S/;
3756             s/\s+$//; # ignore missing final newline
3757             if (m/\s*\#\s*/) {
3758                 my ($k, $v) = ($`, $'); #');
3759                 $v =~ s/^"(.*)"$/$1/;
3760                 $options{$k} = $v;
3761             } else {
3762                 $options{$_} = 1;
3763             }
3764         }
3765         F->error and die $!;
3766         close F;
3767     } else {
3768         die $! unless $!==&ENOENT;
3769     }
3770
3771     if (!open F, "debian/source/format") {
3772         die $! unless $!==&ENOENT;
3773         return '';
3774     }
3775     $_ = <F>;
3776     F->error and die $!;
3777     chomp;
3778     return ($_, \%options);
3779 }
3780
3781 sub madformat_wantfixup ($) {
3782     my ($format) = @_;
3783     return 0 unless $format eq '3.0 (quilt)';
3784     our $quilt_mode_warned;
3785     if ($quilt_mode eq 'nocheck') {
3786         progress "Not doing any fixup of \`$format' due to".
3787             " ----no-quilt-fixup or --quilt=nocheck"
3788             unless $quilt_mode_warned++;
3789         return 0;
3790     }
3791     progress "Format \`$format', need to check/update patch stack"
3792         unless $quilt_mode_warned++;
3793     return 1;
3794 }
3795
3796 sub maybe_split_brain_save ($$$) {
3797     my ($headref, $dgitview, $msg) = @_;
3798     # => message fragment "$saved" describing disposition of $dgitview
3799     my $save = $internal_object_save{'dgit-view'};
3800     return "commit id $dgitview" unless defined $save;
3801     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
3802                git_update_ref_cmd
3803                "dgit --dgit-view-save $msg HEAD=$headref",
3804                $save, $dgitview);
3805     runcmd @cmd;
3806     return "and left in $save";
3807 }
3808
3809 # An "infopair" is a tuple [ $thing, $what ]
3810 # (often $thing is a commit hash; $what is a description)
3811
3812 sub infopair_cond_equal ($$) {
3813     my ($x,$y) = @_;
3814     $x->[0] eq $y->[0] or fail <<END;
3815 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3816 END
3817 };
3818
3819 sub infopair_lrf_tag_lookup ($$) {
3820     my ($tagnames, $what) = @_;
3821     # $tagname may be an array ref
3822     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3823     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3824     foreach my $tagname (@tagnames) {
3825         my $lrefname = lrfetchrefs."/tags/$tagname";
3826         my $tagobj = $lrfetchrefs_f{$lrefname};
3827         next unless defined $tagobj;
3828         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3829         return [ git_rev_parse($tagobj), $what ];
3830     }
3831     fail @tagnames==1 ? <<END : <<END;
3832 Wanted tag $what (@tagnames) on dgit server, but not found
3833 END
3834 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3835 END
3836 }
3837
3838 sub infopair_cond_ff ($$) {
3839     my ($anc,$desc) = @_;
3840     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3841 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3842 END
3843 };
3844
3845 sub pseudomerge_version_check ($$) {
3846     my ($clogp, $archive_hash) = @_;
3847
3848     my $arch_clogp = commit_getclogp $archive_hash;
3849     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3850                      'version currently in archive' ];
3851     if (defined $overwrite_version) {
3852         if (length $overwrite_version) {
3853             infopair_cond_equal([ $overwrite_version,
3854                                   '--overwrite= version' ],
3855                                 $i_arch_v);
3856         } else {
3857             my $v = $i_arch_v->[0];
3858             progress "Checking package changelog for archive version $v ...";
3859             my $cd;
3860             eval {
3861                 my @xa = ("-f$v", "-t$v");
3862                 my $vclogp = parsechangelog @xa;
3863                 my $gf = sub {
3864                     my ($fn) = @_;
3865                     [ (getfield $vclogp, $fn),
3866                       "$fn field from dpkg-parsechangelog @xa" ];
3867                 };
3868                 my $cv = $gf->('Version');
3869                 infopair_cond_equal($i_arch_v, $cv);
3870                 $cd = $gf->('Distribution');
3871             };
3872             if ($@) {
3873                 $@ =~ s/^dgit: //gm;
3874                 fail "$@".
3875                     "Perhaps debian/changelog does not mention $v ?";
3876             }
3877             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3878 $cd->[1] is $cd->[0]
3879 Your tree seems to based on earlier (not uploaded) $v.
3880 END
3881         }
3882     }
3883
3884     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3885     return $i_arch_v;
3886 }
3887
3888 sub pseudomerge_make_commit ($$$$ $$) {
3889     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3890         $msg_cmd, $msg_msg) = @_;
3891     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3892
3893     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3894     my $authline = clogp_authline $clogp;
3895
3896     chomp $msg_msg;
3897     $msg_cmd .=
3898         !defined $overwrite_version ? ""
3899         : !length  $overwrite_version ? " --overwrite"
3900         : " --overwrite=".$overwrite_version;
3901
3902     # Contributing parent is the first parent - that makes
3903     # git rev-list --first-parent DTRT.
3904     my $pmf = dgit_privdir()."/pseudomerge";
3905     open MC, ">", $pmf or die "$pmf $!";
3906     print MC <<END or die $!;
3907 tree $tree
3908 parent $dgitview
3909 parent $archive_hash
3910 author $authline
3911 committer $authline
3912
3913 $msg_msg
3914
3915 [$msg_cmd]
3916 END
3917     close MC or die $!;
3918
3919     return make_commit($pmf);
3920 }
3921
3922 sub splitbrain_pseudomerge ($$$$) {
3923     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3924     # => $merged_dgitview
3925     printdebug "splitbrain_pseudomerge...\n";
3926     #
3927     #     We:      debian/PREVIOUS    HEAD($maintview)
3928     # expect:          o ----------------- o
3929     #                    \                   \
3930     #                     o                   o
3931     #                 a/d/PREVIOUS        $dgitview
3932     #                $archive_hash              \
3933     #  If so,                \                   \
3934     #  we do:                 `------------------ o
3935     #   this:                                   $dgitview'
3936     #
3937
3938     return $dgitview unless defined $archive_hash;
3939     return $dgitview if deliberately_not_fast_forward();
3940
3941     printdebug "splitbrain_pseudomerge...\n";
3942
3943     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3944
3945     if (!defined $overwrite_version) {
3946         progress "Checking that HEAD inciudes all changes in archive...";
3947     }
3948
3949     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3950
3951     if (defined $overwrite_version) {
3952     } elsif (!eval {
3953         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3954         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3955         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3956         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3957         my $i_archive = [ $archive_hash, "current archive contents" ];
3958
3959         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3960
3961         infopair_cond_equal($i_dgit, $i_archive);
3962         infopair_cond_ff($i_dep14, $i_dgit);
3963         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3964         1;
3965     }) {
3966         $@ =~ s/^\n//; chomp $@;
3967         print STDERR <<END;
3968 $@
3969 | Not fast forward; maybe --overwrite is needed ?  Please see dgit(1).
3970 END
3971         finish -1;
3972     }
3973
3974     my $r = pseudomerge_make_commit
3975         $clogp, $dgitview, $archive_hash, $i_arch_v,
3976         "dgit --quilt=$quilt_mode",
3977         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3978 Declare fast forward from $i_arch_v->[0]
3979 END_OVERWR
3980 Make fast forward from $i_arch_v->[0]
3981 END_MAKEFF
3982
3983     maybe_split_brain_save $maintview, $r, "pseudomerge";
3984
3985     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3986     return $r;
3987 }
3988
3989 sub plain_overwrite_pseudomerge ($$$) {
3990     my ($clogp, $head, $archive_hash) = @_;
3991
3992     printdebug "plain_overwrite_pseudomerge...";
3993
3994     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3995
3996     return $head if is_fast_fwd $archive_hash, $head;
3997
3998     my $m = "Declare fast forward from $i_arch_v->[0]";
3999
4000     my $r = pseudomerge_make_commit
4001         $clogp, $head, $archive_hash, $i_arch_v,
4002         "dgit", $m;
4003
4004     runcmd git_update_ref_cmd $m, 'HEAD', $r, $head;
4005
4006     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
4007     return $r;
4008 }
4009
4010 sub push_parse_changelog ($) {
4011     my ($clogpfn) = @_;
4012
4013     my $clogp = Dpkg::Control::Hash->new();
4014     $clogp->load($clogpfn) or die;
4015
4016     my $clogpackage = getfield $clogp, 'Source';
4017     $package //= $clogpackage;
4018     fail "-p specified $package but changelog specified $clogpackage"
4019         unless $package eq $clogpackage;
4020     my $cversion = getfield $clogp, 'Version';
4021
4022     if (!$we_are_initiator) {
4023         # rpush initiator can't do this because it doesn't have $isuite yet
4024         my $tag = debiantag($cversion, access_nomdistro);
4025         runcmd @git, qw(check-ref-format), $tag;
4026     }
4027
4028     my $dscfn = dscfn($cversion);
4029
4030     return ($clogp, $cversion, $dscfn);
4031 }
4032
4033 sub push_parse_dsc ($$$) {
4034     my ($dscfn,$dscfnwhat, $cversion) = @_;
4035     $dsc = parsecontrol($dscfn,$dscfnwhat);
4036     my $dversion = getfield $dsc, 'Version';
4037     my $dscpackage = getfield $dsc, 'Source';
4038     ($dscpackage eq $package && $dversion eq $cversion) or
4039         fail "$dscfn is for $dscpackage $dversion".
4040             " but debian/changelog is for $package $cversion";
4041 }
4042
4043 sub push_tagwants ($$$$) {
4044     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4045     my @tagwants;
4046     push @tagwants, {
4047         TagFn => \&debiantag,
4048         Objid => $dgithead,
4049         TfSuffix => '',
4050         View => 'dgit',
4051     };
4052     if (defined $maintviewhead) {
4053         push @tagwants, {
4054             TagFn => \&debiantag_maintview,
4055             Objid => $maintviewhead,
4056             TfSuffix => '-maintview',
4057             View => 'maint',
4058         };
4059     } elsif ($dodep14tag eq 'no' ? 0
4060              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
4061              : $dodep14tag eq 'always'
4062              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
4063 --dep14tag-always (or equivalent in config) means server must support
4064  both "new" and "maint" tag formats, but config says it doesn't.
4065 END
4066             : die "$dodep14tag ?") {
4067         push @tagwants, {
4068             TagFn => \&debiantag_maintview,
4069             Objid => $dgithead,
4070             TfSuffix => '-dgit',
4071             View => 'dgit',
4072         };
4073     };
4074     foreach my $tw (@tagwants) {
4075         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4076         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4077     }
4078     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4079     return @tagwants;
4080 }
4081
4082 sub push_mktags ($$ $$ $) {
4083     my ($clogp,$dscfn,
4084         $changesfile,$changesfilewhat,
4085         $tagwants) = @_;
4086
4087     die unless $tagwants->[0]{View} eq 'dgit';
4088
4089     my $declaredistro = access_nomdistro();
4090     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4091     $dsc->{$ourdscfield[0]} = join " ",
4092         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4093         $reader_giturl;
4094     $dsc->save("$dscfn.tmp") or die $!;
4095
4096     my $changes = parsecontrol($changesfile,$changesfilewhat);
4097     foreach my $field (qw(Source Distribution Version)) {
4098         $changes->{$field} eq $clogp->{$field} or
4099             fail "changes field $field \`$changes->{$field}'".
4100                 " does not match changelog \`$clogp->{$field}'";
4101     }
4102
4103     my $cversion = getfield $clogp, 'Version';
4104     my $clogsuite = getfield $clogp, 'Distribution';
4105
4106     # We make the git tag by hand because (a) that makes it easier
4107     # to control the "tagger" (b) we can do remote signing
4108     my $authline = clogp_authline $clogp;
4109     my $delibs = join(" ", "",@deliberatelies);
4110
4111     my $mktag = sub {
4112         my ($tw) = @_;
4113         my $tfn = $tw->{Tfn};
4114         my $head = $tw->{Objid};
4115         my $tag = $tw->{Tag};
4116
4117         open TO, '>', $tfn->('.tmp') or die $!;
4118         print TO <<END or die $!;
4119 object $head
4120 type commit
4121 tag $tag
4122 tagger $authline
4123
4124 END
4125         if ($tw->{View} eq 'dgit') {
4126             print TO <<END or die $!;
4127 $package release $cversion for $clogsuite ($csuite) [dgit]
4128 [dgit distro=$declaredistro$delibs]
4129 END
4130             foreach my $ref (sort keys %previously) {
4131                 print TO <<END or die $!;
4132 [dgit previously:$ref=$previously{$ref}]
4133 END
4134             }
4135         } elsif ($tw->{View} eq 'maint') {
4136             print TO <<END or die $!;
4137 $package release $cversion for $clogsuite ($csuite)
4138 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4139 END
4140         } else {
4141             die Dumper($tw)."?";
4142         }
4143
4144         close TO or die $!;
4145
4146         my $tagobjfn = $tfn->('.tmp');
4147         if ($sign) {
4148             if (!defined $keyid) {
4149                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4150             }
4151             if (!defined $keyid) {
4152                 $keyid = getfield $clogp, 'Maintainer';
4153             }
4154             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4155             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4156             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4157             push @sign_cmd, $tfn->('.tmp');
4158             runcmd_ordryrun @sign_cmd;
4159             if (act_scary()) {
4160                 $tagobjfn = $tfn->('.signed.tmp');
4161                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4162                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4163             }
4164         }
4165         return $tagobjfn;
4166     };
4167
4168     my @r = map { $mktag->($_); } @$tagwants;
4169     return @r;
4170 }
4171
4172 sub sign_changes ($) {
4173     my ($changesfile) = @_;
4174     if ($sign) {
4175         my @debsign_cmd = @debsign;
4176         push @debsign_cmd, "-k$keyid" if defined $keyid;
4177         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4178         push @debsign_cmd, $changesfile;
4179         runcmd_ordryrun @debsign_cmd;
4180     }
4181 }
4182
4183 sub dopush () {
4184     printdebug "actually entering push\n";
4185
4186     supplementary_message(<<'END');
4187 Push failed, while checking state of the archive.
4188 You can retry the push, after fixing the problem, if you like.
4189 END
4190     if (check_for_git()) {
4191         git_fetch_us();
4192     }
4193     my $archive_hash = fetch_from_archive();
4194     if (!$archive_hash) {
4195         $new_package or
4196             fail "package appears to be new in this suite;".
4197                 " if this is intentional, use --new";
4198     }
4199
4200     supplementary_message(<<'END');
4201 Push failed, while preparing your push.
4202 You can retry the push, after fixing the problem, if you like.
4203 END
4204
4205     need_tagformat 'new', "quilt mode $quilt_mode"
4206         if quiltmode_splitbrain;
4207
4208     prep_ud();
4209
4210     access_giturl(); # check that success is vaguely likely
4211     rpush_handle_protovsn_bothends() if $we_are_initiator;
4212     select_tagformat();
4213
4214     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4215     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4216
4217     responder_send_file('parsed-changelog', $clogpfn);
4218
4219     my ($clogp, $cversion, $dscfn) =
4220         push_parse_changelog("$clogpfn");
4221
4222     my $dscpath = "$buildproductsdir/$dscfn";
4223     stat_exists $dscpath or
4224         fail "looked for .dsc $dscpath, but $!;".
4225             " maybe you forgot to build";
4226
4227     responder_send_file('dsc', $dscpath);
4228
4229     push_parse_dsc($dscpath, $dscfn, $cversion);
4230
4231     my $format = getfield $dsc, 'Format';
4232     printdebug "format $format\n";
4233
4234     my $symref = git_get_symref();
4235     my $actualhead = git_rev_parse('HEAD');
4236
4237     if (branch_is_gdr_unstitched_ff($symref, $actualhead, $archive_hash)) {
4238         runcmd_ordryrun_local @git_debrebase, 'stitch';
4239         $actualhead = git_rev_parse('HEAD');
4240     }
4241
4242     my $dgithead = $actualhead;
4243     my $maintviewhead = undef;
4244
4245     my $upstreamversion = upstreamversion $clogp->{Version};
4246
4247     if (madformat_wantfixup($format)) {
4248         # user might have not used dgit build, so maybe do this now:
4249         if (quiltmode_splitbrain()) {
4250             changedir $playground;
4251             quilt_make_fake_dsc($upstreamversion);
4252             my $cachekey;
4253             ($dgithead, $cachekey) =
4254                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4255             $dgithead or fail
4256  "--quilt=$quilt_mode but no cached dgit view:
4257  perhaps HEAD changed since dgit build[-source] ?";
4258             $split_brain = 1;
4259             $dgithead = splitbrain_pseudomerge($clogp,
4260                                                $actualhead, $dgithead,
4261                                                $archive_hash);
4262             $maintviewhead = $actualhead;
4263             changedir $maindir;
4264             prep_ud(); # so _only_subdir() works, below
4265         } else {
4266             commit_quilty_patch();
4267         }
4268     }
4269
4270     if (defined $overwrite_version && !defined $maintviewhead
4271         && $archive_hash) {
4272         $dgithead = plain_overwrite_pseudomerge($clogp,
4273                                                 $dgithead,
4274                                                 $archive_hash);
4275     }
4276
4277     check_not_dirty();
4278
4279     my $forceflag = '';
4280     if ($archive_hash) {
4281         if (is_fast_fwd($archive_hash, $dgithead)) {
4282             # ok
4283         } elsif (deliberately_not_fast_forward) {
4284             $forceflag = '+';
4285         } else {
4286             fail "dgit push: HEAD is not a descendant".
4287                 " of the archive's version.\n".
4288                 "To overwrite the archive's contents,".
4289                 " pass --overwrite[=VERSION].\n".
4290                 "To rewind history, if permitted by the archive,".
4291                 " use --deliberately-not-fast-forward.";
4292         }
4293     }
4294
4295     changedir $playground;
4296     progress "checking that $dscfn corresponds to HEAD";
4297     runcmd qw(dpkg-source -x --),
4298         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4299     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4300     check_for_vendor_patches() if madformat($dsc->{format});
4301     changedir $maindir;
4302     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4303     debugcmd "+",@diffcmd;
4304     $!=0; $?=-1;
4305     my $r = system @diffcmd;
4306     if ($r) {
4307         if ($r==256) {
4308             my $referent = $split_brain ? $dgithead : 'HEAD';
4309             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4310
4311             my @mode_changes;
4312             my $raw = cmdoutput @git,
4313                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4314             my $changed;
4315             foreach (split /\0/, $raw) {
4316                 if (defined $changed) {
4317                     push @mode_changes, "$changed: $_\n" if $changed;
4318                     $changed = undef;
4319                     next;
4320                 } elsif (m/^:0+ 0+ /) {
4321                     $changed = '';
4322                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4323                     $changed = "Mode change from $1 to $2"
4324                 } else {
4325                     die "$_ ?";
4326                 }
4327             }
4328             if (@mode_changes) {
4329                 fail <<END.(join '', @mode_changes).<<END;
4330 HEAD specifies a different tree to $dscfn:
4331 $diffs
4332 END
4333 There is a problem with your source tree (see dgit(7) for some hints).
4334 To see a full diff, run git diff $tree $referent
4335 END
4336             }
4337
4338             fail <<END;
4339 HEAD specifies a different tree to $dscfn:
4340 $diffs
4341 Perhaps you forgot to build.  Or perhaps there is a problem with your
4342  source tree (see dgit(7) for some hints).  To see a full diff, run
4343    git diff $tree $referent
4344 END
4345         } else {
4346             failedcmd @diffcmd;
4347         }
4348     }
4349     if (!$changesfile) {
4350         my $pat = changespat $cversion;
4351         my @cs = glob "$buildproductsdir/$pat";
4352         fail "failed to find unique changes file".
4353             " (looked for $pat in $buildproductsdir);".
4354             " perhaps you need to use dgit -C"
4355             unless @cs==1;
4356         ($changesfile) = @cs;
4357     } else {
4358         $changesfile = "$buildproductsdir/$changesfile";
4359     }
4360
4361     # Check that changes and .dsc agree enough
4362     $changesfile =~ m{[^/]*$};
4363     my $changes = parsecontrol($changesfile,$&);
4364     files_compare_inputs($dsc, $changes)
4365         unless forceing [qw(dsc-changes-mismatch)];
4366
4367     # Check whether this is a source only upload
4368     my $hasdebs = $changes->{Files} =~ m{\.deb$}m;
4369     my $sourceonlypolicy = access_cfg 'source-only-uploads';
4370     if ($sourceonlypolicy eq 'ok') {
4371     } elsif ($sourceonlypolicy eq 'always') {
4372         forceable_fail [qw(uploading-binaries)],
4373             "uploading binaries, although distroy policy is source only"
4374             if $hasdebs;
4375     } elsif ($sourceonlypolicy eq 'never') {
4376         forceable_fail [qw(uploading-source-only)],
4377             "source-only upload, although distroy policy requires .debs"
4378             if !$hasdebs;
4379     } elsif ($sourceonlypolicy eq 'not-wholly-new') {
4380         forceable_fail [qw(uploading-source-only)],
4381             "source-only upload, even though package is entirely NEW\n".
4382             "(this is contrary to policy in ".(access_nomdistro()).")"
4383             if !$hasdebs
4384             && $new_package
4385             && !(archive_query('package_not_wholly_new', $package) // 1);
4386     } else {
4387         badcfg "unknown source-only-uploads policy \`$sourceonlypolicy'";
4388     }
4389
4390     # Perhaps adjust .dsc to contain right set of origs
4391     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4392                                   $changesfile)
4393         unless forceing [qw(changes-origs-exactly)];
4394
4395     # Checks complete, we're going to try and go ahead:
4396
4397     responder_send_file('changes',$changesfile);
4398     responder_send_command("param head $dgithead");
4399     responder_send_command("param csuite $csuite");
4400     responder_send_command("param isuite $isuite");
4401     responder_send_command("param tagformat $tagformat");
4402     if (defined $maintviewhead) {
4403         confess "internal error (protovsn=$protovsn)"
4404             if defined $protovsn and $protovsn < 4;
4405         responder_send_command("param maint-view $maintviewhead");
4406     }
4407
4408     # Perhaps send buildinfo(s) for signing
4409     my $changes_files = getfield $changes, 'Files';
4410     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4411     foreach my $bi (@buildinfos) {
4412         responder_send_command("param buildinfo-filename $bi");
4413         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4414     }
4415
4416     if (deliberately_not_fast_forward) {
4417         git_for_each_ref(lrfetchrefs, sub {
4418             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4419             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4420             responder_send_command("previously $rrefname=$objid");
4421             $previously{$rrefname} = $objid;
4422         });
4423     }
4424
4425     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4426                                  dgit_privdir()."/tag");
4427     my @tagobjfns;
4428
4429     supplementary_message(<<'END');
4430 Push failed, while signing the tag.
4431 You can retry the push, after fixing the problem, if you like.
4432 END
4433     # If we manage to sign but fail to record it anywhere, it's fine.
4434     if ($we_are_responder) {
4435         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4436         responder_receive_files('signed-tag', @tagobjfns);
4437     } else {
4438         @tagobjfns = push_mktags($clogp,$dscpath,
4439                               $changesfile,$changesfile,
4440                               \@tagwants);
4441     }
4442     supplementary_message(<<'END');
4443 Push failed, *after* signing the tag.
4444 If you want to try again, you should use a new version number.
4445 END
4446
4447     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4448
4449     foreach my $tw (@tagwants) {
4450         my $tag = $tw->{Tag};
4451         my $tagobjfn = $tw->{TagObjFn};
4452         my $tag_obj_hash =
4453             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4454         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4455         runcmd_ordryrun_local
4456             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4457     }
4458
4459     supplementary_message(<<'END');
4460 Push failed, while updating the remote git repository - see messages above.
4461 If you want to try again, you should use a new version number.
4462 END
4463     if (!check_for_git()) {
4464         create_remote_git_repo();
4465     }
4466
4467     my @pushrefs = $forceflag.$dgithead.":".rrref();
4468     foreach my $tw (@tagwants) {
4469         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4470     }
4471
4472     runcmd_ordryrun @git,
4473         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4474     runcmd_ordryrun git_update_ref_cmd 'dgit push', lrref(), $dgithead;
4475
4476     supplementary_message(<<'END');
4477 Push failed, while obtaining signatures on the .changes and .dsc.
4478 If it was just that the signature failed, you may try again by using
4479 debsign by hand to sign the changes file (see the command dgit tried,
4480 above), and then dput that changes file to complete the upload.
4481 If you need to change the package, you must use a new version number.
4482 END
4483     if ($we_are_responder) {
4484         my $dryrunsuffix = act_local() ? "" : ".tmp";
4485         my @rfiles = ($dscpath, $changesfile);
4486         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4487         responder_receive_files('signed-dsc-changes',
4488                                 map { "$_$dryrunsuffix" } @rfiles);
4489     } else {
4490         if (act_local()) {
4491             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4492         } else {
4493             progress "[new .dsc left in $dscpath.tmp]";
4494         }
4495         sign_changes $changesfile;
4496     }
4497
4498     supplementary_message(<<END);
4499 Push failed, while uploading package(s) to the archive server.
4500 You can retry the upload of exactly these same files with dput of:
4501   $changesfile
4502 If that .changes file is broken, you will need to use a new version
4503 number for your next attempt at the upload.
4504 END
4505     my $host = access_cfg('upload-host','RETURN-UNDEF');
4506     my @hostarg = defined($host) ? ($host,) : ();
4507     runcmd_ordryrun @dput, @hostarg, $changesfile;
4508     printdone "pushed and uploaded $cversion";
4509
4510     supplementary_message('');
4511     responder_send_command("complete");
4512 }
4513
4514 sub pre_clone () {
4515     not_necessarily_a_tree();
4516 }
4517 sub cmd_clone {
4518     parseopts();
4519     my $dstdir;
4520     badusage "-p is not allowed with clone; specify as argument instead"
4521         if defined $package;
4522     if (@ARGV==1) {
4523         ($package) = @ARGV;
4524     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4525         ($package,$isuite) = @ARGV;
4526     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4527         ($package,$dstdir) = @ARGV;
4528     } elsif (@ARGV==3) {
4529         ($package,$isuite,$dstdir) = @ARGV;
4530     } else {
4531         badusage "incorrect arguments to dgit clone";
4532     }
4533     notpushing();
4534
4535     $dstdir ||= "$package";
4536     if (stat_exists $dstdir) {
4537         fail "$dstdir already exists";
4538     }
4539
4540     my $cwd_remove;
4541     if ($rmonerror && !$dryrun_level) {
4542         $cwd_remove= getcwd();
4543         unshift @end, sub {
4544             return unless defined $cwd_remove;
4545             if (!chdir "$cwd_remove") {
4546                 return if $!==&ENOENT;
4547                 die "chdir $cwd_remove: $!";
4548             }
4549             printdebug "clone rmonerror removing $dstdir\n";
4550             if (stat $dstdir) {
4551                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4552             } elsif (grep { $! == $_ }
4553                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4554             } else {
4555                 print STDERR "check whether to remove $dstdir: $!\n";
4556             }
4557         };
4558     }
4559
4560     clone($dstdir);
4561     $cwd_remove = undef;
4562 }
4563
4564 sub branchsuite () {
4565     my $branch = git_get_symref();
4566     if (defined $branch && $branch =~ m#$lbranch_re#o) {
4567         return $1;
4568     } else {
4569         return undef;
4570     }
4571 }
4572
4573 sub package_from_d_control () {
4574     if (!defined $package) {
4575         my $sourcep = parsecontrol('debian/control','debian/control');
4576         $package = getfield $sourcep, 'Source';
4577     }
4578 }
4579
4580 sub fetchpullargs () {
4581     package_from_d_control();
4582     if (@ARGV==0) {
4583         $isuite = branchsuite();
4584         if (!$isuite) {
4585             my $clogp = parsechangelog();
4586             my $clogsuite = getfield $clogp, 'Distribution';
4587             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4588         }
4589     } elsif (@ARGV==1) {
4590         ($isuite) = @ARGV;
4591     } else {
4592         badusage "incorrect arguments to dgit fetch or dgit pull";
4593     }
4594     notpushing();
4595 }
4596
4597 sub cmd_fetch {
4598     parseopts();
4599     fetchpullargs();
4600     dofetch();
4601 }
4602
4603 sub cmd_pull {
4604     parseopts();
4605     fetchpullargs();
4606     if (quiltmode_splitbrain()) {
4607         my ($format, $fopts) = get_source_format();
4608         madformat($format) and fail <<END
4609 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4610 END
4611     }
4612     pull();
4613 }
4614
4615 sub cmd_checkout {
4616     parseopts();
4617     package_from_d_control();
4618     @ARGV==1 or badusage "dgit checkout needs a suite argument";
4619     ($isuite) = @ARGV;
4620     notpushing();
4621
4622     foreach my $canon (qw(0 1)) {
4623         if (!$canon) {
4624             $csuite= $isuite;
4625         } else {
4626             undef $csuite;
4627             canonicalise_suite();
4628         }
4629         if (length git_get_ref lref()) {
4630             # local branch already exists, yay
4631             last;
4632         }
4633         if (!length git_get_ref lrref()) {
4634             if (!$canon) {
4635                 # nope
4636                 next;
4637             }
4638             dofetch();
4639         }
4640         # now lrref exists
4641         runcmd (@git, qw(update-ref), lref(), lrref(), '');
4642         last;
4643     }
4644     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
4645         "dgit checkout $isuite";
4646     runcmd (@git, qw(checkout), lbranch());
4647 }
4648
4649 sub cmd_update_vcs_git () {
4650     my $specsuite;
4651     if (@ARGV==0 || $ARGV[0] =~ m/^-/) {
4652         ($specsuite,) = split /\;/, cfg 'dgit.vcs-git.suites';
4653     } else {
4654         ($specsuite) = (@ARGV);
4655         shift @ARGV;
4656     }
4657     my $dofetch=1;
4658     if (@ARGV) {
4659         if ($ARGV[0] eq '-') {
4660             $dofetch = 0;
4661         } elsif ($ARGV[0] eq '-') {
4662             shift;
4663         }
4664     }
4665
4666     package_from_d_control();
4667     my $ctrl;
4668     if ($specsuite eq '.') {
4669         $ctrl = parsecontrol 'debian/control', 'debian/control';
4670     } else {
4671         $isuite = $specsuite;
4672         get_archive_dsc();
4673         $ctrl = $dsc;
4674     }
4675     my $url = getfield $ctrl, 'Vcs-Git';
4676
4677     my @cmd;
4678     my $orgurl = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
4679     if (!defined $orgurl) {
4680         print STDERR "setting up vcs-git: $url\n";
4681         @cmd = (@git, qw(remote add vcs-git), $url);
4682     } elsif ($orgurl eq $url) {
4683         print STDERR "vcs git already configured: $url\n";
4684     } else {
4685         print STDERR "changing vcs-git url to: $url\n";
4686         @cmd = (@git, qw(remote set-url vcs-git), $url);
4687     }
4688     runcmd_ordryrun_local @cmd;
4689     if ($dofetch) {
4690         print "fetching (@ARGV)\n";
4691         runcmd_ordryrun_local @git, qw(fetch vcs-git), @ARGV;
4692     }
4693 }
4694
4695 sub prep_push () {
4696     parseopts();
4697     build_or_push_prep_early();
4698     pushing();
4699     check_not_dirty();
4700     my $specsuite;
4701     if (@ARGV==0) {
4702     } elsif (@ARGV==1) {
4703         ($specsuite) = (@ARGV);
4704     } else {
4705         badusage "incorrect arguments to dgit $subcommand";
4706     }
4707     if ($new_package) {
4708         local ($package) = $existing_package; # this is a hack
4709         canonicalise_suite();
4710     } else {
4711         canonicalise_suite();
4712     }
4713     if (defined $specsuite &&
4714         $specsuite ne $isuite &&
4715         $specsuite ne $csuite) {
4716             fail "dgit $subcommand: changelog specifies $isuite ($csuite)".
4717                 " but command line specifies $specsuite";
4718     }
4719 }
4720
4721 sub cmd_push {
4722     prep_push();
4723     dopush();
4724 }
4725
4726 #---------- remote commands' implementation ----------
4727
4728 sub pre_remote_push_build_host {
4729     my ($nrargs) = shift @ARGV;
4730     my (@rargs) = @ARGV[0..$nrargs-1];
4731     @ARGV = @ARGV[$nrargs..$#ARGV];
4732     die unless @rargs;
4733     my ($dir,$vsnwant) = @rargs;
4734     # vsnwant is a comma-separated list; we report which we have
4735     # chosen in our ready response (so other end can tell if they
4736     # offered several)
4737     $debugprefix = ' ';
4738     $we_are_responder = 1;
4739     $us .= " (build host)";
4740
4741     open PI, "<&STDIN" or die $!;
4742     open STDIN, "/dev/null" or die $!;
4743     open PO, ">&STDOUT" or die $!;
4744     autoflush PO 1;
4745     open STDOUT, ">&STDERR" or die $!;
4746     autoflush STDOUT 1;
4747
4748     $vsnwant //= 1;
4749     ($protovsn) = grep {
4750         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4751     } @rpushprotovsn_support;
4752
4753     fail "build host has dgit rpush protocol versions ".
4754         (join ",", @rpushprotovsn_support).
4755         " but invocation host has $vsnwant"
4756         unless defined $protovsn;
4757
4758     changedir $dir;
4759 }
4760 sub cmd_remote_push_build_host {
4761     responder_send_command("dgit-remote-push-ready $protovsn");
4762     &cmd_push;
4763 }
4764
4765 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4766 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4767 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4768 #     a good error message)
4769
4770 sub rpush_handle_protovsn_bothends () {
4771     if ($protovsn < 4) {
4772         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4773     }
4774     select_tagformat();
4775 }
4776
4777 our $i_tmp;
4778
4779 sub i_cleanup {
4780     local ($@, $?);
4781     my $report = i_child_report();
4782     if (defined $report) {
4783         printdebug "($report)\n";
4784     } elsif ($i_child_pid) {
4785         printdebug "(killing build host child $i_child_pid)\n";
4786         kill 15, $i_child_pid;
4787     }
4788     if (defined $i_tmp && !defined $initiator_tempdir) {
4789         changedir "/";
4790         eval { rmtree $i_tmp; };
4791     }
4792 }
4793
4794 END {
4795     return unless forkcheck_mainprocess();
4796     i_cleanup();
4797 }
4798
4799 sub i_method {
4800     my ($base,$selector,@args) = @_;
4801     $selector =~ s/\-/_/g;
4802     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4803 }
4804
4805 sub pre_rpush () {
4806     not_necessarily_a_tree();
4807 }
4808 sub cmd_rpush {
4809     my $host = nextarg;
4810     my $dir;
4811     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4812         $host = $1;
4813         $dir = $'; #';
4814     } else {
4815         $dir = nextarg;
4816     }
4817     $dir =~ s{^-}{./-};
4818     my @rargs = ($dir);
4819     push @rargs, join ",", @rpushprotovsn_support;
4820     my @rdgit;
4821     push @rdgit, @dgit;
4822     push @rdgit, @ropts;
4823     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4824     push @rdgit, @ARGV;
4825     my @cmd = (@ssh, $host, shellquote @rdgit);
4826     debugcmd "+",@cmd;
4827
4828     $we_are_initiator=1;
4829
4830     if (defined $initiator_tempdir) {
4831         rmtree $initiator_tempdir;
4832         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4833         $i_tmp = $initiator_tempdir;
4834     } else {
4835         $i_tmp = tempdir();
4836     }
4837     $i_child_pid = open2(\*RO, \*RI, @cmd);
4838     changedir $i_tmp;
4839     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4840     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4841     $supplementary_message = '' unless $protovsn >= 3;
4842
4843     for (;;) {
4844         my ($icmd,$iargs) = initiator_expect {
4845             m/^(\S+)(?: (.*))?$/;
4846             ($1,$2);
4847         };
4848         i_method "i_resp", $icmd, $iargs;
4849     }
4850 }
4851
4852 sub i_resp_progress ($) {
4853     my ($rhs) = @_;
4854     my $msg = protocol_read_bytes \*RO, $rhs;
4855     progress $msg;
4856 }
4857
4858 sub i_resp_supplementary_message ($) {
4859     my ($rhs) = @_;
4860     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4861 }
4862
4863 sub i_resp_complete {
4864     my $pid = $i_child_pid;
4865     $i_child_pid = undef; # prevents killing some other process with same pid
4866     printdebug "waiting for build host child $pid...\n";
4867     my $got = waitpid $pid, 0;
4868     die $! unless $got == $pid;
4869     die "build host child failed $?" if $?;
4870
4871     i_cleanup();
4872     printdebug "all done\n";
4873     finish 0;
4874 }
4875
4876 sub i_resp_file ($) {
4877     my ($keyword) = @_;
4878     my $localname = i_method "i_localname", $keyword;
4879     my $localpath = "$i_tmp/$localname";
4880     stat_exists $localpath and
4881         badproto \*RO, "file $keyword ($localpath) twice";
4882     protocol_receive_file \*RO, $localpath;
4883     i_method "i_file", $keyword;
4884 }
4885
4886 our %i_param;
4887
4888 sub i_resp_param ($) {
4889     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4890     $i_param{$1} = $2;
4891 }
4892
4893 sub i_resp_previously ($) {
4894     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4895         or badproto \*RO, "bad previously spec";
4896     my $r = system qw(git check-ref-format), $1;
4897     die "bad previously ref spec ($r)" if $r;
4898     $previously{$1} = $2;
4899 }
4900
4901 our %i_wanted;
4902
4903 sub i_resp_want ($) {
4904     my ($keyword) = @_;
4905     die "$keyword ?" if $i_wanted{$keyword}++;
4906
4907     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4908     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4909     die unless $isuite =~ m/^$suite_re$/;
4910
4911     pushing();
4912     rpush_handle_protovsn_bothends();
4913
4914     fail "rpush negotiated protocol version $protovsn".
4915         " which does not support quilt mode $quilt_mode"
4916         if quiltmode_splitbrain;
4917
4918     my @localpaths = i_method "i_want", $keyword;
4919     printdebug "[[  $keyword @localpaths\n";
4920     foreach my $localpath (@localpaths) {
4921         protocol_send_file \*RI, $localpath;
4922     }
4923     print RI "files-end\n" or die $!;
4924 }
4925
4926 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4927
4928 sub i_localname_parsed_changelog {
4929     return "remote-changelog.822";
4930 }
4931 sub i_file_parsed_changelog {
4932     ($i_clogp, $i_version, $i_dscfn) =
4933         push_parse_changelog "$i_tmp/remote-changelog.822";
4934     die if $i_dscfn =~ m#/|^\W#;
4935 }
4936
4937 sub i_localname_dsc {
4938     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4939     return $i_dscfn;
4940 }
4941 sub i_file_dsc { }
4942
4943 sub i_localname_buildinfo ($) {
4944     my $bi = $i_param{'buildinfo-filename'};
4945     defined $bi or badproto \*RO, "buildinfo before filename";
4946     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4947     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4948         or badproto \*RO, "improper buildinfo filename";
4949     return $&;
4950 }
4951 sub i_file_buildinfo {
4952     my $bi = $i_param{'buildinfo-filename'};
4953     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4954     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4955     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4956         files_compare_inputs($bd, $ch);
4957         (getfield $bd, $_) eq (getfield $ch, $_) or
4958             fail "buildinfo mismatch $_"
4959             foreach qw(Source Version);
4960         !defined $bd->{$_} or
4961             fail "buildinfo contains $_"
4962             foreach qw(Changes Changed-by Distribution);
4963     }
4964     push @i_buildinfos, $bi;
4965     delete $i_param{'buildinfo-filename'};
4966 }
4967
4968 sub i_localname_changes {
4969     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4970     $i_changesfn = $i_dscfn;
4971     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4972     return $i_changesfn;
4973 }
4974 sub i_file_changes { }
4975
4976 sub i_want_signed_tag {
4977     printdebug Dumper(\%i_param, $i_dscfn);
4978     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4979         && defined $i_param{'csuite'}
4980         or badproto \*RO, "premature desire for signed-tag";
4981     my $head = $i_param{'head'};
4982     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4983
4984     my $maintview = $i_param{'maint-view'};
4985     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4986
4987     select_tagformat();
4988     if ($protovsn >= 4) {
4989         my $p = $i_param{'tagformat'} // '<undef>';
4990         $p eq $tagformat
4991             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4992     }
4993
4994     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4995     $csuite = $&;
4996     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4997
4998     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4999
5000     return
5001         push_mktags $i_clogp, $i_dscfn,
5002             $i_changesfn, 'remote changes',
5003             \@tagwants;
5004 }
5005
5006 sub i_want_signed_dsc_changes {
5007     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
5008     sign_changes $i_changesfn;
5009     return ($i_dscfn, $i_changesfn, @i_buildinfos);
5010 }
5011
5012 #---------- building etc. ----------
5013
5014 our $version;
5015 our $sourcechanges;
5016 our $dscfn;
5017
5018 #----- `3.0 (quilt)' handling -----
5019
5020 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
5021
5022 sub quiltify_dpkg_commit ($$$;$) {
5023     my ($patchname,$author,$msg, $xinfo) = @_;
5024     $xinfo //= '';
5025
5026     mkpath '.git/dgit'; # we are in playtree
5027     my $descfn = ".git/dgit/quilt-description.tmp";
5028     open O, '>', $descfn or die "$descfn: $!";
5029     $msg =~ s/\n+/\n\n/;
5030     print O <<END or die $!;
5031 From: $author
5032 ${xinfo}Subject: $msg
5033 ---
5034
5035 END
5036     close O or die $!;
5037
5038     {
5039         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
5040         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
5041         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
5042         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
5043     }
5044 }
5045
5046 sub quiltify_trees_differ ($$;$$$) {
5047     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
5048     # returns true iff the two tree objects differ other than in debian/
5049     # with $finegrained,
5050     # returns bitmask 01 - differ in upstream files except .gitignore
5051     #                 02 - differ in .gitignore
5052     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
5053     #  is set for each modified .gitignore filename $fn
5054     # if $unrepres is defined, array ref to which is appeneded
5055     #  a list of unrepresentable changes (removals of upstream files
5056     #  (as messages)
5057     local $/=undef;
5058     my @cmd = (@git, qw(diff-tree -z --no-renames));
5059     push @cmd, qw(--name-only) unless $unrepres;
5060     push @cmd, qw(-r) if $finegrained || $unrepres;
5061     push @cmd, $x, $y;
5062     my $diffs= cmdoutput @cmd;
5063     my $r = 0;
5064     my @lmodes;
5065     foreach my $f (split /\0/, $diffs) {
5066         if ($unrepres && !@lmodes) {
5067             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
5068             next;
5069         }
5070         my ($oldmode,$newmode) = @lmodes;
5071         @lmodes = ();
5072
5073         next if $f =~ m#^debian(?:/.*)?$#s;
5074
5075         if ($unrepres) {
5076             eval {
5077                 die "not a plain file or symlink\n"
5078                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
5079                            $oldmode =~ m/^(?:10|12)\d{4}$/;
5080                 if ($oldmode =~ m/[^0]/ &&
5081                     $newmode =~ m/[^0]/) {
5082                     # both old and new files exist
5083                     die "mode or type changed\n" if $oldmode ne $newmode;
5084                     die "modified symlink\n" unless $newmode =~ m/^10/;
5085                 } elsif ($oldmode =~ m/[^0]/) {
5086                     # deletion
5087                     die "deletion of symlink\n"
5088                         unless $oldmode =~ m/^10/;
5089                 } else {
5090                     # creation
5091                     die "creation with non-default mode\n"
5092                         unless $newmode =~ m/^100644$/ or
5093                                $newmode =~ m/^120000$/;
5094                 }
5095             };
5096             if ($@) {
5097                 local $/="\n"; chomp $@;
5098                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
5099             }
5100         }
5101
5102         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
5103         $r |= $isignore ? 02 : 01;
5104         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
5105     }
5106     printdebug "quiltify_trees_differ $x $y => $r\n";
5107     return $r;
5108 }
5109
5110 sub quiltify_tree_sentinelfiles ($) {
5111     # lists the `sentinel' files present in the tree
5112     my ($x) = @_;
5113     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
5114         qw(-- debian/rules debian/control);
5115     $r =~ s/\n/,/g;
5116     return $r;
5117 }
5118
5119 sub quiltify_splitbrain_needed () {
5120     if (!$split_brain) {
5121         progress "dgit view: changes are required...";
5122         runcmd @git, qw(checkout -q -b dgit-view);
5123         $split_brain = 1;
5124     }
5125 }
5126
5127 sub quiltify_splitbrain ($$$$$$$) {
5128     my ($clogp, $unapplied, $headref, $oldtiptree, $diffbits,
5129         $editedignores, $cachekey) = @_;
5130     my $gitignore_special = 1;
5131     if ($quilt_mode !~ m/gbp|dpm/) {
5132         # treat .gitignore just like any other upstream file
5133         $diffbits = { %$diffbits };
5134         $_ = !!$_ foreach values %$diffbits;
5135         $gitignore_special = 0;
5136     }
5137     # We would like any commits we generate to be reproducible
5138     my @authline = clogp_authline($clogp);
5139     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
5140     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
5141     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
5142     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
5143     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
5144     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
5145
5146     my $fulldiffhint = sub {
5147         my ($x,$y) = @_;
5148         my $cmd = "git diff $x $y -- :/ ':!debian'";
5149         $cmd .= " ':!/.gitignore' ':!*/.gitignore'" if $gitignore_special;
5150         return "\nFor full diff showing the problem(s), type:\n $cmd\n";
5151     };
5152
5153     if ($quilt_mode =~ m/gbp|unapplied/ &&
5154         ($diffbits->{O2H} & 01)) {
5155         my $msg =
5156  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
5157  " but git tree differs from orig in upstream files.";
5158         $msg .= $fulldiffhint->($unapplied, 'HEAD');
5159         if (!stat_exists "debian/patches") {
5160             $msg .=
5161  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
5162         }
5163         fail $msg;
5164     }
5165     if ($quilt_mode =~ m/dpm/ &&
5166         ($diffbits->{H2A} & 01)) {
5167         fail <<END. $fulldiffhint->($oldtiptree,'HEAD');
5168 --quilt=$quilt_mode specified, implying patches-applied git tree
5169  but git tree differs from result of applying debian/patches to upstream
5170 END
5171     }
5172     if ($quilt_mode =~ m/gbp|unapplied/ &&
5173         ($diffbits->{O2A} & 01)) { # some patches
5174         quiltify_splitbrain_needed();
5175         progress "dgit view: creating patches-applied version using gbp pq";
5176         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
5177         # gbp pq import creates a fresh branch; push back to dgit-view
5178         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
5179         runcmd @git, qw(checkout -q dgit-view);
5180     }
5181     if ($quilt_mode =~ m/gbp|dpm/ &&
5182         ($diffbits->{O2A} & 02)) {
5183         fail <<END;
5184 --quilt=$quilt_mode specified, implying that HEAD is for use with a
5185  tool which does not create patches for changes to upstream
5186  .gitignores: but, such patches exist in debian/patches.
5187 END
5188     }
5189     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5190         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5191         quiltify_splitbrain_needed();
5192         progress "dgit view: creating patch to represent .gitignore changes";
5193         ensuredir "debian/patches";
5194         my $gipatch = "debian/patches/auto-gitignore";
5195         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
5196         stat GIPATCH or die "$gipatch: $!";
5197         fail "$gipatch already exists; but want to create it".
5198             " to record .gitignore changes" if (stat _)[7];
5199         print GIPATCH <<END or die "$gipatch: $!";
5200 Subject: Update .gitignore from Debian packaging branch
5201
5202 The Debian packaging git branch contains these updates to the upstream
5203 .gitignore file(s).  This patch is autogenerated, to provide these
5204 updates to users of the official Debian archive view of the package.
5205
5206 [dgit ($our_version) update-gitignore]
5207 ---
5208 END
5209         close GIPATCH or die "$gipatch: $!";
5210         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5211             $unapplied, $headref, "--", sort keys %$editedignores;
5212         open SERIES, "+>>", "debian/patches/series" or die $!;
5213         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
5214         my $newline;
5215         defined read SERIES, $newline, 1 or die $!;
5216         print SERIES "\n" or die $! unless $newline eq "\n";
5217         print SERIES "auto-gitignore\n" or die $!;
5218         close SERIES or die  $!;
5219         runcmd @git, qw(add -f -- debian/patches/series), $gipatch;
5220         commit_admin <<END
5221 Commit patch to update .gitignore
5222
5223 [dgit ($our_version) update-gitignore-quilt-fixup]
5224 END
5225     }
5226
5227     my $dgitview = git_rev_parse 'HEAD';
5228
5229     changedir $maindir;
5230     reflog_cache_insert "refs/$splitbraincache", $cachekey, $dgitview;
5231
5232     changedir "$playground/work";
5233
5234     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5235     progress "dgit view: created ($saved)";
5236 }
5237
5238 sub quiltify ($$$$) {
5239     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5240
5241     # Quilt patchification algorithm
5242     #
5243     # We search backwards through the history of the main tree's HEAD
5244     # (T) looking for a start commit S whose tree object is identical
5245     # to to the patch tip tree (ie the tree corresponding to the
5246     # current dpkg-committed patch series).  For these purposes
5247     # `identical' disregards anything in debian/ - this wrinkle is
5248     # necessary because dpkg-source treates debian/ specially.
5249     #
5250     # We can only traverse edges where at most one of the ancestors'
5251     # trees differs (in changes outside in debian/).  And we cannot
5252     # handle edges which change .pc/ or debian/patches.  To avoid
5253     # going down a rathole we avoid traversing edges which introduce
5254     # debian/rules or debian/control.  And we set a limit on the
5255     # number of edges we are willing to look at.
5256     #
5257     # If we succeed, we walk forwards again.  For each traversed edge
5258     # PC (with P parent, C child) (starting with P=S and ending with
5259     # C=T) to we do this:
5260     #  - git checkout C
5261     #  - dpkg-source --commit with a patch name and message derived from C
5262     # After traversing PT, we git commit the changes which
5263     # should be contained within debian/patches.
5264
5265     # The search for the path S..T is breadth-first.  We maintain a
5266     # todo list containing search nodes.  A search node identifies a
5267     # commit, and looks something like this:
5268     #  $p = {
5269     #      Commit => $git_commit_id,
5270     #      Child => $c,                          # or undef if P=T
5271     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5272     #      Nontrivial => true iff $p..$c has relevant changes
5273     #  };
5274
5275     my @todo;
5276     my @nots;
5277     my $sref_S;
5278     my $max_work=100;
5279     my %considered; # saves being exponential on some weird graphs
5280
5281     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5282
5283     my $not = sub {
5284         my ($search,$whynot) = @_;
5285         printdebug " search NOT $search->{Commit} $whynot\n";
5286         $search->{Whynot} = $whynot;
5287         push @nots, $search;
5288         no warnings qw(exiting);
5289         next;
5290     };
5291
5292     push @todo, {
5293         Commit => $target,
5294     };
5295
5296     while (@todo) {
5297         my $c = shift @todo;
5298         next if $considered{$c->{Commit}}++;
5299
5300         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5301
5302         printdebug "quiltify investigate $c->{Commit}\n";
5303
5304         # are we done?
5305         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5306             printdebug " search finished hooray!\n";
5307             $sref_S = $c;
5308             last;
5309         }
5310
5311         quiltify_nofix_bail " $c->{Commit}", " (tree object $oldtiptree)";
5312         if ($quilt_mode eq 'smash') {
5313             printdebug " search quitting smash\n";
5314             last;
5315         }
5316
5317         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5318         $not->($c, "has $c_sentinels not $t_sentinels")
5319             if $c_sentinels ne $t_sentinels;
5320
5321         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5322         $commitdata =~ m/\n\n/;
5323         $commitdata =~ $`;
5324         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5325         @parents = map { { Commit => $_, Child => $c } } @parents;
5326
5327         $not->($c, "root commit") if !@parents;
5328
5329         foreach my $p (@parents) {
5330             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5331         }
5332         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5333         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5334
5335         foreach my $p (@parents) {
5336             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5337
5338             my @cmd= (@git, qw(diff-tree -r --name-only),
5339                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5340             my $patchstackchange = cmdoutput @cmd;
5341             if (length $patchstackchange) {
5342                 $patchstackchange =~ s/\n/,/g;
5343                 $not->($p, "changed $patchstackchange");
5344             }
5345
5346             printdebug " search queue P=$p->{Commit} ",
5347                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5348             push @todo, $p;
5349         }
5350     }
5351
5352     if (!$sref_S) {
5353         printdebug "quiltify want to smash\n";
5354
5355         my $abbrev = sub {
5356             my $x = $_[0]{Commit};
5357             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5358             return $x;
5359         };
5360         my $reportnot = sub {
5361             my ($notp) = @_;
5362             my $s = $abbrev->($notp);
5363             my $c = $notp->{Child};
5364             $s .= "..".$abbrev->($c) if $c;
5365             $s .= ": ".$notp->{Whynot};
5366             return $s;
5367         };
5368         if ($quilt_mode eq 'linear') {
5369             print STDERR "\n$us: error: quilt fixup cannot be linear.  Stopped at:\n";
5370             my $all_gdr = !!@nots;
5371             foreach my $notp (@nots) {
5372                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5373                 $all_gdr &&= $notp->{Child} &&
5374                     (git_cat_file $notp->{Child}{Commit}, 'commit')
5375                     =~ m{^\[git-debrebase.*\]$}m;
5376             }
5377             print STDERR "\n";
5378             $failsuggestion =
5379                 [ grep { $_->[0] ne 'quilt-mode' } @$failsuggestion ]
5380                 if $all_gdr;
5381             print STDERR "$us: $_->[1]\n" foreach @$failsuggestion;
5382             fail
5383  "quilt history linearisation failed.  Search \`quilt fixup' in dgit(7).\n";
5384         } elsif ($quilt_mode eq 'smash') {
5385         } elsif ($quilt_mode eq 'auto') {
5386             progress "quilt fixup cannot be linear, smashing...";
5387         } else {
5388             die "$quilt_mode ?";
5389         }
5390
5391         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5392         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5393         my $ncommits = 3;
5394         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5395
5396         quiltify_dpkg_commit "auto-$version-$target-$time",
5397             (getfield $clogp, 'Maintainer'),
5398             "Automatically generated patch ($clogp->{Version})\n".
5399             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5400         return;
5401     }
5402
5403     progress "quiltify linearisation planning successful, executing...";
5404
5405     for (my $p = $sref_S;
5406          my $c = $p->{Child};
5407          $p = $p->{Child}) {
5408         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5409         next unless $p->{Nontrivial};
5410
5411         my $cc = $c->{Commit};
5412
5413         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5414         $commitdata =~ m/\n\n/ or die "$c ?";
5415         $commitdata = $`;
5416         my $msg = $'; #';
5417         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5418         my $author = $1;
5419
5420         my $commitdate = cmdoutput
5421             @git, qw(log -n1 --pretty=format:%aD), $cc;
5422
5423         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5424
5425         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5426         $strip_nls->();
5427
5428         my $title = $1;
5429         my $patchname;
5430         my $patchdir;
5431
5432         my $gbp_check_suitable = sub {
5433             $_ = shift;
5434             my ($what) = @_;
5435
5436             eval {
5437                 die "contains unexpected slashes\n" if m{//} || m{/$};
5438                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5439                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5440                 die "is series file\n" if m{$series_filename_re}o;
5441                 die "too long" if length > 200;
5442             };
5443             return $_ unless $@;
5444             print STDERR "quiltifying commit $cc:".
5445                 " ignoring/dropping Gbp-Pq $what: $@";
5446             return undef;
5447         };
5448
5449         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5450                            gbp-pq-name: \s* )
5451                        (\S+) \s* \n //ixm) {
5452             $patchname = $gbp_check_suitable->($1, 'Name');
5453         }
5454         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5455                            gbp-pq-topic: \s* )
5456                        (\S+) \s* \n //ixm) {
5457             $patchdir = $gbp_check_suitable->($1, 'Topic');
5458         }
5459
5460         $strip_nls->();
5461
5462         if (!defined $patchname) {
5463             $patchname = $title;
5464             $patchname =~ s/[.:]$//;
5465             use Text::Iconv;
5466             eval {
5467                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5468                 my $translitname = $converter->convert($patchname);
5469                 die unless defined $translitname;
5470                 $patchname = $translitname;
5471             };
5472             print STDERR
5473                 "dgit: patch title transliteration error: $@"
5474                 if $@;
5475             $patchname =~ y/ A-Z/-a-z/;
5476             $patchname =~ y/-a-z0-9_.+=~//cd;
5477             $patchname =~ s/^\W/x-$&/;
5478             $patchname = substr($patchname,0,40);
5479             $patchname .= ".patch";
5480         }
5481         if (!defined $patchdir) {
5482             $patchdir = '';
5483         }
5484         if (length $patchdir) {
5485             $patchname = "$patchdir/$patchname";
5486         }
5487         if ($patchname =~ m{^(.*)/}) {
5488             mkpath "debian/patches/$1";
5489         }
5490
5491         my $index;
5492         for ($index='';
5493              stat "debian/patches/$patchname$index";
5494              $index++) { }
5495         $!==ENOENT or die "$patchname$index $!";
5496
5497         runcmd @git, qw(checkout -q), $cc;
5498
5499         # We use the tip's changelog so that dpkg-source doesn't
5500         # produce complaining messages from dpkg-parsechangelog.  None
5501         # of the information dpkg-source gets from the changelog is
5502         # actually relevant - it gets put into the original message
5503         # which dpkg-source provides our stunt editor, and then
5504         # overwritten.
5505         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5506
5507         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5508             "Date: $commitdate\n".
5509             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5510
5511         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5512     }
5513
5514     runcmd @git, qw(checkout -q master);
5515 }
5516
5517 sub build_maybe_quilt_fixup () {
5518     my ($format,$fopts) = get_source_format;
5519     return unless madformat_wantfixup $format;
5520     # sigh
5521
5522     check_for_vendor_patches();
5523
5524     if (quiltmode_splitbrain) {
5525         fail <<END unless access_cfg_tagformats_can_splitbrain;
5526 quilt mode $quilt_mode requires split view so server needs to support
5527  both "new" and "maint" tag formats, but config says it doesn't.
5528 END
5529     }
5530
5531     my $clogp = parsechangelog();
5532     my $headref = git_rev_parse('HEAD');
5533     my $symref = git_get_symref();
5534
5535     if ($quilt_mode eq 'linear'
5536         && !$fopts->{'single-debian-patch'}
5537         && branch_is_gdr($symref, $headref)) {
5538         # This is much faster.  It also makes patches that gdr
5539         # likes better for future updates without laundering.
5540         #
5541         # However, it can fail in some casses where we would
5542         # succeed: if there are existing patches, which correspond
5543         # to a prefix of the branch, but are not in gbp/gdr
5544         # format, gdr will fail (exiting status 7), but we might
5545         # be able to figure out where to start linearising.  That
5546         # will be slower so hopefully there's not much to do.
5547         my @cmd = (@git_debrebase,
5548                    qw(--noop-ok -funclean-mixed -funclean-ordering
5549                       make-patches --quiet-would-amend));
5550         # We tolerate soe snags that gdr wouldn't, by default.
5551         if (act_local()) {
5552             debugcmd "+",@cmd;
5553             $!=0; $?=-1;
5554             failedcmd @cmd if system @cmd and $?!=7*256;
5555         } else {
5556             dryrun_report @cmd;
5557         }
5558         $headref = git_rev_parse('HEAD');
5559     }
5560
5561     prep_ud();
5562     changedir $playground;
5563
5564     my $upstreamversion = upstreamversion $version;
5565
5566     if ($fopts->{'single-debian-patch'}) {
5567         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5568     } else {
5569         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5570     }
5571
5572     changedir $maindir;
5573     runcmd_ordryrun_local
5574         @git, qw(pull --ff-only -q), "$playground/work", qw(master);
5575 }
5576
5577 sub unpack_playtree_mkwork ($) {
5578     my ($headref) = @_;
5579
5580     mkdir "work" or die $!;
5581     changedir "work";
5582     mktree_in_ud_here();
5583     runcmd @git, qw(reset -q --hard), $headref;
5584 }
5585
5586 sub unpack_playtree_linkorigs ($$) {
5587     my ($upstreamversion, $fn) = @_;
5588     # calls $fn->($leafname);
5589
5590     my $bpd_abs = bpd_abs();
5591     opendir QFD, $bpd_abs or fail "buildproductsdir: $bpd_abs: $!";
5592     while ($!=0, defined(my $b = readdir QFD)) {
5593         my $f = bpd_abs()."/".$b;
5594         {
5595             local ($debuglevel) = $debuglevel-1;
5596             printdebug "QF linkorigs $b, $f ?\n";
5597         }
5598         next unless is_orig_file_of_vsn $b, $upstreamversion;
5599         printdebug "QF linkorigs $b, $f Y\n";
5600         link_ltarget $f, $b or die "$b $!";
5601         $fn->($b);
5602     }
5603     die "$buildproductsdir: $!" if $!;
5604     closedir QFD;
5605 }
5606
5607 sub quilt_fixup_delete_pc () {
5608     runcmd @git, qw(rm -rqf .pc);
5609     commit_admin <<END
5610 Commit removal of .pc (quilt series tracking data)
5611
5612 [dgit ($our_version) upgrade quilt-remove-pc]
5613 END
5614 }
5615
5616 sub quilt_fixup_singlepatch ($$$) {
5617     my ($clogp, $headref, $upstreamversion) = @_;
5618
5619     progress "starting quiltify (single-debian-patch)";
5620
5621     # dpkg-source --commit generates new patches even if
5622     # single-debian-patch is in debian/source/options.  In order to
5623     # get it to generate debian/patches/debian-changes, it is
5624     # necessary to build the source package.
5625
5626     unpack_playtree_linkorigs($upstreamversion, sub { });
5627     unpack_playtree_mkwork($headref);
5628
5629     rmtree("debian/patches");
5630
5631     runcmd @dpkgsource, qw(-b .);
5632     changedir "..";
5633     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5634     rename srcfn("$upstreamversion", "/debian/patches"),
5635            "work/debian/patches";
5636
5637     changedir "work";
5638     commit_quilty_patch();
5639 }
5640
5641 sub quilt_make_fake_dsc ($) {
5642     my ($upstreamversion) = @_;
5643
5644     my $fakeversion="$upstreamversion-~~DGITFAKE";
5645
5646     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5647     print $fakedsc <<END or die $!;
5648 Format: 3.0 (quilt)
5649 Source: $package
5650 Version: $fakeversion
5651 Files:
5652 END
5653
5654     my $dscaddfile=sub {
5655         my ($b) = @_;
5656
5657         my $md = new Digest::MD5;
5658
5659         my $fh = new IO::File $b, '<' or die "$b $!";
5660         stat $fh or die $!;
5661         my $size = -s _;
5662
5663         $md->addfile($fh);
5664         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5665     };
5666
5667     unpack_playtree_linkorigs($upstreamversion, $dscaddfile);
5668
5669     my @files=qw(debian/source/format debian/rules
5670                  debian/control debian/changelog);
5671     foreach my $maybe (qw(debian/patches debian/source/options
5672                           debian/tests/control)) {
5673         next unless stat_exists "$maindir/$maybe";
5674         push @files, $maybe;
5675     }
5676
5677     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5678     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C), $maindir, @files;
5679
5680     $dscaddfile->($debtar);
5681     close $fakedsc or die $!;
5682 }
5683
5684 sub quilt_fakedsc2unapplied ($$) {
5685     my ($headref, $upstreamversion) = @_;
5686     # must be run in the playground
5687     # quilt_make_fake_dsc must have been called
5688
5689     runcmd qw(sh -ec),
5690         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5691
5692     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5693     rename $fakexdir, "fake" or die "$fakexdir $!";
5694
5695     changedir 'fake';
5696
5697     remove_stray_gits("source package");
5698     mktree_in_ud_here();
5699
5700     rmtree '.pc';
5701
5702     rmtree 'debian'; # git checkout commitish paths does not delete!
5703     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5704     my $unapplied=git_add_write_tree();
5705     printdebug "fake orig tree object $unapplied\n";
5706     return $unapplied;
5707 }
5708
5709 sub quilt_check_splitbrain_cache ($$) {
5710     my ($headref, $upstreamversion) = @_;
5711     # Called only if we are in (potentially) split brain mode.
5712     # Called in playground.
5713     # Computes the cache key and looks in the cache.
5714     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5715
5716     my $splitbrain_cachekey;
5717
5718     progress
5719  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5720     # we look in the reflog of dgit-intern/quilt-cache
5721     # we look for an entry whose message is the key for the cache lookup
5722     my @cachekey = (qw(dgit), $our_version);
5723     push @cachekey, $upstreamversion;
5724     push @cachekey, $quilt_mode;
5725     push @cachekey, $headref;
5726
5727     push @cachekey, hashfile('fake.dsc');
5728
5729     my $srcshash = Digest::SHA->new(256);
5730     my %sfs = ( %INC, '$0(dgit)' => $0 );
5731     foreach my $sfk (sort keys %sfs) {
5732         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5733         $srcshash->add($sfk,"  ");
5734         $srcshash->add(hashfile($sfs{$sfk}));
5735         $srcshash->add("\n");
5736     }
5737     push @cachekey, $srcshash->hexdigest();
5738     $splitbrain_cachekey = "@cachekey";
5739
5740     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5741
5742     my $cachehit = reflog_cache_lookup
5743         "refs/$splitbraincache", $splitbrain_cachekey;
5744
5745     if ($cachehit) {
5746         unpack_playtree_mkwork($headref);
5747         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5748         if ($cachehit ne $headref) {
5749             progress "dgit view: found cached ($saved)";
5750             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5751             $split_brain = 1;
5752             return ($cachehit, $splitbrain_cachekey);
5753         }
5754         progress "dgit view: found cached, no changes required";
5755         return ($headref, $splitbrain_cachekey);
5756     }
5757
5758     printdebug "splitbrain cache miss\n";
5759     return (undef, $splitbrain_cachekey);
5760 }
5761
5762 sub quilt_fixup_multipatch ($$$) {
5763     my ($clogp, $headref, $upstreamversion) = @_;
5764
5765     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5766
5767     # Our objective is:
5768     #  - honour any existing .pc in case it has any strangeness
5769     #  - determine the git commit corresponding to the tip of
5770     #    the patch stack (if there is one)
5771     #  - if there is such a git commit, convert each subsequent
5772     #    git commit into a quilt patch with dpkg-source --commit
5773     #  - otherwise convert all the differences in the tree into
5774     #    a single git commit
5775     #
5776     # To do this we:
5777
5778     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5779     # dgit would include the .pc in the git tree.)  If there isn't
5780     # one, we need to generate one by unpacking the patches that we
5781     # have.
5782     #
5783     # We first look for a .pc in the git tree.  If there is one, we
5784     # will use it.  (This is not the normal case.)
5785     #
5786     # Otherwise need to regenerate .pc so that dpkg-source --commit
5787     # can work.  We do this as follows:
5788     #     1. Collect all relevant .orig from parent directory
5789     #     2. Generate a debian.tar.gz out of
5790     #         debian/{patches,rules,source/format,source/options}
5791     #     3. Generate a fake .dsc containing just these fields:
5792     #          Format Source Version Files
5793     #     4. Extract the fake .dsc
5794     #        Now the fake .dsc has a .pc directory.
5795     # (In fact we do this in every case, because in future we will
5796     # want to search for a good base commit for generating patches.)
5797     #
5798     # Then we can actually do the dpkg-source --commit
5799     #     1. Make a new working tree with the same object
5800     #        store as our main tree and check out the main
5801     #        tree's HEAD.
5802     #     2. Copy .pc from the fake's extraction, if necessary
5803     #     3. Run dpkg-source --commit
5804     #     4. If the result has changes to debian/, then
5805     #          - git add them them
5806     #          - git add .pc if we had a .pc in-tree
5807     #          - git commit
5808     #     5. If we had a .pc in-tree, delete it, and git commit
5809     #     6. Back in the main tree, fast forward to the new HEAD
5810
5811     # Another situation we may have to cope with is gbp-style
5812     # patches-unapplied trees.
5813     #
5814     # We would want to detect these, so we know to escape into
5815     # quilt_fixup_gbp.  However, this is in general not possible.
5816     # Consider a package with a one patch which the dgit user reverts
5817     # (with git revert or the moral equivalent).
5818     #
5819     # That is indistinguishable in contents from a patches-unapplied
5820     # tree.  And looking at the history to distinguish them is not
5821     # useful because the user might have made a confusing-looking git
5822     # history structure (which ought to produce an error if dgit can't
5823     # cope, not a silent reintroduction of an unwanted patch).
5824     #
5825     # So gbp users will have to pass an option.  But we can usually
5826     # detect their failure to do so: if the tree is not a clean
5827     # patches-applied tree, quilt linearisation fails, but the tree
5828     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5829     # they want --quilt=unapplied.
5830     #
5831     # To help detect this, when we are extracting the fake dsc, we
5832     # first extract it with --skip-patches, and then apply the patches
5833     # afterwards with dpkg-source --before-build.  That lets us save a
5834     # tree object corresponding to .origs.
5835
5836     my $splitbrain_cachekey;
5837
5838     quilt_make_fake_dsc($upstreamversion);
5839
5840     if (quiltmode_splitbrain()) {
5841         my $cachehit;
5842         ($cachehit, $splitbrain_cachekey) =
5843             quilt_check_splitbrain_cache($headref, $upstreamversion);
5844         return if $cachehit;
5845     }
5846     my $unapplied=quilt_fakedsc2unapplied($headref, $upstreamversion);
5847
5848     ensuredir '.pc';
5849
5850     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5851     $!=0; $?=-1;
5852     if (system @bbcmd) {
5853         failedcmd @bbcmd if $? < 0;
5854         fail <<END;
5855 failed to apply your git tree's patch stack (from debian/patches/) to
5856  the corresponding upstream tarball(s).  Your source tree and .orig
5857  are probably too inconsistent.  dgit can only fix up certain kinds of
5858  anomaly (depending on the quilt mode).  Please see --quilt= in dgit(1).
5859 END
5860     }
5861
5862     changedir '..';
5863
5864     unpack_playtree_mkwork($headref);
5865
5866     my $mustdeletepc=0;
5867     if (stat_exists ".pc") {
5868         -d _ or die;
5869         progress "Tree already contains .pc - will use it then delete it.";
5870         $mustdeletepc=1;
5871     } else {
5872         rename '../fake/.pc','.pc' or die $!;
5873     }
5874
5875     changedir '../fake';
5876     rmtree '.pc';
5877     my $oldtiptree=git_add_write_tree();
5878     printdebug "fake o+d/p tree object $unapplied\n";
5879     changedir '../work';
5880
5881
5882     # We calculate some guesswork now about what kind of tree this might
5883     # be.  This is mostly for error reporting.
5884
5885     my %editedignores;
5886     my @unrepres;
5887     my $diffbits = {
5888         # H = user's HEAD
5889         # O = orig, without patches applied
5890         # A = "applied", ie orig with H's debian/patches applied
5891         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5892                                      \%editedignores, \@unrepres),
5893         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5894         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5895     };
5896
5897     my @dl;
5898     foreach my $b (qw(01 02)) {
5899         foreach my $v (qw(O2H O2A H2A)) {
5900             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5901         }
5902     }
5903     printdebug "differences \@dl @dl.\n";
5904
5905     progress sprintf
5906 "$us: base trees orig=%.20s o+d/p=%.20s",
5907               $unapplied, $oldtiptree;
5908     progress sprintf
5909 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5910 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5911                              $dl[0], $dl[1],              $dl[3], $dl[4],
5912                                  $dl[2],                     $dl[5];
5913
5914     if (@unrepres) {
5915         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5916             foreach @unrepres;
5917         forceable_fail [qw(unrepresentable)], <<END;
5918 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5919 END
5920     }
5921
5922     my @failsuggestion;
5923     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5924         push @failsuggestion, [ 'unapplied',
5925                                "This might be a patches-unapplied branch." ];
5926     } elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5927         push @failsuggestion, [ 'applied',
5928                                 "This might be a patches-applied branch." ];
5929     }
5930     push @failsuggestion, [ 'quilt-mode',
5931  "Maybe you need one of --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?" ];
5932
5933     push @failsuggestion, [ 'gitattrs',
5934  "Warning: Tree has .gitattributes.  See GITATTRIBUTES in dgit(7)." ]
5935         if stat_exists '.gitattributes';
5936
5937     push @failsuggestion, [ 'origs',
5938  "Maybe orig tarball(s) are not identical to git representation?" ];
5939
5940     if (quiltmode_splitbrain()) {
5941         quiltify_splitbrain($clogp, $unapplied, $headref, $oldtiptree,
5942                             $diffbits, \%editedignores,
5943                             $splitbrain_cachekey);
5944         return;
5945     }
5946
5947     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5948     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5949
5950     if (!open P, '>>', ".pc/applied-patches") {
5951         $!==&ENOENT or die $!;
5952     } else {
5953         close P;
5954     }
5955
5956     commit_quilty_patch();
5957
5958     if ($mustdeletepc) {
5959         quilt_fixup_delete_pc();
5960     }
5961 }
5962
5963 sub quilt_fixup_editor () {
5964     my $descfn = $ENV{$fakeeditorenv};
5965     my $editing = $ARGV[$#ARGV];
5966     open I1, '<', $descfn or die "$descfn: $!";
5967     open I2, '<', $editing or die "$editing: $!";
5968     unlink $editing or die "$editing: $!";
5969     open O, '>', $editing or die "$editing: $!";
5970     while (<I1>) { print O or die $!; } I1->error and die $!;
5971     my $copying = 0;
5972     while (<I2>) {
5973         $copying ||= m/^\-\-\- /;
5974         next unless $copying;
5975         print O or die $!;
5976     }
5977     I2->error and die $!;
5978     close O or die $1;
5979     finish 0;
5980 }
5981
5982 sub maybe_apply_patches_dirtily () {
5983     return unless $quilt_mode =~ m/gbp|unapplied/;
5984     print STDERR <<END or die $!;
5985
5986 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5987 dgit: Have to apply the patches - making the tree dirty.
5988 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5989
5990 END
5991     $patches_applied_dirtily = 01;
5992     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5993     runcmd qw(dpkg-source --before-build .);
5994 }
5995
5996 sub maybe_unapply_patches_again () {
5997     progress "dgit: Unapplying patches again to tidy up the tree."
5998         if $patches_applied_dirtily;
5999     runcmd qw(dpkg-source --after-build .)
6000         if $patches_applied_dirtily & 01;
6001     rmtree '.pc'
6002         if $patches_applied_dirtily & 02;
6003     $patches_applied_dirtily = 0;
6004 }
6005
6006 #----- other building -----
6007
6008 our $clean_using_builder;
6009 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
6010 #   clean the tree before building (perhaps invoked indirectly by
6011 #   whatever we are using to run the build), rather than separately
6012 #   and explicitly by us.
6013
6014 sub clean_tree () {
6015     return if $clean_using_builder;
6016     if ($cleanmode eq 'dpkg-source') {
6017         maybe_apply_patches_dirtily();
6018         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
6019     } elsif ($cleanmode eq 'dpkg-source-d') {
6020         maybe_apply_patches_dirtily();
6021         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
6022     } elsif ($cleanmode eq 'git') {
6023         runcmd_ordryrun_local @git, qw(clean -xdf);
6024     } elsif ($cleanmode eq 'git-ff') {
6025         runcmd_ordryrun_local @git, qw(clean -xdff);
6026     } elsif ($cleanmode eq 'check') {
6027         my $leftovers = cmdoutput @git, qw(clean -xdn);
6028         if (length $leftovers) {
6029             print STDERR $leftovers, "\n" or die $!;
6030             fail "tree contains uncommitted files and --clean=check specified";
6031         }
6032     } elsif ($cleanmode eq 'none') {
6033     } else {
6034         die "$cleanmode ?";
6035     }
6036 }
6037
6038 sub cmd_clean () {
6039     badusage "clean takes no additional arguments" if @ARGV;
6040     notpushing();
6041     clean_tree();
6042     maybe_unapply_patches_again();
6043 }
6044
6045 # return values from massage_dbp_args are one or both of these flags
6046 sub WANTSRC_SOURCE  () { 01; } # caller should build source (separately)
6047 sub WANTSRC_BUILDER () { 02; } # caller should run dpkg-buildpackage
6048
6049 sub build_or_push_prep_early () {
6050     our $build_or_push_prep_early_done //= 0;
6051     return if $build_or_push_prep_early_done++;
6052     badusage "-p is not allowed with dgit $subcommand" if defined $package;
6053     my $clogp = parsechangelog();
6054     $isuite = getfield $clogp, 'Distribution';
6055     $package = getfield $clogp, 'Source';
6056     $version = getfield $clogp, 'Version';
6057     $dscfn = dscfn($version);
6058 }
6059
6060 sub build_prep_early () {
6061     build_or_push_prep_early();
6062     notpushing();
6063     check_not_dirty();
6064 }
6065
6066 sub build_prep ($) {
6067     my ($wantsrc) = @_;
6068     build_prep_early();
6069     # clean the tree if we're trying to include dirty changes in the
6070     # source package, or we are running the builder in $maindir
6071     clean_tree() if $includedirty || ($wantsrc & WANTSRC_BUILDER);
6072     build_maybe_quilt_fixup();
6073     if ($rmchanges) {
6074         my $pat = changespat $version;
6075         foreach my $f (glob "$buildproductsdir/$pat") {
6076             if (act_local()) {
6077                 unlink $f or fail "remove old changes file $f: $!";
6078             } else {
6079                 progress "would remove $f";
6080             }
6081         }
6082     }
6083 }
6084
6085 sub changesopts_initial () {
6086     my @opts =@changesopts[1..$#changesopts];
6087 }
6088
6089 sub changesopts_version () {
6090     if (!defined $changes_since_version) {
6091         my @vsns;
6092         unless (eval {
6093             @vsns = archive_query('archive_query');
6094             my @quirk = access_quirk();
6095             if ($quirk[0] eq 'backports') {
6096                 local $isuite = $quirk[2];
6097                 local $csuite;
6098                 canonicalise_suite();
6099                 push @vsns, archive_query('archive_query');
6100             }
6101             1;
6102         }) {
6103             print STDERR $@;
6104             fail
6105  "archive query failed (queried because --since-version not specified)";
6106         }
6107         if (@vsns) {
6108             @vsns = map { $_->[0] } @vsns;
6109             @vsns = sort { -version_compare($a, $b) } @vsns;
6110             $changes_since_version = $vsns[0];
6111             progress "changelog will contain changes since $vsns[0]";
6112         } else {
6113             $changes_since_version = '_';
6114             progress "package seems new, not specifying -v<version>";
6115         }
6116     }
6117     if ($changes_since_version ne '_') {
6118         return ("-v$changes_since_version");
6119     } else {
6120         return ();
6121     }
6122 }
6123
6124 sub changesopts () {
6125     return (changesopts_initial(), changesopts_version());
6126 }
6127
6128 sub massage_dbp_args ($;$) {
6129     my ($cmd,$xargs) = @_;
6130     # Since we split the source build out so we can do strange things
6131     # to it, massage the arguments to dpkg-buildpackage so that the
6132     # main build doessn't build source (or add an argument to stop it
6133     # building source by default).
6134     debugcmd '#massaging#', @$cmd if $debuglevel>1;
6135     # -nc has the side effect of specifying -b if nothing else specified
6136     # and some combinations of -S, -b, et al, are errors, rather than
6137     # later simply overriding earlie.  So we need to:
6138     #  - search the command line for these options
6139     #  - pick the last one
6140     #  - perhaps add our own as a default
6141     #  - perhaps adjust it to the corresponding non-source-building version
6142     my $dmode = '-F';
6143     foreach my $l ($cmd, $xargs) {
6144         next unless $l;
6145         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
6146     }
6147     push @$cmd, '-nc';
6148 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
6149     my $r = WANTSRC_BUILDER;
6150     printdebug "massage split $dmode.\n";
6151     $r = $dmode =~ m/[S]/  ?  WANTSRC_SOURCE :
6152       $dmode =~ y/gGF/ABb/ ?  WANTSRC_SOURCE | WANTSRC_BUILDER :
6153       $dmode =~ m/[ABb]/   ?                   WANTSRC_BUILDER :
6154       die "$dmode ?";
6155     printdebug "massage done $r $dmode.\n";
6156     push @$cmd, $dmode;
6157 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
6158     return $r;
6159 }
6160
6161 sub in_bpd (&) {
6162     my ($fn) = @_;
6163     my $wasdir = must_getcwd();
6164     changedir $buildproductsdir;
6165     $fn->();
6166     changedir $wasdir;
6167 }
6168
6169 # this sub must run with CWD=$buildproductsdir (eg in in_bpd)
6170 sub postbuild_mergechanges ($) {
6171     my ($msg_if_onlyone) = @_;
6172     # If there is only one .changes file, fail with $msg_if_onlyone,
6173     # or if that is undef, be a no-op.
6174     # Returns the changes file to report to the user.
6175     my $pat = changespat $version;
6176     my @changesfiles = grep { !m/_multi\.changes/ } glob $pat;
6177     @changesfiles = sort {
6178         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
6179             or $a cmp $b
6180     } @changesfiles;
6181     my $result;
6182     if (@changesfiles==1) {
6183         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
6184 only one changes file from build (@changesfiles)
6185 END
6186         $result = $changesfiles[0];
6187     } elsif (@changesfiles==2) {
6188         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
6189         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
6190             fail "$l found in binaries changes file $binchanges"
6191                 if $l =~ m/\.dsc$/;
6192         }
6193         runcmd_ordryrun_local @mergechanges, @changesfiles;
6194         my $multichanges = changespat $version,'multi';
6195         if (act_local()) {
6196             stat_exists $multichanges or fail "$multichanges: $!";
6197             foreach my $cf (glob $pat) {
6198                 next if $cf eq $multichanges;
6199                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
6200             }
6201         }
6202         $result = $multichanges;
6203     } else {
6204         fail "wrong number of different changes files (@changesfiles)";
6205     }
6206     printdone "build successful, results in $result\n" or die $!;
6207 }
6208
6209 sub midbuild_checkchanges () {
6210     my $pat = changespat $version;
6211     return if $rmchanges;
6212     my @unwanted = map { s#.*/##; $_; } glob "$bpd_glob/$pat";
6213     @unwanted = grep {
6214         $_ ne changespat $version,'source' and
6215         $_ ne changespat $version,'multi'
6216     } @unwanted;
6217     fail <<END
6218 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
6219 Suggest you delete @unwanted.
6220 END
6221         if @unwanted;
6222 }
6223
6224 sub midbuild_checkchanges_vanilla ($) {
6225     my ($wantsrc) = @_;
6226     midbuild_checkchanges() if $wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER);
6227 }
6228
6229 sub postbuild_mergechanges_vanilla ($) {
6230     my ($wantsrc) = @_;
6231     if ($wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER)) {
6232         in_bpd {
6233             postbuild_mergechanges(undef);
6234         };
6235     } else {
6236         printdone "build successful\n";
6237     }
6238 }
6239
6240 sub cmd_build {
6241     build_prep_early();
6242     $buildproductsdir eq '..' or print STDERR <<END;
6243 $us: warning: build-products-dir set, but not supported by dgit build
6244 $us: warning: things may go wrong or files may go to the wrong place
6245 END
6246     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6247     my $wantsrc = massage_dbp_args \@dbp;
6248     build_prep($wantsrc);
6249     if ($wantsrc & WANTSRC_SOURCE) {
6250         build_source();
6251         midbuild_checkchanges_vanilla $wantsrc;
6252     }
6253     if ($wantsrc & WANTSRC_BUILDER) {
6254         push @dbp, changesopts_version();
6255         maybe_apply_patches_dirtily();
6256         runcmd_ordryrun_local @dbp;
6257     }
6258     maybe_unapply_patches_again();
6259     postbuild_mergechanges_vanilla $wantsrc;
6260 }
6261
6262 sub pre_gbp_build {
6263     $quilt_mode //= 'gbp';
6264 }
6265
6266 sub cmd_gbp_build {
6267     build_prep_early();
6268
6269     # gbp can make .origs out of thin air.  In my tests it does this
6270     # even for a 1.0 format package, with no origs present.  So I
6271     # guess it keys off just the version number.  We don't know
6272     # exactly what .origs ought to exist, but let's assume that we
6273     # should run gbp if: the version has an upstream part and the main
6274     # orig is absent.
6275     my $upstreamversion = upstreamversion $version;
6276     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6277     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "$bpd_glob/$origfnpat");
6278
6279     if ($gbp_make_orig) {
6280         clean_tree();
6281         $cleanmode = 'none'; # don't do it again
6282     }
6283
6284     my @dbp = @dpkgbuildpackage;
6285
6286     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6287
6288     if (!length $gbp_build[0]) {
6289         if (length executable_on_path('git-buildpackage')) {
6290             $gbp_build[0] = qw(git-buildpackage);
6291         } else {
6292             $gbp_build[0] = 'gbp buildpackage';
6293         }
6294     }
6295     my @cmd = opts_opt_multi_cmd [], @gbp_build;
6296
6297     push @cmd, (qw(-us -uc --git-no-sign-tags),
6298                 "--git-builder=".(shellquote @dbp));
6299
6300     if ($gbp_make_orig) {
6301         my $priv = dgit_privdir();
6302         my $ok = "$priv/origs-gen-ok";
6303         unlink $ok or $!==&ENOENT or die $!;
6304         my @origs_cmd = @cmd;
6305         push @origs_cmd, qw(--git-cleaner=true);
6306         push @origs_cmd, "--git-prebuild=".
6307             "touch ".(shellquote $ok)." ".(shellquote "$priv/no-such-dir/ok");
6308         push @origs_cmd, @ARGV;
6309         if (act_local()) {
6310             debugcmd @origs_cmd;
6311             system @origs_cmd;
6312             do { local $!; stat_exists $ok; }
6313                 or failedcmd @origs_cmd;
6314         } else {
6315             dryrun_report @origs_cmd;
6316         }
6317     }
6318
6319     build_prep($wantsrc);
6320     if ($wantsrc & WANTSRC_SOURCE) {
6321         build_source();
6322         midbuild_checkchanges_vanilla $wantsrc;
6323     } else {
6324         if (!$clean_using_builder) {
6325             push @cmd, '--git-cleaner=true';
6326         }
6327     }
6328     maybe_unapply_patches_again();
6329     if ($wantsrc & WANTSRC_BUILDER) {
6330         push @cmd, changesopts();
6331         runcmd_ordryrun_local @cmd, @ARGV;
6332     }
6333     postbuild_mergechanges_vanilla $wantsrc;
6334 }
6335 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6336
6337 sub building_source_in_playtree {
6338     # If $includedirty, we have to build the source package from the
6339     # working tree, not a playtree, so that uncommitted changes are
6340     # included (copying or hardlinking them into the playtree could
6341     # cause trouble).
6342     #
6343     # Note that if we are building a source package in split brain
6344     # mode we do not support including uncommitted changes, because
6345     # that makes quilt fixup too hard.  I.e. ($split_brain && (dgit is
6346     # building a source package)) => !$includedirty
6347     return !$includedirty;
6348 }
6349
6350 sub build_source {
6351     $sourcechanges = changespat $version,'source';
6352     if (act_local()) {
6353         unlink "$buildproductsdir/$sourcechanges" or $!==ENOENT
6354             or fail "remove $sourcechanges: $!";
6355     }
6356     my @cmd = (@dpkgsource, qw(-b --));
6357     my $leafdir;
6358     if (building_source_in_playtree()) {
6359         $leafdir = 'work';
6360         my $headref = git_rev_parse('HEAD');
6361         # If we are in split brain, there is already a playtree with
6362         # the thing we should package into a .dsc (thanks to quilt
6363         # fixup).  If not, make a playtree
6364         prep_ud() unless $split_brain;
6365         changedir $playground;
6366         unless ($split_brain) {
6367             my $upstreamversion = upstreamversion $version;
6368             unpack_playtree_linkorigs($upstreamversion, sub { });
6369             unpack_playtree_mkwork($headref);
6370             changedir '..';
6371         }
6372     } else {
6373         $leafdir = basename $maindir;
6374         changedir '..';
6375     }
6376     runcmd_ordryrun_local @cmd, $leafdir;
6377
6378     changedir $leafdir;
6379     runcmd_ordryrun_local qw(sh -ec),
6380       'exec >../$1; shift; exec "$@"','x', $sourcechanges,
6381       @dpkggenchanges, qw(-S), changesopts();
6382     changedir '..';
6383
6384     printdebug "moving $dscfn, $sourcechanges, etc. to ".bpd_abs()."\n";
6385     $dsc = parsecontrol($dscfn, "source package");
6386
6387     my $mv = sub {
6388         my ($why, $l) = @_;
6389         printdebug " renaming ($why) $l\n";
6390         rename "$l", bpd_abs()."/$l"
6391             or fail "put in place new built file ($l): $!";
6392     };
6393     foreach my $l (split /\n/, getfield $dsc, 'Files') {
6394         $l =~ m/\S+$/ or next;
6395         $mv->('Files', $&);
6396     }
6397     $mv->('dsc', $dscfn);
6398     $mv->('changes', $sourcechanges);
6399
6400     changedir $maindir;
6401 }
6402
6403 sub cmd_build_source {
6404     badusage "build-source takes no additional arguments" if @ARGV;
6405     build_prep(WANTSRC_SOURCE);
6406     build_source();
6407     maybe_unapply_patches_again();
6408     printdone "source built, results in $dscfn and $sourcechanges";
6409 }
6410
6411 sub cmd_push_source {
6412     prep_push();
6413     fail "dgit push-source: --include-dirty/--ignore-dirty does not make".
6414       "sense with push-source!" if $includedirty;
6415     build_maybe_quilt_fixup();
6416     if ($changesfile) {
6417         my $changes = parsecontrol("$buildproductsdir/$changesfile",
6418                                    "source changes file");
6419         unless (test_source_only_changes($changes)) {
6420             fail "user-specified changes file is not source-only";
6421         }
6422     } else {
6423         # Building a source package is very fast, so just do it
6424         build_source();
6425         die "er, patches are applied dirtily but shouldn't be.."
6426             if $patches_applied_dirtily;
6427         $changesfile = $sourcechanges;
6428     }
6429     dopush();
6430 }
6431
6432 sub binary_builder {
6433     my ($bbuilder, $pbmc_msg, @args) = @_;
6434     build_prep(WANTSRC_SOURCE);
6435     build_source();
6436     midbuild_checkchanges();
6437     in_bpd {
6438         if (act_local()) {
6439             stat_exists $dscfn or fail "$dscfn (in build products dir): $!";
6440             stat_exists $sourcechanges
6441                 or fail "$sourcechanges (in build products dir): $!";
6442         }
6443         runcmd_ordryrun_local @$bbuilder, @args;
6444     };
6445     maybe_unapply_patches_again();
6446     in_bpd {
6447         postbuild_mergechanges($pbmc_msg);
6448     };
6449 }
6450
6451 sub cmd_sbuild {
6452     build_prep_early();
6453     binary_builder(\@sbuild, <<END, qw(-d), $isuite, @ARGV, $dscfn);
6454 perhaps you need to pass -A ?  (sbuild's default is to build only
6455 arch-specific binaries; dgit 1.4 used to override that.)
6456 END
6457 }
6458
6459 sub pbuilder ($) {
6460     my ($pbuilder) = @_;
6461     build_prep_early();
6462     # @ARGV is allowed to contain only things that should be passed to
6463     # pbuilder under debbuildopts; just massage those
6464     my $wantsrc = massage_dbp_args \@ARGV;
6465     fail "you asked for a builder but your debbuildopts didn't ask for".
6466       " any binaries -- is this really what you meant?"
6467       unless $wantsrc & WANTSRC_BUILDER;
6468     fail "we must build a .dsc to pass to the builder but your debbuiltopts".
6469       " forbids the building of a source package; cannot continue"
6470       unless $wantsrc & WANTSRC_SOURCE;
6471     # We do not want to include the verb "build" in @pbuilder because
6472     # the user can customise @pbuilder and they shouldn't be required
6473     # to include "build" in their customised value.  However, if the
6474     # user passes any additional args to pbuilder using the dgit
6475     # option --pbuilder:foo, such args need to come after the "build"
6476     # verb.  opts_opt_multi_cmd does all of that.
6477     binary_builder([opts_opt_multi_cmd ["build"], @$pbuilder], undef,
6478                    qw(--debbuildopts), "@ARGV", qw(--distribution), $isuite,
6479                    $dscfn);
6480 }
6481
6482 sub cmd_pbuilder {
6483     pbuilder(\@pbuilder);
6484 }
6485
6486 sub cmd_cowbuilder {
6487     pbuilder(\@cowbuilder);
6488 }
6489
6490 sub cmd_quilt_fixup {
6491     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6492     build_prep_early();
6493     clean_tree();
6494     build_maybe_quilt_fixup();
6495 }
6496
6497 sub cmd_print_unapplied_treeish {
6498     badusage "incorrect arguments to dgit print-unapplied-treeish" if @ARGV;
6499     my $headref = git_rev_parse('HEAD');
6500     my $clogp = commit_getclogp $headref;
6501     $package = getfield $clogp, 'Source';
6502     $version = getfield $clogp, 'Version';
6503     $isuite = getfield $clogp, 'Distribution';
6504     $csuite = $isuite; # we want this to be offline!
6505     notpushing();
6506
6507     prep_ud();
6508     changedir $playground;
6509     my $uv = upstreamversion $version;
6510     quilt_make_fake_dsc($uv);
6511     my $u = quilt_fakedsc2unapplied($headref, $uv);
6512     print $u, "\n" or die $!;
6513 }
6514
6515 sub import_dsc_result {
6516     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6517     my @cmd = (git_update_ref_cmd $what_log, $dstref, $newhash);
6518     runcmd @cmd;
6519     check_gitattrs($newhash, "source tree");
6520
6521     progress "dgit: import-dsc: $what_msg";
6522 }
6523
6524 sub cmd_import_dsc {
6525     my $needsig = 0;
6526
6527     while (@ARGV) {
6528         last unless $ARGV[0] =~ m/^-/;
6529         $_ = shift @ARGV;
6530         last if m/^--?$/;
6531         if (m/^--require-valid-signature$/) {
6532             $needsig = 1;
6533         } else {
6534             badusage "unknown dgit import-dsc sub-option \`$_'";
6535         }
6536     }
6537
6538     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6539     my ($dscfn, $dstbranch) = @ARGV;
6540
6541     badusage "dry run makes no sense with import-dsc" unless act_local();
6542
6543     my $force = $dstbranch =~ s/^\+//   ? +1 :
6544                 $dstbranch =~ s/^\.\.// ? -1 :
6545                                            0;
6546     my $info = $force ? " $&" : '';
6547     $info = "$dscfn$info";
6548
6549     my $specbranch = $dstbranch;
6550     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6551     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6552
6553     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6554     my $chead = cmdoutput_errok @symcmd;
6555     defined $chead or $?==256 or failedcmd @symcmd;
6556
6557     fail "$dstbranch is checked out - will not update it"
6558         if defined $chead and $chead eq $dstbranch;
6559
6560     my $oldhash = git_get_ref $dstbranch;
6561
6562     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6563     $dscdata = do { local $/ = undef; <D>; };
6564     D->error and fail "read $dscfn: $!";
6565     close C;
6566
6567     # we don't normally need this so import it here
6568     use Dpkg::Source::Package;
6569     my $dp = new Dpkg::Source::Package filename => $dscfn,
6570         require_valid_signature => $needsig;
6571     {
6572         local $SIG{__WARN__} = sub {
6573             print STDERR $_[0];
6574             return unless $needsig;
6575             fail "import-dsc signature check failed";
6576         };
6577         if (!$dp->is_signed()) {
6578             warn "$us: warning: importing unsigned .dsc\n";
6579         } else {
6580             my $r = $dp->check_signature();
6581             die "->check_signature => $r" if $needsig && $r;
6582         }
6583     }
6584
6585     parse_dscdata();
6586
6587     $package = getfield $dsc, 'Source';
6588
6589     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6590         unless forceing [qw(import-dsc-with-dgit-field)];
6591     parse_dsc_field_def_dsc_distro();
6592
6593     $isuite = 'DGIT-IMPORT-DSC';
6594     $idistro //= $dsc_distro;
6595
6596     notpushing();
6597
6598     if (defined $dsc_hash) {
6599         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6600         resolve_dsc_field_commit undef, undef;
6601     }
6602     if (defined $dsc_hash) {
6603         my @cmd = (qw(sh -ec),
6604                    "echo $dsc_hash | git cat-file --batch-check");
6605         my $objgot = cmdoutput @cmd;
6606         if ($objgot =~ m#^\w+ missing\b#) {
6607             fail <<END
6608 .dsc contains Dgit field referring to object $dsc_hash
6609 Your git tree does not have that object.  Try `git fetch' from a
6610 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6611 END
6612         }
6613         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6614             if ($force > 0) {
6615                 progress "Not fast forward, forced update.";
6616             } else {
6617                 fail "Not fast forward to $dsc_hash";
6618             }
6619         }
6620         import_dsc_result $dstbranch, $dsc_hash,
6621             "dgit import-dsc (Dgit): $info",
6622             "updated git ref $dstbranch";
6623         return 0;
6624     }
6625
6626     fail <<END
6627 Branch $dstbranch already exists
6628 Specify ..$specbranch for a pseudo-merge, binding in existing history
6629 Specify  +$specbranch to overwrite, discarding existing history
6630 END
6631         if $oldhash && !$force;
6632
6633     my @dfi = dsc_files_info();
6634     foreach my $fi (@dfi) {
6635         my $f = $fi->{Filename};
6636         my $here = "$buildproductsdir/$f";
6637         if (lstat $here) {
6638             next if stat $here;
6639             fail "lstat $here works but stat gives $! !";
6640         }
6641         fail "stat $here: $!" unless $! == ENOENT;
6642         my $there = $dscfn;
6643         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6644             $there = $';
6645         } elsif ($dscfn =~ m#^/#) {
6646             $there = $dscfn;
6647         } else {
6648             fail "cannot import $dscfn which seems to be inside working tree!";
6649         }
6650         $there =~ s#/+[^/]+$## or
6651             fail "import $dscfn requires ../$f, but it does not exist";
6652         $there .= "/$f";
6653         my $test = $there =~ m{^/} ? $there : "../$there";
6654         stat $test or fail "import $dscfn requires $test, but: $!";
6655         symlink $there, $here or fail "symlink $there to $here: $!";
6656         progress "made symlink $here -> $there";
6657 #       print STDERR Dumper($fi);
6658     }
6659     my @mergeinputs = generate_commits_from_dsc();
6660     die unless @mergeinputs == 1;
6661
6662     my $newhash = $mergeinputs[0]{Commit};
6663
6664     if ($oldhash) {
6665         if ($force > 0) {
6666             progress "Import, forced update - synthetic orphan git history.";
6667         } elsif ($force < 0) {
6668             progress "Import, merging.";
6669             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6670             my $version = getfield $dsc, 'Version';
6671             my $clogp = commit_getclogp $newhash;
6672             my $authline = clogp_authline $clogp;
6673             $newhash = make_commit_text <<END;
6674 tree $tree
6675 parent $newhash
6676 parent $oldhash
6677 author $authline
6678 committer $authline
6679
6680 Merge $package ($version) import into $dstbranch
6681 END
6682         } else {
6683             die; # caught earlier
6684         }
6685     }
6686
6687     import_dsc_result $dstbranch, $newhash,
6688         "dgit import-dsc: $info",
6689         "results are in in git ref $dstbranch";
6690 }
6691
6692 sub pre_archive_api_query () {
6693     not_necessarily_a_tree();
6694 }
6695 sub cmd_archive_api_query {
6696     badusage "need only 1 subpath argument" unless @ARGV==1;
6697     my ($subpath) = @ARGV;
6698     local $isuite = 'DGIT-API-QUERY-CMD';
6699     my @cmd = archive_api_query_cmd($subpath);
6700     push @cmd, qw(-f);
6701     debugcmd ">",@cmd;
6702     exec @cmd or fail "exec curl: $!\n";
6703 }
6704
6705 sub repos_server_url () {
6706     $package = '_dgit-repos-server';
6707     local $access_forpush = 1;
6708     local $isuite = 'DGIT-REPOS-SERVER';
6709     my $url = access_giturl();
6710 }
6711
6712 sub pre_clone_dgit_repos_server () {
6713     not_necessarily_a_tree();
6714 }
6715 sub cmd_clone_dgit_repos_server {
6716     badusage "need destination argument" unless @ARGV==1;
6717     my ($destdir) = @ARGV;
6718     my $url = repos_server_url();
6719     my @cmd = (@git, qw(clone), $url, $destdir);
6720     debugcmd ">",@cmd;
6721     exec @cmd or fail "exec git clone: $!\n";
6722 }
6723
6724 sub pre_print_dgit_repos_server_source_url () {
6725     not_necessarily_a_tree();
6726 }
6727 sub cmd_print_dgit_repos_server_source_url {
6728     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6729         if @ARGV;
6730     my $url = repos_server_url();
6731     print $url, "\n" or die $!;
6732 }
6733
6734 sub pre_print_dpkg_source_ignores {
6735     not_necessarily_a_tree();
6736 }
6737 sub cmd_print_dpkg_source_ignores {
6738     badusage "no arguments allowed to dgit print-dpkg-source-ignores"
6739         if @ARGV;
6740     print "@dpkg_source_ignores\n" or die $!;
6741 }
6742
6743 sub cmd_setup_mergechangelogs {
6744     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6745     local $isuite = 'DGIT-SETUP-TREE';
6746     setup_mergechangelogs(1);
6747 }
6748
6749 sub cmd_setup_useremail {
6750     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6751     local $isuite = 'DGIT-SETUP-TREE';
6752     setup_useremail(1);
6753 }
6754
6755 sub cmd_setup_gitattributes {
6756     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6757     local $isuite = 'DGIT-SETUP-TREE';
6758     setup_gitattrs(1);
6759 }
6760
6761 sub cmd_setup_new_tree {
6762     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6763     local $isuite = 'DGIT-SETUP-TREE';
6764     setup_new_tree();
6765 }
6766
6767 #---------- argument parsing and main program ----------
6768
6769 sub cmd_version {
6770     print "dgit version $our_version\n" or die $!;
6771     finish 0;
6772 }
6773
6774 our (%valopts_long, %valopts_short);
6775 our (%funcopts_long);
6776 our @rvalopts;
6777 our (@modeopt_cfgs);
6778
6779 sub defvalopt ($$$$) {
6780     my ($long,$short,$val_re,$how) = @_;
6781     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6782     $valopts_long{$long} = $oi;
6783     $valopts_short{$short} = $oi;
6784     # $how subref should:
6785     #   do whatever assignemnt or thing it likes with $_[0]
6786     #   if the option should not be passed on to remote, @rvalopts=()
6787     # or $how can be a scalar ref, meaning simply assign the value
6788 }
6789
6790 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6791 defvalopt '--distro',        '-d', '.+',      \$idistro;
6792 defvalopt '',                '-k', '.+',      \$keyid;
6793 defvalopt '--existing-package','', '.*',      \$existing_package;
6794 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6795 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6796 defvalopt '--package',   '-p',   $package_re, \$package;
6797 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6798
6799 defvalopt '', '-C', '.+', sub {
6800     ($changesfile) = (@_);
6801     if ($changesfile =~ s#^(.*)/##) {
6802         $buildproductsdir = $1;
6803     }
6804 };
6805
6806 defvalopt '--initiator-tempdir','','.*', sub {
6807     ($initiator_tempdir) = (@_);
6808     $initiator_tempdir =~ m#^/# or
6809         badusage "--initiator-tempdir must be used specify an".
6810         " absolute, not relative, directory."
6811 };
6812
6813 sub defoptmodes ($@) {
6814     my ($varref, $cfgkey, $default, %optmap) = @_;
6815     my %permit;
6816     while (my ($opt,$val) = each %optmap) {
6817         $funcopts_long{$opt} = sub { $$varref = $val; };
6818         $permit{$val} = $val;
6819     }
6820     push @modeopt_cfgs, {
6821         Var => $varref,
6822         Key => $cfgkey,
6823         Default => $default,
6824         Vals => \%permit
6825     };
6826 }
6827
6828 defoptmodes \$dodep14tag, qw( dep14tag          want
6829                               --dep14tag        want
6830                               --no-dep14tag     no
6831                               --always-dep14tag always );
6832
6833 sub parseopts () {
6834     my $om;
6835
6836     if (defined $ENV{'DGIT_SSH'}) {
6837         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6838     } elsif (defined $ENV{'GIT_SSH'}) {
6839         @ssh = ($ENV{'GIT_SSH'});
6840     }
6841
6842     my $oi;
6843     my $val;
6844     my $valopt = sub {
6845         my ($what) = @_;
6846         @rvalopts = ($_);
6847         if (!defined $val) {
6848             badusage "$what needs a value" unless @ARGV;
6849             $val = shift @ARGV;
6850             push @rvalopts, $val;
6851         }
6852         badusage "bad value \`$val' for $what" unless
6853             $val =~ m/^$oi->{Re}$(?!\n)/s;
6854         my $how = $oi->{How};
6855         if (ref($how) eq 'SCALAR') {
6856             $$how = $val;
6857         } else {
6858             $how->($val);
6859         }
6860         push @ropts, @rvalopts;
6861     };
6862
6863     while (@ARGV) {
6864         last unless $ARGV[0] =~ m/^-/;
6865         $_ = shift @ARGV;
6866         last if m/^--?$/;
6867         if (m/^--/) {
6868             if (m/^--dry-run$/) {
6869                 push @ropts, $_;
6870                 $dryrun_level=2;
6871             } elsif (m/^--damp-run$/) {
6872                 push @ropts, $_;
6873                 $dryrun_level=1;
6874             } elsif (m/^--no-sign$/) {
6875                 push @ropts, $_;
6876                 $sign=0;
6877             } elsif (m/^--help$/) {
6878                 cmd_help();
6879             } elsif (m/^--version$/) {
6880                 cmd_version();
6881             } elsif (m/^--new$/) {
6882                 push @ropts, $_;
6883                 $new_package=1;
6884             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6885                      ($om = $opts_opt_map{$1}) &&
6886                      length $om->[0]) {
6887                 push @ropts, $_;
6888                 $om->[0] = $2;
6889             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6890                      !$opts_opt_cmdonly{$1} &&
6891                      ($om = $opts_opt_map{$1})) {
6892                 push @ropts, $_;
6893                 push @$om, $2;
6894             } elsif (m/^--(gbp|dpm)$/s) {
6895                 push @ropts, "--quilt=$1";
6896                 $quilt_mode = $1;
6897             } elsif (m/^--(?:ignore|include)-dirty$/s) {
6898                 push @ropts, $_;
6899                 $includedirty = 1;
6900             } elsif (m/^--no-quilt-fixup$/s) {
6901                 push @ropts, $_;
6902                 $quilt_mode = 'nocheck';
6903             } elsif (m/^--no-rm-on-error$/s) {
6904                 push @ropts, $_;
6905                 $rmonerror = 0;
6906             } elsif (m/^--no-chase-dsc-distro$/s) {
6907                 push @ropts, $_;
6908                 $chase_dsc_distro = 0;
6909             } elsif (m/^--overwrite$/s) {
6910                 push @ropts, $_;
6911                 $overwrite_version = '';
6912             } elsif (m/^--overwrite=(.+)$/s) {
6913                 push @ropts, $_;
6914                 $overwrite_version = $1;
6915             } elsif (m/^--delayed=(\d+)$/s) {
6916                 push @ropts, $_;
6917                 push @dput, $_;
6918             } elsif (my ($k,$v) =
6919                      m/^--save-(dgit-view)=(.+)$/s ||
6920                      m/^--(dgit-view)-save=(.+)$/s
6921                      ) {
6922                 push @ropts, $_;
6923                 $v =~ s#^(?!refs/)#refs/heads/#;
6924                 $internal_object_save{$k} = $v;
6925             } elsif (m/^--(no-)?rm-old-changes$/s) {
6926                 push @ropts, $_;
6927                 $rmchanges = !$1;
6928             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6929                 push @ropts, $_;
6930                 push @deliberatelies, $&;
6931             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6932                 push @ropts, $&;
6933                 $forceopts{$1} = 1;
6934                 $_='';
6935             } elsif (m/^--force-/) {
6936                 print STDERR
6937                     "$us: warning: ignoring unknown force option $_\n";
6938                 $_='';
6939             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6940                 # undocumented, for testing
6941                 push @ropts, $_;
6942                 $tagformat_want = [ $1, 'command line', 1 ];
6943                 # 1 menas overrides distro configuration
6944             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6945                 # undocumented, for testing
6946                 push @ropts, $_;
6947                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6948                 # ^ it's supposed to be an array ref
6949             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6950                 $val = $2 ? $' : undef; #';
6951                 $valopt->($oi->{Long});
6952             } elsif ($funcopts_long{$_}) {
6953                 push @ropts, $_;
6954                 $funcopts_long{$_}();
6955             } else {
6956                 badusage "unknown long option \`$_'";
6957             }
6958         } else {
6959             while (m/^-./s) {
6960                 if (s/^-n/-/) {
6961                     push @ropts, $&;
6962                     $dryrun_level=2;
6963                 } elsif (s/^-L/-/) {
6964                     push @ropts, $&;
6965                     $dryrun_level=1;
6966                 } elsif (s/^-h/-/) {
6967                     cmd_help();
6968                 } elsif (s/^-D/-/) {
6969                     push @ropts, $&;
6970                     $debuglevel++;
6971                     enabledebug();
6972                 } elsif (s/^-N/-/) {
6973                     push @ropts, $&;
6974                     $new_package=1;
6975                 } elsif (m/^-m/) {
6976                     push @ropts, $&;
6977                     push @changesopts, $_;
6978                     $_ = '';
6979                 } elsif (s/^-wn$//s) {
6980                     push @ropts, $&;
6981                     $cleanmode = 'none';
6982                 } elsif (s/^-wg$//s) {
6983                     push @ropts, $&;
6984                     $cleanmode = 'git';
6985                 } elsif (s/^-wgf$//s) {
6986                     push @ropts, $&;
6987                     $cleanmode = 'git-ff';
6988                 } elsif (s/^-wd$//s) {
6989                     push @ropts, $&;
6990                     $cleanmode = 'dpkg-source';
6991                 } elsif (s/^-wdd$//s) {
6992                     push @ropts, $&;
6993                     $cleanmode = 'dpkg-source-d';
6994                 } elsif (s/^-wc$//s) {
6995                     push @ropts, $&;
6996                     $cleanmode = 'check';
6997                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6998                     push @git, '-c', $&;
6999                     $gitcfgs{cmdline}{$1} = [ $2 ];
7000                 } elsif (s/^-c([^=]+)$//s) {
7001                     push @git, '-c', $&;
7002                     $gitcfgs{cmdline}{$1} = [ 'true' ];
7003                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
7004                     $val = $'; #';
7005                     $val = undef unless length $val;
7006                     $valopt->($oi->{Short});
7007                     $_ = '';
7008                 } else {
7009                     badusage "unknown short option \`$_'";
7010                 }
7011             }
7012         }
7013     }
7014 }
7015
7016 sub check_env_sanity () {
7017     my $blocked = new POSIX::SigSet;
7018     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
7019
7020     eval {
7021         foreach my $name (qw(PIPE CHLD)) {
7022             my $signame = "SIG$name";
7023             my $signum = eval "POSIX::$signame" // die;
7024             die "$signame is set to something other than SIG_DFL\n"
7025                 if defined $SIG{$name} and $SIG{$name} ne 'DEFAULT';
7026             $blocked->ismember($signum) and
7027                 die "$signame is blocked\n";
7028         }
7029     };
7030     return unless $@;
7031     chomp $@;
7032     fail <<END;
7033 On entry to dgit, $@
7034 This is a bug produced by something in in your execution environment.
7035 Giving up.
7036 END
7037 }
7038
7039
7040 sub parseopts_late_defaults () {
7041     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
7042         if defined $idistro;
7043     $isuite //= cfg('dgit.default.default-suite');
7044
7045     foreach my $k (keys %opts_opt_map) {
7046         my $om = $opts_opt_map{$k};
7047
7048         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
7049         if (defined $v) {
7050             badcfg "cannot set command for $k"
7051                 unless length $om->[0];
7052             $om->[0] = $v;
7053         }
7054
7055         foreach my $c (access_cfg_cfgs("opts-$k")) {
7056             my @vl =
7057                 map { $_ ? @$_ : () }
7058                 map { $gitcfgs{$_}{$c} }
7059                 reverse @gitcfgsources;
7060             printdebug "CL $c ", (join " ", map { shellquote } @vl),
7061                 "\n" if $debuglevel >= 4;
7062             next unless @vl;
7063             badcfg "cannot configure options for $k"
7064                 if $opts_opt_cmdonly{$k};
7065             my $insertpos = $opts_cfg_insertpos{$k};
7066             @$om = ( @$om[0..$insertpos-1],
7067                      @vl,
7068                      @$om[$insertpos..$#$om] );
7069         }
7070     }
7071
7072     if (!defined $rmchanges) {
7073         local $access_forpush;
7074         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
7075     }
7076
7077     if (!defined $quilt_mode) {
7078         local $access_forpush;
7079         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
7080             // access_cfg('quilt-mode', 'RETURN-UNDEF')
7081             // 'linear';
7082         $quilt_mode =~ m/^($quilt_modes_re)$/
7083             or badcfg "unknown quilt-mode \`$quilt_mode'";
7084         $quilt_mode = $1;
7085     }
7086
7087     foreach my $moc (@modeopt_cfgs) {
7088         local $access_forpush;
7089         my $vr = $moc->{Var};
7090         next if defined $$vr;
7091         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
7092         my $v = $moc->{Vals}{$$vr};
7093         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
7094         $$vr = $v;
7095     }
7096
7097     fail "dgit: --include-dirty is not supported in split view quilt mode"
7098         if $split_brain && $includedirty;
7099
7100     if (!defined $cleanmode) {
7101         local $access_forpush;
7102         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
7103         $cleanmode //= 'dpkg-source';
7104
7105         badcfg "unknown clean-mode \`$cleanmode'" unless
7106             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
7107     }
7108
7109     $buildproductsdir //= access_cfg('build-products-dir', 'RETURN-UNDEF');
7110     $buildproductsdir //= '..';
7111     $bpd_glob = $buildproductsdir;
7112     $bpd_glob =~ s#[][\\{}*?~]#\\$&#g;
7113 }
7114
7115 if ($ENV{$fakeeditorenv}) {
7116     git_slurp_config();
7117     quilt_fixup_editor();
7118 }
7119
7120 parseopts();
7121 check_env_sanity();
7122
7123 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
7124 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
7125     if $dryrun_level == 1;
7126 if (!@ARGV) {
7127     print STDERR $helpmsg or die $!;
7128     finish 8;
7129 }
7130 $cmd = $subcommand = shift @ARGV;
7131 $cmd =~ y/-/_/;
7132
7133 my $pre_fn = ${*::}{"pre_$cmd"};
7134 $pre_fn->() if $pre_fn;
7135
7136 record_maindir if $invoked_in_git_tree;
7137 git_slurp_config();
7138
7139 my $fn = ${*::}{"cmd_$cmd"};
7140 $fn or badusage "unknown operation $cmd";
7141 $fn->();
7142
7143 finish 0;