Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34
  35 BEGIN {
  36     use Exporter   ();
  37     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  38
  39     $VERSION     = 1.00;
  40     @ISA         = qw(Exporter);
  41     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  42                       dep14_version_mangle
  43                       debiantags debiantag_old debiantag_new
  44                       server_branch server_ref
  45                       stat_exists link_ltarget
  46                       hashfile
  47                       fail failmsg ensuredir must_getcwd executable_on_path
  48                       waitstatusmsg failedcmd_waitstatus
  49                       failedcmd_report_cmd failedcmd
  50                       runcmd shell_cmd cmdoutput cmdoutput_errok
  51                       git_rev_parse git_cat_file
  52                       git_get_ref git_get_symref git_for_each_ref
  53                       git_for_each_tag_referring is_fast_fwd
  54                       git_check_unmodified
  55                       $package_re $component_re $deliberately_re
  56                       $distro_re $versiontag_re $series_filename_re
  57                       $extra_orig_namepart_re
  58                       $git_null_obj
  59                       $branchprefix
  60                       $ffq_refprefix $gdrlast_refprefix
  61                       initdebug enabledebug enabledebuglevel
  62                       printdebug debugcmd
  63                       $debugprefix *debuglevel *DEBUG
  64                       shellquote printcmd messagequote
  65                       $negate_harmful_gitattrs
  66                       changedir git_slurp_config_src
  67                       gdr_ffq_prev_branchinfo
  68                       playtree_setup);
  69     # implicitly uses $main::us
  70     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  71                      playground => [qw(record_maindir $maindir $local_git_cfg
  72                                        $maindir_gitdir $maindir_gitcommon
  73                                        fresh_playground
  74                                        ensure_a_playground)]);
  75     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  76                      @{ $EXPORT_TAGS{playground} } );
  77 }
  78
  79 our @EXPORT_OK;
  80
  81 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  82 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  83 our $deliberately_re = "(?:TEST-)?$package_re";
  84 our $distro_re = $component_re;
  85 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  86 our $branchprefix = 'dgit';
  87 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  88 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
  89 our $git_null_obj = '0' x 40;
  90 our $ffq_refprefix = 'ffq-prev';
  91 our $gdrlast_refprefix = 'debrebase-last';
  92
  93 # policy hook exit status bits
  94 # see dgit-repos-server head comment for documentation
  95 # 1 is reserved in case something fails with `exit 1' and to spot
  96 # dynamic loader, runtime, etc., failures, which report 127 or 255
  97 sub NOFFCHECK () { return 0x2; }
  98 sub FRESHREPO () { return 0x4; }
  99 sub NOCOMMITCHECK () { return 0x8; }
 100
 101 our $debugprefix;
 102 our $debuglevel = 0;
 103
 104 our $negate_harmful_gitattrs =
 105     "-text -eol -crlf -ident -filter -working-tree-encoding";
 106     # ^ when updating this, alter the regexp in dgit:is_gitattrs_setup
 107
 108 our $forkcheck_mainprocess;
 109
 110 sub forkcheck_setup () {
 111     $forkcheck_mainprocess = $$;
 112 }
 113
 114 sub forkcheck_mainprocess () {
 115     # You must have called forkcheck_setup or setup_sigwarn already
 116     getppid != $forkcheck_mainprocess;
 117 }
 118
 119 sub setup_sigwarn () {
 120     forkcheck_setup();
 121     $SIG{__WARN__} = sub {
 122         confess $_[0] if forkcheck_mainprocess;
 123     };
 124 }
 125
 126 sub initdebug ($) {
 127     ($debugprefix) = @_;
 128     open DEBUG, ">/dev/null" or die $!;
 129 }
 130
 131 sub enabledebug () {
 132     open DEBUG, ">&STDERR" or die $!;
 133     DEBUG->autoflush(1);
 134     $debuglevel ||= 1;
 135 }
 136
 137 sub enabledebuglevel ($) {
 138     my ($newlevel) = @_; # may be undef (eg from env var)
 139     die if $debuglevel;
 140     $newlevel //= 0;
 141     $newlevel += 0;
 142     return unless $newlevel;
 143     $debuglevel = $newlevel;
 144     enabledebug();
 145 }
 146
 147 sub printdebug {
 148     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 149 }
 150
 151 sub messagequote ($) {
 152     local ($_) = @_;
 153     s{\\}{\\\\}g;
 154     s{\n}{\\n}g;
 155     s{\x08}{\\b}g;
 156     s{\t}{\\t}g;
 157     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 158     $_;
 159 }
 160
 161 sub shellquote {
 162     my @out;
 163     local $_;
 164     defined or confess 'internal error' foreach @_;
 165     foreach my $a (@_) {
 166         $_ = $a;
 167         if (!length || m{[^-=_./:0-9a-z]}i) {
 168             s{['\\]}{'\\$&'}g;
 169             push @out, "'$_'";
 170         } else {
 171             push @out, $_;
 172         }
 173     }
 174     return join ' ', @out;
 175 }
 176
 177 sub printcmd {
 178     my $fh = shift @_;
 179     my $intro = shift @_;
 180     print $fh $intro," " or die $!;
 181     print $fh shellquote @_ or die $!;
 182     print $fh "\n" or die $!;
 183 }
 184
 185 sub debugcmd {
 186     my $extraprefix = shift @_;
 187     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 188 }
 189
 190 sub dep14_version_mangle ($) {
 191     my ($v) = @_;
 192     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 193     $v =~ y/~:/_%/;
 194     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 195     return $v;
 196 }
 197
 198 sub debiantag_old ($$) {
 199     my ($v,$distro) = @_;
 200     return "$distro/". dep14_version_mangle $v;
 201 }
 202
 203 sub debiantag_new ($$) {
 204     my ($v,$distro) = @_;
 205     return "archive/$distro/".dep14_version_mangle $v;
 206 }
 207
 208 sub debiantags ($$) {
 209     my ($version,$distro) = @_;
 210     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 211 }
 212
 213 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 214 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 215
 216 sub stat_exists ($) {
 217     my ($f) = @_;
 218     return 1 if stat $f;
 219     return 0 if $!==&ENOENT;
 220     die "stat $f: $!";
 221 }
 222
 223 sub _us () {
 224     $::us // ($0 =~ m#[^/]*$#, $&);
 225 }
 226
 227 sub failmsg {
 228     my $s = "error: @_\n";
 229     $s =~ s/\n\n$/\n/;
 230     my $prefix = _us().": ";
 231     $s =~ s/^/$prefix/gm;
 232     return "\n".$s;
 233 }
 234
 235 sub fail {
 236     die failmsg @_;
 237 }
 238
 239 sub ensuredir ($) {
 240     my ($dir) = @_; # does not create parents
 241     return if mkdir $dir;
 242     return if $! == EEXIST;
 243     die "mkdir $dir: $!";
 244 }
 245
 246 sub must_getcwd () {
 247     my $d = getcwd();
 248     defined $d or fail "getcwd failed: $!";
 249     return $d;
 250 }
 251
 252 sub executable_on_path ($) {
 253     my ($program) = @_;
 254     return 1 if $program =~ m{/};
 255     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 256     foreach my $pe (@path) {
 257         my $here = "$pe/$program";
 258         return $here if stat_exists $here && -x _;
 259     }
 260     return undef;
 261 }
 262
 263 our @signames = split / /, $Config{sig_name};
 264
 265 sub waitstatusmsg () {
 266     if (!$?) {
 267         return "terminated, reporting successful completion";
 268     } elsif (!($? & 255)) {
 269         return "failed with error exit status ".WEXITSTATUS($?);
 270     } elsif (WIFSIGNALED($?)) {
 271         my $signum=WTERMSIG($?);
 272         return "died due to fatal signal ".
 273             ($signames[$signum] // "number $signum").
 274             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 275     } else {
 276         return "failed with unknown wait status ".$?;
 277     }
 278 }
 279
 280 sub failedcmd_report_cmd {
 281     my $intro = shift @_;
 282     $intro //= "failed command";
 283     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 284 }
 285
 286 sub failedcmd_waitstatus {
 287     if ($? < 0) {
 288         return "failed to fork/exec: $!";
 289     } elsif ($?) {
 290         return "subprocess ".waitstatusmsg();
 291     } else {
 292         return "subprocess produced invalid output";
 293     }
 294 }
 295
 296 sub failedcmd {
 297     # Expects $!,$? as set by close - see below.
 298     # To use with system(), set $?=-1 first.
 299     #
 300     # Actual behaviour of perl operations:
 301     #   success              $!==0       $?==0       close of piped open
 302     #   program failed       $!==0       $? >0       close of piped open
 303     #   syscall failure      $! >0       $?=-1       close of piped open
 304     #   failure              $! >0       unchanged   close of something else
 305     #   success              trashed     $?==0       system
 306     #   program failed       trashed     $? >0       system
 307     #   syscall failure      $! >0       unchanged   system
 308     failedcmd_report_cmd undef, @_;
 309     fail failedcmd_waitstatus();
 310 }
 311
 312 sub runcmd {
 313     debugcmd "+",@_;
 314     $!=0; $?=-1;
 315     failedcmd @_ if system @_;
 316 }
 317
 318 sub shell_cmd {
 319     my ($first_shell, @cmd) = @_;
 320     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 321 }
 322
 323 sub cmdoutput_errok {
 324     confess Dumper(\@_)." ?" if grep { !defined } @_;
 325     debugcmd "|",@_;
 326     open P, "-|", @_ or die "$_[0] $!";
 327     my $d;
 328     $!=0; $?=0;
 329     { local $/ = undef; $d = <P>; }
 330     die $! if P->error;
 331     if (!close P) { printdebug "=>!$?\n"; return undef; }
 332     chomp $d;
 333     if ($debuglevel > 0) {
 334         $d =~ m/^.*/;
 335         my $dd = $&;
 336         my $more = (length $' ? '...' : ''); #');
 337         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 338         printdebug "=> \`$dd'",$more,"\n";
 339     }
 340     return $d;
 341 }
 342
 343 sub cmdoutput {
 344     my $d = cmdoutput_errok @_;
 345     defined $d or failedcmd @_;
 346     return $d;
 347 }
 348
 349 sub link_ltarget ($$) {
 350     my ($old,$new) = @_;
 351     lstat $old or return undef;
 352     if (-l _) {
 353         $old = cmdoutput qw(realpath  --), $old;
 354     }
 355     my $r = link $old, $new;
 356     $r = symlink $old, $new if !$r && $!==EXDEV;
 357     $r or die "(sym)link $old $new: $!";
 358 }
 359
 360 sub hashfile ($) {
 361     my ($fn) = @_;
 362     my $h = Digest::SHA->new(256);
 363     $h->addfile($fn);
 364     return $h->hexdigest();
 365 }
 366
 367 sub git_rev_parse ($) {
 368     return cmdoutput qw(git rev-parse), "$_[0]~0";
 369 }
 370
 371 sub git_cat_file ($;$) {
 372     my ($objname, $etype) = @_;
 373     # => ($type, $data) or ('missing', undef)
 374     # in scalar context, just the data
 375     # if $etype defined, dies unless type is $etype or in @$etype
 376     our ($gcf_pid, $gcf_i, $gcf_o);
 377     my $chk = sub {
 378         my ($gtype, $data) = @_;
 379         if ($etype) {
 380             $etype = [$etype] unless ref $etype;
 381             confess "$objname expected @$etype but is $gtype"
 382                 unless grep { $gtype eq $_ } @$etype;
 383         }
 384         return ($gtype, $data);
 385     };
 386     if (!$gcf_pid) {
 387         my @cmd = qw(git cat-file --batch);
 388         debugcmd "GCF|", @cmd;
 389         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 390     }
 391     printdebug "GCF>| ", $objname, "\n";
 392     print $gcf_i $objname, "\n" or die $!;
 393     my $x = <$gcf_o>;
 394     printdebug "GCF<| ", $x;
 395     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 396     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 397     my $data;
 398     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 399     $x = <$gcf_o>;
 400     $x eq "\n" or die "$objname ($_) $!";
 401     return $chk->($type, $data);
 402 }
 403
 404 sub git_get_symref (;$) {
 405     my ($symref) = @_;  $symref //= 'HEAD';
 406     # => undef if not a symref, otherwise refs/...
 407     my @cmd = (qw(git symbolic-ref -q HEAD));
 408     my $branch = cmdoutput_errok @cmd;
 409     if (!defined $branch) {
 410         $?==256 or failedcmd @cmd;
 411     } else {
 412         chomp $branch;
 413     }
 414     return $branch;
 415 }
 416
 417 sub git_for_each_ref ($$;$) {
 418     my ($pattern,$func,$gitdir) = @_;
 419     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 420     # $reftail is RHS of ref after refs/[^/]+/
 421     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 422     # $pattern may be an array ref to mean multiple patterns
 423     $pattern = [ $pattern ] unless ref $pattern;
 424     my @cmd = (qw(git for-each-ref), @$pattern);
 425     if (defined $gitdir) {
 426         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 427     }
 428     open GFER, "-|", @cmd or die $!;
 429     debugcmd "|", @cmd;
 430     while (<GFER>) {
 431         chomp or die "$_ ?";
 432         printdebug "|> ", $_, "\n";
 433         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 434         $func->($1,$2,$3,$4);
 435     }
 436     $!=0; $?=0; close GFER or die "$pattern $? $!";
 437 }
 438
 439 sub git_get_ref ($) {
 440     # => '' if no such ref
 441     my ($refname) = @_;
 442     local $_ = $refname;
 443     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 444     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 445 }
 446
 447 sub git_for_each_tag_referring ($$) {
 448     my ($objreferring, $func) = @_;
 449     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 450     printdebug "git_for_each_tag_referring ",
 451         ($objreferring // 'UNDEF'),"\n";
 452     git_for_each_ref('refs/tags', sub {
 453         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 454         return unless $objtype eq 'tag';
 455         my $refobjid = git_rev_parse $tagobjid;
 456         return unless
 457             !defined $objreferring # caller wants them all
 458             or $tagobjid eq $objreferring
 459             or $refobjid eq $objreferring;
 460         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 461     });
 462 }
 463
 464 sub git_check_unmodified () {
 465     foreach my $cached (qw(0 1)) {
 466         my @cmd = qw(git diff --quiet);
 467         push @cmd, qw(--cached) if $cached;
 468         push @cmd, qw(HEAD);
 469         debugcmd "+",@cmd;
 470         $!=0; $?=-1; system @cmd;
 471         return if !$?;
 472         if ($?==256) {
 473             fail
 474                 $cached
 475                 ? "git index contains changes (does not match HEAD)"
 476                 : "working tree is dirty (does not match HEAD)";
 477         } else {
 478             failedcmd @cmd;
 479         }
 480     }
 481 }
 482
 483 sub is_fast_fwd ($$) {
 484     my ($ancestor,$child) = @_;
 485     my @cmd = (qw(git merge-base), $ancestor, $child);
 486     my $mb = cmdoutput_errok @cmd;
 487     if (defined $mb) {
 488         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 489     } else {
 490         $?==256 or failedcmd @cmd;
 491         return 0;
 492     }
 493 }
 494
 495 sub changedir ($) {
 496     my ($newdir) = @_;
 497     printdebug "CD $newdir\n";
 498     chdir $newdir or confess "chdir: $newdir: $!";
 499 }
 500
 501 sub git_slurp_config_src ($) {
 502     my ($src) = @_;
 503     # returns $r such that $r->{KEY}[] = VALUE
 504     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 505     debugcmd "|",@cmd;
 506
 507     local ($debuglevel) = $debuglevel-2;
 508     local $/="\0";
 509
 510     my $r = { };
 511     open GITS, "-|", @cmd or die $!;
 512     while (<GITS>) {
 513         chomp or die;
 514         printdebug "=> ", (messagequote $_), "\n";
 515         m/\n/ or die "$_ ?";
 516         push @{ $r->{$`} }, $'; #';
 517     }
 518     $!=0; $?=0;
 519     close GITS
 520         or ($!==0 && $?==256)
 521         or failedcmd @cmd;
 522     return $r;
 523 }
 524
 525 sub gdr_ffq_prev_branchinfo ($) {
 526     my ($symref) = @_;
 527     # => ('status', "message", [$symref, $ffq_prev, $gdrlast])
 528     # 'status' may be
 529     #    branch         message is undef
 530     #    weird-symref   } no $symref,
 531     #    notbranch      }  no $ffq_prev
 532     return ('detached', 'detached HEAD') unless defined $symref;
 533     return ('weird-symref', 'HEAD symref is not to refs/')
 534         unless $symref =~ m{^refs/};
 535     my $ffq_prev = "refs/$ffq_refprefix/$'";
 536     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 537     printdebug "ffq_prev_branchinfo branch current $symref\n";
 538     return ('branch', undef, $symref, $ffq_prev, $gdrlast);
 539 }
 540
 541 # ========== playground handling ==========
 542
 543 # terminology:
 544 #
 545 #   $maindir      user's git working tree
 546 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 547 #   playtree      git working tree sharing object store with the user's
 548 #                 inside playground, or identical to it
 549 #
 550 # other globals
 551 #
 552 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 553 #
 554 # expected calling pattern
 555 #
 556 #  firstly
 557 #
 558 #    [record_maindir]
 559 #      must be run in directory containing .git
 560 #      assigns to $maindir if not already set
 561 #      also calls git_slurp_config_src to record git config
 562 #        in $local_git_cfg, unless it's already set
 563 #
 564 #    fresh_playground SUBDIR_PATH_COMPONENTS
 565 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 566 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 567 #      calls record_maindir
 568 #      sets up a new playground (destroying any old one)
 569 #      returns playground pathname
 570 #      caller may call multiple times with different subdir paths
 571 #       createing different playgrounds
 572 #
 573 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 574 #      like fresh_playground except:
 575 #      merely ensures the directory exists; does not delete an existing one
 576 #
 577 #  then can use
 578 #
 579 #    changedir playground
 580 #    changedir $maindir
 581 #
 582 #    playtree_setup $local_git_cfg
 583 #            # ^ call in some (perhaps trivial) subdir of playground
 584 #
 585 #    rmtree playground
 586
 587 # ----- maindir -----
 588
 589 # these three all go together
 590 our $maindir;
 591 our $maindir_gitdir;
 592 our $maindir_gitcommon;
 593
 594 our $local_git_cfg;
 595
 596 sub record_maindir () {
 597     if (!defined $maindir) {
 598         $maindir = must_getcwd();
 599         if (!stat "$maindir/.git") {
 600             fail "cannot stat $maindir/.git: $!";
 601         }
 602         if (-d _) {
 603             # we fall back to this in case we have a pre-worktree
 604             # git, which may not know git rev-parse --git-common-dir
 605             $maindir_gitdir    = "$maindir/.git";
 606             $maindir_gitcommon = "$maindir/.git";
 607         } else {
 608             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 609             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 610         }
 611     }
 612     $local_git_cfg //= git_slurp_config_src 'local';
 613 }
 614
 615 # ----- playgrounds -----
 616
 617 sub ensure_a_playground_parent ($) {
 618     my ($spc) = @_;
 619     record_maindir();
 620     $spc = "$maindir_gitdir/$spc";
 621     my $parent = dirname $spc;
 622     mkdir $parent or $!==EEXIST
 623         or fail "failed to mkdir playground parent $parent: $!";
 624     return $spc;
 625 }
 626
 627 sub ensure_a_playground ($) {
 628     my ($spc) = @_;
 629     $spc = ensure_a_playground_parent $spc;
 630     mkdir $spc or $!==EEXIST or fail "failed to mkdir a playground $spc: $!";
 631     return $spc;
 632 }
 633
 634 sub fresh_playground ($) {
 635     my ($spc) = @_;
 636     $spc = ensure_a_playground_parent $spc;
 637     rmtree $spc;
 638     mkdir $spc or fail "failed to mkdir the playground $spc: $!";
 639     return $spc;
 640 }
 641
 642 # ----- playtrees -----
 643
 644 sub playtree_setup (;$) {
 645     my ($t_local_git_cfg) = @_;
 646     $t_local_git_cfg //= $local_git_cfg;
 647     # for use in the playtree
 648     # $maindir must be set, eg by calling record_maindir or fresh_playground
 649     runcmd qw(git init -q);
 650     runcmd qw(git config gc.auto 0);
 651     foreach my $copy (qw(user.email user.name user.useConfigOnly
 652                          core.sharedRepository
 653                          core.compression core.looseCompression
 654                          core.bigFileThreshold core.fsyncObjectFiles)) {
 655         my $v = $t_local_git_cfg->{$copy};
 656         next unless $v;
 657         runcmd qw(git config), $copy, $_ foreach @$v;
 658     }
 659     # this is confusing: we have
 660     #   .                   playtree, not a worktree, has .git/, our cwd
 661     #   $maindir            might be a worktree so
 662     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 663     #   $maindir_gitcommon  the shared stuff, including .objects
 664     rmtree('.git/objects');
 665     symlink "$maindir_gitcommon/objects",'.git/objects' or die $!;
 666     ensuredir '.git/info';
 667     open GA, "> .git/info/attributes" or die $!;
 668     print GA "* $negate_harmful_gitattrs\n" or die $!;
 669     close GA or die $!;
 670 }
 671
 672 1;