dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 $SIG{__WARN__} = sub { die $_[0]; };
  22
  23 use IO::Handle;
  24 use Data::Dumper;
  25 use LWP::UserAgent;
  26 use Dpkg::Control::Hash;
  27 use File::Path;
  28 use File::Temp qw(tempdir);
  29 use File::Basename;
  30 use Dpkg::Version;
  31 use POSIX;
  32 use IPC::Open2;
  33 use Digest::SHA;
  34 use Digest::MD5;
  35
  36 use Debian::Dgit;
  37
  38 our $our_version = 'UNRELEASED'; ###substituted###
  39
  40 our $rpushprotovsn = 2;
  41
  42 our $isuite = 'unstable';
  43 our $idistro;
  44 our $package;
  45 our @ropts;
  46
  47 our $sign = 1;
  48 our $dryrun_level = 0;
  49 our $changesfile;
  50 our $buildproductsdir = '..';
  51 our $new_package = 0;
  52 our $ignoredirty = 0;
  53 our $rmonerror = 1;
  54 our @deliberatelies;
  55 our %supersedes;
  56 our $existing_package = 'dpkg';
  57 our $cleanmode = 'dpkg-source';
  58 our $changes_since_version;
  59 our $quilt_mode;
  60 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  61 our $we_are_responder;
  62 our $initiator_tempdir;
  63
  64 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  65
  66 our $suite_re = '[-+.0-9a-z]+';
  67
  68 our (@git) = qw(git);
  69 our (@dget) = qw(dget);
  70 our (@curl) = qw(curl -f);
  71 our (@dput) = qw(dput);
  72 our (@debsign) = qw(debsign);
  73 our (@gpg) = qw(gpg);
  74 our (@sbuild) = qw(sbuild -A);
  75 our (@ssh) = 'ssh';
  76 our (@dgit) = qw(dgit);
  77 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  78 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  79 our (@dpkggenchanges) = qw(dpkg-genchanges);
  80 our (@mergechanges) = qw(mergechanges -f);
  81 our (@changesopts) = ('');
  82
  83 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  84                      'curl' => \@curl,
  85                      'dput' => \@dput,
  86                      'debsign' => \@debsign,
  87                      'gpg' => \@gpg,
  88                      'sbuild' => \@sbuild,
  89                      'ssh' => \@ssh,
  90                      'dgit' => \@dgit,
  91                      'dpkg-source' => \@dpkgsource,
  92                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  93                      'dpkg-genchanges' => \@dpkggenchanges,
  94                      'ch' => \@changesopts,
  95                      'mergechanges' => \@mergechanges);
  96
  97 our %opts_opt_cmdonly = ('gpg' => 1);
  98
  99 our $keyid;
 100
 101 autoflush STDOUT 1;
 102
 103 our $remotename = 'dgit';
 104 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 105 our $csuite;
 106 our $instead_distro;
 107
 108 sub lbranch () { return "$branchprefix/$csuite"; }
 109 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 110 sub lref () { return "refs/heads/".lbranch(); }
 111 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 112 sub rrref () { return server_ref($csuite); }
 113
 114 sub stripepoch ($) {
 115     my ($vsn) = @_;
 116     $vsn =~ s/^\d+\://;
 117     return $vsn;
 118 }
 119
 120 sub srcfn ($$) {
 121     my ($vsn,$sfx) = @_;
 122     return "${package}_".(stripepoch $vsn).$sfx
 123 }
 124
 125 sub dscfn ($) {
 126     my ($vsn) = @_;
 127     return srcfn($vsn,".dsc");
 128 }
 129
 130 our $us = 'dgit';
 131 initdebug('');
 132
 133 our @end;
 134 END {
 135     local ($?);
 136     foreach my $f (@end) {
 137         eval { $f->(); };
 138         warn "$us: cleanup: $@" if length $@;
 139     }
 140 };
 141
 142 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 143
 144 sub no_such_package () {
 145     print STDERR "$us: package $package does not exist in suite $isuite\n";
 146     exit 4;
 147 }
 148
 149 sub fetchspec () {
 150     local $csuite = '*';
 151     return  "+".rrref().":".lrref();
 152 }
 153
 154 sub changedir ($) {
 155     my ($newdir) = @_;
 156     printdebug "CD $newdir\n";
 157     chdir $newdir or die "chdir: $newdir: $!";
 158 }
 159
 160 sub deliberately ($) {
 161     my ($enquiry) = @_;
 162     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 163 }
 164
 165 #---------- remote protocol support, common ----------
 166
 167 # remote push initiator/responder protocol:
 168 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 169 #
 170 #  > file parsed-changelog
 171 #  [indicates that output of dpkg-parsechangelog follows]
 172 #  > data-block NBYTES
 173 #  > [NBYTES bytes of data (no newline)]
 174 #  [maybe some more blocks]
 175 #  > data-end
 176 #
 177 #  > file dsc
 178 #  [etc]
 179 #
 180 #  > file changes
 181 #  [etc]
 182 #
 183 #  > param head HEAD
 184 #
 185 #  > want signed-tag
 186 #  [indicates that signed tag is wanted]
 187 #  < data-block NBYTES
 188 #  < [NBYTES bytes of data (no newline)]
 189 #  [maybe some more blocks]
 190 #  < data-end
 191 #  < files-end
 192 #
 193 #  > want signed-dsc-changes
 194 #  < data-block NBYTES    [transfer of signed dsc]
 195 #  [etc]
 196 #  < data-block NBYTES    [transfer of signed changes]
 197 #  [etc]
 198 #  < files-end
 199 #
 200 #  > complete
 201
 202 our $i_child_pid;
 203
 204 sub i_child_report () {
 205     # Sees if our child has died, and reap it if so.  Returns a string
 206     # describing how it died if it failed, or undef otherwise.
 207     return undef unless $i_child_pid;
 208     my $got = waitpid $i_child_pid, WNOHANG;
 209     return undef if $got <= 0;
 210     die unless $got == $i_child_pid;
 211     $i_child_pid = undef;
 212     return undef unless $?;
 213     return "build host child ".waitstatusmsg();
 214 }
 215
 216 sub badproto ($$) {
 217     my ($fh, $m) = @_;
 218     fail "connection lost: $!" if $fh->error;
 219     fail "protocol violation; $m not expected";
 220 }
 221
 222 sub badproto_badread ($$) {
 223     my ($fh, $wh) = @_;
 224     fail "connection lost: $!" if $!;
 225     my $report = i_child_report();
 226     fail $report if defined $report;
 227     badproto $fh, "eof (reading $wh)";
 228 }
 229
 230 sub protocol_expect (&$) {
 231     my ($match, $fh) = @_;
 232     local $_;
 233     $_ = <$fh>;
 234     defined && chomp or badproto_badread $fh, "protocol message";
 235     if (wantarray) {
 236         my @r = &$match;
 237         return @r if @r;
 238     } else {
 239         my $r = &$match;
 240         return $r if $r;
 241     }
 242     badproto $fh, "\`$_'";
 243 }
 244
 245 sub protocol_send_file ($$) {
 246     my ($fh, $ourfn) = @_;
 247     open PF, "<", $ourfn or die "$ourfn: $!";
 248     for (;;) {
 249         my $d;
 250         my $got = read PF, $d, 65536;
 251         die "$ourfn: $!" unless defined $got;
 252         last if !$got;
 253         print $fh "data-block ".length($d)."\n" or die $!;
 254         print $fh $d or die $!;
 255     }
 256     PF->error and die "$ourfn $!";
 257     print $fh "data-end\n" or die $!;
 258     close PF;
 259 }
 260
 261 sub protocol_read_bytes ($$) {
 262     my ($fh, $nbytes) = @_;
 263     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 264     my $d;
 265     my $got = read $fh, $d, $nbytes;
 266     $got==$nbytes or badproto_badread $fh, "data block";
 267     return $d;
 268 }
 269
 270 sub protocol_receive_file ($$) {
 271     my ($fh, $ourfn) = @_;
 272     printdebug "() $ourfn\n";
 273     open PF, ">", $ourfn or die "$ourfn: $!";
 274     for (;;) {
 275         my ($y,$l) = protocol_expect {
 276             m/^data-block (.*)$/ ? (1,$1) :
 277             m/^data-end$/ ? (0,) :
 278             ();
 279         } $fh;
 280         last unless $y;
 281         my $d = protocol_read_bytes $fh, $l;
 282         print PF $d or die $!;
 283     }
 284     close PF or die $!;
 285 }
 286
 287 #---------- remote protocol support, responder ----------
 288
 289 sub responder_send_command ($) {
 290     my ($command) = @_;
 291     return unless $we_are_responder;
 292     # called even without $we_are_responder
 293     printdebug ">> $command\n";
 294     print PO $command, "\n" or die $!;
 295 }
 296
 297 sub responder_send_file ($$) {
 298     my ($keyword, $ourfn) = @_;
 299     return unless $we_are_responder;
 300     printdebug "]] $keyword $ourfn\n";
 301     responder_send_command "file $keyword";
 302     protocol_send_file \*PO, $ourfn;
 303 }
 304
 305 sub responder_receive_files ($@) {
 306     my ($keyword, @ourfns) = @_;
 307     die unless $we_are_responder;
 308     printdebug "[[ $keyword @ourfns\n";
 309     responder_send_command "want $keyword";
 310     foreach my $fn (@ourfns) {
 311         protocol_receive_file \*PI, $fn;
 312     }
 313     printdebug "[[\$\n";
 314     protocol_expect { m/^files-end$/ } \*PI;
 315 }
 316
 317 #---------- remote protocol support, initiator ----------
 318
 319 sub initiator_expect (&) {
 320     my ($match) = @_;
 321     protocol_expect { &$match } \*RO;
 322 }
 323
 324 #---------- end remote code ----------
 325
 326 sub progress {
 327     if ($we_are_responder) {
 328         my $m = join '', @_;
 329         responder_send_command "progress ".length($m) or die $!;
 330         print PO $m or die $!;
 331     } else {
 332         print @_, "\n";
 333     }
 334 }
 335
 336 our $ua;
 337
 338 sub url_get {
 339     if (!$ua) {
 340         $ua = LWP::UserAgent->new();
 341         $ua->env_proxy;
 342     }
 343     my $what = $_[$#_];
 344     progress "downloading $what...";
 345     my $r = $ua->get(@_) or die $!;
 346     return undef if $r->code == 404;
 347     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 348     return $r->decoded_content(charset => 'none');
 349 }
 350
 351 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 352
 353 sub runcmd {
 354     debugcmd "+",@_;
 355     $!=0; $?=0;
 356     failedcmd @_ if system @_;
 357 }
 358
 359 sub act_local () { return $dryrun_level <= 1; }
 360 sub act_scary () { return !$dryrun_level; }
 361
 362 sub printdone {
 363     if (!$dryrun_level) {
 364         progress "dgit ok: @_";
 365     } else {
 366         progress "would be ok: @_ (but dry run only)";
 367     }
 368 }
 369
 370 sub dryrun_report {
 371     printcmd(\*STDERR,$debugprefix."#",@_);
 372 }
 373
 374 sub runcmd_ordryrun {
 375     if (act_scary()) {
 376         runcmd @_;
 377     } else {
 378         dryrun_report @_;
 379     }
 380 }
 381
 382 sub runcmd_ordryrun_local {
 383     if (act_local()) {
 384         runcmd @_;
 385     } else {
 386         dryrun_report @_;
 387     }
 388 }
 389
 390 sub shell_cmd {
 391     my ($first_shell, @cmd) = @_;
 392     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 393 }
 394
 395 our $helpmsg = <<END;
 396 main usages:
 397   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 398   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 399   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 400   dgit [dgit-opts] push [dgit-opts] [suite]
 401   dgit [dgit-opts] rpush build-host:build-dir ...
 402 important dgit options:
 403   -k<keyid>           sign tag and package with <keyid> instead of default
 404   --dry-run -n        do not change anything, but go through the motions
 405   --damp-run -L       like --dry-run but make local changes, without signing
 406   --new -N            allow introducing a new package
 407   --debug -D          increase debug level
 408   -c<name>=<value>    set git config option (used directly by dgit too)
 409 END
 410
 411 our $later_warning_msg = <<END;
 412 Perhaps the upload is stuck in incoming.  Using the version from git.
 413 END
 414
 415 sub badusage {
 416     print STDERR "$us: @_\n", $helpmsg or die $!;
 417     exit 8;
 418 }
 419
 420 sub nextarg {
 421     @ARGV or badusage "too few arguments";
 422     return scalar shift @ARGV;
 423 }
 424
 425 sub cmd_help () {
 426     print $helpmsg or die $!;
 427     exit 0;
 428 }
 429
 430 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 431
 432 our %defcfg = ('dgit.default.distro' => 'debian',
 433                'dgit.default.username' => '',
 434                'dgit.default.archive-query-default-component' => 'main',
 435                'dgit.default.ssh' => 'ssh',
 436                'dgit.default.archive-query' => 'madison:',
 437                'dgit.default.sshpsql-dbname' => 'service=projectb',
 438                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 439                'dgit-distro.debian.git-host' => 'dgit-git.debian.net',
 440                'dgit-distro.debian.git-user-force' => 'dgit',
 441                'dgit-distro.debian.git-proto' => 'git+ssh://',
 442                'dgit-distro.debian.git-path' => '/dgit/debian/repos',
 443                'dgit-distro.debian.git-check' => 'ssh-cmd',
 444  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 445  'dgit-distro.debian.archive-query-tls-key',
 446     '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 447                'dgit-distro.debian.diverts.alioth' => '/alioth',
 448                'dgit-distro.debian/alioth.git-host' => 'git.debian.org',
 449                'dgit-distro.debian/alioth.git-user-force' => '',
 450                'dgit-distro.debian/alioth.git-proto' => 'git+ssh://',
 451                'dgit-distro.debian/alioth.git-path' => '/git/dgit-repos/repos',
 452                'dgit-distro.debian/alioth.git-create' => 'ssh-cmd',
 453                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 454                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 455  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 456  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 457                'dgit-distro.ubuntu.git-check' => 'false',
 458  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 459                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 460                'dgit-distro.test-dummy.username' => "alice",
 461                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 462                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 463                'dgit-distro.test-dummy.git-url' => "$td/git",
 464                'dgit-distro.test-dummy.git-host' => "git",
 465                'dgit-distro.test-dummy.git-path' => "$td/git",
 466                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 467                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 468                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 469                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 470                );
 471
 472 sub cfg {
 473     foreach my $c (@_) {
 474         return undef if $c =~ /RETURN-UNDEF/;
 475         my @cmd = (@git, qw(config --), $c);
 476         my $v;
 477         {
 478             local ($debuglevel) = $debuglevel-2;
 479             $v = cmdoutput_errok @cmd;
 480         };
 481         if ($?==0) {
 482             return $v;
 483         } elsif ($?!=256) {
 484             failedcmd @cmd;
 485         }
 486         my $dv = $defcfg{$c};
 487         return $dv if defined $dv;
 488     }
 489     badcfg "need value for one of: @_\n".
 490         "$us: distro or suite appears not to be (properly) supported";
 491 }
 492
 493 sub access_basedistro () {
 494     if (defined $idistro) {
 495         return $idistro;
 496     } else {
 497         return cfg("dgit-suite.$isuite.distro",
 498                    "dgit.default.distro");
 499     }
 500 }
 501
 502 sub access_quirk () {
 503     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 504     my $basedistro = access_basedistro();
 505     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 506                               'RETURN-UNDEF');
 507     if (defined $backports_quirk) {
 508         my $re = $backports_quirk;
 509         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 510         $re =~ s/\*/.*/g;
 511         $re =~ s/\%/([-0-9a-z_]+)/
 512             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 513         if ($isuite =~ m/^$re$/) {
 514             return ('backports',"$basedistro-backports",$1);
 515         }
 516     }
 517     return ('none',undef);
 518 }
 519
 520 sub access_distros () {
 521     # Returns list of distros to try, in order
 522     #
 523     # We want to try:
 524     #    0. `instead of' distro name(s) we have been pointed to
 525     #    1. the access_quirk distro, if any
 526     #    2a. the user's specified distro, or failing that  } basedistro
 527     #    2b. the distro calculated from the suite          }
 528     my @l = access_basedistro();
 529
 530     my (undef,$quirkdistro) = access_quirk();
 531     unshift @l, $quirkdistro;
 532     unshift @l, $instead_distro;
 533     return grep { defined } @l;
 534 }
 535
 536 sub access_cfg (@) {
 537     my (@keys) = @_;
 538     my @cfgs;
 539     # The nesting of these loops determines the search order.  We put
 540     # the key loop on the outside so that we search all the distros
 541     # for each key, before going on to the next key.  That means that
 542     # if access_cfg is called with a more specific, and then a less
 543     # specific, key, an earlier distro can override the less specific
 544     # without necessarily overriding any more specific keys.  (If the
 545     # distro wants to override the more specific keys it can simply do
 546     # so; whereas if we did the loop the other way around, it would be
 547     # impossible to for an earlier distro to override a less specific
 548     # key but not the more specific ones without restating the unknown
 549     # values of the more specific keys.
 550     my @realkeys;
 551     my @rundef;
 552     # We have to deal with RETURN-UNDEF specially, so that we don't
 553     # terminate the search prematurely.
 554     foreach (@keys) {
 555         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 556         push @realkeys, $_
 557     }
 558     foreach my $d (access_distros()) {
 559         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 560     }
 561     push @cfgs, map { "dgit.default.$_" } @realkeys;
 562     push @cfgs, @rundef;
 563     my $value = cfg(@cfgs);
 564     return $value;
 565 }
 566
 567 sub string_to_ssh ($) {
 568     my ($spec) = @_;
 569     if ($spec =~ m/\s/) {
 570         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 571     } else {
 572         return ($spec);
 573     }
 574 }
 575
 576 sub access_cfg_ssh () {
 577     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 578     if (!defined $gitssh) {
 579         return @ssh;
 580     } else {
 581         return string_to_ssh $gitssh;
 582     }
 583 }
 584
 585 sub access_runeinfo ($) {
 586     my ($info) = @_;
 587     return ": dgit ".access_basedistro()." $info ;";
 588 }
 589
 590 sub access_someuserhost ($) {
 591     my ($some) = @_;
 592     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 593     defined($user) && length($user) or
 594         $user = access_cfg("$some-user",'username');
 595     my $host = access_cfg("$some-host");
 596     return length($user) ? "$user\@$host" : $host;
 597 }
 598
 599 sub access_gituserhost () {
 600     return access_someuserhost('git');
 601 }
 602
 603 sub access_giturl (;$) {
 604     my ($optional) = @_;
 605     my $url = access_cfg('git-url','RETURN-UNDEF');
 606     if (!defined $url) {
 607         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 608         return undef unless defined $proto;
 609         $url =
 610             $proto.
 611             access_gituserhost().
 612             access_cfg('git-path');
 613     }
 614     return "$url/$package.git";
 615 }
 616
 617 sub parsecontrolfh ($$;$) {
 618     my ($fh, $desc, $allowsigned) = @_;
 619     our $dpkgcontrolhash_noissigned;
 620     my $c;
 621     for (;;) {
 622         my %opts = ('name' => $desc);
 623         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 624         $c = Dpkg::Control::Hash->new(%opts);
 625         $c->parse($fh,$desc) or die "parsing of $desc failed";
 626         last if $allowsigned;
 627         last if $dpkgcontrolhash_noissigned;
 628         my $issigned= $c->get_option('is_pgp_signed');
 629         if (!defined $issigned) {
 630             $dpkgcontrolhash_noissigned= 1;
 631             seek $fh, 0,0 or die "seek $desc: $!";
 632         } elsif ($issigned) {
 633             fail "control file $desc is (already) PGP-signed. ".
 634                 " Note that dgit push needs to modify the .dsc and then".
 635                 " do the signature itself";
 636         } else {
 637             last;
 638         }
 639     }
 640     return $c;
 641 }
 642
 643 sub parsecontrol {
 644     my ($file, $desc) = @_;
 645     my $fh = new IO::Handle;
 646     open $fh, '<', $file or die "$file: $!";
 647     my $c = parsecontrolfh($fh,$desc);
 648     $fh->error and die $!;
 649     close $fh;
 650     return $c;
 651 }
 652
 653 sub getfield ($$) {
 654     my ($dctrl,$field) = @_;
 655     my $v = $dctrl->{$field};
 656     return $v if defined $v;
 657     fail "missing field $field in ".$v->get_option('name');
 658 }
 659
 660 sub parsechangelog {
 661     my $c = Dpkg::Control::Hash->new();
 662     my $p = new IO::Handle;
 663     my @cmd = (qw(dpkg-parsechangelog), @_);
 664     open $p, '-|', @cmd or die $!;
 665     $c->parse($p);
 666     $?=0; $!=0; close $p or failedcmd @cmd;
 667     return $c;
 668 }
 669
 670 sub git_get_ref ($) {
 671     my ($refname) = @_;
 672     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 673     if (!defined $got) {
 674         $?==256 or fail "git show-ref failed (status $?)";
 675         printdebug "ref $refname= [show-ref exited 1]\n";
 676         return '';
 677     }
 678     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 679         printdebug "ref $refname=$1\n";
 680         return $1;
 681     } else {
 682         printdebug "ref $refname= [no match]\n";
 683         return '';
 684     }
 685 }
 686
 687 sub must_getcwd () {
 688     my $d = getcwd();
 689     defined $d or fail "getcwd failed: $!";
 690     return $d;
 691 }
 692
 693 our %rmad;
 694
 695 sub archive_query ($) {
 696     my ($method) = @_;
 697     my $query = access_cfg('archive-query','RETURN-UNDEF');
 698     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 699     my $proto = $1;
 700     my $data = $'; #';
 701     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 702 }
 703
 704 sub pool_dsc_subpath ($$) {
 705     my ($vsn,$component) = @_; # $package is implict arg
 706     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 707     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 708 }
 709
 710 #---------- `ftpmasterapi' archive query method (nascent) ----------
 711
 712 sub archive_api_query_cmd ($) {
 713     my ($subpath) = @_;
 714     my @cmd = qw(curl -sS);
 715     my $url = access_cfg('archive-query-url');
 716     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 717         my $host = $1;
 718         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF');
 719         foreach my $key (split /\:/, $keys) {
 720             $key =~ s/\%HOST\%/$host/g;
 721             if (!stat $key) {
 722                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 723                 next;
 724             }
 725             push @cmd, "--ca-certificate=$key", "--ca-directory=/dev/enoent";
 726             last;
 727         }
 728     }
 729     push @cmd, $url.$subpath;
 730     return @cmd;
 731 }
 732
 733 sub api_query ($$) {
 734     use JSON;
 735     my ($data, $subpath) = @_;
 736     badcfg "ftpmasterapi archive query method takes no data part"
 737         if length $data;
 738     my @cmd = archive_api_query_cmd($subpath);
 739     my $json = cmdoutput @cmd;
 740     return decode_json($json);
 741 }
 742
 743 sub canonicalise_suite_ftpmasterapi () {
 744     my ($proto,$data) = @_;
 745     my $suites = api_query($data, 'suites');
 746     my @matched;
 747     foreach my $entry (@$suites) {
 748         next unless grep {
 749             my $v = $entry->{$_};
 750             defined $v && $v eq $isuite;
 751         } qw(codename name);
 752         push @matched, $entry;
 753     }
 754     fail "unknown suite $isuite" unless @matched;
 755     my $cn;
 756     eval {
 757         @matched==1 or die "multiple matches for suite $isuite\n";
 758         $cn = "$matched[0]{codename}";
 759         defined $cn or die "suite $isuite info has no codename\n";
 760         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 761     };
 762     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 763         if length $@;
 764     return $cn;
 765 }
 766
 767 sub archive_query_ftpmasterapi () {
 768     my ($proto,$data) = @_;
 769     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 770     my @rows;
 771     my $digester = Digest::SHA->new(256);
 772     foreach my $entry (@$info) {
 773         eval {
 774             my $vsn = "$entry->{version}";
 775             my ($ok,$msg) = version_check $vsn;
 776             die "bad version: $msg\n" unless $ok;
 777             my $component = "$entry->{component}";
 778             $component =~ m/^$component_re$/ or die "bad component";
 779             my $filename = "$entry->{filename}";
 780             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 781                 or die "bad filename";
 782             my $sha256sum = "$entry->{sha256sum}";
 783             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 784             push @rows, [ $vsn, "/pool/$component/$filename",
 785                           $digester, $sha256sum ];
 786         };
 787         die "bad ftpmaster api response: $@\n".Dumper($entry)
 788             if length $@;
 789     }
 790     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 791     return @rows;
 792 }
 793
 794 #---------- `madison' archive query method ----------
 795
 796 sub archive_query_madison {
 797     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 798 }
 799
 800 sub madison_get_parse {
 801     my ($proto,$data) = @_;
 802     die unless $proto eq 'madison';
 803     if (!length $data) {
 804         $data= access_cfg('madison-distro','RETURN-UNDEF');
 805         $data //= access_basedistro();
 806     }
 807     $rmad{$proto,$data,$package} ||= cmdoutput
 808         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 809     my $rmad = $rmad{$proto,$data,$package};
 810
 811     my @out;
 812     foreach my $l (split /\n/, $rmad) {
 813         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 814                   \s*( [^ \t|]+ )\s* \|
 815                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 816                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 817         $1 eq $package or die "$rmad $package ?";
 818         my $vsn = $2;
 819         my $newsuite = $3;
 820         my $component;
 821         if (defined $4) {
 822             $component = $4;
 823         } else {
 824             $component = access_cfg('archive-query-default-component');
 825         }
 826         $5 eq 'source' or die "$rmad ?";
 827         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 828     }
 829     return sort { -version_compare($a->[0],$b->[0]); } @out;
 830 }
 831
 832 sub canonicalise_suite_madison {
 833     # madison canonicalises for us
 834     my @r = madison_get_parse(@_);
 835     @r or fail
 836         "unable to canonicalise suite using package $package".
 837         " which does not appear to exist in suite $isuite;".
 838         " --existing-package may help";
 839     return $r[0][2];
 840 }
 841
 842 #---------- `sshpsql' archive query method ----------
 843
 844 sub sshpsql ($$$) {
 845     my ($data,$runeinfo,$sql) = @_;
 846     if (!length $data) {
 847         $data= access_someuserhost('sshpsql').':'.
 848             access_cfg('sshpsql-dbname');
 849     }
 850     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 851     my ($userhost,$dbname) = ($`,$'); #';
 852     my @rows;
 853     my @cmd = (access_cfg_ssh, $userhost,
 854                access_runeinfo("ssh-psql $runeinfo").
 855                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 856                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 857     debugcmd "|",@cmd;
 858     open P, "-|", @cmd or die $!;
 859     while (<P>) {
 860         chomp or die;
 861         printdebug("$debugprefix>|$_|\n");
 862         push @rows, $_;
 863     }
 864     $!=0; $?=0; close P or failedcmd @cmd;
 865     @rows or die;
 866     my $nrows = pop @rows;
 867     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 868     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 869     @rows = map { [ split /\|/, $_ ] } @rows;
 870     my $ncols = scalar @{ shift @rows };
 871     die if grep { scalar @$_ != $ncols } @rows;
 872     return @rows;
 873 }
 874
 875 sub sql_injection_check {
 876     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
 877 }
 878
 879 sub archive_query_sshpsql ($$) {
 880     my ($proto,$data) = @_;
 881     sql_injection_check $isuite, $package;
 882     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
 883         SELECT source.version, component.name, files.filename, files.sha256sum
 884           FROM source
 885           JOIN src_associations ON source.id = src_associations.source
 886           JOIN suite ON suite.id = src_associations.suite
 887           JOIN dsc_files ON dsc_files.source = source.id
 888           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 889           JOIN component ON component.id = files_archive_map.component_id
 890           JOIN files ON files.id = dsc_files.file
 891          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 892            AND source.source='$package'
 893            AND files.filename LIKE '%.dsc';
 894 END
 895     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 896     my $digester = Digest::SHA->new(256);
 897     @rows = map {
 898         my ($vsn,$component,$filename,$sha256sum) = @$_;
 899         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 900     } @rows;
 901     return @rows;
 902 }
 903
 904 sub canonicalise_suite_sshpsql ($$) {
 905     my ($proto,$data) = @_;
 906     sql_injection_check $isuite;
 907     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
 908         SELECT suite.codename
 909           FROM suite where suite_name='$isuite' or codename='$isuite';
 910 END
 911     @rows = map { $_->[0] } @rows;
 912     fail "unknown suite $isuite" unless @rows;
 913     die "ambiguous $isuite: @rows ?" if @rows>1;
 914     return $rows[0];
 915 }
 916
 917 #---------- `dummycat' archive query method ----------
 918
 919 sub canonicalise_suite_dummycat ($$) {
 920     my ($proto,$data) = @_;
 921     my $dpath = "$data/suite.$isuite";
 922     if (!open C, "<", $dpath) {
 923         $!==ENOENT or die "$dpath: $!";
 924         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 925         return $isuite;
 926     }
 927     $!=0; $_ = <C>;
 928     chomp or die "$dpath: $!";
 929     close C;
 930     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 931     return $_;
 932 }
 933
 934 sub archive_query_dummycat ($$) {
 935     my ($proto,$data) = @_;
 936     canonicalise_suite();
 937     my $dpath = "$data/package.$csuite.$package";
 938     if (!open C, "<", $dpath) {
 939         $!==ENOENT or die "$dpath: $!";
 940         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 941         return ();
 942     }
 943     my @rows;
 944     while (<C>) {
 945         next if m/^\#/;
 946         next unless m/\S/;
 947         die unless chomp;
 948         printdebug "dummycat query $csuite $package $dpath | $_\n";
 949         my @row = split /\s+/, $_;
 950         @row==2 or die "$dpath: $_ ?";
 951         push @rows, \@row;
 952     }
 953     C->error and die "$dpath: $!";
 954     close C;
 955     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 956 }
 957
 958 #---------- archive query entrypoints and rest of program ----------
 959
 960 sub canonicalise_suite () {
 961     return if defined $csuite;
 962     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 963     $csuite = archive_query('canonicalise_suite');
 964     if ($isuite ne $csuite) {
 965         progress "canonical suite name for $isuite is $csuite";
 966     }
 967 }
 968
 969 sub get_archive_dsc () {
 970     canonicalise_suite();
 971     my @vsns = archive_query('archive_query');
 972     foreach my $vinfo (@vsns) {
 973         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 974         $dscurl = access_cfg('mirror').$subpath;
 975         $dscdata = url_get($dscurl);
 976         if (!$dscdata) {
 977             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 978             next;
 979         }
 980         if ($digester) {
 981             $digester->reset();
 982             $digester->add($dscdata);
 983             my $got = $digester->hexdigest();
 984             $got eq $digest or
 985                 fail "$dscurl has hash $got but".
 986                     " archive told us to expect $digest";
 987         }
 988         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 989         printdebug Dumper($dscdata) if $debuglevel>1;
 990         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 991         printdebug Dumper($dsc) if $debuglevel>1;
 992         my $fmt = getfield $dsc, 'Format';
 993         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 994         $dsc_checked = !!$digester;
 995         return;
 996     }
 997     $dsc = undef;
 998 }
 999
1000 sub check_for_git ();
1001 sub check_for_git () {
1002     # returns 0 or 1
1003     my $how = access_cfg('git-check');
1004     if ($how eq 'ssh-cmd') {
1005         my @cmd =
1006             (access_cfg_ssh, access_gituserhost(),
1007              access_runeinfo("git-check $package").
1008              " set -e; cd ".access_cfg('git-path').";".
1009              " if test -d $package.git; then echo 1; else echo 0; fi");
1010         my $r= cmdoutput @cmd;
1011         if ($r =~ m/^divert (\w+)$/) {
1012             my $divert=$1;
1013             my ($usedistro,) = access_distros();
1014             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1015             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1016             printdebug "diverting $divert so using distro $instead_distro\n";
1017             return check_for_git();
1018         }
1019         failedcmd @cmd unless $r =~ m/^[01]$/;
1020         return $r+0;
1021     } elsif ($how eq 'true') {
1022         return 1;
1023     } elsif ($how eq 'false') {
1024         return 0;
1025     } else {
1026         badcfg "unknown git-check \`$how'";
1027     }
1028 }
1029
1030 sub create_remote_git_repo () {
1031     my $how = access_cfg('git-create');
1032     if ($how eq 'ssh-cmd') {
1033         runcmd_ordryrun
1034             (access_cfg_ssh, access_gituserhost(),
1035              access_runeinfo("git-create $package").
1036              "set -e; cd ".access_cfg('git-path').";".
1037              " cp -a _template $package.git");
1038     } elsif ($how eq 'true') {
1039         # nothing to do
1040     } else {
1041         badcfg "unknown git-create \`$how'";
1042     }
1043 }
1044
1045 our ($dsc_hash,$lastpush_hash);
1046
1047 our $ud = '.git/dgit/unpack';
1048
1049 sub prep_ud () {
1050     rmtree($ud);
1051     mkpath '.git/dgit';
1052     mkdir $ud or die $!;
1053 }
1054
1055 sub mktree_in_ud_here () {
1056     runcmd qw(git init -q);
1057     rmtree('.git/objects');
1058     symlink '../../../../objects','.git/objects' or die $!;
1059 }
1060
1061 sub git_write_tree () {
1062     my $tree = cmdoutput @git, qw(write-tree);
1063     $tree =~ m/^\w+$/ or die "$tree ?";
1064     return $tree;
1065 }
1066
1067 sub mktree_in_ud_from_only_subdir () {
1068     # changes into the subdir
1069     my (@dirs) = <*/.>;
1070     die unless @dirs==1;
1071     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1072     my $dir = $1;
1073     changedir $dir;
1074     fail "source package contains .git directory" if stat_exists '.git';
1075     mktree_in_ud_here();
1076     my $format=get_source_format();
1077     if (madformat($format)) {
1078         rmtree '.pc';
1079     }
1080     runcmd @git, qw(add -Af);
1081     my $tree=git_write_tree();
1082     return ($tree,$dir);
1083 }
1084
1085 sub dsc_files_info () {
1086     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1087                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1088                        ['Files',           'Digest::MD5', 'new()']) {
1089         my ($fname, $module, $method) = @$csumi;
1090         my $field = $dsc->{$fname};
1091         next unless defined $field;
1092         eval "use $module; 1;" or die $@;
1093         my @out;
1094         foreach (split /\n/, $field) {
1095             next unless m/\S/;
1096             m/^(\w+) (\d+) (\S+)$/ or
1097                 fail "could not parse .dsc $fname line \`$_'";
1098             my $digester = eval "$module"."->$method;" or die $@;
1099             push @out, {
1100                 Hash => $1,
1101                 Bytes => $2,
1102                 Filename => $3,
1103                 Digester => $digester,
1104             };
1105         }
1106         return @out;
1107     }
1108     fail "missing any supported Checksums-* or Files field in ".
1109         $dsc->get_option('name');
1110 }
1111
1112 sub dsc_files () {
1113     map { $_->{Filename} } dsc_files_info();
1114 }
1115
1116 sub is_orig_file ($;$) {
1117     local ($_) = $_[0];
1118     my $base = $_[1];
1119     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1120     defined $base or return 1;
1121     return $` eq $base;
1122 }
1123
1124 sub make_commit ($) {
1125     my ($file) = @_;
1126     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1127 }
1128
1129 sub clogp_authline ($) {
1130     my ($clogp) = @_;
1131     my $author = getfield $clogp, 'Maintainer';
1132     $author =~ s#,.*##ms;
1133     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1134     my $authline = "$author $date";
1135     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1136         fail "unexpected commit author line format \`$authline'".
1137         " (was generated from changelog Maintainer field)";
1138     return $authline;
1139 }
1140
1141 sub generate_commit_from_dsc () {
1142     prep_ud();
1143     changedir $ud;
1144
1145     foreach my $fi (dsc_files_info()) {
1146         my $f = $fi->{Filename};
1147         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1148
1149         link "../../../$f", $f
1150             or $!==&ENOENT
1151             or die "$f $!";
1152
1153         complete_file_from_dsc('.', $fi);
1154
1155         if (is_orig_file($f)) {
1156             link $f, "../../../../$f"
1157                 or $!==&EEXIST
1158                 or die "$f $!";
1159         }
1160     }
1161
1162     my $dscfn = "$package.dsc";
1163
1164     open D, ">", $dscfn or die "$dscfn: $!";
1165     print D $dscdata or die "$dscfn: $!";
1166     close D or die "$dscfn: $!";
1167     my @cmd = qw(dpkg-source);
1168     push @cmd, '--no-check' if $dsc_checked;
1169     push @cmd, qw(-x --), $dscfn;
1170     runcmd @cmd;
1171
1172     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1173     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1174     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1175     my $authline = clogp_authline $clogp;
1176     my $changes = getfield $clogp, 'Changes';
1177     open C, ">../commit.tmp" or die $!;
1178     print C <<END or die $!;
1179 tree $tree
1180 author $authline
1181 committer $authline
1182
1183 $changes
1184
1185 # imported from the archive
1186 END
1187     close C or die $!;
1188     my $outputhash = make_commit qw(../commit.tmp);
1189     my $cversion = getfield $clogp, 'Version';
1190     progress "synthesised git commit from .dsc $cversion";
1191     if ($lastpush_hash) {
1192         runcmd @git, qw(reset --hard), $lastpush_hash;
1193         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1194         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1195         my $oversion = getfield $oldclogp, 'Version';
1196         my $vcmp =
1197             version_compare($oversion, $cversion);
1198         if ($vcmp < 0) {
1199             # git upload/ is earlier vsn than archive, use archive
1200             open C, ">../commit2.tmp" or die $!;
1201             print C <<END or die $!;
1202 tree $tree
1203 parent $lastpush_hash
1204 parent $outputhash
1205 author $authline
1206 committer $authline
1207
1208 Record $package ($cversion) in archive suite $csuite
1209 END
1210             $outputhash = make_commit qw(../commit2.tmp);
1211         } elsif ($vcmp > 0) {
1212             print STDERR <<END or die $!;
1213
1214 Version actually in archive:    $cversion (older)
1215 Last allegedly pushed/uploaded: $oversion (newer or same)
1216 $later_warning_msg
1217 END
1218             $outputhash = $lastpush_hash;
1219         } else {
1220             $outputhash = $lastpush_hash;
1221         }
1222     }
1223     changedir '../../../..';
1224     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1225             'DGIT_ARCHIVE', $outputhash;
1226     cmdoutput @git, qw(log -n2), $outputhash;
1227     # ... gives git a chance to complain if our commit is malformed
1228     rmtree($ud);
1229     return $outputhash;
1230 }
1231
1232 sub complete_file_from_dsc ($$) {
1233     our ($dstdir, $fi) = @_;
1234     # Ensures that we have, in $dir, the file $fi, with the correct
1235     # contents.  (Downloading it from alongside $dscurl if necessary.)
1236
1237     my $f = $fi->{Filename};
1238     my $tf = "$dstdir/$f";
1239     my $downloaded = 0;
1240
1241     if (stat_exists $tf) {
1242         progress "using existing $f";
1243     } else {
1244         my $furl = $dscurl;
1245         $furl =~ s{/[^/]+$}{};
1246         $furl .= "/$f";
1247         die "$f ?" unless $f =~ m/^${package}_/;
1248         die "$f ?" if $f =~ m#/#;
1249         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1250         next if !act_local();
1251         $downloaded = 1;
1252     }
1253
1254     open F, "<", "$tf" or die "$tf: $!";
1255     $fi->{Digester}->reset();
1256     $fi->{Digester}->addfile(*F);
1257     F->error and die $!;
1258     my $got = $fi->{Digester}->hexdigest();
1259     $got eq $fi->{Hash} or
1260         fail "file $f has hash $got but .dsc".
1261             " demands hash $fi->{Hash} ".
1262             ($downloaded ? "(got wrong file from archive!)"
1263              : "(perhaps you should delete this file?)");
1264 }
1265
1266 sub ensure_we_have_orig () {
1267     foreach my $fi (dsc_files_info()) {
1268         my $f = $fi->{Filename};
1269         next unless is_orig_file($f);
1270         complete_file_from_dsc('..', $fi);
1271     }
1272 }
1273
1274 sub git_fetch_us () {
1275     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1276 }
1277
1278 sub fetch_from_archive () {
1279     # ensures that lrref() is what is actually in the archive,
1280     #  one way or another
1281     get_archive_dsc();
1282
1283     if ($dsc) {
1284         foreach my $field (@ourdscfield) {
1285             $dsc_hash = $dsc->{$field};
1286             last if defined $dsc_hash;
1287         }
1288         if (defined $dsc_hash) {
1289             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1290             $dsc_hash = $&;
1291             progress "last upload to archive specified git hash";
1292         } else {
1293             progress "last upload to archive has NO git hash";
1294         }
1295     } else {
1296         progress "no version available from the archive";
1297     }
1298
1299     $lastpush_hash = git_get_ref(lrref());
1300     printdebug "previous reference hash=$lastpush_hash\n";
1301     my $hash;
1302     if (defined $dsc_hash) {
1303         fail "missing remote git history even though dsc has hash -".
1304             " could not find ref ".lrref().
1305             " (should have been fetched from ".access_giturl()."#".rrref().")"
1306             unless $lastpush_hash;
1307         $hash = $dsc_hash;
1308         ensure_we_have_orig();
1309         if ($dsc_hash eq $lastpush_hash) {
1310         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1311             print STDERR <<END or die $!;
1312
1313 Git commit in archive is behind the last version allegedly pushed/uploaded.
1314 Commit referred to by archive:  $dsc_hash
1315 Last allegedly pushed/uploaded: $lastpush_hash
1316 $later_warning_msg
1317 END
1318             $hash = $lastpush_hash;
1319         } else {
1320             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1321                 "descendant of archive's .dsc hash ($dsc_hash)";
1322         }
1323     } elsif ($dsc) {
1324         $hash = generate_commit_from_dsc();
1325     } elsif ($lastpush_hash) {
1326         # only in git, not in the archive yet
1327         $hash = $lastpush_hash;
1328         print STDERR <<END or die $!;
1329
1330 Package not found in the archive, but has allegedly been pushed using dgit.
1331 $later_warning_msg
1332 END
1333     } else {
1334         printdebug "nothing found!\n";
1335         if (defined $skew_warning_vsn) {
1336             print STDERR <<END or die $!;
1337
1338 Warning: relevant archive skew detected.
1339 Archive allegedly contains $skew_warning_vsn
1340 But we were not able to obtain any version from the archive or git.
1341
1342 END
1343         }
1344         return 0;
1345     }
1346     printdebug "current hash=$hash\n";
1347     if ($lastpush_hash) {
1348         fail "not fast forward on last upload branch!".
1349             " (archive's version left in DGIT_ARCHIVE)"
1350             unless is_fast_fwd($lastpush_hash, $hash);
1351     }
1352     if (defined $skew_warning_vsn) {
1353         mkpath '.git/dgit';
1354         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1355         my $clogf = ".git/dgit/changelog.tmp";
1356         runcmd shell_cmd "exec >$clogf",
1357             @git, qw(cat-file blob), "$hash:debian/changelog";
1358         my $gotclogp = parsechangelog("-l$clogf");
1359         my $got_vsn = getfield $gotclogp, 'Version';
1360         printdebug "SKEW CHECK GOT $got_vsn\n";
1361         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1362             print STDERR <<END or die $!;
1363
1364 Warning: archive skew detected.  Using the available version:
1365 Archive allegedly contains    $skew_warning_vsn
1366 We were able to obtain only   $got_vsn
1367
1368 END
1369         }
1370     }
1371     if ($lastpush_hash ne $hash) {
1372         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1373         if (act_local()) {
1374             cmdoutput @upd_cmd;
1375         } else {
1376             dryrun_report @upd_cmd;
1377         }
1378     }
1379     return 1;
1380 }
1381
1382 sub clone ($) {
1383     my ($dstdir) = @_;
1384     canonicalise_suite();
1385     badusage "dry run makes no sense with clone" unless act_local();
1386     my $hasgit = check_for_git();
1387     mkdir $dstdir or die "$dstdir $!";
1388     changedir $dstdir;
1389     runcmd @git, qw(init -q);
1390     my $giturl = access_giturl(1);
1391     if (defined $giturl) {
1392         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1393         open H, "> .git/HEAD" or die $!;
1394         print H "ref: ".lref()."\n" or die $!;
1395         close H or die $!;
1396         runcmd @git, qw(remote add), 'origin', $giturl;
1397     }
1398     if ($hasgit) {
1399         progress "fetching existing git history";
1400         git_fetch_us();
1401         runcmd_ordryrun_local @git, qw(fetch origin);
1402     } else {
1403         progress "starting new git history";
1404     }
1405     fetch_from_archive() or no_such_package;
1406     my $vcsgiturl = $dsc->{'Vcs-Git'};
1407     if (length $vcsgiturl) {
1408         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1409         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1410     }
1411     runcmd @git, qw(reset --hard), lrref();
1412     printdone "ready for work in $dstdir";
1413 }
1414
1415 sub fetch () {
1416     if (check_for_git()) {
1417         git_fetch_us();
1418     }
1419     fetch_from_archive() or no_such_package();
1420     printdone "fetched into ".lrref();
1421 }
1422
1423 sub pull () {
1424     fetch();
1425     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1426         lrref();
1427     printdone "fetched to ".lrref()." and merged into HEAD";
1428 }
1429
1430 sub check_not_dirty () {
1431     return if $ignoredirty;
1432     my @cmd = (@git, qw(diff --quiet HEAD));
1433     debugcmd "+",@cmd;
1434     $!=0; $?=0; system @cmd;
1435     return if !$! && !$?;
1436     if (!$! && $?==256) {
1437         fail "working tree is dirty (does not match HEAD)";
1438     } else {
1439         failedcmd @cmd;
1440     }
1441 }
1442
1443 sub commit_admin ($) {
1444     my ($m) = @_;
1445     progress "$m";
1446     runcmd_ordryrun_local @git, qw(commit -m), $m;
1447 }
1448
1449 sub commit_quilty_patch () {
1450     my $output = cmdoutput @git, qw(status --porcelain);
1451     my %adds;
1452     foreach my $l (split /\n/, $output) {
1453         next unless $l =~ m/\S/;
1454         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1455             $adds{$1}++;
1456         }
1457     }
1458     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1459     if (!%adds) {
1460         progress "nothing quilty to commit, ok.";
1461         return;
1462     }
1463     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1464     commit_admin "Commit Debian 3.0 (quilt) metadata";
1465 }
1466
1467 sub get_source_format () {
1468     if (!open F, "debian/source/format") {
1469         die $! unless $!==&ENOENT;
1470         return '';
1471     }
1472     $_ = <F>;
1473     F->error and die $!;
1474     chomp;
1475     return $_;
1476 }
1477
1478 sub madformat ($) {
1479     my ($format) = @_;
1480     return 0 unless $format eq '3.0 (quilt)';
1481     if ($quilt_mode eq 'nocheck') {
1482         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1483         return 0;
1484     }
1485     progress "Format \`$format', checking/updating patch stack";
1486     return 1;
1487 }
1488
1489 sub push_parse_changelog ($) {
1490     my ($clogpfn) = @_;
1491
1492     my $clogp = Dpkg::Control::Hash->new();
1493     $clogp->load($clogpfn) or die;
1494
1495     $package = getfield $clogp, 'Source';
1496     my $cversion = getfield $clogp, 'Version';
1497     my $tag = debiantag($cversion);
1498     runcmd @git, qw(check-ref-format), $tag;
1499
1500     my $dscfn = dscfn($cversion);
1501
1502     return ($clogp, $cversion, $tag, $dscfn);
1503 }
1504
1505 sub push_parse_dsc ($$$) {
1506     my ($dscfn,$dscfnwhat, $cversion) = @_;
1507     $dsc = parsecontrol($dscfn,$dscfnwhat);
1508     my $dversion = getfield $dsc, 'Version';
1509     my $dscpackage = getfield $dsc, 'Source';
1510     ($dscpackage eq $package && $dversion eq $cversion) or
1511         fail "$dscfn is for $dscpackage $dversion".
1512             " but debian/changelog is for $package $cversion";
1513 }
1514
1515 sub push_mktag ($$$$$$$) {
1516     my ($head,$clogp,$tag,
1517         $dscfn,
1518         $changesfile,$changesfilewhat,
1519         $tfn) = @_;
1520
1521     $dsc->{$ourdscfield[0]} = $head;
1522     $dsc->save("$dscfn.tmp") or die $!;
1523
1524     my $changes = parsecontrol($changesfile,$changesfilewhat);
1525     foreach my $field (qw(Source Distribution Version)) {
1526         $changes->{$field} eq $clogp->{$field} or
1527             fail "changes field $field \`$changes->{$field}'".
1528                 " does not match changelog \`$clogp->{$field}'";
1529     }
1530
1531     my $cversion = getfield $clogp, 'Version';
1532     my $clogsuite = getfield $clogp, 'Distribution';
1533
1534     # We make the git tag by hand because (a) that makes it easier
1535     # to control the "tagger" (b) we can do remote signing
1536     my $authline = clogp_authline $clogp;
1537     my $delibs = join(" ", "",@deliberatelies);
1538     my $declaredistro = access_basedistro();
1539     open TO, '>', $tfn->('.tmp') or die $!;
1540     print TO <<END or die $!;
1541 object $head
1542 type commit
1543 tag $tag
1544 tagger $authline
1545
1546 $package release $cversion for $clogsuite ($csuite) [dgit]
1547 [dgit distro=$declaredistro$delibs]
1548 END
1549     foreach my $ref (sort keys %supersedes) {
1550                     print TO <<END or die $!;
1551 [dgit supersede:$ref=$supersedes{$ref}]
1552 END
1553     }
1554
1555     close TO or die $!;
1556
1557     my $tagobjfn = $tfn->('.tmp');
1558     if ($sign) {
1559         if (!defined $keyid) {
1560             $keyid = access_cfg('keyid','RETURN-UNDEF');
1561         }
1562         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1563         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1564         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1565         push @sign_cmd, $tfn->('.tmp');
1566         runcmd_ordryrun @sign_cmd;
1567         if (act_scary()) {
1568             $tagobjfn = $tfn->('.signed.tmp');
1569             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1570                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1571         }
1572     }
1573
1574     return ($tagobjfn);
1575 }
1576
1577 sub sign_changes ($) {
1578     my ($changesfile) = @_;
1579     if ($sign) {
1580         my @debsign_cmd = @debsign;
1581         push @debsign_cmd, "-k$keyid" if defined $keyid;
1582         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1583         push @debsign_cmd, $changesfile;
1584         runcmd_ordryrun @debsign_cmd;
1585     }
1586 }
1587
1588 sub dopush ($) {
1589     my ($forceflag) = @_;
1590     printdebug "actually entering push\n";
1591     prep_ud();
1592
1593     access_giturl(); # check that success is vaguely likely
1594
1595     my $clogpfn = ".git/dgit/changelog.822.tmp";
1596     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1597
1598     responder_send_file('parsed-changelog', $clogpfn);
1599
1600     my ($clogp, $cversion, $tag, $dscfn) =
1601         push_parse_changelog("$clogpfn");
1602
1603     my $dscpath = "$buildproductsdir/$dscfn";
1604     stat_exists $dscpath or
1605         fail "looked for .dsc $dscfn, but $!;".
1606             " maybe you forgot to build";
1607
1608     responder_send_file('dsc', $dscpath);
1609
1610     push_parse_dsc($dscpath, $dscfn, $cversion);
1611
1612     my $format = getfield $dsc, 'Format';
1613     printdebug "format $format\n";
1614     if (madformat($format)) {
1615         commit_quilty_patch();
1616     }
1617     check_not_dirty();
1618     changedir $ud;
1619     progress "checking that $dscfn corresponds to HEAD";
1620     runcmd qw(dpkg-source -x --),
1621         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1622     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1623     changedir '../../../..';
1624     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1625     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1626     debugcmd "+",@diffcmd;
1627     $!=0; $?=0;
1628     my $r = system @diffcmd;
1629     if ($r) {
1630         if ($r==256) {
1631             fail "$dscfn specifies a different tree to your HEAD commit;".
1632                 " perhaps you forgot to build".
1633                 ($diffopt eq '--exit-code' ? "" :
1634                  " (run with -D to see full diff output)");
1635         } else {
1636             failedcmd @diffcmd;
1637         }
1638     }
1639 #fetch from alioth
1640 #do fast forward check and maybe fake merge
1641 #    if (!is_fast_fwd(mainbranch
1642 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1643 #        map { lref($_).":".rref($_) }
1644 #        (uploadbranch());
1645     my $head = git_rev_parse('HEAD');
1646     if (!$changesfile) {
1647         my $multi = "$buildproductsdir/".
1648             "${package}_".(stripepoch $cversion)."_multi.changes";
1649         if (stat_exists "$multi") {
1650             $changesfile = $multi;
1651         } else {
1652             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1653             my @cs = glob "$buildproductsdir/$pat";
1654             fail "failed to find unique changes file".
1655                 " (looked for $pat in $buildproductsdir, or $multi);".
1656                 " perhaps you need to use dgit -C"
1657                 unless @cs==1;
1658             ($changesfile) = @cs;
1659         }
1660     } else {
1661         $changesfile = "$buildproductsdir/$changesfile";
1662     }
1663
1664     responder_send_file('changes',$changesfile);
1665     responder_send_command("param head $head");
1666     responder_send_command("param csuite $csuite");
1667
1668     if ($forceflag && defined $lastpush_hash) {
1669         git_for_each_tag_referring($lastpush_hash, sub {
1670             my ($objid,$refobjid,$fullrefname,$tagname) = @_;
1671             responder_send_command("supersedes $fullrefname=$objid");
1672             $supersedes{$fullrefname} = $objid;
1673         });
1674     }
1675
1676     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1677     my $tagobjfn;
1678
1679     if ($we_are_responder) {
1680         $tagobjfn = $tfn->('.signed.tmp');
1681         responder_receive_files('signed-tag', $tagobjfn);
1682     } else {
1683         $tagobjfn =
1684             push_mktag($head,$clogp,$tag,
1685                        $dscpath,
1686                        $changesfile,$changesfile,
1687                        $tfn);
1688     }
1689
1690     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1691     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1692     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1693     runcmd_ordryrun @git, qw(tag -v --), $tag;
1694
1695     if (!check_for_git()) {
1696         create_remote_git_repo();
1697     }
1698     runcmd_ordryrun @git, qw(push),access_giturl(),
1699         $forceflag."HEAD:".rrref(), "refs/tags/$tag";
1700     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1701
1702     if ($we_are_responder) {
1703         my $dryrunsuffix = act_local() ? "" : ".tmp";
1704         responder_receive_files('signed-dsc-changes',
1705                                 "$dscpath$dryrunsuffix",
1706                                 "$changesfile$dryrunsuffix");
1707     } else {
1708         if (act_local()) {
1709             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1710         } else {
1711             progress "[new .dsc left in $dscpath.tmp]";
1712         }
1713         sign_changes $changesfile;
1714     }
1715
1716     my $host = access_cfg('upload-host','RETURN-UNDEF');
1717     my @hostarg = defined($host) ? ($host,) : ();
1718     runcmd_ordryrun @dput, @hostarg, $changesfile;
1719     printdone "pushed and uploaded $cversion";
1720
1721     responder_send_command("complete");
1722 }
1723
1724 sub cmd_clone {
1725     parseopts();
1726     my $dstdir;
1727     badusage "-p is not allowed with clone; specify as argument instead"
1728         if defined $package;
1729     if (@ARGV==1) {
1730         ($package) = @ARGV;
1731     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1732         ($package,$isuite) = @ARGV;
1733     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1734         ($package,$dstdir) = @ARGV;
1735     } elsif (@ARGV==3) {
1736         ($package,$isuite,$dstdir) = @ARGV;
1737     } else {
1738         badusage "incorrect arguments to dgit clone";
1739     }
1740     $dstdir ||= "$package";
1741
1742     if (stat_exists $dstdir) {
1743         fail "$dstdir already exists";
1744     }
1745
1746     my $cwd_remove;
1747     if ($rmonerror && !$dryrun_level) {
1748         $cwd_remove= getcwd();
1749         unshift @end, sub {
1750             return unless defined $cwd_remove;
1751             if (!chdir "$cwd_remove") {
1752                 return if $!==&ENOENT;
1753                 die "chdir $cwd_remove: $!";
1754             }
1755             rmtree($dstdir) or die "remove $dstdir: $!\n";
1756         };
1757     }
1758
1759     clone($dstdir);
1760     $cwd_remove = undef;
1761 }
1762
1763 sub branchsuite () {
1764     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1765     if ($branch =~ m#$lbranch_re#o) {
1766         return $1;
1767     } else {
1768         return undef;
1769     }
1770 }
1771
1772 sub fetchpullargs () {
1773     if (!defined $package) {
1774         my $sourcep = parsecontrol('debian/control','debian/control');
1775         $package = getfield $sourcep, 'Source';
1776     }
1777     if (@ARGV==0) {
1778 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1779         if (!$isuite) {
1780             my $clogp = parsechangelog();
1781             $isuite = getfield $clogp, 'Distribution';
1782         }
1783         canonicalise_suite();
1784         progress "fetching from suite $csuite";
1785     } elsif (@ARGV==1) {
1786         ($isuite) = @ARGV;
1787         canonicalise_suite();
1788     } else {
1789         badusage "incorrect arguments to dgit fetch or dgit pull";
1790     }
1791 }
1792
1793 sub cmd_fetch {
1794     parseopts();
1795     fetchpullargs();
1796     fetch();
1797 }
1798
1799 sub cmd_pull {
1800     parseopts();
1801     fetchpullargs();
1802     pull();
1803 }
1804
1805 sub cmd_push {
1806     parseopts();
1807     badusage "-p is not allowed with dgit push" if defined $package;
1808     check_not_dirty();
1809     my $clogp = parsechangelog();
1810     $package = getfield $clogp, 'Source';
1811     my $specsuite;
1812     if (@ARGV==0) {
1813     } elsif (@ARGV==1) {
1814         ($specsuite) = (@ARGV);
1815     } else {
1816         badusage "incorrect arguments to dgit push";
1817     }
1818     $isuite = getfield $clogp, 'Distribution';
1819     if ($new_package) {
1820         local ($package) = $existing_package; # this is a hack
1821         canonicalise_suite();
1822     }
1823     if (defined $specsuite && $specsuite ne $isuite) {
1824         canonicalise_suite();
1825         $csuite eq $specsuite or
1826             fail "dgit push: changelog specifies $isuite ($csuite)".
1827                 " but command line specifies $specsuite";
1828     }
1829     if (check_for_git()) {
1830         git_fetch_us();
1831     }
1832     my $forceflag = '';
1833     if (fetch_from_archive()) {
1834         if (is_fast_fwd(lrref(), 'HEAD')) {
1835             # ok
1836         } elsif (deliberately('not-fast-forward') ||
1837                  deliberately('TEST-not-fast-forward-dgit-only')) {
1838             $forceflag = '+';
1839         } else {
1840             fail "dgit push: HEAD is not a descendant".
1841                 " of the archive's version.\n".
1842                 "dgit: To overwrite its contents,".
1843                 " use git merge -s ours ".lrref().".\n".
1844                 "dgit: To rewind history, if permitted by the archive,".
1845                 " use --deliberately-not-fast-forward";
1846         }
1847     } else {
1848         $new_package or
1849             fail "package appears to be new in this suite;".
1850                 " if this is intentional, use --new";
1851     }
1852     dopush($forceflag);
1853 }
1854
1855 #---------- remote commands' implementation ----------
1856
1857 sub cmd_remote_push_build_host {
1858     my ($nrargs) = shift @ARGV;
1859     my (@rargs) = @ARGV[0..$nrargs-1];
1860     @ARGV = @ARGV[$nrargs..$#ARGV];
1861     die unless @rargs;
1862     my ($dir,$vsnwant) = @rargs;
1863     # vsnwant is a comma-separated list; we report which we have
1864     # chosen in our ready response (so other end can tell if they
1865     # offered several)
1866     $debugprefix = ' ';
1867     $we_are_responder = 1;
1868     $us .= " (build host)";
1869
1870     open PI, "<&STDIN" or die $!;
1871     open STDIN, "/dev/null" or die $!;
1872     open PO, ">&STDOUT" or die $!;
1873     autoflush PO 1;
1874     open STDOUT, ">&STDERR" or die $!;
1875     autoflush STDOUT 1;
1876
1877     $vsnwant //= 1;
1878     fail "build host has dgit rpush protocol version".
1879         " $rpushprotovsn but invocation host has $vsnwant"
1880         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1881
1882     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1883
1884     changedir $dir;
1885     &cmd_push;
1886 }
1887
1888 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1889 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1890 #     a good error message)
1891
1892 our $i_tmp;
1893
1894 sub i_cleanup {
1895     local ($@, $?);
1896     my $report = i_child_report();
1897     if (defined $report) {
1898         printdebug "($report)\n";
1899     } elsif ($i_child_pid) {
1900         printdebug "(killing build host child $i_child_pid)\n";
1901         kill 15, $i_child_pid;
1902     }
1903     if (defined $i_tmp && !defined $initiator_tempdir) {
1904         changedir "/";
1905         eval { rmtree $i_tmp; };
1906     }
1907 }
1908
1909 END { i_cleanup(); }
1910
1911 sub i_method {
1912     my ($base,$selector,@args) = @_;
1913     $selector =~ s/\-/_/g;
1914     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1915 }
1916
1917 sub cmd_rpush {
1918     my $host = nextarg;
1919     my $dir;
1920     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1921         $host = $1;
1922         $dir = $'; #';
1923     } else {
1924         $dir = nextarg;
1925     }
1926     $dir =~ s{^-}{./-};
1927     my @rargs = ($dir,$rpushprotovsn);
1928     my @rdgit;
1929     push @rdgit, @dgit;
1930     push @rdgit, @ropts;
1931     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1932     push @rdgit, @ARGV;
1933     my @cmd = (@ssh, $host, shellquote @rdgit);
1934     debugcmd "+",@cmd;
1935
1936     if (defined $initiator_tempdir) {
1937         rmtree $initiator_tempdir;
1938         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1939         $i_tmp = $initiator_tempdir;
1940     } else {
1941         $i_tmp = tempdir();
1942     }
1943     $i_child_pid = open2(\*RO, \*RI, @cmd);
1944     changedir $i_tmp;
1945     initiator_expect { m/^dgit-remote-push-ready/ };
1946     for (;;) {
1947         my ($icmd,$iargs) = initiator_expect {
1948             m/^(\S+)(?: (.*))?$/;
1949             ($1,$2);
1950         };
1951         i_method "i_resp", $icmd, $iargs;
1952     }
1953 }
1954
1955 sub i_resp_progress ($) {
1956     my ($rhs) = @_;
1957     my $msg = protocol_read_bytes \*RO, $rhs;
1958     progress $msg;
1959 }
1960
1961 sub i_resp_complete {
1962     my $pid = $i_child_pid;
1963     $i_child_pid = undef; # prevents killing some other process with same pid
1964     printdebug "waiting for build host child $pid...\n";
1965     my $got = waitpid $pid, 0;
1966     die $! unless $got == $pid;
1967     die "build host child failed $?" if $?;
1968
1969     i_cleanup();
1970     printdebug "all done\n";
1971     exit 0;
1972 }
1973
1974 sub i_resp_file ($) {
1975     my ($keyword) = @_;
1976     my $localname = i_method "i_localname", $keyword;
1977     my $localpath = "$i_tmp/$localname";
1978     stat_exists $localpath and
1979         badproto \*RO, "file $keyword ($localpath) twice";
1980     protocol_receive_file \*RO, $localpath;
1981     i_method "i_file", $keyword;
1982 }
1983
1984 our %i_param;
1985
1986 sub i_resp_param ($) {
1987     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1988     $i_param{$1} = $2;
1989 }
1990
1991 sub i_resp_supersedes ($) {
1992     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
1993         or badproto \*RO, "bad supersedes spec";
1994     my $r = system qw(git check-ref-format), $1;
1995     die "bad supersedes ref spec ($r)" if $r;
1996     $supersedes{$1} = $2;
1997 }
1998
1999 our %i_wanted;
2000
2001 sub i_resp_want ($) {
2002     my ($keyword) = @_;
2003     die "$keyword ?" if $i_wanted{$keyword}++;
2004     my @localpaths = i_method "i_want", $keyword;
2005     printdebug "[[  $keyword @localpaths\n";
2006     foreach my $localpath (@localpaths) {
2007         protocol_send_file \*RI, $localpath;
2008     }
2009     print RI "files-end\n" or die $!;
2010 }
2011
2012 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2013
2014 sub i_localname_parsed_changelog {
2015     return "remote-changelog.822";
2016 }
2017 sub i_file_parsed_changelog {
2018     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2019         push_parse_changelog "$i_tmp/remote-changelog.822";
2020     die if $i_dscfn =~ m#/|^\W#;
2021 }
2022
2023 sub i_localname_dsc {
2024     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2025     return $i_dscfn;
2026 }
2027 sub i_file_dsc { }
2028
2029 sub i_localname_changes {
2030     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2031     $i_changesfn = $i_dscfn;
2032     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2033     return $i_changesfn;
2034 }
2035 sub i_file_changes { }
2036
2037 sub i_want_signed_tag {
2038     printdebug Dumper(\%i_param, $i_dscfn);
2039     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2040         && defined $i_param{'csuite'}
2041         or badproto \*RO, "premature desire for signed-tag";
2042     my $head = $i_param{'head'};
2043     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2044
2045     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2046     $csuite = $&;
2047     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2048
2049     my $tagobjfn =
2050         push_mktag $head, $i_clogp, $i_tag,
2051             $i_dscfn,
2052             $i_changesfn, 'remote changes',
2053             sub { "tag$_[0]"; };
2054
2055     return $tagobjfn;
2056 }
2057
2058 sub i_want_signed_dsc_changes {
2059     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2060     sign_changes $i_changesfn;
2061     return ($i_dscfn, $i_changesfn);
2062 }
2063
2064 #---------- building etc. ----------
2065
2066 our $version;
2067 our $sourcechanges;
2068 our $dscfn;
2069
2070 #----- `3.0 (quilt)' handling -----
2071
2072 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2073
2074 sub quiltify_dpkg_commit ($$$;$) {
2075     my ($patchname,$author,$msg, $xinfo) = @_;
2076     $xinfo //= '';
2077
2078     mkpath '.git/dgit';
2079     my $descfn = ".git/dgit/quilt-description.tmp";
2080     open O, '>', $descfn or die "$descfn: $!";
2081     $msg =~ s/\s+$//g;
2082     $msg =~ s/\n/\n /g;
2083     $msg =~ s/^\s+$/ ./mg;
2084     print O <<END or die $!;
2085 Description: $msg
2086 Author: $author
2087 $xinfo
2088 ---
2089
2090 END
2091     close O or die $!;
2092
2093     {
2094         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2095         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2096         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2097         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2098     }
2099 }
2100
2101 sub quiltify_trees_differ ($$) {
2102     my ($x,$y) = @_;
2103     # returns 1 iff the two tree objects differ other than in debian/
2104     local $/=undef;
2105     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2106     my $diffs= cmdoutput @cmd;
2107     foreach my $f (split /\0/, $diffs) {
2108         next if $f eq 'debian';
2109         return 1;
2110     }
2111     return 0;
2112 }
2113
2114 sub quiltify_tree_sentinelfiles ($) {
2115     # lists the `sentinel' files present in the tree
2116     my ($x) = @_;
2117     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2118         qw(-- debian/rules debian/control);
2119     $r =~ s/\n/,/g;
2120     return $r;
2121 }
2122
2123 sub quiltify ($$) {
2124     my ($clogp,$target) = @_;
2125
2126     # Quilt patchification algorithm
2127     #
2128     # We search backwards through the history of the main tree's HEAD
2129     # (T) looking for a start commit S whose tree object is identical
2130     # to to the patch tip tree (ie the tree corresponding to the
2131     # current dpkg-committed patch series).  For these purposes
2132     # `identical' disregards anything in debian/ - this wrinkle is
2133     # necessary because dpkg-source treates debian/ specially.
2134     #
2135     # We can only traverse edges where at most one of the ancestors'
2136     # trees differs (in changes outside in debian/).  And we cannot
2137     # handle edges which change .pc/ or debian/patches.  To avoid
2138     # going down a rathole we avoid traversing edges which introduce
2139     # debian/rules or debian/control.  And we set a limit on the
2140     # number of edges we are willing to look at.
2141     #
2142     # If we succeed, we walk forwards again.  For each traversed edge
2143     # PC (with P parent, C child) (starting with P=S and ending with
2144     # C=T) to we do this:
2145     #  - git checkout C
2146     #  - dpkg-source --commit with a patch name and message derived from C
2147     # After traversing PT, we git commit the changes which
2148     # should be contained within debian/patches.
2149
2150     changedir '../fake';
2151     mktree_in_ud_here();
2152     rmtree '.pc';
2153     runcmd @git, 'add', '.';
2154     my $oldtiptree=git_write_tree();
2155     changedir '../work';
2156
2157     # The search for the path S..T is breadth-first.  We maintain a
2158     # todo list containing search nodes.  A search node identifies a
2159     # commit, and looks something like this:
2160     #  $p = {
2161     #      Commit => $git_commit_id,
2162     #      Child => $c,                          # or undef if P=T
2163     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2164     #      Nontrivial => true iff $p..$c has relevant changes
2165     #  };
2166
2167     my @todo;
2168     my @nots;
2169     my $sref_S;
2170     my $max_work=100;
2171     my %considered; # saves being exponential on some weird graphs
2172
2173     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2174
2175     my $not = sub {
2176         my ($search,$whynot) = @_;
2177         printdebug " search NOT $search->{Commit} $whynot\n";
2178         $search->{Whynot} = $whynot;
2179         push @nots, $search;
2180         no warnings qw(exiting);
2181         next;
2182     };
2183
2184     push @todo, {
2185         Commit => $target,
2186     };
2187
2188     while (@todo) {
2189         my $c = shift @todo;
2190         next if $considered{$c->{Commit}}++;
2191
2192         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2193
2194         printdebug "quiltify investigate $c->{Commit}\n";
2195
2196         # are we done?
2197         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2198             printdebug " search finished hooray!\n";
2199             $sref_S = $c;
2200             last;
2201         }
2202
2203         if ($quilt_mode eq 'nofix') {
2204             fail "quilt fixup required but quilt mode is \`nofix'\n".
2205                 "HEAD commit $c->{Commit} differs from tree implied by ".
2206                 " debian/patches (tree object $oldtiptree)";
2207         }
2208         if ($quilt_mode eq 'smash') {
2209             printdebug " search quitting smash\n";
2210             last;
2211         }
2212
2213         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2214         $not->($c, "has $c_sentinels not $t_sentinels")
2215             if $c_sentinels ne $t_sentinels;
2216
2217         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2218         $commitdata =~ m/\n\n/;
2219         $commitdata =~ $`;
2220         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2221         @parents = map { { Commit => $_, Child => $c } } @parents;
2222
2223         $not->($c, "root commit") if !@parents;
2224
2225         foreach my $p (@parents) {
2226             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2227         }
2228         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2229         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2230
2231         foreach my $p (@parents) {
2232             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2233
2234             my @cmd= (@git, qw(diff-tree -r --name-only),
2235                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2236             my $patchstackchange = cmdoutput @cmd;
2237             if (length $patchstackchange) {
2238                 $patchstackchange =~ s/\n/,/g;
2239                 $not->($p, "changed $patchstackchange");
2240             }
2241
2242             printdebug " search queue P=$p->{Commit} ",
2243                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2244             push @todo, $p;
2245         }
2246     }
2247
2248     if (!$sref_S) {
2249         printdebug "quiltify want to smash\n";
2250
2251         my $abbrev = sub {
2252             my $x = $_[0]{Commit};
2253             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2254             return $;
2255         };
2256         my $reportnot = sub {
2257             my ($notp) = @_;
2258             my $s = $abbrev->($notp);
2259             my $c = $notp->{Child};
2260             $s .= "..".$abbrev->($c) if $c;
2261             $s .= ": ".$c->{Whynot};
2262             return $s;
2263         };
2264         if ($quilt_mode eq 'linear') {
2265             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2266             foreach my $notp (@nots) {
2267                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2268             }
2269             fail "quilt fixup naive history linearisation failed.\n".
2270  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2271         } elsif ($quilt_mode eq 'smash') {
2272         } elsif ($quilt_mode eq 'auto') {
2273             progress "quilt fixup cannot be linear, smashing...";
2274         } else {
2275             die "$quilt_mode ?";
2276         }
2277
2278         my $time = time;
2279         my $ncommits = 3;
2280         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2281
2282         quiltify_dpkg_commit "auto-$version-$target-$time",
2283             (getfield $clogp, 'Maintainer'),
2284             "Automatically generated patch ($clogp->{Version})\n".
2285             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2286         return;
2287     }
2288
2289     progress "quiltify linearisation planning successful, executing...";
2290
2291     for (my $p = $sref_S;
2292          my $c = $p->{Child};
2293          $p = $p->{Child}) {
2294         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2295         next unless $p->{Nontrivial};
2296
2297         my $cc = $c->{Commit};
2298
2299         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2300         $commitdata =~ m/\n\n/ or die "$c ?";
2301         $commitdata = $`;
2302         my $msg = $'; #';
2303         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2304         my $author = $1;
2305
2306         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2307
2308         my $title = $1;
2309         my $patchname = $title;
2310         $patchname =~ s/[.:]$//;
2311         $patchname =~ y/ A-Z/-a-z/;
2312         $patchname =~ y/-a-z0-9_.+=~//cd;
2313         $patchname =~ s/^\W/x-$&/;
2314         $patchname = substr($patchname,0,40);
2315         my $index;
2316         for ($index='';
2317              stat "debian/patches/$patchname$index";
2318              $index++) { }
2319         $!==ENOENT or die "$patchname$index $!";
2320
2321         runcmd @git, qw(checkout -q), $cc;
2322
2323         # We use the tip's changelog so that dpkg-source doesn't
2324         # produce complaining messages from dpkg-parsechangelog.  None
2325         # of the information dpkg-source gets from the changelog is
2326         # actually relevant - it gets put into the original message
2327         # which dpkg-source provides our stunt editor, and then
2328         # overwritten.
2329         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2330
2331         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2332             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2333
2334         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2335     }
2336
2337     runcmd @git, qw(checkout -q master);
2338 }
2339
2340 sub build_maybe_quilt_fixup () {
2341     my $format=get_source_format;
2342     return unless madformat $format;
2343     # sigh
2344
2345     # Our objective is:
2346     #  - honour any existing .pc in case it has any strangeness
2347     #  - determine the git commit corresponding to the tip of
2348     #    the patch stack (if there is one)
2349     #  - if there is such a git commit, convert each subsequent
2350     #    git commit into a quilt patch with dpkg-source --commit
2351     #  - otherwise convert all the differences in the tree into
2352     #    a single git commit
2353     #
2354     # To do this we:
2355
2356     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2357     # dgit would include the .pc in the git tree.)  If there isn't
2358     # one, we need to generate one by unpacking the patches that we
2359     # have.
2360     #
2361     # We first look for a .pc in the git tree.  If there is one, we
2362     # will use it.  (This is not the normal case.)
2363     #
2364     # Otherwise need to regenerate .pc so that dpkg-source --commit
2365     # can work.  We do this as follows:
2366     #     1. Collect all relevant .orig from parent directory
2367     #     2. Generate a debian.tar.gz out of
2368     #         debian/{patches,rules,source/format}
2369     #     3. Generate a fake .dsc containing just these fields:
2370     #          Format Source Version Files
2371     #     4. Extract the fake .dsc
2372     #        Now the fake .dsc has a .pc directory.
2373     # (In fact we do this in every case, because in future we will
2374     # want to search for a good base commit for generating patches.)
2375     #
2376     # Then we can actually do the dpkg-source --commit
2377     #     1. Make a new working tree with the same object
2378     #        store as our main tree and check out the main
2379     #        tree's HEAD.
2380     #     2. Copy .pc from the fake's extraction, if necessary
2381     #     3. Run dpkg-source --commit
2382     #     4. If the result has changes to debian/, then
2383     #          - git-add them them
2384     #          - git-add .pc if we had a .pc in-tree
2385     #          - git-commit
2386     #     5. If we had a .pc in-tree, delete it, and git-commit
2387     #     6. Back in the main tree, fast forward to the new HEAD
2388
2389     my $clogp = parsechangelog();
2390     my $headref = git_rev_parse('HEAD');
2391
2392     prep_ud();
2393     changedir $ud;
2394
2395     my $upstreamversion=$version;
2396     $upstreamversion =~ s/-[^-]*$//;
2397
2398     my $fakeversion="$upstreamversion-~~DGITFAKE";
2399
2400     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2401     print $fakedsc <<END or die $!;
2402 Format: 3.0 (quilt)
2403 Source: $package
2404 Version: $fakeversion
2405 Files:
2406 END
2407
2408     my $dscaddfile=sub {
2409         my ($b) = @_;
2410
2411         my $md = new Digest::MD5;
2412
2413         my $fh = new IO::File $b, '<' or die "$b $!";
2414         stat $fh or die $!;
2415         my $size = -s _;
2416
2417         $md->addfile($fh);
2418         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2419     };
2420
2421     foreach my $f (<../../../../*>) { #/){
2422         my $b=$f; $b =~ s{.*/}{};
2423         next unless is_orig_file $b, srcfn $upstreamversion,'';
2424         link $f, $b or die "$b $!";
2425         $dscaddfile->($b);
2426     }
2427
2428     my @files=qw(debian/source/format debian/rules);
2429     if (stat_exists '../../../debian/patches') {
2430         push @files, 'debian/patches';
2431     }
2432
2433     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2434     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2435
2436     $dscaddfile->($debtar);
2437     close $fakedsc or die $!;
2438
2439     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2440
2441     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2442     rename $fakexdir, "fake" or die "$fakexdir $!";
2443
2444     mkdir "work" or die $!;
2445     changedir "work";
2446     mktree_in_ud_here();
2447     runcmd @git, qw(reset --hard), $headref;
2448
2449     my $mustdeletepc=0;
2450     if (stat_exists ".pc") {
2451         -d _ or die;
2452         progress "Tree already contains .pc - will use it then delete it.";
2453         $mustdeletepc=1;
2454     } else {
2455         rename '../fake/.pc','.pc' or die $!;
2456     }
2457
2458     quiltify($clogp,$headref);
2459
2460     if (!open P, '>>', ".pc/applied-patches") {
2461         $!==&ENOENT or die $!;
2462     } else {
2463         close P;
2464     }
2465
2466     commit_quilty_patch();
2467
2468     if ($mustdeletepc) {
2469         runcmd @git, qw(rm -rq .pc);
2470         commit_admin "Commit removal of .pc (quilt series tracking data)";
2471     }
2472
2473     changedir '../../../..';
2474     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2475 }
2476
2477 sub quilt_fixup_editor () {
2478     my $descfn = $ENV{$fakeeditorenv};
2479     my $editing = $ARGV[$#ARGV];
2480     open I1, '<', $descfn or die "$descfn: $!";
2481     open I2, '<', $editing or die "$editing: $!";
2482     unlink $editing or die "$editing: $!";
2483     open O, '>', $editing or die "$editing: $!";
2484     while (<I1>) { print O or die $!; } I1->error and die $!;
2485     my $copying = 0;
2486     while (<I2>) {
2487         $copying ||= m/^\-\-\- /;
2488         next unless $copying;
2489         print O or die $!;
2490     }
2491     I2->error and die $!;
2492     close O or die $1;
2493     exit 0;
2494 }
2495
2496 #----- other building -----
2497
2498 sub clean_tree () {
2499     if ($cleanmode eq 'dpkg-source') {
2500         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2501     } elsif ($cleanmode eq 'git') {
2502         runcmd_ordryrun_local @git, qw(clean -xdf);
2503     } elsif ($cleanmode eq 'none') {
2504     } else {
2505         die "$cleanmode ?";
2506     }
2507 }
2508
2509 sub cmd_clean () {
2510     badusage "clean takes no additional arguments" if @ARGV;
2511     clean_tree();
2512 }
2513
2514 sub build_prep () {
2515     badusage "-p is not allowed when building" if defined $package;
2516     check_not_dirty();
2517     clean_tree();
2518     my $clogp = parsechangelog();
2519     $isuite = getfield $clogp, 'Distribution';
2520     $package = getfield $clogp, 'Source';
2521     $version = getfield $clogp, 'Version';
2522     build_maybe_quilt_fixup();
2523 }
2524
2525 sub changesopts () {
2526     my @opts =@changesopts[1..$#changesopts];
2527     if (!defined $changes_since_version) {
2528         my @vsns = archive_query('archive_query');
2529         my @quirk = access_quirk();
2530         if ($quirk[0] eq 'backports') {
2531             local $isuite = $quirk[2];
2532             local $csuite;
2533             canonicalise_suite();
2534             push @vsns, archive_query('archive_query');
2535         }
2536         if (@vsns) {
2537             @vsns = map { $_->[0] } @vsns;
2538             @vsns = sort { -version_compare($a, $b) } @vsns;
2539             $changes_since_version = $vsns[0];
2540             progress "changelog will contain changes since $vsns[0]";
2541         } else {
2542             $changes_since_version = '_';
2543             progress "package seems new, not specifying -v<version>";
2544         }
2545     }
2546     if ($changes_since_version ne '_') {
2547         unshift @opts, "-v$changes_since_version";
2548     }
2549     return @opts;
2550 }
2551
2552 sub cmd_build {
2553     build_prep();
2554     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2555     printdone "build successful\n";
2556 }
2557
2558 sub cmd_git_build {
2559     build_prep();
2560     my @cmd =
2561         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2562          "--git-builder=@dpkgbuildpackage");
2563     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2564         canonicalise_suite();
2565         push @cmd, "--git-debian-branch=".lbranch();
2566     }
2567     push @cmd, changesopts();
2568     runcmd_ordryrun_local @cmd, @ARGV;
2569     printdone "build successful\n";
2570 }
2571
2572 sub build_source {
2573     build_prep();
2574     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2575     $dscfn = dscfn($version);
2576     if ($cleanmode eq 'dpkg-source') {
2577         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2578             changesopts();
2579     } else {
2580         my $pwd = must_getcwd();
2581         my $leafdir = basename $pwd;
2582         changedir "..";
2583         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2584         changedir $pwd;
2585         runcmd_ordryrun_local qw(sh -ec),
2586             'exec >$1; shift; exec "$@"','x',
2587             "../$sourcechanges",
2588             @dpkggenchanges, qw(-S), changesopts();
2589     }
2590 }
2591
2592 sub cmd_build_source {
2593     badusage "build-source takes no additional arguments" if @ARGV;
2594     build_source();
2595     printdone "source built, results in $dscfn and $sourcechanges";
2596 }
2597
2598 sub cmd_sbuild {
2599     build_source();
2600     changedir "..";
2601     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2602     if (act_local()) {
2603         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2604         stat_exists $sourcechanges
2605             or fail "$sourcechanges (in parent directory): $!";
2606         foreach my $cf (glob $pat) {
2607             next if $cf eq $sourcechanges;
2608             unlink $cf or fail "remove $cf: $!";
2609         }
2610     }
2611     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2612     my @changesfiles = glob $pat;
2613     @changesfiles = sort {
2614         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2615             or $a cmp $b
2616     } @changesfiles;
2617     fail "wrong number of different changes files (@changesfiles)"
2618         unless @changesfiles;
2619     runcmd_ordryrun_local @mergechanges, @changesfiles;
2620     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2621     if (act_local()) {
2622         stat_exists $multichanges or fail "$multichanges: $!";
2623     }
2624     printdone "build successful, results in $multichanges\n" or die $!;
2625 }
2626
2627 sub cmd_quilt_fixup {
2628     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2629     my $clogp = parsechangelog();
2630     $version = getfield $clogp, 'Version';
2631     $package = getfield $clogp, 'Source';
2632     build_maybe_quilt_fixup();
2633 }
2634
2635 sub cmd_archive_api_query {
2636     badusage "need only 1 subpath argument" unless @ARGV==1;
2637     my ($subpath) = @ARGV;
2638     my @cmd = archive_api_query_cmd($subpath);
2639     debugcmd ">",@cmd;
2640     exec @cmd or fail "exec curl: $!\n";
2641 }
2642
2643 #---------- argument parsing and main program ----------
2644
2645 sub cmd_version {
2646     print "dgit version $our_version\n" or die $!;
2647     exit 0;
2648 }
2649
2650 sub parseopts () {
2651     my $om;
2652
2653     if (defined $ENV{'DGIT_SSH'}) {
2654         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2655     } elsif (defined $ENV{'GIT_SSH'}) {
2656         @ssh = ($ENV{'GIT_SSH'});
2657     }
2658
2659     while (@ARGV) {
2660         last unless $ARGV[0] =~ m/^-/;
2661         $_ = shift @ARGV;
2662         last if m/^--?$/;
2663         if (m/^--/) {
2664             if (m/^--dry-run$/) {
2665                 push @ropts, $_;
2666                 $dryrun_level=2;
2667             } elsif (m/^--damp-run$/) {
2668                 push @ropts, $_;
2669                 $dryrun_level=1;
2670             } elsif (m/^--no-sign$/) {
2671                 push @ropts, $_;
2672                 $sign=0;
2673             } elsif (m/^--help$/) {
2674                 cmd_help();
2675             } elsif (m/^--version$/) {
2676                 cmd_version();
2677             } elsif (m/^--new$/) {
2678                 push @ropts, $_;
2679                 $new_package=1;
2680             } elsif (m/^--since-version=([^_]+|_)$/) {
2681                 push @ropts, $_;
2682                 $changes_since_version = $1;
2683             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2684                      ($om = $opts_opt_map{$1}) &&
2685                      length $om->[0]) {
2686                 push @ropts, $_;
2687                 $om->[0] = $2;
2688             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2689                      !$opts_opt_cmdonly{$1} &&
2690                      ($om = $opts_opt_map{$1})) {
2691                 push @ropts, $_;
2692                 push @$om, $2;
2693             } elsif (m/^--existing-package=(.*)/s) {
2694                 push @ropts, $_;
2695                 $existing_package = $1;
2696             } elsif (m/^--initiator-tempdir=(.*)/s) {
2697                 $initiator_tempdir = $1;
2698                 $initiator_tempdir =~ m#^/# or
2699                     badusage "--initiator-tempdir must be used specify an".
2700                         " absolute, not relative, directory."
2701             } elsif (m/^--distro=(.*)/s) {
2702                 push @ropts, $_;
2703                 $idistro = $1;
2704             } elsif (m/^--build-products-dir=(.*)/s) {
2705                 push @ropts, $_;
2706                 $buildproductsdir = $1;
2707             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2708                 push @ropts, $_;
2709                 $cleanmode = $1;
2710             } elsif (m/^--clean=(.*)$/s) {
2711                 badusage "unknown cleaning mode \`$1'";
2712             } elsif (m/^--quilt=($quilt_modes_re)$/s) {
2713                 push @ropts, $_;
2714                 $quilt_mode = $1;
2715             } elsif (m/^--quilt=(.*)$/s) {
2716                 badusage "unknown quilt fixup mode \`$1'";
2717             } elsif (m/^--ignore-dirty$/s) {
2718                 push @ropts, $_;
2719                 $ignoredirty = 1;
2720             } elsif (m/^--no-quilt-fixup$/s) {
2721                 push @ropts, $_;
2722                 $quilt_mode = 'nocheck';
2723             } elsif (m/^--no-rm-on-error$/s) {
2724                 push @ropts, $_;
2725                 $rmonerror = 0;
2726             } elsif (m/^--deliberately-($deliberately_re)$/s) {
2727                 push @ropts, $_;
2728                 push @deliberatelies, $&;
2729             } else {
2730                 badusage "unknown long option \`$_'";
2731             }
2732         } else {
2733             while (m/^-./s) {
2734                 if (s/^-n/-/) {
2735                     push @ropts, $&;
2736                     $dryrun_level=2;
2737                 } elsif (s/^-L/-/) {
2738                     push @ropts, $&;
2739                     $dryrun_level=1;
2740                 } elsif (s/^-h/-/) {
2741                     cmd_help();
2742                 } elsif (s/^-D/-/) {
2743                     push @ropts, $&;
2744                     $debuglevel++;
2745                     enabledebug();
2746                 } elsif (s/^-N/-/) {
2747                     push @ropts, $&;
2748                     $new_package=1;
2749                 } elsif (s/^-v([^_]+|_)$//s) {
2750                     push @ropts, $&;
2751                     $changes_since_version = $1;
2752                 } elsif (m/^-m/) {
2753                     push @ropts, $&;
2754                     push @changesopts, $_;
2755                     $_ = '';
2756                 } elsif (s/^-c(.*=.*)//s) {
2757                     push @ropts, $&;
2758                     push @git, '-c', $1;
2759                 } elsif (s/^-d(.+)//s) {
2760                     push @ropts, $&;
2761                     $idistro = $1;
2762                 } elsif (s/^-C(.+)//s) {
2763                     push @ropts, $&;
2764                     $changesfile = $1;
2765                     if ($changesfile =~ s#^(.*)/##) {
2766                         $buildproductsdir = $1;
2767                     }
2768                 } elsif (s/^-k(.+)//s) {
2769                     $keyid=$1;
2770                 } elsif (m/^-[vdCk]$/) {
2771                     badusage
2772  "option \`$_' requires an argument (and no space before the argument)";
2773                 } elsif (s/^-wn$//s) {
2774                     push @ropts, $&;
2775                     $cleanmode = 'none';
2776                 } elsif (s/^-wg$//s) {
2777                     push @ropts, $&;
2778                     $cleanmode = 'git';
2779                 } elsif (s/^-wd$//s) {
2780                     push @ropts, $&;
2781                     $cleanmode = 'dpkg-source';
2782                 } else {
2783                     badusage "unknown short option \`$_'";
2784                 }
2785             }
2786         }
2787     }
2788 }
2789
2790 if ($ENV{$fakeeditorenv}) {
2791     quilt_fixup_editor();
2792 }
2793
2794 parseopts();
2795 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2796 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2797     if $dryrun_level == 1;
2798 if (!@ARGV) {
2799     print STDERR $helpmsg or die $!;
2800     exit 8;
2801 }
2802 my $cmd = shift @ARGV;
2803 $cmd =~ y/-/_/;
2804
2805 if (!defined $quilt_mode) {
2806     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
2807         // access_cfg('quilt-mode', 'RETURN-UNDEF')
2808         // 'linear';
2809     $quilt_mode =~ m/^($quilt_modes_re)$/
2810         or badcfg "unknown quilt-mode \`$quilt_mode'";
2811     $quilt_mode = $1;
2812 }
2813
2814 my $fn = ${*::}{"cmd_$cmd"};
2815 $fn or badusage "unknown operation $cmd";
2816 $fn->();