Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use Carp;
   9 use POSIX;
  10 use IO::Handle;
  11 use Config;
  12 use Digest::SHA;
  13 use Data::Dumper;
  14
  15 BEGIN {
  16     use Exporter   ();
  17     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  18
  19     $VERSION     = 1.00;
  20     @ISA         = qw(Exporter);
  21     @EXPORT      = qw(setup_sigwarn
  22                       debiantags debiantag_old debiantag_new
  23                       server_branch server_ref
  24                       stat_exists link_ltarget
  25                       hashfile
  26                       fail ensuredir executable_on_path
  27                       waitstatusmsg failedcmd
  28                       cmdoutput cmdoutput_errok
  29                       git_rev_parse git_get_ref git_for_each_ref
  30                       git_for_each_tag_referring is_fast_fwd
  31                       $package_re $component_re $deliberately_re
  32                       $branchprefix
  33                       initdebug enabledebug enabledebuglevel
  34                       printdebug debugcmd
  35                       $debugprefix *debuglevel *DEBUG
  36                       shellquote printcmd messagequote);
  37     # implicitly uses $main::us
  38     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  39     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  40 }
  41
  42 our @EXPORT_OK;
  43
  44 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  45 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  46 our $deliberately_re = "(?:TEST-)?$package_re";
  47 our $branchprefix = 'dgit';
  48
  49 # policy hook exit status bits
  50 # see dgit-repos-server head comment for documentation
  51 # 1 is reserved in case something fails with `exit 1' and to spot
  52 # dynamic loader, runtime, etc., failures, which report 127 or 255
  53 sub NOFFCHECK () { return 0x2; }
  54 sub FRESHREPO () { return 0x4; }
  55
  56 our $debugprefix;
  57 our $debuglevel = 0;
  58
  59 sub setup_sigwarn () {
  60     our $sigwarn_mainprocess = $$;
  61     $SIG{__WARN__} = sub {
  62         die $_[0] unless getppid == $sigwarn_mainprocess;
  63     };
  64 }
  65
  66 sub initdebug ($) {
  67     ($debugprefix) = @_;
  68     open DEBUG, ">/dev/null" or die $!;
  69 }
  70
  71 sub enabledebug () {
  72     open DEBUG, ">&STDERR" or die $!;
  73     DEBUG->autoflush(1);
  74     $debuglevel ||= 1;
  75 }
  76
  77 sub enabledebuglevel ($) {
  78     my ($newlevel) = @_; # may be undef (eg from env var)
  79     die if $debuglevel;
  80     $newlevel //= 0;
  81     $newlevel += 0;
  82     return unless $newlevel;
  83     $debuglevel = $newlevel;
  84     enabledebug();
  85 }
  86
  87 sub printdebug {
  88     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  89 }
  90
  91 sub messagequote ($) {
  92     local ($_) = @_;
  93     s{\\}{\\\\}g;
  94     s{\n}{\\n}g;
  95     s{\x08}{\\b}g;
  96     s{\t}{\\t}g;
  97     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  98     $_;
  99 }
 100
 101 sub shellquote {
 102     my @out;
 103     local $_;
 104     foreach my $a (@_) {
 105         $_ = $a;
 106         if (!length || m{[^-=_./:0-9a-z]}i) {
 107             s{['\\]}{'\\$&'}g;
 108             push @out, "'$_'";
 109         } else {
 110             push @out, $_;
 111         }
 112     }
 113     return join ' ', @out;
 114 }
 115
 116 sub printcmd {
 117     my $fh = shift @_;
 118     my $intro = shift @_;
 119     print $fh $intro," " or die $!;
 120     print $fh shellquote @_ or die $!;
 121     print $fh "\n" or die $!;
 122 }
 123
 124 sub debugcmd {
 125     my $extraprefix = shift @_;
 126     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 127 }
 128
 129 sub debiantag_old ($$) {
 130     my ($v,$distro) = @_;
 131     $v =~ y/~:/_%/;
 132     return "$distro/$v";
 133 }
 134
 135 sub debiantag_new ($$) {
 136     my ($v,$distro) = @_;
 137     $v =~ y/~:/_%/;
 138     return "archive/$distro/$v";
 139 }
 140
 141 sub debiantags ($$) {
 142     my ($version,$distro) = @_;
 143     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 144 }
 145
 146 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 147 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 148
 149 sub stat_exists ($) {
 150     my ($f) = @_;
 151     return 1 if stat $f;
 152     return 0 if $!==&ENOENT;
 153     die "stat $f: $!";
 154 }
 155
 156 sub _us () {
 157     $::us // ($0 =~ m#[^/]*$#, $&);
 158 }
 159
 160 sub fail {
 161     my $s = "@_\n";
 162     $s =~ s/\n\n$/\n/;
 163     my $prefix = _us().": ";
 164     $s =~ s/^/$prefix/gm;
 165     die $s;
 166 }
 167
 168 sub ensuredir ($) {
 169     my ($dir) = @_; # does not create parents
 170     return if mkdir $dir;
 171     return if $! == EEXIST;
 172     die "mkdir $dir: $!";
 173 }
 174
 175 sub executable_on_path ($) {
 176     my ($program) = @_;
 177     return 1 if $program =~ m{/};
 178     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 179     foreach my $pe (@path) {
 180         my $here = "$pe/$program";
 181         return $here if stat_exists $here && -x _;
 182     }
 183     return undef;
 184 }
 185
 186 our @signames = split / /, $Config{sig_name};
 187
 188 sub waitstatusmsg () {
 189     if (!$?) {
 190         return "terminated, reporting successful completion";
 191     } elsif (!($? & 255)) {
 192         return "failed with error exit status ".WEXITSTATUS($?);
 193     } elsif (WIFSIGNALED($?)) {
 194         my $signum=WTERMSIG($?);
 195         return "died due to fatal signal ".
 196             ($signames[$signum] // "number $signum").
 197             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 198     } else {
 199         return "failed with unknown wait status ".$?;
 200     }
 201 }
 202
 203 sub failedcmd {
 204     # Expects $!,$? as set by close - see below.
 205     # To use with system(), set $?=-1 first.
 206     #
 207     # Actual behaviour of perl operations:
 208     #   success              $!==0       $?==0       close of piped open
 209     #   program failed       $!==0       $? >0       close of piped open
 210     #   syscall failure      $! >0       $?=-1       close of piped open
 211     #   failure              $! >0       unchanged   close of something else
 212     #   success              trashed     $?==0       system
 213     #   program failed       trashed     $? >0       system
 214     #   syscall failure      $! >0       unchanged   system
 215     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 216     if ($? < 0) {
 217         fail "failed to fork/exec: $!";
 218     } elsif ($?) {
 219         fail "subprocess ".waitstatusmsg();
 220     } else {
 221         fail "subprocess produced invalid output";
 222     }
 223 }
 224
 225 sub cmdoutput_errok {
 226     confess Dumper(\@_)." ?" if grep { !defined } @_;
 227     debugcmd "|",@_;
 228     open P, "-|", @_ or die "$_[0] $!";
 229     my $d;
 230     $!=0; $?=0;
 231     { local $/ = undef; $d = <P>; }
 232     die $! if P->error;
 233     if (!close P) { printdebug "=>!$?\n"; return undef; }
 234     chomp $d;
 235     if ($debuglevel > 0) {
 236         $d =~ m/^.*/;
 237         my $dd = $&;
 238         my $more = (length $' ? '...' : ''); #');
 239         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 240         printdebug "=> \`$dd'",$more,"\n";
 241     }
 242     return $d;
 243 }
 244
 245 sub cmdoutput {
 246     my $d = cmdoutput_errok @_;
 247     defined $d or failedcmd @_;
 248     return $d;
 249 }
 250
 251 sub link_ltarget ($$) {
 252     my ($old,$new) = @_;
 253     lstat $old or return undef;
 254     if (-l _) {
 255         $old = cmdoutput qw(realpath  --), $old;
 256     }
 257     link $old, $new or die "link $old $new: $!";
 258 }
 259
 260 sub hashfile ($) {
 261     my ($fn) = @_;
 262     my $h = Digest::SHA->new(256);
 263     $h->addfile($fn);
 264     return $h->hexdigest();
 265 }
 266
 267 sub git_rev_parse ($) {
 268     return cmdoutput qw(git rev-parse), "$_[0]~0";
 269 }
 270
 271 sub git_for_each_ref ($$;$) {
 272     my ($pattern,$func,$gitdir) = @_;
 273     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 274     # $reftail is RHS of ref after refs/[^/]+/
 275     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 276     # $pattern may be an array ref to mean multiple patterns
 277     $pattern = [ $pattern ] unless ref $pattern;
 278     my @cmd = (qw(git for-each-ref), @$pattern);
 279     if (defined $gitdir) {
 280         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 281     }
 282     open GFER, "-|", @cmd or die $!;
 283     debugcmd "|", @cmd;
 284     while (<GFER>) {
 285         chomp or die "$_ ?";
 286         printdebug "|> ", $_, "\n";
 287         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 288         $func->($1,$2,$3,$4);
 289     }
 290     $!=0; $?=0; close GFER or die "$pattern $? $!";
 291 }
 292
 293 sub git_get_ref ($) {
 294     # => '' if no such ref
 295     my ($refname) = @_;
 296     local $_ = $refname;
 297     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 298     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 299 }
 300
 301 sub git_for_each_tag_referring ($$) {
 302     my ($objreferring, $func) = @_;
 303     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 304     printdebug "git_for_each_tag_referring ",
 305         ($objreferring // 'UNDEF'),"\n";
 306     git_for_each_ref('refs/tags', sub {
 307         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 308         return unless $objtype eq 'tag';
 309         my $refobjid = git_rev_parse $tagobjid;
 310         return unless
 311             !defined $objreferring # caller wants them all
 312             or $tagobjid eq $objreferring
 313             or $refobjid eq $objreferring;
 314         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 315     });
 316 }
 317
 318 sub is_fast_fwd ($$) {
 319     my ($ancestor,$child) = @_;
 320     my @cmd = (qw(git merge-base), $ancestor, $child);
 321     my $mb = cmdoutput_errok @cmd;
 322     if (defined $mb) {
 323         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 324     } else {
 325         $?==256 or failedcmd @cmd;
 326         return 0;
 327     }
 328 }
 329
 330 1;