dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $cmd;
  51 our $subcommand;
  52 our $isuite;
  53 our $idistro;
  54 our $package;
  55 our @ropts;
  56
  57 our $sign = 1;
  58 our $dryrun_level = 0;
  59 our $changesfile;
  60 our $buildproductsdir = '..';
  61 our $new_package = 0;
  62 our $ignoredirty = 0;
  63 our $rmonerror = 1;
  64 our @deliberatelies;
  65 our %previously;
  66 our $existing_package = 'dpkg';
  67 our $cleanmode;
  68 our $changes_since_version;
  69 our $rmchanges;
  70 our $overwrite_version; # undef: not specified; '': check changelog
  71 our $quilt_mode;
  72 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  73 our $dodep14tag;
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $we_are_initiator;
  77 our $initiator_tempdir;
  78 our $patches_applied_dirtily = 00;
  79 our $tagformat_want;
  80 our $tagformat;
  81 our $tagformatfn;
  82 our $chase_dsc_distro=1;
  83
  84 our %forceopts = map { $_=>0 }
  85     qw(unrepresentable unsupported-source-format
  86        dsc-changes-mismatch changes-origs-exactly
  87        import-gitapply-absurd
  88        import-gitapply-no-absurd
  89        import-dsc-with-dgit-field);
  90
  91 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  92
  93 our $suite_re = '[-+.0-9a-z]+';
  94 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  95 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  96 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  97 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  98
  99 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 100 our $splitbraincache = 'dgit-intern/quilt-cache';
 101 our $rewritemap = 'dgit-rewrite/map';
 102
 103 our (@git) = qw(git);
 104 our (@dget) = qw(dget);
 105 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 106 our (@dput) = qw(dput);
 107 our (@debsign) = qw(debsign);
 108 our (@gpg) = qw(gpg);
 109 our (@sbuild) = qw(sbuild);
 110 our (@ssh) = 'ssh';
 111 our (@dgit) = qw(dgit);
 112 our (@aptget) = qw(apt-get);
 113 our (@aptcache) = qw(apt-cache);
 114 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 115 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 116 our (@dpkggenchanges) = qw(dpkg-genchanges);
 117 our (@mergechanges) = qw(mergechanges -f);
 118 our (@gbp_build) = ('');
 119 our (@gbp_pq) = ('gbp pq');
 120 our (@changesopts) = ('');
 121
 122 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 123                      'curl' => \@curl,
 124                      'dput' => \@dput,
 125                      'debsign' => \@debsign,
 126                      'gpg' => \@gpg,
 127                      'sbuild' => \@sbuild,
 128                      'ssh' => \@ssh,
 129                      'dgit' => \@dgit,
 130                      'git' => \@git,
 131                      'apt-get' => \@aptget,
 132                      'apt-cache' => \@aptcache,
 133                      'dpkg-source' => \@dpkgsource,
 134                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 135                      'dpkg-genchanges' => \@dpkggenchanges,
 136                      'gbp-build' => \@gbp_build,
 137                      'gbp-pq' => \@gbp_pq,
 138                      'ch' => \@changesopts,
 139                      'mergechanges' => \@mergechanges);
 140
 141 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 142 our %opts_cfg_insertpos = map {
 143     $_,
 144     scalar @{ $opts_opt_map{$_} }
 145 } keys %opts_opt_map;
 146
 147 sub parseopts_late_defaults();
 148 sub setup_gitattrs(;$);
 149 sub check_gitattrs($$);
 150
 151 our $keyid;
 152
 153 autoflush STDOUT 1;
 154
 155 our $supplementary_message = '';
 156 our $need_split_build_invocation = 0;
 157 our $split_brain = 0;
 158
 159 END {
 160     local ($@, $?);
 161     return unless forkcheck_mainprocess();
 162     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 163 }
 164
 165 our $remotename = 'dgit';
 166 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 167 our $csuite;
 168 our $instead_distro;
 169
 170 if (!defined $absurdity) {
 171     $absurdity = $0;
 172     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 173 }
 174
 175 sub debiantag ($$) {
 176     my ($v,$distro) = @_;
 177     return $tagformatfn->($v, $distro);
 178 }
 179
 180 sub debiantag_maintview ($$) {
 181     my ($v,$distro) = @_;
 182     return "$distro/".dep14_version_mangle $v;
 183 }
 184
 185 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 186
 187 sub lbranch () { return "$branchprefix/$csuite"; }
 188 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 189 sub lref () { return "refs/heads/".lbranch(); }
 190 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 191 sub rrref () { return server_ref($csuite); }
 192
 193 sub stripepoch ($) {
 194     my ($vsn) = @_;
 195     $vsn =~ s/^\d+\://;
 196     return $vsn;
 197 }
 198
 199 sub srcfn ($$) {
 200     my ($vsn,$sfx) = @_;
 201     return "${package}_".(stripepoch $vsn).$sfx
 202 }
 203
 204 sub dscfn ($) {
 205     my ($vsn) = @_;
 206     return srcfn($vsn,".dsc");
 207 }
 208
 209 sub changespat ($;$) {
 210     my ($vsn, $arch) = @_;
 211     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 212 }
 213
 214 sub upstreamversion ($) {
 215     my ($vsn) = @_;
 216     $vsn =~ s/-[^-]+$//;
 217     return $vsn;
 218 }
 219
 220 our $us = 'dgit';
 221 initdebug('');
 222
 223 our @end;
 224 END {
 225     local ($?);
 226     return unless forkcheck_mainprocess();
 227     foreach my $f (@end) {
 228         eval { $f->(); };
 229         print STDERR "$us: cleanup: $@" if length $@;
 230     }
 231 };
 232
 233 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 234
 235 sub forceable_fail ($$) {
 236     my ($forceoptsl, $msg) = @_;
 237     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 238     print STDERR "warning: overriding problem due to --force:\n". $msg;
 239 }
 240
 241 sub forceing ($) {
 242     my ($forceoptsl) = @_;
 243     my @got = grep { $forceopts{$_} } @$forceoptsl;
 244     return 0 unless @got;
 245     print STDERR
 246  "warning: skipping checks or functionality due to --force-$got[0]\n";
 247 }
 248
 249 sub no_such_package () {
 250     print STDERR "$us: package $package does not exist in suite $isuite\n";
 251     exit 4;
 252 }
 253
 254 sub deliberately ($) {
 255     my ($enquiry) = @_;
 256     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 257 }
 258
 259 sub deliberately_not_fast_forward () {
 260     foreach (qw(not-fast-forward fresh-repo)) {
 261         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 262     }
 263 }
 264
 265 sub quiltmode_splitbrain () {
 266     $quilt_mode =~ m/gbp|dpm|unapplied/;
 267 }
 268
 269 sub opts_opt_multi_cmd {
 270     my @cmd;
 271     push @cmd, split /\s+/, shift @_;
 272     push @cmd, @_;
 273     @cmd;
 274 }
 275
 276 sub gbp_pq {
 277     return opts_opt_multi_cmd @gbp_pq;
 278 }
 279
 280 #---------- remote protocol support, common ----------
 281
 282 # remote push initiator/responder protocol:
 283 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 284 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 285 #  < dgit-remote-push-ready <actual-proto-vsn>
 286 #
 287 # occasionally:
 288 #
 289 #  > progress NBYTES
 290 #  [NBYTES message]
 291 #
 292 #  > supplementary-message NBYTES          # $protovsn >= 3
 293 #  [NBYTES message]
 294 #
 295 # main sequence:
 296 #
 297 #  > file parsed-changelog
 298 #  [indicates that output of dpkg-parsechangelog follows]
 299 #  > data-block NBYTES
 300 #  > [NBYTES bytes of data (no newline)]
 301 #  [maybe some more blocks]
 302 #  > data-end
 303 #
 304 #  > file dsc
 305 #  [etc]
 306 #
 307 #  > file changes
 308 #  [etc]
 309 #
 310 #  > param head DGIT-VIEW-HEAD
 311 #  > param csuite SUITE
 312 #  > param tagformat old|new
 313 #  > param maint-view MAINT-VIEW-HEAD
 314 #
 315 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 316 #  > file buildinfo                             # for buildinfos to sign
 317 #
 318 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 319 #                                     # goes into tag, for replay prevention
 320 #
 321 #  > want signed-tag
 322 #  [indicates that signed tag is wanted]
 323 #  < data-block NBYTES
 324 #  < [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  < data-end
 327 #  < files-end
 328 #
 329 #  > want signed-dsc-changes
 330 #  < data-block NBYTES    [transfer of signed dsc]
 331 #  [etc]
 332 #  < data-block NBYTES    [transfer of signed changes]
 333 #  [etc]
 334 #  < data-block NBYTES    [transfer of each signed buildinfo
 335 #  [etc]                   same number and order as "file buildinfo"]
 336 #  ...
 337 #  < files-end
 338 #
 339 #  > complete
 340
 341 our $i_child_pid;
 342
 343 sub i_child_report () {
 344     # Sees if our child has died, and reap it if so.  Returns a string
 345     # describing how it died if it failed, or undef otherwise.
 346     return undef unless $i_child_pid;
 347     my $got = waitpid $i_child_pid, WNOHANG;
 348     return undef if $got <= 0;
 349     die unless $got == $i_child_pid;
 350     $i_child_pid = undef;
 351     return undef unless $?;
 352     return "build host child ".waitstatusmsg();
 353 }
 354
 355 sub badproto ($$) {
 356     my ($fh, $m) = @_;
 357     fail "connection lost: $!" if $fh->error;
 358     fail "protocol violation; $m not expected";
 359 }
 360
 361 sub badproto_badread ($$) {
 362     my ($fh, $wh) = @_;
 363     fail "connection lost: $!" if $!;
 364     my $report = i_child_report();
 365     fail $report if defined $report;
 366     badproto $fh, "eof (reading $wh)";
 367 }
 368
 369 sub protocol_expect (&$) {
 370     my ($match, $fh) = @_;
 371     local $_;
 372     $_ = <$fh>;
 373     defined && chomp or badproto_badread $fh, "protocol message";
 374     if (wantarray) {
 375         my @r = &$match;
 376         return @r if @r;
 377     } else {
 378         my $r = &$match;
 379         return $r if $r;
 380     }
 381     badproto $fh, "\`$_'";
 382 }
 383
 384 sub protocol_send_file ($$) {
 385     my ($fh, $ourfn) = @_;
 386     open PF, "<", $ourfn or die "$ourfn: $!";
 387     for (;;) {
 388         my $d;
 389         my $got = read PF, $d, 65536;
 390         die "$ourfn: $!" unless defined $got;
 391         last if !$got;
 392         print $fh "data-block ".length($d)."\n" or die $!;
 393         print $fh $d or die $!;
 394     }
 395     PF->error and die "$ourfn $!";
 396     print $fh "data-end\n" or die $!;
 397     close PF;
 398 }
 399
 400 sub protocol_read_bytes ($$) {
 401     my ($fh, $nbytes) = @_;
 402     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 403     my $d;
 404     my $got = read $fh, $d, $nbytes;
 405     $got==$nbytes or badproto_badread $fh, "data block";
 406     return $d;
 407 }
 408
 409 sub protocol_receive_file ($$) {
 410     my ($fh, $ourfn) = @_;
 411     printdebug "() $ourfn\n";
 412     open PF, ">", $ourfn or die "$ourfn: $!";
 413     for (;;) {
 414         my ($y,$l) = protocol_expect {
 415             m/^data-block (.*)$/ ? (1,$1) :
 416             m/^data-end$/ ? (0,) :
 417             ();
 418         } $fh;
 419         last unless $y;
 420         my $d = protocol_read_bytes $fh, $l;
 421         print PF $d or die $!;
 422     }
 423     close PF or die $!;
 424 }
 425
 426 #---------- remote protocol support, responder ----------
 427
 428 sub responder_send_command ($) {
 429     my ($command) = @_;
 430     return unless $we_are_responder;
 431     # called even without $we_are_responder
 432     printdebug ">> $command\n";
 433     print PO $command, "\n" or die $!;
 434 }
 435
 436 sub responder_send_file ($$) {
 437     my ($keyword, $ourfn) = @_;
 438     return unless $we_are_responder;
 439     printdebug "]] $keyword $ourfn\n";
 440     responder_send_command "file $keyword";
 441     protocol_send_file \*PO, $ourfn;
 442 }
 443
 444 sub responder_receive_files ($@) {
 445     my ($keyword, @ourfns) = @_;
 446     die unless $we_are_responder;
 447     printdebug "[[ $keyword @ourfns\n";
 448     responder_send_command "want $keyword";
 449     foreach my $fn (@ourfns) {
 450         protocol_receive_file \*PI, $fn;
 451     }
 452     printdebug "[[\$\n";
 453     protocol_expect { m/^files-end$/ } \*PI;
 454 }
 455
 456 #---------- remote protocol support, initiator ----------
 457
 458 sub initiator_expect (&) {
 459     my ($match) = @_;
 460     protocol_expect { &$match } \*RO;
 461 }
 462
 463 #---------- end remote code ----------
 464
 465 sub progress {
 466     if ($we_are_responder) {
 467         my $m = join '', @_;
 468         responder_send_command "progress ".length($m) or die $!;
 469         print PO $m or die $!;
 470     } else {
 471         print @_, "\n";
 472     }
 473 }
 474
 475 our $ua;
 476
 477 sub url_get {
 478     if (!$ua) {
 479         $ua = LWP::UserAgent->new();
 480         $ua->env_proxy;
 481     }
 482     my $what = $_[$#_];
 483     progress "downloading $what...";
 484     my $r = $ua->get(@_) or die $!;
 485     return undef if $r->code == 404;
 486     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 487     return $r->decoded_content(charset => 'none');
 488 }
 489
 490 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 491
 492 sub act_local () { return $dryrun_level <= 1; }
 493 sub act_scary () { return !$dryrun_level; }
 494
 495 sub printdone {
 496     if (!$dryrun_level) {
 497         progress "$us ok: @_";
 498     } else {
 499         progress "would be ok: @_ (but dry run only)";
 500     }
 501 }
 502
 503 sub dryrun_report {
 504     printcmd(\*STDERR,$debugprefix."#",@_);
 505 }
 506
 507 sub runcmd_ordryrun {
 508     if (act_scary()) {
 509         runcmd @_;
 510     } else {
 511         dryrun_report @_;
 512     }
 513 }
 514
 515 sub runcmd_ordryrun_local {
 516     if (act_local()) {
 517         runcmd @_;
 518     } else {
 519         dryrun_report @_;
 520     }
 521 }
 522
 523 sub shell_cmd {
 524     my ($first_shell, @cmd) = @_;
 525     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 526 }
 527
 528 our $helpmsg = <<END;
 529 main usages:
 530   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 531   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 532   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 533   dgit [dgit-opts] sbuild [sbuild-opts]
 534   dgit [dgit-opts] push [dgit-opts] [suite]
 535   dgit [dgit-opts] rpush build-host:build-dir ...
 536 important dgit options:
 537   -k<keyid>           sign tag and package with <keyid> instead of default
 538   --dry-run -n        do not change anything, but go through the motions
 539   --damp-run -L       like --dry-run but make local changes, without signing
 540   --new -N            allow introducing a new package
 541   --debug -D          increase debug level
 542   -c<name>=<value>    set git config option (used directly by dgit too)
 543 END
 544
 545 our $later_warning_msg = <<END;
 546 Perhaps the upload is stuck in incoming.  Using the version from git.
 547 END
 548
 549 sub badusage {
 550     print STDERR "$us: @_\n", $helpmsg or die $!;
 551     exit 8;
 552 }
 553
 554 sub nextarg {
 555     @ARGV or badusage "too few arguments";
 556     return scalar shift @ARGV;
 557 }
 558
 559 sub pre_help () {
 560     no_local_git_cfg();
 561 }
 562 sub cmd_help () {
 563     print $helpmsg or die $!;
 564     exit 0;
 565 }
 566
 567 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 568
 569 our %defcfg = ('dgit.default.distro' => 'debian',
 570                'dgit.default.default-suite' => 'unstable',
 571                'dgit.default.old-dsc-distro' => 'debian',
 572                'dgit-suite.*-security.distro' => 'debian-security',
 573                'dgit.default.username' => '',
 574                'dgit.default.archive-query-default-component' => 'main',
 575                'dgit.default.ssh' => 'ssh',
 576                'dgit.default.archive-query' => 'madison:',
 577                'dgit.default.sshpsql-dbname' => 'service=projectb',
 578                'dgit.default.aptget-components' => 'main',
 579                'dgit.default.dgit-tag-format' => 'new,old,maint',
 580                'dgit.dsc-url-proto-ok.http'    => 'true',
 581                'dgit.dsc-url-proto-ok.https'   => 'true',
 582                'dgit.dsc-url-proto-ok.git'     => 'true',
 583                'dgit.default.dsc-url-proto-ok' => 'false',
 584                # old means "repo server accepts pushes with old dgit tags"
 585                # new means "repo server accepts pushes with new dgit tags"
 586                # maint means "repo server accepts split brain pushes"
 587                # hist means "repo server may have old pushes without new tag"
 588                #   ("hist" is implied by "old")
 589                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 590                'dgit-distro.debian.git-check' => 'url',
 591                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 592                'dgit-distro.debian.new-private-pushers' => 't',
 593                'dgit-distro.debian/push.git-url' => '',
 594                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 595                'dgit-distro.debian/push.git-user-force' => 'dgit',
 596                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 597                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 598                'dgit-distro.debian/push.git-create' => 'true',
 599                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 600  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 601 # 'dgit-distro.debian.archive-query-tls-key',
 602 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 603 # ^ this does not work because curl is broken nowadays
 604 # Fixing #790093 properly will involve providing providing the key
 605 # in some pacagke and maybe updating these paths.
 606 #
 607 # 'dgit-distro.debian.archive-query-tls-curl-args',
 608 #   '--ca-path=/etc/ssl/ca-debian',
 609 # ^ this is a workaround but works (only) on DSA-administered machines
 610                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 611                'dgit-distro.debian.git-url-suffix' => '',
 612                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 613                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 614  'dgit-distro.debian-security.archive-query' => 'aptget:',
 615  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 616  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 617  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 618  'dgit-distro.debian-security.nominal-distro' => 'debian',
 619  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 620  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 621                'dgit-distro.ubuntu.git-check' => 'false',
 622  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 623                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 624                'dgit-distro.test-dummy.username' => "alice",
 625                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 626                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 627                'dgit-distro.test-dummy.git-url' => "$td/git",
 628                'dgit-distro.test-dummy.git-host' => "git",
 629                'dgit-distro.test-dummy.git-path' => "$td/git",
 630                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 631                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 632                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 633                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 634                );
 635
 636 our %gitcfgs;
 637 our @gitcfgsources = qw(cmdline local global system);
 638
 639 sub git_slurp_config () {
 640     # This algoritm is a bit subtle, but this is needed so that for
 641     # options which we want to be single-valued, we allow the
 642     # different config sources to override properly.  See #835858.
 643     foreach my $src (@gitcfgsources) {
 644         next if $src eq 'cmdline';
 645         # we do this ourselves since git doesn't handle it
 646
 647         $gitcfgs{$src} = git_slurp_config_src $src;
 648     }
 649 }
 650
 651 sub git_get_config ($) {
 652     my ($c) = @_;
 653     foreach my $src (@gitcfgsources) {
 654         my $l = $gitcfgs{$src}{$c};
 655         confess "internal error ($l $c)" if $l && !ref $l;
 656         printdebug"C $c ".(defined $l ?
 657                            join " ", map { messagequote "'$_'" } @$l :
 658                            "undef")."\n"
 659             if $debuglevel >= 4;
 660         $l or next;
 661         @$l==1 or badcfg "multiple values for $c".
 662             " (in $src git config)" if @$l > 1;
 663         return $l->[0];
 664     }
 665     return undef;
 666 }
 667
 668 sub cfg {
 669     foreach my $c (@_) {
 670         return undef if $c =~ /RETURN-UNDEF/;
 671         printdebug "C? $c\n" if $debuglevel >= 5;
 672         my $v = git_get_config($c);
 673         return $v if defined $v;
 674         my $dv = $defcfg{$c};
 675         if (defined $dv) {
 676             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 677             return $dv;
 678         }
 679     }
 680     badcfg "need value for one of: @_\n".
 681         "$us: distro or suite appears not to be (properly) supported";
 682 }
 683
 684 sub no_local_git_cfg () {
 685     # needs to be called from pre_*
 686     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 687 }
 688
 689 sub access_basedistro__noalias () {
 690     if (defined $idistro) {
 691         return $idistro;
 692     } else {
 693         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 694         return $def if defined $def;
 695         foreach my $src (@gitcfgsources, 'internal') {
 696             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 697             next unless $kl;
 698             foreach my $k (keys %$kl) {
 699                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 700                 my $dpat = $1;
 701                 next unless match_glob $dpat, $isuite;
 702                 return $kl->{$k};
 703             }
 704         }
 705         return cfg("dgit.default.distro");
 706     }
 707 }
 708
 709 sub access_basedistro () {
 710     my $noalias = access_basedistro__noalias();
 711     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 712     return $canon // $noalias;
 713 }
 714
 715 sub access_nomdistro () {
 716     my $base = access_basedistro();
 717     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 718     $r =~ m/^$distro_re$/ or badcfg
 719  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 720     return $r;
 721 }
 722
 723 sub access_quirk () {
 724     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 725     my $basedistro = access_basedistro();
 726     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 727                               'RETURN-UNDEF');
 728     if (defined $backports_quirk) {
 729         my $re = $backports_quirk;
 730         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 731         $re =~ s/\*/.*/g;
 732         $re =~ s/\%/([-0-9a-z_]+)/
 733             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 734         if ($isuite =~ m/^$re$/) {
 735             return ('backports',"$basedistro-backports",$1);
 736         }
 737     }
 738     return ('none',undef);
 739 }
 740
 741 our $access_forpush;
 742
 743 sub parse_cfg_bool ($$$) {
 744     my ($what,$def,$v) = @_;
 745     $v //= $def;
 746     return
 747         $v =~ m/^[ty1]/ ? 1 :
 748         $v =~ m/^[fn0]/ ? 0 :
 749         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 750 }
 751
 752 sub access_forpush_config () {
 753     my $d = access_basedistro();
 754
 755     return 1 if
 756         $new_package &&
 757         parse_cfg_bool('new-private-pushers', 0,
 758                        cfg("dgit-distro.$d.new-private-pushers",
 759                            'RETURN-UNDEF'));
 760
 761     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 762     $v //= 'a';
 763     return
 764         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 765         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 766         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 767         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 768 }
 769
 770 sub access_forpush () {
 771     $access_forpush //= access_forpush_config();
 772     return $access_forpush;
 773 }
 774
 775 sub pushing () {
 776     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 777     badcfg "pushing but distro is configured readonly"
 778         if access_forpush_config() eq '0';
 779     $access_forpush = 1;
 780     $supplementary_message = <<'END' unless $we_are_responder;
 781 Push failed, before we got started.
 782 You can retry the push, after fixing the problem, if you like.
 783 END
 784     parseopts_late_defaults();
 785 }
 786
 787 sub notpushing () {
 788     parseopts_late_defaults();
 789 }
 790
 791 sub supplementary_message ($) {
 792     my ($msg) = @_;
 793     if (!$we_are_responder) {
 794         $supplementary_message = $msg;
 795         return;
 796     } elsif ($protovsn >= 3) {
 797         responder_send_command "supplementary-message ".length($msg)
 798             or die $!;
 799         print PO $msg or die $!;
 800     }
 801 }
 802
 803 sub access_distros () {
 804     # Returns list of distros to try, in order
 805     #
 806     # We want to try:
 807     #    0. `instead of' distro name(s) we have been pointed to
 808     #    1. the access_quirk distro, if any
 809     #    2a. the user's specified distro, or failing that  } basedistro
 810     #    2b. the distro calculated from the suite          }
 811     my @l = access_basedistro();
 812
 813     my (undef,$quirkdistro) = access_quirk();
 814     unshift @l, $quirkdistro;
 815     unshift @l, $instead_distro;
 816     @l = grep { defined } @l;
 817
 818     push @l, access_nomdistro();
 819
 820     if (access_forpush()) {
 821         @l = map { ("$_/push", $_) } @l;
 822     }
 823     @l;
 824 }
 825
 826 sub access_cfg_cfgs (@) {
 827     my (@keys) = @_;
 828     my @cfgs;
 829     # The nesting of these loops determines the search order.  We put
 830     # the key loop on the outside so that we search all the distros
 831     # for each key, before going on to the next key.  That means that
 832     # if access_cfg is called with a more specific, and then a less
 833     # specific, key, an earlier distro can override the less specific
 834     # without necessarily overriding any more specific keys.  (If the
 835     # distro wants to override the more specific keys it can simply do
 836     # so; whereas if we did the loop the other way around, it would be
 837     # impossible to for an earlier distro to override a less specific
 838     # key but not the more specific ones without restating the unknown
 839     # values of the more specific keys.
 840     my @realkeys;
 841     my @rundef;
 842     # We have to deal with RETURN-UNDEF specially, so that we don't
 843     # terminate the search prematurely.
 844     foreach (@keys) {
 845         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 846         push @realkeys, $_
 847     }
 848     foreach my $d (access_distros()) {
 849         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 850     }
 851     push @cfgs, map { "dgit.default.$_" } @realkeys;
 852     push @cfgs, @rundef;
 853     return @cfgs;
 854 }
 855
 856 sub access_cfg (@) {
 857     my (@keys) = @_;
 858     my (@cfgs) = access_cfg_cfgs(@keys);
 859     my $value = cfg(@cfgs);
 860     return $value;
 861 }
 862
 863 sub access_cfg_bool ($$) {
 864     my ($def, @keys) = @_;
 865     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 866 }
 867
 868 sub string_to_ssh ($) {
 869     my ($spec) = @_;
 870     if ($spec =~ m/\s/) {
 871         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 872     } else {
 873         return ($spec);
 874     }
 875 }
 876
 877 sub access_cfg_ssh () {
 878     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 879     if (!defined $gitssh) {
 880         return @ssh;
 881     } else {
 882         return string_to_ssh $gitssh;
 883     }
 884 }
 885
 886 sub access_runeinfo ($) {
 887     my ($info) = @_;
 888     return ": dgit ".access_basedistro()." $info ;";
 889 }
 890
 891 sub access_someuserhost ($) {
 892     my ($some) = @_;
 893     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 894     defined($user) && length($user) or
 895         $user = access_cfg("$some-user",'username');
 896     my $host = access_cfg("$some-host");
 897     return length($user) ? "$user\@$host" : $host;
 898 }
 899
 900 sub access_gituserhost () {
 901     return access_someuserhost('git');
 902 }
 903
 904 sub access_giturl (;$) {
 905     my ($optional) = @_;
 906     my $url = access_cfg('git-url','RETURN-UNDEF');
 907     my $suffix;
 908     if (!length $url) {
 909         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 910         return undef unless defined $proto;
 911         $url =
 912             $proto.
 913             access_gituserhost().
 914             access_cfg('git-path');
 915     } else {
 916         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 917     }
 918     $suffix //= '.git';
 919     return "$url/$package$suffix";
 920 }
 921
 922 sub parsecontrolfh ($$;$) {
 923     my ($fh, $desc, $allowsigned) = @_;
 924     our $dpkgcontrolhash_noissigned;
 925     my $c;
 926     for (;;) {
 927         my %opts = ('name' => $desc);
 928         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 929         $c = Dpkg::Control::Hash->new(%opts);
 930         $c->parse($fh,$desc) or die "parsing of $desc failed";
 931         last if $allowsigned;
 932         last if $dpkgcontrolhash_noissigned;
 933         my $issigned= $c->get_option('is_pgp_signed');
 934         if (!defined $issigned) {
 935             $dpkgcontrolhash_noissigned= 1;
 936             seek $fh, 0,0 or die "seek $desc: $!";
 937         } elsif ($issigned) {
 938             fail "control file $desc is (already) PGP-signed. ".
 939                 " Note that dgit push needs to modify the .dsc and then".
 940                 " do the signature itself";
 941         } else {
 942             last;
 943         }
 944     }
 945     return $c;
 946 }
 947
 948 sub parsecontrol {
 949     my ($file, $desc, $allowsigned) = @_;
 950     my $fh = new IO::Handle;
 951     open $fh, '<', $file or die "$file: $!";
 952     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 953     $fh->error and die $!;
 954     close $fh;
 955     return $c;
 956 }
 957
 958 sub getfield ($$) {
 959     my ($dctrl,$field) = @_;
 960     my $v = $dctrl->{$field};
 961     return $v if defined $v;
 962     fail "missing field $field in ".$dctrl->get_option('name');
 963 }
 964
 965 sub parsechangelog {
 966     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 967     my $p = new IO::Handle;
 968     my @cmd = (qw(dpkg-parsechangelog), @_);
 969     open $p, '-|', @cmd or die $!;
 970     $c->parse($p);
 971     $?=0; $!=0; close $p or failedcmd @cmd;
 972     return $c;
 973 }
 974
 975 sub commit_getclogp ($) {
 976     # Returns the parsed changelog hashref for a particular commit
 977     my ($objid) = @_;
 978     our %commit_getclogp_memo;
 979     my $memo = $commit_getclogp_memo{$objid};
 980     return $memo if $memo;
 981     mkpath '.git/dgit';
 982     my $mclog = ".git/dgit/clog-$objid";
 983     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 984         "$objid:debian/changelog";
 985     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 986 }
 987
 988 sub parse_dscdata () {
 989     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 990     printdebug Dumper($dscdata) if $debuglevel>1;
 991     $dsc = parsecontrolfh($dscfh,$dscurl,1);
 992     printdebug Dumper($dsc) if $debuglevel>1;
 993 }
 994
 995 our %rmad;
 996
 997 sub archive_query ($;@) {
 998     my ($method) = shift @_;
 999     fail "this operation does not support multiple comma-separated suites"
1000         if $isuite =~ m/,/;
1001     my $query = access_cfg('archive-query','RETURN-UNDEF');
1002     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1003     my $proto = $1;
1004     my $data = $'; #';
1005     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1006 }
1007
1008 sub archive_query_prepend_mirror {
1009     my $m = access_cfg('mirror');
1010     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1011 }
1012
1013 sub pool_dsc_subpath ($$) {
1014     my ($vsn,$component) = @_; # $package is implict arg
1015     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1016     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1017 }
1018
1019 sub cfg_apply_map ($$$) {
1020     my ($varref, $what, $mapspec) = @_;
1021     return unless $mapspec;
1022
1023     printdebug "config $what EVAL{ $mapspec; }\n";
1024     $_ = $$varref;
1025     eval "package Dgit::Config; $mapspec;";
1026     die $@ if $@;
1027     $$varref = $_;
1028 }
1029
1030 #---------- `ftpmasterapi' archive query method (nascent) ----------
1031
1032 sub archive_api_query_cmd ($) {
1033     my ($subpath) = @_;
1034     my @cmd = (@curl, qw(-sS));
1035     my $url = access_cfg('archive-query-url');
1036     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1037         my $host = $1;
1038         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1039         foreach my $key (split /\:/, $keys) {
1040             $key =~ s/\%HOST\%/$host/g;
1041             if (!stat $key) {
1042                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1043                 next;
1044             }
1045             fail "config requested specific TLS key but do not know".
1046                 " how to get curl to use exactly that EE key ($key)";
1047 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1048 #           # Sadly the above line does not work because of changes
1049 #           # to gnutls.   The real fix for #790093 may involve
1050 #           # new curl options.
1051             last;
1052         }
1053         # Fixing #790093 properly will involve providing a value
1054         # for this on clients.
1055         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1056         push @cmd, split / /, $kargs if defined $kargs;
1057     }
1058     push @cmd, $url.$subpath;
1059     return @cmd;
1060 }
1061
1062 sub api_query ($$;$) {
1063     use JSON;
1064     my ($data, $subpath, $ok404) = @_;
1065     badcfg "ftpmasterapi archive query method takes no data part"
1066         if length $data;
1067     my @cmd = archive_api_query_cmd($subpath);
1068     my $url = $cmd[$#cmd];
1069     push @cmd, qw(-w %{http_code});
1070     my $json = cmdoutput @cmd;
1071     unless ($json =~ s/\d+\d+\d$//) {
1072         failedcmd_report_cmd undef, @cmd;
1073         fail "curl failed to print 3-digit HTTP code";
1074     }
1075     my $code = $&;
1076     return undef if $code eq '404' && $ok404;
1077     fail "fetch of $url gave HTTP code $code"
1078         unless $url =~ m#^file://# or $code =~ m/^2/;
1079     return decode_json($json);
1080 }
1081
1082 sub canonicalise_suite_ftpmasterapi {
1083     my ($proto,$data) = @_;
1084     my $suites = api_query($data, 'suites');
1085     my @matched;
1086     foreach my $entry (@$suites) {
1087         next unless grep {
1088             my $v = $entry->{$_};
1089             defined $v && $v eq $isuite;
1090         } qw(codename name);
1091         push @matched, $entry;
1092     }
1093     fail "unknown suite $isuite" unless @matched;
1094     my $cn;
1095     eval {
1096         @matched==1 or die "multiple matches for suite $isuite\n";
1097         $cn = "$matched[0]{codename}";
1098         defined $cn or die "suite $isuite info has no codename\n";
1099         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1100     };
1101     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1102         if length $@;
1103     return $cn;
1104 }
1105
1106 sub archive_query_ftpmasterapi {
1107     my ($proto,$data) = @_;
1108     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1109     my @rows;
1110     my $digester = Digest::SHA->new(256);
1111     foreach my $entry (@$info) {
1112         eval {
1113             my $vsn = "$entry->{version}";
1114             my ($ok,$msg) = version_check $vsn;
1115             die "bad version: $msg\n" unless $ok;
1116             my $component = "$entry->{component}";
1117             $component =~ m/^$component_re$/ or die "bad component";
1118             my $filename = "$entry->{filename}";
1119             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1120                 or die "bad filename";
1121             my $sha256sum = "$entry->{sha256sum}";
1122             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1123             push @rows, [ $vsn, "/pool/$component/$filename",
1124                           $digester, $sha256sum ];
1125         };
1126         die "bad ftpmaster api response: $@\n".Dumper($entry)
1127             if length $@;
1128     }
1129     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1130     return archive_query_prepend_mirror @rows;
1131 }
1132
1133 sub file_in_archive_ftpmasterapi {
1134     my ($proto,$data,$filename) = @_;
1135     my $pat = $filename;
1136     $pat =~ s/_/\\_/g;
1137     $pat = "%/$pat";
1138     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1139     my $info = api_query($data, "file_in_archive/$pat", 1);
1140 }
1141
1142 #---------- `aptget' archive query method ----------
1143
1144 our $aptget_base;
1145 our $aptget_releasefile;
1146 our $aptget_configpath;
1147
1148 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1149 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1150
1151 sub aptget_cache_clean {
1152     runcmd_ordryrun_local qw(sh -ec),
1153         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1154         'x', $aptget_base;
1155 }
1156
1157 sub aptget_lock_acquire () {
1158     my $lockfile = "$aptget_base/lock";
1159     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1160     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1161 }
1162
1163 sub aptget_prep ($) {
1164     my ($data) = @_;
1165     return if defined $aptget_base;
1166
1167     badcfg "aptget archive query method takes no data part"
1168         if length $data;
1169
1170     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1171
1172     ensuredir $cache;
1173     ensuredir "$cache/dgit";
1174     my $cachekey =
1175         access_cfg('aptget-cachekey','RETURN-UNDEF')
1176         // access_nomdistro();
1177
1178     $aptget_base = "$cache/dgit/aptget";
1179     ensuredir $aptget_base;
1180
1181     my $quoted_base = $aptget_base;
1182     die "$quoted_base contains bad chars, cannot continue"
1183         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1184
1185     ensuredir $aptget_base;
1186
1187     aptget_lock_acquire();
1188
1189     aptget_cache_clean();
1190
1191     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1192     my $sourceslist = "source.list#$cachekey";
1193
1194     my $aptsuites = $isuite;
1195     cfg_apply_map(\$aptsuites, 'suite map',
1196                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1197
1198     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1199     printf SRCS "deb-src %s %s %s\n",
1200         access_cfg('mirror'),
1201         $aptsuites,
1202         access_cfg('aptget-components')
1203         or die $!;
1204
1205     ensuredir "$aptget_base/cache";
1206     ensuredir "$aptget_base/lists";
1207
1208     open CONF, ">", $aptget_configpath or die $!;
1209     print CONF <<END;
1210 Debug::NoLocking "true";
1211 APT::Get::List-Cleanup "false";
1212 #clear APT::Update::Post-Invoke-Success;
1213 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1214 Dir::State::Lists "$quoted_base/lists";
1215 Dir::Etc::preferences "$quoted_base/preferences";
1216 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1217 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1218 END
1219
1220     foreach my $key (qw(
1221                         Dir::Cache
1222                         Dir::State
1223                         Dir::Cache::Archives
1224                         Dir::Etc::SourceParts
1225                         Dir::Etc::preferencesparts
1226                       )) {
1227         ensuredir "$aptget_base/$key";
1228         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1229     };
1230
1231     my $oldatime = (time // die $!) - 1;
1232     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1233         next unless stat_exists $oldlist;
1234         my ($mtime) = (stat _)[9];
1235         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1236     }
1237
1238     runcmd_ordryrun_local aptget_aptget(), qw(update);
1239
1240     my @releasefiles;
1241     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1242         next unless stat_exists $oldlist;
1243         my ($atime) = (stat _)[8];
1244         next if $atime == $oldatime;
1245         push @releasefiles, $oldlist;
1246     }
1247     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1248     @releasefiles = @inreleasefiles if @inreleasefiles;
1249     die "apt updated wrong number of Release files (@releasefiles), erk"
1250         unless @releasefiles == 1;
1251
1252     ($aptget_releasefile) = @releasefiles;
1253 }
1254
1255 sub canonicalise_suite_aptget {
1256     my ($proto,$data) = @_;
1257     aptget_prep($data);
1258
1259     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1260
1261     foreach my $name (qw(Codename Suite)) {
1262         my $val = $release->{$name};
1263         if (defined $val) {
1264             printdebug "release file $name: $val\n";
1265             $val =~ m/^$suite_re$/o or fail
1266  "Release file ($aptget_releasefile) specifies intolerable $name";
1267             cfg_apply_map(\$val, 'suite rmap',
1268                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1269             return $val
1270         }
1271     }
1272     return $isuite;
1273 }
1274
1275 sub archive_query_aptget {
1276     my ($proto,$data) = @_;
1277     aptget_prep($data);
1278
1279     ensuredir "$aptget_base/source";
1280     foreach my $old (<$aptget_base/source/*.dsc>) {
1281         unlink $old or die "$old: $!";
1282     }
1283
1284     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1285     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1286     # avoids apt-get source failing with ambiguous error code
1287
1288     runcmd_ordryrun_local
1289         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1290         aptget_aptget(), qw(--download-only --only-source source), $package;
1291
1292     my @dscs = <$aptget_base/source/*.dsc>;
1293     fail "apt-get source did not produce a .dsc" unless @dscs;
1294     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1295
1296     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1297
1298     use URI::Escape;
1299     my $uri = "file://". uri_escape $dscs[0];
1300     $uri =~ s{\%2f}{/}gi;
1301     return [ (getfield $pre_dsc, 'Version'), $uri ];
1302 }
1303
1304 sub file_in_archive_aptget () { return undef; }
1305
1306 #---------- `dummyapicat' archive query method ----------
1307
1308 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1309 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1310
1311 sub file_in_archive_dummycatapi ($$$) {
1312     my ($proto,$data,$filename) = @_;
1313     my $mirror = access_cfg('mirror');
1314     $mirror =~ s#^file://#/# or die "$mirror ?";
1315     my @out;
1316     my @cmd = (qw(sh -ec), '
1317             cd "$1"
1318             find -name "$2" -print0 |
1319             xargs -0r sha256sum
1320         ', qw(x), $mirror, $filename);
1321     debugcmd "-|", @cmd;
1322     open FIA, "-|", @cmd or die $!;
1323     while (<FIA>) {
1324         chomp or die;
1325         printdebug "| $_\n";
1326         m/^(\w+)  (\S+)$/ or die "$_ ?";
1327         push @out, { sha256sum => $1, filename => $2 };
1328     }
1329     close FIA or die failedcmd @cmd;
1330     return \@out;
1331 }
1332
1333 #---------- `madison' archive query method ----------
1334
1335 sub archive_query_madison {
1336     return archive_query_prepend_mirror
1337         map { [ @$_[0..1] ] } madison_get_parse(@_);
1338 }
1339
1340 sub madison_get_parse {
1341     my ($proto,$data) = @_;
1342     die unless $proto eq 'madison';
1343     if (!length $data) {
1344         $data= access_cfg('madison-distro','RETURN-UNDEF');
1345         $data //= access_basedistro();
1346     }
1347     $rmad{$proto,$data,$package} ||= cmdoutput
1348         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1349     my $rmad = $rmad{$proto,$data,$package};
1350
1351     my @out;
1352     foreach my $l (split /\n/, $rmad) {
1353         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1354                   \s*( [^ \t|]+ )\s* \|
1355                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1356                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1357         $1 eq $package or die "$rmad $package ?";
1358         my $vsn = $2;
1359         my $newsuite = $3;
1360         my $component;
1361         if (defined $4) {
1362             $component = $4;
1363         } else {
1364             $component = access_cfg('archive-query-default-component');
1365         }
1366         $5 eq 'source' or die "$rmad ?";
1367         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1368     }
1369     return sort { -version_compare($a->[0],$b->[0]); } @out;
1370 }
1371
1372 sub canonicalise_suite_madison {
1373     # madison canonicalises for us
1374     my @r = madison_get_parse(@_);
1375     @r or fail
1376         "unable to canonicalise suite using package $package".
1377         " which does not appear to exist in suite $isuite;".
1378         " --existing-package may help";
1379     return $r[0][2];
1380 }
1381
1382 sub file_in_archive_madison { return undef; }
1383
1384 #---------- `sshpsql' archive query method ----------
1385
1386 sub sshpsql ($$$) {
1387     my ($data,$runeinfo,$sql) = @_;
1388     if (!length $data) {
1389         $data= access_someuserhost('sshpsql').':'.
1390             access_cfg('sshpsql-dbname');
1391     }
1392     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1393     my ($userhost,$dbname) = ($`,$'); #';
1394     my @rows;
1395     my @cmd = (access_cfg_ssh, $userhost,
1396                access_runeinfo("ssh-psql $runeinfo").
1397                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1398                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1399     debugcmd "|",@cmd;
1400     open P, "-|", @cmd or die $!;
1401     while (<P>) {
1402         chomp or die;
1403         printdebug(">|$_|\n");
1404         push @rows, $_;
1405     }
1406     $!=0; $?=0; close P or failedcmd @cmd;
1407     @rows or die;
1408     my $nrows = pop @rows;
1409     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1410     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1411     @rows = map { [ split /\|/, $_ ] } @rows;
1412     my $ncols = scalar @{ shift @rows };
1413     die if grep { scalar @$_ != $ncols } @rows;
1414     return @rows;
1415 }
1416
1417 sub sql_injection_check {
1418     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1419 }
1420
1421 sub archive_query_sshpsql ($$) {
1422     my ($proto,$data) = @_;
1423     sql_injection_check $isuite, $package;
1424     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1425         SELECT source.version, component.name, files.filename, files.sha256sum
1426           FROM source
1427           JOIN src_associations ON source.id = src_associations.source
1428           JOIN suite ON suite.id = src_associations.suite
1429           JOIN dsc_files ON dsc_files.source = source.id
1430           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1431           JOIN component ON component.id = files_archive_map.component_id
1432           JOIN files ON files.id = dsc_files.file
1433          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1434            AND source.source='$package'
1435            AND files.filename LIKE '%.dsc';
1436 END
1437     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1438     my $digester = Digest::SHA->new(256);
1439     @rows = map {
1440         my ($vsn,$component,$filename,$sha256sum) = @$_;
1441         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1442     } @rows;
1443     return archive_query_prepend_mirror @rows;
1444 }
1445
1446 sub canonicalise_suite_sshpsql ($$) {
1447     my ($proto,$data) = @_;
1448     sql_injection_check $isuite;
1449     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1450         SELECT suite.codename
1451           FROM suite where suite_name='$isuite' or codename='$isuite';
1452 END
1453     @rows = map { $_->[0] } @rows;
1454     fail "unknown suite $isuite" unless @rows;
1455     die "ambiguous $isuite: @rows ?" if @rows>1;
1456     return $rows[0];
1457 }
1458
1459 sub file_in_archive_sshpsql ($$$) { return undef; }
1460
1461 #---------- `dummycat' archive query method ----------
1462
1463 sub canonicalise_suite_dummycat ($$) {
1464     my ($proto,$data) = @_;
1465     my $dpath = "$data/suite.$isuite";
1466     if (!open C, "<", $dpath) {
1467         $!==ENOENT or die "$dpath: $!";
1468         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1469         return $isuite;
1470     }
1471     $!=0; $_ = <C>;
1472     chomp or die "$dpath: $!";
1473     close C;
1474     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1475     return $_;
1476 }
1477
1478 sub archive_query_dummycat ($$) {
1479     my ($proto,$data) = @_;
1480     canonicalise_suite();
1481     my $dpath = "$data/package.$csuite.$package";
1482     if (!open C, "<", $dpath) {
1483         $!==ENOENT or die "$dpath: $!";
1484         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1485         return ();
1486     }
1487     my @rows;
1488     while (<C>) {
1489         next if m/^\#/;
1490         next unless m/\S/;
1491         die unless chomp;
1492         printdebug "dummycat query $csuite $package $dpath | $_\n";
1493         my @row = split /\s+/, $_;
1494         @row==2 or die "$dpath: $_ ?";
1495         push @rows, \@row;
1496     }
1497     C->error and die "$dpath: $!";
1498     close C;
1499     return archive_query_prepend_mirror
1500         sort { -version_compare($a->[0],$b->[0]); } @rows;
1501 }
1502
1503 sub file_in_archive_dummycat () { return undef; }
1504
1505 #---------- tag format handling ----------
1506
1507 sub access_cfg_tagformats () {
1508     split /\,/, access_cfg('dgit-tag-format');
1509 }
1510
1511 sub access_cfg_tagformats_can_splitbrain () {
1512     my %y = map { $_ => 1 } access_cfg_tagformats;
1513     foreach my $needtf (qw(new maint)) {
1514         next if $y{$needtf};
1515         return 0;
1516     }
1517     return 1;
1518 }
1519
1520 sub need_tagformat ($$) {
1521     my ($fmt, $why) = @_;
1522     fail "need to use tag format $fmt ($why) but also need".
1523         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1524         " - no way to proceed"
1525         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1526     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1527 }
1528
1529 sub select_tagformat () {
1530     # sets $tagformatfn
1531     return if $tagformatfn && !$tagformat_want;
1532     die 'bug' if $tagformatfn && $tagformat_want;
1533     # ... $tagformat_want assigned after previous select_tagformat
1534
1535     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1536     printdebug "select_tagformat supported @supported\n";
1537
1538     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1539     printdebug "select_tagformat specified @$tagformat_want\n";
1540
1541     my ($fmt,$why,$override) = @$tagformat_want;
1542
1543     fail "target distro supports tag formats @supported".
1544         " but have to use $fmt ($why)"
1545         unless $override
1546             or grep { $_ eq $fmt } @supported;
1547
1548     $tagformat_want = undef;
1549     $tagformat = $fmt;
1550     $tagformatfn = ${*::}{"debiantag_$fmt"};
1551
1552     fail "trying to use unknown tag format \`$fmt' ($why) !"
1553         unless $tagformatfn;
1554 }
1555
1556 #---------- archive query entrypoints and rest of program ----------
1557
1558 sub canonicalise_suite () {
1559     return if defined $csuite;
1560     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1561     $csuite = archive_query('canonicalise_suite');
1562     if ($isuite ne $csuite) {
1563         progress "canonical suite name for $isuite is $csuite";
1564     } else {
1565         progress "canonical suite name is $csuite";
1566     }
1567 }
1568
1569 sub get_archive_dsc () {
1570     canonicalise_suite();
1571     my @vsns = archive_query('archive_query');
1572     foreach my $vinfo (@vsns) {
1573         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1574         $dscurl = $vsn_dscurl;
1575         $dscdata = url_get($dscurl);
1576         if (!$dscdata) {
1577             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1578             next;
1579         }
1580         if ($digester) {
1581             $digester->reset();
1582             $digester->add($dscdata);
1583             my $got = $digester->hexdigest();
1584             $got eq $digest or
1585                 fail "$dscurl has hash $got but".
1586                     " archive told us to expect $digest";
1587         }
1588         parse_dscdata();
1589         my $fmt = getfield $dsc, 'Format';
1590         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1591             "unsupported source format $fmt, sorry";
1592
1593         $dsc_checked = !!$digester;
1594         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1595         return;
1596     }
1597     $dsc = undef;
1598     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1599 }
1600
1601 sub check_for_git ();
1602 sub check_for_git () {
1603     # returns 0 or 1
1604     my $how = access_cfg('git-check');
1605     if ($how eq 'ssh-cmd') {
1606         my @cmd =
1607             (access_cfg_ssh, access_gituserhost(),
1608              access_runeinfo("git-check $package").
1609              " set -e; cd ".access_cfg('git-path').";".
1610              " if test -d $package.git; then echo 1; else echo 0; fi");
1611         my $r= cmdoutput @cmd;
1612         if (defined $r and $r =~ m/^divert (\w+)$/) {
1613             my $divert=$1;
1614             my ($usedistro,) = access_distros();
1615             # NB that if we are pushing, $usedistro will be $distro/push
1616             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1617             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1618             progress "diverting to $divert (using config for $instead_distro)";
1619             return check_for_git();
1620         }
1621         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1622         return $r+0;
1623     } elsif ($how eq 'url') {
1624         my $prefix = access_cfg('git-check-url','git-url');
1625         my $suffix = access_cfg('git-check-suffix','git-suffix',
1626                                 'RETURN-UNDEF') // '.git';
1627         my $url = "$prefix/$package$suffix";
1628         my @cmd = (@curl, qw(-sS -I), $url);
1629         my $result = cmdoutput @cmd;
1630         $result =~ s/^\S+ 200 .*\n\r?\n//;
1631         # curl -sS -I with https_proxy prints
1632         # HTTP/1.0 200 Connection established
1633         $result =~ m/^\S+ (404|200) /s or
1634             fail "unexpected results from git check query - ".
1635                 Dumper($prefix, $result);
1636         my $code = $1;
1637         if ($code eq '404') {
1638             return 0;
1639         } elsif ($code eq '200') {
1640             return 1;
1641         } else {
1642             die;
1643         }
1644     } elsif ($how eq 'true') {
1645         return 1;
1646     } elsif ($how eq 'false') {
1647         return 0;
1648     } else {
1649         badcfg "unknown git-check \`$how'";
1650     }
1651 }
1652
1653 sub create_remote_git_repo () {
1654     my $how = access_cfg('git-create');
1655     if ($how eq 'ssh-cmd') {
1656         runcmd_ordryrun
1657             (access_cfg_ssh, access_gituserhost(),
1658              access_runeinfo("git-create $package").
1659              "set -e; cd ".access_cfg('git-path').";".
1660              " cp -a _template $package.git");
1661     } elsif ($how eq 'true') {
1662         # nothing to do
1663     } else {
1664         badcfg "unknown git-create \`$how'";
1665     }
1666 }
1667
1668 our ($dsc_hash,$lastpush_mergeinput);
1669 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1670
1671 our $ud = '.git/dgit/unpack';
1672
1673 sub prep_ud () {
1674     my $d = $ud;
1675     rmtree($d);
1676     mkpath '.git/dgit';
1677     mkdir $d or die $!;
1678 }
1679
1680 sub mktree_in_ud_here () {
1681     playtree_setup $gitcfgs{local};
1682 }
1683
1684 sub git_write_tree () {
1685     my $tree = cmdoutput @git, qw(write-tree);
1686     $tree =~ m/^\w+$/ or die "$tree ?";
1687     return $tree;
1688 }
1689
1690 sub git_add_write_tree () {
1691     runcmd @git, qw(add -Af .);
1692     return git_write_tree();
1693 }
1694
1695 sub remove_stray_gits ($) {
1696     my ($what) = @_;
1697     my @gitscmd = qw(find -name .git -prune -print0);
1698     debugcmd "|",@gitscmd;
1699     open GITS, "-|", @gitscmd or die $!;
1700     {
1701         local $/="\0";
1702         while (<GITS>) {
1703             chomp or die;
1704             print STDERR "$us: warning: removing from $what: ",
1705                 (messagequote $_), "\n";
1706             rmtree $_;
1707         }
1708     }
1709     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1710 }
1711
1712 sub mktree_in_ud_from_only_subdir ($;$) {
1713     my ($what,$raw) = @_;
1714
1715     # changes into the subdir
1716     my (@dirs) = <*/.>;
1717     die "expected one subdir but found @dirs ?" unless @dirs==1;
1718     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1719     my $dir = $1;
1720     changedir $dir;
1721
1722     remove_stray_gits($what);
1723     mktree_in_ud_here();
1724     if (!$raw) {
1725         my ($format, $fopts) = get_source_format();
1726         if (madformat($format)) {
1727             rmtree '.pc';
1728         }
1729     }
1730
1731     my $tree=git_add_write_tree();
1732     return ($tree,$dir);
1733 }
1734
1735 our @files_csum_info_fields =
1736     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1737      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1738      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1739
1740 sub dsc_files_info () {
1741     foreach my $csumi (@files_csum_info_fields) {
1742         my ($fname, $module, $method) = @$csumi;
1743         my $field = $dsc->{$fname};
1744         next unless defined $field;
1745         eval "use $module; 1;" or die $@;
1746         my @out;
1747         foreach (split /\n/, $field) {
1748             next unless m/\S/;
1749             m/^(\w+) (\d+) (\S+)$/ or
1750                 fail "could not parse .dsc $fname line \`$_'";
1751             my $digester = eval "$module"."->$method;" or die $@;
1752             push @out, {
1753                 Hash => $1,
1754                 Bytes => $2,
1755                 Filename => $3,
1756                 Digester => $digester,
1757             };
1758         }
1759         return @out;
1760     }
1761     fail "missing any supported Checksums-* or Files field in ".
1762         $dsc->get_option('name');
1763 }
1764
1765 sub dsc_files () {
1766     map { $_->{Filename} } dsc_files_info();
1767 }
1768
1769 sub files_compare_inputs (@) {
1770     my $inputs = \@_;
1771     my %record;
1772     my %fchecked;
1773
1774     my $showinputs = sub {
1775         return join "; ", map { $_->get_option('name') } @$inputs;
1776     };
1777
1778     foreach my $in (@$inputs) {
1779         my $expected_files;
1780         my $in_name = $in->get_option('name');
1781
1782         printdebug "files_compare_inputs $in_name\n";
1783
1784         foreach my $csumi (@files_csum_info_fields) {
1785             my ($fname) = @$csumi;
1786             printdebug "files_compare_inputs $in_name $fname\n";
1787
1788             my $field = $in->{$fname};
1789             next unless defined $field;
1790
1791             my @files;
1792             foreach (split /\n/, $field) {
1793                 next unless m/\S/;
1794
1795                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1796                     fail "could not parse $in_name $fname line \`$_'";
1797
1798                 printdebug "files_compare_inputs $in_name $fname $f\n";
1799
1800                 push @files, $f;
1801
1802                 my $re = \ $record{$f}{$fname};
1803                 if (defined $$re) {
1804                     $fchecked{$f}{$in_name} = 1;
1805                     $$re eq $info or
1806                         fail "hash or size of $f varies in $fname fields".
1807                         " (between: ".$showinputs->().")";
1808                 } else {
1809                     $$re = $info;
1810                 }
1811             }
1812             @files = sort @files;
1813             $expected_files //= \@files;
1814             "@$expected_files" eq "@files" or
1815                 fail "file list in $in_name varies between hash fields!";
1816         }
1817         $expected_files or
1818             fail "$in_name has no files list field(s)";
1819     }
1820     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1821         if $debuglevel>=2;
1822
1823     grep { keys %$_ == @$inputs-1 } values %fchecked
1824         or fail "no file appears in all file lists".
1825         " (looked in: ".$showinputs->().")";
1826 }
1827
1828 sub is_orig_file_in_dsc ($$) {
1829     my ($f, $dsc_files_info) = @_;
1830     return 0 if @$dsc_files_info <= 1;
1831     # One file means no origs, and the filename doesn't have a "what
1832     # part of dsc" component.  (Consider versions ending `.orig'.)
1833     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1834     return 1;
1835 }
1836
1837 sub is_orig_file_of_vsn ($$) {
1838     my ($f, $upstreamvsn) = @_;
1839     my $base = srcfn $upstreamvsn, '';
1840     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1841     return 1;
1842 }
1843
1844 sub changes_update_origs_from_dsc ($$$$) {
1845     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1846     my %changes_f;
1847     printdebug "checking origs needed ($upstreamvsn)...\n";
1848     $_ = getfield $changes, 'Files';
1849     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1850         fail "cannot find section/priority from .changes Files field";
1851     my $placementinfo = $1;
1852     my %changed;
1853     printdebug "checking origs needed placement '$placementinfo'...\n";
1854     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1855         $l =~ m/\S+$/ or next;
1856         my $file = $&;
1857         printdebug "origs $file | $l\n";
1858         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1859         printdebug "origs $file is_orig\n";
1860         my $have = archive_query('file_in_archive', $file);
1861         if (!defined $have) {
1862             print STDERR <<END;
1863 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1864 END
1865             return;
1866         }
1867         my $found_same = 0;
1868         my @found_differ;
1869         printdebug "origs $file \$#\$have=$#$have\n";
1870         foreach my $h (@$have) {
1871             my $same = 0;
1872             my @differ;
1873             foreach my $csumi (@files_csum_info_fields) {
1874                 my ($fname, $module, $method, $archivefield) = @$csumi;
1875                 next unless defined $h->{$archivefield};
1876                 $_ = $dsc->{$fname};
1877                 next unless defined;
1878                 m/^(\w+) .* \Q$file\E$/m or
1879                     fail ".dsc $fname missing entry for $file";
1880                 if ($h->{$archivefield} eq $1) {
1881                     $same++;
1882                 } else {
1883                     push @differ,
1884  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1885                 }
1886             }
1887             die "$file ".Dumper($h)." ?!" if $same && @differ;
1888             $found_same++
1889                 if $same;
1890             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1891                 if @differ;
1892         }
1893         printdebug "origs $file f.same=$found_same".
1894             " #f._differ=$#found_differ\n";
1895         if (@found_differ && !$found_same) {
1896             fail join "\n",
1897                 "archive contains $file with different checksum",
1898                 @found_differ;
1899         }
1900         # Now we edit the changes file to add or remove it
1901         foreach my $csumi (@files_csum_info_fields) {
1902             my ($fname, $module, $method, $archivefield) = @$csumi;
1903             next unless defined $changes->{$fname};
1904             if ($found_same) {
1905                 # in archive, delete from .changes if it's there
1906                 $changed{$file} = "removed" if
1907                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1908             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1909                 # not in archive, but it's here in the .changes
1910             } else {
1911                 my $dsc_data = getfield $dsc, $fname;
1912                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1913                 my $extra = $1;
1914                 $extra =~ s/ \d+ /$&$placementinfo /
1915                     or die "$fname $extra >$dsc_data< ?"
1916                     if $fname eq 'Files';
1917                 $changes->{$fname} .= "\n". $extra;
1918                 $changed{$file} = "added";
1919             }
1920         }
1921     }
1922     if (%changed) {
1923         foreach my $file (keys %changed) {
1924             progress sprintf
1925                 "edited .changes for archive .orig contents: %s %s",
1926                 $changed{$file}, $file;
1927         }
1928         my $chtmp = "$changesfile.tmp";
1929         $changes->save($chtmp);
1930         if (act_local()) {
1931             rename $chtmp,$changesfile or die "$changesfile $!";
1932         } else {
1933             progress "[new .changes left in $changesfile]";
1934         }
1935     } else {
1936         progress "$changesfile already has appropriate .orig(s) (if any)";
1937     }
1938 }
1939
1940 sub make_commit ($) {
1941     my ($file) = @_;
1942     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1943 }
1944
1945 sub make_commit_text ($) {
1946     my ($text) = @_;
1947     my ($out, $in);
1948     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1949     debugcmd "|",@cmd;
1950     print Dumper($text) if $debuglevel > 1;
1951     my $child = open2($out, $in, @cmd) or die $!;
1952     my $h;
1953     eval {
1954         print $in $text or die $!;
1955         close $in or die $!;
1956         $h = <$out>;
1957         $h =~ m/^\w+$/ or die;
1958         $h = $&;
1959         printdebug "=> $h\n";
1960     };
1961     close $out;
1962     waitpid $child, 0 == $child or die "$child $!";
1963     $? and failedcmd @cmd;
1964     return $h;
1965 }
1966
1967 sub clogp_authline ($) {
1968     my ($clogp) = @_;
1969     my $author = getfield $clogp, 'Maintainer';
1970     if ($author =~ m/^[^"\@]+\,/) {
1971         # single entry Maintainer field with unquoted comma
1972         $author = ($& =~ y/,//rd).$'; # strip the comma
1973     }
1974     # git wants a single author; any remaining commas in $author
1975     # are by now preceded by @ (or ").  It seems safer to punt on
1976     # "..." for now rather than attempting to dequote or something.
1977     $author =~ s#,.*##ms unless $author =~ m/"/;
1978     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1979     my $authline = "$author $date";
1980     $authline =~ m/$git_authline_re/o or
1981         fail "unexpected commit author line format \`$authline'".
1982         " (was generated from changelog Maintainer field)";
1983     return ($1,$2,$3) if wantarray;
1984     return $authline;
1985 }
1986
1987 sub vendor_patches_distro ($$) {
1988     my ($checkdistro, $what) = @_;
1989     return unless defined $checkdistro;
1990
1991     my $series = "debian/patches/\L$checkdistro\E.series";
1992     printdebug "checking for vendor-specific $series ($what)\n";
1993
1994     if (!open SERIES, "<", $series) {
1995         die "$series $!" unless $!==ENOENT;
1996         return;
1997     }
1998     while (<SERIES>) {
1999         next unless m/\S/;
2000         next if m/^\s+\#/;
2001
2002         print STDERR <<END;
2003
2004 Unfortunately, this source package uses a feature of dpkg-source where
2005 the same source package unpacks to different source code on different
2006 distros.  dgit cannot safely operate on such packages on affected
2007 distros, because the meaning of source packages is not stable.
2008
2009 Please ask the distro/maintainer to remove the distro-specific series
2010 files and use a different technique (if necessary, uploading actually
2011 different packages, if different distros are supposed to have
2012 different code).
2013
2014 END
2015         fail "Found active distro-specific series file for".
2016             " $checkdistro ($what): $series, cannot continue";
2017     }
2018     die "$series $!" if SERIES->error;
2019     close SERIES;
2020 }
2021
2022 sub check_for_vendor_patches () {
2023     # This dpkg-source feature doesn't seem to be documented anywhere!
2024     # But it can be found in the changelog (reformatted):
2025
2026     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2027     #   Author: Raphael Hertzog <hertzog@debian.org>
2028     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2029
2030     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2031     #   series files
2032     #
2033     #   If you have debian/patches/ubuntu.series and you were
2034     #   unpacking the source package on ubuntu, quilt was still
2035     #   directed to debian/patches/series instead of
2036     #   debian/patches/ubuntu.series.
2037     #
2038     #   debian/changelog                        |    3 +++
2039     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2040     #   2 files changed, 6 insertions(+), 1 deletion(-)
2041
2042     use Dpkg::Vendor;
2043     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2044     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2045                          "Dpkg::Vendor \`current vendor'");
2046     vendor_patches_distro(access_basedistro(),
2047                           "(base) distro being accessed");
2048     vendor_patches_distro(access_nomdistro(),
2049                           "(nominal) distro being accessed");
2050 }
2051
2052 sub generate_commits_from_dsc () {
2053     # See big comment in fetch_from_archive, below.
2054     # See also README.dsc-import.
2055     prep_ud();
2056     changedir $ud;
2057
2058     my @dfi = dsc_files_info();
2059     foreach my $fi (@dfi) {
2060         my $f = $fi->{Filename};
2061         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2062         my $upper_f = "../../../../$f";
2063
2064         printdebug "considering reusing $f: ";
2065
2066         if (link_ltarget "$upper_f,fetch", $f) {
2067             printdebug "linked (using ...,fetch).\n";
2068         } elsif ((printdebug "($!) "),
2069                  $! != ENOENT) {
2070             fail "accessing ../$f,fetch: $!";
2071         } elsif (link_ltarget $upper_f, $f) {
2072             printdebug "linked.\n";
2073         } elsif ((printdebug "($!) "),
2074                  $! != ENOENT) {
2075             fail "accessing ../$f: $!";
2076         } else {
2077             printdebug "absent.\n";
2078         }
2079
2080         my $refetched;
2081         complete_file_from_dsc('.', $fi, \$refetched)
2082             or next;
2083
2084         printdebug "considering saving $f: ";
2085
2086         if (link $f, $upper_f) {
2087             printdebug "linked.\n";
2088         } elsif ((printdebug "($!) "),
2089                  $! != EEXIST) {
2090             fail "saving ../$f: $!";
2091         } elsif (!$refetched) {
2092             printdebug "no need.\n";
2093         } elsif (link $f, "$upper_f,fetch") {
2094             printdebug "linked (using ...,fetch).\n";
2095         } elsif ((printdebug "($!) "),
2096                  $! != EEXIST) {
2097             fail "saving ../$f,fetch: $!";
2098         } else {
2099             printdebug "cannot.\n";
2100         }
2101     }
2102
2103     # We unpack and record the orig tarballs first, so that we only
2104     # need disk space for one private copy of the unpacked source.
2105     # But we can't make them into commits until we have the metadata
2106     # from the debian/changelog, so we record the tree objects now and
2107     # make them into commits later.
2108     my @tartrees;
2109     my $upstreamv = upstreamversion $dsc->{version};
2110     my $orig_f_base = srcfn $upstreamv, '';
2111
2112     foreach my $fi (@dfi) {
2113         # We actually import, and record as a commit, every tarball
2114         # (unless there is only one file, in which case there seems
2115         # little point.
2116
2117         my $f = $fi->{Filename};
2118         printdebug "import considering $f ";
2119         (printdebug "only one dfi\n"), next if @dfi == 1;
2120         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2121         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2122         my $compr_ext = $1;
2123
2124         my ($orig_f_part) =
2125             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2126
2127         printdebug "Y ", (join ' ', map { $_//"(none)" }
2128                           $compr_ext, $orig_f_part
2129                          ), "\n";
2130
2131         my $input = new IO::File $f, '<' or die "$f $!";
2132         my $compr_pid;
2133         my @compr_cmd;
2134
2135         if (defined $compr_ext) {
2136             my $cname =
2137                 Dpkg::Compression::compression_guess_from_filename $f;
2138             fail "Dpkg::Compression cannot handle file $f in source package"
2139                 if defined $compr_ext && !defined $cname;
2140             my $compr_proc =
2141                 new Dpkg::Compression::Process compression => $cname;
2142             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2143             my $compr_fh = new IO::Handle;
2144             my $compr_pid = open $compr_fh, "-|" // die $!;
2145             if (!$compr_pid) {
2146                 open STDIN, "<&", $input or die $!;
2147                 exec @compr_cmd;
2148                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2149             }
2150             $input = $compr_fh;
2151         }
2152
2153         rmtree "_unpack-tar";
2154         mkdir "_unpack-tar" or die $!;
2155         my @tarcmd = qw(tar -x -f -
2156                         --no-same-owner --no-same-permissions
2157                         --no-acls --no-xattrs --no-selinux);
2158         my $tar_pid = fork // die $!;
2159         if (!$tar_pid) {
2160             chdir "_unpack-tar" or die $!;
2161             open STDIN, "<&", $input or die $!;
2162             exec @tarcmd;
2163             die "dgit (child): exec $tarcmd[0]: $!";
2164         }
2165         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2166         !$? or failedcmd @tarcmd;
2167
2168         close $input or
2169             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2170              : die $!);
2171         # finally, we have the results in "tarball", but maybe
2172         # with the wrong permissions
2173
2174         runcmd qw(chmod -R +rwX _unpack-tar);
2175         changedir "_unpack-tar";
2176         remove_stray_gits($f);
2177         mktree_in_ud_here();
2178
2179         my ($tree) = git_add_write_tree();
2180         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2181         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2182             $tree = $1;
2183             printdebug "one subtree $1\n";
2184         } else {
2185             printdebug "multiple subtrees\n";
2186         }
2187         changedir "..";
2188         rmtree "_unpack-tar";
2189
2190         my $ent = [ $f, $tree ];
2191         push @tartrees, {
2192             Orig => !!$orig_f_part,
2193             Sort => (!$orig_f_part         ? 2 :
2194                      $orig_f_part =~ m/-/g ? 1 :
2195                                              0),
2196             F => $f,
2197             Tree => $tree,
2198         };
2199     }
2200
2201     @tartrees = sort {
2202         # put any without "_" first (spec is not clear whether files
2203         # are always in the usual order).  Tarballs without "_" are
2204         # the main orig or the debian tarball.
2205         $a->{Sort} <=> $b->{Sort} or
2206         $a->{F}    cmp $b->{F}
2207     } @tartrees;
2208
2209     my $any_orig = grep { $_->{Orig} } @tartrees;
2210
2211     my $dscfn = "$package.dsc";
2212
2213     my $treeimporthow = 'package';
2214
2215     open D, ">", $dscfn or die "$dscfn: $!";
2216     print D $dscdata or die "$dscfn: $!";
2217     close D or die "$dscfn: $!";
2218     my @cmd = qw(dpkg-source);
2219     push @cmd, '--no-check' if $dsc_checked;
2220     if (madformat $dsc->{format}) {
2221         push @cmd, '--skip-patches';
2222         $treeimporthow = 'unpatched';
2223     }
2224     push @cmd, qw(-x --), $dscfn;
2225     runcmd @cmd;
2226
2227     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2228     if (madformat $dsc->{format}) {
2229         check_for_vendor_patches();
2230     }
2231
2232     my $dappliedtree;
2233     if (madformat $dsc->{format}) {
2234         my @pcmd = qw(dpkg-source --before-build .);
2235         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2236         rmtree '.pc';
2237         $dappliedtree = git_add_write_tree();
2238     }
2239
2240     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2241     debugcmd "|",@clogcmd;
2242     open CLOGS, "-|", @clogcmd or die $!;
2243
2244     my $clogp;
2245     my $r1clogp;
2246
2247     printdebug "import clog search...\n";
2248
2249     for (;;) {
2250         my $stanzatext = do { local $/=""; <CLOGS>; };
2251         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2252         last if !defined $stanzatext;
2253
2254         my $desc = "package changelog, entry no.$.";
2255         open my $stanzafh, "<", \$stanzatext or die;
2256         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2257         $clogp //= $thisstanza;
2258
2259         printdebug "import clog $thisstanza->{version} $desc...\n";
2260
2261         last if !$any_orig; # we don't need $r1clogp
2262
2263         # We look for the first (most recent) changelog entry whose
2264         # version number is lower than the upstream version of this
2265         # package.  Then the last (least recent) previous changelog
2266         # entry is treated as the one which introduced this upstream
2267         # version and used for the synthetic commits for the upstream
2268         # tarballs.
2269
2270         # One might think that a more sophisticated algorithm would be
2271         # necessary.  But: we do not want to scan the whole changelog
2272         # file.  Stopping when we see an earlier version, which
2273         # necessarily then is an earlier upstream version, is the only
2274         # realistic way to do that.  Then, either the earliest
2275         # changelog entry we have seen so far is indeed the earliest
2276         # upload of this upstream version; or there are only changelog
2277         # entries relating to later upstream versions (which is not
2278         # possible unless the changelog and .dsc disagree about the
2279         # version).  Then it remains to choose between the physically
2280         # last entry in the file, and the one with the lowest version
2281         # number.  If these are not the same, we guess that the
2282         # versions were created in a non-monotic order rather than
2283         # that the changelog entries have been misordered.
2284
2285         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2286
2287         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2288         $r1clogp = $thisstanza;
2289
2290         printdebug "import clog $r1clogp->{version} becomes r1\n";
2291     }
2292     die $! if CLOGS->error;
2293     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2294
2295     $clogp or fail "package changelog has no entries!";
2296
2297     my $authline = clogp_authline $clogp;
2298     my $changes = getfield $clogp, 'Changes';
2299     $changes =~ s/^\n//; # Changes: \n
2300     my $cversion = getfield $clogp, 'Version';
2301
2302     if (@tartrees) {
2303         $r1clogp //= $clogp; # maybe there's only one entry;
2304         my $r1authline = clogp_authline $r1clogp;
2305         # Strictly, r1authline might now be wrong if it's going to be
2306         # unused because !$any_orig.  Whatever.
2307
2308         printdebug "import tartrees authline   $authline\n";
2309         printdebug "import tartrees r1authline $r1authline\n";
2310
2311         foreach my $tt (@tartrees) {
2312             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2313
2314             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2315 tree $tt->{Tree}
2316 author $r1authline
2317 committer $r1authline
2318
2319 Import $tt->{F}
2320
2321 [dgit import orig $tt->{F}]
2322 END_O
2323 tree $tt->{Tree}
2324 author $authline
2325 committer $authline
2326
2327 Import $tt->{F}
2328
2329 [dgit import tarball $package $cversion $tt->{F}]
2330 END_T
2331         }
2332     }
2333
2334     printdebug "import main commit\n";
2335
2336     open C, ">../commit.tmp" or die $!;
2337     print C <<END or die $!;
2338 tree $tree
2339 END
2340     print C <<END or die $! foreach @tartrees;
2341 parent $_->{Commit}
2342 END
2343     print C <<END or die $!;
2344 author $authline
2345 committer $authline
2346
2347 $changes
2348
2349 [dgit import $treeimporthow $package $cversion]
2350 END
2351
2352     close C or die $!;
2353     my $rawimport_hash = make_commit qw(../commit.tmp);
2354
2355     if (madformat $dsc->{format}) {
2356         printdebug "import apply patches...\n";
2357
2358         # regularise the state of the working tree so that
2359         # the checkout of $rawimport_hash works nicely.
2360         my $dappliedcommit = make_commit_text(<<END);
2361 tree $dappliedtree
2362 author $authline
2363 committer $authline
2364
2365 [dgit dummy commit]
2366 END
2367         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2368
2369         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2370
2371         # We need the answers to be reproducible
2372         my @authline = clogp_authline($clogp);
2373         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2374         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2375         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2376         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2377         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2378         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2379
2380         my $path = $ENV{PATH} or die;
2381
2382         foreach my $use_absurd (qw(0 1)) {
2383             runcmd @git, qw(checkout -q unpa);
2384             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2385             local $ENV{PATH} = $path;
2386             if ($use_absurd) {
2387                 chomp $@;
2388                 progress "warning: $@";
2389                 $path = "$absurdity:$path";
2390                 progress "$us: trying slow absurd-git-apply...";
2391                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2392                     or $!==ENOENT
2393                     or die $!;
2394             }
2395             eval {
2396                 die "forbid absurd git-apply\n" if $use_absurd
2397                     && forceing [qw(import-gitapply-no-absurd)];
2398                 die "only absurd git-apply!\n" if !$use_absurd
2399                     && forceing [qw(import-gitapply-absurd)];
2400
2401                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2402                 local $ENV{PATH} = $path                    if $use_absurd;
2403
2404                 my @showcmd = (gbp_pq, qw(import));
2405                 my @realcmd = shell_cmd
2406                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2407                 debugcmd "+",@realcmd;
2408                 if (system @realcmd) {
2409                     die +(shellquote @showcmd).
2410                         " failed: ".
2411                         failedcmd_waitstatus()."\n";
2412                 }
2413
2414                 my $gapplied = git_rev_parse('HEAD');
2415                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2416                 $gappliedtree eq $dappliedtree or
2417                     fail <<END;
2418 gbp-pq import and dpkg-source disagree!
2419  gbp-pq import gave commit $gapplied
2420  gbp-pq import gave tree $gappliedtree
2421  dpkg-source --before-build gave tree $dappliedtree
2422 END
2423                 $rawimport_hash = $gapplied;
2424             };
2425             last unless $@;
2426         }
2427         if ($@) {
2428             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2429             die $@;
2430         }
2431     }
2432
2433     progress "synthesised git commit from .dsc $cversion";
2434
2435     my $rawimport_mergeinput = {
2436         Commit => $rawimport_hash,
2437         Info => "Import of source package",
2438     };
2439     my @output = ($rawimport_mergeinput);
2440
2441     if ($lastpush_mergeinput) {
2442         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2443         my $oversion = getfield $oldclogp, 'Version';
2444         my $vcmp =
2445             version_compare($oversion, $cversion);
2446         if ($vcmp < 0) {
2447             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2448                 { Message => <<END, ReverseParents => 1 });
2449 Record $package ($cversion) in archive suite $csuite
2450 END
2451         } elsif ($vcmp > 0) {
2452             print STDERR <<END or die $!;
2453
2454 Version actually in archive:   $cversion (older)
2455 Last version pushed with dgit: $oversion (newer or same)
2456 $later_warning_msg
2457 END
2458             @output = $lastpush_mergeinput;
2459         } else {
2460             # Same version.  Use what's in the server git branch,
2461             # discarding our own import.  (This could happen if the
2462             # server automatically imports all packages into git.)
2463             @output = $lastpush_mergeinput;
2464         }
2465     }
2466     changedir '../../../..';
2467     rmtree($ud);
2468     return @output;
2469 }
2470
2471 sub complete_file_from_dsc ($$;$) {
2472     our ($dstdir, $fi, $refetched) = @_;
2473     # Ensures that we have, in $dstdir, the file $fi, with the correct
2474     # contents.  (Downloading it from alongside $dscurl if necessary.)
2475     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2476     # and will set $$refetched=1 if it did so (or tried to).
2477
2478     my $f = $fi->{Filename};
2479     my $tf = "$dstdir/$f";
2480     my $downloaded = 0;
2481
2482     my $got;
2483     my $checkhash = sub {
2484         open F, "<", "$tf" or die "$tf: $!";
2485         $fi->{Digester}->reset();
2486         $fi->{Digester}->addfile(*F);
2487         F->error and die $!;
2488         $got = $fi->{Digester}->hexdigest();
2489         return $got eq $fi->{Hash};
2490     };
2491
2492     if (stat_exists $tf) {
2493         if ($checkhash->()) {
2494             progress "using existing $f";
2495             return 1;
2496         }
2497         if (!$refetched) {
2498             fail "file $f has hash $got but .dsc".
2499                 " demands hash $fi->{Hash} ".
2500                 "(perhaps you should delete this file?)";
2501         }
2502         progress "need to fetch correct version of $f";
2503         unlink $tf or die "$tf $!";
2504         $$refetched = 1;
2505     } else {
2506         printdebug "$tf does not exist, need to fetch\n";
2507     }
2508
2509     my $furl = $dscurl;
2510     $furl =~ s{/[^/]+$}{};
2511     $furl .= "/$f";
2512     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2513     die "$f ?" if $f =~ m#/#;
2514     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2515     return 0 if !act_local();
2516
2517     $checkhash->() or
2518         fail "file $f has hash $got but .dsc".
2519             " demands hash $fi->{Hash} ".
2520             "(got wrong file from archive!)";
2521
2522     return 1;
2523 }
2524
2525 sub ensure_we_have_orig () {
2526     my @dfi = dsc_files_info();
2527     foreach my $fi (@dfi) {
2528         my $f = $fi->{Filename};
2529         next unless is_orig_file_in_dsc($f, \@dfi);
2530         complete_file_from_dsc('..', $fi)
2531             or next;
2532     }
2533 }
2534
2535 #---------- git fetch ----------
2536
2537 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2538 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2539
2540 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2541 # locally fetched refs because they have unhelpful names and clutter
2542 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2543 # whether we have made another local ref which refers to this object).
2544 #
2545 # (If we deleted them unconditionally, then we might end up
2546 # re-fetching the same git objects each time dgit fetch was run.)
2547 #
2548 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2549 # in git_fetch_us to fetch the refs in question, and possibly a call
2550 # to lrfetchref_used.
2551
2552 our (%lrfetchrefs_f, %lrfetchrefs_d);
2553 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2554
2555 sub lrfetchref_used ($) {
2556     my ($fullrefname) = @_;
2557     my $objid = $lrfetchrefs_f{$fullrefname};
2558     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2559 }
2560
2561 sub git_lrfetch_sane {
2562     my ($url, $supplementary, @specs) = @_;
2563     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2564     # at least as regards @specs.  Also leave the results in
2565     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2566     # able to clean these up.
2567     #
2568     # With $supplementary==1, @specs must not contain wildcards
2569     # and we add to our previous fetches (non-atomically).
2570
2571     # This is rather miserable:
2572     # When git fetch --prune is passed a fetchspec ending with a *,
2573     # it does a plausible thing.  If there is no * then:
2574     # - it matches subpaths too, even if the supplied refspec
2575     #   starts refs, and behaves completely madly if the source
2576     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2577     # - if there is no matching remote ref, it bombs out the whole
2578     #   fetch.
2579     # We want to fetch a fixed ref, and we don't know in advance
2580     # if it exists, so this is not suitable.
2581     #
2582     # Our workaround is to use git ls-remote.  git ls-remote has its
2583     # own qairks.  Notably, it has the absurd multi-tail-matching
2584     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2585     # refs/refs/foo etc.
2586     #
2587     # Also, we want an idempotent snapshot, but we have to make two
2588     # calls to the remote: one to git ls-remote and to git fetch.  The
2589     # solution is use git ls-remote to obtain a target state, and
2590     # git fetch to try to generate it.  If we don't manage to generate
2591     # the target state, we try again.
2592
2593     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2594
2595     my $specre = join '|', map {
2596         my $x = $_;
2597         $x =~ s/\W/\\$&/g;
2598         my $wildcard = $x =~ s/\\\*$/.*/;
2599         die if $wildcard && $supplementary;
2600         "(?:refs/$x)";
2601     } @specs;
2602     printdebug "git_lrfetch_sane specre=$specre\n";
2603     my $wanted_rref = sub {
2604         local ($_) = @_;
2605         return m/^(?:$specre)$/;
2606     };
2607
2608     my $fetch_iteration = 0;
2609     FETCH_ITERATION:
2610     for (;;) {
2611         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2612         if (++$fetch_iteration > 10) {
2613             fail "too many iterations trying to get sane fetch!";
2614         }
2615
2616         my @look = map { "refs/$_" } @specs;
2617         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2618         debugcmd "|",@lcmd;
2619
2620         my %wantr;
2621         open GITLS, "-|", @lcmd or die $!;
2622         while (<GITLS>) {
2623             printdebug "=> ", $_;
2624             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2625             my ($objid,$rrefname) = ($1,$2);
2626             if (!$wanted_rref->($rrefname)) {
2627                 print STDERR <<END;
2628 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2629 END
2630                 next;
2631             }
2632             $wantr{$rrefname} = $objid;
2633         }
2634         $!=0; $?=0;
2635         close GITLS or failedcmd @lcmd;
2636
2637         # OK, now %want is exactly what we want for refs in @specs
2638         my @fspecs = map {
2639             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2640             "+refs/$_:".lrfetchrefs."/$_";
2641         } @specs;
2642
2643         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2644
2645         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2646         runcmd_ordryrun_local @fcmd if @fspecs;
2647
2648         if (!$supplementary) {
2649             %lrfetchrefs_f = ();
2650         }
2651         my %objgot;
2652
2653         git_for_each_ref(lrfetchrefs, sub {
2654             my ($objid,$objtype,$lrefname,$reftail) = @_;
2655             $lrfetchrefs_f{$lrefname} = $objid;
2656             $objgot{$objid} = 1;
2657         });
2658
2659         if ($supplementary) {
2660             last;
2661         }
2662
2663         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2664             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2665             if (!exists $wantr{$rrefname}) {
2666                 if ($wanted_rref->($rrefname)) {
2667                     printdebug <<END;
2668 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2669 END
2670                 } else {
2671                     print STDERR <<END
2672 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2673 END
2674                 }
2675                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2676                 delete $lrfetchrefs_f{$lrefname};
2677                 next;
2678             }
2679         }
2680         foreach my $rrefname (sort keys %wantr) {
2681             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2682             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2683             my $want = $wantr{$rrefname};
2684             next if $got eq $want;
2685             if (!defined $objgot{$want}) {
2686                 print STDERR <<END;
2687 warning: git ls-remote suggests we want $lrefname
2688 warning:  and it should refer to $want
2689 warning:  but git fetch didn't fetch that object to any relevant ref.
2690 warning:  This may be due to a race with someone updating the server.
2691 warning:  Will try again...
2692 END
2693                 next FETCH_ITERATION;
2694             }
2695             printdebug <<END;
2696 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2697 END
2698             runcmd_ordryrun_local @git, qw(update-ref -m),
2699                 "dgit fetch git fetch fixup", $lrefname, $want;
2700             $lrfetchrefs_f{$lrefname} = $want;
2701         }
2702         last;
2703     }
2704
2705     if (defined $csuite) {
2706         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2707         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2708             my ($objid,$objtype,$lrefname,$reftail) = @_;
2709             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2710             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2711         });
2712     }
2713
2714     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2715         Dumper(\%lrfetchrefs_f);
2716 }
2717
2718 sub git_fetch_us () {
2719     # Want to fetch only what we are going to use, unless
2720     # deliberately-not-ff, in which case we must fetch everything.
2721
2722     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2723         map { "tags/$_" }
2724         (quiltmode_splitbrain
2725          ? (map { $_->('*',access_nomdistro) }
2726             \&debiantag_new, \&debiantag_maintview)
2727          : debiantags('*',access_nomdistro));
2728     push @specs, server_branch($csuite);
2729     push @specs, $rewritemap;
2730     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2731
2732     my $url = access_giturl();
2733     git_lrfetch_sane $url, 0, @specs;
2734
2735     my %here;
2736     my @tagpats = debiantags('*',access_nomdistro);
2737
2738     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2739         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2740         printdebug "currently $fullrefname=$objid\n";
2741         $here{$fullrefname} = $objid;
2742     });
2743     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2744         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2745         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2746         printdebug "offered $lref=$objid\n";
2747         if (!defined $here{$lref}) {
2748             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2749             runcmd_ordryrun_local @upd;
2750             lrfetchref_used $fullrefname;
2751         } elsif ($here{$lref} eq $objid) {
2752             lrfetchref_used $fullrefname;
2753         } else {
2754             print STDERR
2755                 "Not updating $lref from $here{$lref} to $objid.\n";
2756         }
2757     });
2758 }
2759
2760 #---------- dsc and archive handling ----------
2761
2762 sub mergeinfo_getclogp ($) {
2763     # Ensures thit $mi->{Clogp} exists and returns it
2764     my ($mi) = @_;
2765     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2766 }
2767
2768 sub mergeinfo_version ($) {
2769     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2770 }
2771
2772 sub fetch_from_archive_record_1 ($) {
2773     my ($hash) = @_;
2774     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2775             'DGIT_ARCHIVE', $hash;
2776     cmdoutput @git, qw(log -n2), $hash;
2777     # ... gives git a chance to complain if our commit is malformed
2778 }
2779
2780 sub fetch_from_archive_record_2 ($) {
2781     my ($hash) = @_;
2782     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2783     if (act_local()) {
2784         cmdoutput @upd_cmd;
2785     } else {
2786         dryrun_report @upd_cmd;
2787     }
2788 }
2789
2790 sub parse_dsc_field_def_dsc_distro () {
2791     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2792                            dgit.default.distro);
2793 }
2794
2795 sub parse_dsc_field ($$) {
2796     my ($dsc, $what) = @_;
2797     my $f;
2798     foreach my $field (@ourdscfield) {
2799         $f = $dsc->{$field};
2800         last if defined $f;
2801     }
2802
2803     if (!defined $f) {
2804         progress "$what: NO git hash";
2805         parse_dsc_field_def_dsc_distro();
2806     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2807              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2808         progress "$what: specified git info ($dsc_distro)";
2809         $dsc_hint_tag = [ $dsc_hint_tag ];
2810     } elsif ($f =~ m/^\w+\s*$/) {
2811         $dsc_hash = $&;
2812         parse_dsc_field_def_dsc_distro();
2813         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2814                           $dsc_distro ];
2815         progress "$what: specified git hash";
2816     } else {
2817         fail "$what: invalid Dgit info";
2818     }
2819 }
2820
2821 sub resolve_dsc_field_commit ($$) {
2822     my ($already_distro, $already_mapref) = @_;
2823
2824     return unless defined $dsc_hash;
2825
2826     my $mapref =
2827         defined $already_mapref &&
2828         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2829         ? $already_mapref : undef;
2830
2831     my $do_fetch;
2832     $do_fetch = sub {
2833         my ($what, @fetch) = @_;
2834
2835         local $idistro = $dsc_distro;
2836         my $lrf = lrfetchrefs;
2837
2838         if (!$chase_dsc_distro) {
2839             progress
2840                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2841             return 0;
2842         }
2843
2844         progress
2845             ".dsc names distro $dsc_distro: fetching $what";
2846
2847         my $url = access_giturl();
2848         if (!defined $url) {
2849             defined $dsc_hint_url or fail <<END;
2850 .dsc Dgit metadata is in context of distro $dsc_distro
2851 for which we have no configured url and .dsc provides no hint
2852 END
2853             my $proto =
2854                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2855                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2856             parse_cfg_bool "dsc-url-proto-ok", 'false',
2857                 cfg("dgit.dsc-url-proto-ok.$proto",
2858                     "dgit.default.dsc-url-proto-ok")
2859                 or fail <<END;
2860 .dsc Dgit metadata is in context of distro $dsc_distro
2861 for which we have no configured url;
2862 .dsc provides hinted url with protocol $proto which is unsafe.
2863 (can be overridden by config - consult documentation)
2864 END
2865             $url = $dsc_hint_url;
2866         }
2867
2868         git_lrfetch_sane $url, 1, @fetch;
2869
2870         return $lrf;
2871     };
2872
2873     my $rewrite_enable = do {
2874         local $idistro = $dsc_distro;
2875         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2876     };
2877
2878     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2879         if (!defined $mapref) {
2880             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2881             $mapref = $lrf.'/'.$rewritemap;
2882         }
2883         my $rewritemapdata = git_cat_file $mapref.':map';
2884         if (defined $rewritemapdata
2885             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2886             progress
2887                 "server's git history rewrite map contains a relevant entry!";
2888
2889             $dsc_hash = $1;
2890             if (defined $dsc_hash) {
2891                 progress "using rewritten git hash in place of .dsc value";
2892             } else {
2893                 progress "server data says .dsc hash is to be disregarded";
2894             }
2895         }
2896     }
2897
2898     if (!defined git_cat_file $dsc_hash) {
2899         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2900         my $lrf = $do_fetch->("additional commits", @tags) &&
2901             defined git_cat_file $dsc_hash
2902             or fail <<END;
2903 .dsc Dgit metadata requires commit $dsc_hash
2904 but we could not obtain that object anywhere.
2905 END
2906         foreach my $t (@tags) {
2907             my $fullrefname = $lrf.'/'.$t;
2908 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2909             next unless $lrfetchrefs_f{$fullrefname};
2910             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2911             lrfetchref_used $fullrefname;
2912         }
2913     }
2914 }
2915
2916 sub fetch_from_archive () {
2917     ensure_setup_existing_tree();
2918
2919     # Ensures that lrref() is what is actually in the archive, one way
2920     # or another, according to us - ie this client's
2921     # appropritaely-updated archive view.  Also returns the commit id.
2922     # If there is nothing in the archive, leaves lrref alone and
2923     # returns undef.  git_fetch_us must have already been called.
2924     get_archive_dsc();
2925
2926     if ($dsc) {
2927         parse_dsc_field($dsc, 'last upload to archive');
2928         resolve_dsc_field_commit access_basedistro,
2929             lrfetchrefs."/".$rewritemap
2930     } else {
2931         progress "no version available from the archive";
2932     }
2933
2934     # If the archive's .dsc has a Dgit field, there are three
2935     # relevant git commitids we need to choose between and/or merge
2936     # together:
2937     #   1. $dsc_hash: the Dgit field from the archive
2938     #   2. $lastpush_hash: the suite branch on the dgit git server
2939     #   3. $lastfetch_hash: our local tracking brach for the suite
2940     #
2941     # These may all be distinct and need not be in any fast forward
2942     # relationship:
2943     #
2944     # If the dsc was pushed to this suite, then the server suite
2945     # branch will have been updated; but it might have been pushed to
2946     # a different suite and copied by the archive.  Conversely a more
2947     # recent version may have been pushed with dgit but not appeared
2948     # in the archive (yet).
2949     #
2950     # $lastfetch_hash may be awkward because archive imports
2951     # (particularly, imports of Dgit-less .dscs) are performed only as
2952     # needed on individual clients, so different clients may perform a
2953     # different subset of them - and these imports are only made
2954     # public during push.  So $lastfetch_hash may represent a set of
2955     # imports different to a subsequent upload by a different dgit
2956     # client.
2957     #
2958     # Our approach is as follows:
2959     #
2960     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2961     # descendant of $dsc_hash, then it was pushed by a dgit user who
2962     # had based their work on $dsc_hash, so we should prefer it.
2963     # Otherwise, $dsc_hash was installed into this suite in the
2964     # archive other than by a dgit push, and (necessarily) after the
2965     # last dgit push into that suite (since a dgit push would have
2966     # been descended from the dgit server git branch); thus, in that
2967     # case, we prefer the archive's version (and produce a
2968     # pseudo-merge to overwrite the dgit server git branch).
2969     #
2970     # (If there is no Dgit field in the archive's .dsc then
2971     # generate_commit_from_dsc uses the version numbers to decide
2972     # whether the suite branch or the archive is newer.  If the suite
2973     # branch is newer it ignores the archive's .dsc; otherwise it
2974     # generates an import of the .dsc, and produces a pseudo-merge to
2975     # overwrite the suite branch with the archive contents.)
2976     #
2977     # The outcome of that part of the algorithm is the `public view',
2978     # and is same for all dgit clients: it does not depend on any
2979     # unpublished history in the local tracking branch.
2980     #
2981     # As between the public view and the local tracking branch: The
2982     # local tracking branch is only updated by dgit fetch, and
2983     # whenever dgit fetch runs it includes the public view in the
2984     # local tracking branch.  Therefore if the public view is not
2985     # descended from the local tracking branch, the local tracking
2986     # branch must contain history which was imported from the archive
2987     # but never pushed; and, its tip is now out of date.  So, we make
2988     # a pseudo-merge to overwrite the old imports and stitch the old
2989     # history in.
2990     #
2991     # Finally: we do not necessarily reify the public view (as
2992     # described above).  This is so that we do not end up stacking two
2993     # pseudo-merges.  So what we actually do is figure out the inputs
2994     # to any public view pseudo-merge and put them in @mergeinputs.
2995
2996     my @mergeinputs;
2997     # $mergeinputs[]{Commit}
2998     # $mergeinputs[]{Info}
2999     # $mergeinputs[0] is the one whose tree we use
3000     # @mergeinputs is in the order we use in the actual commit)
3001     #
3002     # Also:
3003     # $mergeinputs[]{Message} is a commit message to use
3004     # $mergeinputs[]{ReverseParents} if def specifies that parent
3005     #                                list should be in opposite order
3006     # Such an entry has no Commit or Info.  It applies only when found
3007     # in the last entry.  (This ugliness is to support making
3008     # identical imports to previous dgit versions.)
3009
3010     my $lastpush_hash = git_get_ref(lrfetchref());
3011     printdebug "previous reference hash=$lastpush_hash\n";
3012     $lastpush_mergeinput = $lastpush_hash && {
3013         Commit => $lastpush_hash,
3014         Info => "dgit suite branch on dgit git server",
3015     };
3016
3017     my $lastfetch_hash = git_get_ref(lrref());
3018     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3019     my $lastfetch_mergeinput = $lastfetch_hash && {
3020         Commit => $lastfetch_hash,
3021         Info => "dgit client's archive history view",
3022     };
3023
3024     my $dsc_mergeinput = $dsc_hash && {
3025         Commit => $dsc_hash,
3026         Info => "Dgit field in .dsc from archive",
3027     };
3028
3029     my $cwd = getcwd();
3030     my $del_lrfetchrefs = sub {
3031         changedir $cwd;
3032         my $gur;
3033         printdebug "del_lrfetchrefs...\n";
3034         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3035             my $objid = $lrfetchrefs_d{$fullrefname};
3036             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3037             if (!$gur) {
3038                 $gur ||= new IO::Handle;
3039                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3040             }
3041             printf $gur "delete %s %s\n", $fullrefname, $objid;
3042         }
3043         if ($gur) {
3044             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3045         }
3046     };
3047
3048     if (defined $dsc_hash) {
3049         ensure_we_have_orig();
3050         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3051             @mergeinputs = $dsc_mergeinput
3052         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3053             print STDERR <<END or die $!;
3054
3055 Git commit in archive is behind the last version allegedly pushed/uploaded.
3056 Commit referred to by archive: $dsc_hash
3057 Last version pushed with dgit: $lastpush_hash
3058 $later_warning_msg
3059 END
3060             @mergeinputs = ($lastpush_mergeinput);
3061         } else {
3062             # Archive has .dsc which is not a descendant of the last dgit
3063             # push.  This can happen if the archive moves .dscs about.
3064             # Just follow its lead.
3065             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3066                 progress "archive .dsc names newer git commit";
3067                 @mergeinputs = ($dsc_mergeinput);
3068             } else {
3069                 progress "archive .dsc names other git commit, fixing up";
3070                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3071             }
3072         }
3073     } elsif ($dsc) {
3074         @mergeinputs = generate_commits_from_dsc();
3075         # We have just done an import.  Now, our import algorithm might
3076         # have been improved.  But even so we do not want to generate
3077         # a new different import of the same package.  So if the
3078         # version numbers are the same, just use our existing version.
3079         # If the version numbers are different, the archive has changed
3080         # (perhaps, rewound).
3081         if ($lastfetch_mergeinput &&
3082             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3083                               (mergeinfo_version $mergeinputs[0]) )) {
3084             @mergeinputs = ($lastfetch_mergeinput);
3085         }
3086     } elsif ($lastpush_hash) {
3087         # only in git, not in the archive yet
3088         @mergeinputs = ($lastpush_mergeinput);
3089         print STDERR <<END or die $!;
3090
3091 Package not found in the archive, but has allegedly been pushed using dgit.
3092 $later_warning_msg
3093 END
3094     } else {
3095         printdebug "nothing found!\n";
3096         if (defined $skew_warning_vsn) {
3097             print STDERR <<END or die $!;
3098
3099 Warning: relevant archive skew detected.
3100 Archive allegedly contains $skew_warning_vsn
3101 But we were not able to obtain any version from the archive or git.
3102
3103 END
3104         }
3105         unshift @end, $del_lrfetchrefs;
3106         return undef;
3107     }
3108
3109     if ($lastfetch_hash &&
3110         !grep {
3111             my $h = $_->{Commit};
3112             $h and is_fast_fwd($lastfetch_hash, $h);
3113             # If true, one of the existing parents of this commit
3114             # is a descendant of the $lastfetch_hash, so we'll
3115             # be ff from that automatically.
3116         } @mergeinputs
3117         ) {
3118         # Otherwise:
3119         push @mergeinputs, $lastfetch_mergeinput;
3120     }
3121
3122     printdebug "fetch mergeinfos:\n";
3123     foreach my $mi (@mergeinputs) {
3124         if ($mi->{Info}) {
3125             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3126         } else {
3127             printdebug sprintf " ReverseParents=%d Message=%s",
3128                 $mi->{ReverseParents}, $mi->{Message};
3129         }
3130     }
3131
3132     my $compat_info= pop @mergeinputs
3133         if $mergeinputs[$#mergeinputs]{Message};
3134
3135     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3136
3137     my $hash;
3138     if (@mergeinputs > 1) {
3139         # here we go, then:
3140         my $tree_commit = $mergeinputs[0]{Commit};
3141
3142         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3143         $tree =~ m/\n\n/;  $tree = $`;
3144         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3145         $tree = $1;
3146
3147         # We use the changelog author of the package in question the
3148         # author of this pseudo-merge.  This is (roughly) correct if
3149         # this commit is simply representing aa non-dgit upload.
3150         # (Roughly because it does not record sponsorship - but we
3151         # don't have sponsorship info because that's in the .changes,
3152         # which isn't in the archivw.)
3153         #
3154         # But, it might be that we are representing archive history
3155         # updates (including in-archive copies).  These are not really
3156         # the responsibility of the person who created the .dsc, but
3157         # there is no-one whose name we should better use.  (The
3158         # author of the .dsc-named commit is clearly worse.)
3159
3160         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3161         my $author = clogp_authline $useclogp;
3162         my $cversion = getfield $useclogp, 'Version';
3163
3164         my $mcf = ".git/dgit/mergecommit";
3165         open MC, ">", $mcf or die "$mcf $!";
3166         print MC <<END or die $!;
3167 tree $tree
3168 END
3169
3170         my @parents = grep { $_->{Commit} } @mergeinputs;
3171         @parents = reverse @parents if $compat_info->{ReverseParents};
3172         print MC <<END or die $! foreach @parents;
3173 parent $_->{Commit}
3174 END
3175
3176         print MC <<END or die $!;
3177 author $author
3178 committer $author
3179
3180 END
3181
3182         if (defined $compat_info->{Message}) {
3183             print MC $compat_info->{Message} or die $!;
3184         } else {
3185             print MC <<END or die $!;
3186 Record $package ($cversion) in archive suite $csuite
3187
3188 Record that
3189 END
3190             my $message_add_info = sub {
3191                 my ($mi) = (@_);
3192                 my $mversion = mergeinfo_version $mi;
3193                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3194                     or die $!;
3195             };
3196
3197             $message_add_info->($mergeinputs[0]);
3198             print MC <<END or die $!;
3199 should be treated as descended from
3200 END
3201             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3202         }
3203
3204         close MC or die $!;
3205         $hash = make_commit $mcf;
3206     } else {
3207         $hash = $mergeinputs[0]{Commit};
3208     }
3209     printdebug "fetch hash=$hash\n";
3210
3211     my $chkff = sub {
3212         my ($lasth, $what) = @_;
3213         return unless $lasth;
3214         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3215     };
3216
3217     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3218         if $lastpush_hash;
3219     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3220
3221     fetch_from_archive_record_1($hash);
3222
3223     if (defined $skew_warning_vsn) {
3224         mkpath '.git/dgit';
3225         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3226         my $gotclogp = commit_getclogp($hash);
3227         my $got_vsn = getfield $gotclogp, 'Version';
3228         printdebug "SKEW CHECK GOT $got_vsn\n";
3229         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3230             print STDERR <<END or die $!;
3231
3232 Warning: archive skew detected.  Using the available version:
3233 Archive allegedly contains    $skew_warning_vsn
3234 We were able to obtain only   $got_vsn
3235
3236 END
3237         }
3238     }
3239
3240     if ($lastfetch_hash ne $hash) {
3241         fetch_from_archive_record_2($hash);
3242     }
3243
3244     lrfetchref_used lrfetchref();
3245
3246     check_gitattrs($hash, "fetched source tree");
3247
3248     unshift @end, $del_lrfetchrefs;
3249     return $hash;
3250 }
3251
3252 sub set_local_git_config ($$) {
3253     my ($k, $v) = @_;
3254     runcmd @git, qw(config), $k, $v;
3255 }
3256
3257 sub setup_mergechangelogs (;$) {
3258     my ($always) = @_;
3259     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3260
3261     my $driver = 'dpkg-mergechangelogs';
3262     my $cb = "merge.$driver";
3263     my $attrs = '.git/info/attributes';
3264     ensuredir '.git/info';
3265
3266     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3267     if (!open ATTRS, "<", $attrs) {
3268         $!==ENOENT or die "$attrs: $!";
3269     } else {
3270         while (<ATTRS>) {
3271             chomp;
3272             next if m{^debian/changelog\s};
3273             print NATTRS $_, "\n" or die $!;
3274         }
3275         ATTRS->error and die $!;
3276         close ATTRS;
3277     }
3278     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3279     close NATTRS;
3280
3281     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3282     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3283
3284     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3285 }
3286
3287 sub setup_useremail (;$) {
3288     my ($always) = @_;
3289     return unless $always || access_cfg_bool(1, 'setup-useremail');
3290
3291     my $setup = sub {
3292         my ($k, $envvar) = @_;
3293         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3294         return unless defined $v;
3295         set_local_git_config "user.$k", $v;
3296     };
3297
3298     $setup->('email', 'DEBEMAIL');
3299     $setup->('name', 'DEBFULLNAME');
3300 }
3301
3302 sub ensure_setup_existing_tree () {
3303     my $k = "remote.$remotename.skipdefaultupdate";
3304     my $c = git_get_config $k;
3305     return if defined $c;
3306     set_local_git_config $k, 'true';
3307 }
3308
3309 sub open_gitattrs () {
3310     my $gai = new IO::File ".git/info/attributes"
3311         or $!==ENOENT
3312         or die "open .git/info/attributes: $!";
3313     return $gai;
3314 }
3315
3316 sub is_gitattrs_setup () {
3317     my $gai = open_gitattrs();
3318     return 0 unless $gai;
3319     while (<$gai>) {
3320         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3321     }
3322     $gai->error and die $!;
3323     return 0;
3324 }
3325
3326 sub setup_gitattrs (;$) {
3327     my ($always) = @_;
3328     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3329
3330     if (is_gitattrs_setup()) {
3331         progress <<END;
3332 [attr]dgit-defuse-attrs already found in .git/info/attributes
3333  not doing further gitattributes setup
3334 END
3335         return;
3336     }
3337     my $af = ".git/info/attributes";
3338     ensuredir '.git/info';
3339     open GAO, "> $af.new" or die $!;
3340     print GAO <<END or die $!;
3341 *       dgit-defuse-attrs
3342 [attr]dgit-defuse-attrs $negate_harmful_gitattrs
3343 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3344 END
3345     my $gai = open_gitattrs();
3346     if ($gai) {
3347         while (<$gai>) {
3348             chomp;
3349             print GAO $_, "\n" or die $!;
3350         }
3351         $gai->error and die $!;
3352     }
3353     close GAO or die $!;
3354     rename "$af.new", "$af" or die "install $af: $!";
3355 }
3356
3357 sub setup_new_tree () {
3358     setup_mergechangelogs();
3359     setup_useremail();
3360     setup_gitattrs();
3361 }
3362
3363 sub check_gitattrs ($$) {
3364     my ($treeish, $what) = @_;
3365
3366     return if is_gitattrs_setup;
3367
3368     local $/="\0";
3369     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3370     debugcmd "|",@cmd;
3371     my $gafl = new IO::File;
3372     open $gafl, "-|", @cmd or die $!;
3373     while (<$gafl>) {
3374         chomp or die;
3375         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3376         next if $1 == 0;
3377         next unless m{(?:^|/)\.gitattributes$};
3378
3379         # oh dear, found one
3380         print STDERR <<END;
3381 dgit: warning: $what contains .gitattributes
3382 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3383 END
3384         close $gafl;
3385         return;
3386     }
3387     # tree contains no .gitattributes files
3388     $?=0; $!=0; close $gafl or failedcmd @cmd;
3389 }
3390
3391
3392 sub multisuite_suite_child ($$$) {
3393     my ($tsuite, $merginputs, $fn) = @_;
3394     # in child, sets things up, calls $fn->(), and returns undef
3395     # in parent, returns canonical suite name for $tsuite
3396     my $canonsuitefh = IO::File::new_tmpfile;
3397     my $pid = fork // die $!;
3398     if (!$pid) {
3399         forkcheck_setup();
3400         $isuite = $tsuite;
3401         $us .= " [$isuite]";
3402         $debugprefix .= " ";
3403         progress "fetching $tsuite...";
3404         canonicalise_suite();
3405         print $canonsuitefh $csuite, "\n" or die $!;
3406         close $canonsuitefh or die $!;
3407         $fn->();
3408         return undef;
3409     }
3410     waitpid $pid,0 == $pid or die $!;
3411     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3412     seek $canonsuitefh,0,0 or die $!;
3413     local $csuite = <$canonsuitefh>;
3414     die $! unless defined $csuite && chomp $csuite;
3415     if ($? == 256*4) {
3416         printdebug "multisuite $tsuite missing\n";
3417         return $csuite;
3418     }
3419     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3420     push @$merginputs, {
3421         Ref => lrref,
3422         Info => $csuite,
3423     };
3424     return $csuite;
3425 }
3426
3427 sub fork_for_multisuite ($) {
3428     my ($before_fetch_merge) = @_;
3429     # if nothing unusual, just returns ''
3430     #
3431     # if multisuite:
3432     # returns 0 to caller in child, to do first of the specified suites
3433     # in child, $csuite is not yet set
3434     #
3435     # returns 1 to caller in parent, to finish up anything needed after
3436     # in parent, $csuite is set to canonicalised portmanteau
3437
3438     my $org_isuite = $isuite;
3439     my @suites = split /\,/, $isuite;
3440     return '' unless @suites > 1;
3441     printdebug "fork_for_multisuite: @suites\n";
3442
3443     my @mergeinputs;
3444
3445     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3446                                             sub { });
3447     return 0 unless defined $cbasesuite;
3448
3449     fail "package $package missing in (base suite) $cbasesuite"
3450         unless @mergeinputs;
3451
3452     my @csuites = ($cbasesuite);
3453
3454     $before_fetch_merge->();
3455
3456     foreach my $tsuite (@suites[1..$#suites]) {
3457         $tsuite =~ s/^-/$cbasesuite-/;
3458         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3459                                                sub {
3460             @end = ();
3461             fetch();
3462             exit 0;
3463         });
3464         # xxx collecte the ref here
3465
3466         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3467         push @csuites, $csubsuite;
3468     }
3469
3470     foreach my $mi (@mergeinputs) {
3471         my $ref = git_get_ref $mi->{Ref};
3472         die "$mi->{Ref} ?" unless length $ref;
3473         $mi->{Commit} = $ref;
3474     }
3475
3476     $csuite = join ",", @csuites;
3477
3478     my $previous = git_get_ref lrref;
3479     if ($previous) {
3480         unshift @mergeinputs, {
3481             Commit => $previous,
3482             Info => "local combined tracking branch",
3483             Warning =>
3484  "archive seems to have rewound: local tracking branch is ahead!",
3485         };
3486     }
3487
3488     foreach my $ix (0..$#mergeinputs) {
3489         $mergeinputs[$ix]{Index} = $ix;
3490     }
3491
3492     @mergeinputs = sort {
3493         -version_compare(mergeinfo_version $a,
3494                          mergeinfo_version $b) # highest version first
3495             or
3496         $a->{Index} <=> $b->{Index}; # earliest in spec first
3497     } @mergeinputs;
3498
3499     my @needed;
3500
3501   NEEDED:
3502     foreach my $mi (@mergeinputs) {
3503         printdebug "multisuite merge check $mi->{Info}\n";
3504         foreach my $previous (@needed) {
3505             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3506             printdebug "multisuite merge un-needed $previous->{Info}\n";
3507             next NEEDED;
3508         }
3509         push @needed, $mi;
3510         printdebug "multisuite merge this-needed\n";
3511         $mi->{Character} = '+';
3512     }
3513
3514     $needed[0]{Character} = '*';
3515
3516     my $output = $needed[0]{Commit};
3517
3518     if (@needed > 1) {
3519         printdebug "multisuite merge nontrivial\n";
3520         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3521
3522         my $commit = "tree $tree\n";
3523         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3524             "Input branches:\n";
3525
3526         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3527             printdebug "multisuite merge include $mi->{Info}\n";
3528             $mi->{Character} //= ' ';
3529             $commit .= "parent $mi->{Commit}\n";
3530             $msg .= sprintf " %s  %-25s %s\n",
3531                 $mi->{Character},
3532                 (mergeinfo_version $mi),
3533                 $mi->{Info};
3534         }
3535         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3536         $msg .= "\nKey\n".
3537             " * marks the highest version branch, which choose to use\n".
3538             " + marks each branch which was not already an ancestor\n\n".
3539             "[dgit multi-suite $csuite]\n";
3540         $commit .=
3541             "author $authline\n".
3542             "committer $authline\n\n";
3543         $output = make_commit_text $commit.$msg;
3544         printdebug "multisuite merge generated $output\n";
3545     }
3546
3547     fetch_from_archive_record_1($output);
3548     fetch_from_archive_record_2($output);
3549
3550     progress "calculated combined tracking suite $csuite";
3551
3552     return 1;
3553 }
3554
3555 sub clone_set_head () {
3556     open H, "> .git/HEAD" or die $!;
3557     print H "ref: ".lref()."\n" or die $!;
3558     close H or die $!;
3559 }
3560 sub clone_finish ($) {
3561     my ($dstdir) = @_;
3562     runcmd @git, qw(reset --hard), lrref();
3563     runcmd qw(bash -ec), <<'END';
3564         set -o pipefail
3565         git ls-tree -r --name-only -z HEAD | \
3566         xargs -0r touch -h -r . --
3567 END
3568     printdone "ready for work in $dstdir";
3569 }
3570
3571 sub clone ($) {
3572     # in multisuite, returns twice!
3573     # once in parent after first suite fetched,
3574     # and then again in child after everything is finished
3575     my ($dstdir) = @_;
3576     badusage "dry run makes no sense with clone" unless act_local();
3577
3578     my $multi_fetched = fork_for_multisuite(sub {
3579         printdebug "multi clone before fetch merge\n";
3580         changedir $dstdir;
3581     });
3582     if ($multi_fetched) {
3583         printdebug "multi clone after fetch merge\n";
3584         clone_set_head();
3585         clone_finish($dstdir);
3586         return;
3587     }
3588     printdebug "clone main body\n";
3589
3590     canonicalise_suite();
3591     my $hasgit = check_for_git();
3592     mkdir $dstdir or fail "create \`$dstdir': $!";
3593     changedir $dstdir;
3594     runcmd @git, qw(init -q);
3595     setup_new_tree();
3596     clone_set_head();
3597     my $giturl = access_giturl(1);
3598     if (defined $giturl) {
3599         runcmd @git, qw(remote add), 'origin', $giturl;
3600     }
3601     if ($hasgit) {
3602         progress "fetching existing git history";
3603         git_fetch_us();
3604         runcmd_ordryrun_local @git, qw(fetch origin);
3605     } else {
3606         progress "starting new git history";
3607     }
3608     fetch_from_archive() or no_such_package;
3609     my $vcsgiturl = $dsc->{'Vcs-Git'};
3610     if (length $vcsgiturl) {
3611         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3612         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3613     }
3614     clone_finish($dstdir);
3615 }
3616
3617 sub fetch () {
3618     canonicalise_suite();
3619     if (check_for_git()) {
3620         git_fetch_us();
3621     }
3622     fetch_from_archive() or no_such_package();
3623     printdone "fetched into ".lrref();
3624 }
3625
3626 sub pull () {
3627     my $multi_fetched = fork_for_multisuite(sub { });
3628     fetch() unless $multi_fetched; # parent
3629     return if $multi_fetched eq '0'; # child
3630     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3631         lrref();
3632     printdone "fetched to ".lrref()." and merged into HEAD";
3633 }
3634
3635 sub check_not_dirty () {
3636     foreach my $f (qw(local-options local-patch-header)) {
3637         if (stat_exists "debian/source/$f") {
3638             fail "git tree contains debian/source/$f";
3639         }
3640     }
3641
3642     return if $ignoredirty;
3643
3644     my @cmd = (@git, qw(diff --quiet HEAD));
3645     debugcmd "+",@cmd;
3646     $!=0; $?=-1; system @cmd;
3647     return if !$?;
3648     if ($?==256) {
3649         fail "working tree is dirty (does not match HEAD)";
3650     } else {
3651         failedcmd @cmd;
3652     }
3653 }
3654
3655 sub commit_admin ($) {
3656     my ($m) = @_;
3657     progress "$m";
3658     runcmd_ordryrun_local @git, qw(commit -m), $m;
3659 }
3660
3661 sub commit_quilty_patch () {
3662     my $output = cmdoutput @git, qw(status --porcelain);
3663     my %adds;
3664     foreach my $l (split /\n/, $output) {
3665         next unless $l =~ m/\S/;
3666         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3667             $adds{$1}++;
3668         }
3669     }
3670     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3671     if (!%adds) {
3672         progress "nothing quilty to commit, ok.";
3673         return;
3674     }
3675     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3676     runcmd_ordryrun_local @git, qw(add -f), @adds;
3677     commit_admin <<END
3678 Commit Debian 3.0 (quilt) metadata
3679
3680 [dgit ($our_version) quilt-fixup]
3681 END
3682 }
3683
3684 sub get_source_format () {
3685     my %options;
3686     if (open F, "debian/source/options") {
3687         while (<F>) {
3688             next if m/^\s*\#/;
3689             next unless m/\S/;
3690             s/\s+$//; # ignore missing final newline
3691             if (m/\s*\#\s*/) {
3692                 my ($k, $v) = ($`, $'); #');
3693                 $v =~ s/^"(.*)"$/$1/;
3694                 $options{$k} = $v;
3695             } else {
3696                 $options{$_} = 1;
3697             }
3698         }
3699         F->error and die $!;
3700         close F;
3701     } else {
3702         die $! unless $!==&ENOENT;
3703     }
3704
3705     if (!open F, "debian/source/format") {
3706         die $! unless $!==&ENOENT;
3707         return '';
3708     }
3709     $_ = <F>;
3710     F->error and die $!;
3711     chomp;
3712     return ($_, \%options);
3713 }
3714
3715 sub madformat_wantfixup ($) {
3716     my ($format) = @_;
3717     return 0 unless $format eq '3.0 (quilt)';
3718     our $quilt_mode_warned;
3719     if ($quilt_mode eq 'nocheck') {
3720         progress "Not doing any fixup of \`$format' due to".
3721             " ----no-quilt-fixup or --quilt=nocheck"
3722             unless $quilt_mode_warned++;
3723         return 0;
3724     }
3725     progress "Format \`$format', need to check/update patch stack"
3726         unless $quilt_mode_warned++;
3727     return 1;
3728 }
3729
3730 sub maybe_split_brain_save ($$$) {
3731     my ($headref, $dgitview, $msg) = @_;
3732     # => message fragment "$saved" describing disposition of $dgitview
3733     return "commit id $dgitview" unless defined $split_brain_save;
3734     my @cmd = (shell_cmd "cd ../../../..",
3735                @git, qw(update-ref -m),
3736                "dgit --dgit-view-save $msg HEAD=$headref",
3737                $split_brain_save, $dgitview);
3738     runcmd @cmd;
3739     return "and left in $split_brain_save";
3740 }
3741
3742 # An "infopair" is a tuple [ $thing, $what ]
3743 # (often $thing is a commit hash; $what is a description)
3744
3745 sub infopair_cond_equal ($$) {
3746     my ($x,$y) = @_;
3747     $x->[0] eq $y->[0] or fail <<END;
3748 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3749 END
3750 };
3751
3752 sub infopair_lrf_tag_lookup ($$) {
3753     my ($tagnames, $what) = @_;
3754     # $tagname may be an array ref
3755     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3756     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3757     foreach my $tagname (@tagnames) {
3758         my $lrefname = lrfetchrefs."/tags/$tagname";
3759         my $tagobj = $lrfetchrefs_f{$lrefname};
3760         next unless defined $tagobj;
3761         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3762         return [ git_rev_parse($tagobj), $what ];
3763     }
3764     fail @tagnames==1 ? <<END : <<END;
3765 Wanted tag $what (@tagnames) on dgit server, but not found
3766 END
3767 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3768 END
3769 }
3770
3771 sub infopair_cond_ff ($$) {
3772     my ($anc,$desc) = @_;
3773     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3774 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3775 END
3776 };
3777
3778 sub pseudomerge_version_check ($$) {
3779     my ($clogp, $archive_hash) = @_;
3780
3781     my $arch_clogp = commit_getclogp $archive_hash;
3782     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3783                      'version currently in archive' ];
3784     if (defined $overwrite_version) {
3785         if (length $overwrite_version) {
3786             infopair_cond_equal([ $overwrite_version,
3787                                   '--overwrite= version' ],
3788                                 $i_arch_v);
3789         } else {
3790             my $v = $i_arch_v->[0];
3791             progress "Checking package changelog for archive version $v ...";
3792             my $cd;
3793             eval {
3794                 my @xa = ("-f$v", "-t$v");
3795                 my $vclogp = parsechangelog @xa;
3796                 my $gf = sub {
3797                     my ($fn) = @_;
3798                     [ (getfield $vclogp, $fn),
3799                       "$fn field from dpkg-parsechangelog @xa" ];
3800                 };
3801                 my $cv = $gf->('Version');
3802                 infopair_cond_equal($i_arch_v, $cv);
3803                 $cd = $gf->('Distribution');
3804             };
3805             if ($@) {
3806                 $@ =~ s/^dgit: //gm;
3807                 fail "$@".
3808                     "Perhaps debian/changelog does not mention $v ?";
3809             }
3810             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3811 $cd->[1] is $cd->[0]
3812 Your tree seems to based on earlier (not uploaded) $v.
3813 END
3814         }
3815     }
3816
3817     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3818     return $i_arch_v;
3819 }
3820
3821 sub pseudomerge_make_commit ($$$$ $$) {
3822     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3823         $msg_cmd, $msg_msg) = @_;
3824     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3825
3826     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3827     my $authline = clogp_authline $clogp;
3828
3829     chomp $msg_msg;
3830     $msg_cmd .=
3831         !defined $overwrite_version ? ""
3832         : !length  $overwrite_version ? " --overwrite"
3833         : " --overwrite=".$overwrite_version;
3834
3835     mkpath '.git/dgit';
3836     my $pmf = ".git/dgit/pseudomerge";
3837     open MC, ">", $pmf or die "$pmf $!";
3838     print MC <<END or die $!;
3839 tree $tree
3840 parent $dgitview
3841 parent $archive_hash
3842 author $authline
3843 committer $authline
3844
3845 $msg_msg
3846
3847 [$msg_cmd]
3848 END
3849     close MC or die $!;
3850
3851     return make_commit($pmf);
3852 }
3853
3854 sub splitbrain_pseudomerge ($$$$) {
3855     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3856     # => $merged_dgitview
3857     printdebug "splitbrain_pseudomerge...\n";
3858     #
3859     #     We:      debian/PREVIOUS    HEAD($maintview)
3860     # expect:          o ----------------- o
3861     #                    \                   \
3862     #                     o                   o
3863     #                 a/d/PREVIOUS        $dgitview
3864     #                $archive_hash              \
3865     #  If so,                \                   \
3866     #  we do:                 `------------------ o
3867     #   this:                                   $dgitview'
3868     #
3869
3870     return $dgitview unless defined $archive_hash;
3871     return $dgitview if deliberately_not_fast_forward();
3872
3873     printdebug "splitbrain_pseudomerge...\n";
3874
3875     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3876
3877     if (!defined $overwrite_version) {
3878         progress "Checking that HEAD inciudes all changes in archive...";
3879     }
3880
3881     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3882
3883     if (defined $overwrite_version) {
3884     } elsif (!eval {
3885         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3886         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3887         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3888         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3889         my $i_archive = [ $archive_hash, "current archive contents" ];
3890
3891         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3892
3893         infopair_cond_equal($i_dgit, $i_archive);
3894         infopair_cond_ff($i_dep14, $i_dgit);
3895         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3896         1;
3897     }) {
3898         print STDERR <<END;
3899 $us: check failed (maybe --overwrite is needed, consult documentation)
3900 END
3901         die "$@";
3902     }
3903
3904     my $r = pseudomerge_make_commit
3905         $clogp, $dgitview, $archive_hash, $i_arch_v,
3906         "dgit --quilt=$quilt_mode",
3907         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3908 Declare fast forward from $i_arch_v->[0]
3909 END_OVERWR
3910 Make fast forward from $i_arch_v->[0]
3911 END_MAKEFF
3912
3913     maybe_split_brain_save $maintview, $r, "pseudomerge";
3914
3915     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3916     return $r;
3917 }
3918
3919 sub plain_overwrite_pseudomerge ($$$) {
3920     my ($clogp, $head, $archive_hash) = @_;
3921
3922     printdebug "plain_overwrite_pseudomerge...";
3923
3924     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3925
3926     return $head if is_fast_fwd $archive_hash, $head;
3927
3928     my $m = "Declare fast forward from $i_arch_v->[0]";
3929
3930     my $r = pseudomerge_make_commit
3931         $clogp, $head, $archive_hash, $i_arch_v,
3932         "dgit", $m;
3933
3934     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3935
3936     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3937     return $r;
3938 }
3939
3940 sub push_parse_changelog ($) {
3941     my ($clogpfn) = @_;
3942
3943     my $clogp = Dpkg::Control::Hash->new();
3944     $clogp->load($clogpfn) or die;
3945
3946     my $clogpackage = getfield $clogp, 'Source';
3947     $package //= $clogpackage;
3948     fail "-p specified $package but changelog specified $clogpackage"
3949         unless $package eq $clogpackage;
3950     my $cversion = getfield $clogp, 'Version';
3951
3952     if (!$we_are_initiator) {
3953         # rpush initiator can't do this because it doesn't have $isuite yet
3954         my $tag = debiantag($cversion, access_nomdistro);
3955         runcmd @git, qw(check-ref-format), $tag;
3956     }
3957
3958     my $dscfn = dscfn($cversion);
3959
3960     return ($clogp, $cversion, $dscfn);
3961 }
3962
3963 sub push_parse_dsc ($$$) {
3964     my ($dscfn,$dscfnwhat, $cversion) = @_;
3965     $dsc = parsecontrol($dscfn,$dscfnwhat);
3966     my $dversion = getfield $dsc, 'Version';
3967     my $dscpackage = getfield $dsc, 'Source';
3968     ($dscpackage eq $package && $dversion eq $cversion) or
3969         fail "$dscfn is for $dscpackage $dversion".
3970             " but debian/changelog is for $package $cversion";
3971 }
3972
3973 sub push_tagwants ($$$$) {
3974     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3975     my @tagwants;
3976     push @tagwants, {
3977         TagFn => \&debiantag,
3978         Objid => $dgithead,
3979         TfSuffix => '',
3980         View => 'dgit',
3981     };
3982     if (defined $maintviewhead) {
3983         push @tagwants, {
3984             TagFn => \&debiantag_maintview,
3985             Objid => $maintviewhead,
3986             TfSuffix => '-maintview',
3987             View => 'maint',
3988         };
3989     } elsif ($dodep14tag eq 'no' ? 0
3990              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3991              : $dodep14tag eq 'always'
3992              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3993 --dep14tag-always (or equivalent in config) means server must support
3994  both "new" and "maint" tag formats, but config says it doesn't.
3995 END
3996             : die "$dodep14tag ?") {
3997         push @tagwants, {
3998             TagFn => \&debiantag_maintview,
3999             Objid => $dgithead,
4000             TfSuffix => '-dgit',
4001             View => 'dgit',
4002         };
4003     };
4004     foreach my $tw (@tagwants) {
4005         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4006         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4007     }
4008     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4009     return @tagwants;
4010 }
4011
4012 sub push_mktags ($$ $$ $) {
4013     my ($clogp,$dscfn,
4014         $changesfile,$changesfilewhat,
4015         $tagwants) = @_;
4016
4017     die unless $tagwants->[0]{View} eq 'dgit';
4018
4019     my $declaredistro = access_nomdistro();
4020     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4021     $dsc->{$ourdscfield[0]} = join " ",
4022         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4023         $reader_giturl;
4024     $dsc->save("$dscfn.tmp") or die $!;
4025
4026     my $changes = parsecontrol($changesfile,$changesfilewhat);
4027     foreach my $field (qw(Source Distribution Version)) {
4028         $changes->{$field} eq $clogp->{$field} or
4029             fail "changes field $field \`$changes->{$field}'".
4030                 " does not match changelog \`$clogp->{$field}'";
4031     }
4032
4033     my $cversion = getfield $clogp, 'Version';
4034     my $clogsuite = getfield $clogp, 'Distribution';
4035
4036     # We make the git tag by hand because (a) that makes it easier
4037     # to control the "tagger" (b) we can do remote signing
4038     my $authline = clogp_authline $clogp;
4039     my $delibs = join(" ", "",@deliberatelies);
4040
4041     my $mktag = sub {
4042         my ($tw) = @_;
4043         my $tfn = $tw->{Tfn};
4044         my $head = $tw->{Objid};
4045         my $tag = $tw->{Tag};
4046
4047         open TO, '>', $tfn->('.tmp') or die $!;
4048         print TO <<END or die $!;
4049 object $head
4050 type commit
4051 tag $tag
4052 tagger $authline
4053
4054 END
4055         if ($tw->{View} eq 'dgit') {
4056             print TO <<END or die $!;
4057 $package release $cversion for $clogsuite ($csuite) [dgit]
4058 [dgit distro=$declaredistro$delibs]
4059 END
4060             foreach my $ref (sort keys %previously) {
4061                 print TO <<END or die $!;
4062 [dgit previously:$ref=$previously{$ref}]
4063 END
4064             }
4065         } elsif ($tw->{View} eq 'maint') {
4066             print TO <<END or die $!;
4067 $package release $cversion for $clogsuite ($csuite)
4068 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4069 END
4070         } else {
4071             die Dumper($tw)."?";
4072         }
4073
4074         close TO or die $!;
4075
4076         my $tagobjfn = $tfn->('.tmp');
4077         if ($sign) {
4078             if (!defined $keyid) {
4079                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4080             }
4081             if (!defined $keyid) {
4082                 $keyid = getfield $clogp, 'Maintainer';
4083             }
4084             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4085             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4086             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4087             push @sign_cmd, $tfn->('.tmp');
4088             runcmd_ordryrun @sign_cmd;
4089             if (act_scary()) {
4090                 $tagobjfn = $tfn->('.signed.tmp');
4091                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4092                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4093             }
4094         }
4095         return $tagobjfn;
4096     };
4097
4098     my @r = map { $mktag->($_); } @$tagwants;
4099     return @r;
4100 }
4101
4102 sub sign_changes ($) {
4103     my ($changesfile) = @_;
4104     if ($sign) {
4105         my @debsign_cmd = @debsign;
4106         push @debsign_cmd, "-k$keyid" if defined $keyid;
4107         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4108         push @debsign_cmd, $changesfile;
4109         runcmd_ordryrun @debsign_cmd;
4110     }
4111 }
4112
4113 sub dopush () {
4114     printdebug "actually entering push\n";
4115
4116     supplementary_message(<<'END');
4117 Push failed, while checking state of the archive.
4118 You can retry the push, after fixing the problem, if you like.
4119 END
4120     if (check_for_git()) {
4121         git_fetch_us();
4122     }
4123     my $archive_hash = fetch_from_archive();
4124     if (!$archive_hash) {
4125         $new_package or
4126             fail "package appears to be new in this suite;".
4127                 " if this is intentional, use --new";
4128     }
4129
4130     supplementary_message(<<'END');
4131 Push failed, while preparing your push.
4132 You can retry the push, after fixing the problem, if you like.
4133 END
4134
4135     need_tagformat 'new', "quilt mode $quilt_mode"
4136         if quiltmode_splitbrain;
4137
4138     prep_ud();
4139
4140     access_giturl(); # check that success is vaguely likely
4141     rpush_handle_protovsn_bothends() if $we_are_initiator;
4142     select_tagformat();
4143
4144     my $clogpfn = ".git/dgit/changelog.822.tmp";
4145     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4146
4147     responder_send_file('parsed-changelog', $clogpfn);
4148
4149     my ($clogp, $cversion, $dscfn) =
4150         push_parse_changelog("$clogpfn");
4151
4152     my $dscpath = "$buildproductsdir/$dscfn";
4153     stat_exists $dscpath or
4154         fail "looked for .dsc $dscpath, but $!;".
4155             " maybe you forgot to build";
4156
4157     responder_send_file('dsc', $dscpath);
4158
4159     push_parse_dsc($dscpath, $dscfn, $cversion);
4160
4161     my $format = getfield $dsc, 'Format';
4162     printdebug "format $format\n";
4163
4164     my $actualhead = git_rev_parse('HEAD');
4165     my $dgithead = $actualhead;
4166     my $maintviewhead = undef;
4167
4168     my $upstreamversion = upstreamversion $clogp->{Version};
4169
4170     if (madformat_wantfixup($format)) {
4171         # user might have not used dgit build, so maybe do this now:
4172         if (quiltmode_splitbrain()) {
4173             changedir $ud;
4174             quilt_make_fake_dsc($upstreamversion);
4175             my $cachekey;
4176             ($dgithead, $cachekey) =
4177                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4178             $dgithead or fail
4179  "--quilt=$quilt_mode but no cached dgit view:
4180  perhaps tree changed since dgit build[-source] ?";
4181             $split_brain = 1;
4182             $dgithead = splitbrain_pseudomerge($clogp,
4183                                                $actualhead, $dgithead,
4184                                                $archive_hash);
4185             $maintviewhead = $actualhead;
4186             changedir '../../../..';
4187             prep_ud(); # so _only_subdir() works, below
4188         } else {
4189             commit_quilty_patch();
4190         }
4191     }
4192
4193     if (defined $overwrite_version && !defined $maintviewhead) {
4194         $dgithead = plain_overwrite_pseudomerge($clogp,
4195                                                 $dgithead,
4196                                                 $archive_hash);
4197     }
4198
4199     check_not_dirty();
4200
4201     my $forceflag = '';
4202     if ($archive_hash) {
4203         if (is_fast_fwd($archive_hash, $dgithead)) {
4204             # ok
4205         } elsif (deliberately_not_fast_forward) {
4206             $forceflag = '+';
4207         } else {
4208             fail "dgit push: HEAD is not a descendant".
4209                 " of the archive's version.\n".
4210                 "To overwrite the archive's contents,".
4211                 " pass --overwrite[=VERSION].\n".
4212                 "To rewind history, if permitted by the archive,".
4213                 " use --deliberately-not-fast-forward.";
4214         }
4215     }
4216
4217     changedir $ud;
4218     progress "checking that $dscfn corresponds to HEAD";
4219     runcmd qw(dpkg-source -x --),
4220         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4221     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4222     check_for_vendor_patches() if madformat($dsc->{format});
4223     changedir '../../../..';
4224     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4225     debugcmd "+",@diffcmd;
4226     $!=0; $?=-1;
4227     my $r = system @diffcmd;
4228     if ($r) {
4229         if ($r==256) {
4230             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4231             fail <<END
4232 HEAD specifies a different tree to $dscfn:
4233 $diffs
4234 Perhaps you forgot to build.  Or perhaps there is a problem with your
4235  source tree (see dgit(7) for some hints).  To see a full diff, run
4236    git diff $tree HEAD
4237 END
4238         } else {
4239             failedcmd @diffcmd;
4240         }
4241     }
4242     if (!$changesfile) {
4243         my $pat = changespat $cversion;
4244         my @cs = glob "$buildproductsdir/$pat";
4245         fail "failed to find unique changes file".
4246             " (looked for $pat in $buildproductsdir);".
4247             " perhaps you need to use dgit -C"
4248             unless @cs==1;
4249         ($changesfile) = @cs;
4250     } else {
4251         $changesfile = "$buildproductsdir/$changesfile";
4252     }
4253
4254     # Check that changes and .dsc agree enough
4255     $changesfile =~ m{[^/]*$};
4256     my $changes = parsecontrol($changesfile,$&);
4257     files_compare_inputs($dsc, $changes)
4258         unless forceing [qw(dsc-changes-mismatch)];
4259
4260     # Perhaps adjust .dsc to contain right set of origs
4261     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4262                                   $changesfile)
4263         unless forceing [qw(changes-origs-exactly)];
4264
4265     # Checks complete, we're going to try and go ahead:
4266
4267     responder_send_file('changes',$changesfile);
4268     responder_send_command("param head $dgithead");
4269     responder_send_command("param csuite $csuite");
4270     responder_send_command("param isuite $isuite");
4271     responder_send_command("param tagformat $tagformat");
4272     if (defined $maintviewhead) {
4273         die unless ($protovsn//4) >= 4;
4274         responder_send_command("param maint-view $maintviewhead");
4275     }
4276
4277     # Perhaps send buildinfo(s) for signing
4278     my $changes_files = getfield $changes, 'Files';
4279     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4280     foreach my $bi (@buildinfos) {
4281         responder_send_command("param buildinfo-filename $bi");
4282         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4283     }
4284
4285     if (deliberately_not_fast_forward) {
4286         git_for_each_ref(lrfetchrefs, sub {
4287             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4288             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4289             responder_send_command("previously $rrefname=$objid");
4290             $previously{$rrefname} = $objid;
4291         });
4292     }
4293
4294     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4295                                  ".git/dgit/tag");
4296     my @tagobjfns;
4297
4298     supplementary_message(<<'END');
4299 Push failed, while signing the tag.
4300 You can retry the push, after fixing the problem, if you like.
4301 END
4302     # If we manage to sign but fail to record it anywhere, it's fine.
4303     if ($we_are_responder) {
4304         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4305         responder_receive_files('signed-tag', @tagobjfns);
4306     } else {
4307         @tagobjfns = push_mktags($clogp,$dscpath,
4308                               $changesfile,$changesfile,
4309                               \@tagwants);
4310     }
4311     supplementary_message(<<'END');
4312 Push failed, *after* signing the tag.
4313 If you want to try again, you should use a new version number.
4314 END
4315
4316     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4317
4318     foreach my $tw (@tagwants) {
4319         my $tag = $tw->{Tag};
4320         my $tagobjfn = $tw->{TagObjFn};
4321         my $tag_obj_hash =
4322             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4323         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4324         runcmd_ordryrun_local
4325             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4326     }
4327
4328     supplementary_message(<<'END');
4329 Push failed, while updating the remote git repository - see messages above.
4330 If you want to try again, you should use a new version number.
4331 END
4332     if (!check_for_git()) {
4333         create_remote_git_repo();
4334     }
4335
4336     my @pushrefs = $forceflag.$dgithead.":".rrref();
4337     foreach my $tw (@tagwants) {
4338         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4339     }
4340
4341     runcmd_ordryrun @git,
4342         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4343     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4344
4345     supplementary_message(<<'END');
4346 Push failed, while obtaining signatures on the .changes and .dsc.
4347 If it was just that the signature failed, you may try again by using
4348 debsign by hand to sign the changes
4349    $changesfile
4350 and then dput to complete the upload.
4351 If you need to change the package, you must use a new version number.
4352 END
4353     if ($we_are_responder) {
4354         my $dryrunsuffix = act_local() ? "" : ".tmp";
4355         my @rfiles = ($dscpath, $changesfile);
4356         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4357         responder_receive_files('signed-dsc-changes',
4358                                 map { "$_$dryrunsuffix" } @rfiles);
4359     } else {
4360         if (act_local()) {
4361             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4362         } else {
4363             progress "[new .dsc left in $dscpath.tmp]";
4364         }
4365         sign_changes $changesfile;
4366     }
4367
4368     supplementary_message(<<END);
4369 Push failed, while uploading package(s) to the archive server.
4370 You can retry the upload of exactly these same files with dput of:
4371   $changesfile
4372 If that .changes file is broken, you will need to use a new version
4373 number for your next attempt at the upload.
4374 END
4375     my $host = access_cfg('upload-host','RETURN-UNDEF');
4376     my @hostarg = defined($host) ? ($host,) : ();
4377     runcmd_ordryrun @dput, @hostarg, $changesfile;
4378     printdone "pushed and uploaded $cversion";
4379
4380     supplementary_message('');
4381     responder_send_command("complete");
4382 }
4383
4384 sub pre_clone () {
4385     no_local_git_cfg();
4386 }
4387 sub cmd_clone {
4388     parseopts();
4389     my $dstdir;
4390     badusage "-p is not allowed with clone; specify as argument instead"
4391         if defined $package;
4392     if (@ARGV==1) {
4393         ($package) = @ARGV;
4394     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4395         ($package,$isuite) = @ARGV;
4396     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4397         ($package,$dstdir) = @ARGV;
4398     } elsif (@ARGV==3) {
4399         ($package,$isuite,$dstdir) = @ARGV;
4400     } else {
4401         badusage "incorrect arguments to dgit clone";
4402     }
4403     notpushing();
4404
4405     $dstdir ||= "$package";
4406     if (stat_exists $dstdir) {
4407         fail "$dstdir already exists";
4408     }
4409
4410     my $cwd_remove;
4411     if ($rmonerror && !$dryrun_level) {
4412         $cwd_remove= getcwd();
4413         unshift @end, sub {
4414             return unless defined $cwd_remove;
4415             if (!chdir "$cwd_remove") {
4416                 return if $!==&ENOENT;
4417                 die "chdir $cwd_remove: $!";
4418             }
4419             printdebug "clone rmonerror removing $dstdir\n";
4420             if (stat $dstdir) {
4421                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4422             } elsif (grep { $! == $_ }
4423                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4424             } else {
4425                 print STDERR "check whether to remove $dstdir: $!\n";
4426             }
4427         };
4428     }
4429
4430     clone($dstdir);
4431     $cwd_remove = undef;
4432 }
4433
4434 sub branchsuite () {
4435     my @cmd = (@git, qw(symbolic-ref -q HEAD));
4436     my $branch = cmdoutput_errok @cmd;
4437     if (!defined $branch) {
4438         $?==256 or failedcmd @cmd;
4439         return undef;
4440     }
4441     if ($branch =~ m#$lbranch_re#o) {
4442         return $1;
4443     } else {
4444         return undef;
4445     }
4446 }
4447
4448 sub fetchpullargs () {
4449     if (!defined $package) {
4450         my $sourcep = parsecontrol('debian/control','debian/control');
4451         $package = getfield $sourcep, 'Source';
4452     }
4453     if (@ARGV==0) {
4454         $isuite = branchsuite();
4455         if (!$isuite) {
4456             my $clogp = parsechangelog();
4457             my $clogsuite = getfield $clogp, 'Distribution';
4458             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4459         }
4460     } elsif (@ARGV==1) {
4461         ($isuite) = @ARGV;
4462     } else {
4463         badusage "incorrect arguments to dgit fetch or dgit pull";
4464     }
4465     notpushing();
4466 }
4467
4468 sub cmd_fetch {
4469     parseopts();
4470     fetchpullargs();
4471     my $multi_fetched = fork_for_multisuite(sub { });
4472     exit 0 if $multi_fetched;
4473     fetch();
4474 }
4475
4476 sub cmd_pull {
4477     parseopts();
4478     fetchpullargs();
4479     if (quiltmode_splitbrain()) {
4480         my ($format, $fopts) = get_source_format();
4481         madformat($format) and fail <<END
4482 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4483 END
4484     }
4485     pull();
4486 }
4487
4488 sub prep_push () {
4489     parseopts();
4490     build_or_push_prep_early();
4491     pushing();
4492     check_not_dirty();
4493     my $specsuite;
4494     if (@ARGV==0) {
4495     } elsif (@ARGV==1) {
4496         ($specsuite) = (@ARGV);
4497     } else {
4498         badusage "incorrect arguments to dgit $subcommand";
4499     }
4500     if ($new_package) {
4501         local ($package) = $existing_package; # this is a hack
4502         canonicalise_suite();
4503     } else {
4504         canonicalise_suite();
4505     }
4506     if (defined $specsuite &&
4507         $specsuite ne $isuite &&
4508         $specsuite ne $csuite) {
4509             fail "dgit $subcommand: changelog specifies $isuite ($csuite)".
4510                 " but command line specifies $specsuite";
4511     }
4512 }
4513
4514 sub cmd_push {
4515     prep_push();
4516     dopush();
4517 }
4518
4519 #---------- remote commands' implementation ----------
4520
4521 sub pre_remote_push_build_host {
4522     my ($nrargs) = shift @ARGV;
4523     my (@rargs) = @ARGV[0..$nrargs-1];
4524     @ARGV = @ARGV[$nrargs..$#ARGV];
4525     die unless @rargs;
4526     my ($dir,$vsnwant) = @rargs;
4527     # vsnwant is a comma-separated list; we report which we have
4528     # chosen in our ready response (so other end can tell if they
4529     # offered several)
4530     $debugprefix = ' ';
4531     $we_are_responder = 1;
4532     $us .= " (build host)";
4533
4534     open PI, "<&STDIN" or die $!;
4535     open STDIN, "/dev/null" or die $!;
4536     open PO, ">&STDOUT" or die $!;
4537     autoflush PO 1;
4538     open STDOUT, ">&STDERR" or die $!;
4539     autoflush STDOUT 1;
4540
4541     $vsnwant //= 1;
4542     ($protovsn) = grep {
4543         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4544     } @rpushprotovsn_support;
4545
4546     fail "build host has dgit rpush protocol versions ".
4547         (join ",", @rpushprotovsn_support).
4548         " but invocation host has $vsnwant"
4549         unless defined $protovsn;
4550
4551     changedir $dir;
4552 }
4553 sub cmd_remote_push_build_host {
4554     responder_send_command("dgit-remote-push-ready $protovsn");
4555     &cmd_push;
4556 }
4557
4558 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4559 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4560 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4561 #     a good error message)
4562
4563 sub rpush_handle_protovsn_bothends () {
4564     if ($protovsn < 4) {
4565         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4566     }
4567     select_tagformat();
4568 }
4569
4570 our $i_tmp;
4571
4572 sub i_cleanup {
4573     local ($@, $?);
4574     my $report = i_child_report();
4575     if (defined $report) {
4576         printdebug "($report)\n";
4577     } elsif ($i_child_pid) {
4578         printdebug "(killing build host child $i_child_pid)\n";
4579         kill 15, $i_child_pid;
4580     }
4581     if (defined $i_tmp && !defined $initiator_tempdir) {
4582         changedir "/";
4583         eval { rmtree $i_tmp; };
4584     }
4585 }
4586
4587 END {
4588     return unless forkcheck_mainprocess();
4589     i_cleanup();
4590 }
4591
4592 sub i_method {
4593     my ($base,$selector,@args) = @_;
4594     $selector =~ s/\-/_/g;
4595     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4596 }
4597
4598 sub pre_rpush () {
4599     no_local_git_cfg();
4600 }
4601 sub cmd_rpush {
4602     my $host = nextarg;
4603     my $dir;
4604     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4605         $host = $1;
4606         $dir = $'; #';
4607     } else {
4608         $dir = nextarg;
4609     }
4610     $dir =~ s{^-}{./-};
4611     my @rargs = ($dir);
4612     push @rargs, join ",", @rpushprotovsn_support;
4613     my @rdgit;
4614     push @rdgit, @dgit;
4615     push @rdgit, @ropts;
4616     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4617     push @rdgit, @ARGV;
4618     my @cmd = (@ssh, $host, shellquote @rdgit);
4619     debugcmd "+",@cmd;
4620
4621     $we_are_initiator=1;
4622
4623     if (defined $initiator_tempdir) {
4624         rmtree $initiator_tempdir;
4625         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4626         $i_tmp = $initiator_tempdir;
4627     } else {
4628         $i_tmp = tempdir();
4629     }
4630     $i_child_pid = open2(\*RO, \*RI, @cmd);
4631     changedir $i_tmp;
4632     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4633     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4634     $supplementary_message = '' unless $protovsn >= 3;
4635
4636     for (;;) {
4637         my ($icmd,$iargs) = initiator_expect {
4638             m/^(\S+)(?: (.*))?$/;
4639             ($1,$2);
4640         };
4641         i_method "i_resp", $icmd, $iargs;
4642     }
4643 }
4644
4645 sub i_resp_progress ($) {
4646     my ($rhs) = @_;
4647     my $msg = protocol_read_bytes \*RO, $rhs;
4648     progress $msg;
4649 }
4650
4651 sub i_resp_supplementary_message ($) {
4652     my ($rhs) = @_;
4653     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4654 }
4655
4656 sub i_resp_complete {
4657     my $pid = $i_child_pid;
4658     $i_child_pid = undef; # prevents killing some other process with same pid
4659     printdebug "waiting for build host child $pid...\n";
4660     my $got = waitpid $pid, 0;
4661     die $! unless $got == $pid;
4662     die "build host child failed $?" if $?;
4663
4664     i_cleanup();
4665     printdebug "all done\n";
4666     exit 0;
4667 }
4668
4669 sub i_resp_file ($) {
4670     my ($keyword) = @_;
4671     my $localname = i_method "i_localname", $keyword;
4672     my $localpath = "$i_tmp/$localname";
4673     stat_exists $localpath and
4674         badproto \*RO, "file $keyword ($localpath) twice";
4675     protocol_receive_file \*RO, $localpath;
4676     i_method "i_file", $keyword;
4677 }
4678
4679 our %i_param;
4680
4681 sub i_resp_param ($) {
4682     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4683     $i_param{$1} = $2;
4684 }
4685
4686 sub i_resp_previously ($) {
4687     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4688         or badproto \*RO, "bad previously spec";
4689     my $r = system qw(git check-ref-format), $1;
4690     die "bad previously ref spec ($r)" if $r;
4691     $previously{$1} = $2;
4692 }
4693
4694 our %i_wanted;
4695
4696 sub i_resp_want ($) {
4697     my ($keyword) = @_;
4698     die "$keyword ?" if $i_wanted{$keyword}++;
4699
4700     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4701     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4702     die unless $isuite =~ m/^$suite_re$/;
4703
4704     pushing();
4705     rpush_handle_protovsn_bothends();
4706
4707     fail "rpush negotiated protocol version $protovsn".
4708         " which does not support quilt mode $quilt_mode"
4709         if quiltmode_splitbrain;
4710
4711     my @localpaths = i_method "i_want", $keyword;
4712     printdebug "[[  $keyword @localpaths\n";
4713     foreach my $localpath (@localpaths) {
4714         protocol_send_file \*RI, $localpath;
4715     }
4716     print RI "files-end\n" or die $!;
4717 }
4718
4719 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4720
4721 sub i_localname_parsed_changelog {
4722     return "remote-changelog.822";
4723 }
4724 sub i_file_parsed_changelog {
4725     ($i_clogp, $i_version, $i_dscfn) =
4726         push_parse_changelog "$i_tmp/remote-changelog.822";
4727     die if $i_dscfn =~ m#/|^\W#;
4728 }
4729
4730 sub i_localname_dsc {
4731     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4732     return $i_dscfn;
4733 }
4734 sub i_file_dsc { }
4735
4736 sub i_localname_buildinfo ($) {
4737     my $bi = $i_param{'buildinfo-filename'};
4738     defined $bi or badproto \*RO, "buildinfo before filename";
4739     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4740     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4741         or badproto \*RO, "improper buildinfo filename";
4742     return $&;
4743 }
4744 sub i_file_buildinfo {
4745     my $bi = $i_param{'buildinfo-filename'};
4746     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4747     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4748     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4749         files_compare_inputs($bd, $ch);
4750         (getfield $bd, $_) eq (getfield $ch, $_) or
4751             fail "buildinfo mismatch $_"
4752             foreach qw(Source Version);
4753         !defined $bd->{$_} or
4754             fail "buildinfo contains $_"
4755             foreach qw(Changes Changed-by Distribution);
4756     }
4757     push @i_buildinfos, $bi;
4758     delete $i_param{'buildinfo-filename'};
4759 }
4760
4761 sub i_localname_changes {
4762     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4763     $i_changesfn = $i_dscfn;
4764     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4765     return $i_changesfn;
4766 }
4767 sub i_file_changes { }
4768
4769 sub i_want_signed_tag {
4770     printdebug Dumper(\%i_param, $i_dscfn);
4771     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4772         && defined $i_param{'csuite'}
4773         or badproto \*RO, "premature desire for signed-tag";
4774     my $head = $i_param{'head'};
4775     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4776
4777     my $maintview = $i_param{'maint-view'};
4778     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4779
4780     select_tagformat();
4781     if ($protovsn >= 4) {
4782         my $p = $i_param{'tagformat'} // '<undef>';
4783         $p eq $tagformat
4784             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4785     }
4786
4787     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4788     $csuite = $&;
4789     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4790
4791     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4792
4793     return
4794         push_mktags $i_clogp, $i_dscfn,
4795             $i_changesfn, 'remote changes',
4796             \@tagwants;
4797 }
4798
4799 sub i_want_signed_dsc_changes {
4800     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4801     sign_changes $i_changesfn;
4802     return ($i_dscfn, $i_changesfn, @i_buildinfos);
4803 }
4804
4805 #---------- building etc. ----------
4806
4807 our $version;
4808 our $sourcechanges;
4809 our $dscfn;
4810
4811 #----- `3.0 (quilt)' handling -----
4812
4813 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4814
4815 sub quiltify_dpkg_commit ($$$;$) {
4816     my ($patchname,$author,$msg, $xinfo) = @_;
4817     $xinfo //= '';
4818
4819     mkpath '.git/dgit';
4820     my $descfn = ".git/dgit/quilt-description.tmp";
4821     open O, '>', $descfn or die "$descfn: $!";
4822     $msg =~ s/\n+/\n\n/;
4823     print O <<END or die $!;
4824 From: $author
4825 ${xinfo}Subject: $msg
4826 ---
4827
4828 END
4829     close O or die $!;
4830
4831     {
4832         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4833         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4834         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4835         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4836     }
4837 }
4838
4839 sub quiltify_trees_differ ($$;$$$) {
4840     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4841     # returns true iff the two tree objects differ other than in debian/
4842     # with $finegrained,
4843     # returns bitmask 01 - differ in upstream files except .gitignore
4844     #                 02 - differ in .gitignore
4845     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4846     #  is set for each modified .gitignore filename $fn
4847     # if $unrepres is defined, array ref to which is appeneded
4848     #  a list of unrepresentable changes (removals of upstream files
4849     #  (as messages)
4850     local $/=undef;
4851     my @cmd = (@git, qw(diff-tree -z --no-renames));
4852     push @cmd, qw(--name-only) unless $unrepres;
4853     push @cmd, qw(-r) if $finegrained || $unrepres;
4854     push @cmd, $x, $y;
4855     my $diffs= cmdoutput @cmd;
4856     my $r = 0;
4857     my @lmodes;
4858     foreach my $f (split /\0/, $diffs) {
4859         if ($unrepres && !@lmodes) {
4860             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4861             next;
4862         }
4863         my ($oldmode,$newmode) = @lmodes;
4864         @lmodes = ();
4865
4866         next if $f =~ m#^debian(?:/.*)?$#s;
4867
4868         if ($unrepres) {
4869             eval {
4870                 die "not a plain file or symlink\n"
4871                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
4872                            $oldmode =~ m/^(?:10|12)\d{4}$/;
4873                 if ($oldmode =~ m/[^0]/ &&
4874                     $newmode =~ m/[^0]/) {
4875                     # both old and new files exist
4876                     die "mode or type changed\n" if $oldmode ne $newmode;
4877                     die "modified symlink\n" unless $newmode =~ m/^10/;
4878                 } elsif ($oldmode =~ m/[^0]/) {
4879                     # deletion
4880                     die "deletion of symlink\n"
4881                         unless $oldmode =~ m/^10/;
4882                 } else {
4883                     # creation
4884                     die "creation with non-default mode\n"
4885                         unless $newmode =~ m/^100644$/ or
4886                                $newmode =~ m/^120000$/;
4887                 }
4888             };
4889             if ($@) {
4890                 local $/="\n"; chomp $@;
4891                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4892             }
4893         }
4894
4895         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4896         $r |= $isignore ? 02 : 01;
4897         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4898     }
4899     printdebug "quiltify_trees_differ $x $y => $r\n";
4900     return $r;
4901 }
4902
4903 sub quiltify_tree_sentinelfiles ($) {
4904     # lists the `sentinel' files present in the tree
4905     my ($x) = @_;
4906     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4907         qw(-- debian/rules debian/control);
4908     $r =~ s/\n/,/g;
4909     return $r;
4910 }
4911
4912 sub quiltify_splitbrain_needed () {
4913     if (!$split_brain) {
4914         progress "dgit view: changes are required...";
4915         runcmd @git, qw(checkout -q -b dgit-view);
4916         $split_brain = 1;
4917     }
4918 }
4919
4920 sub quiltify_splitbrain ($$$$$$) {
4921     my ($clogp, $unapplied, $headref, $diffbits,
4922         $editedignores, $cachekey) = @_;
4923     if ($quilt_mode !~ m/gbp|dpm/) {
4924         # treat .gitignore just like any other upstream file
4925         $diffbits = { %$diffbits };
4926         $_ = !!$_ foreach values %$diffbits;
4927     }
4928     # We would like any commits we generate to be reproducible
4929     my @authline = clogp_authline($clogp);
4930     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4931     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4932     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4933     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4934     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4935     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4936
4937     if ($quilt_mode =~ m/gbp|unapplied/ &&
4938         ($diffbits->{O2H} & 01)) {
4939         my $msg =
4940  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4941  " but git tree differs from orig in upstream files.";
4942         if (!stat_exists "debian/patches") {
4943             $msg .=
4944  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4945         }
4946         fail $msg;
4947     }
4948     if ($quilt_mode =~ m/dpm/ &&
4949         ($diffbits->{H2A} & 01)) {
4950         fail <<END;
4951 --quilt=$quilt_mode specified, implying patches-applied git tree
4952  but git tree differs from result of applying debian/patches to upstream
4953 END
4954     }
4955     if ($quilt_mode =~ m/gbp|unapplied/ &&
4956         ($diffbits->{O2A} & 01)) { # some patches
4957         quiltify_splitbrain_needed();
4958         progress "dgit view: creating patches-applied version using gbp pq";
4959         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4960         # gbp pq import creates a fresh branch; push back to dgit-view
4961         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4962         runcmd @git, qw(checkout -q dgit-view);
4963     }
4964     if ($quilt_mode =~ m/gbp|dpm/ &&
4965         ($diffbits->{O2A} & 02)) {
4966         fail <<END
4967 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4968  tool which does not create patches for changes to upstream
4969  .gitignores: but, such patches exist in debian/patches.
4970 END
4971     }
4972     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4973         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4974         quiltify_splitbrain_needed();
4975         progress "dgit view: creating patch to represent .gitignore changes";
4976         ensuredir "debian/patches";
4977         my $gipatch = "debian/patches/auto-gitignore";
4978         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4979         stat GIPATCH or die "$gipatch: $!";
4980         fail "$gipatch already exists; but want to create it".
4981             " to record .gitignore changes" if (stat _)[7];
4982         print GIPATCH <<END or die "$gipatch: $!";
4983 Subject: Update .gitignore from Debian packaging branch
4984
4985 The Debian packaging git branch contains these updates to the upstream
4986 .gitignore file(s).  This patch is autogenerated, to provide these
4987 updates to users of the official Debian archive view of the package.
4988
4989 [dgit ($our_version) update-gitignore]
4990 ---
4991 END
4992         close GIPATCH or die "$gipatch: $!";
4993         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4994             $unapplied, $headref, "--", sort keys %$editedignores;
4995         open SERIES, "+>>", "debian/patches/series" or die $!;
4996         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4997         my $newline;
4998         defined read SERIES, $newline, 1 or die $!;
4999         print SERIES "\n" or die $! unless $newline eq "\n";
5000         print SERIES "auto-gitignore\n" or die $!;
5001         close SERIES or die  $!;
5002         runcmd @git, qw(add -- debian/patches/series), $gipatch;
5003         commit_admin <<END
5004 Commit patch to update .gitignore
5005
5006 [dgit ($our_version) update-gitignore-quilt-fixup]
5007 END
5008     }
5009
5010     my $dgitview = git_rev_parse 'HEAD';
5011
5012     changedir '../../../..';
5013     # When we no longer need to support squeeze, use --create-reflog
5014     # instead of this:
5015     ensuredir ".git/logs/refs/dgit-intern";
5016     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
5017       or die $!;
5018
5019     my $oldcache = git_get_ref "refs/$splitbraincache";
5020     if ($oldcache eq $dgitview) {
5021         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
5022         # git update-ref doesn't always update, in this case.  *sigh*
5023         my $dummy = make_commit_text <<END;
5024 tree $tree
5025 parent $dgitview
5026 author Dgit <dgit\@example.com> 1000000000 +0000
5027 committer Dgit <dgit\@example.com> 1000000000 +0000
5028
5029 Dummy commit - do not use
5030 END
5031         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
5032             "refs/$splitbraincache", $dummy;
5033     }
5034     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
5035         $dgitview;
5036
5037     changedir '.git/dgit/unpack/work';
5038
5039     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5040     progress "dgit view: created ($saved)";
5041 }
5042
5043 sub quiltify ($$$$) {
5044     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5045
5046     # Quilt patchification algorithm
5047     #
5048     # We search backwards through the history of the main tree's HEAD
5049     # (T) looking for a start commit S whose tree object is identical
5050     # to to the patch tip tree (ie the tree corresponding to the
5051     # current dpkg-committed patch series).  For these purposes
5052     # `identical' disregards anything in debian/ - this wrinkle is
5053     # necessary because dpkg-source treates debian/ specially.
5054     #
5055     # We can only traverse edges where at most one of the ancestors'
5056     # trees differs (in changes outside in debian/).  And we cannot
5057     # handle edges which change .pc/ or debian/patches.  To avoid
5058     # going down a rathole we avoid traversing edges which introduce
5059     # debian/rules or debian/control.  And we set a limit on the
5060     # number of edges we are willing to look at.
5061     #
5062     # If we succeed, we walk forwards again.  For each traversed edge
5063     # PC (with P parent, C child) (starting with P=S and ending with
5064     # C=T) to we do this:
5065     #  - git checkout C
5066     #  - dpkg-source --commit with a patch name and message derived from C
5067     # After traversing PT, we git commit the changes which
5068     # should be contained within debian/patches.
5069
5070     # The search for the path S..T is breadth-first.  We maintain a
5071     # todo list containing search nodes.  A search node identifies a
5072     # commit, and looks something like this:
5073     #  $p = {
5074     #      Commit => $git_commit_id,
5075     #      Child => $c,                          # or undef if P=T
5076     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5077     #      Nontrivial => true iff $p..$c has relevant changes
5078     #  };
5079
5080     my @todo;
5081     my @nots;
5082     my $sref_S;
5083     my $max_work=100;
5084     my %considered; # saves being exponential on some weird graphs
5085
5086     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5087
5088     my $not = sub {
5089         my ($search,$whynot) = @_;
5090         printdebug " search NOT $search->{Commit} $whynot\n";
5091         $search->{Whynot} = $whynot;
5092         push @nots, $search;
5093         no warnings qw(exiting);
5094         next;
5095     };
5096
5097     push @todo, {
5098         Commit => $target,
5099     };
5100
5101     while (@todo) {
5102         my $c = shift @todo;
5103         next if $considered{$c->{Commit}}++;
5104
5105         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5106
5107         printdebug "quiltify investigate $c->{Commit}\n";
5108
5109         # are we done?
5110         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5111             printdebug " search finished hooray!\n";
5112             $sref_S = $c;
5113             last;
5114         }
5115
5116         if ($quilt_mode eq 'nofix') {
5117             fail "quilt fixup required but quilt mode is \`nofix'\n".
5118                 "HEAD commit $c->{Commit} differs from tree implied by ".
5119                 " debian/patches (tree object $oldtiptree)";
5120         }
5121         if ($quilt_mode eq 'smash') {
5122             printdebug " search quitting smash\n";
5123             last;
5124         }
5125
5126         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5127         $not->($c, "has $c_sentinels not $t_sentinels")
5128             if $c_sentinels ne $t_sentinels;
5129
5130         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5131         $commitdata =~ m/\n\n/;
5132         $commitdata =~ $`;
5133         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5134         @parents = map { { Commit => $_, Child => $c } } @parents;
5135
5136         $not->($c, "root commit") if !@parents;
5137
5138         foreach my $p (@parents) {
5139             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5140         }
5141         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5142         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5143
5144         foreach my $p (@parents) {
5145             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5146
5147             my @cmd= (@git, qw(diff-tree -r --name-only),
5148                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5149             my $patchstackchange = cmdoutput @cmd;
5150             if (length $patchstackchange) {
5151                 $patchstackchange =~ s/\n/,/g;
5152                 $not->($p, "changed $patchstackchange");
5153             }
5154
5155             printdebug " search queue P=$p->{Commit} ",
5156                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5157             push @todo, $p;
5158         }
5159     }
5160
5161     if (!$sref_S) {
5162         printdebug "quiltify want to smash\n";
5163
5164         my $abbrev = sub {
5165             my $x = $_[0]{Commit};
5166             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5167             return $x;
5168         };
5169         my $reportnot = sub {
5170             my ($notp) = @_;
5171             my $s = $abbrev->($notp);
5172             my $c = $notp->{Child};
5173             $s .= "..".$abbrev->($c) if $c;
5174             $s .= ": ".$notp->{Whynot};
5175             return $s;
5176         };
5177         if ($quilt_mode eq 'linear') {
5178             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5179             foreach my $notp (@nots) {
5180                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5181             }
5182             print STDERR "$us: $_\n" foreach @$failsuggestion;
5183             fail "quilt fixup naive history linearisation failed.\n".
5184  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5185         } elsif ($quilt_mode eq 'smash') {
5186         } elsif ($quilt_mode eq 'auto') {
5187             progress "quilt fixup cannot be linear, smashing...";
5188         } else {
5189             die "$quilt_mode ?";
5190         }
5191
5192         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5193         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5194         my $ncommits = 3;
5195         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5196
5197         quiltify_dpkg_commit "auto-$version-$target-$time",
5198             (getfield $clogp, 'Maintainer'),
5199             "Automatically generated patch ($clogp->{Version})\n".
5200             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5201         return;
5202     }
5203
5204     progress "quiltify linearisation planning successful, executing...";
5205
5206     for (my $p = $sref_S;
5207          my $c = $p->{Child};
5208          $p = $p->{Child}) {
5209         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5210         next unless $p->{Nontrivial};
5211
5212         my $cc = $c->{Commit};
5213
5214         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5215         $commitdata =~ m/\n\n/ or die "$c ?";
5216         $commitdata = $`;
5217         my $msg = $'; #';
5218         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5219         my $author = $1;
5220
5221         my $commitdate = cmdoutput
5222             @git, qw(log -n1 --pretty=format:%aD), $cc;
5223
5224         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5225
5226         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5227         $strip_nls->();
5228
5229         my $title = $1;
5230         my $patchname;
5231         my $patchdir;
5232
5233         my $gbp_check_suitable = sub {
5234             $_ = shift;
5235             my ($what) = @_;
5236
5237             eval {
5238                 die "contains unexpected slashes\n" if m{//} || m{/$};
5239                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5240                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5241                 die "is series file\n" if m{$series_filename_re}o;
5242                 die "too long" if length > 200;
5243             };
5244             return $_ unless $@;
5245             print STDERR "quiltifying commit $cc:".
5246                 " ignoring/dropping Gbp-Pq $what: $@";
5247             return undef;
5248         };
5249
5250         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5251                            gbp-pq-name: \s* )
5252                        (\S+) \s* \n //ixm) {
5253             $patchname = $gbp_check_suitable->($1, 'Name');
5254         }
5255         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5256                            gbp-pq-topic: \s* )
5257                        (\S+) \s* \n //ixm) {
5258             $patchdir = $gbp_check_suitable->($1, 'Topic');
5259         }
5260
5261         $strip_nls->();
5262
5263         if (!defined $patchname) {
5264             $patchname = $title;
5265             $patchname =~ s/[.:]$//;
5266             use Text::Iconv;
5267             eval {
5268                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5269                 my $translitname = $converter->convert($patchname);
5270                 die unless defined $translitname;
5271                 $patchname = $translitname;
5272             };
5273             print STDERR
5274                 "dgit: patch title transliteration error: $@"
5275                 if $@;
5276             $patchname =~ y/ A-Z/-a-z/;
5277             $patchname =~ y/-a-z0-9_.+=~//cd;
5278             $patchname =~ s/^\W/x-$&/;
5279             $patchname = substr($patchname,0,40);
5280             $patchname .= ".patch";
5281         }
5282         if (!defined $patchdir) {
5283             $patchdir = '';
5284         }
5285         if (length $patchdir) {
5286             $patchname = "$patchdir/$patchname";
5287         }
5288         if ($patchname =~ m{^(.*)/}) {
5289             mkpath "debian/patches/$1";
5290         }
5291
5292         my $index;
5293         for ($index='';
5294              stat "debian/patches/$patchname$index";
5295              $index++) { }
5296         $!==ENOENT or die "$patchname$index $!";
5297
5298         runcmd @git, qw(checkout -q), $cc;
5299
5300         # We use the tip's changelog so that dpkg-source doesn't
5301         # produce complaining messages from dpkg-parsechangelog.  None
5302         # of the information dpkg-source gets from the changelog is
5303         # actually relevant - it gets put into the original message
5304         # which dpkg-source provides our stunt editor, and then
5305         # overwritten.
5306         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5307
5308         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5309             "Date: $commitdate\n".
5310             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5311
5312         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5313     }
5314
5315     runcmd @git, qw(checkout -q master);
5316 }
5317
5318 sub build_maybe_quilt_fixup () {
5319     my ($format,$fopts) = get_source_format;
5320     return unless madformat_wantfixup $format;
5321     # sigh
5322
5323     check_for_vendor_patches();
5324
5325     if (quiltmode_splitbrain) {
5326         fail <<END unless access_cfg_tagformats_can_splitbrain;
5327 quilt mode $quilt_mode requires split view so server needs to support
5328  both "new" and "maint" tag formats, but config says it doesn't.
5329 END
5330     }
5331
5332     my $clogp = parsechangelog();
5333     my $headref = git_rev_parse('HEAD');
5334
5335     prep_ud();
5336     changedir $ud;
5337
5338     my $upstreamversion = upstreamversion $version;
5339
5340     if ($fopts->{'single-debian-patch'}) {
5341         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5342     } else {
5343         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5344     }
5345
5346     die 'bug' if $split_brain && !$need_split_build_invocation;
5347
5348     changedir '../../../..';
5349     runcmd_ordryrun_local
5350         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5351 }
5352
5353 sub quilt_fixup_mkwork ($) {
5354     my ($headref) = @_;
5355
5356     mkdir "work" or die $!;
5357     changedir "work";
5358     mktree_in_ud_here();
5359     runcmd @git, qw(reset -q --hard), $headref;
5360 }
5361
5362 sub quilt_fixup_linkorigs ($$) {
5363     my ($upstreamversion, $fn) = @_;
5364     # calls $fn->($leafname);
5365
5366     foreach my $f (<../../../../*>) { #/){
5367         my $b=$f; $b =~ s{.*/}{};
5368         {
5369             local ($debuglevel) = $debuglevel-1;
5370             printdebug "QF linkorigs $b, $f ?\n";
5371         }
5372         next unless is_orig_file_of_vsn $b, $upstreamversion;
5373         printdebug "QF linkorigs $b, $f Y\n";
5374         link_ltarget $f, $b or die "$b $!";
5375         $fn->($b);
5376     }
5377 }
5378
5379 sub quilt_fixup_delete_pc () {
5380     runcmd @git, qw(rm -rqf .pc);
5381     commit_admin <<END
5382 Commit removal of .pc (quilt series tracking data)
5383
5384 [dgit ($our_version) upgrade quilt-remove-pc]
5385 END
5386 }
5387
5388 sub quilt_fixup_singlepatch ($$$) {
5389     my ($clogp, $headref, $upstreamversion) = @_;
5390
5391     progress "starting quiltify (single-debian-patch)";
5392
5393     # dpkg-source --commit generates new patches even if
5394     # single-debian-patch is in debian/source/options.  In order to
5395     # get it to generate debian/patches/debian-changes, it is
5396     # necessary to build the source package.
5397
5398     quilt_fixup_linkorigs($upstreamversion, sub { });
5399     quilt_fixup_mkwork($headref);
5400
5401     rmtree("debian/patches");
5402
5403     runcmd @dpkgsource, qw(-b .);
5404     changedir "..";
5405     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5406     rename srcfn("$upstreamversion", "/debian/patches"),
5407            "work/debian/patches";
5408
5409     changedir "work";
5410     commit_quilty_patch();
5411 }
5412
5413 sub quilt_make_fake_dsc ($) {
5414     my ($upstreamversion) = @_;
5415
5416     my $fakeversion="$upstreamversion-~~DGITFAKE";
5417
5418     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5419     print $fakedsc <<END or die $!;
5420 Format: 3.0 (quilt)
5421 Source: $package
5422 Version: $fakeversion
5423 Files:
5424 END
5425
5426     my $dscaddfile=sub {
5427         my ($b) = @_;
5428
5429         my $md = new Digest::MD5;
5430
5431         my $fh = new IO::File $b, '<' or die "$b $!";
5432         stat $fh or die $!;
5433         my $size = -s _;
5434
5435         $md->addfile($fh);
5436         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5437     };
5438
5439     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5440
5441     my @files=qw(debian/source/format debian/rules
5442                  debian/control debian/changelog);
5443     foreach my $maybe (qw(debian/patches debian/source/options
5444                           debian/tests/control)) {
5445         next unless stat_exists "../../../$maybe";
5446         push @files, $maybe;
5447     }
5448
5449     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5450     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5451
5452     $dscaddfile->($debtar);
5453     close $fakedsc or die $!;
5454 }
5455
5456 sub quilt_check_splitbrain_cache ($$) {
5457     my ($headref, $upstreamversion) = @_;
5458     # Called only if we are in (potentially) split brain mode.
5459     # Called in $ud.
5460     # Computes the cache key and looks in the cache.
5461     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5462
5463     my $splitbrain_cachekey;
5464
5465     progress
5466  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5467     # we look in the reflog of dgit-intern/quilt-cache
5468     # we look for an entry whose message is the key for the cache lookup
5469     my @cachekey = (qw(dgit), $our_version);
5470     push @cachekey, $upstreamversion;
5471     push @cachekey, $quilt_mode;
5472     push @cachekey, $headref;
5473
5474     push @cachekey, hashfile('fake.dsc');
5475
5476     my $srcshash = Digest::SHA->new(256);
5477     my %sfs = ( %INC, '$0(dgit)' => $0 );
5478     foreach my $sfk (sort keys %sfs) {
5479         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5480         $srcshash->add($sfk,"  ");
5481         $srcshash->add(hashfile($sfs{$sfk}));
5482         $srcshash->add("\n");
5483     }
5484     push @cachekey, $srcshash->hexdigest();
5485     $splitbrain_cachekey = "@cachekey";
5486
5487     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5488                $splitbraincache);
5489     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5490     debugcmd "|(probably)",@cmd;
5491     my $child = open GC, "-|";  defined $child or die $!;
5492     if (!$child) {
5493         chdir '../../..' or die $!;
5494         if (!stat ".git/logs/refs/$splitbraincache") {
5495             $! == ENOENT or die $!;
5496             printdebug ">(no reflog)\n";
5497             exit 0;
5498         }
5499         exec @cmd; die $!;
5500     }
5501     while (<GC>) {
5502         chomp;
5503         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5504         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5505
5506         my $cachehit = $1;
5507         quilt_fixup_mkwork($headref);
5508         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5509         if ($cachehit ne $headref) {
5510             progress "dgit view: found cached ($saved)";
5511             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5512             $split_brain = 1;
5513             return ($cachehit, $splitbrain_cachekey);
5514         }
5515         progress "dgit view: found cached, no changes required";
5516         return ($headref, $splitbrain_cachekey);
5517     }
5518     die $! if GC->error;
5519     failedcmd unless close GC;
5520
5521     printdebug "splitbrain cache miss\n";
5522     return (undef, $splitbrain_cachekey);
5523 }
5524
5525 sub quilt_fixup_multipatch ($$$) {
5526     my ($clogp, $headref, $upstreamversion) = @_;
5527
5528     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5529
5530     # Our objective is:
5531     #  - honour any existing .pc in case it has any strangeness
5532     #  - determine the git commit corresponding to the tip of
5533     #    the patch stack (if there is one)
5534     #  - if there is such a git commit, convert each subsequent
5535     #    git commit into a quilt patch with dpkg-source --commit
5536     #  - otherwise convert all the differences in the tree into
5537     #    a single git commit
5538     #
5539     # To do this we:
5540
5541     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5542     # dgit would include the .pc in the git tree.)  If there isn't
5543     # one, we need to generate one by unpacking the patches that we
5544     # have.
5545     #
5546     # We first look for a .pc in the git tree.  If there is one, we
5547     # will use it.  (This is not the normal case.)
5548     #
5549     # Otherwise need to regenerate .pc so that dpkg-source --commit
5550     # can work.  We do this as follows:
5551     #     1. Collect all relevant .orig from parent directory
5552     #     2. Generate a debian.tar.gz out of
5553     #         debian/{patches,rules,source/format,source/options}
5554     #     3. Generate a fake .dsc containing just these fields:
5555     #          Format Source Version Files
5556     #     4. Extract the fake .dsc
5557     #        Now the fake .dsc has a .pc directory.
5558     # (In fact we do this in every case, because in future we will
5559     # want to search for a good base commit for generating patches.)
5560     #
5561     # Then we can actually do the dpkg-source --commit
5562     #     1. Make a new working tree with the same object
5563     #        store as our main tree and check out the main
5564     #        tree's HEAD.
5565     #     2. Copy .pc from the fake's extraction, if necessary
5566     #     3. Run dpkg-source --commit
5567     #     4. If the result has changes to debian/, then
5568     #          - git add them them
5569     #          - git add .pc if we had a .pc in-tree
5570     #          - git commit
5571     #     5. If we had a .pc in-tree, delete it, and git commit
5572     #     6. Back in the main tree, fast forward to the new HEAD
5573
5574     # Another situation we may have to cope with is gbp-style
5575     # patches-unapplied trees.
5576     #
5577     # We would want to detect these, so we know to escape into
5578     # quilt_fixup_gbp.  However, this is in general not possible.
5579     # Consider a package with a one patch which the dgit user reverts
5580     # (with git revert or the moral equivalent).
5581     #
5582     # That is indistinguishable in contents from a patches-unapplied
5583     # tree.  And looking at the history to distinguish them is not
5584     # useful because the user might have made a confusing-looking git
5585     # history structure (which ought to produce an error if dgit can't
5586     # cope, not a silent reintroduction of an unwanted patch).
5587     #
5588     # So gbp users will have to pass an option.  But we can usually
5589     # detect their failure to do so: if the tree is not a clean
5590     # patches-applied tree, quilt linearisation fails, but the tree
5591     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5592     # they want --quilt=unapplied.
5593     #
5594     # To help detect this, when we are extracting the fake dsc, we
5595     # first extract it with --skip-patches, and then apply the patches
5596     # afterwards with dpkg-source --before-build.  That lets us save a
5597     # tree object corresponding to .origs.
5598
5599     my $splitbrain_cachekey;
5600
5601     quilt_make_fake_dsc($upstreamversion);
5602
5603     if (quiltmode_splitbrain()) {
5604         my $cachehit;
5605         ($cachehit, $splitbrain_cachekey) =
5606             quilt_check_splitbrain_cache($headref, $upstreamversion);
5607         return if $cachehit;
5608     }
5609
5610     runcmd qw(sh -ec),
5611         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5612
5613     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5614     rename $fakexdir, "fake" or die "$fakexdir $!";
5615
5616     changedir 'fake';
5617
5618     remove_stray_gits("source package");
5619     mktree_in_ud_here();
5620
5621     rmtree '.pc';
5622
5623     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5624     my $unapplied=git_add_write_tree();
5625     printdebug "fake orig tree object $unapplied\n";
5626
5627     ensuredir '.pc';
5628
5629     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5630     $!=0; $?=-1;
5631     if (system @bbcmd) {
5632         failedcmd @bbcmd if $? < 0;
5633         fail <<END;
5634 failed to apply your git tree's patch stack (from debian/patches/) to
5635  the corresponding upstream tarball(s).  Your source tree and .orig
5636  are probably too inconsistent.  dgit can only fix up certain kinds of
5637  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5638 END
5639     }
5640
5641     changedir '..';
5642
5643     quilt_fixup_mkwork($headref);
5644
5645     my $mustdeletepc=0;
5646     if (stat_exists ".pc") {
5647         -d _ or die;
5648         progress "Tree already contains .pc - will use it then delete it.";
5649         $mustdeletepc=1;
5650     } else {
5651         rename '../fake/.pc','.pc' or die $!;
5652     }
5653
5654     changedir '../fake';
5655     rmtree '.pc';
5656     my $oldtiptree=git_add_write_tree();
5657     printdebug "fake o+d/p tree object $unapplied\n";
5658     changedir '../work';
5659
5660
5661     # We calculate some guesswork now about what kind of tree this might
5662     # be.  This is mostly for error reporting.
5663
5664     my %editedignores;
5665     my @unrepres;
5666     my $diffbits = {
5667         # H = user's HEAD
5668         # O = orig, without patches applied
5669         # A = "applied", ie orig with H's debian/patches applied
5670         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5671                                      \%editedignores, \@unrepres),
5672         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5673         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5674     };
5675
5676     my @dl;
5677     foreach my $b (qw(01 02)) {
5678         foreach my $v (qw(O2H O2A H2A)) {
5679             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5680         }
5681     }
5682     printdebug "differences \@dl @dl.\n";
5683
5684     progress sprintf
5685 "$us: base trees orig=%.20s o+d/p=%.20s",
5686               $unapplied, $oldtiptree;
5687     progress sprintf
5688 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5689 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5690                              $dl[0], $dl[1],              $dl[3], $dl[4],
5691                                  $dl[2],                     $dl[5];
5692
5693     if (@unrepres) {
5694         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5695             foreach @unrepres;
5696         forceable_fail [qw(unrepresentable)], <<END;
5697 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5698 END
5699     }
5700
5701     my @failsuggestion;
5702     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5703         push @failsuggestion, "This might be a patches-unapplied branch.";
5704     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5705         push @failsuggestion, "This might be a patches-applied branch.";
5706     }
5707     push @failsuggestion, "Maybe you need to specify one of".
5708         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5709
5710     if (quiltmode_splitbrain()) {
5711         quiltify_splitbrain($clogp, $unapplied, $headref,
5712                             $diffbits, \%editedignores,
5713                             $splitbrain_cachekey);
5714         return;
5715     }
5716
5717     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5718     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5719
5720     if (!open P, '>>', ".pc/applied-patches") {
5721         $!==&ENOENT or die $!;
5722     } else {
5723         close P;
5724     }
5725
5726     commit_quilty_patch();
5727
5728     if ($mustdeletepc) {
5729         quilt_fixup_delete_pc();
5730     }
5731 }
5732
5733 sub quilt_fixup_editor () {
5734     my $descfn = $ENV{$fakeeditorenv};
5735     my $editing = $ARGV[$#ARGV];
5736     open I1, '<', $descfn or die "$descfn: $!";
5737     open I2, '<', $editing or die "$editing: $!";
5738     unlink $editing or die "$editing: $!";
5739     open O, '>', $editing or die "$editing: $!";
5740     while (<I1>) { print O or die $!; } I1->error and die $!;
5741     my $copying = 0;
5742     while (<I2>) {
5743         $copying ||= m/^\-\-\- /;
5744         next unless $copying;
5745         print O or die $!;
5746     }
5747     I2->error and die $!;
5748     close O or die $1;
5749     exit 0;
5750 }
5751
5752 sub maybe_apply_patches_dirtily () {
5753     return unless $quilt_mode =~ m/gbp|unapplied/;
5754     print STDERR <<END or die $!;
5755
5756 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5757 dgit: Have to apply the patches - making the tree dirty.
5758 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5759
5760 END
5761     $patches_applied_dirtily = 01;
5762     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5763     runcmd qw(dpkg-source --before-build .);
5764 }
5765
5766 sub maybe_unapply_patches_again () {
5767     progress "dgit: Unapplying patches again to tidy up the tree."
5768         if $patches_applied_dirtily;
5769     runcmd qw(dpkg-source --after-build .)
5770         if $patches_applied_dirtily & 01;
5771     rmtree '.pc'
5772         if $patches_applied_dirtily & 02;
5773     $patches_applied_dirtily = 0;
5774 }
5775
5776 #----- other building -----
5777
5778 our $clean_using_builder;
5779 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5780 #   clean the tree before building (perhaps invoked indirectly by
5781 #   whatever we are using to run the build), rather than separately
5782 #   and explicitly by us.
5783
5784 sub clean_tree () {
5785     return if $clean_using_builder;
5786     if ($cleanmode eq 'dpkg-source') {
5787         maybe_apply_patches_dirtily();
5788         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5789     } elsif ($cleanmode eq 'dpkg-source-d') {
5790         maybe_apply_patches_dirtily();
5791         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5792     } elsif ($cleanmode eq 'git') {
5793         runcmd_ordryrun_local @git, qw(clean -xdf);
5794     } elsif ($cleanmode eq 'git-ff') {
5795         runcmd_ordryrun_local @git, qw(clean -xdff);
5796     } elsif ($cleanmode eq 'check') {
5797         my $leftovers = cmdoutput @git, qw(clean -xdn);
5798         if (length $leftovers) {
5799             print STDERR $leftovers, "\n" or die $!;
5800             fail "tree contains uncommitted files and --clean=check specified";
5801         }
5802     } elsif ($cleanmode eq 'none') {
5803     } else {
5804         die "$cleanmode ?";
5805     }
5806 }
5807
5808 sub cmd_clean () {
5809     badusage "clean takes no additional arguments" if @ARGV;
5810     notpushing();
5811     clean_tree();
5812     maybe_unapply_patches_again();
5813 }
5814
5815 sub build_or_push_prep_early () {
5816     our $build_or_push_prep_early_done //= 0;
5817     return if $build_or_push_prep_early_done++;
5818     badusage "-p is not allowed with dgit $subcommand" if defined $package;
5819     my $clogp = parsechangelog();
5820     $isuite = getfield $clogp, 'Distribution';
5821     $package = getfield $clogp, 'Source';
5822     $version = getfield $clogp, 'Version';
5823 }
5824
5825 sub build_prep_early () {
5826     build_or_push_prep_early();
5827     notpushing();
5828     check_not_dirty();
5829 }
5830
5831 sub build_prep () {
5832     build_prep_early();
5833     clean_tree();
5834     build_maybe_quilt_fixup();
5835     if ($rmchanges) {
5836         my $pat = changespat $version;
5837         foreach my $f (glob "$buildproductsdir/$pat") {
5838             if (act_local()) {
5839                 unlink $f or fail "remove old changes file $f: $!";
5840             } else {
5841                 progress "would remove $f";
5842             }
5843         }
5844     }
5845 }
5846
5847 sub changesopts_initial () {
5848     my @opts =@changesopts[1..$#changesopts];
5849 }
5850
5851 sub changesopts_version () {
5852     if (!defined $changes_since_version) {
5853         my @vsns = archive_query('archive_query');
5854         my @quirk = access_quirk();
5855         if ($quirk[0] eq 'backports') {
5856             local $isuite = $quirk[2];
5857             local $csuite;
5858             canonicalise_suite();
5859             push @vsns, archive_query('archive_query');
5860         }
5861         if (@vsns) {
5862             @vsns = map { $_->[0] } @vsns;
5863             @vsns = sort { -version_compare($a, $b) } @vsns;
5864             $changes_since_version = $vsns[0];
5865             progress "changelog will contain changes since $vsns[0]";
5866         } else {
5867             $changes_since_version = '_';
5868             progress "package seems new, not specifying -v<version>";
5869         }
5870     }
5871     if ($changes_since_version ne '_') {
5872         return ("-v$changes_since_version");
5873     } else {
5874         return ();
5875     }
5876 }
5877
5878 sub changesopts () {
5879     return (changesopts_initial(), changesopts_version());
5880 }
5881
5882 sub massage_dbp_args ($;$) {
5883     my ($cmd,$xargs) = @_;
5884     # We need to:
5885     #
5886     #  - if we're going to split the source build out so we can
5887     #    do strange things to it, massage the arguments to dpkg-buildpackage
5888     #    so that the main build doessn't build source (or add an argument
5889     #    to stop it building source by default).
5890     #
5891     #  - add -nc to stop dpkg-source cleaning the source tree,
5892     #    unless we're not doing a split build and want dpkg-source
5893     #    as cleanmode, in which case we can do nothing
5894     #
5895     # return values:
5896     #    0 - source will NOT need to be built separately by caller
5897     #   +1 - source will need to be built separately by caller
5898     #   +2 - source will need to be built separately by caller AND
5899     #        dpkg-buildpackage should not in fact be run at all!
5900     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5901 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5902     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5903         $clean_using_builder = 1;
5904         return 0;
5905     }
5906     # -nc has the side effect of specifying -b if nothing else specified
5907     # and some combinations of -S, -b, et al, are errors, rather than
5908     # later simply overriding earlie.  So we need to:
5909     #  - search the command line for these options
5910     #  - pick the last one
5911     #  - perhaps add our own as a default
5912     #  - perhaps adjust it to the corresponding non-source-building version
5913     my $dmode = '-F';
5914     foreach my $l ($cmd, $xargs) {
5915         next unless $l;
5916         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5917     }
5918     push @$cmd, '-nc';
5919 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5920     my $r = 0;
5921     if ($need_split_build_invocation) {
5922         printdebug "massage split $dmode.\n";
5923         $r = $dmode =~ m/[S]/     ? +2 :
5924              $dmode =~ y/gGF/ABb/ ? +1 :
5925              $dmode =~ m/[ABb]/   ?  0 :
5926              die "$dmode ?";
5927     }
5928     printdebug "massage done $r $dmode.\n";
5929     push @$cmd, $dmode;
5930 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5931     return $r;
5932 }
5933
5934 sub in_parent (&) {
5935     my ($fn) = @_;
5936     my $wasdir = must_getcwd();
5937     changedir "..";
5938     $fn->();
5939     changedir $wasdir;
5940 }
5941
5942 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5943     my ($msg_if_onlyone) = @_;
5944     # If there is only one .changes file, fail with $msg_if_onlyone,
5945     # or if that is undef, be a no-op.
5946     # Returns the changes file to report to the user.
5947     my $pat = changespat $version;
5948     my @changesfiles = glob $pat;
5949     @changesfiles = sort {
5950         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5951             or $a cmp $b
5952     } @changesfiles;
5953     my $result;
5954     if (@changesfiles==1) {
5955         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5956 only one changes file from build (@changesfiles)
5957 END
5958         $result = $changesfiles[0];
5959     } elsif (@changesfiles==2) {
5960         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5961         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5962             fail "$l found in binaries changes file $binchanges"
5963                 if $l =~ m/\.dsc$/;
5964         }
5965         runcmd_ordryrun_local @mergechanges, @changesfiles;
5966         my $multichanges = changespat $version,'multi';
5967         if (act_local()) {
5968             stat_exists $multichanges or fail "$multichanges: $!";
5969             foreach my $cf (glob $pat) {
5970                 next if $cf eq $multichanges;
5971                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5972             }
5973         }
5974         $result = $multichanges;
5975     } else {
5976         fail "wrong number of different changes files (@changesfiles)";
5977     }
5978     printdone "build successful, results in $result\n" or die $!;
5979 }
5980
5981 sub midbuild_checkchanges () {
5982     my $pat = changespat $version;
5983     return if $rmchanges;
5984     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5985     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5986     fail <<END
5987 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5988 Suggest you delete @unwanted.
5989 END
5990         if @unwanted;
5991 }
5992
5993 sub midbuild_checkchanges_vanilla ($) {
5994     my ($wantsrc) = @_;
5995     midbuild_checkchanges() if $wantsrc == 1;
5996 }
5997
5998 sub postbuild_mergechanges_vanilla ($) {
5999     my ($wantsrc) = @_;
6000     if ($wantsrc == 1) {
6001         in_parent {
6002             postbuild_mergechanges(undef);
6003         };
6004     } else {
6005         printdone "build successful\n";
6006     }
6007 }
6008
6009 sub cmd_build {
6010     build_prep_early();
6011     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6012     my $wantsrc = massage_dbp_args \@dbp;
6013     if ($wantsrc > 0) {
6014         build_source();
6015         midbuild_checkchanges_vanilla $wantsrc;
6016     } else {
6017         build_prep();
6018     }
6019     if ($wantsrc < 2) {
6020         push @dbp, changesopts_version();
6021         maybe_apply_patches_dirtily();
6022         runcmd_ordryrun_local @dbp;
6023     }
6024     maybe_unapply_patches_again();
6025     postbuild_mergechanges_vanilla $wantsrc;
6026 }
6027
6028 sub pre_gbp_build {
6029     $quilt_mode //= 'gbp';
6030 }
6031
6032 sub cmd_gbp_build {
6033     build_prep_early();
6034
6035     # gbp can make .origs out of thin air.  In my tests it does this
6036     # even for a 1.0 format package, with no origs present.  So I
6037     # guess it keys off just the version number.  We don't know
6038     # exactly what .origs ought to exist, but let's assume that we
6039     # should run gbp if: the version has an upstream part and the main
6040     # orig is absent.
6041     my $upstreamversion = upstreamversion $version;
6042     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6043     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
6044
6045     if ($gbp_make_orig) {
6046         clean_tree();
6047         $cleanmode = 'none'; # don't do it again
6048         $need_split_build_invocation = 1;
6049     }
6050
6051     my @dbp = @dpkgbuildpackage;
6052
6053     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6054
6055     if (!length $gbp_build[0]) {
6056         if (length executable_on_path('git-buildpackage')) {
6057             $gbp_build[0] = qw(git-buildpackage);
6058         } else {
6059             $gbp_build[0] = 'gbp buildpackage';
6060         }
6061     }
6062     my @cmd = opts_opt_multi_cmd @gbp_build;
6063
6064     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
6065
6066     if ($gbp_make_orig) {
6067         ensuredir '.git/dgit';
6068         my $ok = '.git/dgit/origs-gen-ok';
6069         unlink $ok or $!==&ENOENT or die $!;
6070         my @origs_cmd = @cmd;
6071         push @origs_cmd, qw(--git-cleaner=true);
6072         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
6073         push @origs_cmd, @ARGV;
6074         if (act_local()) {
6075             debugcmd @origs_cmd;
6076             system @origs_cmd;
6077             do { local $!; stat_exists $ok; }
6078                 or failedcmd @origs_cmd;
6079         } else {
6080             dryrun_report @origs_cmd;
6081         }
6082     }
6083
6084     if ($wantsrc > 0) {
6085         build_source();
6086         midbuild_checkchanges_vanilla $wantsrc;
6087     } else {
6088         if (!$clean_using_builder) {
6089             push @cmd, '--git-cleaner=true';
6090         }
6091         build_prep();
6092     }
6093     maybe_unapply_patches_again();
6094     if ($wantsrc < 2) {
6095         push @cmd, changesopts();
6096         runcmd_ordryrun_local @cmd, @ARGV;
6097     }
6098     postbuild_mergechanges_vanilla $wantsrc;
6099 }
6100 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6101
6102 sub build_source {
6103     build_prep_early();
6104     my $our_cleanmode = $cleanmode;
6105     if ($need_split_build_invocation) {
6106         # Pretend that clean is being done some other way.  This
6107         # forces us not to try to use dpkg-buildpackage to clean and
6108         # build source all in one go; and instead we run dpkg-source
6109         # (and build_prep() will do the clean since $clean_using_builder
6110         # is false).
6111         $our_cleanmode = 'ELSEWHERE';
6112     }
6113     if ($our_cleanmode =~ m/^dpkg-source/) {
6114         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6115         $clean_using_builder = 1;
6116     }
6117     build_prep();
6118     $sourcechanges = changespat $version,'source';
6119     if (act_local()) {
6120         unlink "../$sourcechanges" or $!==ENOENT
6121             or fail "remove $sourcechanges: $!";
6122     }
6123     $dscfn = dscfn($version);
6124     if ($our_cleanmode eq 'dpkg-source') {
6125         maybe_apply_patches_dirtily();
6126         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6127             changesopts();
6128     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6129         maybe_apply_patches_dirtily();
6130         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6131             changesopts();
6132     } else {
6133         my @cmd = (@dpkgsource, qw(-b --));
6134         if ($split_brain) {
6135             changedir $ud;
6136             runcmd_ordryrun_local @cmd, "work";
6137             my @udfiles = <${package}_*>;
6138             changedir "../../..";
6139             foreach my $f (@udfiles) {
6140                 printdebug "source copy, found $f\n";
6141                 next unless
6142                     $f eq $dscfn or
6143                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6144                      $f eq srcfn($version, $&));
6145                 printdebug "source copy, found $f - renaming\n";
6146                 rename "$ud/$f", "../$f" or $!==ENOENT
6147                     or fail "put in place new source file ($f): $!";
6148             }
6149         } else {
6150             my $pwd = must_getcwd();
6151             my $leafdir = basename $pwd;
6152             changedir "..";
6153             runcmd_ordryrun_local @cmd, $leafdir;
6154             changedir $pwd;
6155         }
6156         runcmd_ordryrun_local qw(sh -ec),
6157             'exec >$1; shift; exec "$@"','x',
6158             "../$sourcechanges",
6159             @dpkggenchanges, qw(-S), changesopts();
6160     }
6161 }
6162
6163 sub cmd_build_source {
6164     build_prep_early();
6165     badusage "build-source takes no additional arguments" if @ARGV;
6166     build_source();
6167     maybe_unapply_patches_again();
6168     printdone "source built, results in $dscfn and $sourcechanges";
6169 }
6170
6171 sub cmd_sbuild {
6172     build_source();
6173     midbuild_checkchanges();
6174     in_parent {
6175         if (act_local()) {
6176             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6177             stat_exists $sourcechanges
6178                 or fail "$sourcechanges (in parent directory): $!";
6179         }
6180         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6181     };
6182     maybe_unapply_patches_again();
6183     in_parent {
6184         postbuild_mergechanges(<<END);
6185 perhaps you need to pass -A ?  (sbuild's default is to build only
6186 arch-specific binaries; dgit 1.4 used to override that.)
6187 END
6188     };
6189 }
6190
6191 sub cmd_quilt_fixup {
6192     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6193     build_prep_early();
6194     clean_tree();
6195     build_maybe_quilt_fixup();
6196 }
6197
6198 sub import_dsc_result {
6199     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6200     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6201     runcmd @cmd;
6202     check_gitattrs($newhash, "source tree");
6203
6204     progress "dgit: import-dsc: $what_msg";
6205 }
6206
6207 sub cmd_import_dsc {
6208     my $needsig = 0;
6209
6210     while (@ARGV) {
6211         last unless $ARGV[0] =~ m/^-/;
6212         $_ = shift @ARGV;
6213         last if m/^--?$/;
6214         if (m/^--require-valid-signature$/) {
6215             $needsig = 1;
6216         } else {
6217             badusage "unknown dgit import-dsc sub-option \`$_'";
6218         }
6219     }
6220
6221     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6222     my ($dscfn, $dstbranch) = @ARGV;
6223
6224     badusage "dry run makes no sense with import-dsc" unless act_local();
6225
6226     my $force = $dstbranch =~ s/^\+//   ? +1 :
6227                 $dstbranch =~ s/^\.\.// ? -1 :
6228                                            0;
6229     my $info = $force ? " $&" : '';
6230     $info = "$dscfn$info";
6231
6232     my $specbranch = $dstbranch;
6233     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6234     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6235
6236     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6237     my $chead = cmdoutput_errok @symcmd;
6238     defined $chead or $?==256 or failedcmd @symcmd;
6239
6240     fail "$dstbranch is checked out - will not update it"
6241         if defined $chead and $chead eq $dstbranch;
6242
6243     my $oldhash = git_get_ref $dstbranch;
6244
6245     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6246     $dscdata = do { local $/ = undef; <D>; };
6247     D->error and fail "read $dscfn: $!";
6248     close C;
6249
6250     # we don't normally need this so import it here
6251     use Dpkg::Source::Package;
6252     my $dp = new Dpkg::Source::Package filename => $dscfn,
6253         require_valid_signature => $needsig;
6254     {
6255         local $SIG{__WARN__} = sub {
6256             print STDERR $_[0];
6257             return unless $needsig;
6258             fail "import-dsc signature check failed";
6259         };
6260         if (!$dp->is_signed()) {
6261             warn "$us: warning: importing unsigned .dsc\n";
6262         } else {
6263             my $r = $dp->check_signature();
6264             die "->check_signature => $r" if $needsig && $r;
6265         }
6266     }
6267
6268     parse_dscdata();
6269
6270     $package = getfield $dsc, 'Source';
6271
6272     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6273         unless forceing [qw(import-dsc-with-dgit-field)];
6274     parse_dsc_field_def_dsc_distro();
6275
6276     $isuite = 'DGIT-IMPORT-DSC';
6277     $idistro //= $dsc_distro;
6278
6279     notpushing();
6280
6281     if (defined $dsc_hash) {
6282         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6283         resolve_dsc_field_commit undef, undef;
6284     }
6285     if (defined $dsc_hash) {
6286         my @cmd = (qw(sh -ec),
6287                    "echo $dsc_hash | git cat-file --batch-check");
6288         my $objgot = cmdoutput @cmd;
6289         if ($objgot =~ m#^\w+ missing\b#) {
6290             fail <<END
6291 .dsc contains Dgit field referring to object $dsc_hash
6292 Your git tree does not have that object.  Try `git fetch' from a
6293 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6294 END
6295         }
6296         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6297             if ($force > 0) {
6298                 progress "Not fast forward, forced update.";
6299             } else {
6300                 fail "Not fast forward to $dsc_hash";
6301             }
6302         }
6303         import_dsc_result $dstbranch, $dsc_hash,
6304             "dgit import-dsc (Dgit): $info",
6305             "updated git ref $dstbranch";
6306         return 0;
6307     }
6308
6309     fail <<END
6310 Branch $dstbranch already exists
6311 Specify ..$specbranch for a pseudo-merge, binding in existing history
6312 Specify  +$specbranch to overwrite, discarding existing history
6313 END
6314         if $oldhash && !$force;
6315
6316     my @dfi = dsc_files_info();
6317     foreach my $fi (@dfi) {
6318         my $f = $fi->{Filename};
6319         my $here = "../$f";
6320         if (lstat $here) {
6321             next if stat $here;
6322             fail "lstat $here works but stat gives $! !";
6323         }
6324         fail "stat $here: $!" unless $! == ENOENT;
6325         my $there = $dscfn;
6326         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6327             $there = $';
6328         } elsif ($dscfn =~ m#^/#) {
6329             $there = $dscfn;
6330         } else {
6331             fail "cannot import $dscfn which seems to be inside working tree!";
6332         }
6333         $there =~ s#/+[^/]+$## or
6334             fail "import $dscfn requires ../$f, but it does not exist";
6335         $there .= "/$f";
6336         my $test = $there =~ m{^/} ? $there : "../$there";
6337         stat $test or fail "import $dscfn requires $test, but: $!";
6338         symlink $there, $here or fail "symlink $there to $here: $!";
6339         progress "made symlink $here -> $there";
6340 #       print STDERR Dumper($fi);
6341     }
6342     my @mergeinputs = generate_commits_from_dsc();
6343     die unless @mergeinputs == 1;
6344
6345     my $newhash = $mergeinputs[0]{Commit};
6346
6347     if ($oldhash) {
6348         if ($force > 0) {
6349             progress "Import, forced update - synthetic orphan git history.";
6350         } elsif ($force < 0) {
6351             progress "Import, merging.";
6352             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6353             my $version = getfield $dsc, 'Version';
6354             my $clogp = commit_getclogp $newhash;
6355             my $authline = clogp_authline $clogp;
6356             $newhash = make_commit_text <<END;
6357 tree $tree
6358 parent $newhash
6359 parent $oldhash
6360 author $authline
6361 committer $authline
6362
6363 Merge $package ($version) import into $dstbranch
6364 END
6365         } else {
6366             die; # caught earlier
6367         }
6368     }
6369
6370     import_dsc_result $dstbranch, $newhash,
6371         "dgit import-dsc: $info",
6372         "results are in in git ref $dstbranch";
6373 }
6374
6375 sub pre_archive_api_query () {
6376     no_local_git_cfg();
6377 }
6378 sub cmd_archive_api_query {
6379     badusage "need only 1 subpath argument" unless @ARGV==1;
6380     my ($subpath) = @ARGV;
6381     my @cmd = archive_api_query_cmd($subpath);
6382     push @cmd, qw(-f);
6383     debugcmd ">",@cmd;
6384     exec @cmd or fail "exec curl: $!\n";
6385 }
6386
6387 sub repos_server_url () {
6388     $package = '_dgit-repos-server';
6389     local $access_forpush = 1;
6390     local $isuite = 'DGIT-REPOS-SERVER';
6391     my $url = access_giturl();
6392 }
6393
6394 sub pre_clone_dgit_repos_server () {
6395     no_local_git_cfg();
6396 }
6397 sub cmd_clone_dgit_repos_server {
6398     badusage "need destination argument" unless @ARGV==1;
6399     my ($destdir) = @ARGV;
6400     my $url = repos_server_url();
6401     my @cmd = (@git, qw(clone), $url, $destdir);
6402     debugcmd ">",@cmd;
6403     exec @cmd or fail "exec git clone: $!\n";
6404 }
6405
6406 sub pre_print_dgit_repos_server_source_url () {
6407     no_local_git_cfg();
6408 }
6409 sub cmd_print_dgit_repos_server_source_url {
6410     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6411         if @ARGV;
6412     my $url = repos_server_url();
6413     print $url, "\n" or die $!;
6414 }
6415
6416 sub cmd_setup_mergechangelogs {
6417     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6418     local $isuite = 'DGIT-SETUP-TREE';
6419     setup_mergechangelogs(1);
6420 }
6421
6422 sub cmd_setup_useremail {
6423     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6424     local $isuite = 'DGIT-SETUP-TREE';
6425     setup_useremail(1);
6426 }
6427
6428 sub cmd_setup_gitattributes {
6429     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6430     local $isuite = 'DGIT-SETUP-TREE';
6431     setup_gitattrs(1);
6432 }
6433
6434 sub cmd_setup_new_tree {
6435     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6436     local $isuite = 'DGIT-SETUP-TREE';
6437     setup_new_tree();
6438 }
6439
6440 #---------- argument parsing and main program ----------
6441
6442 sub cmd_version {
6443     print "dgit version $our_version\n" or die $!;
6444     exit 0;
6445 }
6446
6447 our (%valopts_long, %valopts_short);
6448 our (%funcopts_long);
6449 our @rvalopts;
6450 our (@modeopt_cfgs);
6451
6452 sub defvalopt ($$$$) {
6453     my ($long,$short,$val_re,$how) = @_;
6454     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6455     $valopts_long{$long} = $oi;
6456     $valopts_short{$short} = $oi;
6457     # $how subref should:
6458     #   do whatever assignemnt or thing it likes with $_[0]
6459     #   if the option should not be passed on to remote, @rvalopts=()
6460     # or $how can be a scalar ref, meaning simply assign the value
6461 }
6462
6463 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6464 defvalopt '--distro',        '-d', '.+',      \$idistro;
6465 defvalopt '',                '-k', '.+',      \$keyid;
6466 defvalopt '--existing-package','', '.*',      \$existing_package;
6467 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6468 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6469 defvalopt '--package',   '-p',   $package_re, \$package;
6470 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6471
6472 defvalopt '', '-C', '.+', sub {
6473     ($changesfile) = (@_);
6474     if ($changesfile =~ s#^(.*)/##) {
6475         $buildproductsdir = $1;
6476     }
6477 };
6478
6479 defvalopt '--initiator-tempdir','','.*', sub {
6480     ($initiator_tempdir) = (@_);
6481     $initiator_tempdir =~ m#^/# or
6482         badusage "--initiator-tempdir must be used specify an".
6483         " absolute, not relative, directory."
6484 };
6485
6486 sub defoptmodes ($@) {
6487     my ($varref, $cfgkey, $default, %optmap) = @_;
6488     my %permit;
6489     while (my ($opt,$val) = each %optmap) {
6490         $funcopts_long{$opt} = sub { $$varref = $val; };
6491         $permit{$val} = $val;
6492     }
6493     push @modeopt_cfgs, {
6494         Var => $varref,
6495         Key => $cfgkey,
6496         Default => $default,
6497         Vals => \%permit
6498     };
6499 }
6500
6501 defoptmodes \$dodep14tag, qw( dep14tag          want
6502                               --dep14tag        want
6503                               --no-dep14tag     no
6504                               --always-dep14tag always );
6505
6506 sub parseopts () {
6507     my $om;
6508
6509     if (defined $ENV{'DGIT_SSH'}) {
6510         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6511     } elsif (defined $ENV{'GIT_SSH'}) {
6512         @ssh = ($ENV{'GIT_SSH'});
6513     }
6514
6515     my $oi;
6516     my $val;
6517     my $valopt = sub {
6518         my ($what) = @_;
6519         @rvalopts = ($_);
6520         if (!defined $val) {
6521             badusage "$what needs a value" unless @ARGV;
6522             $val = shift @ARGV;
6523             push @rvalopts, $val;
6524         }
6525         badusage "bad value \`$val' for $what" unless
6526             $val =~ m/^$oi->{Re}$(?!\n)/s;
6527         my $how = $oi->{How};
6528         if (ref($how) eq 'SCALAR') {
6529             $$how = $val;
6530         } else {
6531             $how->($val);
6532         }
6533         push @ropts, @rvalopts;
6534     };
6535
6536     while (@ARGV) {
6537         last unless $ARGV[0] =~ m/^-/;
6538         $_ = shift @ARGV;
6539         last if m/^--?$/;
6540         if (m/^--/) {
6541             if (m/^--dry-run$/) {
6542                 push @ropts, $_;
6543                 $dryrun_level=2;
6544             } elsif (m/^--damp-run$/) {
6545                 push @ropts, $_;
6546                 $dryrun_level=1;
6547             } elsif (m/^--no-sign$/) {
6548                 push @ropts, $_;
6549                 $sign=0;
6550             } elsif (m/^--help$/) {
6551                 cmd_help();
6552             } elsif (m/^--version$/) {
6553                 cmd_version();
6554             } elsif (m/^--new$/) {
6555                 push @ropts, $_;
6556                 $new_package=1;
6557             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6558                      ($om = $opts_opt_map{$1}) &&
6559                      length $om->[0]) {
6560                 push @ropts, $_;
6561                 $om->[0] = $2;
6562             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6563                      !$opts_opt_cmdonly{$1} &&
6564                      ($om = $opts_opt_map{$1})) {
6565                 push @ropts, $_;
6566                 push @$om, $2;
6567             } elsif (m/^--(gbp|dpm)$/s) {
6568                 push @ropts, "--quilt=$1";
6569                 $quilt_mode = $1;
6570             } elsif (m/^--ignore-dirty$/s) {
6571                 push @ropts, $_;
6572                 $ignoredirty = 1;
6573             } elsif (m/^--no-quilt-fixup$/s) {
6574                 push @ropts, $_;
6575                 $quilt_mode = 'nocheck';
6576             } elsif (m/^--no-rm-on-error$/s) {
6577                 push @ropts, $_;
6578                 $rmonerror = 0;
6579             } elsif (m/^--no-chase-dsc-distro$/s) {
6580                 push @ropts, $_;
6581                 $chase_dsc_distro = 0;
6582             } elsif (m/^--overwrite$/s) {
6583                 push @ropts, $_;
6584                 $overwrite_version = '';
6585             } elsif (m/^--overwrite=(.+)$/s) {
6586                 push @ropts, $_;
6587                 $overwrite_version = $1;
6588             } elsif (m/^--delayed=(\d+)$/s) {
6589                 push @ropts, $_;
6590                 push @dput, $_;
6591             } elsif (m/^--dgit-view-save=(.+)$/s) {
6592                 push @ropts, $_;
6593                 $split_brain_save = $1;
6594                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6595             } elsif (m/^--(no-)?rm-old-changes$/s) {
6596                 push @ropts, $_;
6597                 $rmchanges = !$1;
6598             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6599                 push @ropts, $_;
6600                 push @deliberatelies, $&;
6601             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6602                 push @ropts, $&;
6603                 $forceopts{$1} = 1;
6604                 $_='';
6605             } elsif (m/^--force-/) {
6606                 print STDERR
6607                     "$us: warning: ignoring unknown force option $_\n";
6608                 $_='';
6609             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6610                 # undocumented, for testing
6611                 push @ropts, $_;
6612                 $tagformat_want = [ $1, 'command line', 1 ];
6613                 # 1 menas overrides distro configuration
6614             } elsif (m/^--always-split-source-build$/s) {
6615                 # undocumented, for testing
6616                 push @ropts, $_;
6617                 $need_split_build_invocation = 1;
6618             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6619                 # undocumented, for testing
6620                 push @ropts, $_;
6621                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6622                 # ^ it's supposed to be an array ref
6623             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6624                 $val = $2 ? $' : undef; #';
6625                 $valopt->($oi->{Long});
6626             } elsif ($funcopts_long{$_}) {
6627                 push @ropts, $_;
6628                 $funcopts_long{$_}();
6629             } else {
6630                 badusage "unknown long option \`$_'";
6631             }
6632         } else {
6633             while (m/^-./s) {
6634                 if (s/^-n/-/) {
6635                     push @ropts, $&;
6636                     $dryrun_level=2;
6637                 } elsif (s/^-L/-/) {
6638                     push @ropts, $&;
6639                     $dryrun_level=1;
6640                 } elsif (s/^-h/-/) {
6641                     cmd_help();
6642                 } elsif (s/^-D/-/) {
6643                     push @ropts, $&;
6644                     $debuglevel++;
6645                     enabledebug();
6646                 } elsif (s/^-N/-/) {
6647                     push @ropts, $&;
6648                     $new_package=1;
6649                 } elsif (m/^-m/) {
6650                     push @ropts, $&;
6651                     push @changesopts, $_;
6652                     $_ = '';
6653                 } elsif (s/^-wn$//s) {
6654                     push @ropts, $&;
6655                     $cleanmode = 'none';
6656                 } elsif (s/^-wg$//s) {
6657                     push @ropts, $&;
6658                     $cleanmode = 'git';
6659                 } elsif (s/^-wgf$//s) {
6660                     push @ropts, $&;
6661                     $cleanmode = 'git-ff';
6662                 } elsif (s/^-wd$//s) {
6663                     push @ropts, $&;
6664                     $cleanmode = 'dpkg-source';
6665                 } elsif (s/^-wdd$//s) {
6666                     push @ropts, $&;
6667                     $cleanmode = 'dpkg-source-d';
6668                 } elsif (s/^-wc$//s) {
6669                     push @ropts, $&;
6670                     $cleanmode = 'check';
6671                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6672                     push @git, '-c', $&;
6673                     $gitcfgs{cmdline}{$1} = [ $2 ];
6674                 } elsif (s/^-c([^=]+)$//s) {
6675                     push @git, '-c', $&;
6676                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6677                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6678                     $val = $'; #';
6679                     $val = undef unless length $val;
6680                     $valopt->($oi->{Short});
6681                     $_ = '';
6682                 } else {
6683                     badusage "unknown short option \`$_'";
6684                 }
6685             }
6686         }
6687     }
6688 }
6689
6690 sub check_env_sanity () {
6691     my $blocked = new POSIX::SigSet;
6692     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6693
6694     eval {
6695         foreach my $name (qw(PIPE CHLD)) {
6696             my $signame = "SIG$name";
6697             my $signum = eval "POSIX::$signame" // die;
6698             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6699                 die "$signame is set to something other than SIG_DFL\n";
6700             $blocked->ismember($signum) and
6701                 die "$signame is blocked\n";
6702         }
6703     };
6704     return unless $@;
6705     chomp $@;
6706     fail <<END;
6707 On entry to dgit, $@
6708 This is a bug produced by something in in your execution environment.
6709 Giving up.
6710 END
6711 }
6712
6713
6714 sub parseopts_late_defaults () {
6715     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6716         if defined $idistro;
6717     $isuite //= cfg('dgit.default.default-suite');
6718
6719     foreach my $k (keys %opts_opt_map) {
6720         my $om = $opts_opt_map{$k};
6721
6722         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6723         if (defined $v) {
6724             badcfg "cannot set command for $k"
6725                 unless length $om->[0];
6726             $om->[0] = $v;
6727         }
6728
6729         foreach my $c (access_cfg_cfgs("opts-$k")) {
6730             my @vl =
6731                 map { $_ ? @$_ : () }
6732                 map { $gitcfgs{$_}{$c} }
6733                 reverse @gitcfgsources;
6734             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6735                 "\n" if $debuglevel >= 4;
6736             next unless @vl;
6737             badcfg "cannot configure options for $k"
6738                 if $opts_opt_cmdonly{$k};
6739             my $insertpos = $opts_cfg_insertpos{$k};
6740             @$om = ( @$om[0..$insertpos-1],
6741                      @vl,
6742                      @$om[$insertpos..$#$om] );
6743         }
6744     }
6745
6746     if (!defined $rmchanges) {
6747         local $access_forpush;
6748         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6749     }
6750
6751     if (!defined $quilt_mode) {
6752         local $access_forpush;
6753         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6754             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6755             // 'linear';
6756         $quilt_mode =~ m/^($quilt_modes_re)$/
6757             or badcfg "unknown quilt-mode \`$quilt_mode'";
6758         $quilt_mode = $1;
6759     }
6760
6761     foreach my $moc (@modeopt_cfgs) {
6762         local $access_forpush;
6763         my $vr = $moc->{Var};
6764         next if defined $$vr;
6765         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6766         my $v = $moc->{Vals}{$$vr};
6767         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6768         $$vr = $v;
6769     }
6770
6771     $need_split_build_invocation ||= quiltmode_splitbrain();
6772
6773     if (!defined $cleanmode) {
6774         local $access_forpush;
6775         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6776         $cleanmode //= 'dpkg-source';
6777
6778         badcfg "unknown clean-mode \`$cleanmode'" unless
6779             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6780     }
6781 }
6782
6783 if ($ENV{$fakeeditorenv}) {
6784     git_slurp_config();
6785     quilt_fixup_editor();
6786 }
6787
6788 parseopts();
6789 check_env_sanity();
6790
6791 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6792 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6793     if $dryrun_level == 1;
6794 if (!@ARGV) {
6795     print STDERR $helpmsg or die $!;
6796     exit 8;
6797 }
6798 $cmd = $subcommand = shift @ARGV;
6799 $cmd =~ y/-/_/;
6800
6801 my $pre_fn = ${*::}{"pre_$cmd"};
6802 $pre_fn->() if $pre_fn;
6803
6804 git_slurp_config();
6805
6806 my $fn = ${*::}{"cmd_$cmd"};
6807 $fn or badusage "unknown operation $cmd";
6808 $fn->();