Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp;
   9 use POSIX;
  10 use IO::Handle;
  11 use Config;
  12 use Digest::SHA;
  13 use Data::Dumper;
  14
  15 BEGIN {
  16     use Exporter   ();
  17     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  18
  19     $VERSION     = 1.00;
  20     @ISA         = qw(Exporter);
  21     @EXPORT      = qw(setup_sigwarn
  22                       debiantags debiantag_old debiantag_new
  23                       server_branch server_ref
  24                       stat_exists link_ltarget
  25                       hashfile
  26                       fail ensuredir executable_on_path
  27                       waitstatusmsg failedcmd
  28                       cmdoutput cmdoutput_errok
  29                       git_rev_parse git_get_ref git_for_each_ref
  30                       git_for_each_tag_referring is_fast_fwd
  31                       $package_re $component_re $deliberately_re
  32                       $branchprefix
  33                       initdebug enabledebug enabledebuglevel
  34                       printdebug debugcmd
  35                       $debugprefix *debuglevel *DEBUG
  36                       shellquote printcmd messagequote);
  37     # implicitly uses $main::us
  38     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  39     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  40 }
  41
  42 our @EXPORT_OK;
  43
  44 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  45 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  46 our $deliberately_re = "(?:TEST-)?$package_re";
  47 our $branchprefix = 'dgit';
  48
  49 # policy hook exit status bits
  50 # see dgit-repos-server head comment for documentation
  51 # 1 is reserved in case something fails with `exit 1' and to spot
  52 # dynamic loader, runtime, etc., failures, which report 127 or 255
  53 sub NOFFCHECK () { return 0x2; }
  54 sub FRESHREPO () { return 0x4; }
  55
  56 our $debugprefix;
  57 our $debuglevel = 0;
  58
  59 sub setup_sigwarn () {
  60     our $sigwarn_mainprocess = $$;
  61     $SIG{__WARN__} = sub {
  62         die $_[0] unless getppid == $sigwarn_mainprocess;
  63     };
  64 }
  65
  66 sub initdebug ($) {
  67     ($debugprefix) = @_;
  68     open DEBUG, ">/dev/null" or die $!;
  69 }
  70
  71 sub enabledebug () {
  72     open DEBUG, ">&STDERR" or die $!;
  73     DEBUG->autoflush(1);
  74     $debuglevel ||= 1;
  75 }
  76
  77 sub enabledebuglevel ($) {
  78     my ($newlevel) = @_; # may be undef (eg from env var)
  79     die if $debuglevel;
  80     $newlevel //= 0;
  81     $newlevel += 0;
  82     return unless $newlevel;
  83     $debuglevel = $newlevel;
  84     enabledebug();
  85 }
  86
  87 sub printdebug {
  88     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  89 }
  90
  91 sub messagequote ($) {
  92     local ($_) = @_;
  93     s{\\}{\\\\}g;
  94     s{\n}{\\n}g;
  95     s{\x08}{\\b}g;
  96     s{\t}{\\t}g;
  97     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  98     $_;
  99 }
 100
 101 sub shellquote {
 102     my @out;
 103     local $_;
 104     foreach my $a (@_) {
 105         $_ = $a;
 106         if (!length || m{[^-=_./:0-9a-z]}i) {
 107             s{['\\]}{'\\$&'}g;
 108             push @out, "'$_'";
 109         } else {
 110             push @out, $_;
 111         }
 112     }
 113     return join ' ', @out;
 114 }
 115
 116 sub printcmd {
 117     my $fh = shift @_;
 118     my $intro = shift @_;
 119     print $fh $intro," " or die $!;
 120     print $fh shellquote @_ or die $!;
 121     print $fh "\n" or die $!;
 122 }
 123
 124 sub debugcmd {
 125     my $extraprefix = shift @_;
 126     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 127 }
 128
 129 sub debiantag_old ($$) {
 130     my ($v,$distro) = @_;
 131     $v =~ y/~:/_%/;
 132     return "$distro/$v";
 133 }
 134
 135 sub debiantag_new ($$) {
 136     my ($v,$distro) = @_;
 137     $v =~ y/~:/_%/;
 138     return "archive/$distro/$v";
 139 }
 140
 141 sub debiantags ($$) {
 142     my ($version,$distro) = @_;
 143     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 144 }
 145
 146 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 147 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 148
 149 sub stat_exists ($) {
 150     my ($f) = @_;
 151     return 1 if stat $f;
 152     return 0 if $!==&ENOENT;
 153     die "stat $f: $!";
 154 }
 155
 156 sub _us () {
 157     $::us // ($0 =~ m#[^/]*$#, $&);
 158 }
 159
 160 sub fail {
 161     my $s = "@_\n";
 162     my $prefix = _us().": ";
 163     $s =~ s/^/$prefix/gm;
 164     die $s;
 165 }
 166
 167 sub ensuredir ($) {
 168     my ($dir) = @_; # does not create parents
 169     return if mkdir $dir;
 170     return if $! == EEXIST;
 171     die "mkdir $dir: $!";
 172 }
 173
 174 sub executable_on_path ($) {
 175     my ($program) = @_;
 176     return 1 if $program =~ m{/};
 177     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 178     foreach my $pe (@path) {
 179         my $here = "$pe/$program";
 180         return $here if stat_exists $here && -x _;
 181     }
 182     return undef;
 183 }
 184
 185 our @signames = split / /, $Config{sig_name};
 186
 187 sub waitstatusmsg () {
 188     if (!$?) {
 189         return "terminated, reporting successful completion";
 190     } elsif (!($? & 255)) {
 191         return "failed with error exit status ".WEXITSTATUS($?);
 192     } elsif (WIFSIGNALED($?)) {
 193         my $signum=WTERMSIG($?);
 194         return "died due to fatal signal ".
 195             ($signames[$signum] // "number $signum").
 196             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 197     } else {
 198         return "failed with unknown wait status ".$?;
 199     }
 200 }
 201
 202 sub failedcmd {
 203     # Expects $!,$? as set by close - see below.
 204     # To use with system(), set $?=-1 first.
 205     #
 206     # Actual behaviour of perl operations:
 207     #   success              $!==0       $?==0       close of piped open
 208     #   program failed       $!==0       $? >0       close of piped open
 209     #   syscall failure      $! >0       $?=-1       close of piped open
 210     #   failure              $! >0       unchanged   close of something else
 211     #   success              trashed     $?==0       system
 212     #   program failed       trashed     $? >0       system
 213     #   syscall failure      $! >0       unchanged   system
 214     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 215     if ($? < 0) {
 216         fail "failed to fork/exec: $!";
 217     } elsif ($?) {
 218         fail "subprocess ".waitstatusmsg();
 219     } else {
 220         fail "subprocess produced invalid output";
 221     }
 222 }
 223
 224 sub cmdoutput_errok {
 225     confess Dumper(\@_)." ?" if grep { !defined } @_;
 226     debugcmd "|",@_;
 227     open P, "-|", @_ or die "$_[0] $!";
 228     my $d;
 229     $!=0; $?=0;
 230     { local $/ = undef; $d = <P>; }
 231     die $! if P->error;
 232     if (!close P) { printdebug "=>!$?\n"; return undef; }
 233     chomp $d;
 234     if ($debuglevel > 0) {
 235         $d =~ m/^.*/;
 236         my $dd = $&;
 237         my $more = (length $' ? '...' : ''); #');
 238         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 239         printdebug "=> \`$dd'",$more,"\n";
 240     }
 241     return $d;
 242 }
 243
 244 sub cmdoutput {
 245     my $d = cmdoutput_errok @_;
 246     defined $d or failedcmd @_;
 247     return $d;
 248 }
 249
 250 sub link_ltarget ($$) {
 251     my ($old,$new) = @_;
 252     lstat $old or return undef;
 253     if (-l _) {
 254         $old = cmdoutput qw(realpath  --), $old;
 255     }
 256     link $old, $new or die "link $old $new: $!";
 257 }
 258
 259 sub hashfile ($) {
 260     my ($fn) = @_;
 261     my $h = Digest::SHA->new(256);
 262     $h->addfile($fn);
 263     return $h->hexdigest();
 264 }
 265
 266 sub git_rev_parse ($) {
 267     return cmdoutput qw(git rev-parse), "$_[0]~0";
 268 }
 269
 270 sub git_for_each_ref ($$;$) {
 271     my ($pattern,$func,$gitdir) = @_;
 272     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 273     # $reftail is RHS of ref after refs/[^/]+/
 274     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 275     # $pattern may be an array ref to mean multiple patterns
 276     $pattern = [ $pattern ] unless ref $pattern;
 277     my @cmd = (qw(git for-each-ref), @$pattern);
 278     if (defined $gitdir) {
 279         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 280     }
 281     open GFER, "-|", @cmd or die $!;
 282     debugcmd "|", @cmd;
 283     while (<GFER>) {
 284         chomp or die "$_ ?";
 285         printdebug "|> ", $_, "\n";
 286         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 287         $func->($1,$2,$3,$4);
 288     }
 289     $!=0; $?=0; close GFER or die "$pattern $? $!";
 290 }
 291
 292 sub git_get_ref ($) {
 293     # => '' if no such ref
 294     my ($refname) = @_;
 295     local $_ = $refname;
 296     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 297     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 298 }
 299
 300 sub git_for_each_tag_referring ($$) {
 301     my ($objreferring, $func) = @_;
 302     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 303     printdebug "git_for_each_tag_referring ",
 304         ($objreferring // 'UNDEF'),"\n";
 305     git_for_each_ref('refs/tags', sub {
 306         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 307         return unless $objtype eq 'tag';
 308         my $refobjid = git_rev_parse $tagobjid;
 309         return unless
 310             !defined $objreferring # caller wants them all
 311             or $tagobjid eq $objreferring
 312             or $refobjid eq $objreferring;
 313         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 314     });
 315 }
 316
 317 sub is_fast_fwd ($$) {
 318     my ($ancestor,$child) = @_;
 319     my @cmd = (qw(git merge-base), $ancestor, $child);
 320     my $mb = cmdoutput_errok @cmd;
 321     if (defined $mb) {
 322         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 323     } else {
 324         $?==256 or failedcmd @cmd;
 325         return 0;
 326     }
 327 }
 328
 329 1;