Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34
  35 BEGIN {
  36     use Exporter   ();
  37     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  38
  39     $VERSION     = 1.00;
  40     @ISA         = qw(Exporter);
  41     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  42                       dep14_version_mangle
  43                       debiantags debiantag_old debiantag_new
  44                       server_branch server_ref
  45                       stat_exists link_ltarget
  46                       hashfile
  47                       fail failmsg ensuredir must_getcwd executable_on_path
  48                       waitstatusmsg failedcmd_waitstatus
  49                       failedcmd_report_cmd failedcmd
  50                       runcmd shell_cmd cmdoutput cmdoutput_errok
  51                       git_rev_parse git_cat_file
  52                       git_get_ref git_get_symref git_for_each_ref
  53                       git_for_each_tag_referring is_fast_fwd
  54                       git_check_unmodified
  55                       git_reflog_action_msg  git_update_ref_cmd
  56                       $package_re $component_re $deliberately_re
  57                       $distro_re $versiontag_re $series_filename_re
  58                       $extra_orig_namepart_re
  59                       $git_null_obj
  60                       $branchprefix
  61                       $ffq_refprefix $gdrlast_refprefix
  62                       initdebug enabledebug enabledebuglevel
  63                       printdebug debugcmd
  64                       $debugprefix *debuglevel *DEBUG
  65                       shellquote printcmd messagequote
  66                       $negate_harmful_gitattrs
  67                       changedir git_slurp_config_src
  68                       gdr_ffq_prev_branchinfo
  69                       playtree_setup);
  70     # implicitly uses $main::us
  71     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  72                      playground => [qw(record_maindir $maindir $local_git_cfg
  73                                        $maindir_gitdir $maindir_gitcommon
  74                                        fresh_playground
  75                                        ensure_a_playground)]);
  76     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  77                      @{ $EXPORT_TAGS{playground} } );
  78 }
  79
  80 our @EXPORT_OK;
  81
  82 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  83 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  84 our $deliberately_re = "(?:TEST-)?$package_re";
  85 our $distro_re = $component_re;
  86 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  87 our $branchprefix = 'dgit';
  88 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  89 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
  90 our $git_null_obj = '0' x 40;
  91 our $ffq_refprefix = 'ffq-prev';
  92 our $gdrlast_refprefix = 'debrebase-last';
  93
  94 # policy hook exit status bits
  95 # see dgit-repos-server head comment for documentation
  96 # 1 is reserved in case something fails with `exit 1' and to spot
  97 # dynamic loader, runtime, etc., failures, which report 127 or 255
  98 sub NOFFCHECK () { return 0x2; }
  99 sub FRESHREPO () { return 0x4; }
 100 sub NOCOMMITCHECK () { return 0x8; }
 101
 102 our $debugprefix;
 103 our $debuglevel = 0;
 104
 105 our $negate_harmful_gitattrs =
 106     "-text -eol -crlf -ident -filter -working-tree-encoding";
 107     # ^ when updating this, alter the regexp in dgit:is_gitattrs_setup
 108
 109 our $forkcheck_mainprocess;
 110
 111 sub forkcheck_setup () {
 112     $forkcheck_mainprocess = $$;
 113 }
 114
 115 sub forkcheck_mainprocess () {
 116     # You must have called forkcheck_setup or setup_sigwarn already
 117     getppid != $forkcheck_mainprocess;
 118 }
 119
 120 sub setup_sigwarn () {
 121     forkcheck_setup();
 122     $SIG{__WARN__} = sub {
 123         confess $_[0] if forkcheck_mainprocess;
 124     };
 125 }
 126
 127 sub initdebug ($) {
 128     ($debugprefix) = @_;
 129     open DEBUG, ">/dev/null" or die $!;
 130 }
 131
 132 sub enabledebug () {
 133     open DEBUG, ">&STDERR" or die $!;
 134     DEBUG->autoflush(1);
 135     $debuglevel ||= 1;
 136 }
 137
 138 sub enabledebuglevel ($) {
 139     my ($newlevel) = @_; # may be undef (eg from env var)
 140     die if $debuglevel;
 141     $newlevel //= 0;
 142     $newlevel += 0;
 143     return unless $newlevel;
 144     $debuglevel = $newlevel;
 145     enabledebug();
 146 }
 147
 148 sub printdebug {
 149     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 150 }
 151
 152 sub messagequote ($) {
 153     local ($_) = @_;
 154     s{\\}{\\\\}g;
 155     s{\n}{\\n}g;
 156     s{\x08}{\\b}g;
 157     s{\t}{\\t}g;
 158     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 159     $_;
 160 }
 161
 162 sub shellquote {
 163     my @out;
 164     local $_;
 165     defined or confess 'internal error' foreach @_;
 166     foreach my $a (@_) {
 167         $_ = $a;
 168         if (!length || m{[^-=_./:0-9a-z]}i) {
 169             s{['\\]}{'\\$&'}g;
 170             push @out, "'$_'";
 171         } else {
 172             push @out, $_;
 173         }
 174     }
 175     return join ' ', @out;
 176 }
 177
 178 sub printcmd {
 179     my $fh = shift @_;
 180     my $intro = shift @_;
 181     print $fh $intro," " or die $!;
 182     print $fh shellquote @_ or die $!;
 183     print $fh "\n" or die $!;
 184 }
 185
 186 sub debugcmd {
 187     my $extraprefix = shift @_;
 188     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 189 }
 190
 191 sub dep14_version_mangle ($) {
 192     my ($v) = @_;
 193     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 194     $v =~ y/~:/_%/;
 195     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 196     return $v;
 197 }
 198
 199 sub debiantag_old ($$) {
 200     my ($v,$distro) = @_;
 201     return "$distro/". dep14_version_mangle $v;
 202 }
 203
 204 sub debiantag_new ($$) {
 205     my ($v,$distro) = @_;
 206     return "archive/$distro/".dep14_version_mangle $v;
 207 }
 208
 209 sub debiantags ($$) {
 210     my ($version,$distro) = @_;
 211     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 212 }
 213
 214 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 215 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 216
 217 sub stat_exists ($) {
 218     my ($f) = @_;
 219     return 1 if stat $f;
 220     return 0 if $!==&ENOENT;
 221     die "stat $f: $!";
 222 }
 223
 224 sub _us () {
 225     $::us // ($0 =~ m#[^/]*$#, $&);
 226 }
 227
 228 sub failmsg {
 229     my $s = "error: @_\n";
 230     $s =~ s/\n\n$/\n/;
 231     my $prefix = _us().": ";
 232     $s =~ s/^/$prefix/gm;
 233     return "\n".$s;
 234 }
 235
 236 sub fail {
 237     die failmsg @_;
 238 }
 239
 240 sub ensuredir ($) {
 241     my ($dir) = @_; # does not create parents
 242     return if mkdir $dir;
 243     return if $! == EEXIST;
 244     die "mkdir $dir: $!";
 245 }
 246
 247 sub must_getcwd () {
 248     my $d = getcwd();
 249     defined $d or fail "getcwd failed: $!";
 250     return $d;
 251 }
 252
 253 sub executable_on_path ($) {
 254     my ($program) = @_;
 255     return 1 if $program =~ m{/};
 256     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 257     foreach my $pe (@path) {
 258         my $here = "$pe/$program";
 259         return $here if stat_exists $here && -x _;
 260     }
 261     return undef;
 262 }
 263
 264 our @signames = split / /, $Config{sig_name};
 265
 266 sub waitstatusmsg () {
 267     if (!$?) {
 268         return "terminated, reporting successful completion";
 269     } elsif (!($? & 255)) {
 270         return "failed with error exit status ".WEXITSTATUS($?);
 271     } elsif (WIFSIGNALED($?)) {
 272         my $signum=WTERMSIG($?);
 273         return "died due to fatal signal ".
 274             ($signames[$signum] // "number $signum").
 275             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 276     } else {
 277         return "failed with unknown wait status ".$?;
 278     }
 279 }
 280
 281 sub failedcmd_report_cmd {
 282     my $intro = shift @_;
 283     $intro //= "failed command";
 284     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 285 }
 286
 287 sub failedcmd_waitstatus {
 288     if ($? < 0) {
 289         return "failed to fork/exec: $!";
 290     } elsif ($?) {
 291         return "subprocess ".waitstatusmsg();
 292     } else {
 293         return "subprocess produced invalid output";
 294     }
 295 }
 296
 297 sub failedcmd {
 298     # Expects $!,$? as set by close - see below.
 299     # To use with system(), set $?=-1 first.
 300     #
 301     # Actual behaviour of perl operations:
 302     #   success              $!==0       $?==0       close of piped open
 303     #   program failed       $!==0       $? >0       close of piped open
 304     #   syscall failure      $! >0       $?=-1       close of piped open
 305     #   failure              $! >0       unchanged   close of something else
 306     #   success              trashed     $?==0       system
 307     #   program failed       trashed     $? >0       system
 308     #   syscall failure      $! >0       unchanged   system
 309     failedcmd_report_cmd undef, @_;
 310     fail failedcmd_waitstatus();
 311 }
 312
 313 sub runcmd {
 314     debugcmd "+",@_;
 315     $!=0; $?=-1;
 316     failedcmd @_ if system @_;
 317 }
 318
 319 sub shell_cmd {
 320     my ($first_shell, @cmd) = @_;
 321     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 322 }
 323
 324 sub cmdoutput_errok {
 325     confess Dumper(\@_)." ?" if grep { !defined } @_;
 326     debugcmd "|",@_;
 327     open P, "-|", @_ or die "$_[0] $!";
 328     my $d;
 329     $!=0; $?=0;
 330     { local $/ = undef; $d = <P>; }
 331     die $! if P->error;
 332     if (!close P) { printdebug "=>!$?\n"; return undef; }
 333     chomp $d;
 334     if ($debuglevel > 0) {
 335         $d =~ m/^.*/;
 336         my $dd = $&;
 337         my $more = (length $' ? '...' : ''); #');
 338         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 339         printdebug "=> \`$dd'",$more,"\n";
 340     }
 341     return $d;
 342 }
 343
 344 sub cmdoutput {
 345     my $d = cmdoutput_errok @_;
 346     defined $d or failedcmd @_;
 347     return $d;
 348 }
 349
 350 sub link_ltarget ($$) {
 351     my ($old,$new) = @_;
 352     lstat $old or return undef;
 353     if (-l _) {
 354         $old = cmdoutput qw(realpath  --), $old;
 355     }
 356     my $r = link $old, $new;
 357     $r = symlink $old, $new if !$r && $!==EXDEV;
 358     $r or die "(sym)link $old $new: $!";
 359 }
 360
 361 sub hashfile ($) {
 362     my ($fn) = @_;
 363     my $h = Digest::SHA->new(256);
 364     $h->addfile($fn);
 365     return $h->hexdigest();
 366 }
 367
 368 sub git_rev_parse ($) {
 369     return cmdoutput qw(git rev-parse), "$_[0]~0";
 370 }
 371
 372 sub git_cat_file ($;$) {
 373     my ($objname, $etype) = @_;
 374     # => ($type, $data) or ('missing', undef)
 375     # in scalar context, just the data
 376     # if $etype defined, dies unless type is $etype or in @$etype
 377     our ($gcf_pid, $gcf_i, $gcf_o);
 378     my $chk = sub {
 379         my ($gtype, $data) = @_;
 380         if ($etype) {
 381             $etype = [$etype] unless ref $etype;
 382             confess "$objname expected @$etype but is $gtype"
 383                 unless grep { $gtype eq $_ } @$etype;
 384         }
 385         return ($gtype, $data);
 386     };
 387     if (!$gcf_pid) {
 388         my @cmd = qw(git cat-file --batch);
 389         debugcmd "GCF|", @cmd;
 390         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 391     }
 392     printdebug "GCF>| ", $objname, "\n";
 393     print $gcf_i $objname, "\n" or die $!;
 394     my $x = <$gcf_o>;
 395     printdebug "GCF<| ", $x;
 396     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 397     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 398     my $data;
 399     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 400     $x = <$gcf_o>;
 401     $x eq "\n" or die "$objname ($_) $!";
 402     return $chk->($type, $data);
 403 }
 404
 405 sub git_get_symref (;$) {
 406     my ($symref) = @_;  $symref //= 'HEAD';
 407     # => undef if not a symref, otherwise refs/...
 408     my @cmd = (qw(git symbolic-ref -q HEAD));
 409     my $branch = cmdoutput_errok @cmd;
 410     if (!defined $branch) {
 411         $?==256 or failedcmd @cmd;
 412     } else {
 413         chomp $branch;
 414     }
 415     return $branch;
 416 }
 417
 418 sub git_for_each_ref ($$;$) {
 419     my ($pattern,$func,$gitdir) = @_;
 420     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 421     # $reftail is RHS of ref after refs/[^/]+/
 422     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 423     # $pattern may be an array ref to mean multiple patterns
 424     $pattern = [ $pattern ] unless ref $pattern;
 425     my @cmd = (qw(git for-each-ref), @$pattern);
 426     if (defined $gitdir) {
 427         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 428     }
 429     open GFER, "-|", @cmd or die $!;
 430     debugcmd "|", @cmd;
 431     while (<GFER>) {
 432         chomp or die "$_ ?";
 433         printdebug "|> ", $_, "\n";
 434         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 435         $func->($1,$2,$3,$4);
 436     }
 437     $!=0; $?=0; close GFER or die "$pattern $? $!";
 438 }
 439
 440 sub git_get_ref ($) {
 441     # => '' if no such ref
 442     my ($refname) = @_;
 443     local $_ = $refname;
 444     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 445     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 446 }
 447
 448 sub git_for_each_tag_referring ($$) {
 449     my ($objreferring, $func) = @_;
 450     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 451     printdebug "git_for_each_tag_referring ",
 452         ($objreferring // 'UNDEF'),"\n";
 453     git_for_each_ref('refs/tags', sub {
 454         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 455         return unless $objtype eq 'tag';
 456         my $refobjid = git_rev_parse $tagobjid;
 457         return unless
 458             !defined $objreferring # caller wants them all
 459             or $tagobjid eq $objreferring
 460             or $refobjid eq $objreferring;
 461         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 462     });
 463 }
 464
 465 sub git_check_unmodified () {
 466     foreach my $cached (qw(0 1)) {
 467         my @cmd = qw(git diff --quiet);
 468         push @cmd, qw(--cached) if $cached;
 469         push @cmd, qw(HEAD);
 470         debugcmd "+",@cmd;
 471         $!=0; $?=-1; system @cmd;
 472         return if !$?;
 473         if ($?==256) {
 474             fail
 475                 $cached
 476                 ? "git index contains changes (does not match HEAD)"
 477                 : "working tree is dirty (does not match HEAD)";
 478         } else {
 479             failedcmd @cmd;
 480         }
 481     }
 482 }
 483
 484 sub is_fast_fwd ($$) {
 485     my ($ancestor,$child) = @_;
 486     my @cmd = (qw(git merge-base), $ancestor, $child);
 487     my $mb = cmdoutput_errok @cmd;
 488     if (defined $mb) {
 489         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 490     } else {
 491         $?==256 or failedcmd @cmd;
 492         return 0;
 493     }
 494 }
 495
 496 sub git_reflog_action_msg ($) {
 497     my ($msg) = @_;
 498     my $rla = $ENV{GIT_REFLOG_ACTION};
 499     $msg = "$rla: $msg" if length $rla;
 500     return $msg;
 501 }
 502
 503 sub git_update_ref_cmd {
 504     # returns  qw(git update-ref), qw(-m), @_
 505     # except that message may be modified to honour GIT_REFLOG_ACTION
 506     my $msg = shift @_;
 507     $msg = git_reflog_action_msg $msg;
 508     return qw(git update-ref -m), $msg, @_;
 509 }
 510
 511 sub changedir ($) {
 512     my ($newdir) = @_;
 513     printdebug "CD $newdir\n";
 514     chdir $newdir or confess "chdir: $newdir: $!";
 515 }
 516
 517 sub git_slurp_config_src ($) {
 518     my ($src) = @_;
 519     # returns $r such that $r->{KEY}[] = VALUE
 520     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 521     debugcmd "|",@cmd;
 522
 523     local ($debuglevel) = $debuglevel-2;
 524     local $/="\0";
 525
 526     my $r = { };
 527     open GITS, "-|", @cmd or die $!;
 528     while (<GITS>) {
 529         chomp or die;
 530         printdebug "=> ", (messagequote $_), "\n";
 531         m/\n/ or die "$_ ?";
 532         push @{ $r->{$`} }, $'; #';
 533     }
 534     $!=0; $?=0;
 535     close GITS
 536         or ($!==0 && $?==256)
 537         or failedcmd @cmd;
 538     return $r;
 539 }
 540
 541 sub gdr_ffq_prev_branchinfo ($) {
 542     my ($symref) = @_;
 543     # => ('status', "message", [$symref, $ffq_prev, $gdrlast])
 544     # 'status' may be
 545     #    branch         message is undef
 546     #    weird-symref   } no $symref,
 547     #    notbranch      }  no $ffq_prev
 548     return ('detached', 'detached HEAD') unless defined $symref;
 549     return ('weird-symref', 'HEAD symref is not to refs/')
 550         unless $symref =~ m{^refs/};
 551     my $ffq_prev = "refs/$ffq_refprefix/$'";
 552     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 553     printdebug "ffq_prev_branchinfo branch current $symref\n";
 554     return ('branch', undef, $symref, $ffq_prev, $gdrlast);
 555 }
 556
 557 # ========== playground handling ==========
 558
 559 # terminology:
 560 #
 561 #   $maindir      user's git working tree
 562 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 563 #   playtree      git working tree sharing object store with the user's
 564 #                 inside playground, or identical to it
 565 #
 566 # other globals
 567 #
 568 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 569 #
 570 # expected calling pattern
 571 #
 572 #  firstly
 573 #
 574 #    [record_maindir]
 575 #      must be run in directory containing .git
 576 #      assigns to $maindir if not already set
 577 #      also calls git_slurp_config_src to record git config
 578 #        in $local_git_cfg, unless it's already set
 579 #
 580 #    fresh_playground SUBDIR_PATH_COMPONENTS
 581 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 582 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 583 #      calls record_maindir
 584 #      sets up a new playground (destroying any old one)
 585 #      returns playground pathname
 586 #      caller may call multiple times with different subdir paths
 587 #       createing different playgrounds
 588 #
 589 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 590 #      like fresh_playground except:
 591 #      merely ensures the directory exists; does not delete an existing one
 592 #
 593 #  then can use
 594 #
 595 #    changedir playground
 596 #    changedir $maindir
 597 #
 598 #    playtree_setup $local_git_cfg
 599 #            # ^ call in some (perhaps trivial) subdir of playground
 600 #
 601 #    rmtree playground
 602
 603 # ----- maindir -----
 604
 605 # these three all go together
 606 our $maindir;
 607 our $maindir_gitdir;
 608 our $maindir_gitcommon;
 609
 610 our $local_git_cfg;
 611
 612 sub record_maindir () {
 613     if (!defined $maindir) {
 614         $maindir = must_getcwd();
 615         if (!stat "$maindir/.git") {
 616             fail "cannot stat $maindir/.git: $!";
 617         }
 618         if (-d _) {
 619             # we fall back to this in case we have a pre-worktree
 620             # git, which may not know git rev-parse --git-common-dir
 621             $maindir_gitdir    = "$maindir/.git";
 622             $maindir_gitcommon = "$maindir/.git";
 623         } else {
 624             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 625             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 626         }
 627     }
 628     $local_git_cfg //= git_slurp_config_src 'local';
 629 }
 630
 631 # ----- playgrounds -----
 632
 633 sub ensure_a_playground_parent ($) {
 634     my ($spc) = @_;
 635     record_maindir();
 636     $spc = "$maindir_gitdir/$spc";
 637     my $parent = dirname $spc;
 638     mkdir $parent or $!==EEXIST
 639         or fail "failed to mkdir playground parent $parent: $!";
 640     return $spc;
 641 }
 642
 643 sub ensure_a_playground ($) {
 644     my ($spc) = @_;
 645     $spc = ensure_a_playground_parent $spc;
 646     mkdir $spc or $!==EEXIST or fail "failed to mkdir a playground $spc: $!";
 647     return $spc;
 648 }
 649
 650 sub fresh_playground ($) {
 651     my ($spc) = @_;
 652     $spc = ensure_a_playground_parent $spc;
 653     rmtree $spc;
 654     mkdir $spc or fail "failed to mkdir the playground $spc: $!";
 655     return $spc;
 656 }
 657
 658 # ----- playtrees -----
 659
 660 sub playtree_setup (;$) {
 661     my ($t_local_git_cfg) = @_;
 662     $t_local_git_cfg //= $local_git_cfg;
 663     # for use in the playtree
 664     # $maindir must be set, eg by calling record_maindir or fresh_playground
 665     runcmd qw(git init -q);
 666     runcmd qw(git config gc.auto 0);
 667     foreach my $copy (qw(user.email user.name user.useConfigOnly
 668                          core.sharedRepository
 669                          core.compression core.looseCompression
 670                          core.bigFileThreshold core.fsyncObjectFiles)) {
 671         my $v = $t_local_git_cfg->{$copy};
 672         next unless $v;
 673         runcmd qw(git config), $copy, $_ foreach @$v;
 674     }
 675     # this is confusing: we have
 676     #   .                   playtree, not a worktree, has .git/, our cwd
 677     #   $maindir            might be a worktree so
 678     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 679     #   $maindir_gitcommon  the shared stuff, including .objects
 680     rmtree('.git/objects');
 681     symlink "$maindir_gitcommon/objects",'.git/objects' or die $!;
 682     ensuredir '.git/info';
 683     open GA, "> .git/info/attributes" or die $!;
 684     print GA "* $negate_harmful_gitattrs\n" or die $!;
 685     close GA or die $!;
 686 }
 687
 688 1;