Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp;
   9 use POSIX;
  10 use IO::Handle;
  11 use Config;
  12 use Digest::SHA;
  13 use Data::Dumper;
  14
  15 BEGIN {
  16     use Exporter   ();
  17     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  18
  19     $VERSION     = 1.00;
  20     @ISA         = qw(Exporter);
  21     @EXPORT      = qw(setup_sigwarn
  22                       debiantag_old debiantag_new server_branch server_ref
  23                       stat_exists link_ltarget
  24                       hashfile
  25                       fail ensuredir executable_on_path
  26                       waitstatusmsg failedcmd
  27                       cmdoutput cmdoutput_errok
  28                       git_rev_parse git_get_ref git_for_each_ref
  29                       git_for_each_tag_referring is_fast_fwd
  30                       $package_re $component_re $deliberately_re
  31                       $branchprefix
  32                       initdebug enabledebug enabledebuglevel
  33                       printdebug debugcmd
  34                       $debugprefix *debuglevel *DEBUG
  35                       shellquote printcmd messagequote);
  36     # implicitly uses $main::us
  37     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  38     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  39 }
  40
  41 our @EXPORT_OK;
  42
  43 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  44 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  45 our $deliberately_re = "(?:TEST-)?$package_re";
  46 our $branchprefix = 'dgit';
  47
  48 # policy hook exit status bits
  49 # see dgit-repos-server head comment for documentation
  50 # 1 is reserved in case something fails with `exit 1' and to spot
  51 # dynamic loader, runtime, etc., failures, which report 127 or 255
  52 sub NOFFCHECK () { return 0x2; }
  53 sub FRESHREPO () { return 0x4; }
  54
  55 our $debugprefix;
  56 our $debuglevel = 0;
  57
  58 sub setup_sigwarn () {
  59     our $sigwarn_mainprocess = $$;
  60     $SIG{__WARN__} = sub {
  61         die $_[0] unless getppid == $sigwarn_mainprocess;
  62     };
  63 }
  64
  65 sub initdebug ($) {
  66     ($debugprefix) = @_;
  67     open DEBUG, ">/dev/null" or die $!;
  68 }
  69
  70 sub enabledebug () {
  71     open DEBUG, ">&STDERR" or die $!;
  72     DEBUG->autoflush(1);
  73     $debuglevel ||= 1;
  74 }
  75
  76 sub enabledebuglevel ($) {
  77     my ($newlevel) = @_; # may be undef (eg from env var)
  78     die if $debuglevel;
  79     $newlevel //= 0;
  80     $newlevel += 0;
  81     return unless $newlevel;
  82     $debuglevel = $newlevel;
  83     enabledebug();
  84 }
  85
  86 sub printdebug {
  87     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  88 }
  89
  90 sub messagequote ($) {
  91     local ($_) = @_;
  92     s{\\}{\\\\}g;
  93     s{\n}{\\n}g;
  94     s{\x08}{\\b}g;
  95     s{\t}{\\t}g;
  96     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  97     $_;
  98 }
  99
 100 sub shellquote {
 101     my @out;
 102     local $_;
 103     foreach my $a (@_) {
 104         $_ = $a;
 105         if (!length || m{[^-=_./:0-9a-z]}i) {
 106             s{['\\]}{'\\$&'}g;
 107             push @out, "'$_'";
 108         } else {
 109             push @out, $_;
 110         }
 111     }
 112     return join ' ', @out;
 113 }
 114
 115 sub printcmd {
 116     my $fh = shift @_;
 117     my $intro = shift @_;
 118     print $fh $intro," " or die $!;
 119     print $fh shellquote @_ or die $!;
 120     print $fh "\n" or die $!;
 121 }
 122
 123 sub debugcmd {
 124     my $extraprefix = shift @_;
 125     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 126 }
 127
 128 sub debiantag_old ($$) {
 129     my ($v,$distro) = @_;
 130     $v =~ y/~:/_%/;
 131     return "$distro/$v";
 132 }
 133
 134 sub debiantag_new ($$) {
 135     my ($v,$distro) = @_;
 136     $v =~ y/~:/_%/;
 137     return "archive/$distro/$v";
 138 }
 139
 140 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 141 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 142
 143 sub stat_exists ($) {
 144     my ($f) = @_;
 145     return 1 if stat $f;
 146     return 0 if $!==&ENOENT;
 147     die "stat $f: $!";
 148 }
 149
 150 sub _us () {
 151     $::us // ($0 =~ m#[^/]*$#, $&);
 152 }
 153
 154 sub fail {
 155     my $s = "@_\n";
 156     my $prefix = _us().": ";
 157     $s =~ s/^/$prefix/gm;
 158     die $s;
 159 }
 160
 161 sub ensuredir ($) {
 162     my ($dir) = @_; # does not create parents
 163     return if mkdir $dir;
 164     return if $! == EEXIST;
 165     die "mkdir $dir: $!";
 166 }
 167
 168 sub executable_on_path ($) {
 169     my ($program) = @_;
 170     return 1 if $program =~ m{/};
 171     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 172     foreach my $pe (@path) {
 173         my $here = "$pe/$program";
 174         return $here if stat_exists $here && -x _;
 175     }
 176     return undef;
 177 }
 178
 179 our @signames = split / /, $Config{sig_name};
 180
 181 sub waitstatusmsg () {
 182     if (!$?) {
 183         return "terminated, reporting successful completion";
 184     } elsif (!($? & 255)) {
 185         return "failed with error exit status ".WEXITSTATUS($?);
 186     } elsif (WIFSIGNALED($?)) {
 187         my $signum=WTERMSIG($?);
 188         return "died due to fatal signal ".
 189             ($signames[$signum] // "number $signum").
 190             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 191     } else {
 192         return "failed with unknown wait status ".$?;
 193     }
 194 }
 195
 196 sub failedcmd {
 197     # Expects $!,$? as set by close - see below.
 198     # To use with system(), set $?=-1 first.
 199     #
 200     # Actual behaviour of perl operations:
 201     #   success              $!==0       $?==0       close of piped open
 202     #   program failed       $!==0       $? >0       close of piped open
 203     #   syscall failure      $! >0       $?=-1       close of piped open
 204     #   failure              $! >0       unchanged   close of something else
 205     #   success              trashed     $?==0       system
 206     #   program failed       trashed     $? >0       system
 207     #   syscall failure      $! >0       unchanged   system
 208     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 209     if ($? < 0) {
 210         fail "failed to fork/exec: $!";
 211     } elsif ($?) {
 212         fail "subprocess ".waitstatusmsg();
 213     } else {
 214         fail "subprocess produced invalid output";
 215     }
 216 }
 217
 218 sub cmdoutput_errok {
 219     confess Dumper(\@_)." ?" if grep { !defined } @_;
 220     debugcmd "|",@_;
 221     open P, "-|", @_ or die "$_[0] $!";
 222     my $d;
 223     $!=0; $?=0;
 224     { local $/ = undef; $d = <P>; }
 225     die $! if P->error;
 226     if (!close P) { printdebug "=>!$?\n"; return undef; }
 227     chomp $d;
 228     if ($debuglevel > 0) {
 229         $d =~ m/^.*/;
 230         my $dd = $&;
 231         my $more = (length $' ? '...' : ''); #');
 232         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 233         printdebug "=> \`$dd'",$more,"\n";
 234     }
 235     return $d;
 236 }
 237
 238 sub cmdoutput {
 239     my $d = cmdoutput_errok @_;
 240     defined $d or failedcmd @_;
 241     return $d;
 242 }
 243
 244 sub link_ltarget ($$) {
 245     my ($old,$new) = @_;
 246     lstat $old or return undef;
 247     if (-l _) {
 248         $old = cmdoutput qw(realpath  --), $old;
 249     }
 250     link $old, $new or die "link $old $new: $!";
 251 }
 252
 253 sub hashfile ($) {
 254     my ($fn) = @_;
 255     my $h = Digest::SHA->new(256);
 256     $h->addfile($fn);
 257     return $h->hexdigest();
 258 }
 259
 260 sub git_rev_parse ($) {
 261     return cmdoutput qw(git rev-parse), "$_[0]~0";
 262 }
 263
 264 sub git_for_each_ref ($$;$) {
 265     my ($pattern,$func,$gitdir) = @_;
 266     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 267     # $reftail is RHS of ref after refs/[^/]+/
 268     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 269     # $pattern may be an array ref to mean multiple patterns
 270     $pattern = [ $pattern ] unless ref $pattern;
 271     my @cmd = (qw(git for-each-ref), @$pattern);
 272     if (defined $gitdir) {
 273         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 274     }
 275     open GFER, "-|", @cmd or die $!;
 276     debugcmd "|", @cmd;
 277     while (<GFER>) {
 278         chomp or die "$_ ?";
 279         printdebug "|> ", $_, "\n";
 280         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 281         $func->($1,$2,$3,$4);
 282     }
 283     $!=0; $?=0; close GFER or die "$pattern $? $!";
 284 }
 285
 286 sub git_get_ref ($) {
 287     # => '' if no such ref
 288     my ($refname) = @_;
 289     local $_ = $refname;
 290     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 291     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 292 }
 293
 294 sub git_for_each_tag_referring ($$) {
 295     my ($objreferring, $func) = @_;
 296     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 297     printdebug "git_for_each_tag_referring ",
 298         ($objreferring // 'UNDEF'),"\n";
 299     git_for_each_ref('refs/tags', sub {
 300         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 301         return unless $objtype eq 'tag';
 302         my $refobjid = git_rev_parse $tagobjid;
 303         return unless
 304             !defined $objreferring # caller wants them all
 305             or $tagobjid eq $objreferring
 306             or $refobjid eq $objreferring;
 307         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 308     });
 309 }
 310
 311 sub is_fast_fwd ($$) {
 312     my ($ancestor,$child) = @_;
 313     my @cmd = (qw(git merge-base), $ancestor, $child);
 314     my $mb = cmdoutput_errok @cmd;
 315     if (defined $mb) {
 316         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 317     } else {
 318         $?==256 or failedcmd @cmd;
 319         return 0;
 320     }
 321 }
 322
 323 1;