Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34 use Dpkg::Control::Hash;
  35 use Debian::Dgit::ExitStatus;
  36 use Debian::Dgit::I18n;
  37
  38 BEGIN {
  39     use Exporter   ();
  40     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  41
  42     $VERSION     = 1.00;
  43     @ISA         = qw(Exporter);
  44     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  45                       dep14_version_mangle
  46                       debiantags debiantag_old debiantag_new
  47                       debiantag_maintview
  48                       upstreamversion
  49                       stripepoch source_file_leafname is_orig_file_of_p_v
  50                       server_branch server_ref
  51                       stat_exists link_ltarget rename_link_xf
  52                       hashfile
  53                       fail failmsg ensuredir must_getcwd executable_on_path
  54                       waitstatusmsg failedcmd_waitstatus
  55                       failedcmd_report_cmd failedcmd
  56                       runcmd shell_cmd cmdoutput cmdoutput_errok
  57                       git_rev_parse changedir_git_toplevel git_cat_file
  58                       git_get_ref git_get_symref git_for_each_ref
  59                       git_for_each_tag_referring is_fast_fwd
  60                       git_check_unmodified
  61                       git_reflog_action_msg  git_update_ref_cmd
  62                       make_commit_text
  63                       reflog_cache_insert reflog_cache_lookup
  64                       $package_re $component_re $deliberately_re
  65                       $distro_re $versiontag_re $series_filename_re
  66                       $orig_f_comp_re $orig_f_sig_re $orig_f_tail_re
  67                       $extra_orig_namepart_re
  68                       $git_null_obj
  69                       $branchprefix
  70                       $ffq_refprefix $gdrlast_refprefix
  71                       initdebug enabledebug enabledebuglevel
  72                       printdebug debugcmd
  73                       $printdebug_when_debuglevel $debugcmd_when_debuglevel
  74                       $debugprefix *debuglevel *DEBUG
  75                       shellquote printcmd messagequote
  76                       $negate_harmful_gitattrs
  77                       changedir git_slurp_config_src
  78                       gdr_ffq_prev_branchinfo
  79                       parsecontrolfh parsecontrol parsechangelog
  80                       getfield parsechangelog_loop
  81                       playtree_setup);
  82     # implicitly uses $main::us
  83     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  84                      playground => [qw(record_maindir $maindir $local_git_cfg
  85                                        $maindir_gitdir $maindir_gitcommon
  86                                        fresh_playground
  87                                        ensure_a_playground)]);
  88     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  89                      @{ $EXPORT_TAGS{playground} } );
  90 }
  91
  92 our @EXPORT_OK;
  93
  94 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  95 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  96 our $deliberately_re = "(?:TEST-)?$package_re";
  97 our $distro_re = $component_re;
  98 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  99 our $branchprefix = 'dgit';
 100 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
 101 our $extra_orig_namepart_re = qr{[-0-9a-zA-Z]+};
 102 our $orig_f_comp_re = qr{orig(?:-$extra_orig_namepart_re)?};
 103 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
 104 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
 105 our $git_null_obj = '0' x 40;
 106 our $ffq_refprefix = 'ffq-prev';
 107 our $gdrlast_refprefix = 'debrebase-last';
 108 our $printdebug_when_debuglevel = 1;
 109 our $debugcmd_when_debuglevel = 1;
 110
 111 # these three all go together, only valid after record_maindir
 112 our $maindir;
 113 our $maindir_gitdir;
 114 our $maindir_gitcommon;
 115
 116 # policy hook exit status bits
 117 # see dgit-repos-server head comment for documentation
 118 # 1 is reserved in case something fails with `exit 1' and to spot
 119 # dynamic loader, runtime, etc., failures, which report 127 or 255
 120 sub NOFFCHECK () { return 0x2; }
 121 sub FRESHREPO () { return 0x4; }
 122 sub NOCOMMITCHECK () { return 0x8; }
 123
 124 our $debugprefix;
 125 our $debuglevel = 0;
 126
 127 our $negate_harmful_gitattrs =
 128     "-text -eol -crlf -ident -filter -working-tree-encoding";
 129     # ^ when updating this, alter the regexp in dgit:is_gitattrs_setup
 130
 131 our $forkcheck_mainprocess;
 132
 133 sub forkcheck_setup () {
 134     $forkcheck_mainprocess = $$;
 135 }
 136
 137 sub forkcheck_mainprocess () {
 138     # You must have called forkcheck_setup or setup_sigwarn already
 139     getppid != $forkcheck_mainprocess;
 140 }
 141
 142 sub setup_sigwarn () {
 143     forkcheck_setup();
 144     $SIG{__WARN__} = sub {
 145         confess $_[0] if forkcheck_mainprocess;
 146     };
 147 }
 148
 149 sub initdebug ($) {
 150     ($debugprefix) = @_;
 151     open DEBUG, ">/dev/null" or confess $!;
 152 }
 153
 154 sub enabledebug () {
 155     open DEBUG, ">&STDERR" or confess $!;
 156     DEBUG->autoflush(1);
 157     $debuglevel ||= 1;
 158 }
 159
 160 sub enabledebuglevel ($) {
 161     my ($newlevel) = @_; # may be undef (eg from env var)
 162     confess if $debuglevel;
 163     $newlevel //= 0;
 164     $newlevel += 0;
 165     return unless $newlevel;
 166     $debuglevel = $newlevel;
 167     enabledebug();
 168 }
 169
 170 sub printdebug {
 171     # Prints a prefix, and @_, to DEBUG.  @_ should normally contain
 172     # a trailing \n.
 173
 174     # With no (or only empty) arguments just prints the prefix and
 175     # leaves the caller to do more with DEBUG.  The caller should make
 176     # sure then to call printdebug with something ending in "\n" to
 177     # get the prefix right in subsequent calls.
 178
 179     return unless $debuglevel >= $printdebug_when_debuglevel;
 180     our $printdebug_noprefix;
 181     print DEBUG $debugprefix unless $printdebug_noprefix;
 182     pop @_ while @_ and !length $_[-1];
 183     return unless @_;
 184     print DEBUG @_ or confess $!;
 185     $printdebug_noprefix = $_[-1] !~ m{\n$};
 186 }
 187
 188 sub messagequote ($) {
 189     local ($_) = @_;
 190     s{\\}{\\\\}g;
 191     s{\n}{\\n}g;
 192     s{\x08}{\\b}g;
 193     s{\t}{\\t}g;
 194     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 195     $_;
 196 }
 197
 198 sub shellquote {
 199     my @out;
 200     local $_;
 201     defined or confess __ 'internal error' foreach @_;
 202     foreach my $a (@_) {
 203         $_ = $a;
 204         if (!length || m{[^-=_./:0-9a-z]}i) {
 205             s{['\\]}{'\\$&'}g;
 206             push @out, "'$_'";
 207         } else {
 208             push @out, $_;
 209         }
 210     }
 211     return join ' ', @out;
 212 }
 213
 214 sub printcmd {
 215     my $fh = shift @_;
 216     my $intro = shift @_;
 217     print $fh $intro," " or confess $!;
 218     print $fh shellquote @_ or confess $!;
 219     print $fh "\n" or confess $!;
 220 }
 221
 222 sub debugcmd {
 223     my $extraprefix = shift @_;
 224     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_)
 225         if $debuglevel >= $debugcmd_when_debuglevel;
 226 }
 227
 228 sub dep14_version_mangle ($) {
 229     my ($v) = @_;
 230     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 231     $v =~ y/~:/_%/;
 232     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 233     return $v;
 234 }
 235
 236 sub debiantag_old ($$) {
 237     my ($v,$distro) = @_;
 238     return "$distro/". dep14_version_mangle $v;
 239 }
 240
 241 sub debiantag_new ($$) {
 242     my ($v,$distro) = @_;
 243     return "archive/$distro/".dep14_version_mangle $v;
 244 }
 245
 246 sub debiantag_maintview ($$) {
 247     my ($v,$distro) = @_;
 248     return "$distro/".dep14_version_mangle $v;
 249 }
 250
 251 sub debiantags ($$) {
 252     my ($version,$distro) = @_;
 253     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 254 }
 255
 256 sub stripepoch ($) {
 257     my ($vsn) = @_;
 258     $vsn =~ s/^\d+\://;
 259     return $vsn;
 260 }
 261
 262 sub upstreamversion ($) {
 263     my ($vsn) = @_;
 264     $vsn =~ s/-[^-]+$//;
 265     return $vsn;
 266 }
 267
 268 sub source_file_leafname ($$$) {
 269     my ($package,$vsn,$sfx) = @_;
 270     return "${package}_".(stripepoch $vsn).$sfx
 271 }
 272
 273 sub is_orig_file_of_p_v ($$$) {
 274     my ($f, $package, $upstreamvsn) = @_;
 275     my $base = source_file_leafname $package, $upstreamvsn, '';
 276     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
 277     return 1;
 278 }
 279
 280 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 281 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 282
 283 sub stat_exists ($) {
 284     my ($f) = @_;
 285     return 1 if stat $f;
 286     return 0 if $!==&ENOENT;
 287     confess "stat $f: $!";
 288 }
 289
 290 sub _us () {
 291     $::us // ($0 =~ m#[^/]*$#, $&);
 292 }
 293
 294 sub failmsg {
 295     my $s = f_ "error: %s\n", "@_";
 296     $s =~ s/\n\n$/\n/g;
 297     my $prefix = _us().": ";
 298     $s =~ s/^/$prefix/gm;
 299     return "\n".$s;
 300 }
 301
 302 sub fail {
 303     die failmsg @_;
 304 }
 305
 306 sub ensuredir ($) {
 307     my ($dir) = @_; # does not create parents
 308     return if mkdir $dir;
 309     return if $! == EEXIST;
 310     confess "mkdir $dir: $!";
 311 }
 312
 313 sub must_getcwd () {
 314     my $d = getcwd();
 315     defined $d or fail f_ "getcwd failed: %s\n", $!;
 316     return $d;
 317 }
 318
 319 sub executable_on_path ($) {
 320     my ($program) = @_;
 321     return 1 if $program =~ m{/};
 322     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 323     foreach my $pe (@path) {
 324         my $here = "$pe/$program";
 325         return $here if stat_exists $here && -x _;
 326     }
 327     return undef;
 328 }
 329
 330 our @signames = split / /, $Config{sig_name};
 331
 332 sub waitstatusmsg () {
 333     if (!$?) {
 334         return __ "terminated, reporting successful completion";
 335     } elsif (!($? & 255)) {
 336         return f_ "failed with error exit status %s", WEXITSTATUS($?);
 337     } elsif (WIFSIGNALED($?)) {
 338         my $signum=WTERMSIG($?);
 339         return f_ "died due to fatal signal %s",
 340             ($signames[$signum] // "number $signum").
 341             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 342     } else {
 343         return f_ "failed with unknown wait status %s", $?;
 344     }
 345 }
 346
 347 sub failedcmd_report_cmd {
 348     my $intro = shift @_;
 349     $intro //= __ "failed command";
 350     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or confess $!; };
 351 }
 352
 353 sub failedcmd_waitstatus {
 354     if ($? < 0) {
 355         return f_ "failed to fork/exec: %s", $!;
 356     } elsif ($?) {
 357         return f_ "subprocess %s", waitstatusmsg();
 358     } else {
 359         return __ "subprocess produced invalid output";
 360     }
 361 }
 362
 363 sub failedcmd {
 364     # Expects $!,$? as set by close - see below.
 365     # To use with system(), set $?=-1 first.
 366     #
 367     # Actual behaviour of perl operations:
 368     #   success              $!==0       $?==0       close of piped open
 369     #   program failed       $!==0       $? >0       close of piped open
 370     #   syscall failure      $! >0       $?=-1       close of piped open
 371     #   failure              $! >0       unchanged   close of something else
 372     #   success              trashed     $?==0       system
 373     #   program failed       trashed     $? >0       system
 374     #   syscall failure      $! >0       unchanged   system
 375     failedcmd_report_cmd undef, @_;
 376     fail failedcmd_waitstatus();
 377 }
 378
 379 sub runcmd {
 380     debugcmd "+",@_;
 381     $!=0; $?=-1;
 382     failedcmd @_ if system @_;
 383 }
 384
 385 sub shell_cmd {
 386     my ($first_shell, @cmd) = @_;
 387     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 388 }
 389
 390 sub cmdoutput_errok {
 391     confess Dumper(\@_)." ?" if grep { !defined } @_;
 392     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 393     debugcmd "|",@_;
 394     open P, "-|", @_ or confess "$_[0] $!";
 395     my $d;
 396     $!=0; $?=0;
 397     { local $/ = undef; $d = <P>; }
 398     confess $! if P->error;
 399     if (!close P) { printdebug "=>!$?\n"; return undef; }
 400     chomp $d;
 401     if ($debuglevel > 0) {
 402         $d =~ m/^.*/;
 403         my $dd = $&;
 404         my $more = (length $' ? '...' : ''); #');
 405         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 406         printdebug "=> \`$dd'",$more,"\n";
 407     }
 408     return $d;
 409 }
 410
 411 sub cmdoutput {
 412     my $d = cmdoutput_errok @_;
 413     defined $d or failedcmd @_;
 414     return $d;
 415 }
 416
 417 sub link_ltarget ($$) {
 418     my ($old,$new) = @_;
 419     lstat $old or return undef;
 420     if (-l _) {
 421         $old = cmdoutput qw(realpath  --), $old;
 422     }
 423     my $r = link $old, $new;
 424     $r = symlink $old, $new if !$r && $!==EXDEV;
 425     $r or fail "(sym)link $old $new: $!\n";
 426 }
 427
 428 sub rename_link_xf ($$$) {
 429     # renames/moves or links/copies $src to $dst,
 430     # even if $dst is on a different fs
 431     # (May use the filename "$dst.tmp".);
 432     # On success, returns true.
 433     # On failure, returns false and sets
 434     #    $@ to a reason message
 435     #    $! to an errno value, or -1 if not known
 436     # having possibly printed something about mv to stderr.
 437     # Not safe to use without $keeporig if $dst might be a symlink
 438     # to $src, as it might delete $src leaving $dst invalid.
 439     my ($keeporig,$src,$dst) = @_;
 440     if ($keeporig
 441         ? link   $src, $dst
 442         : rename $src, $dst) {
 443         return 1;
 444     }
 445     if ($! != EXDEV) {
 446         $@ = "$!";
 447         return 0;
 448     }
 449     if (!stat $src) {
 450         $@ = f_ "stat source file: %S", $!;
 451         return 0;
 452     }
 453     my @src_stat = (stat _)[0..1];
 454
 455     my @dst_stat;
 456     if (stat $dst) {
 457         @dst_stat = (stat _)[0..1];
 458     } elsif ($! == ENOENT) {
 459     } else {
 460         $@ = f_ "stat destination file: %S", $!;
 461         return 0;
 462     }
 463
 464     if ("@src_stat" eq "@dst_stat") {
 465         # (Symlinks to) the same file.  No need for a copy but
 466         # we may need to delete the original.
 467         printdebug "rename_link_xf $keeporig $src $dst EXDEV but same\n";
 468     } else {
 469         $!=0; $?=0;
 470         my @cmd = (qw(cp --), $src, "$dst.tmp");
 471         debugcmd '+',@cmd;
 472         if (system @cmd) {
 473             failedcmd_report_cmd undef, @cmd;
 474             $@ = failedcmd_waitstatus();
 475             $! = -1;
 476             return 0;
 477         }
 478         if (!rename "$dst.tmp", $dst) {
 479             $@ = f_ "finally install file after cp: %S", $!;
 480             return 0;
 481         }
 482     }
 483     if (!$keeporig) {
 484         if (!unlink $src) {
 485             $@ = f_ "delete old file after cp: %S", $!;
 486             return 0;
 487         }
 488     }
 489     return 1;
 490 }
 491
 492 sub hashfile ($) {
 493     my ($fn) = @_;
 494     my $h = Digest::SHA->new(256);
 495     $h->addfile($fn);
 496     return $h->hexdigest();
 497 }
 498
 499 sub git_rev_parse ($) {
 500     return cmdoutput qw(git rev-parse), "$_[0]~0";
 501 }
 502
 503 sub changedir_git_toplevel () {
 504     my $toplevel = cmdoutput qw(git rev-parse --show-toplevel);
 505     length $toplevel or fail __ <<END;
 506 not in a git working tree?
 507 (git rev-parse --show-toplevel produced no output)
 508 END
 509     chdir $toplevel or fail f_ "chdir toplevel %s: %s\n", $toplevel, $!;
 510 }
 511
 512 sub git_cat_file ($;$) {
 513     my ($objname, $etype) = @_;
 514     # => ($type, $data) or ('missing', undef)
 515     # in scalar context, just the data
 516     # if $etype defined, dies unless type is $etype or in @$etype
 517     our ($gcf_pid, $gcf_i, $gcf_o);
 518     local $printdebug_when_debuglevel = $debugcmd_when_debuglevel;
 519     my $chk = sub {
 520         my ($gtype, $data) = @_;
 521         if ($etype) {
 522             $etype = [$etype] unless ref $etype;
 523             confess "$objname expected @$etype but is $gtype"
 524                 unless grep { $gtype eq $_ } @$etype;
 525         }
 526         return ($gtype, $data);
 527     };
 528     if (!$gcf_pid) {
 529         my @cmd = qw(git cat-file --batch);
 530         debugcmd "GCF|", @cmd;
 531         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or confess $!;
 532     }
 533     printdebug "GCF>| $objname\n";
 534     print $gcf_i $objname, "\n" or confess $!;
 535     my $x = <$gcf_o>;
 536     printdebug "GCF<| ", $x;
 537     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 538     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or confess "$objname ?";
 539     my $data;
 540     (read $gcf_o, $data, $size) == $size or confess "$objname $!";
 541     $x = <$gcf_o>;
 542     $x eq "\n" or confess "$objname ($_) $!";
 543     return $chk->($type, $data);
 544 }
 545
 546 sub git_get_symref (;$) {
 547     my ($symref) = @_;  $symref //= 'HEAD';
 548     # => undef if not a symref, otherwise refs/...
 549     my @cmd = (qw(git symbolic-ref -q HEAD));
 550     my $branch = cmdoutput_errok @cmd;
 551     if (!defined $branch) {
 552         $?==256 or failedcmd @cmd;
 553     } else {
 554         chomp $branch;
 555     }
 556     return $branch;
 557 }
 558
 559 sub git_for_each_ref ($$;$) {
 560     my ($pattern,$func,$gitdir) = @_;
 561     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 562     # $reftail is RHS of ref after refs/[^/]+/
 563     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 564     # $pattern may be an array ref to mean multiple patterns
 565     $pattern = [ $pattern ] unless ref $pattern;
 566     my @cmd = (qw(git for-each-ref), @$pattern);
 567     if (defined $gitdir) {
 568         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 569     }
 570     open GFER, "-|", @cmd or confess $!;
 571     debugcmd "|", @cmd;
 572     while (<GFER>) {
 573         chomp or confess "$_ ?";
 574         printdebug "|> ", $_, "\n";
 575         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or confess "$_ ?";
 576         $func->($1,$2,$3,$4);
 577     }
 578     $!=0; $?=0; close GFER or confess "$pattern $? $!";
 579 }
 580
 581 sub git_get_ref ($) {
 582     # => '' if no such ref
 583     my ($refname) = @_;
 584     local $_ = $refname;
 585     s{^refs/}{[r]efs/} or confess "$refname $_ ?";
 586     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 587 }
 588
 589 sub git_for_each_tag_referring ($$) {
 590     my ($objreferring, $func) = @_;
 591     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 592     printdebug "git_for_each_tag_referring ",
 593         ($objreferring // 'UNDEF'),"\n";
 594     git_for_each_ref('refs/tags', sub {
 595         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 596         return unless $objtype eq 'tag';
 597         my $refobjid = git_rev_parse $tagobjid;
 598         return unless
 599             !defined $objreferring # caller wants them all
 600             or $tagobjid eq $objreferring
 601             or $refobjid eq $objreferring;
 602         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 603     });
 604 }
 605
 606 sub git_check_unmodified () {
 607     foreach my $cached (qw(0 1)) {
 608         my @cmd = qw(git diff --quiet);
 609         push @cmd, qw(--cached) if $cached;
 610         push @cmd, qw(HEAD);
 611         debugcmd "+",@cmd;
 612         $!=0; $?=-1; system @cmd;
 613         return if !$?;
 614         if ($?==256) {
 615             fail
 616                 $cached
 617                 ? __ "git index contains changes (does not match HEAD)"
 618                 : __ "working tree is dirty (does not match HEAD)";
 619         } else {
 620             failedcmd @cmd;
 621         }
 622     }
 623 }
 624
 625 sub is_fast_fwd ($$) {
 626     my ($ancestor,$child) = @_;
 627     my @cmd = (qw(git merge-base), $ancestor, $child);
 628     my $mb = cmdoutput_errok @cmd;
 629     if (defined $mb) {
 630         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 631     } else {
 632         $?==256 or failedcmd @cmd;
 633         return 0;
 634     }
 635 }
 636
 637 sub git_reflog_action_msg ($) {
 638     my ($msg) = @_;
 639     my $rla = $ENV{GIT_REFLOG_ACTION};
 640     $msg = "$rla: $msg" if length $rla;
 641     return $msg;
 642 }
 643
 644 sub git_update_ref_cmd {
 645     # returns  qw(git update-ref), qw(-m), @_
 646     # except that message may be modified to honour GIT_REFLOG_ACTION
 647     my $msg = shift @_;
 648     $msg = git_reflog_action_msg $msg;
 649     return qw(git update-ref -m), $msg, @_;
 650 }
 651
 652 sub changedir ($) {
 653     my ($newdir) = @_;
 654     printdebug "CD $newdir\n";
 655     chdir $newdir or confess "chdir: $newdir: $!";
 656 }
 657
 658 sub git_slurp_config_src ($) {
 659     my ($src) = @_;
 660     # returns $r such that $r->{KEY}[] = VALUE
 661     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 662     debugcmd "|",@cmd;
 663
 664     local ($debuglevel) = $debuglevel-2;
 665     local $/="\0";
 666
 667     my $r = { };
 668     open GITS, "-|", @cmd or confess $!;
 669     while (<GITS>) {
 670         chomp or confess;
 671         printdebug "=> ", (messagequote $_), "\n";
 672         m/\n/ or confess "$_ ?";
 673         push @{ $r->{$`} }, $'; #';
 674     }
 675     $!=0; $?=0;
 676     close GITS
 677         or ($!==0 && $?==256)
 678         or failedcmd @cmd;
 679     return $r;
 680 }
 681
 682 sub gdr_ffq_prev_branchinfo ($) {
 683     my ($symref) = @_;
 684     # => ('status', "message", [$symref, $ffq_prev, $gdrlast])
 685     # 'status' may be
 686     #    branch         message is undef
 687     #    weird-symref   } no $symref,
 688     #    notbranch      }  no $ffq_prev
 689     return ('detached', __ 'detached HEAD') unless defined $symref;
 690     return ('weird-symref', __ 'HEAD symref is not to refs/')
 691         unless $symref =~ m{^refs/};
 692     my $ffq_prev = "refs/$ffq_refprefix/$'";
 693     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 694     printdebug "ffq_prev_branchinfo branch current $symref\n";
 695     return ('branch', undef, $symref, $ffq_prev, $gdrlast);
 696 }
 697
 698 sub parsecontrolfh ($$;$) {
 699     my ($fh, $desc, $allowsigned) = @_;
 700     our $dpkgcontrolhash_noissigned;
 701     my $c;
 702     for (;;) {
 703         my %opts = ('name' => $desc);
 704         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 705         $c = Dpkg::Control::Hash->new(%opts);
 706         $c->parse($fh,$desc) or fail f_ "parsing of %s failed", $desc;
 707         last if $allowsigned;
 708         last if $dpkgcontrolhash_noissigned;
 709         my $issigned= $c->get_option('is_pgp_signed');
 710         if (!defined $issigned) {
 711             $dpkgcontrolhash_noissigned= 1;
 712             seek $fh, 0,0 or confess "seek $desc: $!";
 713         } elsif ($issigned) {
 714             fail f_
 715                 "control file %s is (already) PGP-signed. ".
 716                 " Note that dgit push needs to modify the .dsc and then".
 717                 " do the signature itself",
 718                 $desc;
 719         } else {
 720             last;
 721         }
 722     }
 723     return $c;
 724 }
 725
 726 sub parsecontrol {
 727     my ($file, $desc, $allowsigned) = @_;
 728     my $fh = new IO::Handle;
 729     open $fh, '<', $file or fail f_ "open %s (%s): %s", $file, $desc, $!;
 730     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 731     $fh->error and confess $!;
 732     close $fh;
 733     return $c;
 734 }
 735
 736 sub parsechangelog {
 737     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 738     my $p = new IO::Handle;
 739     my @cmd = (qw(dpkg-parsechangelog), @_);
 740     open $p, '-|', @cmd or confess $!;
 741     $c->parse($p);
 742     $?=0; $!=0; close $p or failedcmd @cmd;
 743     return $c;
 744 }
 745
 746 sub getfield ($$) {
 747     my ($dctrl,$field) = @_;
 748     my $v = $dctrl->{$field};
 749     return $v if defined $v;
 750     fail f_ "missing field %s in %s", $field, $dctrl->get_option('name');
 751 }
 752
 753 sub parsechangelog_loop ($$$) {
 754     my ($clogcmd, $descbase, $fn) = @_;
 755     # @$clogcmd is qw(dpkg-parsechangelog ...some...options...)
 756     # calls $fn->($thisstanza, $desc);
 757     debugcmd "|",@$clogcmd;
 758     open CLOGS, "-|", @$clogcmd or confess $!;
 759     for (;;) {
 760         my $stanzatext = do { local $/=""; <CLOGS>; };
 761         printdebug "clogp stanza ".Dumper($stanzatext) if $debuglevel>1;
 762         last if !defined $stanzatext;
 763
 764         my $desc = "$descbase, entry no.$.";
 765         open my $stanzafh, "<", \$stanzatext or confess;
 766         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
 767
 768         $fn->($thisstanza, $desc);
 769     }
 770     confess $! if CLOGS->error;
 771     close CLOGS or $?==SIGPIPE or failedcmd @$clogcmd;
 772 }
 773
 774 sub make_commit_text ($) {
 775     my ($text) = @_;
 776     my ($out, $in);
 777     my @cmd = (qw(git hash-object -w -t commit --stdin));
 778     debugcmd "|",@cmd;
 779     print Dumper($text) if $debuglevel > 1;
 780     my $child = open2($out, $in, @cmd) or confess $!;
 781     my $h;
 782     eval {
 783         print $in $text or confess $!;
 784         close $in or confess $!;
 785         $h = <$out>;
 786         $h =~ m/^\w+$/ or confess;
 787         $h = $&;
 788         printdebug "=> $h\n";
 789     };
 790     close $out;
 791     waitpid $child, 0 == $child or confess "$child $!";
 792     $? and failedcmd @cmd;
 793     return $h;
 794 }
 795
 796 sub reflog_cache_insert ($$$) {
 797     my ($ref, $cachekey, $value) = @_;
 798     # you must call this in $maindir
 799     # you must have called record_maindir
 800
 801     # When we no longer need to support squeeze, use --create-reflog
 802     # instead of this:
 803     my $parent = $ref; $parent =~ s{/[^/]+$}{};
 804     ensuredir "$maindir_gitcommon/logs/$parent";
 805     my $makelogfh = new IO::File "$maindir_gitcommon/logs/$ref", '>>'
 806       or confess $!;
 807
 808     my $oldcache = git_get_ref $ref;
 809
 810     if ($oldcache eq $value) {
 811         my $tree = cmdoutput qw(git rev-parse), "$value:";
 812         # git update-ref doesn't always update, in this case.  *sigh*
 813         my $authline = (ucfirst _us()).
 814             ' <'._us().'@example.com> 1000000000 +0000';
 815         my $dummy = make_commit_text <<ENDU.(__ <<END);
 816 tree $tree
 817 parent $value
 818 author $authline
 819 committer $authline
 820
 821 ENDU
 822 Dummy commit - do not use
 823 END
 824         runcmd qw(git update-ref -m), _us()." - dummy", $ref, $dummy;
 825     }
 826     runcmd qw(git update-ref -m), $cachekey, $ref, $value;
 827 }
 828
 829 sub reflog_cache_lookup ($$) {
 830     my ($ref, $cachekey) = @_;
 831     # you may call this in $maindir or in a playtree
 832     # you must have called record_maindir
 833     my @cmd = (qw(git log -g), '--pretty=format:%H %gs', $ref);
 834     debugcmd "|(probably)",@cmd;
 835     my $child = open GC, "-|";  defined $child or confess $!;
 836     if (!$child) {
 837         chdir $maindir or confess $!;
 838         if (!stat "$maindir_gitcommon/logs/$ref") {
 839             $! == ENOENT or confess $!;
 840             printdebug ">(no reflog)\n";
 841             finish 0;
 842         }
 843         exec @cmd; die f_ "exec %s: %s\n", $cmd[0], $!;
 844     }
 845     while (<GC>) {
 846         chomp;
 847         printdebug ">| ", $_, "\n" if $debuglevel > 1;
 848         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $cachekey;
 849         close GC;
 850         return $1;
 851     }
 852     confess $! if GC->error;
 853     failedcmd unless close GC;
 854     return undef;
 855 }
 856
 857 # ========== playground handling ==========
 858
 859 # terminology:
 860 #
 861 #   $maindir      user's git working tree
 862 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 863 #   playtree      git working tree sharing object store with the user's
 864 #                 inside playground, or identical to it
 865 #
 866 # other globals
 867 #
 868 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 869 #
 870 # expected calling pattern
 871 #
 872 #  firstly
 873 #
 874 #    [record_maindir]
 875 #      must be run in directory containing .git
 876 #      assigns to $maindir if not already set
 877 #      also calls git_slurp_config_src to record git config
 878 #        in $local_git_cfg, unless it's already set
 879 #
 880 #    fresh_playground SUBDIR_PATH_COMPONENTS
 881 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 882 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 883 #      calls record_maindir
 884 #      sets up a new playground (destroying any old one)
 885 #      returns playground pathname
 886 #      caller may call multiple times with different subdir paths
 887 #       createing different playgrounds
 888 #
 889 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 890 #      like fresh_playground except:
 891 #      merely ensures the directory exists; does not delete an existing one
 892 #
 893 #  then can use
 894 #
 895 #    changedir playground
 896 #    changedir $maindir
 897 #
 898 #    playtree_setup $local_git_cfg
 899 #            # ^ call in some (perhaps trivial) subdir of playground
 900 #
 901 #    rmtree playground
 902
 903 # ----- maindir -----
 904
 905 our $local_git_cfg;
 906
 907 sub record_maindir () {
 908     if (!defined $maindir) {
 909         $maindir = must_getcwd();
 910         if (!stat "$maindir/.git") {
 911             fail f_ "cannot stat %s/.git: %s", $maindir, $!;
 912         }
 913         if (-d _) {
 914             # we fall back to this in case we have a pre-worktree
 915             # git, which may not know git rev-parse --git-common-dir
 916             $maindir_gitdir    = "$maindir/.git";
 917             $maindir_gitcommon = "$maindir/.git";
 918         } else {
 919             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 920             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 921         }
 922     }
 923     $local_git_cfg //= git_slurp_config_src 'local';
 924 }
 925
 926 # ----- playgrounds -----
 927
 928 sub ensure_a_playground_parent ($) {
 929     my ($spc) = @_;
 930     record_maindir();
 931     $spc = "$maindir_gitdir/$spc";
 932     my $parent = dirname $spc;
 933     mkdir $parent or $!==EEXIST or fail f_
 934         "failed to mkdir playground parent %s: %s", $parent, $!;
 935     return $spc;
 936 }
 937
 938 sub ensure_a_playground ($) {
 939     my ($spc) = @_;
 940     $spc = ensure_a_playground_parent $spc;
 941     mkdir $spc or $!==EEXIST or fail f_
 942         "failed to mkdir a playground %s: %s", $spc, $!;
 943     return $spc;
 944 }
 945
 946 sub fresh_playground ($) {
 947     my ($spc) = @_;
 948     $spc = ensure_a_playground_parent $spc;
 949     rmtree $spc;
 950     mkdir $spc or fail f_
 951         "failed to mkdir the playground %s: %s", $spc, $!;
 952     return $spc;
 953 }
 954
 955 # ----- playtrees -----
 956
 957 sub playtree_setup (;$) {
 958     my ($t_local_git_cfg) = @_;
 959     $t_local_git_cfg //= $local_git_cfg;
 960     # for use in the playtree
 961     # $maindir must be set, eg by calling record_maindir or fresh_playground
 962     runcmd qw(git init -q);
 963     runcmd qw(git config gc.auto 0);
 964     foreach my $copy (qw(user.email user.name user.useConfigOnly
 965                          core.sharedRepository
 966                          core.compression core.looseCompression
 967                          core.bigFileThreshold core.fsyncObjectFiles)) {
 968         my $v = $t_local_git_cfg->{$copy};
 969         next unless $v;
 970         runcmd qw(git config), $copy, $_ foreach @$v;
 971     }
 972     # this is confusing: we have
 973     #   .                   playtree, not a worktree, has .git/, our cwd
 974     #   $maindir            might be a worktree so
 975     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 976     #   $maindir_gitcommon  the shared stuff, including .objects
 977     rmtree('.git/objects');
 978     symlink "$maindir_gitcommon/objects",'.git/objects' or confess $!;
 979     ensuredir '.git/info';
 980     open GA, "> .git/info/attributes" or confess $!;
 981     print GA "* $negate_harmful_gitattrs\n" or confess $!;
 982     close GA or confess $!;
 983 }
 984
 985 1;