Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31
  32 BEGIN {
  33     use Exporter   ();
  34     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  35
  36     $VERSION     = 1.00;
  37     @ISA         = qw(Exporter);
  38     @EXPORT      = qw(setup_sigwarn
  39                       debiantags debiantag_old debiantag_new
  40                       server_branch server_ref
  41                       stat_exists link_ltarget
  42                       hashfile
  43                       fail ensuredir executable_on_path
  44                       waitstatusmsg failedcmd_waitstatus
  45                       failedcmd_report_cmd failedcmd
  46                       cmdoutput cmdoutput_errok
  47                       git_rev_parse git_get_ref git_for_each_ref
  48                       git_for_each_tag_referring is_fast_fwd
  49                       $package_re $component_re $deliberately_re
  50                       $branchprefix
  51                       initdebug enabledebug enabledebuglevel
  52                       printdebug debugcmd
  53                       $debugprefix *debuglevel *DEBUG
  54                       shellquote printcmd messagequote);
  55     # implicitly uses $main::us
  56     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  57     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  58 }
  59
  60 our @EXPORT_OK;
  61
  62 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  63 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  64 our $deliberately_re = "(?:TEST-)?$package_re";
  65 our $branchprefix = 'dgit';
  66
  67 # policy hook exit status bits
  68 # see dgit-repos-server head comment for documentation
  69 # 1 is reserved in case something fails with `exit 1' and to spot
  70 # dynamic loader, runtime, etc., failures, which report 127 or 255
  71 sub NOFFCHECK () { return 0x2; }
  72 sub FRESHREPO () { return 0x4; }
  73
  74 our $debugprefix;
  75 our $debuglevel = 0;
  76
  77 sub setup_sigwarn () {
  78     our $sigwarn_mainprocess = $$;
  79     $SIG{__WARN__} = sub {
  80         die $_[0] unless getppid == $sigwarn_mainprocess;
  81     };
  82 }
  83
  84 sub initdebug ($) {
  85     ($debugprefix) = @_;
  86     open DEBUG, ">/dev/null" or die $!;
  87 }
  88
  89 sub enabledebug () {
  90     open DEBUG, ">&STDERR" or die $!;
  91     DEBUG->autoflush(1);
  92     $debuglevel ||= 1;
  93 }
  94
  95 sub enabledebuglevel ($) {
  96     my ($newlevel) = @_; # may be undef (eg from env var)
  97     die if $debuglevel;
  98     $newlevel //= 0;
  99     $newlevel += 0;
 100     return unless $newlevel;
 101     $debuglevel = $newlevel;
 102     enabledebug();
 103 }
 104
 105 sub printdebug {
 106     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 107 }
 108
 109 sub messagequote ($) {
 110     local ($_) = @_;
 111     s{\\}{\\\\}g;
 112     s{\n}{\\n}g;
 113     s{\x08}{\\b}g;
 114     s{\t}{\\t}g;
 115     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 116     $_;
 117 }
 118
 119 sub shellquote {
 120     my @out;
 121     local $_;
 122     foreach my $a (@_) {
 123         $_ = $a;
 124         if (!length || m{[^-=_./:0-9a-z]}i) {
 125             s{['\\]}{'\\$&'}g;
 126             push @out, "'$_'";
 127         } else {
 128             push @out, $_;
 129         }
 130     }
 131     return join ' ', @out;
 132 }
 133
 134 sub printcmd {
 135     my $fh = shift @_;
 136     my $intro = shift @_;
 137     print $fh $intro," " or die $!;
 138     print $fh shellquote @_ or die $!;
 139     print $fh "\n" or die $!;
 140 }
 141
 142 sub debugcmd {
 143     my $extraprefix = shift @_;
 144     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 145 }
 146
 147 sub debiantag_old ($$) {
 148     my ($v,$distro) = @_;
 149     $v =~ y/~:/_%/;
 150     return "$distro/$v";
 151 }
 152
 153 sub debiantag_new ($$) {
 154     my ($v,$distro) = @_;
 155     $v =~ y/~:/_%/;
 156     return "archive/$distro/$v";
 157 }
 158
 159 sub debiantags ($$) {
 160     my ($version,$distro) = @_;
 161     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 162 }
 163
 164 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 165 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 166
 167 sub stat_exists ($) {
 168     my ($f) = @_;
 169     return 1 if stat $f;
 170     return 0 if $!==&ENOENT;
 171     die "stat $f: $!";
 172 }
 173
 174 sub _us () {
 175     $::us // ($0 =~ m#[^/]*$#, $&);
 176 }
 177
 178 sub fail {
 179     my $s = "@_\n";
 180     $s =~ s/\n\n$/\n/;
 181     my $prefix = _us().": ";
 182     $s =~ s/^/$prefix/gm;
 183     die $s;
 184 }
 185
 186 sub ensuredir ($) {
 187     my ($dir) = @_; # does not create parents
 188     return if mkdir $dir;
 189     return if $! == EEXIST;
 190     die "mkdir $dir: $!";
 191 }
 192
 193 sub executable_on_path ($) {
 194     my ($program) = @_;
 195     return 1 if $program =~ m{/};
 196     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 197     foreach my $pe (@path) {
 198         my $here = "$pe/$program";
 199         return $here if stat_exists $here && -x _;
 200     }
 201     return undef;
 202 }
 203
 204 our @signames = split / /, $Config{sig_name};
 205
 206 sub waitstatusmsg () {
 207     if (!$?) {
 208         return "terminated, reporting successful completion";
 209     } elsif (!($? & 255)) {
 210         return "failed with error exit status ".WEXITSTATUS($?);
 211     } elsif (WIFSIGNALED($?)) {
 212         my $signum=WTERMSIG($?);
 213         return "died due to fatal signal ".
 214             ($signames[$signum] // "number $signum").
 215             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 216     } else {
 217         return "failed with unknown wait status ".$?;
 218     }
 219 }
 220
 221 sub failedcmd_report_cmd {
 222     my $intro = shift @_;
 223     $intro //= "failed command";
 224     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 225 }
 226
 227 sub failedcmd_waitstatus {
 228     if ($? < 0) {
 229         return "failed to fork/exec: $!";
 230     } elsif ($?) {
 231         return "subprocess ".waitstatusmsg();
 232     } else {
 233         return "subprocess produced invalid output";
 234     }
 235 }
 236
 237 sub failedcmd {
 238     # Expects $!,$? as set by close - see below.
 239     # To use with system(), set $?=-1 first.
 240     #
 241     # Actual behaviour of perl operations:
 242     #   success              $!==0       $?==0       close of piped open
 243     #   program failed       $!==0       $? >0       close of piped open
 244     #   syscall failure      $! >0       $?=-1       close of piped open
 245     #   failure              $! >0       unchanged   close of something else
 246     #   success              trashed     $?==0       system
 247     #   program failed       trashed     $? >0       system
 248     #   syscall failure      $! >0       unchanged   system
 249     failedcmd_report_cmd undef, @_;
 250     fail failedcmd_waitstatus();
 251 }
 252
 253 sub cmdoutput_errok {
 254     confess Dumper(\@_)." ?" if grep { !defined } @_;
 255     debugcmd "|",@_;
 256     open P, "-|", @_ or die "$_[0] $!";
 257     my $d;
 258     $!=0; $?=0;
 259     { local $/ = undef; $d = <P>; }
 260     die $! if P->error;
 261     if (!close P) { printdebug "=>!$?\n"; return undef; }
 262     chomp $d;
 263     if ($debuglevel > 0) {
 264         $d =~ m/^.*/;
 265         my $dd = $&;
 266         my $more = (length $' ? '...' : ''); #');
 267         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 268         printdebug "=> \`$dd'",$more,"\n";
 269     }
 270     return $d;
 271 }
 272
 273 sub cmdoutput {
 274     my $d = cmdoutput_errok @_;
 275     defined $d or failedcmd @_;
 276     return $d;
 277 }
 278
 279 sub link_ltarget ($$) {
 280     my ($old,$new) = @_;
 281     lstat $old or return undef;
 282     if (-l _) {
 283         $old = cmdoutput qw(realpath  --), $old;
 284     }
 285     link $old, $new or die "link $old $new: $!";
 286 }
 287
 288 sub hashfile ($) {
 289     my ($fn) = @_;
 290     my $h = Digest::SHA->new(256);
 291     $h->addfile($fn);
 292     return $h->hexdigest();
 293 }
 294
 295 sub git_rev_parse ($) {
 296     return cmdoutput qw(git rev-parse), "$_[0]~0";
 297 }
 298
 299 sub git_for_each_ref ($$;$) {
 300     my ($pattern,$func,$gitdir) = @_;
 301     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 302     # $reftail is RHS of ref after refs/[^/]+/
 303     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 304     # $pattern may be an array ref to mean multiple patterns
 305     $pattern = [ $pattern ] unless ref $pattern;
 306     my @cmd = (qw(git for-each-ref), @$pattern);
 307     if (defined $gitdir) {
 308         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 309     }
 310     open GFER, "-|", @cmd or die $!;
 311     debugcmd "|", @cmd;
 312     while (<GFER>) {
 313         chomp or die "$_ ?";
 314         printdebug "|> ", $_, "\n";
 315         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 316         $func->($1,$2,$3,$4);
 317     }
 318     $!=0; $?=0; close GFER or die "$pattern $? $!";
 319 }
 320
 321 sub git_get_ref ($) {
 322     # => '' if no such ref
 323     my ($refname) = @_;
 324     local $_ = $refname;
 325     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 326     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 327 }
 328
 329 sub git_for_each_tag_referring ($$) {
 330     my ($objreferring, $func) = @_;
 331     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 332     printdebug "git_for_each_tag_referring ",
 333         ($objreferring // 'UNDEF'),"\n";
 334     git_for_each_ref('refs/tags', sub {
 335         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 336         return unless $objtype eq 'tag';
 337         my $refobjid = git_rev_parse $tagobjid;
 338         return unless
 339             !defined $objreferring # caller wants them all
 340             or $tagobjid eq $objreferring
 341             or $refobjid eq $objreferring;
 342         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 343     });
 344 }
 345
 346 sub is_fast_fwd ($$) {
 347     my ($ancestor,$child) = @_;
 348     my @cmd = (qw(git merge-base), $ancestor, $child);
 349     my $mb = cmdoutput_errok @cmd;
 350     if (defined $mb) {
 351         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 352     } else {
 353         $?==256 or failedcmd @cmd;
 354         return 0;
 355     }
 356 }
 357
 358 1;